lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304
 305   if (ref $class) {
 306     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 307     return $class->new_result(@_);
 308   }
 309
 310   my ($source, $attrs) = @_;
 311   $source = $source->resolve
 312     if $source->isa('DBIx::Class::ResultSourceHandle');
 313
 314   $attrs = { %{$attrs||{}} };
 315   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 316
 317   if ($attrs->{page}) {
 318     $attrs->{rows} ||= 10;
 319   }
 320
 321   $attrs->{alias} ||= 'me';
 322
 323   my $self = bless {
 324     result_source => $source,
 325     cond => $attrs->{where},
 326     pager => undef,
 327     attrs => $attrs,
 328   }, $class;
 329
 330   # if there is a dark selector, this means we are already in a
 331   # chain and the cleanup/sanification was taken care of by
 332   # _search_rs already
 333   $self->_normalize_selection($attrs)
 334     unless $attrs->{_dark_selector};
 335
 336   $self->result_class(
 337     $attrs->{result_class} || $source->result_class
 338   );
 339
 340   $self;
 341 }
 342
 343 =head2 search
 344
 345 =over 4
 346
 347 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 348
 349 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 350
 351 =back
 352
 353   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 354   my $new_rs = $cd_rs->search({ year => 2005 });
 355
 356   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 357                  # year = 2005 OR year = 2004
 358
 359 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 360 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 361 To avoid that, use L</search_rs>.
 362
 363 If you need to pass in additional attributes but no additional condition,
 364 call it as C<search(undef, \%attrs)>.
 365
 366   # "SELECT name, artistid FROM $artist_table"
 367   my @all_artists = $schema->resultset('Artist')->search(undef, {
 368     columns => [qw/name artistid/],
 369   });
 370
 371 For a list of attributes that can be passed to C<search>, see
 372 L</ATTRIBUTES>. For more examples of using this function, see
 373 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 374 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 375 and its extension L<DBIx::Class::SQLMaker>.
 376
 377 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 378
 379 =head3 CAVEAT
 380
 381 Note that L</search> does not process/deflate any of the values passed in the
 382 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 383 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 384 manually that any value passed to this method will stringify to something the
 385 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 386 objects, for more info see:
 387 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 388
 389 =cut
 390
 391 sub search {
 392   my $self = shift;
 393   my $rs = $self->search_rs( @_ );
 394
 395   if (wantarray) {
 396     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 397     return $rs->all;
 398   }
 399   elsif (defined wantarray) {
 400     return $rs;
 401   }
 402   else {
 403     # we can be called by a relationship helper, which in
 404     # turn may be called in void context due to some braindead
 405     # overload or whatever else the user decided to be clever
 406     # at this particular day. Thus limit the exception to
 407     # external code calls only
 408     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 409       if (caller)[0] !~ /^\QDBIx::Class::/;
 410
 411     return ();
 412   }
 413 }
 414
 415 =head2 search_rs
 416
 417 =over 4
 418
 419 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 420
 421 =item Return Value: L<$resultset|/search>
 422
 423 =back
 424
 425 This method does the same exact thing as search() except it will
 426 always return a resultset, even in list context.
 427
 428 =cut
 429
 430 sub search_rs {
 431   my $self = shift;
 432
 433   my $rsrc = $self->result_source;
 434   my ($call_cond, $call_attrs);
 435
 436   # Special-case handling for (undef, undef) or (undef)
 437   # Note that (foo => undef) is valid deprecated syntax
 438   @_ = () if not scalar grep { defined $_ } @_;
 439
 440   # just a cond
 441   if (@_ == 1) {
 442     $call_cond = shift;
 443   }
 444   # fish out attrs in the ($condref, $attr) case
 445   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 446     ($call_cond, $call_attrs) = @_;
 447   }
 448   elsif (@_ % 2) {
 449     $self->throw_exception('Odd number of arguments to search')
 450   }
 451   # legacy search
 452   elsif (@_) {
 453     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 454       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 455
 456     for my $i (0 .. $#_) {
 457       next if $i % 2;
 458       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 459         if (! defined $_[$i] or ref $_[$i] ne '');
 460     }
 461
 462     $call_cond = { @_ };
 463   }
 464
 465   # see if we can keep the cache (no $rs changes)
 466   my $cache;
 467   my %safe = (alias => 1, cache => 1);
 468   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 469     ! defined $call_cond
 470       or
 471     ref $call_cond eq 'HASH' && ! keys %$call_cond
 472       or
 473     ref $call_cond eq 'ARRAY' && ! @$call_cond
 474   )) {
 475     $cache = $self->get_cache;
 476   }
 477
 478   my $old_attrs = { %{$self->{attrs}} };
 479   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 480
 481   my $new_attrs = { %$old_attrs };
 482
 483   # take care of call attrs (only if anything is changing)
 484   if ($call_attrs and keys %$call_attrs) {
 485
 486     # copy for _normalize_selection
 487     $call_attrs = { %$call_attrs };
 488
 489     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 490
 491     # reset the current selector list if new selectors are supplied
 492     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 493       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 494     }
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 my $dark_sel_dumper;
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => ($dark_sel_dumper ||= do {
 622                   require Data::Dumper::Concise;
 623                   Data::Dumper::Concise::DumperObject()->Indent(0);
 624                 })->Values([$_])->Dump
 625               ,
 626             };
 627             last SELECTOR;
 628           }
 629         }
 630       }
 631     }
 632     elsif (@$as < @$sel) {
 633       $self->throw_exception(
 634         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 635       );
 636     }
 637     elsif ($pref and $attrs->{_dark_selector}) {
 638       $self->throw_exception(
 639         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 640       );
 641     }
 642
 643
 644     # merge result
 645     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 646     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 647   }
 648 }
 649
 650 sub _stack_cond {
 651   my ($self, $left, $right) = @_;
 652
 653   (
 654     (ref $_ eq 'ARRAY' and !@$_)
 655       or
 656     (ref $_ eq 'HASH' and ! keys %$_)
 657   ) and $_ = undef for ($left, $right);
 658
 659   # either on of the two undef or both undef
 660   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 661     return defined $left ? $left : $right;
 662   }
 663
 664   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 665
 666   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 667
 668     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 669     my @fin = shift @vals;
 670
 671     for my $v (@vals) {
 672       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 673     }
 674
 675     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 676   }
 677
 678   $cond;
 679 }
 680
 681 =head2 search_literal
 682
 683 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 684 should only be used in that context. C<search_literal> is a convenience
 685 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 686 want to ensure columns are bound correctly, use L</search>.
 687
 688 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 689 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 690 require C<search_literal>.
 691
 692 =over 4
 693
 694 =item Arguments: $sql_fragment, @standalone_bind_values
 695
 696 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 697
 698 =back
 699
 700   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 701   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 702
 703 Pass a literal chunk of SQL to be added to the conditional part of the
 704 resultset query.
 705
 706 Example of how to use C<search> instead of C<search_literal>
 707
 708   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 709   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 710
 711 =cut
 712
 713 sub search_literal {
 714   my ($self, $sql, @bind) = @_;
 715   my $attr;
 716   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 717     $attr = pop @bind;
 718   }
 719   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 720 }
 721
 722 =head2 find
 723
 724 =over 4
 725
 726 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 727
 728 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 729
 730 =back
 731
 732 Finds and returns a single row based on supplied criteria. Takes either a
 733 hashref with the same format as L</create> (including inference of foreign
 734 keys from related objects), or a list of primary key values in the same
 735 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 736 declaration on the L</result_source>.
 737
 738 In either case an attempt is made to combine conditions already existing on
 739 the resultset with the condition passed to this method.
 740
 741 To aid with preparing the correct query for the storage you may supply the
 742 C<key> attribute, which is the name of a
 743 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 744 unique constraint corresponding to the
 745 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 746 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 747 to construct a query that satisfies the named unique constraint fully (
 748 non-NULL values for each column member of the constraint) an exception is
 749 thrown.
 750
 751 If no C<key> is specified, the search is carried over all unique constraints
 752 which are fully defined by the available condition.
 753
 754 If no such constraint is found, C<find> currently defaults to a simple
 755 C<< search->(\%column_values) >> which may or may not do what you expect.
 756 Note that this fallback behavior may be deprecated in further versions. If
 757 you need to search with arbitrary conditions - use L</search>. If the query
 758 resulting from this fallback produces more than one row, a warning to the
 759 effect is issued, though only the first row is constructed and returned as
 760 C<$result_object>.
 761
 762 In addition to C<key>, L</find> recognizes and applies standard
 763 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 764
 765 Note that if you have extra concerns about the correctness of the resulting
 766 query you need to specify the C<key> attribute and supply the entire condition
 767 as an argument to find (since it is not always possible to perform the
 768 combination of the resultset condition with the supplied one, especially if
 769 the resultset condition contains literal sql).
 770
 771 For example, to find a row by its primary key:
 772
 773   my $cd = $schema->resultset('CD')->find(5);
 774
 775 You can also find a row by a specific unique constraint:
 776
 777   my $cd = $schema->resultset('CD')->find(
 778     {
 779       artist => 'Massive Attack',
 780       title  => 'Mezzanine',
 781     },
 782     { key => 'cd_artist_title' }
 783   );
 784
 785 See also L</find_or_create> and L</update_or_create>.
 786
 787 =cut
 788
 789 sub find {
 790   my $self = shift;
 791   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 792
 793   my $rsrc = $self->result_source;
 794
 795   my $constraint_name;
 796   if (exists $attrs->{key}) {
 797     $constraint_name = defined $attrs->{key}
 798       ? $attrs->{key}
 799       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 800     ;
 801   }
 802
 803   # Parse out the condition from input
 804   my $call_cond;
 805
 806   if (ref $_[0] eq 'HASH') {
 807     $call_cond = { %{$_[0]} };
 808   }
 809   else {
 810     # if only values are supplied we need to default to 'primary'
 811     $constraint_name = 'primary' unless defined $constraint_name;
 812
 813     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 814
 815     $self->throw_exception(
 816       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 817     ) unless @c_cols;
 818
 819     $self->throw_exception (
 820       'find() expects either a column/value hashref, or a list of values '
 821     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 822     ) unless @c_cols == @_;
 823
 824     $call_cond = {};
 825     @{$call_cond}{@c_cols} = @_;
 826   }
 827
 828   my %related;
 829   for my $key (keys %$call_cond) {
 830     if (
 831       my $keyref = ref($call_cond->{$key})
 832         and
 833       my $relinfo = $rsrc->relationship_info($key)
 834     ) {
 835       my $val = delete $call_cond->{$key};
 836
 837       next if $keyref eq 'ARRAY'; # has_many for multi_create
 838
 839       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 840         $relinfo->{cond}, $val, $key, $key
 841       );
 842
 843       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 844          if $crosstable or ref($rel_cond) ne 'HASH';
 845
 846       # supplement
 847       @related{keys %$rel_cond} = values %$rel_cond;
 848     }
 849   }
 850
 851   # relationship conditions take precedence (?)
 852   @{$call_cond}{keys %related} = values %related;
 853
 854   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 855   my $final_cond;
 856   if (defined $constraint_name) {
 857     $final_cond = $self->_qualify_cond_columns (
 858
 859       $self->_build_unique_cond (
 860         $constraint_name,
 861         $call_cond,
 862       ),
 863
 864       $alias,
 865     );
 866   }
 867   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 868     # This means that we got here after a merger of relationship conditions
 869     # in ::Relationship::Base::search_related (the row method), and furthermore
 870     # the relationship is of the 'single' type. This means that the condition
 871     # provided by the relationship (already attached to $self) is sufficient,
 872     # as there can be only one row in the database that would satisfy the
 873     # relationship
 874   }
 875   else {
 876     # no key was specified - fall down to heuristics mode:
 877     # run through all unique queries registered on the resultset, and
 878     # 'OR' all qualifying queries together
 879     my (@unique_queries, %seen_column_combinations);
 880     for my $c_name ($rsrc->unique_constraint_names) {
 881       next if $seen_column_combinations{
 882         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 883       }++;
 884
 885       push @unique_queries, try {
 886         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 887       } || ();
 888     }
 889
 890     $final_cond = @unique_queries
 891       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 892       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 893     ;
 894   }
 895
 896   # Run the query, passing the result_class since it should propagate for find
 897   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 898   if ($rs->_resolved_attrs->{collapse}) {
 899     my $row = $rs->next;
 900     carp "Query returned more than one row" if $rs->next;
 901     return $row;
 902   }
 903   else {
 904     return $rs->single;
 905   }
 906 }
 907
 908 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 909 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 910 #
 911 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 912 # condition. It is provided for overrides until a saner way forward is devised
 913 #
 914 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 915 # the road. Please adjust your tests accordingly to catch this situation early
 916 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 917 #
 918 # The method will not be removed without an adequately complete replacement
 919 # for strict-mode enforcement
 920 sub _non_unique_find_fallback {
 921   my ($self, $cond, $attrs) = @_;
 922
 923   return $self->_qualify_cond_columns(
 924     $cond,
 925     exists $attrs->{alias}
 926       ? $attrs->{alias}
 927       : $self->{attrs}{alias}
 928   );
 929 }
 930
 931
 932 sub _qualify_cond_columns {
 933   my ($self, $cond, $alias) = @_;
 934
 935   my %aliased = %$cond;
 936   for (keys %aliased) {
 937     $aliased{"$alias.$_"} = delete $aliased{$_}
 938       if $_ !~ /\./;
 939   }
 940
 941   return \%aliased;
 942 }
 943
 944 sub _build_unique_cond {
 945   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 946
 947   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 948
 949   # combination may fail if $self->{cond} is non-trivial
 950   my ($final_cond) = try {
 951     $self->_merge_with_rscond ($extra_cond)
 952   } catch {
 953     +{ %$extra_cond }
 954   };
 955
 956   # trim out everything not in $columns
 957   $final_cond = { map {
 958     exists $final_cond->{$_}
 959       ? ( $_ => $final_cond->{$_} )
 960       : ()
 961   } @c_cols };
 962
 963   if (my @missing = grep
 964     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 965     (@c_cols)
 966   ) {
 967     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 968       $constraint_name,
 969       join (', ', map { "'$_'" } @missing),
 970     ) );
 971   }
 972
 973   if (
 974     !$croak_on_null
 975       and
 976     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 977       and
 978     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 979   ) {
 980     carp_unique ( sprintf (
 981       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 982     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 983     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 984       $constraint_name,
 985       join (', ', map { "'$_'" } @undefs),
 986     ));
 987   }
 988
 989   return $final_cond;
 990 }
 991
 992 =head2 search_related
 993
 994 =over 4
 995
 996 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 997
 998 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 999
