lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs   = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: $source, \%$attrs
 195
 196 =item Return Value: $rs
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you won't need to construct a resultset manually.  You'll
 206 automatically get one from e.g. a L</search> called in scalar context:
 207
 208   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 209
 210 IMPORTANT: If called on an object, proxies to new_result instead so
 211
 212   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 213
 214 will return a CD object, not a ResultSet.
 215
 216 =cut
 217
 218 sub new {
 219   my $class = shift;
 220   return $class->new_result(@_) if ref $class;
 221
 222   my ($source, $attrs) = @_;
 223   $source = $source->resolve
 224     if $source->isa('DBIx::Class::ResultSourceHandle');
 225   $attrs = { %{$attrs||{}} };
 226
 227   if ($attrs->{page}) {
 228     $attrs->{rows} ||= 10;
 229   }
 230
 231   $attrs->{alias} ||= 'me';
 232
 233   my $self = bless {
 234     result_source => $source,
 235     cond => $attrs->{where},
 236     pager => undef,
 237     attrs => $attrs,
 238   }, $class;
 239
 240   # if there is a dark selector, this means we are already in a
 241   # chain and the cleanup/sanification was taken care of by
 242   # _search_rs already
 243   $self->_normalize_selection($attrs)
 244     unless $attrs->{_dark_selector};
 245
 246   $self->result_class(
 247     $attrs->{result_class} || $source->result_class
 248   );
 249
 250   $self;
 251 }
 252
 253 =head2 search
 254
 255 =over 4
 256
 257 =item Arguments: $cond, \%attrs?
 258
 259 =item Return Value: $resultset (scalar context) ||  @row_objs (list context)
 260
 261 =back
 262
 263   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 264   my $new_rs = $cd_rs->search({ year => 2005 });
 265
 266   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 267                  # year = 2005 OR year = 2004
 268
 269 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 270 returning a list of row objects instead. To avoid that, use L</search_rs>.
 271
 272 If you need to pass in additional attributes but no additional condition,
 273 call it as C<search(undef, \%attrs)>.
 274
 275   # "SELECT name, artistid FROM $artist_table"
 276   my @all_artists = $schema->resultset('Artist')->search(undef, {
 277     columns => [qw/name artistid/],
 278   });
 279
 280 For a list of attributes that can be passed to C<search>, see
 281 L</ATTRIBUTES>. For more examples of using this function, see
 282 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 283 documentation for the first argument, see L<SQL::Abstract>
 284 and its extension L<DBIx::Class::SQLMaker>.
 285
 286 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 287
 288 =head3 CAVEAT
 289
 290 Note that L</search> does not process/deflate any of the values passed in the
 291 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 292 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 293 manually that any value passed to this method will stringify to something the
 294 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 295 objects, for more info see:
 296 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 297
 298 =cut
 299
 300 sub search {
 301   my $self = shift;
 302   my $rs = $self->search_rs( @_ );
 303
 304   if (wantarray) {
 305     return $rs->all;
 306   }
 307   elsif (defined wantarray) {
 308     return $rs;
 309   }
 310   else {
 311     # we can be called by a relationship helper, which in
 312     # turn may be called in void context due to some braindead
 313     # overload or whatever else the user decided to be clever
 314     # at this particular day. Thus limit the exception to
 315     # external code calls only
 316     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 317       if (caller)[0] !~ /^\QDBIx::Class::/;
 318
 319     return ();
 320   }
 321 }
 322
 323 =head2 search_rs
 324
 325 =over 4
 326
 327 =item Arguments: $cond, \%attrs?
 328
 329 =item Return Value: $resultset
 330
 331 =back
 332
 333 This method does the same exact thing as search() except it will
 334 always return a resultset, even in list context.
 335
 336 =cut
 337
 338 sub search_rs {
 339   my $self = shift;
 340
 341   # Special-case handling for (undef, undef).
 342   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 343     @_ = ();
 344   }
 345
 346   my $call_attrs = {};
 347   if (@_ > 1) {
 348     if (ref $_[-1] eq 'HASH') {
 349       # copy for _normalize_selection
 350       $call_attrs = { %{ pop @_ } };
 351     }
 352     elsif (! defined $_[-1] ) {
 353       pop @_;   # search({}, undef)
 354     }
 355   }
 356
 357   # see if we can keep the cache (no $rs changes)
 358   my $cache;
 359   my %safe = (alias => 1, cache => 1);
 360   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 361     ! defined $_[0]
 362       or
 363     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 364       or
 365     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 366   )) {
 367     $cache = $self->get_cache;
 368   }
 369
 370   my $rsrc = $self->result_source;
 371
 372   my $old_attrs = { %{$self->{attrs}} };
 373   my $old_having = delete $old_attrs->{having};
 374   my $old_where = delete $old_attrs->{where};
 375
 376   my $new_attrs = { %$old_attrs };
 377
 378   # take care of call attrs (only if anything is changing)
 379   if (keys %$call_attrs) {
 380
 381     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 382
 383     # reset the current selector list if new selectors are supplied
 384     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 385       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 386     }
 387
 388     # Normalize the new selector list (operates on the passed-in attr structure)
 389     # Need to do it on every chain instead of only once on _resolved_attrs, in
 390     # order to allow detection of empty vs partial 'as'
 391     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 392       if $old_attrs->{_dark_selector};
 393     $self->_normalize_selection ($call_attrs);
 394
 395     # start with blind overwriting merge, exclude selector attrs
 396     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 397     delete @{$new_attrs}{@selector_attrs};
 398
 399     for (@selector_attrs) {
 400       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 401         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 402     }
 403
 404     # older deprecated name, use only if {columns} is not there
 405     if (my $c = delete $new_attrs->{cols}) {
 406       if ($new_attrs->{columns}) {
 407         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 408       }
 409       else {
 410         $new_attrs->{columns} = $c;
 411       }
 412     }
 413
 414
 415     # join/prefetch use their own crazy merging heuristics
 416     foreach my $key (qw/join prefetch/) {
 417       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 418         if exists $call_attrs->{$key};
 419     }
 420
 421     # stack binds together
 422     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 423   }
 424
 425
 426   # rip apart the rest of @_, parse a condition
 427   my $call_cond = do {
 428
 429     if (ref $_[0] eq 'HASH') {
 430       (keys %{$_[0]}) ? $_[0] : undef
 431     }
 432     elsif (@_ == 1) {
 433       $_[0]
 434     }
 435     elsif (@_ % 2) {
 436       $self->throw_exception('Odd number of arguments to search')
 437     }
 438     else {
 439       +{ @_ }
 440     }
 441
 442   } if @_;
 443
 444   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 445     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead';
 446   }
 447
 448   for ($old_where, $call_cond) {
 449     if (defined $_) {
 450       $new_attrs->{where} = $self->_stack_cond (
 451         $_, $new_attrs->{where}
 452       );
 453     }
 454   }
 455
 456   if (defined $old_having) {
 457     $new_attrs->{having} = $self->_stack_cond (
 458       $old_having, $new_attrs->{having}
 459     )
 460   }
 461
 462   my $rs = (ref $self)->new($rsrc, $new_attrs);
 463
 464   $rs->set_cache($cache) if ($cache);
 465
 466   return $rs;
 467 }
 468
 469 my $dark_sel_dumper;
 470 sub _normalize_selection {
 471   my ($self, $attrs) = @_;
 472
 473   # legacy syntax
 474   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 475     if exists $attrs->{include_columns};
 476
 477   # columns are always placed first, however
 478
 479   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 480   # delay the decision on whether to use a default select list ($rsrc->columns)
 481   # allowing stuff like the remove_columns helper to work
 482   #
 483   # select/as +select/+as pairs need special handling - the amount of select/as
 484   # elements in each pair does *not* have to be equal (think multicolumn
 485   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 486   # supplied at all) - try to infer the alias, either from the -as parameter
 487   # of the selector spec, or use the parameter whole if it looks like a column
 488   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 489   # is ok as well), but make sure no more additions to the 'as' chain take place
 490   for my $pref ('', '+') {
 491
 492     my ($sel, $as) = map {
 493       my $key = "${pref}${_}";
 494
 495       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 496         ? @{$attrs->{$key}}
 497         : $attrs->{$key} || ()
 498       ];
 499       delete $attrs->{$key};
 500       $val;
 501     } qw/select as/;
 502
 503     if (! @$as and ! @$sel ) {
 504       next;
 505     }
 506     elsif (@$as and ! @$sel) {
 507       $self->throw_exception(
 508         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 509       );
 510     }
 511     elsif( ! @$as ) {
 512       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 513       # if any @$as has been supplied we assume the user knows what (s)he is doing
 514       # and blindly keep stacking up pieces
 515       unless ($attrs->{_dark_selector}) {
 516         SELECTOR:
 517         for (@$sel) {
 518           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 519             push @$as, $_->{-as};
 520           }
 521           # assume any plain no-space, no-parenthesis string to be a column spec
 522           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 523           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 524             push @$as, $_;
 525           }
 526           # if all else fails - raise a flag that no more aliasing will be allowed
 527           else {
 528             $attrs->{_dark_selector} = {
 529               plus_stage => $pref,
 530               string => ($dark_sel_dumper ||= do {
 531                   require Data::Dumper::Concise;
 532                   Data::Dumper::Concise::DumperObject()->Indent(0);
 533                 })->Values([$_])->Dump
 534               ,
 535             };
 536             last SELECTOR;
 537           }
 538         }
 539       }
 540     }
 541     elsif (@$as < @$sel) {
 542       $self->throw_exception(
 543         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 544       );
 545     }
 546     elsif ($pref and $attrs->{_dark_selector}) {
 547       $self->throw_exception(
 548         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 549       );
 550     }
 551
 552
 553     # merge result
 554     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 555     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 556   }
 557 }
 558
 559 sub _stack_cond {
 560   my ($self, $left, $right) = @_;
 561
 562   # collapse single element top-level conditions
 563   # (single pass only, unlikely to need recursion)
 564   for ($left, $right) {
 565     if (ref $_ eq 'ARRAY') {
 566       if (@$_ == 0) {
 567         $_ = undef;
 568       }
 569       elsif (@$_ == 1) {
 570         $_ = $_->[0];
 571       }
 572     }
 573     elsif (ref $_ eq 'HASH') {
 574       my ($first, $more) = keys %$_;
 575
 576       # empty hash
 577       if (! defined $first) {
 578         $_ = undef;
 579       }
 580       # one element hash
 581       elsif (! defined $more) {
 582         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 583           $_ = $_->{'-and'};
 584         }
 585         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 586           $_ = $_->{'-or'};
 587         }
 588       }
 589     }
 590   }
 591
 592   # merge hashes with weeding out of duplicates (simple cases only)
 593   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 594
 595     # shallow copy to destroy
 596     $right = { %$right };
 597     for (grep { exists $right->{$_} } keys %$left) {
 598       # the use of eq_deeply here is justified - the rhs of an
 599       # expression can contain a lot of twisted weird stuff
 600       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 601     }
 602
 603     $right = undef unless keys %$right;
 604   }
 605
 606
 607   if (defined $left xor defined $right) {
 608     return defined $left ? $left : $right;
 609   }
 610   elsif (! defined $left) {
 611     return undef;
 612   }
 613   else {
 614     return { -and => [ $left, $right ] };
 615   }
 616 }
 617
 618 =head2 search_literal
 619
 620 =over 4
 621
 622 =item Arguments: $sql_fragment, @bind_values
 623
 624 =item Return Value: $resultset (scalar context) || @row_objs (list context)
 625
 626 =back
 627
 628   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 629   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 630
 631 Pass a literal chunk of SQL to be added to the conditional part of the
 632 resultset query.
 633
 634 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 635 only be used in that context. C<search_literal> is a convenience method.
 636 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 637 columns are bound correctly, use C<search>.
 638
 639 Example of how to use C<search> instead of C<search_literal>
 640
 641   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 642   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 643
 644
 645 See L<DBIx::Class::Manual::Cookbook/Searching> and
 646 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 647 require C<search_literal>.
 648
 649 =cut
 650
 651 sub search_literal {
 652   my ($self, $sql, @bind) = @_;
 653   my $attr;
 654   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 655     $attr = pop @bind;
 656   }
 657   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 658 }
 659
 660 =head2 find
 661
 662 =over 4
 663
 664 =item Arguments: \%columns_values | @pk_values, \%attrs?
 665
 666 =item Return Value: $row_object | undef
 667
 668 =back
 669
 670 Finds and returns a single row based on supplied criteria. Takes either a
 671 hashref with the same format as L</create> (including inference of foreign
 672 keys from related objects), or a list of primary key values in the same
 673 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 674 declaration on the L</result_source>.
 675
 676 In either case an attempt is made to combine conditions already existing on
 677 the resultset with the condition passed to this method.
 678
 679 To aid with preparing the correct query for the storage you may supply the
 680 C<key> attribute, which is the name of a
 681 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 682 unique constraint corresponding to the
 683 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 684 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 685 to construct a query that satisfies the named unique constraint fully (
 686 non-NULL values for each column member of the constraint) an exception is
 687 thrown.
 688
 689 If no C<key> is specified, the search is carried over all unique constraints
 690 which are fully defined by the available condition.
 691
 692 If no such constraint is found, C<find> currently defaults to a simple
 693 C<< search->(\%column_values) >> which may or may not do what you expect.
 694 Note that this fallback behavior may be deprecated in further versions. If
 695 you need to search with arbitrary conditions - use L</search>. If the query
 696 resulting from this fallback produces more than one row, a warning to the
 697 effect is issued, though only the first row is constructed and returned as
 698 C<$row_object>.
 699
 700 In addition to C<key>, L</find> recognizes and applies standard
 701 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 702
 703 Note that if you have extra concerns about the correctness of the resulting
 704 query you need to specify the C<key> attribute and supply the entire condition
 705 as an argument to find (since it is not always possible to perform the
 706 combination of the resultset condition with the supplied one, especially if
 707 the resultset condition contains literal sql).
 708
 709 For example, to find a row by its primary key:
 710
 711   my $cd = $schema->resultset('CD')->find(5);
 712
 713 You can also find a row by a specific unique constraint:
 714
 715   my $cd = $schema->resultset('CD')->find(
 716     {
 717       artist => 'Massive Attack',
 718       title  => 'Mezzanine',
 719     },
 720     { key => 'cd_artist_title' }
 721   );
 722
 723 See also L</find_or_create> and L</update_or_create>.
 724
 725 =cut
 726
 727 sub find {
 728   my $self = shift;
 729   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 730
 731   my $rsrc = $self->result_source;
 732
 733   my $constraint_name;
 734   if (exists $attrs->{key}) {
 735     $constraint_name = defined $attrs->{key}
 736       ? $attrs->{key}
 737       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 738     ;
 739   }
 740
 741   # Parse out the condition from input
 742   my $call_cond;
 743
 744   if (ref $_[0] eq 'HASH') {
 745     $call_cond = { %{$_[0]} };
 746   }
 747   else {
 748     # if only values are supplied we need to default to 'primary'
 749     $constraint_name = 'primary' unless defined $constraint_name;
 750
 751     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 752
 753     $self->throw_exception(
 754       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 755     ) unless @c_cols;
 756
 757     $self->throw_exception (
 758       'find() expects either a column/value hashref, or a list of values '
 759     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 760     ) unless @c_cols == @_;
 761
 762     $call_cond = {};
 763     @{$call_cond}{@c_cols} = @_;
 764   }
 765
 766   my %related;
 767   for my $key (keys %$call_cond) {
 768     if (
 769       my $keyref = ref($call_cond->{$key})
 770         and
 771       my $relinfo = $rsrc->relationship_info($key)
 772     ) {
 773       my $val = delete $call_cond->{$key};
 774
 775       next if $keyref eq 'ARRAY'; # has_many for multi_create
 776
 777       my $rel_q = $rsrc->_resolve_condition(
 778         $relinfo->{cond}, $val, $key, $key
 779       );
 780       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 781       @related{keys %$rel_q} = values %$rel_q;
 782     }
 783   }
 784
 785   # relationship conditions take precedence (?)
 786   @{$call_cond}{keys %related} = values %related;
 787
 788   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 789   my $final_cond;
 790   if (defined $constraint_name) {
 791     $final_cond = $self->_qualify_cond_columns (
 792
 793       $self->_build_unique_cond (
 794         $constraint_name,
 795         $call_cond,
 796       ),
 797
 798       $alias,
 799     );
 800   }
 801   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 802     # This means that we got here after a merger of relationship conditions
 803     # in ::Relationship::Base::search_related (the row method), and furthermore
 804     # the relationship is of the 'single' type. This means that the condition
 805     # provided by the relationship (already attached to $self) is sufficient,
 806     # as there can be only one row in the database that would satisfy the
 807     # relationship
 808   }
 809   else {
 810     # no key was specified - fall down to heuristics mode:
 811     # run through all unique queries registered on the resultset, and
 812     # 'OR' all qualifying queries together
 813     my (@unique_queries, %seen_column_combinations);
 814     for my $c_name ($rsrc->unique_constraint_names) {
 815       next if $seen_column_combinations{
 816         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 817       }++;
 818
 819       push @unique_queries, try {
 820         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 821       } || ();
 822     }
 823
 824     $final_cond = @unique_queries
 825       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 826       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 827     ;
 828   }
 829
 830   # Run the query, passing the result_class since it should propagate for find
 831   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 832   if ($rs->_resolved_attrs->{collapse}) {
 833     my $row = $rs->next;
 834     carp "Query returned more than one row" if $rs->next;
 835     return $row;
 836   }
 837   else {
 838     return $rs->single;
 839   }
 840 }
 841
 842 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 843 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 844 #
 845 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 846 # condition. It is provided for overrides until a saner way forward is devised
 847 #
 848 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 849 # the road. Please adjust your tests accordingly to catch this situation early
 850 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 851 #
 852 # The method will not be removed without an adequately complete replacement
 853 # for strict-mode enforcement
 854 sub _non_unique_find_fallback {
 855   my ($self, $cond, $attrs) = @_;
 856
 857   return $self->_qualify_cond_columns(
 858     $cond,
 859     exists $attrs->{alias}
 860       ? $attrs->{alias}
 861       : $self->{attrs}{alias}
 862   );
 863 }
 864
 865
 866 sub _qualify_cond_columns {
 867   my ($self, $cond, $alias) = @_;
 868
 869   my %aliased = %$cond;
 870   for (keys %aliased) {
 871     $aliased{"$alias.$_"} = delete $aliased{$_}
 872       if $_ !~ /\./;
 873   }
 874
 875   return \%aliased;
 876 }
 877
 878 sub _build_unique_cond {
 879   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 880
 881   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 882
 883   # combination may fail if $self->{cond} is non-trivial
 884   my ($final_cond) = try {
 885     $self->_merge_with_rscond ($extra_cond)
 886   } catch {
 887     +{ %$extra_cond }
 888   };
 889
 890   # trim out everything not in $columns
 891   $final_cond = { map {
 892     exists $final_cond->{$_}
 893       ? ( $_ => $final_cond->{$_} )
 894       : ()
 895   } @c_cols };
 896
 897   if (my @missing = grep
 898     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 899     (@c_cols)
 900   ) {
 901     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 902       $constraint_name,
 903       join (', ', map { "'$_'" } @missing),
 904     ) );
 905   }
 906
 907   if (
 908     !$croak_on_null
 909       and
 910     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 911       and
 912     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 913   ) {
 914     carp_unique ( sprintf (
 915       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 916     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 917     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 918       $constraint_name,
 919       join (', ', map { "'$_'" } @undefs),
 920     ));
 921   }
 922
 923   return $final_cond;
 924 }
 925
 926 =head2 search_related
 927
 928 =over 4
 929
 930 =item Arguments: $rel, $cond?, \%attrs?
 931
 932 =item Return Value: $new_resultset (scalar context) || @row_objs (list context)
 933
 934 =back
 935
 936   $new_rs = $cd_rs->search_related('artist', {
 937     name => 'Emo-R-Us',
 938   });
 939
 940 Searches the specified relationship, optionally specifying a condition and
 941 attributes for matching records. See L</ATTRIBUTES> for more information.
 942
 943 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 944 returning a list of row objects instead. To avoid that, use L</search_related_rs>.
 945
 946 See also L</search_related_rs>.
 947
 948 =cut
 949
 950 sub search_related {
 951   return shift->related_resultset(shift)->search(@_);
 952 }
 953
 954 =head2 search_related_rs
 955
 956 This method works exactly the same as search_related, except that
 957 it guarantees a resultset, even in list context.
 958
 959 =cut
 960
 961 sub search_related_rs {
 962   return shift->related_resultset(shift)->search_rs(@_);
 963 }
 964
 965 =head2 cursor
 966
 967 =over 4
 968
 969 =item Arguments: none
 970
 971 =item Return Value: $cursor
 972
 973 =back
 974
 975 Returns a storage-driven cursor to the given resultset. See
 976 L<DBIx::Class::Cursor> for more information.
 977
 978 =cut
 979
 980 sub cursor {
 981   my ($self) = @_;
 982
 983   my $attrs = $self->_resolved_attrs_copy;
 984
 985   return $self->{cursor}
 986     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 987           $attrs->{where},$attrs);
 988 }
 989
 990 =head2 single
 991
 992 =over 4
 993
 994 =item Arguments: $cond?
 995
 996 =item Return Value: $row_object | undef
 997
 998 =back
 999
