lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use DBIx::Class::ResultClass::HashRefInflator;
   9 use Scalar::Util qw/blessed weaken reftype/;
  10 use DBIx::Class::_Util qw(
  11   dbic_internal_try dump_value
  12   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  13 );
  14 use Try::Tiny;
  15
  16 # not importing first() as it will clash with our own method
  17 use List::Util ();
  18
  19 BEGIN {
  20   # De-duplication in _merge_attr() is disabled, but left in for reference
  21   # (the merger is used for other things that ought not to be de-duped)
  22   *__HM_DEDUP = sub () { 0 };
  23 }
  24
  25 use namespace::clean;
  26
  27 use overload
  28         '0+'     => "count",
  29         'bool'   => "_bool",
  30         fallback => 1;
  31
  32 # this is real - CDBICompat overrides it with insanity
  33 # yes, prototype won't matter, but that's for now ;)
  34 sub _bool () { 1 }
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  37
  38 =head1 NAME
  39
  40 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  41
  42 =head1 SYNOPSIS
  43
  44   my $users_rs = $schema->resultset('User');
  45   while( $user = $users_rs->next) {
  46     print $user->username;
  47   }
  48
  49   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  50   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  51
  52 =head1 DESCRIPTION
  53
  54 A ResultSet is an object which stores a set of conditions representing
  55 a query. It is the backbone of DBIx::Class (i.e. the really
  56 important/useful bit).
  57
  58 No SQL is executed on the database when a ResultSet is created, it
  59 just stores all the conditions needed to create the query.
  60
  61 A basic ResultSet representing the data of an entire table is returned
  62 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  63 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  64
  65   my $users_rs = $schema->resultset('User');
  66
  67 A new ResultSet is returned from calling L</search> on an existing
  68 ResultSet. The new one will contain all the conditions of the
  69 original, plus any new conditions added in the C<search> call.
  70
  71 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  72 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  73 represents.
  74
  75 The query that the ResultSet represents is B<only> executed against
  76 the database when these methods are called:
  77 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  78
  79 If a resultset is used in a numeric context it returns the L</count>.
  80 However, if it is used in a boolean context it is B<always> true.  So if
  81 you want to check if a resultset has any results, you must use C<if $rs
  82 != 0>.
  83
  84 =head1 EXAMPLES
  85
  86 =head2 Chaining resultsets
  87
  88 Let's say you've got a query that needs to be run to return some data
  89 to the user. But, you have an authorization system in place that
  90 prevents certain users from seeing certain information. So, you want
  91 to construct the basic query in one method, but add constraints to it in
  92 another.
  93
  94   sub get_data {
  95     my $self = shift;
  96     my $request = $self->get_request; # Get a request object somehow.
  97     my $schema = $self->result_source->schema;
  98
  99     my $cd_rs = $schema->resultset('CD')->search({
 100       title => $request->param('title'),
 101       year => $request->param('year'),
 102     });
 103
 104     $cd_rs = $self->apply_security_policy( $cd_rs );
 105
 106     return $cd_rs->all();
 107   }
 108
 109   sub apply_security_policy {
 110     my $self = shift;
 111     my ($rs) = @_;
 112
 113     return $rs->search({
 114       subversive => 0,
 115     });
 116   }
 117
 118 =head3 Resolving conditions and attributes
 119
 120 When a resultset is chained from another resultset (e.g.:
 121 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 122 and attributes with the same keys need resolving.
 123
 124 If any of L</columns>, L</select>, L</as> are present, they reset the
 125 original selection, and start the selection "clean".
 126
 127 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 128 are merged into the existing ones from the original resultset.
 129
 130 The L</where> and L</having> attributes, and any search conditions, are
 131 merged with an SQL C<AND> to the existing condition from the original
 132 resultset.
 133
 134 All other attributes are overridden by any new ones supplied in the
 135 search attributes.
 136
 137 =head2 Multiple queries
 138
 139 Since a resultset just defines a query, you can do all sorts of
 140 things with it with the same object.
 141
 142   # Don't hit the DB yet.
 143   my $cd_rs = $schema->resultset('CD')->search({
 144     title => 'something',
 145     year => 2009,
 146   });
 147
 148   # Each of these hits the DB individually.
 149   my $count = $cd_rs->count;
 150   my $most_recent = $cd_rs->get_column('date_released')->max();
 151   my @records = $cd_rs->all;
 152
 153 And it's not just limited to SELECT statements.
 154
 155   $cd_rs->delete();
 156
 157 This is even cooler:
 158
 159   $cd_rs->create({ artist => 'Fred' });
 160
 161 Which is the same as:
 162
 163   $schema->resultset('CD')->create({
 164     title => 'something',
 165     year => 2009,
 166     artist => 'Fred'
 167   });
 168
 169 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 170
 171 =head2 Custom ResultSet classes
 172
 173 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 174
 175   package MyApp::Schema::ResultSet::User;
 176
 177   use strict;
 178   use warnings;
 179
 180   use base 'DBIx::Class::ResultSet';
 181
 182   sub active {
 183     my $self = shift;
 184     $self->search({ $self->current_source_alias . '.active' => 1 });
 185   }
 186
 187   sub unverified {
 188     my $self = shift;
 189     $self->search({ $self->current_source_alias . '.verified' => 0 });
 190   }
 191
 192   sub created_n_days_ago {
 193     my ($self, $days_ago) = @_;
 194     $self->search({
 195       $self->current_source_alias . '.create_date' => {
 196         '<=',
 197       $self->result_source->schema->storage->datetime_parser->format_datetime(
 198         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 199       )}
 200     });
 201   }
 202
 203   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 204
 205   1;
 206
 207 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 208 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 209 L<ResulSet|DBIx::Class::ResultSet> classes.
 210
 211 =head3 ResultSet subclassing with Moose and similar constructor-providers
 212
 213 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 214 you may find it useful if your ResultSets contain a lot of business logic
 215 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 216 your code via roles.
 217
 218 In order to write custom ResultSet classes with L<Moo> you need to use the
 219 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 220 unusual signature of the L<constructor provided by DBIC
 221 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 222
 223   use Moo;
 224   extends 'DBIx::Class::ResultSet';
 225   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 226
 227   ...your code...
 228
 229   1;
 230
 231 If you want to build your custom ResultSet classes with L<Moose>, you need
 232 a similar, though a little more elaborate template in order to interface the
 233 inlining of the L<Moose>-provided
 234 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 235 with the DBIC one.
 236
 237   package MyApp::Schema::ResultSet::User;
 238
 239   use Moose;
 240   use MooseX::NonMoose;
 241   extends 'DBIx::Class::ResultSet';
 242
 243   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 244
 245   ...your code...
 246
 247   __PACKAGE__->meta->make_immutable;
 248
 249   1;
 250
 251 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 252 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 253 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 254 instead by doing:
 255
 256   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 257
 258 =head1 METHODS
 259
 260 =head2 new
 261
 262 =over 4
 263
 264 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 265
 266 =item Return Value: L<$resultset|/search>
 267
 268 =back
 269
 270 The resultset constructor. Takes a source object (usually a
 271 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 272 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 273 executed as needed by the other methods.
 274
 275 Generally you never construct a resultset manually. Instead you get one
 276 from e.g. a
 277 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 278 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 279 scalar context):
 280
 281   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 282
 283 =over
 284
 285 =item WARNING
 286
 287 If called on an object, proxies to L</new_result> instead, so
 288
 289   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 290
 291 will return a CD object, not a ResultSet, and is equivalent to:
 292
 293   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 294
 295 Please also keep in mind that many internals call L</new_result> directly,
 296 so overloading this method with the idea of intercepting new result object
 297 creation B<will not work>. See also warning pertaining to L</create>.
 298
 299 =back
 300
 301 =cut
 302
 303 sub new {
 304   my $class = shift;
 305
 306   if (ref $class) {
 307     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 308     return $class->new_result(@_);
 309   }
 310
 311   my ($source, $attrs) = @_;
 312   $source = $source->resolve
 313     if $source->isa('DBIx::Class::ResultSourceHandle');
 314
 315   $attrs = { %{$attrs||{}} };
 316   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 317
 318   if ($attrs->{page}) {
 319     $attrs->{rows} ||= 10;
 320   }
 321
 322   $attrs->{alias} ||= 'me';
 323
 324   my $self = bless {
 325     result_source => $source,
 326     cond => $attrs->{where},
 327     pager => undef,
 328     attrs => $attrs,
 329   }, $class;
 330
 331   # if there is a dark selector, this means we are already in a
 332   # chain and the cleanup/sanification was taken care of by
 333   # _search_rs already
 334   $self->_normalize_selection($attrs)
 335     unless $attrs->{_dark_selector};
 336
 337   $self->result_class(
 338     $attrs->{result_class} || $source->result_class
 339   );
 340
 341   $self;
 342 }
 343
 344 =head2 search
 345
 346 =over 4
 347
 348 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 349
 350 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 351
 352 =back
 353
 354   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 355   my $new_rs = $cd_rs->search({ year => 2005 });
 356
 357   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 358                  # year = 2005 OR year = 2004
 359
 360 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 361 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 362 To avoid that, use L</search_rs>.
 363
 364 If you need to pass in additional attributes but no additional condition,
 365 call it as C<search(undef, \%attrs)>.
 366
 367   # "SELECT name, artistid FROM $artist_table"
 368   my @all_artists = $schema->resultset('Artist')->search(undef, {
 369     columns => [qw/name artistid/],
 370   });
 371
 372 For a list of attributes that can be passed to C<search>, see
 373 L</ATTRIBUTES>. For more examples of using this function, see
 374 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 375 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 376 and its extension L<DBIx::Class::SQLMaker>.
 377
 378 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 379
 380 =head3 CAVEAT
 381
 382 Note that L</search> does not process/deflate any of the values passed in the
 383 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 384 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 385 manually that any value passed to this method will stringify to something the
 386 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 387 objects, for more info see:
 388 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 389
 390 =cut
 391
 392 sub search {
 393   my $self = shift;
 394   my $rs = $self->search_rs( @_ );
 395
 396   if (wantarray) {
 397     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 398     return $rs->all;
 399   }
 400   elsif (defined wantarray) {
 401     return $rs;
 402   }
 403   else {
 404     # we can be called by a relationship helper, which in
 405     # turn may be called in void context due to some braindead
 406     # overload or whatever else the user decided to be clever
 407     # at this particular day. Thus limit the exception to
 408     # external code calls only
 409     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 410       if (caller)[0] !~ /^\QDBIx::Class::/;
 411
 412     return ();
 413   }
 414 }
 415
 416 =head2 search_rs
 417
 418 =over 4
 419
 420 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 421
 422 =item Return Value: L<$resultset|/search>
 423
 424 =back
 425
 426 This method does the same exact thing as search() except it will
 427 always return a resultset, even in list context.
 428
 429 =cut
 430
 431 sub search_rs {
 432   my $self = shift;
 433
 434   my $rsrc = $self->result_source;
 435   my ($call_cond, $call_attrs);
 436
 437   # Special-case handling for (undef, undef) or (undef)
 438   # Note that (foo => undef) is valid deprecated syntax
 439   @_ = () if not scalar grep { defined $_ } @_;
 440
 441   # just a cond
 442   if (@_ == 1) {
 443     $call_cond = shift;
 444   }
 445   # fish out attrs in the ($condref, $attr) case
 446   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 447     ($call_cond, $call_attrs) = @_;
 448   }
 449   elsif (@_ % 2) {
 450     $self->throw_exception('Odd number of arguments to search')
 451   }
 452   # legacy search
 453   elsif (@_) {
 454     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 455       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 456
 457     for my $i (0 .. $#_) {
 458       next if $i % 2;
 459       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 460         if (! defined $_[$i] or length ref $_[$i] );
 461     }
 462
 463     $call_cond = { @_ };
 464   }
 465
 466   # see if we can keep the cache (no $rs changes)
 467   my $cache;
 468   my %safe = (alias => 1, cache => 1);
 469   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 470     ! defined $call_cond
 471       or
 472     ref $call_cond eq 'HASH' && ! keys %$call_cond
 473       or
 474     ref $call_cond eq 'ARRAY' && ! @$call_cond
 475   )) {
 476     $cache = $self->get_cache;
 477   }
 478
 479   my $old_attrs = { %{$self->{attrs}} };
 480   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 481
 482   my $new_attrs = { %$old_attrs };
 483
 484   # take care of call attrs (only if anything is changing)
 485   if ($call_attrs and keys %$call_attrs) {
 486
 487     # copy for _normalize_selection
 488     $call_attrs = { %$call_attrs };
 489
 490     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 491
 492     # reset the current selector list if new selectors are supplied
 493     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 494       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 495     }
 496
 497     # Normalize the new selector list (operates on the passed-in attr structure)
 498     # Need to do it on every chain instead of only once on _resolved_attrs, in
 499     # order to allow detection of empty vs partial 'as'
 500     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 501       if $old_attrs->{_dark_selector};
 502     $self->_normalize_selection ($call_attrs);
 503
 504     # start with blind overwriting merge, exclude selector attrs
 505     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 506     delete @{$new_attrs}{@selector_attrs};
 507
 508     for (@selector_attrs) {
 509       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 510         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 511     }
 512
 513     # older deprecated name, use only if {columns} is not there
 514     if (my $c = delete $new_attrs->{cols}) {
 515       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 516       if ($new_attrs->{columns}) {
 517         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 518       }
 519       else {
 520         $new_attrs->{columns} = $c;
 521       }
 522     }
 523
 524
 525     # join/prefetch use their own crazy merging heuristics
 526     foreach my $key (qw/join prefetch/) {
 527       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 528         if exists $call_attrs->{$key};
 529     }
 530
 531     # stack binds together
 532     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 533   }
 534
 535
 536   for ($old_where, $call_cond) {
 537     if (defined $_) {
 538       $new_attrs->{where} = $self->_stack_cond (
 539         $_, $new_attrs->{where}
 540       );
 541     }
 542   }
 543
 544   if (defined $old_having) {
 545     $new_attrs->{having} = $self->_stack_cond (
 546       $old_having, $new_attrs->{having}
 547     )
 548   }
 549
 550   my $rs = (ref $self)->new($rsrc, $new_attrs);
 551
 552   $rs->set_cache($cache) if ($cache);
 553
 554   return $rs;
 555 }
 556
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => do {
 622                 local $Data::Dumper::Indent = 0;
 623                 dump_value $_;
 624               },
 625             };
 626             last SELECTOR;
 627           }
 628         }
 629       }
 630     }
 631     elsif (@$as < @$sel) {
 632       $self->throw_exception(
 633         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 634       );
 635     }
 636     elsif ($pref and $attrs->{_dark_selector}) {
 637       $self->throw_exception(
 638         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 639       );
 640     }
 641
 642
 643     # merge result
 644     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 645     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 646   }
 647 }
 648
 649 sub _stack_cond {
 650   my ($self, $left, $right) = @_;
 651
 652   (
 653     (ref $_ eq 'ARRAY' and !@$_)
 654       or
 655     (ref $_ eq 'HASH' and ! keys %$_)
 656   ) and $_ = undef for ($left, $right);
 657
 658   # either one of the two undef
 659   if ( (defined $left) xor (defined $right) ) {
 660     return defined $left ? $left : $right;
 661   }
 662   # both undef
 663   elsif ( ! defined $left ) {
 664     return undef
 665   }
 666   else {
 667     return $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 668   }
 669 }
 670
 671 =head2 search_literal
 672
 673 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 674 should only be used in that context. C<search_literal> is a convenience
 675 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 676 want to ensure columns are bound correctly, use L</search>.
 677
 678 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 679 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 680 require C<search_literal>.
 681
 682 =over 4
 683
 684 =item Arguments: $sql_fragment, @standalone_bind_values
 685
 686 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 687
 688 =back
 689
 690   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 691   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 692
 693 Pass a literal chunk of SQL to be added to the conditional part of the
 694 resultset query.
 695
 696 Example of how to use C<search> instead of C<search_literal>
 697
 698   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 699   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 700
 701 =cut
 702
 703 sub search_literal {
 704   my ($self, $sql, @bind) = @_;
 705   my $attr;
 706   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 707     $attr = pop @bind;
 708   }
 709   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 710 }
 711
 712 =head2 find
 713
 714 =over 4
 715
 716 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 717
 718 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 719
 720 =back
 721
 722 Finds and returns a single row based on supplied criteria. Takes either a
 723 hashref with the same format as L</create> (including inference of foreign
 724 keys from related objects), or a list of primary key values in the same
 725 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 726 declaration on the L</result_source>.
 727
 728 In either case an attempt is made to combine conditions already existing on
 729 the resultset with the condition passed to this method.
 730
 731 To aid with preparing the correct query for the storage you may supply the
 732 C<key> attribute, which is the name of a
 733 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 734 unique constraint corresponding to the
 735 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 736 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 737 to construct a query that satisfies the named unique constraint fully (
 738 non-NULL values for each column member of the constraint) an exception is
 739 thrown.
 740
 741 If no C<key> is specified, the search is carried over all unique constraints
 742 which are fully defined by the available condition.
 743
 744 If no such constraint is found, C<find> currently defaults to a simple
 745 C<< search->(\%column_values) >> which may or may not do what you expect.
 746 Note that this fallback behavior may be deprecated in further versions. If
 747 you need to search with arbitrary conditions - use L</search>. If the query
 748 resulting from this fallback produces more than one row, a warning to the
 749 effect is issued, though only the first row is constructed and returned as
 750 C<$result_object>.
 751
 752 In addition to C<key>, L</find> recognizes and applies standard
 753 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 754
 755 Note that if you have extra concerns about the correctness of the resulting
 756 query you need to specify the C<key> attribute and supply the entire condition
 757 as an argument to find (since it is not always possible to perform the
 758 combination of the resultset condition with the supplied one, especially if
 759 the resultset condition contains literal sql).
 760
 761 For example, to find a row by its primary key:
 762
 763   my $cd = $schema->resultset('CD')->find(5);
 764
 765 You can also find a row by a specific unique constraint:
 766
 767   my $cd = $schema->resultset('CD')->find(
 768     {
 769       artist => 'Massive Attack',
 770       title  => 'Mezzanine',
 771     },
 772     { key => 'cd_artist_title' }
 773   );
 774
 775 See also L</find_or_create> and L</update_or_create>.
 776
 777 =cut
 778
 779 sub find {
 780   my $self = shift;
 781   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 782
 783   my $rsrc = $self->result_source;
 784
 785   my $constraint_name;
 786   if (exists $attrs->{key}) {
 787     $constraint_name = defined $attrs->{key}
 788       ? $attrs->{key}
 789       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 790     ;
 791   }
 792
 793   # Parse out the condition from input
 794   my $call_cond;
 795
 796   if (ref $_[0] eq 'HASH') {
 797     $call_cond = { %{$_[0]} };
 798   }
 799   else {
 800     # if only values are supplied we need to default to 'primary'
 801     $constraint_name = 'primary' unless defined $constraint_name;
 802
 803     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 804
 805     $self->throw_exception(
 806       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 807     ) unless @c_cols;
 808
 809     $self->throw_exception (
 810       'find() expects either a column/value hashref, or a list of values '
 811     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 812     ) unless @c_cols == @_;
 813
 814     @{$call_cond}{@c_cols} = @_;
 815   }
 816
 817   # process relationship data if any
 818   for my $key (keys %$call_cond) {
 819     if (
 820       length ref($call_cond->{$key})
 821         and
 822       my $relinfo = $rsrc->relationship_info($key)
 823         and
 824       # implicitly skip has_many's (likely MC)
 825       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 826     ) {
 827       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 828         $relinfo->{cond}, $val, $key, $key
 829       );
 830
 831       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 832          if $crosstable or ref($rel_cond) ne 'HASH';
 833
 834       # supplement condition
 835       # relationship conditions take precedence (?)
 836       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 837     }
 838   }
 839
 840   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 841   my $final_cond;
 842   if (defined $constraint_name) {
 843     $final_cond = $self->_qualify_cond_columns (
 844
 845       $self->result_source->_minimal_valueset_satisfying_constraint(
 846         constraint_name => $constraint_name,
 847         values => ($self->_merge_with_rscond($call_cond))[0],
 848         carp_on_nulls => 1,
 849       ),
 850
 851       $alias,
 852     );
 853   }
 854   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 855     # This means that we got here after a merger of relationship conditions
 856     # in ::Relationship::Base::search_related (the row method), and furthermore
 857     # the relationship is of the 'single' type. This means that the condition
 858     # provided by the relationship (already attached to $self) is sufficient,
 859     # as there can be only one row in the database that would satisfy the
 860     # relationship
 861   }
 862   else {
 863     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 864
 865     # no key was specified - fall down to heuristics mode:
 866     # run through all unique queries registered on the resultset, and
 867     # 'OR' all qualifying queries together
 868     #
 869     # always start from 'primary' if it exists at all
 870     for my $c_name ( sort {
 871         $a eq 'primary' ? -1
 872       : $b eq 'primary' ? 1
 873       : $a cmp $b
 874     } $rsrc->unique_constraint_names) {
 875
 876       next if $seen_column_combinations{
 877         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 878       }++;
 879
 880       dbic_internal_try {
 881         push @unique_queries, $self->_qualify_cond_columns(
 882           $self->result_source->_minimal_valueset_satisfying_constraint(
 883             constraint_name => $c_name,
 884             values => ($self->_merge_with_rscond($call_cond))[0],
 885             columns_info => ($ci ||= $self->result_source->columns_info),
 886           ),
 887           $alias
 888         );
 889       }
 890       catch {
 891         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 892       };
 893     }
 894
 895     $final_cond =
 896         @unique_queries   ? \@unique_queries
 897       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 898       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 899     ;
 900   }
 901
 902   # Run the query, passing the result_class since it should propagate for find
 903   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 904   if ($rs->_resolved_attrs->{collapse}) {
 905     my $row = $rs->next;
 906     carp "Query returned more than one row" if $rs->next;
 907     return $row;
 908   }
 909   else {
 910     return $rs->single;
 911   }
 912 }
 913
 914 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 915 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 916 #
 917 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 918 # condition. It is provided for overrides until a saner way forward is devised
 919 #
 920 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 921 # the road. Please adjust your tests accordingly to catch this situation early
 922 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 923 #
 924 # The method will not be removed without an adequately complete replacement
 925 # for strict-mode enforcement
 926 sub _non_unique_find_fallback {
 927   my ($self, $cond, $attrs) = @_;
 928
 929   return $self->_qualify_cond_columns(
 930     $cond,
 931     exists $attrs->{alias}
 932       ? $attrs->{alias}
 933       : $self->{attrs}{alias}
 934   );
 935 }
 936
 937
 938 sub _qualify_cond_columns {
 939   my ($self, $cond, $alias) = @_;
 940
 941   my %aliased = %$cond;
 942   for (keys %aliased) {
 943     $aliased{"$alias.$_"} = delete $aliased{$_}
 944       if $_ !~ /\./;
 945   }
 946
 947   return \%aliased;
 948 }
 949
 950 sub _build_unique_cond {
 951   carp_unique sprintf
 952     '_build_unique_cond is a private method, and moreover is about to go '
 953   . 'away. Please contact the development team at %s if you believe you '
 954   . 'have a genuine use for this method, in order to discuss alternatives.',
 955     DBIx::Class::_ENV_::HELP_URL,
 956   ;
 957
 958   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 959
 960   $self->result_source->_minimal_valueset_satisfying_constraint(
 961     constraint_name => $constraint_name,
 962     values => $cond,
 963     carp_on_nulls => !$croak_on_null
 964   );
 965 }
 966
 967 =head2 search_related
 968
 969 =over 4
 970
 971 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 972
 973 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 974
 975 =back
 976
 977   $new_rs = $cd_rs->search_related('artist', {
 978     name => 'Emo-R-Us',
 979   });
 980
 981 Searches the specified relationship, optionally specifying a condition and
 982 attributes for matching records. See L</ATTRIBUTES> for more information.
 983
 984 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 985 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 986
 987 See also L</search_related_rs>.
 988
 989 =cut
 990
 991 sub search_related {
 992   return shift->related_resultset(shift)->search(@_);
 993 }
 994
 995 =head2 search_related_rs
 996
 997 This method works exactly the same as search_related, except that
 998 it guarantees a resultset, even in list context.
 999