1000 =back
1001
1002   $new_rs = $cd_rs->search_related('artist', {
1003     name => 'Emo-R-Us',
1004   });
1005
1006 Searches the specified relationship, optionally specifying a condition and
1007 attributes for matching records. See L</ATTRIBUTES> for more information.
1008
1009 In list context, C<< ->all() >> is called implicitly on the resultset, thus
1010 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
1011
1012 See also L</search_related_rs>.
1013
1014 =cut
1015
1016 sub search_related {
1017   return shift->related_resultset(shift)->search(@_);
1018 }
1019
1020 =head2 search_related_rs
1021
1022 This method works exactly the same as search_related, except that
1023 it guarantees a resultset, even in list context.
1024
1025 =cut
1026
1027 sub search_related_rs {
1028   return shift->related_resultset(shift)->search_rs(@_);
1029 }
1030
1031 =head2 cursor
1032
1033 =over 4
1034
1035 =item Arguments: none
1036
1037 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1038
1039 =back
1040
1041 Returns a storage-driven cursor to the given resultset. See
1042 L<DBIx::Class::Cursor> for more information.
1043
1044 =cut
1045
1046 sub cursor {
1047   my $self = shift;
1048
1049   return $self->{cursor} ||= do {
1050     my $attrs = $self->_resolved_attrs;
1051     $self->result_source->storage->select(
1052       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1053     );
1054   };
1055 }
1056
1057 =head2 single
1058
1059 =over 4
1060
1061 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1062
1063 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1064
1065 =back
1066
1067   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1068
1069 Inflates the first result without creating a cursor if the resultset has
1070 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1071 of L</search>.
1072
1073 While this method can take an optional search condition (just like L</search>)
1074 being a fast-code-path it does not recognize search attributes. If you need to
1075 add extra joins or similar, call L</search> and then chain-call L</single> on the
1076 L<DBIx::Class::ResultSet> returned.
1077
1078 =over
1079
1080 =item B<Note>
1081
1082 As of 0.08100, this method enforces the assumption that the preceding
1083 query returns only one row. If more than one row is returned, you will receive
1084 a warning:
1085
1086   Query returned more than one row
1087
1088 In this case, you should be using L</next> or L</find> instead, or if you really
1089 know what you are doing, use the L</rows> attribute to explicitly limit the size
1090 of the resultset.
1091
1092 This method will also throw an exception if it is called on a resultset prefetching
1093 has_many, as such a prefetch implies fetching multiple rows from the database in
1094 order to assemble the resulting object.
1095
1096 =back
1097
1098 =cut
1099
1100 sub single {
1101   my ($self, $where) = @_;
1102   if(@_ > 2) {
1103       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1104   }
1105
1106   my $attrs = { %{$self->_resolved_attrs} };
1107
1108   $self->throw_exception(
1109     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1110   ) if $attrs->{collapse};
1111
1112   if ($where) {
1113     if (defined $attrs->{where}) {
1114       $attrs->{where} = {
1115         '-and' =>
1116             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1117                $where, delete $attrs->{where} ]
1118       };
1119     } else {
1120       $attrs->{where} = $where;
1121     }
1122   }
1123
1124   my $data = [ $self->result_source->storage->select_single(
1125     $attrs->{from}, $attrs->{select},
1126     $attrs->{where}, $attrs
1127   )];
1128
1129   return undef unless @$data;
1130   $self->{_stashed_rows} = [ $data ];
1131   $self->_construct_results->[0];
1132 }
1133
1134 =head2 get_column
1135
1136 =over 4
1137
1138 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1139
1140 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1141
1142 =back
1143
1144   my $max_length = $rs->get_column('length')->max;
1145
1146 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1147
1148 =cut
1149
1150 sub get_column {
1151   my ($self, $column) = @_;
1152   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1153   return $new;
1154 }
1155
1156 =head2 search_like
1157
1158 =over 4
1159
1160 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1161
1162 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1163
1164 =back
1165
1166   # WHERE title LIKE '%blue%'
1167   $cd_rs = $rs->search_like({ title => '%blue%'});
1168
1169 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1170 that this is simply a convenience method retained for ex Class::DBI users.
1171 You most likely want to use L</search> with specific operators.
1172
1173 For more information, see L<DBIx::Class::Manual::Cookbook>.
1174
1175 This method is deprecated and will be removed in 0.09. Use L</search()>
1176 instead. An example conversion is:
1177
1178   ->search_like({ foo => 'bar' });
1179
1180   # Becomes
1181
1182   ->search({ foo => { like => 'bar' } });
1183
1184 =cut
1185
1186 sub search_like {
1187   my $class = shift;
1188   carp_unique (
1189     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1190    .' Instead use ->search({ x => { -like => "y%" } })'
1191    .' (note the outer pair of {}s - they are important!)'
1192   );
1193   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1194   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1195   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1196   return $class->search($query, { %$attrs });
1197 }
1198
1199 =head2 slice
1200
1201 =over 4
1202
1203 =item Arguments: $first, $last
1204
1205 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1206
1207 =back
1208
1209 Returns a resultset or object list representing a subset of elements from the
1210 resultset slice is called on. Indexes are from 0, i.e., to get the first
1211 three records, call:
1212
1213   my ($one, $two, $three) = $rs->slice(0, 2);
1214
1215 =cut
1216
1217 sub slice {
1218   my ($self, $min, $max) = @_;
1219   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1220   $attrs->{offset} = $self->{attrs}{offset} || 0;
1221   $attrs->{offset} += $min;
1222   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1223   return $self->search(undef, $attrs);
1224 }
1225
1226 =head2 next
1227
1228 =over 4
1229
1230 =item Arguments: none
1231
1232 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1233
1234 =back
1235
1236 Returns the next element in the resultset (C<undef> is there is none).
1237
1238 Can be used to efficiently iterate over records in the resultset:
1239
1240   my $rs = $schema->resultset('CD')->search;
1241   while (my $cd = $rs->next) {
1242     print $cd->title;
1243   }
1244
1245 Note that you need to store the resultset object, and call C<next> on it.
1246 Calling C<< resultset('Table')->next >> repeatedly will always return the
1247 first record from the resultset.
1248
1249 =cut
1250
1251 sub next {
1252   my ($self) = @_;
1253
1254   if (my $cache = $self->get_cache) {
1255     $self->{all_cache_position} ||= 0;
1256     return $cache->[$self->{all_cache_position}++];
1257   }
1258
1259   if ($self->{attrs}{cache}) {
1260     delete $self->{pager};
1261     $self->{all_cache_position} = 1;
1262     return ($self->all)[0];
1263   }
1264
1265   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1266
1267   $self->{_stashed_results} = $self->_construct_results
1268     or return undef;
1269
1270   return shift @{$self->{_stashed_results}};
1271 }
1272
1273 # Constructs as many results as it can in one pass while respecting
1274 # cursor laziness. Several modes of operation:
1275 #
1276 # * Always builds everything present in @{$self->{_stashed_rows}}
1277 # * If called with $fetch_all true - pulls everything off the cursor and
1278 #   builds all result structures (or objects) in one pass
1279 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1280 #   and if the resultset is ordered properly by the left side:
1281 #   * Fetches stuff off the cursor until the "master object" changes,
1282 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1283 #   OR
1284 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1285 #     was requested (there is no other way to collapse except for an
1286 #     eager cursor)
1287 # * If no collapse is requested - just get the next row, construct and
1288 #   return
1289 sub _construct_results {
1290   my ($self, $fetch_all) = @_;
1291
1292   my $rsrc = $self->result_source;
1293   my $attrs = $self->_resolved_attrs;
1294
1295   if (
1296     ! $fetch_all
1297       and
1298     ! $attrs->{order_by}
1299       and
1300     $attrs->{collapse}
1301       and
1302     my @pcols = $rsrc->primary_columns
1303   ) {
1304     # default order for collapsing unless the user asked for something
1305     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1306     $attrs->{_ordered_for_collapse} = 1;
1307     $attrs->{_order_is_artificial} = 1;
1308   }
1309
1310   # this will be used as both initial raw-row collector AND as a RV of
1311   # _construct_results. Not regrowing the array twice matters a lot...
1312   # a surprising amount actually
1313   my $rows = delete $self->{_stashed_rows};
1314
1315   my $cursor; # we may not need one at all
1316
1317   my $did_fetch_all = $fetch_all;
1318
1319   if ($fetch_all) {
1320     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1321     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1322   }
1323   elsif( $attrs->{collapse} ) {
1324
1325     # a cursor will need to be closed over in case of collapse
1326     $cursor = $self->cursor;
1327
1328     $attrs->{_ordered_for_collapse} = (
1329       (
1330         $attrs->{order_by}
1331           and
1332         $rsrc->schema
1333               ->storage
1334                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1335       ) ? 1 : 0
1336     ) unless defined $attrs->{_ordered_for_collapse};
1337
1338     if (! $attrs->{_ordered_for_collapse}) {
1339       $did_fetch_all = 1;
1340
1341       # instead of looping over ->next, use ->all in stealth mode
1342       # *without* calling a ->reset afterwards
1343       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1344       if (! $cursor->{_done}) {
1345         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1346         $cursor->{_done} = 1;
1347       }
1348     }
1349   }
1350
1351   if (! $did_fetch_all and ! @{$rows||[]} ) {
1352     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1353     $cursor ||= $self->cursor;
1354     if (scalar (my @r = $cursor->next) ) {
1355       $rows = [ \@r ];
1356     }
1357   }
1358
1359   return undef unless @{$rows||[]};
1360
1361   # sanity check - people are too clever for their own good
1362   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1363
1364     my $multiplied_selectors;
1365     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1366       if (
1367         $aliastypes->{multiplying}{$sel_alias}
1368           or
1369         $aliastypes->{premultiplied}{$sel_alias}
1370       ) {
1371         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1372       }
1373     }
1374
1375     for my $i (0 .. $#{$attrs->{as}} ) {
1376       my $sel = $attrs->{select}[$i];
1377
1378       if (ref $sel eq 'SCALAR') {
1379         $sel = $$sel;
1380       }
1381       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1382         $sel = $$sel->[0];
1383       }
1384
1385       $self->throw_exception(
1386         'Result collapse not possible - selection from a has_many source redirected to the main object'
1387       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1388     }
1389   }
1390
1391   # hotspot - skip the setter
1392   my $res_class = $self->_result_class;
1393
1394   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1395     $res_class->can ('inflate_result')
1396       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1397   };
1398
1399   my $infmap = $attrs->{as};
1400
1401   $self->{_result_inflator}{is_core_row} = ( (
1402     $inflator_cref
1403       ==
1404     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1405   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1406
1407   $self->{_result_inflator}{is_hri} = ( (
1408     ! $self->{_result_inflator}{is_core_row}
1409       and
1410     $inflator_cref == (
1411       require DBIx::Class::ResultClass::HashRefInflator
1412         &&
1413       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1414     )
1415   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1416
1417
1418   if ($attrs->{_simple_passthrough_construction}) {
1419     # construct a much simpler array->hash folder for the one-table HRI cases right here
1420     if ($self->{_result_inflator}{is_hri}) {
1421       for my $r (@$rows) {
1422         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1423       }
1424     }
1425     # FIXME SUBOPTIMAL this is a very very very hot spot
1426     # while rather optimal we can *still* do much better, by
1427     # building a smarter Row::inflate_result(), and
1428     # switch to feeding it data via a much leaner interface
1429     #
1430     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1431     # this particular resultset size
1432     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1433       for my $r (@$rows) {
1434         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1435       }
1436     }
1437     else {
1438       eval sprintf (
1439         ( $self->{_result_inflator}{is_core_row}
1440           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1441           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1442           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1443         ),
1444         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1445       );
1446     }
1447   }
1448   else {
1449     my $parser_type =
1450         $self->{_result_inflator}{is_hri}       ? 'hri'
1451       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1452       :                                           'classic_nonpruning'
1453     ;
1454
1455     # $args and $attrs to _mk_row_parser are separated to delineate what is
1456     # core collapser stuff and what is dbic $rs specific
1457     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1458       eval => 1,
1459       inflate_map => $infmap,
1460       collapse => $attrs->{collapse},
1461       premultiplied => $attrs->{_main_source_premultiplied},
1462       hri_style => $self->{_result_inflator}{is_hri},
1463       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1464     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1465
1466     # column_info metadata historically hasn't been too reliable.
1467     # We need to start fixing this somehow (the collapse resolver
1468     # can't work without it). Add an explicit check for the *main*
1469     # result, hopefully this will gradually weed out such errors
1470     #
1471     # FIXME - this is a temporary kludge that reduces performance
1472     # It is however necessary for the time being
1473     my ($unrolled_non_null_cols_to_check, $err);
1474
1475     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1476
1477       $err =
1478         'Collapse aborted due to invalid ResultSource metadata - the following '
1479       . 'selections are declared non-nullable but NULLs were retrieved: '
1480       ;
1481
1482       my @violating_idx;
1483       COL: for my $i (@$check_non_null_cols) {
1484         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1485       }
1486
1487       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1488         if @violating_idx;
1489
1490       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1491     }
1492
1493     my $next_cref =
1494       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1495     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1496 sub {
1497   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1498   my @r = $cursor->next or return;
1499   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1500     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1501   }
1502   \@r
1503 }
1504 EOS
1505     : sub {
1506         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1507         my @r = $cursor->next or return;
1508         \@r
1509       }
1510     ;
1511
1512     $self->{_row_parser}{$parser_type}{cref}->(
1513       $rows,
1514       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1515     );
1516
1517     # simple in-place substitution, does not regrow $rows
1518     if ($self->{_result_inflator}{is_core_row}) {
1519       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1520     }
1521     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1522     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1523       # the inflator may be a multiplier/reductor - put it in list ctx
1524       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1525     }
1526   }
1527
1528   # The @$rows check seems odd at first - why wouldn't we want to warn
1529   # regardless? The issue is things like find() etc, where the user
1530   # *knows* only one result will come back. In these cases the ->all
1531   # is not a pessimization, but rather something we actually want
1532   carp_unique(
1533     'Unable to properly collapse has_many results in iterator mode due '
1534   . 'to order criteria - performed an eager cursor slurp underneath. '
1535   . 'Consider using ->all() instead'
1536   ) if ( ! $fetch_all and @$rows > 1 );
1537
1538   return $rows;
1539 }
1540
1541 =head2 result_source
1542
1543 =over 4
1544
1545 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1546
1547 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1548
1549 =back
1550
1551 An accessor for the primary ResultSource object from which this ResultSet
1552 is derived.
1553
1554 =head2 result_class
1555
1556 =over 4
1557
1558 =item Arguments: $result_class?
1559
1560 =item Return Value: $result_class
1561
1562 =back
1563
1564 An accessor for the class to use when creating result objects. Defaults to
1565 C<< result_source->result_class >> - which in most cases is the name of the
1566 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1567
1568 Note that changing the result_class will also remove any components
1569 that were originally loaded in the source class via
1570 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1571 in the original source class will not run.
1572
1573 =cut
1574
1575 sub result_class {
1576   my ($self, $result_class) = @_;
1577   if ($result_class) {
1578
1579     # don't fire this for an object
1580     $self->ensure_class_loaded($result_class)
1581       unless ref($result_class);
1582
1583     if ($self->get_cache) {
1584       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1585     }
1586     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1587     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1588       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1589     }
1590
1591     $self->_result_class($result_class);
1592
1593     delete $self->{_result_inflator};
1594   }
1595   $self->_result_class;
1596 }
1597
1598 =head2 count
1599
1600 =over 4
1601
1602 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1603
1604 =item Return Value: $count
1605
1606 =back
1607
1608 Performs an SQL C<COUNT> with the same query as the resultset was built
1609 with to find the number of elements. Passing arguments is equivalent to
1610 C<< $rs->search ($cond, \%attrs)->count >>
1611
1612 =cut
1613
1614 sub count {
1615   my $self = shift;
1616   return $self->search(@_)->count if @_ and defined $_[0];
1617   return scalar @{ $self->get_cache } if $self->get_cache;
1618
1619   my $attrs = { %{ $self->_resolved_attrs } };
1620
1621   # this is a little optimization - it is faster to do the limit
1622   # adjustments in software, instead of a subquery
1623   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1624
1625   my $crs;
1626   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1627     $crs = $self->_count_subq_rs ($attrs);
1628   }
1629   else {
1630     $crs = $self->_count_rs ($attrs);
1631   }
1632   my $count = $crs->next;
1633
1634   $count -= $offset if $offset;
1635   $count = $rows if $rows and $rows < $count;
1636   $count = 0 if ($count < 0);
1637
1638   return $count;
1639 }
1640
1641 =head2 count_rs
1642
1643 =over 4
1644
1645 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1646
1647 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1648
1649 =back
1650
1651 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1652 This can be very handy for subqueries:
1653
1654   ->search( { amount => $some_rs->count_rs->as_query } )
1655
1656 As with regular resultsets the SQL query will be executed only after
1657 the resultset is accessed via L</next> or L</all>. That would return
1658 the same single value obtainable via L</count>.
1659
1660 =cut
1661
1662 sub count_rs {
1663   my $self = shift;
1664   return $self->search(@_)->count_rs if @_;
1665
1666   # this may look like a lack of abstraction (count() does about the same)
1667   # but in fact an _rs *must* use a subquery for the limits, as the
1668   # software based limiting can not be ported if this $rs is to be used
1669   # in a subquery itself (i.e. ->as_query)
1670   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1671     return $self->_count_subq_rs($self->{_attrs});
1672   }
1673   else {
1674     return $self->_count_rs($self->{_attrs});
1675   }
1676 }
1677
1678 #
1679 # returns a ResultSetColumn object tied to the count query
1680 #
1681 sub _count_rs {
1682   my ($self, $attrs) = @_;
1683
1684   my $rsrc = $self->result_source;
1685
1686   my $tmp_attrs = { %$attrs };
1687   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1688   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1689
1690   # overwrite the selector (supplied by the storage)
1691   $rsrc->resultset_class->new($rsrc, {
1692     %$tmp_attrs,
1693     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1694     as => 'count',
1695   })->get_column ('count');
1696 }
1697
1698 #
1699 # same as above but uses a subquery
1700 #
1701 sub _count_subq_rs {
1702   my ($self, $attrs) = @_;
1703
1704   my $rsrc = $self->result_source;
1705
1706   my $sub_attrs = { %$attrs };
1707   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1708   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1709
1710   # if we multi-prefetch we group_by something unique, as this is what we would
1711   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1712   if ( $attrs->{collapse}  ) {
1713     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1714       $rsrc->_identifying_column_set || $self->throw_exception(
1715         'Unable to construct a unique group_by criteria properly collapsing the '
1716       . 'has_many prefetch before count()'
1717       );
1718     } ]
1719   }
1720
1721   # Calculate subquery selector
1722   if (my $g = $sub_attrs->{group_by}) {
1723
1724     my $sql_maker = $rsrc->storage->sql_maker;
1725
1726     # necessary as the group_by may refer to aliased functions
1727     my $sel_index;
1728     for my $sel (@{$attrs->{select}}) {
1729       $sel_index->{$sel->{-as}} = $sel
1730         if (ref $sel eq 'HASH' and $sel->{-as});
1731     }
1732
1733     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1734     # also look for named aggregates referred in the having clause
1735     # having often contains scalarrefs - thus parse it out entirely
1736     my @parts = @$g;
1737     if ($attrs->{having}) {
1738       local $sql_maker->{having_bind};
1739       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1740       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1741       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1742         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1743         # if we don't unset it we screw up retarded but unfortunately working
1744         # 'MAX(foo.bar)' => { '>', 3 }
1745         $sql_maker->{name_sep} = '';
1746       }
1747
1748       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1749
1750       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1751       my %seen_having;
1752
1753       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1754       # and if all fails for an utterly naive quoted scalar-with-function
1755       while ($having_sql =~ /
1756         $rquote $sep $lquote (.+?) $rquote
1757           |
1758         [\s,] \w+ \. (\w+) [\s,]
1759           |
1760         [\s,] $lquote (.+?) $rquote [\s,]
1761       /gx) {
1762         my $part = $1 || $2 || $3;  # one of them matched if we got here
1763         unless ($seen_having{$part}++) {
1764           push @parts, $part;
1765         }
1766       }
1767     }
1768
1769     for (@parts) {
1770       my $colpiece = $sel_index->{$_} || $_;
1771
1772       # unqualify join-based group_by's. Arcane but possible query
1773       # also horrible horrible hack to alias a column (not a func.)
1774       # (probably need to introduce SQLA syntax)
1775       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1776         my $as = $colpiece;
1777         $as =~ s/\./__/;
1778         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1779       }
1780       push @{$sub_attrs->{select}}, $colpiece;
1781     }
1782   }
1783   else {
1784     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1785     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1786   }
1787
1788   return $rsrc->resultset_class
1789                ->new ($rsrc, $sub_attrs)
1790                 ->as_subselect_rs
1791                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1792                   ->get_column ('count');
1793 }
1794
1795
1796 =head2 count_literal
1797
1798 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1799 should only be used in that context. See L</search_literal> for further info.
1800
1801 =over 4
1802
1803 =item Arguments: $sql_fragment, @standalone_bind_values
1804
1805 =item Return Value: $count
1806
1807 =back
1808
1809 Counts the results in a literal query. Equivalent to calling L</search_literal>
1810 with the passed arguments, then L</count>.
1811
1812 =cut
1813
1814 sub count_literal { shift->search_literal(@_)->count; }
1815
1816 =head2 all
1817
1818 =over 4
1819
1820 =item Arguments: none
1821
1822 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1823
1824 =back
1825
1826 Returns all elements in the resultset.
1827
1828 =cut
1829
1830 sub all {
1831   my $self = shift;
1832   if(@_) {
1833     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1834   }
1835
1836   delete @{$self}{qw/_stashed_rows _stashed_results/};
1837
1838   if (my $c = $self->get_cache) {
1839     return @$c;
1840   }
1841
1842   $self->cursor->reset;
1843
1844   my $objs = $self->_construct_results('fetch_all') || [];
1845
1846   $self->set_cache($objs) if $self->{attrs}{cache};
1847
1848   return @$objs;
1849 }
1850
1851 =head2 reset
1852
1853 =over 4
1854
1855 =item Arguments: none
1856
1857 =item Return Value: $self
1858
1859 =back
1860
1861 Resets the resultset's cursor, so you can iterate through the elements again.
1862 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1863 another query.
1864
1865 =cut
1866
1867 sub reset {
1868   my ($self) = @_;
1869
1870   delete @{$self}{qw/_stashed_rows _stashed_results/};
1871   $self->{all_cache_position} = 0;
1872   $self->cursor->reset;
1873   return $self;
1874 }
1875
1876 =head2 first
1877
1878 =over 4
1879
1880 =item Arguments: none
1881
1882 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1883
1884 =back
1885
1886 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1887 an object for the first result (or C<undef> if the resultset is empty).
1888
1889 =cut
1890
1891 sub first {
1892   return $_[0]->reset->next;
1893 }
1894
1895
1896 # _rs_update_delete
1897 #
1898 # Determines whether and what type of subquery is required for the $rs operation.
1899 # If grouping is necessary either supplies its own, or verifies the current one
1900 # After all is done delegates to the proper storage method.
1901
1902 sub _rs_update_delete {
1903   my ($self, $op, $values) = @_;
1904
1905   my $rsrc = $self->result_source;
1906   my $storage = $rsrc->schema->storage;
1907
1908   my $attrs = { %{$self->_resolved_attrs} };
1909
1910   my $join_classifications;
1911   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1912
1913   # do we need a subquery for any reason?
1914   my $needs_subq = (
1915     defined $existing_group_by
1916       or
1917     # if {from} is unparseable wrap a subq
1918     ref($attrs->{from}) ne 'ARRAY'
1919       or
1920     # limits call for a subq
1921     $self->_has_resolved_attr(qw/rows offset/)
1922   );
1923
1924   # simplify the joinmap, so we can further decide if a subq is necessary
1925   if (!$needs_subq and @{$attrs->{from}} > 1) {
1926
1927     ($attrs->{from}, $join_classifications) =
1928       $storage->_prune_unused_joins ($attrs);
1929
1930     # any non-pruneable non-local restricting joins imply subq
1931     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1932   }
1933
1934   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1935   $needs_subq ||= (
1936     (ref $attrs->{from}[0]) ne 'HASH'
1937       or
1938     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1939   );
1940
1941   my ($cond, $guard);
1942   # do we need anything like a subquery?
1943   if (! $needs_subq) {
1944     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1945     # a condition containing 'me' or other table prefixes will not work
1946     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1947     $cond = do {
1948       my $sqla = $rsrc->storage->sql_maker;
1949       local $sqla->{_dequalify_idents} = 1;
1950       \[ $sqla->_recurse_where($self->{cond}) ];
1951     };
1952   }
1953   else {
1954     # we got this far - means it is time to wrap a subquery
1955     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1956       sprintf(
1957         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1958         $op,
1959         $rsrc->source_name,
1960       )
1961     );
1962
1963     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1964     delete $attrs->{$_} for qw/select as collapse/;
1965     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1966
1967     # this will be consumed by the pruner waaaaay down the stack
1968     $attrs->{_force_prune_multiplying_joins} = 1;
1969
1970     my $subrs = (ref $self)->new($rsrc, $attrs);
1971
1972     if (@$idcols == 1) {
1973       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1974     }
1975     elsif ($storage->_use_multicolumn_in) {
1976       # no syntax for calling this properly yet
1977       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1978       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1979         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1980         $subrs->as_query
1981       ),
1982     }
1983     else {
1984       # if all else fails - get all primary keys and operate over a ORed set
1985       # wrap in a transaction for consistency
1986       # this is where the group_by/multiplication starts to matter
1987       if (
1988         $existing_group_by
1989           or
1990         # we do not need to check pre-multipliers, since if the premulti is there, its
1991         # parent (who is multi) will be there too
1992         keys %{ $join_classifications->{multiplying} || {} }
1993       ) {
1994         # make sure if there is a supplied group_by it matches the columns compiled above
1995         # perfectly. Anything else can not be sanely executed on most databases so croak
1996         # right then and there
1997         if ($existing_group_by) {
1998           my @current_group_by = map
1999             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
2000             @$existing_group_by
2001           ;
2002
2003           if (
2004             join ("\x00", sort @current_group_by)
2005               ne
2006             join ("\x00", sort @{$attrs->{columns}} )
2007           ) {
2008             $self->throw_exception (
2009               "You have just attempted a $op operation on a resultset which does group_by"
2010               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
2011               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
2012               . ' kind of queries. Please retry the operation with a modified group_by or'
2013               . ' without using one at all.'
2014             );
2015           }
2016         }
2017
2018         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2019       }
2020
2021       $guard = $storage->txn_scope_guard;
2022
2023       for my $row ($subrs->cursor->all) {
2024         push @$cond, { map
2025           { $idcols->[$_] => $row->[$_] }
2026           (0 .. $#$idcols)
2027         };
2028       }
2029     }
2030   }
2031
2032   my $res = $cond ? $storage->$op (
2033     $rsrc,
2034     $op eq 'update' ? $values : (),
2035     $cond,
2036   ) : '0E0';
2037
2038   $guard->commit if $guard;
2039
2040   return $res;
2041 }
2042
2043 =head2 update
2044
2045 =over 4
2046
2047 =item Arguments: \%values
2048
2049 =item Return Value: $underlying_storage_rv
2050
2051 =back
2052
2053 Sets the specified columns in the resultset to the supplied values in a
2054 single query. Note that this will not run any accessor/set_column/update
2055 triggers, nor will it update any result object instances derived from this
2056 resultset (this includes the contents of the L<resultset cache|/set_cache>
2057 if any). See L</update_all> if you need to execute any on-update
2058 triggers or cascades defined either by you or a
2059 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2060
2061 The return value is a pass through of what the underlying
2062 storage backend returned, and may vary. See L<DBI/execute> for the most
2063 common case.
2064
2065 =head3 CAVEAT
2066
2067 Note that L</update> does not process/deflate any of the values passed in.
2068 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2069 ensure manually that any value passed to this method will stringify to
2070 something the RDBMS knows how to deal with. A notable example is the
2071 handling of L<DateTime> objects, for more info see:
2072 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2073
2074 =cut
2075
2076 sub update {
2077   my ($self, $values) = @_;
2078   $self->throw_exception('Values for update must be a hash')
2079     unless ref $values eq 'HASH';
2080
2081   return $self->_rs_update_delete ('update', $values);
2082 }
2083
2084 =head2 update_all
2085
2086 =over 4
2087
2088 =item Arguments: \%values
2089
2090 =item Return Value: 1
2091
2092 =back
2093
2094 Fetches all objects and updates them one at a time via
2095 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2096 triggers, while L</update> will not.
2097
2098 =cut
2099
2100 sub update_all {
2101   my ($self, $values) = @_;
2102   $self->throw_exception('Values for update_all must be a hash')
2103     unless ref $values eq 'HASH';
2104
2105   my $guard = $self->result_source->schema->txn_scope_guard;
2106   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2107   $guard->commit;
2108   return 1;
2109 }
2110
2111 =head2 delete
2112
2113 =over 4
2114
2115 =item Arguments: none
2116
2117 =item Return Value: $underlying_storage_rv
2118
2119 =back
2120
2121 Deletes the rows matching this resultset in a single query. Note that this
2122 will not run any delete triggers, nor will it alter the
2123 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2124 derived from this resultset (this includes the contents of the
2125 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2126 execute any on-delete triggers or cascades defined either by you or a
2127 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2128
2129 The return value is a pass through of what the underlying storage backend
2130 returned, and may vary. See L<DBI/execute> for the most common case.
2131
2132 =cut
2133
2134 sub delete {
2135   my $self = shift;
2136   $self->throw_exception('delete does not accept any arguments')
2137     if @_;
2138
2139   return $self->_rs_update_delete ('delete');
2140 }
2141
2142 =head2 delete_all
2143
2144 =over 4
2145
2146 =item Arguments: none
2147
2148 =item Return Value: 1
2149
2150 =back
2151
2152 Fetches all objects and deletes them one at a time via
2153 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2154 triggers, while L</delete> will not.
2155
2156 =cut
2157
2158 sub delete_all {
2159   my $self = shift;
2160   $self->throw_exception('delete_all does not accept any arguments')
2161     if @_;
2162
2163   my $guard = $self->result_source->schema->txn_scope_guard;
2164   $_->delete for $self->all;
2165   $guard->commit;
2166   return 1;
2167 }
2168
2169 =head2 populate
2170
2171 =over 4
2172
2173 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2174
2175 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2176
2177 =back
2178
2179 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2180 arrayrefs.
2181
2182 =over
2183
2184 =item NOTE
2185
2186 The context of this method call has an important effect on what is
2187 submitted to storage. In void context data is fed directly to fastpath
2188 insertion routines provided by the underlying storage (most often
2189 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2190 L<insert|DBIx::Class::Row/insert> calls on the
2191 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2192 augmentation of these methods provided by components. For example if you
2193 are using something like L<DBIx::Class::UUIDColumns> to create primary
2194 keys for you, you will find that your PKs are empty.  In this case you
2195 will have to explicitly force scalar or list context in order to create
2196 those values.
2197
2198 =back
2199
2200 In non-void (scalar or list) context, this method is simply a wrapper
2201 for L</create>. Depending on list or scalar context either a list of
2202 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2203 containing these objects is returned.
2204
2205 When supplying data in "arrayref of arrayrefs" invocation style, the
2206 first element should be a list of column names and each subsequent
2207 element should be a data value in the earlier specified column order.
2208 For example:
2209
2210   $schema->resultset("Artist")->populate([
2211     [ qw( artistid name ) ],
2212     [ 100, 'A Formally Unknown Singer' ],
2213     [ 101, 'A singer that jumped the shark two albums ago' ],
2214     [ 102, 'An actually cool singer' ],
2215   ]);
2216
2217 For the arrayref of hashrefs style each hashref should be a structure
2218 suitable for passing to L</create>. Multi-create is also permitted with
2219 this syntax.
2220
2221   $schema->resultset("Artist")->populate([
2222      { artistid => 4, name => 'Manufactured Crap', cds => [
2223         { title => 'My First CD', year => 2006 },
2224         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2225       ],
2226      },
2227      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2228         { title => 'My parents sold me to a record company', year => 2005 },
2229         { title => 'Why Am I So Ugly?', year => 2006 },
2230         { title => 'I Got Surgery and am now Popular', year => 2007 }
2231       ],
2232      },
2233   ]);
2234
2235 If you attempt a void-context multi-create as in the example above (each
2236 Artist also has the related list of CDs), and B<do not> supply the
2237 necessary autoinc foreign key information, this method will proxy to the
2238 less efficient L</create>, and then throw the Result objects away. In this
2239 case there are obviously no benefits to using this method over L</create>.
2240
2241 =cut
2242
2243 sub populate {
2244   my $self = shift;
2245
2246   my ($data, $guard);
2247
2248   # this is naive and just a quick check
2249   # the types will need to be checked more thoroughly when the
2250   # multi-source populate gets added
2251   if (ref $_[0] eq 'ARRAY') {
2252     return unless @{$_[0]};
2253
2254     $data = $_[0] if (ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY');
2255   }
2256
2257   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs')
2258     unless $data;
2259
2260   # FIXME - no cref handling
2261   # At this point assume either hashes or arrays
2262
2263   if(defined wantarray) {
2264     my @results;
2265
2266     $guard = $self->result_source->schema->storage->txn_scope_guard
2267       if ( @$data > 2 or ( @$data == 2 and ref $data->[0] eq 'ARRAY' ) );
2268
2269     if (ref $data->[0] eq 'ARRAY') {
2270       @results = map
2271         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2272         @{$data}[1 .. $#$data]
2273       ;
2274     }
2275     else {
2276       @results = map { $self->new_result($_)->insert } @$data;
2277     }
2278
2279     $guard->commit if $guard;
2280     return wantarray ? @results : \@results;
2281   }
2282
2283   # we have to deal with *possibly incomplete* related data
2284   # this means we have to walk the data structure twice
2285   # whether we want this or not
2286   # jnap, I hate you ;)
2287   my $rsrc = $self->result_source;
2288   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2289
2290   my ($colinfo, $colnames, $slices_with_rels);
2291   my $data_start = 0;
2292
2293   DATA_SLICE:
2294   for my $i (0 .. $#$data) {
2295
2296     my $current_slice_seen_rel_infos;
2297
2298 ### Determine/Supplement collists
2299 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2300     if( ref $data->[$i] eq 'ARRAY' ) {
2301
2302       # positional(!) explicit column list
2303       if ($i == 0) {
2304
2305         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2306           for 0 .. $#{$data->[0]};
2307
2308         $data_start = 1;
2309
2310         next DATA_SLICE;
2311       }
2312       else {
2313         for (values %$colinfo) {
2314           if ($_->{is_rel} ||= (
2315             $rel_info->{$_->{name}}
2316               and
2317             (
2318               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2319                 or
2320               ref $data->[$i][$_->{pos}] eq 'HASH'
2321                 or
2322               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2323             )
2324               and
2325             1
2326           )) {
2327
2328             # moar sanity check... sigh
2329             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2330               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2331                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2332                 return my $throwaway = $self->populate(@_);
2333               }
2334             }
2335
2336             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2337           }
2338         }
2339       }
2340
2341      if ($current_slice_seen_rel_infos) {
2342         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2343
2344         # this is needed further down to decide whether or not to fallback to create()
2345         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2346           for 0 .. $#$colnames;
2347       }
2348     }
2349     elsif( ref $data->[$i] eq 'HASH' ) {
2350
2351       for ( sort keys %{$data->[$i]} ) {
2352
2353         $colinfo->{$_} ||= do {
2354
2355           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2356             if $data_start; # it will be 0 on AoH, 1 on AoA
2357
2358           push @$colnames, $_;
2359
2360           # RV
2361           { pos => $#$colnames, name => $_ }
2362         };
2363
2364         if ($colinfo->{$_}{is_rel} ||= (
2365           $rel_info->{$_}
2366             and
2367           (
2368             ref $data->[$i]{$_} eq 'ARRAY'
2369               or
2370             ref $data->[$i]{$_} eq 'HASH'
2371               or
2372             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2373           )
2374             and
2375           1
2376         )) {
2377
2378           # moar sanity check... sigh
2379           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2380             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2381               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2382               return my $throwaway = $self->populate(@_);
2383             }
2384           }
2385
2386           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2387         }
2388       }
2389
2390       if ($current_slice_seen_rel_infos) {
2391         push @$slices_with_rels, $data->[$i];
2392
2393         # this is needed further down to decide whether or not to fallback to create()
2394         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2395           for keys %{$data->[$i]};
2396       }
2397     }
2398     else {
2399       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2400     }
2401
2402     if ( grep
2403       { $_->{attrs}{is_depends_on} }
2404       @{ $current_slice_seen_rel_infos || [] }
2405     ) {
2406       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2407       return my $throwaway = $self->populate(@_);
2408     }
2409   }
2410
2411   if( $slices_with_rels ) {
2412
2413     # need to exclude the rel "columns"
2414     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2415
2416     # extra sanity check - ensure the main source is in fact identifiable
2417     # the localizing of nullability is insane, but oh well... the use-case is legit
2418     my $ci = $rsrc->columns_info($colnames);
2419
2420     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2421       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2422
2423     unless( $rsrc->_identifying_column_set($ci) ) {
2424       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2425       return my $throwaway = $self->populate(@_);
2426     }
2427   }
2428
2429 ### inherit the data locked in the conditions of the resultset
2430   my ($rs_data) = $self->_merge_with_rscond({});
2431   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2432
2433   # if anything left - decompose rs_data
2434   my $rs_data_vals;
2435   if (keys %$rs_data) {
2436      push @$rs_data_vals, $rs_data->{$_}
2437       for sort keys %$rs_data;
2438   }
2439
2440 ### start work
2441   $guard = $rsrc->schema->storage->txn_scope_guard
2442     if $slices_with_rels;
2443
2444 ### main source data
2445   # FIXME - need to switch entirely to a coderef-based thing,
2446   # so that large sets aren't copied several times... I think
2447   $rsrc->storage->insert_bulk(
2448     $rsrc,
2449     [ @$colnames, sort keys %$rs_data ],
2450     [ map {
2451       ref $data->[$_] eq 'ARRAY'
2452       ? (
2453           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2454         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2455         :                     $data->[$_]
2456       )
2457       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2458     } $data_start .. $#$data ],
2459   );
2460
2461 ### do the children relationships
2462   if ( $slices_with_rels ) {
2463     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2464       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2465
2466     for my $sl (@$slices_with_rels) {
2467
2468       my ($main_proto, $main_proto_rs);
2469       for my $rel (@rels) {
2470         next unless defined $sl->{$rel};
2471
2472         $main_proto ||= {
2473           %$rs_data,
2474           (map { $_ => $sl->{$_} } @$colnames),
2475         };
2476
2477         unless (defined $colinfo->{$rel}{rs}) {
2478
2479           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2480
2481           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2482             rel_name => $rel,
2483             self_alias => "\xFE", # irrelevant
2484             foreign_alias => "\xFF", # irrelevant
2485           )->{identity_map} || {} } };
2486
2487         }
2488
2489         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2490           {
2491             $_ => { '=' =>
2492               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2493                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2494                  ->as_query
2495             }
2496           }
2497           keys %{$colinfo->{$rel}{fk_map}}
2498         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2499
2500         1;
2501       }
2502     }
2503   }
2504
2505   $guard->commit if $guard;
2506 }
2507
2508 =head2 pager
2509
2510 =over 4
2511
2512 =item Arguments: none
2513
2514 =item Return Value: L<$pager|Data::Page>
2515
2516 =back
2517
2518 Returns a L<Data::Page> object for the current resultset. Only makes
2519 sense for queries with a C<page> attribute.
2520
2521 To get the full count of entries for a paged resultset, call
2522 C<total_entries> on the L<Data::Page> object.
2523
2524 =cut
2525
2526 sub pager {
2527   my ($self) = @_;
2528
2529   return $self->{pager} if $self->{pager};
2530
2531   my $attrs = $self->{attrs};
2532   if (!defined $attrs->{page}) {
2533     $self->throw_exception("Can't create pager for non-paged rs");
2534   }
2535   elsif ($attrs->{page} <= 0) {
2536     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2537   }
2538   $attrs->{rows} ||= 10;
2539
2540   # throw away the paging flags and re-run the count (possibly
2541   # with a subselect) to get the real total count
2542   my $count_attrs = { %$attrs };
2543   delete @{$count_attrs}{qw/rows offset page pager/};
2544
2545   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2546
2547   require DBIx::Class::ResultSet::Pager;
2548   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2549     sub { $total_rs->count },  #lazy-get the total
2550     $attrs->{rows},
2551     $self->{attrs}{page},
2552   );
2553 }
2554
2555 =head2 page
2556
2557 =over 4
2558
2559 =item Arguments: $page_number
2560
2561 =item Return Value: L<$resultset|/search>
2562
2563 =back
2564
2565 Returns a resultset for the $page_number page of the resultset on which page
2566 is called, where each page contains a number of rows equal to the 'rows'
2567 attribute set on the resultset (10 by default).
2568
2569 =cut
2570
2571 sub page {
2572   my ($self, $page) = @_;
2573   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2574 }
2575
2576 =head2 new_result
2577
2578 =over 4
2579
2580 =item Arguments: \%col_data
2581
2582 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2583
2584 =back
2585
2586 Creates a new result object in the resultset's result class and returns
2587 it. The row is not inserted into the database at this point, call
2588 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2589 will tell you whether the result object has been inserted or not.
2590
2591 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2592
2593 =cut
2594
2595 sub new_result {
2596   my ($self, $values) = @_;
2597
2598   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2599     if @_ > 2;
2600
2601   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2602     unless (ref $values eq 'HASH');
2603
2604   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2605
2606   my $new = $self->result_class->new({
2607     %$merged_cond,
2608     ( @$cols_from_relations
2609       ? (-cols_from_relations => $cols_from_relations)
2610       : ()
2611     ),
2612     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2613   });
2614
2615   if (
2616     reftype($new) eq 'HASH'
2617       and
2618     ! keys %$new
2619       and
2620     blessed($new)
2621   ) {
2622     carp_unique (sprintf (
2623       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2624       $self->result_class,
2625     ));
2626   }
2627
2628   $new;
2629 }
2630
2631 # _merge_with_rscond
2632 #
2633 # Takes a simple hash of K/V data and returns its copy merged with the
2634 # condition already present on the resultset. Additionally returns an
2635 # arrayref of value/condition names, which were inferred from related
2636 # objects (this is needed for in-memory related objects)
2637 sub _merge_with_rscond {
2638   my ($self, $data) = @_;
2639
2640   my ($implied_data, @cols_from_relations);
2641
2642   my $alias = $self->{attrs}{alias};
2643
2644   if (! defined $self->{cond}) {
2645     # just massage $data below
2646   }
2647   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2648     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2649     @cols_from_relations = keys %{ $implied_data || {} };
2650   }
2651   else {
2652     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2653     $implied_data = { map {
2654       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2655     } keys %$eqs };
2656   }
2657
2658   return (
2659     { map
2660       { %{ $self->_remove_alias($_, $alias) } }
2661       # precedence must be given to passed values over values inherited from
2662       # the cond, so the order here is important.
2663       ( $implied_data||(), $data)
2664     },
2665     \@cols_from_relations
2666   );
2667 }
2668
2669 # _has_resolved_attr
2670 #
2671 # determines if the resultset defines at least one
2672 # of the attributes supplied
2673 #
2674 # used to determine if a subquery is necessary
2675 #
2676 # supports some virtual attributes:
2677 #   -join
2678 #     This will scan for any joins being present on the resultset.
2679 #     It is not a mere key-search but a deep inspection of {from}
2680 #
2681
2682 sub _has_resolved_attr {
2683   my ($self, @attr_names) = @_;
2684
2685   my $attrs = $self->_resolved_attrs;
2686
2687   my %extra_checks;
2688
2689   for my $n (@attr_names) {
2690     if (grep { $n eq $_ } (qw/-join/) ) {
2691       $extra_checks{$n}++;
2692       next;
2693     }
2694
2695     my $attr =  $attrs->{$n};
2696
2697     next if not defined $attr;
2698
2699     if (ref $attr eq 'HASH') {
2700       return 1 if keys %$attr;
2701     }
2702     elsif (ref $attr eq 'ARRAY') {
2703       return 1 if @$attr;
2704     }
2705     else {
2706       return 1 if $attr;
2707     }
2708   }
2709
2710   # a resolved join is expressed as a multi-level from
2711   return 1 if (
2712     $extra_checks{-join}
2713       and
2714     ref $attrs->{from} eq 'ARRAY'
2715       and
2716     @{$attrs->{from}} > 1
2717   );
2718
2719   return 0;
2720 }
2721
2722 # _remove_alias
2723 #
2724 # Remove the specified alias from the specified query hash. A copy is made so
2725 # the original query is not modified.
2726
2727 sub _remove_alias {
2728   my ($self, $query, $alias) = @_;
2729
2730   my %orig = %{ $query || {} };
2731   my %unaliased;
2732
2733   foreach my $key (keys %orig) {
2734     if ($key !~ /\./) {
2735       $unaliased{$key} = $orig{$key};
2736       next;
2737     }
2738     $unaliased{$1} = $orig{$key}
2739       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2740   }
2741
2742   return \%unaliased;
2743 }
2744
2745 =head2 as_query
2746
2747 =over 4
2748
2749 =item Arguments: none
2750
2751 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2752
2753 =back
2754
2755 Returns the SQL query and bind vars associated with the invocant.
2756
2757 This is generally used as the RHS for a subquery.
2758
2759 =cut
2760
2761 sub as_query {
2762   my $self = shift;
2763
2764   my $attrs = { %{ $self->_resolved_attrs } };
2765
2766   my $aq = $self->result_source->storage->_select_args_to_query (
2767     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2768   );
2769
2770   $aq;
2771 }
2772
2773 =head2 find_or_new
2774
2775 =over 4
2776
2777 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2778
2779 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2780
2781 =back
2782
2783   my $artist = $schema->resultset('Artist')->find_or_new(
2784     { artist => 'fred' }, { key => 'artists' });
2785
2786   $cd->cd_to_producer->find_or_new({ producer => $producer },
2787                                    { key => 'primary' });
2788
2789 Find an existing record from this resultset using L</find>. if none exists,
2790 instantiate a new result object and return it. The object will not be saved
2791 into your storage until you call L<DBIx::Class::Row/insert> on it.
2792
2793 You most likely want this method when looking for existing rows using a unique
2794 constraint that is not the primary key, or looking for related rows.
2795
2796 If you want objects to be saved immediately, use L</find_or_create> instead.
2797
2798 B<Note>: Make sure to read the documentation of L</find> and understand the
2799 significance of the C<key> attribute, as its lack may skew your search, and
2800 subsequently result in spurious new objects.
2801
2802 B<Note>: Take care when using C<find_or_new> with a table having
2803 columns with default values that you intend to be automatically
2804 supplied by the database (e.g. an auto_increment primary key column).
2805 In normal usage, the value of such columns should NOT be included at
2806 all in the call to C<find_or_new>, even when set to C<undef>.
2807
2808 =cut
2809
2810 sub find_or_new {
2811   my $self     = shift;
2812   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2813   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2814   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2815     return $row;
2816   }
2817   return $self->new_result($hash);
2818 }
2819
2820 =head2 create
2821
2822 =over 4
2823
2824 =item Arguments: \%col_data
2825
2826 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2827
2828 =back
2829
2830 Attempt to create a single new row or a row with multiple related rows
2831 in the table represented by the resultset (and related tables). This
2832 will not check for duplicate rows before inserting, use
2833 L</find_or_create> to do that.
2834
2835 To create one row for this resultset, pass a hashref of key/value
2836 pairs representing the columns of the table and the values you wish to
2837 store. If the appropriate relationships are set up, foreign key fields
2838 can also be passed an object representing the foreign row, and the
2839 value will be set to its primary key.
2840
2841 To create related objects, pass a hashref of related-object column values
2842 B<keyed on the relationship name>. If the relationship is of type C<multi>
2843 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2844 The process will correctly identify columns holding foreign keys, and will
2845 transparently populate them from the keys of the corresponding relation.
2846 This can be applied recursively, and will work correctly for a structure
2847 with an arbitrary depth and width, as long as the relationships actually
2848 exists and the correct column data has been supplied.
2849
2850 Instead of hashrefs of plain related data (key/value pairs), you may
2851 also pass new or inserted objects. New objects (not inserted yet, see
2852 L</new_result>), will be inserted into their appropriate tables.
2853
2854 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2855
2856 Example of creating a new row.
2857
2858   $person_rs->create({
2859     name=>"Some Person",
2860     email=>"somebody@someplace.com"
2861   });
2862
2863 Example of creating a new row and also creating rows in a related C<has_many>
2864 or C<has_one> resultset.  Note Arrayref.
2865
2866   $artist_rs->create(
2867      { artistid => 4, name => 'Manufactured Crap', cds => [
2868         { title => 'My First CD', year => 2006 },
2869         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2870       ],
2871      },
2872   );
2873
2874 Example of creating a new row and also creating a row in a related
2875 C<belongs_to> resultset. Note Hashref.
2876
2877   $cd_rs->create({
2878     title=>"Music for Silly Walks",
2879     year=>2000,
2880     artist => {
2881       name=>"Silly Musician",
2882     }
2883   });
2884
2885 =over
2886
2887 =item WARNING
2888
2889 When subclassing ResultSet never attempt to override this method. Since
2890 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2891 lot of the internals simply never call it, so your override will be
2892 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2893 or L<DBIx::Class::Row/insert> depending on how early in the
2894 L</create> process you need to intervene. See also warning pertaining to
2895 L</new>.
2896
2897 =back
2898
2899 =cut
2900
2901 sub create {
2902   #my ($self, $col_data) = @_;
2903   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2904   return shift->new_result(shift)->insert;
2905 }
2906
2907 =head2 find_or_create
2908
2909 =over 4
2910
2911 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2912
2913 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2914
2915 =back
2916
2917   $cd->cd_to_producer->find_or_create({ producer => $producer },
2918                                       { key => 'primary' });
2919
2920 Tries to find a record based on its primary key or unique constraints; if none
2921 is found, creates one and returns that instead.
2922
2923   my $cd = $schema->resultset('CD')->find_or_create({
2924     cdid   => 5,
2925     artist => 'Massive Attack',
2926     title  => 'Mezzanine',
2927     year   => 2005,
2928   });
2929
2930 Also takes an optional C<key> attribute, to search by a specific key or unique
2931 constraint. For example:
2932
2933   my $cd = $schema->resultset('CD')->find_or_create(
2934     {
2935       artist => 'Massive Attack',
2936       title  => 'Mezzanine',
2937     },
2938     { key => 'cd_artist_title' }
2939   );
2940
2941 B<Note>: Make sure to read the documentation of L</find> and understand the
2942 significance of the C<key> attribute, as its lack may skew your search, and
2943 subsequently result in spurious row creation.
2944
2945 B<Note>: Because find_or_create() reads from the database and then
2946 possibly inserts based on the result, this method is subject to a race
2947 condition. Another process could create a record in the table after
2948 the find has completed and before the create has started. To avoid
2949 this problem, use find_or_create() inside a transaction.
2950
2951 B<Note>: Take care when using C<find_or_create> with a table having
2952 columns with default values that you intend to be automatically
2953 supplied by the database (e.g. an auto_increment primary key column).
2954 In normal usage, the value of such columns should NOT be included at
2955 all in the call to C<find_or_create>, even when set to C<undef>.
2956
2957 See also L</find> and L</update_or_create>. For information on how to declare
2958 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2959
2960 If you need to know if an existing row was found or a new one created use
2961 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2962 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2963 database!
2964
2965   my $cd = $schema->resultset('CD')->find_or_new({
2966     cdid   => 5,
2967     artist => 'Massive Attack',
2968     title  => 'Mezzanine',
2969     year   => 2005,
2970   });
2971
2972   if( !$cd->in_storage ) {
2973       # do some stuff
2974       $cd->insert;
2975   }
2976
2977 =cut
2978
2979 sub find_or_create {
2980   my $self     = shift;
2981   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2982   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2983   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2984     return $row;
2985   }
2986   return $self->new_result($hash)->insert;
2987 }
2988
2989 =head2 update_or_create
2990
2991 =over 4
2992
2993 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2994
2995 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2996
2997 =back
2998
2999   $resultset->update_or_create({ col => $val, ... });
3000
3001 Like L</find_or_create>, but if a row is found it is immediately updated via
3002 C<< $found_row->update (\%col_data) >>.
3003
3004
3005 Takes an optional C<key> attribute to search on a specific unique constraint.
3006 For example:
3007
3008   # In your application
3009   my $cd = $schema->resultset('CD')->update_or_create(
3010     {
3011       artist => 'Massive Attack',
3012       title  => 'Mezzanine',
3013       year   => 1998,
3014     },
3015     { key => 'cd_artist_title' }
3016   );
3017
3018   $cd->cd_to_producer->update_or_create({
3019     producer => $producer,
3020     name => 'harry',
3021   }, {
3022     key => 'primary',
3023   });
3024
3025 B<Note>: Make sure to read the documentation of L</find> and understand the
3026 significance of the C<key> attribute, as its lack may skew your search, and
3027 subsequently result in spurious row creation.
3028
3029 B<Note>: Take care when using C<update_or_create> with a table having
3030 columns with default values that you intend to be automatically
3031 supplied by the database (e.g. an auto_increment primary key column).
3032 In normal usage, the value of such columns should NOT be included at
3033 all in the call to C<update_or_create>, even when set to C<undef>.
3034
3035 See also L</find> and L</find_or_create>. For information on how to declare
3036 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3037
3038 If you need to know if an existing row was updated or a new one created use
3039 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3040 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3041 database!
3042
3043 =cut
3044
3045 sub update_or_create {
3046   my $self = shift;
3047   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3048   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3049
3050   my $row = $self->find($cond, $attrs);
3051   if (defined $row) {
3052     $row->update($cond);
3053     return $row;
3054   }
3055
3056   return $self->new_result($cond)->insert;
3057 }
3058
3059 =head2 update_or_new
3060
3061 =over 4
3062
3063 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3064
3065 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3066
3067 =back
3068
3069   $resultset->update_or_new({ col => $val, ... });
3070
3071 Like L</find_or_new> but if a row is found it is immediately updated via
3072 C<< $found_row->update (\%col_data) >>.
3073
3074 For example:
3075
3076   # In your application
3077   my $cd = $schema->resultset('CD')->update_or_new(
3078     {
3079       artist => 'Massive Attack',
3080       title  => 'Mezzanine',
3081       year   => 1998,
3082     },
3083     { key => 'cd_artist_title' }
3084   );
3085
3086   if ($cd->in_storage) {
3087       # the cd was updated
3088   }
3089   else {
3090       # the cd is not yet in the database, let's insert it
3091       $cd->insert;
3092   }
3093
3094 B<Note>: Make sure to read the documentation of L</find> and understand the
3095 significance of the C<key> attribute, as its lack may skew your search, and
3096 subsequently result in spurious new objects.
3097
3098 B<Note>: Take care when using C<update_or_new> with a table having
3099 columns with default values that you intend to be automatically
3100 supplied by the database (e.g. an auto_increment primary key column).
3101 In normal usage, the value of such columns should NOT be included at
3102 all in the call to C<update_or_new>, even when set to C<undef>.
3103
3104 See also L</find>, L</find_or_create> and L</find_or_new>.
3105
3106 =cut
3107
3108 sub update_or_new {
3109     my $self  = shift;
3110     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3111     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3112
3113     my $row = $self->find( $cond, $attrs );
3114     if ( defined $row ) {
3115         $row->update($cond);
3116         return $row;
3117     }
3118
3119     return $self->new_result($cond);
3120 }
3121
3122 =head2 get_cache
3123
3124 =over 4
3125
3126 =item Arguments: none
3127
3128 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3129
3130 =back
3131
3132 Gets the contents of the cache for the resultset, if the cache is set.
3133
3134 The cache is populated either by using the L</prefetch> attribute to
3135 L</search> or by calling L</set_cache>.
3136
3137 =cut
3138
3139 sub get_cache {
3140   shift->{all_cache};
3141 }
3142
3143 =head2 set_cache
3144
3145 =over 4
3146
3147 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3148
3149 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3150
3151 =back
3152
3153 Sets the contents of the cache for the resultset. Expects an arrayref
3154 of objects of the same class as those produced by the resultset. Note that
3155 if the cache is set, the resultset will return the cached objects rather
3156 than re-querying the database even if the cache attr is not set.
3157
3158 The contents of the cache can also be populated by using the
3159 L</prefetch> attribute to L</search>.
3160
3161 =cut
3162
3163 sub set_cache {
3164   my ( $self, $data ) = @_;
3165   $self->throw_exception("set_cache requires an arrayref")
3166       if defined($data) && (ref $data ne 'ARRAY');
3167   $self->{all_cache} = $data;
3168 }
3169
3170 =head2 clear_cache
3171
3172 =over 4
3173
3174 =item Arguments: none
3175
3176 =item Return Value: undef
3177
3178 =back
3179
3180 Clears the cache for the resultset.
3181
3182 =cut
3183
3184 sub clear_cache {
3185   shift->set_cache(undef);
3186 }
3187
3188 =head2 is_paged
3189
3190 =over 4
3191
3192 =item Arguments: none
3193
3194 =item Return Value: true, if the resultset has been paginated
3195
3196 =back
3197
3198 =cut
3199
3200 sub is_paged {
3201   my ($self) = @_;
3202   return !!$self->{attrs}{page};
3203 }
3204
3205 =head2 is_ordered
3206
3207 =over 4
3208
3209 =item Arguments: none
3210
3211 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3212
3213 =back
3214
3215 =cut
3216
3217 sub is_ordered {
3218   my ($self) = @_;
3219   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3220 }
3221
3222 =head2 related_resultset
3223
3224 =over 4
3225
3226 =item Arguments: $rel_name
3227
3228 =item Return Value: L<$resultset|/search>
3229
3230 =back
3231
3232 Returns a related resultset for the supplied relationship name.
3233
3234   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3235
3236 =cut
3237
3238 sub related_resultset {
3239   my ($self, $rel) = @_;
3240
3241   return $self->{related_resultsets}{$rel}
3242     if defined $self->{related_resultsets}{$rel};
3243
3244   return $self->{related_resultsets}{$rel} = do {
3245     my $rsrc = $self->result_source;
3246     my $rel_info = $rsrc->relationship_info($rel);
3247
3248     $self->throw_exception(
3249       "search_related: result source '" . $rsrc->source_name .
3250         "' has no such relationship $rel")
3251       unless $rel_info;
3252
3253     my $attrs = $self->_chain_relationship($rel);
3254
3255     my $join_count = $attrs->{seen_join}{$rel};
3256
3257     my $alias = $self->result_source->storage
3258         ->relname_to_table_alias($rel, $join_count);
3259
3260     # since this is search_related, and we already slid the select window inwards
3261     # (the select/as attrs were deleted in the beginning), we need to flip all
3262     # left joins to inner, so we get the expected results
3263     # read the comment on top of the actual function to see what this does
3264     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3265
3266
3267     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3268     delete @{$attrs}{qw(result_class alias)};
3269
3270     my $rel_source = $rsrc->related_source($rel);
3271
3272     my $new = do {
3273
3274       # The reason we do this now instead of passing the alias to the
3275       # search_rs below is that if you wrap/overload resultset on the
3276       # source you need to know what alias it's -going- to have for things
3277       # to work sanely (e.g. RestrictWithObject wants to be able to add
3278       # extra query restrictions, and these may need to be $alias.)
3279
3280       my $rel_attrs = $rel_source->resultset_attributes;
3281       local $rel_attrs->{alias} = $alias;
3282
3283       $rel_source->resultset
3284                  ->search_rs(
3285                      undef, {
3286                        %$attrs,
3287                        where => $attrs->{where},
3288                    });
3289     };
3290
3291     if (my $cache = $self->get_cache) {
3292       my @related_cache = map
3293         { $_->related_resultset($rel)->get_cache || () }
3294         @$cache
3295       ;
3296
3297       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3298     }
3299
3300     $new;
3301   };
3302 }
3303
3304 =head2 current_source_alias
3305
3306 =over 4
3307
3308 =item Arguments: none
3309
3310 =item Return Value: $source_alias
3311
3312 =back
3313
3314 Returns the current table alias for the result source this resultset is built
3315 on, that will be used in the SQL query. Usually it is C<me>.
3316
3317 Currently the source alias that refers to the result set returned by a
3318 L</search>/L</find> family method depends on how you got to the resultset: it's
3319 C<me> by default, but eg. L</search_related> aliases it to the related result
3320 source name (and keeps C<me> referring to the original result set). The long
3321 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3322 (and make this method unnecessary).
3323
3324 Thus it's currently necessary to use this method in predefined queries (see
3325 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3326 source alias of the current result set:
3327
3328   # in a result set class
3329   sub modified_by {
3330     my ($self, $user) = @_;
3331
3332     my $me = $self->current_source_alias;
3333
3334     return $self->search({
3335       "$me.modified" => $user->id,
3336     });
3337   }
3338
3339 =cut
3340
3341 sub current_source_alias {
3342   return (shift->{attrs} || {})->{alias} || 'me';
3343 }
3344
3345 =head2 as_subselect_rs
3346
3347 =over 4
3348
3349 =item Arguments: none
3350
3351 =item Return Value: L<$resultset|/search>
3352
3353 =back
3354
3355 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3356 "virtual view" by including it as a subquery within the from clause.  From this
3357 point on, any joined tables are inaccessible to ->search on the resultset (as if
3358 it were simply where-filtered without joins).  For example:
3359
3360  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3361
3362  # 'x' now pollutes the query namespace
3363
3364  # So the following works as expected
3365  my $ok_rs = $rs->search({'x.other' => 1});
3366
3367  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3368  # def) we look for one row with contradictory terms and join in another table
3369  # (aliased 'x_2') which we never use
3370  my $broken_rs = $rs->search({'x.name' => 'def'});
3371
3372  my $rs2 = $rs->as_subselect_rs;
3373
3374  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3375  my $not_joined_rs = $rs2->search({'x.other' => 1});
3376
3377  # works as expected: finds a 'table' row related to two x rows (abc and def)
3378  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3379
3380 Another example of when one might use this would be to select a subset of
3381 columns in a group by clause:
3382
3383  my $rs = $schema->resultset('Bar')->search(undef, {
3384    group_by => [qw{ id foo_id baz_id }],
3385  })->as_subselect_rs->search(undef, {
3386    columns => [qw{ id foo_id }]
3387  });
3388
3389 In the above example normally columns would have to be equal to the group by,
3390 but because we isolated the group by into a subselect the above works.
3391
3392 =cut
3393
3394 sub as_subselect_rs {
3395   my $self = shift;
3396
3397   my $attrs = $self->_resolved_attrs;
3398
3399   my $fresh_rs = (ref $self)->new (
3400     $self->result_source
3401   );
3402
3403   # these pieces will be locked in the subquery
3404   delete $fresh_rs->{cond};
3405   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3406
3407   return $fresh_rs->search( {}, {
3408     from => [{
3409       $attrs->{alias} => $self->as_query,
3410       -alias  => $attrs->{alias},
3411       -rsrc   => $self->result_source,
3412     }],
3413     alias => $attrs->{alias},
3414   });
3415 }
3416
3417 # This code is called by search_related, and makes sure there
3418 # is clear separation between the joins before, during, and
3419 # after the relationship. This information is needed later
3420 # in order to properly resolve prefetch aliases (any alias
3421 # with a relation_chain_depth less than the depth of the
3422 # current prefetch is not considered)
3423 #
3424 # The increments happen twice per join. An even number means a
3425 # relationship specified via a search_related, whereas an odd
3426 # number indicates a join/prefetch added via attributes
3427 #
3428 # Also this code will wrap the current resultset (the one we
3429 # chain to) in a subselect IFF it contains limiting attributes
3430 sub _chain_relationship {
3431   my ($self, $rel) = @_;
3432   my $source = $self->result_source;
3433   my $attrs = { %{$self->{attrs}||{}} };
3434
3435   # we need to take the prefetch the attrs into account before we
3436   # ->_resolve_join as otherwise they get lost - captainL
3437   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3438
3439   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3440
3441   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3442
3443   my $from;
3444   my @force_subq_attrs = qw/offset rows group_by having/;
3445
3446   if (
3447     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3448       ||
3449     $self->_has_resolved_attr (@force_subq_attrs)
3450   ) {
3451     # Nuke the prefetch (if any) before the new $rs attrs
3452     # are resolved (prefetch is useless - we are wrapping
3453     # a subquery anyway).
3454     my $rs_copy = $self->search;
3455     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3456       $rs_copy->{attrs}{join},
3457       delete $rs_copy->{attrs}{prefetch},
3458     );
3459
3460     $from = [{
3461       -rsrc   => $source,
3462       -alias  => $attrs->{alias},
3463       $attrs->{alias} => $rs_copy->as_query,
3464     }];
3465     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3466     $seen->{-relation_chain_depth} = 0;
3467   }
3468   elsif ($attrs->{from}) {  #shallow copy suffices
3469     $from = [ @{$attrs->{from}} ];
3470   }
3471   else {
3472     $from = [{
3473       -rsrc  => $source,
3474       -alias => $attrs->{alias},
3475       $attrs->{alias} => $source->from,
3476     }];
3477   }
3478
3479   my $jpath = ($seen->{-relation_chain_depth})
3480     ? $from->[-1][0]{-join_path}
3481     : [];
3482
3483   my @requested_joins = $source->_resolve_join(
3484     $join,
3485     $attrs->{alias},
3486     $seen,
3487     $jpath,
3488   );
3489
3490   push @$from, @requested_joins;
3491
3492   $seen->{-relation_chain_depth}++;
3493
3494   # if $self already had a join/prefetch specified on it, the requested
3495   # $rel might very well be already included. What we do in this case
3496   # is effectively a no-op (except that we bump up the chain_depth on
3497   # the join in question so we could tell it *is* the search_related)
3498   my $already_joined;
3499
3500   # we consider the last one thus reverse
3501   for my $j (reverse @requested_joins) {
3502     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3503     if ($rel eq $last_j) {
3504       $j->[0]{-relation_chain_depth}++;
3505       $already_joined++;
3506       last;
3507     }
3508   }
3509
3510   unless ($already_joined) {
3511     push @$from, $source->_resolve_join(
3512       $rel,
3513       $attrs->{alias},
3514       $seen,
3515       $jpath,
3516     );
3517   }
3518
3519   $seen->{-relation_chain_depth}++;
3520
3521   return {%$attrs, from => $from, seen_join => $seen};
3522 }
3523
3524 sub _resolved_attrs {
3525   my $self = shift;
3526   return $self->{_attrs} if $self->{_attrs};
3527
3528   my $attrs  = { %{ $self->{attrs} || {} } };
3529   my $source = $attrs->{result_source} = $self->result_source;
3530   my $alias  = $attrs->{alias};
3531
3532   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3533     if $attrs->{collapse} and $attrs->{distinct};
3534
3535   # default selection list
3536   $attrs->{columns} = [ $source->columns ]
3537     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3538
3539   # merge selectors together
3540   for (qw/columns select as/) {
3541     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3542       if $attrs->{$_} or $attrs->{"+$_"};
3543   }
3544
3545   # disassemble columns
3546   my (@sel, @as);
3547   if (my $cols = delete $attrs->{columns}) {
3548     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3549       if (ref $c eq 'HASH') {
3550         for my $as (sort keys %$c) {
3551           push @sel, $c->{$as};
3552           push @as, $as;
3553         }
3554       }
3555       else {
3556         push @sel, $c;
3557         push @as, $c;
3558       }
3559     }
3560   }
3561
3562   # when trying to weed off duplicates later do not go past this point -
3563   # everything added from here on is unbalanced "anyone's guess" stuff
3564   my $dedup_stop_idx = $#as;
3565
3566   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3567     if $attrs->{as};
3568   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3569     if $attrs->{select};
3570
3571   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3572   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3573
3574   # disqualify all $alias.col as-bits (inflate-map mandated)
3575   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3576
3577   # de-duplicate the result (remove *identical* select/as pairs)
3578   # and also die on duplicate {as} pointing to different {select}s
3579   # not using a c-style for as the condition is prone to shrinkage
3580   my $seen;
3581   my $i = 0;
3582   while ($i <= $dedup_stop_idx) {
3583     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3584       splice @sel, $i, 1;
3585       splice @as, $i, 1;
3586       $dedup_stop_idx--;
3587     }
3588     elsif ($seen->{$as[$i]}++) {
3589       $self->throw_exception(
3590         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3591       );
3592     }
3593     else {
3594       $i++;
3595     }
3596   }
3597
3598   $attrs->{select} = \@sel;
3599   $attrs->{as} = \@as;
3600
3601   $attrs->{from} ||= [{
3602     -rsrc   => $source,
3603     -alias  => $self->{attrs}{alias},
3604     $self->{attrs}{alias} => $source->from,
3605   }];
3606
3607   if ( $attrs->{join} || $attrs->{prefetch} ) {
3608
3609     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3610       if ref $attrs->{from} ne 'ARRAY';
3611
3612     my $join = (delete $attrs->{join}) || {};
3613
3614     if ( defined $attrs->{prefetch} ) {
3615       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3616     }
3617
3618     $attrs->{from} =    # have to copy here to avoid corrupting the original
3619       [
3620         @{ $attrs->{from} },
3621         $source->_resolve_join(
3622           $join,
3623           $alias,
3624           { %{ $attrs->{seen_join} || {} } },
3625           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3626             ? $attrs->{from}[-1][0]{-join_path}
3627             : []
3628           ,
3629         )
3630       ];
3631   }
3632
3633   if ( defined $attrs->{order_by} ) {
3634     $attrs->{order_by} = (
3635       ref( $attrs->{order_by} ) eq 'ARRAY'
3636       ? [ @{ $attrs->{order_by} } ]
3637       : [ $attrs->{order_by} || () ]
3638     );
3639   }
3640
3641   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3642     $attrs->{group_by} = [ $attrs->{group_by} ];
3643   }
3644
3645
3646   # generate selections based on the prefetch helper
3647   my ($prefetch, @prefetch_select, @prefetch_as);
3648   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3649     if defined $attrs->{prefetch};
3650
3651   if ($prefetch) {
3652
3653     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3654       if $attrs->{_dark_selector};
3655
3656     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3657       if defined $attrs->{collapse} and ! $attrs->{collapse};
3658
3659     $attrs->{collapse} = 1;
3660
3661     # this is a separate structure (we don't look in {from} directly)
3662     # as the resolver needs to shift things off the lists to work
3663     # properly (identical-prefetches on different branches)
3664     my $join_map = {};
3665     if (ref $attrs->{from} eq 'ARRAY') {
3666
3667       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3668
3669       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3670         next unless $j->[0]{-alias};
3671         next unless $j->[0]{-join_path};
3672         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3673
3674         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3675
3676         my $p = $join_map;
3677         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3678         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3679       }
3680     }
3681
3682     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3683
3684     # save these for after distinct resolution
3685     @prefetch_select = map { $_->[0] } @prefetch;
3686     @prefetch_as = map { $_->[1] } @prefetch;
3687   }
3688
3689   # run through the resulting joinstructure (starting from our current slot)
3690   # and unset collapse if proven unnecessary
3691   #
3692   # also while we are at it find out if the current root source has
3693   # been premultiplied by previous related_source chaining
3694   #
3695   # this allows to predict whether a root object with all other relation
3696   # data set to NULL is in fact unique
3697   if ($attrs->{collapse}) {
3698
3699     if (ref $attrs->{from} eq 'ARRAY') {
3700
3701       if (@{$attrs->{from}} == 1) {
3702         # no joins - no collapse
3703         $attrs->{collapse} = 0;
3704       }
3705       else {
3706         # find where our table-spec starts
3707         my @fromlist = @{$attrs->{from}};
3708         while (@fromlist) {
3709           my $t = shift @fromlist;
3710
3711           my $is_multi;
3712           # me vs join from-spec distinction - a ref means non-root
3713           if (ref $t eq 'ARRAY') {
3714             $t = $t->[0];
3715             $is_multi ||= ! $t->{-is_single};
3716           }
3717           last if ($t->{-alias} && $t->{-alias} eq $alias);
3718           $attrs->{_main_source_premultiplied} ||= $is_multi;
3719         }
3720
3721         # no non-singles remaining, nor any premultiplication - nothing to collapse
3722         if (
3723           ! $attrs->{_main_source_premultiplied}
3724             and
3725           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3726         ) {
3727           $attrs->{collapse} = 0;
3728         }
3729       }
3730     }
3731
3732     else {
3733       # if we can not analyze the from - err on the side of safety
3734       $attrs->{_main_source_premultiplied} = 1;
3735     }
3736   }
3737
3738   # generate the distinct induced group_by before injecting the prefetched select/as parts
3739   if (delete $attrs->{distinct}) {
3740     if ($attrs->{group_by}) {
3741       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3742     }
3743     else {
3744       $attrs->{_grouped_by_distinct} = 1;
3745       # distinct affects only the main selection part, not what prefetch may add below
3746       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3747
3748       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3749       # The thinking is: if we are collapsing the subquerying prefetch engine will
3750       # rip stuff apart for us anyway, and we do not want to have a potentially
3751       # function-converted external order_by
3752       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3753       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3754     }
3755   }
3756
3757   # inject prefetch-bound selection (if any)
3758   push @{$attrs->{select}}, @prefetch_select;
3759   push @{$attrs->{as}}, @prefetch_as;
3760
3761   $attrs->{_simple_passthrough_construction} = !(
3762     $attrs->{collapse}
3763       or
3764     grep { $_ =~ /\./ } @{$attrs->{as}}
3765   );
3766
3767   # if both page and offset are specified, produce a combined offset
3768   # even though it doesn't make much sense, this is what pre 081xx has
3769   # been doing
3770   if (my $page = delete $attrs->{page}) {
3771     $attrs->{offset} =
3772       ($attrs->{rows} * ($page - 1))
3773             +
3774       ($attrs->{offset} || 0)
3775     ;
3776   }
3777
3778   return $self->{_attrs} = $attrs;
3779 }
3780
3781 sub _rollout_attr {
3782   my ($self, $attr) = @_;
3783
3784   if (ref $attr eq 'HASH') {
3785     return $self->_rollout_hash($attr);
3786   } elsif (ref $attr eq 'ARRAY') {
3787     return $self->_rollout_array($attr);
3788   } else {
3789     return [$attr];
3790   }
3791 }
3792
3793 sub _rollout_array {
3794   my ($self, $attr) = @_;
3795
3796   my @rolled_array;
3797   foreach my $element (@{$attr}) {
3798     if (ref $element eq 'HASH') {
3799       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3800     } elsif (ref $element eq 'ARRAY') {
3801       #  XXX - should probably recurse here
3802       push( @rolled_array, @{$self->_rollout_array($element)} );
3803     } else {
3804       push( @rolled_array, $element );
3805     }
3806   }
3807   return \@rolled_array;
3808 }
3809
3810 sub _rollout_hash {
3811   my ($self, $attr) = @_;
3812
3813   my @rolled_array;
3814   foreach my $key (keys %{$attr}) {
3815     push( @rolled_array, { $key => $attr->{$key} } );
3816   }
3817   return \@rolled_array;
3818 }
3819
3820 sub _calculate_score {
3821   my ($self, $a, $b) = @_;
3822
3823   if (defined $a xor defined $b) {
3824     return 0;
3825   }
3826   elsif (not defined $a) {
3827     return 1;
3828   }
3829
3830   if (ref $b eq 'HASH') {
3831     my ($b_key) = keys %{$b};
3832     if (ref $a eq 'HASH') {
3833       my ($a_key) = keys %{$a};
3834       if ($a_key eq $b_key) {
3835         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3836       } else {
3837         return 0;
3838       }
3839     } else {
3840       return ($a eq $b_key) ? 1 : 0;
3841     }
3842   } else {
3843     if (ref $a eq 'HASH') {
3844       my ($a_key) = keys %{$a};
3845       return ($b eq $a_key) ? 1 : 0;
3846     } else {
3847       return ($b eq $a) ? 1 : 0;
3848     }
3849   }
3850 }
3851
3852 sub _merge_joinpref_attr {
3853   my ($self, $orig, $import) = @_;
3854
3855   return $import unless defined($orig);
3856   return $orig unless defined($import);
3857
3858   $orig = $self->_rollout_attr($orig);
3859   $import = $self->_rollout_attr($import);
3860
3861   my $seen_keys;
3862   foreach my $import_element ( @{$import} ) {
3863     # find best candidate from $orig to merge $b_element into
3864     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3865     foreach my $orig_element ( @{$orig} ) {
3866       my $score = $self->_calculate_score( $orig_element, $import_element );
3867       if ($score > $best_candidate->{score}) {
3868         $best_candidate->{position} = $position;
3869         $best_candidate->{score} = $score;
3870       }
3871       $position++;
3872     }
3873     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3874     $import_key = '' if not defined $import_key;
3875
3876     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3877       push( @{$orig}, $import_element );
3878     } else {
3879       my $orig_best = $orig->[$best_candidate->{position}];
3880       # merge orig_best and b_element together and replace original with merged
3881       if (ref $orig_best ne 'HASH') {
3882         $orig->[$best_candidate->{position}] = $import_element;
3883       } elsif (ref $import_element eq 'HASH') {
3884         my ($key) = keys %{$orig_best};
3885         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3886       }
3887     }
3888     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3889   }
3890
3891   return @$orig ? $orig : ();
3892 }
3893
3894 {
3895   my $hm;
3896
3897   sub _merge_attr {
3898     $hm ||= do {
3899       require Hash::Merge;
3900       my $hm = Hash::Merge->new;
3901
3902       $hm->specify_behavior({
3903         SCALAR => {
3904           SCALAR => sub {
3905             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3906
3907             if ($defl xor $defr) {
3908               return [ $defl ? $_[0] : $_[1] ];
3909             }
3910             elsif (! $defl) {
3911               return [];
3912             }
3913             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3914               return [ $_[0] ];
3915             }
3916             else {
3917               return [$_[0], $_[1]];
3918             }
3919           },
3920           ARRAY => sub {
3921             return $_[1] if !defined $_[0];
3922             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3923             return [$_[0], @{$_[1]}]
3924           },
3925           HASH  => sub {
3926             return [] if !defined $_[0] and !keys %{$_[1]};
3927             return [ $_[1] ] if !defined $_[0];
3928             return [ $_[0] ] if !keys %{$_[1]};
3929             return [$_[0], $_[1]]
3930           },
3931         },
3932         ARRAY => {
3933           SCALAR => sub {
3934             return $_[0] if !defined $_[1];
3935             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3936             return [@{$_[0]}, $_[1]]
3937           },
3938           ARRAY => sub {
3939             my @ret = @{$_[0]} or return $_[1];
3940             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3941             my %idx = map { $_ => 1 } @ret;
3942             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3943             \@ret;
3944           },
3945           HASH => sub {
3946             return [ $_[1] ] if ! @{$_[0]};
3947             return $_[0] if !keys %{$_[1]};
3948             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3949             return [ @{$_[0]}, $_[1] ];
3950           },
3951         },
3952         HASH => {
3953           SCALAR => sub {
3954             return [] if !keys %{$_[0]} and !defined $_[1];
3955             return [ $_[0] ] if !defined $_[1];
3956             return [ $_[1] ] if !keys %{$_[0]};
3957             return [$_[0], $_[1]]
3958           },
3959           ARRAY => sub {
3960             return [] if !keys %{$_[0]} and !@{$_[1]};
3961             return [ $_[0] ] if !@{$_[1]};
3962             return $_[1] if !keys %{$_[0]};
3963             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3964             return [ $_[0], @{$_[1]} ];
3965           },
3966           HASH => sub {
3967             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3968             return [ $_[0] ] if !keys %{$_[1]};
3969             return [ $_[1] ] if !keys %{$_[0]};
3970             return [ $_[0] ] if $_[0] eq $_[1];
3971             return [ $_[0], $_[1] ];
3972           },
3973         }
3974       } => 'DBIC_RS_ATTR_MERGER');
3975       $hm;
3976     };
3977
3978     return $hm->merge ($_[1], $_[2]);
3979   }
3980 }
3981
3982 sub STORABLE_freeze {
3983   my ($self, $cloning) = @_;
3984   my $to_serialize = { %$self };
3985
3986   # A cursor in progress can't be serialized (and would make little sense anyway)
3987   # the parser can be regenerated (and can't be serialized)
3988   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3989
3990   # nor is it sensical to store a not-yet-fired-count pager
3991   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3992     delete $to_serialize->{pager};
3993   }
3994
3995   Storable::nfreeze($to_serialize);
3996 }
3997
3998 # need this hook for symmetry
3999 sub STORABLE_thaw {
4000   my ($self, $cloning, $serialized) = @_;
4001
4002   %$self = %{ Storable::thaw($serialized) };
4003
4004   $self;
4005 }
4006
4007
4008 =head2 throw_exception
4009
4010 See L<DBIx::Class::Schema/throw_exception> for details.
4011
4012 =cut
4013
4014 sub throw_exception {
4015   my $self=shift;
4016
4017   if (ref $self and my $rsrc = $self->result_source) {
4018     $rsrc->throw_exception(@_)
4019   }
4020   else {
4021     DBIx::Class::Exception->throw(@_);
4022   }
4023 }
4024
4025 1;
4026
4027 __END__
4028
4029 # XXX: FIXME: Attributes docs need clearing up
4030
4031 =head1 ATTRIBUTES
4032
4033 Attributes are used to refine a ResultSet in various ways when
4034 searching for data. They can be passed to any method which takes an
4035 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4036 L</count>.
4037
4038 Default attributes can be set on the result class using
4039 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4040 the CAVEATS on that feature before using it!)
4041
4042 These are in no particular order:
4043
4044 =head2 order_by
4045
4046 =over 4
4047
4048 =item Value: ( $order_by | \@order_by | \%order_by )
4049
4050 =back
4051
4052 Which column(s) to order the results by.
4053
4054 [The full list of suitable values is documented in
4055 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4056 common options.]
4057
4058 If a single column name, or an arrayref of names is supplied, the
4059 argument is passed through directly to SQL. The hashref syntax allows
4060 for connection-agnostic specification of ordering direction:
4061
4062  For descending order:
4063
4064   order_by => { -desc => [qw/col1 col2 col3/] }
4065
4066  For explicit ascending order:
4067
4068   order_by => { -asc => 'col' }
4069
4070 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4071 supported, although you are strongly encouraged to use the hashref
4072 syntax as outlined above.
4073
4074 =head2 columns
4075
4076 =over 4
4077
4078 =item Value: \@columns | \%columns | $column
4079
4080 =back
4081
4082 Shortcut to request a particular set of columns to be retrieved. Each
4083 column spec may be a string (a table column name), or a hash (in which
4084 case the key is the C<as> value, and the value is used as the C<select>
4085 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4086 it and sets C<select> from that, then auto-populates C<as> from
4087 C<select> as normal. (You may also use the C<cols> attribute, as in
4088 earlier versions of DBIC, but this is deprecated)
4089
4090 Essentially C<columns> does the same as L</select> and L</as>.
4091
4092     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4093
4094 is the same as
4095
4096     select => [qw(some_column another_column)],
4097     as     => [qw(some_column dbic_slot)]
4098
4099 If you want to individually retrieve related columns (in essence perform
4100 manual prefetch) you have to make sure to specify the correct inflation slot
4101 chain such that it matches existing relationships:
4102
4103     my $rs = $schema->resultset('Artist')->search({}, {
4104         # required to tell DBIC to collapse has_many relationships
4105         collapse => 1,
4106         join     => { cds => 'tracks'},
4107         '+columns'  => {
4108           'cds.cdid'         => 'cds.cdid',
4109           'cds.tracks.title' => 'tracks.title',
4110         },
4111     });
4112
4113 =head2 +columns
4114
4115 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4116 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4117 with a unary plus operator before it, which is the same as simply C<columns>.
4118
4119 =over 4
4120
4121 =item Value: \@extra_columns
4122
4123 =back
4124
4125 Indicates additional columns to be selected from storage. Works the same as
4126 L</columns> but adds columns to the current selection. (You may also use the
4127 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4128 deprecated)
4129
4130   $schema->resultset('CD')->search(undef, {
4131     '+columns' => ['artist.name'],
4132     join => ['artist']
4133   });
4134
4135 would return all CDs and include a 'name' column to the information
4136 passed to object inflation. Note that the 'artist' is the name of the
4137 column (or relationship) accessor, and 'name' is the name of the column
4138 accessor in the related table.
4139
4140 =head2 select
4141
4142 =over 4
4143
4144 =item Value: \@select_columns
4145
4146 =back
4147
4148 Indicates which columns should be selected from the storage. You can use
4149 column names, or in the case of RDBMS back ends, function or stored procedure
4150 names:
4151
4152   $rs = $schema->resultset('Employee')->search(undef, {
4153     select => [
4154       'name',
4155       { count => 'employeeid' },
4156       { max => { length => 'name' }, -as => 'longest_name' }
4157     ]
4158   });
4159
4160   # Equivalent SQL
4161   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4162
4163 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4164 use L</select>, to instruct DBIx::Class how to store the result of the column.
4165 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4166 identifier aliasing. You can however alias a function, so you can use it in
4167 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4168 attribute> supplied as shown in the example above.
4169
4170 =head2 +select
4171
4172 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4173 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4174 with a unary plus operator before it, which is the same as simply C<select>.
4175
4176 =over 4
4177
4178 =item Value: \@extra_select_columns
4179
4180 =back
4181
4182 Indicates additional columns to be selected from storage.  Works the same as
4183 L</select> but adds columns to the current selection, instead of specifying
4184 a new explicit list.
4185
4186 =head2 as
4187
4188 =over 4
4189
4190 =item Value: \@inflation_names
4191
4192 =back
4193
4194 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4195 slot name in which the column value will be stored within the
4196 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4197 identifier by the C<get_column> method (or via the object accessor B<if one
4198 with the same name already exists>) as shown below. The L</as> attribute has
4199 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4200
4201   $rs = $schema->resultset('Employee')->search(undef, {
4202     select => [
4203       'name',
4204       { count => 'employeeid' },
4205       { max => { length => 'name' }, -as => 'longest_name' }
4206     ],
4207     as => [qw/
4208       name
4209       employee_count
4210       max_name_length
4211     /],
4212   });
4213
4214 If the object against which the search is performed already has an accessor
4215 matching a column name specified in C<as>, the value can be retrieved using
4216 the accessor as normal:
4217
4218   my $name = $employee->name();
4219
4220 If on the other hand an accessor does not exist in the object, you need to
4221 use C<get_column> instead:
4222
4223   my $employee_count = $employee->get_column('employee_count');
4224
4225 You can create your own accessors if required - see
4226 L<DBIx::Class::Manual::Cookbook> for details.
4227
4228 =head2 +as
4229
4230 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4231 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4232 with a unary plus operator before it, which is the same as simply C<as>.
4233
4234 =over 4
4235
4236 =item Value: \@extra_inflation_names
4237
4238 =back
4239
4240 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4241
4242 =head2 join
4243
4244 =over 4
4245
4246 =item Value: ($rel_name | \@rel_names | \%rel_names)
4247
4248 =back
4249
4250 Contains a list of relationships that should be joined for this query.  For
4251 example:
4252
4253   # Get CDs by Nine Inch Nails
4254   my $rs = $schema->resultset('CD')->search(
4255     { 'artist.name' => 'Nine Inch Nails' },
4256     { join => 'artist' }
4257   );
4258
4259 Can also contain a hash reference to refer to the other relation's relations.
4260 For example:
4261
4262   package MyApp::Schema::Track;
4263   use base qw/DBIx::Class/;
4264   __PACKAGE__->table('track');
4265   __PACKAGE__->add_columns(qw/trackid cd position title/);
4266   __PACKAGE__->set_primary_key('trackid');
4267   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4268   1;
4269
4270   # In your application
4271   my $rs = $schema->resultset('Artist')->search(
4272     { 'track.title' => 'Teardrop' },
4273     {
4274       join     => { cd => 'track' },
4275       order_by => 'artist.name',
4276     }
4277   );
4278
4279 You need to use the relationship (not the table) name in  conditions,
4280 because they are aliased as such. The current table is aliased as "me", so
4281 you need to use me.column_name in order to avoid ambiguity. For example:
4282
4283   # Get CDs from 1984 with a 'Foo' track
4284   my $rs = $schema->resultset('CD')->search(
4285     {
4286       'me.year' => 1984,
4287       'tracks.name' => 'Foo'
4288     },
4289     { join => 'tracks' }
4290   );
4291
4292 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4293 similarly for a third time). For e.g.
4294
4295   my $rs = $schema->resultset('Artist')->search({
4296     'cds.title'   => 'Down to Earth',
4297     'cds_2.title' => 'Popular',
4298   }, {
4299     join => [ qw/cds cds/ ],
4300   });
4301
4302 will return a set of all artists that have both a cd with title 'Down
4303 to Earth' and a cd with title 'Popular'.
4304
4305 If you want to fetch related objects from other tables as well, see L</prefetch>
4306 below.
4307
4308  NOTE: An internal join-chain pruner will discard certain joins while
4309  constructing the actual SQL query, as long as the joins in question do not
4310  affect the retrieved result. This for example includes 1:1 left joins
4311  that are not part of the restriction specification (WHERE/HAVING) nor are
4312  a part of the query selection.
4313
4314 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4315
4316 =head2 collapse
4317
4318 =over 4
4319
4320 =item Value: (0 | 1)
4321
4322 =back
4323
4324 When set to a true value, indicates that any rows fetched from joined has_many
4325 relationships are to be aggregated into the corresponding "parent" object. For
4326 example, the resultset:
4327
4328   my $rs = $schema->resultset('CD')->search({}, {
4329     '+columns' => [ qw/ tracks.title tracks.position / ],
4330     join => 'tracks',
4331     collapse => 1,
4332   });
4333
4334 While executing the following query:
4335
4336   SELECT me.*, tracks.title, tracks.position
4337     FROM cd me
4338     LEFT JOIN track tracks
4339       ON tracks.cdid = me.cdid
4340
4341 Will return only as many objects as there are rows in the CD source, even
4342 though the result of the query may span many rows. Each of these CD objects
4343 will in turn have multiple "Track" objects hidden behind the has_many
4344 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4345 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4346 product"), with each CD object containing exactly one of all fetched Track data.
4347
4348 When a collapse is requested on a non-ordered resultset, an order by some
4349 unique part of the main source (the left-most table) is inserted automatically.
4350 This is done so that the resultset is allowed to be "lazy" - calling
4351 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4352 object with all of its related data.
4353
4354 If an L</order_by> is already declared, and orders the resultset in a way that
4355 makes collapsing as described above impossible (e.g. C<< ORDER BY
4356 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4357 switch to "eager" mode and slurp the entire resultset before constructing the
4358 first object returned by L</next>.
4359
4360 Setting this attribute on a resultset that does not join any has_many
4361 relations is a no-op.
4362
4363 For a more in-depth discussion, see L</PREFETCHING>.
4364
4365 =head2 prefetch
4366
4367 =over 4
4368
4369 =item Value: ($rel_name | \@rel_names | \%rel_names)
4370
4371 =back
4372
4373 This attribute is a shorthand for specifying a L</join> spec, adding all
4374 columns from the joined related sources as L</+columns> and setting
4375 L</collapse> to a true value. For example, the following two queries are
4376 equivalent:
4377
4378   my $rs = $schema->resultset('Artist')->search({}, {
4379     prefetch => { cds => ['genre', 'tracks' ] },
4380   });
4381
4382 and
4383
4384   my $rs = $schema->resultset('Artist')->search({}, {
4385     join => { cds => ['genre', 'tracks' ] },
4386     collapse => 1,
4387     '+columns' => [
4388       (map
4389         { +{ "cds.$_" => "cds.$_" } }
4390         $schema->source('Artist')->related_source('cds')->columns
4391       ),
4392       (map
4393         { +{ "cds.genre.$_" => "genre.$_" } }
4394         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4395       ),
4396       (map
4397         { +{ "cds.tracks.$_" => "tracks.$_" } }
4398         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4399       ),
4400     ],
4401   });
4402
4403 Both producing the following SQL:
4404
4405   SELECT  me.artistid, me.name, me.rank, me.charfield,
4406           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4407           genre.genreid, genre.name,
4408           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4409     FROM artist me
4410     LEFT JOIN cd cds
4411       ON cds.artist = me.artistid
4412     LEFT JOIN genre genre
4413       ON genre.genreid = cds.genreid
4414     LEFT JOIN track tracks
4415       ON tracks.cd = cds.cdid
4416   ORDER BY me.artistid
4417
4418 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4419 the arguments are properly merged and generally do the right thing. For
4420 example, you may want to do the following:
4421
4422   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4423     { 'genre.genreid' => undef },
4424     {
4425       join => { cds => 'genre' },
4426       prefetch => 'cds',
4427     }
4428   );
4429
4430 Which generates the following SQL:
4431
4432   SELECT  me.artistid, me.name, me.rank, me.charfield,
4433           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4434     FROM artist me
4435     LEFT JOIN cd cds
4436       ON cds.artist = me.artistid
4437     LEFT JOIN genre genre
4438       ON genre.genreid = cds.genreid
4439   WHERE genre.genreid IS NULL
4440   ORDER BY me.artistid
4441
4442 For a more in-depth discussion, see L</PREFETCHING>.
4443
4444 =head2 alias
4445
4446 =over 4
4447
4448 =item Value: $source_alias
4449
4450 =back
4451
4452 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4453 nested search queries (sub-SELECTs) might need specific aliases set to
4454 reference inner queries.  For example:
4455
4456    my $q = $rs
4457       ->related_resultset('CDs')
4458       ->related_resultset('Tracks')
4459       ->search({
4460          'track.id' => { -ident => 'none_search.id' },
4461       })
4462       ->as_query;
4463
4464    my $ids = $self->search({
4465       -not_exists => $q,
4466    }, {
4467       alias    => 'none_search',
4468       group_by => 'none_search.id',
4469    })->get_column('id')->as_query;
4470
4471    $self->search({ id => { -in => $ids } })
4472
4473 This attribute is directly tied to L</current_source_alias>.
4474
4475 =head2 page
4476
4477 =over 4
4478
4479 =item Value: $page
4480
4481 =back
4482
4483 Makes the resultset paged and specifies the page to retrieve. Effectively
4484 identical to creating a non-pages resultset and then calling ->page($page)
4485 on it.
4486
4487 If L</rows> attribute is not specified it defaults to 10 rows per page.
4488
4489 When you have a paged resultset, L</count> will only return the number
4490 of rows in the page. To get the total, use the L</pager> and call
4491 C<total_entries> on it.
4492
4493 =head2 rows
4494
4495 =over 4
4496
4497 =item Value: $rows
4498
4499 =back
4500
4501 Specifies the maximum number of rows for direct retrieval or the number of
4502 rows per page if the page attribute or method is used.
4503
4504 =head2 offset
4505
4506 =over 4
4507
4508 =item Value: $offset
4509
4510 =back
4511
4512 Specifies the (zero-based) row number for the  first row to be returned, or the
4513 of the first row of the first page if paging is used.
4514
4515 =head2 software_limit
4516
4517 =over 4
4518
4519 =item Value: (0 | 1)
4520
4521 =back
4522
4523 When combined with L</rows> and/or L</offset> the generated SQL will not
4524 include any limit dialect stanzas. Instead the entire result will be selected
4525 as if no limits were specified, and DBIC will perform the limit locally, by
4526 artificially advancing and finishing the resulting L</cursor>.
4527
4528 This is the recommended way of performing resultset limiting when no sane RDBMS
4529 implementation is available (e.g.
4530 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4531 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4532
4533 =head2 group_by
4534
4535 =over 4
4536
4537 =item Value: \@columns
4538
4539 =back
4540
4541 A arrayref of columns to group by. Can include columns of joined tables.
4542
4543   group_by => [qw/ column1 column2 ... /]
4544
4545 =head2 having
4546
4547 =over 4
4548
4549 =item Value: $condition
4550
4551 =back
4552
4553 HAVING is a select statement attribute that is applied between GROUP BY and
4554 ORDER BY. It is applied to the after the grouping calculations have been
4555 done.
4556
4557   having => { 'count_employee' => { '>=', 100 } }
4558
4559 or with an in-place function in which case literal SQL is required:
4560
4561   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4562
4563 =head2 distinct
4564
4565 =over 4
4566
4567 =item Value: (0 | 1)
4568
4569 =back
4570
4571 Set to 1 to automatically generate a L</group_by> clause based on the selection
4572 (including intelligent handling of L</order_by> contents). Note that the group
4573 criteria calculation takes place over the B<final> selection. This includes
4574 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4575 L</search> calls, and standalone columns selected via
4576 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4577 extra selections specified via L</prefetch> - such selections are explicitly
4578 excluded from group criteria calculations.
4579
4580 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4581 setting is ignored and an appropriate warning is issued.
4582
4583 =head2 where
4584
4585 =over 4
4586
4587 Adds to the WHERE clause.
4588
4589   # only return rows WHERE deleted IS NULL for all searches
4590   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4591
4592 Can be overridden by passing C<< { where => undef } >> as an attribute
4593 to a resultset.
4594
4595 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4596
4597 =back
4598
4599 =head2 cache
4600
4601 Set to 1 to cache search results. This prevents extra SQL queries if you
4602 revisit rows in your ResultSet:
4603
4604   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4605
4606   while( my $artist = $resultset->next ) {
4607     ... do stuff ...
4608   }
4609
4610   $rs->first; # without cache, this would issue a query
4611
4612 By default, searches are not cached.
4613
4614 For more examples of using these attributes, see
4615 L<DBIx::Class::Manual::Cookbook>.
4616
4617 =head2 for
4618
4619 =over 4
4620
4621 =item Value: ( 'update' | 'shared' | \$scalar )
4622
4623 =back
4624
4625 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4626 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4627 query.
4628
4629 =head1 PREFETCHING
4630
4631 DBIx::Class supports arbitrary related data prefetching from multiple related
4632 sources. Any combination of relationship types and column sets are supported.
4633 If L<collapsing|/collapse> is requested, there is an additional requirement of
4634 selecting enough data to make every individual object uniquely identifiable.
4635
4636 Here are some more involved examples, based on the following relationship map:
4637
4638   # Assuming:
4639   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4640   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4641   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4642
4643   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4644
4645   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4646
4647
4648
4649   my $rs = $schema->resultset('Tag')->search(
4650     undef,
4651     {
4652       prefetch => {
4653         cd => 'artist'
4654       }
4655     }
4656   );
4657
4658 The initial search results in SQL like the following:
4659
4660   SELECT tag.*, cd.*, artist.* FROM tag
4661   JOIN cd ON tag.cd = cd.cdid
4662   JOIN artist ON cd.artist = artist.artistid
4663
4664 L<DBIx::Class> has no need to go back to the database when we access the
4665 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4666 case.
4667
4668 Simple prefetches will be joined automatically, so there is no need
4669 for a C<join> attribute in the above search.
4670
4671 The L</prefetch> attribute can be used with any of the relationship types
4672 and multiple prefetches can be specified together. Below is a more complex
4673 example that prefetches a CD's artist, its liner notes (if present),
4674 the cover image, the tracks on that CD, and the guests on those
4675 tracks.
4676
4677   my $rs = $schema->resultset('CD')->search(
4678     undef,
4679     {
4680       prefetch => [
4681         { artist => 'record_label'},  # belongs_to => belongs_to
4682         'liner_note',                 # might_have
4683         'cover_image',                # has_one
4684         { tracks => 'guests' },       # has_many => has_many
4685       ]
4686     }
4687   );
4688
4689 This will produce SQL like the following:
4690
4691   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4692          tracks.*, guests.*
4693     FROM cd me
4694     JOIN artist artist
4695       ON artist.artistid = me.artistid
4696     JOIN record_label record_label
4697       ON record_label.labelid = artist.labelid
4698     LEFT JOIN track tracks
4699       ON tracks.cdid = me.cdid
4700     LEFT JOIN guest guests
4701       ON guests.trackid = track.trackid
4702     LEFT JOIN liner_notes liner_note
4703       ON liner_note.cdid = me.cdid
4704     JOIN cd_artwork cover_image
4705       ON cover_image.cdid = me.cdid
4706   ORDER BY tracks.cd
4707
4708 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4709 C<tracks>, and C<guests> of the CD will all be available through the
4710 relationship accessors without the need for additional queries to the
4711 database.
4712
4713 =head3 CAVEATS
4714
4715 Prefetch does a lot of deep magic. As such, it may not behave exactly
4716 as you might expect.
4717
4718 =over 4
4719
4720 =item *
4721
4722 Prefetch uses the L</cache> to populate the prefetched relationships. This
4723 may or may not be what you want.
4724
4725 =item *
4726
4727 If you specify a condition on a prefetched relationship, ONLY those
4728 rows that match the prefetched condition will be fetched into that relationship.
4729 This means that adding prefetch to a search() B<may alter> what is returned by
4730 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4731
4732   my $artist_rs = $schema->resultset('Artist')->search({
4733       'cds.year' => 2008,
4734   }, {
4735       join => 'cds',
4736   });
4737
4738   my $count = $artist_rs->first->cds->count;
4739
4740   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4741
4742   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4743
4744   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4745
4746 That cmp_ok() may or may not pass depending on the datasets involved. In other
4747 words the C<WHERE> condition would apply to the entire dataset, just like
4748 it would in regular SQL. If you want to add a condition only to the "right side"
4749 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4750 condition|DBIx::Class::Relationship::Base/condition>
4751
4752 =back
4753
4754 =head1 DBIC BIND VALUES
4755
4756 Because DBIC may need more information to bind values than just the column name
4757 and value itself, it uses a special format for both passing and receiving bind
4758 values.  Each bind value should be composed of an arrayref of
4759 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4760
4761 =over 4
4762
4763 =item dbd_attrs
4764
4765 If present (in any form), this is what is being passed directly to bind_param.
4766 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4767 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4768
4769 If this is specified, all other bind options described below are ignored.
4770
4771 =item sqlt_datatype
4772
4773 If present, this is used to infer the actual bind attribute by passing to
4774 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4775 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4776
4777 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4778 currently drivers are expected to "Do the Right Thing" when given a common
4779 datatype name.  (Not ideal, but that's what we got at this point.)
4780
4781 =item sqlt_size
4782
4783 Currently used to correctly allocate buffers for bind_param_inout().
4784 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4785 or to a sensible value based on the "data_type".
4786
4787 =item dbic_colname
4788
4789 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4790 explicitly specified they are never overridden).  Also used by some weird DBDs,
4791 where the column name should be available at bind_param time (e.g. Oracle).
4792
4793 =back
4794
4795 For backwards compatibility and convenience, the following shortcuts are
4796 supported:
4797
4798   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4799   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4800   [ undef,   $val ] === [ {}, $val ]
4801   $val              === [ {}, $val ]
4802
4803 =head1 AUTHOR AND CONTRIBUTORS
4804
4805 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4806
4807 =head1 LICENSE
4808
4809 You may distribute this code under the same terms as Perl itself.
4810