lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset (ie:
 145 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 146 and attributes with the same keys need resolving.
 147
 148 If any of L</columns>, L</select>, L</as> are present, they reset the
 149 original selection, and start the selection "clean".
 150
 151 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 152 are merged into the existing ones from the original resultset.
 153
 154 The L</where> and L</having> attributes, and any search conditions, are
 155 merged with an SQL C<AND> to the existing condition from the original
 156 resultset.
 157
 158 All other attributes are overridden by any new ones supplied in the
 159 search attributes.
 160
 161 =head2 Multiple queries
 162
 163 Since a resultset just defines a query, you can do all sorts of
 164 things with it with the same object.
 165
 166   # Don't hit the DB yet.
 167   my $cd_rs = $schema->resultset('CD')->search({
 168     title => 'something',
 169     year => 2009,
 170   });
 171
 172   # Each of these hits the DB individually.
 173   my $count = $cd_rs->count;
 174   my $most_recent = $cd_rs->get_column('date_released')->max();
 175   my @records = $cd_rs->all;
 176
 177 And it's not just limited to SELECT statements.
 178
 179   $cd_rs->delete();
 180
 181 This is even cooler:
 182
 183   $cd_rs->create({ artist => 'Fred' });
 184
 185 Which is the same as:
 186
 187   $schema->resultset('CD')->create({
 188     title => 'something',
 189     year => 2009,
 190     artist => 'Fred'
 191   });
 192
 193 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 194
 195 =head1 METHODS
 196
 197 =head2 new
 198
 199 =over 4
 200
 201 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 202
 203 =item Return Value: L<$resultset|/search>
 204
 205 =back
 206
 207 The resultset constructor. Takes a source object (usually a
 208 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 209 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 210 executed as needed by the other methods.
 211
 212 Generally you never construct a resultset manually. Instead you get one
 213 from e.g. a
 214 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 215 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 216 scalar context):
 217
 218   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 219
 220 =over
 221
 222 =item WARNING
 223
 224 If called on an object, proxies to L</new_result> instead, so
 225
 226   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 227
 228 will return a CD object, not a ResultSet, and is equivalent to:
 229
 230   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 231
 232 Please also keep in mind that many internals call L</new_result> directly,
 233 so overloading this method with the idea of intercepting new result object
 234 creation B<will not work>. See also warning pertaining to L</create>.
 235
 236 =back
 237
 238 =cut
 239
 240 sub new {
 241   my $class = shift;
 242   return $class->new_result(@_) if ref $class;
 243
 244   my ($source, $attrs) = @_;
 245   $source = $source->resolve
 246     if $source->isa('DBIx::Class::ResultSourceHandle');
 247   $attrs = { %{$attrs||{}} };
 248
 249   if ($attrs->{page}) {
 250     $attrs->{rows} ||= 10;
 251   }
 252
 253   $attrs->{alias} ||= 'me';
 254
 255   my $self = bless {
 256     result_source => $source,
 257     cond => $attrs->{where},
 258     pager => undef,
 259     attrs => $attrs,
 260   }, $class;
 261
 262   # if there is a dark selector, this means we are already in a
 263   # chain and the cleanup/sanification was taken care of by
 264   # _search_rs already
 265   $self->_normalize_selection($attrs)
 266     unless $attrs->{_dark_selector};
 267
 268   $self->result_class(
 269     $attrs->{result_class} || $source->result_class
 270   );
 271
 272   $self;
 273 }
 274
 275 =head2 search
 276
 277 =over 4
 278
 279 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 280
 281 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 282
 283 =back
 284
 285   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 286   my $new_rs = $cd_rs->search({ year => 2005 });
 287
 288   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 289                  # year = 2005 OR year = 2004
 290
 291 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 292 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 293 To avoid that, use L</search_rs>.
 294
 295 If you need to pass in additional attributes but no additional condition,
 296 call it as C<search(undef, \%attrs)>.
 297
 298   # "SELECT name, artistid FROM $artist_table"
 299   my @all_artists = $schema->resultset('Artist')->search(undef, {
 300     columns => [qw/name artistid/],
 301   });
 302
 303 For a list of attributes that can be passed to C<search>, see
 304 L</ATTRIBUTES>. For more examples of using this function, see
 305 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 306 documentation for the first argument, see L<SQL::Abstract>
 307 and its extension L<DBIx::Class::SQLMaker>.
 308
 309 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 310
 311 =head3 CAVEAT
 312
 313 Note that L</search> does not process/deflate any of the values passed in the
 314 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 315 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 316 manually that any value passed to this method will stringify to something the
 317 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 318 objects, for more info see:
 319 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 320
 321 =cut
 322
 323 sub search {
 324   my $self = shift;
 325   my $rs = $self->search_rs( @_ );
 326
 327   if (wantarray) {
 328     return $rs->all;
 329   }
 330   elsif (defined wantarray) {
 331     return $rs;
 332   }
 333   else {
 334     # we can be called by a relationship helper, which in
 335     # turn may be called in void context due to some braindead
 336     # overload or whatever else the user decided to be clever
 337     # at this particular day. Thus limit the exception to
 338     # external code calls only
 339     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 340       if (caller)[0] !~ /^\QDBIx::Class::/;
 341
 342     return ();
 343   }
 344 }
 345
 346 =head2 search_rs
 347
 348 =over 4
 349
 350 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 351
 352 =item Return Value: L<$resultset|/search>
 353
 354 =back
 355
 356 This method does the same exact thing as search() except it will
 357 always return a resultset, even in list context.
 358
 359 =cut
 360
 361 sub search_rs {
 362   my $self = shift;
 363
 364   my $rsrc = $self->result_source;
 365   my ($call_cond, $call_attrs);
 366
 367   # Special-case handling for (undef, undef) or (undef)
 368   # Note that (foo => undef) is valid deprecated syntax
 369   @_ = () if not scalar grep { defined $_ } @_;
 370
 371   # just a cond
 372   if (@_ == 1) {
 373     $call_cond = shift;
 374   }
 375   # fish out attrs in the ($condref, $attr) case
 376   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 377     ($call_cond, $call_attrs) = @_;
 378   }
 379   elsif (@_ % 2) {
 380     $self->throw_exception('Odd number of arguments to search')
 381   }
 382   # legacy search
 383   elsif (@_) {
 384     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 385       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 386
 387     for my $i (0 .. $#_) {
 388       next if $i % 2;
 389       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 390         if (! defined $_[$i] or ref $_[$i] ne '');
 391     }
 392
 393     $call_cond = { @_ };
 394   }
 395
 396   # see if we can keep the cache (no $rs changes)
 397   my $cache;
 398   my %safe = (alias => 1, cache => 1);
 399   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 400     ! defined $call_cond
 401       or
 402     ref $call_cond eq 'HASH' && ! keys %$call_cond
 403       or
 404     ref $call_cond eq 'ARRAY' && ! @$call_cond
 405   )) {
 406     $cache = $self->get_cache;
 407   }
 408
 409   my $old_attrs = { %{$self->{attrs}} };
 410   my $old_having = delete $old_attrs->{having};
 411   my $old_where = delete $old_attrs->{where};
 412
 413   my $new_attrs = { %$old_attrs };
 414
 415   # take care of call attrs (only if anything is changing)
 416   if ($call_attrs and keys %$call_attrs) {
 417
 418     # copy for _normalize_selection
 419     $call_attrs = { %$call_attrs };
 420
 421     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 422
 423     # reset the current selector list if new selectors are supplied
 424     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 425       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 426     }
 427
 428     # Normalize the new selector list (operates on the passed-in attr structure)
 429     # Need to do it on every chain instead of only once on _resolved_attrs, in
 430     # order to allow detection of empty vs partial 'as'
 431     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 432       if $old_attrs->{_dark_selector};
 433     $self->_normalize_selection ($call_attrs);
 434
 435     # start with blind overwriting merge, exclude selector attrs
 436     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 437     delete @{$new_attrs}{@selector_attrs};
 438
 439     for (@selector_attrs) {
 440       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 441         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 442     }
 443
 444     # older deprecated name, use only if {columns} is not there
 445     if (my $c = delete $new_attrs->{cols}) {
 446       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 447       if ($new_attrs->{columns}) {
 448         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 449       }
 450       else {
 451         $new_attrs->{columns} = $c;
 452       }
 453     }
 454
 455
 456     # join/prefetch use their own crazy merging heuristics
 457     foreach my $key (qw/join prefetch/) {
 458       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 459         if exists $call_attrs->{$key};
 460     }
 461
 462     # stack binds together
 463     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 464   }
 465
 466
 467   for ($old_where, $call_cond) {
 468     if (defined $_) {
 469       $new_attrs->{where} = $self->_stack_cond (
 470         $_, $new_attrs->{where}
 471       );
 472     }
 473   }
 474
 475   if (defined $old_having) {
 476     $new_attrs->{having} = $self->_stack_cond (
 477       $old_having, $new_attrs->{having}
 478     )
 479   }
 480
 481   my $rs = (ref $self)->new($rsrc, $new_attrs);
 482
 483   $rs->set_cache($cache) if ($cache);
 484
 485   return $rs;
 486 }
 487
 488 my $dark_sel_dumper;
 489 sub _normalize_selection {
 490   my ($self, $attrs) = @_;
 491
 492   # legacy syntax
 493   if ( exists $attrs->{include_columns} ) {
 494     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 495     $attrs->{'+columns'} = $self->_merge_attr(
 496       $attrs->{'+columns'}, delete $attrs->{include_columns}
 497     );
 498   }
 499
 500   # columns are always placed first, however
 501
 502   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 503   # delay the decision on whether to use a default select list ($rsrc->columns)
 504   # allowing stuff like the remove_columns helper to work
 505   #
 506   # select/as +select/+as pairs need special handling - the amount of select/as
 507   # elements in each pair does *not* have to be equal (think multicolumn
 508   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 509   # supplied at all) - try to infer the alias, either from the -as parameter
 510   # of the selector spec, or use the parameter whole if it looks like a column
 511   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 512   # is ok as well), but make sure no more additions to the 'as' chain take place
 513   for my $pref ('', '+') {
 514
 515     my ($sel, $as) = map {
 516       my $key = "${pref}${_}";
 517
 518       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 519         ? @{$attrs->{$key}}
 520         : $attrs->{$key} || ()
 521       ];
 522       delete $attrs->{$key};
 523       $val;
 524     } qw/select as/;
 525
 526     if (! @$as and ! @$sel ) {
 527       next;
 528     }
 529     elsif (@$as and ! @$sel) {
 530       $self->throw_exception(
 531         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 532       );
 533     }
 534     elsif( ! @$as ) {
 535       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 536       # if any @$as has been supplied we assume the user knows what (s)he is doing
 537       # and blindly keep stacking up pieces
 538       unless ($attrs->{_dark_selector}) {
 539         SELECTOR:
 540         for (@$sel) {
 541           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 542             push @$as, $_->{-as};
 543           }
 544           # assume any plain no-space, no-parenthesis string to be a column spec
 545           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 546           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 547             push @$as, $_;
 548           }
 549           # if all else fails - raise a flag that no more aliasing will be allowed
 550           else {
 551             $attrs->{_dark_selector} = {
 552               plus_stage => $pref,
 553               string => ($dark_sel_dumper ||= do {
 554                   require Data::Dumper::Concise;
 555                   Data::Dumper::Concise::DumperObject()->Indent(0);
 556                 })->Values([$_])->Dump
 557               ,
 558             };
 559             last SELECTOR;
 560           }
 561         }
 562       }
 563     }
 564     elsif (@$as < @$sel) {
 565       $self->throw_exception(
 566         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 567       );
 568     }
 569     elsif ($pref and $attrs->{_dark_selector}) {
 570       $self->throw_exception(
 571         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 572       );
 573     }
 574
 575
 576     # merge result
 577     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 578     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 579   }
 580 }
 581
 582 sub _stack_cond {
 583   my ($self, $left, $right) = @_;
 584
 585   # collapse single element top-level conditions
 586   # (single pass only, unlikely to need recursion)
 587   for ($left, $right) {
 588     if (ref $_ eq 'ARRAY') {
 589       if (@$_ == 0) {
 590         $_ = undef;
 591       }
 592       elsif (@$_ == 1) {
 593         $_ = $_->[0];
 594       }
 595     }
 596     elsif (ref $_ eq 'HASH') {
 597       my ($first, $more) = keys %$_;
 598
 599       # empty hash
 600       if (! defined $first) {
 601         $_ = undef;
 602       }
 603       # one element hash
 604       elsif (! defined $more) {
 605         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 606           $_ = $_->{'-and'};
 607         }
 608         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 609           $_ = $_->{'-or'};
 610         }
 611       }
 612     }
 613   }
 614
 615   # merge hashes with weeding out of duplicates (simple cases only)
 616   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 617
 618     # shallow copy to destroy
 619     $right = { %$right };
 620     for (grep { exists $right->{$_} } keys %$left) {
 621       # the use of eq_deeply here is justified - the rhs of an
 622       # expression can contain a lot of twisted weird stuff
 623       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 624     }
 625
 626     $right = undef unless keys %$right;
 627   }
 628
 629
 630   if (defined $left xor defined $right) {
 631     return defined $left ? $left : $right;
 632   }
 633   elsif (! defined $left) {
 634     return undef;
 635   }
 636   else {
 637     return { -and => [ $left, $right ] };
 638   }
 639 }
 640
 641 =head2 search_literal
 642
 643 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 644 should only be used in that context. C<search_literal> is a convenience
 645 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 646 want to ensure columns are bound correctly, use L</search>.
 647
 648 See L<DBIx::Class::Manual::Cookbook/Searching> and
 649 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 650 require C<search_literal>.
 651
 652 =over 4
 653
 654 =item Arguments: $sql_fragment, @standalone_bind_values
 655
 656 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 657
 658 =back
 659
 660   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 661   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 662
 663 Pass a literal chunk of SQL to be added to the conditional part of the
 664 resultset query.
 665
 666 Example of how to use C<search> instead of C<search_literal>
 667
 668   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 669   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 670
 671 =cut
 672
 673 sub search_literal {
 674   my ($self, $sql, @bind) = @_;
 675   my $attr;
 676   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 677     $attr = pop @bind;
 678   }
 679   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 680 }
 681
 682 =head2 find
 683
 684 =over 4
 685
 686 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 687
 688 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 689
 690 =back
 691
 692 Finds and returns a single row based on supplied criteria. Takes either a
 693 hashref with the same format as L</create> (including inference of foreign
 694 keys from related objects), or a list of primary key values in the same
 695 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 696 declaration on the L</result_source>.
 697
 698 In either case an attempt is made to combine conditions already existing on
 699 the resultset with the condition passed to this method.
 700
 701 To aid with preparing the correct query for the storage you may supply the
 702 C<key> attribute, which is the name of a
 703 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 704 unique constraint corresponding to the
 705 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 706 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 707 to construct a query that satisfies the named unique constraint fully (
 708 non-NULL values for each column member of the constraint) an exception is
 709 thrown.
 710
 711 If no C<key> is specified, the search is carried over all unique constraints
 712 which are fully defined by the available condition.
 713
 714 If no such constraint is found, C<find> currently defaults to a simple
 715 C<< search->(\%column_values) >> which may or may not do what you expect.
 716 Note that this fallback behavior may be deprecated in further versions. If
 717 you need to search with arbitrary conditions - use L</search>. If the query
 718 resulting from this fallback produces more than one row, a warning to the
 719 effect is issued, though only the first row is constructed and returned as
 720 C<$result_object>.
 721
 722 In addition to C<key>, L</find> recognizes and applies standard
 723 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 724
 725 Note that if you have extra concerns about the correctness of the resulting
 726 query you need to specify the C<key> attribute and supply the entire condition
 727 as an argument to find (since it is not always possible to perform the
 728 combination of the resultset condition with the supplied one, especially if
 729 the resultset condition contains literal sql).
 730
 731 For example, to find a row by its primary key:
 732
 733   my $cd = $schema->resultset('CD')->find(5);
 734
 735 You can also find a row by a specific unique constraint:
 736
 737   my $cd = $schema->resultset('CD')->find(
 738     {
 739       artist => 'Massive Attack',
 740       title  => 'Mezzanine',
 741     },
 742     { key => 'cd_artist_title' }
 743   );
 744
 745 See also L</find_or_create> and L</update_or_create>.
 746
 747 =cut
 748
 749 sub find {
 750   my $self = shift;
 751   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 752
 753   my $rsrc = $self->result_source;
 754
 755   my $constraint_name;
 756   if (exists $attrs->{key}) {
 757     $constraint_name = defined $attrs->{key}
 758       ? $attrs->{key}
 759       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 760     ;
 761   }
 762
 763   # Parse out the condition from input
 764   my $call_cond;
 765
 766   if (ref $_[0] eq 'HASH') {
 767     $call_cond = { %{$_[0]} };
 768   }
 769   else {
 770     # if only values are supplied we need to default to 'primary'
 771     $constraint_name = 'primary' unless defined $constraint_name;
 772
 773     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 774
 775     $self->throw_exception(
 776       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 777     ) unless @c_cols;
 778
 779     $self->throw_exception (
 780       'find() expects either a column/value hashref, or a list of values '
 781     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 782     ) unless @c_cols == @_;
 783
 784     $call_cond = {};
 785     @{$call_cond}{@c_cols} = @_;
 786   }
 787
 788   my %related;
 789   for my $key (keys %$call_cond) {
 790     if (
 791       my $keyref = ref($call_cond->{$key})
 792         and
 793       my $relinfo = $rsrc->relationship_info($key)
 794     ) {
 795       my $val = delete $call_cond->{$key};
 796
 797       next if $keyref eq 'ARRAY'; # has_many for multi_create
 798
 799       my $rel_q = $rsrc->_resolve_condition(
 800         $relinfo->{cond}, $val, $key, $key
 801       );
 802       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 803       @related{keys %$rel_q} = values %$rel_q;
 804     }
 805   }
 806
 807   # relationship conditions take precedence (?)
 808   @{$call_cond}{keys %related} = values %related;
 809
 810   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 811   my $final_cond;
 812   if (defined $constraint_name) {
 813     $final_cond = $self->_qualify_cond_columns (
 814
 815       $self->_build_unique_cond (
 816         $constraint_name,
 817         $call_cond,
 818       ),
 819
 820       $alias,
 821     );
 822   }
 823   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 824     # This means that we got here after a merger of relationship conditions
 825     # in ::Relationship::Base::search_related (the row method), and furthermore
 826     # the relationship is of the 'single' type. This means that the condition
 827     # provided by the relationship (already attached to $self) is sufficient,
 828     # as there can be only one row in the database that would satisfy the
 829     # relationship
 830   }
 831   else {
 832     # no key was specified - fall down to heuristics mode:
 833     # run through all unique queries registered on the resultset, and
 834     # 'OR' all qualifying queries together
 835     my (@unique_queries, %seen_column_combinations);
 836     for my $c_name ($rsrc->unique_constraint_names) {
 837       next if $seen_column_combinations{
 838         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 839       }++;
 840
 841       push @unique_queries, try {
 842         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 843       } || ();
 844     }
 845
 846     $final_cond = @unique_queries
 847       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 848       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 849     ;
 850   }
 851
 852   # Run the query, passing the result_class since it should propagate for find
 853   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 854   if ($rs->_resolved_attrs->{collapse}) {
 855     my $row = $rs->next;
 856     carp "Query returned more than one row" if $rs->next;
 857     return $row;
 858   }
 859   else {
 860     return $rs->single;
 861   }
 862 }
 863
 864 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 865 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 866 #
 867 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 868 # condition. It is provided for overrides until a saner way forward is devised
 869 #
 870 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 871 # the road. Please adjust your tests accordingly to catch this situation early
 872 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 873 #
 874 # The method will not be removed without an adequately complete replacement
 875 # for strict-mode enforcement
 876 sub _non_unique_find_fallback {
 877   my ($self, $cond, $attrs) = @_;
 878
 879   return $self->_qualify_cond_columns(
 880     $cond,
 881     exists $attrs->{alias}
 882       ? $attrs->{alias}
 883       : $self->{attrs}{alias}
 884   );
 885 }
 886
 887
 888 sub _qualify_cond_columns {
 889   my ($self, $cond, $alias) = @_;
 890
 891   my %aliased = %$cond;
 892   for (keys %aliased) {
 893     $aliased{"$alias.$_"} = delete $aliased{$_}
 894       if $_ !~ /\./;
 895   }
 896
 897   return \%aliased;
 898 }
 899
 900 sub _build_unique_cond {
 901   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 902
 903   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 904
 905   # combination may fail if $self->{cond} is non-trivial
 906   my ($final_cond) = try {
 907     $self->_merge_with_rscond ($extra_cond)
 908   } catch {
 909     +{ %$extra_cond }
 910   };
 911
 912   # trim out everything not in $columns
 913   $final_cond = { map {
 914     exists $final_cond->{$_}
 915       ? ( $_ => $final_cond->{$_} )
 916       : ()
 917   } @c_cols };
 918
 919   if (my @missing = grep
 920     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 921     (@c_cols)
 922   ) {
 923     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 924       $constraint_name,
 925       join (', ', map { "'$_'" } @missing),
 926     ) );
 927   }
 928
 929   if (
 930     !$croak_on_null
 931       and
 932     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 933       and
 934     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 935   ) {
 936     carp_unique ( sprintf (
 937       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 938     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 939     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 940       $constraint_name,
 941       join (', ', map { "'$_'" } @undefs),
 942     ));
 943   }
 944
 945   return $final_cond;
 946 }
 947
 948 =head2 search_related
 949
 950 =over 4
 951
 952 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 953
 954 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 955
 956 =back
 957
 958   $new_rs = $cd_rs->search_related('artist', {
 959     name => 'Emo-R-Us',
 960   });
 961
 962 Searches the specified relationship, optionally specifying a condition and
 963 attributes for matching records. See L</ATTRIBUTES> for more information.
 964
 965 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 966 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 967
 968 See also L</search_related_rs>.
 969
 970 =cut
 971
 972 sub search_related {
 973   return shift->related_resultset(shift)->search(@_);
 974 }
 975
 976 =head2 search_related_rs
 977
 978 This method works exactly the same as search_related, except that
 979 it guarantees a resultset, even in list context.
 980
 981 =cut
 982
 983 sub search_related_rs {
 984   return shift->related_resultset(shift)->search_rs(@_);
 985 }
 986
 987 =head2 cursor
 988
 989 =over 4
 990
 991 =item Arguments: none
 992
 993 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 994
 995 =back
 996
 997 Returns a storage-driven cursor to the given resultset. See
 998 L<DBIx::Class::Cursor> for more information.
 999
