lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use DBIx::Class::ResultClass::HashRefInflator;
   9 use Scalar::Util qw/blessed weaken reftype/;
  10 use DBIx::Class::_Util qw(
  11   dbic_internal_try dump_value
  12   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  13 );
  14 use Try::Tiny;
  15
  16 # not importing first() as it will clash with our own method
  17 use List::Util ();
  18
  19 BEGIN {
  20   # De-duplication in _merge_attr() is disabled, but left in for reference
  21   # (the merger is used for other things that ought not to be de-duped)
  22   *__HM_DEDUP = sub () { 0 };
  23 }
  24
  25 use namespace::clean;
  26
  27 use overload
  28         '0+'     => "count",
  29         'bool'   => "_bool",
  30         fallback => 1;
  31
  32 # this is real - CDBICompat overrides it with insanity
  33 # yes, prototype won't matter, but that's for now ;)
  34 sub _bool () { 1 }
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  37
  38 =head1 NAME
  39
  40 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  41
  42 =head1 SYNOPSIS
  43
  44   my $users_rs = $schema->resultset('User');
  45   while( $user = $users_rs->next) {
  46     print $user->username;
  47   }
  48
  49   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  50   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  51
  52 =head1 DESCRIPTION
  53
  54 A ResultSet is an object which stores a set of conditions representing
  55 a query. It is the backbone of DBIx::Class (i.e. the really
  56 important/useful bit).
  57
  58 No SQL is executed on the database when a ResultSet is created, it
  59 just stores all the conditions needed to create the query.
  60
  61 A basic ResultSet representing the data of an entire table is returned
  62 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  63 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  64
  65   my $users_rs = $schema->resultset('User');
  66
  67 A new ResultSet is returned from calling L</search> on an existing
  68 ResultSet. The new one will contain all the conditions of the
  69 original, plus any new conditions added in the C<search> call.
  70
  71 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  72 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  73 represents.
  74
  75 The query that the ResultSet represents is B<only> executed against
  76 the database when these methods are called:
  77 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  78
  79 If a resultset is used in a numeric context it returns the L</count>.
  80 However, if it is used in a boolean context it is B<always> true.  So if
  81 you want to check if a resultset has any results, you must use C<if $rs
  82 != 0>.
  83
  84 =head1 EXAMPLES
  85
  86 =head2 Chaining resultsets
  87
  88 Let's say you've got a query that needs to be run to return some data
  89 to the user. But, you have an authorization system in place that
  90 prevents certain users from seeing certain information. So, you want
  91 to construct the basic query in one method, but add constraints to it in
  92 another.
  93
  94   sub get_data {
  95     my $self = shift;
  96     my $request = $self->get_request; # Get a request object somehow.
  97     my $schema = $self->result_source->schema;
  98
  99     my $cd_rs = $schema->resultset('CD')->search({
 100       title => $request->param('title'),
 101       year => $request->param('year'),
 102     });
 103
 104     $cd_rs = $self->apply_security_policy( $cd_rs );
 105
 106     return $cd_rs->all();
 107   }
 108
 109   sub apply_security_policy {
 110     my $self = shift;
 111     my ($rs) = @_;
 112
 113     return $rs->search({
 114       subversive => 0,
 115     });
 116   }
 117
 118 =head3 Resolving conditions and attributes
 119
 120 When a resultset is chained from another resultset (e.g.:
 121 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 122 and attributes with the same keys need resolving.
 123
 124 If any of L</columns>, L</select>, L</as> are present, they reset the
 125 original selection, and start the selection "clean".
 126
 127 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 128 are merged into the existing ones from the original resultset.
 129
 130 The L</where> and L</having> attributes, and any search conditions, are
 131 merged with an SQL C<AND> to the existing condition from the original
 132 resultset.
 133
 134 All other attributes are overridden by any new ones supplied in the
 135 search attributes.
 136
 137 =head2 Multiple queries
 138
 139 Since a resultset just defines a query, you can do all sorts of
 140 things with it with the same object.
 141
 142   # Don't hit the DB yet.
 143   my $cd_rs = $schema->resultset('CD')->search({
 144     title => 'something',
 145     year => 2009,
 146   });
 147
 148   # Each of these hits the DB individually.
 149   my $count = $cd_rs->count;
 150   my $most_recent = $cd_rs->get_column('date_released')->max();
 151   my @records = $cd_rs->all;
 152
 153 And it's not just limited to SELECT statements.
 154
 155   $cd_rs->delete();
 156
 157 This is even cooler:
 158
 159   $cd_rs->create({ artist => 'Fred' });
 160
 161 Which is the same as:
 162
 163   $schema->resultset('CD')->create({
 164     title => 'something',
 165     year => 2009,
 166     artist => 'Fred'
 167   });
 168
 169 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 170
 171 =head2 Custom ResultSet classes
 172
 173 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 174
 175   package MyApp::Schema::ResultSet::User;
 176
 177   use strict;
 178   use warnings;
 179
 180   use base 'DBIx::Class::ResultSet';
 181
 182   sub active {
 183     my $self = shift;
 184     $self->search({ $self->current_source_alias . '.active' => 1 });
 185   }
 186
 187   sub unverified {
 188     my $self = shift;
 189     $self->search({ $self->current_source_alias . '.verified' => 0 });
 190   }
 191
 192   sub created_n_days_ago {
 193     my ($self, $days_ago) = @_;
 194     $self->search({
 195       $self->current_source_alias . '.create_date' => {
 196         '<=',
 197       $self->result_source->schema->storage->datetime_parser->format_datetime(
 198         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 199       )}
 200     });
 201   }
 202
 203   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 204
 205   1;
 206
 207 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 208 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 209 L<ResulSet|DBIx::Class::ResultSet> classes.
 210
 211 =head3 ResultSet subclassing with Moose and similar constructor-providers
 212
 213 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 214 you may find it useful if your ResultSets contain a lot of business logic
 215 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 216 your code via roles.
 217
 218 In order to write custom ResultSet classes with L<Moo> you need to use the
 219 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 220 unusual signature of the L<constructor provided by DBIC
 221 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 222
 223   use Moo;
 224   extends 'DBIx::Class::ResultSet';
 225   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 226
 227   ...your code...
 228
 229   1;
 230
 231 If you want to build your custom ResultSet classes with L<Moose>, you need
 232 a similar, though a little more elaborate template in order to interface the
 233 inlining of the L<Moose>-provided
 234 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 235 with the DBIC one.
 236
 237   package MyApp::Schema::ResultSet::User;
 238
 239   use Moose;
 240   use MooseX::NonMoose;
 241   extends 'DBIx::Class::ResultSet';
 242
 243   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 244
 245   ...your code...
 246
 247   __PACKAGE__->meta->make_immutable;
 248
 249   1;
 250
 251 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 252 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 253 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 254 instead by doing:
 255
 256   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 257
 258 =head1 METHODS
 259
 260 =head2 new
 261
 262 =over 4
 263
 264 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 265
 266 =item Return Value: L<$resultset|/search>
 267
 268 =back
 269
 270 The resultset constructor. Takes a source object (usually a
 271 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 272 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 273 executed as needed by the other methods.
 274
 275 Generally you never construct a resultset manually. Instead you get one
 276 from e.g. a
 277 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 278 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 279 scalar context):
 280
 281   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 282
 283 =over
 284
 285 =item WARNING
 286
 287 If called on an object, proxies to L</new_result> instead, so
 288
 289   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 290
 291 will return a CD object, not a ResultSet, and is equivalent to:
 292
 293   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 294
 295 Please also keep in mind that many internals call L</new_result> directly,
 296 so overloading this method with the idea of intercepting new result object
 297 creation B<will not work>. See also warning pertaining to L</create>.
 298
 299 =back
 300
 301 =cut
 302
 303 sub new {
 304   my $class = shift;
 305
 306   if (ref $class) {
 307     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 308     return $class->new_result(@_);
 309   }
 310
 311   my ($source, $attrs) = @_;
 312   $source = $source->resolve
 313     if $source->isa('DBIx::Class::ResultSourceHandle');
 314
 315   $attrs = { %{$attrs||{}} };
 316   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 317
 318   if ($attrs->{page}) {
 319     $attrs->{rows} ||= 10;
 320   }
 321
 322   $attrs->{alias} ||= 'me';
 323
 324   my $self = bless {
 325     result_source => $source,
 326     cond => $attrs->{where},
 327     pager => undef,
 328     attrs => $attrs,
 329   }, $class;
 330
 331   # if there is a dark selector, this means we are already in a
 332   # chain and the cleanup/sanification was taken care of by
 333   # _search_rs already
 334   $self->_normalize_selection($attrs)
 335     unless $attrs->{_dark_selector};
 336
 337   $self->result_class(
 338     $attrs->{result_class} || $source->result_class
 339   );
 340
 341   $self;
 342 }
 343
 344 =head2 search
 345
 346 =over 4
 347
 348 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 349
 350 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 351
 352 =back
 353
 354   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 355   my $new_rs = $cd_rs->search({ year => 2005 });
 356
 357   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 358                  # year = 2005 OR year = 2004
 359
 360 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 361 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 362 To avoid that, use L</search_rs>.
 363
 364 If you need to pass in additional attributes but no additional condition,
 365 call it as C<search(undef, \%attrs)>.
 366
 367   # "SELECT name, artistid FROM $artist_table"
 368   my @all_artists = $schema->resultset('Artist')->search(undef, {
 369     columns => [qw/name artistid/],
 370   });
 371
 372 For a list of attributes that can be passed to C<search>, see
 373 L</ATTRIBUTES>. For more examples of using this function, see
 374 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 375 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 376 and its extension L<DBIx::Class::SQLMaker>.
 377
 378 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 379
 380 =head3 CAVEAT
 381
 382 Note that L</search> does not process/deflate any of the values passed in the
 383 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 384 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 385 manually that any value passed to this method will stringify to something the
 386 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 387 objects, for more info see:
 388 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 389
 390 =cut
 391
 392 sub search {
 393   my $self = shift;
 394   my $rs = $self->search_rs( @_ );
 395
 396   if (wantarray) {
 397     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 398     return $rs->all;
 399   }
 400   elsif (defined wantarray) {
 401     return $rs;
 402   }
 403   else {
 404     # we can be called by a relationship helper, which in
 405     # turn may be called in void context due to some braindead
 406     # overload or whatever else the user decided to be clever
 407     # at this particular day. Thus limit the exception to
 408     # external code calls only
 409     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 410       if (caller)[0] !~ /^\QDBIx::Class::/;
 411
 412     return ();
 413   }
 414 }
 415
 416 =head2 search_rs
 417
 418 =over 4
 419
 420 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 421
 422 =item Return Value: L<$resultset|/search>
 423
 424 =back
 425
 426 This method does the same exact thing as search() except it will
 427 always return a resultset, even in list context.
 428
 429 =cut
 430
 431 sub search_rs {
 432   my $self = shift;
 433
 434   my $rsrc = $self->result_source;
 435   my ($call_cond, $call_attrs);
 436
 437   # Special-case handling for (undef, undef) or (undef)
 438   # Note that (foo => undef) is valid deprecated syntax
 439   @_ = () if not scalar grep { defined $_ } @_;
 440
 441   # just a cond
 442   if (@_ == 1) {
 443     $call_cond = shift;
 444   }
 445   # fish out attrs in the ($condref, $attr) case
 446   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 447     ($call_cond, $call_attrs) = @_;
 448   }
 449   elsif (@_ % 2) {
 450     $self->throw_exception('Odd number of arguments to search')
 451   }
 452   # legacy search
 453   elsif (@_) {
 454     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 455       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 456
 457     for my $i (0 .. $#_) {
 458       next if $i % 2;
 459       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 460         if (! defined $_[$i] or length ref $_[$i] );
 461     }
 462
 463     $call_cond = { @_ };
 464   }
 465
 466   # see if we can keep the cache (no $rs changes)
 467   my $cache;
 468   my %safe = (alias => 1, cache => 1);
 469   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 470     ! defined $call_cond
 471       or
 472     ref $call_cond eq 'HASH' && ! keys %$call_cond
 473       or
 474     ref $call_cond eq 'ARRAY' && ! @$call_cond
 475   )) {
 476     $cache = $self->get_cache;
 477   }
 478
 479   my $old_attrs = { %{$self->{attrs}} };
 480   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 481
 482   my $new_attrs = { %$old_attrs };
 483
 484   # take care of call attrs (only if anything is changing)
 485   if ($call_attrs and keys %$call_attrs) {
 486
 487     # copy for _normalize_selection
 488     $call_attrs = { %$call_attrs };
 489
 490     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 491
 492     # reset the current selector list if new selectors are supplied
 493     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 494       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 495     }
 496
 497     # Normalize the new selector list (operates on the passed-in attr structure)
 498     # Need to do it on every chain instead of only once on _resolved_attrs, in
 499     # order to allow detection of empty vs partial 'as'
 500     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 501       if $old_attrs->{_dark_selector};
 502     $self->_normalize_selection ($call_attrs);
 503
 504     # start with blind overwriting merge, exclude selector attrs
 505     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 506     delete @{$new_attrs}{@selector_attrs};
 507
 508     for (@selector_attrs) {
 509       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 510         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 511     }
 512
 513     # older deprecated name, use only if {columns} is not there
 514     if (my $c = delete $new_attrs->{cols}) {
 515       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 516       if ($new_attrs->{columns}) {
 517         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 518       }
 519       else {
 520         $new_attrs->{columns} = $c;
 521       }
 522     }
 523
 524
 525     # join/prefetch use their own crazy merging heuristics
 526     foreach my $key (qw/join prefetch/) {
 527       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 528         if exists $call_attrs->{$key};
 529     }
 530
 531     # stack binds together
 532     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 533   }
 534
 535
 536   for ($old_where, $call_cond) {
 537     if (defined $_) {
 538       $new_attrs->{where} = $self->_stack_cond (
 539         $_, $new_attrs->{where}
 540       );
 541     }
 542   }
 543
 544   if (defined $old_having) {
 545     $new_attrs->{having} = $self->_stack_cond (
 546       $old_having, $new_attrs->{having}
 547     )
 548   }
 549
 550   my $rs = (ref $self)->new($rsrc, $new_attrs);
 551
 552   $rs->set_cache($cache) if ($cache);
 553
 554   return $rs;
 555 }
 556
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => do {
 622                 local $Data::Dumper::Indent = 0;
 623                 dump_value $_;
 624               },
 625             };
 626             last SELECTOR;
 627           }
 628         }
 629       }
 630     }
 631     elsif (@$as < @$sel) {
 632       $self->throw_exception(
 633         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 634       );
 635     }
 636     elsif ($pref and $attrs->{_dark_selector}) {
 637       $self->throw_exception(
 638         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 639       );
 640     }
 641
 642
 643     # merge result
 644     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 645     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 646   }
 647 }
 648
 649 sub _stack_cond {
 650   my ($self, $left, $right) = @_;
 651
 652   (
 653     (ref $_ eq 'ARRAY' and !@$_)
 654       or
 655     (ref $_ eq 'HASH' and ! keys %$_)
 656   ) and $_ = undef for ($left, $right);
 657
 658   # either one of the two undef
 659   if ( (defined $left) xor (defined $right) ) {
 660     return defined $left ? $left : $right;
 661   }
 662   # both undef
 663   elsif ( ! defined $left ) {
 664     return undef
 665   }
 666   else {
 667     return $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 668   }
 669 }
 670
 671 =head2 search_literal
 672
 673 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 674 should only be used in that context. C<search_literal> is a convenience
 675 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 676 want to ensure columns are bound correctly, use L</search>.
 677
 678 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 679 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 680 require C<search_literal>.
 681
 682 =over 4
 683
 684 =item Arguments: $sql_fragment, @standalone_bind_values
 685
 686 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 687
 688 =back
 689
 690   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 691   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 692
 693 Pass a literal chunk of SQL to be added to the conditional part of the
 694 resultset query.
 695
 696 Example of how to use C<search> instead of C<search_literal>
 697
 698   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 699   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 700
 701 =cut
 702
 703 sub search_literal {
 704   my ($self, $sql, @bind) = @_;
 705   my $attr;
 706   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 707     $attr = pop @bind;
 708   }
 709   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 710 }
 711
 712 =head2 find
 713
 714 =over 4
 715
 716 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 717
 718 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 719
 720 =back
 721
 722 Finds and returns a single row based on supplied criteria. Takes either a
 723 hashref with the same format as L</create> (including inference of foreign
 724 keys from related objects), or a list of primary key values in the same
 725 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 726 declaration on the L</result_source>.
 727
 728 In either case an attempt is made to combine conditions already existing on
 729 the resultset with the condition passed to this method.
 730
 731 To aid with preparing the correct query for the storage you may supply the
 732 C<key> attribute, which is the name of a
 733 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 734 unique constraint corresponding to the
 735 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 736 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 737 to construct a query that satisfies the named unique constraint fully (
 738 non-NULL values for each column member of the constraint) an exception is
 739 thrown.
 740
 741 If no C<key> is specified, the search is carried over all unique constraints
 742 which are fully defined by the available condition.
 743
 744 If no such constraint is found, C<find> currently defaults to a simple
 745 C<< search->(\%column_values) >> which may or may not do what you expect.
 746 Note that this fallback behavior may be deprecated in further versions. If
 747 you need to search with arbitrary conditions - use L</search>. If the query
 748 resulting from this fallback produces more than one row, a warning to the
 749 effect is issued, though only the first row is constructed and returned as
 750 C<$result_object>.
 751
 752 In addition to C<key>, L</find> recognizes and applies standard
 753 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 754
 755 Note that if you have extra concerns about the correctness of the resulting
 756 query you need to specify the C<key> attribute and supply the entire condition
 757 as an argument to find (since it is not always possible to perform the
 758 combination of the resultset condition with the supplied one, especially if
 759 the resultset condition contains literal sql).
 760
 761 For example, to find a row by its primary key:
 762
 763   my $cd = $schema->resultset('CD')->find(5);
 764
 765 You can also find a row by a specific unique constraint:
 766
 767   my $cd = $schema->resultset('CD')->find(
 768     {
 769       artist => 'Massive Attack',
 770       title  => 'Mezzanine',
 771     },
 772     { key => 'cd_artist_title' }
 773   );
 774
 775 See also L</find_or_create> and L</update_or_create>.
 776
 777 =cut
 778
 779 sub find {
 780   my $self = shift;
 781   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 782
 783   my $rsrc = $self->result_source;
 784
 785   my $constraint_name;
 786   if (exists $attrs->{key}) {
 787     $constraint_name = defined $attrs->{key}
 788       ? $attrs->{key}
 789       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 790     ;
 791   }
 792
 793   # Parse out the condition from input
 794   my $call_cond;
 795
 796   if (ref $_[0] eq 'HASH') {
 797     $call_cond = { %{$_[0]} };
 798   }
 799   else {
 800     # if only values are supplied we need to default to 'primary'
 801     $constraint_name = 'primary' unless defined $constraint_name;
 802
 803     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 804
 805     $self->throw_exception(
 806       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 807     ) unless @c_cols;
 808
 809     $self->throw_exception (
 810       'find() expects either a column/value hashref, or a list of values '
 811     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 812     ) unless @c_cols == @_;
 813
 814     @{$call_cond}{@c_cols} = @_;
 815   }
 816
 817   # process relationship data if any
 818   for my $key (keys %$call_cond) {
 819     if (
 820       length ref($call_cond->{$key})
 821         and
 822       my $relinfo = $rsrc->relationship_info($key)
 823         and
 824       # implicitly skip has_many's (likely MC)
 825       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 826     ) {
 827       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 828         $relinfo->{cond}, $val, $key, $key
 829       );
 830
 831       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 832          if $crosstable or ref($rel_cond) ne 'HASH';
 833
 834       # supplement condition
 835       # relationship conditions take precedence (?)
 836       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 837     }
 838   }
 839
 840   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 841   my $final_cond;
 842   if (defined $constraint_name) {
 843     $final_cond = $self->_qualify_cond_columns (
 844
 845       $self->result_source->_minimal_valueset_satisfying_constraint(
 846         constraint_name => $constraint_name,
 847         values => ($self->_merge_with_rscond($call_cond))[0],
 848         carp_on_nulls => 1,
 849       ),
 850
 851       $alias,
 852     );
 853   }
 854   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 855     # This means that we got here after a merger of relationship conditions
 856     # in ::Relationship::Base::search_related (the row method), and furthermore
 857     # the relationship is of the 'single' type. This means that the condition
 858     # provided by the relationship (already attached to $self) is sufficient,
 859     # as there can be only one row in the database that would satisfy the
 860     # relationship
 861   }
 862   else {
 863     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 864
 865     # no key was specified - fall down to heuristics mode:
 866     # run through all unique queries registered on the resultset, and
 867     # 'OR' all qualifying queries together
 868     #
 869     # always start from 'primary' if it exists at all
 870     for my $c_name ( sort {
 871         $a eq 'primary' ? -1
 872       : $b eq 'primary' ? 1
 873       : $a cmp $b
 874     } $rsrc->unique_constraint_names) {
 875
 876       next if $seen_column_combinations{
 877         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 878       }++;
 879
 880       dbic_internal_try {
 881         push @unique_queries, $self->_qualify_cond_columns(
 882           $self->result_source->_minimal_valueset_satisfying_constraint(
 883             constraint_name => $c_name,
 884             values => ($self->_merge_with_rscond($call_cond))[0],
 885             columns_info => ($ci ||= $self->result_source->columns_info),
 886           ),
 887           $alias
 888         );
 889       }
 890       catch {
 891         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 892       };
 893     }
 894
 895     $final_cond =
 896         @unique_queries   ? \@unique_queries
 897       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 898       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 899     ;
 900   }
 901
 902   # Run the query, passing the result_class since it should propagate for find
 903   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 904   if ($rs->_resolved_attrs->{collapse}) {
 905     my $row = $rs->next;
 906     carp "Query returned more than one row" if $rs->next;
 907     return $row;
 908   }
 909   else {
 910     return $rs->single;
 911   }
 912 }
 913
 914 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 915 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 916 #
 917 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 918 # condition. It is provided for overrides until a saner way forward is devised
 919 #
 920 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 921 # the road. Please adjust your tests accordingly to catch this situation early
 922 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 923 #
 924 # The method will not be removed without an adequately complete replacement
 925 # for strict-mode enforcement
 926 sub _non_unique_find_fallback {
 927   my ($self, $cond, $attrs) = @_;
 928
 929   return $self->_qualify_cond_columns(
 930     $cond,
 931     exists $attrs->{alias}
 932       ? $attrs->{alias}
 933       : $self->{attrs}{alias}
 934   );
 935 }
 936
 937
 938 sub _qualify_cond_columns {
 939   my ($self, $cond, $alias) = @_;
 940
 941   my %aliased = %$cond;
 942   for (keys %aliased) {
 943     $aliased{"$alias.$_"} = delete $aliased{$_}
 944       if $_ !~ /\./;
 945   }
 946
 947   return \%aliased;
 948 }
 949
 950 sub _build_unique_cond {
 951   carp_unique sprintf
 952     '_build_unique_cond is a private method, and moreover is about to go '
 953   . 'away. Please contact the development team at %s if you believe you '
 954   . 'have a genuine use for this method, in order to discuss alternatives.',
 955     DBIx::Class::_ENV_::HELP_URL,
 956   ;
 957
 958   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 959
 960   $self->result_source->_minimal_valueset_satisfying_constraint(
 961     constraint_name => $constraint_name,
 962     values => $cond,
 963     carp_on_nulls => !$croak_on_null
 964   );
 965 }
 966
 967 =head2 search_related
 968
 969 =over 4
 970
 971 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 972
 973 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 974
 975 =back
 976
 977   $new_rs = $cd_rs->search_related('artist', {
 978     name => 'Emo-R-Us',
 979   });
 980
 981 Searches the specified relationship, optionally specifying a condition and
 982 attributes for matching records. See L</ATTRIBUTES> for more information.
 983
 984 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 985 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 986
 987 See also L</search_related_rs>.
 988
 989 =cut
 990
 991 sub search_related {
 992   return shift->related_resultset(shift)->search(@_);
 993 }
 994
 995 =head2 search_related_rs
 996
 997 This method works exactly the same as search_related, except that
 998 it guarantees a resultset, even in list context.
 999
