lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360
 361   $rs->set_cache($rows) if ($rows);
 362
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   my @copy = @$row;
 978
 979   # 'foo'         => [ undef, 'foo' ]
 980   # 'foo.bar'     => [ 'foo', 'bar' ]
 981   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 982
 983   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 984
 985   my %collapse = %{$self->{_attrs}{collapse}||{}};
 986
 987   my @pri_index;
 988
 989   # if we're doing collapsing (has_many prefetch) we need to grab records
 990   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 991   # we know we don't have to bother.
 992
 993   # the reason for not using the collapse stuff directly is because if you
 994   # had for e.g. two artists in a row with no cds, the collapse info for
 995   # both would be NULL (undef) so you'd lose the second artist
 996
 997   # store just the index so we can check the array positions from the row
 998   # without having to contruct the full hash
 999
1000   if (keys %collapse) {
1001     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1002     foreach my $i (0 .. $#construct_as) {
1003       next if defined($construct_as[$i][0]); # only self table
1004       if (delete $pri{$construct_as[$i][1]}) {
1005         push(@pri_index, $i);
1006       }
1007       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1008     }
1009   }
1010
1011   # no need to do an if, it'll be empty if @pri_index is empty anyway
1012
1013   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1014
1015   my @const_rows;
1016
1017   do { # no need to check anything at the front, we always want the first row
1018
1019     my %const;
1020
1021     foreach my $this_as (@construct_as) {
1022       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1023     }
1024
1025     push(@const_rows, \%const);
1026
1027   } until ( # no pri_index => no collapse => drop straight out
1028       !@pri_index
1029     or
1030       do { # get another row, stash it, drop out if different PK
1031
1032         @copy = $self->cursor->next;
1033         $self->{stashed_row} = \@copy;
1034
1035         # last thing in do block, counts as true if anything doesn't match
1036
1037         # check xor defined first for NULL vs. NOT NULL then if one is
1038         # defined the other must be so check string equality
1039
1040         grep {
1041           (defined $pri_vals{$_} ^ defined $copy[$_])
1042           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1043         } @pri_index;
1044       }
1045   );
1046
1047   my $alias = $self->{attrs}{alias};
1048   my $info = [];
1049
1050   my %collapse_pos;
1051
1052   my @const_keys;
1053
1054   foreach my $const (@const_rows) {
1055     scalar @const_keys or do {
1056       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1057     };
1058     foreach my $key (@const_keys) {
1059       if (length $key) {
1060         my $target = $info;
1061         my @parts = split(/\./, $key);
1062         my $cur = '';
1063         my $data = $const->{$key};
1064         foreach my $p (@parts) {
1065           $target = $target->[1]->{$p} ||= [];
1066           $cur .= ".${p}";
1067           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1068             # collapsing at this point and on final part
1069             my $pos = $collapse_pos{$cur};
1070             CK: foreach my $ck (@ckey) {
1071               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1072                 $collapse_pos{$cur} = $data;
1073                 delete @collapse_pos{ # clear all positioning for sub-entries
1074                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1075                 };
1076                 push(@$target, []);
1077                 last CK;
1078               }
1079             }
1080           }
1081           if (exists $collapse{$cur}) {
1082             $target = $target->[-1];
1083           }
1084         }
1085         $target->[0] = $data;
1086       } else {
1087         $info->[0] = $const->{$key};
1088       }
1089     }
1090   }
1091
1092   return $info;
1093 }
1094
1095 =head2 result_source
1096
1097 =over 4
1098
1099 =item Arguments: $result_source?
1100
1101 =item Return Value: $result_source
1102
1103 =back
1104
1105 An accessor for the primary ResultSource object from which this ResultSet
1106 is derived.
1107
1108 =head2 result_class
1109
1110 =over 4
1111
1112 =item Arguments: $result_class?
1113
1114 =item Return Value: $result_class
1115
1116 =back
1117
1118 An accessor for the class to use when creating row objects. Defaults to
1119 C<< result_source->result_class >> - which in most cases is the name of the
1120 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1121
1122 Note that changing the result_class will also remove any components
1123 that were originally loaded in the source class via
1124 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1125 in the original source class will not run.
1126
1127 =cut
1128
1129 sub result_class {
1130   my ($self, $result_class) = @_;
1131   if ($result_class) {
1132     $self->ensure_class_loaded($result_class);
1133     $self->_result_class($result_class);
1134   }
1135   $self->_result_class;
1136 }
1137
1138 =head2 count
1139
1140 =over 4
1141
1142 =item Arguments: $cond, \%attrs??
1143
1144 =item Return Value: $count
1145
1146 =back
1147
1148 Performs an SQL C<COUNT> with the same query as the resultset was built
1149 with to find the number of elements. Passing arguments is equivalent to
1150 C<< $rs->search ($cond, \%attrs)->count >>
1151
1152 =cut
1153
1154 sub count {
1155   my $self = shift;
1156   return $self->search(@_)->count if @_ and defined $_[0];
1157   return scalar @{ $self->get_cache } if $self->get_cache;
1158
1159   my $attrs = $self->_resolved_attrs_copy;
1160
1161   # this is a little optimization - it is faster to do the limit
1162   # adjustments in software, instead of a subquery
1163   my $rows = delete $attrs->{rows};
1164   my $offset = delete $attrs->{offset};
1165
1166   my $crs;
1167   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1168     $crs = $self->_count_subq_rs ($attrs);
1169   }
1170   else {
1171     $crs = $self->_count_rs ($attrs);
1172   }
1173   my $count = $crs->next;
1174
1175   $count -= $offset if $offset;
1176   $count = $rows if $rows and $rows < $count;
1177   $count = 0 if ($count < 0);
1178
1179   return $count;
1180 }
1181
1182 =head2 count_rs
1183
1184 =over 4
1185
1186 =item Arguments: $cond, \%attrs??
1187
1188 =item Return Value: $count_rs
1189
1190 =back
1191
1192 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1193 This can be very handy for subqueries:
1194
1195   ->search( { amount => $some_rs->count_rs->as_query } )
1196
1197 As with regular resultsets the SQL query will be executed only after
1198 the resultset is accessed via L</next> or L</all>. That would return
1199 the same single value obtainable via L</count>.
1200
1201 =cut
1202
1203 sub count_rs {
1204   my $self = shift;
1205   return $self->search(@_)->count_rs if @_;
1206
1207   # this may look like a lack of abstraction (count() does about the same)
1208   # but in fact an _rs *must* use a subquery for the limits, as the
1209   # software based limiting can not be ported if this $rs is to be used
1210   # in a subquery itself (i.e. ->as_query)
1211   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1212     return $self->_count_subq_rs;
1213   }
1214   else {
1215     return $self->_count_rs;
1216   }
1217 }
1218
1219 #
1220 # returns a ResultSetColumn object tied to the count query
1221 #
1222 sub _count_rs {
1223   my ($self, $attrs) = @_;
1224
1225   my $rsrc = $self->result_source;
1226   $attrs ||= $self->_resolved_attrs;
1227
1228   my $tmp_attrs = { %$attrs };
1229
1230   # take off any limits, record_filter is cdbi, and no point of ordering a count
1231   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1232
1233   # overwrite the selector (supplied by the storage)
1234   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1235   $tmp_attrs->{as} = 'count';
1236
1237   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1238
1239   return $tmp_rs;
1240 }
1241
1242 #
1243 # same as above but uses a subquery
1244 #
1245 sub _count_subq_rs {
1246   my ($self, $attrs) = @_;
1247
1248   my $rsrc = $self->result_source;
1249   $attrs ||= $self->_resolved_attrs_copy;
1250
1251   my $sub_attrs = { %$attrs };
1252
1253   # extra selectors do not go in the subquery and there is no point of ordering it
1254   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1255
1256   # if we prefetch, we group_by primary keys only as this is what we would get out
1257   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1258   if ( keys %{$attrs->{collapse}} ) {
1259     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1260   }
1261
1262   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1263
1264   # this is so that the query can be simplified e.g.
1265   # * non-limiting joins can be pruned
1266   # * ordering can be thrown away in things like Top limit
1267   $sub_attrs->{-for_count_only} = 1;
1268
1269   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1270
1271   $attrs->{from} = [{
1272     -alias => 'count_subq',
1273     -source_handle => $rsrc->handle,
1274     count_subq => $sub_rs->as_query,
1275   }];
1276
1277   # the subquery replaces this
1278   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1279
1280   return $self->_count_rs ($attrs);
1281 }
1282
1283 sub _bool {
1284   return 1;
1285 }
1286
1287 =head2 count_literal
1288
1289 =over 4
1290
1291 =item Arguments: $sql_fragment, @bind_values
1292
1293 =item Return Value: $count
1294
1295 =back
1296
1297 Counts the results in a literal query. Equivalent to calling L</search_literal>
1298 with the passed arguments, then L</count>.
1299
1300 =cut
1301
1302 sub count_literal { shift->search_literal(@_)->count; }
1303
1304 =head2 all
1305
1306 =over 4
1307
1308 =item Arguments: none
1309
1310 =item Return Value: @objects
1311
1312 =back
1313
1314 Returns all elements in the resultset. Called implicitly if the resultset
1315 is returned in list context.
1316
1317 =cut
1318
1319 sub all {
1320   my $self = shift;
1321   if(@_) {
1322       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1323   }
1324
1325   return @{ $self->get_cache } if $self->get_cache;
1326
1327   my @obj;
1328
1329   if (keys %{$self->_resolved_attrs->{collapse}}) {
1330     # Using $self->cursor->all is really just an optimisation.
1331     # If we're collapsing has_many prefetches it probably makes
1332     # very little difference, and this is cleaner than hacking
1333     # _construct_object to survive the approach
1334     $self->cursor->reset;
1335     my @row = $self->cursor->next;
1336     while (@row) {
1337       push(@obj, $self->_construct_object(@row));
1338       @row = (exists $self->{stashed_row}
1339                ? @{delete $self->{stashed_row}}
1340                : $self->cursor->next);
1341     }
1342   } else {
1343     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1344   }
1345
1346   $self->set_cache(\@obj) if $self->{attrs}{cache};
1347
1348   return @obj;
1349 }
1350
1351 =head2 reset
1352
1353 =over 4
1354
1355 =item Arguments: none
1356
1357 =item Return Value: $self
1358
1359 =back
1360
1361 Resets the resultset's cursor, so you can iterate through the elements again.
1362 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1363 another query.
1364
1365 =cut
1366
1367 sub reset {
1368   my ($self) = @_;
1369   delete $self->{_attrs} if exists $self->{_attrs};
1370   $self->{all_cache_position} = 0;
1371   $self->cursor->reset;
1372   return $self;
1373 }
1374
1375 =head2 first
1376
1377 =over 4
1378
1379 =item Arguments: none
1380
1381 =item Return Value: $object?
1382
1383 =back
1384
1385 Resets the resultset and returns an object for the first result (if the
1386 resultset returns anything).
1387
1388 =cut
1389
1390 sub first {
1391   return $_[0]->reset->next;
1392 }
1393
1394
1395 # _rs_update_delete
1396 #
1397 # Determines whether and what type of subquery is required for the $rs operation.
1398 # If grouping is necessary either supplies its own, or verifies the current one
1399 # After all is done delegates to the proper storage method.
1400
1401 sub _rs_update_delete {
1402   my ($self, $op, $values) = @_;
1403
1404   my $rsrc = $self->result_source;
1405
1406   # if a condition exists we need to strip all table qualifiers
1407   # if this is not possible we'll force a subquery below
1408   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1409
1410   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1411   my $needs_subq = (not defined $cond) || $self->_has_resolved_attr(qw/row offset/);
1412
1413   if ($needs_group_by_subq or $needs_subq) {
1414
1415     # make a new $rs selecting only the PKs (that's all we really need)
1416     my $attrs = $self->_resolved_attrs_copy;
1417
1418     delete $attrs->{$_} for qw/collapse select as/;
1419     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1420
1421     if ($needs_group_by_subq) {
1422       # make sure no group_by was supplied, or if there is one - make sure it matches
1423       # the columns compiled above perfectly. Anything else can not be sanely executed
1424       # on most databases so croak right then and there
1425
1426       if (my $g = $attrs->{group_by}) {
1427         my @current_group_by = map
1428           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1429           @$g
1430         ;
1431
1432         if (
1433           join ("\x00", sort @current_group_by)
1434             ne
1435           join ("\x00", sort @{$attrs->{columns}} )
1436         ) {
1437           $self->throw_exception (
1438             "You have just attempted a $op operation on a resultset which does group_by"
1439             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1440             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1441             . ' kind of queries. Please retry the operation with a modified group_by or'
1442             . ' without using one at all.'
1443           );
1444         }
1445       }
1446       else {
1447         $attrs->{group_by} = $attrs->{columns};
1448       }
1449     }
1450
1451     my $subrs = (ref $self)->new($rsrc, $attrs);
1452
1453     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1454   }
1455   else {
1456     return $rsrc->storage->$op(
1457       $rsrc,
1458       $op eq 'update' ? $values : (),
1459       $cond,
1460     );
1461   }
1462 }
1463
1464 =head2 update
1465
1466 =over 4
1467
1468 =item Arguments: \%values
1469
1470 =item Return Value: $storage_rv
1471
1472 =back
1473
1474 Sets the specified columns in the resultset to the supplied values in a
1475 single query. Return value will be true if the update succeeded or false
1476 if no records were updated; exact type of success value is storage-dependent.
1477
1478 =cut
1479
1480 sub update {
1481   my ($self, $values) = @_;
1482   $self->throw_exception('Values for update must be a hash')
1483     unless ref $values eq 'HASH';
1484
1485   return $self->_rs_update_delete ('update', $values);
1486 }
1487
1488 =head2 update_all
1489
1490 =over 4
1491
1492 =item Arguments: \%values
1493
1494 =item Return Value: 1
1495
1496 =back
1497
1498 Fetches all objects and updates them one at a time. Note that C<update_all>
1499 will run DBIC cascade triggers, while L</update> will not.
1500
1501 =cut
1502
1503 sub update_all {
1504   my ($self, $values) = @_;
1505   $self->throw_exception('Values for update_all must be a hash')
1506     unless ref $values eq 'HASH';
1507   foreach my $obj ($self->all) {
1508     $obj->set_columns($values)->update;
1509   }
1510   return 1;
1511 }
1512
1513 =head2 delete
1514
1515 =over 4
1516
1517 =item Arguments: none
1518
1519 =item Return Value: $storage_rv
1520
1521 =back
1522
1523 Deletes the contents of the resultset from its result source. Note that this
1524 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1525 to run. See also L<DBIx::Class::Row/delete>.
1526
1527 Return value will be the amount of rows deleted; exact type of return value
1528 is storage-dependent.
1529
1530 =cut
1531
1532 sub delete {
1533   my $self = shift;
1534   $self->throw_exception('delete does not accept any arguments')
1535     if @_;
1536
1537   return $self->_rs_update_delete ('delete');
1538 }
1539
1540 =head2 delete_all
1541
1542 =over 4
1543
1544 =item Arguments: none
1545
1546 =item Return Value: 1
1547
1548 =back
1549
1550 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1551 will run DBIC cascade triggers, while L</delete> will not.
1552
1553 =cut
1554
1555 sub delete_all {
1556   my $self = shift;
1557   $self->throw_exception('delete_all does not accept any arguments')
1558     if @_;
1559
1560   $_->delete for $self->all;
1561   return 1;
1562 }
1563
1564 =head2 populate
1565
1566 =over 4
1567
1568 =item Arguments: \@data;
1569
1570 =back
1571
1572 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1573 For the arrayref of hashrefs style each hashref should be a structure suitable
1574 forsubmitting to a $resultset->create(...) method.
1575
1576 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1577 to insert the data, as this is a faster method.
1578
1579 Otherwise, each set of data is inserted into the database using
1580 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1581 accumulated into an array. The array itself, or an array reference
1582 is returned depending on scalar or list context.
1583
1584 Example:  Assuming an Artist Class that has many CDs Classes relating:
1585
1586   my $Artist_rs = $schema->resultset("Artist");
1587
1588   ## Void Context Example
1589   $Artist_rs->populate([
1590      { artistid => 4, name => 'Manufactured Crap', cds => [
1591         { title => 'My First CD', year => 2006 },
1592         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1593       ],
1594      },
1595      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1596         { title => 'My parents sold me to a record company' ,year => 2005 },
1597         { title => 'Why Am I So Ugly?', year => 2006 },
1598         { title => 'I Got Surgery and am now Popular', year => 2007 }
1599       ],
1600      },
1601   ]);
1602
1603   ## Array Context Example
1604   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1605     { name => "Artist One"},
1606     { name => "Artist Two"},
1607     { name => "Artist Three", cds=> [
1608     { title => "First CD", year => 2007},
1609     { title => "Second CD", year => 2008},
1610   ]}
1611   ]);
1612
1613   print $ArtistOne->name; ## response is 'Artist One'
1614   print $ArtistThree->cds->count ## reponse is '2'
1615
1616 For the arrayref of arrayrefs style,  the first element should be a list of the
1617 fieldsnames to which the remaining elements are rows being inserted.  For
1618 example:
1619
1620   $Arstist_rs->populate([
1621     [qw/artistid name/],
1622     [100, 'A Formally Unknown Singer'],
1623     [101, 'A singer that jumped the shark two albums ago'],
1624     [102, 'An actually cool singer.'],
1625   ]);
1626
1627 Please note an important effect on your data when choosing between void and
1628 wantarray context. Since void context goes straight to C<insert_bulk> in
1629 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1630 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1631 create primary keys for you, you will find that your PKs are empty.  In this
1632 case you will have to use the wantarray context in order to create those
1633 values.
1634
1635 =cut
1636
1637 sub populate {
1638   my $self = shift;
1639
1640   # cruft placed in standalone method
1641   my $data = $self->_normalize_populate_args(@_);
1642
1643   if(defined wantarray) {
1644     my @created;
1645     foreach my $item (@$data) {
1646       push(@created, $self->create($item));
1647     }
1648     return wantarray ? @created : \@created;
1649   } else {
1650     my $first = $data->[0];
1651
1652     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1653     # it relationship data
1654     my (@rels, @columns);
1655     for (keys %$first) {
1656       my $ref = ref $first->{$_};
1657       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1658         ? push @rels, $_
1659         : push @columns, $_
1660       ;
1661     }
1662
1663     my @pks = $self->result_source->primary_columns;
1664
1665     ## do the belongs_to relationships
1666     foreach my $index (0..$#$data) {
1667
1668       # delegate to create() for any dataset without primary keys with specified relationships
1669       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1670         for my $r (@rels) {
1671           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1672             my @ret = $self->populate($data);
1673             return;
1674           }
1675         }
1676       }
1677
1678       foreach my $rel (@rels) {
1679         next unless ref $data->[$index]->{$rel} eq "HASH";
1680         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1681         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1682         my $related = $result->result_source->_resolve_condition(
1683           $result->result_source->relationship_info($reverse)->{cond},
1684           $self,
1685           $result,
1686         );
1687
1688         delete $data->[$index]->{$rel};
1689         $data->[$index] = {%{$data->[$index]}, %$related};
1690
1691         push @columns, keys %$related if $index == 0;
1692       }
1693     }
1694
1695     ## inherit the data locked in the conditions of the resultset
1696     my ($rs_data) = $self->_merge_cond_with_data({});
1697     delete @{$rs_data}{@columns};
1698     my @inherit_cols = keys %$rs_data;
1699     my @inherit_data = values %$rs_data;
1700
1701     ## do bulk insert on current row
1702     $self->result_source->storage->insert_bulk(
1703       $self->result_source,
1704       [@columns, @inherit_cols],
1705       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1706     );
1707
1708     ## do the has_many relationships
1709     foreach my $item (@$data) {
1710
1711       foreach my $rel (@rels) {
1712         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1713
1714         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1715      || $self->throw_exception('Cannot find the relating object.');
1716
1717         my $child = $parent->$rel;
1718
1719         my $related = $child->result_source->_resolve_condition(
1720           $parent->result_source->relationship_info($rel)->{cond},
1721           $child,
1722           $parent,
1723         );
1724
1725         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1726         my @populate = map { {%$_, %$related} } @rows_to_add;
1727
1728         $child->populate( \@populate );
1729       }
1730     }
1731   }
1732 }
1733
1734
1735 # populate() argumnets went over several incarnations
1736 # What we ultimately support is AoH
1737 sub _normalize_populate_args {
1738   my ($self, $arg) = @_;
1739
1740   if (ref $arg eq 'ARRAY') {
1741     if (ref $arg->[0] eq 'HASH') {
1742       return $arg;
1743     }
1744     elsif (ref $arg->[0] eq 'ARRAY') {
1745       my @ret;
1746       my @colnames = @{$arg->[0]};
1747       foreach my $values (@{$arg}[1 .. $#$arg]) {
1748         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
1749       }
1750       return \@ret;
1751     }
1752   }
1753
1754   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
1755 }
1756
1757 =head2 pager
1758
1759 =over 4
1760
1761 =item Arguments: none
1762
1763 =item Return Value: $pager
1764
1765 =back
1766
1767 Return Value a L<Data::Page> object for the current resultset. Only makes
1768 sense for queries with a C<page> attribute.
1769
1770 To get the full count of entries for a paged resultset, call
1771 C<total_entries> on the L<Data::Page> object.
1772
1773 =cut
1774
1775 sub pager {
1776   my ($self) = @_;
1777
1778   return $self->{pager} if $self->{pager};
1779
1780   my $attrs = $self->{attrs};
1781   $self->throw_exception("Can't create pager for non-paged rs")
1782     unless $self->{attrs}{page};
1783   $attrs->{rows} ||= 10;
1784
1785   # throw away the paging flags and re-run the count (possibly
1786   # with a subselect) to get the real total count
1787   my $count_attrs = { %$attrs };
1788   delete $count_attrs->{$_} for qw/rows offset page pager/;
1789   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1790
1791   return $self->{pager} = Data::Page->new(
1792     $total_count,
1793     $attrs->{rows},
1794     $self->{attrs}{page}
1795   );
1796 }
1797
1798 =head2 page
1799
1800 =over 4
1801
1802 =item Arguments: $page_number
1803
1804 =item Return Value: $rs
1805
1806 =back
1807
1808 Returns a resultset for the $page_number page of the resultset on which page
1809 is called, where each page contains a number of rows equal to the 'rows'
1810 attribute set on the resultset (10 by default).
1811
1812 =cut
1813
1814 sub page {
1815   my ($self, $page) = @_;
1816   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1817 }
1818
1819 =head2 new_result
1820
1821 =over 4
1822
1823 =item Arguments: \%vals
1824
1825 =item Return Value: $rowobject
1826
1827 =back
1828
1829 Creates a new row object in the resultset's result class and returns
1830 it. The row is not inserted into the database at this point, call
1831 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1832 will tell you whether the row object has been inserted or not.
1833
1834 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1835
1836 =cut
1837
1838 sub new_result {
1839   my ($self, $values) = @_;
1840   $self->throw_exception( "new_result needs a hash" )
1841     unless (ref $values eq 'HASH');
1842
1843   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
1844
1845   my %new = (
1846     %$merged_cond,
1847     @$cols_from_relations
1848       ? (-cols_from_relations => $cols_from_relations)
1849       : (),
1850     -source_handle => $self->_source_handle,
1851     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1852   );
1853
1854   return $self->result_class->new(\%new);
1855 }
1856
1857 # _merge_cond_with_data
1858 #
1859 # Takes a simple hash of K/V data and returns its copy merged with the
1860 # condition already present on the resultset. Additionally returns an
1861 # arrayref of value/condition names, which were inferred from related
1862 # objects (this is needed for in-memory related objects)
1863 sub _merge_cond_with_data {
1864   my ($self, $data) = @_;
1865
1866   my (%new_data, @cols_from_relations);
1867
1868   my $alias = $self->{attrs}{alias};
1869
1870   if (! defined $self->{cond}) {
1871     # just massage $data below
1872   }
1873   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
1874     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1875     @cols_from_relations = keys %new_data;
1876   }
1877   elsif (ref $self->{cond} ne 'HASH') {
1878     $self->throw_exception(
1879       "Can't abstract implicit construct, resultset condition not a hash"
1880     );
1881   }
1882   else {
1883     # precendence must be given to passed values over values inherited from
1884     # the cond, so the order here is important.
1885     my $collapsed_cond = $self->_collapse_cond($self->{cond});
1886     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
1887
1888     while ( my($col, $value) = each %implied ) {
1889       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
1890         $new_data{$col} = $value->{'='};
1891         next;
1892       }
1893       $new_data{$col} = $value if $self->_is_deterministic_value($value);
1894     }
1895   }
1896
1897   %new_data = (
1898     %new_data,
1899     %{ $self->_remove_alias($data, $alias) },
1900   );
1901
1902   return (\%new_data, \@cols_from_relations);
1903 }
1904
1905 # _is_deterministic_value
1906 #
1907 # Make an effor to strip non-deterministic values from the condition,
1908 # to make sure new_result chokes less
1909
1910 sub _is_deterministic_value {
1911   my $self = shift;
1912   my $value = shift;
1913   my $ref_type = ref $value;
1914   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1915   return 1 if Scalar::Util::blessed($value);
1916   return 0;
1917 }
1918
1919 # _has_resolved_attr
1920 #
1921 # determines if the resultset defines at least one
1922 # of the attributes supplied
1923 #
1924 # used to determine if a subquery is neccessary
1925 #
1926 # supports some virtual attributes:
1927 #   -join
1928 #     This will scan for any joins being present on the resultset.
1929 #     It is not a mere key-search but a deep inspection of {from}
1930 #
1931
1932 sub _has_resolved_attr {
1933   my ($self, @attr_names) = @_;
1934
1935   my $attrs = $self->_resolved_attrs;
1936
1937   my %extra_checks;
1938
1939   for my $n (@attr_names) {
1940     if (grep { $n eq $_ } (qw/-join/) ) {
1941       $extra_checks{$n}++;
1942       next;
1943     }
1944
1945     my $attr =  $attrs->{$n};
1946
1947     next if not defined $attr;
1948
1949     if (ref $attr eq 'HASH') {
1950       return 1 if keys %$attr;
1951     }
1952     elsif (ref $attr eq 'ARRAY') {
1953       return 1 if @$attr;
1954     }
1955     else {
1956       return 1 if $attr;
1957     }
1958   }
1959
1960   # a resolved join is expressed as a multi-level from
1961   return 1 if (
1962     $extra_checks{-join}
1963       and
1964     ref $attrs->{from} eq 'ARRAY'
1965       and
1966     @{$attrs->{from}} > 1
1967   );
1968
1969   return 0;
1970 }
1971
1972 # _collapse_cond
1973 #
1974 # Recursively collapse the condition.
1975
1976 sub _collapse_cond {
1977   my ($self, $cond, $collapsed) = @_;
1978
1979   $collapsed ||= {};
1980
1981   if (ref $cond eq 'ARRAY') {
1982     foreach my $subcond (@$cond) {
1983       next unless ref $subcond;  # -or
1984       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1985     }
1986   }
1987   elsif (ref $cond eq 'HASH') {
1988     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1989       foreach my $subcond (@{$cond->{-and}}) {
1990         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1991       }
1992     }
1993     else {
1994       foreach my $col (keys %$cond) {
1995         my $value = $cond->{$col};
1996         $collapsed->{$col} = $value;
1997       }
1998     }
1999   }
2000
2001   return $collapsed;
2002 }
2003
2004 # _remove_alias
2005 #
2006 # Remove the specified alias from the specified query hash. A copy is made so
2007 # the original query is not modified.
2008
2009 sub _remove_alias {
2010   my ($self, $query, $alias) = @_;
2011
2012   my %orig = %{ $query || {} };
2013   my %unaliased;
2014
2015   foreach my $key (keys %orig) {
2016     if ($key !~ /\./) {
2017       $unaliased{$key} = $orig{$key};
2018       next;
2019     }
2020     $unaliased{$1} = $orig{$key}
2021       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2022   }
2023
2024   return \%unaliased;
2025 }
2026
2027 =head2 as_query (EXPERIMENTAL)
2028
2029 =over 4
2030
2031 =item Arguments: none
2032
2033 =item Return Value: \[ $sql, @bind ]
2034
2035 =back
2036
2037 Returns the SQL query and bind vars associated with the invocant.
2038
2039 This is generally used as the RHS for a subquery.
2040
2041 B<NOTE>: This feature is still experimental.
2042
2043 =cut
2044
2045 sub as_query {
2046   my $self = shift;
2047
2048   my $attrs = $self->_resolved_attrs_copy;
2049
2050   # For future use:
2051   #
2052   # in list ctx:
2053   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2054   # $sql also has no wrapping parenthesis in list ctx
2055   #
2056   my $sqlbind = $self->result_source->storage
2057     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2058
2059   return $sqlbind;
2060 }
2061
2062 =head2 find_or_new
2063
2064 =over 4
2065
2066 =item Arguments: \%vals, \%attrs?
2067
2068 =item Return Value: $rowobject
2069
2070 =back
2071
2072   my $artist = $schema->resultset('Artist')->find_or_new(
2073     { artist => 'fred' }, { key => 'artists' });
2074
2075   $cd->cd_to_producer->find_or_new({ producer => $producer },
2076                                    { key => 'primary });
2077
2078 Find an existing record from this resultset, based on its primary
2079 key, or a unique constraint. If none exists, instantiate a new result
2080 object and return it. The object will not be saved into your storage
2081 until you call L<DBIx::Class::Row/insert> on it.
2082
2083 You most likely want this method when looking for existing rows using
2084 a unique constraint that is not the primary key, or looking for
2085 related rows.
2086
2087 If you want objects to be saved immediately, use L</find_or_create>
2088 instead.
2089
2090 B<Note>: Take care when using C<find_or_new> with a table having
2091 columns with default values that you intend to be automatically
2092 supplied by the database (e.g. an auto_increment primary key column).
2093 In normal usage, the value of such columns should NOT be included at
2094 all in the call to C<find_or_new>, even when set to C<undef>.
2095
2096 =cut
2097
2098 sub find_or_new {
2099   my $self     = shift;
2100   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2101   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2102   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2103     return $row;
2104   }
2105   return $self->new_result($hash);
2106 }
2107
2108 =head2 create
2109
2110 =over 4
2111
2112 =item Arguments: \%vals
2113
2114 =item Return Value: a L<DBIx::Class::Row> $object
2115
2116 =back
2117
2118 Attempt to create a single new row or a row with multiple related rows
2119 in the table represented by the resultset (and related tables). This
2120 will not check for duplicate rows before inserting, use
2121 L</find_or_create> to do that.
2122
2123 To create one row for this resultset, pass a hashref of key/value
2124 pairs representing the columns of the table and the values you wish to
2125 store. If the appropriate relationships are set up, foreign key fields
2126 can also be passed an object representing the foreign row, and the
2127 value will be set to its primary key.
2128
2129 To create related objects, pass a hashref of related-object column values
2130 B<keyed on the relationship name>. If the relationship is of type C<multi>
2131 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2132 The process will correctly identify columns holding foreign keys, and will
2133 transparrently populate them from the keys of the corresponding relation.
2134 This can be applied recursively, and will work correctly for a structure
2135 with an arbitrary depth and width, as long as the relationships actually
2136 exists and the correct column data has been supplied.
2137
2138
2139 Instead of hashrefs of plain related data (key/value pairs), you may
2140 also pass new or inserted objects. New objects (not inserted yet, see
2141 L</new>), will be inserted into their appropriate tables.
2142
2143 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2144
2145 Example of creating a new row.
2146
2147   $person_rs->create({
2148     name=>"Some Person",
2149     email=>"somebody@someplace.com"
2150   });
2151
2152 Example of creating a new row and also creating rows in a related C<has_many>
2153 or C<has_one> resultset.  Note Arrayref.
2154
2155   $artist_rs->create(
2156      { artistid => 4, name => 'Manufactured Crap', cds => [
2157         { title => 'My First CD', year => 2006 },
2158         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2159       ],
2160      },
2161   );
2162
2163 Example of creating a new row and also creating a row in a related
2164 C<belongs_to>resultset. Note Hashref.
2165
2166   $cd_rs->create({
2167     title=>"Music for Silly Walks",
2168     year=>2000,
2169     artist => {
2170       name=>"Silly Musician",
2171     }
2172   });
2173
2174 =over
2175
2176 =item WARNING
2177
2178 When subclassing ResultSet never attempt to override this method. Since
2179 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2180 lot of the internals simply never call it, so your override will be
2181 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2182 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2183 L</create> process you need to intervene.
2184
2185 =back
2186
2187 =cut
2188
2189 sub create {
2190   my ($self, $attrs) = @_;
2191   $self->throw_exception( "create needs a hashref" )
2192     unless ref $attrs eq 'HASH';
2193   return $self->new_result($attrs)->insert;
2194 }
2195
2196 =head2 find_or_create
2197
2198 =over 4
2199
2200 =item Arguments: \%vals, \%attrs?
2201
2202 =item Return Value: $rowobject
2203
2204 =back
2205
2206   $cd->cd_to_producer->find_or_create({ producer => $producer },
2207                                       { key => 'primary' });
2208
2209 Tries to find a record based on its primary key or unique constraints; if none
2210 is found, creates one and returns that instead.
2211
2212   my $cd = $schema->resultset('CD')->find_or_create({
2213     cdid   => 5,
2214     artist => 'Massive Attack',
2215     title  => 'Mezzanine',
2216     year   => 2005,
2217   });
2218
2219 Also takes an optional C<key> attribute, to search by a specific key or unique
2220 constraint. For example:
2221
2222   my $cd = $schema->resultset('CD')->find_or_create(
2223     {
2224       artist => 'Massive Attack',
2225       title  => 'Mezzanine',
2226     },
2227     { key => 'cd_artist_title' }
2228   );
2229
2230 B<Note>: Because find_or_create() reads from the database and then
2231 possibly inserts based on the result, this method is subject to a race
2232 condition. Another process could create a record in the table after
2233 the find has completed and before the create has started. To avoid
2234 this problem, use find_or_create() inside a transaction.
2235
2236 B<Note>: Take care when using C<find_or_create> with a table having
2237 columns with default values that you intend to be automatically
2238 supplied by the database (e.g. an auto_increment primary key column).
2239 In normal usage, the value of such columns should NOT be included at
2240 all in the call to C<find_or_create>, even when set to C<undef>.
2241
2242 See also L</find> and L</update_or_create>. For information on how to declare
2243 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2244
2245 =cut
2246
2247 sub find_or_create {
2248   my $self     = shift;
2249   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2250   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2251   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2252     return $row;
2253   }
2254   return $self->create($hash);
2255 }
2256
2257 =head2 update_or_create
2258
2259 =over 4
2260
2261 =item Arguments: \%col_values, { key => $unique_constraint }?
2262
2263 =item Return Value: $rowobject
2264
2265 =back
2266
2267   $resultset->update_or_create({ col => $val, ... });
2268
2269 First, searches for an existing row matching one of the unique constraints
2270 (including the primary key) on the source of this resultset. If a row is
2271 found, updates it with the other given column values. Otherwise, creates a new
2272 row.
2273
2274 Takes an optional C<key> attribute to search on a specific unique constraint.
2275 For example:
2276
2277   # In your application
2278   my $cd = $schema->resultset('CD')->update_or_create(
2279     {
2280       artist => 'Massive Attack',
2281       title  => 'Mezzanine',
2282       year   => 1998,
2283     },
2284     { key => 'cd_artist_title' }
2285   );
2286
2287   $cd->cd_to_producer->update_or_create({
2288     producer => $producer,
2289     name => 'harry',
2290   }, {
2291     key => 'primary,
2292   });
2293
2294
2295 If no C<key> is specified, it searches on all unique constraints defined on the
2296 source, including the primary key.
2297
2298 If the C<key> is specified as C<primary>, it searches only on the primary key.
2299
2300 See also L</find> and L</find_or_create>. For information on how to declare
2301 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2302
2303 B<Note>: Take care when using C<update_or_create> with a table having
2304 columns with default values that you intend to be automatically
2305 supplied by the database (e.g. an auto_increment primary key column).
2306 In normal usage, the value of such columns should NOT be included at
2307 all in the call to C<update_or_create>, even when set to C<undef>.
2308
2309 =cut
2310
2311 sub update_or_create {
2312   my $self = shift;
2313   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2314   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2315
2316   my $row = $self->find($cond, $attrs);
2317   if (defined $row) {
2318     $row->update($cond);
2319     return $row;
2320   }
2321
2322   return $self->create($cond);
2323 }
2324
2325 =head2 update_or_new
2326
2327 =over 4
2328
2329 =item Arguments: \%col_values, { key => $unique_constraint }?
2330
2331 =item Return Value: $rowobject
2332
2333 =back
2334
2335   $resultset->update_or_new({ col => $val, ... });
2336
2337 First, searches for an existing row matching one of the unique constraints
2338 (including the primary key) on the source of this resultset. If a row is
2339 found, updates it with the other given column values. Otherwise, instantiate
2340 a new result object and return it. The object will not be saved into your storage
2341 until you call L<DBIx::Class::Row/insert> on it.
2342
2343 Takes an optional C<key> attribute to search on a specific unique constraint.
2344 For example:
2345
2346   # In your application
2347   my $cd = $schema->resultset('CD')->update_or_new(
2348     {
2349       artist => 'Massive Attack',
2350       title  => 'Mezzanine',
2351       year   => 1998,
2352     },
2353     { key => 'cd_artist_title' }
2354   );
2355
2356   if ($cd->in_storage) {
2357       # the cd was updated
2358   }
2359   else {
2360       # the cd is not yet in the database, let's insert it
2361       $cd->insert;
2362   }
2363
2364 B<Note>: Take care when using C<update_or_new> with a table having
2365 columns with default values that you intend to be automatically
2366 supplied by the database (e.g. an auto_increment primary key column).
2367 In normal usage, the value of such columns should NOT be included at
2368 all in the call to C<update_or_new>, even when set to C<undef>.
2369
2370 See also L</find>, L</find_or_create> and L</find_or_new>.
2371
2372 =cut
2373
2374 sub update_or_new {
2375     my $self  = shift;
2376     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2377     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2378
2379     my $row = $self->find( $cond, $attrs );
2380     if ( defined $row ) {
2381         $row->update($cond);
2382         return $row;
2383     }
2384
2385     return $self->new_result($cond);
2386 }
2387
2388 =head2 get_cache
2389
2390 =over 4
2391
2392 =item Arguments: none
2393
2394 =item Return Value: \@cache_objects?
2395
2396 =back
2397
2398 Gets the contents of the cache for the resultset, if the cache is set.
2399
2400 The cache is populated either by using the L</prefetch> attribute to
2401 L</search> or by calling L</set_cache>.
2402
2403 =cut
2404
2405 sub get_cache {
2406   shift->{all_cache};
2407 }
2408
2409 =head2 set_cache
2410
2411 =over 4
2412
2413 =item Arguments: \@cache_objects
2414
2415 =item Return Value: \@cache_objects
2416
2417 =back
2418
2419 Sets the contents of the cache for the resultset. Expects an arrayref
2420 of objects of the same class as those produced by the resultset. Note that
2421 if the cache is set the resultset will return the cached objects rather
2422 than re-querying the database even if the cache attr is not set.
2423
2424 The contents of the cache can also be populated by using the
2425 L</prefetch> attribute to L</search>.
2426
2427 =cut
2428
2429 sub set_cache {
2430   my ( $self, $data ) = @_;
2431   $self->throw_exception("set_cache requires an arrayref")
2432       if defined($data) && (ref $data ne 'ARRAY');
2433   $self->{all_cache} = $data;
2434 }
2435
2436 =head2 clear_cache
2437
2438 =over 4
2439
2440 =item Arguments: none
2441
2442 =item Return Value: []
2443
2444 =back
2445
2446 Clears the cache for the resultset.
2447
2448 =cut
2449
2450 sub clear_cache {
2451   shift->set_cache(undef);
2452 }
2453
2454 =head2 is_paged
2455
2456 =over 4
2457
2458 =item Arguments: none
2459
2460 =item Return Value: true, if the resultset has been paginated
2461
2462 =back
2463
2464 =cut
2465
2466 sub is_paged {
2467   my ($self) = @_;
2468   return !!$self->{attrs}{page};
2469 }
2470
2471 =head2 related_resultset
2472
2473 =over 4
2474
2475 =item Arguments: $relationship_name
2476
2477 =item Return Value: $resultset
2478
2479 =back
2480
2481 Returns a related resultset for the supplied relationship name.
2482
2483   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2484
2485 =cut
2486
2487 sub related_resultset {
2488   my ($self, $rel) = @_;
2489
2490   $self->{related_resultsets} ||= {};
2491   return $self->{related_resultsets}{$rel} ||= do {
2492     my $rsrc = $self->result_source;
2493     my $rel_info = $rsrc->relationship_info($rel);
2494
2495     $self->throw_exception(
2496       "search_related: result source '" . $rsrc->source_name .
2497         "' has no such relationship $rel")
2498       unless $rel_info;
2499
2500     my $attrs = $self->_chain_relationship($rel);
2501
2502     my $join_count = $attrs->{seen_join}{$rel};
2503     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2504
2505     # since this is search_related, and we already slid the select window inwards
2506     # (the select/as attrs were deleted in the beginning), we need to flip all
2507     # left joins to inner, so we get the expected results
2508     # read the comment on top of the actual function to see what this does
2509     $attrs->{from} = $rsrc->schema->storage->_straight_join_to_node ($attrs->{from}, $alias);
2510
2511     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2512     delete @{$attrs}{qw(result_class alias)};
2513
2514     my $new_cache;
2515
2516     if (my $cache = $self->get_cache) {
2517       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2518         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2519                         @$cache ];
2520       }
2521     }
2522
2523     my $rel_source = $rsrc->related_source($rel);
2524
2525     my $new = do {
2526
2527       # The reason we do this now instead of passing the alias to the
2528       # search_rs below is that if you wrap/overload resultset on the
2529       # source you need to know what alias it's -going- to have for things
2530       # to work sanely (e.g. RestrictWithObject wants to be able to add
2531       # extra query restrictions, and these may need to be $alias.)
2532
2533       my $rel_attrs = $rel_source->resultset_attributes;
2534       local $rel_attrs->{alias} = $alias;
2535
2536       $rel_source->resultset
2537                  ->search_rs(
2538                      undef, {
2539                        %$attrs,
2540                        where => $attrs->{where},
2541                    });
2542     };
2543     $new->set_cache($new_cache) if $new_cache;
2544     $new;
2545   };
2546 }
2547
2548 =head2 current_source_alias
2549
2550 =over 4
2551
2552 =item Arguments: none
2553
2554 =item Return Value: $source_alias
2555
2556 =back
2557
2558 Returns the current table alias for the result source this resultset is built
2559 on, that will be used in the SQL query. Usually it is C<me>.
2560
2561 Currently the source alias that refers to the result set returned by a
2562 L</search>/L</find> family method depends on how you got to the resultset: it's
2563 C<me> by default, but eg. L</search_related> aliases it to the related result
2564 source name (and keeps C<me> referring to the original result set). The long
2565 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2566 (and make this method unnecessary).
2567
2568 Thus it's currently necessary to use this method in predefined queries (see
2569 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2570 source alias of the current result set:
2571
2572   # in a result set class
2573   sub modified_by {
2574     my ($self, $user) = @_;
2575
2576     my $me = $self->current_source_alias;
2577
2578     return $self->search(
2579       "$me.modified" => $user->id,
2580     );
2581   }
2582
2583 =cut
2584
2585 sub current_source_alias {
2586   my ($self) = @_;
2587
2588   return ($self->{attrs} || {})->{alias} || 'me';
2589 }
2590
2591 # This code is called by search_related, and makes sure there
2592 # is clear separation between the joins before, during, and
2593 # after the relationship. This information is needed later
2594 # in order to properly resolve prefetch aliases (any alias
2595 # with a relation_chain_depth less than the depth of the
2596 # current prefetch is not considered)
2597 #
2598 # The increments happen twice per join. An even number means a
2599 # relationship specified via a search_related, whereas an odd
2600 # number indicates a join/prefetch added via attributes
2601 #
2602 # Also this code will wrap the current resultset (the one we
2603 # chain to) in a subselect IFF it contains limiting attributes
2604 sub _chain_relationship {
2605   my ($self, $rel) = @_;
2606   my $source = $self->result_source;
2607   my $attrs = { %{$self->{attrs}||{}} };
2608
2609   # we need to take the prefetch the attrs into account before we
2610   # ->_resolve_join as otherwise they get lost - captainL
2611   my $join = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2612
2613   delete @{$attrs}{qw/join prefetch collapse distinct select as columns +select +as +columns/};
2614
2615   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
2616
2617   my $from;
2618   my @force_subq_attrs = qw/offset rows group_by having/;
2619
2620   if (
2621     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
2622       ||
2623     $self->_has_resolved_attr (@force_subq_attrs)
2624   ) {
2625     $from = [{
2626       -source_handle => $source->handle,
2627       -alias => $attrs->{alias},
2628       $attrs->{alias} => $self->as_query,
2629     }];
2630     delete @{$attrs}{@force_subq_attrs, 'where'};
2631     $seen->{-relation_chain_depth} = 0;
2632   }
2633   elsif ($attrs->{from}) {  #shallow copy suffices
2634     $from = [ @{$attrs->{from}} ];
2635   }
2636   else {
2637     $from = [{
2638       -source_handle => $source->handle,
2639       -alias => $attrs->{alias},
2640       $attrs->{alias} => $source->from,
2641     }];
2642   }
2643
2644   my $jpath = ($seen->{-relation_chain_depth})
2645     ? $from->[-1][0]{-join_path}
2646     : [];
2647
2648   my @requested_joins = $source->_resolve_join(
2649     $join,
2650     $attrs->{alias},
2651     $seen,
2652     $jpath,
2653   );
2654
2655   push @$from, @requested_joins;
2656
2657   $seen->{-relation_chain_depth}++;
2658
2659   # if $self already had a join/prefetch specified on it, the requested
2660   # $rel might very well be already included. What we do in this case
2661   # is effectively a no-op (except that we bump up the chain_depth on
2662   # the join in question so we could tell it *is* the search_related)
2663   my $already_joined;
2664
2665   # we consider the last one thus reverse
2666   for my $j (reverse @requested_joins) {
2667     if ($rel eq $j->[0]{-join_path}[-1]) {
2668       $j->[0]{-relation_chain_depth}++;
2669       $already_joined++;
2670       last;
2671     }
2672   }
2673 # alternative way to scan the entire chain - not backwards compatible
2674 #  for my $j (reverse @$from) {
2675 #    next unless ref $j eq 'ARRAY';
2676 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2677 #      $j->[0]{-relation_chain_depth}++;
2678 #      $already_joined++;
2679 #      last;
2680 #    }
2681 #  }
2682
2683   unless ($already_joined) {
2684     push @$from, $source->_resolve_join(
2685       $rel,
2686       $attrs->{alias},
2687       $seen,
2688       $jpath,
2689     );
2690   }
2691
2692   $seen->{-relation_chain_depth}++;
2693
2694   return {%$attrs, from => $from, seen_join => $seen};
2695 }
2696
2697 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2698 sub _resolved_attrs_copy {
2699   my $self = shift;
2700   return { %{$self->_resolved_attrs (@_)} };
2701 }
2702
2703 sub _resolved_attrs {
2704   my $self = shift;
2705   return $self->{_attrs} if $self->{_attrs};
2706
2707   my $attrs  = { %{ $self->{attrs} || {} } };
2708   my $source = $self->result_source;
2709   my $alias  = $attrs->{alias};
2710
2711   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2712   my @colbits;
2713
2714   # build columns (as long as select isn't set) into a set of as/select hashes
2715   unless ( $attrs->{select} ) {
2716
2717     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2718       ? @{ delete $attrs->{columns}}
2719       : (
2720           ( delete $attrs->{columns} )
2721             ||
2722           $source->columns
2723         )
2724     ;
2725
2726     @colbits = map {
2727       ( ref($_) eq 'HASH' )
2728       ? $_
2729       : {
2730           (
2731             /^\Q${alias}.\E(.+)$/
2732               ? "$1"
2733               : "$_"
2734           )
2735             =>
2736           (
2737             /\./
2738               ? "$_"
2739               : "${alias}.$_"
2740           )
2741         }
2742     } @cols;
2743   }
2744
2745   # add the additional columns on
2746   foreach ( 'include_columns', '+columns' ) {
2747       push @colbits, map {
2748           ( ref($_) eq 'HASH' )
2749             ? $_
2750             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2751       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2752   }
2753
2754   # start with initial select items
2755   if ( $attrs->{select} ) {
2756     $attrs->{select} =
2757         ( ref $attrs->{select} eq 'ARRAY' )
2758       ? [ @{ $attrs->{select} } ]
2759       : [ $attrs->{select} ];
2760     $attrs->{as} = (
2761       $attrs->{as}
2762       ? (
2763         ref $attrs->{as} eq 'ARRAY'
2764         ? [ @{ $attrs->{as} } ]
2765         : [ $attrs->{as} ]
2766         )
2767       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2768     );
2769   }
2770   else {
2771
2772     # otherwise we intialise select & as to empty
2773     $attrs->{select} = [];
2774     $attrs->{as}     = [];
2775   }
2776
2777   # now add colbits to select/as
2778   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2779   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2780
2781   my $adds;
2782   if ( $adds = delete $attrs->{'+select'} ) {
2783     $adds = [$adds] unless ref $adds eq 'ARRAY';
2784     push(
2785       @{ $attrs->{select} },
2786       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2787     );
2788   }
2789   if ( $adds = delete $attrs->{'+as'} ) {
2790     $adds = [$adds] unless ref $adds eq 'ARRAY';
2791     push( @{ $attrs->{as} }, @$adds );
2792   }
2793
2794   $attrs->{from} ||= [ {
2795     -source_handle => $source->handle,
2796     -alias => $self->{attrs}{alias},
2797     $self->{attrs}{alias} => $source->from,
2798   } ];
2799
2800   if ( $attrs->{join} || $attrs->{prefetch} ) {
2801
2802     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2803       if ref $attrs->{from} ne 'ARRAY';
2804
2805     my $join = delete $attrs->{join} || {};
2806
2807     if ( defined $attrs->{prefetch} ) {
2808       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2809     }
2810
2811     $attrs->{from} =    # have to copy here to avoid corrupting the original
2812       [
2813         @{ $attrs->{from} },
2814         $source->_resolve_join(
2815           $join,
2816           $alias,
2817           { %{ $attrs->{seen_join} || {} } },
2818           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2819             ? $attrs->{from}[-1][0]{-join_path}
2820             : []
2821           ,
2822         )
2823       ];
2824   }
2825
2826   if ( defined $attrs->{order_by} ) {
2827     $attrs->{order_by} = (
2828       ref( $attrs->{order_by} ) eq 'ARRAY'
2829       ? [ @{ $attrs->{order_by} } ]
2830       : [ $attrs->{order_by} || () ]
2831     );
2832   }
2833
2834   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2835     $attrs->{group_by} = [ $attrs->{group_by} ];
2836   }
2837
2838   # generate the distinct induced group_by early, as prefetch will be carried via a
2839   # subquery (since a group_by is present)
2840   if (delete $attrs->{distinct}) {
2841     if ($attrs->{group_by}) {
2842       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2843     }
2844     else {
2845       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2846
2847       # add any order_by parts that are not already present in the group_by
2848       # we need to be careful not to add any named functions/aggregates
2849       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
2850       my %already_grouped = map { $_ => 1 } (@{$attrs->{group_by}});
2851
2852       my $storage = $self->result_source->schema->storage;
2853       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
2854       my @chunks = $storage->sql_maker->_order_by_chunks ($attrs->{order_by});
2855
2856       for my $chunk (map { ref $_ ? @$_ : $_ } (@chunks) ) {
2857         $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
2858         if ($rs_column_list->{$chunk} && not $already_grouped{$chunk}++) {
2859           push @{$attrs->{group_by}}, $chunk;
2860         }
2861       }
2862     }
2863   }
2864
2865   $attrs->{collapse} ||= {};
2866   if ( my $prefetch = delete $attrs->{prefetch} ) {
2867     $prefetch = $self->_merge_attr( {}, $prefetch );
2868
2869     my $prefetch_ordering = [];
2870
2871     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2872
2873     my @prefetch =
2874       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2875
2876     # we need to somehow mark which columns came from prefetch
2877     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2878
2879     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2880     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2881
2882     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2883     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2884   }
2885
2886   # if both page and offset are specified, produce a combined offset
2887   # even though it doesn't make much sense, this is what pre 081xx has
2888   # been doing
2889   if (my $page = delete $attrs->{page}) {
2890     $attrs->{offset} =
2891       ($attrs->{rows} * ($page - 1))
2892             +
2893       ($attrs->{offset} || 0)
2894     ;
2895   }
2896
2897   return $self->{_attrs} = $attrs;
2898 }
2899
2900 sub _joinpath_aliases {
2901   my ($self, $fromspec, $seen) = @_;
2902
2903   my $paths = {};
2904   return $paths unless ref $fromspec eq 'ARRAY';
2905
2906   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2907
2908   if ($cur_depth % 2) {
2909     $self->throw_exception ("-relation_chain_depth is not even, something went horribly wrong ($cur_depth)");
2910   }
2911
2912   for my $j (@$fromspec) {
2913
2914     next if ref $j ne 'ARRAY';
2915     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2916
2917     my $jpath = $j->[0]{-join_path};
2918
2919     my $p = $paths;
2920     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth/2 .. $#$jpath]; #only even depths are actual jpath boundaries
2921     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2922   }
2923
2924   return $paths;
2925 }
2926
2927 sub _rollout_attr {
2928   my ($self, $attr) = @_;
2929
2930   if (ref $attr eq 'HASH') {
2931     return $self->_rollout_hash($attr);
2932   } elsif (ref $attr eq 'ARRAY') {
2933     return $self->_rollout_array($attr);
2934   } else {
2935     return [$attr];
2936   }
2937 }
2938
2939 sub _rollout_array {
2940   my ($self, $attr) = @_;
2941
2942   my @rolled_array;
2943   foreach my $element (@{$attr}) {
2944     if (ref $element eq 'HASH') {
2945       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2946     } elsif (ref $element eq 'ARRAY') {
2947       #  XXX - should probably recurse here
2948       push( @rolled_array, @{$self->_rollout_array($element)} );
2949     } else {
2950       push( @rolled_array, $element );
2951     }
2952   }
2953   return \@rolled_array;
2954 }
2955
2956 sub _rollout_hash {
2957   my ($self, $attr) = @_;
2958
2959   my @rolled_array;
2960   foreach my $key (keys %{$attr}) {
2961     push( @rolled_array, { $key => $attr->{$key} } );
2962   }
2963   return \@rolled_array;
2964 }
2965
2966 sub _calculate_score {
2967   my ($self, $a, $b) = @_;
2968
2969   if (defined $a xor defined $b) {
2970     return 0;
2971   }
2972   elsif (not defined $a) {
2973     return 1;
2974   }
2975
2976   if (ref $b eq 'HASH') {
2977     my ($b_key) = keys %{$b};
2978     if (ref $a eq 'HASH') {
2979       my ($a_key) = keys %{$a};
2980       if ($a_key eq $b_key) {
2981         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2982       } else {
2983         return 0;
2984       }
2985     } else {
2986       return ($a eq $b_key) ? 1 : 0;
2987     }
2988   } else {
2989     if (ref $a eq 'HASH') {
2990       my ($a_key) = keys %{$a};
2991       return ($b eq $a_key) ? 1 : 0;
2992     } else {
2993       return ($b eq $a) ? 1 : 0;
2994     }
2995   }
2996 }
2997
2998 sub _merge_attr {
2999   my ($self, $orig, $import) = @_;
3000
3001   return $import unless defined($orig);
3002   return $orig unless defined($import);
3003
3004   $orig = $self->_rollout_attr($orig);
3005   $import = $self->_rollout_attr($import);
3006
3007   my $seen_keys;
3008   foreach my $import_element ( @{$import} ) {
3009     # find best candidate from $orig to merge $b_element into
3010     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3011     foreach my $orig_element ( @{$orig} ) {
3012       my $score = $self->_calculate_score( $orig_element, $import_element );
3013       if ($score > $best_candidate->{score}) {
3014         $best_candidate->{position} = $position;
3015         $best_candidate->{score} = $score;
3016       }
3017       $position++;
3018     }
3019     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3020
3021     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3022       push( @{$orig}, $import_element );
3023     } else {
3024       my $orig_best = $orig->[$best_candidate->{position}];
3025       # merge orig_best and b_element together and replace original with merged
3026       if (ref $orig_best ne 'HASH') {
3027         $orig->[$best_candidate->{position}] = $import_element;
3028       } elsif (ref $import_element eq 'HASH') {
3029         my ($key) = keys %{$orig_best};
3030         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3031       }
3032     }
3033     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3034   }
3035
3036   return $orig;
3037 }
3038
3039 sub result_source {
3040     my $self = shift;
3041
3042     if (@_) {
3043         $self->_source_handle($_[0]->handle);
3044     } else {
3045         $self->_source_handle->resolve;
3046     }
3047 }
3048
3049 =head2 throw_exception
3050
3051 See L<DBIx::Class::Schema/throw_exception> for details.
3052
3053 =cut
3054
3055 sub throw_exception {
3056   my $self=shift;
3057
3058   if (ref $self && $self->_source_handle->schema) {
3059     $self->_source_handle->schema->throw_exception(@_)
3060   }
3061   else {
3062     DBIx::Class::Exception->throw(@_);
3063   }
3064 }
3065
3066 # XXX: FIXME: Attributes docs need clearing up
3067
3068 =head1 ATTRIBUTES
3069
3070 Attributes are used to refine a ResultSet in various ways when
3071 searching for data. They can be passed to any method which takes an
3072 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3073 L</count>.
3074
3075 These are in no particular order:
3076
3077 =head2 order_by
3078
3079 =over 4
3080
3081 =item Value: ( $order_by | \@order_by | \%order_by )
3082
3083 =back
3084
3085 Which column(s) to order the results by.
3086
3087 [The full list of suitable values is documented in
3088 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3089 common options.]
3090
3091 If a single column name, or an arrayref of names is supplied, the
3092 argument is passed through directly to SQL. The hashref syntax allows
3093 for connection-agnostic specification of ordering direction:
3094
3095  For descending order:
3096
3097   order_by => { -desc => [qw/col1 col2 col3/] }
3098
3099  For explicit ascending order:
3100
3101   order_by => { -asc => 'col' }
3102
3103 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3104 supported, although you are strongly encouraged to use the hashref
3105 syntax as outlined above.
3106
3107 =head2 columns
3108
3109 =over 4
3110
3111 =item Value: \@columns
3112
3113 =back
3114
3115 Shortcut to request a particular set of columns to be retrieved. Each
3116 column spec may be a string (a table column name), or a hash (in which
3117 case the key is the C<as> value, and the value is used as the C<select>
3118 expression). Adds C<me.> onto the start of any column without a C<.> in
3119 it and sets C<select> from that, then auto-populates C<as> from
3120 C<select> as normal. (You may also use the C<cols> attribute, as in
3121 earlier versions of DBIC.)
3122
3123 =head2 +columns
3124
3125 =over 4
3126
3127 =item Value: \@columns
3128
3129 =back
3130
3131 Indicates additional columns to be selected from storage. Works the same
3132 as L</columns> but adds columns to the selection. (You may also use the
3133 C<include_columns> attribute, as in earlier versions of DBIC). For
3134 example:-
3135
3136   $schema->resultset('CD')->search(undef, {
3137     '+columns' => ['artist.name'],
3138     join => ['artist']
3139   });
3140
3141 would return all CDs and include a 'name' column to the information
3142 passed to object inflation. Note that the 'artist' is the name of the
3143 column (or relationship) accessor, and 'name' is the name of the column
3144 accessor in the related table.
3145
3146 =head2 include_columns
3147
3148 =over 4
3149
3150 =item Value: \@columns
3151
3152 =back
3153
3154 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3155
3156 =head2 select
3157
3158 =over 4
3159
3160 =item Value: \@select_columns
3161
3162 =back
3163
3164 Indicates which columns should be selected from the storage. You can use
3165 column names, or in the case of RDBMS back ends, function or stored procedure
3166 names:
3167
3168   $rs = $schema->resultset('Employee')->search(undef, {
3169     select => [
3170       'name',
3171       { count => 'employeeid' },
3172       { sum => 'salary' }
3173     ]
3174   });
3175
3176 When you use function/stored procedure names and do not supply an C<as>
3177 attribute, the column names returned are storage-dependent. E.g. MySQL would
3178 return a column named C<count(employeeid)> in the above example.
3179
3180 B<NOTE:> You will almost always need a corresponding 'as' entry when you use
3181 'select'.
3182
3183 =head2 +select
3184
3185 =over 4
3186
3187 Indicates additional columns to be selected from storage.  Works the same as
3188 L</select> but adds columns to the selection.
3189
3190 =back
3191
3192 =head2 +as
3193
3194 =over 4
3195
3196 Indicates additional column names for those added via L</+select>. See L</as>.
3197
3198 =back
3199
3200 =head2 as
3201
3202 =over 4
3203
3204 =item Value: \@inflation_names
3205
3206 =back
3207
3208 Indicates column names for object inflation. That is, C<as>
3209 indicates the name that the column can be accessed as via the
3210 C<get_column> method (or via the object accessor, B<if one already
3211 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3212
3213 The C<as> attribute is used in conjunction with C<select>,
3214 usually when C<select> contains one or more function or stored
3215 procedure names:
3216
3217   $rs = $schema->resultset('Employee')->search(undef, {
3218     select => [
3219       'name',
3220       { count => 'employeeid' }
3221     ],
3222     as => ['name', 'employee_count'],
3223   });
3224
3225   my $employee = $rs->first(); # get the first Employee
3226
3227 If the object against which the search is performed already has an accessor
3228 matching a column name specified in C<as>, the value can be retrieved using
3229 the accessor as normal:
3230
3231   my $name = $employee->name();
3232
3233 If on the other hand an accessor does not exist in the object, you need to
3234 use C<get_column> instead:
3235
3236   my $employee_count = $employee->get_column('employee_count');
3237
3238 You can create your own accessors if required - see
3239 L<DBIx::Class::Manual::Cookbook> for details.
3240
3241 Please note: This will NOT insert an C<AS employee_count> into the SQL
3242 statement produced, it is used for internal access only. Thus
3243 attempting to use the accessor in an C<order_by> clause or similar
3244 will fail miserably.
3245
3246 To get around this limitation, you can supply literal SQL to your
3247 C<select> attibute that contains the C<AS alias> text, eg:
3248
3249   select => [\'myfield AS alias']
3250
3251 =head2 join
3252
3253 =over 4
3254
3255 =item Value: ($rel_name | \@rel_names | \%rel_names)
3256
3257 =back
3258
3259 Contains a list of relationships that should be joined for this query.  For
3260 example:
3261
3262   # Get CDs by Nine Inch Nails
3263   my $rs = $schema->resultset('CD')->search(
3264     { 'artist.name' => 'Nine Inch Nails' },
3265     { join => 'artist' }
3266   );
3267
3268 Can also contain a hash reference to refer to the other relation's relations.
3269 For example:
3270
3271   package MyApp::Schema::Track;
3272   use base qw/DBIx::Class/;
3273   __PACKAGE__->table('track');
3274   __PACKAGE__->add_columns(qw/trackid cd position title/);
3275   __PACKAGE__->set_primary_key('trackid');
3276   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3277   1;
3278
3279   # In your application
3280   my $rs = $schema->resultset('Artist')->search(
3281     { 'track.title' => 'Teardrop' },
3282     {
3283       join     => { cd => 'track' },
3284       order_by => 'artist.name',
3285     }
3286   );
3287
3288 You need to use the relationship (not the table) name in  conditions,
3289 because they are aliased as such. The current table is aliased as "me", so
3290 you need to use me.column_name in order to avoid ambiguity. For example:
3291
3292   # Get CDs from 1984 with a 'Foo' track
3293   my $rs = $schema->resultset('CD')->search(
3294     {
3295       'me.year' => 1984,
3296       'tracks.name' => 'Foo'
3297     },
3298     { join => 'tracks' }
3299   );
3300
3301 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3302 similarly for a third time). For e.g.
3303
3304   my $rs = $schema->resultset('Artist')->search({
3305     'cds.title'   => 'Down to Earth',
3306     'cds_2.title' => 'Popular',
3307   }, {
3308     join => [ qw/cds cds/ ],
3309   });
3310
3311 will return a set of all artists that have both a cd with title 'Down
3312 to Earth' and a cd with title 'Popular'.
3313
3314 If you want to fetch related objects from other tables as well, see C<prefetch>
3315 below.
3316
3317 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3318
3319 =head2 prefetch
3320
3321 =over 4
3322
3323 =item Value: ($rel_name | \@rel_names | \%rel_names)
3324
3325 =back
3326
3327 Contains one or more relationships that should be fetched along with
3328 the main query (when they are accessed afterwards the data will
3329 already be available, without extra queries to the database).  This is
3330 useful for when you know you will need the related objects, because it
3331 saves at least one query:
3332
3333   my $rs = $schema->resultset('Tag')->search(
3334     undef,
3335     {
3336       prefetch => {
3337         cd => 'artist'
3338       }
3339     }
3340   );
3341
3342 The initial search results in SQL like the following:
3343
3344   SELECT tag.*, cd.*, artist.* FROM tag
3345   JOIN cd ON tag.cd = cd.cdid
3346   JOIN artist ON cd.artist = artist.artistid
3347
3348 L<DBIx::Class> has no need to go back to the database when we access the
3349 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3350 case.
3351
3352 Simple prefetches will be joined automatically, so there is no need
3353 for a C<join> attribute in the above search.
3354
3355 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3356 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3357 with an accessor type of 'single' or 'filter'). A more complex example that
3358 prefetches an artists cds, the tracks on those cds, and the tags associted
3359 with that artist is given below (assuming many-to-many from artists to tags):
3360
3361  my $rs = $schema->resultset('Artist')->search(
3362    undef,
3363    {
3364      prefetch => [
3365        { cds => 'tracks' },
3366        { artist_tags => 'tags' }
3367      ]
3368    }
3369  );
3370
3371
3372 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3373 attributes will be ignored.
3374
3375 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3376 exactly as you might expect.
3377
3378 =over 4
3379
3380 =item *
3381
3382 Prefetch uses the L</cache> to populate the prefetched relationships. This
3383 may or may not be what you want.
3384
3385 =item *
3386
3387 If you specify a condition on a prefetched relationship, ONLY those
3388 rows that match the prefetched condition will be fetched into that relationship.
3389 This means that adding prefetch to a search() B<may alter> what is returned by
3390 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3391
3392   my $artist_rs = $schema->resultset('Artist')->search({
3393       'cds.year' => 2008,
3394   }, {
3395       join => 'cds',
3396   });
3397
3398   my $count = $artist_rs->first->cds->count;
3399
3400   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3401
3402   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3403
3404   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3405
3406 that cmp_ok() may or may not pass depending on the datasets involved. This
3407 behavior may or may not survive the 0.09 transition.
3408
3409 =back
3410
3411 =head2 page
3412
3413 =over 4
3414
3415 =item Value: $page
3416
3417 =back
3418
3419 Makes the resultset paged and specifies the page to retrieve. Effectively
3420 identical to creating a non-pages resultset and then calling ->page($page)
3421 on it.
3422
3423 If L<rows> attribute is not specified it defaults to 10 rows per page.
3424
3425 When you have a paged resultset, L</count> will only return the number
3426 of rows in the page. To get the total, use the L</pager> and call
3427 C<total_entries> on it.
3428
3429 =head2 rows
3430
3431 =over 4
3432
3433 =item Value: $rows
3434
3435 =back
3436
3437 Specifes the maximum number of rows for direct retrieval or the number of
3438 rows per page if the page attribute or method is used.
3439
3440 =head2 offset
3441
3442 =over 4
3443
3444 =item Value: $offset
3445
3446 =back
3447
3448 Specifies the (zero-based) row number for the  first row to be returned, or the
3449 of the first row of the first page if paging is used.
3450
3451 =head2 group_by
3452
3453 =over 4
3454
3455 =item Value: \@columns
3456
3457 =back
3458
3459 A arrayref of columns to group by. Can include columns of joined tables.
3460
3461   group_by => [qw/ column1 column2 ... /]
3462
3463 =head2 having
3464
3465 =over 4
3466
3467 =item Value: $condition
3468
3469 =back
3470
3471 HAVING is a select statement attribute that is applied between GROUP BY and
3472 ORDER BY. It is applied to the after the grouping calculations have been
3473 done.
3474
3475   having => { 'count(employee)' => { '>=', 100 } }
3476
3477 =head2 distinct
3478
3479 =over 4
3480
3481 =item Value: (0 | 1)
3482
3483 =back
3484
3485 Set to 1 to group by all columns. If the resultset already has a group_by
3486 attribute, this setting is ignored and an appropriate warning is issued.
3487
3488 =head2 where
3489
3490 =over 4
3491
3492 Adds to the WHERE clause.
3493
3494   # only return rows WHERE deleted IS NULL for all searches
3495   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3496
3497 Can be overridden by passing C<< { where => undef } >> as an attribute
3498 to a resultset.
3499
3500 =back
3501
3502 =head2 cache
3503
3504 Set to 1 to cache search results. This prevents extra SQL queries if you
3505 revisit rows in your ResultSet:
3506
3507   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3508
3509   while( my $artist = $resultset->next ) {
3510     ... do stuff ...
3511   }
3512
3513   $rs->first; # without cache, this would issue a query
3514
3515 By default, searches are not cached.
3516
3517 For more examples of using these attributes, see
3518 L<DBIx::Class::Manual::Cookbook>.
3519
3520 =head2 for
3521
3522 =over 4
3523
3524 =item Value: ( 'update' | 'shared' )
3525
3526 =back
3527
3528 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3529 ... FOR SHARED.
3530
3531 =cut
3532
3533 1;