lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 195
 196 =item Return Value: L<$resultset|/search>
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you never construct a resultset manually. Instead you get one
 206 from e.g. a
 207 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 208 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 209 scalar context):
 210
 211   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 212
 213 =over
 214
 215 =item WARNING
 216
 217 If called on an object, proxies to L</new_result> instead, so
 218
 219   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 220
 221 will return a CD object, not a ResultSet, and is equivalent to:
 222
 223   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 224
 225 Please also keep in mind that many internals call L</new_result> directly,
 226 so overloading this method with the idea of intercepting new result object
 227 creation B<will not work>. See also warning pertaining to L</create>.
 228
 229 =back
 230
 231 =cut
 232
 233 sub new {
 234   my $class = shift;
 235   return $class->new_result(@_) if ref $class;
 236
 237   my ($source, $attrs) = @_;
 238   $source = $source->resolve
 239     if $source->isa('DBIx::Class::ResultSourceHandle');
 240   $attrs = { %{$attrs||{}} };
 241
 242   if ($attrs->{page}) {
 243     $attrs->{rows} ||= 10;
 244   }
 245
 246   $attrs->{alias} ||= 'me';
 247
 248   my $self = bless {
 249     result_source => $source,
 250     cond => $attrs->{where},
 251     pager => undef,
 252     attrs => $attrs,
 253   }, $class;
 254
 255   # if there is a dark selector, this means we are already in a
 256   # chain and the cleanup/sanification was taken care of by
 257   # _search_rs already
 258   $self->_normalize_selection($attrs)
 259     unless $attrs->{_dark_selector};
 260
 261   $self->result_class(
 262     $attrs->{result_class} || $source->result_class
 263   );
 264
 265   $self;
 266 }
 267
 268 =head2 search
 269
 270 =over 4
 271
 272 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 273
 274 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 275
 276 =back
 277
 278   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 279   my $new_rs = $cd_rs->search({ year => 2005 });
 280
 281   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 282                  # year = 2005 OR year = 2004
 283
 284 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 285 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 286 To avoid that, use L</search_rs>.
 287
 288 If you need to pass in additional attributes but no additional condition,
 289 call it as C<search(undef, \%attrs)>.
 290
 291   # "SELECT name, artistid FROM $artist_table"
 292   my @all_artists = $schema->resultset('Artist')->search(undef, {
 293     columns => [qw/name artistid/],
 294   });
 295
 296 For a list of attributes that can be passed to C<search>, see
 297 L</ATTRIBUTES>. For more examples of using this function, see
 298 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 299 documentation for the first argument, see L<SQL::Abstract>
 300 and its extension L<DBIx::Class::SQLMaker>.
 301
 302 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 303
 304 =head3 CAVEAT
 305
 306 Note that L</search> does not process/deflate any of the values passed in the
 307 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 308 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 309 manually that any value passed to this method will stringify to something the
 310 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 311 objects, for more info see:
 312 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 313
 314 =cut
 315
 316 sub search {
 317   my $self = shift;
 318   my $rs = $self->search_rs( @_ );
 319
 320   if (wantarray) {
 321     return $rs->all;
 322   }
 323   elsif (defined wantarray) {
 324     return $rs;
 325   }
 326   else {
 327     # we can be called by a relationship helper, which in
 328     # turn may be called in void context due to some braindead
 329     # overload or whatever else the user decided to be clever
 330     # at this particular day. Thus limit the exception to
 331     # external code calls only
 332     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 333       if (caller)[0] !~ /^\QDBIx::Class::/;
 334
 335     return ();
 336   }
 337 }
 338
 339 =head2 search_rs
 340
 341 =over 4
 342
 343 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 344
 345 =item Return Value: L<$resultset|/search>
 346
 347 =back
 348
 349 This method does the same exact thing as search() except it will
 350 always return a resultset, even in list context.
 351
 352 =cut
 353
 354 sub search_rs {
 355   my $self = shift;
 356
 357   my $rsrc = $self->result_source;
 358   my ($call_cond, $call_attrs);
 359
 360   # Special-case handling for (undef, undef) or (undef)
 361   # Note that (foo => undef) is valid deprecated syntax
 362   @_ = () if not scalar grep { defined $_ } @_;
 363
 364   # just a cond
 365   if (@_ == 1) {
 366     $call_cond = shift;
 367   }
 368   # fish out attrs in the ($condref, $attr) case
 369   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 370     ($call_cond, $call_attrs) = @_;
 371   }
 372   elsif (@_ % 2) {
 373     $self->throw_exception('Odd number of arguments to search')
 374   }
 375   # legacy search
 376   elsif (@_) {
 377     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 378       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 379
 380     for my $i (0 .. $#_) {
 381       next if $i % 2;
 382       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 383         if (! defined $_[$i] or ref $_[$i] ne '');
 384     }
 385
 386     $call_cond = { @_ };
 387   }
 388
 389   # see if we can keep the cache (no $rs changes)
 390   my $cache;
 391   my %safe = (alias => 1, cache => 1);
 392   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 393     ! defined $_[0]
 394       or
 395     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 396       or
 397     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 398   )) {
 399     $cache = $self->get_cache;
 400   }
 401
 402   my $old_attrs = { %{$self->{attrs}} };
 403   my $old_having = delete $old_attrs->{having};
 404   my $old_where = delete $old_attrs->{where};
 405
 406   my $new_attrs = { %$old_attrs };
 407
 408   # take care of call attrs (only if anything is changing)
 409   if ($call_attrs and keys %$call_attrs) {
 410
 411     # copy for _normalize_selection
 412     $call_attrs = { %$call_attrs };
 413
 414     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 415
 416     # reset the current selector list if new selectors are supplied
 417     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 418       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 419     }
 420
 421     # Normalize the new selector list (operates on the passed-in attr structure)
 422     # Need to do it on every chain instead of only once on _resolved_attrs, in
 423     # order to allow detection of empty vs partial 'as'
 424     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 425       if $old_attrs->{_dark_selector};
 426     $self->_normalize_selection ($call_attrs);
 427
 428     # start with blind overwriting merge, exclude selector attrs
 429     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 430     delete @{$new_attrs}{@selector_attrs};
 431
 432     for (@selector_attrs) {
 433       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 434         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 435     }
 436
 437     # older deprecated name, use only if {columns} is not there
 438     if (my $c = delete $new_attrs->{cols}) {
 439       if ($new_attrs->{columns}) {
 440         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 441       }
 442       else {
 443         $new_attrs->{columns} = $c;
 444       }
 445     }
 446
 447
 448     # join/prefetch use their own crazy merging heuristics
 449     foreach my $key (qw/join prefetch/) {
 450       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 451         if exists $call_attrs->{$key};
 452     }
 453
 454     # stack binds together
 455     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 456   }
 457
 458
 459   for ($old_where, $call_cond) {
 460     if (defined $_) {
 461       $new_attrs->{where} = $self->_stack_cond (
 462         $_, $new_attrs->{where}
 463       );
 464     }
 465   }
 466
 467   if (defined $old_having) {
 468     $new_attrs->{having} = $self->_stack_cond (
 469       $old_having, $new_attrs->{having}
 470     )
 471   }
 472
 473   my $rs = (ref $self)->new($rsrc, $new_attrs);
 474
 475   $rs->set_cache($cache) if ($cache);
 476
 477   return $rs;
 478 }
 479
 480 my $dark_sel_dumper;
 481 sub _normalize_selection {
 482   my ($self, $attrs) = @_;
 483
 484   # legacy syntax
 485   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 486     if exists $attrs->{include_columns};
 487
 488   # columns are always placed first, however
 489
 490   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 491   # delay the decision on whether to use a default select list ($rsrc->columns)
 492   # allowing stuff like the remove_columns helper to work
 493   #
 494   # select/as +select/+as pairs need special handling - the amount of select/as
 495   # elements in each pair does *not* have to be equal (think multicolumn
 496   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 497   # supplied at all) - try to infer the alias, either from the -as parameter
 498   # of the selector spec, or use the parameter whole if it looks like a column
 499   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 500   # is ok as well), but make sure no more additions to the 'as' chain take place
 501   for my $pref ('', '+') {
 502
 503     my ($sel, $as) = map {
 504       my $key = "${pref}${_}";
 505
 506       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 507         ? @{$attrs->{$key}}
 508         : $attrs->{$key} || ()
 509       ];
 510       delete $attrs->{$key};
 511       $val;
 512     } qw/select as/;
 513
 514     if (! @$as and ! @$sel ) {
 515       next;
 516     }
 517     elsif (@$as and ! @$sel) {
 518       $self->throw_exception(
 519         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 520       );
 521     }
 522     elsif( ! @$as ) {
 523       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 524       # if any @$as has been supplied we assume the user knows what (s)he is doing
 525       # and blindly keep stacking up pieces
 526       unless ($attrs->{_dark_selector}) {
 527         SELECTOR:
 528         for (@$sel) {
 529           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 530             push @$as, $_->{-as};
 531           }
 532           # assume any plain no-space, no-parenthesis string to be a column spec
 533           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 534           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 535             push @$as, $_;
 536           }
 537           # if all else fails - raise a flag that no more aliasing will be allowed
 538           else {
 539             $attrs->{_dark_selector} = {
 540               plus_stage => $pref,
 541               string => ($dark_sel_dumper ||= do {
 542                   require Data::Dumper::Concise;
 543                   Data::Dumper::Concise::DumperObject()->Indent(0);
 544                 })->Values([$_])->Dump
 545               ,
 546             };
 547             last SELECTOR;
 548           }
 549         }
 550       }
 551     }
 552     elsif (@$as < @$sel) {
 553       $self->throw_exception(
 554         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 555       );
 556     }
 557     elsif ($pref and $attrs->{_dark_selector}) {
 558       $self->throw_exception(
 559         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 560       );
 561     }
 562
 563
 564     # merge result
 565     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 566     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 567   }
 568 }
 569
 570 sub _stack_cond {
 571   my ($self, $left, $right) = @_;
 572
 573   # collapse single element top-level conditions
 574   # (single pass only, unlikely to need recursion)
 575   for ($left, $right) {
 576     if (ref $_ eq 'ARRAY') {
 577       if (@$_ == 0) {
 578         $_ = undef;
 579       }
 580       elsif (@$_ == 1) {
 581         $_ = $_->[0];
 582       }
 583     }
 584     elsif (ref $_ eq 'HASH') {
 585       my ($first, $more) = keys %$_;
 586
 587       # empty hash
 588       if (! defined $first) {
 589         $_ = undef;
 590       }
 591       # one element hash
 592       elsif (! defined $more) {
 593         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 594           $_ = $_->{'-and'};
 595         }
 596         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 597           $_ = $_->{'-or'};
 598         }
 599       }
 600     }
 601   }
 602
 603   # merge hashes with weeding out of duplicates (simple cases only)
 604   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 605
 606     # shallow copy to destroy
 607     $right = { %$right };
 608     for (grep { exists $right->{$_} } keys %$left) {
 609       # the use of eq_deeply here is justified - the rhs of an
 610       # expression can contain a lot of twisted weird stuff
 611       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 612     }
 613
 614     $right = undef unless keys %$right;
 615   }
 616
 617
 618   if (defined $left xor defined $right) {
 619     return defined $left ? $left : $right;
 620   }
 621   elsif (! defined $left) {
 622     return undef;
 623   }
 624   else {
 625     return { -and => [ $left, $right ] };
 626   }
 627 }
 628
 629 =head2 search_literal
 630
 631 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 632 should only be used in that context. C<search_literal> is a convenience
 633 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 634 want to ensure columns are bound correctly, use L</search>.
 635
 636 See L<DBIx::Class::Manual::Cookbook/Searching> and
 637 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 638 require C<search_literal>.
 639
 640 =over 4
 641
 642 =item Arguments: $sql_fragment, @standalone_bind_values
 643
 644 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 645
 646 =back
 647
 648   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 649   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 650
 651 Pass a literal chunk of SQL to be added to the conditional part of the
 652 resultset query.
 653
 654 Example of how to use C<search> instead of C<search_literal>
 655
 656   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 657   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 658
 659 =cut
 660
 661 sub search_literal {
 662   my ($self, $sql, @bind) = @_;
 663   my $attr;
 664   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 665     $attr = pop @bind;
 666   }
 667   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 668 }
 669
 670 =head2 find
 671
 672 =over 4
 673
 674 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 675
 676 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 677
 678 =back
 679
 680 Finds and returns a single row based on supplied criteria. Takes either a
 681 hashref with the same format as L</create> (including inference of foreign
 682 keys from related objects), or a list of primary key values in the same
 683 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 684 declaration on the L</result_source>.
 685
 686 In either case an attempt is made to combine conditions already existing on
 687 the resultset with the condition passed to this method.
 688
 689 To aid with preparing the correct query for the storage you may supply the
 690 C<key> attribute, which is the name of a
 691 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 692 unique constraint corresponding to the
 693 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 694 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 695 to construct a query that satisfies the named unique constraint fully (
 696 non-NULL values for each column member of the constraint) an exception is
 697 thrown.
 698
 699 If no C<key> is specified, the search is carried over all unique constraints
 700 which are fully defined by the available condition.
 701
 702 If no such constraint is found, C<find> currently defaults to a simple
 703 C<< search->(\%column_values) >> which may or may not do what you expect.
 704 Note that this fallback behavior may be deprecated in further versions. If
 705 you need to search with arbitrary conditions - use L</search>. If the query
 706 resulting from this fallback produces more than one row, a warning to the
 707 effect is issued, though only the first row is constructed and returned as
 708 C<$result_object>.
 709
 710 In addition to C<key>, L</find> recognizes and applies standard
 711 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 712
 713 Note that if you have extra concerns about the correctness of the resulting
 714 query you need to specify the C<key> attribute and supply the entire condition
 715 as an argument to find (since it is not always possible to perform the
 716 combination of the resultset condition with the supplied one, especially if
 717 the resultset condition contains literal sql).
 718
 719 For example, to find a row by its primary key:
 720
 721   my $cd = $schema->resultset('CD')->find(5);
 722
 723 You can also find a row by a specific unique constraint:
 724
 725   my $cd = $schema->resultset('CD')->find(
 726     {
 727       artist => 'Massive Attack',
 728       title  => 'Mezzanine',
 729     },
 730     { key => 'cd_artist_title' }
 731   );
 732
 733 See also L</find_or_create> and L</update_or_create>.
 734
 735 =cut
 736
 737 sub find {
 738   my $self = shift;
 739   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 740
 741   my $rsrc = $self->result_source;
 742
 743   my $constraint_name;
 744   if (exists $attrs->{key}) {
 745     $constraint_name = defined $attrs->{key}
 746       ? $attrs->{key}
 747       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 748     ;
 749   }
 750
 751   # Parse out the condition from input
 752   my $call_cond;
 753
 754   if (ref $_[0] eq 'HASH') {
 755     $call_cond = { %{$_[0]} };
 756   }
 757   else {
 758     # if only values are supplied we need to default to 'primary'
 759     $constraint_name = 'primary' unless defined $constraint_name;
 760
 761     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 762
 763     $self->throw_exception(
 764       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 765     ) unless @c_cols;
 766
 767     $self->throw_exception (
 768       'find() expects either a column/value hashref, or a list of values '
 769     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 770     ) unless @c_cols == @_;
 771
 772     $call_cond = {};
 773     @{$call_cond}{@c_cols} = @_;
 774   }
 775
 776   my %related;
 777   for my $key (keys %$call_cond) {
 778     if (
 779       my $keyref = ref($call_cond->{$key})
 780         and
 781       my $relinfo = $rsrc->relationship_info($key)
 782     ) {
 783       my $val = delete $call_cond->{$key};
 784
 785       next if $keyref eq 'ARRAY'; # has_many for multi_create
 786
 787       my $rel_q = $rsrc->_resolve_condition(
 788         $relinfo->{cond}, $val, $key, $key
 789       );
 790       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 791       @related{keys %$rel_q} = values %$rel_q;
 792     }
 793   }
 794
 795   # relationship conditions take precedence (?)
 796   @{$call_cond}{keys %related} = values %related;
 797
 798   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 799   my $final_cond;
 800   if (defined $constraint_name) {
 801     $final_cond = $self->_qualify_cond_columns (
 802
 803       $self->_build_unique_cond (
 804         $constraint_name,
 805         $call_cond,
 806       ),
 807
 808       $alias,
 809     );
 810   }
 811   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 812     # This means that we got here after a merger of relationship conditions
 813     # in ::Relationship::Base::search_related (the row method), and furthermore
 814     # the relationship is of the 'single' type. This means that the condition
 815     # provided by the relationship (already attached to $self) is sufficient,
 816     # as there can be only one row in the database that would satisfy the
 817     # relationship
 818   }
 819   else {
 820     # no key was specified - fall down to heuristics mode:
 821     # run through all unique queries registered on the resultset, and
 822     # 'OR' all qualifying queries together
 823     my (@unique_queries, %seen_column_combinations);
 824     for my $c_name ($rsrc->unique_constraint_names) {
 825       next if $seen_column_combinations{
 826         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 827       }++;
 828
 829       push @unique_queries, try {
 830         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 831       } || ();
 832     }
 833
 834     $final_cond = @unique_queries
 835       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 836       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 837     ;
 838   }
 839
 840   # Run the query, passing the result_class since it should propagate for find
 841   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 842   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 843     my $row = $rs->next;
 844     carp "Query returned more than one row" if $rs->next;
 845     return $row;
 846   }
 847   else {
 848     return $rs->single;
 849   }
 850 }
 851
 852 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 853 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 854 #
 855 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 856 # condition. It is provided for overrides until a saner way forward is devised
 857 #
 858 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 859 # the road. Please adjust your tests accordingly to catch this situation early
 860 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 861 #
 862 # The method will not be removed without an adequately complete replacement
 863 # for strict-mode enforcement
 864 sub _non_unique_find_fallback {
 865   my ($self, $cond, $attrs) = @_;
 866
 867   return $self->_qualify_cond_columns(
 868     $cond,
 869     exists $attrs->{alias}
 870       ? $attrs->{alias}
 871       : $self->{attrs}{alias}
 872   );
 873 }
 874
 875
 876 sub _qualify_cond_columns {
 877   my ($self, $cond, $alias) = @_;
 878
 879   my %aliased = %$cond;
 880   for (keys %aliased) {
 881     $aliased{"$alias.$_"} = delete $aliased{$_}
 882       if $_ !~ /\./;
 883   }
 884
 885   return \%aliased;
 886 }
 887
 888 sub _build_unique_cond {
 889   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 890
 891   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 892
 893   # combination may fail if $self->{cond} is non-trivial
 894   my ($final_cond) = try {
 895     $self->_merge_with_rscond ($extra_cond)
 896   } catch {
 897     +{ %$extra_cond }
 898   };
 899
 900   # trim out everything not in $columns
 901   $final_cond = { map {
 902     exists $final_cond->{$_}
 903       ? ( $_ => $final_cond->{$_} )
 904       : ()
 905   } @c_cols };
 906
 907   if (my @missing = grep
 908     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 909     (@c_cols)
 910   ) {
 911     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 912       $constraint_name,
 913       join (', ', map { "'$_'" } @missing),
 914     ) );
 915   }
 916
 917   if (
 918     !$croak_on_null
 919       and
 920     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 921       and
 922     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 923   ) {
 924     carp_unique ( sprintf (
 925       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 926     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 927     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 928       $constraint_name,
 929       join (', ', map { "'$_'" } @undefs),
 930     ));
 931   }
 932
 933   return $final_cond;
 934 }
 935
 936 =head2 search_related
 937
 938 =over 4
 939
 940 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 941
 942 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 943
 944 =back
 945
 946   $new_rs = $cd_rs->search_related('artist', {
 947     name => 'Emo-R-Us',
 948   });
 949
 950 Searches the specified relationship, optionally specifying a condition and
 951 attributes for matching records. See L</ATTRIBUTES> for more information.
 952
 953 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 954 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 955
 956 See also L</search_related_rs>.
 957
 958 =cut
 959
 960 sub search_related {
 961   return shift->related_resultset(shift)->search(@_);
 962 }
 963
 964 =head2 search_related_rs
 965
 966 This method works exactly the same as search_related, except that
 967 it guarantees a resultset, even in list context.
 968
 969 =cut
 970
 971 sub search_related_rs {
 972   return shift->related_resultset(shift)->search_rs(@_);
 973 }
 974
 975 =head2 cursor
 976
 977 =over 4
 978
 979 =item Arguments: none
 980
 981 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 982
 983 =back
 984
 985 Returns a storage-driven cursor to the given resultset. See
 986 L<DBIx::Class::Cursor> for more information.
 987
 988 =cut
 989
 990 sub cursor {
 991   my ($self) = @_;
 992
 993   my $attrs = $self->_resolved_attrs_copy;
 994
 995   return $self->{cursor}
 996     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 997           $attrs->{where},$attrs);
 998 }
 999