1000   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1001
1002 Inflates the first result without creating a cursor if the resultset has
1003 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1004 of L</search>.
1005
1006 While this method can take an optional search condition (just like L</search>)
1007 being a fast-code-path it does not recognize search attributes. If you need to
1008 add extra joins or similar, call L</search> and then chain-call L</single> on the
1009 L<DBIx::Class::ResultSet> returned.
1010
1011 =over
1012
1013 =item B<Note>
1014
1015 As of 0.08100, this method enforces the assumption that the preceding
1016 query returns only one row. If more than one row is returned, you will receive
1017 a warning:
1018
1019   Query returned more than one row
1020
1021 In this case, you should be using L</next> or L</find> instead, or if you really
1022 know what you are doing, use the L</rows> attribute to explicitly limit the size
1023 of the resultset.
1024
1025 This method will also throw an exception if it is called on a resultset prefetching
1026 has_many, as such a prefetch implies fetching multiple rows from the database in
1027 order to assemble the resulting object.
1028
1029 =back
1030
1031 =cut
1032
1033 sub single {
1034   my ($self, $where) = @_;
1035   if(@_ > 2) {
1036       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1037   }
1038
1039   my $attrs = $self->_resolved_attrs_copy;
1040
1041   $self->throw_exception(
1042     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1043   ) if $attrs->{collapse};
1044
1045   if ($where) {
1046     if (defined $attrs->{where}) {
1047       $attrs->{where} = {
1048         '-and' =>
1049             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1050                $where, delete $attrs->{where} ]
1051       };
1052     } else {
1053       $attrs->{where} = $where;
1054     }
1055   }
1056
1057   my $data = [ $self->result_source->storage->select_single(
1058     $attrs->{from}, $attrs->{select},
1059     $attrs->{where}, $attrs
1060   )];
1061   return undef unless @$data;
1062   $self->{stashed_rows} = [ $data ];
1063   $self->_construct_objects->[0];
1064 }
1065
1066
1067 # _collapse_query
1068 #
1069 # Recursively collapse the query, accumulating values for each column.
1070
1071 sub _collapse_query {
1072   my ($self, $query, $collapsed) = @_;
1073
1074   $collapsed ||= {};
1075
1076   if (ref $query eq 'ARRAY') {
1077     foreach my $subquery (@$query) {
1078       next unless ref $subquery;  # -or
1079       $collapsed = $self->_collapse_query($subquery, $collapsed);
1080     }
1081   }
1082   elsif (ref $query eq 'HASH') {
1083     if (keys %$query and (keys %$query)[0] eq '-and') {
1084       foreach my $subquery (@{$query->{-and}}) {
1085         $collapsed = $self->_collapse_query($subquery, $collapsed);
1086       }
1087     }
1088     else {
1089       foreach my $col (keys %$query) {
1090         my $value = $query->{$col};
1091         $collapsed->{$col}{$value}++;
1092       }
1093     }
1094   }
1095
1096   return $collapsed;
1097 }
1098
1099 =head2 get_column
1100
1101 =over 4
1102
1103 =item Arguments: $cond?
1104
1105 =item Return Value: $resultsetcolumn
1106
1107 =back
1108
1109   my $max_length = $rs->get_column('length')->max;
1110
1111 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1112
1113 =cut
1114
1115 sub get_column {
1116   my ($self, $column) = @_;
1117   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1118   return $new;
1119 }
1120
1121 =head2 search_like
1122
1123 =over 4
1124
1125 =item Arguments: $cond, \%attrs?
1126
1127 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1128
1129 =back
1130
1131   # WHERE title LIKE '%blue%'
1132   $cd_rs = $rs->search_like({ title => '%blue%'});
1133
1134 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1135 that this is simply a convenience method retained for ex Class::DBI users.
1136 You most likely want to use L</search> with specific operators.
1137
1138 For more information, see L<DBIx::Class::Manual::Cookbook>.
1139
1140 This method is deprecated and will be removed in 0.09. Use L</search()>
1141 instead. An example conversion is:
1142
1143   ->search_like({ foo => 'bar' });
1144
1145   # Becomes
1146
1147   ->search({ foo => { like => 'bar' } });
1148
1149 =cut
1150
1151 sub search_like {
1152   my $class = shift;
1153   carp_unique (
1154     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1155    .' Instead use ->search({ x => { -like => "y%" } })'
1156    .' (note the outer pair of {}s - they are important!)'
1157   );
1158   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1159   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1160   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1161   return $class->search($query, { %$attrs });
1162 }
1163
1164 =head2 slice
1165
1166 =over 4
1167
1168 =item Arguments: $first, $last
1169
1170 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1171
1172 =back
1173
1174 Returns a resultset or object list representing a subset of elements from the
1175 resultset slice is called on. Indexes are from 0, i.e., to get the first
1176 three records, call:
1177
1178   my ($one, $two, $three) = $rs->slice(0, 2);
1179
1180 =cut
1181
1182 sub slice {
1183   my ($self, $min, $max) = @_;
1184   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1185   $attrs->{offset} = $self->{attrs}{offset} || 0;
1186   $attrs->{offset} += $min;
1187   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1188   return $self->search(undef, $attrs);
1189   #my $slice = (ref $self)->new($self->result_source, $attrs);
1190   #return (wantarray ? $slice->all : $slice);
1191 }
1192
1193 =head2 next
1194
1195 =over 4
1196
1197 =item Arguments: none
1198
1199 =item Return Value: $result | undef
1200
1201 =back
1202
1203 Returns the next element in the resultset (C<undef> is there is none).
1204
1205 Can be used to efficiently iterate over records in the resultset:
1206
1207   my $rs = $schema->resultset('CD')->search;
1208   while (my $cd = $rs->next) {
1209     print $cd->title;
1210   }
1211
1212 Note that you need to store the resultset object, and call C<next> on it.
1213 Calling C<< resultset('Table')->next >> repeatedly will always return the
1214 first record from the resultset.
1215
1216 =cut
1217
1218 sub next {
1219   my ($self) = @_;
1220
1221   if (my $cache = $self->get_cache) {
1222     $self->{all_cache_position} ||= 0;
1223     return $cache->[$self->{all_cache_position}++];
1224   }
1225
1226   if ($self->{attrs}{cache}) {
1227     delete $self->{pager};
1228     $self->{all_cache_position} = 1;
1229     return ($self->all)[0];
1230   }
1231
1232   return shift(@{$self->{stashed_objects}}) if @{ $self->{stashed_objects}||[] };
1233
1234   $self->{stashed_objects} = $self->_construct_objects
1235     or return undef;
1236
1237   return shift @{$self->{stashed_objects}};
1238 }
1239
1240 # Constructs as many objects as it can in one pass while respecting
1241 # cursor laziness. Several modes of operation:
1242 #
1243 # * Always builds everything present in @{$self->{stashed_rows}}
1244 # * If called with $fetch_all true - pulls everything off the cursor and
1245 #   builds all objects in one pass
1246 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1247 #   and if the resultset is ordered properly by the left side:
1248 #   * Fetches stuff off the cursor until the "master object" changes,
1249 #     and saves the last extra row (if any) in @{$self->{stashed_rows}}
1250 #   OR
1251 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1252 #     was requested (there is no other way to collapse except for an
1253 #     eager cursor)
1254 # * If no collapse is requested - just get the next row, construct and
1255 #   return
1256 sub _construct_objects {
1257   my ($self, $fetch_all) = @_;
1258
1259   my $rsrc = $self->result_source;
1260   my $attrs = $self->_resolved_attrs;
1261   my $cursor = $self->cursor;
1262
1263   # this will be used as both initial raw-row collector AND as a RV of
1264   # _construct_objects. Not regrowing the array twice matters a lot...
1265   # a suprising amount actually
1266   my $rows = (delete $self->{stashed_rows}) || [];
1267   if ($fetch_all) {
1268     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1269     $rows = [ @$rows, $cursor->all ];
1270   }
1271   elsif (!$attrs->{collapse}) {
1272     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1273     push @$rows, do { my @r = $cursor->next; @r ? \@r : () }
1274       unless @$rows;
1275   }
1276   else {
1277     $attrs->{_ordered_for_collapse} ||= (!$attrs->{order_by}) ? undef : do {
1278       my $st = $rsrc->schema->storage;
1279       my @ord_cols = map
1280         { $_->[0] }
1281         ( $st->_extract_order_criteria($attrs->{order_by}) )
1282       ;
1283
1284       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1285
1286       for (0 .. $#ord_cols) {
1287         if (
1288           ! $colinfos->{$ord_cols[$_]}
1289             or
1290           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1291         ) {
1292           splice @ord_cols, $_;
1293           last;
1294         }
1295       }
1296
1297       # since all we check here are the start of the order_by belonging to the
1298       # top level $rsrc, a present identifying set will mean that the resultset
1299       # is ordered by its leftmost table in a tsable manner
1300       (@ord_cols and $rsrc->_identifying_column_set({ map
1301         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1302         @ord_cols
1303       })) ? 1 : 0;
1304     };
1305
1306     if ($attrs->{_ordered_for_collapse}) {
1307       push @$rows, do { my @r = $cursor->next; @r ? \@r : () };
1308     }
1309     # instead of looping over ->next, use ->all in stealth mode
1310     # FIXME - encapsulation breach, got to be a better way
1311     elsif (! $cursor->{done}) {
1312       push @$rows, $cursor->all;
1313       $cursor->{done} = 1;
1314       $fetch_all = 1;
1315     }
1316   }
1317
1318   return undef unless @$rows;
1319
1320   my $res_class = $self->result_class;
1321   my $inflator = $res_class->can ('inflate_result')
1322     or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1323
1324   my $infmap = $attrs->{as};
1325
1326   if (!$attrs->{collapse} and $attrs->{_single_object_inflation}) {
1327     # construct a much simpler array->hash folder for the one-table cases right here
1328
1329     # FIXME SUBOPTIMAL this is a very very very hot spot
1330     # while rather optimal we can *still* do much better, by
1331     # building a smarter [Row|HRI]::inflate_result(), and
1332     # switch to feeding it data via a much leaner interface
1333     #
1334     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1335     # this particular resultset size
1336     if (@$rows < 60) {
1337       my @as_idx = 0..$#$infmap;
1338       for my $r (@$rows) {
1339         $r = $inflator->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } @as_idx } );
1340       }
1341     }
1342     else {
1343       eval sprintf (
1344         '$_ = $inflator->($res_class, $rsrc, { %s }) for @$rows',
1345         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1346       );
1347     }
1348   }
1349   else {
1350     ($self->{_row_parser} ||= eval sprintf 'sub { %s }', $rsrc->_mk_row_parser({
1351       inflate_map => $infmap,
1352       selection => $attrs->{select},
1353       collapse => $attrs->{collapse},
1354     }) or die $@)->($rows, $fetch_all ? () : (
1355       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1356       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1357       ($self->{stashed_rows} = []),                 # where does it stuff excess
1358     ));  # modify $rows in-place, shrinking/extending as necessary
1359
1360     $_ = $inflator->($res_class, $rsrc, @$_) for @$rows;
1361
1362   }
1363
1364   # CDBI compat stuff
1365   if ($attrs->{record_filter}) {
1366     $_ = $attrs->{record_filter}->($_) for @$rows;
1367   }
1368
1369   return $rows;
1370 }
1371
1372 =head2 result_source
1373
1374 =over 4
1375
1376 =item Arguments: $result_source?
1377
1378 =item Return Value: $result_source
1379
1380 =back
1381
1382 An accessor for the primary ResultSource object from which this ResultSet
1383 is derived.
1384
1385 =head2 result_class
1386
1387 =over 4
1388
1389 =item Arguments: $result_class?
1390
1391 =item Return Value: $result_class
1392
1393 =back
1394
1395 An accessor for the class to use when creating row objects. Defaults to
1396 C<< result_source->result_class >> - which in most cases is the name of the
1397 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1398
1399 Note that changing the result_class will also remove any components
1400 that were originally loaded in the source class via
1401 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1402 in the original source class will not run.
1403
1404 =cut
1405
1406 sub result_class {
1407   my ($self, $result_class) = @_;
1408   if ($result_class) {
1409     unless (ref $result_class) { # don't fire this for an object
1410       $self->ensure_class_loaded($result_class);
1411     }
1412     $self->_result_class($result_class);
1413     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1414     # permit the user to set result class on one result set only; it only
1415     # chains if provided to search()
1416     #$self->{attrs}{result_class} = $result_class if ref $self;
1417   }
1418   $self->_result_class;
1419 }
1420
1421 =head2 count
1422
1423 =over 4
1424
1425 =item Arguments: $cond, \%attrs??
1426
1427 =item Return Value: $count
1428
1429 =back
1430
1431 Performs an SQL C<COUNT> with the same query as the resultset was built
1432 with to find the number of elements. Passing arguments is equivalent to
1433 C<< $rs->search ($cond, \%attrs)->count >>
1434
1435 =cut
1436
1437 sub count {
1438   my $self = shift;
1439   return $self->search(@_)->count if @_ and defined $_[0];
1440   return scalar @{ $self->get_cache } if $self->get_cache;
1441
1442   my $attrs = $self->_resolved_attrs_copy;
1443
1444   # this is a little optimization - it is faster to do the limit
1445   # adjustments in software, instead of a subquery
1446   my $rows = delete $attrs->{rows};
1447   my $offset = delete $attrs->{offset};
1448
1449   my $crs;
1450   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1451     $crs = $self->_count_subq_rs ($attrs);
1452   }
1453   else {
1454     $crs = $self->_count_rs ($attrs);
1455   }
1456   my $count = $crs->next;
1457
1458   $count -= $offset if $offset;
1459   $count = $rows if $rows and $rows < $count;
1460   $count = 0 if ($count < 0);
1461
1462   return $count;
1463 }
1464
1465 =head2 count_rs
1466
1467 =over 4
1468
1469 =item Arguments: $cond, \%attrs??
1470
1471 =item Return Value: $count_rs
1472
1473 =back
1474
1475 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1476 This can be very handy for subqueries:
1477
1478   ->search( { amount => $some_rs->count_rs->as_query } )
1479
1480 As with regular resultsets the SQL query will be executed only after
1481 the resultset is accessed via L</next> or L</all>. That would return
1482 the same single value obtainable via L</count>.
1483
1484 =cut
1485
1486 sub count_rs {
1487   my $self = shift;
1488   return $self->search(@_)->count_rs if @_;
1489
1490   # this may look like a lack of abstraction (count() does about the same)
1491   # but in fact an _rs *must* use a subquery for the limits, as the
1492   # software based limiting can not be ported if this $rs is to be used
1493   # in a subquery itself (i.e. ->as_query)
1494   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1495     return $self->_count_subq_rs;
1496   }
1497   else {
1498     return $self->_count_rs;
1499   }
1500 }
1501
1502 #
1503 # returns a ResultSetColumn object tied to the count query
1504 #
1505 sub _count_rs {
1506   my ($self, $attrs) = @_;
1507
1508   my $rsrc = $self->result_source;
1509   $attrs ||= $self->_resolved_attrs;
1510
1511   my $tmp_attrs = { %$attrs };
1512   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1513   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1514
1515   # overwrite the selector (supplied by the storage)
1516   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1517   $tmp_attrs->{as} = 'count';
1518   delete @{$tmp_attrs}{qw/columns/};
1519
1520   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1521
1522   return $tmp_rs;
1523 }
1524
1525 #
1526 # same as above but uses a subquery
1527 #
1528 sub _count_subq_rs {
1529   my ($self, $attrs) = @_;
1530
1531   my $rsrc = $self->result_source;
1532   $attrs ||= $self->_resolved_attrs;
1533
1534   my $sub_attrs = { %$attrs };
1535   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1536   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1537
1538   # if we multi-prefetch we group_by something unique, as this is what we would
1539   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1540   if ( $attrs->{collapse}  ) {
1541     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1542       $rsrc->_identifying_column_set || $self->throw_exception(
1543         'Unable to construct a unique group_by criteria properly collapsing the '
1544       . 'has_many prefetch before count()'
1545       );
1546     } ]
1547   }
1548
1549   # Calculate subquery selector
1550   if (my $g = $sub_attrs->{group_by}) {
1551
1552     my $sql_maker = $rsrc->storage->sql_maker;
1553
1554     # necessary as the group_by may refer to aliased functions
1555     my $sel_index;
1556     for my $sel (@{$attrs->{select}}) {
1557       $sel_index->{$sel->{-as}} = $sel
1558         if (ref $sel eq 'HASH' and $sel->{-as});
1559     }
1560
1561     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1562     # also look for named aggregates referred in the having clause
1563     # having often contains scalarrefs - thus parse it out entirely
1564     my @parts = @$g;
1565     if ($attrs->{having}) {
1566       local $sql_maker->{having_bind};
1567       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1568       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1569       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1570         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1571         # if we don't unset it we screw up retarded but unfortunately working
1572         # 'MAX(foo.bar)' => { '>', 3 }
1573         $sql_maker->{name_sep} = '';
1574       }
1575
1576       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1577
1578       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1579
1580       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1581       # and if all fails for an utterly naive quoted scalar-with-function
1582       while ($sql =~ /
1583         $rquote $sep $lquote (.+?) $rquote
1584           |
1585         [\s,] \w+ \. (\w+) [\s,]
1586           |
1587         [\s,] $lquote (.+?) $rquote [\s,]
1588       /gx) {
1589         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1590       }
1591     }
1592
1593     for (@parts) {
1594       my $colpiece = $sel_index->{$_} || $_;
1595
1596       # unqualify join-based group_by's. Arcane but possible query
1597       # also horrible horrible hack to alias a column (not a func.)
1598       # (probably need to introduce SQLA syntax)
1599       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1600         my $as = $colpiece;
1601         $as =~ s/\./__/;
1602         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1603       }
1604       push @{$sub_attrs->{select}}, $colpiece;
1605     }
1606   }
1607   else {
1608     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1609     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1610   }
1611
1612   return $rsrc->resultset_class
1613                ->new ($rsrc, $sub_attrs)
1614                 ->as_subselect_rs
1615                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1616                   ->get_column ('count');
1617 }
1618
1619 sub _bool {
1620   return 1;
1621 }
1622
1623 =head2 count_literal
1624
1625 =over 4
1626
1627 =item Arguments: $sql_fragment, @bind_values
1628
1629 =item Return Value: $count
1630
1631 =back
1632
1633 Counts the results in a literal query. Equivalent to calling L</search_literal>
1634 with the passed arguments, then L</count>.
1635
1636 =cut
1637
1638 sub count_literal { shift->search_literal(@_)->count; }
1639
1640 =head2 all
1641
1642 =over 4
1643
1644 =item Arguments: none
1645
1646 =item Return Value: @objects
1647
1648 =back
1649
1650 Returns all elements in the resultset.
1651
1652 =cut
1653
1654 sub all {
1655   my $self = shift;
1656   if(@_) {
1657     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1658   }
1659
1660   delete $self->{stashed_rows};
1661   delete $self->{stashed_objects};
1662
1663   if (my $c = $self->get_cache) {
1664     return @$c;
1665   }
1666
1667   $self->cursor->reset;
1668
1669   my $objs = $self->_construct_objects('fetch_all') || [];
1670
1671   $self->set_cache($objs) if $self->{attrs}{cache};
1672
1673   return @$objs;
1674 }
1675
1676 =head2 reset
1677
1678 =over 4
1679
1680 =item Arguments: none
1681
1682 =item Return Value: $self
1683
1684 =back
1685
1686 Resets the resultset's cursor, so you can iterate through the elements again.
1687 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1688 another query.
1689
1690 =cut
1691
1692 sub reset {
1693   my ($self) = @_;
1694   delete $self->{_attrs};
1695   delete $self->{stashed_rows};
1696   delete $self->{stashed_objects};
1697
1698   $self->{all_cache_position} = 0;
1699   $self->cursor->reset;
1700   return $self;
1701 }
1702
1703 =head2 first
1704
1705 =over 4
1706
1707 =item Arguments: none
1708
1709 =item Return Value: $object | undef
1710
1711 =back
1712
1713 Resets the resultset and returns an object for the first result (or C<undef>
1714 if the resultset is empty).
1715
1716 =cut
1717
1718 sub first {
1719   return $_[0]->reset->next;
1720 }
1721
1722
1723 # _rs_update_delete
1724 #
1725 # Determines whether and what type of subquery is required for the $rs operation.
1726 # If grouping is necessary either supplies its own, or verifies the current one
1727 # After all is done delegates to the proper storage method.
1728
1729 sub _rs_update_delete {
1730   my ($self, $op, $values) = @_;
1731
1732   my $cond = $self->{cond};
1733   my $rsrc = $self->result_source;
1734   my $storage = $rsrc->schema->storage;
1735
1736   my $attrs = { %{$self->_resolved_attrs} };
1737
1738   # "needs" is a strong word here - if the subquery is part of an IN clause - no point of
1739   # even adding the group_by. It will really be used only when composing a poor-man's
1740   # multicolumn-IN equivalent OR set
1741   my $needs_group_by_subq = defined $attrs->{group_by};
1742
1743   # simplify the joinmap and maybe decide if a grouping (and thus subquery) is necessary
1744   my $relation_classifications;
1745   if (ref($attrs->{from}) eq 'ARRAY') {
1746     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1747
1748     $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1749       [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1750       $attrs->{select},
1751       $cond,
1752       $attrs
1753     ) unless $needs_group_by_subq;  # we already know we need a group, no point of resolving them
1754   }
1755   else {
1756     $needs_group_by_subq ||= 1; # if {from} is unparseable assume the worst
1757   }
1758
1759   $needs_group_by_subq ||= exists $relation_classifications->{multiplying};
1760
1761   # if no subquery - life is easy-ish
1762   unless (
1763     $needs_group_by_subq
1764       or
1765     keys %$relation_classifications # if any joins at all - need to wrap a subq
1766       or
1767     $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1768   ) {
1769     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1770     # a condition containing 'me' or other table prefixes will not work
1771     # at all. What this code tries to do (badly) is to generate a condition
1772     # with the qualifiers removed, by exploiting the quote mechanism of sqla
1773     #
1774     # this is atrocious and should be replaced by normal sqla introspection
1775     # one sunny day
1776     my ($sql, @bind) = do {
1777       my $sqla = $rsrc->storage->sql_maker;
1778       local $sqla->{_dequalify_idents} = 1;
1779       $sqla->_recurse_where($self->{cond});
1780     } if $self->{cond};
1781
1782     return $rsrc->storage->$op(
1783       $rsrc,
1784       $op eq 'update' ? $values : (),
1785       $self->{cond} ? \[$sql, @bind] : (),
1786     );
1787   }
1788
1789   # we got this far - means it is time to wrap a subquery
1790   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1791     sprintf(
1792       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1793       $op,
1794       $rsrc->source_name,
1795     )
1796   );
1797   my $existing_group_by = delete $attrs->{group_by};
1798
1799   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1800   delete $attrs->{$_} for qw/collapse select _prefetch_selector_range as/;
1801   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1802   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1803   my $subrs = (ref $self)->new($rsrc, $attrs);
1804
1805   if (@$idcols == 1) {
1806     return $storage->$op (
1807       $rsrc,
1808       $op eq 'update' ? $values : (),
1809       { $idcols->[0] => { -in => $subrs->as_query } },
1810     );
1811   }
1812   elsif ($storage->_use_multicolumn_in) {
1813     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1814     my $sql_maker = $storage->sql_maker;
1815     my ($sql, @bind) = @${$subrs->as_query};
1816     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1817       join (', ', map { $sql_maker->_quote ($_) } @$idcols),
1818       $sql,
1819     );
1820
1821     return $storage->$op (
1822       $rsrc,
1823       $op eq 'update' ? $values : (),
1824       \[$sql, @bind],
1825     );
1826   }
1827   else {
1828     # if all else fails - get all primary keys and operate over a ORed set
1829     # wrap in a transaction for consistency
1830     # this is where the group_by starts to matter
1831     my $subq_group_by;
1832     if ($needs_group_by_subq) {
1833       $subq_group_by = $attrs->{columns};
1834
1835       # make sure if there is a supplied group_by it matches the columns compiled above
1836       # perfectly. Anything else can not be sanely executed on most databases so croak
1837       # right then and there
1838       if ($existing_group_by) {
1839         my @current_group_by = map
1840           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1841           @$existing_group_by
1842         ;
1843
1844         if (
1845           join ("\x00", sort @current_group_by)
1846             ne
1847           join ("\x00", sort @$subq_group_by )
1848         ) {
1849           $self->throw_exception (
1850             "You have just attempted a $op operation on a resultset which does group_by"
1851             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1852             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1853             . ' kind of queries. Please retry the operation with a modified group_by or'
1854             . ' without using one at all.'
1855           );
1856         }
1857       }
1858     }
1859
1860     my $guard = $storage->txn_scope_guard;
1861
1862     my @op_condition;
1863     for my $row ($subrs->search({}, { group_by => $subq_group_by })->cursor->all) {
1864       push @op_condition, { map
1865         { $idcols->[$_] => $row->[$_] }
1866         (0 .. $#$idcols)
1867       };
1868     }
1869
1870     my $res = $storage->$op (
1871       $rsrc,
1872       $op eq 'update' ? $values : (),
1873       \@op_condition,
1874     );
1875
1876     $guard->commit;
1877
1878     return $res;
1879   }
1880 }
1881
1882 =head2 update
1883
1884 =over 4
1885
1886 =item Arguments: \%values
1887
1888 =item Return Value: $storage_rv
1889
1890 =back
1891
1892 Sets the specified columns in the resultset to the supplied values in a
1893 single query. Note that this will not run any accessor/set_column/update
1894 triggers, nor will it update any row object instances derived from this
1895 resultset (this includes the contents of the L<resultset cache|/set_cache>
1896 if any). See L</update_all> if you need to execute any on-update
1897 triggers or cascades defined either by you or a
1898 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1899
1900 The return value is a pass through of what the underlying
1901 storage backend returned, and may vary. See L<DBI/execute> for the most
1902 common case.
1903
1904 =head3 CAVEAT
1905
1906 Note that L</update> does not process/deflate any of the values passed in.
1907 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1908 ensure manually that any value passed to this method will stringify to
1909 something the RDBMS knows how to deal with. A notable example is the
1910 handling of L<DateTime> objects, for more info see:
1911 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1912
1913 =cut
1914
1915 sub update {
1916   my ($self, $values) = @_;
1917   $self->throw_exception('Values for update must be a hash')
1918     unless ref $values eq 'HASH';
1919
1920   return $self->_rs_update_delete ('update', $values);
1921 }
1922
1923 =head2 update_all
1924
1925 =over 4
1926
1927 =item Arguments: \%values
1928
1929 =item Return Value: 1
1930
1931 =back
1932
1933 Fetches all objects and updates them one at a time via
1934 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1935 triggers, while L</update> will not.
1936
1937 =cut
1938
1939 sub update_all {
1940   my ($self, $values) = @_;
1941   $self->throw_exception('Values for update_all must be a hash')
1942     unless ref $values eq 'HASH';
1943
1944   my $guard = $self->result_source->schema->txn_scope_guard;
1945   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1946   $guard->commit;
1947   return 1;
1948 }
1949
1950 =head2 delete
1951
1952 =over 4
1953
1954 =item Arguments: none
1955
1956 =item Return Value: $storage_rv
1957
1958 =back
1959
1960 Deletes the rows matching this resultset in a single query. Note that this
1961 will not run any delete triggers, nor will it alter the
1962 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1963 derived from this resultset (this includes the contents of the
1964 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1965 execute any on-delete triggers or cascades defined either by you or a
1966 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1967
1968 The return value is a pass through of what the underlying storage backend
1969 returned, and may vary. See L<DBI/execute> for the most common case.
1970
1971 =cut
1972
1973 sub delete {
1974   my $self = shift;
1975   $self->throw_exception('delete does not accept any arguments')
1976     if @_;
1977
1978   return $self->_rs_update_delete ('delete');
1979 }
1980
1981 =head2 delete_all
1982
1983 =over 4
1984
1985 =item Arguments: none
1986
1987 =item Return Value: 1
1988
1989 =back
1990
1991 Fetches all objects and deletes them one at a time via
1992 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1993 triggers, while L</delete> will not.
1994
1995 =cut
1996
1997 sub delete_all {
1998   my $self = shift;
1999   $self->throw_exception('delete_all does not accept any arguments')
2000     if @_;
2001
2002   my $guard = $self->result_source->schema->txn_scope_guard;
2003   $_->delete for $self->all;
2004   $guard->commit;
2005   return 1;
2006 }
2007
2008 =head2 populate
2009
2010 =over 4
2011
2012 =item Arguments: \@data;
2013
2014 =back
2015
2016 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
2017 For the arrayref of hashrefs style each hashref should be a structure suitable
2018 for submitting to a $resultset->create(...) method.
2019
2020 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
2021 to insert the data, as this is a faster method.
2022
2023 Otherwise, each set of data is inserted into the database using
2024 L<DBIx::Class::ResultSet/create>, and the resulting objects are
2025 accumulated into an array. The array itself, or an array reference
2026 is returned depending on scalar or list context.
2027
2028 Example:  Assuming an Artist Class that has many CDs Classes relating:
2029
2030   my $Artist_rs = $schema->resultset("Artist");
2031
2032   ## Void Context Example
2033   $Artist_rs->populate([
2034      { artistid => 4, name => 'Manufactured Crap', cds => [
2035         { title => 'My First CD', year => 2006 },
2036         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2037       ],
2038      },
2039      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2040         { title => 'My parents sold me to a record company', year => 2005 },
2041         { title => 'Why Am I So Ugly?', year => 2006 },
2042         { title => 'I Got Surgery and am now Popular', year => 2007 }
2043       ],
2044      },
2045   ]);
2046
2047   ## Array Context Example
2048   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
2049     { name => "Artist One"},
2050     { name => "Artist Two"},
2051     { name => "Artist Three", cds=> [
2052     { title => "First CD", year => 2007},
2053     { title => "Second CD", year => 2008},
2054   ]}
2055   ]);
2056
2057   print $ArtistOne->name; ## response is 'Artist One'
2058   print $ArtistThree->cds->count ## reponse is '2'
2059
2060 For the arrayref of arrayrefs style,  the first element should be a list of the
2061 fieldsnames to which the remaining elements are rows being inserted.  For
2062 example:
2063
2064   $Arstist_rs->populate([
2065     [qw/artistid name/],
2066     [100, 'A Formally Unknown Singer'],
2067     [101, 'A singer that jumped the shark two albums ago'],
2068     [102, 'An actually cool singer'],
2069   ]);
2070
2071 Please note an important effect on your data when choosing between void and
2072 wantarray context. Since void context goes straight to C<insert_bulk> in
2073 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
2074 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
2075 create primary keys for you, you will find that your PKs are empty.  In this
2076 case you will have to use the wantarray context in order to create those
2077 values.
2078
2079 =cut
2080
2081 sub populate {
2082   my $self = shift;
2083
2084   # cruft placed in standalone method
2085   my $data = $self->_normalize_populate_args(@_);
2086
2087   return unless @$data;
2088
2089   if(defined wantarray) {
2090     my @created;
2091     foreach my $item (@$data) {
2092       push(@created, $self->create($item));
2093     }
2094     return wantarray ? @created : \@created;
2095   }
2096   else {
2097     my $first = $data->[0];
2098
2099     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2100     # it relationship data
2101     my (@rels, @columns);
2102     my $rsrc = $self->result_source;
2103     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2104     for (keys %$first) {
2105       my $ref = ref $first->{$_};
2106       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2107         ? push @rels, $_
2108         : push @columns, $_
2109       ;
2110     }
2111
2112     my @pks = $rsrc->primary_columns;
2113
2114     ## do the belongs_to relationships
2115     foreach my $index (0..$#$data) {
2116
2117       # delegate to create() for any dataset without primary keys with specified relationships
2118       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2119         for my $r (@rels) {
2120           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2121             my @ret = $self->populate($data);
2122             return;
2123           }
2124         }
2125       }
2126
2127       foreach my $rel (@rels) {
2128         next unless ref $data->[$index]->{$rel} eq "HASH";
2129         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2130         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2131         my $related = $result->result_source->_resolve_condition(
2132           $reverse_relinfo->{cond},
2133           $self,
2134           $result,
2135           $rel,
2136         );
2137
2138         delete $data->[$index]->{$rel};
2139         $data->[$index] = {%{$data->[$index]}, %$related};
2140
2141         push @columns, keys %$related if $index == 0;
2142       }
2143     }
2144
2145     ## inherit the data locked in the conditions of the resultset
2146     my ($rs_data) = $self->_merge_with_rscond({});
2147     delete @{$rs_data}{@columns};
2148     my @inherit_cols = keys %$rs_data;
2149     my @inherit_data = values %$rs_data;
2150
2151     ## do bulk insert on current row
2152     $rsrc->storage->insert_bulk(
2153       $rsrc,
2154       [@columns, @inherit_cols],
2155       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
2156     );
2157
2158     ## do the has_many relationships
2159     foreach my $item (@$data) {
2160
2161       my $main_row;
2162
2163       foreach my $rel (@rels) {
2164         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2165
2166         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2167
2168         my $child = $main_row->$rel;
2169
2170         my $related = $child->result_source->_resolve_condition(
2171           $rels->{$rel}{cond},
2172           $child,
2173           $main_row,
2174           $rel,
2175         );
2176
2177         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2178         my @populate = map { {%$_, %$related} } @rows_to_add;
2179
2180         $child->populate( \@populate );
2181       }
2182     }
2183   }
2184 }
2185
2186
2187 # populate() argumnets went over several incarnations
2188 # What we ultimately support is AoH
2189 sub _normalize_populate_args {
2190   my ($self, $arg) = @_;
2191
2192   if (ref $arg eq 'ARRAY') {
2193     if (!@$arg) {
2194       return [];
2195     }
2196     elsif (ref $arg->[0] eq 'HASH') {
2197       return $arg;
2198     }
2199     elsif (ref $arg->[0] eq 'ARRAY') {
2200       my @ret;
2201       my @colnames = @{$arg->[0]};
2202       foreach my $values (@{$arg}[1 .. $#$arg]) {
2203         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2204       }
2205       return \@ret;
2206     }
2207   }
2208
2209   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2210 }
2211
2212 =head2 pager
2213
2214 =over 4
2215
2216 =item Arguments: none
2217
2218 =item Return Value: $pager
2219
2220 =back
2221
2222 Return Value a L<Data::Page> object for the current resultset. Only makes
2223 sense for queries with a C<page> attribute.
2224
2225 To get the full count of entries for a paged resultset, call
2226 C<total_entries> on the L<Data::Page> object.
2227
2228 =cut
2229
2230 sub pager {
2231   my ($self) = @_;
2232
2233   return $self->{pager} if $self->{pager};
2234
2235   my $attrs = $self->{attrs};
2236   if (!defined $attrs->{page}) {
2237     $self->throw_exception("Can't create pager for non-paged rs");
2238   }
2239   elsif ($attrs->{page} <= 0) {
2240     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2241   }
2242   $attrs->{rows} ||= 10;
2243
2244   # throw away the paging flags and re-run the count (possibly
2245   # with a subselect) to get the real total count
2246   my $count_attrs = { %$attrs };
2247   delete $count_attrs->{$_} for qw/rows offset page pager/;
2248
2249   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2250
2251   require DBIx::Class::ResultSet::Pager;
2252   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2253     sub { $total_rs->count },  #lazy-get the total
2254     $attrs->{rows},
2255     $self->{attrs}{page},
2256   );
2257 }
2258
2259 =head2 page
2260
2261 =over 4
2262
2263 =item Arguments: $page_number
2264
2265 =item Return Value: $rs
2266
2267 =back
2268
2269 Returns a resultset for the $page_number page of the resultset on which page
2270 is called, where each page contains a number of rows equal to the 'rows'
2271 attribute set on the resultset (10 by default).
2272
2273 =cut
2274
2275 sub page {
2276   my ($self, $page) = @_;
2277   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2278 }
2279
2280 =head2 new_result
2281
2282 =over 4
2283
2284 =item Arguments: \%vals
2285
2286 =item Return Value: $rowobject
2287
2288 =back
2289
2290 Creates a new row object in the resultset's result class and returns
2291 it. The row is not inserted into the database at this point, call
2292 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2293 will tell you whether the row object has been inserted or not.
2294
2295 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2296
2297 =cut
2298
2299 sub new_result {
2300   my ($self, $values) = @_;
2301   $self->throw_exception( "new_result needs a hash" )
2302     unless (ref $values eq 'HASH');
2303
2304   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2305
2306   my %new = (
2307     %$merged_cond,
2308     @$cols_from_relations
2309       ? (-cols_from_relations => $cols_from_relations)
2310       : (),
2311     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2312   );
2313
2314   return $self->result_class->new(\%new);
2315 }
2316
2317 # _merge_with_rscond
2318 #
2319 # Takes a simple hash of K/V data and returns its copy merged with the
2320 # condition already present on the resultset. Additionally returns an
2321 # arrayref of value/condition names, which were inferred from related
2322 # objects (this is needed for in-memory related objects)
2323 sub _merge_with_rscond {
2324   my ($self, $data) = @_;
2325
2326   my (%new_data, @cols_from_relations);
2327
2328   my $alias = $self->{attrs}{alias};
2329
2330   if (! defined $self->{cond}) {
2331     # just massage $data below
2332   }
2333   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2334     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2335     @cols_from_relations = keys %new_data;
2336   }
2337   elsif (ref $self->{cond} ne 'HASH') {
2338     $self->throw_exception(
2339       "Can't abstract implicit construct, resultset condition not a hash"
2340     );
2341   }
2342   else {
2343     # precendence must be given to passed values over values inherited from
2344     # the cond, so the order here is important.
2345     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2346     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2347
2348     while ( my($col, $value) = each %implied ) {
2349       my $vref = ref $value;
2350       if (
2351         $vref eq 'HASH'
2352           and
2353         keys(%$value) == 1
2354           and
2355         (keys %$value)[0] eq '='
2356       ) {
2357         $new_data{$col} = $value->{'='};
2358       }
2359       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2360         $new_data{$col} = $value;
2361       }
2362     }
2363   }
2364
2365   %new_data = (
2366     %new_data,
2367     %{ $self->_remove_alias($data, $alias) },
2368   );
2369
2370   return (\%new_data, \@cols_from_relations);
2371 }
2372
2373 # _has_resolved_attr
2374 #
2375 # determines if the resultset defines at least one
2376 # of the attributes supplied
2377 #
2378 # used to determine if a subquery is neccessary
2379 #
2380 # supports some virtual attributes:
2381 #   -join
2382 #     This will scan for any joins being present on the resultset.
2383 #     It is not a mere key-search but a deep inspection of {from}
2384 #
2385
2386 sub _has_resolved_attr {
2387   my ($self, @attr_names) = @_;
2388
2389   my $attrs = $self->_resolved_attrs;
2390
2391   my %extra_checks;
2392
2393   for my $n (@attr_names) {
2394     if (grep { $n eq $_ } (qw/-join/) ) {
2395       $extra_checks{$n}++;
2396       next;
2397     }
2398
2399     my $attr =  $attrs->{$n};
2400
2401     next if not defined $attr;
2402
2403     if (ref $attr eq 'HASH') {
2404       return 1 if keys %$attr;
2405     }
2406     elsif (ref $attr eq 'ARRAY') {
2407       return 1 if @$attr;
2408     }
2409     else {
2410       return 1 if $attr;
2411     }
2412   }
2413
2414   # a resolved join is expressed as a multi-level from
2415   return 1 if (
2416     $extra_checks{-join}
2417       and
2418     ref $attrs->{from} eq 'ARRAY'
2419       and
2420     @{$attrs->{from}} > 1
2421   );
2422
2423   return 0;
2424 }
2425
2426 # _collapse_cond
2427 #
2428 # Recursively collapse the condition.
2429
2430 sub _collapse_cond {
2431   my ($self, $cond, $collapsed) = @_;
2432
2433   $collapsed ||= {};
2434
2435   if (ref $cond eq 'ARRAY') {
2436     foreach my $subcond (@$cond) {
2437       next unless ref $subcond;  # -or
2438       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2439     }
2440   }
2441   elsif (ref $cond eq 'HASH') {
2442     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2443       foreach my $subcond (@{$cond->{-and}}) {
2444         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2445       }
2446     }
2447     else {
2448       foreach my $col (keys %$cond) {
2449         my $value = $cond->{$col};
2450         $collapsed->{$col} = $value;
2451       }
2452     }
2453   }
2454
2455   return $collapsed;
2456 }
2457
2458 # _remove_alias
2459 #
2460 # Remove the specified alias from the specified query hash. A copy is made so
2461 # the original query is not modified.
2462
2463 sub _remove_alias {
2464   my ($self, $query, $alias) = @_;
2465
2466   my %orig = %{ $query || {} };
2467   my %unaliased;
2468
2469   foreach my $key (keys %orig) {
2470     if ($key !~ /\./) {
2471       $unaliased{$key} = $orig{$key};
2472       next;
2473     }
2474     $unaliased{$1} = $orig{$key}
2475       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2476   }
2477
2478   return \%unaliased;
2479 }
2480
2481 =head2 as_query
2482
2483 =over 4
2484
2485 =item Arguments: none
2486
2487 =item Return Value: \[ $sql, @bind ]
2488
2489 =back
2490
2491 Returns the SQL query and bind vars associated with the invocant.
2492
2493 This is generally used as the RHS for a subquery.
2494
2495 =cut
2496
2497 sub as_query {
2498   my $self = shift;
2499
2500   my $attrs = $self->_resolved_attrs_copy;
2501
2502   # For future use:
2503   #
2504   # in list ctx:
2505   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2506   # $sql also has no wrapping parenthesis in list ctx
2507   #
2508   my $sqlbind = $self->result_source->storage
2509     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2510
2511   return $sqlbind;
2512 }
2513
2514 =head2 find_or_new
2515
2516 =over 4
2517
2518 =item Arguments: \%vals, \%attrs?
2519
2520 =item Return Value: $rowobject
2521
2522 =back
2523
2524   my $artist = $schema->resultset('Artist')->find_or_new(
2525     { artist => 'fred' }, { key => 'artists' });
2526
2527   $cd->cd_to_producer->find_or_new({ producer => $producer },
2528                                    { key => 'primary });
2529
2530 Find an existing record from this resultset using L</find>. if none exists,
2531 instantiate a new result object and return it. The object will not be saved
2532 into your storage until you call L<DBIx::Class::Row/insert> on it.
2533
2534 You most likely want this method when looking for existing rows using a unique
2535 constraint that is not the primary key, or looking for related rows.
2536
2537 If you want objects to be saved immediately, use L</find_or_create> instead.
2538
2539 B<Note>: Make sure to read the documentation of L</find> and understand the
2540 significance of the C<key> attribute, as its lack may skew your search, and
2541 subsequently result in spurious new objects.
2542
2543 B<Note>: Take care when using C<find_or_new> with a table having
2544 columns with default values that you intend to be automatically
2545 supplied by the database (e.g. an auto_increment primary key column).
2546 In normal usage, the value of such columns should NOT be included at
2547 all in the call to C<find_or_new>, even when set to C<undef>.
2548
2549 =cut
2550
2551 sub find_or_new {
2552   my $self     = shift;
2553   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2554   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2555   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2556     return $row;
2557   }
2558   return $self->new_result($hash);
2559 }
2560
2561 =head2 create
2562
2563 =over 4
2564
2565 =item Arguments: \%vals
2566
2567 =item Return Value: a L<DBIx::Class::Row> $object
2568
2569 =back
2570
2571 Attempt to create a single new row or a row with multiple related rows
2572 in the table represented by the resultset (and related tables). This
2573 will not check for duplicate rows before inserting, use
2574 L</find_or_create> to do that.
2575
2576 To create one row for this resultset, pass a hashref of key/value
2577 pairs representing the columns of the table and the values you wish to
2578 store. If the appropriate relationships are set up, foreign key fields
2579 can also be passed an object representing the foreign row, and the
2580 value will be set to its primary key.
2581
2582 To create related objects, pass a hashref of related-object column values
2583 B<keyed on the relationship name>. If the relationship is of type C<multi>
2584 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2585 The process will correctly identify columns holding foreign keys, and will
2586 transparently populate them from the keys of the corresponding relation.
2587 This can be applied recursively, and will work correctly for a structure
2588 with an arbitrary depth and width, as long as the relationships actually
2589 exists and the correct column data has been supplied.
2590
2591
2592 Instead of hashrefs of plain related data (key/value pairs), you may
2593 also pass new or inserted objects. New objects (not inserted yet, see
2594 L</new>), will be inserted into their appropriate tables.
2595
2596 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2597
2598 Example of creating a new row.
2599
2600   $person_rs->create({
2601     name=>"Some Person",
2602     email=>"somebody@someplace.com"
2603   });
2604
2605 Example of creating a new row and also creating rows in a related C<has_many>
2606 or C<has_one> resultset.  Note Arrayref.
2607
2608   $artist_rs->create(
2609      { artistid => 4, name => 'Manufactured Crap', cds => [
2610         { title => 'My First CD', year => 2006 },
2611         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2612       ],
2613      },
2614   );
2615
2616 Example of creating a new row and also creating a row in a related
2617 C<belongs_to> resultset. Note Hashref.
2618
2619   $cd_rs->create({
2620     title=>"Music for Silly Walks",
2621     year=>2000,
2622     artist => {
2623       name=>"Silly Musician",
2624     }
2625   });
2626
2627 =over
2628
2629 =item WARNING
2630
2631 When subclassing ResultSet never attempt to override this method. Since
2632 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2633 lot of the internals simply never call it, so your override will be
2634 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2635 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2636 L</create> process you need to intervene.
2637
2638 =back
2639
2640 =cut
2641
2642 sub create {
2643   my ($self, $attrs) = @_;
2644   $self->throw_exception( "create needs a hashref" )
2645     unless ref $attrs eq 'HASH';
2646   return $self->new_result($attrs)->insert;
2647 }
2648
2649 =head2 find_or_create
2650
2651 =over 4
2652
2653 =item Arguments: \%vals, \%attrs?
2654
2655 =item Return Value: $rowobject
2656
2657 =back
2658
2659   $cd->cd_to_producer->find_or_create({ producer => $producer },
2660                                       { key => 'primary' });
2661
2662 Tries to find a record based on its primary key or unique constraints; if none
2663 is found, creates one and returns that instead.
2664
2665   my $cd = $schema->resultset('CD')->find_or_create({
2666     cdid   => 5,
2667     artist => 'Massive Attack',
2668     title  => 'Mezzanine',
2669     year   => 2005,
2670   });
2671
2672 Also takes an optional C<key> attribute, to search by a specific key or unique
2673 constraint. For example:
2674
2675   my $cd = $schema->resultset('CD')->find_or_create(
2676     {
2677       artist => 'Massive Attack',
2678       title  => 'Mezzanine',
2679     },
2680     { key => 'cd_artist_title' }
2681   );
2682
2683 B<Note>: Make sure to read the documentation of L</find> and understand the
2684 significance of the C<key> attribute, as its lack may skew your search, and
2685 subsequently result in spurious row creation.
2686
2687 B<Note>: Because find_or_create() reads from the database and then
2688 possibly inserts based on the result, this method is subject to a race
2689 condition. Another process could create a record in the table after
2690 the find has completed and before the create has started. To avoid
2691 this problem, use find_or_create() inside a transaction.
2692
2693 B<Note>: Take care when using C<find_or_create> with a table having
2694 columns with default values that you intend to be automatically
2695 supplied by the database (e.g. an auto_increment primary key column).
2696 In normal usage, the value of such columns should NOT be included at
2697 all in the call to C<find_or_create>, even when set to C<undef>.
2698
2699 See also L</find> and L</update_or_create>. For information on how to declare
2700 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2701
2702 If you need to know if an existing row was found or a new one created use
2703 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2704 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2705 database!
2706
2707   my $cd = $schema->resultset('CD')->find_or_new({
2708     cdid   => 5,
2709     artist => 'Massive Attack',
2710     title  => 'Mezzanine',
2711     year   => 2005,
2712   });
2713
2714   if( $cd->in_storage ) {
2715       # do some stuff
2716       $cd->insert;
2717   }
2718
2719 =cut
2720
2721 sub find_or_create {
2722   my $self     = shift;
2723   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2724   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2725   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2726     return $row;
2727   }
2728   return $self->create($hash);
2729 }
2730
2731 =head2 update_or_create
2732
2733 =over 4
2734
2735 =item Arguments: \%col_values, { key => $unique_constraint }?
2736
2737 =item Return Value: $row_object
2738
2739 =back
2740
2741   $resultset->update_or_create({ col => $val, ... });
2742
2743 Like L</find_or_create>, but if a row is found it is immediately updated via
2744 C<< $found_row->update (\%col_values) >>.
2745
2746
2747 Takes an optional C<key> attribute to search on a specific unique constraint.
2748 For example:
2749
2750   # In your application
2751   my $cd = $schema->resultset('CD')->update_or_create(
2752     {
2753       artist => 'Massive Attack',
2754       title  => 'Mezzanine',
2755       year   => 1998,
2756     },
2757     { key => 'cd_artist_title' }
2758   );
2759
2760   $cd->cd_to_producer->update_or_create({
2761     producer => $producer,
2762     name => 'harry',
2763   }, {
2764     key => 'primary',
2765   });
2766
2767 B<Note>: Make sure to read the documentation of L</find> and understand the
2768 significance of the C<key> attribute, as its lack may skew your search, and
2769 subsequently result in spurious row creation.
2770
2771 B<Note>: Take care when using C<update_or_create> with a table having
2772 columns with default values that you intend to be automatically
2773 supplied by the database (e.g. an auto_increment primary key column).
2774 In normal usage, the value of such columns should NOT be included at
2775 all in the call to C<update_or_create>, even when set to C<undef>.
2776
2777 See also L</find> and L</find_or_create>. For information on how to declare
2778 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2779
2780 If you need to know if an existing row was updated or a new one created use
2781 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2782 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2783 database!
2784
2785   my $cd = $schema->resultset('CD')->update_or_new(
2786     {
2787       artist => 'Massive Attack',
2788       title  => 'Mezzanine',
2789       year   => 1998,
2790     },
2791     { key => 'cd_artist_title' }
2792   );
2793
2794   if( $cd->in_storage ) {
2795       # do some stuff
2796       $cd->insert;
2797   }
2798
2799 =cut
2800
2801 sub update_or_create {
2802   my $self = shift;
2803   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2804   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2805
2806   my $row = $self->find($cond, $attrs);
2807   if (defined $row) {
2808     $row->update($cond);
2809     return $row;
2810   }
2811
2812   return $self->create($cond);
2813 }
2814
2815 =head2 update_or_new
2816
2817 =over 4
2818
2819 =item Arguments: \%col_values, { key => $unique_constraint }?
2820
2821 =item Return Value: $rowobject
2822
2823 =back
2824
2825   $resultset->update_or_new({ col => $val, ... });
2826
2827 Like L</find_or_new> but if a row is found it is immediately updated via
2828 C<< $found_row->update (\%col_values) >>.
2829
2830 For example:
2831
2832   # In your application
2833   my $cd = $schema->resultset('CD')->update_or_new(
2834     {
2835       artist => 'Massive Attack',
2836       title  => 'Mezzanine',
2837       year   => 1998,
2838     },
2839     { key => 'cd_artist_title' }
2840   );
2841
2842   if ($cd->in_storage) {
2843       # the cd was updated
2844   }
2845   else {
2846       # the cd is not yet in the database, let's insert it
2847       $cd->insert;
2848   }
2849
2850 B<Note>: Make sure to read the documentation of L</find> and understand the
2851 significance of the C<key> attribute, as its lack may skew your search, and
2852 subsequently result in spurious new objects.
2853
2854 B<Note>: Take care when using C<update_or_new> with a table having
2855 columns with default values that you intend to be automatically
2856 supplied by the database (e.g. an auto_increment primary key column).
2857 In normal usage, the value of such columns should NOT be included at
2858 all in the call to C<update_or_new>, even when set to C<undef>.
2859
2860 See also L</find>, L</find_or_create> and L</find_or_new>.
2861
2862 =cut
2863
2864 sub update_or_new {
2865     my $self  = shift;
2866     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2867     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2868
2869     my $row = $self->find( $cond, $attrs );
2870     if ( defined $row ) {
2871         $row->update($cond);
2872         return $row;
2873     }
2874
2875     return $self->new_result($cond);
2876 }
2877
2878 =head2 get_cache
2879
2880 =over 4
2881
2882 =item Arguments: none
2883
2884 =item Return Value: \@cache_objects | undef
2885
2886 =back
2887
2888 Gets the contents of the cache for the resultset, if the cache is set.
2889
2890 The cache is populated either by using the L</prefetch> attribute to
2891 L</search> or by calling L</set_cache>.
2892
2893 =cut
2894
2895 sub get_cache {
2896   shift->{all_cache};
2897 }
2898
2899 =head2 set_cache
2900
2901 =over 4
2902
2903 =item Arguments: \@cache_objects
2904
2905 =item Return Value: \@cache_objects
2906
2907 =back
2908
2909 Sets the contents of the cache for the resultset. Expects an arrayref
2910 of objects of the same class as those produced by the resultset. Note that
2911 if the cache is set the resultset will return the cached objects rather
2912 than re-querying the database even if the cache attr is not set.
2913
2914 The contents of the cache can also be populated by using the
2915 L</prefetch> attribute to L</search>.
2916
2917 =cut
2918
2919 sub set_cache {
2920   my ( $self, $data ) = @_;
2921   $self->throw_exception("set_cache requires an arrayref")
2922       if defined($data) && (ref $data ne 'ARRAY');
2923   $self->{all_cache} = $data;
2924 }
2925
2926 =head2 clear_cache
2927
2928 =over 4
2929
2930 =item Arguments: none
2931
2932 =item Return Value: undef
2933
2934 =back
2935
2936 Clears the cache for the resultset.
2937
2938 =cut
2939
2940 sub clear_cache {
2941   shift->set_cache(undef);
2942 }
2943
2944 =head2 is_paged
2945
2946 =over 4
2947
2948 =item Arguments: none
2949
2950 =item Return Value: true, if the resultset has been paginated
2951
2952 =back
2953
2954 =cut
2955
2956 sub is_paged {
2957   my ($self) = @_;
2958   return !!$self->{attrs}{page};
2959 }
2960
2961 =head2 is_ordered
2962
2963 =over 4
2964
2965 =item Arguments: none
2966
2967 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2968
2969 =back
2970
2971 =cut
2972
2973 sub is_ordered {
2974   my ($self) = @_;
2975   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2976 }
2977
2978 =head2 related_resultset
2979
2980 =over 4
2981
2982 =item Arguments: $relationship_name
2983
2984 =item Return Value: $resultset
2985
2986 =back
2987
2988 Returns a related resultset for the supplied relationship name.
2989
2990   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2991
2992 =cut
2993
2994 sub related_resultset {
2995   my ($self, $rel) = @_;
2996
2997   $self->{related_resultsets} ||= {};
2998   return $self->{related_resultsets}{$rel} ||= do {
2999     my $rsrc = $self->result_source;
3000     my $rel_info = $rsrc->relationship_info($rel);
3001
3002     $self->throw_exception(
3003       "search_related: result source '" . $rsrc->source_name .
3004         "' has no such relationship $rel")
3005       unless $rel_info;
3006
3007     my $attrs = $self->_chain_relationship($rel);
3008
3009     my $join_count = $attrs->{seen_join}{$rel};
3010
3011     my $alias = $self->result_source->storage
3012         ->relname_to_table_alias($rel, $join_count);
3013
3014     # since this is search_related, and we already slid the select window inwards
3015     # (the select/as attrs were deleted in the beginning), we need to flip all
3016     # left joins to inner, so we get the expected results
3017     # read the comment on top of the actual function to see what this does
3018     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3019
3020
3021     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3022     delete @{$attrs}{qw(result_class alias)};
3023
3024     my $new_cache;
3025
3026     if (my $cache = $self->get_cache) {
3027       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3028         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache||[]} }
3029                         @$cache ];
3030       }
3031     }
3032
3033     my $rel_source = $rsrc->related_source($rel);
3034
3035     my $new = do {
3036
3037       # The reason we do this now instead of passing the alias to the
3038       # search_rs below is that if you wrap/overload resultset on the
3039       # source you need to know what alias it's -going- to have for things
3040       # to work sanely (e.g. RestrictWithObject wants to be able to add
3041       # extra query restrictions, and these may need to be $alias.)
3042
3043       my $rel_attrs = $rel_source->resultset_attributes;
3044       local $rel_attrs->{alias} = $alias;
3045
3046       $rel_source->resultset
3047                  ->search_rs(
3048                      undef, {
3049                        %$attrs,
3050                        where => $attrs->{where},
3051                    });
3052     };
3053     $new->set_cache($new_cache) if $new_cache;
3054     $new;
3055   };
3056 }
3057
3058 =head2 current_source_alias
3059
3060 =over 4
3061
3062 =item Arguments: none
3063
3064 =item Return Value: $source_alias
3065
3066 =back
3067
3068 Returns the current table alias for the result source this resultset is built
3069 on, that will be used in the SQL query. Usually it is C<me>.
3070
3071 Currently the source alias that refers to the result set returned by a
3072 L</search>/L</find> family method depends on how you got to the resultset: it's
3073 C<me> by default, but eg. L</search_related> aliases it to the related result
3074 source name (and keeps C<me> referring to the original result set). The long
3075 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3076 (and make this method unnecessary).
3077
3078 Thus it's currently necessary to use this method in predefined queries (see
3079 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3080 source alias of the current result set:
3081
3082   # in a result set class
3083   sub modified_by {
3084     my ($self, $user) = @_;
3085
3086     my $me = $self->current_source_alias;
3087
3088     return $self->search({
3089       "$me.modified" => $user->id,
3090     });
3091   }
3092
3093 =cut
3094
3095 sub current_source_alias {
3096   my ($self) = @_;
3097
3098   return ($self->{attrs} || {})->{alias} || 'me';
3099 }
3100
3101 =head2 as_subselect_rs
3102
3103 =over 4
3104
3105 =item Arguments: none
3106
3107 =item Return Value: $resultset
3108
3109 =back
3110
3111 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3112 "virtual view" by including it as a subquery within the from clause.  From this
3113 point on, any joined tables are inaccessible to ->search on the resultset (as if
3114 it were simply where-filtered without joins).  For example:
3115
3116  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3117
3118  # 'x' now pollutes the query namespace
3119
3120  # So the following works as expected
3121  my $ok_rs = $rs->search({'x.other' => 1});
3122
3123  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3124  # def) we look for one row with contradictory terms and join in another table
3125  # (aliased 'x_2') which we never use
3126  my $broken_rs = $rs->search({'x.name' => 'def'});
3127
3128  my $rs2 = $rs->as_subselect_rs;
3129
3130  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3131  my $not_joined_rs = $rs2->search({'x.other' => 1});
3132
3133  # works as expected: finds a 'table' row related to two x rows (abc and def)
3134  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3135
3136 Another example of when one might use this would be to select a subset of
3137 columns in a group by clause:
3138
3139  my $rs = $schema->resultset('Bar')->search(undef, {
3140    group_by => [qw{ id foo_id baz_id }],
3141  })->as_subselect_rs->search(undef, {
3142    columns => [qw{ id foo_id }]
3143  });
3144
3145 In the above example normally columns would have to be equal to the group by,
3146 but because we isolated the group by into a subselect the above works.
3147
3148 =cut
3149
3150 sub as_subselect_rs {
3151   my $self = shift;
3152
3153   my $attrs = $self->_resolved_attrs;
3154
3155   my $fresh_rs = (ref $self)->new (
3156     $self->result_source
3157   );
3158
3159   # these pieces will be locked in the subquery
3160   delete $fresh_rs->{cond};
3161   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3162
3163   return $fresh_rs->search( {}, {
3164     from => [{
3165       $attrs->{alias} => $self->as_query,
3166       -alias  => $attrs->{alias},
3167       -rsrc   => $self->result_source,
3168     }],
3169     alias => $attrs->{alias},
3170   });
3171 }
3172
3173 # This code is called by search_related, and makes sure there
3174 # is clear separation between the joins before, during, and
3175 # after the relationship. This information is needed later
3176 # in order to properly resolve prefetch aliases (any alias
3177 # with a relation_chain_depth less than the depth of the
3178 # current prefetch is not considered)
3179 #
3180 # The increments happen twice per join. An even number means a
3181 # relationship specified via a search_related, whereas an odd
3182 # number indicates a join/prefetch added via attributes
3183 #
3184 # Also this code will wrap the current resultset (the one we
3185 # chain to) in a subselect IFF it contains limiting attributes
3186 sub _chain_relationship {
3187   my ($self, $rel) = @_;
3188   my $source = $self->result_source;
3189   my $attrs = { %{$self->{attrs}||{}} };
3190
3191   # we need to take the prefetch the attrs into account before we
3192   # ->_resolve_join as otherwise they get lost - captainL
3193   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3194
3195   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3196
3197   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3198
3199   my $from;
3200   my @force_subq_attrs = qw/offset rows group_by having/;
3201
3202   if (
3203     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3204       ||
3205     $self->_has_resolved_attr (@force_subq_attrs)
3206   ) {
3207     # Nuke the prefetch (if any) before the new $rs attrs
3208     # are resolved (prefetch is useless - we are wrapping
3209     # a subquery anyway).
3210     my $rs_copy = $self->search;
3211     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3212       $rs_copy->{attrs}{join},
3213       delete $rs_copy->{attrs}{prefetch},
3214     );
3215
3216     $from = [{
3217       -rsrc   => $source,
3218       -alias  => $attrs->{alias},
3219       $attrs->{alias} => $rs_copy->as_query,
3220     }];
3221     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3222     $seen->{-relation_chain_depth} = 0;
3223   }
3224   elsif ($attrs->{from}) {  #shallow copy suffices
3225     $from = [ @{$attrs->{from}} ];
3226   }
3227   else {
3228     $from = [{
3229       -rsrc  => $source,
3230       -alias => $attrs->{alias},
3231       $attrs->{alias} => $source->from,
3232     }];
3233   }
3234
3235   my $jpath = ($seen->{-relation_chain_depth})
3236     ? $from->[-1][0]{-join_path}
3237     : [];
3238
3239   my @requested_joins = $source->_resolve_join(
3240     $join,
3241     $attrs->{alias},
3242     $seen,
3243     $jpath,
3244   );
3245
3246   push @$from, @requested_joins;
3247
3248   $seen->{-relation_chain_depth}++;
3249
3250   # if $self already had a join/prefetch specified on it, the requested
3251   # $rel might very well be already included. What we do in this case
3252   # is effectively a no-op (except that we bump up the chain_depth on
3253   # the join in question so we could tell it *is* the search_related)
3254   my $already_joined;
3255
3256   # we consider the last one thus reverse
3257   for my $j (reverse @requested_joins) {
3258     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3259     if ($rel eq $last_j) {
3260       $j->[0]{-relation_chain_depth}++;
3261       $already_joined++;
3262       last;
3263     }
3264   }
3265
3266   unless ($already_joined) {
3267     push @$from, $source->_resolve_join(
3268       $rel,
3269       $attrs->{alias},
3270       $seen,
3271       $jpath,
3272     );
3273   }
3274
3275   $seen->{-relation_chain_depth}++;
3276
3277   return {%$attrs, from => $from, seen_join => $seen};
3278 }
3279
3280 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3281 sub _resolved_attrs_copy {
3282   my $self = shift;
3283   return { %{$self->_resolved_attrs (@_)} };
3284 }
3285
3286 sub _resolved_attrs {
3287   my $self = shift;
3288   return $self->{_attrs} if $self->{_attrs};
3289
3290   my $attrs  = { %{ $self->{attrs} || {} } };
3291   my $source = $self->result_source;
3292   my $alias  = $attrs->{alias};
3293
3294   # default selection list
3295   $attrs->{columns} = [ $source->columns ]
3296     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3297
3298   # merge selectors together
3299   for (qw/columns select as/) {
3300     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3301       if $attrs->{$_} or $attrs->{"+$_"};
3302   }
3303
3304   # disassemble columns
3305   my (@sel, @as);
3306   if (my $cols = delete $attrs->{columns}) {
3307     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3308       if (ref $c eq 'HASH') {
3309         for my $as (keys %$c) {
3310           push @sel, $c->{$as};
3311           push @as, $as;
3312         }
3313       }
3314       else {
3315         push @sel, $c;
3316         push @as, $c;
3317       }
3318     }
3319   }
3320
3321   # when trying to weed off duplicates later do not go past this point -
3322   # everything added from here on is unbalanced "anyone's guess" stuff
3323   my $dedup_stop_idx = $#as;
3324
3325   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3326     if $attrs->{as};
3327   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3328     if $attrs->{select};
3329
3330   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3331   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3332
3333   # disqualify all $alias.col as-bits (inflate-map mandated)
3334   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3335
3336   # de-duplicate the result (remove *identical* select/as pairs)
3337   # and also die on duplicate {as} pointing to different {select}s
3338   # not using a c-style for as the condition is prone to shrinkage
3339   my $seen;
3340   my $i = 0;
3341   while ($i <= $dedup_stop_idx) {
3342     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3343       splice @sel, $i, 1;
3344       splice @as, $i, 1;
3345       $dedup_stop_idx--;
3346     }
3347     elsif ($seen->{$as[$i]}++) {
3348       $self->throw_exception(
3349         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3350       );
3351     }
3352     else {
3353       $i++;
3354     }
3355   }
3356
3357   $attrs->{select} = \@sel;
3358   $attrs->{as} = \@as;
3359
3360   $attrs->{from} ||= [{
3361     -rsrc   => $source,
3362     -alias  => $self->{attrs}{alias},
3363     $self->{attrs}{alias} => $source->from,
3364   }];
3365
3366   if ( $attrs->{join} || $attrs->{prefetch} ) {
3367
3368     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3369       if ref $attrs->{from} ne 'ARRAY';
3370
3371     my $join = (delete $attrs->{join}) || {};
3372
3373     if ( defined $attrs->{prefetch} ) {
3374       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3375     }
3376
3377     $attrs->{from} =    # have to copy here to avoid corrupting the original
3378       [
3379         @{ $attrs->{from} },
3380         $source->_resolve_join(
3381           $join,
3382           $alias,
3383           { %{ $attrs->{seen_join} || {} } },
3384           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3385             ? $attrs->{from}[-1][0]{-join_path}
3386             : []
3387           ,
3388         )
3389       ];
3390   }
3391
3392   if ( defined $attrs->{order_by} ) {
3393     $attrs->{order_by} = (
3394       ref( $attrs->{order_by} ) eq 'ARRAY'
3395       ? [ @{ $attrs->{order_by} } ]
3396       : [ $attrs->{order_by} || () ]
3397     );
3398   }
3399
3400   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3401     $attrs->{group_by} = [ $attrs->{group_by} ];
3402   }
3403
3404   # generate the distinct induced group_by early, as prefetch will be carried via a
3405   # subquery (since a group_by is present)
3406   if (delete $attrs->{distinct}) {
3407     if ($attrs->{group_by}) {
3408       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3409     }
3410     else {
3411       # distinct affects only the main selection part, not what prefetch may
3412       # add below.
3413       $attrs->{group_by} = $source->storage->_group_over_selection (
3414         $attrs->{from},
3415         $attrs->{select},
3416         $attrs->{order_by},
3417       );
3418     }
3419   }
3420
3421   # generate selections based on the prefetch helper
3422   my $prefetch;
3423   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3424     if defined $attrs->{prefetch};
3425
3426   if ($prefetch) {
3427
3428     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3429       if $attrs->{_dark_selector};
3430
3431     $attrs->{collapse} = 1;
3432
3433     # this is a separate structure (we don't look in {from} directly)
3434     # as the resolver needs to shift things off the lists to work
3435     # properly (identical-prefetches on different branches)
3436     my $join_map = {};
3437     if (ref $attrs->{from} eq 'ARRAY') {
3438
3439       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3440
3441       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3442         next unless $j->[0]{-alias};
3443         next unless $j->[0]{-join_path};
3444         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3445
3446         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3447
3448         my $p = $join_map;
3449         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3450         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3451       }
3452     }
3453
3454     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3455
3456     # we need to somehow mark which columns came from prefetch
3457     if (@prefetch) {
3458       my $sel_end = $#{$attrs->{select}};
3459       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3460     }
3461
3462     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3463     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3464   }
3465
3466   $attrs->{_single_object_inflation} = ! List::Util::first { $_ =~ /\./ } @{$attrs->{as}};
3467
3468   # run through the resulting joinstructure (starting from our current slot)
3469   # and unset collapse if proven unnesessary
3470   if ($attrs->{collapse} && ref $attrs->{from} eq 'ARRAY') {
3471
3472     if (@{$attrs->{from}} > 1) {
3473
3474       # find where our table-spec starts and consider only things after us
3475       my @fromlist = @{$attrs->{from}};
3476       while (@fromlist) {
3477         my $t = shift @fromlist;
3478         $t = $t->[0] if ref $t eq 'ARRAY';  #me vs join from-spec mismatch
3479         last if ($t->{-alias} && $t->{-alias} eq $alias);
3480       }
3481
3482       for (@fromlist) {
3483         $attrs->{collapse} = ! $_->[0]{-is_single}
3484           and last;
3485       }
3486     }
3487     else {
3488       # no joins - no collapse
3489       $attrs->{collapse} = 0;
3490     }
3491   }
3492
3493   if (! $attrs->{order_by} and $attrs->{collapse}) {
3494     # default order for collapsing unless the user asked for something
3495     $attrs->{order_by} = [ map { "$alias.$_" } $source->primary_columns ];
3496     $attrs->{_ordered_for_collapse} = 1;
3497   }
3498
3499   # if both page and offset are specified, produce a combined offset
3500   # even though it doesn't make much sense, this is what pre 081xx has
3501   # been doing
3502   if (my $page = delete $attrs->{page}) {
3503     $attrs->{offset} =
3504       ($attrs->{rows} * ($page - 1))
3505             +
3506       ($attrs->{offset} || 0)
3507     ;
3508   }
3509
3510   return $self->{_attrs} = $attrs;
3511 }
3512
3513 sub _rollout_attr {
3514   my ($self, $attr) = @_;
3515
3516   if (ref $attr eq 'HASH') {
3517     return $self->_rollout_hash($attr);
3518   } elsif (ref $attr eq 'ARRAY') {
3519     return $self->_rollout_array($attr);
3520   } else {
3521     return [$attr];
3522   }
3523 }
3524
3525 sub _rollout_array {
3526   my ($self, $attr) = @_;
3527
3528   my @rolled_array;
3529   foreach my $element (@{$attr}) {
3530     if (ref $element eq 'HASH') {
3531       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3532     } elsif (ref $element eq 'ARRAY') {
3533       #  XXX - should probably recurse here
3534       push( @rolled_array, @{$self->_rollout_array($element)} );
3535     } else {
3536       push( @rolled_array, $element );
3537     }
3538   }
3539   return \@rolled_array;
3540 }
3541
3542 sub _rollout_hash {
3543   my ($self, $attr) = @_;
3544
3545   my @rolled_array;
3546   foreach my $key (keys %{$attr}) {
3547     push( @rolled_array, { $key => $attr->{$key} } );
3548   }
3549   return \@rolled_array;
3550 }
3551
3552 sub _calculate_score {
3553   my ($self, $a, $b) = @_;
3554
3555   if (defined $a xor defined $b) {
3556     return 0;
3557   }
3558   elsif (not defined $a) {
3559     return 1;
3560   }
3561
3562   if (ref $b eq 'HASH') {
3563     my ($b_key) = keys %{$b};
3564     if (ref $a eq 'HASH') {
3565       my ($a_key) = keys %{$a};
3566       if ($a_key eq $b_key) {
3567         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3568       } else {
3569         return 0;
3570       }
3571     } else {
3572       return ($a eq $b_key) ? 1 : 0;
3573     }
3574   } else {
3575     if (ref $a eq 'HASH') {
3576       my ($a_key) = keys %{$a};
3577       return ($b eq $a_key) ? 1 : 0;
3578     } else {
3579       return ($b eq $a) ? 1 : 0;
3580     }
3581   }
3582 }
3583
3584 sub _merge_joinpref_attr {
3585   my ($self, $orig, $import) = @_;
3586
3587   return $import unless defined($orig);
3588   return $orig unless defined($import);
3589
3590   $orig = $self->_rollout_attr($orig);
3591   $import = $self->_rollout_attr($import);
3592
3593   my $seen_keys;
3594   foreach my $import_element ( @{$import} ) {
3595     # find best candidate from $orig to merge $b_element into
3596     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3597     foreach my $orig_element ( @{$orig} ) {
3598       my $score = $self->_calculate_score( $orig_element, $import_element );
3599       if ($score > $best_candidate->{score}) {
3600         $best_candidate->{position} = $position;
3601         $best_candidate->{score} = $score;
3602       }
3603       $position++;
3604     }
3605     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3606     $import_key = '' if not defined $import_key;
3607
3608     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3609       push( @{$orig}, $import_element );
3610     } else {
3611       my $orig_best = $orig->[$best_candidate->{position}];
3612       # merge orig_best and b_element together and replace original with merged
3613       if (ref $orig_best ne 'HASH') {
3614         $orig->[$best_candidate->{position}] = $import_element;
3615       } elsif (ref $import_element eq 'HASH') {
3616         my ($key) = keys %{$orig_best};
3617         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3618       }
3619     }
3620     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3621   }
3622
3623   return $orig;
3624 }
3625
3626 {
3627   my $hm;
3628
3629   sub _merge_attr {
3630     $hm ||= do {
3631       require Hash::Merge;
3632       my $hm = Hash::Merge->new;
3633
3634       $hm->specify_behavior({
3635         SCALAR => {
3636           SCALAR => sub {
3637             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3638
3639             if ($defl xor $defr) {
3640               return [ $defl ? $_[0] : $_[1] ];
3641             }
3642             elsif (! $defl) {
3643               return [];
3644             }
3645             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3646               return [ $_[0] ];
3647             }
3648             else {
3649               return [$_[0], $_[1]];
3650             }
3651           },
3652           ARRAY => sub {
3653             return $_[1] if !defined $_[0];
3654             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3655             return [$_[0], @{$_[1]}]
3656           },
3657           HASH  => sub {
3658             return [] if !defined $_[0] and !keys %{$_[1]};
3659             return [ $_[1] ] if !defined $_[0];
3660             return [ $_[0] ] if !keys %{$_[1]};
3661             return [$_[0], $_[1]]
3662           },
3663         },
3664         ARRAY => {
3665           SCALAR => sub {
3666             return $_[0] if !defined $_[1];
3667             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3668             return [@{$_[0]}, $_[1]]
3669           },
3670           ARRAY => sub {
3671             my @ret = @{$_[0]} or return $_[1];
3672             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3673             my %idx = map { $_ => 1 } @ret;
3674             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3675             \@ret;
3676           },
3677           HASH => sub {
3678             return [ $_[1] ] if ! @{$_[0]};
3679             return $_[0] if !keys %{$_[1]};
3680             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3681             return [ @{$_[0]}, $_[1] ];
3682           },
3683         },
3684         HASH => {
3685           SCALAR => sub {
3686             return [] if !keys %{$_[0]} and !defined $_[1];
3687             return [ $_[0] ] if !defined $_[1];
3688             return [ $_[1] ] if !keys %{$_[0]};
3689             return [$_[0], $_[1]]
3690           },
3691           ARRAY => sub {
3692             return [] if !keys %{$_[0]} and !@{$_[1]};
3693             return [ $_[0] ] if !@{$_[1]};
3694             return $_[1] if !keys %{$_[0]};
3695             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3696             return [ $_[0], @{$_[1]} ];
3697           },
3698           HASH => sub {
3699             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3700             return [ $_[0] ] if !keys %{$_[1]};
3701             return [ $_[1] ] if !keys %{$_[0]};
3702             return [ $_[0] ] if $_[0] eq $_[1];
3703             return [ $_[0], $_[1] ];
3704           },
3705         }
3706       } => 'DBIC_RS_ATTR_MERGER');
3707       $hm;
3708     };
3709
3710     return $hm->merge ($_[1], $_[2]);
3711   }
3712 }
3713
3714 sub STORABLE_freeze {
3715   my ($self, $cloning) = @_;
3716   my $to_serialize = { %$self };
3717
3718   # A cursor in progress can't be serialized (and would make little sense anyway)
3719   delete $to_serialize->{cursor};
3720
3721   # the parser can be regenerated
3722   delete $to_serialize->{_row_parser};
3723
3724   # nor is it sensical to store a not-yet-fired-count pager
3725   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3726     delete $to_serialize->{pager};
3727   }
3728
3729   Storable::nfreeze($to_serialize);
3730 }
3731
3732 # need this hook for symmetry
3733 sub STORABLE_thaw {
3734   my ($self, $cloning, $serialized) = @_;
3735
3736   %$self = %{ Storable::thaw($serialized) };
3737
3738   $self;
3739 }
3740
3741
3742 =head2 throw_exception
3743
3744 See L<DBIx::Class::Schema/throw_exception> for details.
3745
3746 =cut
3747
3748 sub throw_exception {
3749   my $self=shift;
3750
3751   if (ref $self and my $rsrc = $self->result_source) {
3752     $rsrc->throw_exception(@_)
3753   }
3754   else {
3755     DBIx::Class::Exception->throw(@_);
3756   }
3757 }
3758
3759 # XXX: FIXME: Attributes docs need clearing up
3760
3761 =head1 ATTRIBUTES
3762
3763 Attributes are used to refine a ResultSet in various ways when
3764 searching for data. They can be passed to any method which takes an
3765 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3766 L</count>.
3767
3768 These are in no particular order:
3769
3770 =head2 order_by
3771
3772 =over 4
3773
3774 =item Value: ( $order_by | \@order_by | \%order_by )
3775
3776 =back
3777
3778 Which column(s) to order the results by.
3779
3780 [The full list of suitable values is documented in
3781 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3782 common options.]
3783
3784 If a single column name, or an arrayref of names is supplied, the
3785 argument is passed through directly to SQL. The hashref syntax allows
3786 for connection-agnostic specification of ordering direction:
3787
3788  For descending order:
3789
3790   order_by => { -desc => [qw/col1 col2 col3/] }
3791
3792  For explicit ascending order:
3793
3794   order_by => { -asc => 'col' }
3795
3796 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3797 supported, although you are strongly encouraged to use the hashref
3798 syntax as outlined above.
3799
3800 =head2 columns
3801
3802 =over 4
3803
3804 =item Value: \@columns
3805
3806 =back
3807
3808 Shortcut to request a particular set of columns to be retrieved. Each
3809 column spec may be a string (a table column name), or a hash (in which
3810 case the key is the C<as> value, and the value is used as the C<select>
3811 expression). Adds C<me.> onto the start of any column without a C<.> in
3812 it and sets C<select> from that, then auto-populates C<as> from
3813 C<select> as normal. (You may also use the C<cols> attribute, as in
3814 earlier versions of DBIC.)
3815
3816 Essentially C<columns> does the same as L</select> and L</as>.
3817
3818     columns => [ 'foo', { bar => 'baz' } ]
3819
3820 is the same as
3821
3822     select => [qw/foo baz/],
3823     as => [qw/foo bar/]
3824
3825 =head2 +columns
3826
3827 =over 4
3828
3829 =item Value: \@columns
3830
3831 =back
3832
3833 Indicates additional columns to be selected from storage. Works the same
3834 as L</columns> but adds columns to the selection. (You may also use the
3835 C<include_columns> attribute, as in earlier versions of DBIC). For
3836 example:-
3837
3838   $schema->resultset('CD')->search(undef, {
3839     '+columns' => ['artist.name'],
3840     join => ['artist']
3841   });
3842
3843 would return all CDs and include a 'name' column to the information
3844 passed to object inflation. Note that the 'artist' is the name of the
3845 column (or relationship) accessor, and 'name' is the name of the column
3846 accessor in the related table.
3847
3848 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3849 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3850 unary plus operator before it.
3851
3852 =head2 include_columns
3853
3854 =over 4
3855
3856 =item Value: \@columns
3857
3858 =back
3859
3860 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3861
3862 =head2 select
3863
3864 =over 4
3865
3866 =item Value: \@select_columns
3867
3868 =back
3869
3870 Indicates which columns should be selected from the storage. You can use
3871 column names, or in the case of RDBMS back ends, function or stored procedure
3872 names:
3873
3874   $rs = $schema->resultset('Employee')->search(undef, {
3875     select => [
3876       'name',
3877       { count => 'employeeid' },
3878       { max => { length => 'name' }, -as => 'longest_name' }
3879     ]
3880   });
3881
3882   # Equivalent SQL
3883   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3884
3885 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3886 use L</select>, to instruct DBIx::Class how to store the result of the column.
3887 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3888 identifier aliasing. You can however alias a function, so you can use it in
3889 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3890 attribute> supplied as shown in the example above.
3891
3892 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3893 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3894 unary plus operator before it.
3895
3896 =head2 +select
3897
3898 =over 4
3899
3900 Indicates additional columns to be selected from storage.  Works the same as
3901 L</select> but adds columns to the default selection, instead of specifying
3902 an explicit list.
3903
3904 =back
3905
3906 =head2 +as
3907
3908 =over 4
3909
3910 Indicates additional column names for those added via L</+select>. See L</as>.
3911
3912 =back
3913
3914 =head2 as
3915
3916 =over 4
3917
3918 =item Value: \@inflation_names
3919
3920 =back
3921
3922 Indicates column names for object inflation. That is L</as> indicates the
3923 slot name in which the column value will be stored within the
3924 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3925 identifier by the C<get_column> method (or via the object accessor B<if one
3926 with the same name already exists>) as shown below. The L</as> attribute has
3927 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3928
3929   $rs = $schema->resultset('Employee')->search(undef, {
3930     select => [
3931       'name',
3932       { count => 'employeeid' },
3933       { max => { length => 'name' }, -as => 'longest_name' }
3934     ],
3935     as => [qw/
3936       name
3937       employee_count
3938       max_name_length
3939     /],
3940   });
3941
3942 If the object against which the search is performed already has an accessor
3943 matching a column name specified in C<as>, the value can be retrieved using
3944 the accessor as normal:
3945
3946   my $name = $employee->name();
3947
3948 If on the other hand an accessor does not exist in the object, you need to
3949 use C<get_column> instead:
3950
3951   my $employee_count = $employee->get_column('employee_count');
3952
3953 You can create your own accessors if required - see
3954 L<DBIx::Class::Manual::Cookbook> for details.
3955
3956 =head2 join
3957
3958 =over 4
3959
3960 =item Value: ($rel_name | \@rel_names | \%rel_names)
3961
3962 =back
3963
3964 Contains a list of relationships that should be joined for this query.  For
3965 example:
3966
3967   # Get CDs by Nine Inch Nails
3968   my $rs = $schema->resultset('CD')->search(
3969     { 'artist.name' => 'Nine Inch Nails' },
3970     { join => 'artist' }
3971   );
3972
3973 Can also contain a hash reference to refer to the other relation's relations.
3974 For example:
3975
3976   package MyApp::Schema::Track;
3977   use base qw/DBIx::Class/;
3978   __PACKAGE__->table('track');
3979   __PACKAGE__->add_columns(qw/trackid cd position title/);
3980   __PACKAGE__->set_primary_key('trackid');
3981   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3982   1;
3983
3984   # In your application
3985   my $rs = $schema->resultset('Artist')->search(
3986     { 'track.title' => 'Teardrop' },
3987     {
3988       join     => { cd => 'track' },
3989       order_by => 'artist.name',
3990     }
3991   );
3992
3993 You need to use the relationship (not the table) name in  conditions,
3994 because they are aliased as such. The current table is aliased as "me", so
3995 you need to use me.column_name in order to avoid ambiguity. For example:
3996
3997   # Get CDs from 1984 with a 'Foo' track
3998   my $rs = $schema->resultset('CD')->search(
3999     {
4000       'me.year' => 1984,
4001       'tracks.name' => 'Foo'
4002     },
4003     { join => 'tracks' }
4004   );
4005
4006 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4007 similarly for a third time). For e.g.
4008
4009   my $rs = $schema->resultset('Artist')->search({
4010     'cds.title'   => 'Down to Earth',
4011     'cds_2.title' => 'Popular',
4012   }, {
4013     join => [ qw/cds cds/ ],
4014   });
4015
4016 will return a set of all artists that have both a cd with title 'Down
4017 to Earth' and a cd with title 'Popular'.
4018
4019 If you want to fetch related objects from other tables as well, see C<prefetch>
4020 below.
4021
4022 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4023
4024 =head2 prefetch
4025
4026 =over 4
4027
4028 =item Value: ($rel_name | \@rel_names | \%rel_names)
4029
4030 =back
4031
4032 Contains one or more relationships that should be fetched along with
4033 the main query (when they are accessed afterwards the data will
4034 already be available, without extra queries to the database).  This is
4035 useful for when you know you will need the related objects, because it
4036 saves at least one query:
4037
4038   my $rs = $schema->resultset('Tag')->search(
4039     undef,
4040     {
4041       prefetch => {
4042         cd => 'artist'
4043       }
4044     }
4045   );
4046
4047 The initial search results in SQL like the following:
4048
4049   SELECT tag.*, cd.*, artist.* FROM tag
4050   JOIN cd ON tag.cd = cd.cdid
4051   JOIN artist ON cd.artist = artist.artistid
4052
4053 L<DBIx::Class> has no need to go back to the database when we access the
4054 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4055 case.
4056
4057 Simple prefetches will be joined automatically, so there is no need
4058 for a C<join> attribute in the above search.
4059
4060 L</prefetch> can be used with the any of the relationship types and
4061 multiple prefetches can be specified together. Below is a more complex
4062 example that prefetches a CD's artist, its liner notes (if present),
4063 the cover image, the tracks on that cd, and the guests on those
4064 tracks.
4065
4066  # Assuming:
4067  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4068  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4069  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4070  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4071
4072  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4073
4074  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4075
4076
4077  my $rs = $schema->resultset('CD')->search(
4078    undef,
4079    {
4080      prefetch => [
4081        { artist => 'record_label'},  # belongs_to => belongs_to
4082        'liner_note',                 # might_have
4083        'cover_image',                # has_one
4084        { tracks => 'guests' },       # has_many => has_many
4085      ]
4086    }
4087  );
4088
4089 This will produce SQL like the following:
4090
4091  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4092         tracks.*, guests.*
4093    FROM cd me
4094    JOIN artist artist
4095      ON artist.artistid = me.artistid
4096    JOIN record_label record_label
4097      ON record_label.labelid = artist.labelid
4098    LEFT JOIN track tracks
4099      ON tracks.cdid = me.cdid
4100    LEFT JOIN guest guests
4101      ON guests.trackid = track.trackid
4102    LEFT JOIN liner_notes liner_note
4103      ON liner_note.cdid = me.cdid
4104    JOIN cd_artwork cover_image
4105      ON cover_image.cdid = me.cdid
4106  ORDER BY tracks.cd
4107
4108 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4109 C<tracks>, and C<guests> of the CD will all be available through the
4110 relationship accessors without the need for additional queries to the
4111 database.
4112
4113 However, there is one caveat to be observed: it can be dangerous to
4114 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4115 relationship on a given level. e.g.:
4116
4117  my $rs = $schema->resultset('CD')->search(
4118    undef,
4119    {
4120      prefetch => [
4121        'tracks',                         # has_many
4122        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4123      ]
4124    }
4125  );
4126
4127 In fact, C<DBIx::Class> will emit the following warning:
4128
4129  Prefetching multiple has_many rels tracks and cd_to_producer at top
4130  level will explode the number of row objects retrievable via ->next
4131  or ->all. Use at your own risk.
4132
4133 The collapser currently can't identify duplicate tuples for multiple
4134 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4135 result the second L<has_many|DBIx::Class::Relationship/has_many>
4136 relation could contain redundant objects.
4137
4138 =head3 Using L</prefetch> with L</join>
4139
4140 L</prefetch> implies a L</join> with the equivalent argument, and is
4141 properly merged with any existing L</join> specification. So the
4142 following:
4143
4144   my $rs = $schema->resultset('CD')->search(
4145    {'record_label.name' => 'Music Product Ltd.'},
4146    {
4147      join     => {artist => 'record_label'},
4148      prefetch => 'artist',
4149    }
4150  );
4151
4152 ... will work, searching on the record label's name, but only
4153 prefetching the C<artist>.
4154
4155 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4156
4157 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4158 prefetched relations.  So given:
4159
4160   my $rs = $schema->resultset('CD')->search(
4161    undef,
4162    {
4163      select   => ['cd.title'],
4164      as       => ['cd_title'],
4165      prefetch => 'artist',
4166    }
4167  );
4168
4169 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4170 becomes: C<'cd_title', 'artist.*'>.
4171
4172 =head3 CAVEATS
4173
4174 Prefetch does a lot of deep magic. As such, it may not behave exactly
4175 as you might expect.
4176
4177 =over 4
4178
4179 =item *
4180
4181 Prefetch uses the L</cache> to populate the prefetched relationships. This
4182 may or may not be what you want.
4183
4184 =item *
4185
4186 If you specify a condition on a prefetched relationship, ONLY those
4187 rows that match the prefetched condition will be fetched into that relationship.
4188 This means that adding prefetch to a search() B<may alter> what is returned by
4189 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4190
4191   my $artist_rs = $schema->resultset('Artist')->search({
4192       'cds.year' => 2008,
4193   }, {
4194       join => 'cds',
4195   });
4196
4197   my $count = $artist_rs->first->cds->count;
4198
4199   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4200
4201   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4202
4203   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4204
4205 that cmp_ok() may or may not pass depending on the datasets involved. This
4206 behavior may or may not survive the 0.09 transition.
4207
4208 =back
4209
4210 =head2 page
4211
4212 =over 4
4213
4214 =item Value: $page
4215
4216 =back
4217
4218 Makes the resultset paged and specifies the page to retrieve. Effectively
4219 identical to creating a non-pages resultset and then calling ->page($page)
4220 on it.
4221
4222 If L</rows> attribute is not specified it defaults to 10 rows per page.
4223
4224 When you have a paged resultset, L</count> will only return the number
4225 of rows in the page. To get the total, use the L</pager> and call
4226 C<total_entries> on it.
4227
4228 =head2 rows
4229
4230 =over 4
4231
4232 =item Value: $rows
4233
4234 =back
4235
4236 Specifies the maximum number of rows for direct retrieval or the number of
4237 rows per page if the page attribute or method is used.
4238
4239 =head2 offset
4240
4241 =over 4
4242
4243 =item Value: $offset
4244
4245 =back
4246
4247 Specifies the (zero-based) row number for the  first row to be returned, or the
4248 of the first row of the first page if paging is used.
4249
4250 =head2 software_limit
4251
4252 =over 4
4253
4254 =item Value: (0 | 1)
4255
4256 =back
4257
4258 When combined with L</rows> and/or L</offset> the generated SQL will not
4259 include any limit dialect stanzas. Instead the entire result will be selected
4260 as if no limits were specified, and DBIC will perform the limit locally, by
4261 artificially advancing and finishing the resulting L</cursor>.
4262
4263 This is the recommended way of performing resultset limiting when no sane RDBMS
4264 implementation is available (e.g.
4265 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4266 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4267
4268 =head2 group_by
4269
4270 =over 4
4271
4272 =item Value: \@columns
4273
4274 =back
4275
4276 A arrayref of columns to group by. Can include columns of joined tables.
4277
4278   group_by => [qw/ column1 column2 ... /]
4279
4280 =head2 having
4281
4282 =over 4
4283
4284 =item Value: $condition
4285
4286 =back
4287
4288 HAVING is a select statement attribute that is applied between GROUP BY and
4289 ORDER BY. It is applied to the after the grouping calculations have been
4290 done.
4291
4292   having => { 'count_employee' => { '>=', 100 } }
4293
4294 or with an in-place function in which case literal SQL is required:
4295
4296   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4297
4298 =head2 distinct
4299
4300 =over 4
4301
4302 =item Value: (0 | 1)
4303
4304 =back
4305
4306 Set to 1 to group by all columns. If the resultset already has a group_by
4307 attribute, this setting is ignored and an appropriate warning is issued.
4308
4309 =head2 where
4310
4311 =over 4
4312
4313 Adds to the WHERE clause.
4314
4315   # only return rows WHERE deleted IS NULL for all searches
4316   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4317
4318 Can be overridden by passing C<< { where => undef } >> as an attribute
4319 to a resultset.
4320
4321 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4322
4323 =back
4324
4325 =head2 cache
4326
4327 Set to 1 to cache search results. This prevents extra SQL queries if you
4328 revisit rows in your ResultSet:
4329
4330   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4331
4332   while( my $artist = $resultset->next ) {
4333     ... do stuff ...
4334   }
4335
4336   $rs->first; # without cache, this would issue a query
4337
4338 By default, searches are not cached.
4339
4340 For more examples of using these attributes, see
4341 L<DBIx::Class::Manual::Cookbook>.
4342
4343 =head2 for
4344
4345 =over 4
4346
4347 =item Value: ( 'update' | 'shared' )
4348
4349 =back
4350
4351 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4352 ... FOR SHARED.
4353
4354 =cut
4355
4356 1;