lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 195
 196 =item Return Value: L<$resultset|/search>
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you never construct a resultset manually. Instead you get one
 206 from e.g. a
 207 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 208 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 209 scalar context):
 210
 211   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 212
 213 =over
 214
 215 =item WARNING
 216
 217 If called on an object, proxies to L</new_result> instead, so
 218
 219   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 220
 221 will return a CD object, not a ResultSet, and is equivalent to:
 222
 223   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 224
 225 Please also keep in mind that many internals call L</new_result> directly,
 226 so overloading this method with the idea of intercepting new result object
 227 creation B<will not work>. See also warning pertaining to L</create>.
 228
 229 =back
 230
 231 =cut
 232
 233 sub new {
 234   my $class = shift;
 235   return $class->new_result(@_) if ref $class;
 236
 237   my ($source, $attrs) = @_;
 238   $source = $source->resolve
 239     if $source->isa('DBIx::Class::ResultSourceHandle');
 240   $attrs = { %{$attrs||{}} };
 241
 242   if ($attrs->{page}) {
 243     $attrs->{rows} ||= 10;
 244   }
 245
 246   $attrs->{alias} ||= 'me';
 247
 248   my $self = bless {
 249     result_source => $source,
 250     cond => $attrs->{where},
 251     pager => undef,
 252     attrs => $attrs,
 253   }, $class;
 254
 255   # if there is a dark selector, this means we are already in a
 256   # chain and the cleanup/sanification was taken care of by
 257   # _search_rs already
 258   $self->_normalize_selection($attrs)
 259     unless $attrs->{_dark_selector};
 260
 261   $self->result_class(
 262     $attrs->{result_class} || $source->result_class
 263   );
 264
 265   $self;
 266 }
 267
 268 =head2 search
 269
 270 =over 4
 271
 272 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 273
 274 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 275
 276 =back
 277
 278   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 279   my $new_rs = $cd_rs->search({ year => 2005 });
 280
 281   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 282                  # year = 2005 OR year = 2004
 283
 284 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 285 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 286 To avoid that, use L</search_rs>.
 287
 288 If you need to pass in additional attributes but no additional condition,
 289 call it as C<search(undef, \%attrs)>.
 290
 291   # "SELECT name, artistid FROM $artist_table"
 292   my @all_artists = $schema->resultset('Artist')->search(undef, {
 293     columns => [qw/name artistid/],
 294   });
 295
 296 For a list of attributes that can be passed to C<search>, see
 297 L</ATTRIBUTES>. For more examples of using this function, see
 298 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 299 documentation for the first argument, see L<SQL::Abstract>
 300 and its extension L<DBIx::Class::SQLMaker>.
 301
 302 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 303
 304 =head3 CAVEAT
 305
 306 Note that L</search> does not process/deflate any of the values passed in the
 307 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 308 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 309 manually that any value passed to this method will stringify to something the
 310 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 311 objects, for more info see:
 312 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 313
 314 =cut
 315
 316 sub search {
 317   my $self = shift;
 318   my $rs = $self->search_rs( @_ );
 319
 320   if (wantarray) {
 321     return $rs->all;
 322   }
 323   elsif (defined wantarray) {
 324     return $rs;
 325   }
 326   else {
 327     # we can be called by a relationship helper, which in
 328     # turn may be called in void context due to some braindead
 329     # overload or whatever else the user decided to be clever
 330     # at this particular day. Thus limit the exception to
 331     # external code calls only
 332     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 333       if (caller)[0] !~ /^\QDBIx::Class::/;
 334
 335     return ();
 336   }
 337 }
 338
 339 =head2 search_rs
 340
 341 =over 4
 342
 343 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 344
 345 =item Return Value: L<$resultset|/search>
 346
 347 =back
 348
 349 This method does the same exact thing as search() except it will
 350 always return a resultset, even in list context.
 351
 352 =cut
 353
 354 sub search_rs {
 355   my $self = shift;
 356
 357   my $rsrc = $self->result_source;
 358   my ($call_cond, $call_attrs);
 359
 360   # Special-case handling for (undef, undef) or (undef)
 361   # Note that (foo => undef) is valid deprecated syntax
 362   @_ = () if not scalar grep { defined $_ } @_;
 363
 364   # just a cond
 365   if (@_ == 1) {
 366     $call_cond = shift;
 367   }
 368   # fish out attrs in the ($condref, $attr) case
 369   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 370     ($call_cond, $call_attrs) = @_;
 371   }
 372   elsif (@_ % 2) {
 373     $self->throw_exception('Odd number of arguments to search')
 374   }
 375   # legacy search
 376   elsif (@_) {
 377     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 378       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 379
 380     for my $i (0 .. $#_) {
 381       next if $i % 2;
 382       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 383         if (! defined $_[$i] or ref $_[$i] ne '');
 384     }
 385
 386     $call_cond = { @_ };
 387   }
 388
 389   # see if we can keep the cache (no $rs changes)
 390   my $cache;
 391   my %safe = (alias => 1, cache => 1);
 392   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 393     ! defined $_[0]
 394       or
 395     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 396       or
 397     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 398   )) {
 399     $cache = $self->get_cache;
 400   }
 401
 402   my $old_attrs = { %{$self->{attrs}} };
 403   my $old_having = delete $old_attrs->{having};
 404   my $old_where = delete $old_attrs->{where};
 405
 406   my $new_attrs = { %$old_attrs };
 407
 408   # take care of call attrs (only if anything is changing)
 409   if ($call_attrs and keys %$call_attrs) {
 410
 411     # copy for _normalize_selection
 412     $call_attrs = { %$call_attrs };
 413
 414     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 415
 416     # reset the current selector list if new selectors are supplied
 417     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 418       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 419     }
 420
 421     # Normalize the new selector list (operates on the passed-in attr structure)
 422     # Need to do it on every chain instead of only once on _resolved_attrs, in
 423     # order to allow detection of empty vs partial 'as'
 424     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 425       if $old_attrs->{_dark_selector};
 426     $self->_normalize_selection ($call_attrs);
 427
 428     # start with blind overwriting merge, exclude selector attrs
 429     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 430     delete @{$new_attrs}{@selector_attrs};
 431
 432     for (@selector_attrs) {
 433       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 434         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 435     }
 436
 437     # older deprecated name, use only if {columns} is not there
 438     if (my $c = delete $new_attrs->{cols}) {
 439       if ($new_attrs->{columns}) {
 440         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 441       }
 442       else {
 443         $new_attrs->{columns} = $c;
 444       }
 445     }
 446
 447
 448     # join/prefetch use their own crazy merging heuristics
 449     foreach my $key (qw/join prefetch/) {
 450       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 451         if exists $call_attrs->{$key};
 452     }
 453
 454     # stack binds together
 455     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 456   }
 457
 458
 459   for ($old_where, $call_cond) {
 460     if (defined $_) {
 461       $new_attrs->{where} = $self->_stack_cond (
 462         $_, $new_attrs->{where}
 463       );
 464     }
 465   }
 466
 467   if (defined $old_having) {
 468     $new_attrs->{having} = $self->_stack_cond (
 469       $old_having, $new_attrs->{having}
 470     )
 471   }
 472
 473   my $rs = (ref $self)->new($rsrc, $new_attrs);
 474
 475   $rs->set_cache($cache) if ($cache);
 476
 477   return $rs;
 478 }
 479
 480 my $dark_sel_dumper;
 481 sub _normalize_selection {
 482   my ($self, $attrs) = @_;
 483
 484   # legacy syntax
 485   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 486     if exists $attrs->{include_columns};
 487
 488   # columns are always placed first, however
 489
 490   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 491   # delay the decision on whether to use a default select list ($rsrc->columns)
 492   # allowing stuff like the remove_columns helper to work
 493   #
 494   # select/as +select/+as pairs need special handling - the amount of select/as
 495   # elements in each pair does *not* have to be equal (think multicolumn
 496   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 497   # supplied at all) - try to infer the alias, either from the -as parameter
 498   # of the selector spec, or use the parameter whole if it looks like a column
 499   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 500   # is ok as well), but make sure no more additions to the 'as' chain take place
 501   for my $pref ('', '+') {
 502
 503     my ($sel, $as) = map {
 504       my $key = "${pref}${_}";
 505
 506       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 507         ? @{$attrs->{$key}}
 508         : $attrs->{$key} || ()
 509       ];
 510       delete $attrs->{$key};
 511       $val;
 512     } qw/select as/;
 513
 514     if (! @$as and ! @$sel ) {
 515       next;
 516     }
 517     elsif (@$as and ! @$sel) {
 518       $self->throw_exception(
 519         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 520       );
 521     }
 522     elsif( ! @$as ) {
 523       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 524       # if any @$as has been supplied we assume the user knows what (s)he is doing
 525       # and blindly keep stacking up pieces
 526       unless ($attrs->{_dark_selector}) {
 527         SELECTOR:
 528         for (@$sel) {
 529           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 530             push @$as, $_->{-as};
 531           }
 532           # assume any plain no-space, no-parenthesis string to be a column spec
 533           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 534           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 535             push @$as, $_;
 536           }
 537           # if all else fails - raise a flag that no more aliasing will be allowed
 538           else {
 539             $attrs->{_dark_selector} = {
 540               plus_stage => $pref,
 541               string => ($dark_sel_dumper ||= do {
 542                   require Data::Dumper::Concise;
 543                   Data::Dumper::Concise::DumperObject()->Indent(0);
 544                 })->Values([$_])->Dump
 545               ,
 546             };
 547             last SELECTOR;
 548           }
 549         }
 550       }
 551     }
 552     elsif (@$as < @$sel) {
 553       $self->throw_exception(
 554         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 555       );
 556     }
 557     elsif ($pref and $attrs->{_dark_selector}) {
 558       $self->throw_exception(
 559         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 560       );
 561     }
 562
 563
 564     # merge result
 565     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 566     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 567   }
 568 }
 569
 570 sub _stack_cond {
 571   my ($self, $left, $right) = @_;
 572
 573   # collapse single element top-level conditions
 574   # (single pass only, unlikely to need recursion)
 575   for ($left, $right) {
 576     if (ref $_ eq 'ARRAY') {
 577       if (@$_ == 0) {
 578         $_ = undef;
 579       }
 580       elsif (@$_ == 1) {
 581         $_ = $_->[0];
 582       }
 583     }
 584     elsif (ref $_ eq 'HASH') {
 585       my ($first, $more) = keys %$_;
 586
 587       # empty hash
 588       if (! defined $first) {
 589         $_ = undef;
 590       }
 591       # one element hash
 592       elsif (! defined $more) {
 593         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 594           $_ = $_->{'-and'};
 595         }
 596         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 597           $_ = $_->{'-or'};
 598         }
 599       }
 600     }
 601   }
 602
 603   # merge hashes with weeding out of duplicates (simple cases only)
 604   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 605
 606     # shallow copy to destroy
 607     $right = { %$right };
 608     for (grep { exists $right->{$_} } keys %$left) {
 609       # the use of eq_deeply here is justified - the rhs of an
 610       # expression can contain a lot of twisted weird stuff
 611       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 612     }
 613
 614     $right = undef unless keys %$right;
 615   }
 616
 617
 618   if (defined $left xor defined $right) {
 619     return defined $left ? $left : $right;
 620   }
 621   elsif (! defined $left) {
 622     return undef;
 623   }
 624   else {
 625     return { -and => [ $left, $right ] };
 626   }
 627 }
 628
 629 =head2 search_literal
 630
 631 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 632 should only be used in that context. C<search_literal> is a convenience
 633 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 634 want to ensure columns are bound correctly, use L</search>.
 635
 636 See L<DBIx::Class::Manual::Cookbook/Searching> and
 637 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 638 require C<search_literal>.
 639
 640 =over 4
 641
 642 =item Arguments: $sql_fragment, @standalone_bind_values
 643
 644 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 645
 646 =back
 647
 648   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 649   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 650
 651 Pass a literal chunk of SQL to be added to the conditional part of the
 652 resultset query.
 653
 654 Example of how to use C<search> instead of C<search_literal>
 655
 656   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 657   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 658
 659 =cut
 660
 661 sub search_literal {
 662   my ($self, $sql, @bind) = @_;
 663   my $attr;
 664   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 665     $attr = pop @bind;
 666   }
 667   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 668 }
 669
 670 =head2 find
 671
 672 =over 4
 673
 674 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 675
 676 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 677
 678 =back
 679
 680 Finds and returns a single row based on supplied criteria. Takes either a
 681 hashref with the same format as L</create> (including inference of foreign
 682 keys from related objects), or a list of primary key values in the same
 683 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 684 declaration on the L</result_source>.
 685
 686 In either case an attempt is made to combine conditions already existing on
 687 the resultset with the condition passed to this method.
 688
 689 To aid with preparing the correct query for the storage you may supply the
 690 C<key> attribute, which is the name of a
 691 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 692 unique constraint corresponding to the
 693 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 694 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 695 to construct a query that satisfies the named unique constraint fully (
 696 non-NULL values for each column member of the constraint) an exception is
 697 thrown.
 698
 699 If no C<key> is specified, the search is carried over all unique constraints
 700 which are fully defined by the available condition.
 701
 702 If no such constraint is found, C<find> currently defaults to a simple
 703 C<< search->(\%column_values) >> which may or may not do what you expect.
 704 Note that this fallback behavior may be deprecated in further versions. If
 705 you need to search with arbitrary conditions - use L</search>. If the query
 706 resulting from this fallback produces more than one row, a warning to the
 707 effect is issued, though only the first row is constructed and returned as
 708 C<$result_object>.
 709
 710 In addition to C<key>, L</find> recognizes and applies standard
 711 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 712
 713 Note that if you have extra concerns about the correctness of the resulting
 714 query you need to specify the C<key> attribute and supply the entire condition
 715 as an argument to find (since it is not always possible to perform the
 716 combination of the resultset condition with the supplied one, especially if
 717 the resultset condition contains literal sql).
 718
 719 For example, to find a row by its primary key:
 720
 721   my $cd = $schema->resultset('CD')->find(5);
 722
 723 You can also find a row by a specific unique constraint:
 724
 725   my $cd = $schema->resultset('CD')->find(
 726     {
 727       artist => 'Massive Attack',
 728       title  => 'Mezzanine',
 729     },
 730     { key => 'cd_artist_title' }
 731   );
 732
 733 See also L</find_or_create> and L</update_or_create>.
 734
 735 =cut
 736
 737 sub find {
 738   my $self = shift;
 739   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 740
 741   my $rsrc = $self->result_source;
 742
 743   my $constraint_name;
 744   if (exists $attrs->{key}) {
 745     $constraint_name = defined $attrs->{key}
 746       ? $attrs->{key}
 747       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 748     ;
 749   }
 750
 751   # Parse out the condition from input
 752   my $call_cond;
 753
 754   if (ref $_[0] eq 'HASH') {
 755     $call_cond = { %{$_[0]} };
 756   }
 757   else {
 758     # if only values are supplied we need to default to 'primary'
 759     $constraint_name = 'primary' unless defined $constraint_name;
 760
 761     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 762
 763     $self->throw_exception(
 764       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 765     ) unless @c_cols;
 766
 767     $self->throw_exception (
 768       'find() expects either a column/value hashref, or a list of values '
 769     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 770     ) unless @c_cols == @_;
 771
 772     $call_cond = {};
 773     @{$call_cond}{@c_cols} = @_;
 774   }
 775
 776   my %related;
 777   for my $key (keys %$call_cond) {
 778     if (
 779       my $keyref = ref($call_cond->{$key})
 780         and
 781       my $relinfo = $rsrc->relationship_info($key)
 782     ) {
 783       my $val = delete $call_cond->{$key};
 784
 785       next if $keyref eq 'ARRAY'; # has_many for multi_create
 786
 787       my $rel_q = $rsrc->_resolve_condition(
 788         $relinfo->{cond}, $val, $key, $key
 789       );
 790       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 791       @related{keys %$rel_q} = values %$rel_q;
 792     }
 793   }
 794
 795   # relationship conditions take precedence (?)
 796   @{$call_cond}{keys %related} = values %related;
 797
 798   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 799   my $final_cond;
 800   if (defined $constraint_name) {
 801     $final_cond = $self->_qualify_cond_columns (
 802
 803       $self->_build_unique_cond (
 804         $constraint_name,
 805         $call_cond,
 806       ),
 807
 808       $alias,
 809     );
 810   }
 811   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 812     # This means that we got here after a merger of relationship conditions
 813     # in ::Relationship::Base::search_related (the row method), and furthermore
 814     # the relationship is of the 'single' type. This means that the condition
 815     # provided by the relationship (already attached to $self) is sufficient,
 816     # as there can be only one row in the database that would satisfy the
 817     # relationship
 818   }
 819   else {
 820     # no key was specified - fall down to heuristics mode:
 821     # run through all unique queries registered on the resultset, and
 822     # 'OR' all qualifying queries together
 823     my (@unique_queries, %seen_column_combinations);
 824     for my $c_name ($rsrc->unique_constraint_names) {
 825       next if $seen_column_combinations{
 826         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 827       }++;
 828
 829       push @unique_queries, try {
 830         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 831       } || ();
 832     }
 833
 834     $final_cond = @unique_queries
 835       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 836       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 837     ;
 838   }
 839
 840   # Run the query, passing the result_class since it should propagate for find
 841   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 842   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 843     my $row = $rs->next;
 844     carp "Query returned more than one row" if $rs->next;
 845     return $row;
 846   }
 847   else {
 848     return $rs->single;
 849   }
 850 }
 851
 852 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 853 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 854 #
 855 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 856 # condition. It is provided for overrides until a saner way forward is devised
 857 #
 858 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 859 # the road. Please adjust your tests accordingly to catch this situation early
 860 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 861 #
 862 # The method will not be removed without an adequately complete replacement
 863 # for strict-mode enforcement
 864 sub _non_unique_find_fallback {
 865   my ($self, $cond, $attrs) = @_;
 866
 867   return $self->_qualify_cond_columns(
 868     $cond,
 869     exists $attrs->{alias}
 870       ? $attrs->{alias}
 871       : $self->{attrs}{alias}
 872   );
 873 }
 874
 875
 876 sub _qualify_cond_columns {
 877   my ($self, $cond, $alias) = @_;
 878
 879   my %aliased = %$cond;
 880   for (keys %aliased) {
 881     $aliased{"$alias.$_"} = delete $aliased{$_}
 882       if $_ !~ /\./;
 883   }
 884
 885   return \%aliased;
 886 }
 887
 888 sub _build_unique_cond {
 889   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 890
 891   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 892
 893   # combination may fail if $self->{cond} is non-trivial
 894   my ($final_cond) = try {
 895     $self->_merge_with_rscond ($extra_cond)
 896   } catch {
 897     +{ %$extra_cond }
 898   };
 899
 900   # trim out everything not in $columns
 901   $final_cond = { map {
 902     exists $final_cond->{$_}
 903       ? ( $_ => $final_cond->{$_} )
 904       : ()
 905   } @c_cols };
 906
 907   if (my @missing = grep
 908     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 909     (@c_cols)
 910   ) {
 911     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 912       $constraint_name,
 913       join (', ', map { "'$_'" } @missing),
 914     ) );
 915   }
 916
 917   if (
 918     !$croak_on_null
 919       and
 920     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 921       and
 922     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 923   ) {
 924     carp_unique ( sprintf (
 925       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 926     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 927     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 928       $constraint_name,
 929       join (', ', map { "'$_'" } @undefs),
 930     ));
 931   }
 932
 933   return $final_cond;
 934 }
 935
 936 =head2 search_related
 937
 938 =over 4
 939
 940 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 941
 942 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 943
 944 =back
 945
 946   $new_rs = $cd_rs->search_related('artist', {
 947     name => 'Emo-R-Us',
 948   });
 949
 950 Searches the specified relationship, optionally specifying a condition and
 951 attributes for matching records. See L</ATTRIBUTES> for more information.
 952
 953 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 954 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 955
 956 See also L</search_related_rs>.
 957
 958 =cut
 959
 960 sub search_related {
 961   return shift->related_resultset(shift)->search(@_);
 962 }
 963
 964 =head2 search_related_rs
 965
 966 This method works exactly the same as search_related, except that
 967 it guarantees a resultset, even in list context.
 968
 969 =cut
 970
 971 sub search_related_rs {
 972   return shift->related_resultset(shift)->search_rs(@_);
 973 }
 974
 975 =head2 cursor
 976
 977 =over 4
 978
 979 =item Arguments: none
 980
 981 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 982
 983 =back
 984
 985 Returns a storage-driven cursor to the given resultset. See
 986 L<DBIx::Class::Cursor> for more information.
 987
 988 =cut
 989
 990 sub cursor {
 991   my $self = shift;
 992
 993   return $self->{cursor} ||= do {
 994     my $attrs = { %{$self->_resolved_attrs } };
 995     $self->result_source->storage->select(
 996       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
 997     );
 998   };
 999 }
