lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304
 305   if (ref $class) {
 306     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 307     return $class->new_result(@_);
 308   }
 309
 310   my ($source, $attrs) = @_;
 311   $source = $source->resolve
 312     if $source->isa('DBIx::Class::ResultSourceHandle');
 313
 314   $attrs = { %{$attrs||{}} };
 315   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 316
 317   if ($attrs->{page}) {
 318     $attrs->{rows} ||= 10;
 319   }
 320
 321   $attrs->{alias} ||= 'me';
 322
 323   my $self = bless {
 324     result_source => $source,
 325     cond => $attrs->{where},
 326     pager => undef,
 327     attrs => $attrs,
 328   }, $class;
 329
 330   # if there is a dark selector, this means we are already in a
 331   # chain and the cleanup/sanification was taken care of by
 332   # _search_rs already
 333   $self->_normalize_selection($attrs)
 334     unless $attrs->{_dark_selector};
 335
 336   $self->result_class(
 337     $attrs->{result_class} || $source->result_class
 338   );
 339
 340   $self;
 341 }
 342
 343 =head2 search
 344
 345 =over 4
 346
 347 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 348
 349 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 350
 351 =back
 352
 353   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 354   my $new_rs = $cd_rs->search({ year => 2005 });
 355
 356   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 357                  # year = 2005 OR year = 2004
 358
 359 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 360 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 361 To avoid that, use L</search_rs>.
 362
 363 If you need to pass in additional attributes but no additional condition,
 364 call it as C<search(undef, \%attrs)>.
 365
 366   # "SELECT name, artistid FROM $artist_table"
 367   my @all_artists = $schema->resultset('Artist')->search(undef, {
 368     columns => [qw/name artistid/],
 369   });
 370
 371 For a list of attributes that can be passed to C<search>, see
 372 L</ATTRIBUTES>. For more examples of using this function, see
 373 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 374 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 375 and its extension L<DBIx::Class::SQLMaker>.
 376
 377 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 378
 379 =head3 CAVEAT
 380
 381 Note that L</search> does not process/deflate any of the values passed in the
 382 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 383 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 384 manually that any value passed to this method will stringify to something the
 385 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 386 objects, for more info see:
 387 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 388
 389 =cut
 390
 391 sub search {
 392   my $self = shift;
 393   my $rs = $self->search_rs( @_ );
 394
 395   if (wantarray) {
 396     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 397     return $rs->all;
 398   }
 399   elsif (defined wantarray) {
 400     return $rs;
 401   }
 402   else {
 403     # we can be called by a relationship helper, which in
 404     # turn may be called in void context due to some braindead
 405     # overload or whatever else the user decided to be clever
 406     # at this particular day. Thus limit the exception to
 407     # external code calls only
 408     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 409       if (caller)[0] !~ /^\QDBIx::Class::/;
 410
 411     return ();
 412   }
 413 }
 414
 415 =head2 search_rs
 416
 417 =over 4
 418
 419 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 420
 421 =item Return Value: L<$resultset|/search>
 422
 423 =back
 424
 425 This method does the same exact thing as search() except it will
 426 always return a resultset, even in list context.
 427
 428 =cut
 429
 430 sub search_rs {
 431   my $self = shift;
 432
 433   my $rsrc = $self->result_source;
 434   my ($call_cond, $call_attrs);
 435
 436   # Special-case handling for (undef, undef) or (undef)
 437   # Note that (foo => undef) is valid deprecated syntax
 438   @_ = () if not scalar grep { defined $_ } @_;
 439
 440   # just a cond
 441   if (@_ == 1) {
 442     $call_cond = shift;
 443   }
 444   # fish out attrs in the ($condref, $attr) case
 445   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 446     ($call_cond, $call_attrs) = @_;
 447   }
 448   elsif (@_ % 2) {
 449     $self->throw_exception('Odd number of arguments to search')
 450   }
 451   # legacy search
 452   elsif (@_) {
 453     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 454       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 455
 456     for my $i (0 .. $#_) {
 457       next if $i % 2;
 458       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 459         if (! defined $_[$i] or ref $_[$i] ne '');
 460     }
 461
 462     $call_cond = { @_ };
 463   }
 464
 465   # see if we can keep the cache (no $rs changes)
 466   my $cache;
 467   my %safe = (alias => 1, cache => 1);
 468   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 469     ! defined $call_cond
 470       or
 471     ref $call_cond eq 'HASH' && ! keys %$call_cond
 472       or
 473     ref $call_cond eq 'ARRAY' && ! @$call_cond
 474   )) {
 475     $cache = $self->get_cache;
 476   }
 477
 478   my $old_attrs = { %{$self->{attrs}} };
 479   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 480
 481   my $new_attrs = { %$old_attrs };
 482
 483   # take care of call attrs (only if anything is changing)
 484   if ($call_attrs and keys %$call_attrs) {
 485
 486     # copy for _normalize_selection
 487     $call_attrs = { %$call_attrs };
 488
 489     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 490
 491     # reset the current selector list if new selectors are supplied
 492     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 493       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 494     }
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 my $dark_sel_dumper;
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => ($dark_sel_dumper ||= do {
 622                   require Data::Dumper::Concise;
 623                   Data::Dumper::Concise::DumperObject()->Indent(0);
 624                 })->Values([$_])->Dump
 625               ,
 626             };
 627             last SELECTOR;
 628           }
 629         }
 630       }
 631     }
 632     elsif (@$as < @$sel) {
 633       $self->throw_exception(
 634         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 635       );
 636     }
 637     elsif ($pref and $attrs->{_dark_selector}) {
 638       $self->throw_exception(
 639         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 640       );
 641     }
 642
 643
 644     # merge result
 645     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 646     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 647   }
 648 }
 649
 650 sub _stack_cond {
 651   my ($self, $left, $right) = @_;
 652
 653   (
 654     (ref $_ eq 'ARRAY' and !@$_)
 655       or
 656     (ref $_ eq 'HASH' and ! keys %$_)
 657   ) and $_ = undef for ($left, $right);
 658
 659   # either on of the two undef or both undef
 660   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 661     return defined $left ? $left : $right;
 662   }
 663
 664   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 665
 666   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 667
 668     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 669     my @fin = shift @vals;
 670
 671     for my $v (@vals) {
 672       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 673     }
 674
 675     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 676   }
 677
 678   $cond;
 679 }
 680
 681 =head2 search_literal
 682
 683 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 684 should only be used in that context. C<search_literal> is a convenience
 685 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 686 want to ensure columns are bound correctly, use L</search>.
 687
 688 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 689 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 690 require C<search_literal>.
 691
 692 =over 4
 693
 694 =item Arguments: $sql_fragment, @standalone_bind_values
 695
 696 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 697
 698 =back
 699
 700   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 701   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 702
 703 Pass a literal chunk of SQL to be added to the conditional part of the
 704 resultset query.
 705
 706 Example of how to use C<search> instead of C<search_literal>
 707
 708   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 709   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 710
 711 =cut
 712
 713 sub search_literal {
 714   my ($self, $sql, @bind) = @_;
 715   my $attr;
 716   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 717     $attr = pop @bind;
 718   }
 719   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 720 }
 721
 722 =head2 find
 723
 724 =over 4
 725
 726 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 727
 728 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 729
 730 =back
 731
 732 Finds and returns a single row based on supplied criteria. Takes either a
 733 hashref with the same format as L</create> (including inference of foreign
 734 keys from related objects), or a list of primary key values in the same
 735 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 736 declaration on the L</result_source>.
 737
 738 In either case an attempt is made to combine conditions already existing on
 739 the resultset with the condition passed to this method.
 740
 741 To aid with preparing the correct query for the storage you may supply the
 742 C<key> attribute, which is the name of a
 743 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 744 unique constraint corresponding to the
 745 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 746 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 747 to construct a query that satisfies the named unique constraint fully (
 748 non-NULL values for each column member of the constraint) an exception is
 749 thrown.
 750
 751 If no C<key> is specified, the search is carried over all unique constraints
 752 which are fully defined by the available condition.
 753
 754 If no such constraint is found, C<find> currently defaults to a simple
 755 C<< search->(\%column_values) >> which may or may not do what you expect.
 756 Note that this fallback behavior may be deprecated in further versions. If
 757 you need to search with arbitrary conditions - use L</search>. If the query
 758 resulting from this fallback produces more than one row, a warning to the
 759 effect is issued, though only the first row is constructed and returned as
 760 C<$result_object>.
 761
 762 In addition to C<key>, L</find> recognizes and applies standard
 763 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 764
 765 Note that if you have extra concerns about the correctness of the resulting
 766 query you need to specify the C<key> attribute and supply the entire condition
 767 as an argument to find (since it is not always possible to perform the
 768 combination of the resultset condition with the supplied one, especially if
 769 the resultset condition contains literal sql).
 770
 771 For example, to find a row by its primary key:
 772
 773   my $cd = $schema->resultset('CD')->find(5);
 774
 775 You can also find a row by a specific unique constraint:
 776
 777   my $cd = $schema->resultset('CD')->find(
 778     {
 779       artist => 'Massive Attack',
 780       title  => 'Mezzanine',
 781     },
 782     { key => 'cd_artist_title' }
 783   );
 784
 785 See also L</find_or_create> and L</update_or_create>.
 786
 787 =cut
 788
 789 sub find {
 790   my $self = shift;
 791   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 792
 793   my $rsrc = $self->result_source;
 794
 795   my $constraint_name;
 796   if (exists $attrs->{key}) {
 797     $constraint_name = defined $attrs->{key}
 798       ? $attrs->{key}
 799       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 800     ;
 801   }
 802
 803   # Parse out the condition from input
 804   my $call_cond;
 805
 806   if (ref $_[0] eq 'HASH') {
 807     $call_cond = { %{$_[0]} };
 808   }
 809   else {
 810     # if only values are supplied we need to default to 'primary'
 811     $constraint_name = 'primary' unless defined $constraint_name;
 812
 813     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 814
 815     $self->throw_exception(
 816       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 817     ) unless @c_cols;
 818
 819     $self->throw_exception (
 820       'find() expects either a column/value hashref, or a list of values '
 821     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 822     ) unless @c_cols == @_;
 823
 824     @{$call_cond}{@c_cols} = @_;
 825   }
 826
 827   # process relationship data if any
 828   for my $key (keys %$call_cond) {
 829     if (
 830       length ref($call_cond->{$key})
 831         and
 832       my $relinfo = $rsrc->relationship_info($key)
 833         and
 834       # implicitly skip has_many's (likely MC)
 835       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 836     ) {
 837       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 838         $relinfo->{cond}, $val, $key, $key
 839       );
 840
 841       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 842          if $crosstable or ref($rel_cond) ne 'HASH';
 843
 844       # supplement condition
 845       # relationship conditions take precedence (?)
 846       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 847     }
 848   }
 849
 850   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 851   my $final_cond;
 852   if (defined $constraint_name) {
 853     $final_cond = $self->_qualify_cond_columns (
 854
 855       $self->result_source->_minimal_valueset_satisfying_constraint(
 856         constraint_name => $constraint_name,
 857         values => ($self->_merge_with_rscond($call_cond))[0],
 858         carp_on_nulls => 1,
 859       ),
 860
 861       $alias,
 862     );
 863   }
 864   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 865     # This means that we got here after a merger of relationship conditions
 866     # in ::Relationship::Base::search_related (the row method), and furthermore
 867     # the relationship is of the 'single' type. This means that the condition
 868     # provided by the relationship (already attached to $self) is sufficient,
 869     # as there can be only one row in the database that would satisfy the
 870     # relationship
 871   }
 872   else {
 873     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 874
 875     # no key was specified - fall down to heuristics mode:
 876     # run through all unique queries registered on the resultset, and
 877     # 'OR' all qualifying queries together
 878     #
 879     # always start from 'primary' if it exists at all
 880     for my $c_name ( sort {
 881         $a eq 'primary' ? -1
 882       : $b eq 'primary' ? 1
 883       : $a cmp $b
 884     } $rsrc->unique_constraint_names) {
 885
 886       next if $seen_column_combinations{
 887         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 888       }++;
 889
 890       try {
 891         push @unique_queries, $self->_qualify_cond_columns(
 892           $self->result_source->_minimal_valueset_satisfying_constraint(
 893             constraint_name => $c_name,
 894             values => ($self->_merge_with_rscond($call_cond))[0],
 895             columns_info => ($ci ||= $self->result_source->columns_info),
 896           ),
 897           $alias
 898         );
 899       }
 900       catch {
 901         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 902       };
 903     }
 904
 905     $final_cond =
 906         @unique_queries   ? \@unique_queries
 907       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 908       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 909     ;
 910   }
 911
 912   # Run the query, passing the result_class since it should propagate for find
 913   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 914   if ($rs->_resolved_attrs->{collapse}) {
 915     my $row = $rs->next;
 916     carp "Query returned more than one row" if $rs->next;
 917     return $row;
 918   }
 919   else {
 920     return $rs->single;
 921   }
 922 }
 923
 924 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 925 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 926 #
 927 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 928 # condition. It is provided for overrides until a saner way forward is devised
 929 #
 930 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 931 # the road. Please adjust your tests accordingly to catch this situation early
 932 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 933 #
 934 # The method will not be removed without an adequately complete replacement
 935 # for strict-mode enforcement
 936 sub _non_unique_find_fallback {
 937   my ($self, $cond, $attrs) = @_;
 938
 939   return $self->_qualify_cond_columns(
 940     $cond,
 941     exists $attrs->{alias}
 942       ? $attrs->{alias}
 943       : $self->{attrs}{alias}
 944   );
 945 }
 946
 947
 948 sub _qualify_cond_columns {
 949   my ($self, $cond, $alias) = @_;
 950
 951   my %aliased = %$cond;
 952   for (keys %aliased) {
 953     $aliased{"$alias.$_"} = delete $aliased{$_}
 954       if $_ !~ /\./;
 955   }
 956
 957   return \%aliased;
 958 }
 959
 960 sub _build_unique_cond {
 961   carp_unique sprintf
 962     '_build_unique_cond is a private method, and moreover is about to go '
 963   . 'away. Please contact the development team at %s if you believe you '
 964   . 'have a genuine use for this method, in order to discuss alternatives.',
 965     DBIx::Class::_ENV_::HELP_URL,
 966   ;
 967
 968   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 969
 970   $self->result_source->_minimal_valueset_satisfying_constraint(
 971     constraint_name => $constraint_name,
 972     values => $cond,
 973     carp_on_nulls => !$croak_on_null
 974   );
 975 }
 976
 977 =head2 search_related
 978
 979 =over 4
 980
 981 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 982
 983 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 984
 985 =back
 986
 987   $new_rs = $cd_rs->search_related('artist', {
 988     name => 'Emo-R-Us',
 989   });
 990
 991 Searches the specified relationship, optionally specifying a condition and
 992 attributes for matching records. See L</ATTRIBUTES> for more information.
 993
 994 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 995 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 996
 997 See also L</search_related_rs>.
 998
 999 =cut
