lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset (ie:
 145 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 146 and attributes with the same keys need resolving.
 147
 148 If any of L</columns>, L</select>, L</as> are present, they reset the
 149 original selection, and start the selection "clean".
 150
 151 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 152 are merged into the existing ones from the original resultset.
 153
 154 The L</where> and L</having> attributes, and any search conditions, are
 155 merged with an SQL C<AND> to the existing condition from the original
 156 resultset.
 157
 158 All other attributes are overridden by any new ones supplied in the
 159 search attributes.
 160
 161 =head2 Multiple queries
 162
 163 Since a resultset just defines a query, you can do all sorts of
 164 things with it with the same object.
 165
 166   # Don't hit the DB yet.
 167   my $cd_rs = $schema->resultset('CD')->search({
 168     title => 'something',
 169     year => 2009,
 170   });
 171
 172   # Each of these hits the DB individually.
 173   my $count = $cd_rs->count;
 174   my $most_recent = $cd_rs->get_column('date_released')->max();
 175   my @records = $cd_rs->all;
 176
 177 And it's not just limited to SELECT statements.
 178
 179   $cd_rs->delete();
 180
 181 This is even cooler:
 182
 183   $cd_rs->create({ artist => 'Fred' });
 184
 185 Which is the same as:
 186
 187   $schema->resultset('CD')->create({
 188     title => 'something',
 189     year => 2009,
 190     artist => 'Fred'
 191   });
 192
 193 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 194
 195 =head1 METHODS
 196
 197 =head2 new
 198
 199 =over 4
 200
 201 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 202
 203 =item Return Value: L<$resultset|/search>
 204
 205 =back
 206
 207 The resultset constructor. Takes a source object (usually a
 208 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 209 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 210 executed as needed by the other methods.
 211
 212 Generally you never construct a resultset manually. Instead you get one
 213 from e.g. a
 214 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 215 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 216 scalar context):
 217
 218   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 219
 220 =over
 221
 222 =item WARNING
 223
 224 If called on an object, proxies to L</new_result> instead, so
 225
 226   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 227
 228 will return a CD object, not a ResultSet, and is equivalent to:
 229
 230   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 231
 232 Please also keep in mind that many internals call L</new_result> directly,
 233 so overloading this method with the idea of intercepting new result object
 234 creation B<will not work>. See also warning pertaining to L</create>.
 235
 236 =back
 237
 238 =cut
 239
 240 sub new {
 241   my $class = shift;
 242   return $class->new_result(@_) if ref $class;
 243
 244   my ($source, $attrs) = @_;
 245   $source = $source->resolve
 246     if $source->isa('DBIx::Class::ResultSourceHandle');
 247   $attrs = { %{$attrs||{}} };
 248
 249   if ($attrs->{page}) {
 250     $attrs->{rows} ||= 10;
 251   }
 252
 253   $attrs->{alias} ||= 'me';
 254
 255   my $self = bless {
 256     result_source => $source,
 257     cond => $attrs->{where},
 258     pager => undef,
 259     attrs => $attrs,
 260   }, $class;
 261
 262   # if there is a dark selector, this means we are already in a
 263   # chain and the cleanup/sanification was taken care of by
 264   # _search_rs already
 265   $self->_normalize_selection($attrs)
 266     unless $attrs->{_dark_selector};
 267
 268   $self->result_class(
 269     $attrs->{result_class} || $source->result_class
 270   );
 271
 272   $self;
 273 }
 274
 275 =head2 search
 276
 277 =over 4
 278
 279 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 280
 281 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 282
 283 =back
 284
 285   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 286   my $new_rs = $cd_rs->search({ year => 2005 });
 287
 288   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 289                  # year = 2005 OR year = 2004
 290
 291 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 292 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 293 To avoid that, use L</search_rs>.
 294
 295 If you need to pass in additional attributes but no additional condition,
 296 call it as C<search(undef, \%attrs)>.
 297
 298   # "SELECT name, artistid FROM $artist_table"
 299   my @all_artists = $schema->resultset('Artist')->search(undef, {
 300     columns => [qw/name artistid/],
 301   });
 302
 303 For a list of attributes that can be passed to C<search>, see
 304 L</ATTRIBUTES>. For more examples of using this function, see
 305 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 306 documentation for the first argument, see L<SQL::Abstract>
 307 and its extension L<DBIx::Class::SQLMaker>.
 308
 309 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 310
 311 =head3 CAVEAT
 312
 313 Note that L</search> does not process/deflate any of the values passed in the
 314 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 315 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 316 manually that any value passed to this method will stringify to something the
 317 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 318 objects, for more info see:
 319 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 320
 321 =cut
 322
 323 sub search {
 324   my $self = shift;
 325   my $rs = $self->search_rs( @_ );
 326
 327   if (wantarray) {
 328     return $rs->all;
 329   }
 330   elsif (defined wantarray) {
 331     return $rs;
 332   }
 333   else {
 334     # we can be called by a relationship helper, which in
 335     # turn may be called in void context due to some braindead
 336     # overload or whatever else the user decided to be clever
 337     # at this particular day. Thus limit the exception to
 338     # external code calls only
 339     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 340       if (caller)[0] !~ /^\QDBIx::Class::/;
 341
 342     return ();
 343   }
 344 }
 345
 346 =head2 search_rs
 347
 348 =over 4
 349
 350 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 351
 352 =item Return Value: L<$resultset|/search>
 353
 354 =back
 355
 356 This method does the same exact thing as search() except it will
 357 always return a resultset, even in list context.
 358
 359 =cut
 360
 361 sub search_rs {
 362   my $self = shift;
 363
 364   my $rsrc = $self->result_source;
 365   my ($call_cond, $call_attrs);
 366
 367   # Special-case handling for (undef, undef) or (undef)
 368   # Note that (foo => undef) is valid deprecated syntax
 369   @_ = () if not scalar grep { defined $_ } @_;
 370
 371   # just a cond
 372   if (@_ == 1) {
 373     $call_cond = shift;
 374   }
 375   # fish out attrs in the ($condref, $attr) case
 376   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 377     ($call_cond, $call_attrs) = @_;
 378   }
 379   elsif (@_ % 2) {
 380     $self->throw_exception('Odd number of arguments to search')
 381   }
 382   # legacy search
 383   elsif (@_) {
 384     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 385       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 386
 387     for my $i (0 .. $#_) {
 388       next if $i % 2;
 389       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 390         if (! defined $_[$i] or ref $_[$i] ne '');
 391     }
 392
 393     $call_cond = { @_ };
 394   }
 395
 396   # see if we can keep the cache (no $rs changes)
 397   my $cache;
 398   my %safe = (alias => 1, cache => 1);
 399   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 400     ! defined $call_cond
 401       or
 402     ref $call_cond eq 'HASH' && ! keys %$call_cond
 403       or
 404     ref $call_cond eq 'ARRAY' && ! @$call_cond
 405   )) {
 406     $cache = $self->get_cache;
 407   }
 408
 409   my $old_attrs = { %{$self->{attrs}} };
 410   my $old_having = delete $old_attrs->{having};
 411   my $old_where = delete $old_attrs->{where};
 412
 413   my $new_attrs = { %$old_attrs };
 414
 415   # take care of call attrs (only if anything is changing)
 416   if ($call_attrs and keys %$call_attrs) {
 417
 418     # copy for _normalize_selection
 419     $call_attrs = { %$call_attrs };
 420
 421     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 422
 423     # reset the current selector list if new selectors are supplied
 424     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 425       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 426     }
 427
 428     # Normalize the new selector list (operates on the passed-in attr structure)
 429     # Need to do it on every chain instead of only once on _resolved_attrs, in
 430     # order to allow detection of empty vs partial 'as'
 431     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 432       if $old_attrs->{_dark_selector};
 433     $self->_normalize_selection ($call_attrs);
 434
 435     # start with blind overwriting merge, exclude selector attrs
 436     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 437     delete @{$new_attrs}{@selector_attrs};
 438
 439     for (@selector_attrs) {
 440       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 441         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 442     }
 443
 444     # older deprecated name, use only if {columns} is not there
 445     if (my $c = delete $new_attrs->{cols}) {
 446       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 447       if ($new_attrs->{columns}) {
 448         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 449       }
 450       else {
 451         $new_attrs->{columns} = $c;
 452       }
 453     }
 454
 455
 456     # join/prefetch use their own crazy merging heuristics
 457     foreach my $key (qw/join prefetch/) {
 458       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 459         if exists $call_attrs->{$key};
 460     }
 461
 462     # stack binds together
 463     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 464   }
 465
 466
 467   for ($old_where, $call_cond) {
 468     if (defined $_) {
 469       $new_attrs->{where} = $self->_stack_cond (
 470         $_, $new_attrs->{where}
 471       );
 472     }
 473   }
 474
 475   if (defined $old_having) {
 476     $new_attrs->{having} = $self->_stack_cond (
 477       $old_having, $new_attrs->{having}
 478     )
 479   }
 480
 481   my $rs = (ref $self)->new($rsrc, $new_attrs);
 482
 483   $rs->set_cache($cache) if ($cache);
 484
 485   return $rs;
 486 }
 487
 488 my $dark_sel_dumper;
 489 sub _normalize_selection {
 490   my ($self, $attrs) = @_;
 491
 492   # legacy syntax
 493   if ( exists $attrs->{include_columns} ) {
 494     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 495     $attrs->{'+columns'} = $self->_merge_attr(
 496       $attrs->{'+columns'}, delete $attrs->{include_columns}
 497     );
 498   }
 499
 500   # columns are always placed first, however
 501
 502   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 503   # delay the decision on whether to use a default select list ($rsrc->columns)
 504   # allowing stuff like the remove_columns helper to work
 505   #
 506   # select/as +select/+as pairs need special handling - the amount of select/as
 507   # elements in each pair does *not* have to be equal (think multicolumn
 508   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 509   # supplied at all) - try to infer the alias, either from the -as parameter
 510   # of the selector spec, or use the parameter whole if it looks like a column
 511   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 512   # is ok as well), but make sure no more additions to the 'as' chain take place
 513   for my $pref ('', '+') {
 514
 515     my ($sel, $as) = map {
 516       my $key = "${pref}${_}";
 517
 518       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 519         ? @{$attrs->{$key}}
 520         : $attrs->{$key} || ()
 521       ];
 522       delete $attrs->{$key};
 523       $val;
 524     } qw/select as/;
 525
 526     if (! @$as and ! @$sel ) {
 527       next;
 528     }
 529     elsif (@$as and ! @$sel) {
 530       $self->throw_exception(
 531         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 532       );
 533     }
 534     elsif( ! @$as ) {
 535       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 536       # if any @$as has been supplied we assume the user knows what (s)he is doing
 537       # and blindly keep stacking up pieces
 538       unless ($attrs->{_dark_selector}) {
 539         SELECTOR:
 540         for (@$sel) {
 541           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 542             push @$as, $_->{-as};
 543           }
 544           # assume any plain no-space, no-parenthesis string to be a column spec
 545           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 546           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 547             push @$as, $_;
 548           }
 549           # if all else fails - raise a flag that no more aliasing will be allowed
 550           else {
 551             $attrs->{_dark_selector} = {
 552               plus_stage => $pref,
 553               string => ($dark_sel_dumper ||= do {
 554                   require Data::Dumper::Concise;
 555                   Data::Dumper::Concise::DumperObject()->Indent(0);
 556                 })->Values([$_])->Dump
 557               ,
 558             };
 559             last SELECTOR;
 560           }
 561         }
 562       }
 563     }
 564     elsif (@$as < @$sel) {
 565       $self->throw_exception(
 566         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 567       );
 568     }
 569     elsif ($pref and $attrs->{_dark_selector}) {
 570       $self->throw_exception(
 571         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 572       );
 573     }
 574
 575
 576     # merge result
 577     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 578     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 579   }
 580 }
 581
 582 sub _stack_cond {
 583   my ($self, $left, $right) = @_;
 584
 585   # collapse single element top-level conditions
 586   # (single pass only, unlikely to need recursion)
 587   for ($left, $right) {
 588     if (ref $_ eq 'ARRAY') {
 589       if (@$_ == 0) {
 590         $_ = undef;
 591       }
 592       elsif (@$_ == 1) {
 593         $_ = $_->[0];
 594       }
 595     }
 596     elsif (ref $_ eq 'HASH') {
 597       my ($first, $more) = keys %$_;
 598
 599       # empty hash
 600       if (! defined $first) {
 601         $_ = undef;
 602       }
 603       # one element hash
 604       elsif (! defined $more) {
 605         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 606           $_ = $_->{'-and'};
 607         }
 608         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 609           $_ = $_->{'-or'};
 610         }
 611       }
 612     }
 613   }
 614
 615   # merge hashes with weeding out of duplicates (simple cases only)
 616   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 617
 618     # shallow copy to destroy
 619     $right = { %$right };
 620     for (grep { exists $right->{$_} } keys %$left) {
 621       # the use of eq_deeply here is justified - the rhs of an
 622       # expression can contain a lot of twisted weird stuff
 623       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 624     }
 625
 626     $right = undef unless keys %$right;
 627   }
 628
 629
 630   if (defined $left xor defined $right) {
 631     return defined $left ? $left : $right;
 632   }
 633   elsif (! defined $left) {
 634     return undef;
 635   }
 636   else {
 637     return { -and => [ $left, $right ] };
 638   }
 639 }
 640
 641 =head2 search_literal
 642
 643 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 644 should only be used in that context. C<search_literal> is a convenience
 645 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 646 want to ensure columns are bound correctly, use L</search>.
 647
 648 See L<DBIx::Class::Manual::Cookbook/Searching> and
 649 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 650 require C<search_literal>.
 651
 652 =over 4
 653
 654 =item Arguments: $sql_fragment, @standalone_bind_values
 655
 656 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 657
 658 =back
 659
 660   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 661   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 662
 663 Pass a literal chunk of SQL to be added to the conditional part of the
 664 resultset query.
 665
 666 Example of how to use C<search> instead of C<search_literal>
 667
 668   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 669   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 670
 671 =cut
 672
 673 sub search_literal {
 674   my ($self, $sql, @bind) = @_;
 675   my $attr;
 676   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 677     $attr = pop @bind;
 678   }
 679   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 680 }
 681
 682 =head2 find
 683
 684 =over 4
 685
 686 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 687
 688 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 689
 690 =back
 691
 692 Finds and returns a single row based on supplied criteria. Takes either a
 693 hashref with the same format as L</create> (including inference of foreign
 694 keys from related objects), or a list of primary key values in the same
 695 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 696 declaration on the L</result_source>.
 697
 698 In either case an attempt is made to combine conditions already existing on
 699 the resultset with the condition passed to this method.
 700
 701 To aid with preparing the correct query for the storage you may supply the
 702 C<key> attribute, which is the name of a
 703 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 704 unique constraint corresponding to the
 705 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 706 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 707 to construct a query that satisfies the named unique constraint fully (
 708 non-NULL values for each column member of the constraint) an exception is
 709 thrown.
 710
 711 If no C<key> is specified, the search is carried over all unique constraints
 712 which are fully defined by the available condition.
 713
 714 If no such constraint is found, C<find> currently defaults to a simple
 715 C<< search->(\%column_values) >> which may or may not do what you expect.
 716 Note that this fallback behavior may be deprecated in further versions. If
 717 you need to search with arbitrary conditions - use L</search>. If the query
 718 resulting from this fallback produces more than one row, a warning to the
 719 effect is issued, though only the first row is constructed and returned as
 720 C<$result_object>.
 721
 722 In addition to C<key>, L</find> recognizes and applies standard
 723 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 724
 725 Note that if you have extra concerns about the correctness of the resulting
 726 query you need to specify the C<key> attribute and supply the entire condition
 727 as an argument to find (since it is not always possible to perform the
 728 combination of the resultset condition with the supplied one, especially if
 729 the resultset condition contains literal sql).
 730
 731 For example, to find a row by its primary key:
 732
 733   my $cd = $schema->resultset('CD')->find(5);
 734
 735 You can also find a row by a specific unique constraint:
 736
 737   my $cd = $schema->resultset('CD')->find(
 738     {
 739       artist => 'Massive Attack',
 740       title  => 'Mezzanine',
 741     },
 742     { key => 'cd_artist_title' }
 743   );
 744
 745 See also L</find_or_create> and L</update_or_create>.
 746
 747 =cut
 748
 749 sub find {
 750   my $self = shift;
 751   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 752
 753   my $rsrc = $self->result_source;
 754
 755   my $constraint_name;
 756   if (exists $attrs->{key}) {
 757     $constraint_name = defined $attrs->{key}
 758       ? $attrs->{key}
 759       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 760     ;
 761   }
 762
 763   # Parse out the condition from input
 764   my $call_cond;
 765
 766   if (ref $_[0] eq 'HASH') {
 767     $call_cond = { %{$_[0]} };
 768   }
 769   else {
 770     # if only values are supplied we need to default to 'primary'
 771     $constraint_name = 'primary' unless defined $constraint_name;
 772
 773     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 774
 775     $self->throw_exception(
 776       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 777     ) unless @c_cols;
 778
 779     $self->throw_exception (
 780       'find() expects either a column/value hashref, or a list of values '
 781     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 782     ) unless @c_cols == @_;
 783
 784     $call_cond = {};
 785     @{$call_cond}{@c_cols} = @_;
 786   }
 787
 788   my %related;
 789   for my $key (keys %$call_cond) {
 790     if (
 791       my $keyref = ref($call_cond->{$key})
 792         and
 793       my $relinfo = $rsrc->relationship_info($key)
 794     ) {
 795       my $val = delete $call_cond->{$key};
 796
 797       next if $keyref eq 'ARRAY'; # has_many for multi_create
 798
 799       my $rel_q = $rsrc->_resolve_condition(
 800         $relinfo->{cond}, $val, $key, $key
 801       );
 802       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 803       @related{keys %$rel_q} = values %$rel_q;
 804     }
 805   }
 806
 807   # relationship conditions take precedence (?)
 808   @{$call_cond}{keys %related} = values %related;
 809
 810   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 811   my $final_cond;
 812   if (defined $constraint_name) {
 813     $final_cond = $self->_qualify_cond_columns (
 814
 815       $self->_build_unique_cond (
 816         $constraint_name,
 817         $call_cond,
 818       ),
 819
 820       $alias,
 821     );
 822   }
 823   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 824     # This means that we got here after a merger of relationship conditions
 825     # in ::Relationship::Base::search_related (the row method), and furthermore
 826     # the relationship is of the 'single' type. This means that the condition
 827     # provided by the relationship (already attached to $self) is sufficient,
 828     # as there can be only one row in the database that would satisfy the
 829     # relationship
 830   }
 831   else {
 832     # no key was specified - fall down to heuristics mode:
 833     # run through all unique queries registered on the resultset, and
 834     # 'OR' all qualifying queries together
 835     my (@unique_queries, %seen_column_combinations);
 836     for my $c_name ($rsrc->unique_constraint_names) {
 837       next if $seen_column_combinations{
 838         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 839       }++;
 840
 841       push @unique_queries, try {
 842         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 843       } || ();
 844     }
 845
 846     $final_cond = @unique_queries
 847       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 848       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 849     ;
 850   }
 851
 852   # Run the query, passing the result_class since it should propagate for find
 853   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 854   if ($rs->_resolved_attrs->{collapse}) {
 855     my $row = $rs->next;
 856     carp "Query returned more than one row" if $rs->next;
 857     return $row;
 858   }
 859   else {
 860     return $rs->single;
 861   }
 862 }
 863
 864 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 865 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 866 #
 867 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 868 # condition. It is provided for overrides until a saner way forward is devised
 869 #
 870 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 871 # the road. Please adjust your tests accordingly to catch this situation early
 872 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 873 #
 874 # The method will not be removed without an adequately complete replacement
 875 # for strict-mode enforcement
 876 sub _non_unique_find_fallback {
 877   my ($self, $cond, $attrs) = @_;
 878
 879   return $self->_qualify_cond_columns(
 880     $cond,
 881     exists $attrs->{alias}
 882       ? $attrs->{alias}
 883       : $self->{attrs}{alias}
 884   );
 885 }
 886
 887
 888 sub _qualify_cond_columns {
 889   my ($self, $cond, $alias) = @_;
 890
 891   my %aliased = %$cond;
 892   for (keys %aliased) {
 893     $aliased{"$alias.$_"} = delete $aliased{$_}
 894       if $_ !~ /\./;
 895   }
 896
 897   return \%aliased;
 898 }
 899
 900 sub _build_unique_cond {
 901   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 902
 903   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 904
 905   # combination may fail if $self->{cond} is non-trivial
 906   my ($final_cond) = try {
 907     $self->_merge_with_rscond ($extra_cond)
 908   } catch {
 909     +{ %$extra_cond }
 910   };
 911
 912   # trim out everything not in $columns
 913   $final_cond = { map {
 914     exists $final_cond->{$_}
 915       ? ( $_ => $final_cond->{$_} )
 916       : ()
 917   } @c_cols };
 918
 919   if (my @missing = grep
 920     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 921     (@c_cols)
 922   ) {
 923     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 924       $constraint_name,
 925       join (', ', map { "'$_'" } @missing),
 926     ) );
 927   }
 928
 929   if (
 930     !$croak_on_null
 931       and
 932     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 933       and
 934     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 935   ) {
 936     carp_unique ( sprintf (
 937       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 938     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 939     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 940       $constraint_name,
 941       join (', ', map { "'$_'" } @undefs),
 942     ));
 943   }
 944
 945   return $final_cond;
 946 }
 947
 948 =head2 search_related
 949
 950 =over 4
 951
 952 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 953
 954 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 955
 956 =back
 957
 958   $new_rs = $cd_rs->search_related('artist', {
 959     name => 'Emo-R-Us',
 960   });
 961
 962 Searches the specified relationship, optionally specifying a condition and
 963 attributes for matching records. See L</ATTRIBUTES> for more information.
 964
 965 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 966 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 967
 968 See also L</search_related_rs>.
 969
 970 =cut
 971
 972 sub search_related {
 973   return shift->related_resultset(shift)->search(@_);
 974 }
 975
 976 =head2 search_related_rs
 977
 978 This method works exactly the same as search_related, except that
 979 it guarantees a resultset, even in list context.
 980
 981 =cut
 982
 983 sub search_related_rs {
 984   return shift->related_resultset(shift)->search_rs(@_);
 985 }
 986
 987 =head2 cursor
 988
 989 =over 4
 990
 991 =item Arguments: none
 992
 993 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 994
 995 =back
 996
 997 Returns a storage-driven cursor to the given resultset. See
 998 L<DBIx::Class::Cursor> for more information.
 999
