lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157   my $count = $self->_count;
1158   return 0 unless $count;
1159
1160   # need to take offset from resolved attrs
1161
1162   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1163   $count = $self->{attrs}{rows} if
1164     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1165   $count = 0 if ($count < 0);
1166   return $count;
1167 }
1168
1169 sub _count { # Separated out so pager can get the full count
1170   my $self = shift;
1171   my $attrs = { %{$self->_resolved_attrs} };
1172
1173   if (my $group_by = $attrs->{group_by}) {
1174     delete $attrs->{order_by};
1175
1176     $attrs->{select} = $group_by;
1177     $attrs->{from} = [ { 'mesub' => (ref $self)->new($self->result_source, $attrs)->cursor->as_query } ];
1178     delete $attrs->{where};
1179   }
1180
1181   $attrs->{select} = { count => '*' };
1182   $attrs->{as} = [qw/count/];
1183
1184   # offset, order by, group by, where and page are not needed to count. record_filter is cdbi
1185   delete $attrs->{$_} for qw/rows offset order_by group_by page pager record_filter/;
1186
1187   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1188   my ($count) = $tmp_rs->cursor->next;
1189   return $count;
1190 }
1191
1192 sub _bool {
1193   return 1;
1194 }
1195
1196 =head2 count_literal
1197
1198 =over 4
1199
1200 =item Arguments: $sql_fragment, @bind_values
1201
1202 =item Return Value: $count
1203
1204 =back
1205
1206 Counts the results in a literal query. Equivalent to calling L</search_literal>
1207 with the passed arguments, then L</count>.
1208
1209 =cut
1210
1211 sub count_literal { shift->search_literal(@_)->count; }
1212
1213 =head2 all
1214
1215 =over 4
1216
1217 =item Arguments: none
1218
1219 =item Return Value: @objects
1220
1221 =back
1222
1223 Returns all elements in the resultset. Called implicitly if the resultset
1224 is returned in list context.
1225
1226 =cut
1227
1228 sub all {
1229   my $self = shift;
1230   if(@_) {
1231       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1232   }
1233
1234   return @{ $self->get_cache } if $self->get_cache;
1235
1236   my @obj;
1237
1238   # TODO: don't call resolve here
1239   if (keys %{$self->_resolved_attrs->{collapse}}) {
1240 #  if ($self->{attrs}{prefetch}) {
1241       # Using $self->cursor->all is really just an optimisation.
1242       # If we're collapsing has_many prefetches it probably makes
1243       # very little difference, and this is cleaner than hacking
1244       # _construct_object to survive the approach
1245     my @row = $self->cursor->next;
1246     while (@row) {
1247       push(@obj, $self->_construct_object(@row));
1248       @row = (exists $self->{stashed_row}
1249                ? @{delete $self->{stashed_row}}
1250                : $self->cursor->next);
1251     }
1252   } else {
1253     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1254   }
1255
1256   $self->set_cache(\@obj) if $self->{attrs}{cache};
1257   return @obj;
1258 }
1259
1260 =head2 reset
1261
1262 =over 4
1263
1264 =item Arguments: none
1265
1266 =item Return Value: $self
1267
1268 =back
1269
1270 Resets the resultset's cursor, so you can iterate through the elements again.
1271
1272 =cut
1273
1274 sub reset {
1275   my ($self) = @_;
1276   delete $self->{_attrs} if exists $self->{_attrs};
1277   $self->{all_cache_position} = 0;
1278   $self->cursor->reset;
1279   return $self;
1280 }
1281
1282 =head2 first
1283
1284 =over 4
1285
1286 =item Arguments: none
1287
1288 =item Return Value: $object?
1289
1290 =back
1291
1292 Resets the resultset and returns an object for the first result (if the
1293 resultset returns anything).
1294
1295 =cut
1296
1297 sub first {
1298   return $_[0]->reset->next;
1299 }
1300
1301 # _cond_for_update_delete
1302 #
1303 # update/delete require the condition to be modified to handle
1304 # the differing SQL syntax available.  This transforms the $self->{cond}
1305 # appropriately, returning the new condition.
1306
1307 sub _cond_for_update_delete {
1308   my ($self, $full_cond) = @_;
1309   my $cond = {};
1310
1311   $full_cond ||= $self->{cond};
1312   # No-op. No condition, we're updating/deleting everything
1313   return $cond unless ref $full_cond;
1314
1315   # Some attributes when present require a subquery
1316   # This might not work on some database (mysql), but...
1317   # it won't work without the subquery either so who cares
1318   if (grep { defined $self->{attrs}{$_} } qw/join seen_join from rows group_by/) {
1319
1320     foreach my $pk ($self->result_source->primary_columns) {
1321       $cond->{$pk} = { IN => $self->get_column($pk)->as_query };
1322     }
1323
1324     return $cond;
1325   }
1326
1327   if (ref $full_cond eq 'ARRAY') {
1328     $cond = [
1329       map {
1330         my %hash;
1331         foreach my $key (keys %{$_}) {
1332           $key =~ /([^.]+)$/;
1333           $hash{$1} = $_->{$key};
1334         }
1335         \%hash;
1336       } @{$full_cond}
1337     ];
1338   }
1339   elsif (ref $full_cond eq 'HASH') {
1340     if ((keys %{$full_cond})[0] eq '-and') {
1341       $cond->{-and} = [];
1342       my @cond = @{$full_cond->{-and}};
1343        for (my $i = 0; $i < @cond; $i++) {
1344         my $entry = $cond[$i];
1345         my $hash;
1346         if (ref $entry eq 'HASH') {
1347           $hash = $self->_cond_for_update_delete($entry);
1348         }
1349         else {
1350           $entry =~ /([^.]+)$/;
1351           $hash->{$1} = $cond[++$i];
1352         }
1353         push @{$cond->{-and}}, $hash;
1354       }
1355     }
1356     else {
1357       foreach my $key (keys %{$full_cond}) {
1358         $key =~ /([^.]+)$/;
1359         $cond->{$1} = $full_cond->{$key};
1360       }
1361     }
1362   }
1363   else {
1364     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1365   }
1366
1367   return $cond;
1368 }
1369
1370
1371 =head2 update
1372
1373 =over 4
1374
1375 =item Arguments: \%values
1376
1377 =item Return Value: $storage_rv
1378
1379 =back
1380
1381 Sets the specified columns in the resultset to the supplied values in a
1382 single query. Return value will be true if the update succeeded or false
1383 if no records were updated; exact type of success value is storage-dependent.
1384
1385 =cut
1386
1387 sub update {
1388   my ($self, $values) = @_;
1389   $self->throw_exception("Values for update must be a hash")
1390     unless ref $values eq 'HASH';
1391
1392   my $cond = $self->_cond_for_update_delete;
1393
1394   return $self->result_source->storage->update(
1395     $self->result_source, $values, $cond
1396   );
1397 }
1398
1399 =head2 update_all
1400
1401 =over 4
1402
1403 =item Arguments: \%values
1404
1405 =item Return Value: 1
1406
1407 =back
1408
1409 Fetches all objects and updates them one at a time. Note that C<update_all>
1410 will run DBIC cascade triggers, while L</update> will not.
1411
1412 =cut
1413
1414 sub update_all {
1415   my ($self, $values) = @_;
1416   $self->throw_exception("Values for update must be a hash")
1417     unless ref $values eq 'HASH';
1418   foreach my $obj ($self->all) {
1419     $obj->set_columns($values)->update;
1420   }
1421   return 1;
1422 }
1423
1424 =head2 delete
1425
1426 =over 4
1427
1428 =item Arguments: none
1429
1430 =item Return Value: 1
1431
1432 =back
1433
1434 Deletes the contents of the resultset from its result source. Note that this
1435 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1436 to run. See also L<DBIx::Class::Row/delete>.
1437
1438 delete may not generate correct SQL for a query with joins or a resultset
1439 chained from a related resultset.  In this case it will generate a warning:-
1440
1441 In these cases you may find that delete_all is more appropriate, or you
1442 need to respecify your query in a way that can be expressed without a join.
1443
1444 =cut
1445
1446 sub delete {
1447   my ($self) = @_;
1448   $self->throw_exception("Delete should not be passed any arguments")
1449     if $_[1];
1450
1451   my $cond = $self->_cond_for_update_delete;
1452
1453   $self->result_source->storage->delete($self->result_source, $cond);
1454   return 1;
1455 }
1456
1457 =head2 delete_all
1458
1459 =over 4
1460
1461 =item Arguments: none
1462
1463 =item Return Value: 1
1464
1465 =back
1466
1467 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1468 will run DBIC cascade triggers, while L</delete> will not.
1469
1470 =cut
1471
1472 sub delete_all {
1473   my ($self) = @_;
1474   $_->delete for $self->all;
1475   return 1;
1476 }
1477
1478 =head2 populate
1479
1480 =over 4
1481
1482 =item Arguments: \@data;
1483
1484 =back
1485
1486 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1487 For the arrayref of hashrefs style each hashref should be a structure suitable
1488 forsubmitting to a $resultset->create(...) method.
1489
1490 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1491 to insert the data, as this is a faster method.
1492
1493 Otherwise, each set of data is inserted into the database using
1494 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1495 objects is returned.
1496
1497 Example:  Assuming an Artist Class that has many CDs Classes relating:
1498
1499   my $Artist_rs = $schema->resultset("Artist");
1500
1501   ## Void Context Example
1502   $Artist_rs->populate([
1503      { artistid => 4, name => 'Manufactured Crap', cds => [
1504         { title => 'My First CD', year => 2006 },
1505         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1506       ],
1507      },
1508      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1509         { title => 'My parents sold me to a record company' ,year => 2005 },
1510         { title => 'Why Am I So Ugly?', year => 2006 },
1511         { title => 'I Got Surgery and am now Popular', year => 2007 }
1512       ],
1513      },
1514   ]);
1515
1516   ## Array Context Example
1517   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1518     { name => "Artist One"},
1519     { name => "Artist Two"},
1520     { name => "Artist Three", cds=> [
1521     { title => "First CD", year => 2007},
1522     { title => "Second CD", year => 2008},
1523   ]}
1524   ]);
1525
1526   print $ArtistOne->name; ## response is 'Artist One'
1527   print $ArtistThree->cds->count ## reponse is '2'
1528
1529 For the arrayref of arrayrefs style,  the first element should be a list of the
1530 fieldsnames to which the remaining elements are rows being inserted.  For
1531 example:
1532
1533   $Arstist_rs->populate([
1534     [qw/artistid name/],
1535     [100, 'A Formally Unknown Singer'],
1536     [101, 'A singer that jumped the shark two albums ago'],
1537     [102, 'An actually cool singer.'],
1538   ]);
1539
1540 Please note an important effect on your data when choosing between void and
1541 wantarray context. Since void context goes straight to C<insert_bulk> in
1542 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1543 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1544 create primary keys for you, you will find that your PKs are empty.  In this
1545 case you will have to use the wantarray context in order to create those
1546 values.
1547
1548 =cut
1549
1550 sub populate {
1551   my $self = shift @_;
1552   my $data = ref $_[0][0] eq 'HASH'
1553     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1554     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1555
1556   if(defined wantarray) {
1557     my @created;
1558     foreach my $item (@$data) {
1559       push(@created, $self->create($item));
1560     }
1561     return @created;
1562   } else {
1563     my ($first, @rest) = @$data;
1564
1565     my @names = grep {!ref $first->{$_}} keys %$first;
1566     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1567     my @pks = $self->result_source->primary_columns;
1568
1569     ## do the belongs_to relationships
1570     foreach my $index (0..$#$data) {
1571       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1572         my @ret = $self->populate($data);
1573         return;
1574       }
1575
1576       foreach my $rel (@rels) {
1577         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1578         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1579         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1580         my $related = $result->result_source->resolve_condition(
1581           $result->result_source->relationship_info($reverse)->{cond},
1582           $self,
1583           $result,
1584         );
1585
1586         delete $data->[$index]->{$rel};
1587         $data->[$index] = {%{$data->[$index]}, %$related};
1588
1589         push @names, keys %$related if $index == 0;
1590       }
1591     }
1592
1593     ## do bulk insert on current row
1594     my @values = map { [ @$_{@names} ] } @$data;
1595
1596     $self->result_source->storage->insert_bulk(
1597       $self->result_source,
1598       \@names,
1599       \@values,
1600     );
1601
1602     ## do the has_many relationships
1603     foreach my $item (@$data) {
1604
1605       foreach my $rel (@rels) {
1606         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1607
1608         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1609      || $self->throw_exception('Cannot find the relating object.');
1610
1611         my $child = $parent->$rel;
1612
1613         my $related = $child->result_source->resolve_condition(
1614           $parent->result_source->relationship_info($rel)->{cond},
1615           $child,
1616           $parent,
1617         );
1618
1619         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1620         my @populate = map { {%$_, %$related} } @rows_to_add;
1621
1622         $child->populate( \@populate );
1623       }
1624     }
1625   }
1626 }
1627
1628 =head2 _normalize_populate_args ($args)
1629
1630 Private method used by L</populate> to normalize its incoming arguments.  Factored
1631 out in case you want to subclass and accept new argument structures to the
1632 L</populate> method.
1633
1634 =cut
1635
1636 sub _normalize_populate_args {
1637   my ($self, $data) = @_;
1638   my @names = @{shift(@$data)};
1639   my @results_to_create;
1640   foreach my $datum (@$data) {
1641     my %result_to_create;
1642     foreach my $index (0..$#names) {
1643       $result_to_create{$names[$index]} = $$datum[$index];
1644     }
1645     push @results_to_create, \%result_to_create;
1646   }
1647   return \@results_to_create;
1648 }
1649
1650 =head2 pager
1651
1652 =over 4
1653
1654 =item Arguments: none
1655
1656 =item Return Value: $pager
1657
1658 =back
1659
1660 Return Value a L<Data::Page> object for the current resultset. Only makes
1661 sense for queries with a C<page> attribute.
1662
1663 To get the full count of entries for a paged resultset, call
1664 C<total_entries> on the L<Data::Page> object.
1665
1666 =cut
1667
1668 sub pager {
1669   my ($self) = @_;
1670   my $attrs = $self->{attrs};
1671   $self->throw_exception("Can't create pager for non-paged rs")
1672     unless $self->{attrs}{page};
1673   $attrs->{rows} ||= 10;
1674   return $self->{pager} ||= Data::Page->new(
1675     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1676 }
1677
1678 =head2 page
1679
1680 =over 4
1681
1682 =item Arguments: $page_number
1683
1684 =item Return Value: $rs
1685
1686 =back
1687
1688 Returns a resultset for the $page_number page of the resultset on which page
1689 is called, where each page contains a number of rows equal to the 'rows'
1690 attribute set on the resultset (10 by default).
1691
1692 =cut
1693
1694 sub page {
1695   my ($self, $page) = @_;
1696   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1697 }
1698
1699 =head2 new_result
1700
1701 =over 4
1702
1703 =item Arguments: \%vals
1704
1705 =item Return Value: $rowobject
1706
1707 =back
1708
1709 Creates a new row object in the resultset's result class and returns
1710 it. The row is not inserted into the database at this point, call
1711 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1712 will tell you whether the row object has been inserted or not.
1713
1714 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1715
1716 =cut
1717
1718 sub new_result {
1719   my ($self, $values) = @_;
1720   $self->throw_exception( "new_result needs a hash" )
1721     unless (ref $values eq 'HASH');
1722
1723   my %new;
1724   my $alias = $self->{attrs}{alias};
1725
1726   if (
1727     defined $self->{cond}
1728     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1729   ) {
1730     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1731     $new{-from_resultset} = [ keys %new ] if keys %new;
1732   } else {
1733     $self->throw_exception(
1734       "Can't abstract implicit construct, condition not a hash"
1735     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1736
1737     my $collapsed_cond = (
1738       $self->{cond}
1739         ? $self->_collapse_cond($self->{cond})
1740         : {}
1741     );
1742
1743     # precendence must be given to passed values over values inherited from
1744     # the cond, so the order here is important.
1745     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1746     while( my($col,$value) = each %implied ){
1747       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1748         $new{$col} = $value->{'='};
1749         next;
1750       }
1751       $new{$col} = $value if $self->_is_deterministic_value($value);
1752     }
1753   }
1754
1755   %new = (
1756     %new,
1757     %{ $self->_remove_alias($values, $alias) },
1758     -source_handle => $self->_source_handle,
1759     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1760   );
1761
1762   return $self->result_class->new(\%new);
1763 }
1764
1765 # _is_deterministic_value
1766 #
1767 # Make an effor to strip non-deterministic values from the condition,
1768 # to make sure new_result chokes less
1769
1770 sub _is_deterministic_value {
1771   my $self = shift;
1772   my $value = shift;
1773   my $ref_type = ref $value;
1774   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1775   return 1 if Scalar::Util::blessed($value);
1776   return 0;
1777 }
1778
1779 # _collapse_cond
1780 #
1781 # Recursively collapse the condition.
1782
1783 sub _collapse_cond {
1784   my ($self, $cond, $collapsed) = @_;
1785
1786   $collapsed ||= {};
1787
1788   if (ref $cond eq 'ARRAY') {
1789     foreach my $subcond (@$cond) {
1790       next unless ref $subcond;  # -or
1791       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1792     }
1793   }
1794   elsif (ref $cond eq 'HASH') {
1795     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1796       foreach my $subcond (@{$cond->{-and}}) {
1797         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1798       }
1799     }
1800     else {
1801       foreach my $col (keys %$cond) {
1802         my $value = $cond->{$col};
1803         $collapsed->{$col} = $value;
1804       }
1805     }
1806   }
1807
1808   return $collapsed;
1809 }
1810
1811 # _remove_alias
1812 #
1813 # Remove the specified alias from the specified query hash. A copy is made so
1814 # the original query is not modified.
1815
1816 sub _remove_alias {
1817   my ($self, $query, $alias) = @_;
1818
1819   my %orig = %{ $query || {} };
1820   my %unaliased;
1821
1822   foreach my $key (keys %orig) {
1823     if ($key !~ /\./) {
1824       $unaliased{$key} = $orig{$key};
1825       next;
1826     }
1827     $unaliased{$1} = $orig{$key}
1828       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1829   }
1830
1831   return \%unaliased;
1832 }
1833
1834 =head2 as_query (EXPERIMENTAL)
1835
1836 =over 4
1837
1838 =item Arguments: none
1839
1840 =item Return Value: \[ $sql, @bind ]
1841
1842 =back
1843
1844 Returns the SQL query and bind vars associated with the invocant.
1845
1846 This is generally used as the RHS for a subquery.
1847
1848 B<NOTE>: This feature is still experimental.
1849
1850 =cut
1851
1852 sub as_query { return shift->cursor->as_query(@_) }
1853
1854 =head2 find_or_new
1855
1856 =over 4
1857
1858 =item Arguments: \%vals, \%attrs?
1859
1860 =item Return Value: $rowobject
1861
1862 =back
1863
1864   my $artist = $schema->resultset('Artist')->find_or_new(
1865     { artist => 'fred' }, { key => 'artists' });
1866
1867   $cd->cd_to_producer->find_or_new({ producer => $producer },
1868                                    { key => 'primary });
1869
1870 Find an existing record from this resultset, based on its primary
1871 key, or a unique constraint. If none exists, instantiate a new result
1872 object and return it. The object will not be saved into your storage
1873 until you call L<DBIx::Class::Row/insert> on it.
1874
1875 You most likely want this method when looking for existing rows using
1876 a unique constraint that is not the primary key, or looking for
1877 related rows.
1878
1879 If you want objects to be saved immediately, use L</find_or_create> instead.
1880
1881 B<Note>: C<find_or_new> is probably not what you want when creating a
1882 new row in a table that uses primary keys supplied by the
1883 database. Passing in a primary key column with a value of I<undef>
1884 will cause L</find> to attempt to search for a row with a value of
1885 I<NULL>.
1886
1887 =cut
1888
1889 sub find_or_new {
1890   my $self     = shift;
1891   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1892   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1893   my $exists   = $self->find($hash, $attrs);
1894   return defined $exists ? $exists : $self->new_result($hash);
1895 }
1896
1897 =head2 create
1898
1899 =over 4
1900
1901 =item Arguments: \%vals
1902
1903 =item Return Value: a L<DBIx::Class::Row> $object
1904
1905 =back
1906
1907 Attempt to create a single new row or a row with multiple related rows
1908 in the table represented by the resultset (and related tables). This
1909 will not check for duplicate rows before inserting, use
1910 L</find_or_create> to do that.
1911
1912 To create one row for this resultset, pass a hashref of key/value
1913 pairs representing the columns of the table and the values you wish to
1914 store. If the appropriate relationships are set up, foreign key fields
1915 can also be passed an object representing the foreign row, and the
1916 value will be set to its primary key.
1917
1918 To create related objects, pass a hashref for the value if the related
1919 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1920 and use the name of the relationship as the key. (NOT the name of the field,
1921 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1922 of hashrefs containing the data for each of the rows to create in the foreign
1923 tables, again using the relationship name as the key.
1924
1925 Instead of hashrefs of plain related data (key/value pairs), you may
1926 also pass new or inserted objects. New objects (not inserted yet, see
1927 L</new>), will be inserted into their appropriate tables.
1928
1929 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1930
1931 Example of creating a new row.
1932
1933   $person_rs->create({
1934     name=>"Some Person",
1935     email=>"somebody@someplace.com"
1936   });
1937
1938 Example of creating a new row and also creating rows in a related C<has_many>
1939 or C<has_one> resultset.  Note Arrayref.
1940
1941   $artist_rs->create(
1942      { artistid => 4, name => 'Manufactured Crap', cds => [
1943         { title => 'My First CD', year => 2006 },
1944         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1945       ],
1946      },
1947   );
1948
1949 Example of creating a new row and also creating a row in a related
1950 C<belongs_to>resultset. Note Hashref.
1951
1952   $cd_rs->create({
1953     title=>"Music for Silly Walks",
1954     year=>2000,
1955     artist => {
1956       name=>"Silly Musician",
1957     }
1958   });
1959
1960 =cut
1961
1962 sub create {
1963   my ($self, $attrs) = @_;
1964   $self->throw_exception( "create needs a hashref" )
1965     unless ref $attrs eq 'HASH';
1966   return $self->new_result($attrs)->insert;
1967 }
1968
1969 =head2 find_or_create
1970
1971 =over 4
1972
1973 =item Arguments: \%vals, \%attrs?
1974
1975 =item Return Value: $rowobject
1976
1977 =back
1978
1979   $cd->cd_to_producer->find_or_create({ producer => $producer },
1980                                       { key => 'primary });
1981
1982 Tries to find a record based on its primary key or unique constraints; if none
1983 is found, creates one and returns that instead.
1984
1985   my $cd = $schema->resultset('CD')->find_or_create({
1986     cdid   => 5,
1987     artist => 'Massive Attack',
1988     title  => 'Mezzanine',
1989     year   => 2005,
1990   });
1991
1992 Also takes an optional C<key> attribute, to search by a specific key or unique
1993 constraint. For example:
1994
1995   my $cd = $schema->resultset('CD')->find_or_create(
1996     {
1997       artist => 'Massive Attack',
1998       title  => 'Mezzanine',
1999     },
2000     { key => 'cd_artist_title' }
2001   );
2002
2003 B<Note>: Because find_or_create() reads from the database and then
2004 possibly inserts based on the result, this method is subject to a race
2005 condition. Another process could create a record in the table after
2006 the find has completed and before the create has started. To avoid
2007 this problem, use find_or_create() inside a transaction.
2008
2009 B<Note>: C<find_or_create> is probably not what you want when creating
2010 a new row in a table that uses primary keys supplied by the
2011 database. Passing in a primary key column with a value of I<undef>
2012 will cause L</find> to attempt to search for a row with a value of
2013 I<NULL>.
2014
2015 See also L</find> and L</update_or_create>. For information on how to declare
2016 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2017
2018 =cut
2019
2020 sub find_or_create {
2021   my $self     = shift;
2022   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2023   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2024   my $exists   = $self->find($hash, $attrs);
2025   return defined $exists ? $exists : $self->create($hash);
2026 }
2027
2028 =head2 update_or_create
2029
2030 =over 4
2031
2032 =item Arguments: \%col_values, { key => $unique_constraint }?
2033
2034 =item Return Value: $rowobject
2035
2036 =back
2037
2038   $resultset->update_or_create({ col => $val, ... });
2039
2040 First, searches for an existing row matching one of the unique constraints
2041 (including the primary key) on the source of this resultset. If a row is
2042 found, updates it with the other given column values. Otherwise, creates a new
2043 row.
2044
2045 Takes an optional C<key> attribute to search on a specific unique constraint.
2046 For example:
2047
2048   # In your application
2049   my $cd = $schema->resultset('CD')->update_or_create(
2050     {
2051       artist => 'Massive Attack',
2052       title  => 'Mezzanine',
2053       year   => 1998,
2054     },
2055     { key => 'cd_artist_title' }
2056   );
2057
2058   $cd->cd_to_producer->update_or_create({
2059     producer => $producer,
2060     name => 'harry',
2061   }, {
2062     key => 'primary,
2063   });
2064
2065
2066 If no C<key> is specified, it searches on all unique constraints defined on the
2067 source, including the primary key.
2068
2069 If the C<key> is specified as C<primary>, it searches only on the primary key.
2070
2071 See also L</find> and L</find_or_create>. For information on how to declare
2072 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2073
2074 B<Note>: C<update_or_create> is probably not what you want when
2075 looking for a row in a table that uses primary keys supplied by the
2076 database, unless you actually have a key value. Passing in a primary
2077 key column with a value of I<undef> will cause L</find> to attempt to
2078 search for a row with a value of I<NULL>.
2079
2080 =cut
2081
2082 sub update_or_create {
2083   my $self = shift;
2084   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2085   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2086
2087   my $row = $self->find($cond, $attrs);
2088   if (defined $row) {
2089     $row->update($cond);
2090     return $row;
2091   }
2092
2093   return $self->create($cond);
2094 }
2095
2096 =head2 update_or_new
2097
2098 =over 4
2099
2100 =item Arguments: \%col_values, { key => $unique_constraint }?
2101
2102 =item Return Value: $rowobject
2103
2104 =back
2105
2106   $resultset->update_or_new({ col => $val, ... });
2107
2108 First, searches for an existing row matching one of the unique constraints
2109 (including the primary key) on the source of this resultset. If a row is
2110 found, updates it with the other given column values. Otherwise, instantiate
2111 a new result object and return it. The object will not be saved into your storage
2112 until you call L<DBIx::Class::Row/insert> on it.
2113
2114 Takes an optional C<key> attribute to search on a specific unique constraint.
2115 For example:
2116
2117   # In your application
2118   my $cd = $schema->resultset('CD')->update_or_new(
2119     {
2120       artist => 'Massive Attack',
2121       title  => 'Mezzanine',
2122       year   => 1998,
2123     },
2124     { key => 'cd_artist_title' }
2125   );
2126
2127   if ($cd->in_storage) {
2128       # the cd was updated
2129   }
2130   else {
2131       # the cd is not yet in the database, let's insert it
2132       $cd->insert;
2133   }
2134
2135 See also L</find>, L</find_or_create> and L<find_or_new>.
2136
2137 =cut
2138
2139 sub update_or_new {
2140     my $self  = shift;
2141     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2142     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2143
2144     my $row = $self->find( $cond, $attrs );
2145     if ( defined $row ) {
2146         $row->update($cond);
2147         return $row;
2148     }
2149
2150     return $self->new_result($cond);
2151 }
2152
2153 =head2 get_cache
2154
2155 =over 4
2156
2157 =item Arguments: none
2158
2159 =item Return Value: \@cache_objects?
2160
2161 =back
2162
2163 Gets the contents of the cache for the resultset, if the cache is set.
2164
2165 The cache is populated either by using the L</prefetch> attribute to
2166 L</search> or by calling L</set_cache>.
2167
2168 =cut
2169
2170 sub get_cache {
2171   shift->{all_cache};
2172 }
2173
2174 =head2 set_cache
2175
2176 =over 4
2177
2178 =item Arguments: \@cache_objects
2179
2180 =item Return Value: \@cache_objects
2181
2182 =back
2183
2184 Sets the contents of the cache for the resultset. Expects an arrayref
2185 of objects of the same class as those produced by the resultset. Note that
2186 if the cache is set the resultset will return the cached objects rather
2187 than re-querying the database even if the cache attr is not set.
2188
2189 The contents of the cache can also be populated by using the
2190 L</prefetch> attribute to L</search>.
2191
2192 =cut
2193
2194 sub set_cache {
2195   my ( $self, $data ) = @_;
2196   $self->throw_exception("set_cache requires an arrayref")
2197       if defined($data) && (ref $data ne 'ARRAY');
2198   $self->{all_cache} = $data;
2199 }
2200
2201 =head2 clear_cache
2202
2203 =over 4
2204
2205 =item Arguments: none
2206
2207 =item Return Value: []
2208
2209 =back
2210
2211 Clears the cache for the resultset.
2212
2213 =cut
2214
2215 sub clear_cache {
2216   shift->set_cache(undef);
2217 }
2218
2219 =head2 related_resultset
2220
2221 =over 4
2222
2223 =item Arguments: $relationship_name
2224
2225 =item Return Value: $resultset
2226
2227 =back
2228
2229 Returns a related resultset for the supplied relationship name.
2230
2231   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2232
2233 =cut
2234
2235 sub related_resultset {
2236   my ($self, $rel) = @_;
2237
2238   $self->{related_resultsets} ||= {};
2239   return $self->{related_resultsets}{$rel} ||= do {
2240     my $rel_obj = $self->result_source->relationship_info($rel);
2241
2242     $self->throw_exception(
2243       "search_related: result source '" . $self->result_source->source_name .
2244         "' has no such relationship $rel")
2245       unless $rel_obj;
2246
2247     my ($from,$seen) = $self->_resolve_from($rel);
2248
2249     my $join_count = $seen->{$rel};
2250     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2251
2252     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2253     my %attrs = %{$self->{attrs}||{}};
2254     delete @attrs{qw(result_class alias)};
2255
2256     my $new_cache;
2257
2258     if (my $cache = $self->get_cache) {
2259       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2260         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2261                         @$cache ];
2262       }
2263     }
2264
2265     my $rel_source = $self->result_source->related_source($rel);
2266
2267     my $new = do {
2268
2269       # The reason we do this now instead of passing the alias to the
2270       # search_rs below is that if you wrap/overload resultset on the
2271       # source you need to know what alias it's -going- to have for things
2272       # to work sanely (e.g. RestrictWithObject wants to be able to add
2273       # extra query restrictions, and these may need to be $alias.)
2274
2275       my $attrs = $rel_source->resultset_attributes;
2276       local $attrs->{alias} = $alias;
2277
2278       $rel_source->resultset
2279                  ->search_rs(
2280                      undef, {
2281                        %attrs,
2282                        join => undef,
2283                        prefetch => undef,
2284                        select => undef,
2285                        as => undef,
2286                        where => $self->{cond},
2287                        seen_join => $seen,
2288                        from => $from,
2289                    });
2290     };
2291     $new->set_cache($new_cache) if $new_cache;
2292     $new;
2293   };
2294 }
2295
2296 =head2 current_source_alias
2297
2298 =over 4
2299
2300 =item Arguments: none
2301
2302 =item Return Value: $source_alias
2303
2304 =back
2305
2306 Returns the current table alias for the result source this resultset is built
2307 on, that will be used in the SQL query. Usually it is C<me>.
2308
2309 Currently the source alias that refers to the result set returned by a
2310 L</search>/L</find> family method depends on how you got to the resultset: it's
2311 C<me> by default, but eg. L</search_related> aliases it to the related result
2312 source name (and keeps C<me> referring to the original result set). The long
2313 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2314 (and make this method unnecessary).
2315
2316 Thus it's currently necessary to use this method in predefined queries (see
2317 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2318 source alias of the current result set:
2319
2320   # in a result set class
2321   sub modified_by {
2322     my ($self, $user) = @_;
2323
2324     my $me = $self->current_source_alias;
2325
2326     return $self->search(
2327       "$me.modified" => $user->id,
2328     );
2329   }
2330
2331 =cut
2332
2333 sub current_source_alias {
2334   my ($self) = @_;
2335
2336   return ($self->{attrs} || {})->{alias} || 'me';
2337 }
2338
2339 # This code is called by search_related, and makes sure there
2340 # is clear separation between the joins before, during, and
2341 # after the relationship. This information is needed later
2342 # in order to properly resolve prefetch aliases (any alias
2343 # with a relation_chain_depth less than the depth of the
2344 # current prefetch is not considered)
2345 sub _resolve_from {
2346   my ($self, $extra_join) = @_;
2347   my $source = $self->result_source;
2348   my $attrs = $self->{attrs};
2349
2350   my $from = $attrs->{from}
2351     || [ { $attrs->{alias} => $source->from } ];
2352
2353   my $seen = { %{$attrs->{seen_join}||{}} };
2354
2355   # we need to take the prefetch the attrs into account before we
2356   # ->resolve_join as otherwise they get lost - captainL
2357   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2358
2359   push @$from, $source->resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2360
2361   ++$seen->{-relation_chain_depth};
2362
2363   push @$from, $source->resolve_join($extra_join, $attrs->{alias}, $seen);
2364
2365   ++$seen->{-relation_chain_depth};
2366
2367   return ($from,$seen);
2368 }
2369
2370 sub _resolved_attrs {
2371   my $self = shift;
2372   return $self->{_attrs} if $self->{_attrs};
2373
2374   my $attrs  = { %{ $self->{attrs} || {} } };
2375   my $source = $self->result_source;
2376   my $alias  = $attrs->{alias};
2377
2378   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2379   my @colbits;
2380
2381   # build columns (as long as select isn't set) into a set of as/select hashes
2382   unless ( $attrs->{select} ) {
2383       @colbits = map {
2384           ( ref($_) eq 'HASH' )
2385               ? $_
2386               : {
2387                   (
2388                     /^\Q${alias}.\E(.+)$/
2389                       ? "$1"
2390                       : "$_"
2391                   )
2392                 =>
2393                   (
2394                     /\./
2395                       ? "$_"
2396                       : "${alias}.$_"
2397                   )
2398             }
2399       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2400   }
2401   # add the additional columns on
2402   foreach ( 'include_columns', '+columns' ) {
2403       push @colbits, map {
2404           ( ref($_) eq 'HASH' )
2405             ? $_
2406             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2407       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2408   }
2409
2410   # start with initial select items
2411   if ( $attrs->{select} ) {
2412     $attrs->{select} =
2413         ( ref $attrs->{select} eq 'ARRAY' )
2414       ? [ @{ $attrs->{select} } ]
2415       : [ $attrs->{select} ];
2416     $attrs->{as} = (
2417       $attrs->{as}
2418       ? (
2419         ref $attrs->{as} eq 'ARRAY'
2420         ? [ @{ $attrs->{as} } ]
2421         : [ $attrs->{as} ]
2422         )
2423       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2424     );
2425   }
2426   else {
2427
2428     # otherwise we intialise select & as to empty
2429     $attrs->{select} = [];
2430     $attrs->{as}     = [];
2431   }
2432
2433   # now add colbits to select/as
2434   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2435   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2436
2437   my $adds;
2438   if ( $adds = delete $attrs->{'+select'} ) {
2439     $adds = [$adds] unless ref $adds eq 'ARRAY';
2440     push(
2441       @{ $attrs->{select} },
2442       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2443     );
2444   }
2445   if ( $adds = delete $attrs->{'+as'} ) {
2446     $adds = [$adds] unless ref $adds eq 'ARRAY';
2447     push( @{ $attrs->{as} }, @$adds );
2448   }
2449
2450   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2451
2452   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2453     my $join = delete $attrs->{join} || {};
2454
2455     if ( defined $attrs->{prefetch} ) {
2456       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2457
2458     }
2459
2460     $attrs->{from} =    # have to copy here to avoid corrupting the original
2461       [
2462       @{ $attrs->{from} },
2463       $source->resolve_join(
2464         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2465       )
2466       ];
2467
2468   }
2469
2470   $attrs->{group_by} ||= $attrs->{select}
2471     if delete $attrs->{distinct};
2472   if ( $attrs->{order_by} ) {
2473     $attrs->{order_by} = (
2474       ref( $attrs->{order_by} ) eq 'ARRAY'
2475       ? [ @{ $attrs->{order_by} } ]
2476       : [ $attrs->{order_by} ]
2477     );
2478   }
2479   else {
2480     $attrs->{order_by} = [];
2481   }
2482
2483   my $collapse = $attrs->{collapse} || {};
2484   if ( my $prefetch = delete $attrs->{prefetch} ) {
2485     $prefetch = $self->_merge_attr( {}, $prefetch );
2486     my @pre_order;
2487     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2488
2489       # bring joins back to level of current class
2490       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2491       my @prefetch =
2492         $source->resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2493       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2494       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2495     }
2496     push( @{ $attrs->{order_by} }, @pre_order );
2497   }
2498   $attrs->{collapse} = $collapse;
2499
2500   if ( $attrs->{page} ) {
2501     $attrs->{offset} ||= 0;
2502     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2503   }
2504
2505   return $self->{_attrs} = $attrs;
2506 }
2507
2508 sub _joinpath_aliases {
2509   my ($self, $fromspec, $seen) = @_;
2510
2511   my $paths = {};
2512   return $paths unless ref $fromspec eq 'ARRAY';
2513
2514   for my $j (@$fromspec) {
2515
2516     next if ref $j ne 'ARRAY';
2517     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2518
2519     my $p = $paths;
2520     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2521     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2522   }
2523
2524   return $paths;
2525 }
2526
2527 sub _rollout_attr {
2528   my ($self, $attr) = @_;
2529
2530   if (ref $attr eq 'HASH') {
2531     return $self->_rollout_hash($attr);
2532   } elsif (ref $attr eq 'ARRAY') {
2533     return $self->_rollout_array($attr);
2534   } else {
2535     return [$attr];
2536   }
2537 }
2538
2539 sub _rollout_array {
2540   my ($self, $attr) = @_;
2541
2542   my @rolled_array;
2543   foreach my $element (@{$attr}) {
2544     if (ref $element eq 'HASH') {
2545       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2546     } elsif (ref $element eq 'ARRAY') {
2547       #  XXX - should probably recurse here
2548       push( @rolled_array, @{$self->_rollout_array($element)} );
2549     } else {
2550       push( @rolled_array, $element );
2551     }
2552   }
2553   return \@rolled_array;
2554 }
2555
2556 sub _rollout_hash {
2557   my ($self, $attr) = @_;
2558
2559   my @rolled_array;
2560   foreach my $key (keys %{$attr}) {
2561     push( @rolled_array, { $key => $attr->{$key} } );
2562   }
2563   return \@rolled_array;
2564 }
2565
2566 sub _calculate_score {
2567   my ($self, $a, $b) = @_;
2568
2569   if (ref $b eq 'HASH') {
2570     my ($b_key) = keys %{$b};
2571     if (ref $a eq 'HASH') {
2572       my ($a_key) = keys %{$a};
2573       if ($a_key eq $b_key) {
2574         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2575       } else {
2576         return 0;
2577       }
2578     } else {
2579       return ($a eq $b_key) ? 1 : 0;
2580     }
2581   } else {
2582     if (ref $a eq 'HASH') {
2583       my ($a_key) = keys %{$a};
2584       return ($b eq $a_key) ? 1 : 0;
2585     } else {
2586       return ($b eq $a) ? 1 : 0;
2587     }
2588   }
2589 }
2590
2591 sub _merge_attr {
2592   my ($self, $orig, $import) = @_;
2593
2594   return $import unless defined($orig);
2595   return $orig unless defined($import);
2596
2597   $orig = $self->_rollout_attr($orig);
2598   $import = $self->_rollout_attr($import);
2599
2600   my $seen_keys;
2601   foreach my $import_element ( @{$import} ) {
2602     # find best candidate from $orig to merge $b_element into
2603     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2604     foreach my $orig_element ( @{$orig} ) {
2605       my $score = $self->_calculate_score( $orig_element, $import_element );
2606       if ($score > $best_candidate->{score}) {
2607         $best_candidate->{position} = $position;
2608         $best_candidate->{score} = $score;
2609       }
2610       $position++;
2611     }
2612     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2613
2614     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2615       push( @{$orig}, $import_element );
2616     } else {
2617       my $orig_best = $orig->[$best_candidate->{position}];
2618       # merge orig_best and b_element together and replace original with merged
2619       if (ref $orig_best ne 'HASH') {
2620         $orig->[$best_candidate->{position}] = $import_element;
2621       } elsif (ref $import_element eq 'HASH') {
2622         my ($key) = keys %{$orig_best};
2623         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2624       }
2625     }
2626     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2627   }
2628
2629   return $orig;
2630 }
2631
2632 sub result_source {
2633     my $self = shift;
2634
2635     if (@_) {
2636         $self->_source_handle($_[0]->handle);
2637     } else {
2638         $self->_source_handle->resolve;
2639     }
2640 }
2641
2642 =head2 throw_exception
2643
2644 See L<DBIx::Class::Schema/throw_exception> for details.
2645
2646 =cut
2647
2648 sub throw_exception {
2649   my $self=shift;
2650   if (ref $self && $self->_source_handle->schema) {
2651     $self->_source_handle->schema->throw_exception(@_)
2652   } else {
2653     croak(@_);
2654   }
2655
2656 }
2657
2658 # XXX: FIXME: Attributes docs need clearing up
2659
2660 =head1 ATTRIBUTES
2661
2662 Attributes are used to refine a ResultSet in various ways when
2663 searching for data. They can be passed to any method which takes an
2664 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2665 L</count>.
2666
2667 These are in no particular order:
2668
2669 =head2 order_by
2670
2671 =over 4
2672
2673 =item Value: ( $order_by | \@order_by | \%order_by )
2674
2675 =back
2676
2677 Which column(s) to order the results by. If a single column name, or
2678 an arrayref of names is supplied, the argument is passed through
2679 directly to SQL. The hashref syntax allows for connection-agnostic
2680 specification of ordering direction:
2681
2682  For descending order:
2683
2684   order_by => { -desc => [qw/col1 col2 col3/] }
2685
2686  For explicit ascending order:
2687
2688   order_by => { -asc => 'col' }
2689
2690 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2691 supported, although you are strongly encouraged to use the hashref
2692 syntax as outlined above.
2693
2694 =head2 columns
2695
2696 =over 4
2697
2698 =item Value: \@columns
2699
2700 =back
2701
2702 Shortcut to request a particular set of columns to be retrieved. Each
2703 column spec may be a string (a table column name), or a hash (in which
2704 case the key is the C<as> value, and the value is used as the C<select>
2705 expression). Adds C<me.> onto the start of any column without a C<.> in
2706 it and sets C<select> from that, then auto-populates C<as> from
2707 C<select> as normal. (You may also use the C<cols> attribute, as in
2708 earlier versions of DBIC.)
2709
2710 =head2 +columns
2711
2712 =over 4
2713
2714 =item Value: \@columns
2715
2716 =back
2717
2718 Indicates additional columns to be selected from storage. Works the same
2719 as L</columns> but adds columns to the selection. (You may also use the
2720 C<include_columns> attribute, as in earlier versions of DBIC). For
2721 example:-
2722
2723   $schema->resultset('CD')->search(undef, {
2724     '+columns' => ['artist.name'],
2725     join => ['artist']
2726   });
2727
2728 would return all CDs and include a 'name' column to the information
2729 passed to object inflation. Note that the 'artist' is the name of the
2730 column (or relationship) accessor, and 'name' is the name of the column
2731 accessor in the related table.
2732
2733 =head2 include_columns
2734
2735 =over 4
2736
2737 =item Value: \@columns
2738
2739 =back
2740
2741 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2742
2743 =head2 select
2744
2745 =over 4
2746
2747 =item Value: \@select_columns
2748
2749 =back
2750
2751 Indicates which columns should be selected from the storage. You can use
2752 column names, or in the case of RDBMS back ends, function or stored procedure
2753 names:
2754
2755   $rs = $schema->resultset('Employee')->search(undef, {
2756     select => [
2757       'name',
2758       { count => 'employeeid' },
2759       { sum => 'salary' }
2760     ]
2761   });
2762
2763 When you use function/stored procedure names and do not supply an C<as>
2764 attribute, the column names returned are storage-dependent. E.g. MySQL would
2765 return a column named C<count(employeeid)> in the above example.
2766
2767 =head2 +select
2768
2769 =over 4
2770
2771 Indicates additional columns to be selected from storage.  Works the same as
2772 L</select> but adds columns to the selection.
2773
2774 =back
2775
2776 =head2 +as
2777
2778 =over 4
2779
2780 Indicates additional column names for those added via L</+select>. See L</as>.
2781
2782 =back
2783
2784 =head2 as
2785
2786 =over 4
2787
2788 =item Value: \@inflation_names
2789
2790 =back
2791
2792 Indicates column names for object inflation. That is, C<as>
2793 indicates the name that the column can be accessed as via the
2794 C<get_column> method (or via the object accessor, B<if one already
2795 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2796
2797 The C<as> attribute is used in conjunction with C<select>,
2798 usually when C<select> contains one or more function or stored
2799 procedure names:
2800
2801   $rs = $schema->resultset('Employee')->search(undef, {
2802     select => [
2803       'name',
2804       { count => 'employeeid' }
2805     ],
2806     as => ['name', 'employee_count'],
2807   });
2808
2809   my $employee = $rs->first(); # get the first Employee
2810
2811 If the object against which the search is performed already has an accessor
2812 matching a column name specified in C<as>, the value can be retrieved using
2813 the accessor as normal:
2814
2815   my $name = $employee->name();
2816
2817 If on the other hand an accessor does not exist in the object, you need to
2818 use C<get_column> instead:
2819
2820   my $employee_count = $employee->get_column('employee_count');
2821
2822 You can create your own accessors if required - see
2823 L<DBIx::Class::Manual::Cookbook> for details.
2824
2825 Please note: This will NOT insert an C<AS employee_count> into the SQL
2826 statement produced, it is used for internal access only. Thus
2827 attempting to use the accessor in an C<order_by> clause or similar
2828 will fail miserably.
2829
2830 To get around this limitation, you can supply literal SQL to your
2831 C<select> attibute that contains the C<AS alias> text, eg:
2832
2833   select => [\'myfield AS alias']
2834
2835 =head2 join
2836
2837 =over 4
2838
2839 =item Value: ($rel_name | \@rel_names | \%rel_names)
2840
2841 =back
2842
2843 Contains a list of relationships that should be joined for this query.  For
2844 example:
2845
2846   # Get CDs by Nine Inch Nails
2847   my $rs = $schema->resultset('CD')->search(
2848     { 'artist.name' => 'Nine Inch Nails' },
2849     { join => 'artist' }
2850   );
2851
2852 Can also contain a hash reference to refer to the other relation's relations.
2853 For example:
2854
2855   package MyApp::Schema::Track;
2856   use base qw/DBIx::Class/;
2857   __PACKAGE__->table('track');
2858   __PACKAGE__->add_columns(qw/trackid cd position title/);
2859   __PACKAGE__->set_primary_key('trackid');
2860   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2861   1;
2862
2863   # In your application
2864   my $rs = $schema->resultset('Artist')->search(
2865     { 'track.title' => 'Teardrop' },
2866     {
2867       join     => { cd => 'track' },
2868       order_by => 'artist.name',
2869     }
2870   );
2871
2872 You need to use the relationship (not the table) name in  conditions,
2873 because they are aliased as such. The current table is aliased as "me", so
2874 you need to use me.column_name in order to avoid ambiguity. For example:
2875
2876   # Get CDs from 1984 with a 'Foo' track
2877   my $rs = $schema->resultset('CD')->search(
2878     {
2879       'me.year' => 1984,
2880       'tracks.name' => 'Foo'
2881     },
2882     { join => 'tracks' }
2883   );
2884
2885 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2886 similarly for a third time). For e.g.
2887
2888   my $rs = $schema->resultset('Artist')->search({
2889     'cds.title'   => 'Down to Earth',
2890     'cds_2.title' => 'Popular',
2891   }, {
2892     join => [ qw/cds cds/ ],
2893   });
2894
2895 will return a set of all artists that have both a cd with title 'Down
2896 to Earth' and a cd with title 'Popular'.
2897
2898 If you want to fetch related objects from other tables as well, see C<prefetch>
2899 below.
2900
2901 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2902
2903 =head2 prefetch
2904
2905 =over 4
2906
2907 =item Value: ($rel_name | \@rel_names | \%rel_names)
2908
2909 =back
2910
2911 Contains one or more relationships that should be fetched along with
2912 the main query (when they are accessed afterwards the data will
2913 already be available, without extra queries to the database).  This is
2914 useful for when you know you will need the related objects, because it
2915 saves at least one query:
2916
2917   my $rs = $schema->resultset('Tag')->search(
2918     undef,
2919     {
2920       prefetch => {
2921         cd => 'artist'
2922       }
2923     }
2924   );
2925
2926 The initial search results in SQL like the following:
2927
2928   SELECT tag.*, cd.*, artist.* FROM tag
2929   JOIN cd ON tag.cd = cd.cdid
2930   JOIN artist ON cd.artist = artist.artistid
2931
2932 L<DBIx::Class> has no need to go back to the database when we access the
2933 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2934 case.
2935
2936 Simple prefetches will be joined automatically, so there is no need
2937 for a C<join> attribute in the above search.
2938
2939 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2940 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2941 with an accessor type of 'single' or 'filter'). A more complex example that
2942 prefetches an artists cds, the tracks on those cds, and the tags associted
2943 with that artist is given below (assuming many-to-many from artists to tags):
2944
2945  my $rs = $schema->resultset('Artist')->search(
2946    undef,
2947    {
2948      prefetch => [
2949        { cds => 'tracks' },
2950        { artist_tags => 'tags' }
2951      ]
2952    }
2953  );
2954
2955
2956 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2957 attributes will be ignored.
2958
2959 =head2 page
2960
2961 =over 4
2962
2963 =item Value: $page
2964
2965 =back
2966
2967 Makes the resultset paged and specifies the page to retrieve. Effectively
2968 identical to creating a non-pages resultset and then calling ->page($page)
2969 on it.
2970
2971 If L<rows> attribute is not specified it defualts to 10 rows per page.
2972
2973 When you have a paged resultset, L</count> will only return the number
2974 of rows in the page. To get the total, use the L</pager> and call
2975 C<total_entries> on it.
2976
2977 =head2 rows
2978
2979 =over 4
2980
2981 =item Value: $rows
2982
2983 =back
2984
2985 Specifes the maximum number of rows for direct retrieval or the number of
2986 rows per page if the page attribute or method is used.
2987
2988 =head2 offset
2989
2990 =over 4
2991
2992 =item Value: $offset
2993
2994 =back
2995
2996 Specifies the (zero-based) row number for the  first row to be returned, or the
2997 of the first row of the first page if paging is used.
2998
2999 =head2 group_by
3000
3001 =over 4
3002
3003 =item Value: \@columns
3004
3005 =back
3006
3007 A arrayref of columns to group by. Can include columns of joined tables.
3008
3009   group_by => [qw/ column1 column2 ... /]
3010
3011 =head2 having
3012
3013 =over 4
3014
3015 =item Value: $condition
3016
3017 =back
3018
3019 HAVING is a select statement attribute that is applied between GROUP BY and
3020 ORDER BY. It is applied to the after the grouping calculations have been
3021 done.
3022
3023   having => { 'count(employee)' => { '>=', 100 } }
3024
3025 =head2 distinct
3026
3027 =over 4
3028
3029 =item Value: (0 | 1)
3030
3031 =back
3032
3033 Set to 1 to group by all columns.
3034
3035 =head2 where
3036
3037 =over 4
3038
3039 Adds to the WHERE clause.
3040
3041   # only return rows WHERE deleted IS NULL for all searches
3042   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3043
3044 Can be overridden by passing C<{ where => undef }> as an attribute
3045 to a resulset.
3046
3047 =back
3048
3049 =head2 cache
3050
3051 Set to 1 to cache search results. This prevents extra SQL queries if you
3052 revisit rows in your ResultSet:
3053
3054   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3055
3056   while( my $artist = $resultset->next ) {
3057     ... do stuff ...
3058   }
3059
3060   $rs->first; # without cache, this would issue a query
3061
3062 By default, searches are not cached.
3063
3064 For more examples of using these attributes, see
3065 L<DBIx::Class::Manual::Cookbook>.
3066
3067 =head2 from
3068
3069 =over 4
3070
3071 =item Value: \@from_clause
3072
3073 =back
3074
3075 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3076 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3077 clauses.
3078
3079 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3080
3081 C<join> will usually do what you need and it is strongly recommended that you
3082 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3083 And we really do mean "cannot", not just tried and failed. Attempting to use
3084 this because you're having problems with C<join> is like trying to use x86
3085 ASM because you've got a syntax error in your C. Trust us on this.
3086
3087 Now, if you're still really, really sure you need to use this (and if you're
3088 not 100% sure, ask the mailing list first), here's an explanation of how this
3089 works.
3090
3091 The syntax is as follows -
3092
3093   [
3094     { <alias1> => <table1> },
3095     [
3096       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3097       [], # nested JOIN (optional)
3098       { <table1.column1> => <table2.column2>, ... (more conditions) },
3099     ],
3100     # More of the above [ ] may follow for additional joins
3101   ]
3102
3103   <table1> <alias1>
3104   JOIN
3105     <table2> <alias2>
3106     [JOIN ...]
3107   ON <table1.column1> = <table2.column2>
3108   <more joins may follow>
3109
3110 An easy way to follow the examples below is to remember the following:
3111
3112     Anything inside "[]" is a JOIN
3113     Anything inside "{}" is a condition for the enclosing JOIN
3114
3115 The following examples utilize a "person" table in a family tree application.
3116 In order to express parent->child relationships, this table is self-joined:
3117
3118     # Person->belongs_to('father' => 'Person');
3119     # Person->belongs_to('mother' => 'Person');
3120
3121 C<from> can be used to nest joins. Here we return all children with a father,
3122 then search against all mothers of those children:
3123
3124   $rs = $schema->resultset('Person')->search(
3125       undef,
3126       {
3127           alias => 'mother', # alias columns in accordance with "from"
3128           from => [
3129               { mother => 'person' },
3130               [
3131                   [
3132                       { child => 'person' },
3133                       [
3134                           { father => 'person' },
3135                           { 'father.person_id' => 'child.father_id' }
3136                       ]
3137                   ],
3138                   { 'mother.person_id' => 'child.mother_id' }
3139               ],
3140           ]
3141       },
3142   );
3143
3144   # Equivalent SQL:
3145   # SELECT mother.* FROM person mother
3146   # JOIN (
3147   #   person child
3148   #   JOIN person father
3149   #   ON ( father.person_id = child.father_id )
3150   # )
3151   # ON ( mother.person_id = child.mother_id )
3152
3153 The type of any join can be controlled manually. To search against only people
3154 with a father in the person table, we could explicitly use C<INNER JOIN>:
3155
3156     $rs = $schema->resultset('Person')->search(
3157         undef,
3158         {
3159             alias => 'child', # alias columns in accordance with "from"
3160             from => [
3161                 { child => 'person' },
3162                 [
3163                     { father => 'person', -join_type => 'inner' },
3164                     { 'father.id' => 'child.father_id' }
3165                 ],
3166             ]
3167         },
3168     );
3169
3170     # Equivalent SQL:
3171     # SELECT child.* FROM person child
3172     # INNER JOIN person father ON child.father_id = father.id
3173
3174 If you need to express really complex joins or you need a subselect, you
3175 can supply literal SQL to C<from> via a scalar reference. In this case
3176 the contents of the scalar will replace the table name asscoiated with the
3177 resultsource.
3178
3179 WARNING: This technique might very well not work as expected on chained
3180 searches - you have been warned.
3181
3182     # Assuming the Event resultsource is defined as:
3183
3184         MySchema::Event->add_columns (
3185             sequence => {
3186                 data_type => 'INT',
3187                 is_auto_increment => 1,
3188             },
3189             location => {
3190                 data_type => 'INT',
3191             },
3192             type => {
3193                 data_type => 'INT',
3194             },
3195         );
3196         MySchema::Event->set_primary_key ('sequence');
3197
3198     # This will get back the latest event for every location. The column
3199     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3200     # combo to limit the resultset
3201
3202     $rs = $schema->resultset('Event');
3203     $table = $rs->result_source->name;
3204     $latest = $rs->search (
3205         undef,
3206         { from => \ "
3207             (SELECT e1.* FROM $table e1
3208                 JOIN $table e2
3209                     ON e1.location = e2.location
3210                     AND e1.sequence < e2.sequence
3211                 WHERE e2.sequence is NULL
3212             ) me",
3213         },
3214     );
3215
3216     # Equivalent SQL (with the DBIC chunks added):
3217
3218     SELECT me.sequence, me.location, me.type FROM
3219        (SELECT e1.* FROM events e1
3220            JOIN events e2
3221                ON e1.location = e2.location
3222                AND e1.sequence < e2.sequence
3223            WHERE e2.sequence is NULL
3224        ) me;
3225
3226 =head2 for
3227
3228 =over 4
3229
3230 =item Value: ( 'update' | 'shared' )
3231
3232 =back
3233
3234 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3235 ... FOR SHARED.
3236
3237 =cut
3238
3239 1;