1000
1001 sub search_related {
1002   return shift->related_resultset(shift)->search(@_);
1003 }
1004
1005 =head2 search_related_rs
1006
1007 This method works exactly the same as search_related, except that
1008 it guarantees a resultset, even in list context.
1009
1010 =cut
1011
1012 sub search_related_rs {
1013   return shift->related_resultset(shift)->search_rs(@_);
1014 }
1015
1016 =head2 cursor
1017
1018 =over 4
1019
1020 =item Arguments: none
1021
1022 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1023
1024 =back
1025
1026 Returns a storage-driven cursor to the given resultset. See
1027 L<DBIx::Class::Cursor> for more information.
1028
1029 =cut
1030
1031 sub cursor {
1032   my $self = shift;
1033
1034   return $self->{cursor} ||= do {
1035     my $attrs = $self->_resolved_attrs;
1036     $self->result_source->storage->select(
1037       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1038     );
1039   };
1040 }
1041
1042 =head2 single
1043
1044 =over 4
1045
1046 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1047
1048 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1049
1050 =back
1051
1052   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1053
1054 Inflates the first result without creating a cursor if the resultset has
1055 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1056 of L</search>.
1057
1058 While this method can take an optional search condition (just like L</search>)
1059 being a fast-code-path it does not recognize search attributes. If you need to
1060 add extra joins or similar, call L</search> and then chain-call L</single> on the
1061 L<DBIx::Class::ResultSet> returned.
1062
1063 =over
1064
1065 =item B<Note>
1066
1067 As of 0.08100, this method enforces the assumption that the preceding
1068 query returns only one row. If more than one row is returned, you will receive
1069 a warning:
1070
1071   Query returned more than one row
1072
1073 In this case, you should be using L</next> or L</find> instead, or if you really
1074 know what you are doing, use the L</rows> attribute to explicitly limit the size
1075 of the resultset.
1076
1077 This method will also throw an exception if it is called on a resultset prefetching
1078 has_many, as such a prefetch implies fetching multiple rows from the database in
1079 order to assemble the resulting object.
1080
1081 =back
1082
1083 =cut
1084
1085 sub single {
1086   my ($self, $where) = @_;
1087   if(@_ > 2) {
1088       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1089   }
1090
1091   my $attrs = { %{$self->_resolved_attrs} };
1092
1093   $self->throw_exception(
1094     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1095   ) if $attrs->{collapse};
1096
1097   if ($where) {
1098     if (defined $attrs->{where}) {
1099       $attrs->{where} = {
1100         '-and' =>
1101             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1102                $where, delete $attrs->{where} ]
1103       };
1104     } else {
1105       $attrs->{where} = $where;
1106     }
1107   }
1108
1109   my $data = [ $self->result_source->storage->select_single(
1110     $attrs->{from}, $attrs->{select},
1111     $attrs->{where}, $attrs
1112   )];
1113
1114   return undef unless @$data;
1115   $self->{_stashed_rows} = [ $data ];
1116   $self->_construct_results->[0];
1117 }
1118
1119 =head2 get_column
1120
1121 =over 4
1122
1123 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1124
1125 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1126
1127 =back
1128
1129   my $max_length = $rs->get_column('length')->max;
1130
1131 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1132
1133 =cut
1134
1135 sub get_column {
1136   my ($self, $column) = @_;
1137   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1138   return $new;
1139 }
1140
1141 =head2 search_like
1142
1143 =over 4
1144
1145 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1146
1147 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1148
1149 =back
1150
1151   # WHERE title LIKE '%blue%'
1152   $cd_rs = $rs->search_like({ title => '%blue%'});
1153
1154 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1155 that this is simply a convenience method retained for ex Class::DBI users.
1156 You most likely want to use L</search> with specific operators.
1157
1158 For more information, see L<DBIx::Class::Manual::Cookbook>.
1159
1160 This method is deprecated and will be removed in 0.09. Use L</search()>
1161 instead. An example conversion is:
1162
1163   ->search_like({ foo => 'bar' });
1164
1165   # Becomes
1166
1167   ->search({ foo => { like => 'bar' } });
1168
1169 =cut
1170
1171 sub search_like {
1172   my $class = shift;
1173   carp_unique (
1174     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1175    .' Instead use ->search({ x => { -like => "y%" } })'
1176    .' (note the outer pair of {}s - they are important!)'
1177   );
1178   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1179   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1180   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1181   return $class->search($query, { %$attrs });
1182 }
1183
1184 =head2 slice
1185
1186 =over 4
1187
1188 =item Arguments: $first, $last
1189
1190 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1191
1192 =back
1193
1194 Returns a resultset or object list representing a subset of elements from the
1195 resultset slice is called on. Indexes are from 0, i.e., to get the first
1196 three records, call:
1197
1198   my ($one, $two, $three) = $rs->slice(0, 2);
1199
1200 =cut
1201
1202 sub slice {
1203   my ($self, $min, $max) = @_;
1204   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1205   $attrs->{offset} = $self->{attrs}{offset} || 0;
1206   $attrs->{offset} += $min;
1207   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1208   return $self->search(undef, $attrs);
1209 }
1210
1211 =head2 next
1212
1213 =over 4
1214
1215 =item Arguments: none
1216
1217 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1218
1219 =back
1220
1221 Returns the next element in the resultset (C<undef> is there is none).
1222
1223 Can be used to efficiently iterate over records in the resultset:
1224
1225   my $rs = $schema->resultset('CD')->search;
1226   while (my $cd = $rs->next) {
1227     print $cd->title;
1228   }
1229
1230 Note that you need to store the resultset object, and call C<next> on it.
1231 Calling C<< resultset('Table')->next >> repeatedly will always return the
1232 first record from the resultset.
1233
1234 =cut
1235
1236 sub next {
1237   my ($self) = @_;
1238
1239   if (my $cache = $self->get_cache) {
1240     $self->{all_cache_position} ||= 0;
1241     return $cache->[$self->{all_cache_position}++];
1242   }
1243
1244   if ($self->{attrs}{cache}) {
1245     delete $self->{pager};
1246     $self->{all_cache_position} = 1;
1247     return ($self->all)[0];
1248   }
1249
1250   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1251
1252   $self->{_stashed_results} = $self->_construct_results
1253     or return undef;
1254
1255   return shift @{$self->{_stashed_results}};
1256 }
1257
1258 # Constructs as many results as it can in one pass while respecting
1259 # cursor laziness. Several modes of operation:
1260 #
1261 # * Always builds everything present in @{$self->{_stashed_rows}}
1262 # * If called with $fetch_all true - pulls everything off the cursor and
1263 #   builds all result structures (or objects) in one pass
1264 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1265 #   and if the resultset is ordered properly by the left side:
1266 #   * Fetches stuff off the cursor until the "master object" changes,
1267 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1268 #   OR
1269 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1270 #     was requested (there is no other way to collapse except for an
1271 #     eager cursor)
1272 # * If no collapse is requested - just get the next row, construct and
1273 #   return
1274 sub _construct_results {
1275   my ($self, $fetch_all) = @_;
1276
1277   my $rsrc = $self->result_source;
1278   my $attrs = $self->_resolved_attrs;
1279
1280   if (
1281     ! $fetch_all
1282       and
1283     ! $attrs->{order_by}
1284       and
1285     $attrs->{collapse}
1286       and
1287     my @pcols = $rsrc->primary_columns
1288   ) {
1289     # default order for collapsing unless the user asked for something
1290     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1291     $attrs->{_ordered_for_collapse} = 1;
1292     $attrs->{_order_is_artificial} = 1;
1293   }
1294
1295   # this will be used as both initial raw-row collector AND as a RV of
1296   # _construct_results. Not regrowing the array twice matters a lot...
1297   # a surprising amount actually
1298   my $rows = delete $self->{_stashed_rows};
1299
1300   my $cursor; # we may not need one at all
1301
1302   my $did_fetch_all = $fetch_all;
1303
1304   if ($fetch_all) {
1305     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1306     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1307   }
1308   elsif( $attrs->{collapse} ) {
1309
1310     # a cursor will need to be closed over in case of collapse
1311     $cursor = $self->cursor;
1312
1313     $attrs->{_ordered_for_collapse} = (
1314       (
1315         $attrs->{order_by}
1316           and
1317         $rsrc->schema
1318               ->storage
1319                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1320       ) ? 1 : 0
1321     ) unless defined $attrs->{_ordered_for_collapse};
1322
1323     if (! $attrs->{_ordered_for_collapse}) {
1324       $did_fetch_all = 1;
1325
1326       # instead of looping over ->next, use ->all in stealth mode
1327       # *without* calling a ->reset afterwards
1328       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1329       if (! $cursor->{_done}) {
1330         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1331         $cursor->{_done} = 1;
1332       }
1333     }
1334   }
1335
1336   if (! $did_fetch_all and ! @{$rows||[]} ) {
1337     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1338     $cursor ||= $self->cursor;
1339     if (scalar (my @r = $cursor->next) ) {
1340       $rows = [ \@r ];
1341     }
1342   }
1343
1344   return undef unless @{$rows||[]};
1345
1346   # sanity check - people are too clever for their own good
1347   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1348
1349     my $multiplied_selectors;
1350     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1351       if (
1352         $aliastypes->{multiplying}{$sel_alias}
1353           or
1354         $aliastypes->{premultiplied}{$sel_alias}
1355       ) {
1356         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1357       }
1358     }
1359
1360     for my $i (0 .. $#{$attrs->{as}} ) {
1361       my $sel = $attrs->{select}[$i];
1362
1363       if (ref $sel eq 'SCALAR') {
1364         $sel = $$sel;
1365       }
1366       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1367         $sel = $$sel->[0];
1368       }
1369
1370       $self->throw_exception(
1371         'Result collapse not possible - selection from a has_many source redirected to the main object'
1372       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1373     }
1374   }
1375
1376   # hotspot - skip the setter
1377   my $res_class = $self->_result_class;
1378
1379   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1380     $res_class->can ('inflate_result')
1381       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1382   };
1383
1384   my $infmap = $attrs->{as};
1385
1386   $self->{_result_inflator}{is_core_row} = ( (
1387     $inflator_cref
1388       ==
1389     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1390   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1391
1392   $self->{_result_inflator}{is_hri} = ( (
1393     ! $self->{_result_inflator}{is_core_row}
1394       and
1395     $inflator_cref == (
1396       require DBIx::Class::ResultClass::HashRefInflator
1397         &&
1398       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1399     )
1400   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1401
1402
1403   if ($attrs->{_simple_passthrough_construction}) {
1404     # construct a much simpler array->hash folder for the one-table HRI cases right here
1405     if ($self->{_result_inflator}{is_hri}) {
1406       for my $r (@$rows) {
1407         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1408       }
1409     }
1410     # FIXME SUBOPTIMAL this is a very very very hot spot
1411     # while rather optimal we can *still* do much better, by
1412     # building a smarter Row::inflate_result(), and
1413     # switch to feeding it data via a much leaner interface
1414     #
1415     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1416     # this particular resultset size
1417     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1418       for my $r (@$rows) {
1419         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1420       }
1421     }
1422     else {
1423       eval sprintf (
1424         ( $self->{_result_inflator}{is_core_row}
1425           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1426           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1427           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1428         ),
1429         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1430       );
1431     }
1432   }
1433   else {
1434     my $parser_type =
1435         $self->{_result_inflator}{is_hri}       ? 'hri'
1436       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1437       :                                           'classic_nonpruning'
1438     ;
1439
1440     # $args and $attrs to _mk_row_parser are separated to delineate what is
1441     # core collapser stuff and what is dbic $rs specific
1442     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1443       eval => 1,
1444       inflate_map => $infmap,
1445       collapse => $attrs->{collapse},
1446       premultiplied => $attrs->{_main_source_premultiplied},
1447       hri_style => $self->{_result_inflator}{is_hri},
1448       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1449     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1450
1451     # column_info metadata historically hasn't been too reliable.
1452     # We need to start fixing this somehow (the collapse resolver
1453     # can't work without it). Add an explicit check for the *main*
1454     # result, hopefully this will gradually weed out such errors
1455     #
1456     # FIXME - this is a temporary kludge that reduces performance
1457     # It is however necessary for the time being
1458     my ($unrolled_non_null_cols_to_check, $err);
1459
1460     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1461
1462       $err =
1463         'Collapse aborted due to invalid ResultSource metadata - the following '
1464       . 'selections are declared non-nullable but NULLs were retrieved: '
1465       ;
1466
1467       my @violating_idx;
1468       COL: for my $i (@$check_non_null_cols) {
1469         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1470       }
1471
1472       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1473         if @violating_idx;
1474
1475       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1476     }
1477
1478     my $next_cref =
1479       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1480     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1481 sub {
1482   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1483   my @r = $cursor->next or return;
1484   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1485     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1486   }
1487   \@r
1488 }
1489 EOS
1490     : sub {
1491         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1492         my @r = $cursor->next or return;
1493         \@r
1494       }
1495     ;
1496
1497     $self->{_row_parser}{$parser_type}{cref}->(
1498       $rows,
1499       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1500     );
1501
1502     # simple in-place substitution, does not regrow $rows
1503     if ($self->{_result_inflator}{is_core_row}) {
1504       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1505     }
1506     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1507     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1508       # the inflator may be a multiplier/reductor - put it in list ctx
1509       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1510     }
1511   }
1512
1513   # The @$rows check seems odd at first - why wouldn't we want to warn
1514   # regardless? The issue is things like find() etc, where the user
1515   # *knows* only one result will come back. In these cases the ->all
1516   # is not a pessimization, but rather something we actually want
1517   carp_unique(
1518     'Unable to properly collapse has_many results in iterator mode due '
1519   . 'to order criteria - performed an eager cursor slurp underneath. '
1520   . 'Consider using ->all() instead'
1521   ) if ( ! $fetch_all and @$rows > 1 );
1522
1523   return $rows;
1524 }
1525
1526 =head2 result_source
1527
1528 =over 4
1529
1530 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1531
1532 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1533
1534 =back
1535
1536 An accessor for the primary ResultSource object from which this ResultSet
1537 is derived.
1538
1539 =head2 result_class
1540
1541 =over 4
1542
1543 =item Arguments: $result_class?
1544
1545 =item Return Value: $result_class
1546
1547 =back
1548
1549 An accessor for the class to use when creating result objects. Defaults to
1550 C<< result_source->result_class >> - which in most cases is the name of the
1551 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1552
1553 Note that changing the result_class will also remove any components
1554 that were originally loaded in the source class via
1555 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1556 in the original source class will not run.
1557
1558 =cut
1559
1560 sub result_class {
1561   my ($self, $result_class) = @_;
1562   if ($result_class) {
1563
1564     # don't fire this for an object
1565     $self->ensure_class_loaded($result_class)
1566       unless ref($result_class);
1567
1568     if ($self->get_cache) {
1569       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1570     }
1571     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1572     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1573       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1574     }
1575
1576     $self->_result_class($result_class);
1577
1578     delete $self->{_result_inflator};
1579   }
1580   $self->_result_class;
1581 }
1582
1583 =head2 count
1584
1585 =over 4
1586
1587 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1588
1589 =item Return Value: $count
1590
1591 =back
1592
1593 Performs an SQL C<COUNT> with the same query as the resultset was built
1594 with to find the number of elements. Passing arguments is equivalent to
1595 C<< $rs->search ($cond, \%attrs)->count >>
1596
1597 =cut
1598
1599 sub count {
1600   my $self = shift;
1601   return $self->search(@_)->count if @_ and defined $_[0];
1602   return scalar @{ $self->get_cache } if $self->get_cache;
1603
1604   my $attrs = { %{ $self->_resolved_attrs } };
1605
1606   # this is a little optimization - it is faster to do the limit
1607   # adjustments in software, instead of a subquery
1608   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1609
1610   my $crs;
1611   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1612     $crs = $self->_count_subq_rs ($attrs);
1613   }
1614   else {
1615     $crs = $self->_count_rs ($attrs);
1616   }
1617   my $count = $crs->next;
1618
1619   $count -= $offset if $offset;
1620   $count = $rows if $rows and $rows < $count;
1621   $count = 0 if ($count < 0);
1622
1623   return $count;
1624 }
1625
1626 =head2 count_rs
1627
1628 =over 4
1629
1630 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1631
1632 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1633
1634 =back
1635
1636 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1637 This can be very handy for subqueries:
1638
1639   ->search( { amount => $some_rs->count_rs->as_query } )
1640
1641 As with regular resultsets the SQL query will be executed only after
1642 the resultset is accessed via L</next> or L</all>. That would return
1643 the same single value obtainable via L</count>.
1644
1645 =cut
1646
1647 sub count_rs {
1648   my $self = shift;
1649   return $self->search(@_)->count_rs if @_;
1650
1651   # this may look like a lack of abstraction (count() does about the same)
1652   # but in fact an _rs *must* use a subquery for the limits, as the
1653   # software based limiting can not be ported if this $rs is to be used
1654   # in a subquery itself (i.e. ->as_query)
1655   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1656     return $self->_count_subq_rs($self->{_attrs});
1657   }
1658   else {
1659     return $self->_count_rs($self->{_attrs});
1660   }
1661 }
1662
1663 #
1664 # returns a ResultSetColumn object tied to the count query
1665 #
1666 sub _count_rs {
1667   my ($self, $attrs) = @_;
1668
1669   my $rsrc = $self->result_source;
1670
1671   my $tmp_attrs = { %$attrs };
1672   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1673   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1674
1675   # overwrite the selector (supplied by the storage)
1676   $rsrc->resultset_class->new($rsrc, {
1677     %$tmp_attrs,
1678     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1679     as => 'count',
1680   })->get_column ('count');
1681 }
1682
1683 #
1684 # same as above but uses a subquery
1685 #
1686 sub _count_subq_rs {
1687   my ($self, $attrs) = @_;
1688
1689   my $rsrc = $self->result_source;
1690
1691   my $sub_attrs = { %$attrs };
1692   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1693   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1694
1695   # if we multi-prefetch we group_by something unique, as this is what we would
1696   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1697   if ( $attrs->{collapse}  ) {
1698     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1699       $rsrc->_identifying_column_set || $self->throw_exception(
1700         'Unable to construct a unique group_by criteria properly collapsing the '
1701       . 'has_many prefetch before count()'
1702       );
1703     } ]
1704   }
1705
1706   # Calculate subquery selector
1707   if (my $g = $sub_attrs->{group_by}) {
1708
1709     my $sql_maker = $rsrc->storage->sql_maker;
1710
1711     # necessary as the group_by may refer to aliased functions
1712     my $sel_index;
1713     for my $sel (@{$attrs->{select}}) {
1714       $sel_index->{$sel->{-as}} = $sel
1715         if (ref $sel eq 'HASH' and $sel->{-as});
1716     }
1717
1718     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1719     # also look for named aggregates referred in the having clause
1720     # having often contains scalarrefs - thus parse it out entirely
1721     my @parts = @$g;
1722     if ($attrs->{having}) {
1723       local $sql_maker->{having_bind};
1724       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1725       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1726       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1727         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1728         # if we don't unset it we screw up retarded but unfortunately working
1729         # 'MAX(foo.bar)' => { '>', 3 }
1730         $sql_maker->{name_sep} = '';
1731       }
1732
1733       my $sep = quotemeta($sql_maker->name_sep);
1734       my $ident_re = $sql_maker->_quoted_ident_re;
1735
1736       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1737       my %seen_having;
1738
1739       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1740       # and if all fails for an utterly naive quoted scalar-with-function
1741       while ($having_sql =~ /
1742         $ident_re $sep ($ident_re)
1743           |
1744         [\s,] \w+ \. (\w+) [\s,]
1745           |
1746         [\s,] ($ident_re) [\s,]
1747       /gx) {
1748         my $part = $sql_maker->_unquote($1 || $2 || $3);  # one of them matched if we got here
1749         unless ($seen_having{$part}++) {
1750           push @parts, $part;
1751         }
1752       }
1753     }
1754
1755     for (@parts) {
1756       my $colpiece = $sel_index->{$_} || $_;
1757
1758       # unqualify join-based group_by's. Arcane but possible query
1759       # also horrible horrible hack to alias a column (not a func.)
1760       # (probably need to introduce SQLA syntax)
1761       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1762         my $as = $colpiece;
1763         $as =~ s/\./__/;
1764         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1765       }
1766       push @{$sub_attrs->{select}}, $colpiece;
1767     }
1768   }
1769   else {
1770     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1771     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1772   }
1773
1774   return $rsrc->resultset_class
1775                ->new ($rsrc, $sub_attrs)
1776                 ->as_subselect_rs
1777                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1778                   ->get_column ('count');
1779 }
1780
1781
1782 =head2 count_literal
1783
1784 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1785 should only be used in that context. See L</search_literal> for further info.
1786
1787 =over 4
1788
1789 =item Arguments: $sql_fragment, @standalone_bind_values
1790
1791 =item Return Value: $count
1792
1793 =back
1794
1795 Counts the results in a literal query. Equivalent to calling L</search_literal>
1796 with the passed arguments, then L</count>.
1797
1798 =cut
1799
1800 sub count_literal { shift->search_literal(@_)->count; }
1801
1802 =head2 all
1803
1804 =over 4
1805
1806 =item Arguments: none
1807
1808 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1809
1810 =back
1811
1812 Returns all elements in the resultset.
1813
1814 =cut
1815
1816 sub all {
1817   my $self = shift;
1818   if(@_) {
1819     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1820   }
1821
1822   delete @{$self}{qw/_stashed_rows _stashed_results/};
1823
1824   if (my $c = $self->get_cache) {
1825     return @$c;
1826   }
1827
1828   $self->cursor->reset;
1829
1830   my $objs = $self->_construct_results('fetch_all') || [];
1831
1832   $self->set_cache($objs) if $self->{attrs}{cache};
1833
1834   return @$objs;
1835 }
1836
1837 =head2 reset
1838
1839 =over 4
1840
1841 =item Arguments: none
1842
1843 =item Return Value: $self
1844
1845 =back
1846
1847 Resets the resultset's cursor, so you can iterate through the elements again.
1848 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1849 another query.
1850
1851 =cut
1852
1853 sub reset {
1854   my ($self) = @_;
1855
1856   delete @{$self}{qw/_stashed_rows _stashed_results/};
1857   $self->{all_cache_position} = 0;
1858   $self->cursor->reset;
1859   return $self;
1860 }
1861
1862 =head2 first
1863
1864 =over 4
1865
1866 =item Arguments: none
1867
1868 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1869
1870 =back
1871
1872 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1873 an object for the first result (or C<undef> if the resultset is empty).
1874
1875 =cut
1876
1877 sub first {
1878   return $_[0]->reset->next;
1879 }
1880
1881
1882 # _rs_update_delete
1883 #
1884 # Determines whether and what type of subquery is required for the $rs operation.
1885 # If grouping is necessary either supplies its own, or verifies the current one
1886 # After all is done delegates to the proper storage method.
1887
1888 sub _rs_update_delete {
1889   my ($self, $op, $values) = @_;
1890
1891   my $rsrc = $self->result_source;
1892   my $storage = $rsrc->schema->storage;
1893
1894   my $attrs = { %{$self->_resolved_attrs} };
1895
1896   my $join_classifications;
1897   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1898
1899   # do we need a subquery for any reason?
1900   my $needs_subq = (
1901     defined $existing_group_by
1902       or
1903     # if {from} is unparseable wrap a subq
1904     ref($attrs->{from}) ne 'ARRAY'
1905       or
1906     # limits call for a subq
1907     $self->_has_resolved_attr(qw/rows offset/)
1908   );
1909
1910   # simplify the joinmap, so we can further decide if a subq is necessary
1911   if (!$needs_subq and @{$attrs->{from}} > 1) {
1912
1913     ($attrs->{from}, $join_classifications) =
1914       $storage->_prune_unused_joins ($attrs);
1915
1916     # any non-pruneable non-local restricting joins imply subq
1917     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1918   }
1919
1920   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1921   $needs_subq ||= (
1922     (ref $attrs->{from}[0]) ne 'HASH'
1923       or
1924     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1925   );
1926
1927   my ($cond, $guard);
1928   # do we need anything like a subquery?
1929   if (! $needs_subq) {
1930     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1931     # a condition containing 'me' or other table prefixes will not work
1932     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1933     $cond = do {
1934       my $sqla = $rsrc->storage->sql_maker;
1935       local $sqla->{_dequalify_idents} = 1;
1936       \[ $sqla->_recurse_where($self->{cond}) ];
1937     };
1938   }
1939   else {
1940     # we got this far - means it is time to wrap a subquery
1941     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1942       sprintf(
1943         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1944         $op,
1945         $rsrc->source_name,
1946       )
1947     );
1948
1949     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1950     delete $attrs->{$_} for qw/select as collapse/;
1951     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1952
1953     # this will be consumed by the pruner waaaaay down the stack
1954     $attrs->{_force_prune_multiplying_joins} = 1;
1955
1956     my $subrs = (ref $self)->new($rsrc, $attrs);
1957
1958     if (@$idcols == 1) {
1959       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1960     }
1961     elsif ($storage->_use_multicolumn_in) {
1962       # no syntax for calling this properly yet
1963       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1964       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1965         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1966         $subrs->as_query
1967       ),
1968     }
1969     else {
1970       # if all else fails - get all primary keys and operate over a ORed set
1971       # wrap in a transaction for consistency
1972       # this is where the group_by/multiplication starts to matter
1973       if (
1974         $existing_group_by
1975           or
1976         # we do not need to check pre-multipliers, since if the premulti is there, its
1977         # parent (who is multi) will be there too
1978         keys %{ $join_classifications->{multiplying} || {} }
1979       ) {
1980         # make sure if there is a supplied group_by it matches the columns compiled above
1981         # perfectly. Anything else can not be sanely executed on most databases so croak
1982         # right then and there
1983         if ($existing_group_by) {
1984           my @current_group_by = map
1985             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1986             @$existing_group_by
1987           ;
1988
1989           if (
1990             join ("\x00", sort @current_group_by)
1991               ne
1992             join ("\x00", sort @{$attrs->{columns}} )
1993           ) {
1994             $self->throw_exception (
1995               "You have just attempted a $op operation on a resultset which does group_by"
1996               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1997               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1998               . ' kind of queries. Please retry the operation with a modified group_by or'
1999               . ' without using one at all.'
2000             );
2001           }
2002         }
2003
2004         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2005       }
2006
2007       $guard = $storage->txn_scope_guard;
2008
2009       for my $row ($subrs->cursor->all) {
2010         push @$cond, { map
2011           { $idcols->[$_] => $row->[$_] }
2012           (0 .. $#$idcols)
2013         };
2014       }
2015     }
2016   }
2017
2018   my $res = $cond ? $storage->$op (
2019     $rsrc,
2020     $op eq 'update' ? $values : (),
2021     $cond,
2022   ) : '0E0';
2023
2024   $guard->commit if $guard;
2025
2026   return $res;
2027 }
2028
2029 =head2 update
2030
2031 =over 4
2032
2033 =item Arguments: \%values
2034
2035 =item Return Value: $underlying_storage_rv
2036
2037 =back
2038
2039 Sets the specified columns in the resultset to the supplied values in a
2040 single query. Note that this will not run any accessor/set_column/update
2041 triggers, nor will it update any result object instances derived from this
2042 resultset (this includes the contents of the L<resultset cache|/set_cache>
2043 if any). See L</update_all> if you need to execute any on-update
2044 triggers or cascades defined either by you or a
2045 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2046
2047 The return value is a pass through of what the underlying
2048 storage backend returned, and may vary. See L<DBI/execute> for the most
2049 common case.
2050
2051 =head3 CAVEAT
2052
2053 Note that L</update> does not process/deflate any of the values passed in.
2054 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2055 ensure manually that any value passed to this method will stringify to
2056 something the RDBMS knows how to deal with. A notable example is the
2057 handling of L<DateTime> objects, for more info see:
2058 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2059
2060 =cut
2061
2062 sub update {
2063   my ($self, $values) = @_;
2064   $self->throw_exception('Values for update must be a hash')
2065     unless ref $values eq 'HASH';
2066
2067   return $self->_rs_update_delete ('update', $values);
2068 }
2069
2070 =head2 update_all
2071
2072 =over 4
2073
2074 =item Arguments: \%values
2075
2076 =item Return Value: 1
2077
2078 =back
2079
2080 Fetches all objects and updates them one at a time via
2081 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2082 triggers, while L</update> will not.
2083
2084 =cut
2085
2086 sub update_all {
2087   my ($self, $values) = @_;
2088   $self->throw_exception('Values for update_all must be a hash')
2089     unless ref $values eq 'HASH';
2090
2091   my $guard = $self->result_source->schema->txn_scope_guard;
2092   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2093   $guard->commit;
2094   return 1;
2095 }
2096
2097 =head2 delete
2098
2099 =over 4
2100
2101 =item Arguments: none
2102
2103 =item Return Value: $underlying_storage_rv
2104
2105 =back
2106
2107 Deletes the rows matching this resultset in a single query. Note that this
2108 will not run any delete triggers, nor will it alter the
2109 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2110 derived from this resultset (this includes the contents of the
2111 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2112 execute any on-delete triggers or cascades defined either by you or a
2113 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2114
2115 The return value is a pass through of what the underlying storage backend
2116 returned, and may vary. See L<DBI/execute> for the most common case.
2117
2118 =cut
2119
2120 sub delete {
2121   my $self = shift;
2122   $self->throw_exception('delete does not accept any arguments')
2123     if @_;
2124
2125   return $self->_rs_update_delete ('delete');
2126 }
2127
2128 =head2 delete_all
2129
2130 =over 4
2131
2132 =item Arguments: none
2133
2134 =item Return Value: 1
2135
2136 =back
2137
2138 Fetches all objects and deletes them one at a time via
2139 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2140 triggers, while L</delete> will not.
2141
2142 =cut
2143
2144 sub delete_all {
2145   my $self = shift;
2146   $self->throw_exception('delete_all does not accept any arguments')
2147     if @_;
2148
2149   my $guard = $self->result_source->schema->txn_scope_guard;
2150   $_->delete for $self->all;
2151   $guard->commit;
2152   return 1;
2153 }
2154
2155 =head2 populate
2156
2157 =over 4
2158
2159 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2160
2161 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2162
2163 =back
2164
2165 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2166 arrayrefs.
2167
2168 =over
2169
2170 =item NOTE
2171
2172 The context of this method call has an important effect on what is
2173 submitted to storage. In void context data is fed directly to fastpath
2174 insertion routines provided by the underlying storage (most often
2175 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2176 L<insert|DBIx::Class::Row/insert> calls on the
2177 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2178 augmentation of these methods provided by components. For example if you
2179 are using something like L<DBIx::Class::UUIDColumns> to create primary
2180 keys for you, you will find that your PKs are empty.  In this case you
2181 will have to explicitly force scalar or list context in order to create
2182 those values.
2183
2184 =back
2185
2186 In non-void (scalar or list) context, this method is simply a wrapper
2187 for L</create>. Depending on list or scalar context either a list of
2188 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2189 containing these objects is returned.
2190
2191 When supplying data in "arrayref of arrayrefs" invocation style, the
2192 first element should be a list of column names and each subsequent
2193 element should be a data value in the earlier specified column order.
2194 For example:
2195
2196   $schema->resultset("Artist")->populate([
2197     [ qw( artistid name ) ],
2198     [ 100, 'A Formally Unknown Singer' ],
2199     [ 101, 'A singer that jumped the shark two albums ago' ],
2200     [ 102, 'An actually cool singer' ],
2201   ]);
2202
2203 For the arrayref of hashrefs style each hashref should be a structure
2204 suitable for passing to L</create>. Multi-create is also permitted with
2205 this syntax.
2206
2207   $schema->resultset("Artist")->populate([
2208      { artistid => 4, name => 'Manufactured Crap', cds => [
2209         { title => 'My First CD', year => 2006 },
2210         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2211       ],
2212      },
2213      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2214         { title => 'My parents sold me to a record company', year => 2005 },
2215         { title => 'Why Am I So Ugly?', year => 2006 },
2216         { title => 'I Got Surgery and am now Popular', year => 2007 }
2217       ],
2218      },
2219   ]);
2220
2221 If you attempt a void-context multi-create as in the example above (each
2222 Artist also has the related list of CDs), and B<do not> supply the
2223 necessary autoinc foreign key information, this method will proxy to the
2224 less efficient L</create>, and then throw the Result objects away. In this
2225 case there are obviously no benefits to using this method over L</create>.
2226
2227 =cut
2228
2229 sub populate {
2230   my $self = shift;
2231
2232   # this is naive and just a quick check
2233   # the types will need to be checked more thoroughly when the
2234   # multi-source populate gets added
2235   my $data = (
2236     ref $_[0] eq 'ARRAY'
2237       and
2238     ( @{$_[0]} or return )
2239       and
2240     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2241       and
2242     $_[0]
2243   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2244
2245   # FIXME - no cref handling
2246   # At this point assume either hashes or arrays
2247
2248   if(defined wantarray) {
2249     my (@results, $guard);
2250
2251     if (ref $data->[0] eq 'ARRAY') {
2252       # column names only, nothing to do
2253       return if @$data == 1;
2254
2255       $guard = $self->result_source->schema->storage->txn_scope_guard
2256         if @$data > 2;
2257
2258       @results = map
2259         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2260         @{$data}[1 .. $#$data]
2261       ;
2262     }
2263     else {
2264
2265       $guard = $self->result_source->schema->storage->txn_scope_guard
2266         if @$data > 1;
2267
2268       @results = map { $self->new_result($_)->insert } @$data;
2269     }
2270
2271     $guard->commit if $guard;
2272     return wantarray ? @results : \@results;
2273   }
2274
2275   # we have to deal with *possibly incomplete* related data
2276   # this means we have to walk the data structure twice
2277   # whether we want this or not
2278   # jnap, I hate you ;)
2279   my $rsrc = $self->result_source;
2280   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2281
2282   my ($colinfo, $colnames, $slices_with_rels);
2283   my $data_start = 0;
2284
2285   DATA_SLICE:
2286   for my $i (0 .. $#$data) {
2287
2288     my $current_slice_seen_rel_infos;
2289
2290 ### Determine/Supplement collists
2291 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2292     if( ref $data->[$i] eq 'ARRAY' ) {
2293
2294       # positional(!) explicit column list
2295       if ($i == 0) {
2296         # column names only, nothing to do
2297         return if @$data == 1;
2298
2299         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2300           for 0 .. $#{$data->[0]};
2301
2302         $data_start = 1;
2303
2304         next DATA_SLICE;
2305       }
2306       else {
2307         for (values %$colinfo) {
2308           if ($_->{is_rel} ||= (
2309             $rel_info->{$_->{name}}
2310               and
2311             (
2312               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2313                 or
2314               ref $data->[$i][$_->{pos}] eq 'HASH'
2315                 or
2316               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2317             )
2318               and
2319             1
2320           )) {
2321
2322             # moar sanity check... sigh
2323             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2324               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2325                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2326                 return my $throwaway = $self->populate(@_);
2327               }
2328             }
2329
2330             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2331           }
2332         }
2333       }
2334
2335      if ($current_slice_seen_rel_infos) {
2336         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2337
2338         # this is needed further down to decide whether or not to fallback to create()
2339         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2340           for 0 .. $#$colnames;
2341       }
2342     }
2343     elsif( ref $data->[$i] eq 'HASH' ) {
2344
2345       for ( sort keys %{$data->[$i]} ) {
2346
2347         $colinfo->{$_} ||= do {
2348
2349           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2350             if $data_start; # it will be 0 on AoH, 1 on AoA
2351
2352           push @$colnames, $_;
2353
2354           # RV
2355           { pos => $#$colnames, name => $_ }
2356         };
2357
2358         if ($colinfo->{$_}{is_rel} ||= (
2359           $rel_info->{$_}
2360             and
2361           (
2362             ref $data->[$i]{$_} eq 'ARRAY'
2363               or
2364             ref $data->[$i]{$_} eq 'HASH'
2365               or
2366             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2367           )
2368             and
2369           1
2370         )) {
2371
2372           # moar sanity check... sigh
2373           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2374             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2375               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2376               return my $throwaway = $self->populate(@_);
2377             }
2378           }
2379
2380           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2381         }
2382       }
2383
2384       if ($current_slice_seen_rel_infos) {
2385         push @$slices_with_rels, $data->[$i];
2386
2387         # this is needed further down to decide whether or not to fallback to create()
2388         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2389           for keys %{$data->[$i]};
2390       }
2391     }
2392     else {
2393       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2394     }
2395
2396     if ( grep
2397       { $_->{attrs}{is_depends_on} }
2398       @{ $current_slice_seen_rel_infos || [] }
2399     ) {
2400       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2401       return my $throwaway = $self->populate(@_);
2402     }
2403   }
2404
2405   if( $slices_with_rels ) {
2406
2407     # need to exclude the rel "columns"
2408     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2409
2410     # extra sanity check - ensure the main source is in fact identifiable
2411     # the localizing of nullability is insane, but oh well... the use-case is legit
2412     my $ci = $rsrc->columns_info($colnames);
2413
2414     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2415       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2416
2417     unless( $rsrc->_identifying_column_set($ci) ) {
2418       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2419       return my $throwaway = $self->populate(@_);
2420     }
2421   }
2422
2423 ### inherit the data locked in the conditions of the resultset
2424   my ($rs_data) = $self->_merge_with_rscond({});
2425   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2426
2427   # if anything left - decompose rs_data
2428   my $rs_data_vals;
2429   if (keys %$rs_data) {
2430      push @$rs_data_vals, $rs_data->{$_}
2431       for sort keys %$rs_data;
2432   }
2433
2434 ### start work
2435   my $guard;
2436   $guard = $rsrc->schema->storage->txn_scope_guard
2437     if $slices_with_rels;
2438
2439 ### main source data
2440   # FIXME - need to switch entirely to a coderef-based thing,
2441   # so that large sets aren't copied several times... I think
2442   $rsrc->storage->_insert_bulk(
2443     $rsrc,
2444     [ @$colnames, sort keys %$rs_data ],
2445     [ map {
2446       ref $data->[$_] eq 'ARRAY'
2447       ? (
2448           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2449         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2450         :                     $data->[$_]
2451       )
2452       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2453     } $data_start .. $#$data ],
2454   );
2455
2456 ### do the children relationships
2457   if ( $slices_with_rels ) {
2458     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2459       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2460
2461     for my $sl (@$slices_with_rels) {
2462
2463       my ($main_proto, $main_proto_rs);
2464       for my $rel (@rels) {
2465         next unless defined $sl->{$rel};
2466
2467         $main_proto ||= {
2468           %$rs_data,
2469           (map { $_ => $sl->{$_} } @$colnames),
2470         };
2471
2472         unless (defined $colinfo->{$rel}{rs}) {
2473
2474           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2475
2476           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2477             rel_name => $rel,
2478             self_alias => "\xFE", # irrelevant
2479             foreign_alias => "\xFF", # irrelevant
2480           )->{identity_map} || {} } };
2481
2482         }
2483
2484         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2485           {
2486             $_ => { '=' =>
2487               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2488                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2489                  ->as_query
2490             }
2491           }
2492           keys %{$colinfo->{$rel}{fk_map}}
2493         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2494
2495         1;
2496       }
2497     }
2498   }
2499
2500   $guard->commit if $guard;
2501 }
2502
2503 =head2 pager
2504
2505 =over 4
2506
2507 =item Arguments: none
2508
2509 =item Return Value: L<$pager|Data::Page>
2510
2511 =back
2512
2513 Returns a L<Data::Page> object for the current resultset. Only makes
2514 sense for queries with a C<page> attribute.
2515
2516 To get the full count of entries for a paged resultset, call
2517 C<total_entries> on the L<Data::Page> object.
2518
2519 =cut
2520
2521 sub pager {
2522   my ($self) = @_;
2523
2524   return $self->{pager} if $self->{pager};
2525
2526   my $attrs = $self->{attrs};
2527   if (!defined $attrs->{page}) {
2528     $self->throw_exception("Can't create pager for non-paged rs");
2529   }
2530   elsif ($attrs->{page} <= 0) {
2531     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2532   }
2533   $attrs->{rows} ||= 10;
2534
2535   # throw away the paging flags and re-run the count (possibly
2536   # with a subselect) to get the real total count
2537   my $count_attrs = { %$attrs };
2538   delete @{$count_attrs}{qw/rows offset page pager/};
2539
2540   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2541
2542   require DBIx::Class::ResultSet::Pager;
2543   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2544     sub { $total_rs->count },  #lazy-get the total
2545     $attrs->{rows},
2546     $self->{attrs}{page},
2547   );
2548 }
2549
2550 =head2 page
2551
2552 =over 4
2553
2554 =item Arguments: $page_number
2555
2556 =item Return Value: L<$resultset|/search>
2557
2558 =back
2559
2560 Returns a resultset for the $page_number page of the resultset on which page
2561 is called, where each page contains a number of rows equal to the 'rows'
2562 attribute set on the resultset (10 by default).
2563
2564 =cut
2565
2566 sub page {
2567   my ($self, $page) = @_;
2568   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2569 }
2570
2571 =head2 new_result
2572
2573 =over 4
2574
2575 =item Arguments: \%col_data
2576
2577 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2578
2579 =back
2580
2581 Creates a new result object in the resultset's result class and returns
2582 it. The row is not inserted into the database at this point, call
2583 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2584 will tell you whether the result object has been inserted or not.
2585
2586 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2587
2588 =cut
2589
2590 sub new_result {
2591   my ($self, $values) = @_;
2592
2593   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2594     if @_ > 2;
2595
2596   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2597     unless (ref $values eq 'HASH');
2598
2599   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2600
2601   my $new = $self->result_class->new({
2602     %$merged_cond,
2603     ( @$cols_from_relations
2604       ? (-cols_from_relations => $cols_from_relations)
2605       : ()
2606     ),
2607     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2608   });
2609
2610   if (
2611     reftype($new) eq 'HASH'
2612       and
2613     ! keys %$new
2614       and
2615     blessed($new)
2616   ) {
2617     carp_unique (sprintf (
2618       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2619       $self->result_class,
2620     ));
2621   }
2622
2623   $new;
2624 }
2625
2626 # _merge_with_rscond
2627 #
2628 # Takes a simple hash of K/V data and returns its copy merged with the
2629 # condition already present on the resultset. Additionally returns an
2630 # arrayref of value/condition names, which were inferred from related
2631 # objects (this is needed for in-memory related objects)
2632 sub _merge_with_rscond {
2633   my ($self, $data) = @_;
2634
2635   my ($implied_data, @cols_from_relations);
2636
2637   my $alias = $self->{attrs}{alias};
2638
2639   if (! defined $self->{cond}) {
2640     # just massage $data below
2641   }
2642   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2643     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2644     @cols_from_relations = keys %{ $implied_data || {} };
2645   }
2646   else {
2647     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2648     $implied_data = { map {
2649       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2650     } keys %$eqs };
2651   }
2652
2653   return (
2654     { map
2655       { %{ $self->_remove_alias($_, $alias) } }
2656       # precedence must be given to passed values over values inherited from
2657       # the cond, so the order here is important.
2658       ( $implied_data||(), $data)
2659     },
2660     \@cols_from_relations
2661   );
2662 }
2663
2664 # _has_resolved_attr
2665 #
2666 # determines if the resultset defines at least one
2667 # of the attributes supplied
2668 #
2669 # used to determine if a subquery is necessary
2670 #
2671 # supports some virtual attributes:
2672 #   -join
2673 #     This will scan for any joins being present on the resultset.
2674 #     It is not a mere key-search but a deep inspection of {from}
2675 #
2676
2677 sub _has_resolved_attr {
2678   my ($self, @attr_names) = @_;
2679
2680   my $attrs = $self->_resolved_attrs;
2681
2682   my %extra_checks;
2683
2684   for my $n (@attr_names) {
2685     if (grep { $n eq $_ } (qw/-join/) ) {
2686       $extra_checks{$n}++;
2687       next;
2688     }
2689
2690     my $attr =  $attrs->{$n};
2691
2692     next if not defined $attr;
2693
2694     if (ref $attr eq 'HASH') {
2695       return 1 if keys %$attr;
2696     }
2697     elsif (ref $attr eq 'ARRAY') {
2698       return 1 if @$attr;
2699     }
2700     else {
2701       return 1 if $attr;
2702     }
2703   }
2704
2705   # a resolved join is expressed as a multi-level from
2706   return 1 if (
2707     $extra_checks{-join}
2708       and
2709     ref $attrs->{from} eq 'ARRAY'
2710       and
2711     @{$attrs->{from}} > 1
2712   );
2713
2714   return 0;
2715 }
2716
2717 # _remove_alias
2718 #
2719 # Remove the specified alias from the specified query hash. A copy is made so
2720 # the original query is not modified.
2721
2722 sub _remove_alias {
2723   my ($self, $query, $alias) = @_;
2724
2725   my %orig = %{ $query || {} };
2726   my %unaliased;
2727
2728   foreach my $key (keys %orig) {
2729     if ($key !~ /\./) {
2730       $unaliased{$key} = $orig{$key};
2731       next;
2732     }
2733     $unaliased{$1} = $orig{$key}
2734       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2735   }
2736
2737   return \%unaliased;
2738 }
2739
2740 =head2 as_query
2741
2742 =over 4
2743
2744 =item Arguments: none
2745
2746 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2747
2748 =back
2749
2750 Returns the SQL query and bind vars associated with the invocant.
2751
2752 This is generally used as the RHS for a subquery.
2753
2754 =cut
2755
2756 sub as_query {
2757   my $self = shift;
2758
2759   my $attrs = { %{ $self->_resolved_attrs } };
2760
2761   my $aq = $self->result_source->storage->_select_args_to_query (
2762     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2763   );
2764
2765   $aq;
2766 }
2767
2768 =head2 find_or_new
2769
2770 =over 4
2771
2772 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2773
2774 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2775
2776 =back
2777
2778   my $artist = $schema->resultset('Artist')->find_or_new(
2779     { artist => 'fred' }, { key => 'artists' });
2780
2781   $cd->cd_to_producer->find_or_new({ producer => $producer },
2782                                    { key => 'primary' });
2783
2784 Find an existing record from this resultset using L</find>. if none exists,
2785 instantiate a new result object and return it. The object will not be saved
2786 into your storage until you call L<DBIx::Class::Row/insert> on it.
2787
2788 You most likely want this method when looking for existing rows using a unique
2789 constraint that is not the primary key, or looking for related rows.
2790
2791 If you want objects to be saved immediately, use L</find_or_create> instead.
2792
2793 B<Note>: Make sure to read the documentation of L</find> and understand the
2794 significance of the C<key> attribute, as its lack may skew your search, and
2795 subsequently result in spurious new objects.
2796
2797 B<Note>: Take care when using C<find_or_new> with a table having
2798 columns with default values that you intend to be automatically
2799 supplied by the database (e.g. an auto_increment primary key column).
2800 In normal usage, the value of such columns should NOT be included at
2801 all in the call to C<find_or_new>, even when set to C<undef>.
2802
2803 =cut
2804
2805 sub find_or_new {
2806   my $self     = shift;
2807   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2808   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2809   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2810     return $row;
2811   }
2812   return $self->new_result($hash);
2813 }
2814
2815 =head2 create
2816
2817 =over 4
2818
2819 =item Arguments: \%col_data
2820
2821 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2822
2823 =back
2824
2825 Attempt to create a single new row or a row with multiple related rows
2826 in the table represented by the resultset (and related tables). This
2827 will not check for duplicate rows before inserting, use
2828 L</find_or_create> to do that.
2829
2830 To create one row for this resultset, pass a hashref of key/value
2831 pairs representing the columns of the table and the values you wish to
2832 store. If the appropriate relationships are set up, foreign key fields
2833 can also be passed an object representing the foreign row, and the
2834 value will be set to its primary key.
2835
2836 To create related objects, pass a hashref of related-object column values
2837 B<keyed on the relationship name>. If the relationship is of type C<multi>
2838 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2839 The process will correctly identify columns holding foreign keys, and will
2840 transparently populate them from the keys of the corresponding relation.
2841 This can be applied recursively, and will work correctly for a structure
2842 with an arbitrary depth and width, as long as the relationships actually
2843 exists and the correct column data has been supplied.
2844
2845 Instead of hashrefs of plain related data (key/value pairs), you may
2846 also pass new or inserted objects. New objects (not inserted yet, see
2847 L</new_result>), will be inserted into their appropriate tables.
2848
2849 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2850
2851 Example of creating a new row.
2852
2853   $person_rs->create({
2854     name=>"Some Person",
2855     email=>"somebody@someplace.com"
2856   });
2857
2858 Example of creating a new row and also creating rows in a related C<has_many>
2859 or C<has_one> resultset.  Note Arrayref.
2860
2861   $artist_rs->create(
2862      { artistid => 4, name => 'Manufactured Crap', cds => [
2863         { title => 'My First CD', year => 2006 },
2864         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2865       ],
2866      },
2867   );
2868
2869 Example of creating a new row and also creating a row in a related
2870 C<belongs_to> resultset. Note Hashref.
2871
2872   $cd_rs->create({
2873     title=>"Music for Silly Walks",
2874     year=>2000,
2875     artist => {
2876       name=>"Silly Musician",
2877     }
2878   });
2879
2880 =over
2881
2882 =item WARNING
2883
2884 When subclassing ResultSet never attempt to override this method. Since
2885 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2886 lot of the internals simply never call it, so your override will be
2887 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2888 or L<DBIx::Class::Row/insert> depending on how early in the
2889 L</create> process you need to intervene. See also warning pertaining to
2890 L</new>.
2891
2892 =back
2893
2894 =cut
2895
2896 sub create {
2897   #my ($self, $col_data) = @_;
2898   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2899   return shift->new_result(shift)->insert;
2900 }
2901
2902 =head2 find_or_create
2903
2904 =over 4
2905
2906 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2907
2908 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2909
2910 =back
2911
2912   $cd->cd_to_producer->find_or_create({ producer => $producer },
2913                                       { key => 'primary' });
2914
2915 Tries to find a record based on its primary key or unique constraints; if none
2916 is found, creates one and returns that instead.
2917
2918   my $cd = $schema->resultset('CD')->find_or_create({
2919     cdid   => 5,
2920     artist => 'Massive Attack',
2921     title  => 'Mezzanine',
2922     year   => 2005,
2923   });
2924
2925 Also takes an optional C<key> attribute, to search by a specific key or unique
2926 constraint. For example:
2927
2928   my $cd = $schema->resultset('CD')->find_or_create(
2929     {
2930       artist => 'Massive Attack',
2931       title  => 'Mezzanine',
2932     },
2933     { key => 'cd_artist_title' }
2934   );
2935
2936 B<Note>: Make sure to read the documentation of L</find> and understand the
2937 significance of the C<key> attribute, as its lack may skew your search, and
2938 subsequently result in spurious row creation.
2939
2940 B<Note>: Because find_or_create() reads from the database and then
2941 possibly inserts based on the result, this method is subject to a race
2942 condition. Another process could create a record in the table after
2943 the find has completed and before the create has started. To avoid
2944 this problem, use find_or_create() inside a transaction.
2945
2946 B<Note>: Take care when using C<find_or_create> with a table having
2947 columns with default values that you intend to be automatically
2948 supplied by the database (e.g. an auto_increment primary key column).
2949 In normal usage, the value of such columns should NOT be included at
2950 all in the call to C<find_or_create>, even when set to C<undef>.
2951
2952 See also L</find> and L</update_or_create>. For information on how to declare
2953 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2954
2955 If you need to know if an existing row was found or a new one created use
2956 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2957 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2958 database!
2959
2960   my $cd = $schema->resultset('CD')->find_or_new({
2961     cdid   => 5,
2962     artist => 'Massive Attack',
2963     title  => 'Mezzanine',
2964     year   => 2005,
2965   });
2966
2967   if( !$cd->in_storage ) {
2968       # do some stuff
2969       $cd->insert;
2970   }
2971
2972 =cut
2973
2974 sub find_or_create {
2975   my $self     = shift;
2976   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2977   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2978   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2979     return $row;
2980   }
2981   return $self->new_result($hash)->insert;
2982 }
2983
2984 =head2 update_or_create
2985
2986 =over 4
2987
2988 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2989
2990 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2991
2992 =back
2993
2994   $resultset->update_or_create({ col => $val, ... });
2995
2996 Like L</find_or_create>, but if a row is found it is immediately updated via
2997 C<< $found_row->update (\%col_data) >>.
2998
2999
3000 Takes an optional C<key> attribute to search on a specific unique constraint.
3001 For example:
3002
3003   # In your application
3004   my $cd = $schema->resultset('CD')->update_or_create(
3005     {
3006       artist => 'Massive Attack',
3007       title  => 'Mezzanine',
3008       year   => 1998,
3009     },
3010     { key => 'cd_artist_title' }
3011   );
3012
3013   $cd->cd_to_producer->update_or_create({
3014     producer => $producer,
3015     name => 'harry',
3016   }, {
3017     key => 'primary',
3018   });
3019
3020 B<Note>: Make sure to read the documentation of L</find> and understand the
3021 significance of the C<key> attribute, as its lack may skew your search, and
3022 subsequently result in spurious row creation.
3023
3024 B<Note>: Take care when using C<update_or_create> with a table having
3025 columns with default values that you intend to be automatically
3026 supplied by the database (e.g. an auto_increment primary key column).
3027 In normal usage, the value of such columns should NOT be included at
3028 all in the call to C<update_or_create>, even when set to C<undef>.
3029
3030 See also L</find> and L</find_or_create>. For information on how to declare
3031 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3032
3033 If you need to know if an existing row was updated or a new one created use
3034 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3035 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3036 database!
3037
3038 =cut
3039
3040 sub update_or_create {
3041   my $self = shift;
3042   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3043   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3044
3045   my $row = $self->find($cond, $attrs);
3046   if (defined $row) {
3047     $row->update($cond);
3048     return $row;
3049   }
3050
3051   return $self->new_result($cond)->insert;
3052 }
3053
3054 =head2 update_or_new
3055
3056 =over 4
3057
3058 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3059
3060 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3061
3062 =back
3063
3064   $resultset->update_or_new({ col => $val, ... });
3065
3066 Like L</find_or_new> but if a row is found it is immediately updated via
3067 C<< $found_row->update (\%col_data) >>.
3068
3069 For example:
3070
3071   # In your application
3072   my $cd = $schema->resultset('CD')->update_or_new(
3073     {
3074       artist => 'Massive Attack',
3075       title  => 'Mezzanine',
3076       year   => 1998,
3077     },
3078     { key => 'cd_artist_title' }
3079   );
3080
3081   if ($cd->in_storage) {
3082       # the cd was updated
3083   }
3084   else {
3085       # the cd is not yet in the database, let's insert it
3086       $cd->insert;
3087   }
3088
3089 B<Note>: Make sure to read the documentation of L</find> and understand the
3090 significance of the C<key> attribute, as its lack may skew your search, and
3091 subsequently result in spurious new objects.
3092
3093 B<Note>: Take care when using C<update_or_new> with a table having
3094 columns with default values that you intend to be automatically
3095 supplied by the database (e.g. an auto_increment primary key column).
3096 In normal usage, the value of such columns should NOT be included at
3097 all in the call to C<update_or_new>, even when set to C<undef>.
3098
3099 See also L</find>, L</find_or_create> and L</find_or_new>.
3100
3101 =cut
3102
3103 sub update_or_new {
3104     my $self  = shift;
3105     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3106     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3107
3108     my $row = $self->find( $cond, $attrs );
3109     if ( defined $row ) {
3110         $row->update($cond);
3111         return $row;
3112     }
3113
3114     return $self->new_result($cond);
3115 }
3116
3117 =head2 get_cache
3118
3119 =over 4
3120
3121 =item Arguments: none
3122
3123 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3124
3125 =back
3126
3127 Gets the contents of the cache for the resultset, if the cache is set.
3128
3129 The cache is populated either by using the L</prefetch> attribute to
3130 L</search> or by calling L</set_cache>.
3131
3132 =cut
3133
3134 sub get_cache {
3135   shift->{all_cache};
3136 }
3137
3138 =head2 set_cache
3139
3140 =over 4
3141
3142 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3143
3144 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3145
3146 =back
3147
3148 Sets the contents of the cache for the resultset. Expects an arrayref
3149 of objects of the same class as those produced by the resultset. Note that
3150 if the cache is set, the resultset will return the cached objects rather
3151 than re-querying the database even if the cache attr is not set.
3152
3153 The contents of the cache can also be populated by using the
3154 L</prefetch> attribute to L</search>.
3155
3156 =cut
3157
3158 sub set_cache {
3159   my ( $self, $data ) = @_;
3160   $self->throw_exception("set_cache requires an arrayref")
3161       if defined($data) && (ref $data ne 'ARRAY');
3162   $self->{all_cache} = $data;
3163 }
3164
3165 =head2 clear_cache
3166
3167 =over 4
3168
3169 =item Arguments: none
3170
3171 =item Return Value: undef
3172
3173 =back
3174
3175 Clears the cache for the resultset.
3176
3177 =cut
3178
3179 sub clear_cache {
3180   shift->set_cache(undef);
3181 }
3182
3183 =head2 is_paged
3184
3185 =over 4
3186
3187 =item Arguments: none
3188
3189 =item Return Value: true, if the resultset has been paginated
3190
3191 =back
3192
3193 =cut
3194
3195 sub is_paged {
3196   my ($self) = @_;
3197   return !!$self->{attrs}{page};
3198 }
3199
3200 =head2 is_ordered
3201
3202 =over 4
3203
3204 =item Arguments: none
3205
3206 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3207
3208 =back
3209
3210 =cut
3211
3212 sub is_ordered {
3213   my ($self) = @_;
3214   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3215 }
3216
3217 =head2 related_resultset
3218
3219 =over 4
3220
3221 =item Arguments: $rel_name
3222
3223 =item Return Value: L<$resultset|/search>
3224
3225 =back
3226
3227 Returns a related resultset for the supplied relationship name.
3228
3229   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3230
3231 =cut
3232
3233 sub related_resultset {
3234   my ($self, $rel) = @_;
3235
3236   return $self->{related_resultsets}{$rel}
3237     if defined $self->{related_resultsets}{$rel};
3238
3239   return $self->{related_resultsets}{$rel} = do {
3240     my $rsrc = $self->result_source;
3241     my $rel_info = $rsrc->relationship_info($rel);
3242
3243     $self->throw_exception(
3244       "search_related: result source '" . $rsrc->source_name .
3245         "' has no such relationship $rel")
3246       unless $rel_info;
3247
3248     my $attrs = $self->_chain_relationship($rel);
3249
3250     my $join_count = $attrs->{seen_join}{$rel};
3251
3252     my $alias = $self->result_source->storage
3253         ->relname_to_table_alias($rel, $join_count);
3254
3255     # since this is search_related, and we already slid the select window inwards
3256     # (the select/as attrs were deleted in the beginning), we need to flip all
3257     # left joins to inner, so we get the expected results
3258     # read the comment on top of the actual function to see what this does
3259     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3260
3261
3262     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3263     delete @{$attrs}{qw(result_class alias)};
3264
3265     my $rel_source = $rsrc->related_source($rel);
3266
3267     my $new = do {
3268
3269       # The reason we do this now instead of passing the alias to the
3270       # search_rs below is that if you wrap/overload resultset on the
3271       # source you need to know what alias it's -going- to have for things
3272       # to work sanely (e.g. RestrictWithObject wants to be able to add
3273       # extra query restrictions, and these may need to be $alias.)
3274
3275       my $rel_attrs = $rel_source->resultset_attributes;
3276       local $rel_attrs->{alias} = $alias;
3277
3278       $rel_source->resultset
3279                  ->search_rs(
3280                      undef, {
3281                        %$attrs,
3282                        where => $attrs->{where},
3283                    });
3284     };
3285
3286     if (my $cache = $self->get_cache) {
3287       my @related_cache = map
3288         { $_->related_resultset($rel)->get_cache || () }
3289         @$cache
3290       ;
3291
3292       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3293     }
3294
3295     $new;
3296   };
3297 }
3298
3299 =head2 current_source_alias
3300
3301 =over 4
3302
3303 =item Arguments: none
3304
3305 =item Return Value: $source_alias
3306
3307 =back
3308
3309 Returns the current table alias for the result source this resultset is built
3310 on, that will be used in the SQL query. Usually it is C<me>.
3311
3312 Currently the source alias that refers to the result set returned by a
3313 L</search>/L</find> family method depends on how you got to the resultset: it's
3314 C<me> by default, but eg. L</search_related> aliases it to the related result
3315 source name (and keeps C<me> referring to the original result set). The long
3316 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3317 (and make this method unnecessary).
3318
3319 Thus it's currently necessary to use this method in predefined queries (see
3320 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3321 source alias of the current result set:
3322
3323   # in a result set class
3324   sub modified_by {
3325     my ($self, $user) = @_;
3326
3327     my $me = $self->current_source_alias;
3328
3329     return $self->search({
3330       "$me.modified" => $user->id,
3331     });
3332   }
3333
3334 =cut
3335
3336 sub current_source_alias {
3337   return (shift->{attrs} || {})->{alias} || 'me';
3338 }
3339
3340 =head2 as_subselect_rs
3341
3342 =over 4
3343
3344 =item Arguments: none
3345
3346 =item Return Value: L<$resultset|/search>
3347
3348 =back
3349
3350 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3351 "virtual view" by including it as a subquery within the from clause.  From this
3352 point on, any joined tables are inaccessible to ->search on the resultset (as if
3353 it were simply where-filtered without joins).  For example:
3354
3355  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3356
3357  # 'x' now pollutes the query namespace
3358
3359  # So the following works as expected
3360  my $ok_rs = $rs->search({'x.other' => 1});
3361
3362  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3363  # def) we look for one row with contradictory terms and join in another table
3364  # (aliased 'x_2') which we never use
3365  my $broken_rs = $rs->search({'x.name' => 'def'});
3366
3367  my $rs2 = $rs->as_subselect_rs;
3368
3369  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3370  my $not_joined_rs = $rs2->search({'x.other' => 1});
3371
3372  # works as expected: finds a 'table' row related to two x rows (abc and def)
3373  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3374
3375 Another example of when one might use this would be to select a subset of
3376 columns in a group by clause:
3377
3378  my $rs = $schema->resultset('Bar')->search(undef, {
3379    group_by => [qw{ id foo_id baz_id }],
3380  })->as_subselect_rs->search(undef, {
3381    columns => [qw{ id foo_id }]
3382  });
3383
3384 In the above example normally columns would have to be equal to the group by,
3385 but because we isolated the group by into a subselect the above works.
3386
3387 =cut
3388
3389 sub as_subselect_rs {
3390   my $self = shift;
3391
3392   my $attrs = $self->_resolved_attrs;
3393
3394   my $fresh_rs = (ref $self)->new (
3395     $self->result_source
3396   );
3397
3398   # these pieces will be locked in the subquery
3399   delete $fresh_rs->{cond};
3400   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3401
3402   return $fresh_rs->search( {}, {
3403     from => [{
3404       $attrs->{alias} => $self->as_query,
3405       -alias  => $attrs->{alias},
3406       -rsrc   => $self->result_source,
3407     }],
3408     alias => $attrs->{alias},
3409   });
3410 }
3411
3412 # This code is called by search_related, and makes sure there
3413 # is clear separation between the joins before, during, and
3414 # after the relationship. This information is needed later
3415 # in order to properly resolve prefetch aliases (any alias
3416 # with a relation_chain_depth less than the depth of the
3417 # current prefetch is not considered)
3418 #
3419 # The increments happen twice per join. An even number means a
3420 # relationship specified via a search_related, whereas an odd
3421 # number indicates a join/prefetch added via attributes
3422 #
3423 # Also this code will wrap the current resultset (the one we
3424 # chain to) in a subselect IFF it contains limiting attributes
3425 sub _chain_relationship {
3426   my ($self, $rel) = @_;
3427   my $source = $self->result_source;
3428   my $attrs = { %{$self->{attrs}||{}} };
3429
3430   # we need to take the prefetch the attrs into account before we
3431   # ->_resolve_join as otherwise they get lost - captainL
3432   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3433
3434   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3435
3436   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3437
3438   my $from;
3439   my @force_subq_attrs = qw/offset rows group_by having/;
3440
3441   if (
3442     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3443       ||
3444     $self->_has_resolved_attr (@force_subq_attrs)
3445   ) {
3446     # Nuke the prefetch (if any) before the new $rs attrs
3447     # are resolved (prefetch is useless - we are wrapping
3448     # a subquery anyway).
3449     my $rs_copy = $self->search;
3450     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3451       $rs_copy->{attrs}{join},
3452       delete $rs_copy->{attrs}{prefetch},
3453     );
3454
3455     $from = [{
3456       -rsrc   => $source,
3457       -alias  => $attrs->{alias},
3458       $attrs->{alias} => $rs_copy->as_query,
3459     }];
3460     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3461     $seen->{-relation_chain_depth} = 0;
3462   }
3463   elsif ($attrs->{from}) {  #shallow copy suffices
3464     $from = [ @{$attrs->{from}} ];
3465   }
3466   else {
3467     $from = [{
3468       -rsrc  => $source,
3469       -alias => $attrs->{alias},
3470       $attrs->{alias} => $source->from,
3471     }];
3472   }
3473
3474   my $jpath = ($seen->{-relation_chain_depth})
3475     ? $from->[-1][0]{-join_path}
3476     : [];
3477
3478   my @requested_joins = $source->_resolve_join(
3479     $join,
3480     $attrs->{alias},
3481     $seen,
3482     $jpath,
3483   );
3484
3485   push @$from, @requested_joins;
3486
3487   $seen->{-relation_chain_depth}++;
3488
3489   # if $self already had a join/prefetch specified on it, the requested
3490   # $rel might very well be already included. What we do in this case
3491   # is effectively a no-op (except that we bump up the chain_depth on
3492   # the join in question so we could tell it *is* the search_related)
3493   my $already_joined;
3494
3495   # we consider the last one thus reverse
3496   for my $j (reverse @requested_joins) {
3497     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3498     if ($rel eq $last_j) {
3499       $j->[0]{-relation_chain_depth}++;
3500       $already_joined++;
3501       last;
3502     }
3503   }
3504
3505   unless ($already_joined) {
3506     push @$from, $source->_resolve_join(
3507       $rel,
3508       $attrs->{alias},
3509       $seen,
3510       $jpath,
3511     );
3512   }
3513
3514   $seen->{-relation_chain_depth}++;
3515
3516   return {%$attrs, from => $from, seen_join => $seen};
3517 }
3518
3519 sub _resolved_attrs {
3520   my $self = shift;
3521   return $self->{_attrs} if $self->{_attrs};
3522
3523   my $attrs  = { %{ $self->{attrs} || {} } };
3524   my $source = $attrs->{result_source} = $self->result_source;
3525   my $alias  = $attrs->{alias};
3526
3527   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3528     if $attrs->{collapse} and $attrs->{distinct};
3529
3530   # default selection list
3531   $attrs->{columns} = [ $source->columns ]
3532     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3533
3534   # merge selectors together
3535   for (qw/columns select as/) {
3536     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3537       if $attrs->{$_} or $attrs->{"+$_"};
3538   }
3539
3540   # disassemble columns
3541   my (@sel, @as);
3542   if (my $cols = delete $attrs->{columns}) {
3543     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3544       if (ref $c eq 'HASH') {
3545         for my $as (sort keys %$c) {
3546           push @sel, $c->{$as};
3547           push @as, $as;
3548         }
3549       }
3550       else {
3551         push @sel, $c;
3552         push @as, $c;
3553       }
3554     }
3555   }
3556
3557   # when trying to weed off duplicates later do not go past this point -
3558   # everything added from here on is unbalanced "anyone's guess" stuff
3559   my $dedup_stop_idx = $#as;
3560
3561   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3562     if $attrs->{as};
3563   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3564     if $attrs->{select};
3565
3566   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3567   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3568
3569   # disqualify all $alias.col as-bits (inflate-map mandated)
3570   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3571
3572   # de-duplicate the result (remove *identical* select/as pairs)
3573   # and also die on duplicate {as} pointing to different {select}s
3574   # not using a c-style for as the condition is prone to shrinkage
3575   my $seen;
3576   my $i = 0;
3577   while ($i <= $dedup_stop_idx) {
3578     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3579       splice @sel, $i, 1;
3580       splice @as, $i, 1;
3581       $dedup_stop_idx--;
3582     }
3583     elsif ($seen->{$as[$i]}++) {
3584       $self->throw_exception(
3585         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3586       );
3587     }
3588     else {
3589       $i++;
3590     }
3591   }
3592
3593   $attrs->{select} = \@sel;
3594   $attrs->{as} = \@as;
3595
3596   $attrs->{from} ||= [{
3597     -rsrc   => $source,
3598     -alias  => $self->{attrs}{alias},
3599     $self->{attrs}{alias} => $source->from,
3600   }];
3601
3602   if ( $attrs->{join} || $attrs->{prefetch} ) {
3603
3604     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3605       if ref $attrs->{from} ne 'ARRAY';
3606
3607     my $join = (delete $attrs->{join}) || {};
3608
3609     if ( defined $attrs->{prefetch} ) {
3610       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3611     }
3612
3613     $attrs->{from} =    # have to copy here to avoid corrupting the original
3614       [
3615         @{ $attrs->{from} },
3616         $source->_resolve_join(
3617           $join,
3618           $alias,
3619           { %{ $attrs->{seen_join} || {} } },
3620           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3621             ? $attrs->{from}[-1][0]{-join_path}
3622             : []
3623           ,
3624         )
3625       ];
3626   }
3627
3628   if ( defined $attrs->{order_by} ) {
3629     $attrs->{order_by} = (
3630       ref( $attrs->{order_by} ) eq 'ARRAY'
3631       ? [ @{ $attrs->{order_by} } ]
3632       : [ $attrs->{order_by} || () ]
3633     );
3634   }
3635
3636   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3637     $attrs->{group_by} = [ $attrs->{group_by} ];
3638   }
3639
3640
3641   # generate selections based on the prefetch helper
3642   my ($prefetch, @prefetch_select, @prefetch_as);
3643   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3644     if defined $attrs->{prefetch};
3645
3646   if ($prefetch) {
3647
3648     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3649       if $attrs->{_dark_selector};
3650
3651     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3652       if defined $attrs->{collapse} and ! $attrs->{collapse};
3653
3654     $attrs->{collapse} = 1;
3655
3656     # this is a separate structure (we don't look in {from} directly)
3657     # as the resolver needs to shift things off the lists to work
3658     # properly (identical-prefetches on different branches)
3659     my $join_map = {};
3660     if (ref $attrs->{from} eq 'ARRAY') {
3661
3662       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3663
3664       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3665         next unless $j->[0]{-alias};
3666         next unless $j->[0]{-join_path};
3667         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3668
3669         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3670
3671         my $p = $join_map;
3672         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3673         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3674       }
3675     }
3676
3677     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3678
3679     # save these for after distinct resolution
3680     @prefetch_select = map { $_->[0] } @prefetch;
3681     @prefetch_as = map { $_->[1] } @prefetch;
3682   }
3683
3684   # run through the resulting joinstructure (starting from our current slot)
3685   # and unset collapse if proven unnecessary
3686   #
3687   # also while we are at it find out if the current root source has
3688   # been premultiplied by previous related_source chaining
3689   #
3690   # this allows to predict whether a root object with all other relation
3691   # data set to NULL is in fact unique
3692   if ($attrs->{collapse}) {
3693
3694     if (ref $attrs->{from} eq 'ARRAY') {
3695
3696       if (@{$attrs->{from}} == 1) {
3697         # no joins - no collapse
3698         $attrs->{collapse} = 0;
3699       }
3700       else {
3701         # find where our table-spec starts
3702         my @fromlist = @{$attrs->{from}};
3703         while (@fromlist) {
3704           my $t = shift @fromlist;
3705
3706           my $is_multi;
3707           # me vs join from-spec distinction - a ref means non-root
3708           if (ref $t eq 'ARRAY') {
3709             $t = $t->[0];
3710             $is_multi ||= ! $t->{-is_single};
3711           }
3712           last if ($t->{-alias} && $t->{-alias} eq $alias);
3713           $attrs->{_main_source_premultiplied} ||= $is_multi;
3714         }
3715
3716         # no non-singles remaining, nor any premultiplication - nothing to collapse
3717         if (
3718           ! $attrs->{_main_source_premultiplied}
3719             and
3720           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3721         ) {
3722           $attrs->{collapse} = 0;
3723         }
3724       }
3725     }
3726
3727     else {
3728       # if we can not analyze the from - err on the side of safety
3729       $attrs->{_main_source_premultiplied} = 1;
3730     }
3731   }
3732
3733   # generate the distinct induced group_by before injecting the prefetched select/as parts
3734   if (delete $attrs->{distinct}) {
3735     if ($attrs->{group_by}) {
3736       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3737     }
3738     else {
3739       $attrs->{_grouped_by_distinct} = 1;
3740       # distinct affects only the main selection part, not what prefetch may add below
3741       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3742
3743       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3744       # The thinking is: if we are collapsing the subquerying prefetch engine will
3745       # rip stuff apart for us anyway, and we do not want to have a potentially
3746       # function-converted external order_by
3747       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3748       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3749     }
3750   }
3751
3752   # inject prefetch-bound selection (if any)
3753   push @{$attrs->{select}}, @prefetch_select;
3754   push @{$attrs->{as}}, @prefetch_as;
3755
3756   $attrs->{_simple_passthrough_construction} = !(
3757     $attrs->{collapse}
3758       or
3759     grep { $_ =~ /\./ } @{$attrs->{as}}
3760   );
3761
3762   # if both page and offset are specified, produce a combined offset
3763   # even though it doesn't make much sense, this is what pre 081xx has
3764   # been doing
3765   if (my $page = delete $attrs->{page}) {
3766     $attrs->{offset} =
3767       ($attrs->{rows} * ($page - 1))
3768             +
3769       ($attrs->{offset} || 0)
3770     ;
3771   }
3772
3773   return $self->{_attrs} = $attrs;
3774 }
3775
3776 sub _rollout_attr {
3777   my ($self, $attr) = @_;
3778
3779   if (ref $attr eq 'HASH') {
3780     return $self->_rollout_hash($attr);
3781   } elsif (ref $attr eq 'ARRAY') {
3782     return $self->_rollout_array($attr);
3783   } else {
3784     return [$attr];
3785   }
3786 }
3787
3788 sub _rollout_array {
3789   my ($self, $attr) = @_;
3790
3791   my @rolled_array;
3792   foreach my $element (@{$attr}) {
3793     if (ref $element eq 'HASH') {
3794       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3795     } elsif (ref $element eq 'ARRAY') {
3796       #  XXX - should probably recurse here
3797       push( @rolled_array, @{$self->_rollout_array($element)} );
3798     } else {
3799       push( @rolled_array, $element );
3800     }
3801   }
3802   return \@rolled_array;
3803 }
3804
3805 sub _rollout_hash {
3806   my ($self, $attr) = @_;
3807
3808   my @rolled_array;
3809   foreach my $key (keys %{$attr}) {
3810     push( @rolled_array, { $key => $attr->{$key} } );
3811   }
3812   return \@rolled_array;
3813 }
3814
3815 sub _calculate_score {
3816   my ($self, $a, $b) = @_;
3817
3818   if (defined $a xor defined $b) {
3819     return 0;
3820   }
3821   elsif (not defined $a) {
3822     return 1;
3823   }
3824
3825   if (ref $b eq 'HASH') {
3826     my ($b_key) = keys %{$b};
3827     if (ref $a eq 'HASH') {
3828       my ($a_key) = keys %{$a};
3829       if ($a_key eq $b_key) {
3830         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3831       } else {
3832         return 0;
3833       }
3834     } else {
3835       return ($a eq $b_key) ? 1 : 0;
3836     }
3837   } else {
3838     if (ref $a eq 'HASH') {
3839       my ($a_key) = keys %{$a};
3840       return ($b eq $a_key) ? 1 : 0;
3841     } else {
3842       return ($b eq $a) ? 1 : 0;
3843     }
3844   }
3845 }
3846
3847 sub _merge_joinpref_attr {
3848   my ($self, $orig, $import) = @_;
3849
3850   return $import unless defined($orig);
3851   return $orig unless defined($import);
3852
3853   $orig = $self->_rollout_attr($orig);
3854   $import = $self->_rollout_attr($import);
3855
3856   my $seen_keys;
3857   foreach my $import_element ( @{$import} ) {
3858     # find best candidate from $orig to merge $b_element into
3859     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3860     foreach my $orig_element ( @{$orig} ) {
3861       my $score = $self->_calculate_score( $orig_element, $import_element );
3862       if ($score > $best_candidate->{score}) {
3863         $best_candidate->{position} = $position;
3864         $best_candidate->{score} = $score;
3865       }
3866       $position++;
3867     }
3868     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3869     $import_key = '' if not defined $import_key;
3870
3871     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3872       push( @{$orig}, $import_element );
3873     } else {
3874       my $orig_best = $orig->[$best_candidate->{position}];
3875       # merge orig_best and b_element together and replace original with merged
3876       if (ref $orig_best ne 'HASH') {
3877         $orig->[$best_candidate->{position}] = $import_element;
3878       } elsif (ref $import_element eq 'HASH') {
3879         my ($key) = keys %{$orig_best};
3880         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3881       }
3882     }
3883     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3884   }
3885
3886   return @$orig ? $orig : ();
3887 }
3888
3889 {
3890   my $hm;
3891
3892   sub _merge_attr {
3893     $hm ||= do {
3894       require Hash::Merge;
3895       my $hm = Hash::Merge->new;
3896
3897       $hm->specify_behavior({
3898         SCALAR => {
3899           SCALAR => sub {
3900             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3901
3902             if ($defl xor $defr) {
3903               return [ $defl ? $_[0] : $_[1] ];
3904             }
3905             elsif (! $defl) {
3906               return [];
3907             }
3908             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3909               return [ $_[0] ];
3910             }
3911             else {
3912               return [$_[0], $_[1]];
3913             }
3914           },
3915           ARRAY => sub {
3916             return $_[1] if !defined $_[0];
3917             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3918             return [$_[0], @{$_[1]}]
3919           },
3920           HASH  => sub {
3921             return [] if !defined $_[0] and !keys %{$_[1]};
3922             return [ $_[1] ] if !defined $_[0];
3923             return [ $_[0] ] if !keys %{$_[1]};
3924             return [$_[0], $_[1]]
3925           },
3926         },
3927         ARRAY => {
3928           SCALAR => sub {
3929             return $_[0] if !defined $_[1];
3930             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3931             return [@{$_[0]}, $_[1]]
3932           },
3933           ARRAY => sub {
3934             my @ret = @{$_[0]} or return $_[1];
3935             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3936             my %idx = map { $_ => 1 } @ret;
3937             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3938             \@ret;
3939           },
3940           HASH => sub {
3941             return [ $_[1] ] if ! @{$_[0]};
3942             return $_[0] if !keys %{$_[1]};
3943             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3944             return [ @{$_[0]}, $_[1] ];
3945           },
3946         },
3947         HASH => {
3948           SCALAR => sub {
3949             return [] if !keys %{$_[0]} and !defined $_[1];
3950             return [ $_[0] ] if !defined $_[1];
3951             return [ $_[1] ] if !keys %{$_[0]};
3952             return [$_[0], $_[1]]
3953           },
3954           ARRAY => sub {
3955             return [] if !keys %{$_[0]} and !@{$_[1]};
3956             return [ $_[0] ] if !@{$_[1]};
3957             return $_[1] if !keys %{$_[0]};
3958             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3959             return [ $_[0], @{$_[1]} ];
3960           },
3961           HASH => sub {
3962             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3963             return [ $_[0] ] if !keys %{$_[1]};
3964             return [ $_[1] ] if !keys %{$_[0]};
3965             return [ $_[0] ] if $_[0] eq $_[1];
3966             return [ $_[0], $_[1] ];
3967           },
3968         }
3969       } => 'DBIC_RS_ATTR_MERGER');
3970       $hm;
3971     };
3972
3973     return $hm->merge ($_[1], $_[2]);
3974   }
3975 }
3976
3977 sub STORABLE_freeze {
3978   my ($self, $cloning) = @_;
3979   my $to_serialize = { %$self };
3980
3981   # A cursor in progress can't be serialized (and would make little sense anyway)
3982   # the parser can be regenerated (and can't be serialized)
3983   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3984
3985   # nor is it sensical to store a not-yet-fired-count pager
3986   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3987     delete $to_serialize->{pager};
3988   }
3989
3990   Storable::nfreeze($to_serialize);
3991 }
3992
3993 # need this hook for symmetry
3994 sub STORABLE_thaw {
3995   my ($self, $cloning, $serialized) = @_;
3996
3997   %$self = %{ Storable::thaw($serialized) };
3998
3999   $self;
4000 }
4001
4002
4003 =head2 throw_exception
4004
4005 See L<DBIx::Class::Schema/throw_exception> for details.
4006
4007 =cut
4008
4009 sub throw_exception {
4010   my $self=shift;
4011
4012   if (ref $self and my $rsrc = $self->result_source) {
4013     $rsrc->throw_exception(@_)
4014   }
4015   else {
4016     DBIx::Class::Exception->throw(@_);
4017   }
4018 }
4019
4020 1;
4021
4022 __END__
4023
4024 # XXX: FIXME: Attributes docs need clearing up
4025
4026 =head1 ATTRIBUTES
4027
4028 Attributes are used to refine a ResultSet in various ways when
4029 searching for data. They can be passed to any method which takes an
4030 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4031 L</count>.
4032
4033 Default attributes can be set on the result class using
4034 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4035 the CAVEATS on that feature before using it!)
4036
4037 These are in no particular order:
4038
4039 =head2 order_by
4040
4041 =over 4
4042
4043 =item Value: ( $order_by | \@order_by | \%order_by )
4044
4045 =back
4046
4047 Which column(s) to order the results by.
4048
4049 [The full list of suitable values is documented in
4050 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4051 common options.]
4052
4053 If a single column name, or an arrayref of names is supplied, the
4054 argument is passed through directly to SQL. The hashref syntax allows
4055 for connection-agnostic specification of ordering direction:
4056
4057  For descending order:
4058
4059   order_by => { -desc => [qw/col1 col2 col3/] }
4060
4061  For explicit ascending order:
4062
4063   order_by => { -asc => 'col' }
4064
4065 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4066 supported, although you are strongly encouraged to use the hashref
4067 syntax as outlined above.
4068
4069 =head2 columns
4070
4071 =over 4
4072
4073 =item Value: \@columns | \%columns | $column
4074
4075 =back
4076
4077 Shortcut to request a particular set of columns to be retrieved. Each
4078 column spec may be a string (a table column name), or a hash (in which
4079 case the key is the C<as> value, and the value is used as the C<select>
4080 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4081 it and sets C<select> from that, then auto-populates C<as> from
4082 C<select> as normal. (You may also use the C<cols> attribute, as in
4083 earlier versions of DBIC, but this is deprecated)
4084
4085 Essentially C<columns> does the same as L</select> and L</as>.
4086
4087     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4088
4089 is the same as
4090
4091     select => [qw(some_column another_column)],
4092     as     => [qw(some_column dbic_slot)]
4093
4094 If you want to individually retrieve related columns (in essence perform
4095 manual prefetch) you have to make sure to specify the correct inflation slot
4096 chain such that it matches existing relationships:
4097
4098     my $rs = $schema->resultset('Artist')->search({}, {
4099         # required to tell DBIC to collapse has_many relationships
4100         collapse => 1,
4101         join     => { cds => 'tracks'},
4102         '+columns'  => {
4103           'cds.cdid'         => 'cds.cdid',
4104           'cds.tracks.title' => 'tracks.title',
4105         },
4106     });
4107
4108 =head2 +columns
4109
4110 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4111 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4112 with a unary plus operator before it, which is the same as simply C<columns>.
4113
4114 =over 4
4115
4116 =item Value: \@extra_columns
4117
4118 =back
4119
4120 Indicates additional columns to be selected from storage. Works the same as
4121 L</columns> but adds columns to the current selection. (You may also use the
4122 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4123 deprecated)
4124
4125   $schema->resultset('CD')->search(undef, {
4126     '+columns' => ['artist.name'],
4127     join => ['artist']
4128   });
4129
4130 would return all CDs and include a 'name' column to the information
4131 passed to object inflation. Note that the 'artist' is the name of the
4132 column (or relationship) accessor, and 'name' is the name of the column
4133 accessor in the related table.
4134
4135 =head2 select
4136
4137 =over 4
4138
4139 =item Value: \@select_columns
4140
4141 =back
4142
4143 Indicates which columns should be selected from the storage. You can use
4144 column names, or in the case of RDBMS back ends, function or stored procedure
4145 names:
4146
4147   $rs = $schema->resultset('Employee')->search(undef, {
4148     select => [
4149       'name',
4150       { count => 'employeeid' },
4151       { max => { length => 'name' }, -as => 'longest_name' }
4152     ]
4153   });
4154
4155   # Equivalent SQL
4156   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4157
4158 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4159 use L</select>, to instruct DBIx::Class how to store the result of the column.
4160
4161 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4162 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4163 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4164 function attribute> supplied as shown in the example above.
4165
4166 =head2 +select
4167
4168 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4169 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4170 with a unary plus operator before it, which is the same as simply C<select>.
4171
4172 =over 4
4173
4174 =item Value: \@extra_select_columns
4175
4176 =back
4177
4178 Indicates additional columns to be selected from storage.  Works the same as
4179 L</select> but adds columns to the current selection, instead of specifying
4180 a new explicit list.
4181
4182 =head2 as
4183
4184 =over 4
4185
4186 =item Value: \@inflation_names
4187
4188 =back
4189
4190 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4191 slot name in which the column value will be stored within the
4192 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4193 identifier by the C<get_column> method (or via the object accessor B<if one
4194 with the same name already exists>) as shown below.
4195
4196 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4197 aliasing C<AS>. See L</select> for details.
4198
4199   $rs = $schema->resultset('Employee')->search(undef, {
4200     select => [
4201       'name',
4202       { count => 'employeeid' },
4203       { max => { length => 'name' }, -as => 'longest_name' }
4204     ],
4205     as => [qw/
4206       name
4207       employee_count
4208       max_name_length
4209     /],
4210   });
4211
4212 If the object against which the search is performed already has an accessor
4213 matching a column name specified in C<as>, the value can be retrieved using
4214 the accessor as normal:
4215
4216   my $name = $employee->name();
4217
4218 If on the other hand an accessor does not exist in the object, you need to
4219 use C<get_column> instead:
4220
4221   my $employee_count = $employee->get_column('employee_count');
4222
4223 You can create your own accessors if required - see
4224 L<DBIx::Class::Manual::Cookbook> for details.
4225
4226 =head2 +as
4227
4228 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4229 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4230 with a unary plus operator before it, which is the same as simply C<as>.
4231
4232 =over 4
4233
4234 =item Value: \@extra_inflation_names
4235
4236 =back
4237
4238 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4239
4240 =head2 join
4241
4242 =over 4
4243
4244 =item Value: ($rel_name | \@rel_names | \%rel_names)
4245
4246 =back
4247
4248 Contains a list of relationships that should be joined for this query.  For
4249 example:
4250
4251   # Get CDs by Nine Inch Nails
4252   my $rs = $schema->resultset('CD')->search(
4253     { 'artist.name' => 'Nine Inch Nails' },
4254     { join => 'artist' }
4255   );
4256
4257 Can also contain a hash reference to refer to the other relation's relations.
4258 For example:
4259
4260   package MyApp::Schema::Track;
4261   use base qw/DBIx::Class/;
4262   __PACKAGE__->table('track');
4263   __PACKAGE__->add_columns(qw/trackid cd position title/);
4264   __PACKAGE__->set_primary_key('trackid');
4265   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4266   1;
4267
4268   # In your application
4269   my $rs = $schema->resultset('Artist')->search(
4270     { 'track.title' => 'Teardrop' },
4271     {
4272       join     => { cd => 'track' },
4273       order_by => 'artist.name',
4274     }
4275   );
4276
4277 You need to use the relationship (not the table) name in  conditions,
4278 because they are aliased as such. The current table is aliased as "me", so
4279 you need to use me.column_name in order to avoid ambiguity. For example:
4280
4281   # Get CDs from 1984 with a 'Foo' track
4282   my $rs = $schema->resultset('CD')->search(
4283     {
4284       'me.year' => 1984,
4285       'tracks.name' => 'Foo'
4286     },
4287     { join => 'tracks' }
4288   );
4289
4290 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4291 similarly for a third time). For e.g.
4292
4293   my $rs = $schema->resultset('Artist')->search({
4294     'cds.title'   => 'Down to Earth',
4295     'cds_2.title' => 'Popular',
4296   }, {
4297     join => [ qw/cds cds/ ],
4298   });
4299
4300 will return a set of all artists that have both a cd with title 'Down
4301 to Earth' and a cd with title 'Popular'.
4302
4303 If you want to fetch related objects from other tables as well, see L</prefetch>
4304 below.
4305
4306  NOTE: An internal join-chain pruner will discard certain joins while
4307  constructing the actual SQL query, as long as the joins in question do not
4308  affect the retrieved result. This for example includes 1:1 left joins
4309  that are not part of the restriction specification (WHERE/HAVING) nor are
4310  a part of the query selection.
4311
4312 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4313
4314 =head2 collapse
4315
4316 =over 4
4317
4318 =item Value: (0 | 1)
4319
4320 =back
4321
4322 When set to a true value, indicates that any rows fetched from joined has_many
4323 relationships are to be aggregated into the corresponding "parent" object. For
4324 example, the resultset:
4325
4326   my $rs = $schema->resultset('CD')->search({}, {
4327     '+columns' => [ qw/ tracks.title tracks.position / ],
4328     join => 'tracks',
4329     collapse => 1,
4330   });
4331
4332 While executing the following query:
4333
4334   SELECT me.*, tracks.title, tracks.position
4335     FROM cd me
4336     LEFT JOIN track tracks
4337       ON tracks.cdid = me.cdid
4338
4339 Will return only as many objects as there are rows in the CD source, even
4340 though the result of the query may span many rows. Each of these CD objects
4341 will in turn have multiple "Track" objects hidden behind the has_many
4342 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4343 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4344 product"), with each CD object containing exactly one of all fetched Track data.
4345
4346 When a collapse is requested on a non-ordered resultset, an order by some
4347 unique part of the main source (the left-most table) is inserted automatically.
4348 This is done so that the resultset is allowed to be "lazy" - calling
4349 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4350 object with all of its related data.
4351
4352 If an L</order_by> is already declared, and orders the resultset in a way that
4353 makes collapsing as described above impossible (e.g. C<< ORDER BY
4354 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4355 switch to "eager" mode and slurp the entire resultset before constructing the
4356 first object returned by L</next>.
4357
4358 Setting this attribute on a resultset that does not join any has_many
4359 relations is a no-op.
4360
4361 For a more in-depth discussion, see L</PREFETCHING>.
4362
4363 =head2 prefetch
4364
4365 =over 4
4366
4367 =item Value: ($rel_name | \@rel_names | \%rel_names)
4368
4369 =back
4370
4371 This attribute is a shorthand for specifying a L</join> spec, adding all
4372 columns from the joined related sources as L</+columns> and setting
4373 L</collapse> to a true value. It can be thought of as a rough B<superset>
4374 of the L</join> attribute.
4375
4376 For example, the following two queries are equivalent:
4377
4378   my $rs = $schema->resultset('Artist')->search({}, {
4379     prefetch => { cds => ['genre', 'tracks' ] },
4380   });
4381
4382 and
4383
4384   my $rs = $schema->resultset('Artist')->search({}, {
4385     join => { cds => ['genre', 'tracks' ] },
4386     collapse => 1,
4387     '+columns' => [
4388       (map
4389         { +{ "cds.$_" => "cds.$_" } }
4390         $schema->source('Artist')->related_source('cds')->columns
4391       ),
4392       (map
4393         { +{ "cds.genre.$_" => "genre.$_" } }
4394         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4395       ),
4396       (map
4397         { +{ "cds.tracks.$_" => "tracks.$_" } }
4398         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4399       ),
4400     ],
4401   });
4402
4403 Both producing the following SQL:
4404
4405   SELECT  me.artistid, me.name, me.rank, me.charfield,
4406           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4407           genre.genreid, genre.name,
4408           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4409     FROM artist me
4410     LEFT JOIN cd cds
4411       ON cds.artist = me.artistid
4412     LEFT JOIN genre genre
4413       ON genre.genreid = cds.genreid
4414     LEFT JOIN track tracks
4415       ON tracks.cd = cds.cdid
4416   ORDER BY me.artistid
4417
4418 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4419 the arguments are properly merged and generally do the right thing. For
4420 example, you may want to do the following:
4421
4422   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4423     { 'genre.genreid' => undef },
4424     {
4425       join => { cds => 'genre' },
4426       prefetch => 'cds',
4427     }
4428   );
4429
4430 Which generates the following SQL:
4431
4432   SELECT  me.artistid, me.name, me.rank, me.charfield,
4433           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4434     FROM artist me
4435     LEFT JOIN cd cds
4436       ON cds.artist = me.artistid
4437     LEFT JOIN genre genre
4438       ON genre.genreid = cds.genreid
4439   WHERE genre.genreid IS NULL
4440   ORDER BY me.artistid
4441
4442 For a more in-depth discussion, see L</PREFETCHING>.
4443
4444 =head2 alias
4445
4446 =over 4
4447
4448 =item Value: $source_alias
4449
4450 =back
4451
4452 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4453 nested search queries (sub-SELECTs) might need specific aliases set to
4454 reference inner queries.  For example:
4455
4456    my $q = $rs
4457       ->related_resultset('CDs')
4458       ->related_resultset('Tracks')
4459       ->search({
4460          'track.id' => { -ident => 'none_search.id' },
4461       })
4462       ->as_query;
4463
4464    my $ids = $self->search({
4465       -not_exists => $q,
4466    }, {
4467       alias    => 'none_search',
4468       group_by => 'none_search.id',
4469    })->get_column('id')->as_query;
4470
4471    $self->search({ id => { -in => $ids } })
4472
4473 This attribute is directly tied to L</current_source_alias>.
4474
4475 =head2 page
4476
4477 =over 4
4478
4479 =item Value: $page
4480
4481 =back
4482
4483 Makes the resultset paged and specifies the page to retrieve. Effectively
4484 identical to creating a non-pages resultset and then calling ->page($page)
4485 on it.
4486
4487 If L</rows> attribute is not specified it defaults to 10 rows per page.
4488
4489 When you have a paged resultset, L</count> will only return the number
4490 of rows in the page. To get the total, use the L</pager> and call
4491 C<total_entries> on it.
4492
4493 =head2 rows
4494
4495 =over 4
4496
4497 =item Value: $rows
4498
4499 =back
4500
4501 Specifies the maximum number of rows for direct retrieval or the number of
4502 rows per page if the page attribute or method is used.
4503
4504 =head2 offset
4505
4506 =over 4
4507
4508 =item Value: $offset
4509
4510 =back
4511
4512 Specifies the (zero-based) row number for the  first row to be returned, or the
4513 of the first row of the first page if paging is used.
4514
4515 =head2 software_limit
4516
4517 =over 4
4518
4519 =item Value: (0 | 1)
4520
4521 =back
4522
4523 When combined with L</rows> and/or L</offset> the generated SQL will not
4524 include any limit dialect stanzas. Instead the entire result will be selected
4525 as if no limits were specified, and DBIC will perform the limit locally, by
4526 artificially advancing and finishing the resulting L</cursor>.
4527
4528 This is the recommended way of performing resultset limiting when no sane RDBMS
4529 implementation is available (e.g.
4530 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4531 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4532
4533 =head2 group_by
4534
4535 =over 4
4536
4537 =item Value: \@columns
4538
4539 =back
4540
4541 A arrayref of columns to group by. Can include columns of joined tables.
4542
4543   group_by => [qw/ column1 column2 ... /]
4544
4545 =head2 having
4546
4547 =over 4
4548
4549 =item Value: $condition
4550
4551 =back
4552
4553 The HAVING operator specifies a B<secondary> condition applied to the set
4554 after the grouping calculations have been done. In other words it is a
4555 constraint just like L</where> (and accepting the same
4556 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4557 as it exists after GROUP BY has taken place. Specifying L</having> without
4558 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4559
4560 E.g.
4561
4562   having => { 'count_employee' => { '>=', 100 } }
4563
4564 or with an in-place function in which case literal SQL is required:
4565
4566   having => \[ 'count(employee) >= ?', 100 ]
4567
4568 =head2 distinct
4569
4570 =over 4
4571
4572 =item Value: (0 | 1)
4573
4574 =back
4575
4576 Set to 1 to automatically generate a L</group_by> clause based on the selection
4577 (including intelligent handling of L</order_by> contents). Note that the group
4578 criteria calculation takes place over the B<final> selection. This includes
4579 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4580 L</search> calls, and standalone columns selected via
4581 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4582 extra selections specified via L</prefetch> - such selections are explicitly
4583 excluded from group criteria calculations.
4584
4585 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4586 setting is ignored and an appropriate warning is issued.
4587
4588 =head2 where
4589
4590 =over 4
4591
4592 Adds to the WHERE clause.
4593
4594   # only return rows WHERE deleted IS NULL for all searches
4595   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4596
4597 Can be overridden by passing C<< { where => undef } >> as an attribute
4598 to a resultset.
4599
4600 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4601
4602 =back
4603
4604 =head2 cache
4605
4606 Set to 1 to cache search results. This prevents extra SQL queries if you
4607 revisit rows in your ResultSet:
4608
4609   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4610
4611   while( my $artist = $resultset->next ) {
4612     ... do stuff ...
4613   }
4614
4615   $rs->first; # without cache, this would issue a query
4616
4617 By default, searches are not cached.
4618
4619 For more examples of using these attributes, see
4620 L<DBIx::Class::Manual::Cookbook>.
4621
4622 =head2 for
4623
4624 =over 4
4625
4626 =item Value: ( 'update' | 'shared' | \$scalar )
4627
4628 =back
4629
4630 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4631 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4632 query.
4633
4634 =head1 PREFETCHING
4635
4636 DBIx::Class supports arbitrary related data prefetching from multiple related
4637 sources. Any combination of relationship types and column sets are supported.
4638 If L<collapsing|/collapse> is requested, there is an additional requirement of
4639 selecting enough data to make every individual object uniquely identifiable.
4640
4641 Here are some more involved examples, based on the following relationship map:
4642
4643   # Assuming:
4644   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4645   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4646   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4647
4648   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4649
4650   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4651
4652
4653
4654   my $rs = $schema->resultset('Tag')->search(
4655     undef,
4656     {
4657       prefetch => {
4658         cd => 'artist'
4659       }
4660     }
4661   );
4662
4663 The initial search results in SQL like the following:
4664
4665   SELECT tag.*, cd.*, artist.* FROM tag
4666   JOIN cd ON tag.cd = cd.cdid
4667   JOIN artist ON cd.artist = artist.artistid
4668
4669 L<DBIx::Class> has no need to go back to the database when we access the
4670 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4671 case.
4672
4673 Simple prefetches will be joined automatically, so there is no need
4674 for a C<join> attribute in the above search.
4675
4676 The L</prefetch> attribute can be used with any of the relationship types
4677 and multiple prefetches can be specified together. Below is a more complex
4678 example that prefetches a CD's artist, its liner notes (if present),
4679 the cover image, the tracks on that CD, and the guests on those
4680 tracks.
4681
4682   my $rs = $schema->resultset('CD')->search(
4683     undef,
4684     {
4685       prefetch => [
4686         { artist => 'record_label'},  # belongs_to => belongs_to
4687         'liner_note',                 # might_have
4688         'cover_image',                # has_one
4689         { tracks => 'guests' },       # has_many => has_many
4690       ]
4691     }
4692   );
4693
4694 This will produce SQL like the following:
4695
4696   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4697          tracks.*, guests.*
4698     FROM cd me
4699     JOIN artist artist
4700       ON artist.artistid = me.artistid
4701     JOIN record_label record_label
4702       ON record_label.labelid = artist.labelid
4703     LEFT JOIN track tracks
4704       ON tracks.cdid = me.cdid
4705     LEFT JOIN guest guests
4706       ON guests.trackid = track.trackid
4707     LEFT JOIN liner_notes liner_note
4708       ON liner_note.cdid = me.cdid
4709     JOIN cd_artwork cover_image
4710       ON cover_image.cdid = me.cdid
4711   ORDER BY tracks.cd
4712
4713 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4714 C<tracks>, and C<guests> of the CD will all be available through the
4715 relationship accessors without the need for additional queries to the
4716 database.
4717
4718 =head3 CAVEATS
4719
4720 Prefetch does a lot of deep magic. As such, it may not behave exactly
4721 as you might expect.
4722
4723 =over 4
4724
4725 =item *
4726
4727 Prefetch uses the L</cache> to populate the prefetched relationships. This
4728 may or may not be what you want.
4729
4730 =item *
4731
4732 If you specify a condition on a prefetched relationship, ONLY those
4733 rows that match the prefetched condition will be fetched into that relationship.
4734 This means that adding prefetch to a search() B<may alter> what is returned by
4735 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4736
4737   my $artist_rs = $schema->resultset('Artist')->search({
4738       'cds.year' => 2008,
4739   }, {
4740       join => 'cds',
4741   });
4742
4743   my $count = $artist_rs->first->cds->count;
4744
4745   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4746
4747   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4748
4749   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4750
4751 That cmp_ok() may or may not pass depending on the datasets involved. In other
4752 words the C<WHERE> condition would apply to the entire dataset, just like
4753 it would in regular SQL. If you want to add a condition only to the "right side"
4754 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4755 condition|DBIx::Class::Relationship::Base/condition>
4756
4757 =back
4758
4759 =head1 DBIC BIND VALUES
4760
4761 Because DBIC may need more information to bind values than just the column name
4762 and value itself, it uses a special format for both passing and receiving bind
4763 values.  Each bind value should be composed of an arrayref of
4764 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4765
4766 =over 4
4767
4768 =item dbd_attrs
4769
4770 If present (in any form), this is what is being passed directly to bind_param.
4771 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4772 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4773
4774 If this is specified, all other bind options described below are ignored.
4775
4776 =item sqlt_datatype
4777
4778 If present, this is used to infer the actual bind attribute by passing to
4779 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4780 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4781
4782 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4783 currently drivers are expected to "Do the Right Thing" when given a common
4784 datatype name.  (Not ideal, but that's what we got at this point.)
4785
4786 =item sqlt_size
4787
4788 Currently used to correctly allocate buffers for bind_param_inout().
4789 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4790 or to a sensible value based on the "data_type".
4791
4792 =item dbic_colname
4793
4794 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4795 explicitly specified they are never overridden).  Also used by some weird DBDs,
4796 where the column name should be available at bind_param time (e.g. Oracle).
4797
4798 =back
4799
4800 For backwards compatibility and convenience, the following shortcuts are
4801 supported:
4802
4803   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4804   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4805   [ undef,   $val ] === [ {}, $val ]
4806   $val              === [ {}, $val ]
4807
4808 =head1 AUTHOR AND CONTRIBUTORS
4809
4810 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4811
4812 =head1 LICENSE
4813
4814 You may distribute this code under the same terms as Perl itself.
4815