lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => \&count,
   7         'bool'   => sub { 1; },
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use base qw/DBIx::Class/;
  15
  16 __PACKAGE__->mk_group_accessors('simple' => qw/result_class _source_handle/);
  17
  18 =head1 NAME
  19
  20 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  21
  22 =head1 SYNOPSIS
  23
  24   my $rs   = $schema->resultset('User')->search(registered => 1);
  25   my @rows = $schema->resultset('CD')->search(year => 2005);
  26
  27 =head1 DESCRIPTION
  28
  29 The resultset is also known as an iterator. It is responsible for handling
  30 queries that may return an arbitrary number of rows, e.g. via L</search>
  31 or a C<has_many> relationship.
  32
  33 In the examples below, the following table classes are used:
  34
  35   package MyApp::Schema::Artist;
  36   use base qw/DBIx::Class/;
  37   __PACKAGE__->load_components(qw/Core/);
  38   __PACKAGE__->table('artist');
  39   __PACKAGE__->add_columns(qw/artistid name/);
  40   __PACKAGE__->set_primary_key('artistid');
  41   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  42   1;
  43
  44   package MyApp::Schema::CD;
  45   use base qw/DBIx::Class/;
  46   __PACKAGE__->load_components(qw/Core/);
  47   __PACKAGE__->table('cd');
  48   __PACKAGE__->add_columns(qw/cdid artist title year/);
  49   __PACKAGE__->set_primary_key('cdid');
  50   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  51   1;
  52
  53 =head1 METHODS
  54
  55 =head2 new
  56
  57 =over 4
  58
  59 =item Arguments: $source, \%$attrs
  60
  61 =item Return Value: $rs
  62
  63 =back
  64
  65 The resultset constructor. Takes a source object (usually a
  66 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  67 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  68 executed as needed by the other methods.
  69
  70 Generally you won't need to construct a resultset manually.  You'll
  71 automatically get one from e.g. a L</search> called in scalar context:
  72
  73   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  74
  75 IMPORTANT: If called on an object, proxies to new_result instead so
  76
  77   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  78
  79 will return a CD object, not a ResultSet.
  80
  81 =cut
  82
  83 sub new {
  84   my $class = shift;
  85   return $class->new_result(@_) if ref $class;
  86
  87   my ($source, $attrs) = @_;
  88   $source = $source->handle
  89     unless $source->isa('DBIx::Class::ResultSourceHandle');
  90   $attrs = { %{$attrs||{}} };
  91
  92   if ($attrs->{page}) {
  93     $attrs->{rows} ||= 10;
  94     $attrs->{offset} ||= 0;
  95     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
  96   }
  97
  98   $attrs->{alias} ||= 'me';
  99
 100   my $self = {
 101     _source_handle => $source,
 102     result_class => $attrs->{result_class} || $source->resolve->result_class,
 103     cond => $attrs->{where},
 104     count => undef,
 105     pager => undef,
 106     attrs => $attrs
 107   };
 108
 109   bless $self, $class;
 110
 111   return $self;
 112 }
 113
 114 =head2 search
 115
 116 =over 4
 117
 118 =item Arguments: $cond, \%attrs?
 119
 120 =item Return Value: $resultset (scalar context), @row_objs (list context)
 121
 122 =back
 123
 124   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 125   my $new_rs = $cd_rs->search({ year => 2005 });
 126
 127   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 128                  # year = 2005 OR year = 2004
 129
 130 If you need to pass in additional attributes but no additional condition,
 131 call it as C<search(undef, \%attrs)>.
 132
 133   # "SELECT name, artistid FROM $artist_table"
 134   my @all_artists = $schema->resultset('Artist')->search(undef, {
 135     columns => [qw/name artistid/],
 136   });
 137
 138 For a list of attributes that can be passed to C<search>, see
 139 L</ATTRIBUTES>. For more examples of using this function, see
 140 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 141 documentation for the first argument, see L<SQL::Abstract>.
 142
 143 =cut
 144
 145 sub search {
 146   my $self = shift;
 147   my $rs = $self->search_rs( @_ );
 148   return (wantarray ? $rs->all : $rs);
 149 }
 150
 151 =head2 search_rs
 152
 153 =over 4
 154
 155 =item Arguments: $cond, \%attrs?
 156
 157 =item Return Value: $resultset
 158
 159 =back
 160
 161 This method does the same exact thing as search() except it will
 162 always return a resultset, even in list context.
 163
 164 =cut
 165
 166 sub search_rs {
 167   my $self = shift;
 168
 169   my $rows;
 170
 171   unless (@_) {                 # no search, effectively just a clone
 172     $rows = $self->get_cache;
 173   }
 174
 175   my $attrs = {};
 176   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 177   my $our_attrs = { %{$self->{attrs}} };
 178   my $having = delete $our_attrs->{having};
 179   my $where = delete $our_attrs->{where};
 180
 181   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 182
 183   # merge new attrs into inherited
 184   foreach my $key (qw/join prefetch/) {
 185     next unless exists $attrs->{$key};
 186     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 187   }
 188
 189   my $cond = (@_
 190     ? (
 191         (@_ == 1 || ref $_[0] eq "HASH")
 192           ? (
 193               (ref $_[0] eq 'HASH')
 194                 ? (
 195                     (keys %{ $_[0] }  > 0)
 196                       ? shift
 197                       : undef
 198                    )
 199                 :  shift
 200              )
 201           : (
 202               (@_ % 2)
 203                 ? $self->throw_exception("Odd number of arguments to search")
 204                 : {@_}
 205              )
 206       )
 207     : undef
 208   );
 209
 210   if (defined $where) {
 211     $new_attrs->{where} = (
 212       defined $new_attrs->{where}
 213         ? { '-and' => [
 214               map {
 215                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 216               } $where, $new_attrs->{where}
 217             ]
 218           }
 219         : $where);
 220   }
 221
 222   if (defined $cond) {
 223     $new_attrs->{where} = (
 224       defined $new_attrs->{where}
 225         ? { '-and' => [
 226               map {
 227                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 228               } $cond, $new_attrs->{where}
 229             ]
 230           }
 231         : $cond);
 232   }
 233
 234   if (defined $having) {
 235     $new_attrs->{having} = (
 236       defined $new_attrs->{having}
 237         ? { '-and' => [
 238               map {
 239                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 240               } $having, $new_attrs->{having}
 241             ]
 242           }
 243         : $having);
 244   }
 245
 246   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 247   if ($rows) {
 248     $rs->set_cache($rows);
 249   }
 250   return $rs;
 251 }
 252
 253 =head2 search_literal
 254
 255 =over 4
 256
 257 =item Arguments: $sql_fragment, @bind_values
 258
 259 =item Return Value: $resultset (scalar context), @row_objs (list context)
 260
 261 =back
 262
 263   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 264   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 265
 266 Pass a literal chunk of SQL to be added to the conditional part of the
 267 resultset query.
 268
 269 =cut
 270
 271 sub search_literal {
 272   my ($self, $cond, @vals) = @_;
 273   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 274   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 275   return $self->search(\$cond, $attrs);
 276 }
 277
 278 =head2 find
 279
 280 =over 4
 281
 282 =item Arguments: @values | \%cols, \%attrs?
 283
 284 =item Return Value: $row_object
 285
 286 =back
 287
 288 Finds a row based on its primary key or unique constraint. For example, to find
 289 a row by its primary key:
 290
 291   my $cd = $schema->resultset('CD')->find(5);
 292
 293 You can also find a row by a specific unique constraint using the C<key>
 294 attribute. For example:
 295
 296   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 297     key => 'cd_artist_title'
 298   });
 299
 300 Additionally, you can specify the columns explicitly by name:
 301
 302   my $cd = $schema->resultset('CD')->find(
 303     {
 304       artist => 'Massive Attack',
 305       title  => 'Mezzanine',
 306     },
 307     { key => 'cd_artist_title' }
 308   );
 309
 310 If the C<key> is specified as C<primary>, it searches only on the primary key.
 311
 312 If no C<key> is specified, it searches on all unique constraints defined on the
 313 source, including the primary key.
 314
 315 If your table does not have a primary key, you B<must> provide a value for the
 316 C<key> attribute matching one of the unique constraints on the source.
 317
 318 See also L</find_or_create> and L</update_or_create>. For information on how to
 319 declare unique constraints, see
 320 L<DBIx::Class::ResultSource/add_unique_constraint>.
 321
 322 =cut
 323
 324 sub find {
 325   my $self = shift;
 326   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 327
 328   # Default to the primary key, but allow a specific key
 329   my @cols = exists $attrs->{key}
 330     ? $self->result_source->unique_constraint_columns($attrs->{key})
 331     : $self->result_source->primary_columns;
 332   $self->throw_exception(
 333     "Can't find unless a primary key is defined or unique constraint is specified"
 334   ) unless @cols;
 335
 336   # Parse out a hashref from input
 337   my $input_query;
 338   if (ref $_[0] eq 'HASH') {
 339     $input_query = { %{$_[0]} };
 340   }
 341   elsif (@_ == @cols) {
 342     $input_query = {};
 343     @{$input_query}{@cols} = @_;
 344   }
 345   else {
 346     # Compatibility: Allow e.g. find(id => $value)
 347     carp "Find by key => value deprecated; please use a hashref instead";
 348     $input_query = {@_};
 349   }
 350
 351   my (%related, $info);
 352
 353   KEY: foreach my $key (keys %$input_query) {
 354     if (ref($input_query->{$key})
 355         && ($info = $self->result_source->relationship_info($key))) {
 356       my $val = delete $input_query->{$key};
 357       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 358       my $rel_q = $self->result_source->resolve_condition(
 359                     $info->{cond}, $val, $key
 360                   );
 361       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 362       @related{keys %$rel_q} = values %$rel_q;
 363     }
 364   }
 365   if (my @keys = keys %related) {
 366     @{$input_query}{@keys} = values %related;
 367   }
 368
 369   my @unique_queries = $self->_unique_queries($input_query, $attrs);
 370
 371   # Build the final query: Default to the disjunction of the unique queries,
 372   # but allow the input query in case the ResultSet defines the query or the
 373   # user is abusing find
 374   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 375   my $query = @unique_queries
 376     ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 377     : $self->_add_alias($input_query, $alias);
 378
 379   # Run the query
 380   if (keys %$attrs) {
 381     my $rs = $self->search($query, $attrs);
 382     return keys %{$rs->_resolved_attrs->{collapse}} ? $rs->next : $rs->single;
 383   }
 384   else {
 385     return keys %{$self->_resolved_attrs->{collapse}}
 386       ? $self->search($query)->next
 387       : $self->single($query);
 388   }
 389 }
 390
 391 # _add_alias
 392 #
 393 # Add the specified alias to the specified query hash. A copy is made so the
 394 # original query is not modified.
 395
 396 sub _add_alias {
 397   my ($self, $query, $alias) = @_;
 398
 399   my %aliased = %$query;
 400   foreach my $col (grep { ! m/\./ } keys %aliased) {
 401     $aliased{"$alias.$col"} = delete $aliased{$col};
 402   }
 403
 404   return \%aliased;
 405 }
 406
 407 # _unique_queries
 408 #
 409 # Build a list of queries which satisfy unique constraints.
 410
 411 sub _unique_queries {
 412   my ($self, $query, $attrs) = @_;
 413
 414   my @constraint_names = exists $attrs->{key}
 415     ? ($attrs->{key})
 416     : $self->result_source->unique_constraint_names;
 417
 418   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 419   my $num_where = scalar keys %$where;
 420
 421   my @unique_queries;
 422   foreach my $name (@constraint_names) {
 423     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 424     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 425
 426     my $num_cols = scalar @unique_cols;
 427     my $num_query = scalar keys %$unique_query;
 428
 429     my $total = $num_query + $num_where;
 430     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 431       # The query is either unique on its own or is unique in combination with
 432       # the existing where clause
 433       push @unique_queries, $unique_query;
 434     }
 435   }
 436
 437   return @unique_queries;
 438 }
 439
 440 # _build_unique_query
 441 #
 442 # Constrain the specified query hash based on the specified column names.
 443
 444 sub _build_unique_query {
 445   my ($self, $query, $unique_cols) = @_;
 446
 447   return {
 448     map  { $_ => $query->{$_} }
 449     grep { exists $query->{$_} }
 450       @$unique_cols
 451   };
 452 }
 453
 454 =head2 search_related
 455
 456 =over 4
 457
 458 =item Arguments: $rel, $cond, \%attrs?
 459
 460 =item Return Value: $new_resultset
 461
 462 =back
 463
 464   $new_rs = $cd_rs->search_related('artist', {
 465     name => 'Emo-R-Us',
 466   });
 467
 468 Searches the specified relationship, optionally specifying a condition and
 469 attributes for matching records. See L</ATTRIBUTES> for more information.
 470
 471 =cut
 472
 473 sub search_related {
 474   return shift->related_resultset(shift)->search(@_);
 475 }
 476
 477 =head2 cursor
 478
 479 =over 4
 480
 481 =item Arguments: none
 482
 483 =item Return Value: $cursor
 484
 485 =back
 486
 487 Returns a storage-driven cursor to the given resultset. See
 488 L<DBIx::Class::Cursor> for more information.
 489
 490 =cut
 491
 492 sub cursor {
 493   my ($self) = @_;
 494
 495   my $attrs = { %{$self->_resolved_attrs} };
 496   return $self->{cursor}
 497     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 498           $attrs->{where},$attrs);
 499 }
 500
 501 =head2 single
 502
 503 =over 4
 504
 505 =item Arguments: $cond?
 506
 507 =item Return Value: $row_object?
 508
 509 =back
 510
 511   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 512
 513 Inflates the first result without creating a cursor if the resultset has
 514 any records in it; if not returns nothing. Used by L</find> as an optimisation.
 515
 516 Can optionally take an additional condition *only* - this is a fast-code-path
 517 method; if you need to add extra joins or similar call ->search and then
 518 ->single without a condition on the $rs returned from that.
 519
 520 =cut
 521
 522 sub single {
 523   my ($self, $where) = @_;
 524   my $attrs = { %{$self->_resolved_attrs} };
 525   if ($where) {
 526     if (defined $attrs->{where}) {
 527       $attrs->{where} = {
 528         '-and' =>
 529             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 530                $where, delete $attrs->{where} ]
 531       };
 532     } else {
 533       $attrs->{where} = $where;
 534     }
 535   }
 536
 537 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 538 #  unless ($self->_is_unique_query($attrs->{where})) {
 539 #    carp "Query not guaranteed to return a single row"
 540 #      . "; please declare your unique constraints or use search instead";
 541 #  }
 542
 543   my @data = $self->result_source->storage->select_single(
 544     $attrs->{from}, $attrs->{select},
 545     $attrs->{where}, $attrs
 546   );
 547
 548   return (@data ? ($self->_construct_object(@data))[0] : ());
 549 }
 550
 551 # _is_unique_query
 552 #
 553 # Try to determine if the specified query is guaranteed to be unique, based on
 554 # the declared unique constraints.
 555
 556 sub _is_unique_query {
 557   my ($self, $query) = @_;
 558
 559   my $collapsed = $self->_collapse_query($query);
 560   my $alias = $self->{attrs}{alias};
 561
 562   foreach my $name ($self->result_source->unique_constraint_names) {
 563     my @unique_cols = map {
 564       "$alias.$_"
 565     } $self->result_source->unique_constraint_columns($name);
 566
 567     # Count the values for each unique column
 568     my %seen = map { $_ => 0 } @unique_cols;
 569
 570     foreach my $key (keys %$collapsed) {
 571       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 572       next unless exists $seen{$aliased};  # Additional constraints are okay
 573       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 574     }
 575
 576     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 577     return 1 unless grep { $_ != 1 } values %seen;
 578   }
 579
 580   return 0;
 581 }
 582
 583 # _collapse_query
 584 #
 585 # Recursively collapse the query, accumulating values for each column.
 586
 587 sub _collapse_query {
 588   my ($self, $query, $collapsed) = @_;
 589
 590   $collapsed ||= {};
 591
 592   if (ref $query eq 'ARRAY') {
 593     foreach my $subquery (@$query) {
 594       next unless ref $subquery;  # -or
 595 #      warn "ARRAY: " . Dumper $subquery;
 596       $collapsed = $self->_collapse_query($subquery, $collapsed);
 597     }
 598   }
 599   elsif (ref $query eq 'HASH') {
 600     if (keys %$query and (keys %$query)[0] eq '-and') {
 601       foreach my $subquery (@{$query->{-and}}) {
 602 #        warn "HASH: " . Dumper $subquery;
 603         $collapsed = $self->_collapse_query($subquery, $collapsed);
 604       }
 605     }
 606     else {
 607 #      warn "LEAF: " . Dumper $query;
 608       foreach my $col (keys %$query) {
 609         my $value = $query->{$col};
 610         $collapsed->{$col}{$value}++;
 611       }
 612     }
 613   }
 614
 615   return $collapsed;
 616 }
 617
 618 =head2 get_column
 619
 620 =over 4
 621
 622 =item Arguments: $cond?
 623
 624 =item Return Value: $resultsetcolumn
 625
 626 =back
 627
 628   my $max_length = $rs->get_column('length')->max;
 629
 630 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 631
 632 =cut
 633
 634 sub get_column {
 635   my ($self, $column) = @_;
 636   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 637   return $new;
 638 }
 639
 640 =head2 search_like
 641
 642 =over 4
 643
 644 =item Arguments: $cond, \%attrs?
 645
 646 =item Return Value: $resultset (scalar context), @row_objs (list context)
 647
 648 =back
 649
 650   # WHERE title LIKE '%blue%'
 651   $cd_rs = $rs->search_like({ title => '%blue%'});
 652
 653 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 654 that this is simply a convenience method. You most likely want to use
 655 L</search> with specific operators.
 656
 657 For more information, see L<DBIx::Class::Manual::Cookbook>.
 658
 659 =cut
 660
 661 sub search_like {
 662   my $class = shift;
 663   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 664   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 665   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 666   return $class->search($query, { %$attrs });
 667 }
 668
 669 =head2 slice
 670
 671 =over 4
 672
 673 =item Arguments: $first, $last
 674
 675 =item Return Value: $resultset (scalar context), @row_objs (list context)
 676
 677 =back
 678
 679 Returns a resultset or object list representing a subset of elements from the
 680 resultset slice is called on. Indexes are from 0, i.e., to get the first
 681 three records, call:
 682
 683   my ($one, $two, $three) = $rs->slice(0, 2);
 684
 685 =cut
 686
 687 sub slice {
 688   my ($self, $min, $max) = @_;
 689   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 690   $attrs->{offset} = $self->{attrs}{offset} || 0;
 691   $attrs->{offset} += $min;
 692   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 693   return $self->search(undef(), $attrs);
 694   #my $slice = (ref $self)->new($self->result_source, $attrs);
 695   #return (wantarray ? $slice->all : $slice);
 696 }
 697
 698 =head2 next
 699
 700 =over 4
 701
 702 =item Arguments: none
 703
 704 =item Return Value: $result?
 705
 706 =back
 707
 708 Returns the next element in the resultset (C<undef> is there is none).
 709
 710 Can be used to efficiently iterate over records in the resultset:
 711
 712   my $rs = $schema->resultset('CD')->search;
 713   while (my $cd = $rs->next) {
 714     print $cd->title;
 715   }
 716
 717 Note that you need to store the resultset object, and call C<next> on it.
 718 Calling C<< resultset('Table')->next >> repeatedly will always return the
 719 first record from the resultset.
 720
 721 =cut
 722
 723 sub next {
 724   my ($self) = @_;
 725   if (my $cache = $self->get_cache) {
 726     $self->{all_cache_position} ||= 0;
 727     return $cache->[$self->{all_cache_position}++];
 728   }
 729   if ($self->{attrs}{cache}) {
 730     $self->{all_cache_position} = 1;
 731     return ($self->all)[0];
 732   }
 733   if ($self->{stashed_objects}) {
 734     my $obj = shift(@{$self->{stashed_objects}});
 735     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 736     return $obj;
 737   }
 738   my @row = (
 739     exists $self->{stashed_row}
 740       ? @{delete $self->{stashed_row}}
 741       : $self->cursor->next
 742   );
 743   return unless (@row);
 744   my ($row, @more) = $self->_construct_object(@row);
 745   $self->{stashed_objects} = \@more if @more;
 746   return $row;
 747 }
 748
 749 sub _construct_object {
 750   my ($self, @row) = @_;
 751   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 752   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 753   @new = $self->{_attrs}{record_filter}->(@new)
 754     if exists $self->{_attrs}{record_filter};
 755   return @new;
 756 }
 757
 758 sub _collapse_result {
 759   my ($self, $as_proto, $row) = @_;
 760
 761   my @copy = @$row;
 762
 763   # 'foo'         => [ undef, 'foo' ]
 764   # 'foo.bar'     => [ 'foo', 'bar' ]
 765   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 766
 767   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 768
 769   my %collapse = %{$self->{_attrs}{collapse}||{}};
 770
 771   my @pri_index;
 772
 773   # if we're doing collapsing (has_many prefetch) we need to grab records
 774   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 775   # we know we don't have to bother.
 776
 777   # the reason for not using the collapse stuff directly is because if you
 778   # had for e.g. two artists in a row with no cds, the collapse info for
 779   # both would be NULL (undef) so you'd lose the second artist
 780
 781   # store just the index so we can check the array positions from the row
 782   # without having to contruct the full hash
 783
 784   if (keys %collapse) {
 785     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 786     foreach my $i (0 .. $#construct_as) {
 787       next if defined($construct_as[$i][0]); # only self table
 788       if (delete $pri{$construct_as[$i][1]}) {
 789         push(@pri_index, $i);
 790       }
 791       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 792     }
 793   }
 794
 795   # no need to do an if, it'll be empty if @pri_index is empty anyway
 796
 797   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 798
 799   my @const_rows;
 800
 801   do { # no need to check anything at the front, we always want the first row
 802
 803     my %const;
 804
 805     foreach my $this_as (@construct_as) {
 806       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 807     }
 808
 809     push(@const_rows, \%const);
 810
 811   } until ( # no pri_index => no collapse => drop straight out
 812       !@pri_index
 813     or
 814       do { # get another row, stash it, drop out if different PK
 815
 816         @copy = $self->cursor->next;
 817         $self->{stashed_row} = \@copy;
 818
 819         # last thing in do block, counts as true if anything doesn't match
 820
 821         # check xor defined first for NULL vs. NOT NULL then if one is
 822         # defined the other must be so check string equality
 823
 824         grep {
 825           (defined $pri_vals{$_} ^ defined $copy[$_])
 826           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 827         } @pri_index;
 828       }
 829   );
 830
 831   my $alias = $self->{attrs}{alias};
 832   my $info = [];
 833
 834   my %collapse_pos;
 835
 836   my @const_keys;
 837
 838   use Data::Dumper;
 839
 840   foreach my $const (@const_rows) {
 841     scalar @const_keys or do {
 842       @const_keys = sort { length($a) <=> length($b) } keys %$const;
 843     };
 844     foreach my $key (@const_keys) {
 845       if (length $key) {
 846         my $target = $info;
 847         my @parts = split(/\./, $key);
 848         my $cur = '';
 849         my $data = $const->{$key};
 850         foreach my $p (@parts) {
 851           $target = $target->[1]->{$p} ||= [];
 852           $cur .= ".${p}";
 853           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
 854             # collapsing at this point and on final part
 855             my $pos = $collapse_pos{$cur};
 856             CK: foreach my $ck (@ckey) {
 857               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
 858                 $collapse_pos{$cur} = $data;
 859                 delete @collapse_pos{ # clear all positioning for sub-entries
 860                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
 861                 };
 862                 push(@$target, []);
 863                 last CK;
 864               }
 865             }
 866           }
 867           if (exists $collapse{$cur}) {
 868             $target = $target->[-1];
 869           }
 870         }
 871         $target->[0] = $data;
 872       } else {
 873         $info->[0] = $const->{$key};
 874       }
 875     }
 876   }
 877
 878   return $info;
 879 }
 880
 881 =head2 result_source
 882
 883 =over 4
 884
 885 =item Arguments: $result_source?
 886
 887 =item Return Value: $result_source
 888
 889 =back
 890
 891 An accessor for the primary ResultSource object from which this ResultSet
 892 is derived.
 893
 894 =head2 result_class
 895
 896 =over 4
 897
 898 =item Arguments: $result_class?
 899
 900 =item Return Value: $result_class
 901
 902 =back
 903
 904 An accessor for the class to use when creating row objects. Defaults to
 905 C<< result_source->result_class >> - which in most cases is the name of the
 906 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
 907
 908 =cut
 909
 910
 911 =head2 count
 912
 913 =over 4
 914
 915 =item Arguments: $cond, \%attrs??
 916
 917 =item Return Value: $count
 918
 919 =back
 920
 921 Performs an SQL C<COUNT> with the same query as the resultset was built
 922 with to find the number of elements. If passed arguments, does a search
 923 on the resultset and counts the results of that.
 924
 925 Note: When using C<count> with C<group_by>, L<DBIX::Class> emulates C<GROUP BY>
 926 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
 927 not support C<DISTINCT> with multiple columns. If you are using such a
 928 database, you should only use columns from the main table in your C<group_by>
 929 clause.
 930
 931 =cut
 932
 933 sub count {
 934   my $self = shift;
 935   return $self->search(@_)->count if @_ and defined $_[0];
 936   return scalar @{ $self->get_cache } if $self->get_cache;
 937   my $count = $self->_count;
 938   return 0 unless $count;
 939
 940   $count -= $self->{attrs}{offset} if $self->{attrs}{offset};
 941   $count = $self->{attrs}{rows} if
 942     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
 943   return $count;
 944 }
 945
 946 sub _count { # Separated out so pager can get the full count
 947   my $self = shift;
 948   my $select = { count => '*' };
 949
 950   my $attrs = { %{$self->_resolved_attrs} };
 951   if (my $group_by = delete $attrs->{group_by}) {
 952     delete $attrs->{having};
 953     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
 954     # todo: try CONCAT for multi-column pk
 955     my @pk = $self->result_source->primary_columns;
 956     if (@pk == 1) {
 957       my $alias = $attrs->{alias};
 958       foreach my $column (@distinct) {
 959         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
 960           @distinct = ($column);
 961           last;
 962         }
 963       }
 964     }
 965
 966     $select = { count => { distinct => \@distinct } };
 967   }
 968
 969   $attrs->{select} = $select;
 970   $attrs->{as} = [qw/count/];
 971
 972   # offset, order by and page are not needed to count. record_filter is cdbi
 973   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
 974
 975   my $tmp_rs = (ref $self)->new($self->_source_handle, $attrs);
 976   my ($count) = $tmp_rs->cursor->next;
 977   return $count;
 978 }
 979
 980 =head2 count_literal
 981
 982 =over 4
 983
 984 =item Arguments: $sql_fragment, @bind_values
 985
 986 =item Return Value: $count
 987
 988 =back
 989
 990 Counts the results in a literal query. Equivalent to calling L</search_literal>
 991 with the passed arguments, then L</count>.
 992
 993 =cut
 994
 995 sub count_literal { shift->search_literal(@_)->count; }
 996
 997 =head2 all
 998
 999 =over 4
