lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 195
 196 =item Return Value: L<$resultset|/search>
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you never construct a resultset manually. Instead you get one
 206 from e.g. a
 207 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 208 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 209 scalar context):
 210
 211   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 212
 213 =over
 214
 215 =item WARNING
 216
 217 If called on an object, proxies to L</new_result> instead, so
 218
 219   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 220
 221 will return a CD object, not a ResultSet, and is equivalent to:
 222
 223   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 224
 225 Please also keep in mind that many internals call L</new_result> directly,
 226 so overloading this method with the idea of intercepting new result object
 227 creation B<will not work>. See also warning pertaining to L</create>.
 228
 229 =back
 230
 231 =cut
 232
 233 sub new {
 234   my $class = shift;
 235   return $class->new_result(@_) if ref $class;
 236
 237   my ($source, $attrs) = @_;
 238   $source = $source->resolve
 239     if $source->isa('DBIx::Class::ResultSourceHandle');
 240   $attrs = { %{$attrs||{}} };
 241
 242   if ($attrs->{page}) {
 243     $attrs->{rows} ||= 10;
 244   }
 245
 246   $attrs->{alias} ||= 'me';
 247
 248   my $self = bless {
 249     result_source => $source,
 250     cond => $attrs->{where},
 251     pager => undef,
 252     attrs => $attrs,
 253   }, $class;
 254
 255   # if there is a dark selector, this means we are already in a
 256   # chain and the cleanup/sanification was taken care of by
 257   # _search_rs already
 258   $self->_normalize_selection($attrs)
 259     unless $attrs->{_dark_selector};
 260
 261   $self->result_class(
 262     $attrs->{result_class} || $source->result_class
 263   );
 264
 265   $self;
 266 }
 267
 268 =head2 search
 269
 270 =over 4
 271
 272 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 273
 274 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 275
 276 =back
 277
 278   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 279   my $new_rs = $cd_rs->search({ year => 2005 });
 280
 281   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 282                  # year = 2005 OR year = 2004
 283
 284 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 285 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 286 To avoid that, use L</search_rs>.
 287
 288 If you need to pass in additional attributes but no additional condition,
 289 call it as C<search(undef, \%attrs)>.
 290
 291   # "SELECT name, artistid FROM $artist_table"
 292   my @all_artists = $schema->resultset('Artist')->search(undef, {
 293     columns => [qw/name artistid/],
 294   });
 295
 296 For a list of attributes that can be passed to C<search>, see
 297 L</ATTRIBUTES>. For more examples of using this function, see
 298 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 299 documentation for the first argument, see L<SQL::Abstract>
 300 and its extension L<DBIx::Class::SQLMaker>.
 301
 302 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 303
 304 =head3 CAVEAT
 305
 306 Note that L</search> does not process/deflate any of the values passed in the
 307 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 308 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 309 manually that any value passed to this method will stringify to something the
 310 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 311 objects, for more info see:
 312 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 313
 314 =cut
 315
 316 sub search {
 317   my $self = shift;
 318   my $rs = $self->search_rs( @_ );
 319
 320   if (wantarray) {
 321     return $rs->all;
 322   }
 323   elsif (defined wantarray) {
 324     return $rs;
 325   }
 326   else {
 327     # we can be called by a relationship helper, which in
 328     # turn may be called in void context due to some braindead
 329     # overload or whatever else the user decided to be clever
 330     # at this particular day. Thus limit the exception to
 331     # external code calls only
 332     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 333       if (caller)[0] !~ /^\QDBIx::Class::/;
 334
 335     return ();
 336   }
 337 }
 338
 339 =head2 search_rs
 340
 341 =over 4
 342
 343 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 344
 345 =item Return Value: L<$resultset|/search>
 346
 347 =back
 348
 349 This method does the same exact thing as search() except it will
 350 always return a resultset, even in list context.
 351
 352 =cut
 353
 354 sub search_rs {
 355   my $self = shift;
 356
 357   my $rsrc = $self->result_source;
 358   my ($call_cond, $call_attrs);
 359
 360   # Special-case handling for (undef, undef) or (undef)
 361   # Note that (foo => undef) is valid deprecated syntax
 362   @_ = () if not scalar grep { defined $_ } @_;
 363
 364   # just a cond
 365   if (@_ == 1) {
 366     $call_cond = shift;
 367   }
 368   # fish out attrs in the ($condref, $attr) case
 369   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 370     ($call_cond, $call_attrs) = @_;
 371   }
 372   elsif (@_ % 2) {
 373     $self->throw_exception('Odd number of arguments to search')
 374   }
 375   # legacy search
 376   elsif (@_) {
 377     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 378       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 379
 380     for my $i (0 .. $#_) {
 381       next if $i % 2;
 382       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 383         if (! defined $_[$i] or ref $_[$i] ne '');
 384     }
 385
 386     $call_cond = { @_ };
 387   }
 388
 389   # see if we can keep the cache (no $rs changes)
 390   my $cache;
 391   my %safe = (alias => 1, cache => 1);
 392   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 393     ! defined $_[0]
 394       or
 395     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 396       or
 397     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 398   )) {
 399     $cache = $self->get_cache;
 400   }
 401
 402   my $old_attrs = { %{$self->{attrs}} };
 403   my $old_having = delete $old_attrs->{having};
 404   my $old_where = delete $old_attrs->{where};
 405
 406   my $new_attrs = { %$old_attrs };
 407
 408   # take care of call attrs (only if anything is changing)
 409   if ($call_attrs and keys %$call_attrs) {
 410
 411     # copy for _normalize_selection
 412     $call_attrs = { %$call_attrs };
 413
 414     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 415
 416     # reset the current selector list if new selectors are supplied
 417     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 418       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 419     }
 420
 421     # Normalize the new selector list (operates on the passed-in attr structure)
 422     # Need to do it on every chain instead of only once on _resolved_attrs, in
 423     # order to allow detection of empty vs partial 'as'
 424     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 425       if $old_attrs->{_dark_selector};
 426     $self->_normalize_selection ($call_attrs);
 427
 428     # start with blind overwriting merge, exclude selector attrs
 429     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 430     delete @{$new_attrs}{@selector_attrs};
 431
 432     for (@selector_attrs) {
 433       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 434         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 435     }
 436
 437     # older deprecated name, use only if {columns} is not there
 438     if (my $c = delete $new_attrs->{cols}) {
 439       if ($new_attrs->{columns}) {
 440         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 441       }
 442       else {
 443         $new_attrs->{columns} = $c;
 444       }
 445     }
 446
 447
 448     # join/prefetch use their own crazy merging heuristics
 449     foreach my $key (qw/join prefetch/) {
 450       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 451         if exists $call_attrs->{$key};
 452     }
 453
 454     # stack binds together
 455     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 456   }
 457
 458
 459   for ($old_where, $call_cond) {
 460     if (defined $_) {
 461       $new_attrs->{where} = $self->_stack_cond (
 462         $_, $new_attrs->{where}
 463       );
 464     }
 465   }
 466
 467   if (defined $old_having) {
 468     $new_attrs->{having} = $self->_stack_cond (
 469       $old_having, $new_attrs->{having}
 470     )
 471   }
 472
 473   my $rs = (ref $self)->new($rsrc, $new_attrs);
 474
 475   $rs->set_cache($cache) if ($cache);
 476
 477   return $rs;
 478 }
 479
 480 my $dark_sel_dumper;
 481 sub _normalize_selection {
 482   my ($self, $attrs) = @_;
 483
 484   # legacy syntax
 485   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 486     if exists $attrs->{include_columns};
 487
 488   # columns are always placed first, however
 489
 490   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 491   # delay the decision on whether to use a default select list ($rsrc->columns)
 492   # allowing stuff like the remove_columns helper to work
 493   #
 494   # select/as +select/+as pairs need special handling - the amount of select/as
 495   # elements in each pair does *not* have to be equal (think multicolumn
 496   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 497   # supplied at all) - try to infer the alias, either from the -as parameter
 498   # of the selector spec, or use the parameter whole if it looks like a column
 499   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 500   # is ok as well), but make sure no more additions to the 'as' chain take place
 501   for my $pref ('', '+') {
 502
 503     my ($sel, $as) = map {
 504       my $key = "${pref}${_}";
 505
 506       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 507         ? @{$attrs->{$key}}
 508         : $attrs->{$key} || ()
 509       ];
 510       delete $attrs->{$key};
 511       $val;
 512     } qw/select as/;
 513
 514     if (! @$as and ! @$sel ) {
 515       next;
 516     }
 517     elsif (@$as and ! @$sel) {
 518       $self->throw_exception(
 519         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 520       );
 521     }
 522     elsif( ! @$as ) {
 523       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 524       # if any @$as has been supplied we assume the user knows what (s)he is doing
 525       # and blindly keep stacking up pieces
 526       unless ($attrs->{_dark_selector}) {
 527         SELECTOR:
 528         for (@$sel) {
 529           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 530             push @$as, $_->{-as};
 531           }
 532           # assume any plain no-space, no-parenthesis string to be a column spec
 533           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 534           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 535             push @$as, $_;
 536           }
 537           # if all else fails - raise a flag that no more aliasing will be allowed
 538           else {
 539             $attrs->{_dark_selector} = {
 540               plus_stage => $pref,
 541               string => ($dark_sel_dumper ||= do {
 542                   require Data::Dumper::Concise;
 543                   Data::Dumper::Concise::DumperObject()->Indent(0);
 544                 })->Values([$_])->Dump
 545               ,
 546             };
 547             last SELECTOR;
 548           }
 549         }
 550       }
 551     }
 552     elsif (@$as < @$sel) {
 553       $self->throw_exception(
 554         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 555       );
 556     }
 557     elsif ($pref and $attrs->{_dark_selector}) {
 558       $self->throw_exception(
 559         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 560       );
 561     }
 562
 563
 564     # merge result
 565     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 566     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 567   }
 568 }
 569
 570 sub _stack_cond {
 571   my ($self, $left, $right) = @_;
 572
 573   # collapse single element top-level conditions
 574   # (single pass only, unlikely to need recursion)
 575   for ($left, $right) {
 576     if (ref $_ eq 'ARRAY') {
 577       if (@$_ == 0) {
 578         $_ = undef;
 579       }
 580       elsif (@$_ == 1) {
 581         $_ = $_->[0];
 582       }
 583     }
 584     elsif (ref $_ eq 'HASH') {
 585       my ($first, $more) = keys %$_;
 586
 587       # empty hash
 588       if (! defined $first) {
 589         $_ = undef;
 590       }
 591       # one element hash
 592       elsif (! defined $more) {
 593         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 594           $_ = $_->{'-and'};
 595         }
 596         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 597           $_ = $_->{'-or'};
 598         }
 599       }
 600     }
 601   }
 602
 603   # merge hashes with weeding out of duplicates (simple cases only)
 604   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 605
 606     # shallow copy to destroy
 607     $right = { %$right };
 608     for (grep { exists $right->{$_} } keys %$left) {
 609       # the use of eq_deeply here is justified - the rhs of an
 610       # expression can contain a lot of twisted weird stuff
 611       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 612     }
 613
 614     $right = undef unless keys %$right;
 615   }
 616
 617
 618   if (defined $left xor defined $right) {
 619     return defined $left ? $left : $right;
 620   }
 621   elsif (! defined $left) {
 622     return undef;
 623   }
 624   else {
 625     return { -and => [ $left, $right ] };
 626   }
 627 }
 628
 629 =head2 search_literal
 630
 631 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 632 should only be used in that context. C<search_literal> is a convenience
 633 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 634 want to ensure columns are bound correctly, use L</search>.
 635
 636 See L<DBIx::Class::Manual::Cookbook/Searching> and
 637 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 638 require C<search_literal>.
 639
 640 =over 4
 641
 642 =item Arguments: $sql_fragment, @standalone_bind_values
 643
 644 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 645
 646 =back
 647
 648   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 649   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 650
 651 Pass a literal chunk of SQL to be added to the conditional part of the
 652 resultset query.
 653
 654 Example of how to use C<search> instead of C<search_literal>
 655
 656   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 657   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 658
 659 =cut
 660
 661 sub search_literal {
 662   my ($self, $sql, @bind) = @_;
 663   my $attr;
 664   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 665     $attr = pop @bind;
 666   }
 667   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 668 }
 669
 670 =head2 find
 671
 672 =over 4
 673
 674 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 675
 676 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 677
 678 =back
 679
 680 Finds and returns a single row based on supplied criteria. Takes either a
 681 hashref with the same format as L</create> (including inference of foreign
 682 keys from related objects), or a list of primary key values in the same
 683 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 684 declaration on the L</result_source>.
 685
 686 In either case an attempt is made to combine conditions already existing on
 687 the resultset with the condition passed to this method.
 688
 689 To aid with preparing the correct query for the storage you may supply the
 690 C<key> attribute, which is the name of a
 691 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 692 unique constraint corresponding to the
 693 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 694 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 695 to construct a query that satisfies the named unique constraint fully (
 696 non-NULL values for each column member of the constraint) an exception is
 697 thrown.
 698
 699 If no C<key> is specified, the search is carried over all unique constraints
 700 which are fully defined by the available condition.
 701
 702 If no such constraint is found, C<find> currently defaults to a simple
 703 C<< search->(\%column_values) >> which may or may not do what you expect.
 704 Note that this fallback behavior may be deprecated in further versions. If
 705 you need to search with arbitrary conditions - use L</search>. If the query
 706 resulting from this fallback produces more than one row, a warning to the
 707 effect is issued, though only the first row is constructed and returned as
 708 C<$result_object>.
 709
 710 In addition to C<key>, L</find> recognizes and applies standard
 711 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 712
 713 Note that if you have extra concerns about the correctness of the resulting
 714 query you need to specify the C<key> attribute and supply the entire condition
 715 as an argument to find (since it is not always possible to perform the
 716 combination of the resultset condition with the supplied one, especially if
 717 the resultset condition contains literal sql).
 718
 719 For example, to find a row by its primary key:
 720
 721   my $cd = $schema->resultset('CD')->find(5);
 722
 723 You can also find a row by a specific unique constraint:
 724
 725   my $cd = $schema->resultset('CD')->find(
 726     {
 727       artist => 'Massive Attack',
 728       title  => 'Mezzanine',
 729     },
 730     { key => 'cd_artist_title' }
 731   );
 732
 733 See also L</find_or_create> and L</update_or_create>.
 734
 735 =cut
 736
 737 sub find {
 738   my $self = shift;
 739   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 740
 741   my $rsrc = $self->result_source;
 742
 743   my $constraint_name;
 744   if (exists $attrs->{key}) {
 745     $constraint_name = defined $attrs->{key}
 746       ? $attrs->{key}
 747       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 748     ;
 749   }
 750
 751   # Parse out the condition from input
 752   my $call_cond;
 753
 754   if (ref $_[0] eq 'HASH') {
 755     $call_cond = { %{$_[0]} };
 756   }
 757   else {
 758     # if only values are supplied we need to default to 'primary'
 759     $constraint_name = 'primary' unless defined $constraint_name;
 760
 761     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 762
 763     $self->throw_exception(
 764       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 765     ) unless @c_cols;
 766
 767     $self->throw_exception (
 768       'find() expects either a column/value hashref, or a list of values '
 769     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 770     ) unless @c_cols == @_;
 771
 772     $call_cond = {};
 773     @{$call_cond}{@c_cols} = @_;
 774   }
 775
 776   my %related;
 777   for my $key (keys %$call_cond) {
 778     if (
 779       my $keyref = ref($call_cond->{$key})
 780         and
 781       my $relinfo = $rsrc->relationship_info($key)
 782     ) {
 783       my $val = delete $call_cond->{$key};
 784
 785       next if $keyref eq 'ARRAY'; # has_many for multi_create
 786
 787       my $rel_q = $rsrc->_resolve_condition(
 788         $relinfo->{cond}, $val, $key, $key
 789       );
 790       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 791       @related{keys %$rel_q} = values %$rel_q;
 792     }
 793   }
 794
 795   # relationship conditions take precedence (?)
 796   @{$call_cond}{keys %related} = values %related;
 797
 798   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 799   my $final_cond;
 800   if (defined $constraint_name) {
 801     $final_cond = $self->_qualify_cond_columns (
 802
 803       $self->_build_unique_cond (
 804         $constraint_name,
 805         $call_cond,
 806       ),
 807
 808       $alias,
 809     );
 810   }
 811   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 812     # This means that we got here after a merger of relationship conditions
 813     # in ::Relationship::Base::search_related (the row method), and furthermore
 814     # the relationship is of the 'single' type. This means that the condition
 815     # provided by the relationship (already attached to $self) is sufficient,
 816     # as there can be only one row in the database that would satisfy the
 817     # relationship
 818   }
 819   else {
 820     # no key was specified - fall down to heuristics mode:
 821     # run through all unique queries registered on the resultset, and
 822     # 'OR' all qualifying queries together
 823     my (@unique_queries, %seen_column_combinations);
 824     for my $c_name ($rsrc->unique_constraint_names) {
 825       next if $seen_column_combinations{
 826         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 827       }++;
 828
 829       push @unique_queries, try {
 830         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 831       } || ();
 832     }
 833
 834     $final_cond = @unique_queries
 835       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 836       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 837     ;
 838   }
 839
 840   # Run the query, passing the result_class since it should propagate for find
 841   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 842   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 843     my $row = $rs->next;
 844     carp "Query returned more than one row" if $rs->next;
 845     return $row;
 846   }
 847   else {
 848     return $rs->single;
 849   }
 850 }
 851
 852 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 853 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 854 #
 855 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 856 # condition. It is provided for overrides until a saner way forward is devised
 857 #
 858 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 859 # the road. Please adjust your tests accordingly to catch this situation early
 860 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 861 #
 862 # The method will not be removed without an adequately complete replacement
 863 # for strict-mode enforcement
 864 sub _non_unique_find_fallback {
 865   my ($self, $cond, $attrs) = @_;
 866
 867   return $self->_qualify_cond_columns(
 868     $cond,
 869     exists $attrs->{alias}
 870       ? $attrs->{alias}
 871       : $self->{attrs}{alias}
 872   );
 873 }
 874
 875
 876 sub _qualify_cond_columns {
 877   my ($self, $cond, $alias) = @_;
 878
 879   my %aliased = %$cond;
 880   for (keys %aliased) {
 881     $aliased{"$alias.$_"} = delete $aliased{$_}
 882       if $_ !~ /\./;
 883   }
 884
 885   return \%aliased;
 886 }
 887
 888 sub _build_unique_cond {
 889   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 890
 891   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 892
 893   # combination may fail if $self->{cond} is non-trivial
 894   my ($final_cond) = try {
 895     $self->_merge_with_rscond ($extra_cond)
 896   } catch {
 897     +{ %$extra_cond }
 898   };
 899
 900   # trim out everything not in $columns
 901   $final_cond = { map {
 902     exists $final_cond->{$_}
 903       ? ( $_ => $final_cond->{$_} )
 904       : ()
 905   } @c_cols };
 906
 907   if (my @missing = grep
 908     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 909     (@c_cols)
 910   ) {
 911     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 912       $constraint_name,
 913       join (', ', map { "'$_'" } @missing),
 914     ) );
 915   }
 916
 917   if (
 918     !$croak_on_null
 919       and
 920     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 921       and
 922     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 923   ) {
 924     carp_unique ( sprintf (
 925       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 926     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 927     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 928       $constraint_name,
 929       join (', ', map { "'$_'" } @undefs),
 930     ));
 931   }
 932
 933   return $final_cond;
 934 }
 935
 936 =head2 search_related
 937
 938 =over 4
 939
 940 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 941
 942 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 943
 944 =back
 945
 946   $new_rs = $cd_rs->search_related('artist', {
 947     name => 'Emo-R-Us',
 948   });
 949
 950 Searches the specified relationship, optionally specifying a condition and
 951 attributes for matching records. See L</ATTRIBUTES> for more information.
 952
 953 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 954 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 955
 956 See also L</search_related_rs>.
 957
 958 =cut
 959
 960 sub search_related {
 961   return shift->related_resultset(shift)->search(@_);
 962 }
 963
 964 =head2 search_related_rs
 965
 966 This method works exactly the same as search_related, except that
 967 it guarantees a resultset, even in list context.
 968
 969 =cut
 970
 971 sub search_related_rs {
 972   return shift->related_resultset(shift)->search_rs(@_);
 973 }
 974
 975 =head2 cursor
 976
 977 =over 4
 978
 979 =item Arguments: none
 980
 981 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 982
 983 =back
 984
 985 Returns a storage-driven cursor to the given resultset. See
 986 L<DBIx::Class::Cursor> for more information.
 987
 988 =cut
 989
 990 sub cursor {
 991   my $self = shift;
 992
 993   return $self->{cursor} ||= do {
 994     my $attrs = { %{$self->_resolved_attrs } };
 995     $self->result_source->storage->select(
 996       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
 997     );
 998   };
 999 }
