lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360
 361   $rs->set_cache($rows) if ($rows);
 362
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   # if the first row that ever came in is totally empty - this means we got
 978   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 979   # instead of producing a {}
 980   #
 981   my $has_def;
 982   for (@$row) {
 983     if (defined $_) {
 984       $has_def++;
 985       last;
 986     }
 987   }
 988   return undef unless $has_def;
 989
 990   my @copy = @$row;
 991
 992   # 'foo'         => [ undef, 'foo' ]
 993   # 'foo.bar'     => [ 'foo', 'bar' ]
 994   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 995
 996   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 997
 998   my %collapse = %{$self->{_attrs}{collapse}||{}};
 999
1000   my @pri_index;
1001
1002   # if we're doing collapsing (has_many prefetch) we need to grab records
1003   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1004   # we know we don't have to bother.
1005
1006   # the reason for not using the collapse stuff directly is because if you
1007   # had for e.g. two artists in a row with no cds, the collapse info for
1008   # both would be NULL (undef) so you'd lose the second artist
1009
1010   # store just the index so we can check the array positions from the row
1011   # without having to contruct the full hash
1012
1013   if (keys %collapse) {
1014     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1015     foreach my $i (0 .. $#construct_as) {
1016       next if defined($construct_as[$i][0]); # only self table
1017       if (delete $pri{$construct_as[$i][1]}) {
1018         push(@pri_index, $i);
1019       }
1020       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1021     }
1022   }
1023
1024   # no need to do an if, it'll be empty if @pri_index is empty anyway
1025
1026   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1027
1028   my @const_rows;
1029
1030   do { # no need to check anything at the front, we always want the first row
1031
1032     my %const;
1033
1034     foreach my $this_as (@construct_as) {
1035       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1036     }
1037
1038     push(@const_rows, \%const);
1039
1040   } until ( # no pri_index => no collapse => drop straight out
1041       !@pri_index
1042     or
1043       do { # get another row, stash it, drop out if different PK
1044
1045         @copy = $self->cursor->next;
1046         $self->{stashed_row} = \@copy;
1047
1048         # last thing in do block, counts as true if anything doesn't match
1049
1050         # check xor defined first for NULL vs. NOT NULL then if one is
1051         # defined the other must be so check string equality
1052
1053         grep {
1054           (defined $pri_vals{$_} ^ defined $copy[$_])
1055           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1056         } @pri_index;
1057       }
1058   );
1059
1060   my $alias = $self->{attrs}{alias};
1061   my $info = [];
1062
1063   my %collapse_pos;
1064
1065   my @const_keys;
1066
1067   foreach my $const (@const_rows) {
1068     scalar @const_keys or do {
1069       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1070     };
1071     foreach my $key (@const_keys) {
1072       if (length $key) {
1073         my $target = $info;
1074         my @parts = split(/\./, $key);
1075         my $cur = '';
1076         my $data = $const->{$key};
1077         foreach my $p (@parts) {
1078           $target = $target->[1]->{$p} ||= [];
1079           $cur .= ".${p}";
1080           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1081             # collapsing at this point and on final part
1082             my $pos = $collapse_pos{$cur};
1083             CK: foreach my $ck (@ckey) {
1084               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1085                 $collapse_pos{$cur} = $data;
1086                 delete @collapse_pos{ # clear all positioning for sub-entries
1087                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1088                 };
1089                 push(@$target, []);
1090                 last CK;
1091               }
1092             }
1093           }
1094           if (exists $collapse{$cur}) {
1095             $target = $target->[-1];
1096           }
1097         }
1098         $target->[0] = $data;
1099       } else {
1100         $info->[0] = $const->{$key};
1101       }
1102     }
1103   }
1104
1105   return $info;
1106 }
1107
1108 =head2 result_source
1109
1110 =over 4
1111
1112 =item Arguments: $result_source?
1113
1114 =item Return Value: $result_source
1115
1116 =back
1117
1118 An accessor for the primary ResultSource object from which this ResultSet
1119 is derived.
1120
1121 =head2 result_class
1122
1123 =over 4
1124
1125 =item Arguments: $result_class?
1126
1127 =item Return Value: $result_class
1128
1129 =back
1130
1131 An accessor for the class to use when creating row objects. Defaults to
1132 C<< result_source->result_class >> - which in most cases is the name of the
1133 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1134
1135 Note that changing the result_class will also remove any components
1136 that were originally loaded in the source class via
1137 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1138 in the original source class will not run.
1139
1140 =cut
1141
1142 sub result_class {
1143   my ($self, $result_class) = @_;
1144   if ($result_class) {
1145     $self->ensure_class_loaded($result_class);
1146     $self->_result_class($result_class);
1147   }
1148   $self->_result_class;
1149 }
1150
1151 =head2 count
1152
1153 =over 4
1154
1155 =item Arguments: $cond, \%attrs??
1156
1157 =item Return Value: $count
1158
1159 =back
1160
1161 Performs an SQL C<COUNT> with the same query as the resultset was built
1162 with to find the number of elements. Passing arguments is equivalent to
1163 C<< $rs->search ($cond, \%attrs)->count >>
1164
1165 =cut
1166
1167 sub count {
1168   my $self = shift;
1169   return $self->search(@_)->count if @_ and defined $_[0];
1170   return scalar @{ $self->get_cache } if $self->get_cache;
1171
1172   my $attrs = $self->_resolved_attrs_copy;
1173
1174   # this is a little optimization - it is faster to do the limit
1175   # adjustments in software, instead of a subquery
1176   my $rows = delete $attrs->{rows};
1177   my $offset = delete $attrs->{offset};
1178
1179   my $crs;
1180   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1181     $crs = $self->_count_subq_rs ($attrs);
1182   }
1183   else {
1184     $crs = $self->_count_rs ($attrs);
1185   }
1186   my $count = $crs->next;
1187
1188   $count -= $offset if $offset;
1189   $count = $rows if $rows and $rows < $count;
1190   $count = 0 if ($count < 0);
1191
1192   return $count;
1193 }
1194
1195 =head2 count_rs
1196
1197 =over 4
1198
1199 =item Arguments: $cond, \%attrs??
1200
1201 =item Return Value: $count_rs
1202
1203 =back
1204
1205 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1206 This can be very handy for subqueries:
1207
1208   ->search( { amount => $some_rs->count_rs->as_query } )
1209
1210 As with regular resultsets the SQL query will be executed only after
1211 the resultset is accessed via L</next> or L</all>. That would return
1212 the same single value obtainable via L</count>.
1213
1214 =cut
1215
1216 sub count_rs {
1217   my $self = shift;
1218   return $self->search(@_)->count_rs if @_;
1219
1220   # this may look like a lack of abstraction (count() does about the same)
1221   # but in fact an _rs *must* use a subquery for the limits, as the
1222   # software based limiting can not be ported if this $rs is to be used
1223   # in a subquery itself (i.e. ->as_query)
1224   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1225     return $self->_count_subq_rs;
1226   }
1227   else {
1228     return $self->_count_rs;
1229   }
1230 }
1231
1232 #
1233 # returns a ResultSetColumn object tied to the count query
1234 #
1235 sub _count_rs {
1236   my ($self, $attrs) = @_;
1237
1238   my $rsrc = $self->result_source;
1239   $attrs ||= $self->_resolved_attrs;
1240
1241   my $tmp_attrs = { %$attrs };
1242
1243   # take off any limits, record_filter is cdbi, and no point of ordering a count
1244   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   # read the comment on top of the actual function to see what this does
1251   $tmp_attrs->{from} = $self->result_source->schema->storage->_straight_join_to_node (
1252     $tmp_attrs->{from}, $tmp_attrs->{alias}
1253   );
1254
1255   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1256
1257   return $tmp_rs;
1258 }
1259
1260 #
1261 # same as above but uses a subquery
1262 #
1263 sub _count_subq_rs {
1264   my ($self, $attrs) = @_;
1265
1266   my $rsrc = $self->result_source;
1267   $attrs ||= $self->_resolved_attrs_copy;
1268
1269   my $sub_attrs = { %$attrs };
1270
1271   # extra selectors do not go in the subquery and there is no point of ordering it
1272   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1273
1274   # if we prefetch, we group_by primary keys only as this is what we would get out
1275   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1276   if ( keys %{$attrs->{collapse}} ) {
1277     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1278   }
1279
1280   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1281
1282   # read the comment on top of the actual function to see what this does
1283   $sub_attrs->{from} = $self->result_source->schema->storage->_straight_join_to_node (
1284     $sub_attrs->{from}, $sub_attrs->{alias}
1285   );
1286
1287   # this is so that the query can be simplified e.g.
1288   # * non-limiting joins can be pruned
1289   # * ordering can be thrown away in things like Top limit
1290   $sub_attrs->{-for_count_only} = 1;
1291
1292   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1293
1294   $attrs->{from} = [{
1295     -alias => 'count_subq',
1296     -source_handle => $rsrc->handle,
1297     count_subq => $sub_rs->as_query,
1298   }];
1299
1300   # the subquery replaces this
1301   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1302
1303   return $self->_count_rs ($attrs);
1304 }
1305
1306 sub _bool {
1307   return 1;
1308 }
1309
1310 =head2 count_literal
1311
1312 =over 4
1313
1314 =item Arguments: $sql_fragment, @bind_values
1315
1316 =item Return Value: $count
1317
1318 =back
1319
1320 Counts the results in a literal query. Equivalent to calling L</search_literal>
1321 with the passed arguments, then L</count>.
1322
1323 =cut
1324
1325 sub count_literal { shift->search_literal(@_)->count; }
1326
1327 =head2 all
1328
1329 =over 4
1330
1331 =item Arguments: none
1332
1333 =item Return Value: @objects
1334
1335 =back
1336
1337 Returns all elements in the resultset. Called implicitly if the resultset
1338 is returned in list context.
1339
1340 =cut
1341
1342 sub all {
1343   my $self = shift;
1344   if(@_) {
1345       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1346   }
1347
1348   return @{ $self->get_cache } if $self->get_cache;
1349
1350   my @obj;
1351
1352   if (keys %{$self->_resolved_attrs->{collapse}}) {
1353     # Using $self->cursor->all is really just an optimisation.
1354     # If we're collapsing has_many prefetches it probably makes
1355     # very little difference, and this is cleaner than hacking
1356     # _construct_object to survive the approach
1357     $self->cursor->reset;
1358     my @row = $self->cursor->next;
1359     while (@row) {
1360       push(@obj, $self->_construct_object(@row));
1361       @row = (exists $self->{stashed_row}
1362                ? @{delete $self->{stashed_row}}
1363                : $self->cursor->next);
1364     }
1365   } else {
1366     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1367   }
1368
1369   $self->set_cache(\@obj) if $self->{attrs}{cache};
1370
1371   return @obj;
1372 }
1373
1374 =head2 reset
1375
1376 =over 4
1377
1378 =item Arguments: none
1379
1380 =item Return Value: $self
1381
1382 =back
1383
1384 Resets the resultset's cursor, so you can iterate through the elements again.
1385 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1386 another query.
1387
1388 =cut
1389
1390 sub reset {
1391   my ($self) = @_;
1392   delete $self->{_attrs} if exists $self->{_attrs};
1393   $self->{all_cache_position} = 0;
1394   $self->cursor->reset;
1395   return $self;
1396 }
1397
1398 =head2 first
1399
1400 =over 4
1401
1402 =item Arguments: none
1403
1404 =item Return Value: $object?
1405
1406 =back
1407
1408 Resets the resultset and returns an object for the first result (if the
1409 resultset returns anything).
1410
1411 =cut
1412
1413 sub first {
1414   return $_[0]->reset->next;
1415 }
1416
1417
1418 # _rs_update_delete
1419 #
1420 # Determines whether and what type of subquery is required for the $rs operation.
1421 # If grouping is necessary either supplies its own, or verifies the current one
1422 # After all is done delegates to the proper storage method.
1423
1424 sub _rs_update_delete {
1425   my ($self, $op, $values) = @_;
1426
1427   my $rsrc = $self->result_source;
1428
1429   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1430   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1431
1432   if ($needs_group_by_subq or $needs_subq) {
1433
1434     # make a new $rs selecting only the PKs (that's all we really need)
1435     my $attrs = $self->_resolved_attrs_copy;
1436
1437     delete $attrs->{$_} for qw/collapse select as/;
1438     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1439
1440     if ($needs_group_by_subq) {
1441       # make sure no group_by was supplied, or if there is one - make sure it matches
1442       # the columns compiled above perfectly. Anything else can not be sanely executed
1443       # on most databases so croak right then and there
1444
1445       if (my $g = $attrs->{group_by}) {
1446         my @current_group_by = map
1447           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1448           @$g
1449         ;
1450
1451         if (
1452           join ("\x00", sort @current_group_by)
1453             ne
1454           join ("\x00", sort @{$attrs->{columns}} )
1455         ) {
1456           $self->throw_exception (
1457             "You have just attempted a $op operation on a resultset which does group_by"
1458             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1459             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1460             . ' kind of queries. Please retry the operation with a modified group_by or'
1461             . ' without using one at all.'
1462           );
1463         }
1464       }
1465       else {
1466         $attrs->{group_by} = $attrs->{columns};
1467       }
1468     }
1469
1470     my $subrs = (ref $self)->new($rsrc, $attrs);
1471
1472     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1473   }
1474   else {
1475     return $rsrc->storage->$op(
1476       $rsrc,
1477       $op eq 'update' ? $values : (),
1478       $self->{cond},
1479     );
1480   }
1481 }
1482
1483 =head2 update
1484
1485 =over 4
1486
1487 =item Arguments: \%values
1488
1489 =item Return Value: $storage_rv
1490
1491 =back
1492
1493 Sets the specified columns in the resultset to the supplied values in a
1494 single query. Return value will be true if the update succeeded or false
1495 if no records were updated; exact type of success value is storage-dependent.
1496
1497 =cut
1498
1499 sub update {
1500   my ($self, $values) = @_;
1501   $self->throw_exception('Values for update must be a hash')
1502     unless ref $values eq 'HASH';
1503
1504   return $self->_rs_update_delete ('update', $values);
1505 }
1506
1507 =head2 update_all
1508
1509 =over 4
1510
1511 =item Arguments: \%values
1512
1513 =item Return Value: 1
1514
1515 =back
1516
1517 Fetches all objects and updates them one at a time. Note that C<update_all>
1518 will run DBIC cascade triggers, while L</update> will not.
1519
1520 =cut
1521
1522 sub update_all {
1523   my ($self, $values) = @_;
1524   $self->throw_exception('Values for update_all must be a hash')
1525     unless ref $values eq 'HASH';
1526   foreach my $obj ($self->all) {
1527     $obj->set_columns($values)->update;
1528   }
1529   return 1;
1530 }
1531
1532 =head2 delete
1533
1534 =over 4
1535
1536 =item Arguments: none
1537
1538 =item Return Value: $storage_rv
1539
1540 =back
1541
1542 Deletes the contents of the resultset from its result source. Note that this
1543 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1544 to run. See also L<DBIx::Class::Row/delete>.
1545
1546 Return value will be the amount of rows deleted; exact type of return value
1547 is storage-dependent.
1548
1549 =cut
1550
1551 sub delete {
1552   my $self = shift;
1553   $self->throw_exception('delete does not accept any arguments')
1554     if @_;
1555
1556   return $self->_rs_update_delete ('delete');
1557 }
1558
1559 =head2 delete_all
1560
1561 =over 4
1562
1563 =item Arguments: none
1564
1565 =item Return Value: 1
1566
1567 =back
1568
1569 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1570 will run DBIC cascade triggers, while L</delete> will not.
1571
1572 =cut
1573
1574 sub delete_all {
1575   my $self = shift;
1576   $self->throw_exception('delete_all does not accept any arguments')
1577     if @_;
1578
1579   $_->delete for $self->all;
1580   return 1;
1581 }
1582
1583 =head2 populate
1584
1585 =over 4
1586
1587 =item Arguments: \@data;
1588
1589 =back
1590
1591 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1592 For the arrayref of hashrefs style each hashref should be a structure suitable
1593 forsubmitting to a $resultset->create(...) method.
1594
1595 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1596 to insert the data, as this is a faster method.
1597
1598 Otherwise, each set of data is inserted into the database using
1599 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1600 accumulated into an array. The array itself, or an array reference
1601 is returned depending on scalar or list context.
1602
1603 Example:  Assuming an Artist Class that has many CDs Classes relating:
1604
1605   my $Artist_rs = $schema->resultset("Artist");
1606
1607   ## Void Context Example
1608   $Artist_rs->populate([
1609      { artistid => 4, name => 'Manufactured Crap', cds => [
1610         { title => 'My First CD', year => 2006 },
1611         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1612       ],
1613      },
1614      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1615         { title => 'My parents sold me to a record company' ,year => 2005 },
1616         { title => 'Why Am I So Ugly?', year => 2006 },
1617         { title => 'I Got Surgery and am now Popular', year => 2007 }
1618       ],
1619      },
1620   ]);
1621
1622   ## Array Context Example
1623   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1624     { name => "Artist One"},
1625     { name => "Artist Two"},
1626     { name => "Artist Three", cds=> [
1627     { title => "First CD", year => 2007},
1628     { title => "Second CD", year => 2008},
1629   ]}
1630   ]);
1631
1632   print $ArtistOne->name; ## response is 'Artist One'
1633   print $ArtistThree->cds->count ## reponse is '2'
1634
1635 For the arrayref of arrayrefs style,  the first element should be a list of the
1636 fieldsnames to which the remaining elements are rows being inserted.  For
1637 example:
1638
1639   $Arstist_rs->populate([
1640     [qw/artistid name/],
1641     [100, 'A Formally Unknown Singer'],
1642     [101, 'A singer that jumped the shark two albums ago'],
1643     [102, 'An actually cool singer.'],
1644   ]);
1645
1646 Please note an important effect on your data when choosing between void and
1647 wantarray context. Since void context goes straight to C<insert_bulk> in
1648 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1649 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1650 create primary keys for you, you will find that your PKs are empty.  In this
1651 case you will have to use the wantarray context in order to create those
1652 values.
1653
1654 =cut
1655
1656 sub populate {
1657   my $self = shift @_;
1658   my $data = ref $_[0][0] eq 'HASH'
1659     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1660     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1661
1662   if(defined wantarray) {
1663     my @created;
1664     foreach my $item (@$data) {
1665       push(@created, $self->create($item));
1666     }
1667     return wantarray ? @created : \@created;
1668   } else {
1669     my $first = $data->[0];
1670
1671     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1672     # it relationship data
1673     my (@rels, @columns);
1674     for (keys %$first) {
1675       my $ref = ref $first->{$_};
1676       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1677         ? push @rels, $_
1678         : push @columns, $_
1679       ;
1680     }
1681
1682     my @pks = $self->result_source->primary_columns;
1683
1684     ## do the belongs_to relationships
1685     foreach my $index (0..$#$data) {
1686
1687       # delegate to create() for any dataset without primary keys with specified relationships
1688       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1689         for my $r (@rels) {
1690           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1691             my @ret = $self->populate($data);
1692             return;
1693           }
1694         }
1695       }
1696
1697       foreach my $rel (@rels) {
1698         next unless ref $data->[$index]->{$rel} eq "HASH";
1699         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1700         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1701         my $related = $result->result_source->_resolve_condition(
1702           $result->result_source->relationship_info($reverse)->{cond},
1703           $self,
1704           $result,
1705         );
1706
1707         delete $data->[$index]->{$rel};
1708         $data->[$index] = {%{$data->[$index]}, %$related};
1709
1710         push @columns, keys %$related if $index == 0;
1711       }
1712     }
1713
1714     ## do bulk insert on current row
1715     $self->result_source->storage->insert_bulk(
1716       $self->result_source,
1717       \@columns,
1718       [ map { [ @$_{@columns} ] } @$data ],
1719     );
1720
1721     ## do the has_many relationships
1722     foreach my $item (@$data) {
1723
1724       foreach my $rel (@rels) {
1725         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1726
1727         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1728      || $self->throw_exception('Cannot find the relating object.');
1729
1730         my $child = $parent->$rel;
1731
1732         my $related = $child->result_source->_resolve_condition(
1733           $parent->result_source->relationship_info($rel)->{cond},
1734           $child,
1735           $parent,
1736         );
1737
1738         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1739         my @populate = map { {%$_, %$related} } @rows_to_add;
1740
1741         $child->populate( \@populate );
1742       }
1743     }
1744   }
1745 }
1746
1747 =head2 _normalize_populate_args ($args)
1748
1749 Private method used by L</populate> to normalize its incoming arguments.  Factored
1750 out in case you want to subclass and accept new argument structures to the
1751 L</populate> method.
1752
1753 =cut
1754
1755 sub _normalize_populate_args {
1756   my ($self, $data) = @_;
1757   my @names = @{shift(@$data)};
1758   my @results_to_create;
1759   foreach my $datum (@$data) {
1760     my %result_to_create;
1761     foreach my $index (0..$#names) {
1762       $result_to_create{$names[$index]} = $$datum[$index];
1763     }
1764     push @results_to_create, \%result_to_create;
1765   }
1766   return \@results_to_create;
1767 }
1768
1769 =head2 pager
1770
1771 =over 4
1772
1773 =item Arguments: none
1774
1775 =item Return Value: $pager
1776
1777 =back
1778
1779 Return Value a L<Data::Page> object for the current resultset. Only makes
1780 sense for queries with a C<page> attribute.
1781
1782 To get the full count of entries for a paged resultset, call
1783 C<total_entries> on the L<Data::Page> object.
1784
1785 =cut
1786
1787 sub pager {
1788   my ($self) = @_;
1789
1790   return $self->{pager} if $self->{pager};
1791
1792   my $attrs = $self->{attrs};
1793   $self->throw_exception("Can't create pager for non-paged rs")
1794     unless $self->{attrs}{page};
1795   $attrs->{rows} ||= 10;
1796
1797   # throw away the paging flags and re-run the count (possibly
1798   # with a subselect) to get the real total count
1799   my $count_attrs = { %$attrs };
1800   delete $count_attrs->{$_} for qw/rows offset page pager/;
1801   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1802
1803   return $self->{pager} = Data::Page->new(
1804     $total_count,
1805     $attrs->{rows},
1806     $self->{attrs}{page}
1807   );
1808 }
1809
1810 =head2 page
1811
1812 =over 4
1813
1814 =item Arguments: $page_number
1815
1816 =item Return Value: $rs
1817
1818 =back
1819
1820 Returns a resultset for the $page_number page of the resultset on which page
1821 is called, where each page contains a number of rows equal to the 'rows'
1822 attribute set on the resultset (10 by default).
1823
1824 =cut
1825
1826 sub page {
1827   my ($self, $page) = @_;
1828   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1829 }
1830
1831 =head2 new_result
1832
1833 =over 4
1834
1835 =item Arguments: \%vals
1836
1837 =item Return Value: $rowobject
1838
1839 =back
1840
1841 Creates a new row object in the resultset's result class and returns
1842 it. The row is not inserted into the database at this point, call
1843 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1844 will tell you whether the row object has been inserted or not.
1845
1846 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1847
1848 =cut
1849
1850 sub new_result {
1851   my ($self, $values) = @_;
1852   $self->throw_exception( "new_result needs a hash" )
1853     unless (ref $values eq 'HASH');
1854
1855   my %new;
1856   my $alias = $self->{attrs}{alias};
1857
1858   if (
1859     defined $self->{cond}
1860     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1861   ) {
1862     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1863     $new{-from_resultset} = [ keys %new ] if keys %new;
1864   } else {
1865     $self->throw_exception(
1866       "Can't abstract implicit construct, condition not a hash"
1867     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1868
1869     my $collapsed_cond = (
1870       $self->{cond}
1871         ? $self->_collapse_cond($self->{cond})
1872         : {}
1873     );
1874
1875     # precendence must be given to passed values over values inherited from
1876     # the cond, so the order here is important.
1877     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1878     while( my($col,$value) = each %implied ){
1879       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1880         $new{$col} = $value->{'='};
1881         next;
1882       }
1883       $new{$col} = $value if $self->_is_deterministic_value($value);
1884     }
1885   }
1886
1887   %new = (
1888     %new,
1889     %{ $self->_remove_alias($values, $alias) },
1890     -source_handle => $self->_source_handle,
1891     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1892   );
1893
1894   return $self->result_class->new(\%new);
1895 }
1896
1897 # _is_deterministic_value
1898 #
1899 # Make an effor to strip non-deterministic values from the condition,
1900 # to make sure new_result chokes less
1901
1902 sub _is_deterministic_value {
1903   my $self = shift;
1904   my $value = shift;
1905   my $ref_type = ref $value;
1906   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1907   return 1 if Scalar::Util::blessed($value);
1908   return 0;
1909 }
1910
1911 # _has_resolved_attr
1912 #
1913 # determines if the resultset defines at least one
1914 # of the attributes supplied
1915 #
1916 # used to determine if a subquery is neccessary
1917 #
1918 # supports some virtual attributes:
1919 #   -join
1920 #     This will scan for any joins being present on the resultset.
1921 #     It is not a mere key-search but a deep inspection of {from}
1922 #
1923
1924 sub _has_resolved_attr {
1925   my ($self, @attr_names) = @_;
1926
1927   my $attrs = $self->_resolved_attrs;
1928
1929   my %extra_checks;
1930
1931   for my $n (@attr_names) {
1932     if (grep { $n eq $_ } (qw/-join/) ) {
1933       $extra_checks{$n}++;
1934       next;
1935     }
1936
1937     my $attr =  $attrs->{$n};
1938
1939     next if not defined $attr;
1940
1941     if (ref $attr eq 'HASH') {
1942       return 1 if keys %$attr;
1943     }
1944     elsif (ref $attr eq 'ARRAY') {
1945       return 1 if @$attr;
1946     }
1947     else {
1948       return 1 if $attr;
1949     }
1950   }
1951
1952   # a resolved join is expressed as a multi-level from
1953   return 1 if (
1954     $extra_checks{-join}
1955       and
1956     ref $attrs->{from} eq 'ARRAY'
1957       and
1958     @{$attrs->{from}} > 1
1959   );
1960
1961   return 0;
1962 }
1963
1964 # _collapse_cond
1965 #
1966 # Recursively collapse the condition.
1967
1968 sub _collapse_cond {
1969   my ($self, $cond, $collapsed) = @_;
1970
1971   $collapsed ||= {};
1972
1973   if (ref $cond eq 'ARRAY') {
1974     foreach my $subcond (@$cond) {
1975       next unless ref $subcond;  # -or
1976       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1977     }
1978   }
1979   elsif (ref $cond eq 'HASH') {
1980     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1981       foreach my $subcond (@{$cond->{-and}}) {
1982         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1983       }
1984     }
1985     else {
1986       foreach my $col (keys %$cond) {
1987         my $value = $cond->{$col};
1988         $collapsed->{$col} = $value;
1989       }
1990     }
1991   }
1992
1993   return $collapsed;
1994 }
1995
1996 # _remove_alias
1997 #
1998 # Remove the specified alias from the specified query hash. A copy is made so
1999 # the original query is not modified.
2000
2001 sub _remove_alias {
2002   my ($self, $query, $alias) = @_;
2003
2004   my %orig = %{ $query || {} };
2005   my %unaliased;
2006
2007   foreach my $key (keys %orig) {
2008     if ($key !~ /\./) {
2009       $unaliased{$key} = $orig{$key};
2010       next;
2011     }
2012     $unaliased{$1} = $orig{$key}
2013       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2014   }
2015
2016   return \%unaliased;
2017 }
2018
2019 =head2 as_query (EXPERIMENTAL)
2020
2021 =over 4
2022
2023 =item Arguments: none
2024
2025 =item Return Value: \[ $sql, @bind ]
2026
2027 =back
2028
2029 Returns the SQL query and bind vars associated with the invocant.
2030
2031 This is generally used as the RHS for a subquery.
2032
2033 B<NOTE>: This feature is still experimental.
2034
2035 =cut
2036
2037 sub as_query {
2038   my $self = shift;
2039
2040   my $attrs = $self->_resolved_attrs_copy;
2041
2042   # For future use:
2043   #
2044   # in list ctx:
2045   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2046   # $sql also has no wrapping parenthesis in list ctx
2047   #
2048   my $sqlbind = $self->result_source->storage
2049     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2050
2051   return $sqlbind;
2052 }
2053
2054 =head2 find_or_new
2055
2056 =over 4
2057
2058 =item Arguments: \%vals, \%attrs?
2059
2060 =item Return Value: $rowobject
2061
2062 =back
2063
2064   my $artist = $schema->resultset('Artist')->find_or_new(
2065     { artist => 'fred' }, { key => 'artists' });
2066
2067   $cd->cd_to_producer->find_or_new({ producer => $producer },
2068                                    { key => 'primary });
2069
2070 Find an existing record from this resultset, based on its primary
2071 key, or a unique constraint. If none exists, instantiate a new result
2072 object and return it. The object will not be saved into your storage
2073 until you call L<DBIx::Class::Row/insert> on it.
2074
2075 You most likely want this method when looking for existing rows using
2076 a unique constraint that is not the primary key, or looking for
2077 related rows.
2078
2079 If you want objects to be saved immediately, use L</find_or_create>
2080 instead.
2081
2082 B<Note>: Take care when using C<find_or_new> with a table having
2083 columns with default values that you intend to be automatically
2084 supplied by the database (e.g. an auto_increment primary key column).
2085 In normal usage, the value of such columns should NOT be included at
2086 all in the call to C<find_or_new>, even when set to C<undef>.
2087
2088 =cut
2089
2090 sub find_or_new {
2091   my $self     = shift;
2092   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2093   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2094   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2095     return $row;
2096   }
2097   return $self->new_result($hash);
2098 }
2099
2100 =head2 create
2101
2102 =over 4
2103
2104 =item Arguments: \%vals
2105
2106 =item Return Value: a L<DBIx::Class::Row> $object
2107
2108 =back
2109
2110 Attempt to create a single new row or a row with multiple related rows
2111 in the table represented by the resultset (and related tables). This
2112 will not check for duplicate rows before inserting, use
2113 L</find_or_create> to do that.
2114
2115 To create one row for this resultset, pass a hashref of key/value
2116 pairs representing the columns of the table and the values you wish to
2117 store. If the appropriate relationships are set up, foreign key fields
2118 can also be passed an object representing the foreign row, and the
2119 value will be set to its primary key.
2120
2121 To create related objects, pass a hashref of related-object column values
2122 B<keyed on the relationship name>. If the relationship is of type C<multi>
2123 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2124 The process will correctly identify columns holding foreign keys, and will
2125 transparrently populate them from the keys of the corresponding relation.
2126 This can be applied recursively, and will work correctly for a structure
2127 with an arbitrary depth and width, as long as the relationships actually
2128 exists and the correct column data has been supplied.
2129
2130
2131 Instead of hashrefs of plain related data (key/value pairs), you may
2132 also pass new or inserted objects. New objects (not inserted yet, see
2133 L</new>), will be inserted into their appropriate tables.
2134
2135 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2136
2137 Example of creating a new row.
2138
2139   $person_rs->create({
2140     name=>"Some Person",
2141     email=>"somebody@someplace.com"
2142   });
2143
2144 Example of creating a new row and also creating rows in a related C<has_many>
2145 or C<has_one> resultset.  Note Arrayref.
2146
2147   $artist_rs->create(
2148      { artistid => 4, name => 'Manufactured Crap', cds => [
2149         { title => 'My First CD', year => 2006 },
2150         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2151       ],
2152      },
2153   );
2154
2155 Example of creating a new row and also creating a row in a related
2156 C<belongs_to>resultset. Note Hashref.
2157
2158   $cd_rs->create({
2159     title=>"Music for Silly Walks",
2160     year=>2000,
2161     artist => {
2162       name=>"Silly Musician",
2163     }
2164   });
2165
2166 =over
2167
2168 =item WARNING
2169
2170 When subclassing ResultSet never attempt to override this method. Since
2171 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2172 lot of the internals simply never call it, so your override will be
2173 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2174 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2175 L</create> process you need to intervene.
2176
2177 =back
2178
2179 =cut
2180
2181 sub create {
2182   my ($self, $attrs) = @_;
2183   $self->throw_exception( "create needs a hashref" )
2184     unless ref $attrs eq 'HASH';
2185   return $self->new_result($attrs)->insert;
2186 }
2187
2188 =head2 find_or_create
2189
2190 =over 4
2191
2192 =item Arguments: \%vals, \%attrs?
2193
2194 =item Return Value: $rowobject
2195
2196 =back
2197
2198   $cd->cd_to_producer->find_or_create({ producer => $producer },
2199                                       { key => 'primary' });
2200
2201 Tries to find a record based on its primary key or unique constraints; if none
2202 is found, creates one and returns that instead.
2203
2204   my $cd = $schema->resultset('CD')->find_or_create({
2205     cdid   => 5,
2206     artist => 'Massive Attack',
2207     title  => 'Mezzanine',
2208     year   => 2005,
2209   });
2210
2211 Also takes an optional C<key> attribute, to search by a specific key or unique
2212 constraint. For example:
2213
2214   my $cd = $schema->resultset('CD')->find_or_create(
2215     {
2216       artist => 'Massive Attack',
2217       title  => 'Mezzanine',
2218     },
2219     { key => 'cd_artist_title' }
2220   );
2221
2222 B<Note>: Because find_or_create() reads from the database and then
2223 possibly inserts based on the result, this method is subject to a race
2224 condition. Another process could create a record in the table after
2225 the find has completed and before the create has started. To avoid
2226 this problem, use find_or_create() inside a transaction.
2227
2228 B<Note>: Take care when using C<find_or_create> with a table having
2229 columns with default values that you intend to be automatically
2230 supplied by the database (e.g. an auto_increment primary key column).
2231 In normal usage, the value of such columns should NOT be included at
2232 all in the call to C<find_or_create>, even when set to C<undef>.
2233
2234 See also L</find> and L</update_or_create>. For information on how to declare
2235 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2236
2237 =cut
2238
2239 sub find_or_create {
2240   my $self     = shift;
2241   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2242   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2243   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2244     return $row;
2245   }
2246   return $self->create($hash);
2247 }
2248
2249 =head2 update_or_create
2250
2251 =over 4
2252
2253 =item Arguments: \%col_values, { key => $unique_constraint }?
2254
2255 =item Return Value: $rowobject
2256
2257 =back
2258
2259   $resultset->update_or_create({ col => $val, ... });
2260
2261 First, searches for an existing row matching one of the unique constraints
2262 (including the primary key) on the source of this resultset. If a row is
2263 found, updates it with the other given column values. Otherwise, creates a new
2264 row.
2265
2266 Takes an optional C<key> attribute to search on a specific unique constraint.
2267 For example:
2268
2269   # In your application
2270   my $cd = $schema->resultset('CD')->update_or_create(
2271     {
2272       artist => 'Massive Attack',
2273       title  => 'Mezzanine',
2274       year   => 1998,
2275     },
2276     { key => 'cd_artist_title' }
2277   );
2278
2279   $cd->cd_to_producer->update_or_create({
2280     producer => $producer,
2281     name => 'harry',
2282   }, {
2283     key => 'primary,
2284   });
2285
2286
2287 If no C<key> is specified, it searches on all unique constraints defined on the
2288 source, including the primary key.
2289
2290 If the C<key> is specified as C<primary>, it searches only on the primary key.
2291
2292 See also L</find> and L</find_or_create>. For information on how to declare
2293 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2294
2295 B<Note>: Take care when using C<update_or_create> with a table having
2296 columns with default values that you intend to be automatically
2297 supplied by the database (e.g. an auto_increment primary key column).
2298 In normal usage, the value of such columns should NOT be included at
2299 all in the call to C<update_or_create>, even when set to C<undef>.
2300
2301 =cut
2302
2303 sub update_or_create {
2304   my $self = shift;
2305   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2306   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2307
2308   my $row = $self->find($cond, $attrs);
2309   if (defined $row) {
2310     $row->update($cond);
2311     return $row;
2312   }
2313
2314   return $self->create($cond);
2315 }
2316
2317 =head2 update_or_new
2318
2319 =over 4
2320
2321 =item Arguments: \%col_values, { key => $unique_constraint }?
2322
2323 =item Return Value: $rowobject
2324
2325 =back
2326
2327   $resultset->update_or_new({ col => $val, ... });
2328
2329 First, searches for an existing row matching one of the unique constraints
2330 (including the primary key) on the source of this resultset. If a row is
2331 found, updates it with the other given column values. Otherwise, instantiate
2332 a new result object and return it. The object will not be saved into your storage
2333 until you call L<DBIx::Class::Row/insert> on it.
2334
2335 Takes an optional C<key> attribute to search on a specific unique constraint.
2336 For example:
2337
2338   # In your application
2339   my $cd = $schema->resultset('CD')->update_or_new(
2340     {
2341       artist => 'Massive Attack',
2342       title  => 'Mezzanine',
2343       year   => 1998,
2344     },
2345     { key => 'cd_artist_title' }
2346   );
2347
2348   if ($cd->in_storage) {
2349       # the cd was updated
2350   }
2351   else {
2352       # the cd is not yet in the database, let's insert it
2353       $cd->insert;
2354   }
2355
2356 B<Note>: Take care when using C<update_or_new> with a table having
2357 columns with default values that you intend to be automatically
2358 supplied by the database (e.g. an auto_increment primary key column).
2359 In normal usage, the value of such columns should NOT be included at
2360 all in the call to C<update_or_new>, even when set to C<undef>.
2361
2362 See also L</find>, L</find_or_create> and L</find_or_new>.
2363
2364 =cut
2365
2366 sub update_or_new {
2367     my $self  = shift;
2368     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2369     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2370
2371     my $row = $self->find( $cond, $attrs );
2372     if ( defined $row ) {
2373         $row->update($cond);
2374         return $row;
2375     }
2376
2377     return $self->new_result($cond);
2378 }
2379
2380 =head2 get_cache
2381
2382 =over 4
2383
2384 =item Arguments: none
2385
2386 =item Return Value: \@cache_objects?
2387
2388 =back
2389
2390 Gets the contents of the cache for the resultset, if the cache is set.
2391
2392 The cache is populated either by using the L</prefetch> attribute to
2393 L</search> or by calling L</set_cache>.
2394
2395 =cut
2396
2397 sub get_cache {
2398   shift->{all_cache};
2399 }
2400
2401 =head2 set_cache
2402
2403 =over 4
2404
2405 =item Arguments: \@cache_objects
2406
2407 =item Return Value: \@cache_objects
2408
2409 =back
2410
2411 Sets the contents of the cache for the resultset. Expects an arrayref
2412 of objects of the same class as those produced by the resultset. Note that
2413 if the cache is set the resultset will return the cached objects rather
2414 than re-querying the database even if the cache attr is not set.
2415
2416 The contents of the cache can also be populated by using the
2417 L</prefetch> attribute to L</search>.
2418
2419 =cut
2420
2421 sub set_cache {
2422   my ( $self, $data ) = @_;
2423   $self->throw_exception("set_cache requires an arrayref")
2424       if defined($data) && (ref $data ne 'ARRAY');
2425   $self->{all_cache} = $data;
2426 }
2427
2428 =head2 clear_cache
2429
2430 =over 4
2431
2432 =item Arguments: none
2433
2434 =item Return Value: []
2435
2436 =back
2437
2438 Clears the cache for the resultset.
2439
2440 =cut
2441
2442 sub clear_cache {
2443   shift->set_cache(undef);
2444 }
2445
2446 =head2 is_paged
2447
2448 =over 4
2449
2450 =item Arguments: none
2451
2452 =item Return Value: true, if the resultset has been paginated
2453
2454 =back
2455
2456 =cut
2457
2458 sub is_paged {
2459   my ($self) = @_;
2460   return !!$self->{attrs}{page};
2461 }
2462
2463 =head2 related_resultset
2464
2465 =over 4
2466
2467 =item Arguments: $relationship_name
2468
2469 =item Return Value: $resultset
2470
2471 =back
2472
2473 Returns a related resultset for the supplied relationship name.
2474
2475   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2476
2477 =cut
2478
2479 sub related_resultset {
2480   my ($self, $rel) = @_;
2481
2482   $self->{related_resultsets} ||= {};
2483   return $self->{related_resultsets}{$rel} ||= do {
2484     my $rel_info = $self->result_source->relationship_info($rel);
2485
2486     $self->throw_exception(
2487       "search_related: result source '" . $self->result_source->source_name .
2488         "' has no such relationship $rel")
2489       unless $rel_info;
2490
2491     my ($from,$seen) = $self->_chain_relationship($rel);
2492
2493     my $join_count = $seen->{$rel};
2494     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2495
2496     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2497     my %attrs = %{$self->{attrs}||{}};
2498     delete @attrs{qw(result_class alias)};
2499
2500     my $new_cache;
2501
2502     if (my $cache = $self->get_cache) {
2503       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2504         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2505                         @$cache ];
2506       }
2507     }
2508
2509     my $rel_source = $self->result_source->related_source($rel);
2510
2511     my $new = do {
2512
2513       # The reason we do this now instead of passing the alias to the
2514       # search_rs below is that if you wrap/overload resultset on the
2515       # source you need to know what alias it's -going- to have for things
2516       # to work sanely (e.g. RestrictWithObject wants to be able to add
2517       # extra query restrictions, and these may need to be $alias.)
2518
2519       my $attrs = $rel_source->resultset_attributes;
2520       local $attrs->{alias} = $alias;
2521
2522       $rel_source->resultset
2523                  ->search_rs(
2524                      undef, {
2525                        %attrs,
2526                        join => undef,
2527                        prefetch => undef,
2528                        select => undef,
2529                        as => undef,
2530                        where => $self->{cond},
2531                        seen_join => $seen,
2532                        from => $from,
2533                    });
2534     };
2535     $new->set_cache($new_cache) if $new_cache;
2536     $new;
2537   };
2538 }
2539
2540 =head2 current_source_alias
2541
2542 =over 4
2543
2544 =item Arguments: none
2545
2546 =item Return Value: $source_alias
2547
2548 =back
2549
2550 Returns the current table alias for the result source this resultset is built
2551 on, that will be used in the SQL query. Usually it is C<me>.
2552
2553 Currently the source alias that refers to the result set returned by a
2554 L</search>/L</find> family method depends on how you got to the resultset: it's
2555 C<me> by default, but eg. L</search_related> aliases it to the related result
2556 source name (and keeps C<me> referring to the original result set). The long
2557 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2558 (and make this method unnecessary).
2559
2560 Thus it's currently necessary to use this method in predefined queries (see
2561 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2562 source alias of the current result set:
2563
2564   # in a result set class
2565   sub modified_by {
2566     my ($self, $user) = @_;
2567
2568     my $me = $self->current_source_alias;
2569
2570     return $self->search(
2571       "$me.modified" => $user->id,
2572     );
2573   }
2574
2575 =cut
2576
2577 sub current_source_alias {
2578   my ($self) = @_;
2579
2580   return ($self->{attrs} || {})->{alias} || 'me';
2581 }
2582
2583 # This code is called by search_related, and makes sure there
2584 # is clear separation between the joins before, during, and
2585 # after the relationship. This information is needed later
2586 # in order to properly resolve prefetch aliases (any alias
2587 # with a relation_chain_depth less than the depth of the
2588 # current prefetch is not considered)
2589 #
2590 # The increments happen in 1/2s to make it easier to correlate the
2591 # join depth with the join path. An integer means a relationship
2592 # specified via a search_related, whereas a fraction means an added
2593 # join/prefetch via attributes
2594 sub _chain_relationship {
2595   my ($self, $rel) = @_;
2596   my $source = $self->result_source;
2597   my $attrs = $self->{attrs};
2598
2599   my $from = [ @{
2600       $attrs->{from}
2601         ||
2602       [{
2603         -source_handle => $source->handle,
2604         -alias => $attrs->{alias},
2605         $attrs->{alias} => $source->from,
2606       }]
2607   }];
2608
2609   my $seen = { %{$attrs->{seen_join} || {} } };
2610   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2611     ? $from->[-1][0]{-join_path}
2612     : [];
2613
2614
2615   # we need to take the prefetch the attrs into account before we
2616   # ->_resolve_join as otherwise they get lost - captainL
2617   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2618
2619   my @requested_joins = $source->_resolve_join(
2620     $merged,
2621     $attrs->{alias},
2622     $seen,
2623     $jpath,
2624   );
2625
2626   push @$from, @requested_joins;
2627
2628   $seen->{-relation_chain_depth} += 0.5;
2629
2630   # if $self already had a join/prefetch specified on it, the requested
2631   # $rel might very well be already included. What we do in this case
2632   # is effectively a no-op (except that we bump up the chain_depth on
2633   # the join in question so we could tell it *is* the search_related)
2634   my $already_joined;
2635
2636
2637   # we consider the last one thus reverse
2638   for my $j (reverse @requested_joins) {
2639     if ($rel eq $j->[0]{-join_path}[-1]) {
2640       $j->[0]{-relation_chain_depth} += 0.5;
2641       $already_joined++;
2642       last;
2643     }
2644   }
2645
2646 # alternative way to scan the entire chain - not backwards compatible
2647 #  for my $j (reverse @$from) {
2648 #    next unless ref $j eq 'ARRAY';
2649 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2650 #      $j->[0]{-relation_chain_depth} += 0.5;
2651 #      $already_joined++;
2652 #      last;
2653 #    }
2654 #  }
2655
2656   unless ($already_joined) {
2657     push @$from, $source->_resolve_join(
2658       $rel,
2659       $attrs->{alias},
2660       $seen,
2661       $jpath,
2662     );
2663   }
2664
2665   $seen->{-relation_chain_depth} += 0.5;
2666
2667   return ($from,$seen);
2668 }
2669
2670 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2671 sub _resolved_attrs_copy {
2672   my $self = shift;
2673   return { %{$self->_resolved_attrs (@_)} };
2674 }
2675
2676 sub _resolved_attrs {
2677   my $self = shift;
2678   return $self->{_attrs} if $self->{_attrs};
2679
2680   my $attrs  = { %{ $self->{attrs} || {} } };
2681   my $source = $self->result_source;
2682   my $alias  = $attrs->{alias};
2683
2684   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2685   my @colbits;
2686
2687   # build columns (as long as select isn't set) into a set of as/select hashes
2688   unless ( $attrs->{select} ) {
2689
2690     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2691       ? @{ delete $attrs->{columns}}
2692       : (
2693           ( delete $attrs->{columns} )
2694             ||
2695           $source->columns
2696         )
2697     ;
2698
2699     @colbits = map {
2700       ( ref($_) eq 'HASH' )
2701       ? $_
2702       : {
2703           (
2704             /^\Q${alias}.\E(.+)$/
2705               ? "$1"
2706               : "$_"
2707           )
2708             =>
2709           (
2710             /\./
2711               ? "$_"
2712               : "${alias}.$_"
2713           )
2714         }
2715     } @cols;
2716   }
2717
2718   # add the additional columns on
2719   foreach ( 'include_columns', '+columns' ) {
2720       push @colbits, map {
2721           ( ref($_) eq 'HASH' )
2722             ? $_
2723             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2724       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2725   }
2726
2727   # start with initial select items
2728   if ( $attrs->{select} ) {
2729     $attrs->{select} =
2730         ( ref $attrs->{select} eq 'ARRAY' )
2731       ? [ @{ $attrs->{select} } ]
2732       : [ $attrs->{select} ];
2733     $attrs->{as} = (
2734       $attrs->{as}
2735       ? (
2736         ref $attrs->{as} eq 'ARRAY'
2737         ? [ @{ $attrs->{as} } ]
2738         : [ $attrs->{as} ]
2739         )
2740       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2741     );
2742   }
2743   else {
2744
2745     # otherwise we intialise select & as to empty
2746     $attrs->{select} = [];
2747     $attrs->{as}     = [];
2748   }
2749
2750   # now add colbits to select/as
2751   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2752   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2753
2754   my $adds;
2755   if ( $adds = delete $attrs->{'+select'} ) {
2756     $adds = [$adds] unless ref $adds eq 'ARRAY';
2757     push(
2758       @{ $attrs->{select} },
2759       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2760     );
2761   }
2762   if ( $adds = delete $attrs->{'+as'} ) {
2763     $adds = [$adds] unless ref $adds eq 'ARRAY';
2764     push( @{ $attrs->{as} }, @$adds );
2765   }
2766
2767   $attrs->{from} ||= [ {
2768     -source_handle => $source->handle,
2769     -alias => $self->{attrs}{alias},
2770     $self->{attrs}{alias} => $source->from,
2771   } ];
2772
2773   if ( $attrs->{join} || $attrs->{prefetch} ) {
2774
2775     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2776       if ref $attrs->{from} ne 'ARRAY';
2777
2778     my $join = delete $attrs->{join} || {};
2779
2780     if ( defined $attrs->{prefetch} ) {
2781       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2782     }
2783
2784     $attrs->{from} =    # have to copy here to avoid corrupting the original
2785       [
2786         @{ $attrs->{from} },
2787         $source->_resolve_join(
2788           $join,
2789           $alias,
2790           { %{ $attrs->{seen_join} || {} } },
2791           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2792             ? $attrs->{from}[-1][0]{-join_path}
2793             : []
2794           ,
2795         )
2796       ];
2797   }
2798
2799   if ( defined $attrs->{order_by} ) {
2800     $attrs->{order_by} = (
2801       ref( $attrs->{order_by} ) eq 'ARRAY'
2802       ? [ @{ $attrs->{order_by} } ]
2803       : [ $attrs->{order_by} || () ]
2804     );
2805   }
2806
2807   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2808     $attrs->{group_by} = [ $attrs->{group_by} ];
2809   }
2810
2811   # generate the distinct induced group_by early, as prefetch will be carried via a
2812   # subquery (since a group_by is present)
2813   if (delete $attrs->{distinct}) {
2814     if ($attrs->{group_by}) {
2815       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2816     }
2817     else {
2818       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2819     }
2820   }
2821
2822   $attrs->{collapse} ||= {};
2823   if ( my $prefetch = delete $attrs->{prefetch} ) {
2824     $prefetch = $self->_merge_attr( {}, $prefetch );
2825
2826     my $prefetch_ordering = [];
2827
2828     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2829
2830     my @prefetch =
2831       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2832
2833     # we need to somehow mark which columns came from prefetch
2834     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2835
2836     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2837     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2838
2839     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2840     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2841   }
2842
2843   # if both page and offset are specified, produce a combined offset
2844   # even though it doesn't make much sense, this is what pre 081xx has
2845   # been doing
2846   if (my $page = delete $attrs->{page}) {
2847     $attrs->{offset} =
2848       ($attrs->{rows} * ($page - 1))
2849             +
2850       ($attrs->{offset} || 0)
2851     ;
2852   }
2853
2854   return $self->{_attrs} = $attrs;
2855 }
2856
2857 sub _joinpath_aliases {
2858   my ($self, $fromspec, $seen) = @_;
2859
2860   my $paths = {};
2861   return $paths unless ref $fromspec eq 'ARRAY';
2862
2863   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2864
2865   if (int ($cur_depth) != $cur_depth) {
2866     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2867   }
2868
2869   for my $j (@$fromspec) {
2870
2871     next if ref $j ne 'ARRAY';
2872     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2873
2874     my $jpath = $j->[0]{-join_path};
2875
2876     my $p = $paths;
2877     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2878     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2879   }
2880
2881   return $paths;
2882 }
2883
2884 sub _rollout_attr {
2885   my ($self, $attr) = @_;
2886
2887   if (ref $attr eq 'HASH') {
2888     return $self->_rollout_hash($attr);
2889   } elsif (ref $attr eq 'ARRAY') {
2890     return $self->_rollout_array($attr);
2891   } else {
2892     return [$attr];
2893   }
2894 }
2895
2896 sub _rollout_array {
2897   my ($self, $attr) = @_;
2898
2899   my @rolled_array;
2900   foreach my $element (@{$attr}) {
2901     if (ref $element eq 'HASH') {
2902       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2903     } elsif (ref $element eq 'ARRAY') {
2904       #  XXX - should probably recurse here
2905       push( @rolled_array, @{$self->_rollout_array($element)} );
2906     } else {
2907       push( @rolled_array, $element );
2908     }
2909   }
2910   return \@rolled_array;
2911 }
2912
2913 sub _rollout_hash {
2914   my ($self, $attr) = @_;
2915
2916   my @rolled_array;
2917   foreach my $key (keys %{$attr}) {
2918     push( @rolled_array, { $key => $attr->{$key} } );
2919   }
2920   return \@rolled_array;
2921 }
2922
2923 sub _calculate_score {
2924   my ($self, $a, $b) = @_;
2925
2926   if (defined $a xor defined $b) {
2927     return 0;
2928   }
2929   elsif (not defined $a) {
2930     return 1;
2931   }
2932
2933   if (ref $b eq 'HASH') {
2934     my ($b_key) = keys %{$b};
2935     if (ref $a eq 'HASH') {
2936       my ($a_key) = keys %{$a};
2937       if ($a_key eq $b_key) {
2938         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2939       } else {
2940         return 0;
2941       }
2942     } else {
2943       return ($a eq $b_key) ? 1 : 0;
2944     }
2945   } else {
2946     if (ref $a eq 'HASH') {
2947       my ($a_key) = keys %{$a};
2948       return ($b eq $a_key) ? 1 : 0;
2949     } else {
2950       return ($b eq $a) ? 1 : 0;
2951     }
2952   }
2953 }
2954
2955 sub _merge_attr {
2956   my ($self, $orig, $import) = @_;
2957
2958   return $import unless defined($orig);
2959   return $orig unless defined($import);
2960
2961   $orig = $self->_rollout_attr($orig);
2962   $import = $self->_rollout_attr($import);
2963
2964   my $seen_keys;
2965   foreach my $import_element ( @{$import} ) {
2966     # find best candidate from $orig to merge $b_element into
2967     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2968     foreach my $orig_element ( @{$orig} ) {
2969       my $score = $self->_calculate_score( $orig_element, $import_element );
2970       if ($score > $best_candidate->{score}) {
2971         $best_candidate->{position} = $position;
2972         $best_candidate->{score} = $score;
2973       }
2974       $position++;
2975     }
2976     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2977
2978     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2979       push( @{$orig}, $import_element );
2980     } else {
2981       my $orig_best = $orig->[$best_candidate->{position}];
2982       # merge orig_best and b_element together and replace original with merged
2983       if (ref $orig_best ne 'HASH') {
2984         $orig->[$best_candidate->{position}] = $import_element;
2985       } elsif (ref $import_element eq 'HASH') {
2986         my ($key) = keys %{$orig_best};
2987         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2988       }
2989     }
2990     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2991   }
2992
2993   return $orig;
2994 }
2995
2996 sub result_source {
2997     my $self = shift;
2998
2999     if (@_) {
3000         $self->_source_handle($_[0]->handle);
3001     } else {
3002         $self->_source_handle->resolve;
3003     }
3004 }
3005
3006 =head2 throw_exception
3007
3008 See L<DBIx::Class::Schema/throw_exception> for details.
3009
3010 =cut
3011
3012 sub throw_exception {
3013   my $self=shift;
3014
3015   if (ref $self && $self->_source_handle->schema) {
3016     $self->_source_handle->schema->throw_exception(@_)
3017   }
3018   else {
3019     DBIx::Class::Exception->throw(@_);
3020   }
3021 }
3022
3023 # XXX: FIXME: Attributes docs need clearing up
3024
3025 =head1 ATTRIBUTES
3026
3027 Attributes are used to refine a ResultSet in various ways when
3028 searching for data. They can be passed to any method which takes an
3029 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3030 L</count>.
3031
3032 These are in no particular order:
3033
3034 =head2 order_by
3035
3036 =over 4
3037
3038 =item Value: ( $order_by | \@order_by | \%order_by )
3039
3040 =back
3041
3042 Which column(s) to order the results by.
3043
3044 [The full list of suitable values is documented in
3045 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3046 common options.]
3047
3048 If a single column name, or an arrayref of names is supplied, the
3049 argument is passed through directly to SQL. The hashref syntax allows
3050 for connection-agnostic specification of ordering direction:
3051
3052  For descending order:
3053
3054   order_by => { -desc => [qw/col1 col2 col3/] }
3055
3056  For explicit ascending order:
3057
3058   order_by => { -asc => 'col' }
3059
3060 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3061 supported, although you are strongly encouraged to use the hashref
3062 syntax as outlined above.
3063
3064 =head2 columns
3065
3066 =over 4
3067
3068 =item Value: \@columns
3069
3070 =back
3071
3072 Shortcut to request a particular set of columns to be retrieved. Each
3073 column spec may be a string (a table column name), or a hash (in which
3074 case the key is the C<as> value, and the value is used as the C<select>
3075 expression). Adds C<me.> onto the start of any column without a C<.> in
3076 it and sets C<select> from that, then auto-populates C<as> from
3077 C<select> as normal. (You may also use the C<cols> attribute, as in
3078 earlier versions of DBIC.)
3079
3080 =head2 +columns
3081
3082 =over 4
3083
3084 =item Value: \@columns
3085
3086 =back
3087
3088 Indicates additional columns to be selected from storage. Works the same
3089 as L</columns> but adds columns to the selection. (You may also use the
3090 C<include_columns> attribute, as in earlier versions of DBIC). For
3091 example:-
3092
3093   $schema->resultset('CD')->search(undef, {
3094     '+columns' => ['artist.name'],
3095     join => ['artist']
3096   });
3097
3098 would return all CDs and include a 'name' column to the information
3099 passed to object inflation. Note that the 'artist' is the name of the
3100 column (or relationship) accessor, and 'name' is the name of the column
3101 accessor in the related table.
3102
3103 =head2 include_columns
3104
3105 =over 4
3106
3107 =item Value: \@columns
3108
3109 =back
3110
3111 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3112
3113 =head2 select
3114
3115 =over 4
3116
3117 =item Value: \@select_columns
3118
3119 =back
3120
3121 Indicates which columns should be selected from the storage. You can use
3122 column names, or in the case of RDBMS back ends, function or stored procedure
3123 names:
3124
3125   $rs = $schema->resultset('Employee')->search(undef, {
3126     select => [
3127       'name',
3128       { count => 'employeeid' },
3129       { sum => 'salary' }
3130     ]
3131   });
3132
3133 When you use function/stored procedure names and do not supply an C<as>
3134 attribute, the column names returned are storage-dependent. E.g. MySQL would
3135 return a column named C<count(employeeid)> in the above example.
3136
3137 B<NOTE:> You will almost always need a corresponding 'as' entry when you use
3138 'select'.
3139
3140 =head2 +select
3141
3142 =over 4
3143
3144 Indicates additional columns to be selected from storage.  Works the same as
3145 L</select> but adds columns to the selection.
3146
3147 =back
3148
3149 =head2 +as
3150
3151 =over 4
3152
3153 Indicates additional column names for those added via L</+select>. See L</as>.
3154
3155 =back
3156
3157 =head2 as
3158
3159 =over 4
3160
3161 =item Value: \@inflation_names
3162
3163 =back
3164
3165 Indicates column names for object inflation. That is, C<as>
3166 indicates the name that the column can be accessed as via the
3167 C<get_column> method (or via the object accessor, B<if one already
3168 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3169
3170 The C<as> attribute is used in conjunction with C<select>,
3171 usually when C<select> contains one or more function or stored
3172 procedure names:
3173
3174   $rs = $schema->resultset('Employee')->search(undef, {
3175     select => [
3176       'name',
3177       { count => 'employeeid' }
3178     ],
3179     as => ['name', 'employee_count'],
3180   });
3181
3182   my $employee = $rs->first(); # get the first Employee
3183
3184 If the object against which the search is performed already has an accessor
3185 matching a column name specified in C<as>, the value can be retrieved using
3186 the accessor as normal:
3187
3188   my $name = $employee->name();
3189
3190 If on the other hand an accessor does not exist in the object, you need to
3191 use C<get_column> instead:
3192
3193   my $employee_count = $employee->get_column('employee_count');
3194
3195 You can create your own accessors if required - see
3196 L<DBIx::Class::Manual::Cookbook> for details.
3197
3198 Please note: This will NOT insert an C<AS employee_count> into the SQL
3199 statement produced, it is used for internal access only. Thus
3200 attempting to use the accessor in an C<order_by> clause or similar
3201 will fail miserably.
3202
3203 To get around this limitation, you can supply literal SQL to your
3204 C<select> attibute that contains the C<AS alias> text, eg:
3205
3206   select => [\'myfield AS alias']
3207
3208 =head2 join
3209
3210 =over 4
3211
3212 =item Value: ($rel_name | \@rel_names | \%rel_names)
3213
3214 =back
3215
3216 Contains a list of relationships that should be joined for this query.  For
3217 example:
3218
3219   # Get CDs by Nine Inch Nails
3220   my $rs = $schema->resultset('CD')->search(
3221     { 'artist.name' => 'Nine Inch Nails' },
3222     { join => 'artist' }
3223   );
3224
3225 Can also contain a hash reference to refer to the other relation's relations.
3226 For example:
3227
3228   package MyApp::Schema::Track;
3229   use base qw/DBIx::Class/;
3230   __PACKAGE__->table('track');
3231   __PACKAGE__->add_columns(qw/trackid cd position title/);
3232   __PACKAGE__->set_primary_key('trackid');
3233   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3234   1;
3235
3236   # In your application
3237   my $rs = $schema->resultset('Artist')->search(
3238     { 'track.title' => 'Teardrop' },
3239     {
3240       join     => { cd => 'track' },
3241       order_by => 'artist.name',
3242     }
3243   );
3244
3245 You need to use the relationship (not the table) name in  conditions,
3246 because they are aliased as such. The current table is aliased as "me", so
3247 you need to use me.column_name in order to avoid ambiguity. For example:
3248
3249   # Get CDs from 1984 with a 'Foo' track
3250   my $rs = $schema->resultset('CD')->search(
3251     {
3252       'me.year' => 1984,
3253       'tracks.name' => 'Foo'
3254     },
3255     { join => 'tracks' }
3256   );
3257
3258 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3259 similarly for a third time). For e.g.
3260
3261   my $rs = $schema->resultset('Artist')->search({
3262     'cds.title'   => 'Down to Earth',
3263     'cds_2.title' => 'Popular',
3264   }, {
3265     join => [ qw/cds cds/ ],
3266   });
3267
3268 will return a set of all artists that have both a cd with title 'Down
3269 to Earth' and a cd with title 'Popular'.
3270
3271 If you want to fetch related objects from other tables as well, see C<prefetch>
3272 below.
3273
3274 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3275
3276 =head2 prefetch
3277
3278 =over 4
3279
3280 =item Value: ($rel_name | \@rel_names | \%rel_names)
3281
3282 =back
3283
3284 Contains one or more relationships that should be fetched along with
3285 the main query (when they are accessed afterwards the data will
3286 already be available, without extra queries to the database).  This is
3287 useful for when you know you will need the related objects, because it
3288 saves at least one query:
3289
3290   my $rs = $schema->resultset('Tag')->search(
3291     undef,
3292     {
3293       prefetch => {
3294         cd => 'artist'
3295       }
3296     }
3297   );
3298
3299 The initial search results in SQL like the following:
3300
3301   SELECT tag.*, cd.*, artist.* FROM tag
3302   JOIN cd ON tag.cd = cd.cdid
3303   JOIN artist ON cd.artist = artist.artistid
3304
3305 L<DBIx::Class> has no need to go back to the database when we access the
3306 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3307 case.
3308
3309 Simple prefetches will be joined automatically, so there is no need
3310 for a C<join> attribute in the above search.
3311
3312 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3313 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3314 with an accessor type of 'single' or 'filter'). A more complex example that
3315 prefetches an artists cds, the tracks on those cds, and the tags associted
3316 with that artist is given below (assuming many-to-many from artists to tags):
3317
3318  my $rs = $schema->resultset('Artist')->search(
3319    undef,
3320    {
3321      prefetch => [
3322        { cds => 'tracks' },
3323        { artist_tags => 'tags' }
3324      ]
3325    }
3326  );
3327
3328
3329 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3330 attributes will be ignored.
3331
3332 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3333 exactly as you might expect.
3334
3335 =over 4
3336
3337 =item *
3338
3339 Prefetch uses the L</cache> to populate the prefetched relationships. This
3340 may or may not be what you want.
3341
3342 =item *
3343
3344 If you specify a condition on a prefetched relationship, ONLY those
3345 rows that match the prefetched condition will be fetched into that relationship.
3346 This means that adding prefetch to a search() B<may alter> what is returned by
3347 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3348
3349   my $artist_rs = $schema->resultset('Artist')->search({
3350       'cds.year' => 2008,
3351   }, {
3352       join => 'cds',
3353   });
3354
3355   my $count = $artist_rs->first->cds->count;
3356
3357   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3358
3359   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3360
3361   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3362
3363 that cmp_ok() may or may not pass depending on the datasets involved. This
3364 behavior may or may not survive the 0.09 transition.
3365
3366 =back
3367
3368 =head2 page
3369
3370 =over 4
3371
3372 =item Value: $page
3373
3374 =back
3375
3376 Makes the resultset paged and specifies the page to retrieve. Effectively
3377 identical to creating a non-pages resultset and then calling ->page($page)
3378 on it.
3379
3380 If L<rows> attribute is not specified it defaults to 10 rows per page.
3381
3382 When you have a paged resultset, L</count> will only return the number
3383 of rows in the page. To get the total, use the L</pager> and call
3384 C<total_entries> on it.
3385
3386 =head2 rows
3387
3388 =over 4
3389
3390 =item Value: $rows
3391
3392 =back
3393
3394 Specifes the maximum number of rows for direct retrieval or the number of
3395 rows per page if the page attribute or method is used.
3396
3397 =head2 offset
3398
3399 =over 4
3400
3401 =item Value: $offset
3402
3403 =back
3404
3405 Specifies the (zero-based) row number for the  first row to be returned, or the
3406 of the first row of the first page if paging is used.
3407
3408 =head2 group_by
3409
3410 =over 4
3411
3412 =item Value: \@columns
3413
3414 =back
3415
3416 A arrayref of columns to group by. Can include columns of joined tables.
3417
3418   group_by => [qw/ column1 column2 ... /]
3419
3420 =head2 having
3421
3422 =over 4
3423
3424 =item Value: $condition
3425
3426 =back
3427
3428 HAVING is a select statement attribute that is applied between GROUP BY and
3429 ORDER BY. It is applied to the after the grouping calculations have been
3430 done.
3431
3432   having => { 'count(employee)' => { '>=', 100 } }
3433
3434 =head2 distinct
3435
3436 =over 4
3437
3438 =item Value: (0 | 1)
3439
3440 =back
3441
3442 Set to 1 to group by all columns. If the resultset already has a group_by
3443 attribute, this setting is ignored and an appropriate warning is issued.
3444
3445 =head2 where
3446
3447 =over 4
3448
3449 Adds to the WHERE clause.
3450
3451   # only return rows WHERE deleted IS NULL for all searches
3452   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3453
3454 Can be overridden by passing C<< { where => undef } >> as an attribute
3455 to a resultset.
3456
3457 =back
3458
3459 =head2 cache
3460
3461 Set to 1 to cache search results. This prevents extra SQL queries if you
3462 revisit rows in your ResultSet:
3463
3464   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3465
3466   while( my $artist = $resultset->next ) {
3467     ... do stuff ...
3468   }
3469
3470   $rs->first; # without cache, this would issue a query
3471
3472 By default, searches are not cached.
3473
3474 For more examples of using these attributes, see
3475 L<DBIx::Class::Manual::Cookbook>.
3476
3477 =head2 for
3478
3479 =over 4
3480
3481 =item Value: ( 'update' | 'shared' )
3482
3483 =back
3484
3485 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3486 ... FOR SHARED.
3487
3488 =cut
3489
3490 1;