lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   if (List::Util::first { exists $attrs->{$_} } qw{columns select as}) {
 295      delete @{$our_attrs}{qw{select as columns +select +as +columns}};
 296   }
 297
 298   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 299
 300   # merge new attrs into inherited
 301   foreach my $key (qw/join prefetch +select +as +columns bind/) {
 302     next unless exists $attrs->{$key};
 303     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 304   }
 305
 306   my $cond = (@_
 307     ? (
 308         (@_ == 1 || ref $_[0] eq "HASH")
 309           ? (
 310               (ref $_[0] eq 'HASH')
 311                 ? (
 312                     (keys %{ $_[0] }  > 0)
 313                       ? shift
 314                       : undef
 315                    )
 316                 :  shift
 317              )
 318           : (
 319               (@_ % 2)
 320                 ? $self->throw_exception("Odd number of arguments to search")
 321                 : {@_}
 322              )
 323       )
 324     : undef
 325   );
 326
 327   if (defined $where) {
 328     $new_attrs->{where} = (
 329       defined $new_attrs->{where}
 330         ? { '-and' => [
 331               map {
 332                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 333               } $where, $new_attrs->{where}
 334             ]
 335           }
 336         : $where);
 337   }
 338
 339   if (defined $cond) {
 340     $new_attrs->{where} = (
 341       defined $new_attrs->{where}
 342         ? { '-and' => [
 343               map {
 344                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 345               } $cond, $new_attrs->{where}
 346             ]
 347           }
 348         : $cond);
 349   }
 350
 351   if (defined $having) {
 352     $new_attrs->{having} = (
 353       defined $new_attrs->{having}
 354         ? { '-and' => [
 355               map {
 356                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 357               } $having, $new_attrs->{having}
 358             ]
 359           }
 360         : $having);
 361   }
 362
 363   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 364
 365   $rs->set_cache($rows) if ($rows);
 366
 367   return $rs;
 368 }
 369
 370 =head2 search_literal
 371
 372 =over 4
 373
 374 =item Arguments: $sql_fragment, @bind_values
 375
 376 =item Return Value: $resultset (scalar context), @row_objs (list context)
 377
 378 =back
 379
 380   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 381   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 382
 383 Pass a literal chunk of SQL to be added to the conditional part of the
 384 resultset query.
 385
 386 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 387 only be used in that context. C<search_literal> is a convenience method.
 388 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 389 columns are bound correctly, use C<search>.
 390
 391 Example of how to use C<search> instead of C<search_literal>
 392
 393   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 394   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 395
 396
 397 See L<DBIx::Class::Manual::Cookbook/Searching> and
 398 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 399 require C<search_literal>.
 400
 401 =cut
 402
 403 sub search_literal {
 404   my ($self, $sql, @bind) = @_;
 405   my $attr;
 406   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 407     $attr = pop @bind;
 408   }
 409   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 410 }
 411
 412 =head2 find
 413
 414 =over 4
 415
 416 =item Arguments: @values | \%cols, \%attrs?
 417
 418 =item Return Value: $row_object | undef
 419
 420 =back
 421
 422 Finds a row based on its primary key or unique constraint. For example, to find
 423 a row by its primary key:
 424
 425   my $cd = $schema->resultset('CD')->find(5);
 426
 427 You can also find a row by a specific unique constraint using the C<key>
 428 attribute. For example:
 429
 430   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 431     key => 'cd_artist_title'
 432   });
 433
 434 Additionally, you can specify the columns explicitly by name:
 435
 436   my $cd = $schema->resultset('CD')->find(
 437     {
 438       artist => 'Massive Attack',
 439       title  => 'Mezzanine',
 440     },
 441     { key => 'cd_artist_title' }
 442   );
 443
 444 If the C<key> is specified as C<primary>, it searches only on the primary key.
 445
 446 If no C<key> is specified, it searches on all unique constraints defined on the
 447 source for which column data is provided, including the primary key.
 448
 449 If your table does not have a primary key, you B<must> provide a value for the
 450 C<key> attribute matching one of the unique constraints on the source.
 451
 452 In addition to C<key>, L</find> recognizes and applies standard
 453 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 454
 455 Note: If your query does not return only one row, a warning is generated:
 456
 457   Query returned more than one row
 458
 459 See also L</find_or_create> and L</update_or_create>. For information on how to
 460 declare unique constraints, see
 461 L<DBIx::Class::ResultSource/add_unique_constraint>.
 462
 463 =cut
 464
 465 sub find {
 466   my $self = shift;
 467   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 468
 469   # Default to the primary key, but allow a specific key
 470   my @cols = exists $attrs->{key}
 471     ? $self->result_source->unique_constraint_columns($attrs->{key})
 472     : $self->result_source->primary_columns;
 473   $self->throw_exception(
 474     "Can't find unless a primary key is defined or unique constraint is specified"
 475   ) unless @cols;
 476
 477   # Parse out a hashref from input
 478   my $input_query;
 479   if (ref $_[0] eq 'HASH') {
 480     $input_query = { %{$_[0]} };
 481   }
 482   elsif (@_ == @cols) {
 483     $input_query = {};
 484     @{$input_query}{@cols} = @_;
 485   }
 486   else {
 487     # Compatibility: Allow e.g. find(id => $value)
 488     carp "Find by key => value deprecated; please use a hashref instead";
 489     $input_query = {@_};
 490   }
 491
 492   my (%related, $info);
 493
 494   KEY: foreach my $key (keys %$input_query) {
 495     if (ref($input_query->{$key})
 496         && ($info = $self->result_source->relationship_info($key))) {
 497       my $val = delete $input_query->{$key};
 498       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 499       my $rel_q = $self->result_source->_resolve_condition(
 500                     $info->{cond}, $val, $key
 501                   );
 502       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 503       @related{keys %$rel_q} = values %$rel_q;
 504     }
 505   }
 506   if (my @keys = keys %related) {
 507     @{$input_query}{@keys} = values %related;
 508   }
 509
 510
 511   # Build the final query: Default to the disjunction of the unique queries,
 512   # but allow the input query in case the ResultSet defines the query or the
 513   # user is abusing find
 514   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 515   my $query;
 516   if (exists $attrs->{key}) {
 517     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 518     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 519     $query = $self->_add_alias($unique_query, $alias);
 520   }
 521   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 522     # This means that we got here after a merger of relationship conditions
 523     # in ::Relationship::Base::search_related (the row method), and furthermore
 524     # the relationship is of the 'single' type. This means that the condition
 525     # provided by the relationship (already attached to $self) is sufficient,
 526     # as there can be only one row in the databse that would satisfy the
 527     # relationship
 528   }
 529   else {
 530     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 531     $query = @unique_queries
 532       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 533       : $self->_add_alias($input_query, $alias);
 534   }
 535
 536   # Run the query
 537   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 538   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 539     my $row = $rs->next;
 540     carp "Query returned more than one row" if $rs->next;
 541     return $row;
 542   }
 543   else {
 544     return $rs->single;
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my (@unique_queries, %seen_column_combinations);
 579   foreach my $name (@constraint_names) {
 580     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 581
 582     my $constraint_sig = join "\x00", sort @constraint_cols;
 583     next if $seen_column_combinations{$constraint_sig}++;
 584
 585     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 586
 587     my $num_cols = scalar @constraint_cols;
 588     my $num_query = scalar keys %$unique_query;
 589
 590     my $total = $num_query + $num_where;
 591     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 592       # The query is either unique on its own or is unique in combination with
 593       # the existing where clause
 594       push @unique_queries, $unique_query;
 595     }
 596   }
 597
 598   return @unique_queries;
 599 }
 600
 601 # _build_unique_query
 602 #
 603 # Constrain the specified query hash based on the specified column names.
 604
 605 sub _build_unique_query {
 606   my ($self, $query, $unique_cols) = @_;
 607
 608   return {
 609     map  { $_ => $query->{$_} }
 610     grep { exists $query->{$_} }
 611       @$unique_cols
 612   };
 613 }
 614
 615 =head2 search_related
 616
 617 =over 4
 618
 619 =item Arguments: $rel, $cond, \%attrs?
 620
 621 =item Return Value: $new_resultset
 622
 623 =back
 624
 625   $new_rs = $cd_rs->search_related('artist', {
 626     name => 'Emo-R-Us',
 627   });
 628
 629 Searches the specified relationship, optionally specifying a condition and
 630 attributes for matching records. See L</ATTRIBUTES> for more information.
 631
 632 =cut
 633
 634 sub search_related {
 635   return shift->related_resultset(shift)->search(@_);
 636 }
 637
 638 =head2 search_related_rs
 639
 640 This method works exactly the same as search_related, except that
 641 it guarantees a restultset, even in list context.
 642
 643 =cut
 644
 645 sub search_related_rs {
 646   return shift->related_resultset(shift)->search_rs(@_);
 647 }
 648
 649 =head2 cursor
 650
 651 =over 4
 652
 653 =item Arguments: none
 654
 655 =item Return Value: $cursor
 656
 657 =back
 658
 659 Returns a storage-driven cursor to the given resultset. See
 660 L<DBIx::Class::Cursor> for more information.
 661
 662 =cut
 663
 664 sub cursor {
 665   my ($self) = @_;
 666
 667   my $attrs = $self->_resolved_attrs_copy;
 668
 669   return $self->{cursor}
 670     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 671           $attrs->{where},$attrs);
 672 }
 673
 674 =head2 single
 675
 676 =over 4
 677
 678 =item Arguments: $cond?
 679
 680 =item Return Value: $row_object?
 681
 682 =back
 683
 684   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 685
 686 Inflates the first result without creating a cursor if the resultset has
 687 any records in it; if not returns nothing. Used by L</find> as a lean version of
 688 L</search>.
 689
 690 While this method can take an optional search condition (just like L</search>)
 691 being a fast-code-path it does not recognize search attributes. If you need to
 692 add extra joins or similar, call L</search> and then chain-call L</single> on the
 693 L<DBIx::Class::ResultSet> returned.
 694
 695 =over
 696
 697 =item B<Note>
 698
 699 As of 0.08100, this method enforces the assumption that the preceeding
 700 query returns only one row. If more than one row is returned, you will receive
 701 a warning:
 702
 703   Query returned more than one row
 704
 705 In this case, you should be using L</next> or L</find> instead, or if you really
 706 know what you are doing, use the L</rows> attribute to explicitly limit the size
 707 of the resultset.
 708
 709 This method will also throw an exception if it is called on a resultset prefetching
 710 has_many, as such a prefetch implies fetching multiple rows from the database in
 711 order to assemble the resulting object.
 712
 713 =back
 714
 715 =cut
 716
 717 sub single {
 718   my ($self, $where) = @_;
 719   if(@_ > 2) {
 720       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 721   }
 722
 723   my $attrs = $self->_resolved_attrs_copy;
 724
 725   if (keys %{$attrs->{collapse}}) {
 726     $self->throw_exception(
 727       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 728     );
 729   }
 730
 731   if ($where) {
 732     if (defined $attrs->{where}) {
 733       $attrs->{where} = {
 734         '-and' =>
 735             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 736                $where, delete $attrs->{where} ]
 737       };
 738     } else {
 739       $attrs->{where} = $where;
 740     }
 741   }
 742
 743 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 744 #  unless ($self->_is_unique_query($attrs->{where})) {
 745 #    carp "Query not guaranteed to return a single row"
 746 #      . "; please declare your unique constraints or use search instead";
 747 #  }
 748
 749   my @data = $self->result_source->storage->select_single(
 750     $attrs->{from}, $attrs->{select},
 751     $attrs->{where}, $attrs
 752   );
 753
 754   return (@data ? ($self->_construct_object(@data))[0] : undef);
 755 }
 756
 757
 758 # _is_unique_query
 759 #
 760 # Try to determine if the specified query is guaranteed to be unique, based on
 761 # the declared unique constraints.
 762
 763 sub _is_unique_query {
 764   my ($self, $query) = @_;
 765
 766   my $collapsed = $self->_collapse_query($query);
 767   my $alias = $self->{attrs}{alias};
 768
 769   foreach my $name ($self->result_source->unique_constraint_names) {
 770     my @unique_cols = map {
 771       "$alias.$_"
 772     } $self->result_source->unique_constraint_columns($name);
 773
 774     # Count the values for each unique column
 775     my %seen = map { $_ => 0 } @unique_cols;
 776
 777     foreach my $key (keys %$collapsed) {
 778       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 779       next unless exists $seen{$aliased};  # Additional constraints are okay
 780       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 781     }
 782
 783     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 784     return 1 unless grep { $_ != 1 } values %seen;
 785   }
 786
 787   return 0;
 788 }
 789
 790 # _collapse_query
 791 #
 792 # Recursively collapse the query, accumulating values for each column.
 793
 794 sub _collapse_query {
 795   my ($self, $query, $collapsed) = @_;
 796
 797   $collapsed ||= {};
 798
 799   if (ref $query eq 'ARRAY') {
 800     foreach my $subquery (@$query) {
 801       next unless ref $subquery;  # -or
 802       $collapsed = $self->_collapse_query($subquery, $collapsed);
 803     }
 804   }
 805   elsif (ref $query eq 'HASH') {
 806     if (keys %$query and (keys %$query)[0] eq '-and') {
 807       foreach my $subquery (@{$query->{-and}}) {
 808         $collapsed = $self->_collapse_query($subquery, $collapsed);
 809       }
 810     }
 811     else {
 812       foreach my $col (keys %$query) {
 813         my $value = $query->{$col};
 814         $collapsed->{$col}{$value}++;
 815       }
 816     }
 817   }
 818
 819   return $collapsed;
 820 }
 821
 822 =head2 get_column
 823
 824 =over 4
 825
 826 =item Arguments: $cond?
 827
 828 =item Return Value: $resultsetcolumn
 829
 830 =back
 831
 832   my $max_length = $rs->get_column('length')->max;
 833
 834 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 835
 836 =cut
 837
 838 sub get_column {
 839   my ($self, $column) = @_;
 840   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 841   return $new;
 842 }
 843
 844 =head2 search_like
 845
 846 =over 4
 847
 848 =item Arguments: $cond, \%attrs?
 849
 850 =item Return Value: $resultset (scalar context), @row_objs (list context)
 851
 852 =back
 853
 854   # WHERE title LIKE '%blue%'
 855   $cd_rs = $rs->search_like({ title => '%blue%'});
 856
 857 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 858 that this is simply a convenience method retained for ex Class::DBI users.
 859 You most likely want to use L</search> with specific operators.
 860
 861 For more information, see L<DBIx::Class::Manual::Cookbook>.
 862
 863 This method is deprecated and will be removed in 0.09. Use L</search()>
 864 instead. An example conversion is:
 865
 866   ->search_like({ foo => 'bar' });
 867
 868   # Becomes
 869
 870   ->search({ foo => { like => 'bar' } });
 871
 872 =cut
 873
 874 sub search_like {
 875   my $class = shift;
 876   carp (
 877     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 878    .' Instead use ->search({ x => { -like => "y%" } })'
 879    .' (note the outer pair of {}s - they are important!)'
 880   );
 881   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 882   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 883   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 884   return $class->search($query, { %$attrs });
 885 }
 886
 887 =head2 slice
 888
 889 =over 4
 890
 891 =item Arguments: $first, $last
 892
 893 =item Return Value: $resultset (scalar context), @row_objs (list context)
 894
 895 =back
 896
 897 Returns a resultset or object list representing a subset of elements from the
 898 resultset slice is called on. Indexes are from 0, i.e., to get the first
 899 three records, call:
 900
 901   my ($one, $two, $three) = $rs->slice(0, 2);
 902
 903 =cut
 904
 905 sub slice {
 906   my ($self, $min, $max) = @_;
 907   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 908   $attrs->{offset} = $self->{attrs}{offset} || 0;
 909   $attrs->{offset} += $min;
 910   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 911   return $self->search(undef(), $attrs);
 912   #my $slice = (ref $self)->new($self->result_source, $attrs);
 913   #return (wantarray ? $slice->all : $slice);
 914 }
 915
 916 =head2 next
 917
 918 =over 4
 919
 920 =item Arguments: none
 921
 922 =item Return Value: $result?
 923
 924 =back
 925
 926 Returns the next element in the resultset (C<undef> is there is none).
 927
 928 Can be used to efficiently iterate over records in the resultset:
 929
 930   my $rs = $schema->resultset('CD')->search;
 931   while (my $cd = $rs->next) {
 932     print $cd->title;
 933   }
 934
 935 Note that you need to store the resultset object, and call C<next> on it.
 936 Calling C<< resultset('Table')->next >> repeatedly will always return the
 937 first record from the resultset.
 938
 939 =cut
 940
 941 sub next {
 942   my ($self) = @_;
 943   if (my $cache = $self->get_cache) {
 944     $self->{all_cache_position} ||= 0;
 945     return $cache->[$self->{all_cache_position}++];
 946   }
 947   if ($self->{attrs}{cache}) {
 948     $self->{all_cache_position} = 1;
 949     return ($self->all)[0];
 950   }
 951   if ($self->{stashed_objects}) {
 952     my $obj = shift(@{$self->{stashed_objects}});
 953     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 954     return $obj;
 955   }
 956   my @row = (
 957     exists $self->{stashed_row}
 958       ? @{delete $self->{stashed_row}}
 959       : $self->cursor->next
 960   );
 961   return undef unless (@row);
 962   my ($row, @more) = $self->_construct_object(@row);
 963   $self->{stashed_objects} = \@more if @more;
 964   return $row;
 965 }
 966
 967 sub _construct_object {
 968   my ($self, @row) = @_;
 969
 970   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 971     or return ();
 972   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 973   @new = $self->{_attrs}{record_filter}->(@new)
 974     if exists $self->{_attrs}{record_filter};
 975   return @new;
 976 }
 977
 978 sub _collapse_result {
 979   my ($self, $as_proto, $row) = @_;
 980
 981   my @copy = @$row;
 982
 983   # 'foo'         => [ undef, 'foo' ]
 984   # 'foo.bar'     => [ 'foo', 'bar' ]
 985   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 986
 987   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 988
 989   my %collapse = %{$self->{_attrs}{collapse}||{}};
 990
 991   my @pri_index;
 992
 993   # if we're doing collapsing (has_many prefetch) we need to grab records
 994   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 995   # we know we don't have to bother.
 996
 997   # the reason for not using the collapse stuff directly is because if you
 998   # had for e.g. two artists in a row with no cds, the collapse info for
 999   # both would be NULL (undef) so you'd lose the second artist
1000
1001   # store just the index so we can check the array positions from the row
1002   # without having to contruct the full hash
1003
1004   if (keys %collapse) {
1005     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1006     foreach my $i (0 .. $#construct_as) {
1007       next if defined($construct_as[$i][0]); # only self table
1008       if (delete $pri{$construct_as[$i][1]}) {
1009         push(@pri_index, $i);
1010       }
1011       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1012     }
1013   }
1014
1015   # no need to do an if, it'll be empty if @pri_index is empty anyway
1016
1017   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1018
1019   my @const_rows;
1020
1021   do { # no need to check anything at the front, we always want the first row
1022
1023     my %const;
1024
1025     foreach my $this_as (@construct_as) {
1026       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1027     }
1028
1029     push(@const_rows, \%const);
1030
1031   } until ( # no pri_index => no collapse => drop straight out
1032       !@pri_index
1033     or
1034       do { # get another row, stash it, drop out if different PK
1035
1036         @copy = $self->cursor->next;
1037         $self->{stashed_row} = \@copy;
1038
1039         # last thing in do block, counts as true if anything doesn't match
1040
1041         # check xor defined first for NULL vs. NOT NULL then if one is
1042         # defined the other must be so check string equality
1043
1044         grep {
1045           (defined $pri_vals{$_} ^ defined $copy[$_])
1046           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1047         } @pri_index;
1048       }
1049   );
1050
1051   my $alias = $self->{attrs}{alias};
1052   my $info = [];
1053
1054   my %collapse_pos;
1055
1056   my @const_keys;
1057
1058   foreach my $const (@const_rows) {
1059     scalar @const_keys or do {
1060       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1061     };
1062     foreach my $key (@const_keys) {
1063       if (length $key) {
1064         my $target = $info;
1065         my @parts = split(/\./, $key);
1066         my $cur = '';
1067         my $data = $const->{$key};
1068         foreach my $p (@parts) {
1069           $target = $target->[1]->{$p} ||= [];
1070           $cur .= ".${p}";
1071           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1072             # collapsing at this point and on final part
1073             my $pos = $collapse_pos{$cur};
1074             CK: foreach my $ck (@ckey) {
1075               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1076                 $collapse_pos{$cur} = $data;
1077                 delete @collapse_pos{ # clear all positioning for sub-entries
1078                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1079                 };
1080                 push(@$target, []);
1081                 last CK;
1082               }
1083             }
1084           }
1085           if (exists $collapse{$cur}) {
1086             $target = $target->[-1];
1087           }
1088         }
1089         $target->[0] = $data;
1090       } else {
1091         $info->[0] = $const->{$key};
1092       }
1093     }
1094   }
1095
1096   return $info;
1097 }
1098
1099 =head2 result_source
1100
1101 =over 4
1102
1103 =item Arguments: $result_source?
1104
1105 =item Return Value: $result_source
1106
1107 =back
1108
1109 An accessor for the primary ResultSource object from which this ResultSet
1110 is derived.
1111
1112 =head2 result_class
1113
1114 =over 4
1115
1116 =item Arguments: $result_class?
1117
1118 =item Return Value: $result_class
1119
1120 =back
1121
1122 An accessor for the class to use when creating row objects. Defaults to
1123 C<< result_source->result_class >> - which in most cases is the name of the
1124 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1125
1126 Note that changing the result_class will also remove any components
1127 that were originally loaded in the source class via
1128 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1129 in the original source class will not run.
1130
1131 =cut
1132
1133 sub result_class {
1134   my ($self, $result_class) = @_;
1135   if ($result_class) {
1136     $self->ensure_class_loaded($result_class);
1137     $self->_result_class($result_class);
1138   }
1139   $self->_result_class;
1140 }
1141
1142 =head2 count
1143
1144 =over 4
1145
1146 =item Arguments: $cond, \%attrs??
1147
1148 =item Return Value: $count
1149
1150 =back
1151
1152 Performs an SQL C<COUNT> with the same query as the resultset was built
1153 with to find the number of elements. Passing arguments is equivalent to
1154 C<< $rs->search ($cond, \%attrs)->count >>
1155
1156 =cut
1157
1158 sub count {
1159   my $self = shift;
1160   return $self->search(@_)->count if @_ and defined $_[0];
1161   return scalar @{ $self->get_cache } if $self->get_cache;
1162
1163   my $attrs = $self->_resolved_attrs_copy;
1164
1165   # this is a little optimization - it is faster to do the limit
1166   # adjustments in software, instead of a subquery
1167   my $rows = delete $attrs->{rows};
1168   my $offset = delete $attrs->{offset};
1169
1170   my $crs;
1171   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1172     $crs = $self->_count_subq_rs ($attrs);
1173   }
1174   else {
1175     $crs = $self->_count_rs ($attrs);
1176   }
1177   my $count = $crs->next;
1178
1179   $count -= $offset if $offset;
1180   $count = $rows if $rows and $rows < $count;
1181   $count = 0 if ($count < 0);
1182
1183   return $count;
1184 }
1185
1186 =head2 count_rs
1187
1188 =over 4
1189
1190 =item Arguments: $cond, \%attrs??
1191
1192 =item Return Value: $count_rs
1193
1194 =back
1195
1196 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1197 This can be very handy for subqueries:
1198
1199   ->search( { amount => $some_rs->count_rs->as_query } )
1200
1201 As with regular resultsets the SQL query will be executed only after
1202 the resultset is accessed via L</next> or L</all>. That would return
1203 the same single value obtainable via L</count>.
1204
1205 =cut
1206
1207 sub count_rs {
1208   my $self = shift;
1209   return $self->search(@_)->count_rs if @_;
1210
1211   # this may look like a lack of abstraction (count() does about the same)
1212   # but in fact an _rs *must* use a subquery for the limits, as the
1213   # software based limiting can not be ported if this $rs is to be used
1214   # in a subquery itself (i.e. ->as_query)
1215   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1216     return $self->_count_subq_rs;
1217   }
1218   else {
1219     return $self->_count_rs;
1220   }
1221 }
1222
1223 #
1224 # returns a ResultSetColumn object tied to the count query
1225 #
1226 sub _count_rs {
1227   my ($self, $attrs) = @_;
1228
1229   my $rsrc = $self->result_source;
1230   $attrs ||= $self->_resolved_attrs;
1231
1232   my $tmp_attrs = { %$attrs };
1233
1234   # take off any limits, record_filter is cdbi, and no point of ordering a count
1235   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1236
1237   # overwrite the selector (supplied by the storage)
1238   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1239   $tmp_attrs->{as} = 'count';
1240
1241   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1242
1243   return $tmp_rs;
1244 }
1245
1246 #
1247 # same as above but uses a subquery
1248 #
1249 sub _count_subq_rs {
1250   my ($self, $attrs) = @_;
1251
1252   my $rsrc = $self->result_source;
1253   $attrs ||= $self->_resolved_attrs_copy;
1254
1255   my $sub_attrs = { %$attrs };
1256
1257   # extra selectors do not go in the subquery and there is no point of ordering it
1258   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1259
1260   # if we multi-prefetch we group_by primary keys only as this is what we would
1261   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1262   if ( keys %{$attrs->{collapse}}  ) {
1263     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1264   }
1265
1266   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1267
1268   # this is so that the query can be simplified e.g.
1269   # * ordering can be thrown away in things like Top limit
1270   $sub_attrs->{-for_count_only} = 1;
1271
1272   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1273
1274   $attrs->{from} = [{
1275     -alias => 'count_subq',
1276     -source_handle => $rsrc->handle,
1277     count_subq => $sub_rs->as_query,
1278   }];
1279
1280   # the subquery replaces this
1281   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1282
1283   return $self->_count_rs ($attrs);
1284 }
1285
1286 sub _bool {
1287   return 1;
1288 }
1289
1290 =head2 count_literal
1291
1292 =over 4
1293
1294 =item Arguments: $sql_fragment, @bind_values
1295
1296 =item Return Value: $count
1297
1298 =back
1299
1300 Counts the results in a literal query. Equivalent to calling L</search_literal>
1301 with the passed arguments, then L</count>.
1302
1303 =cut
1304
1305 sub count_literal { shift->search_literal(@_)->count; }
1306
1307 =head2 all
1308
1309 =over 4
1310
1311 =item Arguments: none
1312
1313 =item Return Value: @objects
1314
1315 =back
1316
1317 Returns all elements in the resultset. Called implicitly if the resultset
1318 is returned in list context.
1319
1320 =cut
1321
1322 sub all {
1323   my $self = shift;
1324   if(@_) {
1325       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1326   }
1327
1328   return @{ $self->get_cache } if $self->get_cache;
1329
1330   my @obj;
1331
1332   if (keys %{$self->_resolved_attrs->{collapse}}) {
1333     # Using $self->cursor->all is really just an optimisation.
1334     # If we're collapsing has_many prefetches it probably makes
1335     # very little difference, and this is cleaner than hacking
1336     # _construct_object to survive the approach
1337     $self->cursor->reset;
1338     my @row = $self->cursor->next;
1339     while (@row) {
1340       push(@obj, $self->_construct_object(@row));
1341       @row = (exists $self->{stashed_row}
1342                ? @{delete $self->{stashed_row}}
1343                : $self->cursor->next);
1344     }
1345   } else {
1346     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1347   }
1348
1349   $self->set_cache(\@obj) if $self->{attrs}{cache};
1350
1351   return @obj;
1352 }
1353
1354 =head2 reset
1355
1356 =over 4
1357
1358 =item Arguments: none
1359
1360 =item Return Value: $self
1361
1362 =back
1363
1364 Resets the resultset's cursor, so you can iterate through the elements again.
1365 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1366 another query.
1367
1368 =cut
1369
1370 sub reset {
1371   my ($self) = @_;
1372   delete $self->{_attrs} if exists $self->{_attrs};
1373   $self->{all_cache_position} = 0;
1374   $self->cursor->reset;
1375   return $self;
1376 }
1377
1378 =head2 first
1379
1380 =over 4
1381
1382 =item Arguments: none
1383
1384 =item Return Value: $object?
1385
1386 =back
1387
1388 Resets the resultset and returns an object for the first result (if the
1389 resultset returns anything).
1390
1391 =cut
1392
1393 sub first {
1394   return $_[0]->reset->next;
1395 }
1396
1397
1398 # _rs_update_delete
1399 #
1400 # Determines whether and what type of subquery is required for the $rs operation.
1401 # If grouping is necessary either supplies its own, or verifies the current one
1402 # After all is done delegates to the proper storage method.
1403
1404 sub _rs_update_delete {
1405   my ($self, $op, $values) = @_;
1406
1407   my $rsrc = $self->result_source;
1408
1409   # if a condition exists we need to strip all table qualifiers
1410   # if this is not possible we'll force a subquery below
1411   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1412
1413   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1414   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/row offset/);
1415
1416   if ($needs_group_by_subq or $needs_subq) {
1417
1418     # make a new $rs selecting only the PKs (that's all we really need)
1419     my $attrs = $self->_resolved_attrs_copy;
1420
1421     delete $attrs->{$_} for qw/collapse select as/;
1422     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1423
1424     if ($needs_group_by_subq) {
1425       # make sure no group_by was supplied, or if there is one - make sure it matches
1426       # the columns compiled above perfectly. Anything else can not be sanely executed
1427       # on most databases so croak right then and there
1428
1429       if (my $g = $attrs->{group_by}) {
1430         my @current_group_by = map
1431           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1432           @$g
1433         ;
1434
1435         if (
1436           join ("\x00", sort @current_group_by)
1437             ne
1438           join ("\x00", sort @{$attrs->{columns}} )
1439         ) {
1440           $self->throw_exception (
1441             "You have just attempted a $op operation on a resultset which does group_by"
1442             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1443             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1444             . ' kind of queries. Please retry the operation with a modified group_by or'
1445             . ' without using one at all.'
1446           );
1447         }
1448       }
1449       else {
1450         $attrs->{group_by} = $attrs->{columns};
1451       }
1452     }
1453
1454     my $subrs = (ref $self)->new($rsrc, $attrs);
1455
1456     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1457   }
1458   else {
1459     return $rsrc->storage->$op(
1460       $rsrc,
1461       $op eq 'update' ? $values : (),
1462       $cond,
1463     );
1464   }
1465 }
1466
1467 =head2 update
1468
1469 =over 4
1470
1471 =item Arguments: \%values
1472
1473 =item Return Value: $storage_rv
1474
1475 =back
1476
1477 Sets the specified columns in the resultset to the supplied values in a
1478 single query. Return value will be true if the update succeeded or false
1479 if no records were updated; exact type of success value is storage-dependent.
1480
1481 =cut
1482
1483 sub update {
1484   my ($self, $values) = @_;
1485   $self->throw_exception('Values for update must be a hash')
1486     unless ref $values eq 'HASH';
1487
1488   return $self->_rs_update_delete ('update', $values);
1489 }
1490
1491 =head2 update_all
1492
1493 =over 4
1494
1495 =item Arguments: \%values
1496
1497 =item Return Value: 1
1498
1499 =back
1500
1501 Fetches all objects and updates them one at a time. Note that C<update_all>
1502 will run DBIC cascade triggers, while L</update> will not.
1503
1504 =cut
1505
1506 sub update_all {
1507   my ($self, $values) = @_;
1508   $self->throw_exception('Values for update_all must be a hash')
1509     unless ref $values eq 'HASH';
1510   foreach my $obj ($self->all) {
1511     $obj->set_columns($values)->update;
1512   }
1513   return 1;
1514 }
1515
1516 =head2 delete
1517
1518 =over 4
1519
1520 =item Arguments: none
1521
1522 =item Return Value: $storage_rv
1523
1524 =back
1525
1526 Deletes the contents of the resultset from its result source. Note that this
1527 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1528 to run. See also L<DBIx::Class::Row/delete>.
1529
1530 Return value will be the amount of rows deleted; exact type of return value
1531 is storage-dependent.
1532
1533 =cut
1534
1535 sub delete {
1536   my $self = shift;
1537   $self->throw_exception('delete does not accept any arguments')
1538     if @_;
1539
1540   return $self->_rs_update_delete ('delete');
1541 }
1542
1543 =head2 delete_all
1544
1545 =over 4
1546
1547 =item Arguments: none
1548
1549 =item Return Value: 1
1550
1551 =back
1552
1553 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1554 will run DBIC cascade triggers, while L</delete> will not.
1555
1556 =cut
1557
1558 sub delete_all {
1559   my $self = shift;
1560   $self->throw_exception('delete_all does not accept any arguments')
1561     if @_;
1562
1563   $_->delete for $self->all;
1564   return 1;
1565 }
1566
1567 =head2 populate
1568
1569 =over 4
1570
1571 =item Arguments: \@data;
1572
1573 =back
1574
1575 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1576 For the arrayref of hashrefs style each hashref should be a structure suitable
1577 forsubmitting to a $resultset->create(...) method.
1578
1579 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1580 to insert the data, as this is a faster method.
1581
1582 Otherwise, each set of data is inserted into the database using
1583 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1584 accumulated into an array. The array itself, or an array reference
1585 is returned depending on scalar or list context.
1586
1587 Example:  Assuming an Artist Class that has many CDs Classes relating:
1588
1589   my $Artist_rs = $schema->resultset("Artist");
1590
1591   ## Void Context Example
1592   $Artist_rs->populate([
1593      { artistid => 4, name => 'Manufactured Crap', cds => [
1594         { title => 'My First CD', year => 2006 },
1595         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1596       ],
1597      },
1598      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1599         { title => 'My parents sold me to a record company' ,year => 2005 },
1600         { title => 'Why Am I So Ugly?', year => 2006 },
1601         { title => 'I Got Surgery and am now Popular', year => 2007 }
1602       ],
1603      },
1604   ]);
1605
1606   ## Array Context Example
1607   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1608     { name => "Artist One"},
1609     { name => "Artist Two"},
1610     { name => "Artist Three", cds=> [
1611     { title => "First CD", year => 2007},
1612     { title => "Second CD", year => 2008},
1613   ]}
1614   ]);
1615
1616   print $ArtistOne->name; ## response is 'Artist One'
1617   print $ArtistThree->cds->count ## reponse is '2'
1618
1619 For the arrayref of arrayrefs style,  the first element should be a list of the
1620 fieldsnames to which the remaining elements are rows being inserted.  For
1621 example:
1622
1623   $Arstist_rs->populate([
1624     [qw/artistid name/],
1625     [100, 'A Formally Unknown Singer'],
1626     [101, 'A singer that jumped the shark two albums ago'],
1627     [102, 'An actually cool singer.'],
1628   ]);
1629
1630 Please note an important effect on your data when choosing between void and
1631 wantarray context. Since void context goes straight to C<insert_bulk> in
1632 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1633 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1634 create primary keys for you, you will find that your PKs are empty.  In this
1635 case you will have to use the wantarray context in order to create those
1636 values.
1637
1638 =cut
1639
1640 sub populate {
1641   my $self = shift;
1642
1643   # cruft placed in standalone method
1644   my $data = $self->_normalize_populate_args(@_);
1645
1646   if(defined wantarray) {
1647     my @created;
1648     foreach my $item (@$data) {
1649       push(@created, $self->create($item));
1650     }
1651     return wantarray ? @created : \@created;
1652   } else {
1653     my $first = $data->[0];
1654
1655     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1656     # it relationship data
1657     my (@rels, @columns);
1658     for (keys %$first) {
1659       my $ref = ref $first->{$_};
1660       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1661         ? push @rels, $_
1662         : push @columns, $_
1663       ;
1664     }
1665
1666     my @pks = $self->result_source->primary_columns;
1667
1668     ## do the belongs_to relationships
1669     foreach my $index (0..$#$data) {
1670
1671       # delegate to create() for any dataset without primary keys with specified relationships
1672       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1673         for my $r (@rels) {
1674           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1675             my @ret = $self->populate($data);
1676             return;
1677           }
1678         }
1679       }
1680
1681       foreach my $rel (@rels) {
1682         next unless ref $data->[$index]->{$rel} eq "HASH";
1683         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1684         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1685         my $related = $result->result_source->_resolve_condition(
1686           $result->result_source->relationship_info($reverse)->{cond},
1687           $self,
1688           $result,
1689         );
1690
1691         delete $data->[$index]->{$rel};
1692         $data->[$index] = {%{$data->[$index]}, %$related};
1693
1694         push @columns, keys %$related if $index == 0;
1695       }
1696     }
1697
1698     ## inherit the data locked in the conditions of the resultset
1699     my ($rs_data) = $self->_merge_cond_with_data({});
1700     delete @{$rs_data}{@columns};
1701     my @inherit_cols = keys %$rs_data;
1702     my @inherit_data = values %$rs_data;
1703
1704     ## do bulk insert on current row
1705     $self->result_source->storage->insert_bulk(
1706       $self->result_source,
1707       [@columns, @inherit_cols],
1708       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1709     );
1710
1711     ## do the has_many relationships
1712     foreach my $item (@$data) {
1713
1714       foreach my $rel (@rels) {
1715         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1716
1717         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1718      || $self->throw_exception('Cannot find the relating object.');
1719
1720         my $child = $parent->$rel;
1721
1722         my $related = $child->result_source->_resolve_condition(
1723           $parent->result_source->relationship_info($rel)->{cond},
1724           $child,
1725           $parent,
1726         );
1727
1728         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1729         my @populate = map { {%$_, %$related} } @rows_to_add;
1730
1731         $child->populate( \@populate );
1732       }
1733     }
1734   }
1735 }
1736
1737
1738 # populate() argumnets went over several incarnations
1739 # What we ultimately support is AoH
1740 sub _normalize_populate_args {
1741   my ($self, $arg) = @_;
1742
1743   if (ref $arg eq 'ARRAY') {
1744     if (ref $arg->[0] eq 'HASH') {
1745       return $arg;
1746     }
1747     elsif (ref $arg->[0] eq 'ARRAY') {
1748       my @ret;
1749       my @colnames = @{$arg->[0]};
1750       foreach my $values (@{$arg}[1 .. $#$arg]) {
1751         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
1752       }
1753       return \@ret;
1754     }
1755   }
1756
1757   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
1758 }
1759
1760 =head2 pager
1761
1762 =over 4
1763
1764 =item Arguments: none
1765
1766 =item Return Value: $pager
1767
1768 =back
1769
1770 Return Value a L<Data::Page> object for the current resultset. Only makes
1771 sense for queries with a C<page> attribute.
1772
1773 To get the full count of entries for a paged resultset, call
1774 C<total_entries> on the L<Data::Page> object.
1775
1776 =cut
1777
1778 sub pager {
1779   my ($self) = @_;
1780
1781   return $self->{pager} if $self->{pager};
1782
1783   my $attrs = $self->{attrs};
1784   $self->throw_exception("Can't create pager for non-paged rs")
1785     unless $self->{attrs}{page};
1786   $attrs->{rows} ||= 10;
1787
1788   # throw away the paging flags and re-run the count (possibly
1789   # with a subselect) to get the real total count
1790   my $count_attrs = { %$attrs };
1791   delete $count_attrs->{$_} for qw/rows offset page pager/;
1792   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1793
1794   return $self->{pager} = Data::Page->new(
1795     $total_count,
1796     $attrs->{rows},
1797     $self->{attrs}{page}
1798   );
1799 }
1800
1801 =head2 page
1802
1803 =over 4
1804
1805 =item Arguments: $page_number
1806
1807 =item Return Value: $rs
1808
1809 =back
1810
1811 Returns a resultset for the $page_number page of the resultset on which page
1812 is called, where each page contains a number of rows equal to the 'rows'
1813 attribute set on the resultset (10 by default).
1814
1815 =cut
1816
1817 sub page {
1818   my ($self, $page) = @_;
1819   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1820 }
1821
1822 =head2 new_result
1823
1824 =over 4
1825
1826 =item Arguments: \%vals
1827
1828 =item Return Value: $rowobject
1829
1830 =back
1831
1832 Creates a new row object in the resultset's result class and returns
1833 it. The row is not inserted into the database at this point, call
1834 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1835 will tell you whether the row object has been inserted or not.
1836
1837 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1838
1839 =cut
1840
1841 sub new_result {
1842   my ($self, $values) = @_;
1843   $self->throw_exception( "new_result needs a hash" )
1844     unless (ref $values eq 'HASH');
1845
1846   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
1847
1848   my %new = (
1849     %$merged_cond,
1850     @$cols_from_relations
1851       ? (-cols_from_relations => $cols_from_relations)
1852       : (),
1853     -source_handle => $self->_source_handle,
1854     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1855   );
1856
1857   return $self->result_class->new(\%new);
1858 }
1859
1860 # _merge_cond_with_data
1861 #
1862 # Takes a simple hash of K/V data and returns its copy merged with the
1863 # condition already present on the resultset. Additionally returns an
1864 # arrayref of value/condition names, which were inferred from related
1865 # objects (this is needed for in-memory related objects)
1866 sub _merge_cond_with_data {
1867   my ($self, $data) = @_;
1868
1869   my (%new_data, @cols_from_relations);
1870
1871   my $alias = $self->{attrs}{alias};
1872
1873   if (! defined $self->{cond}) {
1874     # just massage $data below
1875   }
1876   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
1877     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1878     @cols_from_relations = keys %new_data;
1879   }
1880   elsif (ref $self->{cond} ne 'HASH') {
1881     $self->throw_exception(
1882       "Can't abstract implicit construct, resultset condition not a hash"
1883     );
1884   }
1885   else {
1886     # precendence must be given to passed values over values inherited from
1887     # the cond, so the order here is important.
1888     my $collapsed_cond = $self->_collapse_cond($self->{cond});
1889     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
1890
1891     while ( my($col, $value) = each %implied ) {
1892       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
1893         $new_data{$col} = $value->{'='};
1894         next;
1895       }
1896       $new_data{$col} = $value if $self->_is_deterministic_value($value);
1897     }
1898   }
1899
1900   %new_data = (
1901     %new_data,
1902     %{ $self->_remove_alias($data, $alias) },
1903   );
1904
1905   return (\%new_data, \@cols_from_relations);
1906 }
1907
1908 # _is_deterministic_value
1909 #
1910 # Make an effor to strip non-deterministic values from the condition,
1911 # to make sure new_result chokes less
1912
1913 sub _is_deterministic_value {
1914   my $self = shift;
1915   my $value = shift;
1916   my $ref_type = ref $value;
1917   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1918   return 1 if Scalar::Util::blessed($value);
1919   return 0;
1920 }
1921
1922 # _has_resolved_attr
1923 #
1924 # determines if the resultset defines at least one
1925 # of the attributes supplied
1926 #
1927 # used to determine if a subquery is neccessary
1928 #
1929 # supports some virtual attributes:
1930 #   -join
1931 #     This will scan for any joins being present on the resultset.
1932 #     It is not a mere key-search but a deep inspection of {from}
1933 #
1934
1935 sub _has_resolved_attr {
1936   my ($self, @attr_names) = @_;
1937
1938   my $attrs = $self->_resolved_attrs;
1939
1940   my %extra_checks;
1941
1942   for my $n (@attr_names) {
1943     if (grep { $n eq $_ } (qw/-join/) ) {
1944       $extra_checks{$n}++;
1945       next;
1946     }
1947
1948     my $attr =  $attrs->{$n};
1949
1950     next if not defined $attr;
1951
1952     if (ref $attr eq 'HASH') {
1953       return 1 if keys %$attr;
1954     }
1955     elsif (ref $attr eq 'ARRAY') {
1956       return 1 if @$attr;
1957     }
1958     else {
1959       return 1 if $attr;
1960     }
1961   }
1962
1963   # a resolved join is expressed as a multi-level from
1964   return 1 if (
1965     $extra_checks{-join}
1966       and
1967     ref $attrs->{from} eq 'ARRAY'
1968       and
1969     @{$attrs->{from}} > 1
1970   );
1971
1972   return 0;
1973 }
1974
1975 # _collapse_cond
1976 #
1977 # Recursively collapse the condition.
1978
1979 sub _collapse_cond {
1980   my ($self, $cond, $collapsed) = @_;
1981
1982   $collapsed ||= {};
1983
1984   if (ref $cond eq 'ARRAY') {
1985     foreach my $subcond (@$cond) {
1986       next unless ref $subcond;  # -or
1987       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1988     }
1989   }
1990   elsif (ref $cond eq 'HASH') {
1991     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1992       foreach my $subcond (@{$cond->{-and}}) {
1993         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1994       }
1995     }
1996     else {
1997       foreach my $col (keys %$cond) {
1998         my $value = $cond->{$col};
1999         $collapsed->{$col} = $value;
2000       }
2001     }
2002   }
2003
2004   return $collapsed;
2005 }
2006
2007 # _remove_alias
2008 #
2009 # Remove the specified alias from the specified query hash. A copy is made so
2010 # the original query is not modified.
2011
2012 sub _remove_alias {
2013   my ($self, $query, $alias) = @_;
2014
2015   my %orig = %{ $query || {} };
2016   my %unaliased;
2017
2018   foreach my $key (keys %orig) {
2019     if ($key !~ /\./) {
2020       $unaliased{$key} = $orig{$key};
2021       next;
2022     }
2023     $unaliased{$1} = $orig{$key}
2024       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2025   }
2026
2027   return \%unaliased;
2028 }
2029
2030 =head2 as_query
2031
2032 =over 4
2033
2034 =item Arguments: none
2035
2036 =item Return Value: \[ $sql, @bind ]
2037
2038 =back
2039
2040 Returns the SQL query and bind vars associated with the invocant.
2041
2042 This is generally used as the RHS for a subquery.
2043
2044 =cut
2045
2046 sub as_query {
2047   my $self = shift;
2048
2049   my $attrs = $self->_resolved_attrs_copy;
2050
2051   # For future use:
2052   #
2053   # in list ctx:
2054   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2055   # $sql also has no wrapping parenthesis in list ctx
2056   #
2057   my $sqlbind = $self->result_source->storage
2058     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2059
2060   return $sqlbind;
2061 }
2062
2063 =head2 find_or_new
2064
2065 =over 4
2066
2067 =item Arguments: \%vals, \%attrs?
2068
2069 =item Return Value: $rowobject
2070
2071 =back
2072
2073   my $artist = $schema->resultset('Artist')->find_or_new(
2074     { artist => 'fred' }, { key => 'artists' });
2075
2076   $cd->cd_to_producer->find_or_new({ producer => $producer },
2077                                    { key => 'primary });
2078
2079 Find an existing record from this resultset, based on its primary
2080 key, or a unique constraint. If none exists, instantiate a new result
2081 object and return it. The object will not be saved into your storage
2082 until you call L<DBIx::Class::Row/insert> on it.
2083
2084 You most likely want this method when looking for existing rows using
2085 a unique constraint that is not the primary key, or looking for
2086 related rows.
2087
2088 If you want objects to be saved immediately, use L</find_or_create>
2089 instead.
2090
2091 B<Note>: Take care when using C<find_or_new> with a table having
2092 columns with default values that you intend to be automatically
2093 supplied by the database (e.g. an auto_increment primary key column).
2094 In normal usage, the value of such columns should NOT be included at
2095 all in the call to C<find_or_new>, even when set to C<undef>.
2096
2097 =cut
2098
2099 sub find_or_new {
2100   my $self     = shift;
2101   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2102   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2103   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2104     return $row;
2105   }
2106   return $self->new_result($hash);
2107 }
2108
2109 =head2 create
2110
2111 =over 4
2112
2113 =item Arguments: \%vals
2114
2115 =item Return Value: a L<DBIx::Class::Row> $object
2116
2117 =back
2118
2119 Attempt to create a single new row or a row with multiple related rows
2120 in the table represented by the resultset (and related tables). This
2121 will not check for duplicate rows before inserting, use
2122 L</find_or_create> to do that.
2123
2124 To create one row for this resultset, pass a hashref of key/value
2125 pairs representing the columns of the table and the values you wish to
2126 store. If the appropriate relationships are set up, foreign key fields
2127 can also be passed an object representing the foreign row, and the
2128 value will be set to its primary key.
2129
2130 To create related objects, pass a hashref of related-object column values
2131 B<keyed on the relationship name>. If the relationship is of type C<multi>
2132 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2133 The process will correctly identify columns holding foreign keys, and will
2134 transparrently populate them from the keys of the corresponding relation.
2135 This can be applied recursively, and will work correctly for a structure
2136 with an arbitrary depth and width, as long as the relationships actually
2137 exists and the correct column data has been supplied.
2138
2139
2140 Instead of hashrefs of plain related data (key/value pairs), you may
2141 also pass new or inserted objects. New objects (not inserted yet, see
2142 L</new>), will be inserted into their appropriate tables.
2143
2144 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2145
2146 Example of creating a new row.
2147
2148   $person_rs->create({
2149     name=>"Some Person",
2150     email=>"somebody@someplace.com"
2151   });
2152
2153 Example of creating a new row and also creating rows in a related C<has_many>
2154 or C<has_one> resultset.  Note Arrayref.
2155
2156   $artist_rs->create(
2157      { artistid => 4, name => 'Manufactured Crap', cds => [
2158         { title => 'My First CD', year => 2006 },
2159         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2160       ],
2161      },
2162   );
2163
2164 Example of creating a new row and also creating a row in a related
2165 C<belongs_to>resultset. Note Hashref.
2166
2167   $cd_rs->create({
2168     title=>"Music for Silly Walks",
2169     year=>2000,
2170     artist => {
2171       name=>"Silly Musician",
2172     }
2173   });
2174
2175 =over
2176
2177 =item WARNING
2178
2179 When subclassing ResultSet never attempt to override this method. Since
2180 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2181 lot of the internals simply never call it, so your override will be
2182 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2183 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2184 L</create> process you need to intervene.
2185
2186 =back
2187
2188 =cut
2189
2190 sub create {
2191   my ($self, $attrs) = @_;
2192   $self->throw_exception( "create needs a hashref" )
2193     unless ref $attrs eq 'HASH';
2194   return $self->new_result($attrs)->insert;
2195 }
2196
2197 =head2 find_or_create
2198
2199 =over 4
2200
2201 =item Arguments: \%vals, \%attrs?
2202
2203 =item Return Value: $rowobject
2204
2205 =back
2206
2207   $cd->cd_to_producer->find_or_create({ producer => $producer },
2208                                       { key => 'primary' });
2209
2210 Tries to find a record based on its primary key or unique constraints; if none
2211 is found, creates one and returns that instead.
2212
2213   my $cd = $schema->resultset('CD')->find_or_create({
2214     cdid   => 5,
2215     artist => 'Massive Attack',
2216     title  => 'Mezzanine',
2217     year   => 2005,
2218   });
2219
2220 Also takes an optional C<key> attribute, to search by a specific key or unique
2221 constraint. For example:
2222
2223   my $cd = $schema->resultset('CD')->find_or_create(
2224     {
2225       artist => 'Massive Attack',
2226       title  => 'Mezzanine',
2227     },
2228     { key => 'cd_artist_title' }
2229   );
2230
2231 B<Note>: Because find_or_create() reads from the database and then
2232 possibly inserts based on the result, this method is subject to a race
2233 condition. Another process could create a record in the table after
2234 the find has completed and before the create has started. To avoid
2235 this problem, use find_or_create() inside a transaction.
2236
2237 B<Note>: Take care when using C<find_or_create> with a table having
2238 columns with default values that you intend to be automatically
2239 supplied by the database (e.g. an auto_increment primary key column).
2240 In normal usage, the value of such columns should NOT be included at
2241 all in the call to C<find_or_create>, even when set to C<undef>.
2242
2243 See also L</find> and L</update_or_create>. For information on how to declare
2244 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2245
2246 =cut
2247
2248 sub find_or_create {
2249   my $self     = shift;
2250   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2251   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2252   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2253     return $row;
2254   }
2255   return $self->create($hash);
2256 }
2257
2258 =head2 update_or_create
2259
2260 =over 4
2261
2262 =item Arguments: \%col_values, { key => $unique_constraint }?
2263
2264 =item Return Value: $rowobject
2265
2266 =back
2267
2268   $resultset->update_or_create({ col => $val, ... });
2269
2270 First, searches for an existing row matching one of the unique constraints
2271 (including the primary key) on the source of this resultset. If a row is
2272 found, updates it with the other given column values. Otherwise, creates a new
2273 row.
2274
2275 Takes an optional C<key> attribute to search on a specific unique constraint.
2276 For example:
2277
2278   # In your application
2279   my $cd = $schema->resultset('CD')->update_or_create(
2280     {
2281       artist => 'Massive Attack',
2282       title  => 'Mezzanine',
2283       year   => 1998,
2284     },
2285     { key => 'cd_artist_title' }
2286   );
2287
2288   $cd->cd_to_producer->update_or_create({
2289     producer => $producer,
2290     name => 'harry',
2291   }, {
2292     key => 'primary,
2293   });
2294
2295
2296 If no C<key> is specified, it searches on all unique constraints defined on the
2297 source, including the primary key.
2298
2299 If the C<key> is specified as C<primary>, it searches only on the primary key.
2300
2301 See also L</find> and L</find_or_create>. For information on how to declare
2302 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2303
2304 B<Note>: Take care when using C<update_or_create> with a table having
2305 columns with default values that you intend to be automatically
2306 supplied by the database (e.g. an auto_increment primary key column).
2307 In normal usage, the value of such columns should NOT be included at
2308 all in the call to C<update_or_create>, even when set to C<undef>.
2309
2310 =cut
2311
2312 sub update_or_create {
2313   my $self = shift;
2314   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2315   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2316
2317   my $row = $self->find($cond, $attrs);
2318   if (defined $row) {
2319     $row->update($cond);
2320     return $row;
2321   }
2322
2323   return $self->create($cond);
2324 }
2325
2326 =head2 update_or_new
2327
2328 =over 4
2329
2330 =item Arguments: \%col_values, { key => $unique_constraint }?
2331
2332 =item Return Value: $rowobject
2333
2334 =back
2335
2336   $resultset->update_or_new({ col => $val, ... });
2337
2338 First, searches for an existing row matching one of the unique constraints
2339 (including the primary key) on the source of this resultset. If a row is
2340 found, updates it with the other given column values. Otherwise, instantiate
2341 a new result object and return it. The object will not be saved into your storage
2342 until you call L<DBIx::Class::Row/insert> on it.
2343
2344 Takes an optional C<key> attribute to search on a specific unique constraint.
2345 For example:
2346
2347   # In your application
2348   my $cd = $schema->resultset('CD')->update_or_new(
2349     {
2350       artist => 'Massive Attack',
2351       title  => 'Mezzanine',
2352       year   => 1998,
2353     },
2354     { key => 'cd_artist_title' }
2355   );
2356
2357   if ($cd->in_storage) {
2358       # the cd was updated
2359   }
2360   else {
2361       # the cd is not yet in the database, let's insert it
2362       $cd->insert;
2363   }
2364
2365 B<Note>: Take care when using C<update_or_new> with a table having
2366 columns with default values that you intend to be automatically
2367 supplied by the database (e.g. an auto_increment primary key column).
2368 In normal usage, the value of such columns should NOT be included at
2369 all in the call to C<update_or_new>, even when set to C<undef>.
2370
2371 See also L</find>, L</find_or_create> and L</find_or_new>.
2372
2373 =cut
2374
2375 sub update_or_new {
2376     my $self  = shift;
2377     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2378     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2379
2380     my $row = $self->find( $cond, $attrs );
2381     if ( defined $row ) {
2382         $row->update($cond);
2383         return $row;
2384     }
2385
2386     return $self->new_result($cond);
2387 }
2388
2389 =head2 get_cache
2390
2391 =over 4
2392
2393 =item Arguments: none
2394
2395 =item Return Value: \@cache_objects?
2396
2397 =back
2398
2399 Gets the contents of the cache for the resultset, if the cache is set.
2400
2401 The cache is populated either by using the L</prefetch> attribute to
2402 L</search> or by calling L</set_cache>.
2403
2404 =cut
2405
2406 sub get_cache {
2407   shift->{all_cache};
2408 }
2409
2410 =head2 set_cache
2411
2412 =over 4
2413
2414 =item Arguments: \@cache_objects
2415
2416 =item Return Value: \@cache_objects
2417
2418 =back
2419
2420 Sets the contents of the cache for the resultset. Expects an arrayref
2421 of objects of the same class as those produced by the resultset. Note that
2422 if the cache is set the resultset will return the cached objects rather
2423 than re-querying the database even if the cache attr is not set.
2424
2425 The contents of the cache can also be populated by using the
2426 L</prefetch> attribute to L</search>.
2427
2428 =cut
2429
2430 sub set_cache {
2431   my ( $self, $data ) = @_;
2432   $self->throw_exception("set_cache requires an arrayref")
2433       if defined($data) && (ref $data ne 'ARRAY');
2434   $self->{all_cache} = $data;
2435 }
2436
2437 =head2 clear_cache
2438
2439 =over 4
2440
2441 =item Arguments: none
2442
2443 =item Return Value: []
2444
2445 =back
2446
2447 Clears the cache for the resultset.
2448
2449 =cut
2450
2451 sub clear_cache {
2452   shift->set_cache(undef);
2453 }
2454
2455 =head2 is_paged
2456
2457 =over 4
2458
2459 =item Arguments: none
2460
2461 =item Return Value: true, if the resultset has been paginated
2462
2463 =back
2464
2465 =cut
2466
2467 sub is_paged {
2468   my ($self) = @_;
2469   return !!$self->{attrs}{page};
2470 }
2471
2472 =head2 related_resultset
2473
2474 =over 4
2475
2476 =item Arguments: $relationship_name
2477
2478 =item Return Value: $resultset
2479
2480 =back
2481
2482 Returns a related resultset for the supplied relationship name.
2483
2484   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2485
2486 =cut
2487
2488 sub related_resultset {
2489   my ($self, $rel) = @_;
2490
2491   $self->{related_resultsets} ||= {};
2492   return $self->{related_resultsets}{$rel} ||= do {
2493     my $rsrc = $self->result_source;
2494     my $rel_info = $rsrc->relationship_info($rel);
2495
2496     $self->throw_exception(
2497       "search_related: result source '" . $rsrc->source_name .
2498         "' has no such relationship $rel")
2499       unless $rel_info;
2500
2501     my $attrs = $self->_chain_relationship($rel);
2502
2503     my $join_count = $attrs->{seen_join}{$rel};
2504
2505     my $alias = $self->result_source->storage
2506         ->relname_to_table_alias($rel, $join_count);
2507
2508     # since this is search_related, and we already slid the select window inwards
2509     # (the select/as attrs were deleted in the beginning), we need to flip all
2510     # left joins to inner, so we get the expected results
2511     # read the comment on top of the actual function to see what this does
2512     $attrs->{from} = $rsrc->schema->storage->_straight_join_to_node ($attrs->{from}, $alias);
2513
2514
2515     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2516     delete @{$attrs}{qw(result_class alias)};
2517
2518     my $new_cache;
2519
2520     if (my $cache = $self->get_cache) {
2521       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2522         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2523                         @$cache ];
2524       }
2525     }
2526
2527     my $rel_source = $rsrc->related_source($rel);
2528
2529     my $new = do {
2530
2531       # The reason we do this now instead of passing the alias to the
2532       # search_rs below is that if you wrap/overload resultset on the
2533       # source you need to know what alias it's -going- to have for things
2534       # to work sanely (e.g. RestrictWithObject wants to be able to add
2535       # extra query restrictions, and these may need to be $alias.)
2536
2537       my $rel_attrs = $rel_source->resultset_attributes;
2538       local $rel_attrs->{alias} = $alias;
2539
2540       $rel_source->resultset
2541                  ->search_rs(
2542                      undef, {
2543                        %$attrs,
2544                        where => $attrs->{where},
2545                    });
2546     };
2547     $new->set_cache($new_cache) if $new_cache;
2548     $new;
2549   };
2550 }
2551
2552 =head2 current_source_alias
2553
2554 =over 4
2555
2556 =item Arguments: none
2557
2558 =item Return Value: $source_alias
2559
2560 =back
2561
2562 Returns the current table alias for the result source this resultset is built
2563 on, that will be used in the SQL query. Usually it is C<me>.
2564
2565 Currently the source alias that refers to the result set returned by a
2566 L</search>/L</find> family method depends on how you got to the resultset: it's
2567 C<me> by default, but eg. L</search_related> aliases it to the related result
2568 source name (and keeps C<me> referring to the original result set). The long
2569 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2570 (and make this method unnecessary).
2571
2572 Thus it's currently necessary to use this method in predefined queries (see
2573 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2574 source alias of the current result set:
2575
2576   # in a result set class
2577   sub modified_by {
2578     my ($self, $user) = @_;
2579
2580     my $me = $self->current_source_alias;
2581
2582     return $self->search(
2583       "$me.modified" => $user->id,
2584     );
2585   }
2586
2587 =cut
2588
2589 sub current_source_alias {
2590   my ($self) = @_;
2591
2592   return ($self->{attrs} || {})->{alias} || 'me';
2593 }
2594
2595 =head2 as_subselect_rs
2596
2597 =over 4
2598
2599 =item Arguments: none
2600
2601 =item Return Value: $resultset
2602
2603 =back
2604
2605 Act as a barrier to SQL symbols.  The resultset provided will be made into a
2606 "virtual view" by including it as a subquery within the from clause.  From this
2607 point on, any joined tables are inaccessible to ->search on the resultset (as if
2608 it were simply where-filtered without joins).  For example:
2609
2610  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
2611
2612  # 'x' now pollutes the query namespace
2613
2614  # So the following works as expected
2615  my $ok_rs = $rs->search({'x.other' => 1});
2616
2617  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
2618  # def) we look for one row with contradictory terms and join in another table
2619  # (aliased 'x_2') which we never use
2620  my $broken_rs = $rs->search({'x.name' => 'def'});
2621
2622  my $rs2 = $rs->as_subselect_rs;
2623
2624  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
2625  my $not_joined_rs = $rs2->search({'x.other' => 1});
2626
2627  # works as expected: finds a 'table' row related to two x rows (abc and def)
2628  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
2629
2630 Another example of when one might use this would be to select a subset of
2631 columns in a group by clause:
2632
2633  my $rs = $schema->resultset('Bar')->search(undef, {
2634    group_by => [qw{ id foo_id baz_id }],
2635  })->as_subselect_rs->search(undef, {
2636    columns => [qw{ id foo_id }]
2637  });
2638
2639 In the above example normally columns would have to be equal to the group by,
2640 but because we isolated the group by into a subselect the above works.
2641
2642 =cut
2643
2644 sub as_subselect_rs {
2645    my $self = shift;
2646
2647    return $self->result_source->resultset->search( undef, {
2648       alias => $self->current_source_alias,
2649       from => [{
2650             $self->current_source_alias => $self->as_query,
2651             -alias         => $self->current_source_alias,
2652             -source_handle => $self->result_source->handle,
2653          }]
2654    });
2655 }
2656
2657 # This code is called by search_related, and makes sure there
2658 # is clear separation between the joins before, during, and
2659 # after the relationship. This information is needed later
2660 # in order to properly resolve prefetch aliases (any alias
2661 # with a relation_chain_depth less than the depth of the
2662 # current prefetch is not considered)
2663 #
2664 # The increments happen twice per join. An even number means a
2665 # relationship specified via a search_related, whereas an odd
2666 # number indicates a join/prefetch added via attributes
2667 #
2668 # Also this code will wrap the current resultset (the one we
2669 # chain to) in a subselect IFF it contains limiting attributes
2670 sub _chain_relationship {
2671   my ($self, $rel) = @_;
2672   my $source = $self->result_source;
2673   my $attrs = { %{$self->{attrs}||{}} };
2674
2675   # we need to take the prefetch the attrs into account before we
2676   # ->_resolve_join as otherwise they get lost - captainL
2677   my $join = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2678
2679   delete @{$attrs}{qw/join prefetch collapse distinct select as columns +select +as +columns/};
2680
2681   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
2682
2683   my $from;
2684   my @force_subq_attrs = qw/offset rows group_by having/;
2685
2686   if (
2687     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
2688       ||
2689     $self->_has_resolved_attr (@force_subq_attrs)
2690   ) {
2691     # Nuke the prefetch (if any) before the new $rs attrs
2692     # are resolved (prefetch is useless - we are wrapping
2693     # a subquery anyway).
2694     my $rs_copy = $self->search;
2695     $rs_copy->{attrs}{join} = $self->_merge_attr (
2696       $rs_copy->{attrs}{join},
2697       delete $rs_copy->{attrs}{prefetch},
2698     );
2699
2700     $from = [{
2701       -source_handle => $source->handle,
2702       -alias => $attrs->{alias},
2703       $attrs->{alias} => $rs_copy->as_query,
2704     }];
2705     delete @{$attrs}{@force_subq_attrs, 'where'};
2706     $seen->{-relation_chain_depth} = 0;
2707   }
2708   elsif ($attrs->{from}) {  #shallow copy suffices
2709     $from = [ @{$attrs->{from}} ];
2710   }
2711   else {
2712     $from = [{
2713       -source_handle => $source->handle,
2714       -alias => $attrs->{alias},
2715       $attrs->{alias} => $source->from,
2716     }];
2717   }
2718
2719   my $jpath = ($seen->{-relation_chain_depth})
2720     ? $from->[-1][0]{-join_path}
2721     : [];
2722
2723   my @requested_joins = $source->_resolve_join(
2724     $join,
2725     $attrs->{alias},
2726     $seen,
2727     $jpath,
2728   );
2729
2730   push @$from, @requested_joins;
2731
2732   $seen->{-relation_chain_depth}++;
2733
2734   # if $self already had a join/prefetch specified on it, the requested
2735   # $rel might very well be already included. What we do in this case
2736   # is effectively a no-op (except that we bump up the chain_depth on
2737   # the join in question so we could tell it *is* the search_related)
2738   my $already_joined;
2739
2740   # we consider the last one thus reverse
2741   for my $j (reverse @requested_joins) {
2742     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
2743     if ($rel eq $last_j) {
2744       $j->[0]{-relation_chain_depth}++;
2745       $already_joined++;
2746       last;
2747     }
2748   }
2749
2750   unless ($already_joined) {
2751     push @$from, $source->_resolve_join(
2752       $rel,
2753       $attrs->{alias},
2754       $seen,
2755       $jpath,
2756     );
2757   }
2758
2759   $seen->{-relation_chain_depth}++;
2760
2761   return {%$attrs, from => $from, seen_join => $seen};
2762 }
2763
2764 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2765 sub _resolved_attrs_copy {
2766   my $self = shift;
2767   return { %{$self->_resolved_attrs (@_)} };
2768 }
2769
2770 sub _resolved_attrs {
2771   my $self = shift;
2772   return $self->{_attrs} if $self->{_attrs};
2773
2774   my $attrs  = { %{ $self->{attrs} || {} } };
2775   my $source = $self->result_source;
2776   my $alias  = $attrs->{alias};
2777
2778   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2779   my @colbits;
2780
2781   # build columns (as long as select isn't set) into a set of as/select hashes
2782   unless ( $attrs->{select} ) {
2783
2784     my @cols;
2785     if ( ref $attrs->{columns} eq 'ARRAY' ) {
2786       @cols = @{ delete $attrs->{columns}}
2787     } elsif ( defined $attrs->{columns} ) {
2788       @cols = delete $attrs->{columns}
2789     } else {
2790       @cols = $source->columns
2791     }
2792
2793     for (@cols) {
2794       if ( ref $_ eq 'HASH' ) {
2795         push @colbits, $_
2796       } else {
2797         my $key = /^\Q${alias}.\E(.+)$/
2798           ? "$1"
2799           : "$_";
2800         my $value = /\./
2801           ? "$_"
2802           : "${alias}.$_";
2803         push @colbits, { $key => $value };
2804       }
2805     }
2806   }
2807
2808   # add the additional columns on
2809   foreach (qw{include_columns +columns}) {
2810     if ( $attrs->{$_} ) {
2811       my @list = ( ref($attrs->{$_}) eq 'ARRAY' )
2812         ? @{ delete $attrs->{$_} }
2813         : delete $attrs->{$_};
2814       for (@list) {
2815         if ( ref($_) eq 'HASH' ) {
2816           push @colbits, $_
2817         } else {
2818           my $key = ( split /\./, $_ )[-1];
2819           my $value = ( /\./ ? $_ : "$alias.$_" );
2820           push @colbits, { $key => $value };
2821         }
2822       }
2823     }
2824   }
2825
2826   # start with initial select items
2827   if ( $attrs->{select} ) {
2828     $attrs->{select} =
2829         ( ref $attrs->{select} eq 'ARRAY' )
2830       ? [ @{ $attrs->{select} } ]
2831       : [ $attrs->{select} ];
2832
2833     if ( $attrs->{as} ) {
2834       $attrs->{as} =
2835         (
2836           ref $attrs->{as} eq 'ARRAY'
2837             ? [ @{ $attrs->{as} } ]
2838             : [ $attrs->{as} ]
2839         )
2840     } else {
2841       $attrs->{as} = [ map {
2842          m/^\Q${alias}.\E(.+)$/
2843            ? $1
2844            : $_
2845          } @{ $attrs->{select} }
2846       ]
2847     }
2848   }
2849   else {
2850
2851     # otherwise we intialise select & as to empty
2852     $attrs->{select} = [];
2853     $attrs->{as}     = [];
2854   }
2855
2856   # now add colbits to select/as
2857   push @{ $attrs->{select} }, map values %{$_}, @colbits;
2858   push @{ $attrs->{as}     }, map keys   %{$_}, @colbits;
2859
2860   if ( my $adds = delete $attrs->{'+select'} ) {
2861     $adds = [$adds] unless ref $adds eq 'ARRAY';
2862     push @{ $attrs->{select} },
2863       map { /\./ || ref $_ ? $_ : "$alias.$_" } @$adds;
2864   }
2865   if ( my $adds = delete $attrs->{'+as'} ) {
2866     $adds = [$adds] unless ref $adds eq 'ARRAY';
2867     push @{ $attrs->{as} }, @$adds;
2868   }
2869
2870   $attrs->{from} ||= [{
2871     -source_handle => $source->handle,
2872     -alias => $self->{attrs}{alias},
2873     $self->{attrs}{alias} => $source->from,
2874   }];
2875
2876   if ( $attrs->{join} || $attrs->{prefetch} ) {
2877
2878     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2879       if ref $attrs->{from} ne 'ARRAY';
2880
2881     my $join = delete $attrs->{join} || {};
2882
2883     if ( defined $attrs->{prefetch} ) {
2884       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2885     }
2886
2887     $attrs->{from} =    # have to copy here to avoid corrupting the original
2888       [
2889         @{ $attrs->{from} },
2890         $source->_resolve_join(
2891           $join,
2892           $alias,
2893           { %{ $attrs->{seen_join} || {} } },
2894           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
2895             ? $attrs->{from}[-1][0]{-join_path}
2896             : []
2897           ,
2898         )
2899       ];
2900   }
2901
2902   if ( defined $attrs->{order_by} ) {
2903     $attrs->{order_by} = (
2904       ref( $attrs->{order_by} ) eq 'ARRAY'
2905       ? [ @{ $attrs->{order_by} } ]
2906       : [ $attrs->{order_by} || () ]
2907     );
2908   }
2909
2910   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2911     $attrs->{group_by} = [ $attrs->{group_by} ];
2912   }
2913
2914   # generate the distinct induced group_by early, as prefetch will be carried via a
2915   # subquery (since a group_by is present)
2916   if (delete $attrs->{distinct}) {
2917     if ($attrs->{group_by}) {
2918       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2919     }
2920     else {
2921       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2922
2923       # add any order_by parts that are not already present in the group_by
2924       # we need to be careful not to add any named functions/aggregates
2925       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
2926       my %already_grouped = map { $_ => 1 } (@{$attrs->{group_by}});
2927
2928       my $storage = $self->result_source->schema->storage;
2929
2930       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
2931
2932       for my $chunk ($storage->_parse_order_by($attrs->{order_by})) {
2933         if ($rs_column_list->{$chunk} && not $already_grouped{$chunk}++) {
2934           push @{$attrs->{group_by}}, $chunk;
2935         }
2936       }
2937     }
2938   }
2939
2940   $attrs->{collapse} ||= {};
2941   if ( my $prefetch = delete $attrs->{prefetch} ) {
2942     $prefetch = $self->_merge_attr( {}, $prefetch );
2943
2944     my $prefetch_ordering = [];
2945
2946     # this is a separate structure (we don't look in {from} directly)
2947     # as the resolver needs to shift things off the lists to work
2948     # properly (identical-prefetches on different branches)
2949     my $join_map = {};
2950     if (ref $attrs->{from} eq 'ARRAY') {
2951
2952       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
2953
2954       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
2955         next unless $j->[0]{-alias};
2956         next unless $j->[0]{-join_path};
2957         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
2958
2959         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
2960
2961         my $p = $join_map;
2962         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
2963         push @{$p->{-join_aliases} }, $j->[0]{-alias};
2964       }
2965     }
2966
2967     my @prefetch =
2968       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2969
2970     # we need to somehow mark which columns came from prefetch
2971     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2972
2973     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2974     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2975
2976     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2977     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2978   }
2979
2980   # if both page and offset are specified, produce a combined offset
2981   # even though it doesn't make much sense, this is what pre 081xx has
2982   # been doing
2983   if (my $page = delete $attrs->{page}) {
2984     $attrs->{offset} =
2985       ($attrs->{rows} * ($page - 1))
2986             +
2987       ($attrs->{offset} || 0)
2988     ;
2989   }
2990
2991   return $self->{_attrs} = $attrs;
2992 }
2993
2994 sub _rollout_attr {
2995   my ($self, $attr) = @_;
2996
2997   if (ref $attr eq 'HASH') {
2998     return $self->_rollout_hash($attr);
2999   } elsif (ref $attr eq 'ARRAY') {
3000     return $self->_rollout_array($attr);
3001   } else {
3002     return [$attr];
3003   }
3004 }
3005
3006 sub _rollout_array {
3007   my ($self, $attr) = @_;
3008
3009   my @rolled_array;
3010   foreach my $element (@{$attr}) {
3011     if (ref $element eq 'HASH') {
3012       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3013     } elsif (ref $element eq 'ARRAY') {
3014       #  XXX - should probably recurse here
3015       push( @rolled_array, @{$self->_rollout_array($element)} );
3016     } else {
3017       push( @rolled_array, $element );
3018     }
3019   }
3020   return \@rolled_array;
3021 }
3022
3023 sub _rollout_hash {
3024   my ($self, $attr) = @_;
3025
3026   my @rolled_array;
3027   foreach my $key (keys %{$attr}) {
3028     push( @rolled_array, { $key => $attr->{$key} } );
3029   }
3030   return \@rolled_array;
3031 }
3032
3033 sub _calculate_score {
3034   my ($self, $a, $b) = @_;
3035
3036   if (defined $a xor defined $b) {
3037     return 0;
3038   }
3039   elsif (not defined $a) {
3040     return 1;
3041   }
3042
3043   if (ref $b eq 'HASH') {
3044     my ($b_key) = keys %{$b};
3045     if (ref $a eq 'HASH') {
3046       my ($a_key) = keys %{$a};
3047       if ($a_key eq $b_key) {
3048         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3049       } else {
3050         return 0;
3051       }
3052     } else {
3053       return ($a eq $b_key) ? 1 : 0;
3054     }
3055   } else {
3056     if (ref $a eq 'HASH') {
3057       my ($a_key) = keys %{$a};
3058       return ($b eq $a_key) ? 1 : 0;
3059     } else {
3060       return ($b eq $a) ? 1 : 0;
3061     }
3062   }
3063 }
3064
3065 sub _merge_attr {
3066   my ($self, $orig, $import) = @_;
3067
3068   return $import unless defined($orig);
3069   return $orig unless defined($import);
3070
3071   $orig = $self->_rollout_attr($orig);
3072   $import = $self->_rollout_attr($import);
3073
3074   my $seen_keys;
3075   foreach my $import_element ( @{$import} ) {
3076     # find best candidate from $orig to merge $b_element into
3077     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3078     foreach my $orig_element ( @{$orig} ) {
3079       my $score = $self->_calculate_score( $orig_element, $import_element );
3080       if ($score > $best_candidate->{score}) {
3081         $best_candidate->{position} = $position;
3082         $best_candidate->{score} = $score;
3083       }
3084       $position++;
3085     }
3086     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3087
3088     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3089       push( @{$orig}, $import_element );
3090     } else {
3091       my $orig_best = $orig->[$best_candidate->{position}];
3092       # merge orig_best and b_element together and replace original with merged
3093       if (ref $orig_best ne 'HASH') {
3094         $orig->[$best_candidate->{position}] = $import_element;
3095       } elsif (ref $import_element eq 'HASH') {
3096         my ($key) = keys %{$orig_best};
3097         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3098       }
3099     }
3100     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3101   }
3102
3103   return $orig;
3104 }
3105
3106 sub result_source {
3107     my $self = shift;
3108
3109     if (@_) {
3110         $self->_source_handle($_[0]->handle);
3111     } else {
3112         $self->_source_handle->resolve;
3113     }
3114 }
3115
3116 =head2 throw_exception
3117
3118 See L<DBIx::Class::Schema/throw_exception> for details.
3119
3120 =cut
3121
3122 sub throw_exception {
3123   my $self=shift;
3124
3125   if (ref $self && $self->_source_handle->schema) {
3126     $self->_source_handle->schema->throw_exception(@_)
3127   }
3128   else {
3129     DBIx::Class::Exception->throw(@_);
3130   }
3131 }
3132
3133 # XXX: FIXME: Attributes docs need clearing up
3134
3135 =head1 ATTRIBUTES
3136
3137 Attributes are used to refine a ResultSet in various ways when
3138 searching for data. They can be passed to any method which takes an
3139 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3140 L</count>.
3141
3142 These are in no particular order:
3143
3144 =head2 order_by
3145
3146 =over 4
3147
3148 =item Value: ( $order_by | \@order_by | \%order_by )
3149
3150 =back
3151
3152 Which column(s) to order the results by.
3153
3154 [The full list of suitable values is documented in
3155 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3156 common options.]
3157
3158 If a single column name, or an arrayref of names is supplied, the
3159 argument is passed through directly to SQL. The hashref syntax allows
3160 for connection-agnostic specification of ordering direction:
3161
3162  For descending order:
3163
3164   order_by => { -desc => [qw/col1 col2 col3/] }
3165
3166  For explicit ascending order:
3167
3168   order_by => { -asc => 'col' }
3169
3170 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3171 supported, although you are strongly encouraged to use the hashref
3172 syntax as outlined above.
3173
3174 =head2 columns
3175
3176 =over 4
3177
3178 =item Value: \@columns
3179
3180 =back
3181
3182 Shortcut to request a particular set of columns to be retrieved. Each
3183 column spec may be a string (a table column name), or a hash (in which
3184 case the key is the C<as> value, and the value is used as the C<select>
3185 expression). Adds C<me.> onto the start of any column without a C<.> in
3186 it and sets C<select> from that, then auto-populates C<as> from
3187 C<select> as normal. (You may also use the C<cols> attribute, as in
3188 earlier versions of DBIC.)
3189
3190 =head2 +columns
3191
3192 =over 4
3193
3194 =item Value: \@columns
3195
3196 =back
3197
3198 Indicates additional columns to be selected from storage. Works the same
3199 as L</columns> but adds columns to the selection. (You may also use the
3200 C<include_columns> attribute, as in earlier versions of DBIC). For
3201 example:-
3202
3203   $schema->resultset('CD')->search(undef, {
3204     '+columns' => ['artist.name'],
3205     join => ['artist']
3206   });
3207
3208 would return all CDs and include a 'name' column to the information
3209 passed to object inflation. Note that the 'artist' is the name of the
3210 column (or relationship) accessor, and 'name' is the name of the column
3211 accessor in the related table.
3212
3213 =head2 include_columns
3214
3215 =over 4
3216
3217 =item Value: \@columns
3218
3219 =back
3220
3221 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3222
3223 =head2 select
3224
3225 =over 4
3226
3227 =item Value: \@select_columns
3228
3229 =back
3230
3231 Indicates which columns should be selected from the storage. You can use
3232 column names, or in the case of RDBMS back ends, function or stored procedure
3233 names:
3234
3235   $rs = $schema->resultset('Employee')->search(undef, {
3236     select => [
3237       'name',
3238       { count => 'employeeid' },
3239       { sum => 'salary' }
3240     ]
3241   });
3242
3243 When you use function/stored procedure names and do not supply an C<as>
3244 attribute, the column names returned are storage-dependent. E.g. MySQL would
3245 return a column named C<count(employeeid)> in the above example.
3246
3247 B<NOTE:> You will almost always need a corresponding 'as' entry when you use
3248 'select'.
3249
3250 =head2 +select
3251
3252 =over 4
3253
3254 Indicates additional columns to be selected from storage.  Works the same as
3255 L</select> but adds columns to the selection.
3256
3257 =back
3258
3259 =head2 +as
3260
3261 =over 4
3262
3263 Indicates additional column names for those added via L</+select>. See L</as>.
3264
3265 =back
3266
3267 =head2 as
3268
3269 =over 4
3270
3271 =item Value: \@inflation_names
3272
3273 =back
3274
3275 Indicates column names for object inflation. That is, C<as>
3276 indicates the name that the column can be accessed as via the
3277 C<get_column> method (or via the object accessor, B<if one already
3278 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3279
3280 The C<as> attribute is used in conjunction with C<select>,
3281 usually when C<select> contains one or more function or stored
3282 procedure names:
3283
3284   $rs = $schema->resultset('Employee')->search(undef, {
3285     select => [
3286       'name',
3287       { count => 'employeeid' }
3288     ],
3289     as => ['name', 'employee_count'],
3290   });
3291
3292   my $employee = $rs->first(); # get the first Employee
3293
3294 If the object against which the search is performed already has an accessor
3295 matching a column name specified in C<as>, the value can be retrieved using
3296 the accessor as normal:
3297
3298   my $name = $employee->name();
3299
3300 If on the other hand an accessor does not exist in the object, you need to
3301 use C<get_column> instead:
3302
3303   my $employee_count = $employee->get_column('employee_count');
3304
3305 You can create your own accessors if required - see
3306 L<DBIx::Class::Manual::Cookbook> for details.
3307
3308 Please note: This will NOT insert an C<AS employee_count> into the SQL
3309 statement produced, it is used for internal access only. Thus
3310 attempting to use the accessor in an C<order_by> clause or similar
3311 will fail miserably.
3312
3313 To get around this limitation, you can supply literal SQL to your
3314 C<select> attibute that contains the C<AS alias> text, eg:
3315
3316   select => [\'myfield AS alias']
3317
3318 =head2 join
3319
3320 =over 4
3321
3322 =item Value: ($rel_name | \@rel_names | \%rel_names)
3323
3324 =back
3325
3326 Contains a list of relationships that should be joined for this query.  For
3327 example:
3328
3329   # Get CDs by Nine Inch Nails
3330   my $rs = $schema->resultset('CD')->search(
3331     { 'artist.name' => 'Nine Inch Nails' },
3332     { join => 'artist' }
3333   );
3334
3335 Can also contain a hash reference to refer to the other relation's relations.
3336 For example:
3337
3338   package MyApp::Schema::Track;
3339   use base qw/DBIx::Class/;
3340   __PACKAGE__->table('track');
3341   __PACKAGE__->add_columns(qw/trackid cd position title/);
3342   __PACKAGE__->set_primary_key('trackid');
3343   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3344   1;
3345
3346   # In your application
3347   my $rs = $schema->resultset('Artist')->search(
3348     { 'track.title' => 'Teardrop' },
3349     {
3350       join     => { cd => 'track' },
3351       order_by => 'artist.name',
3352     }
3353   );
3354
3355 You need to use the relationship (not the table) name in  conditions,
3356 because they are aliased as such. The current table is aliased as "me", so
3357 you need to use me.column_name in order to avoid ambiguity. For example:
3358
3359   # Get CDs from 1984 with a 'Foo' track
3360   my $rs = $schema->resultset('CD')->search(
3361     {
3362       'me.year' => 1984,
3363       'tracks.name' => 'Foo'
3364     },
3365     { join => 'tracks' }
3366   );
3367
3368 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3369 similarly for a third time). For e.g.
3370
3371   my $rs = $schema->resultset('Artist')->search({
3372     'cds.title'   => 'Down to Earth',
3373     'cds_2.title' => 'Popular',
3374   }, {
3375     join => [ qw/cds cds/ ],
3376   });
3377
3378 will return a set of all artists that have both a cd with title 'Down
3379 to Earth' and a cd with title 'Popular'.
3380
3381 If you want to fetch related objects from other tables as well, see C<prefetch>
3382 below.
3383
3384 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3385
3386 =head2 prefetch
3387
3388 =over 4
3389
3390 =item Value: ($rel_name | \@rel_names | \%rel_names)
3391
3392 =back
3393
3394 Contains one or more relationships that should be fetched along with
3395 the main query (when they are accessed afterwards the data will
3396 already be available, without extra queries to the database).  This is
3397 useful for when you know you will need the related objects, because it
3398 saves at least one query:
3399
3400   my $rs = $schema->resultset('Tag')->search(
3401     undef,
3402     {
3403       prefetch => {
3404         cd => 'artist'
3405       }
3406     }
3407   );
3408
3409 The initial search results in SQL like the following:
3410
3411   SELECT tag.*, cd.*, artist.* FROM tag
3412   JOIN cd ON tag.cd = cd.cdid
3413   JOIN artist ON cd.artist = artist.artistid
3414
3415 L<DBIx::Class> has no need to go back to the database when we access the
3416 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3417 case.
3418
3419 Simple prefetches will be joined automatically, so there is no need
3420 for a C<join> attribute in the above search.
3421
3422 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3423 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3424 with an accessor type of 'single' or 'filter'). A more complex example that
3425 prefetches an artists cds, the tracks on those cds, and the tags associted
3426 with that artist is given below (assuming many-to-many from artists to tags):
3427
3428  my $rs = $schema->resultset('Artist')->search(
3429    undef,
3430    {
3431      prefetch => [
3432        { cds => 'tracks' },
3433        { artist_tags => 'tags' }
3434      ]
3435    }
3436  );
3437
3438
3439 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3440 attributes will be ignored.
3441
3442 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3443 exactly as you might expect.
3444
3445 =over 4
3446
3447 =item *
3448
3449 Prefetch uses the L</cache> to populate the prefetched relationships. This
3450 may or may not be what you want.
3451
3452 =item *
3453
3454 If you specify a condition on a prefetched relationship, ONLY those
3455 rows that match the prefetched condition will be fetched into that relationship.
3456 This means that adding prefetch to a search() B<may alter> what is returned by
3457 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3458
3459   my $artist_rs = $schema->resultset('Artist')->search({
3460       'cds.year' => 2008,
3461   }, {
3462       join => 'cds',
3463   });
3464
3465   my $count = $artist_rs->first->cds->count;
3466
3467   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3468
3469   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3470
3471   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3472
3473 that cmp_ok() may or may not pass depending on the datasets involved. This
3474 behavior may or may not survive the 0.09 transition.
3475
3476 =back
3477
3478 =head2 page
3479
3480 =over 4
3481
3482 =item Value: $page
3483
3484 =back
3485
3486 Makes the resultset paged and specifies the page to retrieve. Effectively
3487 identical to creating a non-pages resultset and then calling ->page($page)
3488 on it.
3489
3490 If L<rows> attribute is not specified it defaults to 10 rows per page.
3491
3492 When you have a paged resultset, L</count> will only return the number
3493 of rows in the page. To get the total, use the L</pager> and call
3494 C<total_entries> on it.
3495
3496 =head2 rows
3497
3498 =over 4
3499
3500 =item Value: $rows
3501
3502 =back
3503
3504 Specifes the maximum number of rows for direct retrieval or the number of
3505 rows per page if the page attribute or method is used.
3506
3507 =head2 offset
3508
3509 =over 4
3510
3511 =item Value: $offset
3512
3513 =back
3514
3515 Specifies the (zero-based) row number for the  first row to be returned, or the
3516 of the first row of the first page if paging is used.
3517
3518 =head2 group_by
3519
3520 =over 4
3521
3522 =item Value: \@columns
3523
3524 =back
3525
3526 A arrayref of columns to group by. Can include columns of joined tables.
3527
3528   group_by => [qw/ column1 column2 ... /]
3529
3530 =head2 having
3531
3532 =over 4
3533
3534 =item Value: $condition
3535
3536 =back
3537
3538 HAVING is a select statement attribute that is applied between GROUP BY and
3539 ORDER BY. It is applied to the after the grouping calculations have been
3540 done.
3541
3542   having => { 'count(employee)' => { '>=', 100 } }
3543
3544 =head2 distinct
3545
3546 =over 4
3547
3548 =item Value: (0 | 1)
3549
3550 =back
3551
3552 Set to 1 to group by all columns. If the resultset already has a group_by
3553 attribute, this setting is ignored and an appropriate warning is issued.
3554
3555 =head2 where
3556
3557 =over 4
3558
3559 Adds to the WHERE clause.
3560
3561   # only return rows WHERE deleted IS NULL for all searches
3562   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3563
3564 Can be overridden by passing C<< { where => undef } >> as an attribute
3565 to a resultset.
3566
3567 =back
3568
3569 =head2 cache
3570
3571 Set to 1 to cache search results. This prevents extra SQL queries if you
3572 revisit rows in your ResultSet:
3573
3574   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3575
3576   while( my $artist = $resultset->next ) {
3577     ... do stuff ...
3578   }
3579
3580   $rs->first; # without cache, this would issue a query
3581
3582 By default, searches are not cached.
3583
3584 For more examples of using these attributes, see
3585 L<DBIx::Class::Manual::Cookbook>.
3586
3587 =head2 for
3588
3589 =over 4
3590
3591 =item Value: ( 'update' | 'shared' )
3592
3593 =back
3594
3595 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3596 ... FOR SHARED.
3597
3598 =cut
3599
3600 1;