1000
1001 =head2 single
1002
1003 =over 4
1004
1005 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1006
1007 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1008
1009 =back
1010
1011   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1012
1013 Inflates the first result without creating a cursor if the resultset has
1014 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1015 of L</search>.
1016
1017 While this method can take an optional search condition (just like L</search>)
1018 being a fast-code-path it does not recognize search attributes. If you need to
1019 add extra joins or similar, call L</search> and then chain-call L</single> on the
1020 L<DBIx::Class::ResultSet> returned.
1021
1022 =over
1023
1024 =item B<Note>
1025
1026 As of 0.08100, this method enforces the assumption that the preceding
1027 query returns only one row. If more than one row is returned, you will receive
1028 a warning:
1029
1030   Query returned more than one row
1031
1032 In this case, you should be using L</next> or L</find> instead, or if you really
1033 know what you are doing, use the L</rows> attribute to explicitly limit the size
1034 of the resultset.
1035
1036 This method will also throw an exception if it is called on a resultset prefetching
1037 has_many, as such a prefetch implies fetching multiple rows from the database in
1038 order to assemble the resulting object.
1039
1040 =back
1041
1042 =cut
1043
1044 sub single {
1045   my ($self, $where) = @_;
1046   if(@_ > 2) {
1047       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1048   }
1049
1050   my $attrs = { %{$self->_resolved_attrs} };
1051
1052   if (keys %{$attrs->{collapse}}) {
1053     $self->throw_exception(
1054       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1055     );
1056   }
1057
1058   if ($where) {
1059     if (defined $attrs->{where}) {
1060       $attrs->{where} = {
1061         '-and' =>
1062             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1063                $where, delete $attrs->{where} ]
1064       };
1065     } else {
1066       $attrs->{where} = $where;
1067     }
1068   }
1069
1070   my @data = $self->result_source->storage->select_single(
1071     $attrs->{from}, $attrs->{select},
1072     $attrs->{where}, $attrs
1073   );
1074
1075   return (@data ? ($self->_construct_object(@data))[0] : undef);
1076 }
1077
1078
1079 # _collapse_query
1080 #
1081 # Recursively collapse the query, accumulating values for each column.
1082
1083 sub _collapse_query {
1084   my ($self, $query, $collapsed) = @_;
1085
1086   $collapsed ||= {};
1087
1088   if (ref $query eq 'ARRAY') {
1089     foreach my $subquery (@$query) {
1090       next unless ref $subquery;  # -or
1091       $collapsed = $self->_collapse_query($subquery, $collapsed);
1092     }
1093   }
1094   elsif (ref $query eq 'HASH') {
1095     if (keys %$query and (keys %$query)[0] eq '-and') {
1096       foreach my $subquery (@{$query->{-and}}) {
1097         $collapsed = $self->_collapse_query($subquery, $collapsed);
1098       }
1099     }
1100     else {
1101       foreach my $col (keys %$query) {
1102         my $value = $query->{$col};
1103         $collapsed->{$col}{$value}++;
1104       }
1105     }
1106   }
1107
1108   return $collapsed;
1109 }
1110
1111 =head2 get_column
1112
1113 =over 4
1114
1115 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1116
1117 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1118
1119 =back
1120
1121   my $max_length = $rs->get_column('length')->max;
1122
1123 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1124
1125 =cut
1126
1127 sub get_column {
1128   my ($self, $column) = @_;
1129   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1130   return $new;
1131 }
1132
1133 =head2 search_like
1134
1135 =over 4
1136
1137 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1138
1139 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1140
1141 =back
1142
1143   # WHERE title LIKE '%blue%'
1144   $cd_rs = $rs->search_like({ title => '%blue%'});
1145
1146 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1147 that this is simply a convenience method retained for ex Class::DBI users.
1148 You most likely want to use L</search> with specific operators.
1149
1150 For more information, see L<DBIx::Class::Manual::Cookbook>.
1151
1152 This method is deprecated and will be removed in 0.09. Use L</search()>
1153 instead. An example conversion is:
1154
1155   ->search_like({ foo => 'bar' });
1156
1157   # Becomes
1158
1159   ->search({ foo => { like => 'bar' } });
1160
1161 =cut
1162
1163 sub search_like {
1164   my $class = shift;
1165   carp_unique (
1166     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1167    .' Instead use ->search({ x => { -like => "y%" } })'
1168    .' (note the outer pair of {}s - they are important!)'
1169   );
1170   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1171   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1172   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1173   return $class->search($query, { %$attrs });
1174 }
1175
1176 =head2 slice
1177
1178 =over 4
1179
1180 =item Arguments: $first, $last
1181
1182 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1183
1184 =back
1185
1186 Returns a resultset or object list representing a subset of elements from the
1187 resultset slice is called on. Indexes are from 0, i.e., to get the first
1188 three records, call:
1189
1190   my ($one, $two, $three) = $rs->slice(0, 2);
1191
1192 =cut
1193
1194 sub slice {
1195   my ($self, $min, $max) = @_;
1196   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1197   $attrs->{offset} = $self->{attrs}{offset} || 0;
1198   $attrs->{offset} += $min;
1199   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1200   return $self->search(undef, $attrs);
1201   #my $slice = (ref $self)->new($self->result_source, $attrs);
1202   #return (wantarray ? $slice->all : $slice);
1203 }
1204
1205 =head2 next
1206
1207 =over 4
1208
1209 =item Arguments: none
1210
1211 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1212
1213 =back
1214
1215 Returns the next element in the resultset (C<undef> is there is none).
1216
1217 Can be used to efficiently iterate over records in the resultset:
1218
1219   my $rs = $schema->resultset('CD')->search;
1220   while (my $cd = $rs->next) {
1221     print $cd->title;
1222   }
1223
1224 Note that you need to store the resultset object, and call C<next> on it.
1225 Calling C<< resultset('Table')->next >> repeatedly will always return the
1226 first record from the resultset.
1227
1228 =cut
1229
1230 sub next {
1231   my ($self) = @_;
1232   if (my $cache = $self->get_cache) {
1233     $self->{all_cache_position} ||= 0;
1234     return $cache->[$self->{all_cache_position}++];
1235   }
1236   if ($self->{attrs}{cache}) {
1237     delete $self->{pager};
1238     $self->{all_cache_position} = 1;
1239     return ($self->all)[0];
1240   }
1241   if ($self->{stashed_objects}) {
1242     my $obj = shift(@{$self->{stashed_objects}});
1243     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1244     return $obj;
1245   }
1246   my @row = (
1247     exists $self->{stashed_row}
1248       ? @{delete $self->{stashed_row}}
1249       : $self->cursor->next
1250   );
1251   return undef unless (@row);
1252   my ($row, @more) = $self->_construct_object(@row);
1253   $self->{stashed_objects} = \@more if @more;
1254   return $row;
1255 }
1256
1257 sub _construct_object {
1258   my ($self, @row) = @_;
1259
1260   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1261     or return ();
1262   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1263   @new = $self->{_attrs}{record_filter}->(@new)
1264     if exists $self->{_attrs}{record_filter};
1265   return @new;
1266 }
1267
1268 sub _collapse_result {
1269   my ($self, $as_proto, $row) = @_;
1270
1271   my @copy = @$row;
1272
1273   # 'foo'         => [ undef, 'foo' ]
1274   # 'foo.bar'     => [ 'foo', 'bar' ]
1275   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1276
1277   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1278
1279   my %collapse = %{$self->{_attrs}{collapse}||{}};
1280
1281   my @pri_index;
1282
1283   # if we're doing collapsing (has_many prefetch) we need to grab records
1284   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1285   # we know we don't have to bother.
1286
1287   # the reason for not using the collapse stuff directly is because if you
1288   # had for e.g. two artists in a row with no cds, the collapse info for
1289   # both would be NULL (undef) so you'd lose the second artist
1290
1291   # store just the index so we can check the array positions from the row
1292   # without having to contruct the full hash
1293
1294   if (keys %collapse) {
1295     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1296     foreach my $i (0 .. $#construct_as) {
1297       next if defined($construct_as[$i][0]); # only self table
1298       if (delete $pri{$construct_as[$i][1]}) {
1299         push(@pri_index, $i);
1300       }
1301       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1302     }
1303   }
1304
1305   # no need to do an if, it'll be empty if @pri_index is empty anyway
1306
1307   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1308
1309   my @const_rows;
1310
1311   do { # no need to check anything at the front, we always want the first row
1312
1313     my %const;
1314
1315     foreach my $this_as (@construct_as) {
1316       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1317     }
1318
1319     push(@const_rows, \%const);
1320
1321   } until ( # no pri_index => no collapse => drop straight out
1322       !@pri_index
1323     or
1324       do { # get another row, stash it, drop out if different PK
1325
1326         @copy = $self->cursor->next;
1327         $self->{stashed_row} = \@copy;
1328
1329         # last thing in do block, counts as true if anything doesn't match
1330
1331         # check xor defined first for NULL vs. NOT NULL then if one is
1332         # defined the other must be so check string equality
1333
1334         grep {
1335           (defined $pri_vals{$_} ^ defined $copy[$_])
1336           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1337         } @pri_index;
1338       }
1339   );
1340
1341   my $alias = $self->{attrs}{alias};
1342   my $info = [];
1343
1344   my %collapse_pos;
1345
1346   my @const_keys;
1347
1348   foreach my $const (@const_rows) {
1349     scalar @const_keys or do {
1350       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1351     };
1352     foreach my $key (@const_keys) {
1353       if (length $key) {
1354         my $target = $info;
1355         my @parts = split(/\./, $key);
1356         my $cur = '';
1357         my $data = $const->{$key};
1358         foreach my $p (@parts) {
1359           $target = $target->[1]->{$p} ||= [];
1360           $cur .= ".${p}";
1361           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1362             # collapsing at this point and on final part
1363             my $pos = $collapse_pos{$cur};
1364             CK: foreach my $ck (@ckey) {
1365               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1366                 $collapse_pos{$cur} = $data;
1367                 delete @collapse_pos{ # clear all positioning for sub-entries
1368                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1369                 };
1370                 push(@$target, []);
1371                 last CK;
1372               }
1373             }
1374           }
1375           if (exists $collapse{$cur}) {
1376             $target = $target->[-1];
1377           }
1378         }
1379         $target->[0] = $data;
1380       } else {
1381         $info->[0] = $const->{$key};
1382       }
1383     }
1384   }
1385
1386   return $info;
1387 }
1388
1389 =head2 result_source
1390
1391 =over 4
1392
1393 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1394
1395 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1396
1397 =back
1398
1399 An accessor for the primary ResultSource object from which this ResultSet
1400 is derived.
1401
1402 =head2 result_class
1403
1404 =over 4
1405
1406 =item Arguments: $result_class?
1407
1408 =item Return Value: $result_class
1409
1410 =back
1411
1412 An accessor for the class to use when creating result objects. Defaults to
1413 C<< result_source->result_class >> - which in most cases is the name of the
1414 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1415
1416 Note that changing the result_class will also remove any components
1417 that were originally loaded in the source class via
1418 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1419 in the original source class will not run.
1420
1421 =cut
1422
1423 sub result_class {
1424   my ($self, $result_class) = @_;
1425   if ($result_class) {
1426     unless (ref $result_class) { # don't fire this for an object
1427       $self->ensure_class_loaded($result_class);
1428     }
1429     $self->_result_class($result_class);
1430     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1431     # permit the user to set result class on one result set only; it only
1432     # chains if provided to search()
1433     #$self->{attrs}{result_class} = $result_class if ref $self;
1434   }
1435   $self->_result_class;
1436 }
1437
1438 =head2 count
1439
1440 =over 4
1441
1442 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1443
1444 =item Return Value: $count
1445
1446 =back
1447
1448 Performs an SQL C<COUNT> with the same query as the resultset was built
1449 with to find the number of elements. Passing arguments is equivalent to
1450 C<< $rs->search ($cond, \%attrs)->count >>
1451
1452 =cut
1453
1454 sub count {
1455   my $self = shift;
1456   return $self->search(@_)->count if @_ and defined $_[0];
1457   return scalar @{ $self->get_cache } if $self->get_cache;
1458
1459   my $attrs = { %{ $self->_resolved_attrs } };
1460
1461   # this is a little optimization - it is faster to do the limit
1462   # adjustments in software, instead of a subquery
1463   my $rows = delete $attrs->{rows};
1464   my $offset = delete $attrs->{offset};
1465
1466   my $crs;
1467   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1468     $crs = $self->_count_subq_rs ($attrs);
1469   }
1470   else {
1471     $crs = $self->_count_rs ($attrs);
1472   }
1473   my $count = $crs->next;
1474
1475   $count -= $offset if $offset;
1476   $count = $rows if $rows and $rows < $count;
1477   $count = 0 if ($count < 0);
1478
1479   return $count;
1480 }
1481
1482 =head2 count_rs
1483
1484 =over 4
1485
1486 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1487
1488 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1489
1490 =back
1491
1492 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1493 This can be very handy for subqueries:
1494
1495   ->search( { amount => $some_rs->count_rs->as_query } )
1496
1497 As with regular resultsets the SQL query will be executed only after
1498 the resultset is accessed via L</next> or L</all>. That would return
1499 the same single value obtainable via L</count>.
1500
1501 =cut
1502
1503 sub count_rs {
1504   my $self = shift;
1505   return $self->search(@_)->count_rs if @_;
1506
1507   # this may look like a lack of abstraction (count() does about the same)
1508   # but in fact an _rs *must* use a subquery for the limits, as the
1509   # software based limiting can not be ported if this $rs is to be used
1510   # in a subquery itself (i.e. ->as_query)
1511   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1512     return $self->_count_subq_rs;
1513   }
1514   else {
1515     return $self->_count_rs;
1516   }
1517 }
1518
1519 #
1520 # returns a ResultSetColumn object tied to the count query
1521 #
1522 sub _count_rs {
1523   my ($self, $attrs) = @_;
1524
1525   my $rsrc = $self->result_source;
1526   $attrs ||= $self->_resolved_attrs;
1527
1528   my $tmp_attrs = { %$attrs };
1529   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1530   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1531
1532   # overwrite the selector (supplied by the storage)
1533   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1534   $tmp_attrs->{as} = 'count';
1535   delete @{$tmp_attrs}{qw/columns/};
1536
1537   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1538
1539   return $tmp_rs;
1540 }
1541
1542 #
1543 # same as above but uses a subquery
1544 #
1545 sub _count_subq_rs {
1546   my ($self, $attrs) = @_;
1547
1548   my $rsrc = $self->result_source;
1549   $attrs ||= $self->_resolved_attrs;
1550
1551   my $sub_attrs = { %$attrs };
1552   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1553   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1554
1555   # if we multi-prefetch we group_by something unique, as this is what we would
1556   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1557   if ( keys %{$attrs->{collapse}}  ) {
1558     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1559       $rsrc->_identifying_column_set || $self->throw_exception(
1560         'Unable to construct a unique group_by criteria properly collapsing the '
1561       . 'has_many prefetch before count()'
1562       );
1563     } ]
1564   }
1565
1566   # Calculate subquery selector
1567   if (my $g = $sub_attrs->{group_by}) {
1568
1569     my $sql_maker = $rsrc->storage->sql_maker;
1570
1571     # necessary as the group_by may refer to aliased functions
1572     my $sel_index;
1573     for my $sel (@{$attrs->{select}}) {
1574       $sel_index->{$sel->{-as}} = $sel
1575         if (ref $sel eq 'HASH' and $sel->{-as});
1576     }
1577
1578     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1579     # also look for named aggregates referred in the having clause
1580     # having often contains scalarrefs - thus parse it out entirely
1581     my @parts = @$g;
1582     if ($attrs->{having}) {
1583       local $sql_maker->{having_bind};
1584       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1585       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1586       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1587         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1588         # if we don't unset it we screw up retarded but unfortunately working
1589         # 'MAX(foo.bar)' => { '>', 3 }
1590         $sql_maker->{name_sep} = '';
1591       }
1592
1593       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1594
1595       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1596
1597       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1598       # and if all fails for an utterly naive quoted scalar-with-function
1599       while ($sql =~ /
1600         $rquote $sep $lquote (.+?) $rquote
1601           |
1602         [\s,] \w+ \. (\w+) [\s,]
1603           |
1604         [\s,] $lquote (.+?) $rquote [\s,]
1605       /gx) {
1606         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1607       }
1608     }
1609
1610     for (@parts) {
1611       my $colpiece = $sel_index->{$_} || $_;
1612
1613       # unqualify join-based group_by's. Arcane but possible query
1614       # also horrible horrible hack to alias a column (not a func.)
1615       # (probably need to introduce SQLA syntax)
1616       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1617         my $as = $colpiece;
1618         $as =~ s/\./__/;
1619         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1620       }
1621       push @{$sub_attrs->{select}}, $colpiece;
1622     }
1623   }
1624   else {
1625     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1626     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1627   }
1628
1629   return $rsrc->resultset_class
1630                ->new ($rsrc, $sub_attrs)
1631                 ->as_subselect_rs
1632                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1633                   ->get_column ('count');
1634 }
1635
1636 sub _bool {
1637   return 1;
1638 }
1639
1640 =head2 count_literal
1641
1642 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1643 should only be used in that context. See L</search_literal> for further info.
1644
1645 =over 4
1646
1647 =item Arguments: $sql_fragment, @standalone_bind_values
1648
1649 =item Return Value: $count
1650
1651 =back
1652
1653 Counts the results in a literal query. Equivalent to calling L</search_literal>
1654 with the passed arguments, then L</count>.
1655
1656 =cut
1657
1658 sub count_literal { shift->search_literal(@_)->count; }
1659
1660 =head2 all
1661
1662 =over 4
1663
1664 =item Arguments: none
1665
1666 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1667
1668 =back
1669
1670 Returns all elements in the resultset.
1671
1672 =cut
1673
1674 sub all {
1675   my $self = shift;
1676   if(@_) {
1677       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1678   }
1679
1680   return @{ $self->get_cache } if $self->get_cache;
1681
1682   my @obj;
1683
1684   if (keys %{$self->_resolved_attrs->{collapse}}) {
1685     # Using $self->cursor->all is really just an optimisation.
1686     # If we're collapsing has_many prefetches it probably makes
1687     # very little difference, and this is cleaner than hacking
1688     # _construct_object to survive the approach
1689     $self->cursor->reset;
1690     my @row = $self->cursor->next;
1691     while (@row) {
1692       push(@obj, $self->_construct_object(@row));
1693       @row = (exists $self->{stashed_row}
1694                ? @{delete $self->{stashed_row}}
1695                : $self->cursor->next);
1696     }
1697   } else {
1698     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1699   }
1700
1701   $self->set_cache(\@obj) if $self->{attrs}{cache};
1702
1703   return @obj;
1704 }
1705
1706 =head2 reset
1707
1708 =over 4
1709
1710 =item Arguments: none
1711
1712 =item Return Value: $self
1713
1714 =back
1715
1716 Resets the resultset's cursor, so you can iterate through the elements again.
1717 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1718 another query.
1719
1720 =cut
1721
1722 sub reset {
1723   my ($self) = @_;
1724   $self->{all_cache_position} = 0;
1725   $self->cursor->reset;
1726   return $self;
1727 }
1728
1729 =head2 first
1730
1731 =over 4
1732
1733 =item Arguments: none
1734
1735 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1736
1737 =back
1738
1739 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1740 an object for the first result (or C<undef> if the resultset is empty).
1741
1742 =cut
1743
1744 sub first {
1745   return $_[0]->reset->next;
1746 }
1747
1748
1749 # _rs_update_delete
1750 #
1751 # Determines whether and what type of subquery is required for the $rs operation.
1752 # If grouping is necessary either supplies its own, or verifies the current one
1753 # After all is done delegates to the proper storage method.
1754
1755 sub _rs_update_delete {
1756   my ($self, $op, $values) = @_;
1757
1758   my $cond = $self->{cond};
1759   my $rsrc = $self->result_source;
1760   my $storage = $rsrc->schema->storage;
1761
1762   my $attrs = { %{$self->_resolved_attrs} };
1763
1764   my $existing_group_by = delete $attrs->{group_by};
1765   my $needs_subq = defined $existing_group_by;
1766
1767   # simplify the joinmap and maybe decide if a subquery is necessary
1768   my $relation_classifications = {};
1769
1770   if (ref($attrs->{from}) eq 'ARRAY') {
1771     # if we already know we need a subq, no point of classifying relations
1772     if (!$needs_subq and @{$attrs->{from}} > 1) {
1773       $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1774
1775       $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1776         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1777         $attrs->{select},
1778         $cond,
1779         $attrs
1780       );
1781     }
1782   }
1783   else {
1784     $needs_subq ||= 1; # if {from} is unparseable assume the worst
1785   }
1786
1787   # do we need anything like a subquery?
1788   if (
1789     ! $needs_subq
1790       and
1791     ! keys %{ $relation_classifications->{restricting} || {} }
1792       and
1793     ! $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1794   ) {
1795     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1796     # a condition containing 'me' or other table prefixes will not work
1797     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1798     my $cond = do {
1799       my $sqla = $rsrc->storage->sql_maker;
1800       local $sqla->{_dequalify_idents} = 1;
1801       \[ $sqla->_recurse_where($self->{cond}) ];
1802     };
1803     return $rsrc->storage->$op(
1804       $rsrc,
1805       $op eq 'update' ? $values : (),
1806       $cond,
1807     );
1808   }
1809
1810   # we got this far - means it is time to wrap a subquery
1811   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1812     sprintf(
1813       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1814       $op,
1815       $rsrc->source_name,
1816     )
1817   );
1818
1819   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1820   delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1821   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1822   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1823   my $subrs = (ref $self)->new($rsrc, $attrs);
1824
1825   if (@$idcols == 1) {
1826     return $storage->$op (
1827       $rsrc,
1828       $op eq 'update' ? $values : (),
1829       { $idcols->[0] => { -in => $subrs->as_query } },
1830     );
1831   }
1832   elsif ($storage->_use_multicolumn_in) {
1833     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1834     my $sql_maker = $storage->sql_maker;
1835     my ($sql, @bind) = @${$subrs->as_query};
1836     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1837       join (', ', map { $sql_maker->_quote ($_) } @$idcols),
1838       $sql,
1839     );
1840
1841     return $storage->$op (
1842       $rsrc,
1843       $op eq 'update' ? $values : (),
1844       \[$sql, @bind],
1845     );
1846   }
1847   else {
1848
1849     # if all else fails - get all primary keys and operate over a ORed set
1850     # wrap in a transaction for consistency
1851     # this is where the group_by starts to matter
1852     if (
1853       $existing_group_by
1854         or
1855       keys %{ $relation_classifications->{multiplying} || {} }
1856     ) {
1857       # make sure if there is a supplied group_by it matches the columns compiled above
1858       # perfectly. Anything else can not be sanely executed on most databases so croak
1859       # right then and there
1860       if ($existing_group_by) {
1861         my @current_group_by = map
1862           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1863           @$existing_group_by
1864         ;
1865
1866         if (
1867           join ("\x00", sort @current_group_by)
1868             ne
1869           join ("\x00", sort @{$attrs->{columns}} )
1870         ) {
1871           $self->throw_exception (
1872             "You have just attempted a $op operation on a resultset which does group_by"
1873             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1874             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1875             . ' kind of queries. Please retry the operation with a modified group_by or'
1876             . ' without using one at all.'
1877           );
1878         }
1879       }
1880
1881       $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1882     }
1883
1884     my $guard = $storage->txn_scope_guard;
1885
1886     my @op_condition;
1887     for my $row ($subrs->cursor->all) {
1888       push @op_condition, { map
1889         { $idcols->[$_] => $row->[$_] }
1890         (0 .. $#$idcols)
1891       };
1892     }
1893
1894     my $res = $storage->$op (
1895       $rsrc,
1896       $op eq 'update' ? $values : (),
1897       \@op_condition,
1898     );
1899
1900     $guard->commit;
1901
1902     return $res;
1903   }
1904 }
1905
1906 =head2 update
1907
1908 =over 4
1909
1910 =item Arguments: \%values
1911
1912 =item Return Value: $underlying_storage_rv
1913
1914 =back
1915
1916 Sets the specified columns in the resultset to the supplied values in a
1917 single query. Note that this will not run any accessor/set_column/update
1918 triggers, nor will it update any result object instances derived from this
1919 resultset (this includes the contents of the L<resultset cache|/set_cache>
1920 if any). See L</update_all> if you need to execute any on-update
1921 triggers or cascades defined either by you or a
1922 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1923
1924 The return value is a pass through of what the underlying
1925 storage backend returned, and may vary. See L<DBI/execute> for the most
1926 common case.
1927
1928 =head3 CAVEAT
1929
1930 Note that L</update> does not process/deflate any of the values passed in.
1931 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1932 ensure manually that any value passed to this method will stringify to
1933 something the RDBMS knows how to deal with. A notable example is the
1934 handling of L<DateTime> objects, for more info see:
1935 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1936
1937 =cut
1938
1939 sub update {
1940   my ($self, $values) = @_;
1941   $self->throw_exception('Values for update must be a hash')
1942     unless ref $values eq 'HASH';
1943
1944   return $self->_rs_update_delete ('update', $values);
1945 }
1946
1947 =head2 update_all
1948
1949 =over 4
1950
1951 =item Arguments: \%values
1952
1953 =item Return Value: 1
1954
1955 =back
1956
1957 Fetches all objects and updates them one at a time via
1958 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1959 triggers, while L</update> will not.
1960
1961 =cut
1962
1963 sub update_all {
1964   my ($self, $values) = @_;
1965   $self->throw_exception('Values for update_all must be a hash')
1966     unless ref $values eq 'HASH';
1967
1968   my $guard = $self->result_source->schema->txn_scope_guard;
1969   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1970   $guard->commit;
1971   return 1;
1972 }
1973
1974 =head2 delete
1975
1976 =over 4
1977
1978 =item Arguments: none
1979
1980 =item Return Value: $underlying_storage_rv
1981
1982 =back
1983
1984 Deletes the rows matching this resultset in a single query. Note that this
1985 will not run any delete triggers, nor will it alter the
1986 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1987 derived from this resultset (this includes the contents of the
1988 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1989 execute any on-delete triggers or cascades defined either by you or a
1990 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1991
1992 The return value is a pass through of what the underlying storage backend
1993 returned, and may vary. See L<DBI/execute> for the most common case.
1994
1995 =cut
1996
1997 sub delete {
1998   my $self = shift;
1999   $self->throw_exception('delete does not accept any arguments')
2000     if @_;
2001
2002   return $self->_rs_update_delete ('delete');
2003 }
2004
2005 =head2 delete_all
2006
2007 =over 4
2008
2009 =item Arguments: none
2010
2011 =item Return Value: 1
2012
2013 =back
2014
2015 Fetches all objects and deletes them one at a time via
2016 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2017 triggers, while L</delete> will not.
2018
2019 =cut
2020
2021 sub delete_all {
2022   my $self = shift;
2023   $self->throw_exception('delete_all does not accept any arguments')
2024     if @_;
2025
2026   my $guard = $self->result_source->schema->txn_scope_guard;
2027   $_->delete for $self->all;
2028   $guard->commit;
2029   return 1;
2030 }
2031
2032 =head2 populate
2033
2034 =over 4
2035
2036 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2037
2038 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2039
2040 =back
2041
2042 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2043 arrayrefs.
2044
2045 =over
2046
2047 =item NOTE
2048
2049 The context of this method call has an important effect on what is
2050 submitted to storage. In void context data is fed directly to fastpath
2051 insertion routines provided by the underlying storage (most often
2052 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2053 L<insert|DBIx::Class::Row/insert> calls on the
2054 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2055 augmentation of these methods provided by components. For example if you
2056 are using something like L<DBIx::Class::UUIDColumns> to create primary
2057 keys for you, you will find that your PKs are empty.  In this case you
2058 will have to explicitly force scalar or list context in order to create
2059 those values.
2060
2061 =back
2062
2063 In non-void (scalar or list) context, this method is simply a wrapper
2064 for L</create>. Depending on list or scalar context either a list of
2065 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2066 containing these objects is returned.
2067
2068 When supplying data in "arrayref of arrayrefs" invocation style, the
2069 first element should be a list of column names and each subsequent
2070 element should be a data value in the earlier specified column order.
2071 For example:
2072
2073   $Arstist_rs->populate([
2074     [ qw( artistid name ) ],
2075     [ 100, 'A Formally Unknown Singer' ],
2076     [ 101, 'A singer that jumped the shark two albums ago' ],
2077     [ 102, 'An actually cool singer' ],
2078   ]);
2079
2080 For the arrayref of hashrefs style each hashref should be a structure
2081 suitable for passing to L</create>. Multi-create is also permitted with
2082 this syntax.
2083
2084   $schema->resultset("Artist")->populate([
2085      { artistid => 4, name => 'Manufactured Crap', cds => [
2086         { title => 'My First CD', year => 2006 },
2087         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2088       ],
2089      },
2090      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2091         { title => 'My parents sold me to a record company', year => 2005 },
2092         { title => 'Why Am I So Ugly?', year => 2006 },
2093         { title => 'I Got Surgery and am now Popular', year => 2007 }
2094       ],
2095      },
2096   ]);
2097
2098 If you attempt a void-context multi-create as in the example above (each
2099 Artist also has the related list of CDs), and B<do not> supply the
2100 necessary autoinc foreign key information, this method will proxy to the
2101 less efficient L</create>, and then throw the Result objects away. In this
2102 case there are obviously no benefits to using this method over L</create>.
2103
2104 =cut
2105
2106 sub populate {
2107   my $self = shift;
2108
2109   # cruft placed in standalone method
2110   my $data = $self->_normalize_populate_args(@_);
2111
2112   return unless @$data;
2113
2114   if(defined wantarray) {
2115     my @created = map { $self->create($_) } @$data;
2116     return wantarray ? @created : \@created;
2117   }
2118   else {
2119     my $first = $data->[0];
2120
2121     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2122     # it relationship data
2123     my (@rels, @columns);
2124     my $rsrc = $self->result_source;
2125     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2126     for (keys %$first) {
2127       my $ref = ref $first->{$_};
2128       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2129         ? push @rels, $_
2130         : push @columns, $_
2131       ;
2132     }
2133
2134     my @pks = $rsrc->primary_columns;
2135
2136     ## do the belongs_to relationships
2137     foreach my $index (0..$#$data) {
2138
2139       # delegate to create() for any dataset without primary keys with specified relationships
2140       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2141         for my $r (@rels) {
2142           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2143             my @ret = $self->populate($data);
2144             return;
2145           }
2146         }
2147       }
2148
2149       foreach my $rel (@rels) {
2150         next unless ref $data->[$index]->{$rel} eq "HASH";
2151         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2152         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2153         my $related = $result->result_source->_resolve_condition(
2154           $reverse_relinfo->{cond},
2155           $self,
2156           $result,
2157           $rel,
2158         );
2159
2160         delete $data->[$index]->{$rel};
2161         $data->[$index] = {%{$data->[$index]}, %$related};
2162
2163         push @columns, keys %$related if $index == 0;
2164       }
2165     }
2166
2167     ## inherit the data locked in the conditions of the resultset
2168     my ($rs_data) = $self->_merge_with_rscond({});
2169     delete @{$rs_data}{@columns};
2170
2171     ## do bulk insert on current row
2172     $rsrc->storage->insert_bulk(
2173       $rsrc,
2174       [@columns, keys %$rs_data],
2175       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2176     );
2177
2178     ## do the has_many relationships
2179     foreach my $item (@$data) {
2180
2181       my $main_row;
2182
2183       foreach my $rel (@rels) {
2184         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2185
2186         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2187
2188         my $child = $main_row->$rel;
2189
2190         my $related = $child->result_source->_resolve_condition(
2191           $rels->{$rel}{cond},
2192           $child,
2193           $main_row,
2194           $rel,
2195         );
2196
2197         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2198         my @populate = map { {%$_, %$related} } @rows_to_add;
2199
2200         $child->populate( \@populate );
2201       }
2202     }
2203   }
2204 }
2205
2206
2207 # populate() argumnets went over several incarnations
2208 # What we ultimately support is AoH
2209 sub _normalize_populate_args {
2210   my ($self, $arg) = @_;
2211
2212   if (ref $arg eq 'ARRAY') {
2213     if (!@$arg) {
2214       return [];
2215     }
2216     elsif (ref $arg->[0] eq 'HASH') {
2217       return $arg;
2218     }
2219     elsif (ref $arg->[0] eq 'ARRAY') {
2220       my @ret;
2221       my @colnames = @{$arg->[0]};
2222       foreach my $values (@{$arg}[1 .. $#$arg]) {
2223         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2224       }
2225       return \@ret;
2226     }
2227   }
2228
2229   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2230 }
2231
2232 =head2 pager
2233
2234 =over 4
2235
2236 =item Arguments: none
2237
2238 =item Return Value: L<$pager|Data::Page>
2239
2240 =back
2241
2242 Returns a L<Data::Page> object for the current resultset. Only makes
2243 sense for queries with a C<page> attribute.
2244
2245 To get the full count of entries for a paged resultset, call
2246 C<total_entries> on the L<Data::Page> object.
2247
2248 =cut
2249
2250 sub pager {
2251   my ($self) = @_;
2252
2253   return $self->{pager} if $self->{pager};
2254
2255   my $attrs = $self->{attrs};
2256   if (!defined $attrs->{page}) {
2257     $self->throw_exception("Can't create pager for non-paged rs");
2258   }
2259   elsif ($attrs->{page} <= 0) {
2260     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2261   }
2262   $attrs->{rows} ||= 10;
2263
2264   # throw away the paging flags and re-run the count (possibly
2265   # with a subselect) to get the real total count
2266   my $count_attrs = { %$attrs };
2267   delete $count_attrs->{$_} for qw/rows offset page pager/;
2268
2269   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2270
2271   require DBIx::Class::ResultSet::Pager;
2272   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2273     sub { $total_rs->count },  #lazy-get the total
2274     $attrs->{rows},
2275     $self->{attrs}{page},
2276   );
2277 }
2278
2279 =head2 page
2280
2281 =over 4
2282
2283 =item Arguments: $page_number
2284
2285 =item Return Value: L<$resultset|/search>
2286
2287 =back
2288
2289 Returns a resultset for the $page_number page of the resultset on which page
2290 is called, where each page contains a number of rows equal to the 'rows'
2291 attribute set on the resultset (10 by default).
2292
2293 =cut
2294
2295 sub page {
2296   my ($self, $page) = @_;
2297   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2298 }
2299
2300 =head2 new_result
2301
2302 =over 4
2303
2304 =item Arguments: \%col_data
2305
2306 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2307
2308 =back
2309
2310 Creates a new result object in the resultset's result class and returns
2311 it. The row is not inserted into the database at this point, call
2312 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2313 will tell you whether the result object has been inserted or not.
2314
2315 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2316
2317 =cut
2318
2319 sub new_result {
2320   my ($self, $values) = @_;
2321
2322   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2323     if @_ > 2;
2324
2325   $self->throw_exception( "new_result expects a hashref" )
2326     unless (ref $values eq 'HASH');
2327
2328   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2329
2330   my %new = (
2331     %$merged_cond,
2332     @$cols_from_relations
2333       ? (-cols_from_relations => $cols_from_relations)
2334       : (),
2335     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2336   );
2337
2338   return $self->result_class->new(\%new);
2339 }
2340
2341 # _merge_with_rscond
2342 #
2343 # Takes a simple hash of K/V data and returns its copy merged with the
2344 # condition already present on the resultset. Additionally returns an
2345 # arrayref of value/condition names, which were inferred from related
2346 # objects (this is needed for in-memory related objects)
2347 sub _merge_with_rscond {
2348   my ($self, $data) = @_;
2349
2350   my (%new_data, @cols_from_relations);
2351
2352   my $alias = $self->{attrs}{alias};
2353
2354   if (! defined $self->{cond}) {
2355     # just massage $data below
2356   }
2357   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2358     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2359     @cols_from_relations = keys %new_data;
2360   }
2361   elsif (ref $self->{cond} ne 'HASH') {
2362     $self->throw_exception(
2363       "Can't abstract implicit construct, resultset condition not a hash"
2364     );
2365   }
2366   else {
2367     # precendence must be given to passed values over values inherited from
2368     # the cond, so the order here is important.
2369     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2370     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2371
2372     while ( my($col, $value) = each %implied ) {
2373       my $vref = ref $value;
2374       if (
2375         $vref eq 'HASH'
2376           and
2377         keys(%$value) == 1
2378           and
2379         (keys %$value)[0] eq '='
2380       ) {
2381         $new_data{$col} = $value->{'='};
2382       }
2383       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2384         $new_data{$col} = $value;
2385       }
2386     }
2387   }
2388
2389   %new_data = (
2390     %new_data,
2391     %{ $self->_remove_alias($data, $alias) },
2392   );
2393
2394   return (\%new_data, \@cols_from_relations);
2395 }
2396
2397 # _has_resolved_attr
2398 #
2399 # determines if the resultset defines at least one
2400 # of the attributes supplied
2401 #
2402 # used to determine if a subquery is neccessary
2403 #
2404 # supports some virtual attributes:
2405 #   -join
2406 #     This will scan for any joins being present on the resultset.
2407 #     It is not a mere key-search but a deep inspection of {from}
2408 #
2409
2410 sub _has_resolved_attr {
2411   my ($self, @attr_names) = @_;
2412
2413   my $attrs = $self->_resolved_attrs;
2414
2415   my %extra_checks;
2416
2417   for my $n (@attr_names) {
2418     if (grep { $n eq $_ } (qw/-join/) ) {
2419       $extra_checks{$n}++;
2420       next;
2421     }
2422
2423     my $attr =  $attrs->{$n};
2424
2425     next if not defined $attr;
2426
2427     if (ref $attr eq 'HASH') {
2428       return 1 if keys %$attr;
2429     }
2430     elsif (ref $attr eq 'ARRAY') {
2431       return 1 if @$attr;
2432     }
2433     else {
2434       return 1 if $attr;
2435     }
2436   }
2437
2438   # a resolved join is expressed as a multi-level from
2439   return 1 if (
2440     $extra_checks{-join}
2441       and
2442     ref $attrs->{from} eq 'ARRAY'
2443       and
2444     @{$attrs->{from}} > 1
2445   );
2446
2447   return 0;
2448 }
2449
2450 # _collapse_cond
2451 #
2452 # Recursively collapse the condition.
2453
2454 sub _collapse_cond {
2455   my ($self, $cond, $collapsed) = @_;
2456
2457   $collapsed ||= {};
2458
2459   if (ref $cond eq 'ARRAY') {
2460     foreach my $subcond (@$cond) {
2461       next unless ref $subcond;  # -or
2462       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2463     }
2464   }
2465   elsif (ref $cond eq 'HASH') {
2466     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2467       foreach my $subcond (@{$cond->{-and}}) {
2468         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2469       }
2470     }
2471     else {
2472       foreach my $col (keys %$cond) {
2473         my $value = $cond->{$col};
2474         $collapsed->{$col} = $value;
2475       }
2476     }
2477   }
2478
2479   return $collapsed;
2480 }
2481
2482 # _remove_alias
2483 #
2484 # Remove the specified alias from the specified query hash. A copy is made so
2485 # the original query is not modified.
2486
2487 sub _remove_alias {
2488   my ($self, $query, $alias) = @_;
2489
2490   my %orig = %{ $query || {} };
2491   my %unaliased;
2492
2493   foreach my $key (keys %orig) {
2494     if ($key !~ /\./) {
2495       $unaliased{$key} = $orig{$key};
2496       next;
2497     }
2498     $unaliased{$1} = $orig{$key}
2499       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2500   }
2501
2502   return \%unaliased;
2503 }
2504
2505 =head2 as_query
2506
2507 =over 4
2508
2509 =item Arguments: none
2510
2511 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2512
2513 =back
2514
2515 Returns the SQL query and bind vars associated with the invocant.
2516
2517 This is generally used as the RHS for a subquery.
2518
2519 =cut
2520
2521 sub as_query {
2522   my $self = shift;
2523
2524   my $attrs = { %{ $self->_resolved_attrs } };
2525
2526   # For future use:
2527   #
2528   # in list ctx:
2529   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2530   # $sql also has no wrapping parenthesis in list ctx
2531   #
2532   my $sqlbind = $self->result_source->storage
2533     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2534
2535   return $sqlbind;
2536 }
2537
2538 =head2 find_or_new
2539
2540 =over 4
2541
2542 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2543
2544 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2545
2546 =back
2547
2548   my $artist = $schema->resultset('Artist')->find_or_new(
2549     { artist => 'fred' }, { key => 'artists' });
2550
2551   $cd->cd_to_producer->find_or_new({ producer => $producer },
2552                                    { key => 'primary });
2553
2554 Find an existing record from this resultset using L</find>. if none exists,
2555 instantiate a new result object and return it. The object will not be saved
2556 into your storage until you call L<DBIx::Class::Row/insert> on it.
2557
2558 You most likely want this method when looking for existing rows using a unique
2559 constraint that is not the primary key, or looking for related rows.
2560
2561 If you want objects to be saved immediately, use L</find_or_create> instead.
2562
2563 B<Note>: Make sure to read the documentation of L</find> and understand the
2564 significance of the C<key> attribute, as its lack may skew your search, and
2565 subsequently result in spurious new objects.
2566
2567 B<Note>: Take care when using C<find_or_new> with a table having
2568 columns with default values that you intend to be automatically
2569 supplied by the database (e.g. an auto_increment primary key column).
2570 In normal usage, the value of such columns should NOT be included at
2571 all in the call to C<find_or_new>, even when set to C<undef>.
2572
2573 =cut
2574
2575 sub find_or_new {
2576   my $self     = shift;
2577   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2578   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2579   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2580     return $row;
2581   }
2582   return $self->new_result($hash);
2583 }
2584
2585 =head2 create
2586
2587 =over 4
2588
2589 =item Arguments: \%col_data
2590
2591 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2592
2593 =back
2594
2595 Attempt to create a single new row or a row with multiple related rows
2596 in the table represented by the resultset (and related tables). This
2597 will not check for duplicate rows before inserting, use
2598 L</find_or_create> to do that.
2599
2600 To create one row for this resultset, pass a hashref of key/value
2601 pairs representing the columns of the table and the values you wish to
2602 store. If the appropriate relationships are set up, foreign key fields
2603 can also be passed an object representing the foreign row, and the
2604 value will be set to its primary key.
2605
2606 To create related objects, pass a hashref of related-object column values
2607 B<keyed on the relationship name>. If the relationship is of type C<multi>
2608 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2609 The process will correctly identify columns holding foreign keys, and will
2610 transparently populate them from the keys of the corresponding relation.
2611 This can be applied recursively, and will work correctly for a structure
2612 with an arbitrary depth and width, as long as the relationships actually
2613 exists and the correct column data has been supplied.
2614
2615 Instead of hashrefs of plain related data (key/value pairs), you may
2616 also pass new or inserted objects. New objects (not inserted yet, see
2617 L</new_result>), will be inserted into their appropriate tables.
2618
2619 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2620
2621 Example of creating a new row.
2622
2623   $person_rs->create({
2624     name=>"Some Person",
2625     email=>"somebody@someplace.com"
2626   });
2627
2628 Example of creating a new row and also creating rows in a related C<has_many>
2629 or C<has_one> resultset.  Note Arrayref.
2630
2631   $artist_rs->create(
2632      { artistid => 4, name => 'Manufactured Crap', cds => [
2633         { title => 'My First CD', year => 2006 },
2634         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2635       ],
2636      },
2637   );
2638
2639 Example of creating a new row and also creating a row in a related
2640 C<belongs_to> resultset. Note Hashref.
2641
2642   $cd_rs->create({
2643     title=>"Music for Silly Walks",
2644     year=>2000,
2645     artist => {
2646       name=>"Silly Musician",
2647     }
2648   });
2649
2650 =over
2651
2652 =item WARNING
2653
2654 When subclassing ResultSet never attempt to override this method. Since
2655 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2656 lot of the internals simply never call it, so your override will be
2657 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2658 or L<DBIx::Class::Row/insert> depending on how early in the
2659 L</create> process you need to intervene. See also warning pertaining to
2660 L</new>.
2661
2662 =back
2663
2664 =cut
2665
2666 sub create {
2667   my ($self, $attrs) = @_;
2668   $self->throw_exception( "create needs a hashref" )
2669     unless ref $attrs eq 'HASH';
2670   return $self->new_result($attrs)->insert;
2671 }
2672
2673 =head2 find_or_create
2674
2675 =over 4
2676
2677 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2678
2679 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2680
2681 =back
2682
2683   $cd->cd_to_producer->find_or_create({ producer => $producer },
2684                                       { key => 'primary' });
2685
2686 Tries to find a record based on its primary key or unique constraints; if none
2687 is found, creates one and returns that instead.
2688
2689   my $cd = $schema->resultset('CD')->find_or_create({
2690     cdid   => 5,
2691     artist => 'Massive Attack',
2692     title  => 'Mezzanine',
2693     year   => 2005,
2694   });
2695
2696 Also takes an optional C<key> attribute, to search by a specific key or unique
2697 constraint. For example:
2698
2699   my $cd = $schema->resultset('CD')->find_or_create(
2700     {
2701       artist => 'Massive Attack',
2702       title  => 'Mezzanine',
2703     },
2704     { key => 'cd_artist_title' }
2705   );
2706
2707 B<Note>: Make sure to read the documentation of L</find> and understand the
2708 significance of the C<key> attribute, as its lack may skew your search, and
2709 subsequently result in spurious row creation.
2710
2711 B<Note>: Because find_or_create() reads from the database and then
2712 possibly inserts based on the result, this method is subject to a race
2713 condition. Another process could create a record in the table after
2714 the find has completed and before the create has started. To avoid
2715 this problem, use find_or_create() inside a transaction.
2716
2717 B<Note>: Take care when using C<find_or_create> with a table having
2718 columns with default values that you intend to be automatically
2719 supplied by the database (e.g. an auto_increment primary key column).
2720 In normal usage, the value of such columns should NOT be included at
2721 all in the call to C<find_or_create>, even when set to C<undef>.
2722
2723 See also L</find> and L</update_or_create>. For information on how to declare
2724 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2725
2726 If you need to know if an existing row was found or a new one created use
2727 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2728 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2729 database!
2730
2731   my $cd = $schema->resultset('CD')->find_or_new({
2732     cdid   => 5,
2733     artist => 'Massive Attack',
2734     title  => 'Mezzanine',
2735     year   => 2005,
2736   });
2737
2738   if( !$cd->in_storage ) {
2739       # do some stuff
2740       $cd->insert;
2741   }
2742
2743 =cut
2744
2745 sub find_or_create {
2746   my $self     = shift;
2747   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2748   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2749   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2750     return $row;
2751   }
2752   return $self->create($hash);
2753 }
2754
2755 =head2 update_or_create
2756
2757 =over 4
2758
2759 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2760
2761 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2762
2763 =back
2764
2765   $resultset->update_or_create({ col => $val, ... });
2766
2767 Like L</find_or_create>, but if a row is found it is immediately updated via
2768 C<< $found_row->update (\%col_data) >>.
2769
2770
2771 Takes an optional C<key> attribute to search on a specific unique constraint.
2772 For example:
2773
2774   # In your application
2775   my $cd = $schema->resultset('CD')->update_or_create(
2776     {
2777       artist => 'Massive Attack',
2778       title  => 'Mezzanine',
2779       year   => 1998,
2780     },
2781     { key => 'cd_artist_title' }
2782   );
2783
2784   $cd->cd_to_producer->update_or_create({
2785     producer => $producer,
2786     name => 'harry',
2787   }, {
2788     key => 'primary',
2789   });
2790
2791 B<Note>: Make sure to read the documentation of L</find> and understand the
2792 significance of the C<key> attribute, as its lack may skew your search, and
2793 subsequently result in spurious row creation.
2794
2795 B<Note>: Take care when using C<update_or_create> with a table having
2796 columns with default values that you intend to be automatically
2797 supplied by the database (e.g. an auto_increment primary key column).
2798 In normal usage, the value of such columns should NOT be included at
2799 all in the call to C<update_or_create>, even when set to C<undef>.
2800
2801 See also L</find> and L</find_or_create>. For information on how to declare
2802 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2803
2804 If you need to know if an existing row was updated or a new one created use
2805 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2806 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2807 database!
2808
2809 =cut
2810
2811 sub update_or_create {
2812   my $self = shift;
2813   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2814   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2815
2816   my $row = $self->find($cond, $attrs);
2817   if (defined $row) {
2818     $row->update($cond);
2819     return $row;
2820   }
2821
2822   return $self->create($cond);
2823 }
2824
2825 =head2 update_or_new
2826
2827 =over 4
2828
2829 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2830
2831 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2832
2833 =back
2834
2835   $resultset->update_or_new({ col => $val, ... });
2836
2837 Like L</find_or_new> but if a row is found it is immediately updated via
2838 C<< $found_row->update (\%col_data) >>.
2839
2840 For example:
2841
2842   # In your application
2843   my $cd = $schema->resultset('CD')->update_or_new(
2844     {
2845       artist => 'Massive Attack',
2846       title  => 'Mezzanine',
2847       year   => 1998,
2848     },
2849     { key => 'cd_artist_title' }
2850   );
2851
2852   if ($cd->in_storage) {
2853       # the cd was updated
2854   }
2855   else {
2856       # the cd is not yet in the database, let's insert it
2857       $cd->insert;
2858   }
2859
2860 B<Note>: Make sure to read the documentation of L</find> and understand the
2861 significance of the C<key> attribute, as its lack may skew your search, and
2862 subsequently result in spurious new objects.
2863
2864 B<Note>: Take care when using C<update_or_new> with a table having
2865 columns with default values that you intend to be automatically
2866 supplied by the database (e.g. an auto_increment primary key column).
2867 In normal usage, the value of such columns should NOT be included at
2868 all in the call to C<update_or_new>, even when set to C<undef>.
2869
2870 See also L</find>, L</find_or_create> and L</find_or_new>.
2871
2872 =cut
2873
2874 sub update_or_new {
2875     my $self  = shift;
2876     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2877     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2878
2879     my $row = $self->find( $cond, $attrs );
2880     if ( defined $row ) {
2881         $row->update($cond);
2882         return $row;
2883     }
2884
2885     return $self->new_result($cond);
2886 }
2887
2888 =head2 get_cache
2889
2890 =over 4
2891
2892 =item Arguments: none
2893
2894 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2895
2896 =back
2897
2898 Gets the contents of the cache for the resultset, if the cache is set.
2899
2900 The cache is populated either by using the L</prefetch> attribute to
2901 L</search> or by calling L</set_cache>.
2902
2903 =cut
2904
2905 sub get_cache {
2906   shift->{all_cache};
2907 }
2908
2909 =head2 set_cache
2910
2911 =over 4
2912
2913 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2914
2915 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2916
2917 =back
2918
2919 Sets the contents of the cache for the resultset. Expects an arrayref
2920 of objects of the same class as those produced by the resultset. Note that
2921 if the cache is set, the resultset will return the cached objects rather
2922 than re-querying the database even if the cache attr is not set.
2923
2924 The contents of the cache can also be populated by using the
2925 L</prefetch> attribute to L</search>.
2926
2927 =cut
2928
2929 sub set_cache {
2930   my ( $self, $data ) = @_;
2931   $self->throw_exception("set_cache requires an arrayref")
2932       if defined($data) && (ref $data ne 'ARRAY');
2933   $self->{all_cache} = $data;
2934 }
2935
2936 =head2 clear_cache
2937
2938 =over 4
2939
2940 =item Arguments: none
2941
2942 =item Return Value: undef
2943
2944 =back
2945
2946 Clears the cache for the resultset.
2947
2948 =cut
2949
2950 sub clear_cache {
2951   shift->set_cache(undef);
2952 }
2953
2954 =head2 is_paged
2955
2956 =over 4
2957
2958 =item Arguments: none
2959
2960 =item Return Value: true, if the resultset has been paginated
2961
2962 =back
2963
2964 =cut
2965
2966 sub is_paged {
2967   my ($self) = @_;
2968   return !!$self->{attrs}{page};
2969 }
2970
2971 =head2 is_ordered
2972
2973 =over 4
2974
2975 =item Arguments: none
2976
2977 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2978
2979 =back
2980
2981 =cut
2982
2983 sub is_ordered {
2984   my ($self) = @_;
2985   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2986 }
2987
2988 =head2 related_resultset
2989
2990 =over 4
2991
2992 =item Arguments: $rel_name
2993
2994 =item Return Value: L<$resultset|/search>
2995
2996 =back
2997
2998 Returns a related resultset for the supplied relationship name.
2999
3000   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3001
3002 =cut
3003
3004 sub related_resultset {
3005   my ($self, $rel) = @_;
3006
3007   $self->{related_resultsets} ||= {};
3008   return $self->{related_resultsets}{$rel} ||= do {
3009     my $rsrc = $self->result_source;
3010     my $rel_info = $rsrc->relationship_info($rel);
3011
3012     $self->throw_exception(
3013       "search_related: result source '" . $rsrc->source_name .
3014         "' has no such relationship $rel")
3015       unless $rel_info;
3016
3017     my $attrs = $self->_chain_relationship($rel);
3018
3019     my $join_count = $attrs->{seen_join}{$rel};
3020
3021     my $alias = $self->result_source->storage
3022         ->relname_to_table_alias($rel, $join_count);
3023
3024     # since this is search_related, and we already slid the select window inwards
3025     # (the select/as attrs were deleted in the beginning), we need to flip all
3026     # left joins to inner, so we get the expected results
3027     # read the comment on top of the actual function to see what this does
3028     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3029
3030
3031     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3032     delete @{$attrs}{qw(result_class alias)};
3033
3034     my $new_cache;
3035
3036     if (my $cache = $self->get_cache) {
3037       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3038         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3039                         @$cache ];
3040       }
3041     }
3042
3043     my $rel_source = $rsrc->related_source($rel);
3044
3045     my $new = do {
3046
3047       # The reason we do this now instead of passing the alias to the
3048       # search_rs below is that if you wrap/overload resultset on the
3049       # source you need to know what alias it's -going- to have for things
3050       # to work sanely (e.g. RestrictWithObject wants to be able to add
3051       # extra query restrictions, and these may need to be $alias.)
3052
3053       my $rel_attrs = $rel_source->resultset_attributes;
3054       local $rel_attrs->{alias} = $alias;
3055
3056       $rel_source->resultset
3057                  ->search_rs(
3058                      undef, {
3059                        %$attrs,
3060                        where => $attrs->{where},
3061                    });
3062     };
3063     $new->set_cache($new_cache) if $new_cache;
3064     $new;
3065   };
3066 }
3067
3068 =head2 current_source_alias
3069
3070 =over 4
3071
3072 =item Arguments: none
3073
3074 =item Return Value: $source_alias
3075
3076 =back
3077
3078 Returns the current table alias for the result source this resultset is built
3079 on, that will be used in the SQL query. Usually it is C<me>.
3080
3081 Currently the source alias that refers to the result set returned by a
3082 L</search>/L</find> family method depends on how you got to the resultset: it's
3083 C<me> by default, but eg. L</search_related> aliases it to the related result
3084 source name (and keeps C<me> referring to the original result set). The long
3085 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3086 (and make this method unnecessary).
3087
3088 Thus it's currently necessary to use this method in predefined queries (see
3089 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3090 source alias of the current result set:
3091
3092   # in a result set class
3093   sub modified_by {
3094     my ($self, $user) = @_;
3095
3096     my $me = $self->current_source_alias;
3097
3098     return $self->search({
3099       "$me.modified" => $user->id,
3100     });
3101   }
3102
3103 =cut
3104
3105 sub current_source_alias {
3106   return (shift->{attrs} || {})->{alias} || 'me';
3107 }
3108
3109 =head2 as_subselect_rs
3110
3111 =over 4
3112
3113 =item Arguments: none
3114
3115 =item Return Value: L<$resultset|/search>
3116
3117 =back
3118
3119 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3120 "virtual view" by including it as a subquery within the from clause.  From this
3121 point on, any joined tables are inaccessible to ->search on the resultset (as if
3122 it were simply where-filtered without joins).  For example:
3123
3124  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3125
3126  # 'x' now pollutes the query namespace
3127
3128  # So the following works as expected
3129  my $ok_rs = $rs->search({'x.other' => 1});
3130
3131  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3132  # def) we look for one row with contradictory terms and join in another table
3133  # (aliased 'x_2') which we never use
3134  my $broken_rs = $rs->search({'x.name' => 'def'});
3135
3136  my $rs2 = $rs->as_subselect_rs;
3137
3138  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3139  my $not_joined_rs = $rs2->search({'x.other' => 1});
3140
3141  # works as expected: finds a 'table' row related to two x rows (abc and def)
3142  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3143
3144 Another example of when one might use this would be to select a subset of
3145 columns in a group by clause:
3146
3147  my $rs = $schema->resultset('Bar')->search(undef, {
3148    group_by => [qw{ id foo_id baz_id }],
3149  })->as_subselect_rs->search(undef, {
3150    columns => [qw{ id foo_id }]
3151  });
3152
3153 In the above example normally columns would have to be equal to the group by,
3154 but because we isolated the group by into a subselect the above works.
3155
3156 =cut
3157
3158 sub as_subselect_rs {
3159   my $self = shift;
3160
3161   my $attrs = $self->_resolved_attrs;
3162
3163   my $fresh_rs = (ref $self)->new (
3164     $self->result_source
3165   );
3166
3167   # these pieces will be locked in the subquery
3168   delete $fresh_rs->{cond};
3169   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3170
3171   return $fresh_rs->search( {}, {
3172     from => [{
3173       $attrs->{alias} => $self->as_query,
3174       -alias  => $attrs->{alias},
3175       -rsrc   => $self->result_source,
3176     }],
3177     alias => $attrs->{alias},
3178   });
3179 }
3180
3181 # This code is called by search_related, and makes sure there
3182 # is clear separation between the joins before, during, and
3183 # after the relationship. This information is needed later
3184 # in order to properly resolve prefetch aliases (any alias
3185 # with a relation_chain_depth less than the depth of the
3186 # current prefetch is not considered)
3187 #
3188 # The increments happen twice per join. An even number means a
3189 # relationship specified via a search_related, whereas an odd
3190 # number indicates a join/prefetch added via attributes
3191 #
3192 # Also this code will wrap the current resultset (the one we
3193 # chain to) in a subselect IFF it contains limiting attributes
3194 sub _chain_relationship {
3195   my ($self, $rel) = @_;
3196   my $source = $self->result_source;
3197   my $attrs = { %{$self->{attrs}||{}} };
3198
3199   # we need to take the prefetch the attrs into account before we
3200   # ->_resolve_join as otherwise they get lost - captainL
3201   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3202
3203   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3204
3205   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3206
3207   my $from;
3208   my @force_subq_attrs = qw/offset rows group_by having/;
3209
3210   if (
3211     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3212       ||
3213     $self->_has_resolved_attr (@force_subq_attrs)
3214   ) {
3215     # Nuke the prefetch (if any) before the new $rs attrs
3216     # are resolved (prefetch is useless - we are wrapping
3217     # a subquery anyway).
3218     my $rs_copy = $self->search;
3219     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3220       $rs_copy->{attrs}{join},
3221       delete $rs_copy->{attrs}{prefetch},
3222     );
3223
3224     $from = [{
3225       -rsrc   => $source,
3226       -alias  => $attrs->{alias},
3227       $attrs->{alias} => $rs_copy->as_query,
3228     }];
3229     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3230     $seen->{-relation_chain_depth} = 0;
3231   }
3232   elsif ($attrs->{from}) {  #shallow copy suffices
3233     $from = [ @{$attrs->{from}} ];
3234   }
3235   else {
3236     $from = [{
3237       -rsrc  => $source,
3238       -alias => $attrs->{alias},
3239       $attrs->{alias} => $source->from,
3240     }];
3241   }
3242
3243   my $jpath = ($seen->{-relation_chain_depth})
3244     ? $from->[-1][0]{-join_path}
3245     : [];
3246
3247   my @requested_joins = $source->_resolve_join(
3248     $join,
3249     $attrs->{alias},
3250     $seen,
3251     $jpath,
3252   );
3253
3254   push @$from, @requested_joins;
3255
3256   $seen->{-relation_chain_depth}++;
3257
3258   # if $self already had a join/prefetch specified on it, the requested
3259   # $rel might very well be already included. What we do in this case
3260   # is effectively a no-op (except that we bump up the chain_depth on
3261   # the join in question so we could tell it *is* the search_related)
3262   my $already_joined;
3263
3264   # we consider the last one thus reverse
3265   for my $j (reverse @requested_joins) {
3266     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3267     if ($rel eq $last_j) {
3268       $j->[0]{-relation_chain_depth}++;
3269       $already_joined++;
3270       last;
3271     }
3272   }
3273
3274   unless ($already_joined) {
3275     push @$from, $source->_resolve_join(
3276       $rel,
3277       $attrs->{alias},
3278       $seen,
3279       $jpath,
3280     );
3281   }
3282
3283   $seen->{-relation_chain_depth}++;
3284
3285   return {%$attrs, from => $from, seen_join => $seen};
3286 }
3287
3288 sub _resolved_attrs {
3289   my $self = shift;
3290   return $self->{_attrs} if $self->{_attrs};
3291
3292   my $attrs  = { %{ $self->{attrs} || {} } };
3293   my $source = $self->result_source;
3294   my $alias  = $attrs->{alias};
3295
3296   # default selection list
3297   $attrs->{columns} = [ $source->columns ]
3298     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3299
3300   # merge selectors together
3301   for (qw/columns select as/) {
3302     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3303       if $attrs->{$_} or $attrs->{"+$_"};
3304   }
3305
3306   # disassemble columns
3307   my (@sel, @as);
3308   if (my $cols = delete $attrs->{columns}) {
3309     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3310       if (ref $c eq 'HASH') {
3311         for my $as (sort keys %$c) {
3312           push @sel, $c->{$as};
3313           push @as, $as;
3314         }
3315       }
3316       else {
3317         push @sel, $c;
3318         push @as, $c;
3319       }
3320     }
3321   }
3322
3323   # when trying to weed off duplicates later do not go past this point -
3324   # everything added from here on is unbalanced "anyone's guess" stuff
3325   my $dedup_stop_idx = $#as;
3326
3327   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3328     if $attrs->{as};
3329   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3330     if $attrs->{select};
3331
3332   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3333   for (@sel) {
3334     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3335   }
3336
3337   # disqualify all $alias.col as-bits (collapser mandated)
3338   for (@as) {
3339     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3340   }
3341
3342   # de-duplicate the result (remove *identical* select/as pairs)
3343   # and also die on duplicate {as} pointing to different {select}s
3344   # not using a c-style for as the condition is prone to shrinkage
3345   my $seen;
3346   my $i = 0;
3347   while ($i <= $dedup_stop_idx) {
3348     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3349       splice @sel, $i, 1;
3350       splice @as, $i, 1;
3351       $dedup_stop_idx--;
3352     }
3353     elsif ($seen->{$as[$i]}++) {
3354       $self->throw_exception(
3355         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3356       );
3357     }
3358     else {
3359       $i++;
3360     }
3361   }
3362
3363   $attrs->{select} = \@sel;
3364   $attrs->{as} = \@as;
3365
3366   $attrs->{from} ||= [{
3367     -rsrc   => $source,
3368     -alias  => $self->{attrs}{alias},
3369     $self->{attrs}{alias} => $source->from,
3370   }];
3371
3372   if ( $attrs->{join} || $attrs->{prefetch} ) {
3373
3374     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3375       if ref $attrs->{from} ne 'ARRAY';
3376
3377     my $join = (delete $attrs->{join}) || {};
3378
3379     if ( defined $attrs->{prefetch} ) {
3380       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3381     }
3382
3383     $attrs->{from} =    # have to copy here to avoid corrupting the original
3384       [
3385         @{ $attrs->{from} },
3386         $source->_resolve_join(
3387           $join,
3388           $alias,
3389           { %{ $attrs->{seen_join} || {} } },
3390           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3391             ? $attrs->{from}[-1][0]{-join_path}
3392             : []
3393           ,
3394         )
3395       ];
3396   }
3397
3398   if ( defined $attrs->{order_by} ) {
3399     $attrs->{order_by} = (
3400       ref( $attrs->{order_by} ) eq 'ARRAY'
3401       ? [ @{ $attrs->{order_by} } ]
3402       : [ $attrs->{order_by} || () ]
3403     );
3404   }
3405
3406   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3407     $attrs->{group_by} = [ $attrs->{group_by} ];
3408   }
3409
3410   # generate the distinct induced group_by early, as prefetch will be carried via a
3411   # subquery (since a group_by is present)
3412   if (delete $attrs->{distinct}) {
3413     if ($attrs->{group_by}) {
3414       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3415     }
3416     else {
3417       # distinct affects only the main selection part, not what prefetch may
3418       # add below.
3419       $attrs->{group_by} = $source->storage->_group_over_selection (
3420         $attrs->{from},
3421         $attrs->{select},
3422         $attrs->{order_by},
3423       );
3424     }
3425   }
3426
3427   $attrs->{collapse} ||= {};
3428   if ($attrs->{prefetch}) {
3429
3430     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3431       if $attrs->{_dark_selector};
3432
3433     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3434
3435     my $prefetch_ordering = [];
3436
3437     # this is a separate structure (we don't look in {from} directly)
3438     # as the resolver needs to shift things off the lists to work
3439     # properly (identical-prefetches on different branches)
3440     my $join_map = {};
3441     if (ref $attrs->{from} eq 'ARRAY') {
3442
3443       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3444
3445       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3446         next unless $j->[0]{-alias};
3447         next unless $j->[0]{-join_path};
3448         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3449
3450         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3451
3452         my $p = $join_map;
3453         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3454         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3455       }
3456     }
3457
3458     my @prefetch =
3459       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3460
3461     # we need to somehow mark which columns came from prefetch
3462     if (@prefetch) {
3463       my $sel_end = $#{$attrs->{select}};
3464       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3465     }
3466
3467     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3468     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3469
3470     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3471     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3472   }
3473
3474   # if both page and offset are specified, produce a combined offset
3475   # even though it doesn't make much sense, this is what pre 081xx has
3476   # been doing
3477   if (my $page = delete $attrs->{page}) {
3478     $attrs->{offset} =
3479       ($attrs->{rows} * ($page - 1))
3480             +
3481       ($attrs->{offset} || 0)
3482     ;
3483   }
3484
3485   return $self->{_attrs} = $attrs;
3486 }
3487
3488 sub _rollout_attr {
3489   my ($self, $attr) = @_;
3490
3491   if (ref $attr eq 'HASH') {
3492     return $self->_rollout_hash($attr);
3493   } elsif (ref $attr eq 'ARRAY') {
3494     return $self->_rollout_array($attr);
3495   } else {
3496     return [$attr];
3497   }
3498 }
3499
3500 sub _rollout_array {
3501   my ($self, $attr) = @_;
3502
3503   my @rolled_array;
3504   foreach my $element (@{$attr}) {
3505     if (ref $element eq 'HASH') {
3506       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3507     } elsif (ref $element eq 'ARRAY') {
3508       #  XXX - should probably recurse here
3509       push( @rolled_array, @{$self->_rollout_array($element)} );
3510     } else {
3511       push( @rolled_array, $element );
3512     }
3513   }
3514   return \@rolled_array;
3515 }
3516
3517 sub _rollout_hash {
3518   my ($self, $attr) = @_;
3519
3520   my @rolled_array;
3521   foreach my $key (keys %{$attr}) {
3522     push( @rolled_array, { $key => $attr->{$key} } );
3523   }
3524   return \@rolled_array;
3525 }
3526
3527 sub _calculate_score {
3528   my ($self, $a, $b) = @_;
3529
3530   if (defined $a xor defined $b) {
3531     return 0;
3532   }
3533   elsif (not defined $a) {
3534     return 1;
3535   }
3536
3537   if (ref $b eq 'HASH') {
3538     my ($b_key) = keys %{$b};
3539     if (ref $a eq 'HASH') {
3540       my ($a_key) = keys %{$a};
3541       if ($a_key eq $b_key) {
3542         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3543       } else {
3544         return 0;
3545       }
3546     } else {
3547       return ($a eq $b_key) ? 1 : 0;
3548     }
3549   } else {
3550     if (ref $a eq 'HASH') {
3551       my ($a_key) = keys %{$a};
3552       return ($b eq $a_key) ? 1 : 0;
3553     } else {
3554       return ($b eq $a) ? 1 : 0;
3555     }
3556   }
3557 }
3558
3559 sub _merge_joinpref_attr {
3560   my ($self, $orig, $import) = @_;
3561
3562   return $import unless defined($orig);
3563   return $orig unless defined($import);
3564
3565   $orig = $self->_rollout_attr($orig);
3566   $import = $self->_rollout_attr($import);
3567
3568   my $seen_keys;
3569   foreach my $import_element ( @{$import} ) {
3570     # find best candidate from $orig to merge $b_element into
3571     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3572     foreach my $orig_element ( @{$orig} ) {
3573       my $score = $self->_calculate_score( $orig_element, $import_element );
3574       if ($score > $best_candidate->{score}) {
3575         $best_candidate->{position} = $position;
3576         $best_candidate->{score} = $score;
3577       }
3578       $position++;
3579     }
3580     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3581     $import_key = '' if not defined $import_key;
3582
3583     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3584       push( @{$orig}, $import_element );
3585     } else {
3586       my $orig_best = $orig->[$best_candidate->{position}];
3587       # merge orig_best and b_element together and replace original with merged
3588       if (ref $orig_best ne 'HASH') {
3589         $orig->[$best_candidate->{position}] = $import_element;
3590       } elsif (ref $import_element eq 'HASH') {
3591         my ($key) = keys %{$orig_best};
3592         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3593       }
3594     }
3595     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3596   }
3597
3598   return $orig;
3599 }
3600
3601 {
3602   my $hm;
3603
3604   sub _merge_attr {
3605     $hm ||= do {
3606       require Hash::Merge;
3607       my $hm = Hash::Merge->new;
3608
3609       $hm->specify_behavior({
3610         SCALAR => {
3611           SCALAR => sub {
3612             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3613
3614             if ($defl xor $defr) {
3615               return [ $defl ? $_[0] : $_[1] ];
3616             }
3617             elsif (! $defl) {
3618               return [];
3619             }
3620             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3621               return [ $_[0] ];
3622             }
3623             else {
3624               return [$_[0], $_[1]];
3625             }
3626           },
3627           ARRAY => sub {
3628             return $_[1] if !defined $_[0];
3629             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3630             return [$_[0], @{$_[1]}]
3631           },
3632           HASH  => sub {
3633             return [] if !defined $_[0] and !keys %{$_[1]};
3634             return [ $_[1] ] if !defined $_[0];
3635             return [ $_[0] ] if !keys %{$_[1]};
3636             return [$_[0], $_[1]]
3637           },
3638         },
3639         ARRAY => {
3640           SCALAR => sub {
3641             return $_[0] if !defined $_[1];
3642             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3643             return [@{$_[0]}, $_[1]]
3644           },
3645           ARRAY => sub {
3646             my @ret = @{$_[0]} or return $_[1];
3647             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3648             my %idx = map { $_ => 1 } @ret;
3649             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3650             \@ret;
3651           },
3652           HASH => sub {
3653             return [ $_[1] ] if ! @{$_[0]};
3654             return $_[0] if !keys %{$_[1]};
3655             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3656             return [ @{$_[0]}, $_[1] ];
3657           },
3658         },
3659         HASH => {
3660           SCALAR => sub {
3661             return [] if !keys %{$_[0]} and !defined $_[1];
3662             return [ $_[0] ] if !defined $_[1];
3663             return [ $_[1] ] if !keys %{$_[0]};
3664             return [$_[0], $_[1]]
3665           },
3666           ARRAY => sub {
3667             return [] if !keys %{$_[0]} and !@{$_[1]};
3668             return [ $_[0] ] if !@{$_[1]};
3669             return $_[1] if !keys %{$_[0]};
3670             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3671             return [ $_[0], @{$_[1]} ];
3672           },
3673           HASH => sub {
3674             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3675             return [ $_[0] ] if !keys %{$_[1]};
3676             return [ $_[1] ] if !keys %{$_[0]};
3677             return [ $_[0] ] if $_[0] eq $_[1];
3678             return [ $_[0], $_[1] ];
3679           },
3680         }
3681       } => 'DBIC_RS_ATTR_MERGER');
3682       $hm;
3683     };
3684
3685     return $hm->merge ($_[1], $_[2]);
3686   }
3687 }
3688
3689 sub STORABLE_freeze {
3690   my ($self, $cloning) = @_;
3691   my $to_serialize = { %$self };
3692
3693   # A cursor in progress can't be serialized (and would make little sense anyway)
3694   delete $to_serialize->{cursor};
3695
3696   # nor is it sensical to store a not-yet-fired-count pager
3697   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3698     delete $to_serialize->{pager};
3699   }
3700
3701   Storable::nfreeze($to_serialize);
3702 }
3703
3704 # need this hook for symmetry
3705 sub STORABLE_thaw {
3706   my ($self, $cloning, $serialized) = @_;
3707
3708   %$self = %{ Storable::thaw($serialized) };
3709
3710   $self;
3711 }
3712
3713
3714 =head2 throw_exception
3715
3716 See L<DBIx::Class::Schema/throw_exception> for details.
3717
3718 =cut
3719
3720 sub throw_exception {
3721   my $self=shift;
3722
3723   if (ref $self and my $rsrc = $self->result_source) {
3724     $rsrc->throw_exception(@_)
3725   }
3726   else {
3727     DBIx::Class::Exception->throw(@_);
3728   }
3729 }
3730
3731 # XXX: FIXME: Attributes docs need clearing up
3732
3733 =head1 ATTRIBUTES
3734
3735 Attributes are used to refine a ResultSet in various ways when
3736 searching for data. They can be passed to any method which takes an
3737 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3738 L</count>.
3739
3740 Default attributes can be set on the result class using
3741 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3742 the CAVEATS on that feature before using it!)
3743
3744 These are in no particular order:
3745
3746 =head2 order_by
3747
3748 =over 4
3749
3750 =item Value: ( $order_by | \@order_by | \%order_by )
3751
3752 =back
3753
3754 Which column(s) to order the results by.
3755
3756 [The full list of suitable values is documented in
3757 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3758 common options.]
3759
3760 If a single column name, or an arrayref of names is supplied, the
3761 argument is passed through directly to SQL. The hashref syntax allows
3762 for connection-agnostic specification of ordering direction:
3763
3764  For descending order:
3765
3766   order_by => { -desc => [qw/col1 col2 col3/] }
3767
3768  For explicit ascending order:
3769
3770   order_by => { -asc => 'col' }
3771
3772 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3773 supported, although you are strongly encouraged to use the hashref
3774 syntax as outlined above.
3775
3776 =head2 columns
3777
3778 =over 4
3779
3780 =item Value: \@columns
3781
3782 =back
3783
3784 Shortcut to request a particular set of columns to be retrieved. Each
3785 column spec may be a string (a table column name), or a hash (in which
3786 case the key is the C<as> value, and the value is used as the C<select>
3787 expression). Adds C<me.> onto the start of any column without a C<.> in
3788 it and sets C<select> from that, then auto-populates C<as> from
3789 C<select> as normal. (You may also use the C<cols> attribute, as in
3790 earlier versions of DBIC.)
3791
3792 Essentially C<columns> does the same as L</select> and L</as>.
3793
3794     columns => [ 'foo', { bar => 'baz' } ]
3795
3796 is the same as
3797
3798     select => [qw/foo baz/],
3799     as => [qw/foo bar/]
3800
3801 =head2 +columns
3802
3803 =over 4
3804
3805 =item Value: \@columns
3806
3807 =back
3808
3809 Indicates additional columns to be selected from storage. Works the same
3810 as L</columns> but adds columns to the selection. (You may also use the
3811 C<include_columns> attribute, as in earlier versions of DBIC). For
3812 example:-
3813
3814   $schema->resultset('CD')->search(undef, {
3815     '+columns' => ['artist.name'],
3816     join => ['artist']
3817   });
3818
3819 would return all CDs and include a 'name' column to the information
3820 passed to object inflation. Note that the 'artist' is the name of the
3821 column (or relationship) accessor, and 'name' is the name of the column
3822 accessor in the related table.
3823
3824 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3825 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3826 unary plus operator before it.
3827
3828 =head2 include_columns
3829
3830 =over 4
3831
3832 =item Value: \@columns
3833
3834 =back
3835
3836 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3837
3838 =head2 select
3839
3840 =over 4
3841
3842 =item Value: \@select_columns
3843
3844 =back
3845
3846 Indicates which columns should be selected from the storage. You can use
3847 column names, or in the case of RDBMS back ends, function or stored procedure
3848 names:
3849
3850   $rs = $schema->resultset('Employee')->search(undef, {
3851     select => [
3852       'name',
3853       { count => 'employeeid' },
3854       { max => { length => 'name' }, -as => 'longest_name' }
3855     ]
3856   });
3857
3858   # Equivalent SQL
3859   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3860
3861 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3862 use L</select>, to instruct DBIx::Class how to store the result of the column.
3863 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3864 identifier aliasing. You can however alias a function, so you can use it in
3865 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3866 attribute> supplied as shown in the example above.
3867
3868 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3869 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3870 unary plus operator before it.
3871
3872 =head2 +select
3873
3874 =over 4
3875
3876 Indicates additional columns to be selected from storage.  Works the same as
3877 L</select> but adds columns to the default selection, instead of specifying
3878 an explicit list.
3879
3880 =back
3881
3882 =head2 +as
3883
3884 =over 4
3885
3886 Indicates additional column names for those added via L</+select>. See L</as>.
3887
3888 =back
3889
3890 =head2 as
3891
3892 =over 4
3893
3894 =item Value: \@inflation_names
3895
3896 =back
3897
3898 Indicates column names for object inflation. That is L</as> indicates the
3899 slot name in which the column value will be stored within the
3900 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3901 identifier by the C<get_column> method (or via the object accessor B<if one
3902 with the same name already exists>) as shown below. The L</as> attribute has
3903 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3904
3905   $rs = $schema->resultset('Employee')->search(undef, {
3906     select => [
3907       'name',
3908       { count => 'employeeid' },
3909       { max => { length => 'name' }, -as => 'longest_name' }
3910     ],
3911     as => [qw/
3912       name
3913       employee_count
3914       max_name_length
3915     /],
3916   });
3917
3918 If the object against which the search is performed already has an accessor
3919 matching a column name specified in C<as>, the value can be retrieved using
3920 the accessor as normal:
3921
3922   my $name = $employee->name();
3923
3924 If on the other hand an accessor does not exist in the object, you need to
3925 use C<get_column> instead:
3926
3927   my $employee_count = $employee->get_column('employee_count');
3928
3929 You can create your own accessors if required - see
3930 L<DBIx::Class::Manual::Cookbook> for details.
3931
3932 =head2 join
3933
3934 =over 4
3935
3936 =item Value: ($rel_name | \@rel_names | \%rel_names)
3937
3938 =back
3939
3940 Contains a list of relationships that should be joined for this query.  For
3941 example:
3942
3943   # Get CDs by Nine Inch Nails
3944   my $rs = $schema->resultset('CD')->search(
3945     { 'artist.name' => 'Nine Inch Nails' },
3946     { join => 'artist' }
3947   );
3948
3949 Can also contain a hash reference to refer to the other relation's relations.
3950 For example:
3951
3952   package MyApp::Schema::Track;
3953   use base qw/DBIx::Class/;
3954   __PACKAGE__->table('track');
3955   __PACKAGE__->add_columns(qw/trackid cd position title/);
3956   __PACKAGE__->set_primary_key('trackid');
3957   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3958   1;
3959
3960   # In your application
3961   my $rs = $schema->resultset('Artist')->search(
3962     { 'track.title' => 'Teardrop' },
3963     {
3964       join     => { cd => 'track' },
3965       order_by => 'artist.name',
3966     }
3967   );
3968
3969 You need to use the relationship (not the table) name in  conditions,
3970 because they are aliased as such. The current table is aliased as "me", so
3971 you need to use me.column_name in order to avoid ambiguity. For example:
3972
3973   # Get CDs from 1984 with a 'Foo' track
3974   my $rs = $schema->resultset('CD')->search(
3975     {
3976       'me.year' => 1984,
3977       'tracks.name' => 'Foo'
3978     },
3979     { join => 'tracks' }
3980   );
3981
3982 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3983 similarly for a third time). For e.g.
3984
3985   my $rs = $schema->resultset('Artist')->search({
3986     'cds.title'   => 'Down to Earth',
3987     'cds_2.title' => 'Popular',
3988   }, {
3989     join => [ qw/cds cds/ ],
3990   });
3991
3992 will return a set of all artists that have both a cd with title 'Down
3993 to Earth' and a cd with title 'Popular'.
3994
3995 If you want to fetch related objects from other tables as well, see C<prefetch>
3996 below.
3997
3998  NOTE: An internal join-chain pruner will discard certain joins while
3999  constructing the actual SQL query, as long as the joins in question do not
4000  affect the retrieved result. This for example includes 1:1 left joins
4001  that are not part of the restriction specification (WHERE/HAVING) nor are
4002  a part of the query selection.
4003
4004 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4005
4006 =head2 prefetch
4007
4008 =over 4
4009
4010 =item Value: ($rel_name | \@rel_names | \%rel_names)
4011
4012 =back
4013
4014 Contains one or more relationships that should be fetched along with
4015 the main query (when they are accessed afterwards the data will
4016 already be available, without extra queries to the database).  This is
4017 useful for when you know you will need the related objects, because it
4018 saves at least one query:
4019
4020   my $rs = $schema->resultset('Tag')->search(
4021     undef,
4022     {
4023       prefetch => {
4024         cd => 'artist'
4025       }
4026     }
4027   );
4028
4029 The initial search results in SQL like the following:
4030
4031   SELECT tag.*, cd.*, artist.* FROM tag
4032   JOIN cd ON tag.cd = cd.cdid
4033   JOIN artist ON cd.artist = artist.artistid
4034
4035 L<DBIx::Class> has no need to go back to the database when we access the
4036 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4037 case.
4038
4039 Simple prefetches will be joined automatically, so there is no need
4040 for a C<join> attribute in the above search.
4041
4042 L</prefetch> can be used with the any of the relationship types and
4043 multiple prefetches can be specified together. Below is a more complex
4044 example that prefetches a CD's artist, its liner notes (if present),
4045 the cover image, the tracks on that cd, and the guests on those
4046 tracks.
4047
4048  # Assuming:
4049  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4050  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4051  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4052  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4053
4054  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4055
4056  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4057
4058
4059  my $rs = $schema->resultset('CD')->search(
4060    undef,
4061    {
4062      prefetch => [
4063        { artist => 'record_label'},  # belongs_to => belongs_to
4064        'liner_note',                 # might_have
4065        'cover_image',                # has_one
4066        { tracks => 'guests' },       # has_many => has_many
4067      ]
4068    }
4069  );
4070
4071 This will produce SQL like the following:
4072
4073  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4074         tracks.*, guests.*
4075    FROM cd me
4076    JOIN artist artist
4077      ON artist.artistid = me.artistid
4078    JOIN record_label record_label
4079      ON record_label.labelid = artist.labelid
4080    LEFT JOIN track tracks
4081      ON tracks.cdid = me.cdid
4082    LEFT JOIN guest guests
4083      ON guests.trackid = track.trackid
4084    LEFT JOIN liner_notes liner_note
4085      ON liner_note.cdid = me.cdid
4086    JOIN cd_artwork cover_image
4087      ON cover_image.cdid = me.cdid
4088  ORDER BY tracks.cd
4089
4090 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4091 C<tracks>, and C<guests> of the CD will all be available through the
4092 relationship accessors without the need for additional queries to the
4093 database.
4094
4095 However, there is one caveat to be observed: it can be dangerous to
4096 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4097 relationship on a given level. e.g.:
4098
4099  my $rs = $schema->resultset('CD')->search(
4100    undef,
4101    {
4102      prefetch => [
4103        'tracks',                         # has_many
4104        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4105      ]
4106    }
4107  );
4108
4109 The collapser currently can't identify duplicate tuples for multiple
4110 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4111 result the second L<has_many|DBIx::Class::Relationship/has_many>
4112 relation could contain redundant objects.
4113
4114 =head3 Using L</prefetch> with L</join>
4115
4116 L</prefetch> implies a L</join> with the equivalent argument, and is
4117 properly merged with any existing L</join> specification. So the
4118 following:
4119
4120   my $rs = $schema->resultset('CD')->search(
4121    {'record_label.name' => 'Music Product Ltd.'},
4122    {
4123      join     => {artist => 'record_label'},
4124      prefetch => 'artist',
4125    }
4126  );
4127
4128 ... will work, searching on the record label's name, but only
4129 prefetching the C<artist>.
4130
4131 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4132
4133 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4134 prefetched relations.  So given:
4135
4136   my $rs = $schema->resultset('CD')->search(
4137    undef,
4138    {
4139      select   => ['cd.title'],
4140      as       => ['cd_title'],
4141      prefetch => 'artist',
4142    }
4143  );
4144
4145 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4146 becomes: C<'cd_title', 'artist.*'>.
4147
4148 =head3 CAVEATS
4149
4150 Prefetch does a lot of deep magic. As such, it may not behave exactly
4151 as you might expect.
4152
4153 =over 4
4154
4155 =item *
4156
4157 Prefetch uses the L</cache> to populate the prefetched relationships. This
4158 may or may not be what you want.
4159
4160 =item *
4161
4162 If you specify a condition on a prefetched relationship, ONLY those
4163 rows that match the prefetched condition will be fetched into that relationship.
4164 This means that adding prefetch to a search() B<may alter> what is returned by
4165 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4166
4167   my $artist_rs = $schema->resultset('Artist')->search({
4168       'cds.year' => 2008,
4169   }, {
4170       join => 'cds',
4171   });
4172
4173   my $count = $artist_rs->first->cds->count;
4174
4175   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4176
4177   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4178
4179   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4180
4181 that cmp_ok() may or may not pass depending on the datasets involved. This
4182 behavior may or may not survive the 0.09 transition.
4183
4184 =back
4185
4186 =head2 alias
4187
4188 =over 4
4189
4190 =item Value: $source_alias
4191
4192 =back
4193
4194 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4195 nested search queries (sub-SELECTs) might need specific aliases set to
4196 reference inner queries.  For example:
4197
4198    my $q = $rs
4199       ->related_resultset('CDs')
4200       ->related_resultset('Tracks')
4201       ->search({
4202          'track.id' => { -ident => 'none_search.id' },
4203       })
4204       ->as_query;
4205
4206    my $ids = $self->search({
4207       -not_exists => $q,
4208    }, {
4209       alias    => 'none_search',
4210       group_by => 'none_search.id',
4211    })->get_column('id')->as_query;
4212
4213    $self->search({ id => { -in => $ids } })
4214
4215 This attribute is directly tied to L</current_source_alias>.
4216
4217 =head2 page
4218
4219 =over 4
4220
4221 =item Value: $page
4222
4223 =back
4224
4225 Makes the resultset paged and specifies the page to retrieve. Effectively
4226 identical to creating a non-pages resultset and then calling ->page($page)
4227 on it.
4228
4229 If L</rows> attribute is not specified it defaults to 10 rows per page.
4230
4231 When you have a paged resultset, L</count> will only return the number
4232 of rows in the page. To get the total, use the L</pager> and call
4233 C<total_entries> on it.
4234
4235 =head2 rows
4236
4237 =over 4
4238
4239 =item Value: $rows
4240
4241 =back
4242
4243 Specifies the maximum number of rows for direct retrieval or the number of
4244 rows per page if the page attribute or method is used.
4245
4246 =head2 offset
4247
4248 =over 4
4249
4250 =item Value: $offset
4251
4252 =back
4253
4254 Specifies the (zero-based) row number for the  first row to be returned, or the
4255 of the first row of the first page if paging is used.
4256
4257 =head2 software_limit
4258
4259 =over 4
4260
4261 =item Value: (0 | 1)
4262
4263 =back
4264
4265 When combined with L</rows> and/or L</offset> the generated SQL will not
4266 include any limit dialect stanzas. Instead the entire result will be selected
4267 as if no limits were specified, and DBIC will perform the limit locally, by
4268 artificially advancing and finishing the resulting L</cursor>.
4269
4270 This is the recommended way of performing resultset limiting when no sane RDBMS
4271 implementation is available (e.g.
4272 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4273 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4274
4275 =head2 group_by
4276
4277 =over 4
4278
4279 =item Value: \@columns
4280
4281 =back
4282
4283 A arrayref of columns to group by. Can include columns of joined tables.
4284
4285   group_by => [qw/ column1 column2 ... /]
4286
4287 =head2 having
4288
4289 =over 4
4290
4291 =item Value: $condition
4292
4293 =back
4294
4295 HAVING is a select statement attribute that is applied between GROUP BY and
4296 ORDER BY. It is applied to the after the grouping calculations have been
4297 done.
4298
4299   having => { 'count_employee' => { '>=', 100 } }
4300
4301 or with an in-place function in which case literal SQL is required:
4302
4303   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4304
4305 =head2 distinct
4306
4307 =over 4
4308
4309 =item Value: (0 | 1)
4310
4311 =back
4312
4313 Set to 1 to group by all columns. If the resultset already has a group_by
4314 attribute, this setting is ignored and an appropriate warning is issued.
4315
4316 =head2 where
4317
4318 =over 4
4319
4320 Adds to the WHERE clause.
4321
4322   # only return rows WHERE deleted IS NULL for all searches
4323   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4324
4325 Can be overridden by passing C<< { where => undef } >> as an attribute
4326 to a resultset.
4327
4328 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4329
4330 =back
4331
4332 =head2 cache
4333
4334 Set to 1 to cache search results. This prevents extra SQL queries if you
4335 revisit rows in your ResultSet:
4336
4337   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4338
4339   while( my $artist = $resultset->next ) {
4340     ... do stuff ...
4341   }
4342
4343   $rs->first; # without cache, this would issue a query
4344
4345 By default, searches are not cached.
4346
4347 For more examples of using these attributes, see
4348 L<DBIx::Class::Manual::Cookbook>.
4349
4350 =head2 for
4351
4352 =over 4
4353
4354 =item Value: ( 'update' | 'shared' | \$scalar )
4355
4356 =back
4357
4358 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4359 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4360 query.
4361
4362 =head1 DBIC BIND VALUES
4363
4364 Because DBIC may need more information to bind values than just the column name
4365 and value itself, it uses a special format for both passing and receiving bind
4366 values.  Each bind value should be composed of an arrayref of
4367 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4368
4369 =over 4
4370
4371 =item dbd_attrs
4372
4373 If present (in any form), this is what is being passed directly to bind_param.
4374 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4375 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4376
4377 If this is specified, all other bind options described below are ignored.
4378
4379 =item sqlt_datatype
4380
4381 If present, this is used to infer the actual bind attribute by passing to
4382 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4383 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4384
4385 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4386 currently drivers are expected to "Do the Right Thing" when given a common
4387 datatype name.  (Not ideal, but that's what we got at this point.)
4388
4389 =item sqlt_size
4390
4391 Currently used to correctly allocate buffers for bind_param_inout().
4392 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4393 or to a sensible value based on the "data_type".
4394
4395 =item dbic_colname
4396
4397 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4398 explicitly specified they are never overriden).  Also used by some weird DBDs,
4399 where the column name should be available at bind_param time (e.g. Oracle).
4400
4401 =back
4402
4403 For backwards compatibility and convenience, the following shortcuts are
4404 supported:
4405
4406   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4407   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4408   [ undef,   $val ] === [ {}, $val ]
4409
4410 =head1 AUTHOR AND CONTRIBUTORS
4411
4412 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4413
4414 =head1 LICENSE
4415
4416 You may distribute this code under the same terms as Perl itself.
4417
4418 =cut
4419
4420 1;