lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset (ie:
 145 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 146 and attributes with the same keys need resolving.
 147
 148 If any of L</columns>, L</select>, L</as> are present, they reset the
 149 original selection, and start the selection "clean".
 150
 151 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 152 are merged into the existing ones from the original resultset.
 153
 154 The L</where> and L</having> attributes, and any search conditions, are
 155 merged with an SQL C<AND> to the existing condition from the original
 156 resultset.
 157
 158 All other attributes are overridden by any new ones supplied in the
 159 search attributes.
 160
 161 =head2 Multiple queries
 162
 163 Since a resultset just defines a query, you can do all sorts of
 164 things with it with the same object.
 165
 166   # Don't hit the DB yet.
 167   my $cd_rs = $schema->resultset('CD')->search({
 168     title => 'something',
 169     year => 2009,
 170   });
 171
 172   # Each of these hits the DB individually.
 173   my $count = $cd_rs->count;
 174   my $most_recent = $cd_rs->get_column('date_released')->max();
 175   my @records = $cd_rs->all;
 176
 177 And it's not just limited to SELECT statements.
 178
 179   $cd_rs->delete();
 180
 181 This is even cooler:
 182
 183   $cd_rs->create({ artist => 'Fred' });
 184
 185 Which is the same as:
 186
 187   $schema->resultset('CD')->create({
 188     title => 'something',
 189     year => 2009,
 190     artist => 'Fred'
 191   });
 192
 193 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 194
 195 =head1 METHODS
 196
 197 =head2 new
 198
 199 =over 4
 200
 201 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 202
 203 =item Return Value: L<$resultset|/search>
 204
 205 =back
 206
 207 The resultset constructor. Takes a source object (usually a
 208 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 209 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 210 executed as needed by the other methods.
 211
 212 Generally you never construct a resultset manually. Instead you get one
 213 from e.g. a
 214 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 215 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 216 scalar context):
 217
 218   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 219
 220 =over
 221
 222 =item WARNING
 223
 224 If called on an object, proxies to L</new_result> instead, so
 225
 226   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 227
 228 will return a CD object, not a ResultSet, and is equivalent to:
 229
 230   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 231
 232 Please also keep in mind that many internals call L</new_result> directly,
 233 so overloading this method with the idea of intercepting new result object
 234 creation B<will not work>. See also warning pertaining to L</create>.
 235
 236 =back
 237
 238 =cut
 239
 240 sub new {
 241   my $class = shift;
 242   return $class->new_result(@_) if ref $class;
 243
 244   my ($source, $attrs) = @_;
 245   $source = $source->resolve
 246     if $source->isa('DBIx::Class::ResultSourceHandle');
 247   $attrs = { %{$attrs||{}} };
 248
 249   if ($attrs->{page}) {
 250     $attrs->{rows} ||= 10;
 251   }
 252
 253   $attrs->{alias} ||= 'me';
 254
 255   my $self = bless {
 256     result_source => $source,
 257     cond => $attrs->{where},
 258     pager => undef,
 259     attrs => $attrs,
 260   }, $class;
 261
 262   # if there is a dark selector, this means we are already in a
 263   # chain and the cleanup/sanification was taken care of by
 264   # _search_rs already
 265   $self->_normalize_selection($attrs)
 266     unless $attrs->{_dark_selector};
 267
 268   $self->result_class(
 269     $attrs->{result_class} || $source->result_class
 270   );
 271
 272   $self;
 273 }
 274
 275 =head2 search
 276
 277 =over 4
 278
 279 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 280
 281 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 282
 283 =back
 284
 285   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 286   my $new_rs = $cd_rs->search({ year => 2005 });
 287
 288   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 289                  # year = 2005 OR year = 2004
 290
 291 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 292 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 293 To avoid that, use L</search_rs>.
 294
 295 If you need to pass in additional attributes but no additional condition,
 296 call it as C<search(undef, \%attrs)>.
 297
 298   # "SELECT name, artistid FROM $artist_table"
 299   my @all_artists = $schema->resultset('Artist')->search(undef, {
 300     columns => [qw/name artistid/],
 301   });
 302
 303 For a list of attributes that can be passed to C<search>, see
 304 L</ATTRIBUTES>. For more examples of using this function, see
 305 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 306 documentation for the first argument, see L<SQL::Abstract>
 307 and its extension L<DBIx::Class::SQLMaker>.
 308
 309 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 310
 311 =head3 CAVEAT
 312
 313 Note that L</search> does not process/deflate any of the values passed in the
 314 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 315 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 316 manually that any value passed to this method will stringify to something the
 317 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 318 objects, for more info see:
 319 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 320
 321 =cut
 322
 323 sub search {
 324   my $self = shift;
 325   my $rs = $self->search_rs( @_ );
 326
 327   if (wantarray) {
 328     return $rs->all;
 329   }
 330   elsif (defined wantarray) {
 331     return $rs;
 332   }
 333   else {
 334     # we can be called by a relationship helper, which in
 335     # turn may be called in void context due to some braindead
 336     # overload or whatever else the user decided to be clever
 337     # at this particular day. Thus limit the exception to
 338     # external code calls only
 339     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 340       if (caller)[0] !~ /^\QDBIx::Class::/;
 341
 342     return ();
 343   }
 344 }
 345
 346 =head2 search_rs
 347
 348 =over 4
 349
 350 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 351
 352 =item Return Value: L<$resultset|/search>
 353
 354 =back
 355
 356 This method does the same exact thing as search() except it will
 357 always return a resultset, even in list context.
 358
 359 =cut
 360
 361 sub search_rs {
 362   my $self = shift;
 363
 364   my $rsrc = $self->result_source;
 365   my ($call_cond, $call_attrs);
 366
 367   # Special-case handling for (undef, undef) or (undef)
 368   # Note that (foo => undef) is valid deprecated syntax
 369   @_ = () if not scalar grep { defined $_ } @_;
 370
 371   # just a cond
 372   if (@_ == 1) {
 373     $call_cond = shift;
 374   }
 375   # fish out attrs in the ($condref, $attr) case
 376   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 377     ($call_cond, $call_attrs) = @_;
 378   }
 379   elsif (@_ % 2) {
 380     $self->throw_exception('Odd number of arguments to search')
 381   }
 382   # legacy search
 383   elsif (@_) {
 384     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 385       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 386
 387     for my $i (0 .. $#_) {
 388       next if $i % 2;
 389       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 390         if (! defined $_[$i] or ref $_[$i] ne '');
 391     }
 392
 393     $call_cond = { @_ };
 394   }
 395
 396   # see if we can keep the cache (no $rs changes)
 397   my $cache;
 398   my %safe = (alias => 1, cache => 1);
 399   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 400     ! defined $call_cond
 401       or
 402     ref $call_cond eq 'HASH' && ! keys %$call_cond
 403       or
 404     ref $call_cond eq 'ARRAY' && ! @$call_cond
 405   )) {
 406     $cache = $self->get_cache;
 407   }
 408
 409   my $old_attrs = { %{$self->{attrs}} };
 410   my $old_having = delete $old_attrs->{having};
 411   my $old_where = delete $old_attrs->{where};
 412
 413   my $new_attrs = { %$old_attrs };
 414
 415   # take care of call attrs (only if anything is changing)
 416   if ($call_attrs and keys %$call_attrs) {
 417
 418     # copy for _normalize_selection
 419     $call_attrs = { %$call_attrs };
 420
 421     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 422
 423     # reset the current selector list if new selectors are supplied
 424     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 425       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 426     }
 427
 428     # Normalize the new selector list (operates on the passed-in attr structure)
 429     # Need to do it on every chain instead of only once on _resolved_attrs, in
 430     # order to allow detection of empty vs partial 'as'
 431     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 432       if $old_attrs->{_dark_selector};
 433     $self->_normalize_selection ($call_attrs);
 434
 435     # start with blind overwriting merge, exclude selector attrs
 436     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 437     delete @{$new_attrs}{@selector_attrs};
 438
 439     for (@selector_attrs) {
 440       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 441         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 442     }
 443
 444     # older deprecated name, use only if {columns} is not there
 445     if (my $c = delete $new_attrs->{cols}) {
 446       if ($new_attrs->{columns}) {
 447         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 448       }
 449       else {
 450         $new_attrs->{columns} = $c;
 451       }
 452     }
 453
 454
 455     # join/prefetch use their own crazy merging heuristics
 456     foreach my $key (qw/join prefetch/) {
 457       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 458         if exists $call_attrs->{$key};
 459     }
 460
 461     # stack binds together
 462     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 463   }
 464
 465
 466   for ($old_where, $call_cond) {
 467     if (defined $_) {
 468       $new_attrs->{where} = $self->_stack_cond (
 469         $_, $new_attrs->{where}
 470       );
 471     }
 472   }
 473
 474   if (defined $old_having) {
 475     $new_attrs->{having} = $self->_stack_cond (
 476       $old_having, $new_attrs->{having}
 477     )
 478   }
 479
 480   my $rs = (ref $self)->new($rsrc, $new_attrs);
 481
 482   $rs->set_cache($cache) if ($cache);
 483
 484   return $rs;
 485 }
 486
 487 my $dark_sel_dumper;
 488 sub _normalize_selection {
 489   my ($self, $attrs) = @_;
 490
 491   # legacy syntax
 492   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 493     if exists $attrs->{include_columns};
 494
 495   # columns are always placed first, however
 496
 497   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 498   # delay the decision on whether to use a default select list ($rsrc->columns)
 499   # allowing stuff like the remove_columns helper to work
 500   #
 501   # select/as +select/+as pairs need special handling - the amount of select/as
 502   # elements in each pair does *not* have to be equal (think multicolumn
 503   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 504   # supplied at all) - try to infer the alias, either from the -as parameter
 505   # of the selector spec, or use the parameter whole if it looks like a column
 506   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 507   # is ok as well), but make sure no more additions to the 'as' chain take place
 508   for my $pref ('', '+') {
 509
 510     my ($sel, $as) = map {
 511       my $key = "${pref}${_}";
 512
 513       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 514         ? @{$attrs->{$key}}
 515         : $attrs->{$key} || ()
 516       ];
 517       delete $attrs->{$key};
 518       $val;
 519     } qw/select as/;
 520
 521     if (! @$as and ! @$sel ) {
 522       next;
 523     }
 524     elsif (@$as and ! @$sel) {
 525       $self->throw_exception(
 526         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 527       );
 528     }
 529     elsif( ! @$as ) {
 530       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 531       # if any @$as has been supplied we assume the user knows what (s)he is doing
 532       # and blindly keep stacking up pieces
 533       unless ($attrs->{_dark_selector}) {
 534         SELECTOR:
 535         for (@$sel) {
 536           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 537             push @$as, $_->{-as};
 538           }
 539           # assume any plain no-space, no-parenthesis string to be a column spec
 540           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 541           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 542             push @$as, $_;
 543           }
 544           # if all else fails - raise a flag that no more aliasing will be allowed
 545           else {
 546             $attrs->{_dark_selector} = {
 547               plus_stage => $pref,
 548               string => ($dark_sel_dumper ||= do {
 549                   require Data::Dumper::Concise;
 550                   Data::Dumper::Concise::DumperObject()->Indent(0);
 551                 })->Values([$_])->Dump
 552               ,
 553             };
 554             last SELECTOR;
 555           }
 556         }
 557       }
 558     }
 559     elsif (@$as < @$sel) {
 560       $self->throw_exception(
 561         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 562       );
 563     }
 564     elsif ($pref and $attrs->{_dark_selector}) {
 565       $self->throw_exception(
 566         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 567       );
 568     }
 569
 570
 571     # merge result
 572     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 573     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 574   }
 575 }
 576
 577 sub _stack_cond {
 578   my ($self, $left, $right) = @_;
 579
 580   # collapse single element top-level conditions
 581   # (single pass only, unlikely to need recursion)
 582   for ($left, $right) {
 583     if (ref $_ eq 'ARRAY') {
 584       if (@$_ == 0) {
 585         $_ = undef;
 586       }
 587       elsif (@$_ == 1) {
 588         $_ = $_->[0];
 589       }
 590     }
 591     elsif (ref $_ eq 'HASH') {
 592       my ($first, $more) = keys %$_;
 593
 594       # empty hash
 595       if (! defined $first) {
 596         $_ = undef;
 597       }
 598       # one element hash
 599       elsif (! defined $more) {
 600         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 601           $_ = $_->{'-and'};
 602         }
 603         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 604           $_ = $_->{'-or'};
 605         }
 606       }
 607     }
 608   }
 609
 610   # merge hashes with weeding out of duplicates (simple cases only)
 611   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 612
 613     # shallow copy to destroy
 614     $right = { %$right };
 615     for (grep { exists $right->{$_} } keys %$left) {
 616       # the use of eq_deeply here is justified - the rhs of an
 617       # expression can contain a lot of twisted weird stuff
 618       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 619     }
 620
 621     $right = undef unless keys %$right;
 622   }
 623
 624
 625   if (defined $left xor defined $right) {
 626     return defined $left ? $left : $right;
 627   }
 628   elsif (! defined $left) {
 629     return undef;
 630   }
 631   else {
 632     return { -and => [ $left, $right ] };
 633   }
 634 }
 635
 636 =head2 search_literal
 637
 638 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 639 should only be used in that context. C<search_literal> is a convenience
 640 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 641 want to ensure columns are bound correctly, use L</search>.
 642
 643 See L<DBIx::Class::Manual::Cookbook/Searching> and
 644 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 645 require C<search_literal>.
 646
 647 =over 4
 648
 649 =item Arguments: $sql_fragment, @standalone_bind_values
 650
 651 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 652
 653 =back
 654
 655   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 656   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 657
 658 Pass a literal chunk of SQL to be added to the conditional part of the
 659 resultset query.
 660
 661 Example of how to use C<search> instead of C<search_literal>
 662
 663   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 664   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 665
 666 =cut
 667
 668 sub search_literal {
 669   my ($self, $sql, @bind) = @_;
 670   my $attr;
 671   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 672     $attr = pop @bind;
 673   }
 674   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 675 }
 676
 677 =head2 find
 678
 679 =over 4
 680
 681 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 682
 683 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 684
 685 =back
 686
 687 Finds and returns a single row based on supplied criteria. Takes either a
 688 hashref with the same format as L</create> (including inference of foreign
 689 keys from related objects), or a list of primary key values in the same
 690 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 691 declaration on the L</result_source>.
 692
 693 In either case an attempt is made to combine conditions already existing on
 694 the resultset with the condition passed to this method.
 695
 696 To aid with preparing the correct query for the storage you may supply the
 697 C<key> attribute, which is the name of a
 698 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 699 unique constraint corresponding to the
 700 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 701 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 702 to construct a query that satisfies the named unique constraint fully (
 703 non-NULL values for each column member of the constraint) an exception is
 704 thrown.
 705
 706 If no C<key> is specified, the search is carried over all unique constraints
 707 which are fully defined by the available condition.
 708
 709 If no such constraint is found, C<find> currently defaults to a simple
 710 C<< search->(\%column_values) >> which may or may not do what you expect.
 711 Note that this fallback behavior may be deprecated in further versions. If
 712 you need to search with arbitrary conditions - use L</search>. If the query
 713 resulting from this fallback produces more than one row, a warning to the
 714 effect is issued, though only the first row is constructed and returned as
 715 C<$result_object>.
 716
 717 In addition to C<key>, L</find> recognizes and applies standard
 718 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 719
 720 Note that if you have extra concerns about the correctness of the resulting
 721 query you need to specify the C<key> attribute and supply the entire condition
 722 as an argument to find (since it is not always possible to perform the
 723 combination of the resultset condition with the supplied one, especially if
 724 the resultset condition contains literal sql).
 725
 726 For example, to find a row by its primary key:
 727
 728   my $cd = $schema->resultset('CD')->find(5);
 729
 730 You can also find a row by a specific unique constraint:
 731
 732   my $cd = $schema->resultset('CD')->find(
 733     {
 734       artist => 'Massive Attack',
 735       title  => 'Mezzanine',
 736     },
 737     { key => 'cd_artist_title' }
 738   );
 739
 740 See also L</find_or_create> and L</update_or_create>.
 741
 742 =cut
 743
 744 sub find {
 745   my $self = shift;
 746   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 747
 748   my $rsrc = $self->result_source;
 749
 750   my $constraint_name;
 751   if (exists $attrs->{key}) {
 752     $constraint_name = defined $attrs->{key}
 753       ? $attrs->{key}
 754       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 755     ;
 756   }
 757
 758   # Parse out the condition from input
 759   my $call_cond;
 760
 761   if (ref $_[0] eq 'HASH') {
 762     $call_cond = { %{$_[0]} };
 763   }
 764   else {
 765     # if only values are supplied we need to default to 'primary'
 766     $constraint_name = 'primary' unless defined $constraint_name;
 767
 768     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 769
 770     $self->throw_exception(
 771       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 772     ) unless @c_cols;
 773
 774     $self->throw_exception (
 775       'find() expects either a column/value hashref, or a list of values '
 776     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 777     ) unless @c_cols == @_;
 778
 779     $call_cond = {};
 780     @{$call_cond}{@c_cols} = @_;
 781   }
 782
 783   my %related;
 784   for my $key (keys %$call_cond) {
 785     if (
 786       my $keyref = ref($call_cond->{$key})
 787         and
 788       my $relinfo = $rsrc->relationship_info($key)
 789     ) {
 790       my $val = delete $call_cond->{$key};
 791
 792       next if $keyref eq 'ARRAY'; # has_many for multi_create
 793
 794       my $rel_q = $rsrc->_resolve_condition(
 795         $relinfo->{cond}, $val, $key, $key
 796       );
 797       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 798       @related{keys %$rel_q} = values %$rel_q;
 799     }
 800   }
 801
 802   # relationship conditions take precedence (?)
 803   @{$call_cond}{keys %related} = values %related;
 804
 805   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 806   my $final_cond;
 807   if (defined $constraint_name) {
 808     $final_cond = $self->_qualify_cond_columns (
 809
 810       $self->_build_unique_cond (
 811         $constraint_name,
 812         $call_cond,
 813       ),
 814
 815       $alias,
 816     );
 817   }
 818   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 819     # This means that we got here after a merger of relationship conditions
 820     # in ::Relationship::Base::search_related (the row method), and furthermore
 821     # the relationship is of the 'single' type. This means that the condition
 822     # provided by the relationship (already attached to $self) is sufficient,
 823     # as there can be only one row in the database that would satisfy the
 824     # relationship
 825   }
 826   else {
 827     # no key was specified - fall down to heuristics mode:
 828     # run through all unique queries registered on the resultset, and
 829     # 'OR' all qualifying queries together
 830     my (@unique_queries, %seen_column_combinations);
 831     for my $c_name ($rsrc->unique_constraint_names) {
 832       next if $seen_column_combinations{
 833         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 834       }++;
 835
 836       push @unique_queries, try {
 837         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 838       } || ();
 839     }
 840
 841     $final_cond = @unique_queries
 842       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 843       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 844     ;
 845   }
 846
 847   # Run the query, passing the result_class since it should propagate for find
 848   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 849   if ($rs->_resolved_attrs->{collapse}) {
 850     my $row = $rs->next;
 851     carp "Query returned more than one row" if $rs->next;
 852     return $row;
 853   }
 854   else {
 855     return $rs->single;
 856   }
 857 }
 858
 859 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 860 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 861 #
 862 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 863 # condition. It is provided for overrides until a saner way forward is devised
 864 #
 865 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 866 # the road. Please adjust your tests accordingly to catch this situation early
 867 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 868 #
 869 # The method will not be removed without an adequately complete replacement
 870 # for strict-mode enforcement
 871 sub _non_unique_find_fallback {
 872   my ($self, $cond, $attrs) = @_;
 873
 874   return $self->_qualify_cond_columns(
 875     $cond,
 876     exists $attrs->{alias}
 877       ? $attrs->{alias}
 878       : $self->{attrs}{alias}
 879   );
 880 }
 881
 882
 883 sub _qualify_cond_columns {
 884   my ($self, $cond, $alias) = @_;
 885
 886   my %aliased = %$cond;
 887   for (keys %aliased) {
 888     $aliased{"$alias.$_"} = delete $aliased{$_}
 889       if $_ !~ /\./;
 890   }
 891
 892   return \%aliased;
 893 }
 894
 895 sub _build_unique_cond {
 896   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 897
 898   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 899
 900   # combination may fail if $self->{cond} is non-trivial
 901   my ($final_cond) = try {
 902     $self->_merge_with_rscond ($extra_cond)
 903   } catch {
 904     +{ %$extra_cond }
 905   };
 906
 907   # trim out everything not in $columns
 908   $final_cond = { map {
 909     exists $final_cond->{$_}
 910       ? ( $_ => $final_cond->{$_} )
 911       : ()
 912   } @c_cols };
 913
 914   if (my @missing = grep
 915     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 916     (@c_cols)
 917   ) {
 918     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 919       $constraint_name,
 920       join (', ', map { "'$_'" } @missing),
 921     ) );
 922   }
 923
 924   if (
 925     !$croak_on_null
 926       and
 927     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 928       and
 929     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 930   ) {
 931     carp_unique ( sprintf (
 932       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 933     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 934     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 935       $constraint_name,
 936       join (', ', map { "'$_'" } @undefs),
 937     ));
 938   }
 939
 940   return $final_cond;
 941 }
 942
 943 =head2 search_related
 944
 945 =over 4
 946
 947 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 948
 949 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 950
 951 =back
 952
 953   $new_rs = $cd_rs->search_related('artist', {
 954     name => 'Emo-R-Us',
 955   });
 956
 957 Searches the specified relationship, optionally specifying a condition and
 958 attributes for matching records. See L</ATTRIBUTES> for more information.
 959
 960 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 961 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 962
 963 See also L</search_related_rs>.
 964
 965 =cut
 966
 967 sub search_related {
 968   return shift->related_resultset(shift)->search(@_);
 969 }
 970
 971 =head2 search_related_rs
 972
 973 This method works exactly the same as search_related, except that
 974 it guarantees a resultset, even in list context.
 975
 976 =cut
 977
 978 sub search_related_rs {
 979   return shift->related_resultset(shift)->search_rs(@_);
 980 }
 981
 982 =head2 cursor
 983
 984 =over 4
 985
 986 =item Arguments: none
 987
 988 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 989
 990 =back
 991
 992 Returns a storage-driven cursor to the given resultset. See
 993 L<DBIx::Class::Cursor> for more information.
 994
 995 =cut
 996
 997 sub cursor {
 998   my $self = shift;
 999
1000   return $self->{cursor} ||= do {
1001     my $attrs = { %{$self->_resolved_attrs } };
1002     $self->result_source->storage->select(
1003       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1004     );
1005   };
1006 }
1007
1008 =head2 single
1009
1010 =over 4
1011
1012 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1013
1014 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1015
1016 =back
1017
1018   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1019
1020 Inflates the first result without creating a cursor if the resultset has
1021 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1022 of L</search>.
1023
1024 While this method can take an optional search condition (just like L</search>)
1025 being a fast-code-path it does not recognize search attributes. If you need to
1026 add extra joins or similar, call L</search> and then chain-call L</single> on the
1027 L<DBIx::Class::ResultSet> returned.
1028
1029 =over
1030
1031 =item B<Note>
1032
1033 As of 0.08100, this method enforces the assumption that the preceding
1034 query returns only one row. If more than one row is returned, you will receive
1035 a warning:
1036
1037   Query returned more than one row
1038
1039 In this case, you should be using L</next> or L</find> instead, or if you really
1040 know what you are doing, use the L</rows> attribute to explicitly limit the size
1041 of the resultset.
1042
1043 This method will also throw an exception if it is called on a resultset prefetching
1044 has_many, as such a prefetch implies fetching multiple rows from the database in
1045 order to assemble the resulting object.
1046
1047 =back
1048
1049 =cut
1050
1051 sub single {
1052   my ($self, $where) = @_;
1053   if(@_ > 2) {
1054       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1055   }
1056
1057   my $attrs = { %{$self->_resolved_attrs} };
1058
1059   $self->throw_exception(
1060     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1061   ) if $attrs->{collapse};
1062
1063   if ($where) {
1064     if (defined $attrs->{where}) {
1065       $attrs->{where} = {
1066         '-and' =>
1067             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1068                $where, delete $attrs->{where} ]
1069       };
1070     } else {
1071       $attrs->{where} = $where;
1072     }
1073   }
1074
1075   my $data = [ $self->result_source->storage->select_single(
1076     $attrs->{from}, $attrs->{select},
1077     $attrs->{where}, $attrs
1078   )];
1079   return undef unless @$data;
1080   $self->{stashed_rows} = [ $data ];
1081   $self->_construct_objects->[0];
1082 }
1083
1084
1085 # _collapse_query
1086 #
1087 # Recursively collapse the query, accumulating values for each column.
1088
1089 sub _collapse_query {
1090   my ($self, $query, $collapsed) = @_;
1091
1092   $collapsed ||= {};
1093
1094   if (ref $query eq 'ARRAY') {
1095     foreach my $subquery (@$query) {
1096       next unless ref $subquery;  # -or
1097       $collapsed = $self->_collapse_query($subquery, $collapsed);
1098     }
1099   }
1100   elsif (ref $query eq 'HASH') {
1101     if (keys %$query and (keys %$query)[0] eq '-and') {
1102       foreach my $subquery (@{$query->{-and}}) {
1103         $collapsed = $self->_collapse_query($subquery, $collapsed);
1104       }
1105     }
1106     else {
1107       foreach my $col (keys %$query) {
1108         my $value = $query->{$col};
1109         $collapsed->{$col}{$value}++;
1110       }
1111     }
1112   }
1113
1114   return $collapsed;
1115 }
1116
1117 =head2 get_column
1118
1119 =over 4
1120
1121 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1122
1123 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1124
1125 =back
1126
1127   my $max_length = $rs->get_column('length')->max;
1128
1129 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1130
1131 =cut
1132
1133 sub get_column {
1134   my ($self, $column) = @_;
1135   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1136   return $new;
1137 }
1138
1139 =head2 search_like
1140
1141 =over 4
1142
1143 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1144
1145 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1146
1147 =back
1148
1149   # WHERE title LIKE '%blue%'
1150   $cd_rs = $rs->search_like({ title => '%blue%'});
1151
1152 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1153 that this is simply a convenience method retained for ex Class::DBI users.
1154 You most likely want to use L</search> with specific operators.
1155
1156 For more information, see L<DBIx::Class::Manual::Cookbook>.
1157
1158 This method is deprecated and will be removed in 0.09. Use L</search()>
1159 instead. An example conversion is:
1160
1161   ->search_like({ foo => 'bar' });
1162
1163   # Becomes
1164
1165   ->search({ foo => { like => 'bar' } });
1166
1167 =cut
1168
1169 sub search_like {
1170   my $class = shift;
1171   carp_unique (
1172     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1173    .' Instead use ->search({ x => { -like => "y%" } })'
1174    .' (note the outer pair of {}s - they are important!)'
1175   );
1176   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1177   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1178   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1179   return $class->search($query, { %$attrs });
1180 }
1181
1182 =head2 slice
1183
1184 =over 4
1185
1186 =item Arguments: $first, $last
1187
1188 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1189
1190 =back
1191
1192 Returns a resultset or object list representing a subset of elements from the
1193 resultset slice is called on. Indexes are from 0, i.e., to get the first
1194 three records, call:
1195
1196   my ($one, $two, $three) = $rs->slice(0, 2);
1197
1198 =cut
1199
1200 sub slice {
1201   my ($self, $min, $max) = @_;
1202   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1203   $attrs->{offset} = $self->{attrs}{offset} || 0;
1204   $attrs->{offset} += $min;
1205   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1206   return $self->search(undef, $attrs);
1207   #my $slice = (ref $self)->new($self->result_source, $attrs);
1208   #return (wantarray ? $slice->all : $slice);
1209 }
1210
1211 =head2 next
1212
1213 =over 4
1214
1215 =item Arguments: none
1216
1217 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1218
1219 =back
1220
1221 Returns the next element in the resultset (C<undef> is there is none).
1222
1223 Can be used to efficiently iterate over records in the resultset:
1224
1225   my $rs = $schema->resultset('CD')->search;
1226   while (my $cd = $rs->next) {
1227     print $cd->title;
1228   }
1229
1230 Note that you need to store the resultset object, and call C<next> on it.
1231 Calling C<< resultset('Table')->next >> repeatedly will always return the
1232 first record from the resultset.
1233
1234 =cut
1235
1236 sub next {
1237   my ($self) = @_;
1238
1239   if (my $cache = $self->get_cache) {
1240     $self->{all_cache_position} ||= 0;
1241     return $cache->[$self->{all_cache_position}++];
1242   }
1243
1244   if ($self->{attrs}{cache}) {
1245     delete $self->{pager};
1246     $self->{all_cache_position} = 1;
1247     return ($self->all)[0];
1248   }
1249
1250   return shift(@{$self->{stashed_objects}}) if @{ $self->{stashed_objects}||[] };
1251
1252   $self->{stashed_objects} = $self->_construct_objects
1253     or return undef;
1254
1255   return shift @{$self->{stashed_objects}};
1256 }
1257
1258 # Constructs as many objects as it can in one pass while respecting
1259 # cursor laziness. Several modes of operation:
1260 #
1261 # * Always builds everything present in @{$self->{stashed_rows}}
1262 # * If called with $fetch_all true - pulls everything off the cursor and
1263 #   builds all objects in one pass
1264 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1265 #   and if the resultset is ordered properly by the left side:
1266 #   * Fetches stuff off the cursor until the "master object" changes,
1267 #     and saves the last extra row (if any) in @{$self->{stashed_rows}}
1268 #   OR
1269 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1270 #     was requested (there is no other way to collapse except for an
1271 #     eager cursor)
1272 # * If no collapse is requested - just get the next row, construct and
1273 #   return
1274 sub _construct_objects {
1275   my ($self, $fetch_all) = @_;
1276
1277   my $rsrc = $self->result_source;
1278   my $attrs = $self->_resolved_attrs;
1279
1280   if (!$fetch_all and ! $attrs->{order_by} and $attrs->{collapse}) {
1281     # default order for collapsing unless the user asked for something
1282     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} $rsrc->primary_columns ];
1283     $attrs->{_ordered_for_collapse} = 1;
1284     $attrs->{_order_is_artificial} = 1;
1285   }
1286
1287   my $cursor = $self->cursor;
1288
1289   # this will be used as both initial raw-row collector AND as a RV of
1290   # _construct_objects. Not regrowing the array twice matters a lot...
1291   # a suprising amount actually
1292   my $rows = delete $self->{stashed_rows};
1293
1294   if ($fetch_all) {
1295     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1296     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1297   }
1298   elsif( $attrs->{collapse} ) {
1299
1300     $attrs->{_ordered_for_collapse} = (!$attrs->{order_by}) ? 0 : do {
1301       my $st = $rsrc->schema->storage;
1302       my @ord_cols = map
1303         { $_->[0] }
1304         ( $st->_extract_order_criteria($attrs->{order_by}) )
1305       ;
1306
1307       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1308
1309       for (0 .. $#ord_cols) {
1310         if (
1311           ! $colinfos->{$ord_cols[$_]}
1312             or
1313           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1314         ) {
1315           splice @ord_cols, $_;
1316           last;
1317         }
1318       }
1319
1320       # since all we check here are the start of the order_by belonging to the
1321       # top level $rsrc, a present identifying set will mean that the resultset
1322       # is ordered by its leftmost table in a tsable manner
1323       (@ord_cols and $rsrc->_identifying_column_set({ map
1324         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1325         @ord_cols
1326       })) ? 1 : 0;
1327     } unless defined $attrs->{_ordered_for_collapse};
1328
1329     if (! $attrs->{_ordered_for_collapse}) {
1330       $fetch_all = 1;
1331
1332       # instead of looping over ->next, use ->all in stealth mode
1333       # *without* calling a ->reset afterwards
1334       # FIXME - encapsulation breach, got to be a better way
1335       if (! $cursor->{_done}) {
1336         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1337         $cursor->{_done} = 1;
1338       }
1339     }
1340   }
1341
1342   if (! $fetch_all and ! @{$rows||[]} ) {
1343     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1344     if (scalar (my @r = $cursor->next) ) {
1345       $rows = [ \@r ];
1346     }
1347   }
1348
1349   return undef unless @{$rows||[]};
1350
1351   my @extra_collapser_args;
1352   if ($attrs->{collapse} and ! $fetch_all ) {
1353
1354     @extra_collapser_args = (
1355       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1356       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1357       ($self->{stashed_rows} = []),                 # where does it stuff excess
1358     );
1359   }
1360
1361   # hotspot - skip the setter
1362   my $res_class = $self->_result_class;
1363
1364   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1365     $res_class->can ('inflate_result')
1366       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1367   };
1368
1369   my $infmap = $attrs->{as};
1370
1371   $self->{_result_inflator}{is_hri} = do { ( $inflator_cref == (
1372     require DBIx::Class::ResultClass::HashRefInflator
1373       &&
1374     DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1375   ) ) ? 1 : 0
1376   } unless defined $self->{_result_inflator}{is_hri};
1377
1378   if ($attrs->{_single_resultclass_inflation}) {
1379     # construct a much simpler array->hash folder for the one-table cases right here
1380     if ($self->{_result_inflator}{is_hri}) {
1381       for my $r (@$rows) {
1382         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1383       }
1384     }
1385     # FIXME SUBOPTIMAL this is a very very very hot spot
1386     # while rather optimal we can *still* do much better, by
1387     # building a smarter Row::inflate_result(), and
1388     # switch to feeding it data via a much leaner interface
1389     #
1390     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1391     # this particular resultset size
1392     elsif (@$rows < 60) {
1393       for my $r (@$rows) {
1394         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1395       }
1396     }
1397     else {
1398       eval sprintf (
1399         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1400         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1401       );
1402     }
1403   }
1404   # Special-case multi-object HRI (we always prune)
1405   elsif ($self->{_result_inflator}{is_hri}) {
1406     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1407       eval => 1,
1408       inflate_map => $infmap,
1409       selection => $attrs->{select},
1410       collapse => $attrs->{collapse},
1411       premultiplied => $attrs->{_main_source_premultiplied},
1412       hri_style => 1,
1413     }) )->($rows, @extra_collapser_args);
1414   }
1415   # Regular multi-object
1416   else {
1417
1418     ( $self->{_row_parser}{classic} ||= $rsrc->_mk_row_parser({
1419       eval => 1,
1420       inflate_map => $infmap,
1421       selection => $attrs->{select},
1422       collapse => $attrs->{collapse},
1423       premultiplied => $attrs->{_main_source_premultiplied},
1424     }) )->($rows, @extra_collapser_args);
1425
1426     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1427   }
1428
1429   # CDBI compat stuff
1430   if ($attrs->{record_filter}) {
1431     $_ = $attrs->{record_filter}->($_) for @$rows;
1432   }
1433
1434   return $rows;
1435 }
1436
1437 =head2 result_source
1438
1439 =over 4
1440
1441 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1442
1443 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1444
1445 =back
1446
1447 An accessor for the primary ResultSource object from which this ResultSet
1448 is derived.
1449
1450 =head2 result_class
1451
1452 =over 4
1453
1454 =item Arguments: $result_class?
1455
1456 =item Return Value: $result_class
1457
1458 =back
1459
1460 An accessor for the class to use when creating result objects. Defaults to
1461 C<< result_source->result_class >> - which in most cases is the name of the
1462 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1463
1464 Note that changing the result_class will also remove any components
1465 that were originally loaded in the source class via
1466 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1467 in the original source class will not run.
1468
1469 =cut
1470
1471 sub result_class {
1472   my ($self, $result_class) = @_;
1473   if ($result_class) {
1474
1475     unless (ref $result_class) { # don't fire this for an object
1476       $self->ensure_class_loaded($result_class);
1477     }
1478     $self->_result_class($result_class);
1479     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1480     # permit the user to set result class on one result set only; it only
1481     # chains if provided to search()
1482     #$self->{attrs}{result_class} = $result_class if ref $self;
1483
1484     delete $self->{_result_inflator};
1485   }
1486   $self->_result_class;
1487 }
1488
1489 =head2 count
1490
1491 =over 4
1492
1493 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1494
1495 =item Return Value: $count
1496
1497 =back
1498
1499 Performs an SQL C<COUNT> with the same query as the resultset was built
1500 with to find the number of elements. Passing arguments is equivalent to
1501 C<< $rs->search ($cond, \%attrs)->count >>
1502
1503 =cut
1504
1505 sub count {
1506   my $self = shift;
1507   return $self->search(@_)->count if @_ and defined $_[0];
1508   return scalar @{ $self->get_cache } if $self->get_cache;
1509
1510   my $attrs = { %{ $self->_resolved_attrs } };
1511
1512   # this is a little optimization - it is faster to do the limit
1513   # adjustments in software, instead of a subquery
1514   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1515
1516   my $crs;
1517   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1518     $crs = $self->_count_subq_rs ($attrs);
1519   }
1520   else {
1521     $crs = $self->_count_rs ($attrs);
1522   }
1523   my $count = $crs->next;
1524
1525   $count -= $offset if $offset;
1526   $count = $rows if $rows and $rows < $count;
1527   $count = 0 if ($count < 0);
1528
1529   return $count;
1530 }
1531
1532 =head2 count_rs
1533
1534 =over 4
1535
1536 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1537
1538 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1539
1540 =back
1541
1542 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1543 This can be very handy for subqueries:
1544
1545   ->search( { amount => $some_rs->count_rs->as_query } )
1546
1547 As with regular resultsets the SQL query will be executed only after
1548 the resultset is accessed via L</next> or L</all>. That would return
1549 the same single value obtainable via L</count>.
1550
1551 =cut
1552
1553 sub count_rs {
1554   my $self = shift;
1555   return $self->search(@_)->count_rs if @_;
1556
1557   # this may look like a lack of abstraction (count() does about the same)
1558   # but in fact an _rs *must* use a subquery for the limits, as the
1559   # software based limiting can not be ported if this $rs is to be used
1560   # in a subquery itself (i.e. ->as_query)
1561   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1562     return $self->_count_subq_rs;
1563   }
1564   else {
1565     return $self->_count_rs;
1566   }
1567 }
1568
1569 #
1570 # returns a ResultSetColumn object tied to the count query
1571 #
1572 sub _count_rs {
1573   my ($self, $attrs) = @_;
1574
1575   my $rsrc = $self->result_source;
1576   $attrs ||= $self->_resolved_attrs;
1577
1578   my $tmp_attrs = { %$attrs };
1579   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1580   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1581
1582   # overwrite the selector (supplied by the storage)
1583   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1584   $tmp_attrs->{as} = 'count';
1585
1586   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1587
1588   return $tmp_rs;
1589 }
1590
1591 #
1592 # same as above but uses a subquery
1593 #
1594 sub _count_subq_rs {
1595   my ($self, $attrs) = @_;
1596
1597   my $rsrc = $self->result_source;
1598   $attrs ||= $self->_resolved_attrs;
1599
1600   my $sub_attrs = { %$attrs };
1601   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1602   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1603
1604   # if we multi-prefetch we group_by something unique, as this is what we would
1605   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1606   if ( $attrs->{collapse}  ) {
1607     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1608       $rsrc->_identifying_column_set || $self->throw_exception(
1609         'Unable to construct a unique group_by criteria properly collapsing the '
1610       . 'has_many prefetch before count()'
1611       );
1612     } ]
1613   }
1614
1615   # Calculate subquery selector
1616   if (my $g = $sub_attrs->{group_by}) {
1617
1618     my $sql_maker = $rsrc->storage->sql_maker;
1619
1620     # necessary as the group_by may refer to aliased functions
1621     my $sel_index;
1622     for my $sel (@{$attrs->{select}}) {
1623       $sel_index->{$sel->{-as}} = $sel
1624         if (ref $sel eq 'HASH' and $sel->{-as});
1625     }
1626
1627     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1628     # also look for named aggregates referred in the having clause
1629     # having often contains scalarrefs - thus parse it out entirely
1630     my @parts = @$g;
1631     if ($attrs->{having}) {
1632       local $sql_maker->{having_bind};
1633       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1634       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1635       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1636         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1637         # if we don't unset it we screw up retarded but unfortunately working
1638         # 'MAX(foo.bar)' => { '>', 3 }
1639         $sql_maker->{name_sep} = '';
1640       }
1641
1642       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1643
1644       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1645       my %seen_having;
1646
1647       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1648       # and if all fails for an utterly naive quoted scalar-with-function
1649       while ($having_sql =~ /
1650         $rquote $sep $lquote (.+?) $rquote
1651           |
1652         [\s,] \w+ \. (\w+) [\s,]
1653           |
1654         [\s,] $lquote (.+?) $rquote [\s,]
1655       /gx) {
1656         my $part = $1 || $2 || $3;  # one of them matched if we got here
1657         unless ($seen_having{$part}++) {
1658           push @parts, $part;
1659         }
1660       }
1661     }
1662
1663     for (@parts) {
1664       my $colpiece = $sel_index->{$_} || $_;
1665
1666       # unqualify join-based group_by's. Arcane but possible query
1667       # also horrible horrible hack to alias a column (not a func.)
1668       # (probably need to introduce SQLA syntax)
1669       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1670         my $as = $colpiece;
1671         $as =~ s/\./__/;
1672         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1673       }
1674       push @{$sub_attrs->{select}}, $colpiece;
1675     }
1676   }
1677   else {
1678     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1679     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1680   }
1681
1682   return $rsrc->resultset_class
1683                ->new ($rsrc, $sub_attrs)
1684                 ->as_subselect_rs
1685                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1686                   ->get_column ('count');
1687 }
1688
1689
1690 =head2 count_literal
1691
1692 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1693 should only be used in that context. See L</search_literal> for further info.
1694
1695 =over 4
1696
1697 =item Arguments: $sql_fragment, @standalone_bind_values
1698
1699 =item Return Value: $count
1700
1701 =back
1702
1703 Counts the results in a literal query. Equivalent to calling L</search_literal>
1704 with the passed arguments, then L</count>.
1705
1706 =cut
1707
1708 sub count_literal { shift->search_literal(@_)->count; }
1709
1710 =head2 all
1711
1712 =over 4
1713
1714 =item Arguments: none
1715
1716 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1717
1718 =back
1719
1720 Returns all elements in the resultset.
1721
1722 =cut
1723
1724 sub all {
1725   my $self = shift;
1726   if(@_) {
1727     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1728   }
1729
1730   delete @{$self}{qw/stashed_rows stashed_objects/};
1731
1732   if (my $c = $self->get_cache) {
1733     return @$c;
1734   }
1735
1736   $self->cursor->reset;
1737
1738   my $objs = $self->_construct_objects('fetch_all') || [];
1739
1740   $self->set_cache($objs) if $self->{attrs}{cache};
1741
1742   return @$objs;
1743 }
1744
1745 =head2 reset
1746
1747 =over 4
1748
1749 =item Arguments: none
1750
1751 =item Return Value: $self
1752
1753 =back
1754
1755 Resets the resultset's cursor, so you can iterate through the elements again.
1756 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1757 another query.
1758
1759 =cut
1760
1761 sub reset {
1762   my ($self) = @_;
1763
1764   delete @{$self}{qw/stashed_rows stashed_objects/};
1765   $self->{all_cache_position} = 0;
1766   $self->cursor->reset;
1767   return $self;
1768 }
1769
1770 =head2 first
1771
1772 =over 4
1773
1774 =item Arguments: none
1775
1776 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1777
1778 =back
1779
1780 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1781 an object for the first result (or C<undef> if the resultset is empty).
1782
1783 =cut
1784
1785 sub first {
1786   return $_[0]->reset->next;
1787 }
1788
1789
1790 # _rs_update_delete
1791 #
1792 # Determines whether and what type of subquery is required for the $rs operation.
1793 # If grouping is necessary either supplies its own, or verifies the current one
1794 # After all is done delegates to the proper storage method.
1795
1796 sub _rs_update_delete {
1797   my ($self, $op, $values) = @_;
1798
1799   my $rsrc = $self->result_source;
1800   my $storage = $rsrc->schema->storage;
1801
1802   my $attrs = { %{$self->_resolved_attrs} };
1803
1804   my $join_classifications;
1805   my $existing_group_by = delete $attrs->{group_by};
1806
1807   # do we need a subquery for any reason?
1808   my $needs_subq = (
1809     defined $existing_group_by
1810       or
1811     # if {from} is unparseable wrap a subq
1812     ref($attrs->{from}) ne 'ARRAY'
1813       or
1814     # limits call for a subq
1815     $self->_has_resolved_attr(qw/rows offset/)
1816   );
1817
1818   # simplify the joinmap, so we can further decide if a subq is necessary
1819   if (!$needs_subq and @{$attrs->{from}} > 1) {
1820     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1821
1822     # check if there are any joins left after the prune
1823     if ( @{$attrs->{from}} > 1 ) {
1824       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1825         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1826         $attrs->{select},
1827         $self->{cond},
1828         $attrs
1829       );
1830
1831       # any non-pruneable joins imply subq
1832       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1833     }
1834   }
1835
1836   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1837   $needs_subq ||= (
1838     (ref $attrs->{from}[0]) ne 'HASH'
1839       or
1840     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1841   );
1842
1843   my ($cond, $guard);
1844   # do we need anything like a subquery?
1845   if (! $needs_subq) {
1846     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1847     # a condition containing 'me' or other table prefixes will not work
1848     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1849     $cond = do {
1850       my $sqla = $rsrc->storage->sql_maker;
1851       local $sqla->{_dequalify_idents} = 1;
1852       \[ $sqla->_recurse_where($self->{cond}) ];
1853     };
1854   }
1855   else {
1856     # we got this far - means it is time to wrap a subquery
1857     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1858       sprintf(
1859         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1860         $op,
1861         $rsrc->source_name,
1862       )
1863     );
1864
1865     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1866     delete $attrs->{$_} for qw/collapse select _prefetch_selector_range as/;
1867     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1868     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1869     my $subrs = (ref $self)->new($rsrc, $attrs);
1870
1871     if (@$idcols == 1) {
1872       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1873     }
1874     elsif ($storage->_use_multicolumn_in) {
1875       # no syntax for calling this properly yet
1876       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1877       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1878         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1879         $subrs->as_query
1880       ),
1881     }
1882     else {
1883       # if all else fails - get all primary keys and operate over a ORed set
1884       # wrap in a transaction for consistency
1885       # this is where the group_by/multiplication starts to matter
1886       if (
1887         $existing_group_by
1888           or
1889         keys %{ $join_classifications->{multiplying} || {} }
1890       ) {
1891         # make sure if there is a supplied group_by it matches the columns compiled above
1892         # perfectly. Anything else can not be sanely executed on most databases so croak
1893         # right then and there
1894         if ($existing_group_by) {
1895           my @current_group_by = map
1896             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1897             @$existing_group_by
1898           ;
1899
1900           if (
1901             join ("\x00", sort @current_group_by)
1902               ne
1903             join ("\x00", sort @{$attrs->{columns}} )
1904           ) {
1905             $self->throw_exception (
1906               "You have just attempted a $op operation on a resultset which does group_by"
1907               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1908               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1909               . ' kind of queries. Please retry the operation with a modified group_by or'
1910               . ' without using one at all.'
1911             );
1912           }
1913         }
1914
1915         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1916       }
1917
1918       $guard = $storage->txn_scope_guard;
1919
1920       $cond = [];
1921       for my $row ($subrs->cursor->all) {
1922         push @$cond, { map
1923           { $idcols->[$_] => $row->[$_] }
1924           (0 .. $#$idcols)
1925         };
1926       }
1927     }
1928   }
1929
1930   my $res = $storage->$op (
1931     $rsrc,
1932     $op eq 'update' ? $values : (),
1933     $cond,
1934   );
1935
1936   $guard->commit if $guard;
1937
1938   return $res;
1939 }
1940
1941 =head2 update
1942
1943 =over 4
1944
1945 =item Arguments: \%values
1946
1947 =item Return Value: $underlying_storage_rv
1948
1949 =back
1950
1951 Sets the specified columns in the resultset to the supplied values in a
1952 single query. Note that this will not run any accessor/set_column/update
1953 triggers, nor will it update any result object instances derived from this
1954 resultset (this includes the contents of the L<resultset cache|/set_cache>
1955 if any). See L</update_all> if you need to execute any on-update
1956 triggers or cascades defined either by you or a
1957 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1958
1959 The return value is a pass through of what the underlying
1960 storage backend returned, and may vary. See L<DBI/execute> for the most
1961 common case.
1962
1963 =head3 CAVEAT
1964
1965 Note that L</update> does not process/deflate any of the values passed in.
1966 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1967 ensure manually that any value passed to this method will stringify to
1968 something the RDBMS knows how to deal with. A notable example is the
1969 handling of L<DateTime> objects, for more info see:
1970 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1971
1972 =cut
1973
1974 sub update {
1975   my ($self, $values) = @_;
1976   $self->throw_exception('Values for update must be a hash')
1977     unless ref $values eq 'HASH';
1978
1979   return $self->_rs_update_delete ('update', $values);
1980 }
1981
1982 =head2 update_all
1983
1984 =over 4
1985
1986 =item Arguments: \%values
1987
1988 =item Return Value: 1
1989
1990 =back
1991
1992 Fetches all objects and updates them one at a time via
1993 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1994 triggers, while L</update> will not.
1995
1996 =cut
1997
1998 sub update_all {
1999   my ($self, $values) = @_;
2000   $self->throw_exception('Values for update_all must be a hash')
2001     unless ref $values eq 'HASH';
2002
2003   my $guard = $self->result_source->schema->txn_scope_guard;
2004   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2005   $guard->commit;
2006   return 1;
2007 }
2008
2009 =head2 delete
2010
2011 =over 4
2012
2013 =item Arguments: none
2014
2015 =item Return Value: $underlying_storage_rv
2016
2017 =back
2018
2019 Deletes the rows matching this resultset in a single query. Note that this
2020 will not run any delete triggers, nor will it alter the
2021 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2022 derived from this resultset (this includes the contents of the
2023 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2024 execute any on-delete triggers or cascades defined either by you or a
2025 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2026
2027 The return value is a pass through of what the underlying storage backend
2028 returned, and may vary. See L<DBI/execute> for the most common case.
2029
2030 =cut
2031
2032 sub delete {
2033   my $self = shift;
2034   $self->throw_exception('delete does not accept any arguments')
2035     if @_;
2036
2037   return $self->_rs_update_delete ('delete');
2038 }
2039
2040 =head2 delete_all
2041
2042 =over 4
2043
2044 =item Arguments: none
2045
2046 =item Return Value: 1
2047
2048 =back
2049
2050 Fetches all objects and deletes them one at a time via
2051 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2052 triggers, while L</delete> will not.
2053
2054 =cut
2055
2056 sub delete_all {
2057   my $self = shift;
2058   $self->throw_exception('delete_all does not accept any arguments')
2059     if @_;
2060
2061   my $guard = $self->result_source->schema->txn_scope_guard;
2062   $_->delete for $self->all;
2063   $guard->commit;
2064   return 1;
2065 }
2066
2067 =head2 populate
2068
2069 =over 4
2070
2071 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2072
2073 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2074
2075 =back
2076
2077 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2078 arrayrefs.
2079
2080 =over
2081
2082 =item NOTE
2083
2084 The context of this method call has an important effect on what is
2085 submitted to storage. In void context data is fed directly to fastpath
2086 insertion routines provided by the underlying storage (most often
2087 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2088 L<insert|DBIx::Class::Row/insert> calls on the
2089 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2090 augmentation of these methods provided by components. For example if you
2091 are using something like L<DBIx::Class::UUIDColumns> to create primary
2092 keys for you, you will find that your PKs are empty.  In this case you
2093 will have to explicitly force scalar or list context in order to create
2094 those values.
2095
2096 =back
2097
2098 In non-void (scalar or list) context, this method is simply a wrapper
2099 for L</create>. Depending on list or scalar context either a list of
2100 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2101 containing these objects is returned.
2102
2103 When supplying data in "arrayref of arrayrefs" invocation style, the
2104 first element should be a list of column names and each subsequent
2105 element should be a data value in the earlier specified column order.
2106 For example:
2107
2108   $Arstist_rs->populate([
2109     [ qw( artistid name ) ],
2110     [ 100, 'A Formally Unknown Singer' ],
2111     [ 101, 'A singer that jumped the shark two albums ago' ],
2112     [ 102, 'An actually cool singer' ],
2113   ]);
2114
2115 For the arrayref of hashrefs style each hashref should be a structure
2116 suitable for passing to L</create>. Multi-create is also permitted with
2117 this syntax.
2118
2119   $schema->resultset("Artist")->populate([
2120      { artistid => 4, name => 'Manufactured Crap', cds => [
2121         { title => 'My First CD', year => 2006 },
2122         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2123       ],
2124      },
2125      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2126         { title => 'My parents sold me to a record company', year => 2005 },
2127         { title => 'Why Am I So Ugly?', year => 2006 },
2128         { title => 'I Got Surgery and am now Popular', year => 2007 }
2129       ],
2130      },
2131   ]);
2132
2133 If you attempt a void-context multi-create as in the example above (each
2134 Artist also has the related list of CDs), and B<do not> supply the
2135 necessary autoinc foreign key information, this method will proxy to the
2136 less efficient L</create>, and then throw the Result objects away. In this
2137 case there are obviously no benefits to using this method over L</create>.
2138
2139 =cut
2140
2141 sub populate {
2142   my $self = shift;
2143
2144   # cruft placed in standalone method
2145   my $data = $self->_normalize_populate_args(@_);
2146
2147   return unless @$data;
2148
2149   if(defined wantarray) {
2150     my @created = map { $self->create($_) } @$data;
2151     return wantarray ? @created : \@created;
2152   }
2153   else {
2154     my $first = $data->[0];
2155
2156     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2157     # it relationship data
2158     my (@rels, @columns);
2159     my $rsrc = $self->result_source;
2160     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2161     for (keys %$first) {
2162       my $ref = ref $first->{$_};
2163       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2164         ? push @rels, $_
2165         : push @columns, $_
2166       ;
2167     }
2168
2169     my @pks = $rsrc->primary_columns;
2170
2171     ## do the belongs_to relationships
2172     foreach my $index (0..$#$data) {
2173
2174       # delegate to create() for any dataset without primary keys with specified relationships
2175       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2176         for my $r (@rels) {
2177           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2178             my @ret = $self->populate($data);
2179             return;
2180           }
2181         }
2182       }
2183
2184       foreach my $rel (@rels) {
2185         next unless ref $data->[$index]->{$rel} eq "HASH";
2186         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2187         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2188         my $related = $result->result_source->_resolve_condition(
2189           $reverse_relinfo->{cond},
2190           $self,
2191           $result,
2192           $rel,
2193         );
2194
2195         delete $data->[$index]->{$rel};
2196         $data->[$index] = {%{$data->[$index]}, %$related};
2197
2198         push @columns, keys %$related if $index == 0;
2199       }
2200     }
2201
2202     ## inherit the data locked in the conditions of the resultset
2203     my ($rs_data) = $self->_merge_with_rscond({});
2204     delete @{$rs_data}{@columns};
2205
2206     ## do bulk insert on current row
2207     $rsrc->storage->insert_bulk(
2208       $rsrc,
2209       [@columns, keys %$rs_data],
2210       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2211     );
2212
2213     ## do the has_many relationships
2214     foreach my $item (@$data) {
2215
2216       my $main_row;
2217
2218       foreach my $rel (@rels) {
2219         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2220
2221         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2222
2223         my $child = $main_row->$rel;
2224
2225         my $related = $child->result_source->_resolve_condition(
2226           $rels->{$rel}{cond},
2227           $child,
2228           $main_row,
2229           $rel,
2230         );
2231
2232         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2233         my @populate = map { {%$_, %$related} } @rows_to_add;
2234
2235         $child->populate( \@populate );
2236       }
2237     }
2238   }
2239 }
2240
2241
2242 # populate() argumnets went over several incarnations
2243 # What we ultimately support is AoH
2244 sub _normalize_populate_args {
2245   my ($self, $arg) = @_;
2246
2247   if (ref $arg eq 'ARRAY') {
2248     if (!@$arg) {
2249       return [];
2250     }
2251     elsif (ref $arg->[0] eq 'HASH') {
2252       return $arg;
2253     }
2254     elsif (ref $arg->[0] eq 'ARRAY') {
2255       my @ret;
2256       my @colnames = @{$arg->[0]};
2257       foreach my $values (@{$arg}[1 .. $#$arg]) {
2258         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2259       }
2260       return \@ret;
2261     }
2262   }
2263
2264   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2265 }
2266
2267 =head2 pager
2268
2269 =over 4
2270
2271 =item Arguments: none
2272
2273 =item Return Value: L<$pager|Data::Page>
2274
2275 =back
2276
2277 Returns a L<Data::Page> object for the current resultset. Only makes
2278 sense for queries with a C<page> attribute.
2279
2280 To get the full count of entries for a paged resultset, call
2281 C<total_entries> on the L<Data::Page> object.
2282
2283 =cut
2284
2285 sub pager {
2286   my ($self) = @_;
2287
2288   return $self->{pager} if $self->{pager};
2289
2290   my $attrs = $self->{attrs};
2291   if (!defined $attrs->{page}) {
2292     $self->throw_exception("Can't create pager for non-paged rs");
2293   }
2294   elsif ($attrs->{page} <= 0) {
2295     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2296   }
2297   $attrs->{rows} ||= 10;
2298
2299   # throw away the paging flags and re-run the count (possibly
2300   # with a subselect) to get the real total count
2301   my $count_attrs = { %$attrs };
2302   delete @{$count_attrs}{qw/rows offset page pager/};
2303
2304   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2305
2306   require DBIx::Class::ResultSet::Pager;
2307   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2308     sub { $total_rs->count },  #lazy-get the total
2309     $attrs->{rows},
2310     $self->{attrs}{page},
2311   );
2312 }
2313
2314 =head2 page
2315
2316 =over 4
2317
2318 =item Arguments: $page_number
2319
2320 =item Return Value: L<$resultset|/search>
2321
2322 =back
2323
2324 Returns a resultset for the $page_number page of the resultset on which page
2325 is called, where each page contains a number of rows equal to the 'rows'
2326 attribute set on the resultset (10 by default).
2327
2328 =cut
2329
2330 sub page {
2331   my ($self, $page) = @_;
2332   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2333 }
2334
2335 =head2 new_result
2336
2337 =over 4
2338
2339 =item Arguments: \%col_data
2340
2341 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2342
2343 =back
2344
2345 Creates a new result object in the resultset's result class and returns
2346 it. The row is not inserted into the database at this point, call
2347 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2348 will tell you whether the result object has been inserted or not.
2349
2350 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2351
2352 =cut
2353
2354 sub new_result {
2355   my ($self, $values) = @_;
2356
2357   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2358     if @_ > 2;
2359
2360   $self->throw_exception( "new_result expects a hashref" )
2361     unless (ref $values eq 'HASH');
2362
2363   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2364
2365   my $new = $self->result_class->new({
2366     %$merged_cond,
2367     ( @$cols_from_relations
2368       ? (-cols_from_relations => $cols_from_relations)
2369       : ()
2370     ),
2371     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2372   });
2373
2374   if (
2375     reftype($new) eq 'HASH'
2376       and
2377     ! keys %$new
2378       and
2379     blessed($new)
2380   ) {
2381     carp_unique (sprintf (
2382       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2383       $self->result_class,
2384     ));
2385   }
2386
2387   $new;
2388 }
2389
2390 # _merge_with_rscond
2391 #
2392 # Takes a simple hash of K/V data and returns its copy merged with the
2393 # condition already present on the resultset. Additionally returns an
2394 # arrayref of value/condition names, which were inferred from related
2395 # objects (this is needed for in-memory related objects)
2396 sub _merge_with_rscond {
2397   my ($self, $data) = @_;
2398
2399   my (%new_data, @cols_from_relations);
2400
2401   my $alias = $self->{attrs}{alias};
2402
2403   if (! defined $self->{cond}) {
2404     # just massage $data below
2405   }
2406   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2407     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2408     @cols_from_relations = keys %new_data;
2409   }
2410   elsif (ref $self->{cond} ne 'HASH') {
2411     $self->throw_exception(
2412       "Can't abstract implicit construct, resultset condition not a hash"
2413     );
2414   }
2415   else {
2416     # precendence must be given to passed values over values inherited from
2417     # the cond, so the order here is important.
2418     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2419     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2420
2421     while ( my($col, $value) = each %implied ) {
2422       my $vref = ref $value;
2423       if (
2424         $vref eq 'HASH'
2425           and
2426         keys(%$value) == 1
2427           and
2428         (keys %$value)[0] eq '='
2429       ) {
2430         $new_data{$col} = $value->{'='};
2431       }
2432       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2433         $new_data{$col} = $value;
2434       }
2435     }
2436   }
2437
2438   %new_data = (
2439     %new_data,
2440     %{ $self->_remove_alias($data, $alias) },
2441   );
2442
2443   return (\%new_data, \@cols_from_relations);
2444 }
2445
2446 # _has_resolved_attr
2447 #
2448 # determines if the resultset defines at least one
2449 # of the attributes supplied
2450 #
2451 # used to determine if a subquery is neccessary
2452 #
2453 # supports some virtual attributes:
2454 #   -join
2455 #     This will scan for any joins being present on the resultset.
2456 #     It is not a mere key-search but a deep inspection of {from}
2457 #
2458
2459 sub _has_resolved_attr {
2460   my ($self, @attr_names) = @_;
2461
2462   my $attrs = $self->_resolved_attrs;
2463
2464   my %extra_checks;
2465
2466   for my $n (@attr_names) {
2467     if (grep { $n eq $_ } (qw/-join/) ) {
2468       $extra_checks{$n}++;
2469       next;
2470     }
2471
2472     my $attr =  $attrs->{$n};
2473
2474     next if not defined $attr;
2475
2476     if (ref $attr eq 'HASH') {
2477       return 1 if keys %$attr;
2478     }
2479     elsif (ref $attr eq 'ARRAY') {
2480       return 1 if @$attr;
2481     }
2482     else {
2483       return 1 if $attr;
2484     }
2485   }
2486
2487   # a resolved join is expressed as a multi-level from
2488   return 1 if (
2489     $extra_checks{-join}
2490       and
2491     ref $attrs->{from} eq 'ARRAY'
2492       and
2493     @{$attrs->{from}} > 1
2494   );
2495
2496   return 0;
2497 }
2498
2499 # _collapse_cond
2500 #
2501 # Recursively collapse the condition.
2502
2503 sub _collapse_cond {
2504   my ($self, $cond, $collapsed) = @_;
2505
2506   $collapsed ||= {};
2507
2508   if (ref $cond eq 'ARRAY') {
2509     foreach my $subcond (@$cond) {
2510       next unless ref $subcond;  # -or
2511       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2512     }
2513   }
2514   elsif (ref $cond eq 'HASH') {
2515     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2516       foreach my $subcond (@{$cond->{-and}}) {
2517         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2518       }
2519     }
2520     else {
2521       foreach my $col (keys %$cond) {
2522         my $value = $cond->{$col};
2523         $collapsed->{$col} = $value;
2524       }
2525     }
2526   }
2527
2528   return $collapsed;
2529 }
2530
2531 # _remove_alias
2532 #
2533 # Remove the specified alias from the specified query hash. A copy is made so
2534 # the original query is not modified.
2535
2536 sub _remove_alias {
2537   my ($self, $query, $alias) = @_;
2538
2539   my %orig = %{ $query || {} };
2540   my %unaliased;
2541
2542   foreach my $key (keys %orig) {
2543     if ($key !~ /\./) {
2544       $unaliased{$key} = $orig{$key};
2545       next;
2546     }
2547     $unaliased{$1} = $orig{$key}
2548       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2549   }
2550
2551   return \%unaliased;
2552 }
2553
2554 =head2 as_query
2555
2556 =over 4
2557
2558 =item Arguments: none
2559
2560 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2561
2562 =back
2563
2564 Returns the SQL query and bind vars associated with the invocant.
2565
2566 This is generally used as the RHS for a subquery.
2567
2568 =cut
2569
2570 sub as_query {
2571   my $self = shift;
2572
2573   my $attrs = { %{ $self->_resolved_attrs } };
2574
2575   # For future use:
2576   #
2577   # in list ctx:
2578   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2579   # $sql also has no wrapping parenthesis in list ctx
2580   #
2581   my $sqlbind = $self->result_source->storage
2582     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2583
2584   return $sqlbind;
2585 }
2586
2587 =head2 find_or_new
2588
2589 =over 4
2590
2591 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2592
2593 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2594
2595 =back
2596
2597   my $artist = $schema->resultset('Artist')->find_or_new(
2598     { artist => 'fred' }, { key => 'artists' });
2599
2600   $cd->cd_to_producer->find_or_new({ producer => $producer },
2601                                    { key => 'primary });
2602
2603 Find an existing record from this resultset using L</find>. if none exists,
2604 instantiate a new result object and return it. The object will not be saved
2605 into your storage until you call L<DBIx::Class::Row/insert> on it.
2606
2607 You most likely want this method when looking for existing rows using a unique
2608 constraint that is not the primary key, or looking for related rows.
2609
2610 If you want objects to be saved immediately, use L</find_or_create> instead.
2611
2612 B<Note>: Make sure to read the documentation of L</find> and understand the
2613 significance of the C<key> attribute, as its lack may skew your search, and
2614 subsequently result in spurious new objects.
2615
2616 B<Note>: Take care when using C<find_or_new> with a table having
2617 columns with default values that you intend to be automatically
2618 supplied by the database (e.g. an auto_increment primary key column).
2619 In normal usage, the value of such columns should NOT be included at
2620 all in the call to C<find_or_new>, even when set to C<undef>.
2621
2622 =cut
2623
2624 sub find_or_new {
2625   my $self     = shift;
2626   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2627   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2628   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2629     return $row;
2630   }
2631   return $self->new_result($hash);
2632 }
2633
2634 =head2 create
2635
2636 =over 4
2637
2638 =item Arguments: \%col_data
2639
2640 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2641
2642 =back
2643
2644 Attempt to create a single new row or a row with multiple related rows
2645 in the table represented by the resultset (and related tables). This
2646 will not check for duplicate rows before inserting, use
2647 L</find_or_create> to do that.
2648
2649 To create one row for this resultset, pass a hashref of key/value
2650 pairs representing the columns of the table and the values you wish to
2651 store. If the appropriate relationships are set up, foreign key fields
2652 can also be passed an object representing the foreign row, and the
2653 value will be set to its primary key.
2654
2655 To create related objects, pass a hashref of related-object column values
2656 B<keyed on the relationship name>. If the relationship is of type C<multi>
2657 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2658 The process will correctly identify columns holding foreign keys, and will
2659 transparently populate them from the keys of the corresponding relation.
2660 This can be applied recursively, and will work correctly for a structure
2661 with an arbitrary depth and width, as long as the relationships actually
2662 exists and the correct column data has been supplied.
2663
2664 Instead of hashrefs of plain related data (key/value pairs), you may
2665 also pass new or inserted objects. New objects (not inserted yet, see
2666 L</new_result>), will be inserted into their appropriate tables.
2667
2668 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2669
2670 Example of creating a new row.
2671
2672   $person_rs->create({
2673     name=>"Some Person",
2674     email=>"somebody@someplace.com"
2675   });
2676
2677 Example of creating a new row and also creating rows in a related C<has_many>
2678 or C<has_one> resultset.  Note Arrayref.
2679
2680   $artist_rs->create(
2681      { artistid => 4, name => 'Manufactured Crap', cds => [
2682         { title => 'My First CD', year => 2006 },
2683         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2684       ],
2685      },
2686   );
2687
2688 Example of creating a new row and also creating a row in a related
2689 C<belongs_to> resultset. Note Hashref.
2690
2691   $cd_rs->create({
2692     title=>"Music for Silly Walks",
2693     year=>2000,
2694     artist => {
2695       name=>"Silly Musician",
2696     }
2697   });
2698
2699 =over
2700
2701 =item WARNING
2702
2703 When subclassing ResultSet never attempt to override this method. Since
2704 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2705 lot of the internals simply never call it, so your override will be
2706 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2707 or L<DBIx::Class::Row/insert> depending on how early in the
2708 L</create> process you need to intervene. See also warning pertaining to
2709 L</new>.
2710
2711 =back
2712
2713 =cut
2714
2715 sub create {
2716   my ($self, $attrs) = @_;
2717   $self->throw_exception( "create needs a hashref" )
2718     unless ref $attrs eq 'HASH';
2719   return $self->new_result($attrs)->insert;
2720 }
2721
2722 =head2 find_or_create
2723
2724 =over 4
2725
2726 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2727
2728 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2729
2730 =back
2731
2732   $cd->cd_to_producer->find_or_create({ producer => $producer },
2733                                       { key => 'primary' });
2734
2735 Tries to find a record based on its primary key or unique constraints; if none
2736 is found, creates one and returns that instead.
2737
2738   my $cd = $schema->resultset('CD')->find_or_create({
2739     cdid   => 5,
2740     artist => 'Massive Attack',
2741     title  => 'Mezzanine',
2742     year   => 2005,
2743   });
2744
2745 Also takes an optional C<key> attribute, to search by a specific key or unique
2746 constraint. For example:
2747
2748   my $cd = $schema->resultset('CD')->find_or_create(
2749     {
2750       artist => 'Massive Attack',
2751       title  => 'Mezzanine',
2752     },
2753     { key => 'cd_artist_title' }
2754   );
2755
2756 B<Note>: Make sure to read the documentation of L</find> and understand the
2757 significance of the C<key> attribute, as its lack may skew your search, and
2758 subsequently result in spurious row creation.
2759
2760 B<Note>: Because find_or_create() reads from the database and then
2761 possibly inserts based on the result, this method is subject to a race
2762 condition. Another process could create a record in the table after
2763 the find has completed and before the create has started. To avoid
2764 this problem, use find_or_create() inside a transaction.
2765
2766 B<Note>: Take care when using C<find_or_create> with a table having
2767 columns with default values that you intend to be automatically
2768 supplied by the database (e.g. an auto_increment primary key column).
2769 In normal usage, the value of such columns should NOT be included at
2770 all in the call to C<find_or_create>, even when set to C<undef>.
2771
2772 See also L</find> and L</update_or_create>. For information on how to declare
2773 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2774
2775 If you need to know if an existing row was found or a new one created use
2776 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2777 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2778 database!
2779
2780   my $cd = $schema->resultset('CD')->find_or_new({
2781     cdid   => 5,
2782     artist => 'Massive Attack',
2783     title  => 'Mezzanine',
2784     year   => 2005,
2785   });
2786
2787   if( !$cd->in_storage ) {
2788       # do some stuff
2789       $cd->insert;
2790   }
2791
2792 =cut
2793
2794 sub find_or_create {
2795   my $self     = shift;
2796   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2797   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2798   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2799     return $row;
2800   }
2801   return $self->create($hash);
2802 }
2803
2804 =head2 update_or_create
2805
2806 =over 4
2807
2808 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2809
2810 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2811
2812 =back
2813
2814   $resultset->update_or_create({ col => $val, ... });
2815
2816 Like L</find_or_create>, but if a row is found it is immediately updated via
2817 C<< $found_row->update (\%col_data) >>.
2818
2819
2820 Takes an optional C<key> attribute to search on a specific unique constraint.
2821 For example:
2822
2823   # In your application
2824   my $cd = $schema->resultset('CD')->update_or_create(
2825     {
2826       artist => 'Massive Attack',
2827       title  => 'Mezzanine',
2828       year   => 1998,
2829     },
2830     { key => 'cd_artist_title' }
2831   );
2832
2833   $cd->cd_to_producer->update_or_create({
2834     producer => $producer,
2835     name => 'harry',
2836   }, {
2837     key => 'primary',
2838   });
2839
2840 B<Note>: Make sure to read the documentation of L</find> and understand the
2841 significance of the C<key> attribute, as its lack may skew your search, and
2842 subsequently result in spurious row creation.
2843
2844 B<Note>: Take care when using C<update_or_create> with a table having
2845 columns with default values that you intend to be automatically
2846 supplied by the database (e.g. an auto_increment primary key column).
2847 In normal usage, the value of such columns should NOT be included at
2848 all in the call to C<update_or_create>, even when set to C<undef>.
2849
2850 See also L</find> and L</find_or_create>. For information on how to declare
2851 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2852
2853 If you need to know if an existing row was updated or a new one created use
2854 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2855 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2856 database!
2857
2858 =cut
2859
2860 sub update_or_create {
2861   my $self = shift;
2862   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2863   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2864
2865   my $row = $self->find($cond, $attrs);
2866   if (defined $row) {
2867     $row->update($cond);
2868     return $row;
2869   }
2870
2871   return $self->create($cond);
2872 }
2873
2874 =head2 update_or_new
2875
2876 =over 4
2877
2878 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2879
2880 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2881
2882 =back
2883
2884   $resultset->update_or_new({ col => $val, ... });
2885
2886 Like L</find_or_new> but if a row is found it is immediately updated via
2887 C<< $found_row->update (\%col_data) >>.
2888
2889 For example:
2890
2891   # In your application
2892   my $cd = $schema->resultset('CD')->update_or_new(
2893     {
2894       artist => 'Massive Attack',
2895       title  => 'Mezzanine',
2896       year   => 1998,
2897     },
2898     { key => 'cd_artist_title' }
2899   );
2900
2901   if ($cd->in_storage) {
2902       # the cd was updated
2903   }
2904   else {
2905       # the cd is not yet in the database, let's insert it
2906       $cd->insert;
2907   }
2908
2909 B<Note>: Make sure to read the documentation of L</find> and understand the
2910 significance of the C<key> attribute, as its lack may skew your search, and
2911 subsequently result in spurious new objects.
2912
2913 B<Note>: Take care when using C<update_or_new> with a table having
2914 columns with default values that you intend to be automatically
2915 supplied by the database (e.g. an auto_increment primary key column).
2916 In normal usage, the value of such columns should NOT be included at
2917 all in the call to C<update_or_new>, even when set to C<undef>.
2918
2919 See also L</find>, L</find_or_create> and L</find_or_new>.
2920
2921 =cut
2922
2923 sub update_or_new {
2924     my $self  = shift;
2925     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2926     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2927
2928     my $row = $self->find( $cond, $attrs );
2929     if ( defined $row ) {
2930         $row->update($cond);
2931         return $row;
2932     }
2933
2934     return $self->new_result($cond);
2935 }
2936
2937 =head2 get_cache
2938
2939 =over 4
2940
2941 =item Arguments: none
2942
2943 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2944
2945 =back
2946
2947 Gets the contents of the cache for the resultset, if the cache is set.
2948
2949 The cache is populated either by using the L</prefetch> attribute to
2950 L</search> or by calling L</set_cache>.
2951
2952 =cut
2953
2954 sub get_cache {
2955   shift->{all_cache};
2956 }
2957
2958 =head2 set_cache
2959
2960 =over 4
2961
2962 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2963
2964 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2965
2966 =back
2967
2968 Sets the contents of the cache for the resultset. Expects an arrayref
2969 of objects of the same class as those produced by the resultset. Note that
2970 if the cache is set, the resultset will return the cached objects rather
2971 than re-querying the database even if the cache attr is not set.
2972
2973 The contents of the cache can also be populated by using the
2974 L</prefetch> attribute to L</search>.
2975
2976 =cut
2977
2978 sub set_cache {
2979   my ( $self, $data ) = @_;
2980   $self->throw_exception("set_cache requires an arrayref")
2981       if defined($data) && (ref $data ne 'ARRAY');
2982   $self->{all_cache} = $data;
2983 }
2984
2985 =head2 clear_cache
2986
2987 =over 4
2988
2989 =item Arguments: none
2990
2991 =item Return Value: undef
2992
2993 =back
2994
2995 Clears the cache for the resultset.
2996
2997 =cut
2998
2999 sub clear_cache {
3000   shift->set_cache(undef);
3001 }
3002
3003 =head2 is_paged
3004
3005 =over 4
3006
3007 =item Arguments: none
3008
3009 =item Return Value: true, if the resultset has been paginated
3010
3011 =back
3012
3013 =cut
3014
3015 sub is_paged {
3016   my ($self) = @_;
3017   return !!$self->{attrs}{page};
3018 }
3019
3020 =head2 is_ordered
3021
3022 =over 4
3023
3024 =item Arguments: none
3025
3026 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3027
3028 =back
3029
3030 =cut
3031
3032 sub is_ordered {
3033   my ($self) = @_;
3034   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3035 }
3036
3037 =head2 related_resultset
3038
3039 =over 4
3040
3041 =item Arguments: $rel_name
3042
3043 =item Return Value: L<$resultset|/search>
3044
3045 =back
3046
3047 Returns a related resultset for the supplied relationship name.
3048
3049   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3050
3051 =cut
3052
3053 sub related_resultset {
3054   my ($self, $rel) = @_;
3055
3056   return $self->{related_resultsets}{$rel} ||= do {
3057     my $rsrc = $self->result_source;
3058     my $rel_info = $rsrc->relationship_info($rel);
3059
3060     $self->throw_exception(
3061       "search_related: result source '" . $rsrc->source_name .
3062         "' has no such relationship $rel")
3063       unless $rel_info;
3064
3065     my $attrs = $self->_chain_relationship($rel);
3066
3067     my $join_count = $attrs->{seen_join}{$rel};
3068
3069     my $alias = $self->result_source->storage
3070         ->relname_to_table_alias($rel, $join_count);
3071
3072     # since this is search_related, and we already slid the select window inwards
3073     # (the select/as attrs were deleted in the beginning), we need to flip all
3074     # left joins to inner, so we get the expected results
3075     # read the comment on top of the actual function to see what this does
3076     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3077
3078
3079     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3080     delete @{$attrs}{qw(result_class alias)};
3081
3082     my $related_cache;
3083
3084     if (my $cache = $self->get_cache) {
3085       $related_cache = [ map
3086         { @{$_->related_resultset($rel)->get_cache||[]} }
3087         @$cache
3088       ];
3089     }
3090
3091     my $rel_source = $rsrc->related_source($rel);
3092
3093     my $new = do {
3094
3095       # The reason we do this now instead of passing the alias to the
3096       # search_rs below is that if you wrap/overload resultset on the
3097       # source you need to know what alias it's -going- to have for things
3098       # to work sanely (e.g. RestrictWithObject wants to be able to add
3099       # extra query restrictions, and these may need to be $alias.)
3100
3101       my $rel_attrs = $rel_source->resultset_attributes;
3102       local $rel_attrs->{alias} = $alias;
3103
3104       $rel_source->resultset
3105                  ->search_rs(
3106                      undef, {
3107                        %$attrs,
3108                        where => $attrs->{where},
3109                    });
3110     };
3111     $new->set_cache($related_cache) if $related_cache;
3112     $new;
3113   };
3114 }
3115
3116 =head2 current_source_alias
3117
3118 =over 4
3119
3120 =item Arguments: none
3121
3122 =item Return Value: $source_alias
3123
3124 =back
3125
3126 Returns the current table alias for the result source this resultset is built
3127 on, that will be used in the SQL query. Usually it is C<me>.
3128
3129 Currently the source alias that refers to the result set returned by a
3130 L</search>/L</find> family method depends on how you got to the resultset: it's
3131 C<me> by default, but eg. L</search_related> aliases it to the related result
3132 source name (and keeps C<me> referring to the original result set). The long
3133 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3134 (and make this method unnecessary).
3135
3136 Thus it's currently necessary to use this method in predefined queries (see
3137 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3138 source alias of the current result set:
3139
3140   # in a result set class
3141   sub modified_by {
3142     my ($self, $user) = @_;
3143
3144     my $me = $self->current_source_alias;
3145
3146     return $self->search({
3147       "$me.modified" => $user->id,
3148     });
3149   }
3150
3151 =cut
3152
3153 sub current_source_alias {
3154   return (shift->{attrs} || {})->{alias} || 'me';
3155 }
3156
3157 =head2 as_subselect_rs
3158
3159 =over 4
3160
3161 =item Arguments: none
3162
3163 =item Return Value: L<$resultset|/search>
3164
3165 =back
3166
3167 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3168 "virtual view" by including it as a subquery within the from clause.  From this
3169 point on, any joined tables are inaccessible to ->search on the resultset (as if
3170 it were simply where-filtered without joins).  For example:
3171
3172  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3173
3174  # 'x' now pollutes the query namespace
3175
3176  # So the following works as expected
3177  my $ok_rs = $rs->search({'x.other' => 1});
3178
3179  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3180  # def) we look for one row with contradictory terms and join in another table
3181  # (aliased 'x_2') which we never use
3182  my $broken_rs = $rs->search({'x.name' => 'def'});
3183
3184  my $rs2 = $rs->as_subselect_rs;
3185
3186  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3187  my $not_joined_rs = $rs2->search({'x.other' => 1});
3188
3189  # works as expected: finds a 'table' row related to two x rows (abc and def)
3190  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3191
3192 Another example of when one might use this would be to select a subset of
3193 columns in a group by clause:
3194
3195  my $rs = $schema->resultset('Bar')->search(undef, {
3196    group_by => [qw{ id foo_id baz_id }],
3197  })->as_subselect_rs->search(undef, {
3198    columns => [qw{ id foo_id }]
3199  });
3200
3201 In the above example normally columns would have to be equal to the group by,
3202 but because we isolated the group by into a subselect the above works.
3203
3204 =cut
3205
3206 sub as_subselect_rs {
3207   my $self = shift;
3208
3209   my $attrs = $self->_resolved_attrs;
3210
3211   my $fresh_rs = (ref $self)->new (
3212     $self->result_source
3213   );
3214
3215   # these pieces will be locked in the subquery
3216   delete $fresh_rs->{cond};
3217   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3218
3219   return $fresh_rs->search( {}, {
3220     from => [{
3221       $attrs->{alias} => $self->as_query,
3222       -alias  => $attrs->{alias},
3223       -rsrc   => $self->result_source,
3224     }],
3225     alias => $attrs->{alias},
3226   });
3227 }
3228
3229 # This code is called by search_related, and makes sure there
3230 # is clear separation between the joins before, during, and
3231 # after the relationship. This information is needed later
3232 # in order to properly resolve prefetch aliases (any alias
3233 # with a relation_chain_depth less than the depth of the
3234 # current prefetch is not considered)
3235 #
3236 # The increments happen twice per join. An even number means a
3237 # relationship specified via a search_related, whereas an odd
3238 # number indicates a join/prefetch added via attributes
3239 #
3240 # Also this code will wrap the current resultset (the one we
3241 # chain to) in a subselect IFF it contains limiting attributes
3242 sub _chain_relationship {
3243   my ($self, $rel) = @_;
3244   my $source = $self->result_source;
3245   my $attrs = { %{$self->{attrs}||{}} };
3246
3247   # we need to take the prefetch the attrs into account before we
3248   # ->_resolve_join as otherwise they get lost - captainL
3249   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3250
3251   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3252
3253   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3254
3255   my $from;
3256   my @force_subq_attrs = qw/offset rows group_by having/;
3257
3258   if (
3259     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3260       ||
3261     $self->_has_resolved_attr (@force_subq_attrs)
3262   ) {
3263     # Nuke the prefetch (if any) before the new $rs attrs
3264     # are resolved (prefetch is useless - we are wrapping
3265     # a subquery anyway).
3266     my $rs_copy = $self->search;
3267     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3268       $rs_copy->{attrs}{join},
3269       delete $rs_copy->{attrs}{prefetch},
3270     );
3271
3272     $from = [{
3273       -rsrc   => $source,
3274       -alias  => $attrs->{alias},
3275       $attrs->{alias} => $rs_copy->as_query,
3276     }];
3277     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3278     $seen->{-relation_chain_depth} = 0;
3279   }
3280   elsif ($attrs->{from}) {  #shallow copy suffices
3281     $from = [ @{$attrs->{from}} ];
3282   }
3283   else {
3284     $from = [{
3285       -rsrc  => $source,
3286       -alias => $attrs->{alias},
3287       $attrs->{alias} => $source->from,
3288     }];
3289   }
3290
3291   my $jpath = ($seen->{-relation_chain_depth})
3292     ? $from->[-1][0]{-join_path}
3293     : [];
3294
3295   my @requested_joins = $source->_resolve_join(
3296     $join,
3297     $attrs->{alias},
3298     $seen,
3299     $jpath,
3300   );
3301
3302   push @$from, @requested_joins;
3303
3304   $seen->{-relation_chain_depth}++;
3305
3306   # if $self already had a join/prefetch specified on it, the requested
3307   # $rel might very well be already included. What we do in this case
3308   # is effectively a no-op (except that we bump up the chain_depth on
3309   # the join in question so we could tell it *is* the search_related)
3310   my $already_joined;
3311
3312   # we consider the last one thus reverse
3313   for my $j (reverse @requested_joins) {
3314     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3315     if ($rel eq $last_j) {
3316       $j->[0]{-relation_chain_depth}++;
3317       $already_joined++;
3318       last;
3319     }
3320   }
3321
3322   unless ($already_joined) {
3323     push @$from, $source->_resolve_join(
3324       $rel,
3325       $attrs->{alias},
3326       $seen,
3327       $jpath,
3328     );
3329   }
3330
3331   $seen->{-relation_chain_depth}++;
3332
3333   return {%$attrs, from => $from, seen_join => $seen};
3334 }
3335
3336 # FIXME - this needs to go live in Schema with the tree walker... or
3337 # something
3338 my $inflatemap_checker;
3339 $inflatemap_checker = sub {
3340   my ($rsrc, $relpaths) = @_;
3341
3342   my $rels;
3343
3344   for (@$relpaths) {
3345     $_ =~ /^ ( [^\.]+ ) \. (.+) $/x
3346       or next;
3347
3348     push @{$rels->{$1}}, $2;
3349   }
3350
3351   for my $rel (keys %$rels) {
3352     my $rel_rsrc = try {
3353       $rsrc->related_source ($rel)
3354     } catch {
3355     $rsrc->throw_exception(sprintf(
3356       "Inflation into non-existent relationship '%s' of '%s' requested, "
3357     . "check the inflation specification (columns/as) ending in '...%s.%s'",
3358       $rel,
3359       $rsrc->source_name,
3360       $rel,
3361       ( sort { length($a) <=> length ($b) } @{$rels->{$rel}} )[0],
3362     ))};
3363
3364     $inflatemap_checker->($rel_rsrc, $rels->{$rel});
3365   }
3366
3367   return;
3368 };
3369
3370 sub _resolved_attrs {
3371   my $self = shift;
3372   return $self->{_attrs} if $self->{_attrs};
3373
3374   my $attrs  = { %{ $self->{attrs} || {} } };
3375   my $source = $self->result_source;
3376   my $alias  = $attrs->{alias};
3377
3378   # default selection list
3379   $attrs->{columns} = [ $source->columns ]
3380     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3381
3382   # merge selectors together
3383   for (qw/columns select as/) {
3384     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3385       if $attrs->{$_} or $attrs->{"+$_"};
3386   }
3387
3388   # disassemble columns
3389   my (@sel, @as);
3390   if (my $cols = delete $attrs->{columns}) {
3391     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3392       if (ref $c eq 'HASH') {
3393         for my $as (sort keys %$c) {
3394           push @sel, $c->{$as};
3395           push @as, $as;
3396         }
3397       }
3398       else {
3399         push @sel, $c;
3400         push @as, $c;
3401       }
3402     }
3403   }
3404
3405   # when trying to weed off duplicates later do not go past this point -
3406   # everything added from here on is unbalanced "anyone's guess" stuff
3407   my $dedup_stop_idx = $#as;
3408
3409   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3410     if $attrs->{as};
3411   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3412     if $attrs->{select};
3413
3414   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3415   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3416
3417   # disqualify all $alias.col as-bits (inflate-map mandated)
3418   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3419
3420   # de-duplicate the result (remove *identical* select/as pairs)
3421   # and also die on duplicate {as} pointing to different {select}s
3422   # not using a c-style for as the condition is prone to shrinkage
3423   my $seen;
3424   my $i = 0;
3425   while ($i <= $dedup_stop_idx) {
3426     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3427       splice @sel, $i, 1;
3428       splice @as, $i, 1;
3429       $dedup_stop_idx--;
3430     }
3431     elsif ($seen->{$as[$i]}++) {
3432       $self->throw_exception(
3433         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3434       );
3435     }
3436     else {
3437       $i++;
3438     }
3439   }
3440
3441   # validate the user-supplied 'as' chain
3442   # folks get too confused by the (logical) exception message, need to
3443   # go to some lengths to clarify the text
3444   #
3445   # FIXME - this needs to go live in Schema with the tree walker... or
3446   # something
3447   $inflatemap_checker->($source, \@as);
3448
3449   $attrs->{select} = \@sel;
3450   $attrs->{as} = \@as;
3451
3452   $attrs->{from} ||= [{
3453     -rsrc   => $source,
3454     -alias  => $self->{attrs}{alias},
3455     $self->{attrs}{alias} => $source->from,
3456   }];
3457
3458   if ( $attrs->{join} || $attrs->{prefetch} ) {
3459
3460     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3461       if ref $attrs->{from} ne 'ARRAY';
3462
3463     my $join = (delete $attrs->{join}) || {};
3464
3465     if ( defined $attrs->{prefetch} ) {
3466       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3467     }
3468
3469     $attrs->{from} =    # have to copy here to avoid corrupting the original
3470       [
3471         @{ $attrs->{from} },
3472         $source->_resolve_join(
3473           $join,
3474           $alias,
3475           { %{ $attrs->{seen_join} || {} } },
3476           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3477             ? $attrs->{from}[-1][0]{-join_path}
3478             : []
3479           ,
3480         )
3481       ];
3482   }
3483
3484   if ( defined $attrs->{order_by} ) {
3485     $attrs->{order_by} = (
3486       ref( $attrs->{order_by} ) eq 'ARRAY'
3487       ? [ @{ $attrs->{order_by} } ]
3488       : [ $attrs->{order_by} || () ]
3489     );
3490   }
3491
3492   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3493     $attrs->{group_by} = [ $attrs->{group_by} ];
3494   }
3495
3496   # generate the distinct induced group_by early, as prefetch will be carried via a
3497   # subquery (since a group_by is present)
3498   if (delete $attrs->{distinct}) {
3499     if ($attrs->{group_by}) {
3500       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3501     }
3502     else {
3503       # distinct affects only the main selection part, not what prefetch may
3504       # add below.
3505       $attrs->{group_by} = $source->storage->_group_over_selection (
3506         $attrs->{from},
3507         $attrs->{select},
3508         $attrs->{order_by},
3509       );
3510     }
3511   }
3512
3513   # generate selections based on the prefetch helper
3514   my $prefetch;
3515   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3516     if defined $attrs->{prefetch};
3517
3518   if ($prefetch) {
3519
3520     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3521       if $attrs->{_dark_selector};
3522
3523     $attrs->{collapse} = 1;
3524
3525     # this is a separate structure (we don't look in {from} directly)
3526     # as the resolver needs to shift things off the lists to work
3527     # properly (identical-prefetches on different branches)
3528     my $join_map = {};
3529     if (ref $attrs->{from} eq 'ARRAY') {
3530
3531       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3532
3533       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3534         next unless $j->[0]{-alias};
3535         next unless $j->[0]{-join_path};
3536         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3537
3538         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3539
3540         my $p = $join_map;
3541         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3542         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3543       }
3544     }
3545
3546     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3547
3548     # we need to somehow mark which columns came from prefetch
3549     if (@prefetch) {
3550       my $sel_end = $#{$attrs->{select}};
3551       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3552     }
3553
3554     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3555     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3556   }
3557
3558   if ( ! List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3559     $attrs->{_single_resultclass_inflation} = 1;
3560     $attrs->{collapse} = 0;
3561   }
3562
3563   # run through the resulting joinstructure (starting from our current slot)
3564   # and unset collapse if proven unnesessary
3565   #
3566   # also while we are at it find out if the current root source has
3567   # been premultiplied by previous related_source chaining
3568   #
3569   # this allows to predict whether a root object with all other relation
3570   # data set to NULL is in fact unique
3571   if ($attrs->{collapse}) {
3572
3573     if (ref $attrs->{from} eq 'ARRAY') {
3574
3575       if (@{$attrs->{from}} <= 1) {
3576         # no joins - no collapse
3577         $attrs->{collapse} = 0;
3578       }
3579       else {
3580         # find where our table-spec starts
3581         my @fromlist = @{$attrs->{from}};
3582         while (@fromlist) {
3583           my $t = shift @fromlist;
3584
3585           my $is_multi;
3586           # me vs join from-spec distinction - a ref means non-root
3587           if (ref $t eq 'ARRAY') {
3588             $t = $t->[0];
3589             $is_multi ||= ! $t->{-is_single};
3590           }
3591           last if ($t->{-alias} && $t->{-alias} eq $alias);
3592           $attrs->{_main_source_premultiplied} ||= $is_multi;
3593         }
3594
3595         # no non-singles remaining, nor any premultiplication - nothing to collapse
3596         if (
3597           ! $attrs->{_main_source_premultiplied}
3598             and
3599           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3600         ) {
3601           $attrs->{collapse} = 0;
3602         }
3603       }
3604     }
3605
3606     else {
3607       # if we can not analyze the from - err on the side of safety
3608       $attrs->{_main_source_premultiplied} = 1;
3609     }
3610   }
3611
3612   # if both page and offset are specified, produce a combined offset
3613   # even though it doesn't make much sense, this is what pre 081xx has
3614   # been doing
3615   if (my $page = delete $attrs->{page}) {
3616     $attrs->{offset} =
3617       ($attrs->{rows} * ($page - 1))
3618             +
3619       ($attrs->{offset} || 0)
3620     ;
3621   }
3622
3623   return $self->{_attrs} = $attrs;
3624 }
3625
3626 sub _rollout_attr {
3627   my ($self, $attr) = @_;
3628
3629   if (ref $attr eq 'HASH') {
3630     return $self->_rollout_hash($attr);
3631   } elsif (ref $attr eq 'ARRAY') {
3632     return $self->_rollout_array($attr);
3633   } else {
3634     return [$attr];
3635   }
3636 }
3637
3638 sub _rollout_array {
3639   my ($self, $attr) = @_;
3640
3641   my @rolled_array;
3642   foreach my $element (@{$attr}) {
3643     if (ref $element eq 'HASH') {
3644       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3645     } elsif (ref $element eq 'ARRAY') {
3646       #  XXX - should probably recurse here
3647       push( @rolled_array, @{$self->_rollout_array($element)} );
3648     } else {
3649       push( @rolled_array, $element );
3650     }
3651   }
3652   return \@rolled_array;
3653 }
3654
3655 sub _rollout_hash {
3656   my ($self, $attr) = @_;
3657
3658   my @rolled_array;
3659   foreach my $key (keys %{$attr}) {
3660     push( @rolled_array, { $key => $attr->{$key} } );
3661   }
3662   return \@rolled_array;
3663 }
3664
3665 sub _calculate_score {
3666   my ($self, $a, $b) = @_;
3667
3668   if (defined $a xor defined $b) {
3669     return 0;
3670   }
3671   elsif (not defined $a) {
3672     return 1;
3673   }
3674
3675   if (ref $b eq 'HASH') {
3676     my ($b_key) = keys %{$b};
3677     if (ref $a eq 'HASH') {
3678       my ($a_key) = keys %{$a};
3679       if ($a_key eq $b_key) {
3680         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3681       } else {
3682         return 0;
3683       }
3684     } else {
3685       return ($a eq $b_key) ? 1 : 0;
3686     }
3687   } else {
3688     if (ref $a eq 'HASH') {
3689       my ($a_key) = keys %{$a};
3690       return ($b eq $a_key) ? 1 : 0;
3691     } else {
3692       return ($b eq $a) ? 1 : 0;
3693     }
3694   }
3695 }
3696
3697 sub _merge_joinpref_attr {
3698   my ($self, $orig, $import) = @_;
3699
3700   return $import unless defined($orig);
3701   return $orig unless defined($import);
3702
3703   $orig = $self->_rollout_attr($orig);
3704   $import = $self->_rollout_attr($import);
3705
3706   my $seen_keys;
3707   foreach my $import_element ( @{$import} ) {
3708     # find best candidate from $orig to merge $b_element into
3709     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3710     foreach my $orig_element ( @{$orig} ) {
3711       my $score = $self->_calculate_score( $orig_element, $import_element );
3712       if ($score > $best_candidate->{score}) {
3713         $best_candidate->{position} = $position;
3714         $best_candidate->{score} = $score;
3715       }
3716       $position++;
3717     }
3718     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3719     $import_key = '' if not defined $import_key;
3720
3721     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3722       push( @{$orig}, $import_element );
3723     } else {
3724       my $orig_best = $orig->[$best_candidate->{position}];
3725       # merge orig_best and b_element together and replace original with merged
3726       if (ref $orig_best ne 'HASH') {
3727         $orig->[$best_candidate->{position}] = $import_element;
3728       } elsif (ref $import_element eq 'HASH') {
3729         my ($key) = keys %{$orig_best};
3730         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3731       }
3732     }
3733     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3734   }
3735
3736   return @$orig ? $orig : ();
3737 }
3738
3739 {
3740   my $hm;
3741
3742   sub _merge_attr {
3743     $hm ||= do {
3744       require Hash::Merge;
3745       my $hm = Hash::Merge->new;
3746
3747       $hm->specify_behavior({
3748         SCALAR => {
3749           SCALAR => sub {
3750             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3751
3752             if ($defl xor $defr) {
3753               return [ $defl ? $_[0] : $_[1] ];
3754             }
3755             elsif (! $defl) {
3756               return [];
3757             }
3758             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3759               return [ $_[0] ];
3760             }
3761             else {
3762               return [$_[0], $_[1]];
3763             }
3764           },
3765           ARRAY => sub {
3766             return $_[1] if !defined $_[0];
3767             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3768             return [$_[0], @{$_[1]}]
3769           },
3770           HASH  => sub {
3771             return [] if !defined $_[0] and !keys %{$_[1]};
3772             return [ $_[1] ] if !defined $_[0];
3773             return [ $_[0] ] if !keys %{$_[1]};
3774             return [$_[0], $_[1]]
3775           },
3776         },
3777         ARRAY => {
3778           SCALAR => sub {
3779             return $_[0] if !defined $_[1];
3780             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3781             return [@{$_[0]}, $_[1]]
3782           },
3783           ARRAY => sub {
3784             my @ret = @{$_[0]} or return $_[1];
3785             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3786             my %idx = map { $_ => 1 } @ret;
3787             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3788             \@ret;
3789           },
3790           HASH => sub {
3791             return [ $_[1] ] if ! @{$_[0]};
3792             return $_[0] if !keys %{$_[1]};
3793             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3794             return [ @{$_[0]}, $_[1] ];
3795           },
3796         },
3797         HASH => {
3798           SCALAR => sub {
3799             return [] if !keys %{$_[0]} and !defined $_[1];
3800             return [ $_[0] ] if !defined $_[1];
3801             return [ $_[1] ] if !keys %{$_[0]};
3802             return [$_[0], $_[1]]
3803           },
3804           ARRAY => sub {
3805             return [] if !keys %{$_[0]} and !@{$_[1]};
3806             return [ $_[0] ] if !@{$_[1]};
3807             return $_[1] if !keys %{$_[0]};
3808             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3809             return [ $_[0], @{$_[1]} ];
3810           },
3811           HASH => sub {
3812             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3813             return [ $_[0] ] if !keys %{$_[1]};
3814             return [ $_[1] ] if !keys %{$_[0]};
3815             return [ $_[0] ] if $_[0] eq $_[1];
3816             return [ $_[0], $_[1] ];
3817           },
3818         }
3819       } => 'DBIC_RS_ATTR_MERGER');
3820       $hm;
3821     };
3822
3823     return $hm->merge ($_[1], $_[2]);
3824   }
3825 }
3826
3827 sub STORABLE_freeze {
3828   my ($self, $cloning) = @_;
3829   my $to_serialize = { %$self };
3830
3831   # A cursor in progress can't be serialized (and would make little sense anyway)
3832   # the parser can be regenerated (and can't be serialized)
3833   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3834
3835   # nor is it sensical to store a not-yet-fired-count pager
3836   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3837     delete $to_serialize->{pager};
3838   }
3839
3840   Storable::nfreeze($to_serialize);
3841 }
3842
3843 # need this hook for symmetry
3844 sub STORABLE_thaw {
3845   my ($self, $cloning, $serialized) = @_;
3846
3847   %$self = %{ Storable::thaw($serialized) };
3848
3849   $self;
3850 }
3851
3852
3853 =head2 throw_exception
3854
3855 See L<DBIx::Class::Schema/throw_exception> for details.
3856
3857 =cut
3858
3859 sub throw_exception {
3860   my $self=shift;
3861
3862   if (ref $self and my $rsrc = $self->result_source) {
3863     $rsrc->throw_exception(@_)
3864   }
3865   else {
3866     DBIx::Class::Exception->throw(@_);
3867   }
3868 }
3869
3870 1;
3871
3872 __END__
3873
3874 # XXX: FIXME: Attributes docs need clearing up
3875
3876 =head1 ATTRIBUTES
3877
3878 Attributes are used to refine a ResultSet in various ways when
3879 searching for data. They can be passed to any method which takes an
3880 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3881 L</count>.
3882
3883 Default attributes can be set on the result class using
3884 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3885 the CAVEATS on that feature before using it!)
3886
3887 These are in no particular order:
3888
3889 =head2 order_by
3890
3891 =over 4
3892
3893 =item Value: ( $order_by | \@order_by | \%order_by )
3894
3895 =back
3896
3897 Which column(s) to order the results by.
3898
3899 [The full list of suitable values is documented in
3900 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3901 common options.]
3902
3903 If a single column name, or an arrayref of names is supplied, the
3904 argument is passed through directly to SQL. The hashref syntax allows
3905 for connection-agnostic specification of ordering direction:
3906
3907  For descending order:
3908
3909   order_by => { -desc => [qw/col1 col2 col3/] }
3910
3911  For explicit ascending order:
3912
3913   order_by => { -asc => 'col' }
3914
3915 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3916 supported, although you are strongly encouraged to use the hashref
3917 syntax as outlined above.
3918
3919 =head2 columns
3920
3921 =over 4
3922
3923 =item Value: \@columns | \%columns | $column
3924
3925 =back
3926
3927 Shortcut to request a particular set of columns to be retrieved. Each
3928 column spec may be a string (a table column name), or a hash (in which
3929 case the key is the C<as> value, and the value is used as the C<select>
3930 expression). Adds C<me.> onto the start of any column without a C<.> in
3931 it and sets C<select> from that, then auto-populates C<as> from
3932 C<select> as normal. (You may also use the C<cols> attribute, as in
3933 earlier versions of DBIC.)
3934
3935 Essentially C<columns> does the same as L</select> and L</as>.
3936
3937     columns => [ 'foo', { bar => 'baz' } ]
3938
3939 is the same as
3940
3941     select => [qw/foo baz/],
3942     as => [qw/foo bar/]
3943
3944 =head2 +columns
3945
3946 =over 4
3947
3948 =item Value: \@columns
3949
3950 =back
3951
3952 Indicates additional columns to be selected from storage. Works the same
3953 as L</columns> but adds columns to the selection. (You may also use the
3954 C<include_columns> attribute, as in earlier versions of DBIC). For
3955 example:-
3956
3957   $schema->resultset('CD')->search(undef, {
3958     '+columns' => ['artist.name'],
3959     join => ['artist']
3960   });
3961
3962 would return all CDs and include a 'name' column to the information
3963 passed to object inflation. Note that the 'artist' is the name of the
3964 column (or relationship) accessor, and 'name' is the name of the column
3965 accessor in the related table.
3966
3967 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3968 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3969 unary plus operator before it.
3970
3971 =head2 include_columns
3972
3973 =over 4
3974
3975 =item Value: \@columns
3976
3977 =back
3978
3979 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3980
3981 =head2 select
3982
3983 =over 4
3984
3985 =item Value: \@select_columns
3986
3987 =back
3988
3989 Indicates which columns should be selected from the storage. You can use
3990 column names, or in the case of RDBMS back ends, function or stored procedure
3991 names:
3992
3993   $rs = $schema->resultset('Employee')->search(undef, {
3994     select => [
3995       'name',
3996       { count => 'employeeid' },
3997       { max => { length => 'name' }, -as => 'longest_name' }
3998     ]
3999   });
4000
4001   # Equivalent SQL
4002   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4003
4004 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4005 use L</select>, to instruct DBIx::Class how to store the result of the column.
4006 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4007 identifier aliasing. You can however alias a function, so you can use it in
4008 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4009 attribute> supplied as shown in the example above.
4010
4011 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4012 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4013 unary plus operator before it.
4014
4015 =head2 +select
4016
4017 =over 4
4018
4019 Indicates additional columns to be selected from storage.  Works the same as
4020 L</select> but adds columns to the default selection, instead of specifying
4021 an explicit list.
4022
4023 =back
4024
4025 =head2 as
4026
4027 =over 4
4028
4029 =item Value: \@inflation_names
4030
4031 =back
4032
4033 Indicates column names for object inflation. That is L</as> indicates the
4034 slot name in which the column value will be stored within the
4035 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4036 identifier by the C<get_column> method (or via the object accessor B<if one
4037 with the same name already exists>) as shown below. The L</as> attribute has
4038 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4039
4040   $rs = $schema->resultset('Employee')->search(undef, {
4041     select => [
4042       'name',
4043       { count => 'employeeid' },
4044       { max => { length => 'name' }, -as => 'longest_name' }
4045     ],
4046     as => [qw/
4047       name
4048       employee_count
4049       max_name_length
4050     /],
4051   });
4052
4053 If the object against which the search is performed already has an accessor
4054 matching a column name specified in C<as>, the value can be retrieved using
4055 the accessor as normal:
4056
4057   my $name = $employee->name();
4058
4059 If on the other hand an accessor does not exist in the object, you need to
4060 use C<get_column> instead:
4061
4062   my $employee_count = $employee->get_column('employee_count');
4063
4064 You can create your own accessors if required - see
4065 L<DBIx::Class::Manual::Cookbook> for details.
4066
4067 =head2 +as
4068
4069 =over 4
4070
4071 Indicates additional column names for those added via L</+select>. See L</as>.
4072
4073 =back
4074
4075 =head2 join
4076
4077 =over 4
4078
4079 =item Value: ($rel_name | \@rel_names | \%rel_names)
4080
4081 =back
4082
4083 Contains a list of relationships that should be joined for this query.  For
4084 example:
4085
4086   # Get CDs by Nine Inch Nails
4087   my $rs = $schema->resultset('CD')->search(
4088     { 'artist.name' => 'Nine Inch Nails' },
4089     { join => 'artist' }
4090   );
4091
4092 Can also contain a hash reference to refer to the other relation's relations.
4093 For example:
4094
4095   package MyApp::Schema::Track;
4096   use base qw/DBIx::Class/;
4097   __PACKAGE__->table('track');
4098   __PACKAGE__->add_columns(qw/trackid cd position title/);
4099   __PACKAGE__->set_primary_key('trackid');
4100   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4101   1;
4102
4103   # In your application
4104   my $rs = $schema->resultset('Artist')->search(
4105     { 'track.title' => 'Teardrop' },
4106     {
4107       join     => { cd => 'track' },
4108       order_by => 'artist.name',
4109     }
4110   );
4111
4112 You need to use the relationship (not the table) name in  conditions,
4113 because they are aliased as such. The current table is aliased as "me", so
4114 you need to use me.column_name in order to avoid ambiguity. For example:
4115
4116   # Get CDs from 1984 with a 'Foo' track
4117   my $rs = $schema->resultset('CD')->search(
4118     {
4119       'me.year' => 1984,
4120       'tracks.name' => 'Foo'
4121     },
4122     { join => 'tracks' }
4123   );
4124
4125 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4126 similarly for a third time). For e.g.
4127
4128   my $rs = $schema->resultset('Artist')->search({
4129     'cds.title'   => 'Down to Earth',
4130     'cds_2.title' => 'Popular',
4131   }, {
4132     join => [ qw/cds cds/ ],
4133   });
4134
4135 will return a set of all artists that have both a cd with title 'Down
4136 to Earth' and a cd with title 'Popular'.
4137
4138 If you want to fetch related objects from other tables as well, see L</prefetch>
4139 below.
4140
4141  NOTE: An internal join-chain pruner will discard certain joins while
4142  constructing the actual SQL query, as long as the joins in question do not
4143  affect the retrieved result. This for example includes 1:1 left joins
4144  that are not part of the restriction specification (WHERE/HAVING) nor are
4145  a part of the query selection.
4146
4147 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4148
4149 =head2 collapse
4150
4151 =over 4
4152
4153 =item Value: (0 | 1)
4154
4155 =back
4156
4157 When set to a true value, indicates that any rows fetched from joined has_many
4158 relationships are to be aggregated into the corresponding "parent" object. For
4159 example, the resultset:
4160
4161   my $rs = $schema->resultset('CD')->search({}, {
4162     '+columns' => [ qw/ tracks.title tracks.position / ],
4163     join => 'tracks',
4164     collapse => 1,
4165   });
4166
4167 While executing the following query:
4168
4169   SELECT me.*, tracks.title, tracks.position
4170     FROM cd me
4171     LEFT JOIN track tracks
4172       ON tracks.cdid = me.cdid
4173
4174 Will return only as many objects as there are rows in the CD source, even
4175 though the result of the query may span many rows. Each of these CD objects
4176 will in turn have multiple "Track" objects hidden behind the has_many
4177 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4178 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4179 product"), with each CD object containing exactly one of all fetched Track data.
4180
4181 When a collapse is requested on a non-ordered resultset, an order by some
4182 unique part of the main source (the left-most table) is inserted automatically.
4183 This is done so that the resultset is allowed to be "lazy" - calling
4184 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4185 object with all of its related data.
4186
4187 If an L</order_by> is already declared, and orders the resultset in a way that
4188 makes collapsing as described above impossible (e.g. C<< ORDER BY
4189 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4190 switch to "eager" mode and slurp the entire resultset before consturcting the
4191 first object returned by L</next>.
4192
4193 Setting this attribute on a resultset that does not join any has_many
4194 relations is a no-op.
4195
4196 For a more in-depth discussion, see L</PREFETCHING>.
4197
4198 =head2 prefetch
4199
4200 =over 4
4201
4202 =item Value: ($rel_name | \@rel_names | \%rel_names)
4203
4204 =back
4205
4206 This attribute is a shorthand for specifying a L</join> spec, adding all
4207 columns from the joined related sources as L</+columns> and setting
4208 L</collapse> to a true value. For example, the following two queries are
4209 equivalent:
4210
4211   my $rs = $schema->resultset('Artist')->search({}, {
4212     prefetch => { cds => ['genre', 'tracks' ] },
4213   });
4214
4215 and
4216
4217   my $rs = $schema->resultset('Artist')->search({}, {
4218     join => { cds => ['genre', 'tracks' ] },
4219     collapse => 1,
4220     '+columns' => [
4221       (map
4222         { +{ "cds.$_" => "cds.$_" } }
4223         $schema->source('Artist')->related_source('cds')->columns
4224       ),
4225       (map
4226         { +{ "cds.genre.$_" => "genre.$_" } }
4227         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4228       ),
4229       (map
4230         { +{ "cds.tracks.$_" => "tracks.$_" } }
4231         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4232       ),
4233     ],
4234   });
4235
4236 Both producing the following SQL:
4237
4238   SELECT  me.artistid, me.name, me.rank, me.charfield,
4239           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4240           genre.genreid, genre.name,
4241           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4242     FROM artist me
4243     LEFT JOIN cd cds
4244       ON cds.artist = me.artistid
4245     LEFT JOIN genre genre
4246       ON genre.genreid = cds.genreid
4247     LEFT JOIN track tracks
4248       ON tracks.cd = cds.cdid
4249   ORDER BY me.artistid
4250
4251 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4252 the arguments are properly merged and generally do the right thing. For
4253 example, you may want to do the following:
4254
4255   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4256     { 'genre.genreid' => undef },
4257     {
4258       join => { cds => 'genre' },
4259       prefetch => 'cds',
4260     }
4261   );
4262
4263 Which generates the following SQL:
4264
4265   SELECT  me.artistid, me.name, me.rank, me.charfield,
4266           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4267     FROM artist me
4268     LEFT JOIN cd cds
4269       ON cds.artist = me.artistid
4270     LEFT JOIN genre genre
4271       ON genre.genreid = cds.genreid
4272   WHERE genre.genreid IS NULL
4273   ORDER BY me.artistid
4274
4275 For a more in-depth discussion, see L</PREFETCHING>.
4276
4277 =head2 alias
4278
4279 =over 4
4280
4281 =item Value: $source_alias
4282
4283 =back
4284
4285 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4286 nested search queries (sub-SELECTs) might need specific aliases set to
4287 reference inner queries.  For example:
4288
4289    my $q = $rs
4290       ->related_resultset('CDs')
4291       ->related_resultset('Tracks')
4292       ->search({
4293          'track.id' => { -ident => 'none_search.id' },
4294       })
4295       ->as_query;
4296
4297    my $ids = $self->search({
4298       -not_exists => $q,
4299    }, {
4300       alias    => 'none_search',
4301       group_by => 'none_search.id',
4302    })->get_column('id')->as_query;
4303
4304    $self->search({ id => { -in => $ids } })
4305
4306 This attribute is directly tied to L</current_source_alias>.
4307
4308 =head2 page
4309
4310 =over 4
4311
4312 =item Value: $page
4313
4314 =back
4315
4316 Makes the resultset paged and specifies the page to retrieve. Effectively
4317 identical to creating a non-pages resultset and then calling ->page($page)
4318 on it.
4319
4320 If L</rows> attribute is not specified it defaults to 10 rows per page.
4321
4322 When you have a paged resultset, L</count> will only return the number
4323 of rows in the page. To get the total, use the L</pager> and call
4324 C<total_entries> on it.
4325
4326 =head2 rows
4327
4328 =over 4
4329
4330 =item Value: $rows
4331
4332 =back
4333
4334 Specifies the maximum number of rows for direct retrieval or the number of
4335 rows per page if the page attribute or method is used.
4336
4337 =head2 offset
4338
4339 =over 4
4340
4341 =item Value: $offset
4342
4343 =back
4344
4345 Specifies the (zero-based) row number for the  first row to be returned, or the
4346 of the first row of the first page if paging is used.
4347
4348 =head2 software_limit
4349
4350 =over 4
4351
4352 =item Value: (0 | 1)
4353
4354 =back
4355
4356 When combined with L</rows> and/or L</offset> the generated SQL will not
4357 include any limit dialect stanzas. Instead the entire result will be selected
4358 as if no limits were specified, and DBIC will perform the limit locally, by
4359 artificially advancing and finishing the resulting L</cursor>.
4360
4361 This is the recommended way of performing resultset limiting when no sane RDBMS
4362 implementation is available (e.g.
4363 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4364 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4365
4366 =head2 group_by
4367
4368 =over 4
4369
4370 =item Value: \@columns
4371
4372 =back
4373
4374 A arrayref of columns to group by. Can include columns of joined tables.
4375
4376   group_by => [qw/ column1 column2 ... /]
4377
4378 =head2 having
4379
4380 =over 4
4381
4382 =item Value: $condition
4383
4384 =back
4385
4386 HAVING is a select statement attribute that is applied between GROUP BY and
4387 ORDER BY. It is applied to the after the grouping calculations have been
4388 done.
4389
4390   having => { 'count_employee' => { '>=', 100 } }
4391
4392 or with an in-place function in which case literal SQL is required:
4393
4394   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4395
4396 =head2 distinct
4397
4398 =over 4
4399
4400 =item Value: (0 | 1)
4401
4402 =back
4403
4404 Set to 1 to group by all columns. If the resultset already has a group_by
4405 attribute, this setting is ignored and an appropriate warning is issued.
4406
4407 =head2 where
4408
4409 =over 4
4410
4411 Adds to the WHERE clause.
4412
4413   # only return rows WHERE deleted IS NULL for all searches
4414   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4415
4416 Can be overridden by passing C<< { where => undef } >> as an attribute
4417 to a resultset.
4418
4419 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4420
4421 =back
4422
4423 =head2 cache
4424
4425 Set to 1 to cache search results. This prevents extra SQL queries if you
4426 revisit rows in your ResultSet:
4427
4428   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4429
4430   while( my $artist = $resultset->next ) {
4431     ... do stuff ...
4432   }
4433
4434   $rs->first; # without cache, this would issue a query
4435
4436 By default, searches are not cached.
4437
4438 For more examples of using these attributes, see
4439 L<DBIx::Class::Manual::Cookbook>.
4440
4441 =head2 for
4442
4443 =over 4
4444
4445 =item Value: ( 'update' | 'shared' | \$scalar )
4446
4447 =back
4448
4449 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4450 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4451 query.
4452
4453 =head1 PREFETCHING
4454
4455 DBIx::Class supports arbitrary related data prefetching from multiple related
4456 sources. Any combination of relationship types and column sets are supported.
4457 If L<collapsing|/collapse> is requested, there is an additional requirement of
4458 selecting enough data to make every individual object uniquely identifiable.
4459
4460 Here are some more involved examples, based on the following relationship map:
4461
4462   # Assuming:
4463   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4464   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4465   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4466
4467   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4468
4469   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4470
4471
4472
4473   my $rs = $schema->resultset('Tag')->search(
4474     undef,
4475     {
4476       prefetch => {
4477         cd => 'artist'
4478       }
4479     }
4480   );
4481
4482 The initial search results in SQL like the following:
4483
4484   SELECT tag.*, cd.*, artist.* FROM tag
4485   JOIN cd ON tag.cd = cd.cdid
4486   JOIN artist ON cd.artist = artist.artistid
4487
4488 L<DBIx::Class> has no need to go back to the database when we access the
4489 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4490 case.
4491
4492 Simple prefetches will be joined automatically, so there is no need
4493 for a C<join> attribute in the above search.
4494
4495 The L</prefetch> attribute can be used with any of the relationship types
4496 and multiple prefetches can be specified together. Below is a more complex
4497 example that prefetches a CD's artist, its liner notes (if present),
4498 the cover image, the tracks on that CD, and the guests on those
4499 tracks.
4500
4501   my $rs = $schema->resultset('CD')->search(
4502     undef,
4503     {
4504       prefetch => [
4505         { artist => 'record_label'},  # belongs_to => belongs_to
4506         'liner_note',                 # might_have
4507         'cover_image',                # has_one
4508         { tracks => 'guests' },       # has_many => has_many
4509       ]
4510     }
4511   );
4512
4513 This will produce SQL like the following:
4514
4515   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4516          tracks.*, guests.*
4517     FROM cd me
4518     JOIN artist artist
4519       ON artist.artistid = me.artistid
4520     JOIN record_label record_label
4521       ON record_label.labelid = artist.labelid
4522     LEFT JOIN track tracks
4523       ON tracks.cdid = me.cdid
4524     LEFT JOIN guest guests
4525       ON guests.trackid = track.trackid
4526     LEFT JOIN liner_notes liner_note
4527       ON liner_note.cdid = me.cdid
4528     JOIN cd_artwork cover_image
4529       ON cover_image.cdid = me.cdid
4530   ORDER BY tracks.cd
4531
4532 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4533 C<tracks>, and C<guests> of the CD will all be available through the
4534 relationship accessors without the need for additional queries to the
4535 database.
4536
4537 =head3 CAVEATS
4538
4539 Prefetch does a lot of deep magic. As such, it may not behave exactly
4540 as you might expect.
4541
4542 =over 4
4543
4544 =item *
4545
4546 Prefetch uses the L</cache> to populate the prefetched relationships. This
4547 may or may not be what you want.
4548
4549 =item *
4550
4551 If you specify a condition on a prefetched relationship, ONLY those
4552 rows that match the prefetched condition will be fetched into that relationship.
4553 This means that adding prefetch to a search() B<may alter> what is returned by
4554 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4555
4556   my $artist_rs = $schema->resultset('Artist')->search({
4557       'cds.year' => 2008,
4558   }, {
4559       join => 'cds',
4560   });
4561
4562   my $count = $artist_rs->first->cds->count;
4563
4564   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4565
4566   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4567
4568   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4569
4570 That cmp_ok() may or may not pass depending on the datasets involved. In other
4571 words the C<WHERE> condition would apply to the entire dataset, just like
4572 it would in regular SQL. If you want to add a condition only to the "right side"
4573 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4574 condition|DBIx::Class::Relationship::Base/condition>
4575
4576 =back
4577
4578 =head1 DBIC BIND VALUES
4579
4580 Because DBIC may need more information to bind values than just the column name
4581 and value itself, it uses a special format for both passing and receiving bind
4582 values.  Each bind value should be composed of an arrayref of
4583 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4584
4585 =over 4
4586
4587 =item dbd_attrs
4588
4589 If present (in any form), this is what is being passed directly to bind_param.
4590 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4591 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4592
4593 If this is specified, all other bind options described below are ignored.
4594
4595 =item sqlt_datatype
4596
4597 If present, this is used to infer the actual bind attribute by passing to
4598 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4599 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4600
4601 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4602 currently drivers are expected to "Do the Right Thing" when given a common
4603 datatype name.  (Not ideal, but that's what we got at this point.)
4604
4605 =item sqlt_size
4606
4607 Currently used to correctly allocate buffers for bind_param_inout().
4608 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4609 or to a sensible value based on the "data_type".
4610
4611 =item dbic_colname
4612
4613 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4614 explicitly specified they are never overriden).  Also used by some weird DBDs,
4615 where the column name should be available at bind_param time (e.g. Oracle).
4616
4617 =back
4618
4619 For backwards compatibility and convenience, the following shortcuts are
4620 supported:
4621
4622   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4623   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4624   [ undef,   $val ] === [ {}, $val ]
4625
4626 =head1 AUTHOR AND CONTRIBUTORS
4627
4628 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4629
4630 =head1 LICENSE
4631
4632 You may distribute this code under the same terms as Perl itself.
4633