1000 =head2 single
1001
1002 =over 4
1003
1004 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1005
1006 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1007
1008 =back
1009
1010   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1011
1012 Inflates the first result without creating a cursor if the resultset has
1013 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1014 of L</search>.
1015
1016 While this method can take an optional search condition (just like L</search>)
1017 being a fast-code-path it does not recognize search attributes. If you need to
1018 add extra joins or similar, call L</search> and then chain-call L</single> on the
1019 L<DBIx::Class::ResultSet> returned.
1020
1021 =over
1022
1023 =item B<Note>
1024
1025 As of 0.08100, this method enforces the assumption that the preceding
1026 query returns only one row. If more than one row is returned, you will receive
1027 a warning:
1028
1029   Query returned more than one row
1030
1031 In this case, you should be using L</next> or L</find> instead, or if you really
1032 know what you are doing, use the L</rows> attribute to explicitly limit the size
1033 of the resultset.
1034
1035 This method will also throw an exception if it is called on a resultset prefetching
1036 has_many, as such a prefetch implies fetching multiple rows from the database in
1037 order to assemble the resulting object.
1038
1039 =back
1040
1041 =cut
1042
1043 sub single {
1044   my ($self, $where) = @_;
1045   if(@_ > 2) {
1046       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1047   }
1048
1049   my $attrs = $self->_resolved_attrs_copy;
1050
1051   if (keys %{$attrs->{collapse}}) {
1052     $self->throw_exception(
1053       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1054     );
1055   }
1056
1057   if ($where) {
1058     if (defined $attrs->{where}) {
1059       $attrs->{where} = {
1060         '-and' =>
1061             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1062                $where, delete $attrs->{where} ]
1063       };
1064     } else {
1065       $attrs->{where} = $where;
1066     }
1067   }
1068
1069   my @data = $self->result_source->storage->select_single(
1070     $attrs->{from}, $attrs->{select},
1071     $attrs->{where}, $attrs
1072   );
1073
1074   return (@data ? ($self->_construct_object(@data))[0] : undef);
1075 }
1076
1077
1078 # _collapse_query
1079 #
1080 # Recursively collapse the query, accumulating values for each column.
1081
1082 sub _collapse_query {
1083   my ($self, $query, $collapsed) = @_;
1084
1085   $collapsed ||= {};
1086
1087   if (ref $query eq 'ARRAY') {
1088     foreach my $subquery (@$query) {
1089       next unless ref $subquery;  # -or
1090       $collapsed = $self->_collapse_query($subquery, $collapsed);
1091     }
1092   }
1093   elsif (ref $query eq 'HASH') {
1094     if (keys %$query and (keys %$query)[0] eq '-and') {
1095       foreach my $subquery (@{$query->{-and}}) {
1096         $collapsed = $self->_collapse_query($subquery, $collapsed);
1097       }
1098     }
1099     else {
1100       foreach my $col (keys %$query) {
1101         my $value = $query->{$col};
1102         $collapsed->{$col}{$value}++;
1103       }
1104     }
1105   }
1106
1107   return $collapsed;
1108 }
1109
1110 =head2 get_column
1111
1112 =over 4
1113
1114 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1115
1116 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1117
1118 =back
1119
1120   my $max_length = $rs->get_column('length')->max;
1121
1122 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1123
1124 =cut
1125
1126 sub get_column {
1127   my ($self, $column) = @_;
1128   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1129   return $new;
1130 }
1131
1132 =head2 search_like
1133
1134 =over 4
1135
1136 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1137
1138 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1139
1140 =back
1141
1142   # WHERE title LIKE '%blue%'
1143   $cd_rs = $rs->search_like({ title => '%blue%'});
1144
1145 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1146 that this is simply a convenience method retained for ex Class::DBI users.
1147 You most likely want to use L</search> with specific operators.
1148
1149 For more information, see L<DBIx::Class::Manual::Cookbook>.
1150
1151 This method is deprecated and will be removed in 0.09. Use L</search()>
1152 instead. An example conversion is:
1153
1154   ->search_like({ foo => 'bar' });
1155
1156   # Becomes
1157
1158   ->search({ foo => { like => 'bar' } });
1159
1160 =cut
1161
1162 sub search_like {
1163   my $class = shift;
1164   carp_unique (
1165     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1166    .' Instead use ->search({ x => { -like => "y%" } })'
1167    .' (note the outer pair of {}s - they are important!)'
1168   );
1169   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1170   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1171   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1172   return $class->search($query, { %$attrs });
1173 }
1174
1175 =head2 slice
1176
1177 =over 4
1178
1179 =item Arguments: $first, $last
1180
1181 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1182
1183 =back
1184
1185 Returns a resultset or object list representing a subset of elements from the
1186 resultset slice is called on. Indexes are from 0, i.e., to get the first
1187 three records, call:
1188
1189   my ($one, $two, $three) = $rs->slice(0, 2);
1190
1191 =cut
1192
1193 sub slice {
1194   my ($self, $min, $max) = @_;
1195   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1196   $attrs->{offset} = $self->{attrs}{offset} || 0;
1197   $attrs->{offset} += $min;
1198   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1199   return $self->search(undef, $attrs);
1200   #my $slice = (ref $self)->new($self->result_source, $attrs);
1201   #return (wantarray ? $slice->all : $slice);
1202 }
1203
1204 =head2 next
1205
1206 =over 4
1207
1208 =item Arguments: none
1209
1210 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1211
1212 =back
1213
1214 Returns the next element in the resultset (C<undef> is there is none).
1215
1216 Can be used to efficiently iterate over records in the resultset:
1217
1218   my $rs = $schema->resultset('CD')->search;
1219   while (my $cd = $rs->next) {
1220     print $cd->title;
1221   }
1222
1223 Note that you need to store the resultset object, and call C<next> on it.
1224 Calling C<< resultset('Table')->next >> repeatedly will always return the
1225 first record from the resultset.
1226
1227 =cut
1228
1229 sub next {
1230   my ($self) = @_;
1231   if (my $cache = $self->get_cache) {
1232     $self->{all_cache_position} ||= 0;
1233     return $cache->[$self->{all_cache_position}++];
1234   }
1235   if ($self->{attrs}{cache}) {
1236     delete $self->{pager};
1237     $self->{all_cache_position} = 1;
1238     return ($self->all)[0];
1239   }
1240   if ($self->{stashed_objects}) {
1241     my $obj = shift(@{$self->{stashed_objects}});
1242     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1243     return $obj;
1244   }
1245   my @row = (
1246     exists $self->{stashed_row}
1247       ? @{delete $self->{stashed_row}}
1248       : $self->cursor->next
1249   );
1250   return undef unless (@row);
1251   my ($row, @more) = $self->_construct_object(@row);
1252   $self->{stashed_objects} = \@more if @more;
1253   return $row;
1254 }
1255
1256 sub _construct_object {
1257   my ($self, @row) = @_;
1258
1259   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1260     or return ();
1261   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1262   @new = $self->{_attrs}{record_filter}->(@new)
1263     if exists $self->{_attrs}{record_filter};
1264   return @new;
1265 }
1266
1267 sub _collapse_result {
1268   my ($self, $as_proto, $row) = @_;
1269
1270   my @copy = @$row;
1271
1272   # 'foo'         => [ undef, 'foo' ]
1273   # 'foo.bar'     => [ 'foo', 'bar' ]
1274   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1275
1276   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1277
1278   my %collapse = %{$self->{_attrs}{collapse}||{}};
1279
1280   my @pri_index;
1281
1282   # if we're doing collapsing (has_many prefetch) we need to grab records
1283   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1284   # we know we don't have to bother.
1285
1286   # the reason for not using the collapse stuff directly is because if you
1287   # had for e.g. two artists in a row with no cds, the collapse info for
1288   # both would be NULL (undef) so you'd lose the second artist
1289
1290   # store just the index so we can check the array positions from the row
1291   # without having to contruct the full hash
1292
1293   if (keys %collapse) {
1294     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1295     foreach my $i (0 .. $#construct_as) {
1296       next if defined($construct_as[$i][0]); # only self table
1297       if (delete $pri{$construct_as[$i][1]}) {
1298         push(@pri_index, $i);
1299       }
1300       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1301     }
1302   }
1303
1304   # no need to do an if, it'll be empty if @pri_index is empty anyway
1305
1306   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1307
1308   my @const_rows;
1309
1310   do { # no need to check anything at the front, we always want the first row
1311
1312     my %const;
1313
1314     foreach my $this_as (@construct_as) {
1315       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1316     }
1317
1318     push(@const_rows, \%const);
1319
1320   } until ( # no pri_index => no collapse => drop straight out
1321       !@pri_index
1322     or
1323       do { # get another row, stash it, drop out if different PK
1324
1325         @copy = $self->cursor->next;
1326         $self->{stashed_row} = \@copy;
1327
1328         # last thing in do block, counts as true if anything doesn't match
1329
1330         # check xor defined first for NULL vs. NOT NULL then if one is
1331         # defined the other must be so check string equality
1332
1333         grep {
1334           (defined $pri_vals{$_} ^ defined $copy[$_])
1335           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1336         } @pri_index;
1337       }
1338   );
1339
1340   my $alias = $self->{attrs}{alias};
1341   my $info = [];
1342
1343   my %collapse_pos;
1344
1345   my @const_keys;
1346
1347   foreach my $const (@const_rows) {
1348     scalar @const_keys or do {
1349       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1350     };
1351     foreach my $key (@const_keys) {
1352       if (length $key) {
1353         my $target = $info;
1354         my @parts = split(/\./, $key);
1355         my $cur = '';
1356         my $data = $const->{$key};
1357         foreach my $p (@parts) {
1358           $target = $target->[1]->{$p} ||= [];
1359           $cur .= ".${p}";
1360           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1361             # collapsing at this point and on final part
1362             my $pos = $collapse_pos{$cur};
1363             CK: foreach my $ck (@ckey) {
1364               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1365                 $collapse_pos{$cur} = $data;
1366                 delete @collapse_pos{ # clear all positioning for sub-entries
1367                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1368                 };
1369                 push(@$target, []);
1370                 last CK;
1371               }
1372             }
1373           }
1374           if (exists $collapse{$cur}) {
1375             $target = $target->[-1];
1376           }
1377         }
1378         $target->[0] = $data;
1379       } else {
1380         $info->[0] = $const->{$key};
1381       }
1382     }
1383   }
1384
1385   return $info;
1386 }
1387
1388 =head2 result_source
1389
1390 =over 4
1391
1392 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1393
1394 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1395
1396 =back
1397
1398 An accessor for the primary ResultSource object from which this ResultSet
1399 is derived.
1400
1401 =head2 result_class
1402
1403 =over 4
1404
1405 =item Arguments: $result_class?
1406
1407 =item Return Value: $result_class
1408
1409 =back
1410
1411 An accessor for the class to use when creating result objects. Defaults to
1412 C<< result_source->result_class >> - which in most cases is the name of the
1413 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1414
1415 Note that changing the result_class will also remove any components
1416 that were originally loaded in the source class via
1417 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1418 in the original source class will not run.
1419
1420 =cut
1421
1422 sub result_class {
1423   my ($self, $result_class) = @_;
1424   if ($result_class) {
1425     unless (ref $result_class) { # don't fire this for an object
1426       $self->ensure_class_loaded($result_class);
1427     }
1428     $self->_result_class($result_class);
1429     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1430     # permit the user to set result class on one result set only; it only
1431     # chains if provided to search()
1432     #$self->{attrs}{result_class} = $result_class if ref $self;
1433   }
1434   $self->_result_class;
1435 }
1436
1437 =head2 count
1438
1439 =over 4
1440
1441 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1442
1443 =item Return Value: $count
1444
1445 =back
1446
1447 Performs an SQL C<COUNT> with the same query as the resultset was built
1448 with to find the number of elements. Passing arguments is equivalent to
1449 C<< $rs->search ($cond, \%attrs)->count >>
1450
1451 =cut
1452
1453 sub count {
1454   my $self = shift;
1455   return $self->search(@_)->count if @_ and defined $_[0];
1456   return scalar @{ $self->get_cache } if $self->get_cache;
1457
1458   my $attrs = $self->_resolved_attrs_copy;
1459
1460   # this is a little optimization - it is faster to do the limit
1461   # adjustments in software, instead of a subquery
1462   my $rows = delete $attrs->{rows};
1463   my $offset = delete $attrs->{offset};
1464
1465   my $crs;
1466   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1467     $crs = $self->_count_subq_rs ($attrs);
1468   }
1469   else {
1470     $crs = $self->_count_rs ($attrs);
1471   }
1472   my $count = $crs->next;
1473
1474   $count -= $offset if $offset;
1475   $count = $rows if $rows and $rows < $count;
1476   $count = 0 if ($count < 0);
1477
1478   return $count;
1479 }
1480
1481 =head2 count_rs
1482
1483 =over 4
1484
1485 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1486
1487 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1488
1489 =back
1490
1491 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1492 This can be very handy for subqueries:
1493
1494   ->search( { amount => $some_rs->count_rs->as_query } )
1495
1496 As with regular resultsets the SQL query will be executed only after
1497 the resultset is accessed via L</next> or L</all>. That would return
1498 the same single value obtainable via L</count>.
1499
1500 =cut
1501
1502 sub count_rs {
1503   my $self = shift;
1504   return $self->search(@_)->count_rs if @_;
1505
1506   # this may look like a lack of abstraction (count() does about the same)
1507   # but in fact an _rs *must* use a subquery for the limits, as the
1508   # software based limiting can not be ported if this $rs is to be used
1509   # in a subquery itself (i.e. ->as_query)
1510   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1511     return $self->_count_subq_rs;
1512   }
1513   else {
1514     return $self->_count_rs;
1515   }
1516 }
1517
1518 #
1519 # returns a ResultSetColumn object tied to the count query
1520 #
1521 sub _count_rs {
1522   my ($self, $attrs) = @_;
1523
1524   my $rsrc = $self->result_source;
1525   $attrs ||= $self->_resolved_attrs;
1526
1527   my $tmp_attrs = { %$attrs };
1528   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1529   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1530
1531   # overwrite the selector (supplied by the storage)
1532   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1533   $tmp_attrs->{as} = 'count';
1534   delete @{$tmp_attrs}{qw/columns/};
1535
1536   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1537
1538   return $tmp_rs;
1539 }
1540
1541 #
1542 # same as above but uses a subquery
1543 #
1544 sub _count_subq_rs {
1545   my ($self, $attrs) = @_;
1546
1547   my $rsrc = $self->result_source;
1548   $attrs ||= $self->_resolved_attrs;
1549
1550   my $sub_attrs = { %$attrs };
1551   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1552   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1553
1554   # if we multi-prefetch we group_by something unique, as this is what we would
1555   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1556   if ( keys %{$attrs->{collapse}}  ) {
1557     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1558       $rsrc->_identifying_column_set || $self->throw_exception(
1559         'Unable to construct a unique group_by criteria properly collapsing the '
1560       . 'has_many prefetch before count()'
1561       );
1562     } ]
1563   }
1564
1565   # Calculate subquery selector
1566   if (my $g = $sub_attrs->{group_by}) {
1567
1568     my $sql_maker = $rsrc->storage->sql_maker;
1569
1570     # necessary as the group_by may refer to aliased functions
1571     my $sel_index;
1572     for my $sel (@{$attrs->{select}}) {
1573       $sel_index->{$sel->{-as}} = $sel
1574         if (ref $sel eq 'HASH' and $sel->{-as});
1575     }
1576
1577     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1578     # also look for named aggregates referred in the having clause
1579     # having often contains scalarrefs - thus parse it out entirely
1580     my @parts = @$g;
1581     if ($attrs->{having}) {
1582       local $sql_maker->{having_bind};
1583       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1584       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1585       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1586         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1587         # if we don't unset it we screw up retarded but unfortunately working
1588         # 'MAX(foo.bar)' => { '>', 3 }
1589         $sql_maker->{name_sep} = '';
1590       }
1591
1592       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1593
1594       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1595
1596       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1597       # and if all fails for an utterly naive quoted scalar-with-function
1598       while ($sql =~ /
1599         $rquote $sep $lquote (.+?) $rquote
1600           |
1601         [\s,] \w+ \. (\w+) [\s,]
1602           |
1603         [\s,] $lquote (.+?) $rquote [\s,]
1604       /gx) {
1605         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1606       }
1607     }
1608
1609     for (@parts) {
1610       my $colpiece = $sel_index->{$_} || $_;
1611
1612       # unqualify join-based group_by's. Arcane but possible query
1613       # also horrible horrible hack to alias a column (not a func.)
1614       # (probably need to introduce SQLA syntax)
1615       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1616         my $as = $colpiece;
1617         $as =~ s/\./__/;
1618         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1619       }
1620       push @{$sub_attrs->{select}}, $colpiece;
1621     }
1622   }
1623   else {
1624     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1625     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1626   }
1627
1628   return $rsrc->resultset_class
1629                ->new ($rsrc, $sub_attrs)
1630                 ->as_subselect_rs
1631                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1632                   ->get_column ('count');
1633 }
1634
1635 sub _bool {
1636   return 1;
1637 }
1638
1639 =head2 count_literal
1640
1641 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1642 should only be used in that context. See L</search_literal> for further info.
1643
1644 =over 4
1645
1646 =item Arguments: $sql_fragment, @standalone_bind_values
1647
1648 =item Return Value: $count
1649
1650 =back
1651
1652 Counts the results in a literal query. Equivalent to calling L</search_literal>
1653 with the passed arguments, then L</count>.
1654
1655 =cut
1656
1657 sub count_literal { shift->search_literal(@_)->count; }
1658
1659 =head2 all
1660
1661 =over 4
1662
1663 =item Arguments: none
1664
1665 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1666
1667 =back
1668
1669 Returns all elements in the resultset.
1670
1671 =cut
1672
1673 sub all {
1674   my $self = shift;
1675   if(@_) {
1676       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1677   }
1678
1679   return @{ $self->get_cache } if $self->get_cache;
1680
1681   my @obj;
1682
1683   if (keys %{$self->_resolved_attrs->{collapse}}) {
1684     # Using $self->cursor->all is really just an optimisation.
1685     # If we're collapsing has_many prefetches it probably makes
1686     # very little difference, and this is cleaner than hacking
1687     # _construct_object to survive the approach
1688     $self->cursor->reset;
1689     my @row = $self->cursor->next;
1690     while (@row) {
1691       push(@obj, $self->_construct_object(@row));
1692       @row = (exists $self->{stashed_row}
1693                ? @{delete $self->{stashed_row}}
1694                : $self->cursor->next);
1695     }
1696   } else {
1697     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1698   }
1699
1700   $self->set_cache(\@obj) if $self->{attrs}{cache};
1701
1702   return @obj;
1703 }
1704
1705 =head2 reset
1706
1707 =over 4
1708
1709 =item Arguments: none
1710
1711 =item Return Value: $self
1712
1713 =back
1714
1715 Resets the resultset's cursor, so you can iterate through the elements again.
1716 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1717 another query.
1718
1719 =cut
1720
1721 sub reset {
1722   my ($self) = @_;
1723   $self->{all_cache_position} = 0;
1724   $self->cursor->reset;
1725   return $self;
1726 }
1727
1728 =head2 first
1729
1730 =over 4
1731
1732 =item Arguments: none
1733
1734 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1735
1736 =back
1737
1738 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1739 an object for the first result (or C<undef> if the resultset is empty).
1740
1741 =cut
1742
1743 sub first {
1744   return $_[0]->reset->next;
1745 }
1746
1747
1748 # _rs_update_delete
1749 #
1750 # Determines whether and what type of subquery is required for the $rs operation.
1751 # If grouping is necessary either supplies its own, or verifies the current one
1752 # After all is done delegates to the proper storage method.
1753
1754 sub _rs_update_delete {
1755   my ($self, $op, $values) = @_;
1756
1757   my $cond = $self->{cond};
1758   my $rsrc = $self->result_source;
1759   my $storage = $rsrc->schema->storage;
1760
1761   my $attrs = { %{$self->_resolved_attrs} };
1762
1763   my $existing_group_by = delete $attrs->{group_by};
1764   my $needs_subq = defined $existing_group_by;
1765
1766   # simplify the joinmap and maybe decide if a subquery is necessary
1767   my $relation_classifications = {};
1768
1769   if (ref($attrs->{from}) eq 'ARRAY') {
1770     # if we already know we need a subq, no point of classifying relations
1771     if (!$needs_subq and @{$attrs->{from}} > 1) {
1772       $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1773
1774       $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1775         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1776         $attrs->{select},
1777         $cond,
1778         $attrs
1779       );
1780     }
1781   }
1782   else {
1783     $needs_subq ||= 1; # if {from} is unparseable assume the worst
1784   }
1785
1786   # do we need anything like a subquery?
1787   if (
1788     ! $needs_subq
1789       and
1790     ! keys %{ $relation_classifications->{restricting} || {} }
1791       and
1792     ! $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1793   ) {
1794     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1795     # a condition containing 'me' or other table prefixes will not work
1796     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1797     my $cond = do {
1798       my $sqla = $rsrc->storage->sql_maker;
1799       local $sqla->{_dequalify_idents} = 1;
1800       \[ $sqla->_recurse_where($self->{cond}) ];
1801     };
1802     return $rsrc->storage->$op(
1803       $rsrc,
1804       $op eq 'update' ? $values : (),
1805       $cond,
1806     );
1807   }
1808
1809   # we got this far - means it is time to wrap a subquery
1810   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1811     sprintf(
1812       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1813       $op,
1814       $rsrc->source_name,
1815     )
1816   );
1817
1818   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1819   delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1820   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1821   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1822   my $subrs = (ref $self)->new($rsrc, $attrs);
1823
1824   if (@$idcols == 1) {
1825     return $storage->$op (
1826       $rsrc,
1827       $op eq 'update' ? $values : (),
1828       { $idcols->[0] => { -in => $subrs->as_query } },
1829     );
1830   }
1831   elsif ($storage->_use_multicolumn_in) {
1832     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1833     my $sql_maker = $storage->sql_maker;
1834     my ($sql, @bind) = @${$subrs->as_query};
1835     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1836       join (', ', map { $sql_maker->_quote ($_) } @$idcols),
1837       $sql,
1838     );
1839
1840     return $storage->$op (
1841       $rsrc,
1842       $op eq 'update' ? $values : (),
1843       \[$sql, @bind],
1844     );
1845   }
1846   else {
1847
1848     # if all else fails - get all primary keys and operate over a ORed set
1849     # wrap in a transaction for consistency
1850     # this is where the group_by starts to matter
1851     if (
1852       $existing_group_by
1853         or
1854       keys %{ $relation_classifications->{multiplying} || {} }
1855     ) {
1856       # make sure if there is a supplied group_by it matches the columns compiled above
1857       # perfectly. Anything else can not be sanely executed on most databases so croak
1858       # right then and there
1859       if ($existing_group_by) {
1860         my @current_group_by = map
1861           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1862           @$existing_group_by
1863         ;
1864
1865         if (
1866           join ("\x00", sort @current_group_by)
1867             ne
1868           join ("\x00", sort @{$attrs->{columns}} )
1869         ) {
1870           $self->throw_exception (
1871             "You have just attempted a $op operation on a resultset which does group_by"
1872             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1873             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1874             . ' kind of queries. Please retry the operation with a modified group_by or'
1875             . ' without using one at all.'
1876           );
1877         }
1878       }
1879
1880       $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1881     }
1882
1883     my $guard = $storage->txn_scope_guard;
1884
1885     my @op_condition;
1886     for my $row ($subrs->cursor->all) {
1887       push @op_condition, { map
1888         { $idcols->[$_] => $row->[$_] }
1889         (0 .. $#$idcols)
1890       };
1891     }
1892
1893     my $res = $storage->$op (
1894       $rsrc,
1895       $op eq 'update' ? $values : (),
1896       \@op_condition,
1897     );
1898
1899     $guard->commit;
1900
1901     return $res;
1902   }
1903 }
1904
1905 =head2 update
1906
1907 =over 4
1908
1909 =item Arguments: \%values
1910
1911 =item Return Value: $underlying_storage_rv
1912
1913 =back
1914
1915 Sets the specified columns in the resultset to the supplied values in a
1916 single query. Note that this will not run any accessor/set_column/update
1917 triggers, nor will it update any result object instances derived from this
1918 resultset (this includes the contents of the L<resultset cache|/set_cache>
1919 if any). See L</update_all> if you need to execute any on-update
1920 triggers or cascades defined either by you or a
1921 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1922
1923 The return value is a pass through of what the underlying
1924 storage backend returned, and may vary. See L<DBI/execute> for the most
1925 common case.
1926
1927 =head3 CAVEAT
1928
1929 Note that L</update> does not process/deflate any of the values passed in.
1930 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1931 ensure manually that any value passed to this method will stringify to
1932 something the RDBMS knows how to deal with. A notable example is the
1933 handling of L<DateTime> objects, for more info see:
1934 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1935
1936 =cut
1937
1938 sub update {
1939   my ($self, $values) = @_;
1940   $self->throw_exception('Values for update must be a hash')
1941     unless ref $values eq 'HASH';
1942
1943   return $self->_rs_update_delete ('update', $values);
1944 }
1945
1946 =head2 update_all
1947
1948 =over 4
1949
1950 =item Arguments: \%values
1951
1952 =item Return Value: 1
1953
1954 =back
1955
1956 Fetches all objects and updates them one at a time via
1957 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1958 triggers, while L</update> will not.
1959
1960 =cut
1961
1962 sub update_all {
1963   my ($self, $values) = @_;
1964   $self->throw_exception('Values for update_all must be a hash')
1965     unless ref $values eq 'HASH';
1966
1967   my $guard = $self->result_source->schema->txn_scope_guard;
1968   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1969   $guard->commit;
1970   return 1;
1971 }
1972
1973 =head2 delete
1974
1975 =over 4
1976
1977 =item Arguments: none
1978
1979 =item Return Value: $underlying_storage_rv
1980
1981 =back
1982
1983 Deletes the rows matching this resultset in a single query. Note that this
1984 will not run any delete triggers, nor will it alter the
1985 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1986 derived from this resultset (this includes the contents of the
1987 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1988 execute any on-delete triggers or cascades defined either by you or a
1989 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1990
1991 The return value is a pass through of what the underlying storage backend
1992 returned, and may vary. See L<DBI/execute> for the most common case.
1993
1994 =cut
1995
1996 sub delete {
1997   my $self = shift;
1998   $self->throw_exception('delete does not accept any arguments')
1999     if @_;
2000
2001   return $self->_rs_update_delete ('delete');
2002 }
2003
2004 =head2 delete_all
2005
2006 =over 4
2007
2008 =item Arguments: none
2009
2010 =item Return Value: 1
2011
2012 =back
2013
2014 Fetches all objects and deletes them one at a time via
2015 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2016 triggers, while L</delete> will not.
2017
2018 =cut
2019
2020 sub delete_all {
2021   my $self = shift;
2022   $self->throw_exception('delete_all does not accept any arguments')
2023     if @_;
2024
2025   my $guard = $self->result_source->schema->txn_scope_guard;
2026   $_->delete for $self->all;
2027   $guard->commit;
2028   return 1;
2029 }
2030
2031 =head2 populate
2032
2033 =over 4
2034
2035 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2036
2037 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2038
2039 =back
2040
2041 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2042 arrayrefs.
2043
2044 =over
2045
2046 =item NOTE
2047
2048 The context of this method call has an important effect on what is
2049 submitted to storage. In void context data is fed directly to fastpath
2050 insertion routines provided by the underlying storage (most often
2051 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2052 L<insert|DBIx::Class::Row/insert> calls on the
2053 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2054 augmentation of these methods provided by components. For example if you
2055 are using something like L<DBIx::Class::UUIDColumns> to create primary
2056 keys for you, you will find that your PKs are empty.  In this case you
2057 will have to explicitly force scalar or list context in order to create
2058 those values.
2059
2060 =back
2061
2062 In non-void (scalar or list) context, this method is simply a wrapper
2063 for L</create>. Depending on list or scalar context either a list of
2064 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2065 containing these objects is returned.
2066
2067 When supplying data in "arrayref of arrayrefs" invocation style, the
2068 first element should be a list of column names and each subsequent
2069 element should be a data value in the earlier specified column order.
2070 For example:
2071
2072   $Arstist_rs->populate([
2073     [ qw( artistid name ) ],
2074     [ 100, 'A Formally Unknown Singer' ],
2075     [ 101, 'A singer that jumped the shark two albums ago' ],
2076     [ 102, 'An actually cool singer' ],
2077   ]);
2078
2079 For the arrayref of hashrefs style each hashref should be a structure
2080 suitable for passing to L</create>. Multi-create is also permitted with
2081 this syntax.
2082
2083   $schema->resultset("Artist")->populate([
2084      { artistid => 4, name => 'Manufactured Crap', cds => [
2085         { title => 'My First CD', year => 2006 },
2086         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2087       ],
2088      },
2089      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2090         { title => 'My parents sold me to a record company', year => 2005 },
2091         { title => 'Why Am I So Ugly?', year => 2006 },
2092         { title => 'I Got Surgery and am now Popular', year => 2007 }
2093       ],
2094      },
2095   ]);
2096
2097 If you attempt a void-context multi-create as in the example above (each
2098 Artist also has the related list of CDs), and B<do not> supply the
2099 necessary autoinc foreign key information, this method will proxy to the
2100 less efficient L</create>, and then throw the Result objects away. In this
2101 case there are obviously no benefits to using this method over L</create>.
2102
2103 =cut
2104
2105 sub populate {
2106   my $self = shift;
2107
2108   # cruft placed in standalone method
2109   my $data = $self->_normalize_populate_args(@_);
2110
2111   return unless @$data;
2112
2113   if(defined wantarray) {
2114     my @created;
2115     foreach my $item (@$data) {
2116       push(@created, $self->create($item));
2117     }
2118     return wantarray ? @created : \@created;
2119   }
2120   else {
2121     my $first = $data->[0];
2122
2123     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2124     # it relationship data
2125     my (@rels, @columns);
2126     my $rsrc = $self->result_source;
2127     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2128     for (keys %$first) {
2129       my $ref = ref $first->{$_};
2130       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2131         ? push @rels, $_
2132         : push @columns, $_
2133       ;
2134     }
2135
2136     my @pks = $rsrc->primary_columns;
2137
2138     ## do the belongs_to relationships
2139     foreach my $index (0..$#$data) {
2140
2141       # delegate to create() for any dataset without primary keys with specified relationships
2142       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2143         for my $r (@rels) {
2144           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2145             my @ret = $self->populate($data);
2146             return;
2147           }
2148         }
2149       }
2150
2151       foreach my $rel (@rels) {
2152         next unless ref $data->[$index]->{$rel} eq "HASH";
2153         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2154         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2155         my $related = $result->result_source->_resolve_condition(
2156           $reverse_relinfo->{cond},
2157           $self,
2158           $result,
2159           $rel,
2160         );
2161
2162         delete $data->[$index]->{$rel};
2163         $data->[$index] = {%{$data->[$index]}, %$related};
2164
2165         push @columns, keys %$related if $index == 0;
2166       }
2167     }
2168
2169     ## inherit the data locked in the conditions of the resultset
2170     my ($rs_data) = $self->_merge_with_rscond({});
2171     delete @{$rs_data}{@columns};
2172
2173     ## do bulk insert on current row
2174     $rsrc->storage->insert_bulk(
2175       $rsrc,
2176       [@columns, keys %$rs_data],
2177       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2178     );
2179
2180     ## do the has_many relationships
2181     foreach my $item (@$data) {
2182
2183       my $main_row;
2184
2185       foreach my $rel (@rels) {
2186         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2187
2188         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2189
2190         my $child = $main_row->$rel;
2191
2192         my $related = $child->result_source->_resolve_condition(
2193           $rels->{$rel}{cond},
2194           $child,
2195           $main_row,
2196           $rel,
2197         );
2198
2199         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2200         my @populate = map { {%$_, %$related} } @rows_to_add;
2201
2202         $child->populate( \@populate );
2203       }
2204     }
2205   }
2206 }
2207
2208
2209 # populate() argumnets went over several incarnations
2210 # What we ultimately support is AoH
2211 sub _normalize_populate_args {
2212   my ($self, $arg) = @_;
2213
2214   if (ref $arg eq 'ARRAY') {
2215     if (!@$arg) {
2216       return [];
2217     }
2218     elsif (ref $arg->[0] eq 'HASH') {
2219       return $arg;
2220     }
2221     elsif (ref $arg->[0] eq 'ARRAY') {
2222       my @ret;
2223       my @colnames = @{$arg->[0]};
2224       foreach my $values (@{$arg}[1 .. $#$arg]) {
2225         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2226       }
2227       return \@ret;
2228     }
2229   }
2230
2231   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2232 }
2233
2234 =head2 pager
2235
2236 =over 4
2237
2238 =item Arguments: none
2239
2240 =item Return Value: L<$pager|Data::Page>
2241
2242 =back
2243
2244 Returns a L<Data::Page> object for the current resultset. Only makes
2245 sense for queries with a C<page> attribute.
2246
2247 To get the full count of entries for a paged resultset, call
2248 C<total_entries> on the L<Data::Page> object.
2249
2250 =cut
2251
2252 sub pager {
2253   my ($self) = @_;
2254
2255   return $self->{pager} if $self->{pager};
2256
2257   my $attrs = $self->{attrs};
2258   if (!defined $attrs->{page}) {
2259     $self->throw_exception("Can't create pager for non-paged rs");
2260   }
2261   elsif ($attrs->{page} <= 0) {
2262     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2263   }
2264   $attrs->{rows} ||= 10;
2265
2266   # throw away the paging flags and re-run the count (possibly
2267   # with a subselect) to get the real total count
2268   my $count_attrs = { %$attrs };
2269   delete $count_attrs->{$_} for qw/rows offset page pager/;
2270
2271   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2272
2273   require DBIx::Class::ResultSet::Pager;
2274   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2275     sub { $total_rs->count },  #lazy-get the total
2276     $attrs->{rows},
2277     $self->{attrs}{page},
2278   );
2279 }
2280
2281 =head2 page
2282
2283 =over 4
2284
2285 =item Arguments: $page_number
2286
2287 =item Return Value: L<$resultset|/search>
2288
2289 =back
2290
2291 Returns a resultset for the $page_number page of the resultset on which page
2292 is called, where each page contains a number of rows equal to the 'rows'
2293 attribute set on the resultset (10 by default).
2294
2295 =cut
2296
2297 sub page {
2298   my ($self, $page) = @_;
2299   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2300 }
2301
2302 =head2 new_result
2303
2304 =over 4
2305
2306 =item Arguments: \%col_data
2307
2308 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2309
2310 =back
2311
2312 Creates a new result object in the resultset's result class and returns
2313 it. The row is not inserted into the database at this point, call
2314 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2315 will tell you whether the result object has been inserted or not.
2316
2317 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2318
2319 =cut
2320
2321 sub new_result {
2322   my ($self, $values) = @_;
2323
2324   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2325     if @_ > 2;
2326
2327   $self->throw_exception( "new_result expects a hashref" )
2328     unless (ref $values eq 'HASH');
2329
2330   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2331
2332   my %new = (
2333     %$merged_cond,
2334     @$cols_from_relations
2335       ? (-cols_from_relations => $cols_from_relations)
2336       : (),
2337     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2338   );
2339
2340   return $self->result_class->new(\%new);
2341 }
2342
2343 # _merge_with_rscond
2344 #
2345 # Takes a simple hash of K/V data and returns its copy merged with the
2346 # condition already present on the resultset. Additionally returns an
2347 # arrayref of value/condition names, which were inferred from related
2348 # objects (this is needed for in-memory related objects)
2349 sub _merge_with_rscond {
2350   my ($self, $data) = @_;
2351
2352   my (%new_data, @cols_from_relations);
2353
2354   my $alias = $self->{attrs}{alias};
2355
2356   if (! defined $self->{cond}) {
2357     # just massage $data below
2358   }
2359   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2360     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2361     @cols_from_relations = keys %new_data;
2362   }
2363   elsif (ref $self->{cond} ne 'HASH') {
2364     $self->throw_exception(
2365       "Can't abstract implicit construct, resultset condition not a hash"
2366     );
2367   }
2368   else {
2369     # precendence must be given to passed values over values inherited from
2370     # the cond, so the order here is important.
2371     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2372     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2373
2374     while ( my($col, $value) = each %implied ) {
2375       my $vref = ref $value;
2376       if (
2377         $vref eq 'HASH'
2378           and
2379         keys(%$value) == 1
2380           and
2381         (keys %$value)[0] eq '='
2382       ) {
2383         $new_data{$col} = $value->{'='};
2384       }
2385       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2386         $new_data{$col} = $value;
2387       }
2388     }
2389   }
2390
2391   %new_data = (
2392     %new_data,
2393     %{ $self->_remove_alias($data, $alias) },
2394   );
2395
2396   return (\%new_data, \@cols_from_relations);
2397 }
2398
2399 # _has_resolved_attr
2400 #
2401 # determines if the resultset defines at least one
2402 # of the attributes supplied
2403 #
2404 # used to determine if a subquery is neccessary
2405 #
2406 # supports some virtual attributes:
2407 #   -join
2408 #     This will scan for any joins being present on the resultset.
2409 #     It is not a mere key-search but a deep inspection of {from}
2410 #
2411
2412 sub _has_resolved_attr {
2413   my ($self, @attr_names) = @_;
2414
2415   my $attrs = $self->_resolved_attrs;
2416
2417   my %extra_checks;
2418
2419   for my $n (@attr_names) {
2420     if (grep { $n eq $_ } (qw/-join/) ) {
2421       $extra_checks{$n}++;
2422       next;
2423     }
2424
2425     my $attr =  $attrs->{$n};
2426
2427     next if not defined $attr;
2428
2429     if (ref $attr eq 'HASH') {
2430       return 1 if keys %$attr;
2431     }
2432     elsif (ref $attr eq 'ARRAY') {
2433       return 1 if @$attr;
2434     }
2435     else {
2436       return 1 if $attr;
2437     }
2438   }
2439
2440   # a resolved join is expressed as a multi-level from
2441   return 1 if (
2442     $extra_checks{-join}
2443       and
2444     ref $attrs->{from} eq 'ARRAY'
2445       and
2446     @{$attrs->{from}} > 1
2447   );
2448
2449   return 0;
2450 }
2451
2452 # _collapse_cond
2453 #
2454 # Recursively collapse the condition.
2455
2456 sub _collapse_cond {
2457   my ($self, $cond, $collapsed) = @_;
2458
2459   $collapsed ||= {};
2460
2461   if (ref $cond eq 'ARRAY') {
2462     foreach my $subcond (@$cond) {
2463       next unless ref $subcond;  # -or
2464       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2465     }
2466   }
2467   elsif (ref $cond eq 'HASH') {
2468     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2469       foreach my $subcond (@{$cond->{-and}}) {
2470         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2471       }
2472     }
2473     else {
2474       foreach my $col (keys %$cond) {
2475         my $value = $cond->{$col};
2476         $collapsed->{$col} = $value;
2477       }
2478     }
2479   }
2480
2481   return $collapsed;
2482 }
2483
2484 # _remove_alias
2485 #
2486 # Remove the specified alias from the specified query hash. A copy is made so
2487 # the original query is not modified.
2488
2489 sub _remove_alias {
2490   my ($self, $query, $alias) = @_;
2491
2492   my %orig = %{ $query || {} };
2493   my %unaliased;
2494
2495   foreach my $key (keys %orig) {
2496     if ($key !~ /\./) {
2497       $unaliased{$key} = $orig{$key};
2498       next;
2499     }
2500     $unaliased{$1} = $orig{$key}
2501       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2502   }
2503
2504   return \%unaliased;
2505 }
2506
2507 =head2 as_query
2508
2509 =over 4
2510
2511 =item Arguments: none
2512
2513 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2514
2515 =back
2516
2517 Returns the SQL query and bind vars associated with the invocant.
2518
2519 This is generally used as the RHS for a subquery.
2520
2521 =cut
2522
2523 sub as_query {
2524   my $self = shift;
2525
2526   my $attrs = $self->_resolved_attrs_copy;
2527
2528   # For future use:
2529   #
2530   # in list ctx:
2531   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2532   # $sql also has no wrapping parenthesis in list ctx
2533   #
2534   my $sqlbind = $self->result_source->storage
2535     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2536
2537   return $sqlbind;
2538 }
2539
2540 =head2 find_or_new
2541
2542 =over 4
2543
2544 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2545
2546 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2547
2548 =back
2549
2550   my $artist = $schema->resultset('Artist')->find_or_new(
2551     { artist => 'fred' }, { key => 'artists' });
2552
2553   $cd->cd_to_producer->find_or_new({ producer => $producer },
2554                                    { key => 'primary });
2555
2556 Find an existing record from this resultset using L</find>. if none exists,
2557 instantiate a new result object and return it. The object will not be saved
2558 into your storage until you call L<DBIx::Class::Row/insert> on it.
2559
2560 You most likely want this method when looking for existing rows using a unique
2561 constraint that is not the primary key, or looking for related rows.
2562
2563 If you want objects to be saved immediately, use L</find_or_create> instead.
2564
2565 B<Note>: Make sure to read the documentation of L</find> and understand the
2566 significance of the C<key> attribute, as its lack may skew your search, and
2567 subsequently result in spurious new objects.
2568
2569 B<Note>: Take care when using C<find_or_new> with a table having
2570 columns with default values that you intend to be automatically
2571 supplied by the database (e.g. an auto_increment primary key column).
2572 In normal usage, the value of such columns should NOT be included at
2573 all in the call to C<find_or_new>, even when set to C<undef>.
2574
2575 =cut
2576
2577 sub find_or_new {
2578   my $self     = shift;
2579   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2580   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2581   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2582     return $row;
2583   }
2584   return $self->new_result($hash);
2585 }
2586
2587 =head2 create
2588
2589 =over 4
2590
2591 =item Arguments: \%col_data
2592
2593 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2594
2595 =back
2596
2597 Attempt to create a single new row or a row with multiple related rows
2598 in the table represented by the resultset (and related tables). This
2599 will not check for duplicate rows before inserting, use
2600 L</find_or_create> to do that.
2601
2602 To create one row for this resultset, pass a hashref of key/value
2603 pairs representing the columns of the table and the values you wish to
2604 store. If the appropriate relationships are set up, foreign key fields
2605 can also be passed an object representing the foreign row, and the
2606 value will be set to its primary key.
2607
2608 To create related objects, pass a hashref of related-object column values
2609 B<keyed on the relationship name>. If the relationship is of type C<multi>
2610 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2611 The process will correctly identify columns holding foreign keys, and will
2612 transparently populate them from the keys of the corresponding relation.
2613 This can be applied recursively, and will work correctly for a structure
2614 with an arbitrary depth and width, as long as the relationships actually
2615 exists and the correct column data has been supplied.
2616
2617 Instead of hashrefs of plain related data (key/value pairs), you may
2618 also pass new or inserted objects. New objects (not inserted yet, see
2619 L</new_result>), will be inserted into their appropriate tables.
2620
2621 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2622
2623 Example of creating a new row.
2624
2625   $person_rs->create({
2626     name=>"Some Person",
2627     email=>"somebody@someplace.com"
2628   });
2629
2630 Example of creating a new row and also creating rows in a related C<has_many>
2631 or C<has_one> resultset.  Note Arrayref.
2632
2633   $artist_rs->create(
2634      { artistid => 4, name => 'Manufactured Crap', cds => [
2635         { title => 'My First CD', year => 2006 },
2636         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2637       ],
2638      },
2639   );
2640
2641 Example of creating a new row and also creating a row in a related
2642 C<belongs_to> resultset. Note Hashref.
2643
2644   $cd_rs->create({
2645     title=>"Music for Silly Walks",
2646     year=>2000,
2647     artist => {
2648       name=>"Silly Musician",
2649     }
2650   });
2651
2652 =over
2653
2654 =item WARNING
2655
2656 When subclassing ResultSet never attempt to override this method. Since
2657 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2658 lot of the internals simply never call it, so your override will be
2659 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2660 or L<DBIx::Class::Row/insert> depending on how early in the
2661 L</create> process you need to intervene. See also warning pertaining to
2662 L</new>.
2663
2664 =back
2665
2666 =cut
2667
2668 sub create {
2669   my ($self, $attrs) = @_;
2670   $self->throw_exception( "create needs a hashref" )
2671     unless ref $attrs eq 'HASH';
2672   return $self->new_result($attrs)->insert;
2673 }
2674
2675 =head2 find_or_create
2676
2677 =over 4
2678
2679 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2680
2681 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2682
2683 =back
2684
2685   $cd->cd_to_producer->find_or_create({ producer => $producer },
2686                                       { key => 'primary' });
2687
2688 Tries to find a record based on its primary key or unique constraints; if none
2689 is found, creates one and returns that instead.
2690
2691   my $cd = $schema->resultset('CD')->find_or_create({
2692     cdid   => 5,
2693     artist => 'Massive Attack',
2694     title  => 'Mezzanine',
2695     year   => 2005,
2696   });
2697
2698 Also takes an optional C<key> attribute, to search by a specific key or unique
2699 constraint. For example:
2700
2701   my $cd = $schema->resultset('CD')->find_or_create(
2702     {
2703       artist => 'Massive Attack',
2704       title  => 'Mezzanine',
2705     },
2706     { key => 'cd_artist_title' }
2707   );
2708
2709 B<Note>: Make sure to read the documentation of L</find> and understand the
2710 significance of the C<key> attribute, as its lack may skew your search, and
2711 subsequently result in spurious row creation.
2712
2713 B<Note>: Because find_or_create() reads from the database and then
2714 possibly inserts based on the result, this method is subject to a race
2715 condition. Another process could create a record in the table after
2716 the find has completed and before the create has started. To avoid
2717 this problem, use find_or_create() inside a transaction.
2718
2719 B<Note>: Take care when using C<find_or_create> with a table having
2720 columns with default values that you intend to be automatically
2721 supplied by the database (e.g. an auto_increment primary key column).
2722 In normal usage, the value of such columns should NOT be included at
2723 all in the call to C<find_or_create>, even when set to C<undef>.
2724
2725 See also L</find> and L</update_or_create>. For information on how to declare
2726 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2727
2728 If you need to know if an existing row was found or a new one created use
2729 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2730 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2731 database!
2732
2733   my $cd = $schema->resultset('CD')->find_or_new({
2734     cdid   => 5,
2735     artist => 'Massive Attack',
2736     title  => 'Mezzanine',
2737     year   => 2005,
2738   });
2739
2740   if( !$cd->in_storage ) {
2741       # do some stuff
2742       $cd->insert;
2743   }
2744
2745 =cut
2746
2747 sub find_or_create {
2748   my $self     = shift;
2749   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2750   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2751   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2752     return $row;
2753   }
2754   return $self->create($hash);
2755 }
2756
2757 =head2 update_or_create
2758
2759 =over 4
2760
2761 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2762
2763 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2764
2765 =back
2766
2767   $resultset->update_or_create({ col => $val, ... });
2768
2769 Like L</find_or_create>, but if a row is found it is immediately updated via
2770 C<< $found_row->update (\%col_data) >>.
2771
2772
2773 Takes an optional C<key> attribute to search on a specific unique constraint.
2774 For example:
2775
2776   # In your application
2777   my $cd = $schema->resultset('CD')->update_or_create(
2778     {
2779       artist => 'Massive Attack',
2780       title  => 'Mezzanine',
2781       year   => 1998,
2782     },
2783     { key => 'cd_artist_title' }
2784   );
2785
2786   $cd->cd_to_producer->update_or_create({
2787     producer => $producer,
2788     name => 'harry',
2789   }, {
2790     key => 'primary',
2791   });
2792
2793 B<Note>: Make sure to read the documentation of L</find> and understand the
2794 significance of the C<key> attribute, as its lack may skew your search, and
2795 subsequently result in spurious row creation.
2796
2797 B<Note>: Take care when using C<update_or_create> with a table having
2798 columns with default values that you intend to be automatically
2799 supplied by the database (e.g. an auto_increment primary key column).
2800 In normal usage, the value of such columns should NOT be included at
2801 all in the call to C<update_or_create>, even when set to C<undef>.
2802
2803 See also L</find> and L</find_or_create>. For information on how to declare
2804 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2805
2806 If you need to know if an existing row was updated or a new one created use
2807 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2808 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2809 database!
2810
2811 =cut
2812
2813 sub update_or_create {
2814   my $self = shift;
2815   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2816   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2817
2818   my $row = $self->find($cond, $attrs);
2819   if (defined $row) {
2820     $row->update($cond);
2821     return $row;
2822   }
2823
2824   return $self->create($cond);
2825 }
2826
2827 =head2 update_or_new
2828
2829 =over 4
2830
2831 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2832
2833 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2834
2835 =back
2836
2837   $resultset->update_or_new({ col => $val, ... });
2838
2839 Like L</find_or_new> but if a row is found it is immediately updated via
2840 C<< $found_row->update (\%col_data) >>.
2841
2842 For example:
2843
2844   # In your application
2845   my $cd = $schema->resultset('CD')->update_or_new(
2846     {
2847       artist => 'Massive Attack',
2848       title  => 'Mezzanine',
2849       year   => 1998,
2850     },
2851     { key => 'cd_artist_title' }
2852   );
2853
2854   if ($cd->in_storage) {
2855       # the cd was updated
2856   }
2857   else {
2858       # the cd is not yet in the database, let's insert it
2859       $cd->insert;
2860   }
2861
2862 B<Note>: Make sure to read the documentation of L</find> and understand the
2863 significance of the C<key> attribute, as its lack may skew your search, and
2864 subsequently result in spurious new objects.
2865
2866 B<Note>: Take care when using C<update_or_new> with a table having
2867 columns with default values that you intend to be automatically
2868 supplied by the database (e.g. an auto_increment primary key column).
2869 In normal usage, the value of such columns should NOT be included at
2870 all in the call to C<update_or_new>, even when set to C<undef>.
2871
2872 See also L</find>, L</find_or_create> and L</find_or_new>.
2873
2874 =cut
2875
2876 sub update_or_new {
2877     my $self  = shift;
2878     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2879     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2880
2881     my $row = $self->find( $cond, $attrs );
2882     if ( defined $row ) {
2883         $row->update($cond);
2884         return $row;
2885     }
2886
2887     return $self->new_result($cond);
2888 }
2889
2890 =head2 get_cache
2891
2892 =over 4
2893
2894 =item Arguments: none
2895
2896 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2897
2898 =back
2899
2900 Gets the contents of the cache for the resultset, if the cache is set.
2901
2902 The cache is populated either by using the L</prefetch> attribute to
2903 L</search> or by calling L</set_cache>.
2904
2905 =cut
2906
2907 sub get_cache {
2908   shift->{all_cache};
2909 }
2910
2911 =head2 set_cache
2912
2913 =over 4
2914
2915 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2916
2917 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2918
2919 =back
2920
2921 Sets the contents of the cache for the resultset. Expects an arrayref
2922 of objects of the same class as those produced by the resultset. Note that
2923 if the cache is set, the resultset will return the cached objects rather
2924 than re-querying the database even if the cache attr is not set.
2925
2926 The contents of the cache can also be populated by using the
2927 L</prefetch> attribute to L</search>.
2928
2929 =cut
2930
2931 sub set_cache {
2932   my ( $self, $data ) = @_;
2933   $self->throw_exception("set_cache requires an arrayref")
2934       if defined($data) && (ref $data ne 'ARRAY');
2935   $self->{all_cache} = $data;
2936 }
2937
2938 =head2 clear_cache
2939
2940 =over 4
2941
2942 =item Arguments: none
2943
2944 =item Return Value: undef
2945
2946 =back
2947
2948 Clears the cache for the resultset.
2949
2950 =cut
2951
2952 sub clear_cache {
2953   shift->set_cache(undef);
2954 }
2955
2956 =head2 is_paged
2957
2958 =over 4
2959
2960 =item Arguments: none
2961
2962 =item Return Value: true, if the resultset has been paginated
2963
2964 =back
2965
2966 =cut
2967
2968 sub is_paged {
2969   my ($self) = @_;
2970   return !!$self->{attrs}{page};
2971 }
2972
2973 =head2 is_ordered
2974
2975 =over 4
2976
2977 =item Arguments: none
2978
2979 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2980
2981 =back
2982
2983 =cut
2984
2985 sub is_ordered {
2986   my ($self) = @_;
2987   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2988 }
2989
2990 =head2 related_resultset
2991
2992 =over 4
2993
2994 =item Arguments: $rel_name
2995
2996 =item Return Value: L<$resultset|/search>
2997
2998 =back
2999
3000 Returns a related resultset for the supplied relationship name.
3001
3002   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3003
3004 =cut
3005
3006 sub related_resultset {
3007   my ($self, $rel) = @_;
3008
3009   $self->{related_resultsets} ||= {};
3010   return $self->{related_resultsets}{$rel} ||= do {
3011     my $rsrc = $self->result_source;
3012     my $rel_info = $rsrc->relationship_info($rel);
3013
3014     $self->throw_exception(
3015       "search_related: result source '" . $rsrc->source_name .
3016         "' has no such relationship $rel")
3017       unless $rel_info;
3018
3019     my $attrs = $self->_chain_relationship($rel);
3020
3021     my $join_count = $attrs->{seen_join}{$rel};
3022
3023     my $alias = $self->result_source->storage
3024         ->relname_to_table_alias($rel, $join_count);
3025
3026     # since this is search_related, and we already slid the select window inwards
3027     # (the select/as attrs were deleted in the beginning), we need to flip all
3028     # left joins to inner, so we get the expected results
3029     # read the comment on top of the actual function to see what this does
3030     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3031
3032
3033     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3034     delete @{$attrs}{qw(result_class alias)};
3035
3036     my $new_cache;
3037
3038     if (my $cache = $self->get_cache) {
3039       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3040         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3041                         @$cache ];
3042       }
3043     }
3044
3045     my $rel_source = $rsrc->related_source($rel);
3046
3047     my $new = do {
3048
3049       # The reason we do this now instead of passing the alias to the
3050       # search_rs below is that if you wrap/overload resultset on the
3051       # source you need to know what alias it's -going- to have for things
3052       # to work sanely (e.g. RestrictWithObject wants to be able to add
3053       # extra query restrictions, and these may need to be $alias.)
3054
3055       my $rel_attrs = $rel_source->resultset_attributes;
3056       local $rel_attrs->{alias} = $alias;
3057
3058       $rel_source->resultset
3059                  ->search_rs(
3060                      undef, {
3061                        %$attrs,
3062                        where => $attrs->{where},
3063                    });
3064     };
3065     $new->set_cache($new_cache) if $new_cache;
3066     $new;
3067   };
3068 }
3069
3070 =head2 current_source_alias
3071
3072 =over 4
3073
3074 =item Arguments: none
3075
3076 =item Return Value: $source_alias
3077
3078 =back
3079
3080 Returns the current table alias for the result source this resultset is built
3081 on, that will be used in the SQL query. Usually it is C<me>.
3082
3083 Currently the source alias that refers to the result set returned by a
3084 L</search>/L</find> family method depends on how you got to the resultset: it's
3085 C<me> by default, but eg. L</search_related> aliases it to the related result
3086 source name (and keeps C<me> referring to the original result set). The long
3087 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3088 (and make this method unnecessary).
3089
3090 Thus it's currently necessary to use this method in predefined queries (see
3091 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3092 source alias of the current result set:
3093
3094   # in a result set class
3095   sub modified_by {
3096     my ($self, $user) = @_;
3097
3098     my $me = $self->current_source_alias;
3099
3100     return $self->search({
3101       "$me.modified" => $user->id,
3102     });
3103   }
3104
3105 =cut
3106
3107 sub current_source_alias {
3108   my ($self) = @_;
3109
3110   return ($self->{attrs} || {})->{alias} || 'me';
3111 }
3112
3113 =head2 as_subselect_rs
3114
3115 =over 4
3116
3117 =item Arguments: none
3118
3119 =item Return Value: L<$resultset|/search>
3120
3121 =back
3122
3123 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3124 "virtual view" by including it as a subquery within the from clause.  From this
3125 point on, any joined tables are inaccessible to ->search on the resultset (as if
3126 it were simply where-filtered without joins).  For example:
3127
3128  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3129
3130  # 'x' now pollutes the query namespace
3131
3132  # So the following works as expected
3133  my $ok_rs = $rs->search({'x.other' => 1});
3134
3135  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3136  # def) we look for one row with contradictory terms and join in another table
3137  # (aliased 'x_2') which we never use
3138  my $broken_rs = $rs->search({'x.name' => 'def'});
3139
3140  my $rs2 = $rs->as_subselect_rs;
3141
3142  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3143  my $not_joined_rs = $rs2->search({'x.other' => 1});
3144
3145  # works as expected: finds a 'table' row related to two x rows (abc and def)
3146  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3147
3148 Another example of when one might use this would be to select a subset of
3149 columns in a group by clause:
3150
3151  my $rs = $schema->resultset('Bar')->search(undef, {
3152    group_by => [qw{ id foo_id baz_id }],
3153  })->as_subselect_rs->search(undef, {
3154    columns => [qw{ id foo_id }]
3155  });
3156
3157 In the above example normally columns would have to be equal to the group by,
3158 but because we isolated the group by into a subselect the above works.
3159
3160 =cut
3161
3162 sub as_subselect_rs {
3163   my $self = shift;
3164
3165   my $attrs = $self->_resolved_attrs;
3166
3167   my $fresh_rs = (ref $self)->new (
3168     $self->result_source
3169   );
3170
3171   # these pieces will be locked in the subquery
3172   delete $fresh_rs->{cond};
3173   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3174
3175   return $fresh_rs->search( {}, {
3176     from => [{
3177       $attrs->{alias} => $self->as_query,
3178       -alias  => $attrs->{alias},
3179       -rsrc   => $self->result_source,
3180     }],
3181     alias => $attrs->{alias},
3182   });
3183 }
3184
3185 # This code is called by search_related, and makes sure there
3186 # is clear separation between the joins before, during, and
3187 # after the relationship. This information is needed later
3188 # in order to properly resolve prefetch aliases (any alias
3189 # with a relation_chain_depth less than the depth of the
3190 # current prefetch is not considered)
3191 #
3192 # The increments happen twice per join. An even number means a
3193 # relationship specified via a search_related, whereas an odd
3194 # number indicates a join/prefetch added via attributes
3195 #
3196 # Also this code will wrap the current resultset (the one we
3197 # chain to) in a subselect IFF it contains limiting attributes
3198 sub _chain_relationship {
3199   my ($self, $rel) = @_;
3200   my $source = $self->result_source;
3201   my $attrs = { %{$self->{attrs}||{}} };
3202
3203   # we need to take the prefetch the attrs into account before we
3204   # ->_resolve_join as otherwise they get lost - captainL
3205   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3206
3207   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3208
3209   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3210
3211   my $from;
3212   my @force_subq_attrs = qw/offset rows group_by having/;
3213
3214   if (
3215     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3216       ||
3217     $self->_has_resolved_attr (@force_subq_attrs)
3218   ) {
3219     # Nuke the prefetch (if any) before the new $rs attrs
3220     # are resolved (prefetch is useless - we are wrapping
3221     # a subquery anyway).
3222     my $rs_copy = $self->search;
3223     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3224       $rs_copy->{attrs}{join},
3225       delete $rs_copy->{attrs}{prefetch},
3226     );
3227
3228     $from = [{
3229       -rsrc   => $source,
3230       -alias  => $attrs->{alias},
3231       $attrs->{alias} => $rs_copy->as_query,
3232     }];
3233     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3234     $seen->{-relation_chain_depth} = 0;
3235   }
3236   elsif ($attrs->{from}) {  #shallow copy suffices
3237     $from = [ @{$attrs->{from}} ];
3238   }
3239   else {
3240     $from = [{
3241       -rsrc  => $source,
3242       -alias => $attrs->{alias},
3243       $attrs->{alias} => $source->from,
3244     }];
3245   }
3246
3247   my $jpath = ($seen->{-relation_chain_depth})
3248     ? $from->[-1][0]{-join_path}
3249     : [];
3250
3251   my @requested_joins = $source->_resolve_join(
3252     $join,
3253     $attrs->{alias},
3254     $seen,
3255     $jpath,
3256   );
3257
3258   push @$from, @requested_joins;
3259
3260   $seen->{-relation_chain_depth}++;
3261
3262   # if $self already had a join/prefetch specified on it, the requested
3263   # $rel might very well be already included. What we do in this case
3264   # is effectively a no-op (except that we bump up the chain_depth on
3265   # the join in question so we could tell it *is* the search_related)
3266   my $already_joined;
3267
3268   # we consider the last one thus reverse
3269   for my $j (reverse @requested_joins) {
3270     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3271     if ($rel eq $last_j) {
3272       $j->[0]{-relation_chain_depth}++;
3273       $already_joined++;
3274       last;
3275     }
3276   }
3277
3278   unless ($already_joined) {
3279     push @$from, $source->_resolve_join(
3280       $rel,
3281       $attrs->{alias},
3282       $seen,
3283       $jpath,
3284     );
3285   }
3286
3287   $seen->{-relation_chain_depth}++;
3288
3289   return {%$attrs, from => $from, seen_join => $seen};
3290 }
3291
3292 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3293 sub _resolved_attrs_copy {
3294   my $self = shift;
3295   return { %{$self->_resolved_attrs (@_)} };
3296 }
3297
3298 sub _resolved_attrs {
3299   my $self = shift;
3300   return $self->{_attrs} if $self->{_attrs};
3301
3302   my $attrs  = { %{ $self->{attrs} || {} } };
3303   my $source = $self->result_source;
3304   my $alias  = $attrs->{alias};
3305
3306   # default selection list
3307   $attrs->{columns} = [ $source->columns ]
3308     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3309
3310   # merge selectors together
3311   for (qw/columns select as/) {
3312     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3313       if $attrs->{$_} or $attrs->{"+$_"};
3314   }
3315
3316   # disassemble columns
3317   my (@sel, @as);
3318   if (my $cols = delete $attrs->{columns}) {
3319     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3320       if (ref $c eq 'HASH') {
3321         for my $as (sort keys %$c) {
3322           push @sel, $c->{$as};
3323           push @as, $as;
3324         }
3325       }
3326       else {
3327         push @sel, $c;
3328         push @as, $c;
3329       }
3330     }
3331   }
3332
3333   # when trying to weed off duplicates later do not go past this point -
3334   # everything added from here on is unbalanced "anyone's guess" stuff
3335   my $dedup_stop_idx = $#as;
3336
3337   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3338     if $attrs->{as};
3339   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3340     if $attrs->{select};
3341
3342   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3343   for (@sel) {
3344     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3345   }
3346
3347   # disqualify all $alias.col as-bits (collapser mandated)
3348   for (@as) {
3349     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3350   }
3351
3352   # de-duplicate the result (remove *identical* select/as pairs)
3353   # and also die on duplicate {as} pointing to different {select}s
3354   # not using a c-style for as the condition is prone to shrinkage
3355   my $seen;
3356   my $i = 0;
3357   while ($i <= $dedup_stop_idx) {
3358     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3359       splice @sel, $i, 1;
3360       splice @as, $i, 1;
3361       $dedup_stop_idx--;
3362     }
3363     elsif ($seen->{$as[$i]}++) {
3364       $self->throw_exception(
3365         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3366       );
3367     }
3368     else {
3369       $i++;
3370     }
3371   }
3372
3373   $attrs->{select} = \@sel;
3374   $attrs->{as} = \@as;
3375
3376   $attrs->{from} ||= [{
3377     -rsrc   => $source,
3378     -alias  => $self->{attrs}{alias},
3379     $self->{attrs}{alias} => $source->from,
3380   }];
3381
3382   if ( $attrs->{join} || $attrs->{prefetch} ) {
3383
3384     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3385       if ref $attrs->{from} ne 'ARRAY';
3386
3387     my $join = (delete $attrs->{join}) || {};
3388
3389     if ( defined $attrs->{prefetch} ) {
3390       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3391     }
3392
3393     $attrs->{from} =    # have to copy here to avoid corrupting the original
3394       [
3395         @{ $attrs->{from} },
3396         $source->_resolve_join(
3397           $join,
3398           $alias,
3399           { %{ $attrs->{seen_join} || {} } },
3400           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3401             ? $attrs->{from}[-1][0]{-join_path}
3402             : []
3403           ,
3404         )
3405       ];
3406   }
3407
3408   if ( defined $attrs->{order_by} ) {
3409     $attrs->{order_by} = (
3410       ref( $attrs->{order_by} ) eq 'ARRAY'
3411       ? [ @{ $attrs->{order_by} } ]
3412       : [ $attrs->{order_by} || () ]
3413     );
3414   }
3415
3416   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3417     $attrs->{group_by} = [ $attrs->{group_by} ];
3418   }
3419
3420   # generate the distinct induced group_by early, as prefetch will be carried via a
3421   # subquery (since a group_by is present)
3422   if (delete $attrs->{distinct}) {
3423     if ($attrs->{group_by}) {
3424       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3425     }
3426     else {
3427       # distinct affects only the main selection part, not what prefetch may
3428       # add below.
3429       $attrs->{group_by} = $source->storage->_group_over_selection (
3430         $attrs->{from},
3431         $attrs->{select},
3432         $attrs->{order_by},
3433       );
3434     }
3435   }
3436
3437   $attrs->{collapse} ||= {};
3438   if ($attrs->{prefetch}) {
3439
3440     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3441       if $attrs->{_dark_selector};
3442
3443     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3444
3445     my $prefetch_ordering = [];
3446
3447     # this is a separate structure (we don't look in {from} directly)
3448     # as the resolver needs to shift things off the lists to work
3449     # properly (identical-prefetches on different branches)
3450     my $join_map = {};
3451     if (ref $attrs->{from} eq 'ARRAY') {
3452
3453       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3454
3455       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3456         next unless $j->[0]{-alias};
3457         next unless $j->[0]{-join_path};
3458         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3459
3460         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3461
3462         my $p = $join_map;
3463         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3464         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3465       }
3466     }
3467
3468     my @prefetch =
3469       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3470
3471     # we need to somehow mark which columns came from prefetch
3472     if (@prefetch) {
3473       my $sel_end = $#{$attrs->{select}};
3474       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3475     }
3476
3477     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3478     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3479
3480     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3481     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3482   }
3483
3484   # if both page and offset are specified, produce a combined offset
3485   # even though it doesn't make much sense, this is what pre 081xx has
3486   # been doing
3487   if (my $page = delete $attrs->{page}) {
3488     $attrs->{offset} =
3489       ($attrs->{rows} * ($page - 1))
3490             +
3491       ($attrs->{offset} || 0)
3492     ;
3493   }
3494
3495   return $self->{_attrs} = $attrs;
3496 }
3497
3498 sub _rollout_attr {
3499   my ($self, $attr) = @_;
3500
3501   if (ref $attr eq 'HASH') {
3502     return $self->_rollout_hash($attr);
3503   } elsif (ref $attr eq 'ARRAY') {
3504     return $self->_rollout_array($attr);
3505   } else {
3506     return [$attr];
3507   }
3508 }
3509
3510 sub _rollout_array {
3511   my ($self, $attr) = @_;
3512
3513   my @rolled_array;
3514   foreach my $element (@{$attr}) {
3515     if (ref $element eq 'HASH') {
3516       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3517     } elsif (ref $element eq 'ARRAY') {
3518       #  XXX - should probably recurse here
3519       push( @rolled_array, @{$self->_rollout_array($element)} );
3520     } else {
3521       push( @rolled_array, $element );
3522     }
3523   }
3524   return \@rolled_array;
3525 }
3526
3527 sub _rollout_hash {
3528   my ($self, $attr) = @_;
3529
3530   my @rolled_array;
3531   foreach my $key (keys %{$attr}) {
3532     push( @rolled_array, { $key => $attr->{$key} } );
3533   }
3534   return \@rolled_array;
3535 }
3536
3537 sub _calculate_score {
3538   my ($self, $a, $b) = @_;
3539
3540   if (defined $a xor defined $b) {
3541     return 0;
3542   }
3543   elsif (not defined $a) {
3544     return 1;
3545   }
3546
3547   if (ref $b eq 'HASH') {
3548     my ($b_key) = keys %{$b};
3549     if (ref $a eq 'HASH') {
3550       my ($a_key) = keys %{$a};
3551       if ($a_key eq $b_key) {
3552         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3553       } else {
3554         return 0;
3555       }
3556     } else {
3557       return ($a eq $b_key) ? 1 : 0;
3558     }
3559   } else {
3560     if (ref $a eq 'HASH') {
3561       my ($a_key) = keys %{$a};
3562       return ($b eq $a_key) ? 1 : 0;
3563     } else {
3564       return ($b eq $a) ? 1 : 0;
3565     }
3566   }
3567 }
3568
3569 sub _merge_joinpref_attr {
3570   my ($self, $orig, $import) = @_;
3571
3572   return $import unless defined($orig);
3573   return $orig unless defined($import);
3574
3575   $orig = $self->_rollout_attr($orig);
3576   $import = $self->_rollout_attr($import);
3577
3578   my $seen_keys;
3579   foreach my $import_element ( @{$import} ) {
3580     # find best candidate from $orig to merge $b_element into
3581     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3582     foreach my $orig_element ( @{$orig} ) {
3583       my $score = $self->_calculate_score( $orig_element, $import_element );
3584       if ($score > $best_candidate->{score}) {
3585         $best_candidate->{position} = $position;
3586         $best_candidate->{score} = $score;
3587       }
3588       $position++;
3589     }
3590     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3591     $import_key = '' if not defined $import_key;
3592
3593     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3594       push( @{$orig}, $import_element );
3595     } else {
3596       my $orig_best = $orig->[$best_candidate->{position}];
3597       # merge orig_best and b_element together and replace original with merged
3598       if (ref $orig_best ne 'HASH') {
3599         $orig->[$best_candidate->{position}] = $import_element;
3600       } elsif (ref $import_element eq 'HASH') {
3601         my ($key) = keys %{$orig_best};
3602         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3603       }
3604     }
3605     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3606   }
3607
3608   return $orig;
3609 }
3610
3611 {
3612   my $hm;
3613
3614   sub _merge_attr {
3615     $hm ||= do {
3616       require Hash::Merge;
3617       my $hm = Hash::Merge->new;
3618
3619       $hm->specify_behavior({
3620         SCALAR => {
3621           SCALAR => sub {
3622             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3623
3624             if ($defl xor $defr) {
3625               return [ $defl ? $_[0] : $_[1] ];
3626             }
3627             elsif (! $defl) {
3628               return [];
3629             }
3630             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3631               return [ $_[0] ];
3632             }
3633             else {
3634               return [$_[0], $_[1]];
3635             }
3636           },
3637           ARRAY => sub {
3638             return $_[1] if !defined $_[0];
3639             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3640             return [$_[0], @{$_[1]}]
3641           },
3642           HASH  => sub {
3643             return [] if !defined $_[0] and !keys %{$_[1]};
3644             return [ $_[1] ] if !defined $_[0];
3645             return [ $_[0] ] if !keys %{$_[1]};
3646             return [$_[0], $_[1]]
3647           },
3648         },
3649         ARRAY => {
3650           SCALAR => sub {
3651             return $_[0] if !defined $_[1];
3652             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3653             return [@{$_[0]}, $_[1]]
3654           },
3655           ARRAY => sub {
3656             my @ret = @{$_[0]} or return $_[1];
3657             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3658             my %idx = map { $_ => 1 } @ret;
3659             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3660             \@ret;
3661           },
3662           HASH => sub {
3663             return [ $_[1] ] if ! @{$_[0]};
3664             return $_[0] if !keys %{$_[1]};
3665             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3666             return [ @{$_[0]}, $_[1] ];
3667           },
3668         },
3669         HASH => {
3670           SCALAR => sub {
3671             return [] if !keys %{$_[0]} and !defined $_[1];
3672             return [ $_[0] ] if !defined $_[1];
3673             return [ $_[1] ] if !keys %{$_[0]};
3674             return [$_[0], $_[1]]
3675           },
3676           ARRAY => sub {
3677             return [] if !keys %{$_[0]} and !@{$_[1]};
3678             return [ $_[0] ] if !@{$_[1]};
3679             return $_[1] if !keys %{$_[0]};
3680             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3681             return [ $_[0], @{$_[1]} ];
3682           },
3683           HASH => sub {
3684             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3685             return [ $_[0] ] if !keys %{$_[1]};
3686             return [ $_[1] ] if !keys %{$_[0]};
3687             return [ $_[0] ] if $_[0] eq $_[1];
3688             return [ $_[0], $_[1] ];
3689           },
3690         }
3691       } => 'DBIC_RS_ATTR_MERGER');
3692       $hm;
3693     };
3694
3695     return $hm->merge ($_[1], $_[2]);
3696   }
3697 }
3698
3699 sub STORABLE_freeze {
3700   my ($self, $cloning) = @_;
3701   my $to_serialize = { %$self };
3702
3703   # A cursor in progress can't be serialized (and would make little sense anyway)
3704   delete $to_serialize->{cursor};
3705
3706   # nor is it sensical to store a not-yet-fired-count pager
3707   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3708     delete $to_serialize->{pager};
3709   }
3710
3711   Storable::nfreeze($to_serialize);
3712 }
3713
3714 # need this hook for symmetry
3715 sub STORABLE_thaw {
3716   my ($self, $cloning, $serialized) = @_;
3717
3718   %$self = %{ Storable::thaw($serialized) };
3719
3720   $self;
3721 }
3722
3723
3724 =head2 throw_exception
3725
3726 See L<DBIx::Class::Schema/throw_exception> for details.
3727
3728 =cut
3729
3730 sub throw_exception {
3731   my $self=shift;
3732
3733   if (ref $self and my $rsrc = $self->result_source) {
3734     $rsrc->throw_exception(@_)
3735   }
3736   else {
3737     DBIx::Class::Exception->throw(@_);
3738   }
3739 }
3740
3741 # XXX: FIXME: Attributes docs need clearing up
3742
3743 =head1 ATTRIBUTES
3744
3745 Attributes are used to refine a ResultSet in various ways when
3746 searching for data. They can be passed to any method which takes an
3747 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3748 L</count>.
3749
3750 Default attributes can be set on the result class using
3751 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3752 the CAVEATS on that feature before using it!)
3753
3754 These are in no particular order:
3755
3756 =head2 order_by
3757
3758 =over 4
3759
3760 =item Value: ( $order_by | \@order_by | \%order_by )
3761
3762 =back
3763
3764 Which column(s) to order the results by.
3765
3766 [The full list of suitable values is documented in
3767 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3768 common options.]
3769
3770 If a single column name, or an arrayref of names is supplied, the
3771 argument is passed through directly to SQL. The hashref syntax allows
3772 for connection-agnostic specification of ordering direction:
3773
3774  For descending order:
3775
3776   order_by => { -desc => [qw/col1 col2 col3/] }
3777
3778  For explicit ascending order:
3779
3780   order_by => { -asc => 'col' }
3781
3782 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3783 supported, although you are strongly encouraged to use the hashref
3784 syntax as outlined above.
3785
3786 =head2 columns
3787
3788 =over 4
3789
3790 =item Value: \@columns
3791
3792 =back
3793
3794 Shortcut to request a particular set of columns to be retrieved. Each
3795 column spec may be a string (a table column name), or a hash (in which
3796 case the key is the C<as> value, and the value is used as the C<select>
3797 expression). Adds C<me.> onto the start of any column without a C<.> in
3798 it and sets C<select> from that, then auto-populates C<as> from
3799 C<select> as normal. (You may also use the C<cols> attribute, as in
3800 earlier versions of DBIC.)
3801
3802 Essentially C<columns> does the same as L</select> and L</as>.
3803
3804     columns => [ 'foo', { bar => 'baz' } ]
3805
3806 is the same as
3807
3808     select => [qw/foo baz/],
3809     as => [qw/foo bar/]
3810
3811 =head2 +columns
3812
3813 =over 4
3814
3815 =item Value: \@columns
3816
3817 =back
3818
3819 Indicates additional columns to be selected from storage. Works the same
3820 as L</columns> but adds columns to the selection. (You may also use the
3821 C<include_columns> attribute, as in earlier versions of DBIC). For
3822 example:-
3823
3824   $schema->resultset('CD')->search(undef, {
3825     '+columns' => ['artist.name'],
3826     join => ['artist']
3827   });
3828
3829 would return all CDs and include a 'name' column to the information
3830 passed to object inflation. Note that the 'artist' is the name of the
3831 column (or relationship) accessor, and 'name' is the name of the column
3832 accessor in the related table.
3833
3834 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3835 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3836 unary plus operator before it.
3837
3838 =head2 include_columns
3839
3840 =over 4
3841
3842 =item Value: \@columns
3843
3844 =back
3845
3846 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3847
3848 =head2 select
3849
3850 =over 4
3851
3852 =item Value: \@select_columns
3853
3854 =back
3855
3856 Indicates which columns should be selected from the storage. You can use
3857 column names, or in the case of RDBMS back ends, function or stored procedure
3858 names:
3859
3860   $rs = $schema->resultset('Employee')->search(undef, {
3861     select => [
3862       'name',
3863       { count => 'employeeid' },
3864       { max => { length => 'name' }, -as => 'longest_name' }
3865     ]
3866   });
3867
3868   # Equivalent SQL
3869   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3870
3871 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3872 use L</select>, to instruct DBIx::Class how to store the result of the column.
3873 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3874 identifier aliasing. You can however alias a function, so you can use it in
3875 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3876 attribute> supplied as shown in the example above.
3877
3878 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3879 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3880 unary plus operator before it.
3881
3882 =head2 +select
3883
3884 =over 4
3885
3886 Indicates additional columns to be selected from storage.  Works the same as
3887 L</select> but adds columns to the default selection, instead of specifying
3888 an explicit list.
3889
3890 =back
3891
3892 =head2 +as
3893
3894 =over 4
3895
3896 Indicates additional column names for those added via L</+select>. See L</as>.
3897
3898 =back
3899
3900 =head2 as
3901
3902 =over 4
3903
3904 =item Value: \@inflation_names
3905
3906 =back
3907
3908 Indicates column names for object inflation. That is L</as> indicates the
3909 slot name in which the column value will be stored within the
3910 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3911 identifier by the C<get_column> method (or via the object accessor B<if one
3912 with the same name already exists>) as shown below. The L</as> attribute has
3913 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3914
3915   $rs = $schema->resultset('Employee')->search(undef, {
3916     select => [
3917       'name',
3918       { count => 'employeeid' },
3919       { max => { length => 'name' }, -as => 'longest_name' }
3920     ],
3921     as => [qw/
3922       name
3923       employee_count
3924       max_name_length
3925     /],
3926   });
3927
3928 If the object against which the search is performed already has an accessor
3929 matching a column name specified in C<as>, the value can be retrieved using
3930 the accessor as normal:
3931
3932   my $name = $employee->name();
3933
3934 If on the other hand an accessor does not exist in the object, you need to
3935 use C<get_column> instead:
3936
3937   my $employee_count = $employee->get_column('employee_count');
3938
3939 You can create your own accessors if required - see
3940 L<DBIx::Class::Manual::Cookbook> for details.
3941
3942 =head2 join
3943
3944 =over 4
3945
3946 =item Value: ($rel_name | \@rel_names | \%rel_names)
3947
3948 =back
3949
3950 Contains a list of relationships that should be joined for this query.  For
3951 example:
3952
3953   # Get CDs by Nine Inch Nails
3954   my $rs = $schema->resultset('CD')->search(
3955     { 'artist.name' => 'Nine Inch Nails' },
3956     { join => 'artist' }
3957   );
3958
3959 Can also contain a hash reference to refer to the other relation's relations.
3960 For example:
3961
3962   package MyApp::Schema::Track;
3963   use base qw/DBIx::Class/;
3964   __PACKAGE__->table('track');
3965   __PACKAGE__->add_columns(qw/trackid cd position title/);
3966   __PACKAGE__->set_primary_key('trackid');
3967   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3968   1;
3969
3970   # In your application
3971   my $rs = $schema->resultset('Artist')->search(
3972     { 'track.title' => 'Teardrop' },
3973     {
3974       join     => { cd => 'track' },
3975       order_by => 'artist.name',
3976     }
3977   );
3978
3979 You need to use the relationship (not the table) name in  conditions,
3980 because they are aliased as such. The current table is aliased as "me", so
3981 you need to use me.column_name in order to avoid ambiguity. For example:
3982
3983   # Get CDs from 1984 with a 'Foo' track
3984   my $rs = $schema->resultset('CD')->search(
3985     {
3986       'me.year' => 1984,
3987       'tracks.name' => 'Foo'
3988     },
3989     { join => 'tracks' }
3990   );
3991
3992 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3993 similarly for a third time). For e.g.
3994
3995   my $rs = $schema->resultset('Artist')->search({
3996     'cds.title'   => 'Down to Earth',
3997     'cds_2.title' => 'Popular',
3998   }, {
3999     join => [ qw/cds cds/ ],
4000   });
4001
4002 will return a set of all artists that have both a cd with title 'Down
4003 to Earth' and a cd with title 'Popular'.
4004
4005 If you want to fetch related objects from other tables as well, see C<prefetch>
4006 below.
4007
4008  NOTE: An internal join-chain pruner will discard certain joins while
4009  constructing the actual SQL query, as long as the joins in question do not
4010  affect the retrieved result. This for example includes 1:1 left joins
4011  that are not part of the restriction specification (WHERE/HAVING) nor are
4012  a part of the query selection.
4013
4014 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4015
4016 =head2 prefetch
4017
4018 =over 4
4019
4020 =item Value: ($rel_name | \@rel_names | \%rel_names)
4021
4022 =back
4023
4024 Contains one or more relationships that should be fetched along with
4025 the main query (when they are accessed afterwards the data will
4026 already be available, without extra queries to the database).  This is
4027 useful for when you know you will need the related objects, because it
4028 saves at least one query:
4029
4030   my $rs = $schema->resultset('Tag')->search(
4031     undef,
4032     {
4033       prefetch => {
4034         cd => 'artist'
4035       }
4036     }
4037   );
4038
4039 The initial search results in SQL like the following:
4040
4041   SELECT tag.*, cd.*, artist.* FROM tag
4042   JOIN cd ON tag.cd = cd.cdid
4043   JOIN artist ON cd.artist = artist.artistid
4044
4045 L<DBIx::Class> has no need to go back to the database when we access the
4046 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4047 case.
4048
4049 Simple prefetches will be joined automatically, so there is no need
4050 for a C<join> attribute in the above search.
4051
4052 L</prefetch> can be used with the any of the relationship types and
4053 multiple prefetches can be specified together. Below is a more complex
4054 example that prefetches a CD's artist, its liner notes (if present),
4055 the cover image, the tracks on that cd, and the guests on those
4056 tracks.
4057
4058  # Assuming:
4059  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4060  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4061  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4062  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4063
4064  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4065
4066  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4067
4068
4069  my $rs = $schema->resultset('CD')->search(
4070    undef,
4071    {
4072      prefetch => [
4073        { artist => 'record_label'},  # belongs_to => belongs_to
4074        'liner_note',                 # might_have
4075        'cover_image',                # has_one
4076        { tracks => 'guests' },       # has_many => has_many
4077      ]
4078    }
4079  );
4080
4081 This will produce SQL like the following:
4082
4083  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4084         tracks.*, guests.*
4085    FROM cd me
4086    JOIN artist artist
4087      ON artist.artistid = me.artistid
4088    JOIN record_label record_label
4089      ON record_label.labelid = artist.labelid
4090    LEFT JOIN track tracks
4091      ON tracks.cdid = me.cdid
4092    LEFT JOIN guest guests
4093      ON guests.trackid = track.trackid
4094    LEFT JOIN liner_notes liner_note
4095      ON liner_note.cdid = me.cdid
4096    JOIN cd_artwork cover_image
4097      ON cover_image.cdid = me.cdid
4098  ORDER BY tracks.cd
4099
4100 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4101 C<tracks>, and C<guests> of the CD will all be available through the
4102 relationship accessors without the need for additional queries to the
4103 database.
4104
4105 However, there is one caveat to be observed: it can be dangerous to
4106 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4107 relationship on a given level. e.g.:
4108
4109  my $rs = $schema->resultset('CD')->search(
4110    undef,
4111    {
4112      prefetch => [
4113        'tracks',                         # has_many
4114        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4115      ]
4116    }
4117  );
4118
4119 The collapser currently can't identify duplicate tuples for multiple
4120 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4121 result the second L<has_many|DBIx::Class::Relationship/has_many>
4122 relation could contain redundant objects.
4123
4124 =head3 Using L</prefetch> with L</join>
4125
4126 L</prefetch> implies a L</join> with the equivalent argument, and is
4127 properly merged with any existing L</join> specification. So the
4128 following:
4129
4130   my $rs = $schema->resultset('CD')->search(
4131    {'record_label.name' => 'Music Product Ltd.'},
4132    {
4133      join     => {artist => 'record_label'},
4134      prefetch => 'artist',
4135    }
4136  );
4137
4138 ... will work, searching on the record label's name, but only
4139 prefetching the C<artist>.
4140
4141 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4142
4143 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4144 prefetched relations.  So given:
4145
4146   my $rs = $schema->resultset('CD')->search(
4147    undef,
4148    {
4149      select   => ['cd.title'],
4150      as       => ['cd_title'],
4151      prefetch => 'artist',
4152    }
4153  );
4154
4155 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4156 becomes: C<'cd_title', 'artist.*'>.
4157
4158 =head3 CAVEATS
4159
4160 Prefetch does a lot of deep magic. As such, it may not behave exactly
4161 as you might expect.
4162
4163 =over 4
4164
4165 =item *
4166
4167 Prefetch uses the L</cache> to populate the prefetched relationships. This
4168 may or may not be what you want.
4169
4170 =item *
4171
4172 If you specify a condition on a prefetched relationship, ONLY those
4173 rows that match the prefetched condition will be fetched into that relationship.
4174 This means that adding prefetch to a search() B<may alter> what is returned by
4175 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4176
4177   my $artist_rs = $schema->resultset('Artist')->search({
4178       'cds.year' => 2008,
4179   }, {
4180       join => 'cds',
4181   });
4182
4183   my $count = $artist_rs->first->cds->count;
4184
4185   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4186
4187   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4188
4189   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4190
4191 that cmp_ok() may or may not pass depending on the datasets involved. This
4192 behavior may or may not survive the 0.09 transition.
4193
4194 =back
4195
4196 =head2 alias
4197
4198 =over 4
4199
4200 =item Value: $source_alias
4201
4202 =back
4203
4204 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4205 nested search queries (sub-SELECTs) might need specific aliases set to
4206 reference inner queries.  For example:
4207
4208    my $q = $rs
4209       ->related_resultset('CDs')
4210       ->related_resultset('Tracks')
4211       ->search({
4212          'track.id' => { -ident => 'none_search.id' },
4213       })
4214       ->as_query;
4215
4216    my $ids = $self->search({
4217       -not_exists => $q,
4218    }, {
4219       alias    => 'none_search',
4220       group_by => 'none_search.id',
4221    })->get_column('id')->as_query;
4222
4223    $self->search({ id => { -in => $ids } })
4224
4225 This attribute is directly tied to L</current_source_alias>.
4226
4227 =head2 page
4228
4229 =over 4
4230
4231 =item Value: $page
4232
4233 =back
4234
4235 Makes the resultset paged and specifies the page to retrieve. Effectively
4236 identical to creating a non-pages resultset and then calling ->page($page)
4237 on it.
4238
4239 If L</rows> attribute is not specified it defaults to 10 rows per page.
4240
4241 When you have a paged resultset, L</count> will only return the number
4242 of rows in the page. To get the total, use the L</pager> and call
4243 C<total_entries> on it.
4244
4245 =head2 rows
4246
4247 =over 4
4248
4249 =item Value: $rows
4250
4251 =back
4252
4253 Specifies the maximum number of rows for direct retrieval or the number of
4254 rows per page if the page attribute or method is used.
4255
4256 =head2 offset
4257
4258 =over 4
4259
4260 =item Value: $offset
4261
4262 =back
4263
4264 Specifies the (zero-based) row number for the  first row to be returned, or the
4265 of the first row of the first page if paging is used.
4266
4267 =head2 software_limit
4268
4269 =over 4
4270
4271 =item Value: (0 | 1)
4272
4273 =back
4274
4275 When combined with L</rows> and/or L</offset> the generated SQL will not
4276 include any limit dialect stanzas. Instead the entire result will be selected
4277 as if no limits were specified, and DBIC will perform the limit locally, by
4278 artificially advancing and finishing the resulting L</cursor>.
4279
4280 This is the recommended way of performing resultset limiting when no sane RDBMS
4281 implementation is available (e.g.
4282 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4283 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4284
4285 =head2 group_by
4286
4287 =over 4
4288
4289 =item Value: \@columns
4290
4291 =back
4292
4293 A arrayref of columns to group by. Can include columns of joined tables.
4294
4295   group_by => [qw/ column1 column2 ... /]
4296
4297 =head2 having
4298
4299 =over 4
4300
4301 =item Value: $condition
4302
4303 =back
4304
4305 HAVING is a select statement attribute that is applied between GROUP BY and
4306 ORDER BY. It is applied to the after the grouping calculations have been
4307 done.
4308
4309   having => { 'count_employee' => { '>=', 100 } }
4310
4311 or with an in-place function in which case literal SQL is required:
4312
4313   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4314
4315 =head2 distinct
4316
4317 =over 4
4318
4319 =item Value: (0 | 1)
4320
4321 =back
4322
4323 Set to 1 to group by all columns. If the resultset already has a group_by
4324 attribute, this setting is ignored and an appropriate warning is issued.
4325
4326 =head2 where
4327
4328 =over 4
4329
4330 Adds to the WHERE clause.
4331
4332   # only return rows WHERE deleted IS NULL for all searches
4333   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4334
4335 Can be overridden by passing C<< { where => undef } >> as an attribute
4336 to a resultset.
4337
4338 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4339
4340 =back
4341
4342 =head2 cache
4343
4344 Set to 1 to cache search results. This prevents extra SQL queries if you
4345 revisit rows in your ResultSet:
4346
4347   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4348
4349   while( my $artist = $resultset->next ) {
4350     ... do stuff ...
4351   }
4352
4353   $rs->first; # without cache, this would issue a query
4354
4355 By default, searches are not cached.
4356
4357 For more examples of using these attributes, see
4358 L<DBIx::Class::Manual::Cookbook>.
4359
4360 =head2 for
4361
4362 =over 4
4363
4364 =item Value: ( 'update' | 'shared' | \$scalar )
4365
4366 =back
4367
4368 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4369 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4370 query.
4371
4372 =head1 DBIC BIND VALUES
4373
4374 Because DBIC may need more information to bind values than just the column name
4375 and value itself, it uses a special format for both passing and receiving bind
4376 values.  Each bind value should be composed of an arrayref of
4377 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4378
4379 =over 4
4380
4381 =item dbd_attrs
4382
4383 If present (in any form), this is what is being passed directly to bind_param.
4384 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4385 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4386
4387 If this is specified, all other bind options described below are ignored.
4388
4389 =item sqlt_datatype
4390
4391 If present, this is used to infer the actual bind attribute by passing to
4392 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4393 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4394
4395 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4396 currently drivers are expected to "Do the Right Thing" when given a common
4397 datatype name.  (Not ideal, but that's what we got at this point.)
4398
4399 =item sqlt_size
4400
4401 Currently used to correctly allocate buffers for bind_param_inout().
4402 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4403 or to a sensible value based on the "data_type".
4404
4405 =item dbic_colname
4406
4407 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4408 explicitly specified they are never overriden).  Also used by some weird DBDs,
4409 where the column name should be available at bind_param time (e.g. Oracle).
4410
4411 =back
4412
4413 For backwards compatibility and convenience, the following shortcuts are
4414 supported:
4415
4416   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4417   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4418   [ undef,   $val ] === [ {}, $val ]
4419
4420 =head1 AUTHOR AND CONTRIBUTORS
4421
4422 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4423
4424 =head1 LICENSE
4425
4426 You may distribute this code under the same terms as Perl itself.
4427
4428 =cut
4429
4430 1;