lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs   = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: $source, \%$attrs
 195
 196 =item Return Value: $rs
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you won't need to construct a resultset manually.  You'll
 206 automatically get one from e.g. a L</search> called in scalar context:
 207
 208   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 209
 210 IMPORTANT: If called on an object, proxies to new_result instead so
 211
 212   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 213
 214 will return a CD object, not a ResultSet.
 215
 216 =cut
 217
 218 sub new {
 219   my $class = shift;
 220   return $class->new_result(@_) if ref $class;
 221
 222   my ($source, $attrs) = @_;
 223   $source = $source->resolve
 224     if $source->isa('DBIx::Class::ResultSourceHandle');
 225   $attrs = { %{$attrs||{}} };
 226
 227   if ($attrs->{page}) {
 228     $attrs->{rows} ||= 10;
 229   }
 230
 231   $attrs->{alias} ||= 'me';
 232
 233   my $self = bless {
 234     result_source => $source,
 235     cond => $attrs->{where},
 236     pager => undef,
 237     attrs => $attrs,
 238   }, $class;
 239
 240   # if there is a dark selector, this means we are already in a
 241   # chain and the cleanup/sanification was taken care of by
 242   # _search_rs already
 243   $self->_normalize_selection($attrs)
 244     unless $attrs->{_dark_selector};
 245
 246   $self->result_class(
 247     $attrs->{result_class} || $source->result_class
 248   );
 249
 250   $self;
 251 }
 252
 253 =head2 search
 254
 255 =over 4
 256
 257 =item Arguments: $cond, \%attrs?
 258
 259 =item Return Value: $resultset (scalar context) ||  @row_objs (list context)
 260
 261 =back
 262
 263   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 264   my $new_rs = $cd_rs->search({ year => 2005 });
 265
 266   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 267                  # year = 2005 OR year = 2004
 268
 269 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 270 returning a list of row objects instead. To avoid that, use L</search_rs>.
 271
 272 If you need to pass in additional attributes but no additional condition,
 273 call it as C<search(undef, \%attrs)>.
 274
 275   # "SELECT name, artistid FROM $artist_table"
 276   my @all_artists = $schema->resultset('Artist')->search(undef, {
 277     columns => [qw/name artistid/],
 278   });
 279
 280 For a list of attributes that can be passed to C<search>, see
 281 L</ATTRIBUTES>. For more examples of using this function, see
 282 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 283 documentation for the first argument, see L<SQL::Abstract>
 284 and its extension L<DBIx::Class::SQLMaker>.
 285
 286 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 287
 288 =head3 CAVEAT
 289
 290 Note that L</search> does not process/deflate any of the values passed in the
 291 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 292 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 293 manually that any value passed to this method will stringify to something the
 294 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 295 objects, for more info see:
 296 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 297
 298 =cut
 299
 300 sub search {
 301   my $self = shift;
 302   my $rs = $self->search_rs( @_ );
 303
 304   if (wantarray) {
 305     return $rs->all;
 306   }
 307   elsif (defined wantarray) {
 308     return $rs;
 309   }
 310   else {
 311     # we can be called by a relationship helper, which in
 312     # turn may be called in void context due to some braindead
 313     # overload or whatever else the user decided to be clever
 314     # at this particular day. Thus limit the exception to
 315     # external code calls only
 316     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 317       if (caller)[0] !~ /^\QDBIx::Class::/;
 318
 319     return ();
 320   }
 321 }
 322
 323 =head2 search_rs
 324
 325 =over 4
 326
 327 =item Arguments: $cond, \%attrs?
 328
 329 =item Return Value: $resultset
 330
 331 =back
 332
 333 This method does the same exact thing as search() except it will
 334 always return a resultset, even in list context.
 335
 336 =cut
 337
 338 sub search_rs {
 339   my $self = shift;
 340
 341   # Special-case handling for (undef, undef).
 342   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 343     @_ = ();
 344   }
 345
 346   my $call_attrs = {};
 347   if (@_ > 1) {
 348     if (ref $_[-1] eq 'HASH') {
 349       # copy for _normalize_selection
 350       $call_attrs = { %{ pop @_ } };
 351     }
 352     elsif (! defined $_[-1] ) {
 353       pop @_;   # search({}, undef)
 354     }
 355   }
 356
 357   # see if we can keep the cache (no $rs changes)
 358   my $cache;
 359   my %safe = (alias => 1, cache => 1);
 360   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 361     ! defined $_[0]
 362       or
 363     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 364       or
 365     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 366   )) {
 367     $cache = $self->get_cache;
 368   }
 369
 370   my $rsrc = $self->result_source;
 371
 372   my $old_attrs = { %{$self->{attrs}} };
 373   my $old_having = delete $old_attrs->{having};
 374   my $old_where = delete $old_attrs->{where};
 375
 376   my $new_attrs = { %$old_attrs };
 377
 378   # take care of call attrs (only if anything is changing)
 379   if (keys %$call_attrs) {
 380
 381     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 382
 383     # reset the current selector list if new selectors are supplied
 384     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 385       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 386     }
 387
 388     # Normalize the new selector list (operates on the passed-in attr structure)
 389     # Need to do it on every chain instead of only once on _resolved_attrs, in
 390     # order to allow detection of empty vs partial 'as'
 391     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 392       if $old_attrs->{_dark_selector};
 393     $self->_normalize_selection ($call_attrs);
 394
 395     # start with blind overwriting merge, exclude selector attrs
 396     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 397     delete @{$new_attrs}{@selector_attrs};
 398
 399     for (@selector_attrs) {
 400       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 401         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 402     }
 403
 404     # older deprecated name, use only if {columns} is not there
 405     if (my $c = delete $new_attrs->{cols}) {
 406       if ($new_attrs->{columns}) {
 407         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 408       }
 409       else {
 410         $new_attrs->{columns} = $c;
 411       }
 412     }
 413
 414
 415     # join/prefetch use their own crazy merging heuristics
 416     foreach my $key (qw/join prefetch/) {
 417       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 418         if exists $call_attrs->{$key};
 419     }
 420
 421     # stack binds together
 422     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 423   }
 424
 425
 426   # rip apart the rest of @_, parse a condition
 427   my $call_cond = do {
 428
 429     if (ref $_[0] eq 'HASH') {
 430       (keys %{$_[0]}) ? $_[0] : undef
 431     }
 432     elsif (@_ == 1) {
 433       $_[0]
 434     }
 435     elsif (@_ % 2) {
 436       $self->throw_exception('Odd number of arguments to search')
 437     }
 438     else {
 439       +{ @_ }
 440     }
 441
 442   } if @_;
 443
 444   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 445     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead';
 446   }
 447
 448   for ($old_where, $call_cond) {
 449     if (defined $_) {
 450       $new_attrs->{where} = $self->_stack_cond (
 451         $_, $new_attrs->{where}
 452       );
 453     }
 454   }
 455
 456   if (defined $old_having) {
 457     $new_attrs->{having} = $self->_stack_cond (
 458       $old_having, $new_attrs->{having}
 459     )
 460   }
 461
 462   my $rs = (ref $self)->new($rsrc, $new_attrs);
 463
 464   $rs->set_cache($cache) if ($cache);
 465
 466   return $rs;
 467 }
 468
 469 my $dark_sel_dumper;
 470 sub _normalize_selection {
 471   my ($self, $attrs) = @_;
 472
 473   # legacy syntax
 474   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 475     if exists $attrs->{include_columns};
 476
 477   # columns are always placed first, however
 478
 479   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 480   # delay the decision on whether to use a default select list ($rsrc->columns)
 481   # allowing stuff like the remove_columns helper to work
 482   #
 483   # select/as +select/+as pairs need special handling - the amount of select/as
 484   # elements in each pair does *not* have to be equal (think multicolumn
 485   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 486   # supplied at all) - try to infer the alias, either from the -as parameter
 487   # of the selector spec, or use the parameter whole if it looks like a column
 488   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 489   # is ok as well), but make sure no more additions to the 'as' chain take place
 490   for my $pref ('', '+') {
 491
 492     my ($sel, $as) = map {
 493       my $key = "${pref}${_}";
 494
 495       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 496         ? @{$attrs->{$key}}
 497         : $attrs->{$key} || ()
 498       ];
 499       delete $attrs->{$key};
 500       $val;
 501     } qw/select as/;
 502
 503     if (! @$as and ! @$sel ) {
 504       next;
 505     }
 506     elsif (@$as and ! @$sel) {
 507       $self->throw_exception(
 508         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 509       );
 510     }
 511     elsif( ! @$as ) {
 512       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 513       # if any @$as has been supplied we assume the user knows what (s)he is doing
 514       # and blindly keep stacking up pieces
 515       unless ($attrs->{_dark_selector}) {
 516         SELECTOR:
 517         for (@$sel) {
 518           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 519             push @$as, $_->{-as};
 520           }
 521           # assume any plain no-space, no-parenthesis string to be a column spec
 522           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 523           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 524             push @$as, $_;
 525           }
 526           # if all else fails - raise a flag that no more aliasing will be allowed
 527           else {
 528             $attrs->{_dark_selector} = {
 529               plus_stage => $pref,
 530               string => ($dark_sel_dumper ||= do {
 531                   require Data::Dumper::Concise;
 532                   Data::Dumper::Concise::DumperObject()->Indent(0);
 533                 })->Values([$_])->Dump
 534               ,
 535             };
 536             last SELECTOR;
 537           }
 538         }
 539       }
 540     }
 541     elsif (@$as < @$sel) {
 542       $self->throw_exception(
 543         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 544       );
 545     }
 546     elsif ($pref and $attrs->{_dark_selector}) {
 547       $self->throw_exception(
 548         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 549       );
 550     }
 551
 552
 553     # merge result
 554     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 555     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 556   }
 557 }
 558
 559 sub _stack_cond {
 560   my ($self, $left, $right) = @_;
 561
 562   # collapse single element top-level conditions
 563   # (single pass only, unlikely to need recursion)
 564   for ($left, $right) {
 565     if (ref $_ eq 'ARRAY') {
 566       if (@$_ == 0) {
 567         $_ = undef;
 568       }
 569       elsif (@$_ == 1) {
 570         $_ = $_->[0];
 571       }
 572     }
 573     elsif (ref $_ eq 'HASH') {
 574       my ($first, $more) = keys %$_;
 575
 576       # empty hash
 577       if (! defined $first) {
 578         $_ = undef;
 579       }
 580       # one element hash
 581       elsif (! defined $more) {
 582         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 583           $_ = $_->{'-and'};
 584         }
 585         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 586           $_ = $_->{'-or'};
 587         }
 588       }
 589     }
 590   }
 591
 592   # merge hashes with weeding out of duplicates (simple cases only)
 593   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 594
 595     # shallow copy to destroy
 596     $right = { %$right };
 597     for (grep { exists $right->{$_} } keys %$left) {
 598       # the use of eq_deeply here is justified - the rhs of an
 599       # expression can contain a lot of twisted weird stuff
 600       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 601     }
 602
 603     $right = undef unless keys %$right;
 604   }
 605
 606
 607   if (defined $left xor defined $right) {
 608     return defined $left ? $left : $right;
 609   }
 610   elsif (! defined $left) {
 611     return undef;
 612   }
 613   else {
 614     return { -and => [ $left, $right ] };
 615   }
 616 }
 617
 618 =head2 search_literal
 619
 620 =over 4
 621
 622 =item Arguments: $sql_fragment, @bind_values
 623
 624 =item Return Value: $resultset (scalar context) || @row_objs (list context)
 625
 626 =back
 627
 628   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 629   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 630
 631 Pass a literal chunk of SQL to be added to the conditional part of the
 632 resultset query.
 633
 634 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 635 only be used in that context. C<search_literal> is a convenience method.
 636 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 637 columns are bound correctly, use C<search>.
 638
 639 Example of how to use C<search> instead of C<search_literal>
 640
 641   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 642   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 643
 644
 645 See L<DBIx::Class::Manual::Cookbook/Searching> and
 646 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 647 require C<search_literal>.
 648
 649 =cut
 650
 651 sub search_literal {
 652   my ($self, $sql, @bind) = @_;
 653   my $attr;
 654   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 655     $attr = pop @bind;
 656   }
 657   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 658 }
 659
 660 =head2 find
 661
 662 =over 4
 663
 664 =item Arguments: \%columns_values | @pk_values, \%attrs?
 665
 666 =item Return Value: $row_object | undef
 667
 668 =back
 669
 670 Finds and returns a single row based on supplied criteria. Takes either a
 671 hashref with the same format as L</create> (including inference of foreign
 672 keys from related objects), or a list of primary key values in the same
 673 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 674 declaration on the L</result_source>.
 675
 676 In either case an attempt is made to combine conditions already existing on
 677 the resultset with the condition passed to this method.
 678
 679 To aid with preparing the correct query for the storage you may supply the
 680 C<key> attribute, which is the name of a
 681 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 682 unique constraint corresponding to the
 683 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 684 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 685 to construct a query that satisfies the named unique constraint fully (
 686 non-NULL values for each column member of the constraint) an exception is
 687 thrown.
 688
 689 If no C<key> is specified, the search is carried over all unique constraints
 690 which are fully defined by the available condition.
 691
 692 If no such constraint is found, C<find> currently defaults to a simple
 693 C<< search->(\%column_values) >> which may or may not do what you expect.
 694 Note that this fallback behavior may be deprecated in further versions. If
 695 you need to search with arbitrary conditions - use L</search>. If the query
 696 resulting from this fallback produces more than one row, a warning to the
 697 effect is issued, though only the first row is constructed and returned as
 698 C<$row_object>.
 699
 700 In addition to C<key>, L</find> recognizes and applies standard
 701 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 702
 703 Note that if you have extra concerns about the correctness of the resulting
 704 query you need to specify the C<key> attribute and supply the entire condition
 705 as an argument to find (since it is not always possible to perform the
 706 combination of the resultset condition with the supplied one, especially if
 707 the resultset condition contains literal sql).
 708
 709 For example, to find a row by its primary key:
 710
 711   my $cd = $schema->resultset('CD')->find(5);
 712
 713 You can also find a row by a specific unique constraint:
 714
 715   my $cd = $schema->resultset('CD')->find(
 716     {
 717       artist => 'Massive Attack',
 718       title  => 'Mezzanine',
 719     },
 720     { key => 'cd_artist_title' }
 721   );
 722
 723 See also L</find_or_create> and L</update_or_create>.
 724
 725 =cut
 726
 727 sub find {
 728   my $self = shift;
 729   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 730
 731   my $rsrc = $self->result_source;
 732
 733   my $constraint_name;
 734   if (exists $attrs->{key}) {
 735     $constraint_name = defined $attrs->{key}
 736       ? $attrs->{key}
 737       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 738     ;
 739   }
 740
 741   # Parse out the condition from input
 742   my $call_cond;
 743
 744   if (ref $_[0] eq 'HASH') {
 745     $call_cond = { %{$_[0]} };
 746   }
 747   else {
 748     # if only values are supplied we need to default to 'primary'
 749     $constraint_name = 'primary' unless defined $constraint_name;
 750
 751     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 752
 753     $self->throw_exception(
 754       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 755     ) unless @c_cols;
 756
 757     $self->throw_exception (
 758       'find() expects either a column/value hashref, or a list of values '
 759     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 760     ) unless @c_cols == @_;
 761
 762     $call_cond = {};
 763     @{$call_cond}{@c_cols} = @_;
 764   }
 765
 766   my %related;
 767   for my $key (keys %$call_cond) {
 768     if (
 769       my $keyref = ref($call_cond->{$key})
 770         and
 771       my $relinfo = $rsrc->relationship_info($key)
 772     ) {
 773       my $val = delete $call_cond->{$key};
 774
 775       next if $keyref eq 'ARRAY'; # has_many for multi_create
 776
 777       my $rel_q = $rsrc->_resolve_condition(
 778         $relinfo->{cond}, $val, $key, $key
 779       );
 780       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 781       @related{keys %$rel_q} = values %$rel_q;
 782     }
 783   }
 784
 785   # relationship conditions take precedence (?)
 786   @{$call_cond}{keys %related} = values %related;
 787
 788   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 789   my $final_cond;
 790   if (defined $constraint_name) {
 791     $final_cond = $self->_qualify_cond_columns (
 792
 793       $self->_build_unique_cond (
 794         $constraint_name,
 795         $call_cond,
 796       ),
 797
 798       $alias,
 799     );
 800   }
 801   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 802     # This means that we got here after a merger of relationship conditions
 803     # in ::Relationship::Base::search_related (the row method), and furthermore
 804     # the relationship is of the 'single' type. This means that the condition
 805     # provided by the relationship (already attached to $self) is sufficient,
 806     # as there can be only one row in the database that would satisfy the
 807     # relationship
 808   }
 809   else {
 810     # no key was specified - fall down to heuristics mode:
 811     # run through all unique queries registered on the resultset, and
 812     # 'OR' all qualifying queries together
 813     my (@unique_queries, %seen_column_combinations);
 814     for my $c_name ($rsrc->unique_constraint_names) {
 815       next if $seen_column_combinations{
 816         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 817       }++;
 818
 819       push @unique_queries, try {
 820         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 821       } || ();
 822     }
 823
 824     $final_cond = @unique_queries
 825       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 826       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 827     ;
 828   }
 829
 830   # Run the query, passing the result_class since it should propagate for find
 831   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 832   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 833     my $row = $rs->next;
 834     carp "Query returned more than one row" if $rs->next;
 835     return $row;
 836   }
 837   else {
 838     return $rs->single;
 839   }
 840 }
 841
 842 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 843 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 844 #
 845 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 846 # condition. It is provided for overrides until a saner way forward is devised
 847 #
 848 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 849 # the road. Please adjust your tests accordingly to catch this situation early
 850 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 851 #
 852 # The method will not be removed without an adequately complete replacement
 853 # for strict-mode enforcement
 854 sub _non_unique_find_fallback {
 855   my ($self, $cond, $attrs) = @_;
 856
 857   return $self->_qualify_cond_columns(
 858     $cond,
 859     exists $attrs->{alias}
 860       ? $attrs->{alias}
 861       : $self->{attrs}{alias}
 862   );
 863 }
 864
 865
 866 sub _qualify_cond_columns {
 867   my ($self, $cond, $alias) = @_;
 868
 869   my %aliased = %$cond;
 870   for (keys %aliased) {
 871     $aliased{"$alias.$_"} = delete $aliased{$_}
 872       if $_ !~ /\./;
 873   }
 874
 875   return \%aliased;
 876 }
 877
 878 sub _build_unique_cond {
 879   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 880
 881   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 882
 883   # combination may fail if $self->{cond} is non-trivial
 884   my ($final_cond) = try {
 885     $self->_merge_with_rscond ($extra_cond)
 886   } catch {
 887     +{ %$extra_cond }
 888   };
 889
 890   # trim out everything not in $columns
 891   $final_cond = { map {
 892     exists $final_cond->{$_}
 893       ? ( $_ => $final_cond->{$_} )
 894       : ()
 895   } @c_cols };
 896
 897   if (my @missing = grep
 898     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 899     (@c_cols)
 900   ) {
 901     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 902       $constraint_name,
 903       join (', ', map { "'$_'" } @missing),
 904     ) );
 905   }
 906
 907   if (
 908     !$croak_on_null
 909       and
 910     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 911       and
 912     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 913   ) {
 914     carp_unique ( sprintf (
 915       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 916     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 917     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 918       $constraint_name,
 919       join (', ', map { "'$_'" } @undefs),
 920     ));
 921   }
 922
 923   return $final_cond;
 924 }
 925
 926 =head2 search_related
 927
 928 =over 4
 929
 930 =item Arguments: $rel, $cond, \%attrs?
 931
 932 =item Return Value: $new_resultset (scalar context) || @row_objs (list context)
 933
 934 =back
 935
 936   $new_rs = $cd_rs->search_related('artist', {
 937     name => 'Emo-R-Us',
 938   });
 939
 940 Searches the specified relationship, optionally specifying a condition and
 941 attributes for matching records. See L</ATTRIBUTES> for more information.
 942
 943 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 944 returning a list of row objects instead. To avoid that, use L</search_related_rs>.
 945
 946 See also L</search_related_rs>.
 947
 948 =cut
 949
 950 sub search_related {
 951   return shift->related_resultset(shift)->search(@_);
 952 }
 953
 954 =head2 search_related_rs
 955
 956 This method works exactly the same as search_related, except that
 957 it guarantees a resultset, even in list context.
 958
 959 =cut
 960
 961 sub search_related_rs {
 962   return shift->related_resultset(shift)->search_rs(@_);
 963 }
 964
 965 =head2 cursor
 966
 967 =over 4
 968
 969 =item Arguments: none
 970
 971 =item Return Value: $cursor
 972
 973 =back
 974
 975 Returns a storage-driven cursor to the given resultset. See
 976 L<DBIx::Class::Cursor> for more information.
 977
 978 =cut
 979
 980 sub cursor {
 981   my ($self) = @_;
 982
 983   my $attrs = $self->_resolved_attrs_copy;
 984
 985   return $self->{cursor}
 986     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 987           $attrs->{where},$attrs);
 988 }
 989
 990 =head2 single
 991
 992 =over 4
 993
 994 =item Arguments: $cond?
 995
 996 =item Return Value: $row_object | undef
 997
 998 =back
 999
