lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 665
 666   return $self->{cursor}
 667     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 668           $attrs->{where},$attrs);
 669 }
 670
 671 =head2 single
 672
 673 =over 4
 674
 675 =item Arguments: $cond?
 676
 677 =item Return Value: $row_object?
 678
 679 =back
 680
 681   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 682
 683 Inflates the first result without creating a cursor if the resultset has
 684 any records in it; if not returns nothing. Used by L</find> as a lean version of
 685 L</search>.
 686
 687 While this method can take an optional search condition (just like L</search>)
 688 being a fast-code-path it does not recognize search attributes. If you need to
 689 add extra joins or similar, call L</search> and then chain-call L</single> on the
 690 L<DBIx::Class::ResultSet> returned.
 691
 692 =over
 693
 694 =item B<Note>
 695
 696 As of 0.08100, this method enforces the assumption that the preceeding
 697 query returns only one row. If more than one row is returned, you will receive
 698 a warning:
 699
 700   Query returned more than one row
 701
 702 In this case, you should be using L</first> or L</find> instead, or if you really
 703 know what you are doing, use the L</rows> attribute to explicitly limit the size
 704 of the resultset.
 705
 706 =back
 707
 708 =cut
 709
 710 sub single {
 711   my ($self, $where) = @_;
 712   if(@_ > 2) {
 713       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 714   }
 715
 716   my $attrs = $self->_resolved_attrs_copy;
 717   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 718
 719   if ($where) {
 720     if (defined $attrs->{where}) {
 721       $attrs->{where} = {
 722         '-and' =>
 723             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 724                $where, delete $attrs->{where} ]
 725       };
 726     } else {
 727       $attrs->{where} = $where;
 728     }
 729   }
 730
 731 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 732 #  unless ($self->_is_unique_query($attrs->{where})) {
 733 #    carp "Query not guaranteed to return a single row"
 734 #      . "; please declare your unique constraints or use search instead";
 735 #  }
 736
 737   my @data = $self->result_source->storage->select_single(
 738     $attrs->{from}, $attrs->{select},
 739     $attrs->{where}, $attrs
 740   );
 741
 742   return (@data ? ($self->_construct_object(@data))[0] : undef);
 743 }
 744
 745 # _gen_virtual_order
 746 #
 747 # This is a horrble hack, but seems like the best we can do at this point
 748 # Some limit emulations (Top) require an ordered resultset in order to
 749 # function at all. So supply a PK order if such a condition is detected
 750
 751 sub _gen_virtual_order {
 752   my $self = shift;
 753   my $attrs = $self->_resolved_attrs_copy;
 754
 755   if ($attrs->{rows} or $attrs->{offset} ) {
 756
 757 #   This check requires ensure_connected, so probably cheaper to just calculate all the time
 758
 759 #    my $sm = $self->result_source->storage->_sql_maker;
 760 #
 761 #    if ($sm->_default_limit_syntax eq 'Top' and not @{$sm->_resolve_order ($attrs->{order_by}) }) {
 762
 763       return [ $self->result_source->primary_columns ];
 764
 765 #    }
 766   }
 767
 768   return undef;
 769 }
 770
 771 # _is_unique_query
 772 #
 773 # Try to determine if the specified query is guaranteed to be unique, based on
 774 # the declared unique constraints.
 775
 776 sub _is_unique_query {
 777   my ($self, $query) = @_;
 778
 779   my $collapsed = $self->_collapse_query($query);
 780   my $alias = $self->{attrs}{alias};
 781
 782   foreach my $name ($self->result_source->unique_constraint_names) {
 783     my @unique_cols = map {
 784       "$alias.$_"
 785     } $self->result_source->unique_constraint_columns($name);
 786
 787     # Count the values for each unique column
 788     my %seen = map { $_ => 0 } @unique_cols;
 789
 790     foreach my $key (keys %$collapsed) {
 791       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 792       next unless exists $seen{$aliased};  # Additional constraints are okay
 793       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 794     }
 795
 796     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 797     return 1 unless grep { $_ != 1 } values %seen;
 798   }
 799
 800   return 0;
 801 }
 802
 803 # _collapse_query
 804 #
 805 # Recursively collapse the query, accumulating values for each column.
 806
 807 sub _collapse_query {
 808   my ($self, $query, $collapsed) = @_;
 809
 810   $collapsed ||= {};
 811
 812   if (ref $query eq 'ARRAY') {
 813     foreach my $subquery (@$query) {
 814       next unless ref $subquery;  # -or
 815       $collapsed = $self->_collapse_query($subquery, $collapsed);
 816     }
 817   }
 818   elsif (ref $query eq 'HASH') {
 819     if (keys %$query and (keys %$query)[0] eq '-and') {
 820       foreach my $subquery (@{$query->{-and}}) {
 821         $collapsed = $self->_collapse_query($subquery, $collapsed);
 822       }
 823     }
 824     else {
 825       foreach my $col (keys %$query) {
 826         my $value = $query->{$col};
 827         $collapsed->{$col}{$value}++;
 828       }
 829     }
 830   }
 831
 832   return $collapsed;
 833 }
 834
 835 =head2 get_column
 836
 837 =over 4
 838
 839 =item Arguments: $cond?
 840
 841 =item Return Value: $resultsetcolumn
 842
 843 =back
 844
 845   my $max_length = $rs->get_column('length')->max;
 846
 847 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 848
 849 =cut
 850
 851 sub get_column {
 852   my ($self, $column) = @_;
 853   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 854   return $new;
 855 }
 856
 857 =head2 search_like
 858
 859 =over 4
 860
 861 =item Arguments: $cond, \%attrs?
 862
 863 =item Return Value: $resultset (scalar context), @row_objs (list context)
 864
 865 =back
 866
 867   # WHERE title LIKE '%blue%'
 868   $cd_rs = $rs->search_like({ title => '%blue%'});
 869
 870 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 871 that this is simply a convenience method retained for ex Class::DBI users.
 872 You most likely want to use L</search> with specific operators.
 873
 874 For more information, see L<DBIx::Class::Manual::Cookbook>.
 875
 876 This method is deprecated and will be removed in 0.09. Use L</search()>
 877 instead. An example conversion is:
 878
 879   ->search_like({ foo => 'bar' });
 880
 881   # Becomes
 882
 883   ->search({ foo => { like => 'bar' } });
 884
 885 =cut
 886
 887 sub search_like {
 888   my $class = shift;
 889   carp (
 890     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 891    .' Instead use ->search({ x => { -like => "y%" } })'
 892    .' (note the outer pair of {}s - they are important!)'
 893   );
 894   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 895   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 896   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 897   return $class->search($query, { %$attrs });
 898 }
 899
 900 =head2 slice
 901
 902 =over 4
 903
 904 =item Arguments: $first, $last
 905
 906 =item Return Value: $resultset (scalar context), @row_objs (list context)
 907
 908 =back
 909
 910 Returns a resultset or object list representing a subset of elements from the
 911 resultset slice is called on. Indexes are from 0, i.e., to get the first
 912 three records, call:
 913
 914   my ($one, $two, $three) = $rs->slice(0, 2);
 915
 916 =cut
 917
 918 sub slice {
 919   my ($self, $min, $max) = @_;
 920   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 921   $attrs->{offset} = $self->{attrs}{offset} || 0;
 922   $attrs->{offset} += $min;
 923   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 924   return $self->search(undef(), $attrs);
 925   #my $slice = (ref $self)->new($self->result_source, $attrs);
 926   #return (wantarray ? $slice->all : $slice);
 927 }
 928
 929 =head2 next
 930
 931 =over 4
 932
 933 =item Arguments: none
 934
 935 =item Return Value: $result?
 936
 937 =back
 938
 939 Returns the next element in the resultset (C<undef> is there is none).
 940
 941 Can be used to efficiently iterate over records in the resultset:
 942
 943   my $rs = $schema->resultset('CD')->search;
 944   while (my $cd = $rs->next) {
 945     print $cd->title;
 946   }
 947
 948 Note that you need to store the resultset object, and call C<next> on it.
 949 Calling C<< resultset('Table')->next >> repeatedly will always return the
 950 first record from the resultset.
 951
 952 =cut
 953
 954 sub next {
 955   my ($self) = @_;
 956   if (my $cache = $self->get_cache) {
 957     $self->{all_cache_position} ||= 0;
 958     return $cache->[$self->{all_cache_position}++];
 959   }
 960   if ($self->{attrs}{cache}) {
 961     $self->{all_cache_position} = 1;
 962     return ($self->all)[0];
 963   }
 964   if ($self->{stashed_objects}) {
 965     my $obj = shift(@{$self->{stashed_objects}});
 966     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 967     return $obj;
 968   }
 969   my @row = (
 970     exists $self->{stashed_row}
 971       ? @{delete $self->{stashed_row}}
 972       : $self->cursor->next
 973   );
 974   return undef unless (@row);
 975   my ($row, @more) = $self->_construct_object(@row);
 976   $self->{stashed_objects} = \@more if @more;
 977   return $row;
 978 }
 979
 980 sub _construct_object {
 981   my ($self, @row) = @_;
 982   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 983   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 984   @new = $self->{_attrs}{record_filter}->(@new)
 985     if exists $self->{_attrs}{record_filter};
 986   return @new;
 987 }
 988
 989 sub _collapse_result {
 990   my ($self, $as_proto, $row) = @_;
 991
 992   my @copy = @$row;
 993
 994   # 'foo'         => [ undef, 'foo' ]
 995   # 'foo.bar'     => [ 'foo', 'bar' ]
 996   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 997
 998   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 999
1000   my %collapse = %{$self->{_attrs}{collapse}||{}};
1001
1002   my @pri_index;
1003
1004   # if we're doing collapsing (has_many prefetch) we need to grab records
1005   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1006   # we know we don't have to bother.
1007
1008   # the reason for not using the collapse stuff directly is because if you
1009   # had for e.g. two artists in a row with no cds, the collapse info for
1010   # both would be NULL (undef) so you'd lose the second artist
1011
1012   # store just the index so we can check the array positions from the row
1013   # without having to contruct the full hash
1014
1015   if (keys %collapse) {
1016     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1017     foreach my $i (0 .. $#construct_as) {
1018       next if defined($construct_as[$i][0]); # only self table
1019       if (delete $pri{$construct_as[$i][1]}) {
1020         push(@pri_index, $i);
1021       }
1022       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1023     }
1024   }
1025
1026   # no need to do an if, it'll be empty if @pri_index is empty anyway
1027
1028   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1029
1030   my @const_rows;
1031
1032   do { # no need to check anything at the front, we always want the first row
1033
1034     my %const;
1035
1036     foreach my $this_as (@construct_as) {
1037       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1038     }
1039
1040     push(@const_rows, \%const);
1041
1042   } until ( # no pri_index => no collapse => drop straight out
1043       !@pri_index
1044     or
1045       do { # get another row, stash it, drop out if different PK
1046
1047         @copy = $self->cursor->next;
1048         $self->{stashed_row} = \@copy;
1049
1050         # last thing in do block, counts as true if anything doesn't match
1051
1052         # check xor defined first for NULL vs. NOT NULL then if one is
1053         # defined the other must be so check string equality
1054
1055         grep {
1056           (defined $pri_vals{$_} ^ defined $copy[$_])
1057           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1058         } @pri_index;
1059       }
1060   );
1061
1062   my $alias = $self->{attrs}{alias};
1063   my $info = [];
1064
1065   my %collapse_pos;
1066
1067   my @const_keys;
1068
1069   foreach my $const (@const_rows) {
1070     scalar @const_keys or do {
1071       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1072     };
1073     foreach my $key (@const_keys) {
1074       if (length $key) {
1075         my $target = $info;
1076         my @parts = split(/\./, $key);
1077         my $cur = '';
1078         my $data = $const->{$key};
1079         foreach my $p (@parts) {
1080           $target = $target->[1]->{$p} ||= [];
1081           $cur .= ".${p}";
1082           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1083             # collapsing at this point and on final part
1084             my $pos = $collapse_pos{$cur};
1085             CK: foreach my $ck (@ckey) {
1086               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1087                 $collapse_pos{$cur} = $data;
1088                 delete @collapse_pos{ # clear all positioning for sub-entries
1089                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1090                 };
1091                 push(@$target, []);
1092                 last CK;
1093               }
1094             }
1095           }
1096           if (exists $collapse{$cur}) {
1097             $target = $target->[-1];
1098           }
1099         }
1100         $target->[0] = $data;
1101       } else {
1102         $info->[0] = $const->{$key};
1103       }
1104     }
1105   }
1106
1107   return $info;
1108 }
1109
1110 =head2 result_source
1111
1112 =over 4
1113
1114 =item Arguments: $result_source?
1115
1116 =item Return Value: $result_source
1117
1118 =back
1119
1120 An accessor for the primary ResultSource object from which this ResultSet
1121 is derived.
1122
1123 =head2 result_class
1124
1125 =over 4
1126
1127 =item Arguments: $result_class?
1128
1129 =item Return Value: $result_class
1130
1131 =back
1132
1133 An accessor for the class to use when creating row objects. Defaults to
1134 C<< result_source->result_class >> - which in most cases is the name of the
1135 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1136
1137 Note that changing the result_class will also remove any components
1138 that were originally loaded in the source class via
1139 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1140 in the original source class will not run.
1141
1142 =cut
1143
1144 sub result_class {
1145   my ($self, $result_class) = @_;
1146   if ($result_class) {
1147     $self->ensure_class_loaded($result_class);
1148     $self->_result_class($result_class);
1149   }
1150   $self->_result_class;
1151 }
1152
1153 =head2 count
1154
1155 =over 4
1156
1157 =item Arguments: $cond, \%attrs??
1158
1159 =item Return Value: $count
1160
1161 =back
1162
1163 Performs an SQL C<COUNT> with the same query as the resultset was built
1164 with to find the number of elements. Passing arguments is equivalent to
1165 C<< $rs->search ($cond, \%attrs)->count >>
1166
1167 =cut
1168
1169 sub count {
1170   my $self = shift;
1171   return $self->search(@_)->count if @_ and defined $_[0];
1172   return scalar @{ $self->get_cache } if $self->get_cache;
1173
1174   my @grouped_subq_attrs = qw/prefetch collapse distinct group_by having/;
1175   my @subq_attrs = ();
1176
1177   my $attrs = $self->_resolved_attrs;
1178   # if we are not paged - we are simply asking for a limit
1179   if (not $attrs->{page} and not $attrs->{software_limit}) {
1180     push @subq_attrs, qw/rows offset/;
1181   }
1182
1183   my $need_subq = $self->_has_attr (@subq_attrs);
1184   my $need_group_subq = $self->_has_attr (@grouped_subq_attrs);
1185
1186   return ($need_subq || $need_group_subq)
1187     ? $self->_count_subq ($need_group_subq)
1188     : $self->_count_simple
1189 }
1190
1191 sub _count_subq {
1192   my ($self, $add_group_by) = @_;
1193
1194   my $attrs = $self->_resolved_attrs_copy;
1195
1196   # copy for the subquery, we need to do some adjustments to it too
1197   my $sub_attrs = { %$attrs };
1198
1199   # these can not go in the subquery, and there is no point of ordering it
1200   delete $sub_attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns order_by/;
1201
1202   # if needed force a group_by and the same set of columns (most databases require this)
1203   if ($add_group_by) {
1204
1205     # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1206     # simply deleting group_by suffices, as the code below will re-fill it
1207     # Note: we check $attrs, as $sub_attrs has collapse deleted
1208     if (ref $attrs->{collapse} and keys %{$attrs->{collapse}} ) {
1209       delete $sub_attrs->{group_by};
1210     }
1211
1212     $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1213   }
1214
1215   $attrs->{from} = [{
1216     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1217   }];
1218
1219   # the subquery replaces this
1220   delete $attrs->{$_} for qw/where bind prefetch collapse distinct group_by having having_bind/;
1221
1222   return $self->__count ($attrs);
1223 }
1224
1225 sub _count_simple {
1226   my $self = shift;
1227
1228   my $count = $self->__count;
1229   return 0 unless $count;
1230
1231   # need to take offset from resolved attrs
1232
1233   my $attrs = $self->_resolved_attrs;
1234
1235   $count -= $attrs->{offset} if $attrs->{offset};
1236   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1237   $count = 0 if ($count < 0);
1238   return $count;
1239 }
1240
1241 sub __count {
1242   my ($self, $attrs) = @_;
1243
1244   $attrs ||= $self->_resolved_attrs_copy;
1245
1246   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1247   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1248
1249   $attrs->{select} = { count => '*' };
1250   $attrs->{as} = [qw/count/];
1251
1252   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1253   my ($count) = $tmp_rs->cursor->next;
1254
1255   return $count;
1256 }
1257
1258 sub _bool {
1259   return 1;
1260 }
1261
1262 =head2 count_literal
1263
1264 =over 4
1265
1266 =item Arguments: $sql_fragment, @bind_values
1267
1268 =item Return Value: $count
1269
1270 =back
1271
1272 Counts the results in a literal query. Equivalent to calling L</search_literal>
1273 with the passed arguments, then L</count>.
1274
1275 =cut
1276
1277 sub count_literal { shift->search_literal(@_)->count; }
1278
1279 =head2 all
1280
1281 =over 4
1282
1283 =item Arguments: none
1284
1285 =item Return Value: @objects
1286
1287 =back
1288
1289 Returns all elements in the resultset. Called implicitly if the resultset
1290 is returned in list context.
1291
1292 =cut
1293
1294 sub all {
1295   my $self = shift;
1296   if(@_) {
1297       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1298   }
1299
1300   return @{ $self->get_cache } if $self->get_cache;
1301
1302   my @obj;
1303
1304   # TODO: don't call resolve here
1305   if (keys %{$self->_resolved_attrs->{collapse}}) {
1306 #  if ($self->{attrs}{prefetch}) {
1307       # Using $self->cursor->all is really just an optimisation.
1308       # If we're collapsing has_many prefetches it probably makes
1309       # very little difference, and this is cleaner than hacking
1310       # _construct_object to survive the approach
1311     my @row = $self->cursor->next;
1312     while (@row) {
1313       push(@obj, $self->_construct_object(@row));
1314       @row = (exists $self->{stashed_row}
1315                ? @{delete $self->{stashed_row}}
1316                : $self->cursor->next);
1317     }
1318   } else {
1319     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1320   }
1321
1322   $self->set_cache(\@obj) if $self->{attrs}{cache};
1323   return @obj;
1324 }
1325
1326 =head2 reset
1327
1328 =over 4
1329
1330 =item Arguments: none
1331
1332 =item Return Value: $self
1333
1334 =back
1335
1336 Resets the resultset's cursor, so you can iterate through the elements again.
1337
1338 =cut
1339
1340 sub reset {
1341   my ($self) = @_;
1342   delete $self->{_attrs} if exists $self->{_attrs};
1343   $self->{all_cache_position} = 0;
1344   $self->cursor->reset;
1345   return $self;
1346 }
1347
1348 =head2 first
1349
1350 =over 4
1351
1352 =item Arguments: none
1353
1354 =item Return Value: $object?
1355
1356 =back
1357
1358 Resets the resultset and returns an object for the first result (if the
1359 resultset returns anything).
1360
1361 =cut
1362
1363 sub first {
1364   return $_[0]->reset->next;
1365 }
1366
1367
1368 # _rs_update_delete
1369 #
1370 # Determines whether and what type of subquery is required for the $rs operation.
1371 # If grouping is necessary either supplies its own, or verifies the current one
1372 # After all is done delegates to the proper storage method.
1373
1374 sub _rs_update_delete {
1375   my ($self, $op, $values) = @_;
1376
1377   my $rsrc = $self->result_source;
1378
1379   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1380   my $needs_subq = $self->_has_attr (qw/row offset page/);
1381
1382   if ($needs_group_by_subq or $needs_subq) {
1383
1384     # make a new $rs selecting only the PKs (that's all we really need)
1385     my $attrs = $self->_resolved_attrs_copy;
1386
1387     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1388     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1389
1390     if ($needs_group_by_subq) {
1391       # make sure no group_by was supplied, or if there is one - make sure it matches
1392       # the columns compiled above perfectly. Anything else can not be sanely executed
1393       # on most databases so croak right then and there
1394
1395       if (my $g = $attrs->{group_by}) {
1396         my @current_group_by = map
1397           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1398           (ref $g eq 'ARRAY' ? @$g : $g );
1399
1400         if (
1401           join ("\x00", sort @current_group_by)
1402             ne
1403           join ("\x00", sort @{$attrs->{columns}} )
1404         ) {
1405           $self->throw_exception (
1406             "You have just attempted a $op operation on a resultset which does group_by"
1407             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1408             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1409             . ' kind of queries. Please retry the operation with a modified group_by or'
1410             . ' without using one at all.'
1411           );
1412         }
1413       }
1414       else {
1415         $attrs->{group_by} = $attrs->{columns};
1416       }
1417     }
1418
1419     my $subrs = (ref $self)->new($rsrc, $attrs);
1420
1421     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1422   }
1423   else {
1424     return $rsrc->storage->$op(
1425       $rsrc,
1426       $op eq 'update' ? $values : (),
1427       $self->_cond_for_update_delete,
1428     );
1429   }
1430 }
1431
1432
1433 # _cond_for_update_delete
1434 #
1435 # update/delete require the condition to be modified to handle
1436 # the differing SQL syntax available.  This transforms the $self->{cond}
1437 # appropriately, returning the new condition.
1438
1439 sub _cond_for_update_delete {
1440   my ($self, $full_cond) = @_;
1441   my $cond = {};
1442
1443   $full_cond ||= $self->{cond};
1444   # No-op. No condition, we're updating/deleting everything
1445   return $cond unless ref $full_cond;
1446
1447   if (ref $full_cond eq 'ARRAY') {
1448     $cond = [
1449       map {
1450         my %hash;
1451         foreach my $key (keys %{$_}) {
1452           $key =~ /([^.]+)$/;
1453           $hash{$1} = $_->{$key};
1454         }
1455         \%hash;
1456       } @{$full_cond}
1457     ];
1458   }
1459   elsif (ref $full_cond eq 'HASH') {
1460     if ((keys %{$full_cond})[0] eq '-and') {
1461       $cond->{-and} = [];
1462       my @cond = @{$full_cond->{-and}};
1463        for (my $i = 0; $i < @cond; $i++) {
1464         my $entry = $cond[$i];
1465         my $hash;
1466         if (ref $entry eq 'HASH') {
1467           $hash = $self->_cond_for_update_delete($entry);
1468         }
1469         else {
1470           $entry =~ /([^.]+)$/;
1471           $hash->{$1} = $cond[++$i];
1472         }
1473         push @{$cond->{-and}}, $hash;
1474       }
1475     }
1476     else {
1477       foreach my $key (keys %{$full_cond}) {
1478         $key =~ /([^.]+)$/;
1479         $cond->{$1} = $full_cond->{$key};
1480       }
1481     }
1482   }
1483   else {
1484     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1485   }
1486
1487   return $cond;
1488 }
1489
1490
1491 =head2 update
1492
1493 =over 4
1494
1495 =item Arguments: \%values
1496
1497 =item Return Value: $storage_rv
1498
1499 =back
1500
1501 Sets the specified columns in the resultset to the supplied values in a
1502 single query. Return value will be true if the update succeeded or false
1503 if no records were updated; exact type of success value is storage-dependent.
1504
1505 =cut
1506
1507 sub update {
1508   my ($self, $values) = @_;
1509   $self->throw_exception('Values for update must be a hash')
1510     unless ref $values eq 'HASH';
1511
1512   return $self->_rs_update_delete ('update', $values);
1513 }
1514
1515 =head2 update_all
1516
1517 =over 4
1518
1519 =item Arguments: \%values
1520
1521 =item Return Value: 1
1522
1523 =back
1524
1525 Fetches all objects and updates them one at a time. Note that C<update_all>
1526 will run DBIC cascade triggers, while L</update> will not.
1527
1528 =cut
1529
1530 sub update_all {
1531   my ($self, $values) = @_;
1532   $self->throw_exception('Values for update_all must be a hash')
1533     unless ref $values eq 'HASH';
1534   foreach my $obj ($self->all) {
1535     $obj->set_columns($values)->update;
1536   }
1537   return 1;
1538 }
1539
1540 =head2 delete
1541
1542 =over 4
1543
1544 =item Arguments: none
1545
1546 =item Return Value: 1
1547
1548 =back
1549
1550 Deletes the contents of the resultset from its result source. Note that this
1551 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1552 to run. See also L<DBIx::Class::Row/delete>.
1553
1554 delete may not generate correct SQL for a query with joins or a resultset
1555 chained from a related resultset.  In this case it will generate a warning:-
1556
1557 In these cases you may find that delete_all is more appropriate, or you
1558 need to respecify your query in a way that can be expressed without a join.
1559
1560 =cut
1561
1562 sub delete {
1563   my $self = shift;
1564   $self->throw_exception('delete does not accept any arguments')
1565     if @_;
1566
1567   return $self->_rs_update_delete ('delete');
1568 }
1569
1570 =head2 delete_all
1571
1572 =over 4
1573
1574 =item Arguments: none
1575
1576 =item Return Value: 1
1577
1578 =back
1579
1580 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1581 will run DBIC cascade triggers, while L</delete> will not.
1582
1583 =cut
1584
1585 sub delete_all {
1586   my $self = shift;
1587   $self->throw_exception('delete_all does not accept any arguments')
1588     if @_;
1589
1590   $_->delete for $self->all;
1591   return 1;
1592 }
1593
1594 =head2 populate
1595
1596 =over 4
1597
1598 =item Arguments: \@data;
1599
1600 =back
1601
1602 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1603 For the arrayref of hashrefs style each hashref should be a structure suitable
1604 forsubmitting to a $resultset->create(...) method.
1605
1606 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1607 to insert the data, as this is a faster method.
1608
1609 Otherwise, each set of data is inserted into the database using
1610 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1611 objects is returned.
1612
1613 Example:  Assuming an Artist Class that has many CDs Classes relating:
1614
1615   my $Artist_rs = $schema->resultset("Artist");
1616
1617   ## Void Context Example
1618   $Artist_rs->populate([
1619      { artistid => 4, name => 'Manufactured Crap', cds => [
1620         { title => 'My First CD', year => 2006 },
1621         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1622       ],
1623      },
1624      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1625         { title => 'My parents sold me to a record company' ,year => 2005 },
1626         { title => 'Why Am I So Ugly?', year => 2006 },
1627         { title => 'I Got Surgery and am now Popular', year => 2007 }
1628       ],
1629      },
1630   ]);
1631
1632   ## Array Context Example
1633   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1634     { name => "Artist One"},
1635     { name => "Artist Two"},
1636     { name => "Artist Three", cds=> [
1637     { title => "First CD", year => 2007},
1638     { title => "Second CD", year => 2008},
1639   ]}
1640   ]);
1641
1642   print $ArtistOne->name; ## response is 'Artist One'
1643   print $ArtistThree->cds->count ## reponse is '2'
1644
1645 For the arrayref of arrayrefs style,  the first element should be a list of the
1646 fieldsnames to which the remaining elements are rows being inserted.  For
1647 example:
1648
1649   $Arstist_rs->populate([
1650     [qw/artistid name/],
1651     [100, 'A Formally Unknown Singer'],
1652     [101, 'A singer that jumped the shark two albums ago'],
1653     [102, 'An actually cool singer.'],
1654   ]);
1655
1656 Please note an important effect on your data when choosing between void and
1657 wantarray context. Since void context goes straight to C<insert_bulk> in
1658 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1659 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1660 create primary keys for you, you will find that your PKs are empty.  In this
1661 case you will have to use the wantarray context in order to create those
1662 values.
1663
1664 =cut
1665
1666 sub populate {
1667   my $self = shift @_;
1668   my $data = ref $_[0][0] eq 'HASH'
1669     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1670     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1671
1672   if(defined wantarray) {
1673     my @created;
1674     foreach my $item (@$data) {
1675       push(@created, $self->create($item));
1676     }
1677     return @created;
1678   } else {
1679     my ($first, @rest) = @$data;
1680
1681     my @names = grep {!ref $first->{$_}} keys %$first;
1682     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1683     my @pks = $self->result_source->primary_columns;
1684
1685     ## do the belongs_to relationships
1686     foreach my $index (0..$#$data) {
1687       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1688         my @ret = $self->populate($data);
1689         return;
1690       }
1691
1692       foreach my $rel (@rels) {
1693         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1694         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1695         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1696         my $related = $result->result_source->_resolve_condition(
1697           $result->result_source->relationship_info($reverse)->{cond},
1698           $self,
1699           $result,
1700         );
1701
1702         delete $data->[$index]->{$rel};
1703         $data->[$index] = {%{$data->[$index]}, %$related};
1704
1705         push @names, keys %$related if $index == 0;
1706       }
1707     }
1708
1709     ## do bulk insert on current row
1710     my @values = map { [ @$_{@names} ] } @$data;
1711
1712     $self->result_source->storage->insert_bulk(
1713       $self->result_source,
1714       \@names,
1715       \@values,
1716     );
1717
1718     ## do the has_many relationships
1719     foreach my $item (@$data) {
1720
1721       foreach my $rel (@rels) {
1722         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1723
1724         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1725      || $self->throw_exception('Cannot find the relating object.');
1726
1727         my $child = $parent->$rel;
1728
1729         my $related = $child->result_source->_resolve_condition(
1730           $parent->result_source->relationship_info($rel)->{cond},
1731           $child,
1732           $parent,
1733         );
1734
1735         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1736         my @populate = map { {%$_, %$related} } @rows_to_add;
1737
1738         $child->populate( \@populate );
1739       }
1740     }
1741   }
1742 }
1743
1744 =head2 _normalize_populate_args ($args)
1745
1746 Private method used by L</populate> to normalize its incoming arguments.  Factored
1747 out in case you want to subclass and accept new argument structures to the
1748 L</populate> method.
1749
1750 =cut
1751
1752 sub _normalize_populate_args {
1753   my ($self, $data) = @_;
1754   my @names = @{shift(@$data)};
1755   my @results_to_create;
1756   foreach my $datum (@$data) {
1757     my %result_to_create;
1758     foreach my $index (0..$#names) {
1759       $result_to_create{$names[$index]} = $$datum[$index];
1760     }
1761     push @results_to_create, \%result_to_create;
1762   }
1763   return \@results_to_create;
1764 }
1765
1766 =head2 pager
1767
1768 =over 4
1769
1770 =item Arguments: none
1771
1772 =item Return Value: $pager
1773
1774 =back
1775
1776 Return Value a L<Data::Page> object for the current resultset. Only makes
1777 sense for queries with a C<page> attribute.
1778
1779 To get the full count of entries for a paged resultset, call
1780 C<total_entries> on the L<Data::Page> object.
1781
1782 =cut
1783
1784 sub pager {
1785   my ($self) = @_;
1786
1787   return $self->{pager} if $self->{pager};
1788
1789   my $attrs = $self->{attrs};
1790   $self->throw_exception("Can't create pager for non-paged rs")
1791     unless $self->{attrs}{page};
1792   $attrs->{rows} ||= 10;
1793
1794   # throw away the paging flags and re-run the count (possibly
1795   # with a subselect) to get the real total count
1796   my $count_attrs = { %$attrs };
1797   delete $count_attrs->{$_} for qw/rows offset page pager/;
1798   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1799
1800   return $self->{pager} = Data::Page->new(
1801     $total_count,
1802     $attrs->{rows},
1803     $self->{attrs}{page}
1804   );
1805 }
1806
1807 =head2 page
1808
1809 =over 4
1810
1811 =item Arguments: $page_number
1812
1813 =item Return Value: $rs
1814
1815 =back
1816
1817 Returns a resultset for the $page_number page of the resultset on which page
1818 is called, where each page contains a number of rows equal to the 'rows'
1819 attribute set on the resultset (10 by default).
1820
1821 =cut
1822
1823 sub page {
1824   my ($self, $page) = @_;
1825   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1826 }
1827
1828 =head2 new_result
1829
1830 =over 4
1831
1832 =item Arguments: \%vals
1833
1834 =item Return Value: $rowobject
1835
1836 =back
1837
1838 Creates a new row object in the resultset's result class and returns
1839 it. The row is not inserted into the database at this point, call
1840 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1841 will tell you whether the row object has been inserted or not.
1842
1843 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1844
1845 =cut
1846
1847 sub new_result {
1848   my ($self, $values) = @_;
1849   $self->throw_exception( "new_result needs a hash" )
1850     unless (ref $values eq 'HASH');
1851
1852   my %new;
1853   my $alias = $self->{attrs}{alias};
1854
1855   if (
1856     defined $self->{cond}
1857     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1858   ) {
1859     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1860     $new{-from_resultset} = [ keys %new ] if keys %new;
1861   } else {
1862     $self->throw_exception(
1863       "Can't abstract implicit construct, condition not a hash"
1864     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1865
1866     my $collapsed_cond = (
1867       $self->{cond}
1868         ? $self->_collapse_cond($self->{cond})
1869         : {}
1870     );
1871
1872     # precendence must be given to passed values over values inherited from
1873     # the cond, so the order here is important.
1874     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1875     while( my($col,$value) = each %implied ){
1876       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1877         $new{$col} = $value->{'='};
1878         next;
1879       }
1880       $new{$col} = $value if $self->_is_deterministic_value($value);
1881     }
1882   }
1883
1884   %new = (
1885     %new,
1886     %{ $self->_remove_alias($values, $alias) },
1887     -source_handle => $self->_source_handle,
1888     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1889   );
1890
1891   return $self->result_class->new(\%new);
1892 }
1893
1894 # _is_deterministic_value
1895 #
1896 # Make an effor to strip non-deterministic values from the condition,
1897 # to make sure new_result chokes less
1898
1899 sub _is_deterministic_value {
1900   my $self = shift;
1901   my $value = shift;
1902   my $ref_type = ref $value;
1903   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1904   return 1 if Scalar::Util::blessed($value);
1905   return 0;
1906 }
1907
1908 # _has_attr
1909 #
1910 # determines if the resultset defines at least one
1911 # of the attributes supplied
1912 #
1913 # used to determine if a subquery is neccessary
1914
1915 sub _has_attr {
1916   my ($self, @attr_names) = @_;
1917
1918   my $attrs = $self->_resolved_attrs;
1919
1920   my $join_check_req;
1921
1922   for my $n (@attr_names) {
1923     ++$join_check_req if $n =~ /join/;
1924
1925     my $attr =  $attrs->{$n};
1926
1927     next if not defined $attr;
1928
1929     if (ref $attr eq 'HASH') {
1930       return 1 if keys %$attr;
1931     }
1932     elsif (ref $attr eq 'ARRAY') {
1933       return 1 if @$attr;
1934     }
1935     else {
1936       return 1 if $attr;
1937     }
1938   }
1939
1940   # a join can be expressed as a multi-level from
1941   return 1 if (
1942     $join_check_req
1943       and
1944     ref $attrs->{from} eq 'ARRAY'
1945       and
1946     @{$attrs->{from}} > 1
1947   );
1948
1949   return 0;
1950 }
1951
1952 # _collapse_cond
1953 #
1954 # Recursively collapse the condition.
1955
1956 sub _collapse_cond {
1957   my ($self, $cond, $collapsed) = @_;
1958
1959   $collapsed ||= {};
1960
1961   if (ref $cond eq 'ARRAY') {
1962     foreach my $subcond (@$cond) {
1963       next unless ref $subcond;  # -or
1964       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1965     }
1966   }
1967   elsif (ref $cond eq 'HASH') {
1968     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1969       foreach my $subcond (@{$cond->{-and}}) {
1970         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1971       }
1972     }
1973     else {
1974       foreach my $col (keys %$cond) {
1975         my $value = $cond->{$col};
1976         $collapsed->{$col} = $value;
1977       }
1978     }
1979   }
1980
1981   return $collapsed;
1982 }
1983
1984 # _remove_alias
1985 #
1986 # Remove the specified alias from the specified query hash. A copy is made so
1987 # the original query is not modified.
1988
1989 sub _remove_alias {
1990   my ($self, $query, $alias) = @_;
1991
1992   my %orig = %{ $query || {} };
1993   my %unaliased;
1994
1995   foreach my $key (keys %orig) {
1996     if ($key !~ /\./) {
1997       $unaliased{$key} = $orig{$key};
1998       next;
1999     }
2000     $unaliased{$1} = $orig{$key}
2001       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2002   }
2003
2004   return \%unaliased;
2005 }
2006
2007 =head2 as_query (EXPERIMENTAL)
2008
2009 =over 4
2010
2011 =item Arguments: none
2012
2013 =item Return Value: \[ $sql, @bind ]
2014
2015 =back
2016
2017 Returns the SQL query and bind vars associated with the invocant.
2018
2019 This is generally used as the RHS for a subquery.
2020
2021 B<NOTE>: This feature is still experimental.
2022
2023 =cut
2024
2025 sub as_query { return shift->cursor->as_query(@_) }
2026
2027 =head2 find_or_new
2028
2029 =over 4
2030
2031 =item Arguments: \%vals, \%attrs?
2032
2033 =item Return Value: $rowobject
2034
2035 =back
2036
2037   my $artist = $schema->resultset('Artist')->find_or_new(
2038     { artist => 'fred' }, { key => 'artists' });
2039
2040   $cd->cd_to_producer->find_or_new({ producer => $producer },
2041                                    { key => 'primary });
2042
2043 Find an existing record from this resultset, based on its primary
2044 key, or a unique constraint. If none exists, instantiate a new result
2045 object and return it. The object will not be saved into your storage
2046 until you call L<DBIx::Class::Row/insert> on it.
2047
2048 You most likely want this method when looking for existing rows using
2049 a unique constraint that is not the primary key, or looking for
2050 related rows.
2051
2052 If you want objects to be saved immediately, use L</find_or_create> instead.
2053
2054 B<Note>: C<find_or_new> is probably not what you want when creating a
2055 new row in a table that uses primary keys supplied by the
2056 database. Passing in a primary key column with a value of I<undef>
2057 will cause L</find> to attempt to search for a row with a value of
2058 I<NULL>.
2059
2060 =cut
2061
2062 sub find_or_new {
2063   my $self     = shift;
2064   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2065   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2066   my $exists   = $self->find($hash, $attrs);
2067   return defined $exists ? $exists : $self->new_result($hash);
2068 }
2069
2070 =head2 create
2071
2072 =over 4
2073
2074 =item Arguments: \%vals
2075
2076 =item Return Value: a L<DBIx::Class::Row> $object
2077
2078 =back
2079
2080 Attempt to create a single new row or a row with multiple related rows
2081 in the table represented by the resultset (and related tables). This
2082 will not check for duplicate rows before inserting, use
2083 L</find_or_create> to do that.
2084
2085 To create one row for this resultset, pass a hashref of key/value
2086 pairs representing the columns of the table and the values you wish to
2087 store. If the appropriate relationships are set up, foreign key fields
2088 can also be passed an object representing the foreign row, and the
2089 value will be set to its primary key.
2090
2091 To create related objects, pass a hashref for the value if the related
2092 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2093 and use the name of the relationship as the key. (NOT the name of the field,
2094 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2095 of hashrefs containing the data for each of the rows to create in the foreign
2096 tables, again using the relationship name as the key.
2097
2098 Instead of hashrefs of plain related data (key/value pairs), you may
2099 also pass new or inserted objects. New objects (not inserted yet, see
2100 L</new>), will be inserted into their appropriate tables.
2101
2102 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2103
2104 Example of creating a new row.
2105
2106   $person_rs->create({
2107     name=>"Some Person",
2108     email=>"somebody@someplace.com"
2109   });
2110
2111 Example of creating a new row and also creating rows in a related C<has_many>
2112 or C<has_one> resultset.  Note Arrayref.
2113
2114   $artist_rs->create(
2115      { artistid => 4, name => 'Manufactured Crap', cds => [
2116         { title => 'My First CD', year => 2006 },
2117         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2118       ],
2119      },
2120   );
2121
2122 Example of creating a new row and also creating a row in a related
2123 C<belongs_to>resultset. Note Hashref.
2124
2125   $cd_rs->create({
2126     title=>"Music for Silly Walks",
2127     year=>2000,
2128     artist => {
2129       name=>"Silly Musician",
2130     }
2131   });
2132
2133 =cut
2134
2135 sub create {
2136   my ($self, $attrs) = @_;
2137   $self->throw_exception( "create needs a hashref" )
2138     unless ref $attrs eq 'HASH';
2139   return $self->new_result($attrs)->insert;
2140 }
2141
2142 =head2 find_or_create
2143
2144 =over 4
2145
2146 =item Arguments: \%vals, \%attrs?
2147
2148 =item Return Value: $rowobject
2149
2150 =back
2151
2152   $cd->cd_to_producer->find_or_create({ producer => $producer },
2153                                       { key => 'primary });
2154
2155 Tries to find a record based on its primary key or unique constraints; if none
2156 is found, creates one and returns that instead.
2157
2158   my $cd = $schema->resultset('CD')->find_or_create({
2159     cdid   => 5,
2160     artist => 'Massive Attack',
2161     title  => 'Mezzanine',
2162     year   => 2005,
2163   });
2164
2165 Also takes an optional C<key> attribute, to search by a specific key or unique
2166 constraint. For example:
2167
2168   my $cd = $schema->resultset('CD')->find_or_create(
2169     {
2170       artist => 'Massive Attack',
2171       title  => 'Mezzanine',
2172     },
2173     { key => 'cd_artist_title' }
2174   );
2175
2176 B<Note>: Because find_or_create() reads from the database and then
2177 possibly inserts based on the result, this method is subject to a race
2178 condition. Another process could create a record in the table after
2179 the find has completed and before the create has started. To avoid
2180 this problem, use find_or_create() inside a transaction.
2181
2182 B<Note>: C<find_or_create> is probably not what you want when creating
2183 a new row in a table that uses primary keys supplied by the
2184 database. Passing in a primary key column with a value of I<undef>
2185 will cause L</find> to attempt to search for a row with a value of
2186 I<NULL>.
2187
2188 See also L</find> and L</update_or_create>. For information on how to declare
2189 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2190
2191 =cut
2192
2193 sub find_or_create {
2194   my $self     = shift;
2195   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2196   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2197   my $exists   = $self->find($hash, $attrs);
2198   return defined $exists ? $exists : $self->create($hash);
2199 }
2200
2201 =head2 update_or_create
2202
2203 =over 4
2204
2205 =item Arguments: \%col_values, { key => $unique_constraint }?
2206
2207 =item Return Value: $rowobject
2208
2209 =back
2210
2211   $resultset->update_or_create({ col => $val, ... });
2212
2213 First, searches for an existing row matching one of the unique constraints
2214 (including the primary key) on the source of this resultset. If a row is
2215 found, updates it with the other given column values. Otherwise, creates a new
2216 row.
2217
2218 Takes an optional C<key> attribute to search on a specific unique constraint.
2219 For example:
2220
2221   # In your application
2222   my $cd = $schema->resultset('CD')->update_or_create(
2223     {
2224       artist => 'Massive Attack',
2225       title  => 'Mezzanine',
2226       year   => 1998,
2227     },
2228     { key => 'cd_artist_title' }
2229   );
2230
2231   $cd->cd_to_producer->update_or_create({
2232     producer => $producer,
2233     name => 'harry',
2234   }, {
2235     key => 'primary,
2236   });
2237
2238
2239 If no C<key> is specified, it searches on all unique constraints defined on the
2240 source, including the primary key.
2241
2242 If the C<key> is specified as C<primary>, it searches only on the primary key.
2243
2244 See also L</find> and L</find_or_create>. For information on how to declare
2245 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2246
2247 B<Note>: C<update_or_create> is probably not what you want when
2248 looking for a row in a table that uses primary keys supplied by the
2249 database, unless you actually have a key value. Passing in a primary
2250 key column with a value of I<undef> will cause L</find> to attempt to
2251 search for a row with a value of I<NULL>.
2252
2253 =cut
2254
2255 sub update_or_create {
2256   my $self = shift;
2257   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2258   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2259
2260   my $row = $self->find($cond, $attrs);
2261   if (defined $row) {
2262     $row->update($cond);
2263     return $row;
2264   }
2265
2266   return $self->create($cond);
2267 }
2268
2269 =head2 update_or_new
2270
2271 =over 4
2272
2273 =item Arguments: \%col_values, { key => $unique_constraint }?
2274
2275 =item Return Value: $rowobject
2276
2277 =back
2278
2279   $resultset->update_or_new({ col => $val, ... });
2280
2281 First, searches for an existing row matching one of the unique constraints
2282 (including the primary key) on the source of this resultset. If a row is
2283 found, updates it with the other given column values. Otherwise, instantiate
2284 a new result object and return it. The object will not be saved into your storage
2285 until you call L<DBIx::Class::Row/insert> on it.
2286
2287 Takes an optional C<key> attribute to search on a specific unique constraint.
2288 For example:
2289
2290   # In your application
2291   my $cd = $schema->resultset('CD')->update_or_new(
2292     {
2293       artist => 'Massive Attack',
2294       title  => 'Mezzanine',
2295       year   => 1998,
2296     },
2297     { key => 'cd_artist_title' }
2298   );
2299
2300   if ($cd->in_storage) {
2301       # the cd was updated
2302   }
2303   else {
2304       # the cd is not yet in the database, let's insert it
2305       $cd->insert;
2306   }
2307
2308 See also L</find>, L</find_or_create> and L<find_or_new>.
2309
2310 =cut
2311
2312 sub update_or_new {
2313     my $self  = shift;
2314     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2315     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2316
2317     my $row = $self->find( $cond, $attrs );
2318     if ( defined $row ) {
2319         $row->update($cond);
2320         return $row;
2321     }
2322
2323     return $self->new_result($cond);
2324 }
2325
2326 =head2 get_cache
2327
2328 =over 4
2329
2330 =item Arguments: none
2331
2332 =item Return Value: \@cache_objects?
2333
2334 =back
2335
2336 Gets the contents of the cache for the resultset, if the cache is set.
2337
2338 The cache is populated either by using the L</prefetch> attribute to
2339 L</search> or by calling L</set_cache>.
2340
2341 =cut
2342
2343 sub get_cache {
2344   shift->{all_cache};
2345 }
2346
2347 =head2 set_cache
2348
2349 =over 4
2350
2351 =item Arguments: \@cache_objects
2352
2353 =item Return Value: \@cache_objects
2354
2355 =back
2356
2357 Sets the contents of the cache for the resultset. Expects an arrayref
2358 of objects of the same class as those produced by the resultset. Note that
2359 if the cache is set the resultset will return the cached objects rather
2360 than re-querying the database even if the cache attr is not set.
2361
2362 The contents of the cache can also be populated by using the
2363 L</prefetch> attribute to L</search>.
2364
2365 =cut
2366
2367 sub set_cache {
2368   my ( $self, $data ) = @_;
2369   $self->throw_exception("set_cache requires an arrayref")
2370       if defined($data) && (ref $data ne 'ARRAY');
2371   $self->{all_cache} = $data;
2372 }
2373
2374 =head2 clear_cache
2375
2376 =over 4
2377
2378 =item Arguments: none
2379
2380 =item Return Value: []
2381
2382 =back
2383
2384 Clears the cache for the resultset.
2385
2386 =cut
2387
2388 sub clear_cache {
2389   shift->set_cache(undef);
2390 }
2391
2392 =head2 related_resultset
2393
2394 =over 4
2395
2396 =item Arguments: $relationship_name
2397
2398 =item Return Value: $resultset
2399
2400 =back
2401
2402 Returns a related resultset for the supplied relationship name.
2403
2404   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2405
2406 =cut
2407
2408 sub related_resultset {
2409   my ($self, $rel) = @_;
2410
2411   $self->{related_resultsets} ||= {};
2412   return $self->{related_resultsets}{$rel} ||= do {
2413     my $rel_obj = $self->result_source->relationship_info($rel);
2414
2415     $self->throw_exception(
2416       "search_related: result source '" . $self->result_source->source_name .
2417         "' has no such relationship $rel")
2418       unless $rel_obj;
2419
2420     my ($from,$seen) = $self->_resolve_from($rel);
2421
2422     my $join_count = $seen->{$rel};
2423     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2424
2425     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2426     my %attrs = %{$self->{attrs}||{}};
2427     delete @attrs{qw(result_class alias)};
2428
2429     my $new_cache;
2430
2431     if (my $cache = $self->get_cache) {
2432       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2433         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2434                         @$cache ];
2435       }
2436     }
2437
2438     my $rel_source = $self->result_source->related_source($rel);
2439
2440     my $new = do {
2441
2442       # The reason we do this now instead of passing the alias to the
2443       # search_rs below is that if you wrap/overload resultset on the
2444       # source you need to know what alias it's -going- to have for things
2445       # to work sanely (e.g. RestrictWithObject wants to be able to add
2446       # extra query restrictions, and these may need to be $alias.)
2447
2448       my $attrs = $rel_source->resultset_attributes;
2449       local $attrs->{alias} = $alias;
2450
2451       $rel_source->resultset
2452                  ->search_rs(
2453                      undef, {
2454                        %attrs,
2455                        join => undef,
2456                        prefetch => undef,
2457                        select => undef,
2458                        as => undef,
2459                        where => $self->{cond},
2460                        seen_join => $seen,
2461                        from => $from,
2462                    });
2463     };
2464     $new->set_cache($new_cache) if $new_cache;
2465     $new;
2466   };
2467 }
2468
2469 =head2 current_source_alias
2470
2471 =over 4
2472
2473 =item Arguments: none
2474
2475 =item Return Value: $source_alias
2476
2477 =back
2478
2479 Returns the current table alias for the result source this resultset is built
2480 on, that will be used in the SQL query. Usually it is C<me>.
2481
2482 Currently the source alias that refers to the result set returned by a
2483 L</search>/L</find> family method depends on how you got to the resultset: it's
2484 C<me> by default, but eg. L</search_related> aliases it to the related result
2485 source name (and keeps C<me> referring to the original result set). The long
2486 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2487 (and make this method unnecessary).
2488
2489 Thus it's currently necessary to use this method in predefined queries (see
2490 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2491 source alias of the current result set:
2492
2493   # in a result set class
2494   sub modified_by {
2495     my ($self, $user) = @_;
2496
2497     my $me = $self->current_source_alias;
2498
2499     return $self->search(
2500       "$me.modified" => $user->id,
2501     );
2502   }
2503
2504 =cut
2505
2506 sub current_source_alias {
2507   my ($self) = @_;
2508
2509   return ($self->{attrs} || {})->{alias} || 'me';
2510 }
2511
2512 # This code is called by search_related, and makes sure there
2513 # is clear separation between the joins before, during, and
2514 # after the relationship. This information is needed later
2515 # in order to properly resolve prefetch aliases (any alias
2516 # with a relation_chain_depth less than the depth of the
2517 # current prefetch is not considered)
2518 sub _resolve_from {
2519   my ($self, $extra_join) = @_;
2520   my $source = $self->result_source;
2521   my $attrs = $self->{attrs};
2522
2523   my $from = $attrs->{from}
2524     || [ { $attrs->{alias} => $source->from } ];
2525
2526   my $seen = { %{$attrs->{seen_join}||{}} };
2527
2528   # we need to take the prefetch the attrs into account before we
2529   # ->_resolve_join as otherwise they get lost - captainL
2530   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2531
2532   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2533
2534   ++$seen->{-relation_chain_depth};
2535
2536   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2537
2538   ++$seen->{-relation_chain_depth};
2539
2540   return ($from,$seen);
2541 }
2542
2543 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2544 sub _resolved_attrs_copy {
2545   my $self = shift;
2546   return { %{$self->_resolved_attrs (@_)} };
2547 }
2548
2549 sub _resolved_attrs {
2550   my $self = shift;
2551   return $self->{_attrs} if $self->{_attrs};
2552
2553   my $attrs  = { %{ $self->{attrs} || {} } };
2554   my $source = $self->result_source;
2555   my $alias  = $attrs->{alias};
2556
2557   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2558   my @colbits;
2559
2560   # build columns (as long as select isn't set) into a set of as/select hashes
2561   unless ( $attrs->{select} ) {
2562       @colbits = map {
2563           ( ref($_) eq 'HASH' )
2564               ? $_
2565               : {
2566                   (
2567                     /^\Q${alias}.\E(.+)$/
2568                       ? "$1"
2569                       : "$_"
2570                   )
2571                 =>
2572                   (
2573                     /\./
2574                       ? "$_"
2575                       : "${alias}.$_"
2576                   )
2577             }
2578       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2579   }
2580   # add the additional columns on
2581   foreach ( 'include_columns', '+columns' ) {
2582       push @colbits, map {
2583           ( ref($_) eq 'HASH' )
2584             ? $_
2585             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2586       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2587   }
2588
2589   # start with initial select items
2590   if ( $attrs->{select} ) {
2591     $attrs->{select} =
2592         ( ref $attrs->{select} eq 'ARRAY' )
2593       ? [ @{ $attrs->{select} } ]
2594       : [ $attrs->{select} ];
2595     $attrs->{as} = (
2596       $attrs->{as}
2597       ? (
2598         ref $attrs->{as} eq 'ARRAY'
2599         ? [ @{ $attrs->{as} } ]
2600         : [ $attrs->{as} ]
2601         )
2602       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2603     );
2604   }
2605   else {
2606
2607     # otherwise we intialise select & as to empty
2608     $attrs->{select} = [];
2609     $attrs->{as}     = [];
2610   }
2611
2612   # now add colbits to select/as
2613   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2614   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2615
2616   my $adds;
2617   if ( $adds = delete $attrs->{'+select'} ) {
2618     $adds = [$adds] unless ref $adds eq 'ARRAY';
2619     push(
2620       @{ $attrs->{select} },
2621       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2622     );
2623   }
2624   if ( $adds = delete $attrs->{'+as'} ) {
2625     $adds = [$adds] unless ref $adds eq 'ARRAY';
2626     push( @{ $attrs->{as} }, @$adds );
2627   }
2628
2629   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2630
2631   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2632     my $join = delete $attrs->{join} || {};
2633
2634     if ( defined $attrs->{prefetch} ) {
2635       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2636
2637     }
2638
2639     $attrs->{from} =    # have to copy here to avoid corrupting the original
2640       [
2641       @{ $attrs->{from} },
2642       $source->_resolve_join(
2643         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2644       )
2645       ];
2646
2647   }
2648
2649   if ( $attrs->{order_by} ) {
2650     $attrs->{order_by} = (
2651       ref( $attrs->{order_by} ) eq 'ARRAY'
2652       ? [ @{ $attrs->{order_by} } ]
2653       : [ $attrs->{order_by} ]
2654     );
2655   }
2656   else {
2657     $attrs->{order_by} = [];
2658   }
2659
2660   my $collapse = $attrs->{collapse} || {};
2661   if ( my $prefetch = delete $attrs->{prefetch} ) {
2662     $prefetch = $self->_merge_attr( {}, $prefetch );
2663     my @pre_order;
2664     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2665
2666       # bring joins back to level of current class
2667       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2668       my @prefetch =
2669         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2670       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2671       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2672     }
2673     push( @{ $attrs->{order_by} }, @pre_order );
2674   }
2675
2676   if (delete $attrs->{distinct}) {
2677     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2678   }
2679
2680   $attrs->{collapse} = $collapse;
2681
2682   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2683     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2684   }
2685
2686   return $self->{_attrs} = $attrs;
2687 }
2688
2689 sub _joinpath_aliases {
2690   my ($self, $fromspec, $seen) = @_;
2691
2692   my $paths = {};
2693   return $paths unless ref $fromspec eq 'ARRAY';
2694
2695   for my $j (@$fromspec) {
2696
2697     next if ref $j ne 'ARRAY';
2698     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2699
2700     my $p = $paths;
2701     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2702     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2703   }
2704
2705   return $paths;
2706 }
2707
2708 sub _rollout_attr {
2709   my ($self, $attr) = @_;
2710
2711   if (ref $attr eq 'HASH') {
2712     return $self->_rollout_hash($attr);
2713   } elsif (ref $attr eq 'ARRAY') {
2714     return $self->_rollout_array($attr);
2715   } else {
2716     return [$attr];
2717   }
2718 }
2719
2720 sub _rollout_array {
2721   my ($self, $attr) = @_;
2722
2723   my @rolled_array;
2724   foreach my $element (@{$attr}) {
2725     if (ref $element eq 'HASH') {
2726       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2727     } elsif (ref $element eq 'ARRAY') {
2728       #  XXX - should probably recurse here
2729       push( @rolled_array, @{$self->_rollout_array($element)} );
2730     } else {
2731       push( @rolled_array, $element );
2732     }
2733   }
2734   return \@rolled_array;
2735 }
2736
2737 sub _rollout_hash {
2738   my ($self, $attr) = @_;
2739
2740   my @rolled_array;
2741   foreach my $key (keys %{$attr}) {
2742     push( @rolled_array, { $key => $attr->{$key} } );
2743   }
2744   return \@rolled_array;
2745 }
2746
2747 sub _calculate_score {
2748   my ($self, $a, $b) = @_;
2749
2750   if (ref $b eq 'HASH') {
2751     my ($b_key) = keys %{$b};
2752     if (ref $a eq 'HASH') {
2753       my ($a_key) = keys %{$a};
2754       if ($a_key eq $b_key) {
2755         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2756       } else {
2757         return 0;
2758       }
2759     } else {
2760       return ($a eq $b_key) ? 1 : 0;
2761     }
2762   } else {
2763     if (ref $a eq 'HASH') {
2764       my ($a_key) = keys %{$a};
2765       return ($b eq $a_key) ? 1 : 0;
2766     } else {
2767       return ($b eq $a) ? 1 : 0;
2768     }
2769   }
2770 }
2771
2772 sub _merge_attr {
2773   my ($self, $orig, $import) = @_;
2774
2775   return $import unless defined($orig);
2776   return $orig unless defined($import);
2777
2778   $orig = $self->_rollout_attr($orig);
2779   $import = $self->_rollout_attr($import);
2780
2781   my $seen_keys;
2782   foreach my $import_element ( @{$import} ) {
2783     # find best candidate from $orig to merge $b_element into
2784     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2785     foreach my $orig_element ( @{$orig} ) {
2786       my $score = $self->_calculate_score( $orig_element, $import_element );
2787       if ($score > $best_candidate->{score}) {
2788         $best_candidate->{position} = $position;
2789         $best_candidate->{score} = $score;
2790       }
2791       $position++;
2792     }
2793     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2794
2795     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2796       push( @{$orig}, $import_element );
2797     } else {
2798       my $orig_best = $orig->[$best_candidate->{position}];
2799       # merge orig_best and b_element together and replace original with merged
2800       if (ref $orig_best ne 'HASH') {
2801         $orig->[$best_candidate->{position}] = $import_element;
2802       } elsif (ref $import_element eq 'HASH') {
2803         my ($key) = keys %{$orig_best};
2804         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2805       }
2806     }
2807     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2808   }
2809
2810   return $orig;
2811 }
2812
2813 sub result_source {
2814     my $self = shift;
2815
2816     if (@_) {
2817         $self->_source_handle($_[0]->handle);
2818     } else {
2819         $self->_source_handle->resolve;
2820     }
2821 }
2822
2823 =head2 throw_exception
2824
2825 See L<DBIx::Class::Schema/throw_exception> for details.
2826
2827 =cut
2828
2829 sub throw_exception {
2830   my $self=shift;
2831   if (ref $self && $self->_source_handle->schema) {
2832     $self->_source_handle->schema->throw_exception(@_)
2833   } else {
2834     croak(@_);
2835   }
2836
2837 }
2838
2839 # XXX: FIXME: Attributes docs need clearing up
2840
2841 =head1 ATTRIBUTES
2842
2843 Attributes are used to refine a ResultSet in various ways when
2844 searching for data. They can be passed to any method which takes an
2845 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2846 L</count>.
2847
2848 These are in no particular order:
2849
2850 =head2 order_by
2851
2852 =over 4
2853
2854 =item Value: ( $order_by | \@order_by | \%order_by )
2855
2856 =back
2857
2858 Which column(s) to order the results by. If a single column name, or
2859 an arrayref of names is supplied, the argument is passed through
2860 directly to SQL. The hashref syntax allows for connection-agnostic
2861 specification of ordering direction:
2862
2863  For descending order:
2864
2865   order_by => { -desc => [qw/col1 col2 col3/] }
2866
2867  For explicit ascending order:
2868
2869   order_by => { -asc => 'col' }
2870
2871 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2872 supported, although you are strongly encouraged to use the hashref
2873 syntax as outlined above.
2874
2875 =head2 columns
2876
2877 =over 4
2878
2879 =item Value: \@columns
2880
2881 =back
2882
2883 Shortcut to request a particular set of columns to be retrieved. Each
2884 column spec may be a string (a table column name), or a hash (in which
2885 case the key is the C<as> value, and the value is used as the C<select>
2886 expression). Adds C<me.> onto the start of any column without a C<.> in
2887 it and sets C<select> from that, then auto-populates C<as> from
2888 C<select> as normal. (You may also use the C<cols> attribute, as in
2889 earlier versions of DBIC.)
2890
2891 =head2 +columns
2892
2893 =over 4
2894
2895 =item Value: \@columns
2896
2897 =back
2898
2899 Indicates additional columns to be selected from storage. Works the same
2900 as L</columns> but adds columns to the selection. (You may also use the
2901 C<include_columns> attribute, as in earlier versions of DBIC). For
2902 example:-
2903
2904   $schema->resultset('CD')->search(undef, {
2905     '+columns' => ['artist.name'],
2906     join => ['artist']
2907   });
2908
2909 would return all CDs and include a 'name' column to the information
2910 passed to object inflation. Note that the 'artist' is the name of the
2911 column (or relationship) accessor, and 'name' is the name of the column
2912 accessor in the related table.
2913
2914 =head2 include_columns
2915
2916 =over 4
2917
2918 =item Value: \@columns
2919
2920 =back
2921
2922 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2923
2924 =head2 select
2925
2926 =over 4
2927
2928 =item Value: \@select_columns
2929
2930 =back
2931
2932 Indicates which columns should be selected from the storage. You can use
2933 column names, or in the case of RDBMS back ends, function or stored procedure
2934 names:
2935
2936   $rs = $schema->resultset('Employee')->search(undef, {
2937     select => [
2938       'name',
2939       { count => 'employeeid' },
2940       { sum => 'salary' }
2941     ]
2942   });
2943
2944 When you use function/stored procedure names and do not supply an C<as>
2945 attribute, the column names returned are storage-dependent. E.g. MySQL would
2946 return a column named C<count(employeeid)> in the above example.
2947
2948 =head2 +select
2949
2950 =over 4
2951
2952 Indicates additional columns to be selected from storage.  Works the same as
2953 L</select> but adds columns to the selection.
2954
2955 =back
2956
2957 =head2 +as
2958
2959 =over 4
2960
2961 Indicates additional column names for those added via L</+select>. See L</as>.
2962
2963 =back
2964
2965 =head2 as
2966
2967 =over 4
2968
2969 =item Value: \@inflation_names
2970
2971 =back
2972
2973 Indicates column names for object inflation. That is, C<as>
2974 indicates the name that the column can be accessed as via the
2975 C<get_column> method (or via the object accessor, B<if one already
2976 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2977
2978 The C<as> attribute is used in conjunction with C<select>,
2979 usually when C<select> contains one or more function or stored
2980 procedure names:
2981
2982   $rs = $schema->resultset('Employee')->search(undef, {
2983     select => [
2984       'name',
2985       { count => 'employeeid' }
2986     ],
2987     as => ['name', 'employee_count'],
2988   });
2989
2990   my $employee = $rs->first(); # get the first Employee
2991
2992 If the object against which the search is performed already has an accessor
2993 matching a column name specified in C<as>, the value can be retrieved using
2994 the accessor as normal:
2995
2996   my $name = $employee->name();
2997
2998 If on the other hand an accessor does not exist in the object, you need to
2999 use C<get_column> instead:
3000
3001   my $employee_count = $employee->get_column('employee_count');
3002
3003 You can create your own accessors if required - see
3004 L<DBIx::Class::Manual::Cookbook> for details.
3005
3006 Please note: This will NOT insert an C<AS employee_count> into the SQL
3007 statement produced, it is used for internal access only. Thus
3008 attempting to use the accessor in an C<order_by> clause or similar
3009 will fail miserably.
3010
3011 To get around this limitation, you can supply literal SQL to your
3012 C<select> attibute that contains the C<AS alias> text, eg:
3013
3014   select => [\'myfield AS alias']
3015
3016 =head2 join
3017
3018 =over 4
3019
3020 =item Value: ($rel_name | \@rel_names | \%rel_names)
3021
3022 =back
3023
3024 Contains a list of relationships that should be joined for this query.  For
3025 example:
3026
3027   # Get CDs by Nine Inch Nails
3028   my $rs = $schema->resultset('CD')->search(
3029     { 'artist.name' => 'Nine Inch Nails' },
3030     { join => 'artist' }
3031   );
3032
3033 Can also contain a hash reference to refer to the other relation's relations.
3034 For example:
3035
3036   package MyApp::Schema::Track;
3037   use base qw/DBIx::Class/;
3038   __PACKAGE__->table('track');
3039   __PACKAGE__->add_columns(qw/trackid cd position title/);
3040   __PACKAGE__->set_primary_key('trackid');
3041   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3042   1;
3043
3044   # In your application
3045   my $rs = $schema->resultset('Artist')->search(
3046     { 'track.title' => 'Teardrop' },
3047     {
3048       join     => { cd => 'track' },
3049       order_by => 'artist.name',
3050     }
3051   );
3052
3053 You need to use the relationship (not the table) name in  conditions,
3054 because they are aliased as such. The current table is aliased as "me", so
3055 you need to use me.column_name in order to avoid ambiguity. For example:
3056
3057   # Get CDs from 1984 with a 'Foo' track
3058   my $rs = $schema->resultset('CD')->search(
3059     {
3060       'me.year' => 1984,
3061       'tracks.name' => 'Foo'
3062     },
3063     { join => 'tracks' }
3064   );
3065
3066 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3067 similarly for a third time). For e.g.
3068
3069   my $rs = $schema->resultset('Artist')->search({
3070     'cds.title'   => 'Down to Earth',
3071     'cds_2.title' => 'Popular',
3072   }, {
3073     join => [ qw/cds cds/ ],
3074   });
3075
3076 will return a set of all artists that have both a cd with title 'Down
3077 to Earth' and a cd with title 'Popular'.
3078
3079 If you want to fetch related objects from other tables as well, see C<prefetch>
3080 below.
3081
3082 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3083
3084 =head2 prefetch
3085
3086 =over 4
3087
3088 =item Value: ($rel_name | \@rel_names | \%rel_names)
3089
3090 =back
3091
3092 Contains one or more relationships that should be fetched along with
3093 the main query (when they are accessed afterwards the data will
3094 already be available, without extra queries to the database).  This is
3095 useful for when you know you will need the related objects, because it
3096 saves at least one query:
3097
3098   my $rs = $schema->resultset('Tag')->search(
3099     undef,
3100     {
3101       prefetch => {
3102         cd => 'artist'
3103       }
3104     }
3105   );
3106
3107 The initial search results in SQL like the following:
3108
3109   SELECT tag.*, cd.*, artist.* FROM tag
3110   JOIN cd ON tag.cd = cd.cdid
3111   JOIN artist ON cd.artist = artist.artistid
3112
3113 L<DBIx::Class> has no need to go back to the database when we access the
3114 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3115 case.
3116
3117 Simple prefetches will be joined automatically, so there is no need
3118 for a C<join> attribute in the above search.
3119
3120 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3121 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3122 with an accessor type of 'single' or 'filter'). A more complex example that
3123 prefetches an artists cds, the tracks on those cds, and the tags associted
3124 with that artist is given below (assuming many-to-many from artists to tags):
3125
3126  my $rs = $schema->resultset('Artist')->search(
3127    undef,
3128    {
3129      prefetch => [
3130        { cds => 'tracks' },
3131        { artist_tags => 'tags' }
3132      ]
3133    }
3134  );
3135
3136
3137 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3138 attributes will be ignored.
3139
3140 =head2 page
3141
3142 =over 4
3143
3144 =item Value: $page
3145
3146 =back
3147
3148 Makes the resultset paged and specifies the page to retrieve. Effectively
3149 identical to creating a non-pages resultset and then calling ->page($page)
3150 on it.
3151
3152 If L<rows> attribute is not specified it defualts to 10 rows per page.
3153
3154 When you have a paged resultset, L</count> will only return the number
3155 of rows in the page. To get the total, use the L</pager> and call
3156 C<total_entries> on it.
3157
3158 =head2 rows
3159
3160 =over 4
3161
3162 =item Value: $rows
3163
3164 =back
3165
3166 Specifes the maximum number of rows for direct retrieval or the number of
3167 rows per page if the page attribute or method is used.
3168
3169 =head2 offset
3170
3171 =over 4
3172
3173 =item Value: $offset
3174
3175 =back
3176
3177 Specifies the (zero-based) row number for the  first row to be returned, or the
3178 of the first row of the first page if paging is used.
3179
3180 =head2 group_by
3181
3182 =over 4
3183
3184 =item Value: \@columns
3185
3186 =back
3187
3188 A arrayref of columns to group by. Can include columns of joined tables.
3189
3190   group_by => [qw/ column1 column2 ... /]
3191
3192 =head2 having
3193
3194 =over 4
3195
3196 =item Value: $condition
3197
3198 =back
3199
3200 HAVING is a select statement attribute that is applied between GROUP BY and
3201 ORDER BY. It is applied to the after the grouping calculations have been
3202 done.
3203
3204   having => { 'count(employee)' => { '>=', 100 } }
3205
3206 =head2 distinct
3207
3208 =over 4
3209
3210 =item Value: (0 | 1)
3211
3212 =back
3213
3214 Set to 1 to group by all columns.
3215
3216 =head2 where
3217
3218 =over 4
3219
3220 Adds to the WHERE clause.
3221
3222   # only return rows WHERE deleted IS NULL for all searches
3223   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3224
3225 Can be overridden by passing C<{ where => undef }> as an attribute
3226 to a resulset.
3227
3228 =back
3229
3230 =head2 cache
3231
3232 Set to 1 to cache search results. This prevents extra SQL queries if you
3233 revisit rows in your ResultSet:
3234
3235   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3236
3237   while( my $artist = $resultset->next ) {
3238     ... do stuff ...
3239   }
3240
3241   $rs->first; # without cache, this would issue a query
3242
3243 By default, searches are not cached.
3244
3245 For more examples of using these attributes, see
3246 L<DBIx::Class::Manual::Cookbook>.
3247
3248 =head2 from
3249
3250 =over 4
3251
3252 =item Value: \@from_clause
3253
3254 =back
3255
3256 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3257 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3258 clauses.
3259
3260 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3261
3262 C<join> will usually do what you need and it is strongly recommended that you
3263 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3264 And we really do mean "cannot", not just tried and failed. Attempting to use
3265 this because you're having problems with C<join> is like trying to use x86
3266 ASM because you've got a syntax error in your C. Trust us on this.
3267
3268 Now, if you're still really, really sure you need to use this (and if you're
3269 not 100% sure, ask the mailing list first), here's an explanation of how this
3270 works.
3271
3272 The syntax is as follows -
3273
3274   [
3275     { <alias1> => <table1> },
3276     [
3277       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3278       [], # nested JOIN (optional)
3279       { <table1.column1> => <table2.column2>, ... (more conditions) },
3280     ],
3281     # More of the above [ ] may follow for additional joins
3282   ]
3283
3284   <table1> <alias1>
3285   JOIN
3286     <table2> <alias2>
3287     [JOIN ...]
3288   ON <table1.column1> = <table2.column2>
3289   <more joins may follow>
3290
3291 An easy way to follow the examples below is to remember the following:
3292
3293     Anything inside "[]" is a JOIN
3294     Anything inside "{}" is a condition for the enclosing JOIN
3295
3296 The following examples utilize a "person" table in a family tree application.
3297 In order to express parent->child relationships, this table is self-joined:
3298
3299     # Person->belongs_to('father' => 'Person');
3300     # Person->belongs_to('mother' => 'Person');
3301
3302 C<from> can be used to nest joins. Here we return all children with a father,
3303 then search against all mothers of those children:
3304
3305   $rs = $schema->resultset('Person')->search(
3306       undef,
3307       {
3308           alias => 'mother', # alias columns in accordance with "from"
3309           from => [
3310               { mother => 'person' },
3311               [
3312                   [
3313                       { child => 'person' },
3314                       [
3315                           { father => 'person' },
3316                           { 'father.person_id' => 'child.father_id' }
3317                       ]
3318                   ],
3319                   { 'mother.person_id' => 'child.mother_id' }
3320               ],
3321           ]
3322       },
3323   );
3324
3325   # Equivalent SQL:
3326   # SELECT mother.* FROM person mother
3327   # JOIN (
3328   #   person child
3329   #   JOIN person father
3330   #   ON ( father.person_id = child.father_id )
3331   # )
3332   # ON ( mother.person_id = child.mother_id )
3333
3334 The type of any join can be controlled manually. To search against only people
3335 with a father in the person table, we could explicitly use C<INNER JOIN>:
3336
3337     $rs = $schema->resultset('Person')->search(
3338         undef,
3339         {
3340             alias => 'child', # alias columns in accordance with "from"
3341             from => [
3342                 { child => 'person' },
3343                 [
3344                     { father => 'person', -join_type => 'inner' },
3345                     { 'father.id' => 'child.father_id' }
3346                 ],
3347             ]
3348         },
3349     );
3350
3351     # Equivalent SQL:
3352     # SELECT child.* FROM person child
3353     # INNER JOIN person father ON child.father_id = father.id
3354
3355 If you need to express really complex joins or you need a subselect, you
3356 can supply literal SQL to C<from> via a scalar reference. In this case
3357 the contents of the scalar will replace the table name asscoiated with the
3358 resultsource.
3359
3360 WARNING: This technique might very well not work as expected on chained
3361 searches - you have been warned.
3362
3363     # Assuming the Event resultsource is defined as:
3364
3365         MySchema::Event->add_columns (
3366             sequence => {
3367                 data_type => 'INT',
3368                 is_auto_increment => 1,
3369             },
3370             location => {
3371                 data_type => 'INT',
3372             },
3373             type => {
3374                 data_type => 'INT',
3375             },
3376         );
3377         MySchema::Event->set_primary_key ('sequence');
3378
3379     # This will get back the latest event for every location. The column
3380     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3381     # combo to limit the resultset
3382
3383     $rs = $schema->resultset('Event');
3384     $table = $rs->result_source->name;
3385     $latest = $rs->search (
3386         undef,
3387         { from => \ "
3388             (SELECT e1.* FROM $table e1
3389                 JOIN $table e2
3390                     ON e1.location = e2.location
3391                     AND e1.sequence < e2.sequence
3392                 WHERE e2.sequence is NULL
3393             ) me",
3394         },
3395     );
3396
3397     # Equivalent SQL (with the DBIC chunks added):
3398
3399     SELECT me.sequence, me.location, me.type FROM
3400        (SELECT e1.* FROM events e1
3401            JOIN events e2
3402                ON e1.location = e2.location
3403                AND e1.sequence < e2.sequence
3404            WHERE e2.sequence is NULL
3405        ) me;
3406
3407 =head2 for
3408
3409 =over 4
3410
3411 =item Value: ( 'update' | 'shared' )
3412
3413 =back
3414
3415 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3416 ... FOR SHARED.
3417
3418 =cut
3419
3420 1;