lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960
 961   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 962     or return ();
 963   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 964   @new = $self->{_attrs}{record_filter}->(@new)
 965     if exists $self->{_attrs}{record_filter};
 966   return @new;
 967 }
 968
 969 sub _collapse_result {
 970   my ($self, $as_proto, $row) = @_;
 971
 972   # if the first row that ever came in is totally empty - this means we got
 973   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 974   # instead of producing a {}
 975   #
 976   my $has_def;
 977   for (@$row) {
 978     if (defined $_) {
 979       $has_def++;
 980       last;
 981     }
 982   }
 983   return undef unless $has_def;
 984
 985   my @copy = @$row;
 986
 987   # 'foo'         => [ undef, 'foo' ]
 988   # 'foo.bar'     => [ 'foo', 'bar' ]
 989   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 990
 991   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 992
 993   my %collapse = %{$self->{_attrs}{collapse}||{}};
 994
 995   my @pri_index;
 996
 997   # if we're doing collapsing (has_many prefetch) we need to grab records
 998   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 999   # we know we don't have to bother.
1000
1001   # the reason for not using the collapse stuff directly is because if you
1002   # had for e.g. two artists in a row with no cds, the collapse info for
1003   # both would be NULL (undef) so you'd lose the second artist
1004
1005   # store just the index so we can check the array positions from the row
1006   # without having to contruct the full hash
1007
1008   if (keys %collapse) {
1009     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1010     foreach my $i (0 .. $#construct_as) {
1011       next if defined($construct_as[$i][0]); # only self table
1012       if (delete $pri{$construct_as[$i][1]}) {
1013         push(@pri_index, $i);
1014       }
1015       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1016     }
1017   }
1018
1019   # no need to do an if, it'll be empty if @pri_index is empty anyway
1020
1021   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1022
1023   my @const_rows;
1024
1025   do { # no need to check anything at the front, we always want the first row
1026
1027     my %const;
1028
1029     foreach my $this_as (@construct_as) {
1030       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1031     }
1032
1033     push(@const_rows, \%const);
1034
1035   } until ( # no pri_index => no collapse => drop straight out
1036       !@pri_index
1037     or
1038       do { # get another row, stash it, drop out if different PK
1039
1040         @copy = $self->cursor->next;
1041         $self->{stashed_row} = \@copy;
1042
1043         # last thing in do block, counts as true if anything doesn't match
1044
1045         # check xor defined first for NULL vs. NOT NULL then if one is
1046         # defined the other must be so check string equality
1047
1048         grep {
1049           (defined $pri_vals{$_} ^ defined $copy[$_])
1050           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1051         } @pri_index;
1052       }
1053   );
1054
1055   my $alias = $self->{attrs}{alias};
1056   my $info = [];
1057
1058   my %collapse_pos;
1059
1060   my @const_keys;
1061
1062   foreach my $const (@const_rows) {
1063     scalar @const_keys or do {
1064       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1065     };
1066     foreach my $key (@const_keys) {
1067       if (length $key) {
1068         my $target = $info;
1069         my @parts = split(/\./, $key);
1070         my $cur = '';
1071         my $data = $const->{$key};
1072         foreach my $p (@parts) {
1073           $target = $target->[1]->{$p} ||= [];
1074           $cur .= ".${p}";
1075           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1076             # collapsing at this point and on final part
1077             my $pos = $collapse_pos{$cur};
1078             CK: foreach my $ck (@ckey) {
1079               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1080                 $collapse_pos{$cur} = $data;
1081                 delete @collapse_pos{ # clear all positioning for sub-entries
1082                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1083                 };
1084                 push(@$target, []);
1085                 last CK;
1086               }
1087             }
1088           }
1089           if (exists $collapse{$cur}) {
1090             $target = $target->[-1];
1091           }
1092         }
1093         $target->[0] = $data;
1094       } else {
1095         $info->[0] = $const->{$key};
1096       }
1097     }
1098   }
1099
1100   return $info;
1101 }
1102
1103 =head2 result_source
1104
1105 =over 4
1106
1107 =item Arguments: $result_source?
1108
1109 =item Return Value: $result_source
1110
1111 =back
1112
1113 An accessor for the primary ResultSource object from which this ResultSet
1114 is derived.
1115
1116 =head2 result_class
1117
1118 =over 4
1119
1120 =item Arguments: $result_class?
1121
1122 =item Return Value: $result_class
1123
1124 =back
1125
1126 An accessor for the class to use when creating row objects. Defaults to
1127 C<< result_source->result_class >> - which in most cases is the name of the
1128 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1129
1130 Note that changing the result_class will also remove any components
1131 that were originally loaded in the source class via
1132 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1133 in the original source class will not run.
1134
1135 =cut
1136
1137 sub result_class {
1138   my ($self, $result_class) = @_;
1139   if ($result_class) {
1140     $self->ensure_class_loaded($result_class);
1141     $self->_result_class($result_class);
1142   }
1143   $self->_result_class;
1144 }
1145
1146 =head2 count
1147
1148 =over 4
1149
1150 =item Arguments: $cond, \%attrs??
1151
1152 =item Return Value: $count
1153
1154 =back
1155
1156 Performs an SQL C<COUNT> with the same query as the resultset was built
1157 with to find the number of elements. Passing arguments is equivalent to
1158 C<< $rs->search ($cond, \%attrs)->count >>
1159
1160 =cut
1161
1162 sub count {
1163   my $self = shift;
1164   return $self->search(@_)->count if @_ and defined $_[0];
1165   return scalar @{ $self->get_cache } if $self->get_cache;
1166
1167   my $attrs = $self->_resolved_attrs_copy;
1168
1169   # this is a little optimization - it is faster to do the limit
1170   # adjustments in software, instead of a subquery
1171   my $rows = delete $attrs->{rows};
1172   my $offset = delete $attrs->{offset};
1173
1174   my $crs;
1175   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1176     $crs = $self->_count_subq_rs ($attrs);
1177   }
1178   else {
1179     $crs = $self->_count_rs ($attrs);
1180   }
1181   my $count = $crs->next;
1182
1183   $count -= $offset if $offset;
1184   $count = $rows if $rows and $rows < $count;
1185   $count = 0 if ($count < 0);
1186
1187   return $count;
1188 }
1189
1190 =head2 count_rs
1191
1192 =over 4
1193
1194 =item Arguments: $cond, \%attrs??
1195
1196 =item Return Value: $count_rs
1197
1198 =back
1199
1200 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1201 This can be very handy for subqueries:
1202
1203   ->search( { amount => $some_rs->count_rs->as_query } )
1204
1205 As with regular resultsets the SQL query will be executed only after
1206 the resultset is accessed via L</next> or L</all>. That would return
1207 the same single value obtainable via L</count>.
1208
1209 =cut
1210
1211 sub count_rs {
1212   my $self = shift;
1213   return $self->search(@_)->count_rs if @_;
1214
1215   # this may look like a lack of abstraction (count() does about the same)
1216   # but in fact an _rs *must* use a subquery for the limits, as the
1217   # software based limiting can not be ported if this $rs is to be used
1218   # in a subquery itself (i.e. ->as_query)
1219   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1220     return $self->_count_subq_rs;
1221   }
1222   else {
1223     return $self->_count_rs;
1224   }
1225 }
1226
1227 #
1228 # returns a ResultSetColumn object tied to the count query
1229 #
1230 sub _count_rs {
1231   my ($self, $attrs) = @_;
1232
1233   my $rsrc = $self->result_source;
1234   $attrs ||= $self->_resolved_attrs;
1235
1236   my $tmp_attrs = { %$attrs };
1237
1238   # take off any limits, record_filter is cdbi, and no point of ordering a count
1239   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1240
1241   # overwrite the selector (supplied by the storage)
1242   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1243   $tmp_attrs->{as} = 'count';
1244
1245   # read the comment on top of the actual function to see what this does
1246   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1247     $tmp_attrs->{from}, $tmp_attrs->{alias}
1248   );
1249
1250   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1251
1252   return $tmp_rs;
1253 }
1254
1255 #
1256 # same as above but uses a subquery
1257 #
1258 sub _count_subq_rs {
1259   my ($self, $attrs) = @_;
1260
1261   my $rsrc = $self->result_source;
1262   $attrs ||= $self->_resolved_attrs_copy;
1263
1264   my $sub_attrs = { %$attrs };
1265
1266   # extra selectors do not go in the subquery and there is no point of ordering it
1267   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1268
1269   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1270   # clobber old group_by regardless
1271   if ( keys %{$attrs->{collapse}} ) {
1272     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1273   }
1274
1275   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1276
1277   # read the comment on top of the actual function to see what this does
1278   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1279     $sub_attrs->{from}, $sub_attrs->{alias}
1280   );
1281
1282   # this is so that ordering can be thrown away in things like Top limit
1283   $sub_attrs->{-for_count_only} = 1;
1284
1285   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1286
1287   $attrs->{from} = [{
1288     -alias => 'count_subq',
1289     -source_handle => $rsrc->handle,
1290     count_subq => $sub_rs->as_query,
1291   }];
1292
1293   # the subquery replaces this
1294   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1295
1296   return $self->_count_rs ($attrs);
1297 }
1298
1299
1300 # The DBIC relationship chaining implementation is pretty simple - every
1301 # new related_relationship is pushed onto the {from} stack, and the {select}
1302 # window simply slides further in. This means that when we count somewhere
1303 # in the middle, we got to make sure that everything in the join chain is an
1304 # actual inner join, otherwise the count will come back with unpredictable
1305 # results (a resultset may be generated with _some_ rows regardless of if
1306 # the relation which the $rs currently selects has rows or not). E.g.
1307 # $artist_rs->cds->count - normally generates:
1308 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1309 # which actually returns the number of artists * (number of cds || 1)
1310 #
1311 # So what we do here is crawl {from}, determine if the current alias is at
1312 # the top of the stack, and if not - make sure the chain is inner-joined down
1313 # to the root.
1314 #
1315 sub _switch_to_inner_join_if_needed {
1316   my ($self, $from, $alias) = @_;
1317
1318   # subqueries and other oddness is naturally not supported
1319   return $from if (
1320     ref $from ne 'ARRAY'
1321       ||
1322     @$from <= 1
1323       ||
1324     ref $from->[0] ne 'HASH'
1325       ||
1326     ! $from->[0]{-alias}
1327       ||
1328     $from->[0]{-alias} eq $alias
1329   );
1330
1331   my $switch_branch;
1332   JOINSCAN:
1333   for my $j (@{$from}[1 .. $#$from]) {
1334     if ($j->[0]{-alias} eq $alias) {
1335       $switch_branch = $j->[0]{-join_path};
1336       last JOINSCAN;
1337     }
1338   }
1339
1340   # something else went wrong
1341   return $from unless $switch_branch;
1342
1343   # So it looks like we will have to switch some stuff around.
1344   # local() is useless here as we will be leaving the scope
1345   # anyway, and deep cloning is just too fucking expensive
1346   # So replace the inner hashref manually
1347   my @new_from = ($from->[0]);
1348   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1349
1350   for my $j (@{$from}[1 .. $#$from]) {
1351     my $jalias = $j->[0]{-alias};
1352
1353     if ($sw_idx->{$jalias}) {
1354       my %attrs = %{$j->[0]};
1355       delete $attrs{-join_type};
1356       push @new_from, [
1357         \%attrs,
1358         @{$j}[ 1 .. $#$j ],
1359       ];
1360     }
1361     else {
1362       push @new_from, $j;
1363     }
1364   }
1365
1366   return \@new_from;
1367 }
1368
1369
1370 sub _bool {
1371   return 1;
1372 }
1373
1374 =head2 count_literal
1375
1376 =over 4
1377
1378 =item Arguments: $sql_fragment, @bind_values
1379
1380 =item Return Value: $count
1381
1382 =back
1383
1384 Counts the results in a literal query. Equivalent to calling L</search_literal>
1385 with the passed arguments, then L</count>.
1386
1387 =cut
1388
1389 sub count_literal { shift->search_literal(@_)->count; }
1390
1391 =head2 all
1392
1393 =over 4
1394
1395 =item Arguments: none
1396
1397 =item Return Value: @objects
1398
1399 =back
1400
1401 Returns all elements in the resultset. Called implicitly if the resultset
1402 is returned in list context.
1403
1404 =cut
1405
1406 sub all {
1407   my $self = shift;
1408   if(@_) {
1409       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1410   }
1411
1412   return @{ $self->get_cache } if $self->get_cache;
1413
1414   my @obj;
1415
1416   if (keys %{$self->_resolved_attrs->{collapse}}) {
1417     # Using $self->cursor->all is really just an optimisation.
1418     # If we're collapsing has_many prefetches it probably makes
1419     # very little difference, and this is cleaner than hacking
1420     # _construct_object to survive the approach
1421     $self->cursor->reset;
1422     my @row = $self->cursor->next;
1423     while (@row) {
1424       push(@obj, $self->_construct_object(@row));
1425       @row = (exists $self->{stashed_row}
1426                ? @{delete $self->{stashed_row}}
1427                : $self->cursor->next);
1428     }
1429   } else {
1430     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1431   }
1432
1433   $self->set_cache(\@obj) if $self->{attrs}{cache};
1434
1435   return @obj;
1436 }
1437
1438 =head2 reset
1439
1440 =over 4
1441
1442 =item Arguments: none
1443
1444 =item Return Value: $self
1445
1446 =back
1447
1448 Resets the resultset's cursor, so you can iterate through the elements again.
1449 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1450 another query.
1451
1452 =cut
1453
1454 sub reset {
1455   my ($self) = @_;
1456   delete $self->{_attrs} if exists $self->{_attrs};
1457   $self->{all_cache_position} = 0;
1458   $self->cursor->reset;
1459   return $self;
1460 }
1461
1462 =head2 first
1463
1464 =over 4
1465
1466 =item Arguments: none
1467
1468 =item Return Value: $object?
1469
1470 =back
1471
1472 Resets the resultset and returns an object for the first result (if the
1473 resultset returns anything).
1474
1475 =cut
1476
1477 sub first {
1478   return $_[0]->reset->next;
1479 }
1480
1481
1482 # _rs_update_delete
1483 #
1484 # Determines whether and what type of subquery is required for the $rs operation.
1485 # If grouping is necessary either supplies its own, or verifies the current one
1486 # After all is done delegates to the proper storage method.
1487
1488 sub _rs_update_delete {
1489   my ($self, $op, $values) = @_;
1490
1491   my $rsrc = $self->result_source;
1492
1493   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1494   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1495
1496   if ($needs_group_by_subq or $needs_subq) {
1497
1498     # make a new $rs selecting only the PKs (that's all we really need)
1499     my $attrs = $self->_resolved_attrs_copy;
1500
1501     delete $attrs->{$_} for qw/collapse select as/;
1502     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1503
1504     if ($needs_group_by_subq) {
1505       # make sure no group_by was supplied, or if there is one - make sure it matches
1506       # the columns compiled above perfectly. Anything else can not be sanely executed
1507       # on most databases so croak right then and there
1508
1509       if (my $g = $attrs->{group_by}) {
1510         my @current_group_by = map
1511           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1512           (ref $g eq 'ARRAY' ? @$g : $g );
1513
1514         if (
1515           join ("\x00", sort @current_group_by)
1516             ne
1517           join ("\x00", sort @{$attrs->{columns}} )
1518         ) {
1519           $self->throw_exception (
1520             "You have just attempted a $op operation on a resultset which does group_by"
1521             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1522             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1523             . ' kind of queries. Please retry the operation with a modified group_by or'
1524             . ' without using one at all.'
1525           );
1526         }
1527       }
1528       else {
1529         $attrs->{group_by} = $attrs->{columns};
1530       }
1531     }
1532
1533     my $subrs = (ref $self)->new($rsrc, $attrs);
1534
1535     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1536   }
1537   else {
1538     return $rsrc->storage->$op(
1539       $rsrc,
1540       $op eq 'update' ? $values : (),
1541       $self->_cond_for_update_delete,
1542     );
1543   }
1544 }
1545
1546
1547 # _cond_for_update_delete
1548 #
1549 # update/delete require the condition to be modified to handle
1550 # the differing SQL syntax available.  This transforms the $self->{cond}
1551 # appropriately, returning the new condition.
1552
1553 sub _cond_for_update_delete {
1554   my ($self, $full_cond) = @_;
1555   my $cond = {};
1556
1557   $full_cond ||= $self->{cond};
1558   # No-op. No condition, we're updating/deleting everything
1559   return $cond unless ref $full_cond;
1560
1561   if (ref $full_cond eq 'ARRAY') {
1562     $cond = [
1563       map {
1564         my %hash;
1565         foreach my $key (keys %{$_}) {
1566           $key =~ /([^.]+)$/;
1567           $hash{$1} = $_->{$key};
1568         }
1569         \%hash;
1570       } @{$full_cond}
1571     ];
1572   }
1573   elsif (ref $full_cond eq 'HASH') {
1574     if ((keys %{$full_cond})[0] eq '-and') {
1575       $cond->{-and} = [];
1576       my @cond = @{$full_cond->{-and}};
1577        for (my $i = 0; $i < @cond; $i++) {
1578         my $entry = $cond[$i];
1579         my $hash;
1580         if (ref $entry eq 'HASH') {
1581           $hash = $self->_cond_for_update_delete($entry);
1582         }
1583         else {
1584           $entry =~ /([^.]+)$/;
1585           $hash->{$1} = $cond[++$i];
1586         }
1587         push @{$cond->{-and}}, $hash;
1588       }
1589     }
1590     else {
1591       foreach my $key (keys %{$full_cond}) {
1592         $key =~ /([^.]+)$/;
1593         $cond->{$1} = $full_cond->{$key};
1594       }
1595     }
1596   }
1597   else {
1598     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1599   }
1600
1601   return $cond;
1602 }
1603
1604
1605 =head2 update
1606
1607 =over 4
1608
1609 =item Arguments: \%values
1610
1611 =item Return Value: $storage_rv
1612
1613 =back
1614
1615 Sets the specified columns in the resultset to the supplied values in a
1616 single query. Return value will be true if the update succeeded or false
1617 if no records were updated; exact type of success value is storage-dependent.
1618
1619 =cut
1620
1621 sub update {
1622   my ($self, $values) = @_;
1623   $self->throw_exception('Values for update must be a hash')
1624     unless ref $values eq 'HASH';
1625
1626   return $self->_rs_update_delete ('update', $values);
1627 }
1628
1629 =head2 update_all
1630
1631 =over 4
1632
1633 =item Arguments: \%values
1634
1635 =item Return Value: 1
1636
1637 =back
1638
1639 Fetches all objects and updates them one at a time. Note that C<update_all>
1640 will run DBIC cascade triggers, while L</update> will not.
1641
1642 =cut
1643
1644 sub update_all {
1645   my ($self, $values) = @_;
1646   $self->throw_exception('Values for update_all must be a hash')
1647     unless ref $values eq 'HASH';
1648   foreach my $obj ($self->all) {
1649     $obj->set_columns($values)->update;
1650   }
1651   return 1;
1652 }
1653
1654 =head2 delete
1655
1656 =over 4
1657
1658 =item Arguments: none
1659
1660 =item Return Value: $storage_rv
1661
1662 =back
1663
1664 Deletes the contents of the resultset from its result source. Note that this
1665 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1666 to run. See also L<DBIx::Class::Row/delete>.
1667
1668 Return value will be the amount of rows deleted; exact type of return value
1669 is storage-dependent.
1670
1671 =cut
1672
1673 sub delete {
1674   my $self = shift;
1675   $self->throw_exception('delete does not accept any arguments')
1676     if @_;
1677
1678   return $self->_rs_update_delete ('delete');
1679 }
1680
1681 =head2 delete_all
1682
1683 =over 4
1684
1685 =item Arguments: none
1686
1687 =item Return Value: 1
1688
1689 =back
1690
1691 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1692 will run DBIC cascade triggers, while L</delete> will not.
1693
1694 =cut
1695
1696 sub delete_all {
1697   my $self = shift;
1698   $self->throw_exception('delete_all does not accept any arguments')
1699     if @_;
1700
1701   $_->delete for $self->all;
1702   return 1;
1703 }
1704
1705 =head2 populate
1706
1707 =over 4
1708
1709 =item Arguments: \@data;
1710
1711 =back
1712
1713 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1714 For the arrayref of hashrefs style each hashref should be a structure suitable
1715 forsubmitting to a $resultset->create(...) method.
1716
1717 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1718 to insert the data, as this is a faster method.
1719
1720 Otherwise, each set of data is inserted into the database using
1721 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1722 accumulated into an array. The array itself, or an array reference
1723 is returned depending on scalar or list context.
1724
1725 Example:  Assuming an Artist Class that has many CDs Classes relating:
1726
1727   my $Artist_rs = $schema->resultset("Artist");
1728
1729   ## Void Context Example
1730   $Artist_rs->populate([
1731      { artistid => 4, name => 'Manufactured Crap', cds => [
1732         { title => 'My First CD', year => 2006 },
1733         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1734       ],
1735      },
1736      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1737         { title => 'My parents sold me to a record company' ,year => 2005 },
1738         { title => 'Why Am I So Ugly?', year => 2006 },
1739         { title => 'I Got Surgery and am now Popular', year => 2007 }
1740       ],
1741      },
1742   ]);
1743
1744   ## Array Context Example
1745   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1746     { name => "Artist One"},
1747     { name => "Artist Two"},
1748     { name => "Artist Three", cds=> [
1749     { title => "First CD", year => 2007},
1750     { title => "Second CD", year => 2008},
1751   ]}
1752   ]);
1753
1754   print $ArtistOne->name; ## response is 'Artist One'
1755   print $ArtistThree->cds->count ## reponse is '2'
1756
1757 For the arrayref of arrayrefs style,  the first element should be a list of the
1758 fieldsnames to which the remaining elements are rows being inserted.  For
1759 example:
1760
1761   $Arstist_rs->populate([
1762     [qw/artistid name/],
1763     [100, 'A Formally Unknown Singer'],
1764     [101, 'A singer that jumped the shark two albums ago'],
1765     [102, 'An actually cool singer.'],
1766   ]);
1767
1768 Please note an important effect on your data when choosing between void and
1769 wantarray context. Since void context goes straight to C<insert_bulk> in
1770 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1771 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1772 create primary keys for you, you will find that your PKs are empty.  In this
1773 case you will have to use the wantarray context in order to create those
1774 values.
1775
1776 =cut
1777
1778 sub populate {
1779   my $self = shift @_;
1780   my $data = ref $_[0][0] eq 'HASH'
1781     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1782     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1783
1784   if(defined wantarray) {
1785     my @created;
1786     foreach my $item (@$data) {
1787       push(@created, $self->create($item));
1788     }
1789     return wantarray ? @created : \@created;
1790   } else {
1791     my ($first, @rest) = @$data;
1792
1793     my @names = grep {!ref $first->{$_}} keys %$first;
1794     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1795     my @pks = $self->result_source->primary_columns;
1796
1797     ## do the belongs_to relationships
1798     foreach my $index (0..$#$data) {
1799
1800       # delegate to create() for any dataset without primary keys with specified relationships
1801       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1802         for my $r (@rels) {
1803           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1804             my @ret = $self->populate($data);
1805             return;
1806           }
1807         }
1808       }
1809
1810       foreach my $rel (@rels) {
1811         next unless ref $data->[$index]->{$rel} eq "HASH";
1812         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1813         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1814         my $related = $result->result_source->_resolve_condition(
1815           $result->result_source->relationship_info($reverse)->{cond},
1816           $self,
1817           $result,
1818         );
1819
1820         delete $data->[$index]->{$rel};
1821         $data->[$index] = {%{$data->[$index]}, %$related};
1822
1823         push @names, keys %$related if $index == 0;
1824       }
1825     }
1826
1827     ## do bulk insert on current row
1828     my @values = map { [ @$_{@names} ] } @$data;
1829
1830     $self->result_source->storage->insert_bulk(
1831       $self->result_source,
1832       \@names,
1833       \@values,
1834     );
1835
1836     ## do the has_many relationships
1837     foreach my $item (@$data) {
1838
1839       foreach my $rel (@rels) {
1840         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1841
1842         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1843      || $self->throw_exception('Cannot find the relating object.');
1844
1845         my $child = $parent->$rel;
1846
1847         my $related = $child->result_source->_resolve_condition(
1848           $parent->result_source->relationship_info($rel)->{cond},
1849           $child,
1850           $parent,
1851         );
1852
1853         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1854         my @populate = map { {%$_, %$related} } @rows_to_add;
1855
1856         $child->populate( \@populate );
1857       }
1858     }
1859   }
1860 }
1861
1862 =head2 _normalize_populate_args ($args)
1863
1864 Private method used by L</populate> to normalize its incoming arguments.  Factored
1865 out in case you want to subclass and accept new argument structures to the
1866 L</populate> method.
1867
1868 =cut
1869
1870 sub _normalize_populate_args {
1871   my ($self, $data) = @_;
1872   my @names = @{shift(@$data)};
1873   my @results_to_create;
1874   foreach my $datum (@$data) {
1875     my %result_to_create;
1876     foreach my $index (0..$#names) {
1877       $result_to_create{$names[$index]} = $$datum[$index];
1878     }
1879     push @results_to_create, \%result_to_create;
1880   }
1881   return \@results_to_create;
1882 }
1883
1884 =head2 pager
1885
1886 =over 4
1887
1888 =item Arguments: none
1889
1890 =item Return Value: $pager
1891
1892 =back
1893
1894 Return Value a L<Data::Page> object for the current resultset. Only makes
1895 sense for queries with a C<page> attribute.
1896
1897 To get the full count of entries for a paged resultset, call
1898 C<total_entries> on the L<Data::Page> object.
1899
1900 =cut
1901
1902 sub pager {
1903   my ($self) = @_;
1904
1905   return $self->{pager} if $self->{pager};
1906
1907   my $attrs = $self->{attrs};
1908   $self->throw_exception("Can't create pager for non-paged rs")
1909     unless $self->{attrs}{page};
1910   $attrs->{rows} ||= 10;
1911
1912   # throw away the paging flags and re-run the count (possibly
1913   # with a subselect) to get the real total count
1914   my $count_attrs = { %$attrs };
1915   delete $count_attrs->{$_} for qw/rows offset page pager/;
1916   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1917
1918   return $self->{pager} = Data::Page->new(
1919     $total_count,
1920     $attrs->{rows},
1921     $self->{attrs}{page}
1922   );
1923 }
1924
1925 =head2 page
1926
1927 =over 4
1928
1929 =item Arguments: $page_number
1930
1931 =item Return Value: $rs
1932
1933 =back
1934
1935 Returns a resultset for the $page_number page of the resultset on which page
1936 is called, where each page contains a number of rows equal to the 'rows'
1937 attribute set on the resultset (10 by default).
1938
1939 =cut
1940
1941 sub page {
1942   my ($self, $page) = @_;
1943   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1944 }
1945
1946 =head2 new_result
1947
1948 =over 4
1949
1950 =item Arguments: \%vals
1951
1952 =item Return Value: $rowobject
1953
1954 =back
1955
1956 Creates a new row object in the resultset's result class and returns
1957 it. The row is not inserted into the database at this point, call
1958 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1959 will tell you whether the row object has been inserted or not.
1960
1961 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1962
1963 =cut
1964
1965 sub new_result {
1966   my ($self, $values) = @_;
1967   $self->throw_exception( "new_result needs a hash" )
1968     unless (ref $values eq 'HASH');
1969
1970   my %new;
1971   my $alias = $self->{attrs}{alias};
1972
1973   if (
1974     defined $self->{cond}
1975     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1976   ) {
1977     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1978     $new{-from_resultset} = [ keys %new ] if keys %new;
1979   } else {
1980     $self->throw_exception(
1981       "Can't abstract implicit construct, condition not a hash"
1982     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1983
1984     my $collapsed_cond = (
1985       $self->{cond}
1986         ? $self->_collapse_cond($self->{cond})
1987         : {}
1988     );
1989
1990     # precendence must be given to passed values over values inherited from
1991     # the cond, so the order here is important.
1992     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1993     while( my($col,$value) = each %implied ){
1994       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1995         $new{$col} = $value->{'='};
1996         next;
1997       }
1998       $new{$col} = $value if $self->_is_deterministic_value($value);
1999     }
2000   }
2001
2002   %new = (
2003     %new,
2004     %{ $self->_remove_alias($values, $alias) },
2005     -source_handle => $self->_source_handle,
2006     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2007   );
2008
2009   return $self->result_class->new(\%new);
2010 }
2011
2012 # _is_deterministic_value
2013 #
2014 # Make an effor to strip non-deterministic values from the condition,
2015 # to make sure new_result chokes less
2016
2017 sub _is_deterministic_value {
2018   my $self = shift;
2019   my $value = shift;
2020   my $ref_type = ref $value;
2021   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2022   return 1 if Scalar::Util::blessed($value);
2023   return 0;
2024 }
2025
2026 # _has_resolved_attr
2027 #
2028 # determines if the resultset defines at least one
2029 # of the attributes supplied
2030 #
2031 # used to determine if a subquery is neccessary
2032 #
2033 # supports some virtual attributes:
2034 #   -join
2035 #     This will scan for any joins being present on the resultset.
2036 #     It is not a mere key-search but a deep inspection of {from}
2037 #
2038
2039 sub _has_resolved_attr {
2040   my ($self, @attr_names) = @_;
2041
2042   my $attrs = $self->_resolved_attrs;
2043
2044   my %extra_checks;
2045
2046   for my $n (@attr_names) {
2047     if (grep { $n eq $_ } (qw/-join/) ) {
2048       $extra_checks{$n}++;
2049       next;
2050     }
2051
2052     my $attr =  $attrs->{$n};
2053
2054     next if not defined $attr;
2055
2056     if (ref $attr eq 'HASH') {
2057       return 1 if keys %$attr;
2058     }
2059     elsif (ref $attr eq 'ARRAY') {
2060       return 1 if @$attr;
2061     }
2062     else {
2063       return 1 if $attr;
2064     }
2065   }
2066
2067   # a resolved join is expressed as a multi-level from
2068   return 1 if (
2069     $extra_checks{-join}
2070       and
2071     ref $attrs->{from} eq 'ARRAY'
2072       and
2073     @{$attrs->{from}} > 1
2074   );
2075
2076   return 0;
2077 }
2078
2079 # _collapse_cond
2080 #
2081 # Recursively collapse the condition.
2082
2083 sub _collapse_cond {
2084   my ($self, $cond, $collapsed) = @_;
2085
2086   $collapsed ||= {};
2087
2088   if (ref $cond eq 'ARRAY') {
2089     foreach my $subcond (@$cond) {
2090       next unless ref $subcond;  # -or
2091       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2092     }
2093   }
2094   elsif (ref $cond eq 'HASH') {
2095     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2096       foreach my $subcond (@{$cond->{-and}}) {
2097         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2098       }
2099     }
2100     else {
2101       foreach my $col (keys %$cond) {
2102         my $value = $cond->{$col};
2103         $collapsed->{$col} = $value;
2104       }
2105     }
2106   }
2107
2108   return $collapsed;
2109 }
2110
2111 # _remove_alias
2112 #
2113 # Remove the specified alias from the specified query hash. A copy is made so
2114 # the original query is not modified.
2115
2116 sub _remove_alias {
2117   my ($self, $query, $alias) = @_;
2118
2119   my %orig = %{ $query || {} };
2120   my %unaliased;
2121
2122   foreach my $key (keys %orig) {
2123     if ($key !~ /\./) {
2124       $unaliased{$key} = $orig{$key};
2125       next;
2126     }
2127     $unaliased{$1} = $orig{$key}
2128       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2129   }
2130
2131   return \%unaliased;
2132 }
2133
2134 =head2 as_query (EXPERIMENTAL)
2135
2136 =over 4
2137
2138 =item Arguments: none
2139
2140 =item Return Value: \[ $sql, @bind ]
2141
2142 =back
2143
2144 Returns the SQL query and bind vars associated with the invocant.
2145
2146 This is generally used as the RHS for a subquery.
2147
2148 B<NOTE>: This feature is still experimental.
2149
2150 =cut
2151
2152 sub as_query {
2153   my $self = shift;
2154
2155   my $attrs = $self->_resolved_attrs_copy;
2156
2157   # For future use:
2158   #
2159   # in list ctx:
2160   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2161   # $sql also has no wrapping parenthesis in list ctx
2162   #
2163   my $sqlbind = $self->result_source->storage
2164     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2165
2166   return $sqlbind;
2167 }
2168
2169 =head2 find_or_new
2170
2171 =over 4
2172
2173 =item Arguments: \%vals, \%attrs?
2174
2175 =item Return Value: $rowobject
2176
2177 =back
2178
2179   my $artist = $schema->resultset('Artist')->find_or_new(
2180     { artist => 'fred' }, { key => 'artists' });
2181
2182   $cd->cd_to_producer->find_or_new({ producer => $producer },
2183                                    { key => 'primary });
2184
2185 Find an existing record from this resultset, based on its primary
2186 key, or a unique constraint. If none exists, instantiate a new result
2187 object and return it. The object will not be saved into your storage
2188 until you call L<DBIx::Class::Row/insert> on it.
2189
2190 You most likely want this method when looking for existing rows using
2191 a unique constraint that is not the primary key, or looking for
2192 related rows.
2193
2194 If you want objects to be saved immediately, use L</find_or_create> instead.
2195
2196 B<Note>: C<find_or_new> is probably not what you want when creating a
2197 new row in a table that uses primary keys supplied by the
2198 database. Passing in a primary key column with a value of I<undef>
2199 will cause L</find> to attempt to search for a row with a value of
2200 I<NULL>.
2201
2202 =cut
2203
2204 sub find_or_new {
2205   my $self     = shift;
2206   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2207   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2208   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2209     return $row;
2210   }
2211   return $self->new_result($hash);
2212 }
2213
2214 =head2 create
2215
2216 =over 4
2217
2218 =item Arguments: \%vals
2219
2220 =item Return Value: a L<DBIx::Class::Row> $object
2221
2222 =back
2223
2224 Attempt to create a single new row or a row with multiple related rows
2225 in the table represented by the resultset (and related tables). This
2226 will not check for duplicate rows before inserting, use
2227 L</find_or_create> to do that.
2228
2229 To create one row for this resultset, pass a hashref of key/value
2230 pairs representing the columns of the table and the values you wish to
2231 store. If the appropriate relationships are set up, foreign key fields
2232 can also be passed an object representing the foreign row, and the
2233 value will be set to its primary key.
2234
2235 To create related objects, pass a hashref of related-object column values
2236 B<keyed on the relationship name>. If the relationship is of type C<multi>
2237 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2238 The process will correctly identify columns holding foreign keys, and will
2239 transparrently populate them from the keys of the corresponding relation.
2240 This can be applied recursively, and will work correctly for a structure
2241 with an arbitrary depth and width, as long as the relationships actually
2242 exists and the correct column data has been supplied.
2243
2244
2245 Instead of hashrefs of plain related data (key/value pairs), you may
2246 also pass new or inserted objects. New objects (not inserted yet, see
2247 L</new>), will be inserted into their appropriate tables.
2248
2249 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2250
2251 Example of creating a new row.
2252
2253   $person_rs->create({
2254     name=>"Some Person",
2255     email=>"somebody@someplace.com"
2256   });
2257
2258 Example of creating a new row and also creating rows in a related C<has_many>
2259 or C<has_one> resultset.  Note Arrayref.
2260
2261   $artist_rs->create(
2262      { artistid => 4, name => 'Manufactured Crap', cds => [
2263         { title => 'My First CD', year => 2006 },
2264         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2265       ],
2266      },
2267   );
2268
2269 Example of creating a new row and also creating a row in a related
2270 C<belongs_to>resultset. Note Hashref.
2271
2272   $cd_rs->create({
2273     title=>"Music for Silly Walks",
2274     year=>2000,
2275     artist => {
2276       name=>"Silly Musician",
2277     }
2278   });
2279
2280 =cut
2281
2282 sub create {
2283   my ($self, $attrs) = @_;
2284   $self->throw_exception( "create needs a hashref" )
2285     unless ref $attrs eq 'HASH';
2286   return $self->new_result($attrs)->insert;
2287 }
2288
2289 =head2 find_or_create
2290
2291 =over 4
2292
2293 =item Arguments: \%vals, \%attrs?
2294
2295 =item Return Value: $rowobject
2296
2297 =back
2298
2299   $cd->cd_to_producer->find_or_create({ producer => $producer },
2300                                       { key => 'primary' });
2301
2302 Tries to find a record based on its primary key or unique constraints; if none
2303 is found, creates one and returns that instead.
2304
2305   my $cd = $schema->resultset('CD')->find_or_create({
2306     cdid   => 5,
2307     artist => 'Massive Attack',
2308     title  => 'Mezzanine',
2309     year   => 2005,
2310   });
2311
2312 Also takes an optional C<key> attribute, to search by a specific key or unique
2313 constraint. For example:
2314
2315   my $cd = $schema->resultset('CD')->find_or_create(
2316     {
2317       artist => 'Massive Attack',
2318       title  => 'Mezzanine',
2319     },
2320     { key => 'cd_artist_title' }
2321   );
2322
2323 B<Note>: Because find_or_create() reads from the database and then
2324 possibly inserts based on the result, this method is subject to a race
2325 condition. Another process could create a record in the table after
2326 the find has completed and before the create has started. To avoid
2327 this problem, use find_or_create() inside a transaction.
2328
2329 B<Note>: C<find_or_create> is probably not what you want when creating
2330 a new row in a table that uses primary keys supplied by the
2331 database. Passing in a primary key column with a value of I<undef>
2332 will cause L</find> to attempt to search for a row with a value of
2333 I<NULL>.
2334
2335 See also L</find> and L</update_or_create>. For information on how to declare
2336 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2337
2338 =cut
2339
2340 sub find_or_create {
2341   my $self     = shift;
2342   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2343   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2344   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2345     return $row;
2346   }
2347   return $self->create($hash);
2348 }
2349
2350 =head2 update_or_create
2351
2352 =over 4
2353
2354 =item Arguments: \%col_values, { key => $unique_constraint }?
2355
2356 =item Return Value: $rowobject
2357
2358 =back
2359
2360   $resultset->update_or_create({ col => $val, ... });
2361
2362 First, searches for an existing row matching one of the unique constraints
2363 (including the primary key) on the source of this resultset. If a row is
2364 found, updates it with the other given column values. Otherwise, creates a new
2365 row.
2366
2367 Takes an optional C<key> attribute to search on a specific unique constraint.
2368 For example:
2369
2370   # In your application
2371   my $cd = $schema->resultset('CD')->update_or_create(
2372     {
2373       artist => 'Massive Attack',
2374       title  => 'Mezzanine',
2375       year   => 1998,
2376     },
2377     { key => 'cd_artist_title' }
2378   );
2379
2380   $cd->cd_to_producer->update_or_create({
2381     producer => $producer,
2382     name => 'harry',
2383   }, {
2384     key => 'primary,
2385   });
2386
2387
2388 If no C<key> is specified, it searches on all unique constraints defined on the
2389 source, including the primary key.
2390
2391 If the C<key> is specified as C<primary>, it searches only on the primary key.
2392
2393 See also L</find> and L</find_or_create>. For information on how to declare
2394 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2395
2396 B<Note>: C<update_or_create> is probably not what you want when
2397 looking for a row in a table that uses primary keys supplied by the
2398 database, unless you actually have a key value. Passing in a primary
2399 key column with a value of I<undef> will cause L</find> to attempt to
2400 search for a row with a value of I<NULL>.
2401
2402 =cut
2403
2404 sub update_or_create {
2405   my $self = shift;
2406   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2407   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2408
2409   my $row = $self->find($cond, $attrs);
2410   if (defined $row) {
2411     $row->update($cond);
2412     return $row;
2413   }
2414
2415   return $self->create($cond);
2416 }
2417
2418 =head2 update_or_new
2419
2420 =over 4
2421
2422 =item Arguments: \%col_values, { key => $unique_constraint }?
2423
2424 =item Return Value: $rowobject
2425
2426 =back
2427
2428   $resultset->update_or_new({ col => $val, ... });
2429
2430 First, searches for an existing row matching one of the unique constraints
2431 (including the primary key) on the source of this resultset. If a row is
2432 found, updates it with the other given column values. Otherwise, instantiate
2433 a new result object and return it. The object will not be saved into your storage
2434 until you call L<DBIx::Class::Row/insert> on it.
2435
2436 Takes an optional C<key> attribute to search on a specific unique constraint.
2437 For example:
2438
2439   # In your application
2440   my $cd = $schema->resultset('CD')->update_or_new(
2441     {
2442       artist => 'Massive Attack',
2443       title  => 'Mezzanine',
2444       year   => 1998,
2445     },
2446     { key => 'cd_artist_title' }
2447   );
2448
2449   if ($cd->in_storage) {
2450       # the cd was updated
2451   }
2452   else {
2453       # the cd is not yet in the database, let's insert it
2454       $cd->insert;
2455   }
2456
2457 See also L</find>, L</find_or_create> and L<find_or_new>.
2458
2459 =cut
2460
2461 sub update_or_new {
2462     my $self  = shift;
2463     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2464     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2465
2466     my $row = $self->find( $cond, $attrs );
2467     if ( defined $row ) {
2468         $row->update($cond);
2469         return $row;
2470     }
2471
2472     return $self->new_result($cond);
2473 }
2474
2475 =head2 get_cache
2476
2477 =over 4
2478
2479 =item Arguments: none
2480
2481 =item Return Value: \@cache_objects?
2482
2483 =back
2484
2485 Gets the contents of the cache for the resultset, if the cache is set.
2486
2487 The cache is populated either by using the L</prefetch> attribute to
2488 L</search> or by calling L</set_cache>.
2489
2490 =cut
2491
2492 sub get_cache {
2493   shift->{all_cache};
2494 }
2495
2496 =head2 set_cache
2497
2498 =over 4
2499
2500 =item Arguments: \@cache_objects
2501
2502 =item Return Value: \@cache_objects
2503
2504 =back
2505
2506 Sets the contents of the cache for the resultset. Expects an arrayref
2507 of objects of the same class as those produced by the resultset. Note that
2508 if the cache is set the resultset will return the cached objects rather
2509 than re-querying the database even if the cache attr is not set.
2510
2511 The contents of the cache can also be populated by using the
2512 L</prefetch> attribute to L</search>.
2513
2514 =cut
2515
2516 sub set_cache {
2517   my ( $self, $data ) = @_;
2518   $self->throw_exception("set_cache requires an arrayref")
2519       if defined($data) && (ref $data ne 'ARRAY');
2520   $self->{all_cache} = $data;
2521 }
2522
2523 =head2 clear_cache
2524
2525 =over 4
2526
2527 =item Arguments: none
2528
2529 =item Return Value: []
2530
2531 =back
2532
2533 Clears the cache for the resultset.
2534
2535 =cut
2536
2537 sub clear_cache {
2538   shift->set_cache(undef);
2539 }
2540
2541 =head2 related_resultset
2542
2543 =over 4
2544
2545 =item Arguments: $relationship_name
2546
2547 =item Return Value: $resultset
2548
2549 =back
2550
2551 Returns a related resultset for the supplied relationship name.
2552
2553   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2554
2555 =cut
2556
2557 sub related_resultset {
2558   my ($self, $rel) = @_;
2559
2560   $self->{related_resultsets} ||= {};
2561   return $self->{related_resultsets}{$rel} ||= do {
2562     my $rel_info = $self->result_source->relationship_info($rel);
2563
2564     $self->throw_exception(
2565       "search_related: result source '" . $self->result_source->source_name .
2566         "' has no such relationship $rel")
2567       unless $rel_info;
2568
2569     my ($from,$seen) = $self->_chain_relationship($rel);
2570
2571     my $join_count = $seen->{$rel};
2572     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2573
2574     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2575     my %attrs = %{$self->{attrs}||{}};
2576     delete @attrs{qw(result_class alias)};
2577
2578     my $new_cache;
2579
2580     if (my $cache = $self->get_cache) {
2581       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2582         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2583                         @$cache ];
2584       }
2585     }
2586
2587     my $rel_source = $self->result_source->related_source($rel);
2588
2589     my $new = do {
2590
2591       # The reason we do this now instead of passing the alias to the
2592       # search_rs below is that if you wrap/overload resultset on the
2593       # source you need to know what alias it's -going- to have for things
2594       # to work sanely (e.g. RestrictWithObject wants to be able to add
2595       # extra query restrictions, and these may need to be $alias.)
2596
2597       my $attrs = $rel_source->resultset_attributes;
2598       local $attrs->{alias} = $alias;
2599
2600       $rel_source->resultset
2601                  ->search_rs(
2602                      undef, {
2603                        %attrs,
2604                        join => undef,
2605                        prefetch => undef,
2606                        select => undef,
2607                        as => undef,
2608                        where => $self->{cond},
2609                        seen_join => $seen,
2610                        from => $from,
2611                    });
2612     };
2613     $new->set_cache($new_cache) if $new_cache;
2614     $new;
2615   };
2616 }
2617
2618 =head2 current_source_alias
2619
2620 =over 4
2621
2622 =item Arguments: none
2623
2624 =item Return Value: $source_alias
2625
2626 =back
2627
2628 Returns the current table alias for the result source this resultset is built
2629 on, that will be used in the SQL query. Usually it is C<me>.
2630
2631 Currently the source alias that refers to the result set returned by a
2632 L</search>/L</find> family method depends on how you got to the resultset: it's
2633 C<me> by default, but eg. L</search_related> aliases it to the related result
2634 source name (and keeps C<me> referring to the original result set). The long
2635 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2636 (and make this method unnecessary).
2637
2638 Thus it's currently necessary to use this method in predefined queries (see
2639 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2640 source alias of the current result set:
2641
2642   # in a result set class
2643   sub modified_by {
2644     my ($self, $user) = @_;
2645
2646     my $me = $self->current_source_alias;
2647
2648     return $self->search(
2649       "$me.modified" => $user->id,
2650     );
2651   }
2652
2653 =cut
2654
2655 sub current_source_alias {
2656   my ($self) = @_;
2657
2658   return ($self->{attrs} || {})->{alias} || 'me';
2659 }
2660
2661 # This code is called by search_related, and makes sure there
2662 # is clear separation between the joins before, during, and
2663 # after the relationship. This information is needed later
2664 # in order to properly resolve prefetch aliases (any alias
2665 # with a relation_chain_depth less than the depth of the
2666 # current prefetch is not considered)
2667 #
2668 # The increments happen in 1/2s to make it easier to correlate the
2669 # join depth with the join path. An integer means a relationship
2670 # specified via a search_related, whereas a fraction means an added
2671 # join/prefetch via attributes
2672 sub _chain_relationship {
2673   my ($self, $rel) = @_;
2674   my $source = $self->result_source;
2675   my $attrs = $self->{attrs};
2676
2677   my $from = [ @{
2678       $attrs->{from}
2679         ||
2680       [{
2681         -source_handle => $source->handle,
2682         -alias => $attrs->{alias},
2683         $attrs->{alias} => $source->from,
2684       }]
2685   }];
2686
2687   my $seen = { %{$attrs->{seen_join} || {} } };
2688   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2689     ? $from->[-1][0]{-join_path}
2690     : [];
2691
2692
2693   # we need to take the prefetch the attrs into account before we
2694   # ->_resolve_join as otherwise they get lost - captainL
2695   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2696
2697   my @requested_joins = $source->_resolve_join(
2698     $merged,
2699     $attrs->{alias},
2700     $seen,
2701     $jpath,
2702   );
2703
2704   push @$from, @requested_joins;
2705
2706   $seen->{-relation_chain_depth} += 0.5;
2707
2708   # if $self already had a join/prefetch specified on it, the requested
2709   # $rel might very well be already included. What we do in this case
2710   # is effectively a no-op (except that we bump up the chain_depth on
2711   # the join in question so we could tell it *is* the search_related)
2712   my $already_joined;
2713
2714
2715   # we consider the last one thus reverse
2716   for my $j (reverse @requested_joins) {
2717     if ($rel eq $j->[0]{-join_path}[-1]) {
2718       $j->[0]{-relation_chain_depth} += 0.5;
2719       $already_joined++;
2720       last;
2721     }
2722   }
2723
2724 # alternative way to scan the entire chain - not backwards compatible
2725 #  for my $j (reverse @$from) {
2726 #    next unless ref $j eq 'ARRAY';
2727 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2728 #      $j->[0]{-relation_chain_depth} += 0.5;
2729 #      $already_joined++;
2730 #      last;
2731 #    }
2732 #  }
2733
2734   unless ($already_joined) {
2735     push @$from, $source->_resolve_join(
2736       $rel,
2737       $attrs->{alias},
2738       $seen,
2739       $jpath,
2740     );
2741   }
2742
2743   $seen->{-relation_chain_depth} += 0.5;
2744
2745   return ($from,$seen);
2746 }
2747
2748 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2749 sub _resolved_attrs_copy {
2750   my $self = shift;
2751   return { %{$self->_resolved_attrs (@_)} };
2752 }
2753
2754 sub _resolved_attrs {
2755   my $self = shift;
2756   return $self->{_attrs} if $self->{_attrs};
2757
2758   my $attrs  = { %{ $self->{attrs} || {} } };
2759   my $source = $self->result_source;
2760   my $alias  = $attrs->{alias};
2761
2762   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2763   my @colbits;
2764
2765   # build columns (as long as select isn't set) into a set of as/select hashes
2766   unless ( $attrs->{select} ) {
2767
2768     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2769       ? @{ delete $attrs->{columns}}
2770       : (
2771           ( delete $attrs->{columns} )
2772             ||
2773           $source->storage->_order_select_columns(
2774               $source,
2775               [ $source->columns ],
2776           )
2777         )
2778     ;
2779
2780     @colbits = map {
2781       ( ref($_) eq 'HASH' )
2782       ? $_
2783       : {
2784           (
2785             /^\Q${alias}.\E(.+)$/
2786               ? "$1"
2787               : "$_"
2788           )
2789             =>
2790           (
2791             /\./
2792               ? "$_"
2793               : "${alias}.$_"
2794           )
2795         }
2796     } @cols;
2797   }
2798
2799   # add the additional columns on
2800   foreach ( 'include_columns', '+columns' ) {
2801       push @colbits, map {
2802           ( ref($_) eq 'HASH' )
2803             ? $_
2804             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2805       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2806   }
2807
2808   # start with initial select items
2809   if ( $attrs->{select} ) {
2810     $attrs->{select} =
2811         ( ref $attrs->{select} eq 'ARRAY' )
2812       ? [ @{ $attrs->{select} } ]
2813       : [ $attrs->{select} ];
2814     $attrs->{as} = (
2815       $attrs->{as}
2816       ? (
2817         ref $attrs->{as} eq 'ARRAY'
2818         ? [ @{ $attrs->{as} } ]
2819         : [ $attrs->{as} ]
2820         )
2821       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2822     );
2823   }
2824   else {
2825
2826     # otherwise we intialise select & as to empty
2827     $attrs->{select} = [];
2828     $attrs->{as}     = [];
2829   }
2830
2831   # now add colbits to select/as
2832   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2833   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2834
2835   my $adds;
2836   if ( $adds = delete $attrs->{'+select'} ) {
2837     $adds = [$adds] unless ref $adds eq 'ARRAY';
2838     push(
2839       @{ $attrs->{select} },
2840       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2841     );
2842   }
2843   if ( $adds = delete $attrs->{'+as'} ) {
2844     $adds = [$adds] unless ref $adds eq 'ARRAY';
2845     push( @{ $attrs->{as} }, @$adds );
2846   }
2847
2848   $attrs->{from} ||= [ {
2849     -source_handle => $source->handle,
2850     -alias => $self->{attrs}{alias},
2851     $self->{attrs}{alias} => $source->from,
2852   } ];
2853
2854   if ( $attrs->{join} || $attrs->{prefetch} ) {
2855
2856     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2857       if ref $attrs->{from} ne 'ARRAY';
2858
2859     my $join = delete $attrs->{join} || {};
2860
2861     if ( defined $attrs->{prefetch} ) {
2862       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2863     }
2864
2865     $attrs->{from} =    # have to copy here to avoid corrupting the original
2866       [
2867         @{ $attrs->{from} },
2868         $source->_resolve_join(
2869           $join,
2870           $alias,
2871           { %{ $attrs->{seen_join} || {} } },
2872           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2873             ? $attrs->{from}[-1][0]{-join_path}
2874             : []
2875           ,
2876         )
2877       ];
2878   }
2879
2880   if ( defined $attrs->{order_by} ) {
2881     $attrs->{order_by} = (
2882       ref( $attrs->{order_by} ) eq 'ARRAY'
2883       ? [ @{ $attrs->{order_by} } ]
2884       : [ $attrs->{order_by} || () ]
2885     );
2886   }
2887
2888   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2889     $attrs->{group_by} = [ $attrs->{group_by} ];
2890   }
2891
2892   # generate the distinct induced group_by early, as prefetch will be carried via a
2893   # subquery (since a group_by is present)
2894   if (delete $attrs->{distinct}) {
2895     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2896   }
2897
2898   $attrs->{collapse} ||= {};
2899   if ( my $prefetch = delete $attrs->{prefetch} ) {
2900     $prefetch = $self->_merge_attr( {}, $prefetch );
2901
2902     my $prefetch_ordering = [];
2903
2904     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2905
2906     my @prefetch =
2907       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2908
2909     # we need to somehow mark which columns came from prefetch
2910     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2911
2912     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2913     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2914
2915     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2916     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2917   }
2918
2919   # if both page and offset are specified, produce a combined offset
2920   # even though it doesn't make much sense, this is what pre 081xx has
2921   # been doing
2922   if (my $page = delete $attrs->{page}) {
2923     $attrs->{offset} =
2924       ($attrs->{rows} * ($page - 1))
2925             +
2926       ($attrs->{offset} || 0)
2927     ;
2928   }
2929
2930   return $self->{_attrs} = $attrs;
2931 }
2932
2933 sub _joinpath_aliases {
2934   my ($self, $fromspec, $seen) = @_;
2935
2936   my $paths = {};
2937   return $paths unless ref $fromspec eq 'ARRAY';
2938
2939   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2940
2941   if (int ($cur_depth) != $cur_depth) {
2942     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2943   }
2944
2945   for my $j (@$fromspec) {
2946
2947     next if ref $j ne 'ARRAY';
2948     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2949
2950     my $jpath = $j->[0]{-join_path};
2951
2952     my $p = $paths;
2953     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2954     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2955   }
2956
2957   return $paths;
2958 }
2959
2960 sub _rollout_attr {
2961   my ($self, $attr) = @_;
2962
2963   if (ref $attr eq 'HASH') {
2964     return $self->_rollout_hash($attr);
2965   } elsif (ref $attr eq 'ARRAY') {
2966     return $self->_rollout_array($attr);
2967   } else {
2968     return [$attr];
2969   }
2970 }
2971
2972 sub _rollout_array {
2973   my ($self, $attr) = @_;
2974
2975   my @rolled_array;
2976   foreach my $element (@{$attr}) {
2977     if (ref $element eq 'HASH') {
2978       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2979     } elsif (ref $element eq 'ARRAY') {
2980       #  XXX - should probably recurse here
2981       push( @rolled_array, @{$self->_rollout_array($element)} );
2982     } else {
2983       push( @rolled_array, $element );
2984     }
2985   }
2986   return \@rolled_array;
2987 }
2988
2989 sub _rollout_hash {
2990   my ($self, $attr) = @_;
2991
2992   my @rolled_array;
2993   foreach my $key (keys %{$attr}) {
2994     push( @rolled_array, { $key => $attr->{$key} } );
2995   }
2996   return \@rolled_array;
2997 }
2998
2999 sub _calculate_score {
3000   my ($self, $a, $b) = @_;
3001
3002   if (ref $b eq 'HASH') {
3003     my ($b_key) = keys %{$b};
3004     if (ref $a eq 'HASH') {
3005       my ($a_key) = keys %{$a};
3006       if ($a_key eq $b_key) {
3007         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3008       } else {
3009         return 0;
3010       }
3011     } else {
3012       return ($a eq $b_key) ? 1 : 0;
3013     }
3014   } else {
3015     if (ref $a eq 'HASH') {
3016       my ($a_key) = keys %{$a};
3017       return ($b eq $a_key) ? 1 : 0;
3018     } else {
3019       return ($b eq $a) ? 1 : 0;
3020     }
3021   }
3022 }
3023
3024 sub _merge_attr {
3025   my ($self, $orig, $import) = @_;
3026
3027   return $import unless defined($orig);
3028   return $orig unless defined($import);
3029
3030   $orig = $self->_rollout_attr($orig);
3031   $import = $self->_rollout_attr($import);
3032
3033   my $seen_keys;
3034   foreach my $import_element ( @{$import} ) {
3035     # find best candidate from $orig to merge $b_element into
3036     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3037     foreach my $orig_element ( @{$orig} ) {
3038       my $score = $self->_calculate_score( $orig_element, $import_element );
3039       if ($score > $best_candidate->{score}) {
3040         $best_candidate->{position} = $position;
3041         $best_candidate->{score} = $score;
3042       }
3043       $position++;
3044     }
3045     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3046
3047     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3048       push( @{$orig}, $import_element );
3049     } else {
3050       my $orig_best = $orig->[$best_candidate->{position}];
3051       # merge orig_best and b_element together and replace original with merged
3052       if (ref $orig_best ne 'HASH') {
3053         $orig->[$best_candidate->{position}] = $import_element;
3054       } elsif (ref $import_element eq 'HASH') {
3055         my ($key) = keys %{$orig_best};
3056         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3057       }
3058     }
3059     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3060   }
3061
3062   return $orig;
3063 }
3064
3065 sub result_source {
3066     my $self = shift;
3067
3068     if (@_) {
3069         $self->_source_handle($_[0]->handle);
3070     } else {
3071         $self->_source_handle->resolve;
3072     }
3073 }
3074
3075 =head2 throw_exception
3076
3077 See L<DBIx::Class::Schema/throw_exception> for details.
3078
3079 =cut
3080
3081 sub throw_exception {
3082   my $self=shift;
3083   if (ref $self && $self->_source_handle->schema) {
3084     $self->_source_handle->schema->throw_exception(@_)
3085   } else {
3086     croak(@_);
3087   }
3088
3089 }
3090
3091 # XXX: FIXME: Attributes docs need clearing up
3092
3093 =head1 ATTRIBUTES
3094
3095 Attributes are used to refine a ResultSet in various ways when
3096 searching for data. They can be passed to any method which takes an
3097 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3098 L</count>.
3099
3100 These are in no particular order:
3101
3102 =head2 order_by
3103
3104 =over 4
3105
3106 =item Value: ( $order_by | \@order_by | \%order_by )
3107
3108 =back
3109
3110 Which column(s) to order the results by.
3111
3112 [The full list of suitable values is documented in
3113 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3114 common options.]
3115
3116 If a single column name, or an arrayref of names is supplied, the
3117 argument is passed through directly to SQL. The hashref syntax allows
3118 for connection-agnostic specification of ordering direction:
3119
3120  For descending order:
3121
3122   order_by => { -desc => [qw/col1 col2 col3/] }
3123
3124  For explicit ascending order:
3125
3126   order_by => { -asc => 'col' }
3127
3128 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3129 supported, although you are strongly encouraged to use the hashref
3130 syntax as outlined above.
3131
3132 =head2 columns
3133
3134 =over 4
3135
3136 =item Value: \@columns
3137
3138 =back
3139
3140 Shortcut to request a particular set of columns to be retrieved. Each
3141 column spec may be a string (a table column name), or a hash (in which
3142 case the key is the C<as> value, and the value is used as the C<select>
3143 expression). Adds C<me.> onto the start of any column without a C<.> in
3144 it and sets C<select> from that, then auto-populates C<as> from
3145 C<select> as normal. (You may also use the C<cols> attribute, as in
3146 earlier versions of DBIC.)
3147
3148 =head2 +columns
3149
3150 =over 4
3151
3152 =item Value: \@columns
3153
3154 =back
3155
3156 Indicates additional columns to be selected from storage. Works the same
3157 as L</columns> but adds columns to the selection. (You may also use the
3158 C<include_columns> attribute, as in earlier versions of DBIC). For
3159 example:-
3160
3161   $schema->resultset('CD')->search(undef, {
3162     '+columns' => ['artist.name'],
3163     join => ['artist']
3164   });
3165
3166 would return all CDs and include a 'name' column to the information
3167 passed to object inflation. Note that the 'artist' is the name of the
3168 column (or relationship) accessor, and 'name' is the name of the column
3169 accessor in the related table.
3170
3171 =head2 include_columns
3172
3173 =over 4
3174
3175 =item Value: \@columns
3176
3177 =back
3178
3179 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3180
3181 =head2 select
3182
3183 =over 4
3184
3185 =item Value: \@select_columns
3186
3187 =back
3188
3189 Indicates which columns should be selected from the storage. You can use
3190 column names, or in the case of RDBMS back ends, function or stored procedure
3191 names:
3192
3193   $rs = $schema->resultset('Employee')->search(undef, {
3194     select => [
3195       'name',
3196       { count => 'employeeid' },
3197       { sum => 'salary' }
3198     ]
3199   });
3200
3201 When you use function/stored procedure names and do not supply an C<as>
3202 attribute, the column names returned are storage-dependent. E.g. MySQL would
3203 return a column named C<count(employeeid)> in the above example.
3204
3205 =head2 +select
3206
3207 =over 4
3208
3209 Indicates additional columns to be selected from storage.  Works the same as
3210 L</select> but adds columns to the selection.
3211
3212 =back
3213
3214 =head2 +as
3215
3216 =over 4
3217
3218 Indicates additional column names for those added via L</+select>. See L</as>.
3219
3220 =back
3221
3222 =head2 as
3223
3224 =over 4
3225
3226 =item Value: \@inflation_names
3227
3228 =back
3229
3230 Indicates column names for object inflation. That is, C<as>
3231 indicates the name that the column can be accessed as via the
3232 C<get_column> method (or via the object accessor, B<if one already
3233 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3234
3235 The C<as> attribute is used in conjunction with C<select>,
3236 usually when C<select> contains one or more function or stored
3237 procedure names:
3238
3239   $rs = $schema->resultset('Employee')->search(undef, {
3240     select => [
3241       'name',
3242       { count => 'employeeid' }
3243     ],
3244     as => ['name', 'employee_count'],
3245   });
3246
3247   my $employee = $rs->first(); # get the first Employee
3248
3249 If the object against which the search is performed already has an accessor
3250 matching a column name specified in C<as>, the value can be retrieved using
3251 the accessor as normal:
3252
3253   my $name = $employee->name();
3254
3255 If on the other hand an accessor does not exist in the object, you need to
3256 use C<get_column> instead:
3257
3258   my $employee_count = $employee->get_column('employee_count');
3259
3260 You can create your own accessors if required - see
3261 L<DBIx::Class::Manual::Cookbook> for details.
3262
3263 Please note: This will NOT insert an C<AS employee_count> into the SQL
3264 statement produced, it is used for internal access only. Thus
3265 attempting to use the accessor in an C<order_by> clause or similar
3266 will fail miserably.
3267
3268 To get around this limitation, you can supply literal SQL to your
3269 C<select> attibute that contains the C<AS alias> text, eg:
3270
3271   select => [\'myfield AS alias']
3272
3273 =head2 join
3274
3275 =over 4
3276
3277 =item Value: ($rel_name | \@rel_names | \%rel_names)
3278
3279 =back
3280
3281 Contains a list of relationships that should be joined for this query.  For
3282 example:
3283
3284   # Get CDs by Nine Inch Nails
3285   my $rs = $schema->resultset('CD')->search(
3286     { 'artist.name' => 'Nine Inch Nails' },
3287     { join => 'artist' }
3288   );
3289
3290 Can also contain a hash reference to refer to the other relation's relations.
3291 For example:
3292
3293   package MyApp::Schema::Track;
3294   use base qw/DBIx::Class/;
3295   __PACKAGE__->table('track');
3296   __PACKAGE__->add_columns(qw/trackid cd position title/);
3297   __PACKAGE__->set_primary_key('trackid');
3298   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3299   1;
3300
3301   # In your application
3302   my $rs = $schema->resultset('Artist')->search(
3303     { 'track.title' => 'Teardrop' },
3304     {
3305       join     => { cd => 'track' },
3306       order_by => 'artist.name',
3307     }
3308   );
3309
3310 You need to use the relationship (not the table) name in  conditions,
3311 because they are aliased as such. The current table is aliased as "me", so
3312 you need to use me.column_name in order to avoid ambiguity. For example:
3313
3314   # Get CDs from 1984 with a 'Foo' track
3315   my $rs = $schema->resultset('CD')->search(
3316     {
3317       'me.year' => 1984,
3318       'tracks.name' => 'Foo'
3319     },
3320     { join => 'tracks' }
3321   );
3322
3323 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3324 similarly for a third time). For e.g.
3325
3326   my $rs = $schema->resultset('Artist')->search({
3327     'cds.title'   => 'Down to Earth',
3328     'cds_2.title' => 'Popular',
3329   }, {
3330     join => [ qw/cds cds/ ],
3331   });
3332
3333 will return a set of all artists that have both a cd with title 'Down
3334 to Earth' and a cd with title 'Popular'.
3335
3336 If you want to fetch related objects from other tables as well, see C<prefetch>
3337 below.
3338
3339 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3340
3341 =head2 prefetch
3342
3343 =over 4
3344
3345 =item Value: ($rel_name | \@rel_names | \%rel_names)
3346
3347 =back
3348
3349 Contains one or more relationships that should be fetched along with
3350 the main query (when they are accessed afterwards the data will
3351 already be available, without extra queries to the database).  This is
3352 useful for when you know you will need the related objects, because it
3353 saves at least one query:
3354
3355   my $rs = $schema->resultset('Tag')->search(
3356     undef,
3357     {
3358       prefetch => {
3359         cd => 'artist'
3360       }
3361     }
3362   );
3363
3364 The initial search results in SQL like the following:
3365
3366   SELECT tag.*, cd.*, artist.* FROM tag
3367   JOIN cd ON tag.cd = cd.cdid
3368   JOIN artist ON cd.artist = artist.artistid
3369
3370 L<DBIx::Class> has no need to go back to the database when we access the
3371 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3372 case.
3373
3374 Simple prefetches will be joined automatically, so there is no need
3375 for a C<join> attribute in the above search.
3376
3377 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3378 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3379 with an accessor type of 'single' or 'filter'). A more complex example that
3380 prefetches an artists cds, the tracks on those cds, and the tags associted
3381 with that artist is given below (assuming many-to-many from artists to tags):
3382
3383  my $rs = $schema->resultset('Artist')->search(
3384    undef,
3385    {
3386      prefetch => [
3387        { cds => 'tracks' },
3388        { artist_tags => 'tags' }
3389      ]
3390    }
3391  );
3392
3393
3394 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3395 attributes will be ignored.
3396
3397 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3398 exactly as you might expect.
3399
3400 =over 4
3401
3402 =item *
3403
3404 Prefetch uses the L</cache> to populate the prefetched relationships. This
3405 may or may not be what you want.
3406
3407 =item *
3408
3409 If you specify a condition on a prefetched relationship, ONLY those
3410 rows that match the prefetched condition will be fetched into that relationship.
3411 This means that adding prefetch to a search() B<may alter> what is returned by
3412 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3413
3414   my $artist_rs = $schema->resultset('Artist')->search({
3415       'cds.year' => 2008,
3416   }, {
3417       join => 'cds',
3418   });
3419
3420   my $count = $artist_rs->first->cds->count;
3421
3422   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3423
3424   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3425
3426   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3427
3428 that cmp_ok() may or may not pass depending on the datasets involved. This
3429 behavior may or may not survive the 0.09 transition.
3430
3431 =back
3432
3433 =head2 page
3434
3435 =over 4
3436
3437 =item Value: $page
3438
3439 =back
3440
3441 Makes the resultset paged and specifies the page to retrieve. Effectively
3442 identical to creating a non-pages resultset and then calling ->page($page)
3443 on it.
3444
3445 If L<rows> attribute is not specified it defaults to 10 rows per page.
3446
3447 When you have a paged resultset, L</count> will only return the number
3448 of rows in the page. To get the total, use the L</pager> and call
3449 C<total_entries> on it.
3450
3451 =head2 rows
3452
3453 =over 4
3454
3455 =item Value: $rows
3456
3457 =back
3458
3459 Specifes the maximum number of rows for direct retrieval or the number of
3460 rows per page if the page attribute or method is used.
3461
3462 =head2 offset
3463
3464 =over 4
3465
3466 =item Value: $offset
3467
3468 =back
3469
3470 Specifies the (zero-based) row number for the  first row to be returned, or the
3471 of the first row of the first page if paging is used.
3472
3473 =head2 group_by
3474
3475 =over 4
3476
3477 =item Value: \@columns
3478
3479 =back
3480
3481 A arrayref of columns to group by. Can include columns of joined tables.
3482
3483   group_by => [qw/ column1 column2 ... /]
3484
3485 =head2 having
3486
3487 =over 4
3488
3489 =item Value: $condition
3490
3491 =back
3492
3493 HAVING is a select statement attribute that is applied between GROUP BY and
3494 ORDER BY. It is applied to the after the grouping calculations have been
3495 done.
3496
3497   having => { 'count(employee)' => { '>=', 100 } }
3498
3499 =head2 distinct
3500
3501 =over 4
3502
3503 =item Value: (0 | 1)
3504
3505 =back
3506
3507 Set to 1 to group by all columns.
3508
3509 =head2 where
3510
3511 =over 4
3512
3513 Adds to the WHERE clause.
3514
3515   # only return rows WHERE deleted IS NULL for all searches
3516   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3517
3518 Can be overridden by passing C<{ where => undef }> as an attribute
3519 to a resulset.
3520
3521 =back
3522
3523 =head2 cache
3524
3525 Set to 1 to cache search results. This prevents extra SQL queries if you
3526 revisit rows in your ResultSet:
3527
3528   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3529
3530   while( my $artist = $resultset->next ) {
3531     ... do stuff ...
3532   }
3533
3534   $rs->first; # without cache, this would issue a query
3535
3536 By default, searches are not cached.
3537
3538 For more examples of using these attributes, see
3539 L<DBIx::Class::Manual::Cookbook>.
3540
3541 =head2 from
3542
3543 =over 4
3544
3545 =item Value: \@from_clause
3546
3547 =back
3548
3549 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3550 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3551 clauses.
3552
3553 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3554
3555 C<join> will usually do what you need and it is strongly recommended that you
3556 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3557 And we really do mean "cannot", not just tried and failed. Attempting to use
3558 this because you're having problems with C<join> is like trying to use x86
3559 ASM because you've got a syntax error in your C. Trust us on this.
3560
3561 Now, if you're still really, really sure you need to use this (and if you're
3562 not 100% sure, ask the mailing list first), here's an explanation of how this
3563 works.
3564
3565 The syntax is as follows -
3566
3567   [
3568     { <alias1> => <table1> },
3569     [
3570       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3571       [], # nested JOIN (optional)
3572       { <table1.column1> => <table2.column2>, ... (more conditions) },
3573     ],
3574     # More of the above [ ] may follow for additional joins
3575   ]
3576
3577   <table1> <alias1>
3578   JOIN
3579     <table2> <alias2>
3580     [JOIN ...]
3581   ON <table1.column1> = <table2.column2>
3582   <more joins may follow>
3583
3584 An easy way to follow the examples below is to remember the following:
3585
3586     Anything inside "[]" is a JOIN
3587     Anything inside "{}" is a condition for the enclosing JOIN
3588
3589 The following examples utilize a "person" table in a family tree application.
3590 In order to express parent->child relationships, this table is self-joined:
3591
3592     # Person->belongs_to('father' => 'Person');
3593     # Person->belongs_to('mother' => 'Person');
3594
3595 C<from> can be used to nest joins. Here we return all children with a father,
3596 then search against all mothers of those children:
3597
3598   $rs = $schema->resultset('Person')->search(
3599       undef,
3600       {
3601           alias => 'mother', # alias columns in accordance with "from"
3602           from => [
3603               { mother => 'person' },
3604               [
3605                   [
3606                       { child => 'person' },
3607                       [
3608                           { father => 'person' },
3609                           { 'father.person_id' => 'child.father_id' }
3610                       ]
3611                   ],
3612                   { 'mother.person_id' => 'child.mother_id' }
3613               ],
3614           ]
3615       },
3616   );
3617
3618   # Equivalent SQL:
3619   # SELECT mother.* FROM person mother
3620   # JOIN (
3621   #   person child
3622   #   JOIN person father
3623   #   ON ( father.person_id = child.father_id )
3624   # )
3625   # ON ( mother.person_id = child.mother_id )
3626
3627 The type of any join can be controlled manually. To search against only people
3628 with a father in the person table, we could explicitly use C<INNER JOIN>:
3629
3630     $rs = $schema->resultset('Person')->search(
3631         undef,
3632         {
3633             alias => 'child', # alias columns in accordance with "from"
3634             from => [
3635                 { child => 'person' },
3636                 [
3637                     { father => 'person', -join_type => 'inner' },
3638                     { 'father.id' => 'child.father_id' }
3639                 ],
3640             ]
3641         },
3642     );
3643
3644     # Equivalent SQL:
3645     # SELECT child.* FROM person child
3646     # INNER JOIN person father ON child.father_id = father.id
3647
3648 You can select from a subquery by passing a resultset to from as follows.
3649
3650     $schema->resultset('Artist')->search(
3651         undef,
3652         {   alias => 'artist2',
3653             from  => [ { artist2 => $artist_rs->as_query } ],
3654         } );
3655
3656     # and you'll get sql like this..
3657     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3658     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3659
3660 If you need to express really complex joins, you
3661 can supply literal SQL to C<from> via a scalar reference. In this case
3662 the contents of the scalar will replace the table name associated with the
3663 resultsource.
3664
3665 WARNING: This technique might very well not work as expected on chained
3666 searches - you have been warned.
3667
3668     # Assuming the Event resultsource is defined as:
3669
3670         MySchema::Event->add_columns (
3671             sequence => {
3672                 data_type => 'INT',
3673                 is_auto_increment => 1,
3674             },
3675             location => {
3676                 data_type => 'INT',
3677             },
3678             type => {
3679                 data_type => 'INT',
3680             },
3681         );
3682         MySchema::Event->set_primary_key ('sequence');
3683
3684     # This will get back the latest event for every location. The column
3685     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3686     # combo to limit the resultset
3687
3688     $rs = $schema->resultset('Event');
3689     $table = $rs->result_source->name;
3690     $latest = $rs->search (
3691         undef,
3692         { from => \ "
3693             (SELECT e1.* FROM $table e1
3694                 JOIN $table e2
3695                     ON e1.location = e2.location
3696                     AND e1.sequence < e2.sequence
3697                 WHERE e2.sequence is NULL
3698             ) me",
3699         },
3700     );
3701
3702     # Equivalent SQL (with the DBIC chunks added):
3703
3704     SELECT me.sequence, me.location, me.type FROM
3705        (SELECT e1.* FROM events e1
3706            JOIN events e2
3707                ON e1.location = e2.location
3708                AND e1.sequence < e2.sequence
3709            WHERE e2.sequence is NULL
3710        ) me;
3711
3712 =head2 for
3713
3714 =over 4
3715
3716 =item Value: ( 'update' | 'shared' )
3717
3718 =back
3719
3720 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3721 ... FOR SHARED.
3722
3723 =cut
3724
3725 1;