lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset (ie:
 145 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 146 and attributes with the same keys need resolving.
 147
 148 If any of L</columns>, L</select>, L</as> are present, they reset the
 149 original selection, and start the selection "clean".
 150
 151 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 152 are merged into the existing ones from the original resultset.
 153
 154 The L</where> and L</having> attributes, and any search conditions, are
 155 merged with an SQL C<AND> to the existing condition from the original
 156 resultset.
 157
 158 All other attributes are overridden by any new ones supplied in the
 159 search attributes.
 160
 161 =head2 Multiple queries
 162
 163 Since a resultset just defines a query, you can do all sorts of
 164 things with it with the same object.
 165
 166   # Don't hit the DB yet.
 167   my $cd_rs = $schema->resultset('CD')->search({
 168     title => 'something',
 169     year => 2009,
 170   });
 171
 172   # Each of these hits the DB individually.
 173   my $count = $cd_rs->count;
 174   my $most_recent = $cd_rs->get_column('date_released')->max();
 175   my @records = $cd_rs->all;
 176
 177 And it's not just limited to SELECT statements.
 178
 179   $cd_rs->delete();
 180
 181 This is even cooler:
 182
 183   $cd_rs->create({ artist => 'Fred' });
 184
 185 Which is the same as:
 186
 187   $schema->resultset('CD')->create({
 188     title => 'something',
 189     year => 2009,
 190     artist => 'Fred'
 191   });
 192
 193 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 194
 195 =head1 METHODS
 196
 197 =head2 new
 198
 199 =over 4
 200
 201 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 202
 203 =item Return Value: L<$resultset|/search>
 204
 205 =back
 206
 207 The resultset constructor. Takes a source object (usually a
 208 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 209 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 210 executed as needed by the other methods.
 211
 212 Generally you never construct a resultset manually. Instead you get one
 213 from e.g. a
 214 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 215 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 216 scalar context):
 217
 218   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 219
 220 =over
 221
 222 =item WARNING
 223
 224 If called on an object, proxies to L</new_result> instead, so
 225
 226   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 227
 228 will return a CD object, not a ResultSet, and is equivalent to:
 229
 230   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 231
 232 Please also keep in mind that many internals call L</new_result> directly,
 233 so overloading this method with the idea of intercepting new result object
 234 creation B<will not work>. See also warning pertaining to L</create>.
 235
 236 =back
 237
 238 =cut
 239
 240 sub new {
 241   my $class = shift;
 242   return $class->new_result(@_) if ref $class;
 243
 244   my ($source, $attrs) = @_;
 245   $source = $source->resolve
 246     if $source->isa('DBIx::Class::ResultSourceHandle');
 247   $attrs = { %{$attrs||{}} };
 248
 249   if ($attrs->{page}) {
 250     $attrs->{rows} ||= 10;
 251   }
 252
 253   $attrs->{alias} ||= 'me';
 254
 255   my $self = bless {
 256     result_source => $source,
 257     cond => $attrs->{where},
 258     pager => undef,
 259     attrs => $attrs,
 260   }, $class;
 261
 262   # if there is a dark selector, this means we are already in a
 263   # chain and the cleanup/sanification was taken care of by
 264   # _search_rs already
 265   $self->_normalize_selection($attrs)
 266     unless $attrs->{_dark_selector};
 267
 268   $self->result_class(
 269     $attrs->{result_class} || $source->result_class
 270   );
 271
 272   $self;
 273 }
 274
 275 =head2 search
 276
 277 =over 4
 278
 279 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 280
 281 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 282
 283 =back
 284
 285   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 286   my $new_rs = $cd_rs->search({ year => 2005 });
 287
 288   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 289                  # year = 2005 OR year = 2004
 290
 291 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 292 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 293 To avoid that, use L</search_rs>.
 294
 295 If you need to pass in additional attributes but no additional condition,
 296 call it as C<search(undef, \%attrs)>.
 297
 298   # "SELECT name, artistid FROM $artist_table"
 299   my @all_artists = $schema->resultset('Artist')->search(undef, {
 300     columns => [qw/name artistid/],
 301   });
 302
 303 For a list of attributes that can be passed to C<search>, see
 304 L</ATTRIBUTES>. For more examples of using this function, see
 305 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 306 documentation for the first argument, see L<SQL::Abstract>
 307 and its extension L<DBIx::Class::SQLMaker>.
 308
 309 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 310
 311 =head3 CAVEAT
 312
 313 Note that L</search> does not process/deflate any of the values passed in the
 314 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 315 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 316 manually that any value passed to this method will stringify to something the
 317 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 318 objects, for more info see:
 319 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 320
 321 =cut
 322
 323 sub search {
 324   my $self = shift;
 325   my $rs = $self->search_rs( @_ );
 326
 327   if (wantarray) {
 328     return $rs->all;
 329   }
 330   elsif (defined wantarray) {
 331     return $rs;
 332   }
 333   else {
 334     # we can be called by a relationship helper, which in
 335     # turn may be called in void context due to some braindead
 336     # overload or whatever else the user decided to be clever
 337     # at this particular day. Thus limit the exception to
 338     # external code calls only
 339     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 340       if (caller)[0] !~ /^\QDBIx::Class::/;
 341
 342     return ();
 343   }
 344 }
 345
 346 =head2 search_rs
 347
 348 =over 4
 349
 350 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 351
 352 =item Return Value: L<$resultset|/search>
 353
 354 =back
 355
 356 This method does the same exact thing as search() except it will
 357 always return a resultset, even in list context.
 358
 359 =cut
 360
 361 sub search_rs {
 362   my $self = shift;
 363
 364   my $rsrc = $self->result_source;
 365   my ($call_cond, $call_attrs);
 366
 367   # Special-case handling for (undef, undef) or (undef)
 368   # Note that (foo => undef) is valid deprecated syntax
 369   @_ = () if not scalar grep { defined $_ } @_;
 370
 371   # just a cond
 372   if (@_ == 1) {
 373     $call_cond = shift;
 374   }
 375   # fish out attrs in the ($condref, $attr) case
 376   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 377     ($call_cond, $call_attrs) = @_;
 378   }
 379   elsif (@_ % 2) {
 380     $self->throw_exception('Odd number of arguments to search')
 381   }
 382   # legacy search
 383   elsif (@_) {
 384     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 385       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 386
 387     for my $i (0 .. $#_) {
 388       next if $i % 2;
 389       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 390         if (! defined $_[$i] or ref $_[$i] ne '');
 391     }
 392
 393     $call_cond = { @_ };
 394   }
 395
 396   # see if we can keep the cache (no $rs changes)
 397   my $cache;
 398   my %safe = (alias => 1, cache => 1);
 399   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 400     ! defined $call_cond
 401       or
 402     ref $call_cond eq 'HASH' && ! keys %$call_cond
 403       or
 404     ref $call_cond eq 'ARRAY' && ! @$call_cond
 405   )) {
 406     $cache = $self->get_cache;
 407   }
 408
 409   my $old_attrs = { %{$self->{attrs}} };
 410   my $old_having = delete $old_attrs->{having};
 411   my $old_where = delete $old_attrs->{where};
 412
 413   my $new_attrs = { %$old_attrs };
 414
 415   # take care of call attrs (only if anything is changing)
 416   if ($call_attrs and keys %$call_attrs) {
 417
 418     # copy for _normalize_selection
 419     $call_attrs = { %$call_attrs };
 420
 421     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 422
 423     # reset the current selector list if new selectors are supplied
 424     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 425       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 426     }
 427
 428     # Normalize the new selector list (operates on the passed-in attr structure)
 429     # Need to do it on every chain instead of only once on _resolved_attrs, in
 430     # order to allow detection of empty vs partial 'as'
 431     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 432       if $old_attrs->{_dark_selector};
 433     $self->_normalize_selection ($call_attrs);
 434
 435     # start with blind overwriting merge, exclude selector attrs
 436     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 437     delete @{$new_attrs}{@selector_attrs};
 438
 439     for (@selector_attrs) {
 440       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 441         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 442     }
 443
 444     # older deprecated name, use only if {columns} is not there
 445     if (my $c = delete $new_attrs->{cols}) {
 446       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 447       if ($new_attrs->{columns}) {
 448         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 449       }
 450       else {
 451         $new_attrs->{columns} = $c;
 452       }
 453     }
 454
 455
 456     # join/prefetch use their own crazy merging heuristics
 457     foreach my $key (qw/join prefetch/) {
 458       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 459         if exists $call_attrs->{$key};
 460     }
 461
 462     # stack binds together
 463     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 464   }
 465
 466
 467   for ($old_where, $call_cond) {
 468     if (defined $_) {
 469       $new_attrs->{where} = $self->_stack_cond (
 470         $_, $new_attrs->{where}
 471       );
 472     }
 473   }
 474
 475   if (defined $old_having) {
 476     $new_attrs->{having} = $self->_stack_cond (
 477       $old_having, $new_attrs->{having}
 478     )
 479   }
 480
 481   my $rs = (ref $self)->new($rsrc, $new_attrs);
 482
 483   $rs->set_cache($cache) if ($cache);
 484
 485   return $rs;
 486 }
 487
 488 my $dark_sel_dumper;
 489 sub _normalize_selection {
 490   my ($self, $attrs) = @_;
 491
 492   # legacy syntax
 493   if ( exists $attrs->{include_columns} ) {
 494     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 495     $attrs->{'+columns'} = $self->_merge_attr(
 496       $attrs->{'+columns'}, delete $attrs->{include_columns}
 497     );
 498   }
 499
 500   # columns are always placed first, however
 501
 502   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 503   # delay the decision on whether to use a default select list ($rsrc->columns)
 504   # allowing stuff like the remove_columns helper to work
 505   #
 506   # select/as +select/+as pairs need special handling - the amount of select/as
 507   # elements in each pair does *not* have to be equal (think multicolumn
 508   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 509   # supplied at all) - try to infer the alias, either from the -as parameter
 510   # of the selector spec, or use the parameter whole if it looks like a column
 511   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 512   # is ok as well), but make sure no more additions to the 'as' chain take place
 513   for my $pref ('', '+') {
 514
 515     my ($sel, $as) = map {
 516       my $key = "${pref}${_}";
 517
 518       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 519         ? @{$attrs->{$key}}
 520         : $attrs->{$key} || ()
 521       ];
 522       delete $attrs->{$key};
 523       $val;
 524     } qw/select as/;
 525
 526     if (! @$as and ! @$sel ) {
 527       next;
 528     }
 529     elsif (@$as and ! @$sel) {
 530       $self->throw_exception(
 531         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 532       );
 533     }
 534     elsif( ! @$as ) {
 535       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 536       # if any @$as has been supplied we assume the user knows what (s)he is doing
 537       # and blindly keep stacking up pieces
 538       unless ($attrs->{_dark_selector}) {
 539         SELECTOR:
 540         for (@$sel) {
 541           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 542             push @$as, $_->{-as};
 543           }
 544           # assume any plain no-space, no-parenthesis string to be a column spec
 545           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 546           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 547             push @$as, $_;
 548           }
 549           # if all else fails - raise a flag that no more aliasing will be allowed
 550           else {
 551             $attrs->{_dark_selector} = {
 552               plus_stage => $pref,
 553               string => ($dark_sel_dumper ||= do {
 554                   require Data::Dumper::Concise;
 555                   Data::Dumper::Concise::DumperObject()->Indent(0);
 556                 })->Values([$_])->Dump
 557               ,
 558             };
 559             last SELECTOR;
 560           }
 561         }
 562       }
 563     }
 564     elsif (@$as < @$sel) {
 565       $self->throw_exception(
 566         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 567       );
 568     }
 569     elsif ($pref and $attrs->{_dark_selector}) {
 570       $self->throw_exception(
 571         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 572       );
 573     }
 574
 575
 576     # merge result
 577     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 578     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 579   }
 580 }
 581
 582 sub _stack_cond {
 583   my ($self, $left, $right) = @_;
 584
 585   # collapse single element top-level conditions
 586   # (single pass only, unlikely to need recursion)
 587   for ($left, $right) {
 588     if (ref $_ eq 'ARRAY') {
 589       if (@$_ == 0) {
 590         $_ = undef;
 591       }
 592       elsif (@$_ == 1) {
 593         $_ = $_->[0];
 594       }
 595     }
 596     elsif (ref $_ eq 'HASH') {
 597       my ($first, $more) = keys %$_;
 598
 599       # empty hash
 600       if (! defined $first) {
 601         $_ = undef;
 602       }
 603       # one element hash
 604       elsif (! defined $more) {
 605         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 606           $_ = $_->{'-and'};
 607         }
 608         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 609           $_ = $_->{'-or'};
 610         }
 611       }
 612     }
 613   }
 614
 615   # merge hashes with weeding out of duplicates (simple cases only)
 616   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 617
 618     # shallow copy to destroy
 619     $right = { %$right };
 620     for (grep { exists $right->{$_} } keys %$left) {
 621       # the use of eq_deeply here is justified - the rhs of an
 622       # expression can contain a lot of twisted weird stuff
 623       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 624     }
 625
 626     $right = undef unless keys %$right;
 627   }
 628
 629
 630   if (defined $left xor defined $right) {
 631     return defined $left ? $left : $right;
 632   }
 633   elsif (! defined $left) {
 634     return undef;
 635   }
 636   else {
 637     return { -and => [ $left, $right ] };
 638   }
 639 }
 640
 641 =head2 search_literal
 642
 643 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 644 should only be used in that context. C<search_literal> is a convenience
 645 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 646 want to ensure columns are bound correctly, use L</search>.
 647
 648 See L<DBIx::Class::Manual::Cookbook/Searching> and
 649 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 650 require C<search_literal>.
 651
 652 =over 4
 653
 654 =item Arguments: $sql_fragment, @standalone_bind_values
 655
 656 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 657
 658 =back
 659
 660   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 661   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 662
 663 Pass a literal chunk of SQL to be added to the conditional part of the
 664 resultset query.
 665
 666 Example of how to use C<search> instead of C<search_literal>
 667
 668   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 669   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 670
 671 =cut
 672
 673 sub search_literal {
 674   my ($self, $sql, @bind) = @_;
 675   my $attr;
 676   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 677     $attr = pop @bind;
 678   }
 679   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 680 }
 681
 682 =head2 find
 683
 684 =over 4
 685
 686 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 687
 688 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 689
 690 =back
 691
 692 Finds and returns a single row based on supplied criteria. Takes either a
 693 hashref with the same format as L</create> (including inference of foreign
 694 keys from related objects), or a list of primary key values in the same
 695 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 696 declaration on the L</result_source>.
 697
 698 In either case an attempt is made to combine conditions already existing on
 699 the resultset with the condition passed to this method.
 700
 701 To aid with preparing the correct query for the storage you may supply the
 702 C<key> attribute, which is the name of a
 703 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 704 unique constraint corresponding to the
 705 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 706 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 707 to construct a query that satisfies the named unique constraint fully (
 708 non-NULL values for each column member of the constraint) an exception is
 709 thrown.
 710
 711 If no C<key> is specified, the search is carried over all unique constraints
 712 which are fully defined by the available condition.
 713
 714 If no such constraint is found, C<find> currently defaults to a simple
 715 C<< search->(\%column_values) >> which may or may not do what you expect.
 716 Note that this fallback behavior may be deprecated in further versions. If
 717 you need to search with arbitrary conditions - use L</search>. If the query
 718 resulting from this fallback produces more than one row, a warning to the
 719 effect is issued, though only the first row is constructed and returned as
 720 C<$result_object>.
 721
 722 In addition to C<key>, L</find> recognizes and applies standard
 723 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 724
 725 Note that if you have extra concerns about the correctness of the resulting
 726 query you need to specify the C<key> attribute and supply the entire condition
 727 as an argument to find (since it is not always possible to perform the
 728 combination of the resultset condition with the supplied one, especially if
 729 the resultset condition contains literal sql).
 730
 731 For example, to find a row by its primary key:
 732
 733   my $cd = $schema->resultset('CD')->find(5);
 734
 735 You can also find a row by a specific unique constraint:
 736
 737   my $cd = $schema->resultset('CD')->find(
 738     {
 739       artist => 'Massive Attack',
 740       title  => 'Mezzanine',
 741     },
 742     { key => 'cd_artist_title' }
 743   );
 744
 745 See also L</find_or_create> and L</update_or_create>.
 746
 747 =cut
 748
 749 sub find {
 750   my $self = shift;
 751   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 752
 753   my $rsrc = $self->result_source;
 754
 755   my $constraint_name;
 756   if (exists $attrs->{key}) {
 757     $constraint_name = defined $attrs->{key}
 758       ? $attrs->{key}
 759       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 760     ;
 761   }
 762
 763   # Parse out the condition from input
 764   my $call_cond;
 765
 766   if (ref $_[0] eq 'HASH') {
 767     $call_cond = { %{$_[0]} };
 768   }
 769   else {
 770     # if only values are supplied we need to default to 'primary'
 771     $constraint_name = 'primary' unless defined $constraint_name;
 772
 773     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 774
 775     $self->throw_exception(
 776       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 777     ) unless @c_cols;
 778
 779     $self->throw_exception (
 780       'find() expects either a column/value hashref, or a list of values '
 781     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 782     ) unless @c_cols == @_;
 783
 784     $call_cond = {};
 785     @{$call_cond}{@c_cols} = @_;
 786   }
 787
 788   my %related;
 789   for my $key (keys %$call_cond) {
 790     if (
 791       my $keyref = ref($call_cond->{$key})
 792         and
 793       my $relinfo = $rsrc->relationship_info($key)
 794     ) {
 795       my $val = delete $call_cond->{$key};
 796
 797       next if $keyref eq 'ARRAY'; # has_many for multi_create
 798
 799       my $rel_q = $rsrc->_resolve_condition(
 800         $relinfo->{cond}, $val, $key, $key
 801       );
 802       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 803       @related{keys %$rel_q} = values %$rel_q;
 804     }
 805   }
 806
 807   # relationship conditions take precedence (?)
 808   @{$call_cond}{keys %related} = values %related;
 809
 810   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 811   my $final_cond;
 812   if (defined $constraint_name) {
 813     $final_cond = $self->_qualify_cond_columns (
 814
 815       $self->_build_unique_cond (
 816         $constraint_name,
 817         $call_cond,
 818       ),
 819
 820       $alias,
 821     );
 822   }
 823   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 824     # This means that we got here after a merger of relationship conditions
 825     # in ::Relationship::Base::search_related (the row method), and furthermore
 826     # the relationship is of the 'single' type. This means that the condition
 827     # provided by the relationship (already attached to $self) is sufficient,
 828     # as there can be only one row in the database that would satisfy the
 829     # relationship
 830   }
 831   else {
 832     # no key was specified - fall down to heuristics mode:
 833     # run through all unique queries registered on the resultset, and
 834     # 'OR' all qualifying queries together
 835     my (@unique_queries, %seen_column_combinations);
 836     for my $c_name ($rsrc->unique_constraint_names) {
 837       next if $seen_column_combinations{
 838         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 839       }++;
 840
 841       push @unique_queries, try {
 842         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 843       } || ();
 844     }
 845
 846     $final_cond = @unique_queries
 847       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 848       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 849     ;
 850   }
 851
 852   # Run the query, passing the result_class since it should propagate for find
 853   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 854   if ($rs->_resolved_attrs->{collapse}) {
 855     my $row = $rs->next;
 856     carp "Query returned more than one row" if $rs->next;
 857     return $row;
 858   }
 859   else {
 860     return $rs->single;
 861   }
 862 }
 863
 864 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 865 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 866 #
 867 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 868 # condition. It is provided for overrides until a saner way forward is devised
 869 #
 870 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 871 # the road. Please adjust your tests accordingly to catch this situation early
 872 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 873 #
 874 # The method will not be removed without an adequately complete replacement
 875 # for strict-mode enforcement
 876 sub _non_unique_find_fallback {
 877   my ($self, $cond, $attrs) = @_;
 878
 879   return $self->_qualify_cond_columns(
 880     $cond,
 881     exists $attrs->{alias}
 882       ? $attrs->{alias}
 883       : $self->{attrs}{alias}
 884   );
 885 }
 886
 887
 888 sub _qualify_cond_columns {
 889   my ($self, $cond, $alias) = @_;
 890
 891   my %aliased = %$cond;
 892   for (keys %aliased) {
 893     $aliased{"$alias.$_"} = delete $aliased{$_}
 894       if $_ !~ /\./;
 895   }
 896
 897   return \%aliased;
 898 }
 899
 900 sub _build_unique_cond {
 901   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 902
 903   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 904
 905   # combination may fail if $self->{cond} is non-trivial
 906   my ($final_cond) = try {
 907     $self->_merge_with_rscond ($extra_cond)
 908   } catch {
 909     +{ %$extra_cond }
 910   };
 911
 912   # trim out everything not in $columns
 913   $final_cond = { map {
 914     exists $final_cond->{$_}
 915       ? ( $_ => $final_cond->{$_} )
 916       : ()
 917   } @c_cols };
 918
 919   if (my @missing = grep
 920     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 921     (@c_cols)
 922   ) {
 923     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 924       $constraint_name,
 925       join (', ', map { "'$_'" } @missing),
 926     ) );
 927   }
 928
 929   if (
 930     !$croak_on_null
 931       and
 932     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 933       and
 934     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 935   ) {
 936     carp_unique ( sprintf (
 937       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 938     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 939     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 940       $constraint_name,
 941       join (', ', map { "'$_'" } @undefs),
 942     ));
 943   }
 944
 945   return $final_cond;
 946 }
 947
 948 =head2 search_related
 949
 950 =over 4
 951
 952 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 953
 954 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 955
 956 =back
 957
 958   $new_rs = $cd_rs->search_related('artist', {
 959     name => 'Emo-R-Us',
 960   });
 961
 962 Searches the specified relationship, optionally specifying a condition and
 963 attributes for matching records. See L</ATTRIBUTES> for more information.
 964
 965 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 966 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 967
 968 See also L</search_related_rs>.
 969
 970 =cut
 971
 972 sub search_related {
 973   return shift->related_resultset(shift)->search(@_);
 974 }
 975
 976 =head2 search_related_rs
 977
 978 This method works exactly the same as search_related, except that
 979 it guarantees a resultset, even in list context.
 980
 981 =cut
 982
 983 sub search_related_rs {
 984   return shift->related_resultset(shift)->search_rs(@_);
 985 }
 986
 987 =head2 cursor
 988
 989 =over 4
 990
 991 =item Arguments: none
 992
 993 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 994
 995 =back
 996
 997 Returns a storage-driven cursor to the given resultset. See
 998 L<DBIx::Class::Cursor> for more information.
 999
