lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray UNRESOLVABLE_CONDITION
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304   return $class->new_result(@_) if ref $class;
 305
 306   my ($source, $attrs) = @_;
 307   $source = $source->resolve
 308     if $source->isa('DBIx::Class::ResultSourceHandle');
 309
 310   $attrs = { %{$attrs||{}} };
 311   delete @{$attrs}{qw(_last_sqlmaker_alias_map _related_results_construction)};
 312
 313   if ($attrs->{page}) {
 314     $attrs->{rows} ||= 10;
 315   }
 316
 317   $attrs->{alias} ||= 'me';
 318
 319   my $self = bless {
 320     result_source => $source,
 321     cond => $attrs->{where},
 322     pager => undef,
 323     attrs => $attrs,
 324   }, $class;
 325
 326   # if there is a dark selector, this means we are already in a
 327   # chain and the cleanup/sanification was taken care of by
 328   # _search_rs already
 329   $self->_normalize_selection($attrs)
 330     unless $attrs->{_dark_selector};
 331
 332   $self->result_class(
 333     $attrs->{result_class} || $source->result_class
 334   );
 335
 336   $self;
 337 }
 338
 339 =head2 search
 340
 341 =over 4
 342
 343 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 344
 345 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 346
 347 =back
 348
 349   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 350   my $new_rs = $cd_rs->search({ year => 2005 });
 351
 352   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 353                  # year = 2005 OR year = 2004
 354
 355 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 356 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 357 To avoid that, use L</search_rs>.
 358
 359 If you need to pass in additional attributes but no additional condition,
 360 call it as C<search(undef, \%attrs)>.
 361
 362   # "SELECT name, artistid FROM $artist_table"
 363   my @all_artists = $schema->resultset('Artist')->search(undef, {
 364     columns => [qw/name artistid/],
 365   });
 366
 367 For a list of attributes that can be passed to C<search>, see
 368 L</ATTRIBUTES>. For more examples of using this function, see
 369 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 370 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 371 and its extension L<DBIx::Class::SQLMaker>.
 372
 373 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 374
 375 =head3 CAVEAT
 376
 377 Note that L</search> does not process/deflate any of the values passed in the
 378 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 379 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 380 manually that any value passed to this method will stringify to something the
 381 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 382 objects, for more info see:
 383 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 384
 385 =cut
 386
 387 sub search {
 388   my $self = shift;
 389   my $rs = $self->search_rs( @_ );
 390
 391   if (wantarray) {
 392     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 393     return $rs->all;
 394   }
 395   elsif (defined wantarray) {
 396     return $rs;
 397   }
 398   else {
 399     # we can be called by a relationship helper, which in
 400     # turn may be called in void context due to some braindead
 401     # overload or whatever else the user decided to be clever
 402     # at this particular day. Thus limit the exception to
 403     # external code calls only
 404     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 405       if (caller)[0] !~ /^\QDBIx::Class::/;
 406
 407     return ();
 408   }
 409 }
 410
 411 =head2 search_rs
 412
 413 =over 4
 414
 415 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 416
 417 =item Return Value: L<$resultset|/search>
 418
 419 =back
 420
 421 This method does the same exact thing as search() except it will
 422 always return a resultset, even in list context.
 423
 424 =cut
 425
 426 sub search_rs {
 427   my $self = shift;
 428
 429   my $rsrc = $self->result_source;
 430   my ($call_cond, $call_attrs);
 431
 432   # Special-case handling for (undef, undef) or (undef)
 433   # Note that (foo => undef) is valid deprecated syntax
 434   @_ = () if not scalar grep { defined $_ } @_;
 435
 436   # just a cond
 437   if (@_ == 1) {
 438     $call_cond = shift;
 439   }
 440   # fish out attrs in the ($condref, $attr) case
 441   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 442     ($call_cond, $call_attrs) = @_;
 443   }
 444   elsif (@_ % 2) {
 445     $self->throw_exception('Odd number of arguments to search')
 446   }
 447   # legacy search
 448   elsif (@_) {
 449     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 450       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 451
 452     for my $i (0 .. $#_) {
 453       next if $i % 2;
 454       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 455         if (! defined $_[$i] or ref $_[$i] ne '');
 456     }
 457
 458     $call_cond = { @_ };
 459   }
 460
 461   # see if we can keep the cache (no $rs changes)
 462   my $cache;
 463   my %safe = (alias => 1, cache => 1);
 464   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 465     ! defined $call_cond
 466       or
 467     ref $call_cond eq 'HASH' && ! keys %$call_cond
 468       or
 469     ref $call_cond eq 'ARRAY' && ! @$call_cond
 470   )) {
 471     $cache = $self->get_cache;
 472   }
 473
 474   my $old_attrs = { %{$self->{attrs}} };
 475   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 476
 477   my $new_attrs = { %$old_attrs };
 478
 479   # take care of call attrs (only if anything is changing)
 480   if ($call_attrs and keys %$call_attrs) {
 481
 482     # copy for _normalize_selection
 483     $call_attrs = { %$call_attrs };
 484
 485     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 486
 487     # reset the current selector list if new selectors are supplied
 488     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 489       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 490     }
 491
 492     # Normalize the new selector list (operates on the passed-in attr structure)
 493     # Need to do it on every chain instead of only once on _resolved_attrs, in
 494     # order to allow detection of empty vs partial 'as'
 495     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 496       if $old_attrs->{_dark_selector};
 497     $self->_normalize_selection ($call_attrs);
 498
 499     # start with blind overwriting merge, exclude selector attrs
 500     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 501     delete @{$new_attrs}{@selector_attrs};
 502
 503     for (@selector_attrs) {
 504       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 505         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 506     }
 507
 508     # older deprecated name, use only if {columns} is not there
 509     if (my $c = delete $new_attrs->{cols}) {
 510       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 511       if ($new_attrs->{columns}) {
 512         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 513       }
 514       else {
 515         $new_attrs->{columns} = $c;
 516       }
 517     }
 518
 519
 520     # join/prefetch use their own crazy merging heuristics
 521     foreach my $key (qw/join prefetch/) {
 522       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 523         if exists $call_attrs->{$key};
 524     }
 525
 526     # stack binds together
 527     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 528   }
 529
 530
 531   for ($old_where, $call_cond) {
 532     if (defined $_) {
 533       $new_attrs->{where} = $self->_stack_cond (
 534         $_, $new_attrs->{where}
 535       );
 536     }
 537   }
 538
 539   if (defined $old_having) {
 540     $new_attrs->{having} = $self->_stack_cond (
 541       $old_having, $new_attrs->{having}
 542     )
 543   }
 544
 545   my $rs = (ref $self)->new($rsrc, $new_attrs);
 546
 547   $rs->set_cache($cache) if ($cache);
 548
 549   return $rs;
 550 }
 551
 552 my $dark_sel_dumper;
 553 sub _normalize_selection {
 554   my ($self, $attrs) = @_;
 555
 556   # legacy syntax
 557   if ( exists $attrs->{include_columns} ) {
 558     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 559     $attrs->{'+columns'} = $self->_merge_attr(
 560       $attrs->{'+columns'}, delete $attrs->{include_columns}
 561     );
 562   }
 563
 564   # columns are always placed first, however
 565
 566   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 567   # delay the decision on whether to use a default select list ($rsrc->columns)
 568   # allowing stuff like the remove_columns helper to work
 569   #
 570   # select/as +select/+as pairs need special handling - the amount of select/as
 571   # elements in each pair does *not* have to be equal (think multicolumn
 572   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 573   # supplied at all) - try to infer the alias, either from the -as parameter
 574   # of the selector spec, or use the parameter whole if it looks like a column
 575   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 576   # is ok as well), but make sure no more additions to the 'as' chain take place
 577   for my $pref ('', '+') {
 578
 579     my ($sel, $as) = map {
 580       my $key = "${pref}${_}";
 581
 582       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 583         ? @{$attrs->{$key}}
 584         : $attrs->{$key} || ()
 585       ];
 586       delete $attrs->{$key};
 587       $val;
 588     } qw/select as/;
 589
 590     if (! @$as and ! @$sel ) {
 591       next;
 592     }
 593     elsif (@$as and ! @$sel) {
 594       $self->throw_exception(
 595         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 596       );
 597     }
 598     elsif( ! @$as ) {
 599       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 600       # if any @$as has been supplied we assume the user knows what (s)he is doing
 601       # and blindly keep stacking up pieces
 602       unless ($attrs->{_dark_selector}) {
 603         SELECTOR:
 604         for (@$sel) {
 605           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 606             push @$as, $_->{-as};
 607           }
 608           # assume any plain no-space, no-parenthesis string to be a column spec
 609           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 610           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 611             push @$as, $_;
 612           }
 613           # if all else fails - raise a flag that no more aliasing will be allowed
 614           else {
 615             $attrs->{_dark_selector} = {
 616               plus_stage => $pref,
 617               string => ($dark_sel_dumper ||= do {
 618                   require Data::Dumper::Concise;
 619                   Data::Dumper::Concise::DumperObject()->Indent(0);
 620                 })->Values([$_])->Dump
 621               ,
 622             };
 623             last SELECTOR;
 624           }
 625         }
 626       }
 627     }
 628     elsif (@$as < @$sel) {
 629       $self->throw_exception(
 630         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 631       );
 632     }
 633     elsif ($pref and $attrs->{_dark_selector}) {
 634       $self->throw_exception(
 635         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 636       );
 637     }
 638
 639
 640     # merge result
 641     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 642     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 643   }
 644 }
 645
 646 sub _stack_cond {
 647   my ($self, $left, $right) = @_;
 648
 649   (
 650     (ref $_ eq 'ARRAY' and !@$_)
 651       or
 652     (ref $_ eq 'HASH' and ! keys %$_)
 653   ) and $_ = undef for ($left, $right);
 654
 655   # either on of the two undef or both undef
 656   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 657     return defined $left ? $left : $right;
 658   }
 659
 660   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 661
 662   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 663
 664     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 665     my @fin = shift @vals;
 666
 667     for my $v (@vals) {
 668       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 669     }
 670
 671     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 672   }
 673
 674   $cond;
 675 }
 676
 677 =head2 search_literal
 678
 679 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 680 should only be used in that context. C<search_literal> is a convenience
 681 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 682 want to ensure columns are bound correctly, use L</search>.
 683
 684 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 685 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 686 require C<search_literal>.
 687
 688 =over 4
 689
 690 =item Arguments: $sql_fragment, @standalone_bind_values
 691
 692 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 693
 694 =back
 695
 696   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 697   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 698
 699 Pass a literal chunk of SQL to be added to the conditional part of the
 700 resultset query.
 701
 702 Example of how to use C<search> instead of C<search_literal>
 703
 704   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 705   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 706
 707 =cut
 708
 709 sub search_literal {
 710   my ($self, $sql, @bind) = @_;
 711   my $attr;
 712   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 713     $attr = pop @bind;
 714   }
 715   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 716 }
 717
 718 =head2 find
 719
 720 =over 4
 721
 722 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 723
 724 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 725
 726 =back
 727
 728 Finds and returns a single row based on supplied criteria. Takes either a
 729 hashref with the same format as L</create> (including inference of foreign
 730 keys from related objects), or a list of primary key values in the same
 731 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 732 declaration on the L</result_source>.
 733
 734 In either case an attempt is made to combine conditions already existing on
 735 the resultset with the condition passed to this method.
 736
 737 To aid with preparing the correct query for the storage you may supply the
 738 C<key> attribute, which is the name of a
 739 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 740 unique constraint corresponding to the
 741 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 742 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 743 to construct a query that satisfies the named unique constraint fully (
 744 non-NULL values for each column member of the constraint) an exception is
 745 thrown.
 746
 747 If no C<key> is specified, the search is carried over all unique constraints
 748 which are fully defined by the available condition.
 749
 750 If no such constraint is found, C<find> currently defaults to a simple
 751 C<< search->(\%column_values) >> which may or may not do what you expect.
 752 Note that this fallback behavior may be deprecated in further versions. If
 753 you need to search with arbitrary conditions - use L</search>. If the query
 754 resulting from this fallback produces more than one row, a warning to the
 755 effect is issued, though only the first row is constructed and returned as
 756 C<$result_object>.
 757
 758 In addition to C<key>, L</find> recognizes and applies standard
 759 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 760
 761 Note that if you have extra concerns about the correctness of the resulting
 762 query you need to specify the C<key> attribute and supply the entire condition
 763 as an argument to find (since it is not always possible to perform the
 764 combination of the resultset condition with the supplied one, especially if
 765 the resultset condition contains literal sql).
 766
 767 For example, to find a row by its primary key:
 768
 769   my $cd = $schema->resultset('CD')->find(5);
 770
 771 You can also find a row by a specific unique constraint:
 772
 773   my $cd = $schema->resultset('CD')->find(
 774     {
 775       artist => 'Massive Attack',
 776       title  => 'Mezzanine',
 777     },
 778     { key => 'cd_artist_title' }
 779   );
 780
 781 See also L</find_or_create> and L</update_or_create>.
 782
 783 =cut
 784
 785 sub find {
 786   my $self = shift;
 787   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 788
 789   my $rsrc = $self->result_source;
 790
 791   my $constraint_name;
 792   if (exists $attrs->{key}) {
 793     $constraint_name = defined $attrs->{key}
 794       ? $attrs->{key}
 795       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 796     ;
 797   }
 798
 799   # Parse out the condition from input
 800   my $call_cond;
 801
 802   if (ref $_[0] eq 'HASH') {
 803     $call_cond = { %{$_[0]} };
 804   }
 805   else {
 806     # if only values are supplied we need to default to 'primary'
 807     $constraint_name = 'primary' unless defined $constraint_name;
 808
 809     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 810
 811     $self->throw_exception(
 812       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 813     ) unless @c_cols;
 814
 815     $self->throw_exception (
 816       'find() expects either a column/value hashref, or a list of values '
 817     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 818     ) unless @c_cols == @_;
 819
 820     $call_cond = {};
 821     @{$call_cond}{@c_cols} = @_;
 822   }
 823
 824   my %related;
 825   for my $key (keys %$call_cond) {
 826     if (
 827       my $keyref = ref($call_cond->{$key})
 828         and
 829       my $relinfo = $rsrc->relationship_info($key)
 830     ) {
 831       my $val = delete $call_cond->{$key};
 832
 833       next if $keyref eq 'ARRAY'; # has_many for multi_create
 834
 835       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 836         $relinfo->{cond}, $val, $key, $key
 837       );
 838
 839       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 840          if $crosstable or ref($rel_cond) ne 'HASH';
 841
 842       # supplement
 843       @related{keys %$rel_cond} = values %$rel_cond;
 844     }
 845   }
 846
 847   # relationship conditions take precedence (?)
 848   @{$call_cond}{keys %related} = values %related;
 849
 850   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 851   my $final_cond;
 852   if (defined $constraint_name) {
 853     $final_cond = $self->_qualify_cond_columns (
 854
 855       $self->_build_unique_cond (
 856         $constraint_name,
 857         $call_cond,
 858       ),
 859
 860       $alias,
 861     );
 862   }
 863   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 864     # This means that we got here after a merger of relationship conditions
 865     # in ::Relationship::Base::search_related (the row method), and furthermore
 866     # the relationship is of the 'single' type. This means that the condition
 867     # provided by the relationship (already attached to $self) is sufficient,
 868     # as there can be only one row in the database that would satisfy the
 869     # relationship
 870   }
 871   else {
 872     # no key was specified - fall down to heuristics mode:
 873     # run through all unique queries registered on the resultset, and
 874     # 'OR' all qualifying queries together
 875     my (@unique_queries, %seen_column_combinations);
 876     for my $c_name ($rsrc->unique_constraint_names) {
 877       next if $seen_column_combinations{
 878         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 879       }++;
 880
 881       push @unique_queries, try {
 882         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 883       } || ();
 884     }
 885
 886     $final_cond = @unique_queries
 887       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 888       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 889     ;
 890   }
 891
 892   # Run the query, passing the result_class since it should propagate for find
 893   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 894   if ($rs->_resolved_attrs->{collapse}) {
 895     my $row = $rs->next;
 896     carp "Query returned more than one row" if $rs->next;
 897     return $row;
 898   }
 899   else {
 900     return $rs->single;
 901   }
 902 }
 903
 904 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 905 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 906 #
 907 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 908 # condition. It is provided for overrides until a saner way forward is devised
 909 #
 910 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 911 # the road. Please adjust your tests accordingly to catch this situation early
 912 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 913 #
 914 # The method will not be removed without an adequately complete replacement
 915 # for strict-mode enforcement
 916 sub _non_unique_find_fallback {
 917   my ($self, $cond, $attrs) = @_;
 918
 919   return $self->_qualify_cond_columns(
 920     $cond,
 921     exists $attrs->{alias}
 922       ? $attrs->{alias}
 923       : $self->{attrs}{alias}
 924   );
 925 }
 926
 927
 928 sub _qualify_cond_columns {
 929   my ($self, $cond, $alias) = @_;
 930
 931   my %aliased = %$cond;
 932   for (keys %aliased) {
 933     $aliased{"$alias.$_"} = delete $aliased{$_}
 934       if $_ !~ /\./;
 935   }
 936
 937   return \%aliased;
 938 }
 939
 940 sub _build_unique_cond {
 941   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 942
 943   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 944
 945   # combination may fail if $self->{cond} is non-trivial
 946   my ($final_cond) = try {
 947     $self->_merge_with_rscond ($extra_cond)
 948   } catch {
 949     +{ %$extra_cond }
 950   };
 951
 952   # trim out everything not in $columns
 953   $final_cond = { map {
 954     exists $final_cond->{$_}
 955       ? ( $_ => $final_cond->{$_} )
 956       : ()
 957   } @c_cols };
 958
 959   if (my @missing = grep
 960     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 961     (@c_cols)
 962   ) {
 963     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 964       $constraint_name,
 965       join (', ', map { "'$_'" } @missing),
 966     ) );
 967   }
 968
 969   if (
 970     !$croak_on_null
 971       and
 972     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 973       and
 974     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 975   ) {
 976     carp_unique ( sprintf (
 977       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 978     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 979     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 980       $constraint_name,
 981       join (', ', map { "'$_'" } @undefs),
 982     ));
 983   }
 984
 985   return $final_cond;
 986 }
 987
 988 =head2 search_related
 989
 990 =over 4
 991
 992 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 993
 994 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 995
 996 =back
 997
 998   $new_rs = $cd_rs->search_related('artist', {
 999     name => 'Emo-R-Us',
1000   });
1001
1002 Searches the specified relationship, optionally specifying a condition and
1003 attributes for matching records. See L</ATTRIBUTES> for more information.
1004
1005 In list context, C<< ->all() >> is called implicitly on the resultset, thus
1006 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
1007
1008 See also L</search_related_rs>.
1009
1010 =cut
1011
1012 sub search_related {
1013   return shift->related_resultset(shift)->search(@_);
1014 }
1015
1016 =head2 search_related_rs
1017
1018 This method works exactly the same as search_related, except that
1019 it guarantees a resultset, even in list context.
1020
1021 =cut
1022
1023 sub search_related_rs {
1024   return shift->related_resultset(shift)->search_rs(@_);
1025 }
1026
1027 =head2 cursor
1028
1029 =over 4
1030
1031 =item Arguments: none
1032
1033 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1034
1035 =back
1036
1037 Returns a storage-driven cursor to the given resultset. See
1038 L<DBIx::Class::Cursor> for more information.
1039
1040 =cut
1041
1042 sub cursor {
1043   my $self = shift;
1044
1045   return $self->{cursor} ||= do {
1046     my $attrs = $self->_resolved_attrs;
1047     $self->result_source->storage->select(
1048       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1049     );
1050   };
1051 }
1052
1053 =head2 single
1054
1055 =over 4
1056
1057 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1058
1059 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1060
1061 =back
1062
1063   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1064
1065 Inflates the first result without creating a cursor if the resultset has
1066 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1067 of L</search>.
1068
1069 While this method can take an optional search condition (just like L</search>)
1070 being a fast-code-path it does not recognize search attributes. If you need to
1071 add extra joins or similar, call L</search> and then chain-call L</single> on the
1072 L<DBIx::Class::ResultSet> returned.
1073
1074 =over
1075
1076 =item B<Note>
1077
1078 As of 0.08100, this method enforces the assumption that the preceding
1079 query returns only one row. If more than one row is returned, you will receive
1080 a warning:
1081
1082   Query returned more than one row
1083
1084 In this case, you should be using L</next> or L</find> instead, or if you really
1085 know what you are doing, use the L</rows> attribute to explicitly limit the size
1086 of the resultset.
1087
1088 This method will also throw an exception if it is called on a resultset prefetching
1089 has_many, as such a prefetch implies fetching multiple rows from the database in
1090 order to assemble the resulting object.
1091
1092 =back
1093
1094 =cut
1095
1096 sub single {
1097   my ($self, $where) = @_;
1098   if(@_ > 2) {
1099       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1100   }
1101
1102   my $attrs = { %{$self->_resolved_attrs} };
1103
1104   $self->throw_exception(
1105     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1106   ) if $attrs->{collapse};
1107
1108   if ($where) {
1109     if (defined $attrs->{where}) {
1110       $attrs->{where} = {
1111         '-and' =>
1112             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1113                $where, delete $attrs->{where} ]
1114       };
1115     } else {
1116       $attrs->{where} = $where;
1117     }
1118   }
1119
1120   my $data = [ $self->result_source->storage->select_single(
1121     $attrs->{from}, $attrs->{select},
1122     $attrs->{where}, $attrs
1123   )];
1124
1125   return undef unless @$data;
1126   $self->{_stashed_rows} = [ $data ];
1127   $self->_construct_results->[0];
1128 }
1129
1130 =head2 get_column
1131
1132 =over 4
1133
1134 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1135
1136 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1137
1138 =back
1139
1140   my $max_length = $rs->get_column('length')->max;
1141
1142 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1143
1144 =cut
1145
1146 sub get_column {
1147   my ($self, $column) = @_;
1148   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1149   return $new;
1150 }
1151
1152 =head2 search_like
1153
1154 =over 4
1155
1156 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1157
1158 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1159
1160 =back
1161
1162   # WHERE title LIKE '%blue%'
1163   $cd_rs = $rs->search_like({ title => '%blue%'});
1164
1165 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1166 that this is simply a convenience method retained for ex Class::DBI users.
1167 You most likely want to use L</search> with specific operators.
1168
1169 For more information, see L<DBIx::Class::Manual::Cookbook>.
1170
1171 This method is deprecated and will be removed in 0.09. Use L</search()>
1172 instead. An example conversion is:
1173
1174   ->search_like({ foo => 'bar' });
1175
1176   # Becomes
1177
1178   ->search({ foo => { like => 'bar' } });
1179
1180 =cut
1181
1182 sub search_like {
1183   my $class = shift;
1184   carp_unique (
1185     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1186    .' Instead use ->search({ x => { -like => "y%" } })'
1187    .' (note the outer pair of {}s - they are important!)'
1188   );
1189   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1190   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1191   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1192   return $class->search($query, { %$attrs });
1193 }
1194
1195 =head2 slice
1196
1197 =over 4
1198
1199 =item Arguments: $first, $last
1200
1201 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1202
1203 =back
1204
1205 Returns a resultset or object list representing a subset of elements from the
1206 resultset slice is called on. Indexes are from 0, i.e., to get the first
1207 three records, call:
1208
1209   my ($one, $two, $three) = $rs->slice(0, 2);
1210
1211 =cut
1212
1213 sub slice {
1214   my ($self, $min, $max) = @_;
1215   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1216   $attrs->{offset} = $self->{attrs}{offset} || 0;
1217   $attrs->{offset} += $min;
1218   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1219   return $self->search(undef, $attrs);
1220 }
1221
1222 =head2 next
1223
1224 =over 4
1225
1226 =item Arguments: none
1227
1228 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1229
1230 =back
1231
1232 Returns the next element in the resultset (C<undef> is there is none).
1233
1234 Can be used to efficiently iterate over records in the resultset:
1235
1236   my $rs = $schema->resultset('CD')->search;
1237   while (my $cd = $rs->next) {
1238     print $cd->title;
1239   }
1240
1241 Note that you need to store the resultset object, and call C<next> on it.
1242 Calling C<< resultset('Table')->next >> repeatedly will always return the
1243 first record from the resultset.
1244
1245 =cut
1246
1247 sub next {
1248   my ($self) = @_;
1249
1250   if (my $cache = $self->get_cache) {
1251     $self->{all_cache_position} ||= 0;
1252     return $cache->[$self->{all_cache_position}++];
1253   }
1254
1255   if ($self->{attrs}{cache}) {
1256     delete $self->{pager};
1257     $self->{all_cache_position} = 1;
1258     return ($self->all)[0];
1259   }
1260
1261   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1262
1263   $self->{_stashed_results} = $self->_construct_results
1264     or return undef;
1265
1266   return shift @{$self->{_stashed_results}};
1267 }
1268
1269 # Constructs as many results as it can in one pass while respecting
1270 # cursor laziness. Several modes of operation:
1271 #
1272 # * Always builds everything present in @{$self->{_stashed_rows}}
1273 # * If called with $fetch_all true - pulls everything off the cursor and
1274 #   builds all result structures (or objects) in one pass
1275 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1276 #   and if the resultset is ordered properly by the left side:
1277 #   * Fetches stuff off the cursor until the "master object" changes,
1278 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1279 #   OR
1280 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1281 #     was requested (there is no other way to collapse except for an
1282 #     eager cursor)
1283 # * If no collapse is requested - just get the next row, construct and
1284 #   return
1285 sub _construct_results {
1286   my ($self, $fetch_all) = @_;
1287
1288   my $rsrc = $self->result_source;
1289   my $attrs = $self->_resolved_attrs;
1290
1291   if (
1292     ! $fetch_all
1293       and
1294     ! $attrs->{order_by}
1295       and
1296     $attrs->{collapse}
1297       and
1298     my @pcols = $rsrc->primary_columns
1299   ) {
1300     # default order for collapsing unless the user asked for something
1301     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1302     $attrs->{_ordered_for_collapse} = 1;
1303     $attrs->{_order_is_artificial} = 1;
1304   }
1305
1306   # this will be used as both initial raw-row collector AND as a RV of
1307   # _construct_results. Not regrowing the array twice matters a lot...
1308   # a surprising amount actually
1309   my $rows = delete $self->{_stashed_rows};
1310
1311   my $cursor; # we may not need one at all
1312
1313   my $did_fetch_all = $fetch_all;
1314
1315   if ($fetch_all) {
1316     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1317     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1318   }
1319   elsif( $attrs->{collapse} ) {
1320
1321     # a cursor will need to be closed over in case of collapse
1322     $cursor = $self->cursor;
1323
1324     $attrs->{_ordered_for_collapse} = (
1325       (
1326         $attrs->{order_by}
1327           and
1328         $rsrc->schema
1329               ->storage
1330                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1331       ) ? 1 : 0
1332     ) unless defined $attrs->{_ordered_for_collapse};
1333
1334     if (! $attrs->{_ordered_for_collapse}) {
1335       $did_fetch_all = 1;
1336
1337       # instead of looping over ->next, use ->all in stealth mode
1338       # *without* calling a ->reset afterwards
1339       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1340       if (! $cursor->{_done}) {
1341         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1342         $cursor->{_done} = 1;
1343       }
1344     }
1345   }
1346
1347   if (! $did_fetch_all and ! @{$rows||[]} ) {
1348     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1349     $cursor ||= $self->cursor;
1350     if (scalar (my @r = $cursor->next) ) {
1351       $rows = [ \@r ];
1352     }
1353   }
1354
1355   return undef unless @{$rows||[]};
1356
1357   # sanity check - people are too clever for their own good
1358   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1359
1360     my $multiplied_selectors;
1361     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1362       if (
1363         $aliastypes->{multiplying}{$sel_alias}
1364           or
1365         $aliastypes->{premultiplied}{$sel_alias}
1366       ) {
1367         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1368       }
1369     }
1370
1371     for my $i (0 .. $#{$attrs->{as}} ) {
1372       my $sel = $attrs->{select}[$i];
1373
1374       if (ref $sel eq 'SCALAR') {
1375         $sel = $$sel;
1376       }
1377       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1378         $sel = $$sel->[0];
1379       }
1380
1381       $self->throw_exception(
1382         'Result collapse not possible - selection from a has_many source redirected to the main object'
1383       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1384     }
1385   }
1386
1387   # hotspot - skip the setter
1388   my $res_class = $self->_result_class;
1389
1390   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1391     $res_class->can ('inflate_result')
1392       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1393   };
1394
1395   my $infmap = $attrs->{as};
1396
1397   $self->{_result_inflator}{is_core_row} = ( (
1398     $inflator_cref
1399       ==
1400     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1401   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1402
1403   $self->{_result_inflator}{is_hri} = ( (
1404     ! $self->{_result_inflator}{is_core_row}
1405       and
1406     $inflator_cref == (
1407       require DBIx::Class::ResultClass::HashRefInflator
1408         &&
1409       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1410     )
1411   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1412
1413
1414   if (! $attrs->{_related_results_construction}) {
1415     # construct a much simpler array->hash folder for the one-table cases right here
1416     if ($self->{_result_inflator}{is_hri}) {
1417       for my $r (@$rows) {
1418         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1419       }
1420     }
1421     # FIXME SUBOPTIMAL this is a very very very hot spot
1422     # while rather optimal we can *still* do much better, by
1423     # building a smarter Row::inflate_result(), and
1424     # switch to feeding it data via a much leaner interface
1425     #
1426     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1427     # this particular resultset size
1428     elsif (@$rows < 60) {
1429       for my $r (@$rows) {
1430         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1431       }
1432     }
1433     else {
1434       eval sprintf (
1435         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1436         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1437       );
1438     }
1439   }
1440   else {
1441     my $parser_type =
1442         $self->{_result_inflator}{is_hri}       ? 'hri'
1443       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1444       :                                           'classic_nonpruning'
1445     ;
1446
1447     # $args and $attrs to _mk_row_parser are separated to delineate what is
1448     # core collapser stuff and what is dbic $rs specific
1449     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1450       eval => 1,
1451       inflate_map => $infmap,
1452       collapse => $attrs->{collapse},
1453       premultiplied => $attrs->{_main_source_premultiplied},
1454       hri_style => $self->{_result_inflator}{is_hri},
1455       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1456     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1457
1458     # column_info metadata historically hasn't been too reliable.
1459     # We need to start fixing this somehow (the collapse resolver
1460     # can't work without it). Add an explicit check for the *main*
1461     # result, hopefully this will gradually weed out such errors
1462     #
1463     # FIXME - this is a temporary kludge that reduces performance
1464     # It is however necessary for the time being
1465     my ($unrolled_non_null_cols_to_check, $err);
1466
1467     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1468
1469       $err =
1470         'Collapse aborted due to invalid ResultSource metadata - the following '
1471       . 'selections are declared non-nullable but NULLs were retrieved: '
1472       ;
1473
1474       my @violating_idx;
1475       COL: for my $i (@$check_non_null_cols) {
1476         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1477       }
1478
1479       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1480         if @violating_idx;
1481
1482       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1483     }
1484
1485     my $next_cref =
1486       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1487     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1488 sub {
1489   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1490   my @r = $cursor->next or return;
1491   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1492     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1493   }
1494   \@r
1495 }
1496 EOS
1497     : sub {
1498         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1499         my @r = $cursor->next or return;
1500         \@r
1501       }
1502     ;
1503
1504     $self->{_row_parser}{$parser_type}{cref}->(
1505       $rows,
1506       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1507     );
1508
1509     # Special-case multi-object HRI - there is no $inflator_cref pass
1510     unless ($self->{_result_inflator}{is_hri}) {
1511       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1512     }
1513   }
1514
1515   # The @$rows check seems odd at first - why wouldn't we want to warn
1516   # regardless? The issue is things like find() etc, where the user
1517   # *knows* only one result will come back. In these cases the ->all
1518   # is not a pessimization, but rather something we actually want
1519   carp_unique(
1520     'Unable to properly collapse has_many results in iterator mode due '
1521   . 'to order criteria - performed an eager cursor slurp underneath. '
1522   . 'Consider using ->all() instead'
1523   ) if ( ! $fetch_all and @$rows > 1 );
1524
1525   return $rows;
1526 }
1527
1528 =head2 result_source
1529
1530 =over 4
1531
1532 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1533
1534 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1535
1536 =back
1537
1538 An accessor for the primary ResultSource object from which this ResultSet
1539 is derived.
1540
1541 =head2 result_class
1542
1543 =over 4
1544
1545 =item Arguments: $result_class?
1546
1547 =item Return Value: $result_class
1548
1549 =back
1550
1551 An accessor for the class to use when creating result objects. Defaults to
1552 C<< result_source->result_class >> - which in most cases is the name of the
1553 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1554
1555 Note that changing the result_class will also remove any components
1556 that were originally loaded in the source class via
1557 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1558 in the original source class will not run.
1559
1560 =cut
1561
1562 sub result_class {
1563   my ($self, $result_class) = @_;
1564   if ($result_class) {
1565
1566     # don't fire this for an object
1567     $self->ensure_class_loaded($result_class)
1568       unless ref($result_class);
1569
1570     if ($self->get_cache) {
1571       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1572     }
1573     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1574     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1575       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1576     }
1577
1578     $self->_result_class($result_class);
1579
1580     delete $self->{_result_inflator};
1581   }
1582   $self->_result_class;
1583 }
1584
1585 =head2 count
1586
1587 =over 4
1588
1589 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1590
1591 =item Return Value: $count
1592
1593 =back
1594
1595 Performs an SQL C<COUNT> with the same query as the resultset was built
1596 with to find the number of elements. Passing arguments is equivalent to
1597 C<< $rs->search ($cond, \%attrs)->count >>
1598
1599 =cut
1600
1601 sub count {
1602   my $self = shift;
1603   return $self->search(@_)->count if @_ and defined $_[0];
1604   return scalar @{ $self->get_cache } if $self->get_cache;
1605
1606   my $attrs = { %{ $self->_resolved_attrs } };
1607
1608   # this is a little optimization - it is faster to do the limit
1609   # adjustments in software, instead of a subquery
1610   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1611
1612   my $crs;
1613   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1614     $crs = $self->_count_subq_rs ($attrs);
1615   }
1616   else {
1617     $crs = $self->_count_rs ($attrs);
1618   }
1619   my $count = $crs->next;
1620
1621   $count -= $offset if $offset;
1622   $count = $rows if $rows and $rows < $count;
1623   $count = 0 if ($count < 0);
1624
1625   return $count;
1626 }
1627
1628 =head2 count_rs
1629
1630 =over 4
1631
1632 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1633
1634 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1635
1636 =back
1637
1638 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1639 This can be very handy for subqueries:
1640
1641   ->search( { amount => $some_rs->count_rs->as_query } )
1642
1643 As with regular resultsets the SQL query will be executed only after
1644 the resultset is accessed via L</next> or L</all>. That would return
1645 the same single value obtainable via L</count>.
1646
1647 =cut
1648
1649 sub count_rs {
1650   my $self = shift;
1651   return $self->search(@_)->count_rs if @_;
1652
1653   # this may look like a lack of abstraction (count() does about the same)
1654   # but in fact an _rs *must* use a subquery for the limits, as the
1655   # software based limiting can not be ported if this $rs is to be used
1656   # in a subquery itself (i.e. ->as_query)
1657   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1658     return $self->_count_subq_rs($self->{_attrs});
1659   }
1660   else {
1661     return $self->_count_rs($self->{_attrs});
1662   }
1663 }
1664
1665 #
1666 # returns a ResultSetColumn object tied to the count query
1667 #
1668 sub _count_rs {
1669   my ($self, $attrs) = @_;
1670
1671   my $rsrc = $self->result_source;
1672
1673   my $tmp_attrs = { %$attrs };
1674   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1675   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1676
1677   # overwrite the selector (supplied by the storage)
1678   $rsrc->resultset_class->new($rsrc, {
1679     %$tmp_attrs,
1680     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1681     as => 'count',
1682   })->get_column ('count');
1683 }
1684
1685 #
1686 # same as above but uses a subquery
1687 #
1688 sub _count_subq_rs {
1689   my ($self, $attrs) = @_;
1690
1691   my $rsrc = $self->result_source;
1692
1693   my $sub_attrs = { %$attrs };
1694   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1695   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1696
1697   # if we multi-prefetch we group_by something unique, as this is what we would
1698   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1699   if ( $attrs->{collapse}  ) {
1700     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1701       $rsrc->_identifying_column_set || $self->throw_exception(
1702         'Unable to construct a unique group_by criteria properly collapsing the '
1703       . 'has_many prefetch before count()'
1704       );
1705     } ]
1706   }
1707
1708   # Calculate subquery selector
1709   if (my $g = $sub_attrs->{group_by}) {
1710
1711     my $sql_maker = $rsrc->storage->sql_maker;
1712
1713     # necessary as the group_by may refer to aliased functions
1714     my $sel_index;
1715     for my $sel (@{$attrs->{select}}) {
1716       $sel_index->{$sel->{-as}} = $sel
1717         if (ref $sel eq 'HASH' and $sel->{-as});
1718     }
1719
1720     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1721     # also look for named aggregates referred in the having clause
1722     # having often contains scalarrefs - thus parse it out entirely
1723     my @parts = @$g;
1724     if ($attrs->{having}) {
1725       local $sql_maker->{having_bind};
1726       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1727       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1728       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1729         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1730         # if we don't unset it we screw up retarded but unfortunately working
1731         # 'MAX(foo.bar)' => { '>', 3 }
1732         $sql_maker->{name_sep} = '';
1733       }
1734
1735       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1736
1737       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1738       my %seen_having;
1739
1740       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1741       # and if all fails for an utterly naive quoted scalar-with-function
1742       while ($having_sql =~ /
1743         $rquote $sep $lquote (.+?) $rquote
1744           |
1745         [\s,] \w+ \. (\w+) [\s,]
1746           |
1747         [\s,] $lquote (.+?) $rquote [\s,]
1748       /gx) {
1749         my $part = $1 || $2 || $3;  # one of them matched if we got here
1750         unless ($seen_having{$part}++) {
1751           push @parts, $part;
1752         }
1753       }
1754     }
1755
1756     for (@parts) {
1757       my $colpiece = $sel_index->{$_} || $_;
1758
1759       # unqualify join-based group_by's. Arcane but possible query
1760       # also horrible horrible hack to alias a column (not a func.)
1761       # (probably need to introduce SQLA syntax)
1762       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1763         my $as = $colpiece;
1764         $as =~ s/\./__/;
1765         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1766       }
1767       push @{$sub_attrs->{select}}, $colpiece;
1768     }
1769   }
1770   else {
1771     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1772     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1773   }
1774
1775   return $rsrc->resultset_class
1776                ->new ($rsrc, $sub_attrs)
1777                 ->as_subselect_rs
1778                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1779                   ->get_column ('count');
1780 }
1781
1782
1783 =head2 count_literal
1784
1785 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1786 should only be used in that context. See L</search_literal> for further info.
1787
1788 =over 4
1789
1790 =item Arguments: $sql_fragment, @standalone_bind_values
1791
1792 =item Return Value: $count
1793
1794 =back
1795
1796 Counts the results in a literal query. Equivalent to calling L</search_literal>
1797 with the passed arguments, then L</count>.
1798
1799 =cut
1800
1801 sub count_literal { shift->search_literal(@_)->count; }
1802
1803 =head2 all
1804
1805 =over 4
1806
1807 =item Arguments: none
1808
1809 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1810
1811 =back
1812
1813 Returns all elements in the resultset.
1814
1815 =cut
1816
1817 sub all {
1818   my $self = shift;
1819   if(@_) {
1820     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1821   }
1822
1823   delete @{$self}{qw/_stashed_rows _stashed_results/};
1824
1825   if (my $c = $self->get_cache) {
1826     return @$c;
1827   }
1828
1829   $self->cursor->reset;
1830
1831   my $objs = $self->_construct_results('fetch_all') || [];
1832
1833   $self->set_cache($objs) if $self->{attrs}{cache};
1834
1835   return @$objs;
1836 }
1837
1838 =head2 reset
1839
1840 =over 4
1841
1842 =item Arguments: none
1843
1844 =item Return Value: $self
1845
1846 =back
1847
1848 Resets the resultset's cursor, so you can iterate through the elements again.
1849 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1850 another query.
1851
1852 =cut
1853
1854 sub reset {
1855   my ($self) = @_;
1856
1857   delete @{$self}{qw/_stashed_rows _stashed_results/};
1858   $self->{all_cache_position} = 0;
1859   $self->cursor->reset;
1860   return $self;
1861 }
1862
1863 =head2 first
1864
1865 =over 4
1866
1867 =item Arguments: none
1868
1869 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1870
1871 =back
1872
1873 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1874 an object for the first result (or C<undef> if the resultset is empty).
1875
1876 =cut
1877
1878 sub first {
1879   return $_[0]->reset->next;
1880 }
1881
1882
1883 # _rs_update_delete
1884 #
1885 # Determines whether and what type of subquery is required for the $rs operation.
1886 # If grouping is necessary either supplies its own, or verifies the current one
1887 # After all is done delegates to the proper storage method.
1888
1889 sub _rs_update_delete {
1890   my ($self, $op, $values) = @_;
1891
1892   my $rsrc = $self->result_source;
1893   my $storage = $rsrc->schema->storage;
1894
1895   my $attrs = { %{$self->_resolved_attrs} };
1896
1897   my $join_classifications;
1898   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1899
1900   # do we need a subquery for any reason?
1901   my $needs_subq = (
1902     defined $existing_group_by
1903       or
1904     # if {from} is unparseable wrap a subq
1905     ref($attrs->{from}) ne 'ARRAY'
1906       or
1907     # limits call for a subq
1908     $self->_has_resolved_attr(qw/rows offset/)
1909   );
1910
1911   # simplify the joinmap, so we can further decide if a subq is necessary
1912   if (!$needs_subq and @{$attrs->{from}} > 1) {
1913
1914     ($attrs->{from}, $join_classifications) =
1915       $storage->_prune_unused_joins ($attrs);
1916
1917     # any non-pruneable non-local restricting joins imply subq
1918     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1919   }
1920
1921   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1922   $needs_subq ||= (
1923     (ref $attrs->{from}[0]) ne 'HASH'
1924       or
1925     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1926   );
1927
1928   my ($cond, $guard);
1929   # do we need anything like a subquery?
1930   if (! $needs_subq) {
1931     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1932     # a condition containing 'me' or other table prefixes will not work
1933     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1934     $cond = do {
1935       my $sqla = $rsrc->storage->sql_maker;
1936       local $sqla->{_dequalify_idents} = 1;
1937       \[ $sqla->_recurse_where($self->{cond}) ];
1938     };
1939   }
1940   else {
1941     # we got this far - means it is time to wrap a subquery
1942     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1943       sprintf(
1944         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1945         $op,
1946         $rsrc->source_name,
1947       )
1948     );
1949
1950     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1951     delete $attrs->{$_} for qw/select as collapse/;
1952     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1953
1954     # this will be consumed by the pruner waaaaay down the stack
1955     $attrs->{_force_prune_multiplying_joins} = 1;
1956
1957     my $subrs = (ref $self)->new($rsrc, $attrs);
1958
1959     if (@$idcols == 1) {
1960       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1961     }
1962     elsif ($storage->_use_multicolumn_in) {
1963       # no syntax for calling this properly yet
1964       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1965       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1966         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1967         $subrs->as_query
1968       ),
1969     }
1970     else {
1971       # if all else fails - get all primary keys and operate over a ORed set
1972       # wrap in a transaction for consistency
1973       # this is where the group_by/multiplication starts to matter
1974       if (
1975         $existing_group_by
1976           or
1977         # we do not need to check pre-multipliers, since if the premulti is there, its
1978         # parent (who is multi) will be there too
1979         keys %{ $join_classifications->{multiplying} || {} }
1980       ) {
1981         # make sure if there is a supplied group_by it matches the columns compiled above
1982         # perfectly. Anything else can not be sanely executed on most databases so croak
1983         # right then and there
1984         if ($existing_group_by) {
1985           my @current_group_by = map
1986             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1987             @$existing_group_by
1988           ;
1989
1990           if (
1991             join ("\x00", sort @current_group_by)
1992               ne
1993             join ("\x00", sort @{$attrs->{columns}} )
1994           ) {
1995             $self->throw_exception (
1996               "You have just attempted a $op operation on a resultset which does group_by"
1997               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1998               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1999               . ' kind of queries. Please retry the operation with a modified group_by or'
2000               . ' without using one at all.'
2001             );
2002           }
2003         }
2004
2005         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2006       }
2007
2008       $guard = $storage->txn_scope_guard;
2009
2010       for my $row ($subrs->cursor->all) {
2011         push @$cond, { map
2012           { $idcols->[$_] => $row->[$_] }
2013           (0 .. $#$idcols)
2014         };
2015       }
2016     }
2017   }
2018
2019   my $res = $cond ? $storage->$op (
2020     $rsrc,
2021     $op eq 'update' ? $values : (),
2022     $cond,
2023   ) : '0E0';
2024
2025   $guard->commit if $guard;
2026
2027   return $res;
2028 }
2029
2030 =head2 update
2031
2032 =over 4
2033
2034 =item Arguments: \%values
2035
2036 =item Return Value: $underlying_storage_rv
2037
2038 =back
2039
2040 Sets the specified columns in the resultset to the supplied values in a
2041 single query. Note that this will not run any accessor/set_column/update
2042 triggers, nor will it update any result object instances derived from this
2043 resultset (this includes the contents of the L<resultset cache|/set_cache>
2044 if any). See L</update_all> if you need to execute any on-update
2045 triggers or cascades defined either by you or a
2046 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2047
2048 The return value is a pass through of what the underlying
2049 storage backend returned, and may vary. See L<DBI/execute> for the most
2050 common case.
2051
2052 =head3 CAVEAT
2053
2054 Note that L</update> does not process/deflate any of the values passed in.
2055 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2056 ensure manually that any value passed to this method will stringify to
2057 something the RDBMS knows how to deal with. A notable example is the
2058 handling of L<DateTime> objects, for more info see:
2059 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2060
2061 =cut
2062
2063 sub update {
2064   my ($self, $values) = @_;
2065   $self->throw_exception('Values for update must be a hash')
2066     unless ref $values eq 'HASH';
2067
2068   return $self->_rs_update_delete ('update', $values);
2069 }
2070
2071 =head2 update_all
2072
2073 =over 4
2074
2075 =item Arguments: \%values
2076
2077 =item Return Value: 1
2078
2079 =back
2080
2081 Fetches all objects and updates them one at a time via
2082 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2083 triggers, while L</update> will not.
2084
2085 =cut
2086
2087 sub update_all {
2088   my ($self, $values) = @_;
2089   $self->throw_exception('Values for update_all must be a hash')
2090     unless ref $values eq 'HASH';
2091
2092   my $guard = $self->result_source->schema->txn_scope_guard;
2093   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2094   $guard->commit;
2095   return 1;
2096 }
2097
2098 =head2 delete
2099
2100 =over 4
2101
2102 =item Arguments: none
2103
2104 =item Return Value: $underlying_storage_rv
2105
2106 =back
2107
2108 Deletes the rows matching this resultset in a single query. Note that this
2109 will not run any delete triggers, nor will it alter the
2110 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2111 derived from this resultset (this includes the contents of the
2112 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2113 execute any on-delete triggers or cascades defined either by you or a
2114 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2115
2116 The return value is a pass through of what the underlying storage backend
2117 returned, and may vary. See L<DBI/execute> for the most common case.
2118
2119 =cut
2120
2121 sub delete {
2122   my $self = shift;
2123   $self->throw_exception('delete does not accept any arguments')
2124     if @_;
2125
2126   return $self->_rs_update_delete ('delete');
2127 }
2128
2129 =head2 delete_all
2130
2131 =over 4
2132
2133 =item Arguments: none
2134
2135 =item Return Value: 1
2136
2137 =back
2138
2139 Fetches all objects and deletes them one at a time via
2140 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2141 triggers, while L</delete> will not.
2142
2143 =cut
2144
2145 sub delete_all {
2146   my $self = shift;
2147   $self->throw_exception('delete_all does not accept any arguments')
2148     if @_;
2149
2150   my $guard = $self->result_source->schema->txn_scope_guard;
2151   $_->delete for $self->all;
2152   $guard->commit;
2153   return 1;
2154 }
2155
2156 =head2 populate
2157
2158 =over 4
2159
2160 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2161
2162 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2163
2164 =back
2165
2166 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2167 arrayrefs.
2168
2169 =over
2170
2171 =item NOTE
2172
2173 The context of this method call has an important effect on what is
2174 submitted to storage. In void context data is fed directly to fastpath
2175 insertion routines provided by the underlying storage (most often
2176 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2177 L<insert|DBIx::Class::Row/insert> calls on the
2178 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2179 augmentation of these methods provided by components. For example if you
2180 are using something like L<DBIx::Class::UUIDColumns> to create primary
2181 keys for you, you will find that your PKs are empty.  In this case you
2182 will have to explicitly force scalar or list context in order to create
2183 those values.
2184
2185 =back
2186
2187 In non-void (scalar or list) context, this method is simply a wrapper
2188 for L</create>. Depending on list or scalar context either a list of
2189 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2190 containing these objects is returned.
2191
2192 When supplying data in "arrayref of arrayrefs" invocation style, the
2193 first element should be a list of column names and each subsequent
2194 element should be a data value in the earlier specified column order.
2195 For example:
2196
2197   $schema->resultset("Artist")->populate([
2198     [ qw( artistid name ) ],
2199     [ 100, 'A Formally Unknown Singer' ],
2200     [ 101, 'A singer that jumped the shark two albums ago' ],
2201     [ 102, 'An actually cool singer' ],
2202   ]);
2203
2204 For the arrayref of hashrefs style each hashref should be a structure
2205 suitable for passing to L</create>. Multi-create is also permitted with
2206 this syntax.
2207
2208   $schema->resultset("Artist")->populate([
2209      { artistid => 4, name => 'Manufactured Crap', cds => [
2210         { title => 'My First CD', year => 2006 },
2211         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2212       ],
2213      },
2214      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2215         { title => 'My parents sold me to a record company', year => 2005 },
2216         { title => 'Why Am I So Ugly?', year => 2006 },
2217         { title => 'I Got Surgery and am now Popular', year => 2007 }
2218       ],
2219      },
2220   ]);
2221
2222 If you attempt a void-context multi-create as in the example above (each
2223 Artist also has the related list of CDs), and B<do not> supply the
2224 necessary autoinc foreign key information, this method will proxy to the
2225 less efficient L</create>, and then throw the Result objects away. In this
2226 case there are obviously no benefits to using this method over L</create>.
2227
2228 =cut
2229
2230 sub populate {
2231   my $self = shift;
2232
2233   # cruft placed in standalone method
2234   my $data = $self->_normalize_populate_args(@_);
2235
2236   return unless @$data;
2237
2238   if(defined wantarray) {
2239     my @created = map { $self->create($_) } @$data;
2240     return wantarray ? @created : \@created;
2241   }
2242   else {
2243     my $first = $data->[0];
2244
2245     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2246     # it relationship data
2247     my (@rels, @columns);
2248     my $rsrc = $self->result_source;
2249     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2250     for (keys %$first) {
2251       my $ref = ref $first->{$_};
2252       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2253         ? push @rels, $_
2254         : push @columns, $_
2255       ;
2256     }
2257
2258     my @pks = $rsrc->primary_columns;
2259
2260     ## do the belongs_to relationships
2261     foreach my $index (0..$#$data) {
2262
2263       # delegate to create() for any dataset without primary keys with specified relationships
2264       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2265         for my $r (@rels) {
2266           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2267             my @ret = $self->populate($data);
2268             return;
2269           }
2270         }
2271       }
2272
2273       foreach my $rel (@rels) {
2274         next unless ref $data->[$index]->{$rel} eq "HASH";
2275         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2276         my (undef, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2277         my $related = $result->result_source->_resolve_condition(
2278           $reverse_relinfo->{cond},
2279           $self,
2280           $result,
2281           $rel,
2282         );
2283
2284         delete $data->[$index]->{$rel};
2285         $data->[$index] = {%{$data->[$index]}, %$related};
2286
2287         push @columns, keys %$related if $index == 0;
2288       }
2289     }
2290
2291     ## inherit the data locked in the conditions of the resultset
2292     my ($rs_data) = $self->_merge_with_rscond({});
2293     delete @{$rs_data}{@columns};
2294
2295     ## do bulk insert on current row
2296     $rsrc->storage->insert_bulk(
2297       $rsrc,
2298       [@columns, keys %$rs_data],
2299       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2300     );
2301
2302     ## do the has_many relationships
2303     foreach my $item (@$data) {
2304
2305       my $main_row;
2306
2307       foreach my $rel (@rels) {
2308         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2309
2310         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2311
2312         my $child = $main_row->$rel;
2313
2314         my $related = $child->result_source->_resolve_condition(
2315           $rels->{$rel}{cond},
2316           $child,
2317           $main_row,
2318           $rel,
2319         );
2320
2321         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2322         my @populate = map { {%$_, %$related} } @rows_to_add;
2323
2324         $child->populate( \@populate );
2325       }
2326     }
2327   }
2328 }
2329
2330
2331 # populate() arguments went over several incarnations
2332 # What we ultimately support is AoH
2333 sub _normalize_populate_args {
2334   my ($self, $arg) = @_;
2335
2336   if (ref $arg eq 'ARRAY') {
2337     if (!@$arg) {
2338       return [];
2339     }
2340     elsif (ref $arg->[0] eq 'HASH') {
2341       return $arg;
2342     }
2343     elsif (ref $arg->[0] eq 'ARRAY') {
2344       my @ret;
2345       my @colnames = @{$arg->[0]};
2346       foreach my $values (@{$arg}[1 .. $#$arg]) {
2347         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2348       }
2349       return \@ret;
2350     }
2351   }
2352
2353   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2354 }
2355
2356 =head2 pager
2357
2358 =over 4
2359
2360 =item Arguments: none
2361
2362 =item Return Value: L<$pager|Data::Page>
2363
2364 =back
2365
2366 Returns a L<Data::Page> object for the current resultset. Only makes
2367 sense for queries with a C<page> attribute.
2368
2369 To get the full count of entries for a paged resultset, call
2370 C<total_entries> on the L<Data::Page> object.
2371
2372 =cut
2373
2374 sub pager {
2375   my ($self) = @_;
2376
2377   return $self->{pager} if $self->{pager};
2378
2379   my $attrs = $self->{attrs};
2380   if (!defined $attrs->{page}) {
2381     $self->throw_exception("Can't create pager for non-paged rs");
2382   }
2383   elsif ($attrs->{page} <= 0) {
2384     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2385   }
2386   $attrs->{rows} ||= 10;
2387
2388   # throw away the paging flags and re-run the count (possibly
2389   # with a subselect) to get the real total count
2390   my $count_attrs = { %$attrs };
2391   delete @{$count_attrs}{qw/rows offset page pager/};
2392
2393   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2394
2395   require DBIx::Class::ResultSet::Pager;
2396   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2397     sub { $total_rs->count },  #lazy-get the total
2398     $attrs->{rows},
2399     $self->{attrs}{page},
2400   );
2401 }
2402
2403 =head2 page
2404
2405 =over 4
2406
2407 =item Arguments: $page_number
2408
2409 =item Return Value: L<$resultset|/search>
2410
2411 =back
2412
2413 Returns a resultset for the $page_number page of the resultset on which page
2414 is called, where each page contains a number of rows equal to the 'rows'
2415 attribute set on the resultset (10 by default).
2416
2417 =cut
2418
2419 sub page {
2420   my ($self, $page) = @_;
2421   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2422 }
2423
2424 =head2 new_result
2425
2426 =over 4
2427
2428 =item Arguments: \%col_data
2429
2430 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2431
2432 =back
2433
2434 Creates a new result object in the resultset's result class and returns
2435 it. The row is not inserted into the database at this point, call
2436 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2437 will tell you whether the result object has been inserted or not.
2438
2439 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2440
2441 =cut
2442
2443 sub new_result {
2444   my ($self, $values) = @_;
2445
2446   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2447     if @_ > 2;
2448
2449   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2450     unless (ref $values eq 'HASH');
2451
2452   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2453
2454   my $new = $self->result_class->new({
2455     %$merged_cond,
2456     ( @$cols_from_relations
2457       ? (-cols_from_relations => $cols_from_relations)
2458       : ()
2459     ),
2460     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2461   });
2462
2463   if (
2464     reftype($new) eq 'HASH'
2465       and
2466     ! keys %$new
2467       and
2468     blessed($new)
2469   ) {
2470     carp_unique (sprintf (
2471       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2472       $self->result_class,
2473     ));
2474   }
2475
2476   $new;
2477 }
2478
2479 # _merge_with_rscond
2480 #
2481 # Takes a simple hash of K/V data and returns its copy merged with the
2482 # condition already present on the resultset. Additionally returns an
2483 # arrayref of value/condition names, which were inferred from related
2484 # objects (this is needed for in-memory related objects)
2485 sub _merge_with_rscond {
2486   my ($self, $data) = @_;
2487
2488   my ($implied_data, @cols_from_relations);
2489
2490   my $alias = $self->{attrs}{alias};
2491
2492   if (! defined $self->{cond}) {
2493     # just massage $data below
2494   }
2495   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2496     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2497     @cols_from_relations = keys %{ $implied_data || {} };
2498   }
2499   else {
2500     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2501     $implied_data = { map {
2502       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2503     } keys %$eqs };
2504   }
2505
2506   return (
2507     { map
2508       { %{ $self->_remove_alias($_, $alias) } }
2509       # precedence must be given to passed values over values inherited from
2510       # the cond, so the order here is important.
2511       ( $implied_data||(), $data)
2512     },
2513     \@cols_from_relations
2514   );
2515 }
2516
2517 # _has_resolved_attr
2518 #
2519 # determines if the resultset defines at least one
2520 # of the attributes supplied
2521 #
2522 # used to determine if a subquery is necessary
2523 #
2524 # supports some virtual attributes:
2525 #   -join
2526 #     This will scan for any joins being present on the resultset.
2527 #     It is not a mere key-search but a deep inspection of {from}
2528 #
2529
2530 sub _has_resolved_attr {
2531   my ($self, @attr_names) = @_;
2532
2533   my $attrs = $self->_resolved_attrs;
2534
2535   my %extra_checks;
2536
2537   for my $n (@attr_names) {
2538     if (grep { $n eq $_ } (qw/-join/) ) {
2539       $extra_checks{$n}++;
2540       next;
2541     }
2542
2543     my $attr =  $attrs->{$n};
2544
2545     next if not defined $attr;
2546
2547     if (ref $attr eq 'HASH') {
2548       return 1 if keys %$attr;
2549     }
2550     elsif (ref $attr eq 'ARRAY') {
2551       return 1 if @$attr;
2552     }
2553     else {
2554       return 1 if $attr;
2555     }
2556   }
2557
2558   # a resolved join is expressed as a multi-level from
2559   return 1 if (
2560     $extra_checks{-join}
2561       and
2562     ref $attrs->{from} eq 'ARRAY'
2563       and
2564     @{$attrs->{from}} > 1
2565   );
2566
2567   return 0;
2568 }
2569
2570 # _remove_alias
2571 #
2572 # Remove the specified alias from the specified query hash. A copy is made so
2573 # the original query is not modified.
2574
2575 sub _remove_alias {
2576   my ($self, $query, $alias) = @_;
2577
2578   my %orig = %{ $query || {} };
2579   my %unaliased;
2580
2581   foreach my $key (keys %orig) {
2582     if ($key !~ /\./) {
2583       $unaliased{$key} = $orig{$key};
2584       next;
2585     }
2586     $unaliased{$1} = $orig{$key}
2587       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2588   }
2589
2590   return \%unaliased;
2591 }
2592
2593 =head2 as_query
2594
2595 =over 4
2596
2597 =item Arguments: none
2598
2599 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2600
2601 =back
2602
2603 Returns the SQL query and bind vars associated with the invocant.
2604
2605 This is generally used as the RHS for a subquery.
2606
2607 =cut
2608
2609 sub as_query {
2610   my $self = shift;
2611
2612   my $attrs = { %{ $self->_resolved_attrs } };
2613
2614   my $aq = $self->result_source->storage->_select_args_to_query (
2615     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2616   );
2617
2618   $aq;
2619 }
2620
2621 =head2 find_or_new
2622
2623 =over 4
2624
2625 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2626
2627 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2628
2629 =back
2630
2631   my $artist = $schema->resultset('Artist')->find_or_new(
2632     { artist => 'fred' }, { key => 'artists' });
2633
2634   $cd->cd_to_producer->find_or_new({ producer => $producer },
2635                                    { key => 'primary' });
2636
2637 Find an existing record from this resultset using L</find>. if none exists,
2638 instantiate a new result object and return it. The object will not be saved
2639 into your storage until you call L<DBIx::Class::Row/insert> on it.
2640
2641 You most likely want this method when looking for existing rows using a unique
2642 constraint that is not the primary key, or looking for related rows.
2643
2644 If you want objects to be saved immediately, use L</find_or_create> instead.
2645
2646 B<Note>: Make sure to read the documentation of L</find> and understand the
2647 significance of the C<key> attribute, as its lack may skew your search, and
2648 subsequently result in spurious new objects.
2649
2650 B<Note>: Take care when using C<find_or_new> with a table having
2651 columns with default values that you intend to be automatically
2652 supplied by the database (e.g. an auto_increment primary key column).
2653 In normal usage, the value of such columns should NOT be included at
2654 all in the call to C<find_or_new>, even when set to C<undef>.
2655
2656 =cut
2657
2658 sub find_or_new {
2659   my $self     = shift;
2660   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2661   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2662   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2663     return $row;
2664   }
2665   return $self->new_result($hash);
2666 }
2667
2668 =head2 create
2669
2670 =over 4
2671
2672 =item Arguments: \%col_data
2673
2674 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2675
2676 =back
2677
2678 Attempt to create a single new row or a row with multiple related rows
2679 in the table represented by the resultset (and related tables). This
2680 will not check for duplicate rows before inserting, use
2681 L</find_or_create> to do that.
2682
2683 To create one row for this resultset, pass a hashref of key/value
2684 pairs representing the columns of the table and the values you wish to
2685 store. If the appropriate relationships are set up, foreign key fields
2686 can also be passed an object representing the foreign row, and the
2687 value will be set to its primary key.
2688
2689 To create related objects, pass a hashref of related-object column values
2690 B<keyed on the relationship name>. If the relationship is of type C<multi>
2691 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2692 The process will correctly identify columns holding foreign keys, and will
2693 transparently populate them from the keys of the corresponding relation.
2694 This can be applied recursively, and will work correctly for a structure
2695 with an arbitrary depth and width, as long as the relationships actually
2696 exists and the correct column data has been supplied.
2697
2698 Instead of hashrefs of plain related data (key/value pairs), you may
2699 also pass new or inserted objects. New objects (not inserted yet, see
2700 L</new_result>), will be inserted into their appropriate tables.
2701
2702 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2703
2704 Example of creating a new row.
2705
2706   $person_rs->create({
2707     name=>"Some Person",
2708     email=>"somebody@someplace.com"
2709   });
2710
2711 Example of creating a new row and also creating rows in a related C<has_many>
2712 or C<has_one> resultset.  Note Arrayref.
2713
2714   $artist_rs->create(
2715      { artistid => 4, name => 'Manufactured Crap', cds => [
2716         { title => 'My First CD', year => 2006 },
2717         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2718       ],
2719      },
2720   );
2721
2722 Example of creating a new row and also creating a row in a related
2723 C<belongs_to> resultset. Note Hashref.
2724
2725   $cd_rs->create({
2726     title=>"Music for Silly Walks",
2727     year=>2000,
2728     artist => {
2729       name=>"Silly Musician",
2730     }
2731   });
2732
2733 =over
2734
2735 =item WARNING
2736
2737 When subclassing ResultSet never attempt to override this method. Since
2738 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2739 lot of the internals simply never call it, so your override will be
2740 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2741 or L<DBIx::Class::Row/insert> depending on how early in the
2742 L</create> process you need to intervene. See also warning pertaining to
2743 L</new>.
2744
2745 =back
2746
2747 =cut
2748
2749 sub create {
2750   #my ($self, $col_data) = @_;
2751   return shift->new_result(shift)->insert;
2752 }
2753
2754 =head2 find_or_create
2755
2756 =over 4
2757
2758 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2759
2760 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2761
2762 =back
2763
2764   $cd->cd_to_producer->find_or_create({ producer => $producer },
2765                                       { key => 'primary' });
2766
2767 Tries to find a record based on its primary key or unique constraints; if none
2768 is found, creates one and returns that instead.
2769
2770   my $cd = $schema->resultset('CD')->find_or_create({
2771     cdid   => 5,
2772     artist => 'Massive Attack',
2773     title  => 'Mezzanine',
2774     year   => 2005,
2775   });
2776
2777 Also takes an optional C<key> attribute, to search by a specific key or unique
2778 constraint. For example:
2779
2780   my $cd = $schema->resultset('CD')->find_or_create(
2781     {
2782       artist => 'Massive Attack',
2783       title  => 'Mezzanine',
2784     },
2785     { key => 'cd_artist_title' }
2786   );
2787
2788 B<Note>: Make sure to read the documentation of L</find> and understand the
2789 significance of the C<key> attribute, as its lack may skew your search, and
2790 subsequently result in spurious row creation.
2791
2792 B<Note>: Because find_or_create() reads from the database and then
2793 possibly inserts based on the result, this method is subject to a race
2794 condition. Another process could create a record in the table after
2795 the find has completed and before the create has started. To avoid
2796 this problem, use find_or_create() inside a transaction.
2797
2798 B<Note>: Take care when using C<find_or_create> with a table having
2799 columns with default values that you intend to be automatically
2800 supplied by the database (e.g. an auto_increment primary key column).
2801 In normal usage, the value of such columns should NOT be included at
2802 all in the call to C<find_or_create>, even when set to C<undef>.
2803
2804 See also L</find> and L</update_or_create>. For information on how to declare
2805 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2806
2807 If you need to know if an existing row was found or a new one created use
2808 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2809 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2810 database!
2811
2812   my $cd = $schema->resultset('CD')->find_or_new({
2813     cdid   => 5,
2814     artist => 'Massive Attack',
2815     title  => 'Mezzanine',
2816     year   => 2005,
2817   });
2818
2819   if( !$cd->in_storage ) {
2820       # do some stuff
2821       $cd->insert;
2822   }
2823
2824 =cut
2825
2826 sub find_or_create {
2827   my $self     = shift;
2828   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2829   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2830   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2831     return $row;
2832   }
2833   return $self->create($hash);
2834 }
2835
2836 =head2 update_or_create
2837
2838 =over 4
2839
2840 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2841
2842 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2843
2844 =back
2845
2846   $resultset->update_or_create({ col => $val, ... });
2847
2848 Like L</find_or_create>, but if a row is found it is immediately updated via
2849 C<< $found_row->update (\%col_data) >>.
2850
2851
2852 Takes an optional C<key> attribute to search on a specific unique constraint.
2853 For example:
2854
2855   # In your application
2856   my $cd = $schema->resultset('CD')->update_or_create(
2857     {
2858       artist => 'Massive Attack',
2859       title  => 'Mezzanine',
2860       year   => 1998,
2861     },
2862     { key => 'cd_artist_title' }
2863   );
2864
2865   $cd->cd_to_producer->update_or_create({
2866     producer => $producer,
2867     name => 'harry',
2868   }, {
2869     key => 'primary',
2870   });
2871
2872 B<Note>: Make sure to read the documentation of L</find> and understand the
2873 significance of the C<key> attribute, as its lack may skew your search, and
2874 subsequently result in spurious row creation.
2875
2876 B<Note>: Take care when using C<update_or_create> with a table having
2877 columns with default values that you intend to be automatically
2878 supplied by the database (e.g. an auto_increment primary key column).
2879 In normal usage, the value of such columns should NOT be included at
2880 all in the call to C<update_or_create>, even when set to C<undef>.
2881
2882 See also L</find> and L</find_or_create>. For information on how to declare
2883 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2884
2885 If you need to know if an existing row was updated or a new one created use
2886 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2887 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2888 database!
2889
2890 =cut
2891
2892 sub update_or_create {
2893   my $self = shift;
2894   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2895   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2896
2897   my $row = $self->find($cond, $attrs);
2898   if (defined $row) {
2899     $row->update($cond);
2900     return $row;
2901   }
2902
2903   return $self->create($cond);
2904 }
2905
2906 =head2 update_or_new
2907
2908 =over 4
2909
2910 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2911
2912 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2913
2914 =back
2915
2916   $resultset->update_or_new({ col => $val, ... });
2917
2918 Like L</find_or_new> but if a row is found it is immediately updated via
2919 C<< $found_row->update (\%col_data) >>.
2920
2921 For example:
2922
2923   # In your application
2924   my $cd = $schema->resultset('CD')->update_or_new(
2925     {
2926       artist => 'Massive Attack',
2927       title  => 'Mezzanine',
2928       year   => 1998,
2929     },
2930     { key => 'cd_artist_title' }
2931   );
2932
2933   if ($cd->in_storage) {
2934       # the cd was updated
2935   }
2936   else {
2937       # the cd is not yet in the database, let's insert it
2938       $cd->insert;
2939   }
2940
2941 B<Note>: Make sure to read the documentation of L</find> and understand the
2942 significance of the C<key> attribute, as its lack may skew your search, and
2943 subsequently result in spurious new objects.
2944
2945 B<Note>: Take care when using C<update_or_new> with a table having
2946 columns with default values that you intend to be automatically
2947 supplied by the database (e.g. an auto_increment primary key column).
2948 In normal usage, the value of such columns should NOT be included at
2949 all in the call to C<update_or_new>, even when set to C<undef>.
2950
2951 See also L</find>, L</find_or_create> and L</find_or_new>.
2952
2953 =cut
2954
2955 sub update_or_new {
2956     my $self  = shift;
2957     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2958     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2959
2960     my $row = $self->find( $cond, $attrs );
2961     if ( defined $row ) {
2962         $row->update($cond);
2963         return $row;
2964     }
2965
2966     return $self->new_result($cond);
2967 }
2968
2969 =head2 get_cache
2970
2971 =over 4
2972
2973 =item Arguments: none
2974
2975 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2976
2977 =back
2978
2979 Gets the contents of the cache for the resultset, if the cache is set.
2980
2981 The cache is populated either by using the L</prefetch> attribute to
2982 L</search> or by calling L</set_cache>.
2983
2984 =cut
2985
2986 sub get_cache {
2987   shift->{all_cache};
2988 }
2989
2990 =head2 set_cache
2991
2992 =over 4
2993
2994 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2995
2996 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2997
2998 =back
2999
3000 Sets the contents of the cache for the resultset. Expects an arrayref
3001 of objects of the same class as those produced by the resultset. Note that
3002 if the cache is set, the resultset will return the cached objects rather
3003 than re-querying the database even if the cache attr is not set.
3004
3005 The contents of the cache can also be populated by using the
3006 L</prefetch> attribute to L</search>.
3007
3008 =cut
3009
3010 sub set_cache {
3011   my ( $self, $data ) = @_;
3012   $self->throw_exception("set_cache requires an arrayref")
3013       if defined($data) && (ref $data ne 'ARRAY');
3014   $self->{all_cache} = $data;
3015 }
3016
3017 =head2 clear_cache
3018
3019 =over 4
3020
3021 =item Arguments: none
3022
3023 =item Return Value: undef
3024
3025 =back
3026
3027 Clears the cache for the resultset.
3028
3029 =cut
3030
3031 sub clear_cache {
3032   shift->set_cache(undef);
3033 }
3034
3035 =head2 is_paged
3036
3037 =over 4
3038
3039 =item Arguments: none
3040
3041 =item Return Value: true, if the resultset has been paginated
3042
3043 =back
3044
3045 =cut
3046
3047 sub is_paged {
3048   my ($self) = @_;
3049   return !!$self->{attrs}{page};
3050 }
3051
3052 =head2 is_ordered
3053
3054 =over 4
3055
3056 =item Arguments: none
3057
3058 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3059
3060 =back
3061
3062 =cut
3063
3064 sub is_ordered {
3065   my ($self) = @_;
3066   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3067 }
3068
3069 =head2 related_resultset
3070
3071 =over 4
3072
3073 =item Arguments: $rel_name
3074
3075 =item Return Value: L<$resultset|/search>
3076
3077 =back
3078
3079 Returns a related resultset for the supplied relationship name.
3080
3081   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3082
3083 =cut
3084
3085 sub related_resultset {
3086   my ($self, $rel) = @_;
3087
3088   return $self->{related_resultsets}{$rel}
3089     if defined $self->{related_resultsets}{$rel};
3090
3091   return $self->{related_resultsets}{$rel} = do {
3092     my $rsrc = $self->result_source;
3093     my $rel_info = $rsrc->relationship_info($rel);
3094
3095     $self->throw_exception(
3096       "search_related: result source '" . $rsrc->source_name .
3097         "' has no such relationship $rel")
3098       unless $rel_info;
3099
3100     my $attrs = $self->_chain_relationship($rel);
3101
3102     my $join_count = $attrs->{seen_join}{$rel};
3103
3104     my $alias = $self->result_source->storage
3105         ->relname_to_table_alias($rel, $join_count);
3106
3107     # since this is search_related, and we already slid the select window inwards
3108     # (the select/as attrs were deleted in the beginning), we need to flip all
3109     # left joins to inner, so we get the expected results
3110     # read the comment on top of the actual function to see what this does
3111     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3112
3113
3114     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3115     delete @{$attrs}{qw(result_class alias)};
3116
3117     my $rel_source = $rsrc->related_source($rel);
3118
3119     my $new = do {
3120
3121       # The reason we do this now instead of passing the alias to the
3122       # search_rs below is that if you wrap/overload resultset on the
3123       # source you need to know what alias it's -going- to have for things
3124       # to work sanely (e.g. RestrictWithObject wants to be able to add
3125       # extra query restrictions, and these may need to be $alias.)
3126
3127       my $rel_attrs = $rel_source->resultset_attributes;
3128       local $rel_attrs->{alias} = $alias;
3129
3130       $rel_source->resultset
3131                  ->search_rs(
3132                      undef, {
3133                        %$attrs,
3134                        where => $attrs->{where},
3135                    });
3136     };
3137
3138     if (my $cache = $self->get_cache) {
3139       my @related_cache = map
3140         { $_->related_resultset($rel)->get_cache || () }
3141         @$cache
3142       ;
3143
3144       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3145     }
3146
3147     $new;
3148   };
3149 }
3150
3151 =head2 current_source_alias
3152
3153 =over 4
3154
3155 =item Arguments: none
3156
3157 =item Return Value: $source_alias
3158
3159 =back
3160
3161 Returns the current table alias for the result source this resultset is built
3162 on, that will be used in the SQL query. Usually it is C<me>.
3163
3164 Currently the source alias that refers to the result set returned by a
3165 L</search>/L</find> family method depends on how you got to the resultset: it's
3166 C<me> by default, but eg. L</search_related> aliases it to the related result
3167 source name (and keeps C<me> referring to the original result set). The long
3168 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3169 (and make this method unnecessary).
3170
3171 Thus it's currently necessary to use this method in predefined queries (see
3172 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3173 source alias of the current result set:
3174
3175   # in a result set class
3176   sub modified_by {
3177     my ($self, $user) = @_;
3178
3179     my $me = $self->current_source_alias;
3180
3181     return $self->search({
3182       "$me.modified" => $user->id,
3183     });
3184   }
3185
3186 =cut
3187
3188 sub current_source_alias {
3189   return (shift->{attrs} || {})->{alias} || 'me';
3190 }
3191
3192 =head2 as_subselect_rs
3193
3194 =over 4
3195
3196 =item Arguments: none
3197
3198 =item Return Value: L<$resultset|/search>
3199
3200 =back
3201
3202 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3203 "virtual view" by including it as a subquery within the from clause.  From this
3204 point on, any joined tables are inaccessible to ->search on the resultset (as if
3205 it were simply where-filtered without joins).  For example:
3206
3207  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3208
3209  # 'x' now pollutes the query namespace
3210
3211  # So the following works as expected
3212  my $ok_rs = $rs->search({'x.other' => 1});
3213
3214  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3215  # def) we look for one row with contradictory terms and join in another table
3216  # (aliased 'x_2') which we never use
3217  my $broken_rs = $rs->search({'x.name' => 'def'});
3218
3219  my $rs2 = $rs->as_subselect_rs;
3220
3221  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3222  my $not_joined_rs = $rs2->search({'x.other' => 1});
3223
3224  # works as expected: finds a 'table' row related to two x rows (abc and def)
3225  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3226
3227 Another example of when one might use this would be to select a subset of
3228 columns in a group by clause:
3229
3230  my $rs = $schema->resultset('Bar')->search(undef, {
3231    group_by => [qw{ id foo_id baz_id }],
3232  })->as_subselect_rs->search(undef, {
3233    columns => [qw{ id foo_id }]
3234  });
3235
3236 In the above example normally columns would have to be equal to the group by,
3237 but because we isolated the group by into a subselect the above works.
3238
3239 =cut
3240
3241 sub as_subselect_rs {
3242   my $self = shift;
3243
3244   my $attrs = $self->_resolved_attrs;
3245
3246   my $fresh_rs = (ref $self)->new (
3247     $self->result_source
3248   );
3249
3250   # these pieces will be locked in the subquery
3251   delete $fresh_rs->{cond};
3252   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3253
3254   return $fresh_rs->search( {}, {
3255     from => [{
3256       $attrs->{alias} => $self->as_query,
3257       -alias  => $attrs->{alias},
3258       -rsrc   => $self->result_source,
3259     }],
3260     alias => $attrs->{alias},
3261   });
3262 }
3263
3264 # This code is called by search_related, and makes sure there
3265 # is clear separation between the joins before, during, and
3266 # after the relationship. This information is needed later
3267 # in order to properly resolve prefetch aliases (any alias
3268 # with a relation_chain_depth less than the depth of the
3269 # current prefetch is not considered)
3270 #
3271 # The increments happen twice per join. An even number means a
3272 # relationship specified via a search_related, whereas an odd
3273 # number indicates a join/prefetch added via attributes
3274 #
3275 # Also this code will wrap the current resultset (the one we
3276 # chain to) in a subselect IFF it contains limiting attributes
3277 sub _chain_relationship {
3278   my ($self, $rel) = @_;
3279   my $source = $self->result_source;
3280   my $attrs = { %{$self->{attrs}||{}} };
3281
3282   # we need to take the prefetch the attrs into account before we
3283   # ->_resolve_join as otherwise they get lost - captainL
3284   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3285
3286   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3287
3288   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3289
3290   my $from;
3291   my @force_subq_attrs = qw/offset rows group_by having/;
3292
3293   if (
3294     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3295       ||
3296     $self->_has_resolved_attr (@force_subq_attrs)
3297   ) {
3298     # Nuke the prefetch (if any) before the new $rs attrs
3299     # are resolved (prefetch is useless - we are wrapping
3300     # a subquery anyway).
3301     my $rs_copy = $self->search;
3302     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3303       $rs_copy->{attrs}{join},
3304       delete $rs_copy->{attrs}{prefetch},
3305     );
3306
3307     $from = [{
3308       -rsrc   => $source,
3309       -alias  => $attrs->{alias},
3310       $attrs->{alias} => $rs_copy->as_query,
3311     }];
3312     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3313     $seen->{-relation_chain_depth} = 0;
3314   }
3315   elsif ($attrs->{from}) {  #shallow copy suffices
3316     $from = [ @{$attrs->{from}} ];
3317   }
3318   else {
3319     $from = [{
3320       -rsrc  => $source,
3321       -alias => $attrs->{alias},
3322       $attrs->{alias} => $source->from,
3323     }];
3324   }
3325
3326   my $jpath = ($seen->{-relation_chain_depth})
3327     ? $from->[-1][0]{-join_path}
3328     : [];
3329
3330   my @requested_joins = $source->_resolve_join(
3331     $join,
3332     $attrs->{alias},
3333     $seen,
3334     $jpath,
3335   );
3336
3337   push @$from, @requested_joins;
3338
3339   $seen->{-relation_chain_depth}++;
3340
3341   # if $self already had a join/prefetch specified on it, the requested
3342   # $rel might very well be already included. What we do in this case
3343   # is effectively a no-op (except that we bump up the chain_depth on
3344   # the join in question so we could tell it *is* the search_related)
3345   my $already_joined;
3346
3347   # we consider the last one thus reverse
3348   for my $j (reverse @requested_joins) {
3349     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3350     if ($rel eq $last_j) {
3351       $j->[0]{-relation_chain_depth}++;
3352       $already_joined++;
3353       last;
3354     }
3355   }
3356
3357   unless ($already_joined) {
3358     push @$from, $source->_resolve_join(
3359       $rel,
3360       $attrs->{alias},
3361       $seen,
3362       $jpath,
3363     );
3364   }
3365
3366   $seen->{-relation_chain_depth}++;
3367
3368   return {%$attrs, from => $from, seen_join => $seen};
3369 }
3370
3371 sub _resolved_attrs {
3372   my $self = shift;
3373   return $self->{_attrs} if $self->{_attrs};
3374
3375   my $attrs  = { %{ $self->{attrs} || {} } };
3376   my $source = $attrs->{result_source} = $self->result_source;
3377   my $alias  = $attrs->{alias};
3378
3379   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3380     if $attrs->{collapse} and $attrs->{distinct};
3381
3382   # default selection list
3383   $attrs->{columns} = [ $source->columns ]
3384     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3385
3386   # merge selectors together
3387   for (qw/columns select as/) {
3388     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3389       if $attrs->{$_} or $attrs->{"+$_"};
3390   }
3391
3392   # disassemble columns
3393   my (@sel, @as);
3394   if (my $cols = delete $attrs->{columns}) {
3395     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3396       if (ref $c eq 'HASH') {
3397         for my $as (sort keys %$c) {
3398           push @sel, $c->{$as};
3399           push @as, $as;
3400         }
3401       }
3402       else {
3403         push @sel, $c;
3404         push @as, $c;
3405       }
3406     }
3407   }
3408
3409   # when trying to weed off duplicates later do not go past this point -
3410   # everything added from here on is unbalanced "anyone's guess" stuff
3411   my $dedup_stop_idx = $#as;
3412
3413   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3414     if $attrs->{as};
3415   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3416     if $attrs->{select};
3417
3418   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3419   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3420
3421   # disqualify all $alias.col as-bits (inflate-map mandated)
3422   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3423
3424   # de-duplicate the result (remove *identical* select/as pairs)
3425   # and also die on duplicate {as} pointing to different {select}s
3426   # not using a c-style for as the condition is prone to shrinkage
3427   my $seen;
3428   my $i = 0;
3429   while ($i <= $dedup_stop_idx) {
3430     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3431       splice @sel, $i, 1;
3432       splice @as, $i, 1;
3433       $dedup_stop_idx--;
3434     }
3435     elsif ($seen->{$as[$i]}++) {
3436       $self->throw_exception(
3437         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3438       );
3439     }
3440     else {
3441       $i++;
3442     }
3443   }
3444
3445   $attrs->{select} = \@sel;
3446   $attrs->{as} = \@as;
3447
3448   $attrs->{from} ||= [{
3449     -rsrc   => $source,
3450     -alias  => $self->{attrs}{alias},
3451     $self->{attrs}{alias} => $source->from,
3452   }];
3453
3454   if ( $attrs->{join} || $attrs->{prefetch} ) {
3455
3456     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3457       if ref $attrs->{from} ne 'ARRAY';
3458
3459     my $join = (delete $attrs->{join}) || {};
3460
3461     if ( defined $attrs->{prefetch} ) {
3462       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3463     }
3464
3465     $attrs->{from} =    # have to copy here to avoid corrupting the original
3466       [
3467         @{ $attrs->{from} },
3468         $source->_resolve_join(
3469           $join,
3470           $alias,
3471           { %{ $attrs->{seen_join} || {} } },
3472           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3473             ? $attrs->{from}[-1][0]{-join_path}
3474             : []
3475           ,
3476         )
3477       ];
3478   }
3479
3480   if ( defined $attrs->{order_by} ) {
3481     $attrs->{order_by} = (
3482       ref( $attrs->{order_by} ) eq 'ARRAY'
3483       ? [ @{ $attrs->{order_by} } ]
3484       : [ $attrs->{order_by} || () ]
3485     );
3486   }
3487
3488   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3489     $attrs->{group_by} = [ $attrs->{group_by} ];
3490   }
3491
3492
3493   # generate selections based on the prefetch helper
3494   my ($prefetch, @prefetch_select, @prefetch_as);
3495   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3496     if defined $attrs->{prefetch};
3497
3498   if ($prefetch) {
3499
3500     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3501       if $attrs->{_dark_selector};
3502
3503     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3504       if defined $attrs->{collapse} and ! $attrs->{collapse};
3505
3506     $attrs->{collapse} = 1;
3507
3508     # this is a separate structure (we don't look in {from} directly)
3509     # as the resolver needs to shift things off the lists to work
3510     # properly (identical-prefetches on different branches)
3511     my $join_map = {};
3512     if (ref $attrs->{from} eq 'ARRAY') {
3513
3514       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3515
3516       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3517         next unless $j->[0]{-alias};
3518         next unless $j->[0]{-join_path};
3519         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3520
3521         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3522
3523         my $p = $join_map;
3524         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3525         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3526       }
3527     }
3528
3529     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3530
3531     # save these for after distinct resolution
3532     @prefetch_select = map { $_->[0] } @prefetch;
3533     @prefetch_as = map { $_->[1] } @prefetch;
3534   }
3535
3536   # run through the resulting joinstructure (starting from our current slot)
3537   # and unset collapse if proven unnecessary
3538   #
3539   # also while we are at it find out if the current root source has
3540   # been premultiplied by previous related_source chaining
3541   #
3542   # this allows to predict whether a root object with all other relation
3543   # data set to NULL is in fact unique
3544   if ($attrs->{collapse}) {
3545
3546     if (ref $attrs->{from} eq 'ARRAY') {
3547
3548       if (@{$attrs->{from}} == 1) {
3549         # no joins - no collapse
3550         $attrs->{collapse} = 0;
3551       }
3552       else {
3553         # find where our table-spec starts
3554         my @fromlist = @{$attrs->{from}};
3555         while (@fromlist) {
3556           my $t = shift @fromlist;
3557
3558           my $is_multi;
3559           # me vs join from-spec distinction - a ref means non-root
3560           if (ref $t eq 'ARRAY') {
3561             $t = $t->[0];
3562             $is_multi ||= ! $t->{-is_single};
3563           }
3564           last if ($t->{-alias} && $t->{-alias} eq $alias);
3565           $attrs->{_main_source_premultiplied} ||= $is_multi;
3566         }
3567
3568         # no non-singles remaining, nor any premultiplication - nothing to collapse
3569         if (
3570           ! $attrs->{_main_source_premultiplied}
3571             and
3572           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3573         ) {
3574           $attrs->{collapse} = 0;
3575         }
3576       }
3577     }
3578
3579     else {
3580       # if we can not analyze the from - err on the side of safety
3581       $attrs->{_main_source_premultiplied} = 1;
3582     }
3583   }
3584
3585   # generate the distinct induced group_by before injecting the prefetched select/as parts
3586   if (delete $attrs->{distinct}) {
3587     if ($attrs->{group_by}) {
3588       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3589     }
3590     else {
3591       $attrs->{_grouped_by_distinct} = 1;
3592       # distinct affects only the main selection part, not what prefetch may add below
3593       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3594
3595       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3596       # The thinking is: if we are collapsing the subquerying prefetch engine will
3597       # rip stuff apart for us anyway, and we do not want to have a potentially
3598       # function-converted external order_by
3599       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3600       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3601     }
3602   }
3603
3604   # inject prefetch-bound selection (if any)
3605   push @{$attrs->{select}}, @prefetch_select;
3606   push @{$attrs->{as}}, @prefetch_as;
3607
3608   # whether we can get away with the dumbest (possibly DBI-internal) collapser
3609   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3610     $attrs->{_related_results_construction} = 1;
3611   }
3612
3613   # if both page and offset are specified, produce a combined offset
3614   # even though it doesn't make much sense, this is what pre 081xx has
3615   # been doing
3616   if (my $page = delete $attrs->{page}) {
3617     $attrs->{offset} =
3618       ($attrs->{rows} * ($page - 1))
3619             +
3620       ($attrs->{offset} || 0)
3621     ;
3622   }
3623
3624   return $self->{_attrs} = $attrs;
3625 }
3626
3627 sub _rollout_attr {
3628   my ($self, $attr) = @_;
3629
3630   if (ref $attr eq 'HASH') {
3631     return $self->_rollout_hash($attr);
3632   } elsif (ref $attr eq 'ARRAY') {
3633     return $self->_rollout_array($attr);
3634   } else {
3635     return [$attr];
3636   }
3637 }
3638
3639 sub _rollout_array {
3640   my ($self, $attr) = @_;
3641
3642   my @rolled_array;
3643   foreach my $element (@{$attr}) {
3644     if (ref $element eq 'HASH') {
3645       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3646     } elsif (ref $element eq 'ARRAY') {
3647       #  XXX - should probably recurse here
3648       push( @rolled_array, @{$self->_rollout_array($element)} );
3649     } else {
3650       push( @rolled_array, $element );
3651     }
3652   }
3653   return \@rolled_array;
3654 }
3655
3656 sub _rollout_hash {
3657   my ($self, $attr) = @_;
3658
3659   my @rolled_array;
3660   foreach my $key (keys %{$attr}) {
3661     push( @rolled_array, { $key => $attr->{$key} } );
3662   }
3663   return \@rolled_array;
3664 }
3665
3666 sub _calculate_score {
3667   my ($self, $a, $b) = @_;
3668
3669   if (defined $a xor defined $b) {
3670     return 0;
3671   }
3672   elsif (not defined $a) {
3673     return 1;
3674   }
3675
3676   if (ref $b eq 'HASH') {
3677     my ($b_key) = keys %{$b};
3678     if (ref $a eq 'HASH') {
3679       my ($a_key) = keys %{$a};
3680       if ($a_key eq $b_key) {
3681         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3682       } else {
3683         return 0;
3684       }
3685     } else {
3686       return ($a eq $b_key) ? 1 : 0;
3687     }
3688   } else {
3689     if (ref $a eq 'HASH') {
3690       my ($a_key) = keys %{$a};
3691       return ($b eq $a_key) ? 1 : 0;
3692     } else {
3693       return ($b eq $a) ? 1 : 0;
3694     }
3695   }
3696 }
3697
3698 sub _merge_joinpref_attr {
3699   my ($self, $orig, $import) = @_;
3700
3701   return $import unless defined($orig);
3702   return $orig unless defined($import);
3703
3704   $orig = $self->_rollout_attr($orig);
3705   $import = $self->_rollout_attr($import);
3706
3707   my $seen_keys;
3708   foreach my $import_element ( @{$import} ) {
3709     # find best candidate from $orig to merge $b_element into
3710     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3711     foreach my $orig_element ( @{$orig} ) {
3712       my $score = $self->_calculate_score( $orig_element, $import_element );
3713       if ($score > $best_candidate->{score}) {
3714         $best_candidate->{position} = $position;
3715         $best_candidate->{score} = $score;
3716       }
3717       $position++;
3718     }
3719     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3720     $import_key = '' if not defined $import_key;
3721
3722     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3723       push( @{$orig}, $import_element );
3724     } else {
3725       my $orig_best = $orig->[$best_candidate->{position}];
3726       # merge orig_best and b_element together and replace original with merged
3727       if (ref $orig_best ne 'HASH') {
3728         $orig->[$best_candidate->{position}] = $import_element;
3729       } elsif (ref $import_element eq 'HASH') {
3730         my ($key) = keys %{$orig_best};
3731         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3732       }
3733     }
3734     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3735   }
3736
3737   return @$orig ? $orig : ();
3738 }
3739
3740 {
3741   my $hm;
3742
3743   sub _merge_attr {
3744     $hm ||= do {
3745       require Hash::Merge;
3746       my $hm = Hash::Merge->new;
3747
3748       $hm->specify_behavior({
3749         SCALAR => {
3750           SCALAR => sub {
3751             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3752
3753             if ($defl xor $defr) {
3754               return [ $defl ? $_[0] : $_[1] ];
3755             }
3756             elsif (! $defl) {
3757               return [];
3758             }
3759             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3760               return [ $_[0] ];
3761             }
3762             else {
3763               return [$_[0], $_[1]];
3764             }
3765           },
3766           ARRAY => sub {
3767             return $_[1] if !defined $_[0];
3768             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3769             return [$_[0], @{$_[1]}]
3770           },
3771           HASH  => sub {
3772             return [] if !defined $_[0] and !keys %{$_[1]};
3773             return [ $_[1] ] if !defined $_[0];
3774             return [ $_[0] ] if !keys %{$_[1]};
3775             return [$_[0], $_[1]]
3776           },
3777         },
3778         ARRAY => {
3779           SCALAR => sub {
3780             return $_[0] if !defined $_[1];
3781             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3782             return [@{$_[0]}, $_[1]]
3783           },
3784           ARRAY => sub {
3785             my @ret = @{$_[0]} or return $_[1];
3786             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3787             my %idx = map { $_ => 1 } @ret;
3788             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3789             \@ret;
3790           },
3791           HASH => sub {
3792             return [ $_[1] ] if ! @{$_[0]};
3793             return $_[0] if !keys %{$_[1]};
3794             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3795             return [ @{$_[0]}, $_[1] ];
3796           },
3797         },
3798         HASH => {
3799           SCALAR => sub {
3800             return [] if !keys %{$_[0]} and !defined $_[1];
3801             return [ $_[0] ] if !defined $_[1];
3802             return [ $_[1] ] if !keys %{$_[0]};
3803             return [$_[0], $_[1]]
3804           },
3805           ARRAY => sub {
3806             return [] if !keys %{$_[0]} and !@{$_[1]};
3807             return [ $_[0] ] if !@{$_[1]};
3808             return $_[1] if !keys %{$_[0]};
3809             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3810             return [ $_[0], @{$_[1]} ];
3811           },
3812           HASH => sub {
3813             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3814             return [ $_[0] ] if !keys %{$_[1]};
3815             return [ $_[1] ] if !keys %{$_[0]};
3816             return [ $_[0] ] if $_[0] eq $_[1];
3817             return [ $_[0], $_[1] ];
3818           },
3819         }
3820       } => 'DBIC_RS_ATTR_MERGER');
3821       $hm;
3822     };
3823
3824     return $hm->merge ($_[1], $_[2]);
3825   }
3826 }
3827
3828 sub STORABLE_freeze {
3829   my ($self, $cloning) = @_;
3830   my $to_serialize = { %$self };
3831
3832   # A cursor in progress can't be serialized (and would make little sense anyway)
3833   # the parser can be regenerated (and can't be serialized)
3834   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3835
3836   # nor is it sensical to store a not-yet-fired-count pager
3837   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3838     delete $to_serialize->{pager};
3839   }
3840
3841   Storable::nfreeze($to_serialize);
3842 }
3843
3844 # need this hook for symmetry
3845 sub STORABLE_thaw {
3846   my ($self, $cloning, $serialized) = @_;
3847
3848   %$self = %{ Storable::thaw($serialized) };
3849
3850   $self;
3851 }
3852
3853
3854 =head2 throw_exception
3855
3856 See L<DBIx::Class::Schema/throw_exception> for details.
3857
3858 =cut
3859
3860 sub throw_exception {
3861   my $self=shift;
3862
3863   if (ref $self and my $rsrc = $self->result_source) {
3864     $rsrc->throw_exception(@_)
3865   }
3866   else {
3867     DBIx::Class::Exception->throw(@_);
3868   }
3869 }
3870
3871 1;
3872
3873 __END__
3874
3875 # XXX: FIXME: Attributes docs need clearing up
3876
3877 =head1 ATTRIBUTES
3878
3879 Attributes are used to refine a ResultSet in various ways when
3880 searching for data. They can be passed to any method which takes an
3881 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3882 L</count>.
3883
3884 Default attributes can be set on the result class using
3885 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3886 the CAVEATS on that feature before using it!)
3887
3888 These are in no particular order:
3889
3890 =head2 order_by
3891
3892 =over 4
3893
3894 =item Value: ( $order_by | \@order_by | \%order_by )
3895
3896 =back
3897
3898 Which column(s) to order the results by.
3899
3900 [The full list of suitable values is documented in
3901 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3902 common options.]
3903
3904 If a single column name, or an arrayref of names is supplied, the
3905 argument is passed through directly to SQL. The hashref syntax allows
3906 for connection-agnostic specification of ordering direction:
3907
3908  For descending order:
3909
3910   order_by => { -desc => [qw/col1 col2 col3/] }
3911
3912  For explicit ascending order:
3913
3914   order_by => { -asc => 'col' }
3915
3916 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3917 supported, although you are strongly encouraged to use the hashref
3918 syntax as outlined above.
3919
3920 =head2 columns
3921
3922 =over 4
3923
3924 =item Value: \@columns | \%columns | $column
3925
3926 =back
3927
3928 Shortcut to request a particular set of columns to be retrieved. Each
3929 column spec may be a string (a table column name), or a hash (in which
3930 case the key is the C<as> value, and the value is used as the C<select>
3931 expression). Adds C<me.> onto the start of any column without a C<.> in
3932 it and sets C<select> from that, then auto-populates C<as> from
3933 C<select> as normal. (You may also use the C<cols> attribute, as in
3934 earlier versions of DBIC, but this is deprecated)
3935
3936 Essentially C<columns> does the same as L</select> and L</as>.
3937
3938     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
3939
3940 is the same as
3941
3942     select => [qw(some_column another_column)],
3943     as     => [qw(some_column dbic_slot)]
3944
3945 If you want to individually retrieve related columns (in essence perform
3946 manual prefetch) you have to make sure to specify the correct inflation slot
3947 chain such that it matches existing relationships:
3948
3949     my $rs = $schema->resultset('Artist')->search({}, {
3950         # required to tell DBIC to collapse has_many relationships
3951         collapse => 1,
3952         join     => { cds => 'tracks'},
3953         '+columns'  => {
3954           'cds.cdid'         => 'cds.cdid',
3955           'cds.tracks.title' => 'tracks.title',
3956         },
3957     });
3958
3959 =head2 +columns
3960
3961 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
3962 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
3963 with a unary plus operator before it, which is the same as simply C<columns>.
3964
3965 =over 4
3966
3967 =item Value: \@extra_columns
3968
3969 =back
3970
3971 Indicates additional columns to be selected from storage. Works the same as
3972 L</columns> but adds columns to the current selection. (You may also use the
3973 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3974 deprecated)
3975
3976   $schema->resultset('CD')->search(undef, {
3977     '+columns' => ['artist.name'],
3978     join => ['artist']
3979   });
3980
3981 would return all CDs and include a 'name' column to the information
3982 passed to object inflation. Note that the 'artist' is the name of the
3983 column (or relationship) accessor, and 'name' is the name of the column
3984 accessor in the related table.
3985
3986 =head2 select
3987
3988 =over 4
3989
3990 =item Value: \@select_columns
3991
3992 =back
3993
3994 Indicates which columns should be selected from the storage. You can use
3995 column names, or in the case of RDBMS back ends, function or stored procedure
3996 names:
3997
3998   $rs = $schema->resultset('Employee')->search(undef, {
3999     select => [
4000       'name',
4001       { count => 'employeeid' },
4002       { max => { length => 'name' }, -as => 'longest_name' }
4003     ]
4004   });
4005
4006   # Equivalent SQL
4007   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4008
4009 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4010 use L</select>, to instruct DBIx::Class how to store the result of the column.
4011 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4012 identifier aliasing. You can however alias a function, so you can use it in
4013 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4014 attribute> supplied as shown in the example above.
4015
4016 =head2 +select
4017
4018 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4019 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4020 with a unary plus operator before it, which is the same as simply C<select>.
4021
4022 =over 4
4023
4024 =item Value: \@extra_select_columns
4025
4026 =back
4027
4028 Indicates additional columns to be selected from storage.  Works the same as
4029 L</select> but adds columns to the current selection, instead of specifying
4030 a new explicit list.
4031
4032 =head2 as
4033
4034 =over 4
4035
4036 =item Value: \@inflation_names
4037
4038 =back
4039
4040 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4041 slot name in which the column value will be stored within the
4042 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4043 identifier by the C<get_column> method (or via the object accessor B<if one
4044 with the same name already exists>) as shown below. The L</as> attribute has
4045 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4046
4047   $rs = $schema->resultset('Employee')->search(undef, {
4048     select => [
4049       'name',
4050       { count => 'employeeid' },
4051       { max => { length => 'name' }, -as => 'longest_name' }
4052     ],
4053     as => [qw/
4054       name
4055       employee_count
4056       max_name_length
4057     /],
4058   });
4059
4060 If the object against which the search is performed already has an accessor
4061 matching a column name specified in C<as>, the value can be retrieved using
4062 the accessor as normal:
4063
4064   my $name = $employee->name();
4065
4066 If on the other hand an accessor does not exist in the object, you need to
4067 use C<get_column> instead:
4068
4069   my $employee_count = $employee->get_column('employee_count');
4070
4071 You can create your own accessors if required - see
4072 L<DBIx::Class::Manual::Cookbook> for details.
4073
4074 =head2 +as
4075
4076 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4077 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4078 with a unary plus operator before it, which is the same as simply C<as>.
4079
4080 =over 4
4081
4082 =item Value: \@extra_inflation_names
4083
4084 =back
4085
4086 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4087
4088 =head2 join
4089
4090 =over 4
4091
4092 =item Value: ($rel_name | \@rel_names | \%rel_names)
4093
4094 =back
4095
4096 Contains a list of relationships that should be joined for this query.  For
4097 example:
4098
4099   # Get CDs by Nine Inch Nails
4100   my $rs = $schema->resultset('CD')->search(
4101     { 'artist.name' => 'Nine Inch Nails' },
4102     { join => 'artist' }
4103   );
4104
4105 Can also contain a hash reference to refer to the other relation's relations.
4106 For example:
4107
4108   package MyApp::Schema::Track;
4109   use base qw/DBIx::Class/;
4110   __PACKAGE__->table('track');
4111   __PACKAGE__->add_columns(qw/trackid cd position title/);
4112   __PACKAGE__->set_primary_key('trackid');
4113   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4114   1;
4115
4116   # In your application
4117   my $rs = $schema->resultset('Artist')->search(
4118     { 'track.title' => 'Teardrop' },
4119     {
4120       join     => { cd => 'track' },
4121       order_by => 'artist.name',
4122     }
4123   );
4124
4125 You need to use the relationship (not the table) name in  conditions,
4126 because they are aliased as such. The current table is aliased as "me", so
4127 you need to use me.column_name in order to avoid ambiguity. For example:
4128
4129   # Get CDs from 1984 with a 'Foo' track
4130   my $rs = $schema->resultset('CD')->search(
4131     {
4132       'me.year' => 1984,
4133       'tracks.name' => 'Foo'
4134     },
4135     { join => 'tracks' }
4136   );
4137
4138 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4139 similarly for a third time). For e.g.
4140
4141   my $rs = $schema->resultset('Artist')->search({
4142     'cds.title'   => 'Down to Earth',
4143     'cds_2.title' => 'Popular',
4144   }, {
4145     join => [ qw/cds cds/ ],
4146   });
4147
4148 will return a set of all artists that have both a cd with title 'Down
4149 to Earth' and a cd with title 'Popular'.
4150
4151 If you want to fetch related objects from other tables as well, see L</prefetch>
4152 below.
4153
4154  NOTE: An internal join-chain pruner will discard certain joins while
4155  constructing the actual SQL query, as long as the joins in question do not
4156  affect the retrieved result. This for example includes 1:1 left joins
4157  that are not part of the restriction specification (WHERE/HAVING) nor are
4158  a part of the query selection.
4159
4160 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4161
4162 =head2 collapse
4163
4164 =over 4
4165
4166 =item Value: (0 | 1)
4167
4168 =back
4169
4170 When set to a true value, indicates that any rows fetched from joined has_many
4171 relationships are to be aggregated into the corresponding "parent" object. For
4172 example, the resultset:
4173
4174   my $rs = $schema->resultset('CD')->search({}, {
4175     '+columns' => [ qw/ tracks.title tracks.position / ],
4176     join => 'tracks',
4177     collapse => 1,
4178   });
4179
4180 While executing the following query:
4181
4182   SELECT me.*, tracks.title, tracks.position
4183     FROM cd me
4184     LEFT JOIN track tracks
4185       ON tracks.cdid = me.cdid
4186
4187 Will return only as many objects as there are rows in the CD source, even
4188 though the result of the query may span many rows. Each of these CD objects
4189 will in turn have multiple "Track" objects hidden behind the has_many
4190 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4191 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4192 product"), with each CD object containing exactly one of all fetched Track data.
4193
4194 When a collapse is requested on a non-ordered resultset, an order by some
4195 unique part of the main source (the left-most table) is inserted automatically.
4196 This is done so that the resultset is allowed to be "lazy" - calling
4197 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4198 object with all of its related data.
4199
4200 If an L</order_by> is already declared, and orders the resultset in a way that
4201 makes collapsing as described above impossible (e.g. C<< ORDER BY
4202 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4203 switch to "eager" mode and slurp the entire resultset before constructing the
4204 first object returned by L</next>.
4205
4206 Setting this attribute on a resultset that does not join any has_many
4207 relations is a no-op.
4208
4209 For a more in-depth discussion, see L</PREFETCHING>.
4210
4211 =head2 prefetch
4212
4213 =over 4
4214
4215 =item Value: ($rel_name | \@rel_names | \%rel_names)
4216
4217 =back
4218
4219 This attribute is a shorthand for specifying a L</join> spec, adding all
4220 columns from the joined related sources as L</+columns> and setting
4221 L</collapse> to a true value. For example, the following two queries are
4222 equivalent:
4223
4224   my $rs = $schema->resultset('Artist')->search({}, {
4225     prefetch => { cds => ['genre', 'tracks' ] },
4226   });
4227
4228 and
4229
4230   my $rs = $schema->resultset('Artist')->search({}, {
4231     join => { cds => ['genre', 'tracks' ] },
4232     collapse => 1,
4233     '+columns' => [
4234       (map
4235         { +{ "cds.$_" => "cds.$_" } }
4236         $schema->source('Artist')->related_source('cds')->columns
4237       ),
4238       (map
4239         { +{ "cds.genre.$_" => "genre.$_" } }
4240         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4241       ),
4242       (map
4243         { +{ "cds.tracks.$_" => "tracks.$_" } }
4244         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4245       ),
4246     ],
4247   });
4248
4249 Both producing the following SQL:
4250
4251   SELECT  me.artistid, me.name, me.rank, me.charfield,
4252           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4253           genre.genreid, genre.name,
4254           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4255     FROM artist me
4256     LEFT JOIN cd cds
4257       ON cds.artist = me.artistid
4258     LEFT JOIN genre genre
4259       ON genre.genreid = cds.genreid
4260     LEFT JOIN track tracks
4261       ON tracks.cd = cds.cdid
4262   ORDER BY me.artistid
4263
4264 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4265 the arguments are properly merged and generally do the right thing. For
4266 example, you may want to do the following:
4267
4268   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4269     { 'genre.genreid' => undef },
4270     {
4271       join => { cds => 'genre' },
4272       prefetch => 'cds',
4273     }
4274   );
4275
4276 Which generates the following SQL:
4277
4278   SELECT  me.artistid, me.name, me.rank, me.charfield,
4279           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4280     FROM artist me
4281     LEFT JOIN cd cds
4282       ON cds.artist = me.artistid
4283     LEFT JOIN genre genre
4284       ON genre.genreid = cds.genreid
4285   WHERE genre.genreid IS NULL
4286   ORDER BY me.artistid
4287
4288 For a more in-depth discussion, see L</PREFETCHING>.
4289
4290 =head2 alias
4291
4292 =over 4
4293
4294 =item Value: $source_alias
4295
4296 =back
4297
4298 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4299 nested search queries (sub-SELECTs) might need specific aliases set to
4300 reference inner queries.  For example:
4301
4302    my $q = $rs
4303       ->related_resultset('CDs')
4304       ->related_resultset('Tracks')
4305       ->search({
4306          'track.id' => { -ident => 'none_search.id' },
4307       })
4308       ->as_query;
4309
4310    my $ids = $self->search({
4311       -not_exists => $q,
4312    }, {
4313       alias    => 'none_search',
4314       group_by => 'none_search.id',
4315    })->get_column('id')->as_query;
4316
4317    $self->search({ id => { -in => $ids } })
4318
4319 This attribute is directly tied to L</current_source_alias>.
4320
4321 =head2 page
4322
4323 =over 4
4324
4325 =item Value: $page
4326
4327 =back
4328
4329 Makes the resultset paged and specifies the page to retrieve. Effectively
4330 identical to creating a non-pages resultset and then calling ->page($page)
4331 on it.
4332
4333 If L</rows> attribute is not specified it defaults to 10 rows per page.
4334
4335 When you have a paged resultset, L</count> will only return the number
4336 of rows in the page. To get the total, use the L</pager> and call
4337 C<total_entries> on it.
4338
4339 =head2 rows
4340
4341 =over 4
4342
4343 =item Value: $rows
4344
4345 =back
4346
4347 Specifies the maximum number of rows for direct retrieval or the number of
4348 rows per page if the page attribute or method is used.
4349
4350 =head2 offset
4351
4352 =over 4
4353
4354 =item Value: $offset
4355
4356 =back
4357
4358 Specifies the (zero-based) row number for the  first row to be returned, or the
4359 of the first row of the first page if paging is used.
4360
4361 =head2 software_limit
4362
4363 =over 4
4364
4365 =item Value: (0 | 1)
4366
4367 =back
4368
4369 When combined with L</rows> and/or L</offset> the generated SQL will not
4370 include any limit dialect stanzas. Instead the entire result will be selected
4371 as if no limits were specified, and DBIC will perform the limit locally, by
4372 artificially advancing and finishing the resulting L</cursor>.
4373
4374 This is the recommended way of performing resultset limiting when no sane RDBMS
4375 implementation is available (e.g.
4376 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4377 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4378
4379 =head2 group_by
4380
4381 =over 4
4382
4383 =item Value: \@columns
4384
4385 =back
4386
4387 A arrayref of columns to group by. Can include columns of joined tables.
4388
4389   group_by => [qw/ column1 column2 ... /]
4390
4391 =head2 having
4392
4393 =over 4
4394
4395 =item Value: $condition
4396
4397 =back
4398
4399 HAVING is a select statement attribute that is applied between GROUP BY and
4400 ORDER BY. It is applied to the after the grouping calculations have been
4401 done.
4402
4403   having => { 'count_employee' => { '>=', 100 } }
4404
4405 or with an in-place function in which case literal SQL is required:
4406
4407   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4408
4409 =head2 distinct
4410
4411 =over 4
4412
4413 =item Value: (0 | 1)
4414
4415 =back
4416
4417 Set to 1 to automatically generate a L</group_by> clause based on the selection
4418 (including intelligent handling of L</order_by> contents). Note that the group
4419 criteria calculation takes place over the B<final> selection. This includes
4420 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4421 L</search> calls, and standalone columns selected via
4422 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4423 extra selections specified via L</prefetch> - such selections are explicitly
4424 excluded from group criteria calculations.
4425
4426 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4427 setting is ignored and an appropriate warning is issued.
4428
4429 =head2 where
4430
4431 =over 4
4432
4433 Adds to the WHERE clause.
4434
4435   # only return rows WHERE deleted IS NULL for all searches
4436   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4437
4438 Can be overridden by passing C<< { where => undef } >> as an attribute
4439 to a resultset.
4440
4441 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4442
4443 =back
4444
4445 =head2 cache
4446
4447 Set to 1 to cache search results. This prevents extra SQL queries if you
4448 revisit rows in your ResultSet:
4449
4450   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4451
4452   while( my $artist = $resultset->next ) {
4453     ... do stuff ...
4454   }
4455
4456   $rs->first; # without cache, this would issue a query
4457
4458 By default, searches are not cached.
4459
4460 For more examples of using these attributes, see
4461 L<DBIx::Class::Manual::Cookbook>.
4462
4463 =head2 for
4464
4465 =over 4
4466
4467 =item Value: ( 'update' | 'shared' | \$scalar )
4468
4469 =back
4470
4471 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4472 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4473 query.
4474
4475 =head1 PREFETCHING
4476
4477 DBIx::Class supports arbitrary related data prefetching from multiple related
4478 sources. Any combination of relationship types and column sets are supported.
4479 If L<collapsing|/collapse> is requested, there is an additional requirement of
4480 selecting enough data to make every individual object uniquely identifiable.
4481
4482 Here are some more involved examples, based on the following relationship map:
4483
4484   # Assuming:
4485   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4486   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4487   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4488
4489   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4490
4491   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4492
4493
4494
4495   my $rs = $schema->resultset('Tag')->search(
4496     undef,
4497     {
4498       prefetch => {
4499         cd => 'artist'
4500       }
4501     }
4502   );
4503
4504 The initial search results in SQL like the following:
4505
4506   SELECT tag.*, cd.*, artist.* FROM tag
4507   JOIN cd ON tag.cd = cd.cdid
4508   JOIN artist ON cd.artist = artist.artistid
4509
4510 L<DBIx::Class> has no need to go back to the database when we access the
4511 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4512 case.
4513
4514 Simple prefetches will be joined automatically, so there is no need
4515 for a C<join> attribute in the above search.
4516
4517 The L</prefetch> attribute can be used with any of the relationship types
4518 and multiple prefetches can be specified together. Below is a more complex
4519 example that prefetches a CD's artist, its liner notes (if present),
4520 the cover image, the tracks on that CD, and the guests on those
4521 tracks.
4522
4523   my $rs = $schema->resultset('CD')->search(
4524     undef,
4525     {
4526       prefetch => [
4527         { artist => 'record_label'},  # belongs_to => belongs_to
4528         'liner_note',                 # might_have
4529         'cover_image',                # has_one
4530         { tracks => 'guests' },       # has_many => has_many
4531       ]
4532     }
4533   );
4534
4535 This will produce SQL like the following:
4536
4537   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4538          tracks.*, guests.*
4539     FROM cd me
4540     JOIN artist artist
4541       ON artist.artistid = me.artistid
4542     JOIN record_label record_label
4543       ON record_label.labelid = artist.labelid
4544     LEFT JOIN track tracks
4545       ON tracks.cdid = me.cdid
4546     LEFT JOIN guest guests
4547       ON guests.trackid = track.trackid
4548     LEFT JOIN liner_notes liner_note
4549       ON liner_note.cdid = me.cdid
4550     JOIN cd_artwork cover_image
4551       ON cover_image.cdid = me.cdid
4552   ORDER BY tracks.cd
4553
4554 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4555 C<tracks>, and C<guests> of the CD will all be available through the
4556 relationship accessors without the need for additional queries to the
4557 database.
4558
4559 =head3 CAVEATS
4560
4561 Prefetch does a lot of deep magic. As such, it may not behave exactly
4562 as you might expect.
4563
4564 =over 4
4565
4566 =item *
4567
4568 Prefetch uses the L</cache> to populate the prefetched relationships. This
4569 may or may not be what you want.
4570
4571 =item *
4572
4573 If you specify a condition on a prefetched relationship, ONLY those
4574 rows that match the prefetched condition will be fetched into that relationship.
4575 This means that adding prefetch to a search() B<may alter> what is returned by
4576 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4577
4578   my $artist_rs = $schema->resultset('Artist')->search({
4579       'cds.year' => 2008,
4580   }, {
4581       join => 'cds',
4582   });
4583
4584   my $count = $artist_rs->first->cds->count;
4585
4586   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4587
4588   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4589
4590   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4591
4592 That cmp_ok() may or may not pass depending on the datasets involved. In other
4593 words the C<WHERE> condition would apply to the entire dataset, just like
4594 it would in regular SQL. If you want to add a condition only to the "right side"
4595 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4596 condition|DBIx::Class::Relationship::Base/condition>
4597
4598 =back
4599
4600 =head1 DBIC BIND VALUES
4601
4602 Because DBIC may need more information to bind values than just the column name
4603 and value itself, it uses a special format for both passing and receiving bind
4604 values.  Each bind value should be composed of an arrayref of
4605 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4606
4607 =over 4
4608
4609 =item dbd_attrs
4610
4611 If present (in any form), this is what is being passed directly to bind_param.
4612 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4613 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4614
4615 If this is specified, all other bind options described below are ignored.
4616
4617 =item sqlt_datatype
4618
4619 If present, this is used to infer the actual bind attribute by passing to
4620 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4621 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4622
4623 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4624 currently drivers are expected to "Do the Right Thing" when given a common
4625 datatype name.  (Not ideal, but that's what we got at this point.)
4626
4627 =item sqlt_size
4628
4629 Currently used to correctly allocate buffers for bind_param_inout().
4630 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4631 or to a sensible value based on the "data_type".
4632
4633 =item dbic_colname
4634
4635 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4636 explicitly specified they are never overridden).  Also used by some weird DBDs,
4637 where the column name should be available at bind_param time (e.g. Oracle).
4638
4639 =back
4640
4641 For backwards compatibility and convenience, the following shortcuts are
4642 supported:
4643
4644   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4645   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4646   [ undef,   $val ] === [ {}, $val ]
4647   $val              === [ {}, $val ]
4648
4649 =head1 AUTHOR AND CONTRIBUTORS
4650
4651 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4652
4653 =head1 LICENSE
4654
4655 You may distribute this code under the same terms as Perl itself.
4656