lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 665
 666   return $self->{cursor}
 667     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 668           $attrs->{where},$attrs);
 669 }
 670
 671 =head2 single
 672
 673 =over 4
 674
 675 =item Arguments: $cond?
 676
 677 =item Return Value: $row_object?
 678
 679 =back
 680
 681   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 682
 683 Inflates the first result without creating a cursor if the resultset has
 684 any records in it; if not returns nothing. Used by L</find> as a lean version of
 685 L</search>.
 686
 687 While this method can take an optional search condition (just like L</search>)
 688 being a fast-code-path it does not recognize search attributes. If you need to
 689 add extra joins or similar, call L</search> and then chain-call L</single> on the
 690 L<DBIx::Class::ResultSet> returned.
 691
 692 =over
 693
 694 =item B<Note>
 695
 696 As of 0.08100, this method enforces the assumption that the preceeding
 697 query returns only one row. If more than one row is returned, you will receive
 698 a warning:
 699
 700   Query returned more than one row
 701
 702 In this case, you should be using L</first> or L</find> instead, or if you really
 703 know what you are doing, use the L</rows> attribute to explicitly limit the size
 704 of the resultset.
 705
 706 =back
 707
 708 =cut
 709
 710 sub single {
 711   my ($self, $where) = @_;
 712   if(@_ > 2) {
 713       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 714   }
 715
 716   my $attrs = $self->_resolved_attrs_copy;
 717   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 718
 719   if ($where) {
 720     if (defined $attrs->{where}) {
 721       $attrs->{where} = {
 722         '-and' =>
 723             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 724                $where, delete $attrs->{where} ]
 725       };
 726     } else {
 727       $attrs->{where} = $where;
 728     }
 729   }
 730
 731 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 732 #  unless ($self->_is_unique_query($attrs->{where})) {
 733 #    carp "Query not guaranteed to return a single row"
 734 #      . "; please declare your unique constraints or use search instead";
 735 #  }
 736
 737   my @data = $self->result_source->storage->select_single(
 738     $attrs->{from}, $attrs->{select},
 739     $attrs->{where}, $attrs
 740   );
 741
 742   return (@data ? ($self->_construct_object(@data))[0] : undef);
 743 }
 744
 745 # _gen_virtual_order
 746 #
 747 # This is a horrble hack, but seems like the best we can do at this point
 748 # Some limit emulations (Top) require an ordered resultset in order to
 749 # function at all. So supply a PK order to be used if necessary
 750
 751 sub _gen_virtual_order {
 752   return [ shift->result_source->primary_columns ];
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp (
 874     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 875    .' Instead use ->search({ x => { -like => "y%" } })'
 876    .' (note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. Passing arguments is equivalent to
1149 C<< $rs->search ($cond, \%attrs)->count >>
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my @grouped_subq_attrs = qw/prefetch collapse distinct group_by having/;
1159   my @subq_attrs = ();
1160
1161   my $attrs = $self->_resolved_attrs;
1162   # if we are not paged - we are simply asking for a limit
1163   if (not $attrs->{page} and not $attrs->{software_limit}) {
1164     push @subq_attrs, qw/rows offset/;
1165   }
1166
1167   my $need_subq = $self->_has_attr (@subq_attrs);
1168   my $need_group_subq = $self->_has_attr (@grouped_subq_attrs);
1169
1170   return ($need_subq || $need_group_subq)
1171     ? $self->_count_subq ($need_group_subq)
1172     : $self->_count_simple
1173 }
1174
1175 sub _count_subq {
1176   my ($self, $add_group_by) = @_;
1177
1178   my $attrs = $self->_resolved_attrs_copy;
1179   my $rsrc = $self->result_source;
1180
1181   # copy for the subquery, we need to do some adjustments to it too
1182   my $sub_attrs = { %$attrs };
1183
1184   # these can not go in the subquery, and there is no point of ordering it
1185   delete $sub_attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns order_by/;
1186
1187   # if needed force a group_by and the same set of columns (most databases require this)
1188   if ($add_group_by) {
1189
1190     # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1191     # simply deleting group_by suffices, as the code below will re-fill it
1192     # Note: we check $attrs, as $sub_attrs has collapse deleted
1193     if (ref $attrs->{collapse} and keys %{$attrs->{collapse}} ) {
1194       delete $sub_attrs->{group_by};
1195     }
1196
1197     $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ];
1198   }
1199
1200   $attrs->{from} = [{
1201     count_subq => (ref $self)->new ($rsrc, $sub_attrs )->as_query
1202   }];
1203
1204   # the subquery replaces this
1205   delete $attrs->{$_} for qw/where bind prefetch collapse distinct group_by having having_bind/;
1206
1207   return $rsrc->storage->count ($rsrc, $attrs);
1208 }
1209
1210 sub _count_simple {
1211   my $self = shift;
1212
1213   my $rsrc = $self->result_source;
1214
1215   # the attrs supplied here are getting modified, do not reuse below
1216   my $count = $rsrc->storage->count ($rsrc, $self->_resolved_attrs_copy);
1217   return 0 unless $count;
1218
1219   # need to take offset from resolved attrs
1220   my $attrs = $self->_resolved_attrs;
1221
1222   $count -= $attrs->{offset} if $attrs->{offset};
1223   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1224   $count = 0 if ($count < 0);
1225   return $count;
1226 }
1227
1228 sub _bool {
1229   return 1;
1230 }
1231
1232 =head2 count_literal
1233
1234 =over 4
1235
1236 =item Arguments: $sql_fragment, @bind_values
1237
1238 =item Return Value: $count
1239
1240 =back
1241
1242 Counts the results in a literal query. Equivalent to calling L</search_literal>
1243 with the passed arguments, then L</count>.
1244
1245 =cut
1246
1247 sub count_literal { shift->search_literal(@_)->count; }
1248
1249 =head2 all
1250
1251 =over 4
1252
1253 =item Arguments: none
1254
1255 =item Return Value: @objects
1256
1257 =back
1258
1259 Returns all elements in the resultset. Called implicitly if the resultset
1260 is returned in list context.
1261
1262 =cut
1263
1264 sub all {
1265   my $self = shift;
1266   if(@_) {
1267       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1268   }
1269
1270   return @{ $self->get_cache } if $self->get_cache;
1271
1272   my @obj;
1273
1274   # TODO: don't call resolve here
1275   if (keys %{$self->_resolved_attrs->{collapse}}) {
1276 #  if ($self->{attrs}{prefetch}) {
1277       # Using $self->cursor->all is really just an optimisation.
1278       # If we're collapsing has_many prefetches it probably makes
1279       # very little difference, and this is cleaner than hacking
1280       # _construct_object to survive the approach
1281     my @row = $self->cursor->next;
1282     while (@row) {
1283       push(@obj, $self->_construct_object(@row));
1284       @row = (exists $self->{stashed_row}
1285                ? @{delete $self->{stashed_row}}
1286                : $self->cursor->next);
1287     }
1288   } else {
1289     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1290   }
1291
1292   $self->set_cache(\@obj) if $self->{attrs}{cache};
1293   return @obj;
1294 }
1295
1296 =head2 reset
1297
1298 =over 4
1299
1300 =item Arguments: none
1301
1302 =item Return Value: $self
1303
1304 =back
1305
1306 Resets the resultset's cursor, so you can iterate through the elements again.
1307
1308 =cut
1309
1310 sub reset {
1311   my ($self) = @_;
1312   delete $self->{_attrs} if exists $self->{_attrs};
1313   $self->{all_cache_position} = 0;
1314   $self->cursor->reset;
1315   return $self;
1316 }
1317
1318 =head2 first
1319
1320 =over 4
1321
1322 =item Arguments: none
1323
1324 =item Return Value: $object?
1325
1326 =back
1327
1328 Resets the resultset and returns an object for the first result (if the
1329 resultset returns anything).
1330
1331 =cut
1332
1333 sub first {
1334   return $_[0]->reset->next;
1335 }
1336
1337
1338 # _rs_update_delete
1339 #
1340 # Determines whether and what type of subquery is required for the $rs operation.
1341 # If grouping is necessary either supplies its own, or verifies the current one
1342 # After all is done delegates to the proper storage method.
1343
1344 sub _rs_update_delete {
1345   my ($self, $op, $values) = @_;
1346
1347   my $rsrc = $self->result_source;
1348
1349   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1350   my $needs_subq = $self->_has_attr (qw/row offset page/);
1351
1352   if ($needs_group_by_subq or $needs_subq) {
1353
1354     # make a new $rs selecting only the PKs (that's all we really need)
1355     my $attrs = $self->_resolved_attrs_copy;
1356
1357     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1358     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1359
1360     if ($needs_group_by_subq) {
1361       # make sure no group_by was supplied, or if there is one - make sure it matches
1362       # the columns compiled above perfectly. Anything else can not be sanely executed
1363       # on most databases so croak right then and there
1364
1365       if (my $g = $attrs->{group_by}) {
1366         my @current_group_by = map
1367           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1368           (ref $g eq 'ARRAY' ? @$g : $g );
1369
1370         if (
1371           join ("\x00", sort @current_group_by)
1372             ne
1373           join ("\x00", sort @{$attrs->{columns}} )
1374         ) {
1375           $self->throw_exception (
1376             "You have just attempted a $op operation on a resultset which does group_by"
1377             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1378             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1379             . ' kind of queries. Please retry the operation with a modified group_by or'
1380             . ' without using one at all.'
1381           );
1382         }
1383       }
1384       else {
1385         $attrs->{group_by} = $attrs->{columns};
1386       }
1387     }
1388
1389     my $subrs = (ref $self)->new($rsrc, $attrs);
1390
1391     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1392   }
1393   else {
1394     return $rsrc->storage->$op(
1395       $rsrc,
1396       $op eq 'update' ? $values : (),
1397       $self->_cond_for_update_delete,
1398     );
1399   }
1400 }
1401
1402
1403 # _cond_for_update_delete
1404 #
1405 # update/delete require the condition to be modified to handle
1406 # the differing SQL syntax available.  This transforms the $self->{cond}
1407 # appropriately, returning the new condition.
1408
1409 sub _cond_for_update_delete {
1410   my ($self, $full_cond) = @_;
1411   my $cond = {};
1412
1413   $full_cond ||= $self->{cond};
1414   # No-op. No condition, we're updating/deleting everything
1415   return $cond unless ref $full_cond;
1416
1417   if (ref $full_cond eq 'ARRAY') {
1418     $cond = [
1419       map {
1420         my %hash;
1421         foreach my $key (keys %{$_}) {
1422           $key =~ /([^.]+)$/;
1423           $hash{$1} = $_->{$key};
1424         }
1425         \%hash;
1426       } @{$full_cond}
1427     ];
1428   }
1429   elsif (ref $full_cond eq 'HASH') {
1430     if ((keys %{$full_cond})[0] eq '-and') {
1431       $cond->{-and} = [];
1432       my @cond = @{$full_cond->{-and}};
1433        for (my $i = 0; $i < @cond; $i++) {
1434         my $entry = $cond[$i];
1435         my $hash;
1436         if (ref $entry eq 'HASH') {
1437           $hash = $self->_cond_for_update_delete($entry);
1438         }
1439         else {
1440           $entry =~ /([^.]+)$/;
1441           $hash->{$1} = $cond[++$i];
1442         }
1443         push @{$cond->{-and}}, $hash;
1444       }
1445     }
1446     else {
1447       foreach my $key (keys %{$full_cond}) {
1448         $key =~ /([^.]+)$/;
1449         $cond->{$1} = $full_cond->{$key};
1450       }
1451     }
1452   }
1453   else {
1454     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1455   }
1456
1457   return $cond;
1458 }
1459
1460
1461 =head2 update
1462
1463 =over 4
1464
1465 =item Arguments: \%values
1466
1467 =item Return Value: $storage_rv
1468
1469 =back
1470
1471 Sets the specified columns in the resultset to the supplied values in a
1472 single query. Return value will be true if the update succeeded or false
1473 if no records were updated; exact type of success value is storage-dependent.
1474
1475 =cut
1476
1477 sub update {
1478   my ($self, $values) = @_;
1479   $self->throw_exception('Values for update must be a hash')
1480     unless ref $values eq 'HASH';
1481
1482   return $self->_rs_update_delete ('update', $values);
1483 }
1484
1485 =head2 update_all
1486
1487 =over 4
1488
1489 =item Arguments: \%values
1490
1491 =item Return Value: 1
1492
1493 =back
1494
1495 Fetches all objects and updates them one at a time. Note that C<update_all>
1496 will run DBIC cascade triggers, while L</update> will not.
1497
1498 =cut
1499
1500 sub update_all {
1501   my ($self, $values) = @_;
1502   $self->throw_exception('Values for update_all must be a hash')
1503     unless ref $values eq 'HASH';
1504   foreach my $obj ($self->all) {
1505     $obj->set_columns($values)->update;
1506   }
1507   return 1;
1508 }
1509
1510 =head2 delete
1511
1512 =over 4
1513
1514 =item Arguments: none
1515
1516 =item Return Value: $storage_rv
1517
1518 =back
1519
1520 Deletes the contents of the resultset from its result source. Note that this
1521 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1522 to run. See also L<DBIx::Class::Row/delete>.
1523
1524 Return value will be the amount of rows deleted; exact type of return value
1525 is storage-dependent.
1526
1527 =cut
1528
1529 sub delete {
1530   my $self = shift;
1531   $self->throw_exception('delete does not accept any arguments')
1532     if @_;
1533
1534   return $self->_rs_update_delete ('delete');
1535 }
1536
1537 =head2 delete_all
1538
1539 =over 4
1540
1541 =item Arguments: none
1542
1543 =item Return Value: 1
1544
1545 =back
1546
1547 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1548 will run DBIC cascade triggers, while L</delete> will not.
1549
1550 =cut
1551
1552 sub delete_all {
1553   my $self = shift;
1554   $self->throw_exception('delete_all does not accept any arguments')
1555     if @_;
1556
1557   $_->delete for $self->all;
1558   return 1;
1559 }
1560
1561 =head2 populate
1562
1563 =over 4
1564
1565 =item Arguments: \@data;
1566
1567 =back
1568
1569 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1570 For the arrayref of hashrefs style each hashref should be a structure suitable
1571 forsubmitting to a $resultset->create(...) method.
1572
1573 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1574 to insert the data, as this is a faster method.
1575
1576 Otherwise, each set of data is inserted into the database using
1577 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1578 objects is returned.
1579
1580 Example:  Assuming an Artist Class that has many CDs Classes relating:
1581
1582   my $Artist_rs = $schema->resultset("Artist");
1583
1584   ## Void Context Example
1585   $Artist_rs->populate([
1586      { artistid => 4, name => 'Manufactured Crap', cds => [
1587         { title => 'My First CD', year => 2006 },
1588         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1589       ],
1590      },
1591      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1592         { title => 'My parents sold me to a record company' ,year => 2005 },
1593         { title => 'Why Am I So Ugly?', year => 2006 },
1594         { title => 'I Got Surgery and am now Popular', year => 2007 }
1595       ],
1596      },
1597   ]);
1598
1599   ## Array Context Example
1600   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1601     { name => "Artist One"},
1602     { name => "Artist Two"},
1603     { name => "Artist Three", cds=> [
1604     { title => "First CD", year => 2007},
1605     { title => "Second CD", year => 2008},
1606   ]}
1607   ]);
1608
1609   print $ArtistOne->name; ## response is 'Artist One'
1610   print $ArtistThree->cds->count ## reponse is '2'
1611
1612 For the arrayref of arrayrefs style,  the first element should be a list of the
1613 fieldsnames to which the remaining elements are rows being inserted.  For
1614 example:
1615
1616   $Arstist_rs->populate([
1617     [qw/artistid name/],
1618     [100, 'A Formally Unknown Singer'],
1619     [101, 'A singer that jumped the shark two albums ago'],
1620     [102, 'An actually cool singer.'],
1621   ]);
1622
1623 Please note an important effect on your data when choosing between void and
1624 wantarray context. Since void context goes straight to C<insert_bulk> in
1625 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1626 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1627 create primary keys for you, you will find that your PKs are empty.  In this
1628 case you will have to use the wantarray context in order to create those
1629 values.
1630
1631 =cut
1632
1633 sub populate {
1634   my $self = shift @_;
1635   my $data = ref $_[0][0] eq 'HASH'
1636     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1637     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1638
1639   if(defined wantarray) {
1640     my @created;
1641     foreach my $item (@$data) {
1642       push(@created, $self->create($item));
1643     }
1644     return @created;
1645   } else {
1646     my ($first, @rest) = @$data;
1647
1648     my @names = grep {!ref $first->{$_}} keys %$first;
1649     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1650     my @pks = $self->result_source->primary_columns;
1651
1652     ## do the belongs_to relationships
1653     foreach my $index (0..$#$data) {
1654
1655       # delegate to create() for any dataset without primary keys with specified relationships
1656       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1657         for my $r (@rels) {
1658           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1659             my @ret = $self->populate($data);
1660             return;
1661           }
1662         }
1663       }
1664
1665       foreach my $rel (@rels) {
1666         next unless ref $data->[$index]->{$rel} eq "HASH";
1667         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1668         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1669         my $related = $result->result_source->_resolve_condition(
1670           $result->result_source->relationship_info($reverse)->{cond},
1671           $self,
1672           $result,
1673         );
1674
1675         delete $data->[$index]->{$rel};
1676         $data->[$index] = {%{$data->[$index]}, %$related};
1677
1678         push @names, keys %$related if $index == 0;
1679       }
1680     }
1681
1682     ## do bulk insert on current row
1683     my @values = map { [ @$_{@names} ] } @$data;
1684
1685     $self->result_source->storage->insert_bulk(
1686       $self->result_source,
1687       \@names,
1688       \@values,
1689     );
1690
1691     ## do the has_many relationships
1692     foreach my $item (@$data) {
1693
1694       foreach my $rel (@rels) {
1695         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1696
1697         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1698      || $self->throw_exception('Cannot find the relating object.');
1699
1700         my $child = $parent->$rel;
1701
1702         my $related = $child->result_source->_resolve_condition(
1703           $parent->result_source->relationship_info($rel)->{cond},
1704           $child,
1705           $parent,
1706         );
1707
1708         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1709         my @populate = map { {%$_, %$related} } @rows_to_add;
1710
1711         $child->populate( \@populate );
1712       }
1713     }
1714   }
1715 }
1716
1717 =head2 _normalize_populate_args ($args)
1718
1719 Private method used by L</populate> to normalize its incoming arguments.  Factored
1720 out in case you want to subclass and accept new argument structures to the
1721 L</populate> method.
1722
1723 =cut
1724
1725 sub _normalize_populate_args {
1726   my ($self, $data) = @_;
1727   my @names = @{shift(@$data)};
1728   my @results_to_create;
1729   foreach my $datum (@$data) {
1730     my %result_to_create;
1731     foreach my $index (0..$#names) {
1732       $result_to_create{$names[$index]} = $$datum[$index];
1733     }
1734     push @results_to_create, \%result_to_create;
1735   }
1736   return \@results_to_create;
1737 }
1738
1739 =head2 pager
1740
1741 =over 4
1742
1743 =item Arguments: none
1744
1745 =item Return Value: $pager
1746
1747 =back
1748
1749 Return Value a L<Data::Page> object for the current resultset. Only makes
1750 sense for queries with a C<page> attribute.
1751
1752 To get the full count of entries for a paged resultset, call
1753 C<total_entries> on the L<Data::Page> object.
1754
1755 =cut
1756
1757 sub pager {
1758   my ($self) = @_;
1759
1760   return $self->{pager} if $self->{pager};
1761
1762   my $attrs = $self->{attrs};
1763   $self->throw_exception("Can't create pager for non-paged rs")
1764     unless $self->{attrs}{page};
1765   $attrs->{rows} ||= 10;
1766
1767   # throw away the paging flags and re-run the count (possibly
1768   # with a subselect) to get the real total count
1769   my $count_attrs = { %$attrs };
1770   delete $count_attrs->{$_} for qw/rows offset page pager/;
1771   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1772
1773   return $self->{pager} = Data::Page->new(
1774     $total_count,
1775     $attrs->{rows},
1776     $self->{attrs}{page}
1777   );
1778 }
1779
1780 =head2 page
1781
1782 =over 4
1783
1784 =item Arguments: $page_number
1785
1786 =item Return Value: $rs
1787
1788 =back
1789
1790 Returns a resultset for the $page_number page of the resultset on which page
1791 is called, where each page contains a number of rows equal to the 'rows'
1792 attribute set on the resultset (10 by default).
1793
1794 =cut
1795
1796 sub page {
1797   my ($self, $page) = @_;
1798   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1799 }
1800
1801 =head2 new_result
1802
1803 =over 4
1804
1805 =item Arguments: \%vals
1806
1807 =item Return Value: $rowobject
1808
1809 =back
1810
1811 Creates a new row object in the resultset's result class and returns
1812 it. The row is not inserted into the database at this point, call
1813 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1814 will tell you whether the row object has been inserted or not.
1815
1816 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1817
1818 =cut
1819
1820 sub new_result {
1821   my ($self, $values) = @_;
1822   $self->throw_exception( "new_result needs a hash" )
1823     unless (ref $values eq 'HASH');
1824
1825   my %new;
1826   my $alias = $self->{attrs}{alias};
1827
1828   if (
1829     defined $self->{cond}
1830     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1831   ) {
1832     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1833     $new{-from_resultset} = [ keys %new ] if keys %new;
1834   } else {
1835     $self->throw_exception(
1836       "Can't abstract implicit construct, condition not a hash"
1837     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1838
1839     my $collapsed_cond = (
1840       $self->{cond}
1841         ? $self->_collapse_cond($self->{cond})
1842         : {}
1843     );
1844
1845     # precendence must be given to passed values over values inherited from
1846     # the cond, so the order here is important.
1847     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1848     while( my($col,$value) = each %implied ){
1849       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1850         $new{$col} = $value->{'='};
1851         next;
1852       }
1853       $new{$col} = $value if $self->_is_deterministic_value($value);
1854     }
1855   }
1856
1857   %new = (
1858     %new,
1859     %{ $self->_remove_alias($values, $alias) },
1860     -source_handle => $self->_source_handle,
1861     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1862   );
1863
1864   return $self->result_class->new(\%new);
1865 }
1866
1867 # _is_deterministic_value
1868 #
1869 # Make an effor to strip non-deterministic values from the condition,
1870 # to make sure new_result chokes less
1871
1872 sub _is_deterministic_value {
1873   my $self = shift;
1874   my $value = shift;
1875   my $ref_type = ref $value;
1876   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1877   return 1 if Scalar::Util::blessed($value);
1878   return 0;
1879 }
1880
1881 # _has_attr
1882 #
1883 # determines if the resultset defines at least one
1884 # of the attributes supplied
1885 #
1886 # used to determine if a subquery is neccessary
1887
1888 sub _has_attr {
1889   my ($self, @attr_names) = @_;
1890
1891   my $attrs = $self->_resolved_attrs;
1892
1893   my $join_check_req;
1894
1895   for my $n (@attr_names) {
1896     ++$join_check_req if $n =~ /join/;
1897
1898     my $attr =  $attrs->{$n};
1899
1900     next if not defined $attr;
1901
1902     if (ref $attr eq 'HASH') {
1903       return 1 if keys %$attr;
1904     }
1905     elsif (ref $attr eq 'ARRAY') {
1906       return 1 if @$attr;
1907     }
1908     else {
1909       return 1 if $attr;
1910     }
1911   }
1912
1913   # a join can be expressed as a multi-level from
1914   return 1 if (
1915     $join_check_req
1916       and
1917     ref $attrs->{from} eq 'ARRAY'
1918       and
1919     @{$attrs->{from}} > 1
1920   );
1921
1922   return 0;
1923 }
1924
1925 # _collapse_cond
1926 #
1927 # Recursively collapse the condition.
1928
1929 sub _collapse_cond {
1930   my ($self, $cond, $collapsed) = @_;
1931
1932   $collapsed ||= {};
1933
1934   if (ref $cond eq 'ARRAY') {
1935     foreach my $subcond (@$cond) {
1936       next unless ref $subcond;  # -or
1937       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1938     }
1939   }
1940   elsif (ref $cond eq 'HASH') {
1941     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1942       foreach my $subcond (@{$cond->{-and}}) {
1943         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1944       }
1945     }
1946     else {
1947       foreach my $col (keys %$cond) {
1948         my $value = $cond->{$col};
1949         $collapsed->{$col} = $value;
1950       }
1951     }
1952   }
1953
1954   return $collapsed;
1955 }
1956
1957 # _remove_alias
1958 #
1959 # Remove the specified alias from the specified query hash. A copy is made so
1960 # the original query is not modified.
1961
1962 sub _remove_alias {
1963   my ($self, $query, $alias) = @_;
1964
1965   my %orig = %{ $query || {} };
1966   my %unaliased;
1967
1968   foreach my $key (keys %orig) {
1969     if ($key !~ /\./) {
1970       $unaliased{$key} = $orig{$key};
1971       next;
1972     }
1973     $unaliased{$1} = $orig{$key}
1974       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1975   }
1976
1977   return \%unaliased;
1978 }
1979
1980 =head2 as_query (EXPERIMENTAL)
1981
1982 =over 4
1983
1984 =item Arguments: none
1985
1986 =item Return Value: \[ $sql, @bind ]
1987
1988 =back
1989
1990 Returns the SQL query and bind vars associated with the invocant.
1991
1992 This is generally used as the RHS for a subquery.
1993
1994 B<NOTE>: This feature is still experimental.
1995
1996 =cut
1997
1998 sub as_query { return shift->cursor->as_query(@_) }
1999
2000 =head2 find_or_new
2001
2002 =over 4
2003
2004 =item Arguments: \%vals, \%attrs?
2005
2006 =item Return Value: $rowobject
2007
2008 =back
2009
2010   my $artist = $schema->resultset('Artist')->find_or_new(
2011     { artist => 'fred' }, { key => 'artists' });
2012
2013   $cd->cd_to_producer->find_or_new({ producer => $producer },
2014                                    { key => 'primary });
2015
2016 Find an existing record from this resultset, based on its primary
2017 key, or a unique constraint. If none exists, instantiate a new result
2018 object and return it. The object will not be saved into your storage
2019 until you call L<DBIx::Class::Row/insert> on it.
2020
2021 You most likely want this method when looking for existing rows using
2022 a unique constraint that is not the primary key, or looking for
2023 related rows.
2024
2025 If you want objects to be saved immediately, use L</find_or_create> instead.
2026
2027 B<Note>: C<find_or_new> is probably not what you want when creating a
2028 new row in a table that uses primary keys supplied by the
2029 database. Passing in a primary key column with a value of I<undef>
2030 will cause L</find> to attempt to search for a row with a value of
2031 I<NULL>.
2032
2033 =cut
2034
2035 sub find_or_new {
2036   my $self     = shift;
2037   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2038   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2039   my $exists   = $self->find($hash, $attrs);
2040   return defined $exists ? $exists : $self->new_result($hash);
2041 }
2042
2043 =head2 create
2044
2045 =over 4
2046
2047 =item Arguments: \%vals
2048
2049 =item Return Value: a L<DBIx::Class::Row> $object
2050
2051 =back
2052
2053 Attempt to create a single new row or a row with multiple related rows
2054 in the table represented by the resultset (and related tables). This
2055 will not check for duplicate rows before inserting, use
2056 L</find_or_create> to do that.
2057
2058 To create one row for this resultset, pass a hashref of key/value
2059 pairs representing the columns of the table and the values you wish to
2060 store. If the appropriate relationships are set up, foreign key fields
2061 can also be passed an object representing the foreign row, and the
2062 value will be set to its primary key.
2063
2064 To create related objects, pass a hashref for the value if the related
2065 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2066 and use the name of the relationship as the key. (NOT the name of the field,
2067 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2068 of hashrefs containing the data for each of the rows to create in the foreign
2069 tables, again using the relationship name as the key.
2070
2071 Instead of hashrefs of plain related data (key/value pairs), you may
2072 also pass new or inserted objects. New objects (not inserted yet, see
2073 L</new>), will be inserted into their appropriate tables.
2074
2075 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2076
2077 Example of creating a new row.
2078
2079   $person_rs->create({
2080     name=>"Some Person",
2081     email=>"somebody@someplace.com"
2082   });
2083
2084 Example of creating a new row and also creating rows in a related C<has_many>
2085 or C<has_one> resultset.  Note Arrayref.
2086
2087   $artist_rs->create(
2088      { artistid => 4, name => 'Manufactured Crap', cds => [
2089         { title => 'My First CD', year => 2006 },
2090         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2091       ],
2092      },
2093   );
2094
2095 Example of creating a new row and also creating a row in a related
2096 C<belongs_to>resultset. Note Hashref.
2097
2098   $cd_rs->create({
2099     title=>"Music for Silly Walks",
2100     year=>2000,
2101     artist => {
2102       name=>"Silly Musician",
2103     }
2104   });
2105
2106 =cut
2107
2108 sub create {
2109   my ($self, $attrs) = @_;
2110   $self->throw_exception( "create needs a hashref" )
2111     unless ref $attrs eq 'HASH';
2112   return $self->new_result($attrs)->insert;
2113 }
2114
2115 =head2 find_or_create
2116
2117 =over 4
2118
2119 =item Arguments: \%vals, \%attrs?
2120
2121 =item Return Value: $rowobject
2122
2123 =back
2124
2125   $cd->cd_to_producer->find_or_create({ producer => $producer },
2126                                       { key => 'primary });
2127
2128 Tries to find a record based on its primary key or unique constraints; if none
2129 is found, creates one and returns that instead.
2130
2131   my $cd = $schema->resultset('CD')->find_or_create({
2132     cdid   => 5,
2133     artist => 'Massive Attack',
2134     title  => 'Mezzanine',
2135     year   => 2005,
2136   });
2137
2138 Also takes an optional C<key> attribute, to search by a specific key or unique
2139 constraint. For example:
2140
2141   my $cd = $schema->resultset('CD')->find_or_create(
2142     {
2143       artist => 'Massive Attack',
2144       title  => 'Mezzanine',
2145     },
2146     { key => 'cd_artist_title' }
2147   );
2148
2149 B<Note>: Because find_or_create() reads from the database and then
2150 possibly inserts based on the result, this method is subject to a race
2151 condition. Another process could create a record in the table after
2152 the find has completed and before the create has started. To avoid
2153 this problem, use find_or_create() inside a transaction.
2154
2155 B<Note>: C<find_or_create> is probably not what you want when creating
2156 a new row in a table that uses primary keys supplied by the
2157 database. Passing in a primary key column with a value of I<undef>
2158 will cause L</find> to attempt to search for a row with a value of
2159 I<NULL>.
2160
2161 See also L</find> and L</update_or_create>. For information on how to declare
2162 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2163
2164 =cut
2165
2166 sub find_or_create {
2167   my $self     = shift;
2168   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2169   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2170   my $exists   = $self->find($hash, $attrs);
2171   return defined $exists ? $exists : $self->create($hash);
2172 }
2173
2174 =head2 update_or_create
2175
2176 =over 4
2177
2178 =item Arguments: \%col_values, { key => $unique_constraint }?
2179
2180 =item Return Value: $rowobject
2181
2182 =back
2183
2184   $resultset->update_or_create({ col => $val, ... });
2185
2186 First, searches for an existing row matching one of the unique constraints
2187 (including the primary key) on the source of this resultset. If a row is
2188 found, updates it with the other given column values. Otherwise, creates a new
2189 row.
2190
2191 Takes an optional C<key> attribute to search on a specific unique constraint.
2192 For example:
2193
2194   # In your application
2195   my $cd = $schema->resultset('CD')->update_or_create(
2196     {
2197       artist => 'Massive Attack',
2198       title  => 'Mezzanine',
2199       year   => 1998,
2200     },
2201     { key => 'cd_artist_title' }
2202   );
2203
2204   $cd->cd_to_producer->update_or_create({
2205     producer => $producer,
2206     name => 'harry',
2207   }, {
2208     key => 'primary,
2209   });
2210
2211
2212 If no C<key> is specified, it searches on all unique constraints defined on the
2213 source, including the primary key.
2214
2215 If the C<key> is specified as C<primary>, it searches only on the primary key.
2216
2217 See also L</find> and L</find_or_create>. For information on how to declare
2218 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2219
2220 B<Note>: C<update_or_create> is probably not what you want when
2221 looking for a row in a table that uses primary keys supplied by the
2222 database, unless you actually have a key value. Passing in a primary
2223 key column with a value of I<undef> will cause L</find> to attempt to
2224 search for a row with a value of I<NULL>.
2225
2226 =cut
2227
2228 sub update_or_create {
2229   my $self = shift;
2230   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2231   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2232
2233   my $row = $self->find($cond, $attrs);
2234   if (defined $row) {
2235     $row->update($cond);
2236     return $row;
2237   }
2238
2239   return $self->create($cond);
2240 }
2241
2242 =head2 update_or_new
2243
2244 =over 4
2245
2246 =item Arguments: \%col_values, { key => $unique_constraint }?
2247
2248 =item Return Value: $rowobject
2249
2250 =back
2251
2252   $resultset->update_or_new({ col => $val, ... });
2253
2254 First, searches for an existing row matching one of the unique constraints
2255 (including the primary key) on the source of this resultset. If a row is
2256 found, updates it with the other given column values. Otherwise, instantiate
2257 a new result object and return it. The object will not be saved into your storage
2258 until you call L<DBIx::Class::Row/insert> on it.
2259
2260 Takes an optional C<key> attribute to search on a specific unique constraint.
2261 For example:
2262
2263   # In your application
2264   my $cd = $schema->resultset('CD')->update_or_new(
2265     {
2266       artist => 'Massive Attack',
2267       title  => 'Mezzanine',
2268       year   => 1998,
2269     },
2270     { key => 'cd_artist_title' }
2271   );
2272
2273   if ($cd->in_storage) {
2274       # the cd was updated
2275   }
2276   else {
2277       # the cd is not yet in the database, let's insert it
2278       $cd->insert;
2279   }
2280
2281 See also L</find>, L</find_or_create> and L<find_or_new>.
2282
2283 =cut
2284
2285 sub update_or_new {
2286     my $self  = shift;
2287     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2288     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2289
2290     my $row = $self->find( $cond, $attrs );
2291     if ( defined $row ) {
2292         $row->update($cond);
2293         return $row;
2294     }
2295
2296     return $self->new_result($cond);
2297 }
2298
2299 =head2 get_cache
2300
2301 =over 4
2302
2303 =item Arguments: none
2304
2305 =item Return Value: \@cache_objects?
2306
2307 =back
2308
2309 Gets the contents of the cache for the resultset, if the cache is set.
2310
2311 The cache is populated either by using the L</prefetch> attribute to
2312 L</search> or by calling L</set_cache>.
2313
2314 =cut
2315
2316 sub get_cache {
2317   shift->{all_cache};
2318 }
2319
2320 =head2 set_cache
2321
2322 =over 4
2323
2324 =item Arguments: \@cache_objects
2325
2326 =item Return Value: \@cache_objects
2327
2328 =back
2329
2330 Sets the contents of the cache for the resultset. Expects an arrayref
2331 of objects of the same class as those produced by the resultset. Note that
2332 if the cache is set the resultset will return the cached objects rather
2333 than re-querying the database even if the cache attr is not set.
2334
2335 The contents of the cache can also be populated by using the
2336 L</prefetch> attribute to L</search>.
2337
2338 =cut
2339
2340 sub set_cache {
2341   my ( $self, $data ) = @_;
2342   $self->throw_exception("set_cache requires an arrayref")
2343       if defined($data) && (ref $data ne 'ARRAY');
2344   $self->{all_cache} = $data;
2345 }
2346
2347 =head2 clear_cache
2348
2349 =over 4
2350
2351 =item Arguments: none
2352
2353 =item Return Value: []
2354
2355 =back
2356
2357 Clears the cache for the resultset.
2358
2359 =cut
2360
2361 sub clear_cache {
2362   shift->set_cache(undef);
2363 }
2364
2365 =head2 related_resultset
2366
2367 =over 4
2368
2369 =item Arguments: $relationship_name
2370
2371 =item Return Value: $resultset
2372
2373 =back
2374
2375 Returns a related resultset for the supplied relationship name.
2376
2377   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2378
2379 =cut
2380
2381 sub related_resultset {
2382   my ($self, $rel) = @_;
2383
2384   $self->{related_resultsets} ||= {};
2385   return $self->{related_resultsets}{$rel} ||= do {
2386     my $rel_obj = $self->result_source->relationship_info($rel);
2387
2388     $self->throw_exception(
2389       "search_related: result source '" . $self->result_source->source_name .
2390         "' has no such relationship $rel")
2391       unless $rel_obj;
2392
2393     my ($from,$seen) = $self->_resolve_from($rel);
2394
2395     my $join_count = $seen->{$rel};
2396     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2397
2398     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2399     my %attrs = %{$self->{attrs}||{}};
2400     delete @attrs{qw(result_class alias)};
2401
2402     my $new_cache;
2403
2404     if (my $cache = $self->get_cache) {
2405       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2406         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2407                         @$cache ];
2408       }
2409     }
2410
2411     my $rel_source = $self->result_source->related_source($rel);
2412
2413     my $new = do {
2414
2415       # The reason we do this now instead of passing the alias to the
2416       # search_rs below is that if you wrap/overload resultset on the
2417       # source you need to know what alias it's -going- to have for things
2418       # to work sanely (e.g. RestrictWithObject wants to be able to add
2419       # extra query restrictions, and these may need to be $alias.)
2420
2421       my $attrs = $rel_source->resultset_attributes;
2422       local $attrs->{alias} = $alias;
2423
2424       $rel_source->resultset
2425                  ->search_rs(
2426                      undef, {
2427                        %attrs,
2428                        join => undef,
2429                        prefetch => undef,
2430                        select => undef,
2431                        as => undef,
2432                        where => $self->{cond},
2433                        seen_join => $seen,
2434                        from => $from,
2435                    });
2436     };
2437     $new->set_cache($new_cache) if $new_cache;
2438     $new;
2439   };
2440 }
2441
2442 =head2 current_source_alias
2443
2444 =over 4
2445
2446 =item Arguments: none
2447
2448 =item Return Value: $source_alias
2449
2450 =back
2451
2452 Returns the current table alias for the result source this resultset is built
2453 on, that will be used in the SQL query. Usually it is C<me>.
2454
2455 Currently the source alias that refers to the result set returned by a
2456 L</search>/L</find> family method depends on how you got to the resultset: it's
2457 C<me> by default, but eg. L</search_related> aliases it to the related result
2458 source name (and keeps C<me> referring to the original result set). The long
2459 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2460 (and make this method unnecessary).
2461
2462 Thus it's currently necessary to use this method in predefined queries (see
2463 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2464 source alias of the current result set:
2465
2466   # in a result set class
2467   sub modified_by {
2468     my ($self, $user) = @_;
2469
2470     my $me = $self->current_source_alias;
2471
2472     return $self->search(
2473       "$me.modified" => $user->id,
2474     );
2475   }
2476
2477 =cut
2478
2479 sub current_source_alias {
2480   my ($self) = @_;
2481
2482   return ($self->{attrs} || {})->{alias} || 'me';
2483 }
2484
2485 # This code is called by search_related, and makes sure there
2486 # is clear separation between the joins before, during, and
2487 # after the relationship. This information is needed later
2488 # in order to properly resolve prefetch aliases (any alias
2489 # with a relation_chain_depth less than the depth of the
2490 # current prefetch is not considered)
2491 sub _resolve_from {
2492   my ($self, $extra_join) = @_;
2493   my $source = $self->result_source;
2494   my $attrs = $self->{attrs};
2495
2496   my $from = $attrs->{from}
2497     || [ { $attrs->{alias} => $source->from } ];
2498
2499   my $seen = { %{$attrs->{seen_join}||{}} };
2500
2501   # we need to take the prefetch the attrs into account before we
2502   # ->_resolve_join as otherwise they get lost - captainL
2503   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2504
2505   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2506
2507   ++$seen->{-relation_chain_depth};
2508
2509   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2510
2511   ++$seen->{-relation_chain_depth};
2512
2513   return ($from,$seen);
2514 }
2515
2516 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2517 sub _resolved_attrs_copy {
2518   my $self = shift;
2519   return { %{$self->_resolved_attrs (@_)} };
2520 }
2521
2522 sub _resolved_attrs {
2523   my $self = shift;
2524   return $self->{_attrs} if $self->{_attrs};
2525
2526   my $attrs  = { %{ $self->{attrs} || {} } };
2527   my $source = $self->result_source;
2528   my $alias  = $attrs->{alias};
2529
2530   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2531   my @colbits;
2532
2533   # build columns (as long as select isn't set) into a set of as/select hashes
2534   unless ( $attrs->{select} ) {
2535       @colbits = map {
2536           ( ref($_) eq 'HASH' )
2537               ? $_
2538               : {
2539                   (
2540                     /^\Q${alias}.\E(.+)$/
2541                       ? "$1"
2542                       : "$_"
2543                   )
2544                 =>
2545                   (
2546                     /\./
2547                       ? "$_"
2548                       : "${alias}.$_"
2549                   )
2550             }
2551       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2552   }
2553   # add the additional columns on
2554   foreach ( 'include_columns', '+columns' ) {
2555       push @colbits, map {
2556           ( ref($_) eq 'HASH' )
2557             ? $_
2558             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2559       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2560   }
2561
2562   # start with initial select items
2563   if ( $attrs->{select} ) {
2564     $attrs->{select} =
2565         ( ref $attrs->{select} eq 'ARRAY' )
2566       ? [ @{ $attrs->{select} } ]
2567       : [ $attrs->{select} ];
2568     $attrs->{as} = (
2569       $attrs->{as}
2570       ? (
2571         ref $attrs->{as} eq 'ARRAY'
2572         ? [ @{ $attrs->{as} } ]
2573         : [ $attrs->{as} ]
2574         )
2575       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2576     );
2577   }
2578   else {
2579
2580     # otherwise we intialise select & as to empty
2581     $attrs->{select} = [];
2582     $attrs->{as}     = [];
2583   }
2584
2585   # now add colbits to select/as
2586   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2587   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2588
2589   my $adds;
2590   if ( $adds = delete $attrs->{'+select'} ) {
2591     $adds = [$adds] unless ref $adds eq 'ARRAY';
2592     push(
2593       @{ $attrs->{select} },
2594       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2595     );
2596   }
2597   if ( $adds = delete $attrs->{'+as'} ) {
2598     $adds = [$adds] unless ref $adds eq 'ARRAY';
2599     push( @{ $attrs->{as} }, @$adds );
2600   }
2601
2602   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2603
2604   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2605     my $join = delete $attrs->{join} || {};
2606
2607     if ( defined $attrs->{prefetch} ) {
2608       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2609
2610     }
2611
2612     $attrs->{from} =    # have to copy here to avoid corrupting the original
2613       [
2614       @{ $attrs->{from} },
2615       $source->_resolve_join(
2616         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2617       )
2618       ];
2619
2620   }
2621
2622   if ( $attrs->{order_by} ) {
2623     $attrs->{order_by} = (
2624       ref( $attrs->{order_by} ) eq 'ARRAY'
2625       ? [ @{ $attrs->{order_by} } ]
2626       : [ $attrs->{order_by} ]
2627     );
2628   }
2629   else {
2630     $attrs->{order_by} = [];
2631   }
2632
2633   my $collapse = $attrs->{collapse} || {};
2634   if ( my $prefetch = delete $attrs->{prefetch} ) {
2635     $prefetch = $self->_merge_attr( {}, $prefetch );
2636     my @pre_order;
2637     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2638
2639       # bring joins back to level of current class
2640       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2641       my @prefetch =
2642         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2643       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2644       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2645     }
2646     push( @{ $attrs->{order_by} }, @pre_order );
2647   }
2648
2649   if (delete $attrs->{distinct}) {
2650     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2651   }
2652
2653   $attrs->{collapse} = $collapse;
2654
2655   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2656     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2657   }
2658
2659   return $self->{_attrs} = $attrs;
2660 }
2661
2662 sub _joinpath_aliases {
2663   my ($self, $fromspec, $seen) = @_;
2664
2665   my $paths = {};
2666   return $paths unless ref $fromspec eq 'ARRAY';
2667
2668   for my $j (@$fromspec) {
2669
2670     next if ref $j ne 'ARRAY';
2671     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2672
2673     my $p = $paths;
2674     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2675     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2676   }
2677
2678   return $paths;
2679 }
2680
2681 sub _rollout_attr {
2682   my ($self, $attr) = @_;
2683
2684   if (ref $attr eq 'HASH') {
2685     return $self->_rollout_hash($attr);
2686   } elsif (ref $attr eq 'ARRAY') {
2687     return $self->_rollout_array($attr);
2688   } else {
2689     return [$attr];
2690   }
2691 }
2692
2693 sub _rollout_array {
2694   my ($self, $attr) = @_;
2695
2696   my @rolled_array;
2697   foreach my $element (@{$attr}) {
2698     if (ref $element eq 'HASH') {
2699       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2700     } elsif (ref $element eq 'ARRAY') {
2701       #  XXX - should probably recurse here
2702       push( @rolled_array, @{$self->_rollout_array($element)} );
2703     } else {
2704       push( @rolled_array, $element );
2705     }
2706   }
2707   return \@rolled_array;
2708 }
2709
2710 sub _rollout_hash {
2711   my ($self, $attr) = @_;
2712
2713   my @rolled_array;
2714   foreach my $key (keys %{$attr}) {
2715     push( @rolled_array, { $key => $attr->{$key} } );
2716   }
2717   return \@rolled_array;
2718 }
2719
2720 sub _calculate_score {
2721   my ($self, $a, $b) = @_;
2722
2723   if (ref $b eq 'HASH') {
2724     my ($b_key) = keys %{$b};
2725     if (ref $a eq 'HASH') {
2726       my ($a_key) = keys %{$a};
2727       if ($a_key eq $b_key) {
2728         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2729       } else {
2730         return 0;
2731       }
2732     } else {
2733       return ($a eq $b_key) ? 1 : 0;
2734     }
2735   } else {
2736     if (ref $a eq 'HASH') {
2737       my ($a_key) = keys %{$a};
2738       return ($b eq $a_key) ? 1 : 0;
2739     } else {
2740       return ($b eq $a) ? 1 : 0;
2741     }
2742   }
2743 }
2744
2745 sub _merge_attr {
2746   my ($self, $orig, $import) = @_;
2747
2748   return $import unless defined($orig);
2749   return $orig unless defined($import);
2750
2751   $orig = $self->_rollout_attr($orig);
2752   $import = $self->_rollout_attr($import);
2753
2754   my $seen_keys;
2755   foreach my $import_element ( @{$import} ) {
2756     # find best candidate from $orig to merge $b_element into
2757     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2758     foreach my $orig_element ( @{$orig} ) {
2759       my $score = $self->_calculate_score( $orig_element, $import_element );
2760       if ($score > $best_candidate->{score}) {
2761         $best_candidate->{position} = $position;
2762         $best_candidate->{score} = $score;
2763       }
2764       $position++;
2765     }
2766     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2767
2768     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2769       push( @{$orig}, $import_element );
2770     } else {
2771       my $orig_best = $orig->[$best_candidate->{position}];
2772       # merge orig_best and b_element together and replace original with merged
2773       if (ref $orig_best ne 'HASH') {
2774         $orig->[$best_candidate->{position}] = $import_element;
2775       } elsif (ref $import_element eq 'HASH') {
2776         my ($key) = keys %{$orig_best};
2777         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2778       }
2779     }
2780     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2781   }
2782
2783   return $orig;
2784 }
2785
2786 sub result_source {
2787     my $self = shift;
2788
2789     if (@_) {
2790         $self->_source_handle($_[0]->handle);
2791     } else {
2792         $self->_source_handle->resolve;
2793     }
2794 }
2795
2796 =head2 throw_exception
2797
2798 See L<DBIx::Class::Schema/throw_exception> for details.
2799
2800 =cut
2801
2802 sub throw_exception {
2803   my $self=shift;
2804   if (ref $self && $self->_source_handle->schema) {
2805     $self->_source_handle->schema->throw_exception(@_)
2806   } else {
2807     croak(@_);
2808   }
2809
2810 }
2811
2812 # XXX: FIXME: Attributes docs need clearing up
2813
2814 =head1 ATTRIBUTES
2815
2816 Attributes are used to refine a ResultSet in various ways when
2817 searching for data. They can be passed to any method which takes an
2818 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2819 L</count>.
2820
2821 These are in no particular order:
2822
2823 =head2 order_by
2824
2825 =over 4
2826
2827 =item Value: ( $order_by | \@order_by | \%order_by )
2828
2829 =back
2830
2831 Which column(s) to order the results by. If a single column name, or
2832 an arrayref of names is supplied, the argument is passed through
2833 directly to SQL. The hashref syntax allows for connection-agnostic
2834 specification of ordering direction:
2835
2836  For descending order:
2837
2838   order_by => { -desc => [qw/col1 col2 col3/] }
2839
2840  For explicit ascending order:
2841
2842   order_by => { -asc => 'col' }
2843
2844 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2845 supported, although you are strongly encouraged to use the hashref
2846 syntax as outlined above.
2847
2848 =head2 columns
2849
2850 =over 4
2851
2852 =item Value: \@columns
2853
2854 =back
2855
2856 Shortcut to request a particular set of columns to be retrieved. Each
2857 column spec may be a string (a table column name), or a hash (in which
2858 case the key is the C<as> value, and the value is used as the C<select>
2859 expression). Adds C<me.> onto the start of any column without a C<.> in
2860 it and sets C<select> from that, then auto-populates C<as> from
2861 C<select> as normal. (You may also use the C<cols> attribute, as in
2862 earlier versions of DBIC.)
2863
2864 =head2 +columns
2865
2866 =over 4
2867
2868 =item Value: \@columns
2869
2870 =back
2871
2872 Indicates additional columns to be selected from storage. Works the same
2873 as L</columns> but adds columns to the selection. (You may also use the
2874 C<include_columns> attribute, as in earlier versions of DBIC). For
2875 example:-
2876
2877   $schema->resultset('CD')->search(undef, {
2878     '+columns' => ['artist.name'],
2879     join => ['artist']
2880   });
2881
2882 would return all CDs and include a 'name' column to the information
2883 passed to object inflation. Note that the 'artist' is the name of the
2884 column (or relationship) accessor, and 'name' is the name of the column
2885 accessor in the related table.
2886
2887 =head2 include_columns
2888
2889 =over 4
2890
2891 =item Value: \@columns
2892
2893 =back
2894
2895 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2896
2897 =head2 select
2898
2899 =over 4
2900
2901 =item Value: \@select_columns
2902
2903 =back
2904
2905 Indicates which columns should be selected from the storage. You can use
2906 column names, or in the case of RDBMS back ends, function or stored procedure
2907 names:
2908
2909   $rs = $schema->resultset('Employee')->search(undef, {
2910     select => [
2911       'name',
2912       { count => 'employeeid' },
2913       { sum => 'salary' }
2914     ]
2915   });
2916
2917 When you use function/stored procedure names and do not supply an C<as>
2918 attribute, the column names returned are storage-dependent. E.g. MySQL would
2919 return a column named C<count(employeeid)> in the above example.
2920
2921 =head2 +select
2922
2923 =over 4
2924
2925 Indicates additional columns to be selected from storage.  Works the same as
2926 L</select> but adds columns to the selection.
2927
2928 =back
2929
2930 =head2 +as
2931
2932 =over 4
2933
2934 Indicates additional column names for those added via L</+select>. See L</as>.
2935
2936 =back
2937
2938 =head2 as
2939
2940 =over 4
2941
2942 =item Value: \@inflation_names
2943
2944 =back
2945
2946 Indicates column names for object inflation. That is, C<as>
2947 indicates the name that the column can be accessed as via the
2948 C<get_column> method (or via the object accessor, B<if one already
2949 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2950
2951 The C<as> attribute is used in conjunction with C<select>,
2952 usually when C<select> contains one or more function or stored
2953 procedure names:
2954
2955   $rs = $schema->resultset('Employee')->search(undef, {
2956     select => [
2957       'name',
2958       { count => 'employeeid' }
2959     ],
2960     as => ['name', 'employee_count'],
2961   });
2962
2963   my $employee = $rs->first(); # get the first Employee
2964
2965 If the object against which the search is performed already has an accessor
2966 matching a column name specified in C<as>, the value can be retrieved using
2967 the accessor as normal:
2968
2969   my $name = $employee->name();
2970
2971 If on the other hand an accessor does not exist in the object, you need to
2972 use C<get_column> instead:
2973
2974   my $employee_count = $employee->get_column('employee_count');
2975
2976 You can create your own accessors if required - see
2977 L<DBIx::Class::Manual::Cookbook> for details.
2978
2979 Please note: This will NOT insert an C<AS employee_count> into the SQL
2980 statement produced, it is used for internal access only. Thus
2981 attempting to use the accessor in an C<order_by> clause or similar
2982 will fail miserably.
2983
2984 To get around this limitation, you can supply literal SQL to your
2985 C<select> attibute that contains the C<AS alias> text, eg:
2986
2987   select => [\'myfield AS alias']
2988
2989 =head2 join
2990
2991 =over 4
2992
2993 =item Value: ($rel_name | \@rel_names | \%rel_names)
2994
2995 =back
2996
2997 Contains a list of relationships that should be joined for this query.  For
2998 example:
2999
3000   # Get CDs by Nine Inch Nails
3001   my $rs = $schema->resultset('CD')->search(
3002     { 'artist.name' => 'Nine Inch Nails' },
3003     { join => 'artist' }
3004   );
3005
3006 Can also contain a hash reference to refer to the other relation's relations.
3007 For example:
3008
3009   package MyApp::Schema::Track;
3010   use base qw/DBIx::Class/;
3011   __PACKAGE__->table('track');
3012   __PACKAGE__->add_columns(qw/trackid cd position title/);
3013   __PACKAGE__->set_primary_key('trackid');
3014   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3015   1;
3016
3017   # In your application
3018   my $rs = $schema->resultset('Artist')->search(
3019     { 'track.title' => 'Teardrop' },
3020     {
3021       join     => { cd => 'track' },
3022       order_by => 'artist.name',
3023     }
3024   );
3025
3026 You need to use the relationship (not the table) name in  conditions,
3027 because they are aliased as such. The current table is aliased as "me", so
3028 you need to use me.column_name in order to avoid ambiguity. For example:
3029
3030   # Get CDs from 1984 with a 'Foo' track
3031   my $rs = $schema->resultset('CD')->search(
3032     {
3033       'me.year' => 1984,
3034       'tracks.name' => 'Foo'
3035     },
3036     { join => 'tracks' }
3037   );
3038
3039 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3040 similarly for a third time). For e.g.
3041
3042   my $rs = $schema->resultset('Artist')->search({
3043     'cds.title'   => 'Down to Earth',
3044     'cds_2.title' => 'Popular',
3045   }, {
3046     join => [ qw/cds cds/ ],
3047   });
3048
3049 will return a set of all artists that have both a cd with title 'Down
3050 to Earth' and a cd with title 'Popular'.
3051
3052 If you want to fetch related objects from other tables as well, see C<prefetch>
3053 below.
3054
3055 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3056
3057 =head2 prefetch
3058
3059 =over 4
3060
3061 =item Value: ($rel_name | \@rel_names | \%rel_names)
3062
3063 =back
3064
3065 Contains one or more relationships that should be fetched along with
3066 the main query (when they are accessed afterwards the data will
3067 already be available, without extra queries to the database).  This is
3068 useful for when you know you will need the related objects, because it
3069 saves at least one query:
3070
3071   my $rs = $schema->resultset('Tag')->search(
3072     undef,
3073     {
3074       prefetch => {
3075         cd => 'artist'
3076       }
3077     }
3078   );
3079
3080 The initial search results in SQL like the following:
3081
3082   SELECT tag.*, cd.*, artist.* FROM tag
3083   JOIN cd ON tag.cd = cd.cdid
3084   JOIN artist ON cd.artist = artist.artistid
3085
3086 L<DBIx::Class> has no need to go back to the database when we access the
3087 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3088 case.
3089
3090 Simple prefetches will be joined automatically, so there is no need
3091 for a C<join> attribute in the above search.
3092
3093 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3094 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3095 with an accessor type of 'single' or 'filter'). A more complex example that
3096 prefetches an artists cds, the tracks on those cds, and the tags associted
3097 with that artist is given below (assuming many-to-many from artists to tags):
3098
3099  my $rs = $schema->resultset('Artist')->search(
3100    undef,
3101    {
3102      prefetch => [
3103        { cds => 'tracks' },
3104        { artist_tags => 'tags' }
3105      ]
3106    }
3107  );
3108
3109
3110 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3111 attributes will be ignored.
3112
3113 =head2 page
3114
3115 =over 4
3116
3117 =item Value: $page
3118
3119 =back
3120
3121 Makes the resultset paged and specifies the page to retrieve. Effectively
3122 identical to creating a non-pages resultset and then calling ->page($page)
3123 on it.
3124
3125 If L<rows> attribute is not specified it defualts to 10 rows per page.
3126
3127 When you have a paged resultset, L</count> will only return the number
3128 of rows in the page. To get the total, use the L</pager> and call
3129 C<total_entries> on it.
3130
3131 =head2 rows
3132
3133 =over 4
3134
3135 =item Value: $rows
3136
3137 =back
3138
3139 Specifes the maximum number of rows for direct retrieval or the number of
3140 rows per page if the page attribute or method is used.
3141
3142 =head2 offset
3143
3144 =over 4
3145
3146 =item Value: $offset
3147
3148 =back
3149
3150 Specifies the (zero-based) row number for the  first row to be returned, or the
3151 of the first row of the first page if paging is used.
3152
3153 =head2 group_by
3154
3155 =over 4
3156
3157 =item Value: \@columns
3158
3159 =back
3160
3161 A arrayref of columns to group by. Can include columns of joined tables.
3162
3163   group_by => [qw/ column1 column2 ... /]
3164
3165 =head2 having
3166
3167 =over 4
3168
3169 =item Value: $condition
3170
3171 =back
3172
3173 HAVING is a select statement attribute that is applied between GROUP BY and
3174 ORDER BY. It is applied to the after the grouping calculations have been
3175 done.
3176
3177   having => { 'count(employee)' => { '>=', 100 } }
3178
3179 =head2 distinct
3180
3181 =over 4
3182
3183 =item Value: (0 | 1)
3184
3185 =back
3186
3187 Set to 1 to group by all columns.
3188
3189 =head2 where
3190
3191 =over 4
3192
3193 Adds to the WHERE clause.
3194
3195   # only return rows WHERE deleted IS NULL for all searches
3196   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3197
3198 Can be overridden by passing C<{ where => undef }> as an attribute
3199 to a resulset.
3200
3201 =back
3202
3203 =head2 cache
3204
3205 Set to 1 to cache search results. This prevents extra SQL queries if you
3206 revisit rows in your ResultSet:
3207
3208   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3209
3210   while( my $artist = $resultset->next ) {
3211     ... do stuff ...
3212   }
3213
3214   $rs->first; # without cache, this would issue a query
3215
3216 By default, searches are not cached.
3217
3218 For more examples of using these attributes, see
3219 L<DBIx::Class::Manual::Cookbook>.
3220
3221 =head2 from
3222
3223 =over 4
3224
3225 =item Value: \@from_clause
3226
3227 =back
3228
3229 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3230 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3231 clauses.
3232
3233 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3234
3235 C<join> will usually do what you need and it is strongly recommended that you
3236 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3237 And we really do mean "cannot", not just tried and failed. Attempting to use
3238 this because you're having problems with C<join> is like trying to use x86
3239 ASM because you've got a syntax error in your C. Trust us on this.
3240
3241 Now, if you're still really, really sure you need to use this (and if you're
3242 not 100% sure, ask the mailing list first), here's an explanation of how this
3243 works.
3244
3245 The syntax is as follows -
3246
3247   [
3248     { <alias1> => <table1> },
3249     [
3250       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3251       [], # nested JOIN (optional)
3252       { <table1.column1> => <table2.column2>, ... (more conditions) },
3253     ],
3254     # More of the above [ ] may follow for additional joins
3255   ]
3256
3257   <table1> <alias1>
3258   JOIN
3259     <table2> <alias2>
3260     [JOIN ...]
3261   ON <table1.column1> = <table2.column2>
3262   <more joins may follow>
3263
3264 An easy way to follow the examples below is to remember the following:
3265
3266     Anything inside "[]" is a JOIN
3267     Anything inside "{}" is a condition for the enclosing JOIN
3268
3269 The following examples utilize a "person" table in a family tree application.
3270 In order to express parent->child relationships, this table is self-joined:
3271
3272     # Person->belongs_to('father' => 'Person');
3273     # Person->belongs_to('mother' => 'Person');
3274
3275 C<from> can be used to nest joins. Here we return all children with a father,
3276 then search against all mothers of those children:
3277
3278   $rs = $schema->resultset('Person')->search(
3279       undef,
3280       {
3281           alias => 'mother', # alias columns in accordance with "from"
3282           from => [
3283               { mother => 'person' },
3284               [
3285                   [
3286                       { child => 'person' },
3287                       [
3288                           { father => 'person' },
3289                           { 'father.person_id' => 'child.father_id' }
3290                       ]
3291                   ],
3292                   { 'mother.person_id' => 'child.mother_id' }
3293               ],
3294           ]
3295       },
3296   );
3297
3298   # Equivalent SQL:
3299   # SELECT mother.* FROM person mother
3300   # JOIN (
3301   #   person child
3302   #   JOIN person father
3303   #   ON ( father.person_id = child.father_id )
3304   # )
3305   # ON ( mother.person_id = child.mother_id )
3306
3307 The type of any join can be controlled manually. To search against only people
3308 with a father in the person table, we could explicitly use C<INNER JOIN>:
3309
3310     $rs = $schema->resultset('Person')->search(
3311         undef,
3312         {
3313             alias => 'child', # alias columns in accordance with "from"
3314             from => [
3315                 { child => 'person' },
3316                 [
3317                     { father => 'person', -join_type => 'inner' },
3318                     { 'father.id' => 'child.father_id' }
3319                 ],
3320             ]
3321         },
3322     );
3323
3324     # Equivalent SQL:
3325     # SELECT child.* FROM person child
3326     # INNER JOIN person father ON child.father_id = father.id
3327
3328 If you need to express really complex joins or you need a subselect, you
3329 can supply literal SQL to C<from> via a scalar reference. In this case
3330 the contents of the scalar will replace the table name asscoiated with the
3331 resultsource.
3332
3333 WARNING: This technique might very well not work as expected on chained
3334 searches - you have been warned.
3335
3336     # Assuming the Event resultsource is defined as:
3337
3338         MySchema::Event->add_columns (
3339             sequence => {
3340                 data_type => 'INT',
3341                 is_auto_increment => 1,
3342             },
3343             location => {
3344                 data_type => 'INT',
3345             },
3346             type => {
3347                 data_type => 'INT',
3348             },
3349         );
3350         MySchema::Event->set_primary_key ('sequence');
3351
3352     # This will get back the latest event for every location. The column
3353     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3354     # combo to limit the resultset
3355
3356     $rs = $schema->resultset('Event');
3357     $table = $rs->result_source->name;
3358     $latest = $rs->search (
3359         undef,
3360         { from => \ "
3361             (SELECT e1.* FROM $table e1
3362                 JOIN $table e2
3363                     ON e1.location = e2.location
3364                     AND e1.sequence < e2.sequence
3365                 WHERE e2.sequence is NULL
3366             ) me",
3367         },
3368     );
3369
3370     # Equivalent SQL (with the DBIC chunks added):
3371
3372     SELECT me.sequence, me.location, me.type FROM
3373        (SELECT e1.* FROM events e1
3374            JOIN events e2
3375                ON e1.location = e2.location
3376                AND e1.sequence < e2.sequence
3377            WHERE e2.sequence is NULL
3378        ) me;
3379
3380 =head2 for
3381
3382 =over 4
3383
3384 =item Value: ( 'update' | 'shared' )
3385
3386 =back
3387
3388 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3389 ... FOR SHARED.
3390
3391 =cut
3392
3393 1;