1000 =cut
1001
1002 sub cursor {
1003   my $self = shift;
1004
1005   return $self->{cursor} ||= do {
1006     my $attrs = { %{$self->_resolved_attrs } };
1007     $self->result_source->storage->select(
1008       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1009     );
1010   };
1011 }
1012
1013 =head2 single
1014
1015 =over 4
1016
1017 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1018
1019 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1020
1021 =back
1022
1023   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1024
1025 Inflates the first result without creating a cursor if the resultset has
1026 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1027 of L</search>.
1028
1029 While this method can take an optional search condition (just like L</search>)
1030 being a fast-code-path it does not recognize search attributes. If you need to
1031 add extra joins or similar, call L</search> and then chain-call L</single> on the
1032 L<DBIx::Class::ResultSet> returned.
1033
1034 =over
1035
1036 =item B<Note>
1037
1038 As of 0.08100, this method enforces the assumption that the preceding
1039 query returns only one row. If more than one row is returned, you will receive
1040 a warning:
1041
1042   Query returned more than one row
1043
1044 In this case, you should be using L</next> or L</find> instead, or if you really
1045 know what you are doing, use the L</rows> attribute to explicitly limit the size
1046 of the resultset.
1047
1048 This method will also throw an exception if it is called on a resultset prefetching
1049 has_many, as such a prefetch implies fetching multiple rows from the database in
1050 order to assemble the resulting object.
1051
1052 =back
1053
1054 =cut
1055
1056 sub single {
1057   my ($self, $where) = @_;
1058   if(@_ > 2) {
1059       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1060   }
1061
1062   my $attrs = { %{$self->_resolved_attrs} };
1063
1064   $self->throw_exception(
1065     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1066   ) if $attrs->{collapse};
1067
1068   if ($where) {
1069     if (defined $attrs->{where}) {
1070       $attrs->{where} = {
1071         '-and' =>
1072             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1073                $where, delete $attrs->{where} ]
1074       };
1075     } else {
1076       $attrs->{where} = $where;
1077     }
1078   }
1079
1080   my $data = [ $self->result_source->storage->select_single(
1081     $attrs->{from}, $attrs->{select},
1082     $attrs->{where}, $attrs
1083   )];
1084   return undef unless @$data;
1085   $self->{_stashed_rows} = [ $data ];
1086   $self->_construct_results->[0];
1087 }
1088
1089
1090 # _collapse_query
1091 #
1092 # Recursively collapse the query, accumulating values for each column.
1093
1094 sub _collapse_query {
1095   my ($self, $query, $collapsed) = @_;
1096
1097   $collapsed ||= {};
1098
1099   if (ref $query eq 'ARRAY') {
1100     foreach my $subquery (@$query) {
1101       next unless ref $subquery;  # -or
1102       $collapsed = $self->_collapse_query($subquery, $collapsed);
1103     }
1104   }
1105   elsif (ref $query eq 'HASH') {
1106     if (keys %$query and (keys %$query)[0] eq '-and') {
1107       foreach my $subquery (@{$query->{-and}}) {
1108         $collapsed = $self->_collapse_query($subquery, $collapsed);
1109       }
1110     }
1111     else {
1112       foreach my $col (keys %$query) {
1113         my $value = $query->{$col};
1114         $collapsed->{$col}{$value}++;
1115       }
1116     }
1117   }
1118
1119   return $collapsed;
1120 }
1121
1122 =head2 get_column
1123
1124 =over 4
1125
1126 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1127
1128 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1129
1130 =back
1131
1132   my $max_length = $rs->get_column('length')->max;
1133
1134 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1135
1136 =cut
1137
1138 sub get_column {
1139   my ($self, $column) = @_;
1140   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1141   return $new;
1142 }
1143
1144 =head2 search_like
1145
1146 =over 4
1147
1148 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1149
1150 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1151
1152 =back
1153
1154   # WHERE title LIKE '%blue%'
1155   $cd_rs = $rs->search_like({ title => '%blue%'});
1156
1157 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1158 that this is simply a convenience method retained for ex Class::DBI users.
1159 You most likely want to use L</search> with specific operators.
1160
1161 For more information, see L<DBIx::Class::Manual::Cookbook>.
1162
1163 This method is deprecated and will be removed in 0.09. Use L</search()>
1164 instead. An example conversion is:
1165
1166   ->search_like({ foo => 'bar' });
1167
1168   # Becomes
1169
1170   ->search({ foo => { like => 'bar' } });
1171
1172 =cut
1173
1174 sub search_like {
1175   my $class = shift;
1176   carp_unique (
1177     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1178    .' Instead use ->search({ x => { -like => "y%" } })'
1179    .' (note the outer pair of {}s - they are important!)'
1180   );
1181   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1182   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1183   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1184   return $class->search($query, { %$attrs });
1185 }
1186
1187 =head2 slice
1188
1189 =over 4
1190
1191 =item Arguments: $first, $last
1192
1193 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1194
1195 =back
1196
1197 Returns a resultset or object list representing a subset of elements from the
1198 resultset slice is called on. Indexes are from 0, i.e., to get the first
1199 three records, call:
1200
1201   my ($one, $two, $three) = $rs->slice(0, 2);
1202
1203 =cut
1204
1205 sub slice {
1206   my ($self, $min, $max) = @_;
1207   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1208   $attrs->{offset} = $self->{attrs}{offset} || 0;
1209   $attrs->{offset} += $min;
1210   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1211   return $self->search(undef, $attrs);
1212   #my $slice = (ref $self)->new($self->result_source, $attrs);
1213   #return (wantarray ? $slice->all : $slice);
1214 }
1215
1216 =head2 next
1217
1218 =over 4
1219
1220 =item Arguments: none
1221
1222 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1223
1224 =back
1225
1226 Returns the next element in the resultset (C<undef> is there is none).
1227
1228 Can be used to efficiently iterate over records in the resultset:
1229
1230   my $rs = $schema->resultset('CD')->search;
1231   while (my $cd = $rs->next) {
1232     print $cd->title;
1233   }
1234
1235 Note that you need to store the resultset object, and call C<next> on it.
1236 Calling C<< resultset('Table')->next >> repeatedly will always return the
1237 first record from the resultset.
1238
1239 =cut
1240
1241 sub next {
1242   my ($self) = @_;
1243
1244   if (my $cache = $self->get_cache) {
1245     $self->{all_cache_position} ||= 0;
1246     return $cache->[$self->{all_cache_position}++];
1247   }
1248
1249   if ($self->{attrs}{cache}) {
1250     delete $self->{pager};
1251     $self->{all_cache_position} = 1;
1252     return ($self->all)[0];
1253   }
1254
1255   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1256
1257   $self->{_stashed_results} = $self->_construct_results
1258     or return undef;
1259
1260   return shift @{$self->{_stashed_results}};
1261 }
1262
1263 # Constructs as many results as it can in one pass while respecting
1264 # cursor laziness. Several modes of operation:
1265 #
1266 # * Always builds everything present in @{$self->{_stashed_rows}}
1267 # * If called with $fetch_all true - pulls everything off the cursor and
1268 #   builds all result structures (or objects) in one pass
1269 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1270 #   and if the resultset is ordered properly by the left side:
1271 #   * Fetches stuff off the cursor until the "master object" changes,
1272 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1273 #   OR
1274 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1275 #     was requested (there is no other way to collapse except for an
1276 #     eager cursor)
1277 # * If no collapse is requested - just get the next row, construct and
1278 #   return
1279 sub _construct_results {
1280   my ($self, $fetch_all) = @_;
1281
1282   my $rsrc = $self->result_source;
1283   my $attrs = $self->_resolved_attrs;
1284
1285   if (
1286     ! $fetch_all
1287       and
1288     ! $attrs->{order_by}
1289       and
1290     $attrs->{collapse}
1291       and
1292     my @pcols = $rsrc->primary_columns
1293   ) {
1294     # default order for collapsing unless the user asked for something
1295     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1296     $attrs->{_ordered_for_collapse} = 1;
1297     $attrs->{_order_is_artificial} = 1;
1298   }
1299
1300   my $cursor = $self->cursor;
1301
1302   # this will be used as both initial raw-row collector AND as a RV of
1303   # _construct_results. Not regrowing the array twice matters a lot...
1304   # a surprising amount actually
1305   my $rows = delete $self->{_stashed_rows};
1306
1307   my $did_fetch_all = $fetch_all;
1308
1309   if ($fetch_all) {
1310     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1311     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1312   }
1313   elsif( $attrs->{collapse} ) {
1314
1315     $attrs->{_ordered_for_collapse} = (!$attrs->{order_by}) ? 0 : do {
1316       my $st = $rsrc->schema->storage;
1317       my @ord_cols = map
1318         { $_->[0] }
1319         ( $st->_extract_order_criteria($attrs->{order_by}) )
1320       ;
1321
1322       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1323
1324       for (0 .. $#ord_cols) {
1325         if (
1326           ! $colinfos->{$ord_cols[$_]}
1327             or
1328           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1329         ) {
1330           splice @ord_cols, $_;
1331           last;
1332         }
1333       }
1334
1335       # since all we check here are the start of the order_by belonging to the
1336       # top level $rsrc, a present identifying set will mean that the resultset
1337       # is ordered by its leftmost table in a tsable manner
1338       (@ord_cols and $rsrc->_identifying_column_set({ map
1339         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1340         @ord_cols
1341       })) ? 1 : 0;
1342     } unless defined $attrs->{_ordered_for_collapse};
1343
1344     if (! $attrs->{_ordered_for_collapse}) {
1345       $did_fetch_all = 1;
1346
1347       # instead of looping over ->next, use ->all in stealth mode
1348       # *without* calling a ->reset afterwards
1349       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1350       if (! $cursor->{_done}) {
1351         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1352         $cursor->{_done} = 1;
1353       }
1354     }
1355   }
1356
1357   if (! $did_fetch_all and ! @{$rows||[]} ) {
1358     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1359     if (scalar (my @r = $cursor->next) ) {
1360       $rows = [ \@r ];
1361     }
1362   }
1363
1364   return undef unless @{$rows||[]};
1365
1366   my @extra_collapser_args;
1367   if ($attrs->{collapse} and ! $did_fetch_all ) {
1368
1369     @extra_collapser_args = (
1370       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1371       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1372       ($self->{_stashed_rows} = []),                # where does it stuff excess
1373     );
1374   }
1375
1376   # hotspot - skip the setter
1377   my $res_class = $self->_result_class;
1378
1379   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1380     $res_class->can ('inflate_result')
1381       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1382   };
1383
1384   my $infmap = $attrs->{as};
1385
1386
1387   $self->{_result_inflator}{is_core_row} = ( (
1388     $inflator_cref
1389       ==
1390     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1391   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1392
1393   $self->{_result_inflator}{is_hri} = ( (
1394     ! $self->{_result_inflator}{is_core_row}
1395       and
1396     $inflator_cref == (
1397       require DBIx::Class::ResultClass::HashRefInflator
1398         &&
1399       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1400     )
1401   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1402
1403
1404   if (! $attrs->{_related_results_construction}) {
1405     # construct a much simpler array->hash folder for the one-table cases right here
1406     if ($self->{_result_inflator}{is_hri}) {
1407       for my $r (@$rows) {
1408         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1409       }
1410     }
1411     # FIXME SUBOPTIMAL this is a very very very hot spot
1412     # while rather optimal we can *still* do much better, by
1413     # building a smarter Row::inflate_result(), and
1414     # switch to feeding it data via a much leaner interface
1415     #
1416     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1417     # this particular resultset size
1418     elsif (@$rows < 60) {
1419       for my $r (@$rows) {
1420         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1421       }
1422     }
1423     else {
1424       eval sprintf (
1425         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1426         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1427       );
1428     }
1429   }
1430   # Special-case multi-object HRI (we always prune, and there is no $inflator_cref pass)
1431   elsif ($self->{_result_inflator}{is_hri}) {
1432     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1433       eval => 1,
1434       inflate_map => $infmap,
1435       selection => $attrs->{select},
1436       collapse => $attrs->{collapse},
1437       premultiplied => $attrs->{_main_source_premultiplied},
1438       hri_style => 1,
1439       prune_null_branches => 1,
1440     }) )->($rows, @extra_collapser_args);
1441   }
1442   # Regular multi-object
1443   else {
1444     my $parser_type = $self->{_result_inflator}{is_core_row} ? 'classic_pruning' : 'classic_nonpruning';
1445
1446     ( $self->{_row_parser}{$parser_type} ||= $rsrc->_mk_row_parser({
1447       eval => 1,
1448       inflate_map => $infmap,
1449       selection => $attrs->{select},
1450       collapse => $attrs->{collapse},
1451       premultiplied => $attrs->{_main_source_premultiplied},
1452       prune_null_branches => $self->{_result_inflator}{is_core_row},
1453     }) )->($rows, @extra_collapser_args);
1454
1455     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1456   }
1457
1458   # The @$rows check seems odd at first - why wouldn't we want to warn
1459   # regardless? The issue is things like find() etc, where the user
1460   # *knows* only one result will come back. In these cases the ->all
1461   # is not a pessimization, but rather something we actually want
1462   carp_unique(
1463     'Unable to properly collapse has_many results in iterator mode due '
1464   . 'to order criteria - performed an eager cursor slurp underneath. '
1465   . 'Consider using ->all() instead'
1466   ) if ( ! $fetch_all and @$rows > 1 );
1467
1468   return $rows;
1469 }
1470
1471 =head2 result_source
1472
1473 =over 4
1474
1475 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1476
1477 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1478
1479 =back
1480
1481 An accessor for the primary ResultSource object from which this ResultSet
1482 is derived.
1483
1484 =head2 result_class
1485
1486 =over 4
1487
1488 =item Arguments: $result_class?
1489
1490 =item Return Value: $result_class
1491
1492 =back
1493
1494 An accessor for the class to use when creating result objects. Defaults to
1495 C<< result_source->result_class >> - which in most cases is the name of the
1496 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1497
1498 Note that changing the result_class will also remove any components
1499 that were originally loaded in the source class via
1500 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1501 in the original source class will not run.
1502
1503 =cut
1504
1505 sub result_class {
1506   my ($self, $result_class) = @_;
1507   if ($result_class) {
1508
1509     # don't fire this for an object
1510     $self->ensure_class_loaded($result_class)
1511       unless ref($result_class);
1512
1513     if ($self->get_cache) {
1514       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1515     }
1516     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1517     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1518       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1519     }
1520
1521     $self->_result_class($result_class);
1522
1523     delete $self->{_result_inflator};
1524   }
1525   $self->_result_class;
1526 }
1527
1528 =head2 count
1529
1530 =over 4
1531
1532 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1533
1534 =item Return Value: $count
1535
1536 =back
1537
1538 Performs an SQL C<COUNT> with the same query as the resultset was built
1539 with to find the number of elements. Passing arguments is equivalent to
1540 C<< $rs->search ($cond, \%attrs)->count >>
1541
1542 =cut
1543
1544 sub count {
1545   my $self = shift;
1546   return $self->search(@_)->count if @_ and defined $_[0];
1547   return scalar @{ $self->get_cache } if $self->get_cache;
1548
1549   my $attrs = { %{ $self->_resolved_attrs } };
1550
1551   # this is a little optimization - it is faster to do the limit
1552   # adjustments in software, instead of a subquery
1553   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1554
1555   my $crs;
1556   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1557     $crs = $self->_count_subq_rs ($attrs);
1558   }
1559   else {
1560     $crs = $self->_count_rs ($attrs);
1561   }
1562   my $count = $crs->next;
1563
1564   $count -= $offset if $offset;
1565   $count = $rows if $rows and $rows < $count;
1566   $count = 0 if ($count < 0);
1567
1568   return $count;
1569 }
1570
1571 =head2 count_rs
1572
1573 =over 4
1574
1575 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1576
1577 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1578
1579 =back
1580
1581 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1582 This can be very handy for subqueries:
1583
1584   ->search( { amount => $some_rs->count_rs->as_query } )
1585
1586 As with regular resultsets the SQL query will be executed only after
1587 the resultset is accessed via L</next> or L</all>. That would return
1588 the same single value obtainable via L</count>.
1589
1590 =cut
1591
1592 sub count_rs {
1593   my $self = shift;
1594   return $self->search(@_)->count_rs if @_;
1595
1596   # this may look like a lack of abstraction (count() does about the same)
1597   # but in fact an _rs *must* use a subquery for the limits, as the
1598   # software based limiting can not be ported if this $rs is to be used
1599   # in a subquery itself (i.e. ->as_query)
1600   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1601     return $self->_count_subq_rs;
1602   }
1603   else {
1604     return $self->_count_rs;
1605   }
1606 }
1607
1608 #
1609 # returns a ResultSetColumn object tied to the count query
1610 #
1611 sub _count_rs {
1612   my ($self, $attrs) = @_;
1613
1614   my $rsrc = $self->result_source;
1615   $attrs ||= $self->_resolved_attrs;
1616
1617   my $tmp_attrs = { %$attrs };
1618   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1619   delete @{$tmp_attrs}{qw/rows offset order_by _related_results_construction record_filter for/};
1620
1621   # overwrite the selector (supplied by the storage)
1622   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1623   $tmp_attrs->{as} = 'count';
1624
1625   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1626
1627   return $tmp_rs;
1628 }
1629
1630 #
1631 # same as above but uses a subquery
1632 #
1633 sub _count_subq_rs {
1634   my ($self, $attrs) = @_;
1635
1636   my $rsrc = $self->result_source;
1637   $attrs ||= $self->_resolved_attrs;
1638
1639   my $sub_attrs = { %$attrs };
1640   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1641   delete @{$sub_attrs}{qw/collapse columns as select _related_results_construction order_by for/};
1642
1643   # if we multi-prefetch we group_by something unique, as this is what we would
1644   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1645   if ( $attrs->{collapse}  ) {
1646     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1647       $rsrc->_identifying_column_set || $self->throw_exception(
1648         'Unable to construct a unique group_by criteria properly collapsing the '
1649       . 'has_many prefetch before count()'
1650       );
1651     } ]
1652   }
1653
1654   # Calculate subquery selector
1655   if (my $g = $sub_attrs->{group_by}) {
1656
1657     my $sql_maker = $rsrc->storage->sql_maker;
1658
1659     # necessary as the group_by may refer to aliased functions
1660     my $sel_index;
1661     for my $sel (@{$attrs->{select}}) {
1662       $sel_index->{$sel->{-as}} = $sel
1663         if (ref $sel eq 'HASH' and $sel->{-as});
1664     }
1665
1666     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1667     # also look for named aggregates referred in the having clause
1668     # having often contains scalarrefs - thus parse it out entirely
1669     my @parts = @$g;
1670     if ($attrs->{having}) {
1671       local $sql_maker->{having_bind};
1672       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1673       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1674       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1675         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1676         # if we don't unset it we screw up retarded but unfortunately working
1677         # 'MAX(foo.bar)' => { '>', 3 }
1678         $sql_maker->{name_sep} = '';
1679       }
1680
1681       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1682
1683       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1684       my %seen_having;
1685
1686       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1687       # and if all fails for an utterly naive quoted scalar-with-function
1688       while ($having_sql =~ /
1689         $rquote $sep $lquote (.+?) $rquote
1690           |
1691         [\s,] \w+ \. (\w+) [\s,]
1692           |
1693         [\s,] $lquote (.+?) $rquote [\s,]
1694       /gx) {
1695         my $part = $1 || $2 || $3;  # one of them matched if we got here
1696         unless ($seen_having{$part}++) {
1697           push @parts, $part;
1698         }
1699       }
1700     }
1701
1702     for (@parts) {
1703       my $colpiece = $sel_index->{$_} || $_;
1704
1705       # unqualify join-based group_by's. Arcane but possible query
1706       # also horrible horrible hack to alias a column (not a func.)
1707       # (probably need to introduce SQLA syntax)
1708       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1709         my $as = $colpiece;
1710         $as =~ s/\./__/;
1711         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1712       }
1713       push @{$sub_attrs->{select}}, $colpiece;
1714     }
1715   }
1716   else {
1717     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1718     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1719   }
1720
1721   return $rsrc->resultset_class
1722                ->new ($rsrc, $sub_attrs)
1723                 ->as_subselect_rs
1724                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1725                   ->get_column ('count');
1726 }
1727
1728
1729 =head2 count_literal
1730
1731 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1732 should only be used in that context. See L</search_literal> for further info.
1733
1734 =over 4
1735
1736 =item Arguments: $sql_fragment, @standalone_bind_values
1737
1738 =item Return Value: $count
1739
1740 =back
1741
1742 Counts the results in a literal query. Equivalent to calling L</search_literal>
1743 with the passed arguments, then L</count>.
1744
1745 =cut
1746
1747 sub count_literal { shift->search_literal(@_)->count; }
1748
1749 =head2 all
1750
1751 =over 4
1752
1753 =item Arguments: none
1754
1755 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1756
1757 =back
1758
1759 Returns all elements in the resultset.
1760
1761 =cut
1762
1763 sub all {
1764   my $self = shift;
1765   if(@_) {
1766     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1767   }
1768
1769   delete @{$self}{qw/_stashed_rows _stashed_results/};
1770
1771   if (my $c = $self->get_cache) {
1772     return @$c;
1773   }
1774
1775   $self->cursor->reset;
1776
1777   my $objs = $self->_construct_results('fetch_all') || [];
1778
1779   $self->set_cache($objs) if $self->{attrs}{cache};
1780
1781   return @$objs;
1782 }
1783
1784 =head2 reset
1785
1786 =over 4
1787
1788 =item Arguments: none
1789
1790 =item Return Value: $self
1791
1792 =back
1793
1794 Resets the resultset's cursor, so you can iterate through the elements again.
1795 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1796 another query.
1797
1798 =cut
1799
1800 sub reset {
1801   my ($self) = @_;
1802
1803   delete @{$self}{qw/_stashed_rows _stashed_results/};
1804   $self->{all_cache_position} = 0;
1805   $self->cursor->reset;
1806   return $self;
1807 }
1808
1809 =head2 first
1810
1811 =over 4
1812
1813 =item Arguments: none
1814
1815 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1816
1817 =back
1818
1819 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1820 an object for the first result (or C<undef> if the resultset is empty).
1821
1822 =cut
1823
1824 sub first {
1825   return $_[0]->reset->next;
1826 }
1827
1828
1829 # _rs_update_delete
1830 #
1831 # Determines whether and what type of subquery is required for the $rs operation.
1832 # If grouping is necessary either supplies its own, or verifies the current one
1833 # After all is done delegates to the proper storage method.
1834
1835 sub _rs_update_delete {
1836   my ($self, $op, $values) = @_;
1837
1838   my $rsrc = $self->result_source;
1839   my $storage = $rsrc->schema->storage;
1840
1841   my $attrs = { %{$self->_resolved_attrs} };
1842
1843   my $join_classifications;
1844   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1845
1846   # do we need a subquery for any reason?
1847   my $needs_subq = (
1848     defined $existing_group_by
1849       or
1850     # if {from} is unparseable wrap a subq
1851     ref($attrs->{from}) ne 'ARRAY'
1852       or
1853     # limits call for a subq
1854     $self->_has_resolved_attr(qw/rows offset/)
1855   );
1856
1857   # simplify the joinmap, so we can further decide if a subq is necessary
1858   if (!$needs_subq and @{$attrs->{from}} > 1) {
1859     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1860
1861     # check if there are any joins left after the prune
1862     if ( @{$attrs->{from}} > 1 ) {
1863       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1864         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1865         $attrs->{select},
1866         $self->{cond},
1867         $attrs
1868       );
1869
1870       # any non-pruneable joins imply subq
1871       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1872     }
1873   }
1874
1875   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1876   $needs_subq ||= (
1877     (ref $attrs->{from}[0]) ne 'HASH'
1878       or
1879     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1880   );
1881
1882   my ($cond, $guard);
1883   # do we need anything like a subquery?
1884   if (! $needs_subq) {
1885     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1886     # a condition containing 'me' or other table prefixes will not work
1887     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1888     $cond = do {
1889       my $sqla = $rsrc->storage->sql_maker;
1890       local $sqla->{_dequalify_idents} = 1;
1891       \[ $sqla->_recurse_where($self->{cond}) ];
1892     };
1893   }
1894   else {
1895     # we got this far - means it is time to wrap a subquery
1896     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1897       sprintf(
1898         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1899         $op,
1900         $rsrc->source_name,
1901       )
1902     );
1903
1904     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1905     delete $attrs->{$_} for qw/select as collapse _related_results_construction/;
1906     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1907     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1908     my $subrs = (ref $self)->new($rsrc, $attrs);
1909
1910     if (@$idcols == 1) {
1911       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1912     }
1913     elsif ($storage->_use_multicolumn_in) {
1914       # no syntax for calling this properly yet
1915       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1916       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1917         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1918         $subrs->as_query
1919       ),
1920     }
1921     else {
1922       # if all else fails - get all primary keys and operate over a ORed set
1923       # wrap in a transaction for consistency
1924       # this is where the group_by/multiplication starts to matter
1925       if (
1926         $existing_group_by
1927           or
1928         keys %{ $join_classifications->{multiplying} || {} }
1929       ) {
1930         # make sure if there is a supplied group_by it matches the columns compiled above
1931         # perfectly. Anything else can not be sanely executed on most databases so croak
1932         # right then and there
1933         if ($existing_group_by) {
1934           my @current_group_by = map
1935             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1936             @$existing_group_by
1937           ;
1938
1939           if (
1940             join ("\x00", sort @current_group_by)
1941               ne
1942             join ("\x00", sort @{$attrs->{columns}} )
1943           ) {
1944             $self->throw_exception (
1945               "You have just attempted a $op operation on a resultset which does group_by"
1946               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1947               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1948               . ' kind of queries. Please retry the operation with a modified group_by or'
1949               . ' without using one at all.'
1950             );
1951           }
1952         }
1953
1954         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1955       }
1956
1957       $guard = $storage->txn_scope_guard;
1958
1959       $cond = [];
1960       for my $row ($subrs->cursor->all) {
1961         push @$cond, { map
1962           { $idcols->[$_] => $row->[$_] }
1963           (0 .. $#$idcols)
1964         };
1965       }
1966     }
1967   }
1968
1969   my $res = $storage->$op (
1970     $rsrc,
1971     $op eq 'update' ? $values : (),
1972     $cond,
1973   );
1974
1975   $guard->commit if $guard;
1976
1977   return $res;
1978 }
1979
1980 =head2 update
1981
1982 =over 4
1983
1984 =item Arguments: \%values
1985
1986 =item Return Value: $underlying_storage_rv
1987
1988 =back
1989
1990 Sets the specified columns in the resultset to the supplied values in a
1991 single query. Note that this will not run any accessor/set_column/update
1992 triggers, nor will it update any result object instances derived from this
1993 resultset (this includes the contents of the L<resultset cache|/set_cache>
1994 if any). See L</update_all> if you need to execute any on-update
1995 triggers or cascades defined either by you or a
1996 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1997
1998 The return value is a pass through of what the underlying
1999 storage backend returned, and may vary. See L<DBI/execute> for the most
2000 common case.
2001
2002 =head3 CAVEAT
2003
2004 Note that L</update> does not process/deflate any of the values passed in.
2005 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2006 ensure manually that any value passed to this method will stringify to
2007 something the RDBMS knows how to deal with. A notable example is the
2008 handling of L<DateTime> objects, for more info see:
2009 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2010
2011 =cut
2012
2013 sub update {
2014   my ($self, $values) = @_;
2015   $self->throw_exception('Values for update must be a hash')
2016     unless ref $values eq 'HASH';
2017
2018   return $self->_rs_update_delete ('update', $values);
2019 }
2020
2021 =head2 update_all
2022
2023 =over 4
2024
2025 =item Arguments: \%values
2026
2027 =item Return Value: 1
2028
2029 =back
2030
2031 Fetches all objects and updates them one at a time via
2032 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2033 triggers, while L</update> will not.
2034
2035 =cut
2036
2037 sub update_all {
2038   my ($self, $values) = @_;
2039   $self->throw_exception('Values for update_all must be a hash')
2040     unless ref $values eq 'HASH';
2041
2042   my $guard = $self->result_source->schema->txn_scope_guard;
2043   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2044   $guard->commit;
2045   return 1;
2046 }
2047
2048 =head2 delete
2049
2050 =over 4
2051
2052 =item Arguments: none
2053
2054 =item Return Value: $underlying_storage_rv
2055
2056 =back
2057
2058 Deletes the rows matching this resultset in a single query. Note that this
2059 will not run any delete triggers, nor will it alter the
2060 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2061 derived from this resultset (this includes the contents of the
2062 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2063 execute any on-delete triggers or cascades defined either by you or a
2064 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2065
2066 The return value is a pass through of what the underlying storage backend
2067 returned, and may vary. See L<DBI/execute> for the most common case.
2068
2069 =cut
2070
2071 sub delete {
2072   my $self = shift;
2073   $self->throw_exception('delete does not accept any arguments')
2074     if @_;
2075
2076   return $self->_rs_update_delete ('delete');
2077 }
2078
2079 =head2 delete_all
2080
2081 =over 4
2082
2083 =item Arguments: none
2084
2085 =item Return Value: 1
2086
2087 =back
2088
2089 Fetches all objects and deletes them one at a time via
2090 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2091 triggers, while L</delete> will not.
2092
2093 =cut
2094
2095 sub delete_all {
2096   my $self = shift;
2097   $self->throw_exception('delete_all does not accept any arguments')
2098     if @_;
2099
2100   my $guard = $self->result_source->schema->txn_scope_guard;
2101   $_->delete for $self->all;
2102   $guard->commit;
2103   return 1;
2104 }
2105
2106 =head2 populate
2107
2108 =over 4
2109
2110 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2111
2112 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2113
2114 =back
2115
2116 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2117 arrayrefs.
2118
2119 =over
2120
2121 =item NOTE
2122
2123 The context of this method call has an important effect on what is
2124 submitted to storage. In void context data is fed directly to fastpath
2125 insertion routines provided by the underlying storage (most often
2126 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2127 L<insert|DBIx::Class::Row/insert> calls on the
2128 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2129 augmentation of these methods provided by components. For example if you
2130 are using something like L<DBIx::Class::UUIDColumns> to create primary
2131 keys for you, you will find that your PKs are empty.  In this case you
2132 will have to explicitly force scalar or list context in order to create
2133 those values.
2134
2135 =back
2136
2137 In non-void (scalar or list) context, this method is simply a wrapper
2138 for L</create>. Depending on list or scalar context either a list of
2139 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2140 containing these objects is returned.
2141
2142 When supplying data in "arrayref of arrayrefs" invocation style, the
2143 first element should be a list of column names and each subsequent
2144 element should be a data value in the earlier specified column order.
2145 For example:
2146
2147   $Arstist_rs->populate([
2148     [ qw( artistid name ) ],
2149     [ 100, 'A Formally Unknown Singer' ],
2150     [ 101, 'A singer that jumped the shark two albums ago' ],
2151     [ 102, 'An actually cool singer' ],
2152   ]);
2153
2154 For the arrayref of hashrefs style each hashref should be a structure
2155 suitable for passing to L</create>. Multi-create is also permitted with
2156 this syntax.
2157
2158   $schema->resultset("Artist")->populate([
2159      { artistid => 4, name => 'Manufactured Crap', cds => [
2160         { title => 'My First CD', year => 2006 },
2161         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2162       ],
2163      },
2164      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2165         { title => 'My parents sold me to a record company', year => 2005 },
2166         { title => 'Why Am I So Ugly?', year => 2006 },
2167         { title => 'I Got Surgery and am now Popular', year => 2007 }
2168       ],
2169      },
2170   ]);
2171
2172 If you attempt a void-context multi-create as in the example above (each
2173 Artist also has the related list of CDs), and B<do not> supply the
2174 necessary autoinc foreign key information, this method will proxy to the
2175 less efficient L</create>, and then throw the Result objects away. In this
2176 case there are obviously no benefits to using this method over L</create>.
2177
2178 =cut
2179
2180 sub populate {
2181   my $self = shift;
2182
2183   # cruft placed in standalone method
2184   my $data = $self->_normalize_populate_args(@_);
2185
2186   return unless @$data;
2187
2188   if(defined wantarray) {
2189     my @created = map { $self->create($_) } @$data;
2190     return wantarray ? @created : \@created;
2191   }
2192   else {
2193     my $first = $data->[0];
2194
2195     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2196     # it relationship data
2197     my (@rels, @columns);
2198     my $rsrc = $self->result_source;
2199     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2200     for (keys %$first) {
2201       my $ref = ref $first->{$_};
2202       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2203         ? push @rels, $_
2204         : push @columns, $_
2205       ;
2206     }
2207
2208     my @pks = $rsrc->primary_columns;
2209
2210     ## do the belongs_to relationships
2211     foreach my $index (0..$#$data) {
2212
2213       # delegate to create() for any dataset without primary keys with specified relationships
2214       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2215         for my $r (@rels) {
2216           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2217             my @ret = $self->populate($data);
2218             return;
2219           }
2220         }
2221       }
2222
2223       foreach my $rel (@rels) {
2224         next unless ref $data->[$index]->{$rel} eq "HASH";
2225         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2226         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2227         my $related = $result->result_source->_resolve_condition(
2228           $reverse_relinfo->{cond},
2229           $self,
2230           $result,
2231           $rel,
2232         );
2233
2234         delete $data->[$index]->{$rel};
2235         $data->[$index] = {%{$data->[$index]}, %$related};
2236
2237         push @columns, keys %$related if $index == 0;
2238       }
2239     }
2240
2241     ## inherit the data locked in the conditions of the resultset
2242     my ($rs_data) = $self->_merge_with_rscond({});
2243     delete @{$rs_data}{@columns};
2244
2245     ## do bulk insert on current row
2246     $rsrc->storage->insert_bulk(
2247       $rsrc,
2248       [@columns, keys %$rs_data],
2249       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2250     );
2251
2252     ## do the has_many relationships
2253     foreach my $item (@$data) {
2254
2255       my $main_row;
2256
2257       foreach my $rel (@rels) {
2258         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2259
2260         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2261
2262         my $child = $main_row->$rel;
2263
2264         my $related = $child->result_source->_resolve_condition(
2265           $rels->{$rel}{cond},
2266           $child,
2267           $main_row,
2268           $rel,
2269         );
2270
2271         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2272         my @populate = map { {%$_, %$related} } @rows_to_add;
2273
2274         $child->populate( \@populate );
2275       }
2276     }
2277   }
2278 }
2279
2280
2281 # populate() argumnets went over several incarnations
2282 # What we ultimately support is AoH
2283 sub _normalize_populate_args {
2284   my ($self, $arg) = @_;
2285
2286   if (ref $arg eq 'ARRAY') {
2287     if (!@$arg) {
2288       return [];
2289     }
2290     elsif (ref $arg->[0] eq 'HASH') {
2291       return $arg;
2292     }
2293     elsif (ref $arg->[0] eq 'ARRAY') {
2294       my @ret;
2295       my @colnames = @{$arg->[0]};
2296       foreach my $values (@{$arg}[1 .. $#$arg]) {
2297         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2298       }
2299       return \@ret;
2300     }
2301   }
2302
2303   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2304 }
2305
2306 =head2 pager
2307
2308 =over 4
2309
2310 =item Arguments: none
2311
2312 =item Return Value: L<$pager|Data::Page>
2313
2314 =back
2315
2316 Returns a L<Data::Page> object for the current resultset. Only makes
2317 sense for queries with a C<page> attribute.
2318
2319 To get the full count of entries for a paged resultset, call
2320 C<total_entries> on the L<Data::Page> object.
2321
2322 =cut
2323
2324 sub pager {
2325   my ($self) = @_;
2326
2327   return $self->{pager} if $self->{pager};
2328
2329   my $attrs = $self->{attrs};
2330   if (!defined $attrs->{page}) {
2331     $self->throw_exception("Can't create pager for non-paged rs");
2332   }
2333   elsif ($attrs->{page} <= 0) {
2334     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2335   }
2336   $attrs->{rows} ||= 10;
2337
2338   # throw away the paging flags and re-run the count (possibly
2339   # with a subselect) to get the real total count
2340   my $count_attrs = { %$attrs };
2341   delete @{$count_attrs}{qw/rows offset page pager/};
2342
2343   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2344
2345   require DBIx::Class::ResultSet::Pager;
2346   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2347     sub { $total_rs->count },  #lazy-get the total
2348     $attrs->{rows},
2349     $self->{attrs}{page},
2350   );
2351 }
2352
2353 =head2 page
2354
2355 =over 4
2356
2357 =item Arguments: $page_number
2358
2359 =item Return Value: L<$resultset|/search>
2360
2361 =back
2362
2363 Returns a resultset for the $page_number page of the resultset on which page
2364 is called, where each page contains a number of rows equal to the 'rows'
2365 attribute set on the resultset (10 by default).
2366
2367 =cut
2368
2369 sub page {
2370   my ($self, $page) = @_;
2371   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2372 }
2373
2374 =head2 new_result
2375
2376 =over 4
2377
2378 =item Arguments: \%col_data
2379
2380 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2381
2382 =back
2383
2384 Creates a new result object in the resultset's result class and returns
2385 it. The row is not inserted into the database at this point, call
2386 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2387 will tell you whether the result object has been inserted or not.
2388
2389 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2390
2391 =cut
2392
2393 sub new_result {
2394   my ($self, $values) = @_;
2395
2396   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2397     if @_ > 2;
2398
2399   $self->throw_exception( "new_result expects a hashref" )
2400     unless (ref $values eq 'HASH');
2401
2402   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2403
2404   my $new = $self->result_class->new({
2405     %$merged_cond,
2406     ( @$cols_from_relations
2407       ? (-cols_from_relations => $cols_from_relations)
2408       : ()
2409     ),
2410     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2411   });
2412
2413   if (
2414     reftype($new) eq 'HASH'
2415       and
2416     ! keys %$new
2417       and
2418     blessed($new)
2419   ) {
2420     carp_unique (sprintf (
2421       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2422       $self->result_class,
2423     ));
2424   }
2425
2426   $new;
2427 }
2428
2429 # _merge_with_rscond
2430 #
2431 # Takes a simple hash of K/V data and returns its copy merged with the
2432 # condition already present on the resultset. Additionally returns an
2433 # arrayref of value/condition names, which were inferred from related
2434 # objects (this is needed for in-memory related objects)
2435 sub _merge_with_rscond {
2436   my ($self, $data) = @_;
2437
2438   my (%new_data, @cols_from_relations);
2439
2440   my $alias = $self->{attrs}{alias};
2441
2442   if (! defined $self->{cond}) {
2443     # just massage $data below
2444   }
2445   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2446     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2447     @cols_from_relations = keys %new_data;
2448   }
2449   elsif (ref $self->{cond} ne 'HASH') {
2450     $self->throw_exception(
2451       "Can't abstract implicit construct, resultset condition not a hash"
2452     );
2453   }
2454   else {
2455     # precendence must be given to passed values over values inherited from
2456     # the cond, so the order here is important.
2457     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2458     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2459
2460     while ( my($col, $value) = each %implied ) {
2461       my $vref = ref $value;
2462       if (
2463         $vref eq 'HASH'
2464           and
2465         keys(%$value) == 1
2466           and
2467         (keys %$value)[0] eq '='
2468       ) {
2469         $new_data{$col} = $value->{'='};
2470       }
2471       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2472         $new_data{$col} = $value;
2473       }
2474     }
2475   }
2476
2477   %new_data = (
2478     %new_data,
2479     %{ $self->_remove_alias($data, $alias) },
2480   );
2481
2482   return (\%new_data, \@cols_from_relations);
2483 }
2484
2485 # _has_resolved_attr
2486 #
2487 # determines if the resultset defines at least one
2488 # of the attributes supplied
2489 #
2490 # used to determine if a subquery is neccessary
2491 #
2492 # supports some virtual attributes:
2493 #   -join
2494 #     This will scan for any joins being present on the resultset.
2495 #     It is not a mere key-search but a deep inspection of {from}
2496 #
2497
2498 sub _has_resolved_attr {
2499   my ($self, @attr_names) = @_;
2500
2501   my $attrs = $self->_resolved_attrs;
2502
2503   my %extra_checks;
2504
2505   for my $n (@attr_names) {
2506     if (grep { $n eq $_ } (qw/-join/) ) {
2507       $extra_checks{$n}++;
2508       next;
2509     }
2510
2511     my $attr =  $attrs->{$n};
2512
2513     next if not defined $attr;
2514
2515     if (ref $attr eq 'HASH') {
2516       return 1 if keys %$attr;
2517     }
2518     elsif (ref $attr eq 'ARRAY') {
2519       return 1 if @$attr;
2520     }
2521     else {
2522       return 1 if $attr;
2523     }
2524   }
2525
2526   # a resolved join is expressed as a multi-level from
2527   return 1 if (
2528     $extra_checks{-join}
2529       and
2530     ref $attrs->{from} eq 'ARRAY'
2531       and
2532     @{$attrs->{from}} > 1
2533   );
2534
2535   return 0;
2536 }
2537
2538 # _collapse_cond
2539 #
2540 # Recursively collapse the condition.
2541
2542 sub _collapse_cond {
2543   my ($self, $cond, $collapsed) = @_;
2544
2545   $collapsed ||= {};
2546
2547   if (ref $cond eq 'ARRAY') {
2548     foreach my $subcond (@$cond) {
2549       next unless ref $subcond;  # -or
2550       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2551     }
2552   }
2553   elsif (ref $cond eq 'HASH') {
2554     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2555       foreach my $subcond (@{$cond->{-and}}) {
2556         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2557       }
2558     }
2559     else {
2560       foreach my $col (keys %$cond) {
2561         my $value = $cond->{$col};
2562         $collapsed->{$col} = $value;
2563       }
2564     }
2565   }
2566
2567   return $collapsed;
2568 }
2569
2570 # _remove_alias
2571 #
2572 # Remove the specified alias from the specified query hash. A copy is made so
2573 # the original query is not modified.
2574
2575 sub _remove_alias {
2576   my ($self, $query, $alias) = @_;
2577
2578   my %orig = %{ $query || {} };
2579   my %unaliased;
2580
2581   foreach my $key (keys %orig) {
2582     if ($key !~ /\./) {
2583       $unaliased{$key} = $orig{$key};
2584       next;
2585     }
2586     $unaliased{$1} = $orig{$key}
2587       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2588   }
2589
2590   return \%unaliased;
2591 }
2592
2593 =head2 as_query
2594
2595 =over 4
2596
2597 =item Arguments: none
2598
2599 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2600
2601 =back
2602
2603 Returns the SQL query and bind vars associated with the invocant.
2604
2605 This is generally used as the RHS for a subquery.
2606
2607 =cut
2608
2609 sub as_query {
2610   my $self = shift;
2611
2612   my $attrs = { %{ $self->_resolved_attrs } };
2613
2614   $self->result_source->storage->_select_args_to_query (
2615     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2616   );
2617 }
2618
2619 =head2 find_or_new
2620
2621 =over 4
2622
2623 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2624
2625 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2626
2627 =back
2628
2629   my $artist = $schema->resultset('Artist')->find_or_new(
2630     { artist => 'fred' }, { key => 'artists' });
2631
2632   $cd->cd_to_producer->find_or_new({ producer => $producer },
2633                                    { key => 'primary });
2634
2635 Find an existing record from this resultset using L</find>. if none exists,
2636 instantiate a new result object and return it. The object will not be saved
2637 into your storage until you call L<DBIx::Class::Row/insert> on it.
2638
2639 You most likely want this method when looking for existing rows using a unique
2640 constraint that is not the primary key, or looking for related rows.
2641
2642 If you want objects to be saved immediately, use L</find_or_create> instead.
2643
2644 B<Note>: Make sure to read the documentation of L</find> and understand the
2645 significance of the C<key> attribute, as its lack may skew your search, and
2646 subsequently result in spurious new objects.
2647
2648 B<Note>: Take care when using C<find_or_new> with a table having
2649 columns with default values that you intend to be automatically
2650 supplied by the database (e.g. an auto_increment primary key column).
2651 In normal usage, the value of such columns should NOT be included at
2652 all in the call to C<find_or_new>, even when set to C<undef>.
2653
2654 =cut
2655
2656 sub find_or_new {
2657   my $self     = shift;
2658   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2659   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2660   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2661     return $row;
2662   }
2663   return $self->new_result($hash);
2664 }
2665
2666 =head2 create
2667
2668 =over 4
2669
2670 =item Arguments: \%col_data
2671
2672 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2673
2674 =back
2675
2676 Attempt to create a single new row or a row with multiple related rows
2677 in the table represented by the resultset (and related tables). This
2678 will not check for duplicate rows before inserting, use
2679 L</find_or_create> to do that.
2680
2681 To create one row for this resultset, pass a hashref of key/value
2682 pairs representing the columns of the table and the values you wish to
2683 store. If the appropriate relationships are set up, foreign key fields
2684 can also be passed an object representing the foreign row, and the
2685 value will be set to its primary key.
2686
2687 To create related objects, pass a hashref of related-object column values
2688 B<keyed on the relationship name>. If the relationship is of type C<multi>
2689 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2690 The process will correctly identify columns holding foreign keys, and will
2691 transparently populate them from the keys of the corresponding relation.
2692 This can be applied recursively, and will work correctly for a structure
2693 with an arbitrary depth and width, as long as the relationships actually
2694 exists and the correct column data has been supplied.
2695
2696 Instead of hashrefs of plain related data (key/value pairs), you may
2697 also pass new or inserted objects. New objects (not inserted yet, see
2698 L</new_result>), will be inserted into their appropriate tables.
2699
2700 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2701
2702 Example of creating a new row.
2703
2704   $person_rs->create({
2705     name=>"Some Person",
2706     email=>"somebody@someplace.com"
2707   });
2708
2709 Example of creating a new row and also creating rows in a related C<has_many>
2710 or C<has_one> resultset.  Note Arrayref.
2711
2712   $artist_rs->create(
2713      { artistid => 4, name => 'Manufactured Crap', cds => [
2714         { title => 'My First CD', year => 2006 },
2715         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2716       ],
2717      },
2718   );
2719
2720 Example of creating a new row and also creating a row in a related
2721 C<belongs_to> resultset. Note Hashref.
2722
2723   $cd_rs->create({
2724     title=>"Music for Silly Walks",
2725     year=>2000,
2726     artist => {
2727       name=>"Silly Musician",
2728     }
2729   });
2730
2731 =over
2732
2733 =item WARNING
2734
2735 When subclassing ResultSet never attempt to override this method. Since
2736 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2737 lot of the internals simply never call it, so your override will be
2738 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2739 or L<DBIx::Class::Row/insert> depending on how early in the
2740 L</create> process you need to intervene. See also warning pertaining to
2741 L</new>.
2742
2743 =back
2744
2745 =cut
2746
2747 sub create {
2748   my ($self, $col_data) = @_;
2749   $self->throw_exception( "create needs a hashref" )
2750     unless ref $col_data eq 'HASH';
2751   return $self->new_result($col_data)->insert;
2752 }
2753
2754 =head2 find_or_create
2755
2756 =over 4
2757
2758 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2759
2760 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2761
2762 =back
2763
2764   $cd->cd_to_producer->find_or_create({ producer => $producer },
2765                                       { key => 'primary' });
2766
2767 Tries to find a record based on its primary key or unique constraints; if none
2768 is found, creates one and returns that instead.
2769
2770   my $cd = $schema->resultset('CD')->find_or_create({
2771     cdid   => 5,
2772     artist => 'Massive Attack',
2773     title  => 'Mezzanine',
2774     year   => 2005,
2775   });
2776
2777 Also takes an optional C<key> attribute, to search by a specific key or unique
2778 constraint. For example:
2779
2780   my $cd = $schema->resultset('CD')->find_or_create(
2781     {
2782       artist => 'Massive Attack',
2783       title  => 'Mezzanine',
2784     },
2785     { key => 'cd_artist_title' }
2786   );
2787
2788 B<Note>: Make sure to read the documentation of L</find> and understand the
2789 significance of the C<key> attribute, as its lack may skew your search, and
2790 subsequently result in spurious row creation.
2791
2792 B<Note>: Because find_or_create() reads from the database and then
2793 possibly inserts based on the result, this method is subject to a race
2794 condition. Another process could create a record in the table after
2795 the find has completed and before the create has started. To avoid
2796 this problem, use find_or_create() inside a transaction.
2797
2798 B<Note>: Take care when using C<find_or_create> with a table having
2799 columns with default values that you intend to be automatically
2800 supplied by the database (e.g. an auto_increment primary key column).
2801 In normal usage, the value of such columns should NOT be included at
2802 all in the call to C<find_or_create>, even when set to C<undef>.
2803
2804 See also L</find> and L</update_or_create>. For information on how to declare
2805 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2806
2807 If you need to know if an existing row was found or a new one created use
2808 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2809 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2810 database!
2811
2812   my $cd = $schema->resultset('CD')->find_or_new({
2813     cdid   => 5,
2814     artist => 'Massive Attack',
2815     title  => 'Mezzanine',
2816     year   => 2005,
2817   });
2818
2819   if( !$cd->in_storage ) {
2820       # do some stuff
2821       $cd->insert;
2822   }
2823
2824 =cut
2825
2826 sub find_or_create {
2827   my $self     = shift;
2828   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2829   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2830   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2831     return $row;
2832   }
2833   return $self->create($hash);
2834 }
2835
2836 =head2 update_or_create
2837
2838 =over 4
2839
2840 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2841
2842 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2843
2844 =back
2845
2846   $resultset->update_or_create({ col => $val, ... });
2847
2848 Like L</find_or_create>, but if a row is found it is immediately updated via
2849 C<< $found_row->update (\%col_data) >>.
2850
2851
2852 Takes an optional C<key> attribute to search on a specific unique constraint.
2853 For example:
2854
2855   # In your application
2856   my $cd = $schema->resultset('CD')->update_or_create(
2857     {
2858       artist => 'Massive Attack',
2859       title  => 'Mezzanine',
2860       year   => 1998,
2861     },
2862     { key => 'cd_artist_title' }
2863   );
2864
2865   $cd->cd_to_producer->update_or_create({
2866     producer => $producer,
2867     name => 'harry',
2868   }, {
2869     key => 'primary',
2870   });
2871
2872 B<Note>: Make sure to read the documentation of L</find> and understand the
2873 significance of the C<key> attribute, as its lack may skew your search, and
2874 subsequently result in spurious row creation.
2875
2876 B<Note>: Take care when using C<update_or_create> with a table having
2877 columns with default values that you intend to be automatically
2878 supplied by the database (e.g. an auto_increment primary key column).
2879 In normal usage, the value of such columns should NOT be included at
2880 all in the call to C<update_or_create>, even when set to C<undef>.
2881
2882 See also L</find> and L</find_or_create>. For information on how to declare
2883 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2884
2885 If you need to know if an existing row was updated or a new one created use
2886 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2887 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2888 database!
2889
2890 =cut
2891
2892 sub update_or_create {
2893   my $self = shift;
2894   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2895   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2896
2897   my $row = $self->find($cond, $attrs);
2898   if (defined $row) {
2899     $row->update($cond);
2900     return $row;
2901   }
2902
2903   return $self->create($cond);
2904 }
2905
2906 =head2 update_or_new
2907
2908 =over 4
2909
2910 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2911
2912 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2913
2914 =back
2915
2916   $resultset->update_or_new({ col => $val, ... });
2917
2918 Like L</find_or_new> but if a row is found it is immediately updated via
2919 C<< $found_row->update (\%col_data) >>.
2920
2921 For example:
2922
2923   # In your application
2924   my $cd = $schema->resultset('CD')->update_or_new(
2925     {
2926       artist => 'Massive Attack',
2927       title  => 'Mezzanine',
2928       year   => 1998,
2929     },
2930     { key => 'cd_artist_title' }
2931   );
2932
2933   if ($cd->in_storage) {
2934       # the cd was updated
2935   }
2936   else {
2937       # the cd is not yet in the database, let's insert it
2938       $cd->insert;
2939   }
2940
2941 B<Note>: Make sure to read the documentation of L</find> and understand the
2942 significance of the C<key> attribute, as its lack may skew your search, and
2943 subsequently result in spurious new objects.
2944
2945 B<Note>: Take care when using C<update_or_new> with a table having
2946 columns with default values that you intend to be automatically
2947 supplied by the database (e.g. an auto_increment primary key column).
2948 In normal usage, the value of such columns should NOT be included at
2949 all in the call to C<update_or_new>, even when set to C<undef>.
2950
2951 See also L</find>, L</find_or_create> and L</find_or_new>.
2952
2953 =cut
2954
2955 sub update_or_new {
2956     my $self  = shift;
2957     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2958     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2959
2960     my $row = $self->find( $cond, $attrs );
2961     if ( defined $row ) {
2962         $row->update($cond);
2963         return $row;
2964     }
2965
2966     return $self->new_result($cond);
2967 }
2968
2969 =head2 get_cache
2970
2971 =over 4
2972
2973 =item Arguments: none
2974
2975 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2976
2977 =back
2978
2979 Gets the contents of the cache for the resultset, if the cache is set.
2980
2981 The cache is populated either by using the L</prefetch> attribute to
2982 L</search> or by calling L</set_cache>.
2983
2984 =cut
2985
2986 sub get_cache {
2987   shift->{all_cache};
2988 }
2989
2990 =head2 set_cache
2991
2992 =over 4
2993
2994 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2995
2996 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2997
2998 =back
2999
3000 Sets the contents of the cache for the resultset. Expects an arrayref
3001 of objects of the same class as those produced by the resultset. Note that
3002 if the cache is set, the resultset will return the cached objects rather
3003 than re-querying the database even if the cache attr is not set.
3004
3005 The contents of the cache can also be populated by using the
3006 L</prefetch> attribute to L</search>.
3007
3008 =cut
3009
3010 sub set_cache {
3011   my ( $self, $data ) = @_;
3012   $self->throw_exception("set_cache requires an arrayref")
3013       if defined($data) && (ref $data ne 'ARRAY');
3014   $self->{all_cache} = $data;
3015 }
3016
3017 =head2 clear_cache
3018
3019 =over 4
3020
3021 =item Arguments: none
3022
3023 =item Return Value: undef
3024
3025 =back
3026
3027 Clears the cache for the resultset.
3028
3029 =cut
3030
3031 sub clear_cache {
3032   shift->set_cache(undef);
3033 }
3034
3035 =head2 is_paged
3036
3037 =over 4
3038
3039 =item Arguments: none
3040
3041 =item Return Value: true, if the resultset has been paginated
3042
3043 =back
3044
3045 =cut
3046
3047 sub is_paged {
3048   my ($self) = @_;
3049   return !!$self->{attrs}{page};
3050 }
3051
3052 =head2 is_ordered
3053
3054 =over 4
3055
3056 =item Arguments: none
3057
3058 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3059
3060 =back
3061
3062 =cut
3063
3064 sub is_ordered {
3065   my ($self) = @_;
3066   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3067 }
3068
3069 =head2 related_resultset
3070
3071 =over 4
3072
3073 =item Arguments: $rel_name
3074
3075 =item Return Value: L<$resultset|/search>
3076
3077 =back
3078
3079 Returns a related resultset for the supplied relationship name.
3080
3081   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3082
3083 =cut
3084
3085 sub related_resultset {
3086   my ($self, $rel) = @_;
3087
3088   return $self->{related_resultsets}{$rel}
3089     if defined $self->{related_resultsets}{$rel};
3090
3091   return $self->{related_resultsets}{$rel} = do {
3092     my $rsrc = $self->result_source;
3093     my $rel_info = $rsrc->relationship_info($rel);
3094
3095     $self->throw_exception(
3096       "search_related: result source '" . $rsrc->source_name .
3097         "' has no such relationship $rel")
3098       unless $rel_info;
3099
3100     my $attrs = $self->_chain_relationship($rel);
3101
3102     my $join_count = $attrs->{seen_join}{$rel};
3103
3104     my $alias = $self->result_source->storage
3105         ->relname_to_table_alias($rel, $join_count);
3106
3107     # since this is search_related, and we already slid the select window inwards
3108     # (the select/as attrs were deleted in the beginning), we need to flip all
3109     # left joins to inner, so we get the expected results
3110     # read the comment on top of the actual function to see what this does
3111     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3112
3113
3114     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3115     delete @{$attrs}{qw(result_class alias)};
3116
3117     my $related_cache;
3118
3119     if (my $cache = $self->get_cache) {
3120       $related_cache = [ map
3121         { @{$_->related_resultset($rel)->get_cache||[]} }
3122         @$cache
3123       ];
3124     }
3125
3126     my $rel_source = $rsrc->related_source($rel);
3127
3128     my $new = do {
3129
3130       # The reason we do this now instead of passing the alias to the
3131       # search_rs below is that if you wrap/overload resultset on the
3132       # source you need to know what alias it's -going- to have for things
3133       # to work sanely (e.g. RestrictWithObject wants to be able to add
3134       # extra query restrictions, and these may need to be $alias.)
3135
3136       my $rel_attrs = $rel_source->resultset_attributes;
3137       local $rel_attrs->{alias} = $alias;
3138
3139       $rel_source->resultset
3140                  ->search_rs(
3141                      undef, {
3142                        %$attrs,
3143                        where => $attrs->{where},
3144                    });
3145     };
3146     $new->set_cache($related_cache) if $related_cache;
3147     $new;
3148   };
3149 }
3150
3151 =head2 current_source_alias
3152
3153 =over 4
3154
3155 =item Arguments: none
3156
3157 =item Return Value: $source_alias
3158
3159 =back
3160
3161 Returns the current table alias for the result source this resultset is built
3162 on, that will be used in the SQL query. Usually it is C<me>.
3163
3164 Currently the source alias that refers to the result set returned by a
3165 L</search>/L</find> family method depends on how you got to the resultset: it's
3166 C<me> by default, but eg. L</search_related> aliases it to the related result
3167 source name (and keeps C<me> referring to the original result set). The long
3168 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3169 (and make this method unnecessary).
3170
3171 Thus it's currently necessary to use this method in predefined queries (see
3172 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3173 source alias of the current result set:
3174
3175   # in a result set class
3176   sub modified_by {
3177     my ($self, $user) = @_;
3178
3179     my $me = $self->current_source_alias;
3180
3181     return $self->search({
3182       "$me.modified" => $user->id,
3183     });
3184   }
3185
3186 =cut
3187
3188 sub current_source_alias {
3189   return (shift->{attrs} || {})->{alias} || 'me';
3190 }
3191
3192 =head2 as_subselect_rs
3193
3194 =over 4
3195
3196 =item Arguments: none
3197
3198 =item Return Value: L<$resultset|/search>
3199
3200 =back
3201
3202 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3203 "virtual view" by including it as a subquery within the from clause.  From this
3204 point on, any joined tables are inaccessible to ->search on the resultset (as if
3205 it were simply where-filtered without joins).  For example:
3206
3207  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3208
3209  # 'x' now pollutes the query namespace
3210
3211  # So the following works as expected
3212  my $ok_rs = $rs->search({'x.other' => 1});
3213
3214  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3215  # def) we look for one row with contradictory terms and join in another table
3216  # (aliased 'x_2') which we never use
3217  my $broken_rs = $rs->search({'x.name' => 'def'});
3218
3219  my $rs2 = $rs->as_subselect_rs;
3220
3221  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3222  my $not_joined_rs = $rs2->search({'x.other' => 1});
3223
3224  # works as expected: finds a 'table' row related to two x rows (abc and def)
3225  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3226
3227 Another example of when one might use this would be to select a subset of
3228 columns in a group by clause:
3229
3230  my $rs = $schema->resultset('Bar')->search(undef, {
3231    group_by => [qw{ id foo_id baz_id }],
3232  })->as_subselect_rs->search(undef, {
3233    columns => [qw{ id foo_id }]
3234  });
3235
3236 In the above example normally columns would have to be equal to the group by,
3237 but because we isolated the group by into a subselect the above works.
3238
3239 =cut
3240
3241 sub as_subselect_rs {
3242   my $self = shift;
3243
3244   my $attrs = $self->_resolved_attrs;
3245
3246   my $fresh_rs = (ref $self)->new (
3247     $self->result_source
3248   );
3249
3250   # these pieces will be locked in the subquery
3251   delete $fresh_rs->{cond};
3252   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3253
3254   return $fresh_rs->search( {}, {
3255     from => [{
3256       $attrs->{alias} => $self->as_query,
3257       -alias  => $attrs->{alias},
3258       -rsrc   => $self->result_source,
3259     }],
3260     alias => $attrs->{alias},
3261   });
3262 }
3263
3264 # This code is called by search_related, and makes sure there
3265 # is clear separation between the joins before, during, and
3266 # after the relationship. This information is needed later
3267 # in order to properly resolve prefetch aliases (any alias
3268 # with a relation_chain_depth less than the depth of the
3269 # current prefetch is not considered)
3270 #
3271 # The increments happen twice per join. An even number means a
3272 # relationship specified via a search_related, whereas an odd
3273 # number indicates a join/prefetch added via attributes
3274 #
3275 # Also this code will wrap the current resultset (the one we
3276 # chain to) in a subselect IFF it contains limiting attributes
3277 sub _chain_relationship {
3278   my ($self, $rel) = @_;
3279   my $source = $self->result_source;
3280   my $attrs = { %{$self->{attrs}||{}} };
3281
3282   # we need to take the prefetch the attrs into account before we
3283   # ->_resolve_join as otherwise they get lost - captainL
3284   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3285
3286   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3287
3288   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3289
3290   my $from;
3291   my @force_subq_attrs = qw/offset rows group_by having/;
3292
3293   if (
3294     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3295       ||
3296     $self->_has_resolved_attr (@force_subq_attrs)
3297   ) {
3298     # Nuke the prefetch (if any) before the new $rs attrs
3299     # are resolved (prefetch is useless - we are wrapping
3300     # a subquery anyway).
3301     my $rs_copy = $self->search;
3302     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3303       $rs_copy->{attrs}{join},
3304       delete $rs_copy->{attrs}{prefetch},
3305     );
3306
3307     $from = [{
3308       -rsrc   => $source,
3309       -alias  => $attrs->{alias},
3310       $attrs->{alias} => $rs_copy->as_query,
3311     }];
3312     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3313     $seen->{-relation_chain_depth} = 0;
3314   }
3315   elsif ($attrs->{from}) {  #shallow copy suffices
3316     $from = [ @{$attrs->{from}} ];
3317   }
3318   else {
3319     $from = [{
3320       -rsrc  => $source,
3321       -alias => $attrs->{alias},
3322       $attrs->{alias} => $source->from,
3323     }];
3324   }
3325
3326   my $jpath = ($seen->{-relation_chain_depth})
3327     ? $from->[-1][0]{-join_path}
3328     : [];
3329
3330   my @requested_joins = $source->_resolve_join(
3331     $join,
3332     $attrs->{alias},
3333     $seen,
3334     $jpath,
3335   );
3336
3337   push @$from, @requested_joins;
3338
3339   $seen->{-relation_chain_depth}++;
3340
3341   # if $self already had a join/prefetch specified on it, the requested
3342   # $rel might very well be already included. What we do in this case
3343   # is effectively a no-op (except that we bump up the chain_depth on
3344   # the join in question so we could tell it *is* the search_related)
3345   my $already_joined;
3346
3347   # we consider the last one thus reverse
3348   for my $j (reverse @requested_joins) {
3349     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3350     if ($rel eq $last_j) {
3351       $j->[0]{-relation_chain_depth}++;
3352       $already_joined++;
3353       last;
3354     }
3355   }
3356
3357   unless ($already_joined) {
3358     push @$from, $source->_resolve_join(
3359       $rel,
3360       $attrs->{alias},
3361       $seen,
3362       $jpath,
3363     );
3364   }
3365
3366   $seen->{-relation_chain_depth}++;
3367
3368   return {%$attrs, from => $from, seen_join => $seen};
3369 }
3370
3371 sub _resolved_attrs {
3372   my $self = shift;
3373   return $self->{_attrs} if $self->{_attrs};
3374
3375   my $attrs  = { %{ $self->{attrs} || {} } };
3376   my $source = $self->result_source;
3377   my $alias  = $attrs->{alias};
3378
3379   # default selection list
3380   $attrs->{columns} = [ $source->columns ]
3381     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3382
3383   # merge selectors together
3384   for (qw/columns select as/) {
3385     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3386       if $attrs->{$_} or $attrs->{"+$_"};
3387   }
3388
3389   # disassemble columns
3390   my (@sel, @as);
3391   if (my $cols = delete $attrs->{columns}) {
3392     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3393       if (ref $c eq 'HASH') {
3394         for my $as (sort keys %$c) {
3395           push @sel, $c->{$as};
3396           push @as, $as;
3397         }
3398       }
3399       else {
3400         push @sel, $c;
3401         push @as, $c;
3402       }
3403     }
3404   }
3405
3406   # when trying to weed off duplicates later do not go past this point -
3407   # everything added from here on is unbalanced "anyone's guess" stuff
3408   my $dedup_stop_idx = $#as;
3409
3410   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3411     if $attrs->{as};
3412   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3413     if $attrs->{select};
3414
3415   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3416   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3417
3418   # disqualify all $alias.col as-bits (inflate-map mandated)
3419   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3420
3421   # de-duplicate the result (remove *identical* select/as pairs)
3422   # and also die on duplicate {as} pointing to different {select}s
3423   # not using a c-style for as the condition is prone to shrinkage
3424   my $seen;
3425   my $i = 0;
3426   while ($i <= $dedup_stop_idx) {
3427     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3428       splice @sel, $i, 1;
3429       splice @as, $i, 1;
3430       $dedup_stop_idx--;
3431     }
3432     elsif ($seen->{$as[$i]}++) {
3433       $self->throw_exception(
3434         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3435       );
3436     }
3437     else {
3438       $i++;
3439     }
3440   }
3441
3442   $attrs->{select} = \@sel;
3443   $attrs->{as} = \@as;
3444
3445   $attrs->{from} ||= [{
3446     -rsrc   => $source,
3447     -alias  => $self->{attrs}{alias},
3448     $self->{attrs}{alias} => $source->from,
3449   }];
3450
3451   if ( $attrs->{join} || $attrs->{prefetch} ) {
3452
3453     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3454       if ref $attrs->{from} ne 'ARRAY';
3455
3456     my $join = (delete $attrs->{join}) || {};
3457
3458     if ( defined $attrs->{prefetch} ) {
3459       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3460     }
3461
3462     $attrs->{from} =    # have to copy here to avoid corrupting the original
3463       [
3464         @{ $attrs->{from} },
3465         $source->_resolve_join(
3466           $join,
3467           $alias,
3468           { %{ $attrs->{seen_join} || {} } },
3469           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3470             ? $attrs->{from}[-1][0]{-join_path}
3471             : []
3472           ,
3473         )
3474       ];
3475   }
3476
3477   if ( defined $attrs->{order_by} ) {
3478     $attrs->{order_by} = (
3479       ref( $attrs->{order_by} ) eq 'ARRAY'
3480       ? [ @{ $attrs->{order_by} } ]
3481       : [ $attrs->{order_by} || () ]
3482     );
3483   }
3484
3485   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3486     $attrs->{group_by} = [ $attrs->{group_by} ];
3487   }
3488
3489   # generate the distinct induced group_by early, as prefetch will be carried via a
3490   # subquery (since a group_by is present)
3491   if (delete $attrs->{distinct}) {
3492     if ($attrs->{group_by}) {
3493       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3494     }
3495     else {
3496       $attrs->{_grouped_by_distinct} = 1;
3497       # distinct affects only the main selection part, not what prefetch may
3498       # add below.
3499       $attrs->{group_by} = $source->storage->_group_over_selection (
3500         $attrs->{from},
3501         $attrs->{select},
3502         $attrs->{order_by},
3503       );
3504     }
3505   }
3506
3507   # generate selections based on the prefetch helper
3508   my $prefetch;
3509   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3510     if defined $attrs->{prefetch};
3511
3512   if ($prefetch) {
3513
3514     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3515       if $attrs->{_dark_selector};
3516
3517     $attrs->{collapse} = 1;
3518
3519     # this is a separate structure (we don't look in {from} directly)
3520     # as the resolver needs to shift things off the lists to work
3521     # properly (identical-prefetches on different branches)
3522     my $join_map = {};
3523     if (ref $attrs->{from} eq 'ARRAY') {
3524
3525       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3526
3527       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3528         next unless $j->[0]{-alias};
3529         next unless $j->[0]{-join_path};
3530         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3531
3532         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3533
3534         my $p = $join_map;
3535         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3536         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3537       }
3538     }
3539
3540     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3541
3542     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3543     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3544   }
3545
3546   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3547     $attrs->{_related_results_construction} = 1;
3548   }
3549   else {
3550     $attrs->{collapse} = 0;
3551   }
3552
3553   # run through the resulting joinstructure (starting from our current slot)
3554   # and unset collapse if proven unnesessary
3555   #
3556   # also while we are at it find out if the current root source has
3557   # been premultiplied by previous related_source chaining
3558   #
3559   # this allows to predict whether a root object with all other relation
3560   # data set to NULL is in fact unique
3561   if ($attrs->{collapse}) {
3562
3563     if (ref $attrs->{from} eq 'ARRAY') {
3564
3565       if (@{$attrs->{from}} <= 1) {
3566         # no joins - no collapse
3567         $attrs->{collapse} = 0;
3568       }
3569       else {
3570         # find where our table-spec starts
3571         my @fromlist = @{$attrs->{from}};
3572         while (@fromlist) {
3573           my $t = shift @fromlist;
3574
3575           my $is_multi;
3576           # me vs join from-spec distinction - a ref means non-root
3577           if (ref $t eq 'ARRAY') {
3578             $t = $t->[0];
3579             $is_multi ||= ! $t->{-is_single};
3580           }
3581           last if ($t->{-alias} && $t->{-alias} eq $alias);
3582           $attrs->{_main_source_premultiplied} ||= $is_multi;
3583         }
3584
3585         # no non-singles remaining, nor any premultiplication - nothing to collapse
3586         if (
3587           ! $attrs->{_main_source_premultiplied}
3588             and
3589           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3590         ) {
3591           $attrs->{collapse} = 0;
3592         }
3593       }
3594     }
3595
3596     else {
3597       # if we can not analyze the from - err on the side of safety
3598       $attrs->{_main_source_premultiplied} = 1;
3599     }
3600   }
3601
3602   # if both page and offset are specified, produce a combined offset
3603   # even though it doesn't make much sense, this is what pre 081xx has
3604   # been doing
3605   if (my $page = delete $attrs->{page}) {
3606     $attrs->{offset} =
3607       ($attrs->{rows} * ($page - 1))
3608             +
3609       ($attrs->{offset} || 0)
3610     ;
3611   }
3612
3613   return $self->{_attrs} = $attrs;
3614 }
3615
3616 sub _rollout_attr {
3617   my ($self, $attr) = @_;
3618
3619   if (ref $attr eq 'HASH') {
3620     return $self->_rollout_hash($attr);
3621   } elsif (ref $attr eq 'ARRAY') {
3622     return $self->_rollout_array($attr);
3623   } else {
3624     return [$attr];
3625   }
3626 }
3627
3628 sub _rollout_array {
3629   my ($self, $attr) = @_;
3630
3631   my @rolled_array;
3632   foreach my $element (@{$attr}) {
3633     if (ref $element eq 'HASH') {
3634       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3635     } elsif (ref $element eq 'ARRAY') {
3636       #  XXX - should probably recurse here
3637       push( @rolled_array, @{$self->_rollout_array($element)} );
3638     } else {
3639       push( @rolled_array, $element );
3640     }
3641   }
3642   return \@rolled_array;
3643 }
3644
3645 sub _rollout_hash {
3646   my ($self, $attr) = @_;
3647
3648   my @rolled_array;
3649   foreach my $key (keys %{$attr}) {
3650     push( @rolled_array, { $key => $attr->{$key} } );
3651   }
3652   return \@rolled_array;
3653 }
3654
3655 sub _calculate_score {
3656   my ($self, $a, $b) = @_;
3657
3658   if (defined $a xor defined $b) {
3659     return 0;
3660   }
3661   elsif (not defined $a) {
3662     return 1;
3663   }
3664
3665   if (ref $b eq 'HASH') {
3666     my ($b_key) = keys %{$b};
3667     if (ref $a eq 'HASH') {
3668       my ($a_key) = keys %{$a};
3669       if ($a_key eq $b_key) {
3670         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3671       } else {
3672         return 0;
3673       }
3674     } else {
3675       return ($a eq $b_key) ? 1 : 0;
3676     }
3677   } else {
3678     if (ref $a eq 'HASH') {
3679       my ($a_key) = keys %{$a};
3680       return ($b eq $a_key) ? 1 : 0;
3681     } else {
3682       return ($b eq $a) ? 1 : 0;
3683     }
3684   }
3685 }
3686
3687 sub _merge_joinpref_attr {
3688   my ($self, $orig, $import) = @_;
3689
3690   return $import unless defined($orig);
3691   return $orig unless defined($import);
3692
3693   $orig = $self->_rollout_attr($orig);
3694   $import = $self->_rollout_attr($import);
3695
3696   my $seen_keys;
3697   foreach my $import_element ( @{$import} ) {
3698     # find best candidate from $orig to merge $b_element into
3699     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3700     foreach my $orig_element ( @{$orig} ) {
3701       my $score = $self->_calculate_score( $orig_element, $import_element );
3702       if ($score > $best_candidate->{score}) {
3703         $best_candidate->{position} = $position;
3704         $best_candidate->{score} = $score;
3705       }
3706       $position++;
3707     }
3708     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3709     $import_key = '' if not defined $import_key;
3710
3711     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3712       push( @{$orig}, $import_element );
3713     } else {
3714       my $orig_best = $orig->[$best_candidate->{position}];
3715       # merge orig_best and b_element together and replace original with merged
3716       if (ref $orig_best ne 'HASH') {
3717         $orig->[$best_candidate->{position}] = $import_element;
3718       } elsif (ref $import_element eq 'HASH') {
3719         my ($key) = keys %{$orig_best};
3720         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3721       }
3722     }
3723     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3724   }
3725
3726   return @$orig ? $orig : ();
3727 }
3728
3729 {
3730   my $hm;
3731
3732   sub _merge_attr {
3733     $hm ||= do {
3734       require Hash::Merge;
3735       my $hm = Hash::Merge->new;
3736
3737       $hm->specify_behavior({
3738         SCALAR => {
3739           SCALAR => sub {
3740             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3741
3742             if ($defl xor $defr) {
3743               return [ $defl ? $_[0] : $_[1] ];
3744             }
3745             elsif (! $defl) {
3746               return [];
3747             }
3748             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3749               return [ $_[0] ];
3750             }
3751             else {
3752               return [$_[0], $_[1]];
3753             }
3754           },
3755           ARRAY => sub {
3756             return $_[1] if !defined $_[0];
3757             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3758             return [$_[0], @{$_[1]}]
3759           },
3760           HASH  => sub {
3761             return [] if !defined $_[0] and !keys %{$_[1]};
3762             return [ $_[1] ] if !defined $_[0];
3763             return [ $_[0] ] if !keys %{$_[1]};
3764             return [$_[0], $_[1]]
3765           },
3766         },
3767         ARRAY => {
3768           SCALAR => sub {
3769             return $_[0] if !defined $_[1];
3770             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3771             return [@{$_[0]}, $_[1]]
3772           },
3773           ARRAY => sub {
3774             my @ret = @{$_[0]} or return $_[1];
3775             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3776             my %idx = map { $_ => 1 } @ret;
3777             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3778             \@ret;
3779           },
3780           HASH => sub {
3781             return [ $_[1] ] if ! @{$_[0]};
3782             return $_[0] if !keys %{$_[1]};
3783             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3784             return [ @{$_[0]}, $_[1] ];
3785           },
3786         },
3787         HASH => {
3788           SCALAR => sub {
3789             return [] if !keys %{$_[0]} and !defined $_[1];
3790             return [ $_[0] ] if !defined $_[1];
3791             return [ $_[1] ] if !keys %{$_[0]};
3792             return [$_[0], $_[1]]
3793           },
3794           ARRAY => sub {
3795             return [] if !keys %{$_[0]} and !@{$_[1]};
3796             return [ $_[0] ] if !@{$_[1]};
3797             return $_[1] if !keys %{$_[0]};
3798             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3799             return [ $_[0], @{$_[1]} ];
3800           },
3801           HASH => sub {
3802             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3803             return [ $_[0] ] if !keys %{$_[1]};
3804             return [ $_[1] ] if !keys %{$_[0]};
3805             return [ $_[0] ] if $_[0] eq $_[1];
3806             return [ $_[0], $_[1] ];
3807           },
3808         }
3809       } => 'DBIC_RS_ATTR_MERGER');
3810       $hm;
3811     };
3812
3813     return $hm->merge ($_[1], $_[2]);
3814   }
3815 }
3816
3817 sub STORABLE_freeze {
3818   my ($self, $cloning) = @_;
3819   my $to_serialize = { %$self };
3820
3821   # A cursor in progress can't be serialized (and would make little sense anyway)
3822   # the parser can be regenerated (and can't be serialized)
3823   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3824
3825   # nor is it sensical to store a not-yet-fired-count pager
3826   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3827     delete $to_serialize->{pager};
3828   }
3829
3830   Storable::nfreeze($to_serialize);
3831 }
3832
3833 # need this hook for symmetry
3834 sub STORABLE_thaw {
3835   my ($self, $cloning, $serialized) = @_;
3836
3837   %$self = %{ Storable::thaw($serialized) };
3838
3839   $self;
3840 }
3841
3842
3843 =head2 throw_exception
3844
3845 See L<DBIx::Class::Schema/throw_exception> for details.
3846
3847 =cut
3848
3849 sub throw_exception {
3850   my $self=shift;
3851
3852   if (ref $self and my $rsrc = $self->result_source) {
3853     $rsrc->throw_exception(@_)
3854   }
3855   else {
3856     DBIx::Class::Exception->throw(@_);
3857   }
3858 }
3859
3860 1;
3861
3862 __END__
3863
3864 # XXX: FIXME: Attributes docs need clearing up
3865
3866 =head1 ATTRIBUTES
3867
3868 Attributes are used to refine a ResultSet in various ways when
3869 searching for data. They can be passed to any method which takes an
3870 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3871 L</count>.
3872
3873 Default attributes can be set on the result class using
3874 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3875 the CAVEATS on that feature before using it!)
3876
3877 These are in no particular order:
3878
3879 =head2 order_by
3880
3881 =over 4
3882
3883 =item Value: ( $order_by | \@order_by | \%order_by )
3884
3885 =back
3886
3887 Which column(s) to order the results by.
3888
3889 [The full list of suitable values is documented in
3890 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3891 common options.]
3892
3893 If a single column name, or an arrayref of names is supplied, the
3894 argument is passed through directly to SQL. The hashref syntax allows
3895 for connection-agnostic specification of ordering direction:
3896
3897  For descending order:
3898
3899   order_by => { -desc => [qw/col1 col2 col3/] }
3900
3901  For explicit ascending order:
3902
3903   order_by => { -asc => 'col' }
3904
3905 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3906 supported, although you are strongly encouraged to use the hashref
3907 syntax as outlined above.
3908
3909 =head2 columns
3910
3911 =over 4
3912
3913 =item Value: \@columns | \%columns | $column
3914
3915 =back
3916
3917 Shortcut to request a particular set of columns to be retrieved. Each
3918 column spec may be a string (a table column name), or a hash (in which
3919 case the key is the C<as> value, and the value is used as the C<select>
3920 expression). Adds C<me.> onto the start of any column without a C<.> in
3921 it and sets C<select> from that, then auto-populates C<as> from
3922 C<select> as normal. (You may also use the C<cols> attribute, as in
3923 earlier versions of DBIC, but this is deprecated.)
3924
3925 Essentially C<columns> does the same as L</select> and L</as>.
3926
3927     columns => [ 'foo', { bar => 'baz' } ]
3928
3929 is the same as
3930
3931     select => [qw/foo baz/],
3932     as => [qw/foo bar/]
3933
3934 =head2 +columns
3935
3936 =over 4
3937
3938 =item Value: \@columns
3939
3940 =back
3941
3942 Indicates additional columns to be selected from storage. Works the same as
3943 L</columns> but adds columns to the selection. (You may also use the
3944 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3945 deprecated). For example:-
3946
3947   $schema->resultset('CD')->search(undef, {
3948     '+columns' => ['artist.name'],
3949     join => ['artist']
3950   });
3951
3952 would return all CDs and include a 'name' column to the information
3953 passed to object inflation. Note that the 'artist' is the name of the
3954 column (or relationship) accessor, and 'name' is the name of the column
3955 accessor in the related table.
3956
3957 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3958 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3959 unary plus operator before it.
3960
3961 =head2 include_columns
3962
3963 =over 4
3964
3965 =item Value: \@columns
3966
3967 =back
3968
3969 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3970
3971 =head2 select
3972
3973 =over 4
3974
3975 =item Value: \@select_columns
3976
3977 =back
3978
3979 Indicates which columns should be selected from the storage. You can use
3980 column names, or in the case of RDBMS back ends, function or stored procedure
3981 names:
3982
3983   $rs = $schema->resultset('Employee')->search(undef, {
3984     select => [
3985       'name',
3986       { count => 'employeeid' },
3987       { max => { length => 'name' }, -as => 'longest_name' }
3988     ]
3989   });
3990
3991   # Equivalent SQL
3992   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3993
3994 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3995 use L</select>, to instruct DBIx::Class how to store the result of the column.
3996 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3997 identifier aliasing. You can however alias a function, so you can use it in
3998 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3999 attribute> supplied as shown in the example above.
4000
4001 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4002 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4003 unary plus operator before it.
4004
4005 =head2 +select
4006
4007 =over 4
4008
4009 Indicates additional columns to be selected from storage.  Works the same as
4010 L</select> but adds columns to the default selection, instead of specifying
4011 an explicit list.
4012
4013 =back
4014
4015 =head2 as
4016
4017 =over 4
4018
4019 =item Value: \@inflation_names
4020
4021 =back
4022
4023 Indicates column names for object inflation. That is L</as> indicates the
4024 slot name in which the column value will be stored within the
4025 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4026 identifier by the C<get_column> method (or via the object accessor B<if one
4027 with the same name already exists>) as shown below. The L</as> attribute has
4028 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4029
4030   $rs = $schema->resultset('Employee')->search(undef, {
4031     select => [
4032       'name',
4033       { count => 'employeeid' },
4034       { max => { length => 'name' }, -as => 'longest_name' }
4035     ],
4036     as => [qw/
4037       name
4038       employee_count
4039       max_name_length
4040     /],
4041   });
4042
4043 If the object against which the search is performed already has an accessor
4044 matching a column name specified in C<as>, the value can be retrieved using
4045 the accessor as normal:
4046
4047   my $name = $employee->name();
4048
4049 If on the other hand an accessor does not exist in the object, you need to
4050 use C<get_column> instead:
4051
4052   my $employee_count = $employee->get_column('employee_count');
4053
4054 You can create your own accessors if required - see
4055 L<DBIx::Class::Manual::Cookbook> for details.
4056
4057 =head2 +as
4058
4059 =over 4
4060
4061 Indicates additional column names for those added via L</+select>. See L</as>.
4062
4063 =back
4064
4065 =head2 join
4066
4067 =over 4
4068
4069 =item Value: ($rel_name | \@rel_names | \%rel_names)
4070
4071 =back
4072
4073 Contains a list of relationships that should be joined for this query.  For
4074 example:
4075
4076   # Get CDs by Nine Inch Nails
4077   my $rs = $schema->resultset('CD')->search(
4078     { 'artist.name' => 'Nine Inch Nails' },
4079     { join => 'artist' }
4080   );
4081
4082 Can also contain a hash reference to refer to the other relation's relations.
4083 For example:
4084
4085   package MyApp::Schema::Track;
4086   use base qw/DBIx::Class/;
4087   __PACKAGE__->table('track');
4088   __PACKAGE__->add_columns(qw/trackid cd position title/);
4089   __PACKAGE__->set_primary_key('trackid');
4090   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4091   1;
4092
4093   # In your application
4094   my $rs = $schema->resultset('Artist')->search(
4095     { 'track.title' => 'Teardrop' },
4096     {
4097       join     => { cd => 'track' },
4098       order_by => 'artist.name',
4099     }
4100   );
4101
4102 You need to use the relationship (not the table) name in  conditions,
4103 because they are aliased as such. The current table is aliased as "me", so
4104 you need to use me.column_name in order to avoid ambiguity. For example:
4105
4106   # Get CDs from 1984 with a 'Foo' track
4107   my $rs = $schema->resultset('CD')->search(
4108     {
4109       'me.year' => 1984,
4110       'tracks.name' => 'Foo'
4111     },
4112     { join => 'tracks' }
4113   );
4114
4115 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4116 similarly for a third time). For e.g.
4117
4118   my $rs = $schema->resultset('Artist')->search({
4119     'cds.title'   => 'Down to Earth',
4120     'cds_2.title' => 'Popular',
4121   }, {
4122     join => [ qw/cds cds/ ],
4123   });
4124
4125 will return a set of all artists that have both a cd with title 'Down
4126 to Earth' and a cd with title 'Popular'.
4127
4128 If you want to fetch related objects from other tables as well, see L</prefetch>
4129 below.
4130
4131  NOTE: An internal join-chain pruner will discard certain joins while
4132  constructing the actual SQL query, as long as the joins in question do not
4133  affect the retrieved result. This for example includes 1:1 left joins
4134  that are not part of the restriction specification (WHERE/HAVING) nor are
4135  a part of the query selection.
4136
4137 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4138
4139 =head2 collapse
4140
4141 =over 4
4142
4143 =item Value: (0 | 1)
4144
4145 =back
4146
4147 When set to a true value, indicates that any rows fetched from joined has_many
4148 relationships are to be aggregated into the corresponding "parent" object. For
4149 example, the resultset:
4150
4151   my $rs = $schema->resultset('CD')->search({}, {
4152     '+columns' => [ qw/ tracks.title tracks.position / ],
4153     join => 'tracks',
4154     collapse => 1,
4155   });
4156
4157 While executing the following query:
4158
4159   SELECT me.*, tracks.title, tracks.position
4160     FROM cd me
4161     LEFT JOIN track tracks
4162       ON tracks.cdid = me.cdid
4163
4164 Will return only as many objects as there are rows in the CD source, even
4165 though the result of the query may span many rows. Each of these CD objects
4166 will in turn have multiple "Track" objects hidden behind the has_many
4167 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4168 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4169 product"), with each CD object containing exactly one of all fetched Track data.
4170
4171 When a collapse is requested on a non-ordered resultset, an order by some
4172 unique part of the main source (the left-most table) is inserted automatically.
4173 This is done so that the resultset is allowed to be "lazy" - calling
4174 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4175 object with all of its related data.
4176
4177 If an L</order_by> is already declared, and orders the resultset in a way that
4178 makes collapsing as described above impossible (e.g. C<< ORDER BY
4179 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4180 switch to "eager" mode and slurp the entire resultset before consturcting the
4181 first object returned by L</next>.
4182
4183 Setting this attribute on a resultset that does not join any has_many
4184 relations is a no-op.
4185
4186 For a more in-depth discussion, see L</PREFETCHING>.
4187
4188 =head2 prefetch
4189
4190 =over 4
4191
4192 =item Value: ($rel_name | \@rel_names | \%rel_names)
4193
4194 =back
4195
4196 This attribute is a shorthand for specifying a L</join> spec, adding all
4197 columns from the joined related sources as L</+columns> and setting
4198 L</collapse> to a true value. For example, the following two queries are
4199 equivalent:
4200
4201   my $rs = $schema->resultset('Artist')->search({}, {
4202     prefetch => { cds => ['genre', 'tracks' ] },
4203   });
4204
4205 and
4206
4207   my $rs = $schema->resultset('Artist')->search({}, {
4208     join => { cds => ['genre', 'tracks' ] },
4209     collapse => 1,
4210     '+columns' => [
4211       (map
4212         { +{ "cds.$_" => "cds.$_" } }
4213         $schema->source('Artist')->related_source('cds')->columns
4214       ),
4215       (map
4216         { +{ "cds.genre.$_" => "genre.$_" } }
4217         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4218       ),
4219       (map
4220         { +{ "cds.tracks.$_" => "tracks.$_" } }
4221         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4222       ),
4223     ],
4224   });
4225
4226 Both producing the following SQL:
4227
4228   SELECT  me.artistid, me.name, me.rank, me.charfield,
4229           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4230           genre.genreid, genre.name,
4231           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4232     FROM artist me
4233     LEFT JOIN cd cds
4234       ON cds.artist = me.artistid
4235     LEFT JOIN genre genre
4236       ON genre.genreid = cds.genreid
4237     LEFT JOIN track tracks
4238       ON tracks.cd = cds.cdid
4239   ORDER BY me.artistid
4240
4241 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4242 the arguments are properly merged and generally do the right thing. For
4243 example, you may want to do the following:
4244
4245   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4246     { 'genre.genreid' => undef },
4247     {
4248       join => { cds => 'genre' },
4249       prefetch => 'cds',
4250     }
4251   );
4252
4253 Which generates the following SQL:
4254
4255   SELECT  me.artistid, me.name, me.rank, me.charfield,
4256           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4257     FROM artist me
4258     LEFT JOIN cd cds
4259       ON cds.artist = me.artistid
4260     LEFT JOIN genre genre
4261       ON genre.genreid = cds.genreid
4262   WHERE genre.genreid IS NULL
4263   ORDER BY me.artistid
4264
4265 For a more in-depth discussion, see L</PREFETCHING>.
4266
4267 =head2 alias
4268
4269 =over 4
4270
4271 =item Value: $source_alias
4272
4273 =back
4274
4275 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4276 nested search queries (sub-SELECTs) might need specific aliases set to
4277 reference inner queries.  For example:
4278
4279    my $q = $rs
4280       ->related_resultset('CDs')
4281       ->related_resultset('Tracks')
4282       ->search({
4283          'track.id' => { -ident => 'none_search.id' },
4284       })
4285       ->as_query;
4286
4287    my $ids = $self->search({
4288       -not_exists => $q,
4289    }, {
4290       alias    => 'none_search',
4291       group_by => 'none_search.id',
4292    })->get_column('id')->as_query;
4293
4294    $self->search({ id => { -in => $ids } })
4295
4296 This attribute is directly tied to L</current_source_alias>.
4297
4298 =head2 page
4299
4300 =over 4
4301
4302 =item Value: $page
4303
4304 =back
4305
4306 Makes the resultset paged and specifies the page to retrieve. Effectively
4307 identical to creating a non-pages resultset and then calling ->page($page)
4308 on it.
4309
4310 If L</rows> attribute is not specified it defaults to 10 rows per page.
4311
4312 When you have a paged resultset, L</count> will only return the number
4313 of rows in the page. To get the total, use the L</pager> and call
4314 C<total_entries> on it.
4315
4316 =head2 rows
4317
4318 =over 4
4319
4320 =item Value: $rows
4321
4322 =back
4323
4324 Specifies the maximum number of rows for direct retrieval or the number of
4325 rows per page if the page attribute or method is used.
4326
4327 =head2 offset
4328
4329 =over 4
4330
4331 =item Value: $offset
4332
4333 =back
4334
4335 Specifies the (zero-based) row number for the  first row to be returned, or the
4336 of the first row of the first page if paging is used.
4337
4338 =head2 software_limit
4339
4340 =over 4
4341
4342 =item Value: (0 | 1)
4343
4344 =back
4345
4346 When combined with L</rows> and/or L</offset> the generated SQL will not
4347 include any limit dialect stanzas. Instead the entire result will be selected
4348 as if no limits were specified, and DBIC will perform the limit locally, by
4349 artificially advancing and finishing the resulting L</cursor>.
4350
4351 This is the recommended way of performing resultset limiting when no sane RDBMS
4352 implementation is available (e.g.
4353 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4354 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4355
4356 =head2 group_by
4357
4358 =over 4
4359
4360 =item Value: \@columns
4361
4362 =back
4363
4364 A arrayref of columns to group by. Can include columns of joined tables.
4365
4366   group_by => [qw/ column1 column2 ... /]
4367
4368 =head2 having
4369
4370 =over 4
4371
4372 =item Value: $condition
4373
4374 =back
4375
4376 HAVING is a select statement attribute that is applied between GROUP BY and
4377 ORDER BY. It is applied to the after the grouping calculations have been
4378 done.
4379
4380   having => { 'count_employee' => { '>=', 100 } }
4381
4382 or with an in-place function in which case literal SQL is required:
4383
4384   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4385
4386 =head2 distinct
4387
4388 =over 4
4389
4390 =item Value: (0 | 1)
4391
4392 =back
4393
4394 Set to 1 to group by all columns. If the resultset already has a group_by
4395 attribute, this setting is ignored and an appropriate warning is issued.
4396
4397 =head2 where
4398
4399 =over 4
4400
4401 Adds to the WHERE clause.
4402
4403   # only return rows WHERE deleted IS NULL for all searches
4404   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4405
4406 Can be overridden by passing C<< { where => undef } >> as an attribute
4407 to a resultset.
4408
4409 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4410
4411 =back
4412
4413 =head2 cache
4414
4415 Set to 1 to cache search results. This prevents extra SQL queries if you
4416 revisit rows in your ResultSet:
4417
4418   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4419
4420   while( my $artist = $resultset->next ) {
4421     ... do stuff ...
4422   }
4423
4424   $rs->first; # without cache, this would issue a query
4425
4426 By default, searches are not cached.
4427
4428 For more examples of using these attributes, see
4429 L<DBIx::Class::Manual::Cookbook>.
4430
4431 =head2 for
4432
4433 =over 4
4434
4435 =item Value: ( 'update' | 'shared' | \$scalar )
4436
4437 =back
4438
4439 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4440 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4441 query.
4442
4443 =head1 PREFETCHING
4444
4445 DBIx::Class supports arbitrary related data prefetching from multiple related
4446 sources. Any combination of relationship types and column sets are supported.
4447 If L<collapsing|/collapse> is requested, there is an additional requirement of
4448 selecting enough data to make every individual object uniquely identifiable.
4449
4450 Here are some more involved examples, based on the following relationship map:
4451
4452   # Assuming:
4453   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4454   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4455   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4456
4457   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4458
4459   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4460
4461
4462
4463   my $rs = $schema->resultset('Tag')->search(
4464     undef,
4465     {
4466       prefetch => {
4467         cd => 'artist'
4468       }
4469     }
4470   );
4471
4472 The initial search results in SQL like the following:
4473
4474   SELECT tag.*, cd.*, artist.* FROM tag
4475   JOIN cd ON tag.cd = cd.cdid
4476   JOIN artist ON cd.artist = artist.artistid
4477
4478 L<DBIx::Class> has no need to go back to the database when we access the
4479 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4480 case.
4481
4482 Simple prefetches will be joined automatically, so there is no need
4483 for a C<join> attribute in the above search.
4484
4485 The L</prefetch> attribute can be used with any of the relationship types
4486 and multiple prefetches can be specified together. Below is a more complex
4487 example that prefetches a CD's artist, its liner notes (if present),
4488 the cover image, the tracks on that CD, and the guests on those
4489 tracks.
4490
4491   my $rs = $schema->resultset('CD')->search(
4492     undef,
4493     {
4494       prefetch => [
4495         { artist => 'record_label'},  # belongs_to => belongs_to
4496         'liner_note',                 # might_have
4497         'cover_image',                # has_one
4498         { tracks => 'guests' },       # has_many => has_many
4499       ]
4500     }
4501   );
4502
4503 This will produce SQL like the following:
4504
4505   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4506          tracks.*, guests.*
4507     FROM cd me
4508     JOIN artist artist
4509       ON artist.artistid = me.artistid
4510     JOIN record_label record_label
4511       ON record_label.labelid = artist.labelid
4512     LEFT JOIN track tracks
4513       ON tracks.cdid = me.cdid
4514     LEFT JOIN guest guests
4515       ON guests.trackid = track.trackid
4516     LEFT JOIN liner_notes liner_note
4517       ON liner_note.cdid = me.cdid
4518     JOIN cd_artwork cover_image
4519       ON cover_image.cdid = me.cdid
4520   ORDER BY tracks.cd
4521
4522 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4523 C<tracks>, and C<guests> of the CD will all be available through the
4524 relationship accessors without the need for additional queries to the
4525 database.
4526
4527 =head3 CAVEATS
4528
4529 Prefetch does a lot of deep magic. As such, it may not behave exactly
4530 as you might expect.
4531
4532 =over 4
4533
4534 =item *
4535
4536 Prefetch uses the L</cache> to populate the prefetched relationships. This
4537 may or may not be what you want.
4538
4539 =item *
4540
4541 If you specify a condition on a prefetched relationship, ONLY those
4542 rows that match the prefetched condition will be fetched into that relationship.
4543 This means that adding prefetch to a search() B<may alter> what is returned by
4544 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4545
4546   my $artist_rs = $schema->resultset('Artist')->search({
4547       'cds.year' => 2008,
4548   }, {
4549       join => 'cds',
4550   });
4551
4552   my $count = $artist_rs->first->cds->count;
4553
4554   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4555
4556   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4557
4558   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4559
4560 That cmp_ok() may or may not pass depending on the datasets involved. In other
4561 words the C<WHERE> condition would apply to the entire dataset, just like
4562 it would in regular SQL. If you want to add a condition only to the "right side"
4563 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4564 condition|DBIx::Class::Relationship::Base/condition>
4565
4566 =back
4567
4568 =head1 DBIC BIND VALUES
4569
4570 Because DBIC may need more information to bind values than just the column name
4571 and value itself, it uses a special format for both passing and receiving bind
4572 values.  Each bind value should be composed of an arrayref of
4573 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4574
4575 =over 4
4576
4577 =item dbd_attrs
4578
4579 If present (in any form), this is what is being passed directly to bind_param.
4580 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4581 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4582
4583 If this is specified, all other bind options described below are ignored.
4584
4585 =item sqlt_datatype
4586
4587 If present, this is used to infer the actual bind attribute by passing to
4588 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4589 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4590
4591 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4592 currently drivers are expected to "Do the Right Thing" when given a common
4593 datatype name.  (Not ideal, but that's what we got at this point.)
4594
4595 =item sqlt_size
4596
4597 Currently used to correctly allocate buffers for bind_param_inout().
4598 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4599 or to a sensible value based on the "data_type".
4600
4601 =item dbic_colname
4602
4603 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4604 explicitly specified they are never overriden).  Also used by some weird DBDs,
4605 where the column name should be available at bind_param time (e.g. Oracle).
4606
4607 =back
4608
4609 For backwards compatibility and convenience, the following shortcuts are
4610 supported:
4611
4612   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4613   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4614   [ undef,   $val ] === [ {}, $val ]
4615
4616 =head1 AUTHOR AND CONTRIBUTORS
4617
4618 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4619
4620 =head1 LICENSE
4621
4622 You may distribute this code under the same terms as Perl itself.
4623