1000 =cut
1001
1002 sub search_related_rs {
1003   return shift->related_resultset(shift)->search_rs(@_);
1004 }
1005
1006 =head2 cursor
1007
1008 =over 4
1009
1010 =item Arguments: none
1011
1012 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1013
1014 =back
1015
1016 Returns a storage-driven cursor to the given resultset. See
1017 L<DBIx::Class::Cursor> for more information.
1018
1019 =cut
1020
1021 sub cursor {
1022   my $self = shift;
1023
1024   return $self->{cursor} ||= do {
1025     my $attrs = $self->_resolved_attrs;
1026     $self->result_source->storage->select(
1027       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1028     );
1029   };
1030 }
1031
1032 =head2 single
1033
1034 =over 4
1035
1036 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1037
1038 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1039
1040 =back
1041
1042   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1043
1044 Inflates the first result without creating a cursor if the resultset has
1045 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1046 of L</search>.
1047
1048 While this method can take an optional search condition (just like L</search>)
1049 being a fast-code-path it does not recognize search attributes. If you need to
1050 add extra joins or similar, call L</search> and then chain-call L</single> on the
1051 L<DBIx::Class::ResultSet> returned.
1052
1053 =over
1054
1055 =item B<Note>
1056
1057 As of 0.08100, this method enforces the assumption that the preceding
1058 query returns only one row. If more than one row is returned, you will receive
1059 a warning:
1060
1061   Query returned more than one row
1062
1063 In this case, you should be using L</next> or L</find> instead, or if you really
1064 know what you are doing, use the L</rows> attribute to explicitly limit the size
1065 of the resultset.
1066
1067 This method will also throw an exception if it is called on a resultset prefetching
1068 has_many, as such a prefetch implies fetching multiple rows from the database in
1069 order to assemble the resulting object.
1070
1071 =back
1072
1073 =cut
1074
1075 sub single {
1076   my ($self, $where) = @_;
1077   if(@_ > 2) {
1078       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1079   }
1080
1081   my $attrs = { %{$self->_resolved_attrs} };
1082
1083   $self->throw_exception(
1084     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1085   ) if $attrs->{collapse};
1086
1087   if ($where) {
1088     if (defined $attrs->{where}) {
1089       $attrs->{where} = {
1090         '-and' =>
1091             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1092                $where, delete $attrs->{where} ]
1093       };
1094     } else {
1095       $attrs->{where} = $where;
1096     }
1097   }
1098
1099   my $data = [ $self->result_source->storage->select_single(
1100     $attrs->{from}, $attrs->{select},
1101     $attrs->{where}, $attrs
1102   )];
1103
1104   return undef unless @$data;
1105   $self->{_stashed_rows} = [ $data ];
1106   $self->_construct_results->[0];
1107 }
1108
1109 =head2 get_column
1110
1111 =over 4
1112
1113 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1114
1115 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1116
1117 =back
1118
1119   my $max_length = $rs->get_column('length')->max;
1120
1121 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1122
1123 =cut
1124
1125 sub get_column {
1126   my ($self, $column) = @_;
1127   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1128   return $new;
1129 }
1130
1131 =head2 search_like
1132
1133 =over 4
1134
1135 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1136
1137 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1138
1139 =back
1140
1141   # WHERE title LIKE '%blue%'
1142   $cd_rs = $rs->search_like({ title => '%blue%'});
1143
1144 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1145 that this is simply a convenience method retained for ex Class::DBI users.
1146 You most likely want to use L</search> with specific operators.
1147
1148 For more information, see L<DBIx::Class::Manual::Cookbook>.
1149
1150 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1151 instead. An example conversion is:
1152
1153   ->search_like({ foo => 'bar' });
1154
1155   # Becomes
1156
1157   ->search({ foo => { like => 'bar' } });
1158
1159 =cut
1160
1161 sub search_like {
1162   my $class = shift;
1163   carp_unique (
1164     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1165    .' Instead use ->search({ x => { -like => "y%" } })'
1166    .' (note the outer pair of {}s - they are important!)'
1167   );
1168   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1169   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1170   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1171   return $class->search($query, { %$attrs });
1172 }
1173
1174 =head2 slice
1175
1176 =over 4
1177
1178 =item Arguments: $first, $last
1179
1180 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1181
1182 =back
1183
1184 Returns a resultset or object list representing a subset of elements from the
1185 resultset slice is called on. Indexes are from 0, i.e., to get the first
1186 three records, call:
1187
1188   my ($one, $two, $three) = $rs->slice(0, 2);
1189
1190 =cut
1191
1192 sub slice {
1193   my ($self, $min, $max) = @_;
1194   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1195   $attrs->{offset} = $self->{attrs}{offset} || 0;
1196   $attrs->{offset} += $min;
1197   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1198   return $self->search(undef, $attrs);
1199 }
1200
1201 =head2 next
1202
1203 =over 4
1204
1205 =item Arguments: none
1206
1207 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1208
1209 =back
1210
1211 Returns the next element in the resultset (C<undef> is there is none).
1212
1213 Can be used to efficiently iterate over records in the resultset:
1214
1215   my $rs = $schema->resultset('CD')->search;
1216   while (my $cd = $rs->next) {
1217     print $cd->title;
1218   }
1219
1220 Note that you need to store the resultset object, and call C<next> on it.
1221 Calling C<< resultset('Table')->next >> repeatedly will always return the
1222 first record from the resultset.
1223
1224 =cut
1225
1226 sub next {
1227   my ($self) = @_;
1228
1229   if (my $cache = $self->get_cache) {
1230     $self->{all_cache_position} ||= 0;
1231     return $cache->[$self->{all_cache_position}++];
1232   }
1233
1234   if ($self->{attrs}{cache}) {
1235     delete $self->{pager};
1236     $self->{all_cache_position} = 1;
1237     return ($self->all)[0];
1238   }
1239
1240   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1241
1242   $self->{_stashed_results} = $self->_construct_results
1243     or return undef;
1244
1245   return shift @{$self->{_stashed_results}};
1246 }
1247
1248 # Constructs as many results as it can in one pass while respecting
1249 # cursor laziness. Several modes of operation:
1250 #
1251 # * Always builds everything present in @{$self->{_stashed_rows}}
1252 # * If called with $fetch_all true - pulls everything off the cursor and
1253 #   builds all result structures (or objects) in one pass
1254 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1255 #   and if the resultset is ordered properly by the left side:
1256 #   * Fetches stuff off the cursor until the "master object" changes,
1257 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1258 #   OR
1259 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1260 #     was requested (there is no other way to collapse except for an
1261 #     eager cursor)
1262 # * If no collapse is requested - just get the next row, construct and
1263 #   return
1264 sub _construct_results {
1265   my ($self, $fetch_all) = @_;
1266
1267   my $rsrc = $self->result_source;
1268   my $attrs = $self->_resolved_attrs;
1269
1270   if (
1271     ! $fetch_all
1272       and
1273     ! $attrs->{order_by}
1274       and
1275     $attrs->{collapse}
1276       and
1277     my @pcols = $rsrc->primary_columns
1278   ) {
1279     # default order for collapsing unless the user asked for something
1280     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1281     $attrs->{_ordered_for_collapse} = 1;
1282     $attrs->{_order_is_artificial} = 1;
1283   }
1284
1285   # this will be used as both initial raw-row collector AND as a RV of
1286   # _construct_results. Not regrowing the array twice matters a lot...
1287   # a surprising amount actually
1288   my $rows = delete $self->{_stashed_rows};
1289
1290   my $cursor; # we may not need one at all
1291
1292   my $did_fetch_all = $fetch_all;
1293
1294   if ($fetch_all) {
1295     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1296     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1297   }
1298   elsif( $attrs->{collapse} ) {
1299
1300     # a cursor will need to be closed over in case of collapse
1301     $cursor = $self->cursor;
1302
1303     $attrs->{_ordered_for_collapse} = (
1304       (
1305         $attrs->{order_by}
1306           and
1307         $rsrc->schema
1308               ->storage
1309                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1310       ) ? 1 : 0
1311     ) unless defined $attrs->{_ordered_for_collapse};
1312
1313     if (! $attrs->{_ordered_for_collapse}) {
1314       $did_fetch_all = 1;
1315
1316       # instead of looping over ->next, use ->all in stealth mode
1317       # *without* calling a ->reset afterwards
1318       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1319       if (! $cursor->{_done}) {
1320         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1321         $cursor->{_done} = 1;
1322       }
1323     }
1324   }
1325
1326   if (! $did_fetch_all and ! @{$rows||[]} ) {
1327     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1328     $cursor ||= $self->cursor;
1329     if (scalar (my @r = $cursor->next) ) {
1330       $rows = [ \@r ];
1331     }
1332   }
1333
1334   return undef unless @{$rows||[]};
1335
1336   # sanity check - people are too clever for their own good
1337   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1338
1339     my $multiplied_selectors;
1340     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1341       if (
1342         $aliastypes->{multiplying}{$sel_alias}
1343           or
1344         $aliastypes->{premultiplied}{$sel_alias}
1345       ) {
1346         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1347       }
1348     }
1349
1350     for my $i (0 .. $#{$attrs->{as}} ) {
1351       my $sel = $attrs->{select}[$i];
1352
1353       if (ref $sel eq 'SCALAR') {
1354         $sel = $$sel;
1355       }
1356       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1357         $sel = $$sel->[0];
1358       }
1359
1360       $self->throw_exception(
1361         'Result collapse not possible - selection from a has_many source redirected to the main object'
1362       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1363     }
1364   }
1365
1366   # hotspot - skip the setter
1367   my $res_class = $self->_result_class;
1368
1369   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1370     $res_class->can ('inflate_result')
1371       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1372   };
1373
1374   my $infmap = $attrs->{as};
1375
1376   $self->{_result_inflator}{is_core_row} = ( (
1377     $inflator_cref
1378       ==
1379     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1380   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1381
1382   $self->{_result_inflator}{is_hri} = ( (
1383     ! $self->{_result_inflator}{is_core_row}
1384       and
1385     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1386   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1387
1388
1389   if ($attrs->{_simple_passthrough_construction}) {
1390     # construct a much simpler array->hash folder for the one-table HRI cases right here
1391     if ($self->{_result_inflator}{is_hri}) {
1392       for my $r (@$rows) {
1393         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1394       }
1395     }
1396     # FIXME SUBOPTIMAL this is a very very very hot spot
1397     # while rather optimal we can *still* do much better, by
1398     # building a smarter Row::inflate_result(), and
1399     # switch to feeding it data via a much leaner interface
1400     #
1401     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1402     # this particular resultset size
1403     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1404       for my $r (@$rows) {
1405         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1406       }
1407     }
1408     else {
1409       eval sprintf (
1410         ( $self->{_result_inflator}{is_core_row}
1411           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1412           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1413           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1414         ),
1415         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1416       );
1417     }
1418   }
1419   else {
1420     my $parser_type =
1421         $self->{_result_inflator}{is_hri}       ? 'hri'
1422       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1423       :                                           'classic_nonpruning'
1424     ;
1425
1426     unless( $self->{_row_parser}{$parser_type}{cref} ) {
1427
1428       # $args and $attrs to _mk_row_parser are separated to delineate what is
1429       # core collapser stuff and what is dbic $rs specific
1430       $self->{_row_parser}{$parser_type}{src} = $rsrc->_mk_row_parser({
1431         inflate_map => $infmap,
1432         collapse => $attrs->{collapse},
1433         premultiplied => $attrs->{_main_source_premultiplied},
1434         hri_style => $self->{_result_inflator}{is_hri},
1435         prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1436       }, $attrs);
1437
1438       $self->{_row_parser}{$parser_type}{cref} = do {
1439         package # hide form PAUSE
1440           DBIx::Class::__GENERATED_ROW_PARSER__;
1441
1442         eval $self->{_row_parser}{$parser_type}{src};
1443       } || die $@;
1444     }
1445
1446     # this needs to close over the *current* cursor, hence why it is not cached above
1447     my $next_cref = ($did_fetch_all or ! $attrs->{collapse})
1448       ? undef
1449       : sub {
1450         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1451         my @r = $cursor->next or return;
1452         \@r
1453       }
1454     ;
1455
1456     $self->{_row_parser}{$parser_type}{cref}->(
1457       $rows,
1458       $next_cref,
1459       ( $self->{_stashed_rows} = [] ),
1460       ( my $null_violations = {} ),
1461     );
1462
1463     $self->throw_exception(
1464       'Collapse aborted - the following columns are declared (or defaulted to) '
1465     . 'non-nullable within DBIC but NULLs were retrieved from storage: '
1466     . join( ', ', map { "'$infmap->[$_]'" } sort { $a <=> $b } keys %$null_violations )
1467     . ' within data row ' . dump_value({
1468       map {
1469         $infmap->[$_] =>
1470           ( ! defined $self->{_stashed_rows}[0][$_] or length $self->{_stashed_rows}[0][$_] < 50 )
1471             ? $self->{_stashed_rows}[0][$_]
1472             : substr( $self->{_stashed_rows}[0][$_], 0, 50 ) . '...'
1473       } 0 .. $#{$self->{_stashed_rows}[0]}
1474     })
1475     ) if keys %$null_violations;
1476
1477     # simple in-place substitution, does not regrow $rows
1478     if ($self->{_result_inflator}{is_core_row}) {
1479       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1480     }
1481     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1482     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1483       # the inflator may be a multiplier/reductor - put it in list ctx
1484       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1485     }
1486   }
1487
1488   # The @$rows check seems odd at first - why wouldn't we want to warn
1489   # regardless? The issue is things like find() etc, where the user
1490   # *knows* only one result will come back. In these cases the ->all
1491   # is not a pessimization, but rather something we actually want
1492   carp_unique(
1493     'Unable to properly collapse has_many results in iterator mode due '
1494   . 'to order criteria - performed an eager cursor slurp underneath. '
1495   . 'Consider using ->all() instead'
1496   ) if ( ! $fetch_all and @$rows > 1 );
1497
1498   return $rows;
1499 }
1500
1501 =head2 result_source
1502
1503 =over 4
1504
1505 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1506
1507 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1508
1509 =back
1510
1511 An accessor for the primary ResultSource object from which this ResultSet
1512 is derived.
1513
1514 =head2 result_class
1515
1516 =over 4
1517
1518 =item Arguments: $result_class?
1519
1520 =item Return Value: $result_class
1521
1522 =back
1523
1524 An accessor for the class to use when creating result objects. Defaults to
1525 C<< result_source->result_class >> - which in most cases is the name of the
1526 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1527
1528 Note that changing the result_class will also remove any components
1529 that were originally loaded in the source class via
1530 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1531 Any overloaded methods in the original source class will not run.
1532
1533 =cut
1534
1535 sub result_class {
1536   my ($self, $result_class) = @_;
1537   if ($result_class) {
1538
1539     # don't fire this for an object
1540     $self->ensure_class_loaded($result_class)
1541       unless ref($result_class);
1542
1543     if ($self->get_cache) {
1544       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1545     }
1546     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1547     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1548       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1549     }
1550
1551     $self->_result_class($result_class);
1552
1553     delete $self->{_result_inflator};
1554   }
1555   $self->_result_class;
1556 }
1557
1558 =head2 count
1559
1560 =over 4
1561
1562 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1563
1564 =item Return Value: $count
1565
1566 =back
1567
1568 Performs an SQL C<COUNT> with the same query as the resultset was built
1569 with to find the number of elements. Passing arguments is equivalent to
1570 C<< $rs->search ($cond, \%attrs)->count >>
1571
1572 =cut
1573
1574 sub count {
1575   my $self = shift;
1576   return $self->search(@_)->count if @_ and defined $_[0];
1577   return scalar @{ $self->get_cache } if $self->get_cache;
1578
1579   my $attrs = { %{ $self->_resolved_attrs } };
1580
1581   # this is a little optimization - it is faster to do the limit
1582   # adjustments in software, instead of a subquery
1583   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1584
1585   my $crs;
1586   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1587     $crs = $self->_count_subq_rs ($attrs);
1588   }
1589   else {
1590     $crs = $self->_count_rs ($attrs);
1591   }
1592   my $count = $crs->next;
1593
1594   $count -= $offset if $offset;
1595   $count = $rows if $rows and $rows < $count;
1596   $count = 0 if ($count < 0);
1597
1598   return $count;
1599 }
1600
1601 =head2 count_rs
1602
1603 =over 4
1604
1605 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1606
1607 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1608
1609 =back
1610
1611 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1612 This can be very handy for subqueries:
1613
1614   ->search( { amount => $some_rs->count_rs->as_query } )
1615
1616 As with regular resultsets the SQL query will be executed only after
1617 the resultset is accessed via L</next> or L</all>. That would return
1618 the same single value obtainable via L</count>.
1619
1620 =cut
1621
1622 sub count_rs {
1623   my $self = shift;
1624   return $self->search(@_)->count_rs if @_;
1625
1626   # this may look like a lack of abstraction (count() does about the same)
1627   # but in fact an _rs *must* use a subquery for the limits, as the
1628   # software based limiting can not be ported if this $rs is to be used
1629   # in a subquery itself (i.e. ->as_query)
1630   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1631     return $self->_count_subq_rs($self->{_attrs});
1632   }
1633   else {
1634     return $self->_count_rs($self->{_attrs});
1635   }
1636 }
1637
1638 #
1639 # returns a ResultSetColumn object tied to the count query
1640 #
1641 sub _count_rs {
1642   my ($self, $attrs) = @_;
1643
1644   my $rsrc = $self->result_source;
1645
1646   my $tmp_attrs = { %$attrs };
1647   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1648   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1649
1650   # overwrite the selector (supplied by the storage)
1651   $rsrc->resultset_class->new($rsrc, {
1652     %$tmp_attrs,
1653     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1654     as => 'count',
1655   })->get_column ('count');
1656 }
1657
1658 #
1659 # same as above but uses a subquery
1660 #
1661 sub _count_subq_rs {
1662   my ($self, $attrs) = @_;
1663
1664   my $rsrc = $self->result_source;
1665
1666   my $sub_attrs = { %$attrs };
1667   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1668   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1669
1670   # if we multi-prefetch we group_by something unique, as this is what we would
1671   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1672   if ( $attrs->{collapse}  ) {
1673     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1674       $rsrc->_identifying_column_set || $self->throw_exception(
1675         'Unable to construct a unique group_by criteria properly collapsing the '
1676       . 'has_many prefetch before count()'
1677       );
1678     } ]
1679   }
1680
1681   # Calculate subquery selector
1682   if (my $g = $sub_attrs->{group_by}) {
1683
1684     my $sql_maker = $rsrc->storage->sql_maker;
1685
1686     # necessary as the group_by may refer to aliased functions
1687     my $sel_index;
1688     for my $sel (@{$attrs->{select}}) {
1689       $sel_index->{$sel->{-as}} = $sel
1690         if (ref $sel eq 'HASH' and $sel->{-as});
1691     }
1692
1693     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1694     # also look for named aggregates referred in the having clause
1695     # having often contains scalarrefs - thus parse it out entirely
1696     my @parts = @$g;
1697     if ($attrs->{having}) {
1698       local $sql_maker->{having_bind};
1699       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1700       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1701       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1702         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1703         # if we don't unset it we screw up retarded but unfortunately working
1704         # 'MAX(foo.bar)' => { '>', 3 }
1705         $sql_maker->{name_sep} = '';
1706       }
1707
1708       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1709
1710       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1711       my %seen_having;
1712
1713       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1714       # and if all fails for an utterly naive quoted scalar-with-function
1715       while ($having_sql =~ /
1716         $rquote $sep $lquote (.+?) $rquote
1717           |
1718         [\s,] \w+ \. (\w+) [\s,]
1719           |
1720         [\s,] $lquote (.+?) $rquote [\s,]
1721       /gx) {
1722         my $part = $1 || $2 || $3;  # one of them matched if we got here
1723         unless ($seen_having{$part}++) {
1724           push @parts, $part;
1725         }
1726       }
1727     }
1728
1729     for (@parts) {
1730       my $colpiece = $sel_index->{$_} || $_;
1731
1732       # unqualify join-based group_by's. Arcane but possible query
1733       # also horrible horrible hack to alias a column (not a func.)
1734       # (probably need to introduce SQLA syntax)
1735       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1736         my $as = $colpiece;
1737         $as =~ s/\./__/;
1738         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1739       }
1740       push @{$sub_attrs->{select}}, $colpiece;
1741     }
1742   }
1743   else {
1744     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1745     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1746   }
1747
1748   return $rsrc->resultset_class
1749                ->new ($rsrc, $sub_attrs)
1750                 ->as_subselect_rs
1751                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1752                   ->get_column ('count');
1753 }
1754
1755
1756 =head2 count_literal
1757
1758 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1759 should only be used in that context. See L</search_literal> for further info.
1760
1761 =over 4
1762
1763 =item Arguments: $sql_fragment, @standalone_bind_values
1764
1765 =item Return Value: $count
1766
1767 =back
1768
1769 Counts the results in a literal query. Equivalent to calling L</search_literal>
1770 with the passed arguments, then L</count>.
1771
1772 =cut
1773
1774 sub count_literal { shift->search_literal(@_)->count; }
1775
1776 =head2 all
1777
1778 =over 4
1779
1780 =item Arguments: none
1781
1782 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1783
1784 =back
1785
1786 Returns all elements in the resultset.
1787
1788 =cut
1789
1790 sub all {
1791   my $self = shift;
1792   if(@_) {
1793     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1794   }
1795
1796   delete @{$self}{qw/_stashed_rows _stashed_results/};
1797
1798   if (my $c = $self->get_cache) {
1799     return @$c;
1800   }
1801
1802   $self->cursor->reset;
1803
1804   my $objs = $self->_construct_results('fetch_all') || [];
1805
1806   $self->set_cache($objs) if $self->{attrs}{cache};
1807
1808   return @$objs;
1809 }
1810
1811 =head2 reset
1812
1813 =over 4
1814
1815 =item Arguments: none
1816
1817 =item Return Value: $self
1818
1819 =back
1820
1821 Resets the resultset's cursor, so you can iterate through the elements again.
1822 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1823 another query.
1824
1825 =cut
1826
1827 sub reset {
1828   my ($self) = @_;
1829
1830   delete @{$self}{qw/_stashed_rows _stashed_results/};
1831   $self->{all_cache_position} = 0;
1832   $self->cursor->reset;
1833   return $self;
1834 }
1835
1836 =head2 first
1837
1838 =over 4
1839
1840 =item Arguments: none
1841
1842 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1843
1844 =back
1845
1846 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1847 an object for the first result (or C<undef> if the resultset is empty).
1848
1849 =cut
1850
1851 sub first {
1852   return $_[0]->reset->next;
1853 }
1854
1855
1856 # _rs_update_delete
1857 #
1858 # Determines whether and what type of subquery is required for the $rs operation.
1859 # If grouping is necessary either supplies its own, or verifies the current one
1860 # After all is done delegates to the proper storage method.
1861
1862 sub _rs_update_delete {
1863   my ($self, $op, $values) = @_;
1864
1865   my $rsrc = $self->result_source;
1866   my $storage = $rsrc->schema->storage;
1867
1868   my $attrs = { %{$self->_resolved_attrs} };
1869
1870   my $join_classifications;
1871   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1872
1873   # do we need a subquery for any reason?
1874   my $needs_subq = (
1875     defined $existing_group_by
1876       or
1877     # if {from} is unparseable wrap a subq
1878     ref($attrs->{from}) ne 'ARRAY'
1879       or
1880     # limits call for a subq
1881     $self->_has_resolved_attr(qw/rows offset/)
1882   );
1883
1884   # simplify the joinmap, so we can further decide if a subq is necessary
1885   if (!$needs_subq and @{$attrs->{from}} > 1) {
1886
1887     ($attrs->{from}, $join_classifications) =
1888       $storage->_prune_unused_joins ($attrs);
1889
1890     # any non-pruneable non-local restricting joins imply subq
1891     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1892   }
1893
1894   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1895   $needs_subq ||= (
1896     (ref $attrs->{from}[0]) ne 'HASH'
1897       or
1898     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1899   );
1900
1901   my ($cond, $guard);
1902   # do we need anything like a subquery?
1903   if (! $needs_subq) {
1904     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1905     # a condition containing 'me' or other table prefixes will not work
1906     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1907     $cond = do {
1908       my $sqla = $rsrc->storage->sql_maker;
1909       local $sqla->{_dequalify_idents} = 1;
1910       \[ $sqla->_recurse_where($self->{cond}) ];
1911     };
1912   }
1913   else {
1914     # we got this far - means it is time to wrap a subquery
1915     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1916       sprintf(
1917         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1918         $op,
1919         $rsrc->source_name,
1920       )
1921     );
1922
1923     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1924     delete $attrs->{$_} for qw/select as collapse/;
1925     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1926
1927     # this will be consumed by the pruner waaaaay down the stack
1928     $attrs->{_force_prune_multiplying_joins} = 1;
1929
1930     my $subrs = (ref $self)->new($rsrc, $attrs);
1931
1932     if (@$idcols == 1) {
1933       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1934     }
1935     elsif ($storage->_use_multicolumn_in) {
1936       # no syntax for calling this properly yet
1937       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1938       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1939         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1940         $subrs->as_query
1941       ),
1942     }
1943     else {
1944       # if all else fails - get all primary keys and operate over a ORed set
1945       # wrap in a transaction for consistency
1946       # this is where the group_by/multiplication starts to matter
1947       if (
1948         $existing_group_by
1949           or
1950         # we do not need to check pre-multipliers, since if the premulti is there, its
1951         # parent (who is multi) will be there too
1952         keys %{ $join_classifications->{multiplying} || {} }
1953       ) {
1954         # make sure if there is a supplied group_by it matches the columns compiled above
1955         # perfectly. Anything else can not be sanely executed on most databases so croak
1956         # right then and there
1957         if ($existing_group_by) {
1958           my @current_group_by = map
1959             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1960             @$existing_group_by
1961           ;
1962
1963           if (
1964             join ("\x00", sort @current_group_by)
1965               ne
1966             join ("\x00", sort @{$attrs->{columns}} )
1967           ) {
1968             $self->throw_exception (
1969               "You have just attempted a $op operation on a resultset which does group_by"
1970               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1971               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1972               . ' kind of queries. Please retry the operation with a modified group_by or'
1973               . ' without using one at all.'
1974             );
1975           }
1976         }
1977
1978         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1979       }
1980
1981       $guard = $storage->txn_scope_guard;
1982
1983       for my $row ($subrs->cursor->all) {
1984         push @$cond, { map
1985           { $idcols->[$_] => $row->[$_] }
1986           (0 .. $#$idcols)
1987         };
1988       }
1989     }
1990   }
1991
1992   my $res = $cond ? $storage->$op (
1993     $rsrc,
1994     $op eq 'update' ? $values : (),
1995     $cond,
1996   ) : '0E0';
1997
1998   $guard->commit if $guard;
1999
2000   return $res;
2001 }
2002
2003 =head2 update
2004
2005 =over 4
2006
2007 =item Arguments: \%values
2008
2009 =item Return Value: $underlying_storage_rv
2010
2011 =back
2012
2013 Sets the specified columns in the resultset to the supplied values in a
2014 single query. Note that this will not run any accessor/set_column/update
2015 triggers, nor will it update any result object instances derived from this
2016 resultset (this includes the contents of the L<resultset cache|/set_cache>
2017 if any). See L</update_all> if you need to execute any on-update
2018 triggers or cascades defined either by you or a
2019 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2020
2021 The return value is a pass through of what the underlying
2022 storage backend returned, and may vary. See L<DBI/execute> for the most
2023 common case.
2024
2025 =head3 CAVEAT
2026
2027 Note that L</update> does not process/deflate any of the values passed in.
2028 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2029 ensure manually that any value passed to this method will stringify to
2030 something the RDBMS knows how to deal with. A notable example is the
2031 handling of L<DateTime> objects, for more info see:
2032 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2033
2034 =cut
2035
2036 sub update {
2037   my ($self, $values) = @_;
2038   $self->throw_exception('Values for update must be a hash')
2039     unless ref $values eq 'HASH';
2040
2041   return $self->_rs_update_delete ('update', $values);
2042 }
2043
2044 =head2 update_all
2045
2046 =over 4
2047
2048 =item Arguments: \%values
2049
2050 =item Return Value: 1
2051
2052 =back
2053
2054 Fetches all objects and updates them one at a time via
2055 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2056 triggers, while L</update> will not.
2057
2058 =cut
2059
2060 sub update_all {
2061   my ($self, $values) = @_;
2062   $self->throw_exception('Values for update_all must be a hash')
2063     unless ref $values eq 'HASH';
2064
2065   my $guard = $self->result_source->schema->txn_scope_guard;
2066   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2067   $guard->commit;
2068   return 1;
2069 }
2070
2071 =head2 delete
2072
2073 =over 4
2074
2075 =item Arguments: none
2076
2077 =item Return Value: $underlying_storage_rv
2078
2079 =back
2080
2081 Deletes the rows matching this resultset in a single query. Note that this
2082 will not run any delete triggers, nor will it alter the
2083 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2084 derived from this resultset (this includes the contents of the
2085 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2086 execute any on-delete triggers or cascades defined either by you or a
2087 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2088
2089 The return value is a pass through of what the underlying storage backend
2090 returned, and may vary. See L<DBI/execute> for the most common case.
2091
2092 =cut
2093
2094 sub delete {
2095   my $self = shift;
2096   $self->throw_exception('delete does not accept any arguments')
2097     if @_;
2098
2099   return $self->_rs_update_delete ('delete');
2100 }
2101
2102 =head2 delete_all
2103
2104 =over 4
2105
2106 =item Arguments: none
2107
2108 =item Return Value: 1
2109
2110 =back
2111
2112 Fetches all objects and deletes them one at a time via
2113 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2114 triggers, while L</delete> will not.
2115
2116 =cut
2117
2118 sub delete_all {
2119   my $self = shift;
2120   $self->throw_exception('delete_all does not accept any arguments')
2121     if @_;
2122
2123   my $guard = $self->result_source->schema->txn_scope_guard;
2124   $_->delete for $self->all;
2125   $guard->commit;
2126   return 1;
2127 }
2128
2129 =head2 populate
2130
2131 =over 4
2132
2133 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2134
2135 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2136
2137 =back
2138
2139 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2140 arrayrefs.
2141
2142 =over
2143
2144 =item NOTE
2145
2146 The context of this method call has an important effect on what is
2147 submitted to storage. In void context data is fed directly to fastpath
2148 insertion routines provided by the underlying storage (most often
2149 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2150 L<insert|DBIx::Class::Row/insert> calls on the
2151 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2152 augmentation of these methods provided by components. For example if you
2153 are using something like L<DBIx::Class::UUIDColumns> to create primary
2154 keys for you, you will find that your PKs are empty.  In this case you
2155 will have to explicitly force scalar or list context in order to create
2156 those values.
2157
2158 =back
2159
2160 In non-void (scalar or list) context, this method is simply a wrapper
2161 for L</create>. Depending on list or scalar context either a list of
2162 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2163 containing these objects is returned.
2164
2165 When supplying data in "arrayref of arrayrefs" invocation style, the
2166 first element should be a list of column names and each subsequent
2167 element should be a data value in the earlier specified column order.
2168 For example:
2169
2170   $schema->resultset("Artist")->populate([
2171     [ qw( artistid name ) ],
2172     [ 100, 'A Formally Unknown Singer' ],
2173     [ 101, 'A singer that jumped the shark two albums ago' ],
2174     [ 102, 'An actually cool singer' ],
2175   ]);
2176
2177 For the arrayref of hashrefs style each hashref should be a structure
2178 suitable for passing to L</create>. Multi-create is also permitted with
2179 this syntax.
2180
2181   $schema->resultset("Artist")->populate([
2182      { artistid => 4, name => 'Manufactured Crap', cds => [
2183         { title => 'My First CD', year => 2006 },
2184         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2185       ],
2186      },
2187      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2188         { title => 'My parents sold me to a record company', year => 2005 },
2189         { title => 'Why Am I So Ugly?', year => 2006 },
2190         { title => 'I Got Surgery and am now Popular', year => 2007 }
2191       ],
2192      },
2193   ]);
2194
2195 If you attempt a void-context multi-create as in the example above (each
2196 Artist also has the related list of CDs), and B<do not> supply the
2197 necessary autoinc foreign key information, this method will proxy to the
2198 less efficient L</create>, and then throw the Result objects away. In this
2199 case there are obviously no benefits to using this method over L</create>.
2200
2201 =cut
2202
2203 sub populate {
2204   my $self = shift;
2205
2206   # this is naive and just a quick check
2207   # the types will need to be checked more thoroughly when the
2208   # multi-source populate gets added
2209   my $data = (
2210     ref $_[0] eq 'ARRAY'
2211       and
2212     ( @{$_[0]} or return )
2213       and
2214     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2215       and
2216     $_[0]
2217   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2218
2219   # FIXME - no cref handling
2220   # At this point assume either hashes or arrays
2221
2222   if(defined wantarray) {
2223     my (@results, $guard);
2224
2225     if (ref $data->[0] eq 'ARRAY') {
2226       # column names only, nothing to do
2227       return if @$data == 1;
2228
2229       $guard = $self->result_source->schema->storage->txn_scope_guard
2230         if @$data > 2;
2231
2232       @results = map
2233         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2234         @{$data}[1 .. $#$data]
2235       ;
2236     }
2237     else {
2238
2239       $guard = $self->result_source->schema->storage->txn_scope_guard
2240         if @$data > 1;
2241
2242       @results = map { $self->new_result($_)->insert } @$data;
2243     }
2244
2245     $guard->commit if $guard;
2246     return wantarray ? @results : \@results;
2247   }
2248
2249   # we have to deal with *possibly incomplete* related data
2250   # this means we have to walk the data structure twice
2251   # whether we want this or not
2252   # jnap, I hate you ;)
2253   my $rsrc = $self->result_source;
2254   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2255
2256   my ($colinfo, $colnames, $slices_with_rels);
2257   my $data_start = 0;
2258
2259   DATA_SLICE:
2260   for my $i (0 .. $#$data) {
2261
2262     my $current_slice_seen_rel_infos;
2263
2264 ### Determine/Supplement collists
2265 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2266     if( ref $data->[$i] eq 'ARRAY' ) {
2267
2268       # positional(!) explicit column list
2269       if ($i == 0) {
2270         # column names only, nothing to do
2271         return if @$data == 1;
2272
2273         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2274           for 0 .. $#{$data->[0]};
2275
2276         $data_start = 1;
2277
2278         next DATA_SLICE;
2279       }
2280       else {
2281         for (values %$colinfo) {
2282           if ($_->{is_rel} ||= (
2283             $rel_info->{$_->{name}}
2284               and
2285             (
2286               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2287                 or
2288               ref $data->[$i][$_->{pos}] eq 'HASH'
2289                 or
2290               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2291             )
2292               and
2293             1
2294           )) {
2295
2296             # moar sanity check... sigh
2297             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2298               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2299                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2300                 return my $throwaway = $self->populate(@_);
2301               }
2302             }
2303
2304             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2305           }
2306         }
2307       }
2308
2309      if ($current_slice_seen_rel_infos) {
2310         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2311
2312         # this is needed further down to decide whether or not to fallback to create()
2313         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2314           for 0 .. $#$colnames;
2315       }
2316     }
2317     elsif( ref $data->[$i] eq 'HASH' ) {
2318
2319       for ( sort keys %{$data->[$i]} ) {
2320
2321         $colinfo->{$_} ||= do {
2322
2323           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2324             if $data_start; # it will be 0 on AoH, 1 on AoA
2325
2326           push @$colnames, $_;
2327
2328           # RV
2329           { pos => $#$colnames, name => $_ }
2330         };
2331
2332         if ($colinfo->{$_}{is_rel} ||= (
2333           $rel_info->{$_}
2334             and
2335           (
2336             ref $data->[$i]{$_} eq 'ARRAY'
2337               or
2338             ref $data->[$i]{$_} eq 'HASH'
2339               or
2340             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2341           )
2342             and
2343           1
2344         )) {
2345
2346           # moar sanity check... sigh
2347           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2348             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2349               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2350               return my $throwaway = $self->populate(@_);
2351             }
2352           }
2353
2354           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2355         }
2356       }
2357
2358       if ($current_slice_seen_rel_infos) {
2359         push @$slices_with_rels, $data->[$i];
2360
2361         # this is needed further down to decide whether or not to fallback to create()
2362         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2363           for keys %{$data->[$i]};
2364       }
2365     }
2366     else {
2367       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2368     }
2369
2370     if ( grep
2371       { $_->{attrs}{is_depends_on} }
2372       @{ $current_slice_seen_rel_infos || [] }
2373     ) {
2374       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2375       return my $throwaway = $self->populate(@_);
2376     }
2377   }
2378
2379   if( $slices_with_rels ) {
2380
2381     # need to exclude the rel "columns"
2382     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2383
2384     # extra sanity check - ensure the main source is in fact identifiable
2385     # the localizing of nullability is insane, but oh well... the use-case is legit
2386     my $ci = $rsrc->columns_info($colnames);
2387
2388     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2389       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2390
2391     unless( $rsrc->_identifying_column_set($ci) ) {
2392       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2393       return my $throwaway = $self->populate(@_);
2394     }
2395   }
2396
2397 ### inherit the data locked in the conditions of the resultset
2398   my ($rs_data) = $self->_merge_with_rscond({});
2399   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2400
2401   # if anything left - decompose rs_data
2402   my $rs_data_vals;
2403   if (keys %$rs_data) {
2404      push @$rs_data_vals, $rs_data->{$_}
2405       for sort keys %$rs_data;
2406   }
2407
2408 ### start work
2409   my $guard;
2410   $guard = $rsrc->schema->storage->txn_scope_guard
2411     if $slices_with_rels;
2412
2413 ### main source data
2414   # FIXME - need to switch entirely to a coderef-based thing,
2415   # so that large sets aren't copied several times... I think
2416   $rsrc->storage->_insert_bulk(
2417     $rsrc,
2418     [ @$colnames, sort keys %$rs_data ],
2419     [ map {
2420       ref $data->[$_] eq 'ARRAY'
2421       ? (
2422           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2423         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2424         :                     $data->[$_]
2425       )
2426       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2427     } $data_start .. $#$data ],
2428   );
2429
2430 ### do the children relationships
2431   if ( $slices_with_rels ) {
2432     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2433       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2434
2435     for my $sl (@$slices_with_rels) {
2436
2437       my ($main_proto, $main_proto_rs);
2438       for my $rel (@rels) {
2439         next unless defined $sl->{$rel};
2440
2441         $main_proto ||= {
2442           %$rs_data,
2443           (map { $_ => $sl->{$_} } @$colnames),
2444         };
2445
2446         unless (defined $colinfo->{$rel}{rs}) {
2447
2448           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2449
2450           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2451             rel_name => $rel,
2452             self_alias => "\xFE", # irrelevant
2453             foreign_alias => "\xFF", # irrelevant
2454           )->{identity_map} || {} } };
2455
2456         }
2457
2458         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2459           {
2460             $_ => { '=' =>
2461               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2462                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2463                  ->as_query
2464             }
2465           }
2466           keys %{$colinfo->{$rel}{fk_map}}
2467         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2468
2469         1;
2470       }
2471     }
2472   }
2473
2474   $guard->commit if $guard;
2475 }
2476
2477 =head2 pager
2478
2479 =over 4
2480
2481 =item Arguments: none
2482
2483 =item Return Value: L<$pager|Data::Page>
2484
2485 =back
2486
2487 Returns a L<Data::Page> object for the current resultset. Only makes
2488 sense for queries with a C<page> attribute.
2489
2490 To get the full count of entries for a paged resultset, call
2491 C<total_entries> on the L<Data::Page> object.
2492
2493 =cut
2494
2495 sub pager {
2496   my ($self) = @_;
2497
2498   return $self->{pager} if $self->{pager};
2499
2500   my $attrs = $self->{attrs};
2501   if (!defined $attrs->{page}) {
2502     $self->throw_exception("Can't create pager for non-paged rs");
2503   }
2504   elsif ($attrs->{page} <= 0) {
2505     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2506   }
2507   $attrs->{rows} ||= 10;
2508
2509   # throw away the paging flags and re-run the count (possibly
2510   # with a subselect) to get the real total count
2511   my $count_attrs = { %$attrs };
2512   delete @{$count_attrs}{qw/rows offset page pager/};
2513
2514   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2515
2516   require DBIx::Class::ResultSet::Pager;
2517   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2518     sub { $total_rs->count },  #lazy-get the total
2519     $attrs->{rows},
2520     $self->{attrs}{page},
2521   );
2522 }
2523
2524 =head2 page
2525
2526 =over 4
2527
2528 =item Arguments: $page_number
2529
2530 =item Return Value: L<$resultset|/search>
2531
2532 =back
2533
2534 Returns a resultset for the $page_number page of the resultset on which page
2535 is called, where each page contains a number of rows equal to the 'rows'
2536 attribute set on the resultset (10 by default).
2537
2538 =cut
2539
2540 sub page {
2541   my ($self, $page) = @_;
2542   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2543 }
2544
2545 =head2 new_result
2546
2547 =over 4
2548
2549 =item Arguments: \%col_data
2550
2551 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2552
2553 =back
2554
2555 Creates a new result object in the resultset's result class and returns
2556 it. The row is not inserted into the database at this point, call
2557 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2558 will tell you whether the result object has been inserted or not.
2559
2560 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2561
2562 =cut
2563
2564 sub new_result {
2565   my ($self, $values) = @_;
2566
2567   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2568     if @_ > 2;
2569
2570   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2571     unless (ref $values eq 'HASH');
2572
2573   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2574
2575   my $new = $self->result_class->new({
2576     %$merged_cond,
2577     ( @$cols_from_relations
2578       ? (-cols_from_relations => $cols_from_relations)
2579       : ()
2580     ),
2581     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2582   });
2583
2584   if (
2585     reftype($new) eq 'HASH'
2586       and
2587     ! keys %$new
2588       and
2589     blessed($new)
2590   ) {
2591     carp_unique (sprintf (
2592       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2593       $self->result_class,
2594     ));
2595   }
2596
2597   $new;
2598 }
2599
2600 # _merge_with_rscond
2601 #
2602 # Takes a simple hash of K/V data and returns its copy merged with the
2603 # condition already present on the resultset. Additionally returns an
2604 # arrayref of value/condition names, which were inferred from related
2605 # objects (this is needed for in-memory related objects)
2606 sub _merge_with_rscond {
2607   my ($self, $data) = @_;
2608
2609   my ($implied_data, @cols_from_relations);
2610
2611   my $alias = $self->{attrs}{alias};
2612
2613   if (! defined $self->{cond}) {
2614     # just massage $data below
2615   }
2616   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2617     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2618     @cols_from_relations = keys %{ $implied_data || {} };
2619   }
2620   else {
2621     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2622     $implied_data = { map {
2623       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2624     } keys %$eqs };
2625   }
2626
2627   return (
2628     { map
2629       { %{ $self->_remove_alias($_, $alias) } }
2630       # precedence must be given to passed values over values inherited from
2631       # the cond, so the order here is important.
2632       ( $implied_data||(), $data)
2633     },
2634     \@cols_from_relations
2635   );
2636 }
2637
2638 # _has_resolved_attr
2639 #
2640 # determines if the resultset defines at least one
2641 # of the attributes supplied
2642 #
2643 # used to determine if a subquery is necessary
2644 #
2645 # supports some virtual attributes:
2646 #   -join
2647 #     This will scan for any joins being present on the resultset.
2648 #     It is not a mere key-search but a deep inspection of {from}
2649 #
2650
2651 sub _has_resolved_attr {
2652   my ($self, @attr_names) = @_;
2653
2654   my $attrs = $self->_resolved_attrs;
2655
2656   my %extra_checks;
2657
2658   for my $n (@attr_names) {
2659     if (grep { $n eq $_ } (qw/-join/) ) {
2660       $extra_checks{$n}++;
2661       next;
2662     }
2663
2664     my $attr =  $attrs->{$n};
2665
2666     next if not defined $attr;
2667
2668     if (ref $attr eq 'HASH') {
2669       return 1 if keys %$attr;
2670     }
2671     elsif (ref $attr eq 'ARRAY') {
2672       return 1 if @$attr;
2673     }
2674     else {
2675       return 1 if $attr;
2676     }
2677   }
2678
2679   # a resolved join is expressed as a multi-level from
2680   return 1 if (
2681     $extra_checks{-join}
2682       and
2683     ref $attrs->{from} eq 'ARRAY'
2684       and
2685     @{$attrs->{from}} > 1
2686   );
2687
2688   return 0;
2689 }
2690
2691 # _remove_alias
2692 #
2693 # Remove the specified alias from the specified query hash. A copy is made so
2694 # the original query is not modified.
2695
2696 sub _remove_alias {
2697   my ($self, $query, $alias) = @_;
2698
2699   my %orig = %{ $query || {} };
2700   my %unaliased;
2701
2702   foreach my $key (keys %orig) {
2703     if ($key !~ /\./) {
2704       $unaliased{$key} = $orig{$key};
2705       next;
2706     }
2707     $unaliased{$1} = $orig{$key}
2708       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2709   }
2710
2711   return \%unaliased;
2712 }
2713
2714 =head2 as_query
2715
2716 =over 4
2717
2718 =item Arguments: none
2719
2720 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2721
2722 =back
2723
2724 Returns the SQL query and bind vars associated with the invocant.
2725
2726 This is generally used as the RHS for a subquery.
2727
2728 =cut
2729
2730 sub as_query {
2731   my $self = shift;
2732
2733   my $attrs = { %{ $self->_resolved_attrs } };
2734
2735   my $aq = $self->result_source->storage->_select_args_to_query (
2736     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2737   );
2738
2739   $aq;
2740 }
2741
2742 =head2 find_or_new
2743
2744 =over 4
2745
2746 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2747
2748 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2749
2750 =back
2751
2752   my $artist = $schema->resultset('Artist')->find_or_new(
2753     { artist => 'fred' }, { key => 'artists' });
2754
2755   $cd->cd_to_producer->find_or_new({ producer => $producer },
2756                                    { key => 'primary' });
2757
2758 Find an existing record from this resultset using L</find>. if none exists,
2759 instantiate a new result object and return it. The object will not be saved
2760 into your storage until you call L<DBIx::Class::Row/insert> on it.
2761
2762 You most likely want this method when looking for existing rows using a unique
2763 constraint that is not the primary key, or looking for related rows.
2764
2765 If you want objects to be saved immediately, use L</find_or_create> instead.
2766
2767 B<Note>: Make sure to read the documentation of L</find> and understand the
2768 significance of the C<key> attribute, as its lack may skew your search, and
2769 subsequently result in spurious new objects.
2770
2771 B<Note>: Take care when using C<find_or_new> with a table having
2772 columns with default values that you intend to be automatically
2773 supplied by the database (e.g. an auto_increment primary key column).
2774 In normal usage, the value of such columns should NOT be included at
2775 all in the call to C<find_or_new>, even when set to C<undef>.
2776
2777 =cut
2778
2779 sub find_or_new {
2780   my $self     = shift;
2781   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2782   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2783   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2784     return $row;
2785   }
2786   return $self->new_result($hash);
2787 }
2788
2789 =head2 create
2790
2791 =over 4
2792
2793 =item Arguments: \%col_data
2794
2795 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2796
2797 =back
2798
2799 Attempt to create a single new row or a row with multiple related rows
2800 in the table represented by the resultset (and related tables). This
2801 will not check for duplicate rows before inserting, use
2802 L</find_or_create> to do that.
2803
2804 To create one row for this resultset, pass a hashref of key/value
2805 pairs representing the columns of the table and the values you wish to
2806 store. If the appropriate relationships are set up, foreign key fields
2807 can also be passed an object representing the foreign row, and the
2808 value will be set to its primary key.
2809
2810 To create related objects, pass a hashref of related-object column values
2811 B<keyed on the relationship name>. If the relationship is of type C<multi>
2812 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2813 The process will correctly identify columns holding foreign keys, and will
2814 transparently populate them from the keys of the corresponding relation.
2815 This can be applied recursively, and will work correctly for a structure
2816 with an arbitrary depth and width, as long as the relationships actually
2817 exists and the correct column data has been supplied.
2818
2819 Instead of hashrefs of plain related data (key/value pairs), you may
2820 also pass new or inserted objects. New objects (not inserted yet, see
2821 L</new_result>), will be inserted into their appropriate tables.
2822
2823 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2824
2825 Example of creating a new row.
2826
2827   $person_rs->create({
2828     name=>"Some Person",
2829     email=>"somebody@someplace.com"
2830   });
2831
2832 Example of creating a new row and also creating rows in a related C<has_many>
2833 or C<has_one> resultset.  Note Arrayref.
2834
2835   $artist_rs->create(
2836      { artistid => 4, name => 'Manufactured Crap', cds => [
2837         { title => 'My First CD', year => 2006 },
2838         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2839       ],
2840      },
2841   );
2842
2843 Example of creating a new row and also creating a row in a related
2844 C<belongs_to> resultset. Note Hashref.
2845
2846   $cd_rs->create({
2847     title=>"Music for Silly Walks",
2848     year=>2000,
2849     artist => {
2850       name=>"Silly Musician",
2851     }
2852   });
2853
2854 =over
2855
2856 =item WARNING
2857
2858 When subclassing ResultSet never attempt to override this method. Since
2859 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2860 lot of the internals simply never call it, so your override will be
2861 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2862 or L<DBIx::Class::Row/insert> depending on how early in the
2863 L</create> process you need to intervene. See also warning pertaining to
2864 L</new>.
2865
2866 =back
2867
2868 =cut
2869
2870 sub create {
2871   #my ($self, $col_data) = @_;
2872   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2873   return shift->new_result(shift)->insert;
2874 }
2875
2876 =head2 find_or_create
2877
2878 =over 4
2879
2880 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2881
2882 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2883
2884 =back
2885
2886   $cd->cd_to_producer->find_or_create({ producer => $producer },
2887                                       { key => 'primary' });
2888
2889 Tries to find a record based on its primary key or unique constraints; if none
2890 is found, creates one and returns that instead.
2891
2892   my $cd = $schema->resultset('CD')->find_or_create({
2893     cdid   => 5,
2894     artist => 'Massive Attack',
2895     title  => 'Mezzanine',
2896     year   => 2005,
2897   });
2898
2899 Also takes an optional C<key> attribute, to search by a specific key or unique
2900 constraint. For example:
2901
2902   my $cd = $schema->resultset('CD')->find_or_create(
2903     {
2904       artist => 'Massive Attack',
2905       title  => 'Mezzanine',
2906     },
2907     { key => 'cd_artist_title' }
2908   );
2909
2910 B<Note>: Make sure to read the documentation of L</find> and understand the
2911 significance of the C<key> attribute, as its lack may skew your search, and
2912 subsequently result in spurious row creation.
2913
2914 B<Note>: Because find_or_create() reads from the database and then
2915 possibly inserts based on the result, this method is subject to a race
2916 condition. Another process could create a record in the table after
2917 the find has completed and before the create has started. To avoid
2918 this problem, use find_or_create() inside a transaction.
2919
2920 B<Note>: Take care when using C<find_or_create> with a table having
2921 columns with default values that you intend to be automatically
2922 supplied by the database (e.g. an auto_increment primary key column).
2923 In normal usage, the value of such columns should NOT be included at
2924 all in the call to C<find_or_create>, even when set to C<undef>.
2925
2926 See also L</find> and L</update_or_create>. For information on how to declare
2927 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2928
2929 If you need to know if an existing row was found or a new one created use
2930 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2931 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2932 database!
2933
2934   my $cd = $schema->resultset('CD')->find_or_new({
2935     cdid   => 5,
2936     artist => 'Massive Attack',
2937     title  => 'Mezzanine',
2938     year   => 2005,
2939   });
2940
2941   if( !$cd->in_storage ) {
2942       # do some stuff
2943       $cd->insert;
2944   }
2945
2946 =cut
2947
2948 sub find_or_create {
2949   my $self     = shift;
2950   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2951   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2952   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2953     return $row;
2954   }
2955   return $self->new_result($hash)->insert;
2956 }
2957
2958 =head2 update_or_create
2959
2960 =over 4
2961
2962 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2963
2964 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2965
2966 =back
2967
2968   $resultset->update_or_create({ col => $val, ... });
2969
2970 Like L</find_or_create>, but if a row is found it is immediately updated via
2971 C<< $found_row->update (\%col_data) >>.
2972
2973
2974 Takes an optional C<key> attribute to search on a specific unique constraint.
2975 For example:
2976
2977   # In your application
2978   my $cd = $schema->resultset('CD')->update_or_create(
2979     {
2980       artist => 'Massive Attack',
2981       title  => 'Mezzanine',
2982       year   => 1998,
2983     },
2984     { key => 'cd_artist_title' }
2985   );
2986
2987   $cd->cd_to_producer->update_or_create({
2988     producer => $producer,
2989     name => 'harry',
2990   }, {
2991     key => 'primary',
2992   });
2993
2994 B<Note>: Make sure to read the documentation of L</find> and understand the
2995 significance of the C<key> attribute, as its lack may skew your search, and
2996 subsequently result in spurious row creation.
2997
2998 B<Note>: Take care when using C<update_or_create> with a table having
2999 columns with default values that you intend to be automatically
3000 supplied by the database (e.g. an auto_increment primary key column).
3001 In normal usage, the value of such columns should NOT be included at
3002 all in the call to C<update_or_create>, even when set to C<undef>.
3003
3004 See also L</find> and L</find_or_create>. For information on how to declare
3005 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3006
3007 If you need to know if an existing row was updated or a new one created use
3008 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3009 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3010 database!
3011
3012 =cut
3013
3014 sub update_or_create {
3015   my $self = shift;
3016   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3017   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3018
3019   my $row = $self->find($cond, $attrs);
3020   if (defined $row) {
3021     $row->update($cond);
3022     return $row;
3023   }
3024
3025   return $self->new_result($cond)->insert;
3026 }
3027
3028 =head2 update_or_new
3029
3030 =over 4
3031
3032 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3033
3034 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3035
3036 =back
3037
3038   $resultset->update_or_new({ col => $val, ... });
3039
3040 Like L</find_or_new> but if a row is found it is immediately updated via
3041 C<< $found_row->update (\%col_data) >>.
3042
3043 For example:
3044
3045   # In your application
3046   my $cd = $schema->resultset('CD')->update_or_new(
3047     {
3048       artist => 'Massive Attack',
3049       title  => 'Mezzanine',
3050       year   => 1998,
3051     },
3052     { key => 'cd_artist_title' }
3053   );
3054
3055   if ($cd->in_storage) {
3056       # the cd was updated
3057   }
3058   else {
3059       # the cd is not yet in the database, let's insert it
3060       $cd->insert;
3061   }
3062
3063 B<Note>: Make sure to read the documentation of L</find> and understand the
3064 significance of the C<key> attribute, as its lack may skew your search, and
3065 subsequently result in spurious new objects.
3066
3067 B<Note>: Take care when using C<update_or_new> with a table having
3068 columns with default values that you intend to be automatically
3069 supplied by the database (e.g. an auto_increment primary key column).
3070 In normal usage, the value of such columns should NOT be included at
3071 all in the call to C<update_or_new>, even when set to C<undef>.
3072
3073 See also L</find>, L</find_or_create> and L</find_or_new>.
3074
3075 =cut
3076
3077 sub update_or_new {
3078     my $self  = shift;
3079     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3080     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3081
3082     my $row = $self->find( $cond, $attrs );
3083     if ( defined $row ) {
3084         $row->update($cond);
3085         return $row;
3086     }
3087
3088     return $self->new_result($cond);
3089 }
3090
3091 =head2 get_cache
3092
3093 =over 4
3094
3095 =item Arguments: none
3096
3097 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3098
3099 =back
3100
3101 Gets the contents of the cache for the resultset, if the cache is set.
3102
3103 The cache is populated either by using the L</prefetch> attribute to
3104 L</search> or by calling L</set_cache>.
3105
3106 =cut
3107
3108 sub get_cache {
3109   shift->{all_cache};
3110 }
3111
3112 =head2 set_cache
3113
3114 =over 4
3115
3116 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3117
3118 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3119
3120 =back
3121
3122 Sets the contents of the cache for the resultset. Expects an arrayref
3123 of objects of the same class as those produced by the resultset. Note that
3124 if the cache is set, the resultset will return the cached objects rather
3125 than re-querying the database even if the cache attr is not set.
3126
3127 The contents of the cache can also be populated by using the
3128 L</prefetch> attribute to L</search>.
3129
3130 =cut
3131
3132 sub set_cache {
3133   my ( $self, $data ) = @_;
3134   $self->throw_exception("set_cache requires an arrayref")
3135       if defined($data) && (ref $data ne 'ARRAY');
3136   $self->{all_cache} = $data;
3137 }
3138
3139 =head2 clear_cache
3140
3141 =over 4
3142
3143 =item Arguments: none
3144
3145 =item Return Value: undef
3146
3147 =back
3148
3149 Clears the cache for the resultset.
3150
3151 =cut
3152
3153 sub clear_cache {
3154   shift->set_cache(undef);
3155 }
3156
3157 =head2 is_paged
3158
3159 =over 4
3160
3161 =item Arguments: none
3162
3163 =item Return Value: true, if the resultset has been paginated
3164
3165 =back
3166
3167 =cut
3168
3169 sub is_paged {
3170   my ($self) = @_;
3171   return !!$self->{attrs}{page};
3172 }
3173
3174 =head2 is_ordered
3175
3176 =over 4
3177
3178 =item Arguments: none
3179
3180 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3181
3182 =back
3183
3184 =cut
3185
3186 sub is_ordered {
3187   my ($self) = @_;
3188   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3189 }
3190
3191 =head2 related_resultset
3192
3193 =over 4
3194
3195 =item Arguments: $rel_name
3196
3197 =item Return Value: L<$resultset|/search>
3198
3199 =back
3200
3201 Returns a related resultset for the supplied relationship name.
3202
3203   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3204
3205 =cut
3206
3207 sub related_resultset {
3208   $_[0]->throw_exception(
3209     'Extra arguments to $rs->related_resultset() were always quietly '
3210   . 'discarded without consideration, you need to switch to '
3211   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3212   ) if @_ > 2;
3213
3214   return $_[0]->{related_resultsets}{$_[1]}
3215     if defined $_[0]->{related_resultsets}{$_[1]};
3216
3217   my ($self, $rel) = @_;
3218
3219   return $self->{related_resultsets}{$rel} = do {
3220     my $rsrc = $self->result_source;
3221     my $rel_info = $rsrc->relationship_info($rel);
3222
3223     $self->throw_exception(
3224       "search_related: result source '" . $rsrc->source_name .
3225         "' has no such relationship $rel")
3226       unless $rel_info;
3227
3228     my $attrs = $self->_chain_relationship($rel);
3229
3230     my $storage = $rsrc->schema->storage;
3231
3232     # Previously this atribute was deleted (instead of being set as it is now)
3233     # Doing so seems to be harmless in all available test permutations
3234     # See also 01d59a6a6 and mst's comment below
3235     #
3236     $attrs->{alias} = $storage->relname_to_table_alias(
3237       $rel,
3238       $attrs->{seen_join}{$rel}
3239     );
3240
3241     # since this is search_related, and we already slid the select window inwards
3242     # (the select/as attrs were deleted in the beginning), we need to flip all
3243     # left joins to inner, so we get the expected results
3244     # read the comment on top of the actual function to see what this does
3245     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3246
3247     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3248     delete $attrs->{result_class};
3249
3250     my $new = do {
3251
3252       # The reason we do this now instead of passing the alias to the
3253       # search_rs below is that if you wrap/overload resultset on the
3254       # source you need to know what alias it's -going- to have for things
3255       # to work sanely (e.g. RestrictWithObject wants to be able to add
3256       # extra query restrictions, and these may need to be $alias.)
3257       #                                       -- mst ~ 2007 (01d59a6a6)
3258       #
3259       # FIXME - this seems to be no longer neccessary (perhaps due to the
3260       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3261       # dependent (as of Jun 2015 ) does not yield any difference with or
3262       # without this line. Nevertheless keep it as is for now, to minimize
3263       # churn, there is enough potential for breakage in 0.0829xx as it is
3264       #                                       -- ribasushi Jun 2015
3265       #
3266       my $rel_source = $rsrc->related_source($rel);
3267       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3268
3269       $rel_source->resultset->search_rs( undef, $attrs );
3270     };
3271
3272     if (my $cache = $self->get_cache) {
3273       my @related_cache = map
3274         { $_->related_resultset($rel)->get_cache || () }
3275         @$cache
3276       ;
3277
3278       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3279     }
3280
3281     $new;
3282   };
3283 }
3284
3285 =head2 current_source_alias
3286
3287 =over 4
3288
3289 =item Arguments: none
3290
3291 =item Return Value: $source_alias
3292
3293 =back
3294
3295 Returns the current table alias for the result source this resultset is built
3296 on, that will be used in the SQL query. Usually it is C<me>.
3297
3298 Currently the source alias that refers to the result set returned by a
3299 L</search>/L</find> family method depends on how you got to the resultset: it's
3300 C<me> by default, but eg. L</search_related> aliases it to the related result
3301 source name (and keeps C<me> referring to the original result set). The long
3302 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3303 (and make this method unnecessary).
3304
3305 Thus it's currently necessary to use this method in predefined queries (see
3306 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3307 source alias of the current result set:
3308
3309   # in a result set class
3310   sub modified_by {
3311     my ($self, $user) = @_;
3312
3313     my $me = $self->current_source_alias;
3314
3315     return $self->search({
3316       "$me.modified" => $user->id,
3317     });
3318   }
3319
3320 The alias of L<newly created resultsets|/search> can be altered by the
3321 L<alias attribute|/alias>.
3322
3323 =cut
3324
3325 sub current_source_alias {
3326   return (shift->{attrs} || {})->{alias} || 'me';
3327 }
3328
3329 =head2 as_subselect_rs
3330
3331 =over 4
3332
3333 =item Arguments: none
3334
3335 =item Return Value: L<$resultset|/search>
3336
3337 =back
3338
3339 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3340 "virtual view" by including it as a subquery within the from clause.  From this
3341 point on, any joined tables are inaccessible to ->search on the resultset (as if
3342 it were simply where-filtered without joins).  For example:
3343
3344  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3345
3346  # 'x' now pollutes the query namespace
3347
3348  # So the following works as expected
3349  my $ok_rs = $rs->search({'x.other' => 1});
3350
3351  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3352  # def) we look for one row with contradictory terms and join in another table
3353  # (aliased 'x_2') which we never use
3354  my $broken_rs = $rs->search({'x.name' => 'def'});
3355
3356  my $rs2 = $rs->as_subselect_rs;
3357
3358  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3359  my $not_joined_rs = $rs2->search({'x.other' => 1});
3360
3361  # works as expected: finds a 'table' row related to two x rows (abc and def)
3362  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3363
3364 Another example of when one might use this would be to select a subset of
3365 columns in a group by clause:
3366
3367  my $rs = $schema->resultset('Bar')->search(undef, {
3368    group_by => [qw{ id foo_id baz_id }],
3369  })->as_subselect_rs->search(undef, {
3370    columns => [qw{ id foo_id }]
3371  });
3372
3373 In the above example normally columns would have to be equal to the group by,
3374 but because we isolated the group by into a subselect the above works.
3375
3376 =cut
3377
3378 sub as_subselect_rs {
3379   my $self = shift;
3380
3381   my $attrs = $self->_resolved_attrs;
3382
3383   my $fresh_rs = (ref $self)->new (
3384     $self->result_source
3385   );
3386
3387   # these pieces will be locked in the subquery
3388   delete $fresh_rs->{cond};
3389   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3390
3391   return $fresh_rs->search( {}, {
3392     from => [{
3393       $attrs->{alias} => $self->as_query,
3394       -alias  => $attrs->{alias},
3395       -rsrc   => $self->result_source,
3396     }],
3397     alias => $attrs->{alias},
3398   });
3399 }
3400
3401 # This code is called by search_related, and makes sure there
3402 # is clear separation between the joins before, during, and
3403 # after the relationship. This information is needed later
3404 # in order to properly resolve prefetch aliases (any alias
3405 # with a relation_chain_depth less than the depth of the
3406 # current prefetch is not considered)
3407 #
3408 # The increments happen twice per join. An even number means a
3409 # relationship specified via a search_related, whereas an odd
3410 # number indicates a join/prefetch added via attributes
3411 #
3412 # Also this code will wrap the current resultset (the one we
3413 # chain to) in a subselect IFF it contains limiting attributes
3414 sub _chain_relationship {
3415   my ($self, $rel) = @_;
3416   my $source = $self->result_source;
3417   my $attrs = { %{$self->{attrs}||{}} };
3418
3419   # we need to take the prefetch the attrs into account before we
3420   # ->_resolve_join as otherwise they get lost - captainL
3421   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3422
3423   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3424
3425   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3426
3427   my $from;
3428   my @force_subq_attrs = qw/offset rows group_by having/;
3429
3430   if (
3431     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3432       ||
3433     $self->_has_resolved_attr (@force_subq_attrs)
3434   ) {
3435     # Nuke the prefetch (if any) before the new $rs attrs
3436     # are resolved (prefetch is useless - we are wrapping
3437     # a subquery anyway).
3438     my $rs_copy = $self->search;
3439     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3440       $rs_copy->{attrs}{join},
3441       delete $rs_copy->{attrs}{prefetch},
3442     );
3443
3444     $from = [{
3445       -rsrc   => $source,
3446       -alias  => $attrs->{alias},
3447       $attrs->{alias} => $rs_copy->as_query,
3448     }];
3449     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3450     $seen->{-relation_chain_depth} = 0;
3451   }
3452   elsif ($attrs->{from}) {  #shallow copy suffices
3453     $from = [ @{$attrs->{from}} ];
3454   }
3455   else {
3456     $from = [{
3457       -rsrc  => $source,
3458       -alias => $attrs->{alias},
3459       $attrs->{alias} => $source->from,
3460     }];
3461   }
3462
3463   my $jpath = ($seen->{-relation_chain_depth})
3464     ? $from->[-1][0]{-join_path}
3465     : [];
3466
3467   my @requested_joins = $source->_resolve_join(
3468     $join,
3469     $attrs->{alias},
3470     $seen,
3471     $jpath,
3472   );
3473
3474   push @$from, @requested_joins;
3475
3476   $seen->{-relation_chain_depth}++;
3477
3478   # if $self already had a join/prefetch specified on it, the requested
3479   # $rel might very well be already included. What we do in this case
3480   # is effectively a no-op (except that we bump up the chain_depth on
3481   # the join in question so we could tell it *is* the search_related)
3482   my $already_joined;
3483
3484   # we consider the last one thus reverse
3485   for my $j (reverse @requested_joins) {
3486     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3487     if ($rel eq $last_j) {
3488       $j->[0]{-relation_chain_depth}++;
3489       $already_joined++;
3490       last;
3491     }
3492   }
3493
3494   unless ($already_joined) {
3495     push @$from, $source->_resolve_join(
3496       $rel,
3497       $attrs->{alias},
3498       $seen,
3499       $jpath,
3500     );
3501   }
3502
3503   $seen->{-relation_chain_depth}++;
3504
3505   return {%$attrs, from => $from, seen_join => $seen};
3506 }
3507
3508 sub _resolved_attrs {
3509   my $self = shift;
3510   return $self->{_attrs} if $self->{_attrs};
3511
3512   my $attrs  = { %{ $self->{attrs} || {} } };
3513   my $source = $attrs->{result_source} = $self->result_source;
3514   my $alias  = $attrs->{alias};
3515
3516   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3517     if $attrs->{collapse} and $attrs->{distinct};
3518
3519
3520   # Sanity check the paging attributes
3521   # SQLMaker does it too, but in case of a software_limit we'll never get there
3522   if (defined $attrs->{offset}) {
3523     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3524       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3525   }
3526   if (defined $attrs->{rows}) {
3527     $self->throw_exception("The rows attribute must be a positive integer if present")
3528       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3529   }
3530
3531
3532   # default selection list
3533   $attrs->{columns} = [ $source->columns ]
3534     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3535
3536   # merge selectors together
3537   for (qw/columns select as/) {
3538     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3539       if $attrs->{$_} or $attrs->{"+$_"};
3540   }
3541
3542   # disassemble columns
3543   my (@sel, @as);
3544   if (my $cols = delete $attrs->{columns}) {
3545     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3546       if (ref $c eq 'HASH') {
3547         for my $as (sort keys %$c) {
3548           push @sel, $c->{$as};
3549           push @as, $as;
3550         }
3551       }
3552       else {
3553         push @sel, $c;
3554         push @as, $c;
3555       }
3556     }
3557   }
3558
3559   # when trying to weed off duplicates later do not go past this point -
3560   # everything added from here on is unbalanced "anyone's guess" stuff
3561   my $dedup_stop_idx = $#as;
3562
3563   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3564     if $attrs->{as};
3565   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3566     if $attrs->{select};
3567
3568   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3569   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3570
3571   # disqualify all $alias.col as-bits (inflate-map mandated)
3572   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3573
3574   # de-duplicate the result (remove *identical* select/as pairs)
3575   # and also die on duplicate {as} pointing to different {select}s
3576   # not using a c-style for as the condition is prone to shrinkage
3577   my $seen;
3578   my $i = 0;
3579   while ($i <= $dedup_stop_idx) {
3580     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3581       splice @sel, $i, 1;
3582       splice @as, $i, 1;
3583       $dedup_stop_idx--;
3584     }
3585     elsif ($seen->{$as[$i]}++) {
3586       $self->throw_exception(
3587         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3588       );
3589     }
3590     else {
3591       $i++;
3592     }
3593   }
3594
3595   $attrs->{select} = \@sel;
3596   $attrs->{as} = \@as;
3597
3598   $attrs->{from} ||= [{
3599     -rsrc   => $source,
3600     -alias  => $self->{attrs}{alias},
3601     $self->{attrs}{alias} => $source->from,
3602   }];
3603
3604   if ( $attrs->{join} || $attrs->{prefetch} ) {
3605
3606     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3607       if ref $attrs->{from} ne 'ARRAY';
3608
3609     my $join = (delete $attrs->{join}) || {};
3610
3611     if ( defined $attrs->{prefetch} ) {
3612       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3613     }
3614
3615     $attrs->{from} =    # have to copy here to avoid corrupting the original
3616       [
3617         @{ $attrs->{from} },
3618         $source->_resolve_join(
3619           $join,
3620           $alias,
3621           { %{ $attrs->{seen_join} || {} } },
3622           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3623             ? $attrs->{from}[-1][0]{-join_path}
3624             : []
3625           ,
3626         )
3627       ];
3628   }
3629
3630
3631   for my $attr (qw(order_by group_by)) {
3632
3633     if ( defined $attrs->{$attr} ) {
3634       $attrs->{$attr} = (
3635         ref( $attrs->{$attr} ) eq 'ARRAY'
3636         ? [ @{ $attrs->{$attr} } ]
3637         : [ $attrs->{$attr} || () ]
3638       );
3639
3640       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3641     }
3642   }
3643
3644
3645   # set collapse default based on presence of prefetch
3646   my $prefetch;
3647   if (
3648     defined $attrs->{prefetch}
3649       and
3650     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3651   ) {
3652     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3653       if defined $attrs->{collapse} and ! $attrs->{collapse};
3654
3655     $attrs->{collapse} = 1;
3656   }
3657
3658
3659   # run through the resulting joinstructure (starting from our current slot)
3660   # and unset collapse if proven unnecessary
3661   #
3662   # also while we are at it find out if the current root source has
3663   # been premultiplied by previous related_source chaining
3664   #
3665   # this allows to predict whether a root object with all other relation
3666   # data set to NULL is in fact unique
3667   if ($attrs->{collapse}) {
3668
3669     if (ref $attrs->{from} eq 'ARRAY') {
3670
3671       if (@{$attrs->{from}} == 1) {
3672         # no joins - no collapse
3673         $attrs->{collapse} = 0;
3674       }
3675       else {
3676         # find where our table-spec starts
3677         my @fromlist = @{$attrs->{from}};
3678         while (@fromlist) {
3679           my $t = shift @fromlist;
3680
3681           my $is_multi;
3682           # me vs join from-spec distinction - a ref means non-root
3683           if (ref $t eq 'ARRAY') {
3684             $t = $t->[0];
3685             $is_multi ||= ! $t->{-is_single};
3686           }
3687           last if ($t->{-alias} && $t->{-alias} eq $alias);
3688           $attrs->{_main_source_premultiplied} ||= $is_multi;
3689         }
3690
3691         # no non-singles remaining, nor any premultiplication - nothing to collapse
3692         if (
3693           ! $attrs->{_main_source_premultiplied}
3694             and
3695           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3696         ) {
3697           $attrs->{collapse} = 0;
3698         }
3699       }
3700     }
3701
3702     else {
3703       # if we can not analyze the from - err on the side of safety
3704       $attrs->{_main_source_premultiplied} = 1;
3705     }
3706   }
3707
3708
3709   # generate the distinct induced group_by before injecting the prefetched select/as parts
3710   if (delete $attrs->{distinct}) {
3711     if ($attrs->{group_by}) {
3712       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3713     }
3714     else {
3715       $attrs->{_grouped_by_distinct} = 1;
3716       # distinct affects only the main selection part, not what prefetch may add below
3717       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3718
3719       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3720       # The thinking is: if we are collapsing the subquerying prefetch engine will
3721       # rip stuff apart for us anyway, and we do not want to have a potentially
3722       # function-converted external order_by
3723       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3724       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3725     }
3726   }
3727
3728
3729   # generate selections based on the prefetch helper
3730   if ($prefetch) {
3731
3732     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3733       if $attrs->{_dark_selector};
3734
3735     # this is a separate structure (we don't look in {from} directly)
3736     # as the resolver needs to shift things off the lists to work
3737     # properly (identical-prefetches on different branches)
3738     my $joined_node_aliases_map = {};
3739     if (ref $attrs->{from} eq 'ARRAY') {
3740
3741       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3742
3743       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3744         next unless $j->[0]{-alias};
3745         next unless $j->[0]{-join_path};
3746         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3747
3748         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3749
3750         my $p = $joined_node_aliases_map;
3751         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3752         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3753       }
3754     }
3755
3756     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3757       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3758   }
3759
3760
3761   $attrs->{_simple_passthrough_construction} = !(
3762     $attrs->{collapse}
3763       or
3764     grep { $_ =~ /\./ } @{$attrs->{as}}
3765   );
3766
3767
3768   # if both page and offset are specified, produce a combined offset
3769   # even though it doesn't make much sense, this is what pre 081xx has
3770   # been doing
3771   if (my $page = delete $attrs->{page}) {
3772     $attrs->{offset} =
3773       ($attrs->{rows} * ($page - 1))
3774             +
3775       ($attrs->{offset} || 0)
3776     ;
3777   }
3778
3779   return $self->{_attrs} = $attrs;
3780 }
3781
3782 sub _rollout_attr {
3783   my ($self, $attr) = @_;
3784
3785   if (ref $attr eq 'HASH') {
3786     return $self->_rollout_hash($attr);
3787   } elsif (ref $attr eq 'ARRAY') {
3788     return $self->_rollout_array($attr);
3789   } else {
3790     return [$attr];
3791   }
3792 }
3793
3794 sub _rollout_array {
3795   my ($self, $attr) = @_;
3796
3797   my @rolled_array;
3798   foreach my $element (@{$attr}) {
3799     if (ref $element eq 'HASH') {
3800       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3801     } elsif (ref $element eq 'ARRAY') {
3802       #  XXX - should probably recurse here
3803       push( @rolled_array, @{$self->_rollout_array($element)} );
3804     } else {
3805       push( @rolled_array, $element );
3806     }
3807   }
3808   return \@rolled_array;
3809 }
3810
3811 sub _rollout_hash {
3812   my ($self, $attr) = @_;
3813
3814   my @rolled_array;
3815   foreach my $key (keys %{$attr}) {
3816     push( @rolled_array, { $key => $attr->{$key} } );
3817   }
3818   return \@rolled_array;
3819 }
3820
3821 sub _calculate_score {
3822   my ($self, $a, $b) = @_;
3823
3824   if (defined $a xor defined $b) {
3825     return 0;
3826   }
3827   elsif (not defined $a) {
3828     return 1;
3829   }
3830
3831   if (ref $b eq 'HASH') {
3832     my ($b_key) = keys %{$b};
3833     $b_key = '' if ! defined $b_key;
3834     if (ref $a eq 'HASH') {
3835       my ($a_key) = keys %{$a};
3836       $a_key = '' if ! defined $a_key;
3837       if ($a_key eq $b_key) {
3838         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3839       } else {
3840         return 0;
3841       }
3842     } else {
3843       return ($a eq $b_key) ? 1 : 0;
3844     }
3845   } else {
3846     if (ref $a eq 'HASH') {
3847       my ($a_key) = keys %{$a};
3848       return ($b eq $a_key) ? 1 : 0;
3849     } else {
3850       return ($b eq $a) ? 1 : 0;
3851     }
3852   }
3853 }
3854
3855 sub _merge_joinpref_attr {
3856   my ($self, $orig, $import) = @_;
3857
3858   return $import unless defined($orig);
3859   return $orig unless defined($import);
3860
3861   $orig = $self->_rollout_attr($orig);
3862   $import = $self->_rollout_attr($import);
3863
3864   my $seen_keys;
3865   foreach my $import_element ( @{$import} ) {
3866     # find best candidate from $orig to merge $b_element into
3867     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3868     foreach my $orig_element ( @{$orig} ) {
3869       my $score = $self->_calculate_score( $orig_element, $import_element );
3870       if ($score > $best_candidate->{score}) {
3871         $best_candidate->{position} = $position;
3872         $best_candidate->{score} = $score;
3873       }
3874       $position++;
3875     }
3876     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3877     $import_key = '' if not defined $import_key;
3878
3879     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3880       push( @{$orig}, $import_element );
3881     } else {
3882       my $orig_best = $orig->[$best_candidate->{position}];
3883       # merge orig_best and b_element together and replace original with merged
3884       if (ref $orig_best ne 'HASH') {
3885         $orig->[$best_candidate->{position}] = $import_element;
3886       } elsif (ref $import_element eq 'HASH') {
3887         my ($key) = keys %{$orig_best};
3888         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3889       }
3890     }
3891     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3892   }
3893
3894   return @$orig ? $orig : ();
3895 }
3896
3897 {
3898   my $hm;
3899
3900   sub _merge_attr {
3901     $hm ||= do {
3902       require Hash::Merge;
3903       my $hm = Hash::Merge->new;
3904
3905       $hm->specify_behavior({
3906         SCALAR => {
3907           SCALAR => sub {
3908             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3909
3910             if ($defl xor $defr) {
3911               return [ $defl ? $_[0] : $_[1] ];
3912             }
3913             elsif (! $defl) {
3914               return [];
3915             }
3916             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3917               return [ $_[0] ];
3918             }
3919             else {
3920               return [$_[0], $_[1]];
3921             }
3922           },
3923           ARRAY => sub {
3924             return $_[1] if !defined $_[0];
3925             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3926             return [$_[0], @{$_[1]}]
3927           },
3928           HASH  => sub {
3929             return [] if !defined $_[0] and !keys %{$_[1]};
3930             return [ $_[1] ] if !defined $_[0];
3931             return [ $_[0] ] if !keys %{$_[1]};
3932             return [$_[0], $_[1]]
3933           },
3934         },
3935         ARRAY => {
3936           SCALAR => sub {
3937             return $_[0] if !defined $_[1];
3938             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3939             return [@{$_[0]}, $_[1]]
3940           },
3941           ARRAY => sub {
3942             my @ret = @{$_[0]} or return $_[1];
3943             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3944             my %idx = map { $_ => 1 } @ret;
3945             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3946             \@ret;
3947           },
3948           HASH => sub {
3949             return [ $_[1] ] if ! @{$_[0]};
3950             return $_[0] if !keys %{$_[1]};
3951             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3952             return [ @{$_[0]}, $_[1] ];
3953           },
3954         },
3955         HASH => {
3956           SCALAR => sub {
3957             return [] if !keys %{$_[0]} and !defined $_[1];
3958             return [ $_[0] ] if !defined $_[1];
3959             return [ $_[1] ] if !keys %{$_[0]};
3960             return [$_[0], $_[1]]
3961           },
3962           ARRAY => sub {
3963             return [] if !keys %{$_[0]} and !@{$_[1]};
3964             return [ $_[0] ] if !@{$_[1]};
3965             return $_[1] if !keys %{$_[0]};
3966             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3967             return [ $_[0], @{$_[1]} ];
3968           },
3969           HASH => sub {
3970             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3971             return [ $_[0] ] if !keys %{$_[1]};
3972             return [ $_[1] ] if !keys %{$_[0]};
3973             return [ $_[0] ] if $_[0] eq $_[1];
3974             return [ $_[0], $_[1] ];
3975           },
3976         }
3977       } => 'DBIC_RS_ATTR_MERGER');
3978       $hm;
3979     };
3980
3981     return $hm->merge ($_[1], $_[2]);
3982   }
3983 }
3984
3985 sub STORABLE_freeze {
3986   my ($self, $cloning) = @_;
3987   my $to_serialize = { %$self };
3988
3989   # A cursor in progress can't be serialized (and would make little sense anyway)
3990   # the parser can be regenerated (and can't be serialized)
3991   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3992
3993   # nor is it sensical to store a not-yet-fired-count pager
3994   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3995     delete $to_serialize->{pager};
3996   }
3997
3998   Storable::nfreeze($to_serialize);
3999 }
4000
4001 # need this hook for symmetry
4002 sub STORABLE_thaw {
4003   my ($self, $cloning, $serialized) = @_;
4004
4005   %$self = %{ Storable::thaw($serialized) };
4006
4007   $self;
4008 }
4009
4010
4011 =head2 throw_exception
4012
4013 See L<DBIx::Class::Schema/throw_exception> for details.
4014
4015 =cut
4016
4017 sub throw_exception {
4018   my $self=shift;
4019
4020   if (ref $self and my $rsrc = $self->result_source) {
4021     $rsrc->throw_exception(@_)
4022   }
4023   else {
4024     DBIx::Class::Exception->throw(@_);
4025   }
4026 }
4027
4028 1;
4029
4030 __END__
4031
4032 # XXX: FIXME: Attributes docs need clearing up
4033
4034 =head1 ATTRIBUTES
4035
4036 Attributes are used to refine a ResultSet in various ways when
4037 searching for data. They can be passed to any method which takes an
4038 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4039 L</count>.
4040
4041 Default attributes can be set on the result class using
4042 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4043 the CAVEATS on that feature before using it!)
4044
4045 These are in no particular order:
4046
4047 =head2 order_by
4048
4049 =over 4
4050
4051 =item Value: ( $order_by | \@order_by | \%order_by )
4052
4053 =back
4054
4055 Which column(s) to order the results by.
4056
4057 [The full list of suitable values is documented in
4058 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4059 common options.]
4060
4061 If a single column name, or an arrayref of names is supplied, the
4062 argument is passed through directly to SQL. The hashref syntax allows
4063 for connection-agnostic specification of ordering direction:
4064
4065  For descending order:
4066
4067   order_by => { -desc => [qw/col1 col2 col3/] }
4068
4069  For explicit ascending order:
4070
4071   order_by => { -asc => 'col' }
4072
4073 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4074 supported, although you are strongly encouraged to use the hashref
4075 syntax as outlined above.
4076
4077 =head2 columns
4078
4079 =over 4
4080
4081 =item Value: \@columns | \%columns | $column
4082
4083 =back
4084
4085 Shortcut to request a particular set of columns to be retrieved. Each
4086 column spec may be a string (a table column name), or a hash (in which
4087 case the key is the C<as> value, and the value is used as the C<select>
4088 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4089 it and sets C<select> from that, then auto-populates C<as> from
4090 C<select> as normal. (You may also use the C<cols> attribute, as in
4091 earlier versions of DBIC, but this is deprecated)
4092
4093 Essentially C<columns> does the same as L</select> and L</as>.
4094
4095     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4096
4097 is the same as
4098
4099     select => [qw(some_column another_column)],
4100     as     => [qw(some_column dbic_slot)]
4101
4102 If you want to individually retrieve related columns (in essence perform
4103 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4104 chain such that it matches existing relationships:
4105
4106     my $rs = $schema->resultset('Artist')->search({}, {
4107         # required to tell DBIC to collapse has_many relationships
4108         collapse => 1,
4109         join     => { cds => 'tracks' },
4110         '+columns'  => {
4111           'cds.cdid'         => 'cds.cdid',
4112           'cds.tracks.title' => 'tracks.title',
4113         },
4114     });
4115
4116 Like elsewhere, literal SQL or literal values can be included by using a
4117 scalar reference or a literal bind value, and these values will be available
4118 in the result with C<get_column> (see also
4119 L<SQL::Abstract/Literal SQL and value type operators>):
4120
4121     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4122     # bind values: $true_value, $false_value
4123     columns => [
4124         {
4125             foo => \1,
4126             bar => \q{'a string'},
4127             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4128         }
4129     ]
4130
4131 =head2 +columns
4132
4133 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4134 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4135 with a unary plus operator before it, which is the same as simply C<columns>.
4136
4137 =over 4
4138
4139 =item Value: \@extra_columns
4140
4141 =back
4142
4143 Indicates additional columns to be selected from storage. Works the same as
4144 L</columns> but adds columns to the current selection. (You may also use the
4145 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4146 deprecated)
4147
4148   $schema->resultset('CD')->search(undef, {
4149     '+columns' => ['artist.name'],
4150     join => ['artist']
4151   });
4152
4153 would return all CDs and include a 'name' column to the information
4154 passed to object inflation. Note that the 'artist' is the name of the
4155 column (or relationship) accessor, and 'name' is the name of the column
4156 accessor in the related table.
4157
4158 =head2 select
4159
4160 =over 4
4161
4162 =item Value: \@select_columns
4163
4164 =back
4165
4166 Indicates which columns should be selected from the storage. You can use
4167 column names, or in the case of RDBMS back ends, function or stored procedure
4168 names:
4169
4170   $rs = $schema->resultset('Employee')->search(undef, {
4171     select => [
4172       'name',
4173       { count => 'employeeid' },
4174       { max => { length => 'name' }, -as => 'longest_name' }
4175     ]
4176   });
4177
4178   # Equivalent SQL
4179   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4180
4181 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4182 use L</select>, to instruct DBIx::Class how to store the result of the column.
4183
4184 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4185 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4186 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4187 function attribute> supplied as shown in the example above.
4188
4189 =head2 +select
4190
4191 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4192 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4193 with a unary plus operator before it, which is the same as simply C<select>.
4194
4195 =over 4
4196
4197 =item Value: \@extra_select_columns
4198
4199 =back
4200
4201 Indicates additional columns to be selected from storage.  Works the same as
4202 L</select> but adds columns to the current selection, instead of specifying
4203 a new explicit list.
4204
4205 =head2 as
4206
4207 =over 4
4208
4209 =item Value: \@inflation_names
4210
4211 =back
4212
4213 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4214 slot name in which the column value will be stored within the
4215 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4216 identifier by the C<get_column> method (or via the object accessor B<if one
4217 with the same name already exists>) as shown below.
4218
4219 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4220 aliasing C<AS>. See L</select> for details.
4221
4222   $rs = $schema->resultset('Employee')->search(undef, {
4223     select => [
4224       'name',
4225       { count => 'employeeid' },
4226       { max => { length => 'name' }, -as => 'longest_name' }
4227     ],
4228     as => [qw/
4229       name
4230       employee_count
4231       max_name_length
4232     /],
4233   });
4234
4235 If the object against which the search is performed already has an accessor
4236 matching a column name specified in C<as>, the value can be retrieved using
4237 the accessor as normal:
4238
4239   my $name = $employee->name();
4240
4241 If on the other hand an accessor does not exist in the object, you need to
4242 use C<get_column> instead:
4243
4244   my $employee_count = $employee->get_column('employee_count');
4245
4246 You can create your own accessors if required - see
4247 L<DBIx::Class::Manual::Cookbook> for details.
4248
4249 =head2 +as
4250
4251 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4252 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4253 with a unary plus operator before it, which is the same as simply C<as>.
4254
4255 =over 4
4256
4257 =item Value: \@extra_inflation_names
4258
4259 =back
4260
4261 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4262
4263 =head2 join
4264
4265 =over 4
4266
4267 =item Value: ($rel_name | \@rel_names | \%rel_names)
4268
4269 =back
4270
4271 Contains a list of relationships that should be joined for this query.  For
4272 example:
4273
4274   # Get CDs by Nine Inch Nails
4275   my $rs = $schema->resultset('CD')->search(
4276     { 'artist.name' => 'Nine Inch Nails' },
4277     { join => 'artist' }
4278   );
4279
4280 Can also contain a hash reference to refer to the other relation's relations.
4281 For example:
4282
4283   package MyApp::Schema::Track;
4284   use base qw/DBIx::Class/;
4285   __PACKAGE__->table('track');
4286   __PACKAGE__->add_columns(qw/trackid cd position title/);
4287   __PACKAGE__->set_primary_key('trackid');
4288   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4289   1;
4290
4291   # In your application
4292   my $rs = $schema->resultset('Artist')->search(
4293     { 'track.title' => 'Teardrop' },
4294     {
4295       join     => { cd => 'track' },
4296       order_by => 'artist.name',
4297     }
4298   );
4299
4300 You need to use the relationship (not the table) name in  conditions,
4301 because they are aliased as such. The current table is aliased as "me", so
4302 you need to use me.column_name in order to avoid ambiguity. For example:
4303
4304   # Get CDs from 1984 with a 'Foo' track
4305   my $rs = $schema->resultset('CD')->search(
4306     {
4307       'me.year' => 1984,
4308       'tracks.name' => 'Foo'
4309     },
4310     { join => 'tracks' }
4311   );
4312
4313 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4314 similarly for a third time). For e.g.
4315
4316   my $rs = $schema->resultset('Artist')->search({
4317     'cds.title'   => 'Down to Earth',
4318     'cds_2.title' => 'Popular',
4319   }, {
4320     join => [ qw/cds cds/ ],
4321   });
4322
4323 will return a set of all artists that have both a cd with title 'Down
4324 to Earth' and a cd with title 'Popular'.
4325
4326 If you want to fetch related objects from other tables as well, see L</prefetch>
4327 below.
4328
4329  NOTE: An internal join-chain pruner will discard certain joins while
4330  constructing the actual SQL query, as long as the joins in question do not
4331  affect the retrieved result. This for example includes 1:1 left joins
4332  that are not part of the restriction specification (WHERE/HAVING) nor are
4333  a part of the query selection.
4334
4335 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4336
4337 =head2 collapse
4338
4339 =over 4
4340
4341 =item Value: (0 | 1)
4342
4343 =back
4344
4345 When set to a true value, indicates that any rows fetched from joined has_many
4346 relationships are to be aggregated into the corresponding "parent" object. For
4347 example, the resultset:
4348
4349   my $rs = $schema->resultset('CD')->search({}, {
4350     '+columns' => [ qw/ tracks.title tracks.position / ],
4351     join => 'tracks',
4352     collapse => 1,
4353   });
4354
4355 While executing the following query:
4356
4357   SELECT me.*, tracks.title, tracks.position
4358     FROM cd me
4359     LEFT JOIN track tracks
4360       ON tracks.cdid = me.cdid
4361
4362 Will return only as many objects as there are rows in the CD source, even
4363 though the result of the query may span many rows. Each of these CD objects
4364 will in turn have multiple "Track" objects hidden behind the has_many
4365 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4366 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4367 product"), with each CD object containing exactly one of all fetched Track data.
4368
4369 When a collapse is requested on a non-ordered resultset, an order by some
4370 unique part of the main source (the left-most table) is inserted automatically.
4371 This is done so that the resultset is allowed to be "lazy" - calling
4372 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4373 object with all of its related data.
4374
4375 If an L</order_by> is already declared, and orders the resultset in a way that
4376 makes collapsing as described above impossible (e.g. C<< ORDER BY
4377 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4378 switch to "eager" mode and slurp the entire resultset before constructing the
4379 first object returned by L</next>.
4380
4381 Setting this attribute on a resultset that does not join any has_many
4382 relations is a no-op.
4383
4384 For a more in-depth discussion, see L</PREFETCHING>.
4385
4386 =head2 prefetch
4387
4388 =over 4
4389
4390 =item Value: ($rel_name | \@rel_names | \%rel_names)
4391
4392 =back
4393
4394 This attribute is a shorthand for specifying a L</join> spec, adding all
4395 columns from the joined related sources as L</+columns> and setting
4396 L</collapse> to a true value. It can be thought of as a rough B<superset>
4397 of the L</join> attribute.
4398
4399 For example, the following two queries are equivalent:
4400
4401   my $rs = $schema->resultset('Artist')->search({}, {
4402     prefetch => { cds => ['genre', 'tracks' ] },
4403   });
4404
4405 and
4406
4407   my $rs = $schema->resultset('Artist')->search({}, {
4408     join => { cds => ['genre', 'tracks' ] },
4409     collapse => 1,
4410     '+columns' => [
4411       (map
4412         { +{ "cds.$_" => "cds.$_" } }
4413         $schema->source('Artist')->related_source('cds')->columns
4414       ),
4415       (map
4416         { +{ "cds.genre.$_" => "genre.$_" } }
4417         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4418       ),
4419       (map
4420         { +{ "cds.tracks.$_" => "tracks.$_" } }
4421         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4422       ),
4423     ],
4424   });
4425
4426 Both producing the following SQL:
4427
4428   SELECT  me.artistid, me.name, me.rank, me.charfield,
4429           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4430           genre.genreid, genre.name,
4431           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4432     FROM artist me
4433     LEFT JOIN cd cds
4434       ON cds.artist = me.artistid
4435     LEFT JOIN genre genre
4436       ON genre.genreid = cds.genreid
4437     LEFT JOIN track tracks
4438       ON tracks.cd = cds.cdid
4439   ORDER BY me.artistid
4440
4441 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4442 the arguments are properly merged and generally do the right thing. For
4443 example, you may want to do the following:
4444
4445   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4446     { 'genre.genreid' => undef },
4447     {
4448       join => { cds => 'genre' },
4449       prefetch => 'cds',
4450     }
4451   );
4452
4453 Which generates the following SQL:
4454
4455   SELECT  me.artistid, me.name, me.rank, me.charfield,
4456           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4457     FROM artist me
4458     LEFT JOIN cd cds
4459       ON cds.artist = me.artistid
4460     LEFT JOIN genre genre
4461       ON genre.genreid = cds.genreid
4462   WHERE genre.genreid IS NULL
4463   ORDER BY me.artistid
4464
4465 For a more in-depth discussion, see L</PREFETCHING>.
4466
4467 =head2 alias
4468
4469 =over 4
4470
4471 =item Value: $source_alias
4472
4473 =back
4474
4475 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4476 nested search queries (sub-SELECTs) might need specific aliases set to
4477 reference inner queries.  For example:
4478
4479    my $q = $rs
4480       ->related_resultset('CDs')
4481       ->related_resultset('Tracks')
4482       ->search({
4483          'track.id' => { -ident => 'none_search.id' },
4484       })
4485       ->as_query;
4486
4487    my $ids = $self->search({
4488       -not_exists => $q,
4489    }, {
4490       alias    => 'none_search',
4491       group_by => 'none_search.id',
4492    })->get_column('id')->as_query;
4493
4494    $self->search({ id => { -in => $ids } })
4495
4496 This attribute is directly tied to L</current_source_alias>.
4497
4498 =head2 page
4499
4500 =over 4
4501
4502 =item Value: $page
4503
4504 =back
4505
4506 Makes the resultset paged and specifies the page to retrieve. Effectively
4507 identical to creating a non-pages resultset and then calling ->page($page)
4508 on it.
4509
4510 If L</rows> attribute is not specified it defaults to 10 rows per page.
4511
4512 When you have a paged resultset, L</count> will only return the number
4513 of rows in the page. To get the total, use the L</pager> and call
4514 C<total_entries> on it.
4515
4516 =head2 rows
4517
4518 =over 4
4519
4520 =item Value: $rows
4521
4522 =back
4523
4524 Specifies the maximum number of rows for direct retrieval or the number of
4525 rows per page if the page attribute or method is used.
4526
4527 =head2 offset
4528
4529 =over 4
4530
4531 =item Value: $offset
4532
4533 =back
4534
4535 Specifies the (zero-based) row number for the  first row to be returned, or the
4536 of the first row of the first page if paging is used.
4537
4538 =head2 software_limit
4539
4540 =over 4
4541
4542 =item Value: (0 | 1)
4543
4544 =back
4545
4546 When combined with L</rows> and/or L</offset> the generated SQL will not
4547 include any limit dialect stanzas. Instead the entire result will be selected
4548 as if no limits were specified, and DBIC will perform the limit locally, by
4549 artificially advancing and finishing the resulting L</cursor>.
4550
4551 This is the recommended way of performing resultset limiting when no sane RDBMS
4552 implementation is available (e.g.
4553 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4554 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4555
4556 =head2 group_by
4557
4558 =over 4
4559
4560 =item Value: \@columns
4561
4562 =back
4563
4564 A arrayref of columns to group by. Can include columns of joined tables.
4565
4566   group_by => [qw/ column1 column2 ... /]
4567
4568 =head2 having
4569
4570 =over 4
4571
4572 =item Value: $condition
4573
4574 =back
4575
4576 The HAVING operator specifies a B<secondary> condition applied to the set
4577 after the grouping calculations have been done. In other words it is a
4578 constraint just like L</where> (and accepting the same
4579 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4580 as it exists after GROUP BY has taken place. Specifying L</having> without
4581 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4582
4583 E.g.
4584
4585   having => { 'count_employee' => { '>=', 100 } }
4586
4587 or with an in-place function in which case literal SQL is required:
4588
4589   having => \[ 'count(employee) >= ?', 100 ]
4590
4591 =head2 distinct
4592
4593 =over 4
4594
4595 =item Value: (0 | 1)
4596
4597 =back
4598
4599 Set to 1 to automatically generate a L</group_by> clause based on the selection
4600 (including intelligent handling of L</order_by> contents). Note that the group
4601 criteria calculation takes place over the B<final> selection. This includes
4602 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4603 L</search> calls, and standalone columns selected via
4604 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4605 extra selections specified via L</prefetch> - such selections are explicitly
4606 excluded from group criteria calculations.
4607
4608 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4609 setting is ignored and an appropriate warning is issued.
4610
4611 =head2 where
4612
4613 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4614 conditions, same as the B<first> argument to the L<search operator|/search>
4615
4616   # only return rows WHERE deleted IS NULL for all searches
4617   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4618
4619 Note that the above example is
4620 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4621
4622 =head2 cache
4623
4624 Set to 1 to cache search results. This prevents extra SQL queries if you
4625 revisit rows in your ResultSet:
4626
4627   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4628
4629   while( my $artist = $resultset->next ) {
4630     ... do stuff ...
4631   }
4632
4633   $resultset->first; # without cache, this would issue a query
4634
4635 By default, searches are not cached.
4636
4637 For more examples of using these attributes, see
4638 L<DBIx::Class::Manual::Cookbook>.
4639
4640 =head2 for
4641
4642 =over 4
4643
4644 =item Value: ( 'update' | 'shared' | \$scalar )
4645
4646 =back
4647
4648 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4649 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4650 query.
4651
4652 =head1 PREFETCHING
4653
4654 DBIx::Class supports arbitrary related data prefetching from multiple related
4655 sources. Any combination of relationship types and column sets are supported.
4656 If L<collapsing|/collapse> is requested, there is an additional requirement of
4657 selecting enough data to make every individual object uniquely identifiable.
4658
4659 Here are some more involved examples, based on the following relationship map:
4660
4661   # Assuming:
4662   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4663   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4664   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4665
4666   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4667
4668   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4669
4670
4671
4672   my $rs = $schema->resultset('Tag')->search(
4673     undef,
4674     {
4675       prefetch => {
4676         cd => 'artist'
4677       }
4678     }
4679   );
4680
4681 The initial search results in SQL like the following:
4682
4683   SELECT tag.*, cd.*, artist.* FROM tag
4684   JOIN cd ON tag.cd = cd.cdid
4685   JOIN artist ON cd.artist = artist.artistid
4686
4687 L<DBIx::Class> has no need to go back to the database when we access the
4688 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4689 case.
4690
4691 Simple prefetches will be joined automatically, so there is no need
4692 for a C<join> attribute in the above search.
4693
4694 The L</prefetch> attribute can be used with any of the relationship types
4695 and multiple prefetches can be specified together. Below is a more complex
4696 example that prefetches a CD's artist, its liner notes (if present),
4697 the cover image, the tracks on that CD, and the guests on those
4698 tracks.
4699
4700   my $rs = $schema->resultset('CD')->search(
4701     undef,
4702     {
4703       prefetch => [
4704         { artist => 'record_label'},  # belongs_to => belongs_to
4705         'liner_note',                 # might_have
4706         'cover_image',                # has_one
4707         { tracks => 'guests' },       # has_many => has_many
4708       ]
4709     }
4710   );
4711
4712 This will produce SQL like the following:
4713
4714   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4715          tracks.*, guests.*
4716     FROM cd me
4717     JOIN artist artist
4718       ON artist.artistid = me.artistid
4719     JOIN record_label record_label
4720       ON record_label.labelid = artist.labelid
4721     LEFT JOIN track tracks
4722       ON tracks.cdid = me.cdid
4723     LEFT JOIN guest guests
4724       ON guests.trackid = track.trackid
4725     LEFT JOIN liner_notes liner_note
4726       ON liner_note.cdid = me.cdid
4727     JOIN cd_artwork cover_image
4728       ON cover_image.cdid = me.cdid
4729   ORDER BY tracks.cd
4730
4731 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4732 C<tracks>, and C<guests> of the CD will all be available through the
4733 relationship accessors without the need for additional queries to the
4734 database.
4735
4736 =head3 CAVEATS
4737
4738 Prefetch does a lot of deep magic. As such, it may not behave exactly
4739 as you might expect.
4740
4741 =over 4
4742
4743 =item *
4744
4745 Prefetch uses the L</cache> to populate the prefetched relationships. This
4746 may or may not be what you want.
4747
4748 =item *
4749
4750 If you specify a condition on a prefetched relationship, ONLY those
4751 rows that match the prefetched condition will be fetched into that relationship.
4752 This means that adding prefetch to a search() B<may alter> what is returned by
4753 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4754
4755   my $artist_rs = $schema->resultset('Artist')->search({
4756       'cds.year' => 2008,
4757   }, {
4758       join => 'cds',
4759   });
4760
4761   my $count = $artist_rs->first->cds->count;
4762
4763   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4764
4765   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4766
4767   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4768
4769 That cmp_ok() may or may not pass depending on the datasets involved. In other
4770 words the C<WHERE> condition would apply to the entire dataset, just like
4771 it would in regular SQL. If you want to add a condition only to the "right side"
4772 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4773 condition|DBIx::Class::Relationship::Base/condition>
4774
4775 =back
4776
4777 =head1 DBIC BIND VALUES
4778
4779 Because DBIC may need more information to bind values than just the column name
4780 and value itself, it uses a special format for both passing and receiving bind
4781 values.  Each bind value should be composed of an arrayref of
4782 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4783
4784 =over 4
4785
4786 =item dbd_attrs
4787
4788 If present (in any form), this is what is being passed directly to bind_param.
4789 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4790 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4791
4792 If this is specified, all other bind options described below are ignored.
4793
4794 =item sqlt_datatype
4795
4796 If present, this is used to infer the actual bind attribute by passing to
4797 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4798 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4799
4800 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4801 currently drivers are expected to "Do the Right Thing" when given a common
4802 datatype name.  (Not ideal, but that's what we got at this point.)
4803
4804 =item sqlt_size
4805
4806 Currently used to correctly allocate buffers for bind_param_inout().
4807 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4808 or to a sensible value based on the "data_type".
4809
4810 =item dbic_colname
4811
4812 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4813 explicitly specified they are never overridden).  Also used by some weird DBDs,
4814 where the column name should be available at bind_param time (e.g. Oracle).
4815
4816 =back
4817
4818 For backwards compatibility and convenience, the following shortcuts are
4819 supported:
4820
4821   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4822   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4823   [ undef,   $val ] === [ {}, $val ]
4824   $val              === [ {}, $val ]
4825
4826 =head1 FURTHER QUESTIONS?
4827
4828 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4829
4830 =head1 COPYRIGHT AND LICENSE
4831
4832 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4833 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4834 redistribute it and/or modify it under the same terms as the
4835 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4836
4837 =cut