lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   while( $user = $users_rs->next) {
  29     print $user->username;
  30   }
  31
  32   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  33   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  34
  35 =head1 DESCRIPTION
  36
  37 A ResultSet is an object which stores a set of conditions representing
  38 a query. It is the backbone of DBIx::Class (i.e. the really
  39 important/useful bit).
  40
  41 No SQL is executed on the database when a ResultSet is created, it
  42 just stores all the conditions needed to create the query.
  43
  44 A basic ResultSet representing the data of an entire table is returned
  45 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  46 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  47
  48   my $users_rs = $schema->resultset('User');
  49
  50 A new ResultSet is returned from calling L</search> on an existing
  51 ResultSet. The new one will contain all the conditions of the
  52 original, plus any new conditions added in the C<search> call.
  53
  54 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  55 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  56 represents.
  57
  58 The query that the ResultSet represents is B<only> executed against
  59 the database when these methods are called:
  60 L</find> L</next> L</all> L</first> L</single> L</count>
  61
  62 =head1 EXAMPLES
  63
  64 =head2 Chaining resultsets
  65
  66 Let's say you've got a query that needs to be run to return some data
  67 to the user. But, you have an authorization system in place that
  68 prevents certain users from seeing certain information. So, you want
  69 to construct the basic query in one method, but add constraints to it in
  70 another.
  71
  72   sub get_data {
  73     my $self = shift;
  74     my $request = $self->get_request; # Get a request object somehow.
  75     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  76
  77     my $cd_rs = $schema->resultset('CD')->search({
  78       title => $request->param('title'),
  79       year => $request->param('year'),
  80     });
  81
  82     $self->apply_security_policy( $cd_rs );
  83
  84     return $cd_rs->all();
  85   }
  86
  87   sub apply_security_policy {
  88     my $self = shift;
  89     my ($rs) = @_;
  90
  91     return $rs->search({
  92       subversive => 0,
  93     });
  94   }
  95
  96 =head3 Resolving conditions and attributes
  97
  98 When a resultset is chained from another resultset, conditions and
  99 attributes with the same keys need resolving.
 100
 101 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 102 into the existing ones from the original resultset.
 103
 104 The L</where>, L</having> attribute, and any search conditions are
 105 merged with an SQL C<AND> to the existing condition from the original
 106 resultset.
 107
 108 All other attributes are overridden by any new ones supplied in the
 109 search attributes.
 110
 111 =head2 Multiple queries
 112
 113 Since a resultset just defines a query, you can do all sorts of
 114 things with it with the same object.
 115
 116   # Don't hit the DB yet.
 117   my $cd_rs = $schema->resultset('CD')->search({
 118     title => 'something',
 119     year => 2009,
 120   });
 121
 122   # Each of these hits the DB individually.
 123   my $count = $cd_rs->count;
 124   my $most_recent = $cd_rs->get_column('date_released')->max();
 125   my @records = $cd_rs->all;
 126
 127 And it's not just limited to SELECT statements.
 128
 129   $cd_rs->delete();
 130
 131 This is even cooler:
 132
 133   $cd_rs->create({ artist => 'Fred' });
 134
 135 Which is the same as:
 136
 137   $schema->resultset('CD')->create({
 138     title => 'something',
 139     year => 2009,
 140     artist => 'Fred'
 141   });
 142
 143 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 144
 145 =head1 OVERLOADING
 146
 147 If a resultset is used in a numeric context it returns the L</count>.
 148 However, if it is used in a boolean context it is always true.  So if
 149 you want to check if a resultset has any results use C<if $rs != 0>.
 150 C<if $rs> will always be true.
 151
 152 =head1 METHODS
 153
 154 =head2 new
 155
 156 =over 4
 157
 158 =item Arguments: $source, \%$attrs
 159
 160 =item Return Value: $rs
 161
 162 =back
 163
 164 The resultset constructor. Takes a source object (usually a
 165 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 166 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 167 executed as needed by the other methods.
 168
 169 Generally you won't need to construct a resultset manually.  You'll
 170 automatically get one from e.g. a L</search> called in scalar context:
 171
 172   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 173
 174 IMPORTANT: If called on an object, proxies to new_result instead so
 175
 176   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 177
 178 will return a CD object, not a ResultSet.
 179
 180 =cut
 181
 182 sub new {
 183   my $class = shift;
 184   return $class->new_result(@_) if ref $class;
 185
 186   my ($source, $attrs) = @_;
 187   $source = $source->handle
 188     unless $source->isa('DBIx::Class::ResultSourceHandle');
 189   $attrs = { %{$attrs||{}} };
 190
 191   if ($attrs->{page}) {
 192     $attrs->{rows} ||= 10;
 193   }
 194
 195   $attrs->{alias} ||= 'me';
 196
 197   # Creation of {} and bless separated to mitigate RH perl bug
 198   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 199   my $self = {
 200     _source_handle => $source,
 201     cond => $attrs->{where},
 202     count => undef,
 203     pager => undef,
 204     attrs => $attrs
 205   };
 206
 207   bless $self, $class;
 208
 209   $self->result_class(
 210     $attrs->{result_class} || $source->resolve->result_class
 211   );
 212
 213   return $self;
 214 }
 215
 216 =head2 search
 217
 218 =over 4
 219
 220 =item Arguments: $cond, \%attrs?
 221
 222 =item Return Value: $resultset (scalar context), @row_objs (list context)
 223
 224 =back
 225
 226   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 227   my $new_rs = $cd_rs->search({ year => 2005 });
 228
 229   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 230                  # year = 2005 OR year = 2004
 231
 232 If you need to pass in additional attributes but no additional condition,
 233 call it as C<search(undef, \%attrs)>.
 234
 235   # "SELECT name, artistid FROM $artist_table"
 236   my @all_artists = $schema->resultset('Artist')->search(undef, {
 237     columns => [qw/name artistid/],
 238   });
 239
 240 For a list of attributes that can be passed to C<search>, see
 241 L</ATTRIBUTES>. For more examples of using this function, see
 242 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 243 documentation for the first argument, see L<SQL::Abstract>.
 244
 245 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 246
 247 =cut
 248
 249 sub search {
 250   my $self = shift;
 251   my $rs = $self->search_rs( @_ );
 252   return (wantarray ? $rs->all : $rs);
 253 }
 254
 255 =head2 search_rs
 256
 257 =over 4
 258
 259 =item Arguments: $cond, \%attrs?
 260
 261 =item Return Value: $resultset
 262
 263 =back
 264
 265 This method does the same exact thing as search() except it will
 266 always return a resultset, even in list context.
 267
 268 =cut
 269
 270 sub search_rs {
 271   my $self = shift;
 272
 273   # Special-case handling for (undef, undef).
 274   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 275     pop(@_); pop(@_);
 276   }
 277
 278   my $attrs = {};
 279   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 280   my $our_attrs = { %{$self->{attrs}} };
 281   my $having = delete $our_attrs->{having};
 282   my $where = delete $our_attrs->{where};
 283
 284   my $rows;
 285
 286   my %safe = (alias => 1, cache => 1);
 287
 288   unless (
 289     (@_ && defined($_[0])) # @_ == () or (undef)
 290     ||
 291     (keys %$attrs # empty attrs or only 'safe' attrs
 292     && List::Util::first { !$safe{$_} } keys %$attrs)
 293   ) {
 294     # no search, effectively just a clone
 295     $rows = $self->get_cache;
 296   }
 297
 298   # reset the selector list
 299   if (List::Util::first { exists $attrs->{$_} } qw{columns select as}) {
 300      delete @{$our_attrs}{qw{select as columns +select +as +columns include_columns}};
 301   }
 302
 303   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 304
 305   # merge new attrs into inherited
 306   foreach my $key (qw/join prefetch +select +as +columns include_columns bind/) {
 307     next unless exists $attrs->{$key};
 308     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 309   }
 310
 311   my $cond = (@_
 312     ? (
 313         (@_ == 1 || ref $_[0] eq "HASH")
 314           ? (
 315               (ref $_[0] eq 'HASH')
 316                 ? (
 317                     (keys %{ $_[0] }  > 0)
 318                       ? shift
 319                       : undef
 320                    )
 321                 :  shift
 322              )
 323           : (
 324               (@_ % 2)
 325                 ? $self->throw_exception("Odd number of arguments to search")
 326                 : {@_}
 327              )
 328       )
 329     : undef
 330   );
 331
 332   if (defined $where) {
 333     $new_attrs->{where} = (
 334       defined $new_attrs->{where}
 335         ? { '-and' => [
 336               map {
 337                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 338               } $where, $new_attrs->{where}
 339             ]
 340           }
 341         : $where);
 342   }
 343
 344   if (defined $cond) {
 345     $new_attrs->{where} = (
 346       defined $new_attrs->{where}
 347         ? { '-and' => [
 348               map {
 349                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 350               } $cond, $new_attrs->{where}
 351             ]
 352           }
 353         : $cond);
 354   }
 355
 356   if (defined $having) {
 357     $new_attrs->{having} = (
 358       defined $new_attrs->{having}
 359         ? { '-and' => [
 360               map {
 361                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 362               } $having, $new_attrs->{having}
 363             ]
 364           }
 365         : $having);
 366   }
 367
 368   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 369
 370   $rs->set_cache($rows) if ($rows);
 371
 372   return $rs;
 373 }
 374
 375 =head2 search_literal
 376
 377 =over 4
 378
 379 =item Arguments: $sql_fragment, @bind_values
 380
 381 =item Return Value: $resultset (scalar context), @row_objs (list context)
 382
 383 =back
 384
 385   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 386   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 387
 388 Pass a literal chunk of SQL to be added to the conditional part of the
 389 resultset query.
 390
 391 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 392 only be used in that context. C<search_literal> is a convenience method.
 393 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 394 columns are bound correctly, use C<search>.
 395
 396 Example of how to use C<search> instead of C<search_literal>
 397
 398   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 399   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 400
 401
 402 See L<DBIx::Class::Manual::Cookbook/Searching> and
 403 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 404 require C<search_literal>.
 405
 406 =cut
 407
 408 sub search_literal {
 409   my ($self, $sql, @bind) = @_;
 410   my $attr;
 411   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 412     $attr = pop @bind;
 413   }
 414   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 415 }
 416
 417 =head2 find
 418
 419 =over 4
 420
 421 =item Arguments: @values | \%cols, \%attrs?
 422
 423 =item Return Value: $row_object | undef
 424
 425 =back
 426
 427 Finds a row based on its primary key or unique constraint. For example, to find
 428 a row by its primary key:
 429
 430   my $cd = $schema->resultset('CD')->find(5);
 431
 432 You can also find a row by a specific unique constraint using the C<key>
 433 attribute. For example:
 434
 435   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 436     key => 'cd_artist_title'
 437   });
 438
 439 Additionally, you can specify the columns explicitly by name:
 440
 441   my $cd = $schema->resultset('CD')->find(
 442     {
 443       artist => 'Massive Attack',
 444       title  => 'Mezzanine',
 445     },
 446     { key => 'cd_artist_title' }
 447   );
 448
 449 If the C<key> is specified as C<primary>, it searches only on the primary key.
 450
 451 If no C<key> is specified, it searches on all unique constraints defined on the
 452 source for which column data is provided, including the primary key.
 453
 454 If your table does not have a primary key, you B<must> provide a value for the
 455 C<key> attribute matching one of the unique constraints on the source.
 456
 457 In addition to C<key>, L</find> recognizes and applies standard
 458 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 459
 460 Note: If your query does not return only one row, a warning is generated:
 461
 462   Query returned more than one row
 463
 464 See also L</find_or_create> and L</update_or_create>. For information on how to
 465 declare unique constraints, see
 466 L<DBIx::Class::ResultSource/add_unique_constraint>.
 467
 468 =cut
 469
 470 sub find {
 471   my $self = shift;
 472   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 473
 474   # Default to the primary key, but allow a specific key
 475   my @cols = exists $attrs->{key}
 476     ? $self->result_source->unique_constraint_columns($attrs->{key})
 477     : $self->result_source->primary_columns;
 478   $self->throw_exception(
 479     "Can't find unless a primary key is defined or unique constraint is specified"
 480   ) unless @cols;
 481
 482   # Parse out a hashref from input
 483   my $input_query;
 484   if (ref $_[0] eq 'HASH') {
 485     $input_query = { %{$_[0]} };
 486   }
 487   elsif (@_ == @cols) {
 488     $input_query = {};
 489     @{$input_query}{@cols} = @_;
 490   }
 491   else {
 492     # Compatibility: Allow e.g. find(id => $value)
 493     carp "Find by key => value deprecated; please use a hashref instead";
 494     $input_query = {@_};
 495   }
 496
 497   my (%related, $info);
 498
 499   KEY: foreach my $key (keys %$input_query) {
 500     if (ref($input_query->{$key})
 501         && ($info = $self->result_source->relationship_info($key))) {
 502       my $val = delete $input_query->{$key};
 503       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 504       my $rel_q = $self->result_source->_resolve_condition(
 505                     $info->{cond}, $val, $key
 506                   );
 507       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 508       @related{keys %$rel_q} = values %$rel_q;
 509     }
 510   }
 511   if (my @keys = keys %related) {
 512     @{$input_query}{@keys} = values %related;
 513   }
 514
 515
 516   # Build the final query: Default to the disjunction of the unique queries,
 517   # but allow the input query in case the ResultSet defines the query or the
 518   # user is abusing find
 519   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 520   my $query;
 521   if (exists $attrs->{key}) {
 522     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 523     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 524     $query = $self->_add_alias($unique_query, $alias);
 525   }
 526   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 527     # This means that we got here after a merger of relationship conditions
 528     # in ::Relationship::Base::search_related (the row method), and furthermore
 529     # the relationship is of the 'single' type. This means that the condition
 530     # provided by the relationship (already attached to $self) is sufficient,
 531     # as there can be only one row in the database that would satisfy the
 532     # relationship
 533   }
 534   else {
 535     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 536     $query = @unique_queries
 537       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 538       : $self->_add_alias($input_query, $alias);
 539   }
 540
 541   # Run the query
 542   my $rs = $self->search ($query, $attrs);
 543   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 544     my $row = $rs->next;
 545     carp "Query returned more than one row" if $rs->next;
 546     return $row;
 547   }
 548   else {
 549     return $rs->single;
 550   }
 551 }
 552
 553 # _add_alias
 554 #
 555 # Add the specified alias to the specified query hash. A copy is made so the
 556 # original query is not modified.
 557
 558 sub _add_alias {
 559   my ($self, $query, $alias) = @_;
 560
 561   my %aliased = %$query;
 562   foreach my $col (grep { ! m/\./ } keys %aliased) {
 563     $aliased{"$alias.$col"} = delete $aliased{$col};
 564   }
 565
 566   return \%aliased;
 567 }
 568
 569 # _unique_queries
 570 #
 571 # Build a list of queries which satisfy unique constraints.
 572
 573 sub _unique_queries {
 574   my ($self, $query, $attrs) = @_;
 575
 576   my @constraint_names = exists $attrs->{key}
 577     ? ($attrs->{key})
 578     : $self->result_source->unique_constraint_names;
 579
 580   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 581   my $num_where = scalar keys %$where;
 582
 583   my (@unique_queries, %seen_column_combinations);
 584   foreach my $name (@constraint_names) {
 585     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 586
 587     my $constraint_sig = join "\x00", sort @constraint_cols;
 588     next if $seen_column_combinations{$constraint_sig}++;
 589
 590     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 591
 592     my $num_cols = scalar @constraint_cols;
 593     my $num_query = scalar keys %$unique_query;
 594
 595     my $total = $num_query + $num_where;
 596     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 597       # The query is either unique on its own or is unique in combination with
 598       # the existing where clause
 599       push @unique_queries, $unique_query;
 600     }
 601   }
 602
 603   return @unique_queries;
 604 }
 605
 606 # _build_unique_query
 607 #
 608 # Constrain the specified query hash based on the specified column names.
 609
 610 sub _build_unique_query {
 611   my ($self, $query, $unique_cols) = @_;
 612
 613   return {
 614     map  { $_ => $query->{$_} }
 615     grep { exists $query->{$_} }
 616       @$unique_cols
 617   };
 618 }
 619
 620 =head2 search_related
 621
 622 =over 4
 623
 624 =item Arguments: $rel, $cond, \%attrs?
 625
 626 =item Return Value: $new_resultset
 627
 628 =back
 629
 630   $new_rs = $cd_rs->search_related('artist', {
 631     name => 'Emo-R-Us',
 632   });
 633
 634 Searches the specified relationship, optionally specifying a condition and
 635 attributes for matching records. See L</ATTRIBUTES> for more information.
 636
 637 =cut
 638
 639 sub search_related {
 640   return shift->related_resultset(shift)->search(@_);
 641 }
 642
 643 =head2 search_related_rs
 644
 645 This method works exactly the same as search_related, except that
 646 it guarantees a resultset, even in list context.
 647
 648 =cut
 649
 650 sub search_related_rs {
 651   return shift->related_resultset(shift)->search_rs(@_);
 652 }
 653
 654 =head2 cursor
 655
 656 =over 4
 657
 658 =item Arguments: none
 659
 660 =item Return Value: $cursor
 661
 662 =back
 663
 664 Returns a storage-driven cursor to the given resultset. See
 665 L<DBIx::Class::Cursor> for more information.
 666
 667 =cut
 668
 669 sub cursor {
 670   my ($self) = @_;
 671
 672   my $attrs = $self->_resolved_attrs_copy;
 673
 674   return $self->{cursor}
 675     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 676           $attrs->{where},$attrs);
 677 }
 678
 679 =head2 single
 680
 681 =over 4
 682
 683 =item Arguments: $cond?
 684
 685 =item Return Value: $row_object?
 686
 687 =back
 688
 689   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 690
 691 Inflates the first result without creating a cursor if the resultset has
 692 any records in it; if not returns nothing. Used by L</find> as a lean version of
 693 L</search>.
 694
 695 While this method can take an optional search condition (just like L</search>)
 696 being a fast-code-path it does not recognize search attributes. If you need to
 697 add extra joins or similar, call L</search> and then chain-call L</single> on the
 698 L<DBIx::Class::ResultSet> returned.
 699
 700 =over
 701
 702 =item B<Note>
 703
 704 As of 0.08100, this method enforces the assumption that the preceding
 705 query returns only one row. If more than one row is returned, you will receive
 706 a warning:
 707
 708   Query returned more than one row
 709
 710 In this case, you should be using L</next> or L</find> instead, or if you really
 711 know what you are doing, use the L</rows> attribute to explicitly limit the size
 712 of the resultset.
 713
 714 This method will also throw an exception if it is called on a resultset prefetching
 715 has_many, as such a prefetch implies fetching multiple rows from the database in
 716 order to assemble the resulting object.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = $self->_resolved_attrs_copy;
 729
 730   if (keys %{$attrs->{collapse}}) {
 731     $self->throw_exception(
 732       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 733     );
 734   }
 735
 736   if ($where) {
 737     if (defined $attrs->{where}) {
 738       $attrs->{where} = {
 739         '-and' =>
 740             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 741                $where, delete $attrs->{where} ]
 742       };
 743     } else {
 744       $attrs->{where} = $where;
 745     }
 746   }
 747
 748 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 749 #  unless ($self->_is_unique_query($attrs->{where})) {
 750 #    carp "Query not guaranteed to return a single row"
 751 #      . "; please declare your unique constraints or use search instead";
 752 #  }
 753
 754   my @data = $self->result_source->storage->select_single(
 755     $attrs->{from}, $attrs->{select},
 756     $attrs->{where}, $attrs
 757   );
 758
 759   return (@data ? ($self->_construct_object(@data))[0] : undef);
 760 }
 761
 762
 763 # _is_unique_query
 764 #
 765 # Try to determine if the specified query is guaranteed to be unique, based on
 766 # the declared unique constraints.
 767
 768 sub _is_unique_query {
 769   my ($self, $query) = @_;
 770
 771   my $collapsed = $self->_collapse_query($query);
 772   my $alias = $self->{attrs}{alias};
 773
 774   foreach my $name ($self->result_source->unique_constraint_names) {
 775     my @unique_cols = map {
 776       "$alias.$_"
 777     } $self->result_source->unique_constraint_columns($name);
 778
 779     # Count the values for each unique column
 780     my %seen = map { $_ => 0 } @unique_cols;
 781
 782     foreach my $key (keys %$collapsed) {
 783       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 784       next unless exists $seen{$aliased};  # Additional constraints are okay
 785       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 786     }
 787
 788     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 789     return 1 unless grep { $_ != 1 } values %seen;
 790   }
 791
 792   return 0;
 793 }
 794
 795 # _collapse_query
 796 #
 797 # Recursively collapse the query, accumulating values for each column.
 798
 799 sub _collapse_query {
 800   my ($self, $query, $collapsed) = @_;
 801
 802   $collapsed ||= {};
 803
 804   if (ref $query eq 'ARRAY') {
 805     foreach my $subquery (@$query) {
 806       next unless ref $subquery;  # -or
 807       $collapsed = $self->_collapse_query($subquery, $collapsed);
 808     }
 809   }
 810   elsif (ref $query eq 'HASH') {
 811     if (keys %$query and (keys %$query)[0] eq '-and') {
 812       foreach my $subquery (@{$query->{-and}}) {
 813         $collapsed = $self->_collapse_query($subquery, $collapsed);
 814       }
 815     }
 816     else {
 817       foreach my $col (keys %$query) {
 818         my $value = $query->{$col};
 819         $collapsed->{$col}{$value}++;
 820       }
 821     }
 822   }
 823
 824   return $collapsed;
 825 }
 826
 827 =head2 get_column
 828
 829 =over 4
 830
 831 =item Arguments: $cond?
 832
 833 =item Return Value: $resultsetcolumn
 834
 835 =back
 836
 837   my $max_length = $rs->get_column('length')->max;
 838
 839 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 840
 841 =cut
 842
 843 sub get_column {
 844   my ($self, $column) = @_;
 845   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 846   return $new;
 847 }
 848
 849 =head2 search_like
 850
 851 =over 4
 852
 853 =item Arguments: $cond, \%attrs?
 854
 855 =item Return Value: $resultset (scalar context), @row_objs (list context)
 856
 857 =back
 858
 859   # WHERE title LIKE '%blue%'
 860   $cd_rs = $rs->search_like({ title => '%blue%'});
 861
 862 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 863 that this is simply a convenience method retained for ex Class::DBI users.
 864 You most likely want to use L</search> with specific operators.
 865
 866 For more information, see L<DBIx::Class::Manual::Cookbook>.
 867
 868 This method is deprecated and will be removed in 0.09. Use L</search()>
 869 instead. An example conversion is:
 870
 871   ->search_like({ foo => 'bar' });
 872
 873   # Becomes
 874
 875   ->search({ foo => { like => 'bar' } });
 876
 877 =cut
 878
 879 sub search_like {
 880   my $class = shift;
 881   carp (
 882     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 883    .' Instead use ->search({ x => { -like => "y%" } })'
 884    .' (note the outer pair of {}s - they are important!)'
 885   );
 886   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 887   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 888   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 889   return $class->search($query, { %$attrs });
 890 }
 891
 892 =head2 slice
 893
 894 =over 4
 895
 896 =item Arguments: $first, $last
 897
 898 =item Return Value: $resultset (scalar context), @row_objs (list context)
 899
 900 =back
 901
 902 Returns a resultset or object list representing a subset of elements from the
 903 resultset slice is called on. Indexes are from 0, i.e., to get the first
 904 three records, call:
 905
 906   my ($one, $two, $three) = $rs->slice(0, 2);
 907
 908 =cut
 909
 910 sub slice {
 911   my ($self, $min, $max) = @_;
 912   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 913   $attrs->{offset} = $self->{attrs}{offset} || 0;
 914   $attrs->{offset} += $min;
 915   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 916   return $self->search(undef(), $attrs);
 917   #my $slice = (ref $self)->new($self->result_source, $attrs);
 918   #return (wantarray ? $slice->all : $slice);
 919 }
 920
 921 =head2 next
 922
 923 =over 4
 924
 925 =item Arguments: none
 926
 927 =item Return Value: $result?
 928
 929 =back
 930
 931 Returns the next element in the resultset (C<undef> is there is none).
 932
 933 Can be used to efficiently iterate over records in the resultset:
 934
 935   my $rs = $schema->resultset('CD')->search;
 936   while (my $cd = $rs->next) {
 937     print $cd->title;
 938   }
 939
 940 Note that you need to store the resultset object, and call C<next> on it.
 941 Calling C<< resultset('Table')->next >> repeatedly will always return the
 942 first record from the resultset.
 943
 944 =cut
 945
 946 sub next {
 947   my ($self) = @_;
 948   if (my $cache = $self->get_cache) {
 949     $self->{all_cache_position} ||= 0;
 950     return $cache->[$self->{all_cache_position}++];
 951   }
 952   if ($self->{attrs}{cache}) {
 953     $self->{all_cache_position} = 1;
 954     return ($self->all)[0];
 955   }
 956   if ($self->{stashed_objects}) {
 957     my $obj = shift(@{$self->{stashed_objects}});
 958     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 959     return $obj;
 960   }
 961   my @row = (
 962     exists $self->{stashed_row}
 963       ? @{delete $self->{stashed_row}}
 964       : $self->cursor->next
 965   );
 966   return undef unless (@row);
 967   my ($row, @more) = $self->_construct_object(@row);
 968   $self->{stashed_objects} = \@more if @more;
 969   return $row;
 970 }
 971
 972 sub _construct_object {
 973   my ($self, @row) = @_;
 974
 975   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 976     or return ();
 977   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 978   @new = $self->{_attrs}{record_filter}->(@new)
 979     if exists $self->{_attrs}{record_filter};
 980   return @new;
 981 }
 982
 983 sub _collapse_result {
 984   my ($self, $as_proto, $row) = @_;
 985
 986   my @copy = @$row;
 987
 988   # 'foo'         => [ undef, 'foo' ]
 989   # 'foo.bar'     => [ 'foo', 'bar' ]
 990   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 991
 992   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 993
 994   my %collapse = %{$self->{_attrs}{collapse}||{}};
 995
 996   my @pri_index;
 997
 998   # if we're doing collapsing (has_many prefetch) we need to grab records
 999   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1000   # we know we don't have to bother.
1001
1002   # the reason for not using the collapse stuff directly is because if you
1003   # had for e.g. two artists in a row with no cds, the collapse info for
1004   # both would be NULL (undef) so you'd lose the second artist
1005
1006   # store just the index so we can check the array positions from the row
1007   # without having to contruct the full hash
1008
1009   if (keys %collapse) {
1010     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1011     foreach my $i (0 .. $#construct_as) {
1012       next if defined($construct_as[$i][0]); # only self table
1013       if (delete $pri{$construct_as[$i][1]}) {
1014         push(@pri_index, $i);
1015       }
1016       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1017     }
1018   }
1019
1020   # no need to do an if, it'll be empty if @pri_index is empty anyway
1021
1022   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1023
1024   my @const_rows;
1025
1026   do { # no need to check anything at the front, we always want the first row
1027
1028     my %const;
1029
1030     foreach my $this_as (@construct_as) {
1031       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1032     }
1033
1034     push(@const_rows, \%const);
1035
1036   } until ( # no pri_index => no collapse => drop straight out
1037       !@pri_index
1038     or
1039       do { # get another row, stash it, drop out if different PK
1040
1041         @copy = $self->cursor->next;
1042         $self->{stashed_row} = \@copy;
1043
1044         # last thing in do block, counts as true if anything doesn't match
1045
1046         # check xor defined first for NULL vs. NOT NULL then if one is
1047         # defined the other must be so check string equality
1048
1049         grep {
1050           (defined $pri_vals{$_} ^ defined $copy[$_])
1051           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1052         } @pri_index;
1053       }
1054   );
1055
1056   my $alias = $self->{attrs}{alias};
1057   my $info = [];
1058
1059   my %collapse_pos;
1060
1061   my @const_keys;
1062
1063   foreach my $const (@const_rows) {
1064     scalar @const_keys or do {
1065       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1066     };
1067     foreach my $key (@const_keys) {
1068       if (length $key) {
1069         my $target = $info;
1070         my @parts = split(/\./, $key);
1071         my $cur = '';
1072         my $data = $const->{$key};
1073         foreach my $p (@parts) {
1074           $target = $target->[1]->{$p} ||= [];
1075           $cur .= ".${p}";
1076           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1077             # collapsing at this point and on final part
1078             my $pos = $collapse_pos{$cur};
1079             CK: foreach my $ck (@ckey) {
1080               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1081                 $collapse_pos{$cur} = $data;
1082                 delete @collapse_pos{ # clear all positioning for sub-entries
1083                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1084                 };
1085                 push(@$target, []);
1086                 last CK;
1087               }
1088             }
1089           }
1090           if (exists $collapse{$cur}) {
1091             $target = $target->[-1];
1092           }
1093         }
1094         $target->[0] = $data;
1095       } else {
1096         $info->[0] = $const->{$key};
1097       }
1098     }
1099   }
1100
1101   return $info;
1102 }
1103
1104 =head2 result_source
1105
1106 =over 4
1107
1108 =item Arguments: $result_source?
1109
1110 =item Return Value: $result_source
1111
1112 =back
1113
1114 An accessor for the primary ResultSource object from which this ResultSet
1115 is derived.
1116
1117 =head2 result_class
1118
1119 =over 4
1120
1121 =item Arguments: $result_class?
1122
1123 =item Return Value: $result_class
1124
1125 =back
1126
1127 An accessor for the class to use when creating row objects. Defaults to
1128 C<< result_source->result_class >> - which in most cases is the name of the
1129 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1130
1131 Note that changing the result_class will also remove any components
1132 that were originally loaded in the source class via
1133 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1134 in the original source class will not run.
1135
1136 =cut
1137
1138 sub result_class {
1139   my ($self, $result_class) = @_;
1140   if ($result_class) {
1141     $self->ensure_class_loaded($result_class);
1142     $self->_result_class($result_class);
1143     $self->{attrs}{result_class} = $result_class if ref $self;
1144   }
1145   $self->_result_class;
1146 }
1147
1148 =head2 count
1149
1150 =over 4
1151
1152 =item Arguments: $cond, \%attrs??
1153
1154 =item Return Value: $count
1155
1156 =back
1157
1158 Performs an SQL C<COUNT> with the same query as the resultset was built
1159 with to find the number of elements. Passing arguments is equivalent to
1160 C<< $rs->search ($cond, \%attrs)->count >>
1161
1162 =cut
1163
1164 sub count {
1165   my $self = shift;
1166   return $self->search(@_)->count if @_ and defined $_[0];
1167   return scalar @{ $self->get_cache } if $self->get_cache;
1168
1169   my $attrs = $self->_resolved_attrs_copy;
1170
1171   # this is a little optimization - it is faster to do the limit
1172   # adjustments in software, instead of a subquery
1173   my $rows = delete $attrs->{rows};
1174   my $offset = delete $attrs->{offset};
1175
1176   my $crs;
1177   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1178     $crs = $self->_count_subq_rs ($attrs);
1179   }
1180   else {
1181     $crs = $self->_count_rs ($attrs);
1182   }
1183   my $count = $crs->next;
1184
1185   $count -= $offset if $offset;
1186   $count = $rows if $rows and $rows < $count;
1187   $count = 0 if ($count < 0);
1188
1189   return $count;
1190 }
1191
1192 =head2 count_rs
1193
1194 =over 4
1195
1196 =item Arguments: $cond, \%attrs??
1197
1198 =item Return Value: $count_rs
1199
1200 =back
1201
1202 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1203 This can be very handy for subqueries:
1204
1205   ->search( { amount => $some_rs->count_rs->as_query } )
1206
1207 As with regular resultsets the SQL query will be executed only after
1208 the resultset is accessed via L</next> or L</all>. That would return
1209 the same single value obtainable via L</count>.
1210
1211 =cut
1212
1213 sub count_rs {
1214   my $self = shift;
1215   return $self->search(@_)->count_rs if @_;
1216
1217   # this may look like a lack of abstraction (count() does about the same)
1218   # but in fact an _rs *must* use a subquery for the limits, as the
1219   # software based limiting can not be ported if this $rs is to be used
1220   # in a subquery itself (i.e. ->as_query)
1221   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1222     return $self->_count_subq_rs;
1223   }
1224   else {
1225     return $self->_count_rs;
1226   }
1227 }
1228
1229 #
1230 # returns a ResultSetColumn object tied to the count query
1231 #
1232 sub _count_rs {
1233   my ($self, $attrs) = @_;
1234
1235   my $rsrc = $self->result_source;
1236   $attrs ||= $self->_resolved_attrs;
1237
1238   my $tmp_attrs = { %$attrs };
1239
1240   # take off any limits, record_filter is cdbi, and no point of ordering a count
1241   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1242
1243   # overwrite the selector (supplied by the storage)
1244   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1245   $tmp_attrs->{as} = 'count';
1246
1247   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1248
1249   return $tmp_rs;
1250 }
1251
1252 #
1253 # same as above but uses a subquery
1254 #
1255 sub _count_subq_rs {
1256   my ($self, $attrs) = @_;
1257
1258   my $rsrc = $self->result_source;
1259   $attrs ||= $self->_resolved_attrs_copy;
1260
1261   my $sub_attrs = { %$attrs };
1262
1263   # extra selectors do not go in the subquery and there is no point of ordering it
1264   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1265
1266   # if we multi-prefetch we group_by primary keys only as this is what we would
1267   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1268   if ( keys %{$attrs->{collapse}}  ) {
1269     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1270   }
1271
1272   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $attrs);
1273
1274   # this is so that the query can be simplified e.g.
1275   # * ordering can be thrown away in things like Top limit
1276   $sub_attrs->{-for_count_only} = 1;
1277
1278   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1279
1280   $attrs->{from} = [{
1281     -alias => 'count_subq',
1282     -source_handle => $rsrc->handle,
1283     count_subq => $sub_rs->as_query,
1284   }];
1285
1286   # the subquery replaces this
1287   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1288
1289   return $self->_count_rs ($attrs);
1290 }
1291
1292 sub _bool {
1293   return 1;
1294 }
1295
1296 =head2 count_literal
1297
1298 =over 4
1299
1300 =item Arguments: $sql_fragment, @bind_values
1301
1302 =item Return Value: $count
1303
1304 =back
1305
1306 Counts the results in a literal query. Equivalent to calling L</search_literal>
1307 with the passed arguments, then L</count>.
1308
1309 =cut
1310
1311 sub count_literal { shift->search_literal(@_)->count; }
1312
1313 =head2 all
1314
1315 =over 4
1316
1317 =item Arguments: none
1318
1319 =item Return Value: @objects
1320
1321 =back
1322
1323 Returns all elements in the resultset. Called implicitly if the resultset
1324 is returned in list context.
1325
1326 =cut
1327
1328 sub all {
1329   my $self = shift;
1330   if(@_) {
1331       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1332   }
1333
1334   return @{ $self->get_cache } if $self->get_cache;
1335
1336   my @obj;
1337
1338   if (keys %{$self->_resolved_attrs->{collapse}}) {
1339     # Using $self->cursor->all is really just an optimisation.
1340     # If we're collapsing has_many prefetches it probably makes
1341     # very little difference, and this is cleaner than hacking
1342     # _construct_object to survive the approach
1343     $self->cursor->reset;
1344     my @row = $self->cursor->next;
1345     while (@row) {
1346       push(@obj, $self->_construct_object(@row));
1347       @row = (exists $self->{stashed_row}
1348                ? @{delete $self->{stashed_row}}
1349                : $self->cursor->next);
1350     }
1351   } else {
1352     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1353   }
1354
1355   $self->set_cache(\@obj) if $self->{attrs}{cache};
1356
1357   return @obj;
1358 }
1359
1360 =head2 reset
1361
1362 =over 4
1363
1364 =item Arguments: none
1365
1366 =item Return Value: $self
1367
1368 =back
1369
1370 Resets the resultset's cursor, so you can iterate through the elements again.
1371 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1372 another query.
1373
1374 =cut
1375
1376 sub reset {
1377   my ($self) = @_;
1378   delete $self->{_attrs} if exists $self->{_attrs};
1379   $self->{all_cache_position} = 0;
1380   $self->cursor->reset;
1381   return $self;
1382 }
1383
1384 =head2 first
1385
1386 =over 4
1387
1388 =item Arguments: none
1389
1390 =item Return Value: $object?
1391
1392 =back
1393
1394 Resets the resultset and returns an object for the first result (if the
1395 resultset returns anything).
1396
1397 =cut
1398
1399 sub first {
1400   return $_[0]->reset->next;
1401 }
1402
1403
1404 # _rs_update_delete
1405 #
1406 # Determines whether and what type of subquery is required for the $rs operation.
1407 # If grouping is necessary either supplies its own, or verifies the current one
1408 # After all is done delegates to the proper storage method.
1409
1410 sub _rs_update_delete {
1411   my ($self, $op, $values) = @_;
1412
1413   my $rsrc = $self->result_source;
1414
1415   # if a condition exists we need to strip all table qualifiers
1416   # if this is not possible we'll force a subquery below
1417   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1418
1419   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1420   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/row offset/);
1421
1422   if ($needs_group_by_subq or $needs_subq) {
1423
1424     # make a new $rs selecting only the PKs (that's all we really need)
1425     my $attrs = $self->_resolved_attrs_copy;
1426
1427     delete $attrs->{$_} for qw/collapse select as/;
1428     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1429
1430     if ($needs_group_by_subq) {
1431       # make sure no group_by was supplied, or if there is one - make sure it matches
1432       # the columns compiled above perfectly. Anything else can not be sanely executed
1433       # on most databases so croak right then and there
1434
1435       if (my $g = $attrs->{group_by}) {
1436         my @current_group_by = map
1437           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1438           @$g
1439         ;
1440
1441         if (
1442           join ("\x00", sort @current_group_by)
1443             ne
1444           join ("\x00", sort @{$attrs->{columns}} )
1445         ) {
1446           $self->throw_exception (
1447             "You have just attempted a $op operation on a resultset which does group_by"
1448             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1449             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1450             . ' kind of queries. Please retry the operation with a modified group_by or'
1451             . ' without using one at all.'
1452           );
1453         }
1454       }
1455       else {
1456         $attrs->{group_by} = $attrs->{columns};
1457       }
1458     }
1459
1460     my $subrs = (ref $self)->new($rsrc, $attrs);
1461
1462     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1463   }
1464   else {
1465     return $rsrc->storage->$op(
1466       $rsrc,
1467       $op eq 'update' ? $values : (),
1468       $cond,
1469     );
1470   }
1471 }
1472
1473 =head2 update
1474
1475 =over 4
1476
1477 =item Arguments: \%values
1478
1479 =item Return Value: $storage_rv
1480
1481 =back
1482
1483 Sets the specified columns in the resultset to the supplied values in a
1484 single query. Return value will be true if the update succeeded or false
1485 if no records were updated; exact type of success value is storage-dependent.
1486
1487 =cut
1488
1489 sub update {
1490   my ($self, $values) = @_;
1491   $self->throw_exception('Values for update must be a hash')
1492     unless ref $values eq 'HASH';
1493
1494   return $self->_rs_update_delete ('update', $values);
1495 }
1496
1497 =head2 update_all
1498
1499 =over 4
1500
1501 =item Arguments: \%values
1502
1503 =item Return Value: 1
1504
1505 =back
1506
1507 Fetches all objects and updates them one at a time. Note that C<update_all>
1508 will run DBIC cascade triggers, while L</update> will not.
1509
1510 =cut
1511
1512 sub update_all {
1513   my ($self, $values) = @_;
1514   $self->throw_exception('Values for update_all must be a hash')
1515     unless ref $values eq 'HASH';
1516   foreach my $obj ($self->all) {
1517     $obj->set_columns($values)->update;
1518   }
1519   return 1;
1520 }
1521
1522 =head2 delete
1523
1524 =over 4
1525
1526 =item Arguments: none
1527
1528 =item Return Value: $storage_rv
1529
1530 =back
1531
1532 Deletes the contents of the resultset from its result source. Note that this
1533 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1534 to run. See also L<DBIx::Class::Row/delete>.
1535
1536 Return value will be the number of rows deleted; exact type of return value
1537 is storage-dependent.
1538
1539 =cut
1540
1541 sub delete {
1542   my $self = shift;
1543   $self->throw_exception('delete does not accept any arguments')
1544     if @_;
1545
1546   return $self->_rs_update_delete ('delete');
1547 }
1548
1549 =head2 delete_all
1550
1551 =over 4
1552
1553 =item Arguments: none
1554
1555 =item Return Value: 1
1556
1557 =back
1558
1559 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1560 will run DBIC cascade triggers, while L</delete> will not.
1561
1562 =cut
1563
1564 sub delete_all {
1565   my $self = shift;
1566   $self->throw_exception('delete_all does not accept any arguments')
1567     if @_;
1568
1569   $_->delete for $self->all;
1570   return 1;
1571 }
1572
1573 =head2 populate
1574
1575 =over 4
1576
1577 =item Arguments: \@data;
1578
1579 =back
1580
1581 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1582 For the arrayref of hashrefs style each hashref should be a structure suitable
1583 forsubmitting to a $resultset->create(...) method.
1584
1585 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1586 to insert the data, as this is a faster method.
1587
1588 Otherwise, each set of data is inserted into the database using
1589 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1590 accumulated into an array. The array itself, or an array reference
1591 is returned depending on scalar or list context.
1592
1593 Example:  Assuming an Artist Class that has many CDs Classes relating:
1594
1595   my $Artist_rs = $schema->resultset("Artist");
1596
1597   ## Void Context Example
1598   $Artist_rs->populate([
1599      { artistid => 4, name => 'Manufactured Crap', cds => [
1600         { title => 'My First CD', year => 2006 },
1601         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1602       ],
1603      },
1604      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1605         { title => 'My parents sold me to a record company', year => 2005 },
1606         { title => 'Why Am I So Ugly?', year => 2006 },
1607         { title => 'I Got Surgery and am now Popular', year => 2007 }
1608       ],
1609      },
1610   ]);
1611
1612   ## Array Context Example
1613   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1614     { name => "Artist One"},
1615     { name => "Artist Two"},
1616     { name => "Artist Three", cds=> [
1617     { title => "First CD", year => 2007},
1618     { title => "Second CD", year => 2008},
1619   ]}
1620   ]);
1621
1622   print $ArtistOne->name; ## response is 'Artist One'
1623   print $ArtistThree->cds->count ## reponse is '2'
1624
1625 For the arrayref of arrayrefs style,  the first element should be a list of the
1626 fieldsnames to which the remaining elements are rows being inserted.  For
1627 example:
1628
1629   $Arstist_rs->populate([
1630     [qw/artistid name/],
1631     [100, 'A Formally Unknown Singer'],
1632     [101, 'A singer that jumped the shark two albums ago'],
1633     [102, 'An actually cool singer'],
1634   ]);
1635
1636 Please note an important effect on your data when choosing between void and
1637 wantarray context. Since void context goes straight to C<insert_bulk> in
1638 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1639 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1640 create primary keys for you, you will find that your PKs are empty.  In this
1641 case you will have to use the wantarray context in order to create those
1642 values.
1643
1644 =cut
1645
1646 sub populate {
1647   my $self = shift;
1648
1649   # cruft placed in standalone method
1650   my $data = $self->_normalize_populate_args(@_);
1651
1652   if(defined wantarray) {
1653     my @created;
1654     foreach my $item (@$data) {
1655       push(@created, $self->create($item));
1656     }
1657     return wantarray ? @created : \@created;
1658   } else {
1659     my $first = $data->[0];
1660
1661     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1662     # it relationship data
1663     my (@rels, @columns);
1664     for (keys %$first) {
1665       my $ref = ref $first->{$_};
1666       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1667         ? push @rels, $_
1668         : push @columns, $_
1669       ;
1670     }
1671
1672     my @pks = $self->result_source->primary_columns;
1673
1674     ## do the belongs_to relationships
1675     foreach my $index (0..$#$data) {
1676
1677       # delegate to create() for any dataset without primary keys with specified relationships
1678       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1679         for my $r (@rels) {
1680           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1681             my @ret = $self->populate($data);
1682             return;
1683           }
1684         }
1685       }
1686
1687       foreach my $rel (@rels) {
1688         next unless ref $data->[$index]->{$rel} eq "HASH";
1689         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1690         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1691         my $related = $result->result_source->_resolve_condition(
1692           $result->result_source->relationship_info($reverse)->{cond},
1693           $self,
1694           $result,
1695         );
1696
1697         delete $data->[$index]->{$rel};
1698         $data->[$index] = {%{$data->[$index]}, %$related};
1699
1700         push @columns, keys %$related if $index == 0;
1701       }
1702     }
1703
1704     ## inherit the data locked in the conditions of the resultset
1705     my ($rs_data) = $self->_merge_cond_with_data({});
1706     delete @{$rs_data}{@columns};
1707     my @inherit_cols = keys %$rs_data;
1708     my @inherit_data = values %$rs_data;
1709
1710     ## do bulk insert on current row
1711     $self->result_source->storage->insert_bulk(
1712       $self->result_source,
1713       [@columns, @inherit_cols],
1714       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1715     );
1716
1717     ## do the has_many relationships
1718     foreach my $item (@$data) {
1719
1720       foreach my $rel (@rels) {
1721         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1722
1723         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1724      || $self->throw_exception('Cannot find the relating object.');
1725
1726         my $child = $parent->$rel;
1727
1728         my $related = $child->result_source->_resolve_condition(
1729           $parent->result_source->relationship_info($rel)->{cond},
1730           $child,
1731           $parent,
1732         );
1733
1734         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1735         my @populate = map { {%$_, %$related} } @rows_to_add;
1736
1737         $child->populate( \@populate );
1738       }
1739     }
1740   }
1741 }
1742
1743
1744 # populate() argumnets went over several incarnations
1745 # What we ultimately support is AoH
1746 sub _normalize_populate_args {
1747   my ($self, $arg) = @_;
1748
1749   if (ref $arg eq 'ARRAY') {
1750     if (ref $arg->[0] eq 'HASH') {
1751       return $arg;
1752     }
1753     elsif (ref $arg->[0] eq 'ARRAY') {
1754       my @ret;
1755       my @colnames = @{$arg->[0]};
1756       foreach my $values (@{$arg}[1 .. $#$arg]) {
1757         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
1758       }
1759       return \@ret;
1760     }
1761   }
1762
1763   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
1764 }
1765
1766 =head2 pager
1767
1768 =over 4
1769
1770 =item Arguments: none
1771
1772 =item Return Value: $pager
1773
1774 =back
1775
1776 Return Value a L<Data::Page> object for the current resultset. Only makes
1777 sense for queries with a C<page> attribute.
1778
1779 To get the full count of entries for a paged resultset, call
1780 C<total_entries> on the L<Data::Page> object.
1781
1782 =cut
1783
1784 sub pager {
1785   my ($self) = @_;
1786
1787   return $self->{pager} if $self->{pager};
1788
1789   my $attrs = $self->{attrs};
1790   $self->throw_exception("Can't create pager for non-paged rs")
1791     unless $self->{attrs}{page};
1792   $attrs->{rows} ||= 10;
1793
1794   # throw away the paging flags and re-run the count (possibly
1795   # with a subselect) to get the real total count
1796   my $count_attrs = { %$attrs };
1797   delete $count_attrs->{$_} for qw/rows offset page pager/;
1798   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1799
1800   return $self->{pager} = Data::Page->new(
1801     $total_count,
1802     $attrs->{rows},
1803     $self->{attrs}{page}
1804   );
1805 }
1806
1807 =head2 page
1808
1809 =over 4
1810
1811 =item Arguments: $page_number
1812
1813 =item Return Value: $rs
1814
1815 =back
1816
1817 Returns a resultset for the $page_number page of the resultset on which page
1818 is called, where each page contains a number of rows equal to the 'rows'
1819 attribute set on the resultset (10 by default).
1820
1821 =cut
1822
1823 sub page {
1824   my ($self, $page) = @_;
1825   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1826 }
1827
1828 =head2 new_result
1829
1830 =over 4
1831
1832 =item Arguments: \%vals
1833
1834 =item Return Value: $rowobject
1835
1836 =back
1837
1838 Creates a new row object in the resultset's result class and returns
1839 it. The row is not inserted into the database at this point, call
1840 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1841 will tell you whether the row object has been inserted or not.
1842
1843 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1844
1845 =cut
1846
1847 sub new_result {
1848   my ($self, $values) = @_;
1849   $self->throw_exception( "new_result needs a hash" )
1850     unless (ref $values eq 'HASH');
1851
1852   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
1853
1854   my %new = (
1855     %$merged_cond,
1856     @$cols_from_relations
1857       ? (-cols_from_relations => $cols_from_relations)
1858       : (),
1859     -source_handle => $self->_source_handle,
1860     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1861   );
1862   my $row = $self->result_class->new(\%new);
1863   #return $row;
1864   return $self->result_class->inflate_result($self->result_source, $row->{_column_data}, undef, $row);
1865 }
1866
1867 # _merge_cond_with_data
1868 #
1869 # Takes a simple hash of K/V data and returns its copy merged with the
1870 # condition already present on the resultset. Additionally returns an
1871 # arrayref of value/condition names, which were inferred from related
1872 # objects (this is needed for in-memory related objects)
1873 sub _merge_cond_with_data {
1874   my ($self, $data) = @_;
1875
1876   my (%new_data, @cols_from_relations);
1877
1878   my $alias = $self->{attrs}{alias};
1879
1880   if (! defined $self->{cond}) {
1881     # just massage $data below
1882   }
1883   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
1884     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1885     @cols_from_relations = keys %new_data;
1886   }
1887   elsif (ref $self->{cond} ne 'HASH') {
1888     $self->throw_exception(
1889       "Can't abstract implicit construct, resultset condition not a hash"
1890     );
1891   }
1892   else {
1893     # precendence must be given to passed values over values inherited from
1894     # the cond, so the order here is important.
1895     my $collapsed_cond = $self->_collapse_cond($self->{cond});
1896     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
1897
1898     while ( my($col, $value) = each %implied ) {
1899       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
1900         $new_data{$col} = $value->{'='};
1901         next;
1902       }
1903       $new_data{$col} = $value if $self->_is_deterministic_value($value);
1904     }
1905   }
1906
1907   %new_data = (
1908     %new_data,
1909     %{ $self->_remove_alias($data, $alias) },
1910   );
1911
1912   return (\%new_data, \@cols_from_relations);
1913 }
1914
1915 # _is_deterministic_value
1916 #
1917 # Make an effor to strip non-deterministic values from the condition,
1918 # to make sure new_result chokes less
1919
1920 sub _is_deterministic_value {
1921   my $self = shift;
1922   my $value = shift;
1923   my $ref_type = ref $value;
1924   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1925   return 1 if Scalar::Util::blessed($value);
1926   return 0;
1927 }
1928
1929 # _has_resolved_attr
1930 #
1931 # determines if the resultset defines at least one
1932 # of the attributes supplied
1933 #
1934 # used to determine if a subquery is neccessary
1935 #
1936 # supports some virtual attributes:
1937 #   -join
1938 #     This will scan for any joins being present on the resultset.
1939 #     It is not a mere key-search but a deep inspection of {from}
1940 #
1941
1942 sub _has_resolved_attr {
1943   my ($self, @attr_names) = @_;
1944
1945   my $attrs = $self->_resolved_attrs;
1946
1947   my %extra_checks;
1948
1949   for my $n (@attr_names) {
1950     if (grep { $n eq $_ } (qw/-join/) ) {
1951       $extra_checks{$n}++;
1952       next;
1953     }
1954
1955     my $attr =  $attrs->{$n};
1956
1957     next if not defined $attr;
1958
1959     if (ref $attr eq 'HASH') {
1960       return 1 if keys %$attr;
1961     }
1962     elsif (ref $attr eq 'ARRAY') {
1963       return 1 if @$attr;
1964     }
1965     else {
1966       return 1 if $attr;
1967     }
1968   }
1969
1970   # a resolved join is expressed as a multi-level from
1971   return 1 if (
1972     $extra_checks{-join}
1973       and
1974     ref $attrs->{from} eq 'ARRAY'
1975       and
1976     @{$attrs->{from}} > 1
1977   );
1978
1979   return 0;
1980 }
1981
1982 # _collapse_cond
1983 #
1984 # Recursively collapse the condition.
1985
1986 sub _collapse_cond {
1987   my ($self, $cond, $collapsed) = @_;
1988
1989   $collapsed ||= {};
1990
1991   if (ref $cond eq 'ARRAY') {
1992     foreach my $subcond (@$cond) {
1993       next unless ref $subcond;  # -or
1994       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1995     }
1996   }
1997   elsif (ref $cond eq 'HASH') {
1998     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1999       foreach my $subcond (@{$cond->{-and}}) {
2000         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2001       }
2002     }
2003     else {
2004       foreach my $col (keys %$cond) {
2005         my $value = $cond->{$col};
2006         $collapsed->{$col} = $value;
2007       }
2008     }
2009   }
2010
2011   return $collapsed;
2012 }
2013
2014 # _remove_alias
2015 #
2016 # Remove the specified alias from the specified query hash. A copy is made so
2017 # the original query is not modified.
2018
2019 sub _remove_alias {
2020   my ($self, $query, $alias) = @_;
2021
2022   my %orig = %{ $query || {} };
2023   my %unaliased;
2024
2025   foreach my $key (keys %orig) {
2026     if ($key !~ /\./) {
2027       $unaliased{$key} = $orig{$key};
2028       next;
2029     }
2030     $unaliased{$1} = $orig{$key}
2031       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2032   }
2033
2034   return \%unaliased;
2035 }
2036
2037 =head2 as_query
2038
2039 =over 4
2040
2041 =item Arguments: none
2042
2043 =item Return Value: \[ $sql, @bind ]
2044
2045 =back
2046
2047 Returns the SQL query and bind vars associated with the invocant.
2048
2049 This is generally used as the RHS for a subquery.
2050
2051 =cut
2052
2053 sub as_query {
2054   my $self = shift;
2055
2056   my $attrs = $self->_resolved_attrs_copy;
2057
2058   # For future use:
2059   #
2060   # in list ctx:
2061   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2062   # $sql also has no wrapping parenthesis in list ctx
2063   #
2064   my $sqlbind = $self->result_source->storage
2065     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2066
2067   return $sqlbind;
2068 }
2069
2070 =head2 find_or_new
2071
2072 =over 4
2073
2074 =item Arguments: \%vals, \%attrs?
2075
2076 =item Return Value: $rowobject
2077
2078 =back
2079
2080   my $artist = $schema->resultset('Artist')->find_or_new(
2081     { artist => 'fred' }, { key => 'artists' });
2082
2083   $cd->cd_to_producer->find_or_new({ producer => $producer },
2084                                    { key => 'primary });
2085
2086 Find an existing record from this resultset, based on its primary
2087 key, or a unique constraint. If none exists, instantiate a new result
2088 object and return it. The object will not be saved into your storage
2089 until you call L<DBIx::Class::Row/insert> on it.
2090
2091 You most likely want this method when looking for existing rows using
2092 a unique constraint that is not the primary key, or looking for
2093 related rows.
2094
2095 If you want objects to be saved immediately, use L</find_or_create>
2096 instead.
2097
2098 B<Note>: Take care when using C<find_or_new> with a table having
2099 columns with default values that you intend to be automatically
2100 supplied by the database (e.g. an auto_increment primary key column).
2101 In normal usage, the value of such columns should NOT be included at
2102 all in the call to C<find_or_new>, even when set to C<undef>.
2103
2104 =cut
2105
2106 sub find_or_new {
2107   my $self     = shift;
2108   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2109   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2110   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2111     return $row;
2112   }
2113   return $self->new_result($hash);
2114 }
2115
2116 =head2 create
2117
2118 =over 4
2119
2120 =item Arguments: \%vals
2121
2122 =item Return Value: a L<DBIx::Class::Row> $object
2123
2124 =back
2125
2126 Attempt to create a single new row or a row with multiple related rows
2127 in the table represented by the resultset (and related tables). This
2128 will not check for duplicate rows before inserting, use
2129 L</find_or_create> to do that.
2130
2131 To create one row for this resultset, pass a hashref of key/value
2132 pairs representing the columns of the table and the values you wish to
2133 store. If the appropriate relationships are set up, foreign key fields
2134 can also be passed an object representing the foreign row, and the
2135 value will be set to its primary key.
2136
2137 To create related objects, pass a hashref of related-object column values
2138 B<keyed on the relationship name>. If the relationship is of type C<multi>
2139 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2140 The process will correctly identify columns holding foreign keys, and will
2141 transparently populate them from the keys of the corresponding relation.
2142 This can be applied recursively, and will work correctly for a structure
2143 with an arbitrary depth and width, as long as the relationships actually
2144 exists and the correct column data has been supplied.
2145
2146
2147 Instead of hashrefs of plain related data (key/value pairs), you may
2148 also pass new or inserted objects. New objects (not inserted yet, see
2149 L</new>), will be inserted into their appropriate tables.
2150
2151 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2152
2153 Example of creating a new row.
2154
2155   $person_rs->create({
2156     name=>"Some Person",
2157     email=>"somebody@someplace.com"
2158   });
2159
2160 Example of creating a new row and also creating rows in a related C<has_many>
2161 or C<has_one> resultset.  Note Arrayref.
2162
2163   $artist_rs->create(
2164      { artistid => 4, name => 'Manufactured Crap', cds => [
2165         { title => 'My First CD', year => 2006 },
2166         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2167       ],
2168      },
2169   );
2170
2171 Example of creating a new row and also creating a row in a related
2172 C<belongs_to>resultset. Note Hashref.
2173
2174   $cd_rs->create({
2175     title=>"Music for Silly Walks",
2176     year=>2000,
2177     artist => {
2178       name=>"Silly Musician",
2179     }
2180   });
2181
2182 =over
2183
2184 =item WARNING
2185
2186 When subclassing ResultSet never attempt to override this method. Since
2187 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2188 lot of the internals simply never call it, so your override will be
2189 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2190 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2191 L</create> process you need to intervene.
2192
2193 =back
2194
2195 =cut
2196
2197 sub create {
2198   my ($self, $attrs) = @_;
2199   $self->throw_exception( "create needs a hashref" )
2200     unless ref $attrs eq 'HASH';
2201   return $self->new_result($attrs)->insert;
2202 }
2203
2204 =head2 find_or_create
2205
2206 =over 4
2207
2208 =item Arguments: \%vals, \%attrs?
2209
2210 =item Return Value: $rowobject
2211
2212 =back
2213
2214   $cd->cd_to_producer->find_or_create({ producer => $producer },
2215                                       { key => 'primary' });
2216
2217 Tries to find a record based on its primary key or unique constraints; if none
2218 is found, creates one and returns that instead.
2219
2220   my $cd = $schema->resultset('CD')->find_or_create({
2221     cdid   => 5,
2222     artist => 'Massive Attack',
2223     title  => 'Mezzanine',
2224     year   => 2005,
2225   });
2226
2227 Also takes an optional C<key> attribute, to search by a specific key or unique
2228 constraint. For example:
2229
2230   my $cd = $schema->resultset('CD')->find_or_create(
2231     {
2232       artist => 'Massive Attack',
2233       title  => 'Mezzanine',
2234     },
2235     { key => 'cd_artist_title' }
2236   );
2237
2238 B<Note>: Because find_or_create() reads from the database and then
2239 possibly inserts based on the result, this method is subject to a race
2240 condition. Another process could create a record in the table after
2241 the find has completed and before the create has started. To avoid
2242 this problem, use find_or_create() inside a transaction.
2243
2244 B<Note>: Take care when using C<find_or_create> with a table having
2245 columns with default values that you intend to be automatically
2246 supplied by the database (e.g. an auto_increment primary key column).
2247 In normal usage, the value of such columns should NOT be included at
2248 all in the call to C<find_or_create>, even when set to C<undef>.
2249
2250 See also L</find> and L</update_or_create>. For information on how to declare
2251 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2252
2253 =cut
2254
2255 sub find_or_create {
2256   my $self     = shift;
2257   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2258   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2259   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2260     return $row;
2261   }
2262   return $self->create($hash);
2263 }
2264
2265 =head2 update_or_create
2266
2267 =over 4
2268
2269 =item Arguments: \%col_values, { key => $unique_constraint }?
2270
2271 =item Return Value: $rowobject
2272
2273 =back
2274
2275   $resultset->update_or_create({ col => $val, ... });
2276
2277 First, searches for an existing row matching one of the unique constraints
2278 (including the primary key) on the source of this resultset. If a row is
2279 found, updates it with the other given column values. Otherwise, creates a new
2280 row.
2281
2282 Takes an optional C<key> attribute to search on a specific unique constraint.
2283 For example:
2284
2285   # In your application
2286   my $cd = $schema->resultset('CD')->update_or_create(
2287     {
2288       artist => 'Massive Attack',
2289       title  => 'Mezzanine',
2290       year   => 1998,
2291     },
2292     { key => 'cd_artist_title' }
2293   );
2294
2295   $cd->cd_to_producer->update_or_create({
2296     producer => $producer,
2297     name => 'harry',
2298   }, {
2299     key => 'primary,
2300   });
2301
2302
2303 If no C<key> is specified, it searches on all unique constraints defined on the
2304 source, including the primary key.
2305
2306 If the C<key> is specified as C<primary>, it searches only on the primary key.
2307
2308 See also L</find> and L</find_or_create>. For information on how to declare
2309 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2310
2311 B<Note>: Take care when using C<update_or_create> with a table having
2312 columns with default values that you intend to be automatically
2313 supplied by the database (e.g. an auto_increment primary key column).
2314 In normal usage, the value of such columns should NOT be included at
2315 all in the call to C<update_or_create>, even when set to C<undef>.
2316
2317 =cut
2318
2319 sub update_or_create {
2320   my $self = shift;
2321   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2322   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2323
2324   my $row = $self->find($cond, $attrs);
2325   if (defined $row) {
2326     $row->update($cond);
2327     return $row;
2328   }
2329
2330   return $self->create($cond);
2331 }
2332
2333 =head2 update_or_new
2334
2335 =over 4
2336
2337 =item Arguments: \%col_values, { key => $unique_constraint }?
2338
2339 =item Return Value: $rowobject
2340
2341 =back
2342
2343   $resultset->update_or_new({ col => $val, ... });
2344
2345 First, searches for an existing row matching one of the unique constraints
2346 (including the primary key) on the source of this resultset. If a row is
2347 found, updates it with the other given column values. Otherwise, instantiate
2348 a new result object and return it. The object will not be saved into your storage
2349 until you call L<DBIx::Class::Row/insert> on it.
2350
2351 Takes an optional C<key> attribute to search on a specific unique constraint.
2352 For example:
2353
2354   # In your application
2355   my $cd = $schema->resultset('CD')->update_or_new(
2356     {
2357       artist => 'Massive Attack',
2358       title  => 'Mezzanine',
2359       year   => 1998,
2360     },
2361     { key => 'cd_artist_title' }
2362   );
2363
2364   if ($cd->in_storage) {
2365       # the cd was updated
2366   }
2367   else {
2368       # the cd is not yet in the database, let's insert it
2369       $cd->insert;
2370   }
2371
2372 B<Note>: Take care when using C<update_or_new> with a table having
2373 columns with default values that you intend to be automatically
2374 supplied by the database (e.g. an auto_increment primary key column).
2375 In normal usage, the value of such columns should NOT be included at
2376 all in the call to C<update_or_new>, even when set to C<undef>.
2377
2378 See also L</find>, L</find_or_create> and L</find_or_new>.
2379
2380 =cut
2381
2382 sub update_or_new {
2383     my $self  = shift;
2384     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2385     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2386
2387     my $row = $self->find( $cond, $attrs );
2388     if ( defined $row ) {
2389         $row->update($cond);
2390         return $row;
2391     }
2392
2393     return $self->new_result($cond);
2394 }
2395
2396 =head2 get_cache
2397
2398 =over 4
2399
2400 =item Arguments: none
2401
2402 =item Return Value: \@cache_objects?
2403
2404 =back
2405
2406 Gets the contents of the cache for the resultset, if the cache is set.
2407
2408 The cache is populated either by using the L</prefetch> attribute to
2409 L</search> or by calling L</set_cache>.
2410
2411 =cut
2412
2413 sub get_cache {
2414   shift->{all_cache};
2415 }
2416
2417 =head2 set_cache
2418
2419 =over 4
2420
2421 =item Arguments: \@cache_objects
2422
2423 =item Return Value: \@cache_objects
2424
2425 =back
2426
2427 Sets the contents of the cache for the resultset. Expects an arrayref
2428 of objects of the same class as those produced by the resultset. Note that
2429 if the cache is set the resultset will return the cached objects rather
2430 than re-querying the database even if the cache attr is not set.
2431
2432 The contents of the cache can also be populated by using the
2433 L</prefetch> attribute to L</search>.
2434
2435 =cut
2436
2437 sub set_cache {
2438   my ( $self, $data ) = @_;
2439   $self->throw_exception("set_cache requires an arrayref")
2440       if defined($data) && (ref $data ne 'ARRAY');
2441   $self->{all_cache} = $data;
2442 }
2443
2444 =head2 clear_cache
2445
2446 =over 4
2447
2448 =item Arguments: none
2449
2450 =item Return Value: []
2451
2452 =back
2453
2454 Clears the cache for the resultset.
2455
2456 =cut
2457
2458 sub clear_cache {
2459   shift->set_cache(undef);
2460 }
2461
2462 =head2 is_paged
2463
2464 =over 4
2465
2466 =item Arguments: none
2467
2468 =item Return Value: true, if the resultset has been paginated
2469
2470 =back
2471
2472 =cut
2473
2474 sub is_paged {
2475   my ($self) = @_;
2476   return !!$self->{attrs}{page};
2477 }
2478
2479 =head2 is_ordered
2480
2481 =over 4
2482
2483 =item Arguments: none
2484
2485 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2486
2487 =back
2488
2489 =cut
2490
2491 sub is_ordered {
2492   my ($self) = @_;
2493   return scalar $self->result_source->storage->_parse_order_by($self->{attrs}{order_by});
2494 }
2495
2496 =head2 related_resultset
2497
2498 =over 4
2499
2500 =item Arguments: $relationship_name
2501
2502 =item Return Value: $resultset
2503
2504 =back
2505
2506 Returns a related resultset for the supplied relationship name.
2507
2508   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2509
2510 =cut
2511
2512 sub related_resultset {
2513   my ($self, $rel) = @_;
2514
2515   $self->{related_resultsets} ||= {};
2516   return $self->{related_resultsets}{$rel} ||= do {
2517     my $rsrc = $self->result_source;
2518     my $rel_info = $rsrc->relationship_info($rel);
2519
2520     $self->throw_exception(
2521       "search_related: result source '" . $rsrc->source_name .
2522         "' has no such relationship $rel")
2523       unless $rel_info;
2524
2525     my $attrs = $self->_chain_relationship($rel);
2526
2527     my $join_count = $attrs->{seen_join}{$rel};
2528
2529     my $alias = $self->result_source->storage
2530         ->relname_to_table_alias($rel, $join_count);
2531
2532     # since this is search_related, and we already slid the select window inwards
2533     # (the select/as attrs were deleted in the beginning), we need to flip all
2534     # left joins to inner, so we get the expected results
2535     # read the comment on top of the actual function to see what this does
2536     $attrs->{from} = $rsrc->schema->storage->_straight_join_to_node ($attrs->{from}, $alias);
2537
2538
2539     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2540     delete @{$attrs}{qw(result_class alias)};
2541
2542     my $new_cache;
2543
2544     if (my $cache = $self->get_cache) {
2545       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2546         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2547                         @$cache ];
2548       }
2549     }
2550
2551     my $rel_source = $rsrc->related_source($rel);
2552
2553     my $new = do {
2554
2555       # The reason we do this now instead of passing the alias to the
2556       # search_rs below is that if you wrap/overload resultset on the
2557       # source you need to know what alias it's -going- to have for things
2558       # to work sanely (e.g. RestrictWithObject wants to be able to add
2559       # extra query restrictions, and these may need to be $alias.)
2560
2561       my $rel_attrs = $rel_source->resultset_attributes;
2562       local $rel_attrs->{alias} = $alias;
2563
2564       $rel_source->resultset
2565                  ->search_rs(
2566                      undef, {
2567                        %$attrs,
2568                        where => $attrs->{where},
2569                    });
2570     };
2571     $new->set_cache($new_cache) if $new_cache;
2572     $new;
2573   };
2574 }
2575
2576 =head2 current_source_alias
2577
2578 =over 4
2579
2580 =item Arguments: none
2581
2582 =item Return Value: $source_alias
2583
2584 =back
2585
2586 Returns the current table alias for the result source this resultset is built
2587 on, that will be used in the SQL query. Usually it is C<me>.
2588
2589 Currently the source alias that refers to the result set returned by a
2590 L</search>/L</find> family method depends on how you got to the resultset: it's
2591 C<me> by default, but eg. L</search_related> aliases it to the related result
2592 source name (and keeps C<me> referring to the original result set). The long
2593 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2594 (and make this method unnecessary).
2595
2596 Thus it's currently necessary to use this method in predefined queries (see
2597 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2598 source alias of the current result set:
2599
2600   # in a result set class
2601   sub modified_by {
2602     my ($self, $user) = @_;
2603
2604     my $me = $self->current_source_alias;
2605
2606     return $self->search(
2607       "$me.modified" => $user->id,
2608     );
2609   }
2610
2611 =cut
2612
2613 sub current_source_alias {
2614   my ($self) = @_;
2615
2616   return ($self->{attrs} || {})->{alias} || 'me';
2617 }
2618
2619 =head2 as_subselect_rs
2620
2621 =over 4
2622
2623 =item Arguments: none
2624
2625 =item Return Value: $resultset
2626
2627 =back
2628
2629 Act as a barrier to SQL symbols.  The resultset provided will be made into a
2630 "virtual view" by including it as a subquery within the from clause.  From this
2631 point on, any joined tables are inaccessible to ->search on the resultset (as if
2632 it were simply where-filtered without joins).  For example:
2633
2634  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
2635
2636  # 'x' now pollutes the query namespace
2637
2638  # So the following works as expected
2639  my $ok_rs = $rs->search({'x.other' => 1});
2640
2641  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
2642  # def) we look for one row with contradictory terms and join in another table
2643  # (aliased 'x_2') which we never use
2644  my $broken_rs = $rs->search({'x.name' => 'def'});
2645
2646  my $rs2 = $rs->as_subselect_rs;
2647
2648  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
2649  my $not_joined_rs = $rs2->search({'x.other' => 1});
2650
2651  # works as expected: finds a 'table' row related to two x rows (abc and def)
2652  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
2653
2654 Another example of when one might use this would be to select a subset of
2655 columns in a group by clause:
2656
2657  my $rs = $schema->resultset('Bar')->search(undef, {
2658    group_by => [qw{ id foo_id baz_id }],
2659  })->as_subselect_rs->search(undef, {
2660    columns => [qw{ id foo_id }]
2661  });
2662
2663 In the above example normally columns would have to be equal to the group by,
2664 but because we isolated the group by into a subselect the above works.
2665
2666 =cut
2667
2668 sub as_subselect_rs {
2669    my $self = shift;
2670
2671    return $self->result_source->resultset->search( undef, {
2672       alias => $self->current_source_alias,
2673       from => [{
2674             $self->current_source_alias => $self->as_query,
2675             -alias         => $self->current_source_alias,
2676             -source_handle => $self->result_source->handle,
2677          }]
2678    });
2679 }
2680
2681 # This code is called by search_related, and makes sure there
2682 # is clear separation between the joins before, during, and
2683 # after the relationship. This information is needed later
2684 # in order to properly resolve prefetch aliases (any alias
2685 # with a relation_chain_depth less than the depth of the
2686 # current prefetch is not considered)
2687 #
2688 # The increments happen twice per join. An even number means a
2689 # relationship specified via a search_related, whereas an odd
2690 # number indicates a join/prefetch added via attributes
2691 #
2692 # Also this code will wrap the current resultset (the one we
2693 # chain to) in a subselect IFF it contains limiting attributes
2694 sub _chain_relationship {
2695   my ($self, $rel) = @_;
2696   my $source = $self->result_source;
2697   my $attrs = { %{$self->{attrs}||{}} };
2698
2699   # we need to take the prefetch the attrs into account before we
2700   # ->_resolve_join as otherwise they get lost - captainL
2701   my $join = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2702
2703   delete @{$attrs}{qw/join prefetch collapse distinct select as columns +select +as +columns/};
2704
2705   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
2706
2707   my $from;
2708   my @force_subq_attrs = qw/offset rows group_by having/;
2709
2710   if (
2711     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
2712       ||
2713     $self->_has_resolved_attr (@force_subq_attrs)
2714   ) {
2715     # Nuke the prefetch (if any) before the new $rs attrs
2716     # are resolved (prefetch is useless - we are wrapping
2717     # a subquery anyway).
2718     my $rs_copy = $self->search;
2719     $rs_copy->{attrs}{join} = $self->_merge_attr (
2720       $rs_copy->{attrs}{join},
2721       delete $rs_copy->{attrs}{prefetch},
2722     );
2723
2724     $from = [{
2725       -source_handle => $source->handle,
2726       -alias => $attrs->{alias},
2727       $attrs->{alias} => $rs_copy->as_query,
2728     }];
2729     delete @{$attrs}{@force_subq_attrs, 'where'};
2730     $seen->{-relation_chain_depth} = 0;
2731   }
2732   elsif ($attrs->{from}) {  #shallow copy suffices
2733     $from = [ @{$attrs->{from}} ];
2734   }
2735   else {
2736     $from = [{
2737       -source_handle => $source->handle,
2738       -alias => $attrs->{alias},
2739       $attrs->{alias} => $source->from,
2740     }];
2741   }
2742
2743   my $jpath = ($seen->{-relation_chain_depth})
2744     ? $from->[-1][0]{-join_path}
2745     : [];
2746
2747   my @requested_joins = $source->_resolve_join(
2748     $join,
2749     $attrs->{alias},
2750     $seen,
2751     $jpath,
2752   );
2753
2754   push @$from, @requested_joins;
2755
2756   $seen->{-relation_chain_depth}++;
2757
2758   # if $self already had a join/prefetch specified on it, the requested
2759   # $rel might very well be already included. What we do in this case
2760   # is effectively a no-op (except that we bump up the chain_depth on
2761   # the join in question so we could tell it *is* the search_related)
2762   my $already_joined;
2763
2764   # we consider the last one thus reverse
2765   for my $j (reverse @requested_joins) {
2766     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
2767     if ($rel eq $last_j) {
2768       $j->[0]{-relation_chain_depth}++;
2769       $already_joined++;
2770       last;
2771     }
2772   }
2773
2774   unless ($already_joined) {
2775     push @$from, $source->_resolve_join(
2776       $rel,
2777       $attrs->{alias},
2778       $seen,
2779       $jpath,
2780     );
2781   }
2782
2783   $seen->{-relation_chain_depth}++;
2784
2785   return {%$attrs, from => $from, seen_join => $seen};
2786 }
2787
2788 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2789 sub _resolved_attrs_copy {
2790   my $self = shift;
2791   return { %{$self->_resolved_attrs (@_)} };
2792 }
2793
2794 sub _resolved_attrs {
2795   my $self = shift;
2796   return $self->{_attrs} if $self->{_attrs};
2797
2798   my $attrs  = { %{ $self->{attrs} || {} } };
2799   my $source = $self->result_source;
2800   my $alias  = $attrs->{alias};
2801
2802   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2803   my @colbits;
2804
2805   # build columns (as long as select isn't set) into a set of as/select hashes
2806   unless ( $attrs->{select} ) {
2807
2808     my @cols;
2809     if ( ref $attrs->{columns} eq 'ARRAY' ) {
2810       @cols = @{ delete $attrs->{columns}}
2811     } elsif ( defined $attrs->{columns} ) {
2812       @cols = delete $attrs->{columns}
2813     } else {
2814       @cols = $source->columns
2815     }
2816
2817     for (@cols) {
2818       if ( ref $_ eq 'HASH' ) {
2819         push @colbits, $_
2820       } else {
2821         my $key = /^\Q${alias}.\E(.+)$/
2822           ? "$1"
2823           : "$_";
2824         my $value = /\./
2825           ? "$_"
2826           : "${alias}.$_";
2827         push @colbits, { $key => $value };
2828       }
2829     }
2830   }
2831
2832   # add the additional columns on
2833   foreach (qw{include_columns +columns}) {
2834     if ( $attrs->{$_} ) {
2835       my @list = ( ref($attrs->{$_}) eq 'ARRAY' )
2836         ? @{ delete $attrs->{$_} }
2837         : delete $attrs->{$_};
2838       for (@list) {
2839         if ( ref($_) eq 'HASH' ) {
2840           push @colbits, $_
2841         } else {
2842           my $key = ( split /\./, $_ )[-1];
2843           my $value = ( /\./ ? $_ : "$alias.$_" );
2844           push @colbits, { $key => $value };
2845         }
2846       }
2847     }
2848   }
2849
2850   # start with initial select items
2851   if ( $attrs->{select} ) {
2852     $attrs->{select} =
2853         ( ref $attrs->{select} eq 'ARRAY' )
2854       ? [ @{ $attrs->{select} } ]
2855       : [ $attrs->{select} ];
2856
2857     if ( $attrs->{as} ) {
2858       $attrs->{as} =
2859         (
2860           ref $attrs->{as} eq 'ARRAY'
2861             ? [ @{ $attrs->{as} } ]
2862             : [ $attrs->{as} ]
2863         )
2864     } else {
2865       $attrs->{as} = [ map {
2866          m/^\Q${alias}.\E(.+)$/
2867            ? $1
2868            : $_
2869          } @{ $attrs->{select} }
2870       ]
2871     }
2872   }
2873   else {
2874
2875     # otherwise we intialise select & as to empty
2876     $attrs->{select} = [];
2877     $attrs->{as}     = [];
2878   }
2879
2880   # now add colbits to select/as
2881   push @{ $attrs->{select} }, map values %{$_}, @colbits;
2882   push @{ $attrs->{as}     }, map keys   %{$_}, @colbits;
2883
2884   if ( my $adds = delete $attrs->{'+select'} ) {
2885     $adds = [$adds] unless ref $adds eq 'ARRAY';
2886     push @{ $attrs->{select} },
2887       map { /\./ || ref $_ ? $_ : "$alias.$_" } @$adds;
2888   }
2889   if ( my $adds = delete $attrs->{'+as'} ) {
2890     $adds = [$adds] unless ref $adds eq 'ARRAY';
2891     push @{ $attrs->{as} }, @$adds;
2892   }
2893
2894   $attrs->{from} ||= [{
2895     -source_handle => $source->handle,
2896     -alias => $self->{attrs}{alias},
2897     $self->{attrs}{alias} => $source->from,
2898   }];
2899
2900   if ( $attrs->{join} || $attrs->{prefetch} ) {
2901
2902     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2903       if ref $attrs->{from} ne 'ARRAY';
2904
2905     my $join = delete $attrs->{join} || {};
2906
2907     if ( defined $attrs->{prefetch} ) {
2908       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2909     }
2910
2911     $attrs->{from} =    # have to copy here to avoid corrupting the original
2912       [
2913         @{ $attrs->{from} },
2914         $source->_resolve_join(
2915           $join,
2916           $alias,
2917           { %{ $attrs->{seen_join} || {} } },
2918           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
2919             ? $attrs->{from}[-1][0]{-join_path}
2920             : []
2921           ,
2922         )
2923       ];
2924   }
2925
2926   if ( defined $attrs->{order_by} ) {
2927     $attrs->{order_by} = (
2928       ref( $attrs->{order_by} ) eq 'ARRAY'
2929       ? [ @{ $attrs->{order_by} } ]
2930       : [ $attrs->{order_by} || () ]
2931     );
2932   }
2933
2934   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2935     $attrs->{group_by} = [ $attrs->{group_by} ];
2936   }
2937
2938   # generate the distinct induced group_by early, as prefetch will be carried via a
2939   # subquery (since a group_by is present)
2940   if (delete $attrs->{distinct}) {
2941     if ($attrs->{group_by}) {
2942       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2943     }
2944     else {
2945       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2946
2947       # add any order_by parts that are not already present in the group_by
2948       # we need to be careful not to add any named functions/aggregates
2949       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
2950       my %already_grouped = map { $_ => 1 } (@{$attrs->{group_by}});
2951
2952       my $storage = $self->result_source->schema->storage;
2953
2954       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
2955
2956       for my $chunk ($storage->_parse_order_by($attrs->{order_by})) {
2957         if ($rs_column_list->{$chunk} && not $already_grouped{$chunk}++) {
2958           push @{$attrs->{group_by}}, $chunk;
2959         }
2960       }
2961     }
2962   }
2963
2964   $attrs->{collapse} ||= {};
2965   if ( my $prefetch = delete $attrs->{prefetch} ) {
2966     $prefetch = $self->_merge_attr( {}, $prefetch );
2967
2968     my $prefetch_ordering = [];
2969
2970     # this is a separate structure (we don't look in {from} directly)
2971     # as the resolver needs to shift things off the lists to work
2972     # properly (identical-prefetches on different branches)
2973     my $join_map = {};
2974     if (ref $attrs->{from} eq 'ARRAY') {
2975
2976       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
2977
2978       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
2979         next unless $j->[0]{-alias};
2980         next unless $j->[0]{-join_path};
2981         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
2982
2983         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
2984
2985         my $p = $join_map;
2986         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
2987         push @{$p->{-join_aliases} }, $j->[0]{-alias};
2988       }
2989     }
2990
2991     my @prefetch =
2992       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2993
2994     # we need to somehow mark which columns came from prefetch
2995     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2996
2997     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2998     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2999
3000     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3001     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3002   }
3003
3004   # if both page and offset are specified, produce a combined offset
3005   # even though it doesn't make much sense, this is what pre 081xx has
3006   # been doing
3007   if (my $page = delete $attrs->{page}) {
3008     $attrs->{offset} =
3009       ($attrs->{rows} * ($page - 1))
3010             +
3011       ($attrs->{offset} || 0)
3012     ;
3013   }
3014
3015   return $self->{_attrs} = $attrs;
3016 }
3017
3018 sub _rollout_attr {
3019   my ($self, $attr) = @_;
3020
3021   if (ref $attr eq 'HASH') {
3022     return $self->_rollout_hash($attr);
3023   } elsif (ref $attr eq 'ARRAY') {
3024     return $self->_rollout_array($attr);
3025   } else {
3026     return [$attr];
3027   }
3028 }
3029
3030 sub _rollout_array {
3031   my ($self, $attr) = @_;
3032
3033   my @rolled_array;
3034   foreach my $element (@{$attr}) {
3035     if (ref $element eq 'HASH') {
3036       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3037     } elsif (ref $element eq 'ARRAY') {
3038       #  XXX - should probably recurse here
3039       push( @rolled_array, @{$self->_rollout_array($element)} );
3040     } else {
3041       push( @rolled_array, $element );
3042     }
3043   }
3044   return \@rolled_array;
3045 }
3046
3047 sub _rollout_hash {
3048   my ($self, $attr) = @_;
3049
3050   my @rolled_array;
3051   foreach my $key (keys %{$attr}) {
3052     push( @rolled_array, { $key => $attr->{$key} } );
3053   }
3054   return \@rolled_array;
3055 }
3056
3057 sub _calculate_score {
3058   my ($self, $a, $b) = @_;
3059
3060   if (defined $a xor defined $b) {
3061     return 0;
3062   }
3063   elsif (not defined $a) {
3064     return 1;
3065   }
3066
3067   if (ref $b eq 'HASH') {
3068     my ($b_key) = keys %{$b};
3069     if (ref $a eq 'HASH') {
3070       my ($a_key) = keys %{$a};
3071       if ($a_key eq $b_key) {
3072         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3073       } else {
3074         return 0;
3075       }
3076     } else {
3077       return ($a eq $b_key) ? 1 : 0;
3078     }
3079   } else {
3080     if (ref $a eq 'HASH') {
3081       my ($a_key) = keys %{$a};
3082       return ($b eq $a_key) ? 1 : 0;
3083     } else {
3084       return ($b eq $a) ? 1 : 0;
3085     }
3086   }
3087 }
3088
3089 sub _merge_attr {
3090   my ($self, $orig, $import) = @_;
3091
3092   return $import unless defined($orig);
3093   return $orig unless defined($import);
3094
3095   $orig = $self->_rollout_attr($orig);
3096   $import = $self->_rollout_attr($import);
3097
3098   my $seen_keys;
3099   foreach my $import_element ( @{$import} ) {
3100     # find best candidate from $orig to merge $b_element into
3101     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3102     foreach my $orig_element ( @{$orig} ) {
3103       my $score = $self->_calculate_score( $orig_element, $import_element );
3104       if ($score > $best_candidate->{score}) {
3105         $best_candidate->{position} = $position;
3106         $best_candidate->{score} = $score;
3107       }
3108       $position++;
3109     }
3110     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3111
3112     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3113       push( @{$orig}, $import_element );
3114     } else {
3115       my $orig_best = $orig->[$best_candidate->{position}];
3116       # merge orig_best and b_element together and replace original with merged
3117       if (ref $orig_best ne 'HASH') {
3118         $orig->[$best_candidate->{position}] = $import_element;
3119       } elsif (ref $import_element eq 'HASH') {
3120         my ($key) = keys %{$orig_best};
3121         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3122       }
3123     }
3124     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3125   }
3126
3127   return $orig;
3128 }
3129
3130 sub result_source {
3131     my $self = shift;
3132
3133     if (@_) {
3134         $self->_source_handle($_[0]->handle);
3135     } else {
3136         $self->_source_handle->resolve;
3137     }
3138 }
3139
3140 =head2 throw_exception
3141
3142 See L<DBIx::Class::Schema/throw_exception> for details.
3143
3144 =cut
3145
3146 sub throw_exception {
3147   my $self=shift;
3148
3149   if (ref $self && $self->_source_handle->schema) {
3150     $self->_source_handle->schema->throw_exception(@_)
3151   }
3152   else {
3153     DBIx::Class::Exception->throw(@_);
3154   }
3155 }
3156
3157 # XXX: FIXME: Attributes docs need clearing up
3158
3159 =head1 ATTRIBUTES
3160
3161 Attributes are used to refine a ResultSet in various ways when
3162 searching for data. They can be passed to any method which takes an
3163 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3164 L</count>.
3165
3166 These are in no particular order:
3167
3168 =head2 order_by
3169
3170 =over 4
3171
3172 =item Value: ( $order_by | \@order_by | \%order_by )
3173
3174 =back
3175
3176 Which column(s) to order the results by.
3177
3178 [The full list of suitable values is documented in
3179 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3180 common options.]
3181
3182 If a single column name, or an arrayref of names is supplied, the
3183 argument is passed through directly to SQL. The hashref syntax allows
3184 for connection-agnostic specification of ordering direction:
3185
3186  For descending order:
3187
3188   order_by => { -desc => [qw/col1 col2 col3/] }
3189
3190  For explicit ascending order:
3191
3192   order_by => { -asc => 'col' }
3193
3194 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3195 supported, although you are strongly encouraged to use the hashref
3196 syntax as outlined above.
3197
3198 =head2 columns
3199
3200 =over 4
3201
3202 =item Value: \@columns
3203
3204 =back
3205
3206 Shortcut to request a particular set of columns to be retrieved. Each
3207 column spec may be a string (a table column name), or a hash (in which
3208 case the key is the C<as> value, and the value is used as the C<select>
3209 expression). Adds C<me.> onto the start of any column without a C<.> in
3210 it and sets C<select> from that, then auto-populates C<as> from
3211 C<select> as normal. (You may also use the C<cols> attribute, as in
3212 earlier versions of DBIC.)
3213
3214 =head2 +columns
3215
3216 =over 4
3217
3218 =item Value: \@columns
3219
3220 =back
3221
3222 Indicates additional columns to be selected from storage. Works the same
3223 as L</columns> but adds columns to the selection. (You may also use the
3224 C<include_columns> attribute, as in earlier versions of DBIC). For
3225 example:-
3226
3227   $schema->resultset('CD')->search(undef, {
3228     '+columns' => ['artist.name'],
3229     join => ['artist']
3230   });
3231
3232 would return all CDs and include a 'name' column to the information
3233 passed to object inflation. Note that the 'artist' is the name of the
3234 column (or relationship) accessor, and 'name' is the name of the column
3235 accessor in the related table.
3236
3237 =head2 include_columns
3238
3239 =over 4
3240
3241 =item Value: \@columns
3242
3243 =back
3244
3245 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3246
3247 =head2 select
3248
3249 =over 4
3250
3251 =item Value: \@select_columns
3252
3253 =back
3254
3255 Indicates which columns should be selected from the storage. You can use
3256 column names, or in the case of RDBMS back ends, function or stored procedure
3257 names:
3258
3259   $rs = $schema->resultset('Employee')->search(undef, {
3260     select => [
3261       'name',
3262       { count => 'employeeid' },
3263       { max => { length => 'name' }, -as => 'longest_name' }
3264     ]
3265   });
3266
3267   # Equivalent SQL
3268   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3269
3270 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3271 use L</select>, to instruct DBIx::Class how to store the result of the column.
3272 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3273 identifier aliasing. You can however alias a function, so you can use it in
3274 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3275 attribute> supplied as shown in the example above.
3276
3277 =head2 +select
3278
3279 =over 4
3280
3281 Indicates additional columns to be selected from storage.  Works the same as
3282 L</select> but adds columns to the default selection, instead of specifying
3283 an explicit list.
3284
3285 =back
3286
3287 =head2 +as
3288
3289 =over 4
3290
3291 Indicates additional column names for those added via L</+select>. See L</as>.
3292
3293 =back
3294
3295 =head2 as
3296
3297 =over 4
3298
3299 =item Value: \@inflation_names
3300
3301 =back
3302
3303 Indicates column names for object inflation. That is L</as> indicates the
3304 slot name in which the column value will be stored within the
3305 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3306 identifier by the C<get_column> method (or via the object accessor B<if one
3307 with the same name already exists>) as shown below. The L</as> attribute has
3308 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3309
3310   $rs = $schema->resultset('Employee')->search(undef, {
3311     select => [
3312       'name',
3313       { count => 'employeeid' },
3314       { max => { length => 'name' }, -as => 'longest_name' }
3315     ],
3316     as => [qw/
3317       name
3318       employee_count
3319       max_name_length
3320     /],
3321   });
3322
3323 If the object against which the search is performed already has an accessor
3324 matching a column name specified in C<as>, the value can be retrieved using
3325 the accessor as normal:
3326
3327   my $name = $employee->name();
3328
3329 If on the other hand an accessor does not exist in the object, you need to
3330 use C<get_column> instead:
3331
3332   my $employee_count = $employee->get_column('employee_count');
3333
3334 You can create your own accessors if required - see
3335 L<DBIx::Class::Manual::Cookbook> for details.
3336
3337 =head2 join
3338
3339 =over 4
3340
3341 =item Value: ($rel_name | \@rel_names | \%rel_names)
3342
3343 =back
3344
3345 Contains a list of relationships that should be joined for this query.  For
3346 example:
3347
3348   # Get CDs by Nine Inch Nails
3349   my $rs = $schema->resultset('CD')->search(
3350     { 'artist.name' => 'Nine Inch Nails' },
3351     { join => 'artist' }
3352   );
3353
3354 Can also contain a hash reference to refer to the other relation's relations.
3355 For example:
3356
3357   package MyApp::Schema::Track;
3358   use base qw/DBIx::Class/;
3359   __PACKAGE__->table('track');
3360   __PACKAGE__->add_columns(qw/trackid cd position title/);
3361   __PACKAGE__->set_primary_key('trackid');
3362   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3363   1;
3364
3365   # In your application
3366   my $rs = $schema->resultset('Artist')->search(
3367     { 'track.title' => 'Teardrop' },
3368     {
3369       join     => { cd => 'track' },
3370       order_by => 'artist.name',
3371     }
3372   );
3373
3374 You need to use the relationship (not the table) name in  conditions,
3375 because they are aliased as such. The current table is aliased as "me", so
3376 you need to use me.column_name in order to avoid ambiguity. For example:
3377
3378   # Get CDs from 1984 with a 'Foo' track
3379   my $rs = $schema->resultset('CD')->search(
3380     {
3381       'me.year' => 1984,
3382       'tracks.name' => 'Foo'
3383     },
3384     { join => 'tracks' }
3385   );
3386
3387 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3388 similarly for a third time). For e.g.
3389
3390   my $rs = $schema->resultset('Artist')->search({
3391     'cds.title'   => 'Down to Earth',
3392     'cds_2.title' => 'Popular',
3393   }, {
3394     join => [ qw/cds cds/ ],
3395   });
3396
3397 will return a set of all artists that have both a cd with title 'Down
3398 to Earth' and a cd with title 'Popular'.
3399
3400 If you want to fetch related objects from other tables as well, see C<prefetch>
3401 below.
3402
3403 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3404
3405 =head2 prefetch
3406
3407 =over 4
3408
3409 =item Value: ($rel_name | \@rel_names | \%rel_names)
3410
3411 =back
3412
3413 Contains one or more relationships that should be fetched along with
3414 the main query (when they are accessed afterwards the data will
3415 already be available, without extra queries to the database).  This is
3416 useful for when you know you will need the related objects, because it
3417 saves at least one query:
3418
3419   my $rs = $schema->resultset('Tag')->search(
3420     undef,
3421     {
3422       prefetch => {
3423         cd => 'artist'
3424       }
3425     }
3426   );
3427
3428 The initial search results in SQL like the following:
3429
3430   SELECT tag.*, cd.*, artist.* FROM tag
3431   JOIN cd ON tag.cd = cd.cdid
3432   JOIN artist ON cd.artist = artist.artistid
3433
3434 L<DBIx::Class> has no need to go back to the database when we access the
3435 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3436 case.
3437
3438 Simple prefetches will be joined automatically, so there is no need
3439 for a C<join> attribute in the above search.
3440
3441 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3442 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3443 with an accessor type of 'single' or 'filter'). A more complex example that
3444 prefetches an artists cds, the tracks on those cds, and the tags associated
3445 with that artist is given below (assuming many-to-many from artists to tags):
3446
3447  my $rs = $schema->resultset('Artist')->search(
3448    undef,
3449    {
3450      prefetch => [
3451        { cds => 'tracks' },
3452        { artist_tags => 'tags' }
3453      ]
3454    }
3455  );
3456
3457
3458 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3459 attributes will be ignored.
3460
3461 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3462 exactly as you might expect.
3463
3464 =over 4
3465
3466 =item *
3467
3468 Prefetch uses the L</cache> to populate the prefetched relationships. This
3469 may or may not be what you want.
3470
3471 =item *
3472
3473 If you specify a condition on a prefetched relationship, ONLY those
3474 rows that match the prefetched condition will be fetched into that relationship.
3475 This means that adding prefetch to a search() B<may alter> what is returned by
3476 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3477
3478   my $artist_rs = $schema->resultset('Artist')->search({
3479       'cds.year' => 2008,
3480   }, {
3481       join => 'cds',
3482   });
3483
3484   my $count = $artist_rs->first->cds->count;
3485
3486   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3487
3488   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3489
3490   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3491
3492 that cmp_ok() may or may not pass depending on the datasets involved. This
3493 behavior may or may not survive the 0.09 transition.
3494
3495 =back
3496
3497 =head2 page
3498
3499 =over 4
3500
3501 =item Value: $page
3502
3503 =back
3504
3505 Makes the resultset paged and specifies the page to retrieve. Effectively
3506 identical to creating a non-pages resultset and then calling ->page($page)
3507 on it.
3508
3509 If L<rows> attribute is not specified it defaults to 10 rows per page.
3510
3511 When you have a paged resultset, L</count> will only return the number
3512 of rows in the page. To get the total, use the L</pager> and call
3513 C<total_entries> on it.
3514
3515 =head2 rows
3516
3517 =over 4
3518
3519 =item Value: $rows
3520
3521 =back
3522
3523 Specifies the maximum number of rows for direct retrieval or the number of
3524 rows per page if the page attribute or method is used.
3525
3526 =head2 offset
3527
3528 =over 4
3529
3530 =item Value: $offset
3531
3532 =back
3533
3534 Specifies the (zero-based) row number for the  first row to be returned, or the
3535 of the first row of the first page if paging is used.
3536
3537 =head2 group_by
3538
3539 =over 4
3540
3541 =item Value: \@columns
3542
3543 =back
3544
3545 A arrayref of columns to group by. Can include columns of joined tables.
3546
3547   group_by => [qw/ column1 column2 ... /]
3548
3549 =head2 having
3550
3551 =over 4
3552
3553 =item Value: $condition
3554
3555 =back
3556
3557 HAVING is a select statement attribute that is applied between GROUP BY and
3558 ORDER BY. It is applied to the after the grouping calculations have been
3559 done.
3560
3561   having => { 'count(employee)' => { '>=', 100 } }
3562
3563 =head2 distinct
3564
3565 =over 4
3566
3567 =item Value: (0 | 1)
3568
3569 =back
3570
3571 Set to 1 to group by all columns. If the resultset already has a group_by
3572 attribute, this setting is ignored and an appropriate warning is issued.
3573
3574 =head2 where
3575
3576 =over 4
3577
3578 Adds to the WHERE clause.
3579
3580   # only return rows WHERE deleted IS NULL for all searches
3581   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3582
3583 Can be overridden by passing C<< { where => undef } >> as an attribute
3584 to a resultset.
3585
3586 =back
3587
3588 =head2 cache
3589
3590 Set to 1 to cache search results. This prevents extra SQL queries if you
3591 revisit rows in your ResultSet:
3592
3593   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3594
3595   while( my $artist = $resultset->next ) {
3596     ... do stuff ...
3597   }
3598
3599   $rs->first; # without cache, this would issue a query
3600
3601 By default, searches are not cached.
3602
3603 For more examples of using these attributes, see
3604 L<DBIx::Class::Manual::Cookbook>.
3605
3606 =head2 for
3607
3608 =over 4
3609
3610 =item Value: ( 'update' | 'shared' )
3611
3612 =back
3613
3614 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3615 ... FOR SHARED.
3616
3617 =cut
3618
3619 1;