lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 966   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 967   @new = $self->{_attrs}{record_filter}->(@new)
 968     if exists $self->{_attrs}{record_filter};
 969   return @new;
 970 }
 971
 972 sub _collapse_result {
 973   my ($self, $as_proto, $row) = @_;
 974
 975   my @copy = @$row;
 976
 977   # 'foo'         => [ undef, 'foo' ]
 978   # 'foo.bar'     => [ 'foo', 'bar' ]
 979   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 980
 981   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 982
 983   my %collapse = %{$self->{_attrs}{collapse}||{}};
 984
 985   my @pri_index;
 986
 987   # if we're doing collapsing (has_many prefetch) we need to grab records
 988   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 989   # we know we don't have to bother.
 990
 991   # the reason for not using the collapse stuff directly is because if you
 992   # had for e.g. two artists in a row with no cds, the collapse info for
 993   # both would be NULL (undef) so you'd lose the second artist
 994
 995   # store just the index so we can check the array positions from the row
 996   # without having to contruct the full hash
 997
 998   if (keys %collapse) {
 999     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1000     foreach my $i (0 .. $#construct_as) {
1001       next if defined($construct_as[$i][0]); # only self table
1002       if (delete $pri{$construct_as[$i][1]}) {
1003         push(@pri_index, $i);
1004       }
1005       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1006     }
1007   }
1008
1009   # no need to do an if, it'll be empty if @pri_index is empty anyway
1010
1011   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1012
1013   my @const_rows;
1014
1015   do { # no need to check anything at the front, we always want the first row
1016
1017     my %const;
1018
1019     foreach my $this_as (@construct_as) {
1020       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1021     }
1022
1023     push(@const_rows, \%const);
1024
1025   } until ( # no pri_index => no collapse => drop straight out
1026       !@pri_index
1027     or
1028       do { # get another row, stash it, drop out if different PK
1029
1030         @copy = $self->cursor->next;
1031         $self->{stashed_row} = \@copy;
1032
1033         # last thing in do block, counts as true if anything doesn't match
1034
1035         # check xor defined first for NULL vs. NOT NULL then if one is
1036         # defined the other must be so check string equality
1037
1038         grep {
1039           (defined $pri_vals{$_} ^ defined $copy[$_])
1040           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1041         } @pri_index;
1042       }
1043   );
1044
1045   my $alias = $self->{attrs}{alias};
1046   my $info = [];
1047
1048   my %collapse_pos;
1049
1050   my @const_keys;
1051
1052   foreach my $const (@const_rows) {
1053     scalar @const_keys or do {
1054       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1055     };
1056     foreach my $key (@const_keys) {
1057       if (length $key) {
1058         my $target = $info;
1059         my @parts = split(/\./, $key);
1060         my $cur = '';
1061         my $data = $const->{$key};
1062         foreach my $p (@parts) {
1063           $target = $target->[1]->{$p} ||= [];
1064           $cur .= ".${p}";
1065           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1066             # collapsing at this point and on final part
1067             my $pos = $collapse_pos{$cur};
1068             CK: foreach my $ck (@ckey) {
1069               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1070                 $collapse_pos{$cur} = $data;
1071                 delete @collapse_pos{ # clear all positioning for sub-entries
1072                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1073                 };
1074                 push(@$target, []);
1075                 last CK;
1076               }
1077             }
1078           }
1079           if (exists $collapse{$cur}) {
1080             $target = $target->[-1];
1081           }
1082         }
1083         $target->[0] = $data;
1084       } else {
1085         $info->[0] = $const->{$key};
1086       }
1087     }
1088   }
1089
1090   return $info;
1091 }
1092
1093 =head2 result_source
1094
1095 =over 4
1096
1097 =item Arguments: $result_source?
1098
1099 =item Return Value: $result_source
1100
1101 =back
1102
1103 An accessor for the primary ResultSource object from which this ResultSet
1104 is derived.
1105
1106 =head2 result_class
1107
1108 =over 4
1109
1110 =item Arguments: $result_class?
1111
1112 =item Return Value: $result_class
1113
1114 =back
1115
1116 An accessor for the class to use when creating row objects. Defaults to
1117 C<< result_source->result_class >> - which in most cases is the name of the
1118 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1119
1120 Note that changing the result_class will also remove any components
1121 that were originally loaded in the source class via
1122 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1123 in the original source class will not run.
1124
1125 =cut
1126
1127 sub result_class {
1128   my ($self, $result_class) = @_;
1129   if ($result_class) {
1130     $self->ensure_class_loaded($result_class);
1131     $self->_result_class($result_class);
1132   }
1133   $self->_result_class;
1134 }
1135
1136 =head2 count
1137
1138 =over 4
1139
1140 =item Arguments: $cond, \%attrs??
1141
1142 =item Return Value: $count
1143
1144 =back
1145
1146 Performs an SQL C<COUNT> with the same query as the resultset was built
1147 with to find the number of elements. Passing arguments is equivalent to
1148 C<< $rs->search ($cond, \%attrs)->count >>
1149
1150 =cut
1151
1152 sub count {
1153   my $self = shift;
1154   return $self->search(@_)->count if @_ and defined $_[0];
1155   return scalar @{ $self->get_cache } if $self->get_cache;
1156
1157   my $attrs = $self->_resolved_attrs_copy;
1158
1159   # this is a little optimization - it is faster to do the limit
1160   # adjustments in software, instead of a subquery
1161   my $rows = delete $attrs->{rows};
1162   my $offset = delete $attrs->{offset};
1163
1164   my $crs;
1165   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1166     $crs = $self->_count_subq_rs ($attrs);
1167   }
1168   else {
1169     $crs = $self->_count_rs ($attrs);
1170   }
1171   my $count = $crs->next;
1172
1173   $count -= $offset if $offset;
1174   $count = $rows if $rows and $rows < $count;
1175   $count = 0 if ($count < 0);
1176
1177   return $count;
1178 }
1179
1180 =head2 count_rs
1181
1182 =over 4
1183
1184 =item Arguments: $cond, \%attrs??
1185
1186 =item Return Value: $count_rs
1187
1188 =back
1189
1190 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1191 This can be very handy for subqueries:
1192
1193   ->search( { amount => $some_rs->count_rs->as_query } )
1194
1195 As with regular resultsets the SQL query will be executed only after
1196 the resultset is accessed via L</next> or L</all>. That would return
1197 the same single value obtainable via L</count>.
1198
1199 =cut
1200
1201 sub count_rs {
1202   my $self = shift;
1203   return $self->search(@_)->count_rs if @_;
1204
1205   # this may look like a lack of abstraction (count() does about the same)
1206   # but in fact an _rs *must* use a subquery for the limits, as the
1207   # software based limiting can not be ported if this $rs is to be used
1208   # in a subquery itself (i.e. ->as_query)
1209   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1210     return $self->_count_subq_rs;
1211   }
1212   else {
1213     return $self->_count_rs;
1214   }
1215 }
1216
1217 #
1218 # returns a ResultSetColumn object tied to the count query
1219 #
1220 sub _count_rs {
1221   my ($self, $attrs) = @_;
1222
1223   my $rsrc = $self->result_source;
1224   $attrs ||= $self->_resolved_attrs;
1225
1226   my $tmp_attrs = { %$attrs };
1227
1228   # take off any limits, record_filter is cdbi, and no point of ordering a count
1229   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1230
1231   # overwrite the selector (supplied by the storage)
1232   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1233   $tmp_attrs->{as} = 'count';
1234
1235   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1236
1237   return $tmp_rs;
1238 }
1239
1240 #
1241 # same as above but uses a subquery
1242 #
1243 sub _count_subq_rs {
1244   my ($self, $attrs) = @_;
1245
1246   my $rsrc = $self->result_source;
1247   $attrs ||= $self->_resolved_attrs_copy;
1248
1249   my $sub_attrs = { %$attrs };
1250
1251   # these can not go in the subquery, and there is no point of ordering it
1252   delete $sub_attrs->{$_} for qw/collapse select as order_by/;
1253
1254   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1255   # clobber old group_by regardless
1256   if ( keys %{$attrs->{collapse}} ) {
1257     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1258   }
1259
1260   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1261
1262   $attrs->{from} = [{
1263     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1264   }];
1265
1266   # the subquery replaces this
1267   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1268
1269   return $self->_count_rs ($attrs);
1270 }
1271
1272
1273 sub _bool {
1274   return 1;
1275 }
1276
1277 =head2 count_literal
1278
1279 =over 4
1280
1281 =item Arguments: $sql_fragment, @bind_values
1282
1283 =item Return Value: $count
1284
1285 =back
1286
1287 Counts the results in a literal query. Equivalent to calling L</search_literal>
1288 with the passed arguments, then L</count>.
1289
1290 =cut
1291
1292 sub count_literal { shift->search_literal(@_)->count; }
1293
1294 =head2 all
1295
1296 =over 4
1297
1298 =item Arguments: none
1299
1300 =item Return Value: @objects
1301
1302 =back
1303
1304 Returns all elements in the resultset. Called implicitly if the resultset
1305 is returned in list context.
1306
1307 =cut
1308
1309 sub all {
1310   my $self = shift;
1311   if(@_) {
1312       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1313   }
1314
1315   return @{ $self->get_cache } if $self->get_cache;
1316
1317   my @obj;
1318
1319   # TODO: don't call resolve here
1320   if (keys %{$self->_resolved_attrs->{collapse}}) {
1321 #  if ($self->{attrs}{prefetch}) {
1322       # Using $self->cursor->all is really just an optimisation.
1323       # If we're collapsing has_many prefetches it probably makes
1324       # very little difference, and this is cleaner than hacking
1325       # _construct_object to survive the approach
1326     my @row = $self->cursor->next;
1327     while (@row) {
1328       push(@obj, $self->_construct_object(@row));
1329       @row = (exists $self->{stashed_row}
1330                ? @{delete $self->{stashed_row}}
1331                : $self->cursor->next);
1332     }
1333   } else {
1334     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1335   }
1336
1337   $self->set_cache(\@obj) if $self->{attrs}{cache};
1338   return @obj;
1339 }
1340
1341 =head2 reset
1342
1343 =over 4
1344
1345 =item Arguments: none
1346
1347 =item Return Value: $self
1348
1349 =back
1350
1351 Resets the resultset's cursor, so you can iterate through the elements again.
1352
1353 =cut
1354
1355 sub reset {
1356   my ($self) = @_;
1357   delete $self->{_attrs} if exists $self->{_attrs};
1358   $self->{all_cache_position} = 0;
1359   $self->cursor->reset;
1360   return $self;
1361 }
1362
1363 =head2 first
1364
1365 =over 4
1366
1367 =item Arguments: none
1368
1369 =item Return Value: $object?
1370
1371 =back
1372
1373 Resets the resultset and returns an object for the first result (if the
1374 resultset returns anything).
1375
1376 =cut
1377
1378 sub first {
1379   return $_[0]->reset->next;
1380 }
1381
1382
1383 # _rs_update_delete
1384 #
1385 # Determines whether and what type of subquery is required for the $rs operation.
1386 # If grouping is necessary either supplies its own, or verifies the current one
1387 # After all is done delegates to the proper storage method.
1388
1389 sub _rs_update_delete {
1390   my ($self, $op, $values) = @_;
1391
1392   my $rsrc = $self->result_source;
1393
1394   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1395   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1396
1397   if ($needs_group_by_subq or $needs_subq) {
1398
1399     # make a new $rs selecting only the PKs (that's all we really need)
1400     my $attrs = $self->_resolved_attrs_copy;
1401
1402     delete $attrs->{$_} for qw/collapse select as/;
1403     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1404
1405     if ($needs_group_by_subq) {
1406       # make sure no group_by was supplied, or if there is one - make sure it matches
1407       # the columns compiled above perfectly. Anything else can not be sanely executed
1408       # on most databases so croak right then and there
1409
1410       if (my $g = $attrs->{group_by}) {
1411         my @current_group_by = map
1412           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1413           (ref $g eq 'ARRAY' ? @$g : $g );
1414
1415         if (
1416           join ("\x00", sort @current_group_by)
1417             ne
1418           join ("\x00", sort @{$attrs->{columns}} )
1419         ) {
1420           $self->throw_exception (
1421             "You have just attempted a $op operation on a resultset which does group_by"
1422             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1423             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1424             . ' kind of queries. Please retry the operation with a modified group_by or'
1425             . ' without using one at all.'
1426           );
1427         }
1428       }
1429       else {
1430         $attrs->{group_by} = $attrs->{columns};
1431       }
1432     }
1433
1434     my $subrs = (ref $self)->new($rsrc, $attrs);
1435
1436     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1437   }
1438   else {
1439     return $rsrc->storage->$op(
1440       $rsrc,
1441       $op eq 'update' ? $values : (),
1442       $self->_cond_for_update_delete,
1443     );
1444   }
1445 }
1446
1447
1448 # _cond_for_update_delete
1449 #
1450 # update/delete require the condition to be modified to handle
1451 # the differing SQL syntax available.  This transforms the $self->{cond}
1452 # appropriately, returning the new condition.
1453
1454 sub _cond_for_update_delete {
1455   my ($self, $full_cond) = @_;
1456   my $cond = {};
1457
1458   $full_cond ||= $self->{cond};
1459   # No-op. No condition, we're updating/deleting everything
1460   return $cond unless ref $full_cond;
1461
1462   if (ref $full_cond eq 'ARRAY') {
1463     $cond = [
1464       map {
1465         my %hash;
1466         foreach my $key (keys %{$_}) {
1467           $key =~ /([^.]+)$/;
1468           $hash{$1} = $_->{$key};
1469         }
1470         \%hash;
1471       } @{$full_cond}
1472     ];
1473   }
1474   elsif (ref $full_cond eq 'HASH') {
1475     if ((keys %{$full_cond})[0] eq '-and') {
1476       $cond->{-and} = [];
1477       my @cond = @{$full_cond->{-and}};
1478        for (my $i = 0; $i < @cond; $i++) {
1479         my $entry = $cond[$i];
1480         my $hash;
1481         if (ref $entry eq 'HASH') {
1482           $hash = $self->_cond_for_update_delete($entry);
1483         }
1484         else {
1485           $entry =~ /([^.]+)$/;
1486           $hash->{$1} = $cond[++$i];
1487         }
1488         push @{$cond->{-and}}, $hash;
1489       }
1490     }
1491     else {
1492       foreach my $key (keys %{$full_cond}) {
1493         $key =~ /([^.]+)$/;
1494         $cond->{$1} = $full_cond->{$key};
1495       }
1496     }
1497   }
1498   else {
1499     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1500   }
1501
1502   return $cond;
1503 }
1504
1505
1506 =head2 update
1507
1508 =over 4
1509
1510 =item Arguments: \%values
1511
1512 =item Return Value: $storage_rv
1513
1514 =back
1515
1516 Sets the specified columns in the resultset to the supplied values in a
1517 single query. Return value will be true if the update succeeded or false
1518 if no records were updated; exact type of success value is storage-dependent.
1519
1520 =cut
1521
1522 sub update {
1523   my ($self, $values) = @_;
1524   $self->throw_exception('Values for update must be a hash')
1525     unless ref $values eq 'HASH';
1526
1527   return $self->_rs_update_delete ('update', $values);
1528 }
1529
1530 =head2 update_all
1531
1532 =over 4
1533
1534 =item Arguments: \%values
1535
1536 =item Return Value: 1
1537
1538 =back
1539
1540 Fetches all objects and updates them one at a time. Note that C<update_all>
1541 will run DBIC cascade triggers, while L</update> will not.
1542
1543 =cut
1544
1545 sub update_all {
1546   my ($self, $values) = @_;
1547   $self->throw_exception('Values for update_all must be a hash')
1548     unless ref $values eq 'HASH';
1549   foreach my $obj ($self->all) {
1550     $obj->set_columns($values)->update;
1551   }
1552   return 1;
1553 }
1554
1555 =head2 delete
1556
1557 =over 4
1558
1559 =item Arguments: none
1560
1561 =item Return Value: $storage_rv
1562
1563 =back
1564
1565 Deletes the contents of the resultset from its result source. Note that this
1566 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1567 to run. See also L<DBIx::Class::Row/delete>.
1568
1569 Return value will be the amount of rows deleted; exact type of return value
1570 is storage-dependent.
1571
1572 =cut
1573
1574 sub delete {
1575   my $self = shift;
1576   $self->throw_exception('delete does not accept any arguments')
1577     if @_;
1578
1579   return $self->_rs_update_delete ('delete');
1580 }
1581
1582 =head2 delete_all
1583
1584 =over 4
1585
1586 =item Arguments: none
1587
1588 =item Return Value: 1
1589
1590 =back
1591
1592 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1593 will run DBIC cascade triggers, while L</delete> will not.
1594
1595 =cut
1596
1597 sub delete_all {
1598   my $self = shift;
1599   $self->throw_exception('delete_all does not accept any arguments')
1600     if @_;
1601
1602   $_->delete for $self->all;
1603   return 1;
1604 }
1605
1606 =head2 populate
1607
1608 =over 4
1609
1610 =item Arguments: \@data;
1611
1612 =back
1613
1614 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1615 For the arrayref of hashrefs style each hashref should be a structure suitable
1616 forsubmitting to a $resultset->create(...) method.
1617
1618 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1619 to insert the data, as this is a faster method.
1620
1621 Otherwise, each set of data is inserted into the database using
1622 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1623 accumulated into an array. The array itself, or an array reference
1624 is returned depending on scalar or list context.
1625
1626 Example:  Assuming an Artist Class that has many CDs Classes relating:
1627
1628   my $Artist_rs = $schema->resultset("Artist");
1629
1630   ## Void Context Example
1631   $Artist_rs->populate([
1632      { artistid => 4, name => 'Manufactured Crap', cds => [
1633         { title => 'My First CD', year => 2006 },
1634         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1635       ],
1636      },
1637      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1638         { title => 'My parents sold me to a record company' ,year => 2005 },
1639         { title => 'Why Am I So Ugly?', year => 2006 },
1640         { title => 'I Got Surgery and am now Popular', year => 2007 }
1641       ],
1642      },
1643   ]);
1644
1645   ## Array Context Example
1646   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1647     { name => "Artist One"},
1648     { name => "Artist Two"},
1649     { name => "Artist Three", cds=> [
1650     { title => "First CD", year => 2007},
1651     { title => "Second CD", year => 2008},
1652   ]}
1653   ]);
1654
1655   print $ArtistOne->name; ## response is 'Artist One'
1656   print $ArtistThree->cds->count ## reponse is '2'
1657
1658 For the arrayref of arrayrefs style,  the first element should be a list of the
1659 fieldsnames to which the remaining elements are rows being inserted.  For
1660 example:
1661
1662   $Arstist_rs->populate([
1663     [qw/artistid name/],
1664     [100, 'A Formally Unknown Singer'],
1665     [101, 'A singer that jumped the shark two albums ago'],
1666     [102, 'An actually cool singer.'],
1667   ]);
1668
1669 Please note an important effect on your data when choosing between void and
1670 wantarray context. Since void context goes straight to C<insert_bulk> in
1671 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1672 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1673 create primary keys for you, you will find that your PKs are empty.  In this
1674 case you will have to use the wantarray context in order to create those
1675 values.
1676
1677 =cut
1678
1679 sub populate {
1680   my $self = shift @_;
1681   my $data = ref $_[0][0] eq 'HASH'
1682     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1683     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1684
1685   if(defined wantarray) {
1686     my @created;
1687     foreach my $item (@$data) {
1688       push(@created, $self->create($item));
1689     }
1690     return wantarray ? @created : \@created;
1691   } else {
1692     my ($first, @rest) = @$data;
1693
1694     my @names = grep {!ref $first->{$_}} keys %$first;
1695     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1696     my @pks = $self->result_source->primary_columns;
1697
1698     ## do the belongs_to relationships
1699     foreach my $index (0..$#$data) {
1700
1701       # delegate to create() for any dataset without primary keys with specified relationships
1702       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1703         for my $r (@rels) {
1704           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1705             my @ret = $self->populate($data);
1706             return;
1707           }
1708         }
1709       }
1710
1711       foreach my $rel (@rels) {
1712         next unless ref $data->[$index]->{$rel} eq "HASH";
1713         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1714         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1715         my $related = $result->result_source->_resolve_condition(
1716           $result->result_source->relationship_info($reverse)->{cond},
1717           $self,
1718           $result,
1719         );
1720
1721         delete $data->[$index]->{$rel};
1722         $data->[$index] = {%{$data->[$index]}, %$related};
1723
1724         push @names, keys %$related if $index == 0;
1725       }
1726     }
1727
1728     ## do bulk insert on current row
1729     my @values = map { [ @$_{@names} ] } @$data;
1730
1731     $self->result_source->storage->insert_bulk(
1732       $self->result_source,
1733       \@names,
1734       \@values,
1735     );
1736
1737     ## do the has_many relationships
1738     foreach my $item (@$data) {
1739
1740       foreach my $rel (@rels) {
1741         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1742
1743         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1744      || $self->throw_exception('Cannot find the relating object.');
1745
1746         my $child = $parent->$rel;
1747
1748         my $related = $child->result_source->_resolve_condition(
1749           $parent->result_source->relationship_info($rel)->{cond},
1750           $child,
1751           $parent,
1752         );
1753
1754         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1755         my @populate = map { {%$_, %$related} } @rows_to_add;
1756
1757         $child->populate( \@populate );
1758       }
1759     }
1760   }
1761 }
1762
1763 =head2 _normalize_populate_args ($args)
1764
1765 Private method used by L</populate> to normalize its incoming arguments.  Factored
1766 out in case you want to subclass and accept new argument structures to the
1767 L</populate> method.
1768
1769 =cut
1770
1771 sub _normalize_populate_args {
1772   my ($self, $data) = @_;
1773   my @names = @{shift(@$data)};
1774   my @results_to_create;
1775   foreach my $datum (@$data) {
1776     my %result_to_create;
1777     foreach my $index (0..$#names) {
1778       $result_to_create{$names[$index]} = $$datum[$index];
1779     }
1780     push @results_to_create, \%result_to_create;
1781   }
1782   return \@results_to_create;
1783 }
1784
1785 =head2 pager
1786
1787 =over 4
1788
1789 =item Arguments: none
1790
1791 =item Return Value: $pager
1792
1793 =back
1794
1795 Return Value a L<Data::Page> object for the current resultset. Only makes
1796 sense for queries with a C<page> attribute.
1797
1798 To get the full count of entries for a paged resultset, call
1799 C<total_entries> on the L<Data::Page> object.
1800
1801 =cut
1802
1803 sub pager {
1804   my ($self) = @_;
1805
1806   return $self->{pager} if $self->{pager};
1807
1808   my $attrs = $self->{attrs};
1809   $self->throw_exception("Can't create pager for non-paged rs")
1810     unless $self->{attrs}{page};
1811   $attrs->{rows} ||= 10;
1812
1813   # throw away the paging flags and re-run the count (possibly
1814   # with a subselect) to get the real total count
1815   my $count_attrs = { %$attrs };
1816   delete $count_attrs->{$_} for qw/rows offset page pager/;
1817   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1818
1819   return $self->{pager} = Data::Page->new(
1820     $total_count,
1821     $attrs->{rows},
1822     $self->{attrs}{page}
1823   );
1824 }
1825
1826 =head2 page
1827
1828 =over 4
1829
1830 =item Arguments: $page_number
1831
1832 =item Return Value: $rs
1833
1834 =back
1835
1836 Returns a resultset for the $page_number page of the resultset on which page
1837 is called, where each page contains a number of rows equal to the 'rows'
1838 attribute set on the resultset (10 by default).
1839
1840 =cut
1841
1842 sub page {
1843   my ($self, $page) = @_;
1844   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1845 }
1846
1847 =head2 new_result
1848
1849 =over 4
1850
1851 =item Arguments: \%vals
1852
1853 =item Return Value: $rowobject
1854
1855 =back
1856
1857 Creates a new row object in the resultset's result class and returns
1858 it. The row is not inserted into the database at this point, call
1859 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1860 will tell you whether the row object has been inserted or not.
1861
1862 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1863
1864 =cut
1865
1866 sub new_result {
1867   my ($self, $values) = @_;
1868   $self->throw_exception( "new_result needs a hash" )
1869     unless (ref $values eq 'HASH');
1870
1871   my %new;
1872   my $alias = $self->{attrs}{alias};
1873
1874   if (
1875     defined $self->{cond}
1876     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1877   ) {
1878     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1879     $new{-from_resultset} = [ keys %new ] if keys %new;
1880   } else {
1881     $self->throw_exception(
1882       "Can't abstract implicit construct, condition not a hash"
1883     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1884
1885     my $collapsed_cond = (
1886       $self->{cond}
1887         ? $self->_collapse_cond($self->{cond})
1888         : {}
1889     );
1890
1891     # precendence must be given to passed values over values inherited from
1892     # the cond, so the order here is important.
1893     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1894     while( my($col,$value) = each %implied ){
1895       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1896         $new{$col} = $value->{'='};
1897         next;
1898       }
1899       $new{$col} = $value if $self->_is_deterministic_value($value);
1900     }
1901   }
1902
1903   %new = (
1904     %new,
1905     %{ $self->_remove_alias($values, $alias) },
1906     -source_handle => $self->_source_handle,
1907     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1908   );
1909
1910   return $self->result_class->new(\%new);
1911 }
1912
1913 # _is_deterministic_value
1914 #
1915 # Make an effor to strip non-deterministic values from the condition,
1916 # to make sure new_result chokes less
1917
1918 sub _is_deterministic_value {
1919   my $self = shift;
1920   my $value = shift;
1921   my $ref_type = ref $value;
1922   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1923   return 1 if Scalar::Util::blessed($value);
1924   return 0;
1925 }
1926
1927 # _has_resolved_attr
1928 #
1929 # determines if the resultset defines at least one
1930 # of the attributes supplied
1931 #
1932 # used to determine if a subquery is neccessary
1933
1934 sub _has_resolved_attr {
1935   my ($self, @attr_names) = @_;
1936
1937   my $attrs = $self->_resolved_attrs;
1938
1939   my $join_check_req;
1940
1941   for my $n (@attr_names) {
1942     ++$join_check_req if $n eq '-join';
1943
1944     my $attr =  $attrs->{$n};
1945
1946     next if not defined $attr;
1947
1948     if (ref $attr eq 'HASH') {
1949       return 1 if keys %$attr;
1950     }
1951     elsif (ref $attr eq 'ARRAY') {
1952       return 1 if @$attr;
1953     }
1954     else {
1955       return 1 if $attr;
1956     }
1957   }
1958
1959   # a resolved join is expressed as a multi-level from
1960   return 1 if (
1961     $join_check_req
1962       and
1963     ref $attrs->{from} eq 'ARRAY'
1964       and
1965     @{$attrs->{from}} > 1
1966   );
1967
1968   return 0;
1969 }
1970
1971 # _collapse_cond
1972 #
1973 # Recursively collapse the condition.
1974
1975 sub _collapse_cond {
1976   my ($self, $cond, $collapsed) = @_;
1977
1978   $collapsed ||= {};
1979
1980   if (ref $cond eq 'ARRAY') {
1981     foreach my $subcond (@$cond) {
1982       next unless ref $subcond;  # -or
1983       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1984     }
1985   }
1986   elsif (ref $cond eq 'HASH') {
1987     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1988       foreach my $subcond (@{$cond->{-and}}) {
1989         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1990       }
1991     }
1992     else {
1993       foreach my $col (keys %$cond) {
1994         my $value = $cond->{$col};
1995         $collapsed->{$col} = $value;
1996       }
1997     }
1998   }
1999
2000   return $collapsed;
2001 }
2002
2003 # _remove_alias
2004 #
2005 # Remove the specified alias from the specified query hash. A copy is made so
2006 # the original query is not modified.
2007
2008 sub _remove_alias {
2009   my ($self, $query, $alias) = @_;
2010
2011   my %orig = %{ $query || {} };
2012   my %unaliased;
2013
2014   foreach my $key (keys %orig) {
2015     if ($key !~ /\./) {
2016       $unaliased{$key} = $orig{$key};
2017       next;
2018     }
2019     $unaliased{$1} = $orig{$key}
2020       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2021   }
2022
2023   return \%unaliased;
2024 }
2025
2026 =head2 as_query (EXPERIMENTAL)
2027
2028 =over 4
2029
2030 =item Arguments: none
2031
2032 =item Return Value: \[ $sql, @bind ]
2033
2034 =back
2035
2036 Returns the SQL query and bind vars associated with the invocant.
2037
2038 This is generally used as the RHS for a subquery.
2039
2040 B<NOTE>: This feature is still experimental.
2041
2042 =cut
2043
2044 sub as_query {
2045   my $self = shift;
2046
2047   my $attrs = $self->_resolved_attrs_copy;
2048
2049   # For future use:
2050   #
2051   # in list ctx:
2052   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2053   # $sql also has no wrapping parenthesis in list ctx
2054   #
2055   my $sqlbind = $self->result_source->storage
2056     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2057
2058   return $sqlbind;
2059 }
2060
2061 =head2 find_or_new
2062
2063 =over 4
2064
2065 =item Arguments: \%vals, \%attrs?
2066
2067 =item Return Value: $rowobject
2068
2069 =back
2070
2071   my $artist = $schema->resultset('Artist')->find_or_new(
2072     { artist => 'fred' }, { key => 'artists' });
2073
2074   $cd->cd_to_producer->find_or_new({ producer => $producer },
2075                                    { key => 'primary });
2076
2077 Find an existing record from this resultset, based on its primary
2078 key, or a unique constraint. If none exists, instantiate a new result
2079 object and return it. The object will not be saved into your storage
2080 until you call L<DBIx::Class::Row/insert> on it.
2081
2082 You most likely want this method when looking for existing rows using
2083 a unique constraint that is not the primary key, or looking for
2084 related rows.
2085
2086 If you want objects to be saved immediately, use L</find_or_create> instead.
2087
2088 B<Note>: C<find_or_new> is probably not what you want when creating a
2089 new row in a table that uses primary keys supplied by the
2090 database. Passing in a primary key column with a value of I<undef>
2091 will cause L</find> to attempt to search for a row with a value of
2092 I<NULL>.
2093
2094 =cut
2095
2096 sub find_or_new {
2097   my $self     = shift;
2098   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2099   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2100   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2101     return $row;
2102   }
2103   return $self->new_result($hash);
2104 }
2105
2106 =head2 create
2107
2108 =over 4
2109
2110 =item Arguments: \%vals
2111
2112 =item Return Value: a L<DBIx::Class::Row> $object
2113
2114 =back
2115
2116 Attempt to create a single new row or a row with multiple related rows
2117 in the table represented by the resultset (and related tables). This
2118 will not check for duplicate rows before inserting, use
2119 L</find_or_create> to do that.
2120
2121 To create one row for this resultset, pass a hashref of key/value
2122 pairs representing the columns of the table and the values you wish to
2123 store. If the appropriate relationships are set up, foreign key fields
2124 can also be passed an object representing the foreign row, and the
2125 value will be set to its primary key.
2126
2127 To create related objects, pass a hashref for the value if the related
2128 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2129 and use the name of the relationship as the key. (NOT the name of the field,
2130 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2131 of hashrefs containing the data for each of the rows to create in the foreign
2132 tables, again using the relationship name as the key.
2133
2134 Instead of hashrefs of plain related data (key/value pairs), you may
2135 also pass new or inserted objects. New objects (not inserted yet, see
2136 L</new>), will be inserted into their appropriate tables.
2137
2138 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2139
2140 Example of creating a new row.
2141
2142   $person_rs->create({
2143     name=>"Some Person",
2144     email=>"somebody@someplace.com"
2145   });
2146
2147 Example of creating a new row and also creating rows in a related C<has_many>
2148 or C<has_one> resultset.  Note Arrayref.
2149
2150   $artist_rs->create(
2151      { artistid => 4, name => 'Manufactured Crap', cds => [
2152         { title => 'My First CD', year => 2006 },
2153         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2154       ],
2155      },
2156   );
2157
2158 Example of creating a new row and also creating a row in a related
2159 C<belongs_to>resultset. Note Hashref.
2160
2161   $cd_rs->create({
2162     title=>"Music for Silly Walks",
2163     year=>2000,
2164     artist => {
2165       name=>"Silly Musician",
2166     }
2167   });
2168
2169 =cut
2170
2171 sub create {
2172   my ($self, $attrs) = @_;
2173   $self->throw_exception( "create needs a hashref" )
2174     unless ref $attrs eq 'HASH';
2175   return $self->new_result($attrs)->insert;
2176 }
2177
2178 =head2 find_or_create
2179
2180 =over 4
2181
2182 =item Arguments: \%vals, \%attrs?
2183
2184 =item Return Value: $rowobject
2185
2186 =back
2187
2188   $cd->cd_to_producer->find_or_create({ producer => $producer },
2189                                       { key => 'primary });
2190
2191 Tries to find a record based on its primary key or unique constraints; if none
2192 is found, creates one and returns that instead.
2193
2194   my $cd = $schema->resultset('CD')->find_or_create({
2195     cdid   => 5,
2196     artist => 'Massive Attack',
2197     title  => 'Mezzanine',
2198     year   => 2005,
2199   });
2200
2201 Also takes an optional C<key> attribute, to search by a specific key or unique
2202 constraint. For example:
2203
2204   my $cd = $schema->resultset('CD')->find_or_create(
2205     {
2206       artist => 'Massive Attack',
2207       title  => 'Mezzanine',
2208     },
2209     { key => 'cd_artist_title' }
2210   );
2211
2212 B<Note>: Because find_or_create() reads from the database and then
2213 possibly inserts based on the result, this method is subject to a race
2214 condition. Another process could create a record in the table after
2215 the find has completed and before the create has started. To avoid
2216 this problem, use find_or_create() inside a transaction.
2217
2218 B<Note>: C<find_or_create> is probably not what you want when creating
2219 a new row in a table that uses primary keys supplied by the
2220 database. Passing in a primary key column with a value of I<undef>
2221 will cause L</find> to attempt to search for a row with a value of
2222 I<NULL>.
2223
2224 See also L</find> and L</update_or_create>. For information on how to declare
2225 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2226
2227 =cut
2228
2229 sub find_or_create {
2230   my $self     = shift;
2231   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2232   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2233   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2234     return $row;
2235   }
2236   return $self->create($hash);
2237 }
2238
2239 =head2 update_or_create
2240
2241 =over 4
2242
2243 =item Arguments: \%col_values, { key => $unique_constraint }?
2244
2245 =item Return Value: $rowobject
2246
2247 =back
2248
2249   $resultset->update_or_create({ col => $val, ... });
2250
2251 First, searches for an existing row matching one of the unique constraints
2252 (including the primary key) on the source of this resultset. If a row is
2253 found, updates it with the other given column values. Otherwise, creates a new
2254 row.
2255
2256 Takes an optional C<key> attribute to search on a specific unique constraint.
2257 For example:
2258
2259   # In your application
2260   my $cd = $schema->resultset('CD')->update_or_create(
2261     {
2262       artist => 'Massive Attack',
2263       title  => 'Mezzanine',
2264       year   => 1998,
2265     },
2266     { key => 'cd_artist_title' }
2267   );
2268
2269   $cd->cd_to_producer->update_or_create({
2270     producer => $producer,
2271     name => 'harry',
2272   }, {
2273     key => 'primary,
2274   });
2275
2276
2277 If no C<key> is specified, it searches on all unique constraints defined on the
2278 source, including the primary key.
2279
2280 If the C<key> is specified as C<primary>, it searches only on the primary key.
2281
2282 See also L</find> and L</find_or_create>. For information on how to declare
2283 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2284
2285 B<Note>: C<update_or_create> is probably not what you want when
2286 looking for a row in a table that uses primary keys supplied by the
2287 database, unless you actually have a key value. Passing in a primary
2288 key column with a value of I<undef> will cause L</find> to attempt to
2289 search for a row with a value of I<NULL>.
2290
2291 =cut
2292
2293 sub update_or_create {
2294   my $self = shift;
2295   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2296   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2297
2298   my $row = $self->find($cond, $attrs);
2299   if (defined $row) {
2300     $row->update($cond);
2301     return $row;
2302   }
2303
2304   return $self->create($cond);
2305 }
2306
2307 =head2 update_or_new
2308
2309 =over 4
2310
2311 =item Arguments: \%col_values, { key => $unique_constraint }?
2312
2313 =item Return Value: $rowobject
2314
2315 =back
2316
2317   $resultset->update_or_new({ col => $val, ... });
2318
2319 First, searches for an existing row matching one of the unique constraints
2320 (including the primary key) on the source of this resultset. If a row is
2321 found, updates it with the other given column values. Otherwise, instantiate
2322 a new result object and return it. The object will not be saved into your storage
2323 until you call L<DBIx::Class::Row/insert> on it.
2324
2325 Takes an optional C<key> attribute to search on a specific unique constraint.
2326 For example:
2327
2328   # In your application
2329   my $cd = $schema->resultset('CD')->update_or_new(
2330     {
2331       artist => 'Massive Attack',
2332       title  => 'Mezzanine',
2333       year   => 1998,
2334     },
2335     { key => 'cd_artist_title' }
2336   );
2337
2338   if ($cd->in_storage) {
2339       # the cd was updated
2340   }
2341   else {
2342       # the cd is not yet in the database, let's insert it
2343       $cd->insert;
2344   }
2345
2346 See also L</find>, L</find_or_create> and L<find_or_new>.
2347
2348 =cut
2349
2350 sub update_or_new {
2351     my $self  = shift;
2352     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2353     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2354
2355     my $row = $self->find( $cond, $attrs );
2356     if ( defined $row ) {
2357         $row->update($cond);
2358         return $row;
2359     }
2360
2361     return $self->new_result($cond);
2362 }
2363
2364 =head2 get_cache
2365
2366 =over 4
2367
2368 =item Arguments: none
2369
2370 =item Return Value: \@cache_objects?
2371
2372 =back
2373
2374 Gets the contents of the cache for the resultset, if the cache is set.
2375
2376 The cache is populated either by using the L</prefetch> attribute to
2377 L</search> or by calling L</set_cache>.
2378
2379 =cut
2380
2381 sub get_cache {
2382   shift->{all_cache};
2383 }
2384
2385 =head2 set_cache
2386
2387 =over 4
2388
2389 =item Arguments: \@cache_objects
2390
2391 =item Return Value: \@cache_objects
2392
2393 =back
2394
2395 Sets the contents of the cache for the resultset. Expects an arrayref
2396 of objects of the same class as those produced by the resultset. Note that
2397 if the cache is set the resultset will return the cached objects rather
2398 than re-querying the database even if the cache attr is not set.
2399
2400 The contents of the cache can also be populated by using the
2401 L</prefetch> attribute to L</search>.
2402
2403 =cut
2404
2405 sub set_cache {
2406   my ( $self, $data ) = @_;
2407   $self->throw_exception("set_cache requires an arrayref")
2408       if defined($data) && (ref $data ne 'ARRAY');
2409   $self->{all_cache} = $data;
2410 }
2411
2412 =head2 clear_cache
2413
2414 =over 4
2415
2416 =item Arguments: none
2417
2418 =item Return Value: []
2419
2420 =back
2421
2422 Clears the cache for the resultset.
2423
2424 =cut
2425
2426 sub clear_cache {
2427   shift->set_cache(undef);
2428 }
2429
2430 =head2 related_resultset
2431
2432 =over 4
2433
2434 =item Arguments: $relationship_name
2435
2436 =item Return Value: $resultset
2437
2438 =back
2439
2440 Returns a related resultset for the supplied relationship name.
2441
2442   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2443
2444 =cut
2445
2446 sub related_resultset {
2447   my ($self, $rel) = @_;
2448
2449   $self->{related_resultsets} ||= {};
2450   return $self->{related_resultsets}{$rel} ||= do {
2451     my $rel_obj = $self->result_source->relationship_info($rel);
2452
2453     $self->throw_exception(
2454       "search_related: result source '" . $self->result_source->source_name .
2455         "' has no such relationship $rel")
2456       unless $rel_obj;
2457
2458     my ($from,$seen) = $self->_resolve_from($rel);
2459
2460     my $join_count = $seen->{$rel};
2461     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2462
2463     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2464     my %attrs = %{$self->{attrs}||{}};
2465     delete @attrs{qw(result_class alias)};
2466
2467     my $new_cache;
2468
2469     if (my $cache = $self->get_cache) {
2470       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2471         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2472                         @$cache ];
2473       }
2474     }
2475
2476     my $rel_source = $self->result_source->related_source($rel);
2477
2478     my $new = do {
2479
2480       # The reason we do this now instead of passing the alias to the
2481       # search_rs below is that if you wrap/overload resultset on the
2482       # source you need to know what alias it's -going- to have for things
2483       # to work sanely (e.g. RestrictWithObject wants to be able to add
2484       # extra query restrictions, and these may need to be $alias.)
2485
2486       my $attrs = $rel_source->resultset_attributes;
2487       local $attrs->{alias} = $alias;
2488
2489       $rel_source->resultset
2490                  ->search_rs(
2491                      undef, {
2492                        %attrs,
2493                        join => undef,
2494                        prefetch => undef,
2495                        select => undef,
2496                        as => undef,
2497                        where => $self->{cond},
2498                        seen_join => $seen,
2499                        from => $from,
2500                    });
2501     };
2502     $new->set_cache($new_cache) if $new_cache;
2503     $new;
2504   };
2505 }
2506
2507 =head2 current_source_alias
2508
2509 =over 4
2510
2511 =item Arguments: none
2512
2513 =item Return Value: $source_alias
2514
2515 =back
2516
2517 Returns the current table alias for the result source this resultset is built
2518 on, that will be used in the SQL query. Usually it is C<me>.
2519
2520 Currently the source alias that refers to the result set returned by a
2521 L</search>/L</find> family method depends on how you got to the resultset: it's
2522 C<me> by default, but eg. L</search_related> aliases it to the related result
2523 source name (and keeps C<me> referring to the original result set). The long
2524 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2525 (and make this method unnecessary).
2526
2527 Thus it's currently necessary to use this method in predefined queries (see
2528 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2529 source alias of the current result set:
2530
2531   # in a result set class
2532   sub modified_by {
2533     my ($self, $user) = @_;
2534
2535     my $me = $self->current_source_alias;
2536
2537     return $self->search(
2538       "$me.modified" => $user->id,
2539     );
2540   }
2541
2542 =cut
2543
2544 sub current_source_alias {
2545   my ($self) = @_;
2546
2547   return ($self->{attrs} || {})->{alias} || 'me';
2548 }
2549
2550 # This code is called by search_related, and makes sure there
2551 # is clear separation between the joins before, during, and
2552 # after the relationship. This information is needed later
2553 # in order to properly resolve prefetch aliases (any alias
2554 # with a relation_chain_depth less than the depth of the
2555 # current prefetch is not considered)
2556 sub _resolve_from {
2557   my ($self, $extra_join) = @_;
2558   my $source = $self->result_source;
2559   my $attrs = $self->{attrs};
2560
2561   my $from = [ @{
2562       $attrs->{from}
2563         ||
2564       [{
2565         -source_handle => $source->handle,
2566         -alias => $attrs->{alias},
2567         $attrs->{alias} => $source->from,
2568       }]
2569   }];
2570
2571   my $seen = { %{$attrs->{seen_join} || {} } };
2572
2573   # we need to take the prefetch the attrs into account before we
2574   # ->_resolve_join as otherwise they get lost - captainL
2575   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2576
2577   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2578
2579   ++$seen->{-relation_chain_depth};
2580
2581   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2582
2583   ++$seen->{-relation_chain_depth};
2584
2585   return ($from,$seen);
2586 }
2587
2588 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2589 sub _resolved_attrs_copy {
2590   my $self = shift;
2591   return { %{$self->_resolved_attrs (@_)} };
2592 }
2593
2594 sub _resolved_attrs {
2595   my $self = shift;
2596   return $self->{_attrs} if $self->{_attrs};
2597
2598   my $attrs  = { %{ $self->{attrs} || {} } };
2599   my $source = $self->result_source;
2600   my $alias  = $attrs->{alias};
2601
2602   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2603   my @colbits;
2604
2605   # build columns (as long as select isn't set) into a set of as/select hashes
2606   unless ( $attrs->{select} ) {
2607       @colbits = map {
2608           ( ref($_) eq 'HASH' )
2609               ? $_
2610               : {
2611                   (
2612                     /^\Q${alias}.\E(.+)$/
2613                       ? "$1"
2614                       : "$_"
2615                   )
2616                 =>
2617                   (
2618                     /\./
2619                       ? "$_"
2620                       : "${alias}.$_"
2621                   )
2622             }
2623       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2624   }
2625   # add the additional columns on
2626   foreach ( 'include_columns', '+columns' ) {
2627       push @colbits, map {
2628           ( ref($_) eq 'HASH' )
2629             ? $_
2630             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2631       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2632   }
2633
2634   # start with initial select items
2635   if ( $attrs->{select} ) {
2636     $attrs->{select} =
2637         ( ref $attrs->{select} eq 'ARRAY' )
2638       ? [ @{ $attrs->{select} } ]
2639       : [ $attrs->{select} ];
2640     $attrs->{as} = (
2641       $attrs->{as}
2642       ? (
2643         ref $attrs->{as} eq 'ARRAY'
2644         ? [ @{ $attrs->{as} } ]
2645         : [ $attrs->{as} ]
2646         )
2647       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2648     );
2649   }
2650   else {
2651
2652     # otherwise we intialise select & as to empty
2653     $attrs->{select} = [];
2654     $attrs->{as}     = [];
2655   }
2656
2657   # now add colbits to select/as
2658   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2659   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2660
2661   my $adds;
2662   if ( $adds = delete $attrs->{'+select'} ) {
2663     $adds = [$adds] unless ref $adds eq 'ARRAY';
2664     push(
2665       @{ $attrs->{select} },
2666       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2667     );
2668   }
2669   if ( $adds = delete $attrs->{'+as'} ) {
2670     $adds = [$adds] unless ref $adds eq 'ARRAY';
2671     push( @{ $attrs->{as} }, @$adds );
2672   }
2673
2674   $attrs->{from} ||= [ {
2675     -source_handle => $source->handle,
2676     -alias => $self->{attrs}{alias},
2677     $self->{attrs}{alias} => $source->from,
2678   } ];
2679
2680   if ( $attrs->{join} || $attrs->{prefetch} ) {
2681
2682     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2683       if ref $attrs->{from} ne 'ARRAY';
2684
2685     my $join = delete $attrs->{join} || {};
2686
2687     if ( defined $attrs->{prefetch} ) {
2688       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2689     }
2690
2691     $attrs->{from} =    # have to copy here to avoid corrupting the original
2692       [
2693         @{ $attrs->{from} },
2694         $source->_resolve_join(
2695           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2696         )
2697       ];
2698   }
2699
2700   if ( $attrs->{order_by} ) {
2701     $attrs->{order_by} = (
2702       ref( $attrs->{order_by} ) eq 'ARRAY'
2703       ? [ @{ $attrs->{order_by} } ]
2704       : [ $attrs->{order_by} ]
2705     );
2706   }
2707   else {
2708     $attrs->{order_by} = [];
2709   }
2710
2711   # If the order_by is otherwise empty - we will use this for TOP limit
2712   # emulation and the like.
2713   # Although this is needed only if the order_by is not defined, it is
2714   # actually cheaper to just populate this rather than properly examining
2715   # order_by (stuf like [ {} ] and the like)
2716   my $prefix = $alias . ($source->schema->storage->_sql_maker_opts->{name_sep} || '.');
2717   $attrs->{_virtual_order_by} = [
2718     map { $prefix . $_ } ($source->primary_columns)
2719   ];
2720
2721   $attrs->{collapse} ||= {};
2722   if ( my $prefetch = delete $attrs->{prefetch} ) {
2723     $prefetch = $self->_merge_attr( {}, $prefetch );
2724
2725     my $prefetch_ordering = [];
2726
2727     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2728
2729     my @prefetch =
2730       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2731
2732     push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2733     push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2734
2735     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2736     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2737   }
2738
2739
2740   if (delete $attrs->{distinct}) {
2741     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2742   }
2743
2744   # if both page and offset are specified, produce a combined offset
2745   # even though it doesn't make much sense, this is what pre 081xx has
2746   # been doing
2747   if (my $page = delete $attrs->{page}) {
2748     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2749       ($attrs->{offset} || 0);
2750   }
2751
2752   return $self->{_attrs} = $attrs;
2753 }
2754
2755 sub _joinpath_aliases {
2756   my ($self, $fromspec, $seen) = @_;
2757
2758   my $paths = {};
2759   return $paths unless ref $fromspec eq 'ARRAY';
2760
2761   for my $j (@$fromspec) {
2762
2763     next if ref $j ne 'ARRAY';
2764     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2765
2766     my $p = $paths;
2767     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2768     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2769   }
2770
2771   return $paths;
2772 }
2773
2774 sub _rollout_attr {
2775   my ($self, $attr) = @_;
2776
2777   if (ref $attr eq 'HASH') {
2778     return $self->_rollout_hash($attr);
2779   } elsif (ref $attr eq 'ARRAY') {
2780     return $self->_rollout_array($attr);
2781   } else {
2782     return [$attr];
2783   }
2784 }
2785
2786 sub _rollout_array {
2787   my ($self, $attr) = @_;
2788
2789   my @rolled_array;
2790   foreach my $element (@{$attr}) {
2791     if (ref $element eq 'HASH') {
2792       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2793     } elsif (ref $element eq 'ARRAY') {
2794       #  XXX - should probably recurse here
2795       push( @rolled_array, @{$self->_rollout_array($element)} );
2796     } else {
2797       push( @rolled_array, $element );
2798     }
2799   }
2800   return \@rolled_array;
2801 }
2802
2803 sub _rollout_hash {
2804   my ($self, $attr) = @_;
2805
2806   my @rolled_array;
2807   foreach my $key (keys %{$attr}) {
2808     push( @rolled_array, { $key => $attr->{$key} } );
2809   }
2810   return \@rolled_array;
2811 }
2812
2813 sub _calculate_score {
2814   my ($self, $a, $b) = @_;
2815
2816   if (ref $b eq 'HASH') {
2817     my ($b_key) = keys %{$b};
2818     if (ref $a eq 'HASH') {
2819       my ($a_key) = keys %{$a};
2820       if ($a_key eq $b_key) {
2821         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2822       } else {
2823         return 0;
2824       }
2825     } else {
2826       return ($a eq $b_key) ? 1 : 0;
2827     }
2828   } else {
2829     if (ref $a eq 'HASH') {
2830       my ($a_key) = keys %{$a};
2831       return ($b eq $a_key) ? 1 : 0;
2832     } else {
2833       return ($b eq $a) ? 1 : 0;
2834     }
2835   }
2836 }
2837
2838 sub _merge_attr {
2839   my ($self, $orig, $import) = @_;
2840
2841   return $import unless defined($orig);
2842   return $orig unless defined($import);
2843
2844   $orig = $self->_rollout_attr($orig);
2845   $import = $self->_rollout_attr($import);
2846
2847   my $seen_keys;
2848   foreach my $import_element ( @{$import} ) {
2849     # find best candidate from $orig to merge $b_element into
2850     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2851     foreach my $orig_element ( @{$orig} ) {
2852       my $score = $self->_calculate_score( $orig_element, $import_element );
2853       if ($score > $best_candidate->{score}) {
2854         $best_candidate->{position} = $position;
2855         $best_candidate->{score} = $score;
2856       }
2857       $position++;
2858     }
2859     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2860
2861     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2862       push( @{$orig}, $import_element );
2863     } else {
2864       my $orig_best = $orig->[$best_candidate->{position}];
2865       # merge orig_best and b_element together and replace original with merged
2866       if (ref $orig_best ne 'HASH') {
2867         $orig->[$best_candidate->{position}] = $import_element;
2868       } elsif (ref $import_element eq 'HASH') {
2869         my ($key) = keys %{$orig_best};
2870         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2871       }
2872     }
2873     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2874   }
2875
2876   return $orig;
2877 }
2878
2879 sub result_source {
2880     my $self = shift;
2881
2882     if (@_) {
2883         $self->_source_handle($_[0]->handle);
2884     } else {
2885         $self->_source_handle->resolve;
2886     }
2887 }
2888
2889 =head2 throw_exception
2890
2891 See L<DBIx::Class::Schema/throw_exception> for details.
2892
2893 =cut
2894
2895 sub throw_exception {
2896   my $self=shift;
2897   if (ref $self && $self->_source_handle->schema) {
2898     $self->_source_handle->schema->throw_exception(@_)
2899   } else {
2900     croak(@_);
2901   }
2902
2903 }
2904
2905 # XXX: FIXME: Attributes docs need clearing up
2906
2907 =head1 ATTRIBUTES
2908
2909 Attributes are used to refine a ResultSet in various ways when
2910 searching for data. They can be passed to any method which takes an
2911 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2912 L</count>.
2913
2914 These are in no particular order:
2915
2916 =head2 order_by
2917
2918 =over 4
2919
2920 =item Value: ( $order_by | \@order_by | \%order_by )
2921
2922 =back
2923
2924 Which column(s) to order the results by. If a single column name, or
2925 an arrayref of names is supplied, the argument is passed through
2926 directly to SQL. The hashref syntax allows for connection-agnostic
2927 specification of ordering direction:
2928
2929  For descending order:
2930
2931   order_by => { -desc => [qw/col1 col2 col3/] }
2932
2933  For explicit ascending order:
2934
2935   order_by => { -asc => 'col' }
2936
2937 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2938 supported, although you are strongly encouraged to use the hashref
2939 syntax as outlined above.
2940
2941 =head2 columns
2942
2943 =over 4
2944
2945 =item Value: \@columns
2946
2947 =back
2948
2949 Shortcut to request a particular set of columns to be retrieved. Each
2950 column spec may be a string (a table column name), or a hash (in which
2951 case the key is the C<as> value, and the value is used as the C<select>
2952 expression). Adds C<me.> onto the start of any column without a C<.> in
2953 it and sets C<select> from that, then auto-populates C<as> from
2954 C<select> as normal. (You may also use the C<cols> attribute, as in
2955 earlier versions of DBIC.)
2956
2957 =head2 +columns
2958
2959 =over 4
2960
2961 =item Value: \@columns
2962
2963 =back
2964
2965 Indicates additional columns to be selected from storage. Works the same
2966 as L</columns> but adds columns to the selection. (You may also use the
2967 C<include_columns> attribute, as in earlier versions of DBIC). For
2968 example:-
2969
2970   $schema->resultset('CD')->search(undef, {
2971     '+columns' => ['artist.name'],
2972     join => ['artist']
2973   });
2974
2975 would return all CDs and include a 'name' column to the information
2976 passed to object inflation. Note that the 'artist' is the name of the
2977 column (or relationship) accessor, and 'name' is the name of the column
2978 accessor in the related table.
2979
2980 =head2 include_columns
2981
2982 =over 4
2983
2984 =item Value: \@columns
2985
2986 =back
2987
2988 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2989
2990 =head2 select
2991
2992 =over 4
2993
2994 =item Value: \@select_columns
2995
2996 =back
2997
2998 Indicates which columns should be selected from the storage. You can use
2999 column names, or in the case of RDBMS back ends, function or stored procedure
3000 names:
3001
3002   $rs = $schema->resultset('Employee')->search(undef, {
3003     select => [
3004       'name',
3005       { count => 'employeeid' },
3006       { sum => 'salary' }
3007     ]
3008   });
3009
3010 When you use function/stored procedure names and do not supply an C<as>
3011 attribute, the column names returned are storage-dependent. E.g. MySQL would
3012 return a column named C<count(employeeid)> in the above example.
3013
3014 =head2 +select
3015
3016 =over 4
3017
3018 Indicates additional columns to be selected from storage.  Works the same as
3019 L</select> but adds columns to the selection.
3020
3021 =back
3022
3023 =head2 +as
3024
3025 =over 4
3026
3027 Indicates additional column names for those added via L</+select>. See L</as>.
3028
3029 =back
3030
3031 =head2 as
3032
3033 =over 4
3034
3035 =item Value: \@inflation_names
3036
3037 =back
3038
3039 Indicates column names for object inflation. That is, C<as>
3040 indicates the name that the column can be accessed as via the
3041 C<get_column> method (or via the object accessor, B<if one already
3042 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3043
3044 The C<as> attribute is used in conjunction with C<select>,
3045 usually when C<select> contains one or more function or stored
3046 procedure names:
3047
3048   $rs = $schema->resultset('Employee')->search(undef, {
3049     select => [
3050       'name',
3051       { count => 'employeeid' }
3052     ],
3053     as => ['name', 'employee_count'],
3054   });
3055
3056   my $employee = $rs->first(); # get the first Employee
3057
3058 If the object against which the search is performed already has an accessor
3059 matching a column name specified in C<as>, the value can be retrieved using
3060 the accessor as normal:
3061
3062   my $name = $employee->name();
3063
3064 If on the other hand an accessor does not exist in the object, you need to
3065 use C<get_column> instead:
3066
3067   my $employee_count = $employee->get_column('employee_count');
3068
3069 You can create your own accessors if required - see
3070 L<DBIx::Class::Manual::Cookbook> for details.
3071
3072 Please note: This will NOT insert an C<AS employee_count> into the SQL
3073 statement produced, it is used for internal access only. Thus
3074 attempting to use the accessor in an C<order_by> clause or similar
3075 will fail miserably.
3076
3077 To get around this limitation, you can supply literal SQL to your
3078 C<select> attibute that contains the C<AS alias> text, eg:
3079
3080   select => [\'myfield AS alias']
3081
3082 =head2 join
3083
3084 =over 4
3085
3086 =item Value: ($rel_name | \@rel_names | \%rel_names)
3087
3088 =back
3089
3090 Contains a list of relationships that should be joined for this query.  For
3091 example:
3092
3093   # Get CDs by Nine Inch Nails
3094   my $rs = $schema->resultset('CD')->search(
3095     { 'artist.name' => 'Nine Inch Nails' },
3096     { join => 'artist' }
3097   );
3098
3099 Can also contain a hash reference to refer to the other relation's relations.
3100 For example:
3101
3102   package MyApp::Schema::Track;
3103   use base qw/DBIx::Class/;
3104   __PACKAGE__->table('track');
3105   __PACKAGE__->add_columns(qw/trackid cd position title/);
3106   __PACKAGE__->set_primary_key('trackid');
3107   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3108   1;
3109
3110   # In your application
3111   my $rs = $schema->resultset('Artist')->search(
3112     { 'track.title' => 'Teardrop' },
3113     {
3114       join     => { cd => 'track' },
3115       order_by => 'artist.name',
3116     }
3117   );
3118
3119 You need to use the relationship (not the table) name in  conditions,
3120 because they are aliased as such. The current table is aliased as "me", so
3121 you need to use me.column_name in order to avoid ambiguity. For example:
3122
3123   # Get CDs from 1984 with a 'Foo' track
3124   my $rs = $schema->resultset('CD')->search(
3125     {
3126       'me.year' => 1984,
3127       'tracks.name' => 'Foo'
3128     },
3129     { join => 'tracks' }
3130   );
3131
3132 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3133 similarly for a third time). For e.g.
3134
3135   my $rs = $schema->resultset('Artist')->search({
3136     'cds.title'   => 'Down to Earth',
3137     'cds_2.title' => 'Popular',
3138   }, {
3139     join => [ qw/cds cds/ ],
3140   });
3141
3142 will return a set of all artists that have both a cd with title 'Down
3143 to Earth' and a cd with title 'Popular'.
3144
3145 If you want to fetch related objects from other tables as well, see C<prefetch>
3146 below.
3147
3148 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3149
3150 =head2 prefetch
3151
3152 =over 4
3153
3154 =item Value: ($rel_name | \@rel_names | \%rel_names)
3155
3156 =back
3157
3158 Contains one or more relationships that should be fetched along with
3159 the main query (when they are accessed afterwards the data will
3160 already be available, without extra queries to the database).  This is
3161 useful for when you know you will need the related objects, because it
3162 saves at least one query:
3163
3164   my $rs = $schema->resultset('Tag')->search(
3165     undef,
3166     {
3167       prefetch => {
3168         cd => 'artist'
3169       }
3170     }
3171   );
3172
3173 The initial search results in SQL like the following:
3174
3175   SELECT tag.*, cd.*, artist.* FROM tag
3176   JOIN cd ON tag.cd = cd.cdid
3177   JOIN artist ON cd.artist = artist.artistid
3178
3179 L<DBIx::Class> has no need to go back to the database when we access the
3180 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3181 case.
3182
3183 Simple prefetches will be joined automatically, so there is no need
3184 for a C<join> attribute in the above search.
3185
3186 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3187 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3188 with an accessor type of 'single' or 'filter'). A more complex example that
3189 prefetches an artists cds, the tracks on those cds, and the tags associted
3190 with that artist is given below (assuming many-to-many from artists to tags):
3191
3192  my $rs = $schema->resultset('Artist')->search(
3193    undef,
3194    {
3195      prefetch => [
3196        { cds => 'tracks' },
3197        { artist_tags => 'tags' }
3198      ]
3199    }
3200  );
3201
3202
3203 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3204 attributes will be ignored.
3205
3206 =head2 page
3207
3208 =over 4
3209
3210 =item Value: $page
3211
3212 =back
3213
3214 Makes the resultset paged and specifies the page to retrieve. Effectively
3215 identical to creating a non-pages resultset and then calling ->page($page)
3216 on it.
3217
3218 If L<rows> attribute is not specified it defualts to 10 rows per page.
3219
3220 When you have a paged resultset, L</count> will only return the number
3221 of rows in the page. To get the total, use the L</pager> and call
3222 C<total_entries> on it.
3223
3224 =head2 rows
3225
3226 =over 4
3227
3228 =item Value: $rows
3229
3230 =back
3231
3232 Specifes the maximum number of rows for direct retrieval or the number of
3233 rows per page if the page attribute or method is used.
3234
3235 =head2 offset
3236
3237 =over 4
3238
3239 =item Value: $offset
3240
3241 =back
3242
3243 Specifies the (zero-based) row number for the  first row to be returned, or the
3244 of the first row of the first page if paging is used.
3245
3246 =head2 group_by
3247
3248 =over 4
3249
3250 =item Value: \@columns
3251
3252 =back
3253
3254 A arrayref of columns to group by. Can include columns of joined tables.
3255
3256   group_by => [qw/ column1 column2 ... /]
3257
3258 =head2 having
3259
3260 =over 4
3261
3262 =item Value: $condition
3263
3264 =back
3265
3266 HAVING is a select statement attribute that is applied between GROUP BY and
3267 ORDER BY. It is applied to the after the grouping calculations have been
3268 done.
3269
3270   having => { 'count(employee)' => { '>=', 100 } }
3271
3272 =head2 distinct
3273
3274 =over 4
3275
3276 =item Value: (0 | 1)
3277
3278 =back
3279
3280 Set to 1 to group by all columns.
3281
3282 =head2 where
3283
3284 =over 4
3285
3286 Adds to the WHERE clause.
3287
3288   # only return rows WHERE deleted IS NULL for all searches
3289   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3290
3291 Can be overridden by passing C<{ where => undef }> as an attribute
3292 to a resulset.
3293
3294 =back
3295
3296 =head2 cache
3297
3298 Set to 1 to cache search results. This prevents extra SQL queries if you
3299 revisit rows in your ResultSet:
3300
3301   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3302
3303   while( my $artist = $resultset->next ) {
3304     ... do stuff ...
3305   }
3306
3307   $rs->first; # without cache, this would issue a query
3308
3309 By default, searches are not cached.
3310
3311 For more examples of using these attributes, see
3312 L<DBIx::Class::Manual::Cookbook>.
3313
3314 =head2 from
3315
3316 =over 4
3317
3318 =item Value: \@from_clause
3319
3320 =back
3321
3322 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3323 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3324 clauses.
3325
3326 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3327
3328 C<join> will usually do what you need and it is strongly recommended that you
3329 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3330 And we really do mean "cannot", not just tried and failed. Attempting to use
3331 this because you're having problems with C<join> is like trying to use x86
3332 ASM because you've got a syntax error in your C. Trust us on this.
3333
3334 Now, if you're still really, really sure you need to use this (and if you're
3335 not 100% sure, ask the mailing list first), here's an explanation of how this
3336 works.
3337
3338 The syntax is as follows -
3339
3340   [
3341     { <alias1> => <table1> },
3342     [
3343       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3344       [], # nested JOIN (optional)
3345       { <table1.column1> => <table2.column2>, ... (more conditions) },
3346     ],
3347     # More of the above [ ] may follow for additional joins
3348   ]
3349
3350   <table1> <alias1>
3351   JOIN
3352     <table2> <alias2>
3353     [JOIN ...]
3354   ON <table1.column1> = <table2.column2>
3355   <more joins may follow>
3356
3357 An easy way to follow the examples below is to remember the following:
3358
3359     Anything inside "[]" is a JOIN
3360     Anything inside "{}" is a condition for the enclosing JOIN
3361
3362 The following examples utilize a "person" table in a family tree application.
3363 In order to express parent->child relationships, this table is self-joined:
3364
3365     # Person->belongs_to('father' => 'Person');
3366     # Person->belongs_to('mother' => 'Person');
3367
3368 C<from> can be used to nest joins. Here we return all children with a father,
3369 then search against all mothers of those children:
3370
3371   $rs = $schema->resultset('Person')->search(
3372       undef,
3373       {
3374           alias => 'mother', # alias columns in accordance with "from"
3375           from => [
3376               { mother => 'person' },
3377               [
3378                   [
3379                       { child => 'person' },
3380                       [
3381                           { father => 'person' },
3382                           { 'father.person_id' => 'child.father_id' }
3383                       ]
3384                   ],
3385                   { 'mother.person_id' => 'child.mother_id' }
3386               ],
3387           ]
3388       },
3389   );
3390
3391   # Equivalent SQL:
3392   # SELECT mother.* FROM person mother
3393   # JOIN (
3394   #   person child
3395   #   JOIN person father
3396   #   ON ( father.person_id = child.father_id )
3397   # )
3398   # ON ( mother.person_id = child.mother_id )
3399
3400 The type of any join can be controlled manually. To search against only people
3401 with a father in the person table, we could explicitly use C<INNER JOIN>:
3402
3403     $rs = $schema->resultset('Person')->search(
3404         undef,
3405         {
3406             alias => 'child', # alias columns in accordance with "from"
3407             from => [
3408                 { child => 'person' },
3409                 [
3410                     { father => 'person', -join_type => 'inner' },
3411                     { 'father.id' => 'child.father_id' }
3412                 ],
3413             ]
3414         },
3415     );
3416
3417     # Equivalent SQL:
3418     # SELECT child.* FROM person child
3419     # INNER JOIN person father ON child.father_id = father.id
3420
3421 You can select from a subquery by passing a resultset to from as follows.
3422
3423     $schema->resultset('Artist')->search(
3424         undef,
3425         {   alias => 'artist2',
3426             from  => [ { artist2 => $artist_rs->as_query } ],
3427         } );
3428
3429     # and you'll get sql like this..
3430     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3431     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3432
3433 If you need to express really complex joins, you
3434 can supply literal SQL to C<from> via a scalar reference. In this case
3435 the contents of the scalar will replace the table name associated with the
3436 resultsource.
3437
3438 WARNING: This technique might very well not work as expected on chained
3439 searches - you have been warned.
3440
3441     # Assuming the Event resultsource is defined as:
3442
3443         MySchema::Event->add_columns (
3444             sequence => {
3445                 data_type => 'INT',
3446                 is_auto_increment => 1,
3447             },
3448             location => {
3449                 data_type => 'INT',
3450             },
3451             type => {
3452                 data_type => 'INT',
3453             },
3454         );
3455         MySchema::Event->set_primary_key ('sequence');
3456
3457     # This will get back the latest event for every location. The column
3458     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3459     # combo to limit the resultset
3460
3461     $rs = $schema->resultset('Event');
3462     $table = $rs->result_source->name;
3463     $latest = $rs->search (
3464         undef,
3465         { from => \ "
3466             (SELECT e1.* FROM $table e1
3467                 JOIN $table e2
3468                     ON e1.location = e2.location
3469                     AND e1.sequence < e2.sequence
3470                 WHERE e2.sequence is NULL
3471             ) me",
3472         },
3473     );
3474
3475     # Equivalent SQL (with the DBIC chunks added):
3476
3477     SELECT me.sequence, me.location, me.type FROM
3478        (SELECT e1.* FROM events e1
3479            JOIN events e2
3480                ON e1.location = e2.location
3481                AND e1.sequence < e2.sequence
3482            WHERE e2.sequence is NULL
3483        ) me;
3484
3485 =head2 for
3486
3487 =over 4
3488
3489 =item Value: ( 'update' | 'shared' )
3490
3491 =back
3492
3493 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3494 ... FOR SHARED.
3495
3496 =cut
3497
3498 1;