1000   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1001
1002 Inflates the first result without creating a cursor if the resultset has
1003 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1004 of L</search>.
1005
1006 While this method can take an optional search condition (just like L</search>)
1007 being a fast-code-path it does not recognize search attributes. If you need to
1008 add extra joins or similar, call L</search> and then chain-call L</single> on the
1009 L<DBIx::Class::ResultSet> returned.
1010
1011 =over
1012
1013 =item B<Note>
1014
1015 As of 0.08100, this method enforces the assumption that the preceding
1016 query returns only one row. If more than one row is returned, you will receive
1017 a warning:
1018
1019   Query returned more than one row
1020
1021 In this case, you should be using L</next> or L</find> instead, or if you really
1022 know what you are doing, use the L</rows> attribute to explicitly limit the size
1023 of the resultset.
1024
1025 This method will also throw an exception if it is called on a resultset prefetching
1026 has_many, as such a prefetch implies fetching multiple rows from the database in
1027 order to assemble the resulting object.
1028
1029 =back
1030
1031 =cut
1032
1033 sub single {
1034   my ($self, $where) = @_;
1035   if(@_ > 2) {
1036       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1037   }
1038
1039   my $attrs = $self->_resolved_attrs_copy;
1040
1041   if (keys %{$attrs->{collapse}}) {
1042     $self->throw_exception(
1043       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1044     );
1045   }
1046
1047   if ($where) {
1048     if (defined $attrs->{where}) {
1049       $attrs->{where} = {
1050         '-and' =>
1051             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1052                $where, delete $attrs->{where} ]
1053       };
1054     } else {
1055       $attrs->{where} = $where;
1056     }
1057   }
1058
1059   my @data = $self->result_source->storage->select_single(
1060     $attrs->{from}, $attrs->{select},
1061     $attrs->{where}, $attrs
1062   );
1063
1064   return (@data ? ($self->_construct_object(@data))[0] : undef);
1065 }
1066
1067
1068 # _collapse_query
1069 #
1070 # Recursively collapse the query, accumulating values for each column.
1071
1072 sub _collapse_query {
1073   my ($self, $query, $collapsed) = @_;
1074
1075   $collapsed ||= {};
1076
1077   if (ref $query eq 'ARRAY') {
1078     foreach my $subquery (@$query) {
1079       next unless ref $subquery;  # -or
1080       $collapsed = $self->_collapse_query($subquery, $collapsed);
1081     }
1082   }
1083   elsif (ref $query eq 'HASH') {
1084     if (keys %$query and (keys %$query)[0] eq '-and') {
1085       foreach my $subquery (@{$query->{-and}}) {
1086         $collapsed = $self->_collapse_query($subquery, $collapsed);
1087       }
1088     }
1089     else {
1090       foreach my $col (keys %$query) {
1091         my $value = $query->{$col};
1092         $collapsed->{$col}{$value}++;
1093       }
1094     }
1095   }
1096
1097   return $collapsed;
1098 }
1099
1100 =head2 get_column
1101
1102 =over 4
1103
1104 =item Arguments: $cond?
1105
1106 =item Return Value: $resultsetcolumn
1107
1108 =back
1109
1110   my $max_length = $rs->get_column('length')->max;
1111
1112 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1113
1114 =cut
1115
1116 sub get_column {
1117   my ($self, $column) = @_;
1118   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1119   return $new;
1120 }
1121
1122 =head2 search_like
1123
1124 =over 4
1125
1126 =item Arguments: $cond, \%attrs?
1127
1128 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1129
1130 =back
1131
1132   # WHERE title LIKE '%blue%'
1133   $cd_rs = $rs->search_like({ title => '%blue%'});
1134
1135 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1136 that this is simply a convenience method retained for ex Class::DBI users.
1137 You most likely want to use L</search> with specific operators.
1138
1139 For more information, see L<DBIx::Class::Manual::Cookbook>.
1140
1141 This method is deprecated and will be removed in 0.09. Use L</search()>
1142 instead. An example conversion is:
1143
1144   ->search_like({ foo => 'bar' });
1145
1146   # Becomes
1147
1148   ->search({ foo => { like => 'bar' } });
1149
1150 =cut
1151
1152 sub search_like {
1153   my $class = shift;
1154   carp_unique (
1155     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1156    .' Instead use ->search({ x => { -like => "y%" } })'
1157    .' (note the outer pair of {}s - they are important!)'
1158   );
1159   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1160   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1161   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1162   return $class->search($query, { %$attrs });
1163 }
1164
1165 =head2 slice
1166
1167 =over 4
1168
1169 =item Arguments: $first, $last
1170
1171 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1172
1173 =back
1174
1175 Returns a resultset or object list representing a subset of elements from the
1176 resultset slice is called on. Indexes are from 0, i.e., to get the first
1177 three records, call:
1178
1179   my ($one, $two, $three) = $rs->slice(0, 2);
1180
1181 =cut
1182
1183 sub slice {
1184   my ($self, $min, $max) = @_;
1185   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1186   $attrs->{offset} = $self->{attrs}{offset} || 0;
1187   $attrs->{offset} += $min;
1188   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1189   return $self->search(undef, $attrs);
1190   #my $slice = (ref $self)->new($self->result_source, $attrs);
1191   #return (wantarray ? $slice->all : $slice);
1192 }
1193
1194 =head2 next
1195
1196 =over 4
1197
1198 =item Arguments: none
1199
1200 =item Return Value: $result | undef
1201
1202 =back
1203
1204 Returns the next element in the resultset (C<undef> is there is none).
1205
1206 Can be used to efficiently iterate over records in the resultset:
1207
1208   my $rs = $schema->resultset('CD')->search;
1209   while (my $cd = $rs->next) {
1210     print $cd->title;
1211   }
1212
1213 Note that you need to store the resultset object, and call C<next> on it.
1214 Calling C<< resultset('Table')->next >> repeatedly will always return the
1215 first record from the resultset.
1216
1217 =cut
1218
1219 sub next {
1220   my ($self) = @_;
1221   if (my $cache = $self->get_cache) {
1222     $self->{all_cache_position} ||= 0;
1223     return $cache->[$self->{all_cache_position}++];
1224   }
1225   if ($self->{attrs}{cache}) {
1226     delete $self->{pager};
1227     $self->{all_cache_position} = 1;
1228     return ($self->all)[0];
1229   }
1230   if ($self->{stashed_objects}) {
1231     my $obj = shift(@{$self->{stashed_objects}});
1232     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1233     return $obj;
1234   }
1235   my @row = (
1236     exists $self->{stashed_row}
1237       ? @{delete $self->{stashed_row}}
1238       : $self->cursor->next
1239   );
1240   return undef unless (@row);
1241   my ($row, @more) = $self->_construct_object(@row);
1242   $self->{stashed_objects} = \@more if @more;
1243   return $row;
1244 }
1245
1246 sub _construct_object {
1247   my ($self, @row) = @_;
1248
1249   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1250     or return ();
1251   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1252   @new = $self->{_attrs}{record_filter}->(@new)
1253     if exists $self->{_attrs}{record_filter};
1254   return @new;
1255 }
1256
1257 sub _collapse_result {
1258   my ($self, $as_proto, $row) = @_;
1259
1260   my @copy = @$row;
1261
1262   # 'foo'         => [ undef, 'foo' ]
1263   # 'foo.bar'     => [ 'foo', 'bar' ]
1264   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1265
1266   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1267
1268   my %collapse = %{$self->{_attrs}{collapse}||{}};
1269
1270   my @pri_index;
1271
1272   # if we're doing collapsing (has_many prefetch) we need to grab records
1273   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1274   # we know we don't have to bother.
1275
1276   # the reason for not using the collapse stuff directly is because if you
1277   # had for e.g. two artists in a row with no cds, the collapse info for
1278   # both would be NULL (undef) so you'd lose the second artist
1279
1280   # store just the index so we can check the array positions from the row
1281   # without having to contruct the full hash
1282
1283   if (keys %collapse) {
1284     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1285     foreach my $i (0 .. $#construct_as) {
1286       next if defined($construct_as[$i][0]); # only self table
1287       if (delete $pri{$construct_as[$i][1]}) {
1288         push(@pri_index, $i);
1289       }
1290       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1291     }
1292   }
1293
1294   # no need to do an if, it'll be empty if @pri_index is empty anyway
1295
1296   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1297
1298   my @const_rows;
1299
1300   do { # no need to check anything at the front, we always want the first row
1301
1302     my %const;
1303
1304     foreach my $this_as (@construct_as) {
1305       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1306     }
1307
1308     push(@const_rows, \%const);
1309
1310   } until ( # no pri_index => no collapse => drop straight out
1311       !@pri_index
1312     or
1313       do { # get another row, stash it, drop out if different PK
1314
1315         @copy = $self->cursor->next;
1316         $self->{stashed_row} = \@copy;
1317
1318         # last thing in do block, counts as true if anything doesn't match
1319
1320         # check xor defined first for NULL vs. NOT NULL then if one is
1321         # defined the other must be so check string equality
1322
1323         grep {
1324           (defined $pri_vals{$_} ^ defined $copy[$_])
1325           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1326         } @pri_index;
1327       }
1328   );
1329
1330   my $alias = $self->{attrs}{alias};
1331   my $info = [];
1332
1333   my %collapse_pos;
1334
1335   my @const_keys;
1336
1337   foreach my $const (@const_rows) {
1338     scalar @const_keys or do {
1339       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1340     };
1341     foreach my $key (@const_keys) {
1342       if (length $key) {
1343         my $target = $info;
1344         my @parts = split(/\./, $key);
1345         my $cur = '';
1346         my $data = $const->{$key};
1347         foreach my $p (@parts) {
1348           $target = $target->[1]->{$p} ||= [];
1349           $cur .= ".${p}";
1350           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1351             # collapsing at this point and on final part
1352             my $pos = $collapse_pos{$cur};
1353             CK: foreach my $ck (@ckey) {
1354               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1355                 $collapse_pos{$cur} = $data;
1356                 delete @collapse_pos{ # clear all positioning for sub-entries
1357                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1358                 };
1359                 push(@$target, []);
1360                 last CK;
1361               }
1362             }
1363           }
1364           if (exists $collapse{$cur}) {
1365             $target = $target->[-1];
1366           }
1367         }
1368         $target->[0] = $data;
1369       } else {
1370         $info->[0] = $const->{$key};
1371       }
1372     }
1373   }
1374
1375   return $info;
1376 }
1377
1378 =head2 result_source
1379
1380 =over 4
1381
1382 =item Arguments: $result_source?
1383
1384 =item Return Value: $result_source
1385
1386 =back
1387
1388 An accessor for the primary ResultSource object from which this ResultSet
1389 is derived.
1390
1391 =head2 result_class
1392
1393 =over 4
1394
1395 =item Arguments: $result_class?
1396
1397 =item Return Value: $result_class
1398
1399 =back
1400
1401 An accessor for the class to use when creating row objects. Defaults to
1402 C<< result_source->result_class >> - which in most cases is the name of the
1403 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1404
1405 Note that changing the result_class will also remove any components
1406 that were originally loaded in the source class via
1407 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1408 in the original source class will not run.
1409
1410 =cut
1411
1412 sub result_class {
1413   my ($self, $result_class) = @_;
1414   if ($result_class) {
1415     unless (ref $result_class) { # don't fire this for an object
1416       $self->ensure_class_loaded($result_class);
1417     }
1418     $self->_result_class($result_class);
1419     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1420     # permit the user to set result class on one result set only; it only
1421     # chains if provided to search()
1422     #$self->{attrs}{result_class} = $result_class if ref $self;
1423   }
1424   $self->_result_class;
1425 }
1426
1427 =head2 count
1428
1429 =over 4
1430
1431 =item Arguments: $cond, \%attrs??
1432
1433 =item Return Value: $count
1434
1435 =back
1436
1437 Performs an SQL C<COUNT> with the same query as the resultset was built
1438 with to find the number of elements. Passing arguments is equivalent to
1439 C<< $rs->search ($cond, \%attrs)->count >>
1440
1441 =cut
1442
1443 sub count {
1444   my $self = shift;
1445   return $self->search(@_)->count if @_ and defined $_[0];
1446   return scalar @{ $self->get_cache } if $self->get_cache;
1447
1448   my $attrs = $self->_resolved_attrs_copy;
1449
1450   # this is a little optimization - it is faster to do the limit
1451   # adjustments in software, instead of a subquery
1452   my $rows = delete $attrs->{rows};
1453   my $offset = delete $attrs->{offset};
1454
1455   my $crs;
1456   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1457     $crs = $self->_count_subq_rs ($attrs);
1458   }
1459   else {
1460     $crs = $self->_count_rs ($attrs);
1461   }
1462   my $count = $crs->next;
1463
1464   $count -= $offset if $offset;
1465   $count = $rows if $rows and $rows < $count;
1466   $count = 0 if ($count < 0);
1467
1468   return $count;
1469 }
1470
1471 =head2 count_rs
1472
1473 =over 4
1474
1475 =item Arguments: $cond, \%attrs??
1476
1477 =item Return Value: $count_rs
1478
1479 =back
1480
1481 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1482 This can be very handy for subqueries:
1483
1484   ->search( { amount => $some_rs->count_rs->as_query } )
1485
1486 As with regular resultsets the SQL query will be executed only after
1487 the resultset is accessed via L</next> or L</all>. That would return
1488 the same single value obtainable via L</count>.
1489
1490 =cut
1491
1492 sub count_rs {
1493   my $self = shift;
1494   return $self->search(@_)->count_rs if @_;
1495
1496   # this may look like a lack of abstraction (count() does about the same)
1497   # but in fact an _rs *must* use a subquery for the limits, as the
1498   # software based limiting can not be ported if this $rs is to be used
1499   # in a subquery itself (i.e. ->as_query)
1500   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1501     return $self->_count_subq_rs;
1502   }
1503   else {
1504     return $self->_count_rs;
1505   }
1506 }
1507
1508 #
1509 # returns a ResultSetColumn object tied to the count query
1510 #
1511 sub _count_rs {
1512   my ($self, $attrs) = @_;
1513
1514   my $rsrc = $self->result_source;
1515   $attrs ||= $self->_resolved_attrs;
1516
1517   my $tmp_attrs = { %$attrs };
1518   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1519   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1520
1521   # overwrite the selector (supplied by the storage)
1522   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1523   $tmp_attrs->{as} = 'count';
1524   delete @{$tmp_attrs}{qw/columns/};
1525
1526   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1527
1528   return $tmp_rs;
1529 }
1530
1531 #
1532 # same as above but uses a subquery
1533 #
1534 sub _count_subq_rs {
1535   my ($self, $attrs) = @_;
1536
1537   my $rsrc = $self->result_source;
1538   $attrs ||= $self->_resolved_attrs;
1539
1540   my $sub_attrs = { %$attrs };
1541   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1542   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1543
1544   # if we multi-prefetch we group_by primary keys only as this is what we would
1545   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1546   if ( keys %{$attrs->{collapse}}  ) {
1547     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1548   }
1549
1550   # Calculate subquery selector
1551   if (my $g = $sub_attrs->{group_by}) {
1552
1553     my $sql_maker = $rsrc->storage->sql_maker;
1554
1555     # necessary as the group_by may refer to aliased functions
1556     my $sel_index;
1557     for my $sel (@{$attrs->{select}}) {
1558       $sel_index->{$sel->{-as}} = $sel
1559         if (ref $sel eq 'HASH' and $sel->{-as});
1560     }
1561
1562     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1563     # also look for named aggregates referred in the having clause
1564     # having often contains scalarrefs - thus parse it out entirely
1565     my @parts = @$g;
1566     if ($attrs->{having}) {
1567       local $sql_maker->{having_bind};
1568       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1569       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1570       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1571         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1572         # if we don't unset it we screw up retarded but unfortunately working
1573         # 'MAX(foo.bar)' => { '>', 3 }
1574         $sql_maker->{name_sep} = '';
1575       }
1576
1577       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1578
1579       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1580
1581       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1582       # and if all fails for an utterly naive quoted scalar-with-function
1583       while ($sql =~ /
1584         $rquote $sep $lquote (.+?) $rquote
1585           |
1586         [\s,] \w+ \. (\w+) [\s,]
1587           |
1588         [\s,] $lquote (.+?) $rquote [\s,]
1589       /gx) {
1590         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1591       }
1592     }
1593
1594     for (@parts) {
1595       my $colpiece = $sel_index->{$_} || $_;
1596
1597       # unqualify join-based group_by's. Arcane but possible query
1598       # also horrible horrible hack to alias a column (not a func.)
1599       # (probably need to introduce SQLA syntax)
1600       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1601         my $as = $colpiece;
1602         $as =~ s/\./__/;
1603         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1604       }
1605       push @{$sub_attrs->{select}}, $colpiece;
1606     }
1607   }
1608   else {
1609     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1610     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1611   }
1612
1613   return $rsrc->resultset_class
1614                ->new ($rsrc, $sub_attrs)
1615                 ->as_subselect_rs
1616                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1617                   ->get_column ('count');
1618 }
1619
1620 sub _bool {
1621   return 1;
1622 }
1623
1624 =head2 count_literal
1625
1626 =over 4
1627
1628 =item Arguments: $sql_fragment, @bind_values
1629
1630 =item Return Value: $count
1631
1632 =back
1633
1634 Counts the results in a literal query. Equivalent to calling L</search_literal>
1635 with the passed arguments, then L</count>.
1636
1637 =cut
1638
1639 sub count_literal { shift->search_literal(@_)->count; }
1640
1641 =head2 all
1642
1643 =over 4
1644
1645 =item Arguments: none
1646
1647 =item Return Value: @objects
1648
1649 =back
1650
1651 Returns all elements in the resultset.
1652
1653 =cut
1654
1655 sub all {
1656   my $self = shift;
1657   if(@_) {
1658       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1659   }
1660
1661   return @{ $self->get_cache } if $self->get_cache;
1662
1663   my @obj;
1664
1665   if (keys %{$self->_resolved_attrs->{collapse}}) {
1666     # Using $self->cursor->all is really just an optimisation.
1667     # If we're collapsing has_many prefetches it probably makes
1668     # very little difference, and this is cleaner than hacking
1669     # _construct_object to survive the approach
1670     $self->cursor->reset;
1671     my @row = $self->cursor->next;
1672     while (@row) {
1673       push(@obj, $self->_construct_object(@row));
1674       @row = (exists $self->{stashed_row}
1675                ? @{delete $self->{stashed_row}}
1676                : $self->cursor->next);
1677     }
1678   } else {
1679     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1680   }
1681
1682   $self->set_cache(\@obj) if $self->{attrs}{cache};
1683
1684   return @obj;
1685 }
1686
1687 =head2 reset
1688
1689 =over 4
1690
1691 =item Arguments: none
1692
1693 =item Return Value: $self
1694
1695 =back
1696
1697 Resets the resultset's cursor, so you can iterate through the elements again.
1698 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1699 another query.
1700
1701 =cut
1702
1703 sub reset {
1704   my ($self) = @_;
1705   delete $self->{_attrs} if exists $self->{_attrs};
1706   $self->{all_cache_position} = 0;
1707   $self->cursor->reset;
1708   return $self;
1709 }
1710
1711 =head2 first
1712
1713 =over 4
1714
1715 =item Arguments: none
1716
1717 =item Return Value: $object | undef
1718
1719 =back
1720
1721 Resets the resultset and returns an object for the first result (or C<undef>
1722 if the resultset is empty).
1723
1724 =cut
1725
1726 sub first {
1727   return $_[0]->reset->next;
1728 }
1729
1730
1731 # _rs_update_delete
1732 #
1733 # Determines whether and what type of subquery is required for the $rs operation.
1734 # If grouping is necessary either supplies its own, or verifies the current one
1735 # After all is done delegates to the proper storage method.
1736
1737 sub _rs_update_delete {
1738   my ($self, $op, $values) = @_;
1739
1740   my $cond = $self->{cond};
1741   my $rsrc = $self->result_source;
1742   my $storage = $rsrc->schema->storage;
1743
1744   my $attrs = { %{$self->_resolved_attrs} };
1745
1746   # "needs" is a strong word here - if the subquery is part of an IN clause - no point of
1747   # even adding the group_by. It will really be used only when composing a poor-man's
1748   # multicolumn-IN equivalent OR set
1749   my $needs_group_by_subq = defined $attrs->{group_by};
1750
1751   # simplify the joinmap and maybe decide if a grouping (and thus subquery) is necessary
1752   my $relation_classifications;
1753   if (ref($attrs->{from}) eq 'ARRAY') {
1754     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1755
1756     $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1757       [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1758       $attrs->{select},
1759       $cond,
1760       $attrs
1761     ) unless $needs_group_by_subq;  # we already know we need a group, no point of resolving them
1762   }
1763   else {
1764     $needs_group_by_subq ||= 1; # if {from} is unparseable assume the worst
1765   }
1766
1767   $needs_group_by_subq ||= exists $relation_classifications->{multiplying};
1768
1769   # if no subquery - life is easy-ish
1770   unless (
1771     $needs_group_by_subq
1772       or
1773     keys %$relation_classifications # if any joins at all - need to wrap a subq
1774       or
1775     $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1776   ) {
1777     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1778     # a condition containing 'me' or other table prefixes will not work
1779     # at all. What this code tries to do (badly) is to generate a condition
1780     # with the qualifiers removed, by exploiting the quote mechanism of sqla
1781     #
1782     # this is atrocious and should be replaced by normal sqla introspection
1783     # one sunny day
1784     my ($sql, @bind) = do {
1785       my $sqla = $rsrc->storage->sql_maker;
1786       local $sqla->{_dequalify_idents} = 1;
1787       $sqla->_recurse_where($self->{cond});
1788     } if $self->{cond};
1789
1790     return $rsrc->storage->$op(
1791       $rsrc,
1792       $op eq 'update' ? $values : (),
1793       $self->{cond} ? \[$sql, @bind] : (),
1794     );
1795   }
1796
1797   # we got this far - means it is time to wrap a subquery
1798   my $pcols = [ $rsrc->_pri_cols ];
1799   my $existing_group_by = delete $attrs->{group_by};
1800
1801   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1802   delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1803   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$pcols ];
1804   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1805   my $subrs = (ref $self)->new($rsrc, $attrs);
1806
1807   if (@$pcols == 1) {
1808     return $storage->$op (
1809       $rsrc,
1810       $op eq 'update' ? $values : (),
1811       { $pcols->[0] => { -in => $subrs->as_query } },
1812     );
1813   }
1814   elsif ($storage->_use_multicolumn_in) {
1815     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1816     my $sql_maker = $storage->sql_maker;
1817     my ($sql, @bind) = @${$subrs->as_query};
1818     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1819       join (', ', map { $sql_maker->_quote ($_) } @$pcols),
1820       $sql,
1821     );
1822
1823     return $storage->$op (
1824       $rsrc,
1825       $op eq 'update' ? $values : (),
1826       \[$sql, @bind],
1827     );
1828   }
1829   else {
1830     # if all else fails - get all primary keys and operate over a ORed set
1831     # wrap in a transaction for consistency
1832     # this is where the group_by starts to matter
1833     my $subq_group_by;
1834     if ($needs_group_by_subq) {
1835       $subq_group_by = $attrs->{columns};
1836
1837       # make sure if there is a supplied group_by it matches the columns compiled above
1838       # perfectly. Anything else can not be sanely executed on most databases so croak
1839       # right then and there
1840       if ($existing_group_by) {
1841         my @current_group_by = map
1842           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1843           @$existing_group_by
1844         ;
1845
1846         if (
1847           join ("\x00", sort @current_group_by)
1848             ne
1849           join ("\x00", sort @$subq_group_by )
1850         ) {
1851           $self->throw_exception (
1852             "You have just attempted a $op operation on a resultset which does group_by"
1853             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1854             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1855             . ' kind of queries. Please retry the operation with a modified group_by or'
1856             . ' without using one at all.'
1857           );
1858         }
1859       }
1860     }
1861
1862     my $guard = $storage->txn_scope_guard;
1863
1864     my @op_condition;
1865     for my $row ($subrs->search({}, { group_by => $subq_group_by })->cursor->all) {
1866       push @op_condition, { map
1867         { $pcols->[$_] => $row->[$_] }
1868         (0 .. $#$pcols)
1869       };
1870     }
1871
1872     my $res = $storage->$op (
1873       $rsrc,
1874       $op eq 'update' ? $values : (),
1875       \@op_condition,
1876     );
1877
1878     $guard->commit;
1879
1880     return $res;
1881   }
1882 }
1883
1884 =head2 update
1885
1886 =over 4
1887
1888 =item Arguments: \%values
1889
1890 =item Return Value: $storage_rv
1891
1892 =back
1893
1894 Sets the specified columns in the resultset to the supplied values in a
1895 single query. Note that this will not run any accessor/set_column/update
1896 triggers, nor will it update any row object instances derived from this
1897 resultset (this includes the contents of the L<resultset cache|/set_cache>
1898 if any). See L</update_all> if you need to execute any on-update
1899 triggers or cascades defined either by you or a
1900 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1901
1902 The return value is a pass through of what the underlying
1903 storage backend returned, and may vary. See L<DBI/execute> for the most
1904 common case.
1905
1906 =head3 CAVEAT
1907
1908 Note that L</update> does not process/deflate any of the values passed in.
1909 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1910 ensure manually that any value passed to this method will stringify to
1911 something the RDBMS knows how to deal with. A notable example is the
1912 handling of L<DateTime> objects, for more info see:
1913 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1914
1915 =cut
1916
1917 sub update {
1918   my ($self, $values) = @_;
1919   $self->throw_exception('Values for update must be a hash')
1920     unless ref $values eq 'HASH';
1921
1922   return $self->_rs_update_delete ('update', $values);
1923 }
1924
1925 =head2 update_all
1926
1927 =over 4
1928
1929 =item Arguments: \%values
1930
1931 =item Return Value: 1
1932
1933 =back
1934
1935 Fetches all objects and updates them one at a time via
1936 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1937 triggers, while L</update> will not.
1938
1939 =cut
1940
1941 sub update_all {
1942   my ($self, $values) = @_;
1943   $self->throw_exception('Values for update_all must be a hash')
1944     unless ref $values eq 'HASH';
1945
1946   my $guard = $self->result_source->schema->txn_scope_guard;
1947   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1948   $guard->commit;
1949   return 1;
1950 }
1951
1952 =head2 delete
1953
1954 =over 4
1955
1956 =item Arguments: none
1957
1958 =item Return Value: $storage_rv
1959
1960 =back
1961
1962 Deletes the rows matching this resultset in a single query. Note that this
1963 will not run any delete triggers, nor will it alter the
1964 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1965 derived from this resultset (this includes the contents of the
1966 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1967 execute any on-delete triggers or cascades defined either by you or a
1968 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1969
1970 The return value is a pass through of what the underlying storage backend
1971 returned, and may vary. See L<DBI/execute> for the most common case.
1972
1973 =cut
1974
1975 sub delete {
1976   my $self = shift;
1977   $self->throw_exception('delete does not accept any arguments')
1978     if @_;
1979
1980   return $self->_rs_update_delete ('delete');
1981 }
1982
1983 =head2 delete_all
1984
1985 =over 4
1986
1987 =item Arguments: none
1988
1989 =item Return Value: 1
1990
1991 =back
1992
1993 Fetches all objects and deletes them one at a time via
1994 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1995 triggers, while L</delete> will not.
1996
1997 =cut
1998
1999 sub delete_all {
2000   my $self = shift;
2001   $self->throw_exception('delete_all does not accept any arguments')
2002     if @_;
2003
2004   my $guard = $self->result_source->schema->txn_scope_guard;
2005   $_->delete for $self->all;
2006   $guard->commit;
2007   return 1;
2008 }
2009
2010 =head2 populate
2011
2012 =over 4
2013
2014 =item Arguments: \@data;
2015
2016 =back
2017
2018 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
2019 For the arrayref of hashrefs style each hashref should be a structure suitable
2020 for submitting to a $resultset->create(...) method.
2021
2022 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
2023 to insert the data, as this is a faster method.
2024
2025 Otherwise, each set of data is inserted into the database using
2026 L<DBIx::Class::ResultSet/create>, and the resulting objects are
2027 accumulated into an array. The array itself, or an array reference
2028 is returned depending on scalar or list context.
2029
2030 Example:  Assuming an Artist Class that has many CDs Classes relating:
2031
2032   my $Artist_rs = $schema->resultset("Artist");
2033
2034   ## Void Context Example
2035   $Artist_rs->populate([
2036      { artistid => 4, name => 'Manufactured Crap', cds => [
2037         { title => 'My First CD', year => 2006 },
2038         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2039       ],
2040      },
2041      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2042         { title => 'My parents sold me to a record company', year => 2005 },
2043         { title => 'Why Am I So Ugly?', year => 2006 },
2044         { title => 'I Got Surgery and am now Popular', year => 2007 }
2045       ],
2046      },
2047   ]);
2048
2049   ## Array Context Example
2050   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
2051     { name => "Artist One"},
2052     { name => "Artist Two"},
2053     { name => "Artist Three", cds=> [
2054     { title => "First CD", year => 2007},
2055     { title => "Second CD", year => 2008},
2056   ]}
2057   ]);
2058
2059   print $ArtistOne->name; ## response is 'Artist One'
2060   print $ArtistThree->cds->count ## reponse is '2'
2061
2062 For the arrayref of arrayrefs style,  the first element should be a list of the
2063 fieldsnames to which the remaining elements are rows being inserted.  For
2064 example:
2065
2066   $Arstist_rs->populate([
2067     [qw/artistid name/],
2068     [100, 'A Formally Unknown Singer'],
2069     [101, 'A singer that jumped the shark two albums ago'],
2070     [102, 'An actually cool singer'],
2071   ]);
2072
2073 Please note an important effect on your data when choosing between void and
2074 wantarray context. Since void context goes straight to C<insert_bulk> in
2075 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
2076 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
2077 create primary keys for you, you will find that your PKs are empty.  In this
2078 case you will have to use the wantarray context in order to create those
2079 values.
2080
2081 =cut
2082
2083 sub populate {
2084   my $self = shift;
2085
2086   # cruft placed in standalone method
2087   my $data = $self->_normalize_populate_args(@_);
2088
2089   return unless @$data;
2090
2091   if(defined wantarray) {
2092     my @created;
2093     foreach my $item (@$data) {
2094       push(@created, $self->create($item));
2095     }
2096     return wantarray ? @created : \@created;
2097   }
2098   else {
2099     my $first = $data->[0];
2100
2101     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2102     # it relationship data
2103     my (@rels, @columns);
2104     my $rsrc = $self->result_source;
2105     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2106     for (keys %$first) {
2107       my $ref = ref $first->{$_};
2108       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2109         ? push @rels, $_
2110         : push @columns, $_
2111       ;
2112     }
2113
2114     my @pks = $rsrc->primary_columns;
2115
2116     ## do the belongs_to relationships
2117     foreach my $index (0..$#$data) {
2118
2119       # delegate to create() for any dataset without primary keys with specified relationships
2120       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2121         for my $r (@rels) {
2122           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2123             my @ret = $self->populate($data);
2124             return;
2125           }
2126         }
2127       }
2128
2129       foreach my $rel (@rels) {
2130         next unless ref $data->[$index]->{$rel} eq "HASH";
2131         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2132         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2133         my $related = $result->result_source->_resolve_condition(
2134           $reverse_relinfo->{cond},
2135           $self,
2136           $result,
2137           $rel,
2138         );
2139
2140         delete $data->[$index]->{$rel};
2141         $data->[$index] = {%{$data->[$index]}, %$related};
2142
2143         push @columns, keys %$related if $index == 0;
2144       }
2145     }
2146
2147     ## inherit the data locked in the conditions of the resultset
2148     my ($rs_data) = $self->_merge_with_rscond({});
2149     delete @{$rs_data}{@columns};
2150     my @inherit_cols = keys %$rs_data;
2151     my @inherit_data = values %$rs_data;
2152
2153     ## do bulk insert on current row
2154     $rsrc->storage->insert_bulk(
2155       $rsrc,
2156       [@columns, @inherit_cols],
2157       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
2158     );
2159
2160     ## do the has_many relationships
2161     foreach my $item (@$data) {
2162
2163       my $main_row;
2164
2165       foreach my $rel (@rels) {
2166         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2167
2168         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2169
2170         my $child = $main_row->$rel;
2171
2172         my $related = $child->result_source->_resolve_condition(
2173           $rels->{$rel}{cond},
2174           $child,
2175           $main_row,
2176           $rel,
2177         );
2178
2179         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2180         my @populate = map { {%$_, %$related} } @rows_to_add;
2181
2182         $child->populate( \@populate );
2183       }
2184     }
2185   }
2186 }
2187
2188
2189 # populate() argumnets went over several incarnations
2190 # What we ultimately support is AoH
2191 sub _normalize_populate_args {
2192   my ($self, $arg) = @_;
2193
2194   if (ref $arg eq 'ARRAY') {
2195     if (!@$arg) {
2196       return [];
2197     }
2198     elsif (ref $arg->[0] eq 'HASH') {
2199       return $arg;
2200     }
2201     elsif (ref $arg->[0] eq 'ARRAY') {
2202       my @ret;
2203       my @colnames = @{$arg->[0]};
2204       foreach my $values (@{$arg}[1 .. $#$arg]) {
2205         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2206       }
2207       return \@ret;
2208     }
2209   }
2210
2211   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2212 }
2213
2214 =head2 pager
2215
2216 =over 4
2217
2218 =item Arguments: none
2219
2220 =item Return Value: $pager
2221
2222 =back
2223
2224 Return Value a L<Data::Page> object for the current resultset. Only makes
2225 sense for queries with a C<page> attribute.
2226
2227 To get the full count of entries for a paged resultset, call
2228 C<total_entries> on the L<Data::Page> object.
2229
2230 =cut
2231
2232 sub pager {
2233   my ($self) = @_;
2234
2235   return $self->{pager} if $self->{pager};
2236
2237   my $attrs = $self->{attrs};
2238   if (!defined $attrs->{page}) {
2239     $self->throw_exception("Can't create pager for non-paged rs");
2240   }
2241   elsif ($attrs->{page} <= 0) {
2242     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2243   }
2244   $attrs->{rows} ||= 10;
2245
2246   # throw away the paging flags and re-run the count (possibly
2247   # with a subselect) to get the real total count
2248   my $count_attrs = { %$attrs };
2249   delete $count_attrs->{$_} for qw/rows offset page pager/;
2250
2251   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2252
2253   require DBIx::Class::ResultSet::Pager;
2254   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2255     sub { $total_rs->count },  #lazy-get the total
2256     $attrs->{rows},
2257     $self->{attrs}{page},
2258   );
2259 }
2260
2261 =head2 page
2262
2263 =over 4
2264
2265 =item Arguments: $page_number
2266
2267 =item Return Value: $rs
2268
2269 =back
2270
2271 Returns a resultset for the $page_number page of the resultset on which page
2272 is called, where each page contains a number of rows equal to the 'rows'
2273 attribute set on the resultset (10 by default).
2274
2275 =cut
2276
2277 sub page {
2278   my ($self, $page) = @_;
2279   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2280 }
2281
2282 =head2 new_result
2283
2284 =over 4
2285
2286 =item Arguments: \%vals
2287
2288 =item Return Value: $rowobject
2289
2290 =back
2291
2292 Creates a new row object in the resultset's result class and returns
2293 it. The row is not inserted into the database at this point, call
2294 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2295 will tell you whether the row object has been inserted or not.
2296
2297 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2298
2299 =cut
2300
2301 sub new_result {
2302   my ($self, $values) = @_;
2303   $self->throw_exception( "new_result needs a hash" )
2304     unless (ref $values eq 'HASH');
2305
2306   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2307
2308   my %new = (
2309     %$merged_cond,
2310     @$cols_from_relations
2311       ? (-cols_from_relations => $cols_from_relations)
2312       : (),
2313     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2314   );
2315
2316   return $self->result_class->new(\%new);
2317 }
2318
2319 # _merge_with_rscond
2320 #
2321 # Takes a simple hash of K/V data and returns its copy merged with the
2322 # condition already present on the resultset. Additionally returns an
2323 # arrayref of value/condition names, which were inferred from related
2324 # objects (this is needed for in-memory related objects)
2325 sub _merge_with_rscond {
2326   my ($self, $data) = @_;
2327
2328   my (%new_data, @cols_from_relations);
2329
2330   my $alias = $self->{attrs}{alias};
2331
2332   if (! defined $self->{cond}) {
2333     # just massage $data below
2334   }
2335   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2336     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2337     @cols_from_relations = keys %new_data;
2338   }
2339   elsif (ref $self->{cond} ne 'HASH') {
2340     $self->throw_exception(
2341       "Can't abstract implicit construct, resultset condition not a hash"
2342     );
2343   }
2344   else {
2345     # precendence must be given to passed values over values inherited from
2346     # the cond, so the order here is important.
2347     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2348     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2349
2350     while ( my($col, $value) = each %implied ) {
2351       my $vref = ref $value;
2352       if (
2353         $vref eq 'HASH'
2354           and
2355         keys(%$value) == 1
2356           and
2357         (keys %$value)[0] eq '='
2358       ) {
2359         $new_data{$col} = $value->{'='};
2360       }
2361       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2362         $new_data{$col} = $value;
2363       }
2364     }
2365   }
2366
2367   %new_data = (
2368     %new_data,
2369     %{ $self->_remove_alias($data, $alias) },
2370   );
2371
2372   return (\%new_data, \@cols_from_relations);
2373 }
2374
2375 # _has_resolved_attr
2376 #
2377 # determines if the resultset defines at least one
2378 # of the attributes supplied
2379 #
2380 # used to determine if a subquery is neccessary
2381 #
2382 # supports some virtual attributes:
2383 #   -join
2384 #     This will scan for any joins being present on the resultset.
2385 #     It is not a mere key-search but a deep inspection of {from}
2386 #
2387
2388 sub _has_resolved_attr {
2389   my ($self, @attr_names) = @_;
2390
2391   my $attrs = $self->_resolved_attrs;
2392
2393   my %extra_checks;
2394
2395   for my $n (@attr_names) {
2396     if (grep { $n eq $_ } (qw/-join/) ) {
2397       $extra_checks{$n}++;
2398       next;
2399     }
2400
2401     my $attr =  $attrs->{$n};
2402
2403     next if not defined $attr;
2404
2405     if (ref $attr eq 'HASH') {
2406       return 1 if keys %$attr;
2407     }
2408     elsif (ref $attr eq 'ARRAY') {
2409       return 1 if @$attr;
2410     }
2411     else {
2412       return 1 if $attr;
2413     }
2414   }
2415
2416   # a resolved join is expressed as a multi-level from
2417   return 1 if (
2418     $extra_checks{-join}
2419       and
2420     ref $attrs->{from} eq 'ARRAY'
2421       and
2422     @{$attrs->{from}} > 1
2423   );
2424
2425   return 0;
2426 }
2427
2428 # _collapse_cond
2429 #
2430 # Recursively collapse the condition.
2431
2432 sub _collapse_cond {
2433   my ($self, $cond, $collapsed) = @_;
2434
2435   $collapsed ||= {};
2436
2437   if (ref $cond eq 'ARRAY') {
2438     foreach my $subcond (@$cond) {
2439       next unless ref $subcond;  # -or
2440       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2441     }
2442   }
2443   elsif (ref $cond eq 'HASH') {
2444     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2445       foreach my $subcond (@{$cond->{-and}}) {
2446         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2447       }
2448     }
2449     else {
2450       foreach my $col (keys %$cond) {
2451         my $value = $cond->{$col};
2452         $collapsed->{$col} = $value;
2453       }
2454     }
2455   }
2456
2457   return $collapsed;
2458 }
2459
2460 # _remove_alias
2461 #
2462 # Remove the specified alias from the specified query hash. A copy is made so
2463 # the original query is not modified.
2464
2465 sub _remove_alias {
2466   my ($self, $query, $alias) = @_;
2467
2468   my %orig = %{ $query || {} };
2469   my %unaliased;
2470
2471   foreach my $key (keys %orig) {
2472     if ($key !~ /\./) {
2473       $unaliased{$key} = $orig{$key};
2474       next;
2475     }
2476     $unaliased{$1} = $orig{$key}
2477       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2478   }
2479
2480   return \%unaliased;
2481 }
2482
2483 =head2 as_query
2484
2485 =over 4
2486
2487 =item Arguments: none
2488
2489 =item Return Value: \[ $sql, @bind ]
2490
2491 =back
2492
2493 Returns the SQL query and bind vars associated with the invocant.
2494
2495 This is generally used as the RHS for a subquery.
2496
2497 =cut
2498
2499 sub as_query {
2500   my $self = shift;
2501
2502   my $attrs = $self->_resolved_attrs_copy;
2503
2504   # For future use:
2505   #
2506   # in list ctx:
2507   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2508   # $sql also has no wrapping parenthesis in list ctx
2509   #
2510   my $sqlbind = $self->result_source->storage
2511     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2512
2513   return $sqlbind;
2514 }
2515
2516 =head2 find_or_new
2517
2518 =over 4
2519
2520 =item Arguments: \%vals, \%attrs?
2521
2522 =item Return Value: $rowobject
2523
2524 =back
2525
2526   my $artist = $schema->resultset('Artist')->find_or_new(
2527     { artist => 'fred' }, { key => 'artists' });
2528
2529   $cd->cd_to_producer->find_or_new({ producer => $producer },
2530                                    { key => 'primary });
2531
2532 Find an existing record from this resultset using L</find>. if none exists,
2533 instantiate a new result object and return it. The object will not be saved
2534 into your storage until you call L<DBIx::Class::Row/insert> on it.
2535
2536 You most likely want this method when looking for existing rows using a unique
2537 constraint that is not the primary key, or looking for related rows.
2538
2539 If you want objects to be saved immediately, use L</find_or_create> instead.
2540
2541 B<Note>: Make sure to read the documentation of L</find> and understand the
2542 significance of the C<key> attribute, as its lack may skew your search, and
2543 subsequently result in spurious new objects.
2544
2545 B<Note>: Take care when using C<find_or_new> with a table having
2546 columns with default values that you intend to be automatically
2547 supplied by the database (e.g. an auto_increment primary key column).
2548 In normal usage, the value of such columns should NOT be included at
2549 all in the call to C<find_or_new>, even when set to C<undef>.
2550
2551 =cut
2552
2553 sub find_or_new {
2554   my $self     = shift;
2555   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2556   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2557   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2558     return $row;
2559   }
2560   return $self->new_result($hash);
2561 }
2562
2563 =head2 create
2564
2565 =over 4
2566
2567 =item Arguments: \%vals
2568
2569 =item Return Value: a L<DBIx::Class::Row> $object
2570
2571 =back
2572
2573 Attempt to create a single new row or a row with multiple related rows
2574 in the table represented by the resultset (and related tables). This
2575 will not check for duplicate rows before inserting, use
2576 L</find_or_create> to do that.
2577
2578 To create one row for this resultset, pass a hashref of key/value
2579 pairs representing the columns of the table and the values you wish to
2580 store. If the appropriate relationships are set up, foreign key fields
2581 can also be passed an object representing the foreign row, and the
2582 value will be set to its primary key.
2583
2584 To create related objects, pass a hashref of related-object column values
2585 B<keyed on the relationship name>. If the relationship is of type C<multi>
2586 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2587 The process will correctly identify columns holding foreign keys, and will
2588 transparently populate them from the keys of the corresponding relation.
2589 This can be applied recursively, and will work correctly for a structure
2590 with an arbitrary depth and width, as long as the relationships actually
2591 exists and the correct column data has been supplied.
2592
2593
2594 Instead of hashrefs of plain related data (key/value pairs), you may
2595 also pass new or inserted objects. New objects (not inserted yet, see
2596 L</new>), will be inserted into their appropriate tables.
2597
2598 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2599
2600 Example of creating a new row.
2601
2602   $person_rs->create({
2603     name=>"Some Person",
2604     email=>"somebody@someplace.com"
2605   });
2606
2607 Example of creating a new row and also creating rows in a related C<has_many>
2608 or C<has_one> resultset.  Note Arrayref.
2609
2610   $artist_rs->create(
2611      { artistid => 4, name => 'Manufactured Crap', cds => [
2612         { title => 'My First CD', year => 2006 },
2613         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2614       ],
2615      },
2616   );
2617
2618 Example of creating a new row and also creating a row in a related
2619 C<belongs_to> resultset. Note Hashref.
2620
2621   $cd_rs->create({
2622     title=>"Music for Silly Walks",
2623     year=>2000,
2624     artist => {
2625       name=>"Silly Musician",
2626     }
2627   });
2628
2629 =over
2630
2631 =item WARNING
2632
2633 When subclassing ResultSet never attempt to override this method. Since
2634 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2635 lot of the internals simply never call it, so your override will be
2636 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2637 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2638 L</create> process you need to intervene.
2639
2640 =back
2641
2642 =cut
2643
2644 sub create {
2645   my ($self, $attrs) = @_;
2646   $self->throw_exception( "create needs a hashref" )
2647     unless ref $attrs eq 'HASH';
2648   return $self->new_result($attrs)->insert;
2649 }
2650
2651 =head2 find_or_create
2652
2653 =over 4
2654
2655 =item Arguments: \%vals, \%attrs?
2656
2657 =item Return Value: $rowobject
2658
2659 =back
2660
2661   $cd->cd_to_producer->find_or_create({ producer => $producer },
2662                                       { key => 'primary' });
2663
2664 Tries to find a record based on its primary key or unique constraints; if none
2665 is found, creates one and returns that instead.
2666
2667   my $cd = $schema->resultset('CD')->find_or_create({
2668     cdid   => 5,
2669     artist => 'Massive Attack',
2670     title  => 'Mezzanine',
2671     year   => 2005,
2672   });
2673
2674 Also takes an optional C<key> attribute, to search by a specific key or unique
2675 constraint. For example:
2676
2677   my $cd = $schema->resultset('CD')->find_or_create(
2678     {
2679       artist => 'Massive Attack',
2680       title  => 'Mezzanine',
2681     },
2682     { key => 'cd_artist_title' }
2683   );
2684
2685 B<Note>: Make sure to read the documentation of L</find> and understand the
2686 significance of the C<key> attribute, as its lack may skew your search, and
2687 subsequently result in spurious row creation.
2688
2689 B<Note>: Because find_or_create() reads from the database and then
2690 possibly inserts based on the result, this method is subject to a race
2691 condition. Another process could create a record in the table after
2692 the find has completed and before the create has started. To avoid
2693 this problem, use find_or_create() inside a transaction.
2694
2695 B<Note>: Take care when using C<find_or_create> with a table having
2696 columns with default values that you intend to be automatically
2697 supplied by the database (e.g. an auto_increment primary key column).
2698 In normal usage, the value of such columns should NOT be included at
2699 all in the call to C<find_or_create>, even when set to C<undef>.
2700
2701 See also L</find> and L</update_or_create>. For information on how to declare
2702 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2703
2704 =cut
2705
2706 sub find_or_create {
2707   my $self     = shift;
2708   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2709   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2710   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2711     return $row;
2712   }
2713   return $self->create($hash);
2714 }
2715
2716 =head2 update_or_create
2717
2718 =over 4
2719
2720 =item Arguments: \%col_values, { key => $unique_constraint }?
2721
2722 =item Return Value: $row_object
2723
2724 =back
2725
2726   $resultset->update_or_create({ col => $val, ... });
2727
2728 Like L</find_or_create>, but if a row is found it is immediately updated via
2729 C<< $found_row->update (\%col_values) >>.
2730
2731
2732 Takes an optional C<key> attribute to search on a specific unique constraint.
2733 For example:
2734
2735   # In your application
2736   my $cd = $schema->resultset('CD')->update_or_create(
2737     {
2738       artist => 'Massive Attack',
2739       title  => 'Mezzanine',
2740       year   => 1998,
2741     },
2742     { key => 'cd_artist_title' }
2743   );
2744
2745   $cd->cd_to_producer->update_or_create({
2746     producer => $producer,
2747     name => 'harry',
2748   }, {
2749     key => 'primary',
2750   });
2751
2752 B<Note>: Make sure to read the documentation of L</find> and understand the
2753 significance of the C<key> attribute, as its lack may skew your search, and
2754 subsequently result in spurious row creation.
2755
2756 B<Note>: Take care when using C<update_or_create> with a table having
2757 columns with default values that you intend to be automatically
2758 supplied by the database (e.g. an auto_increment primary key column).
2759 In normal usage, the value of such columns should NOT be included at
2760 all in the call to C<update_or_create>, even when set to C<undef>.
2761
2762 See also L</find> and L</find_or_create>. For information on how to declare
2763 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2764
2765 =cut
2766
2767 sub update_or_create {
2768   my $self = shift;
2769   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2770   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2771
2772   my $row = $self->find($cond, $attrs);
2773   if (defined $row) {
2774     $row->update($cond);
2775     return $row;
2776   }
2777
2778   return $self->create($cond);
2779 }
2780
2781 =head2 update_or_new
2782
2783 =over 4
2784
2785 =item Arguments: \%col_values, { key => $unique_constraint }?
2786
2787 =item Return Value: $rowobject
2788
2789 =back
2790
2791   $resultset->update_or_new({ col => $val, ... });
2792
2793 Like L</find_or_new> but if a row is found it is immediately updated via
2794 C<< $found_row->update (\%col_values) >>.
2795
2796 For example:
2797
2798   # In your application
2799   my $cd = $schema->resultset('CD')->update_or_new(
2800     {
2801       artist => 'Massive Attack',
2802       title  => 'Mezzanine',
2803       year   => 1998,
2804     },
2805     { key => 'cd_artist_title' }
2806   );
2807
2808   if ($cd->in_storage) {
2809       # the cd was updated
2810   }
2811   else {
2812       # the cd is not yet in the database, let's insert it
2813       $cd->insert;
2814   }
2815
2816 B<Note>: Make sure to read the documentation of L</find> and understand the
2817 significance of the C<key> attribute, as its lack may skew your search, and
2818 subsequently result in spurious new objects.
2819
2820 B<Note>: Take care when using C<update_or_new> with a table having
2821 columns with default values that you intend to be automatically
2822 supplied by the database (e.g. an auto_increment primary key column).
2823 In normal usage, the value of such columns should NOT be included at
2824 all in the call to C<update_or_new>, even when set to C<undef>.
2825
2826 See also L</find>, L</find_or_create> and L</find_or_new>.
2827
2828 =cut
2829
2830 sub update_or_new {
2831     my $self  = shift;
2832     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2833     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2834
2835     my $row = $self->find( $cond, $attrs );
2836     if ( defined $row ) {
2837         $row->update($cond);
2838         return $row;
2839     }
2840
2841     return $self->new_result($cond);
2842 }
2843
2844 =head2 get_cache
2845
2846 =over 4
2847
2848 =item Arguments: none
2849
2850 =item Return Value: \@cache_objects | undef
2851
2852 =back
2853
2854 Gets the contents of the cache for the resultset, if the cache is set.
2855
2856 The cache is populated either by using the L</prefetch> attribute to
2857 L</search> or by calling L</set_cache>.
2858
2859 =cut
2860
2861 sub get_cache {
2862   shift->{all_cache};
2863 }
2864
2865 =head2 set_cache
2866
2867 =over 4
2868
2869 =item Arguments: \@cache_objects
2870
2871 =item Return Value: \@cache_objects
2872
2873 =back
2874
2875 Sets the contents of the cache for the resultset. Expects an arrayref
2876 of objects of the same class as those produced by the resultset. Note that
2877 if the cache is set the resultset will return the cached objects rather
2878 than re-querying the database even if the cache attr is not set.
2879
2880 The contents of the cache can also be populated by using the
2881 L</prefetch> attribute to L</search>.
2882
2883 =cut
2884
2885 sub set_cache {
2886   my ( $self, $data ) = @_;
2887   $self->throw_exception("set_cache requires an arrayref")
2888       if defined($data) && (ref $data ne 'ARRAY');
2889   $self->{all_cache} = $data;
2890 }
2891
2892 =head2 clear_cache
2893
2894 =over 4
2895
2896 =item Arguments: none
2897
2898 =item Return Value: undef
2899
2900 =back
2901
2902 Clears the cache for the resultset.
2903
2904 =cut
2905
2906 sub clear_cache {
2907   shift->set_cache(undef);
2908 }
2909
2910 =head2 is_paged
2911
2912 =over 4
2913
2914 =item Arguments: none
2915
2916 =item Return Value: true, if the resultset has been paginated
2917
2918 =back
2919
2920 =cut
2921
2922 sub is_paged {
2923   my ($self) = @_;
2924   return !!$self->{attrs}{page};
2925 }
2926
2927 =head2 is_ordered
2928
2929 =over 4
2930
2931 =item Arguments: none
2932
2933 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2934
2935 =back
2936
2937 =cut
2938
2939 sub is_ordered {
2940   my ($self) = @_;
2941   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2942 }
2943
2944 =head2 related_resultset
2945
2946 =over 4
2947
2948 =item Arguments: $relationship_name
2949
2950 =item Return Value: $resultset
2951
2952 =back
2953
2954 Returns a related resultset for the supplied relationship name.
2955
2956   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2957
2958 =cut
2959
2960 sub related_resultset {
2961   my ($self, $rel) = @_;
2962
2963   $self->{related_resultsets} ||= {};
2964   return $self->{related_resultsets}{$rel} ||= do {
2965     my $rsrc = $self->result_source;
2966     my $rel_info = $rsrc->relationship_info($rel);
2967
2968     $self->throw_exception(
2969       "search_related: result source '" . $rsrc->source_name .
2970         "' has no such relationship $rel")
2971       unless $rel_info;
2972
2973     my $attrs = $self->_chain_relationship($rel);
2974
2975     my $join_count = $attrs->{seen_join}{$rel};
2976
2977     my $alias = $self->result_source->storage
2978         ->relname_to_table_alias($rel, $join_count);
2979
2980     # since this is search_related, and we already slid the select window inwards
2981     # (the select/as attrs were deleted in the beginning), we need to flip all
2982     # left joins to inner, so we get the expected results
2983     # read the comment on top of the actual function to see what this does
2984     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2985
2986
2987     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2988     delete @{$attrs}{qw(result_class alias)};
2989
2990     my $new_cache;
2991
2992     if (my $cache = $self->get_cache) {
2993       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2994         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2995                         @$cache ];
2996       }
2997     }
2998
2999     my $rel_source = $rsrc->related_source($rel);
3000
3001     my $new = do {
3002
3003       # The reason we do this now instead of passing the alias to the
3004       # search_rs below is that if you wrap/overload resultset on the
3005       # source you need to know what alias it's -going- to have for things
3006       # to work sanely (e.g. RestrictWithObject wants to be able to add
3007       # extra query restrictions, and these may need to be $alias.)
3008
3009       my $rel_attrs = $rel_source->resultset_attributes;
3010       local $rel_attrs->{alias} = $alias;
3011
3012       $rel_source->resultset
3013                  ->search_rs(
3014                      undef, {
3015                        %$attrs,
3016                        where => $attrs->{where},
3017                    });
3018     };
3019     $new->set_cache($new_cache) if $new_cache;
3020     $new;
3021   };
3022 }
3023
3024 =head2 current_source_alias
3025
3026 =over 4
3027
3028 =item Arguments: none
3029
3030 =item Return Value: $source_alias
3031
3032 =back
3033
3034 Returns the current table alias for the result source this resultset is built
3035 on, that will be used in the SQL query. Usually it is C<me>.
3036
3037 Currently the source alias that refers to the result set returned by a
3038 L</search>/L</find> family method depends on how you got to the resultset: it's
3039 C<me> by default, but eg. L</search_related> aliases it to the related result
3040 source name (and keeps C<me> referring to the original result set). The long
3041 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3042 (and make this method unnecessary).
3043
3044 Thus it's currently necessary to use this method in predefined queries (see
3045 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3046 source alias of the current result set:
3047
3048   # in a result set class
3049   sub modified_by {
3050     my ($self, $user) = @_;
3051
3052     my $me = $self->current_source_alias;
3053
3054     return $self->search(
3055       "$me.modified" => $user->id,
3056     );
3057   }
3058
3059 =cut
3060
3061 sub current_source_alias {
3062   my ($self) = @_;
3063
3064   return ($self->{attrs} || {})->{alias} || 'me';
3065 }
3066
3067 =head2 as_subselect_rs
3068
3069 =over 4
3070
3071 =item Arguments: none
3072
3073 =item Return Value: $resultset
3074
3075 =back
3076
3077 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3078 "virtual view" by including it as a subquery within the from clause.  From this
3079 point on, any joined tables are inaccessible to ->search on the resultset (as if
3080 it were simply where-filtered without joins).  For example:
3081
3082  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3083
3084  # 'x' now pollutes the query namespace
3085
3086  # So the following works as expected
3087  my $ok_rs = $rs->search({'x.other' => 1});
3088
3089  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3090  # def) we look for one row with contradictory terms and join in another table
3091  # (aliased 'x_2') which we never use
3092  my $broken_rs = $rs->search({'x.name' => 'def'});
3093
3094  my $rs2 = $rs->as_subselect_rs;
3095
3096  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3097  my $not_joined_rs = $rs2->search({'x.other' => 1});
3098
3099  # works as expected: finds a 'table' row related to two x rows (abc and def)
3100  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3101
3102 Another example of when one might use this would be to select a subset of
3103 columns in a group by clause:
3104
3105  my $rs = $schema->resultset('Bar')->search(undef, {
3106    group_by => [qw{ id foo_id baz_id }],
3107  })->as_subselect_rs->search(undef, {
3108    columns => [qw{ id foo_id }]
3109  });
3110
3111 In the above example normally columns would have to be equal to the group by,
3112 but because we isolated the group by into a subselect the above works.
3113
3114 =cut
3115
3116 sub as_subselect_rs {
3117   my $self = shift;
3118
3119   my $attrs = $self->_resolved_attrs;
3120
3121   my $fresh_rs = (ref $self)->new (
3122     $self->result_source
3123   );
3124
3125   # these pieces will be locked in the subquery
3126   delete $fresh_rs->{cond};
3127   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3128
3129   return $fresh_rs->search( {}, {
3130     from => [{
3131       $attrs->{alias} => $self->as_query,
3132       -alias  => $attrs->{alias},
3133       -rsrc   => $self->result_source,
3134     }],
3135     alias => $attrs->{alias},
3136   });
3137 }
3138
3139 # This code is called by search_related, and makes sure there
3140 # is clear separation between the joins before, during, and
3141 # after the relationship. This information is needed later
3142 # in order to properly resolve prefetch aliases (any alias
3143 # with a relation_chain_depth less than the depth of the
3144 # current prefetch is not considered)
3145 #
3146 # The increments happen twice per join. An even number means a
3147 # relationship specified via a search_related, whereas an odd
3148 # number indicates a join/prefetch added via attributes
3149 #
3150 # Also this code will wrap the current resultset (the one we
3151 # chain to) in a subselect IFF it contains limiting attributes
3152 sub _chain_relationship {
3153   my ($self, $rel) = @_;
3154   my $source = $self->result_source;
3155   my $attrs = { %{$self->{attrs}||{}} };
3156
3157   # we need to take the prefetch the attrs into account before we
3158   # ->_resolve_join as otherwise they get lost - captainL
3159   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3160
3161   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3162
3163   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3164
3165   my $from;
3166   my @force_subq_attrs = qw/offset rows group_by having/;
3167
3168   if (
3169     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3170       ||
3171     $self->_has_resolved_attr (@force_subq_attrs)
3172   ) {
3173     # Nuke the prefetch (if any) before the new $rs attrs
3174     # are resolved (prefetch is useless - we are wrapping
3175     # a subquery anyway).
3176     my $rs_copy = $self->search;
3177     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3178       $rs_copy->{attrs}{join},
3179       delete $rs_copy->{attrs}{prefetch},
3180     );
3181
3182     $from = [{
3183       -rsrc   => $source,
3184       -alias  => $attrs->{alias},
3185       $attrs->{alias} => $rs_copy->as_query,
3186     }];
3187     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3188     $seen->{-relation_chain_depth} = 0;
3189   }
3190   elsif ($attrs->{from}) {  #shallow copy suffices
3191     $from = [ @{$attrs->{from}} ];
3192   }
3193   else {
3194     $from = [{
3195       -rsrc  => $source,
3196       -alias => $attrs->{alias},
3197       $attrs->{alias} => $source->from,
3198     }];
3199   }
3200
3201   my $jpath = ($seen->{-relation_chain_depth})
3202     ? $from->[-1][0]{-join_path}
3203     : [];
3204
3205   my @requested_joins = $source->_resolve_join(
3206     $join,
3207     $attrs->{alias},
3208     $seen,
3209     $jpath,
3210   );
3211
3212   push @$from, @requested_joins;
3213
3214   $seen->{-relation_chain_depth}++;
3215
3216   # if $self already had a join/prefetch specified on it, the requested
3217   # $rel might very well be already included. What we do in this case
3218   # is effectively a no-op (except that we bump up the chain_depth on
3219   # the join in question so we could tell it *is* the search_related)
3220   my $already_joined;
3221
3222   # we consider the last one thus reverse
3223   for my $j (reverse @requested_joins) {
3224     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3225     if ($rel eq $last_j) {
3226       $j->[0]{-relation_chain_depth}++;
3227       $already_joined++;
3228       last;
3229     }
3230   }
3231
3232   unless ($already_joined) {
3233     push @$from, $source->_resolve_join(
3234       $rel,
3235       $attrs->{alias},
3236       $seen,
3237       $jpath,
3238     );
3239   }
3240
3241   $seen->{-relation_chain_depth}++;
3242
3243   return {%$attrs, from => $from, seen_join => $seen};
3244 }
3245
3246 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3247 sub _resolved_attrs_copy {
3248   my $self = shift;
3249   return { %{$self->_resolved_attrs (@_)} };
3250 }
3251
3252 sub _resolved_attrs {
3253   my $self = shift;
3254   return $self->{_attrs} if $self->{_attrs};
3255
3256   my $attrs  = { %{ $self->{attrs} || {} } };
3257   my $source = $self->result_source;
3258   my $alias  = $attrs->{alias};
3259
3260   # default selection list
3261   $attrs->{columns} = [ $source->columns ]
3262     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3263
3264   # merge selectors together
3265   for (qw/columns select as/) {
3266     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3267       if $attrs->{$_} or $attrs->{"+$_"};
3268   }
3269
3270   # disassemble columns
3271   my (@sel, @as);
3272   if (my $cols = delete $attrs->{columns}) {
3273     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3274       if (ref $c eq 'HASH') {
3275         for my $as (keys %$c) {
3276           push @sel, $c->{$as};
3277           push @as, $as;
3278         }
3279       }
3280       else {
3281         push @sel, $c;
3282         push @as, $c;
3283       }
3284     }
3285   }
3286
3287   # when trying to weed off duplicates later do not go past this point -
3288   # everything added from here on is unbalanced "anyone's guess" stuff
3289   my $dedup_stop_idx = $#as;
3290
3291   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3292     if $attrs->{as};
3293   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3294     if $attrs->{select};
3295
3296   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3297   for (@sel) {
3298     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3299   }
3300
3301   # disqualify all $alias.col as-bits (collapser mandated)
3302   for (@as) {
3303     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3304   }
3305
3306   # de-duplicate the result (remove *identical* select/as pairs)
3307   # and also die on duplicate {as} pointing to different {select}s
3308   # not using a c-style for as the condition is prone to shrinkage
3309   my $seen;
3310   my $i = 0;
3311   while ($i <= $dedup_stop_idx) {
3312     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3313       splice @sel, $i, 1;
3314       splice @as, $i, 1;
3315       $dedup_stop_idx--;
3316     }
3317     elsif ($seen->{$as[$i]}++) {
3318       $self->throw_exception(
3319         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3320       );
3321     }
3322     else {
3323       $i++;
3324     }
3325   }
3326
3327   $attrs->{select} = \@sel;
3328   $attrs->{as} = \@as;
3329
3330   $attrs->{from} ||= [{
3331     -rsrc   => $source,
3332     -alias  => $self->{attrs}{alias},
3333     $self->{attrs}{alias} => $source->from,
3334   }];
3335
3336   if ( $attrs->{join} || $attrs->{prefetch} ) {
3337
3338     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3339       if ref $attrs->{from} ne 'ARRAY';
3340
3341     my $join = (delete $attrs->{join}) || {};
3342
3343     if ( defined $attrs->{prefetch} ) {
3344       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3345     }
3346
3347     $attrs->{from} =    # have to copy here to avoid corrupting the original
3348       [
3349         @{ $attrs->{from} },
3350         $source->_resolve_join(
3351           $join,
3352           $alias,
3353           { %{ $attrs->{seen_join} || {} } },
3354           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3355             ? $attrs->{from}[-1][0]{-join_path}
3356             : []
3357           ,
3358         )
3359       ];
3360   }
3361
3362   if ( defined $attrs->{order_by} ) {
3363     $attrs->{order_by} = (
3364       ref( $attrs->{order_by} ) eq 'ARRAY'
3365       ? [ @{ $attrs->{order_by} } ]
3366       : [ $attrs->{order_by} || () ]
3367     );
3368   }
3369
3370   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3371     $attrs->{group_by} = [ $attrs->{group_by} ];
3372   }
3373
3374   # generate the distinct induced group_by early, as prefetch will be carried via a
3375   # subquery (since a group_by is present)
3376   if (delete $attrs->{distinct}) {
3377     if ($attrs->{group_by}) {
3378       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3379     }
3380     else {
3381       # distinct affects only the main selection part, not what prefetch may
3382       # add below.
3383       $attrs->{group_by} = $source->storage->_group_over_selection (
3384         $attrs->{from},
3385         $attrs->{select},
3386         $attrs->{order_by},
3387       );
3388     }
3389   }
3390
3391   $attrs->{collapse} ||= {};
3392   if ($attrs->{prefetch}) {
3393
3394     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3395       if $attrs->{_dark_selector};
3396
3397     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3398
3399     my $prefetch_ordering = [];
3400
3401     # this is a separate structure (we don't look in {from} directly)
3402     # as the resolver needs to shift things off the lists to work
3403     # properly (identical-prefetches on different branches)
3404     my $join_map = {};
3405     if (ref $attrs->{from} eq 'ARRAY') {
3406
3407       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3408
3409       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3410         next unless $j->[0]{-alias};
3411         next unless $j->[0]{-join_path};
3412         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3413
3414         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3415
3416         my $p = $join_map;
3417         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3418         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3419       }
3420     }
3421
3422     my @prefetch =
3423       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3424
3425     # we need to somehow mark which columns came from prefetch
3426     if (@prefetch) {
3427       my $sel_end = $#{$attrs->{select}};
3428       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3429     }
3430
3431     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3432     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3433
3434     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3435     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3436   }
3437
3438
3439   # if both page and offset are specified, produce a combined offset
3440   # even though it doesn't make much sense, this is what pre 081xx has
3441   # been doing
3442   if (my $page = delete $attrs->{page}) {
3443     $attrs->{offset} =
3444       ($attrs->{rows} * ($page - 1))
3445             +
3446       ($attrs->{offset} || 0)
3447     ;
3448   }
3449
3450   return $self->{_attrs} = $attrs;
3451 }
3452
3453 sub _rollout_attr {
3454   my ($self, $attr) = @_;
3455
3456   if (ref $attr eq 'HASH') {
3457     return $self->_rollout_hash($attr);
3458   } elsif (ref $attr eq 'ARRAY') {
3459     return $self->_rollout_array($attr);
3460   } else {
3461     return [$attr];
3462   }
3463 }
3464
3465 sub _rollout_array {
3466   my ($self, $attr) = @_;
3467
3468   my @rolled_array;
3469   foreach my $element (@{$attr}) {
3470     if (ref $element eq 'HASH') {
3471       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3472     } elsif (ref $element eq 'ARRAY') {
3473       #  XXX - should probably recurse here
3474       push( @rolled_array, @{$self->_rollout_array($element)} );
3475     } else {
3476       push( @rolled_array, $element );
3477     }
3478   }
3479   return \@rolled_array;
3480 }
3481
3482 sub _rollout_hash {
3483   my ($self, $attr) = @_;
3484
3485   my @rolled_array;
3486   foreach my $key (keys %{$attr}) {
3487     push( @rolled_array, { $key => $attr->{$key} } );
3488   }
3489   return \@rolled_array;
3490 }
3491
3492 sub _calculate_score {
3493   my ($self, $a, $b) = @_;
3494
3495   if (defined $a xor defined $b) {
3496     return 0;
3497   }
3498   elsif (not defined $a) {
3499     return 1;
3500   }
3501
3502   if (ref $b eq 'HASH') {
3503     my ($b_key) = keys %{$b};
3504     if (ref $a eq 'HASH') {
3505       my ($a_key) = keys %{$a};
3506       if ($a_key eq $b_key) {
3507         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3508       } else {
3509         return 0;
3510       }
3511     } else {
3512       return ($a eq $b_key) ? 1 : 0;
3513     }
3514   } else {
3515     if (ref $a eq 'HASH') {
3516       my ($a_key) = keys %{$a};
3517       return ($b eq $a_key) ? 1 : 0;
3518     } else {
3519       return ($b eq $a) ? 1 : 0;
3520     }
3521   }
3522 }
3523
3524 sub _merge_joinpref_attr {
3525   my ($self, $orig, $import) = @_;
3526
3527   return $import unless defined($orig);
3528   return $orig unless defined($import);
3529
3530   $orig = $self->_rollout_attr($orig);
3531   $import = $self->_rollout_attr($import);
3532
3533   my $seen_keys;
3534   foreach my $import_element ( @{$import} ) {
3535     # find best candidate from $orig to merge $b_element into
3536     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3537     foreach my $orig_element ( @{$orig} ) {
3538       my $score = $self->_calculate_score( $orig_element, $import_element );
3539       if ($score > $best_candidate->{score}) {
3540         $best_candidate->{position} = $position;
3541         $best_candidate->{score} = $score;
3542       }
3543       $position++;
3544     }
3545     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3546     $import_key = '' if not defined $import_key;
3547
3548     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3549       push( @{$orig}, $import_element );
3550     } else {
3551       my $orig_best = $orig->[$best_candidate->{position}];
3552       # merge orig_best and b_element together and replace original with merged
3553       if (ref $orig_best ne 'HASH') {
3554         $orig->[$best_candidate->{position}] = $import_element;
3555       } elsif (ref $import_element eq 'HASH') {
3556         my ($key) = keys %{$orig_best};
3557         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3558       }
3559     }
3560     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3561   }
3562
3563   return $orig;
3564 }
3565
3566 {
3567   my $hm;
3568
3569   sub _merge_attr {
3570     $hm ||= do {
3571       require Hash::Merge;
3572       my $hm = Hash::Merge->new;
3573
3574       $hm->specify_behavior({
3575         SCALAR => {
3576           SCALAR => sub {
3577             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3578
3579             if ($defl xor $defr) {
3580               return [ $defl ? $_[0] : $_[1] ];
3581             }
3582             elsif (! $defl) {
3583               return [];
3584             }
3585             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3586               return [ $_[0] ];
3587             }
3588             else {
3589               return [$_[0], $_[1]];
3590             }
3591           },
3592           ARRAY => sub {
3593             return $_[1] if !defined $_[0];
3594             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3595             return [$_[0], @{$_[1]}]
3596           },
3597           HASH  => sub {
3598             return [] if !defined $_[0] and !keys %{$_[1]};
3599             return [ $_[1] ] if !defined $_[0];
3600             return [ $_[0] ] if !keys %{$_[1]};
3601             return [$_[0], $_[1]]
3602           },
3603         },
3604         ARRAY => {
3605           SCALAR => sub {
3606             return $_[0] if !defined $_[1];
3607             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3608             return [@{$_[0]}, $_[1]]
3609           },
3610           ARRAY => sub {
3611             my @ret = @{$_[0]} or return $_[1];
3612             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3613             my %idx = map { $_ => 1 } @ret;
3614             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3615             \@ret;
3616           },
3617           HASH => sub {
3618             return [ $_[1] ] if ! @{$_[0]};
3619             return $_[0] if !keys %{$_[1]};
3620             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3621             return [ @{$_[0]}, $_[1] ];
3622           },
3623         },
3624         HASH => {
3625           SCALAR => sub {
3626             return [] if !keys %{$_[0]} and !defined $_[1];
3627             return [ $_[0] ] if !defined $_[1];
3628             return [ $_[1] ] if !keys %{$_[0]};
3629             return [$_[0], $_[1]]
3630           },
3631           ARRAY => sub {
3632             return [] if !keys %{$_[0]} and !@{$_[1]};
3633             return [ $_[0] ] if !@{$_[1]};
3634             return $_[1] if !keys %{$_[0]};
3635             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3636             return [ $_[0], @{$_[1]} ];
3637           },
3638           HASH => sub {
3639             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3640             return [ $_[0] ] if !keys %{$_[1]};
3641             return [ $_[1] ] if !keys %{$_[0]};
3642             return [ $_[0] ] if $_[0] eq $_[1];
3643             return [ $_[0], $_[1] ];
3644           },
3645         }
3646       } => 'DBIC_RS_ATTR_MERGER');
3647       $hm;
3648     };
3649
3650     return $hm->merge ($_[1], $_[2]);
3651   }
3652 }
3653
3654 sub STORABLE_freeze {
3655   my ($self, $cloning) = @_;
3656   my $to_serialize = { %$self };
3657
3658   # A cursor in progress can't be serialized (and would make little sense anyway)
3659   delete $to_serialize->{cursor};
3660
3661   # nor is it sensical to store a not-yet-fired-count pager
3662   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3663     delete $to_serialize->{pager};
3664   }
3665
3666   Storable::nfreeze($to_serialize);
3667 }
3668
3669 # need this hook for symmetry
3670 sub STORABLE_thaw {
3671   my ($self, $cloning, $serialized) = @_;
3672
3673   %$self = %{ Storable::thaw($serialized) };
3674
3675   $self;
3676 }
3677
3678
3679 =head2 throw_exception
3680
3681 See L<DBIx::Class::Schema/throw_exception> for details.
3682
3683 =cut
3684
3685 sub throw_exception {
3686   my $self=shift;
3687
3688   if (ref $self and my $rsrc = $self->result_source) {
3689     $rsrc->throw_exception(@_)
3690   }
3691   else {
3692     DBIx::Class::Exception->throw(@_);
3693   }
3694 }
3695
3696 # XXX: FIXME: Attributes docs need clearing up
3697
3698 =head1 ATTRIBUTES
3699
3700 Attributes are used to refine a ResultSet in various ways when
3701 searching for data. They can be passed to any method which takes an
3702 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3703 L</count>.
3704
3705 These are in no particular order:
3706
3707 =head2 order_by
3708
3709 =over 4
3710
3711 =item Value: ( $order_by | \@order_by | \%order_by )
3712
3713 =back
3714
3715 Which column(s) to order the results by.
3716
3717 [The full list of suitable values is documented in
3718 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3719 common options.]
3720
3721 If a single column name, or an arrayref of names is supplied, the
3722 argument is passed through directly to SQL. The hashref syntax allows
3723 for connection-agnostic specification of ordering direction:
3724
3725  For descending order:
3726
3727   order_by => { -desc => [qw/col1 col2 col3/] }
3728
3729  For explicit ascending order:
3730
3731   order_by => { -asc => 'col' }
3732
3733 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3734 supported, although you are strongly encouraged to use the hashref
3735 syntax as outlined above.
3736
3737 =head2 columns
3738
3739 =over 4
3740
3741 =item Value: \@columns
3742
3743 =back
3744
3745 Shortcut to request a particular set of columns to be retrieved. Each
3746 column spec may be a string (a table column name), or a hash (in which
3747 case the key is the C<as> value, and the value is used as the C<select>
3748 expression). Adds C<me.> onto the start of any column without a C<.> in
3749 it and sets C<select> from that, then auto-populates C<as> from
3750 C<select> as normal. (You may also use the C<cols> attribute, as in
3751 earlier versions of DBIC.)
3752
3753 Essentially C<columns> does the same as L</select> and L</as>.
3754
3755     columns => [ 'foo', { bar => 'baz' } ]
3756
3757 is the same as
3758
3759     select => [qw/foo baz/],
3760     as => [qw/foo bar/]
3761
3762 =head2 +columns
3763
3764 =over 4
3765
3766 =item Value: \@columns
3767
3768 =back
3769
3770 Indicates additional columns to be selected from storage. Works the same
3771 as L</columns> but adds columns to the selection. (You may also use the
3772 C<include_columns> attribute, as in earlier versions of DBIC). For
3773 example:-
3774
3775   $schema->resultset('CD')->search(undef, {
3776     '+columns' => ['artist.name'],
3777     join => ['artist']
3778   });
3779
3780 would return all CDs and include a 'name' column to the information
3781 passed to object inflation. Note that the 'artist' is the name of the
3782 column (or relationship) accessor, and 'name' is the name of the column
3783 accessor in the related table.
3784
3785 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3786 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3787 unary plus operator before it.
3788
3789 =head2 include_columns
3790
3791 =over 4
3792
3793 =item Value: \@columns
3794
3795 =back
3796
3797 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3798
3799 =head2 select
3800
3801 =over 4
3802
3803 =item Value: \@select_columns
3804
3805 =back
3806
3807 Indicates which columns should be selected from the storage. You can use
3808 column names, or in the case of RDBMS back ends, function or stored procedure
3809 names:
3810
3811   $rs = $schema->resultset('Employee')->search(undef, {
3812     select => [
3813       'name',
3814       { count => 'employeeid' },
3815       { max => { length => 'name' }, -as => 'longest_name' }
3816     ]
3817   });
3818
3819   # Equivalent SQL
3820   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3821
3822 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3823 use L</select>, to instruct DBIx::Class how to store the result of the column.
3824 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3825 identifier aliasing. You can however alias a function, so you can use it in
3826 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3827 attribute> supplied as shown in the example above.
3828
3829 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3830 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3831 unary plus operator before it.
3832
3833 =head2 +select
3834
3835 =over 4
3836
3837 Indicates additional columns to be selected from storage.  Works the same as
3838 L</select> but adds columns to the default selection, instead of specifying
3839 an explicit list.
3840
3841 =back
3842
3843 =head2 +as
3844
3845 =over 4
3846
3847 Indicates additional column names for those added via L</+select>. See L</as>.
3848
3849 =back
3850
3851 =head2 as
3852
3853 =over 4
3854
3855 =item Value: \@inflation_names
3856
3857 =back
3858
3859 Indicates column names for object inflation. That is L</as> indicates the
3860 slot name in which the column value will be stored within the
3861 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3862 identifier by the C<get_column> method (or via the object accessor B<if one
3863 with the same name already exists>) as shown below. The L</as> attribute has
3864 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3865
3866   $rs = $schema->resultset('Employee')->search(undef, {
3867     select => [
3868       'name',
3869       { count => 'employeeid' },
3870       { max => { length => 'name' }, -as => 'longest_name' }
3871     ],
3872     as => [qw/
3873       name
3874       employee_count
3875       max_name_length
3876     /],
3877   });
3878
3879 If the object against which the search is performed already has an accessor
3880 matching a column name specified in C<as>, the value can be retrieved using
3881 the accessor as normal:
3882
3883   my $name = $employee->name();
3884
3885 If on the other hand an accessor does not exist in the object, you need to
3886 use C<get_column> instead:
3887
3888   my $employee_count = $employee->get_column('employee_count');
3889
3890 You can create your own accessors if required - see
3891 L<DBIx::Class::Manual::Cookbook> for details.
3892
3893 =head2 join
3894
3895 =over 4
3896
3897 =item Value: ($rel_name | \@rel_names | \%rel_names)
3898
3899 =back
3900
3901 Contains a list of relationships that should be joined for this query.  For
3902 example:
3903
3904   # Get CDs by Nine Inch Nails
3905   my $rs = $schema->resultset('CD')->search(
3906     { 'artist.name' => 'Nine Inch Nails' },
3907     { join => 'artist' }
3908   );
3909
3910 Can also contain a hash reference to refer to the other relation's relations.
3911 For example:
3912
3913   package MyApp::Schema::Track;
3914   use base qw/DBIx::Class/;
3915   __PACKAGE__->table('track');
3916   __PACKAGE__->add_columns(qw/trackid cd position title/);
3917   __PACKAGE__->set_primary_key('trackid');
3918   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3919   1;
3920
3921   # In your application
3922   my $rs = $schema->resultset('Artist')->search(
3923     { 'track.title' => 'Teardrop' },
3924     {
3925       join     => { cd => 'track' },
3926       order_by => 'artist.name',
3927     }
3928   );
3929
3930 You need to use the relationship (not the table) name in  conditions,
3931 because they are aliased as such. The current table is aliased as "me", so
3932 you need to use me.column_name in order to avoid ambiguity. For example:
3933
3934   # Get CDs from 1984 with a 'Foo' track
3935   my $rs = $schema->resultset('CD')->search(
3936     {
3937       'me.year' => 1984,
3938       'tracks.name' => 'Foo'
3939     },
3940     { join => 'tracks' }
3941   );
3942
3943 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3944 similarly for a third time). For e.g.
3945
3946   my $rs = $schema->resultset('Artist')->search({
3947     'cds.title'   => 'Down to Earth',
3948     'cds_2.title' => 'Popular',
3949   }, {
3950     join => [ qw/cds cds/ ],
3951   });
3952
3953 will return a set of all artists that have both a cd with title 'Down
3954 to Earth' and a cd with title 'Popular'.
3955
3956 If you want to fetch related objects from other tables as well, see C<prefetch>
3957 below.
3958
3959 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3960
3961 =head2 prefetch
3962
3963 =over 4
3964
3965 =item Value: ($rel_name | \@rel_names | \%rel_names)
3966
3967 =back
3968
3969 Contains one or more relationships that should be fetched along with
3970 the main query (when they are accessed afterwards the data will
3971 already be available, without extra queries to the database).  This is
3972 useful for when you know you will need the related objects, because it
3973 saves at least one query:
3974
3975   my $rs = $schema->resultset('Tag')->search(
3976     undef,
3977     {
3978       prefetch => {
3979         cd => 'artist'
3980       }
3981     }
3982   );
3983
3984 The initial search results in SQL like the following:
3985
3986   SELECT tag.*, cd.*, artist.* FROM tag
3987   JOIN cd ON tag.cd = cd.cdid
3988   JOIN artist ON cd.artist = artist.artistid
3989
3990 L<DBIx::Class> has no need to go back to the database when we access the
3991 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3992 case.
3993
3994 Simple prefetches will be joined automatically, so there is no need
3995 for a C<join> attribute in the above search.
3996
3997 L</prefetch> can be used with the any of the relationship types and
3998 multiple prefetches can be specified together. Below is a more complex
3999 example that prefetches a CD's artist, its liner notes (if present),
4000 the cover image, the tracks on that cd, and the guests on those
4001 tracks.
4002
4003  # Assuming:
4004  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4005  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4006  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4007  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4008
4009  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4010
4011  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4012
4013
4014  my $rs = $schema->resultset('CD')->search(
4015    undef,
4016    {
4017      prefetch => [
4018        { artist => 'record_label'},  # belongs_to => belongs_to
4019        'liner_note',                 # might_have
4020        'cover_image',                # has_one
4021        { tracks => 'guests' },       # has_many => has_many
4022      ]
4023    }
4024  );
4025
4026 This will produce SQL like the following:
4027
4028  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4029         tracks.*, guests.*
4030    FROM cd me
4031    JOIN artist artist
4032      ON artist.artistid = me.artistid
4033    JOIN record_label record_label
4034      ON record_label.labelid = artist.labelid
4035    LEFT JOIN track tracks
4036      ON tracks.cdid = me.cdid
4037    LEFT JOIN guest guests
4038      ON guests.trackid = track.trackid
4039    LEFT JOIN liner_notes liner_note
4040      ON liner_note.cdid = me.cdid
4041    JOIN cd_artwork cover_image
4042      ON cover_image.cdid = me.cdid
4043  ORDER BY tracks.cd
4044
4045 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4046 C<tracks>, and C<guests> of the CD will all be available through the
4047 relationship accessors without the need for additional queries to the
4048 database.
4049
4050 However, there is one caveat to be observed: it can be dangerous to
4051 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4052 relationship on a given level. e.g.:
4053
4054  my $rs = $schema->resultset('CD')->search(
4055    undef,
4056    {
4057      prefetch => [
4058        'tracks',                         # has_many
4059        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4060      ]
4061    }
4062  );
4063
4064 In fact, C<DBIx::Class> will emit the following warning:
4065
4066  Prefetching multiple has_many rels tracks and cd_to_producer at top
4067  level will explode the number of row objects retrievable via ->next
4068  or ->all. Use at your own risk.
4069
4070 The collapser currently can't identify duplicate tuples for multiple
4071 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4072 result the second L<has_many|DBIx::Class::Relationship/has_many>
4073 relation could contain redundant objects.
4074
4075 =head3 Using L</prefetch> with L</join>
4076
4077 L</prefetch> implies a L</join> with the equivalent argument, and is
4078 properly merged with any existing L</join> specification. So the
4079 following:
4080
4081   my $rs = $schema->resultset('CD')->search(
4082    {'record_label.name' => 'Music Product Ltd.'},
4083    {
4084      join     => {artist => 'record_label'},
4085      prefetch => 'artist',
4086    }
4087  );
4088
4089 ... will work, searching on the record label's name, but only
4090 prefetching the C<artist>.
4091
4092 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4093
4094 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4095 prefetched relations.  So given:
4096
4097   my $rs = $schema->resultset('CD')->search(
4098    undef,
4099    {
4100      select   => ['cd.title'],
4101      as       => ['cd_title'],
4102      prefetch => 'artist',
4103    }
4104  );
4105
4106 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4107 becomes: C<'cd_title', 'artist.*'>.
4108
4109 =head3 CAVEATS
4110
4111 Prefetch does a lot of deep magic. As such, it may not behave exactly
4112 as you might expect.
4113
4114 =over 4
4115
4116 =item *
4117
4118 Prefetch uses the L</cache> to populate the prefetched relationships. This
4119 may or may not be what you want.
4120
4121 =item *
4122
4123 If you specify a condition on a prefetched relationship, ONLY those
4124 rows that match the prefetched condition will be fetched into that relationship.
4125 This means that adding prefetch to a search() B<may alter> what is returned by
4126 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4127
4128   my $artist_rs = $schema->resultset('Artist')->search({
4129       'cds.year' => 2008,
4130   }, {
4131       join => 'cds',
4132   });
4133
4134   my $count = $artist_rs->first->cds->count;
4135
4136   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4137
4138   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4139
4140   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4141
4142 that cmp_ok() may or may not pass depending on the datasets involved. This
4143 behavior may or may not survive the 0.09 transition.
4144
4145 =back
4146
4147 =head2 page
4148
4149 =over 4
4150
4151 =item Value: $page
4152
4153 =back
4154
4155 Makes the resultset paged and specifies the page to retrieve. Effectively
4156 identical to creating a non-pages resultset and then calling ->page($page)
4157 on it.
4158
4159 If L</rows> attribute is not specified it defaults to 10 rows per page.
4160
4161 When you have a paged resultset, L</count> will only return the number
4162 of rows in the page. To get the total, use the L</pager> and call
4163 C<total_entries> on it.
4164
4165 =head2 rows
4166
4167 =over 4
4168
4169 =item Value: $rows
4170
4171 =back
4172
4173 Specifies the maximum number of rows for direct retrieval or the number of
4174 rows per page if the page attribute or method is used.
4175
4176 =head2 offset
4177
4178 =over 4
4179
4180 =item Value: $offset
4181
4182 =back
4183
4184 Specifies the (zero-based) row number for the  first row to be returned, or the
4185 of the first row of the first page if paging is used.
4186
4187 =head2 group_by
4188
4189 =over 4
4190
4191 =item Value: \@columns
4192
4193 =back
4194
4195 A arrayref of columns to group by. Can include columns of joined tables.
4196
4197   group_by => [qw/ column1 column2 ... /]
4198
4199 =head2 having
4200
4201 =over 4
4202
4203 =item Value: $condition
4204
4205 =back
4206
4207 HAVING is a select statement attribute that is applied between GROUP BY and
4208 ORDER BY. It is applied to the after the grouping calculations have been
4209 done.
4210
4211   having => { 'count_employee' => { '>=', 100 } }
4212
4213 or with an in-place function in which case literal SQL is required:
4214
4215   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4216
4217 =head2 distinct
4218
4219 =over 4
4220
4221 =item Value: (0 | 1)
4222
4223 =back
4224
4225 Set to 1 to group by all columns. If the resultset already has a group_by
4226 attribute, this setting is ignored and an appropriate warning is issued.
4227
4228 =head2 where
4229
4230 =over 4
4231
4232 Adds to the WHERE clause.
4233
4234   # only return rows WHERE deleted IS NULL for all searches
4235   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4236
4237 Can be overridden by passing C<< { where => undef } >> as an attribute
4238 to a resultset.
4239
4240 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4241
4242 =back
4243
4244 =head2 cache
4245
4246 Set to 1 to cache search results. This prevents extra SQL queries if you
4247 revisit rows in your ResultSet:
4248
4249   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4250
4251   while( my $artist = $resultset->next ) {
4252     ... do stuff ...
4253   }
4254
4255   $rs->first; # without cache, this would issue a query
4256
4257 By default, searches are not cached.
4258
4259 For more examples of using these attributes, see
4260 L<DBIx::Class::Manual::Cookbook>.
4261
4262 =head2 for
4263
4264 =over 4
4265
4266 =item Value: ( 'update' | 'shared' )
4267
4268 =back
4269
4270 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4271 ... FOR SHARED.
4272
4273 =cut
4274
4275 1;