1000 =cut
1001
1002 sub cursor {
1003   my $self = shift;
1004
1005   return $self->{cursor} ||= do {
1006     my $attrs = { %{$self->_resolved_attrs } };
1007     $self->result_source->storage->select(
1008       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1009     );
1010   };
1011 }
1012
1013 =head2 single
1014
1015 =over 4
1016
1017 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1018
1019 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1020
1021 =back
1022
1023   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1024
1025 Inflates the first result without creating a cursor if the resultset has
1026 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1027 of L</search>.
1028
1029 While this method can take an optional search condition (just like L</search>)
1030 being a fast-code-path it does not recognize search attributes. If you need to
1031 add extra joins or similar, call L</search> and then chain-call L</single> on the
1032 L<DBIx::Class::ResultSet> returned.
1033
1034 =over
1035
1036 =item B<Note>
1037
1038 As of 0.08100, this method enforces the assumption that the preceding
1039 query returns only one row. If more than one row is returned, you will receive
1040 a warning:
1041
1042   Query returned more than one row
1043
1044 In this case, you should be using L</next> or L</find> instead, or if you really
1045 know what you are doing, use the L</rows> attribute to explicitly limit the size
1046 of the resultset.
1047
1048 This method will also throw an exception if it is called on a resultset prefetching
1049 has_many, as such a prefetch implies fetching multiple rows from the database in
1050 order to assemble the resulting object.
1051
1052 =back
1053
1054 =cut
1055
1056 sub single {
1057   my ($self, $where) = @_;
1058   if(@_ > 2) {
1059       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1060   }
1061
1062   my $attrs = { %{$self->_resolved_attrs} };
1063
1064   $self->throw_exception(
1065     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1066   ) if $attrs->{collapse};
1067
1068   if ($where) {
1069     if (defined $attrs->{where}) {
1070       $attrs->{where} = {
1071         '-and' =>
1072             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1073                $where, delete $attrs->{where} ]
1074       };
1075     } else {
1076       $attrs->{where} = $where;
1077     }
1078   }
1079
1080   my $data = [ $self->result_source->storage->select_single(
1081     $attrs->{from}, $attrs->{select},
1082     $attrs->{where}, $attrs
1083   )];
1084   return undef unless @$data;
1085   $self->{_stashed_rows} = [ $data ];
1086   $self->_construct_results->[0];
1087 }
1088
1089
1090 # _collapse_query
1091 #
1092 # Recursively collapse the query, accumulating values for each column.
1093
1094 sub _collapse_query {
1095   my ($self, $query, $collapsed) = @_;
1096
1097   $collapsed ||= {};
1098
1099   if (ref $query eq 'ARRAY') {
1100     foreach my $subquery (@$query) {
1101       next unless ref $subquery;  # -or
1102       $collapsed = $self->_collapse_query($subquery, $collapsed);
1103     }
1104   }
1105   elsif (ref $query eq 'HASH') {
1106     if (keys %$query and (keys %$query)[0] eq '-and') {
1107       foreach my $subquery (@{$query->{-and}}) {
1108         $collapsed = $self->_collapse_query($subquery, $collapsed);
1109       }
1110     }
1111     else {
1112       foreach my $col (keys %$query) {
1113         my $value = $query->{$col};
1114         $collapsed->{$col}{$value}++;
1115       }
1116     }
1117   }
1118
1119   return $collapsed;
1120 }
1121
1122 =head2 get_column
1123
1124 =over 4
1125
1126 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1127
1128 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1129
1130 =back
1131
1132   my $max_length = $rs->get_column('length')->max;
1133
1134 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1135
1136 =cut
1137
1138 sub get_column {
1139   my ($self, $column) = @_;
1140   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1141   return $new;
1142 }
1143
1144 =head2 search_like
1145
1146 =over 4
1147
1148 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1149
1150 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1151
1152 =back
1153
1154   # WHERE title LIKE '%blue%'
1155   $cd_rs = $rs->search_like({ title => '%blue%'});
1156
1157 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1158 that this is simply a convenience method retained for ex Class::DBI users.
1159 You most likely want to use L</search> with specific operators.
1160
1161 For more information, see L<DBIx::Class::Manual::Cookbook>.
1162
1163 This method is deprecated and will be removed in 0.09. Use L</search()>
1164 instead. An example conversion is:
1165
1166   ->search_like({ foo => 'bar' });
1167
1168   # Becomes
1169
1170   ->search({ foo => { like => 'bar' } });
1171
1172 =cut
1173
1174 sub search_like {
1175   my $class = shift;
1176   carp_unique (
1177     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1178    .' Instead use ->search({ x => { -like => "y%" } })'
1179    .' (note the outer pair of {}s - they are important!)'
1180   );
1181   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1182   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1183   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1184   return $class->search($query, { %$attrs });
1185 }
1186
1187 =head2 slice
1188
1189 =over 4
1190
1191 =item Arguments: $first, $last
1192
1193 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1194
1195 =back
1196
1197 Returns a resultset or object list representing a subset of elements from the
1198 resultset slice is called on. Indexes are from 0, i.e., to get the first
1199 three records, call:
1200
1201   my ($one, $two, $three) = $rs->slice(0, 2);
1202
1203 =cut
1204
1205 sub slice {
1206   my ($self, $min, $max) = @_;
1207   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1208   $attrs->{offset} = $self->{attrs}{offset} || 0;
1209   $attrs->{offset} += $min;
1210   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1211   return $self->search(undef, $attrs);
1212   #my $slice = (ref $self)->new($self->result_source, $attrs);
1213   #return (wantarray ? $slice->all : $slice);
1214 }
1215
1216 =head2 next
1217
1218 =over 4
1219
1220 =item Arguments: none
1221
1222 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1223
1224 =back
1225
1226 Returns the next element in the resultset (C<undef> is there is none).
1227
1228 Can be used to efficiently iterate over records in the resultset:
1229
1230   my $rs = $schema->resultset('CD')->search;
1231   while (my $cd = $rs->next) {
1232     print $cd->title;
1233   }
1234
1235 Note that you need to store the resultset object, and call C<next> on it.
1236 Calling C<< resultset('Table')->next >> repeatedly will always return the
1237 first record from the resultset.
1238
1239 =cut
1240
1241 sub next {
1242   my ($self) = @_;
1243
1244   if (my $cache = $self->get_cache) {
1245     $self->{all_cache_position} ||= 0;
1246     return $cache->[$self->{all_cache_position}++];
1247   }
1248
1249   if ($self->{attrs}{cache}) {
1250     delete $self->{pager};
1251     $self->{all_cache_position} = 1;
1252     return ($self->all)[0];
1253   }
1254
1255   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1256
1257   $self->{_stashed_results} = $self->_construct_results
1258     or return undef;
1259
1260   return shift @{$self->{_stashed_results}};
1261 }
1262
1263 # Constructs as many results as it can in one pass while respecting
1264 # cursor laziness. Several modes of operation:
1265 #
1266 # * Always builds everything present in @{$self->{_stashed_rows}}
1267 # * If called with $fetch_all true - pulls everything off the cursor and
1268 #   builds all result structures (or objects) in one pass
1269 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1270 #   and if the resultset is ordered properly by the left side:
1271 #   * Fetches stuff off the cursor until the "master object" changes,
1272 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1273 #   OR
1274 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1275 #     was requested (there is no other way to collapse except for an
1276 #     eager cursor)
1277 # * If no collapse is requested - just get the next row, construct and
1278 #   return
1279 sub _construct_results {
1280   my ($self, $fetch_all) = @_;
1281
1282   my $rsrc = $self->result_source;
1283   my $attrs = $self->_resolved_attrs;
1284
1285   if (
1286     ! $fetch_all
1287       and
1288     ! $attrs->{order_by}
1289       and
1290     $attrs->{collapse}
1291       and
1292     my @pcols = $rsrc->primary_columns
1293   ) {
1294     # default order for collapsing unless the user asked for something
1295     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1296     $attrs->{_ordered_for_collapse} = 1;
1297     $attrs->{_order_is_artificial} = 1;
1298   }
1299
1300   my $cursor = $self->cursor;
1301
1302   # this will be used as both initial raw-row collector AND as a RV of
1303   # _construct_results. Not regrowing the array twice matters a lot...
1304   # a surprising amount actually
1305   my $rows = delete $self->{_stashed_rows};
1306
1307   my $did_fetch_all = $fetch_all;
1308
1309   if ($fetch_all) {
1310     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1311     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1312   }
1313   elsif( $attrs->{collapse} ) {
1314
1315     $attrs->{_ordered_for_collapse} = (
1316       (
1317         $attrs->{order_by}
1318           and
1319         $rsrc->schema
1320               ->storage
1321                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1322       ) ? 1 : 0
1323     ) unless defined $attrs->{_ordered_for_collapse};
1324
1325     if (! $attrs->{_ordered_for_collapse}) {
1326       $did_fetch_all = 1;
1327
1328       # instead of looping over ->next, use ->all in stealth mode
1329       # *without* calling a ->reset afterwards
1330       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1331       if (! $cursor->{_done}) {
1332         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1333         $cursor->{_done} = 1;
1334       }
1335     }
1336   }
1337
1338   if (! $did_fetch_all and ! @{$rows||[]} ) {
1339     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1340     if (scalar (my @r = $cursor->next) ) {
1341       $rows = [ \@r ];
1342     }
1343   }
1344
1345   return undef unless @{$rows||[]};
1346
1347   my @extra_collapser_args;
1348   if ($attrs->{collapse} and ! $did_fetch_all ) {
1349
1350     @extra_collapser_args = (
1351       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1352       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1353       ($self->{_stashed_rows} = []),                # where does it stuff excess
1354     );
1355   }
1356
1357   # hotspot - skip the setter
1358   my $res_class = $self->_result_class;
1359
1360   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1361     $res_class->can ('inflate_result')
1362       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1363   };
1364
1365   my $infmap = $attrs->{as};
1366
1367
1368   $self->{_result_inflator}{is_core_row} = ( (
1369     $inflator_cref
1370       ==
1371     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1372   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1373
1374   $self->{_result_inflator}{is_hri} = ( (
1375     ! $self->{_result_inflator}{is_core_row}
1376       and
1377     $inflator_cref == (
1378       require DBIx::Class::ResultClass::HashRefInflator
1379         &&
1380       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1381     )
1382   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1383
1384
1385   if (! $attrs->{_related_results_construction}) {
1386     # construct a much simpler array->hash folder for the one-table cases right here
1387     if ($self->{_result_inflator}{is_hri}) {
1388       for my $r (@$rows) {
1389         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1390       }
1391     }
1392     # FIXME SUBOPTIMAL this is a very very very hot spot
1393     # while rather optimal we can *still* do much better, by
1394     # building a smarter Row::inflate_result(), and
1395     # switch to feeding it data via a much leaner interface
1396     #
1397     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1398     # this particular resultset size
1399     elsif (@$rows < 60) {
1400       for my $r (@$rows) {
1401         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1402       }
1403     }
1404     else {
1405       eval sprintf (
1406         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1407         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1408       );
1409     }
1410   }
1411   # Special-case multi-object HRI (we always prune, and there is no $inflator_cref pass)
1412   elsif ($self->{_result_inflator}{is_hri}) {
1413     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1414       eval => 1,
1415       inflate_map => $infmap,
1416       selection => $attrs->{select},
1417       collapse => $attrs->{collapse},
1418       premultiplied => $attrs->{_main_source_premultiplied},
1419       hri_style => 1,
1420       prune_null_branches => 1,
1421     }) )->($rows, @extra_collapser_args);
1422   }
1423   # Regular multi-object
1424   else {
1425     my $parser_type = $self->{_result_inflator}{is_core_row} ? 'classic_pruning' : 'classic_nonpruning';
1426
1427     ( $self->{_row_parser}{$parser_type} ||= $rsrc->_mk_row_parser({
1428       eval => 1,
1429       inflate_map => $infmap,
1430       selection => $attrs->{select},
1431       collapse => $attrs->{collapse},
1432       premultiplied => $attrs->{_main_source_premultiplied},
1433       prune_null_branches => $self->{_result_inflator}{is_core_row},
1434     }) )->($rows, @extra_collapser_args);
1435
1436     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1437   }
1438
1439   # The @$rows check seems odd at first - why wouldn't we want to warn
1440   # regardless? The issue is things like find() etc, where the user
1441   # *knows* only one result will come back. In these cases the ->all
1442   # is not a pessimization, but rather something we actually want
1443   carp_unique(
1444     'Unable to properly collapse has_many results in iterator mode due '
1445   . 'to order criteria - performed an eager cursor slurp underneath. '
1446   . 'Consider using ->all() instead'
1447   ) if ( ! $fetch_all and @$rows > 1 );
1448
1449   return $rows;
1450 }
1451
1452 =head2 result_source
1453
1454 =over 4
1455
1456 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1457
1458 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1459
1460 =back
1461
1462 An accessor for the primary ResultSource object from which this ResultSet
1463 is derived.
1464
1465 =head2 result_class
1466
1467 =over 4
1468
1469 =item Arguments: $result_class?
1470
1471 =item Return Value: $result_class
1472
1473 =back
1474
1475 An accessor for the class to use when creating result objects. Defaults to
1476 C<< result_source->result_class >> - which in most cases is the name of the
1477 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1478
1479 Note that changing the result_class will also remove any components
1480 that were originally loaded in the source class via
1481 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1482 in the original source class will not run.
1483
1484 =cut
1485
1486 sub result_class {
1487   my ($self, $result_class) = @_;
1488   if ($result_class) {
1489
1490     # don't fire this for an object
1491     $self->ensure_class_loaded($result_class)
1492       unless ref($result_class);
1493
1494     if ($self->get_cache) {
1495       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1496     }
1497     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1498     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1499       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1500     }
1501
1502     $self->_result_class($result_class);
1503
1504     delete $self->{_result_inflator};
1505   }
1506   $self->_result_class;
1507 }
1508
1509 =head2 count
1510
1511 =over 4
1512
1513 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1514
1515 =item Return Value: $count
1516
1517 =back
1518
1519 Performs an SQL C<COUNT> with the same query as the resultset was built
1520 with to find the number of elements. Passing arguments is equivalent to
1521 C<< $rs->search ($cond, \%attrs)->count >>
1522
1523 =cut
1524
1525 sub count {
1526   my $self = shift;
1527   return $self->search(@_)->count if @_ and defined $_[0];
1528   return scalar @{ $self->get_cache } if $self->get_cache;
1529
1530   my $attrs = { %{ $self->_resolved_attrs } };
1531
1532   # this is a little optimization - it is faster to do the limit
1533   # adjustments in software, instead of a subquery
1534   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1535
1536   my $crs;
1537   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1538     $crs = $self->_count_subq_rs ($attrs);
1539   }
1540   else {
1541     $crs = $self->_count_rs ($attrs);
1542   }
1543   my $count = $crs->next;
1544
1545   $count -= $offset if $offset;
1546   $count = $rows if $rows and $rows < $count;
1547   $count = 0 if ($count < 0);
1548
1549   return $count;
1550 }
1551
1552 =head2 count_rs
1553
1554 =over 4
1555
1556 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1557
1558 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1559
1560 =back
1561
1562 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1563 This can be very handy for subqueries:
1564
1565   ->search( { amount => $some_rs->count_rs->as_query } )
1566
1567 As with regular resultsets the SQL query will be executed only after
1568 the resultset is accessed via L</next> or L</all>. That would return
1569 the same single value obtainable via L</count>.
1570
1571 =cut
1572
1573 sub count_rs {
1574   my $self = shift;
1575   return $self->search(@_)->count_rs if @_;
1576
1577   # this may look like a lack of abstraction (count() does about the same)
1578   # but in fact an _rs *must* use a subquery for the limits, as the
1579   # software based limiting can not be ported if this $rs is to be used
1580   # in a subquery itself (i.e. ->as_query)
1581   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1582     return $self->_count_subq_rs;
1583   }
1584   else {
1585     return $self->_count_rs;
1586   }
1587 }
1588
1589 #
1590 # returns a ResultSetColumn object tied to the count query
1591 #
1592 sub _count_rs {
1593   my ($self, $attrs) = @_;
1594
1595   my $rsrc = $self->result_source;
1596   $attrs ||= $self->_resolved_attrs;
1597
1598   my $tmp_attrs = { %$attrs };
1599   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1600   delete @{$tmp_attrs}{qw/rows offset order_by _related_results_construction record_filter for/};
1601
1602   # overwrite the selector (supplied by the storage)
1603   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1604   $tmp_attrs->{as} = 'count';
1605
1606   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1607
1608   return $tmp_rs;
1609 }
1610
1611 #
1612 # same as above but uses a subquery
1613 #
1614 sub _count_subq_rs {
1615   my ($self, $attrs) = @_;
1616
1617   my $rsrc = $self->result_source;
1618   $attrs ||= $self->_resolved_attrs;
1619
1620   my $sub_attrs = { %$attrs };
1621   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1622   delete @{$sub_attrs}{qw/collapse columns as select _related_results_construction order_by for/};
1623
1624   # if we multi-prefetch we group_by something unique, as this is what we would
1625   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1626   if ( $attrs->{collapse}  ) {
1627     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1628       $rsrc->_identifying_column_set || $self->throw_exception(
1629         'Unable to construct a unique group_by criteria properly collapsing the '
1630       . 'has_many prefetch before count()'
1631       );
1632     } ]
1633   }
1634
1635   # Calculate subquery selector
1636   if (my $g = $sub_attrs->{group_by}) {
1637
1638     my $sql_maker = $rsrc->storage->sql_maker;
1639
1640     # necessary as the group_by may refer to aliased functions
1641     my $sel_index;
1642     for my $sel (@{$attrs->{select}}) {
1643       $sel_index->{$sel->{-as}} = $sel
1644         if (ref $sel eq 'HASH' and $sel->{-as});
1645     }
1646
1647     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1648     # also look for named aggregates referred in the having clause
1649     # having often contains scalarrefs - thus parse it out entirely
1650     my @parts = @$g;
1651     if ($attrs->{having}) {
1652       local $sql_maker->{having_bind};
1653       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1654       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1655       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1656         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1657         # if we don't unset it we screw up retarded but unfortunately working
1658         # 'MAX(foo.bar)' => { '>', 3 }
1659         $sql_maker->{name_sep} = '';
1660       }
1661
1662       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1663
1664       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1665       my %seen_having;
1666
1667       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1668       # and if all fails for an utterly naive quoted scalar-with-function
1669       while ($having_sql =~ /
1670         $rquote $sep $lquote (.+?) $rquote
1671           |
1672         [\s,] \w+ \. (\w+) [\s,]
1673           |
1674         [\s,] $lquote (.+?) $rquote [\s,]
1675       /gx) {
1676         my $part = $1 || $2 || $3;  # one of them matched if we got here
1677         unless ($seen_having{$part}++) {
1678           push @parts, $part;
1679         }
1680       }
1681     }
1682
1683     for (@parts) {
1684       my $colpiece = $sel_index->{$_} || $_;
1685
1686       # unqualify join-based group_by's. Arcane but possible query
1687       # also horrible horrible hack to alias a column (not a func.)
1688       # (probably need to introduce SQLA syntax)
1689       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1690         my $as = $colpiece;
1691         $as =~ s/\./__/;
1692         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1693       }
1694       push @{$sub_attrs->{select}}, $colpiece;
1695     }
1696   }
1697   else {
1698     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1699     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1700   }
1701
1702   return $rsrc->resultset_class
1703                ->new ($rsrc, $sub_attrs)
1704                 ->as_subselect_rs
1705                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1706                   ->get_column ('count');
1707 }
1708
1709
1710 =head2 count_literal
1711
1712 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1713 should only be used in that context. See L</search_literal> for further info.
1714
1715 =over 4
1716
1717 =item Arguments: $sql_fragment, @standalone_bind_values
1718
1719 =item Return Value: $count
1720
1721 =back
1722
1723 Counts the results in a literal query. Equivalent to calling L</search_literal>
1724 with the passed arguments, then L</count>.
1725
1726 =cut
1727
1728 sub count_literal { shift->search_literal(@_)->count; }
1729
1730 =head2 all
1731
1732 =over 4
1733
1734 =item Arguments: none
1735
1736 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1737
1738 =back
1739
1740 Returns all elements in the resultset.
1741
1742 =cut
1743
1744 sub all {
1745   my $self = shift;
1746   if(@_) {
1747     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1748   }
1749
1750   delete @{$self}{qw/_stashed_rows _stashed_results/};
1751
1752   if (my $c = $self->get_cache) {
1753     return @$c;
1754   }
1755
1756   $self->cursor->reset;
1757
1758   my $objs = $self->_construct_results('fetch_all') || [];
1759
1760   $self->set_cache($objs) if $self->{attrs}{cache};
1761
1762   return @$objs;
1763 }
1764
1765 =head2 reset
1766
1767 =over 4
1768
1769 =item Arguments: none
1770
1771 =item Return Value: $self
1772
1773 =back
1774
1775 Resets the resultset's cursor, so you can iterate through the elements again.
1776 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1777 another query.
1778
1779 =cut
1780
1781 sub reset {
1782   my ($self) = @_;
1783
1784   delete @{$self}{qw/_stashed_rows _stashed_results/};
1785   $self->{all_cache_position} = 0;
1786   $self->cursor->reset;
1787   return $self;
1788 }
1789
1790 =head2 first
1791
1792 =over 4
1793
1794 =item Arguments: none
1795
1796 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1797
1798 =back
1799
1800 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1801 an object for the first result (or C<undef> if the resultset is empty).
1802
1803 =cut
1804
1805 sub first {
1806   return $_[0]->reset->next;
1807 }
1808
1809
1810 # _rs_update_delete
1811 #
1812 # Determines whether and what type of subquery is required for the $rs operation.
1813 # If grouping is necessary either supplies its own, or verifies the current one
1814 # After all is done delegates to the proper storage method.
1815
1816 sub _rs_update_delete {
1817   my ($self, $op, $values) = @_;
1818
1819   my $rsrc = $self->result_source;
1820   my $storage = $rsrc->schema->storage;
1821
1822   my $attrs = { %{$self->_resolved_attrs} };
1823
1824   my $join_classifications;
1825   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1826
1827   # do we need a subquery for any reason?
1828   my $needs_subq = (
1829     defined $existing_group_by
1830       or
1831     # if {from} is unparseable wrap a subq
1832     ref($attrs->{from}) ne 'ARRAY'
1833       or
1834     # limits call for a subq
1835     $self->_has_resolved_attr(qw/rows offset/)
1836   );
1837
1838   # simplify the joinmap, so we can further decide if a subq is necessary
1839   if (!$needs_subq and @{$attrs->{from}} > 1) {
1840     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1841
1842     # check if there are any joins left after the prune
1843     if ( @{$attrs->{from}} > 1 ) {
1844       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1845         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1846         $attrs->{select},
1847         $self->{cond},
1848         $attrs
1849       );
1850
1851       # any non-pruneable joins imply subq
1852       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1853     }
1854   }
1855
1856   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1857   $needs_subq ||= (
1858     (ref $attrs->{from}[0]) ne 'HASH'
1859       or
1860     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1861   );
1862
1863   my ($cond, $guard);
1864   # do we need anything like a subquery?
1865   if (! $needs_subq) {
1866     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1867     # a condition containing 'me' or other table prefixes will not work
1868     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1869     $cond = do {
1870       my $sqla = $rsrc->storage->sql_maker;
1871       local $sqla->{_dequalify_idents} = 1;
1872       \[ $sqla->_recurse_where($self->{cond}) ];
1873     };
1874   }
1875   else {
1876     # we got this far - means it is time to wrap a subquery
1877     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1878       sprintf(
1879         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1880         $op,
1881         $rsrc->source_name,
1882       )
1883     );
1884
1885     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1886     delete $attrs->{$_} for qw/select as collapse _related_results_construction/;
1887     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1888     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1889     my $subrs = (ref $self)->new($rsrc, $attrs);
1890
1891     if (@$idcols == 1) {
1892       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1893     }
1894     elsif ($storage->_use_multicolumn_in) {
1895       # no syntax for calling this properly yet
1896       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1897       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1898         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1899         $subrs->as_query
1900       ),
1901     }
1902     else {
1903       # if all else fails - get all primary keys and operate over a ORed set
1904       # wrap in a transaction for consistency
1905       # this is where the group_by/multiplication starts to matter
1906       if (
1907         $existing_group_by
1908           or
1909         keys %{ $join_classifications->{multiplying} || {} }
1910       ) {
1911         # make sure if there is a supplied group_by it matches the columns compiled above
1912         # perfectly. Anything else can not be sanely executed on most databases so croak
1913         # right then and there
1914         if ($existing_group_by) {
1915           my @current_group_by = map
1916             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1917             @$existing_group_by
1918           ;
1919
1920           if (
1921             join ("\x00", sort @current_group_by)
1922               ne
1923             join ("\x00", sort @{$attrs->{columns}} )
1924           ) {
1925             $self->throw_exception (
1926               "You have just attempted a $op operation on a resultset which does group_by"
1927               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1928               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1929               . ' kind of queries. Please retry the operation with a modified group_by or'
1930               . ' without using one at all.'
1931             );
1932           }
1933         }
1934
1935         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1936       }
1937
1938       $guard = $storage->txn_scope_guard;
1939
1940       $cond = [];
1941       for my $row ($subrs->cursor->all) {
1942         push @$cond, { map
1943           { $idcols->[$_] => $row->[$_] }
1944           (0 .. $#$idcols)
1945         };
1946       }
1947     }
1948   }
1949
1950   my $res = $storage->$op (
1951     $rsrc,
1952     $op eq 'update' ? $values : (),
1953     $cond,
1954   );
1955
1956   $guard->commit if $guard;
1957
1958   return $res;
1959 }
1960
1961 =head2 update
1962
1963 =over 4
1964
1965 =item Arguments: \%values
1966
1967 =item Return Value: $underlying_storage_rv
1968
1969 =back
1970
1971 Sets the specified columns in the resultset to the supplied values in a
1972 single query. Note that this will not run any accessor/set_column/update
1973 triggers, nor will it update any result object instances derived from this
1974 resultset (this includes the contents of the L<resultset cache|/set_cache>
1975 if any). See L</update_all> if you need to execute any on-update
1976 triggers or cascades defined either by you or a
1977 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1978
1979 The return value is a pass through of what the underlying
1980 storage backend returned, and may vary. See L<DBI/execute> for the most
1981 common case.
1982
1983 =head3 CAVEAT
1984
1985 Note that L</update> does not process/deflate any of the values passed in.
1986 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1987 ensure manually that any value passed to this method will stringify to
1988 something the RDBMS knows how to deal with. A notable example is the
1989 handling of L<DateTime> objects, for more info see:
1990 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1991
1992 =cut
1993
1994 sub update {
1995   my ($self, $values) = @_;
1996   $self->throw_exception('Values for update must be a hash')
1997     unless ref $values eq 'HASH';
1998
1999   return $self->_rs_update_delete ('update', $values);
2000 }
2001
2002 =head2 update_all
2003
2004 =over 4
2005
2006 =item Arguments: \%values
2007
2008 =item Return Value: 1
2009
2010 =back
2011
2012 Fetches all objects and updates them one at a time via
2013 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2014 triggers, while L</update> will not.
2015
2016 =cut
2017
2018 sub update_all {
2019   my ($self, $values) = @_;
2020   $self->throw_exception('Values for update_all must be a hash')
2021     unless ref $values eq 'HASH';
2022
2023   my $guard = $self->result_source->schema->txn_scope_guard;
2024   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2025   $guard->commit;
2026   return 1;
2027 }
2028
2029 =head2 delete
2030
2031 =over 4
2032
2033 =item Arguments: none
2034
2035 =item Return Value: $underlying_storage_rv
2036
2037 =back
2038
2039 Deletes the rows matching this resultset in a single query. Note that this
2040 will not run any delete triggers, nor will it alter the
2041 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2042 derived from this resultset (this includes the contents of the
2043 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2044 execute any on-delete triggers or cascades defined either by you or a
2045 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2046
2047 The return value is a pass through of what the underlying storage backend
2048 returned, and may vary. See L<DBI/execute> for the most common case.
2049
2050 =cut
2051
2052 sub delete {
2053   my $self = shift;
2054   $self->throw_exception('delete does not accept any arguments')
2055     if @_;
2056
2057   return $self->_rs_update_delete ('delete');
2058 }
2059
2060 =head2 delete_all
2061
2062 =over 4
2063
2064 =item Arguments: none
2065
2066 =item Return Value: 1
2067
2068 =back
2069
2070 Fetches all objects and deletes them one at a time via
2071 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2072 triggers, while L</delete> will not.
2073
2074 =cut
2075
2076 sub delete_all {
2077   my $self = shift;
2078   $self->throw_exception('delete_all does not accept any arguments')
2079     if @_;
2080
2081   my $guard = $self->result_source->schema->txn_scope_guard;
2082   $_->delete for $self->all;
2083   $guard->commit;
2084   return 1;
2085 }
2086
2087 =head2 populate
2088
2089 =over 4
2090
2091 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2092
2093 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2094
2095 =back
2096
2097 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2098 arrayrefs.
2099
2100 =over
2101
2102 =item NOTE
2103
2104 The context of this method call has an important effect on what is
2105 submitted to storage. In void context data is fed directly to fastpath
2106 insertion routines provided by the underlying storage (most often
2107 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2108 L<insert|DBIx::Class::Row/insert> calls on the
2109 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2110 augmentation of these methods provided by components. For example if you
2111 are using something like L<DBIx::Class::UUIDColumns> to create primary
2112 keys for you, you will find that your PKs are empty.  In this case you
2113 will have to explicitly force scalar or list context in order to create
2114 those values.
2115
2116 =back
2117
2118 In non-void (scalar or list) context, this method is simply a wrapper
2119 for L</create>. Depending on list or scalar context either a list of
2120 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2121 containing these objects is returned.
2122
2123 When supplying data in "arrayref of arrayrefs" invocation style, the
2124 first element should be a list of column names and each subsequent
2125 element should be a data value in the earlier specified column order.
2126 For example:
2127
2128   $Arstist_rs->populate([
2129     [ qw( artistid name ) ],
2130     [ 100, 'A Formally Unknown Singer' ],
2131     [ 101, 'A singer that jumped the shark two albums ago' ],
2132     [ 102, 'An actually cool singer' ],
2133   ]);
2134
2135 For the arrayref of hashrefs style each hashref should be a structure
2136 suitable for passing to L</create>. Multi-create is also permitted with
2137 this syntax.
2138
2139   $schema->resultset("Artist")->populate([
2140      { artistid => 4, name => 'Manufactured Crap', cds => [
2141         { title => 'My First CD', year => 2006 },
2142         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2143       ],
2144      },
2145      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2146         { title => 'My parents sold me to a record company', year => 2005 },
2147         { title => 'Why Am I So Ugly?', year => 2006 },
2148         { title => 'I Got Surgery and am now Popular', year => 2007 }
2149       ],
2150      },
2151   ]);
2152
2153 If you attempt a void-context multi-create as in the example above (each
2154 Artist also has the related list of CDs), and B<do not> supply the
2155 necessary autoinc foreign key information, this method will proxy to the
2156 less efficient L</create>, and then throw the Result objects away. In this
2157 case there are obviously no benefits to using this method over L</create>.
2158
2159 =cut
2160
2161 sub populate {
2162   my $self = shift;
2163
2164   # cruft placed in standalone method
2165   my $data = $self->_normalize_populate_args(@_);
2166
2167   return unless @$data;
2168
2169   if(defined wantarray) {
2170     my @created = map { $self->create($_) } @$data;
2171     return wantarray ? @created : \@created;
2172   }
2173   else {
2174     my $first = $data->[0];
2175
2176     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2177     # it relationship data
2178     my (@rels, @columns);
2179     my $rsrc = $self->result_source;
2180     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2181     for (keys %$first) {
2182       my $ref = ref $first->{$_};
2183       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2184         ? push @rels, $_
2185         : push @columns, $_
2186       ;
2187     }
2188
2189     my @pks = $rsrc->primary_columns;
2190
2191     ## do the belongs_to relationships
2192     foreach my $index (0..$#$data) {
2193
2194       # delegate to create() for any dataset without primary keys with specified relationships
2195       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2196         for my $r (@rels) {
2197           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2198             my @ret = $self->populate($data);
2199             return;
2200           }
2201         }
2202       }
2203
2204       foreach my $rel (@rels) {
2205         next unless ref $data->[$index]->{$rel} eq "HASH";
2206         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2207         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2208         my $related = $result->result_source->_resolve_condition(
2209           $reverse_relinfo->{cond},
2210           $self,
2211           $result,
2212           $rel,
2213         );
2214
2215         delete $data->[$index]->{$rel};
2216         $data->[$index] = {%{$data->[$index]}, %$related};
2217
2218         push @columns, keys %$related if $index == 0;
2219       }
2220     }
2221
2222     ## inherit the data locked in the conditions of the resultset
2223     my ($rs_data) = $self->_merge_with_rscond({});
2224     delete @{$rs_data}{@columns};
2225
2226     ## do bulk insert on current row
2227     $rsrc->storage->insert_bulk(
2228       $rsrc,
2229       [@columns, keys %$rs_data],
2230       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2231     );
2232
2233     ## do the has_many relationships
2234     foreach my $item (@$data) {
2235
2236       my $main_row;
2237
2238       foreach my $rel (@rels) {
2239         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2240
2241         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2242
2243         my $child = $main_row->$rel;
2244
2245         my $related = $child->result_source->_resolve_condition(
2246           $rels->{$rel}{cond},
2247           $child,
2248           $main_row,
2249           $rel,
2250         );
2251
2252         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2253         my @populate = map { {%$_, %$related} } @rows_to_add;
2254
2255         $child->populate( \@populate );
2256       }
2257     }
2258   }
2259 }
2260
2261
2262 # populate() argumnets went over several incarnations
2263 # What we ultimately support is AoH
2264 sub _normalize_populate_args {
2265   my ($self, $arg) = @_;
2266
2267   if (ref $arg eq 'ARRAY') {
2268     if (!@$arg) {
2269       return [];
2270     }
2271     elsif (ref $arg->[0] eq 'HASH') {
2272       return $arg;
2273     }
2274     elsif (ref $arg->[0] eq 'ARRAY') {
2275       my @ret;
2276       my @colnames = @{$arg->[0]};
2277       foreach my $values (@{$arg}[1 .. $#$arg]) {
2278         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2279       }
2280       return \@ret;
2281     }
2282   }
2283
2284   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2285 }
2286
2287 =head2 pager
2288
2289 =over 4
2290
2291 =item Arguments: none
2292
2293 =item Return Value: L<$pager|Data::Page>
2294
2295 =back
2296
2297 Returns a L<Data::Page> object for the current resultset. Only makes
2298 sense for queries with a C<page> attribute.
2299
2300 To get the full count of entries for a paged resultset, call
2301 C<total_entries> on the L<Data::Page> object.
2302
2303 =cut
2304
2305 sub pager {
2306   my ($self) = @_;
2307
2308   return $self->{pager} if $self->{pager};
2309
2310   my $attrs = $self->{attrs};
2311   if (!defined $attrs->{page}) {
2312     $self->throw_exception("Can't create pager for non-paged rs");
2313   }
2314   elsif ($attrs->{page} <= 0) {
2315     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2316   }
2317   $attrs->{rows} ||= 10;
2318
2319   # throw away the paging flags and re-run the count (possibly
2320   # with a subselect) to get the real total count
2321   my $count_attrs = { %$attrs };
2322   delete @{$count_attrs}{qw/rows offset page pager/};
2323
2324   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2325
2326   require DBIx::Class::ResultSet::Pager;
2327   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2328     sub { $total_rs->count },  #lazy-get the total
2329     $attrs->{rows},
2330     $self->{attrs}{page},
2331   );
2332 }
2333
2334 =head2 page
2335
2336 =over 4
2337
2338 =item Arguments: $page_number
2339
2340 =item Return Value: L<$resultset|/search>
2341
2342 =back
2343
2344 Returns a resultset for the $page_number page of the resultset on which page
2345 is called, where each page contains a number of rows equal to the 'rows'
2346 attribute set on the resultset (10 by default).
2347
2348 =cut
2349
2350 sub page {
2351   my ($self, $page) = @_;
2352   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2353 }
2354
2355 =head2 new_result
2356
2357 =over 4
2358
2359 =item Arguments: \%col_data
2360
2361 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2362
2363 =back
2364
2365 Creates a new result object in the resultset's result class and returns
2366 it. The row is not inserted into the database at this point, call
2367 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2368 will tell you whether the result object has been inserted or not.
2369
2370 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2371
2372 =cut
2373
2374 sub new_result {
2375   my ($self, $values) = @_;
2376
2377   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2378     if @_ > 2;
2379
2380   $self->throw_exception( "new_result expects a hashref" )
2381     unless (ref $values eq 'HASH');
2382
2383   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2384
2385   my $new = $self->result_class->new({
2386     %$merged_cond,
2387     ( @$cols_from_relations
2388       ? (-cols_from_relations => $cols_from_relations)
2389       : ()
2390     ),
2391     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2392   });
2393
2394   if (
2395     reftype($new) eq 'HASH'
2396       and
2397     ! keys %$new
2398       and
2399     blessed($new)
2400   ) {
2401     carp_unique (sprintf (
2402       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2403       $self->result_class,
2404     ));
2405   }
2406
2407   $new;
2408 }
2409
2410 # _merge_with_rscond
2411 #
2412 # Takes a simple hash of K/V data and returns its copy merged with the
2413 # condition already present on the resultset. Additionally returns an
2414 # arrayref of value/condition names, which were inferred from related
2415 # objects (this is needed for in-memory related objects)
2416 sub _merge_with_rscond {
2417   my ($self, $data) = @_;
2418
2419   my (%new_data, @cols_from_relations);
2420
2421   my $alias = $self->{attrs}{alias};
2422
2423   if (! defined $self->{cond}) {
2424     # just massage $data below
2425   }
2426   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2427     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2428     @cols_from_relations = keys %new_data;
2429   }
2430   elsif (ref $self->{cond} ne 'HASH') {
2431     $self->throw_exception(
2432       "Can't abstract implicit construct, resultset condition not a hash"
2433     );
2434   }
2435   else {
2436     # precendence must be given to passed values over values inherited from
2437     # the cond, so the order here is important.
2438     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2439     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2440
2441     while ( my($col, $value) = each %implied ) {
2442       my $vref = ref $value;
2443       if (
2444         $vref eq 'HASH'
2445           and
2446         keys(%$value) == 1
2447           and
2448         (keys %$value)[0] eq '='
2449       ) {
2450         $new_data{$col} = $value->{'='};
2451       }
2452       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2453         $new_data{$col} = $value;
2454       }
2455     }
2456   }
2457
2458   %new_data = (
2459     %new_data,
2460     %{ $self->_remove_alias($data, $alias) },
2461   );
2462
2463   return (\%new_data, \@cols_from_relations);
2464 }
2465
2466 # _has_resolved_attr
2467 #
2468 # determines if the resultset defines at least one
2469 # of the attributes supplied
2470 #
2471 # used to determine if a subquery is neccessary
2472 #
2473 # supports some virtual attributes:
2474 #   -join
2475 #     This will scan for any joins being present on the resultset.
2476 #     It is not a mere key-search but a deep inspection of {from}
2477 #
2478
2479 sub _has_resolved_attr {
2480   my ($self, @attr_names) = @_;
2481
2482   my $attrs = $self->_resolved_attrs;
2483
2484   my %extra_checks;
2485
2486   for my $n (@attr_names) {
2487     if (grep { $n eq $_ } (qw/-join/) ) {
2488       $extra_checks{$n}++;
2489       next;
2490     }
2491
2492     my $attr =  $attrs->{$n};
2493
2494     next if not defined $attr;
2495
2496     if (ref $attr eq 'HASH') {
2497       return 1 if keys %$attr;
2498     }
2499     elsif (ref $attr eq 'ARRAY') {
2500       return 1 if @$attr;
2501     }
2502     else {
2503       return 1 if $attr;
2504     }
2505   }
2506
2507   # a resolved join is expressed as a multi-level from
2508   return 1 if (
2509     $extra_checks{-join}
2510       and
2511     ref $attrs->{from} eq 'ARRAY'
2512       and
2513     @{$attrs->{from}} > 1
2514   );
2515
2516   return 0;
2517 }
2518
2519 # _collapse_cond
2520 #
2521 # Recursively collapse the condition.
2522
2523 sub _collapse_cond {
2524   my ($self, $cond, $collapsed) = @_;
2525
2526   $collapsed ||= {};
2527
2528   if (ref $cond eq 'ARRAY') {
2529     foreach my $subcond (@$cond) {
2530       next unless ref $subcond;  # -or
2531       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2532     }
2533   }
2534   elsif (ref $cond eq 'HASH') {
2535     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2536       foreach my $subcond (@{$cond->{-and}}) {
2537         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2538       }
2539     }
2540     else {
2541       foreach my $col (keys %$cond) {
2542         my $value = $cond->{$col};
2543         $collapsed->{$col} = $value;
2544       }
2545     }
2546   }
2547
2548   return $collapsed;
2549 }
2550
2551 # _remove_alias
2552 #
2553 # Remove the specified alias from the specified query hash. A copy is made so
2554 # the original query is not modified.
2555
2556 sub _remove_alias {
2557   my ($self, $query, $alias) = @_;
2558
2559   my %orig = %{ $query || {} };
2560   my %unaliased;
2561
2562   foreach my $key (keys %orig) {
2563     if ($key !~ /\./) {
2564       $unaliased{$key} = $orig{$key};
2565       next;
2566     }
2567     $unaliased{$1} = $orig{$key}
2568       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2569   }
2570
2571   return \%unaliased;
2572 }
2573
2574 =head2 as_query
2575
2576 =over 4
2577
2578 =item Arguments: none
2579
2580 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2581
2582 =back
2583
2584 Returns the SQL query and bind vars associated with the invocant.
2585
2586 This is generally used as the RHS for a subquery.
2587
2588 =cut
2589
2590 sub as_query {
2591   my $self = shift;
2592
2593   my $attrs = { %{ $self->_resolved_attrs } };
2594
2595   $self->result_source->storage->_select_args_to_query (
2596     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2597   );
2598 }
2599
2600 =head2 find_or_new
2601
2602 =over 4
2603
2604 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2605
2606 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2607
2608 =back
2609
2610   my $artist = $schema->resultset('Artist')->find_or_new(
2611     { artist => 'fred' }, { key => 'artists' });
2612
2613   $cd->cd_to_producer->find_or_new({ producer => $producer },
2614                                    { key => 'primary });
2615
2616 Find an existing record from this resultset using L</find>. if none exists,
2617 instantiate a new result object and return it. The object will not be saved
2618 into your storage until you call L<DBIx::Class::Row/insert> on it.
2619
2620 You most likely want this method when looking for existing rows using a unique
2621 constraint that is not the primary key, or looking for related rows.
2622
2623 If you want objects to be saved immediately, use L</find_or_create> instead.
2624
2625 B<Note>: Make sure to read the documentation of L</find> and understand the
2626 significance of the C<key> attribute, as its lack may skew your search, and
2627 subsequently result in spurious new objects.
2628
2629 B<Note>: Take care when using C<find_or_new> with a table having
2630 columns with default values that you intend to be automatically
2631 supplied by the database (e.g. an auto_increment primary key column).
2632 In normal usage, the value of such columns should NOT be included at
2633 all in the call to C<find_or_new>, even when set to C<undef>.
2634
2635 =cut
2636
2637 sub find_or_new {
2638   my $self     = shift;
2639   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2640   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2641   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2642     return $row;
2643   }
2644   return $self->new_result($hash);
2645 }
2646
2647 =head2 create
2648
2649 =over 4
2650
2651 =item Arguments: \%col_data
2652
2653 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2654
2655 =back
2656
2657 Attempt to create a single new row or a row with multiple related rows
2658 in the table represented by the resultset (and related tables). This
2659 will not check for duplicate rows before inserting, use
2660 L</find_or_create> to do that.
2661
2662 To create one row for this resultset, pass a hashref of key/value
2663 pairs representing the columns of the table and the values you wish to
2664 store. If the appropriate relationships are set up, foreign key fields
2665 can also be passed an object representing the foreign row, and the
2666 value will be set to its primary key.
2667
2668 To create related objects, pass a hashref of related-object column values
2669 B<keyed on the relationship name>. If the relationship is of type C<multi>
2670 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2671 The process will correctly identify columns holding foreign keys, and will
2672 transparently populate them from the keys of the corresponding relation.
2673 This can be applied recursively, and will work correctly for a structure
2674 with an arbitrary depth and width, as long as the relationships actually
2675 exists and the correct column data has been supplied.
2676
2677 Instead of hashrefs of plain related data (key/value pairs), you may
2678 also pass new or inserted objects. New objects (not inserted yet, see
2679 L</new_result>), will be inserted into their appropriate tables.
2680
2681 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2682
2683 Example of creating a new row.
2684
2685   $person_rs->create({
2686     name=>"Some Person",
2687     email=>"somebody@someplace.com"
2688   });
2689
2690 Example of creating a new row and also creating rows in a related C<has_many>
2691 or C<has_one> resultset.  Note Arrayref.
2692
2693   $artist_rs->create(
2694      { artistid => 4, name => 'Manufactured Crap', cds => [
2695         { title => 'My First CD', year => 2006 },
2696         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2697       ],
2698      },
2699   );
2700
2701 Example of creating a new row and also creating a row in a related
2702 C<belongs_to> resultset. Note Hashref.
2703
2704   $cd_rs->create({
2705     title=>"Music for Silly Walks",
2706     year=>2000,
2707     artist => {
2708       name=>"Silly Musician",
2709     }
2710   });
2711
2712 =over
2713
2714 =item WARNING
2715
2716 When subclassing ResultSet never attempt to override this method. Since
2717 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2718 lot of the internals simply never call it, so your override will be
2719 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2720 or L<DBIx::Class::Row/insert> depending on how early in the
2721 L</create> process you need to intervene. See also warning pertaining to
2722 L</new>.
2723
2724 =back
2725
2726 =cut
2727
2728 sub create {
2729   my ($self, $col_data) = @_;
2730   $self->throw_exception( "create needs a hashref" )
2731     unless ref $col_data eq 'HASH';
2732   return $self->new_result($col_data)->insert;
2733 }
2734
2735 =head2 find_or_create
2736
2737 =over 4
2738
2739 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2740
2741 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2742
2743 =back
2744
2745   $cd->cd_to_producer->find_or_create({ producer => $producer },
2746                                       { key => 'primary' });
2747
2748 Tries to find a record based on its primary key or unique constraints; if none
2749 is found, creates one and returns that instead.
2750
2751   my $cd = $schema->resultset('CD')->find_or_create({
2752     cdid   => 5,
2753     artist => 'Massive Attack',
2754     title  => 'Mezzanine',
2755     year   => 2005,
2756   });
2757
2758 Also takes an optional C<key> attribute, to search by a specific key or unique
2759 constraint. For example:
2760
2761   my $cd = $schema->resultset('CD')->find_or_create(
2762     {
2763       artist => 'Massive Attack',
2764       title  => 'Mezzanine',
2765     },
2766     { key => 'cd_artist_title' }
2767   );
2768
2769 B<Note>: Make sure to read the documentation of L</find> and understand the
2770 significance of the C<key> attribute, as its lack may skew your search, and
2771 subsequently result in spurious row creation.
2772
2773 B<Note>: Because find_or_create() reads from the database and then
2774 possibly inserts based on the result, this method is subject to a race
2775 condition. Another process could create a record in the table after
2776 the find has completed and before the create has started. To avoid
2777 this problem, use find_or_create() inside a transaction.
2778
2779 B<Note>: Take care when using C<find_or_create> with a table having
2780 columns with default values that you intend to be automatically
2781 supplied by the database (e.g. an auto_increment primary key column).
2782 In normal usage, the value of such columns should NOT be included at
2783 all in the call to C<find_or_create>, even when set to C<undef>.
2784
2785 See also L</find> and L</update_or_create>. For information on how to declare
2786 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2787
2788 If you need to know if an existing row was found or a new one created use
2789 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2790 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2791 database!
2792
2793   my $cd = $schema->resultset('CD')->find_or_new({
2794     cdid   => 5,
2795     artist => 'Massive Attack',
2796     title  => 'Mezzanine',
2797     year   => 2005,
2798   });
2799
2800   if( !$cd->in_storage ) {
2801       # do some stuff
2802       $cd->insert;
2803   }
2804
2805 =cut
2806
2807 sub find_or_create {
2808   my $self     = shift;
2809   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2810   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2811   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2812     return $row;
2813   }
2814   return $self->create($hash);
2815 }
2816
2817 =head2 update_or_create
2818
2819 =over 4
2820
2821 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2822
2823 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2824
2825 =back
2826
2827   $resultset->update_or_create({ col => $val, ... });
2828
2829 Like L</find_or_create>, but if a row is found it is immediately updated via
2830 C<< $found_row->update (\%col_data) >>.
2831
2832
2833 Takes an optional C<key> attribute to search on a specific unique constraint.
2834 For example:
2835
2836   # In your application
2837   my $cd = $schema->resultset('CD')->update_or_create(
2838     {
2839       artist => 'Massive Attack',
2840       title  => 'Mezzanine',
2841       year   => 1998,
2842     },
2843     { key => 'cd_artist_title' }
2844   );
2845
2846   $cd->cd_to_producer->update_or_create({
2847     producer => $producer,
2848     name => 'harry',
2849   }, {
2850     key => 'primary',
2851   });
2852
2853 B<Note>: Make sure to read the documentation of L</find> and understand the
2854 significance of the C<key> attribute, as its lack may skew your search, and
2855 subsequently result in spurious row creation.
2856
2857 B<Note>: Take care when using C<update_or_create> with a table having
2858 columns with default values that you intend to be automatically
2859 supplied by the database (e.g. an auto_increment primary key column).
2860 In normal usage, the value of such columns should NOT be included at
2861 all in the call to C<update_or_create>, even when set to C<undef>.
2862
2863 See also L</find> and L</find_or_create>. For information on how to declare
2864 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2865
2866 If you need to know if an existing row was updated or a new one created use
2867 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2868 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2869 database!
2870
2871 =cut
2872
2873 sub update_or_create {
2874   my $self = shift;
2875   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2876   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2877
2878   my $row = $self->find($cond, $attrs);
2879   if (defined $row) {
2880     $row->update($cond);
2881     return $row;
2882   }
2883
2884   return $self->create($cond);
2885 }
2886
2887 =head2 update_or_new
2888
2889 =over 4
2890
2891 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2892
2893 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2894
2895 =back
2896
2897   $resultset->update_or_new({ col => $val, ... });
2898
2899 Like L</find_or_new> but if a row is found it is immediately updated via
2900 C<< $found_row->update (\%col_data) >>.
2901
2902 For example:
2903
2904   # In your application
2905   my $cd = $schema->resultset('CD')->update_or_new(
2906     {
2907       artist => 'Massive Attack',
2908       title  => 'Mezzanine',
2909       year   => 1998,
2910     },
2911     { key => 'cd_artist_title' }
2912   );
2913
2914   if ($cd->in_storage) {
2915       # the cd was updated
2916   }
2917   else {
2918       # the cd is not yet in the database, let's insert it
2919       $cd->insert;
2920   }
2921
2922 B<Note>: Make sure to read the documentation of L</find> and understand the
2923 significance of the C<key> attribute, as its lack may skew your search, and
2924 subsequently result in spurious new objects.
2925
2926 B<Note>: Take care when using C<update_or_new> with a table having
2927 columns with default values that you intend to be automatically
2928 supplied by the database (e.g. an auto_increment primary key column).
2929 In normal usage, the value of such columns should NOT be included at
2930 all in the call to C<update_or_new>, even when set to C<undef>.
2931
2932 See also L</find>, L</find_or_create> and L</find_or_new>.
2933
2934 =cut
2935
2936 sub update_or_new {
2937     my $self  = shift;
2938     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2939     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2940
2941     my $row = $self->find( $cond, $attrs );
2942     if ( defined $row ) {
2943         $row->update($cond);
2944         return $row;
2945     }
2946
2947     return $self->new_result($cond);
2948 }
2949
2950 =head2 get_cache
2951
2952 =over 4
2953
2954 =item Arguments: none
2955
2956 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2957
2958 =back
2959
2960 Gets the contents of the cache for the resultset, if the cache is set.
2961
2962 The cache is populated either by using the L</prefetch> attribute to
2963 L</search> or by calling L</set_cache>.
2964
2965 =cut
2966
2967 sub get_cache {
2968   shift->{all_cache};
2969 }
2970
2971 =head2 set_cache
2972
2973 =over 4
2974
2975 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2976
2977 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2978
2979 =back
2980
2981 Sets the contents of the cache for the resultset. Expects an arrayref
2982 of objects of the same class as those produced by the resultset. Note that
2983 if the cache is set, the resultset will return the cached objects rather
2984 than re-querying the database even if the cache attr is not set.
2985
2986 The contents of the cache can also be populated by using the
2987 L</prefetch> attribute to L</search>.
2988
2989 =cut
2990
2991 sub set_cache {
2992   my ( $self, $data ) = @_;
2993   $self->throw_exception("set_cache requires an arrayref")
2994       if defined($data) && (ref $data ne 'ARRAY');
2995   $self->{all_cache} = $data;
2996 }
2997
2998 =head2 clear_cache
2999
3000 =over 4
3001
3002 =item Arguments: none
3003
3004 =item Return Value: undef
3005
3006 =back
3007
3008 Clears the cache for the resultset.
3009
3010 =cut
3011
3012 sub clear_cache {
3013   shift->set_cache(undef);
3014 }
3015
3016 =head2 is_paged
3017
3018 =over 4
3019
3020 =item Arguments: none
3021
3022 =item Return Value: true, if the resultset has been paginated
3023
3024 =back
3025
3026 =cut
3027
3028 sub is_paged {
3029   my ($self) = @_;
3030   return !!$self->{attrs}{page};
3031 }
3032
3033 =head2 is_ordered
3034
3035 =over 4
3036
3037 =item Arguments: none
3038
3039 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3040
3041 =back
3042
3043 =cut
3044
3045 sub is_ordered {
3046   my ($self) = @_;
3047   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3048 }
3049
3050 =head2 related_resultset
3051
3052 =over 4
3053
3054 =item Arguments: $rel_name
3055
3056 =item Return Value: L<$resultset|/search>
3057
3058 =back
3059
3060 Returns a related resultset for the supplied relationship name.
3061
3062   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3063
3064 =cut
3065
3066 sub related_resultset {
3067   my ($self, $rel) = @_;
3068
3069   return $self->{related_resultsets}{$rel}
3070     if defined $self->{related_resultsets}{$rel};
3071
3072   return $self->{related_resultsets}{$rel} = do {
3073     my $rsrc = $self->result_source;
3074     my $rel_info = $rsrc->relationship_info($rel);
3075
3076     $self->throw_exception(
3077       "search_related: result source '" . $rsrc->source_name .
3078         "' has no such relationship $rel")
3079       unless $rel_info;
3080
3081     my $attrs = $self->_chain_relationship($rel);
3082
3083     my $join_count = $attrs->{seen_join}{$rel};
3084
3085     my $alias = $self->result_source->storage
3086         ->relname_to_table_alias($rel, $join_count);
3087
3088     # since this is search_related, and we already slid the select window inwards
3089     # (the select/as attrs were deleted in the beginning), we need to flip all
3090     # left joins to inner, so we get the expected results
3091     # read the comment on top of the actual function to see what this does
3092     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3093
3094
3095     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3096     delete @{$attrs}{qw(result_class alias)};
3097
3098     my $related_cache;
3099
3100     if (my $cache = $self->get_cache) {
3101       $related_cache = [ map
3102         { @{$_->related_resultset($rel)->get_cache||[]} }
3103         @$cache
3104       ];
3105     }
3106
3107     my $rel_source = $rsrc->related_source($rel);
3108
3109     my $new = do {
3110
3111       # The reason we do this now instead of passing the alias to the
3112       # search_rs below is that if you wrap/overload resultset on the
3113       # source you need to know what alias it's -going- to have for things
3114       # to work sanely (e.g. RestrictWithObject wants to be able to add
3115       # extra query restrictions, and these may need to be $alias.)
3116
3117       my $rel_attrs = $rel_source->resultset_attributes;
3118       local $rel_attrs->{alias} = $alias;
3119
3120       $rel_source->resultset
3121                  ->search_rs(
3122                      undef, {
3123                        %$attrs,
3124                        where => $attrs->{where},
3125                    });
3126     };
3127     $new->set_cache($related_cache) if $related_cache;
3128     $new;
3129   };
3130 }
3131
3132 =head2 current_source_alias
3133
3134 =over 4
3135
3136 =item Arguments: none
3137
3138 =item Return Value: $source_alias
3139
3140 =back
3141
3142 Returns the current table alias for the result source this resultset is built
3143 on, that will be used in the SQL query. Usually it is C<me>.
3144
3145 Currently the source alias that refers to the result set returned by a
3146 L</search>/L</find> family method depends on how you got to the resultset: it's
3147 C<me> by default, but eg. L</search_related> aliases it to the related result
3148 source name (and keeps C<me> referring to the original result set). The long
3149 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3150 (and make this method unnecessary).
3151
3152 Thus it's currently necessary to use this method in predefined queries (see
3153 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3154 source alias of the current result set:
3155
3156   # in a result set class
3157   sub modified_by {
3158     my ($self, $user) = @_;
3159
3160     my $me = $self->current_source_alias;
3161
3162     return $self->search({
3163       "$me.modified" => $user->id,
3164     });
3165   }
3166
3167 =cut
3168
3169 sub current_source_alias {
3170   return (shift->{attrs} || {})->{alias} || 'me';
3171 }
3172
3173 =head2 as_subselect_rs
3174
3175 =over 4
3176
3177 =item Arguments: none
3178
3179 =item Return Value: L<$resultset|/search>
3180
3181 =back
3182
3183 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3184 "virtual view" by including it as a subquery within the from clause.  From this
3185 point on, any joined tables are inaccessible to ->search on the resultset (as if
3186 it were simply where-filtered without joins).  For example:
3187
3188  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3189
3190  # 'x' now pollutes the query namespace
3191
3192  # So the following works as expected
3193  my $ok_rs = $rs->search({'x.other' => 1});
3194
3195  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3196  # def) we look for one row with contradictory terms and join in another table
3197  # (aliased 'x_2') which we never use
3198  my $broken_rs = $rs->search({'x.name' => 'def'});
3199
3200  my $rs2 = $rs->as_subselect_rs;
3201
3202  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3203  my $not_joined_rs = $rs2->search({'x.other' => 1});
3204
3205  # works as expected: finds a 'table' row related to two x rows (abc and def)
3206  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3207
3208 Another example of when one might use this would be to select a subset of
3209 columns in a group by clause:
3210
3211  my $rs = $schema->resultset('Bar')->search(undef, {
3212    group_by => [qw{ id foo_id baz_id }],
3213  })->as_subselect_rs->search(undef, {
3214    columns => [qw{ id foo_id }]
3215  });
3216
3217 In the above example normally columns would have to be equal to the group by,
3218 but because we isolated the group by into a subselect the above works.
3219
3220 =cut
3221
3222 sub as_subselect_rs {
3223   my $self = shift;
3224
3225   my $attrs = $self->_resolved_attrs;
3226
3227   my $fresh_rs = (ref $self)->new (
3228     $self->result_source
3229   );
3230
3231   # these pieces will be locked in the subquery
3232   delete $fresh_rs->{cond};
3233   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3234
3235   return $fresh_rs->search( {}, {
3236     from => [{
3237       $attrs->{alias} => $self->as_query,
3238       -alias  => $attrs->{alias},
3239       -rsrc   => $self->result_source,
3240     }],
3241     alias => $attrs->{alias},
3242   });
3243 }
3244
3245 # This code is called by search_related, and makes sure there
3246 # is clear separation between the joins before, during, and
3247 # after the relationship. This information is needed later
3248 # in order to properly resolve prefetch aliases (any alias
3249 # with a relation_chain_depth less than the depth of the
3250 # current prefetch is not considered)
3251 #
3252 # The increments happen twice per join. An even number means a
3253 # relationship specified via a search_related, whereas an odd
3254 # number indicates a join/prefetch added via attributes
3255 #
3256 # Also this code will wrap the current resultset (the one we
3257 # chain to) in a subselect IFF it contains limiting attributes
3258 sub _chain_relationship {
3259   my ($self, $rel) = @_;
3260   my $source = $self->result_source;
3261   my $attrs = { %{$self->{attrs}||{}} };
3262
3263   # we need to take the prefetch the attrs into account before we
3264   # ->_resolve_join as otherwise they get lost - captainL
3265   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3266
3267   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3268
3269   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3270
3271   my $from;
3272   my @force_subq_attrs = qw/offset rows group_by having/;
3273
3274   if (
3275     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3276       ||
3277     $self->_has_resolved_attr (@force_subq_attrs)
3278   ) {
3279     # Nuke the prefetch (if any) before the new $rs attrs
3280     # are resolved (prefetch is useless - we are wrapping
3281     # a subquery anyway).
3282     my $rs_copy = $self->search;
3283     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3284       $rs_copy->{attrs}{join},
3285       delete $rs_copy->{attrs}{prefetch},
3286     );
3287
3288     $from = [{
3289       -rsrc   => $source,
3290       -alias  => $attrs->{alias},
3291       $attrs->{alias} => $rs_copy->as_query,
3292     }];
3293     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3294     $seen->{-relation_chain_depth} = 0;
3295   }
3296   elsif ($attrs->{from}) {  #shallow copy suffices
3297     $from = [ @{$attrs->{from}} ];
3298   }
3299   else {
3300     $from = [{
3301       -rsrc  => $source,
3302       -alias => $attrs->{alias},
3303       $attrs->{alias} => $source->from,
3304     }];
3305   }
3306
3307   my $jpath = ($seen->{-relation_chain_depth})
3308     ? $from->[-1][0]{-join_path}
3309     : [];
3310
3311   my @requested_joins = $source->_resolve_join(
3312     $join,
3313     $attrs->{alias},
3314     $seen,
3315     $jpath,
3316   );
3317
3318   push @$from, @requested_joins;
3319
3320   $seen->{-relation_chain_depth}++;
3321
3322   # if $self already had a join/prefetch specified on it, the requested
3323   # $rel might very well be already included. What we do in this case
3324   # is effectively a no-op (except that we bump up the chain_depth on
3325   # the join in question so we could tell it *is* the search_related)
3326   my $already_joined;
3327
3328   # we consider the last one thus reverse
3329   for my $j (reverse @requested_joins) {
3330     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3331     if ($rel eq $last_j) {
3332       $j->[0]{-relation_chain_depth}++;
3333       $already_joined++;
3334       last;
3335     }
3336   }
3337
3338   unless ($already_joined) {
3339     push @$from, $source->_resolve_join(
3340       $rel,
3341       $attrs->{alias},
3342       $seen,
3343       $jpath,
3344     );
3345   }
3346
3347   $seen->{-relation_chain_depth}++;
3348
3349   return {%$attrs, from => $from, seen_join => $seen};
3350 }
3351
3352 sub _resolved_attrs {
3353   my $self = shift;
3354   return $self->{_attrs} if $self->{_attrs};
3355
3356   my $attrs  = { %{ $self->{attrs} || {} } };
3357   my $source = $self->result_source;
3358   my $alias  = $attrs->{alias};
3359
3360   # default selection list
3361   $attrs->{columns} = [ $source->columns ]
3362     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3363
3364   # merge selectors together
3365   for (qw/columns select as/) {
3366     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3367       if $attrs->{$_} or $attrs->{"+$_"};
3368   }
3369
3370   # disassemble columns
3371   my (@sel, @as);
3372   if (my $cols = delete $attrs->{columns}) {
3373     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3374       if (ref $c eq 'HASH') {
3375         for my $as (sort keys %$c) {
3376           push @sel, $c->{$as};
3377           push @as, $as;
3378         }
3379       }
3380       else {
3381         push @sel, $c;
3382         push @as, $c;
3383       }
3384     }
3385   }
3386
3387   # when trying to weed off duplicates later do not go past this point -
3388   # everything added from here on is unbalanced "anyone's guess" stuff
3389   my $dedup_stop_idx = $#as;
3390
3391   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3392     if $attrs->{as};
3393   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3394     if $attrs->{select};
3395
3396   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3397   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3398
3399   # disqualify all $alias.col as-bits (inflate-map mandated)
3400   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3401
3402   # de-duplicate the result (remove *identical* select/as pairs)
3403   # and also die on duplicate {as} pointing to different {select}s
3404   # not using a c-style for as the condition is prone to shrinkage
3405   my $seen;
3406   my $i = 0;
3407   while ($i <= $dedup_stop_idx) {
3408     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3409       splice @sel, $i, 1;
3410       splice @as, $i, 1;
3411       $dedup_stop_idx--;
3412     }
3413     elsif ($seen->{$as[$i]}++) {
3414       $self->throw_exception(
3415         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3416       );
3417     }
3418     else {
3419       $i++;
3420     }
3421   }
3422
3423   $attrs->{select} = \@sel;
3424   $attrs->{as} = \@as;
3425
3426   $attrs->{from} ||= [{
3427     -rsrc   => $source,
3428     -alias  => $self->{attrs}{alias},
3429     $self->{attrs}{alias} => $source->from,
3430   }];
3431
3432   if ( $attrs->{join} || $attrs->{prefetch} ) {
3433
3434     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3435       if ref $attrs->{from} ne 'ARRAY';
3436
3437     my $join = (delete $attrs->{join}) || {};
3438
3439     if ( defined $attrs->{prefetch} ) {
3440       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3441     }
3442
3443     $attrs->{from} =    # have to copy here to avoid corrupting the original
3444       [
3445         @{ $attrs->{from} },
3446         $source->_resolve_join(
3447           $join,
3448           $alias,
3449           { %{ $attrs->{seen_join} || {} } },
3450           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3451             ? $attrs->{from}[-1][0]{-join_path}
3452             : []
3453           ,
3454         )
3455       ];
3456   }
3457
3458   if ( defined $attrs->{order_by} ) {
3459     $attrs->{order_by} = (
3460       ref( $attrs->{order_by} ) eq 'ARRAY'
3461       ? [ @{ $attrs->{order_by} } ]
3462       : [ $attrs->{order_by} || () ]
3463     );
3464   }
3465
3466   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3467     $attrs->{group_by} = [ $attrs->{group_by} ];
3468   }
3469
3470   # generate the distinct induced group_by early, as prefetch will be carried via a
3471   # subquery (since a group_by is present)
3472   if (delete $attrs->{distinct}) {
3473     if ($attrs->{group_by}) {
3474       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3475     }
3476     else {
3477       $attrs->{_grouped_by_distinct} = 1;
3478       # distinct affects only the main selection part, not what prefetch may
3479       # add below.
3480       $attrs->{group_by} = $source->storage->_group_over_selection (
3481         $attrs->{from},
3482         $attrs->{select},
3483         $attrs->{order_by},
3484       );
3485     }
3486   }
3487
3488   # generate selections based on the prefetch helper
3489   my $prefetch;
3490   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3491     if defined $attrs->{prefetch};
3492
3493   if ($prefetch) {
3494
3495     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3496       if $attrs->{_dark_selector};
3497
3498     $attrs->{collapse} = 1;
3499
3500     # this is a separate structure (we don't look in {from} directly)
3501     # as the resolver needs to shift things off the lists to work
3502     # properly (identical-prefetches on different branches)
3503     my $join_map = {};
3504     if (ref $attrs->{from} eq 'ARRAY') {
3505
3506       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3507
3508       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3509         next unless $j->[0]{-alias};
3510         next unless $j->[0]{-join_path};
3511         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3512
3513         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3514
3515         my $p = $join_map;
3516         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3517         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3518       }
3519     }
3520
3521     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3522
3523     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3524     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3525   }
3526
3527   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3528     $attrs->{_related_results_construction} = 1;
3529   }
3530   else {
3531     $attrs->{collapse} = 0;
3532   }
3533
3534   # run through the resulting joinstructure (starting from our current slot)
3535   # and unset collapse if proven unnesessary
3536   #
3537   # also while we are at it find out if the current root source has
3538   # been premultiplied by previous related_source chaining
3539   #
3540   # this allows to predict whether a root object with all other relation
3541   # data set to NULL is in fact unique
3542   if ($attrs->{collapse}) {
3543
3544     if (ref $attrs->{from} eq 'ARRAY') {
3545
3546       if (@{$attrs->{from}} <= 1) {
3547         # no joins - no collapse
3548         $attrs->{collapse} = 0;
3549       }
3550       else {
3551         # find where our table-spec starts
3552         my @fromlist = @{$attrs->{from}};
3553         while (@fromlist) {
3554           my $t = shift @fromlist;
3555
3556           my $is_multi;
3557           # me vs join from-spec distinction - a ref means non-root
3558           if (ref $t eq 'ARRAY') {
3559             $t = $t->[0];
3560             $is_multi ||= ! $t->{-is_single};
3561           }
3562           last if ($t->{-alias} && $t->{-alias} eq $alias);
3563           $attrs->{_main_source_premultiplied} ||= $is_multi;
3564         }
3565
3566         # no non-singles remaining, nor any premultiplication - nothing to collapse
3567         if (
3568           ! $attrs->{_main_source_premultiplied}
3569             and
3570           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3571         ) {
3572           $attrs->{collapse} = 0;
3573         }
3574       }
3575     }
3576
3577     else {
3578       # if we can not analyze the from - err on the side of safety
3579       $attrs->{_main_source_premultiplied} = 1;
3580     }
3581   }
3582
3583   # if both page and offset are specified, produce a combined offset
3584   # even though it doesn't make much sense, this is what pre 081xx has
3585   # been doing
3586   if (my $page = delete $attrs->{page}) {
3587     $attrs->{offset} =
3588       ($attrs->{rows} * ($page - 1))
3589             +
3590       ($attrs->{offset} || 0)
3591     ;
3592   }
3593
3594   return $self->{_attrs} = $attrs;
3595 }
3596
3597 sub _rollout_attr {
3598   my ($self, $attr) = @_;
3599
3600   if (ref $attr eq 'HASH') {
3601     return $self->_rollout_hash($attr);
3602   } elsif (ref $attr eq 'ARRAY') {
3603     return $self->_rollout_array($attr);
3604   } else {
3605     return [$attr];
3606   }
3607 }
3608
3609 sub _rollout_array {
3610   my ($self, $attr) = @_;
3611
3612   my @rolled_array;
3613   foreach my $element (@{$attr}) {
3614     if (ref $element eq 'HASH') {
3615       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3616     } elsif (ref $element eq 'ARRAY') {
3617       #  XXX - should probably recurse here
3618       push( @rolled_array, @{$self->_rollout_array($element)} );
3619     } else {
3620       push( @rolled_array, $element );
3621     }
3622   }
3623   return \@rolled_array;
3624 }
3625
3626 sub _rollout_hash {
3627   my ($self, $attr) = @_;
3628
3629   my @rolled_array;
3630   foreach my $key (keys %{$attr}) {
3631     push( @rolled_array, { $key => $attr->{$key} } );
3632   }
3633   return \@rolled_array;
3634 }
3635
3636 sub _calculate_score {
3637   my ($self, $a, $b) = @_;
3638
3639   if (defined $a xor defined $b) {
3640     return 0;
3641   }
3642   elsif (not defined $a) {
3643     return 1;
3644   }
3645
3646   if (ref $b eq 'HASH') {
3647     my ($b_key) = keys %{$b};
3648     if (ref $a eq 'HASH') {
3649       my ($a_key) = keys %{$a};
3650       if ($a_key eq $b_key) {
3651         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3652       } else {
3653         return 0;
3654       }
3655     } else {
3656       return ($a eq $b_key) ? 1 : 0;
3657     }
3658   } else {
3659     if (ref $a eq 'HASH') {
3660       my ($a_key) = keys %{$a};
3661       return ($b eq $a_key) ? 1 : 0;
3662     } else {
3663       return ($b eq $a) ? 1 : 0;
3664     }
3665   }
3666 }
3667
3668 sub _merge_joinpref_attr {
3669   my ($self, $orig, $import) = @_;
3670
3671   return $import unless defined($orig);
3672   return $orig unless defined($import);
3673
3674   $orig = $self->_rollout_attr($orig);
3675   $import = $self->_rollout_attr($import);
3676
3677   my $seen_keys;
3678   foreach my $import_element ( @{$import} ) {
3679     # find best candidate from $orig to merge $b_element into
3680     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3681     foreach my $orig_element ( @{$orig} ) {
3682       my $score = $self->_calculate_score( $orig_element, $import_element );
3683       if ($score > $best_candidate->{score}) {
3684         $best_candidate->{position} = $position;
3685         $best_candidate->{score} = $score;
3686       }
3687       $position++;
3688     }
3689     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3690     $import_key = '' if not defined $import_key;
3691
3692     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3693       push( @{$orig}, $import_element );
3694     } else {
3695       my $orig_best = $orig->[$best_candidate->{position}];
3696       # merge orig_best and b_element together and replace original with merged
3697       if (ref $orig_best ne 'HASH') {
3698         $orig->[$best_candidate->{position}] = $import_element;
3699       } elsif (ref $import_element eq 'HASH') {
3700         my ($key) = keys %{$orig_best};
3701         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3702       }
3703     }
3704     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3705   }
3706
3707   return @$orig ? $orig : ();
3708 }
3709
3710 {
3711   my $hm;
3712
3713   sub _merge_attr {
3714     $hm ||= do {
3715       require Hash::Merge;
3716       my $hm = Hash::Merge->new;
3717
3718       $hm->specify_behavior({
3719         SCALAR => {
3720           SCALAR => sub {
3721             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3722
3723             if ($defl xor $defr) {
3724               return [ $defl ? $_[0] : $_[1] ];
3725             }
3726             elsif (! $defl) {
3727               return [];
3728             }
3729             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3730               return [ $_[0] ];
3731             }
3732             else {
3733               return [$_[0], $_[1]];
3734             }
3735           },
3736           ARRAY => sub {
3737             return $_[1] if !defined $_[0];
3738             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3739             return [$_[0], @{$_[1]}]
3740           },
3741           HASH  => sub {
3742             return [] if !defined $_[0] and !keys %{$_[1]};
3743             return [ $_[1] ] if !defined $_[0];
3744             return [ $_[0] ] if !keys %{$_[1]};
3745             return [$_[0], $_[1]]
3746           },
3747         },
3748         ARRAY => {
3749           SCALAR => sub {
3750             return $_[0] if !defined $_[1];
3751             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3752             return [@{$_[0]}, $_[1]]
3753           },
3754           ARRAY => sub {
3755             my @ret = @{$_[0]} or return $_[1];
3756             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3757             my %idx = map { $_ => 1 } @ret;
3758             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3759             \@ret;
3760           },
3761           HASH => sub {
3762             return [ $_[1] ] if ! @{$_[0]};
3763             return $_[0] if !keys %{$_[1]};
3764             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3765             return [ @{$_[0]}, $_[1] ];
3766           },
3767         },
3768         HASH => {
3769           SCALAR => sub {
3770             return [] if !keys %{$_[0]} and !defined $_[1];
3771             return [ $_[0] ] if !defined $_[1];
3772             return [ $_[1] ] if !keys %{$_[0]};
3773             return [$_[0], $_[1]]
3774           },
3775           ARRAY => sub {
3776             return [] if !keys %{$_[0]} and !@{$_[1]};
3777             return [ $_[0] ] if !@{$_[1]};
3778             return $_[1] if !keys %{$_[0]};
3779             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3780             return [ $_[0], @{$_[1]} ];
3781           },
3782           HASH => sub {
3783             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3784             return [ $_[0] ] if !keys %{$_[1]};
3785             return [ $_[1] ] if !keys %{$_[0]};
3786             return [ $_[0] ] if $_[0] eq $_[1];
3787             return [ $_[0], $_[1] ];
3788           },
3789         }
3790       } => 'DBIC_RS_ATTR_MERGER');
3791       $hm;
3792     };
3793
3794     return $hm->merge ($_[1], $_[2]);
3795   }
3796 }
3797
3798 sub STORABLE_freeze {
3799   my ($self, $cloning) = @_;
3800   my $to_serialize = { %$self };
3801
3802   # A cursor in progress can't be serialized (and would make little sense anyway)
3803   # the parser can be regenerated (and can't be serialized)
3804   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3805
3806   # nor is it sensical to store a not-yet-fired-count pager
3807   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3808     delete $to_serialize->{pager};
3809   }
3810
3811   Storable::nfreeze($to_serialize);
3812 }
3813
3814 # need this hook for symmetry
3815 sub STORABLE_thaw {
3816   my ($self, $cloning, $serialized) = @_;
3817
3818   %$self = %{ Storable::thaw($serialized) };
3819
3820   $self;
3821 }
3822
3823
3824 =head2 throw_exception
3825
3826 See L<DBIx::Class::Schema/throw_exception> for details.
3827
3828 =cut
3829
3830 sub throw_exception {
3831   my $self=shift;
3832
3833   if (ref $self and my $rsrc = $self->result_source) {
3834     $rsrc->throw_exception(@_)
3835   }
3836   else {
3837     DBIx::Class::Exception->throw(@_);
3838   }
3839 }
3840
3841 1;
3842
3843 __END__
3844
3845 # XXX: FIXME: Attributes docs need clearing up
3846
3847 =head1 ATTRIBUTES
3848
3849 Attributes are used to refine a ResultSet in various ways when
3850 searching for data. They can be passed to any method which takes an
3851 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3852 L</count>.
3853
3854 Default attributes can be set on the result class using
3855 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3856 the CAVEATS on that feature before using it!)
3857
3858 These are in no particular order:
3859
3860 =head2 order_by
3861
3862 =over 4
3863
3864 =item Value: ( $order_by | \@order_by | \%order_by )
3865
3866 =back
3867
3868 Which column(s) to order the results by.
3869
3870 [The full list of suitable values is documented in
3871 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3872 common options.]
3873
3874 If a single column name, or an arrayref of names is supplied, the
3875 argument is passed through directly to SQL. The hashref syntax allows
3876 for connection-agnostic specification of ordering direction:
3877
3878  For descending order:
3879
3880   order_by => { -desc => [qw/col1 col2 col3/] }
3881
3882  For explicit ascending order:
3883
3884   order_by => { -asc => 'col' }
3885
3886 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3887 supported, although you are strongly encouraged to use the hashref
3888 syntax as outlined above.
3889
3890 =head2 columns
3891
3892 =over 4
3893
3894 =item Value: \@columns | \%columns | $column
3895
3896 =back
3897
3898 Shortcut to request a particular set of columns to be retrieved. Each
3899 column spec may be a string (a table column name), or a hash (in which
3900 case the key is the C<as> value, and the value is used as the C<select>
3901 expression). Adds C<me.> onto the start of any column without a C<.> in
3902 it and sets C<select> from that, then auto-populates C<as> from
3903 C<select> as normal. (You may also use the C<cols> attribute, as in
3904 earlier versions of DBIC, but this is deprecated.)
3905
3906 Essentially C<columns> does the same as L</select> and L</as>.
3907
3908     columns => [ 'foo', { bar => 'baz' } ]
3909
3910 is the same as
3911
3912     select => [qw/foo baz/],
3913     as => [qw/foo bar/]
3914
3915 =head2 +columns
3916
3917 =over 4
3918
3919 =item Value: \@columns
3920
3921 =back
3922
3923 Indicates additional columns to be selected from storage. Works the same as
3924 L</columns> but adds columns to the selection. (You may also use the
3925 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3926 deprecated). For example:-
3927
3928   $schema->resultset('CD')->search(undef, {
3929     '+columns' => ['artist.name'],
3930     join => ['artist']
3931   });
3932
3933 would return all CDs and include a 'name' column to the information
3934 passed to object inflation. Note that the 'artist' is the name of the
3935 column (or relationship) accessor, and 'name' is the name of the column
3936 accessor in the related table.
3937
3938 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3939 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3940 unary plus operator before it.
3941
3942 =head2 include_columns
3943
3944 =over 4
3945
3946 =item Value: \@columns
3947
3948 =back
3949
3950 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3951
3952 =head2 select
3953
3954 =over 4
3955
3956 =item Value: \@select_columns
3957
3958 =back
3959
3960 Indicates which columns should be selected from the storage. You can use
3961 column names, or in the case of RDBMS back ends, function or stored procedure
3962 names:
3963
3964   $rs = $schema->resultset('Employee')->search(undef, {
3965     select => [
3966       'name',
3967       { count => 'employeeid' },
3968       { max => { length => 'name' }, -as => 'longest_name' }
3969     ]
3970   });
3971
3972   # Equivalent SQL
3973   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3974
3975 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3976 use L</select>, to instruct DBIx::Class how to store the result of the column.
3977 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3978 identifier aliasing. You can however alias a function, so you can use it in
3979 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3980 attribute> supplied as shown in the example above.
3981
3982 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3983 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3984 unary plus operator before it.
3985
3986 =head2 +select
3987
3988 =over 4
3989
3990 Indicates additional columns to be selected from storage.  Works the same as
3991 L</select> but adds columns to the default selection, instead of specifying
3992 an explicit list.
3993
3994 =back
3995
3996 =head2 as
3997
3998 =over 4
3999
4000 =item Value: \@inflation_names
4001
4002 =back
4003
4004 Indicates column names for object inflation. That is L</as> indicates the
4005 slot name in which the column value will be stored within the
4006 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4007 identifier by the C<get_column> method (or via the object accessor B<if one
4008 with the same name already exists>) as shown below. The L</as> attribute has
4009 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4010
4011   $rs = $schema->resultset('Employee')->search(undef, {
4012     select => [
4013       'name',
4014       { count => 'employeeid' },
4015       { max => { length => 'name' }, -as => 'longest_name' }
4016     ],
4017     as => [qw/
4018       name
4019       employee_count
4020       max_name_length
4021     /],
4022   });
4023
4024 If the object against which the search is performed already has an accessor
4025 matching a column name specified in C<as>, the value can be retrieved using
4026 the accessor as normal:
4027
4028   my $name = $employee->name();
4029
4030 If on the other hand an accessor does not exist in the object, you need to
4031 use C<get_column> instead:
4032
4033   my $employee_count = $employee->get_column('employee_count');
4034
4035 You can create your own accessors if required - see
4036 L<DBIx::Class::Manual::Cookbook> for details.
4037
4038 =head2 +as
4039
4040 =over 4
4041
4042 Indicates additional column names for those added via L</+select>. See L</as>.
4043
4044 =back
4045
4046 =head2 join
4047
4048 =over 4
4049
4050 =item Value: ($rel_name | \@rel_names | \%rel_names)
4051
4052 =back
4053
4054 Contains a list of relationships that should be joined for this query.  For
4055 example:
4056
4057   # Get CDs by Nine Inch Nails
4058   my $rs = $schema->resultset('CD')->search(
4059     { 'artist.name' => 'Nine Inch Nails' },
4060     { join => 'artist' }
4061   );
4062
4063 Can also contain a hash reference to refer to the other relation's relations.
4064 For example:
4065
4066   package MyApp::Schema::Track;
4067   use base qw/DBIx::Class/;
4068   __PACKAGE__->table('track');
4069   __PACKAGE__->add_columns(qw/trackid cd position title/);
4070   __PACKAGE__->set_primary_key('trackid');
4071   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4072   1;
4073
4074   # In your application
4075   my $rs = $schema->resultset('Artist')->search(
4076     { 'track.title' => 'Teardrop' },
4077     {
4078       join     => { cd => 'track' },
4079       order_by => 'artist.name',
4080     }
4081   );
4082
4083 You need to use the relationship (not the table) name in  conditions,
4084 because they are aliased as such. The current table is aliased as "me", so
4085 you need to use me.column_name in order to avoid ambiguity. For example:
4086
4087   # Get CDs from 1984 with a 'Foo' track
4088   my $rs = $schema->resultset('CD')->search(
4089     {
4090       'me.year' => 1984,
4091       'tracks.name' => 'Foo'
4092     },
4093     { join => 'tracks' }
4094   );
4095
4096 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4097 similarly for a third time). For e.g.
4098
4099   my $rs = $schema->resultset('Artist')->search({
4100     'cds.title'   => 'Down to Earth',
4101     'cds_2.title' => 'Popular',
4102   }, {
4103     join => [ qw/cds cds/ ],
4104   });
4105
4106 will return a set of all artists that have both a cd with title 'Down
4107 to Earth' and a cd with title 'Popular'.
4108
4109 If you want to fetch related objects from other tables as well, see L</prefetch>
4110 below.
4111
4112  NOTE: An internal join-chain pruner will discard certain joins while
4113  constructing the actual SQL query, as long as the joins in question do not
4114  affect the retrieved result. This for example includes 1:1 left joins
4115  that are not part of the restriction specification (WHERE/HAVING) nor are
4116  a part of the query selection.
4117
4118 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4119
4120 =head2 collapse
4121
4122 =over 4
4123
4124 =item Value: (0 | 1)
4125
4126 =back
4127
4128 When set to a true value, indicates that any rows fetched from joined has_many
4129 relationships are to be aggregated into the corresponding "parent" object. For
4130 example, the resultset:
4131
4132   my $rs = $schema->resultset('CD')->search({}, {
4133     '+columns' => [ qw/ tracks.title tracks.position / ],
4134     join => 'tracks',
4135     collapse => 1,
4136   });
4137
4138 While executing the following query:
4139
4140   SELECT me.*, tracks.title, tracks.position
4141     FROM cd me
4142     LEFT JOIN track tracks
4143       ON tracks.cdid = me.cdid
4144
4145 Will return only as many objects as there are rows in the CD source, even
4146 though the result of the query may span many rows. Each of these CD objects
4147 will in turn have multiple "Track" objects hidden behind the has_many
4148 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4149 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4150 product"), with each CD object containing exactly one of all fetched Track data.
4151
4152 When a collapse is requested on a non-ordered resultset, an order by some
4153 unique part of the main source (the left-most table) is inserted automatically.
4154 This is done so that the resultset is allowed to be "lazy" - calling
4155 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4156 object with all of its related data.
4157
4158 If an L</order_by> is already declared, and orders the resultset in a way that
4159 makes collapsing as described above impossible (e.g. C<< ORDER BY
4160 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4161 switch to "eager" mode and slurp the entire resultset before consturcting the
4162 first object returned by L</next>.
4163
4164 Setting this attribute on a resultset that does not join any has_many
4165 relations is a no-op.
4166
4167 For a more in-depth discussion, see L</PREFETCHING>.
4168
4169 =head2 prefetch
4170
4171 =over 4
4172
4173 =item Value: ($rel_name | \@rel_names | \%rel_names)
4174
4175 =back
4176
4177 This attribute is a shorthand for specifying a L</join> spec, adding all
4178 columns from the joined related sources as L</+columns> and setting
4179 L</collapse> to a true value. For example, the following two queries are
4180 equivalent:
4181
4182   my $rs = $schema->resultset('Artist')->search({}, {
4183     prefetch => { cds => ['genre', 'tracks' ] },
4184   });
4185
4186 and
4187
4188   my $rs = $schema->resultset('Artist')->search({}, {
4189     join => { cds => ['genre', 'tracks' ] },
4190     collapse => 1,
4191     '+columns' => [
4192       (map
4193         { +{ "cds.$_" => "cds.$_" } }
4194         $schema->source('Artist')->related_source('cds')->columns
4195       ),
4196       (map
4197         { +{ "cds.genre.$_" => "genre.$_" } }
4198         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4199       ),
4200       (map
4201         { +{ "cds.tracks.$_" => "tracks.$_" } }
4202         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4203       ),
4204     ],
4205   });
4206
4207 Both producing the following SQL:
4208
4209   SELECT  me.artistid, me.name, me.rank, me.charfield,
4210           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4211           genre.genreid, genre.name,
4212           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4213     FROM artist me
4214     LEFT JOIN cd cds
4215       ON cds.artist = me.artistid
4216     LEFT JOIN genre genre
4217       ON genre.genreid = cds.genreid
4218     LEFT JOIN track tracks
4219       ON tracks.cd = cds.cdid
4220   ORDER BY me.artistid
4221
4222 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4223 the arguments are properly merged and generally do the right thing. For
4224 example, you may want to do the following:
4225
4226   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4227     { 'genre.genreid' => undef },
4228     {
4229       join => { cds => 'genre' },
4230       prefetch => 'cds',
4231     }
4232   );
4233
4234 Which generates the following SQL:
4235
4236   SELECT  me.artistid, me.name, me.rank, me.charfield,
4237           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4238     FROM artist me
4239     LEFT JOIN cd cds
4240       ON cds.artist = me.artistid
4241     LEFT JOIN genre genre
4242       ON genre.genreid = cds.genreid
4243   WHERE genre.genreid IS NULL
4244   ORDER BY me.artistid
4245
4246 For a more in-depth discussion, see L</PREFETCHING>.
4247
4248 =head2 alias
4249
4250 =over 4
4251
4252 =item Value: $source_alias
4253
4254 =back
4255
4256 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4257 nested search queries (sub-SELECTs) might need specific aliases set to
4258 reference inner queries.  For example:
4259
4260    my $q = $rs
4261       ->related_resultset('CDs')
4262       ->related_resultset('Tracks')
4263       ->search({
4264          'track.id' => { -ident => 'none_search.id' },
4265       })
4266       ->as_query;
4267
4268    my $ids = $self->search({
4269       -not_exists => $q,
4270    }, {
4271       alias    => 'none_search',
4272       group_by => 'none_search.id',
4273    })->get_column('id')->as_query;
4274
4275    $self->search({ id => { -in => $ids } })
4276
4277 This attribute is directly tied to L</current_source_alias>.
4278
4279 =head2 page
4280
4281 =over 4
4282
4283 =item Value: $page
4284
4285 =back
4286
4287 Makes the resultset paged and specifies the page to retrieve. Effectively
4288 identical to creating a non-pages resultset and then calling ->page($page)
4289 on it.
4290
4291 If L</rows> attribute is not specified it defaults to 10 rows per page.
4292
4293 When you have a paged resultset, L</count> will only return the number
4294 of rows in the page. To get the total, use the L</pager> and call
4295 C<total_entries> on it.
4296
4297 =head2 rows
4298
4299 =over 4
4300
4301 =item Value: $rows
4302
4303 =back
4304
4305 Specifies the maximum number of rows for direct retrieval or the number of
4306 rows per page if the page attribute or method is used.
4307
4308 =head2 offset
4309
4310 =over 4
4311
4312 =item Value: $offset
4313
4314 =back
4315
4316 Specifies the (zero-based) row number for the  first row to be returned, or the
4317 of the first row of the first page if paging is used.
4318
4319 =head2 software_limit
4320
4321 =over 4
4322
4323 =item Value: (0 | 1)
4324
4325 =back
4326
4327 When combined with L</rows> and/or L</offset> the generated SQL will not
4328 include any limit dialect stanzas. Instead the entire result will be selected
4329 as if no limits were specified, and DBIC will perform the limit locally, by
4330 artificially advancing and finishing the resulting L</cursor>.
4331
4332 This is the recommended way of performing resultset limiting when no sane RDBMS
4333 implementation is available (e.g.
4334 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4335 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4336
4337 =head2 group_by
4338
4339 =over 4
4340
4341 =item Value: \@columns
4342
4343 =back
4344
4345 A arrayref of columns to group by. Can include columns of joined tables.
4346
4347   group_by => [qw/ column1 column2 ... /]
4348
4349 =head2 having
4350
4351 =over 4
4352
4353 =item Value: $condition
4354
4355 =back
4356
4357 HAVING is a select statement attribute that is applied between GROUP BY and
4358 ORDER BY. It is applied to the after the grouping calculations have been
4359 done.
4360
4361   having => { 'count_employee' => { '>=', 100 } }
4362
4363 or with an in-place function in which case literal SQL is required:
4364
4365   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4366
4367 =head2 distinct
4368
4369 =over 4
4370
4371 =item Value: (0 | 1)
4372
4373 =back
4374
4375 Set to 1 to group by all columns. If the resultset already has a group_by
4376 attribute, this setting is ignored and an appropriate warning is issued.
4377
4378 =head2 where
4379
4380 =over 4
4381
4382 Adds to the WHERE clause.
4383
4384   # only return rows WHERE deleted IS NULL for all searches
4385   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4386
4387 Can be overridden by passing C<< { where => undef } >> as an attribute
4388 to a resultset.
4389
4390 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4391
4392 =back
4393
4394 =head2 cache
4395
4396 Set to 1 to cache search results. This prevents extra SQL queries if you
4397 revisit rows in your ResultSet:
4398
4399   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4400
4401   while( my $artist = $resultset->next ) {
4402     ... do stuff ...
4403   }
4404
4405   $rs->first; # without cache, this would issue a query
4406
4407 By default, searches are not cached.
4408
4409 For more examples of using these attributes, see
4410 L<DBIx::Class::Manual::Cookbook>.
4411
4412 =head2 for
4413
4414 =over 4
4415
4416 =item Value: ( 'update' | 'shared' | \$scalar )
4417
4418 =back
4419
4420 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4421 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4422 query.
4423
4424 =head1 PREFETCHING
4425
4426 DBIx::Class supports arbitrary related data prefetching from multiple related
4427 sources. Any combination of relationship types and column sets are supported.
4428 If L<collapsing|/collapse> is requested, there is an additional requirement of
4429 selecting enough data to make every individual object uniquely identifiable.
4430
4431 Here are some more involved examples, based on the following relationship map:
4432
4433   # Assuming:
4434   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4435   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4436   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4437
4438   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4439
4440   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4441
4442
4443
4444   my $rs = $schema->resultset('Tag')->search(
4445     undef,
4446     {
4447       prefetch => {
4448         cd => 'artist'
4449       }
4450     }
4451   );
4452
4453 The initial search results in SQL like the following:
4454
4455   SELECT tag.*, cd.*, artist.* FROM tag
4456   JOIN cd ON tag.cd = cd.cdid
4457   JOIN artist ON cd.artist = artist.artistid
4458
4459 L<DBIx::Class> has no need to go back to the database when we access the
4460 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4461 case.
4462
4463 Simple prefetches will be joined automatically, so there is no need
4464 for a C<join> attribute in the above search.
4465
4466 The L</prefetch> attribute can be used with any of the relationship types
4467 and multiple prefetches can be specified together. Below is a more complex
4468 example that prefetches a CD's artist, its liner notes (if present),
4469 the cover image, the tracks on that CD, and the guests on those
4470 tracks.
4471
4472   my $rs = $schema->resultset('CD')->search(
4473     undef,
4474     {
4475       prefetch => [
4476         { artist => 'record_label'},  # belongs_to => belongs_to
4477         'liner_note',                 # might_have
4478         'cover_image',                # has_one
4479         { tracks => 'guests' },       # has_many => has_many
4480       ]
4481     }
4482   );
4483
4484 This will produce SQL like the following:
4485
4486   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4487          tracks.*, guests.*
4488     FROM cd me
4489     JOIN artist artist
4490       ON artist.artistid = me.artistid
4491     JOIN record_label record_label
4492       ON record_label.labelid = artist.labelid
4493     LEFT JOIN track tracks
4494       ON tracks.cdid = me.cdid
4495     LEFT JOIN guest guests
4496       ON guests.trackid = track.trackid
4497     LEFT JOIN liner_notes liner_note
4498       ON liner_note.cdid = me.cdid
4499     JOIN cd_artwork cover_image
4500       ON cover_image.cdid = me.cdid
4501   ORDER BY tracks.cd
4502
4503 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4504 C<tracks>, and C<guests> of the CD will all be available through the
4505 relationship accessors without the need for additional queries to the
4506 database.
4507
4508 =head3 CAVEATS
4509
4510 Prefetch does a lot of deep magic. As such, it may not behave exactly
4511 as you might expect.
4512
4513 =over 4
4514
4515 =item *
4516
4517 Prefetch uses the L</cache> to populate the prefetched relationships. This
4518 may or may not be what you want.
4519
4520 =item *
4521
4522 If you specify a condition on a prefetched relationship, ONLY those
4523 rows that match the prefetched condition will be fetched into that relationship.
4524 This means that adding prefetch to a search() B<may alter> what is returned by
4525 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4526
4527   my $artist_rs = $schema->resultset('Artist')->search({
4528       'cds.year' => 2008,
4529   }, {
4530       join => 'cds',
4531   });
4532
4533   my $count = $artist_rs->first->cds->count;
4534
4535   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4536
4537   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4538
4539   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4540
4541 That cmp_ok() may or may not pass depending on the datasets involved. In other
4542 words the C<WHERE> condition would apply to the entire dataset, just like
4543 it would in regular SQL. If you want to add a condition only to the "right side"
4544 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4545 condition|DBIx::Class::Relationship::Base/condition>
4546
4547 =back
4548
4549 =head1 DBIC BIND VALUES
4550
4551 Because DBIC may need more information to bind values than just the column name
4552 and value itself, it uses a special format for both passing and receiving bind
4553 values.  Each bind value should be composed of an arrayref of
4554 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4555
4556 =over 4
4557
4558 =item dbd_attrs
4559
4560 If present (in any form), this is what is being passed directly to bind_param.
4561 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4562 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4563
4564 If this is specified, all other bind options described below are ignored.
4565
4566 =item sqlt_datatype
4567
4568 If present, this is used to infer the actual bind attribute by passing to
4569 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4570 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4571
4572 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4573 currently drivers are expected to "Do the Right Thing" when given a common
4574 datatype name.  (Not ideal, but that's what we got at this point.)
4575
4576 =item sqlt_size
4577
4578 Currently used to correctly allocate buffers for bind_param_inout().
4579 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4580 or to a sensible value based on the "data_type".
4581
4582 =item dbic_colname
4583
4584 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4585 explicitly specified they are never overriden).  Also used by some weird DBDs,
4586 where the column name should be available at bind_param time (e.g. Oracle).
4587
4588 =back
4589
4590 For backwards compatibility and convenience, the following shortcuts are
4591 supported:
4592
4593   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4594   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4595   [ undef,   $val ] === [ {}, $val ]
4596
4597 =head1 AUTHOR AND CONTRIBUTORS
4598
4599 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4600
4601 =head1 LICENSE
4602
4603 You may distribute this code under the same terms as Perl itself.
4604