1000
1001 =item Arguments: none
1002
1003 =item Return Value: @objects
1004
1005 =back
1006
1007 Returns all elements in the resultset. Called implicitly if the resultset
1008 is returned in list context.
1009
1010 =cut
1011
1012 sub all {
1013   my ($self) = @_;
1014   return @{ $self->get_cache } if $self->get_cache;
1015
1016   my @obj;
1017
1018   # TODO: don't call resolve here
1019   if (keys %{$self->_resolved_attrs->{collapse}}) {
1020 #  if ($self->{attrs}{prefetch}) {
1021       # Using $self->cursor->all is really just an optimisation.
1022       # If we're collapsing has_many prefetches it probably makes
1023       # very little difference, and this is cleaner than hacking
1024       # _construct_object to survive the approach
1025     my @row = $self->cursor->next;
1026     while (@row) {
1027       push(@obj, $self->_construct_object(@row));
1028       @row = (exists $self->{stashed_row}
1029                ? @{delete $self->{stashed_row}}
1030                : $self->cursor->next);
1031     }
1032   } else {
1033     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1034   }
1035
1036   $self->set_cache(\@obj) if $self->{attrs}{cache};
1037   return @obj;
1038 }
1039
1040 =head2 reset
1041
1042 =over 4
1043
1044 =item Arguments: none
1045
1046 =item Return Value: $self
1047
1048 =back
1049
1050 Resets the resultset's cursor, so you can iterate through the elements again.
1051
1052 =cut
1053
1054 sub reset {
1055   my ($self) = @_;
1056   delete $self->{_attrs} if exists $self->{_attrs};
1057   $self->{all_cache_position} = 0;
1058   $self->cursor->reset;
1059   return $self;
1060 }
1061
1062 =head2 first
1063
1064 =over 4
1065
1066 =item Arguments: none
1067
1068 =item Return Value: $object?
1069
1070 =back
1071
1072 Resets the resultset and returns an object for the first result (if the
1073 resultset returns anything).
1074
1075 =cut
1076
1077 sub first {
1078   return $_[0]->reset->next;
1079 }
1080
1081 # _cond_for_update_delete
1082 #
1083 # update/delete require the condition to be modified to handle
1084 # the differing SQL syntax available.  This transforms the $self->{cond}
1085 # appropriately, returning the new condition.
1086
1087 sub _cond_for_update_delete {
1088   my ($self, $full_cond) = @_;
1089   my $cond = {};
1090
1091   $full_cond ||= $self->{cond};
1092   # No-op. No condition, we're updating/deleting everything
1093   return $cond unless ref $full_cond;
1094
1095   if (ref $full_cond eq 'ARRAY') {
1096     $cond = [
1097       map {
1098         my %hash;
1099         foreach my $key (keys %{$_}) {
1100           $key =~ /([^.]+)$/;
1101           $hash{$1} = $_->{$key};
1102         }
1103         \%hash;
1104       } @{$full_cond}
1105     ];
1106   }
1107   elsif (ref $full_cond eq 'HASH') {
1108     if ((keys %{$full_cond})[0] eq '-and') {
1109       $cond->{-and} = [];
1110
1111       my @cond = @{$full_cond->{-and}};
1112       for (my $i = 0; $i < @cond; $i++) {
1113         my $entry = $cond[$i];
1114
1115         my $hash;
1116         if (ref $entry eq 'HASH') {
1117           $hash = $self->_cond_for_update_delete($entry);
1118         }
1119         else {
1120           $entry =~ /([^.]+)$/;
1121           $hash->{$1} = $cond[++$i];
1122         }
1123
1124         push @{$cond->{-and}}, $hash;
1125       }
1126     }
1127     else {
1128       foreach my $key (keys %{$full_cond}) {
1129         $key =~ /([^.]+)$/;
1130         $cond->{$1} = $full_cond->{$key};
1131       }
1132     }
1133   }
1134   else {
1135     $self->throw_exception(
1136       "Can't update/delete on resultset with condition unless hash or array"
1137     );
1138   }
1139
1140   return $cond;
1141 }
1142
1143
1144 =head2 update
1145
1146 =over 4
1147
1148 =item Arguments: \%values
1149
1150 =item Return Value: $storage_rv
1151
1152 =back
1153
1154 Sets the specified columns in the resultset to the supplied values in a
1155 single query. Return value will be true if the update succeeded or false
1156 if no records were updated; exact type of success value is storage-dependent.
1157
1158 =cut
1159
1160 sub update {
1161   my ($self, $values) = @_;
1162   $self->throw_exception("Values for update must be a hash")
1163     unless ref $values eq 'HASH';
1164
1165   my $cond = $self->_cond_for_update_delete;
1166
1167   return $self->result_source->storage->update(
1168     $self->result_source, $values, $cond
1169   );
1170 }
1171
1172 =head2 update_all
1173
1174 =over 4
1175
1176 =item Arguments: \%values
1177
1178 =item Return Value: 1
1179
1180 =back
1181
1182 Fetches all objects and updates them one at a time. Note that C<update_all>
1183 will run DBIC cascade triggers, while L</update> will not.
1184
1185 =cut
1186
1187 sub update_all {
1188   my ($self, $values) = @_;
1189   $self->throw_exception("Values for update must be a hash")
1190     unless ref $values eq 'HASH';
1191   foreach my $obj ($self->all) {
1192     $obj->set_columns($values)->update;
1193   }
1194   return 1;
1195 }
1196
1197 =head2 delete
1198
1199 =over 4
1200
1201 =item Arguments: none
1202
1203 =item Return Value: 1
1204
1205 =back
1206
1207 Deletes the contents of the resultset from its result source. Note that this
1208 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1209 to run. See also L<DBIx::Class::Row/delete>.
1210
1211 =cut
1212
1213 sub delete {
1214   my ($self) = @_;
1215
1216   my $cond = $self->_cond_for_update_delete;
1217
1218   $self->result_source->storage->delete($self->result_source, $cond);
1219   return 1;
1220 }
1221
1222 =head2 delete_all
1223
1224 =over 4
1225
1226 =item Arguments: none
1227
1228 =item Return Value: 1
1229
1230 =back
1231
1232 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1233 will run DBIC cascade triggers, while L</delete> will not.
1234
1235 =cut
1236
1237 sub delete_all {
1238   my ($self) = @_;
1239   $_->delete for $self->all;
1240   return 1;
1241 }
1242
1243 =head2 pager
1244
1245 =over 4
1246
1247 =item Arguments: none
1248
1249 =item Return Value: $pager
1250
1251 =back
1252
1253 Return Value a L<Data::Page> object for the current resultset. Only makes
1254 sense for queries with a C<page> attribute.
1255
1256 =cut
1257
1258 sub pager {
1259   my ($self) = @_;
1260   my $attrs = $self->{attrs};
1261   $self->throw_exception("Can't create pager for non-paged rs")
1262     unless $self->{attrs}{page};
1263   $attrs->{rows} ||= 10;
1264   return $self->{pager} ||= Data::Page->new(
1265     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1266 }
1267
1268 =head2 page
1269
1270 =over 4
1271
1272 =item Arguments: $page_number
1273
1274 =item Return Value: $rs
1275
1276 =back
1277
1278 Returns a resultset for the $page_number page of the resultset on which page
1279 is called, where each page contains a number of rows equal to the 'rows'
1280 attribute set on the resultset (10 by default).
1281
1282 =cut
1283
1284 sub page {
1285   my ($self, $page) = @_;
1286   return (ref $self)->new($self->_source_handle, { %{$self->{attrs}}, page => $page });
1287 }
1288
1289 =head2 new_result
1290
1291 =over 4
1292
1293 =item Arguments: \%vals
1294
1295 =item Return Value: $object
1296
1297 =back
1298
1299 Creates an object in the resultset's result class and returns it.
1300
1301 =cut
1302
1303 sub new_result {
1304   my ($self, $values) = @_;
1305   $self->throw_exception( "new_result needs a hash" )
1306     unless (ref $values eq 'HASH');
1307   $self->throw_exception(
1308     "Can't abstract implicit construct, condition not a hash"
1309   ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1310
1311   my $alias = $self->{attrs}{alias};
1312   my $collapsed_cond = $self->{cond} ? $self->_collapse_cond($self->{cond}) : {};
1313   my %new = (
1314     %{ $self->_remove_alias($values, $alias) },
1315     %{ $self->_remove_alias($collapsed_cond, $alias) },
1316     -source_handle => $self->_source_handle
1317   );
1318
1319   return $self->result_class->new(\%new);
1320 }
1321
1322 # _collapse_cond
1323 #
1324 # Recursively collapse the condition.
1325
1326 sub _collapse_cond {
1327   my ($self, $cond, $collapsed) = @_;
1328
1329   $collapsed ||= {};
1330
1331   if (ref $cond eq 'ARRAY') {
1332     foreach my $subcond (@$cond) {
1333       next unless ref $subcond;  # -or
1334 #      warn "ARRAY: " . Dumper $subcond;
1335       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1336     }
1337   }
1338   elsif (ref $cond eq 'HASH') {
1339     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1340       foreach my $subcond (@{$cond->{-and}}) {
1341 #        warn "HASH: " . Dumper $subcond;
1342         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1343       }
1344     }
1345     else {
1346 #      warn "LEAF: " . Dumper $cond;
1347       foreach my $col (keys %$cond) {
1348         my $value = $cond->{$col};
1349         $collapsed->{$col} = $value;
1350       }
1351     }
1352   }
1353
1354   return $collapsed;
1355 }
1356
1357 # _remove_alias
1358 #
1359 # Remove the specified alias from the specified query hash. A copy is made so
1360 # the original query is not modified.
1361
1362 sub _remove_alias {
1363   my ($self, $query, $alias) = @_;
1364
1365   my %orig = %{ $query || {} };
1366   my %unaliased;
1367
1368   foreach my $key (keys %orig) {
1369     if ($key !~ /\./) {
1370       $unaliased{$key} = $orig{$key};
1371       next;
1372     }
1373     $unaliased{$1} = $orig{$key}
1374       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1375   }
1376
1377   return \%unaliased;
1378 }
1379
1380 =head2 find_or_new
1381
1382 =over 4
1383
1384 =item Arguments: \%vals, \%attrs?
1385
1386 =item Return Value: $object
1387
1388 =back
1389
1390 Find an existing record from this resultset. If none exists, instantiate a new
1391 result object and return it. The object will not be saved into your storage
1392 until you call L<DBIx::Class::Row/insert> on it.
1393
1394 If you want objects to be saved immediately, use L</find_or_create> instead.
1395
1396 =cut
1397
1398 sub find_or_new {
1399   my $self     = shift;
1400   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1401   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1402   my $exists   = $self->find($hash, $attrs);
1403   return defined $exists ? $exists : $self->new_result($hash);
1404 }
1405
1406 =head2 create
1407
1408 =over 4
1409
1410 =item Arguments: \%vals
1411
1412 =item Return Value: $object
1413
1414 =back
1415
1416 Inserts a record into the resultset and returns the object representing it.
1417
1418 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1419
1420 =cut
1421
1422 sub create {
1423   my ($self, $attrs) = @_;
1424   $self->throw_exception( "create needs a hashref" )
1425     unless ref $attrs eq 'HASH';
1426   return $self->new_result($attrs)->insert;
1427 }
1428
1429 =head2 find_or_create
1430
1431 =over 4
1432
1433 =item Arguments: \%vals, \%attrs?
1434
1435 =item Return Value: $object
1436
1437 =back
1438
1439   $class->find_or_create({ key => $val, ... });
1440
1441 Tries to find a record based on its primary key or unique constraint; if none
1442 is found, creates one and returns that instead.
1443
1444   my $cd = $schema->resultset('CD')->find_or_create({
1445     cdid   => 5,
1446     artist => 'Massive Attack',
1447     title  => 'Mezzanine',
1448     year   => 2005,
1449   });
1450
1451 Also takes an optional C<key> attribute, to search by a specific key or unique
1452 constraint. For example:
1453
1454   my $cd = $schema->resultset('CD')->find_or_create(
1455     {
1456       artist => 'Massive Attack',
1457       title  => 'Mezzanine',
1458     },
1459     { key => 'cd_artist_title' }
1460   );
1461
1462 See also L</find> and L</update_or_create>. For information on how to declare
1463 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1464
1465 =cut
1466
1467 sub find_or_create {
1468   my $self     = shift;
1469   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1470   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1471   my $exists   = $self->find($hash, $attrs);
1472   return defined $exists ? $exists : $self->create($hash);
1473 }
1474
1475 =head2 update_or_create
1476
1477 =over 4
1478
1479 =item Arguments: \%col_values, { key => $unique_constraint }?
1480
1481 =item Return Value: $object
1482
1483 =back
1484
1485   $class->update_or_create({ col => $val, ... });
1486
1487 First, searches for an existing row matching one of the unique constraints
1488 (including the primary key) on the source of this resultset. If a row is
1489 found, updates it with the other given column values. Otherwise, creates a new
1490 row.
1491
1492 Takes an optional C<key> attribute to search on a specific unique constraint.
1493 For example:
1494
1495   # In your application
1496   my $cd = $schema->resultset('CD')->update_or_create(
1497     {
1498       artist => 'Massive Attack',
1499       title  => 'Mezzanine',
1500       year   => 1998,
1501     },
1502     { key => 'cd_artist_title' }
1503   );
1504
1505 If no C<key> is specified, it searches on all unique constraints defined on the
1506 source, including the primary key.
1507
1508 If the C<key> is specified as C<primary>, it searches only on the primary key.
1509
1510 See also L</find> and L</find_or_create>. For information on how to declare
1511 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1512
1513 =cut
1514
1515 sub update_or_create {
1516   my $self = shift;
1517   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1518   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
1519
1520   my $row = $self->find($cond, $attrs);
1521   if (defined $row) {
1522     $row->update($cond);
1523     return $row;
1524   }
1525
1526   return $self->create($cond);
1527 }
1528
1529 =head2 get_cache
1530
1531 =over 4
1532
1533 =item Arguments: none
1534
1535 =item Return Value: \@cache_objects?
1536
1537 =back
1538
1539 Gets the contents of the cache for the resultset, if the cache is set.
1540
1541 =cut
1542
1543 sub get_cache {
1544   shift->{all_cache};
1545 }
1546
1547 =head2 set_cache
1548
1549 =over 4
1550
1551 =item Arguments: \@cache_objects
1552
1553 =item Return Value: \@cache_objects
1554
1555 =back
1556
1557 Sets the contents of the cache for the resultset. Expects an arrayref
1558 of objects of the same class as those produced by the resultset. Note that
1559 if the cache is set the resultset will return the cached objects rather
1560 than re-querying the database even if the cache attr is not set.
1561
1562 =cut
1563
1564 sub set_cache {
1565   my ( $self, $data ) = @_;
1566   $self->throw_exception("set_cache requires an arrayref")
1567       if defined($data) && (ref $data ne 'ARRAY');
1568   $self->{all_cache} = $data;
1569 }
1570
1571 =head2 clear_cache
1572
1573 =over 4
1574
1575 =item Arguments: none
1576
1577 =item Return Value: []
1578
1579 =back
1580
1581 Clears the cache for the resultset.
1582
1583 =cut
1584
1585 sub clear_cache {
1586   shift->set_cache(undef);
1587 }
1588
1589 =head2 related_resultset
1590
1591 =over 4
1592
1593 =item Arguments: $relationship_name
1594
1595 =item Return Value: $resultset
1596
1597 =back
1598
1599 Returns a related resultset for the supplied relationship name.
1600
1601   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1602
1603 =cut
1604
1605 sub related_resultset {
1606   my ($self, $rel) = @_;
1607
1608   $self->{related_resultsets} ||= {};
1609   return $self->{related_resultsets}{$rel} ||= do {
1610     my $rel_obj = $self->result_source->relationship_info($rel);
1611
1612     $self->throw_exception(
1613       "search_related: result source '" . $self->_source_handle->source_moniker .
1614         "' has no such relationship $rel")
1615       unless $rel_obj;
1616
1617     my ($from,$seen) = $self->_resolve_from($rel);
1618
1619     my $join_count = $seen->{$rel};
1620     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
1621
1622     $self->_source_handle->schema->resultset($rel_obj->{class})->search_rs(
1623       undef, {
1624         %{$self->{attrs}||{}},
1625         join => undef,
1626         prefetch => undef,
1627         select => undef,
1628         as => undef,
1629         alias => $alias,
1630         where => $self->{cond},
1631         seen_join => $seen,
1632         from => $from,
1633     });
1634   };
1635 }
1636
1637 sub _resolve_from {
1638   my ($self, $extra_join) = @_;
1639   my $source = $self->result_source;
1640   my $attrs = $self->{attrs};
1641
1642   my $from = $attrs->{from}
1643     || [ { $attrs->{alias} => $source->from } ];
1644
1645   my $seen = { %{$attrs->{seen_join}||{}} };
1646
1647   my $join = ($attrs->{join}
1648                ? [ $attrs->{join}, $extra_join ]
1649                : $extra_join);
1650   $from = [
1651     @$from,
1652     ($join ? $source->resolve_join($join, $attrs->{alias}, $seen) : ()),
1653   ];
1654
1655   return ($from,$seen);
1656 }
1657
1658 sub _resolved_attrs {
1659   my $self = shift;
1660   return $self->{_attrs} if $self->{_attrs};
1661
1662   my $attrs = { %{$self->{attrs}||{}} };
1663   my $source = $self->result_source;
1664   my $alias = $attrs->{alias};
1665
1666   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
1667   if ($attrs->{columns}) {
1668     delete $attrs->{as};
1669   } elsif (!$attrs->{select}) {
1670     $attrs->{columns} = [ $source->columns ];
1671   }
1672
1673   $attrs->{select} =
1674     ($attrs->{select}
1675       ? (ref $attrs->{select} eq 'ARRAY'
1676           ? [ @{$attrs->{select}} ]
1677           : [ $attrs->{select} ])
1678       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
1679     );
1680   $attrs->{as} =
1681     ($attrs->{as}
1682       ? (ref $attrs->{as} eq 'ARRAY'
1683           ? [ @{$attrs->{as}} ]
1684           : [ $attrs->{as} ])
1685       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
1686     );
1687
1688   my $adds;
1689   if ($adds = delete $attrs->{include_columns}) {
1690     $adds = [$adds] unless ref $adds eq 'ARRAY';
1691     push(@{$attrs->{select}}, @$adds);
1692     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
1693   }
1694   if ($adds = delete $attrs->{'+select'}) {
1695     $adds = [$adds] unless ref $adds eq 'ARRAY';
1696     push(@{$attrs->{select}},
1697            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
1698   }
1699   if (my $adds = delete $attrs->{'+as'}) {
1700     $adds = [$adds] unless ref $adds eq 'ARRAY';
1701     push(@{$attrs->{as}}, @$adds);
1702   }
1703
1704   $attrs->{from} ||= [ { 'me' => $source->from } ];
1705
1706   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
1707     my $join = delete $attrs->{join} || {};
1708
1709     if (defined $attrs->{prefetch}) {
1710       $join = $self->_merge_attr(
1711         $join, $attrs->{prefetch}
1712       );
1713     }
1714
1715     $attrs->{from} =   # have to copy here to avoid corrupting the original
1716       [
1717         @{$attrs->{from}},
1718         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
1719       ];
1720   }
1721
1722   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
1723   if ($attrs->{order_by}) {
1724     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
1725                            ? [ @{$attrs->{order_by}} ]
1726                            : [ $attrs->{order_by} ]);
1727   } else {
1728     $attrs->{order_by} = [];
1729   }
1730
1731   my $collapse = $attrs->{collapse} || {};
1732   if (my $prefetch = delete $attrs->{prefetch}) {
1733     $prefetch = $self->_merge_attr({}, $prefetch);
1734     my @pre_order;
1735     my $seen = $attrs->{seen_join} || {};
1736     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
1737       # bring joins back to level of current class
1738       my @prefetch = $source->resolve_prefetch(
1739         $p, $alias, $seen, \@pre_order, $collapse
1740       );
1741       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
1742       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
1743     }
1744     push(@{$attrs->{order_by}}, @pre_order);
1745   }
1746   $attrs->{collapse} = $collapse;
1747
1748   return $self->{_attrs} = $attrs;
1749 }
1750
1751 sub _merge_attr {
1752   my ($self, $a, $b) = @_;
1753   return $b unless defined($a);
1754   return $a unless defined($b);
1755
1756   if (ref $b eq 'HASH' && ref $a eq 'HASH') {
1757     foreach my $key (keys %{$b}) {
1758       if (exists $a->{$key}) {
1759         $a->{$key} = $self->_merge_attr($a->{$key}, $b->{$key});
1760       } else {
1761         $a->{$key} = $b->{$key};
1762       }
1763     }
1764     return $a;
1765   } else {
1766     $a = [$a] unless ref $a eq 'ARRAY';
1767     $b = [$b] unless ref $b eq 'ARRAY';
1768
1769     my $hash = {};
1770     my @array;
1771     foreach my $x ($a, $b) {
1772       foreach my $element (@{$x}) {
1773         if (ref $element eq 'HASH') {
1774           $hash = $self->_merge_attr($hash, $element);
1775         } elsif (ref $element eq 'ARRAY') {
1776           push(@array, @{$element});
1777         } else {
1778           push(@array, $element) unless $b == $x
1779             && grep { $_ eq $element } @array;
1780         }
1781       }
1782     }
1783
1784     @array = grep { !exists $hash->{$_} } @array;
1785
1786     return keys %{$hash}
1787       ? ( scalar(@array)
1788             ? [$hash, @array]
1789             : $hash
1790         )
1791       : \@array;
1792   }
1793 }
1794
1795 sub result_source {
1796     my $self = shift;
1797
1798     if (@_) {
1799         $self->_source_handle($_[0]->handle);
1800     } else {
1801         $self->_source_handle->resolve;
1802     }
1803 }
1804
1805 =head2 throw_exception
1806
1807 See L<DBIx::Class::Schema/throw_exception> for details.
1808
1809 =cut
1810
1811 sub throw_exception {
1812   my $self=shift;
1813   $self->_source_handle->schema->throw_exception(@_);
1814 }
1815
1816 # XXX: FIXME: Attributes docs need clearing up
1817
1818 =head1 ATTRIBUTES
1819
1820 The resultset takes various attributes that modify its behavior. Here's an
1821 overview of them:
1822
1823 =head2 order_by
1824
1825 =over 4
1826
1827 =item Value: ($order_by | \@order_by)
1828
1829 =back
1830
1831 Which column(s) to order the results by. This is currently passed
1832 through directly to SQL, so you can give e.g. C<year DESC> for a
1833 descending order on the column `year'.
1834
1835 Please note that if you have C<quote_char> enabled (see
1836 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
1837 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
1838 so you will need to manually quote things as appropriate.)
1839
1840 =head2 columns
1841
1842 =over 4
1843
1844 =item Value: \@columns
1845
1846 =back
1847
1848 Shortcut to request a particular set of columns to be retrieved.  Adds
1849 C<me.> onto the start of any column without a C<.> in it and sets C<select>
1850 from that, then auto-populates C<as> from C<select> as normal. (You may also
1851 use the C<cols> attribute, as in earlier versions of DBIC.)
1852
1853 =head2 include_columns
1854
1855 =over 4
1856
1857 =item Value: \@columns
1858
1859 =back
1860
1861 Shortcut to include additional columns in the returned results - for example
1862
1863   $schema->resultset('CD')->search(undef, {
1864     include_columns => ['artist.name'],
1865     join => ['artist']
1866   });
1867
1868 would return all CDs and include a 'name' column to the information
1869 passed to object inflation. Note that the 'artist' is the name of the
1870 column (or relationship) accessor, and 'name' is the name of the column
1871 accessor in the related table.
1872
1873 =head2 select
1874
1875 =over 4
1876
1877 =item Value: \@select_columns
1878
1879 =back
1880
1881 Indicates which columns should be selected from the storage. You can use
1882 column names, or in the case of RDBMS back ends, function or stored procedure
1883 names:
1884
1885   $rs = $schema->resultset('Employee')->search(undef, {
1886     select => [
1887       'name',
1888       { count => 'employeeid' },
1889       { sum => 'salary' }
1890     ]
1891   });
1892
1893 When you use function/stored procedure names and do not supply an C<as>
1894 attribute, the column names returned are storage-dependent. E.g. MySQL would
1895 return a column named C<count(employeeid)> in the above example.
1896
1897 =head2 +select
1898
1899 =over 4
1900
1901 Indicates additional columns to be selected from storage.  Works the same as
1902 L<select> but adds columns to the selection.
1903
1904 =back
1905
1906 =head2 +as
1907
1908 =over 4
1909
1910 Indicates additional column names for those added via L<+select>.
1911
1912 =back
1913
1914 =head2 as
1915
1916 =over 4
1917
1918 =item Value: \@inflation_names
1919
1920 =back
1921
1922 Indicates column names for object inflation. That is, c< as >
1923 indicates the name that the column can be accessed as via the
1924 C<get_column> method (or via the object accessor, B<if one already
1925 exists>).  It has nothing to do with the SQL code C< SELECT foo AS bar
1926 >.
1927
1928 The C< as > attribute is used in conjunction with C<select>,
1929 usually when C<select> contains one or more function or stored
1930 procedure names:
1931
1932   $rs = $schema->resultset('Employee')->search(undef, {
1933     select => [
1934       'name',
1935       { count => 'employeeid' }
1936     ],
1937     as => ['name', 'employee_count'],
1938   });
1939
1940   my $employee = $rs->first(); # get the first Employee
1941
1942 If the object against which the search is performed already has an accessor
1943 matching a column name specified in C<as>, the value can be retrieved using
1944 the accessor as normal:
1945
1946   my $name = $employee->name();
1947
1948 If on the other hand an accessor does not exist in the object, you need to
1949 use C<get_column> instead:
1950
1951   my $employee_count = $employee->get_column('employee_count');
1952
1953 You can create your own accessors if required - see
1954 L<DBIx::Class::Manual::Cookbook> for details.
1955
1956 Please note: This will NOT insert an C<AS employee_count> into the SQL
1957 statement produced, it is used for internal access only. Thus
1958 attempting to use the accessor in an C<order_by> clause or similar
1959 will fail miserably.
1960
1961 To get around this limitation, you can supply literal SQL to your
1962 C<select> attibute that contains the C<AS alias> text, eg:
1963
1964   select => [\'myfield AS alias']
1965
1966 =head2 join
1967
1968 =over 4
1969
1970 =item Value: ($rel_name | \@rel_names | \%rel_names)
1971
1972 =back
1973
1974 Contains a list of relationships that should be joined for this query.  For
1975 example:
1976
1977   # Get CDs by Nine Inch Nails
1978   my $rs = $schema->resultset('CD')->search(
1979     { 'artist.name' => 'Nine Inch Nails' },
1980     { join => 'artist' }
1981   );
1982
1983 Can also contain a hash reference to refer to the other relation's relations.
1984 For example:
1985
1986   package MyApp::Schema::Track;
1987   use base qw/DBIx::Class/;
1988   __PACKAGE__->table('track');
1989   __PACKAGE__->add_columns(qw/trackid cd position title/);
1990   __PACKAGE__->set_primary_key('trackid');
1991   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
1992   1;
1993
1994   # In your application
1995   my $rs = $schema->resultset('Artist')->search(
1996     { 'track.title' => 'Teardrop' },
1997     {
1998       join     => { cd => 'track' },
1999       order_by => 'artist.name',
2000     }
2001   );
2002
2003 You need to use the relationship (not the table) name in  conditions,
2004 because they are aliased as such. The current table is aliased as "me", so
2005 you need to use me.column_name in order to avoid ambiguity. For example:
2006
2007   # Get CDs from 1984 with a 'Foo' track
2008   my $rs = $schema->resultset('CD')->search(
2009     {
2010       'me.year' => 1984,
2011       'tracks.name' => 'Foo'
2012     },
2013     { join => 'tracks' }
2014   );
2015
2016 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2017 similarly for a third time). For e.g.
2018
2019   my $rs = $schema->resultset('Artist')->search({
2020     'cds.title'   => 'Down to Earth',
2021     'cds_2.title' => 'Popular',
2022   }, {
2023     join => [ qw/cds cds/ ],
2024   });
2025
2026 will return a set of all artists that have both a cd with title 'Down
2027 to Earth' and a cd with title 'Popular'.
2028
2029 If you want to fetch related objects from other tables as well, see C<prefetch>
2030 below.
2031
2032 =head2 prefetch
2033
2034 =over 4
2035
2036 =item Value: ($rel_name | \@rel_names | \%rel_names)
2037
2038 =back
2039
2040 Contains one or more relationships that should be fetched along with the main
2041 query (when they are accessed afterwards they will have already been
2042 "prefetched").  This is useful for when you know you will need the related
2043 objects, because it saves at least one query:
2044
2045   my $rs = $schema->resultset('Tag')->search(
2046     undef,
2047     {
2048       prefetch => {
2049         cd => 'artist'
2050       }
2051     }
2052   );
2053
2054 The initial search results in SQL like the following:
2055
2056   SELECT tag.*, cd.*, artist.* FROM tag
2057   JOIN cd ON tag.cd = cd.cdid
2058   JOIN artist ON cd.artist = artist.artistid
2059
2060 L<DBIx::Class> has no need to go back to the database when we access the
2061 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2062 case.
2063
2064 Simple prefetches will be joined automatically, so there is no need
2065 for a C<join> attribute in the above search. If you're prefetching to
2066 depth (e.g. { cd => { artist => 'label' } or similar), you'll need to
2067 specify the join as well.
2068
2069 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2070 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2071 with an accessor type of 'single' or 'filter').
2072
2073 =head2 page
2074
2075 =over 4
2076
2077 =item Value: $page
2078
2079 =back
2080
2081 Makes the resultset paged and specifies the page to retrieve. Effectively
2082 identical to creating a non-pages resultset and then calling ->page($page)
2083 on it.
2084
2085 If L<rows> attribute is not specified it defualts to 10 rows per page.
2086
2087 =head2 rows
2088
2089 =over 4
2090
2091 =item Value: $rows
2092
2093 =back
2094
2095 Specifes the maximum number of rows for direct retrieval or the number of
2096 rows per page if the page attribute or method is used.
2097
2098 =head2 offset
2099
2100 =over 4
2101
2102 =item Value: $offset
2103
2104 =back
2105
2106 Specifies the (zero-based) row number for the  first row to be returned, or the
2107 of the first row of the first page if paging is used.
2108
2109 =head2 group_by
2110
2111 =over 4
2112
2113 =item Value: \@columns
2114
2115 =back
2116
2117 A arrayref of columns to group by. Can include columns of joined tables.
2118
2119   group_by => [qw/ column1 column2 ... /]
2120
2121 =head2 having
2122
2123 =over 4
2124
2125 =item Value: $condition
2126
2127 =back
2128
2129 HAVING is a select statement attribute that is applied between GROUP BY and
2130 ORDER BY. It is applied to the after the grouping calculations have been
2131 done.
2132
2133   having => { 'count(employee)' => { '>=', 100 } }
2134
2135 =head2 distinct
2136
2137 =over 4
2138
2139 =item Value: (0 | 1)
2140
2141 =back
2142
2143 Set to 1 to group by all columns.
2144
2145 =head2 where
2146
2147 =over 4
2148
2149 Adds to the WHERE clause.
2150
2151   # only return rows WHERE deleted IS NULL for all searches
2152   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2153
2154 Can be overridden by passing C<{ where => undef }> as an attribute
2155 to a resulset.
2156
2157 =back
2158
2159 =head2 cache
2160
2161 Set to 1 to cache search results. This prevents extra SQL queries if you
2162 revisit rows in your ResultSet:
2163
2164   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2165
2166   while( my $artist = $resultset->next ) {
2167     ... do stuff ...
2168   }
2169
2170   $rs->first; # without cache, this would issue a query
2171
2172 By default, searches are not cached.
2173
2174 For more examples of using these attributes, see
2175 L<DBIx::Class::Manual::Cookbook>.
2176
2177 =head2 from
2178
2179 =over 4
2180
2181 =item Value: \@from_clause
2182
2183 =back
2184
2185 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2186 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2187 clauses.
2188
2189 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2190
2191 C<join> will usually do what you need and it is strongly recommended that you
2192 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2193 And we really do mean "cannot", not just tried and failed. Attempting to use
2194 this because you're having problems with C<join> is like trying to use x86
2195 ASM because you've got a syntax error in your C. Trust us on this.
2196
2197 Now, if you're still really, really sure you need to use this (and if you're
2198 not 100% sure, ask the mailing list first), here's an explanation of how this
2199 works.
2200
2201 The syntax is as follows -
2202
2203   [
2204     { <alias1> => <table1> },
2205     [
2206       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2207       [], # nested JOIN (optional)
2208       { <table1.column1> => <table2.column2>, ... (more conditions) },
2209     ],
2210     # More of the above [ ] may follow for additional joins
2211   ]
2212
2213   <table1> <alias1>
2214   JOIN
2215     <table2> <alias2>
2216     [JOIN ...]
2217   ON <table1.column1> = <table2.column2>
2218   <more joins may follow>
2219
2220 An easy way to follow the examples below is to remember the following:
2221
2222     Anything inside "[]" is a JOIN
2223     Anything inside "{}" is a condition for the enclosing JOIN
2224
2225 The following examples utilize a "person" table in a family tree application.
2226 In order to express parent->child relationships, this table is self-joined:
2227
2228     # Person->belongs_to('father' => 'Person');
2229     # Person->belongs_to('mother' => 'Person');
2230
2231 C<from> can be used to nest joins. Here we return all children with a father,
2232 then search against all mothers of those children:
2233
2234   $rs = $schema->resultset('Person')->search(
2235       undef,
2236       {
2237           alias => 'mother', # alias columns in accordance with "from"
2238           from => [
2239               { mother => 'person' },
2240               [
2241                   [
2242                       { child => 'person' },
2243                       [
2244                           { father => 'person' },
2245                           { 'father.person_id' => 'child.father_id' }
2246                       ]
2247                   ],
2248                   { 'mother.person_id' => 'child.mother_id' }
2249               ],
2250           ]
2251       },
2252   );
2253
2254   # Equivalent SQL:
2255   # SELECT mother.* FROM person mother
2256   # JOIN (
2257   #   person child
2258   #   JOIN person father
2259   #   ON ( father.person_id = child.father_id )
2260   # )
2261   # ON ( mother.person_id = child.mother_id )
2262
2263 The type of any join can be controlled manually. To search against only people
2264 with a father in the person table, we could explicitly use C<INNER JOIN>:
2265
2266     $rs = $schema->resultset('Person')->search(
2267         undef,
2268         {
2269             alias => 'child', # alias columns in accordance with "from"
2270             from => [
2271                 { child => 'person' },
2272                 [
2273                     { father => 'person', -join_type => 'inner' },
2274                     { 'father.id' => 'child.father_id' }
2275                 ],
2276             ]
2277         },
2278     );
2279
2280     # Equivalent SQL:
2281     # SELECT child.* FROM person child
2282     # INNER JOIN person father ON child.father_id = father.id
2283
2284 =cut
2285
2286 1;