lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 665
 666   return $self->{cursor}
 667     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 668           $attrs->{where},$attrs);
 669 }
 670
 671 =head2 single
 672
 673 =over 4
 674
 675 =item Arguments: $cond?
 676
 677 =item Return Value: $row_object?
 678
 679 =back
 680
 681   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 682
 683 Inflates the first result without creating a cursor if the resultset has
 684 any records in it; if not returns nothing. Used by L</find> as a lean version of
 685 L</search>.
 686
 687 While this method can take an optional search condition (just like L</search>)
 688 being a fast-code-path it does not recognize search attributes. If you need to
 689 add extra joins or similar, call L</search> and then chain-call L</single> on the
 690 L<DBIx::Class::ResultSet> returned.
 691
 692 =over
 693
 694 =item B<Note>
 695
 696 As of 0.08100, this method enforces the assumption that the preceeding
 697 query returns only one row. If more than one row is returned, you will receive
 698 a warning:
 699
 700   Query returned more than one row
 701
 702 In this case, you should be using L</first> or L</find> instead, or if you really
 703 know what you are doing, use the L</rows> attribute to explicitly limit the size
 704 of the resultset.
 705
 706 =back
 707
 708 =cut
 709
 710 sub single {
 711   my ($self, $where) = @_;
 712   if(@_ > 2) {
 713       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 714   }
 715
 716   my $attrs = $self->_resolved_attrs_copy;
 717   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 718
 719   if ($where) {
 720     if (defined $attrs->{where}) {
 721       $attrs->{where} = {
 722         '-and' =>
 723             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 724                $where, delete $attrs->{where} ]
 725       };
 726     } else {
 727       $attrs->{where} = $where;
 728     }
 729   }
 730
 731 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 732 #  unless ($self->_is_unique_query($attrs->{where})) {
 733 #    carp "Query not guaranteed to return a single row"
 734 #      . "; please declare your unique constraints or use search instead";
 735 #  }
 736
 737   my @data = $self->result_source->storage->select_single(
 738     $attrs->{from}, $attrs->{select},
 739     $attrs->{where}, $attrs
 740   );
 741
 742   return (@data ? ($self->_construct_object(@data))[0] : undef);
 743 }
 744
 745 # _gen_virtual_order
 746 #
 747 # This is a horrble hack, but seems like the best we can do at this point
 748 # Some limit emulations (Top) require an ordered resultset in order to
 749 # function at all. So supply a PK order to be used if necessary
 750
 751 sub _gen_virtual_order {
 752   return [ shift->result_source->primary_columns ];
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp (
 874     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 875    .' Instead use ->search({ x => { -like => "y%" } })'
 876    .' (note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. Passing arguments is equivalent to
1149 C<< $rs->search ($cond, \%attrs)->count >>
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my $meth = $self->_has_attr (qw/prefetch collapse distinct group_by/)
1159     ? 'count_grouped'
1160     : 'count'
1161   ;
1162
1163   my $attrs = $self->_resolved_attrs_copy;
1164   my $rsrc = $self->result_source;
1165
1166   return $rsrc->storage->$meth ($rsrc, $attrs);
1167 }
1168
1169 sub _bool {
1170   return 1;
1171 }
1172
1173 =head2 count_literal
1174
1175 =over 4
1176
1177 =item Arguments: $sql_fragment, @bind_values
1178
1179 =item Return Value: $count
1180
1181 =back
1182
1183 Counts the results in a literal query. Equivalent to calling L</search_literal>
1184 with the passed arguments, then L</count>.
1185
1186 =cut
1187
1188 sub count_literal { shift->search_literal(@_)->count; }
1189
1190 =head2 all
1191
1192 =over 4
1193
1194 =item Arguments: none
1195
1196 =item Return Value: @objects
1197
1198 =back
1199
1200 Returns all elements in the resultset. Called implicitly if the resultset
1201 is returned in list context.
1202
1203 =cut
1204
1205 sub all {
1206   my $self = shift;
1207   if(@_) {
1208       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1209   }
1210
1211   return @{ $self->get_cache } if $self->get_cache;
1212
1213   my @obj;
1214
1215   # TODO: don't call resolve here
1216   if (keys %{$self->_resolved_attrs->{collapse}}) {
1217 #  if ($self->{attrs}{prefetch}) {
1218       # Using $self->cursor->all is really just an optimisation.
1219       # If we're collapsing has_many prefetches it probably makes
1220       # very little difference, and this is cleaner than hacking
1221       # _construct_object to survive the approach
1222     my @row = $self->cursor->next;
1223     while (@row) {
1224       push(@obj, $self->_construct_object(@row));
1225       @row = (exists $self->{stashed_row}
1226                ? @{delete $self->{stashed_row}}
1227                : $self->cursor->next);
1228     }
1229   } else {
1230     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1231   }
1232
1233   $self->set_cache(\@obj) if $self->{attrs}{cache};
1234   return @obj;
1235 }
1236
1237 =head2 reset
1238
1239 =over 4
1240
1241 =item Arguments: none
1242
1243 =item Return Value: $self
1244
1245 =back
1246
1247 Resets the resultset's cursor, so you can iterate through the elements again.
1248
1249 =cut
1250
1251 sub reset {
1252   my ($self) = @_;
1253   delete $self->{_attrs} if exists $self->{_attrs};
1254   $self->{all_cache_position} = 0;
1255   $self->cursor->reset;
1256   return $self;
1257 }
1258
1259 =head2 first
1260
1261 =over 4
1262
1263 =item Arguments: none
1264
1265 =item Return Value: $object?
1266
1267 =back
1268
1269 Resets the resultset and returns an object for the first result (if the
1270 resultset returns anything).
1271
1272 =cut
1273
1274 sub first {
1275   return $_[0]->reset->next;
1276 }
1277
1278
1279 # _rs_update_delete
1280 #
1281 # Determines whether and what type of subquery is required for the $rs operation.
1282 # If grouping is necessary either supplies its own, or verifies the current one
1283 # After all is done delegates to the proper storage method.
1284
1285 sub _rs_update_delete {
1286   my ($self, $op, $values) = @_;
1287
1288   my $rsrc = $self->result_source;
1289
1290   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1291   my $needs_subq = $self->_has_attr (qw/row offset page/);
1292
1293   if ($needs_group_by_subq or $needs_subq) {
1294
1295     # make a new $rs selecting only the PKs (that's all we really need)
1296     my $attrs = $self->_resolved_attrs_copy;
1297
1298     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1299     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1300
1301     if ($needs_group_by_subq) {
1302       # make sure no group_by was supplied, or if there is one - make sure it matches
1303       # the columns compiled above perfectly. Anything else can not be sanely executed
1304       # on most databases so croak right then and there
1305
1306       if (my $g = $attrs->{group_by}) {
1307         my @current_group_by = map
1308           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1309           (ref $g eq 'ARRAY' ? @$g : $g );
1310
1311         if (
1312           join ("\x00", sort @current_group_by)
1313             ne
1314           join ("\x00", sort @{$attrs->{columns}} )
1315         ) {
1316           $self->throw_exception (
1317             "You have just attempted a $op operation on a resultset which does group_by"
1318             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1319             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1320             . ' kind of queries. Please retry the operation with a modified group_by or'
1321             . ' without using one at all.'
1322           );
1323         }
1324       }
1325       else {
1326         $attrs->{group_by} = $attrs->{columns};
1327       }
1328     }
1329
1330     my $subrs = (ref $self)->new($rsrc, $attrs);
1331
1332     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1333   }
1334   else {
1335     return $rsrc->storage->$op(
1336       $rsrc,
1337       $op eq 'update' ? $values : (),
1338       $self->_cond_for_update_delete,
1339     );
1340   }
1341 }
1342
1343
1344 # _cond_for_update_delete
1345 #
1346 # update/delete require the condition to be modified to handle
1347 # the differing SQL syntax available.  This transforms the $self->{cond}
1348 # appropriately, returning the new condition.
1349
1350 sub _cond_for_update_delete {
1351   my ($self, $full_cond) = @_;
1352   my $cond = {};
1353
1354   $full_cond ||= $self->{cond};
1355   # No-op. No condition, we're updating/deleting everything
1356   return $cond unless ref $full_cond;
1357
1358   if (ref $full_cond eq 'ARRAY') {
1359     $cond = [
1360       map {
1361         my %hash;
1362         foreach my $key (keys %{$_}) {
1363           $key =~ /([^.]+)$/;
1364           $hash{$1} = $_->{$key};
1365         }
1366         \%hash;
1367       } @{$full_cond}
1368     ];
1369   }
1370   elsif (ref $full_cond eq 'HASH') {
1371     if ((keys %{$full_cond})[0] eq '-and') {
1372       $cond->{-and} = [];
1373       my @cond = @{$full_cond->{-and}};
1374        for (my $i = 0; $i < @cond; $i++) {
1375         my $entry = $cond[$i];
1376         my $hash;
1377         if (ref $entry eq 'HASH') {
1378           $hash = $self->_cond_for_update_delete($entry);
1379         }
1380         else {
1381           $entry =~ /([^.]+)$/;
1382           $hash->{$1} = $cond[++$i];
1383         }
1384         push @{$cond->{-and}}, $hash;
1385       }
1386     }
1387     else {
1388       foreach my $key (keys %{$full_cond}) {
1389         $key =~ /([^.]+)$/;
1390         $cond->{$1} = $full_cond->{$key};
1391       }
1392     }
1393   }
1394   else {
1395     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1396   }
1397
1398   return $cond;
1399 }
1400
1401
1402 =head2 update
1403
1404 =over 4
1405
1406 =item Arguments: \%values
1407
1408 =item Return Value: $storage_rv
1409
1410 =back
1411
1412 Sets the specified columns in the resultset to the supplied values in a
1413 single query. Return value will be true if the update succeeded or false
1414 if no records were updated; exact type of success value is storage-dependent.
1415
1416 =cut
1417
1418 sub update {
1419   my ($self, $values) = @_;
1420   $self->throw_exception('Values for update must be a hash')
1421     unless ref $values eq 'HASH';
1422
1423   return $self->_rs_update_delete ('update', $values);
1424 }
1425
1426 =head2 update_all
1427
1428 =over 4
1429
1430 =item Arguments: \%values
1431
1432 =item Return Value: 1
1433
1434 =back
1435
1436 Fetches all objects and updates them one at a time. Note that C<update_all>
1437 will run DBIC cascade triggers, while L</update> will not.
1438
1439 =cut
1440
1441 sub update_all {
1442   my ($self, $values) = @_;
1443   $self->throw_exception('Values for update_all must be a hash')
1444     unless ref $values eq 'HASH';
1445   foreach my $obj ($self->all) {
1446     $obj->set_columns($values)->update;
1447   }
1448   return 1;
1449 }
1450
1451 =head2 delete
1452
1453 =over 4
1454
1455 =item Arguments: none
1456
1457 =item Return Value: $storage_rv
1458
1459 =back
1460
1461 Deletes the contents of the resultset from its result source. Note that this
1462 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1463 to run. See also L<DBIx::Class::Row/delete>.
1464
1465 Return value will be the amount of rows deleted; exact type of return value
1466 is storage-dependent.
1467
1468 =cut
1469
1470 sub delete {
1471   my $self = shift;
1472   $self->throw_exception('delete does not accept any arguments')
1473     if @_;
1474
1475   return $self->_rs_update_delete ('delete');
1476 }
1477
1478 =head2 delete_all
1479
1480 =over 4
1481
1482 =item Arguments: none
1483
1484 =item Return Value: 1
1485
1486 =back
1487
1488 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1489 will run DBIC cascade triggers, while L</delete> will not.
1490
1491 =cut
1492
1493 sub delete_all {
1494   my $self = shift;
1495   $self->throw_exception('delete_all does not accept any arguments')
1496     if @_;
1497
1498   $_->delete for $self->all;
1499   return 1;
1500 }
1501
1502 =head2 populate
1503
1504 =over 4
1505
1506 =item Arguments: \@data;
1507
1508 =back
1509
1510 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1511 For the arrayref of hashrefs style each hashref should be a structure suitable
1512 forsubmitting to a $resultset->create(...) method.
1513
1514 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1515 to insert the data, as this is a faster method.
1516
1517 Otherwise, each set of data is inserted into the database using
1518 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1519 objects is returned.
1520
1521 Example:  Assuming an Artist Class that has many CDs Classes relating:
1522
1523   my $Artist_rs = $schema->resultset("Artist");
1524
1525   ## Void Context Example
1526   $Artist_rs->populate([
1527      { artistid => 4, name => 'Manufactured Crap', cds => [
1528         { title => 'My First CD', year => 2006 },
1529         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1530       ],
1531      },
1532      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1533         { title => 'My parents sold me to a record company' ,year => 2005 },
1534         { title => 'Why Am I So Ugly?', year => 2006 },
1535         { title => 'I Got Surgery and am now Popular', year => 2007 }
1536       ],
1537      },
1538   ]);
1539
1540   ## Array Context Example
1541   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1542     { name => "Artist One"},
1543     { name => "Artist Two"},
1544     { name => "Artist Three", cds=> [
1545     { title => "First CD", year => 2007},
1546     { title => "Second CD", year => 2008},
1547   ]}
1548   ]);
1549
1550   print $ArtistOne->name; ## response is 'Artist One'
1551   print $ArtistThree->cds->count ## reponse is '2'
1552
1553 For the arrayref of arrayrefs style,  the first element should be a list of the
1554 fieldsnames to which the remaining elements are rows being inserted.  For
1555 example:
1556
1557   $Arstist_rs->populate([
1558     [qw/artistid name/],
1559     [100, 'A Formally Unknown Singer'],
1560     [101, 'A singer that jumped the shark two albums ago'],
1561     [102, 'An actually cool singer.'],
1562   ]);
1563
1564 Please note an important effect on your data when choosing between void and
1565 wantarray context. Since void context goes straight to C<insert_bulk> in
1566 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1567 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1568 create primary keys for you, you will find that your PKs are empty.  In this
1569 case you will have to use the wantarray context in order to create those
1570 values.
1571
1572 =cut
1573
1574 sub populate {
1575   my $self = shift @_;
1576   my $data = ref $_[0][0] eq 'HASH'
1577     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1578     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1579
1580   if(defined wantarray) {
1581     my @created;
1582     foreach my $item (@$data) {
1583       push(@created, $self->create($item));
1584     }
1585     return @created;
1586   } else {
1587     my ($first, @rest) = @$data;
1588
1589     my @names = grep {!ref $first->{$_}} keys %$first;
1590     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1591     my @pks = $self->result_source->primary_columns;
1592
1593     ## do the belongs_to relationships
1594     foreach my $index (0..$#$data) {
1595
1596       # delegate to create() for any dataset without primary keys with specified relationships
1597       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1598         for my $r (@rels) {
1599           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1600             my @ret = $self->populate($data);
1601             return;
1602           }
1603         }
1604       }
1605
1606       foreach my $rel (@rels) {
1607         next unless ref $data->[$index]->{$rel} eq "HASH";
1608         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1609         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1610         my $related = $result->result_source->_resolve_condition(
1611           $result->result_source->relationship_info($reverse)->{cond},
1612           $self,
1613           $result,
1614         );
1615
1616         delete $data->[$index]->{$rel};
1617         $data->[$index] = {%{$data->[$index]}, %$related};
1618
1619         push @names, keys %$related if $index == 0;
1620       }
1621     }
1622
1623     ## do bulk insert on current row
1624     my @values = map { [ @$_{@names} ] } @$data;
1625
1626     $self->result_source->storage->insert_bulk(
1627       $self->result_source,
1628       \@names,
1629       \@values,
1630     );
1631
1632     ## do the has_many relationships
1633     foreach my $item (@$data) {
1634
1635       foreach my $rel (@rels) {
1636         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1637
1638         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1639      || $self->throw_exception('Cannot find the relating object.');
1640
1641         my $child = $parent->$rel;
1642
1643         my $related = $child->result_source->_resolve_condition(
1644           $parent->result_source->relationship_info($rel)->{cond},
1645           $child,
1646           $parent,
1647         );
1648
1649         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1650         my @populate = map { {%$_, %$related} } @rows_to_add;
1651
1652         $child->populate( \@populate );
1653       }
1654     }
1655   }
1656 }
1657
1658 =head2 _normalize_populate_args ($args)
1659
1660 Private method used by L</populate> to normalize its incoming arguments.  Factored
1661 out in case you want to subclass and accept new argument structures to the
1662 L</populate> method.
1663
1664 =cut
1665
1666 sub _normalize_populate_args {
1667   my ($self, $data) = @_;
1668   my @names = @{shift(@$data)};
1669   my @results_to_create;
1670   foreach my $datum (@$data) {
1671     my %result_to_create;
1672     foreach my $index (0..$#names) {
1673       $result_to_create{$names[$index]} = $$datum[$index];
1674     }
1675     push @results_to_create, \%result_to_create;
1676   }
1677   return \@results_to_create;
1678 }
1679
1680 =head2 pager
1681
1682 =over 4
1683
1684 =item Arguments: none
1685
1686 =item Return Value: $pager
1687
1688 =back
1689
1690 Return Value a L<Data::Page> object for the current resultset. Only makes
1691 sense for queries with a C<page> attribute.
1692
1693 To get the full count of entries for a paged resultset, call
1694 C<total_entries> on the L<Data::Page> object.
1695
1696 =cut
1697
1698 sub pager {
1699   my ($self) = @_;
1700
1701   return $self->{pager} if $self->{pager};
1702
1703   my $attrs = $self->{attrs};
1704   $self->throw_exception("Can't create pager for non-paged rs")
1705     unless $self->{attrs}{page};
1706   $attrs->{rows} ||= 10;
1707
1708   # throw away the paging flags and re-run the count (possibly
1709   # with a subselect) to get the real total count
1710   my $count_attrs = { %$attrs };
1711   delete $count_attrs->{$_} for qw/rows offset page pager/;
1712   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1713
1714   return $self->{pager} = Data::Page->new(
1715     $total_count,
1716     $attrs->{rows},
1717     $self->{attrs}{page}
1718   );
1719 }
1720
1721 =head2 page
1722
1723 =over 4
1724
1725 =item Arguments: $page_number
1726
1727 =item Return Value: $rs
1728
1729 =back
1730
1731 Returns a resultset for the $page_number page of the resultset on which page
1732 is called, where each page contains a number of rows equal to the 'rows'
1733 attribute set on the resultset (10 by default).
1734
1735 =cut
1736
1737 sub page {
1738   my ($self, $page) = @_;
1739   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1740 }
1741
1742 =head2 new_result
1743
1744 =over 4
1745
1746 =item Arguments: \%vals
1747
1748 =item Return Value: $rowobject
1749
1750 =back
1751
1752 Creates a new row object in the resultset's result class and returns
1753 it. The row is not inserted into the database at this point, call
1754 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1755 will tell you whether the row object has been inserted or not.
1756
1757 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1758
1759 =cut
1760
1761 sub new_result {
1762   my ($self, $values) = @_;
1763   $self->throw_exception( "new_result needs a hash" )
1764     unless (ref $values eq 'HASH');
1765
1766   my %new;
1767   my $alias = $self->{attrs}{alias};
1768
1769   if (
1770     defined $self->{cond}
1771     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1772   ) {
1773     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1774     $new{-from_resultset} = [ keys %new ] if keys %new;
1775   } else {
1776     $self->throw_exception(
1777       "Can't abstract implicit construct, condition not a hash"
1778     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1779
1780     my $collapsed_cond = (
1781       $self->{cond}
1782         ? $self->_collapse_cond($self->{cond})
1783         : {}
1784     );
1785
1786     # precendence must be given to passed values over values inherited from
1787     # the cond, so the order here is important.
1788     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1789     while( my($col,$value) = each %implied ){
1790       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1791         $new{$col} = $value->{'='};
1792         next;
1793       }
1794       $new{$col} = $value if $self->_is_deterministic_value($value);
1795     }
1796   }
1797
1798   %new = (
1799     %new,
1800     %{ $self->_remove_alias($values, $alias) },
1801     -source_handle => $self->_source_handle,
1802     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1803   );
1804
1805   return $self->result_class->new(\%new);
1806 }
1807
1808 # _is_deterministic_value
1809 #
1810 # Make an effor to strip non-deterministic values from the condition,
1811 # to make sure new_result chokes less
1812
1813 sub _is_deterministic_value {
1814   my $self = shift;
1815   my $value = shift;
1816   my $ref_type = ref $value;
1817   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1818   return 1 if Scalar::Util::blessed($value);
1819   return 0;
1820 }
1821
1822 # _has_attr
1823 #
1824 # determines if the resultset defines at least one
1825 # of the attributes supplied
1826 #
1827 # used to determine if a subquery is neccessary
1828
1829 sub _has_attr {
1830   my ($self, @attr_names) = @_;
1831
1832   my $attrs = $self->_resolved_attrs;
1833
1834   my $join_check_req;
1835
1836   for my $n (@attr_names) {
1837     ++$join_check_req if $n =~ /join/;
1838
1839     my $attr =  $attrs->{$n};
1840
1841     next if not defined $attr;
1842
1843     if (ref $attr eq 'HASH') {
1844       return 1 if keys %$attr;
1845     }
1846     elsif (ref $attr eq 'ARRAY') {
1847       return 1 if @$attr;
1848     }
1849     else {
1850       return 1 if $attr;
1851     }
1852   }
1853
1854   # a join can be expressed as a multi-level from
1855   return 1 if (
1856     $join_check_req
1857       and
1858     ref $attrs->{from} eq 'ARRAY'
1859       and
1860     @{$attrs->{from}} > 1
1861   );
1862
1863   return 0;
1864 }
1865
1866 # _collapse_cond
1867 #
1868 # Recursively collapse the condition.
1869
1870 sub _collapse_cond {
1871   my ($self, $cond, $collapsed) = @_;
1872
1873   $collapsed ||= {};
1874
1875   if (ref $cond eq 'ARRAY') {
1876     foreach my $subcond (@$cond) {
1877       next unless ref $subcond;  # -or
1878       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1879     }
1880   }
1881   elsif (ref $cond eq 'HASH') {
1882     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1883       foreach my $subcond (@{$cond->{-and}}) {
1884         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1885       }
1886     }
1887     else {
1888       foreach my $col (keys %$cond) {
1889         my $value = $cond->{$col};
1890         $collapsed->{$col} = $value;
1891       }
1892     }
1893   }
1894
1895   return $collapsed;
1896 }
1897
1898 # _remove_alias
1899 #
1900 # Remove the specified alias from the specified query hash. A copy is made so
1901 # the original query is not modified.
1902
1903 sub _remove_alias {
1904   my ($self, $query, $alias) = @_;
1905
1906   my %orig = %{ $query || {} };
1907   my %unaliased;
1908
1909   foreach my $key (keys %orig) {
1910     if ($key !~ /\./) {
1911       $unaliased{$key} = $orig{$key};
1912       next;
1913     }
1914     $unaliased{$1} = $orig{$key}
1915       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1916   }
1917
1918   return \%unaliased;
1919 }
1920
1921 =head2 as_query (EXPERIMENTAL)
1922
1923 =over 4
1924
1925 =item Arguments: none
1926
1927 =item Return Value: \[ $sql, @bind ]
1928
1929 =back
1930
1931 Returns the SQL query and bind vars associated with the invocant.
1932
1933 This is generally used as the RHS for a subquery.
1934
1935 B<NOTE>: This feature is still experimental.
1936
1937 =cut
1938
1939 sub as_query { return shift->cursor->as_query(@_) }
1940
1941 =head2 find_or_new
1942
1943 =over 4
1944
1945 =item Arguments: \%vals, \%attrs?
1946
1947 =item Return Value: $rowobject
1948
1949 =back
1950
1951   my $artist = $schema->resultset('Artist')->find_or_new(
1952     { artist => 'fred' }, { key => 'artists' });
1953
1954   $cd->cd_to_producer->find_or_new({ producer => $producer },
1955                                    { key => 'primary });
1956
1957 Find an existing record from this resultset, based on its primary
1958 key, or a unique constraint. If none exists, instantiate a new result
1959 object and return it. The object will not be saved into your storage
1960 until you call L<DBIx::Class::Row/insert> on it.
1961
1962 You most likely want this method when looking for existing rows using
1963 a unique constraint that is not the primary key, or looking for
1964 related rows.
1965
1966 If you want objects to be saved immediately, use L</find_or_create> instead.
1967
1968 B<Note>: C<find_or_new> is probably not what you want when creating a
1969 new row in a table that uses primary keys supplied by the
1970 database. Passing in a primary key column with a value of I<undef>
1971 will cause L</find> to attempt to search for a row with a value of
1972 I<NULL>.
1973
1974 =cut
1975
1976 sub find_or_new {
1977   my $self     = shift;
1978   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1979   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1980   my $exists   = $self->find($hash, $attrs);
1981   return defined $exists ? $exists : $self->new_result($hash);
1982 }
1983
1984 =head2 create
1985
1986 =over 4
1987
1988 =item Arguments: \%vals
1989
1990 =item Return Value: a L<DBIx::Class::Row> $object
1991
1992 =back
1993
1994 Attempt to create a single new row or a row with multiple related rows
1995 in the table represented by the resultset (and related tables). This
1996 will not check for duplicate rows before inserting, use
1997 L</find_or_create> to do that.
1998
1999 To create one row for this resultset, pass a hashref of key/value
2000 pairs representing the columns of the table and the values you wish to
2001 store. If the appropriate relationships are set up, foreign key fields
2002 can also be passed an object representing the foreign row, and the
2003 value will be set to its primary key.
2004
2005 To create related objects, pass a hashref for the value if the related
2006 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2007 and use the name of the relationship as the key. (NOT the name of the field,
2008 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2009 of hashrefs containing the data for each of the rows to create in the foreign
2010 tables, again using the relationship name as the key.
2011
2012 Instead of hashrefs of plain related data (key/value pairs), you may
2013 also pass new or inserted objects. New objects (not inserted yet, see
2014 L</new>), will be inserted into their appropriate tables.
2015
2016 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2017
2018 Example of creating a new row.
2019
2020   $person_rs->create({
2021     name=>"Some Person",
2022     email=>"somebody@someplace.com"
2023   });
2024
2025 Example of creating a new row and also creating rows in a related C<has_many>
2026 or C<has_one> resultset.  Note Arrayref.
2027
2028   $artist_rs->create(
2029      { artistid => 4, name => 'Manufactured Crap', cds => [
2030         { title => 'My First CD', year => 2006 },
2031         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2032       ],
2033      },
2034   );
2035
2036 Example of creating a new row and also creating a row in a related
2037 C<belongs_to>resultset. Note Hashref.
2038
2039   $cd_rs->create({
2040     title=>"Music for Silly Walks",
2041     year=>2000,
2042     artist => {
2043       name=>"Silly Musician",
2044     }
2045   });
2046
2047 =cut
2048
2049 sub create {
2050   my ($self, $attrs) = @_;
2051   $self->throw_exception( "create needs a hashref" )
2052     unless ref $attrs eq 'HASH';
2053   return $self->new_result($attrs)->insert;
2054 }
2055
2056 =head2 find_or_create
2057
2058 =over 4
2059
2060 =item Arguments: \%vals, \%attrs?
2061
2062 =item Return Value: $rowobject
2063
2064 =back
2065
2066   $cd->cd_to_producer->find_or_create({ producer => $producer },
2067                                       { key => 'primary });
2068
2069 Tries to find a record based on its primary key or unique constraints; if none
2070 is found, creates one and returns that instead.
2071
2072   my $cd = $schema->resultset('CD')->find_or_create({
2073     cdid   => 5,
2074     artist => 'Massive Attack',
2075     title  => 'Mezzanine',
2076     year   => 2005,
2077   });
2078
2079 Also takes an optional C<key> attribute, to search by a specific key or unique
2080 constraint. For example:
2081
2082   my $cd = $schema->resultset('CD')->find_or_create(
2083     {
2084       artist => 'Massive Attack',
2085       title  => 'Mezzanine',
2086     },
2087     { key => 'cd_artist_title' }
2088   );
2089
2090 B<Note>: Because find_or_create() reads from the database and then
2091 possibly inserts based on the result, this method is subject to a race
2092 condition. Another process could create a record in the table after
2093 the find has completed and before the create has started. To avoid
2094 this problem, use find_or_create() inside a transaction.
2095
2096 B<Note>: C<find_or_create> is probably not what you want when creating
2097 a new row in a table that uses primary keys supplied by the
2098 database. Passing in a primary key column with a value of I<undef>
2099 will cause L</find> to attempt to search for a row with a value of
2100 I<NULL>.
2101
2102 See also L</find> and L</update_or_create>. For information on how to declare
2103 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2104
2105 =cut
2106
2107 sub find_or_create {
2108   my $self     = shift;
2109   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2110   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2111   my $exists   = $self->find($hash, $attrs);
2112   return defined $exists ? $exists : $self->create($hash);
2113 }
2114
2115 =head2 update_or_create
2116
2117 =over 4
2118
2119 =item Arguments: \%col_values, { key => $unique_constraint }?
2120
2121 =item Return Value: $rowobject
2122
2123 =back
2124
2125   $resultset->update_or_create({ col => $val, ... });
2126
2127 First, searches for an existing row matching one of the unique constraints
2128 (including the primary key) on the source of this resultset. If a row is
2129 found, updates it with the other given column values. Otherwise, creates a new
2130 row.
2131
2132 Takes an optional C<key> attribute to search on a specific unique constraint.
2133 For example:
2134
2135   # In your application
2136   my $cd = $schema->resultset('CD')->update_or_create(
2137     {
2138       artist => 'Massive Attack',
2139       title  => 'Mezzanine',
2140       year   => 1998,
2141     },
2142     { key => 'cd_artist_title' }
2143   );
2144
2145   $cd->cd_to_producer->update_or_create({
2146     producer => $producer,
2147     name => 'harry',
2148   }, {
2149     key => 'primary,
2150   });
2151
2152
2153 If no C<key> is specified, it searches on all unique constraints defined on the
2154 source, including the primary key.
2155
2156 If the C<key> is specified as C<primary>, it searches only on the primary key.
2157
2158 See also L</find> and L</find_or_create>. For information on how to declare
2159 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2160
2161 B<Note>: C<update_or_create> is probably not what you want when
2162 looking for a row in a table that uses primary keys supplied by the
2163 database, unless you actually have a key value. Passing in a primary
2164 key column with a value of I<undef> will cause L</find> to attempt to
2165 search for a row with a value of I<NULL>.
2166
2167 =cut
2168
2169 sub update_or_create {
2170   my $self = shift;
2171   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2172   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2173
2174   my $row = $self->find($cond, $attrs);
2175   if (defined $row) {
2176     $row->update($cond);
2177     return $row;
2178   }
2179
2180   return $self->create($cond);
2181 }
2182
2183 =head2 update_or_new
2184
2185 =over 4
2186
2187 =item Arguments: \%col_values, { key => $unique_constraint }?
2188
2189 =item Return Value: $rowobject
2190
2191 =back
2192
2193   $resultset->update_or_new({ col => $val, ... });
2194
2195 First, searches for an existing row matching one of the unique constraints
2196 (including the primary key) on the source of this resultset. If a row is
2197 found, updates it with the other given column values. Otherwise, instantiate
2198 a new result object and return it. The object will not be saved into your storage
2199 until you call L<DBIx::Class::Row/insert> on it.
2200
2201 Takes an optional C<key> attribute to search on a specific unique constraint.
2202 For example:
2203
2204   # In your application
2205   my $cd = $schema->resultset('CD')->update_or_new(
2206     {
2207       artist => 'Massive Attack',
2208       title  => 'Mezzanine',
2209       year   => 1998,
2210     },
2211     { key => 'cd_artist_title' }
2212   );
2213
2214   if ($cd->in_storage) {
2215       # the cd was updated
2216   }
2217   else {
2218       # the cd is not yet in the database, let's insert it
2219       $cd->insert;
2220   }
2221
2222 See also L</find>, L</find_or_create> and L<find_or_new>.
2223
2224 =cut
2225
2226 sub update_or_new {
2227     my $self  = shift;
2228     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2229     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2230
2231     my $row = $self->find( $cond, $attrs );
2232     if ( defined $row ) {
2233         $row->update($cond);
2234         return $row;
2235     }
2236
2237     return $self->new_result($cond);
2238 }
2239
2240 =head2 get_cache
2241
2242 =over 4
2243
2244 =item Arguments: none
2245
2246 =item Return Value: \@cache_objects?
2247
2248 =back
2249
2250 Gets the contents of the cache for the resultset, if the cache is set.
2251
2252 The cache is populated either by using the L</prefetch> attribute to
2253 L</search> or by calling L</set_cache>.
2254
2255 =cut
2256
2257 sub get_cache {
2258   shift->{all_cache};
2259 }
2260
2261 =head2 set_cache
2262
2263 =over 4
2264
2265 =item Arguments: \@cache_objects
2266
2267 =item Return Value: \@cache_objects
2268
2269 =back
2270
2271 Sets the contents of the cache for the resultset. Expects an arrayref
2272 of objects of the same class as those produced by the resultset. Note that
2273 if the cache is set the resultset will return the cached objects rather
2274 than re-querying the database even if the cache attr is not set.
2275
2276 The contents of the cache can also be populated by using the
2277 L</prefetch> attribute to L</search>.
2278
2279 =cut
2280
2281 sub set_cache {
2282   my ( $self, $data ) = @_;
2283   $self->throw_exception("set_cache requires an arrayref")
2284       if defined($data) && (ref $data ne 'ARRAY');
2285   $self->{all_cache} = $data;
2286 }
2287
2288 =head2 clear_cache
2289
2290 =over 4
2291
2292 =item Arguments: none
2293
2294 =item Return Value: []
2295
2296 =back
2297
2298 Clears the cache for the resultset.
2299
2300 =cut
2301
2302 sub clear_cache {
2303   shift->set_cache(undef);
2304 }
2305
2306 =head2 related_resultset
2307
2308 =over 4
2309
2310 =item Arguments: $relationship_name
2311
2312 =item Return Value: $resultset
2313
2314 =back
2315
2316 Returns a related resultset for the supplied relationship name.
2317
2318   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2319
2320 =cut
2321
2322 sub related_resultset {
2323   my ($self, $rel) = @_;
2324
2325   $self->{related_resultsets} ||= {};
2326   return $self->{related_resultsets}{$rel} ||= do {
2327     my $rel_obj = $self->result_source->relationship_info($rel);
2328
2329     $self->throw_exception(
2330       "search_related: result source '" . $self->result_source->source_name .
2331         "' has no such relationship $rel")
2332       unless $rel_obj;
2333
2334     my ($from,$seen) = $self->_resolve_from($rel);
2335
2336     my $join_count = $seen->{$rel};
2337     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2338
2339     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2340     my %attrs = %{$self->{attrs}||{}};
2341     delete @attrs{qw(result_class alias)};
2342
2343     my $new_cache;
2344
2345     if (my $cache = $self->get_cache) {
2346       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2347         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2348                         @$cache ];
2349       }
2350     }
2351
2352     my $rel_source = $self->result_source->related_source($rel);
2353
2354     my $new = do {
2355
2356       # The reason we do this now instead of passing the alias to the
2357       # search_rs below is that if you wrap/overload resultset on the
2358       # source you need to know what alias it's -going- to have for things
2359       # to work sanely (e.g. RestrictWithObject wants to be able to add
2360       # extra query restrictions, and these may need to be $alias.)
2361
2362       my $attrs = $rel_source->resultset_attributes;
2363       local $attrs->{alias} = $alias;
2364
2365       $rel_source->resultset
2366                  ->search_rs(
2367                      undef, {
2368                        %attrs,
2369                        join => undef,
2370                        prefetch => undef,
2371                        select => undef,
2372                        as => undef,
2373                        where => $self->{cond},
2374                        seen_join => $seen,
2375                        from => $from,
2376                    });
2377     };
2378     $new->set_cache($new_cache) if $new_cache;
2379     $new;
2380   };
2381 }
2382
2383 =head2 current_source_alias
2384
2385 =over 4
2386
2387 =item Arguments: none
2388
2389 =item Return Value: $source_alias
2390
2391 =back
2392
2393 Returns the current table alias for the result source this resultset is built
2394 on, that will be used in the SQL query. Usually it is C<me>.
2395
2396 Currently the source alias that refers to the result set returned by a
2397 L</search>/L</find> family method depends on how you got to the resultset: it's
2398 C<me> by default, but eg. L</search_related> aliases it to the related result
2399 source name (and keeps C<me> referring to the original result set). The long
2400 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2401 (and make this method unnecessary).
2402
2403 Thus it's currently necessary to use this method in predefined queries (see
2404 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2405 source alias of the current result set:
2406
2407   # in a result set class
2408   sub modified_by {
2409     my ($self, $user) = @_;
2410
2411     my $me = $self->current_source_alias;
2412
2413     return $self->search(
2414       "$me.modified" => $user->id,
2415     );
2416   }
2417
2418 =cut
2419
2420 sub current_source_alias {
2421   my ($self) = @_;
2422
2423   return ($self->{attrs} || {})->{alias} || 'me';
2424 }
2425
2426 # This code is called by search_related, and makes sure there
2427 # is clear separation between the joins before, during, and
2428 # after the relationship. This information is needed later
2429 # in order to properly resolve prefetch aliases (any alias
2430 # with a relation_chain_depth less than the depth of the
2431 # current prefetch is not considered)
2432 sub _resolve_from {
2433   my ($self, $extra_join) = @_;
2434   my $source = $self->result_source;
2435   my $attrs = $self->{attrs};
2436
2437   my $from = $attrs->{from}
2438     || [ { $attrs->{alias} => $source->from } ];
2439
2440   my $seen = { %{$attrs->{seen_join} || {} } };
2441
2442   # we need to take the prefetch the attrs into account before we
2443   # ->_resolve_join as otherwise they get lost - captainL
2444   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2445
2446   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2447
2448   ++$seen->{-relation_chain_depth};
2449
2450   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2451
2452   ++$seen->{-relation_chain_depth};
2453
2454   return ($from,$seen);
2455 }
2456
2457 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2458 sub _resolved_attrs_copy {
2459   my $self = shift;
2460   return { %{$self->_resolved_attrs (@_)} };
2461 }
2462
2463 sub _resolved_attrs {
2464   my $self = shift;
2465   return $self->{_attrs} if $self->{_attrs};
2466
2467   my $attrs  = { %{ $self->{attrs} || {} } };
2468   my $source = $self->result_source;
2469   my $alias  = $attrs->{alias};
2470
2471   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2472   my @colbits;
2473
2474   # build columns (as long as select isn't set) into a set of as/select hashes
2475   unless ( $attrs->{select} ) {
2476       @colbits = map {
2477           ( ref($_) eq 'HASH' )
2478               ? $_
2479               : {
2480                   (
2481                     /^\Q${alias}.\E(.+)$/
2482                       ? "$1"
2483                       : "$_"
2484                   )
2485                 =>
2486                   (
2487                     /\./
2488                       ? "$_"
2489                       : "${alias}.$_"
2490                   )
2491             }
2492       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2493   }
2494   # add the additional columns on
2495   foreach ( 'include_columns', '+columns' ) {
2496       push @colbits, map {
2497           ( ref($_) eq 'HASH' )
2498             ? $_
2499             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2500       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2501   }
2502
2503   # start with initial select items
2504   if ( $attrs->{select} ) {
2505     $attrs->{select} =
2506         ( ref $attrs->{select} eq 'ARRAY' )
2507       ? [ @{ $attrs->{select} } ]
2508       : [ $attrs->{select} ];
2509     $attrs->{as} = (
2510       $attrs->{as}
2511       ? (
2512         ref $attrs->{as} eq 'ARRAY'
2513         ? [ @{ $attrs->{as} } ]
2514         : [ $attrs->{as} ]
2515         )
2516       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2517     );
2518   }
2519   else {
2520
2521     # otherwise we intialise select & as to empty
2522     $attrs->{select} = [];
2523     $attrs->{as}     = [];
2524   }
2525
2526   # now add colbits to select/as
2527   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2528   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2529
2530   my $adds;
2531   if ( $adds = delete $attrs->{'+select'} ) {
2532     $adds = [$adds] unless ref $adds eq 'ARRAY';
2533     push(
2534       @{ $attrs->{select} },
2535       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2536     );
2537   }
2538   if ( $adds = delete $attrs->{'+as'} ) {
2539     $adds = [$adds] unless ref $adds eq 'ARRAY';
2540     push( @{ $attrs->{as} }, @$adds );
2541   }
2542
2543   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2544
2545   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2546     my $join = delete $attrs->{join} || {};
2547
2548     if ( defined $attrs->{prefetch} ) {
2549       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2550
2551     }
2552
2553     $attrs->{from} =    # have to copy here to avoid corrupting the original
2554       [
2555       @{ $attrs->{from} },
2556       $source->_resolve_join(
2557         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2558       )
2559       ];
2560
2561   }
2562
2563   if ( $attrs->{order_by} ) {
2564     $attrs->{order_by} = (
2565       ref( $attrs->{order_by} ) eq 'ARRAY'
2566       ? [ @{ $attrs->{order_by} } ]
2567       : [ $attrs->{order_by} ]
2568     );
2569   }
2570   else {
2571     $attrs->{order_by} = [];
2572   }
2573
2574   my $collapse = $attrs->{collapse} || {};
2575   if ( my $prefetch = delete $attrs->{prefetch} ) {
2576     $prefetch = $self->_merge_attr( {}, $prefetch );
2577     my @pre_order;
2578     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2579
2580       # bring joins back to level of current class
2581       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2582       my @prefetch =
2583         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2584       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2585       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2586     }
2587     push( @{ $attrs->{order_by} }, @pre_order );
2588   }
2589
2590   if (delete $attrs->{distinct}) {
2591     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2592   }
2593
2594   $attrs->{collapse} = $collapse;
2595
2596   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2597     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2598   }
2599
2600   return $self->{_attrs} = $attrs;
2601 }
2602
2603 sub _joinpath_aliases {
2604   my ($self, $fromspec, $seen) = @_;
2605
2606   my $paths = {};
2607   return $paths unless ref $fromspec eq 'ARRAY';
2608
2609   for my $j (@$fromspec) {
2610
2611     next if ref $j ne 'ARRAY';
2612     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2613
2614     my $p = $paths;
2615     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2616     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2617   }
2618
2619   return $paths;
2620 }
2621
2622 sub _rollout_attr {
2623   my ($self, $attr) = @_;
2624
2625   if (ref $attr eq 'HASH') {
2626     return $self->_rollout_hash($attr);
2627   } elsif (ref $attr eq 'ARRAY') {
2628     return $self->_rollout_array($attr);
2629   } else {
2630     return [$attr];
2631   }
2632 }
2633
2634 sub _rollout_array {
2635   my ($self, $attr) = @_;
2636
2637   my @rolled_array;
2638   foreach my $element (@{$attr}) {
2639     if (ref $element eq 'HASH') {
2640       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2641     } elsif (ref $element eq 'ARRAY') {
2642       #  XXX - should probably recurse here
2643       push( @rolled_array, @{$self->_rollout_array($element)} );
2644     } else {
2645       push( @rolled_array, $element );
2646     }
2647   }
2648   return \@rolled_array;
2649 }
2650
2651 sub _rollout_hash {
2652   my ($self, $attr) = @_;
2653
2654   my @rolled_array;
2655   foreach my $key (keys %{$attr}) {
2656     push( @rolled_array, { $key => $attr->{$key} } );
2657   }
2658   return \@rolled_array;
2659 }
2660
2661 sub _calculate_score {
2662   my ($self, $a, $b) = @_;
2663
2664   if (ref $b eq 'HASH') {
2665     my ($b_key) = keys %{$b};
2666     if (ref $a eq 'HASH') {
2667       my ($a_key) = keys %{$a};
2668       if ($a_key eq $b_key) {
2669         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2670       } else {
2671         return 0;
2672       }
2673     } else {
2674       return ($a eq $b_key) ? 1 : 0;
2675     }
2676   } else {
2677     if (ref $a eq 'HASH') {
2678       my ($a_key) = keys %{$a};
2679       return ($b eq $a_key) ? 1 : 0;
2680     } else {
2681       return ($b eq $a) ? 1 : 0;
2682     }
2683   }
2684 }
2685
2686 sub _merge_attr {
2687   my ($self, $orig, $import) = @_;
2688
2689   return $import unless defined($orig);
2690   return $orig unless defined($import);
2691
2692   $orig = $self->_rollout_attr($orig);
2693   $import = $self->_rollout_attr($import);
2694
2695   my $seen_keys;
2696   foreach my $import_element ( @{$import} ) {
2697     # find best candidate from $orig to merge $b_element into
2698     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2699     foreach my $orig_element ( @{$orig} ) {
2700       my $score = $self->_calculate_score( $orig_element, $import_element );
2701       if ($score > $best_candidate->{score}) {
2702         $best_candidate->{position} = $position;
2703         $best_candidate->{score} = $score;
2704       }
2705       $position++;
2706     }
2707     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2708
2709     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2710       push( @{$orig}, $import_element );
2711     } else {
2712       my $orig_best = $orig->[$best_candidate->{position}];
2713       # merge orig_best and b_element together and replace original with merged
2714       if (ref $orig_best ne 'HASH') {
2715         $orig->[$best_candidate->{position}] = $import_element;
2716       } elsif (ref $import_element eq 'HASH') {
2717         my ($key) = keys %{$orig_best};
2718         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2719       }
2720     }
2721     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2722   }
2723
2724   return $orig;
2725 }
2726
2727 sub result_source {
2728     my $self = shift;
2729
2730     if (@_) {
2731         $self->_source_handle($_[0]->handle);
2732     } else {
2733         $self->_source_handle->resolve;
2734     }
2735 }
2736
2737 =head2 throw_exception
2738
2739 See L<DBIx::Class::Schema/throw_exception> for details.
2740
2741 =cut
2742
2743 sub throw_exception {
2744   my $self=shift;
2745   if (ref $self && $self->_source_handle->schema) {
2746     $self->_source_handle->schema->throw_exception(@_)
2747   } else {
2748     croak(@_);
2749   }
2750
2751 }
2752
2753 # XXX: FIXME: Attributes docs need clearing up
2754
2755 =head1 ATTRIBUTES
2756
2757 Attributes are used to refine a ResultSet in various ways when
2758 searching for data. They can be passed to any method which takes an
2759 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2760 L</count>.
2761
2762 These are in no particular order:
2763
2764 =head2 order_by
2765
2766 =over 4
2767
2768 =item Value: ( $order_by | \@order_by | \%order_by )
2769
2770 =back
2771
2772 Which column(s) to order the results by. If a single column name, or
2773 an arrayref of names is supplied, the argument is passed through
2774 directly to SQL. The hashref syntax allows for connection-agnostic
2775 specification of ordering direction:
2776
2777  For descending order:
2778
2779   order_by => { -desc => [qw/col1 col2 col3/] }
2780
2781  For explicit ascending order:
2782
2783   order_by => { -asc => 'col' }
2784
2785 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2786 supported, although you are strongly encouraged to use the hashref
2787 syntax as outlined above.
2788
2789 =head2 columns
2790
2791 =over 4
2792
2793 =item Value: \@columns
2794
2795 =back
2796
2797 Shortcut to request a particular set of columns to be retrieved. Each
2798 column spec may be a string (a table column name), or a hash (in which
2799 case the key is the C<as> value, and the value is used as the C<select>
2800 expression). Adds C<me.> onto the start of any column without a C<.> in
2801 it and sets C<select> from that, then auto-populates C<as> from
2802 C<select> as normal. (You may also use the C<cols> attribute, as in
2803 earlier versions of DBIC.)
2804
2805 =head2 +columns
2806
2807 =over 4
2808
2809 =item Value: \@columns
2810
2811 =back
2812
2813 Indicates additional columns to be selected from storage. Works the same
2814 as L</columns> but adds columns to the selection. (You may also use the
2815 C<include_columns> attribute, as in earlier versions of DBIC). For
2816 example:-
2817
2818   $schema->resultset('CD')->search(undef, {
2819     '+columns' => ['artist.name'],
2820     join => ['artist']
2821   });
2822
2823 would return all CDs and include a 'name' column to the information
2824 passed to object inflation. Note that the 'artist' is the name of the
2825 column (or relationship) accessor, and 'name' is the name of the column
2826 accessor in the related table.
2827
2828 =head2 include_columns
2829
2830 =over 4
2831
2832 =item Value: \@columns
2833
2834 =back
2835
2836 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2837
2838 =head2 select
2839
2840 =over 4
2841
2842 =item Value: \@select_columns
2843
2844 =back
2845
2846 Indicates which columns should be selected from the storage. You can use
2847 column names, or in the case of RDBMS back ends, function or stored procedure
2848 names:
2849
2850   $rs = $schema->resultset('Employee')->search(undef, {
2851     select => [
2852       'name',
2853       { count => 'employeeid' },
2854       { sum => 'salary' }
2855     ]
2856   });
2857
2858 When you use function/stored procedure names and do not supply an C<as>
2859 attribute, the column names returned are storage-dependent. E.g. MySQL would
2860 return a column named C<count(employeeid)> in the above example.
2861
2862 =head2 +select
2863
2864 =over 4
2865
2866 Indicates additional columns to be selected from storage.  Works the same as
2867 L</select> but adds columns to the selection.
2868
2869 =back
2870
2871 =head2 +as
2872
2873 =over 4
2874
2875 Indicates additional column names for those added via L</+select>. See L</as>.
2876
2877 =back
2878
2879 =head2 as
2880
2881 =over 4
2882
2883 =item Value: \@inflation_names
2884
2885 =back
2886
2887 Indicates column names for object inflation. That is, C<as>
2888 indicates the name that the column can be accessed as via the
2889 C<get_column> method (or via the object accessor, B<if one already
2890 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2891
2892 The C<as> attribute is used in conjunction with C<select>,
2893 usually when C<select> contains one or more function or stored
2894 procedure names:
2895
2896   $rs = $schema->resultset('Employee')->search(undef, {
2897     select => [
2898       'name',
2899       { count => 'employeeid' }
2900     ],
2901     as => ['name', 'employee_count'],
2902   });
2903
2904   my $employee = $rs->first(); # get the first Employee
2905
2906 If the object against which the search is performed already has an accessor
2907 matching a column name specified in C<as>, the value can be retrieved using
2908 the accessor as normal:
2909
2910   my $name = $employee->name();
2911
2912 If on the other hand an accessor does not exist in the object, you need to
2913 use C<get_column> instead:
2914
2915   my $employee_count = $employee->get_column('employee_count');
2916
2917 You can create your own accessors if required - see
2918 L<DBIx::Class::Manual::Cookbook> for details.
2919
2920 Please note: This will NOT insert an C<AS employee_count> into the SQL
2921 statement produced, it is used for internal access only. Thus
2922 attempting to use the accessor in an C<order_by> clause or similar
2923 will fail miserably.
2924
2925 To get around this limitation, you can supply literal SQL to your
2926 C<select> attibute that contains the C<AS alias> text, eg:
2927
2928   select => [\'myfield AS alias']
2929
2930 =head2 join
2931
2932 =over 4
2933
2934 =item Value: ($rel_name | \@rel_names | \%rel_names)
2935
2936 =back
2937
2938 Contains a list of relationships that should be joined for this query.  For
2939 example:
2940
2941   # Get CDs by Nine Inch Nails
2942   my $rs = $schema->resultset('CD')->search(
2943     { 'artist.name' => 'Nine Inch Nails' },
2944     { join => 'artist' }
2945   );
2946
2947 Can also contain a hash reference to refer to the other relation's relations.
2948 For example:
2949
2950   package MyApp::Schema::Track;
2951   use base qw/DBIx::Class/;
2952   __PACKAGE__->table('track');
2953   __PACKAGE__->add_columns(qw/trackid cd position title/);
2954   __PACKAGE__->set_primary_key('trackid');
2955   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2956   1;
2957
2958   # In your application
2959   my $rs = $schema->resultset('Artist')->search(
2960     { 'track.title' => 'Teardrop' },
2961     {
2962       join     => { cd => 'track' },
2963       order_by => 'artist.name',
2964     }
2965   );
2966
2967 You need to use the relationship (not the table) name in  conditions,
2968 because they are aliased as such. The current table is aliased as "me", so
2969 you need to use me.column_name in order to avoid ambiguity. For example:
2970
2971   # Get CDs from 1984 with a 'Foo' track
2972   my $rs = $schema->resultset('CD')->search(
2973     {
2974       'me.year' => 1984,
2975       'tracks.name' => 'Foo'
2976     },
2977     { join => 'tracks' }
2978   );
2979
2980 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2981 similarly for a third time). For e.g.
2982
2983   my $rs = $schema->resultset('Artist')->search({
2984     'cds.title'   => 'Down to Earth',
2985     'cds_2.title' => 'Popular',
2986   }, {
2987     join => [ qw/cds cds/ ],
2988   });
2989
2990 will return a set of all artists that have both a cd with title 'Down
2991 to Earth' and a cd with title 'Popular'.
2992
2993 If you want to fetch related objects from other tables as well, see C<prefetch>
2994 below.
2995
2996 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2997
2998 =head2 prefetch
2999
3000 =over 4
3001
3002 =item Value: ($rel_name | \@rel_names | \%rel_names)
3003
3004 =back
3005
3006 Contains one or more relationships that should be fetched along with
3007 the main query (when they are accessed afterwards the data will
3008 already be available, without extra queries to the database).  This is
3009 useful for when you know you will need the related objects, because it
3010 saves at least one query:
3011
3012   my $rs = $schema->resultset('Tag')->search(
3013     undef,
3014     {
3015       prefetch => {
3016         cd => 'artist'
3017       }
3018     }
3019   );
3020
3021 The initial search results in SQL like the following:
3022
3023   SELECT tag.*, cd.*, artist.* FROM tag
3024   JOIN cd ON tag.cd = cd.cdid
3025   JOIN artist ON cd.artist = artist.artistid
3026
3027 L<DBIx::Class> has no need to go back to the database when we access the
3028 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3029 case.
3030
3031 Simple prefetches will be joined automatically, so there is no need
3032 for a C<join> attribute in the above search.
3033
3034 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3035 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3036 with an accessor type of 'single' or 'filter'). A more complex example that
3037 prefetches an artists cds, the tracks on those cds, and the tags associted
3038 with that artist is given below (assuming many-to-many from artists to tags):
3039
3040  my $rs = $schema->resultset('Artist')->search(
3041    undef,
3042    {
3043      prefetch => [
3044        { cds => 'tracks' },
3045        { artist_tags => 'tags' }
3046      ]
3047    }
3048  );
3049
3050
3051 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3052 attributes will be ignored.
3053
3054 =head2 page
3055
3056 =over 4
3057
3058 =item Value: $page
3059
3060 =back
3061
3062 Makes the resultset paged and specifies the page to retrieve. Effectively
3063 identical to creating a non-pages resultset and then calling ->page($page)
3064 on it.
3065
3066 If L<rows> attribute is not specified it defualts to 10 rows per page.
3067
3068 When you have a paged resultset, L</count> will only return the number
3069 of rows in the page. To get the total, use the L</pager> and call
3070 C<total_entries> on it.
3071
3072 =head2 rows
3073
3074 =over 4
3075
3076 =item Value: $rows
3077
3078 =back
3079
3080 Specifes the maximum number of rows for direct retrieval or the number of
3081 rows per page if the page attribute or method is used.
3082
3083 =head2 offset
3084
3085 =over 4
3086
3087 =item Value: $offset
3088
3089 =back
3090
3091 Specifies the (zero-based) row number for the  first row to be returned, or the
3092 of the first row of the first page if paging is used.
3093
3094 =head2 group_by
3095
3096 =over 4
3097
3098 =item Value: \@columns
3099
3100 =back
3101
3102 A arrayref of columns to group by. Can include columns of joined tables.
3103
3104   group_by => [qw/ column1 column2 ... /]
3105
3106 =head2 having
3107
3108 =over 4
3109
3110 =item Value: $condition
3111
3112 =back
3113
3114 HAVING is a select statement attribute that is applied between GROUP BY and
3115 ORDER BY. It is applied to the after the grouping calculations have been
3116 done.
3117
3118   having => { 'count(employee)' => { '>=', 100 } }
3119
3120 =head2 distinct
3121
3122 =over 4
3123
3124 =item Value: (0 | 1)
3125
3126 =back
3127
3128 Set to 1 to group by all columns.
3129
3130 =head2 where
3131
3132 =over 4
3133
3134 Adds to the WHERE clause.
3135
3136   # only return rows WHERE deleted IS NULL for all searches
3137   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3138
3139 Can be overridden by passing C<{ where => undef }> as an attribute
3140 to a resulset.
3141
3142 =back
3143
3144 =head2 cache
3145
3146 Set to 1 to cache search results. This prevents extra SQL queries if you
3147 revisit rows in your ResultSet:
3148
3149   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3150
3151   while( my $artist = $resultset->next ) {
3152     ... do stuff ...
3153   }
3154
3155   $rs->first; # without cache, this would issue a query
3156
3157 By default, searches are not cached.
3158
3159 For more examples of using these attributes, see
3160 L<DBIx::Class::Manual::Cookbook>.
3161
3162 =head2 from
3163
3164 =over 4
3165
3166 =item Value: \@from_clause
3167
3168 =back
3169
3170 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3171 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3172 clauses.
3173
3174 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3175
3176 C<join> will usually do what you need and it is strongly recommended that you
3177 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3178 And we really do mean "cannot", not just tried and failed. Attempting to use
3179 this because you're having problems with C<join> is like trying to use x86
3180 ASM because you've got a syntax error in your C. Trust us on this.
3181
3182 Now, if you're still really, really sure you need to use this (and if you're
3183 not 100% sure, ask the mailing list first), here's an explanation of how this
3184 works.
3185
3186 The syntax is as follows -
3187
3188   [
3189     { <alias1> => <table1> },
3190     [
3191       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3192       [], # nested JOIN (optional)
3193       { <table1.column1> => <table2.column2>, ... (more conditions) },
3194     ],
3195     # More of the above [ ] may follow for additional joins
3196   ]
3197
3198   <table1> <alias1>
3199   JOIN
3200     <table2> <alias2>
3201     [JOIN ...]
3202   ON <table1.column1> = <table2.column2>
3203   <more joins may follow>
3204
3205 An easy way to follow the examples below is to remember the following:
3206
3207     Anything inside "[]" is a JOIN
3208     Anything inside "{}" is a condition for the enclosing JOIN
3209
3210 The following examples utilize a "person" table in a family tree application.
3211 In order to express parent->child relationships, this table is self-joined:
3212
3213     # Person->belongs_to('father' => 'Person');
3214     # Person->belongs_to('mother' => 'Person');
3215
3216 C<from> can be used to nest joins. Here we return all children with a father,
3217 then search against all mothers of those children:
3218
3219   $rs = $schema->resultset('Person')->search(
3220       undef,
3221       {
3222           alias => 'mother', # alias columns in accordance with "from"
3223           from => [
3224               { mother => 'person' },
3225               [
3226                   [
3227                       { child => 'person' },
3228                       [
3229                           { father => 'person' },
3230                           { 'father.person_id' => 'child.father_id' }
3231                       ]
3232                   ],
3233                   { 'mother.person_id' => 'child.mother_id' }
3234               ],
3235           ]
3236       },
3237   );
3238
3239   # Equivalent SQL:
3240   # SELECT mother.* FROM person mother
3241   # JOIN (
3242   #   person child
3243   #   JOIN person father
3244   #   ON ( father.person_id = child.father_id )
3245   # )
3246   # ON ( mother.person_id = child.mother_id )
3247
3248 The type of any join can be controlled manually. To search against only people
3249 with a father in the person table, we could explicitly use C<INNER JOIN>:
3250
3251     $rs = $schema->resultset('Person')->search(
3252         undef,
3253         {
3254             alias => 'child', # alias columns in accordance with "from"
3255             from => [
3256                 { child => 'person' },
3257                 [
3258                     { father => 'person', -join_type => 'inner' },
3259                     { 'father.id' => 'child.father_id' }
3260                 ],
3261             ]
3262         },
3263     );
3264
3265     # Equivalent SQL:
3266     # SELECT child.* FROM person child
3267     # INNER JOIN person father ON child.father_id = father.id
3268
3269 If you need to express really complex joins or you need a subselect, you
3270 can supply literal SQL to C<from> via a scalar reference. In this case
3271 the contents of the scalar will replace the table name asscoiated with the
3272 resultsource.
3273
3274 WARNING: This technique might very well not work as expected on chained
3275 searches - you have been warned.
3276
3277     # Assuming the Event resultsource is defined as:
3278
3279         MySchema::Event->add_columns (
3280             sequence => {
3281                 data_type => 'INT',
3282                 is_auto_increment => 1,
3283             },
3284             location => {
3285                 data_type => 'INT',
3286             },
3287             type => {
3288                 data_type => 'INT',
3289             },
3290         );
3291         MySchema::Event->set_primary_key ('sequence');
3292
3293     # This will get back the latest event for every location. The column
3294     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3295     # combo to limit the resultset
3296
3297     $rs = $schema->resultset('Event');
3298     $table = $rs->result_source->name;
3299     $latest = $rs->search (
3300         undef,
3301         { from => \ "
3302             (SELECT e1.* FROM $table e1
3303                 JOIN $table e2
3304                     ON e1.location = e2.location
3305                     AND e1.sequence < e2.sequence
3306                 WHERE e2.sequence is NULL
3307             ) me",
3308         },
3309     );
3310
3311     # Equivalent SQL (with the DBIC chunks added):
3312
3313     SELECT me.sequence, me.location, me.type FROM
3314        (SELECT e1.* FROM events e1
3315            JOIN events e2
3316                ON e1.location = e2.location
3317                AND e1.sequence < e2.sequence
3318            WHERE e2.sequence is NULL
3319        ) me;
3320
3321 =head2 for
3322
3323 =over 4
3324
3325 =item Value: ( 'update' | 'shared' )
3326
3327 =back
3328
3329 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3330 ... FOR SHARED.
3331
3332 =cut
3333
3334 1;