lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960
 961   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 962     or return ();
 963   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 964   @new = $self->{_attrs}{record_filter}->(@new)
 965     if exists $self->{_attrs}{record_filter};
 966   return @new;
 967 }
 968
 969 sub _collapse_result {
 970   my ($self, $as_proto, $row) = @_;
 971
 972   # if the first row that ever came in is totally empty - this means we got
 973   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 974   # instead of producing a {}
 975   #
 976   # Note the double-defined - $row may be [ 0, '' ]
 977   #
 978   return undef unless ( defined List::Util::first { defined $_ } (@$row) );
 979
 980   my @copy = @$row;
 981
 982   # 'foo'         => [ undef, 'foo' ]
 983   # 'foo.bar'     => [ 'foo', 'bar' ]
 984   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 985
 986   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 987
 988   my %collapse = %{$self->{_attrs}{collapse}||{}};
 989
 990   my @pri_index;
 991
 992   # if we're doing collapsing (has_many prefetch) we need to grab records
 993   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 994   # we know we don't have to bother.
 995
 996   # the reason for not using the collapse stuff directly is because if you
 997   # had for e.g. two artists in a row with no cds, the collapse info for
 998   # both would be NULL (undef) so you'd lose the second artist
 999
1000   # store just the index so we can check the array positions from the row
1001   # without having to contruct the full hash
1002
1003   if (keys %collapse) {
1004     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1005     foreach my $i (0 .. $#construct_as) {
1006       next if defined($construct_as[$i][0]); # only self table
1007       if (delete $pri{$construct_as[$i][1]}) {
1008         push(@pri_index, $i);
1009       }
1010       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1011     }
1012   }
1013
1014   # no need to do an if, it'll be empty if @pri_index is empty anyway
1015
1016   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1017
1018   my @const_rows;
1019
1020   do { # no need to check anything at the front, we always want the first row
1021
1022     my %const;
1023
1024     foreach my $this_as (@construct_as) {
1025       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1026     }
1027
1028     push(@const_rows, \%const);
1029
1030   } until ( # no pri_index => no collapse => drop straight out
1031       !@pri_index
1032     or
1033       do { # get another row, stash it, drop out if different PK
1034
1035         @copy = $self->cursor->next;
1036         $self->{stashed_row} = \@copy;
1037
1038         # last thing in do block, counts as true if anything doesn't match
1039
1040         # check xor defined first for NULL vs. NOT NULL then if one is
1041         # defined the other must be so check string equality
1042
1043         grep {
1044           (defined $pri_vals{$_} ^ defined $copy[$_])
1045           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1046         } @pri_index;
1047       }
1048   );
1049
1050   my $alias = $self->{attrs}{alias};
1051   my $info = [];
1052
1053   my %collapse_pos;
1054
1055   my @const_keys;
1056
1057   foreach my $const (@const_rows) {
1058     scalar @const_keys or do {
1059       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1060     };
1061     foreach my $key (@const_keys) {
1062       if (length $key) {
1063         my $target = $info;
1064         my @parts = split(/\./, $key);
1065         my $cur = '';
1066         my $data = $const->{$key};
1067         foreach my $p (@parts) {
1068           $target = $target->[1]->{$p} ||= [];
1069           $cur .= ".${p}";
1070           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1071             # collapsing at this point and on final part
1072             my $pos = $collapse_pos{$cur};
1073             CK: foreach my $ck (@ckey) {
1074               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1075                 $collapse_pos{$cur} = $data;
1076                 delete @collapse_pos{ # clear all positioning for sub-entries
1077                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1078                 };
1079                 push(@$target, []);
1080                 last CK;
1081               }
1082             }
1083           }
1084           if (exists $collapse{$cur}) {
1085             $target = $target->[-1];
1086           }
1087         }
1088         $target->[0] = $data;
1089       } else {
1090         $info->[0] = $const->{$key};
1091       }
1092     }
1093   }
1094
1095   return $info;
1096 }
1097
1098 =head2 result_source
1099
1100 =over 4
1101
1102 =item Arguments: $result_source?
1103
1104 =item Return Value: $result_source
1105
1106 =back
1107
1108 An accessor for the primary ResultSource object from which this ResultSet
1109 is derived.
1110
1111 =head2 result_class
1112
1113 =over 4
1114
1115 =item Arguments: $result_class?
1116
1117 =item Return Value: $result_class
1118
1119 =back
1120
1121 An accessor for the class to use when creating row objects. Defaults to
1122 C<< result_source->result_class >> - which in most cases is the name of the
1123 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1124
1125 Note that changing the result_class will also remove any components
1126 that were originally loaded in the source class via
1127 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1128 in the original source class will not run.
1129
1130 =cut
1131
1132 sub result_class {
1133   my ($self, $result_class) = @_;
1134   if ($result_class) {
1135     $self->ensure_class_loaded($result_class);
1136     $self->_result_class($result_class);
1137   }
1138   $self->_result_class;
1139 }
1140
1141 =head2 count
1142
1143 =over 4
1144
1145 =item Arguments: $cond, \%attrs??
1146
1147 =item Return Value: $count
1148
1149 =back
1150
1151 Performs an SQL C<COUNT> with the same query as the resultset was built
1152 with to find the number of elements. Passing arguments is equivalent to
1153 C<< $rs->search ($cond, \%attrs)->count >>
1154
1155 =cut
1156
1157 sub count {
1158   my $self = shift;
1159   return $self->search(@_)->count if @_ and defined $_[0];
1160   return scalar @{ $self->get_cache } if $self->get_cache;
1161
1162   my $attrs = $self->_resolved_attrs_copy;
1163
1164   # this is a little optimization - it is faster to do the limit
1165   # adjustments in software, instead of a subquery
1166   my $rows = delete $attrs->{rows};
1167   my $offset = delete $attrs->{offset};
1168
1169   my $crs;
1170   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1171     $crs = $self->_count_subq_rs ($attrs);
1172   }
1173   else {
1174     $crs = $self->_count_rs ($attrs);
1175   }
1176   my $count = $crs->next;
1177
1178   $count -= $offset if $offset;
1179   $count = $rows if $rows and $rows < $count;
1180   $count = 0 if ($count < 0);
1181
1182   return $count;
1183 }
1184
1185 =head2 count_rs
1186
1187 =over 4
1188
1189 =item Arguments: $cond, \%attrs??
1190
1191 =item Return Value: $count_rs
1192
1193 =back
1194
1195 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1196 This can be very handy for subqueries:
1197
1198   ->search( { amount => $some_rs->count_rs->as_query } )
1199
1200 As with regular resultsets the SQL query will be executed only after
1201 the resultset is accessed via L</next> or L</all>. That would return
1202 the same single value obtainable via L</count>.
1203
1204 =cut
1205
1206 sub count_rs {
1207   my $self = shift;
1208   return $self->search(@_)->count_rs if @_;
1209
1210   # this may look like a lack of abstraction (count() does about the same)
1211   # but in fact an _rs *must* use a subquery for the limits, as the
1212   # software based limiting can not be ported if this $rs is to be used
1213   # in a subquery itself (i.e. ->as_query)
1214   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1215     return $self->_count_subq_rs;
1216   }
1217   else {
1218     return $self->_count_rs;
1219   }
1220 }
1221
1222 #
1223 # returns a ResultSetColumn object tied to the count query
1224 #
1225 sub _count_rs {
1226   my ($self, $attrs) = @_;
1227
1228   my $rsrc = $self->result_source;
1229   $attrs ||= $self->_resolved_attrs;
1230
1231   my $tmp_attrs = { %$attrs };
1232
1233   # take off any limits, record_filter is cdbi, and no point of ordering a count
1234   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1235
1236   # overwrite the selector (supplied by the storage)
1237   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1238   $tmp_attrs->{as} = 'count';
1239
1240   # read the comment on top of the actual function to see what this does
1241   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1242     $tmp_attrs->{from}, $tmp_attrs->{alias}
1243   );
1244
1245   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1246
1247   return $tmp_rs;
1248 }
1249
1250 #
1251 # same as above but uses a subquery
1252 #
1253 sub _count_subq_rs {
1254   my ($self, $attrs) = @_;
1255
1256   my $rsrc = $self->result_source;
1257   $attrs ||= $self->_resolved_attrs_copy;
1258
1259   my $sub_attrs = { %$attrs };
1260
1261   # extra selectors do not go in the subquery and there is no point of ordering it
1262   delete $sub_attrs->{$_} for qw/collapse prefetch_select select as order_by/;
1263
1264   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1265   # clobber old group_by regardless
1266   if ( keys %{$attrs->{collapse}} ) {
1267     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1268   }
1269
1270   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1271
1272   # read the comment on top of the actual function to see what this does
1273   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1274     $sub_attrs->{from}, $sub_attrs->{alias}
1275   );
1276
1277   $attrs->{from} = [{
1278     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1279   }];
1280
1281   # the subquery replaces this
1282   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1283
1284   return $self->_count_rs ($attrs);
1285 }
1286
1287
1288 # The DBIC relationship chaining implementation is pretty simple - every
1289 # new related_relationship is pushed onto the {from} stack, and the {select}
1290 # window simply slides further in. This means that when we count somewhere
1291 # in the middle, we got to make sure that everything in the join chain is an
1292 # actual inner join, otherwise the count will come back with unpredictable
1293 # results (a resultset may be generated with _some_ rows regardless of if
1294 # the relation which the $rs currently selects has rows or not). E.g.
1295 # $artist_rs->cds->count - normally generates:
1296 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1297 # which actually returns the number of artists * (number of cds || 1)
1298 #
1299 # So what we do here is crawl {from}, determine if the current alias is at
1300 # the top of the stack, and if not - make sure the chain is inner-joined down
1301 # to the root.
1302 #
1303 sub _switch_to_inner_join_if_needed {
1304   my ($self, $from, $alias) = @_;
1305
1306   return $from if (
1307     ref $from ne 'ARRAY'
1308       ||
1309     ref $from->[0] ne 'HASH'
1310       ||
1311     ! $from->[0]{-alias}
1312       ||
1313     $from->[0]{-alias} eq $alias
1314   );
1315
1316   # this would be the case with a subquery - we'll never find
1317   # the target as it is not in the parseable part of {from}
1318   return $from if @$from == 1;
1319
1320   my (@switch_idx, $found_target);
1321
1322   JOINSCAN:
1323   for my $i (1 .. $#$from) {
1324
1325     push @switch_idx, $i;
1326     my $j = $from->[$i];
1327     my $jalias = $j->[0]{-alias};
1328
1329     # we found our current target - delete any siblings (same level joins)
1330     # and bail out
1331     if ($jalias eq $alias) {
1332       $found_target++;
1333
1334       my $cur_depth = $j->[0]{-relation_chain_depth};
1335       # we are -1, so look at -2
1336       while (@switch_idx > 1
1337               && $from->[$switch_idx[-2]][0]{-relation_chain_depth} == $cur_depth
1338       ) {
1339         splice @switch_idx, -2, 1;
1340       }
1341
1342       last JOINSCAN;
1343     }
1344   }
1345
1346   # something else went wrong
1347   return $from unless $found_target;
1348
1349   # So it looks like we will have to switch some stuff around.
1350   # local() is useless here as we will be leaving the scope
1351   # anyway, and deep cloning is just too fucking expensive
1352   # So replace the inner hashref manually
1353   my @new_from;
1354   my $sw_idx = { map { $_ => 1 } @switch_idx };
1355
1356   for my $i (0 .. $#$from) {
1357     if ($sw_idx->{$i}) {
1358       my %attrs = %{$from->[$i][0]};
1359       delete $attrs{-join_type};
1360
1361       push @new_from, [
1362         \%attrs,
1363         @{$from->[$i]}[ 1 .. $#{$from->[$i]} ],
1364       ];
1365     }
1366     else {
1367       push @new_from, $from->[$i];
1368     }
1369   }
1370
1371   return \@new_from;
1372 }
1373
1374
1375 sub _bool {
1376   return 1;
1377 }
1378
1379 =head2 count_literal
1380
1381 =over 4
1382
1383 =item Arguments: $sql_fragment, @bind_values
1384
1385 =item Return Value: $count
1386
1387 =back
1388
1389 Counts the results in a literal query. Equivalent to calling L</search_literal>
1390 with the passed arguments, then L</count>.
1391
1392 =cut
1393
1394 sub count_literal { shift->search_literal(@_)->count; }
1395
1396 =head2 all
1397
1398 =over 4
1399
1400 =item Arguments: none
1401
1402 =item Return Value: @objects
1403
1404 =back
1405
1406 Returns all elements in the resultset. Called implicitly if the resultset
1407 is returned in list context.
1408
1409 =cut
1410
1411 sub all {
1412   my $self = shift;
1413   if(@_) {
1414       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1415   }
1416
1417   return @{ $self->get_cache } if $self->get_cache;
1418
1419   my @obj;
1420
1421   if (keys %{$self->_resolved_attrs->{collapse}}) {
1422     # Using $self->cursor->all is really just an optimisation.
1423     # If we're collapsing has_many prefetches it probably makes
1424     # very little difference, and this is cleaner than hacking
1425     # _construct_object to survive the approach
1426     $self->cursor->reset;
1427     my @row = $self->cursor->next;
1428     while (@row) {
1429       push(@obj, $self->_construct_object(@row));
1430       @row = (exists $self->{stashed_row}
1431                ? @{delete $self->{stashed_row}}
1432                : $self->cursor->next);
1433     }
1434   } else {
1435     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1436   }
1437
1438   $self->set_cache(\@obj) if $self->{attrs}{cache};
1439
1440   return @obj;
1441 }
1442
1443 =head2 reset
1444
1445 =over 4
1446
1447 =item Arguments: none
1448
1449 =item Return Value: $self
1450
1451 =back
1452
1453 Resets the resultset's cursor, so you can iterate through the elements again.
1454 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1455 another query.
1456
1457 =cut
1458
1459 sub reset {
1460   my ($self) = @_;
1461   delete $self->{_attrs} if exists $self->{_attrs};
1462   $self->{all_cache_position} = 0;
1463   $self->cursor->reset;
1464   return $self;
1465 }
1466
1467 =head2 first
1468
1469 =over 4
1470
1471 =item Arguments: none
1472
1473 =item Return Value: $object?
1474
1475 =back
1476
1477 Resets the resultset and returns an object for the first result (if the
1478 resultset returns anything).
1479
1480 =cut
1481
1482 sub first {
1483   return $_[0]->reset->next;
1484 }
1485
1486
1487 # _rs_update_delete
1488 #
1489 # Determines whether and what type of subquery is required for the $rs operation.
1490 # If grouping is necessary either supplies its own, or verifies the current one
1491 # After all is done delegates to the proper storage method.
1492
1493 sub _rs_update_delete {
1494   my ($self, $op, $values) = @_;
1495
1496   my $rsrc = $self->result_source;
1497
1498   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1499   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1500
1501   if ($needs_group_by_subq or $needs_subq) {
1502
1503     # make a new $rs selecting only the PKs (that's all we really need)
1504     my $attrs = $self->_resolved_attrs_copy;
1505
1506     delete $attrs->{$_} for qw/collapse select as/;
1507     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1508
1509     if ($needs_group_by_subq) {
1510       # make sure no group_by was supplied, or if there is one - make sure it matches
1511       # the columns compiled above perfectly. Anything else can not be sanely executed
1512       # on most databases so croak right then and there
1513
1514       if (my $g = $attrs->{group_by}) {
1515         my @current_group_by = map
1516           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1517           (ref $g eq 'ARRAY' ? @$g : $g );
1518
1519         if (
1520           join ("\x00", sort @current_group_by)
1521             ne
1522           join ("\x00", sort @{$attrs->{columns}} )
1523         ) {
1524           $self->throw_exception (
1525             "You have just attempted a $op operation on a resultset which does group_by"
1526             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1527             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1528             . ' kind of queries. Please retry the operation with a modified group_by or'
1529             . ' without using one at all.'
1530           );
1531         }
1532       }
1533       else {
1534         $attrs->{group_by} = $attrs->{columns};
1535       }
1536     }
1537
1538     my $subrs = (ref $self)->new($rsrc, $attrs);
1539
1540     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1541   }
1542   else {
1543     return $rsrc->storage->$op(
1544       $rsrc,
1545       $op eq 'update' ? $values : (),
1546       $self->_cond_for_update_delete,
1547     );
1548   }
1549 }
1550
1551
1552 # _cond_for_update_delete
1553 #
1554 # update/delete require the condition to be modified to handle
1555 # the differing SQL syntax available.  This transforms the $self->{cond}
1556 # appropriately, returning the new condition.
1557
1558 sub _cond_for_update_delete {
1559   my ($self, $full_cond) = @_;
1560   my $cond = {};
1561
1562   $full_cond ||= $self->{cond};
1563   # No-op. No condition, we're updating/deleting everything
1564   return $cond unless ref $full_cond;
1565
1566   if (ref $full_cond eq 'ARRAY') {
1567     $cond = [
1568       map {
1569         my %hash;
1570         foreach my $key (keys %{$_}) {
1571           $key =~ /([^.]+)$/;
1572           $hash{$1} = $_->{$key};
1573         }
1574         \%hash;
1575       } @{$full_cond}
1576     ];
1577   }
1578   elsif (ref $full_cond eq 'HASH') {
1579     if ((keys %{$full_cond})[0] eq '-and') {
1580       $cond->{-and} = [];
1581       my @cond = @{$full_cond->{-and}};
1582        for (my $i = 0; $i < @cond; $i++) {
1583         my $entry = $cond[$i];
1584         my $hash;
1585         if (ref $entry eq 'HASH') {
1586           $hash = $self->_cond_for_update_delete($entry);
1587         }
1588         else {
1589           $entry =~ /([^.]+)$/;
1590           $hash->{$1} = $cond[++$i];
1591         }
1592         push @{$cond->{-and}}, $hash;
1593       }
1594     }
1595     else {
1596       foreach my $key (keys %{$full_cond}) {
1597         $key =~ /([^.]+)$/;
1598         $cond->{$1} = $full_cond->{$key};
1599       }
1600     }
1601   }
1602   else {
1603     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1604   }
1605
1606   return $cond;
1607 }
1608
1609
1610 =head2 update
1611
1612 =over 4
1613
1614 =item Arguments: \%values
1615
1616 =item Return Value: $storage_rv
1617
1618 =back
1619
1620 Sets the specified columns in the resultset to the supplied values in a
1621 single query. Return value will be true if the update succeeded or false
1622 if no records were updated; exact type of success value is storage-dependent.
1623
1624 =cut
1625
1626 sub update {
1627   my ($self, $values) = @_;
1628   $self->throw_exception('Values for update must be a hash')
1629     unless ref $values eq 'HASH';
1630
1631   return $self->_rs_update_delete ('update', $values);
1632 }
1633
1634 =head2 update_all
1635
1636 =over 4
1637
1638 =item Arguments: \%values
1639
1640 =item Return Value: 1
1641
1642 =back
1643
1644 Fetches all objects and updates them one at a time. Note that C<update_all>
1645 will run DBIC cascade triggers, while L</update> will not.
1646
1647 =cut
1648
1649 sub update_all {
1650   my ($self, $values) = @_;
1651   $self->throw_exception('Values for update_all must be a hash')
1652     unless ref $values eq 'HASH';
1653   foreach my $obj ($self->all) {
1654     $obj->set_columns($values)->update;
1655   }
1656   return 1;
1657 }
1658
1659 =head2 delete
1660
1661 =over 4
1662
1663 =item Arguments: none
1664
1665 =item Return Value: $storage_rv
1666
1667 =back
1668
1669 Deletes the contents of the resultset from its result source. Note that this
1670 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1671 to run. See also L<DBIx::Class::Row/delete>.
1672
1673 Return value will be the amount of rows deleted; exact type of return value
1674 is storage-dependent.
1675
1676 =cut
1677
1678 sub delete {
1679   my $self = shift;
1680   $self->throw_exception('delete does not accept any arguments')
1681     if @_;
1682
1683   return $self->_rs_update_delete ('delete');
1684 }
1685
1686 =head2 delete_all
1687
1688 =over 4
1689
1690 =item Arguments: none
1691
1692 =item Return Value: 1
1693
1694 =back
1695
1696 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1697 will run DBIC cascade triggers, while L</delete> will not.
1698
1699 =cut
1700
1701 sub delete_all {
1702   my $self = shift;
1703   $self->throw_exception('delete_all does not accept any arguments')
1704     if @_;
1705
1706   $_->delete for $self->all;
1707   return 1;
1708 }
1709
1710 =head2 populate
1711
1712 =over 4
1713
1714 =item Arguments: \@data;
1715
1716 =back
1717
1718 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1719 For the arrayref of hashrefs style each hashref should be a structure suitable
1720 forsubmitting to a $resultset->create(...) method.
1721
1722 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1723 to insert the data, as this is a faster method.
1724
1725 Otherwise, each set of data is inserted into the database using
1726 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1727 accumulated into an array. The array itself, or an array reference
1728 is returned depending on scalar or list context.
1729
1730 Example:  Assuming an Artist Class that has many CDs Classes relating:
1731
1732   my $Artist_rs = $schema->resultset("Artist");
1733
1734   ## Void Context Example
1735   $Artist_rs->populate([
1736      { artistid => 4, name => 'Manufactured Crap', cds => [
1737         { title => 'My First CD', year => 2006 },
1738         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1739       ],
1740      },
1741      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1742         { title => 'My parents sold me to a record company' ,year => 2005 },
1743         { title => 'Why Am I So Ugly?', year => 2006 },
1744         { title => 'I Got Surgery and am now Popular', year => 2007 }
1745       ],
1746      },
1747   ]);
1748
1749   ## Array Context Example
1750   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1751     { name => "Artist One"},
1752     { name => "Artist Two"},
1753     { name => "Artist Three", cds=> [
1754     { title => "First CD", year => 2007},
1755     { title => "Second CD", year => 2008},
1756   ]}
1757   ]);
1758
1759   print $ArtistOne->name; ## response is 'Artist One'
1760   print $ArtistThree->cds->count ## reponse is '2'
1761
1762 For the arrayref of arrayrefs style,  the first element should be a list of the
1763 fieldsnames to which the remaining elements are rows being inserted.  For
1764 example:
1765
1766   $Arstist_rs->populate([
1767     [qw/artistid name/],
1768     [100, 'A Formally Unknown Singer'],
1769     [101, 'A singer that jumped the shark two albums ago'],
1770     [102, 'An actually cool singer.'],
1771   ]);
1772
1773 Please note an important effect on your data when choosing between void and
1774 wantarray context. Since void context goes straight to C<insert_bulk> in
1775 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1776 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1777 create primary keys for you, you will find that your PKs are empty.  In this
1778 case you will have to use the wantarray context in order to create those
1779 values.
1780
1781 =cut
1782
1783 sub populate {
1784   my $self = shift @_;
1785   my $data = ref $_[0][0] eq 'HASH'
1786     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1787     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1788
1789   if(defined wantarray) {
1790     my @created;
1791     foreach my $item (@$data) {
1792       push(@created, $self->create($item));
1793     }
1794     return wantarray ? @created : \@created;
1795   } else {
1796     my ($first, @rest) = @$data;
1797
1798     my @names = grep {!ref $first->{$_}} keys %$first;
1799     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1800     my @pks = $self->result_source->primary_columns;
1801
1802     ## do the belongs_to relationships
1803     foreach my $index (0..$#$data) {
1804
1805       # delegate to create() for any dataset without primary keys with specified relationships
1806       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1807         for my $r (@rels) {
1808           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1809             my @ret = $self->populate($data);
1810             return;
1811           }
1812         }
1813       }
1814
1815       foreach my $rel (@rels) {
1816         next unless ref $data->[$index]->{$rel} eq "HASH";
1817         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1818         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1819         my $related = $result->result_source->_resolve_condition(
1820           $result->result_source->relationship_info($reverse)->{cond},
1821           $self,
1822           $result,
1823         );
1824
1825         delete $data->[$index]->{$rel};
1826         $data->[$index] = {%{$data->[$index]}, %$related};
1827
1828         push @names, keys %$related if $index == 0;
1829       }
1830     }
1831
1832     ## do bulk insert on current row
1833     my @values = map { [ @$_{@names} ] } @$data;
1834
1835     $self->result_source->storage->insert_bulk(
1836       $self->result_source,
1837       \@names,
1838       \@values,
1839     );
1840
1841     ## do the has_many relationships
1842     foreach my $item (@$data) {
1843
1844       foreach my $rel (@rels) {
1845         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1846
1847         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1848      || $self->throw_exception('Cannot find the relating object.');
1849
1850         my $child = $parent->$rel;
1851
1852         my $related = $child->result_source->_resolve_condition(
1853           $parent->result_source->relationship_info($rel)->{cond},
1854           $child,
1855           $parent,
1856         );
1857
1858         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1859         my @populate = map { {%$_, %$related} } @rows_to_add;
1860
1861         $child->populate( \@populate );
1862       }
1863     }
1864   }
1865 }
1866
1867 =head2 _normalize_populate_args ($args)
1868
1869 Private method used by L</populate> to normalize its incoming arguments.  Factored
1870 out in case you want to subclass and accept new argument structures to the
1871 L</populate> method.
1872
1873 =cut
1874
1875 sub _normalize_populate_args {
1876   my ($self, $data) = @_;
1877   my @names = @{shift(@$data)};
1878   my @results_to_create;
1879   foreach my $datum (@$data) {
1880     my %result_to_create;
1881     foreach my $index (0..$#names) {
1882       $result_to_create{$names[$index]} = $$datum[$index];
1883     }
1884     push @results_to_create, \%result_to_create;
1885   }
1886   return \@results_to_create;
1887 }
1888
1889 =head2 pager
1890
1891 =over 4
1892
1893 =item Arguments: none
1894
1895 =item Return Value: $pager
1896
1897 =back
1898
1899 Return Value a L<Data::Page> object for the current resultset. Only makes
1900 sense for queries with a C<page> attribute.
1901
1902 To get the full count of entries for a paged resultset, call
1903 C<total_entries> on the L<Data::Page> object.
1904
1905 =cut
1906
1907 sub pager {
1908   my ($self) = @_;
1909
1910   return $self->{pager} if $self->{pager};
1911
1912   my $attrs = $self->{attrs};
1913   $self->throw_exception("Can't create pager for non-paged rs")
1914     unless $self->{attrs}{page};
1915   $attrs->{rows} ||= 10;
1916
1917   # throw away the paging flags and re-run the count (possibly
1918   # with a subselect) to get the real total count
1919   my $count_attrs = { %$attrs };
1920   delete $count_attrs->{$_} for qw/rows offset page pager/;
1921   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1922
1923   return $self->{pager} = Data::Page->new(
1924     $total_count,
1925     $attrs->{rows},
1926     $self->{attrs}{page}
1927   );
1928 }
1929
1930 =head2 page
1931
1932 =over 4
1933
1934 =item Arguments: $page_number
1935
1936 =item Return Value: $rs
1937
1938 =back
1939
1940 Returns a resultset for the $page_number page of the resultset on which page
1941 is called, where each page contains a number of rows equal to the 'rows'
1942 attribute set on the resultset (10 by default).
1943
1944 =cut
1945
1946 sub page {
1947   my ($self, $page) = @_;
1948   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1949 }
1950
1951 =head2 new_result
1952
1953 =over 4
1954
1955 =item Arguments: \%vals
1956
1957 =item Return Value: $rowobject
1958
1959 =back
1960
1961 Creates a new row object in the resultset's result class and returns
1962 it. The row is not inserted into the database at this point, call
1963 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1964 will tell you whether the row object has been inserted or not.
1965
1966 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1967
1968 =cut
1969
1970 sub new_result {
1971   my ($self, $values) = @_;
1972   $self->throw_exception( "new_result needs a hash" )
1973     unless (ref $values eq 'HASH');
1974
1975   my %new;
1976   my $alias = $self->{attrs}{alias};
1977
1978   if (
1979     defined $self->{cond}
1980     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1981   ) {
1982     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1983     $new{-from_resultset} = [ keys %new ] if keys %new;
1984   } else {
1985     $self->throw_exception(
1986       "Can't abstract implicit construct, condition not a hash"
1987     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1988
1989     my $collapsed_cond = (
1990       $self->{cond}
1991         ? $self->_collapse_cond($self->{cond})
1992         : {}
1993     );
1994
1995     # precendence must be given to passed values over values inherited from
1996     # the cond, so the order here is important.
1997     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1998     while( my($col,$value) = each %implied ){
1999       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
2000         $new{$col} = $value->{'='};
2001         next;
2002       }
2003       $new{$col} = $value if $self->_is_deterministic_value($value);
2004     }
2005   }
2006
2007   %new = (
2008     %new,
2009     %{ $self->_remove_alias($values, $alias) },
2010     -source_handle => $self->_source_handle,
2011     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2012   );
2013
2014   return $self->result_class->new(\%new);
2015 }
2016
2017 # _is_deterministic_value
2018 #
2019 # Make an effor to strip non-deterministic values from the condition,
2020 # to make sure new_result chokes less
2021
2022 sub _is_deterministic_value {
2023   my $self = shift;
2024   my $value = shift;
2025   my $ref_type = ref $value;
2026   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2027   return 1 if Scalar::Util::blessed($value);
2028   return 0;
2029 }
2030
2031 # _has_resolved_attr
2032 #
2033 # determines if the resultset defines at least one
2034 # of the attributes supplied
2035 #
2036 # used to determine if a subquery is neccessary
2037 #
2038 # supports some virtual attributes:
2039 #   -join
2040 #     This will scan for any joins being present on the resultset.
2041 #     It is not a mere key-search but a deep inspection of {from}
2042 #
2043
2044 sub _has_resolved_attr {
2045   my ($self, @attr_names) = @_;
2046
2047   my $attrs = $self->_resolved_attrs;
2048
2049   my %extra_checks;
2050
2051   for my $n (@attr_names) {
2052     if (grep { $n eq $_ } (qw/-join/) ) {
2053       $extra_checks{$n}++;
2054       next;
2055     }
2056
2057     my $attr =  $attrs->{$n};
2058
2059     next if not defined $attr;
2060
2061     if (ref $attr eq 'HASH') {
2062       return 1 if keys %$attr;
2063     }
2064     elsif (ref $attr eq 'ARRAY') {
2065       return 1 if @$attr;
2066     }
2067     else {
2068       return 1 if $attr;
2069     }
2070   }
2071
2072   # a resolved join is expressed as a multi-level from
2073   return 1 if (
2074     $extra_checks{-join}
2075       and
2076     ref $attrs->{from} eq 'ARRAY'
2077       and
2078     @{$attrs->{from}} > 1
2079   );
2080
2081   return 0;
2082 }
2083
2084 # _collapse_cond
2085 #
2086 # Recursively collapse the condition.
2087
2088 sub _collapse_cond {
2089   my ($self, $cond, $collapsed) = @_;
2090
2091   $collapsed ||= {};
2092
2093   if (ref $cond eq 'ARRAY') {
2094     foreach my $subcond (@$cond) {
2095       next unless ref $subcond;  # -or
2096       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2097     }
2098   }
2099   elsif (ref $cond eq 'HASH') {
2100     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2101       foreach my $subcond (@{$cond->{-and}}) {
2102         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2103       }
2104     }
2105     else {
2106       foreach my $col (keys %$cond) {
2107         my $value = $cond->{$col};
2108         $collapsed->{$col} = $value;
2109       }
2110     }
2111   }
2112
2113   return $collapsed;
2114 }
2115
2116 # _remove_alias
2117 #
2118 # Remove the specified alias from the specified query hash. A copy is made so
2119 # the original query is not modified.
2120
2121 sub _remove_alias {
2122   my ($self, $query, $alias) = @_;
2123
2124   my %orig = %{ $query || {} };
2125   my %unaliased;
2126
2127   foreach my $key (keys %orig) {
2128     if ($key !~ /\./) {
2129       $unaliased{$key} = $orig{$key};
2130       next;
2131     }
2132     $unaliased{$1} = $orig{$key}
2133       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2134   }
2135
2136   return \%unaliased;
2137 }
2138
2139 =head2 as_query (EXPERIMENTAL)
2140
2141 =over 4
2142
2143 =item Arguments: none
2144
2145 =item Return Value: \[ $sql, @bind ]
2146
2147 =back
2148
2149 Returns the SQL query and bind vars associated with the invocant.
2150
2151 This is generally used as the RHS for a subquery.
2152
2153 B<NOTE>: This feature is still experimental.
2154
2155 =cut
2156
2157 sub as_query {
2158   my $self = shift;
2159
2160   my $attrs = $self->_resolved_attrs_copy;
2161
2162   # For future use:
2163   #
2164   # in list ctx:
2165   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2166   # $sql also has no wrapping parenthesis in list ctx
2167   #
2168   my $sqlbind = $self->result_source->storage
2169     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2170
2171   return $sqlbind;
2172 }
2173
2174 =head2 find_or_new
2175
2176 =over 4
2177
2178 =item Arguments: \%vals, \%attrs?
2179
2180 =item Return Value: $rowobject
2181
2182 =back
2183
2184   my $artist = $schema->resultset('Artist')->find_or_new(
2185     { artist => 'fred' }, { key => 'artists' });
2186
2187   $cd->cd_to_producer->find_or_new({ producer => $producer },
2188                                    { key => 'primary });
2189
2190 Find an existing record from this resultset, based on its primary
2191 key, or a unique constraint. If none exists, instantiate a new result
2192 object and return it. The object will not be saved into your storage
2193 until you call L<DBIx::Class::Row/insert> on it.
2194
2195 You most likely want this method when looking for existing rows using
2196 a unique constraint that is not the primary key, or looking for
2197 related rows.
2198
2199 If you want objects to be saved immediately, use L</find_or_create> instead.
2200
2201 B<Note>: C<find_or_new> is probably not what you want when creating a
2202 new row in a table that uses primary keys supplied by the
2203 database. Passing in a primary key column with a value of I<undef>
2204 will cause L</find> to attempt to search for a row with a value of
2205 I<NULL>.
2206
2207 =cut
2208
2209 sub find_or_new {
2210   my $self     = shift;
2211   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2212   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2213   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2214     return $row;
2215   }
2216   return $self->new_result($hash);
2217 }
2218
2219 =head2 create
2220
2221 =over 4
2222
2223 =item Arguments: \%vals
2224
2225 =item Return Value: a L<DBIx::Class::Row> $object
2226
2227 =back
2228
2229 Attempt to create a single new row or a row with multiple related rows
2230 in the table represented by the resultset (and related tables). This
2231 will not check for duplicate rows before inserting, use
2232 L</find_or_create> to do that.
2233
2234 To create one row for this resultset, pass a hashref of key/value
2235 pairs representing the columns of the table and the values you wish to
2236 store. If the appropriate relationships are set up, foreign key fields
2237 can also be passed an object representing the foreign row, and the
2238 value will be set to its primary key.
2239
2240 To create related objects, pass a hashref for the value if the related
2241 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2242 and use the name of the relationship as the key. (NOT the name of the field,
2243 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2244 of hashrefs containing the data for each of the rows to create in the foreign
2245 tables, again using the relationship name as the key.
2246
2247 Instead of hashrefs of plain related data (key/value pairs), you may
2248 also pass new or inserted objects. New objects (not inserted yet, see
2249 L</new>), will be inserted into their appropriate tables.
2250
2251 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2252
2253 Example of creating a new row.
2254
2255   $person_rs->create({
2256     name=>"Some Person",
2257     email=>"somebody@someplace.com"
2258   });
2259
2260 Example of creating a new row and also creating rows in a related C<has_many>
2261 or C<has_one> resultset.  Note Arrayref.
2262
2263   $artist_rs->create(
2264      { artistid => 4, name => 'Manufactured Crap', cds => [
2265         { title => 'My First CD', year => 2006 },
2266         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2267       ],
2268      },
2269   );
2270
2271 Example of creating a new row and also creating a row in a related
2272 C<belongs_to>resultset. Note Hashref.
2273
2274   $cd_rs->create({
2275     title=>"Music for Silly Walks",
2276     year=>2000,
2277     artist => {
2278       name=>"Silly Musician",
2279     }
2280   });
2281
2282 =cut
2283
2284 sub create {
2285   my ($self, $attrs) = @_;
2286   $self->throw_exception( "create needs a hashref" )
2287     unless ref $attrs eq 'HASH';
2288   return $self->new_result($attrs)->insert;
2289 }
2290
2291 =head2 find_or_create
2292
2293 =over 4
2294
2295 =item Arguments: \%vals, \%attrs?
2296
2297 =item Return Value: $rowobject
2298
2299 =back
2300
2301   $cd->cd_to_producer->find_or_create({ producer => $producer },
2302                                       { key => 'primary' });
2303
2304 Tries to find a record based on its primary key or unique constraints; if none
2305 is found, creates one and returns that instead.
2306
2307   my $cd = $schema->resultset('CD')->find_or_create({
2308     cdid   => 5,
2309     artist => 'Massive Attack',
2310     title  => 'Mezzanine',
2311     year   => 2005,
2312   });
2313
2314 Also takes an optional C<key> attribute, to search by a specific key or unique
2315 constraint. For example:
2316
2317   my $cd = $schema->resultset('CD')->find_or_create(
2318     {
2319       artist => 'Massive Attack',
2320       title  => 'Mezzanine',
2321     },
2322     { key => 'cd_artist_title' }
2323   );
2324
2325 B<Note>: Because find_or_create() reads from the database and then
2326 possibly inserts based on the result, this method is subject to a race
2327 condition. Another process could create a record in the table after
2328 the find has completed and before the create has started. To avoid
2329 this problem, use find_or_create() inside a transaction.
2330
2331 B<Note>: C<find_or_create> is probably not what you want when creating
2332 a new row in a table that uses primary keys supplied by the
2333 database. Passing in a primary key column with a value of I<undef>
2334 will cause L</find> to attempt to search for a row with a value of
2335 I<NULL>.
2336
2337 See also L</find> and L</update_or_create>. For information on how to declare
2338 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2339
2340 =cut
2341
2342 sub find_or_create {
2343   my $self     = shift;
2344   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2345   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2346   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2347     return $row;
2348   }
2349   return $self->create($hash);
2350 }
2351
2352 =head2 update_or_create
2353
2354 =over 4
2355
2356 =item Arguments: \%col_values, { key => $unique_constraint }?
2357
2358 =item Return Value: $rowobject
2359
2360 =back
2361
2362   $resultset->update_or_create({ col => $val, ... });
2363
2364 First, searches for an existing row matching one of the unique constraints
2365 (including the primary key) on the source of this resultset. If a row is
2366 found, updates it with the other given column values. Otherwise, creates a new
2367 row.
2368
2369 Takes an optional C<key> attribute to search on a specific unique constraint.
2370 For example:
2371
2372   # In your application
2373   my $cd = $schema->resultset('CD')->update_or_create(
2374     {
2375       artist => 'Massive Attack',
2376       title  => 'Mezzanine',
2377       year   => 1998,
2378     },
2379     { key => 'cd_artist_title' }
2380   );
2381
2382   $cd->cd_to_producer->update_or_create({
2383     producer => $producer,
2384     name => 'harry',
2385   }, {
2386     key => 'primary,
2387   });
2388
2389
2390 If no C<key> is specified, it searches on all unique constraints defined on the
2391 source, including the primary key.
2392
2393 If the C<key> is specified as C<primary>, it searches only on the primary key.
2394
2395 See also L</find> and L</find_or_create>. For information on how to declare
2396 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2397
2398 B<Note>: C<update_or_create> is probably not what you want when
2399 looking for a row in a table that uses primary keys supplied by the
2400 database, unless you actually have a key value. Passing in a primary
2401 key column with a value of I<undef> will cause L</find> to attempt to
2402 search for a row with a value of I<NULL>.
2403
2404 =cut
2405
2406 sub update_or_create {
2407   my $self = shift;
2408   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2409   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2410
2411   my $row = $self->find($cond, $attrs);
2412   if (defined $row) {
2413     $row->update($cond);
2414     return $row;
2415   }
2416
2417   return $self->create($cond);
2418 }
2419
2420 =head2 update_or_new
2421
2422 =over 4
2423
2424 =item Arguments: \%col_values, { key => $unique_constraint }?
2425
2426 =item Return Value: $rowobject
2427
2428 =back
2429
2430   $resultset->update_or_new({ col => $val, ... });
2431
2432 First, searches for an existing row matching one of the unique constraints
2433 (including the primary key) on the source of this resultset. If a row is
2434 found, updates it with the other given column values. Otherwise, instantiate
2435 a new result object and return it. The object will not be saved into your storage
2436 until you call L<DBIx::Class::Row/insert> on it.
2437
2438 Takes an optional C<key> attribute to search on a specific unique constraint.
2439 For example:
2440
2441   # In your application
2442   my $cd = $schema->resultset('CD')->update_or_new(
2443     {
2444       artist => 'Massive Attack',
2445       title  => 'Mezzanine',
2446       year   => 1998,
2447     },
2448     { key => 'cd_artist_title' }
2449   );
2450
2451   if ($cd->in_storage) {
2452       # the cd was updated
2453   }
2454   else {
2455       # the cd is not yet in the database, let's insert it
2456       $cd->insert;
2457   }
2458
2459 See also L</find>, L</find_or_create> and L<find_or_new>.
2460
2461 =cut
2462
2463 sub update_or_new {
2464     my $self  = shift;
2465     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2466     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2467
2468     my $row = $self->find( $cond, $attrs );
2469     if ( defined $row ) {
2470         $row->update($cond);
2471         return $row;
2472     }
2473
2474     return $self->new_result($cond);
2475 }
2476
2477 =head2 get_cache
2478
2479 =over 4
2480
2481 =item Arguments: none
2482
2483 =item Return Value: \@cache_objects?
2484
2485 =back
2486
2487 Gets the contents of the cache for the resultset, if the cache is set.
2488
2489 The cache is populated either by using the L</prefetch> attribute to
2490 L</search> or by calling L</set_cache>.
2491
2492 =cut
2493
2494 sub get_cache {
2495   shift->{all_cache};
2496 }
2497
2498 =head2 set_cache
2499
2500 =over 4
2501
2502 =item Arguments: \@cache_objects
2503
2504 =item Return Value: \@cache_objects
2505
2506 =back
2507
2508 Sets the contents of the cache for the resultset. Expects an arrayref
2509 of objects of the same class as those produced by the resultset. Note that
2510 if the cache is set the resultset will return the cached objects rather
2511 than re-querying the database even if the cache attr is not set.
2512
2513 The contents of the cache can also be populated by using the
2514 L</prefetch> attribute to L</search>.
2515
2516 =cut
2517
2518 sub set_cache {
2519   my ( $self, $data ) = @_;
2520   $self->throw_exception("set_cache requires an arrayref")
2521       if defined($data) && (ref $data ne 'ARRAY');
2522   $self->{all_cache} = $data;
2523 }
2524
2525 =head2 clear_cache
2526
2527 =over 4
2528
2529 =item Arguments: none
2530
2531 =item Return Value: []
2532
2533 =back
2534
2535 Clears the cache for the resultset.
2536
2537 =cut
2538
2539 sub clear_cache {
2540   shift->set_cache(undef);
2541 }
2542
2543 =head2 related_resultset
2544
2545 =over 4
2546
2547 =item Arguments: $relationship_name
2548
2549 =item Return Value: $resultset
2550
2551 =back
2552
2553 Returns a related resultset for the supplied relationship name.
2554
2555   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2556
2557 =cut
2558
2559 sub related_resultset {
2560   my ($self, $rel) = @_;
2561
2562   $self->{related_resultsets} ||= {};
2563   return $self->{related_resultsets}{$rel} ||= do {
2564     my $rel_info = $self->result_source->relationship_info($rel);
2565
2566     $self->throw_exception(
2567       "search_related: result source '" . $self->result_source->source_name .
2568         "' has no such relationship $rel")
2569       unless $rel_info;
2570
2571     my ($from,$seen) = $self->_chain_relationship($rel);
2572
2573     my $join_count = $seen->{$rel};
2574     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2575
2576     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2577     my %attrs = %{$self->{attrs}||{}};
2578     delete @attrs{qw(result_class alias)};
2579
2580     my $new_cache;
2581
2582     if (my $cache = $self->get_cache) {
2583       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2584         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2585                         @$cache ];
2586       }
2587     }
2588
2589     my $rel_source = $self->result_source->related_source($rel);
2590
2591     my $new = do {
2592
2593       # The reason we do this now instead of passing the alias to the
2594       # search_rs below is that if you wrap/overload resultset on the
2595       # source you need to know what alias it's -going- to have for things
2596       # to work sanely (e.g. RestrictWithObject wants to be able to add
2597       # extra query restrictions, and these may need to be $alias.)
2598
2599       my $attrs = $rel_source->resultset_attributes;
2600       local $attrs->{alias} = $alias;
2601
2602       $rel_source->resultset
2603                  ->search_rs(
2604                      undef, {
2605                        %attrs,
2606                        join => undef,
2607                        prefetch => undef,
2608                        select => undef,
2609                        as => undef,
2610                        where => $self->{cond},
2611                        seen_join => $seen,
2612                        from => $from,
2613                    });
2614     };
2615     $new->set_cache($new_cache) if $new_cache;
2616     $new;
2617   };
2618 }
2619
2620 =head2 current_source_alias
2621
2622 =over 4
2623
2624 =item Arguments: none
2625
2626 =item Return Value: $source_alias
2627
2628 =back
2629
2630 Returns the current table alias for the result source this resultset is built
2631 on, that will be used in the SQL query. Usually it is C<me>.
2632
2633 Currently the source alias that refers to the result set returned by a
2634 L</search>/L</find> family method depends on how you got to the resultset: it's
2635 C<me> by default, but eg. L</search_related> aliases it to the related result
2636 source name (and keeps C<me> referring to the original result set). The long
2637 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2638 (and make this method unnecessary).
2639
2640 Thus it's currently necessary to use this method in predefined queries (see
2641 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2642 source alias of the current result set:
2643
2644   # in a result set class
2645   sub modified_by {
2646     my ($self, $user) = @_;
2647
2648     my $me = $self->current_source_alias;
2649
2650     return $self->search(
2651       "$me.modified" => $user->id,
2652     );
2653   }
2654
2655 =cut
2656
2657 sub current_source_alias {
2658   my ($self) = @_;
2659
2660   return ($self->{attrs} || {})->{alias} || 'me';
2661 }
2662
2663 # This code is called by search_related, and makes sure there
2664 # is clear separation between the joins before, during, and
2665 # after the relationship. This information is needed later
2666 # in order to properly resolve prefetch aliases (any alias
2667 # with a relation_chain_depth less than the depth of the
2668 # current prefetch is not considered)
2669 sub _chain_relationship {
2670   my ($self, $rel) = @_;
2671   my $source = $self->result_source;
2672   my $attrs = $self->{attrs};
2673
2674   my $from = [ @{
2675       $attrs->{from}
2676         ||
2677       [{
2678         -source_handle => $source->handle,
2679         -alias => $attrs->{alias},
2680         $attrs->{alias} => $source->from,
2681       }]
2682   }];
2683
2684   my $seen = { %{$attrs->{seen_join} || {} } };
2685
2686   # we need to take the prefetch the attrs into account before we
2687   # ->_resolve_join as otherwise they get lost - captainL
2688   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2689
2690   my @requested_joins = $source->_resolve_join($merged, $attrs->{alias}, $seen);
2691
2692   push @$from, @requested_joins;
2693
2694   ++$seen->{-relation_chain_depth};
2695
2696   # if $self already had a join/prefetch specified on it, the requested
2697   # $rel might very well be already included. What we do in this case
2698   # is effectively a no-op (except that we bump up the chain_depth on
2699   # the join in question so we could tell it *is* the search_related)
2700   my $already_joined;
2701
2702   # we consider the last one thus reverse
2703   for my $j (reverse @requested_joins) {
2704     if ($rel eq $j->[0]{-join_path}[-1]) {
2705       $j->[0]{-relation_chain_depth}++;
2706       $already_joined++;
2707       last;
2708     }
2709   }
2710   unless ($already_joined) {
2711     push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2712   }
2713
2714   ++$seen->{-relation_chain_depth};
2715
2716   return ($from,$seen);
2717 }
2718
2719 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2720 sub _resolved_attrs_copy {
2721   my $self = shift;
2722   return { %{$self->_resolved_attrs (@_)} };
2723 }
2724
2725 sub _resolved_attrs {
2726   my $self = shift;
2727   return $self->{_attrs} if $self->{_attrs};
2728
2729   my $attrs  = { %{ $self->{attrs} || {} } };
2730   my $source = $self->result_source;
2731   my $alias  = $attrs->{alias};
2732
2733   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2734   my @colbits;
2735
2736   # build columns (as long as select isn't set) into a set of as/select hashes
2737   unless ( $attrs->{select} ) {
2738       @colbits = map {
2739           ( ref($_) eq 'HASH' )
2740               ? $_
2741               : {
2742                   (
2743                     /^\Q${alias}.\E(.+)$/
2744                       ? "$1"
2745                       : "$_"
2746                   )
2747                 =>
2748                   (
2749                     /\./
2750                       ? "$_"
2751                       : "${alias}.$_"
2752                   )
2753             }
2754       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2755   }
2756   # add the additional columns on
2757   foreach ( 'include_columns', '+columns' ) {
2758       push @colbits, map {
2759           ( ref($_) eq 'HASH' )
2760             ? $_
2761             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2762       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2763   }
2764
2765   # start with initial select items
2766   if ( $attrs->{select} ) {
2767     $attrs->{select} =
2768         ( ref $attrs->{select} eq 'ARRAY' )
2769       ? [ @{ $attrs->{select} } ]
2770       : [ $attrs->{select} ];
2771     $attrs->{as} = (
2772       $attrs->{as}
2773       ? (
2774         ref $attrs->{as} eq 'ARRAY'
2775         ? [ @{ $attrs->{as} } ]
2776         : [ $attrs->{as} ]
2777         )
2778       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2779     );
2780   }
2781   else {
2782
2783     # otherwise we intialise select & as to empty
2784     $attrs->{select} = [];
2785     $attrs->{as}     = [];
2786   }
2787
2788   # now add colbits to select/as
2789   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2790   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2791
2792   my $adds;
2793   if ( $adds = delete $attrs->{'+select'} ) {
2794     $adds = [$adds] unless ref $adds eq 'ARRAY';
2795     push(
2796       @{ $attrs->{select} },
2797       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2798     );
2799   }
2800   if ( $adds = delete $attrs->{'+as'} ) {
2801     $adds = [$adds] unless ref $adds eq 'ARRAY';
2802     push( @{ $attrs->{as} }, @$adds );
2803   }
2804
2805   $attrs->{from} ||= [ {
2806     -source_handle => $source->handle,
2807     -alias => $self->{attrs}{alias},
2808     $self->{attrs}{alias} => $source->from,
2809   } ];
2810
2811   if ( $attrs->{join} || $attrs->{prefetch} ) {
2812
2813     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2814       if ref $attrs->{from} ne 'ARRAY';
2815
2816     my $join = delete $attrs->{join} || {};
2817
2818     if ( defined $attrs->{prefetch} ) {
2819       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2820     }
2821
2822     $attrs->{from} =    # have to copy here to avoid corrupting the original
2823       [
2824         @{ $attrs->{from} },
2825         $source->_resolve_join(
2826           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2827         )
2828       ];
2829   }
2830
2831   if ( $attrs->{order_by} ) {
2832     $attrs->{order_by} = (
2833       ref( $attrs->{order_by} ) eq 'ARRAY'
2834       ? [ @{ $attrs->{order_by} } ]
2835       : [ $attrs->{order_by} ]
2836     );
2837   }
2838
2839   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2840     $attrs->{group_by} = [ $attrs->{group_by} ];
2841   }
2842
2843   # If the order_by is otherwise empty - we will use this for TOP limit
2844   # emulation and the like.
2845   # Although this is needed only if the order_by is not defined, it is
2846   # actually cheaper to just populate this rather than properly examining
2847   # order_by (stuf like [ {} ] and the like)
2848   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2849
2850
2851   $attrs->{collapse} ||= {};
2852   if ( my $prefetch = delete $attrs->{prefetch} ) {
2853     $prefetch = $self->_merge_attr( {}, $prefetch );
2854
2855     my $prefetch_ordering = [];
2856
2857     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2858
2859     my @prefetch =
2860       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2861
2862     $attrs->{prefetch_select} = [ map { $_->[0] } @prefetch ];
2863     push @{ $attrs->{select} }, @{$attrs->{prefetch_select}};
2864     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2865
2866     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2867     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2868   }
2869
2870
2871   if (delete $attrs->{distinct}) {
2872     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2873   }
2874
2875   # if both page and offset are specified, produce a combined offset
2876   # even though it doesn't make much sense, this is what pre 081xx has
2877   # been doing
2878   if (my $page = delete $attrs->{page}) {
2879     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2880       ($attrs->{offset} || 0);
2881   }
2882
2883   return $self->{_attrs} = $attrs;
2884 }
2885
2886 sub _joinpath_aliases {
2887   my ($self, $fromspec, $seen) = @_;
2888
2889   my $paths = {};
2890   return $paths unless ref $fromspec eq 'ARRAY';
2891
2892   for my $j (@$fromspec) {
2893
2894     next if ref $j ne 'ARRAY';
2895     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2896
2897     my $p = $paths;
2898     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2899     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2900   }
2901
2902   return $paths;
2903 }
2904
2905 sub _rollout_attr {
2906   my ($self, $attr) = @_;
2907
2908   if (ref $attr eq 'HASH') {
2909     return $self->_rollout_hash($attr);
2910   } elsif (ref $attr eq 'ARRAY') {
2911     return $self->_rollout_array($attr);
2912   } else {
2913     return [$attr];
2914   }
2915 }
2916
2917 sub _rollout_array {
2918   my ($self, $attr) = @_;
2919
2920   my @rolled_array;
2921   foreach my $element (@{$attr}) {
2922     if (ref $element eq 'HASH') {
2923       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2924     } elsif (ref $element eq 'ARRAY') {
2925       #  XXX - should probably recurse here
2926       push( @rolled_array, @{$self->_rollout_array($element)} );
2927     } else {
2928       push( @rolled_array, $element );
2929     }
2930   }
2931   return \@rolled_array;
2932 }
2933
2934 sub _rollout_hash {
2935   my ($self, $attr) = @_;
2936
2937   my @rolled_array;
2938   foreach my $key (keys %{$attr}) {
2939     push( @rolled_array, { $key => $attr->{$key} } );
2940   }
2941   return \@rolled_array;
2942 }
2943
2944 sub _calculate_score {
2945   my ($self, $a, $b) = @_;
2946
2947   if (ref $b eq 'HASH') {
2948     my ($b_key) = keys %{$b};
2949     if (ref $a eq 'HASH') {
2950       my ($a_key) = keys %{$a};
2951       if ($a_key eq $b_key) {
2952         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2953       } else {
2954         return 0;
2955       }
2956     } else {
2957       return ($a eq $b_key) ? 1 : 0;
2958     }
2959   } else {
2960     if (ref $a eq 'HASH') {
2961       my ($a_key) = keys %{$a};
2962       return ($b eq $a_key) ? 1 : 0;
2963     } else {
2964       return ($b eq $a) ? 1 : 0;
2965     }
2966   }
2967 }
2968
2969 sub _merge_attr {
2970   my ($self, $orig, $import) = @_;
2971
2972   return $import unless defined($orig);
2973   return $orig unless defined($import);
2974
2975   $orig = $self->_rollout_attr($orig);
2976   $import = $self->_rollout_attr($import);
2977
2978   my $seen_keys;
2979   foreach my $import_element ( @{$import} ) {
2980     # find best candidate from $orig to merge $b_element into
2981     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2982     foreach my $orig_element ( @{$orig} ) {
2983       my $score = $self->_calculate_score( $orig_element, $import_element );
2984       if ($score > $best_candidate->{score}) {
2985         $best_candidate->{position} = $position;
2986         $best_candidate->{score} = $score;
2987       }
2988       $position++;
2989     }
2990     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2991
2992     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2993       push( @{$orig}, $import_element );
2994     } else {
2995       my $orig_best = $orig->[$best_candidate->{position}];
2996       # merge orig_best and b_element together and replace original with merged
2997       if (ref $orig_best ne 'HASH') {
2998         $orig->[$best_candidate->{position}] = $import_element;
2999       } elsif (ref $import_element eq 'HASH') {
3000         my ($key) = keys %{$orig_best};
3001         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3002       }
3003     }
3004     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3005   }
3006
3007   return $orig;
3008 }
3009
3010 sub result_source {
3011     my $self = shift;
3012
3013     if (@_) {
3014         $self->_source_handle($_[0]->handle);
3015     } else {
3016         $self->_source_handle->resolve;
3017     }
3018 }
3019
3020 =head2 throw_exception
3021
3022 See L<DBIx::Class::Schema/throw_exception> for details.
3023
3024 =cut
3025
3026 sub throw_exception {
3027   my $self=shift;
3028   if (ref $self && $self->_source_handle->schema) {
3029     $self->_source_handle->schema->throw_exception(@_)
3030   } else {
3031     croak(@_);
3032   }
3033
3034 }
3035
3036 # XXX: FIXME: Attributes docs need clearing up
3037
3038 =head1 ATTRIBUTES
3039
3040 Attributes are used to refine a ResultSet in various ways when
3041 searching for data. They can be passed to any method which takes an
3042 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3043 L</count>.
3044
3045 These are in no particular order:
3046
3047 =head2 order_by
3048
3049 =over 4
3050
3051 =item Value: ( $order_by | \@order_by | \%order_by )
3052
3053 =back
3054
3055 Which column(s) to order the results by. If a single column name, or
3056 an arrayref of names is supplied, the argument is passed through
3057 directly to SQL. The hashref syntax allows for connection-agnostic
3058 specification of ordering direction:
3059
3060  For descending order:
3061
3062   order_by => { -desc => [qw/col1 col2 col3/] }
3063
3064  For explicit ascending order:
3065
3066   order_by => { -asc => 'col' }
3067
3068 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3069 supported, although you are strongly encouraged to use the hashref
3070 syntax as outlined above.
3071
3072 =head2 columns
3073
3074 =over 4
3075
3076 =item Value: \@columns
3077
3078 =back
3079
3080 Shortcut to request a particular set of columns to be retrieved. Each
3081 column spec may be a string (a table column name), or a hash (in which
3082 case the key is the C<as> value, and the value is used as the C<select>
3083 expression). Adds C<me.> onto the start of any column without a C<.> in
3084 it and sets C<select> from that, then auto-populates C<as> from
3085 C<select> as normal. (You may also use the C<cols> attribute, as in
3086 earlier versions of DBIC.)
3087
3088 =head2 +columns
3089
3090 =over 4
3091
3092 =item Value: \@columns
3093
3094 =back
3095
3096 Indicates additional columns to be selected from storage. Works the same
3097 as L</columns> but adds columns to the selection. (You may also use the
3098 C<include_columns> attribute, as in earlier versions of DBIC). For
3099 example:-
3100
3101   $schema->resultset('CD')->search(undef, {
3102     '+columns' => ['artist.name'],
3103     join => ['artist']
3104   });
3105
3106 would return all CDs and include a 'name' column to the information
3107 passed to object inflation. Note that the 'artist' is the name of the
3108 column (or relationship) accessor, and 'name' is the name of the column
3109 accessor in the related table.
3110
3111 =head2 include_columns
3112
3113 =over 4
3114
3115 =item Value: \@columns
3116
3117 =back
3118
3119 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3120
3121 =head2 select
3122
3123 =over 4
3124
3125 =item Value: \@select_columns
3126
3127 =back
3128
3129 Indicates which columns should be selected from the storage. You can use
3130 column names, or in the case of RDBMS back ends, function or stored procedure
3131 names:
3132
3133   $rs = $schema->resultset('Employee')->search(undef, {
3134     select => [
3135       'name',
3136       { count => 'employeeid' },
3137       { sum => 'salary' }
3138     ]
3139   });
3140
3141 When you use function/stored procedure names and do not supply an C<as>
3142 attribute, the column names returned are storage-dependent. E.g. MySQL would
3143 return a column named C<count(employeeid)> in the above example.
3144
3145 =head2 +select
3146
3147 =over 4
3148
3149 Indicates additional columns to be selected from storage.  Works the same as
3150 L</select> but adds columns to the selection.
3151
3152 =back
3153
3154 =head2 +as
3155
3156 =over 4
3157
3158 Indicates additional column names for those added via L</+select>. See L</as>.
3159
3160 =back
3161
3162 =head2 as
3163
3164 =over 4
3165
3166 =item Value: \@inflation_names
3167
3168 =back
3169
3170 Indicates column names for object inflation. That is, C<as>
3171 indicates the name that the column can be accessed as via the
3172 C<get_column> method (or via the object accessor, B<if one already
3173 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3174
3175 The C<as> attribute is used in conjunction with C<select>,
3176 usually when C<select> contains one or more function or stored
3177 procedure names:
3178
3179   $rs = $schema->resultset('Employee')->search(undef, {
3180     select => [
3181       'name',
3182       { count => 'employeeid' }
3183     ],
3184     as => ['name', 'employee_count'],
3185   });
3186
3187   my $employee = $rs->first(); # get the first Employee
3188
3189 If the object against which the search is performed already has an accessor
3190 matching a column name specified in C<as>, the value can be retrieved using
3191 the accessor as normal:
3192
3193   my $name = $employee->name();
3194
3195 If on the other hand an accessor does not exist in the object, you need to
3196 use C<get_column> instead:
3197
3198   my $employee_count = $employee->get_column('employee_count');
3199
3200 You can create your own accessors if required - see
3201 L<DBIx::Class::Manual::Cookbook> for details.
3202
3203 Please note: This will NOT insert an C<AS employee_count> into the SQL
3204 statement produced, it is used for internal access only. Thus
3205 attempting to use the accessor in an C<order_by> clause or similar
3206 will fail miserably.
3207
3208 To get around this limitation, you can supply literal SQL to your
3209 C<select> attibute that contains the C<AS alias> text, eg:
3210
3211   select => [\'myfield AS alias']
3212
3213 =head2 join
3214
3215 =over 4
3216
3217 =item Value: ($rel_name | \@rel_names | \%rel_names)
3218
3219 =back
3220
3221 Contains a list of relationships that should be joined for this query.  For
3222 example:
3223
3224   # Get CDs by Nine Inch Nails
3225   my $rs = $schema->resultset('CD')->search(
3226     { 'artist.name' => 'Nine Inch Nails' },
3227     { join => 'artist' }
3228   );
3229
3230 Can also contain a hash reference to refer to the other relation's relations.
3231 For example:
3232
3233   package MyApp::Schema::Track;
3234   use base qw/DBIx::Class/;
3235   __PACKAGE__->table('track');
3236   __PACKAGE__->add_columns(qw/trackid cd position title/);
3237   __PACKAGE__->set_primary_key('trackid');
3238   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3239   1;
3240
3241   # In your application
3242   my $rs = $schema->resultset('Artist')->search(
3243     { 'track.title' => 'Teardrop' },
3244     {
3245       join     => { cd => 'track' },
3246       order_by => 'artist.name',
3247     }
3248   );
3249
3250 You need to use the relationship (not the table) name in  conditions,
3251 because they are aliased as such. The current table is aliased as "me", so
3252 you need to use me.column_name in order to avoid ambiguity. For example:
3253
3254   # Get CDs from 1984 with a 'Foo' track
3255   my $rs = $schema->resultset('CD')->search(
3256     {
3257       'me.year' => 1984,
3258       'tracks.name' => 'Foo'
3259     },
3260     { join => 'tracks' }
3261   );
3262
3263 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3264 similarly for a third time). For e.g.
3265
3266   my $rs = $schema->resultset('Artist')->search({
3267     'cds.title'   => 'Down to Earth',
3268     'cds_2.title' => 'Popular',
3269   }, {
3270     join => [ qw/cds cds/ ],
3271   });
3272
3273 will return a set of all artists that have both a cd with title 'Down
3274 to Earth' and a cd with title 'Popular'.
3275
3276 If you want to fetch related objects from other tables as well, see C<prefetch>
3277 below.
3278
3279 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3280
3281 =head2 prefetch
3282
3283 =over 4
3284
3285 =item Value: ($rel_name | \@rel_names | \%rel_names)
3286
3287 =back
3288
3289 Contains one or more relationships that should be fetched along with
3290 the main query (when they are accessed afterwards the data will
3291 already be available, without extra queries to the database).  This is
3292 useful for when you know you will need the related objects, because it
3293 saves at least one query:
3294
3295   my $rs = $schema->resultset('Tag')->search(
3296     undef,
3297     {
3298       prefetch => {
3299         cd => 'artist'
3300       }
3301     }
3302   );
3303
3304 The initial search results in SQL like the following:
3305
3306   SELECT tag.*, cd.*, artist.* FROM tag
3307   JOIN cd ON tag.cd = cd.cdid
3308   JOIN artist ON cd.artist = artist.artistid
3309
3310 L<DBIx::Class> has no need to go back to the database when we access the
3311 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3312 case.
3313
3314 Simple prefetches will be joined automatically, so there is no need
3315 for a C<join> attribute in the above search.
3316
3317 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3318 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3319 with an accessor type of 'single' or 'filter'). A more complex example that
3320 prefetches an artists cds, the tracks on those cds, and the tags associted
3321 with that artist is given below (assuming many-to-many from artists to tags):
3322
3323  my $rs = $schema->resultset('Artist')->search(
3324    undef,
3325    {
3326      prefetch => [
3327        { cds => 'tracks' },
3328        { artist_tags => 'tags' }
3329      ]
3330    }
3331  );
3332
3333
3334 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3335 attributes will be ignored.
3336
3337 =head2 page
3338
3339 =over 4
3340
3341 =item Value: $page
3342
3343 =back
3344
3345 Makes the resultset paged and specifies the page to retrieve. Effectively
3346 identical to creating a non-pages resultset and then calling ->page($page)
3347 on it.
3348
3349 If L<rows> attribute is not specified it defaults to 10 rows per page.
3350
3351 When you have a paged resultset, L</count> will only return the number
3352 of rows in the page. To get the total, use the L</pager> and call
3353 C<total_entries> on it.
3354
3355 =head2 rows
3356
3357 =over 4
3358
3359 =item Value: $rows
3360
3361 =back
3362
3363 Specifes the maximum number of rows for direct retrieval or the number of
3364 rows per page if the page attribute or method is used.
3365
3366 =head2 offset
3367
3368 =over 4
3369
3370 =item Value: $offset
3371
3372 =back
3373
3374 Specifies the (zero-based) row number for the  first row to be returned, or the
3375 of the first row of the first page if paging is used.
3376
3377 =head2 group_by
3378
3379 =over 4
3380
3381 =item Value: \@columns
3382
3383 =back
3384
3385 A arrayref of columns to group by. Can include columns of joined tables.
3386
3387   group_by => [qw/ column1 column2 ... /]
3388
3389 =head2 having
3390
3391 =over 4
3392
3393 =item Value: $condition
3394
3395 =back
3396
3397 HAVING is a select statement attribute that is applied between GROUP BY and
3398 ORDER BY. It is applied to the after the grouping calculations have been
3399 done.
3400
3401   having => { 'count(employee)' => { '>=', 100 } }
3402
3403 =head2 distinct
3404
3405 =over 4
3406
3407 =item Value: (0 | 1)
3408
3409 =back
3410
3411 Set to 1 to group by all columns.
3412
3413 =head2 where
3414
3415 =over 4
3416
3417 Adds to the WHERE clause.
3418
3419   # only return rows WHERE deleted IS NULL for all searches
3420   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3421
3422 Can be overridden by passing C<{ where => undef }> as an attribute
3423 to a resulset.
3424
3425 =back
3426
3427 =head2 cache
3428
3429 Set to 1 to cache search results. This prevents extra SQL queries if you
3430 revisit rows in your ResultSet:
3431
3432   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3433
3434   while( my $artist = $resultset->next ) {
3435     ... do stuff ...
3436   }
3437
3438   $rs->first; # without cache, this would issue a query
3439
3440 By default, searches are not cached.
3441
3442 For more examples of using these attributes, see
3443 L<DBIx::Class::Manual::Cookbook>.
3444
3445 =head2 from
3446
3447 =over 4
3448
3449 =item Value: \@from_clause
3450
3451 =back
3452
3453 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3454 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3455 clauses.
3456
3457 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3458
3459 C<join> will usually do what you need and it is strongly recommended that you
3460 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3461 And we really do mean "cannot", not just tried and failed. Attempting to use
3462 this because you're having problems with C<join> is like trying to use x86
3463 ASM because you've got a syntax error in your C. Trust us on this.
3464
3465 Now, if you're still really, really sure you need to use this (and if you're
3466 not 100% sure, ask the mailing list first), here's an explanation of how this
3467 works.
3468
3469 The syntax is as follows -
3470
3471   [
3472     { <alias1> => <table1> },
3473     [
3474       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3475       [], # nested JOIN (optional)
3476       { <table1.column1> => <table2.column2>, ... (more conditions) },
3477     ],
3478     # More of the above [ ] may follow for additional joins
3479   ]
3480
3481   <table1> <alias1>
3482   JOIN
3483     <table2> <alias2>
3484     [JOIN ...]
3485   ON <table1.column1> = <table2.column2>
3486   <more joins may follow>
3487
3488 An easy way to follow the examples below is to remember the following:
3489
3490     Anything inside "[]" is a JOIN
3491     Anything inside "{}" is a condition for the enclosing JOIN
3492
3493 The following examples utilize a "person" table in a family tree application.
3494 In order to express parent->child relationships, this table is self-joined:
3495
3496     # Person->belongs_to('father' => 'Person');
3497     # Person->belongs_to('mother' => 'Person');
3498
3499 C<from> can be used to nest joins. Here we return all children with a father,
3500 then search against all mothers of those children:
3501
3502   $rs = $schema->resultset('Person')->search(
3503       undef,
3504       {
3505           alias => 'mother', # alias columns in accordance with "from"
3506           from => [
3507               { mother => 'person' },
3508               [
3509                   [
3510                       { child => 'person' },
3511                       [
3512                           { father => 'person' },
3513                           { 'father.person_id' => 'child.father_id' }
3514                       ]
3515                   ],
3516                   { 'mother.person_id' => 'child.mother_id' }
3517               ],
3518           ]
3519       },
3520   );
3521
3522   # Equivalent SQL:
3523   # SELECT mother.* FROM person mother
3524   # JOIN (
3525   #   person child
3526   #   JOIN person father
3527   #   ON ( father.person_id = child.father_id )
3528   # )
3529   # ON ( mother.person_id = child.mother_id )
3530
3531 The type of any join can be controlled manually. To search against only people
3532 with a father in the person table, we could explicitly use C<INNER JOIN>:
3533
3534     $rs = $schema->resultset('Person')->search(
3535         undef,
3536         {
3537             alias => 'child', # alias columns in accordance with "from"
3538             from => [
3539                 { child => 'person' },
3540                 [
3541                     { father => 'person', -join_type => 'inner' },
3542                     { 'father.id' => 'child.father_id' }
3543                 ],
3544             ]
3545         },
3546     );
3547
3548     # Equivalent SQL:
3549     # SELECT child.* FROM person child
3550     # INNER JOIN person father ON child.father_id = father.id
3551
3552 You can select from a subquery by passing a resultset to from as follows.
3553
3554     $schema->resultset('Artist')->search(
3555         undef,
3556         {   alias => 'artist2',
3557             from  => [ { artist2 => $artist_rs->as_query } ],
3558         } );
3559
3560     # and you'll get sql like this..
3561     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3562     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3563
3564 If you need to express really complex joins, you
3565 can supply literal SQL to C<from> via a scalar reference. In this case
3566 the contents of the scalar will replace the table name associated with the
3567 resultsource.
3568
3569 WARNING: This technique might very well not work as expected on chained
3570 searches - you have been warned.
3571
3572     # Assuming the Event resultsource is defined as:
3573
3574         MySchema::Event->add_columns (
3575             sequence => {
3576                 data_type => 'INT',
3577                 is_auto_increment => 1,
3578             },
3579             location => {
3580                 data_type => 'INT',
3581             },
3582             type => {
3583                 data_type => 'INT',
3584             },
3585         );
3586         MySchema::Event->set_primary_key ('sequence');
3587
3588     # This will get back the latest event for every location. The column
3589     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3590     # combo to limit the resultset
3591
3592     $rs = $schema->resultset('Event');
3593     $table = $rs->result_source->name;
3594     $latest = $rs->search (
3595         undef,
3596         { from => \ "
3597             (SELECT e1.* FROM $table e1
3598                 JOIN $table e2
3599                     ON e1.location = e2.location
3600                     AND e1.sequence < e2.sequence
3601                 WHERE e2.sequence is NULL
3602             ) me",
3603         },
3604     );
3605
3606     # Equivalent SQL (with the DBIC chunks added):
3607
3608     SELECT me.sequence, me.location, me.type FROM
3609        (SELECT e1.* FROM events e1
3610            JOIN events e2
3611                ON e1.location = e2.location
3612                AND e1.sequence < e2.sequence
3613            WHERE e2.sequence is NULL
3614        ) me;
3615
3616 =head2 for
3617
3618 =over 4
3619
3620 =item Value: ( 'update' | 'shared' )
3621
3622 =back
3623
3624 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3625 ... FOR SHARED.
3626
3627 =cut
3628
3629 1;