lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset, conditions and
 145 attributes with the same keys need resolving.
 146
 147 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 148 into the existing ones from the original resultset.
 149
 150 The L</where> and L</having> attributes, and any search conditions, are
 151 merged with an SQL C<AND> to the existing condition from the original
 152 resultset.
 153
 154 All other attributes are overridden by any new ones supplied in the
 155 search attributes.
 156
 157 =head2 Multiple queries
 158
 159 Since a resultset just defines a query, you can do all sorts of
 160 things with it with the same object.
 161
 162   # Don't hit the DB yet.
 163   my $cd_rs = $schema->resultset('CD')->search({
 164     title => 'something',
 165     year => 2009,
 166   });
 167
 168   # Each of these hits the DB individually.
 169   my $count = $cd_rs->count;
 170   my $most_recent = $cd_rs->get_column('date_released')->max();
 171   my @records = $cd_rs->all;
 172
 173 And it's not just limited to SELECT statements.
 174
 175   $cd_rs->delete();
 176
 177 This is even cooler:
 178
 179   $cd_rs->create({ artist => 'Fred' });
 180
 181 Which is the same as:
 182
 183   $schema->resultset('CD')->create({
 184     title => 'something',
 185     year => 2009,
 186     artist => 'Fred'
 187   });
 188
 189 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 190
 191 =head1 METHODS
 192
 193 =head2 new
 194
 195 =over 4
 196
 197 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 198
 199 =item Return Value: L<$resultset|/search>
 200
 201 =back
 202
 203 The resultset constructor. Takes a source object (usually a
 204 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 205 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 206 executed as needed by the other methods.
 207
 208 Generally you never construct a resultset manually. Instead you get one
 209 from e.g. a
 210 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 211 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 212 scalar context):
 213
 214   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 215
 216 =over
 217
 218 =item WARNING
 219
 220 If called on an object, proxies to L</new_result> instead, so
 221
 222   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 223
 224 will return a CD object, not a ResultSet, and is equivalent to:
 225
 226   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 227
 228 Please also keep in mind that many internals call L</new_result> directly,
 229 so overloading this method with the idea of intercepting new result object
 230 creation B<will not work>. See also warning pertaining to L</create>.
 231
 232 =back
 233
 234 =cut
 235
 236 sub new {
 237   my $class = shift;
 238   return $class->new_result(@_) if ref $class;
 239
 240   my ($source, $attrs) = @_;
 241   $source = $source->resolve
 242     if $source->isa('DBIx::Class::ResultSourceHandle');
 243   $attrs = { %{$attrs||{}} };
 244
 245   if ($attrs->{page}) {
 246     $attrs->{rows} ||= 10;
 247   }
 248
 249   $attrs->{alias} ||= 'me';
 250
 251   my $self = bless {
 252     result_source => $source,
 253     cond => $attrs->{where},
 254     pager => undef,
 255     attrs => $attrs,
 256   }, $class;
 257
 258   # if there is a dark selector, this means we are already in a
 259   # chain and the cleanup/sanification was taken care of by
 260   # _search_rs already
 261   $self->_normalize_selection($attrs)
 262     unless $attrs->{_dark_selector};
 263
 264   $self->result_class(
 265     $attrs->{result_class} || $source->result_class
 266   );
 267
 268   $self;
 269 }
 270
 271 =head2 search
 272
 273 =over 4
 274
 275 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 276
 277 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 278
 279 =back
 280
 281   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 282   my $new_rs = $cd_rs->search({ year => 2005 });
 283
 284   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 285                  # year = 2005 OR year = 2004
 286
 287 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 288 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 289 To avoid that, use L</search_rs>.
 290
 291 If you need to pass in additional attributes but no additional condition,
 292 call it as C<search(undef, \%attrs)>.
 293
 294   # "SELECT name, artistid FROM $artist_table"
 295   my @all_artists = $schema->resultset('Artist')->search(undef, {
 296     columns => [qw/name artistid/],
 297   });
 298
 299 For a list of attributes that can be passed to C<search>, see
 300 L</ATTRIBUTES>. For more examples of using this function, see
 301 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 302 documentation for the first argument, see L<SQL::Abstract>
 303 and its extension L<DBIx::Class::SQLMaker>.
 304
 305 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 306
 307 =head3 CAVEAT
 308
 309 Note that L</search> does not process/deflate any of the values passed in the
 310 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 311 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 312 manually that any value passed to this method will stringify to something the
 313 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 314 objects, for more info see:
 315 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 316
 317 =cut
 318
 319 sub search {
 320   my $self = shift;
 321   my $rs = $self->search_rs( @_ );
 322
 323   if (wantarray) {
 324     return $rs->all;
 325   }
 326   elsif (defined wantarray) {
 327     return $rs;
 328   }
 329   else {
 330     # we can be called by a relationship helper, which in
 331     # turn may be called in void context due to some braindead
 332     # overload or whatever else the user decided to be clever
 333     # at this particular day. Thus limit the exception to
 334     # external code calls only
 335     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 336       if (caller)[0] !~ /^\QDBIx::Class::/;
 337
 338     return ();
 339   }
 340 }
 341
 342 =head2 search_rs
 343
 344 =over 4
 345
 346 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 347
 348 =item Return Value: L<$resultset|/search>
 349
 350 =back
 351
 352 This method does the same exact thing as search() except it will
 353 always return a resultset, even in list context.
 354
 355 =cut
 356
 357 sub search_rs {
 358   my $self = shift;
 359
 360   my $rsrc = $self->result_source;
 361   my ($call_cond, $call_attrs);
 362
 363   # Special-case handling for (undef, undef) or (undef)
 364   # Note that (foo => undef) is valid deprecated syntax
 365   @_ = () if not scalar grep { defined $_ } @_;
 366
 367   # just a cond
 368   if (@_ == 1) {
 369     $call_cond = shift;
 370   }
 371   # fish out attrs in the ($condref, $attr) case
 372   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 373     ($call_cond, $call_attrs) = @_;
 374   }
 375   elsif (@_ % 2) {
 376     $self->throw_exception('Odd number of arguments to search')
 377   }
 378   # legacy search
 379   elsif (@_) {
 380     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 381       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 382
 383     for my $i (0 .. $#_) {
 384       next if $i % 2;
 385       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 386         if (! defined $_[$i] or ref $_[$i] ne '');
 387     }
 388
 389     $call_cond = { @_ };
 390   }
 391
 392   # see if we can keep the cache (no $rs changes)
 393   my $cache;
 394   my %safe = (alias => 1, cache => 1);
 395   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 396     ! defined $call_cond
 397       or
 398     ref $call_cond eq 'HASH' && ! keys %$call_cond
 399       or
 400     ref $call_cond eq 'ARRAY' && ! @$call_cond
 401   )) {
 402     $cache = $self->get_cache;
 403   }
 404
 405   my $old_attrs = { %{$self->{attrs}} };
 406   my $old_having = delete $old_attrs->{having};
 407   my $old_where = delete $old_attrs->{where};
 408
 409   my $new_attrs = { %$old_attrs };
 410
 411   # take care of call attrs (only if anything is changing)
 412   if ($call_attrs and keys %$call_attrs) {
 413
 414     # copy for _normalize_selection
 415     $call_attrs = { %$call_attrs };
 416
 417     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 418
 419     # reset the current selector list if new selectors are supplied
 420     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 421       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 422     }
 423
 424     # Normalize the new selector list (operates on the passed-in attr structure)
 425     # Need to do it on every chain instead of only once on _resolved_attrs, in
 426     # order to allow detection of empty vs partial 'as'
 427     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 428       if $old_attrs->{_dark_selector};
 429     $self->_normalize_selection ($call_attrs);
 430
 431     # start with blind overwriting merge, exclude selector attrs
 432     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 433     delete @{$new_attrs}{@selector_attrs};
 434
 435     for (@selector_attrs) {
 436       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 437         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 438     }
 439
 440     # older deprecated name, use only if {columns} is not there
 441     if (my $c = delete $new_attrs->{cols}) {
 442       if ($new_attrs->{columns}) {
 443         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 444       }
 445       else {
 446         $new_attrs->{columns} = $c;
 447       }
 448     }
 449
 450
 451     # join/prefetch use their own crazy merging heuristics
 452     foreach my $key (qw/join prefetch/) {
 453       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 454         if exists $call_attrs->{$key};
 455     }
 456
 457     # stack binds together
 458     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 459   }
 460
 461
 462   for ($old_where, $call_cond) {
 463     if (defined $_) {
 464       $new_attrs->{where} = $self->_stack_cond (
 465         $_, $new_attrs->{where}
 466       );
 467     }
 468   }
 469
 470   if (defined $old_having) {
 471     $new_attrs->{having} = $self->_stack_cond (
 472       $old_having, $new_attrs->{having}
 473     )
 474   }
 475
 476   my $rs = (ref $self)->new($rsrc, $new_attrs);
 477
 478   $rs->set_cache($cache) if ($cache);
 479
 480   return $rs;
 481 }
 482
 483 my $dark_sel_dumper;
 484 sub _normalize_selection {
 485   my ($self, $attrs) = @_;
 486
 487   # legacy syntax
 488   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 489     if exists $attrs->{include_columns};
 490
 491   # columns are always placed first, however
 492
 493   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 494   # delay the decision on whether to use a default select list ($rsrc->columns)
 495   # allowing stuff like the remove_columns helper to work
 496   #
 497   # select/as +select/+as pairs need special handling - the amount of select/as
 498   # elements in each pair does *not* have to be equal (think multicolumn
 499   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 500   # supplied at all) - try to infer the alias, either from the -as parameter
 501   # of the selector spec, or use the parameter whole if it looks like a column
 502   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 503   # is ok as well), but make sure no more additions to the 'as' chain take place
 504   for my $pref ('', '+') {
 505
 506     my ($sel, $as) = map {
 507       my $key = "${pref}${_}";
 508
 509       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 510         ? @{$attrs->{$key}}
 511         : $attrs->{$key} || ()
 512       ];
 513       delete $attrs->{$key};
 514       $val;
 515     } qw/select as/;
 516
 517     if (! @$as and ! @$sel ) {
 518       next;
 519     }
 520     elsif (@$as and ! @$sel) {
 521       $self->throw_exception(
 522         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 523       );
 524     }
 525     elsif( ! @$as ) {
 526       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 527       # if any @$as has been supplied we assume the user knows what (s)he is doing
 528       # and blindly keep stacking up pieces
 529       unless ($attrs->{_dark_selector}) {
 530         SELECTOR:
 531         for (@$sel) {
 532           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 533             push @$as, $_->{-as};
 534           }
 535           # assume any plain no-space, no-parenthesis string to be a column spec
 536           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 537           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 538             push @$as, $_;
 539           }
 540           # if all else fails - raise a flag that no more aliasing will be allowed
 541           else {
 542             $attrs->{_dark_selector} = {
 543               plus_stage => $pref,
 544               string => ($dark_sel_dumper ||= do {
 545                   require Data::Dumper::Concise;
 546                   Data::Dumper::Concise::DumperObject()->Indent(0);
 547                 })->Values([$_])->Dump
 548               ,
 549             };
 550             last SELECTOR;
 551           }
 552         }
 553       }
 554     }
 555     elsif (@$as < @$sel) {
 556       $self->throw_exception(
 557         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 558       );
 559     }
 560     elsif ($pref and $attrs->{_dark_selector}) {
 561       $self->throw_exception(
 562         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 563       );
 564     }
 565
 566
 567     # merge result
 568     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 569     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 570   }
 571 }
 572
 573 sub _stack_cond {
 574   my ($self, $left, $right) = @_;
 575
 576   # collapse single element top-level conditions
 577   # (single pass only, unlikely to need recursion)
 578   for ($left, $right) {
 579     if (ref $_ eq 'ARRAY') {
 580       if (@$_ == 0) {
 581         $_ = undef;
 582       }
 583       elsif (@$_ == 1) {
 584         $_ = $_->[0];
 585       }
 586     }
 587     elsif (ref $_ eq 'HASH') {
 588       my ($first, $more) = keys %$_;
 589
 590       # empty hash
 591       if (! defined $first) {
 592         $_ = undef;
 593       }
 594       # one element hash
 595       elsif (! defined $more) {
 596         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 597           $_ = $_->{'-and'};
 598         }
 599         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 600           $_ = $_->{'-or'};
 601         }
 602       }
 603     }
 604   }
 605
 606   # merge hashes with weeding out of duplicates (simple cases only)
 607   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 608
 609     # shallow copy to destroy
 610     $right = { %$right };
 611     for (grep { exists $right->{$_} } keys %$left) {
 612       # the use of eq_deeply here is justified - the rhs of an
 613       # expression can contain a lot of twisted weird stuff
 614       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 615     }
 616
 617     $right = undef unless keys %$right;
 618   }
 619
 620
 621   if (defined $left xor defined $right) {
 622     return defined $left ? $left : $right;
 623   }
 624   elsif (! defined $left) {
 625     return undef;
 626   }
 627   else {
 628     return { -and => [ $left, $right ] };
 629   }
 630 }
 631
 632 =head2 search_literal
 633
 634 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 635 should only be used in that context. C<search_literal> is a convenience
 636 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 637 want to ensure columns are bound correctly, use L</search>.
 638
 639 See L<DBIx::Class::Manual::Cookbook/Searching> and
 640 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 641 require C<search_literal>.
 642
 643 =over 4
 644
 645 =item Arguments: $sql_fragment, @standalone_bind_values
 646
 647 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 648
 649 =back
 650
 651   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 652   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 653
 654 Pass a literal chunk of SQL to be added to the conditional part of the
 655 resultset query.
 656
 657 Example of how to use C<search> instead of C<search_literal>
 658
 659   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 660   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 661
 662 =cut
 663
 664 sub search_literal {
 665   my ($self, $sql, @bind) = @_;
 666   my $attr;
 667   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 668     $attr = pop @bind;
 669   }
 670   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 671 }
 672
 673 =head2 find
 674
 675 =over 4
 676
 677 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 678
 679 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 680
 681 =back
 682
 683 Finds and returns a single row based on supplied criteria. Takes either a
 684 hashref with the same format as L</create> (including inference of foreign
 685 keys from related objects), or a list of primary key values in the same
 686 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 687 declaration on the L</result_source>.
 688
 689 In either case an attempt is made to combine conditions already existing on
 690 the resultset with the condition passed to this method.
 691
 692 To aid with preparing the correct query for the storage you may supply the
 693 C<key> attribute, which is the name of a
 694 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 695 unique constraint corresponding to the
 696 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 697 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 698 to construct a query that satisfies the named unique constraint fully (
 699 non-NULL values for each column member of the constraint) an exception is
 700 thrown.
 701
 702 If no C<key> is specified, the search is carried over all unique constraints
 703 which are fully defined by the available condition.
 704
 705 If no such constraint is found, C<find> currently defaults to a simple
 706 C<< search->(\%column_values) >> which may or may not do what you expect.
 707 Note that this fallback behavior may be deprecated in further versions. If
 708 you need to search with arbitrary conditions - use L</search>. If the query
 709 resulting from this fallback produces more than one row, a warning to the
 710 effect is issued, though only the first row is constructed and returned as
 711 C<$result_object>.
 712
 713 In addition to C<key>, L</find> recognizes and applies standard
 714 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 715
 716 Note that if you have extra concerns about the correctness of the resulting
 717 query you need to specify the C<key> attribute and supply the entire condition
 718 as an argument to find (since it is not always possible to perform the
 719 combination of the resultset condition with the supplied one, especially if
 720 the resultset condition contains literal sql).
 721
 722 For example, to find a row by its primary key:
 723
 724   my $cd = $schema->resultset('CD')->find(5);
 725
 726 You can also find a row by a specific unique constraint:
 727
 728   my $cd = $schema->resultset('CD')->find(
 729     {
 730       artist => 'Massive Attack',
 731       title  => 'Mezzanine',
 732     },
 733     { key => 'cd_artist_title' }
 734   );
 735
 736 See also L</find_or_create> and L</update_or_create>.
 737
 738 =cut
 739
 740 sub find {
 741   my $self = shift;
 742   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 743
 744   my $rsrc = $self->result_source;
 745
 746   my $constraint_name;
 747   if (exists $attrs->{key}) {
 748     $constraint_name = defined $attrs->{key}
 749       ? $attrs->{key}
 750       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 751     ;
 752   }
 753
 754   # Parse out the condition from input
 755   my $call_cond;
 756
 757   if (ref $_[0] eq 'HASH') {
 758     $call_cond = { %{$_[0]} };
 759   }
 760   else {
 761     # if only values are supplied we need to default to 'primary'
 762     $constraint_name = 'primary' unless defined $constraint_name;
 763
 764     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 765
 766     $self->throw_exception(
 767       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 768     ) unless @c_cols;
 769
 770     $self->throw_exception (
 771       'find() expects either a column/value hashref, or a list of values '
 772     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 773     ) unless @c_cols == @_;
 774
 775     $call_cond = {};
 776     @{$call_cond}{@c_cols} = @_;
 777   }
 778
 779   my %related;
 780   for my $key (keys %$call_cond) {
 781     if (
 782       my $keyref = ref($call_cond->{$key})
 783         and
 784       my $relinfo = $rsrc->relationship_info($key)
 785     ) {
 786       my $val = delete $call_cond->{$key};
 787
 788       next if $keyref eq 'ARRAY'; # has_many for multi_create
 789
 790       my $rel_q = $rsrc->_resolve_condition(
 791         $relinfo->{cond}, $val, $key, $key
 792       );
 793       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 794       @related{keys %$rel_q} = values %$rel_q;
 795     }
 796   }
 797
 798   # relationship conditions take precedence (?)
 799   @{$call_cond}{keys %related} = values %related;
 800
 801   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 802   my $final_cond;
 803   if (defined $constraint_name) {
 804     $final_cond = $self->_qualify_cond_columns (
 805
 806       $self->_build_unique_cond (
 807         $constraint_name,
 808         $call_cond,
 809       ),
 810
 811       $alias,
 812     );
 813   }
 814   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 815     # This means that we got here after a merger of relationship conditions
 816     # in ::Relationship::Base::search_related (the row method), and furthermore
 817     # the relationship is of the 'single' type. This means that the condition
 818     # provided by the relationship (already attached to $self) is sufficient,
 819     # as there can be only one row in the database that would satisfy the
 820     # relationship
 821   }
 822   else {
 823     # no key was specified - fall down to heuristics mode:
 824     # run through all unique queries registered on the resultset, and
 825     # 'OR' all qualifying queries together
 826     my (@unique_queries, %seen_column_combinations);
 827     for my $c_name ($rsrc->unique_constraint_names) {
 828       next if $seen_column_combinations{
 829         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 830       }++;
 831
 832       push @unique_queries, try {
 833         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 834       } || ();
 835     }
 836
 837     $final_cond = @unique_queries
 838       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 839       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 840     ;
 841   }
 842
 843   # Run the query, passing the result_class since it should propagate for find
 844   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 845   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 846     my $row = $rs->next;
 847     carp "Query returned more than one row" if $rs->next;
 848     return $row;
 849   }
 850   else {
 851     return $rs->single;
 852   }
 853 }
 854
 855 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 856 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 857 #
 858 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 859 # condition. It is provided for overrides until a saner way forward is devised
 860 #
 861 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 862 # the road. Please adjust your tests accordingly to catch this situation early
 863 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 864 #
 865 # The method will not be removed without an adequately complete replacement
 866 # for strict-mode enforcement
 867 sub _non_unique_find_fallback {
 868   my ($self, $cond, $attrs) = @_;
 869
 870   return $self->_qualify_cond_columns(
 871     $cond,
 872     exists $attrs->{alias}
 873       ? $attrs->{alias}
 874       : $self->{attrs}{alias}
 875   );
 876 }
 877
 878
 879 sub _qualify_cond_columns {
 880   my ($self, $cond, $alias) = @_;
 881
 882   my %aliased = %$cond;
 883   for (keys %aliased) {
 884     $aliased{"$alias.$_"} = delete $aliased{$_}
 885       if $_ !~ /\./;
 886   }
 887
 888   return \%aliased;
 889 }
 890
 891 sub _build_unique_cond {
 892   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 893
 894   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 895
 896   # combination may fail if $self->{cond} is non-trivial
 897   my ($final_cond) = try {
 898     $self->_merge_with_rscond ($extra_cond)
 899   } catch {
 900     +{ %$extra_cond }
 901   };
 902
 903   # trim out everything not in $columns
 904   $final_cond = { map {
 905     exists $final_cond->{$_}
 906       ? ( $_ => $final_cond->{$_} )
 907       : ()
 908   } @c_cols };
 909
 910   if (my @missing = grep
 911     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 912     (@c_cols)
 913   ) {
 914     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 915       $constraint_name,
 916       join (', ', map { "'$_'" } @missing),
 917     ) );
 918   }
 919
 920   if (
 921     !$croak_on_null
 922       and
 923     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 924       and
 925     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 926   ) {
 927     carp_unique ( sprintf (
 928       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 929     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 930     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 931       $constraint_name,
 932       join (', ', map { "'$_'" } @undefs),
 933     ));
 934   }
 935
 936   return $final_cond;
 937 }
 938
 939 =head2 search_related
 940
 941 =over 4
 942
 943 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 944
 945 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 946
 947 =back
 948
 949   $new_rs = $cd_rs->search_related('artist', {
 950     name => 'Emo-R-Us',
 951   });
 952
 953 Searches the specified relationship, optionally specifying a condition and
 954 attributes for matching records. See L</ATTRIBUTES> for more information.
 955
 956 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 957 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 958
 959 See also L</search_related_rs>.
 960
 961 =cut
 962
 963 sub search_related {
 964   return shift->related_resultset(shift)->search(@_);
 965 }
 966
 967 =head2 search_related_rs
 968
 969 This method works exactly the same as search_related, except that
 970 it guarantees a resultset, even in list context.
 971
 972 =cut
 973
 974 sub search_related_rs {
 975   return shift->related_resultset(shift)->search_rs(@_);
 976 }
 977
 978 =head2 cursor
 979
 980 =over 4
 981
 982 =item Arguments: none
 983
 984 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 985
 986 =back
 987
 988 Returns a storage-driven cursor to the given resultset. See
 989 L<DBIx::Class::Cursor> for more information.
 990
 991 =cut
 992
 993 sub cursor {
 994   my $self = shift;
 995
 996   return $self->{cursor} ||= do {
 997     my $attrs = { %{$self->_resolved_attrs } };
 998     $self->result_source->storage->select(
 999       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1000     );
1001   };
1002 }
1003
1004 =head2 single
1005
1006 =over 4
1007
1008 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1009
1010 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1011
1012 =back
1013
1014   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1015
1016 Inflates the first result without creating a cursor if the resultset has
1017 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1018 of L</search>.
1019
1020 While this method can take an optional search condition (just like L</search>)
1021 being a fast-code-path it does not recognize search attributes. If you need to
1022 add extra joins or similar, call L</search> and then chain-call L</single> on the
1023 L<DBIx::Class::ResultSet> returned.
1024
1025 =over
1026
1027 =item B<Note>
1028
1029 As of 0.08100, this method enforces the assumption that the preceding
1030 query returns only one row. If more than one row is returned, you will receive
1031 a warning:
1032
1033   Query returned more than one row
1034
1035 In this case, you should be using L</next> or L</find> instead, or if you really
1036 know what you are doing, use the L</rows> attribute to explicitly limit the size
1037 of the resultset.
1038
1039 This method will also throw an exception if it is called on a resultset prefetching
1040 has_many, as such a prefetch implies fetching multiple rows from the database in
1041 order to assemble the resulting object.
1042
1043 =back
1044
1045 =cut
1046
1047 sub single {
1048   my ($self, $where) = @_;
1049   if(@_ > 2) {
1050       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1051   }
1052
1053   my $attrs = { %{$self->_resolved_attrs} };
1054
1055   if (keys %{$attrs->{collapse}}) {
1056     $self->throw_exception(
1057       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1058     );
1059   }
1060
1061   if ($where) {
1062     if (defined $attrs->{where}) {
1063       $attrs->{where} = {
1064         '-and' =>
1065             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1066                $where, delete $attrs->{where} ]
1067       };
1068     } else {
1069       $attrs->{where} = $where;
1070     }
1071   }
1072
1073   my @data = $self->result_source->storage->select_single(
1074     $attrs->{from}, $attrs->{select},
1075     $attrs->{where}, $attrs
1076   );
1077
1078   return (@data ? ($self->_construct_object(@data))[0] : undef);
1079 }
1080
1081
1082 # _collapse_query
1083 #
1084 # Recursively collapse the query, accumulating values for each column.
1085
1086 sub _collapse_query {
1087   my ($self, $query, $collapsed) = @_;
1088
1089   $collapsed ||= {};
1090
1091   if (ref $query eq 'ARRAY') {
1092     foreach my $subquery (@$query) {
1093       next unless ref $subquery;  # -or
1094       $collapsed = $self->_collapse_query($subquery, $collapsed);
1095     }
1096   }
1097   elsif (ref $query eq 'HASH') {
1098     if (keys %$query and (keys %$query)[0] eq '-and') {
1099       foreach my $subquery (@{$query->{-and}}) {
1100         $collapsed = $self->_collapse_query($subquery, $collapsed);
1101       }
1102     }
1103     else {
1104       foreach my $col (keys %$query) {
1105         my $value = $query->{$col};
1106         $collapsed->{$col}{$value}++;
1107       }
1108     }
1109   }
1110
1111   return $collapsed;
1112 }
1113
1114 =head2 get_column
1115
1116 =over 4
1117
1118 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1119
1120 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1121
1122 =back
1123
1124   my $max_length = $rs->get_column('length')->max;
1125
1126 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1127
1128 =cut
1129
1130 sub get_column {
1131   my ($self, $column) = @_;
1132   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1133   return $new;
1134 }
1135
1136 =head2 search_like
1137
1138 =over 4
1139
1140 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1141
1142 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1143
1144 =back
1145
1146   # WHERE title LIKE '%blue%'
1147   $cd_rs = $rs->search_like({ title => '%blue%'});
1148
1149 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1150 that this is simply a convenience method retained for ex Class::DBI users.
1151 You most likely want to use L</search> with specific operators.
1152
1153 For more information, see L<DBIx::Class::Manual::Cookbook>.
1154
1155 This method is deprecated and will be removed in 0.09. Use L</search()>
1156 instead. An example conversion is:
1157
1158   ->search_like({ foo => 'bar' });
1159
1160   # Becomes
1161
1162   ->search({ foo => { like => 'bar' } });
1163
1164 =cut
1165
1166 sub search_like {
1167   my $class = shift;
1168   carp_unique (
1169     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1170    .' Instead use ->search({ x => { -like => "y%" } })'
1171    .' (note the outer pair of {}s - they are important!)'
1172   );
1173   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1174   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1175   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1176   return $class->search($query, { %$attrs });
1177 }
1178
1179 =head2 slice
1180
1181 =over 4
1182
1183 =item Arguments: $first, $last
1184
1185 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1186
1187 =back
1188
1189 Returns a resultset or object list representing a subset of elements from the
1190 resultset slice is called on. Indexes are from 0, i.e., to get the first
1191 three records, call:
1192
1193   my ($one, $two, $three) = $rs->slice(0, 2);
1194
1195 =cut
1196
1197 sub slice {
1198   my ($self, $min, $max) = @_;
1199   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1200   $attrs->{offset} = $self->{attrs}{offset} || 0;
1201   $attrs->{offset} += $min;
1202   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1203   return $self->search(undef, $attrs);
1204   #my $slice = (ref $self)->new($self->result_source, $attrs);
1205   #return (wantarray ? $slice->all : $slice);
1206 }
1207
1208 =head2 next
1209
1210 =over 4
1211
1212 =item Arguments: none
1213
1214 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1215
1216 =back
1217
1218 Returns the next element in the resultset (C<undef> is there is none).
1219
1220 Can be used to efficiently iterate over records in the resultset:
1221
1222   my $rs = $schema->resultset('CD')->search;
1223   while (my $cd = $rs->next) {
1224     print $cd->title;
1225   }
1226
1227 Note that you need to store the resultset object, and call C<next> on it.
1228 Calling C<< resultset('Table')->next >> repeatedly will always return the
1229 first record from the resultset.
1230
1231 =cut
1232
1233 sub next {
1234   my ($self) = @_;
1235   if (my $cache = $self->get_cache) {
1236     $self->{all_cache_position} ||= 0;
1237     return $cache->[$self->{all_cache_position}++];
1238   }
1239   if ($self->{attrs}{cache}) {
1240     delete $self->{pager};
1241     $self->{all_cache_position} = 1;
1242     return ($self->all)[0];
1243   }
1244   if ($self->{stashed_objects}) {
1245     my $obj = shift(@{$self->{stashed_objects}});
1246     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1247     return $obj;
1248   }
1249   my @row = (
1250     exists $self->{stashed_row}
1251       ? @{delete $self->{stashed_row}}
1252       : $self->cursor->next
1253   );
1254   return undef unless (@row);
1255   my ($row, @more) = $self->_construct_object(@row);
1256   $self->{stashed_objects} = \@more if @more;
1257   return $row;
1258 }
1259
1260 sub _construct_object {
1261   my ($self, @row) = @_;
1262
1263   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1264     or return ();
1265   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1266   @new = $self->{_attrs}{record_filter}->(@new)
1267     if exists $self->{_attrs}{record_filter};
1268   return @new;
1269 }
1270
1271 sub _collapse_result {
1272   my ($self, $as_proto, $row) = @_;
1273
1274   my @copy = @$row;
1275
1276   # 'foo'         => [ undef, 'foo' ]
1277   # 'foo.bar'     => [ 'foo', 'bar' ]
1278   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1279
1280   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1281
1282   my %collapse = %{$self->{_attrs}{collapse}||{}};
1283
1284   my @pri_index;
1285
1286   # if we're doing collapsing (has_many prefetch) we need to grab records
1287   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1288   # we know we don't have to bother.
1289
1290   # the reason for not using the collapse stuff directly is because if you
1291   # had for e.g. two artists in a row with no cds, the collapse info for
1292   # both would be NULL (undef) so you'd lose the second artist
1293
1294   # store just the index so we can check the array positions from the row
1295   # without having to contruct the full hash
1296
1297   if (keys %collapse) {
1298     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1299     foreach my $i (0 .. $#construct_as) {
1300       next if defined($construct_as[$i][0]); # only self table
1301       if (delete $pri{$construct_as[$i][1]}) {
1302         push(@pri_index, $i);
1303       }
1304       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1305     }
1306   }
1307
1308   # no need to do an if, it'll be empty if @pri_index is empty anyway
1309
1310   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1311
1312   my @const_rows;
1313
1314   do { # no need to check anything at the front, we always want the first row
1315
1316     my %const;
1317
1318     foreach my $this_as (@construct_as) {
1319       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1320     }
1321
1322     push(@const_rows, \%const);
1323
1324   } until ( # no pri_index => no collapse => drop straight out
1325       !@pri_index
1326     or
1327       do { # get another row, stash it, drop out if different PK
1328
1329         @copy = $self->cursor->next;
1330         $self->{stashed_row} = \@copy;
1331
1332         # last thing in do block, counts as true if anything doesn't match
1333
1334         # check xor defined first for NULL vs. NOT NULL then if one is
1335         # defined the other must be so check string equality
1336
1337         grep {
1338           (defined $pri_vals{$_} ^ defined $copy[$_])
1339           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1340         } @pri_index;
1341       }
1342   );
1343
1344   my $alias = $self->{attrs}{alias};
1345   my $info = [];
1346
1347   my %collapse_pos;
1348
1349   my @const_keys;
1350
1351   foreach my $const (@const_rows) {
1352     scalar @const_keys or do {
1353       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1354     };
1355     foreach my $key (@const_keys) {
1356       if (length $key) {
1357         my $target = $info;
1358         my @parts = split(/\./, $key);
1359         my $cur = '';
1360         my $data = $const->{$key};
1361         foreach my $p (@parts) {
1362           $target = $target->[1]->{$p} ||= [];
1363           $cur .= ".${p}";
1364           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1365             # collapsing at this point and on final part
1366             my $pos = $collapse_pos{$cur};
1367             CK: foreach my $ck (@ckey) {
1368               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1369                 $collapse_pos{$cur} = $data;
1370                 delete @collapse_pos{ # clear all positioning for sub-entries
1371                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1372                 };
1373                 push(@$target, []);
1374                 last CK;
1375               }
1376             }
1377           }
1378           if (exists $collapse{$cur}) {
1379             $target = $target->[-1];
1380           }
1381         }
1382         $target->[0] = $data;
1383       } else {
1384         $info->[0] = $const->{$key};
1385       }
1386     }
1387   }
1388
1389   return $info;
1390 }
1391
1392 =head2 result_source
1393
1394 =over 4
1395
1396 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1397
1398 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1399
1400 =back
1401
1402 An accessor for the primary ResultSource object from which this ResultSet
1403 is derived.
1404
1405 =head2 result_class
1406
1407 =over 4
1408
1409 =item Arguments: $result_class?
1410
1411 =item Return Value: $result_class
1412
1413 =back
1414
1415 An accessor for the class to use when creating result objects. Defaults to
1416 C<< result_source->result_class >> - which in most cases is the name of the
1417 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1418
1419 Note that changing the result_class will also remove any components
1420 that were originally loaded in the source class via
1421 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1422 in the original source class will not run.
1423
1424 =cut
1425
1426 sub result_class {
1427   my ($self, $result_class) = @_;
1428   if ($result_class) {
1429     unless (ref $result_class) { # don't fire this for an object
1430       $self->ensure_class_loaded($result_class);
1431     }
1432     $self->_result_class($result_class);
1433     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1434     # permit the user to set result class on one result set only; it only
1435     # chains if provided to search()
1436     #$self->{attrs}{result_class} = $result_class if ref $self;
1437   }
1438   $self->_result_class;
1439 }
1440
1441 =head2 count
1442
1443 =over 4
1444
1445 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1446
1447 =item Return Value: $count
1448
1449 =back
1450
1451 Performs an SQL C<COUNT> with the same query as the resultset was built
1452 with to find the number of elements. Passing arguments is equivalent to
1453 C<< $rs->search ($cond, \%attrs)->count >>
1454
1455 =cut
1456
1457 sub count {
1458   my $self = shift;
1459   return $self->search(@_)->count if @_ and defined $_[0];
1460   return scalar @{ $self->get_cache } if $self->get_cache;
1461
1462   my $attrs = { %{ $self->_resolved_attrs } };
1463
1464   # this is a little optimization - it is faster to do the limit
1465   # adjustments in software, instead of a subquery
1466   my $rows = delete $attrs->{rows};
1467   my $offset = delete $attrs->{offset};
1468
1469   my $crs;
1470   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1471     $crs = $self->_count_subq_rs ($attrs);
1472   }
1473   else {
1474     $crs = $self->_count_rs ($attrs);
1475   }
1476   my $count = $crs->next;
1477
1478   $count -= $offset if $offset;
1479   $count = $rows if $rows and $rows < $count;
1480   $count = 0 if ($count < 0);
1481
1482   return $count;
1483 }
1484
1485 =head2 count_rs
1486
1487 =over 4
1488
1489 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1490
1491 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1492
1493 =back
1494
1495 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1496 This can be very handy for subqueries:
1497
1498   ->search( { amount => $some_rs->count_rs->as_query } )
1499
1500 As with regular resultsets the SQL query will be executed only after
1501 the resultset is accessed via L</next> or L</all>. That would return
1502 the same single value obtainable via L</count>.
1503
1504 =cut
1505
1506 sub count_rs {
1507   my $self = shift;
1508   return $self->search(@_)->count_rs if @_;
1509
1510   # this may look like a lack of abstraction (count() does about the same)
1511   # but in fact an _rs *must* use a subquery for the limits, as the
1512   # software based limiting can not be ported if this $rs is to be used
1513   # in a subquery itself (i.e. ->as_query)
1514   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1515     return $self->_count_subq_rs;
1516   }
1517   else {
1518     return $self->_count_rs;
1519   }
1520 }
1521
1522 #
1523 # returns a ResultSetColumn object tied to the count query
1524 #
1525 sub _count_rs {
1526   my ($self, $attrs) = @_;
1527
1528   my $rsrc = $self->result_source;
1529   $attrs ||= $self->_resolved_attrs;
1530
1531   my $tmp_attrs = { %$attrs };
1532   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1533   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1534
1535   # overwrite the selector (supplied by the storage)
1536   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1537   $tmp_attrs->{as} = 'count';
1538   delete @{$tmp_attrs}{qw/columns/};
1539
1540   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1541
1542   return $tmp_rs;
1543 }
1544
1545 #
1546 # same as above but uses a subquery
1547 #
1548 sub _count_subq_rs {
1549   my ($self, $attrs) = @_;
1550
1551   my $rsrc = $self->result_source;
1552   $attrs ||= $self->_resolved_attrs;
1553
1554   my $sub_attrs = { %$attrs };
1555   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1556   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1557
1558   # if we multi-prefetch we group_by something unique, as this is what we would
1559   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1560   if ( keys %{$attrs->{collapse}}  ) {
1561     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1562       $rsrc->_identifying_column_set || $self->throw_exception(
1563         'Unable to construct a unique group_by criteria properly collapsing the '
1564       . 'has_many prefetch before count()'
1565       );
1566     } ]
1567   }
1568
1569   # Calculate subquery selector
1570   if (my $g = $sub_attrs->{group_by}) {
1571
1572     my $sql_maker = $rsrc->storage->sql_maker;
1573
1574     # necessary as the group_by may refer to aliased functions
1575     my $sel_index;
1576     for my $sel (@{$attrs->{select}}) {
1577       $sel_index->{$sel->{-as}} = $sel
1578         if (ref $sel eq 'HASH' and $sel->{-as});
1579     }
1580
1581     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1582     # also look for named aggregates referred in the having clause
1583     # having often contains scalarrefs - thus parse it out entirely
1584     my @parts = @$g;
1585     if ($attrs->{having}) {
1586       local $sql_maker->{having_bind};
1587       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1588       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1589       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1590         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1591         # if we don't unset it we screw up retarded but unfortunately working
1592         # 'MAX(foo.bar)' => { '>', 3 }
1593         $sql_maker->{name_sep} = '';
1594       }
1595
1596       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1597
1598       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1599       my %seen_having;
1600
1601       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1602       # and if all fails for an utterly naive quoted scalar-with-function
1603       while ($having_sql =~ /
1604         $rquote $sep $lquote (.+?) $rquote
1605           |
1606         [\s,] \w+ \. (\w+) [\s,]
1607           |
1608         [\s,] $lquote (.+?) $rquote [\s,]
1609       /gx) {
1610         my $part = $1 || $2 || $3;  # one of them matched if we got here
1611         unless ($seen_having{$part}++) {
1612           push @parts, $part;
1613         }
1614       }
1615     }
1616
1617     for (@parts) {
1618       my $colpiece = $sel_index->{$_} || $_;
1619
1620       # unqualify join-based group_by's. Arcane but possible query
1621       # also horrible horrible hack to alias a column (not a func.)
1622       # (probably need to introduce SQLA syntax)
1623       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1624         my $as = $colpiece;
1625         $as =~ s/\./__/;
1626         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1627       }
1628       push @{$sub_attrs->{select}}, $colpiece;
1629     }
1630   }
1631   else {
1632     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1633     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1634   }
1635
1636   return $rsrc->resultset_class
1637                ->new ($rsrc, $sub_attrs)
1638                 ->as_subselect_rs
1639                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1640                   ->get_column ('count');
1641 }
1642
1643
1644 =head2 count_literal
1645
1646 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1647 should only be used in that context. See L</search_literal> for further info.
1648
1649 =over 4
1650
1651 =item Arguments: $sql_fragment, @standalone_bind_values
1652
1653 =item Return Value: $count
1654
1655 =back
1656
1657 Counts the results in a literal query. Equivalent to calling L</search_literal>
1658 with the passed arguments, then L</count>.
1659
1660 =cut
1661
1662 sub count_literal { shift->search_literal(@_)->count; }
1663
1664 =head2 all
1665
1666 =over 4
1667
1668 =item Arguments: none
1669
1670 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1671
1672 =back
1673
1674 Returns all elements in the resultset.
1675
1676 =cut
1677
1678 sub all {
1679   my $self = shift;
1680   if(@_) {
1681       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1682   }
1683
1684   return @{ $self->get_cache } if $self->get_cache;
1685
1686   my @obj;
1687
1688   if (keys %{$self->_resolved_attrs->{collapse}}) {
1689     # Using $self->cursor->all is really just an optimisation.
1690     # If we're collapsing has_many prefetches it probably makes
1691     # very little difference, and this is cleaner than hacking
1692     # _construct_object to survive the approach
1693     $self->cursor->reset;
1694     my @row = $self->cursor->next;
1695     while (@row) {
1696       push(@obj, $self->_construct_object(@row));
1697       @row = (exists $self->{stashed_row}
1698                ? @{delete $self->{stashed_row}}
1699                : $self->cursor->next);
1700     }
1701   } else {
1702     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1703   }
1704
1705   $self->set_cache(\@obj) if $self->{attrs}{cache};
1706
1707   return @obj;
1708 }
1709
1710 =head2 reset
1711
1712 =over 4
1713
1714 =item Arguments: none
1715
1716 =item Return Value: $self
1717
1718 =back
1719
1720 Resets the resultset's cursor, so you can iterate through the elements again.
1721 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1722 another query.
1723
1724 =cut
1725
1726 sub reset {
1727   my ($self) = @_;
1728   $self->{all_cache_position} = 0;
1729   $self->cursor->reset;
1730   return $self;
1731 }
1732
1733 =head2 first
1734
1735 =over 4
1736
1737 =item Arguments: none
1738
1739 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1740
1741 =back
1742
1743 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1744 an object for the first result (or C<undef> if the resultset is empty).
1745
1746 =cut
1747
1748 sub first {
1749   return $_[0]->reset->next;
1750 }
1751
1752
1753 # _rs_update_delete
1754 #
1755 # Determines whether and what type of subquery is required for the $rs operation.
1756 # If grouping is necessary either supplies its own, or verifies the current one
1757 # After all is done delegates to the proper storage method.
1758
1759 sub _rs_update_delete {
1760   my ($self, $op, $values) = @_;
1761
1762   my $rsrc = $self->result_source;
1763   my $storage = $rsrc->schema->storage;
1764
1765   my $attrs = { %{$self->_resolved_attrs} };
1766
1767   my $join_classifications;
1768   my $existing_group_by = delete $attrs->{group_by};
1769
1770   # do we need a subquery for any reason?
1771   my $needs_subq = (
1772     defined $existing_group_by
1773       or
1774     # if {from} is unparseable wrap a subq
1775     ref($attrs->{from}) ne 'ARRAY'
1776       or
1777     # limits call for a subq
1778     $self->_has_resolved_attr(qw/rows offset/)
1779   );
1780
1781   # simplify the joinmap, so we can further decide if a subq is necessary
1782   if (!$needs_subq and @{$attrs->{from}} > 1) {
1783     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1784
1785     # check if there are any joins left after the prune
1786     if ( @{$attrs->{from}} > 1 ) {
1787       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1788         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1789         $attrs->{select},
1790         $self->{cond},
1791         $attrs
1792       );
1793
1794       # any non-pruneable joins imply subq
1795       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1796     }
1797   }
1798
1799   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1800   $needs_subq ||= (
1801     (ref $attrs->{from}[0]) ne 'HASH'
1802       or
1803     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1804   );
1805
1806   my ($cond, $guard);
1807   # do we need anything like a subquery?
1808   if (! $needs_subq) {
1809     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1810     # a condition containing 'me' or other table prefixes will not work
1811     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1812     $cond = do {
1813       my $sqla = $rsrc->storage->sql_maker;
1814       local $sqla->{_dequalify_idents} = 1;
1815       \[ $sqla->_recurse_where($self->{cond}) ];
1816     };
1817   }
1818   else {
1819     # we got this far - means it is time to wrap a subquery
1820     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1821       sprintf(
1822         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1823         $op,
1824         $rsrc->source_name,
1825       )
1826     );
1827
1828     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1829     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1830     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1831     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1832     my $subrs = (ref $self)->new($rsrc, $attrs);
1833
1834     if (@$idcols == 1) {
1835       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1836     }
1837     elsif ($storage->_use_multicolumn_in) {
1838       # no syntax for calling this properly yet
1839       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1840       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1841         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1842         $subrs->as_query
1843       ),
1844     }
1845     else {
1846       # if all else fails - get all primary keys and operate over a ORed set
1847       # wrap in a transaction for consistency
1848       # this is where the group_by/multiplication starts to matter
1849       if (
1850         $existing_group_by
1851           or
1852         keys %{ $join_classifications->{multiplying} || {} }
1853       ) {
1854         # make sure if there is a supplied group_by it matches the columns compiled above
1855         # perfectly. Anything else can not be sanely executed on most databases so croak
1856         # right then and there
1857         if ($existing_group_by) {
1858           my @current_group_by = map
1859             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1860             @$existing_group_by
1861           ;
1862
1863           if (
1864             join ("\x00", sort @current_group_by)
1865               ne
1866             join ("\x00", sort @{$attrs->{columns}} )
1867           ) {
1868             $self->throw_exception (
1869               "You have just attempted a $op operation on a resultset which does group_by"
1870               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1871               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1872               . ' kind of queries. Please retry the operation with a modified group_by or'
1873               . ' without using one at all.'
1874             );
1875           }
1876         }
1877
1878         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1879       }
1880
1881       $guard = $storage->txn_scope_guard;
1882
1883       $cond = [];
1884       for my $row ($subrs->cursor->all) {
1885         push @$cond, { map
1886           { $idcols->[$_] => $row->[$_] }
1887           (0 .. $#$idcols)
1888         };
1889       }
1890     }
1891   }
1892
1893   my $res = $storage->$op (
1894     $rsrc,
1895     $op eq 'update' ? $values : (),
1896     $cond,
1897   );
1898
1899   $guard->commit if $guard;
1900
1901   return $res;
1902 }
1903
1904 =head2 update
1905
1906 =over 4
1907
1908 =item Arguments: \%values
1909
1910 =item Return Value: $underlying_storage_rv
1911
1912 =back
1913
1914 Sets the specified columns in the resultset to the supplied values in a
1915 single query. Note that this will not run any accessor/set_column/update
1916 triggers, nor will it update any result object instances derived from this
1917 resultset (this includes the contents of the L<resultset cache|/set_cache>
1918 if any). See L</update_all> if you need to execute any on-update
1919 triggers or cascades defined either by you or a
1920 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1921
1922 The return value is a pass through of what the underlying
1923 storage backend returned, and may vary. See L<DBI/execute> for the most
1924 common case.
1925
1926 =head3 CAVEAT
1927
1928 Note that L</update> does not process/deflate any of the values passed in.
1929 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1930 ensure manually that any value passed to this method will stringify to
1931 something the RDBMS knows how to deal with. A notable example is the
1932 handling of L<DateTime> objects, for more info see:
1933 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1934
1935 =cut
1936
1937 sub update {
1938   my ($self, $values) = @_;
1939   $self->throw_exception('Values for update must be a hash')
1940     unless ref $values eq 'HASH';
1941
1942   return $self->_rs_update_delete ('update', $values);
1943 }
1944
1945 =head2 update_all
1946
1947 =over 4
1948
1949 =item Arguments: \%values
1950
1951 =item Return Value: 1
1952
1953 =back
1954
1955 Fetches all objects and updates them one at a time via
1956 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1957 triggers, while L</update> will not.
1958
1959 =cut
1960
1961 sub update_all {
1962   my ($self, $values) = @_;
1963   $self->throw_exception('Values for update_all must be a hash')
1964     unless ref $values eq 'HASH';
1965
1966   my $guard = $self->result_source->schema->txn_scope_guard;
1967   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1968   $guard->commit;
1969   return 1;
1970 }
1971
1972 =head2 delete
1973
1974 =over 4
1975
1976 =item Arguments: none
1977
1978 =item Return Value: $underlying_storage_rv
1979
1980 =back
1981
1982 Deletes the rows matching this resultset in a single query. Note that this
1983 will not run any delete triggers, nor will it alter the
1984 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1985 derived from this resultset (this includes the contents of the
1986 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1987 execute any on-delete triggers or cascades defined either by you or a
1988 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1989
1990 The return value is a pass through of what the underlying storage backend
1991 returned, and may vary. See L<DBI/execute> for the most common case.
1992
1993 =cut
1994
1995 sub delete {
1996   my $self = shift;
1997   $self->throw_exception('delete does not accept any arguments')
1998     if @_;
1999
2000   return $self->_rs_update_delete ('delete');
2001 }
2002
2003 =head2 delete_all
2004
2005 =over 4
2006
2007 =item Arguments: none
2008
2009 =item Return Value: 1
2010
2011 =back
2012
2013 Fetches all objects and deletes them one at a time via
2014 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2015 triggers, while L</delete> will not.
2016
2017 =cut
2018
2019 sub delete_all {
2020   my $self = shift;
2021   $self->throw_exception('delete_all does not accept any arguments')
2022     if @_;
2023
2024   my $guard = $self->result_source->schema->txn_scope_guard;
2025   $_->delete for $self->all;
2026   $guard->commit;
2027   return 1;
2028 }
2029
2030 =head2 populate
2031
2032 =over 4
2033
2034 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2035
2036 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2037
2038 =back
2039
2040 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2041 arrayrefs.
2042
2043 =over
2044
2045 =item NOTE
2046
2047 The context of this method call has an important effect on what is
2048 submitted to storage. In void context data is fed directly to fastpath
2049 insertion routines provided by the underlying storage (most often
2050 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2051 L<insert|DBIx::Class::Row/insert> calls on the
2052 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2053 augmentation of these methods provided by components. For example if you
2054 are using something like L<DBIx::Class::UUIDColumns> to create primary
2055 keys for you, you will find that your PKs are empty.  In this case you
2056 will have to explicitly force scalar or list context in order to create
2057 those values.
2058
2059 =back
2060
2061 In non-void (scalar or list) context, this method is simply a wrapper
2062 for L</create>. Depending on list or scalar context either a list of
2063 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2064 containing these objects is returned.
2065
2066 When supplying data in "arrayref of arrayrefs" invocation style, the
2067 first element should be a list of column names and each subsequent
2068 element should be a data value in the earlier specified column order.
2069 For example:
2070
2071   $Arstist_rs->populate([
2072     [ qw( artistid name ) ],
2073     [ 100, 'A Formally Unknown Singer' ],
2074     [ 101, 'A singer that jumped the shark two albums ago' ],
2075     [ 102, 'An actually cool singer' ],
2076   ]);
2077
2078 For the arrayref of hashrefs style each hashref should be a structure
2079 suitable for passing to L</create>. Multi-create is also permitted with
2080 this syntax.
2081
2082   $schema->resultset("Artist")->populate([
2083      { artistid => 4, name => 'Manufactured Crap', cds => [
2084         { title => 'My First CD', year => 2006 },
2085         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2086       ],
2087      },
2088      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2089         { title => 'My parents sold me to a record company', year => 2005 },
2090         { title => 'Why Am I So Ugly?', year => 2006 },
2091         { title => 'I Got Surgery and am now Popular', year => 2007 }
2092       ],
2093      },
2094   ]);
2095
2096 If you attempt a void-context multi-create as in the example above (each
2097 Artist also has the related list of CDs), and B<do not> supply the
2098 necessary autoinc foreign key information, this method will proxy to the
2099 less efficient L</create>, and then throw the Result objects away. In this
2100 case there are obviously no benefits to using this method over L</create>.
2101
2102 =cut
2103
2104 sub populate {
2105   my $self = shift;
2106
2107   # cruft placed in standalone method
2108   my $data = $self->_normalize_populate_args(@_);
2109
2110   return unless @$data;
2111
2112   if(defined wantarray) {
2113     my @created = map { $self->create($_) } @$data;
2114     return wantarray ? @created : \@created;
2115   }
2116   else {
2117     my $first = $data->[0];
2118
2119     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2120     # it relationship data
2121     my (@rels, @columns);
2122     my $rsrc = $self->result_source;
2123     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2124     for (keys %$first) {
2125       my $ref = ref $first->{$_};
2126       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2127         ? push @rels, $_
2128         : push @columns, $_
2129       ;
2130     }
2131
2132     my @pks = $rsrc->primary_columns;
2133
2134     ## do the belongs_to relationships
2135     foreach my $index (0..$#$data) {
2136
2137       # delegate to create() for any dataset without primary keys with specified relationships
2138       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2139         for my $r (@rels) {
2140           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2141             my @ret = $self->populate($data);
2142             return;
2143           }
2144         }
2145       }
2146
2147       foreach my $rel (@rels) {
2148         next unless ref $data->[$index]->{$rel} eq "HASH";
2149         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2150         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2151         my $related = $result->result_source->_resolve_condition(
2152           $reverse_relinfo->{cond},
2153           $self,
2154           $result,
2155           $rel,
2156         );
2157
2158         delete $data->[$index]->{$rel};
2159         $data->[$index] = {%{$data->[$index]}, %$related};
2160
2161         push @columns, keys %$related if $index == 0;
2162       }
2163     }
2164
2165     ## inherit the data locked in the conditions of the resultset
2166     my ($rs_data) = $self->_merge_with_rscond({});
2167     delete @{$rs_data}{@columns};
2168
2169     ## do bulk insert on current row
2170     $rsrc->storage->insert_bulk(
2171       $rsrc,
2172       [@columns, keys %$rs_data],
2173       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2174     );
2175
2176     ## do the has_many relationships
2177     foreach my $item (@$data) {
2178
2179       my $main_row;
2180
2181       foreach my $rel (@rels) {
2182         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2183
2184         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2185
2186         my $child = $main_row->$rel;
2187
2188         my $related = $child->result_source->_resolve_condition(
2189           $rels->{$rel}{cond},
2190           $child,
2191           $main_row,
2192           $rel,
2193         );
2194
2195         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2196         my @populate = map { {%$_, %$related} } @rows_to_add;
2197
2198         $child->populate( \@populate );
2199       }
2200     }
2201   }
2202 }
2203
2204
2205 # populate() argumnets went over several incarnations
2206 # What we ultimately support is AoH
2207 sub _normalize_populate_args {
2208   my ($self, $arg) = @_;
2209
2210   if (ref $arg eq 'ARRAY') {
2211     if (!@$arg) {
2212       return [];
2213     }
2214     elsif (ref $arg->[0] eq 'HASH') {
2215       return $arg;
2216     }
2217     elsif (ref $arg->[0] eq 'ARRAY') {
2218       my @ret;
2219       my @colnames = @{$arg->[0]};
2220       foreach my $values (@{$arg}[1 .. $#$arg]) {
2221         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2222       }
2223       return \@ret;
2224     }
2225   }
2226
2227   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2228 }
2229
2230 =head2 pager
2231
2232 =over 4
2233
2234 =item Arguments: none
2235
2236 =item Return Value: L<$pager|Data::Page>
2237
2238 =back
2239
2240 Returns a L<Data::Page> object for the current resultset. Only makes
2241 sense for queries with a C<page> attribute.
2242
2243 To get the full count of entries for a paged resultset, call
2244 C<total_entries> on the L<Data::Page> object.
2245
2246 =cut
2247
2248 sub pager {
2249   my ($self) = @_;
2250
2251   return $self->{pager} if $self->{pager};
2252
2253   my $attrs = $self->{attrs};
2254   if (!defined $attrs->{page}) {
2255     $self->throw_exception("Can't create pager for non-paged rs");
2256   }
2257   elsif ($attrs->{page} <= 0) {
2258     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2259   }
2260   $attrs->{rows} ||= 10;
2261
2262   # throw away the paging flags and re-run the count (possibly
2263   # with a subselect) to get the real total count
2264   my $count_attrs = { %$attrs };
2265   delete $count_attrs->{$_} for qw/rows offset page pager/;
2266
2267   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2268
2269   require DBIx::Class::ResultSet::Pager;
2270   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2271     sub { $total_rs->count },  #lazy-get the total
2272     $attrs->{rows},
2273     $self->{attrs}{page},
2274   );
2275 }
2276
2277 =head2 page
2278
2279 =over 4
2280
2281 =item Arguments: $page_number
2282
2283 =item Return Value: L<$resultset|/search>
2284
2285 =back
2286
2287 Returns a resultset for the $page_number page of the resultset on which page
2288 is called, where each page contains a number of rows equal to the 'rows'
2289 attribute set on the resultset (10 by default).
2290
2291 =cut
2292
2293 sub page {
2294   my ($self, $page) = @_;
2295   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2296 }
2297
2298 =head2 new_result
2299
2300 =over 4
2301
2302 =item Arguments: \%col_data
2303
2304 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2305
2306 =back
2307
2308 Creates a new result object in the resultset's result class and returns
2309 it. The row is not inserted into the database at this point, call
2310 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2311 will tell you whether the result object has been inserted or not.
2312
2313 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2314
2315 =cut
2316
2317 sub new_result {
2318   my ($self, $values) = @_;
2319
2320   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2321     if @_ > 2;
2322
2323   $self->throw_exception( "new_result expects a hashref" )
2324     unless (ref $values eq 'HASH');
2325
2326   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2327
2328   my $new = $self->result_class->new({
2329     %$merged_cond,
2330     ( @$cols_from_relations
2331       ? (-cols_from_relations => $cols_from_relations)
2332       : ()
2333     ),
2334     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2335   });
2336
2337   if (
2338     reftype($new) eq 'HASH'
2339       and
2340     ! keys %$new
2341       and
2342     blessed($new)
2343   ) {
2344     carp_unique (sprintf (
2345       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2346       $self->result_class,
2347     ));
2348   }
2349
2350   $new;
2351 }
2352
2353 # _merge_with_rscond
2354 #
2355 # Takes a simple hash of K/V data and returns its copy merged with the
2356 # condition already present on the resultset. Additionally returns an
2357 # arrayref of value/condition names, which were inferred from related
2358 # objects (this is needed for in-memory related objects)
2359 sub _merge_with_rscond {
2360   my ($self, $data) = @_;
2361
2362   my (%new_data, @cols_from_relations);
2363
2364   my $alias = $self->{attrs}{alias};
2365
2366   if (! defined $self->{cond}) {
2367     # just massage $data below
2368   }
2369   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2370     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2371     @cols_from_relations = keys %new_data;
2372   }
2373   elsif (ref $self->{cond} ne 'HASH') {
2374     $self->throw_exception(
2375       "Can't abstract implicit construct, resultset condition not a hash"
2376     );
2377   }
2378   else {
2379     # precendence must be given to passed values over values inherited from
2380     # the cond, so the order here is important.
2381     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2382     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2383
2384     while ( my($col, $value) = each %implied ) {
2385       my $vref = ref $value;
2386       if (
2387         $vref eq 'HASH'
2388           and
2389         keys(%$value) == 1
2390           and
2391         (keys %$value)[0] eq '='
2392       ) {
2393         $new_data{$col} = $value->{'='};
2394       }
2395       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2396         $new_data{$col} = $value;
2397       }
2398     }
2399   }
2400
2401   %new_data = (
2402     %new_data,
2403     %{ $self->_remove_alias($data, $alias) },
2404   );
2405
2406   return (\%new_data, \@cols_from_relations);
2407 }
2408
2409 # _has_resolved_attr
2410 #
2411 # determines if the resultset defines at least one
2412 # of the attributes supplied
2413 #
2414 # used to determine if a subquery is neccessary
2415 #
2416 # supports some virtual attributes:
2417 #   -join
2418 #     This will scan for any joins being present on the resultset.
2419 #     It is not a mere key-search but a deep inspection of {from}
2420 #
2421
2422 sub _has_resolved_attr {
2423   my ($self, @attr_names) = @_;
2424
2425   my $attrs = $self->_resolved_attrs;
2426
2427   my %extra_checks;
2428
2429   for my $n (@attr_names) {
2430     if (grep { $n eq $_ } (qw/-join/) ) {
2431       $extra_checks{$n}++;
2432       next;
2433     }
2434
2435     my $attr =  $attrs->{$n};
2436
2437     next if not defined $attr;
2438
2439     if (ref $attr eq 'HASH') {
2440       return 1 if keys %$attr;
2441     }
2442     elsif (ref $attr eq 'ARRAY') {
2443       return 1 if @$attr;
2444     }
2445     else {
2446       return 1 if $attr;
2447     }
2448   }
2449
2450   # a resolved join is expressed as a multi-level from
2451   return 1 if (
2452     $extra_checks{-join}
2453       and
2454     ref $attrs->{from} eq 'ARRAY'
2455       and
2456     @{$attrs->{from}} > 1
2457   );
2458
2459   return 0;
2460 }
2461
2462 # _collapse_cond
2463 #
2464 # Recursively collapse the condition.
2465
2466 sub _collapse_cond {
2467   my ($self, $cond, $collapsed) = @_;
2468
2469   $collapsed ||= {};
2470
2471   if (ref $cond eq 'ARRAY') {
2472     foreach my $subcond (@$cond) {
2473       next unless ref $subcond;  # -or
2474       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2475     }
2476   }
2477   elsif (ref $cond eq 'HASH') {
2478     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2479       foreach my $subcond (@{$cond->{-and}}) {
2480         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2481       }
2482     }
2483     else {
2484       foreach my $col (keys %$cond) {
2485         my $value = $cond->{$col};
2486         $collapsed->{$col} = $value;
2487       }
2488     }
2489   }
2490
2491   return $collapsed;
2492 }
2493
2494 # _remove_alias
2495 #
2496 # Remove the specified alias from the specified query hash. A copy is made so
2497 # the original query is not modified.
2498
2499 sub _remove_alias {
2500   my ($self, $query, $alias) = @_;
2501
2502   my %orig = %{ $query || {} };
2503   my %unaliased;
2504
2505   foreach my $key (keys %orig) {
2506     if ($key !~ /\./) {
2507       $unaliased{$key} = $orig{$key};
2508       next;
2509     }
2510     $unaliased{$1} = $orig{$key}
2511       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2512   }
2513
2514   return \%unaliased;
2515 }
2516
2517 =head2 as_query
2518
2519 =over 4
2520
2521 =item Arguments: none
2522
2523 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2524
2525 =back
2526
2527 Returns the SQL query and bind vars associated with the invocant.
2528
2529 This is generally used as the RHS for a subquery.
2530
2531 =cut
2532
2533 sub as_query {
2534   my $self = shift;
2535
2536   my $attrs = { %{ $self->_resolved_attrs } };
2537
2538   # For future use:
2539   #
2540   # in list ctx:
2541   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2542   # $sql also has no wrapping parenthesis in list ctx
2543   #
2544   my $sqlbind = $self->result_source->storage
2545     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2546
2547   return $sqlbind;
2548 }
2549
2550 =head2 find_or_new
2551
2552 =over 4
2553
2554 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2555
2556 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2557
2558 =back
2559
2560   my $artist = $schema->resultset('Artist')->find_or_new(
2561     { artist => 'fred' }, { key => 'artists' });
2562
2563   $cd->cd_to_producer->find_or_new({ producer => $producer },
2564                                    { key => 'primary });
2565
2566 Find an existing record from this resultset using L</find>. if none exists,
2567 instantiate a new result object and return it. The object will not be saved
2568 into your storage until you call L<DBIx::Class::Row/insert> on it.
2569
2570 You most likely want this method when looking for existing rows using a unique
2571 constraint that is not the primary key, or looking for related rows.
2572
2573 If you want objects to be saved immediately, use L</find_or_create> instead.
2574
2575 B<Note>: Make sure to read the documentation of L</find> and understand the
2576 significance of the C<key> attribute, as its lack may skew your search, and
2577 subsequently result in spurious new objects.
2578
2579 B<Note>: Take care when using C<find_or_new> with a table having
2580 columns with default values that you intend to be automatically
2581 supplied by the database (e.g. an auto_increment primary key column).
2582 In normal usage, the value of such columns should NOT be included at
2583 all in the call to C<find_or_new>, even when set to C<undef>.
2584
2585 =cut
2586
2587 sub find_or_new {
2588   my $self     = shift;
2589   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2590   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2591   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2592     return $row;
2593   }
2594   return $self->new_result($hash);
2595 }
2596
2597 =head2 create
2598
2599 =over 4
2600
2601 =item Arguments: \%col_data
2602
2603 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2604
2605 =back
2606
2607 Attempt to create a single new row or a row with multiple related rows
2608 in the table represented by the resultset (and related tables). This
2609 will not check for duplicate rows before inserting, use
2610 L</find_or_create> to do that.
2611
2612 To create one row for this resultset, pass a hashref of key/value
2613 pairs representing the columns of the table and the values you wish to
2614 store. If the appropriate relationships are set up, foreign key fields
2615 can also be passed an object representing the foreign row, and the
2616 value will be set to its primary key.
2617
2618 To create related objects, pass a hashref of related-object column values
2619 B<keyed on the relationship name>. If the relationship is of type C<multi>
2620 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2621 The process will correctly identify columns holding foreign keys, and will
2622 transparently populate them from the keys of the corresponding relation.
2623 This can be applied recursively, and will work correctly for a structure
2624 with an arbitrary depth and width, as long as the relationships actually
2625 exists and the correct column data has been supplied.
2626
2627 Instead of hashrefs of plain related data (key/value pairs), you may
2628 also pass new or inserted objects. New objects (not inserted yet, see
2629 L</new_result>), will be inserted into their appropriate tables.
2630
2631 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2632
2633 Example of creating a new row.
2634
2635   $person_rs->create({
2636     name=>"Some Person",
2637     email=>"somebody@someplace.com"
2638   });
2639
2640 Example of creating a new row and also creating rows in a related C<has_many>
2641 or C<has_one> resultset.  Note Arrayref.
2642
2643   $artist_rs->create(
2644      { artistid => 4, name => 'Manufactured Crap', cds => [
2645         { title => 'My First CD', year => 2006 },
2646         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2647       ],
2648      },
2649   );
2650
2651 Example of creating a new row and also creating a row in a related
2652 C<belongs_to> resultset. Note Hashref.
2653
2654   $cd_rs->create({
2655     title=>"Music for Silly Walks",
2656     year=>2000,
2657     artist => {
2658       name=>"Silly Musician",
2659     }
2660   });
2661
2662 =over
2663
2664 =item WARNING
2665
2666 When subclassing ResultSet never attempt to override this method. Since
2667 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2668 lot of the internals simply never call it, so your override will be
2669 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2670 or L<DBIx::Class::Row/insert> depending on how early in the
2671 L</create> process you need to intervene. See also warning pertaining to
2672 L</new>.
2673
2674 =back
2675
2676 =cut
2677
2678 sub create {
2679   my ($self, $attrs) = @_;
2680   $self->throw_exception( "create needs a hashref" )
2681     unless ref $attrs eq 'HASH';
2682   return $self->new_result($attrs)->insert;
2683 }
2684
2685 =head2 find_or_create
2686
2687 =over 4
2688
2689 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2690
2691 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2692
2693 =back
2694
2695   $cd->cd_to_producer->find_or_create({ producer => $producer },
2696                                       { key => 'primary' });
2697
2698 Tries to find a record based on its primary key or unique constraints; if none
2699 is found, creates one and returns that instead.
2700
2701   my $cd = $schema->resultset('CD')->find_or_create({
2702     cdid   => 5,
2703     artist => 'Massive Attack',
2704     title  => 'Mezzanine',
2705     year   => 2005,
2706   });
2707
2708 Also takes an optional C<key> attribute, to search by a specific key or unique
2709 constraint. For example:
2710
2711   my $cd = $schema->resultset('CD')->find_or_create(
2712     {
2713       artist => 'Massive Attack',
2714       title  => 'Mezzanine',
2715     },
2716     { key => 'cd_artist_title' }
2717   );
2718
2719 B<Note>: Make sure to read the documentation of L</find> and understand the
2720 significance of the C<key> attribute, as its lack may skew your search, and
2721 subsequently result in spurious row creation.
2722
2723 B<Note>: Because find_or_create() reads from the database and then
2724 possibly inserts based on the result, this method is subject to a race
2725 condition. Another process could create a record in the table after
2726 the find has completed and before the create has started. To avoid
2727 this problem, use find_or_create() inside a transaction.
2728
2729 B<Note>: Take care when using C<find_or_create> with a table having
2730 columns with default values that you intend to be automatically
2731 supplied by the database (e.g. an auto_increment primary key column).
2732 In normal usage, the value of such columns should NOT be included at
2733 all in the call to C<find_or_create>, even when set to C<undef>.
2734
2735 See also L</find> and L</update_or_create>. For information on how to declare
2736 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2737
2738 If you need to know if an existing row was found or a new one created use
2739 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2740 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2741 database!
2742
2743   my $cd = $schema->resultset('CD')->find_or_new({
2744     cdid   => 5,
2745     artist => 'Massive Attack',
2746     title  => 'Mezzanine',
2747     year   => 2005,
2748   });
2749
2750   if( !$cd->in_storage ) {
2751       # do some stuff
2752       $cd->insert;
2753   }
2754
2755 =cut
2756
2757 sub find_or_create {
2758   my $self     = shift;
2759   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2760   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2761   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2762     return $row;
2763   }
2764   return $self->create($hash);
2765 }
2766
2767 =head2 update_or_create
2768
2769 =over 4
2770
2771 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2772
2773 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2774
2775 =back
2776
2777   $resultset->update_or_create({ col => $val, ... });
2778
2779 Like L</find_or_create>, but if a row is found it is immediately updated via
2780 C<< $found_row->update (\%col_data) >>.
2781
2782
2783 Takes an optional C<key> attribute to search on a specific unique constraint.
2784 For example:
2785
2786   # In your application
2787   my $cd = $schema->resultset('CD')->update_or_create(
2788     {
2789       artist => 'Massive Attack',
2790       title  => 'Mezzanine',
2791       year   => 1998,
2792     },
2793     { key => 'cd_artist_title' }
2794   );
2795
2796   $cd->cd_to_producer->update_or_create({
2797     producer => $producer,
2798     name => 'harry',
2799   }, {
2800     key => 'primary',
2801   });
2802
2803 B<Note>: Make sure to read the documentation of L</find> and understand the
2804 significance of the C<key> attribute, as its lack may skew your search, and
2805 subsequently result in spurious row creation.
2806
2807 B<Note>: Take care when using C<update_or_create> with a table having
2808 columns with default values that you intend to be automatically
2809 supplied by the database (e.g. an auto_increment primary key column).
2810 In normal usage, the value of such columns should NOT be included at
2811 all in the call to C<update_or_create>, even when set to C<undef>.
2812
2813 See also L</find> and L</find_or_create>. For information on how to declare
2814 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2815
2816 If you need to know if an existing row was updated or a new one created use
2817 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2818 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2819 database!
2820
2821 =cut
2822
2823 sub update_or_create {
2824   my $self = shift;
2825   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2826   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2827
2828   my $row = $self->find($cond, $attrs);
2829   if (defined $row) {
2830     $row->update($cond);
2831     return $row;
2832   }
2833
2834   return $self->create($cond);
2835 }
2836
2837 =head2 update_or_new
2838
2839 =over 4
2840
2841 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2842
2843 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2844
2845 =back
2846
2847   $resultset->update_or_new({ col => $val, ... });
2848
2849 Like L</find_or_new> but if a row is found it is immediately updated via
2850 C<< $found_row->update (\%col_data) >>.
2851
2852 For example:
2853
2854   # In your application
2855   my $cd = $schema->resultset('CD')->update_or_new(
2856     {
2857       artist => 'Massive Attack',
2858       title  => 'Mezzanine',
2859       year   => 1998,
2860     },
2861     { key => 'cd_artist_title' }
2862   );
2863
2864   if ($cd->in_storage) {
2865       # the cd was updated
2866   }
2867   else {
2868       # the cd is not yet in the database, let's insert it
2869       $cd->insert;
2870   }
2871
2872 B<Note>: Make sure to read the documentation of L</find> and understand the
2873 significance of the C<key> attribute, as its lack may skew your search, and
2874 subsequently result in spurious new objects.
2875
2876 B<Note>: Take care when using C<update_or_new> with a table having
2877 columns with default values that you intend to be automatically
2878 supplied by the database (e.g. an auto_increment primary key column).
2879 In normal usage, the value of such columns should NOT be included at
2880 all in the call to C<update_or_new>, even when set to C<undef>.
2881
2882 See also L</find>, L</find_or_create> and L</find_or_new>.
2883
2884 =cut
2885
2886 sub update_or_new {
2887     my $self  = shift;
2888     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2889     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2890
2891     my $row = $self->find( $cond, $attrs );
2892     if ( defined $row ) {
2893         $row->update($cond);
2894         return $row;
2895     }
2896
2897     return $self->new_result($cond);
2898 }
2899
2900 =head2 get_cache
2901
2902 =over 4
2903
2904 =item Arguments: none
2905
2906 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2907
2908 =back
2909
2910 Gets the contents of the cache for the resultset, if the cache is set.
2911
2912 The cache is populated either by using the L</prefetch> attribute to
2913 L</search> or by calling L</set_cache>.
2914
2915 =cut
2916
2917 sub get_cache {
2918   shift->{all_cache};
2919 }
2920
2921 =head2 set_cache
2922
2923 =over 4
2924
2925 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2926
2927 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2928
2929 =back
2930
2931 Sets the contents of the cache for the resultset. Expects an arrayref
2932 of objects of the same class as those produced by the resultset. Note that
2933 if the cache is set, the resultset will return the cached objects rather
2934 than re-querying the database even if the cache attr is not set.
2935
2936 The contents of the cache can also be populated by using the
2937 L</prefetch> attribute to L</search>.
2938
2939 =cut
2940
2941 sub set_cache {
2942   my ( $self, $data ) = @_;
2943   $self->throw_exception("set_cache requires an arrayref")
2944       if defined($data) && (ref $data ne 'ARRAY');
2945   $self->{all_cache} = $data;
2946 }
2947
2948 =head2 clear_cache
2949
2950 =over 4
2951
2952 =item Arguments: none
2953
2954 =item Return Value: undef
2955
2956 =back
2957
2958 Clears the cache for the resultset.
2959
2960 =cut
2961
2962 sub clear_cache {
2963   shift->set_cache(undef);
2964 }
2965
2966 =head2 is_paged
2967
2968 =over 4
2969
2970 =item Arguments: none
2971
2972 =item Return Value: true, if the resultset has been paginated
2973
2974 =back
2975
2976 =cut
2977
2978 sub is_paged {
2979   my ($self) = @_;
2980   return !!$self->{attrs}{page};
2981 }
2982
2983 =head2 is_ordered
2984
2985 =over 4
2986
2987 =item Arguments: none
2988
2989 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2990
2991 =back
2992
2993 =cut
2994
2995 sub is_ordered {
2996   my ($self) = @_;
2997   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2998 }
2999
3000 =head2 related_resultset
3001
3002 =over 4
3003
3004 =item Arguments: $rel_name
3005
3006 =item Return Value: L<$resultset|/search>
3007
3008 =back
3009
3010 Returns a related resultset for the supplied relationship name.
3011
3012   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3013
3014 =cut
3015
3016 sub related_resultset {
3017   my ($self, $rel) = @_;
3018
3019   $self->{related_resultsets} ||= {};
3020   return $self->{related_resultsets}{$rel} ||= do {
3021     my $rsrc = $self->result_source;
3022     my $rel_info = $rsrc->relationship_info($rel);
3023
3024     $self->throw_exception(
3025       "search_related: result source '" . $rsrc->source_name .
3026         "' has no such relationship $rel")
3027       unless $rel_info;
3028
3029     my $attrs = $self->_chain_relationship($rel);
3030
3031     my $join_count = $attrs->{seen_join}{$rel};
3032
3033     my $alias = $self->result_source->storage
3034         ->relname_to_table_alias($rel, $join_count);
3035
3036     # since this is search_related, and we already slid the select window inwards
3037     # (the select/as attrs were deleted in the beginning), we need to flip all
3038     # left joins to inner, so we get the expected results
3039     # read the comment on top of the actual function to see what this does
3040     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3041
3042
3043     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3044     delete @{$attrs}{qw(result_class alias)};
3045
3046     my $new_cache;
3047
3048     if (my $cache = $self->get_cache) {
3049       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3050         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3051                         @$cache ];
3052       }
3053     }
3054
3055     my $rel_source = $rsrc->related_source($rel);
3056
3057     my $new = do {
3058
3059       # The reason we do this now instead of passing the alias to the
3060       # search_rs below is that if you wrap/overload resultset on the
3061       # source you need to know what alias it's -going- to have for things
3062       # to work sanely (e.g. RestrictWithObject wants to be able to add
3063       # extra query restrictions, and these may need to be $alias.)
3064
3065       my $rel_attrs = $rel_source->resultset_attributes;
3066       local $rel_attrs->{alias} = $alias;
3067
3068       $rel_source->resultset
3069                  ->search_rs(
3070                      undef, {
3071                        %$attrs,
3072                        where => $attrs->{where},
3073                    });
3074     };
3075     $new->set_cache($new_cache) if $new_cache;
3076     $new;
3077   };
3078 }
3079
3080 =head2 current_source_alias
3081
3082 =over 4
3083
3084 =item Arguments: none
3085
3086 =item Return Value: $source_alias
3087
3088 =back
3089
3090 Returns the current table alias for the result source this resultset is built
3091 on, that will be used in the SQL query. Usually it is C<me>.
3092
3093 Currently the source alias that refers to the result set returned by a
3094 L</search>/L</find> family method depends on how you got to the resultset: it's
3095 C<me> by default, but eg. L</search_related> aliases it to the related result
3096 source name (and keeps C<me> referring to the original result set). The long
3097 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3098 (and make this method unnecessary).
3099
3100 Thus it's currently necessary to use this method in predefined queries (see
3101 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3102 source alias of the current result set:
3103
3104   # in a result set class
3105   sub modified_by {
3106     my ($self, $user) = @_;
3107
3108     my $me = $self->current_source_alias;
3109
3110     return $self->search({
3111       "$me.modified" => $user->id,
3112     });
3113   }
3114
3115 =cut
3116
3117 sub current_source_alias {
3118   return (shift->{attrs} || {})->{alias} || 'me';
3119 }
3120
3121 =head2 as_subselect_rs
3122
3123 =over 4
3124
3125 =item Arguments: none
3126
3127 =item Return Value: L<$resultset|/search>
3128
3129 =back
3130
3131 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3132 "virtual view" by including it as a subquery within the from clause.  From this
3133 point on, any joined tables are inaccessible to ->search on the resultset (as if
3134 it were simply where-filtered without joins).  For example:
3135
3136  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3137
3138  # 'x' now pollutes the query namespace
3139
3140  # So the following works as expected
3141  my $ok_rs = $rs->search({'x.other' => 1});
3142
3143  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3144  # def) we look for one row with contradictory terms and join in another table
3145  # (aliased 'x_2') which we never use
3146  my $broken_rs = $rs->search({'x.name' => 'def'});
3147
3148  my $rs2 = $rs->as_subselect_rs;
3149
3150  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3151  my $not_joined_rs = $rs2->search({'x.other' => 1});
3152
3153  # works as expected: finds a 'table' row related to two x rows (abc and def)
3154  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3155
3156 Another example of when one might use this would be to select a subset of
3157 columns in a group by clause:
3158
3159  my $rs = $schema->resultset('Bar')->search(undef, {
3160    group_by => [qw{ id foo_id baz_id }],
3161  })->as_subselect_rs->search(undef, {
3162    columns => [qw{ id foo_id }]
3163  });
3164
3165 In the above example normally columns would have to be equal to the group by,
3166 but because we isolated the group by into a subselect the above works.
3167
3168 =cut
3169
3170 sub as_subselect_rs {
3171   my $self = shift;
3172
3173   my $attrs = $self->_resolved_attrs;
3174
3175   my $fresh_rs = (ref $self)->new (
3176     $self->result_source
3177   );
3178
3179   # these pieces will be locked in the subquery
3180   delete $fresh_rs->{cond};
3181   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3182
3183   return $fresh_rs->search( {}, {
3184     from => [{
3185       $attrs->{alias} => $self->as_query,
3186       -alias  => $attrs->{alias},
3187       -rsrc   => $self->result_source,
3188     }],
3189     alias => $attrs->{alias},
3190   });
3191 }
3192
3193 # This code is called by search_related, and makes sure there
3194 # is clear separation between the joins before, during, and
3195 # after the relationship. This information is needed later
3196 # in order to properly resolve prefetch aliases (any alias
3197 # with a relation_chain_depth less than the depth of the
3198 # current prefetch is not considered)
3199 #
3200 # The increments happen twice per join. An even number means a
3201 # relationship specified via a search_related, whereas an odd
3202 # number indicates a join/prefetch added via attributes
3203 #
3204 # Also this code will wrap the current resultset (the one we
3205 # chain to) in a subselect IFF it contains limiting attributes
3206 sub _chain_relationship {
3207   my ($self, $rel) = @_;
3208   my $source = $self->result_source;
3209   my $attrs = { %{$self->{attrs}||{}} };
3210
3211   # we need to take the prefetch the attrs into account before we
3212   # ->_resolve_join as otherwise they get lost - captainL
3213   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3214
3215   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3216
3217   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3218
3219   my $from;
3220   my @force_subq_attrs = qw/offset rows group_by having/;
3221
3222   if (
3223     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3224       ||
3225     $self->_has_resolved_attr (@force_subq_attrs)
3226   ) {
3227     # Nuke the prefetch (if any) before the new $rs attrs
3228     # are resolved (prefetch is useless - we are wrapping
3229     # a subquery anyway).
3230     my $rs_copy = $self->search;
3231     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3232       $rs_copy->{attrs}{join},
3233       delete $rs_copy->{attrs}{prefetch},
3234     );
3235
3236     $from = [{
3237       -rsrc   => $source,
3238       -alias  => $attrs->{alias},
3239       $attrs->{alias} => $rs_copy->as_query,
3240     }];
3241     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3242     $seen->{-relation_chain_depth} = 0;
3243   }
3244   elsif ($attrs->{from}) {  #shallow copy suffices
3245     $from = [ @{$attrs->{from}} ];
3246   }
3247   else {
3248     $from = [{
3249       -rsrc  => $source,
3250       -alias => $attrs->{alias},
3251       $attrs->{alias} => $source->from,
3252     }];
3253   }
3254
3255   my $jpath = ($seen->{-relation_chain_depth})
3256     ? $from->[-1][0]{-join_path}
3257     : [];
3258
3259   my @requested_joins = $source->_resolve_join(
3260     $join,
3261     $attrs->{alias},
3262     $seen,
3263     $jpath,
3264   );
3265
3266   push @$from, @requested_joins;
3267
3268   $seen->{-relation_chain_depth}++;
3269
3270   # if $self already had a join/prefetch specified on it, the requested
3271   # $rel might very well be already included. What we do in this case
3272   # is effectively a no-op (except that we bump up the chain_depth on
3273   # the join in question so we could tell it *is* the search_related)
3274   my $already_joined;
3275
3276   # we consider the last one thus reverse
3277   for my $j (reverse @requested_joins) {
3278     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3279     if ($rel eq $last_j) {
3280       $j->[0]{-relation_chain_depth}++;
3281       $already_joined++;
3282       last;
3283     }
3284   }
3285
3286   unless ($already_joined) {
3287     push @$from, $source->_resolve_join(
3288       $rel,
3289       $attrs->{alias},
3290       $seen,
3291       $jpath,
3292     );
3293   }
3294
3295   $seen->{-relation_chain_depth}++;
3296
3297   return {%$attrs, from => $from, seen_join => $seen};
3298 }
3299
3300 sub _resolved_attrs {
3301   my $self = shift;
3302   return $self->{_attrs} if $self->{_attrs};
3303
3304   my $attrs  = { %{ $self->{attrs} || {} } };
3305   my $source = $self->result_source;
3306   my $alias  = $attrs->{alias};
3307
3308   # default selection list
3309   $attrs->{columns} = [ $source->columns ]
3310     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3311
3312   # merge selectors together
3313   for (qw/columns select as/) {
3314     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3315       if $attrs->{$_} or $attrs->{"+$_"};
3316   }
3317
3318   # disassemble columns
3319   my (@sel, @as);
3320   if (my $cols = delete $attrs->{columns}) {
3321     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3322       if (ref $c eq 'HASH') {
3323         for my $as (sort keys %$c) {
3324           push @sel, $c->{$as};
3325           push @as, $as;
3326         }
3327       }
3328       else {
3329         push @sel, $c;
3330         push @as, $c;
3331       }
3332     }
3333   }
3334
3335   # when trying to weed off duplicates later do not go past this point -
3336   # everything added from here on is unbalanced "anyone's guess" stuff
3337   my $dedup_stop_idx = $#as;
3338
3339   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3340     if $attrs->{as};
3341   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3342     if $attrs->{select};
3343
3344   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3345   for (@sel) {
3346     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3347   }
3348
3349   # disqualify all $alias.col as-bits (collapser mandated)
3350   for (@as) {
3351     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3352   }
3353
3354   # de-duplicate the result (remove *identical* select/as pairs)
3355   # and also die on duplicate {as} pointing to different {select}s
3356   # not using a c-style for as the condition is prone to shrinkage
3357   my $seen;
3358   my $i = 0;
3359   while ($i <= $dedup_stop_idx) {
3360     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3361       splice @sel, $i, 1;
3362       splice @as, $i, 1;
3363       $dedup_stop_idx--;
3364     }
3365     elsif ($seen->{$as[$i]}++) {
3366       $self->throw_exception(
3367         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3368       );
3369     }
3370     else {
3371       $i++;
3372     }
3373   }
3374
3375   $attrs->{select} = \@sel;
3376   $attrs->{as} = \@as;
3377
3378   $attrs->{from} ||= [{
3379     -rsrc   => $source,
3380     -alias  => $self->{attrs}{alias},
3381     $self->{attrs}{alias} => $source->from,
3382   }];
3383
3384   if ( $attrs->{join} || $attrs->{prefetch} ) {
3385
3386     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3387       if ref $attrs->{from} ne 'ARRAY';
3388
3389     my $join = (delete $attrs->{join}) || {};
3390
3391     if ( defined $attrs->{prefetch} ) {
3392       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3393     }
3394
3395     $attrs->{from} =    # have to copy here to avoid corrupting the original
3396       [
3397         @{ $attrs->{from} },
3398         $source->_resolve_join(
3399           $join,
3400           $alias,
3401           { %{ $attrs->{seen_join} || {} } },
3402           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3403             ? $attrs->{from}[-1][0]{-join_path}
3404             : []
3405           ,
3406         )
3407       ];
3408   }
3409
3410   if ( defined $attrs->{order_by} ) {
3411     $attrs->{order_by} = (
3412       ref( $attrs->{order_by} ) eq 'ARRAY'
3413       ? [ @{ $attrs->{order_by} } ]
3414       : [ $attrs->{order_by} || () ]
3415     );
3416   }
3417
3418   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3419     $attrs->{group_by} = [ $attrs->{group_by} ];
3420   }
3421
3422   # generate the distinct induced group_by early, as prefetch will be carried via a
3423   # subquery (since a group_by is present)
3424   if (delete $attrs->{distinct}) {
3425     if ($attrs->{group_by}) {
3426       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3427     }
3428     else {
3429       # distinct affects only the main selection part, not what prefetch may
3430       # add below.
3431       $attrs->{group_by} = $source->storage->_group_over_selection (
3432         $attrs->{from},
3433         $attrs->{select},
3434         $attrs->{order_by},
3435       );
3436     }
3437   }
3438
3439   $attrs->{collapse} ||= {};
3440   if ($attrs->{prefetch}) {
3441
3442     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3443       if $attrs->{_dark_selector};
3444
3445     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3446
3447     my $prefetch_ordering = [];
3448
3449     # this is a separate structure (we don't look in {from} directly)
3450     # as the resolver needs to shift things off the lists to work
3451     # properly (identical-prefetches on different branches)
3452     my $join_map = {};
3453     if (ref $attrs->{from} eq 'ARRAY') {
3454
3455       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3456
3457       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3458         next unless $j->[0]{-alias};
3459         next unless $j->[0]{-join_path};
3460         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3461
3462         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3463
3464         my $p = $join_map;
3465         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3466         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3467       }
3468     }
3469
3470     my @prefetch =
3471       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3472
3473     # we need to somehow mark which columns came from prefetch
3474     if (@prefetch) {
3475       my $sel_end = $#{$attrs->{select}};
3476       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3477     }
3478
3479     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3480     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3481
3482     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3483     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3484   }
3485
3486   # if both page and offset are specified, produce a combined offset
3487   # even though it doesn't make much sense, this is what pre 081xx has
3488   # been doing
3489   if (my $page = delete $attrs->{page}) {
3490     $attrs->{offset} =
3491       ($attrs->{rows} * ($page - 1))
3492             +
3493       ($attrs->{offset} || 0)
3494     ;
3495   }
3496
3497   return $self->{_attrs} = $attrs;
3498 }
3499
3500 sub _rollout_attr {
3501   my ($self, $attr) = @_;
3502
3503   if (ref $attr eq 'HASH') {
3504     return $self->_rollout_hash($attr);
3505   } elsif (ref $attr eq 'ARRAY') {
3506     return $self->_rollout_array($attr);
3507   } else {
3508     return [$attr];
3509   }
3510 }
3511
3512 sub _rollout_array {
3513   my ($self, $attr) = @_;
3514
3515   my @rolled_array;
3516   foreach my $element (@{$attr}) {
3517     if (ref $element eq 'HASH') {
3518       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3519     } elsif (ref $element eq 'ARRAY') {
3520       #  XXX - should probably recurse here
3521       push( @rolled_array, @{$self->_rollout_array($element)} );
3522     } else {
3523       push( @rolled_array, $element );
3524     }
3525   }
3526   return \@rolled_array;
3527 }
3528
3529 sub _rollout_hash {
3530   my ($self, $attr) = @_;
3531
3532   my @rolled_array;
3533   foreach my $key (keys %{$attr}) {
3534     push( @rolled_array, { $key => $attr->{$key} } );
3535   }
3536   return \@rolled_array;
3537 }
3538
3539 sub _calculate_score {
3540   my ($self, $a, $b) = @_;
3541
3542   if (defined $a xor defined $b) {
3543     return 0;
3544   }
3545   elsif (not defined $a) {
3546     return 1;
3547   }
3548
3549   if (ref $b eq 'HASH') {
3550     my ($b_key) = keys %{$b};
3551     if (ref $a eq 'HASH') {
3552       my ($a_key) = keys %{$a};
3553       if ($a_key eq $b_key) {
3554         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3555       } else {
3556         return 0;
3557       }
3558     } else {
3559       return ($a eq $b_key) ? 1 : 0;
3560     }
3561   } else {
3562     if (ref $a eq 'HASH') {
3563       my ($a_key) = keys %{$a};
3564       return ($b eq $a_key) ? 1 : 0;
3565     } else {
3566       return ($b eq $a) ? 1 : 0;
3567     }
3568   }
3569 }
3570
3571 sub _merge_joinpref_attr {
3572   my ($self, $orig, $import) = @_;
3573
3574   return $import unless defined($orig);
3575   return $orig unless defined($import);
3576
3577   $orig = $self->_rollout_attr($orig);
3578   $import = $self->_rollout_attr($import);
3579
3580   my $seen_keys;
3581   foreach my $import_element ( @{$import} ) {
3582     # find best candidate from $orig to merge $b_element into
3583     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3584     foreach my $orig_element ( @{$orig} ) {
3585       my $score = $self->_calculate_score( $orig_element, $import_element );
3586       if ($score > $best_candidate->{score}) {
3587         $best_candidate->{position} = $position;
3588         $best_candidate->{score} = $score;
3589       }
3590       $position++;
3591     }
3592     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3593     $import_key = '' if not defined $import_key;
3594
3595     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3596       push( @{$orig}, $import_element );
3597     } else {
3598       my $orig_best = $orig->[$best_candidate->{position}];
3599       # merge orig_best and b_element together and replace original with merged
3600       if (ref $orig_best ne 'HASH') {
3601         $orig->[$best_candidate->{position}] = $import_element;
3602       } elsif (ref $import_element eq 'HASH') {
3603         my ($key) = keys %{$orig_best};
3604         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3605       }
3606     }
3607     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3608   }
3609
3610   return $orig;
3611 }
3612
3613 {
3614   my $hm;
3615
3616   sub _merge_attr {
3617     $hm ||= do {
3618       require Hash::Merge;
3619       my $hm = Hash::Merge->new;
3620
3621       $hm->specify_behavior({
3622         SCALAR => {
3623           SCALAR => sub {
3624             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3625
3626             if ($defl xor $defr) {
3627               return [ $defl ? $_[0] : $_[1] ];
3628             }
3629             elsif (! $defl) {
3630               return [];
3631             }
3632             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3633               return [ $_[0] ];
3634             }
3635             else {
3636               return [$_[0], $_[1]];
3637             }
3638           },
3639           ARRAY => sub {
3640             return $_[1] if !defined $_[0];
3641             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3642             return [$_[0], @{$_[1]}]
3643           },
3644           HASH  => sub {
3645             return [] if !defined $_[0] and !keys %{$_[1]};
3646             return [ $_[1] ] if !defined $_[0];
3647             return [ $_[0] ] if !keys %{$_[1]};
3648             return [$_[0], $_[1]]
3649           },
3650         },
3651         ARRAY => {
3652           SCALAR => sub {
3653             return $_[0] if !defined $_[1];
3654             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3655             return [@{$_[0]}, $_[1]]
3656           },
3657           ARRAY => sub {
3658             my @ret = @{$_[0]} or return $_[1];
3659             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3660             my %idx = map { $_ => 1 } @ret;
3661             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3662             \@ret;
3663           },
3664           HASH => sub {
3665             return [ $_[1] ] if ! @{$_[0]};
3666             return $_[0] if !keys %{$_[1]};
3667             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3668             return [ @{$_[0]}, $_[1] ];
3669           },
3670         },
3671         HASH => {
3672           SCALAR => sub {
3673             return [] if !keys %{$_[0]} and !defined $_[1];
3674             return [ $_[0] ] if !defined $_[1];
3675             return [ $_[1] ] if !keys %{$_[0]};
3676             return [$_[0], $_[1]]
3677           },
3678           ARRAY => sub {
3679             return [] if !keys %{$_[0]} and !@{$_[1]};
3680             return [ $_[0] ] if !@{$_[1]};
3681             return $_[1] if !keys %{$_[0]};
3682             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3683             return [ $_[0], @{$_[1]} ];
3684           },
3685           HASH => sub {
3686             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3687             return [ $_[0] ] if !keys %{$_[1]};
3688             return [ $_[1] ] if !keys %{$_[0]};
3689             return [ $_[0] ] if $_[0] eq $_[1];
3690             return [ $_[0], $_[1] ];
3691           },
3692         }
3693       } => 'DBIC_RS_ATTR_MERGER');
3694       $hm;
3695     };
3696
3697     return $hm->merge ($_[1], $_[2]);
3698   }
3699 }
3700
3701 sub STORABLE_freeze {
3702   my ($self, $cloning) = @_;
3703   my $to_serialize = { %$self };
3704
3705   # A cursor in progress can't be serialized (and would make little sense anyway)
3706   delete $to_serialize->{cursor};
3707
3708   # nor is it sensical to store a not-yet-fired-count pager
3709   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3710     delete $to_serialize->{pager};
3711   }
3712
3713   Storable::nfreeze($to_serialize);
3714 }
3715
3716 # need this hook for symmetry
3717 sub STORABLE_thaw {
3718   my ($self, $cloning, $serialized) = @_;
3719
3720   %$self = %{ Storable::thaw($serialized) };
3721
3722   $self;
3723 }
3724
3725
3726 =head2 throw_exception
3727
3728 See L<DBIx::Class::Schema/throw_exception> for details.
3729
3730 =cut
3731
3732 sub throw_exception {
3733   my $self=shift;
3734
3735   if (ref $self and my $rsrc = $self->result_source) {
3736     $rsrc->throw_exception(@_)
3737   }
3738   else {
3739     DBIx::Class::Exception->throw(@_);
3740   }
3741 }
3742
3743 # XXX: FIXME: Attributes docs need clearing up
3744
3745 =head1 ATTRIBUTES
3746
3747 Attributes are used to refine a ResultSet in various ways when
3748 searching for data. They can be passed to any method which takes an
3749 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3750 L</count>.
3751
3752 Default attributes can be set on the result class using
3753 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3754 the CAVEATS on that feature before using it!)
3755
3756 These are in no particular order:
3757
3758 =head2 order_by
3759
3760 =over 4
3761
3762 =item Value: ( $order_by | \@order_by | \%order_by )
3763
3764 =back
3765
3766 Which column(s) to order the results by.
3767
3768 [The full list of suitable values is documented in
3769 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3770 common options.]
3771
3772 If a single column name, or an arrayref of names is supplied, the
3773 argument is passed through directly to SQL. The hashref syntax allows
3774 for connection-agnostic specification of ordering direction:
3775
3776  For descending order:
3777
3778   order_by => { -desc => [qw/col1 col2 col3/] }
3779
3780  For explicit ascending order:
3781
3782   order_by => { -asc => 'col' }
3783
3784 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3785 supported, although you are strongly encouraged to use the hashref
3786 syntax as outlined above.
3787
3788 =head2 columns
3789
3790 =over 4
3791
3792 =item Value: \@columns
3793
3794 =back
3795
3796 Shortcut to request a particular set of columns to be retrieved. Each
3797 column spec may be a string (a table column name), or a hash (in which
3798 case the key is the C<as> value, and the value is used as the C<select>
3799 expression). Adds C<me.> onto the start of any column without a C<.> in
3800 it and sets C<select> from that, then auto-populates C<as> from
3801 C<select> as normal. (You may also use the C<cols> attribute, as in
3802 earlier versions of DBIC.)
3803
3804 Essentially C<columns> does the same as L</select> and L</as>.
3805
3806     columns => [ 'foo', { bar => 'baz' } ]
3807
3808 is the same as
3809
3810     select => [qw/foo baz/],
3811     as => [qw/foo bar/]
3812
3813 =head2 +columns
3814
3815 =over 4
3816
3817 =item Value: \@columns
3818
3819 =back
3820
3821 Indicates additional columns to be selected from storage. Works the same
3822 as L</columns> but adds columns to the selection. (You may also use the
3823 C<include_columns> attribute, as in earlier versions of DBIC). For
3824 example:-
3825
3826   $schema->resultset('CD')->search(undef, {
3827     '+columns' => ['artist.name'],
3828     join => ['artist']
3829   });
3830
3831 would return all CDs and include a 'name' column to the information
3832 passed to object inflation. Note that the 'artist' is the name of the
3833 column (or relationship) accessor, and 'name' is the name of the column
3834 accessor in the related table.
3835
3836 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3837 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3838 unary plus operator before it.
3839
3840 =head2 include_columns
3841
3842 =over 4
3843
3844 =item Value: \@columns
3845
3846 =back
3847
3848 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3849
3850 =head2 select
3851
3852 =over 4
3853
3854 =item Value: \@select_columns
3855
3856 =back
3857
3858 Indicates which columns should be selected from the storage. You can use
3859 column names, or in the case of RDBMS back ends, function or stored procedure
3860 names:
3861
3862   $rs = $schema->resultset('Employee')->search(undef, {
3863     select => [
3864       'name',
3865       { count => 'employeeid' },
3866       { max => { length => 'name' }, -as => 'longest_name' }
3867     ]
3868   });
3869
3870   # Equivalent SQL
3871   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3872
3873 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3874 use L</select>, to instruct DBIx::Class how to store the result of the column.
3875 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3876 identifier aliasing. You can however alias a function, so you can use it in
3877 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3878 attribute> supplied as shown in the example above.
3879
3880 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3881 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3882 unary plus operator before it.
3883
3884 =head2 +select
3885
3886 =over 4
3887
3888 Indicates additional columns to be selected from storage.  Works the same as
3889 L</select> but adds columns to the default selection, instead of specifying
3890 an explicit list.
3891
3892 =back
3893
3894 =head2 +as
3895
3896 =over 4
3897
3898 Indicates additional column names for those added via L</+select>. See L</as>.
3899
3900 =back
3901
3902 =head2 as
3903
3904 =over 4
3905
3906 =item Value: \@inflation_names
3907
3908 =back
3909
3910 Indicates column names for object inflation. That is L</as> indicates the
3911 slot name in which the column value will be stored within the
3912 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3913 identifier by the C<get_column> method (or via the object accessor B<if one
3914 with the same name already exists>) as shown below. The L</as> attribute has
3915 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3916
3917   $rs = $schema->resultset('Employee')->search(undef, {
3918     select => [
3919       'name',
3920       { count => 'employeeid' },
3921       { max => { length => 'name' }, -as => 'longest_name' }
3922     ],
3923     as => [qw/
3924       name
3925       employee_count
3926       max_name_length
3927     /],
3928   });
3929
3930 If the object against which the search is performed already has an accessor
3931 matching a column name specified in C<as>, the value can be retrieved using
3932 the accessor as normal:
3933
3934   my $name = $employee->name();
3935
3936 If on the other hand an accessor does not exist in the object, you need to
3937 use C<get_column> instead:
3938
3939   my $employee_count = $employee->get_column('employee_count');
3940
3941 You can create your own accessors if required - see
3942 L<DBIx::Class::Manual::Cookbook> for details.
3943
3944 =head2 join
3945
3946 =over 4
3947
3948 =item Value: ($rel_name | \@rel_names | \%rel_names)
3949
3950 =back
3951
3952 Contains a list of relationships that should be joined for this query.  For
3953 example:
3954
3955   # Get CDs by Nine Inch Nails
3956   my $rs = $schema->resultset('CD')->search(
3957     { 'artist.name' => 'Nine Inch Nails' },
3958     { join => 'artist' }
3959   );
3960
3961 Can also contain a hash reference to refer to the other relation's relations.
3962 For example:
3963
3964   package MyApp::Schema::Track;
3965   use base qw/DBIx::Class/;
3966   __PACKAGE__->table('track');
3967   __PACKAGE__->add_columns(qw/trackid cd position title/);
3968   __PACKAGE__->set_primary_key('trackid');
3969   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3970   1;
3971
3972   # In your application
3973   my $rs = $schema->resultset('Artist')->search(
3974     { 'track.title' => 'Teardrop' },
3975     {
3976       join     => { cd => 'track' },
3977       order_by => 'artist.name',
3978     }
3979   );
3980
3981 You need to use the relationship (not the table) name in  conditions,
3982 because they are aliased as such. The current table is aliased as "me", so
3983 you need to use me.column_name in order to avoid ambiguity. For example:
3984
3985   # Get CDs from 1984 with a 'Foo' track
3986   my $rs = $schema->resultset('CD')->search(
3987     {
3988       'me.year' => 1984,
3989       'tracks.name' => 'Foo'
3990     },
3991     { join => 'tracks' }
3992   );
3993
3994 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3995 similarly for a third time). For e.g.
3996
3997   my $rs = $schema->resultset('Artist')->search({
3998     'cds.title'   => 'Down to Earth',
3999     'cds_2.title' => 'Popular',
4000   }, {
4001     join => [ qw/cds cds/ ],
4002   });
4003
4004 will return a set of all artists that have both a cd with title 'Down
4005 to Earth' and a cd with title 'Popular'.
4006
4007 If you want to fetch related objects from other tables as well, see C<prefetch>
4008 below.
4009
4010  NOTE: An internal join-chain pruner will discard certain joins while
4011  constructing the actual SQL query, as long as the joins in question do not
4012  affect the retrieved result. This for example includes 1:1 left joins
4013  that are not part of the restriction specification (WHERE/HAVING) nor are
4014  a part of the query selection.
4015
4016 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4017
4018 =head2 prefetch
4019
4020 =over 4
4021
4022 =item Value: ($rel_name | \@rel_names | \%rel_names)
4023
4024 =back
4025
4026 Contains one or more relationships that should be fetched along with
4027 the main query (when they are accessed afterwards the data will
4028 already be available, without extra queries to the database).  This is
4029 useful for when you know you will need the related objects, because it
4030 saves at least one query:
4031
4032   my $rs = $schema->resultset('Tag')->search(
4033     undef,
4034     {
4035       prefetch => {
4036         cd => 'artist'
4037       }
4038     }
4039   );
4040
4041 The initial search results in SQL like the following:
4042
4043   SELECT tag.*, cd.*, artist.* FROM tag
4044   JOIN cd ON tag.cd = cd.cdid
4045   JOIN artist ON cd.artist = artist.artistid
4046
4047 L<DBIx::Class> has no need to go back to the database when we access the
4048 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4049 case.
4050
4051 Simple prefetches will be joined automatically, so there is no need
4052 for a C<join> attribute in the above search.
4053
4054 L</prefetch> can be used with the any of the relationship types and
4055 multiple prefetches can be specified together. Below is a more complex
4056 example that prefetches a CD's artist, its liner notes (if present),
4057 the cover image, the tracks on that cd, and the guests on those
4058 tracks.
4059
4060  # Assuming:
4061  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4062  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4063  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4064  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4065
4066  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4067
4068  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4069
4070
4071  my $rs = $schema->resultset('CD')->search(
4072    undef,
4073    {
4074      prefetch => [
4075        { artist => 'record_label'},  # belongs_to => belongs_to
4076        'liner_note',                 # might_have
4077        'cover_image',                # has_one
4078        { tracks => 'guests' },       # has_many => has_many
4079      ]
4080    }
4081  );
4082
4083 This will produce SQL like the following:
4084
4085  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4086         tracks.*, guests.*
4087    FROM cd me
4088    JOIN artist artist
4089      ON artist.artistid = me.artistid
4090    JOIN record_label record_label
4091      ON record_label.labelid = artist.labelid
4092    LEFT JOIN track tracks
4093      ON tracks.cdid = me.cdid
4094    LEFT JOIN guest guests
4095      ON guests.trackid = track.trackid
4096    LEFT JOIN liner_notes liner_note
4097      ON liner_note.cdid = me.cdid
4098    JOIN cd_artwork cover_image
4099      ON cover_image.cdid = me.cdid
4100  ORDER BY tracks.cd
4101
4102 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4103 C<tracks>, and C<guests> of the CD will all be available through the
4104 relationship accessors without the need for additional queries to the
4105 database.
4106
4107 However, there is one caveat to be observed: it can be dangerous to
4108 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4109 relationship on a given level. e.g.:
4110
4111  my $rs = $schema->resultset('CD')->search(
4112    undef,
4113    {
4114      prefetch => [
4115        'tracks',                         # has_many
4116        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4117      ]
4118    }
4119  );
4120
4121 The collapser currently can't identify duplicate tuples for multiple
4122 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4123 result the second L<has_many|DBIx::Class::Relationship/has_many>
4124 relation could contain redundant objects.
4125
4126 =head3 Using L</prefetch> with L</join>
4127
4128 L</prefetch> implies a L</join> with the equivalent argument, and is
4129 properly merged with any existing L</join> specification. So the
4130 following:
4131
4132   my $rs = $schema->resultset('CD')->search(
4133    {'record_label.name' => 'Music Product Ltd.'},
4134    {
4135      join     => {artist => 'record_label'},
4136      prefetch => 'artist',
4137    }
4138  );
4139
4140 ... will work, searching on the record label's name, but only
4141 prefetching the C<artist>.
4142
4143 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4144
4145 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4146 prefetched relations.  So given:
4147
4148   my $rs = $schema->resultset('CD')->search(
4149    undef,
4150    {
4151      select   => ['cd.title'],
4152      as       => ['cd_title'],
4153      prefetch => 'artist',
4154    }
4155  );
4156
4157 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4158 becomes: C<'cd_title', 'artist.*'>.
4159
4160 =head3 CAVEATS
4161
4162 Prefetch does a lot of deep magic. As such, it may not behave exactly
4163 as you might expect.
4164
4165 =over 4
4166
4167 =item *
4168
4169 Prefetch uses the L</cache> to populate the prefetched relationships. This
4170 may or may not be what you want.
4171
4172 =item *
4173
4174 If you specify a condition on a prefetched relationship, ONLY those
4175 rows that match the prefetched condition will be fetched into that relationship.
4176 This means that adding prefetch to a search() B<may alter> what is returned by
4177 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4178
4179   my $artist_rs = $schema->resultset('Artist')->search({
4180       'cds.year' => 2008,
4181   }, {
4182       join => 'cds',
4183   });
4184
4185   my $count = $artist_rs->first->cds->count;
4186
4187   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4188
4189   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4190
4191   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4192
4193 that cmp_ok() may or may not pass depending on the datasets involved. This
4194 behavior may or may not survive the 0.09 transition.
4195
4196 =back
4197
4198 =head2 alias
4199
4200 =over 4
4201
4202 =item Value: $source_alias
4203
4204 =back
4205
4206 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4207 nested search queries (sub-SELECTs) might need specific aliases set to
4208 reference inner queries.  For example:
4209
4210    my $q = $rs
4211       ->related_resultset('CDs')
4212       ->related_resultset('Tracks')
4213       ->search({
4214          'track.id' => { -ident => 'none_search.id' },
4215       })
4216       ->as_query;
4217
4218    my $ids = $self->search({
4219       -not_exists => $q,
4220    }, {
4221       alias    => 'none_search',
4222       group_by => 'none_search.id',
4223    })->get_column('id')->as_query;
4224
4225    $self->search({ id => { -in => $ids } })
4226
4227 This attribute is directly tied to L</current_source_alias>.
4228
4229 =head2 page
4230
4231 =over 4
4232
4233 =item Value: $page
4234
4235 =back
4236
4237 Makes the resultset paged and specifies the page to retrieve. Effectively
4238 identical to creating a non-pages resultset and then calling ->page($page)
4239 on it.
4240
4241 If L</rows> attribute is not specified it defaults to 10 rows per page.
4242
4243 When you have a paged resultset, L</count> will only return the number
4244 of rows in the page. To get the total, use the L</pager> and call
4245 C<total_entries> on it.
4246
4247 =head2 rows
4248
4249 =over 4
4250
4251 =item Value: $rows
4252
4253 =back
4254
4255 Specifies the maximum number of rows for direct retrieval or the number of
4256 rows per page if the page attribute or method is used.
4257
4258 =head2 offset
4259
4260 =over 4
4261
4262 =item Value: $offset
4263
4264 =back
4265
4266 Specifies the (zero-based) row number for the  first row to be returned, or the
4267 of the first row of the first page if paging is used.
4268
4269 =head2 software_limit
4270
4271 =over 4
4272
4273 =item Value: (0 | 1)
4274
4275 =back
4276
4277 When combined with L</rows> and/or L</offset> the generated SQL will not
4278 include any limit dialect stanzas. Instead the entire result will be selected
4279 as if no limits were specified, and DBIC will perform the limit locally, by
4280 artificially advancing and finishing the resulting L</cursor>.
4281
4282 This is the recommended way of performing resultset limiting when no sane RDBMS
4283 implementation is available (e.g.
4284 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4285 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4286
4287 =head2 group_by
4288
4289 =over 4
4290
4291 =item Value: \@columns
4292
4293 =back
4294
4295 A arrayref of columns to group by. Can include columns of joined tables.
4296
4297   group_by => [qw/ column1 column2 ... /]
4298
4299 =head2 having
4300
4301 =over 4
4302
4303 =item Value: $condition
4304
4305 =back
4306
4307 HAVING is a select statement attribute that is applied between GROUP BY and
4308 ORDER BY. It is applied to the after the grouping calculations have been
4309 done.
4310
4311   having => { 'count_employee' => { '>=', 100 } }
4312
4313 or with an in-place function in which case literal SQL is required:
4314
4315   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4316
4317 =head2 distinct
4318
4319 =over 4
4320
4321 =item Value: (0 | 1)
4322
4323 =back
4324
4325 Set to 1 to group by all columns. If the resultset already has a group_by
4326 attribute, this setting is ignored and an appropriate warning is issued.
4327
4328 =head2 where
4329
4330 =over 4
4331
4332 Adds to the WHERE clause.
4333
4334   # only return rows WHERE deleted IS NULL for all searches
4335   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4336
4337 Can be overridden by passing C<< { where => undef } >> as an attribute
4338 to a resultset.
4339
4340 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4341
4342 =back
4343
4344 =head2 cache
4345
4346 Set to 1 to cache search results. This prevents extra SQL queries if you
4347 revisit rows in your ResultSet:
4348
4349   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4350
4351   while( my $artist = $resultset->next ) {
4352     ... do stuff ...
4353   }
4354
4355   $rs->first; # without cache, this would issue a query
4356
4357 By default, searches are not cached.
4358
4359 For more examples of using these attributes, see
4360 L<DBIx::Class::Manual::Cookbook>.
4361
4362 =head2 for
4363
4364 =over 4
4365
4366 =item Value: ( 'update' | 'shared' | \$scalar )
4367
4368 =back
4369
4370 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4371 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4372 query.
4373
4374 =head1 DBIC BIND VALUES
4375
4376 Because DBIC may need more information to bind values than just the column name
4377 and value itself, it uses a special format for both passing and receiving bind
4378 values.  Each bind value should be composed of an arrayref of
4379 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4380
4381 =over 4
4382
4383 =item dbd_attrs
4384
4385 If present (in any form), this is what is being passed directly to bind_param.
4386 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4387 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4388
4389 If this is specified, all other bind options described below are ignored.
4390
4391 =item sqlt_datatype
4392
4393 If present, this is used to infer the actual bind attribute by passing to
4394 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4395 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4396
4397 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4398 currently drivers are expected to "Do the Right Thing" when given a common
4399 datatype name.  (Not ideal, but that's what we got at this point.)
4400
4401 =item sqlt_size
4402
4403 Currently used to correctly allocate buffers for bind_param_inout().
4404 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4405 or to a sensible value based on the "data_type".
4406
4407 =item dbic_colname
4408
4409 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4410 explicitly specified they are never overriden).  Also used by some weird DBDs,
4411 where the column name should be available at bind_param time (e.g. Oracle).
4412
4413 =back
4414
4415 For backwards compatibility and convenience, the following shortcuts are
4416 supported:
4417
4418   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4419   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4420   [ undef,   $val ] === [ {}, $val ]
4421
4422 =head1 AUTHOR AND CONTRIBUTORS
4423
4424 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4425
4426 =head1 LICENSE
4427
4428 You may distribute this code under the same terms as Perl itself.
4429
4430 =cut
4431
4432 1;