lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360
 361   $rs->set_cache($rows) if ($rows);
 362
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   # if the first row that ever came in is totally empty - this means we got
 978   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 979   # instead of producing a {}
 980   #
 981   my $has_def;
 982   for (@$row) {
 983     if (defined $_) {
 984       $has_def++;
 985       last;
 986     }
 987   }
 988   return undef unless $has_def;
 989
 990   my @copy = @$row;
 991
 992   # 'foo'         => [ undef, 'foo' ]
 993   # 'foo.bar'     => [ 'foo', 'bar' ]
 994   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 995
 996   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 997
 998   my %collapse = %{$self->{_attrs}{collapse}||{}};
 999
1000   my @pri_index;
1001
1002   # if we're doing collapsing (has_many prefetch) we need to grab records
1003   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1004   # we know we don't have to bother.
1005
1006   # the reason for not using the collapse stuff directly is because if you
1007   # had for e.g. two artists in a row with no cds, the collapse info for
1008   # both would be NULL (undef) so you'd lose the second artist
1009
1010   # store just the index so we can check the array positions from the row
1011   # without having to contruct the full hash
1012
1013   if (keys %collapse) {
1014     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1015     foreach my $i (0 .. $#construct_as) {
1016       next if defined($construct_as[$i][0]); # only self table
1017       if (delete $pri{$construct_as[$i][1]}) {
1018         push(@pri_index, $i);
1019       }
1020       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1021     }
1022   }
1023
1024   # no need to do an if, it'll be empty if @pri_index is empty anyway
1025
1026   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1027
1028   my @const_rows;
1029
1030   do { # no need to check anything at the front, we always want the first row
1031
1032     my %const;
1033
1034     foreach my $this_as (@construct_as) {
1035       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1036     }
1037
1038     push(@const_rows, \%const);
1039
1040   } until ( # no pri_index => no collapse => drop straight out
1041       !@pri_index
1042     or
1043       do { # get another row, stash it, drop out if different PK
1044
1045         @copy = $self->cursor->next;
1046         $self->{stashed_row} = \@copy;
1047
1048         # last thing in do block, counts as true if anything doesn't match
1049
1050         # check xor defined first for NULL vs. NOT NULL then if one is
1051         # defined the other must be so check string equality
1052
1053         grep {
1054           (defined $pri_vals{$_} ^ defined $copy[$_])
1055           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1056         } @pri_index;
1057       }
1058   );
1059
1060   my $alias = $self->{attrs}{alias};
1061   my $info = [];
1062
1063   my %collapse_pos;
1064
1065   my @const_keys;
1066
1067   foreach my $const (@const_rows) {
1068     scalar @const_keys or do {
1069       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1070     };
1071     foreach my $key (@const_keys) {
1072       if (length $key) {
1073         my $target = $info;
1074         my @parts = split(/\./, $key);
1075         my $cur = '';
1076         my $data = $const->{$key};
1077         foreach my $p (@parts) {
1078           $target = $target->[1]->{$p} ||= [];
1079           $cur .= ".${p}";
1080           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1081             # collapsing at this point and on final part
1082             my $pos = $collapse_pos{$cur};
1083             CK: foreach my $ck (@ckey) {
1084               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1085                 $collapse_pos{$cur} = $data;
1086                 delete @collapse_pos{ # clear all positioning for sub-entries
1087                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1088                 };
1089                 push(@$target, []);
1090                 last CK;
1091               }
1092             }
1093           }
1094           if (exists $collapse{$cur}) {
1095             $target = $target->[-1];
1096           }
1097         }
1098         $target->[0] = $data;
1099       } else {
1100         $info->[0] = $const->{$key};
1101       }
1102     }
1103   }
1104
1105   return $info;
1106 }
1107
1108 =head2 result_source
1109
1110 =over 4
1111
1112 =item Arguments: $result_source?
1113
1114 =item Return Value: $result_source
1115
1116 =back
1117
1118 An accessor for the primary ResultSource object from which this ResultSet
1119 is derived.
1120
1121 =head2 result_class
1122
1123 =over 4
1124
1125 =item Arguments: $result_class?
1126
1127 =item Return Value: $result_class
1128
1129 =back
1130
1131 An accessor for the class to use when creating row objects. Defaults to
1132 C<< result_source->result_class >> - which in most cases is the name of the
1133 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1134
1135 Note that changing the result_class will also remove any components
1136 that were originally loaded in the source class via
1137 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1138 in the original source class will not run.
1139
1140 =cut
1141
1142 sub result_class {
1143   my ($self, $result_class) = @_;
1144   if ($result_class) {
1145     $self->ensure_class_loaded($result_class);
1146     $self->_result_class($result_class);
1147   }
1148   $self->_result_class;
1149 }
1150
1151 =head2 count
1152
1153 =over 4
1154
1155 =item Arguments: $cond, \%attrs??
1156
1157 =item Return Value: $count
1158
1159 =back
1160
1161 Performs an SQL C<COUNT> with the same query as the resultset was built
1162 with to find the number of elements. Passing arguments is equivalent to
1163 C<< $rs->search ($cond, \%attrs)->count >>
1164
1165 =cut
1166
1167 sub count {
1168   my $self = shift;
1169   return $self->search(@_)->count if @_ and defined $_[0];
1170   return scalar @{ $self->get_cache } if $self->get_cache;
1171
1172   my $attrs = $self->_resolved_attrs_copy;
1173
1174   # this is a little optimization - it is faster to do the limit
1175   # adjustments in software, instead of a subquery
1176   my $rows = delete $attrs->{rows};
1177   my $offset = delete $attrs->{offset};
1178
1179   my $crs;
1180   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1181     $crs = $self->_count_subq_rs ($attrs);
1182   }
1183   else {
1184     $crs = $self->_count_rs ($attrs);
1185   }
1186   my $count = $crs->next;
1187
1188   $count -= $offset if $offset;
1189   $count = $rows if $rows and $rows < $count;
1190   $count = 0 if ($count < 0);
1191
1192   return $count;
1193 }
1194
1195 =head2 count_rs
1196
1197 =over 4
1198
1199 =item Arguments: $cond, \%attrs??
1200
1201 =item Return Value: $count_rs
1202
1203 =back
1204
1205 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1206 This can be very handy for subqueries:
1207
1208   ->search( { amount => $some_rs->count_rs->as_query } )
1209
1210 As with regular resultsets the SQL query will be executed only after
1211 the resultset is accessed via L</next> or L</all>. That would return
1212 the same single value obtainable via L</count>.
1213
1214 =cut
1215
1216 sub count_rs {
1217   my $self = shift;
1218   return $self->search(@_)->count_rs if @_;
1219
1220   # this may look like a lack of abstraction (count() does about the same)
1221   # but in fact an _rs *must* use a subquery for the limits, as the
1222   # software based limiting can not be ported if this $rs is to be used
1223   # in a subquery itself (i.e. ->as_query)
1224   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1225     return $self->_count_subq_rs;
1226   }
1227   else {
1228     return $self->_count_rs;
1229   }
1230 }
1231
1232 #
1233 # returns a ResultSetColumn object tied to the count query
1234 #
1235 sub _count_rs {
1236   my ($self, $attrs) = @_;
1237
1238   my $rsrc = $self->result_source;
1239   $attrs ||= $self->_resolved_attrs;
1240
1241   my $tmp_attrs = { %$attrs };
1242
1243   # take off any limits, record_filter is cdbi, and no point of ordering a count
1244   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   # read the comment on top of the actual function to see what this does
1251   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1252     $tmp_attrs->{from}, $tmp_attrs->{alias}
1253   );
1254
1255   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1256
1257   return $tmp_rs;
1258 }
1259
1260 #
1261 # same as above but uses a subquery
1262 #
1263 sub _count_subq_rs {
1264   my ($self, $attrs) = @_;
1265
1266   my $rsrc = $self->result_source;
1267   $attrs ||= $self->_resolved_attrs_copy;
1268
1269   my $sub_attrs = { %$attrs };
1270
1271   # extra selectors do not go in the subquery and there is no point of ordering it
1272   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1273
1274   # if we prefetch, we group_by primary keys only as this is what we would get out
1275   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1276   if ( keys %{$attrs->{collapse}} ) {
1277     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1278   }
1279
1280   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1281
1282   # read the comment on top of the actual function to see what this does
1283   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1284     $sub_attrs->{from}, $sub_attrs->{alias}
1285   );
1286
1287   # this is so that ordering can be thrown away in things like Top limit
1288   $sub_attrs->{-for_count_only} = 1;
1289
1290   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1291
1292   $attrs->{from} = [{
1293     -alias => 'count_subq',
1294     -source_handle => $rsrc->handle,
1295     count_subq => $sub_rs->as_query,
1296   }];
1297
1298   # the subquery replaces this
1299   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1300
1301   return $self->_count_rs ($attrs);
1302 }
1303
1304
1305 # The DBIC relationship chaining implementation is pretty simple - every
1306 # new related_relationship is pushed onto the {from} stack, and the {select}
1307 # window simply slides further in. This means that when we count somewhere
1308 # in the middle, we got to make sure that everything in the join chain is an
1309 # actual inner join, otherwise the count will come back with unpredictable
1310 # results (a resultset may be generated with _some_ rows regardless of if
1311 # the relation which the $rs currently selects has rows or not). E.g.
1312 # $artist_rs->cds->count - normally generates:
1313 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1314 # which actually returns the number of artists * (number of cds || 1)
1315 #
1316 # So what we do here is crawl {from}, determine if the current alias is at
1317 # the top of the stack, and if not - make sure the chain is inner-joined down
1318 # to the root.
1319 #
1320 sub _switch_to_inner_join_if_needed {
1321   my ($self, $from, $alias) = @_;
1322
1323   # subqueries and other oddness is naturally not supported
1324   return $from if (
1325     ref $from ne 'ARRAY'
1326       ||
1327     @$from <= 1
1328       ||
1329     ref $from->[0] ne 'HASH'
1330       ||
1331     ! $from->[0]{-alias}
1332       ||
1333     $from->[0]{-alias} eq $alias
1334   );
1335
1336   my $switch_branch;
1337   JOINSCAN:
1338   for my $j (@{$from}[1 .. $#$from]) {
1339     if ($j->[0]{-alias} eq $alias) {
1340       $switch_branch = $j->[0]{-join_path};
1341       last JOINSCAN;
1342     }
1343   }
1344
1345   # something else went wrong
1346   return $from unless $switch_branch;
1347
1348   # So it looks like we will have to switch some stuff around.
1349   # local() is useless here as we will be leaving the scope
1350   # anyway, and deep cloning is just too fucking expensive
1351   # So replace the inner hashref manually
1352   my @new_from = ($from->[0]);
1353   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1354
1355   for my $j (@{$from}[1 .. $#$from]) {
1356     my $jalias = $j->[0]{-alias};
1357
1358     if ($sw_idx->{$jalias}) {
1359       my %attrs = %{$j->[0]};
1360       delete $attrs{-join_type};
1361       push @new_from, [
1362         \%attrs,
1363         @{$j}[ 1 .. $#$j ],
1364       ];
1365     }
1366     else {
1367       push @new_from, $j;
1368     }
1369   }
1370
1371   return \@new_from;
1372 }
1373
1374
1375 sub _bool {
1376   return 1;
1377 }
1378
1379 =head2 count_literal
1380
1381 =over 4
1382
1383 =item Arguments: $sql_fragment, @bind_values
1384
1385 =item Return Value: $count
1386
1387 =back
1388
1389 Counts the results in a literal query. Equivalent to calling L</search_literal>
1390 with the passed arguments, then L</count>.
1391
1392 =cut
1393
1394 sub count_literal { shift->search_literal(@_)->count; }
1395
1396 =head2 all
1397
1398 =over 4
1399
1400 =item Arguments: none
1401
1402 =item Return Value: @objects
1403
1404 =back
1405
1406 Returns all elements in the resultset. Called implicitly if the resultset
1407 is returned in list context.
1408
1409 =cut
1410
1411 sub all {
1412   my $self = shift;
1413   if(@_) {
1414       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1415   }
1416
1417   return @{ $self->get_cache } if $self->get_cache;
1418
1419   my @obj;
1420
1421   if (keys %{$self->_resolved_attrs->{collapse}}) {
1422     # Using $self->cursor->all is really just an optimisation.
1423     # If we're collapsing has_many prefetches it probably makes
1424     # very little difference, and this is cleaner than hacking
1425     # _construct_object to survive the approach
1426     $self->cursor->reset;
1427     my @row = $self->cursor->next;
1428     while (@row) {
1429       push(@obj, $self->_construct_object(@row));
1430       @row = (exists $self->{stashed_row}
1431                ? @{delete $self->{stashed_row}}
1432                : $self->cursor->next);
1433     }
1434   } else {
1435     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1436   }
1437
1438   $self->set_cache(\@obj) if $self->{attrs}{cache};
1439
1440   return @obj;
1441 }
1442
1443 =head2 reset
1444
1445 =over 4
1446
1447 =item Arguments: none
1448
1449 =item Return Value: $self
1450
1451 =back
1452
1453 Resets the resultset's cursor, so you can iterate through the elements again.
1454 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1455 another query.
1456
1457 =cut
1458
1459 sub reset {
1460   my ($self) = @_;
1461   delete $self->{_attrs} if exists $self->{_attrs};
1462   $self->{all_cache_position} = 0;
1463   $self->cursor->reset;
1464   return $self;
1465 }
1466
1467 =head2 first
1468
1469 =over 4
1470
1471 =item Arguments: none
1472
1473 =item Return Value: $object?
1474
1475 =back
1476
1477 Resets the resultset and returns an object for the first result (if the
1478 resultset returns anything).
1479
1480 =cut
1481
1482 sub first {
1483   return $_[0]->reset->next;
1484 }
1485
1486
1487 # _rs_update_delete
1488 #
1489 # Determines whether and what type of subquery is required for the $rs operation.
1490 # If grouping is necessary either supplies its own, or verifies the current one
1491 # After all is done delegates to the proper storage method.
1492
1493 sub _rs_update_delete {
1494   my ($self, $op, $values) = @_;
1495
1496   my $rsrc = $self->result_source;
1497
1498   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1499   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1500
1501   if ($needs_group_by_subq or $needs_subq) {
1502
1503     # make a new $rs selecting only the PKs (that's all we really need)
1504     my $attrs = $self->_resolved_attrs_copy;
1505
1506     delete $attrs->{$_} for qw/collapse select as/;
1507     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1508
1509     if ($needs_group_by_subq) {
1510       # make sure no group_by was supplied, or if there is one - make sure it matches
1511       # the columns compiled above perfectly. Anything else can not be sanely executed
1512       # on most databases so croak right then and there
1513
1514       if (my $g = $attrs->{group_by}) {
1515         my @current_group_by = map
1516           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1517           @$g
1518         ;
1519
1520         if (
1521           join ("\x00", sort @current_group_by)
1522             ne
1523           join ("\x00", sort @{$attrs->{columns}} )
1524         ) {
1525           $self->throw_exception (
1526             "You have just attempted a $op operation on a resultset which does group_by"
1527             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1528             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1529             . ' kind of queries. Please retry the operation with a modified group_by or'
1530             . ' without using one at all.'
1531           );
1532         }
1533       }
1534       else {
1535         $attrs->{group_by} = $attrs->{columns};
1536       }
1537     }
1538
1539     my $subrs = (ref $self)->new($rsrc, $attrs);
1540
1541     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1542   }
1543   else {
1544     return $rsrc->storage->$op(
1545       $rsrc,
1546       $op eq 'update' ? $values : (),
1547       $self->{cond},
1548     );
1549   }
1550 }
1551
1552 =head2 update
1553
1554 =over 4
1555
1556 =item Arguments: \%values
1557
1558 =item Return Value: $storage_rv
1559
1560 =back
1561
1562 Sets the specified columns in the resultset to the supplied values in a
1563 single query. Return value will be true if the update succeeded or false
1564 if no records were updated; exact type of success value is storage-dependent.
1565
1566 =cut
1567
1568 sub update {
1569   my ($self, $values) = @_;
1570   $self->throw_exception('Values for update must be a hash')
1571     unless ref $values eq 'HASH';
1572
1573   return $self->_rs_update_delete ('update', $values);
1574 }
1575
1576 =head2 update_all
1577
1578 =over 4
1579
1580 =item Arguments: \%values
1581
1582 =item Return Value: 1
1583
1584 =back
1585
1586 Fetches all objects and updates them one at a time. Note that C<update_all>
1587 will run DBIC cascade triggers, while L</update> will not.
1588
1589 =cut
1590
1591 sub update_all {
1592   my ($self, $values) = @_;
1593   $self->throw_exception('Values for update_all must be a hash')
1594     unless ref $values eq 'HASH';
1595   foreach my $obj ($self->all) {
1596     $obj->set_columns($values)->update;
1597   }
1598   return 1;
1599 }
1600
1601 =head2 delete
1602
1603 =over 4
1604
1605 =item Arguments: none
1606
1607 =item Return Value: $storage_rv
1608
1609 =back
1610
1611 Deletes the contents of the resultset from its result source. Note that this
1612 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1613 to run. See also L<DBIx::Class::Row/delete>.
1614
1615 Return value will be the amount of rows deleted; exact type of return value
1616 is storage-dependent.
1617
1618 =cut
1619
1620 sub delete {
1621   my $self = shift;
1622   $self->throw_exception('delete does not accept any arguments')
1623     if @_;
1624
1625   return $self->_rs_update_delete ('delete');
1626 }
1627
1628 =head2 delete_all
1629
1630 =over 4
1631
1632 =item Arguments: none
1633
1634 =item Return Value: 1
1635
1636 =back
1637
1638 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1639 will run DBIC cascade triggers, while L</delete> will not.
1640
1641 =cut
1642
1643 sub delete_all {
1644   my $self = shift;
1645   $self->throw_exception('delete_all does not accept any arguments')
1646     if @_;
1647
1648   $_->delete for $self->all;
1649   return 1;
1650 }
1651
1652 =head2 populate
1653
1654 =over 4
1655
1656 =item Arguments: \@data;
1657
1658 =back
1659
1660 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1661 For the arrayref of hashrefs style each hashref should be a structure suitable
1662 forsubmitting to a $resultset->create(...) method.
1663
1664 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1665 to insert the data, as this is a faster method.
1666
1667 Otherwise, each set of data is inserted into the database using
1668 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1669 accumulated into an array. The array itself, or an array reference
1670 is returned depending on scalar or list context.
1671
1672 Example:  Assuming an Artist Class that has many CDs Classes relating:
1673
1674   my $Artist_rs = $schema->resultset("Artist");
1675
1676   ## Void Context Example
1677   $Artist_rs->populate([
1678      { artistid => 4, name => 'Manufactured Crap', cds => [
1679         { title => 'My First CD', year => 2006 },
1680         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1681       ],
1682      },
1683      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1684         { title => 'My parents sold me to a record company' ,year => 2005 },
1685         { title => 'Why Am I So Ugly?', year => 2006 },
1686         { title => 'I Got Surgery and am now Popular', year => 2007 }
1687       ],
1688      },
1689   ]);
1690
1691   ## Array Context Example
1692   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1693     { name => "Artist One"},
1694     { name => "Artist Two"},
1695     { name => "Artist Three", cds=> [
1696     { title => "First CD", year => 2007},
1697     { title => "Second CD", year => 2008},
1698   ]}
1699   ]);
1700
1701   print $ArtistOne->name; ## response is 'Artist One'
1702   print $ArtistThree->cds->count ## reponse is '2'
1703
1704 For the arrayref of arrayrefs style,  the first element should be a list of the
1705 fieldsnames to which the remaining elements are rows being inserted.  For
1706 example:
1707
1708   $Arstist_rs->populate([
1709     [qw/artistid name/],
1710     [100, 'A Formally Unknown Singer'],
1711     [101, 'A singer that jumped the shark two albums ago'],
1712     [102, 'An actually cool singer.'],
1713   ]);
1714
1715 Please note an important effect on your data when choosing between void and
1716 wantarray context. Since void context goes straight to C<insert_bulk> in
1717 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1718 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1719 create primary keys for you, you will find that your PKs are empty.  In this
1720 case you will have to use the wantarray context in order to create those
1721 values.
1722
1723 =cut
1724
1725 sub populate {
1726   my $self = shift @_;
1727   my $data = ref $_[0][0] eq 'HASH'
1728     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1729     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1730
1731   if(defined wantarray) {
1732     my @created;
1733     foreach my $item (@$data) {
1734       push(@created, $self->create($item));
1735     }
1736     return wantarray ? @created : \@created;
1737   } else {
1738     my $first = $data->[0];
1739
1740     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1741     # it relationship data
1742     my (@rels, @columns);
1743     for (keys %$first) {
1744       my $ref = ref $first->{$_};
1745       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1746         ? push @rels, $_
1747         : push @columns, $_
1748       ;
1749     }
1750
1751     my @pks = $self->result_source->primary_columns;
1752
1753     ## do the belongs_to relationships
1754     foreach my $index (0..$#$data) {
1755
1756       # delegate to create() for any dataset without primary keys with specified relationships
1757       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1758         for my $r (@rels) {
1759           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1760             my @ret = $self->populate($data);
1761             return;
1762           }
1763         }
1764       }
1765
1766       foreach my $rel (@rels) {
1767         next unless ref $data->[$index]->{$rel} eq "HASH";
1768         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1769         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1770         my $related = $result->result_source->_resolve_condition(
1771           $result->result_source->relationship_info($reverse)->{cond},
1772           $self,
1773           $result,
1774         );
1775
1776         delete $data->[$index]->{$rel};
1777         $data->[$index] = {%{$data->[$index]}, %$related};
1778
1779         push @columns, keys %$related if $index == 0;
1780       }
1781     }
1782
1783     ## do bulk insert on current row
1784     $self->result_source->storage->insert_bulk(
1785       $self->result_source,
1786       \@columns,
1787       [ map { [ @$_{@columns} ] } @$data ],
1788     );
1789
1790     ## do the has_many relationships
1791     foreach my $item (@$data) {
1792
1793       foreach my $rel (@rels) {
1794         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1795
1796         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1797      || $self->throw_exception('Cannot find the relating object.');
1798
1799         my $child = $parent->$rel;
1800
1801         my $related = $child->result_source->_resolve_condition(
1802           $parent->result_source->relationship_info($rel)->{cond},
1803           $child,
1804           $parent,
1805         );
1806
1807         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1808         my @populate = map { {%$_, %$related} } @rows_to_add;
1809
1810         $child->populate( \@populate );
1811       }
1812     }
1813   }
1814 }
1815
1816 =head2 _normalize_populate_args ($args)
1817
1818 Private method used by L</populate> to normalize its incoming arguments.  Factored
1819 out in case you want to subclass and accept new argument structures to the
1820 L</populate> method.
1821
1822 =cut
1823
1824 sub _normalize_populate_args {
1825   my ($self, $data) = @_;
1826   my @names = @{shift(@$data)};
1827   my @results_to_create;
1828   foreach my $datum (@$data) {
1829     my %result_to_create;
1830     foreach my $index (0..$#names) {
1831       $result_to_create{$names[$index]} = $$datum[$index];
1832     }
1833     push @results_to_create, \%result_to_create;
1834   }
1835   return \@results_to_create;
1836 }
1837
1838 =head2 pager
1839
1840 =over 4
1841
1842 =item Arguments: none
1843
1844 =item Return Value: $pager
1845
1846 =back
1847
1848 Return Value a L<Data::Page> object for the current resultset. Only makes
1849 sense for queries with a C<page> attribute.
1850
1851 To get the full count of entries for a paged resultset, call
1852 C<total_entries> on the L<Data::Page> object.
1853
1854 =cut
1855
1856 sub pager {
1857   my ($self) = @_;
1858
1859   return $self->{pager} if $self->{pager};
1860
1861   my $attrs = $self->{attrs};
1862   $self->throw_exception("Can't create pager for non-paged rs")
1863     unless $self->{attrs}{page};
1864   $attrs->{rows} ||= 10;
1865
1866   # throw away the paging flags and re-run the count (possibly
1867   # with a subselect) to get the real total count
1868   my $count_attrs = { %$attrs };
1869   delete $count_attrs->{$_} for qw/rows offset page pager/;
1870   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1871
1872   return $self->{pager} = Data::Page->new(
1873     $total_count,
1874     $attrs->{rows},
1875     $self->{attrs}{page}
1876   );
1877 }
1878
1879 =head2 page
1880
1881 =over 4
1882
1883 =item Arguments: $page_number
1884
1885 =item Return Value: $rs
1886
1887 =back
1888
1889 Returns a resultset for the $page_number page of the resultset on which page
1890 is called, where each page contains a number of rows equal to the 'rows'
1891 attribute set on the resultset (10 by default).
1892
1893 =cut
1894
1895 sub page {
1896   my ($self, $page) = @_;
1897   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1898 }
1899
1900 =head2 new_result
1901
1902 =over 4
1903
1904 =item Arguments: \%vals
1905
1906 =item Return Value: $rowobject
1907
1908 =back
1909
1910 Creates a new row object in the resultset's result class and returns
1911 it. The row is not inserted into the database at this point, call
1912 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1913 will tell you whether the row object has been inserted or not.
1914
1915 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1916
1917 =cut
1918
1919 sub new_result {
1920   my ($self, $values) = @_;
1921   $self->throw_exception( "new_result needs a hash" )
1922     unless (ref $values eq 'HASH');
1923
1924   my %new;
1925   my $alias = $self->{attrs}{alias};
1926
1927   if (
1928     defined $self->{cond}
1929     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1930   ) {
1931     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1932     $new{-from_resultset} = [ keys %new ] if keys %new;
1933   } else {
1934     $self->throw_exception(
1935       "Can't abstract implicit construct, condition not a hash"
1936     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1937
1938     my $collapsed_cond = (
1939       $self->{cond}
1940         ? $self->_collapse_cond($self->{cond})
1941         : {}
1942     );
1943
1944     # precendence must be given to passed values over values inherited from
1945     # the cond, so the order here is important.
1946     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1947     while( my($col,$value) = each %implied ){
1948       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1949         $new{$col} = $value->{'='};
1950         next;
1951       }
1952       $new{$col} = $value if $self->_is_deterministic_value($value);
1953     }
1954   }
1955
1956   %new = (
1957     %new,
1958     %{ $self->_remove_alias($values, $alias) },
1959     -source_handle => $self->_source_handle,
1960     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1961   );
1962
1963   return $self->result_class->new(\%new);
1964 }
1965
1966 # _is_deterministic_value
1967 #
1968 # Make an effor to strip non-deterministic values from the condition,
1969 # to make sure new_result chokes less
1970
1971 sub _is_deterministic_value {
1972   my $self = shift;
1973   my $value = shift;
1974   my $ref_type = ref $value;
1975   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1976   return 1 if Scalar::Util::blessed($value);
1977   return 0;
1978 }
1979
1980 # _has_resolved_attr
1981 #
1982 # determines if the resultset defines at least one
1983 # of the attributes supplied
1984 #
1985 # used to determine if a subquery is neccessary
1986 #
1987 # supports some virtual attributes:
1988 #   -join
1989 #     This will scan for any joins being present on the resultset.
1990 #     It is not a mere key-search but a deep inspection of {from}
1991 #
1992
1993 sub _has_resolved_attr {
1994   my ($self, @attr_names) = @_;
1995
1996   my $attrs = $self->_resolved_attrs;
1997
1998   my %extra_checks;
1999
2000   for my $n (@attr_names) {
2001     if (grep { $n eq $_ } (qw/-join/) ) {
2002       $extra_checks{$n}++;
2003       next;
2004     }
2005
2006     my $attr =  $attrs->{$n};
2007
2008     next if not defined $attr;
2009
2010     if (ref $attr eq 'HASH') {
2011       return 1 if keys %$attr;
2012     }
2013     elsif (ref $attr eq 'ARRAY') {
2014       return 1 if @$attr;
2015     }
2016     else {
2017       return 1 if $attr;
2018     }
2019   }
2020
2021   # a resolved join is expressed as a multi-level from
2022   return 1 if (
2023     $extra_checks{-join}
2024       and
2025     ref $attrs->{from} eq 'ARRAY'
2026       and
2027     @{$attrs->{from}} > 1
2028   );
2029
2030   return 0;
2031 }
2032
2033 # _collapse_cond
2034 #
2035 # Recursively collapse the condition.
2036
2037 sub _collapse_cond {
2038   my ($self, $cond, $collapsed) = @_;
2039
2040   $collapsed ||= {};
2041
2042   if (ref $cond eq 'ARRAY') {
2043     foreach my $subcond (@$cond) {
2044       next unless ref $subcond;  # -or
2045       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2046     }
2047   }
2048   elsif (ref $cond eq 'HASH') {
2049     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2050       foreach my $subcond (@{$cond->{-and}}) {
2051         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2052       }
2053     }
2054     else {
2055       foreach my $col (keys %$cond) {
2056         my $value = $cond->{$col};
2057         $collapsed->{$col} = $value;
2058       }
2059     }
2060   }
2061
2062   return $collapsed;
2063 }
2064
2065 # _remove_alias
2066 #
2067 # Remove the specified alias from the specified query hash. A copy is made so
2068 # the original query is not modified.
2069
2070 sub _remove_alias {
2071   my ($self, $query, $alias) = @_;
2072
2073   my %orig = %{ $query || {} };
2074   my %unaliased;
2075
2076   foreach my $key (keys %orig) {
2077     if ($key !~ /\./) {
2078       $unaliased{$key} = $orig{$key};
2079       next;
2080     }
2081     $unaliased{$1} = $orig{$key}
2082       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2083   }
2084
2085   return \%unaliased;
2086 }
2087
2088 =head2 as_query (EXPERIMENTAL)
2089
2090 =over 4
2091
2092 =item Arguments: none
2093
2094 =item Return Value: \[ $sql, @bind ]
2095
2096 =back
2097
2098 Returns the SQL query and bind vars associated with the invocant.
2099
2100 This is generally used as the RHS for a subquery.
2101
2102 B<NOTE>: This feature is still experimental.
2103
2104 =cut
2105
2106 sub as_query {
2107   my $self = shift;
2108
2109   my $attrs = $self->_resolved_attrs_copy;
2110
2111   # For future use:
2112   #
2113   # in list ctx:
2114   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2115   # $sql also has no wrapping parenthesis in list ctx
2116   #
2117   my $sqlbind = $self->result_source->storage
2118     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2119
2120   return $sqlbind;
2121 }
2122
2123 =head2 find_or_new
2124
2125 =over 4
2126
2127 =item Arguments: \%vals, \%attrs?
2128
2129 =item Return Value: $rowobject
2130
2131 =back
2132
2133   my $artist = $schema->resultset('Artist')->find_or_new(
2134     { artist => 'fred' }, { key => 'artists' });
2135
2136   $cd->cd_to_producer->find_or_new({ producer => $producer },
2137                                    { key => 'primary });
2138
2139 Find an existing record from this resultset, based on its primary
2140 key, or a unique constraint. If none exists, instantiate a new result
2141 object and return it. The object will not be saved into your storage
2142 until you call L<DBIx::Class::Row/insert> on it.
2143
2144 You most likely want this method when looking for existing rows using
2145 a unique constraint that is not the primary key, or looking for
2146 related rows.
2147
2148 If you want objects to be saved immediately, use L</find_or_create>
2149 instead.
2150
2151 B<Note>: Take care when using C<find_or_new> with a table having
2152 columns with default values that you intend to be automatically
2153 supplied by the database (e.g. an auto_increment primary key column).
2154 In normal usage, the value of such columns should NOT be included at
2155 all in the call to C<find_or_new>, even when set to C<undef>.
2156
2157 =cut
2158
2159 sub find_or_new {
2160   my $self     = shift;
2161   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2162   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2163   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2164     return $row;
2165   }
2166   return $self->new_result($hash);
2167 }
2168
2169 =head2 create
2170
2171 =over 4
2172
2173 =item Arguments: \%vals
2174
2175 =item Return Value: a L<DBIx::Class::Row> $object
2176
2177 =back
2178
2179 Attempt to create a single new row or a row with multiple related rows
2180 in the table represented by the resultset (and related tables). This
2181 will not check for duplicate rows before inserting, use
2182 L</find_or_create> to do that.
2183
2184 To create one row for this resultset, pass a hashref of key/value
2185 pairs representing the columns of the table and the values you wish to
2186 store. If the appropriate relationships are set up, foreign key fields
2187 can also be passed an object representing the foreign row, and the
2188 value will be set to its primary key.
2189
2190 To create related objects, pass a hashref of related-object column values
2191 B<keyed on the relationship name>. If the relationship is of type C<multi>
2192 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2193 The process will correctly identify columns holding foreign keys, and will
2194 transparrently populate them from the keys of the corresponding relation.
2195 This can be applied recursively, and will work correctly for a structure
2196 with an arbitrary depth and width, as long as the relationships actually
2197 exists and the correct column data has been supplied.
2198
2199
2200 Instead of hashrefs of plain related data (key/value pairs), you may
2201 also pass new or inserted objects. New objects (not inserted yet, see
2202 L</new>), will be inserted into their appropriate tables.
2203
2204 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2205
2206 Example of creating a new row.
2207
2208   $person_rs->create({
2209     name=>"Some Person",
2210     email=>"somebody@someplace.com"
2211   });
2212
2213 Example of creating a new row and also creating rows in a related C<has_many>
2214 or C<has_one> resultset.  Note Arrayref.
2215
2216   $artist_rs->create(
2217      { artistid => 4, name => 'Manufactured Crap', cds => [
2218         { title => 'My First CD', year => 2006 },
2219         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2220       ],
2221      },
2222   );
2223
2224 Example of creating a new row and also creating a row in a related
2225 C<belongs_to>resultset. Note Hashref.
2226
2227   $cd_rs->create({
2228     title=>"Music for Silly Walks",
2229     year=>2000,
2230     artist => {
2231       name=>"Silly Musician",
2232     }
2233   });
2234
2235 =over
2236
2237 =item WARNING
2238
2239 When subclassing ResultSet never attempt to override this method. Since
2240 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2241 lot of the internals simply never call it, so your override will be
2242 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2243 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2244 L</create> process you need to intervene.
2245
2246 =back
2247
2248 =cut
2249
2250 sub create {
2251   my ($self, $attrs) = @_;
2252   $self->throw_exception( "create needs a hashref" )
2253     unless ref $attrs eq 'HASH';
2254   return $self->new_result($attrs)->insert;
2255 }
2256
2257 =head2 find_or_create
2258
2259 =over 4
2260
2261 =item Arguments: \%vals, \%attrs?
2262
2263 =item Return Value: $rowobject
2264
2265 =back
2266
2267   $cd->cd_to_producer->find_or_create({ producer => $producer },
2268                                       { key => 'primary' });
2269
2270 Tries to find a record based on its primary key or unique constraints; if none
2271 is found, creates one and returns that instead.
2272
2273   my $cd = $schema->resultset('CD')->find_or_create({
2274     cdid   => 5,
2275     artist => 'Massive Attack',
2276     title  => 'Mezzanine',
2277     year   => 2005,
2278   });
2279
2280 Also takes an optional C<key> attribute, to search by a specific key or unique
2281 constraint. For example:
2282
2283   my $cd = $schema->resultset('CD')->find_or_create(
2284     {
2285       artist => 'Massive Attack',
2286       title  => 'Mezzanine',
2287     },
2288     { key => 'cd_artist_title' }
2289   );
2290
2291 B<Note>: Because find_or_create() reads from the database and then
2292 possibly inserts based on the result, this method is subject to a race
2293 condition. Another process could create a record in the table after
2294 the find has completed and before the create has started. To avoid
2295 this problem, use find_or_create() inside a transaction.
2296
2297 B<Note>: Take care when using C<find_or_create> with a table having
2298 columns with default values that you intend to be automatically
2299 supplied by the database (e.g. an auto_increment primary key column).
2300 In normal usage, the value of such columns should NOT be included at
2301 all in the call to C<find_or_create>, even when set to C<undef>.
2302
2303 See also L</find> and L</update_or_create>. For information on how to declare
2304 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2305
2306 =cut
2307
2308 sub find_or_create {
2309   my $self     = shift;
2310   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2311   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2312   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2313     return $row;
2314   }
2315   return $self->create($hash);
2316 }
2317
2318 =head2 update_or_create
2319
2320 =over 4
2321
2322 =item Arguments: \%col_values, { key => $unique_constraint }?
2323
2324 =item Return Value: $rowobject
2325
2326 =back
2327
2328   $resultset->update_or_create({ col => $val, ... });
2329
2330 First, searches for an existing row matching one of the unique constraints
2331 (including the primary key) on the source of this resultset. If a row is
2332 found, updates it with the other given column values. Otherwise, creates a new
2333 row.
2334
2335 Takes an optional C<key> attribute to search on a specific unique constraint.
2336 For example:
2337
2338   # In your application
2339   my $cd = $schema->resultset('CD')->update_or_create(
2340     {
2341       artist => 'Massive Attack',
2342       title  => 'Mezzanine',
2343       year   => 1998,
2344     },
2345     { key => 'cd_artist_title' }
2346   );
2347
2348   $cd->cd_to_producer->update_or_create({
2349     producer => $producer,
2350     name => 'harry',
2351   }, {
2352     key => 'primary,
2353   });
2354
2355
2356 If no C<key> is specified, it searches on all unique constraints defined on the
2357 source, including the primary key.
2358
2359 If the C<key> is specified as C<primary>, it searches only on the primary key.
2360
2361 See also L</find> and L</find_or_create>. For information on how to declare
2362 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2363
2364 B<Note>: Take care when using C<update_or_create> with a table having
2365 columns with default values that you intend to be automatically
2366 supplied by the database (e.g. an auto_increment primary key column).
2367 In normal usage, the value of such columns should NOT be included at
2368 all in the call to C<update_or_create>, even when set to C<undef>.
2369
2370 =cut
2371
2372 sub update_or_create {
2373   my $self = shift;
2374   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2375   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2376
2377   my $row = $self->find($cond, $attrs);
2378   if (defined $row) {
2379     $row->update($cond);
2380     return $row;
2381   }
2382
2383   return $self->create($cond);
2384 }
2385
2386 =head2 update_or_new
2387
2388 =over 4
2389
2390 =item Arguments: \%col_values, { key => $unique_constraint }?
2391
2392 =item Return Value: $rowobject
2393
2394 =back
2395
2396   $resultset->update_or_new({ col => $val, ... });
2397
2398 First, searches for an existing row matching one of the unique constraints
2399 (including the primary key) on the source of this resultset. If a row is
2400 found, updates it with the other given column values. Otherwise, instantiate
2401 a new result object and return it. The object will not be saved into your storage
2402 until you call L<DBIx::Class::Row/insert> on it.
2403
2404 Takes an optional C<key> attribute to search on a specific unique constraint.
2405 For example:
2406
2407   # In your application
2408   my $cd = $schema->resultset('CD')->update_or_new(
2409     {
2410       artist => 'Massive Attack',
2411       title  => 'Mezzanine',
2412       year   => 1998,
2413     },
2414     { key => 'cd_artist_title' }
2415   );
2416
2417   if ($cd->in_storage) {
2418       # the cd was updated
2419   }
2420   else {
2421       # the cd is not yet in the database, let's insert it
2422       $cd->insert;
2423   }
2424
2425 B<Note>: Take care when using C<update_or_new> with a table having
2426 columns with default values that you intend to be automatically
2427 supplied by the database (e.g. an auto_increment primary key column).
2428 In normal usage, the value of such columns should NOT be included at
2429 all in the call to C<update_or_new>, even when set to C<undef>.
2430
2431 See also L</find>, L</find_or_create> and L</find_or_new>.
2432
2433 =cut
2434
2435 sub update_or_new {
2436     my $self  = shift;
2437     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2438     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2439
2440     my $row = $self->find( $cond, $attrs );
2441     if ( defined $row ) {
2442         $row->update($cond);
2443         return $row;
2444     }
2445
2446     return $self->new_result($cond);
2447 }
2448
2449 =head2 get_cache
2450
2451 =over 4
2452
2453 =item Arguments: none
2454
2455 =item Return Value: \@cache_objects?
2456
2457 =back
2458
2459 Gets the contents of the cache for the resultset, if the cache is set.
2460
2461 The cache is populated either by using the L</prefetch> attribute to
2462 L</search> or by calling L</set_cache>.
2463
2464 =cut
2465
2466 sub get_cache {
2467   shift->{all_cache};
2468 }
2469
2470 =head2 set_cache
2471
2472 =over 4
2473
2474 =item Arguments: \@cache_objects
2475
2476 =item Return Value: \@cache_objects
2477
2478 =back
2479
2480 Sets the contents of the cache for the resultset. Expects an arrayref
2481 of objects of the same class as those produced by the resultset. Note that
2482 if the cache is set the resultset will return the cached objects rather
2483 than re-querying the database even if the cache attr is not set.
2484
2485 The contents of the cache can also be populated by using the
2486 L</prefetch> attribute to L</search>.
2487
2488 =cut
2489
2490 sub set_cache {
2491   my ( $self, $data ) = @_;
2492   $self->throw_exception("set_cache requires an arrayref")
2493       if defined($data) && (ref $data ne 'ARRAY');
2494   $self->{all_cache} = $data;
2495 }
2496
2497 =head2 clear_cache
2498
2499 =over 4
2500
2501 =item Arguments: none
2502
2503 =item Return Value: []
2504
2505 =back
2506
2507 Clears the cache for the resultset.
2508
2509 =cut
2510
2511 sub clear_cache {
2512   shift->set_cache(undef);
2513 }
2514
2515 =head2 is_paged
2516
2517 =over 4
2518
2519 =item Arguments: none
2520
2521 =item Return Value: true, if the resultset has been paginated
2522
2523 =back
2524
2525 =cut
2526
2527 sub is_paged {
2528   my ($self) = @_;
2529   return !!$self->{attrs}{page};
2530 }
2531
2532 =head2 related_resultset
2533
2534 =over 4
2535
2536 =item Arguments: $relationship_name
2537
2538 =item Return Value: $resultset
2539
2540 =back
2541
2542 Returns a related resultset for the supplied relationship name.
2543
2544   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2545
2546 =cut
2547
2548 sub related_resultset {
2549   my ($self, $rel) = @_;
2550
2551   $self->{related_resultsets} ||= {};
2552   return $self->{related_resultsets}{$rel} ||= do {
2553     my $rel_info = $self->result_source->relationship_info($rel);
2554
2555     $self->throw_exception(
2556       "search_related: result source '" . $self->result_source->source_name .
2557         "' has no such relationship $rel")
2558       unless $rel_info;
2559
2560     my ($from,$seen) = $self->_chain_relationship($rel);
2561
2562     my $join_count = $seen->{$rel};
2563     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2564
2565     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2566     my %attrs = %{$self->{attrs}||{}};
2567     delete @attrs{qw(result_class alias)};
2568
2569     my $new_cache;
2570
2571     if (my $cache = $self->get_cache) {
2572       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2573         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2574                         @$cache ];
2575       }
2576     }
2577
2578     my $rel_source = $self->result_source->related_source($rel);
2579
2580     my $new = do {
2581
2582       # The reason we do this now instead of passing the alias to the
2583       # search_rs below is that if you wrap/overload resultset on the
2584       # source you need to know what alias it's -going- to have for things
2585       # to work sanely (e.g. RestrictWithObject wants to be able to add
2586       # extra query restrictions, and these may need to be $alias.)
2587
2588       my $attrs = $rel_source->resultset_attributes;
2589       local $attrs->{alias} = $alias;
2590
2591       $rel_source->resultset
2592                  ->search_rs(
2593                      undef, {
2594                        %attrs,
2595                        join => undef,
2596                        prefetch => undef,
2597                        select => undef,
2598                        as => undef,
2599                        where => $self->{cond},
2600                        seen_join => $seen,
2601                        from => $from,
2602                    });
2603     };
2604     $new->set_cache($new_cache) if $new_cache;
2605     $new;
2606   };
2607 }
2608
2609 =head2 current_source_alias
2610
2611 =over 4
2612
2613 =item Arguments: none
2614
2615 =item Return Value: $source_alias
2616
2617 =back
2618
2619 Returns the current table alias for the result source this resultset is built
2620 on, that will be used in the SQL query. Usually it is C<me>.
2621
2622 Currently the source alias that refers to the result set returned by a
2623 L</search>/L</find> family method depends on how you got to the resultset: it's
2624 C<me> by default, but eg. L</search_related> aliases it to the related result
2625 source name (and keeps C<me> referring to the original result set). The long
2626 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2627 (and make this method unnecessary).
2628
2629 Thus it's currently necessary to use this method in predefined queries (see
2630 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2631 source alias of the current result set:
2632
2633   # in a result set class
2634   sub modified_by {
2635     my ($self, $user) = @_;
2636
2637     my $me = $self->current_source_alias;
2638
2639     return $self->search(
2640       "$me.modified" => $user->id,
2641     );
2642   }
2643
2644 =cut
2645
2646 sub current_source_alias {
2647   my ($self) = @_;
2648
2649   return ($self->{attrs} || {})->{alias} || 'me';
2650 }
2651
2652 # This code is called by search_related, and makes sure there
2653 # is clear separation between the joins before, during, and
2654 # after the relationship. This information is needed later
2655 # in order to properly resolve prefetch aliases (any alias
2656 # with a relation_chain_depth less than the depth of the
2657 # current prefetch is not considered)
2658 #
2659 # The increments happen in 1/2s to make it easier to correlate the
2660 # join depth with the join path. An integer means a relationship
2661 # specified via a search_related, whereas a fraction means an added
2662 # join/prefetch via attributes
2663 sub _chain_relationship {
2664   my ($self, $rel) = @_;
2665   my $source = $self->result_source;
2666   my $attrs = $self->{attrs};
2667
2668   my $from = [ @{
2669       $attrs->{from}
2670         ||
2671       [{
2672         -source_handle => $source->handle,
2673         -alias => $attrs->{alias},
2674         $attrs->{alias} => $source->from,
2675       }]
2676   }];
2677
2678   my $seen = { %{$attrs->{seen_join} || {} } };
2679   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2680     ? $from->[-1][0]{-join_path}
2681     : [];
2682
2683
2684   # we need to take the prefetch the attrs into account before we
2685   # ->_resolve_join as otherwise they get lost - captainL
2686   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2687
2688   my @requested_joins = $source->_resolve_join(
2689     $merged,
2690     $attrs->{alias},
2691     $seen,
2692     $jpath,
2693   );
2694
2695   push @$from, @requested_joins;
2696
2697   $seen->{-relation_chain_depth} += 0.5;
2698
2699   # if $self already had a join/prefetch specified on it, the requested
2700   # $rel might very well be already included. What we do in this case
2701   # is effectively a no-op (except that we bump up the chain_depth on
2702   # the join in question so we could tell it *is* the search_related)
2703   my $already_joined;
2704
2705
2706   # we consider the last one thus reverse
2707   for my $j (reverse @requested_joins) {
2708     if ($rel eq $j->[0]{-join_path}[-1]) {
2709       $j->[0]{-relation_chain_depth} += 0.5;
2710       $already_joined++;
2711       last;
2712     }
2713   }
2714
2715 # alternative way to scan the entire chain - not backwards compatible
2716 #  for my $j (reverse @$from) {
2717 #    next unless ref $j eq 'ARRAY';
2718 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2719 #      $j->[0]{-relation_chain_depth} += 0.5;
2720 #      $already_joined++;
2721 #      last;
2722 #    }
2723 #  }
2724
2725   unless ($already_joined) {
2726     push @$from, $source->_resolve_join(
2727       $rel,
2728       $attrs->{alias},
2729       $seen,
2730       $jpath,
2731     );
2732   }
2733
2734   $seen->{-relation_chain_depth} += 0.5;
2735
2736   return ($from,$seen);
2737 }
2738
2739 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2740 sub _resolved_attrs_copy {
2741   my $self = shift;
2742   return { %{$self->_resolved_attrs (@_)} };
2743 }
2744
2745 sub _resolved_attrs {
2746   my $self = shift;
2747   return $self->{_attrs} if $self->{_attrs};
2748
2749   my $attrs  = { %{ $self->{attrs} || {} } };
2750   my $source = $self->result_source;
2751   my $alias  = $attrs->{alias};
2752
2753   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2754   my @colbits;
2755
2756   # build columns (as long as select isn't set) into a set of as/select hashes
2757   unless ( $attrs->{select} ) {
2758
2759     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2760       ? @{ delete $attrs->{columns}}
2761       : (
2762           ( delete $attrs->{columns} )
2763             ||
2764           $source->columns
2765         )
2766     ;
2767
2768     @colbits = map {
2769       ( ref($_) eq 'HASH' )
2770       ? $_
2771       : {
2772           (
2773             /^\Q${alias}.\E(.+)$/
2774               ? "$1"
2775               : "$_"
2776           )
2777             =>
2778           (
2779             /\./
2780               ? "$_"
2781               : "${alias}.$_"
2782           )
2783         }
2784     } @cols;
2785   }
2786
2787   # add the additional columns on
2788   foreach ( 'include_columns', '+columns' ) {
2789       push @colbits, map {
2790           ( ref($_) eq 'HASH' )
2791             ? $_
2792             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2793       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2794   }
2795
2796   # start with initial select items
2797   if ( $attrs->{select} ) {
2798     $attrs->{select} =
2799         ( ref $attrs->{select} eq 'ARRAY' )
2800       ? [ @{ $attrs->{select} } ]
2801       : [ $attrs->{select} ];
2802     $attrs->{as} = (
2803       $attrs->{as}
2804       ? (
2805         ref $attrs->{as} eq 'ARRAY'
2806         ? [ @{ $attrs->{as} } ]
2807         : [ $attrs->{as} ]
2808         )
2809       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2810     );
2811   }
2812   else {
2813
2814     # otherwise we intialise select & as to empty
2815     $attrs->{select} = [];
2816     $attrs->{as}     = [];
2817   }
2818
2819   # now add colbits to select/as
2820   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2821   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2822
2823   my $adds;
2824   if ( $adds = delete $attrs->{'+select'} ) {
2825     $adds = [$adds] unless ref $adds eq 'ARRAY';
2826     push(
2827       @{ $attrs->{select} },
2828       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2829     );
2830   }
2831   if ( $adds = delete $attrs->{'+as'} ) {
2832     $adds = [$adds] unless ref $adds eq 'ARRAY';
2833     push( @{ $attrs->{as} }, @$adds );
2834   }
2835
2836   $attrs->{from} ||= [ {
2837     -source_handle => $source->handle,
2838     -alias => $self->{attrs}{alias},
2839     $self->{attrs}{alias} => $source->from,
2840   } ];
2841
2842   if ( $attrs->{join} || $attrs->{prefetch} ) {
2843
2844     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2845       if ref $attrs->{from} ne 'ARRAY';
2846
2847     my $join = delete $attrs->{join} || {};
2848
2849     if ( defined $attrs->{prefetch} ) {
2850       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2851     }
2852
2853     $attrs->{from} =    # have to copy here to avoid corrupting the original
2854       [
2855         @{ $attrs->{from} },
2856         $source->_resolve_join(
2857           $join,
2858           $alias,
2859           { %{ $attrs->{seen_join} || {} } },
2860           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2861             ? $attrs->{from}[-1][0]{-join_path}
2862             : []
2863           ,
2864         )
2865       ];
2866   }
2867
2868   if ( defined $attrs->{order_by} ) {
2869     $attrs->{order_by} = (
2870       ref( $attrs->{order_by} ) eq 'ARRAY'
2871       ? [ @{ $attrs->{order_by} } ]
2872       : [ $attrs->{order_by} || () ]
2873     );
2874   }
2875
2876   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2877     $attrs->{group_by} = [ $attrs->{group_by} ];
2878   }
2879
2880   # generate the distinct induced group_by early, as prefetch will be carried via a
2881   # subquery (since a group_by is present)
2882   if (delete $attrs->{distinct}) {
2883     if ($attrs->{group_by}) {
2884       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2885     }
2886     else {
2887       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2888     }
2889   }
2890
2891   $attrs->{collapse} ||= {};
2892   if ( my $prefetch = delete $attrs->{prefetch} ) {
2893     $prefetch = $self->_merge_attr( {}, $prefetch );
2894
2895     my $prefetch_ordering = [];
2896
2897     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2898
2899     my @prefetch =
2900       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2901
2902     # we need to somehow mark which columns came from prefetch
2903     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2904
2905     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2906     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2907
2908     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2909     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2910   }
2911
2912   # if both page and offset are specified, produce a combined offset
2913   # even though it doesn't make much sense, this is what pre 081xx has
2914   # been doing
2915   if (my $page = delete $attrs->{page}) {
2916     $attrs->{offset} =
2917       ($attrs->{rows} * ($page - 1))
2918             +
2919       ($attrs->{offset} || 0)
2920     ;
2921   }
2922
2923   return $self->{_attrs} = $attrs;
2924 }
2925
2926 sub _joinpath_aliases {
2927   my ($self, $fromspec, $seen) = @_;
2928
2929   my $paths = {};
2930   return $paths unless ref $fromspec eq 'ARRAY';
2931
2932   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2933
2934   if (int ($cur_depth) != $cur_depth) {
2935     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2936   }
2937
2938   for my $j (@$fromspec) {
2939
2940     next if ref $j ne 'ARRAY';
2941     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2942
2943     my $jpath = $j->[0]{-join_path};
2944
2945     my $p = $paths;
2946     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2947     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2948   }
2949
2950   return $paths;
2951 }
2952
2953 sub _rollout_attr {
2954   my ($self, $attr) = @_;
2955
2956   if (ref $attr eq 'HASH') {
2957     return $self->_rollout_hash($attr);
2958   } elsif (ref $attr eq 'ARRAY') {
2959     return $self->_rollout_array($attr);
2960   } else {
2961     return [$attr];
2962   }
2963 }
2964
2965 sub _rollout_array {
2966   my ($self, $attr) = @_;
2967
2968   my @rolled_array;
2969   foreach my $element (@{$attr}) {
2970     if (ref $element eq 'HASH') {
2971       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2972     } elsif (ref $element eq 'ARRAY') {
2973       #  XXX - should probably recurse here
2974       push( @rolled_array, @{$self->_rollout_array($element)} );
2975     } else {
2976       push( @rolled_array, $element );
2977     }
2978   }
2979   return \@rolled_array;
2980 }
2981
2982 sub _rollout_hash {
2983   my ($self, $attr) = @_;
2984
2985   my @rolled_array;
2986   foreach my $key (keys %{$attr}) {
2987     push( @rolled_array, { $key => $attr->{$key} } );
2988   }
2989   return \@rolled_array;
2990 }
2991
2992 sub _calculate_score {
2993   my ($self, $a, $b) = @_;
2994
2995   if (defined $a xor defined $b) {
2996     return 0;
2997   }
2998   elsif (not defined $a) {
2999     return 1;
3000   }
3001
3002   if (ref $b eq 'HASH') {
3003     my ($b_key) = keys %{$b};
3004     if (ref $a eq 'HASH') {
3005       my ($a_key) = keys %{$a};
3006       if ($a_key eq $b_key) {
3007         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3008       } else {
3009         return 0;
3010       }
3011     } else {
3012       return ($a eq $b_key) ? 1 : 0;
3013     }
3014   } else {
3015     if (ref $a eq 'HASH') {
3016       my ($a_key) = keys %{$a};
3017       return ($b eq $a_key) ? 1 : 0;
3018     } else {
3019       return ($b eq $a) ? 1 : 0;
3020     }
3021   }
3022 }
3023
3024 sub _merge_attr {
3025   my ($self, $orig, $import) = @_;
3026
3027   return $import unless defined($orig);
3028   return $orig unless defined($import);
3029
3030   $orig = $self->_rollout_attr($orig);
3031   $import = $self->_rollout_attr($import);
3032
3033   my $seen_keys;
3034   foreach my $import_element ( @{$import} ) {
3035     # find best candidate from $orig to merge $b_element into
3036     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3037     foreach my $orig_element ( @{$orig} ) {
3038       my $score = $self->_calculate_score( $orig_element, $import_element );
3039       if ($score > $best_candidate->{score}) {
3040         $best_candidate->{position} = $position;
3041         $best_candidate->{score} = $score;
3042       }
3043       $position++;
3044     }
3045     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3046
3047     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3048       push( @{$orig}, $import_element );
3049     } else {
3050       my $orig_best = $orig->[$best_candidate->{position}];
3051       # merge orig_best and b_element together and replace original with merged
3052       if (ref $orig_best ne 'HASH') {
3053         $orig->[$best_candidate->{position}] = $import_element;
3054       } elsif (ref $import_element eq 'HASH') {
3055         my ($key) = keys %{$orig_best};
3056         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3057       }
3058     }
3059     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3060   }
3061
3062   return $orig;
3063 }
3064
3065 sub result_source {
3066     my $self = shift;
3067
3068     if (@_) {
3069         $self->_source_handle($_[0]->handle);
3070     } else {
3071         $self->_source_handle->resolve;
3072     }
3073 }
3074
3075 =head2 throw_exception
3076
3077 See L<DBIx::Class::Schema/throw_exception> for details.
3078
3079 =cut
3080
3081 sub throw_exception {
3082   my $self=shift;
3083
3084   if (ref $self && $self->_source_handle->schema) {
3085     $self->_source_handle->schema->throw_exception(@_)
3086   }
3087   else {
3088     DBIx::Class::Exception->throw(@_);
3089   }
3090 }
3091
3092 # XXX: FIXME: Attributes docs need clearing up
3093
3094 =head1 ATTRIBUTES
3095
3096 Attributes are used to refine a ResultSet in various ways when
3097 searching for data. They can be passed to any method which takes an
3098 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3099 L</count>.
3100
3101 These are in no particular order:
3102
3103 =head2 order_by
3104
3105 =over 4
3106
3107 =item Value: ( $order_by | \@order_by | \%order_by )
3108
3109 =back
3110
3111 Which column(s) to order the results by.
3112
3113 [The full list of suitable values is documented in
3114 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3115 common options.]
3116
3117 If a single column name, or an arrayref of names is supplied, the
3118 argument is passed through directly to SQL. The hashref syntax allows
3119 for connection-agnostic specification of ordering direction:
3120
3121  For descending order:
3122
3123   order_by => { -desc => [qw/col1 col2 col3/] }
3124
3125  For explicit ascending order:
3126
3127   order_by => { -asc => 'col' }
3128
3129 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3130 supported, although you are strongly encouraged to use the hashref
3131 syntax as outlined above.
3132
3133 =head2 columns
3134
3135 =over 4
3136
3137 =item Value: \@columns
3138
3139 =back
3140
3141 Shortcut to request a particular set of columns to be retrieved. Each
3142 column spec may be a string (a table column name), or a hash (in which
3143 case the key is the C<as> value, and the value is used as the C<select>
3144 expression). Adds C<me.> onto the start of any column without a C<.> in
3145 it and sets C<select> from that, then auto-populates C<as> from
3146 C<select> as normal. (You may also use the C<cols> attribute, as in
3147 earlier versions of DBIC.)
3148
3149 =head2 +columns
3150
3151 =over 4
3152
3153 =item Value: \@columns
3154
3155 =back
3156
3157 Indicates additional columns to be selected from storage. Works the same
3158 as L</columns> but adds columns to the selection. (You may also use the
3159 C<include_columns> attribute, as in earlier versions of DBIC). For
3160 example:-
3161
3162   $schema->resultset('CD')->search(undef, {
3163     '+columns' => ['artist.name'],
3164     join => ['artist']
3165   });
3166
3167 would return all CDs and include a 'name' column to the information
3168 passed to object inflation. Note that the 'artist' is the name of the
3169 column (or relationship) accessor, and 'name' is the name of the column
3170 accessor in the related table.
3171
3172 =head2 include_columns
3173
3174 =over 4
3175
3176 =item Value: \@columns
3177
3178 =back
3179
3180 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3181
3182 =head2 select
3183
3184 =over 4
3185
3186 =item Value: \@select_columns
3187
3188 =back
3189
3190 Indicates which columns should be selected from the storage. You can use
3191 column names, or in the case of RDBMS back ends, function or stored procedure
3192 names:
3193
3194   $rs = $schema->resultset('Employee')->search(undef, {
3195     select => [
3196       'name',
3197       { count => 'employeeid' },
3198       { sum => 'salary' }
3199     ]
3200   });
3201
3202 When you use function/stored procedure names and do not supply an C<as>
3203 attribute, the column names returned are storage-dependent. E.g. MySQL would
3204 return a column named C<count(employeeid)> in the above example.
3205
3206 B<NOTE:> You will almost always need a corresponding 'as' entry when you use
3207 'select'.
3208
3209 =head2 +select
3210
3211 =over 4
3212
3213 Indicates additional columns to be selected from storage.  Works the same as
3214 L</select> but adds columns to the selection.
3215
3216 =back
3217
3218 =head2 +as
3219
3220 =over 4
3221
3222 Indicates additional column names for those added via L</+select>. See L</as>.
3223
3224 =back
3225
3226 =head2 as
3227
3228 =over 4
3229
3230 =item Value: \@inflation_names
3231
3232 =back
3233
3234 Indicates column names for object inflation. That is, C<as>
3235 indicates the name that the column can be accessed as via the
3236 C<get_column> method (or via the object accessor, B<if one already
3237 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3238
3239 The C<as> attribute is used in conjunction with C<select>,
3240 usually when C<select> contains one or more function or stored
3241 procedure names:
3242
3243   $rs = $schema->resultset('Employee')->search(undef, {
3244     select => [
3245       'name',
3246       { count => 'employeeid' }
3247     ],
3248     as => ['name', 'employee_count'],
3249   });
3250
3251   my $employee = $rs->first(); # get the first Employee
3252
3253 If the object against which the search is performed already has an accessor
3254 matching a column name specified in C<as>, the value can be retrieved using
3255 the accessor as normal:
3256
3257   my $name = $employee->name();
3258
3259 If on the other hand an accessor does not exist in the object, you need to
3260 use C<get_column> instead:
3261
3262   my $employee_count = $employee->get_column('employee_count');
3263
3264 You can create your own accessors if required - see
3265 L<DBIx::Class::Manual::Cookbook> for details.
3266
3267 Please note: This will NOT insert an C<AS employee_count> into the SQL
3268 statement produced, it is used for internal access only. Thus
3269 attempting to use the accessor in an C<order_by> clause or similar
3270 will fail miserably.
3271
3272 To get around this limitation, you can supply literal SQL to your
3273 C<select> attibute that contains the C<AS alias> text, eg:
3274
3275   select => [\'myfield AS alias']
3276
3277 =head2 join
3278
3279 =over 4
3280
3281 =item Value: ($rel_name | \@rel_names | \%rel_names)
3282
3283 =back
3284
3285 Contains a list of relationships that should be joined for this query.  For
3286 example:
3287
3288   # Get CDs by Nine Inch Nails
3289   my $rs = $schema->resultset('CD')->search(
3290     { 'artist.name' => 'Nine Inch Nails' },
3291     { join => 'artist' }
3292   );
3293
3294 Can also contain a hash reference to refer to the other relation's relations.
3295 For example:
3296
3297   package MyApp::Schema::Track;
3298   use base qw/DBIx::Class/;
3299   __PACKAGE__->table('track');
3300   __PACKAGE__->add_columns(qw/trackid cd position title/);
3301   __PACKAGE__->set_primary_key('trackid');
3302   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3303   1;
3304
3305   # In your application
3306   my $rs = $schema->resultset('Artist')->search(
3307     { 'track.title' => 'Teardrop' },
3308     {
3309       join     => { cd => 'track' },
3310       order_by => 'artist.name',
3311     }
3312   );
3313
3314 You need to use the relationship (not the table) name in  conditions,
3315 because they are aliased as such. The current table is aliased as "me", so
3316 you need to use me.column_name in order to avoid ambiguity. For example:
3317
3318   # Get CDs from 1984 with a 'Foo' track
3319   my $rs = $schema->resultset('CD')->search(
3320     {
3321       'me.year' => 1984,
3322       'tracks.name' => 'Foo'
3323     },
3324     { join => 'tracks' }
3325   );
3326
3327 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3328 similarly for a third time). For e.g.
3329
3330   my $rs = $schema->resultset('Artist')->search({
3331     'cds.title'   => 'Down to Earth',
3332     'cds_2.title' => 'Popular',
3333   }, {
3334     join => [ qw/cds cds/ ],
3335   });
3336
3337 will return a set of all artists that have both a cd with title 'Down
3338 to Earth' and a cd with title 'Popular'.
3339
3340 If you want to fetch related objects from other tables as well, see C<prefetch>
3341 below.
3342
3343 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3344
3345 =head2 prefetch
3346
3347 =over 4
3348
3349 =item Value: ($rel_name | \@rel_names | \%rel_names)
3350
3351 =back
3352
3353 Contains one or more relationships that should be fetched along with
3354 the main query (when they are accessed afterwards the data will
3355 already be available, without extra queries to the database).  This is
3356 useful for when you know you will need the related objects, because it
3357 saves at least one query:
3358
3359   my $rs = $schema->resultset('Tag')->search(
3360     undef,
3361     {
3362       prefetch => {
3363         cd => 'artist'
3364       }
3365     }
3366   );
3367
3368 The initial search results in SQL like the following:
3369
3370   SELECT tag.*, cd.*, artist.* FROM tag
3371   JOIN cd ON tag.cd = cd.cdid
3372   JOIN artist ON cd.artist = artist.artistid
3373
3374 L<DBIx::Class> has no need to go back to the database when we access the
3375 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3376 case.
3377
3378 Simple prefetches will be joined automatically, so there is no need
3379 for a C<join> attribute in the above search.
3380
3381 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3382 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3383 with an accessor type of 'single' or 'filter'). A more complex example that
3384 prefetches an artists cds, the tracks on those cds, and the tags associted
3385 with that artist is given below (assuming many-to-many from artists to tags):
3386
3387  my $rs = $schema->resultset('Artist')->search(
3388    undef,
3389    {
3390      prefetch => [
3391        { cds => 'tracks' },
3392        { artist_tags => 'tags' }
3393      ]
3394    }
3395  );
3396
3397
3398 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3399 attributes will be ignored.
3400
3401 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3402 exactly as you might expect.
3403
3404 =over 4
3405
3406 =item *
3407
3408 Prefetch uses the L</cache> to populate the prefetched relationships. This
3409 may or may not be what you want.
3410
3411 =item *
3412
3413 If you specify a condition on a prefetched relationship, ONLY those
3414 rows that match the prefetched condition will be fetched into that relationship.
3415 This means that adding prefetch to a search() B<may alter> what is returned by
3416 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3417
3418   my $artist_rs = $schema->resultset('Artist')->search({
3419       'cds.year' => 2008,
3420   }, {
3421       join => 'cds',
3422   });
3423
3424   my $count = $artist_rs->first->cds->count;
3425
3426   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3427
3428   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3429
3430   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3431
3432 that cmp_ok() may or may not pass depending on the datasets involved. This
3433 behavior may or may not survive the 0.09 transition.
3434
3435 =back
3436
3437 =head2 page
3438
3439 =over 4
3440
3441 =item Value: $page
3442
3443 =back
3444
3445 Makes the resultset paged and specifies the page to retrieve. Effectively
3446 identical to creating a non-pages resultset and then calling ->page($page)
3447 on it.
3448
3449 If L<rows> attribute is not specified it defaults to 10 rows per page.
3450
3451 When you have a paged resultset, L</count> will only return the number
3452 of rows in the page. To get the total, use the L</pager> and call
3453 C<total_entries> on it.
3454
3455 =head2 rows
3456
3457 =over 4
3458
3459 =item Value: $rows
3460
3461 =back
3462
3463 Specifes the maximum number of rows for direct retrieval or the number of
3464 rows per page if the page attribute or method is used.
3465
3466 =head2 offset
3467
3468 =over 4
3469
3470 =item Value: $offset
3471
3472 =back
3473
3474 Specifies the (zero-based) row number for the  first row to be returned, or the
3475 of the first row of the first page if paging is used.
3476
3477 =head2 group_by
3478
3479 =over 4
3480
3481 =item Value: \@columns
3482
3483 =back
3484
3485 A arrayref of columns to group by. Can include columns of joined tables.
3486
3487   group_by => [qw/ column1 column2 ... /]
3488
3489 =head2 having
3490
3491 =over 4
3492
3493 =item Value: $condition
3494
3495 =back
3496
3497 HAVING is a select statement attribute that is applied between GROUP BY and
3498 ORDER BY. It is applied to the after the grouping calculations have been
3499 done.
3500
3501   having => { 'count(employee)' => { '>=', 100 } }
3502
3503 =head2 distinct
3504
3505 =over 4
3506
3507 =item Value: (0 | 1)
3508
3509 =back
3510
3511 Set to 1 to group by all columns. If the resultset already has a group_by
3512 attribute, this setting is ignored and an appropriate warning is issued.
3513
3514 =head2 where
3515
3516 =over 4
3517
3518 Adds to the WHERE clause.
3519
3520   # only return rows WHERE deleted IS NULL for all searches
3521   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3522
3523 Can be overridden by passing C<< { where => undef } >> as an attribute
3524 to a resultset.
3525
3526 =back
3527
3528 =head2 cache
3529
3530 Set to 1 to cache search results. This prevents extra SQL queries if you
3531 revisit rows in your ResultSet:
3532
3533   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3534
3535   while( my $artist = $resultset->next ) {
3536     ... do stuff ...
3537   }
3538
3539   $rs->first; # without cache, this would issue a query
3540
3541 By default, searches are not cached.
3542
3543 For more examples of using these attributes, see
3544 L<DBIx::Class::Manual::Cookbook>.
3545
3546 =head2 for
3547
3548 =over 4
3549
3550 =item Value: ( 'update' | 'shared' )
3551
3552 =back
3553
3554 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3555 ... FOR SHARED.
3556
3557 =cut
3558
3559 1;