1000
1001 =head2 single
1002
1003 =over 4
1004
1005 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1006
1007 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1008
1009 =back
1010
1011   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1012
1013 Inflates the first result without creating a cursor if the resultset has
1014 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1015 of L</search>.
1016
1017 While this method can take an optional search condition (just like L</search>)
1018 being a fast-code-path it does not recognize search attributes. If you need to
1019 add extra joins or similar, call L</search> and then chain-call L</single> on the
1020 L<DBIx::Class::ResultSet> returned.
1021
1022 =over
1023
1024 =item B<Note>
1025
1026 As of 0.08100, this method enforces the assumption that the preceding
1027 query returns only one row. If more than one row is returned, you will receive
1028 a warning:
1029
1030   Query returned more than one row
1031
1032 In this case, you should be using L</next> or L</find> instead, or if you really
1033 know what you are doing, use the L</rows> attribute to explicitly limit the size
1034 of the resultset.
1035
1036 This method will also throw an exception if it is called on a resultset prefetching
1037 has_many, as such a prefetch implies fetching multiple rows from the database in
1038 order to assemble the resulting object.
1039
1040 =back
1041
1042 =cut
1043
1044 sub single {
1045   my ($self, $where) = @_;
1046   if(@_ > 2) {
1047       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1048   }
1049
1050   my $attrs = { %{$self->_resolved_attrs} };
1051
1052   if (keys %{$attrs->{collapse}}) {
1053     $self->throw_exception(
1054       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1055     );
1056   }
1057
1058   if ($where) {
1059     if (defined $attrs->{where}) {
1060       $attrs->{where} = {
1061         '-and' =>
1062             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1063                $where, delete $attrs->{where} ]
1064       };
1065     } else {
1066       $attrs->{where} = $where;
1067     }
1068   }
1069
1070   my @data = $self->result_source->storage->select_single(
1071     $attrs->{from}, $attrs->{select},
1072     $attrs->{where}, $attrs
1073   );
1074
1075   return (@data ? ($self->_construct_object(@data))[0] : undef);
1076 }
1077
1078
1079 # _collapse_query
1080 #
1081 # Recursively collapse the query, accumulating values for each column.
1082
1083 sub _collapse_query {
1084   my ($self, $query, $collapsed) = @_;
1085
1086   $collapsed ||= {};
1087
1088   if (ref $query eq 'ARRAY') {
1089     foreach my $subquery (@$query) {
1090       next unless ref $subquery;  # -or
1091       $collapsed = $self->_collapse_query($subquery, $collapsed);
1092     }
1093   }
1094   elsif (ref $query eq 'HASH') {
1095     if (keys %$query and (keys %$query)[0] eq '-and') {
1096       foreach my $subquery (@{$query->{-and}}) {
1097         $collapsed = $self->_collapse_query($subquery, $collapsed);
1098       }
1099     }
1100     else {
1101       foreach my $col (keys %$query) {
1102         my $value = $query->{$col};
1103         $collapsed->{$col}{$value}++;
1104       }
1105     }
1106   }
1107
1108   return $collapsed;
1109 }
1110
1111 =head2 get_column
1112
1113 =over 4
1114
1115 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1116
1117 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1118
1119 =back
1120
1121   my $max_length = $rs->get_column('length')->max;
1122
1123 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1124
1125 =cut
1126
1127 sub get_column {
1128   my ($self, $column) = @_;
1129   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1130   return $new;
1131 }
1132
1133 =head2 search_like
1134
1135 =over 4
1136
1137 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1138
1139 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1140
1141 =back
1142
1143   # WHERE title LIKE '%blue%'
1144   $cd_rs = $rs->search_like({ title => '%blue%'});
1145
1146 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1147 that this is simply a convenience method retained for ex Class::DBI users.
1148 You most likely want to use L</search> with specific operators.
1149
1150 For more information, see L<DBIx::Class::Manual::Cookbook>.
1151
1152 This method is deprecated and will be removed in 0.09. Use L</search()>
1153 instead. An example conversion is:
1154
1155   ->search_like({ foo => 'bar' });
1156
1157   # Becomes
1158
1159   ->search({ foo => { like => 'bar' } });
1160
1161 =cut
1162
1163 sub search_like {
1164   my $class = shift;
1165   carp_unique (
1166     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1167    .' Instead use ->search({ x => { -like => "y%" } })'
1168    .' (note the outer pair of {}s - they are important!)'
1169   );
1170   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1171   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1172   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1173   return $class->search($query, { %$attrs });
1174 }
1175
1176 =head2 slice
1177
1178 =over 4
1179
1180 =item Arguments: $first, $last
1181
1182 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1183
1184 =back
1185
1186 Returns a resultset or object list representing a subset of elements from the
1187 resultset slice is called on. Indexes are from 0, i.e., to get the first
1188 three records, call:
1189
1190   my ($one, $two, $three) = $rs->slice(0, 2);
1191
1192 =cut
1193
1194 sub slice {
1195   my ($self, $min, $max) = @_;
1196   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1197   $attrs->{offset} = $self->{attrs}{offset} || 0;
1198   $attrs->{offset} += $min;
1199   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1200   return $self->search(undef, $attrs);
1201   #my $slice = (ref $self)->new($self->result_source, $attrs);
1202   #return (wantarray ? $slice->all : $slice);
1203 }
1204
1205 =head2 next
1206
1207 =over 4
1208
1209 =item Arguments: none
1210
1211 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1212
1213 =back
1214
1215 Returns the next element in the resultset (C<undef> is there is none).
1216
1217 Can be used to efficiently iterate over records in the resultset:
1218
1219   my $rs = $schema->resultset('CD')->search;
1220   while (my $cd = $rs->next) {
1221     print $cd->title;
1222   }
1223
1224 Note that you need to store the resultset object, and call C<next> on it.
1225 Calling C<< resultset('Table')->next >> repeatedly will always return the
1226 first record from the resultset.
1227
1228 =cut
1229
1230 sub next {
1231   my ($self) = @_;
1232   if (my $cache = $self->get_cache) {
1233     $self->{all_cache_position} ||= 0;
1234     return $cache->[$self->{all_cache_position}++];
1235   }
1236   if ($self->{attrs}{cache}) {
1237     delete $self->{pager};
1238     $self->{all_cache_position} = 1;
1239     return ($self->all)[0];
1240   }
1241   if ($self->{stashed_objects}) {
1242     my $obj = shift(@{$self->{stashed_objects}});
1243     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1244     return $obj;
1245   }
1246   my @row = (
1247     exists $self->{stashed_row}
1248       ? @{delete $self->{stashed_row}}
1249       : $self->cursor->next
1250   );
1251   return undef unless (@row);
1252   my ($row, @more) = $self->_construct_object(@row);
1253   $self->{stashed_objects} = \@more if @more;
1254   return $row;
1255 }
1256
1257 sub _construct_object {
1258   my ($self, @row) = @_;
1259
1260   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1261     or return ();
1262   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1263   @new = $self->{_attrs}{record_filter}->(@new)
1264     if exists $self->{_attrs}{record_filter};
1265   return @new;
1266 }
1267
1268 sub _collapse_result {
1269   my ($self, $as_proto, $row) = @_;
1270
1271   my @copy = @$row;
1272
1273   # 'foo'         => [ undef, 'foo' ]
1274   # 'foo.bar'     => [ 'foo', 'bar' ]
1275   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1276
1277   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1278
1279   my %collapse = %{$self->{_attrs}{collapse}||{}};
1280
1281   my @pri_index;
1282
1283   # if we're doing collapsing (has_many prefetch) we need to grab records
1284   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1285   # we know we don't have to bother.
1286
1287   # the reason for not using the collapse stuff directly is because if you
1288   # had for e.g. two artists in a row with no cds, the collapse info for
1289   # both would be NULL (undef) so you'd lose the second artist
1290
1291   # store just the index so we can check the array positions from the row
1292   # without having to contruct the full hash
1293
1294   if (keys %collapse) {
1295     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1296     foreach my $i (0 .. $#construct_as) {
1297       next if defined($construct_as[$i][0]); # only self table
1298       if (delete $pri{$construct_as[$i][1]}) {
1299         push(@pri_index, $i);
1300       }
1301       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1302     }
1303   }
1304
1305   # no need to do an if, it'll be empty if @pri_index is empty anyway
1306
1307   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1308
1309   my @const_rows;
1310
1311   do { # no need to check anything at the front, we always want the first row
1312
1313     my %const;
1314
1315     foreach my $this_as (@construct_as) {
1316       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1317     }
1318
1319     push(@const_rows, \%const);
1320
1321   } until ( # no pri_index => no collapse => drop straight out
1322       !@pri_index
1323     or
1324       do { # get another row, stash it, drop out if different PK
1325
1326         @copy = $self->cursor->next;
1327         $self->{stashed_row} = \@copy;
1328
1329         # last thing in do block, counts as true if anything doesn't match
1330
1331         # check xor defined first for NULL vs. NOT NULL then if one is
1332         # defined the other must be so check string equality
1333
1334         grep {
1335           (defined $pri_vals{$_} ^ defined $copy[$_])
1336           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1337         } @pri_index;
1338       }
1339   );
1340
1341   my $alias = $self->{attrs}{alias};
1342   my $info = [];
1343
1344   my %collapse_pos;
1345
1346   my @const_keys;
1347
1348   foreach my $const (@const_rows) {
1349     scalar @const_keys or do {
1350       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1351     };
1352     foreach my $key (@const_keys) {
1353       if (length $key) {
1354         my $target = $info;
1355         my @parts = split(/\./, $key);
1356         my $cur = '';
1357         my $data = $const->{$key};
1358         foreach my $p (@parts) {
1359           $target = $target->[1]->{$p} ||= [];
1360           $cur .= ".${p}";
1361           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1362             # collapsing at this point and on final part
1363             my $pos = $collapse_pos{$cur};
1364             CK: foreach my $ck (@ckey) {
1365               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1366                 $collapse_pos{$cur} = $data;
1367                 delete @collapse_pos{ # clear all positioning for sub-entries
1368                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1369                 };
1370                 push(@$target, []);
1371                 last CK;
1372               }
1373             }
1374           }
1375           if (exists $collapse{$cur}) {
1376             $target = $target->[-1];
1377           }
1378         }
1379         $target->[0] = $data;
1380       } else {
1381         $info->[0] = $const->{$key};
1382       }
1383     }
1384   }
1385
1386   return $info;
1387 }
1388
1389 =head2 result_source
1390
1391 =over 4
1392
1393 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1394
1395 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1396
1397 =back
1398
1399 An accessor for the primary ResultSource object from which this ResultSet
1400 is derived.
1401
1402 =head2 result_class
1403
1404 =over 4
1405
1406 =item Arguments: $result_class?
1407
1408 =item Return Value: $result_class
1409
1410 =back
1411
1412 An accessor for the class to use when creating result objects. Defaults to
1413 C<< result_source->result_class >> - which in most cases is the name of the
1414 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1415
1416 Note that changing the result_class will also remove any components
1417 that were originally loaded in the source class via
1418 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1419 in the original source class will not run.
1420
1421 =cut
1422
1423 sub result_class {
1424   my ($self, $result_class) = @_;
1425   if ($result_class) {
1426     unless (ref $result_class) { # don't fire this for an object
1427       $self->ensure_class_loaded($result_class);
1428     }
1429     $self->_result_class($result_class);
1430     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1431     # permit the user to set result class on one result set only; it only
1432     # chains if provided to search()
1433     #$self->{attrs}{result_class} = $result_class if ref $self;
1434   }
1435   $self->_result_class;
1436 }
1437
1438 =head2 count
1439
1440 =over 4
1441
1442 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1443
1444 =item Return Value: $count
1445
1446 =back
1447
1448 Performs an SQL C<COUNT> with the same query as the resultset was built
1449 with to find the number of elements. Passing arguments is equivalent to
1450 C<< $rs->search ($cond, \%attrs)->count >>
1451
1452 =cut
1453
1454 sub count {
1455   my $self = shift;
1456   return $self->search(@_)->count if @_ and defined $_[0];
1457   return scalar @{ $self->get_cache } if $self->get_cache;
1458
1459   my $attrs = { %{ $self->_resolved_attrs } };
1460
1461   # this is a little optimization - it is faster to do the limit
1462   # adjustments in software, instead of a subquery
1463   my $rows = delete $attrs->{rows};
1464   my $offset = delete $attrs->{offset};
1465
1466   my $crs;
1467   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1468     $crs = $self->_count_subq_rs ($attrs);
1469   }
1470   else {
1471     $crs = $self->_count_rs ($attrs);
1472   }
1473   my $count = $crs->next;
1474
1475   $count -= $offset if $offset;
1476   $count = $rows if $rows and $rows < $count;
1477   $count = 0 if ($count < 0);
1478
1479   return $count;
1480 }
1481
1482 =head2 count_rs
1483
1484 =over 4
1485
1486 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1487
1488 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1489
1490 =back
1491
1492 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1493 This can be very handy for subqueries:
1494
1495   ->search( { amount => $some_rs->count_rs->as_query } )
1496
1497 As with regular resultsets the SQL query will be executed only after
1498 the resultset is accessed via L</next> or L</all>. That would return
1499 the same single value obtainable via L</count>.
1500
1501 =cut
1502
1503 sub count_rs {
1504   my $self = shift;
1505   return $self->search(@_)->count_rs if @_;
1506
1507   # this may look like a lack of abstraction (count() does about the same)
1508   # but in fact an _rs *must* use a subquery for the limits, as the
1509   # software based limiting can not be ported if this $rs is to be used
1510   # in a subquery itself (i.e. ->as_query)
1511   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1512     return $self->_count_subq_rs;
1513   }
1514   else {
1515     return $self->_count_rs;
1516   }
1517 }
1518
1519 #
1520 # returns a ResultSetColumn object tied to the count query
1521 #
1522 sub _count_rs {
1523   my ($self, $attrs) = @_;
1524
1525   my $rsrc = $self->result_source;
1526   $attrs ||= $self->_resolved_attrs;
1527
1528   my $tmp_attrs = { %$attrs };
1529   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1530   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1531
1532   # overwrite the selector (supplied by the storage)
1533   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1534   $tmp_attrs->{as} = 'count';
1535   delete @{$tmp_attrs}{qw/columns/};
1536
1537   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1538
1539   return $tmp_rs;
1540 }
1541
1542 #
1543 # same as above but uses a subquery
1544 #
1545 sub _count_subq_rs {
1546   my ($self, $attrs) = @_;
1547
1548   my $rsrc = $self->result_source;
1549   $attrs ||= $self->_resolved_attrs;
1550
1551   my $sub_attrs = { %$attrs };
1552   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1553   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1554
1555   # if we multi-prefetch we group_by something unique, as this is what we would
1556   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1557   if ( keys %{$attrs->{collapse}}  ) {
1558     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1559       $rsrc->_identifying_column_set || $self->throw_exception(
1560         'Unable to construct a unique group_by criteria properly collapsing the '
1561       . 'has_many prefetch before count()'
1562       );
1563     } ]
1564   }
1565
1566   # Calculate subquery selector
1567   if (my $g = $sub_attrs->{group_by}) {
1568
1569     my $sql_maker = $rsrc->storage->sql_maker;
1570
1571     # necessary as the group_by may refer to aliased functions
1572     my $sel_index;
1573     for my $sel (@{$attrs->{select}}) {
1574       $sel_index->{$sel->{-as}} = $sel
1575         if (ref $sel eq 'HASH' and $sel->{-as});
1576     }
1577
1578     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1579     # also look for named aggregates referred in the having clause
1580     # having often contains scalarrefs - thus parse it out entirely
1581     my @parts = @$g;
1582     if ($attrs->{having}) {
1583       local $sql_maker->{having_bind};
1584       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1585       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1586       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1587         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1588         # if we don't unset it we screw up retarded but unfortunately working
1589         # 'MAX(foo.bar)' => { '>', 3 }
1590         $sql_maker->{name_sep} = '';
1591       }
1592
1593       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1594
1595       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1596
1597       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1598       # and if all fails for an utterly naive quoted scalar-with-function
1599       while ($sql =~ /
1600         $rquote $sep $lquote (.+?) $rquote
1601           |
1602         [\s,] \w+ \. (\w+) [\s,]
1603           |
1604         [\s,] $lquote (.+?) $rquote [\s,]
1605       /gx) {
1606         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1607       }
1608     }
1609
1610     for (@parts) {
1611       my $colpiece = $sel_index->{$_} || $_;
1612
1613       # unqualify join-based group_by's. Arcane but possible query
1614       # also horrible horrible hack to alias a column (not a func.)
1615       # (probably need to introduce SQLA syntax)
1616       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1617         my $as = $colpiece;
1618         $as =~ s/\./__/;
1619         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1620       }
1621       push @{$sub_attrs->{select}}, $colpiece;
1622     }
1623   }
1624   else {
1625     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1626     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1627   }
1628
1629   return $rsrc->resultset_class
1630                ->new ($rsrc, $sub_attrs)
1631                 ->as_subselect_rs
1632                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1633                   ->get_column ('count');
1634 }
1635
1636 sub _bool {
1637   return 1;
1638 }
1639
1640 =head2 count_literal
1641
1642 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1643 should only be used in that context. See L</search_literal> for further info.
1644
1645 =over 4
1646
1647 =item Arguments: $sql_fragment, @standalone_bind_values
1648
1649 =item Return Value: $count
1650
1651 =back
1652
1653 Counts the results in a literal query. Equivalent to calling L</search_literal>
1654 with the passed arguments, then L</count>.
1655
1656 =cut
1657
1658 sub count_literal { shift->search_literal(@_)->count; }
1659
1660 =head2 all
1661
1662 =over 4
1663
1664 =item Arguments: none
1665
1666 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1667
1668 =back
1669
1670 Returns all elements in the resultset.
1671
1672 =cut
1673
1674 sub all {
1675   my $self = shift;
1676   if(@_) {
1677       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1678   }
1679
1680   return @{ $self->get_cache } if $self->get_cache;
1681
1682   my @obj;
1683
1684   if (keys %{$self->_resolved_attrs->{collapse}}) {
1685     # Using $self->cursor->all is really just an optimisation.
1686     # If we're collapsing has_many prefetches it probably makes
1687     # very little difference, and this is cleaner than hacking
1688     # _construct_object to survive the approach
1689     $self->cursor->reset;
1690     my @row = $self->cursor->next;
1691     while (@row) {
1692       push(@obj, $self->_construct_object(@row));
1693       @row = (exists $self->{stashed_row}
1694                ? @{delete $self->{stashed_row}}
1695                : $self->cursor->next);
1696     }
1697   } else {
1698     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1699   }
1700
1701   $self->set_cache(\@obj) if $self->{attrs}{cache};
1702
1703   return @obj;
1704 }
1705
1706 =head2 reset
1707
1708 =over 4
1709
1710 =item Arguments: none
1711
1712 =item Return Value: $self
1713
1714 =back
1715
1716 Resets the resultset's cursor, so you can iterate through the elements again.
1717 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1718 another query.
1719
1720 =cut
1721
1722 sub reset {
1723   my ($self) = @_;
1724   $self->{all_cache_position} = 0;
1725   $self->cursor->reset;
1726   return $self;
1727 }
1728
1729 =head2 first
1730
1731 =over 4
1732
1733 =item Arguments: none
1734
1735 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1736
1737 =back
1738
1739 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1740 an object for the first result (or C<undef> if the resultset is empty).
1741
1742 =cut
1743
1744 sub first {
1745   return $_[0]->reset->next;
1746 }
1747
1748
1749 # _rs_update_delete
1750 #
1751 # Determines whether and what type of subquery is required for the $rs operation.
1752 # If grouping is necessary either supplies its own, or verifies the current one
1753 # After all is done delegates to the proper storage method.
1754
1755 sub _rs_update_delete {
1756   my ($self, $op, $values) = @_;
1757
1758   my $cond = $self->{cond};
1759   my $rsrc = $self->result_source;
1760   my $storage = $rsrc->schema->storage;
1761
1762   my $attrs = { %{$self->_resolved_attrs} };
1763
1764   my $join_classifications;
1765   my $existing_group_by = delete $attrs->{group_by};
1766
1767   # do we need a subquery for any reason?
1768   my $needs_subq = (
1769     defined $existing_group_by
1770       or
1771     # if {from} is unparseable wrap a subq
1772     ref($attrs->{from}) ne 'ARRAY'
1773       or
1774     # limits call for a subq
1775     $self->_has_resolved_attr(qw/rows offset/)
1776   );
1777
1778   # simplify the joinmap, so we can further decide if a subq is necessary
1779   if (!$needs_subq and @{$attrs->{from}} > 1) {
1780     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1781
1782     # check if there are any joins left after the prune
1783     if ( @{$attrs->{from}} > 1 ) {
1784       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1785         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1786         $attrs->{select},
1787         $cond,
1788         $attrs
1789       );
1790
1791       # any non-pruneable joins imply subq
1792       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1793     }
1794   }
1795
1796   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1797   $needs_subq ||= (
1798     (ref $attrs->{from}[0]) ne 'HASH'
1799       or
1800     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1801   );
1802
1803   # do we need anything like a subquery?
1804   unless ($needs_subq) {
1805     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1806     # a condition containing 'me' or other table prefixes will not work
1807     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1808     my $cond = do {
1809       my $sqla = $rsrc->storage->sql_maker;
1810       local $sqla->{_dequalify_idents} = 1;
1811       \[ $sqla->_recurse_where($self->{cond}) ];
1812     };
1813
1814     return $rsrc->storage->$op(
1815       $rsrc,
1816       $op eq 'update' ? $values : (),
1817       $cond,
1818     );
1819   }
1820
1821   # we got this far - means it is time to wrap a subquery
1822   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1823     sprintf(
1824       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1825       $op,
1826       $rsrc->source_name,
1827     )
1828   );
1829
1830   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1831   delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1832   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1833   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1834   my $subrs = (ref $self)->new($rsrc, $attrs);
1835
1836   if (@$idcols == 1) {
1837     return $storage->$op (
1838       $rsrc,
1839       $op eq 'update' ? $values : (),
1840       { $idcols->[0] => { -in => $subrs->as_query } },
1841     );
1842   }
1843   elsif ($storage->_use_multicolumn_in) {
1844     return $storage->$op (
1845       $rsrc,
1846       $op eq 'update' ? $values : (),
1847       # no syntax for calling this properly yet
1848       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1849       $storage->sql_maker->_where_op_multicolumn_in (
1850         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1851         $subrs->as_query
1852       ),
1853     );
1854   }
1855   else {
1856
1857     # if all else fails - get all primary keys and operate over a ORed set
1858     # wrap in a transaction for consistency
1859     # this is where the group_by/multiplication starts to matter
1860     if (
1861       $existing_group_by
1862         or
1863       keys %{ $join_classifications->{multiplying} || {} }
1864     ) {
1865       # make sure if there is a supplied group_by it matches the columns compiled above
1866       # perfectly. Anything else can not be sanely executed on most databases so croak
1867       # right then and there
1868       if ($existing_group_by) {
1869         my @current_group_by = map
1870           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1871           @$existing_group_by
1872         ;
1873
1874         if (
1875           join ("\x00", sort @current_group_by)
1876             ne
1877           join ("\x00", sort @{$attrs->{columns}} )
1878         ) {
1879           $self->throw_exception (
1880             "You have just attempted a $op operation on a resultset which does group_by"
1881             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1882             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1883             . ' kind of queries. Please retry the operation with a modified group_by or'
1884             . ' without using one at all.'
1885           );
1886         }
1887       }
1888
1889       $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1890     }
1891
1892     my $guard = $storage->txn_scope_guard;
1893
1894     my @op_condition;
1895     for my $row ($subrs->cursor->all) {
1896       push @op_condition, { map
1897         { $idcols->[$_] => $row->[$_] }
1898         (0 .. $#$idcols)
1899       };
1900     }
1901
1902     my $res = $storage->$op (
1903       $rsrc,
1904       $op eq 'update' ? $values : (),
1905       \@op_condition,
1906     );
1907
1908     $guard->commit;
1909
1910     return $res;
1911   }
1912 }
1913
1914 =head2 update
1915
1916 =over 4
1917
1918 =item Arguments: \%values
1919
1920 =item Return Value: $underlying_storage_rv
1921
1922 =back
1923
1924 Sets the specified columns in the resultset to the supplied values in a
1925 single query. Note that this will not run any accessor/set_column/update
1926 triggers, nor will it update any result object instances derived from this
1927 resultset (this includes the contents of the L<resultset cache|/set_cache>
1928 if any). See L</update_all> if you need to execute any on-update
1929 triggers or cascades defined either by you or a
1930 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1931
1932 The return value is a pass through of what the underlying
1933 storage backend returned, and may vary. See L<DBI/execute> for the most
1934 common case.
1935
1936 =head3 CAVEAT
1937
1938 Note that L</update> does not process/deflate any of the values passed in.
1939 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1940 ensure manually that any value passed to this method will stringify to
1941 something the RDBMS knows how to deal with. A notable example is the
1942 handling of L<DateTime> objects, for more info see:
1943 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1944
1945 =cut
1946
1947 sub update {
1948   my ($self, $values) = @_;
1949   $self->throw_exception('Values for update must be a hash')
1950     unless ref $values eq 'HASH';
1951
1952   return $self->_rs_update_delete ('update', $values);
1953 }
1954
1955 =head2 update_all
1956
1957 =over 4
1958
1959 =item Arguments: \%values
1960
1961 =item Return Value: 1
1962
1963 =back
1964
1965 Fetches all objects and updates them one at a time via
1966 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1967 triggers, while L</update> will not.
1968
1969 =cut
1970
1971 sub update_all {
1972   my ($self, $values) = @_;
1973   $self->throw_exception('Values for update_all must be a hash')
1974     unless ref $values eq 'HASH';
1975
1976   my $guard = $self->result_source->schema->txn_scope_guard;
1977   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1978   $guard->commit;
1979   return 1;
1980 }
1981
1982 =head2 delete
1983
1984 =over 4
1985
1986 =item Arguments: none
1987
1988 =item Return Value: $underlying_storage_rv
1989
1990 =back
1991
1992 Deletes the rows matching this resultset in a single query. Note that this
1993 will not run any delete triggers, nor will it alter the
1994 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1995 derived from this resultset (this includes the contents of the
1996 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1997 execute any on-delete triggers or cascades defined either by you or a
1998 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1999
2000 The return value is a pass through of what the underlying storage backend
2001 returned, and may vary. See L<DBI/execute> for the most common case.
2002
2003 =cut
2004
2005 sub delete {
2006   my $self = shift;
2007   $self->throw_exception('delete does not accept any arguments')
2008     if @_;
2009
2010   return $self->_rs_update_delete ('delete');
2011 }
2012
2013 =head2 delete_all
2014
2015 =over 4
2016
2017 =item Arguments: none
2018
2019 =item Return Value: 1
2020
2021 =back
2022
2023 Fetches all objects and deletes them one at a time via
2024 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2025 triggers, while L</delete> will not.
2026
2027 =cut
2028
2029 sub delete_all {
2030   my $self = shift;
2031   $self->throw_exception('delete_all does not accept any arguments')
2032     if @_;
2033
2034   my $guard = $self->result_source->schema->txn_scope_guard;
2035   $_->delete for $self->all;
2036   $guard->commit;
2037   return 1;
2038 }
2039
2040 =head2 populate
2041
2042 =over 4
2043
2044 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2045
2046 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2047
2048 =back
2049
2050 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2051 arrayrefs.
2052
2053 =over
2054
2055 =item NOTE
2056
2057 The context of this method call has an important effect on what is
2058 submitted to storage. In void context data is fed directly to fastpath
2059 insertion routines provided by the underlying storage (most often
2060 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2061 L<insert|DBIx::Class::Row/insert> calls on the
2062 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2063 augmentation of these methods provided by components. For example if you
2064 are using something like L<DBIx::Class::UUIDColumns> to create primary
2065 keys for you, you will find that your PKs are empty.  In this case you
2066 will have to explicitly force scalar or list context in order to create
2067 those values.
2068
2069 =back
2070
2071 In non-void (scalar or list) context, this method is simply a wrapper
2072 for L</create>. Depending on list or scalar context either a list of
2073 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2074 containing these objects is returned.
2075
2076 When supplying data in "arrayref of arrayrefs" invocation style, the
2077 first element should be a list of column names and each subsequent
2078 element should be a data value in the earlier specified column order.
2079 For example:
2080
2081   $Arstist_rs->populate([
2082     [ qw( artistid name ) ],
2083     [ 100, 'A Formally Unknown Singer' ],
2084     [ 101, 'A singer that jumped the shark two albums ago' ],
2085     [ 102, 'An actually cool singer' ],
2086   ]);
2087
2088 For the arrayref of hashrefs style each hashref should be a structure
2089 suitable for passing to L</create>. Multi-create is also permitted with
2090 this syntax.
2091
2092   $schema->resultset("Artist")->populate([
2093      { artistid => 4, name => 'Manufactured Crap', cds => [
2094         { title => 'My First CD', year => 2006 },
2095         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2096       ],
2097      },
2098      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2099         { title => 'My parents sold me to a record company', year => 2005 },
2100         { title => 'Why Am I So Ugly?', year => 2006 },
2101         { title => 'I Got Surgery and am now Popular', year => 2007 }
2102       ],
2103      },
2104   ]);
2105
2106 If you attempt a void-context multi-create as in the example above (each
2107 Artist also has the related list of CDs), and B<do not> supply the
2108 necessary autoinc foreign key information, this method will proxy to the
2109 less efficient L</create>, and then throw the Result objects away. In this
2110 case there are obviously no benefits to using this method over L</create>.
2111
2112 =cut
2113
2114 sub populate {
2115   my $self = shift;
2116
2117   # cruft placed in standalone method
2118   my $data = $self->_normalize_populate_args(@_);
2119
2120   return unless @$data;
2121
2122   if(defined wantarray) {
2123     my @created = map { $self->create($_) } @$data;
2124     return wantarray ? @created : \@created;
2125   }
2126   else {
2127     my $first = $data->[0];
2128
2129     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2130     # it relationship data
2131     my (@rels, @columns);
2132     my $rsrc = $self->result_source;
2133     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2134     for (keys %$first) {
2135       my $ref = ref $first->{$_};
2136       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2137         ? push @rels, $_
2138         : push @columns, $_
2139       ;
2140     }
2141
2142     my @pks = $rsrc->primary_columns;
2143
2144     ## do the belongs_to relationships
2145     foreach my $index (0..$#$data) {
2146
2147       # delegate to create() for any dataset without primary keys with specified relationships
2148       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2149         for my $r (@rels) {
2150           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2151             my @ret = $self->populate($data);
2152             return;
2153           }
2154         }
2155       }
2156
2157       foreach my $rel (@rels) {
2158         next unless ref $data->[$index]->{$rel} eq "HASH";
2159         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2160         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2161         my $related = $result->result_source->_resolve_condition(
2162           $reverse_relinfo->{cond},
2163           $self,
2164           $result,
2165           $rel,
2166         );
2167
2168         delete $data->[$index]->{$rel};
2169         $data->[$index] = {%{$data->[$index]}, %$related};
2170
2171         push @columns, keys %$related if $index == 0;
2172       }
2173     }
2174
2175     ## inherit the data locked in the conditions of the resultset
2176     my ($rs_data) = $self->_merge_with_rscond({});
2177     delete @{$rs_data}{@columns};
2178
2179     ## do bulk insert on current row
2180     $rsrc->storage->insert_bulk(
2181       $rsrc,
2182       [@columns, keys %$rs_data],
2183       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2184     );
2185
2186     ## do the has_many relationships
2187     foreach my $item (@$data) {
2188
2189       my $main_row;
2190
2191       foreach my $rel (@rels) {
2192         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2193
2194         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2195
2196         my $child = $main_row->$rel;
2197
2198         my $related = $child->result_source->_resolve_condition(
2199           $rels->{$rel}{cond},
2200           $child,
2201           $main_row,
2202           $rel,
2203         );
2204
2205         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2206         my @populate = map { {%$_, %$related} } @rows_to_add;
2207
2208         $child->populate( \@populate );
2209       }
2210     }
2211   }
2212 }
2213
2214
2215 # populate() argumnets went over several incarnations
2216 # What we ultimately support is AoH
2217 sub _normalize_populate_args {
2218   my ($self, $arg) = @_;
2219
2220   if (ref $arg eq 'ARRAY') {
2221     if (!@$arg) {
2222       return [];
2223     }
2224     elsif (ref $arg->[0] eq 'HASH') {
2225       return $arg;
2226     }
2227     elsif (ref $arg->[0] eq 'ARRAY') {
2228       my @ret;
2229       my @colnames = @{$arg->[0]};
2230       foreach my $values (@{$arg}[1 .. $#$arg]) {
2231         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2232       }
2233       return \@ret;
2234     }
2235   }
2236
2237   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2238 }
2239
2240 =head2 pager
2241
2242 =over 4
2243
2244 =item Arguments: none
2245
2246 =item Return Value: L<$pager|Data::Page>
2247
2248 =back
2249
2250 Returns a L<Data::Page> object for the current resultset. Only makes
2251 sense for queries with a C<page> attribute.
2252
2253 To get the full count of entries for a paged resultset, call
2254 C<total_entries> on the L<Data::Page> object.
2255
2256 =cut
2257
2258 sub pager {
2259   my ($self) = @_;
2260
2261   return $self->{pager} if $self->{pager};
2262
2263   my $attrs = $self->{attrs};
2264   if (!defined $attrs->{page}) {
2265     $self->throw_exception("Can't create pager for non-paged rs");
2266   }
2267   elsif ($attrs->{page} <= 0) {
2268     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2269   }
2270   $attrs->{rows} ||= 10;
2271
2272   # throw away the paging flags and re-run the count (possibly
2273   # with a subselect) to get the real total count
2274   my $count_attrs = { %$attrs };
2275   delete $count_attrs->{$_} for qw/rows offset page pager/;
2276
2277   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2278
2279   require DBIx::Class::ResultSet::Pager;
2280   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2281     sub { $total_rs->count },  #lazy-get the total
2282     $attrs->{rows},
2283     $self->{attrs}{page},
2284   );
2285 }
2286
2287 =head2 page
2288
2289 =over 4
2290
2291 =item Arguments: $page_number
2292
2293 =item Return Value: L<$resultset|/search>
2294
2295 =back
2296
2297 Returns a resultset for the $page_number page of the resultset on which page
2298 is called, where each page contains a number of rows equal to the 'rows'
2299 attribute set on the resultset (10 by default).
2300
2301 =cut
2302
2303 sub page {
2304   my ($self, $page) = @_;
2305   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2306 }
2307
2308 =head2 new_result
2309
2310 =over 4
2311
2312 =item Arguments: \%col_data
2313
2314 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2315
2316 =back
2317
2318 Creates a new result object in the resultset's result class and returns
2319 it. The row is not inserted into the database at this point, call
2320 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2321 will tell you whether the result object has been inserted or not.
2322
2323 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2324
2325 =cut
2326
2327 sub new_result {
2328   my ($self, $values) = @_;
2329
2330   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2331     if @_ > 2;
2332
2333   $self->throw_exception( "new_result expects a hashref" )
2334     unless (ref $values eq 'HASH');
2335
2336   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2337
2338   my %new = (
2339     %$merged_cond,
2340     @$cols_from_relations
2341       ? (-cols_from_relations => $cols_from_relations)
2342       : (),
2343     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2344   );
2345
2346   return $self->result_class->new(\%new);
2347 }
2348
2349 # _merge_with_rscond
2350 #
2351 # Takes a simple hash of K/V data and returns its copy merged with the
2352 # condition already present on the resultset. Additionally returns an
2353 # arrayref of value/condition names, which were inferred from related
2354 # objects (this is needed for in-memory related objects)
2355 sub _merge_with_rscond {
2356   my ($self, $data) = @_;
2357
2358   my (%new_data, @cols_from_relations);
2359
2360   my $alias = $self->{attrs}{alias};
2361
2362   if (! defined $self->{cond}) {
2363     # just massage $data below
2364   }
2365   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2366     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2367     @cols_from_relations = keys %new_data;
2368   }
2369   elsif (ref $self->{cond} ne 'HASH') {
2370     $self->throw_exception(
2371       "Can't abstract implicit construct, resultset condition not a hash"
2372     );
2373   }
2374   else {
2375     # precendence must be given to passed values over values inherited from
2376     # the cond, so the order here is important.
2377     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2378     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2379
2380     while ( my($col, $value) = each %implied ) {
2381       my $vref = ref $value;
2382       if (
2383         $vref eq 'HASH'
2384           and
2385         keys(%$value) == 1
2386           and
2387         (keys %$value)[0] eq '='
2388       ) {
2389         $new_data{$col} = $value->{'='};
2390       }
2391       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2392         $new_data{$col} = $value;
2393       }
2394     }
2395   }
2396
2397   %new_data = (
2398     %new_data,
2399     %{ $self->_remove_alias($data, $alias) },
2400   );
2401
2402   return (\%new_data, \@cols_from_relations);
2403 }
2404
2405 # _has_resolved_attr
2406 #
2407 # determines if the resultset defines at least one
2408 # of the attributes supplied
2409 #
2410 # used to determine if a subquery is neccessary
2411 #
2412 # supports some virtual attributes:
2413 #   -join
2414 #     This will scan for any joins being present on the resultset.
2415 #     It is not a mere key-search but a deep inspection of {from}
2416 #
2417
2418 sub _has_resolved_attr {
2419   my ($self, @attr_names) = @_;
2420
2421   my $attrs = $self->_resolved_attrs;
2422
2423   my %extra_checks;
2424
2425   for my $n (@attr_names) {
2426     if (grep { $n eq $_ } (qw/-join/) ) {
2427       $extra_checks{$n}++;
2428       next;
2429     }
2430
2431     my $attr =  $attrs->{$n};
2432
2433     next if not defined $attr;
2434
2435     if (ref $attr eq 'HASH') {
2436       return 1 if keys %$attr;
2437     }
2438     elsif (ref $attr eq 'ARRAY') {
2439       return 1 if @$attr;
2440     }
2441     else {
2442       return 1 if $attr;
2443     }
2444   }
2445
2446   # a resolved join is expressed as a multi-level from
2447   return 1 if (
2448     $extra_checks{-join}
2449       and
2450     ref $attrs->{from} eq 'ARRAY'
2451       and
2452     @{$attrs->{from}} > 1
2453   );
2454
2455   return 0;
2456 }
2457
2458 # _collapse_cond
2459 #
2460 # Recursively collapse the condition.
2461
2462 sub _collapse_cond {
2463   my ($self, $cond, $collapsed) = @_;
2464
2465   $collapsed ||= {};
2466
2467   if (ref $cond eq 'ARRAY') {
2468     foreach my $subcond (@$cond) {
2469       next unless ref $subcond;  # -or
2470       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2471     }
2472   }
2473   elsif (ref $cond eq 'HASH') {
2474     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2475       foreach my $subcond (@{$cond->{-and}}) {
2476         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2477       }
2478     }
2479     else {
2480       foreach my $col (keys %$cond) {
2481         my $value = $cond->{$col};
2482         $collapsed->{$col} = $value;
2483       }
2484     }
2485   }
2486
2487   return $collapsed;
2488 }
2489
2490 # _remove_alias
2491 #
2492 # Remove the specified alias from the specified query hash. A copy is made so
2493 # the original query is not modified.
2494
2495 sub _remove_alias {
2496   my ($self, $query, $alias) = @_;
2497
2498   my %orig = %{ $query || {} };
2499   my %unaliased;
2500
2501   foreach my $key (keys %orig) {
2502     if ($key !~ /\./) {
2503       $unaliased{$key} = $orig{$key};
2504       next;
2505     }
2506     $unaliased{$1} = $orig{$key}
2507       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2508   }
2509
2510   return \%unaliased;
2511 }
2512
2513 =head2 as_query
2514
2515 =over 4
2516
2517 =item Arguments: none
2518
2519 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2520
2521 =back
2522
2523 Returns the SQL query and bind vars associated with the invocant.
2524
2525 This is generally used as the RHS for a subquery.
2526
2527 =cut
2528
2529 sub as_query {
2530   my $self = shift;
2531
2532   my $attrs = { %{ $self->_resolved_attrs } };
2533
2534   # For future use:
2535   #
2536   # in list ctx:
2537   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2538   # $sql also has no wrapping parenthesis in list ctx
2539   #
2540   my $sqlbind = $self->result_source->storage
2541     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2542
2543   return $sqlbind;
2544 }
2545
2546 =head2 find_or_new
2547
2548 =over 4
2549
2550 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2551
2552 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2553
2554 =back
2555
2556   my $artist = $schema->resultset('Artist')->find_or_new(
2557     { artist => 'fred' }, { key => 'artists' });
2558
2559   $cd->cd_to_producer->find_or_new({ producer => $producer },
2560                                    { key => 'primary });
2561
2562 Find an existing record from this resultset using L</find>. if none exists,
2563 instantiate a new result object and return it. The object will not be saved
2564 into your storage until you call L<DBIx::Class::Row/insert> on it.
2565
2566 You most likely want this method when looking for existing rows using a unique
2567 constraint that is not the primary key, or looking for related rows.
2568
2569 If you want objects to be saved immediately, use L</find_or_create> instead.
2570
2571 B<Note>: Make sure to read the documentation of L</find> and understand the
2572 significance of the C<key> attribute, as its lack may skew your search, and
2573 subsequently result in spurious new objects.
2574
2575 B<Note>: Take care when using C<find_or_new> with a table having
2576 columns with default values that you intend to be automatically
2577 supplied by the database (e.g. an auto_increment primary key column).
2578 In normal usage, the value of such columns should NOT be included at
2579 all in the call to C<find_or_new>, even when set to C<undef>.
2580
2581 =cut
2582
2583 sub find_or_new {
2584   my $self     = shift;
2585   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2586   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2587   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2588     return $row;
2589   }
2590   return $self->new_result($hash);
2591 }
2592
2593 =head2 create
2594
2595 =over 4
2596
2597 =item Arguments: \%col_data
2598
2599 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2600
2601 =back
2602
2603 Attempt to create a single new row or a row with multiple related rows
2604 in the table represented by the resultset (and related tables). This
2605 will not check for duplicate rows before inserting, use
2606 L</find_or_create> to do that.
2607
2608 To create one row for this resultset, pass a hashref of key/value
2609 pairs representing the columns of the table and the values you wish to
2610 store. If the appropriate relationships are set up, foreign key fields
2611 can also be passed an object representing the foreign row, and the
2612 value will be set to its primary key.
2613
2614 To create related objects, pass a hashref of related-object column values
2615 B<keyed on the relationship name>. If the relationship is of type C<multi>
2616 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2617 The process will correctly identify columns holding foreign keys, and will
2618 transparently populate them from the keys of the corresponding relation.
2619 This can be applied recursively, and will work correctly for a structure
2620 with an arbitrary depth and width, as long as the relationships actually
2621 exists and the correct column data has been supplied.
2622
2623 Instead of hashrefs of plain related data (key/value pairs), you may
2624 also pass new or inserted objects. New objects (not inserted yet, see
2625 L</new_result>), will be inserted into their appropriate tables.
2626
2627 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2628
2629 Example of creating a new row.
2630
2631   $person_rs->create({
2632     name=>"Some Person",
2633     email=>"somebody@someplace.com"
2634   });
2635
2636 Example of creating a new row and also creating rows in a related C<has_many>
2637 or C<has_one> resultset.  Note Arrayref.
2638
2639   $artist_rs->create(
2640      { artistid => 4, name => 'Manufactured Crap', cds => [
2641         { title => 'My First CD', year => 2006 },
2642         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2643       ],
2644      },
2645   );
2646
2647 Example of creating a new row and also creating a row in a related
2648 C<belongs_to> resultset. Note Hashref.
2649
2650   $cd_rs->create({
2651     title=>"Music for Silly Walks",
2652     year=>2000,
2653     artist => {
2654       name=>"Silly Musician",
2655     }
2656   });
2657
2658 =over
2659
2660 =item WARNING
2661
2662 When subclassing ResultSet never attempt to override this method. Since
2663 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2664 lot of the internals simply never call it, so your override will be
2665 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2666 or L<DBIx::Class::Row/insert> depending on how early in the
2667 L</create> process you need to intervene. See also warning pertaining to
2668 L</new>.
2669
2670 =back
2671
2672 =cut
2673
2674 sub create {
2675   my ($self, $attrs) = @_;
2676   $self->throw_exception( "create needs a hashref" )
2677     unless ref $attrs eq 'HASH';
2678   return $self->new_result($attrs)->insert;
2679 }
2680
2681 =head2 find_or_create
2682
2683 =over 4
2684
2685 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2686
2687 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2688
2689 =back
2690
2691   $cd->cd_to_producer->find_or_create({ producer => $producer },
2692                                       { key => 'primary' });
2693
2694 Tries to find a record based on its primary key or unique constraints; if none
2695 is found, creates one and returns that instead.
2696
2697   my $cd = $schema->resultset('CD')->find_or_create({
2698     cdid   => 5,
2699     artist => 'Massive Attack',
2700     title  => 'Mezzanine',
2701     year   => 2005,
2702   });
2703
2704 Also takes an optional C<key> attribute, to search by a specific key or unique
2705 constraint. For example:
2706
2707   my $cd = $schema->resultset('CD')->find_or_create(
2708     {
2709       artist => 'Massive Attack',
2710       title  => 'Mezzanine',
2711     },
2712     { key => 'cd_artist_title' }
2713   );
2714
2715 B<Note>: Make sure to read the documentation of L</find> and understand the
2716 significance of the C<key> attribute, as its lack may skew your search, and
2717 subsequently result in spurious row creation.
2718
2719 B<Note>: Because find_or_create() reads from the database and then
2720 possibly inserts based on the result, this method is subject to a race
2721 condition. Another process could create a record in the table after
2722 the find has completed and before the create has started. To avoid
2723 this problem, use find_or_create() inside a transaction.
2724
2725 B<Note>: Take care when using C<find_or_create> with a table having
2726 columns with default values that you intend to be automatically
2727 supplied by the database (e.g. an auto_increment primary key column).
2728 In normal usage, the value of such columns should NOT be included at
2729 all in the call to C<find_or_create>, even when set to C<undef>.
2730
2731 See also L</find> and L</update_or_create>. For information on how to declare
2732 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2733
2734 If you need to know if an existing row was found or a new one created use
2735 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2736 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2737 database!
2738
2739   my $cd = $schema->resultset('CD')->find_or_new({
2740     cdid   => 5,
2741     artist => 'Massive Attack',
2742     title  => 'Mezzanine',
2743     year   => 2005,
2744   });
2745
2746   if( !$cd->in_storage ) {
2747       # do some stuff
2748       $cd->insert;
2749   }
2750
2751 =cut
2752
2753 sub find_or_create {
2754   my $self     = shift;
2755   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2756   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2757   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2758     return $row;
2759   }
2760   return $self->create($hash);
2761 }
2762
2763 =head2 update_or_create
2764
2765 =over 4
2766
2767 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2768
2769 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2770
2771 =back
2772
2773   $resultset->update_or_create({ col => $val, ... });
2774
2775 Like L</find_or_create>, but if a row is found it is immediately updated via
2776 C<< $found_row->update (\%col_data) >>.
2777
2778
2779 Takes an optional C<key> attribute to search on a specific unique constraint.
2780 For example:
2781
2782   # In your application
2783   my $cd = $schema->resultset('CD')->update_or_create(
2784     {
2785       artist => 'Massive Attack',
2786       title  => 'Mezzanine',
2787       year   => 1998,
2788     },
2789     { key => 'cd_artist_title' }
2790   );
2791
2792   $cd->cd_to_producer->update_or_create({
2793     producer => $producer,
2794     name => 'harry',
2795   }, {
2796     key => 'primary',
2797   });
2798
2799 B<Note>: Make sure to read the documentation of L</find> and understand the
2800 significance of the C<key> attribute, as its lack may skew your search, and
2801 subsequently result in spurious row creation.
2802
2803 B<Note>: Take care when using C<update_or_create> with a table having
2804 columns with default values that you intend to be automatically
2805 supplied by the database (e.g. an auto_increment primary key column).
2806 In normal usage, the value of such columns should NOT be included at
2807 all in the call to C<update_or_create>, even when set to C<undef>.
2808
2809 See also L</find> and L</find_or_create>. For information on how to declare
2810 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2811
2812 If you need to know if an existing row was updated or a new one created use
2813 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2814 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2815 database!
2816
2817 =cut
2818
2819 sub update_or_create {
2820   my $self = shift;
2821   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2822   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2823
2824   my $row = $self->find($cond, $attrs);
2825   if (defined $row) {
2826     $row->update($cond);
2827     return $row;
2828   }
2829
2830   return $self->create($cond);
2831 }
2832
2833 =head2 update_or_new
2834
2835 =over 4
2836
2837 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2838
2839 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2840
2841 =back
2842
2843   $resultset->update_or_new({ col => $val, ... });
2844
2845 Like L</find_or_new> but if a row is found it is immediately updated via
2846 C<< $found_row->update (\%col_data) >>.
2847
2848 For example:
2849
2850   # In your application
2851   my $cd = $schema->resultset('CD')->update_or_new(
2852     {
2853       artist => 'Massive Attack',
2854       title  => 'Mezzanine',
2855       year   => 1998,
2856     },
2857     { key => 'cd_artist_title' }
2858   );
2859
2860   if ($cd->in_storage) {
2861       # the cd was updated
2862   }
2863   else {
2864       # the cd is not yet in the database, let's insert it
2865       $cd->insert;
2866   }
2867
2868 B<Note>: Make sure to read the documentation of L</find> and understand the
2869 significance of the C<key> attribute, as its lack may skew your search, and
2870 subsequently result in spurious new objects.
2871
2872 B<Note>: Take care when using C<update_or_new> with a table having
2873 columns with default values that you intend to be automatically
2874 supplied by the database (e.g. an auto_increment primary key column).
2875 In normal usage, the value of such columns should NOT be included at
2876 all in the call to C<update_or_new>, even when set to C<undef>.
2877
2878 See also L</find>, L</find_or_create> and L</find_or_new>.
2879
2880 =cut
2881
2882 sub update_or_new {
2883     my $self  = shift;
2884     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2885     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2886
2887     my $row = $self->find( $cond, $attrs );
2888     if ( defined $row ) {
2889         $row->update($cond);
2890         return $row;
2891     }
2892
2893     return $self->new_result($cond);
2894 }
2895
2896 =head2 get_cache
2897
2898 =over 4
2899
2900 =item Arguments: none
2901
2902 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2903
2904 =back
2905
2906 Gets the contents of the cache for the resultset, if the cache is set.
2907
2908 The cache is populated either by using the L</prefetch> attribute to
2909 L</search> or by calling L</set_cache>.
2910
2911 =cut
2912
2913 sub get_cache {
2914   shift->{all_cache};
2915 }
2916
2917 =head2 set_cache
2918
2919 =over 4
2920
2921 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2922
2923 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2924
2925 =back
2926
2927 Sets the contents of the cache for the resultset. Expects an arrayref
2928 of objects of the same class as those produced by the resultset. Note that
2929 if the cache is set, the resultset will return the cached objects rather
2930 than re-querying the database even if the cache attr is not set.
2931
2932 The contents of the cache can also be populated by using the
2933 L</prefetch> attribute to L</search>.
2934
2935 =cut
2936
2937 sub set_cache {
2938   my ( $self, $data ) = @_;
2939   $self->throw_exception("set_cache requires an arrayref")
2940       if defined($data) && (ref $data ne 'ARRAY');
2941   $self->{all_cache} = $data;
2942 }
2943
2944 =head2 clear_cache
2945
2946 =over 4
2947
2948 =item Arguments: none
2949
2950 =item Return Value: undef
2951
2952 =back
2953
2954 Clears the cache for the resultset.
2955
2956 =cut
2957
2958 sub clear_cache {
2959   shift->set_cache(undef);
2960 }
2961
2962 =head2 is_paged
2963
2964 =over 4
2965
2966 =item Arguments: none
2967
2968 =item Return Value: true, if the resultset has been paginated
2969
2970 =back
2971
2972 =cut
2973
2974 sub is_paged {
2975   my ($self) = @_;
2976   return !!$self->{attrs}{page};
2977 }
2978
2979 =head2 is_ordered
2980
2981 =over 4
2982
2983 =item Arguments: none
2984
2985 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2986
2987 =back
2988
2989 =cut
2990
2991 sub is_ordered {
2992   my ($self) = @_;
2993   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2994 }
2995
2996 =head2 related_resultset
2997
2998 =over 4
2999
3000 =item Arguments: $rel_name
3001
3002 =item Return Value: L<$resultset|/search>
3003
3004 =back
3005
3006 Returns a related resultset for the supplied relationship name.
3007
3008   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3009
3010 =cut
3011
3012 sub related_resultset {
3013   my ($self, $rel) = @_;
3014
3015   $self->{related_resultsets} ||= {};
3016   return $self->{related_resultsets}{$rel} ||= do {
3017     my $rsrc = $self->result_source;
3018     my $rel_info = $rsrc->relationship_info($rel);
3019
3020     $self->throw_exception(
3021       "search_related: result source '" . $rsrc->source_name .
3022         "' has no such relationship $rel")
3023       unless $rel_info;
3024
3025     my $attrs = $self->_chain_relationship($rel);
3026
3027     my $join_count = $attrs->{seen_join}{$rel};
3028
3029     my $alias = $self->result_source->storage
3030         ->relname_to_table_alias($rel, $join_count);
3031
3032     # since this is search_related, and we already slid the select window inwards
3033     # (the select/as attrs were deleted in the beginning), we need to flip all
3034     # left joins to inner, so we get the expected results
3035     # read the comment on top of the actual function to see what this does
3036     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3037
3038
3039     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3040     delete @{$attrs}{qw(result_class alias)};
3041
3042     my $new_cache;
3043
3044     if (my $cache = $self->get_cache) {
3045       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3046         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3047                         @$cache ];
3048       }
3049     }
3050
3051     my $rel_source = $rsrc->related_source($rel);
3052
3053     my $new = do {
3054
3055       # The reason we do this now instead of passing the alias to the
3056       # search_rs below is that if you wrap/overload resultset on the
3057       # source you need to know what alias it's -going- to have for things
3058       # to work sanely (e.g. RestrictWithObject wants to be able to add
3059       # extra query restrictions, and these may need to be $alias.)
3060
3061       my $rel_attrs = $rel_source->resultset_attributes;
3062       local $rel_attrs->{alias} = $alias;
3063
3064       $rel_source->resultset
3065                  ->search_rs(
3066                      undef, {
3067                        %$attrs,
3068                        where => $attrs->{where},
3069                    });
3070     };
3071     $new->set_cache($new_cache) if $new_cache;
3072     $new;
3073   };
3074 }
3075
3076 =head2 current_source_alias
3077
3078 =over 4
3079
3080 =item Arguments: none
3081
3082 =item Return Value: $source_alias
3083
3084 =back
3085
3086 Returns the current table alias for the result source this resultset is built
3087 on, that will be used in the SQL query. Usually it is C<me>.
3088
3089 Currently the source alias that refers to the result set returned by a
3090 L</search>/L</find> family method depends on how you got to the resultset: it's
3091 C<me> by default, but eg. L</search_related> aliases it to the related result
3092 source name (and keeps C<me> referring to the original result set). The long
3093 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3094 (and make this method unnecessary).
3095
3096 Thus it's currently necessary to use this method in predefined queries (see
3097 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3098 source alias of the current result set:
3099
3100   # in a result set class
3101   sub modified_by {
3102     my ($self, $user) = @_;
3103
3104     my $me = $self->current_source_alias;
3105
3106     return $self->search({
3107       "$me.modified" => $user->id,
3108     });
3109   }
3110
3111 =cut
3112
3113 sub current_source_alias {
3114   return (shift->{attrs} || {})->{alias} || 'me';
3115 }
3116
3117 =head2 as_subselect_rs
3118
3119 =over 4
3120
3121 =item Arguments: none
3122
3123 =item Return Value: L<$resultset|/search>
3124
3125 =back
3126
3127 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3128 "virtual view" by including it as a subquery within the from clause.  From this
3129 point on, any joined tables are inaccessible to ->search on the resultset (as if
3130 it were simply where-filtered without joins).  For example:
3131
3132  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3133
3134  # 'x' now pollutes the query namespace
3135
3136  # So the following works as expected
3137  my $ok_rs = $rs->search({'x.other' => 1});
3138
3139  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3140  # def) we look for one row with contradictory terms and join in another table
3141  # (aliased 'x_2') which we never use
3142  my $broken_rs = $rs->search({'x.name' => 'def'});
3143
3144  my $rs2 = $rs->as_subselect_rs;
3145
3146  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3147  my $not_joined_rs = $rs2->search({'x.other' => 1});
3148
3149  # works as expected: finds a 'table' row related to two x rows (abc and def)
3150  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3151
3152 Another example of when one might use this would be to select a subset of
3153 columns in a group by clause:
3154
3155  my $rs = $schema->resultset('Bar')->search(undef, {
3156    group_by => [qw{ id foo_id baz_id }],
3157  })->as_subselect_rs->search(undef, {
3158    columns => [qw{ id foo_id }]
3159  });
3160
3161 In the above example normally columns would have to be equal to the group by,
3162 but because we isolated the group by into a subselect the above works.
3163
3164 =cut
3165
3166 sub as_subselect_rs {
3167   my $self = shift;
3168
3169   my $attrs = $self->_resolved_attrs;
3170
3171   my $fresh_rs = (ref $self)->new (
3172     $self->result_source
3173   );
3174
3175   # these pieces will be locked in the subquery
3176   delete $fresh_rs->{cond};
3177   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3178
3179   return $fresh_rs->search( {}, {
3180     from => [{
3181       $attrs->{alias} => $self->as_query,
3182       -alias  => $attrs->{alias},
3183       -rsrc   => $self->result_source,
3184     }],
3185     alias => $attrs->{alias},
3186   });
3187 }
3188
3189 # This code is called by search_related, and makes sure there
3190 # is clear separation between the joins before, during, and
3191 # after the relationship. This information is needed later
3192 # in order to properly resolve prefetch aliases (any alias
3193 # with a relation_chain_depth less than the depth of the
3194 # current prefetch is not considered)
3195 #
3196 # The increments happen twice per join. An even number means a
3197 # relationship specified via a search_related, whereas an odd
3198 # number indicates a join/prefetch added via attributes
3199 #
3200 # Also this code will wrap the current resultset (the one we
3201 # chain to) in a subselect IFF it contains limiting attributes
3202 sub _chain_relationship {
3203   my ($self, $rel) = @_;
3204   my $source = $self->result_source;
3205   my $attrs = { %{$self->{attrs}||{}} };
3206
3207   # we need to take the prefetch the attrs into account before we
3208   # ->_resolve_join as otherwise they get lost - captainL
3209   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3210
3211   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3212
3213   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3214
3215   my $from;
3216   my @force_subq_attrs = qw/offset rows group_by having/;
3217
3218   if (
3219     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3220       ||
3221     $self->_has_resolved_attr (@force_subq_attrs)
3222   ) {
3223     # Nuke the prefetch (if any) before the new $rs attrs
3224     # are resolved (prefetch is useless - we are wrapping
3225     # a subquery anyway).
3226     my $rs_copy = $self->search;
3227     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3228       $rs_copy->{attrs}{join},
3229       delete $rs_copy->{attrs}{prefetch},
3230     );
3231
3232     $from = [{
3233       -rsrc   => $source,
3234       -alias  => $attrs->{alias},
3235       $attrs->{alias} => $rs_copy->as_query,
3236     }];
3237     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3238     $seen->{-relation_chain_depth} = 0;
3239   }
3240   elsif ($attrs->{from}) {  #shallow copy suffices
3241     $from = [ @{$attrs->{from}} ];
3242   }
3243   else {
3244     $from = [{
3245       -rsrc  => $source,
3246       -alias => $attrs->{alias},
3247       $attrs->{alias} => $source->from,
3248     }];
3249   }
3250
3251   my $jpath = ($seen->{-relation_chain_depth})
3252     ? $from->[-1][0]{-join_path}
3253     : [];
3254
3255   my @requested_joins = $source->_resolve_join(
3256     $join,
3257     $attrs->{alias},
3258     $seen,
3259     $jpath,
3260   );
3261
3262   push @$from, @requested_joins;
3263
3264   $seen->{-relation_chain_depth}++;
3265
3266   # if $self already had a join/prefetch specified on it, the requested
3267   # $rel might very well be already included. What we do in this case
3268   # is effectively a no-op (except that we bump up the chain_depth on
3269   # the join in question so we could tell it *is* the search_related)
3270   my $already_joined;
3271
3272   # we consider the last one thus reverse
3273   for my $j (reverse @requested_joins) {
3274     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3275     if ($rel eq $last_j) {
3276       $j->[0]{-relation_chain_depth}++;
3277       $already_joined++;
3278       last;
3279     }
3280   }
3281
3282   unless ($already_joined) {
3283     push @$from, $source->_resolve_join(
3284       $rel,
3285       $attrs->{alias},
3286       $seen,
3287       $jpath,
3288     );
3289   }
3290
3291   $seen->{-relation_chain_depth}++;
3292
3293   return {%$attrs, from => $from, seen_join => $seen};
3294 }
3295
3296 sub _resolved_attrs {
3297   my $self = shift;
3298   return $self->{_attrs} if $self->{_attrs};
3299
3300   my $attrs  = { %{ $self->{attrs} || {} } };
3301   my $source = $self->result_source;
3302   my $alias  = $attrs->{alias};
3303
3304   # default selection list
3305   $attrs->{columns} = [ $source->columns ]
3306     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3307
3308   # merge selectors together
3309   for (qw/columns select as/) {
3310     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3311       if $attrs->{$_} or $attrs->{"+$_"};
3312   }
3313
3314   # disassemble columns
3315   my (@sel, @as);
3316   if (my $cols = delete $attrs->{columns}) {
3317     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3318       if (ref $c eq 'HASH') {
3319         for my $as (sort keys %$c) {
3320           push @sel, $c->{$as};
3321           push @as, $as;
3322         }
3323       }
3324       else {
3325         push @sel, $c;
3326         push @as, $c;
3327       }
3328     }
3329   }
3330
3331   # when trying to weed off duplicates later do not go past this point -
3332   # everything added from here on is unbalanced "anyone's guess" stuff
3333   my $dedup_stop_idx = $#as;
3334
3335   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3336     if $attrs->{as};
3337   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3338     if $attrs->{select};
3339
3340   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3341   for (@sel) {
3342     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3343   }
3344
3345   # disqualify all $alias.col as-bits (collapser mandated)
3346   for (@as) {
3347     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3348   }
3349
3350   # de-duplicate the result (remove *identical* select/as pairs)
3351   # and also die on duplicate {as} pointing to different {select}s
3352   # not using a c-style for as the condition is prone to shrinkage
3353   my $seen;
3354   my $i = 0;
3355   while ($i <= $dedup_stop_idx) {
3356     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3357       splice @sel, $i, 1;
3358       splice @as, $i, 1;
3359       $dedup_stop_idx--;
3360     }
3361     elsif ($seen->{$as[$i]}++) {
3362       $self->throw_exception(
3363         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3364       );
3365     }
3366     else {
3367       $i++;
3368     }
3369   }
3370
3371   $attrs->{select} = \@sel;
3372   $attrs->{as} = \@as;
3373
3374   $attrs->{from} ||= [{
3375     -rsrc   => $source,
3376     -alias  => $self->{attrs}{alias},
3377     $self->{attrs}{alias} => $source->from,
3378   }];
3379
3380   if ( $attrs->{join} || $attrs->{prefetch} ) {
3381
3382     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3383       if ref $attrs->{from} ne 'ARRAY';
3384
3385     my $join = (delete $attrs->{join}) || {};
3386
3387     if ( defined $attrs->{prefetch} ) {
3388       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3389     }
3390
3391     $attrs->{from} =    # have to copy here to avoid corrupting the original
3392       [
3393         @{ $attrs->{from} },
3394         $source->_resolve_join(
3395           $join,
3396           $alias,
3397           { %{ $attrs->{seen_join} || {} } },
3398           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3399             ? $attrs->{from}[-1][0]{-join_path}
3400             : []
3401           ,
3402         )
3403       ];
3404   }
3405
3406   if ( defined $attrs->{order_by} ) {
3407     $attrs->{order_by} = (
3408       ref( $attrs->{order_by} ) eq 'ARRAY'
3409       ? [ @{ $attrs->{order_by} } ]
3410       : [ $attrs->{order_by} || () ]
3411     );
3412   }
3413
3414   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3415     $attrs->{group_by} = [ $attrs->{group_by} ];
3416   }
3417
3418   # generate the distinct induced group_by early, as prefetch will be carried via a
3419   # subquery (since a group_by is present)
3420   if (delete $attrs->{distinct}) {
3421     if ($attrs->{group_by}) {
3422       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3423     }
3424     else {
3425       # distinct affects only the main selection part, not what prefetch may
3426       # add below.
3427       $attrs->{group_by} = $source->storage->_group_over_selection (
3428         $attrs->{from},
3429         $attrs->{select},
3430         $attrs->{order_by},
3431       );
3432     }
3433   }
3434
3435   $attrs->{collapse} ||= {};
3436   if ($attrs->{prefetch}) {
3437
3438     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3439       if $attrs->{_dark_selector};
3440
3441     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3442
3443     my $prefetch_ordering = [];
3444
3445     # this is a separate structure (we don't look in {from} directly)
3446     # as the resolver needs to shift things off the lists to work
3447     # properly (identical-prefetches on different branches)
3448     my $join_map = {};
3449     if (ref $attrs->{from} eq 'ARRAY') {
3450
3451       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3452
3453       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3454         next unless $j->[0]{-alias};
3455         next unless $j->[0]{-join_path};
3456         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3457
3458         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3459
3460         my $p = $join_map;
3461         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3462         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3463       }
3464     }
3465
3466     my @prefetch =
3467       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3468
3469     # we need to somehow mark which columns came from prefetch
3470     if (@prefetch) {
3471       my $sel_end = $#{$attrs->{select}};
3472       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3473     }
3474
3475     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3476     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3477
3478     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3479     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3480   }
3481
3482   # if both page and offset are specified, produce a combined offset
3483   # even though it doesn't make much sense, this is what pre 081xx has
3484   # been doing
3485   if (my $page = delete $attrs->{page}) {
3486     $attrs->{offset} =
3487       ($attrs->{rows} * ($page - 1))
3488             +
3489       ($attrs->{offset} || 0)
3490     ;
3491   }
3492
3493   return $self->{_attrs} = $attrs;
3494 }
3495
3496 sub _rollout_attr {
3497   my ($self, $attr) = @_;
3498
3499   if (ref $attr eq 'HASH') {
3500     return $self->_rollout_hash($attr);
3501   } elsif (ref $attr eq 'ARRAY') {
3502     return $self->_rollout_array($attr);
3503   } else {
3504     return [$attr];
3505   }
3506 }
3507
3508 sub _rollout_array {
3509   my ($self, $attr) = @_;
3510
3511   my @rolled_array;
3512   foreach my $element (@{$attr}) {
3513     if (ref $element eq 'HASH') {
3514       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3515     } elsif (ref $element eq 'ARRAY') {
3516       #  XXX - should probably recurse here
3517       push( @rolled_array, @{$self->_rollout_array($element)} );
3518     } else {
3519       push( @rolled_array, $element );
3520     }
3521   }
3522   return \@rolled_array;
3523 }
3524
3525 sub _rollout_hash {
3526   my ($self, $attr) = @_;
3527
3528   my @rolled_array;
3529   foreach my $key (keys %{$attr}) {
3530     push( @rolled_array, { $key => $attr->{$key} } );
3531   }
3532   return \@rolled_array;
3533 }
3534
3535 sub _calculate_score {
3536   my ($self, $a, $b) = @_;
3537
3538   if (defined $a xor defined $b) {
3539     return 0;
3540   }
3541   elsif (not defined $a) {
3542     return 1;
3543   }
3544
3545   if (ref $b eq 'HASH') {
3546     my ($b_key) = keys %{$b};
3547     if (ref $a eq 'HASH') {
3548       my ($a_key) = keys %{$a};
3549       if ($a_key eq $b_key) {
3550         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3551       } else {
3552         return 0;
3553       }
3554     } else {
3555       return ($a eq $b_key) ? 1 : 0;
3556     }
3557   } else {
3558     if (ref $a eq 'HASH') {
3559       my ($a_key) = keys %{$a};
3560       return ($b eq $a_key) ? 1 : 0;
3561     } else {
3562       return ($b eq $a) ? 1 : 0;
3563     }
3564   }
3565 }
3566
3567 sub _merge_joinpref_attr {
3568   my ($self, $orig, $import) = @_;
3569
3570   return $import unless defined($orig);
3571   return $orig unless defined($import);
3572
3573   $orig = $self->_rollout_attr($orig);
3574   $import = $self->_rollout_attr($import);
3575
3576   my $seen_keys;
3577   foreach my $import_element ( @{$import} ) {
3578     # find best candidate from $orig to merge $b_element into
3579     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3580     foreach my $orig_element ( @{$orig} ) {
3581       my $score = $self->_calculate_score( $orig_element, $import_element );
3582       if ($score > $best_candidate->{score}) {
3583         $best_candidate->{position} = $position;
3584         $best_candidate->{score} = $score;
3585       }
3586       $position++;
3587     }
3588     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3589     $import_key = '' if not defined $import_key;
3590
3591     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3592       push( @{$orig}, $import_element );
3593     } else {
3594       my $orig_best = $orig->[$best_candidate->{position}];
3595       # merge orig_best and b_element together and replace original with merged
3596       if (ref $orig_best ne 'HASH') {
3597         $orig->[$best_candidate->{position}] = $import_element;
3598       } elsif (ref $import_element eq 'HASH') {
3599         my ($key) = keys %{$orig_best};
3600         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3601       }
3602     }
3603     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3604   }
3605
3606   return $orig;
3607 }
3608
3609 {
3610   my $hm;
3611
3612   sub _merge_attr {
3613     $hm ||= do {
3614       require Hash::Merge;
3615       my $hm = Hash::Merge->new;
3616
3617       $hm->specify_behavior({
3618         SCALAR => {
3619           SCALAR => sub {
3620             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3621
3622             if ($defl xor $defr) {
3623               return [ $defl ? $_[0] : $_[1] ];
3624             }
3625             elsif (! $defl) {
3626               return [];
3627             }
3628             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3629               return [ $_[0] ];
3630             }
3631             else {
3632               return [$_[0], $_[1]];
3633             }
3634           },
3635           ARRAY => sub {
3636             return $_[1] if !defined $_[0];
3637             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3638             return [$_[0], @{$_[1]}]
3639           },
3640           HASH  => sub {
3641             return [] if !defined $_[0] and !keys %{$_[1]};
3642             return [ $_[1] ] if !defined $_[0];
3643             return [ $_[0] ] if !keys %{$_[1]};
3644             return [$_[0], $_[1]]
3645           },
3646         },
3647         ARRAY => {
3648           SCALAR => sub {
3649             return $_[0] if !defined $_[1];
3650             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3651             return [@{$_[0]}, $_[1]]
3652           },
3653           ARRAY => sub {
3654             my @ret = @{$_[0]} or return $_[1];
3655             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3656             my %idx = map { $_ => 1 } @ret;
3657             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3658             \@ret;
3659           },
3660           HASH => sub {
3661             return [ $_[1] ] if ! @{$_[0]};
3662             return $_[0] if !keys %{$_[1]};
3663             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3664             return [ @{$_[0]}, $_[1] ];
3665           },
3666         },
3667         HASH => {
3668           SCALAR => sub {
3669             return [] if !keys %{$_[0]} and !defined $_[1];
3670             return [ $_[0] ] if !defined $_[1];
3671             return [ $_[1] ] if !keys %{$_[0]};
3672             return [$_[0], $_[1]]
3673           },
3674           ARRAY => sub {
3675             return [] if !keys %{$_[0]} and !@{$_[1]};
3676             return [ $_[0] ] if !@{$_[1]};
3677             return $_[1] if !keys %{$_[0]};
3678             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3679             return [ $_[0], @{$_[1]} ];
3680           },
3681           HASH => sub {
3682             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3683             return [ $_[0] ] if !keys %{$_[1]};
3684             return [ $_[1] ] if !keys %{$_[0]};
3685             return [ $_[0] ] if $_[0] eq $_[1];
3686             return [ $_[0], $_[1] ];
3687           },
3688         }
3689       } => 'DBIC_RS_ATTR_MERGER');
3690       $hm;
3691     };
3692
3693     return $hm->merge ($_[1], $_[2]);
3694   }
3695 }
3696
3697 sub STORABLE_freeze {
3698   my ($self, $cloning) = @_;
3699   my $to_serialize = { %$self };
3700
3701   # A cursor in progress can't be serialized (and would make little sense anyway)
3702   delete $to_serialize->{cursor};
3703
3704   # nor is it sensical to store a not-yet-fired-count pager
3705   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3706     delete $to_serialize->{pager};
3707   }
3708
3709   Storable::nfreeze($to_serialize);
3710 }
3711
3712 # need this hook for symmetry
3713 sub STORABLE_thaw {
3714   my ($self, $cloning, $serialized) = @_;
3715
3716   %$self = %{ Storable::thaw($serialized) };
3717
3718   $self;
3719 }
3720
3721
3722 =head2 throw_exception
3723
3724 See L<DBIx::Class::Schema/throw_exception> for details.
3725
3726 =cut
3727
3728 sub throw_exception {
3729   my $self=shift;
3730
3731   if (ref $self and my $rsrc = $self->result_source) {
3732     $rsrc->throw_exception(@_)
3733   }
3734   else {
3735     DBIx::Class::Exception->throw(@_);
3736   }
3737 }
3738
3739 # XXX: FIXME: Attributes docs need clearing up
3740
3741 =head1 ATTRIBUTES
3742
3743 Attributes are used to refine a ResultSet in various ways when
3744 searching for data. They can be passed to any method which takes an
3745 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3746 L</count>.
3747
3748 Default attributes can be set on the result class using
3749 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3750 the CAVEATS on that feature before using it!)
3751
3752 These are in no particular order:
3753
3754 =head2 order_by
3755
3756 =over 4
3757
3758 =item Value: ( $order_by | \@order_by | \%order_by )
3759
3760 =back
3761
3762 Which column(s) to order the results by.
3763
3764 [The full list of suitable values is documented in
3765 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3766 common options.]
3767
3768 If a single column name, or an arrayref of names is supplied, the
3769 argument is passed through directly to SQL. The hashref syntax allows
3770 for connection-agnostic specification of ordering direction:
3771
3772  For descending order:
3773
3774   order_by => { -desc => [qw/col1 col2 col3/] }
3775
3776  For explicit ascending order:
3777
3778   order_by => { -asc => 'col' }
3779
3780 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3781 supported, although you are strongly encouraged to use the hashref
3782 syntax as outlined above.
3783
3784 =head2 columns
3785
3786 =over 4
3787
3788 =item Value: \@columns
3789
3790 =back
3791
3792 Shortcut to request a particular set of columns to be retrieved. Each
3793 column spec may be a string (a table column name), or a hash (in which
3794 case the key is the C<as> value, and the value is used as the C<select>
3795 expression). Adds C<me.> onto the start of any column without a C<.> in
3796 it and sets C<select> from that, then auto-populates C<as> from
3797 C<select> as normal. (You may also use the C<cols> attribute, as in
3798 earlier versions of DBIC.)
3799
3800 Essentially C<columns> does the same as L</select> and L</as>.
3801
3802     columns => [ 'foo', { bar => 'baz' } ]
3803
3804 is the same as
3805
3806     select => [qw/foo baz/],
3807     as => [qw/foo bar/]
3808
3809 =head2 +columns
3810
3811 =over 4
3812
3813 =item Value: \@columns
3814
3815 =back
3816
3817 Indicates additional columns to be selected from storage. Works the same
3818 as L</columns> but adds columns to the selection. (You may also use the
3819 C<include_columns> attribute, as in earlier versions of DBIC). For
3820 example:-
3821
3822   $schema->resultset('CD')->search(undef, {
3823     '+columns' => ['artist.name'],
3824     join => ['artist']
3825   });
3826
3827 would return all CDs and include a 'name' column to the information
3828 passed to object inflation. Note that the 'artist' is the name of the
3829 column (or relationship) accessor, and 'name' is the name of the column
3830 accessor in the related table.
3831
3832 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3833 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3834 unary plus operator before it.
3835
3836 =head2 include_columns
3837
3838 =over 4
3839
3840 =item Value: \@columns
3841
3842 =back
3843
3844 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3845
3846 =head2 select
3847
3848 =over 4
3849
3850 =item Value: \@select_columns
3851
3852 =back
3853
3854 Indicates which columns should be selected from the storage. You can use
3855 column names, or in the case of RDBMS back ends, function or stored procedure
3856 names:
3857
3858   $rs = $schema->resultset('Employee')->search(undef, {
3859     select => [
3860       'name',
3861       { count => 'employeeid' },
3862       { max => { length => 'name' }, -as => 'longest_name' }
3863     ]
3864   });
3865
3866   # Equivalent SQL
3867   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3868
3869 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3870 use L</select>, to instruct DBIx::Class how to store the result of the column.
3871 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3872 identifier aliasing. You can however alias a function, so you can use it in
3873 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3874 attribute> supplied as shown in the example above.
3875
3876 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3877 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3878 unary plus operator before it.
3879
3880 =head2 +select
3881
3882 =over 4
3883
3884 Indicates additional columns to be selected from storage.  Works the same as
3885 L</select> but adds columns to the default selection, instead of specifying
3886 an explicit list.
3887
3888 =back
3889
3890 =head2 +as
3891
3892 =over 4
3893
3894 Indicates additional column names for those added via L</+select>. See L</as>.
3895
3896 =back
3897
3898 =head2 as
3899
3900 =over 4
3901
3902 =item Value: \@inflation_names
3903
3904 =back
3905
3906 Indicates column names for object inflation. That is L</as> indicates the
3907 slot name in which the column value will be stored within the
3908 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3909 identifier by the C<get_column> method (or via the object accessor B<if one
3910 with the same name already exists>) as shown below. The L</as> attribute has
3911 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3912
3913   $rs = $schema->resultset('Employee')->search(undef, {
3914     select => [
3915       'name',
3916       { count => 'employeeid' },
3917       { max => { length => 'name' }, -as => 'longest_name' }
3918     ],
3919     as => [qw/
3920       name
3921       employee_count
3922       max_name_length
3923     /],
3924   });
3925
3926 If the object against which the search is performed already has an accessor
3927 matching a column name specified in C<as>, the value can be retrieved using
3928 the accessor as normal:
3929
3930   my $name = $employee->name();
3931
3932 If on the other hand an accessor does not exist in the object, you need to
3933 use C<get_column> instead:
3934
3935   my $employee_count = $employee->get_column('employee_count');
3936
3937 You can create your own accessors if required - see
3938 L<DBIx::Class::Manual::Cookbook> for details.
3939
3940 =head2 join
3941
3942 =over 4
3943
3944 =item Value: ($rel_name | \@rel_names | \%rel_names)
3945
3946 =back
3947
3948 Contains a list of relationships that should be joined for this query.  For
3949 example:
3950
3951   # Get CDs by Nine Inch Nails
3952   my $rs = $schema->resultset('CD')->search(
3953     { 'artist.name' => 'Nine Inch Nails' },
3954     { join => 'artist' }
3955   );
3956
3957 Can also contain a hash reference to refer to the other relation's relations.
3958 For example:
3959
3960   package MyApp::Schema::Track;
3961   use base qw/DBIx::Class/;
3962   __PACKAGE__->table('track');
3963   __PACKAGE__->add_columns(qw/trackid cd position title/);
3964   __PACKAGE__->set_primary_key('trackid');
3965   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3966   1;
3967
3968   # In your application
3969   my $rs = $schema->resultset('Artist')->search(
3970     { 'track.title' => 'Teardrop' },
3971     {
3972       join     => { cd => 'track' },
3973       order_by => 'artist.name',
3974     }
3975   );
3976
3977 You need to use the relationship (not the table) name in  conditions,
3978 because they are aliased as such. The current table is aliased as "me", so
3979 you need to use me.column_name in order to avoid ambiguity. For example:
3980
3981   # Get CDs from 1984 with a 'Foo' track
3982   my $rs = $schema->resultset('CD')->search(
3983     {
3984       'me.year' => 1984,
3985       'tracks.name' => 'Foo'
3986     },
3987     { join => 'tracks' }
3988   );
3989
3990 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3991 similarly for a third time). For e.g.
3992
3993   my $rs = $schema->resultset('Artist')->search({
3994     'cds.title'   => 'Down to Earth',
3995     'cds_2.title' => 'Popular',
3996   }, {
3997     join => [ qw/cds cds/ ],
3998   });
3999
4000 will return a set of all artists that have both a cd with title 'Down
4001 to Earth' and a cd with title 'Popular'.
4002
4003 If you want to fetch related objects from other tables as well, see C<prefetch>
4004 below.
4005
4006  NOTE: An internal join-chain pruner will discard certain joins while
4007  constructing the actual SQL query, as long as the joins in question do not
4008  affect the retrieved result. This for example includes 1:1 left joins
4009  that are not part of the restriction specification (WHERE/HAVING) nor are
4010  a part of the query selection.
4011
4012 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4013
4014 =head2 prefetch
4015
4016 =over 4
4017
4018 =item Value: ($rel_name | \@rel_names | \%rel_names)
4019
4020 =back
4021
4022 Contains one or more relationships that should be fetched along with
4023 the main query (when they are accessed afterwards the data will
4024 already be available, without extra queries to the database).  This is
4025 useful for when you know you will need the related objects, because it
4026 saves at least one query:
4027
4028   my $rs = $schema->resultset('Tag')->search(
4029     undef,
4030     {
4031       prefetch => {
4032         cd => 'artist'
4033       }
4034     }
4035   );
4036
4037 The initial search results in SQL like the following:
4038
4039   SELECT tag.*, cd.*, artist.* FROM tag
4040   JOIN cd ON tag.cd = cd.cdid
4041   JOIN artist ON cd.artist = artist.artistid
4042
4043 L<DBIx::Class> has no need to go back to the database when we access the
4044 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4045 case.
4046
4047 Simple prefetches will be joined automatically, so there is no need
4048 for a C<join> attribute in the above search.
4049
4050 L</prefetch> can be used with the any of the relationship types and
4051 multiple prefetches can be specified together. Below is a more complex
4052 example that prefetches a CD's artist, its liner notes (if present),
4053 the cover image, the tracks on that cd, and the guests on those
4054 tracks.
4055
4056  # Assuming:
4057  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4058  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4059  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4060  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4061
4062  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4063
4064  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4065
4066
4067  my $rs = $schema->resultset('CD')->search(
4068    undef,
4069    {
4070      prefetch => [
4071        { artist => 'record_label'},  # belongs_to => belongs_to
4072        'liner_note',                 # might_have
4073        'cover_image',                # has_one
4074        { tracks => 'guests' },       # has_many => has_many
4075      ]
4076    }
4077  );
4078
4079 This will produce SQL like the following:
4080
4081  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4082         tracks.*, guests.*
4083    FROM cd me
4084    JOIN artist artist
4085      ON artist.artistid = me.artistid
4086    JOIN record_label record_label
4087      ON record_label.labelid = artist.labelid
4088    LEFT JOIN track tracks
4089      ON tracks.cdid = me.cdid
4090    LEFT JOIN guest guests
4091      ON guests.trackid = track.trackid
4092    LEFT JOIN liner_notes liner_note
4093      ON liner_note.cdid = me.cdid
4094    JOIN cd_artwork cover_image
4095      ON cover_image.cdid = me.cdid
4096  ORDER BY tracks.cd
4097
4098 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4099 C<tracks>, and C<guests> of the CD will all be available through the
4100 relationship accessors without the need for additional queries to the
4101 database.
4102
4103 However, there is one caveat to be observed: it can be dangerous to
4104 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4105 relationship on a given level. e.g.:
4106
4107  my $rs = $schema->resultset('CD')->search(
4108    undef,
4109    {
4110      prefetch => [
4111        'tracks',                         # has_many
4112        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4113      ]
4114    }
4115  );
4116
4117 The collapser currently can't identify duplicate tuples for multiple
4118 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4119 result the second L<has_many|DBIx::Class::Relationship/has_many>
4120 relation could contain redundant objects.
4121
4122 =head3 Using L</prefetch> with L</join>
4123
4124 L</prefetch> implies a L</join> with the equivalent argument, and is
4125 properly merged with any existing L</join> specification. So the
4126 following:
4127
4128   my $rs = $schema->resultset('CD')->search(
4129    {'record_label.name' => 'Music Product Ltd.'},
4130    {
4131      join     => {artist => 'record_label'},
4132      prefetch => 'artist',
4133    }
4134  );
4135
4136 ... will work, searching on the record label's name, but only
4137 prefetching the C<artist>.
4138
4139 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4140
4141 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4142 prefetched relations.  So given:
4143
4144   my $rs = $schema->resultset('CD')->search(
4145    undef,
4146    {
4147      select   => ['cd.title'],
4148      as       => ['cd_title'],
4149      prefetch => 'artist',
4150    }
4151  );
4152
4153 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4154 becomes: C<'cd_title', 'artist.*'>.
4155
4156 =head3 CAVEATS
4157
4158 Prefetch does a lot of deep magic. As such, it may not behave exactly
4159 as you might expect.
4160
4161 =over 4
4162
4163 =item *
4164
4165 Prefetch uses the L</cache> to populate the prefetched relationships. This
4166 may or may not be what you want.
4167
4168 =item *
4169
4170 If you specify a condition on a prefetched relationship, ONLY those
4171 rows that match the prefetched condition will be fetched into that relationship.
4172 This means that adding prefetch to a search() B<may alter> what is returned by
4173 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4174
4175   my $artist_rs = $schema->resultset('Artist')->search({
4176       'cds.year' => 2008,
4177   }, {
4178       join => 'cds',
4179   });
4180
4181   my $count = $artist_rs->first->cds->count;
4182
4183   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4184
4185   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4186
4187   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4188
4189 that cmp_ok() may or may not pass depending on the datasets involved. This
4190 behavior may or may not survive the 0.09 transition.
4191
4192 =back
4193
4194 =head2 alias
4195
4196 =over 4
4197
4198 =item Value: $source_alias
4199
4200 =back
4201
4202 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4203 nested search queries (sub-SELECTs) might need specific aliases set to
4204 reference inner queries.  For example:
4205
4206    my $q = $rs
4207       ->related_resultset('CDs')
4208       ->related_resultset('Tracks')
4209       ->search({
4210          'track.id' => { -ident => 'none_search.id' },
4211       })
4212       ->as_query;
4213
4214    my $ids = $self->search({
4215       -not_exists => $q,
4216    }, {
4217       alias    => 'none_search',
4218       group_by => 'none_search.id',
4219    })->get_column('id')->as_query;
4220
4221    $self->search({ id => { -in => $ids } })
4222
4223 This attribute is directly tied to L</current_source_alias>.
4224
4225 =head2 page
4226
4227 =over 4
4228
4229 =item Value: $page
4230
4231 =back
4232
4233 Makes the resultset paged and specifies the page to retrieve. Effectively
4234 identical to creating a non-pages resultset and then calling ->page($page)
4235 on it.
4236
4237 If L</rows> attribute is not specified it defaults to 10 rows per page.
4238
4239 When you have a paged resultset, L</count> will only return the number
4240 of rows in the page. To get the total, use the L</pager> and call
4241 C<total_entries> on it.
4242
4243 =head2 rows
4244
4245 =over 4
4246
4247 =item Value: $rows
4248
4249 =back
4250
4251 Specifies the maximum number of rows for direct retrieval or the number of
4252 rows per page if the page attribute or method is used.
4253
4254 =head2 offset
4255
4256 =over 4
4257
4258 =item Value: $offset
4259
4260 =back
4261
4262 Specifies the (zero-based) row number for the  first row to be returned, or the
4263 of the first row of the first page if paging is used.
4264
4265 =head2 software_limit
4266
4267 =over 4
4268
4269 =item Value: (0 | 1)
4270
4271 =back
4272
4273 When combined with L</rows> and/or L</offset> the generated SQL will not
4274 include any limit dialect stanzas. Instead the entire result will be selected
4275 as if no limits were specified, and DBIC will perform the limit locally, by
4276 artificially advancing and finishing the resulting L</cursor>.
4277
4278 This is the recommended way of performing resultset limiting when no sane RDBMS
4279 implementation is available (e.g.
4280 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4281 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4282
4283 =head2 group_by
4284
4285 =over 4
4286
4287 =item Value: \@columns
4288
4289 =back
4290
4291 A arrayref of columns to group by. Can include columns of joined tables.
4292
4293   group_by => [qw/ column1 column2 ... /]
4294
4295 =head2 having
4296
4297 =over 4
4298
4299 =item Value: $condition
4300
4301 =back
4302
4303 HAVING is a select statement attribute that is applied between GROUP BY and
4304 ORDER BY. It is applied to the after the grouping calculations have been
4305 done.
4306
4307   having => { 'count_employee' => { '>=', 100 } }
4308
4309 or with an in-place function in which case literal SQL is required:
4310
4311   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4312
4313 =head2 distinct
4314
4315 =over 4
4316
4317 =item Value: (0 | 1)
4318
4319 =back
4320
4321 Set to 1 to group by all columns. If the resultset already has a group_by
4322 attribute, this setting is ignored and an appropriate warning is issued.
4323
4324 =head2 where
4325
4326 =over 4
4327
4328 Adds to the WHERE clause.
4329
4330   # only return rows WHERE deleted IS NULL for all searches
4331   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4332
4333 Can be overridden by passing C<< { where => undef } >> as an attribute
4334 to a resultset.
4335
4336 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4337
4338 =back
4339
4340 =head2 cache
4341
4342 Set to 1 to cache search results. This prevents extra SQL queries if you
4343 revisit rows in your ResultSet:
4344
4345   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4346
4347   while( my $artist = $resultset->next ) {
4348     ... do stuff ...
4349   }
4350
4351   $rs->first; # without cache, this would issue a query
4352
4353 By default, searches are not cached.
4354
4355 For more examples of using these attributes, see
4356 L<DBIx::Class::Manual::Cookbook>.
4357
4358 =head2 for
4359
4360 =over 4
4361
4362 =item Value: ( 'update' | 'shared' | \$scalar )
4363
4364 =back
4365
4366 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4367 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4368 query.
4369
4370 =head1 DBIC BIND VALUES
4371
4372 Because DBIC may need more information to bind values than just the column name
4373 and value itself, it uses a special format for both passing and receiving bind
4374 values.  Each bind value should be composed of an arrayref of
4375 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4376
4377 =over 4
4378
4379 =item dbd_attrs
4380
4381 If present (in any form), this is what is being passed directly to bind_param.
4382 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4383 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4384
4385 If this is specified, all other bind options described below are ignored.
4386
4387 =item sqlt_datatype
4388
4389 If present, this is used to infer the actual bind attribute by passing to
4390 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4391 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4392
4393 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4394 currently drivers are expected to "Do the Right Thing" when given a common
4395 datatype name.  (Not ideal, but that's what we got at this point.)
4396
4397 =item sqlt_size
4398
4399 Currently used to correctly allocate buffers for bind_param_inout().
4400 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4401 or to a sensible value based on the "data_type".
4402
4403 =item dbic_colname
4404
4405 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4406 explicitly specified they are never overriden).  Also used by some weird DBDs,
4407 where the column name should be available at bind_param time (e.g. Oracle).
4408
4409 =back
4410
4411 For backwards compatibility and convenience, the following shortcuts are
4412 supported:
4413
4414   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4415   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4416   [ undef,   $val ] === [ {}, $val ]
4417
4418 =head1 AUTHOR AND CONTRIBUTORS
4419
4420 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4421
4422 =head1 LICENSE
4423
4424 You may distribute this code under the same terms as Perl itself.
4425
4426 =cut
4427
4428 1;