lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use DBIx::Class::ResultClass::HashRefInflator;
   9 use Scalar::Util qw/blessed weaken reftype/;
  10 use DBIx::Class::_Util qw(
  11   dbic_internal_try dump_value
  12   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  13 );
  14 use Try::Tiny;
  15
  16 # not importing first() as it will clash with our own method
  17 use List::Util ();
  18
  19 BEGIN {
  20   # De-duplication in _merge_attr() is disabled, but left in for reference
  21   # (the merger is used for other things that ought not to be de-duped)
  22   *__HM_DEDUP = sub () { 0 };
  23 }
  24
  25 use namespace::clean;
  26
  27 use overload
  28         '0+'     => "count",
  29         'bool'   => "_bool",
  30         fallback => 1;
  31
  32 # this is real - CDBICompat overrides it with insanity
  33 # yes, prototype won't matter, but that's for now ;)
  34 sub _bool () { 1 }
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  37
  38 =head1 NAME
  39
  40 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  41
  42 =head1 SYNOPSIS
  43
  44   my $users_rs = $schema->resultset('User');
  45   while( $user = $users_rs->next) {
  46     print $user->username;
  47   }
  48
  49   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  50   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  51
  52 =head1 DESCRIPTION
  53
  54 A ResultSet is an object which stores a set of conditions representing
  55 a query. It is the backbone of DBIx::Class (i.e. the really
  56 important/useful bit).
  57
  58 No SQL is executed on the database when a ResultSet is created, it
  59 just stores all the conditions needed to create the query.
  60
  61 A basic ResultSet representing the data of an entire table is returned
  62 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  63 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  64
  65   my $users_rs = $schema->resultset('User');
  66
  67 A new ResultSet is returned from calling L</search> on an existing
  68 ResultSet. The new one will contain all the conditions of the
  69 original, plus any new conditions added in the C<search> call.
  70
  71 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  72 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  73 represents.
  74
  75 The query that the ResultSet represents is B<only> executed against
  76 the database when these methods are called:
  77 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  78
  79 If a resultset is used in a numeric context it returns the L</count>.
  80 However, if it is used in a boolean context it is B<always> true.  So if
  81 you want to check if a resultset has any results, you must use C<if $rs
  82 != 0>.
  83
  84 =head1 EXAMPLES
  85
  86 =head2 Chaining resultsets
  87
  88 Let's say you've got a query that needs to be run to return some data
  89 to the user. But, you have an authorization system in place that
  90 prevents certain users from seeing certain information. So, you want
  91 to construct the basic query in one method, but add constraints to it in
  92 another.
  93
  94   sub get_data {
  95     my $self = shift;
  96     my $request = $self->get_request; # Get a request object somehow.
  97     my $schema = $self->result_source->schema;
  98
  99     my $cd_rs = $schema->resultset('CD')->search({
 100       title => $request->param('title'),
 101       year => $request->param('year'),
 102     });
 103
 104     $cd_rs = $self->apply_security_policy( $cd_rs );
 105
 106     return $cd_rs->all();
 107   }
 108
 109   sub apply_security_policy {
 110     my $self = shift;
 111     my ($rs) = @_;
 112
 113     return $rs->search({
 114       subversive => 0,
 115     });
 116   }
 117
 118 =head3 Resolving conditions and attributes
 119
 120 When a resultset is chained from another resultset (e.g.:
 121 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 122 and attributes with the same keys need resolving.
 123
 124 If any of L</columns>, L</select>, L</as> are present, they reset the
 125 original selection, and start the selection "clean".
 126
 127 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 128 are merged into the existing ones from the original resultset.
 129
 130 The L</where> and L</having> attributes, and any search conditions, are
 131 merged with an SQL C<AND> to the existing condition from the original
 132 resultset.
 133
 134 All other attributes are overridden by any new ones supplied in the
 135 search attributes.
 136
 137 =head2 Multiple queries
 138
 139 Since a resultset just defines a query, you can do all sorts of
 140 things with it with the same object.
 141
 142   # Don't hit the DB yet.
 143   my $cd_rs = $schema->resultset('CD')->search({
 144     title => 'something',
 145     year => 2009,
 146   });
 147
 148   # Each of these hits the DB individually.
 149   my $count = $cd_rs->count;
 150   my $most_recent = $cd_rs->get_column('date_released')->max();
 151   my @records = $cd_rs->all;
 152
 153 And it's not just limited to SELECT statements.
 154
 155   $cd_rs->delete();
 156
 157 This is even cooler:
 158
 159   $cd_rs->create({ artist => 'Fred' });
 160
 161 Which is the same as:
 162
 163   $schema->resultset('CD')->create({
 164     title => 'something',
 165     year => 2009,
 166     artist => 'Fred'
 167   });
 168
 169 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 170
 171 =head2 Custom ResultSet classes
 172
 173 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 174
 175   package MyApp::Schema::ResultSet::User;
 176
 177   use strict;
 178   use warnings;
 179
 180   use base 'DBIx::Class::ResultSet';
 181
 182   sub active {
 183     my $self = shift;
 184     $self->search({ $self->current_source_alias . '.active' => 1 });
 185   }
 186
 187   sub unverified {
 188     my $self = shift;
 189     $self->search({ $self->current_source_alias . '.verified' => 0 });
 190   }
 191
 192   sub created_n_days_ago {
 193     my ($self, $days_ago) = @_;
 194     $self->search({
 195       $self->current_source_alias . '.create_date' => {
 196         '<=',
 197       $self->result_source->schema->storage->datetime_parser->format_datetime(
 198         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 199       )}
 200     });
 201   }
 202
 203   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 204
 205   1;
 206
 207 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 208 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 209 L<ResulSet|DBIx::Class::ResultSet> classes.
 210
 211 =head3 ResultSet subclassing with Moose and similar constructor-providers
 212
 213 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 214 you may find it useful if your ResultSets contain a lot of business logic
 215 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 216 your code via roles.
 217
 218 In order to write custom ResultSet classes with L<Moo> you need to use the
 219 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 220 unusual signature of the L<constructor provided by DBIC
 221 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 222
 223   use Moo;
 224   extends 'DBIx::Class::ResultSet';
 225   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 226
 227   ...your code...
 228
 229   1;
 230
 231 If you want to build your custom ResultSet classes with L<Moose>, you need
 232 a similar, though a little more elaborate template in order to interface the
 233 inlining of the L<Moose>-provided
 234 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 235 with the DBIC one.
 236
 237   package MyApp::Schema::ResultSet::User;
 238
 239   use Moose;
 240   use MooseX::NonMoose;
 241   extends 'DBIx::Class::ResultSet';
 242
 243   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 244
 245   ...your code...
 246
 247   __PACKAGE__->meta->make_immutable;
 248
 249   1;
 250
 251 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 252 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 253 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 254 instead by doing:
 255
 256   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 257
 258 =head1 METHODS
 259
 260 =head2 new
 261
 262 =over 4
 263
 264 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 265
 266 =item Return Value: L<$resultset|/search>
 267
 268 =back
 269
 270 The resultset constructor. Takes a source object (usually a
 271 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 272 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 273 executed as needed by the other methods.
 274
 275 Generally you never construct a resultset manually. Instead you get one
 276 from e.g. a
 277 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 278 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 279 scalar context):
 280
 281   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 282
 283 =over
 284
 285 =item WARNING
 286
 287 If called on an object, proxies to L</new_result> instead, so
 288
 289   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 290
 291 will return a CD object, not a ResultSet, and is equivalent to:
 292
 293   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 294
 295 Please also keep in mind that many internals call L</new_result> directly,
 296 so overloading this method with the idea of intercepting new result object
 297 creation B<will not work>. See also warning pertaining to L</create>.
 298
 299 =back
 300
 301 =cut
 302
 303 sub new {
 304   my $class = shift;
 305
 306   if (ref $class) {
 307     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 308     return $class->new_result(@_);
 309   }
 310
 311   my ($source, $attrs) = @_;
 312   $source = $source->resolve
 313     if $source->isa('DBIx::Class::ResultSourceHandle');
 314
 315   $attrs = { %{$attrs||{}} };
 316   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 317
 318   if ($attrs->{page}) {
 319     $attrs->{rows} ||= 10;
 320   }
 321
 322   $attrs->{alias} ||= 'me';
 323
 324   my $self = bless {
 325     result_source => $source,
 326     cond => $attrs->{where},
 327     pager => undef,
 328     attrs => $attrs,
 329   }, $class;
 330
 331   # if there is a dark selector, this means we are already in a
 332   # chain and the cleanup/sanification was taken care of by
 333   # _search_rs already
 334   $self->_normalize_selection($attrs)
 335     unless $attrs->{_dark_selector};
 336
 337   $self->result_class(
 338     $attrs->{result_class} || $source->result_class
 339   );
 340
 341   $self;
 342 }
 343
 344 =head2 search
 345
 346 =over 4
 347
 348 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 349
 350 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 351
 352 =back
 353
 354   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 355   my $new_rs = $cd_rs->search({ year => 2005 });
 356
 357   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 358                  # year = 2005 OR year = 2004
 359
 360 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 361 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 362 To avoid that, use L</search_rs>.
 363
 364 If you need to pass in additional attributes but no additional condition,
 365 call it as C<search(undef, \%attrs)>.
 366
 367   # "SELECT name, artistid FROM $artist_table"
 368   my @all_artists = $schema->resultset('Artist')->search(undef, {
 369     columns => [qw/name artistid/],
 370   });
 371
 372 For a list of attributes that can be passed to C<search>, see
 373 L</ATTRIBUTES>. For more examples of using this function, see
 374 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 375 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 376 and its extension L<DBIx::Class::SQLMaker>.
 377
 378 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 379
 380 =head3 CAVEAT
 381
 382 Note that L</search> does not process/deflate any of the values passed in the
 383 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 384 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 385 manually that any value passed to this method will stringify to something the
 386 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 387 objects, for more info see:
 388 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 389
 390 =cut
 391
 392 sub search {
 393   my $self = shift;
 394   my $rs = $self->search_rs( @_ );
 395
 396   if (wantarray) {
 397     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 398     return $rs->all;
 399   }
 400   elsif (defined wantarray) {
 401     return $rs;
 402   }
 403   else {
 404     # we can be called by a relationship helper, which in
 405     # turn may be called in void context due to some braindead
 406     # overload or whatever else the user decided to be clever
 407     # at this particular day. Thus limit the exception to
 408     # external code calls only
 409     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 410       if (caller)[0] !~ /^\QDBIx::Class::/;
 411
 412     return ();
 413   }
 414 }
 415
 416 =head2 search_rs
 417
 418 =over 4
 419
 420 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 421
 422 =item Return Value: L<$resultset|/search>
 423
 424 =back
 425
 426 This method does the same exact thing as search() except it will
 427 always return a resultset, even in list context.
 428
 429 =cut
 430
 431 sub search_rs {
 432   my $self = shift;
 433
 434   my $rsrc = $self->result_source;
 435   my ($call_cond, $call_attrs);
 436
 437   # Special-case handling for (undef, undef) or (undef)
 438   # Note that (foo => undef) is valid deprecated syntax
 439   @_ = () if not scalar grep { defined $_ } @_;
 440
 441   # just a cond
 442   if (@_ == 1) {
 443     $call_cond = shift;
 444   }
 445   # fish out attrs in the ($condref, $attr) case
 446   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 447     ($call_cond, $call_attrs) = @_;
 448   }
 449   elsif (@_ % 2) {
 450     $self->throw_exception('Odd number of arguments to search')
 451   }
 452   # legacy search
 453   elsif (@_) {
 454     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 455       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 456
 457     for my $i (0 .. $#_) {
 458       next if $i % 2;
 459       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 460         if (! defined $_[$i] or length ref $_[$i] );
 461     }
 462
 463     $call_cond = { @_ };
 464   }
 465
 466   # see if we can keep the cache (no $rs changes)
 467   my $cache;
 468   my %safe = (alias => 1, cache => 1);
 469   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 470     ! defined $call_cond
 471       or
 472     ref $call_cond eq 'HASH' && ! keys %$call_cond
 473       or
 474     ref $call_cond eq 'ARRAY' && ! @$call_cond
 475   )) {
 476     $cache = $self->get_cache;
 477   }
 478
 479   my $old_attrs = { %{$self->{attrs}} };
 480   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 481
 482   my $new_attrs = { %$old_attrs };
 483
 484   # take care of call attrs (only if anything is changing)
 485   if ($call_attrs and keys %$call_attrs) {
 486
 487     # copy for _normalize_selection
 488     $call_attrs = { %$call_attrs };
 489
 490     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 491
 492     # reset the current selector list if new selectors are supplied
 493     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 494       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 495     }
 496
 497     # Normalize the new selector list (operates on the passed-in attr structure)
 498     # Need to do it on every chain instead of only once on _resolved_attrs, in
 499     # order to allow detection of empty vs partial 'as'
 500     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 501       if $old_attrs->{_dark_selector};
 502     $self->_normalize_selection ($call_attrs);
 503
 504     # start with blind overwriting merge, exclude selector attrs
 505     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 506     delete @{$new_attrs}{@selector_attrs};
 507
 508     for (@selector_attrs) {
 509       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 510         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 511     }
 512
 513     # older deprecated name, use only if {columns} is not there
 514     if (my $c = delete $new_attrs->{cols}) {
 515       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 516       if ($new_attrs->{columns}) {
 517         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 518       }
 519       else {
 520         $new_attrs->{columns} = $c;
 521       }
 522     }
 523
 524
 525     # join/prefetch use their own crazy merging heuristics
 526     foreach my $key (qw/join prefetch/) {
 527       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 528         if exists $call_attrs->{$key};
 529     }
 530
 531     # stack binds together
 532     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 533   }
 534
 535
 536   for ($old_where, $call_cond) {
 537     if (defined $_) {
 538       $new_attrs->{where} = $self->_stack_cond (
 539         $_, $new_attrs->{where}
 540       );
 541     }
 542   }
 543
 544   if (defined $old_having) {
 545     $new_attrs->{having} = $self->_stack_cond (
 546       $old_having, $new_attrs->{having}
 547     )
 548   }
 549
 550   my $rs = (ref $self)->new($rsrc, $new_attrs);
 551
 552   $rs->set_cache($cache) if ($cache);
 553
 554   return $rs;
 555 }
 556
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => do {
 622                 local $Data::Dumper::Indent = 0;
 623                 dump_value $_;
 624               },
 625             };
 626             last SELECTOR;
 627           }
 628         }
 629       }
 630     }
 631     elsif (@$as < @$sel) {
 632       $self->throw_exception(
 633         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 634       );
 635     }
 636     elsif ($pref and $attrs->{_dark_selector}) {
 637       $self->throw_exception(
 638         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 639       );
 640     }
 641
 642
 643     # merge result
 644     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 645     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 646   }
 647 }
 648
 649 sub _stack_cond {
 650   my ($self, $left, $right) = @_;
 651
 652   (
 653     (ref $_ eq 'ARRAY' and !@$_)
 654       or
 655     (ref $_ eq 'HASH' and ! keys %$_)
 656   ) and $_ = undef for ($left, $right);
 657
 658   # either one of the two undef
 659   if ( (defined $left) xor (defined $right) ) {
 660     return defined $left ? $left : $right;
 661   }
 662   # both undef
 663   elsif ( ! defined $left ) {
 664     return undef
 665   }
 666   else {
 667     return $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 668   }
 669 }
 670
 671 =head2 search_literal
 672
 673 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 674 should only be used in that context. C<search_literal> is a convenience
 675 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 676 want to ensure columns are bound correctly, use L</search>.
 677
 678 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 679 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 680 require C<search_literal>.
 681
 682 =over 4
 683
 684 =item Arguments: $sql_fragment, @standalone_bind_values
 685
 686 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 687
 688 =back
 689
 690   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 691   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 692
 693 Pass a literal chunk of SQL to be added to the conditional part of the
 694 resultset query.
 695
 696 Example of how to use C<search> instead of C<search_literal>
 697
 698   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 699   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 700
 701 =cut
 702
 703 sub search_literal {
 704   my ($self, $sql, @bind) = @_;
 705   my $attr;
 706   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 707     $attr = pop @bind;
 708   }
 709   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 710 }
 711
 712 =head2 find
 713
 714 =over 4
 715
 716 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 717
 718 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 719
 720 =back
 721
 722 Finds and returns a single row based on supplied criteria. Takes either a
 723 hashref with the same format as L</create> (including inference of foreign
 724 keys from related objects), or a list of primary key values in the same
 725 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 726 declaration on the L</result_source>.
 727
 728 In either case an attempt is made to combine conditions already existing on
 729 the resultset with the condition passed to this method.
 730
 731 To aid with preparing the correct query for the storage you may supply the
 732 C<key> attribute, which is the name of a
 733 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 734 unique constraint corresponding to the
 735 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 736 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 737 to construct a query that satisfies the named unique constraint fully (
 738 non-NULL values for each column member of the constraint) an exception is
 739 thrown.
 740
 741 If no C<key> is specified, the search is carried over all unique constraints
 742 which are fully defined by the available condition.
 743
 744 If no such constraint is found, C<find> currently defaults to a simple
 745 C<< search->(\%column_values) >> which may or may not do what you expect.
 746 Note that this fallback behavior may be deprecated in further versions. If
 747 you need to search with arbitrary conditions - use L</search>. If the query
 748 resulting from this fallback produces more than one row, a warning to the
 749 effect is issued, though only the first row is constructed and returned as
 750 C<$result_object>.
 751
 752 In addition to C<key>, L</find> recognizes and applies standard
 753 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 754
 755 Note that if you have extra concerns about the correctness of the resulting
 756 query you need to specify the C<key> attribute and supply the entire condition
 757 as an argument to find (since it is not always possible to perform the
 758 combination of the resultset condition with the supplied one, especially if
 759 the resultset condition contains literal sql).
 760
 761 For example, to find a row by its primary key:
 762
 763   my $cd = $schema->resultset('CD')->find(5);
 764
 765 You can also find a row by a specific unique constraint:
 766
 767   my $cd = $schema->resultset('CD')->find(
 768     {
 769       artist => 'Massive Attack',
 770       title  => 'Mezzanine',
 771     },
 772     { key => 'cd_artist_title' }
 773   );
 774
 775 See also L</find_or_create> and L</update_or_create>.
 776
 777 =cut
 778
 779 sub find {
 780   my $self = shift;
 781   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 782
 783   my $rsrc = $self->result_source;
 784
 785   my $constraint_name;
 786   if (exists $attrs->{key}) {
 787     $constraint_name = defined $attrs->{key}
 788       ? $attrs->{key}
 789       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 790     ;
 791   }
 792
 793   # Parse out the condition from input
 794   my $call_cond;
 795
 796   if (ref $_[0] eq 'HASH') {
 797     $call_cond = { %{$_[0]} };
 798   }
 799   else {
 800     # if only values are supplied we need to default to 'primary'
 801     $constraint_name = 'primary' unless defined $constraint_name;
 802
 803     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 804
 805     $self->throw_exception(
 806       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 807     ) unless @c_cols;
 808
 809     $self->throw_exception (
 810       'find() expects either a column/value hashref, or a list of values '
 811     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 812     ) unless @c_cols == @_;
 813
 814     @{$call_cond}{@c_cols} = @_;
 815   }
 816
 817   # process relationship data if any
 818   for my $key (keys %$call_cond) {
 819     if (
 820       length ref($call_cond->{$key})
 821         and
 822       my $relinfo = $rsrc->relationship_info($key)
 823         and
 824       # implicitly skip has_many's (likely MC)
 825       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 826     ) {
 827       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 828         $relinfo->{cond}, $val, $key, $key
 829       );
 830
 831       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 832          if $crosstable or ref($rel_cond) ne 'HASH';
 833
 834       # supplement condition
 835       # relationship conditions take precedence (?)
 836       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 837     }
 838   }
 839
 840   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 841   my $final_cond;
 842   if (defined $constraint_name) {
 843     $final_cond = $self->_qualify_cond_columns (
 844
 845       $self->result_source->_minimal_valueset_satisfying_constraint(
 846         constraint_name => $constraint_name,
 847         values => ($self->_merge_with_rscond($call_cond))[0],
 848         carp_on_nulls => 1,
 849       ),
 850
 851       $alias,
 852     );
 853   }
 854   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 855     # This means that we got here after a merger of relationship conditions
 856     # in ::Relationship::Base::search_related (the row method), and furthermore
 857     # the relationship is of the 'single' type. This means that the condition
 858     # provided by the relationship (already attached to $self) is sufficient,
 859     # as there can be only one row in the database that would satisfy the
 860     # relationship
 861   }
 862   else {
 863     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 864
 865     # no key was specified - fall down to heuristics mode:
 866     # run through all unique queries registered on the resultset, and
 867     # 'OR' all qualifying queries together
 868     #
 869     # always start from 'primary' if it exists at all
 870     for my $c_name ( sort {
 871         $a eq 'primary' ? -1
 872       : $b eq 'primary' ? 1
 873       : $a cmp $b
 874     } $rsrc->unique_constraint_names) {
 875
 876       next if $seen_column_combinations{
 877         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 878       }++;
 879
 880       dbic_internal_try {
 881         push @unique_queries, $self->_qualify_cond_columns(
 882           $self->result_source->_minimal_valueset_satisfying_constraint(
 883             constraint_name => $c_name,
 884             values => ($self->_merge_with_rscond($call_cond))[0],
 885             columns_info => ($ci ||= $self->result_source->columns_info),
 886           ),
 887           $alias
 888         );
 889       }
 890       catch {
 891         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 892       };
 893     }
 894
 895     $final_cond =
 896         @unique_queries   ? \@unique_queries
 897       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 898       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 899     ;
 900   }
 901
 902   # Run the query, passing the result_class since it should propagate for find
 903   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 904   if ($rs->_resolved_attrs->{collapse}) {
 905     my $row = $rs->next;
 906     carp "Query returned more than one row" if $rs->next;
 907     return $row;
 908   }
 909   else {
 910     return $rs->single;
 911   }
 912 }
 913
 914 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 915 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 916 #
 917 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 918 # condition. It is provided for overrides until a saner way forward is devised
 919 #
 920 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 921 # the road. Please adjust your tests accordingly to catch this situation early
 922 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 923 #
 924 # The method will not be removed without an adequately complete replacement
 925 # for strict-mode enforcement
 926 sub _non_unique_find_fallback {
 927   my ($self, $cond, $attrs) = @_;
 928
 929   return $self->_qualify_cond_columns(
 930     $cond,
 931     exists $attrs->{alias}
 932       ? $attrs->{alias}
 933       : $self->{attrs}{alias}
 934   );
 935 }
 936
 937
 938 sub _qualify_cond_columns {
 939   my ($self, $cond, $alias) = @_;
 940
 941   my %aliased = %$cond;
 942   for (keys %aliased) {
 943     $aliased{"$alias.$_"} = delete $aliased{$_}
 944       if $_ !~ /\./;
 945   }
 946
 947   return \%aliased;
 948 }
 949
 950 sub _build_unique_cond {
 951   carp_unique sprintf
 952     '_build_unique_cond is a private method, and moreover is about to go '
 953   . 'away. Please contact the development team at %s if you believe you '
 954   . 'have a genuine use for this method, in order to discuss alternatives.',
 955     DBIx::Class::_ENV_::HELP_URL,
 956   ;
 957
 958   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 959
 960   $self->result_source->_minimal_valueset_satisfying_constraint(
 961     constraint_name => $constraint_name,
 962     values => $cond,
 963     carp_on_nulls => !$croak_on_null
 964   );
 965 }
 966
 967 =head2 search_related
 968
 969 =over 4
 970
 971 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 972
 973 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 974
 975 =back
 976
 977   $new_rs = $cd_rs->search_related('artist', {
 978     name => 'Emo-R-Us',
 979   });
 980
 981 Searches the specified relationship, optionally specifying a condition and
 982 attributes for matching records. See L</ATTRIBUTES> for more information.
 983
 984 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 985 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 986
 987 See also L</search_related_rs>.
 988
 989 =cut
 990
 991 sub search_related {
 992   return shift->related_resultset(shift)->search(@_);
 993 }
 994
 995 =head2 search_related_rs
 996
 997 This method works exactly the same as search_related, except that
 998 it guarantees a resultset, even in list context.
 999