1000 =cut
1001
1002 sub search_related_rs {
1003   return shift->related_resultset(shift)->search_rs(@_);
1004 }
1005
1006 =head2 cursor
1007
1008 =over 4
1009
1010 =item Arguments: none
1011
1012 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1013
1014 =back
1015
1016 Returns a storage-driven cursor to the given resultset. See
1017 L<DBIx::Class::Cursor> for more information.
1018
1019 =cut
1020
1021 sub cursor {
1022   my $self = shift;
1023
1024   return $self->{cursor} ||= do {
1025     my $attrs = $self->_resolved_attrs;
1026     $self->result_source->storage->select(
1027       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1028     );
1029   };
1030 }
1031
1032 =head2 single
1033
1034 =over 4
1035
1036 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1037
1038 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1039
1040 =back
1041
1042   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1043
1044 Inflates the first result without creating a cursor if the resultset has
1045 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1046 of L</search>.
1047
1048 While this method can take an optional search condition (just like L</search>)
1049 being a fast-code-path it does not recognize search attributes. If you need to
1050 add extra joins or similar, call L</search> and then chain-call L</single> on the
1051 L<DBIx::Class::ResultSet> returned.
1052
1053 =over
1054
1055 =item B<Note>
1056
1057 As of 0.08100, this method enforces the assumption that the preceding
1058 query returns only one row. If more than one row is returned, you will receive
1059 a warning:
1060
1061   Query returned more than one row
1062
1063 In this case, you should be using L</next> or L</find> instead, or if you really
1064 know what you are doing, use the L</rows> attribute to explicitly limit the size
1065 of the resultset.
1066
1067 This method will also throw an exception if it is called on a resultset prefetching
1068 has_many, as such a prefetch implies fetching multiple rows from the database in
1069 order to assemble the resulting object.
1070
1071 =back
1072
1073 =cut
1074
1075 sub single {
1076   my ($self, $where) = @_;
1077   if(@_ > 2) {
1078       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1079   }
1080
1081   my $attrs = { %{$self->_resolved_attrs} };
1082
1083   $self->throw_exception(
1084     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1085   ) if $attrs->{collapse};
1086
1087   if ($where) {
1088     if (defined $attrs->{where}) {
1089       $attrs->{where} = {
1090         '-and' =>
1091             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1092                $where, delete $attrs->{where} ]
1093       };
1094     } else {
1095       $attrs->{where} = $where;
1096     }
1097   }
1098
1099   my $data = [ $self->result_source->storage->select_single(
1100     $attrs->{from}, $attrs->{select},
1101     $attrs->{where}, $attrs
1102   )];
1103
1104   return undef unless @$data;
1105   $self->{_stashed_rows} = [ $data ];
1106   $self->_construct_results->[0];
1107 }
1108
1109 =head2 get_column
1110
1111 =over 4
1112
1113 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1114
1115 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1116
1117 =back
1118
1119   my $max_length = $rs->get_column('length')->max;
1120
1121 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1122
1123 =cut
1124
1125 sub get_column {
1126   my ($self, $column) = @_;
1127   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1128   return $new;
1129 }
1130
1131 =head2 search_like
1132
1133 =over 4
1134
1135 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1136
1137 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1138
1139 =back
1140
1141   # WHERE title LIKE '%blue%'
1142   $cd_rs = $rs->search_like({ title => '%blue%'});
1143
1144 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1145 that this is simply a convenience method retained for ex Class::DBI users.
1146 You most likely want to use L</search> with specific operators.
1147
1148 For more information, see L<DBIx::Class::Manual::Cookbook>.
1149
1150 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1151 instead. An example conversion is:
1152
1153   ->search_like({ foo => 'bar' });
1154
1155   # Becomes
1156
1157   ->search({ foo => { like => 'bar' } });
1158
1159 =cut
1160
1161 sub search_like {
1162   my $class = shift;
1163   carp_unique (
1164     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1165    .' Instead use ->search({ x => { -like => "y%" } })'
1166    .' (note the outer pair of {}s - they are important!)'
1167   );
1168   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1169   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1170   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1171   return $class->search($query, { %$attrs });
1172 }
1173
1174 =head2 slice
1175
1176 =over 4
1177
1178 =item Arguments: $first, $last
1179
1180 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1181
1182 =back
1183
1184 Returns a resultset or object list representing a subset of elements from the
1185 resultset slice is called on. Indexes are from 0, i.e., to get the first
1186 three records, call:
1187
1188   my ($one, $two, $three) = $rs->slice(0, 2);
1189
1190 =cut
1191
1192 sub slice {
1193   my ($self, $min, $max) = @_;
1194   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1195   $attrs->{offset} = $self->{attrs}{offset} || 0;
1196   $attrs->{offset} += $min;
1197   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1198   return $self->search(undef, $attrs);
1199 }
1200
1201 =head2 next
1202
1203 =over 4
1204
1205 =item Arguments: none
1206
1207 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1208
1209 =back
1210
1211 Returns the next element in the resultset (C<undef> is there is none).
1212
1213 Can be used to efficiently iterate over records in the resultset:
1214
1215   my $rs = $schema->resultset('CD')->search;
1216   while (my $cd = $rs->next) {
1217     print $cd->title;
1218   }
1219
1220 Note that you need to store the resultset object, and call C<next> on it.
1221 Calling C<< resultset('Table')->next >> repeatedly will always return the
1222 first record from the resultset.
1223
1224 =cut
1225
1226 sub next {
1227   my ($self) = @_;
1228
1229   if (my $cache = $self->get_cache) {
1230     $self->{all_cache_position} ||= 0;
1231     return $cache->[$self->{all_cache_position}++];
1232   }
1233
1234   if ($self->{attrs}{cache}) {
1235     delete $self->{pager};
1236     $self->{all_cache_position} = 1;
1237     return ($self->all)[0];
1238   }
1239
1240   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1241
1242   $self->{_stashed_results} = $self->_construct_results
1243     or return undef;
1244
1245   return shift @{$self->{_stashed_results}};
1246 }
1247
1248 # Constructs as many results as it can in one pass while respecting
1249 # cursor laziness. Several modes of operation:
1250 #
1251 # * Always builds everything present in @{$self->{_stashed_rows}}
1252 # * If called with $fetch_all true - pulls everything off the cursor and
1253 #   builds all result structures (or objects) in one pass
1254 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1255 #   and if the resultset is ordered properly by the left side:
1256 #   * Fetches stuff off the cursor until the "master object" changes,
1257 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1258 #   OR
1259 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1260 #     was requested (there is no other way to collapse except for an
1261 #     eager cursor)
1262 # * If no collapse is requested - just get the next row, construct and
1263 #   return
1264 sub _construct_results {
1265   my ($self, $fetch_all) = @_;
1266
1267   my $rsrc = $self->result_source;
1268   my $attrs = $self->_resolved_attrs;
1269
1270   if (
1271     ! $fetch_all
1272       and
1273     ! $attrs->{order_by}
1274       and
1275     $attrs->{collapse}
1276       and
1277     my @pcols = $rsrc->primary_columns
1278   ) {
1279     # default order for collapsing unless the user asked for something
1280     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1281     $attrs->{_ordered_for_collapse} = 1;
1282     $attrs->{_order_is_artificial} = 1;
1283   }
1284
1285   # this will be used as both initial raw-row collector AND as a RV of
1286   # _construct_results. Not regrowing the array twice matters a lot...
1287   # a surprising amount actually
1288   my $rows = delete $self->{_stashed_rows};
1289
1290   my $cursor; # we may not need one at all
1291
1292   my $did_fetch_all = $fetch_all;
1293
1294   if ($fetch_all) {
1295     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1296     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1297   }
1298   elsif( $attrs->{collapse} ) {
1299
1300     # a cursor will need to be closed over in case of collapse
1301     $cursor = $self->cursor;
1302
1303     $attrs->{_ordered_for_collapse} = (
1304       (
1305         $attrs->{order_by}
1306           and
1307         $rsrc->schema
1308               ->storage
1309                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1310       ) ? 1 : 0
1311     ) unless defined $attrs->{_ordered_for_collapse};
1312
1313     if (! $attrs->{_ordered_for_collapse}) {
1314       $did_fetch_all = 1;
1315
1316       # instead of looping over ->next, use ->all in stealth mode
1317       # *without* calling a ->reset afterwards
1318       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1319       if (! $cursor->{_done}) {
1320         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1321         $cursor->{_done} = 1;
1322       }
1323     }
1324   }
1325
1326   if (! $did_fetch_all and ! @{$rows||[]} ) {
1327     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1328     $cursor ||= $self->cursor;
1329     if (scalar (my @r = $cursor->next) ) {
1330       $rows = [ \@r ];
1331     }
1332   }
1333
1334   return undef unless @{$rows||[]};
1335
1336   # sanity check - people are too clever for their own good
1337   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1338
1339     my $multiplied_selectors;
1340     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1341       if (
1342         $aliastypes->{multiplying}{$sel_alias}
1343           or
1344         $aliastypes->{premultiplied}{$sel_alias}
1345       ) {
1346         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1347       }
1348     }
1349
1350     for my $i (0 .. $#{$attrs->{as}} ) {
1351       my $sel = $attrs->{select}[$i];
1352
1353       if (ref $sel eq 'SCALAR') {
1354         $sel = $$sel;
1355       }
1356       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1357         $sel = $$sel->[0];
1358       }
1359
1360       $self->throw_exception(
1361         'Result collapse not possible - selection from a has_many source redirected to the main object'
1362       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1363     }
1364   }
1365
1366   # hotspot - skip the setter
1367   my $res_class = $self->_result_class;
1368
1369   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1370     $res_class->can ('inflate_result')
1371       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1372   };
1373
1374   my $infmap = $attrs->{as};
1375
1376   $self->{_result_inflator}{is_core_row} = ( (
1377     $inflator_cref
1378       ==
1379     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1380   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1381
1382   $self->{_result_inflator}{is_hri} = ( (
1383     ! $self->{_result_inflator}{is_core_row}
1384       and
1385     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1386   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1387
1388
1389   if ($attrs->{_simple_passthrough_construction}) {
1390     # construct a much simpler array->hash folder for the one-table HRI cases right here
1391     if ($self->{_result_inflator}{is_hri}) {
1392       for my $r (@$rows) {
1393         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1394       }
1395     }
1396     # FIXME SUBOPTIMAL this is a very very very hot spot
1397     # while rather optimal we can *still* do much better, by
1398     # building a smarter Row::inflate_result(), and
1399     # switch to feeding it data via a much leaner interface
1400     #
1401     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1402     # this particular resultset size
1403     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1404       for my $r (@$rows) {
1405         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1406       }
1407     }
1408     else {
1409       eval sprintf (
1410         ( $self->{_result_inflator}{is_core_row}
1411           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1412           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1413           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1414         ),
1415         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1416       );
1417     }
1418   }
1419   else {
1420     my $parser_type =
1421         $self->{_result_inflator}{is_hri}       ? 'hri'
1422       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1423       :                                           'classic_nonpruning'
1424     ;
1425
1426     # $args and $attrs to _mk_row_parser are separated to delineate what is
1427     # core collapser stuff and what is dbic $rs specific
1428     $self->{_row_parser}{$parser_type}{cref} = $rsrc->_mk_row_parser({
1429       eval => 1,
1430       inflate_map => $infmap,
1431       collapse => $attrs->{collapse},
1432       premultiplied => $attrs->{_main_source_premultiplied},
1433       hri_style => $self->{_result_inflator}{is_hri},
1434       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1435     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1436
1437     my $next_cref = ($did_fetch_all or ! $attrs->{collapse})
1438       ? undef
1439       : sub {
1440         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1441         my @r = $cursor->next or return;
1442         \@r
1443       }
1444     ;
1445
1446     $self->{_row_parser}{$parser_type}{cref}->(
1447       $rows,
1448       $next_cref,
1449       ( $self->{_stashed_rows} = [] ),
1450       ( my $null_violations = {} ),
1451     );
1452
1453     $self->throw_exception(
1454       'Collapse aborted - the following columns are declared (or defaulted to) '
1455     . 'non-nullable within DBIC but NULLs were retrieved from storage: '
1456     . join( ', ', map { "'$infmap->[$_]'" } sort { $a <=> $b } keys %$null_violations )
1457     . ' within data row ' . dump_value({
1458       map {
1459         $infmap->[$_] =>
1460           ( ! defined $self->{_stashed_rows}[0][$_] or length $self->{_stashed_rows}[0][$_] < 50 )
1461             ? $self->{_stashed_rows}[0][$_]
1462             : substr( $self->{_stashed_rows}[0][$_], 0, 50 ) . '...'
1463       } 0 .. $#{$self->{_stashed_rows}[0]}
1464     })
1465     ) if keys %$null_violations;
1466
1467     # simple in-place substitution, does not regrow $rows
1468     if ($self->{_result_inflator}{is_core_row}) {
1469       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1470     }
1471     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1472     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1473       # the inflator may be a multiplier/reductor - put it in list ctx
1474       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1475     }
1476   }
1477
1478   # The @$rows check seems odd at first - why wouldn't we want to warn
1479   # regardless? The issue is things like find() etc, where the user
1480   # *knows* only one result will come back. In these cases the ->all
1481   # is not a pessimization, but rather something we actually want
1482   carp_unique(
1483     'Unable to properly collapse has_many results in iterator mode due '
1484   . 'to order criteria - performed an eager cursor slurp underneath. '
1485   . 'Consider using ->all() instead'
1486   ) if ( ! $fetch_all and @$rows > 1 );
1487
1488   return $rows;
1489 }
1490
1491 =head2 result_source
1492
1493 =over 4
1494
1495 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1496
1497 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1498
1499 =back
1500
1501 An accessor for the primary ResultSource object from which this ResultSet
1502 is derived.
1503
1504 =head2 result_class
1505
1506 =over 4
1507
1508 =item Arguments: $result_class?
1509
1510 =item Return Value: $result_class
1511
1512 =back
1513
1514 An accessor for the class to use when creating result objects. Defaults to
1515 C<< result_source->result_class >> - which in most cases is the name of the
1516 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1517
1518 Note that changing the result_class will also remove any components
1519 that were originally loaded in the source class via
1520 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1521 Any overloaded methods in the original source class will not run.
1522
1523 =cut
1524
1525 sub result_class {
1526   my ($self, $result_class) = @_;
1527   if ($result_class) {
1528
1529     # don't fire this for an object
1530     $self->ensure_class_loaded($result_class)
1531       unless ref($result_class);
1532
1533     if ($self->get_cache) {
1534       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1535     }
1536     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1537     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1538       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1539     }
1540
1541     $self->_result_class($result_class);
1542
1543     delete $self->{_result_inflator};
1544   }
1545   $self->_result_class;
1546 }
1547
1548 =head2 count
1549
1550 =over 4
1551
1552 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1553
1554 =item Return Value: $count
1555
1556 =back
1557
1558 Performs an SQL C<COUNT> with the same query as the resultset was built
1559 with to find the number of elements. Passing arguments is equivalent to
1560 C<< $rs->search ($cond, \%attrs)->count >>
1561
1562 =cut
1563
1564 sub count {
1565   my $self = shift;
1566   return $self->search(@_)->count if @_ and defined $_[0];
1567   return scalar @{ $self->get_cache } if $self->get_cache;
1568
1569   my $attrs = { %{ $self->_resolved_attrs } };
1570
1571   # this is a little optimization - it is faster to do the limit
1572   # adjustments in software, instead of a subquery
1573   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1574
1575   my $crs;
1576   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1577     $crs = $self->_count_subq_rs ($attrs);
1578   }
1579   else {
1580     $crs = $self->_count_rs ($attrs);
1581   }
1582   my $count = $crs->next;
1583
1584   $count -= $offset if $offset;
1585   $count = $rows if $rows and $rows < $count;
1586   $count = 0 if ($count < 0);
1587
1588   return $count;
1589 }
1590
1591 =head2 count_rs
1592
1593 =over 4
1594
1595 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1596
1597 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1598
1599 =back
1600
1601 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1602 This can be very handy for subqueries:
1603
1604   ->search( { amount => $some_rs->count_rs->as_query } )
1605
1606 As with regular resultsets the SQL query will be executed only after
1607 the resultset is accessed via L</next> or L</all>. That would return
1608 the same single value obtainable via L</count>.
1609
1610 =cut
1611
1612 sub count_rs {
1613   my $self = shift;
1614   return $self->search(@_)->count_rs if @_;
1615
1616   # this may look like a lack of abstraction (count() does about the same)
1617   # but in fact an _rs *must* use a subquery for the limits, as the
1618   # software based limiting can not be ported if this $rs is to be used
1619   # in a subquery itself (i.e. ->as_query)
1620   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1621     return $self->_count_subq_rs($self->{_attrs});
1622   }
1623   else {
1624     return $self->_count_rs($self->{_attrs});
1625   }
1626 }
1627
1628 #
1629 # returns a ResultSetColumn object tied to the count query
1630 #
1631 sub _count_rs {
1632   my ($self, $attrs) = @_;
1633
1634   my $rsrc = $self->result_source;
1635
1636   my $tmp_attrs = { %$attrs };
1637   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1638   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1639
1640   # overwrite the selector (supplied by the storage)
1641   $rsrc->resultset_class->new($rsrc, {
1642     %$tmp_attrs,
1643     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1644     as => 'count',
1645   })->get_column ('count');
1646 }
1647
1648 #
1649 # same as above but uses a subquery
1650 #
1651 sub _count_subq_rs {
1652   my ($self, $attrs) = @_;
1653
1654   my $rsrc = $self->result_source;
1655
1656   my $sub_attrs = { %$attrs };
1657   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1658   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1659
1660   # if we multi-prefetch we group_by something unique, as this is what we would
1661   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1662   if ( $attrs->{collapse}  ) {
1663     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1664       $rsrc->_identifying_column_set || $self->throw_exception(
1665         'Unable to construct a unique group_by criteria properly collapsing the '
1666       . 'has_many prefetch before count()'
1667       );
1668     } ]
1669   }
1670
1671   # Calculate subquery selector
1672   if (my $g = $sub_attrs->{group_by}) {
1673
1674     my $sql_maker = $rsrc->storage->sql_maker;
1675
1676     # necessary as the group_by may refer to aliased functions
1677     my $sel_index;
1678     for my $sel (@{$attrs->{select}}) {
1679       $sel_index->{$sel->{-as}} = $sel
1680         if (ref $sel eq 'HASH' and $sel->{-as});
1681     }
1682
1683     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1684     # also look for named aggregates referred in the having clause
1685     # having often contains scalarrefs - thus parse it out entirely
1686     my @parts = @$g;
1687     if ($attrs->{having}) {
1688       local $sql_maker->{having_bind};
1689       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1690       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1691       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1692         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1693         # if we don't unset it we screw up retarded but unfortunately working
1694         # 'MAX(foo.bar)' => { '>', 3 }
1695         $sql_maker->{name_sep} = '';
1696       }
1697
1698       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1699
1700       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1701       my %seen_having;
1702
1703       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1704       # and if all fails for an utterly naive quoted scalar-with-function
1705       while ($having_sql =~ /
1706         $rquote $sep $lquote (.+?) $rquote
1707           |
1708         [\s,] \w+ \. (\w+) [\s,]
1709           |
1710         [\s,] $lquote (.+?) $rquote [\s,]
1711       /gx) {
1712         my $part = $1 || $2 || $3;  # one of them matched if we got here
1713         unless ($seen_having{$part}++) {
1714           push @parts, $part;
1715         }
1716       }
1717     }
1718
1719     for (@parts) {
1720       my $colpiece = $sel_index->{$_} || $_;
1721
1722       # unqualify join-based group_by's. Arcane but possible query
1723       # also horrible horrible hack to alias a column (not a func.)
1724       # (probably need to introduce SQLA syntax)
1725       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1726         my $as = $colpiece;
1727         $as =~ s/\./__/;
1728         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1729       }
1730       push @{$sub_attrs->{select}}, $colpiece;
1731     }
1732   }
1733   else {
1734     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1735     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1736   }
1737
1738   return $rsrc->resultset_class
1739                ->new ($rsrc, $sub_attrs)
1740                 ->as_subselect_rs
1741                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1742                   ->get_column ('count');
1743 }
1744
1745
1746 =head2 count_literal
1747
1748 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1749 should only be used in that context. See L</search_literal> for further info.
1750
1751 =over 4
1752
1753 =item Arguments: $sql_fragment, @standalone_bind_values
1754
1755 =item Return Value: $count
1756
1757 =back
1758
1759 Counts the results in a literal query. Equivalent to calling L</search_literal>
1760 with the passed arguments, then L</count>.
1761
1762 =cut
1763
1764 sub count_literal { shift->search_literal(@_)->count; }
1765
1766 =head2 all
1767
1768 =over 4
1769
1770 =item Arguments: none
1771
1772 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1773
1774 =back
1775
1776 Returns all elements in the resultset.
1777
1778 =cut
1779
1780 sub all {
1781   my $self = shift;
1782   if(@_) {
1783     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1784   }
1785
1786   delete @{$self}{qw/_stashed_rows _stashed_results/};
1787
1788   if (my $c = $self->get_cache) {
1789     return @$c;
1790   }
1791
1792   $self->cursor->reset;
1793
1794   my $objs = $self->_construct_results('fetch_all') || [];
1795
1796   $self->set_cache($objs) if $self->{attrs}{cache};
1797
1798   return @$objs;
1799 }
1800
1801 =head2 reset
1802
1803 =over 4
1804
1805 =item Arguments: none
1806
1807 =item Return Value: $self
1808
1809 =back
1810
1811 Resets the resultset's cursor, so you can iterate through the elements again.
1812 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1813 another query.
1814
1815 =cut
1816
1817 sub reset {
1818   my ($self) = @_;
1819
1820   delete @{$self}{qw/_stashed_rows _stashed_results/};
1821   $self->{all_cache_position} = 0;
1822   $self->cursor->reset;
1823   return $self;
1824 }
1825
1826 =head2 first
1827
1828 =over 4
1829
1830 =item Arguments: none
1831
1832 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1833
1834 =back
1835
1836 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1837 an object for the first result (or C<undef> if the resultset is empty).
1838
1839 =cut
1840
1841 sub first {
1842   return $_[0]->reset->next;
1843 }
1844
1845
1846 # _rs_update_delete
1847 #
1848 # Determines whether and what type of subquery is required for the $rs operation.
1849 # If grouping is necessary either supplies its own, or verifies the current one
1850 # After all is done delegates to the proper storage method.
1851
1852 sub _rs_update_delete {
1853   my ($self, $op, $values) = @_;
1854
1855   my $rsrc = $self->result_source;
1856   my $storage = $rsrc->schema->storage;
1857
1858   my $attrs = { %{$self->_resolved_attrs} };
1859
1860   my $join_classifications;
1861   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1862
1863   # do we need a subquery for any reason?
1864   my $needs_subq = (
1865     defined $existing_group_by
1866       or
1867     # if {from} is unparseable wrap a subq
1868     ref($attrs->{from}) ne 'ARRAY'
1869       or
1870     # limits call for a subq
1871     $self->_has_resolved_attr(qw/rows offset/)
1872   );
1873
1874   # simplify the joinmap, so we can further decide if a subq is necessary
1875   if (!$needs_subq and @{$attrs->{from}} > 1) {
1876
1877     ($attrs->{from}, $join_classifications) =
1878       $storage->_prune_unused_joins ($attrs);
1879
1880     # any non-pruneable non-local restricting joins imply subq
1881     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1882   }
1883
1884   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1885   $needs_subq ||= (
1886     (ref $attrs->{from}[0]) ne 'HASH'
1887       or
1888     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1889   );
1890
1891   my ($cond, $guard);
1892   # do we need anything like a subquery?
1893   if (! $needs_subq) {
1894     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1895     # a condition containing 'me' or other table prefixes will not work
1896     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1897     $cond = do {
1898       my $sqla = $rsrc->storage->sql_maker;
1899       local $sqla->{_dequalify_idents} = 1;
1900       \[ $sqla->_recurse_where($self->{cond}) ];
1901     };
1902   }
1903   else {
1904     # we got this far - means it is time to wrap a subquery
1905     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1906       sprintf(
1907         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1908         $op,
1909         $rsrc->source_name,
1910       )
1911     );
1912
1913     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1914     delete $attrs->{$_} for qw/select as collapse/;
1915     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1916
1917     # this will be consumed by the pruner waaaaay down the stack
1918     $attrs->{_force_prune_multiplying_joins} = 1;
1919
1920     my $subrs = (ref $self)->new($rsrc, $attrs);
1921
1922     if (@$idcols == 1) {
1923       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1924     }
1925     elsif ($storage->_use_multicolumn_in) {
1926       # no syntax for calling this properly yet
1927       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1928       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1929         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1930         $subrs->as_query
1931       ),
1932     }
1933     else {
1934       # if all else fails - get all primary keys and operate over a ORed set
1935       # wrap in a transaction for consistency
1936       # this is where the group_by/multiplication starts to matter
1937       if (
1938         $existing_group_by
1939           or
1940         # we do not need to check pre-multipliers, since if the premulti is there, its
1941         # parent (who is multi) will be there too
1942         keys %{ $join_classifications->{multiplying} || {} }
1943       ) {
1944         # make sure if there is a supplied group_by it matches the columns compiled above
1945         # perfectly. Anything else can not be sanely executed on most databases so croak
1946         # right then and there
1947         if ($existing_group_by) {
1948           my @current_group_by = map
1949             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1950             @$existing_group_by
1951           ;
1952
1953           if (
1954             join ("\x00", sort @current_group_by)
1955               ne
1956             join ("\x00", sort @{$attrs->{columns}} )
1957           ) {
1958             $self->throw_exception (
1959               "You have just attempted a $op operation on a resultset which does group_by"
1960               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1961               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1962               . ' kind of queries. Please retry the operation with a modified group_by or'
1963               . ' without using one at all.'
1964             );
1965           }
1966         }
1967
1968         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1969       }
1970
1971       $guard = $storage->txn_scope_guard;
1972
1973       for my $row ($subrs->cursor->all) {
1974         push @$cond, { map
1975           { $idcols->[$_] => $row->[$_] }
1976           (0 .. $#$idcols)
1977         };
1978       }
1979     }
1980   }
1981
1982   my $res = $cond ? $storage->$op (
1983     $rsrc,
1984     $op eq 'update' ? $values : (),
1985     $cond,
1986   ) : '0E0';
1987
1988   $guard->commit if $guard;
1989
1990   return $res;
1991 }
1992
1993 =head2 update
1994
1995 =over 4
1996
1997 =item Arguments: \%values
1998
1999 =item Return Value: $underlying_storage_rv
2000
2001 =back
2002
2003 Sets the specified columns in the resultset to the supplied values in a
2004 single query. Note that this will not run any accessor/set_column/update
2005 triggers, nor will it update any result object instances derived from this
2006 resultset (this includes the contents of the L<resultset cache|/set_cache>
2007 if any). See L</update_all> if you need to execute any on-update
2008 triggers or cascades defined either by you or a
2009 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2010
2011 The return value is a pass through of what the underlying
2012 storage backend returned, and may vary. See L<DBI/execute> for the most
2013 common case.
2014
2015 =head3 CAVEAT
2016
2017 Note that L</update> does not process/deflate any of the values passed in.
2018 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2019 ensure manually that any value passed to this method will stringify to
2020 something the RDBMS knows how to deal with. A notable example is the
2021 handling of L<DateTime> objects, for more info see:
2022 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2023
2024 =cut
2025
2026 sub update {
2027   my ($self, $values) = @_;
2028   $self->throw_exception('Values for update must be a hash')
2029     unless ref $values eq 'HASH';
2030
2031   return $self->_rs_update_delete ('update', $values);
2032 }
2033
2034 =head2 update_all
2035
2036 =over 4
2037
2038 =item Arguments: \%values
2039
2040 =item Return Value: 1
2041
2042 =back
2043
2044 Fetches all objects and updates them one at a time via
2045 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2046 triggers, while L</update> will not.
2047
2048 =cut
2049
2050 sub update_all {
2051   my ($self, $values) = @_;
2052   $self->throw_exception('Values for update_all must be a hash')
2053     unless ref $values eq 'HASH';
2054
2055   my $guard = $self->result_source->schema->txn_scope_guard;
2056   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2057   $guard->commit;
2058   return 1;
2059 }
2060
2061 =head2 delete
2062
2063 =over 4
2064
2065 =item Arguments: none
2066
2067 =item Return Value: $underlying_storage_rv
2068
2069 =back
2070
2071 Deletes the rows matching this resultset in a single query. Note that this
2072 will not run any delete triggers, nor will it alter the
2073 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2074 derived from this resultset (this includes the contents of the
2075 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2076 execute any on-delete triggers or cascades defined either by you or a
2077 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2078
2079 The return value is a pass through of what the underlying storage backend
2080 returned, and may vary. See L<DBI/execute> for the most common case.
2081
2082 =cut
2083
2084 sub delete {
2085   my $self = shift;
2086   $self->throw_exception('delete does not accept any arguments')
2087     if @_;
2088
2089   return $self->_rs_update_delete ('delete');
2090 }
2091
2092 =head2 delete_all
2093
2094 =over 4
2095
2096 =item Arguments: none
2097
2098 =item Return Value: 1
2099
2100 =back
2101
2102 Fetches all objects and deletes them one at a time via
2103 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2104 triggers, while L</delete> will not.
2105
2106 =cut
2107
2108 sub delete_all {
2109   my $self = shift;
2110   $self->throw_exception('delete_all does not accept any arguments')
2111     if @_;
2112
2113   my $guard = $self->result_source->schema->txn_scope_guard;
2114   $_->delete for $self->all;
2115   $guard->commit;
2116   return 1;
2117 }
2118
2119 =head2 populate
2120
2121 =over 4
2122
2123 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2124
2125 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2126
2127 =back
2128
2129 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2130 arrayrefs.
2131
2132 =over
2133
2134 =item NOTE
2135
2136 The context of this method call has an important effect on what is
2137 submitted to storage. In void context data is fed directly to fastpath
2138 insertion routines provided by the underlying storage (most often
2139 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2140 L<insert|DBIx::Class::Row/insert> calls on the
2141 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2142 augmentation of these methods provided by components. For example if you
2143 are using something like L<DBIx::Class::UUIDColumns> to create primary
2144 keys for you, you will find that your PKs are empty.  In this case you
2145 will have to explicitly force scalar or list context in order to create
2146 those values.
2147
2148 =back
2149
2150 In non-void (scalar or list) context, this method is simply a wrapper
2151 for L</create>. Depending on list or scalar context either a list of
2152 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2153 containing these objects is returned.
2154
2155 When supplying data in "arrayref of arrayrefs" invocation style, the
2156 first element should be a list of column names and each subsequent
2157 element should be a data value in the earlier specified column order.
2158 For example:
2159
2160   $schema->resultset("Artist")->populate([
2161     [ qw( artistid name ) ],
2162     [ 100, 'A Formally Unknown Singer' ],
2163     [ 101, 'A singer that jumped the shark two albums ago' ],
2164     [ 102, 'An actually cool singer' ],
2165   ]);
2166
2167 For the arrayref of hashrefs style each hashref should be a structure
2168 suitable for passing to L</create>. Multi-create is also permitted with
2169 this syntax.
2170
2171   $schema->resultset("Artist")->populate([
2172      { artistid => 4, name => 'Manufactured Crap', cds => [
2173         { title => 'My First CD', year => 2006 },
2174         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2175       ],
2176      },
2177      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2178         { title => 'My parents sold me to a record company', year => 2005 },
2179         { title => 'Why Am I So Ugly?', year => 2006 },
2180         { title => 'I Got Surgery and am now Popular', year => 2007 }
2181       ],
2182      },
2183   ]);
2184
2185 If you attempt a void-context multi-create as in the example above (each
2186 Artist also has the related list of CDs), and B<do not> supply the
2187 necessary autoinc foreign key information, this method will proxy to the
2188 less efficient L</create>, and then throw the Result objects away. In this
2189 case there are obviously no benefits to using this method over L</create>.
2190
2191 =cut
2192
2193 sub populate {
2194   my $self = shift;
2195
2196   # this is naive and just a quick check
2197   # the types will need to be checked more thoroughly when the
2198   # multi-source populate gets added
2199   my $data = (
2200     ref $_[0] eq 'ARRAY'
2201       and
2202     ( @{$_[0]} or return )
2203       and
2204     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2205       and
2206     $_[0]
2207   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2208
2209   # FIXME - no cref handling
2210   # At this point assume either hashes or arrays
2211
2212   if(defined wantarray) {
2213     my (@results, $guard);
2214
2215     if (ref $data->[0] eq 'ARRAY') {
2216       # column names only, nothing to do
2217       return if @$data == 1;
2218
2219       $guard = $self->result_source->schema->storage->txn_scope_guard
2220         if @$data > 2;
2221
2222       @results = map
2223         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2224         @{$data}[1 .. $#$data]
2225       ;
2226     }
2227     else {
2228
2229       $guard = $self->result_source->schema->storage->txn_scope_guard
2230         if @$data > 1;
2231
2232       @results = map { $self->new_result($_)->insert } @$data;
2233     }
2234
2235     $guard->commit if $guard;
2236     return wantarray ? @results : \@results;
2237   }
2238
2239   # we have to deal with *possibly incomplete* related data
2240   # this means we have to walk the data structure twice
2241   # whether we want this or not
2242   # jnap, I hate you ;)
2243   my $rsrc = $self->result_source;
2244   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2245
2246   my ($colinfo, $colnames, $slices_with_rels);
2247   my $data_start = 0;
2248
2249   DATA_SLICE:
2250   for my $i (0 .. $#$data) {
2251
2252     my $current_slice_seen_rel_infos;
2253
2254 ### Determine/Supplement collists
2255 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2256     if( ref $data->[$i] eq 'ARRAY' ) {
2257
2258       # positional(!) explicit column list
2259       if ($i == 0) {
2260         # column names only, nothing to do
2261         return if @$data == 1;
2262
2263         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2264           for 0 .. $#{$data->[0]};
2265
2266         $data_start = 1;
2267
2268         next DATA_SLICE;
2269       }
2270       else {
2271         for (values %$colinfo) {
2272           if ($_->{is_rel} ||= (
2273             $rel_info->{$_->{name}}
2274               and
2275             (
2276               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2277                 or
2278               ref $data->[$i][$_->{pos}] eq 'HASH'
2279                 or
2280               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2281             )
2282               and
2283             1
2284           )) {
2285
2286             # moar sanity check... sigh
2287             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2288               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2289                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2290                 return my $throwaway = $self->populate(@_);
2291               }
2292             }
2293
2294             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2295           }
2296         }
2297       }
2298
2299      if ($current_slice_seen_rel_infos) {
2300         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2301
2302         # this is needed further down to decide whether or not to fallback to create()
2303         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2304           for 0 .. $#$colnames;
2305       }
2306     }
2307     elsif( ref $data->[$i] eq 'HASH' ) {
2308
2309       for ( sort keys %{$data->[$i]} ) {
2310
2311         $colinfo->{$_} ||= do {
2312
2313           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2314             if $data_start; # it will be 0 on AoH, 1 on AoA
2315
2316           push @$colnames, $_;
2317
2318           # RV
2319           { pos => $#$colnames, name => $_ }
2320         };
2321
2322         if ($colinfo->{$_}{is_rel} ||= (
2323           $rel_info->{$_}
2324             and
2325           (
2326             ref $data->[$i]{$_} eq 'ARRAY'
2327               or
2328             ref $data->[$i]{$_} eq 'HASH'
2329               or
2330             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2331           )
2332             and
2333           1
2334         )) {
2335
2336           # moar sanity check... sigh
2337           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2338             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2339               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2340               return my $throwaway = $self->populate(@_);
2341             }
2342           }
2343
2344           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2345         }
2346       }
2347
2348       if ($current_slice_seen_rel_infos) {
2349         push @$slices_with_rels, $data->[$i];
2350
2351         # this is needed further down to decide whether or not to fallback to create()
2352         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2353           for keys %{$data->[$i]};
2354       }
2355     }
2356     else {
2357       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2358     }
2359
2360     if ( grep
2361       { $_->{attrs}{is_depends_on} }
2362       @{ $current_slice_seen_rel_infos || [] }
2363     ) {
2364       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2365       return my $throwaway = $self->populate(@_);
2366     }
2367   }
2368
2369   if( $slices_with_rels ) {
2370
2371     # need to exclude the rel "columns"
2372     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2373
2374     # extra sanity check - ensure the main source is in fact identifiable
2375     # the localizing of nullability is insane, but oh well... the use-case is legit
2376     my $ci = $rsrc->columns_info($colnames);
2377
2378     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2379       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2380
2381     unless( $rsrc->_identifying_column_set($ci) ) {
2382       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2383       return my $throwaway = $self->populate(@_);
2384     }
2385   }
2386
2387 ### inherit the data locked in the conditions of the resultset
2388   my ($rs_data) = $self->_merge_with_rscond({});
2389   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2390
2391   # if anything left - decompose rs_data
2392   my $rs_data_vals;
2393   if (keys %$rs_data) {
2394      push @$rs_data_vals, $rs_data->{$_}
2395       for sort keys %$rs_data;
2396   }
2397
2398 ### start work
2399   my $guard;
2400   $guard = $rsrc->schema->storage->txn_scope_guard
2401     if $slices_with_rels;
2402
2403 ### main source data
2404   # FIXME - need to switch entirely to a coderef-based thing,
2405   # so that large sets aren't copied several times... I think
2406   $rsrc->storage->_insert_bulk(
2407     $rsrc,
2408     [ @$colnames, sort keys %$rs_data ],
2409     [ map {
2410       ref $data->[$_] eq 'ARRAY'
2411       ? (
2412           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2413         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2414         :                     $data->[$_]
2415       )
2416       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2417     } $data_start .. $#$data ],
2418   );
2419
2420 ### do the children relationships
2421   if ( $slices_with_rels ) {
2422     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2423       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2424
2425     for my $sl (@$slices_with_rels) {
2426
2427       my ($main_proto, $main_proto_rs);
2428       for my $rel (@rels) {
2429         next unless defined $sl->{$rel};
2430
2431         $main_proto ||= {
2432           %$rs_data,
2433           (map { $_ => $sl->{$_} } @$colnames),
2434         };
2435
2436         unless (defined $colinfo->{$rel}{rs}) {
2437
2438           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2439
2440           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2441             rel_name => $rel,
2442             self_alias => "\xFE", # irrelevant
2443             foreign_alias => "\xFF", # irrelevant
2444           )->{identity_map} || {} } };
2445
2446         }
2447
2448         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2449           {
2450             $_ => { '=' =>
2451               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2452                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2453                  ->as_query
2454             }
2455           }
2456           keys %{$colinfo->{$rel}{fk_map}}
2457         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2458
2459         1;
2460       }
2461     }
2462   }
2463
2464   $guard->commit if $guard;
2465 }
2466
2467 =head2 pager
2468
2469 =over 4
2470
2471 =item Arguments: none
2472
2473 =item Return Value: L<$pager|Data::Page>
2474
2475 =back
2476
2477 Returns a L<Data::Page> object for the current resultset. Only makes
2478 sense for queries with a C<page> attribute.
2479
2480 To get the full count of entries for a paged resultset, call
2481 C<total_entries> on the L<Data::Page> object.
2482
2483 =cut
2484
2485 sub pager {
2486   my ($self) = @_;
2487
2488   return $self->{pager} if $self->{pager};
2489
2490   my $attrs = $self->{attrs};
2491   if (!defined $attrs->{page}) {
2492     $self->throw_exception("Can't create pager for non-paged rs");
2493   }
2494   elsif ($attrs->{page} <= 0) {
2495     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2496   }
2497   $attrs->{rows} ||= 10;
2498
2499   # throw away the paging flags and re-run the count (possibly
2500   # with a subselect) to get the real total count
2501   my $count_attrs = { %$attrs };
2502   delete @{$count_attrs}{qw/rows offset page pager/};
2503
2504   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2505
2506   require DBIx::Class::ResultSet::Pager;
2507   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2508     sub { $total_rs->count },  #lazy-get the total
2509     $attrs->{rows},
2510     $self->{attrs}{page},
2511   );
2512 }
2513
2514 =head2 page
2515
2516 =over 4
2517
2518 =item Arguments: $page_number
2519
2520 =item Return Value: L<$resultset|/search>
2521
2522 =back
2523
2524 Returns a resultset for the $page_number page of the resultset on which page
2525 is called, where each page contains a number of rows equal to the 'rows'
2526 attribute set on the resultset (10 by default).
2527
2528 =cut
2529
2530 sub page {
2531   my ($self, $page) = @_;
2532   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2533 }
2534
2535 =head2 new_result
2536
2537 =over 4
2538
2539 =item Arguments: \%col_data
2540
2541 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2542
2543 =back
2544
2545 Creates a new result object in the resultset's result class and returns
2546 it. The row is not inserted into the database at this point, call
2547 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2548 will tell you whether the result object has been inserted or not.
2549
2550 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2551
2552 =cut
2553
2554 sub new_result {
2555   my ($self, $values) = @_;
2556
2557   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2558     if @_ > 2;
2559
2560   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2561     unless (ref $values eq 'HASH');
2562
2563   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2564
2565   my $new = $self->result_class->new({
2566     %$merged_cond,
2567     ( @$cols_from_relations
2568       ? (-cols_from_relations => $cols_from_relations)
2569       : ()
2570     ),
2571     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2572   });
2573
2574   if (
2575     reftype($new) eq 'HASH'
2576       and
2577     ! keys %$new
2578       and
2579     blessed($new)
2580   ) {
2581     carp_unique (sprintf (
2582       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2583       $self->result_class,
2584     ));
2585   }
2586
2587   $new;
2588 }
2589
2590 # _merge_with_rscond
2591 #
2592 # Takes a simple hash of K/V data and returns its copy merged with the
2593 # condition already present on the resultset. Additionally returns an
2594 # arrayref of value/condition names, which were inferred from related
2595 # objects (this is needed for in-memory related objects)
2596 sub _merge_with_rscond {
2597   my ($self, $data) = @_;
2598
2599   my ($implied_data, @cols_from_relations);
2600
2601   my $alias = $self->{attrs}{alias};
2602
2603   if (! defined $self->{cond}) {
2604     # just massage $data below
2605   }
2606   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2607     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2608     @cols_from_relations = keys %{ $implied_data || {} };
2609   }
2610   else {
2611     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2612     $implied_data = { map {
2613       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2614     } keys %$eqs };
2615   }
2616
2617   return (
2618     { map
2619       { %{ $self->_remove_alias($_, $alias) } }
2620       # precedence must be given to passed values over values inherited from
2621       # the cond, so the order here is important.
2622       ( $implied_data||(), $data)
2623     },
2624     \@cols_from_relations
2625   );
2626 }
2627
2628 # _has_resolved_attr
2629 #
2630 # determines if the resultset defines at least one
2631 # of the attributes supplied
2632 #
2633 # used to determine if a subquery is necessary
2634 #
2635 # supports some virtual attributes:
2636 #   -join
2637 #     This will scan for any joins being present on the resultset.
2638 #     It is not a mere key-search but a deep inspection of {from}
2639 #
2640
2641 sub _has_resolved_attr {
2642   my ($self, @attr_names) = @_;
2643
2644   my $attrs = $self->_resolved_attrs;
2645
2646   my %extra_checks;
2647
2648   for my $n (@attr_names) {
2649     if (grep { $n eq $_ } (qw/-join/) ) {
2650       $extra_checks{$n}++;
2651       next;
2652     }
2653
2654     my $attr =  $attrs->{$n};
2655
2656     next if not defined $attr;
2657
2658     if (ref $attr eq 'HASH') {
2659       return 1 if keys %$attr;
2660     }
2661     elsif (ref $attr eq 'ARRAY') {
2662       return 1 if @$attr;
2663     }
2664     else {
2665       return 1 if $attr;
2666     }
2667   }
2668
2669   # a resolved join is expressed as a multi-level from
2670   return 1 if (
2671     $extra_checks{-join}
2672       and
2673     ref $attrs->{from} eq 'ARRAY'
2674       and
2675     @{$attrs->{from}} > 1
2676   );
2677
2678   return 0;
2679 }
2680
2681 # _remove_alias
2682 #
2683 # Remove the specified alias from the specified query hash. A copy is made so
2684 # the original query is not modified.
2685
2686 sub _remove_alias {
2687   my ($self, $query, $alias) = @_;
2688
2689   my %orig = %{ $query || {} };
2690   my %unaliased;
2691
2692   foreach my $key (keys %orig) {
2693     if ($key !~ /\./) {
2694       $unaliased{$key} = $orig{$key};
2695       next;
2696     }
2697     $unaliased{$1} = $orig{$key}
2698       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2699   }
2700
2701   return \%unaliased;
2702 }
2703
2704 =head2 as_query
2705
2706 =over 4
2707
2708 =item Arguments: none
2709
2710 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2711
2712 =back
2713
2714 Returns the SQL query and bind vars associated with the invocant.
2715
2716 This is generally used as the RHS for a subquery.
2717
2718 =cut
2719
2720 sub as_query {
2721   my $self = shift;
2722
2723   my $attrs = { %{ $self->_resolved_attrs } };
2724
2725   my $aq = $self->result_source->storage->_select_args_to_query (
2726     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2727   );
2728
2729   $aq;
2730 }
2731
2732 =head2 find_or_new
2733
2734 =over 4
2735
2736 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2737
2738 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2739
2740 =back
2741
2742   my $artist = $schema->resultset('Artist')->find_or_new(
2743     { artist => 'fred' }, { key => 'artists' });
2744
2745   $cd->cd_to_producer->find_or_new({ producer => $producer },
2746                                    { key => 'primary' });
2747
2748 Find an existing record from this resultset using L</find>. if none exists,
2749 instantiate a new result object and return it. The object will not be saved
2750 into your storage until you call L<DBIx::Class::Row/insert> on it.
2751
2752 You most likely want this method when looking for existing rows using a unique
2753 constraint that is not the primary key, or looking for related rows.
2754
2755 If you want objects to be saved immediately, use L</find_or_create> instead.
2756
2757 B<Note>: Make sure to read the documentation of L</find> and understand the
2758 significance of the C<key> attribute, as its lack may skew your search, and
2759 subsequently result in spurious new objects.
2760
2761 B<Note>: Take care when using C<find_or_new> with a table having
2762 columns with default values that you intend to be automatically
2763 supplied by the database (e.g. an auto_increment primary key column).
2764 In normal usage, the value of such columns should NOT be included at
2765 all in the call to C<find_or_new>, even when set to C<undef>.
2766
2767 =cut
2768
2769 sub find_or_new {
2770   my $self     = shift;
2771   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2772   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2773   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2774     return $row;
2775   }
2776   return $self->new_result($hash);
2777 }
2778
2779 =head2 create
2780
2781 =over 4
2782
2783 =item Arguments: \%col_data
2784
2785 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2786
2787 =back
2788
2789 Attempt to create a single new row or a row with multiple related rows
2790 in the table represented by the resultset (and related tables). This
2791 will not check for duplicate rows before inserting, use
2792 L</find_or_create> to do that.
2793
2794 To create one row for this resultset, pass a hashref of key/value
2795 pairs representing the columns of the table and the values you wish to
2796 store. If the appropriate relationships are set up, foreign key fields
2797 can also be passed an object representing the foreign row, and the
2798 value will be set to its primary key.
2799
2800 To create related objects, pass a hashref of related-object column values
2801 B<keyed on the relationship name>. If the relationship is of type C<multi>
2802 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2803 The process will correctly identify columns holding foreign keys, and will
2804 transparently populate them from the keys of the corresponding relation.
2805 This can be applied recursively, and will work correctly for a structure
2806 with an arbitrary depth and width, as long as the relationships actually
2807 exists and the correct column data has been supplied.
2808
2809 Instead of hashrefs of plain related data (key/value pairs), you may
2810 also pass new or inserted objects. New objects (not inserted yet, see
2811 L</new_result>), will be inserted into their appropriate tables.
2812
2813 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2814
2815 Example of creating a new row.
2816
2817   $person_rs->create({
2818     name=>"Some Person",
2819     email=>"somebody@someplace.com"
2820   });
2821
2822 Example of creating a new row and also creating rows in a related C<has_many>
2823 or C<has_one> resultset.  Note Arrayref.
2824
2825   $artist_rs->create(
2826      { artistid => 4, name => 'Manufactured Crap', cds => [
2827         { title => 'My First CD', year => 2006 },
2828         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2829       ],
2830      },
2831   );
2832
2833 Example of creating a new row and also creating a row in a related
2834 C<belongs_to> resultset. Note Hashref.
2835
2836   $cd_rs->create({
2837     title=>"Music for Silly Walks",
2838     year=>2000,
2839     artist => {
2840       name=>"Silly Musician",
2841     }
2842   });
2843
2844 =over
2845
2846 =item WARNING
2847
2848 When subclassing ResultSet never attempt to override this method. Since
2849 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2850 lot of the internals simply never call it, so your override will be
2851 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2852 or L<DBIx::Class::Row/insert> depending on how early in the
2853 L</create> process you need to intervene. See also warning pertaining to
2854 L</new>.
2855
2856 =back
2857
2858 =cut
2859
2860 sub create {
2861   #my ($self, $col_data) = @_;
2862   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2863   return shift->new_result(shift)->insert;
2864 }
2865
2866 =head2 find_or_create
2867
2868 =over 4
2869
2870 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2871
2872 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2873
2874 =back
2875
2876   $cd->cd_to_producer->find_or_create({ producer => $producer },
2877                                       { key => 'primary' });
2878
2879 Tries to find a record based on its primary key or unique constraints; if none
2880 is found, creates one and returns that instead.
2881
2882   my $cd = $schema->resultset('CD')->find_or_create({
2883     cdid   => 5,
2884     artist => 'Massive Attack',
2885     title  => 'Mezzanine',
2886     year   => 2005,
2887   });
2888
2889 Also takes an optional C<key> attribute, to search by a specific key or unique
2890 constraint. For example:
2891
2892   my $cd = $schema->resultset('CD')->find_or_create(
2893     {
2894       artist => 'Massive Attack',
2895       title  => 'Mezzanine',
2896     },
2897     { key => 'cd_artist_title' }
2898   );
2899
2900 B<Note>: Make sure to read the documentation of L</find> and understand the
2901 significance of the C<key> attribute, as its lack may skew your search, and
2902 subsequently result in spurious row creation.
2903
2904 B<Note>: Because find_or_create() reads from the database and then
2905 possibly inserts based on the result, this method is subject to a race
2906 condition. Another process could create a record in the table after
2907 the find has completed and before the create has started. To avoid
2908 this problem, use find_or_create() inside a transaction.
2909
2910 B<Note>: Take care when using C<find_or_create> with a table having
2911 columns with default values that you intend to be automatically
2912 supplied by the database (e.g. an auto_increment primary key column).
2913 In normal usage, the value of such columns should NOT be included at
2914 all in the call to C<find_or_create>, even when set to C<undef>.
2915
2916 See also L</find> and L</update_or_create>. For information on how to declare
2917 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2918
2919 If you need to know if an existing row was found or a new one created use
2920 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2921 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2922 database!
2923
2924   my $cd = $schema->resultset('CD')->find_or_new({
2925     cdid   => 5,
2926     artist => 'Massive Attack',
2927     title  => 'Mezzanine',
2928     year   => 2005,
2929   });
2930
2931   if( !$cd->in_storage ) {
2932       # do some stuff
2933       $cd->insert;
2934   }
2935
2936 =cut
2937
2938 sub find_or_create {
2939   my $self     = shift;
2940   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2941   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2942   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2943     return $row;
2944   }
2945   return $self->new_result($hash)->insert;
2946 }
2947
2948 =head2 update_or_create
2949
2950 =over 4
2951
2952 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2953
2954 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2955
2956 =back
2957
2958   $resultset->update_or_create({ col => $val, ... });
2959
2960 Like L</find_or_create>, but if a row is found it is immediately updated via
2961 C<< $found_row->update (\%col_data) >>.
2962
2963
2964 Takes an optional C<key> attribute to search on a specific unique constraint.
2965 For example:
2966
2967   # In your application
2968   my $cd = $schema->resultset('CD')->update_or_create(
2969     {
2970       artist => 'Massive Attack',
2971       title  => 'Mezzanine',
2972       year   => 1998,
2973     },
2974     { key => 'cd_artist_title' }
2975   );
2976
2977   $cd->cd_to_producer->update_or_create({
2978     producer => $producer,
2979     name => 'harry',
2980   }, {
2981     key => 'primary',
2982   });
2983
2984 B<Note>: Make sure to read the documentation of L</find> and understand the
2985 significance of the C<key> attribute, as its lack may skew your search, and
2986 subsequently result in spurious row creation.
2987
2988 B<Note>: Take care when using C<update_or_create> with a table having
2989 columns with default values that you intend to be automatically
2990 supplied by the database (e.g. an auto_increment primary key column).
2991 In normal usage, the value of such columns should NOT be included at
2992 all in the call to C<update_or_create>, even when set to C<undef>.
2993
2994 See also L</find> and L</find_or_create>. For information on how to declare
2995 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2996
2997 If you need to know if an existing row was updated or a new one created use
2998 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2999 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3000 database!
3001
3002 =cut
3003
3004 sub update_or_create {
3005   my $self = shift;
3006   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3007   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3008
3009   my $row = $self->find($cond, $attrs);
3010   if (defined $row) {
3011     $row->update($cond);
3012     return $row;
3013   }
3014
3015   return $self->new_result($cond)->insert;
3016 }
3017
3018 =head2 update_or_new
3019
3020 =over 4
3021
3022 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3023
3024 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3025
3026 =back
3027
3028   $resultset->update_or_new({ col => $val, ... });
3029
3030 Like L</find_or_new> but if a row is found it is immediately updated via
3031 C<< $found_row->update (\%col_data) >>.
3032
3033 For example:
3034
3035   # In your application
3036   my $cd = $schema->resultset('CD')->update_or_new(
3037     {
3038       artist => 'Massive Attack',
3039       title  => 'Mezzanine',
3040       year   => 1998,
3041     },
3042     { key => 'cd_artist_title' }
3043   );
3044
3045   if ($cd->in_storage) {
3046       # the cd was updated
3047   }
3048   else {
3049       # the cd is not yet in the database, let's insert it
3050       $cd->insert;
3051   }
3052
3053 B<Note>: Make sure to read the documentation of L</find> and understand the
3054 significance of the C<key> attribute, as its lack may skew your search, and
3055 subsequently result in spurious new objects.
3056
3057 B<Note>: Take care when using C<update_or_new> with a table having
3058 columns with default values that you intend to be automatically
3059 supplied by the database (e.g. an auto_increment primary key column).
3060 In normal usage, the value of such columns should NOT be included at
3061 all in the call to C<update_or_new>, even when set to C<undef>.
3062
3063 See also L</find>, L</find_or_create> and L</find_or_new>.
3064
3065 =cut
3066
3067 sub update_or_new {
3068     my $self  = shift;
3069     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3070     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3071
3072     my $row = $self->find( $cond, $attrs );
3073     if ( defined $row ) {
3074         $row->update($cond);
3075         return $row;
3076     }
3077
3078     return $self->new_result($cond);
3079 }
3080
3081 =head2 get_cache
3082
3083 =over 4
3084
3085 =item Arguments: none
3086
3087 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3088
3089 =back
3090
3091 Gets the contents of the cache for the resultset, if the cache is set.
3092
3093 The cache is populated either by using the L</prefetch> attribute to
3094 L</search> or by calling L</set_cache>.
3095
3096 =cut
3097
3098 sub get_cache {
3099   shift->{all_cache};
3100 }
3101
3102 =head2 set_cache
3103
3104 =over 4
3105
3106 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3107
3108 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3109
3110 =back
3111
3112 Sets the contents of the cache for the resultset. Expects an arrayref
3113 of objects of the same class as those produced by the resultset. Note that
3114 if the cache is set, the resultset will return the cached objects rather
3115 than re-querying the database even if the cache attr is not set.
3116
3117 The contents of the cache can also be populated by using the
3118 L</prefetch> attribute to L</search>.
3119
3120 =cut
3121
3122 sub set_cache {
3123   my ( $self, $data ) = @_;
3124   $self->throw_exception("set_cache requires an arrayref")
3125       if defined($data) && (ref $data ne 'ARRAY');
3126   $self->{all_cache} = $data;
3127 }
3128
3129 =head2 clear_cache
3130
3131 =over 4
3132
3133 =item Arguments: none
3134
3135 =item Return Value: undef
3136
3137 =back
3138
3139 Clears the cache for the resultset.
3140
3141 =cut
3142
3143 sub clear_cache {
3144   shift->set_cache(undef);
3145 }
3146
3147 =head2 is_paged
3148
3149 =over 4
3150
3151 =item Arguments: none
3152
3153 =item Return Value: true, if the resultset has been paginated
3154
3155 =back
3156
3157 =cut
3158
3159 sub is_paged {
3160   my ($self) = @_;
3161   return !!$self->{attrs}{page};
3162 }
3163
3164 =head2 is_ordered
3165
3166 =over 4
3167
3168 =item Arguments: none
3169
3170 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3171
3172 =back
3173
3174 =cut
3175
3176 sub is_ordered {
3177   my ($self) = @_;
3178   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3179 }
3180
3181 =head2 related_resultset
3182
3183 =over 4
3184
3185 =item Arguments: $rel_name
3186
3187 =item Return Value: L<$resultset|/search>
3188
3189 =back
3190
3191 Returns a related resultset for the supplied relationship name.
3192
3193   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3194
3195 =cut
3196
3197 sub related_resultset {
3198   $_[0]->throw_exception(
3199     'Extra arguments to $rs->related_resultset() were always quietly '
3200   . 'discarded without consideration, you need to switch to '
3201   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3202   ) if @_ > 2;
3203
3204   return $_[0]->{related_resultsets}{$_[1]}
3205     if defined $_[0]->{related_resultsets}{$_[1]};
3206
3207   my ($self, $rel) = @_;
3208
3209   return $self->{related_resultsets}{$rel} = do {
3210     my $rsrc = $self->result_source;
3211     my $rel_info = $rsrc->relationship_info($rel);
3212
3213     $self->throw_exception(
3214       "search_related: result source '" . $rsrc->source_name .
3215         "' has no such relationship $rel")
3216       unless $rel_info;
3217
3218     my $attrs = $self->_chain_relationship($rel);
3219
3220     my $storage = $rsrc->schema->storage;
3221
3222     # Previously this atribute was deleted (instead of being set as it is now)
3223     # Doing so seems to be harmless in all available test permutations
3224     # See also 01d59a6a6 and mst's comment below
3225     #
3226     $attrs->{alias} = $storage->relname_to_table_alias(
3227       $rel,
3228       $attrs->{seen_join}{$rel}
3229     );
3230
3231     # since this is search_related, and we already slid the select window inwards
3232     # (the select/as attrs were deleted in the beginning), we need to flip all
3233     # left joins to inner, so we get the expected results
3234     # read the comment on top of the actual function to see what this does
3235     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3236
3237     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3238     delete $attrs->{result_class};
3239
3240     my $new = do {
3241
3242       # The reason we do this now instead of passing the alias to the
3243       # search_rs below is that if you wrap/overload resultset on the
3244       # source you need to know what alias it's -going- to have for things
3245       # to work sanely (e.g. RestrictWithObject wants to be able to add
3246       # extra query restrictions, and these may need to be $alias.)
3247       #                                       -- mst ~ 2007 (01d59a6a6)
3248       #
3249       # FIXME - this seems to be no longer neccessary (perhaps due to the
3250       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3251       # dependent (as of Jun 2015 ) does not yield any difference with or
3252       # without this line. Nevertheless keep it as is for now, to minimize
3253       # churn, there is enough potential for breakage in 0.0829xx as it is
3254       #                                       -- ribasushi Jun 2015
3255       #
3256       my $rel_source = $rsrc->related_source($rel);
3257       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3258
3259       $rel_source->resultset->search_rs( undef, $attrs );
3260     };
3261
3262     if (my $cache = $self->get_cache) {
3263       my @related_cache = map
3264         { $_->related_resultset($rel)->get_cache || () }
3265         @$cache
3266       ;
3267
3268       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3269     }
3270
3271     $new;
3272   };
3273 }
3274
3275 =head2 current_source_alias
3276
3277 =over 4
3278
3279 =item Arguments: none
3280
3281 =item Return Value: $source_alias
3282
3283 =back
3284
3285 Returns the current table alias for the result source this resultset is built
3286 on, that will be used in the SQL query. Usually it is C<me>.
3287
3288 Currently the source alias that refers to the result set returned by a
3289 L</search>/L</find> family method depends on how you got to the resultset: it's
3290 C<me> by default, but eg. L</search_related> aliases it to the related result
3291 source name (and keeps C<me> referring to the original result set). The long
3292 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3293 (and make this method unnecessary).
3294
3295 Thus it's currently necessary to use this method in predefined queries (see
3296 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3297 source alias of the current result set:
3298
3299   # in a result set class
3300   sub modified_by {
3301     my ($self, $user) = @_;
3302
3303     my $me = $self->current_source_alias;
3304
3305     return $self->search({
3306       "$me.modified" => $user->id,
3307     });
3308   }
3309
3310 The alias of L<newly created resultsets|/search> can be altered by the
3311 L<alias attribute|/alias>.
3312
3313 =cut
3314
3315 sub current_source_alias {
3316   return (shift->{attrs} || {})->{alias} || 'me';
3317 }
3318
3319 =head2 as_subselect_rs
3320
3321 =over 4
3322
3323 =item Arguments: none
3324
3325 =item Return Value: L<$resultset|/search>
3326
3327 =back
3328
3329 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3330 "virtual view" by including it as a subquery within the from clause.  From this
3331 point on, any joined tables are inaccessible to ->search on the resultset (as if
3332 it were simply where-filtered without joins).  For example:
3333
3334  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3335
3336  # 'x' now pollutes the query namespace
3337
3338  # So the following works as expected
3339  my $ok_rs = $rs->search({'x.other' => 1});
3340
3341  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3342  # def) we look for one row with contradictory terms and join in another table
3343  # (aliased 'x_2') which we never use
3344  my $broken_rs = $rs->search({'x.name' => 'def'});
3345
3346  my $rs2 = $rs->as_subselect_rs;
3347
3348  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3349  my $not_joined_rs = $rs2->search({'x.other' => 1});
3350
3351  # works as expected: finds a 'table' row related to two x rows (abc and def)
3352  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3353
3354 Another example of when one might use this would be to select a subset of
3355 columns in a group by clause:
3356
3357  my $rs = $schema->resultset('Bar')->search(undef, {
3358    group_by => [qw{ id foo_id baz_id }],
3359  })->as_subselect_rs->search(undef, {
3360    columns => [qw{ id foo_id }]
3361  });
3362
3363 In the above example normally columns would have to be equal to the group by,
3364 but because we isolated the group by into a subselect the above works.
3365
3366 =cut
3367
3368 sub as_subselect_rs {
3369   my $self = shift;
3370
3371   my $attrs = $self->_resolved_attrs;
3372
3373   my $fresh_rs = (ref $self)->new (
3374     $self->result_source
3375   );
3376
3377   # these pieces will be locked in the subquery
3378   delete $fresh_rs->{cond};
3379   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3380
3381   return $fresh_rs->search( {}, {
3382     from => [{
3383       $attrs->{alias} => $self->as_query,
3384       -alias  => $attrs->{alias},
3385       -rsrc   => $self->result_source,
3386     }],
3387     alias => $attrs->{alias},
3388   });
3389 }
3390
3391 # This code is called by search_related, and makes sure there
3392 # is clear separation between the joins before, during, and
3393 # after the relationship. This information is needed later
3394 # in order to properly resolve prefetch aliases (any alias
3395 # with a relation_chain_depth less than the depth of the
3396 # current prefetch is not considered)
3397 #
3398 # The increments happen twice per join. An even number means a
3399 # relationship specified via a search_related, whereas an odd
3400 # number indicates a join/prefetch added via attributes
3401 #
3402 # Also this code will wrap the current resultset (the one we
3403 # chain to) in a subselect IFF it contains limiting attributes
3404 sub _chain_relationship {
3405   my ($self, $rel) = @_;
3406   my $source = $self->result_source;
3407   my $attrs = { %{$self->{attrs}||{}} };
3408
3409   # we need to take the prefetch the attrs into account before we
3410   # ->_resolve_join as otherwise they get lost - captainL
3411   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3412
3413   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3414
3415   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3416
3417   my $from;
3418   my @force_subq_attrs = qw/offset rows group_by having/;
3419
3420   if (
3421     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3422       ||
3423     $self->_has_resolved_attr (@force_subq_attrs)
3424   ) {
3425     # Nuke the prefetch (if any) before the new $rs attrs
3426     # are resolved (prefetch is useless - we are wrapping
3427     # a subquery anyway).
3428     my $rs_copy = $self->search;
3429     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3430       $rs_copy->{attrs}{join},
3431       delete $rs_copy->{attrs}{prefetch},
3432     );
3433
3434     $from = [{
3435       -rsrc   => $source,
3436       -alias  => $attrs->{alias},
3437       $attrs->{alias} => $rs_copy->as_query,
3438     }];
3439     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3440     $seen->{-relation_chain_depth} = 0;
3441   }
3442   elsif ($attrs->{from}) {  #shallow copy suffices
3443     $from = [ @{$attrs->{from}} ];
3444   }
3445   else {
3446     $from = [{
3447       -rsrc  => $source,
3448       -alias => $attrs->{alias},
3449       $attrs->{alias} => $source->from,
3450     }];
3451   }
3452
3453   my $jpath = ($seen->{-relation_chain_depth})
3454     ? $from->[-1][0]{-join_path}
3455     : [];
3456
3457   my @requested_joins = $source->_resolve_join(
3458     $join,
3459     $attrs->{alias},
3460     $seen,
3461     $jpath,
3462   );
3463
3464   push @$from, @requested_joins;
3465
3466   $seen->{-relation_chain_depth}++;
3467
3468   # if $self already had a join/prefetch specified on it, the requested
3469   # $rel might very well be already included. What we do in this case
3470   # is effectively a no-op (except that we bump up the chain_depth on
3471   # the join in question so we could tell it *is* the search_related)
3472   my $already_joined;
3473
3474   # we consider the last one thus reverse
3475   for my $j (reverse @requested_joins) {
3476     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3477     if ($rel eq $last_j) {
3478       $j->[0]{-relation_chain_depth}++;
3479       $already_joined++;
3480       last;
3481     }
3482   }
3483
3484   unless ($already_joined) {
3485     push @$from, $source->_resolve_join(
3486       $rel,
3487       $attrs->{alias},
3488       $seen,
3489       $jpath,
3490     );
3491   }
3492
3493   $seen->{-relation_chain_depth}++;
3494
3495   return {%$attrs, from => $from, seen_join => $seen};
3496 }
3497
3498 sub _resolved_attrs {
3499   my $self = shift;
3500   return $self->{_attrs} if $self->{_attrs};
3501
3502   my $attrs  = { %{ $self->{attrs} || {} } };
3503   my $source = $attrs->{result_source} = $self->result_source;
3504   my $alias  = $attrs->{alias};
3505
3506   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3507     if $attrs->{collapse} and $attrs->{distinct};
3508
3509
3510   # Sanity check the paging attributes
3511   # SQLMaker does it too, but in case of a software_limit we'll never get there
3512   if (defined $attrs->{offset}) {
3513     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3514       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3515   }
3516   if (defined $attrs->{rows}) {
3517     $self->throw_exception("The rows attribute must be a positive integer if present")
3518       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3519   }
3520
3521
3522   # default selection list
3523   $attrs->{columns} = [ $source->columns ]
3524     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3525
3526   # merge selectors together
3527   for (qw/columns select as/) {
3528     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3529       if $attrs->{$_} or $attrs->{"+$_"};
3530   }
3531
3532   # disassemble columns
3533   my (@sel, @as);
3534   if (my $cols = delete $attrs->{columns}) {
3535     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3536       if (ref $c eq 'HASH') {
3537         for my $as (sort keys %$c) {
3538           push @sel, $c->{$as};
3539           push @as, $as;
3540         }
3541       }
3542       else {
3543         push @sel, $c;
3544         push @as, $c;
3545       }
3546     }
3547   }
3548
3549   # when trying to weed off duplicates later do not go past this point -
3550   # everything added from here on is unbalanced "anyone's guess" stuff
3551   my $dedup_stop_idx = $#as;
3552
3553   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3554     if $attrs->{as};
3555   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3556     if $attrs->{select};
3557
3558   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3559   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3560
3561   # disqualify all $alias.col as-bits (inflate-map mandated)
3562   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3563
3564   # de-duplicate the result (remove *identical* select/as pairs)
3565   # and also die on duplicate {as} pointing to different {select}s
3566   # not using a c-style for as the condition is prone to shrinkage
3567   my $seen;
3568   my $i = 0;
3569   while ($i <= $dedup_stop_idx) {
3570     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3571       splice @sel, $i, 1;
3572       splice @as, $i, 1;
3573       $dedup_stop_idx--;
3574     }
3575     elsif ($seen->{$as[$i]}++) {
3576       $self->throw_exception(
3577         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3578       );
3579     }
3580     else {
3581       $i++;
3582     }
3583   }
3584
3585   $attrs->{select} = \@sel;
3586   $attrs->{as} = \@as;
3587
3588   $attrs->{from} ||= [{
3589     -rsrc   => $source,
3590     -alias  => $self->{attrs}{alias},
3591     $self->{attrs}{alias} => $source->from,
3592   }];
3593
3594   if ( $attrs->{join} || $attrs->{prefetch} ) {
3595
3596     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3597       if ref $attrs->{from} ne 'ARRAY';
3598
3599     my $join = (delete $attrs->{join}) || {};
3600
3601     if ( defined $attrs->{prefetch} ) {
3602       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3603     }
3604
3605     $attrs->{from} =    # have to copy here to avoid corrupting the original
3606       [
3607         @{ $attrs->{from} },
3608         $source->_resolve_join(
3609           $join,
3610           $alias,
3611           { %{ $attrs->{seen_join} || {} } },
3612           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3613             ? $attrs->{from}[-1][0]{-join_path}
3614             : []
3615           ,
3616         )
3617       ];
3618   }
3619
3620
3621   for my $attr (qw(order_by group_by)) {
3622
3623     if ( defined $attrs->{$attr} ) {
3624       $attrs->{$attr} = (
3625         ref( $attrs->{$attr} ) eq 'ARRAY'
3626         ? [ @{ $attrs->{$attr} } ]
3627         : [ $attrs->{$attr} || () ]
3628       );
3629
3630       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3631     }
3632   }
3633
3634
3635   # set collapse default based on presence of prefetch
3636   my $prefetch;
3637   if (
3638     defined $attrs->{prefetch}
3639       and
3640     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3641   ) {
3642     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3643       if defined $attrs->{collapse} and ! $attrs->{collapse};
3644
3645     $attrs->{collapse} = 1;
3646   }
3647
3648
3649   # run through the resulting joinstructure (starting from our current slot)
3650   # and unset collapse if proven unnecessary
3651   #
3652   # also while we are at it find out if the current root source has
3653   # been premultiplied by previous related_source chaining
3654   #
3655   # this allows to predict whether a root object with all other relation
3656   # data set to NULL is in fact unique
3657   if ($attrs->{collapse}) {
3658
3659     if (ref $attrs->{from} eq 'ARRAY') {
3660
3661       if (@{$attrs->{from}} == 1) {
3662         # no joins - no collapse
3663         $attrs->{collapse} = 0;
3664       }
3665       else {
3666         # find where our table-spec starts
3667         my @fromlist = @{$attrs->{from}};
3668         while (@fromlist) {
3669           my $t = shift @fromlist;
3670
3671           my $is_multi;
3672           # me vs join from-spec distinction - a ref means non-root
3673           if (ref $t eq 'ARRAY') {
3674             $t = $t->[0];
3675             $is_multi ||= ! $t->{-is_single};
3676           }
3677           last if ($t->{-alias} && $t->{-alias} eq $alias);
3678           $attrs->{_main_source_premultiplied} ||= $is_multi;
3679         }
3680
3681         # no non-singles remaining, nor any premultiplication - nothing to collapse
3682         if (
3683           ! $attrs->{_main_source_premultiplied}
3684             and
3685           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3686         ) {
3687           $attrs->{collapse} = 0;
3688         }
3689       }
3690     }
3691
3692     else {
3693       # if we can not analyze the from - err on the side of safety
3694       $attrs->{_main_source_premultiplied} = 1;
3695     }
3696   }
3697
3698
3699   # generate the distinct induced group_by before injecting the prefetched select/as parts
3700   if (delete $attrs->{distinct}) {
3701     if ($attrs->{group_by}) {
3702       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3703     }
3704     else {
3705       $attrs->{_grouped_by_distinct} = 1;
3706       # distinct affects only the main selection part, not what prefetch may add below
3707       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3708
3709       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3710       # The thinking is: if we are collapsing the subquerying prefetch engine will
3711       # rip stuff apart for us anyway, and we do not want to have a potentially
3712       # function-converted external order_by
3713       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3714       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3715     }
3716   }
3717
3718
3719   # generate selections based on the prefetch helper
3720   if ($prefetch) {
3721
3722     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3723       if $attrs->{_dark_selector};
3724
3725     # this is a separate structure (we don't look in {from} directly)
3726     # as the resolver needs to shift things off the lists to work
3727     # properly (identical-prefetches on different branches)
3728     my $joined_node_aliases_map = {};
3729     if (ref $attrs->{from} eq 'ARRAY') {
3730
3731       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3732
3733       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3734         next unless $j->[0]{-alias};
3735         next unless $j->[0]{-join_path};
3736         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3737
3738         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3739
3740         my $p = $joined_node_aliases_map;
3741         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3742         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3743       }
3744     }
3745
3746     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3747       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3748   }
3749
3750
3751   $attrs->{_simple_passthrough_construction} = !(
3752     $attrs->{collapse}
3753       or
3754     grep { $_ =~ /\./ } @{$attrs->{as}}
3755   );
3756
3757
3758   # if both page and offset are specified, produce a combined offset
3759   # even though it doesn't make much sense, this is what pre 081xx has
3760   # been doing
3761   if (my $page = delete $attrs->{page}) {
3762     $attrs->{offset} =
3763       ($attrs->{rows} * ($page - 1))
3764             +
3765       ($attrs->{offset} || 0)
3766     ;
3767   }
3768
3769   return $self->{_attrs} = $attrs;
3770 }
3771
3772 sub _rollout_attr {
3773   my ($self, $attr) = @_;
3774
3775   if (ref $attr eq 'HASH') {
3776     return $self->_rollout_hash($attr);
3777   } elsif (ref $attr eq 'ARRAY') {
3778     return $self->_rollout_array($attr);
3779   } else {
3780     return [$attr];
3781   }
3782 }
3783
3784 sub _rollout_array {
3785   my ($self, $attr) = @_;
3786
3787   my @rolled_array;
3788   foreach my $element (@{$attr}) {
3789     if (ref $element eq 'HASH') {
3790       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3791     } elsif (ref $element eq 'ARRAY') {
3792       #  XXX - should probably recurse here
3793       push( @rolled_array, @{$self->_rollout_array($element)} );
3794     } else {
3795       push( @rolled_array, $element );
3796     }
3797   }
3798   return \@rolled_array;
3799 }
3800
3801 sub _rollout_hash {
3802   my ($self, $attr) = @_;
3803
3804   my @rolled_array;
3805   foreach my $key (keys %{$attr}) {
3806     push( @rolled_array, { $key => $attr->{$key} } );
3807   }
3808   return \@rolled_array;
3809 }
3810
3811 sub _calculate_score {
3812   my ($self, $a, $b) = @_;
3813
3814   if (defined $a xor defined $b) {
3815     return 0;
3816   }
3817   elsif (not defined $a) {
3818     return 1;
3819   }
3820
3821   if (ref $b eq 'HASH') {
3822     my ($b_key) = keys %{$b};
3823     $b_key = '' if ! defined $b_key;
3824     if (ref $a eq 'HASH') {
3825       my ($a_key) = keys %{$a};
3826       $a_key = '' if ! defined $a_key;
3827       if ($a_key eq $b_key) {
3828         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3829       } else {
3830         return 0;
3831       }
3832     } else {
3833       return ($a eq $b_key) ? 1 : 0;
3834     }
3835   } else {
3836     if (ref $a eq 'HASH') {
3837       my ($a_key) = keys %{$a};
3838       return ($b eq $a_key) ? 1 : 0;
3839     } else {
3840       return ($b eq $a) ? 1 : 0;
3841     }
3842   }
3843 }
3844
3845 sub _merge_joinpref_attr {
3846   my ($self, $orig, $import) = @_;
3847
3848   return $import unless defined($orig);
3849   return $orig unless defined($import);
3850
3851   $orig = $self->_rollout_attr($orig);
3852   $import = $self->_rollout_attr($import);
3853
3854   my $seen_keys;
3855   foreach my $import_element ( @{$import} ) {
3856     # find best candidate from $orig to merge $b_element into
3857     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3858     foreach my $orig_element ( @{$orig} ) {
3859       my $score = $self->_calculate_score( $orig_element, $import_element );
3860       if ($score > $best_candidate->{score}) {
3861         $best_candidate->{position} = $position;
3862         $best_candidate->{score} = $score;
3863       }
3864       $position++;
3865     }
3866     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3867     $import_key = '' if not defined $import_key;
3868
3869     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3870       push( @{$orig}, $import_element );
3871     } else {
3872       my $orig_best = $orig->[$best_candidate->{position}];
3873       # merge orig_best and b_element together and replace original with merged
3874       if (ref $orig_best ne 'HASH') {
3875         $orig->[$best_candidate->{position}] = $import_element;
3876       } elsif (ref $import_element eq 'HASH') {
3877         my ($key) = keys %{$orig_best};
3878         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3879       }
3880     }
3881     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3882   }
3883
3884   return @$orig ? $orig : ();
3885 }
3886
3887 {
3888   my $hm;
3889
3890   sub _merge_attr {
3891     $hm ||= do {
3892       require Hash::Merge;
3893       my $hm = Hash::Merge->new;
3894
3895       $hm->specify_behavior({
3896         SCALAR => {
3897           SCALAR => sub {
3898             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3899
3900             if ($defl xor $defr) {
3901               return [ $defl ? $_[0] : $_[1] ];
3902             }
3903             elsif (! $defl) {
3904               return [];
3905             }
3906             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3907               return [ $_[0] ];
3908             }
3909             else {
3910               return [$_[0], $_[1]];
3911             }
3912           },
3913           ARRAY => sub {
3914             return $_[1] if !defined $_[0];
3915             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3916             return [$_[0], @{$_[1]}]
3917           },
3918           HASH  => sub {
3919             return [] if !defined $_[0] and !keys %{$_[1]};
3920             return [ $_[1] ] if !defined $_[0];
3921             return [ $_[0] ] if !keys %{$_[1]};
3922             return [$_[0], $_[1]]
3923           },
3924         },
3925         ARRAY => {
3926           SCALAR => sub {
3927             return $_[0] if !defined $_[1];
3928             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3929             return [@{$_[0]}, $_[1]]
3930           },
3931           ARRAY => sub {
3932             my @ret = @{$_[0]} or return $_[1];
3933             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3934             my %idx = map { $_ => 1 } @ret;
3935             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3936             \@ret;
3937           },
3938           HASH => sub {
3939             return [ $_[1] ] if ! @{$_[0]};
3940             return $_[0] if !keys %{$_[1]};
3941             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3942             return [ @{$_[0]}, $_[1] ];
3943           },
3944         },
3945         HASH => {
3946           SCALAR => sub {
3947             return [] if !keys %{$_[0]} and !defined $_[1];
3948             return [ $_[0] ] if !defined $_[1];
3949             return [ $_[1] ] if !keys %{$_[0]};
3950             return [$_[0], $_[1]]
3951           },
3952           ARRAY => sub {
3953             return [] if !keys %{$_[0]} and !@{$_[1]};
3954             return [ $_[0] ] if !@{$_[1]};
3955             return $_[1] if !keys %{$_[0]};
3956             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3957             return [ $_[0], @{$_[1]} ];
3958           },
3959           HASH => sub {
3960             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3961             return [ $_[0] ] if !keys %{$_[1]};
3962             return [ $_[1] ] if !keys %{$_[0]};
3963             return [ $_[0] ] if $_[0] eq $_[1];
3964             return [ $_[0], $_[1] ];
3965           },
3966         }
3967       } => 'DBIC_RS_ATTR_MERGER');
3968       $hm;
3969     };
3970
3971     return $hm->merge ($_[1], $_[2]);
3972   }
3973 }
3974
3975 sub STORABLE_freeze {
3976   my ($self, $cloning) = @_;
3977   my $to_serialize = { %$self };
3978
3979   # A cursor in progress can't be serialized (and would make little sense anyway)
3980   # the parser can be regenerated (and can't be serialized)
3981   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3982
3983   # nor is it sensical to store a not-yet-fired-count pager
3984   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3985     delete $to_serialize->{pager};
3986   }
3987
3988   Storable::nfreeze($to_serialize);
3989 }
3990
3991 # need this hook for symmetry
3992 sub STORABLE_thaw {
3993   my ($self, $cloning, $serialized) = @_;
3994
3995   %$self = %{ Storable::thaw($serialized) };
3996
3997   $self;
3998 }
3999
4000
4001 =head2 throw_exception
4002
4003 See L<DBIx::Class::Schema/throw_exception> for details.
4004
4005 =cut
4006
4007 sub throw_exception {
4008   my $self=shift;
4009
4010   if (ref $self and my $rsrc = $self->result_source) {
4011     $rsrc->throw_exception(@_)
4012   }
4013   else {
4014     DBIx::Class::Exception->throw(@_);
4015   }
4016 }
4017
4018 1;
4019
4020 __END__
4021
4022 # XXX: FIXME: Attributes docs need clearing up
4023
4024 =head1 ATTRIBUTES
4025
4026 Attributes are used to refine a ResultSet in various ways when
4027 searching for data. They can be passed to any method which takes an
4028 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4029 L</count>.
4030
4031 Default attributes can be set on the result class using
4032 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4033 the CAVEATS on that feature before using it!)
4034
4035 These are in no particular order:
4036
4037 =head2 order_by
4038
4039 =over 4
4040
4041 =item Value: ( $order_by | \@order_by | \%order_by )
4042
4043 =back
4044
4045 Which column(s) to order the results by.
4046
4047 [The full list of suitable values is documented in
4048 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4049 common options.]
4050
4051 If a single column name, or an arrayref of names is supplied, the
4052 argument is passed through directly to SQL. The hashref syntax allows
4053 for connection-agnostic specification of ordering direction:
4054
4055  For descending order:
4056
4057   order_by => { -desc => [qw/col1 col2 col3/] }
4058
4059  For explicit ascending order:
4060
4061   order_by => { -asc => 'col' }
4062
4063 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4064 supported, although you are strongly encouraged to use the hashref
4065 syntax as outlined above.
4066
4067 =head2 columns
4068
4069 =over 4
4070
4071 =item Value: \@columns | \%columns | $column
4072
4073 =back
4074
4075 Shortcut to request a particular set of columns to be retrieved. Each
4076 column spec may be a string (a table column name), or a hash (in which
4077 case the key is the C<as> value, and the value is used as the C<select>
4078 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4079 it and sets C<select> from that, then auto-populates C<as> from
4080 C<select> as normal. (You may also use the C<cols> attribute, as in
4081 earlier versions of DBIC, but this is deprecated)
4082
4083 Essentially C<columns> does the same as L</select> and L</as>.
4084
4085     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4086
4087 is the same as
4088
4089     select => [qw(some_column another_column)],
4090     as     => [qw(some_column dbic_slot)]
4091
4092 If you want to individually retrieve related columns (in essence perform
4093 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4094 chain such that it matches existing relationships:
4095
4096     my $rs = $schema->resultset('Artist')->search({}, {
4097         # required to tell DBIC to collapse has_many relationships
4098         collapse => 1,
4099         join     => { cds => 'tracks' },
4100         '+columns'  => {
4101           'cds.cdid'         => 'cds.cdid',
4102           'cds.tracks.title' => 'tracks.title',
4103         },
4104     });
4105
4106 Like elsewhere, literal SQL or literal values can be included by using a
4107 scalar reference or a literal bind value, and these values will be available
4108 in the result with C<get_column> (see also
4109 L<SQL::Abstract/Literal SQL and value type operators>):
4110
4111     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4112     # bind values: $true_value, $false_value
4113     columns => [
4114         {
4115             foo => \1,
4116             bar => \q{'a string'},
4117             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4118         }
4119     ]
4120
4121 =head2 +columns
4122
4123 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4124 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4125 with a unary plus operator before it, which is the same as simply C<columns>.
4126
4127 =over 4
4128
4129 =item Value: \@extra_columns
4130
4131 =back
4132
4133 Indicates additional columns to be selected from storage. Works the same as
4134 L</columns> but adds columns to the current selection. (You may also use the
4135 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4136 deprecated)
4137
4138   $schema->resultset('CD')->search(undef, {
4139     '+columns' => ['artist.name'],
4140     join => ['artist']
4141   });
4142
4143 would return all CDs and include a 'name' column to the information
4144 passed to object inflation. Note that the 'artist' is the name of the
4145 column (or relationship) accessor, and 'name' is the name of the column
4146 accessor in the related table.
4147
4148 =head2 select
4149
4150 =over 4
4151
4152 =item Value: \@select_columns
4153
4154 =back
4155
4156 Indicates which columns should be selected from the storage. You can use
4157 column names, or in the case of RDBMS back ends, function or stored procedure
4158 names:
4159
4160   $rs = $schema->resultset('Employee')->search(undef, {
4161     select => [
4162       'name',
4163       { count => 'employeeid' },
4164       { max => { length => 'name' }, -as => 'longest_name' }
4165     ]
4166   });
4167
4168   # Equivalent SQL
4169   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4170
4171 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4172 use L</select>, to instruct DBIx::Class how to store the result of the column.
4173
4174 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4175 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4176 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4177 function attribute> supplied as shown in the example above.
4178
4179 =head2 +select
4180
4181 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4182 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4183 with a unary plus operator before it, which is the same as simply C<select>.
4184
4185 =over 4
4186
4187 =item Value: \@extra_select_columns
4188
4189 =back
4190
4191 Indicates additional columns to be selected from storage.  Works the same as
4192 L</select> but adds columns to the current selection, instead of specifying
4193 a new explicit list.
4194
4195 =head2 as
4196
4197 =over 4
4198
4199 =item Value: \@inflation_names
4200
4201 =back
4202
4203 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4204 slot name in which the column value will be stored within the
4205 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4206 identifier by the C<get_column> method (or via the object accessor B<if one
4207 with the same name already exists>) as shown below.
4208
4209 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4210 aliasing C<AS>. See L</select> for details.
4211
4212   $rs = $schema->resultset('Employee')->search(undef, {
4213     select => [
4214       'name',
4215       { count => 'employeeid' },
4216       { max => { length => 'name' }, -as => 'longest_name' }
4217     ],
4218     as => [qw/
4219       name
4220       employee_count
4221       max_name_length
4222     /],
4223   });
4224
4225 If the object against which the search is performed already has an accessor
4226 matching a column name specified in C<as>, the value can be retrieved using
4227 the accessor as normal:
4228
4229   my $name = $employee->name();
4230
4231 If on the other hand an accessor does not exist in the object, you need to
4232 use C<get_column> instead:
4233
4234   my $employee_count = $employee->get_column('employee_count');
4235
4236 You can create your own accessors if required - see
4237 L<DBIx::Class::Manual::Cookbook> for details.
4238
4239 =head2 +as
4240
4241 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4242 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4243 with a unary plus operator before it, which is the same as simply C<as>.
4244
4245 =over 4
4246
4247 =item Value: \@extra_inflation_names
4248
4249 =back
4250
4251 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4252
4253 =head2 join
4254
4255 =over 4
4256
4257 =item Value: ($rel_name | \@rel_names | \%rel_names)
4258
4259 =back
4260
4261 Contains a list of relationships that should be joined for this query.  For
4262 example:
4263
4264   # Get CDs by Nine Inch Nails
4265   my $rs = $schema->resultset('CD')->search(
4266     { 'artist.name' => 'Nine Inch Nails' },
4267     { join => 'artist' }
4268   );
4269
4270 Can also contain a hash reference to refer to the other relation's relations.
4271 For example:
4272
4273   package MyApp::Schema::Track;
4274   use base qw/DBIx::Class/;
4275   __PACKAGE__->table('track');
4276   __PACKAGE__->add_columns(qw/trackid cd position title/);
4277   __PACKAGE__->set_primary_key('trackid');
4278   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4279   1;
4280
4281   # In your application
4282   my $rs = $schema->resultset('Artist')->search(
4283     { 'track.title' => 'Teardrop' },
4284     {
4285       join     => { cd => 'track' },
4286       order_by => 'artist.name',
4287     }
4288   );
4289
4290 You need to use the relationship (not the table) name in  conditions,
4291 because they are aliased as such. The current table is aliased as "me", so
4292 you need to use me.column_name in order to avoid ambiguity. For example:
4293
4294   # Get CDs from 1984 with a 'Foo' track
4295   my $rs = $schema->resultset('CD')->search(
4296     {
4297       'me.year' => 1984,
4298       'tracks.name' => 'Foo'
4299     },
4300     { join => 'tracks' }
4301   );
4302
4303 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4304 similarly for a third time). For e.g.
4305
4306   my $rs = $schema->resultset('Artist')->search({
4307     'cds.title'   => 'Down to Earth',
4308     'cds_2.title' => 'Popular',
4309   }, {
4310     join => [ qw/cds cds/ ],
4311   });
4312
4313 will return a set of all artists that have both a cd with title 'Down
4314 to Earth' and a cd with title 'Popular'.
4315
4316 If you want to fetch related objects from other tables as well, see L</prefetch>
4317 below.
4318
4319  NOTE: An internal join-chain pruner will discard certain joins while
4320  constructing the actual SQL query, as long as the joins in question do not
4321  affect the retrieved result. This for example includes 1:1 left joins
4322  that are not part of the restriction specification (WHERE/HAVING) nor are
4323  a part of the query selection.
4324
4325 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4326
4327 =head2 collapse
4328
4329 =over 4
4330
4331 =item Value: (0 | 1)
4332
4333 =back
4334
4335 When set to a true value, indicates that any rows fetched from joined has_many
4336 relationships are to be aggregated into the corresponding "parent" object. For
4337 example, the resultset:
4338
4339   my $rs = $schema->resultset('CD')->search({}, {
4340     '+columns' => [ qw/ tracks.title tracks.position / ],
4341     join => 'tracks',
4342     collapse => 1,
4343   });
4344
4345 While executing the following query:
4346
4347   SELECT me.*, tracks.title, tracks.position
4348     FROM cd me
4349     LEFT JOIN track tracks
4350       ON tracks.cdid = me.cdid
4351
4352 Will return only as many objects as there are rows in the CD source, even
4353 though the result of the query may span many rows. Each of these CD objects
4354 will in turn have multiple "Track" objects hidden behind the has_many
4355 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4356 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4357 product"), with each CD object containing exactly one of all fetched Track data.
4358
4359 When a collapse is requested on a non-ordered resultset, an order by some
4360 unique part of the main source (the left-most table) is inserted automatically.
4361 This is done so that the resultset is allowed to be "lazy" - calling
4362 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4363 object with all of its related data.
4364
4365 If an L</order_by> is already declared, and orders the resultset in a way that
4366 makes collapsing as described above impossible (e.g. C<< ORDER BY
4367 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4368 switch to "eager" mode and slurp the entire resultset before constructing the
4369 first object returned by L</next>.
4370
4371 Setting this attribute on a resultset that does not join any has_many
4372 relations is a no-op.
4373
4374 For a more in-depth discussion, see L</PREFETCHING>.
4375
4376 =head2 prefetch
4377
4378 =over 4
4379
4380 =item Value: ($rel_name | \@rel_names | \%rel_names)
4381
4382 =back
4383
4384 This attribute is a shorthand for specifying a L</join> spec, adding all
4385 columns from the joined related sources as L</+columns> and setting
4386 L</collapse> to a true value. It can be thought of as a rough B<superset>
4387 of the L</join> attribute.
4388
4389 For example, the following two queries are equivalent:
4390
4391   my $rs = $schema->resultset('Artist')->search({}, {
4392     prefetch => { cds => ['genre', 'tracks' ] },
4393   });
4394
4395 and
4396
4397   my $rs = $schema->resultset('Artist')->search({}, {
4398     join => { cds => ['genre', 'tracks' ] },
4399     collapse => 1,
4400     '+columns' => [
4401       (map
4402         { +{ "cds.$_" => "cds.$_" } }
4403         $schema->source('Artist')->related_source('cds')->columns
4404       ),
4405       (map
4406         { +{ "cds.genre.$_" => "genre.$_" } }
4407         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4408       ),
4409       (map
4410         { +{ "cds.tracks.$_" => "tracks.$_" } }
4411         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4412       ),
4413     ],
4414   });
4415
4416 Both producing the following SQL:
4417
4418   SELECT  me.artistid, me.name, me.rank, me.charfield,
4419           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4420           genre.genreid, genre.name,
4421           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4422     FROM artist me
4423     LEFT JOIN cd cds
4424       ON cds.artist = me.artistid
4425     LEFT JOIN genre genre
4426       ON genre.genreid = cds.genreid
4427     LEFT JOIN track tracks
4428       ON tracks.cd = cds.cdid
4429   ORDER BY me.artistid
4430
4431 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4432 the arguments are properly merged and generally do the right thing. For
4433 example, you may want to do the following:
4434
4435   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4436     { 'genre.genreid' => undef },
4437     {
4438       join => { cds => 'genre' },
4439       prefetch => 'cds',
4440     }
4441   );
4442
4443 Which generates the following SQL:
4444
4445   SELECT  me.artistid, me.name, me.rank, me.charfield,
4446           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4447     FROM artist me
4448     LEFT JOIN cd cds
4449       ON cds.artist = me.artistid
4450     LEFT JOIN genre genre
4451       ON genre.genreid = cds.genreid
4452   WHERE genre.genreid IS NULL
4453   ORDER BY me.artistid
4454
4455 For a more in-depth discussion, see L</PREFETCHING>.
4456
4457 =head2 alias
4458
4459 =over 4
4460
4461 =item Value: $source_alias
4462
4463 =back
4464
4465 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4466 nested search queries (sub-SELECTs) might need specific aliases set to
4467 reference inner queries.  For example:
4468
4469    my $q = $rs
4470       ->related_resultset('CDs')
4471       ->related_resultset('Tracks')
4472       ->search({
4473          'track.id' => { -ident => 'none_search.id' },
4474       })
4475       ->as_query;
4476
4477    my $ids = $self->search({
4478       -not_exists => $q,
4479    }, {
4480       alias    => 'none_search',
4481       group_by => 'none_search.id',
4482    })->get_column('id')->as_query;
4483
4484    $self->search({ id => { -in => $ids } })
4485
4486 This attribute is directly tied to L</current_source_alias>.
4487
4488 =head2 page
4489
4490 =over 4
4491
4492 =item Value: $page
4493
4494 =back
4495
4496 Makes the resultset paged and specifies the page to retrieve. Effectively
4497 identical to creating a non-pages resultset and then calling ->page($page)
4498 on it.
4499
4500 If L</rows> attribute is not specified it defaults to 10 rows per page.
4501
4502 When you have a paged resultset, L</count> will only return the number
4503 of rows in the page. To get the total, use the L</pager> and call
4504 C<total_entries> on it.
4505
4506 =head2 rows
4507
4508 =over 4
4509
4510 =item Value: $rows
4511
4512 =back
4513
4514 Specifies the maximum number of rows for direct retrieval or the number of
4515 rows per page if the page attribute or method is used.
4516
4517 =head2 offset
4518
4519 =over 4
4520
4521 =item Value: $offset
4522
4523 =back
4524
4525 Specifies the (zero-based) row number for the  first row to be returned, or the
4526 of the first row of the first page if paging is used.
4527
4528 =head2 software_limit
4529
4530 =over 4
4531
4532 =item Value: (0 | 1)
4533
4534 =back
4535
4536 When combined with L</rows> and/or L</offset> the generated SQL will not
4537 include any limit dialect stanzas. Instead the entire result will be selected
4538 as if no limits were specified, and DBIC will perform the limit locally, by
4539 artificially advancing and finishing the resulting L</cursor>.
4540
4541 This is the recommended way of performing resultset limiting when no sane RDBMS
4542 implementation is available (e.g.
4543 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4544 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4545
4546 =head2 group_by
4547
4548 =over 4
4549
4550 =item Value: \@columns
4551
4552 =back
4553
4554 A arrayref of columns to group by. Can include columns of joined tables.
4555
4556   group_by => [qw/ column1 column2 ... /]
4557
4558 =head2 having
4559
4560 =over 4
4561
4562 =item Value: $condition
4563
4564 =back
4565
4566 The HAVING operator specifies a B<secondary> condition applied to the set
4567 after the grouping calculations have been done. In other words it is a
4568 constraint just like L</where> (and accepting the same
4569 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4570 as it exists after GROUP BY has taken place. Specifying L</having> without
4571 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4572
4573 E.g.
4574
4575   having => { 'count_employee' => { '>=', 100 } }
4576
4577 or with an in-place function in which case literal SQL is required:
4578
4579   having => \[ 'count(employee) >= ?', 100 ]
4580
4581 =head2 distinct
4582
4583 =over 4
4584
4585 =item Value: (0 | 1)
4586
4587 =back
4588
4589 Set to 1 to automatically generate a L</group_by> clause based on the selection
4590 (including intelligent handling of L</order_by> contents). Note that the group
4591 criteria calculation takes place over the B<final> selection. This includes
4592 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4593 L</search> calls, and standalone columns selected via
4594 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4595 extra selections specified via L</prefetch> - such selections are explicitly
4596 excluded from group criteria calculations.
4597
4598 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4599 setting is ignored and an appropriate warning is issued.
4600
4601 =head2 where
4602
4603 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4604 conditions, same as the B<first> argument to the L<search operator|/search>
4605
4606   # only return rows WHERE deleted IS NULL for all searches
4607   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4608
4609 Note that the above example is
4610 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4611
4612 =head2 cache
4613
4614 Set to 1 to cache search results. This prevents extra SQL queries if you
4615 revisit rows in your ResultSet:
4616
4617   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4618
4619   while( my $artist = $resultset->next ) {
4620     ... do stuff ...
4621   }
4622
4623   $resultset->first; # without cache, this would issue a query
4624
4625 By default, searches are not cached.
4626
4627 For more examples of using these attributes, see
4628 L<DBIx::Class::Manual::Cookbook>.
4629
4630 =head2 for
4631
4632 =over 4
4633
4634 =item Value: ( 'update' | 'shared' | \$scalar )
4635
4636 =back
4637
4638 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4639 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4640 query.
4641
4642 =head1 PREFETCHING
4643
4644 DBIx::Class supports arbitrary related data prefetching from multiple related
4645 sources. Any combination of relationship types and column sets are supported.
4646 If L<collapsing|/collapse> is requested, there is an additional requirement of
4647 selecting enough data to make every individual object uniquely identifiable.
4648
4649 Here are some more involved examples, based on the following relationship map:
4650
4651   # Assuming:
4652   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4653   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4654   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4655
4656   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4657
4658   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4659
4660
4661
4662   my $rs = $schema->resultset('Tag')->search(
4663     undef,
4664     {
4665       prefetch => {
4666         cd => 'artist'
4667       }
4668     }
4669   );
4670
4671 The initial search results in SQL like the following:
4672
4673   SELECT tag.*, cd.*, artist.* FROM tag
4674   JOIN cd ON tag.cd = cd.cdid
4675   JOIN artist ON cd.artist = artist.artistid
4676
4677 L<DBIx::Class> has no need to go back to the database when we access the
4678 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4679 case.
4680
4681 Simple prefetches will be joined automatically, so there is no need
4682 for a C<join> attribute in the above search.
4683
4684 The L</prefetch> attribute can be used with any of the relationship types
4685 and multiple prefetches can be specified together. Below is a more complex
4686 example that prefetches a CD's artist, its liner notes (if present),
4687 the cover image, the tracks on that CD, and the guests on those
4688 tracks.
4689
4690   my $rs = $schema->resultset('CD')->search(
4691     undef,
4692     {
4693       prefetch => [
4694         { artist => 'record_label'},  # belongs_to => belongs_to
4695         'liner_note',                 # might_have
4696         'cover_image',                # has_one
4697         { tracks => 'guests' },       # has_many => has_many
4698       ]
4699     }
4700   );
4701
4702 This will produce SQL like the following:
4703
4704   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4705          tracks.*, guests.*
4706     FROM cd me
4707     JOIN artist artist
4708       ON artist.artistid = me.artistid
4709     JOIN record_label record_label
4710       ON record_label.labelid = artist.labelid
4711     LEFT JOIN track tracks
4712       ON tracks.cdid = me.cdid
4713     LEFT JOIN guest guests
4714       ON guests.trackid = track.trackid
4715     LEFT JOIN liner_notes liner_note
4716       ON liner_note.cdid = me.cdid
4717     JOIN cd_artwork cover_image
4718       ON cover_image.cdid = me.cdid
4719   ORDER BY tracks.cd
4720
4721 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4722 C<tracks>, and C<guests> of the CD will all be available through the
4723 relationship accessors without the need for additional queries to the
4724 database.
4725
4726 =head3 CAVEATS
4727
4728 Prefetch does a lot of deep magic. As such, it may not behave exactly
4729 as you might expect.
4730
4731 =over 4
4732
4733 =item *
4734
4735 Prefetch uses the L</cache> to populate the prefetched relationships. This
4736 may or may not be what you want.
4737
4738 =item *
4739
4740 If you specify a condition on a prefetched relationship, ONLY those
4741 rows that match the prefetched condition will be fetched into that relationship.
4742 This means that adding prefetch to a search() B<may alter> what is returned by
4743 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4744
4745   my $artist_rs = $schema->resultset('Artist')->search({
4746       'cds.year' => 2008,
4747   }, {
4748       join => 'cds',
4749   });
4750
4751   my $count = $artist_rs->first->cds->count;
4752
4753   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4754
4755   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4756
4757   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4758
4759 That cmp_ok() may or may not pass depending on the datasets involved. In other
4760 words the C<WHERE> condition would apply to the entire dataset, just like
4761 it would in regular SQL. If you want to add a condition only to the "right side"
4762 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4763 condition|DBIx::Class::Relationship::Base/condition>
4764
4765 =back
4766
4767 =head1 DBIC BIND VALUES
4768
4769 Because DBIC may need more information to bind values than just the column name
4770 and value itself, it uses a special format for both passing and receiving bind
4771 values.  Each bind value should be composed of an arrayref of
4772 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4773
4774 =over 4
4775
4776 =item dbd_attrs
4777
4778 If present (in any form), this is what is being passed directly to bind_param.
4779 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4780 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4781
4782 If this is specified, all other bind options described below are ignored.
4783
4784 =item sqlt_datatype
4785
4786 If present, this is used to infer the actual bind attribute by passing to
4787 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4788 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4789
4790 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4791 currently drivers are expected to "Do the Right Thing" when given a common
4792 datatype name.  (Not ideal, but that's what we got at this point.)
4793
4794 =item sqlt_size
4795
4796 Currently used to correctly allocate buffers for bind_param_inout().
4797 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4798 or to a sensible value based on the "data_type".
4799
4800 =item dbic_colname
4801
4802 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4803 explicitly specified they are never overridden).  Also used by some weird DBDs,
4804 where the column name should be available at bind_param time (e.g. Oracle).
4805
4806 =back
4807
4808 For backwards compatibility and convenience, the following shortcuts are
4809 supported:
4810
4811   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4812   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4813   [ undef,   $val ] === [ {}, $val ]
4814   $val              === [ {}, $val ]
4815
4816 =head1 FURTHER QUESTIONS?
4817
4818 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4819
4820 =head1 COPYRIGHT AND LICENSE
4821
4822 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4823 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4824 redistribute it and/or modify it under the same terms as the
4825 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4826
4827 =cut