lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset (ie:
 145 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 146 and attributes with the same keys need resolving.
 147
 148 If any of L</columns>, L</select>, L</as> are present, they reset the
 149 original selection, and start the selection "clean".
 150
 151 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 152 are merged into the existing ones from the original resultset.
 153
 154 The L</where> and L</having> attributes, and any search conditions, are
 155 merged with an SQL C<AND> to the existing condition from the original
 156 resultset.
 157
 158 All other attributes are overridden by any new ones supplied in the
 159 search attributes.
 160
 161 =head2 Multiple queries
 162
 163 Since a resultset just defines a query, you can do all sorts of
 164 things with it with the same object.
 165
 166   # Don't hit the DB yet.
 167   my $cd_rs = $schema->resultset('CD')->search({
 168     title => 'something',
 169     year => 2009,
 170   });
 171
 172   # Each of these hits the DB individually.
 173   my $count = $cd_rs->count;
 174   my $most_recent = $cd_rs->get_column('date_released')->max();
 175   my @records = $cd_rs->all;
 176
 177 And it's not just limited to SELECT statements.
 178
 179   $cd_rs->delete();
 180
 181 This is even cooler:
 182
 183   $cd_rs->create({ artist => 'Fred' });
 184
 185 Which is the same as:
 186
 187   $schema->resultset('CD')->create({
 188     title => 'something',
 189     year => 2009,
 190     artist => 'Fred'
 191   });
 192
 193 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 194
 195 =head1 METHODS
 196
 197 =head2 new
 198
 199 =over 4
 200
 201 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 202
 203 =item Return Value: L<$resultset|/search>
 204
 205 =back
 206
 207 The resultset constructor. Takes a source object (usually a
 208 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 209 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 210 executed as needed by the other methods.
 211
 212 Generally you never construct a resultset manually. Instead you get one
 213 from e.g. a
 214 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 215 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 216 scalar context):
 217
 218   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 219
 220 =over
 221
 222 =item WARNING
 223
 224 If called on an object, proxies to L</new_result> instead, so
 225
 226   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 227
 228 will return a CD object, not a ResultSet, and is equivalent to:
 229
 230   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 231
 232 Please also keep in mind that many internals call L</new_result> directly,
 233 so overloading this method with the idea of intercepting new result object
 234 creation B<will not work>. See also warning pertaining to L</create>.
 235
 236 =back
 237
 238 =cut
 239
 240 sub new {
 241   my $class = shift;
 242   return $class->new_result(@_) if ref $class;
 243
 244   my ($source, $attrs) = @_;
 245   $source = $source->resolve
 246     if $source->isa('DBIx::Class::ResultSourceHandle');
 247   $attrs = { %{$attrs||{}} };
 248
 249   if ($attrs->{page}) {
 250     $attrs->{rows} ||= 10;
 251   }
 252
 253   $attrs->{alias} ||= 'me';
 254
 255   my $self = bless {
 256     result_source => $source,
 257     cond => $attrs->{where},
 258     pager => undef,
 259     attrs => $attrs,
 260   }, $class;
 261
 262   # if there is a dark selector, this means we are already in a
 263   # chain and the cleanup/sanification was taken care of by
 264   # _search_rs already
 265   $self->_normalize_selection($attrs)
 266     unless $attrs->{_dark_selector};
 267
 268   $self->result_class(
 269     $attrs->{result_class} || $source->result_class
 270   );
 271
 272   $self;
 273 }
 274
 275 =head2 search
 276
 277 =over 4
 278
 279 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 280
 281 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 282
 283 =back
 284
 285   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 286   my $new_rs = $cd_rs->search({ year => 2005 });
 287
 288   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 289                  # year = 2005 OR year = 2004
 290
 291 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 292 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 293 To avoid that, use L</search_rs>.
 294
 295 If you need to pass in additional attributes but no additional condition,
 296 call it as C<search(undef, \%attrs)>.
 297
 298   # "SELECT name, artistid FROM $artist_table"
 299   my @all_artists = $schema->resultset('Artist')->search(undef, {
 300     columns => [qw/name artistid/],
 301   });
 302
 303 For a list of attributes that can be passed to C<search>, see
 304 L</ATTRIBUTES>. For more examples of using this function, see
 305 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 306 documentation for the first argument, see L<SQL::Abstract>
 307 and its extension L<DBIx::Class::SQLMaker>.
 308
 309 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 310
 311 =head3 CAVEAT
 312
 313 Note that L</search> does not process/deflate any of the values passed in the
 314 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 315 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 316 manually that any value passed to this method will stringify to something the
 317 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 318 objects, for more info see:
 319 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 320
 321 =cut
 322
 323 sub search {
 324   my $self = shift;
 325   my $rs = $self->search_rs( @_ );
 326
 327   if (wantarray) {
 328     return $rs->all;
 329   }
 330   elsif (defined wantarray) {
 331     return $rs;
 332   }
 333   else {
 334     # we can be called by a relationship helper, which in
 335     # turn may be called in void context due to some braindead
 336     # overload or whatever else the user decided to be clever
 337     # at this particular day. Thus limit the exception to
 338     # external code calls only
 339     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 340       if (caller)[0] !~ /^\QDBIx::Class::/;
 341
 342     return ();
 343   }
 344 }
 345
 346 =head2 search_rs
 347
 348 =over 4
 349
 350 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 351
 352 =item Return Value: L<$resultset|/search>
 353
 354 =back
 355
 356 This method does the same exact thing as search() except it will
 357 always return a resultset, even in list context.
 358
 359 =cut
 360
 361 sub search_rs {
 362   my $self = shift;
 363
 364   my $rsrc = $self->result_source;
 365   my ($call_cond, $call_attrs);
 366
 367   # Special-case handling for (undef, undef) or (undef)
 368   # Note that (foo => undef) is valid deprecated syntax
 369   @_ = () if not scalar grep { defined $_ } @_;
 370
 371   # just a cond
 372   if (@_ == 1) {
 373     $call_cond = shift;
 374   }
 375   # fish out attrs in the ($condref, $attr) case
 376   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 377     ($call_cond, $call_attrs) = @_;
 378   }
 379   elsif (@_ % 2) {
 380     $self->throw_exception('Odd number of arguments to search')
 381   }
 382   # legacy search
 383   elsif (@_) {
 384     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 385       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 386
 387     for my $i (0 .. $#_) {
 388       next if $i % 2;
 389       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 390         if (! defined $_[$i] or ref $_[$i] ne '');
 391     }
 392
 393     $call_cond = { @_ };
 394   }
 395
 396   # see if we can keep the cache (no $rs changes)
 397   my $cache;
 398   my %safe = (alias => 1, cache => 1);
 399   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 400     ! defined $call_cond
 401       or
 402     ref $call_cond eq 'HASH' && ! keys %$call_cond
 403       or
 404     ref $call_cond eq 'ARRAY' && ! @$call_cond
 405   )) {
 406     $cache = $self->get_cache;
 407   }
 408
 409   my $old_attrs = { %{$self->{attrs}} };
 410   my $old_having = delete $old_attrs->{having};
 411   my $old_where = delete $old_attrs->{where};
 412
 413   my $new_attrs = { %$old_attrs };
 414
 415   # take care of call attrs (only if anything is changing)
 416   if ($call_attrs and keys %$call_attrs) {
 417
 418     # copy for _normalize_selection
 419     $call_attrs = { %$call_attrs };
 420
 421     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 422
 423     # reset the current selector list if new selectors are supplied
 424     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 425       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 426     }
 427
 428     # Normalize the new selector list (operates on the passed-in attr structure)
 429     # Need to do it on every chain instead of only once on _resolved_attrs, in
 430     # order to allow detection of empty vs partial 'as'
 431     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 432       if $old_attrs->{_dark_selector};
 433     $self->_normalize_selection ($call_attrs);
 434
 435     # start with blind overwriting merge, exclude selector attrs
 436     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 437     delete @{$new_attrs}{@selector_attrs};
 438
 439     for (@selector_attrs) {
 440       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 441         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 442     }
 443
 444     # older deprecated name, use only if {columns} is not there
 445     if (my $c = delete $new_attrs->{cols}) {
 446       if ($new_attrs->{columns}) {
 447         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 448       }
 449       else {
 450         $new_attrs->{columns} = $c;
 451       }
 452     }
 453
 454
 455     # join/prefetch use their own crazy merging heuristics
 456     foreach my $key (qw/join prefetch/) {
 457       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 458         if exists $call_attrs->{$key};
 459     }
 460
 461     # stack binds together
 462     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 463   }
 464
 465
 466   for ($old_where, $call_cond) {
 467     if (defined $_) {
 468       $new_attrs->{where} = $self->_stack_cond (
 469         $_, $new_attrs->{where}
 470       );
 471     }
 472   }
 473
 474   if (defined $old_having) {
 475     $new_attrs->{having} = $self->_stack_cond (
 476       $old_having, $new_attrs->{having}
 477     )
 478   }
 479
 480   my $rs = (ref $self)->new($rsrc, $new_attrs);
 481
 482   $rs->set_cache($cache) if ($cache);
 483
 484   return $rs;
 485 }
 486
 487 my $dark_sel_dumper;
 488 sub _normalize_selection {
 489   my ($self, $attrs) = @_;
 490
 491   # legacy syntax
 492   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 493     if exists $attrs->{include_columns};
 494
 495   # columns are always placed first, however
 496
 497   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 498   # delay the decision on whether to use a default select list ($rsrc->columns)
 499   # allowing stuff like the remove_columns helper to work
 500   #
 501   # select/as +select/+as pairs need special handling - the amount of select/as
 502   # elements in each pair does *not* have to be equal (think multicolumn
 503   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 504   # supplied at all) - try to infer the alias, either from the -as parameter
 505   # of the selector spec, or use the parameter whole if it looks like a column
 506   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 507   # is ok as well), but make sure no more additions to the 'as' chain take place
 508   for my $pref ('', '+') {
 509
 510     my ($sel, $as) = map {
 511       my $key = "${pref}${_}";
 512
 513       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 514         ? @{$attrs->{$key}}
 515         : $attrs->{$key} || ()
 516       ];
 517       delete $attrs->{$key};
 518       $val;
 519     } qw/select as/;
 520
 521     if (! @$as and ! @$sel ) {
 522       next;
 523     }
 524     elsif (@$as and ! @$sel) {
 525       $self->throw_exception(
 526         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 527       );
 528     }
 529     elsif( ! @$as ) {
 530       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 531       # if any @$as has been supplied we assume the user knows what (s)he is doing
 532       # and blindly keep stacking up pieces
 533       unless ($attrs->{_dark_selector}) {
 534         SELECTOR:
 535         for (@$sel) {
 536           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 537             push @$as, $_->{-as};
 538           }
 539           # assume any plain no-space, no-parenthesis string to be a column spec
 540           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 541           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 542             push @$as, $_;
 543           }
 544           # if all else fails - raise a flag that no more aliasing will be allowed
 545           else {
 546             $attrs->{_dark_selector} = {
 547               plus_stage => $pref,
 548               string => ($dark_sel_dumper ||= do {
 549                   require Data::Dumper::Concise;
 550                   Data::Dumper::Concise::DumperObject()->Indent(0);
 551                 })->Values([$_])->Dump
 552               ,
 553             };
 554             last SELECTOR;
 555           }
 556         }
 557       }
 558     }
 559     elsif (@$as < @$sel) {
 560       $self->throw_exception(
 561         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 562       );
 563     }
 564     elsif ($pref and $attrs->{_dark_selector}) {
 565       $self->throw_exception(
 566         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 567       );
 568     }
 569
 570
 571     # merge result
 572     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 573     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 574   }
 575 }
 576
 577 sub _stack_cond {
 578   my ($self, $left, $right) = @_;
 579
 580   # collapse single element top-level conditions
 581   # (single pass only, unlikely to need recursion)
 582   for ($left, $right) {
 583     if (ref $_ eq 'ARRAY') {
 584       if (@$_ == 0) {
 585         $_ = undef;
 586       }
 587       elsif (@$_ == 1) {
 588         $_ = $_->[0];
 589       }
 590     }
 591     elsif (ref $_ eq 'HASH') {
 592       my ($first, $more) = keys %$_;
 593
 594       # empty hash
 595       if (! defined $first) {
 596         $_ = undef;
 597       }
 598       # one element hash
 599       elsif (! defined $more) {
 600         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 601           $_ = $_->{'-and'};
 602         }
 603         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 604           $_ = $_->{'-or'};
 605         }
 606       }
 607     }
 608   }
 609
 610   # merge hashes with weeding out of duplicates (simple cases only)
 611   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 612
 613     # shallow copy to destroy
 614     $right = { %$right };
 615     for (grep { exists $right->{$_} } keys %$left) {
 616       # the use of eq_deeply here is justified - the rhs of an
 617       # expression can contain a lot of twisted weird stuff
 618       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 619     }
 620
 621     $right = undef unless keys %$right;
 622   }
 623
 624
 625   if (defined $left xor defined $right) {
 626     return defined $left ? $left : $right;
 627   }
 628   elsif (! defined $left) {
 629     return undef;
 630   }
 631   else {
 632     return { -and => [ $left, $right ] };
 633   }
 634 }
 635
 636 =head2 search_literal
 637
 638 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 639 should only be used in that context. C<search_literal> is a convenience
 640 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 641 want to ensure columns are bound correctly, use L</search>.
 642
 643 See L<DBIx::Class::Manual::Cookbook/Searching> and
 644 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 645 require C<search_literal>.
 646
 647 =over 4
 648
 649 =item Arguments: $sql_fragment, @standalone_bind_values
 650
 651 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 652
 653 =back
 654
 655   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 656   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 657
 658 Pass a literal chunk of SQL to be added to the conditional part of the
 659 resultset query.
 660
 661 Example of how to use C<search> instead of C<search_literal>
 662
 663   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 664   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 665
 666 =cut
 667
 668 sub search_literal {
 669   my ($self, $sql, @bind) = @_;
 670   my $attr;
 671   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 672     $attr = pop @bind;
 673   }
 674   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 675 }
 676
 677 =head2 find
 678
 679 =over 4
 680
 681 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 682
 683 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 684
 685 =back
 686
 687 Finds and returns a single row based on supplied criteria. Takes either a
 688 hashref with the same format as L</create> (including inference of foreign
 689 keys from related objects), or a list of primary key values in the same
 690 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 691 declaration on the L</result_source>.
 692
 693 In either case an attempt is made to combine conditions already existing on
 694 the resultset with the condition passed to this method.
 695
 696 To aid with preparing the correct query for the storage you may supply the
 697 C<key> attribute, which is the name of a
 698 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 699 unique constraint corresponding to the
 700 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 701 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 702 to construct a query that satisfies the named unique constraint fully (
 703 non-NULL values for each column member of the constraint) an exception is
 704 thrown.
 705
 706 If no C<key> is specified, the search is carried over all unique constraints
 707 which are fully defined by the available condition.
 708
 709 If no such constraint is found, C<find> currently defaults to a simple
 710 C<< search->(\%column_values) >> which may or may not do what you expect.
 711 Note that this fallback behavior may be deprecated in further versions. If
 712 you need to search with arbitrary conditions - use L</search>. If the query
 713 resulting from this fallback produces more than one row, a warning to the
 714 effect is issued, though only the first row is constructed and returned as
 715 C<$result_object>.
 716
 717 In addition to C<key>, L</find> recognizes and applies standard
 718 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 719
 720 Note that if you have extra concerns about the correctness of the resulting
 721 query you need to specify the C<key> attribute and supply the entire condition
 722 as an argument to find (since it is not always possible to perform the
 723 combination of the resultset condition with the supplied one, especially if
 724 the resultset condition contains literal sql).
 725
 726 For example, to find a row by its primary key:
 727
 728   my $cd = $schema->resultset('CD')->find(5);
 729
 730 You can also find a row by a specific unique constraint:
 731
 732   my $cd = $schema->resultset('CD')->find(
 733     {
 734       artist => 'Massive Attack',
 735       title  => 'Mezzanine',
 736     },
 737     { key => 'cd_artist_title' }
 738   );
 739
 740 See also L</find_or_create> and L</update_or_create>.
 741
 742 =cut
 743
 744 sub find {
 745   my $self = shift;
 746   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 747
 748   my $rsrc = $self->result_source;
 749
 750   my $constraint_name;
 751   if (exists $attrs->{key}) {
 752     $constraint_name = defined $attrs->{key}
 753       ? $attrs->{key}
 754       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 755     ;
 756   }
 757
 758   # Parse out the condition from input
 759   my $call_cond;
 760
 761   if (ref $_[0] eq 'HASH') {
 762     $call_cond = { %{$_[0]} };
 763   }
 764   else {
 765     # if only values are supplied we need to default to 'primary'
 766     $constraint_name = 'primary' unless defined $constraint_name;
 767
 768     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 769
 770     $self->throw_exception(
 771       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 772     ) unless @c_cols;
 773
 774     $self->throw_exception (
 775       'find() expects either a column/value hashref, or a list of values '
 776     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 777     ) unless @c_cols == @_;
 778
 779     $call_cond = {};
 780     @{$call_cond}{@c_cols} = @_;
 781   }
 782
 783   my %related;
 784   for my $key (keys %$call_cond) {
 785     if (
 786       my $keyref = ref($call_cond->{$key})
 787         and
 788       my $relinfo = $rsrc->relationship_info($key)
 789     ) {
 790       my $val = delete $call_cond->{$key};
 791
 792       next if $keyref eq 'ARRAY'; # has_many for multi_create
 793
 794       my $rel_q = $rsrc->_resolve_condition(
 795         $relinfo->{cond}, $val, $key, $key
 796       );
 797       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 798       @related{keys %$rel_q} = values %$rel_q;
 799     }
 800   }
 801
 802   # relationship conditions take precedence (?)
 803   @{$call_cond}{keys %related} = values %related;
 804
 805   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 806   my $final_cond;
 807   if (defined $constraint_name) {
 808     $final_cond = $self->_qualify_cond_columns (
 809
 810       $self->_build_unique_cond (
 811         $constraint_name,
 812         $call_cond,
 813       ),
 814
 815       $alias,
 816     );
 817   }
 818   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 819     # This means that we got here after a merger of relationship conditions
 820     # in ::Relationship::Base::search_related (the row method), and furthermore
 821     # the relationship is of the 'single' type. This means that the condition
 822     # provided by the relationship (already attached to $self) is sufficient,
 823     # as there can be only one row in the database that would satisfy the
 824     # relationship
 825   }
 826   else {
 827     # no key was specified - fall down to heuristics mode:
 828     # run through all unique queries registered on the resultset, and
 829     # 'OR' all qualifying queries together
 830     my (@unique_queries, %seen_column_combinations);
 831     for my $c_name ($rsrc->unique_constraint_names) {
 832       next if $seen_column_combinations{
 833         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 834       }++;
 835
 836       push @unique_queries, try {
 837         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 838       } || ();
 839     }
 840
 841     $final_cond = @unique_queries
 842       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 843       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 844     ;
 845   }
 846
 847   # Run the query, passing the result_class since it should propagate for find
 848   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 849   if ($rs->_resolved_attrs->{collapse}) {
 850     my $row = $rs->next;
 851     carp "Query returned more than one row" if $rs->next;
 852     return $row;
 853   }
 854   else {
 855     return $rs->single;
 856   }
 857 }
 858
 859 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 860 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 861 #
 862 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 863 # condition. It is provided for overrides until a saner way forward is devised
 864 #
 865 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 866 # the road. Please adjust your tests accordingly to catch this situation early
 867 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 868 #
 869 # The method will not be removed without an adequately complete replacement
 870 # for strict-mode enforcement
 871 sub _non_unique_find_fallback {
 872   my ($self, $cond, $attrs) = @_;
 873
 874   return $self->_qualify_cond_columns(
 875     $cond,
 876     exists $attrs->{alias}
 877       ? $attrs->{alias}
 878       : $self->{attrs}{alias}
 879   );
 880 }
 881
 882
 883 sub _qualify_cond_columns {
 884   my ($self, $cond, $alias) = @_;
 885
 886   my %aliased = %$cond;
 887   for (keys %aliased) {
 888     $aliased{"$alias.$_"} = delete $aliased{$_}
 889       if $_ !~ /\./;
 890   }
 891
 892   return \%aliased;
 893 }
 894
 895 sub _build_unique_cond {
 896   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 897
 898   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 899
 900   # combination may fail if $self->{cond} is non-trivial
 901   my ($final_cond) = try {
 902     $self->_merge_with_rscond ($extra_cond)
 903   } catch {
 904     +{ %$extra_cond }
 905   };
 906
 907   # trim out everything not in $columns
 908   $final_cond = { map {
 909     exists $final_cond->{$_}
 910       ? ( $_ => $final_cond->{$_} )
 911       : ()
 912   } @c_cols };
 913
 914   if (my @missing = grep
 915     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 916     (@c_cols)
 917   ) {
 918     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 919       $constraint_name,
 920       join (', ', map { "'$_'" } @missing),
 921     ) );
 922   }
 923
 924   if (
 925     !$croak_on_null
 926       and
 927     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 928       and
 929     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 930   ) {
 931     carp_unique ( sprintf (
 932       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 933     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 934     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 935       $constraint_name,
 936       join (', ', map { "'$_'" } @undefs),
 937     ));
 938   }
 939
 940   return $final_cond;
 941 }
 942
 943 =head2 search_related
 944
 945 =over 4
 946
 947 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 948
 949 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 950
 951 =back
 952
 953   $new_rs = $cd_rs->search_related('artist', {
 954     name => 'Emo-R-Us',
 955   });
 956
 957 Searches the specified relationship, optionally specifying a condition and
 958 attributes for matching records. See L</ATTRIBUTES> for more information.
 959
 960 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 961 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 962
 963 See also L</search_related_rs>.
 964
 965 =cut
 966
 967 sub search_related {
 968   return shift->related_resultset(shift)->search(@_);
 969 }
 970
 971 =head2 search_related_rs
 972
 973 This method works exactly the same as search_related, except that
 974 it guarantees a resultset, even in list context.
 975
 976 =cut
 977
 978 sub search_related_rs {
 979   return shift->related_resultset(shift)->search_rs(@_);
 980 }
 981
 982 =head2 cursor
 983
 984 =over 4
 985
 986 =item Arguments: none
 987
 988 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 989
 990 =back
 991
 992 Returns a storage-driven cursor to the given resultset. See
 993 L<DBIx::Class::Cursor> for more information.
 994
 995 =cut
 996
 997 sub cursor {
 998   my $self = shift;
 999
1000   return $self->{cursor} ||= do {
1001     my $attrs = { %{$self->_resolved_attrs } };
1002     $self->result_source->storage->select(
1003       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1004     );
1005   };
1006 }
1007
1008 =head2 single
1009
1010 =over 4
1011
1012 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1013
1014 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1015
1016 =back
1017
1018   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1019
1020 Inflates the first result without creating a cursor if the resultset has
1021 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1022 of L</search>.
1023
1024 While this method can take an optional search condition (just like L</search>)
1025 being a fast-code-path it does not recognize search attributes. If you need to
1026 add extra joins or similar, call L</search> and then chain-call L</single> on the
1027 L<DBIx::Class::ResultSet> returned.
1028
1029 =over
1030
1031 =item B<Note>
1032
1033 As of 0.08100, this method enforces the assumption that the preceding
1034 query returns only one row. If more than one row is returned, you will receive
1035 a warning:
1036
1037   Query returned more than one row
1038
1039 In this case, you should be using L</next> or L</find> instead, or if you really
1040 know what you are doing, use the L</rows> attribute to explicitly limit the size
1041 of the resultset.
1042
1043 This method will also throw an exception if it is called on a resultset prefetching
1044 has_many, as such a prefetch implies fetching multiple rows from the database in
1045 order to assemble the resulting object.
1046
1047 =back
1048
1049 =cut
1050
1051 sub single {
1052   my ($self, $where) = @_;
1053   if(@_ > 2) {
1054       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1055   }
1056
1057   my $attrs = { %{$self->_resolved_attrs} };
1058
1059   $self->throw_exception(
1060     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1061   ) if $attrs->{collapse};
1062
1063   if ($where) {
1064     if (defined $attrs->{where}) {
1065       $attrs->{where} = {
1066         '-and' =>
1067             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1068                $where, delete $attrs->{where} ]
1069       };
1070     } else {
1071       $attrs->{where} = $where;
1072     }
1073   }
1074
1075   my $data = [ $self->result_source->storage->select_single(
1076     $attrs->{from}, $attrs->{select},
1077     $attrs->{where}, $attrs
1078   )];
1079   return undef unless @$data;
1080   $self->{stashed_rows} = [ $data ];
1081   $self->_construct_objects->[0];
1082 }
1083
1084
1085 # _collapse_query
1086 #
1087 # Recursively collapse the query, accumulating values for each column.
1088
1089 sub _collapse_query {
1090   my ($self, $query, $collapsed) = @_;
1091
1092   $collapsed ||= {};
1093
1094   if (ref $query eq 'ARRAY') {
1095     foreach my $subquery (@$query) {
1096       next unless ref $subquery;  # -or
1097       $collapsed = $self->_collapse_query($subquery, $collapsed);
1098     }
1099   }
1100   elsif (ref $query eq 'HASH') {
1101     if (keys %$query and (keys %$query)[0] eq '-and') {
1102       foreach my $subquery (@{$query->{-and}}) {
1103         $collapsed = $self->_collapse_query($subquery, $collapsed);
1104       }
1105     }
1106     else {
1107       foreach my $col (keys %$query) {
1108         my $value = $query->{$col};
1109         $collapsed->{$col}{$value}++;
1110       }
1111     }
1112   }
1113
1114   return $collapsed;
1115 }
1116
1117 =head2 get_column
1118
1119 =over 4
1120
1121 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1122
1123 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1124
1125 =back
1126
1127   my $max_length = $rs->get_column('length')->max;
1128
1129 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1130
1131 =cut
1132
1133 sub get_column {
1134   my ($self, $column) = @_;
1135   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1136   return $new;
1137 }
1138
1139 =head2 search_like
1140
1141 =over 4
1142
1143 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1144
1145 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1146
1147 =back
1148
1149   # WHERE title LIKE '%blue%'
1150   $cd_rs = $rs->search_like({ title => '%blue%'});
1151
1152 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1153 that this is simply a convenience method retained for ex Class::DBI users.
1154 You most likely want to use L</search> with specific operators.
1155
1156 For more information, see L<DBIx::Class::Manual::Cookbook>.
1157
1158 This method is deprecated and will be removed in 0.09. Use L</search()>
1159 instead. An example conversion is:
1160
1161   ->search_like({ foo => 'bar' });
1162
1163   # Becomes
1164
1165   ->search({ foo => { like => 'bar' } });
1166
1167 =cut
1168
1169 sub search_like {
1170   my $class = shift;
1171   carp_unique (
1172     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1173    .' Instead use ->search({ x => { -like => "y%" } })'
1174    .' (note the outer pair of {}s - they are important!)'
1175   );
1176   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1177   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1178   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1179   return $class->search($query, { %$attrs });
1180 }
1181
1182 =head2 slice
1183
1184 =over 4
1185
1186 =item Arguments: $first, $last
1187
1188 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1189
1190 =back
1191
1192 Returns a resultset or object list representing a subset of elements from the
1193 resultset slice is called on. Indexes are from 0, i.e., to get the first
1194 three records, call:
1195
1196   my ($one, $two, $three) = $rs->slice(0, 2);
1197
1198 =cut
1199
1200 sub slice {
1201   my ($self, $min, $max) = @_;
1202   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1203   $attrs->{offset} = $self->{attrs}{offset} || 0;
1204   $attrs->{offset} += $min;
1205   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1206   return $self->search(undef, $attrs);
1207   #my $slice = (ref $self)->new($self->result_source, $attrs);
1208   #return (wantarray ? $slice->all : $slice);
1209 }
1210
1211 =head2 next
1212
1213 =over 4
1214
1215 =item Arguments: none
1216
1217 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1218
1219 =back
1220
1221 Returns the next element in the resultset (C<undef> is there is none).
1222
1223 Can be used to efficiently iterate over records in the resultset:
1224
1225   my $rs = $schema->resultset('CD')->search;
1226   while (my $cd = $rs->next) {
1227     print $cd->title;
1228   }
1229
1230 Note that you need to store the resultset object, and call C<next> on it.
1231 Calling C<< resultset('Table')->next >> repeatedly will always return the
1232 first record from the resultset.
1233
1234 =cut
1235
1236 sub next {
1237   my ($self) = @_;
1238
1239   if (my $cache = $self->get_cache) {
1240     $self->{all_cache_position} ||= 0;
1241     return $cache->[$self->{all_cache_position}++];
1242   }
1243
1244   if ($self->{attrs}{cache}) {
1245     delete $self->{pager};
1246     $self->{all_cache_position} = 1;
1247     return ($self->all)[0];
1248   }
1249
1250   return shift(@{$self->{stashed_objects}}) if @{ $self->{stashed_objects}||[] };
1251
1252   $self->{stashed_objects} = $self->_construct_objects
1253     or return undef;
1254
1255   return shift @{$self->{stashed_objects}};
1256 }
1257
1258 # Constructs as many objects as it can in one pass while respecting
1259 # cursor laziness. Several modes of operation:
1260 #
1261 # * Always builds everything present in @{$self->{stashed_rows}}
1262 # * If called with $fetch_all true - pulls everything off the cursor and
1263 #   builds all objects in one pass
1264 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1265 #   and if the resultset is ordered properly by the left side:
1266 #   * Fetches stuff off the cursor until the "master object" changes,
1267 #     and saves the last extra row (if any) in @{$self->{stashed_rows}}
1268 #   OR
1269 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1270 #     was requested (there is no other way to collapse except for an
1271 #     eager cursor)
1272 # * If no collapse is requested - just get the next row, construct and
1273 #   return
1274 sub _construct_objects {
1275   my ($self, $fetch_all) = @_;
1276
1277   my $rsrc = $self->result_source;
1278   my $attrs = $self->_resolved_attrs;
1279
1280   if (!$fetch_all and ! $attrs->{order_by} and $attrs->{collapse}) {
1281     # default order for collapsing unless the user asked for something
1282     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} $rsrc->primary_columns ];
1283     $attrs->{_ordered_for_collapse} = 1;
1284     $attrs->{_order_is_artificial} = 1;
1285   }
1286
1287   my $cursor = $self->cursor;
1288
1289   # this will be used as both initial raw-row collector AND as a RV of
1290   # _construct_objects. Not regrowing the array twice matters a lot...
1291   # a suprising amount actually
1292   my $rows = delete $self->{stashed_rows};
1293
1294   if ($fetch_all) {
1295     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1296     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1297   }
1298   elsif( $attrs->{collapse} ) {
1299
1300     $attrs->{_ordered_for_collapse} = (!$attrs->{order_by}) ? 0 : do {
1301       my $st = $rsrc->schema->storage;
1302       my @ord_cols = map
1303         { $_->[0] }
1304         ( $st->_extract_order_criteria($attrs->{order_by}) )
1305       ;
1306
1307       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1308
1309       for (0 .. $#ord_cols) {
1310         if (
1311           ! $colinfos->{$ord_cols[$_]}
1312             or
1313           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1314         ) {
1315           splice @ord_cols, $_;
1316           last;
1317         }
1318       }
1319
1320       # since all we check here are the start of the order_by belonging to the
1321       # top level $rsrc, a present identifying set will mean that the resultset
1322       # is ordered by its leftmost table in a tsable manner
1323       (@ord_cols and $rsrc->_identifying_column_set({ map
1324         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1325         @ord_cols
1326       })) ? 1 : 0;
1327     } unless defined $attrs->{_ordered_for_collapse};
1328
1329     if (! $attrs->{_ordered_for_collapse}) {
1330       $fetch_all = 1;
1331
1332       # instead of looping over ->next, use ->all in stealth mode
1333       # *without* calling a ->reset afterwards
1334       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1335       if (! $cursor->{_done}) {
1336         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1337         $cursor->{_done} = 1;
1338       }
1339     }
1340   }
1341
1342   if (! $fetch_all and ! @{$rows||[]} ) {
1343     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1344     if (scalar (my @r = $cursor->next) ) {
1345       $rows = [ \@r ];
1346     }
1347   }
1348
1349   return undef unless @{$rows||[]};
1350
1351   my @extra_collapser_args;
1352   if ($attrs->{collapse} and ! $fetch_all ) {
1353
1354     @extra_collapser_args = (
1355       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1356       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1357       ($self->{stashed_rows} = []),                 # where does it stuff excess
1358     );
1359   }
1360
1361   # hotspot - skip the setter
1362   my $res_class = $self->_result_class;
1363
1364   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1365     $res_class->can ('inflate_result')
1366       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1367   };
1368
1369   my $infmap = $attrs->{as};
1370
1371   $self->{_result_inflator}{is_hri} = do { ( $inflator_cref == (
1372     require DBIx::Class::ResultClass::HashRefInflator
1373       &&
1374     DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1375   ) ) ? 1 : 0
1376   } unless defined $self->{_result_inflator}{is_hri};
1377
1378   if ($attrs->{_single_resultclass_inflation}) {
1379     # construct a much simpler array->hash folder for the one-table cases right here
1380     if ($self->{_result_inflator}{is_hri}) {
1381       for my $r (@$rows) {
1382         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1383       }
1384     }
1385     # FIXME SUBOPTIMAL this is a very very very hot spot
1386     # while rather optimal we can *still* do much better, by
1387     # building a smarter Row::inflate_result(), and
1388     # switch to feeding it data via a much leaner interface
1389     #
1390     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1391     # this particular resultset size
1392     elsif (@$rows < 60) {
1393       for my $r (@$rows) {
1394         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1395       }
1396     }
1397     else {
1398       eval sprintf (
1399         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1400         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1401       );
1402     }
1403   }
1404   # Special-case multi-object HRI (we always prune)
1405   elsif ($self->{_result_inflator}{is_hri}) {
1406     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1407       eval => 1,
1408       inflate_map => $infmap,
1409       selection => $attrs->{select},
1410       collapse => $attrs->{collapse},
1411       premultiplied => $attrs->{_main_source_premultiplied},
1412       hri_style => 1,
1413     }) )->($rows, @extra_collapser_args);
1414   }
1415   # Regular multi-object
1416   else {
1417
1418     ( $self->{_row_parser}{classic} ||= $rsrc->_mk_row_parser({
1419       eval => 1,
1420       inflate_map => $infmap,
1421       selection => $attrs->{select},
1422       collapse => $attrs->{collapse},
1423       premultiplied => $attrs->{_main_source_premultiplied},
1424     }) )->($rows, @extra_collapser_args);
1425
1426     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1427   }
1428
1429   # CDBI compat stuff
1430   if ($attrs->{record_filter}) {
1431     $_ = $attrs->{record_filter}->($_) for @$rows;
1432   }
1433
1434   return $rows;
1435 }
1436
1437 =head2 result_source
1438
1439 =over 4
1440
1441 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1442
1443 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1444
1445 =back
1446
1447 An accessor for the primary ResultSource object from which this ResultSet
1448 is derived.
1449
1450 =head2 result_class
1451
1452 =over 4
1453
1454 =item Arguments: $result_class?
1455
1456 =item Return Value: $result_class
1457
1458 =back
1459
1460 An accessor for the class to use when creating result objects. Defaults to
1461 C<< result_source->result_class >> - which in most cases is the name of the
1462 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1463
1464 Note that changing the result_class will also remove any components
1465 that were originally loaded in the source class via
1466 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1467 in the original source class will not run.
1468
1469 =cut
1470
1471 sub result_class {
1472   my ($self, $result_class) = @_;
1473   if ($result_class) {
1474
1475     # don't fire this for an object
1476     $self->ensure_class_loaded($result_class)
1477       unless ref($result_class);
1478
1479     if ($self->get_cache) {
1480       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1481     }
1482     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1483     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1484       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1485     }
1486
1487     $self->_result_class($result_class);
1488
1489     delete $self->{_result_inflator};
1490   }
1491   $self->_result_class;
1492 }
1493
1494 =head2 count
1495
1496 =over 4
1497
1498 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1499
1500 =item Return Value: $count
1501
1502 =back
1503
1504 Performs an SQL C<COUNT> with the same query as the resultset was built
1505 with to find the number of elements. Passing arguments is equivalent to
1506 C<< $rs->search ($cond, \%attrs)->count >>
1507
1508 =cut
1509
1510 sub count {
1511   my $self = shift;
1512   return $self->search(@_)->count if @_ and defined $_[0];
1513   return scalar @{ $self->get_cache } if $self->get_cache;
1514
1515   my $attrs = { %{ $self->_resolved_attrs } };
1516
1517   # this is a little optimization - it is faster to do the limit
1518   # adjustments in software, instead of a subquery
1519   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1520
1521   my $crs;
1522   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1523     $crs = $self->_count_subq_rs ($attrs);
1524   }
1525   else {
1526     $crs = $self->_count_rs ($attrs);
1527   }
1528   my $count = $crs->next;
1529
1530   $count -= $offset if $offset;
1531   $count = $rows if $rows and $rows < $count;
1532   $count = 0 if ($count < 0);
1533
1534   return $count;
1535 }
1536
1537 =head2 count_rs
1538
1539 =over 4
1540
1541 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1542
1543 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1544
1545 =back
1546
1547 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1548 This can be very handy for subqueries:
1549
1550   ->search( { amount => $some_rs->count_rs->as_query } )
1551
1552 As with regular resultsets the SQL query will be executed only after
1553 the resultset is accessed via L</next> or L</all>. That would return
1554 the same single value obtainable via L</count>.
1555
1556 =cut
1557
1558 sub count_rs {
1559   my $self = shift;
1560   return $self->search(@_)->count_rs if @_;
1561
1562   # this may look like a lack of abstraction (count() does about the same)
1563   # but in fact an _rs *must* use a subquery for the limits, as the
1564   # software based limiting can not be ported if this $rs is to be used
1565   # in a subquery itself (i.e. ->as_query)
1566   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1567     return $self->_count_subq_rs;
1568   }
1569   else {
1570     return $self->_count_rs;
1571   }
1572 }
1573
1574 #
1575 # returns a ResultSetColumn object tied to the count query
1576 #
1577 sub _count_rs {
1578   my ($self, $attrs) = @_;
1579
1580   my $rsrc = $self->result_source;
1581   $attrs ||= $self->_resolved_attrs;
1582
1583   my $tmp_attrs = { %$attrs };
1584   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1585   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1586
1587   # overwrite the selector (supplied by the storage)
1588   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1589   $tmp_attrs->{as} = 'count';
1590
1591   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1592
1593   return $tmp_rs;
1594 }
1595
1596 #
1597 # same as above but uses a subquery
1598 #
1599 sub _count_subq_rs {
1600   my ($self, $attrs) = @_;
1601
1602   my $rsrc = $self->result_source;
1603   $attrs ||= $self->_resolved_attrs;
1604
1605   my $sub_attrs = { %$attrs };
1606   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1607   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1608
1609   # if we multi-prefetch we group_by something unique, as this is what we would
1610   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1611   if ( $attrs->{collapse}  ) {
1612     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1613       $rsrc->_identifying_column_set || $self->throw_exception(
1614         'Unable to construct a unique group_by criteria properly collapsing the '
1615       . 'has_many prefetch before count()'
1616       );
1617     } ]
1618   }
1619
1620   # Calculate subquery selector
1621   if (my $g = $sub_attrs->{group_by}) {
1622
1623     my $sql_maker = $rsrc->storage->sql_maker;
1624
1625     # necessary as the group_by may refer to aliased functions
1626     my $sel_index;
1627     for my $sel (@{$attrs->{select}}) {
1628       $sel_index->{$sel->{-as}} = $sel
1629         if (ref $sel eq 'HASH' and $sel->{-as});
1630     }
1631
1632     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1633     # also look for named aggregates referred in the having clause
1634     # having often contains scalarrefs - thus parse it out entirely
1635     my @parts = @$g;
1636     if ($attrs->{having}) {
1637       local $sql_maker->{having_bind};
1638       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1639       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1640       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1641         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1642         # if we don't unset it we screw up retarded but unfortunately working
1643         # 'MAX(foo.bar)' => { '>', 3 }
1644         $sql_maker->{name_sep} = '';
1645       }
1646
1647       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1648
1649       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1650       my %seen_having;
1651
1652       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1653       # and if all fails for an utterly naive quoted scalar-with-function
1654       while ($having_sql =~ /
1655         $rquote $sep $lquote (.+?) $rquote
1656           |
1657         [\s,] \w+ \. (\w+) [\s,]
1658           |
1659         [\s,] $lquote (.+?) $rquote [\s,]
1660       /gx) {
1661         my $part = $1 || $2 || $3;  # one of them matched if we got here
1662         unless ($seen_having{$part}++) {
1663           push @parts, $part;
1664         }
1665       }
1666     }
1667
1668     for (@parts) {
1669       my $colpiece = $sel_index->{$_} || $_;
1670
1671       # unqualify join-based group_by's. Arcane but possible query
1672       # also horrible horrible hack to alias a column (not a func.)
1673       # (probably need to introduce SQLA syntax)
1674       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1675         my $as = $colpiece;
1676         $as =~ s/\./__/;
1677         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1678       }
1679       push @{$sub_attrs->{select}}, $colpiece;
1680     }
1681   }
1682   else {
1683     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1684     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1685   }
1686
1687   return $rsrc->resultset_class
1688                ->new ($rsrc, $sub_attrs)
1689                 ->as_subselect_rs
1690                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1691                   ->get_column ('count');
1692 }
1693
1694
1695 =head2 count_literal
1696
1697 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1698 should only be used in that context. See L</search_literal> for further info.
1699
1700 =over 4
1701
1702 =item Arguments: $sql_fragment, @standalone_bind_values
1703
1704 =item Return Value: $count
1705
1706 =back
1707
1708 Counts the results in a literal query. Equivalent to calling L</search_literal>
1709 with the passed arguments, then L</count>.
1710
1711 =cut
1712
1713 sub count_literal { shift->search_literal(@_)->count; }
1714
1715 =head2 all
1716
1717 =over 4
1718
1719 =item Arguments: none
1720
1721 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1722
1723 =back
1724
1725 Returns all elements in the resultset.
1726
1727 =cut
1728
1729 sub all {
1730   my $self = shift;
1731   if(@_) {
1732     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1733   }
1734
1735   delete @{$self}{qw/stashed_rows stashed_objects/};
1736
1737   if (my $c = $self->get_cache) {
1738     return @$c;
1739   }
1740
1741   $self->cursor->reset;
1742
1743   my $objs = $self->_construct_objects('fetch_all') || [];
1744
1745   $self->set_cache($objs) if $self->{attrs}{cache};
1746
1747   return @$objs;
1748 }
1749
1750 =head2 reset
1751
1752 =over 4
1753
1754 =item Arguments: none
1755
1756 =item Return Value: $self
1757
1758 =back
1759
1760 Resets the resultset's cursor, so you can iterate through the elements again.
1761 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1762 another query.
1763
1764 =cut
1765
1766 sub reset {
1767   my ($self) = @_;
1768
1769   delete @{$self}{qw/stashed_rows stashed_objects/};
1770   $self->{all_cache_position} = 0;
1771   $self->cursor->reset;
1772   return $self;
1773 }
1774
1775 =head2 first
1776
1777 =over 4
1778
1779 =item Arguments: none
1780
1781 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1782
1783 =back
1784
1785 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1786 an object for the first result (or C<undef> if the resultset is empty).
1787
1788 =cut
1789
1790 sub first {
1791   return $_[0]->reset->next;
1792 }
1793
1794
1795 # _rs_update_delete
1796 #
1797 # Determines whether and what type of subquery is required for the $rs operation.
1798 # If grouping is necessary either supplies its own, or verifies the current one
1799 # After all is done delegates to the proper storage method.
1800
1801 sub _rs_update_delete {
1802   my ($self, $op, $values) = @_;
1803
1804   my $rsrc = $self->result_source;
1805   my $storage = $rsrc->schema->storage;
1806
1807   my $attrs = { %{$self->_resolved_attrs} };
1808
1809   my $join_classifications;
1810   my $existing_group_by = delete $attrs->{group_by};
1811
1812   # do we need a subquery for any reason?
1813   my $needs_subq = (
1814     defined $existing_group_by
1815       or
1816     # if {from} is unparseable wrap a subq
1817     ref($attrs->{from}) ne 'ARRAY'
1818       or
1819     # limits call for a subq
1820     $self->_has_resolved_attr(qw/rows offset/)
1821   );
1822
1823   # simplify the joinmap, so we can further decide if a subq is necessary
1824   if (!$needs_subq and @{$attrs->{from}} > 1) {
1825     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1826
1827     # check if there are any joins left after the prune
1828     if ( @{$attrs->{from}} > 1 ) {
1829       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1830         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1831         $attrs->{select},
1832         $self->{cond},
1833         $attrs
1834       );
1835
1836       # any non-pruneable joins imply subq
1837       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1838     }
1839   }
1840
1841   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1842   $needs_subq ||= (
1843     (ref $attrs->{from}[0]) ne 'HASH'
1844       or
1845     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1846   );
1847
1848   my ($cond, $guard);
1849   # do we need anything like a subquery?
1850   if (! $needs_subq) {
1851     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1852     # a condition containing 'me' or other table prefixes will not work
1853     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1854     $cond = do {
1855       my $sqla = $rsrc->storage->sql_maker;
1856       local $sqla->{_dequalify_idents} = 1;
1857       \[ $sqla->_recurse_where($self->{cond}) ];
1858     };
1859   }
1860   else {
1861     # we got this far - means it is time to wrap a subquery
1862     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1863       sprintf(
1864         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1865         $op,
1866         $rsrc->source_name,
1867       )
1868     );
1869
1870     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1871     delete $attrs->{$_} for qw/collapse select _prefetch_selector_range as/;
1872     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1873     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1874     my $subrs = (ref $self)->new($rsrc, $attrs);
1875
1876     if (@$idcols == 1) {
1877       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1878     }
1879     elsif ($storage->_use_multicolumn_in) {
1880       # no syntax for calling this properly yet
1881       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1882       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1883         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1884         $subrs->as_query
1885       ),
1886     }
1887     else {
1888       # if all else fails - get all primary keys and operate over a ORed set
1889       # wrap in a transaction for consistency
1890       # this is where the group_by/multiplication starts to matter
1891       if (
1892         $existing_group_by
1893           or
1894         keys %{ $join_classifications->{multiplying} || {} }
1895       ) {
1896         # make sure if there is a supplied group_by it matches the columns compiled above
1897         # perfectly. Anything else can not be sanely executed on most databases so croak
1898         # right then and there
1899         if ($existing_group_by) {
1900           my @current_group_by = map
1901             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1902             @$existing_group_by
1903           ;
1904
1905           if (
1906             join ("\x00", sort @current_group_by)
1907               ne
1908             join ("\x00", sort @{$attrs->{columns}} )
1909           ) {
1910             $self->throw_exception (
1911               "You have just attempted a $op operation on a resultset which does group_by"
1912               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1913               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1914               . ' kind of queries. Please retry the operation with a modified group_by or'
1915               . ' without using one at all.'
1916             );
1917           }
1918         }
1919
1920         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1921       }
1922
1923       $guard = $storage->txn_scope_guard;
1924
1925       $cond = [];
1926       for my $row ($subrs->cursor->all) {
1927         push @$cond, { map
1928           { $idcols->[$_] => $row->[$_] }
1929           (0 .. $#$idcols)
1930         };
1931       }
1932     }
1933   }
1934
1935   my $res = $storage->$op (
1936     $rsrc,
1937     $op eq 'update' ? $values : (),
1938     $cond,
1939   );
1940
1941   $guard->commit if $guard;
1942
1943   return $res;
1944 }
1945
1946 =head2 update
1947
1948 =over 4
1949
1950 =item Arguments: \%values
1951
1952 =item Return Value: $underlying_storage_rv
1953
1954 =back
1955
1956 Sets the specified columns in the resultset to the supplied values in a
1957 single query. Note that this will not run any accessor/set_column/update
1958 triggers, nor will it update any result object instances derived from this
1959 resultset (this includes the contents of the L<resultset cache|/set_cache>
1960 if any). See L</update_all> if you need to execute any on-update
1961 triggers or cascades defined either by you or a
1962 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1963
1964 The return value is a pass through of what the underlying
1965 storage backend returned, and may vary. See L<DBI/execute> for the most
1966 common case.
1967
1968 =head3 CAVEAT
1969
1970 Note that L</update> does not process/deflate any of the values passed in.
1971 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1972 ensure manually that any value passed to this method will stringify to
1973 something the RDBMS knows how to deal with. A notable example is the
1974 handling of L<DateTime> objects, for more info see:
1975 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1976
1977 =cut
1978
1979 sub update {
1980   my ($self, $values) = @_;
1981   $self->throw_exception('Values for update must be a hash')
1982     unless ref $values eq 'HASH';
1983
1984   return $self->_rs_update_delete ('update', $values);
1985 }
1986
1987 =head2 update_all
1988
1989 =over 4
1990
1991 =item Arguments: \%values
1992
1993 =item Return Value: 1
1994
1995 =back
1996
1997 Fetches all objects and updates them one at a time via
1998 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1999 triggers, while L</update> will not.
2000
2001 =cut
2002
2003 sub update_all {
2004   my ($self, $values) = @_;
2005   $self->throw_exception('Values for update_all must be a hash')
2006     unless ref $values eq 'HASH';
2007
2008   my $guard = $self->result_source->schema->txn_scope_guard;
2009   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2010   $guard->commit;
2011   return 1;
2012 }
2013
2014 =head2 delete
2015
2016 =over 4
2017
2018 =item Arguments: none
2019
2020 =item Return Value: $underlying_storage_rv
2021
2022 =back
2023
2024 Deletes the rows matching this resultset in a single query. Note that this
2025 will not run any delete triggers, nor will it alter the
2026 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2027 derived from this resultset (this includes the contents of the
2028 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2029 execute any on-delete triggers or cascades defined either by you or a
2030 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2031
2032 The return value is a pass through of what the underlying storage backend
2033 returned, and may vary. See L<DBI/execute> for the most common case.
2034
2035 =cut
2036
2037 sub delete {
2038   my $self = shift;
2039   $self->throw_exception('delete does not accept any arguments')
2040     if @_;
2041
2042   return $self->_rs_update_delete ('delete');
2043 }
2044
2045 =head2 delete_all
2046
2047 =over 4
2048
2049 =item Arguments: none
2050
2051 =item Return Value: 1
2052
2053 =back
2054
2055 Fetches all objects and deletes them one at a time via
2056 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2057 triggers, while L</delete> will not.
2058
2059 =cut
2060
2061 sub delete_all {
2062   my $self = shift;
2063   $self->throw_exception('delete_all does not accept any arguments')
2064     if @_;
2065
2066   my $guard = $self->result_source->schema->txn_scope_guard;
2067   $_->delete for $self->all;
2068   $guard->commit;
2069   return 1;
2070 }
2071
2072 =head2 populate
2073
2074 =over 4
2075
2076 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2077
2078 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2079
2080 =back
2081
2082 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2083 arrayrefs.
2084
2085 =over
2086
2087 =item NOTE
2088
2089 The context of this method call has an important effect on what is
2090 submitted to storage. In void context data is fed directly to fastpath
2091 insertion routines provided by the underlying storage (most often
2092 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2093 L<insert|DBIx::Class::Row/insert> calls on the
2094 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2095 augmentation of these methods provided by components. For example if you
2096 are using something like L<DBIx::Class::UUIDColumns> to create primary
2097 keys for you, you will find that your PKs are empty.  In this case you
2098 will have to explicitly force scalar or list context in order to create
2099 those values.
2100
2101 =back
2102
2103 In non-void (scalar or list) context, this method is simply a wrapper
2104 for L</create>. Depending on list or scalar context either a list of
2105 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2106 containing these objects is returned.
2107
2108 When supplying data in "arrayref of arrayrefs" invocation style, the
2109 first element should be a list of column names and each subsequent
2110 element should be a data value in the earlier specified column order.
2111 For example:
2112
2113   $Arstist_rs->populate([
2114     [ qw( artistid name ) ],
2115     [ 100, 'A Formally Unknown Singer' ],
2116     [ 101, 'A singer that jumped the shark two albums ago' ],
2117     [ 102, 'An actually cool singer' ],
2118   ]);
2119
2120 For the arrayref of hashrefs style each hashref should be a structure
2121 suitable for passing to L</create>. Multi-create is also permitted with
2122 this syntax.
2123
2124   $schema->resultset("Artist")->populate([
2125      { artistid => 4, name => 'Manufactured Crap', cds => [
2126         { title => 'My First CD', year => 2006 },
2127         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2128       ],
2129      },
2130      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2131         { title => 'My parents sold me to a record company', year => 2005 },
2132         { title => 'Why Am I So Ugly?', year => 2006 },
2133         { title => 'I Got Surgery and am now Popular', year => 2007 }
2134       ],
2135      },
2136   ]);
2137
2138 If you attempt a void-context multi-create as in the example above (each
2139 Artist also has the related list of CDs), and B<do not> supply the
2140 necessary autoinc foreign key information, this method will proxy to the
2141 less efficient L</create>, and then throw the Result objects away. In this
2142 case there are obviously no benefits to using this method over L</create>.
2143
2144 =cut
2145
2146 sub populate {
2147   my $self = shift;
2148
2149   # cruft placed in standalone method
2150   my $data = $self->_normalize_populate_args(@_);
2151
2152   return unless @$data;
2153
2154   if(defined wantarray) {
2155     my @created = map { $self->create($_) } @$data;
2156     return wantarray ? @created : \@created;
2157   }
2158   else {
2159     my $first = $data->[0];
2160
2161     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2162     # it relationship data
2163     my (@rels, @columns);
2164     my $rsrc = $self->result_source;
2165     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2166     for (keys %$first) {
2167       my $ref = ref $first->{$_};
2168       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2169         ? push @rels, $_
2170         : push @columns, $_
2171       ;
2172     }
2173
2174     my @pks = $rsrc->primary_columns;
2175
2176     ## do the belongs_to relationships
2177     foreach my $index (0..$#$data) {
2178
2179       # delegate to create() for any dataset without primary keys with specified relationships
2180       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2181         for my $r (@rels) {
2182           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2183             my @ret = $self->populate($data);
2184             return;
2185           }
2186         }
2187       }
2188
2189       foreach my $rel (@rels) {
2190         next unless ref $data->[$index]->{$rel} eq "HASH";
2191         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2192         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2193         my $related = $result->result_source->_resolve_condition(
2194           $reverse_relinfo->{cond},
2195           $self,
2196           $result,
2197           $rel,
2198         );
2199
2200         delete $data->[$index]->{$rel};
2201         $data->[$index] = {%{$data->[$index]}, %$related};
2202
2203         push @columns, keys %$related if $index == 0;
2204       }
2205     }
2206
2207     ## inherit the data locked in the conditions of the resultset
2208     my ($rs_data) = $self->_merge_with_rscond({});
2209     delete @{$rs_data}{@columns};
2210
2211     ## do bulk insert on current row
2212     $rsrc->storage->insert_bulk(
2213       $rsrc,
2214       [@columns, keys %$rs_data],
2215       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2216     );
2217
2218     ## do the has_many relationships
2219     foreach my $item (@$data) {
2220
2221       my $main_row;
2222
2223       foreach my $rel (@rels) {
2224         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2225
2226         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2227
2228         my $child = $main_row->$rel;
2229
2230         my $related = $child->result_source->_resolve_condition(
2231           $rels->{$rel}{cond},
2232           $child,
2233           $main_row,
2234           $rel,
2235         );
2236
2237         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2238         my @populate = map { {%$_, %$related} } @rows_to_add;
2239
2240         $child->populate( \@populate );
2241       }
2242     }
2243   }
2244 }
2245
2246
2247 # populate() argumnets went over several incarnations
2248 # What we ultimately support is AoH
2249 sub _normalize_populate_args {
2250   my ($self, $arg) = @_;
2251
2252   if (ref $arg eq 'ARRAY') {
2253     if (!@$arg) {
2254       return [];
2255     }
2256     elsif (ref $arg->[0] eq 'HASH') {
2257       return $arg;
2258     }
2259     elsif (ref $arg->[0] eq 'ARRAY') {
2260       my @ret;
2261       my @colnames = @{$arg->[0]};
2262       foreach my $values (@{$arg}[1 .. $#$arg]) {
2263         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2264       }
2265       return \@ret;
2266     }
2267   }
2268
2269   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2270 }
2271
2272 =head2 pager
2273
2274 =over 4
2275
2276 =item Arguments: none
2277
2278 =item Return Value: L<$pager|Data::Page>
2279
2280 =back
2281
2282 Returns a L<Data::Page> object for the current resultset. Only makes
2283 sense for queries with a C<page> attribute.
2284
2285 To get the full count of entries for a paged resultset, call
2286 C<total_entries> on the L<Data::Page> object.
2287
2288 =cut
2289
2290 sub pager {
2291   my ($self) = @_;
2292
2293   return $self->{pager} if $self->{pager};
2294
2295   my $attrs = $self->{attrs};
2296   if (!defined $attrs->{page}) {
2297     $self->throw_exception("Can't create pager for non-paged rs");
2298   }
2299   elsif ($attrs->{page} <= 0) {
2300     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2301   }
2302   $attrs->{rows} ||= 10;
2303
2304   # throw away the paging flags and re-run the count (possibly
2305   # with a subselect) to get the real total count
2306   my $count_attrs = { %$attrs };
2307   delete @{$count_attrs}{qw/rows offset page pager/};
2308
2309   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2310
2311   require DBIx::Class::ResultSet::Pager;
2312   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2313     sub { $total_rs->count },  #lazy-get the total
2314     $attrs->{rows},
2315     $self->{attrs}{page},
2316   );
2317 }
2318
2319 =head2 page
2320
2321 =over 4
2322
2323 =item Arguments: $page_number
2324
2325 =item Return Value: L<$resultset|/search>
2326
2327 =back
2328
2329 Returns a resultset for the $page_number page of the resultset on which page
2330 is called, where each page contains a number of rows equal to the 'rows'
2331 attribute set on the resultset (10 by default).
2332
2333 =cut
2334
2335 sub page {
2336   my ($self, $page) = @_;
2337   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2338 }
2339
2340 =head2 new_result
2341
2342 =over 4
2343
2344 =item Arguments: \%col_data
2345
2346 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2347
2348 =back
2349
2350 Creates a new result object in the resultset's result class and returns
2351 it. The row is not inserted into the database at this point, call
2352 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2353 will tell you whether the result object has been inserted or not.
2354
2355 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2356
2357 =cut
2358
2359 sub new_result {
2360   my ($self, $values) = @_;
2361
2362   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2363     if @_ > 2;
2364
2365   $self->throw_exception( "new_result expects a hashref" )
2366     unless (ref $values eq 'HASH');
2367
2368   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2369
2370   my $new = $self->result_class->new({
2371     %$merged_cond,
2372     ( @$cols_from_relations
2373       ? (-cols_from_relations => $cols_from_relations)
2374       : ()
2375     ),
2376     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2377   });
2378
2379   if (
2380     reftype($new) eq 'HASH'
2381       and
2382     ! keys %$new
2383       and
2384     blessed($new)
2385   ) {
2386     carp_unique (sprintf (
2387       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2388       $self->result_class,
2389     ));
2390   }
2391
2392   $new;
2393 }
2394
2395 # _merge_with_rscond
2396 #
2397 # Takes a simple hash of K/V data and returns its copy merged with the
2398 # condition already present on the resultset. Additionally returns an
2399 # arrayref of value/condition names, which were inferred from related
2400 # objects (this is needed for in-memory related objects)
2401 sub _merge_with_rscond {
2402   my ($self, $data) = @_;
2403
2404   my (%new_data, @cols_from_relations);
2405
2406   my $alias = $self->{attrs}{alias};
2407
2408   if (! defined $self->{cond}) {
2409     # just massage $data below
2410   }
2411   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2412     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2413     @cols_from_relations = keys %new_data;
2414   }
2415   elsif (ref $self->{cond} ne 'HASH') {
2416     $self->throw_exception(
2417       "Can't abstract implicit construct, resultset condition not a hash"
2418     );
2419   }
2420   else {
2421     # precendence must be given to passed values over values inherited from
2422     # the cond, so the order here is important.
2423     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2424     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2425
2426     while ( my($col, $value) = each %implied ) {
2427       my $vref = ref $value;
2428       if (
2429         $vref eq 'HASH'
2430           and
2431         keys(%$value) == 1
2432           and
2433         (keys %$value)[0] eq '='
2434       ) {
2435         $new_data{$col} = $value->{'='};
2436       }
2437       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2438         $new_data{$col} = $value;
2439       }
2440     }
2441   }
2442
2443   %new_data = (
2444     %new_data,
2445     %{ $self->_remove_alias($data, $alias) },
2446   );
2447
2448   return (\%new_data, \@cols_from_relations);
2449 }
2450
2451 # _has_resolved_attr
2452 #
2453 # determines if the resultset defines at least one
2454 # of the attributes supplied
2455 #
2456 # used to determine if a subquery is neccessary
2457 #
2458 # supports some virtual attributes:
2459 #   -join
2460 #     This will scan for any joins being present on the resultset.
2461 #     It is not a mere key-search but a deep inspection of {from}
2462 #
2463
2464 sub _has_resolved_attr {
2465   my ($self, @attr_names) = @_;
2466
2467   my $attrs = $self->_resolved_attrs;
2468
2469   my %extra_checks;
2470
2471   for my $n (@attr_names) {
2472     if (grep { $n eq $_ } (qw/-join/) ) {
2473       $extra_checks{$n}++;
2474       next;
2475     }
2476
2477     my $attr =  $attrs->{$n};
2478
2479     next if not defined $attr;
2480
2481     if (ref $attr eq 'HASH') {
2482       return 1 if keys %$attr;
2483     }
2484     elsif (ref $attr eq 'ARRAY') {
2485       return 1 if @$attr;
2486     }
2487     else {
2488       return 1 if $attr;
2489     }
2490   }
2491
2492   # a resolved join is expressed as a multi-level from
2493   return 1 if (
2494     $extra_checks{-join}
2495       and
2496     ref $attrs->{from} eq 'ARRAY'
2497       and
2498     @{$attrs->{from}} > 1
2499   );
2500
2501   return 0;
2502 }
2503
2504 # _collapse_cond
2505 #
2506 # Recursively collapse the condition.
2507
2508 sub _collapse_cond {
2509   my ($self, $cond, $collapsed) = @_;
2510
2511   $collapsed ||= {};
2512
2513   if (ref $cond eq 'ARRAY') {
2514     foreach my $subcond (@$cond) {
2515       next unless ref $subcond;  # -or
2516       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2517     }
2518   }
2519   elsif (ref $cond eq 'HASH') {
2520     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2521       foreach my $subcond (@{$cond->{-and}}) {
2522         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2523       }
2524     }
2525     else {
2526       foreach my $col (keys %$cond) {
2527         my $value = $cond->{$col};
2528         $collapsed->{$col} = $value;
2529       }
2530     }
2531   }
2532
2533   return $collapsed;
2534 }
2535
2536 # _remove_alias
2537 #
2538 # Remove the specified alias from the specified query hash. A copy is made so
2539 # the original query is not modified.
2540
2541 sub _remove_alias {
2542   my ($self, $query, $alias) = @_;
2543
2544   my %orig = %{ $query || {} };
2545   my %unaliased;
2546
2547   foreach my $key (keys %orig) {
2548     if ($key !~ /\./) {
2549       $unaliased{$key} = $orig{$key};
2550       next;
2551     }
2552     $unaliased{$1} = $orig{$key}
2553       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2554   }
2555
2556   return \%unaliased;
2557 }
2558
2559 =head2 as_query
2560
2561 =over 4
2562
2563 =item Arguments: none
2564
2565 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2566
2567 =back
2568
2569 Returns the SQL query and bind vars associated with the invocant.
2570
2571 This is generally used as the RHS for a subquery.
2572
2573 =cut
2574
2575 sub as_query {
2576   my $self = shift;
2577
2578   my $attrs = { %{ $self->_resolved_attrs } };
2579
2580   # For future use:
2581   #
2582   # in list ctx:
2583   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2584   # $sql also has no wrapping parenthesis in list ctx
2585   #
2586   my $sqlbind = $self->result_source->storage
2587     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2588
2589   return $sqlbind;
2590 }
2591
2592 =head2 find_or_new
2593
2594 =over 4
2595
2596 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2597
2598 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2599
2600 =back
2601
2602   my $artist = $schema->resultset('Artist')->find_or_new(
2603     { artist => 'fred' }, { key => 'artists' });
2604
2605   $cd->cd_to_producer->find_or_new({ producer => $producer },
2606                                    { key => 'primary });
2607
2608 Find an existing record from this resultset using L</find>. if none exists,
2609 instantiate a new result object and return it. The object will not be saved
2610 into your storage until you call L<DBIx::Class::Row/insert> on it.
2611
2612 You most likely want this method when looking for existing rows using a unique
2613 constraint that is not the primary key, or looking for related rows.
2614
2615 If you want objects to be saved immediately, use L</find_or_create> instead.
2616
2617 B<Note>: Make sure to read the documentation of L</find> and understand the
2618 significance of the C<key> attribute, as its lack may skew your search, and
2619 subsequently result in spurious new objects.
2620
2621 B<Note>: Take care when using C<find_or_new> with a table having
2622 columns with default values that you intend to be automatically
2623 supplied by the database (e.g. an auto_increment primary key column).
2624 In normal usage, the value of such columns should NOT be included at
2625 all in the call to C<find_or_new>, even when set to C<undef>.
2626
2627 =cut
2628
2629 sub find_or_new {
2630   my $self     = shift;
2631   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2632   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2633   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2634     return $row;
2635   }
2636   return $self->new_result($hash);
2637 }
2638
2639 =head2 create
2640
2641 =over 4
2642
2643 =item Arguments: \%col_data
2644
2645 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2646
2647 =back
2648
2649 Attempt to create a single new row or a row with multiple related rows
2650 in the table represented by the resultset (and related tables). This
2651 will not check for duplicate rows before inserting, use
2652 L</find_or_create> to do that.
2653
2654 To create one row for this resultset, pass a hashref of key/value
2655 pairs representing the columns of the table and the values you wish to
2656 store. If the appropriate relationships are set up, foreign key fields
2657 can also be passed an object representing the foreign row, and the
2658 value will be set to its primary key.
2659
2660 To create related objects, pass a hashref of related-object column values
2661 B<keyed on the relationship name>. If the relationship is of type C<multi>
2662 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2663 The process will correctly identify columns holding foreign keys, and will
2664 transparently populate them from the keys of the corresponding relation.
2665 This can be applied recursively, and will work correctly for a structure
2666 with an arbitrary depth and width, as long as the relationships actually
2667 exists and the correct column data has been supplied.
2668
2669 Instead of hashrefs of plain related data (key/value pairs), you may
2670 also pass new or inserted objects. New objects (not inserted yet, see
2671 L</new_result>), will be inserted into their appropriate tables.
2672
2673 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2674
2675 Example of creating a new row.
2676
2677   $person_rs->create({
2678     name=>"Some Person",
2679     email=>"somebody@someplace.com"
2680   });
2681
2682 Example of creating a new row and also creating rows in a related C<has_many>
2683 or C<has_one> resultset.  Note Arrayref.
2684
2685   $artist_rs->create(
2686      { artistid => 4, name => 'Manufactured Crap', cds => [
2687         { title => 'My First CD', year => 2006 },
2688         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2689       ],
2690      },
2691   );
2692
2693 Example of creating a new row and also creating a row in a related
2694 C<belongs_to> resultset. Note Hashref.
2695
2696   $cd_rs->create({
2697     title=>"Music for Silly Walks",
2698     year=>2000,
2699     artist => {
2700       name=>"Silly Musician",
2701     }
2702   });
2703
2704 =over
2705
2706 =item WARNING
2707
2708 When subclassing ResultSet never attempt to override this method. Since
2709 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2710 lot of the internals simply never call it, so your override will be
2711 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2712 or L<DBIx::Class::Row/insert> depending on how early in the
2713 L</create> process you need to intervene. See also warning pertaining to
2714 L</new>.
2715
2716 =back
2717
2718 =cut
2719
2720 sub create {
2721   my ($self, $attrs) = @_;
2722   $self->throw_exception( "create needs a hashref" )
2723     unless ref $attrs eq 'HASH';
2724   return $self->new_result($attrs)->insert;
2725 }
2726
2727 =head2 find_or_create
2728
2729 =over 4
2730
2731 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2732
2733 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2734
2735 =back
2736
2737   $cd->cd_to_producer->find_or_create({ producer => $producer },
2738                                       { key => 'primary' });
2739
2740 Tries to find a record based on its primary key or unique constraints; if none
2741 is found, creates one and returns that instead.
2742
2743   my $cd = $schema->resultset('CD')->find_or_create({
2744     cdid   => 5,
2745     artist => 'Massive Attack',
2746     title  => 'Mezzanine',
2747     year   => 2005,
2748   });
2749
2750 Also takes an optional C<key> attribute, to search by a specific key or unique
2751 constraint. For example:
2752
2753   my $cd = $schema->resultset('CD')->find_or_create(
2754     {
2755       artist => 'Massive Attack',
2756       title  => 'Mezzanine',
2757     },
2758     { key => 'cd_artist_title' }
2759   );
2760
2761 B<Note>: Make sure to read the documentation of L</find> and understand the
2762 significance of the C<key> attribute, as its lack may skew your search, and
2763 subsequently result in spurious row creation.
2764
2765 B<Note>: Because find_or_create() reads from the database and then
2766 possibly inserts based on the result, this method is subject to a race
2767 condition. Another process could create a record in the table after
2768 the find has completed and before the create has started. To avoid
2769 this problem, use find_or_create() inside a transaction.
2770
2771 B<Note>: Take care when using C<find_or_create> with a table having
2772 columns with default values that you intend to be automatically
2773 supplied by the database (e.g. an auto_increment primary key column).
2774 In normal usage, the value of such columns should NOT be included at
2775 all in the call to C<find_or_create>, even when set to C<undef>.
2776
2777 See also L</find> and L</update_or_create>. For information on how to declare
2778 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2779
2780 If you need to know if an existing row was found or a new one created use
2781 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2782 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2783 database!
2784
2785   my $cd = $schema->resultset('CD')->find_or_new({
2786     cdid   => 5,
2787     artist => 'Massive Attack',
2788     title  => 'Mezzanine',
2789     year   => 2005,
2790   });
2791
2792   if( !$cd->in_storage ) {
2793       # do some stuff
2794       $cd->insert;
2795   }
2796
2797 =cut
2798
2799 sub find_or_create {
2800   my $self     = shift;
2801   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2802   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2803   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2804     return $row;
2805   }
2806   return $self->create($hash);
2807 }
2808
2809 =head2 update_or_create
2810
2811 =over 4
2812
2813 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2814
2815 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2816
2817 =back
2818
2819   $resultset->update_or_create({ col => $val, ... });
2820
2821 Like L</find_or_create>, but if a row is found it is immediately updated via
2822 C<< $found_row->update (\%col_data) >>.
2823
2824
2825 Takes an optional C<key> attribute to search on a specific unique constraint.
2826 For example:
2827
2828   # In your application
2829   my $cd = $schema->resultset('CD')->update_or_create(
2830     {
2831       artist => 'Massive Attack',
2832       title  => 'Mezzanine',
2833       year   => 1998,
2834     },
2835     { key => 'cd_artist_title' }
2836   );
2837
2838   $cd->cd_to_producer->update_or_create({
2839     producer => $producer,
2840     name => 'harry',
2841   }, {
2842     key => 'primary',
2843   });
2844
2845 B<Note>: Make sure to read the documentation of L</find> and understand the
2846 significance of the C<key> attribute, as its lack may skew your search, and
2847 subsequently result in spurious row creation.
2848
2849 B<Note>: Take care when using C<update_or_create> with a table having
2850 columns with default values that you intend to be automatically
2851 supplied by the database (e.g. an auto_increment primary key column).
2852 In normal usage, the value of such columns should NOT be included at
2853 all in the call to C<update_or_create>, even when set to C<undef>.
2854
2855 See also L</find> and L</find_or_create>. For information on how to declare
2856 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2857
2858 If you need to know if an existing row was updated or a new one created use
2859 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2860 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2861 database!
2862
2863 =cut
2864
2865 sub update_or_create {
2866   my $self = shift;
2867   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2868   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2869
2870   my $row = $self->find($cond, $attrs);
2871   if (defined $row) {
2872     $row->update($cond);
2873     return $row;
2874   }
2875
2876   return $self->create($cond);
2877 }
2878
2879 =head2 update_or_new
2880
2881 =over 4
2882
2883 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2884
2885 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2886
2887 =back
2888
2889   $resultset->update_or_new({ col => $val, ... });
2890
2891 Like L</find_or_new> but if a row is found it is immediately updated via
2892 C<< $found_row->update (\%col_data) >>.
2893
2894 For example:
2895
2896   # In your application
2897   my $cd = $schema->resultset('CD')->update_or_new(
2898     {
2899       artist => 'Massive Attack',
2900       title  => 'Mezzanine',
2901       year   => 1998,
2902     },
2903     { key => 'cd_artist_title' }
2904   );
2905
2906   if ($cd->in_storage) {
2907       # the cd was updated
2908   }
2909   else {
2910       # the cd is not yet in the database, let's insert it
2911       $cd->insert;
2912   }
2913
2914 B<Note>: Make sure to read the documentation of L</find> and understand the
2915 significance of the C<key> attribute, as its lack may skew your search, and
2916 subsequently result in spurious new objects.
2917
2918 B<Note>: Take care when using C<update_or_new> with a table having
2919 columns with default values that you intend to be automatically
2920 supplied by the database (e.g. an auto_increment primary key column).
2921 In normal usage, the value of such columns should NOT be included at
2922 all in the call to C<update_or_new>, even when set to C<undef>.
2923
2924 See also L</find>, L</find_or_create> and L</find_or_new>.
2925
2926 =cut
2927
2928 sub update_or_new {
2929     my $self  = shift;
2930     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2931     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2932
2933     my $row = $self->find( $cond, $attrs );
2934     if ( defined $row ) {
2935         $row->update($cond);
2936         return $row;
2937     }
2938
2939     return $self->new_result($cond);
2940 }
2941
2942 =head2 get_cache
2943
2944 =over 4
2945
2946 =item Arguments: none
2947
2948 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2949
2950 =back
2951
2952 Gets the contents of the cache for the resultset, if the cache is set.
2953
2954 The cache is populated either by using the L</prefetch> attribute to
2955 L</search> or by calling L</set_cache>.
2956
2957 =cut
2958
2959 sub get_cache {
2960   shift->{all_cache};
2961 }
2962
2963 =head2 set_cache
2964
2965 =over 4
2966
2967 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2968
2969 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2970
2971 =back
2972
2973 Sets the contents of the cache for the resultset. Expects an arrayref
2974 of objects of the same class as those produced by the resultset. Note that
2975 if the cache is set, the resultset will return the cached objects rather
2976 than re-querying the database even if the cache attr is not set.
2977
2978 The contents of the cache can also be populated by using the
2979 L</prefetch> attribute to L</search>.
2980
2981 =cut
2982
2983 sub set_cache {
2984   my ( $self, $data ) = @_;
2985   $self->throw_exception("set_cache requires an arrayref")
2986       if defined($data) && (ref $data ne 'ARRAY');
2987   $self->{all_cache} = $data;
2988 }
2989
2990 =head2 clear_cache
2991
2992 =over 4
2993
2994 =item Arguments: none
2995
2996 =item Return Value: undef
2997
2998 =back
2999
3000 Clears the cache for the resultset.
3001
3002 =cut
3003
3004 sub clear_cache {
3005   shift->set_cache(undef);
3006 }
3007
3008 =head2 is_paged
3009
3010 =over 4
3011
3012 =item Arguments: none
3013
3014 =item Return Value: true, if the resultset has been paginated
3015
3016 =back
3017
3018 =cut
3019
3020 sub is_paged {
3021   my ($self) = @_;
3022   return !!$self->{attrs}{page};
3023 }
3024
3025 =head2 is_ordered
3026
3027 =over 4
3028
3029 =item Arguments: none
3030
3031 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3032
3033 =back
3034
3035 =cut
3036
3037 sub is_ordered {
3038   my ($self) = @_;
3039   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3040 }
3041
3042 =head2 related_resultset
3043
3044 =over 4
3045
3046 =item Arguments: $rel_name
3047
3048 =item Return Value: L<$resultset|/search>
3049
3050 =back
3051
3052 Returns a related resultset for the supplied relationship name.
3053
3054   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3055
3056 =cut
3057
3058 sub related_resultset {
3059   my ($self, $rel) = @_;
3060
3061   return $self->{related_resultsets}{$rel} ||= do {
3062     my $rsrc = $self->result_source;
3063     my $rel_info = $rsrc->relationship_info($rel);
3064
3065     $self->throw_exception(
3066       "search_related: result source '" . $rsrc->source_name .
3067         "' has no such relationship $rel")
3068       unless $rel_info;
3069
3070     my $attrs = $self->_chain_relationship($rel);
3071
3072     my $join_count = $attrs->{seen_join}{$rel};
3073
3074     my $alias = $self->result_source->storage
3075         ->relname_to_table_alias($rel, $join_count);
3076
3077     # since this is search_related, and we already slid the select window inwards
3078     # (the select/as attrs were deleted in the beginning), we need to flip all
3079     # left joins to inner, so we get the expected results
3080     # read the comment on top of the actual function to see what this does
3081     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3082
3083
3084     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3085     delete @{$attrs}{qw(result_class alias)};
3086
3087     my $related_cache;
3088
3089     if (my $cache = $self->get_cache) {
3090       $related_cache = [ map
3091         { @{$_->related_resultset($rel)->get_cache||[]} }
3092         @$cache
3093       ];
3094     }
3095
3096     my $rel_source = $rsrc->related_source($rel);
3097
3098     my $new = do {
3099
3100       # The reason we do this now instead of passing the alias to the
3101       # search_rs below is that if you wrap/overload resultset on the
3102       # source you need to know what alias it's -going- to have for things
3103       # to work sanely (e.g. RestrictWithObject wants to be able to add
3104       # extra query restrictions, and these may need to be $alias.)
3105
3106       my $rel_attrs = $rel_source->resultset_attributes;
3107       local $rel_attrs->{alias} = $alias;
3108
3109       $rel_source->resultset
3110                  ->search_rs(
3111                      undef, {
3112                        %$attrs,
3113                        where => $attrs->{where},
3114                    });
3115     };
3116     $new->set_cache($related_cache) if $related_cache;
3117     $new;
3118   };
3119 }
3120
3121 =head2 current_source_alias
3122
3123 =over 4
3124
3125 =item Arguments: none
3126
3127 =item Return Value: $source_alias
3128
3129 =back
3130
3131 Returns the current table alias for the result source this resultset is built
3132 on, that will be used in the SQL query. Usually it is C<me>.
3133
3134 Currently the source alias that refers to the result set returned by a
3135 L</search>/L</find> family method depends on how you got to the resultset: it's
3136 C<me> by default, but eg. L</search_related> aliases it to the related result
3137 source name (and keeps C<me> referring to the original result set). The long
3138 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3139 (and make this method unnecessary).
3140
3141 Thus it's currently necessary to use this method in predefined queries (see
3142 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3143 source alias of the current result set:
3144
3145   # in a result set class
3146   sub modified_by {
3147     my ($self, $user) = @_;
3148
3149     my $me = $self->current_source_alias;
3150
3151     return $self->search({
3152       "$me.modified" => $user->id,
3153     });
3154   }
3155
3156 =cut
3157
3158 sub current_source_alias {
3159   return (shift->{attrs} || {})->{alias} || 'me';
3160 }
3161
3162 =head2 as_subselect_rs
3163
3164 =over 4
3165
3166 =item Arguments: none
3167
3168 =item Return Value: L<$resultset|/search>
3169
3170 =back
3171
3172 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3173 "virtual view" by including it as a subquery within the from clause.  From this
3174 point on, any joined tables are inaccessible to ->search on the resultset (as if
3175 it were simply where-filtered without joins).  For example:
3176
3177  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3178
3179  # 'x' now pollutes the query namespace
3180
3181  # So the following works as expected
3182  my $ok_rs = $rs->search({'x.other' => 1});
3183
3184  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3185  # def) we look for one row with contradictory terms and join in another table
3186  # (aliased 'x_2') which we never use
3187  my $broken_rs = $rs->search({'x.name' => 'def'});
3188
3189  my $rs2 = $rs->as_subselect_rs;
3190
3191  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3192  my $not_joined_rs = $rs2->search({'x.other' => 1});
3193
3194  # works as expected: finds a 'table' row related to two x rows (abc and def)
3195  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3196
3197 Another example of when one might use this would be to select a subset of
3198 columns in a group by clause:
3199
3200  my $rs = $schema->resultset('Bar')->search(undef, {
3201    group_by => [qw{ id foo_id baz_id }],
3202  })->as_subselect_rs->search(undef, {
3203    columns => [qw{ id foo_id }]
3204  });
3205
3206 In the above example normally columns would have to be equal to the group by,
3207 but because we isolated the group by into a subselect the above works.
3208
3209 =cut
3210
3211 sub as_subselect_rs {
3212   my $self = shift;
3213
3214   my $attrs = $self->_resolved_attrs;
3215
3216   my $fresh_rs = (ref $self)->new (
3217     $self->result_source
3218   );
3219
3220   # these pieces will be locked in the subquery
3221   delete $fresh_rs->{cond};
3222   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3223
3224   return $fresh_rs->search( {}, {
3225     from => [{
3226       $attrs->{alias} => $self->as_query,
3227       -alias  => $attrs->{alias},
3228       -rsrc   => $self->result_source,
3229     }],
3230     alias => $attrs->{alias},
3231   });
3232 }
3233
3234 # This code is called by search_related, and makes sure there
3235 # is clear separation between the joins before, during, and
3236 # after the relationship. This information is needed later
3237 # in order to properly resolve prefetch aliases (any alias
3238 # with a relation_chain_depth less than the depth of the
3239 # current prefetch is not considered)
3240 #
3241 # The increments happen twice per join. An even number means a
3242 # relationship specified via a search_related, whereas an odd
3243 # number indicates a join/prefetch added via attributes
3244 #
3245 # Also this code will wrap the current resultset (the one we
3246 # chain to) in a subselect IFF it contains limiting attributes
3247 sub _chain_relationship {
3248   my ($self, $rel) = @_;
3249   my $source = $self->result_source;
3250   my $attrs = { %{$self->{attrs}||{}} };
3251
3252   # we need to take the prefetch the attrs into account before we
3253   # ->_resolve_join as otherwise they get lost - captainL
3254   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3255
3256   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3257
3258   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3259
3260   my $from;
3261   my @force_subq_attrs = qw/offset rows group_by having/;
3262
3263   if (
3264     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3265       ||
3266     $self->_has_resolved_attr (@force_subq_attrs)
3267   ) {
3268     # Nuke the prefetch (if any) before the new $rs attrs
3269     # are resolved (prefetch is useless - we are wrapping
3270     # a subquery anyway).
3271     my $rs_copy = $self->search;
3272     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3273       $rs_copy->{attrs}{join},
3274       delete $rs_copy->{attrs}{prefetch},
3275     );
3276
3277     $from = [{
3278       -rsrc   => $source,
3279       -alias  => $attrs->{alias},
3280       $attrs->{alias} => $rs_copy->as_query,
3281     }];
3282     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3283     $seen->{-relation_chain_depth} = 0;
3284   }
3285   elsif ($attrs->{from}) {  #shallow copy suffices
3286     $from = [ @{$attrs->{from}} ];
3287   }
3288   else {
3289     $from = [{
3290       -rsrc  => $source,
3291       -alias => $attrs->{alias},
3292       $attrs->{alias} => $source->from,
3293     }];
3294   }
3295
3296   my $jpath = ($seen->{-relation_chain_depth})
3297     ? $from->[-1][0]{-join_path}
3298     : [];
3299
3300   my @requested_joins = $source->_resolve_join(
3301     $join,
3302     $attrs->{alias},
3303     $seen,
3304     $jpath,
3305   );
3306
3307   push @$from, @requested_joins;
3308
3309   $seen->{-relation_chain_depth}++;
3310
3311   # if $self already had a join/prefetch specified on it, the requested
3312   # $rel might very well be already included. What we do in this case
3313   # is effectively a no-op (except that we bump up the chain_depth on
3314   # the join in question so we could tell it *is* the search_related)
3315   my $already_joined;
3316
3317   # we consider the last one thus reverse
3318   for my $j (reverse @requested_joins) {
3319     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3320     if ($rel eq $last_j) {
3321       $j->[0]{-relation_chain_depth}++;
3322       $already_joined++;
3323       last;
3324     }
3325   }
3326
3327   unless ($already_joined) {
3328     push @$from, $source->_resolve_join(
3329       $rel,
3330       $attrs->{alias},
3331       $seen,
3332       $jpath,
3333     );
3334   }
3335
3336   $seen->{-relation_chain_depth}++;
3337
3338   return {%$attrs, from => $from, seen_join => $seen};
3339 }
3340
3341 sub _resolved_attrs {
3342   my $self = shift;
3343   return $self->{_attrs} if $self->{_attrs};
3344
3345   my $attrs  = { %{ $self->{attrs} || {} } };
3346   my $source = $self->result_source;
3347   my $alias  = $attrs->{alias};
3348
3349   # default selection list
3350   $attrs->{columns} = [ $source->columns ]
3351     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3352
3353   # merge selectors together
3354   for (qw/columns select as/) {
3355     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3356       if $attrs->{$_} or $attrs->{"+$_"};
3357   }
3358
3359   # disassemble columns
3360   my (@sel, @as);
3361   if (my $cols = delete $attrs->{columns}) {
3362     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3363       if (ref $c eq 'HASH') {
3364         for my $as (sort keys %$c) {
3365           push @sel, $c->{$as};
3366           push @as, $as;
3367         }
3368       }
3369       else {
3370         push @sel, $c;
3371         push @as, $c;
3372       }
3373     }
3374   }
3375
3376   # when trying to weed off duplicates later do not go past this point -
3377   # everything added from here on is unbalanced "anyone's guess" stuff
3378   my $dedup_stop_idx = $#as;
3379
3380   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3381     if $attrs->{as};
3382   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3383     if $attrs->{select};
3384
3385   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3386   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3387
3388   # disqualify all $alias.col as-bits (inflate-map mandated)
3389   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3390
3391   # de-duplicate the result (remove *identical* select/as pairs)
3392   # and also die on duplicate {as} pointing to different {select}s
3393   # not using a c-style for as the condition is prone to shrinkage
3394   my $seen;
3395   my $i = 0;
3396   while ($i <= $dedup_stop_idx) {
3397     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3398       splice @sel, $i, 1;
3399       splice @as, $i, 1;
3400       $dedup_stop_idx--;
3401     }
3402     elsif ($seen->{$as[$i]}++) {
3403       $self->throw_exception(
3404         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3405       );
3406     }
3407     else {
3408       $i++;
3409     }
3410   }
3411
3412   $attrs->{select} = \@sel;
3413   $attrs->{as} = \@as;
3414
3415   $attrs->{from} ||= [{
3416     -rsrc   => $source,
3417     -alias  => $self->{attrs}{alias},
3418     $self->{attrs}{alias} => $source->from,
3419   }];
3420
3421   if ( $attrs->{join} || $attrs->{prefetch} ) {
3422
3423     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3424       if ref $attrs->{from} ne 'ARRAY';
3425
3426     my $join = (delete $attrs->{join}) || {};
3427
3428     if ( defined $attrs->{prefetch} ) {
3429       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3430     }
3431
3432     $attrs->{from} =    # have to copy here to avoid corrupting the original
3433       [
3434         @{ $attrs->{from} },
3435         $source->_resolve_join(
3436           $join,
3437           $alias,
3438           { %{ $attrs->{seen_join} || {} } },
3439           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3440             ? $attrs->{from}[-1][0]{-join_path}
3441             : []
3442           ,
3443         )
3444       ];
3445   }
3446
3447   if ( defined $attrs->{order_by} ) {
3448     $attrs->{order_by} = (
3449       ref( $attrs->{order_by} ) eq 'ARRAY'
3450       ? [ @{ $attrs->{order_by} } ]
3451       : [ $attrs->{order_by} || () ]
3452     );
3453   }
3454
3455   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3456     $attrs->{group_by} = [ $attrs->{group_by} ];
3457   }
3458
3459   # generate the distinct induced group_by early, as prefetch will be carried via a
3460   # subquery (since a group_by is present)
3461   if (delete $attrs->{distinct}) {
3462     if ($attrs->{group_by}) {
3463       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3464     }
3465     else {
3466       # distinct affects only the main selection part, not what prefetch may
3467       # add below.
3468       $attrs->{group_by} = $source->storage->_group_over_selection (
3469         $attrs->{from},
3470         $attrs->{select},
3471         $attrs->{order_by},
3472       );
3473     }
3474   }
3475
3476   # generate selections based on the prefetch helper
3477   my $prefetch;
3478   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3479     if defined $attrs->{prefetch};
3480
3481   if ($prefetch) {
3482
3483     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3484       if $attrs->{_dark_selector};
3485
3486     $attrs->{collapse} = 1;
3487
3488     # this is a separate structure (we don't look in {from} directly)
3489     # as the resolver needs to shift things off the lists to work
3490     # properly (identical-prefetches on different branches)
3491     my $join_map = {};
3492     if (ref $attrs->{from} eq 'ARRAY') {
3493
3494       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3495
3496       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3497         next unless $j->[0]{-alias};
3498         next unless $j->[0]{-join_path};
3499         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3500
3501         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3502
3503         my $p = $join_map;
3504         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3505         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3506       }
3507     }
3508
3509     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3510
3511     # we need to somehow mark which columns came from prefetch
3512     if (@prefetch) {
3513       my $sel_end = $#{$attrs->{select}};
3514       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3515     }
3516
3517     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3518     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3519   }
3520
3521   if ( ! List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3522     $attrs->{_single_resultclass_inflation} = 1;
3523     $attrs->{collapse} = 0;
3524   }
3525
3526   # run through the resulting joinstructure (starting from our current slot)
3527   # and unset collapse if proven unnesessary
3528   #
3529   # also while we are at it find out if the current root source has
3530   # been premultiplied by previous related_source chaining
3531   #
3532   # this allows to predict whether a root object with all other relation
3533   # data set to NULL is in fact unique
3534   if ($attrs->{collapse}) {
3535
3536     if (ref $attrs->{from} eq 'ARRAY') {
3537
3538       if (@{$attrs->{from}} <= 1) {
3539         # no joins - no collapse
3540         $attrs->{collapse} = 0;
3541       }
3542       else {
3543         # find where our table-spec starts
3544         my @fromlist = @{$attrs->{from}};
3545         while (@fromlist) {
3546           my $t = shift @fromlist;
3547
3548           my $is_multi;
3549           # me vs join from-spec distinction - a ref means non-root
3550           if (ref $t eq 'ARRAY') {
3551             $t = $t->[0];
3552             $is_multi ||= ! $t->{-is_single};
3553           }
3554           last if ($t->{-alias} && $t->{-alias} eq $alias);
3555           $attrs->{_main_source_premultiplied} ||= $is_multi;
3556         }
3557
3558         # no non-singles remaining, nor any premultiplication - nothing to collapse
3559         if (
3560           ! $attrs->{_main_source_premultiplied}
3561             and
3562           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3563         ) {
3564           $attrs->{collapse} = 0;
3565         }
3566       }
3567     }
3568
3569     else {
3570       # if we can not analyze the from - err on the side of safety
3571       $attrs->{_main_source_premultiplied} = 1;
3572     }
3573   }
3574
3575   # if both page and offset are specified, produce a combined offset
3576   # even though it doesn't make much sense, this is what pre 081xx has
3577   # been doing
3578   if (my $page = delete $attrs->{page}) {
3579     $attrs->{offset} =
3580       ($attrs->{rows} * ($page - 1))
3581             +
3582       ($attrs->{offset} || 0)
3583     ;
3584   }
3585
3586   return $self->{_attrs} = $attrs;
3587 }
3588
3589 sub _rollout_attr {
3590   my ($self, $attr) = @_;
3591
3592   if (ref $attr eq 'HASH') {
3593     return $self->_rollout_hash($attr);
3594   } elsif (ref $attr eq 'ARRAY') {
3595     return $self->_rollout_array($attr);
3596   } else {
3597     return [$attr];
3598   }
3599 }
3600
3601 sub _rollout_array {
3602   my ($self, $attr) = @_;
3603
3604   my @rolled_array;
3605   foreach my $element (@{$attr}) {
3606     if (ref $element eq 'HASH') {
3607       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3608     } elsif (ref $element eq 'ARRAY') {
3609       #  XXX - should probably recurse here
3610       push( @rolled_array, @{$self->_rollout_array($element)} );
3611     } else {
3612       push( @rolled_array, $element );
3613     }
3614   }
3615   return \@rolled_array;
3616 }
3617
3618 sub _rollout_hash {
3619   my ($self, $attr) = @_;
3620
3621   my @rolled_array;
3622   foreach my $key (keys %{$attr}) {
3623     push( @rolled_array, { $key => $attr->{$key} } );
3624   }
3625   return \@rolled_array;
3626 }
3627
3628 sub _calculate_score {
3629   my ($self, $a, $b) = @_;
3630
3631   if (defined $a xor defined $b) {
3632     return 0;
3633   }
3634   elsif (not defined $a) {
3635     return 1;
3636   }
3637
3638   if (ref $b eq 'HASH') {
3639     my ($b_key) = keys %{$b};
3640     if (ref $a eq 'HASH') {
3641       my ($a_key) = keys %{$a};
3642       if ($a_key eq $b_key) {
3643         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3644       } else {
3645         return 0;
3646       }
3647     } else {
3648       return ($a eq $b_key) ? 1 : 0;
3649     }
3650   } else {
3651     if (ref $a eq 'HASH') {
3652       my ($a_key) = keys %{$a};
3653       return ($b eq $a_key) ? 1 : 0;
3654     } else {
3655       return ($b eq $a) ? 1 : 0;
3656     }
3657   }
3658 }
3659
3660 sub _merge_joinpref_attr {
3661   my ($self, $orig, $import) = @_;
3662
3663   return $import unless defined($orig);
3664   return $orig unless defined($import);
3665
3666   $orig = $self->_rollout_attr($orig);
3667   $import = $self->_rollout_attr($import);
3668
3669   my $seen_keys;
3670   foreach my $import_element ( @{$import} ) {
3671     # find best candidate from $orig to merge $b_element into
3672     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3673     foreach my $orig_element ( @{$orig} ) {
3674       my $score = $self->_calculate_score( $orig_element, $import_element );
3675       if ($score > $best_candidate->{score}) {
3676         $best_candidate->{position} = $position;
3677         $best_candidate->{score} = $score;
3678       }
3679       $position++;
3680     }
3681     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3682     $import_key = '' if not defined $import_key;
3683
3684     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3685       push( @{$orig}, $import_element );
3686     } else {
3687       my $orig_best = $orig->[$best_candidate->{position}];
3688       # merge orig_best and b_element together and replace original with merged
3689       if (ref $orig_best ne 'HASH') {
3690         $orig->[$best_candidate->{position}] = $import_element;
3691       } elsif (ref $import_element eq 'HASH') {
3692         my ($key) = keys %{$orig_best};
3693         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3694       }
3695     }
3696     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3697   }
3698
3699   return @$orig ? $orig : ();
3700 }
3701
3702 {
3703   my $hm;
3704
3705   sub _merge_attr {
3706     $hm ||= do {
3707       require Hash::Merge;
3708       my $hm = Hash::Merge->new;
3709
3710       $hm->specify_behavior({
3711         SCALAR => {
3712           SCALAR => sub {
3713             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3714
3715             if ($defl xor $defr) {
3716               return [ $defl ? $_[0] : $_[1] ];
3717             }
3718             elsif (! $defl) {
3719               return [];
3720             }
3721             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3722               return [ $_[0] ];
3723             }
3724             else {
3725               return [$_[0], $_[1]];
3726             }
3727           },
3728           ARRAY => sub {
3729             return $_[1] if !defined $_[0];
3730             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3731             return [$_[0], @{$_[1]}]
3732           },
3733           HASH  => sub {
3734             return [] if !defined $_[0] and !keys %{$_[1]};
3735             return [ $_[1] ] if !defined $_[0];
3736             return [ $_[0] ] if !keys %{$_[1]};
3737             return [$_[0], $_[1]]
3738           },
3739         },
3740         ARRAY => {
3741           SCALAR => sub {
3742             return $_[0] if !defined $_[1];
3743             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3744             return [@{$_[0]}, $_[1]]
3745           },
3746           ARRAY => sub {
3747             my @ret = @{$_[0]} or return $_[1];
3748             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3749             my %idx = map { $_ => 1 } @ret;
3750             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3751             \@ret;
3752           },
3753           HASH => sub {
3754             return [ $_[1] ] if ! @{$_[0]};
3755             return $_[0] if !keys %{$_[1]};
3756             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3757             return [ @{$_[0]}, $_[1] ];
3758           },
3759         },
3760         HASH => {
3761           SCALAR => sub {
3762             return [] if !keys %{$_[0]} and !defined $_[1];
3763             return [ $_[0] ] if !defined $_[1];
3764             return [ $_[1] ] if !keys %{$_[0]};
3765             return [$_[0], $_[1]]
3766           },
3767           ARRAY => sub {
3768             return [] if !keys %{$_[0]} and !@{$_[1]};
3769             return [ $_[0] ] if !@{$_[1]};
3770             return $_[1] if !keys %{$_[0]};
3771             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3772             return [ $_[0], @{$_[1]} ];
3773           },
3774           HASH => sub {
3775             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3776             return [ $_[0] ] if !keys %{$_[1]};
3777             return [ $_[1] ] if !keys %{$_[0]};
3778             return [ $_[0] ] if $_[0] eq $_[1];
3779             return [ $_[0], $_[1] ];
3780           },
3781         }
3782       } => 'DBIC_RS_ATTR_MERGER');
3783       $hm;
3784     };
3785
3786     return $hm->merge ($_[1], $_[2]);
3787   }
3788 }
3789
3790 sub STORABLE_freeze {
3791   my ($self, $cloning) = @_;
3792   my $to_serialize = { %$self };
3793
3794   # A cursor in progress can't be serialized (and would make little sense anyway)
3795   # the parser can be regenerated (and can't be serialized)
3796   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3797
3798   # nor is it sensical to store a not-yet-fired-count pager
3799   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3800     delete $to_serialize->{pager};
3801   }
3802
3803   Storable::nfreeze($to_serialize);
3804 }
3805
3806 # need this hook for symmetry
3807 sub STORABLE_thaw {
3808   my ($self, $cloning, $serialized) = @_;
3809
3810   %$self = %{ Storable::thaw($serialized) };
3811
3812   $self;
3813 }
3814
3815
3816 =head2 throw_exception
3817
3818 See L<DBIx::Class::Schema/throw_exception> for details.
3819
3820 =cut
3821
3822 sub throw_exception {
3823   my $self=shift;
3824
3825   if (ref $self and my $rsrc = $self->result_source) {
3826     $rsrc->throw_exception(@_)
3827   }
3828   else {
3829     DBIx::Class::Exception->throw(@_);
3830   }
3831 }
3832
3833 1;
3834
3835 __END__
3836
3837 # XXX: FIXME: Attributes docs need clearing up
3838
3839 =head1 ATTRIBUTES
3840
3841 Attributes are used to refine a ResultSet in various ways when
3842 searching for data. They can be passed to any method which takes an
3843 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3844 L</count>.
3845
3846 Default attributes can be set on the result class using
3847 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3848 the CAVEATS on that feature before using it!)
3849
3850 These are in no particular order:
3851
3852 =head2 order_by
3853
3854 =over 4
3855
3856 =item Value: ( $order_by | \@order_by | \%order_by )
3857
3858 =back
3859
3860 Which column(s) to order the results by.
3861
3862 [The full list of suitable values is documented in
3863 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3864 common options.]
3865
3866 If a single column name, or an arrayref of names is supplied, the
3867 argument is passed through directly to SQL. The hashref syntax allows
3868 for connection-agnostic specification of ordering direction:
3869
3870  For descending order:
3871
3872   order_by => { -desc => [qw/col1 col2 col3/] }
3873
3874  For explicit ascending order:
3875
3876   order_by => { -asc => 'col' }
3877
3878 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3879 supported, although you are strongly encouraged to use the hashref
3880 syntax as outlined above.
3881
3882 =head2 columns
3883
3884 =over 4
3885
3886 =item Value: \@columns | \%columns | $column
3887
3888 =back
3889
3890 Shortcut to request a particular set of columns to be retrieved. Each
3891 column spec may be a string (a table column name), or a hash (in which
3892 case the key is the C<as> value, and the value is used as the C<select>
3893 expression). Adds C<me.> onto the start of any column without a C<.> in
3894 it and sets C<select> from that, then auto-populates C<as> from
3895 C<select> as normal. (You may also use the C<cols> attribute, as in
3896 earlier versions of DBIC.)
3897
3898 Essentially C<columns> does the same as L</select> and L</as>.
3899
3900     columns => [ 'foo', { bar => 'baz' } ]
3901
3902 is the same as
3903
3904     select => [qw/foo baz/],
3905     as => [qw/foo bar/]
3906
3907 =head2 +columns
3908
3909 =over 4
3910
3911 =item Value: \@columns
3912
3913 =back
3914
3915 Indicates additional columns to be selected from storage. Works the same
3916 as L</columns> but adds columns to the selection. (You may also use the
3917 C<include_columns> attribute, as in earlier versions of DBIC). For
3918 example:-
3919
3920   $schema->resultset('CD')->search(undef, {
3921     '+columns' => ['artist.name'],
3922     join => ['artist']
3923   });
3924
3925 would return all CDs and include a 'name' column to the information
3926 passed to object inflation. Note that the 'artist' is the name of the
3927 column (or relationship) accessor, and 'name' is the name of the column
3928 accessor in the related table.
3929
3930 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3931 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3932 unary plus operator before it.
3933
3934 =head2 include_columns
3935
3936 =over 4
3937
3938 =item Value: \@columns
3939
3940 =back
3941
3942 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3943
3944 =head2 select
3945
3946 =over 4
3947
3948 =item Value: \@select_columns
3949
3950 =back
3951
3952 Indicates which columns should be selected from the storage. You can use
3953 column names, or in the case of RDBMS back ends, function or stored procedure
3954 names:
3955
3956   $rs = $schema->resultset('Employee')->search(undef, {
3957     select => [
3958       'name',
3959       { count => 'employeeid' },
3960       { max => { length => 'name' }, -as => 'longest_name' }
3961     ]
3962   });
3963
3964   # Equivalent SQL
3965   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3966
3967 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3968 use L</select>, to instruct DBIx::Class how to store the result of the column.
3969 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3970 identifier aliasing. You can however alias a function, so you can use it in
3971 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3972 attribute> supplied as shown in the example above.
3973
3974 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3975 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3976 unary plus operator before it.
3977
3978 =head2 +select
3979
3980 =over 4
3981
3982 Indicates additional columns to be selected from storage.  Works the same as
3983 L</select> but adds columns to the default selection, instead of specifying
3984 an explicit list.
3985
3986 =back
3987
3988 =head2 as
3989
3990 =over 4
3991
3992 =item Value: \@inflation_names
3993
3994 =back
3995
3996 Indicates column names for object inflation. That is L</as> indicates the
3997 slot name in which the column value will be stored within the
3998 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3999 identifier by the C<get_column> method (or via the object accessor B<if one
4000 with the same name already exists>) as shown below. The L</as> attribute has
4001 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4002
4003   $rs = $schema->resultset('Employee')->search(undef, {
4004     select => [
4005       'name',
4006       { count => 'employeeid' },
4007       { max => { length => 'name' }, -as => 'longest_name' }
4008     ],
4009     as => [qw/
4010       name
4011       employee_count
4012       max_name_length
4013     /],
4014   });
4015
4016 If the object against which the search is performed already has an accessor
4017 matching a column name specified in C<as>, the value can be retrieved using
4018 the accessor as normal:
4019
4020   my $name = $employee->name();
4021
4022 If on the other hand an accessor does not exist in the object, you need to
4023 use C<get_column> instead:
4024
4025   my $employee_count = $employee->get_column('employee_count');
4026
4027 You can create your own accessors if required - see
4028 L<DBIx::Class::Manual::Cookbook> for details.
4029
4030 =head2 +as
4031
4032 =over 4
4033
4034 Indicates additional column names for those added via L</+select>. See L</as>.
4035
4036 =back
4037
4038 =head2 join
4039
4040 =over 4
4041
4042 =item Value: ($rel_name | \@rel_names | \%rel_names)
4043
4044 =back
4045
4046 Contains a list of relationships that should be joined for this query.  For
4047 example:
4048
4049   # Get CDs by Nine Inch Nails
4050   my $rs = $schema->resultset('CD')->search(
4051     { 'artist.name' => 'Nine Inch Nails' },
4052     { join => 'artist' }
4053   );
4054
4055 Can also contain a hash reference to refer to the other relation's relations.
4056 For example:
4057
4058   package MyApp::Schema::Track;
4059   use base qw/DBIx::Class/;
4060   __PACKAGE__->table('track');
4061   __PACKAGE__->add_columns(qw/trackid cd position title/);
4062   __PACKAGE__->set_primary_key('trackid');
4063   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4064   1;
4065
4066   # In your application
4067   my $rs = $schema->resultset('Artist')->search(
4068     { 'track.title' => 'Teardrop' },
4069     {
4070       join     => { cd => 'track' },
4071       order_by => 'artist.name',
4072     }
4073   );
4074
4075 You need to use the relationship (not the table) name in  conditions,
4076 because they are aliased as such. The current table is aliased as "me", so
4077 you need to use me.column_name in order to avoid ambiguity. For example:
4078
4079   # Get CDs from 1984 with a 'Foo' track
4080   my $rs = $schema->resultset('CD')->search(
4081     {
4082       'me.year' => 1984,
4083       'tracks.name' => 'Foo'
4084     },
4085     { join => 'tracks' }
4086   );
4087
4088 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4089 similarly for a third time). For e.g.
4090
4091   my $rs = $schema->resultset('Artist')->search({
4092     'cds.title'   => 'Down to Earth',
4093     'cds_2.title' => 'Popular',
4094   }, {
4095     join => [ qw/cds cds/ ],
4096   });
4097
4098 will return a set of all artists that have both a cd with title 'Down
4099 to Earth' and a cd with title 'Popular'.
4100
4101 If you want to fetch related objects from other tables as well, see L</prefetch>
4102 below.
4103
4104  NOTE: An internal join-chain pruner will discard certain joins while
4105  constructing the actual SQL query, as long as the joins in question do not
4106  affect the retrieved result. This for example includes 1:1 left joins
4107  that are not part of the restriction specification (WHERE/HAVING) nor are
4108  a part of the query selection.
4109
4110 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4111
4112 =head2 collapse
4113
4114 =over 4
4115
4116 =item Value: (0 | 1)
4117
4118 =back
4119
4120 When set to a true value, indicates that any rows fetched from joined has_many
4121 relationships are to be aggregated into the corresponding "parent" object. For
4122 example, the resultset:
4123
4124   my $rs = $schema->resultset('CD')->search({}, {
4125     '+columns' => [ qw/ tracks.title tracks.position / ],
4126     join => 'tracks',
4127     collapse => 1,
4128   });
4129
4130 While executing the following query:
4131
4132   SELECT me.*, tracks.title, tracks.position
4133     FROM cd me
4134     LEFT JOIN track tracks
4135       ON tracks.cdid = me.cdid
4136
4137 Will return only as many objects as there are rows in the CD source, even
4138 though the result of the query may span many rows. Each of these CD objects
4139 will in turn have multiple "Track" objects hidden behind the has_many
4140 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4141 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4142 product"), with each CD object containing exactly one of all fetched Track data.
4143
4144 When a collapse is requested on a non-ordered resultset, an order by some
4145 unique part of the main source (the left-most table) is inserted automatically.
4146 This is done so that the resultset is allowed to be "lazy" - calling
4147 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4148 object with all of its related data.
4149
4150 If an L</order_by> is already declared, and orders the resultset in a way that
4151 makes collapsing as described above impossible (e.g. C<< ORDER BY
4152 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4153 switch to "eager" mode and slurp the entire resultset before consturcting the
4154 first object returned by L</next>.
4155
4156 Setting this attribute on a resultset that does not join any has_many
4157 relations is a no-op.
4158
4159 For a more in-depth discussion, see L</PREFETCHING>.
4160
4161 =head2 prefetch
4162
4163 =over 4
4164
4165 =item Value: ($rel_name | \@rel_names | \%rel_names)
4166
4167 =back
4168
4169 This attribute is a shorthand for specifying a L</join> spec, adding all
4170 columns from the joined related sources as L</+columns> and setting
4171 L</collapse> to a true value. For example, the following two queries are
4172 equivalent:
4173
4174   my $rs = $schema->resultset('Artist')->search({}, {
4175     prefetch => { cds => ['genre', 'tracks' ] },
4176   });
4177
4178 and
4179
4180   my $rs = $schema->resultset('Artist')->search({}, {
4181     join => { cds => ['genre', 'tracks' ] },
4182     collapse => 1,
4183     '+columns' => [
4184       (map
4185         { +{ "cds.$_" => "cds.$_" } }
4186         $schema->source('Artist')->related_source('cds')->columns
4187       ),
4188       (map
4189         { +{ "cds.genre.$_" => "genre.$_" } }
4190         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4191       ),
4192       (map
4193         { +{ "cds.tracks.$_" => "tracks.$_" } }
4194         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4195       ),
4196     ],
4197   });
4198
4199 Both producing the following SQL:
4200
4201   SELECT  me.artistid, me.name, me.rank, me.charfield,
4202           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4203           genre.genreid, genre.name,
4204           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4205     FROM artist me
4206     LEFT JOIN cd cds
4207       ON cds.artist = me.artistid
4208     LEFT JOIN genre genre
4209       ON genre.genreid = cds.genreid
4210     LEFT JOIN track tracks
4211       ON tracks.cd = cds.cdid
4212   ORDER BY me.artistid
4213
4214 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4215 the arguments are properly merged and generally do the right thing. For
4216 example, you may want to do the following:
4217
4218   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4219     { 'genre.genreid' => undef },
4220     {
4221       join => { cds => 'genre' },
4222       prefetch => 'cds',
4223     }
4224   );
4225
4226 Which generates the following SQL:
4227
4228   SELECT  me.artistid, me.name, me.rank, me.charfield,
4229           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4230     FROM artist me
4231     LEFT JOIN cd cds
4232       ON cds.artist = me.artistid
4233     LEFT JOIN genre genre
4234       ON genre.genreid = cds.genreid
4235   WHERE genre.genreid IS NULL
4236   ORDER BY me.artistid
4237
4238 For a more in-depth discussion, see L</PREFETCHING>.
4239
4240 =head2 alias
4241
4242 =over 4
4243
4244 =item Value: $source_alias
4245
4246 =back
4247
4248 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4249 nested search queries (sub-SELECTs) might need specific aliases set to
4250 reference inner queries.  For example:
4251
4252    my $q = $rs
4253       ->related_resultset('CDs')
4254       ->related_resultset('Tracks')
4255       ->search({
4256          'track.id' => { -ident => 'none_search.id' },
4257       })
4258       ->as_query;
4259
4260    my $ids = $self->search({
4261       -not_exists => $q,
4262    }, {
4263       alias    => 'none_search',
4264       group_by => 'none_search.id',
4265    })->get_column('id')->as_query;
4266
4267    $self->search({ id => { -in => $ids } })
4268
4269 This attribute is directly tied to L</current_source_alias>.
4270
4271 =head2 page
4272
4273 =over 4
4274
4275 =item Value: $page
4276
4277 =back
4278
4279 Makes the resultset paged and specifies the page to retrieve. Effectively
4280 identical to creating a non-pages resultset and then calling ->page($page)
4281 on it.
4282
4283 If L</rows> attribute is not specified it defaults to 10 rows per page.
4284
4285 When you have a paged resultset, L</count> will only return the number
4286 of rows in the page. To get the total, use the L</pager> and call
4287 C<total_entries> on it.
4288
4289 =head2 rows
4290
4291 =over 4
4292
4293 =item Value: $rows
4294
4295 =back
4296
4297 Specifies the maximum number of rows for direct retrieval or the number of
4298 rows per page if the page attribute or method is used.
4299
4300 =head2 offset
4301
4302 =over 4
4303
4304 =item Value: $offset
4305
4306 =back
4307
4308 Specifies the (zero-based) row number for the  first row to be returned, or the
4309 of the first row of the first page if paging is used.
4310
4311 =head2 software_limit
4312
4313 =over 4
4314
4315 =item Value: (0 | 1)
4316
4317 =back
4318
4319 When combined with L</rows> and/or L</offset> the generated SQL will not
4320 include any limit dialect stanzas. Instead the entire result will be selected
4321 as if no limits were specified, and DBIC will perform the limit locally, by
4322 artificially advancing and finishing the resulting L</cursor>.
4323
4324 This is the recommended way of performing resultset limiting when no sane RDBMS
4325 implementation is available (e.g.
4326 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4327 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4328
4329 =head2 group_by
4330
4331 =over 4
4332
4333 =item Value: \@columns
4334
4335 =back
4336
4337 A arrayref of columns to group by. Can include columns of joined tables.
4338
4339   group_by => [qw/ column1 column2 ... /]
4340
4341 =head2 having
4342
4343 =over 4
4344
4345 =item Value: $condition
4346
4347 =back
4348
4349 HAVING is a select statement attribute that is applied between GROUP BY and
4350 ORDER BY. It is applied to the after the grouping calculations have been
4351 done.
4352
4353   having => { 'count_employee' => { '>=', 100 } }
4354
4355 or with an in-place function in which case literal SQL is required:
4356
4357   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4358
4359 =head2 distinct
4360
4361 =over 4
4362
4363 =item Value: (0 | 1)
4364
4365 =back
4366
4367 Set to 1 to group by all columns. If the resultset already has a group_by
4368 attribute, this setting is ignored and an appropriate warning is issued.
4369
4370 =head2 where
4371
4372 =over 4
4373
4374 Adds to the WHERE clause.
4375
4376   # only return rows WHERE deleted IS NULL for all searches
4377   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4378
4379 Can be overridden by passing C<< { where => undef } >> as an attribute
4380 to a resultset.
4381
4382 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4383
4384 =back
4385
4386 =head2 cache
4387
4388 Set to 1 to cache search results. This prevents extra SQL queries if you
4389 revisit rows in your ResultSet:
4390
4391   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4392
4393   while( my $artist = $resultset->next ) {
4394     ... do stuff ...
4395   }
4396
4397   $rs->first; # without cache, this would issue a query
4398
4399 By default, searches are not cached.
4400
4401 For more examples of using these attributes, see
4402 L<DBIx::Class::Manual::Cookbook>.
4403
4404 =head2 for
4405
4406 =over 4
4407
4408 =item Value: ( 'update' | 'shared' | \$scalar )
4409
4410 =back
4411
4412 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4413 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4414 query.
4415
4416 =head1 PREFETCHING
4417
4418 DBIx::Class supports arbitrary related data prefetching from multiple related
4419 sources. Any combination of relationship types and column sets are supported.
4420 If L<collapsing|/collapse> is requested, there is an additional requirement of
4421 selecting enough data to make every individual object uniquely identifiable.
4422
4423 Here are some more involved examples, based on the following relationship map:
4424
4425   # Assuming:
4426   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4427   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4428   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4429
4430   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4431
4432   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4433
4434
4435
4436   my $rs = $schema->resultset('Tag')->search(
4437     undef,
4438     {
4439       prefetch => {
4440         cd => 'artist'
4441       }
4442     }
4443   );
4444
4445 The initial search results in SQL like the following:
4446
4447   SELECT tag.*, cd.*, artist.* FROM tag
4448   JOIN cd ON tag.cd = cd.cdid
4449   JOIN artist ON cd.artist = artist.artistid
4450
4451 L<DBIx::Class> has no need to go back to the database when we access the
4452 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4453 case.
4454
4455 Simple prefetches will be joined automatically, so there is no need
4456 for a C<join> attribute in the above search.
4457
4458 The L</prefetch> attribute can be used with any of the relationship types
4459 and multiple prefetches can be specified together. Below is a more complex
4460 example that prefetches a CD's artist, its liner notes (if present),
4461 the cover image, the tracks on that CD, and the guests on those
4462 tracks.
4463
4464   my $rs = $schema->resultset('CD')->search(
4465     undef,
4466     {
4467       prefetch => [
4468         { artist => 'record_label'},  # belongs_to => belongs_to
4469         'liner_note',                 # might_have
4470         'cover_image',                # has_one
4471         { tracks => 'guests' },       # has_many => has_many
4472       ]
4473     }
4474   );
4475
4476 This will produce SQL like the following:
4477
4478   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4479          tracks.*, guests.*
4480     FROM cd me
4481     JOIN artist artist
4482       ON artist.artistid = me.artistid
4483     JOIN record_label record_label
4484       ON record_label.labelid = artist.labelid
4485     LEFT JOIN track tracks
4486       ON tracks.cdid = me.cdid
4487     LEFT JOIN guest guests
4488       ON guests.trackid = track.trackid
4489     LEFT JOIN liner_notes liner_note
4490       ON liner_note.cdid = me.cdid
4491     JOIN cd_artwork cover_image
4492       ON cover_image.cdid = me.cdid
4493   ORDER BY tracks.cd
4494
4495 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4496 C<tracks>, and C<guests> of the CD will all be available through the
4497 relationship accessors without the need for additional queries to the
4498 database.
4499
4500 =head3 CAVEATS
4501
4502 Prefetch does a lot of deep magic. As such, it may not behave exactly
4503 as you might expect.
4504
4505 =over 4
4506
4507 =item *
4508
4509 Prefetch uses the L</cache> to populate the prefetched relationships. This
4510 may or may not be what you want.
4511
4512 =item *
4513
4514 If you specify a condition on a prefetched relationship, ONLY those
4515 rows that match the prefetched condition will be fetched into that relationship.
4516 This means that adding prefetch to a search() B<may alter> what is returned by
4517 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4518
4519   my $artist_rs = $schema->resultset('Artist')->search({
4520       'cds.year' => 2008,
4521   }, {
4522       join => 'cds',
4523   });
4524
4525   my $count = $artist_rs->first->cds->count;
4526
4527   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4528
4529   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4530
4531   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4532
4533 That cmp_ok() may or may not pass depending on the datasets involved. In other
4534 words the C<WHERE> condition would apply to the entire dataset, just like
4535 it would in regular SQL. If you want to add a condition only to the "right side"
4536 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4537 condition|DBIx::Class::Relationship::Base/condition>
4538
4539 =back
4540
4541 =head1 DBIC BIND VALUES
4542
4543 Because DBIC may need more information to bind values than just the column name
4544 and value itself, it uses a special format for both passing and receiving bind
4545 values.  Each bind value should be composed of an arrayref of
4546 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4547
4548 =over 4
4549
4550 =item dbd_attrs
4551
4552 If present (in any form), this is what is being passed directly to bind_param.
4553 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4554 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4555
4556 If this is specified, all other bind options described below are ignored.
4557
4558 =item sqlt_datatype
4559
4560 If present, this is used to infer the actual bind attribute by passing to
4561 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4562 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4563
4564 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4565 currently drivers are expected to "Do the Right Thing" when given a common
4566 datatype name.  (Not ideal, but that's what we got at this point.)
4567
4568 =item sqlt_size
4569
4570 Currently used to correctly allocate buffers for bind_param_inout().
4571 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4572 or to a sensible value based on the "data_type".
4573
4574 =item dbic_colname
4575
4576 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4577 explicitly specified they are never overriden).  Also used by some weird DBDs,
4578 where the column name should be available at bind_param time (e.g. Oracle).
4579
4580 =back
4581
4582 For backwards compatibility and convenience, the following shortcuts are
4583 supported:
4584
4585   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4586   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4587   [ undef,   $val ] === [ {}, $val ]
4588
4589 =head1 AUTHOR AND CONTRIBUTORS
4590
4591 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4592
4593 =head1 LICENSE
4594
4595 You may distribute this code under the same terms as Perl itself.
4596