1000 =cut
1001
1002 sub cursor {
1003   my $self = shift;
1004
1005   return $self->{cursor} ||= do {
1006     my $attrs = { %{$self->_resolved_attrs } };
1007     $self->result_source->storage->select(
1008       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1009     );
1010   };
1011 }
1012
1013 =head2 single
1014
1015 =over 4
1016
1017 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1018
1019 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1020
1021 =back
1022
1023   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1024
1025 Inflates the first result without creating a cursor if the resultset has
1026 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1027 of L</search>.
1028
1029 While this method can take an optional search condition (just like L</search>)
1030 being a fast-code-path it does not recognize search attributes. If you need to
1031 add extra joins or similar, call L</search> and then chain-call L</single> on the
1032 L<DBIx::Class::ResultSet> returned.
1033
1034 =over
1035
1036 =item B<Note>
1037
1038 As of 0.08100, this method enforces the assumption that the preceding
1039 query returns only one row. If more than one row is returned, you will receive
1040 a warning:
1041
1042   Query returned more than one row
1043
1044 In this case, you should be using L</next> or L</find> instead, or if you really
1045 know what you are doing, use the L</rows> attribute to explicitly limit the size
1046 of the resultset.
1047
1048 This method will also throw an exception if it is called on a resultset prefetching
1049 has_many, as such a prefetch implies fetching multiple rows from the database in
1050 order to assemble the resulting object.
1051
1052 =back
1053
1054 =cut
1055
1056 sub single {
1057   my ($self, $where) = @_;
1058   if(@_ > 2) {
1059       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1060   }
1061
1062   my $attrs = { %{$self->_resolved_attrs} };
1063
1064   $self->throw_exception(
1065     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1066   ) if $attrs->{collapse};
1067
1068   if ($where) {
1069     if (defined $attrs->{where}) {
1070       $attrs->{where} = {
1071         '-and' =>
1072             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1073                $where, delete $attrs->{where} ]
1074       };
1075     } else {
1076       $attrs->{where} = $where;
1077     }
1078   }
1079
1080   my $data = [ $self->result_source->storage->select_single(
1081     $attrs->{from}, $attrs->{select},
1082     $attrs->{where}, $attrs
1083   )];
1084   return undef unless @$data;
1085   $self->{_stashed_rows} = [ $data ];
1086   $self->_construct_results->[0];
1087 }
1088
1089
1090 # _collapse_query
1091 #
1092 # Recursively collapse the query, accumulating values for each column.
1093
1094 sub _collapse_query {
1095   my ($self, $query, $collapsed) = @_;
1096
1097   $collapsed ||= {};
1098
1099   if (ref $query eq 'ARRAY') {
1100     foreach my $subquery (@$query) {
1101       next unless ref $subquery;  # -or
1102       $collapsed = $self->_collapse_query($subquery, $collapsed);
1103     }
1104   }
1105   elsif (ref $query eq 'HASH') {
1106     if (keys %$query and (keys %$query)[0] eq '-and') {
1107       foreach my $subquery (@{$query->{-and}}) {
1108         $collapsed = $self->_collapse_query($subquery, $collapsed);
1109       }
1110     }
1111     else {
1112       foreach my $col (keys %$query) {
1113         my $value = $query->{$col};
1114         $collapsed->{$col}{$value}++;
1115       }
1116     }
1117   }
1118
1119   return $collapsed;
1120 }
1121
1122 =head2 get_column
1123
1124 =over 4
1125
1126 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1127
1128 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1129
1130 =back
1131
1132   my $max_length = $rs->get_column('length')->max;
1133
1134 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1135
1136 =cut
1137
1138 sub get_column {
1139   my ($self, $column) = @_;
1140   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1141   return $new;
1142 }
1143
1144 =head2 search_like
1145
1146 =over 4
1147
1148 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1149
1150 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1151
1152 =back
1153
1154   # WHERE title LIKE '%blue%'
1155   $cd_rs = $rs->search_like({ title => '%blue%'});
1156
1157 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1158 that this is simply a convenience method retained for ex Class::DBI users.
1159 You most likely want to use L</search> with specific operators.
1160
1161 For more information, see L<DBIx::Class::Manual::Cookbook>.
1162
1163 This method is deprecated and will be removed in 0.09. Use L</search()>
1164 instead. An example conversion is:
1165
1166   ->search_like({ foo => 'bar' });
1167
1168   # Becomes
1169
1170   ->search({ foo => { like => 'bar' } });
1171
1172 =cut
1173
1174 sub search_like {
1175   my $class = shift;
1176   carp_unique (
1177     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1178    .' Instead use ->search({ x => { -like => "y%" } })'
1179    .' (note the outer pair of {}s - they are important!)'
1180   );
1181   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1182   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1183   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1184   return $class->search($query, { %$attrs });
1185 }
1186
1187 =head2 slice
1188
1189 =over 4
1190
1191 =item Arguments: $first, $last
1192
1193 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1194
1195 =back
1196
1197 Returns a resultset or object list representing a subset of elements from the
1198 resultset slice is called on. Indexes are from 0, i.e., to get the first
1199 three records, call:
1200
1201   my ($one, $two, $three) = $rs->slice(0, 2);
1202
1203 =cut
1204
1205 sub slice {
1206   my ($self, $min, $max) = @_;
1207   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1208   $attrs->{offset} = $self->{attrs}{offset} || 0;
1209   $attrs->{offset} += $min;
1210   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1211   return $self->search(undef, $attrs);
1212   #my $slice = (ref $self)->new($self->result_source, $attrs);
1213   #return (wantarray ? $slice->all : $slice);
1214 }
1215
1216 =head2 next
1217
1218 =over 4
1219
1220 =item Arguments: none
1221
1222 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1223
1224 =back
1225
1226 Returns the next element in the resultset (C<undef> is there is none).
1227
1228 Can be used to efficiently iterate over records in the resultset:
1229
1230   my $rs = $schema->resultset('CD')->search;
1231   while (my $cd = $rs->next) {
1232     print $cd->title;
1233   }
1234
1235 Note that you need to store the resultset object, and call C<next> on it.
1236 Calling C<< resultset('Table')->next >> repeatedly will always return the
1237 first record from the resultset.
1238
1239 =cut
1240
1241 sub next {
1242   my ($self) = @_;
1243
1244   if (my $cache = $self->get_cache) {
1245     $self->{all_cache_position} ||= 0;
1246     return $cache->[$self->{all_cache_position}++];
1247   }
1248
1249   if ($self->{attrs}{cache}) {
1250     delete $self->{pager};
1251     $self->{all_cache_position} = 1;
1252     return ($self->all)[0];
1253   }
1254
1255   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1256
1257   $self->{_stashed_results} = $self->_construct_results
1258     or return undef;
1259
1260   return shift @{$self->{_stashed_results}};
1261 }
1262
1263 # Constructs as many results as it can in one pass while respecting
1264 # cursor laziness. Several modes of operation:
1265 #
1266 # * Always builds everything present in @{$self->{_stashed_rows}}
1267 # * If called with $fetch_all true - pulls everything off the cursor and
1268 #   builds all result structures (or objects) in one pass
1269 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1270 #   and if the resultset is ordered properly by the left side:
1271 #   * Fetches stuff off the cursor until the "master object" changes,
1272 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1273 #   OR
1274 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1275 #     was requested (there is no other way to collapse except for an
1276 #     eager cursor)
1277 # * If no collapse is requested - just get the next row, construct and
1278 #   return
1279 sub _construct_results {
1280   my ($self, $fetch_all) = @_;
1281
1282   my $rsrc = $self->result_source;
1283   my $attrs = $self->_resolved_attrs;
1284
1285   if (
1286     ! $fetch_all
1287       and
1288     ! $attrs->{order_by}
1289       and
1290     $attrs->{collapse}
1291       and
1292     my @pcols = $rsrc->primary_columns
1293   ) {
1294     # default order for collapsing unless the user asked for something
1295     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1296     $attrs->{_ordered_for_collapse} = 1;
1297     $attrs->{_order_is_artificial} = 1;
1298   }
1299
1300   my $cursor = $self->cursor;
1301
1302   # this will be used as both initial raw-row collector AND as a RV of
1303   # _construct_results. Not regrowing the array twice matters a lot...
1304   # a surprising amount actually
1305   my $rows = delete $self->{_stashed_rows};
1306
1307   my $did_fetch_all = $fetch_all;
1308
1309   if ($fetch_all) {
1310     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1311     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1312   }
1313   elsif( $attrs->{collapse} ) {
1314
1315     $attrs->{_ordered_for_collapse} = (
1316       (
1317         $attrs->{order_by}
1318           and
1319         $rsrc->schema
1320               ->storage
1321                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1322       ) ? 1 : 0
1323     ) unless defined $attrs->{_ordered_for_collapse};
1324
1325     if (! $attrs->{_ordered_for_collapse}) {
1326       $did_fetch_all = 1;
1327
1328       # instead of looping over ->next, use ->all in stealth mode
1329       # *without* calling a ->reset afterwards
1330       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1331       if (! $cursor->{_done}) {
1332         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1333         $cursor->{_done} = 1;
1334       }
1335     }
1336   }
1337
1338   if (! $did_fetch_all and ! @{$rows||[]} ) {
1339     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1340     if (scalar (my @r = $cursor->next) ) {
1341       $rows = [ \@r ];
1342     }
1343   }
1344
1345   return undef unless @{$rows||[]};
1346
1347   my @extra_collapser_args;
1348   if ($attrs->{collapse} and ! $did_fetch_all ) {
1349
1350     @extra_collapser_args = (
1351       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1352       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1353       ($self->{_stashed_rows} = []),                # where does it stuff excess
1354     );
1355   }
1356
1357   # hotspot - skip the setter
1358   my $res_class = $self->_result_class;
1359
1360   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1361     $res_class->can ('inflate_result')
1362       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1363   };
1364
1365   my $infmap = $attrs->{as};
1366
1367
1368   $self->{_result_inflator}{is_core_row} = ( (
1369     $inflator_cref
1370       ==
1371     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1372   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1373
1374   $self->{_result_inflator}{is_hri} = ( (
1375     ! $self->{_result_inflator}{is_core_row}
1376       and
1377     $inflator_cref == (
1378       require DBIx::Class::ResultClass::HashRefInflator
1379         &&
1380       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1381     )
1382   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1383
1384
1385   if (! $attrs->{_related_results_construction}) {
1386     # construct a much simpler array->hash folder for the one-table cases right here
1387     if ($self->{_result_inflator}{is_hri}) {
1388       for my $r (@$rows) {
1389         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1390       }
1391     }
1392     # FIXME SUBOPTIMAL this is a very very very hot spot
1393     # while rather optimal we can *still* do much better, by
1394     # building a smarter Row::inflate_result(), and
1395     # switch to feeding it data via a much leaner interface
1396     #
1397     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1398     # this particular resultset size
1399     elsif (@$rows < 60) {
1400       for my $r (@$rows) {
1401         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1402       }
1403     }
1404     else {
1405       eval sprintf (
1406         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1407         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1408       );
1409     }
1410   }
1411   # Special-case multi-object HRI (we always prune, and there is no $inflator_cref pass)
1412   elsif ($self->{_result_inflator}{is_hri}) {
1413     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1414       eval => 1,
1415       inflate_map => $infmap,
1416       selection => $attrs->{select},
1417       collapse => $attrs->{collapse},
1418       premultiplied => $attrs->{_main_source_premultiplied},
1419       hri_style => 1,
1420       prune_null_branches => 1,
1421     }) )->($rows, @extra_collapser_args);
1422   }
1423   # Regular multi-object
1424   else {
1425     my $parser_type = $self->{_result_inflator}{is_core_row} ? 'classic_pruning' : 'classic_nonpruning';
1426
1427     ( $self->{_row_parser}{$parser_type} ||= $rsrc->_mk_row_parser({
1428       eval => 1,
1429       inflate_map => $infmap,
1430       selection => $attrs->{select},
1431       collapse => $attrs->{collapse},
1432       premultiplied => $attrs->{_main_source_premultiplied},
1433       prune_null_branches => $self->{_result_inflator}{is_core_row},
1434     }) )->($rows, @extra_collapser_args);
1435
1436     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1437   }
1438
1439   # The @$rows check seems odd at first - why wouldn't we want to warn
1440   # regardless? The issue is things like find() etc, where the user
1441   # *knows* only one result will come back. In these cases the ->all
1442   # is not a pessimization, but rather something we actually want
1443   carp_unique(
1444     'Unable to properly collapse has_many results in iterator mode due '
1445   . 'to order criteria - performed an eager cursor slurp underneath. '
1446   . 'Consider using ->all() instead'
1447   ) if ( ! $fetch_all and @$rows > 1 );
1448
1449   return $rows;
1450 }
1451
1452 =head2 result_source
1453
1454 =over 4
1455
1456 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1457
1458 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1459
1460 =back
1461
1462 An accessor for the primary ResultSource object from which this ResultSet
1463 is derived.
1464
1465 =head2 result_class
1466
1467 =over 4
1468
1469 =item Arguments: $result_class?
1470
1471 =item Return Value: $result_class
1472
1473 =back
1474
1475 An accessor for the class to use when creating result objects. Defaults to
1476 C<< result_source->result_class >> - which in most cases is the name of the
1477 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1478
1479 Note that changing the result_class will also remove any components
1480 that were originally loaded in the source class via
1481 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1482 in the original source class will not run.
1483
1484 =cut
1485
1486 sub result_class {
1487   my ($self, $result_class) = @_;
1488   if ($result_class) {
1489
1490     # don't fire this for an object
1491     $self->ensure_class_loaded($result_class)
1492       unless ref($result_class);
1493
1494     if ($self->get_cache) {
1495       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1496     }
1497     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1498     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1499       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1500     }
1501
1502     $self->_result_class($result_class);
1503
1504     delete $self->{_result_inflator};
1505   }
1506   $self->_result_class;
1507 }
1508
1509 =head2 count
1510
1511 =over 4
1512
1513 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1514
1515 =item Return Value: $count
1516
1517 =back
1518
1519 Performs an SQL C<COUNT> with the same query as the resultset was built
1520 with to find the number of elements. Passing arguments is equivalent to
1521 C<< $rs->search ($cond, \%attrs)->count >>
1522
1523 =cut
1524
1525 sub count {
1526   my $self = shift;
1527   return $self->search(@_)->count if @_ and defined $_[0];
1528   return scalar @{ $self->get_cache } if $self->get_cache;
1529
1530   my $attrs = { %{ $self->_resolved_attrs } };
1531
1532   # this is a little optimization - it is faster to do the limit
1533   # adjustments in software, instead of a subquery
1534   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1535
1536   my $crs;
1537   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1538     $crs = $self->_count_subq_rs ($attrs);
1539   }
1540   else {
1541     $crs = $self->_count_rs ($attrs);
1542   }
1543   my $count = $crs->next;
1544
1545   $count -= $offset if $offset;
1546   $count = $rows if $rows and $rows < $count;
1547   $count = 0 if ($count < 0);
1548
1549   return $count;
1550 }
1551
1552 =head2 count_rs
1553
1554 =over 4
1555
1556 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1557
1558 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1559
1560 =back
1561
1562 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1563 This can be very handy for subqueries:
1564
1565   ->search( { amount => $some_rs->count_rs->as_query } )
1566
1567 As with regular resultsets the SQL query will be executed only after
1568 the resultset is accessed via L</next> or L</all>. That would return
1569 the same single value obtainable via L</count>.
1570
1571 =cut
1572
1573 sub count_rs {
1574   my $self = shift;
1575   return $self->search(@_)->count_rs if @_;
1576
1577   # this may look like a lack of abstraction (count() does about the same)
1578   # but in fact an _rs *must* use a subquery for the limits, as the
1579   # software based limiting can not be ported if this $rs is to be used
1580   # in a subquery itself (i.e. ->as_query)
1581   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1582     return $self->_count_subq_rs;
1583   }
1584   else {
1585     return $self->_count_rs;
1586   }
1587 }
1588
1589 #
1590 # returns a ResultSetColumn object tied to the count query
1591 #
1592 sub _count_rs {
1593   my ($self, $attrs) = @_;
1594
1595   my $rsrc = $self->result_source;
1596   $attrs ||= $self->_resolved_attrs;
1597
1598   my $tmp_attrs = { %$attrs };
1599   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1600   delete @{$tmp_attrs}{qw/rows offset order_by _related_results_construction record_filter for/};
1601
1602   # overwrite the selector (supplied by the storage)
1603   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1604   $tmp_attrs->{as} = 'count';
1605
1606   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1607
1608   return $tmp_rs;
1609 }
1610
1611 #
1612 # same as above but uses a subquery
1613 #
1614 sub _count_subq_rs {
1615   my ($self, $attrs) = @_;
1616
1617   my $rsrc = $self->result_source;
1618   $attrs ||= $self->_resolved_attrs;
1619
1620   my $sub_attrs = { %$attrs };
1621   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1622   delete @{$sub_attrs}{qw/collapse columns as select _related_results_construction order_by for/};
1623
1624   # if we multi-prefetch we group_by something unique, as this is what we would
1625   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1626   if ( $attrs->{collapse}  ) {
1627     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1628       $rsrc->_identifying_column_set || $self->throw_exception(
1629         'Unable to construct a unique group_by criteria properly collapsing the '
1630       . 'has_many prefetch before count()'
1631       );
1632     } ]
1633   }
1634
1635   # Calculate subquery selector
1636   if (my $g = $sub_attrs->{group_by}) {
1637
1638     my $sql_maker = $rsrc->storage->sql_maker;
1639
1640     # necessary as the group_by may refer to aliased functions
1641     my $sel_index;
1642     for my $sel (@{$attrs->{select}}) {
1643       $sel_index->{$sel->{-as}} = $sel
1644         if (ref $sel eq 'HASH' and $sel->{-as});
1645     }
1646
1647     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1648     # also look for named aggregates referred in the having clause
1649     # having often contains scalarrefs - thus parse it out entirely
1650     my @parts = @$g;
1651     if ($attrs->{having}) {
1652       local $sql_maker->{having_bind};
1653       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1654       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1655       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1656         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1657         # if we don't unset it we screw up retarded but unfortunately working
1658         # 'MAX(foo.bar)' => { '>', 3 }
1659         $sql_maker->{name_sep} = '';
1660       }
1661
1662       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1663
1664       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1665       my %seen_having;
1666
1667       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1668       # and if all fails for an utterly naive quoted scalar-with-function
1669       while ($having_sql =~ /
1670         $rquote $sep $lquote (.+?) $rquote
1671           |
1672         [\s,] \w+ \. (\w+) [\s,]
1673           |
1674         [\s,] $lquote (.+?) $rquote [\s,]
1675       /gx) {
1676         my $part = $1 || $2 || $3;  # one of them matched if we got here
1677         unless ($seen_having{$part}++) {
1678           push @parts, $part;
1679         }
1680       }
1681     }
1682
1683     for (@parts) {
1684       my $colpiece = $sel_index->{$_} || $_;
1685
1686       # unqualify join-based group_by's. Arcane but possible query
1687       # also horrible horrible hack to alias a column (not a func.)
1688       # (probably need to introduce SQLA syntax)
1689       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1690         my $as = $colpiece;
1691         $as =~ s/\./__/;
1692         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1693       }
1694       push @{$sub_attrs->{select}}, $colpiece;
1695     }
1696   }
1697   else {
1698     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1699     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1700   }
1701
1702   return $rsrc->resultset_class
1703                ->new ($rsrc, $sub_attrs)
1704                 ->as_subselect_rs
1705                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1706                   ->get_column ('count');
1707 }
1708
1709
1710 =head2 count_literal
1711
1712 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1713 should only be used in that context. See L</search_literal> for further info.
1714
1715 =over 4
1716
1717 =item Arguments: $sql_fragment, @standalone_bind_values
1718
1719 =item Return Value: $count
1720
1721 =back
1722
1723 Counts the results in a literal query. Equivalent to calling L</search_literal>
1724 with the passed arguments, then L</count>.
1725
1726 =cut
1727
1728 sub count_literal { shift->search_literal(@_)->count; }
1729
1730 =head2 all
1731
1732 =over 4
1733
1734 =item Arguments: none
1735
1736 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1737
1738 =back
1739
1740 Returns all elements in the resultset.
1741
1742 =cut
1743
1744 sub all {
1745   my $self = shift;
1746   if(@_) {
1747     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1748   }
1749
1750   delete @{$self}{qw/_stashed_rows _stashed_results/};
1751
1752   if (my $c = $self->get_cache) {
1753     return @$c;
1754   }
1755
1756   $self->cursor->reset;
1757
1758   my $objs = $self->_construct_results('fetch_all') || [];
1759
1760   $self->set_cache($objs) if $self->{attrs}{cache};
1761
1762   return @$objs;
1763 }
1764
1765 =head2 reset
1766
1767 =over 4
1768
1769 =item Arguments: none
1770
1771 =item Return Value: $self
1772
1773 =back
1774
1775 Resets the resultset's cursor, so you can iterate through the elements again.
1776 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1777 another query.
1778
1779 =cut
1780
1781 sub reset {
1782   my ($self) = @_;
1783
1784   delete @{$self}{qw/_stashed_rows _stashed_results/};
1785   $self->{all_cache_position} = 0;
1786   $self->cursor->reset;
1787   return $self;
1788 }
1789
1790 =head2 first
1791
1792 =over 4
1793
1794 =item Arguments: none
1795
1796 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1797
1798 =back
1799
1800 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1801 an object for the first result (or C<undef> if the resultset is empty).
1802
1803 =cut
1804
1805 sub first {
1806   return $_[0]->reset->next;
1807 }
1808
1809
1810 # _rs_update_delete
1811 #
1812 # Determines whether and what type of subquery is required for the $rs operation.
1813 # If grouping is necessary either supplies its own, or verifies the current one
1814 # After all is done delegates to the proper storage method.
1815
1816 sub _rs_update_delete {
1817   my ($self, $op, $values) = @_;
1818
1819   my $rsrc = $self->result_source;
1820   my $storage = $rsrc->schema->storage;
1821
1822   my $attrs = { %{$self->_resolved_attrs} };
1823
1824   my $join_classifications;
1825   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1826
1827   # do we need a subquery for any reason?
1828   my $needs_subq = (
1829     defined $existing_group_by
1830       or
1831     # if {from} is unparseable wrap a subq
1832     ref($attrs->{from}) ne 'ARRAY'
1833       or
1834     # limits call for a subq
1835     $self->_has_resolved_attr(qw/rows offset/)
1836   );
1837
1838   # simplify the joinmap, so we can further decide if a subq is necessary
1839   if (!$needs_subq and @{$attrs->{from}} > 1) {
1840     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1841
1842     # check if there are any joins left after the prune
1843     if ( @{$attrs->{from}} > 1 ) {
1844       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1845         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1846         $attrs->{select},
1847         $self->{cond},
1848         $attrs
1849       );
1850
1851       # any non-pruneable joins imply subq
1852       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1853     }
1854   }
1855
1856   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1857   $needs_subq ||= (
1858     (ref $attrs->{from}[0]) ne 'HASH'
1859       or
1860     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1861   );
1862
1863   my ($cond, $guard);
1864   # do we need anything like a subquery?
1865   if (! $needs_subq) {
1866     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1867     # a condition containing 'me' or other table prefixes will not work
1868     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1869     $cond = do {
1870       my $sqla = $rsrc->storage->sql_maker;
1871       local $sqla->{_dequalify_idents} = 1;
1872       \[ $sqla->_recurse_where($self->{cond}) ];
1873     };
1874   }
1875   else {
1876     # we got this far - means it is time to wrap a subquery
1877     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1878       sprintf(
1879         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1880         $op,
1881         $rsrc->source_name,
1882       )
1883     );
1884
1885     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1886     delete $attrs->{$_} for qw/select as collapse _related_results_construction/;
1887     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1888
1889     # this will be consumed by the pruner waaaaay down the stack
1890     $attrs->{_force_prune_multiplying_joins} = 1;
1891
1892     my $subrs = (ref $self)->new($rsrc, $attrs);
1893
1894     if (@$idcols == 1) {
1895       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1896     }
1897     elsif ($storage->_use_multicolumn_in) {
1898       # no syntax for calling this properly yet
1899       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1900       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1901         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1902         $subrs->as_query
1903       ),
1904     }
1905     else {
1906       # if all else fails - get all primary keys and operate over a ORed set
1907       # wrap in a transaction for consistency
1908       # this is where the group_by/multiplication starts to matter
1909       if (
1910         $existing_group_by
1911           or
1912         keys %{ $join_classifications->{multiplying} || {} }
1913       ) {
1914         # make sure if there is a supplied group_by it matches the columns compiled above
1915         # perfectly. Anything else can not be sanely executed on most databases so croak
1916         # right then and there
1917         if ($existing_group_by) {
1918           my @current_group_by = map
1919             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1920             @$existing_group_by
1921           ;
1922
1923           if (
1924             join ("\x00", sort @current_group_by)
1925               ne
1926             join ("\x00", sort @{$attrs->{columns}} )
1927           ) {
1928             $self->throw_exception (
1929               "You have just attempted a $op operation on a resultset which does group_by"
1930               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1931               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1932               . ' kind of queries. Please retry the operation with a modified group_by or'
1933               . ' without using one at all.'
1934             );
1935           }
1936         }
1937
1938         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1939       }
1940
1941       $guard = $storage->txn_scope_guard;
1942
1943       $cond = [];
1944       for my $row ($subrs->cursor->all) {
1945         push @$cond, { map
1946           { $idcols->[$_] => $row->[$_] }
1947           (0 .. $#$idcols)
1948         };
1949       }
1950     }
1951   }
1952
1953   my $res = $storage->$op (
1954     $rsrc,
1955     $op eq 'update' ? $values : (),
1956     $cond,
1957   );
1958
1959   $guard->commit if $guard;
1960
1961   return $res;
1962 }
1963
1964 =head2 update
1965
1966 =over 4
1967
1968 =item Arguments: \%values
1969
1970 =item Return Value: $underlying_storage_rv
1971
1972 =back
1973
1974 Sets the specified columns in the resultset to the supplied values in a
1975 single query. Note that this will not run any accessor/set_column/update
1976 triggers, nor will it update any result object instances derived from this
1977 resultset (this includes the contents of the L<resultset cache|/set_cache>
1978 if any). See L</update_all> if you need to execute any on-update
1979 triggers or cascades defined either by you or a
1980 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1981
1982 The return value is a pass through of what the underlying
1983 storage backend returned, and may vary. See L<DBI/execute> for the most
1984 common case.
1985
1986 =head3 CAVEAT
1987
1988 Note that L</update> does not process/deflate any of the values passed in.
1989 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1990 ensure manually that any value passed to this method will stringify to
1991 something the RDBMS knows how to deal with. A notable example is the
1992 handling of L<DateTime> objects, for more info see:
1993 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1994
1995 =cut
1996
1997 sub update {
1998   my ($self, $values) = @_;
1999   $self->throw_exception('Values for update must be a hash')
2000     unless ref $values eq 'HASH';
2001
2002   return $self->_rs_update_delete ('update', $values);
2003 }
2004
2005 =head2 update_all
2006
2007 =over 4
2008
2009 =item Arguments: \%values
2010
2011 =item Return Value: 1
2012
2013 =back
2014
2015 Fetches all objects and updates them one at a time via
2016 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2017 triggers, while L</update> will not.
2018
2019 =cut
2020
2021 sub update_all {
2022   my ($self, $values) = @_;
2023   $self->throw_exception('Values for update_all must be a hash')
2024     unless ref $values eq 'HASH';
2025
2026   my $guard = $self->result_source->schema->txn_scope_guard;
2027   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2028   $guard->commit;
2029   return 1;
2030 }
2031
2032 =head2 delete
2033
2034 =over 4
2035
2036 =item Arguments: none
2037
2038 =item Return Value: $underlying_storage_rv
2039
2040 =back
2041
2042 Deletes the rows matching this resultset in a single query. Note that this
2043 will not run any delete triggers, nor will it alter the
2044 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2045 derived from this resultset (this includes the contents of the
2046 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2047 execute any on-delete triggers or cascades defined either by you or a
2048 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2049
2050 The return value is a pass through of what the underlying storage backend
2051 returned, and may vary. See L<DBI/execute> for the most common case.
2052
2053 =cut
2054
2055 sub delete {
2056   my $self = shift;
2057   $self->throw_exception('delete does not accept any arguments')
2058     if @_;
2059
2060   return $self->_rs_update_delete ('delete');
2061 }
2062
2063 =head2 delete_all
2064
2065 =over 4
2066
2067 =item Arguments: none
2068
2069 =item Return Value: 1
2070
2071 =back
2072
2073 Fetches all objects and deletes them one at a time via
2074 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2075 triggers, while L</delete> will not.
2076
2077 =cut
2078
2079 sub delete_all {
2080   my $self = shift;
2081   $self->throw_exception('delete_all does not accept any arguments')
2082     if @_;
2083
2084   my $guard = $self->result_source->schema->txn_scope_guard;
2085   $_->delete for $self->all;
2086   $guard->commit;
2087   return 1;
2088 }
2089
2090 =head2 populate
2091
2092 =over 4
2093
2094 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2095
2096 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2097
2098 =back
2099
2100 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2101 arrayrefs.
2102
2103 =over
2104
2105 =item NOTE
2106
2107 The context of this method call has an important effect on what is
2108 submitted to storage. In void context data is fed directly to fastpath
2109 insertion routines provided by the underlying storage (most often
2110 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2111 L<insert|DBIx::Class::Row/insert> calls on the
2112 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2113 augmentation of these methods provided by components. For example if you
2114 are using something like L<DBIx::Class::UUIDColumns> to create primary
2115 keys for you, you will find that your PKs are empty.  In this case you
2116 will have to explicitly force scalar or list context in order to create
2117 those values.
2118
2119 =back
2120
2121 In non-void (scalar or list) context, this method is simply a wrapper
2122 for L</create>. Depending on list or scalar context either a list of
2123 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2124 containing these objects is returned.
2125
2126 When supplying data in "arrayref of arrayrefs" invocation style, the
2127 first element should be a list of column names and each subsequent
2128 element should be a data value in the earlier specified column order.
2129 For example:
2130
2131   $Arstist_rs->populate([
2132     [ qw( artistid name ) ],
2133     [ 100, 'A Formally Unknown Singer' ],
2134     [ 101, 'A singer that jumped the shark two albums ago' ],
2135     [ 102, 'An actually cool singer' ],
2136   ]);
2137
2138 For the arrayref of hashrefs style each hashref should be a structure
2139 suitable for passing to L</create>. Multi-create is also permitted with
2140 this syntax.
2141
2142   $schema->resultset("Artist")->populate([
2143      { artistid => 4, name => 'Manufactured Crap', cds => [
2144         { title => 'My First CD', year => 2006 },
2145         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2146       ],
2147      },
2148      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2149         { title => 'My parents sold me to a record company', year => 2005 },
2150         { title => 'Why Am I So Ugly?', year => 2006 },
2151         { title => 'I Got Surgery and am now Popular', year => 2007 }
2152       ],
2153      },
2154   ]);
2155
2156 If you attempt a void-context multi-create as in the example above (each
2157 Artist also has the related list of CDs), and B<do not> supply the
2158 necessary autoinc foreign key information, this method will proxy to the
2159 less efficient L</create>, and then throw the Result objects away. In this
2160 case there are obviously no benefits to using this method over L</create>.
2161
2162 =cut
2163
2164 sub populate {
2165   my $self = shift;
2166
2167   # cruft placed in standalone method
2168   my $data = $self->_normalize_populate_args(@_);
2169
2170   return unless @$data;
2171
2172   if(defined wantarray) {
2173     my @created = map { $self->create($_) } @$data;
2174     return wantarray ? @created : \@created;
2175   }
2176   else {
2177     my $first = $data->[0];
2178
2179     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2180     # it relationship data
2181     my (@rels, @columns);
2182     my $rsrc = $self->result_source;
2183     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2184     for (keys %$first) {
2185       my $ref = ref $first->{$_};
2186       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2187         ? push @rels, $_
2188         : push @columns, $_
2189       ;
2190     }
2191
2192     my @pks = $rsrc->primary_columns;
2193
2194     ## do the belongs_to relationships
2195     foreach my $index (0..$#$data) {
2196
2197       # delegate to create() for any dataset without primary keys with specified relationships
2198       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2199         for my $r (@rels) {
2200           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2201             my @ret = $self->populate($data);
2202             return;
2203           }
2204         }
2205       }
2206
2207       foreach my $rel (@rels) {
2208         next unless ref $data->[$index]->{$rel} eq "HASH";
2209         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2210         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2211         my $related = $result->result_source->_resolve_condition(
2212           $reverse_relinfo->{cond},
2213           $self,
2214           $result,
2215           $rel,
2216         );
2217
2218         delete $data->[$index]->{$rel};
2219         $data->[$index] = {%{$data->[$index]}, %$related};
2220
2221         push @columns, keys %$related if $index == 0;
2222       }
2223     }
2224
2225     ## inherit the data locked in the conditions of the resultset
2226     my ($rs_data) = $self->_merge_with_rscond({});
2227     delete @{$rs_data}{@columns};
2228
2229     ## do bulk insert on current row
2230     $rsrc->storage->insert_bulk(
2231       $rsrc,
2232       [@columns, keys %$rs_data],
2233       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2234     );
2235
2236     ## do the has_many relationships
2237     foreach my $item (@$data) {
2238
2239       my $main_row;
2240
2241       foreach my $rel (@rels) {
2242         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2243
2244         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2245
2246         my $child = $main_row->$rel;
2247
2248         my $related = $child->result_source->_resolve_condition(
2249           $rels->{$rel}{cond},
2250           $child,
2251           $main_row,
2252           $rel,
2253         );
2254
2255         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2256         my @populate = map { {%$_, %$related} } @rows_to_add;
2257
2258         $child->populate( \@populate );
2259       }
2260     }
2261   }
2262 }
2263
2264
2265 # populate() argumnets went over several incarnations
2266 # What we ultimately support is AoH
2267 sub _normalize_populate_args {
2268   my ($self, $arg) = @_;
2269
2270   if (ref $arg eq 'ARRAY') {
2271     if (!@$arg) {
2272       return [];
2273     }
2274     elsif (ref $arg->[0] eq 'HASH') {
2275       return $arg;
2276     }
2277     elsif (ref $arg->[0] eq 'ARRAY') {
2278       my @ret;
2279       my @colnames = @{$arg->[0]};
2280       foreach my $values (@{$arg}[1 .. $#$arg]) {
2281         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2282       }
2283       return \@ret;
2284     }
2285   }
2286
2287   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2288 }
2289
2290 =head2 pager
2291
2292 =over 4
2293
2294 =item Arguments: none
2295
2296 =item Return Value: L<$pager|Data::Page>
2297
2298 =back
2299
2300 Returns a L<Data::Page> object for the current resultset. Only makes
2301 sense for queries with a C<page> attribute.
2302
2303 To get the full count of entries for a paged resultset, call
2304 C<total_entries> on the L<Data::Page> object.
2305
2306 =cut
2307
2308 sub pager {
2309   my ($self) = @_;
2310
2311   return $self->{pager} if $self->{pager};
2312
2313   my $attrs = $self->{attrs};
2314   if (!defined $attrs->{page}) {
2315     $self->throw_exception("Can't create pager for non-paged rs");
2316   }
2317   elsif ($attrs->{page} <= 0) {
2318     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2319   }
2320   $attrs->{rows} ||= 10;
2321
2322   # throw away the paging flags and re-run the count (possibly
2323   # with a subselect) to get the real total count
2324   my $count_attrs = { %$attrs };
2325   delete @{$count_attrs}{qw/rows offset page pager/};
2326
2327   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2328
2329   require DBIx::Class::ResultSet::Pager;
2330   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2331     sub { $total_rs->count },  #lazy-get the total
2332     $attrs->{rows},
2333     $self->{attrs}{page},
2334   );
2335 }
2336
2337 =head2 page
2338
2339 =over 4
2340
2341 =item Arguments: $page_number
2342
2343 =item Return Value: L<$resultset|/search>
2344
2345 =back
2346
2347 Returns a resultset for the $page_number page of the resultset on which page
2348 is called, where each page contains a number of rows equal to the 'rows'
2349 attribute set on the resultset (10 by default).
2350
2351 =cut
2352
2353 sub page {
2354   my ($self, $page) = @_;
2355   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2356 }
2357
2358 =head2 new_result
2359
2360 =over 4
2361
2362 =item Arguments: \%col_data
2363
2364 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2365
2366 =back
2367
2368 Creates a new result object in the resultset's result class and returns
2369 it. The row is not inserted into the database at this point, call
2370 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2371 will tell you whether the result object has been inserted or not.
2372
2373 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2374
2375 =cut
2376
2377 sub new_result {
2378   my ($self, $values) = @_;
2379
2380   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2381     if @_ > 2;
2382
2383   $self->throw_exception( "new_result expects a hashref" )
2384     unless (ref $values eq 'HASH');
2385
2386   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2387
2388   my $new = $self->result_class->new({
2389     %$merged_cond,
2390     ( @$cols_from_relations
2391       ? (-cols_from_relations => $cols_from_relations)
2392       : ()
2393     ),
2394     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2395   });
2396
2397   if (
2398     reftype($new) eq 'HASH'
2399       and
2400     ! keys %$new
2401       and
2402     blessed($new)
2403   ) {
2404     carp_unique (sprintf (
2405       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2406       $self->result_class,
2407     ));
2408   }
2409
2410   $new;
2411 }
2412
2413 # _merge_with_rscond
2414 #
2415 # Takes a simple hash of K/V data and returns its copy merged with the
2416 # condition already present on the resultset. Additionally returns an
2417 # arrayref of value/condition names, which were inferred from related
2418 # objects (this is needed for in-memory related objects)
2419 sub _merge_with_rscond {
2420   my ($self, $data) = @_;
2421
2422   my (%new_data, @cols_from_relations);
2423
2424   my $alias = $self->{attrs}{alias};
2425
2426   if (! defined $self->{cond}) {
2427     # just massage $data below
2428   }
2429   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2430     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2431     @cols_from_relations = keys %new_data;
2432   }
2433   elsif (ref $self->{cond} ne 'HASH') {
2434     $self->throw_exception(
2435       "Can't abstract implicit construct, resultset condition not a hash"
2436     );
2437   }
2438   else {
2439     # precendence must be given to passed values over values inherited from
2440     # the cond, so the order here is important.
2441     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2442     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2443
2444     while ( my($col, $value) = each %implied ) {
2445       my $vref = ref $value;
2446       if (
2447         $vref eq 'HASH'
2448           and
2449         keys(%$value) == 1
2450           and
2451         (keys %$value)[0] eq '='
2452       ) {
2453         $new_data{$col} = $value->{'='};
2454       }
2455       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2456         $new_data{$col} = $value;
2457       }
2458     }
2459   }
2460
2461   %new_data = (
2462     %new_data,
2463     %{ $self->_remove_alias($data, $alias) },
2464   );
2465
2466   return (\%new_data, \@cols_from_relations);
2467 }
2468
2469 # _has_resolved_attr
2470 #
2471 # determines if the resultset defines at least one
2472 # of the attributes supplied
2473 #
2474 # used to determine if a subquery is neccessary
2475 #
2476 # supports some virtual attributes:
2477 #   -join
2478 #     This will scan for any joins being present on the resultset.
2479 #     It is not a mere key-search but a deep inspection of {from}
2480 #
2481
2482 sub _has_resolved_attr {
2483   my ($self, @attr_names) = @_;
2484
2485   my $attrs = $self->_resolved_attrs;
2486
2487   my %extra_checks;
2488
2489   for my $n (@attr_names) {
2490     if (grep { $n eq $_ } (qw/-join/) ) {
2491       $extra_checks{$n}++;
2492       next;
2493     }
2494
2495     my $attr =  $attrs->{$n};
2496
2497     next if not defined $attr;
2498
2499     if (ref $attr eq 'HASH') {
2500       return 1 if keys %$attr;
2501     }
2502     elsif (ref $attr eq 'ARRAY') {
2503       return 1 if @$attr;
2504     }
2505     else {
2506       return 1 if $attr;
2507     }
2508   }
2509
2510   # a resolved join is expressed as a multi-level from
2511   return 1 if (
2512     $extra_checks{-join}
2513       and
2514     ref $attrs->{from} eq 'ARRAY'
2515       and
2516     @{$attrs->{from}} > 1
2517   );
2518
2519   return 0;
2520 }
2521
2522 # _collapse_cond
2523 #
2524 # Recursively collapse the condition.
2525
2526 sub _collapse_cond {
2527   my ($self, $cond, $collapsed) = @_;
2528
2529   $collapsed ||= {};
2530
2531   if (ref $cond eq 'ARRAY') {
2532     foreach my $subcond (@$cond) {
2533       next unless ref $subcond;  # -or
2534       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2535     }
2536   }
2537   elsif (ref $cond eq 'HASH') {
2538     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2539       foreach my $subcond (@{$cond->{-and}}) {
2540         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2541       }
2542     }
2543     else {
2544       foreach my $col (keys %$cond) {
2545         my $value = $cond->{$col};
2546         $collapsed->{$col} = $value;
2547       }
2548     }
2549   }
2550
2551   return $collapsed;
2552 }
2553
2554 # _remove_alias
2555 #
2556 # Remove the specified alias from the specified query hash. A copy is made so
2557 # the original query is not modified.
2558
2559 sub _remove_alias {
2560   my ($self, $query, $alias) = @_;
2561
2562   my %orig = %{ $query || {} };
2563   my %unaliased;
2564
2565   foreach my $key (keys %orig) {
2566     if ($key !~ /\./) {
2567       $unaliased{$key} = $orig{$key};
2568       next;
2569     }
2570     $unaliased{$1} = $orig{$key}
2571       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2572   }
2573
2574   return \%unaliased;
2575 }
2576
2577 =head2 as_query
2578
2579 =over 4
2580
2581 =item Arguments: none
2582
2583 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2584
2585 =back
2586
2587 Returns the SQL query and bind vars associated with the invocant.
2588
2589 This is generally used as the RHS for a subquery.
2590
2591 =cut
2592
2593 sub as_query {
2594   my $self = shift;
2595
2596   my $attrs = { %{ $self->_resolved_attrs } };
2597
2598   $self->result_source->storage->_select_args_to_query (
2599     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2600   );
2601 }
2602
2603 =head2 find_or_new
2604
2605 =over 4
2606
2607 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2608
2609 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2610
2611 =back
2612
2613   my $artist = $schema->resultset('Artist')->find_or_new(
2614     { artist => 'fred' }, { key => 'artists' });
2615
2616   $cd->cd_to_producer->find_or_new({ producer => $producer },
2617                                    { key => 'primary });
2618
2619 Find an existing record from this resultset using L</find>. if none exists,
2620 instantiate a new result object and return it. The object will not be saved
2621 into your storage until you call L<DBIx::Class::Row/insert> on it.
2622
2623 You most likely want this method when looking for existing rows using a unique
2624 constraint that is not the primary key, or looking for related rows.
2625
2626 If you want objects to be saved immediately, use L</find_or_create> instead.
2627
2628 B<Note>: Make sure to read the documentation of L</find> and understand the
2629 significance of the C<key> attribute, as its lack may skew your search, and
2630 subsequently result in spurious new objects.
2631
2632 B<Note>: Take care when using C<find_or_new> with a table having
2633 columns with default values that you intend to be automatically
2634 supplied by the database (e.g. an auto_increment primary key column).
2635 In normal usage, the value of such columns should NOT be included at
2636 all in the call to C<find_or_new>, even when set to C<undef>.
2637
2638 =cut
2639
2640 sub find_or_new {
2641   my $self     = shift;
2642   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2643   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2644   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2645     return $row;
2646   }
2647   return $self->new_result($hash);
2648 }
2649
2650 =head2 create
2651
2652 =over 4
2653
2654 =item Arguments: \%col_data
2655
2656 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2657
2658 =back
2659
2660 Attempt to create a single new row or a row with multiple related rows
2661 in the table represented by the resultset (and related tables). This
2662 will not check for duplicate rows before inserting, use
2663 L</find_or_create> to do that.
2664
2665 To create one row for this resultset, pass a hashref of key/value
2666 pairs representing the columns of the table and the values you wish to
2667 store. If the appropriate relationships are set up, foreign key fields
2668 can also be passed an object representing the foreign row, and the
2669 value will be set to its primary key.
2670
2671 To create related objects, pass a hashref of related-object column values
2672 B<keyed on the relationship name>. If the relationship is of type C<multi>
2673 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2674 The process will correctly identify columns holding foreign keys, and will
2675 transparently populate them from the keys of the corresponding relation.
2676 This can be applied recursively, and will work correctly for a structure
2677 with an arbitrary depth and width, as long as the relationships actually
2678 exists and the correct column data has been supplied.
2679
2680 Instead of hashrefs of plain related data (key/value pairs), you may
2681 also pass new or inserted objects. New objects (not inserted yet, see
2682 L</new_result>), will be inserted into their appropriate tables.
2683
2684 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2685
2686 Example of creating a new row.
2687
2688   $person_rs->create({
2689     name=>"Some Person",
2690     email=>"somebody@someplace.com"
2691   });
2692
2693 Example of creating a new row and also creating rows in a related C<has_many>
2694 or C<has_one> resultset.  Note Arrayref.
2695
2696   $artist_rs->create(
2697      { artistid => 4, name => 'Manufactured Crap', cds => [
2698         { title => 'My First CD', year => 2006 },
2699         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2700       ],
2701      },
2702   );
2703
2704 Example of creating a new row and also creating a row in a related
2705 C<belongs_to> resultset. Note Hashref.
2706
2707   $cd_rs->create({
2708     title=>"Music for Silly Walks",
2709     year=>2000,
2710     artist => {
2711       name=>"Silly Musician",
2712     }
2713   });
2714
2715 =over
2716
2717 =item WARNING
2718
2719 When subclassing ResultSet never attempt to override this method. Since
2720 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2721 lot of the internals simply never call it, so your override will be
2722 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2723 or L<DBIx::Class::Row/insert> depending on how early in the
2724 L</create> process you need to intervene. See also warning pertaining to
2725 L</new>.
2726
2727 =back
2728
2729 =cut
2730
2731 sub create {
2732   my ($self, $col_data) = @_;
2733   $self->throw_exception( "create needs a hashref" )
2734     unless ref $col_data eq 'HASH';
2735   return $self->new_result($col_data)->insert;
2736 }
2737
2738 =head2 find_or_create
2739
2740 =over 4
2741
2742 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2743
2744 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2745
2746 =back
2747
2748   $cd->cd_to_producer->find_or_create({ producer => $producer },
2749                                       { key => 'primary' });
2750
2751 Tries to find a record based on its primary key or unique constraints; if none
2752 is found, creates one and returns that instead.
2753
2754   my $cd = $schema->resultset('CD')->find_or_create({
2755     cdid   => 5,
2756     artist => 'Massive Attack',
2757     title  => 'Mezzanine',
2758     year   => 2005,
2759   });
2760
2761 Also takes an optional C<key> attribute, to search by a specific key or unique
2762 constraint. For example:
2763
2764   my $cd = $schema->resultset('CD')->find_or_create(
2765     {
2766       artist => 'Massive Attack',
2767       title  => 'Mezzanine',
2768     },
2769     { key => 'cd_artist_title' }
2770   );
2771
2772 B<Note>: Make sure to read the documentation of L</find> and understand the
2773 significance of the C<key> attribute, as its lack may skew your search, and
2774 subsequently result in spurious row creation.
2775
2776 B<Note>: Because find_or_create() reads from the database and then
2777 possibly inserts based on the result, this method is subject to a race
2778 condition. Another process could create a record in the table after
2779 the find has completed and before the create has started. To avoid
2780 this problem, use find_or_create() inside a transaction.
2781
2782 B<Note>: Take care when using C<find_or_create> with a table having
2783 columns with default values that you intend to be automatically
2784 supplied by the database (e.g. an auto_increment primary key column).
2785 In normal usage, the value of such columns should NOT be included at
2786 all in the call to C<find_or_create>, even when set to C<undef>.
2787
2788 See also L</find> and L</update_or_create>. For information on how to declare
2789 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2790
2791 If you need to know if an existing row was found or a new one created use
2792 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2793 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2794 database!
2795
2796   my $cd = $schema->resultset('CD')->find_or_new({
2797     cdid   => 5,
2798     artist => 'Massive Attack',
2799     title  => 'Mezzanine',
2800     year   => 2005,
2801   });
2802
2803   if( !$cd->in_storage ) {
2804       # do some stuff
2805       $cd->insert;
2806   }
2807
2808 =cut
2809
2810 sub find_or_create {
2811   my $self     = shift;
2812   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2813   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2814   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2815     return $row;
2816   }
2817   return $self->create($hash);
2818 }
2819
2820 =head2 update_or_create
2821
2822 =over 4
2823
2824 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2825
2826 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2827
2828 =back
2829
2830   $resultset->update_or_create({ col => $val, ... });
2831
2832 Like L</find_or_create>, but if a row is found it is immediately updated via
2833 C<< $found_row->update (\%col_data) >>.
2834
2835
2836 Takes an optional C<key> attribute to search on a specific unique constraint.
2837 For example:
2838
2839   # In your application
2840   my $cd = $schema->resultset('CD')->update_or_create(
2841     {
2842       artist => 'Massive Attack',
2843       title  => 'Mezzanine',
2844       year   => 1998,
2845     },
2846     { key => 'cd_artist_title' }
2847   );
2848
2849   $cd->cd_to_producer->update_or_create({
2850     producer => $producer,
2851     name => 'harry',
2852   }, {
2853     key => 'primary',
2854   });
2855
2856 B<Note>: Make sure to read the documentation of L</find> and understand the
2857 significance of the C<key> attribute, as its lack may skew your search, and
2858 subsequently result in spurious row creation.
2859
2860 B<Note>: Take care when using C<update_or_create> with a table having
2861 columns with default values that you intend to be automatically
2862 supplied by the database (e.g. an auto_increment primary key column).
2863 In normal usage, the value of such columns should NOT be included at
2864 all in the call to C<update_or_create>, even when set to C<undef>.
2865
2866 See also L</find> and L</find_or_create>. For information on how to declare
2867 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2868
2869 If you need to know if an existing row was updated or a new one created use
2870 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2871 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2872 database!
2873
2874 =cut
2875
2876 sub update_or_create {
2877   my $self = shift;
2878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2879   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2880
2881   my $row = $self->find($cond, $attrs);
2882   if (defined $row) {
2883     $row->update($cond);
2884     return $row;
2885   }
2886
2887   return $self->create($cond);
2888 }
2889
2890 =head2 update_or_new
2891
2892 =over 4
2893
2894 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2895
2896 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2897
2898 =back
2899
2900   $resultset->update_or_new({ col => $val, ... });
2901
2902 Like L</find_or_new> but if a row is found it is immediately updated via
2903 C<< $found_row->update (\%col_data) >>.
2904
2905 For example:
2906
2907   # In your application
2908   my $cd = $schema->resultset('CD')->update_or_new(
2909     {
2910       artist => 'Massive Attack',
2911       title  => 'Mezzanine',
2912       year   => 1998,
2913     },
2914     { key => 'cd_artist_title' }
2915   );
2916
2917   if ($cd->in_storage) {
2918       # the cd was updated
2919   }
2920   else {
2921       # the cd is not yet in the database, let's insert it
2922       $cd->insert;
2923   }
2924
2925 B<Note>: Make sure to read the documentation of L</find> and understand the
2926 significance of the C<key> attribute, as its lack may skew your search, and
2927 subsequently result in spurious new objects.
2928
2929 B<Note>: Take care when using C<update_or_new> with a table having
2930 columns with default values that you intend to be automatically
2931 supplied by the database (e.g. an auto_increment primary key column).
2932 In normal usage, the value of such columns should NOT be included at
2933 all in the call to C<update_or_new>, even when set to C<undef>.
2934
2935 See also L</find>, L</find_or_create> and L</find_or_new>.
2936
2937 =cut
2938
2939 sub update_or_new {
2940     my $self  = shift;
2941     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2942     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2943
2944     my $row = $self->find( $cond, $attrs );
2945     if ( defined $row ) {
2946         $row->update($cond);
2947         return $row;
2948     }
2949
2950     return $self->new_result($cond);
2951 }
2952
2953 =head2 get_cache
2954
2955 =over 4
2956
2957 =item Arguments: none
2958
2959 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2960
2961 =back
2962
2963 Gets the contents of the cache for the resultset, if the cache is set.
2964
2965 The cache is populated either by using the L</prefetch> attribute to
2966 L</search> or by calling L</set_cache>.
2967
2968 =cut
2969
2970 sub get_cache {
2971   shift->{all_cache};
2972 }
2973
2974 =head2 set_cache
2975
2976 =over 4
2977
2978 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2979
2980 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2981
2982 =back
2983
2984 Sets the contents of the cache for the resultset. Expects an arrayref
2985 of objects of the same class as those produced by the resultset. Note that
2986 if the cache is set, the resultset will return the cached objects rather
2987 than re-querying the database even if the cache attr is not set.
2988
2989 The contents of the cache can also be populated by using the
2990 L</prefetch> attribute to L</search>.
2991
2992 =cut
2993
2994 sub set_cache {
2995   my ( $self, $data ) = @_;
2996   $self->throw_exception("set_cache requires an arrayref")
2997       if defined($data) && (ref $data ne 'ARRAY');
2998   $self->{all_cache} = $data;
2999 }
3000
3001 =head2 clear_cache
3002
3003 =over 4
3004
3005 =item Arguments: none
3006
3007 =item Return Value: undef
3008
3009 =back
3010
3011 Clears the cache for the resultset.
3012
3013 =cut
3014
3015 sub clear_cache {
3016   shift->set_cache(undef);
3017 }
3018
3019 =head2 is_paged
3020
3021 =over 4
3022
3023 =item Arguments: none
3024
3025 =item Return Value: true, if the resultset has been paginated
3026
3027 =back
3028
3029 =cut
3030
3031 sub is_paged {
3032   my ($self) = @_;
3033   return !!$self->{attrs}{page};
3034 }
3035
3036 =head2 is_ordered
3037
3038 =over 4
3039
3040 =item Arguments: none
3041
3042 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3043
3044 =back
3045
3046 =cut
3047
3048 sub is_ordered {
3049   my ($self) = @_;
3050   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3051 }
3052
3053 =head2 related_resultset
3054
3055 =over 4
3056
3057 =item Arguments: $rel_name
3058
3059 =item Return Value: L<$resultset|/search>
3060
3061 =back
3062
3063 Returns a related resultset for the supplied relationship name.
3064
3065   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3066
3067 =cut
3068
3069 sub related_resultset {
3070   my ($self, $rel) = @_;
3071
3072   return $self->{related_resultsets}{$rel}
3073     if defined $self->{related_resultsets}{$rel};
3074
3075   return $self->{related_resultsets}{$rel} = do {
3076     my $rsrc = $self->result_source;
3077     my $rel_info = $rsrc->relationship_info($rel);
3078
3079     $self->throw_exception(
3080       "search_related: result source '" . $rsrc->source_name .
3081         "' has no such relationship $rel")
3082       unless $rel_info;
3083
3084     my $attrs = $self->_chain_relationship($rel);
3085
3086     my $join_count = $attrs->{seen_join}{$rel};
3087
3088     my $alias = $self->result_source->storage
3089         ->relname_to_table_alias($rel, $join_count);
3090
3091     # since this is search_related, and we already slid the select window inwards
3092     # (the select/as attrs were deleted in the beginning), we need to flip all
3093     # left joins to inner, so we get the expected results
3094     # read the comment on top of the actual function to see what this does
3095     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3096
3097
3098     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3099     delete @{$attrs}{qw(result_class alias)};
3100
3101     my $related_cache;
3102
3103     if (my $cache = $self->get_cache) {
3104       $related_cache = [ map
3105         { @{$_->related_resultset($rel)->get_cache||[]} }
3106         @$cache
3107       ];
3108     }
3109
3110     my $rel_source = $rsrc->related_source($rel);
3111
3112     my $new = do {
3113
3114       # The reason we do this now instead of passing the alias to the
3115       # search_rs below is that if you wrap/overload resultset on the
3116       # source you need to know what alias it's -going- to have for things
3117       # to work sanely (e.g. RestrictWithObject wants to be able to add
3118       # extra query restrictions, and these may need to be $alias.)
3119
3120       my $rel_attrs = $rel_source->resultset_attributes;
3121       local $rel_attrs->{alias} = $alias;
3122
3123       $rel_source->resultset
3124                  ->search_rs(
3125                      undef, {
3126                        %$attrs,
3127                        where => $attrs->{where},
3128                    });
3129     };
3130     $new->set_cache($related_cache) if $related_cache;
3131     $new;
3132   };
3133 }
3134
3135 =head2 current_source_alias
3136
3137 =over 4
3138
3139 =item Arguments: none
3140
3141 =item Return Value: $source_alias
3142
3143 =back
3144
3145 Returns the current table alias for the result source this resultset is built
3146 on, that will be used in the SQL query. Usually it is C<me>.
3147
3148 Currently the source alias that refers to the result set returned by a
3149 L</search>/L</find> family method depends on how you got to the resultset: it's
3150 C<me> by default, but eg. L</search_related> aliases it to the related result
3151 source name (and keeps C<me> referring to the original result set). The long
3152 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3153 (and make this method unnecessary).
3154
3155 Thus it's currently necessary to use this method in predefined queries (see
3156 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3157 source alias of the current result set:
3158
3159   # in a result set class
3160   sub modified_by {
3161     my ($self, $user) = @_;
3162
3163     my $me = $self->current_source_alias;
3164
3165     return $self->search({
3166       "$me.modified" => $user->id,
3167     });
3168   }
3169
3170 =cut
3171
3172 sub current_source_alias {
3173   return (shift->{attrs} || {})->{alias} || 'me';
3174 }
3175
3176 =head2 as_subselect_rs
3177
3178 =over 4
3179
3180 =item Arguments: none
3181
3182 =item Return Value: L<$resultset|/search>
3183
3184 =back
3185
3186 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3187 "virtual view" by including it as a subquery within the from clause.  From this
3188 point on, any joined tables are inaccessible to ->search on the resultset (as if
3189 it were simply where-filtered without joins).  For example:
3190
3191  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3192
3193  # 'x' now pollutes the query namespace
3194
3195  # So the following works as expected
3196  my $ok_rs = $rs->search({'x.other' => 1});
3197
3198  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3199  # def) we look for one row with contradictory terms and join in another table
3200  # (aliased 'x_2') which we never use
3201  my $broken_rs = $rs->search({'x.name' => 'def'});
3202
3203  my $rs2 = $rs->as_subselect_rs;
3204
3205  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3206  my $not_joined_rs = $rs2->search({'x.other' => 1});
3207
3208  # works as expected: finds a 'table' row related to two x rows (abc and def)
3209  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3210
3211 Another example of when one might use this would be to select a subset of
3212 columns in a group by clause:
3213
3214  my $rs = $schema->resultset('Bar')->search(undef, {
3215    group_by => [qw{ id foo_id baz_id }],
3216  })->as_subselect_rs->search(undef, {
3217    columns => [qw{ id foo_id }]
3218  });
3219
3220 In the above example normally columns would have to be equal to the group by,
3221 but because we isolated the group by into a subselect the above works.
3222
3223 =cut
3224
3225 sub as_subselect_rs {
3226   my $self = shift;
3227
3228   my $attrs = $self->_resolved_attrs;
3229
3230   my $fresh_rs = (ref $self)->new (
3231     $self->result_source
3232   );
3233
3234   # these pieces will be locked in the subquery
3235   delete $fresh_rs->{cond};
3236   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3237
3238   return $fresh_rs->search( {}, {
3239     from => [{
3240       $attrs->{alias} => $self->as_query,
3241       -alias  => $attrs->{alias},
3242       -rsrc   => $self->result_source,
3243     }],
3244     alias => $attrs->{alias},
3245   });
3246 }
3247
3248 # This code is called by search_related, and makes sure there
3249 # is clear separation between the joins before, during, and
3250 # after the relationship. This information is needed later
3251 # in order to properly resolve prefetch aliases (any alias
3252 # with a relation_chain_depth less than the depth of the
3253 # current prefetch is not considered)
3254 #
3255 # The increments happen twice per join. An even number means a
3256 # relationship specified via a search_related, whereas an odd
3257 # number indicates a join/prefetch added via attributes
3258 #
3259 # Also this code will wrap the current resultset (the one we
3260 # chain to) in a subselect IFF it contains limiting attributes
3261 sub _chain_relationship {
3262   my ($self, $rel) = @_;
3263   my $source = $self->result_source;
3264   my $attrs = { %{$self->{attrs}||{}} };
3265
3266   # we need to take the prefetch the attrs into account before we
3267   # ->_resolve_join as otherwise they get lost - captainL
3268   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3269
3270   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3271
3272   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3273
3274   my $from;
3275   my @force_subq_attrs = qw/offset rows group_by having/;
3276
3277   if (
3278     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3279       ||
3280     $self->_has_resolved_attr (@force_subq_attrs)
3281   ) {
3282     # Nuke the prefetch (if any) before the new $rs attrs
3283     # are resolved (prefetch is useless - we are wrapping
3284     # a subquery anyway).
3285     my $rs_copy = $self->search;
3286     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3287       $rs_copy->{attrs}{join},
3288       delete $rs_copy->{attrs}{prefetch},
3289     );
3290
3291     $from = [{
3292       -rsrc   => $source,
3293       -alias  => $attrs->{alias},
3294       $attrs->{alias} => $rs_copy->as_query,
3295     }];
3296     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3297     $seen->{-relation_chain_depth} = 0;
3298   }
3299   elsif ($attrs->{from}) {  #shallow copy suffices
3300     $from = [ @{$attrs->{from}} ];
3301   }
3302   else {
3303     $from = [{
3304       -rsrc  => $source,
3305       -alias => $attrs->{alias},
3306       $attrs->{alias} => $source->from,
3307     }];
3308   }
3309
3310   my $jpath = ($seen->{-relation_chain_depth})
3311     ? $from->[-1][0]{-join_path}
3312     : [];
3313
3314   my @requested_joins = $source->_resolve_join(
3315     $join,
3316     $attrs->{alias},
3317     $seen,
3318     $jpath,
3319   );
3320
3321   push @$from, @requested_joins;
3322
3323   $seen->{-relation_chain_depth}++;
3324
3325   # if $self already had a join/prefetch specified on it, the requested
3326   # $rel might very well be already included. What we do in this case
3327   # is effectively a no-op (except that we bump up the chain_depth on
3328   # the join in question so we could tell it *is* the search_related)
3329   my $already_joined;
3330
3331   # we consider the last one thus reverse
3332   for my $j (reverse @requested_joins) {
3333     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3334     if ($rel eq $last_j) {
3335       $j->[0]{-relation_chain_depth}++;
3336       $already_joined++;
3337       last;
3338     }
3339   }
3340
3341   unless ($already_joined) {
3342     push @$from, $source->_resolve_join(
3343       $rel,
3344       $attrs->{alias},
3345       $seen,
3346       $jpath,
3347     );
3348   }
3349
3350   $seen->{-relation_chain_depth}++;
3351
3352   return {%$attrs, from => $from, seen_join => $seen};
3353 }
3354
3355 sub _resolved_attrs {
3356   my $self = shift;
3357   return $self->{_attrs} if $self->{_attrs};
3358
3359   my $attrs  = { %{ $self->{attrs} || {} } };
3360   my $source = $self->result_source;
3361   my $alias  = $attrs->{alias};
3362
3363   # default selection list
3364   $attrs->{columns} = [ $source->columns ]
3365     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3366
3367   # merge selectors together
3368   for (qw/columns select as/) {
3369     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3370       if $attrs->{$_} or $attrs->{"+$_"};
3371   }
3372
3373   # disassemble columns
3374   my (@sel, @as);
3375   if (my $cols = delete $attrs->{columns}) {
3376     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3377       if (ref $c eq 'HASH') {
3378         for my $as (sort keys %$c) {
3379           push @sel, $c->{$as};
3380           push @as, $as;
3381         }
3382       }
3383       else {
3384         push @sel, $c;
3385         push @as, $c;
3386       }
3387     }
3388   }
3389
3390   # when trying to weed off duplicates later do not go past this point -
3391   # everything added from here on is unbalanced "anyone's guess" stuff
3392   my $dedup_stop_idx = $#as;
3393
3394   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3395     if $attrs->{as};
3396   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3397     if $attrs->{select};
3398
3399   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3400   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3401
3402   # disqualify all $alias.col as-bits (inflate-map mandated)
3403   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3404
3405   # de-duplicate the result (remove *identical* select/as pairs)
3406   # and also die on duplicate {as} pointing to different {select}s
3407   # not using a c-style for as the condition is prone to shrinkage
3408   my $seen;
3409   my $i = 0;
3410   while ($i <= $dedup_stop_idx) {
3411     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3412       splice @sel, $i, 1;
3413       splice @as, $i, 1;
3414       $dedup_stop_idx--;
3415     }
3416     elsif ($seen->{$as[$i]}++) {
3417       $self->throw_exception(
3418         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3419       );
3420     }
3421     else {
3422       $i++;
3423     }
3424   }
3425
3426   $attrs->{select} = \@sel;
3427   $attrs->{as} = \@as;
3428
3429   $attrs->{from} ||= [{
3430     -rsrc   => $source,
3431     -alias  => $self->{attrs}{alias},
3432     $self->{attrs}{alias} => $source->from,
3433   }];
3434
3435   if ( $attrs->{join} || $attrs->{prefetch} ) {
3436
3437     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3438       if ref $attrs->{from} ne 'ARRAY';
3439
3440     my $join = (delete $attrs->{join}) || {};
3441
3442     if ( defined $attrs->{prefetch} ) {
3443       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3444     }
3445
3446     $attrs->{from} =    # have to copy here to avoid corrupting the original
3447       [
3448         @{ $attrs->{from} },
3449         $source->_resolve_join(
3450           $join,
3451           $alias,
3452           { %{ $attrs->{seen_join} || {} } },
3453           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3454             ? $attrs->{from}[-1][0]{-join_path}
3455             : []
3456           ,
3457         )
3458       ];
3459   }
3460
3461   if ( defined $attrs->{order_by} ) {
3462     $attrs->{order_by} = (
3463       ref( $attrs->{order_by} ) eq 'ARRAY'
3464       ? [ @{ $attrs->{order_by} } ]
3465       : [ $attrs->{order_by} || () ]
3466     );
3467   }
3468
3469   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3470     $attrs->{group_by} = [ $attrs->{group_by} ];
3471   }
3472
3473   # generate the distinct induced group_by early, as prefetch will be carried via a
3474   # subquery (since a group_by is present)
3475   if (delete $attrs->{distinct}) {
3476     if ($attrs->{group_by}) {
3477       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3478     }
3479     else {
3480       $attrs->{_grouped_by_distinct} = 1;
3481       # distinct affects only the main selection part, not what prefetch may
3482       # add below.
3483       $attrs->{group_by} = $source->storage->_group_over_selection (
3484         $attrs->{from},
3485         $attrs->{select},
3486         $attrs->{order_by},
3487       );
3488     }
3489   }
3490
3491   # generate selections based on the prefetch helper
3492   my $prefetch;
3493   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3494     if defined $attrs->{prefetch};
3495
3496   if ($prefetch) {
3497
3498     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3499       if $attrs->{_dark_selector};
3500
3501     $attrs->{collapse} = 1;
3502
3503     # this is a separate structure (we don't look in {from} directly)
3504     # as the resolver needs to shift things off the lists to work
3505     # properly (identical-prefetches on different branches)
3506     my $join_map = {};
3507     if (ref $attrs->{from} eq 'ARRAY') {
3508
3509       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3510
3511       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3512         next unless $j->[0]{-alias};
3513         next unless $j->[0]{-join_path};
3514         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3515
3516         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3517
3518         my $p = $join_map;
3519         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3520         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3521       }
3522     }
3523
3524     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3525
3526     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3527     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3528   }
3529
3530   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3531     $attrs->{_related_results_construction} = 1;
3532   }
3533   else {
3534     $attrs->{collapse} = 0;
3535   }
3536
3537   # run through the resulting joinstructure (starting from our current slot)
3538   # and unset collapse if proven unnesessary
3539   #
3540   # also while we are at it find out if the current root source has
3541   # been premultiplied by previous related_source chaining
3542   #
3543   # this allows to predict whether a root object with all other relation
3544   # data set to NULL is in fact unique
3545   if ($attrs->{collapse}) {
3546
3547     if (ref $attrs->{from} eq 'ARRAY') {
3548
3549       if (@{$attrs->{from}} <= 1) {
3550         # no joins - no collapse
3551         $attrs->{collapse} = 0;
3552       }
3553       else {
3554         # find where our table-spec starts
3555         my @fromlist = @{$attrs->{from}};
3556         while (@fromlist) {
3557           my $t = shift @fromlist;
3558
3559           my $is_multi;
3560           # me vs join from-spec distinction - a ref means non-root
3561           if (ref $t eq 'ARRAY') {
3562             $t = $t->[0];
3563             $is_multi ||= ! $t->{-is_single};
3564           }
3565           last if ($t->{-alias} && $t->{-alias} eq $alias);
3566           $attrs->{_main_source_premultiplied} ||= $is_multi;
3567         }
3568
3569         # no non-singles remaining, nor any premultiplication - nothing to collapse
3570         if (
3571           ! $attrs->{_main_source_premultiplied}
3572             and
3573           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3574         ) {
3575           $attrs->{collapse} = 0;
3576         }
3577       }
3578     }
3579
3580     else {
3581       # if we can not analyze the from - err on the side of safety
3582       $attrs->{_main_source_premultiplied} = 1;
3583     }
3584   }
3585
3586   # if both page and offset are specified, produce a combined offset
3587   # even though it doesn't make much sense, this is what pre 081xx has
3588   # been doing
3589   if (my $page = delete $attrs->{page}) {
3590     $attrs->{offset} =
3591       ($attrs->{rows} * ($page - 1))
3592             +
3593       ($attrs->{offset} || 0)
3594     ;
3595   }
3596
3597   return $self->{_attrs} = $attrs;
3598 }
3599
3600 sub _rollout_attr {
3601   my ($self, $attr) = @_;
3602
3603   if (ref $attr eq 'HASH') {
3604     return $self->_rollout_hash($attr);
3605   } elsif (ref $attr eq 'ARRAY') {
3606     return $self->_rollout_array($attr);
3607   } else {
3608     return [$attr];
3609   }
3610 }
3611
3612 sub _rollout_array {
3613   my ($self, $attr) = @_;
3614
3615   my @rolled_array;
3616   foreach my $element (@{$attr}) {
3617     if (ref $element eq 'HASH') {
3618       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3619     } elsif (ref $element eq 'ARRAY') {
3620       #  XXX - should probably recurse here
3621       push( @rolled_array, @{$self->_rollout_array($element)} );
3622     } else {
3623       push( @rolled_array, $element );
3624     }
3625   }
3626   return \@rolled_array;
3627 }
3628
3629 sub _rollout_hash {
3630   my ($self, $attr) = @_;
3631
3632   my @rolled_array;
3633   foreach my $key (keys %{$attr}) {
3634     push( @rolled_array, { $key => $attr->{$key} } );
3635   }
3636   return \@rolled_array;
3637 }
3638
3639 sub _calculate_score {
3640   my ($self, $a, $b) = @_;
3641
3642   if (defined $a xor defined $b) {
3643     return 0;
3644   }
3645   elsif (not defined $a) {
3646     return 1;
3647   }
3648
3649   if (ref $b eq 'HASH') {
3650     my ($b_key) = keys %{$b};
3651     if (ref $a eq 'HASH') {
3652       my ($a_key) = keys %{$a};
3653       if ($a_key eq $b_key) {
3654         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3655       } else {
3656         return 0;
3657       }
3658     } else {
3659       return ($a eq $b_key) ? 1 : 0;
3660     }
3661   } else {
3662     if (ref $a eq 'HASH') {
3663       my ($a_key) = keys %{$a};
3664       return ($b eq $a_key) ? 1 : 0;
3665     } else {
3666       return ($b eq $a) ? 1 : 0;
3667     }
3668   }
3669 }
3670
3671 sub _merge_joinpref_attr {
3672   my ($self, $orig, $import) = @_;
3673
3674   return $import unless defined($orig);
3675   return $orig unless defined($import);
3676
3677   $orig = $self->_rollout_attr($orig);
3678   $import = $self->_rollout_attr($import);
3679
3680   my $seen_keys;
3681   foreach my $import_element ( @{$import} ) {
3682     # find best candidate from $orig to merge $b_element into
3683     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3684     foreach my $orig_element ( @{$orig} ) {
3685       my $score = $self->_calculate_score( $orig_element, $import_element );
3686       if ($score > $best_candidate->{score}) {
3687         $best_candidate->{position} = $position;
3688         $best_candidate->{score} = $score;
3689       }
3690       $position++;
3691     }
3692     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3693     $import_key = '' if not defined $import_key;
3694
3695     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3696       push( @{$orig}, $import_element );
3697     } else {
3698       my $orig_best = $orig->[$best_candidate->{position}];
3699       # merge orig_best and b_element together and replace original with merged
3700       if (ref $orig_best ne 'HASH') {
3701         $orig->[$best_candidate->{position}] = $import_element;
3702       } elsif (ref $import_element eq 'HASH') {
3703         my ($key) = keys %{$orig_best};
3704         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3705       }
3706     }
3707     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3708   }
3709
3710   return @$orig ? $orig : ();
3711 }
3712
3713 {
3714   my $hm;
3715
3716   sub _merge_attr {
3717     $hm ||= do {
3718       require Hash::Merge;
3719       my $hm = Hash::Merge->new;
3720
3721       $hm->specify_behavior({
3722         SCALAR => {
3723           SCALAR => sub {
3724             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3725
3726             if ($defl xor $defr) {
3727               return [ $defl ? $_[0] : $_[1] ];
3728             }
3729             elsif (! $defl) {
3730               return [];
3731             }
3732             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3733               return [ $_[0] ];
3734             }
3735             else {
3736               return [$_[0], $_[1]];
3737             }
3738           },
3739           ARRAY => sub {
3740             return $_[1] if !defined $_[0];
3741             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3742             return [$_[0], @{$_[1]}]
3743           },
3744           HASH  => sub {
3745             return [] if !defined $_[0] and !keys %{$_[1]};
3746             return [ $_[1] ] if !defined $_[0];
3747             return [ $_[0] ] if !keys %{$_[1]};
3748             return [$_[0], $_[1]]
3749           },
3750         },
3751         ARRAY => {
3752           SCALAR => sub {
3753             return $_[0] if !defined $_[1];
3754             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3755             return [@{$_[0]}, $_[1]]
3756           },
3757           ARRAY => sub {
3758             my @ret = @{$_[0]} or return $_[1];
3759             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3760             my %idx = map { $_ => 1 } @ret;
3761             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3762             \@ret;
3763           },
3764           HASH => sub {
3765             return [ $_[1] ] if ! @{$_[0]};
3766             return $_[0] if !keys %{$_[1]};
3767             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3768             return [ @{$_[0]}, $_[1] ];
3769           },
3770         },
3771         HASH => {
3772           SCALAR => sub {
3773             return [] if !keys %{$_[0]} and !defined $_[1];
3774             return [ $_[0] ] if !defined $_[1];
3775             return [ $_[1] ] if !keys %{$_[0]};
3776             return [$_[0], $_[1]]
3777           },
3778           ARRAY => sub {
3779             return [] if !keys %{$_[0]} and !@{$_[1]};
3780             return [ $_[0] ] if !@{$_[1]};
3781             return $_[1] if !keys %{$_[0]};
3782             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3783             return [ $_[0], @{$_[1]} ];
3784           },
3785           HASH => sub {
3786             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3787             return [ $_[0] ] if !keys %{$_[1]};
3788             return [ $_[1] ] if !keys %{$_[0]};
3789             return [ $_[0] ] if $_[0] eq $_[1];
3790             return [ $_[0], $_[1] ];
3791           },
3792         }
3793       } => 'DBIC_RS_ATTR_MERGER');
3794       $hm;
3795     };
3796
3797     return $hm->merge ($_[1], $_[2]);
3798   }
3799 }
3800
3801 sub STORABLE_freeze {
3802   my ($self, $cloning) = @_;
3803   my $to_serialize = { %$self };
3804
3805   # A cursor in progress can't be serialized (and would make little sense anyway)
3806   # the parser can be regenerated (and can't be serialized)
3807   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3808
3809   # nor is it sensical to store a not-yet-fired-count pager
3810   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3811     delete $to_serialize->{pager};
3812   }
3813
3814   Storable::nfreeze($to_serialize);
3815 }
3816
3817 # need this hook for symmetry
3818 sub STORABLE_thaw {
3819   my ($self, $cloning, $serialized) = @_;
3820
3821   %$self = %{ Storable::thaw($serialized) };
3822
3823   $self;
3824 }
3825
3826
3827 =head2 throw_exception
3828
3829 See L<DBIx::Class::Schema/throw_exception> for details.
3830
3831 =cut
3832
3833 sub throw_exception {
3834   my $self=shift;
3835
3836   if (ref $self and my $rsrc = $self->result_source) {
3837     $rsrc->throw_exception(@_)
3838   }
3839   else {
3840     DBIx::Class::Exception->throw(@_);
3841   }
3842 }
3843
3844 1;
3845
3846 __END__
3847
3848 # XXX: FIXME: Attributes docs need clearing up
3849
3850 =head1 ATTRIBUTES
3851
3852 Attributes are used to refine a ResultSet in various ways when
3853 searching for data. They can be passed to any method which takes an
3854 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3855 L</count>.
3856
3857 Default attributes can be set on the result class using
3858 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3859 the CAVEATS on that feature before using it!)
3860
3861 These are in no particular order:
3862
3863 =head2 order_by
3864
3865 =over 4
3866
3867 =item Value: ( $order_by | \@order_by | \%order_by )
3868
3869 =back
3870
3871 Which column(s) to order the results by.
3872
3873 [The full list of suitable values is documented in
3874 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3875 common options.]
3876
3877 If a single column name, or an arrayref of names is supplied, the
3878 argument is passed through directly to SQL. The hashref syntax allows
3879 for connection-agnostic specification of ordering direction:
3880
3881  For descending order:
3882
3883   order_by => { -desc => [qw/col1 col2 col3/] }
3884
3885  For explicit ascending order:
3886
3887   order_by => { -asc => 'col' }
3888
3889 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3890 supported, although you are strongly encouraged to use the hashref
3891 syntax as outlined above.
3892
3893 =head2 columns
3894
3895 =over 4
3896
3897 =item Value: \@columns | \%columns | $column
3898
3899 =back
3900
3901 Shortcut to request a particular set of columns to be retrieved. Each
3902 column spec may be a string (a table column name), or a hash (in which
3903 case the key is the C<as> value, and the value is used as the C<select>
3904 expression). Adds C<me.> onto the start of any column without a C<.> in
3905 it and sets C<select> from that, then auto-populates C<as> from
3906 C<select> as normal. (You may also use the C<cols> attribute, as in
3907 earlier versions of DBIC, but this is deprecated.)
3908
3909 Essentially C<columns> does the same as L</select> and L</as>.
3910
3911     columns => [ 'foo', { bar => 'baz' } ]
3912
3913 is the same as
3914
3915     select => [qw/foo baz/],
3916     as => [qw/foo bar/]
3917
3918 =head2 +columns
3919
3920 =over 4
3921
3922 =item Value: \@columns
3923
3924 =back
3925
3926 Indicates additional columns to be selected from storage. Works the same as
3927 L</columns> but adds columns to the selection. (You may also use the
3928 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3929 deprecated). For example:-
3930
3931   $schema->resultset('CD')->search(undef, {
3932     '+columns' => ['artist.name'],
3933     join => ['artist']
3934   });
3935
3936 would return all CDs and include a 'name' column to the information
3937 passed to object inflation. Note that the 'artist' is the name of the
3938 column (or relationship) accessor, and 'name' is the name of the column
3939 accessor in the related table.
3940
3941 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3942 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3943 unary plus operator before it.
3944
3945 =head2 include_columns
3946
3947 =over 4
3948
3949 =item Value: \@columns
3950
3951 =back
3952
3953 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3954
3955 =head2 select
3956
3957 =over 4
3958
3959 =item Value: \@select_columns
3960
3961 =back
3962
3963 Indicates which columns should be selected from the storage. You can use
3964 column names, or in the case of RDBMS back ends, function or stored procedure
3965 names:
3966
3967   $rs = $schema->resultset('Employee')->search(undef, {
3968     select => [
3969       'name',
3970       { count => 'employeeid' },
3971       { max => { length => 'name' }, -as => 'longest_name' }
3972     ]
3973   });
3974
3975   # Equivalent SQL
3976   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3977
3978 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3979 use L</select>, to instruct DBIx::Class how to store the result of the column.
3980 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3981 identifier aliasing. You can however alias a function, so you can use it in
3982 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3983 attribute> supplied as shown in the example above.
3984
3985 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3986 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3987 unary plus operator before it.
3988
3989 =head2 +select
3990
3991 =over 4
3992
3993 Indicates additional columns to be selected from storage.  Works the same as
3994 L</select> but adds columns to the default selection, instead of specifying
3995 an explicit list.
3996
3997 =back
3998
3999 =head2 as
4000
4001 =over 4
4002
4003 =item Value: \@inflation_names
4004
4005 =back
4006
4007 Indicates column names for object inflation. That is L</as> indicates the
4008 slot name in which the column value will be stored within the
4009 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4010 identifier by the C<get_column> method (or via the object accessor B<if one
4011 with the same name already exists>) as shown below. The L</as> attribute has
4012 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4013
4014   $rs = $schema->resultset('Employee')->search(undef, {
4015     select => [
4016       'name',
4017       { count => 'employeeid' },
4018       { max => { length => 'name' }, -as => 'longest_name' }
4019     ],
4020     as => [qw/
4021       name
4022       employee_count
4023       max_name_length
4024     /],
4025   });
4026
4027 If the object against which the search is performed already has an accessor
4028 matching a column name specified in C<as>, the value can be retrieved using
4029 the accessor as normal:
4030
4031   my $name = $employee->name();
4032
4033 If on the other hand an accessor does not exist in the object, you need to
4034 use C<get_column> instead:
4035
4036   my $employee_count = $employee->get_column('employee_count');
4037
4038 You can create your own accessors if required - see
4039 L<DBIx::Class::Manual::Cookbook> for details.
4040
4041 =head2 +as
4042
4043 =over 4
4044
4045 Indicates additional column names for those added via L</+select>. See L</as>.
4046
4047 =back
4048
4049 =head2 join
4050
4051 =over 4
4052
4053 =item Value: ($rel_name | \@rel_names | \%rel_names)
4054
4055 =back
4056
4057 Contains a list of relationships that should be joined for this query.  For
4058 example:
4059
4060   # Get CDs by Nine Inch Nails
4061   my $rs = $schema->resultset('CD')->search(
4062     { 'artist.name' => 'Nine Inch Nails' },
4063     { join => 'artist' }
4064   );
4065
4066 Can also contain a hash reference to refer to the other relation's relations.
4067 For example:
4068
4069   package MyApp::Schema::Track;
4070   use base qw/DBIx::Class/;
4071   __PACKAGE__->table('track');
4072   __PACKAGE__->add_columns(qw/trackid cd position title/);
4073   __PACKAGE__->set_primary_key('trackid');
4074   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4075   1;
4076
4077   # In your application
4078   my $rs = $schema->resultset('Artist')->search(
4079     { 'track.title' => 'Teardrop' },
4080     {
4081       join     => { cd => 'track' },
4082       order_by => 'artist.name',
4083     }
4084   );
4085
4086 You need to use the relationship (not the table) name in  conditions,
4087 because they are aliased as such. The current table is aliased as "me", so
4088 you need to use me.column_name in order to avoid ambiguity. For example:
4089
4090   # Get CDs from 1984 with a 'Foo' track
4091   my $rs = $schema->resultset('CD')->search(
4092     {
4093       'me.year' => 1984,
4094       'tracks.name' => 'Foo'
4095     },
4096     { join => 'tracks' }
4097   );
4098
4099 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4100 similarly for a third time). For e.g.
4101
4102   my $rs = $schema->resultset('Artist')->search({
4103     'cds.title'   => 'Down to Earth',
4104     'cds_2.title' => 'Popular',
4105   }, {
4106     join => [ qw/cds cds/ ],
4107   });
4108
4109 will return a set of all artists that have both a cd with title 'Down
4110 to Earth' and a cd with title 'Popular'.
4111
4112 If you want to fetch related objects from other tables as well, see L</prefetch>
4113 below.
4114
4115  NOTE: An internal join-chain pruner will discard certain joins while
4116  constructing the actual SQL query, as long as the joins in question do not
4117  affect the retrieved result. This for example includes 1:1 left joins
4118  that are not part of the restriction specification (WHERE/HAVING) nor are
4119  a part of the query selection.
4120
4121 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4122
4123 =head2 collapse
4124
4125 =over 4
4126
4127 =item Value: (0 | 1)
4128
4129 =back
4130
4131 When set to a true value, indicates that any rows fetched from joined has_many
4132 relationships are to be aggregated into the corresponding "parent" object. For
4133 example, the resultset:
4134
4135   my $rs = $schema->resultset('CD')->search({}, {
4136     '+columns' => [ qw/ tracks.title tracks.position / ],
4137     join => 'tracks',
4138     collapse => 1,
4139   });
4140
4141 While executing the following query:
4142
4143   SELECT me.*, tracks.title, tracks.position
4144     FROM cd me
4145     LEFT JOIN track tracks
4146       ON tracks.cdid = me.cdid
4147
4148 Will return only as many objects as there are rows in the CD source, even
4149 though the result of the query may span many rows. Each of these CD objects
4150 will in turn have multiple "Track" objects hidden behind the has_many
4151 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4152 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4153 product"), with each CD object containing exactly one of all fetched Track data.
4154
4155 When a collapse is requested on a non-ordered resultset, an order by some
4156 unique part of the main source (the left-most table) is inserted automatically.
4157 This is done so that the resultset is allowed to be "lazy" - calling
4158 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4159 object with all of its related data.
4160
4161 If an L</order_by> is already declared, and orders the resultset in a way that
4162 makes collapsing as described above impossible (e.g. C<< ORDER BY
4163 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4164 switch to "eager" mode and slurp the entire resultset before consturcting the
4165 first object returned by L</next>.
4166
4167 Setting this attribute on a resultset that does not join any has_many
4168 relations is a no-op.
4169
4170 For a more in-depth discussion, see L</PREFETCHING>.
4171
4172 =head2 prefetch
4173
4174 =over 4
4175
4176 =item Value: ($rel_name | \@rel_names | \%rel_names)
4177
4178 =back
4179
4180 This attribute is a shorthand for specifying a L</join> spec, adding all
4181 columns from the joined related sources as L</+columns> and setting
4182 L</collapse> to a true value. For example, the following two queries are
4183 equivalent:
4184
4185   my $rs = $schema->resultset('Artist')->search({}, {
4186     prefetch => { cds => ['genre', 'tracks' ] },
4187   });
4188
4189 and
4190
4191   my $rs = $schema->resultset('Artist')->search({}, {
4192     join => { cds => ['genre', 'tracks' ] },
4193     collapse => 1,
4194     '+columns' => [
4195       (map
4196         { +{ "cds.$_" => "cds.$_" } }
4197         $schema->source('Artist')->related_source('cds')->columns
4198       ),
4199       (map
4200         { +{ "cds.genre.$_" => "genre.$_" } }
4201         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4202       ),
4203       (map
4204         { +{ "cds.tracks.$_" => "tracks.$_" } }
4205         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4206       ),
4207     ],
4208   });
4209
4210 Both producing the following SQL:
4211
4212   SELECT  me.artistid, me.name, me.rank, me.charfield,
4213           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4214           genre.genreid, genre.name,
4215           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4216     FROM artist me
4217     LEFT JOIN cd cds
4218       ON cds.artist = me.artistid
4219     LEFT JOIN genre genre
4220       ON genre.genreid = cds.genreid
4221     LEFT JOIN track tracks
4222       ON tracks.cd = cds.cdid
4223   ORDER BY me.artistid
4224
4225 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4226 the arguments are properly merged and generally do the right thing. For
4227 example, you may want to do the following:
4228
4229   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4230     { 'genre.genreid' => undef },
4231     {
4232       join => { cds => 'genre' },
4233       prefetch => 'cds',
4234     }
4235   );
4236
4237 Which generates the following SQL:
4238
4239   SELECT  me.artistid, me.name, me.rank, me.charfield,
4240           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4241     FROM artist me
4242     LEFT JOIN cd cds
4243       ON cds.artist = me.artistid
4244     LEFT JOIN genre genre
4245       ON genre.genreid = cds.genreid
4246   WHERE genre.genreid IS NULL
4247   ORDER BY me.artistid
4248
4249 For a more in-depth discussion, see L</PREFETCHING>.
4250
4251 =head2 alias
4252
4253 =over 4
4254
4255 =item Value: $source_alias
4256
4257 =back
4258
4259 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4260 nested search queries (sub-SELECTs) might need specific aliases set to
4261 reference inner queries.  For example:
4262
4263    my $q = $rs
4264       ->related_resultset('CDs')
4265       ->related_resultset('Tracks')
4266       ->search({
4267          'track.id' => { -ident => 'none_search.id' },
4268       })
4269       ->as_query;
4270
4271    my $ids = $self->search({
4272       -not_exists => $q,
4273    }, {
4274       alias    => 'none_search',
4275       group_by => 'none_search.id',
4276    })->get_column('id')->as_query;
4277
4278    $self->search({ id => { -in => $ids } })
4279
4280 This attribute is directly tied to L</current_source_alias>.
4281
4282 =head2 page
4283
4284 =over 4
4285
4286 =item Value: $page
4287
4288 =back
4289
4290 Makes the resultset paged and specifies the page to retrieve. Effectively
4291 identical to creating a non-pages resultset and then calling ->page($page)
4292 on it.
4293
4294 If L</rows> attribute is not specified it defaults to 10 rows per page.
4295
4296 When you have a paged resultset, L</count> will only return the number
4297 of rows in the page. To get the total, use the L</pager> and call
4298 C<total_entries> on it.
4299
4300 =head2 rows
4301
4302 =over 4
4303
4304 =item Value: $rows
4305
4306 =back
4307
4308 Specifies the maximum number of rows for direct retrieval or the number of
4309 rows per page if the page attribute or method is used.
4310
4311 =head2 offset
4312
4313 =over 4
4314
4315 =item Value: $offset
4316
4317 =back
4318
4319 Specifies the (zero-based) row number for the  first row to be returned, or the
4320 of the first row of the first page if paging is used.
4321
4322 =head2 software_limit
4323
4324 =over 4
4325
4326 =item Value: (0 | 1)
4327
4328 =back
4329
4330 When combined with L</rows> and/or L</offset> the generated SQL will not
4331 include any limit dialect stanzas. Instead the entire result will be selected
4332 as if no limits were specified, and DBIC will perform the limit locally, by
4333 artificially advancing and finishing the resulting L</cursor>.
4334
4335 This is the recommended way of performing resultset limiting when no sane RDBMS
4336 implementation is available (e.g.
4337 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4338 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4339
4340 =head2 group_by
4341
4342 =over 4
4343
4344 =item Value: \@columns
4345
4346 =back
4347
4348 A arrayref of columns to group by. Can include columns of joined tables.
4349
4350   group_by => [qw/ column1 column2 ... /]
4351
4352 =head2 having
4353
4354 =over 4
4355
4356 =item Value: $condition
4357
4358 =back
4359
4360 HAVING is a select statement attribute that is applied between GROUP BY and
4361 ORDER BY. It is applied to the after the grouping calculations have been
4362 done.
4363
4364   having => { 'count_employee' => { '>=', 100 } }
4365
4366 or with an in-place function in which case literal SQL is required:
4367
4368   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4369
4370 =head2 distinct
4371
4372 =over 4
4373
4374 =item Value: (0 | 1)
4375
4376 =back
4377
4378 Set to 1 to group by all columns. If the resultset already has a group_by
4379 attribute, this setting is ignored and an appropriate warning is issued.
4380
4381 =head2 where
4382
4383 =over 4
4384
4385 Adds to the WHERE clause.
4386
4387   # only return rows WHERE deleted IS NULL for all searches
4388   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4389
4390 Can be overridden by passing C<< { where => undef } >> as an attribute
4391 to a resultset.
4392
4393 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4394
4395 =back
4396
4397 =head2 cache
4398
4399 Set to 1 to cache search results. This prevents extra SQL queries if you
4400 revisit rows in your ResultSet:
4401
4402   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4403
4404   while( my $artist = $resultset->next ) {
4405     ... do stuff ...
4406   }
4407
4408   $rs->first; # without cache, this would issue a query
4409
4410 By default, searches are not cached.
4411
4412 For more examples of using these attributes, see
4413 L<DBIx::Class::Manual::Cookbook>.
4414
4415 =head2 for
4416
4417 =over 4
4418
4419 =item Value: ( 'update' | 'shared' | \$scalar )
4420
4421 =back
4422
4423 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4424 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4425 query.
4426
4427 =head1 PREFETCHING
4428
4429 DBIx::Class supports arbitrary related data prefetching from multiple related
4430 sources. Any combination of relationship types and column sets are supported.
4431 If L<collapsing|/collapse> is requested, there is an additional requirement of
4432 selecting enough data to make every individual object uniquely identifiable.
4433
4434 Here are some more involved examples, based on the following relationship map:
4435
4436   # Assuming:
4437   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4438   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4439   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4440
4441   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4442
4443   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4444
4445
4446
4447   my $rs = $schema->resultset('Tag')->search(
4448     undef,
4449     {
4450       prefetch => {
4451         cd => 'artist'
4452       }
4453     }
4454   );
4455
4456 The initial search results in SQL like the following:
4457
4458   SELECT tag.*, cd.*, artist.* FROM tag
4459   JOIN cd ON tag.cd = cd.cdid
4460   JOIN artist ON cd.artist = artist.artistid
4461
4462 L<DBIx::Class> has no need to go back to the database when we access the
4463 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4464 case.
4465
4466 Simple prefetches will be joined automatically, so there is no need
4467 for a C<join> attribute in the above search.
4468
4469 The L</prefetch> attribute can be used with any of the relationship types
4470 and multiple prefetches can be specified together. Below is a more complex
4471 example that prefetches a CD's artist, its liner notes (if present),
4472 the cover image, the tracks on that CD, and the guests on those
4473 tracks.
4474
4475   my $rs = $schema->resultset('CD')->search(
4476     undef,
4477     {
4478       prefetch => [
4479         { artist => 'record_label'},  # belongs_to => belongs_to
4480         'liner_note',                 # might_have
4481         'cover_image',                # has_one
4482         { tracks => 'guests' },       # has_many => has_many
4483       ]
4484     }
4485   );
4486
4487 This will produce SQL like the following:
4488
4489   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4490          tracks.*, guests.*
4491     FROM cd me
4492     JOIN artist artist
4493       ON artist.artistid = me.artistid
4494     JOIN record_label record_label
4495       ON record_label.labelid = artist.labelid
4496     LEFT JOIN track tracks
4497       ON tracks.cdid = me.cdid
4498     LEFT JOIN guest guests
4499       ON guests.trackid = track.trackid
4500     LEFT JOIN liner_notes liner_note
4501       ON liner_note.cdid = me.cdid
4502     JOIN cd_artwork cover_image
4503       ON cover_image.cdid = me.cdid
4504   ORDER BY tracks.cd
4505
4506 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4507 C<tracks>, and C<guests> of the CD will all be available through the
4508 relationship accessors without the need for additional queries to the
4509 database.
4510
4511 =head3 CAVEATS
4512
4513 Prefetch does a lot of deep magic. As such, it may not behave exactly
4514 as you might expect.
4515
4516 =over 4
4517
4518 =item *
4519
4520 Prefetch uses the L</cache> to populate the prefetched relationships. This
4521 may or may not be what you want.
4522
4523 =item *
4524
4525 If you specify a condition on a prefetched relationship, ONLY those
4526 rows that match the prefetched condition will be fetched into that relationship.
4527 This means that adding prefetch to a search() B<may alter> what is returned by
4528 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4529
4530   my $artist_rs = $schema->resultset('Artist')->search({
4531       'cds.year' => 2008,
4532   }, {
4533       join => 'cds',
4534   });
4535
4536   my $count = $artist_rs->first->cds->count;
4537
4538   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4539
4540   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4541
4542   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4543
4544 That cmp_ok() may or may not pass depending on the datasets involved. In other
4545 words the C<WHERE> condition would apply to the entire dataset, just like
4546 it would in regular SQL. If you want to add a condition only to the "right side"
4547 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4548 condition|DBIx::Class::Relationship::Base/condition>
4549
4550 =back
4551
4552 =head1 DBIC BIND VALUES
4553
4554 Because DBIC may need more information to bind values than just the column name
4555 and value itself, it uses a special format for both passing and receiving bind
4556 values.  Each bind value should be composed of an arrayref of
4557 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4558
4559 =over 4
4560
4561 =item dbd_attrs
4562
4563 If present (in any form), this is what is being passed directly to bind_param.
4564 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4565 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4566
4567 If this is specified, all other bind options described below are ignored.
4568
4569 =item sqlt_datatype
4570
4571 If present, this is used to infer the actual bind attribute by passing to
4572 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4573 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4574
4575 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4576 currently drivers are expected to "Do the Right Thing" when given a common
4577 datatype name.  (Not ideal, but that's what we got at this point.)
4578
4579 =item sqlt_size
4580
4581 Currently used to correctly allocate buffers for bind_param_inout().
4582 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4583 or to a sensible value based on the "data_type".
4584
4585 =item dbic_colname
4586
4587 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4588 explicitly specified they are never overriden).  Also used by some weird DBDs,
4589 where the column name should be available at bind_param time (e.g. Oracle).
4590
4591 =back
4592
4593 For backwards compatibility and convenience, the following shortcuts are
4594 supported:
4595
4596   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4597   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4598   [ undef,   $val ] === [ {}, $val ]
4599
4600 =head1 AUTHOR AND CONTRIBUTORS
4601
4602 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4603
4604 =head1 LICENSE
4605
4606 You may distribute this code under the same terms as Perl itself.
4607