lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use DBIx::Class::Exception;
   8 use Data::Page;
   9 use Storable;
  10 use DBIx::Class::ResultSetColumn;
  11 use DBIx::Class::ResultSourceHandle;
  12 use List::Util ();
  13 use Scalar::Util 'blessed';
  14 use namespace::clean;
  15
  16 use overload
  17         '0+'     => "count",
  18         'bool'   => "_bool",
  19         fallback => 1;
  20
  21 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  22
  23 =head1 NAME
  24
  25 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  26
  27 =head1 SYNOPSIS
  28
  29   my $users_rs   = $schema->resultset('User');
  30   while( $user = $users_rs->next) {
  31     print $user->username;
  32   }
  33
  34   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  35   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  36
  37 =head1 DESCRIPTION
  38
  39 A ResultSet is an object which stores a set of conditions representing
  40 a query. It is the backbone of DBIx::Class (i.e. the really
  41 important/useful bit).
  42
  43 No SQL is executed on the database when a ResultSet is created, it
  44 just stores all the conditions needed to create the query.
  45
  46 A basic ResultSet representing the data of an entire table is returned
  47 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  48 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  49
  50   my $users_rs = $schema->resultset('User');
  51
  52 A new ResultSet is returned from calling L</search> on an existing
  53 ResultSet. The new one will contain all the conditions of the
  54 original, plus any new conditions added in the C<search> call.
  55
  56 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  57 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  58 represents.
  59
  60 The query that the ResultSet represents is B<only> executed against
  61 the database when these methods are called:
  62 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  63
  64 If a resultset is used in a numeric context it returns the L</count>.
  65 However, if it is used in a boolean context it is B<always> true.  So if
  66 you want to check if a resultset has any results, you must use C<if $rs
  67 != 0>.
  68
  69 =head1 EXAMPLES
  70
  71 =head2 Chaining resultsets
  72
  73 Let's say you've got a query that needs to be run to return some data
  74 to the user. But, you have an authorization system in place that
  75 prevents certain users from seeing certain information. So, you want
  76 to construct the basic query in one method, but add constraints to it in
  77 another.
  78
  79   sub get_data {
  80     my $self = shift;
  81     my $request = $self->get_request; # Get a request object somehow.
  82     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  83
  84     my $cd_rs = $schema->resultset('CD')->search({
  85       title => $request->param('title'),
  86       year => $request->param('year'),
  87     });
  88
  89     $self->apply_security_policy( $cd_rs );
  90
  91     return $cd_rs->all();
  92   }
  93
  94   sub apply_security_policy {
  95     my $self = shift;
  96     my ($rs) = @_;
  97
  98     return $rs->search({
  99       subversive => 0,
 100     });
 101   }
 102
 103 =head3 Resolving conditions and attributes
 104
 105 When a resultset is chained from another resultset, conditions and
 106 attributes with the same keys need resolving.
 107
 108 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 109 into the existing ones from the original resultset.
 110
 111 The L</where> and L</having> attributes, and any search conditions, are
 112 merged with an SQL C<AND> to the existing condition from the original
 113 resultset.
 114
 115 All other attributes are overridden by any new ones supplied in the
 116 search attributes.
 117
 118 =head2 Multiple queries
 119
 120 Since a resultset just defines a query, you can do all sorts of
 121 things with it with the same object.
 122
 123   # Don't hit the DB yet.
 124   my $cd_rs = $schema->resultset('CD')->search({
 125     title => 'something',
 126     year => 2009,
 127   });
 128
 129   # Each of these hits the DB individually.
 130   my $count = $cd_rs->count;
 131   my $most_recent = $cd_rs->get_column('date_released')->max();
 132   my @records = $cd_rs->all;
 133
 134 And it's not just limited to SELECT statements.
 135
 136   $cd_rs->delete();
 137
 138 This is even cooler:
 139
 140   $cd_rs->create({ artist => 'Fred' });
 141
 142 Which is the same as:
 143
 144   $schema->resultset('CD')->create({
 145     title => 'something',
 146     year => 2009,
 147     artist => 'Fred'
 148   });
 149
 150 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 151
 152 =head1 METHODS
 153
 154 =head2 new
 155
 156 =over 4
 157
 158 =item Arguments: $source, \%$attrs
 159
 160 =item Return Value: $rs
 161
 162 =back
 163
 164 The resultset constructor. Takes a source object (usually a
 165 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 166 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 167 executed as needed by the other methods.
 168
 169 Generally you won't need to construct a resultset manually.  You'll
 170 automatically get one from e.g. a L</search> called in scalar context:
 171
 172   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 173
 174 IMPORTANT: If called on an object, proxies to new_result instead so
 175
 176   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 177
 178 will return a CD object, not a ResultSet.
 179
 180 =cut
 181
 182 sub new {
 183   my $class = shift;
 184   return $class->new_result(@_) if ref $class;
 185
 186   my ($source, $attrs) = @_;
 187   $source = $source->handle
 188     unless $source->isa('DBIx::Class::ResultSourceHandle');
 189   $attrs = { %{$attrs||{}} };
 190
 191   if ($attrs->{page}) {
 192     $attrs->{rows} ||= 10;
 193   }
 194
 195   $attrs->{alias} ||= 'me';
 196
 197   # Creation of {} and bless separated to mitigate RH perl bug
 198   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 199   my $self = {
 200     _source_handle => $source,
 201     cond => $attrs->{where},
 202     pager => undef,
 203     attrs => $attrs
 204   };
 205
 206   bless $self, $class;
 207
 208   $self->result_class(
 209     $attrs->{result_class} || $source->resolve->result_class
 210   );
 211
 212   return $self;
 213 }
 214
 215 =head2 search
 216
 217 =over 4
 218
 219 =item Arguments: $cond, \%attrs?
 220
 221 =item Return Value: $resultset (scalar context), @row_objs (list context)
 222
 223 =back
 224
 225   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 226   my $new_rs = $cd_rs->search({ year => 2005 });
 227
 228   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 229                  # year = 2005 OR year = 2004
 230
 231 If you need to pass in additional attributes but no additional condition,
 232 call it as C<search(undef, \%attrs)>.
 233
 234   # "SELECT name, artistid FROM $artist_table"
 235   my @all_artists = $schema->resultset('Artist')->search(undef, {
 236     columns => [qw/name artistid/],
 237   });
 238
 239 For a list of attributes that can be passed to C<search>, see
 240 L</ATTRIBUTES>. For more examples of using this function, see
 241 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 242 documentation for the first argument, see L<SQL::Abstract>.
 243
 244 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 245
 246 =cut
 247
 248 sub search {
 249   my $self = shift;
 250   my $rs = $self->search_rs( @_ );
 251   return (wantarray ? $rs->all : $rs);
 252 }
 253
 254 =head2 search_rs
 255
 256 =over 4
 257
 258 =item Arguments: $cond, \%attrs?
 259
 260 =item Return Value: $resultset
 261
 262 =back
 263
 264 This method does the same exact thing as search() except it will
 265 always return a resultset, even in list context.
 266
 267 =cut
 268
 269 sub search_rs {
 270   my $self = shift;
 271
 272   # Special-case handling for (undef, undef).
 273   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 274     pop(@_); pop(@_);
 275   }
 276
 277   my $attrs = {};
 278   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 279   my $our_attrs = { %{$self->{attrs}} };
 280   my $having = delete $our_attrs->{having};
 281   my $where = delete $our_attrs->{where};
 282
 283   my $rows;
 284
 285   my %safe = (alias => 1, cache => 1);
 286
 287   unless (
 288     (@_ && defined($_[0])) # @_ == () or (undef)
 289     ||
 290     (keys %$attrs # empty attrs or only 'safe' attrs
 291     && List::Util::first { !$safe{$_} } keys %$attrs)
 292   ) {
 293     # no search, effectively just a clone
 294     $rows = $self->get_cache;
 295   }
 296
 297   # reset the selector list
 298   if (List::Util::first { exists $attrs->{$_} } qw{columns select as}) {
 299      delete @{$our_attrs}{qw{select as columns +select +as +columns include_columns}};
 300   }
 301
 302   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 303
 304   # merge new attrs into inherited
 305   foreach my $key (qw/join prefetch +select +as +columns include_columns bind/) {
 306     next unless exists $attrs->{$key};
 307     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 308   }
 309
 310   my $cond = (@_
 311     ? (
 312         (@_ == 1 || ref $_[0] eq "HASH")
 313           ? (
 314               (ref $_[0] eq 'HASH')
 315                 ? (
 316                     (keys %{ $_[0] }  > 0)
 317                       ? shift
 318                       : undef
 319                    )
 320                 :  shift
 321              )
 322           : (
 323               (@_ % 2)
 324                 ? $self->throw_exception("Odd number of arguments to search")
 325                 : {@_}
 326              )
 327       )
 328     : undef
 329   );
 330
 331   if (defined $where) {
 332     $new_attrs->{where} = (
 333       defined $new_attrs->{where}
 334         ? { '-and' => [
 335               map {
 336                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 337               } $where, $new_attrs->{where}
 338             ]
 339           }
 340         : $where);
 341   }
 342
 343   if (defined $cond) {
 344     $new_attrs->{where} = (
 345       defined $new_attrs->{where}
 346         ? { '-and' => [
 347               map {
 348                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 349               } $cond, $new_attrs->{where}
 350             ]
 351           }
 352         : $cond);
 353   }
 354
 355   if (defined $having) {
 356     $new_attrs->{having} = (
 357       defined $new_attrs->{having}
 358         ? { '-and' => [
 359               map {
 360                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 361               } $having, $new_attrs->{having}
 362             ]
 363           }
 364         : $having);
 365   }
 366
 367   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 368
 369   $rs->set_cache($rows) if ($rows);
 370
 371   return $rs;
 372 }
 373
 374 =head2 search_literal
 375
 376 =over 4
 377
 378 =item Arguments: $sql_fragment, @bind_values
 379
 380 =item Return Value: $resultset (scalar context), @row_objs (list context)
 381
 382 =back
 383
 384   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 385   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 386
 387 Pass a literal chunk of SQL to be added to the conditional part of the
 388 resultset query.
 389
 390 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 391 only be used in that context. C<search_literal> is a convenience method.
 392 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 393 columns are bound correctly, use C<search>.
 394
 395 Example of how to use C<search> instead of C<search_literal>
 396
 397   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 398   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 399
 400
 401 See L<DBIx::Class::Manual::Cookbook/Searching> and
 402 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 403 require C<search_literal>.
 404
 405 =cut
 406
 407 sub search_literal {
 408   my ($self, $sql, @bind) = @_;
 409   my $attr;
 410   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 411     $attr = pop @bind;
 412   }
 413   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 414 }
 415
 416 =head2 find
 417
 418 =over 4
 419
 420 =item Arguments: @values | \%cols, \%attrs?
 421
 422 =item Return Value: $row_object | undef
 423
 424 =back
 425
 426 Finds a row based on its primary key or unique constraint. For example, to find
 427 a row by its primary key:
 428
 429   my $cd = $schema->resultset('CD')->find(5);
 430
 431 You can also find a row by a specific unique constraint using the C<key>
 432 attribute. For example:
 433
 434   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 435     key => 'cd_artist_title'
 436   });
 437
 438 Additionally, you can specify the columns explicitly by name:
 439
 440   my $cd = $schema->resultset('CD')->find(
 441     {
 442       artist => 'Massive Attack',
 443       title  => 'Mezzanine',
 444     },
 445     { key => 'cd_artist_title' }
 446   );
 447
 448 If the C<key> is specified as C<primary>, it searches only on the primary key.
 449
 450 If no C<key> is specified, it searches on all unique constraints defined on the
 451 source for which column data is provided, including the primary key.
 452
 453 If your table does not have a primary key, you B<must> provide a value for the
 454 C<key> attribute matching one of the unique constraints on the source.
 455
 456 In addition to C<key>, L</find> recognizes and applies standard
 457 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 458
 459 Note: If your query does not return only one row, a warning is generated:
 460
 461   Query returned more than one row
 462
 463 See also L</find_or_create> and L</update_or_create>. For information on how to
 464 declare unique constraints, see
 465 L<DBIx::Class::ResultSource/add_unique_constraint>.
 466
 467 =cut
 468
 469 sub find {
 470   my $self = shift;
 471   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 472
 473   # Default to the primary key, but allow a specific key
 474   my @cols = exists $attrs->{key}
 475     ? $self->result_source->unique_constraint_columns($attrs->{key})
 476     : $self->result_source->primary_columns;
 477   $self->throw_exception(
 478     "Can't find unless a primary key is defined or unique constraint is specified"
 479   ) unless @cols;
 480
 481   # Parse out a hashref from input
 482   my $input_query;
 483   if (ref $_[0] eq 'HASH') {
 484     $input_query = { %{$_[0]} };
 485   }
 486   elsif (@_ == @cols) {
 487     $input_query = {};
 488     @{$input_query}{@cols} = @_;
 489   }
 490   else {
 491     # Compatibility: Allow e.g. find(id => $value)
 492     carp "Find by key => value deprecated; please use a hashref instead";
 493     $input_query = {@_};
 494   }
 495
 496   my (%related, $info);
 497
 498   KEY: foreach my $key (keys %$input_query) {
 499     if (ref($input_query->{$key})
 500         && ($info = $self->result_source->relationship_info($key))) {
 501       my $val = delete $input_query->{$key};
 502       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 503       my $rel_q = $self->result_source->_resolve_condition(
 504                     $info->{cond}, $val, $key
 505                   );
 506       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 507       @related{keys %$rel_q} = values %$rel_q;
 508     }
 509   }
 510   if (my @keys = keys %related) {
 511     @{$input_query}{@keys} = values %related;
 512   }
 513
 514
 515   # Build the final query: Default to the disjunction of the unique queries,
 516   # but allow the input query in case the ResultSet defines the query or the
 517   # user is abusing find
 518   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 519   my $query;
 520   if (exists $attrs->{key}) {
 521     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 522     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 523     $query = $self->_add_alias($unique_query, $alias);
 524   }
 525   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 526     # This means that we got here after a merger of relationship conditions
 527     # in ::Relationship::Base::search_related (the row method), and furthermore
 528     # the relationship is of the 'single' type. This means that the condition
 529     # provided by the relationship (already attached to $self) is sufficient,
 530     # as there can be only one row in the database that would satisfy the
 531     # relationship
 532   }
 533   else {
 534     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 535     $query = @unique_queries
 536       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 537       : $self->_add_alias($input_query, $alias);
 538   }
 539
 540   # Run the query, passing the result_class since it should propagate for find
 541   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 542   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 543     my $row = $rs->next;
 544     carp "Query returned more than one row" if $rs->next;
 545     return $row;
 546   }
 547   else {
 548     return $rs->single;
 549   }
 550 }
 551
 552 # _add_alias
 553 #
 554 # Add the specified alias to the specified query hash. A copy is made so the
 555 # original query is not modified.
 556
 557 sub _add_alias {
 558   my ($self, $query, $alias) = @_;
 559
 560   my %aliased = %$query;
 561   foreach my $col (grep { ! m/\./ } keys %aliased) {
 562     $aliased{"$alias.$col"} = delete $aliased{$col};
 563   }
 564
 565   return \%aliased;
 566 }
 567
 568 # _unique_queries
 569 #
 570 # Build a list of queries which satisfy unique constraints.
 571
 572 sub _unique_queries {
 573   my ($self, $query, $attrs) = @_;
 574
 575   my @constraint_names = exists $attrs->{key}
 576     ? ($attrs->{key})
 577     : $self->result_source->unique_constraint_names;
 578
 579   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 580   my $num_where = scalar keys %$where;
 581
 582   my (@unique_queries, %seen_column_combinations);
 583   foreach my $name (@constraint_names) {
 584     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 585
 586     my $constraint_sig = join "\x00", sort @constraint_cols;
 587     next if $seen_column_combinations{$constraint_sig}++;
 588
 589     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 590
 591     my $num_cols = scalar @constraint_cols;
 592     my $num_query = scalar keys %$unique_query;
 593
 594     my $total = $num_query + $num_where;
 595     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 596       # The query is either unique on its own or is unique in combination with
 597       # the existing where clause
 598       push @unique_queries, $unique_query;
 599     }
 600   }
 601
 602   return @unique_queries;
 603 }
 604
 605 # _build_unique_query
 606 #
 607 # Constrain the specified query hash based on the specified column names.
 608
 609 sub _build_unique_query {
 610   my ($self, $query, $unique_cols) = @_;
 611
 612   return {
 613     map  { $_ => $query->{$_} }
 614     grep { exists $query->{$_} }
 615       @$unique_cols
 616   };
 617 }
 618
 619 =head2 search_related
 620
 621 =over 4
 622
 623 =item Arguments: $rel, $cond, \%attrs?
 624
 625 =item Return Value: $new_resultset
 626
 627 =back
 628
 629   $new_rs = $cd_rs->search_related('artist', {
 630     name => 'Emo-R-Us',
 631   });
 632
 633 Searches the specified relationship, optionally specifying a condition and
 634 attributes for matching records. See L</ATTRIBUTES> for more information.
 635
 636 =cut
 637
 638 sub search_related {
 639   return shift->related_resultset(shift)->search(@_);
 640 }
 641
 642 =head2 search_related_rs
 643
 644 This method works exactly the same as search_related, except that
 645 it guarantees a resultset, even in list context.
 646
 647 =cut
 648
 649 sub search_related_rs {
 650   return shift->related_resultset(shift)->search_rs(@_);
 651 }
 652
 653 =head2 cursor
 654
 655 =over 4
 656
 657 =item Arguments: none
 658
 659 =item Return Value: $cursor
 660
 661 =back
 662
 663 Returns a storage-driven cursor to the given resultset. See
 664 L<DBIx::Class::Cursor> for more information.
 665
 666 =cut
 667
 668 sub cursor {
 669   my ($self) = @_;
 670
 671   my $attrs = $self->_resolved_attrs_copy;
 672
 673   return $self->{cursor}
 674     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 675           $attrs->{where},$attrs);
 676 }
 677
 678 =head2 single
 679
 680 =over 4
 681
 682 =item Arguments: $cond?
 683
 684 =item Return Value: $row_object?
 685
 686 =back
 687
 688   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 689
 690 Inflates the first result without creating a cursor if the resultset has
 691 any records in it; if not returns nothing. Used by L</find> as a lean version of
 692 L</search>.
 693
 694 While this method can take an optional search condition (just like L</search>)
 695 being a fast-code-path it does not recognize search attributes. If you need to
 696 add extra joins or similar, call L</search> and then chain-call L</single> on the
 697 L<DBIx::Class::ResultSet> returned.
 698
 699 =over
 700
 701 =item B<Note>
 702
 703 As of 0.08100, this method enforces the assumption that the preceding
 704 query returns only one row. If more than one row is returned, you will receive
 705 a warning:
 706
 707   Query returned more than one row
 708
 709 In this case, you should be using L</next> or L</find> instead, or if you really
 710 know what you are doing, use the L</rows> attribute to explicitly limit the size
 711 of the resultset.
 712
 713 This method will also throw an exception if it is called on a resultset prefetching
 714 has_many, as such a prefetch implies fetching multiple rows from the database in
 715 order to assemble the resulting object.
 716
 717 =back
 718
 719 =cut
 720
 721 sub single {
 722   my ($self, $where) = @_;
 723   if(@_ > 2) {
 724       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 725   }
 726
 727   my $attrs = $self->_resolved_attrs_copy;
 728
 729   if (keys %{$attrs->{collapse}}) {
 730     $self->throw_exception(
 731       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 732     );
 733   }
 734
 735   if ($where) {
 736     if (defined $attrs->{where}) {
 737       $attrs->{where} = {
 738         '-and' =>
 739             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 740                $where, delete $attrs->{where} ]
 741       };
 742     } else {
 743       $attrs->{where} = $where;
 744     }
 745   }
 746
 747 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 748 #  unless ($self->_is_unique_query($attrs->{where})) {
 749 #    carp "Query not guaranteed to return a single row"
 750 #      . "; please declare your unique constraints or use search instead";
 751 #  }
 752
 753   my @data = $self->result_source->storage->select_single(
 754     $attrs->{from}, $attrs->{select},
 755     $attrs->{where}, $attrs
 756   );
 757
 758   return (@data ? ($self->_construct_object(@data))[0] : undef);
 759 }
 760
 761
 762 # _is_unique_query
 763 #
 764 # Try to determine if the specified query is guaranteed to be unique, based on
 765 # the declared unique constraints.
 766
 767 sub _is_unique_query {
 768   my ($self, $query) = @_;
 769
 770   my $collapsed = $self->_collapse_query($query);
 771   my $alias = $self->{attrs}{alias};
 772
 773   foreach my $name ($self->result_source->unique_constraint_names) {
 774     my @unique_cols = map {
 775       "$alias.$_"
 776     } $self->result_source->unique_constraint_columns($name);
 777
 778     # Count the values for each unique column
 779     my %seen = map { $_ => 0 } @unique_cols;
 780
 781     foreach my $key (keys %$collapsed) {
 782       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 783       next unless exists $seen{$aliased};  # Additional constraints are okay
 784       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 785     }
 786
 787     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 788     return 1 unless grep { $_ != 1 } values %seen;
 789   }
 790
 791   return 0;
 792 }
 793
 794 # _collapse_query
 795 #
 796 # Recursively collapse the query, accumulating values for each column.
 797
 798 sub _collapse_query {
 799   my ($self, $query, $collapsed) = @_;
 800
 801   $collapsed ||= {};
 802
 803   if (ref $query eq 'ARRAY') {
 804     foreach my $subquery (@$query) {
 805       next unless ref $subquery;  # -or
 806       $collapsed = $self->_collapse_query($subquery, $collapsed);
 807     }
 808   }
 809   elsif (ref $query eq 'HASH') {
 810     if (keys %$query and (keys %$query)[0] eq '-and') {
 811       foreach my $subquery (@{$query->{-and}}) {
 812         $collapsed = $self->_collapse_query($subquery, $collapsed);
 813       }
 814     }
 815     else {
 816       foreach my $col (keys %$query) {
 817         my $value = $query->{$col};
 818         $collapsed->{$col}{$value}++;
 819       }
 820     }
 821   }
 822
 823   return $collapsed;
 824 }
 825
 826 =head2 get_column
 827
 828 =over 4
 829
 830 =item Arguments: $cond?
 831
 832 =item Return Value: $resultsetcolumn
 833
 834 =back
 835
 836   my $max_length = $rs->get_column('length')->max;
 837
 838 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 839
 840 =cut
 841
 842 sub get_column {
 843   my ($self, $column) = @_;
 844   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 845   return $new;
 846 }
 847
 848 =head2 search_like
 849
 850 =over 4
 851
 852 =item Arguments: $cond, \%attrs?
 853
 854 =item Return Value: $resultset (scalar context), @row_objs (list context)
 855
 856 =back
 857
 858   # WHERE title LIKE '%blue%'
 859   $cd_rs = $rs->search_like({ title => '%blue%'});
 860
 861 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 862 that this is simply a convenience method retained for ex Class::DBI users.
 863 You most likely want to use L</search> with specific operators.
 864
 865 For more information, see L<DBIx::Class::Manual::Cookbook>.
 866
 867 This method is deprecated and will be removed in 0.09. Use L</search()>
 868 instead. An example conversion is:
 869
 870   ->search_like({ foo => 'bar' });
 871
 872   # Becomes
 873
 874   ->search({ foo => { like => 'bar' } });
 875
 876 =cut
 877
 878 sub search_like {
 879   my $class = shift;
 880   carp (
 881     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 882    .' Instead use ->search({ x => { -like => "y%" } })'
 883    .' (note the outer pair of {}s - they are important!)'
 884   );
 885   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 886   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 887   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 888   return $class->search($query, { %$attrs });
 889 }
 890
 891 =head2 slice
 892
 893 =over 4
 894
 895 =item Arguments: $first, $last
 896
 897 =item Return Value: $resultset (scalar context), @row_objs (list context)
 898
 899 =back
 900
 901 Returns a resultset or object list representing a subset of elements from the
 902 resultset slice is called on. Indexes are from 0, i.e., to get the first
 903 three records, call:
 904
 905   my ($one, $two, $three) = $rs->slice(0, 2);
 906
 907 =cut
 908
 909 sub slice {
 910   my ($self, $min, $max) = @_;
 911   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 912   $attrs->{offset} = $self->{attrs}{offset} || 0;
 913   $attrs->{offset} += $min;
 914   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 915   return $self->search(undef(), $attrs);
 916   #my $slice = (ref $self)->new($self->result_source, $attrs);
 917   #return (wantarray ? $slice->all : $slice);
 918 }
 919
 920 =head2 next
 921
 922 =over 4
 923
 924 =item Arguments: none
 925
 926 =item Return Value: $result?
 927
 928 =back
 929
 930 Returns the next element in the resultset (C<undef> is there is none).
 931
 932 Can be used to efficiently iterate over records in the resultset:
 933
 934   my $rs = $schema->resultset('CD')->search;
 935   while (my $cd = $rs->next) {
 936     print $cd->title;
 937   }
 938
 939 Note that you need to store the resultset object, and call C<next> on it.
 940 Calling C<< resultset('Table')->next >> repeatedly will always return the
 941 first record from the resultset.
 942
 943 =cut
 944
 945 sub next {
 946   my ($self) = @_;
 947   if (my $cache = $self->get_cache) {
 948     $self->{all_cache_position} ||= 0;
 949     return $cache->[$self->{all_cache_position}++];
 950   }
 951   if ($self->{attrs}{cache}) {
 952     $self->{all_cache_position} = 1;
 953     return ($self->all)[0];
 954   }
 955   if ($self->{stashed_objects}) {
 956     my $obj = shift(@{$self->{stashed_objects}});
 957     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 958     return $obj;
 959   }
 960   my @row = (
 961     exists $self->{stashed_row}
 962       ? @{delete $self->{stashed_row}}
 963       : $self->cursor->next
 964   );
 965   return undef unless (@row);
 966   my ($row, @more) = $self->_construct_object(@row);
 967   $self->{stashed_objects} = \@more if @more;
 968   return $row;
 969 }
 970
 971 sub _construct_object {
 972   my ($self, @row) = @_;
 973
 974   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 975     or return ();
 976   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 977   @new = $self->{_attrs}{record_filter}->(@new)
 978     if exists $self->{_attrs}{record_filter};
 979   return @new;
 980 }
 981
 982 sub _collapse_result {
 983   my ($self, $as_proto, $row) = @_;
 984
 985   my @copy = @$row;
 986
 987   # 'foo'         => [ undef, 'foo' ]
 988   # 'foo.bar'     => [ 'foo', 'bar' ]
 989   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 990
 991   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 992
 993   my %collapse = %{$self->{_attrs}{collapse}||{}};
 994
 995   my @pri_index;
 996
 997   # if we're doing collapsing (has_many prefetch) we need to grab records
 998   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 999   # we know we don't have to bother.
1000
1001   # the reason for not using the collapse stuff directly is because if you
1002   # had for e.g. two artists in a row with no cds, the collapse info for
1003   # both would be NULL (undef) so you'd lose the second artist
1004
1005   # store just the index so we can check the array positions from the row
1006   # without having to contruct the full hash
1007
1008   if (keys %collapse) {
1009     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1010     foreach my $i (0 .. $#construct_as) {
1011       next if defined($construct_as[$i][0]); # only self table
1012       if (delete $pri{$construct_as[$i][1]}) {
1013         push(@pri_index, $i);
1014       }
1015       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1016     }
1017   }
1018
1019   # no need to do an if, it'll be empty if @pri_index is empty anyway
1020
1021   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1022
1023   my @const_rows;
1024
1025   do { # no need to check anything at the front, we always want the first row
1026
1027     my %const;
1028
1029     foreach my $this_as (@construct_as) {
1030       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1031     }
1032
1033     push(@const_rows, \%const);
1034
1035   } until ( # no pri_index => no collapse => drop straight out
1036       !@pri_index
1037     or
1038       do { # get another row, stash it, drop out if different PK
1039
1040         @copy = $self->cursor->next;
1041         $self->{stashed_row} = \@copy;
1042
1043         # last thing in do block, counts as true if anything doesn't match
1044
1045         # check xor defined first for NULL vs. NOT NULL then if one is
1046         # defined the other must be so check string equality
1047
1048         grep {
1049           (defined $pri_vals{$_} ^ defined $copy[$_])
1050           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1051         } @pri_index;
1052       }
1053   );
1054
1055   my $alias = $self->{attrs}{alias};
1056   my $info = [];
1057
1058   my %collapse_pos;
1059
1060   my @const_keys;
1061
1062   foreach my $const (@const_rows) {
1063     scalar @const_keys or do {
1064       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1065     };
1066     foreach my $key (@const_keys) {
1067       if (length $key) {
1068         my $target = $info;
1069         my @parts = split(/\./, $key);
1070         my $cur = '';
1071         my $data = $const->{$key};
1072         foreach my $p (@parts) {
1073           $target = $target->[1]->{$p} ||= [];
1074           $cur .= ".${p}";
1075           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1076             # collapsing at this point and on final part
1077             my $pos = $collapse_pos{$cur};
1078             CK: foreach my $ck (@ckey) {
1079               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1080                 $collapse_pos{$cur} = $data;
1081                 delete @collapse_pos{ # clear all positioning for sub-entries
1082                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1083                 };
1084                 push(@$target, []);
1085                 last CK;
1086               }
1087             }
1088           }
1089           if (exists $collapse{$cur}) {
1090             $target = $target->[-1];
1091           }
1092         }
1093         $target->[0] = $data;
1094       } else {
1095         $info->[0] = $const->{$key};
1096       }
1097     }
1098   }
1099
1100   return $info;
1101 }
1102
1103 =head2 result_source
1104
1105 =over 4
1106
1107 =item Arguments: $result_source?
1108
1109 =item Return Value: $result_source
1110
1111 =back
1112
1113 An accessor for the primary ResultSource object from which this ResultSet
1114 is derived.
1115
1116 =head2 result_class
1117
1118 =over 4
1119
1120 =item Arguments: $result_class?
1121
1122 =item Return Value: $result_class
1123
1124 =back
1125
1126 An accessor for the class to use when creating row objects. Defaults to
1127 C<< result_source->result_class >> - which in most cases is the name of the
1128 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1129
1130 Note that changing the result_class will also remove any components
1131 that were originally loaded in the source class via
1132 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1133 in the original source class will not run.
1134
1135 =cut
1136
1137 sub result_class {
1138   my ($self, $result_class) = @_;
1139   if ($result_class) {
1140     unless (ref $result_class) { # don't fire this for an object
1141       $self->ensure_class_loaded($result_class);
1142     }
1143     $self->_result_class($result_class);
1144     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1145     # permit the user to set result class on one result set only; it only
1146     # chains if provided to search()
1147     #$self->{attrs}{result_class} = $result_class if ref $self;
1148   }
1149   $self->_result_class;
1150 }
1151
1152 =head2 count
1153
1154 =over 4
1155
1156 =item Arguments: $cond, \%attrs??
1157
1158 =item Return Value: $count
1159
1160 =back
1161
1162 Performs an SQL C<COUNT> with the same query as the resultset was built
1163 with to find the number of elements. Passing arguments is equivalent to
1164 C<< $rs->search ($cond, \%attrs)->count >>
1165
1166 =cut
1167
1168 sub count {
1169   my $self = shift;
1170   return $self->search(@_)->count if @_ and defined $_[0];
1171   return scalar @{ $self->get_cache } if $self->get_cache;
1172
1173   my $attrs = $self->_resolved_attrs_copy;
1174
1175   # this is a little optimization - it is faster to do the limit
1176   # adjustments in software, instead of a subquery
1177   my $rows = delete $attrs->{rows};
1178   my $offset = delete $attrs->{offset};
1179
1180   my $crs;
1181   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1182     $crs = $self->_count_subq_rs ($attrs);
1183   }
1184   else {
1185     $crs = $self->_count_rs ($attrs);
1186   }
1187   my $count = $crs->next;
1188
1189   $count -= $offset if $offset;
1190   $count = $rows if $rows and $rows < $count;
1191   $count = 0 if ($count < 0);
1192
1193   return $count;
1194 }
1195
1196 =head2 count_rs
1197
1198 =over 4
1199
1200 =item Arguments: $cond, \%attrs??
1201
1202 =item Return Value: $count_rs
1203
1204 =back
1205
1206 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1207 This can be very handy for subqueries:
1208
1209   ->search( { amount => $some_rs->count_rs->as_query } )
1210
1211 As with regular resultsets the SQL query will be executed only after
1212 the resultset is accessed via L</next> or L</all>. That would return
1213 the same single value obtainable via L</count>.
1214
1215 =cut
1216
1217 sub count_rs {
1218   my $self = shift;
1219   return $self->search(@_)->count_rs if @_;
1220
1221   # this may look like a lack of abstraction (count() does about the same)
1222   # but in fact an _rs *must* use a subquery for the limits, as the
1223   # software based limiting can not be ported if this $rs is to be used
1224   # in a subquery itself (i.e. ->as_query)
1225   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1226     return $self->_count_subq_rs;
1227   }
1228   else {
1229     return $self->_count_rs;
1230   }
1231 }
1232
1233 #
1234 # returns a ResultSetColumn object tied to the count query
1235 #
1236 sub _count_rs {
1237   my ($self, $attrs) = @_;
1238
1239   my $rsrc = $self->result_source;
1240   $attrs ||= $self->_resolved_attrs;
1241
1242   my $tmp_attrs = { %$attrs };
1243   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1244   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1251
1252   return $tmp_rs;
1253 }
1254
1255 #
1256 # same as above but uses a subquery
1257 #
1258 sub _count_subq_rs {
1259   my ($self, $attrs) = @_;
1260
1261   my $rsrc = $self->result_source;
1262   $attrs ||= $self->_resolved_attrs;
1263
1264   my $sub_attrs = { %$attrs };
1265   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1266   delete @{$sub_attrs}{qw/collapse select _prefetch_select as order_by for/};
1267
1268   # if we multi-prefetch we group_by primary keys only as this is what we would
1269   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1270   if ( keys %{$attrs->{collapse}}  ) {
1271     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1272   }
1273
1274   # Calculate subquery selector
1275   if (my $g = $sub_attrs->{group_by}) {
1276
1277     # necessary as the group_by may refer to aliased functions
1278     my $sel_index;
1279     for my $sel (@{$attrs->{select}}) {
1280       $sel_index->{$sel->{-as}} = $sel
1281         if (ref $sel eq 'HASH' and $sel->{-as});
1282     }
1283
1284     for my $g_part (@$g) {
1285       push @{$sub_attrs->{select}}, $sel_index->{$g_part} || $g_part;
1286     }
1287   }
1288   else {
1289     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1290     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1291   }
1292
1293   return $rsrc->resultset_class
1294                ->new ($rsrc, $sub_attrs)
1295                 ->as_subselect_rs
1296                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1297                   ->get_column ('count');
1298 }
1299
1300 sub _bool {
1301   return 1;
1302 }
1303
1304 =head2 count_literal
1305
1306 =over 4
1307
1308 =item Arguments: $sql_fragment, @bind_values
1309
1310 =item Return Value: $count
1311
1312 =back
1313
1314 Counts the results in a literal query. Equivalent to calling L</search_literal>
1315 with the passed arguments, then L</count>.
1316
1317 =cut
1318
1319 sub count_literal { shift->search_literal(@_)->count; }
1320
1321 =head2 all
1322
1323 =over 4
1324
1325 =item Arguments: none
1326
1327 =item Return Value: @objects
1328
1329 =back
1330
1331 Returns all elements in the resultset. Called implicitly if the resultset
1332 is returned in list context.
1333
1334 =cut
1335
1336 sub all {
1337   my $self = shift;
1338   if(@_) {
1339       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1340   }
1341
1342   return @{ $self->get_cache } if $self->get_cache;
1343
1344   my @obj;
1345
1346   if (keys %{$self->_resolved_attrs->{collapse}}) {
1347     # Using $self->cursor->all is really just an optimisation.
1348     # If we're collapsing has_many prefetches it probably makes
1349     # very little difference, and this is cleaner than hacking
1350     # _construct_object to survive the approach
1351     $self->cursor->reset;
1352     my @row = $self->cursor->next;
1353     while (@row) {
1354       push(@obj, $self->_construct_object(@row));
1355       @row = (exists $self->{stashed_row}
1356                ? @{delete $self->{stashed_row}}
1357                : $self->cursor->next);
1358     }
1359   } else {
1360     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1361   }
1362
1363   $self->set_cache(\@obj) if $self->{attrs}{cache};
1364
1365   return @obj;
1366 }
1367
1368 =head2 reset
1369
1370 =over 4
1371
1372 =item Arguments: none
1373
1374 =item Return Value: $self
1375
1376 =back
1377
1378 Resets the resultset's cursor, so you can iterate through the elements again.
1379 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1380 another query.
1381
1382 =cut
1383
1384 sub reset {
1385   my ($self) = @_;
1386   delete $self->{_attrs} if exists $self->{_attrs};
1387   $self->{all_cache_position} = 0;
1388   $self->cursor->reset;
1389   return $self;
1390 }
1391
1392 =head2 first
1393
1394 =over 4
1395
1396 =item Arguments: none
1397
1398 =item Return Value: $object?
1399
1400 =back
1401
1402 Resets the resultset and returns an object for the first result (if the
1403 resultset returns anything).
1404
1405 =cut
1406
1407 sub first {
1408   return $_[0]->reset->next;
1409 }
1410
1411
1412 # _rs_update_delete
1413 #
1414 # Determines whether and what type of subquery is required for the $rs operation.
1415 # If grouping is necessary either supplies its own, or verifies the current one
1416 # After all is done delegates to the proper storage method.
1417
1418 sub _rs_update_delete {
1419   my ($self, $op, $values) = @_;
1420
1421   my $rsrc = $self->result_source;
1422
1423   # if a condition exists we need to strip all table qualifiers
1424   # if this is not possible we'll force a subquery below
1425   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1426
1427   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1428   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/rows offset/);
1429
1430   if ($needs_group_by_subq or $needs_subq) {
1431
1432     # make a new $rs selecting only the PKs (that's all we really need)
1433     my $attrs = $self->_resolved_attrs_copy;
1434
1435
1436     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_select as/;
1437     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1438
1439     if ($needs_group_by_subq) {
1440       # make sure no group_by was supplied, or if there is one - make sure it matches
1441       # the columns compiled above perfectly. Anything else can not be sanely executed
1442       # on most databases so croak right then and there
1443
1444       if (my $g = $attrs->{group_by}) {
1445         my @current_group_by = map
1446           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1447           @$g
1448         ;
1449
1450         if (
1451           join ("\x00", sort @current_group_by)
1452             ne
1453           join ("\x00", sort @{$attrs->{columns}} )
1454         ) {
1455           $self->throw_exception (
1456             "You have just attempted a $op operation on a resultset which does group_by"
1457             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1458             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1459             . ' kind of queries. Please retry the operation with a modified group_by or'
1460             . ' without using one at all.'
1461           );
1462         }
1463       }
1464       else {
1465         $attrs->{group_by} = $attrs->{columns};
1466       }
1467     }
1468
1469     my $subrs = (ref $self)->new($rsrc, $attrs);
1470     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1471   }
1472   else {
1473     return $rsrc->storage->$op(
1474       $rsrc,
1475       $op eq 'update' ? $values : (),
1476       $cond,
1477     );
1478   }
1479 }
1480
1481 =head2 update
1482
1483 =over 4
1484
1485 =item Arguments: \%values
1486
1487 =item Return Value: $storage_rv
1488
1489 =back
1490
1491 Sets the specified columns in the resultset to the supplied values in a
1492 single query. Return value will be true if the update succeeded or false
1493 if no records were updated; exact type of success value is storage-dependent.
1494
1495 =cut
1496
1497 sub update {
1498   my ($self, $values) = @_;
1499   $self->throw_exception('Values for update must be a hash')
1500     unless ref $values eq 'HASH';
1501
1502   return $self->_rs_update_delete ('update', $values);
1503 }
1504
1505 =head2 update_all
1506
1507 =over 4
1508
1509 =item Arguments: \%values
1510
1511 =item Return Value: 1
1512
1513 =back
1514
1515 Fetches all objects and updates them one at a time. Note that C<update_all>
1516 will run DBIC cascade triggers, while L</update> will not.
1517
1518 =cut
1519
1520 sub update_all {
1521   my ($self, $values) = @_;
1522   $self->throw_exception('Values for update_all must be a hash')
1523     unless ref $values eq 'HASH';
1524
1525   my $guard = $self->result_source->schema->txn_scope_guard;
1526   $_->update($values) for $self->all;
1527   $guard->commit;
1528   return 1;
1529 }
1530
1531 =head2 delete
1532
1533 =over 4
1534
1535 =item Arguments: none
1536
1537 =item Return Value: $storage_rv
1538
1539 =back
1540
1541 Deletes the contents of the resultset from its result source. Note that this
1542 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1543 to run. See also L<DBIx::Class::Row/delete>.
1544
1545 Return value will be the number of rows deleted; exact type of return value
1546 is storage-dependent.
1547
1548 =cut
1549
1550 sub delete {
1551   my $self = shift;
1552   $self->throw_exception('delete does not accept any arguments')
1553     if @_;
1554
1555   return $self->_rs_update_delete ('delete');
1556 }
1557
1558 =head2 delete_all
1559
1560 =over 4
1561
1562 =item Arguments: none
1563
1564 =item Return Value: 1
1565
1566 =back
1567
1568 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1569 will run DBIC cascade triggers, while L</delete> will not.
1570
1571 =cut
1572
1573 sub delete_all {
1574   my $self = shift;
1575   $self->throw_exception('delete_all does not accept any arguments')
1576     if @_;
1577
1578   my $guard = $self->result_source->schema->txn_scope_guard;
1579   $_->delete for $self->all;
1580   $guard->commit;
1581   return 1;
1582 }
1583
1584 =head2 populate
1585
1586 =over 4
1587
1588 =item Arguments: \@data;
1589
1590 =back
1591
1592 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1593 For the arrayref of hashrefs style each hashref should be a structure suitable
1594 forsubmitting to a $resultset->create(...) method.
1595
1596 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1597 to insert the data, as this is a faster method.
1598
1599 Otherwise, each set of data is inserted into the database using
1600 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1601 accumulated into an array. The array itself, or an array reference
1602 is returned depending on scalar or list context.
1603
1604 Example:  Assuming an Artist Class that has many CDs Classes relating:
1605
1606   my $Artist_rs = $schema->resultset("Artist");
1607
1608   ## Void Context Example
1609   $Artist_rs->populate([
1610      { artistid => 4, name => 'Manufactured Crap', cds => [
1611         { title => 'My First CD', year => 2006 },
1612         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1613       ],
1614      },
1615      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1616         { title => 'My parents sold me to a record company', year => 2005 },
1617         { title => 'Why Am I So Ugly?', year => 2006 },
1618         { title => 'I Got Surgery and am now Popular', year => 2007 }
1619       ],
1620      },
1621   ]);
1622
1623   ## Array Context Example
1624   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1625     { name => "Artist One"},
1626     { name => "Artist Two"},
1627     { name => "Artist Three", cds=> [
1628     { title => "First CD", year => 2007},
1629     { title => "Second CD", year => 2008},
1630   ]}
1631   ]);
1632
1633   print $ArtistOne->name; ## response is 'Artist One'
1634   print $ArtistThree->cds->count ## reponse is '2'
1635
1636 For the arrayref of arrayrefs style,  the first element should be a list of the
1637 fieldsnames to which the remaining elements are rows being inserted.  For
1638 example:
1639
1640   $Arstist_rs->populate([
1641     [qw/artistid name/],
1642     [100, 'A Formally Unknown Singer'],
1643     [101, 'A singer that jumped the shark two albums ago'],
1644     [102, 'An actually cool singer'],
1645   ]);
1646
1647 Please note an important effect on your data when choosing between void and
1648 wantarray context. Since void context goes straight to C<insert_bulk> in
1649 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1650 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1651 create primary keys for you, you will find that your PKs are empty.  In this
1652 case you will have to use the wantarray context in order to create those
1653 values.
1654
1655 =cut
1656
1657 sub populate {
1658   my $self = shift;
1659
1660   # cruft placed in standalone method
1661   my $data = $self->_normalize_populate_args(@_);
1662
1663   if(defined wantarray) {
1664     my @created;
1665     foreach my $item (@$data) {
1666       push(@created, $self->create($item));
1667     }
1668     return wantarray ? @created : \@created;
1669   } else {
1670     my $first = $data->[0];
1671
1672     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1673     # it relationship data
1674     my (@rels, @columns);
1675     for (keys %$first) {
1676       my $ref = ref $first->{$_};
1677       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1678         ? push @rels, $_
1679         : push @columns, $_
1680       ;
1681     }
1682
1683     my @pks = $self->result_source->primary_columns;
1684
1685     ## do the belongs_to relationships
1686     foreach my $index (0..$#$data) {
1687
1688       # delegate to create() for any dataset without primary keys with specified relationships
1689       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1690         for my $r (@rels) {
1691           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1692             my @ret = $self->populate($data);
1693             return;
1694           }
1695         }
1696       }
1697
1698       foreach my $rel (@rels) {
1699         next unless ref $data->[$index]->{$rel} eq "HASH";
1700         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1701         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1702         my $related = $result->result_source->_resolve_condition(
1703           $result->result_source->relationship_info($reverse)->{cond},
1704           $self,
1705           $result,
1706         );
1707
1708         delete $data->[$index]->{$rel};
1709         $data->[$index] = {%{$data->[$index]}, %$related};
1710
1711         push @columns, keys %$related if $index == 0;
1712       }
1713     }
1714
1715     ## inherit the data locked in the conditions of the resultset
1716     my ($rs_data) = $self->_merge_cond_with_data({});
1717     delete @{$rs_data}{@columns};
1718     my @inherit_cols = keys %$rs_data;
1719     my @inherit_data = values %$rs_data;
1720
1721     ## do bulk insert on current row
1722     $self->result_source->storage->insert_bulk(
1723       $self->result_source,
1724       [@columns, @inherit_cols],
1725       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1726     );
1727
1728     ## do the has_many relationships
1729     foreach my $item (@$data) {
1730
1731       foreach my $rel (@rels) {
1732         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1733
1734         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1735      || $self->throw_exception('Cannot find the relating object.');
1736
1737         my $child = $parent->$rel;
1738
1739         my $related = $child->result_source->_resolve_condition(
1740           $parent->result_source->relationship_info($rel)->{cond},
1741           $child,
1742           $parent,
1743         );
1744
1745         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1746         my @populate = map { {%$_, %$related} } @rows_to_add;
1747
1748         $child->populate( \@populate );
1749       }
1750     }
1751   }
1752 }
1753
1754
1755 # populate() argumnets went over several incarnations
1756 # What we ultimately support is AoH
1757 sub _normalize_populate_args {
1758   my ($self, $arg) = @_;
1759
1760   if (ref $arg eq 'ARRAY') {
1761     if (ref $arg->[0] eq 'HASH') {
1762       return $arg;
1763     }
1764     elsif (ref $arg->[0] eq 'ARRAY') {
1765       my @ret;
1766       my @colnames = @{$arg->[0]};
1767       foreach my $values (@{$arg}[1 .. $#$arg]) {
1768         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
1769       }
1770       return \@ret;
1771     }
1772   }
1773
1774   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
1775 }
1776
1777 =head2 pager
1778
1779 =over 4
1780
1781 =item Arguments: none
1782
1783 =item Return Value: $pager
1784
1785 =back
1786
1787 Return Value a L<Data::Page> object for the current resultset. Only makes
1788 sense for queries with a C<page> attribute.
1789
1790 To get the full count of entries for a paged resultset, call
1791 C<total_entries> on the L<Data::Page> object.
1792
1793 =cut
1794
1795 sub pager {
1796   my ($self) = @_;
1797
1798   return $self->{pager} if $self->{pager};
1799
1800   my $attrs = $self->{attrs};
1801   $self->throw_exception("Can't create pager for non-paged rs")
1802     unless $self->{attrs}{page};
1803   $attrs->{rows} ||= 10;
1804
1805   # throw away the paging flags and re-run the count (possibly
1806   # with a subselect) to get the real total count
1807   my $count_attrs = { %$attrs };
1808   delete $count_attrs->{$_} for qw/rows offset page pager/;
1809   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1810
1811   return $self->{pager} = Data::Page->new(
1812     $total_count,
1813     $attrs->{rows},
1814     $self->{attrs}{page}
1815   );
1816 }
1817
1818 =head2 page
1819
1820 =over 4
1821
1822 =item Arguments: $page_number
1823
1824 =item Return Value: $rs
1825
1826 =back
1827
1828 Returns a resultset for the $page_number page of the resultset on which page
1829 is called, where each page contains a number of rows equal to the 'rows'
1830 attribute set on the resultset (10 by default).
1831
1832 =cut
1833
1834 sub page {
1835   my ($self, $page) = @_;
1836   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1837 }
1838
1839 =head2 new_result
1840
1841 =over 4
1842
1843 =item Arguments: \%vals
1844
1845 =item Return Value: $rowobject
1846
1847 =back
1848
1849 Creates a new row object in the resultset's result class and returns
1850 it. The row is not inserted into the database at this point, call
1851 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1852 will tell you whether the row object has been inserted or not.
1853
1854 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1855
1856 =cut
1857
1858 sub new_result {
1859   my ($self, $values) = @_;
1860   $self->throw_exception( "new_result needs a hash" )
1861     unless (ref $values eq 'HASH');
1862
1863   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
1864
1865   my %new = (
1866     %$merged_cond,
1867     @$cols_from_relations
1868       ? (-cols_from_relations => $cols_from_relations)
1869       : (),
1870     -source_handle => $self->_source_handle,
1871     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1872   );
1873
1874   return $self->result_class->new(\%new);
1875 }
1876
1877 # _merge_cond_with_data
1878 #
1879 # Takes a simple hash of K/V data and returns its copy merged with the
1880 # condition already present on the resultset. Additionally returns an
1881 # arrayref of value/condition names, which were inferred from related
1882 # objects (this is needed for in-memory related objects)
1883 sub _merge_cond_with_data {
1884   my ($self, $data) = @_;
1885
1886   my (%new_data, @cols_from_relations);
1887
1888   my $alias = $self->{attrs}{alias};
1889
1890   if (! defined $self->{cond}) {
1891     # just massage $data below
1892   }
1893   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
1894     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1895     @cols_from_relations = keys %new_data;
1896   }
1897   elsif (ref $self->{cond} ne 'HASH') {
1898     $self->throw_exception(
1899       "Can't abstract implicit construct, resultset condition not a hash"
1900     );
1901   }
1902   else {
1903     # precendence must be given to passed values over values inherited from
1904     # the cond, so the order here is important.
1905     my $collapsed_cond = $self->_collapse_cond($self->{cond});
1906     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
1907
1908     while ( my($col, $value) = each %implied ) {
1909       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
1910         $new_data{$col} = $value->{'='};
1911         next;
1912       }
1913       $new_data{$col} = $value if $self->_is_deterministic_value($value);
1914     }
1915   }
1916
1917   %new_data = (
1918     %new_data,
1919     %{ $self->_remove_alias($data, $alias) },
1920   );
1921
1922   return (\%new_data, \@cols_from_relations);
1923 }
1924
1925 # _is_deterministic_value
1926 #
1927 # Make an effor to strip non-deterministic values from the condition,
1928 # to make sure new_result chokes less
1929
1930 sub _is_deterministic_value {
1931   my $self = shift;
1932   my $value = shift;
1933   my $ref_type = ref $value;
1934   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1935   return 1 if blessed $value;
1936   return 0;
1937 }
1938
1939 # _has_resolved_attr
1940 #
1941 # determines if the resultset defines at least one
1942 # of the attributes supplied
1943 #
1944 # used to determine if a subquery is neccessary
1945 #
1946 # supports some virtual attributes:
1947 #   -join
1948 #     This will scan for any joins being present on the resultset.
1949 #     It is not a mere key-search but a deep inspection of {from}
1950 #
1951
1952 sub _has_resolved_attr {
1953   my ($self, @attr_names) = @_;
1954
1955   my $attrs = $self->_resolved_attrs;
1956
1957   my %extra_checks;
1958
1959   for my $n (@attr_names) {
1960     if (grep { $n eq $_ } (qw/-join/) ) {
1961       $extra_checks{$n}++;
1962       next;
1963     }
1964
1965     my $attr =  $attrs->{$n};
1966
1967     next if not defined $attr;
1968
1969     if (ref $attr eq 'HASH') {
1970       return 1 if keys %$attr;
1971     }
1972     elsif (ref $attr eq 'ARRAY') {
1973       return 1 if @$attr;
1974     }
1975     else {
1976       return 1 if $attr;
1977     }
1978   }
1979
1980   # a resolved join is expressed as a multi-level from
1981   return 1 if (
1982     $extra_checks{-join}
1983       and
1984     ref $attrs->{from} eq 'ARRAY'
1985       and
1986     @{$attrs->{from}} > 1
1987   );
1988
1989   return 0;
1990 }
1991
1992 # _collapse_cond
1993 #
1994 # Recursively collapse the condition.
1995
1996 sub _collapse_cond {
1997   my ($self, $cond, $collapsed) = @_;
1998
1999   $collapsed ||= {};
2000
2001   if (ref $cond eq 'ARRAY') {
2002     foreach my $subcond (@$cond) {
2003       next unless ref $subcond;  # -or
2004       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2005     }
2006   }
2007   elsif (ref $cond eq 'HASH') {
2008     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2009       foreach my $subcond (@{$cond->{-and}}) {
2010         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2011       }
2012     }
2013     else {
2014       foreach my $col (keys %$cond) {
2015         my $value = $cond->{$col};
2016         $collapsed->{$col} = $value;
2017       }
2018     }
2019   }
2020
2021   return $collapsed;
2022 }
2023
2024 # _remove_alias
2025 #
2026 # Remove the specified alias from the specified query hash. A copy is made so
2027 # the original query is not modified.
2028
2029 sub _remove_alias {
2030   my ($self, $query, $alias) = @_;
2031
2032   my %orig = %{ $query || {} };
2033   my %unaliased;
2034
2035   foreach my $key (keys %orig) {
2036     if ($key !~ /\./) {
2037       $unaliased{$key} = $orig{$key};
2038       next;
2039     }
2040     $unaliased{$1} = $orig{$key}
2041       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2042   }
2043
2044   return \%unaliased;
2045 }
2046
2047 =head2 as_query
2048
2049 =over 4
2050
2051 =item Arguments: none
2052
2053 =item Return Value: \[ $sql, @bind ]
2054
2055 =back
2056
2057 Returns the SQL query and bind vars associated with the invocant.
2058
2059 This is generally used as the RHS for a subquery.
2060
2061 =cut
2062
2063 sub as_query {
2064   my $self = shift;
2065
2066   my $attrs = $self->_resolved_attrs_copy;
2067
2068   # For future use:
2069   #
2070   # in list ctx:
2071   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2072   # $sql also has no wrapping parenthesis in list ctx
2073   #
2074   my $sqlbind = $self->result_source->storage
2075     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2076
2077   return $sqlbind;
2078 }
2079
2080 =head2 find_or_new
2081
2082 =over 4
2083
2084 =item Arguments: \%vals, \%attrs?
2085
2086 =item Return Value: $rowobject
2087
2088 =back
2089
2090   my $artist = $schema->resultset('Artist')->find_or_new(
2091     { artist => 'fred' }, { key => 'artists' });
2092
2093   $cd->cd_to_producer->find_or_new({ producer => $producer },
2094                                    { key => 'primary });
2095
2096 Find an existing record from this resultset, based on its primary
2097 key, or a unique constraint. If none exists, instantiate a new result
2098 object and return it. The object will not be saved into your storage
2099 until you call L<DBIx::Class::Row/insert> on it.
2100
2101 You most likely want this method when looking for existing rows using
2102 a unique constraint that is not the primary key, or looking for
2103 related rows.
2104
2105 If you want objects to be saved immediately, use L</find_or_create>
2106 instead.
2107
2108 B<Note>: Take care when using C<find_or_new> with a table having
2109 columns with default values that you intend to be automatically
2110 supplied by the database (e.g. an auto_increment primary key column).
2111 In normal usage, the value of such columns should NOT be included at
2112 all in the call to C<find_or_new>, even when set to C<undef>.
2113
2114 =cut
2115
2116 sub find_or_new {
2117   my $self     = shift;
2118   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2119   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2120   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2121     return $row;
2122   }
2123   return $self->new_result($hash);
2124 }
2125
2126 =head2 create
2127
2128 =over 4
2129
2130 =item Arguments: \%vals
2131
2132 =item Return Value: a L<DBIx::Class::Row> $object
2133
2134 =back
2135
2136 Attempt to create a single new row or a row with multiple related rows
2137 in the table represented by the resultset (and related tables). This
2138 will not check for duplicate rows before inserting, use
2139 L</find_or_create> to do that.
2140
2141 To create one row for this resultset, pass a hashref of key/value
2142 pairs representing the columns of the table and the values you wish to
2143 store. If the appropriate relationships are set up, foreign key fields
2144 can also be passed an object representing the foreign row, and the
2145 value will be set to its primary key.
2146
2147 To create related objects, pass a hashref of related-object column values
2148 B<keyed on the relationship name>. If the relationship is of type C<multi>
2149 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2150 The process will correctly identify columns holding foreign keys, and will
2151 transparently populate them from the keys of the corresponding relation.
2152 This can be applied recursively, and will work correctly for a structure
2153 with an arbitrary depth and width, as long as the relationships actually
2154 exists and the correct column data has been supplied.
2155
2156
2157 Instead of hashrefs of plain related data (key/value pairs), you may
2158 also pass new or inserted objects. New objects (not inserted yet, see
2159 L</new>), will be inserted into their appropriate tables.
2160
2161 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2162
2163 Example of creating a new row.
2164
2165   $person_rs->create({
2166     name=>"Some Person",
2167     email=>"somebody@someplace.com"
2168   });
2169
2170 Example of creating a new row and also creating rows in a related C<has_many>
2171 or C<has_one> resultset.  Note Arrayref.
2172
2173   $artist_rs->create(
2174      { artistid => 4, name => 'Manufactured Crap', cds => [
2175         { title => 'My First CD', year => 2006 },
2176         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2177       ],
2178      },
2179   );
2180
2181 Example of creating a new row and also creating a row in a related
2182 C<belongs_to> resultset. Note Hashref.
2183
2184   $cd_rs->create({
2185     title=>"Music for Silly Walks",
2186     year=>2000,
2187     artist => {
2188       name=>"Silly Musician",
2189     }
2190   });
2191
2192 =over
2193
2194 =item WARNING
2195
2196 When subclassing ResultSet never attempt to override this method. Since
2197 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2198 lot of the internals simply never call it, so your override will be
2199 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2200 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2201 L</create> process you need to intervene.
2202
2203 =back
2204
2205 =cut
2206
2207 sub create {
2208   my ($self, $attrs) = @_;
2209   $self->throw_exception( "create needs a hashref" )
2210     unless ref $attrs eq 'HASH';
2211   return $self->new_result($attrs)->insert;
2212 }
2213
2214 =head2 find_or_create
2215
2216 =over 4
2217
2218 =item Arguments: \%vals, \%attrs?
2219
2220 =item Return Value: $rowobject
2221
2222 =back
2223
2224   $cd->cd_to_producer->find_or_create({ producer => $producer },
2225                                       { key => 'primary' });
2226
2227 Tries to find a record based on its primary key or unique constraints; if none
2228 is found, creates one and returns that instead.
2229
2230   my $cd = $schema->resultset('CD')->find_or_create({
2231     cdid   => 5,
2232     artist => 'Massive Attack',
2233     title  => 'Mezzanine',
2234     year   => 2005,
2235   });
2236
2237 Also takes an optional C<key> attribute, to search by a specific key or unique
2238 constraint. For example:
2239
2240   my $cd = $schema->resultset('CD')->find_or_create(
2241     {
2242       artist => 'Massive Attack',
2243       title  => 'Mezzanine',
2244     },
2245     { key => 'cd_artist_title' }
2246   );
2247
2248 B<Note>: Because find_or_create() reads from the database and then
2249 possibly inserts based on the result, this method is subject to a race
2250 condition. Another process could create a record in the table after
2251 the find has completed and before the create has started. To avoid
2252 this problem, use find_or_create() inside a transaction.
2253
2254 B<Note>: Take care when using C<find_or_create> with a table having
2255 columns with default values that you intend to be automatically
2256 supplied by the database (e.g. an auto_increment primary key column).
2257 In normal usage, the value of such columns should NOT be included at
2258 all in the call to C<find_or_create>, even when set to C<undef>.
2259
2260 See also L</find> and L</update_or_create>. For information on how to declare
2261 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2262
2263 =cut
2264
2265 sub find_or_create {
2266   my $self     = shift;
2267   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2268   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2269   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2270     return $row;
2271   }
2272   return $self->create($hash);
2273 }
2274
2275 =head2 update_or_create
2276
2277 =over 4
2278
2279 =item Arguments: \%col_values, { key => $unique_constraint }?
2280
2281 =item Return Value: $rowobject
2282
2283 =back
2284
2285   $resultset->update_or_create({ col => $val, ... });
2286
2287 First, searches for an existing row matching one of the unique constraints
2288 (including the primary key) on the source of this resultset. If a row is
2289 found, updates it with the other given column values. Otherwise, creates a new
2290 row.
2291
2292 Takes an optional C<key> attribute to search on a specific unique constraint.
2293 For example:
2294
2295   # In your application
2296   my $cd = $schema->resultset('CD')->update_or_create(
2297     {
2298       artist => 'Massive Attack',
2299       title  => 'Mezzanine',
2300       year   => 1998,
2301     },
2302     { key => 'cd_artist_title' }
2303   );
2304
2305   $cd->cd_to_producer->update_or_create({
2306     producer => $producer,
2307     name => 'harry',
2308   }, {
2309     key => 'primary',
2310   });
2311
2312
2313 If no C<key> is specified, it searches on all unique constraints defined on the
2314 source, including the primary key.
2315
2316 If the C<key> is specified as C<primary>, it searches only on the primary key.
2317
2318 See also L</find> and L</find_or_create>. For information on how to declare
2319 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2320
2321 B<Note>: Take care when using C<update_or_create> with a table having
2322 columns with default values that you intend to be automatically
2323 supplied by the database (e.g. an auto_increment primary key column).
2324 In normal usage, the value of such columns should NOT be included at
2325 all in the call to C<update_or_create>, even when set to C<undef>.
2326
2327 =cut
2328
2329 sub update_or_create {
2330   my $self = shift;
2331   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2332   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2333
2334   my $row = $self->find($cond, $attrs);
2335   if (defined $row) {
2336     $row->update($cond);
2337     return $row;
2338   }
2339
2340   return $self->create($cond);
2341 }
2342
2343 =head2 update_or_new
2344
2345 =over 4
2346
2347 =item Arguments: \%col_values, { key => $unique_constraint }?
2348
2349 =item Return Value: $rowobject
2350
2351 =back
2352
2353   $resultset->update_or_new({ col => $val, ... });
2354
2355 First, searches for an existing row matching one of the unique constraints
2356 (including the primary key) on the source of this resultset. If a row is
2357 found, updates it with the other given column values. Otherwise, instantiate
2358 a new result object and return it. The object will not be saved into your storage
2359 until you call L<DBIx::Class::Row/insert> on it.
2360
2361 Takes an optional C<key> attribute to search on a specific unique constraint.
2362 For example:
2363
2364   # In your application
2365   my $cd = $schema->resultset('CD')->update_or_new(
2366     {
2367       artist => 'Massive Attack',
2368       title  => 'Mezzanine',
2369       year   => 1998,
2370     },
2371     { key => 'cd_artist_title' }
2372   );
2373
2374   if ($cd->in_storage) {
2375       # the cd was updated
2376   }
2377   else {
2378       # the cd is not yet in the database, let's insert it
2379       $cd->insert;
2380   }
2381
2382 B<Note>: Take care when using C<update_or_new> with a table having
2383 columns with default values that you intend to be automatically
2384 supplied by the database (e.g. an auto_increment primary key column).
2385 In normal usage, the value of such columns should NOT be included at
2386 all in the call to C<update_or_new>, even when set to C<undef>.
2387
2388 See also L</find>, L</find_or_create> and L</find_or_new>.
2389
2390 =cut
2391
2392 sub update_or_new {
2393     my $self  = shift;
2394     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2395     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2396
2397     my $row = $self->find( $cond, $attrs );
2398     if ( defined $row ) {
2399         $row->update($cond);
2400         return $row;
2401     }
2402
2403     return $self->new_result($cond);
2404 }
2405
2406 =head2 get_cache
2407
2408 =over 4
2409
2410 =item Arguments: none
2411
2412 =item Return Value: \@cache_objects?
2413
2414 =back
2415
2416 Gets the contents of the cache for the resultset, if the cache is set.
2417
2418 The cache is populated either by using the L</prefetch> attribute to
2419 L</search> or by calling L</set_cache>.
2420
2421 =cut
2422
2423 sub get_cache {
2424   shift->{all_cache};
2425 }
2426
2427 =head2 set_cache
2428
2429 =over 4
2430
2431 =item Arguments: \@cache_objects
2432
2433 =item Return Value: \@cache_objects
2434
2435 =back
2436
2437 Sets the contents of the cache for the resultset. Expects an arrayref
2438 of objects of the same class as those produced by the resultset. Note that
2439 if the cache is set the resultset will return the cached objects rather
2440 than re-querying the database even if the cache attr is not set.
2441
2442 The contents of the cache can also be populated by using the
2443 L</prefetch> attribute to L</search>.
2444
2445 =cut
2446
2447 sub set_cache {
2448   my ( $self, $data ) = @_;
2449   $self->throw_exception("set_cache requires an arrayref")
2450       if defined($data) && (ref $data ne 'ARRAY');
2451   $self->{all_cache} = $data;
2452 }
2453
2454 =head2 clear_cache
2455
2456 =over 4
2457
2458 =item Arguments: none
2459
2460 =item Return Value: []
2461
2462 =back
2463
2464 Clears the cache for the resultset.
2465
2466 =cut
2467
2468 sub clear_cache {
2469   shift->set_cache(undef);
2470 }
2471
2472 =head2 is_paged
2473
2474 =over 4
2475
2476 =item Arguments: none
2477
2478 =item Return Value: true, if the resultset has been paginated
2479
2480 =back
2481
2482 =cut
2483
2484 sub is_paged {
2485   my ($self) = @_;
2486   return !!$self->{attrs}{page};
2487 }
2488
2489 =head2 is_ordered
2490
2491 =over 4
2492
2493 =item Arguments: none
2494
2495 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2496
2497 =back
2498
2499 =cut
2500
2501 sub is_ordered {
2502   my ($self) = @_;
2503   return scalar $self->result_source->storage->_parse_order_by($self->{attrs}{order_by});
2504 }
2505
2506 =head2 related_resultset
2507
2508 =over 4
2509
2510 =item Arguments: $relationship_name
2511
2512 =item Return Value: $resultset
2513
2514 =back
2515
2516 Returns a related resultset for the supplied relationship name.
2517
2518   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2519
2520 =cut
2521
2522 sub related_resultset {
2523   my ($self, $rel) = @_;
2524
2525   $self->{related_resultsets} ||= {};
2526   return $self->{related_resultsets}{$rel} ||= do {
2527     my $rsrc = $self->result_source;
2528     my $rel_info = $rsrc->relationship_info($rel);
2529
2530     $self->throw_exception(
2531       "search_related: result source '" . $rsrc->source_name .
2532         "' has no such relationship $rel")
2533       unless $rel_info;
2534
2535     my $attrs = $self->_chain_relationship($rel);
2536
2537     my $join_count = $attrs->{seen_join}{$rel};
2538
2539     my $alias = $self->result_source->storage
2540         ->relname_to_table_alias($rel, $join_count);
2541
2542     # since this is search_related, and we already slid the select window inwards
2543     # (the select/as attrs were deleted in the beginning), we need to flip all
2544     # left joins to inner, so we get the expected results
2545     # read the comment on top of the actual function to see what this does
2546     $attrs->{from} = $rsrc->schema->storage->_straight_join_to_node ($attrs->{from}, $alias);
2547
2548
2549     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2550     delete @{$attrs}{qw(result_class alias)};
2551
2552     my $new_cache;
2553
2554     if (my $cache = $self->get_cache) {
2555       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2556         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2557                         @$cache ];
2558       }
2559     }
2560
2561     my $rel_source = $rsrc->related_source($rel);
2562
2563     my $new = do {
2564
2565       # The reason we do this now instead of passing the alias to the
2566       # search_rs below is that if you wrap/overload resultset on the
2567       # source you need to know what alias it's -going- to have for things
2568       # to work sanely (e.g. RestrictWithObject wants to be able to add
2569       # extra query restrictions, and these may need to be $alias.)
2570
2571       my $rel_attrs = $rel_source->resultset_attributes;
2572       local $rel_attrs->{alias} = $alias;
2573
2574       $rel_source->resultset
2575                  ->search_rs(
2576                      undef, {
2577                        %$attrs,
2578                        where => $attrs->{where},
2579                    });
2580     };
2581     $new->set_cache($new_cache) if $new_cache;
2582     $new;
2583   };
2584 }
2585
2586 =head2 current_source_alias
2587
2588 =over 4
2589
2590 =item Arguments: none
2591
2592 =item Return Value: $source_alias
2593
2594 =back
2595
2596 Returns the current table alias for the result source this resultset is built
2597 on, that will be used in the SQL query. Usually it is C<me>.
2598
2599 Currently the source alias that refers to the result set returned by a
2600 L</search>/L</find> family method depends on how you got to the resultset: it's
2601 C<me> by default, but eg. L</search_related> aliases it to the related result
2602 source name (and keeps C<me> referring to the original result set). The long
2603 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2604 (and make this method unnecessary).
2605
2606 Thus it's currently necessary to use this method in predefined queries (see
2607 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2608 source alias of the current result set:
2609
2610   # in a result set class
2611   sub modified_by {
2612     my ($self, $user) = @_;
2613
2614     my $me = $self->current_source_alias;
2615
2616     return $self->search(
2617       "$me.modified" => $user->id,
2618     );
2619   }
2620
2621 =cut
2622
2623 sub current_source_alias {
2624   my ($self) = @_;
2625
2626   return ($self->{attrs} || {})->{alias} || 'me';
2627 }
2628
2629 =head2 as_subselect_rs
2630
2631 =over 4
2632
2633 =item Arguments: none
2634
2635 =item Return Value: $resultset
2636
2637 =back
2638
2639 Act as a barrier to SQL symbols.  The resultset provided will be made into a
2640 "virtual view" by including it as a subquery within the from clause.  From this
2641 point on, any joined tables are inaccessible to ->search on the resultset (as if
2642 it were simply where-filtered without joins).  For example:
2643
2644  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
2645
2646  # 'x' now pollutes the query namespace
2647
2648  # So the following works as expected
2649  my $ok_rs = $rs->search({'x.other' => 1});
2650
2651  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
2652  # def) we look for one row with contradictory terms and join in another table
2653  # (aliased 'x_2') which we never use
2654  my $broken_rs = $rs->search({'x.name' => 'def'});
2655
2656  my $rs2 = $rs->as_subselect_rs;
2657
2658  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
2659  my $not_joined_rs = $rs2->search({'x.other' => 1});
2660
2661  # works as expected: finds a 'table' row related to two x rows (abc and def)
2662  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
2663
2664 Another example of when one might use this would be to select a subset of
2665 columns in a group by clause:
2666
2667  my $rs = $schema->resultset('Bar')->search(undef, {
2668    group_by => [qw{ id foo_id baz_id }],
2669  })->as_subselect_rs->search(undef, {
2670    columns => [qw{ id foo_id }]
2671  });
2672
2673 In the above example normally columns would have to be equal to the group by,
2674 but because we isolated the group by into a subselect the above works.
2675
2676 =cut
2677
2678 sub as_subselect_rs {
2679   my $self = shift;
2680
2681   my $attrs = $self->_resolved_attrs;
2682
2683   my $fresh_rs = (ref $self)->new (
2684     $self->result_source
2685   );
2686
2687   # these pieces will be locked in the subquery
2688   delete $fresh_rs->{cond};
2689   delete @{$fresh_rs->{attrs}}{qw/where bind/};
2690
2691   return $fresh_rs->search( {}, {
2692     from => [{
2693       $attrs->{alias} => $self->as_query,
2694       -alias         => $attrs->{alias},
2695       -source_handle => $self->result_source->handle,
2696     }],
2697     alias => $attrs->{alias},
2698   });
2699 }
2700
2701 # This code is called by search_related, and makes sure there
2702 # is clear separation between the joins before, during, and
2703 # after the relationship. This information is needed later
2704 # in order to properly resolve prefetch aliases (any alias
2705 # with a relation_chain_depth less than the depth of the
2706 # current prefetch is not considered)
2707 #
2708 # The increments happen twice per join. An even number means a
2709 # relationship specified via a search_related, whereas an odd
2710 # number indicates a join/prefetch added via attributes
2711 #
2712 # Also this code will wrap the current resultset (the one we
2713 # chain to) in a subselect IFF it contains limiting attributes
2714 sub _chain_relationship {
2715   my ($self, $rel) = @_;
2716   my $source = $self->result_source;
2717   my $attrs = { %{$self->{attrs}||{}} };
2718
2719   # we need to take the prefetch the attrs into account before we
2720   # ->_resolve_join as otherwise they get lost - captainL
2721   my $join = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2722
2723   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
2724
2725   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
2726
2727   my $from;
2728   my @force_subq_attrs = qw/offset rows group_by having/;
2729
2730   if (
2731     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
2732       ||
2733     $self->_has_resolved_attr (@force_subq_attrs)
2734   ) {
2735     # Nuke the prefetch (if any) before the new $rs attrs
2736     # are resolved (prefetch is useless - we are wrapping
2737     # a subquery anyway).
2738     my $rs_copy = $self->search;
2739     $rs_copy->{attrs}{join} = $self->_merge_attr (
2740       $rs_copy->{attrs}{join},
2741       delete $rs_copy->{attrs}{prefetch},
2742     );
2743
2744     $from = [{
2745       -source_handle => $source->handle,
2746       -alias => $attrs->{alias},
2747       $attrs->{alias} => $rs_copy->as_query,
2748     }];
2749     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
2750     $seen->{-relation_chain_depth} = 0;
2751   }
2752   elsif ($attrs->{from}) {  #shallow copy suffices
2753     $from = [ @{$attrs->{from}} ];
2754   }
2755   else {
2756     $from = [{
2757       -source_handle => $source->handle,
2758       -alias => $attrs->{alias},
2759       $attrs->{alias} => $source->from,
2760     }];
2761   }
2762
2763   my $jpath = ($seen->{-relation_chain_depth})
2764     ? $from->[-1][0]{-join_path}
2765     : [];
2766
2767   my @requested_joins = $source->_resolve_join(
2768     $join,
2769     $attrs->{alias},
2770     $seen,
2771     $jpath,
2772   );
2773
2774   push @$from, @requested_joins;
2775
2776   $seen->{-relation_chain_depth}++;
2777
2778   # if $self already had a join/prefetch specified on it, the requested
2779   # $rel might very well be already included. What we do in this case
2780   # is effectively a no-op (except that we bump up the chain_depth on
2781   # the join in question so we could tell it *is* the search_related)
2782   my $already_joined;
2783
2784   # we consider the last one thus reverse
2785   for my $j (reverse @requested_joins) {
2786     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
2787     if ($rel eq $last_j) {
2788       $j->[0]{-relation_chain_depth}++;
2789       $already_joined++;
2790       last;
2791     }
2792   }
2793
2794   unless ($already_joined) {
2795     push @$from, $source->_resolve_join(
2796       $rel,
2797       $attrs->{alias},
2798       $seen,
2799       $jpath,
2800     );
2801   }
2802
2803   $seen->{-relation_chain_depth}++;
2804
2805   return {%$attrs, from => $from, seen_join => $seen};
2806 }
2807
2808 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2809 sub _resolved_attrs_copy {
2810   my $self = shift;
2811   return { %{$self->_resolved_attrs (@_)} };
2812 }
2813
2814 sub _resolved_attrs {
2815   my $self = shift;
2816   return $self->{_attrs} if $self->{_attrs};
2817
2818   my $attrs  = { %{ $self->{attrs} || {} } };
2819   my $source = $self->result_source;
2820   my $alias  = $attrs->{alias};
2821
2822   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2823   my @colbits;
2824
2825   # build columns (as long as select isn't set) into a set of as/select hashes
2826   unless ( $attrs->{select} ) {
2827
2828     my @cols;
2829     if ( ref $attrs->{columns} eq 'ARRAY' ) {
2830       @cols = @{ delete $attrs->{columns}}
2831     } elsif ( defined $attrs->{columns} ) {
2832       @cols = delete $attrs->{columns}
2833     } else {
2834       @cols = $source->columns
2835     }
2836
2837     for (@cols) {
2838       if ( ref $_ eq 'HASH' ) {
2839         push @colbits, $_
2840       } else {
2841         my $key = /^\Q${alias}.\E(.+)$/
2842           ? "$1"
2843           : "$_";
2844         my $value = /\./
2845           ? "$_"
2846           : "${alias}.$_";
2847         push @colbits, { $key => $value };
2848       }
2849     }
2850   }
2851
2852   # add the additional columns on
2853   foreach (qw{include_columns +columns}) {
2854     if ( $attrs->{$_} ) {
2855       my @list = ( ref($attrs->{$_}) eq 'ARRAY' )
2856         ? @{ delete $attrs->{$_} }
2857         : delete $attrs->{$_};
2858       for (@list) {
2859         if ( ref($_) eq 'HASH' ) {
2860           push @colbits, $_
2861         } else {
2862           my $key = ( split /\./, $_ )[-1];
2863           my $value = ( /\./ ? $_ : "$alias.$_" );
2864           push @colbits, { $key => $value };
2865         }
2866       }
2867     }
2868   }
2869
2870   # start with initial select items
2871   if ( $attrs->{select} ) {
2872     $attrs->{select} =
2873         ( ref $attrs->{select} eq 'ARRAY' )
2874       ? [ @{ $attrs->{select} } ]
2875       : [ $attrs->{select} ];
2876
2877     if ( $attrs->{as} ) {
2878       $attrs->{as} =
2879         (
2880           ref $attrs->{as} eq 'ARRAY'
2881             ? [ @{ $attrs->{as} } ]
2882             : [ $attrs->{as} ]
2883         )
2884     } else {
2885       $attrs->{as} = [ map {
2886          m/^\Q${alias}.\E(.+)$/
2887            ? $1
2888            : $_
2889          } @{ $attrs->{select} }
2890       ]
2891     }
2892   }
2893   else {
2894
2895     # otherwise we intialise select & as to empty
2896     $attrs->{select} = [];
2897     $attrs->{as}     = [];
2898   }
2899
2900   # now add colbits to select/as
2901   push @{ $attrs->{select} }, map values %{$_}, @colbits;
2902   push @{ $attrs->{as}     }, map keys   %{$_}, @colbits;
2903
2904   if ( my $adds = delete $attrs->{'+select'} ) {
2905     $adds = [$adds] unless ref $adds eq 'ARRAY';
2906     push @{ $attrs->{select} },
2907       map { /\./ || ref $_ ? $_ : "$alias.$_" } @$adds;
2908   }
2909   if ( my $adds = delete $attrs->{'+as'} ) {
2910     $adds = [$adds] unless ref $adds eq 'ARRAY';
2911     push @{ $attrs->{as} }, @$adds;
2912   }
2913
2914   $attrs->{from} ||= [{
2915     -source_handle => $source->handle,
2916     -alias => $self->{attrs}{alias},
2917     $self->{attrs}{alias} => $source->from,
2918   }];
2919
2920   if ( $attrs->{join} || $attrs->{prefetch} ) {
2921
2922     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2923       if ref $attrs->{from} ne 'ARRAY';
2924
2925     my $join = delete $attrs->{join} || {};
2926
2927     if ( defined $attrs->{prefetch} ) {
2928       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2929     }
2930
2931     $attrs->{from} =    # have to copy here to avoid corrupting the original
2932       [
2933         @{ $attrs->{from} },
2934         $source->_resolve_join(
2935           $join,
2936           $alias,
2937           { %{ $attrs->{seen_join} || {} } },
2938           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
2939             ? $attrs->{from}[-1][0]{-join_path}
2940             : []
2941           ,
2942         )
2943       ];
2944   }
2945
2946   if ( defined $attrs->{order_by} ) {
2947     $attrs->{order_by} = (
2948       ref( $attrs->{order_by} ) eq 'ARRAY'
2949       ? [ @{ $attrs->{order_by} } ]
2950       : [ $attrs->{order_by} || () ]
2951     );
2952   }
2953
2954   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2955     $attrs->{group_by} = [ $attrs->{group_by} ];
2956   }
2957
2958   # generate the distinct induced group_by early, as prefetch will be carried via a
2959   # subquery (since a group_by is present)
2960   if (delete $attrs->{distinct}) {
2961     if ($attrs->{group_by}) {
2962       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2963     }
2964     else {
2965       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2966
2967       # add any order_by parts that are not already present in the group_by
2968       # we need to be careful not to add any named functions/aggregates
2969       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
2970       my %already_grouped = map { $_ => 1 } (@{$attrs->{group_by}});
2971
2972       my $storage = $self->result_source->schema->storage;
2973
2974       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
2975
2976       for my $chunk ($storage->_parse_order_by($attrs->{order_by})) {
2977         if ($rs_column_list->{$chunk} && not $already_grouped{$chunk}++) {
2978           push @{$attrs->{group_by}}, $chunk;
2979         }
2980       }
2981     }
2982   }
2983
2984   $attrs->{collapse} ||= {};
2985   if ( my $prefetch = delete $attrs->{prefetch} ) {
2986     $prefetch = $self->_merge_attr( {}, $prefetch );
2987
2988     my $prefetch_ordering = [];
2989
2990     # this is a separate structure (we don't look in {from} directly)
2991     # as the resolver needs to shift things off the lists to work
2992     # properly (identical-prefetches on different branches)
2993     my $join_map = {};
2994     if (ref $attrs->{from} eq 'ARRAY') {
2995
2996       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
2997
2998       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
2999         next unless $j->[0]{-alias};
3000         next unless $j->[0]{-join_path};
3001         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3002
3003         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3004
3005         my $p = $join_map;
3006         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3007         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3008       }
3009     }
3010
3011     my @prefetch =
3012       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3013
3014     # we need to somehow mark which columns came from prefetch
3015     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
3016
3017     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
3018     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3019
3020     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3021     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3022   }
3023
3024   # if both page and offset are specified, produce a combined offset
3025   # even though it doesn't make much sense, this is what pre 081xx has
3026   # been doing
3027   if (my $page = delete $attrs->{page}) {
3028     $attrs->{offset} =
3029       ($attrs->{rows} * ($page - 1))
3030             +
3031       ($attrs->{offset} || 0)
3032     ;
3033   }
3034
3035   return $self->{_attrs} = $attrs;
3036 }
3037
3038 sub _rollout_attr {
3039   my ($self, $attr) = @_;
3040
3041   if (ref $attr eq 'HASH') {
3042     return $self->_rollout_hash($attr);
3043   } elsif (ref $attr eq 'ARRAY') {
3044     return $self->_rollout_array($attr);
3045   } else {
3046     return [$attr];
3047   }
3048 }
3049
3050 sub _rollout_array {
3051   my ($self, $attr) = @_;
3052
3053   my @rolled_array;
3054   foreach my $element (@{$attr}) {
3055     if (ref $element eq 'HASH') {
3056       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3057     } elsif (ref $element eq 'ARRAY') {
3058       #  XXX - should probably recurse here
3059       push( @rolled_array, @{$self->_rollout_array($element)} );
3060     } else {
3061       push( @rolled_array, $element );
3062     }
3063   }
3064   return \@rolled_array;
3065 }
3066
3067 sub _rollout_hash {
3068   my ($self, $attr) = @_;
3069
3070   my @rolled_array;
3071   foreach my $key (keys %{$attr}) {
3072     push( @rolled_array, { $key => $attr->{$key} } );
3073   }
3074   return \@rolled_array;
3075 }
3076
3077 sub _calculate_score {
3078   my ($self, $a, $b) = @_;
3079
3080   if (defined $a xor defined $b) {
3081     return 0;
3082   }
3083   elsif (not defined $a) {
3084     return 1;
3085   }
3086
3087   if (ref $b eq 'HASH') {
3088     my ($b_key) = keys %{$b};
3089     if (ref $a eq 'HASH') {
3090       my ($a_key) = keys %{$a};
3091       if ($a_key eq $b_key) {
3092         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3093       } else {
3094         return 0;
3095       }
3096     } else {
3097       return ($a eq $b_key) ? 1 : 0;
3098     }
3099   } else {
3100     if (ref $a eq 'HASH') {
3101       my ($a_key) = keys %{$a};
3102       return ($b eq $a_key) ? 1 : 0;
3103     } else {
3104       return ($b eq $a) ? 1 : 0;
3105     }
3106   }
3107 }
3108
3109 sub _merge_attr {
3110   my ($self, $orig, $import) = @_;
3111
3112   return $import unless defined($orig);
3113   return $orig unless defined($import);
3114
3115   $orig = $self->_rollout_attr($orig);
3116   $import = $self->_rollout_attr($import);
3117
3118   my $seen_keys;
3119   foreach my $import_element ( @{$import} ) {
3120     # find best candidate from $orig to merge $b_element into
3121     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3122     foreach my $orig_element ( @{$orig} ) {
3123       my $score = $self->_calculate_score( $orig_element, $import_element );
3124       if ($score > $best_candidate->{score}) {
3125         $best_candidate->{position} = $position;
3126         $best_candidate->{score} = $score;
3127       }
3128       $position++;
3129     }
3130     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3131
3132     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3133       push( @{$orig}, $import_element );
3134     } else {
3135       my $orig_best = $orig->[$best_candidate->{position}];
3136       # merge orig_best and b_element together and replace original with merged
3137       if (ref $orig_best ne 'HASH') {
3138         $orig->[$best_candidate->{position}] = $import_element;
3139       } elsif (ref $import_element eq 'HASH') {
3140         my ($key) = keys %{$orig_best};
3141         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3142       }
3143     }
3144     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3145   }
3146
3147   return $orig;
3148 }
3149
3150 sub result_source {
3151     my $self = shift;
3152
3153     if (@_) {
3154         $self->_source_handle($_[0]->handle);
3155     } else {
3156         $self->_source_handle->resolve;
3157     }
3158 }
3159
3160 =head2 throw_exception
3161
3162 See L<DBIx::Class::Schema/throw_exception> for details.
3163
3164 =cut
3165
3166 sub throw_exception {
3167   my $self=shift;
3168
3169   if (ref $self && $self->_source_handle->schema) {
3170     $self->_source_handle->schema->throw_exception(@_)
3171   }
3172   else {
3173     DBIx::Class::Exception->throw(@_);
3174   }
3175 }
3176
3177 # XXX: FIXME: Attributes docs need clearing up
3178
3179 =head1 ATTRIBUTES
3180
3181 Attributes are used to refine a ResultSet in various ways when
3182 searching for data. They can be passed to any method which takes an
3183 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3184 L</count>.
3185
3186 These are in no particular order:
3187
3188 =head2 order_by
3189
3190 =over 4
3191
3192 =item Value: ( $order_by | \@order_by | \%order_by )
3193
3194 =back
3195
3196 Which column(s) to order the results by.
3197
3198 [The full list of suitable values is documented in
3199 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3200 common options.]
3201
3202 If a single column name, or an arrayref of names is supplied, the
3203 argument is passed through directly to SQL. The hashref syntax allows
3204 for connection-agnostic specification of ordering direction:
3205
3206  For descending order:
3207
3208   order_by => { -desc => [qw/col1 col2 col3/] }
3209
3210  For explicit ascending order:
3211
3212   order_by => { -asc => 'col' }
3213
3214 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3215 supported, although you are strongly encouraged to use the hashref
3216 syntax as outlined above.
3217
3218 =head2 columns
3219
3220 =over 4
3221
3222 =item Value: \@columns
3223
3224 =back
3225
3226 Shortcut to request a particular set of columns to be retrieved. Each
3227 column spec may be a string (a table column name), or a hash (in which
3228 case the key is the C<as> value, and the value is used as the C<select>
3229 expression). Adds C<me.> onto the start of any column without a C<.> in
3230 it and sets C<select> from that, then auto-populates C<as> from
3231 C<select> as normal. (You may also use the C<cols> attribute, as in
3232 earlier versions of DBIC.)
3233
3234 =head2 +columns
3235
3236 =over 4
3237
3238 =item Value: \@columns
3239
3240 =back
3241
3242 Indicates additional columns to be selected from storage. Works the same
3243 as L</columns> but adds columns to the selection. (You may also use the
3244 C<include_columns> attribute, as in earlier versions of DBIC). For
3245 example:-
3246
3247   $schema->resultset('CD')->search(undef, {
3248     '+columns' => ['artist.name'],
3249     join => ['artist']
3250   });
3251
3252 would return all CDs and include a 'name' column to the information
3253 passed to object inflation. Note that the 'artist' is the name of the
3254 column (or relationship) accessor, and 'name' is the name of the column
3255 accessor in the related table.
3256
3257 =head2 include_columns
3258
3259 =over 4
3260
3261 =item Value: \@columns
3262
3263 =back
3264
3265 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3266
3267 =head2 select
3268
3269 =over 4
3270
3271 =item Value: \@select_columns
3272
3273 =back
3274
3275 Indicates which columns should be selected from the storage. You can use
3276 column names, or in the case of RDBMS back ends, function or stored procedure
3277 names:
3278
3279   $rs = $schema->resultset('Employee')->search(undef, {
3280     select => [
3281       'name',
3282       { count => 'employeeid' },
3283       { max => { length => 'name' }, -as => 'longest_name' }
3284     ]
3285   });
3286
3287   # Equivalent SQL
3288   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3289
3290 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3291 use L</select>, to instruct DBIx::Class how to store the result of the column.
3292 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3293 identifier aliasing. You can however alias a function, so you can use it in
3294 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3295 attribute> supplied as shown in the example above.
3296
3297 =head2 +select
3298
3299 =over 4
3300
3301 Indicates additional columns to be selected from storage.  Works the same as
3302 L</select> but adds columns to the default selection, instead of specifying
3303 an explicit list.
3304
3305 =back
3306
3307 =head2 +as
3308
3309 =over 4
3310
3311 Indicates additional column names for those added via L</+select>. See L</as>.
3312
3313 =back
3314
3315 =head2 as
3316
3317 =over 4
3318
3319 =item Value: \@inflation_names
3320
3321 =back
3322
3323 Indicates column names for object inflation. That is L</as> indicates the
3324 slot name in which the column value will be stored within the
3325 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3326 identifier by the C<get_column> method (or via the object accessor B<if one
3327 with the same name already exists>) as shown below. The L</as> attribute has
3328 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3329
3330   $rs = $schema->resultset('Employee')->search(undef, {
3331     select => [
3332       'name',
3333       { count => 'employeeid' },
3334       { max => { length => 'name' }, -as => 'longest_name' }
3335     ],
3336     as => [qw/
3337       name
3338       employee_count
3339       max_name_length
3340     /],
3341   });
3342
3343 If the object against which the search is performed already has an accessor
3344 matching a column name specified in C<as>, the value can be retrieved using
3345 the accessor as normal:
3346
3347   my $name = $employee->name();
3348
3349 If on the other hand an accessor does not exist in the object, you need to
3350 use C<get_column> instead:
3351
3352   my $employee_count = $employee->get_column('employee_count');
3353
3354 You can create your own accessors if required - see
3355 L<DBIx::Class::Manual::Cookbook> for details.
3356
3357 =head2 join
3358
3359 =over 4
3360
3361 =item Value: ($rel_name | \@rel_names | \%rel_names)
3362
3363 =back
3364
3365 Contains a list of relationships that should be joined for this query.  For
3366 example:
3367
3368   # Get CDs by Nine Inch Nails
3369   my $rs = $schema->resultset('CD')->search(
3370     { 'artist.name' => 'Nine Inch Nails' },
3371     { join => 'artist' }
3372   );
3373
3374 Can also contain a hash reference to refer to the other relation's relations.
3375 For example:
3376
3377   package MyApp::Schema::Track;
3378   use base qw/DBIx::Class/;
3379   __PACKAGE__->table('track');
3380   __PACKAGE__->add_columns(qw/trackid cd position title/);
3381   __PACKAGE__->set_primary_key('trackid');
3382   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3383   1;
3384
3385   # In your application
3386   my $rs = $schema->resultset('Artist')->search(
3387     { 'track.title' => 'Teardrop' },
3388     {
3389       join     => { cd => 'track' },
3390       order_by => 'artist.name',
3391     }
3392   );
3393
3394 You need to use the relationship (not the table) name in  conditions,
3395 because they are aliased as such. The current table is aliased as "me", so
3396 you need to use me.column_name in order to avoid ambiguity. For example:
3397
3398   # Get CDs from 1984 with a 'Foo' track
3399   my $rs = $schema->resultset('CD')->search(
3400     {
3401       'me.year' => 1984,
3402       'tracks.name' => 'Foo'
3403     },
3404     { join => 'tracks' }
3405   );
3406
3407 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3408 similarly for a third time). For e.g.
3409
3410   my $rs = $schema->resultset('Artist')->search({
3411     'cds.title'   => 'Down to Earth',
3412     'cds_2.title' => 'Popular',
3413   }, {
3414     join => [ qw/cds cds/ ],
3415   });
3416
3417 will return a set of all artists that have both a cd with title 'Down
3418 to Earth' and a cd with title 'Popular'.
3419
3420 If you want to fetch related objects from other tables as well, see C<prefetch>
3421 below.
3422
3423 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3424
3425 =head2 prefetch
3426
3427 =over 4
3428
3429 =item Value: ($rel_name | \@rel_names | \%rel_names)
3430
3431 =back
3432
3433 Contains one or more relationships that should be fetched along with
3434 the main query (when they are accessed afterwards the data will
3435 already be available, without extra queries to the database).  This is
3436 useful for when you know you will need the related objects, because it
3437 saves at least one query:
3438
3439   my $rs = $schema->resultset('Tag')->search(
3440     undef,
3441     {
3442       prefetch => {
3443         cd => 'artist'
3444       }
3445     }
3446   );
3447
3448 The initial search results in SQL like the following:
3449
3450   SELECT tag.*, cd.*, artist.* FROM tag
3451   JOIN cd ON tag.cd = cd.cdid
3452   JOIN artist ON cd.artist = artist.artistid
3453
3454 L<DBIx::Class> has no need to go back to the database when we access the
3455 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3456 case.
3457
3458 Simple prefetches will be joined automatically, so there is no need
3459 for a C<join> attribute in the above search.
3460
3461 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3462 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3463 with an accessor type of 'single' or 'filter'). A more complex example that
3464 prefetches an artists cds, the tracks on those cds, and the tags associated
3465 with that artist is given below (assuming many-to-many from artists to tags):
3466
3467  my $rs = $schema->resultset('Artist')->search(
3468    undef,
3469    {
3470      prefetch => [
3471        { cds => 'tracks' },
3472        { artist_tags => 'tags' }
3473      ]
3474    }
3475  );
3476
3477
3478 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3479 attributes will be ignored.
3480
3481 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3482 exactly as you might expect.
3483
3484 =over 4
3485
3486 =item *
3487
3488 Prefetch uses the L</cache> to populate the prefetched relationships. This
3489 may or may not be what you want.
3490
3491 =item *
3492
3493 If you specify a condition on a prefetched relationship, ONLY those
3494 rows that match the prefetched condition will be fetched into that relationship.
3495 This means that adding prefetch to a search() B<may alter> what is returned by
3496 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3497
3498   my $artist_rs = $schema->resultset('Artist')->search({
3499       'cds.year' => 2008,
3500   }, {
3501       join => 'cds',
3502   });
3503
3504   my $count = $artist_rs->first->cds->count;
3505
3506   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3507
3508   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3509
3510   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3511
3512 that cmp_ok() may or may not pass depending on the datasets involved. This
3513 behavior may or may not survive the 0.09 transition.
3514
3515 =back
3516
3517 =head2 page
3518
3519 =over 4
3520
3521 =item Value: $page
3522
3523 =back
3524
3525 Makes the resultset paged and specifies the page to retrieve. Effectively
3526 identical to creating a non-pages resultset and then calling ->page($page)
3527 on it.
3528
3529 If L<rows> attribute is not specified it defaults to 10 rows per page.
3530
3531 When you have a paged resultset, L</count> will only return the number
3532 of rows in the page. To get the total, use the L</pager> and call
3533 C<total_entries> on it.
3534
3535 =head2 rows
3536
3537 =over 4
3538
3539 =item Value: $rows
3540
3541 =back
3542
3543 Specifies the maximum number of rows for direct retrieval or the number of
3544 rows per page if the page attribute or method is used.
3545
3546 =head2 offset
3547
3548 =over 4
3549
3550 =item Value: $offset
3551
3552 =back
3553
3554 Specifies the (zero-based) row number for the  first row to be returned, or the
3555 of the first row of the first page if paging is used.
3556
3557 =head2 group_by
3558
3559 =over 4
3560
3561 =item Value: \@columns
3562
3563 =back
3564
3565 A arrayref of columns to group by. Can include columns of joined tables.
3566
3567   group_by => [qw/ column1 column2 ... /]
3568
3569 =head2 having
3570
3571 =over 4
3572
3573 =item Value: $condition
3574
3575 =back
3576
3577 HAVING is a select statement attribute that is applied between GROUP BY and
3578 ORDER BY. It is applied to the after the grouping calculations have been
3579 done.
3580
3581   having => { 'count(employee)' => { '>=', 100 } }
3582
3583 =head2 distinct
3584
3585 =over 4
3586
3587 =item Value: (0 | 1)
3588
3589 =back
3590
3591 Set to 1 to group by all columns. If the resultset already has a group_by
3592 attribute, this setting is ignored and an appropriate warning is issued.
3593
3594 =head2 where
3595
3596 =over 4
3597
3598 Adds to the WHERE clause.
3599
3600   # only return rows WHERE deleted IS NULL for all searches
3601   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3602
3603 Can be overridden by passing C<< { where => undef } >> as an attribute
3604 to a resultset.
3605
3606 =back
3607
3608 =head2 cache
3609
3610 Set to 1 to cache search results. This prevents extra SQL queries if you
3611 revisit rows in your ResultSet:
3612
3613   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3614
3615   while( my $artist = $resultset->next ) {
3616     ... do stuff ...
3617   }
3618
3619   $rs->first; # without cache, this would issue a query
3620
3621 By default, searches are not cached.
3622
3623 For more examples of using these attributes, see
3624 L<DBIx::Class::Manual::Cookbook>.
3625
3626 =head2 for
3627
3628 =over 4
3629
3630 =item Value: ( 'update' | 'shared' )
3631
3632 =back
3633
3634 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3635 ... FOR SHARED.
3636
3637 =cut
3638
3639 1;