1000 =cut
1001
1002 sub search_related_rs {
1003   return shift->related_resultset(shift)->search_rs(@_);
1004 }
1005
1006 =head2 cursor
1007
1008 =over 4
1009
1010 =item Arguments: none
1011
1012 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1013
1014 =back
1015
1016 Returns a storage-driven cursor to the given resultset. See
1017 L<DBIx::Class::Cursor> for more information.
1018
1019 =cut
1020
1021 sub cursor {
1022   my $self = shift;
1023
1024   return $self->{cursor} ||= do {
1025     my $attrs = $self->_resolved_attrs;
1026     $self->result_source->storage->select(
1027       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1028     );
1029   };
1030 }
1031
1032 =head2 single
1033
1034 =over 4
1035
1036 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1037
1038 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1039
1040 =back
1041
1042   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1043
1044 Inflates the first result without creating a cursor if the resultset has
1045 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1046 of L</search>.
1047
1048 While this method can take an optional search condition (just like L</search>)
1049 being a fast-code-path it does not recognize search attributes. If you need to
1050 add extra joins or similar, call L</search> and then chain-call L</single> on the
1051 L<DBIx::Class::ResultSet> returned.
1052
1053 =over
1054
1055 =item B<Note>
1056
1057 As of 0.08100, this method enforces the assumption that the preceding
1058 query returns only one row. If more than one row is returned, you will receive
1059 a warning:
1060
1061   Query returned more than one row
1062
1063 In this case, you should be using L</next> or L</find> instead, or if you really
1064 know what you are doing, use the L</rows> attribute to explicitly limit the size
1065 of the resultset.
1066
1067 This method will also throw an exception if it is called on a resultset prefetching
1068 has_many, as such a prefetch implies fetching multiple rows from the database in
1069 order to assemble the resulting object.
1070
1071 =back
1072
1073 =cut
1074
1075 sub single {
1076   my ($self, $where) = @_;
1077   if(@_ > 2) {
1078       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1079   }
1080
1081   my $attrs = { %{$self->_resolved_attrs} };
1082
1083   $self->throw_exception(
1084     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1085   ) if $attrs->{collapse};
1086
1087   if ($where) {
1088     if (defined $attrs->{where}) {
1089       $attrs->{where} = {
1090         '-and' =>
1091             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1092                $where, delete $attrs->{where} ]
1093       };
1094     } else {
1095       $attrs->{where} = $where;
1096     }
1097   }
1098
1099   my $data = [ $self->result_source->storage->select_single(
1100     $attrs->{from}, $attrs->{select},
1101     $attrs->{where}, $attrs
1102   )];
1103
1104   return undef unless @$data;
1105   $self->{_stashed_rows} = [ $data ];
1106   $self->_construct_results->[0];
1107 }
1108
1109 =head2 get_column
1110
1111 =over 4
1112
1113 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1114
1115 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1116
1117 =back
1118
1119   my $max_length = $rs->get_column('length')->max;
1120
1121 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1122
1123 =cut
1124
1125 sub get_column {
1126   my ($self, $column) = @_;
1127   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1128   return $new;
1129 }
1130
1131 =head2 search_like
1132
1133 =over 4
1134
1135 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1136
1137 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1138
1139 =back
1140
1141   # WHERE title LIKE '%blue%'
1142   $cd_rs = $rs->search_like({ title => '%blue%'});
1143
1144 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1145 that this is simply a convenience method retained for ex Class::DBI users.
1146 You most likely want to use L</search> with specific operators.
1147
1148 For more information, see L<DBIx::Class::Manual::Cookbook>.
1149
1150 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1151 instead. An example conversion is:
1152
1153   ->search_like({ foo => 'bar' });
1154
1155   # Becomes
1156
1157   ->search({ foo => { like => 'bar' } });
1158
1159 =cut
1160
1161 sub search_like {
1162   my $class = shift;
1163   carp_unique (
1164     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1165    .' Instead use ->search({ x => { -like => "y%" } })'
1166    .' (note the outer pair of {}s - they are important!)'
1167   );
1168   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1169   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1170   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1171   return $class->search($query, { %$attrs });
1172 }
1173
1174 =head2 slice
1175
1176 =over 4
1177
1178 =item Arguments: $first, $last
1179
1180 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1181
1182 =back
1183
1184 Returns a resultset or object list representing a subset of elements from the
1185 resultset slice is called on. Indexes are from 0, i.e., to get the first
1186 three records, call:
1187
1188   my ($one, $two, $three) = $rs->slice(0, 2);
1189
1190 =cut
1191
1192 sub slice {
1193   my ($self, $min, $max) = @_;
1194   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1195   $attrs->{offset} = $self->{attrs}{offset} || 0;
1196   $attrs->{offset} += $min;
1197   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1198   return $self->search(undef, $attrs);
1199 }
1200
1201 =head2 next
1202
1203 =over 4
1204
1205 =item Arguments: none
1206
1207 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1208
1209 =back
1210
1211 Returns the next element in the resultset (C<undef> is there is none).
1212
1213 Can be used to efficiently iterate over records in the resultset:
1214
1215   my $rs = $schema->resultset('CD')->search;
1216   while (my $cd = $rs->next) {
1217     print $cd->title;
1218   }
1219
1220 Note that you need to store the resultset object, and call C<next> on it.
1221 Calling C<< resultset('Table')->next >> repeatedly will always return the
1222 first record from the resultset.
1223
1224 =cut
1225
1226 sub next {
1227   my ($self) = @_;
1228
1229   if (my $cache = $self->get_cache) {
1230     $self->{all_cache_position} ||= 0;
1231     return $cache->[$self->{all_cache_position}++];
1232   }
1233
1234   if ($self->{attrs}{cache}) {
1235     delete $self->{pager};
1236     $self->{all_cache_position} = 1;
1237     return ($self->all)[0];
1238   }
1239
1240   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1241
1242   $self->{_stashed_results} = $self->_construct_results
1243     or return undef;
1244
1245   return shift @{$self->{_stashed_results}};
1246 }
1247
1248 # Constructs as many results as it can in one pass while respecting
1249 # cursor laziness. Several modes of operation:
1250 #
1251 # * Always builds everything present in @{$self->{_stashed_rows}}
1252 # * If called with $fetch_all true - pulls everything off the cursor and
1253 #   builds all result structures (or objects) in one pass
1254 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1255 #   and if the resultset is ordered properly by the left side:
1256 #   * Fetches stuff off the cursor until the "master object" changes,
1257 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1258 #   OR
1259 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1260 #     was requested (there is no other way to collapse except for an
1261 #     eager cursor)
1262 # * If no collapse is requested - just get the next row, construct and
1263 #   return
1264 sub _construct_results {
1265   my ($self, $fetch_all) = @_;
1266
1267   my $rsrc = $self->result_source;
1268   my $attrs = $self->_resolved_attrs;
1269
1270   if (
1271     ! $fetch_all
1272       and
1273     ! $attrs->{order_by}
1274       and
1275     $attrs->{collapse}
1276       and
1277     my @pcols = $rsrc->primary_columns
1278   ) {
1279     # default order for collapsing unless the user asked for something
1280     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1281     $attrs->{_ordered_for_collapse} = 1;
1282     $attrs->{_order_is_artificial} = 1;
1283   }
1284
1285   # this will be used as both initial raw-row collector AND as a RV of
1286   # _construct_results. Not regrowing the array twice matters a lot...
1287   # a surprising amount actually
1288   my $rows = delete $self->{_stashed_rows};
1289
1290   my $cursor; # we may not need one at all
1291
1292   my $did_fetch_all = $fetch_all;
1293
1294   if ($fetch_all) {
1295     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1296     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1297   }
1298   elsif( $attrs->{collapse} ) {
1299
1300     # a cursor will need to be closed over in case of collapse
1301     $cursor = $self->cursor;
1302
1303     $attrs->{_ordered_for_collapse} = (
1304       (
1305         $attrs->{order_by}
1306           and
1307         $rsrc->schema
1308               ->storage
1309                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1310       ) ? 1 : 0
1311     ) unless defined $attrs->{_ordered_for_collapse};
1312
1313     if (! $attrs->{_ordered_for_collapse}) {
1314       $did_fetch_all = 1;
1315
1316       # instead of looping over ->next, use ->all in stealth mode
1317       # *without* calling a ->reset afterwards
1318       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1319       if (! $cursor->{_done}) {
1320         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1321         $cursor->{_done} = 1;
1322       }
1323     }
1324   }
1325
1326   if (! $did_fetch_all and ! @{$rows||[]} ) {
1327     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1328     $cursor ||= $self->cursor;
1329     if (scalar (my @r = $cursor->next) ) {
1330       $rows = [ \@r ];
1331     }
1332   }
1333
1334   return undef unless @{$rows||[]};
1335
1336   # sanity check - people are too clever for their own good
1337   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1338
1339     my $multiplied_selectors;
1340     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1341       if (
1342         $aliastypes->{multiplying}{$sel_alias}
1343           or
1344         $aliastypes->{premultiplied}{$sel_alias}
1345       ) {
1346         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1347       }
1348     }
1349
1350     for my $i (0 .. $#{$attrs->{as}} ) {
1351       my $sel = $attrs->{select}[$i];
1352
1353       if (ref $sel eq 'SCALAR') {
1354         $sel = $$sel;
1355       }
1356       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1357         $sel = $$sel->[0];
1358       }
1359
1360       $self->throw_exception(
1361         'Result collapse not possible - selection from a has_many source redirected to the main object'
1362       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1363     }
1364   }
1365
1366   # hotspot - skip the setter
1367   my $res_class = $self->_result_class;
1368
1369   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1370     $res_class->can ('inflate_result')
1371       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1372   };
1373
1374   my $infmap = $attrs->{as};
1375
1376   $self->{_result_inflator}{is_core_row} = ( (
1377     $inflator_cref
1378       ==
1379     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1380   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1381
1382   $self->{_result_inflator}{is_hri} = ( (
1383     ! $self->{_result_inflator}{is_core_row}
1384       and
1385     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1386   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1387
1388
1389   if ($attrs->{_simple_passthrough_construction}) {
1390     # construct a much simpler array->hash folder for the one-table HRI cases right here
1391     if ($self->{_result_inflator}{is_hri}) {
1392       for my $r (@$rows) {
1393         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1394       }
1395     }
1396     # FIXME SUBOPTIMAL this is a very very very hot spot
1397     # while rather optimal we can *still* do much better, by
1398     # building a smarter Row::inflate_result(), and
1399     # switch to feeding it data via a much leaner interface
1400     #
1401     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1402     # this particular resultset size
1403     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1404       for my $r (@$rows) {
1405         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1406       }
1407     }
1408     else {
1409       eval sprintf (
1410         ( $self->{_result_inflator}{is_core_row}
1411           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1412           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1413           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1414         ),
1415         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1416       );
1417     }
1418   }
1419   else {
1420     my $parser_type =
1421         $self->{_result_inflator}{is_hri}       ? 'hri'
1422       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1423       :                                           'classic_nonpruning'
1424     ;
1425
1426     # $args and $attrs to _mk_row_parser are separated to delineate what is
1427     # core collapser stuff and what is dbic $rs specific
1428     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1429       eval => 1,
1430       inflate_map => $infmap,
1431       collapse => $attrs->{collapse},
1432       premultiplied => $attrs->{_main_source_premultiplied},
1433       hri_style => $self->{_result_inflator}{is_hri},
1434       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1435     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1436
1437     # column_info metadata historically hasn't been too reliable.
1438     # We need to start fixing this somehow (the collapse resolver
1439     # can't work without it). Add an explicit check for the *main*
1440     # result, hopefully this will gradually weed out such errors
1441     #
1442     # FIXME - this is a temporary kludge that reduces performance
1443     # It is however necessary for the time being
1444     my ($unrolled_non_null_cols_to_check, $err);
1445
1446     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1447
1448       $err =
1449         'Collapse aborted due to invalid ResultSource metadata - the following '
1450       . 'selections are declared non-nullable but NULLs were retrieved: '
1451       ;
1452
1453       my @violating_idx;
1454       COL: for my $i (@$check_non_null_cols) {
1455         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1456       }
1457
1458       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1459         if @violating_idx;
1460
1461       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1462
1463       utf8::upgrade($unrolled_non_null_cols_to_check)
1464         if DBIx::Class::_ENV_::STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE;
1465     }
1466
1467     my $next_cref =
1468       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1469     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1470 sub {
1471   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1472   my @r = $cursor->next or return;
1473   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1474     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1475   }
1476   \@r
1477 }
1478 EOS
1479     : sub {
1480         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1481         my @r = $cursor->next or return;
1482         \@r
1483       }
1484     ;
1485
1486     $self->{_row_parser}{$parser_type}{cref}->(
1487       $rows,
1488       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1489     );
1490
1491     # simple in-place substitution, does not regrow $rows
1492     if ($self->{_result_inflator}{is_core_row}) {
1493       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1494     }
1495     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1496     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1497       # the inflator may be a multiplier/reductor - put it in list ctx
1498       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1499     }
1500   }
1501
1502   # The @$rows check seems odd at first - why wouldn't we want to warn
1503   # regardless? The issue is things like find() etc, where the user
1504   # *knows* only one result will come back. In these cases the ->all
1505   # is not a pessimization, but rather something we actually want
1506   carp_unique(
1507     'Unable to properly collapse has_many results in iterator mode due '
1508   . 'to order criteria - performed an eager cursor slurp underneath. '
1509   . 'Consider using ->all() instead'
1510   ) if ( ! $fetch_all and @$rows > 1 );
1511
1512   return $rows;
1513 }
1514
1515 =head2 result_source
1516
1517 =over 4
1518
1519 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1520
1521 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1522
1523 =back
1524
1525 An accessor for the primary ResultSource object from which this ResultSet
1526 is derived.
1527
1528 =head2 result_class
1529
1530 =over 4
1531
1532 =item Arguments: $result_class?
1533
1534 =item Return Value: $result_class
1535
1536 =back
1537
1538 An accessor for the class to use when creating result objects. Defaults to
1539 C<< result_source->result_class >> - which in most cases is the name of the
1540 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1541
1542 Note that changing the result_class will also remove any components
1543 that were originally loaded in the source class via
1544 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1545 Any overloaded methods in the original source class will not run.
1546
1547 =cut
1548
1549 sub result_class {
1550   my ($self, $result_class) = @_;
1551   if ($result_class) {
1552
1553     # don't fire this for an object
1554     $self->ensure_class_loaded($result_class)
1555       unless ref($result_class);
1556
1557     if ($self->get_cache) {
1558       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1559     }
1560     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1561     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1562       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1563     }
1564
1565     $self->_result_class($result_class);
1566
1567     delete $self->{_result_inflator};
1568   }
1569   $self->_result_class;
1570 }
1571
1572 =head2 count
1573
1574 =over 4
1575
1576 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1577
1578 =item Return Value: $count
1579
1580 =back
1581
1582 Performs an SQL C<COUNT> with the same query as the resultset was built
1583 with to find the number of elements. Passing arguments is equivalent to
1584 C<< $rs->search ($cond, \%attrs)->count >>
1585
1586 =cut
1587
1588 sub count {
1589   my $self = shift;
1590   return $self->search(@_)->count if @_ and defined $_[0];
1591   return scalar @{ $self->get_cache } if $self->get_cache;
1592
1593   my $attrs = { %{ $self->_resolved_attrs } };
1594
1595   # this is a little optimization - it is faster to do the limit
1596   # adjustments in software, instead of a subquery
1597   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1598
1599   my $crs;
1600   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1601     $crs = $self->_count_subq_rs ($attrs);
1602   }
1603   else {
1604     $crs = $self->_count_rs ($attrs);
1605   }
1606   my $count = $crs->next;
1607
1608   $count -= $offset if $offset;
1609   $count = $rows if $rows and $rows < $count;
1610   $count = 0 if ($count < 0);
1611
1612   return $count;
1613 }
1614
1615 =head2 count_rs
1616
1617 =over 4
1618
1619 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1620
1621 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1622
1623 =back
1624
1625 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1626 This can be very handy for subqueries:
1627
1628   ->search( { amount => $some_rs->count_rs->as_query } )
1629
1630 As with regular resultsets the SQL query will be executed only after
1631 the resultset is accessed via L</next> or L</all>. That would return
1632 the same single value obtainable via L</count>.
1633
1634 =cut
1635
1636 sub count_rs {
1637   my $self = shift;
1638   return $self->search(@_)->count_rs if @_;
1639
1640   # this may look like a lack of abstraction (count() does about the same)
1641   # but in fact an _rs *must* use a subquery for the limits, as the
1642   # software based limiting can not be ported if this $rs is to be used
1643   # in a subquery itself (i.e. ->as_query)
1644   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1645     return $self->_count_subq_rs($self->{_attrs});
1646   }
1647   else {
1648     return $self->_count_rs($self->{_attrs});
1649   }
1650 }
1651
1652 #
1653 # returns a ResultSetColumn object tied to the count query
1654 #
1655 sub _count_rs {
1656   my ($self, $attrs) = @_;
1657
1658   my $rsrc = $self->result_source;
1659
1660   my $tmp_attrs = { %$attrs };
1661   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1662   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1663
1664   # overwrite the selector (supplied by the storage)
1665   $rsrc->resultset_class->new($rsrc, {
1666     %$tmp_attrs,
1667     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1668     as => 'count',
1669   })->get_column ('count');
1670 }
1671
1672 #
1673 # same as above but uses a subquery
1674 #
1675 sub _count_subq_rs {
1676   my ($self, $attrs) = @_;
1677
1678   my $rsrc = $self->result_source;
1679
1680   my $sub_attrs = { %$attrs };
1681   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1682   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1683
1684   # if we multi-prefetch we group_by something unique, as this is what we would
1685   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1686   if ( $attrs->{collapse}  ) {
1687     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1688       $rsrc->_identifying_column_set || $self->throw_exception(
1689         'Unable to construct a unique group_by criteria properly collapsing the '
1690       . 'has_many prefetch before count()'
1691       );
1692     } ]
1693   }
1694
1695   # Calculate subquery selector
1696   if (my $g = $sub_attrs->{group_by}) {
1697
1698     my $sql_maker = $rsrc->storage->sql_maker;
1699
1700     # necessary as the group_by may refer to aliased functions
1701     my $sel_index;
1702     for my $sel (@{$attrs->{select}}) {
1703       $sel_index->{$sel->{-as}} = $sel
1704         if (ref $sel eq 'HASH' and $sel->{-as});
1705     }
1706
1707     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1708     # also look for named aggregates referred in the having clause
1709     # having often contains scalarrefs - thus parse it out entirely
1710     my @parts = @$g;
1711     if ($attrs->{having}) {
1712       local $sql_maker->{having_bind};
1713       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1714       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1715       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1716         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1717         # if we don't unset it we screw up retarded but unfortunately working
1718         # 'MAX(foo.bar)' => { '>', 3 }
1719         $sql_maker->{name_sep} = '';
1720       }
1721
1722       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1723
1724       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1725       my %seen_having;
1726
1727       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1728       # and if all fails for an utterly naive quoted scalar-with-function
1729       while ($having_sql =~ /
1730         $rquote $sep $lquote (.+?) $rquote
1731           |
1732         [\s,] \w+ \. (\w+) [\s,]
1733           |
1734         [\s,] $lquote (.+?) $rquote [\s,]
1735       /gx) {
1736         my $part = $1 || $2 || $3;  # one of them matched if we got here
1737         unless ($seen_having{$part}++) {
1738           push @parts, $part;
1739         }
1740       }
1741     }
1742
1743     for (@parts) {
1744       my $colpiece = $sel_index->{$_} || $_;
1745
1746       # unqualify join-based group_by's. Arcane but possible query
1747       # also horrible horrible hack to alias a column (not a func.)
1748       # (probably need to introduce SQLA syntax)
1749       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1750         my $as = $colpiece;
1751         $as =~ s/\./__/;
1752         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1753       }
1754       push @{$sub_attrs->{select}}, $colpiece;
1755     }
1756   }
1757   else {
1758     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1759     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1760   }
1761
1762   return $rsrc->resultset_class
1763                ->new ($rsrc, $sub_attrs)
1764                 ->as_subselect_rs
1765                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1766                   ->get_column ('count');
1767 }
1768
1769
1770 =head2 count_literal
1771
1772 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1773 should only be used in that context. See L</search_literal> for further info.
1774
1775 =over 4
1776
1777 =item Arguments: $sql_fragment, @standalone_bind_values
1778
1779 =item Return Value: $count
1780
1781 =back
1782
1783 Counts the results in a literal query. Equivalent to calling L</search_literal>
1784 with the passed arguments, then L</count>.
1785
1786 =cut
1787
1788 sub count_literal { shift->search_literal(@_)->count; }
1789
1790 =head2 all
1791
1792 =over 4
1793
1794 =item Arguments: none
1795
1796 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1797
1798 =back
1799
1800 Returns all elements in the resultset.
1801
1802 =cut
1803
1804 sub all {
1805   my $self = shift;
1806   if(@_) {
1807     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1808   }
1809
1810   delete @{$self}{qw/_stashed_rows _stashed_results/};
1811
1812   if (my $c = $self->get_cache) {
1813     return @$c;
1814   }
1815
1816   $self->cursor->reset;
1817
1818   my $objs = $self->_construct_results('fetch_all') || [];
1819
1820   $self->set_cache($objs) if $self->{attrs}{cache};
1821
1822   return @$objs;
1823 }
1824
1825 =head2 reset
1826
1827 =over 4
1828
1829 =item Arguments: none
1830
1831 =item Return Value: $self
1832
1833 =back
1834
1835 Resets the resultset's cursor, so you can iterate through the elements again.
1836 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1837 another query.
1838
1839 =cut
1840
1841 sub reset {
1842   my ($self) = @_;
1843
1844   delete @{$self}{qw/_stashed_rows _stashed_results/};
1845   $self->{all_cache_position} = 0;
1846   $self->cursor->reset;
1847   return $self;
1848 }
1849
1850 =head2 first
1851
1852 =over 4
1853
1854 =item Arguments: none
1855
1856 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1857
1858 =back
1859
1860 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1861 an object for the first result (or C<undef> if the resultset is empty).
1862
1863 =cut
1864
1865 sub first {
1866   return $_[0]->reset->next;
1867 }
1868
1869
1870 # _rs_update_delete
1871 #
1872 # Determines whether and what type of subquery is required for the $rs operation.
1873 # If grouping is necessary either supplies its own, or verifies the current one
1874 # After all is done delegates to the proper storage method.
1875
1876 sub _rs_update_delete {
1877   my ($self, $op, $values) = @_;
1878
1879   my $rsrc = $self->result_source;
1880   my $storage = $rsrc->schema->storage;
1881
1882   my $attrs = { %{$self->_resolved_attrs} };
1883
1884   my $join_classifications;
1885   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1886
1887   # do we need a subquery for any reason?
1888   my $needs_subq = (
1889     defined $existing_group_by
1890       or
1891     # if {from} is unparseable wrap a subq
1892     ref($attrs->{from}) ne 'ARRAY'
1893       or
1894     # limits call for a subq
1895     $self->_has_resolved_attr(qw/rows offset/)
1896   );
1897
1898   # simplify the joinmap, so we can further decide if a subq is necessary
1899   if (!$needs_subq and @{$attrs->{from}} > 1) {
1900
1901     ($attrs->{from}, $join_classifications) =
1902       $storage->_prune_unused_joins ($attrs);
1903
1904     # any non-pruneable non-local restricting joins imply subq
1905     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1906   }
1907
1908   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1909   $needs_subq ||= (
1910     (ref $attrs->{from}[0]) ne 'HASH'
1911       or
1912     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1913   );
1914
1915   my ($cond, $guard);
1916   # do we need anything like a subquery?
1917   if (! $needs_subq) {
1918     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1919     # a condition containing 'me' or other table prefixes will not work
1920     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1921     $cond = do {
1922       my $sqla = $rsrc->storage->sql_maker;
1923       local $sqla->{_dequalify_idents} = 1;
1924       \[ $sqla->_recurse_where($self->{cond}) ];
1925     };
1926   }
1927   else {
1928     # we got this far - means it is time to wrap a subquery
1929     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1930       sprintf(
1931         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1932         $op,
1933         $rsrc->source_name,
1934       )
1935     );
1936
1937     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1938     delete $attrs->{$_} for qw/select as collapse/;
1939     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1940
1941     # this will be consumed by the pruner waaaaay down the stack
1942     $attrs->{_force_prune_multiplying_joins} = 1;
1943
1944     my $subrs = (ref $self)->new($rsrc, $attrs);
1945
1946     if (@$idcols == 1) {
1947       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1948     }
1949     elsif ($storage->_use_multicolumn_in) {
1950       # no syntax for calling this properly yet
1951       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1952       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1953         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1954         $subrs->as_query
1955       ),
1956     }
1957     else {
1958       # if all else fails - get all primary keys and operate over a ORed set
1959       # wrap in a transaction for consistency
1960       # this is where the group_by/multiplication starts to matter
1961       if (
1962         $existing_group_by
1963           or
1964         # we do not need to check pre-multipliers, since if the premulti is there, its
1965         # parent (who is multi) will be there too
1966         keys %{ $join_classifications->{multiplying} || {} }
1967       ) {
1968         # make sure if there is a supplied group_by it matches the columns compiled above
1969         # perfectly. Anything else can not be sanely executed on most databases so croak
1970         # right then and there
1971         if ($existing_group_by) {
1972           my @current_group_by = map
1973             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1974             @$existing_group_by
1975           ;
1976
1977           if (
1978             join ("\x00", sort @current_group_by)
1979               ne
1980             join ("\x00", sort @{$attrs->{columns}} )
1981           ) {
1982             $self->throw_exception (
1983               "You have just attempted a $op operation on a resultset which does group_by"
1984               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1985               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1986               . ' kind of queries. Please retry the operation with a modified group_by or'
1987               . ' without using one at all.'
1988             );
1989           }
1990         }
1991
1992         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1993       }
1994
1995       $guard = $storage->txn_scope_guard;
1996
1997       for my $row ($subrs->cursor->all) {
1998         push @$cond, { map
1999           { $idcols->[$_] => $row->[$_] }
2000           (0 .. $#$idcols)
2001         };
2002       }
2003     }
2004   }
2005
2006   my $res = $cond ? $storage->$op (
2007     $rsrc,
2008     $op eq 'update' ? $values : (),
2009     $cond,
2010   ) : '0E0';
2011
2012   $guard->commit if $guard;
2013
2014   return $res;
2015 }
2016
2017 =head2 update
2018
2019 =over 4
2020
2021 =item Arguments: \%values
2022
2023 =item Return Value: $underlying_storage_rv
2024
2025 =back
2026
2027 Sets the specified columns in the resultset to the supplied values in a
2028 single query. Note that this will not run any accessor/set_column/update
2029 triggers, nor will it update any result object instances derived from this
2030 resultset (this includes the contents of the L<resultset cache|/set_cache>
2031 if any). See L</update_all> if you need to execute any on-update
2032 triggers or cascades defined either by you or a
2033 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2034
2035 The return value is a pass through of what the underlying
2036 storage backend returned, and may vary. See L<DBI/execute> for the most
2037 common case.
2038
2039 =head3 CAVEAT
2040
2041 Note that L</update> does not process/deflate any of the values passed in.
2042 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2043 ensure manually that any value passed to this method will stringify to
2044 something the RDBMS knows how to deal with. A notable example is the
2045 handling of L<DateTime> objects, for more info see:
2046 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2047
2048 =cut
2049
2050 sub update {
2051   my ($self, $values) = @_;
2052   $self->throw_exception('Values for update must be a hash')
2053     unless ref $values eq 'HASH';
2054
2055   return $self->_rs_update_delete ('update', $values);
2056 }
2057
2058 =head2 update_all
2059
2060 =over 4
2061
2062 =item Arguments: \%values
2063
2064 =item Return Value: 1
2065
2066 =back
2067
2068 Fetches all objects and updates them one at a time via
2069 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2070 triggers, while L</update> will not.
2071
2072 =cut
2073
2074 sub update_all {
2075   my ($self, $values) = @_;
2076   $self->throw_exception('Values for update_all must be a hash')
2077     unless ref $values eq 'HASH';
2078
2079   my $guard = $self->result_source->schema->txn_scope_guard;
2080   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2081   $guard->commit;
2082   return 1;
2083 }
2084
2085 =head2 delete
2086
2087 =over 4
2088
2089 =item Arguments: none
2090
2091 =item Return Value: $underlying_storage_rv
2092
2093 =back
2094
2095 Deletes the rows matching this resultset in a single query. Note that this
2096 will not run any delete triggers, nor will it alter the
2097 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2098 derived from this resultset (this includes the contents of the
2099 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2100 execute any on-delete triggers or cascades defined either by you or a
2101 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2102
2103 The return value is a pass through of what the underlying storage backend
2104 returned, and may vary. See L<DBI/execute> for the most common case.
2105
2106 =cut
2107
2108 sub delete {
2109   my $self = shift;
2110   $self->throw_exception('delete does not accept any arguments')
2111     if @_;
2112
2113   return $self->_rs_update_delete ('delete');
2114 }
2115
2116 =head2 delete_all
2117
2118 =over 4
2119
2120 =item Arguments: none
2121
2122 =item Return Value: 1
2123
2124 =back
2125
2126 Fetches all objects and deletes them one at a time via
2127 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2128 triggers, while L</delete> will not.
2129
2130 =cut
2131
2132 sub delete_all {
2133   my $self = shift;
2134   $self->throw_exception('delete_all does not accept any arguments')
2135     if @_;
2136
2137   my $guard = $self->result_source->schema->txn_scope_guard;
2138   $_->delete for $self->all;
2139   $guard->commit;
2140   return 1;
2141 }
2142
2143 =head2 populate
2144
2145 =over 4
2146
2147 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2148
2149 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2150
2151 =back
2152
2153 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2154 arrayrefs.
2155
2156 =over
2157
2158 =item NOTE
2159
2160 The context of this method call has an important effect on what is
2161 submitted to storage. In void context data is fed directly to fastpath
2162 insertion routines provided by the underlying storage (most often
2163 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2164 L<insert|DBIx::Class::Row/insert> calls on the
2165 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2166 augmentation of these methods provided by components. For example if you
2167 are using something like L<DBIx::Class::UUIDColumns> to create primary
2168 keys for you, you will find that your PKs are empty.  In this case you
2169 will have to explicitly force scalar or list context in order to create
2170 those values.
2171
2172 =back
2173
2174 In non-void (scalar or list) context, this method is simply a wrapper
2175 for L</create>. Depending on list or scalar context either a list of
2176 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2177 containing these objects is returned.
2178
2179 When supplying data in "arrayref of arrayrefs" invocation style, the
2180 first element should be a list of column names and each subsequent
2181 element should be a data value in the earlier specified column order.
2182 For example:
2183
2184   $schema->resultset("Artist")->populate([
2185     [ qw( artistid name ) ],
2186     [ 100, 'A Formally Unknown Singer' ],
2187     [ 101, 'A singer that jumped the shark two albums ago' ],
2188     [ 102, 'An actually cool singer' ],
2189   ]);
2190
2191 For the arrayref of hashrefs style each hashref should be a structure
2192 suitable for passing to L</create>. Multi-create is also permitted with
2193 this syntax.
2194
2195   $schema->resultset("Artist")->populate([
2196      { artistid => 4, name => 'Manufactured Crap', cds => [
2197         { title => 'My First CD', year => 2006 },
2198         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2199       ],
2200      },
2201      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2202         { title => 'My parents sold me to a record company', year => 2005 },
2203         { title => 'Why Am I So Ugly?', year => 2006 },
2204         { title => 'I Got Surgery and am now Popular', year => 2007 }
2205       ],
2206      },
2207   ]);
2208
2209 If you attempt a void-context multi-create as in the example above (each
2210 Artist also has the related list of CDs), and B<do not> supply the
2211 necessary autoinc foreign key information, this method will proxy to the
2212 less efficient L</create>, and then throw the Result objects away. In this
2213 case there are obviously no benefits to using this method over L</create>.
2214
2215 =cut
2216
2217 sub populate {
2218   my $self = shift;
2219
2220   # this is naive and just a quick check
2221   # the types will need to be checked more thoroughly when the
2222   # multi-source populate gets added
2223   my $data = (
2224     ref $_[0] eq 'ARRAY'
2225       and
2226     ( @{$_[0]} or return )
2227       and
2228     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2229       and
2230     $_[0]
2231   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2232
2233   # FIXME - no cref handling
2234   # At this point assume either hashes or arrays
2235
2236   if(defined wantarray) {
2237     my (@results, $guard);
2238
2239     if (ref $data->[0] eq 'ARRAY') {
2240       # column names only, nothing to do
2241       return if @$data == 1;
2242
2243       $guard = $self->result_source->schema->storage->txn_scope_guard
2244         if @$data > 2;
2245
2246       @results = map
2247         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2248         @{$data}[1 .. $#$data]
2249       ;
2250     }
2251     else {
2252
2253       $guard = $self->result_source->schema->storage->txn_scope_guard
2254         if @$data > 1;
2255
2256       @results = map { $self->new_result($_)->insert } @$data;
2257     }
2258
2259     $guard->commit if $guard;
2260     return wantarray ? @results : \@results;
2261   }
2262
2263   # we have to deal with *possibly incomplete* related data
2264   # this means we have to walk the data structure twice
2265   # whether we want this or not
2266   # jnap, I hate you ;)
2267   my $rsrc = $self->result_source;
2268   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2269
2270   my ($colinfo, $colnames, $slices_with_rels);
2271   my $data_start = 0;
2272
2273   DATA_SLICE:
2274   for my $i (0 .. $#$data) {
2275
2276     my $current_slice_seen_rel_infos;
2277
2278 ### Determine/Supplement collists
2279 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2280     if( ref $data->[$i] eq 'ARRAY' ) {
2281
2282       # positional(!) explicit column list
2283       if ($i == 0) {
2284         # column names only, nothing to do
2285         return if @$data == 1;
2286
2287         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2288           for 0 .. $#{$data->[0]};
2289
2290         $data_start = 1;
2291
2292         next DATA_SLICE;
2293       }
2294       else {
2295         for (values %$colinfo) {
2296           if ($_->{is_rel} ||= (
2297             $rel_info->{$_->{name}}
2298               and
2299             (
2300               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2301                 or
2302               ref $data->[$i][$_->{pos}] eq 'HASH'
2303                 or
2304               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2305             )
2306               and
2307             1
2308           )) {
2309
2310             # moar sanity check... sigh
2311             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2312               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2313                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2314                 return my $throwaway = $self->populate(@_);
2315               }
2316             }
2317
2318             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2319           }
2320         }
2321       }
2322
2323      if ($current_slice_seen_rel_infos) {
2324         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2325
2326         # this is needed further down to decide whether or not to fallback to create()
2327         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2328           for 0 .. $#$colnames;
2329       }
2330     }
2331     elsif( ref $data->[$i] eq 'HASH' ) {
2332
2333       for ( sort keys %{$data->[$i]} ) {
2334
2335         $colinfo->{$_} ||= do {
2336
2337           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2338             if $data_start; # it will be 0 on AoH, 1 on AoA
2339
2340           push @$colnames, $_;
2341
2342           # RV
2343           { pos => $#$colnames, name => $_ }
2344         };
2345
2346         if ($colinfo->{$_}{is_rel} ||= (
2347           $rel_info->{$_}
2348             and
2349           (
2350             ref $data->[$i]{$_} eq 'ARRAY'
2351               or
2352             ref $data->[$i]{$_} eq 'HASH'
2353               or
2354             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2355           )
2356             and
2357           1
2358         )) {
2359
2360           # moar sanity check... sigh
2361           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2362             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2363               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2364               return my $throwaway = $self->populate(@_);
2365             }
2366           }
2367
2368           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2369         }
2370       }
2371
2372       if ($current_slice_seen_rel_infos) {
2373         push @$slices_with_rels, $data->[$i];
2374
2375         # this is needed further down to decide whether or not to fallback to create()
2376         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2377           for keys %{$data->[$i]};
2378       }
2379     }
2380     else {
2381       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2382     }
2383
2384     if ( grep
2385       { $_->{attrs}{is_depends_on} }
2386       @{ $current_slice_seen_rel_infos || [] }
2387     ) {
2388       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2389       return my $throwaway = $self->populate(@_);
2390     }
2391   }
2392
2393   if( $slices_with_rels ) {
2394
2395     # need to exclude the rel "columns"
2396     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2397
2398     # extra sanity check - ensure the main source is in fact identifiable
2399     # the localizing of nullability is insane, but oh well... the use-case is legit
2400     my $ci = $rsrc->columns_info($colnames);
2401
2402     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2403       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2404
2405     unless( $rsrc->_identifying_column_set($ci) ) {
2406       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2407       return my $throwaway = $self->populate(@_);
2408     }
2409   }
2410
2411 ### inherit the data locked in the conditions of the resultset
2412   my ($rs_data) = $self->_merge_with_rscond({});
2413   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2414
2415   # if anything left - decompose rs_data
2416   my $rs_data_vals;
2417   if (keys %$rs_data) {
2418      push @$rs_data_vals, $rs_data->{$_}
2419       for sort keys %$rs_data;
2420   }
2421
2422 ### start work
2423   my $guard;
2424   $guard = $rsrc->schema->storage->txn_scope_guard
2425     if $slices_with_rels;
2426
2427 ### main source data
2428   # FIXME - need to switch entirely to a coderef-based thing,
2429   # so that large sets aren't copied several times... I think
2430   $rsrc->storage->_insert_bulk(
2431     $rsrc,
2432     [ @$colnames, sort keys %$rs_data ],
2433     [ map {
2434       ref $data->[$_] eq 'ARRAY'
2435       ? (
2436           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2437         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2438         :                     $data->[$_]
2439       )
2440       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2441     } $data_start .. $#$data ],
2442   );
2443
2444 ### do the children relationships
2445   if ( $slices_with_rels ) {
2446     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2447       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2448
2449     for my $sl (@$slices_with_rels) {
2450
2451       my ($main_proto, $main_proto_rs);
2452       for my $rel (@rels) {
2453         next unless defined $sl->{$rel};
2454
2455         $main_proto ||= {
2456           %$rs_data,
2457           (map { $_ => $sl->{$_} } @$colnames),
2458         };
2459
2460         unless (defined $colinfo->{$rel}{rs}) {
2461
2462           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2463
2464           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2465             rel_name => $rel,
2466             self_alias => "\xFE", # irrelevant
2467             foreign_alias => "\xFF", # irrelevant
2468           )->{identity_map} || {} } };
2469
2470         }
2471
2472         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2473           {
2474             $_ => { '=' =>
2475               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2476                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2477                  ->as_query
2478             }
2479           }
2480           keys %{$colinfo->{$rel}{fk_map}}
2481         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2482
2483         1;
2484       }
2485     }
2486   }
2487
2488   $guard->commit if $guard;
2489 }
2490
2491 =head2 pager
2492
2493 =over 4
2494
2495 =item Arguments: none
2496
2497 =item Return Value: L<$pager|Data::Page>
2498
2499 =back
2500
2501 Returns a L<Data::Page> object for the current resultset. Only makes
2502 sense for queries with a C<page> attribute.
2503
2504 To get the full count of entries for a paged resultset, call
2505 C<total_entries> on the L<Data::Page> object.
2506
2507 =cut
2508
2509 sub pager {
2510   my ($self) = @_;
2511
2512   return $self->{pager} if $self->{pager};
2513
2514   my $attrs = $self->{attrs};
2515   if (!defined $attrs->{page}) {
2516     $self->throw_exception("Can't create pager for non-paged rs");
2517   }
2518   elsif ($attrs->{page} <= 0) {
2519     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2520   }
2521   $attrs->{rows} ||= 10;
2522
2523   # throw away the paging flags and re-run the count (possibly
2524   # with a subselect) to get the real total count
2525   my $count_attrs = { %$attrs };
2526   delete @{$count_attrs}{qw/rows offset page pager/};
2527
2528   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2529
2530   require DBIx::Class::ResultSet::Pager;
2531   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2532     sub { $total_rs->count },  #lazy-get the total
2533     $attrs->{rows},
2534     $self->{attrs}{page},
2535   );
2536 }
2537
2538 =head2 page
2539
2540 =over 4
2541
2542 =item Arguments: $page_number
2543
2544 =item Return Value: L<$resultset|/search>
2545
2546 =back
2547
2548 Returns a resultset for the $page_number page of the resultset on which page
2549 is called, where each page contains a number of rows equal to the 'rows'
2550 attribute set on the resultset (10 by default).
2551
2552 =cut
2553
2554 sub page {
2555   my ($self, $page) = @_;
2556   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2557 }
2558
2559 =head2 new_result
2560
2561 =over 4
2562
2563 =item Arguments: \%col_data
2564
2565 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2566
2567 =back
2568
2569 Creates a new result object in the resultset's result class and returns
2570 it. The row is not inserted into the database at this point, call
2571 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2572 will tell you whether the result object has been inserted or not.
2573
2574 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2575
2576 =cut
2577
2578 sub new_result {
2579   my ($self, $values) = @_;
2580
2581   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2582     if @_ > 2;
2583
2584   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2585     unless (ref $values eq 'HASH');
2586
2587   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2588
2589   my $new = $self->result_class->new({
2590     %$merged_cond,
2591     ( @$cols_from_relations
2592       ? (-cols_from_relations => $cols_from_relations)
2593       : ()
2594     ),
2595     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2596   });
2597
2598   if (
2599     reftype($new) eq 'HASH'
2600       and
2601     ! keys %$new
2602       and
2603     blessed($new)
2604   ) {
2605     carp_unique (sprintf (
2606       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2607       $self->result_class,
2608     ));
2609   }
2610
2611   $new;
2612 }
2613
2614 # _merge_with_rscond
2615 #
2616 # Takes a simple hash of K/V data and returns its copy merged with the
2617 # condition already present on the resultset. Additionally returns an
2618 # arrayref of value/condition names, which were inferred from related
2619 # objects (this is needed for in-memory related objects)
2620 sub _merge_with_rscond {
2621   my ($self, $data) = @_;
2622
2623   my ($implied_data, @cols_from_relations);
2624
2625   my $alias = $self->{attrs}{alias};
2626
2627   if (! defined $self->{cond}) {
2628     # just massage $data below
2629   }
2630   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2631     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2632     @cols_from_relations = keys %{ $implied_data || {} };
2633   }
2634   else {
2635     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2636     $implied_data = { map {
2637       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2638     } keys %$eqs };
2639   }
2640
2641   return (
2642     { map
2643       { %{ $self->_remove_alias($_, $alias) } }
2644       # precedence must be given to passed values over values inherited from
2645       # the cond, so the order here is important.
2646       ( $implied_data||(), $data)
2647     },
2648     \@cols_from_relations
2649   );
2650 }
2651
2652 # _has_resolved_attr
2653 #
2654 # determines if the resultset defines at least one
2655 # of the attributes supplied
2656 #
2657 # used to determine if a subquery is necessary
2658 #
2659 # supports some virtual attributes:
2660 #   -join
2661 #     This will scan for any joins being present on the resultset.
2662 #     It is not a mere key-search but a deep inspection of {from}
2663 #
2664
2665 sub _has_resolved_attr {
2666   my ($self, @attr_names) = @_;
2667
2668   my $attrs = $self->_resolved_attrs;
2669
2670   my %extra_checks;
2671
2672   for my $n (@attr_names) {
2673     if (grep { $n eq $_ } (qw/-join/) ) {
2674       $extra_checks{$n}++;
2675       next;
2676     }
2677
2678     my $attr =  $attrs->{$n};
2679
2680     next if not defined $attr;
2681
2682     if (ref $attr eq 'HASH') {
2683       return 1 if keys %$attr;
2684     }
2685     elsif (ref $attr eq 'ARRAY') {
2686       return 1 if @$attr;
2687     }
2688     else {
2689       return 1 if $attr;
2690     }
2691   }
2692
2693   # a resolved join is expressed as a multi-level from
2694   return 1 if (
2695     $extra_checks{-join}
2696       and
2697     ref $attrs->{from} eq 'ARRAY'
2698       and
2699     @{$attrs->{from}} > 1
2700   );
2701
2702   return 0;
2703 }
2704
2705 # _remove_alias
2706 #
2707 # Remove the specified alias from the specified query hash. A copy is made so
2708 # the original query is not modified.
2709
2710 sub _remove_alias {
2711   my ($self, $query, $alias) = @_;
2712
2713   my %orig = %{ $query || {} };
2714   my %unaliased;
2715
2716   foreach my $key (keys %orig) {
2717     if ($key !~ /\./) {
2718       $unaliased{$key} = $orig{$key};
2719       next;
2720     }
2721     $unaliased{$1} = $orig{$key}
2722       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2723   }
2724
2725   return \%unaliased;
2726 }
2727
2728 =head2 as_query
2729
2730 =over 4
2731
2732 =item Arguments: none
2733
2734 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2735
2736 =back
2737
2738 Returns the SQL query and bind vars associated with the invocant.
2739
2740 This is generally used as the RHS for a subquery.
2741
2742 =cut
2743
2744 sub as_query {
2745   my $self = shift;
2746
2747   my $attrs = { %{ $self->_resolved_attrs } };
2748
2749   my $aq = $self->result_source->storage->_select_args_to_query (
2750     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2751   );
2752
2753   $aq;
2754 }
2755
2756 =head2 find_or_new
2757
2758 =over 4
2759
2760 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2761
2762 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2763
2764 =back
2765
2766   my $artist = $schema->resultset('Artist')->find_or_new(
2767     { artist => 'fred' }, { key => 'artists' });
2768
2769   $cd->cd_to_producer->find_or_new({ producer => $producer },
2770                                    { key => 'primary' });
2771
2772 Find an existing record from this resultset using L</find>. if none exists,
2773 instantiate a new result object and return it. The object will not be saved
2774 into your storage until you call L<DBIx::Class::Row/insert> on it.
2775
2776 You most likely want this method when looking for existing rows using a unique
2777 constraint that is not the primary key, or looking for related rows.
2778
2779 If you want objects to be saved immediately, use L</find_or_create> instead.
2780
2781 B<Note>: Make sure to read the documentation of L</find> and understand the
2782 significance of the C<key> attribute, as its lack may skew your search, and
2783 subsequently result in spurious new objects.
2784
2785 B<Note>: Take care when using C<find_or_new> with a table having
2786 columns with default values that you intend to be automatically
2787 supplied by the database (e.g. an auto_increment primary key column).
2788 In normal usage, the value of such columns should NOT be included at
2789 all in the call to C<find_or_new>, even when set to C<undef>.
2790
2791 =cut
2792
2793 sub find_or_new {
2794   my $self     = shift;
2795   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2796   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2797   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2798     return $row;
2799   }
2800   return $self->new_result($hash);
2801 }
2802
2803 =head2 create
2804
2805 =over 4
2806
2807 =item Arguments: \%col_data
2808
2809 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2810
2811 =back
2812
2813 Attempt to create a single new row or a row with multiple related rows
2814 in the table represented by the resultset (and related tables). This
2815 will not check for duplicate rows before inserting, use
2816 L</find_or_create> to do that.
2817
2818 To create one row for this resultset, pass a hashref of key/value
2819 pairs representing the columns of the table and the values you wish to
2820 store. If the appropriate relationships are set up, foreign key fields
2821 can also be passed an object representing the foreign row, and the
2822 value will be set to its primary key.
2823
2824 To create related objects, pass a hashref of related-object column values
2825 B<keyed on the relationship name>. If the relationship is of type C<multi>
2826 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2827 The process will correctly identify columns holding foreign keys, and will
2828 transparently populate them from the keys of the corresponding relation.
2829 This can be applied recursively, and will work correctly for a structure
2830 with an arbitrary depth and width, as long as the relationships actually
2831 exists and the correct column data has been supplied.
2832
2833 Instead of hashrefs of plain related data (key/value pairs), you may
2834 also pass new or inserted objects. New objects (not inserted yet, see
2835 L</new_result>), will be inserted into their appropriate tables.
2836
2837 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2838
2839 Example of creating a new row.
2840
2841   $person_rs->create({
2842     name=>"Some Person",
2843     email=>"somebody@someplace.com"
2844   });
2845
2846 Example of creating a new row and also creating rows in a related C<has_many>
2847 or C<has_one> resultset.  Note Arrayref.
2848
2849   $artist_rs->create(
2850      { artistid => 4, name => 'Manufactured Crap', cds => [
2851         { title => 'My First CD', year => 2006 },
2852         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2853       ],
2854      },
2855   );
2856
2857 Example of creating a new row and also creating a row in a related
2858 C<belongs_to> resultset. Note Hashref.
2859
2860   $cd_rs->create({
2861     title=>"Music for Silly Walks",
2862     year=>2000,
2863     artist => {
2864       name=>"Silly Musician",
2865     }
2866   });
2867
2868 =over
2869
2870 =item WARNING
2871
2872 When subclassing ResultSet never attempt to override this method. Since
2873 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2874 lot of the internals simply never call it, so your override will be
2875 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2876 or L<DBIx::Class::Row/insert> depending on how early in the
2877 L</create> process you need to intervene. See also warning pertaining to
2878 L</new>.
2879
2880 =back
2881
2882 =cut
2883
2884 sub create {
2885   #my ($self, $col_data) = @_;
2886   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2887   return shift->new_result(shift)->insert;
2888 }
2889
2890 =head2 find_or_create
2891
2892 =over 4
2893
2894 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2895
2896 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2897
2898 =back
2899
2900   $cd->cd_to_producer->find_or_create({ producer => $producer },
2901                                       { key => 'primary' });
2902
2903 Tries to find a record based on its primary key or unique constraints; if none
2904 is found, creates one and returns that instead.
2905
2906   my $cd = $schema->resultset('CD')->find_or_create({
2907     cdid   => 5,
2908     artist => 'Massive Attack',
2909     title  => 'Mezzanine',
2910     year   => 2005,
2911   });
2912
2913 Also takes an optional C<key> attribute, to search by a specific key or unique
2914 constraint. For example:
2915
2916   my $cd = $schema->resultset('CD')->find_or_create(
2917     {
2918       artist => 'Massive Attack',
2919       title  => 'Mezzanine',
2920     },
2921     { key => 'cd_artist_title' }
2922   );
2923
2924 B<Note>: Make sure to read the documentation of L</find> and understand the
2925 significance of the C<key> attribute, as its lack may skew your search, and
2926 subsequently result in spurious row creation.
2927
2928 B<Note>: Because find_or_create() reads from the database and then
2929 possibly inserts based on the result, this method is subject to a race
2930 condition. Another process could create a record in the table after
2931 the find has completed and before the create has started. To avoid
2932 this problem, use find_or_create() inside a transaction.
2933
2934 B<Note>: Take care when using C<find_or_create> with a table having
2935 columns with default values that you intend to be automatically
2936 supplied by the database (e.g. an auto_increment primary key column).
2937 In normal usage, the value of such columns should NOT be included at
2938 all in the call to C<find_or_create>, even when set to C<undef>.
2939
2940 See also L</find> and L</update_or_create>. For information on how to declare
2941 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2942
2943 If you need to know if an existing row was found or a new one created use
2944 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2945 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2946 database!
2947
2948   my $cd = $schema->resultset('CD')->find_or_new({
2949     cdid   => 5,
2950     artist => 'Massive Attack',
2951     title  => 'Mezzanine',
2952     year   => 2005,
2953   });
2954
2955   if( !$cd->in_storage ) {
2956       # do some stuff
2957       $cd->insert;
2958   }
2959
2960 =cut
2961
2962 sub find_or_create {
2963   my $self     = shift;
2964   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2965   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2966   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2967     return $row;
2968   }
2969   return $self->new_result($hash)->insert;
2970 }
2971
2972 =head2 update_or_create
2973
2974 =over 4
2975
2976 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2977
2978 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2979
2980 =back
2981
2982   $resultset->update_or_create({ col => $val, ... });
2983
2984 Like L</find_or_create>, but if a row is found it is immediately updated via
2985 C<< $found_row->update (\%col_data) >>.
2986
2987
2988 Takes an optional C<key> attribute to search on a specific unique constraint.
2989 For example:
2990
2991   # In your application
2992   my $cd = $schema->resultset('CD')->update_or_create(
2993     {
2994       artist => 'Massive Attack',
2995       title  => 'Mezzanine',
2996       year   => 1998,
2997     },
2998     { key => 'cd_artist_title' }
2999   );
3000
3001   $cd->cd_to_producer->update_or_create({
3002     producer => $producer,
3003     name => 'harry',
3004   }, {
3005     key => 'primary',
3006   });
3007
3008 B<Note>: Make sure to read the documentation of L</find> and understand the
3009 significance of the C<key> attribute, as its lack may skew your search, and
3010 subsequently result in spurious row creation.
3011
3012 B<Note>: Take care when using C<update_or_create> with a table having
3013 columns with default values that you intend to be automatically
3014 supplied by the database (e.g. an auto_increment primary key column).
3015 In normal usage, the value of such columns should NOT be included at
3016 all in the call to C<update_or_create>, even when set to C<undef>.
3017
3018 See also L</find> and L</find_or_create>. For information on how to declare
3019 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3020
3021 If you need to know if an existing row was updated or a new one created use
3022 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3023 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3024 database!
3025
3026 =cut
3027
3028 sub update_or_create {
3029   my $self = shift;
3030   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3031   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3032
3033   my $row = $self->find($cond, $attrs);
3034   if (defined $row) {
3035     $row->update($cond);
3036     return $row;
3037   }
3038
3039   return $self->new_result($cond)->insert;
3040 }
3041
3042 =head2 update_or_new
3043
3044 =over 4
3045
3046 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3047
3048 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3049
3050 =back
3051
3052   $resultset->update_or_new({ col => $val, ... });
3053
3054 Like L</find_or_new> but if a row is found it is immediately updated via
3055 C<< $found_row->update (\%col_data) >>.
3056
3057 For example:
3058
3059   # In your application
3060   my $cd = $schema->resultset('CD')->update_or_new(
3061     {
3062       artist => 'Massive Attack',
3063       title  => 'Mezzanine',
3064       year   => 1998,
3065     },
3066     { key => 'cd_artist_title' }
3067   );
3068
3069   if ($cd->in_storage) {
3070       # the cd was updated
3071   }
3072   else {
3073       # the cd is not yet in the database, let's insert it
3074       $cd->insert;
3075   }
3076
3077 B<Note>: Make sure to read the documentation of L</find> and understand the
3078 significance of the C<key> attribute, as its lack may skew your search, and
3079 subsequently result in spurious new objects.
3080
3081 B<Note>: Take care when using C<update_or_new> with a table having
3082 columns with default values that you intend to be automatically
3083 supplied by the database (e.g. an auto_increment primary key column).
3084 In normal usage, the value of such columns should NOT be included at
3085 all in the call to C<update_or_new>, even when set to C<undef>.
3086
3087 See also L</find>, L</find_or_create> and L</find_or_new>.
3088
3089 =cut
3090
3091 sub update_or_new {
3092     my $self  = shift;
3093     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3094     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3095
3096     my $row = $self->find( $cond, $attrs );
3097     if ( defined $row ) {
3098         $row->update($cond);
3099         return $row;
3100     }
3101
3102     return $self->new_result($cond);
3103 }
3104
3105 =head2 get_cache
3106
3107 =over 4
3108
3109 =item Arguments: none
3110
3111 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3112
3113 =back
3114
3115 Gets the contents of the cache for the resultset, if the cache is set.
3116
3117 The cache is populated either by using the L</prefetch> attribute to
3118 L</search> or by calling L</set_cache>.
3119
3120 =cut
3121
3122 sub get_cache {
3123   shift->{all_cache};
3124 }
3125
3126 =head2 set_cache
3127
3128 =over 4
3129
3130 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3131
3132 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3133
3134 =back
3135
3136 Sets the contents of the cache for the resultset. Expects an arrayref
3137 of objects of the same class as those produced by the resultset. Note that
3138 if the cache is set, the resultset will return the cached objects rather
3139 than re-querying the database even if the cache attr is not set.
3140
3141 The contents of the cache can also be populated by using the
3142 L</prefetch> attribute to L</search>.
3143
3144 =cut
3145
3146 sub set_cache {
3147   my ( $self, $data ) = @_;
3148   $self->throw_exception("set_cache requires an arrayref")
3149       if defined($data) && (ref $data ne 'ARRAY');
3150   $self->{all_cache} = $data;
3151 }
3152
3153 =head2 clear_cache
3154
3155 =over 4
3156
3157 =item Arguments: none
3158
3159 =item Return Value: undef
3160
3161 =back
3162
3163 Clears the cache for the resultset.
3164
3165 =cut
3166
3167 sub clear_cache {
3168   shift->set_cache(undef);
3169 }
3170
3171 =head2 is_paged
3172
3173 =over 4
3174
3175 =item Arguments: none
3176
3177 =item Return Value: true, if the resultset has been paginated
3178
3179 =back
3180
3181 =cut
3182
3183 sub is_paged {
3184   my ($self) = @_;
3185   return !!$self->{attrs}{page};
3186 }
3187
3188 =head2 is_ordered
3189
3190 =over 4
3191
3192 =item Arguments: none
3193
3194 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3195
3196 =back
3197
3198 =cut
3199
3200 sub is_ordered {
3201   my ($self) = @_;
3202   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3203 }
3204
3205 =head2 related_resultset
3206
3207 =over 4
3208
3209 =item Arguments: $rel_name
3210
3211 =item Return Value: L<$resultset|/search>
3212
3213 =back
3214
3215 Returns a related resultset for the supplied relationship name.
3216
3217   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3218
3219 =cut
3220
3221 sub related_resultset {
3222   $_[0]->throw_exception(
3223     'Extra arguments to $rs->related_resultset() were always quietly '
3224   . 'discarded without consideration, you need to switch to '
3225   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3226   ) if @_ > 2;
3227
3228   return $_[0]->{related_resultsets}{$_[1]}
3229     if defined $_[0]->{related_resultsets}{$_[1]};
3230
3231   my ($self, $rel) = @_;
3232
3233   return $self->{related_resultsets}{$rel} = do {
3234     my $rsrc = $self->result_source;
3235     my $rel_info = $rsrc->relationship_info($rel);
3236
3237     $self->throw_exception(
3238       "search_related: result source '" . $rsrc->source_name .
3239         "' has no such relationship $rel")
3240       unless $rel_info;
3241
3242     my $attrs = $self->_chain_relationship($rel);
3243
3244     my $storage = $rsrc->schema->storage;
3245
3246     # Previously this atribute was deleted (instead of being set as it is now)
3247     # Doing so seems to be harmless in all available test permutations
3248     # See also 01d59a6a6 and mst's comment below
3249     #
3250     $attrs->{alias} = $storage->relname_to_table_alias(
3251       $rel,
3252       $attrs->{seen_join}{$rel}
3253     );
3254
3255     # since this is search_related, and we already slid the select window inwards
3256     # (the select/as attrs were deleted in the beginning), we need to flip all
3257     # left joins to inner, so we get the expected results
3258     # read the comment on top of the actual function to see what this does
3259     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3260
3261     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3262     delete $attrs->{result_class};
3263
3264     my $new = do {
3265
3266       # The reason we do this now instead of passing the alias to the
3267       # search_rs below is that if you wrap/overload resultset on the
3268       # source you need to know what alias it's -going- to have for things
3269       # to work sanely (e.g. RestrictWithObject wants to be able to add
3270       # extra query restrictions, and these may need to be $alias.)
3271       #                                       -- mst ~ 2007 (01d59a6a6)
3272       #
3273       # FIXME - this seems to be no longer neccessary (perhaps due to the
3274       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3275       # dependent (as of Jun 2015 ) does not yield any difference with or
3276       # without this line. Nevertheless keep it as is for now, to minimize
3277       # churn, there is enough potential for breakage in 0.0829xx as it is
3278       #                                       -- ribasushi Jun 2015
3279       #
3280       my $rel_source = $rsrc->related_source($rel);
3281       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3282
3283       $rel_source->resultset->search_rs( undef, $attrs );
3284     };
3285
3286     if (my $cache = $self->get_cache) {
3287       my @related_cache = map
3288         { $_->related_resultset($rel)->get_cache || () }
3289         @$cache
3290       ;
3291
3292       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3293     }
3294
3295     $new;
3296   };
3297 }
3298
3299 =head2 current_source_alias
3300
3301 =over 4
3302
3303 =item Arguments: none
3304
3305 =item Return Value: $source_alias
3306
3307 =back
3308
3309 Returns the current table alias for the result source this resultset is built
3310 on, that will be used in the SQL query. Usually it is C<me>.
3311
3312 Currently the source alias that refers to the result set returned by a
3313 L</search>/L</find> family method depends on how you got to the resultset: it's
3314 C<me> by default, but eg. L</search_related> aliases it to the related result
3315 source name (and keeps C<me> referring to the original result set). The long
3316 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3317 (and make this method unnecessary).
3318
3319 Thus it's currently necessary to use this method in predefined queries (see
3320 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3321 source alias of the current result set:
3322
3323   # in a result set class
3324   sub modified_by {
3325     my ($self, $user) = @_;
3326
3327     my $me = $self->current_source_alias;
3328
3329     return $self->search({
3330       "$me.modified" => $user->id,
3331     });
3332   }
3333
3334 The alias of L<newly created resultsets|/search> can be altered by the
3335 L<alias attribute|/alias>.
3336
3337 =cut
3338
3339 sub current_source_alias {
3340   return (shift->{attrs} || {})->{alias} || 'me';
3341 }
3342
3343 =head2 as_subselect_rs
3344
3345 =over 4
3346
3347 =item Arguments: none
3348
3349 =item Return Value: L<$resultset|/search>
3350
3351 =back
3352
3353 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3354 "virtual view" by including it as a subquery within the from clause.  From this
3355 point on, any joined tables are inaccessible to ->search on the resultset (as if
3356 it were simply where-filtered without joins).  For example:
3357
3358  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3359
3360  # 'x' now pollutes the query namespace
3361
3362  # So the following works as expected
3363  my $ok_rs = $rs->search({'x.other' => 1});
3364
3365  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3366  # def) we look for one row with contradictory terms and join in another table
3367  # (aliased 'x_2') which we never use
3368  my $broken_rs = $rs->search({'x.name' => 'def'});
3369
3370  my $rs2 = $rs->as_subselect_rs;
3371
3372  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3373  my $not_joined_rs = $rs2->search({'x.other' => 1});
3374
3375  # works as expected: finds a 'table' row related to two x rows (abc and def)
3376  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3377
3378 Another example of when one might use this would be to select a subset of
3379 columns in a group by clause:
3380
3381  my $rs = $schema->resultset('Bar')->search(undef, {
3382    group_by => [qw{ id foo_id baz_id }],
3383  })->as_subselect_rs->search(undef, {
3384    columns => [qw{ id foo_id }]
3385  });
3386
3387 In the above example normally columns would have to be equal to the group by,
3388 but because we isolated the group by into a subselect the above works.
3389
3390 =cut
3391
3392 sub as_subselect_rs {
3393   my $self = shift;
3394
3395   my $attrs = $self->_resolved_attrs;
3396
3397   my $fresh_rs = (ref $self)->new (
3398     $self->result_source
3399   );
3400
3401   # these pieces will be locked in the subquery
3402   delete $fresh_rs->{cond};
3403   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3404
3405   return $fresh_rs->search( {}, {
3406     from => [{
3407       $attrs->{alias} => $self->as_query,
3408       -alias  => $attrs->{alias},
3409       -rsrc   => $self->result_source,
3410     }],
3411     alias => $attrs->{alias},
3412   });
3413 }
3414
3415 # This code is called by search_related, and makes sure there
3416 # is clear separation between the joins before, during, and
3417 # after the relationship. This information is needed later
3418 # in order to properly resolve prefetch aliases (any alias
3419 # with a relation_chain_depth less than the depth of the
3420 # current prefetch is not considered)
3421 #
3422 # The increments happen twice per join. An even number means a
3423 # relationship specified via a search_related, whereas an odd
3424 # number indicates a join/prefetch added via attributes
3425 #
3426 # Also this code will wrap the current resultset (the one we
3427 # chain to) in a subselect IFF it contains limiting attributes
3428 sub _chain_relationship {
3429   my ($self, $rel) = @_;
3430   my $source = $self->result_source;
3431   my $attrs = { %{$self->{attrs}||{}} };
3432
3433   # we need to take the prefetch the attrs into account before we
3434   # ->_resolve_join as otherwise they get lost - captainL
3435   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3436
3437   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3438
3439   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3440
3441   my $from;
3442   my @force_subq_attrs = qw/offset rows group_by having/;
3443
3444   if (
3445     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3446       ||
3447     $self->_has_resolved_attr (@force_subq_attrs)
3448   ) {
3449     # Nuke the prefetch (if any) before the new $rs attrs
3450     # are resolved (prefetch is useless - we are wrapping
3451     # a subquery anyway).
3452     my $rs_copy = $self->search;
3453     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3454       $rs_copy->{attrs}{join},
3455       delete $rs_copy->{attrs}{prefetch},
3456     );
3457
3458     $from = [{
3459       -rsrc   => $source,
3460       -alias  => $attrs->{alias},
3461       $attrs->{alias} => $rs_copy->as_query,
3462     }];
3463     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3464     $seen->{-relation_chain_depth} = 0;
3465   }
3466   elsif ($attrs->{from}) {  #shallow copy suffices
3467     $from = [ @{$attrs->{from}} ];
3468   }
3469   else {
3470     $from = [{
3471       -rsrc  => $source,
3472       -alias => $attrs->{alias},
3473       $attrs->{alias} => $source->from,
3474     }];
3475   }
3476
3477   my $jpath = ($seen->{-relation_chain_depth})
3478     ? $from->[-1][0]{-join_path}
3479     : [];
3480
3481   my @requested_joins = $source->_resolve_join(
3482     $join,
3483     $attrs->{alias},
3484     $seen,
3485     $jpath,
3486   );
3487
3488   push @$from, @requested_joins;
3489
3490   $seen->{-relation_chain_depth}++;
3491
3492   # if $self already had a join/prefetch specified on it, the requested
3493   # $rel might very well be already included. What we do in this case
3494   # is effectively a no-op (except that we bump up the chain_depth on
3495   # the join in question so we could tell it *is* the search_related)
3496   my $already_joined;
3497
3498   # we consider the last one thus reverse
3499   for my $j (reverse @requested_joins) {
3500     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3501     if ($rel eq $last_j) {
3502       $j->[0]{-relation_chain_depth}++;
3503       $already_joined++;
3504       last;
3505     }
3506   }
3507
3508   unless ($already_joined) {
3509     push @$from, $source->_resolve_join(
3510       $rel,
3511       $attrs->{alias},
3512       $seen,
3513       $jpath,
3514     );
3515   }
3516
3517   $seen->{-relation_chain_depth}++;
3518
3519   return {%$attrs, from => $from, seen_join => $seen};
3520 }
3521
3522 sub _resolved_attrs {
3523   my $self = shift;
3524   return $self->{_attrs} if $self->{_attrs};
3525
3526   my $attrs  = { %{ $self->{attrs} || {} } };
3527   my $source = $attrs->{result_source} = $self->result_source;
3528   my $alias  = $attrs->{alias};
3529
3530   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3531     if $attrs->{collapse} and $attrs->{distinct};
3532
3533
3534   # Sanity check the paging attributes
3535   # SQLMaker does it too, but in case of a software_limit we'll never get there
3536   if (defined $attrs->{offset}) {
3537     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3538       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3539   }
3540   if (defined $attrs->{rows}) {
3541     $self->throw_exception("The rows attribute must be a positive integer if present")
3542       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3543   }
3544
3545
3546   # default selection list
3547   $attrs->{columns} = [ $source->columns ]
3548     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3549
3550   # merge selectors together
3551   for (qw/columns select as/) {
3552     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3553       if $attrs->{$_} or $attrs->{"+$_"};
3554   }
3555
3556   # disassemble columns
3557   my (@sel, @as);
3558   if (my $cols = delete $attrs->{columns}) {
3559     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3560       if (ref $c eq 'HASH') {
3561         for my $as (sort keys %$c) {
3562           push @sel, $c->{$as};
3563           push @as, $as;
3564         }
3565       }
3566       else {
3567         push @sel, $c;
3568         push @as, $c;
3569       }
3570     }
3571   }
3572
3573   # when trying to weed off duplicates later do not go past this point -
3574   # everything added from here on is unbalanced "anyone's guess" stuff
3575   my $dedup_stop_idx = $#as;
3576
3577   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3578     if $attrs->{as};
3579   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3580     if $attrs->{select};
3581
3582   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3583   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3584
3585   # disqualify all $alias.col as-bits (inflate-map mandated)
3586   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3587
3588   # de-duplicate the result (remove *identical* select/as pairs)
3589   # and also die on duplicate {as} pointing to different {select}s
3590   # not using a c-style for as the condition is prone to shrinkage
3591   my $seen;
3592   my $i = 0;
3593   while ($i <= $dedup_stop_idx) {
3594     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3595       splice @sel, $i, 1;
3596       splice @as, $i, 1;
3597       $dedup_stop_idx--;
3598     }
3599     elsif ($seen->{$as[$i]}++) {
3600       $self->throw_exception(
3601         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3602       );
3603     }
3604     else {
3605       $i++;
3606     }
3607   }
3608
3609   $attrs->{select} = \@sel;
3610   $attrs->{as} = \@as;
3611
3612   $attrs->{from} ||= [{
3613     -rsrc   => $source,
3614     -alias  => $self->{attrs}{alias},
3615     $self->{attrs}{alias} => $source->from,
3616   }];
3617
3618   if ( $attrs->{join} || $attrs->{prefetch} ) {
3619
3620     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3621       if ref $attrs->{from} ne 'ARRAY';
3622
3623     my $join = (delete $attrs->{join}) || {};
3624
3625     if ( defined $attrs->{prefetch} ) {
3626       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3627     }
3628
3629     $attrs->{from} =    # have to copy here to avoid corrupting the original
3630       [
3631         @{ $attrs->{from} },
3632         $source->_resolve_join(
3633           $join,
3634           $alias,
3635           { %{ $attrs->{seen_join} || {} } },
3636           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3637             ? $attrs->{from}[-1][0]{-join_path}
3638             : []
3639           ,
3640         )
3641       ];
3642   }
3643
3644
3645   for my $attr (qw(order_by group_by)) {
3646
3647     if ( defined $attrs->{$attr} ) {
3648       $attrs->{$attr} = (
3649         ref( $attrs->{$attr} ) eq 'ARRAY'
3650         ? [ @{ $attrs->{$attr} } ]
3651         : [ $attrs->{$attr} || () ]
3652       );
3653
3654       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3655     }
3656   }
3657
3658
3659   # set collapse default based on presence of prefetch
3660   my $prefetch;
3661   if (
3662     defined $attrs->{prefetch}
3663       and
3664     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3665   ) {
3666     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3667       if defined $attrs->{collapse} and ! $attrs->{collapse};
3668
3669     $attrs->{collapse} = 1;
3670   }
3671
3672
3673   # run through the resulting joinstructure (starting from our current slot)
3674   # and unset collapse if proven unnecessary
3675   #
3676   # also while we are at it find out if the current root source has
3677   # been premultiplied by previous related_source chaining
3678   #
3679   # this allows to predict whether a root object with all other relation
3680   # data set to NULL is in fact unique
3681   if ($attrs->{collapse}) {
3682
3683     if (ref $attrs->{from} eq 'ARRAY') {
3684
3685       if (@{$attrs->{from}} == 1) {
3686         # no joins - no collapse
3687         $attrs->{collapse} = 0;
3688       }
3689       else {
3690         # find where our table-spec starts
3691         my @fromlist = @{$attrs->{from}};
3692         while (@fromlist) {
3693           my $t = shift @fromlist;
3694
3695           my $is_multi;
3696           # me vs join from-spec distinction - a ref means non-root
3697           if (ref $t eq 'ARRAY') {
3698             $t = $t->[0];
3699             $is_multi ||= ! $t->{-is_single};
3700           }
3701           last if ($t->{-alias} && $t->{-alias} eq $alias);
3702           $attrs->{_main_source_premultiplied} ||= $is_multi;
3703         }
3704
3705         # no non-singles remaining, nor any premultiplication - nothing to collapse
3706         if (
3707           ! $attrs->{_main_source_premultiplied}
3708             and
3709           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3710         ) {
3711           $attrs->{collapse} = 0;
3712         }
3713       }
3714     }
3715
3716     else {
3717       # if we can not analyze the from - err on the side of safety
3718       $attrs->{_main_source_premultiplied} = 1;
3719     }
3720   }
3721
3722
3723   # generate the distinct induced group_by before injecting the prefetched select/as parts
3724   if (delete $attrs->{distinct}) {
3725     if ($attrs->{group_by}) {
3726       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3727     }
3728     else {
3729       $attrs->{_grouped_by_distinct} = 1;
3730       # distinct affects only the main selection part, not what prefetch may add below
3731       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3732
3733       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3734       # The thinking is: if we are collapsing the subquerying prefetch engine will
3735       # rip stuff apart for us anyway, and we do not want to have a potentially
3736       # function-converted external order_by
3737       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3738       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3739     }
3740   }
3741
3742
3743   # generate selections based on the prefetch helper
3744   if ($prefetch) {
3745
3746     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3747       if $attrs->{_dark_selector};
3748
3749     # this is a separate structure (we don't look in {from} directly)
3750     # as the resolver needs to shift things off the lists to work
3751     # properly (identical-prefetches on different branches)
3752     my $joined_node_aliases_map = {};
3753     if (ref $attrs->{from} eq 'ARRAY') {
3754
3755       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3756
3757       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3758         next unless $j->[0]{-alias};
3759         next unless $j->[0]{-join_path};
3760         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3761
3762         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3763
3764         my $p = $joined_node_aliases_map;
3765         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3766         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3767       }
3768     }
3769
3770     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3771       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3772   }
3773
3774
3775   $attrs->{_simple_passthrough_construction} = !(
3776     $attrs->{collapse}
3777       or
3778     grep { $_ =~ /\./ } @{$attrs->{as}}
3779   );
3780
3781
3782   # if both page and offset are specified, produce a combined offset
3783   # even though it doesn't make much sense, this is what pre 081xx has
3784   # been doing
3785   if (my $page = delete $attrs->{page}) {
3786     $attrs->{offset} =
3787       ($attrs->{rows} * ($page - 1))
3788             +
3789       ($attrs->{offset} || 0)
3790     ;
3791   }
3792
3793   return $self->{_attrs} = $attrs;
3794 }
3795
3796 sub _rollout_attr {
3797   my ($self, $attr) = @_;
3798
3799   if (ref $attr eq 'HASH') {
3800     return $self->_rollout_hash($attr);
3801   } elsif (ref $attr eq 'ARRAY') {
3802     return $self->_rollout_array($attr);
3803   } else {
3804     return [$attr];
3805   }
3806 }
3807
3808 sub _rollout_array {
3809   my ($self, $attr) = @_;
3810
3811   my @rolled_array;
3812   foreach my $element (@{$attr}) {
3813     if (ref $element eq 'HASH') {
3814       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3815     } elsif (ref $element eq 'ARRAY') {
3816       #  XXX - should probably recurse here
3817       push( @rolled_array, @{$self->_rollout_array($element)} );
3818     } else {
3819       push( @rolled_array, $element );
3820     }
3821   }
3822   return \@rolled_array;
3823 }
3824
3825 sub _rollout_hash {
3826   my ($self, $attr) = @_;
3827
3828   my @rolled_array;
3829   foreach my $key (keys %{$attr}) {
3830     push( @rolled_array, { $key => $attr->{$key} } );
3831   }
3832   return \@rolled_array;
3833 }
3834
3835 sub _calculate_score {
3836   my ($self, $a, $b) = @_;
3837
3838   if (defined $a xor defined $b) {
3839     return 0;
3840   }
3841   elsif (not defined $a) {
3842     return 1;
3843   }
3844
3845   if (ref $b eq 'HASH') {
3846     my ($b_key) = keys %{$b};
3847     $b_key = '' if ! defined $b_key;
3848     if (ref $a eq 'HASH') {
3849       my ($a_key) = keys %{$a};
3850       $a_key = '' if ! defined $a_key;
3851       if ($a_key eq $b_key) {
3852         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3853       } else {
3854         return 0;
3855       }
3856     } else {
3857       return ($a eq $b_key) ? 1 : 0;
3858     }
3859   } else {
3860     if (ref $a eq 'HASH') {
3861       my ($a_key) = keys %{$a};
3862       return ($b eq $a_key) ? 1 : 0;
3863     } else {
3864       return ($b eq $a) ? 1 : 0;
3865     }
3866   }
3867 }
3868
3869 sub _merge_joinpref_attr {
3870   my ($self, $orig, $import) = @_;
3871
3872   return $import unless defined($orig);
3873   return $orig unless defined($import);
3874
3875   $orig = $self->_rollout_attr($orig);
3876   $import = $self->_rollout_attr($import);
3877
3878   my $seen_keys;
3879   foreach my $import_element ( @{$import} ) {
3880     # find best candidate from $orig to merge $b_element into
3881     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3882     foreach my $orig_element ( @{$orig} ) {
3883       my $score = $self->_calculate_score( $orig_element, $import_element );
3884       if ($score > $best_candidate->{score}) {
3885         $best_candidate->{position} = $position;
3886         $best_candidate->{score} = $score;
3887       }
3888       $position++;
3889     }
3890     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3891     $import_key = '' if not defined $import_key;
3892
3893     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3894       push( @{$orig}, $import_element );
3895     } else {
3896       my $orig_best = $orig->[$best_candidate->{position}];
3897       # merge orig_best and b_element together and replace original with merged
3898       if (ref $orig_best ne 'HASH') {
3899         $orig->[$best_candidate->{position}] = $import_element;
3900       } elsif (ref $import_element eq 'HASH') {
3901         my ($key) = keys %{$orig_best};
3902         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3903       }
3904     }
3905     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3906   }
3907
3908   return @$orig ? $orig : ();
3909 }
3910
3911 {
3912   my $hm;
3913
3914   sub _merge_attr {
3915     $hm ||= do {
3916       require Hash::Merge;
3917       my $hm = Hash::Merge->new;
3918
3919       $hm->specify_behavior({
3920         SCALAR => {
3921           SCALAR => sub {
3922             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3923
3924             if ($defl xor $defr) {
3925               return [ $defl ? $_[0] : $_[1] ];
3926             }
3927             elsif (! $defl) {
3928               return [];
3929             }
3930             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3931               return [ $_[0] ];
3932             }
3933             else {
3934               return [$_[0], $_[1]];
3935             }
3936           },
3937           ARRAY => sub {
3938             return $_[1] if !defined $_[0];
3939             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3940             return [$_[0], @{$_[1]}]
3941           },
3942           HASH  => sub {
3943             return [] if !defined $_[0] and !keys %{$_[1]};
3944             return [ $_[1] ] if !defined $_[0];
3945             return [ $_[0] ] if !keys %{$_[1]};
3946             return [$_[0], $_[1]]
3947           },
3948         },
3949         ARRAY => {
3950           SCALAR => sub {
3951             return $_[0] if !defined $_[1];
3952             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3953             return [@{$_[0]}, $_[1]]
3954           },
3955           ARRAY => sub {
3956             my @ret = @{$_[0]} or return $_[1];
3957             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3958             my %idx = map { $_ => 1 } @ret;
3959             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3960             \@ret;
3961           },
3962           HASH => sub {
3963             return [ $_[1] ] if ! @{$_[0]};
3964             return $_[0] if !keys %{$_[1]};
3965             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3966             return [ @{$_[0]}, $_[1] ];
3967           },
3968         },
3969         HASH => {
3970           SCALAR => sub {
3971             return [] if !keys %{$_[0]} and !defined $_[1];
3972             return [ $_[0] ] if !defined $_[1];
3973             return [ $_[1] ] if !keys %{$_[0]};
3974             return [$_[0], $_[1]]
3975           },
3976           ARRAY => sub {
3977             return [] if !keys %{$_[0]} and !@{$_[1]};
3978             return [ $_[0] ] if !@{$_[1]};
3979             return $_[1] if !keys %{$_[0]};
3980             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3981             return [ $_[0], @{$_[1]} ];
3982           },
3983           HASH => sub {
3984             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3985             return [ $_[0] ] if !keys %{$_[1]};
3986             return [ $_[1] ] if !keys %{$_[0]};
3987             return [ $_[0] ] if $_[0] eq $_[1];
3988             return [ $_[0], $_[1] ];
3989           },
3990         }
3991       } => 'DBIC_RS_ATTR_MERGER');
3992       $hm;
3993     };
3994
3995     return $hm->merge ($_[1], $_[2]);
3996   }
3997 }
3998
3999 sub STORABLE_freeze {
4000   my ($self, $cloning) = @_;
4001   my $to_serialize = { %$self };
4002
4003   # A cursor in progress can't be serialized (and would make little sense anyway)
4004   # the parser can be regenerated (and can't be serialized)
4005   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
4006
4007   # nor is it sensical to store a not-yet-fired-count pager
4008   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
4009     delete $to_serialize->{pager};
4010   }
4011
4012   Storable::nfreeze($to_serialize);
4013 }
4014
4015 # need this hook for symmetry
4016 sub STORABLE_thaw {
4017   my ($self, $cloning, $serialized) = @_;
4018
4019   %$self = %{ Storable::thaw($serialized) };
4020
4021   $self;
4022 }
4023
4024
4025 =head2 throw_exception
4026
4027 See L<DBIx::Class::Schema/throw_exception> for details.
4028
4029 =cut
4030
4031 sub throw_exception {
4032   my $self=shift;
4033
4034   if (ref $self and my $rsrc = $self->result_source) {
4035     $rsrc->throw_exception(@_)
4036   }
4037   else {
4038     DBIx::Class::Exception->throw(@_);
4039   }
4040 }
4041
4042 1;
4043
4044 __END__
4045
4046 # XXX: FIXME: Attributes docs need clearing up
4047
4048 =head1 ATTRIBUTES
4049
4050 Attributes are used to refine a ResultSet in various ways when
4051 searching for data. They can be passed to any method which takes an
4052 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4053 L</count>.
4054
4055 Default attributes can be set on the result class using
4056 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4057 the CAVEATS on that feature before using it!)
4058
4059 These are in no particular order:
4060
4061 =head2 order_by
4062
4063 =over 4
4064
4065 =item Value: ( $order_by | \@order_by | \%order_by )
4066
4067 =back
4068
4069 Which column(s) to order the results by.
4070
4071 [The full list of suitable values is documented in
4072 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4073 common options.]
4074
4075 If a single column name, or an arrayref of names is supplied, the
4076 argument is passed through directly to SQL. The hashref syntax allows
4077 for connection-agnostic specification of ordering direction:
4078
4079  For descending order:
4080
4081   order_by => { -desc => [qw/col1 col2 col3/] }
4082
4083  For explicit ascending order:
4084
4085   order_by => { -asc => 'col' }
4086
4087 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4088 supported, although you are strongly encouraged to use the hashref
4089 syntax as outlined above.
4090
4091 =head2 columns
4092
4093 =over 4
4094
4095 =item Value: \@columns | \%columns | $column
4096
4097 =back
4098
4099 Shortcut to request a particular set of columns to be retrieved. Each
4100 column spec may be a string (a table column name), or a hash (in which
4101 case the key is the C<as> value, and the value is used as the C<select>
4102 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4103 it and sets C<select> from that, then auto-populates C<as> from
4104 C<select> as normal. (You may also use the C<cols> attribute, as in
4105 earlier versions of DBIC, but this is deprecated)
4106
4107 Essentially C<columns> does the same as L</select> and L</as>.
4108
4109     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4110
4111 is the same as
4112
4113     select => [qw(some_column another_column)],
4114     as     => [qw(some_column dbic_slot)]
4115
4116 If you want to individually retrieve related columns (in essence perform
4117 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4118 chain such that it matches existing relationships:
4119
4120     my $rs = $schema->resultset('Artist')->search({}, {
4121         # required to tell DBIC to collapse has_many relationships
4122         collapse => 1,
4123         join     => { cds => 'tracks' },
4124         '+columns'  => {
4125           'cds.cdid'         => 'cds.cdid',
4126           'cds.tracks.title' => 'tracks.title',
4127         },
4128     });
4129
4130 Like elsewhere, literal SQL or literal values can be included by using a
4131 scalar reference or a literal bind value, and these values will be available
4132 in the result with C<get_column> (see also
4133 L<SQL::Abstract/Literal SQL and value type operators>):
4134
4135     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4136     # bind values: $true_value, $false_value
4137     columns => [
4138         {
4139             foo => \1,
4140             bar => \q{'a string'},
4141             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4142         }
4143     ]
4144
4145 =head2 +columns
4146
4147 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4148 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4149 with a unary plus operator before it, which is the same as simply C<columns>.
4150
4151 =over 4
4152
4153 =item Value: \@extra_columns
4154
4155 =back
4156
4157 Indicates additional columns to be selected from storage. Works the same as
4158 L</columns> but adds columns to the current selection. (You may also use the
4159 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4160 deprecated)
4161
4162   $schema->resultset('CD')->search(undef, {
4163     '+columns' => ['artist.name'],
4164     join => ['artist']
4165   });
4166
4167 would return all CDs and include a 'name' column to the information
4168 passed to object inflation. Note that the 'artist' is the name of the
4169 column (or relationship) accessor, and 'name' is the name of the column
4170 accessor in the related table.
4171
4172 =head2 select
4173
4174 =over 4
4175
4176 =item Value: \@select_columns
4177
4178 =back
4179
4180 Indicates which columns should be selected from the storage. You can use
4181 column names, or in the case of RDBMS back ends, function or stored procedure
4182 names:
4183
4184   $rs = $schema->resultset('Employee')->search(undef, {
4185     select => [
4186       'name',
4187       { count => 'employeeid' },
4188       { max => { length => 'name' }, -as => 'longest_name' }
4189     ]
4190   });
4191
4192   # Equivalent SQL
4193   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4194
4195 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4196 use L</select>, to instruct DBIx::Class how to store the result of the column.
4197
4198 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4199 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4200 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4201 function attribute> supplied as shown in the example above.
4202
4203 =head2 +select
4204
4205 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4206 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4207 with a unary plus operator before it, which is the same as simply C<select>.
4208
4209 =over 4
4210
4211 =item Value: \@extra_select_columns
4212
4213 =back
4214
4215 Indicates additional columns to be selected from storage.  Works the same as
4216 L</select> but adds columns to the current selection, instead of specifying
4217 a new explicit list.
4218
4219 =head2 as
4220
4221 =over 4
4222
4223 =item Value: \@inflation_names
4224
4225 =back
4226
4227 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4228 slot name in which the column value will be stored within the
4229 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4230 identifier by the C<get_column> method (or via the object accessor B<if one
4231 with the same name already exists>) as shown below.
4232
4233 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4234 aliasing C<AS>. See L</select> for details.
4235
4236   $rs = $schema->resultset('Employee')->search(undef, {
4237     select => [
4238       'name',
4239       { count => 'employeeid' },
4240       { max => { length => 'name' }, -as => 'longest_name' }
4241     ],
4242     as => [qw/
4243       name
4244       employee_count
4245       max_name_length
4246     /],
4247   });
4248
4249 If the object against which the search is performed already has an accessor
4250 matching a column name specified in C<as>, the value can be retrieved using
4251 the accessor as normal:
4252
4253   my $name = $employee->name();
4254
4255 If on the other hand an accessor does not exist in the object, you need to
4256 use C<get_column> instead:
4257
4258   my $employee_count = $employee->get_column('employee_count');
4259
4260 You can create your own accessors if required - see
4261 L<DBIx::Class::Manual::Cookbook> for details.
4262
4263 =head2 +as
4264
4265 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4266 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4267 with a unary plus operator before it, which is the same as simply C<as>.
4268
4269 =over 4
4270
4271 =item Value: \@extra_inflation_names
4272
4273 =back
4274
4275 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4276
4277 =head2 join
4278
4279 =over 4
4280
4281 =item Value: ($rel_name | \@rel_names | \%rel_names)
4282
4283 =back
4284
4285 Contains a list of relationships that should be joined for this query.  For
4286 example:
4287
4288   # Get CDs by Nine Inch Nails
4289   my $rs = $schema->resultset('CD')->search(
4290     { 'artist.name' => 'Nine Inch Nails' },
4291     { join => 'artist' }
4292   );
4293
4294 Can also contain a hash reference to refer to the other relation's relations.
4295 For example:
4296
4297   package MyApp::Schema::Track;
4298   use base qw/DBIx::Class/;
4299   __PACKAGE__->table('track');
4300   __PACKAGE__->add_columns(qw/trackid cd position title/);
4301   __PACKAGE__->set_primary_key('trackid');
4302   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4303   1;
4304
4305   # In your application
4306   my $rs = $schema->resultset('Artist')->search(
4307     { 'track.title' => 'Teardrop' },
4308     {
4309       join     => { cd => 'track' },
4310       order_by => 'artist.name',
4311     }
4312   );
4313
4314 You need to use the relationship (not the table) name in  conditions,
4315 because they are aliased as such. The current table is aliased as "me", so
4316 you need to use me.column_name in order to avoid ambiguity. For example:
4317
4318   # Get CDs from 1984 with a 'Foo' track
4319   my $rs = $schema->resultset('CD')->search(
4320     {
4321       'me.year' => 1984,
4322       'tracks.name' => 'Foo'
4323     },
4324     { join => 'tracks' }
4325   );
4326
4327 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4328 similarly for a third time). For e.g.
4329
4330   my $rs = $schema->resultset('Artist')->search({
4331     'cds.title'   => 'Down to Earth',
4332     'cds_2.title' => 'Popular',
4333   }, {
4334     join => [ qw/cds cds/ ],
4335   });
4336
4337 will return a set of all artists that have both a cd with title 'Down
4338 to Earth' and a cd with title 'Popular'.
4339
4340 If you want to fetch related objects from other tables as well, see L</prefetch>
4341 below.
4342
4343  NOTE: An internal join-chain pruner will discard certain joins while
4344  constructing the actual SQL query, as long as the joins in question do not
4345  affect the retrieved result. This for example includes 1:1 left joins
4346  that are not part of the restriction specification (WHERE/HAVING) nor are
4347  a part of the query selection.
4348
4349 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4350
4351 =head2 collapse
4352
4353 =over 4
4354
4355 =item Value: (0 | 1)
4356
4357 =back
4358
4359 When set to a true value, indicates that any rows fetched from joined has_many
4360 relationships are to be aggregated into the corresponding "parent" object. For
4361 example, the resultset:
4362
4363   my $rs = $schema->resultset('CD')->search({}, {
4364     '+columns' => [ qw/ tracks.title tracks.position / ],
4365     join => 'tracks',
4366     collapse => 1,
4367   });
4368
4369 While executing the following query:
4370
4371   SELECT me.*, tracks.title, tracks.position
4372     FROM cd me
4373     LEFT JOIN track tracks
4374       ON tracks.cdid = me.cdid
4375
4376 Will return only as many objects as there are rows in the CD source, even
4377 though the result of the query may span many rows. Each of these CD objects
4378 will in turn have multiple "Track" objects hidden behind the has_many
4379 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4380 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4381 product"), with each CD object containing exactly one of all fetched Track data.
4382
4383 When a collapse is requested on a non-ordered resultset, an order by some
4384 unique part of the main source (the left-most table) is inserted automatically.
4385 This is done so that the resultset is allowed to be "lazy" - calling
4386 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4387 object with all of its related data.
4388
4389 If an L</order_by> is already declared, and orders the resultset in a way that
4390 makes collapsing as described above impossible (e.g. C<< ORDER BY
4391 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4392 switch to "eager" mode and slurp the entire resultset before constructing the
4393 first object returned by L</next>.
4394
4395 Setting this attribute on a resultset that does not join any has_many
4396 relations is a no-op.
4397
4398 For a more in-depth discussion, see L</PREFETCHING>.
4399
4400 =head2 prefetch
4401
4402 =over 4
4403
4404 =item Value: ($rel_name | \@rel_names | \%rel_names)
4405
4406 =back
4407
4408 This attribute is a shorthand for specifying a L</join> spec, adding all
4409 columns from the joined related sources as L</+columns> and setting
4410 L</collapse> to a true value. It can be thought of as a rough B<superset>
4411 of the L</join> attribute.
4412
4413 For example, the following two queries are equivalent:
4414
4415   my $rs = $schema->resultset('Artist')->search({}, {
4416     prefetch => { cds => ['genre', 'tracks' ] },
4417   });
4418
4419 and
4420
4421   my $rs = $schema->resultset('Artist')->search({}, {
4422     join => { cds => ['genre', 'tracks' ] },
4423     collapse => 1,
4424     '+columns' => [
4425       (map
4426         { +{ "cds.$_" => "cds.$_" } }
4427         $schema->source('Artist')->related_source('cds')->columns
4428       ),
4429       (map
4430         { +{ "cds.genre.$_" => "genre.$_" } }
4431         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4432       ),
4433       (map
4434         { +{ "cds.tracks.$_" => "tracks.$_" } }
4435         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4436       ),
4437     ],
4438   });
4439
4440 Both producing the following SQL:
4441
4442   SELECT  me.artistid, me.name, me.rank, me.charfield,
4443           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4444           genre.genreid, genre.name,
4445           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4446     FROM artist me
4447     LEFT JOIN cd cds
4448       ON cds.artist = me.artistid
4449     LEFT JOIN genre genre
4450       ON genre.genreid = cds.genreid
4451     LEFT JOIN track tracks
4452       ON tracks.cd = cds.cdid
4453   ORDER BY me.artistid
4454
4455 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4456 the arguments are properly merged and generally do the right thing. For
4457 example, you may want to do the following:
4458
4459   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4460     { 'genre.genreid' => undef },
4461     {
4462       join => { cds => 'genre' },
4463       prefetch => 'cds',
4464     }
4465   );
4466
4467 Which generates the following SQL:
4468
4469   SELECT  me.artistid, me.name, me.rank, me.charfield,
4470           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4471     FROM artist me
4472     LEFT JOIN cd cds
4473       ON cds.artist = me.artistid
4474     LEFT JOIN genre genre
4475       ON genre.genreid = cds.genreid
4476   WHERE genre.genreid IS NULL
4477   ORDER BY me.artistid
4478
4479 For a more in-depth discussion, see L</PREFETCHING>.
4480
4481 =head2 alias
4482
4483 =over 4
4484
4485 =item Value: $source_alias
4486
4487 =back
4488
4489 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4490 nested search queries (sub-SELECTs) might need specific aliases set to
4491 reference inner queries.  For example:
4492
4493    my $q = $rs
4494       ->related_resultset('CDs')
4495       ->related_resultset('Tracks')
4496       ->search({
4497          'track.id' => { -ident => 'none_search.id' },
4498       })
4499       ->as_query;
4500
4501    my $ids = $self->search({
4502       -not_exists => $q,
4503    }, {
4504       alias    => 'none_search',
4505       group_by => 'none_search.id',
4506    })->get_column('id')->as_query;
4507
4508    $self->search({ id => { -in => $ids } })
4509
4510 This attribute is directly tied to L</current_source_alias>.
4511
4512 =head2 page
4513
4514 =over 4
4515
4516 =item Value: $page
4517
4518 =back
4519
4520 Makes the resultset paged and specifies the page to retrieve. Effectively
4521 identical to creating a non-pages resultset and then calling ->page($page)
4522 on it.
4523
4524 If L</rows> attribute is not specified it defaults to 10 rows per page.
4525
4526 When you have a paged resultset, L</count> will only return the number
4527 of rows in the page. To get the total, use the L</pager> and call
4528 C<total_entries> on it.
4529
4530 =head2 rows
4531
4532 =over 4
4533
4534 =item Value: $rows
4535
4536 =back
4537
4538 Specifies the maximum number of rows for direct retrieval or the number of
4539 rows per page if the page attribute or method is used.
4540
4541 =head2 offset
4542
4543 =over 4
4544
4545 =item Value: $offset
4546
4547 =back
4548
4549 Specifies the (zero-based) row number for the  first row to be returned, or the
4550 of the first row of the first page if paging is used.
4551
4552 =head2 software_limit
4553
4554 =over 4
4555
4556 =item Value: (0 | 1)
4557
4558 =back
4559
4560 When combined with L</rows> and/or L</offset> the generated SQL will not
4561 include any limit dialect stanzas. Instead the entire result will be selected
4562 as if no limits were specified, and DBIC will perform the limit locally, by
4563 artificially advancing and finishing the resulting L</cursor>.
4564
4565 This is the recommended way of performing resultset limiting when no sane RDBMS
4566 implementation is available (e.g.
4567 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4568 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4569
4570 =head2 group_by
4571
4572 =over 4
4573
4574 =item Value: \@columns
4575
4576 =back
4577
4578 A arrayref of columns to group by. Can include columns of joined tables.
4579
4580   group_by => [qw/ column1 column2 ... /]
4581
4582 =head2 having
4583
4584 =over 4
4585
4586 =item Value: $condition
4587
4588 =back
4589
4590 The HAVING operator specifies a B<secondary> condition applied to the set
4591 after the grouping calculations have been done. In other words it is a
4592 constraint just like L</where> (and accepting the same
4593 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4594 as it exists after GROUP BY has taken place. Specifying L</having> without
4595 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4596
4597 E.g.
4598
4599   having => { 'count_employee' => { '>=', 100 } }
4600
4601 or with an in-place function in which case literal SQL is required:
4602
4603   having => \[ 'count(employee) >= ?', 100 ]
4604
4605 =head2 distinct
4606
4607 =over 4
4608
4609 =item Value: (0 | 1)
4610
4611 =back
4612
4613 Set to 1 to automatically generate a L</group_by> clause based on the selection
4614 (including intelligent handling of L</order_by> contents). Note that the group
4615 criteria calculation takes place over the B<final> selection. This includes
4616 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4617 L</search> calls, and standalone columns selected via
4618 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4619 extra selections specified via L</prefetch> - such selections are explicitly
4620 excluded from group criteria calculations.
4621
4622 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4623 setting is ignored and an appropriate warning is issued.
4624
4625 =head2 where
4626
4627 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4628 conditions, same as the B<first> argument to the L<search operator|/search>
4629
4630   # only return rows WHERE deleted IS NULL for all searches
4631   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4632
4633 Note that the above example is
4634 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4635
4636 =head2 cache
4637
4638 Set to 1 to cache search results. This prevents extra SQL queries if you
4639 revisit rows in your ResultSet:
4640
4641   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4642
4643   while( my $artist = $resultset->next ) {
4644     ... do stuff ...
4645   }
4646
4647   $resultset->first; # without cache, this would issue a query
4648
4649 By default, searches are not cached.
4650
4651 For more examples of using these attributes, see
4652 L<DBIx::Class::Manual::Cookbook>.
4653
4654 =head2 for
4655
4656 =over 4
4657
4658 =item Value: ( 'update' | 'shared' | \$scalar )
4659
4660 =back
4661
4662 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4663 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4664 query.
4665
4666 =head1 PREFETCHING
4667
4668 DBIx::Class supports arbitrary related data prefetching from multiple related
4669 sources. Any combination of relationship types and column sets are supported.
4670 If L<collapsing|/collapse> is requested, there is an additional requirement of
4671 selecting enough data to make every individual object uniquely identifiable.
4672
4673 Here are some more involved examples, based on the following relationship map:
4674
4675   # Assuming:
4676   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4677   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4678   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4679
4680   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4681
4682   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4683
4684
4685
4686   my $rs = $schema->resultset('Tag')->search(
4687     undef,
4688     {
4689       prefetch => {
4690         cd => 'artist'
4691       }
4692     }
4693   );
4694
4695 The initial search results in SQL like the following:
4696
4697   SELECT tag.*, cd.*, artist.* FROM tag
4698   JOIN cd ON tag.cd = cd.cdid
4699   JOIN artist ON cd.artist = artist.artistid
4700
4701 L<DBIx::Class> has no need to go back to the database when we access the
4702 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4703 case.
4704
4705 Simple prefetches will be joined automatically, so there is no need
4706 for a C<join> attribute in the above search.
4707
4708 The L</prefetch> attribute can be used with any of the relationship types
4709 and multiple prefetches can be specified together. Below is a more complex
4710 example that prefetches a CD's artist, its liner notes (if present),
4711 the cover image, the tracks on that CD, and the guests on those
4712 tracks.
4713
4714   my $rs = $schema->resultset('CD')->search(
4715     undef,
4716     {
4717       prefetch => [
4718         { artist => 'record_label'},  # belongs_to => belongs_to
4719         'liner_note',                 # might_have
4720         'cover_image',                # has_one
4721         { tracks => 'guests' },       # has_many => has_many
4722       ]
4723     }
4724   );
4725
4726 This will produce SQL like the following:
4727
4728   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4729          tracks.*, guests.*
4730     FROM cd me
4731     JOIN artist artist
4732       ON artist.artistid = me.artistid
4733     JOIN record_label record_label
4734       ON record_label.labelid = artist.labelid
4735     LEFT JOIN track tracks
4736       ON tracks.cdid = me.cdid
4737     LEFT JOIN guest guests
4738       ON guests.trackid = track.trackid
4739     LEFT JOIN liner_notes liner_note
4740       ON liner_note.cdid = me.cdid
4741     JOIN cd_artwork cover_image
4742       ON cover_image.cdid = me.cdid
4743   ORDER BY tracks.cd
4744
4745 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4746 C<tracks>, and C<guests> of the CD will all be available through the
4747 relationship accessors without the need for additional queries to the
4748 database.
4749
4750 =head3 CAVEATS
4751
4752 Prefetch does a lot of deep magic. As such, it may not behave exactly
4753 as you might expect.
4754
4755 =over 4
4756
4757 =item *
4758
4759 Prefetch uses the L</cache> to populate the prefetched relationships. This
4760 may or may not be what you want.
4761
4762 =item *
4763
4764 If you specify a condition on a prefetched relationship, ONLY those
4765 rows that match the prefetched condition will be fetched into that relationship.
4766 This means that adding prefetch to a search() B<may alter> what is returned by
4767 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4768
4769   my $artist_rs = $schema->resultset('Artist')->search({
4770       'cds.year' => 2008,
4771   }, {
4772       join => 'cds',
4773   });
4774
4775   my $count = $artist_rs->first->cds->count;
4776
4777   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4778
4779   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4780
4781   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4782
4783 That cmp_ok() may or may not pass depending on the datasets involved. In other
4784 words the C<WHERE> condition would apply to the entire dataset, just like
4785 it would in regular SQL. If you want to add a condition only to the "right side"
4786 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4787 condition|DBIx::Class::Relationship::Base/condition>
4788
4789 =back
4790
4791 =head1 DBIC BIND VALUES
4792
4793 Because DBIC may need more information to bind values than just the column name
4794 and value itself, it uses a special format for both passing and receiving bind
4795 values.  Each bind value should be composed of an arrayref of
4796 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4797
4798 =over 4
4799
4800 =item dbd_attrs
4801
4802 If present (in any form), this is what is being passed directly to bind_param.
4803 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4804 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4805
4806 If this is specified, all other bind options described below are ignored.
4807
4808 =item sqlt_datatype
4809
4810 If present, this is used to infer the actual bind attribute by passing to
4811 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4812 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4813
4814 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4815 currently drivers are expected to "Do the Right Thing" when given a common
4816 datatype name.  (Not ideal, but that's what we got at this point.)
4817
4818 =item sqlt_size
4819
4820 Currently used to correctly allocate buffers for bind_param_inout().
4821 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4822 or to a sensible value based on the "data_type".
4823
4824 =item dbic_colname
4825
4826 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4827 explicitly specified they are never overridden).  Also used by some weird DBDs,
4828 where the column name should be available at bind_param time (e.g. Oracle).
4829
4830 =back
4831
4832 For backwards compatibility and convenience, the following shortcuts are
4833 supported:
4834
4835   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4836   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4837   [ undef,   $val ] === [ {}, $val ]
4838   $val              === [ {}, $val ]
4839
4840 =head1 FURTHER QUESTIONS?
4841
4842 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4843
4844 =head1 COPYRIGHT AND LICENSE
4845
4846 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4847 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4848 redistribute it and/or modify it under the same terms as the
4849 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4850
4851 =cut