lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use DBIx::Class::ResultClass::HashRefInflator;
   9 use Scalar::Util qw( blessed reftype );
  10 use DBIx::Class::_Util qw(
  11   dbic_internal_try dump_value
  12   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  13 );
  14 use Try::Tiny;
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 # this is real - CDBICompat overrides it with insanity
  30 # yes, prototype won't matter, but that's for now ;)
  31 sub _bool () { 1 }
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  34
  35 =head1 NAME
  36
  37 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  38
  39 =head1 SYNOPSIS
  40
  41   my $users_rs = $schema->resultset('User');
  42   while( $user = $users_rs->next) {
  43     print $user->username;
  44   }
  45
  46   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  47   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  48
  49 =head1 DESCRIPTION
  50
  51 A ResultSet is an object which stores a set of conditions representing
  52 a query. It is the backbone of DBIx::Class (i.e. the really
  53 important/useful bit).
  54
  55 No SQL is executed on the database when a ResultSet is created, it
  56 just stores all the conditions needed to create the query.
  57
  58 A basic ResultSet representing the data of an entire table is returned
  59 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  60 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  61
  62   my $users_rs = $schema->resultset('User');
  63
  64 A new ResultSet is returned from calling L</search> on an existing
  65 ResultSet. The new one will contain all the conditions of the
  66 original, plus any new conditions added in the C<search> call.
  67
  68 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  69 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  70 represents.
  71
  72 The query that the ResultSet represents is B<only> executed against
  73 the database when these methods are called:
  74 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  75
  76 If a resultset is used in a numeric context it returns the L</count>.
  77 However, if it is used in a boolean context it is B<always> true.  So if
  78 you want to check if a resultset has any results, you must use C<if $rs
  79 != 0>.
  80
  81 =head1 EXAMPLES
  82
  83 =head2 Chaining resultsets
  84
  85 Let's say you've got a query that needs to be run to return some data
  86 to the user. But, you have an authorization system in place that
  87 prevents certain users from seeing certain information. So, you want
  88 to construct the basic query in one method, but add constraints to it in
  89 another.
  90
  91   sub get_data {
  92     my $self = shift;
  93     my $request = $self->get_request; # Get a request object somehow.
  94     my $schema = $self->result_source->schema;
  95
  96     my $cd_rs = $schema->resultset('CD')->search({
  97       title => $request->param('title'),
  98       year => $request->param('year'),
  99     });
 100
 101     $cd_rs = $self->apply_security_policy( $cd_rs );
 102
 103     return $cd_rs->all();
 104   }
 105
 106   sub apply_security_policy {
 107     my $self = shift;
 108     my ($rs) = @_;
 109
 110     return $rs->search({
 111       subversive => 0,
 112     });
 113   }
 114
 115 =head3 Resolving conditions and attributes
 116
 117 When a resultset is chained from another resultset (e.g.:
 118 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 119 and attributes with the same keys need resolving.
 120
 121 If any of L</columns>, L</select>, L</as> are present, they reset the
 122 original selection, and start the selection "clean".
 123
 124 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 125 are merged into the existing ones from the original resultset.
 126
 127 The L</where> and L</having> attributes, and any search conditions, are
 128 merged with an SQL C<AND> to the existing condition from the original
 129 resultset.
 130
 131 All other attributes are overridden by any new ones supplied in the
 132 search attributes.
 133
 134 =head2 Multiple queries
 135
 136 Since a resultset just defines a query, you can do all sorts of
 137 things with it with the same object.
 138
 139   # Don't hit the DB yet.
 140   my $cd_rs = $schema->resultset('CD')->search({
 141     title => 'something',
 142     year => 2009,
 143   });
 144
 145   # Each of these hits the DB individually.
 146   my $count = $cd_rs->count;
 147   my $most_recent = $cd_rs->get_column('date_released')->max();
 148   my @records = $cd_rs->all;
 149
 150 And it's not just limited to SELECT statements.
 151
 152   $cd_rs->delete();
 153
 154 This is even cooler:
 155
 156   $cd_rs->create({ artist => 'Fred' });
 157
 158 Which is the same as:
 159
 160   $schema->resultset('CD')->create({
 161     title => 'something',
 162     year => 2009,
 163     artist => 'Fred'
 164   });
 165
 166 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 167
 168 =head2 Custom ResultSet classes
 169
 170 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 171
 172   package MyApp::Schema::ResultSet::User;
 173
 174   use strict;
 175   use warnings;
 176
 177   use base 'DBIx::Class::ResultSet';
 178
 179   sub active {
 180     my $self = shift;
 181     $self->search({ $self->current_source_alias . '.active' => 1 });
 182   }
 183
 184   sub unverified {
 185     my $self = shift;
 186     $self->search({ $self->current_source_alias . '.verified' => 0 });
 187   }
 188
 189   sub created_n_days_ago {
 190     my ($self, $days_ago) = @_;
 191     $self->search({
 192       $self->current_source_alias . '.create_date' => {
 193         '<=',
 194       $self->result_source->schema->storage->datetime_parser->format_datetime(
 195         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 196       )}
 197     });
 198   }
 199
 200   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 201
 202   1;
 203
 204 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 205 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 206 L<ResulSet|DBIx::Class::ResultSet> classes.
 207
 208 =head3 ResultSet subclassing with Moose and similar constructor-providers
 209
 210 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 211 you may find it useful if your ResultSets contain a lot of business logic
 212 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 213 your code via roles.
 214
 215 In order to write custom ResultSet classes with L<Moo> you need to use the
 216 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 217 unusual signature of the L<constructor provided by DBIC
 218 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 219
 220   use Moo;
 221   extends 'DBIx::Class::ResultSet';
 222   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 223
 224   ...your code...
 225
 226   1;
 227
 228 If you want to build your custom ResultSet classes with L<Moose>, you need
 229 a similar, though a little more elaborate template in order to interface the
 230 inlining of the L<Moose>-provided
 231 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 232 with the DBIC one.
 233
 234   package MyApp::Schema::ResultSet::User;
 235
 236   use Moose;
 237   use MooseX::NonMoose;
 238   extends 'DBIx::Class::ResultSet';
 239
 240   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 241
 242   ...your code...
 243
 244   __PACKAGE__->meta->make_immutable;
 245
 246   1;
 247
 248 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 249 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 250 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 251 instead by doing:
 252
 253   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 254
 255 =head1 METHODS
 256
 257 =head2 new
 258
 259 =over 4
 260
 261 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 262
 263 =item Return Value: L<$resultset|/search>
 264
 265 =back
 266
 267 The resultset constructor. Takes a source object (usually a
 268 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 269 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 270 executed as needed by the other methods.
 271
 272 Generally you never construct a resultset manually. Instead you get one
 273 from e.g. a
 274 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 275 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 276 scalar context):
 277
 278   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 279
 280 =over
 281
 282 =item WARNING
 283
 284 If called on an object, proxies to L</new_result> instead, so
 285
 286   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 287
 288 will return a CD object, not a ResultSet, and is equivalent to:
 289
 290   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 291
 292 Please also keep in mind that many internals call L</new_result> directly,
 293 so overloading this method with the idea of intercepting new result object
 294 creation B<will not work>. See also warning pertaining to L</create>.
 295
 296 =back
 297
 298 =cut
 299
 300 sub new {
 301   my $class = shift;
 302
 303   if (ref $class) {
 304     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 305     return $class->new_result(@_);
 306   }
 307
 308   my ($source, $attrs) = @_;
 309   $source = $source->resolve
 310     if $source->isa('DBIx::Class::ResultSourceHandle');
 311
 312   $attrs = { %{$attrs||{}} };
 313   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 314
 315   if ($attrs->{page}) {
 316     $attrs->{rows} ||= 10;
 317   }
 318
 319   $attrs->{alias} ||= 'me';
 320
 321   my $self = bless {
 322     result_source => $source,
 323     cond => $attrs->{where},
 324     pager => undef,
 325     attrs => $attrs,
 326   }, $class;
 327
 328   # if there is a dark selector, this means we are already in a
 329   # chain and the cleanup/sanification was taken care of by
 330   # _search_rs already
 331   $self->_normalize_selection($attrs)
 332     unless $attrs->{_dark_selector};
 333
 334   $self->result_class(
 335     $attrs->{result_class} || $source->result_class
 336   );
 337
 338   $self;
 339 }
 340
 341 =head2 search
 342
 343 =over 4
 344
 345 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 346
 347 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 348
 349 =back
 350
 351   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 352   my $new_rs = $cd_rs->search({ year => 2005 });
 353
 354   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 355                  # year = 2005 OR year = 2004
 356
 357 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 358 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 359 To avoid that, use L</search_rs>.
 360
 361 If you need to pass in additional attributes but no additional condition,
 362 call it as C<search(undef, \%attrs)>.
 363
 364   # "SELECT name, artistid FROM $artist_table"
 365   my @all_artists = $schema->resultset('Artist')->search(undef, {
 366     columns => [qw/name artistid/],
 367   });
 368
 369 For a list of attributes that can be passed to C<search>, see
 370 L</ATTRIBUTES>. For more examples of using this function, see
 371 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 372 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 373 and its extension L<DBIx::Class::SQLMaker>.
 374
 375 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 376
 377 =head3 CAVEAT
 378
 379 Note that L</search> does not process/deflate any of the values passed in the
 380 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 381 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 382 manually that any value passed to this method will stringify to something the
 383 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 384 objects, for more info see:
 385 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 386
 387 =cut
 388
 389 sub search {
 390   my $self = shift;
 391   my $rs = $self->search_rs( @_ );
 392
 393   if (wantarray) {
 394     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 395     return $rs->all;
 396   }
 397   elsif (defined wantarray) {
 398     return $rs;
 399   }
 400   else {
 401     # we can be called by a relationship helper, which in
 402     # turn may be called in void context due to some braindead
 403     # overload or whatever else the user decided to be clever
 404     # at this particular day. Thus limit the exception to
 405     # external code calls only
 406     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 407       if (caller)[0] !~ /^\QDBIx::Class::/;
 408
 409     return ();
 410   }
 411 }
 412
 413 =head2 search_rs
 414
 415 =over 4
 416
 417 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 418
 419 =item Return Value: L<$resultset|/search>
 420
 421 =back
 422
 423 This method does the same exact thing as search() except it will
 424 always return a resultset, even in list context.
 425
 426 =cut
 427
 428 sub search_rs {
 429   my $self = shift;
 430
 431   my $rsrc = $self->result_source;
 432   my ($call_cond, $call_attrs);
 433
 434   # Special-case handling for (undef, undef) or (undef)
 435   # Note that (foo => undef) is valid deprecated syntax
 436   @_ = () if not scalar grep { defined $_ } @_;
 437
 438   # just a cond
 439   if (@_ == 1) {
 440     $call_cond = shift;
 441   }
 442   # fish out attrs in the ($condref, $attr) case
 443   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 444     ($call_cond, $call_attrs) = @_;
 445   }
 446   elsif (@_ % 2) {
 447     $self->throw_exception('Odd number of arguments to search')
 448   }
 449   # legacy search
 450   elsif (@_) {
 451     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 452       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 453
 454     for my $i (0 .. $#_) {
 455       next if $i % 2;
 456       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 457         if (! defined $_[$i] or length ref $_[$i] );
 458     }
 459
 460     $call_cond = { @_ };
 461   }
 462
 463   # see if we can keep the cache (no $rs changes)
 464   my $cache;
 465   my %safe = (alias => 1, cache => 1);
 466   if ( ! grep { !$safe{$_} } keys %$call_attrs and (
 467     ! defined $call_cond
 468       or
 469     ref $call_cond eq 'HASH' && ! keys %$call_cond
 470       or
 471     ref $call_cond eq 'ARRAY' && ! @$call_cond
 472   )) {
 473     $cache = $self->get_cache;
 474   }
 475
 476   my $old_attrs = { %{$self->{attrs}} };
 477   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 478
 479   my $new_attrs = { %$old_attrs };
 480
 481   # take care of call attrs (only if anything is changing)
 482   if ($call_attrs and keys %$call_attrs) {
 483
 484     # copy for _normalize_selection
 485     $call_attrs = { %$call_attrs };
 486
 487     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 488
 489     # reset the current selector list if new selectors are supplied
 490     delete @{$old_attrs}{(@selector_attrs, '_dark_selector')}
 491       if grep { exists $call_attrs->{$_} } qw(columns cols select as);
 492
 493     # Normalize the new selector list (operates on the passed-in attr structure)
 494     # Need to do it on every chain instead of only once on _resolved_attrs, in
 495     # order to allow detection of empty vs partial 'as'
 496     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 497       if $old_attrs->{_dark_selector};
 498     $self->_normalize_selection ($call_attrs);
 499
 500     # start with blind overwriting merge, exclude selector attrs
 501     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 502     delete @{$new_attrs}{@selector_attrs};
 503
 504     for (@selector_attrs) {
 505       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 506         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 507     }
 508
 509     # older deprecated name, use only if {columns} is not there
 510     if (my $c = delete $new_attrs->{cols}) {
 511       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 512       if ($new_attrs->{columns}) {
 513         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 514       }
 515       else {
 516         $new_attrs->{columns} = $c;
 517       }
 518     }
 519
 520
 521     # join/prefetch use their own crazy merging heuristics
 522     foreach my $key (qw/join prefetch/) {
 523       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 524         if exists $call_attrs->{$key};
 525     }
 526
 527     # stack binds together
 528     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 529   }
 530
 531
 532   for ($old_where, $call_cond) {
 533     if (defined $_) {
 534       $new_attrs->{where} = $self->_stack_cond (
 535         $_, $new_attrs->{where}
 536       );
 537     }
 538   }
 539
 540   if (defined $old_having) {
 541     $new_attrs->{having} = $self->_stack_cond (
 542       $old_having, $new_attrs->{having}
 543     )
 544   }
 545
 546   my $rs = (ref $self)->new($rsrc, $new_attrs);
 547
 548   $rs->set_cache($cache) if ($cache);
 549
 550   return $rs;
 551 }
 552
 553 sub _normalize_selection {
 554   my ($self, $attrs) = @_;
 555
 556   # legacy syntax
 557   if ( exists $attrs->{include_columns} ) {
 558     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 559     $attrs->{'+columns'} = $self->_merge_attr(
 560       $attrs->{'+columns'}, delete $attrs->{include_columns}
 561     );
 562   }
 563
 564   # columns are always placed first, however
 565
 566   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 567   # delay the decision on whether to use a default select list ($rsrc->columns)
 568   # allowing stuff like the remove_columns helper to work
 569   #
 570   # select/as +select/+as pairs need special handling - the amount of select/as
 571   # elements in each pair does *not* have to be equal (think multicolumn
 572   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 573   # supplied at all) - try to infer the alias, either from the -as parameter
 574   # of the selector spec, or use the parameter whole if it looks like a column
 575   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 576   # is ok as well), but make sure no more additions to the 'as' chain take place
 577   for my $pref ('', '+') {
 578
 579     my ($sel, $as) = map {
 580       my $key = "${pref}${_}";
 581
 582       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 583         ? @{$attrs->{$key}}
 584         : $attrs->{$key} || ()
 585       ];
 586       delete $attrs->{$key};
 587       $val;
 588     } qw/select as/;
 589
 590     if (! @$as and ! @$sel ) {
 591       next;
 592     }
 593     elsif (@$as and ! @$sel) {
 594       $self->throw_exception(
 595         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 596       );
 597     }
 598     elsif( ! @$as ) {
 599       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 600       # if any @$as has been supplied we assume the user knows what (s)he is doing
 601       # and blindly keep stacking up pieces
 602       unless ($attrs->{_dark_selector}) {
 603         SELECTOR:
 604         for (@$sel) {
 605           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 606             push @$as, $_->{-as};
 607           }
 608           # assume any plain no-space, no-parenthesis string to be a column spec
 609           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 610           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 611             push @$as, $_;
 612           }
 613           # if all else fails - raise a flag that no more aliasing will be allowed
 614           else {
 615             $attrs->{_dark_selector} = {
 616               plus_stage => $pref,
 617               string => do {
 618                 local $Data::Dumper::Indent = 0;
 619                 dump_value $_;
 620               },
 621             };
 622             last SELECTOR;
 623           }
 624         }
 625       }
 626     }
 627     elsif (@$as < @$sel) {
 628       $self->throw_exception(
 629         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 630       );
 631     }
 632     elsif ($pref and $attrs->{_dark_selector}) {
 633       $self->throw_exception(
 634         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 635       );
 636     }
 637
 638
 639     # merge result
 640     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 641     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 642   }
 643 }
 644
 645 sub _stack_cond {
 646   my ($self, $left, $right) = @_;
 647
 648   (
 649     (ref $_ eq 'ARRAY' and !@$_)
 650       or
 651     (ref $_ eq 'HASH' and ! keys %$_)
 652   ) and $_ = undef for ($left, $right);
 653
 654   # either one of the two undef
 655   if ( (defined $left) xor (defined $right) ) {
 656     return defined $left ? $left : $right;
 657   }
 658   # both undef
 659   elsif ( ! defined $left ) {
 660     return undef
 661   }
 662   else {
 663     return $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 664   }
 665 }
 666
 667 =head2 search_literal
 668
 669 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 670 should only be used in that context. C<search_literal> is a convenience
 671 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 672 want to ensure columns are bound correctly, use L</search>.
 673
 674 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 675 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 676 require C<search_literal>.
 677
 678 =over 4
 679
 680 =item Arguments: $sql_fragment, @standalone_bind_values
 681
 682 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 683
 684 =back
 685
 686   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 687   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 688
 689 Pass a literal chunk of SQL to be added to the conditional part of the
 690 resultset query.
 691
 692 Example of how to use C<search> instead of C<search_literal>
 693
 694   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 695   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 696
 697 =cut
 698
 699 sub search_literal {
 700   my ($self, $sql, @bind) = @_;
 701   my $attr;
 702   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 703     $attr = pop @bind;
 704   }
 705   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 706 }
 707
 708 =head2 find
 709
 710 =over 4
 711
 712 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 713
 714 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 715
 716 =back
 717
 718 Finds and returns a single row based on supplied criteria. Takes either a
 719 hashref with the same format as L</create> (including inference of foreign
 720 keys from related objects), or a list of primary key values in the same
 721 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 722 declaration on the L</result_source>.
 723
 724 In either case an attempt is made to combine conditions already existing on
 725 the resultset with the condition passed to this method.
 726
 727 To aid with preparing the correct query for the storage you may supply the
 728 C<key> attribute, which is the name of a
 729 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 730 unique constraint corresponding to the
 731 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 732 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 733 to construct a query that satisfies the named unique constraint fully (
 734 non-NULL values for each column member of the constraint) an exception is
 735 thrown.
 736
 737 If no C<key> is specified, the search is carried over all unique constraints
 738 which are fully defined by the available condition.
 739
 740 If no such constraint is found, C<find> currently defaults to a simple
 741 C<< search->(\%column_values) >> which may or may not do what you expect.
 742 Note that this fallback behavior may be deprecated in further versions. If
 743 you need to search with arbitrary conditions - use L</search>. If the query
 744 resulting from this fallback produces more than one row, a warning to the
 745 effect is issued, though only the first row is constructed and returned as
 746 C<$result_object>.
 747
 748 In addition to C<key>, L</find> recognizes and applies standard
 749 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 750
 751 Note that if you have extra concerns about the correctness of the resulting
 752 query you need to specify the C<key> attribute and supply the entire condition
 753 as an argument to find (since it is not always possible to perform the
 754 combination of the resultset condition with the supplied one, especially if
 755 the resultset condition contains literal sql).
 756
 757 For example, to find a row by its primary key:
 758
 759   my $cd = $schema->resultset('CD')->find(5);
 760
 761 You can also find a row by a specific unique constraint:
 762
 763   my $cd = $schema->resultset('CD')->find(
 764     {
 765       artist => 'Massive Attack',
 766       title  => 'Mezzanine',
 767     },
 768     { key => 'cd_artist_title' }
 769   );
 770
 771 See also L</find_or_create> and L</update_or_create>.
 772
 773 =cut
 774
 775 sub find {
 776   my $self = shift;
 777   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 778
 779   my $rsrc = $self->result_source;
 780
 781   my $constraint_name;
 782   if (exists $attrs->{key}) {
 783     $constraint_name = defined $attrs->{key}
 784       ? $attrs->{key}
 785       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 786     ;
 787   }
 788
 789   # Parse out the condition from input
 790   my $call_cond;
 791
 792   if (ref $_[0] eq 'HASH') {
 793     $call_cond = { %{$_[0]} };
 794   }
 795   else {
 796     # if only values are supplied we need to default to 'primary'
 797     $constraint_name = 'primary' unless defined $constraint_name;
 798
 799     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 800
 801     $self->throw_exception(
 802       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 803     ) unless @c_cols;
 804
 805     $self->throw_exception (
 806       'find() expects either a column/value hashref, or a list of values '
 807     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 808     ) unless @c_cols == @_;
 809
 810     @{$call_cond}{@c_cols} = @_;
 811   }
 812
 813   # process relationship data if any
 814   for my $key (keys %$call_cond) {
 815     if (
 816       length ref($call_cond->{$key})
 817         and
 818       my $relinfo = $rsrc->relationship_info($key)
 819         and
 820       # implicitly skip has_many's (likely MC)
 821       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 822     ) {
 823       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 824         $relinfo->{cond}, $val, $key, $key
 825       );
 826
 827       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 828          if $crosstable or ref($rel_cond) ne 'HASH';
 829
 830       # supplement condition
 831       # relationship conditions take precedence (?)
 832       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 833     }
 834   }
 835
 836   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 837   my $final_cond;
 838   if (defined $constraint_name) {
 839     $final_cond = $self->_qualify_cond_columns (
 840
 841       $rsrc->_minimal_valueset_satisfying_constraint(
 842         constraint_name => $constraint_name,
 843         values => ($self->_merge_with_rscond($call_cond))[0],
 844         carp_on_nulls => 1,
 845       ),
 846
 847       $alias,
 848     );
 849   }
 850   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 851     # This means that we got here after a merger of relationship conditions
 852     # in ::Relationship::Base::search_related (the row method), and furthermore
 853     # the relationship is of the 'single' type. This means that the condition
 854     # provided by the relationship (already attached to $self) is sufficient,
 855     # as there can be only one row in the database that would satisfy the
 856     # relationship
 857   }
 858   else {
 859     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 860
 861     # no key was specified - fall down to heuristics mode:
 862     # run through all unique queries registered on the resultset, and
 863     # 'OR' all qualifying queries together
 864     #
 865     # always start from 'primary' if it exists at all
 866     for my $c_name ( sort {
 867         $a eq 'primary' ? -1
 868       : $b eq 'primary' ? 1
 869       : $a cmp $b
 870     } $rsrc->unique_constraint_names) {
 871
 872       next if $seen_column_combinations{
 873         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 874       }++;
 875
 876       dbic_internal_try {
 877         push @unique_queries, $self->_qualify_cond_columns(
 878           $rsrc->_minimal_valueset_satisfying_constraint(
 879             constraint_name => $c_name,
 880             values => ($self->_merge_with_rscond($call_cond))[0],
 881             columns_info => ($ci ||= $rsrc->columns_info),
 882           ),
 883           $alias
 884         );
 885       }
 886       catch {
 887         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 888       };
 889     }
 890
 891     $final_cond =
 892         @unique_queries   ? \@unique_queries
 893       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 894       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 895     ;
 896   }
 897
 898   # Run the query, passing the result_class since it should propagate for find
 899   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 900   if ($rs->_resolved_attrs->{collapse}) {
 901     my $row = $rs->next;
 902     carp "Query returned more than one row" if $rs->next;
 903     return $row;
 904   }
 905   else {
 906     return $rs->single;
 907   }
 908 }
 909
 910 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 911 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 912 #
 913 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 914 # condition. It is provided for overrides until a saner way forward is devised
 915 #
 916 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 917 # the road. Please adjust your tests accordingly to catch this situation early
 918 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 919 #
 920 # The method will not be removed without an adequately complete replacement
 921 # for strict-mode enforcement
 922 sub _non_unique_find_fallback {
 923   my ($self, $cond, $attrs) = @_;
 924
 925   return $self->_qualify_cond_columns(
 926     $cond,
 927     exists $attrs->{alias}
 928       ? $attrs->{alias}
 929       : $self->{attrs}{alias}
 930   );
 931 }
 932
 933
 934 sub _qualify_cond_columns {
 935   my ($self, $cond, $alias) = @_;
 936
 937   my %aliased = %$cond;
 938   for (keys %aliased) {
 939     $aliased{"$alias.$_"} = delete $aliased{$_}
 940       if $_ !~ /\./;
 941   }
 942
 943   return \%aliased;
 944 }
 945
 946 sub _build_unique_cond {
 947   carp_unique sprintf
 948     '_build_unique_cond is a private method, and moreover is about to go '
 949   . 'away. Please contact the development team at %s if you believe you '
 950   . 'have a genuine use for this method, in order to discuss alternatives.',
 951     DBIx::Class::_ENV_::HELP_URL,
 952   ;
 953
 954   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 955
 956   $self->result_source->_minimal_valueset_satisfying_constraint(
 957     constraint_name => $constraint_name,
 958     values => $cond,
 959     carp_on_nulls => !$croak_on_null
 960   );
 961 }
 962
 963 =head2 search_related
 964
 965 =over 4
 966
 967 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 968
 969 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 970
 971 =back
 972
 973   $new_rs = $cd_rs->search_related('artist', {
 974     name => 'Emo-R-Us',
 975   });
 976
 977 Searches the specified relationship, optionally specifying a condition and
 978 attributes for matching records. See L</ATTRIBUTES> for more information.
 979
 980 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 981 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 982
 983 See also L</search_related_rs>.
 984
 985 =cut
 986
 987 sub search_related {
 988   return shift->related_resultset(shift)->search(@_);
 989 }
 990
 991 =head2 search_related_rs
 992
 993 This method works exactly the same as search_related, except that
 994 it guarantees a resultset, even in list context.
 995
 996 =cut
 997
 998 sub search_related_rs {
 999   return shift->related_resultset(shift)->search_rs(@_);
1000 }
1001
1002 =head2 cursor
1003
1004 =over 4
1005
1006 =item Arguments: none
1007
1008 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1009
1010 =back
1011
1012 Returns a storage-driven cursor to the given resultset. See
1013 L<DBIx::Class::Cursor> for more information.
1014
1015 =cut
1016
1017 sub cursor {
1018   my $self = shift;
1019
1020   return $self->{cursor} ||= do {
1021     my $attrs = $self->_resolved_attrs;
1022     $self->result_source->storage->select(
1023       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1024     );
1025   };
1026 }
1027
1028 =head2 single
1029
1030 =over 4
1031
1032 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1033
1034 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1035
1036 =back
1037
1038   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1039
1040 Inflates the first result without creating a cursor if the resultset has
1041 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1042 of L</search>.
1043
1044 While this method can take an optional search condition (just like L</search>)
1045 being a fast-code-path it does not recognize search attributes. If you need to
1046 add extra joins or similar, call L</search> and then chain-call L</single> on the
1047 L<DBIx::Class::ResultSet> returned.
1048
1049 =over
1050
1051 =item B<Note>
1052
1053 As of 0.08100, this method enforces the assumption that the preceding
1054 query returns only one row. If more than one row is returned, you will receive
1055 a warning:
1056
1057   Query returned more than one row
1058
1059 In this case, you should be using L</next> or L</find> instead, or if you really
1060 know what you are doing, use the L</rows> attribute to explicitly limit the size
1061 of the resultset.
1062
1063 This method will also throw an exception if it is called on a resultset prefetching
1064 has_many, as such a prefetch implies fetching multiple rows from the database in
1065 order to assemble the resulting object.
1066
1067 =back
1068
1069 =cut
1070
1071 sub single {
1072   my ($self, $where) = @_;
1073   if(@_ > 2) {
1074       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1075   }
1076
1077   my $attrs = { %{$self->_resolved_attrs} };
1078
1079   $self->throw_exception(
1080     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1081   ) if $attrs->{collapse};
1082
1083   if ($where) {
1084     if (defined $attrs->{where}) {
1085       $attrs->{where} = {
1086         '-and' =>
1087             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1088                $where, delete $attrs->{where} ]
1089       };
1090     } else {
1091       $attrs->{where} = $where;
1092     }
1093   }
1094
1095   my $data = [ $self->result_source->storage->select_single(
1096     $attrs->{from}, $attrs->{select},
1097     $attrs->{where}, $attrs
1098   )];
1099
1100   return undef unless @$data;
1101   $self->{_stashed_rows} = [ $data ];
1102   $self->_construct_results->[0];
1103 }
1104
1105 =head2 get_column
1106
1107 =over 4
1108
1109 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1110
1111 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1112
1113 =back
1114
1115   my $max_length = $rs->get_column('length')->max;
1116
1117 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1118
1119 =cut
1120
1121 sub get_column {
1122   my ($self, $column) = @_;
1123   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1124   return $new;
1125 }
1126
1127 =head2 search_like
1128
1129 =over 4
1130
1131 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1132
1133 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1134
1135 =back
1136
1137   # WHERE title LIKE '%blue%'
1138   $cd_rs = $rs->search_like({ title => '%blue%'});
1139
1140 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1141 that this is simply a convenience method retained for ex Class::DBI users.
1142 You most likely want to use L</search> with specific operators.
1143
1144 For more information, see L<DBIx::Class::Manual::Cookbook>.
1145
1146 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1147 instead. An example conversion is:
1148
1149   ->search_like({ foo => 'bar' });
1150
1151   # Becomes
1152
1153   ->search({ foo => { like => 'bar' } });
1154
1155 =cut
1156
1157 sub search_like {
1158   my $class = shift;
1159   carp_unique (
1160     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1161    .' Instead use ->search({ x => { -like => "y%" } })'
1162    .' (note the outer pair of {}s - they are important!)'
1163   );
1164   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1165   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1166   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1167   return $class->search($query, { %$attrs });
1168 }
1169
1170 =head2 slice
1171
1172 =over 4
1173
1174 =item Arguments: $first, $last
1175
1176 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1177
1178 =back
1179
1180 Returns a resultset or object list representing a subset of elements from the
1181 resultset slice is called on. Indexes are from 0, i.e., to get the first
1182 three records, call:
1183
1184   my ($one, $two, $three) = $rs->slice(0, 2);
1185
1186 =cut
1187
1188 sub slice {
1189   my ($self, $min, $max) = @_;
1190   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1191   $attrs->{offset} = $self->{attrs}{offset} || 0;
1192   $attrs->{offset} += $min;
1193   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1194   return $self->search(undef, $attrs);
1195 }
1196
1197 =head2 next
1198
1199 =over 4
1200
1201 =item Arguments: none
1202
1203 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1204
1205 =back
1206
1207 Returns the next element in the resultset (C<undef> is there is none).
1208
1209 Can be used to efficiently iterate over records in the resultset:
1210
1211   my $rs = $schema->resultset('CD')->search;
1212   while (my $cd = $rs->next) {
1213     print $cd->title;
1214   }
1215
1216 Note that you need to store the resultset object, and call C<next> on it.
1217 Calling C<< resultset('Table')->next >> repeatedly will always return the
1218 first record from the resultset.
1219
1220 =cut
1221
1222 sub next {
1223   my ($self) = @_;
1224
1225   if (my $cache = $self->get_cache) {
1226     $self->{all_cache_position} ||= 0;
1227     return $cache->[$self->{all_cache_position}++];
1228   }
1229
1230   if ($self->{attrs}{cache}) {
1231     delete $self->{pager};
1232     $self->{all_cache_position} = 1;
1233     return ($self->all)[0];
1234   }
1235
1236   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1237
1238   $self->{_stashed_results} = $self->_construct_results
1239     or return undef;
1240
1241   return shift @{$self->{_stashed_results}};
1242 }
1243
1244 # Constructs as many results as it can in one pass while respecting
1245 # cursor laziness. Several modes of operation:
1246 #
1247 # * Always builds everything present in @{$self->{_stashed_rows}}
1248 # * If called with $fetch_all true - pulls everything off the cursor and
1249 #   builds all result structures (or objects) in one pass
1250 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1251 #   and if the resultset is ordered properly by the left side:
1252 #   * Fetches stuff off the cursor until the "master object" changes,
1253 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1254 #   OR
1255 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1256 #     was requested (there is no other way to collapse except for an
1257 #     eager cursor)
1258 # * If no collapse is requested - just get the next row, construct and
1259 #   return
1260 sub _construct_results {
1261   my ($self, $fetch_all) = @_;
1262
1263   my $rsrc = $self->result_source;
1264   my $attrs = $self->_resolved_attrs;
1265
1266   if (
1267     ! $fetch_all
1268       and
1269     ! $attrs->{order_by}
1270       and
1271     $attrs->{collapse}
1272       and
1273     my @pcols = $rsrc->primary_columns
1274   ) {
1275     # default order for collapsing unless the user asked for something
1276     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1277     $attrs->{_ordered_for_collapse} = 1;
1278     $attrs->{_order_is_artificial} = 1;
1279   }
1280
1281   # this will be used as both initial raw-row collector AND as a RV of
1282   # _construct_results. Not regrowing the array twice matters a lot...
1283   # a surprising amount actually
1284   my $rows = delete $self->{_stashed_rows};
1285
1286   my $cursor; # we may not need one at all
1287
1288   my $did_fetch_all = $fetch_all;
1289
1290   if ($fetch_all) {
1291     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1292     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1293   }
1294   elsif( $attrs->{collapse} ) {
1295
1296     # a cursor will need to be closed over in case of collapse
1297     $cursor = $self->cursor;
1298
1299     $attrs->{_ordered_for_collapse} = (
1300       (
1301         $attrs->{order_by}
1302           and
1303         $rsrc->schema
1304               ->storage
1305                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1306       ) ? 1 : 0
1307     ) unless defined $attrs->{_ordered_for_collapse};
1308
1309     if (! $attrs->{_ordered_for_collapse}) {
1310       $did_fetch_all = 1;
1311
1312       # instead of looping over ->next, use ->all in stealth mode
1313       # *without* calling a ->reset afterwards
1314       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1315       if (! $cursor->{_done}) {
1316         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1317         $cursor->{_done} = 1;
1318       }
1319     }
1320   }
1321
1322   if (! $did_fetch_all and ! @{$rows||[]} ) {
1323     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1324     $cursor ||= $self->cursor;
1325     if (scalar (my @r = $cursor->next) ) {
1326       $rows = [ \@r ];
1327     }
1328   }
1329
1330   return undef unless @{$rows||[]};
1331
1332   # sanity check - people are too clever for their own good
1333   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1334
1335     my $multiplied_selectors;
1336     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1337       if (
1338         $aliastypes->{multiplying}{$sel_alias}
1339           or
1340         $aliastypes->{premultiplied}{$sel_alias}
1341       ) {
1342         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1343       }
1344     }
1345
1346     for my $i (0 .. $#{$attrs->{as}} ) {
1347       my $sel = $attrs->{select}[$i];
1348
1349       if (ref $sel eq 'SCALAR') {
1350         $sel = $$sel;
1351       }
1352       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1353         $sel = $$sel->[0];
1354       }
1355
1356       $self->throw_exception(
1357         'Result collapse not possible - selection from a has_many source redirected to the main object'
1358       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1359     }
1360   }
1361
1362   # hotspot - skip the setter
1363   my $res_class = $self->_result_class;
1364
1365   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1366     $res_class->can ('inflate_result')
1367       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1368   };
1369
1370   my $infmap = $attrs->{as};
1371
1372   $self->{_result_inflator}{is_core_row} = ( (
1373     $inflator_cref
1374       ==
1375     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1376   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1377
1378   $self->{_result_inflator}{is_hri} = ( (
1379     ! $self->{_result_inflator}{is_core_row}
1380       and
1381     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1382   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1383
1384
1385   if ($attrs->{_simple_passthrough_construction}) {
1386     # construct a much simpler array->hash folder for the one-table HRI cases right here
1387     if ($self->{_result_inflator}{is_hri}) {
1388       for my $r (@$rows) {
1389         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1390       }
1391     }
1392     # FIXME SUBOPTIMAL this is a very very very hot spot
1393     # while rather optimal we can *still* do much better, by
1394     # building a smarter Row::inflate_result(), and
1395     # switch to feeding it data via a much leaner interface
1396     #
1397     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1398     # this particular resultset size
1399     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1400       for my $r (@$rows) {
1401         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1402       }
1403     }
1404     else {
1405       eval sprintf (
1406         ( $self->{_result_inflator}{is_core_row}
1407           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1408           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1409           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1410         ),
1411         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1412       ) . '; 1' or die;
1413     }
1414   }
1415   else {
1416     my $parser_type =
1417         $self->{_result_inflator}{is_hri}       ? 'hri'
1418       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1419       :                                           'classic_nonpruning'
1420     ;
1421
1422     unless( $self->{_row_parser}{$parser_type}{cref} ) {
1423
1424       # $args and $attrs to _mk_row_parser are separated to delineate what is
1425       # core collapser stuff and what is dbic $rs specific
1426       $self->{_row_parser}{$parser_type}{src} = $rsrc->_mk_row_parser({
1427         inflate_map => $infmap,
1428         collapse => $attrs->{collapse},
1429         premultiplied => $attrs->{_main_source_premultiplied},
1430         hri_style => $self->{_result_inflator}{is_hri},
1431         prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1432       }, $attrs);
1433
1434       $self->{_row_parser}{$parser_type}{cref} = do {
1435         package # hide form PAUSE
1436           DBIx::Class::__GENERATED_ROW_PARSER__;
1437
1438         eval $self->{_row_parser}{$parser_type}{src};
1439       } || die $@;
1440     }
1441
1442     # this needs to close over the *current* cursor, hence why it is not cached above
1443     my $next_cref = ($did_fetch_all or ! $attrs->{collapse})
1444       ? undef
1445       : sub {
1446         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1447         my @r = $cursor->next or return;
1448         \@r
1449       }
1450     ;
1451
1452     $self->{_row_parser}{$parser_type}{cref}->(
1453       $rows,
1454       $next_cref,
1455       ( $self->{_stashed_rows} = [] ),
1456       ( my $null_violations = {} ),
1457     );
1458
1459     $self->throw_exception(
1460       'Collapse aborted - the following columns are declared (or defaulted to) '
1461     . 'non-nullable within DBIC but NULLs were retrieved from storage: '
1462     . join( ', ', map { "'$infmap->[$_]'" } sort { $a <=> $b } keys %$null_violations )
1463     . ' within data row ' . dump_value({
1464       map {
1465         $infmap->[$_] =>
1466           ( ! defined $self->{_stashed_rows}[0][$_] or length $self->{_stashed_rows}[0][$_] < 50 )
1467             ? $self->{_stashed_rows}[0][$_]
1468             : substr( $self->{_stashed_rows}[0][$_], 0, 50 ) . '...'
1469       } 0 .. $#{$self->{_stashed_rows}[0]}
1470     })
1471     ) if keys %$null_violations;
1472
1473     # simple in-place substitution, does not regrow $rows
1474     if ($self->{_result_inflator}{is_core_row}) {
1475       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1476     }
1477     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1478     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1479       # the inflator may be a multiplier/reductor - put it in list ctx
1480       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1481     }
1482   }
1483
1484   # The @$rows check seems odd at first - why wouldn't we want to warn
1485   # regardless? The issue is things like find() etc, where the user
1486   # *knows* only one result will come back. In these cases the ->all
1487   # is not a pessimization, but rather something we actually want
1488   carp_unique(
1489     'Unable to properly collapse has_many results in iterator mode due '
1490   . 'to order criteria - performed an eager cursor slurp underneath. '
1491   . 'Consider using ->all() instead'
1492   ) if ( ! $fetch_all and @$rows > 1 );
1493
1494   return $rows;
1495 }
1496
1497 =head2 result_source
1498
1499 =over 4
1500
1501 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1502
1503 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1504
1505 =back
1506
1507 An accessor for the primary ResultSource object from which this ResultSet
1508 is derived.
1509
1510 =head2 result_class
1511
1512 =over 4
1513
1514 =item Arguments: $result_class?
1515
1516 =item Return Value: $result_class
1517
1518 =back
1519
1520 An accessor for the class to use when creating result objects. Defaults to
1521 C<< result_source->result_class >> - which in most cases is the name of the
1522 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1523
1524 Note that changing the result_class will also remove any components
1525 that were originally loaded in the source class via
1526 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1527 Any overloaded methods in the original source class will not run.
1528
1529 =cut
1530
1531 sub result_class {
1532   my ($self, $result_class) = @_;
1533   if ($result_class) {
1534
1535     # don't fire this for an object
1536     $self->ensure_class_loaded($result_class)
1537       unless ref($result_class);
1538
1539     if ($self->get_cache) {
1540       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1541     }
1542     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1543     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1544       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1545     }
1546
1547     $self->_result_class($result_class);
1548
1549     delete $self->{_result_inflator};
1550   }
1551   $self->_result_class;
1552 }
1553
1554 =head2 count
1555
1556 =over 4
1557
1558 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1559
1560 =item Return Value: $count
1561
1562 =back
1563
1564 Performs an SQL C<COUNT> with the same query as the resultset was built
1565 with to find the number of elements. Passing arguments is equivalent to
1566 C<< $rs->search ($cond, \%attrs)->count >>
1567
1568 =cut
1569
1570 sub count {
1571   my $self = shift;
1572   return $self->search(@_)->count if @_ and defined $_[0];
1573   return scalar @{ $self->get_cache } if $self->get_cache;
1574
1575   my $attrs = { %{ $self->_resolved_attrs } };
1576
1577   # this is a little optimization - it is faster to do the limit
1578   # adjustments in software, instead of a subquery
1579   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1580
1581   my $crs;
1582   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1583     $crs = $self->_count_subq_rs ($attrs);
1584   }
1585   else {
1586     $crs = $self->_count_rs ($attrs);
1587   }
1588   my $count = $crs->next;
1589
1590   $count -= $offset if $offset;
1591   $count = $rows if $rows and $rows < $count;
1592   $count = 0 if ($count < 0);
1593
1594   return $count;
1595 }
1596
1597 =head2 count_rs
1598
1599 =over 4
1600
1601 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1602
1603 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1604
1605 =back
1606
1607 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1608 This can be very handy for subqueries:
1609
1610   ->search( { amount => $some_rs->count_rs->as_query } )
1611
1612 As with regular resultsets the SQL query will be executed only after
1613 the resultset is accessed via L</next> or L</all>. That would return
1614 the same single value obtainable via L</count>.
1615
1616 =cut
1617
1618 sub count_rs {
1619   my $self = shift;
1620   return $self->search(@_)->count_rs if @_;
1621
1622   # this may look like a lack of abstraction (count() does about the same)
1623   # but in fact an _rs *must* use a subquery for the limits, as the
1624   # software based limiting can not be ported if this $rs is to be used
1625   # in a subquery itself (i.e. ->as_query)
1626   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1627     return $self->_count_subq_rs($self->{_attrs});
1628   }
1629   else {
1630     return $self->_count_rs($self->{_attrs});
1631   }
1632 }
1633
1634 #
1635 # returns a ResultSetColumn object tied to the count query
1636 #
1637 sub _count_rs {
1638   my ($self, $attrs) = @_;
1639
1640   my $rsrc = $self->result_source;
1641
1642   my $tmp_attrs = { %$attrs };
1643   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1644   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1645
1646   # overwrite the selector (supplied by the storage)
1647   $rsrc->resultset_class->new($rsrc, {
1648     %$tmp_attrs,
1649     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1650     as => 'count',
1651   })->get_column ('count');
1652 }
1653
1654 #
1655 # same as above but uses a subquery
1656 #
1657 sub _count_subq_rs {
1658   my ($self, $attrs) = @_;
1659
1660   my $rsrc = $self->result_source;
1661
1662   my $sub_attrs = { %$attrs };
1663   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1664   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1665
1666   # if we multi-prefetch we group_by something unique, as this is what we would
1667   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1668   if ( $attrs->{collapse}  ) {
1669     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1670       $rsrc->_identifying_column_set || $self->throw_exception(
1671         'Unable to construct a unique group_by criteria properly collapsing the '
1672       . 'has_many prefetch before count()'
1673       );
1674     } ]
1675   }
1676
1677   # Calculate subquery selector
1678   if (my $g = $sub_attrs->{group_by}) {
1679
1680     my $sql_maker = $rsrc->storage->sql_maker;
1681
1682     # necessary as the group_by may refer to aliased functions
1683     my $sel_index;
1684     for my $sel (@{$attrs->{select}}) {
1685       $sel_index->{$sel->{-as}} = $sel
1686         if (ref $sel eq 'HASH' and $sel->{-as});
1687     }
1688
1689     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1690     # also look for named aggregates referred in the having clause
1691     # having often contains scalarrefs - thus parse it out entirely
1692     my @parts = @$g;
1693     if ($attrs->{having}) {
1694       local $sql_maker->{having_bind};
1695       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1696       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1697       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1698         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1699         # if we don't unset it we screw up retarded but unfortunately working
1700         # 'MAX(foo.bar)' => { '>', 3 }
1701         $sql_maker->{name_sep} = '';
1702       }
1703
1704       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1705
1706       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1707       my %seen_having;
1708
1709       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1710       # and if all fails for an utterly naive quoted scalar-with-function
1711       while ($having_sql =~ /
1712         $rquote $sep $lquote (.+?) $rquote
1713           |
1714         [\s,] \w+ \. (\w+) [\s,]
1715           |
1716         [\s,] $lquote (.+?) $rquote [\s,]
1717       /gx) {
1718         my $part = $1 || $2 || $3;  # one of them matched if we got here
1719         unless ($seen_having{$part}++) {
1720           push @parts, $part;
1721         }
1722       }
1723     }
1724
1725     for (@parts) {
1726       my $colpiece = $sel_index->{$_} || $_;
1727
1728       # unqualify join-based group_by's. Arcane but possible query
1729       # also horrible horrible hack to alias a column (not a func.)
1730       # (probably need to introduce SQLA syntax)
1731       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1732         my $as = $colpiece;
1733         $as =~ s/\./__/;
1734         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1735       }
1736       push @{$sub_attrs->{select}}, $colpiece;
1737     }
1738   }
1739   else {
1740     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1741     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1742   }
1743
1744   return $rsrc->resultset_class
1745                ->new ($rsrc, $sub_attrs)
1746                 ->as_subselect_rs
1747                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1748                   ->get_column ('count');
1749 }
1750
1751
1752 =head2 count_literal
1753
1754 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1755 should only be used in that context. See L</search_literal> for further info.
1756
1757 =over 4
1758
1759 =item Arguments: $sql_fragment, @standalone_bind_values
1760
1761 =item Return Value: $count
1762
1763 =back
1764
1765 Counts the results in a literal query. Equivalent to calling L</search_literal>
1766 with the passed arguments, then L</count>.
1767
1768 =cut
1769
1770 sub count_literal { shift->search_literal(@_)->count; }
1771
1772 =head2 all
1773
1774 =over 4
1775
1776 =item Arguments: none
1777
1778 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1779
1780 =back
1781
1782 Returns all elements in the resultset.
1783
1784 =cut
1785
1786 sub all {
1787   my $self = shift;
1788   if(@_) {
1789     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1790   }
1791
1792   delete @{$self}{qw/_stashed_rows _stashed_results/};
1793
1794   if (my $c = $self->get_cache) {
1795     return @$c;
1796   }
1797
1798   $self->cursor->reset;
1799
1800   my $objs = $self->_construct_results('fetch_all') || [];
1801
1802   $self->set_cache($objs) if $self->{attrs}{cache};
1803
1804   return @$objs;
1805 }
1806
1807 =head2 reset
1808
1809 =over 4
1810
1811 =item Arguments: none
1812
1813 =item Return Value: $self
1814
1815 =back
1816
1817 Resets the resultset's cursor, so you can iterate through the elements again.
1818 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1819 another query.
1820
1821 =cut
1822
1823 sub reset {
1824   my ($self) = @_;
1825
1826   delete @{$self}{qw/_stashed_rows _stashed_results/};
1827   $self->{all_cache_position} = 0;
1828   $self->cursor->reset;
1829   return $self;
1830 }
1831
1832 =head2 first
1833
1834 =over 4
1835
1836 =item Arguments: none
1837
1838 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1839
1840 =back
1841
1842 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1843 an object for the first result (or C<undef> if the resultset is empty).
1844
1845 =cut
1846
1847 sub first {
1848   return $_[0]->reset->next;
1849 }
1850
1851
1852 # _rs_update_delete
1853 #
1854 # Determines whether and what type of subquery is required for the $rs operation.
1855 # If grouping is necessary either supplies its own, or verifies the current one
1856 # After all is done delegates to the proper storage method.
1857
1858 sub _rs_update_delete {
1859   my ($self, $op, $values) = @_;
1860
1861   my $rsrc = $self->result_source;
1862   my $storage = $rsrc->schema->storage;
1863
1864   my $attrs = { %{$self->_resolved_attrs} };
1865
1866   my $join_classifications;
1867   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1868
1869   # do we need a subquery for any reason?
1870   my $needs_subq = (
1871     defined $existing_group_by
1872       or
1873     # if {from} is unparseable wrap a subq
1874     ref($attrs->{from}) ne 'ARRAY'
1875       or
1876     # limits call for a subq
1877     $self->_has_resolved_attr(qw/rows offset/)
1878   );
1879
1880   # simplify the joinmap, so we can further decide if a subq is necessary
1881   if (!$needs_subq and @{$attrs->{from}} > 1) {
1882
1883     ($attrs->{from}, $join_classifications) =
1884       $storage->_prune_unused_joins ($attrs);
1885
1886     # any non-pruneable non-local restricting joins imply subq
1887     $needs_subq = grep { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1888   }
1889
1890   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1891   $needs_subq ||= (
1892     (ref $attrs->{from}[0]) ne 'HASH'
1893       or
1894     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1895   );
1896
1897   my ($cond, $guard);
1898   # do we need anything like a subquery?
1899   if (! $needs_subq) {
1900     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1901     # a condition containing 'me' or other table prefixes will not work
1902     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1903     $cond = do {
1904       my $sqla = $rsrc->storage->sql_maker;
1905       local $sqla->{_dequalify_idents} = 1;
1906       \[ $sqla->_recurse_where($self->{cond}) ];
1907     };
1908   }
1909   else {
1910     # we got this far - means it is time to wrap a subquery
1911     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1912       sprintf(
1913         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1914         $op,
1915         $rsrc->source_name,
1916       )
1917     );
1918
1919     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1920     delete $attrs->{$_} for qw/select as collapse/;
1921     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1922
1923     # this will be consumed by the pruner waaaaay down the stack
1924     $attrs->{_force_prune_multiplying_joins} = 1;
1925
1926     my $subrs = (ref $self)->new($rsrc, $attrs);
1927
1928     if (@$idcols == 1) {
1929       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1930     }
1931     elsif ($storage->_use_multicolumn_in) {
1932       # no syntax for calling this properly yet
1933       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1934       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1935         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1936         $subrs->as_query
1937       ),
1938     }
1939     else {
1940       # if all else fails - get all primary keys and operate over a ORed set
1941       # wrap in a transaction for consistency
1942       # this is where the group_by/multiplication starts to matter
1943       if (
1944         $existing_group_by
1945           or
1946         # we do not need to check pre-multipliers, since if the premulti is there, its
1947         # parent (who is multi) will be there too
1948         keys %{ $join_classifications->{multiplying} || {} }
1949       ) {
1950         # make sure if there is a supplied group_by it matches the columns compiled above
1951         # perfectly. Anything else can not be sanely executed on most databases so croak
1952         # right then and there
1953         if ($existing_group_by) {
1954           my @current_group_by = map
1955             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1956             @$existing_group_by
1957           ;
1958
1959           if (
1960             join ("\x00", sort @current_group_by)
1961               ne
1962             join ("\x00", sort @{$attrs->{columns}} )
1963           ) {
1964             $self->throw_exception (
1965               "You have just attempted a $op operation on a resultset which does group_by"
1966               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1967               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1968               . ' kind of queries. Please retry the operation with a modified group_by or'
1969               . ' without using one at all.'
1970             );
1971           }
1972         }
1973
1974         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1975       }
1976
1977       $guard = $storage->txn_scope_guard;
1978
1979       for my $row ($subrs->cursor->all) {
1980         push @$cond, { map
1981           { $idcols->[$_] => $row->[$_] }
1982           (0 .. $#$idcols)
1983         };
1984       }
1985     }
1986   }
1987
1988   my $res = $cond ? $storage->$op (
1989     $rsrc,
1990     $op eq 'update' ? $values : (),
1991     $cond,
1992   ) : '0E0';
1993
1994   $guard->commit if $guard;
1995
1996   return $res;
1997 }
1998
1999 =head2 update
2000
2001 =over 4
2002
2003 =item Arguments: \%values
2004
2005 =item Return Value: $underlying_storage_rv
2006
2007 =back
2008
2009 Sets the specified columns in the resultset to the supplied values in a
2010 single query. Note that this will not run any accessor/set_column/update
2011 triggers, nor will it update any result object instances derived from this
2012 resultset (this includes the contents of the L<resultset cache|/set_cache>
2013 if any). See L</update_all> if you need to execute any on-update
2014 triggers or cascades defined either by you or a
2015 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2016
2017 The return value is a pass through of what the underlying
2018 storage backend returned, and may vary. See L<DBI/execute> for the most
2019 common case.
2020
2021 =head3 CAVEAT
2022
2023 Note that L</update> does not process/deflate any of the values passed in.
2024 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2025 ensure manually that any value passed to this method will stringify to
2026 something the RDBMS knows how to deal with. A notable example is the
2027 handling of L<DateTime> objects, for more info see:
2028 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2029
2030 =cut
2031
2032 sub update {
2033   my ($self, $values) = @_;
2034   $self->throw_exception('Values for update must be a hash')
2035     unless ref $values eq 'HASH';
2036
2037   return $self->_rs_update_delete ('update', $values);
2038 }
2039
2040 =head2 update_all
2041
2042 =over 4
2043
2044 =item Arguments: \%values
2045
2046 =item Return Value: 1
2047
2048 =back
2049
2050 Fetches all objects and updates them one at a time via
2051 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2052 triggers, while L</update> will not.
2053
2054 =cut
2055
2056 sub update_all {
2057   my ($self, $values) = @_;
2058   $self->throw_exception('Values for update_all must be a hash')
2059     unless ref $values eq 'HASH';
2060
2061   my $guard = $self->result_source->schema->txn_scope_guard;
2062   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2063   $guard->commit;
2064   return 1;
2065 }
2066
2067 =head2 delete
2068
2069 =over 4
2070
2071 =item Arguments: none
2072
2073 =item Return Value: $underlying_storage_rv
2074
2075 =back
2076
2077 Deletes the rows matching this resultset in a single query. Note that this
2078 will not run any delete triggers, nor will it alter the
2079 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2080 derived from this resultset (this includes the contents of the
2081 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2082 execute any on-delete triggers or cascades defined either by you or a
2083 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2084
2085 The return value is a pass through of what the underlying storage backend
2086 returned, and may vary. See L<DBI/execute> for the most common case.
2087
2088 =cut
2089
2090 sub delete {
2091   my $self = shift;
2092   $self->throw_exception('delete does not accept any arguments')
2093     if @_;
2094
2095   return $self->_rs_update_delete ('delete');
2096 }
2097
2098 =head2 delete_all
2099
2100 =over 4
2101
2102 =item Arguments: none
2103
2104 =item Return Value: 1
2105
2106 =back
2107
2108 Fetches all objects and deletes them one at a time via
2109 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2110 triggers, while L</delete> will not.
2111
2112 =cut
2113
2114 sub delete_all {
2115   my $self = shift;
2116   $self->throw_exception('delete_all does not accept any arguments')
2117     if @_;
2118
2119   my $guard = $self->result_source->schema->txn_scope_guard;
2120   $_->delete for $self->all;
2121   $guard->commit;
2122   return 1;
2123 }
2124
2125 =head2 populate
2126
2127 =over 4
2128
2129 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2130
2131 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2132
2133 =back
2134
2135 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2136 arrayrefs.
2137
2138 =over
2139
2140 =item NOTE
2141
2142 The context of this method call has an important effect on what is
2143 submitted to storage. In void context data is fed directly to fastpath
2144 insertion routines provided by the underlying storage (most often
2145 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2146 L<insert|DBIx::Class::Row/insert> calls on the
2147 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2148 augmentation of these methods provided by components. For example if you
2149 are using something like L<DBIx::Class::UUIDColumns> to create primary
2150 keys for you, you will find that your PKs are empty.  In this case you
2151 will have to explicitly force scalar or list context in order to create
2152 those values.
2153
2154 =back
2155
2156 In non-void (scalar or list) context, this method is simply a wrapper
2157 for L</create>. Depending on list or scalar context either a list of
2158 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2159 containing these objects is returned.
2160
2161 When supplying data in "arrayref of arrayrefs" invocation style, the
2162 first element should be a list of column names and each subsequent
2163 element should be a data value in the earlier specified column order.
2164 For example:
2165
2166   $schema->resultset("Artist")->populate([
2167     [ qw( artistid name ) ],
2168     [ 100, 'A Formally Unknown Singer' ],
2169     [ 101, 'A singer that jumped the shark two albums ago' ],
2170     [ 102, 'An actually cool singer' ],
2171   ]);
2172
2173 For the arrayref of hashrefs style each hashref should be a structure
2174 suitable for passing to L</create>. Multi-create is also permitted with
2175 this syntax.
2176
2177   $schema->resultset("Artist")->populate([
2178      { artistid => 4, name => 'Manufactured Crap', cds => [
2179         { title => 'My First CD', year => 2006 },
2180         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2181       ],
2182      },
2183      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2184         { title => 'My parents sold me to a record company', year => 2005 },
2185         { title => 'Why Am I So Ugly?', year => 2006 },
2186         { title => 'I Got Surgery and am now Popular', year => 2007 }
2187       ],
2188      },
2189   ]);
2190
2191 If you attempt a void-context multi-create as in the example above (each
2192 Artist also has the related list of CDs), and B<do not> supply the
2193 necessary autoinc foreign key information, this method will proxy to the
2194 less efficient L</create>, and then throw the Result objects away. In this
2195 case there are obviously no benefits to using this method over L</create>.
2196
2197 =cut
2198
2199 sub populate {
2200   my $self = shift;
2201
2202   # this is naive and just a quick check
2203   # the types will need to be checked more thoroughly when the
2204   # multi-source populate gets added
2205   my $data = (
2206     ref $_[0] eq 'ARRAY'
2207       and
2208     ( @{$_[0]} or return )
2209       and
2210     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2211       and
2212     $_[0]
2213   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2214
2215   # FIXME - no cref handling
2216   # At this point assume either hashes or arrays
2217
2218   my $rsrc = $self->result_source;
2219
2220   if(defined wantarray) {
2221     my (@results, $guard);
2222
2223     if (ref $data->[0] eq 'ARRAY') {
2224       # column names only, nothing to do
2225       return if @$data == 1;
2226
2227       $guard = $rsrc->schema->storage->txn_scope_guard
2228         if @$data > 2;
2229
2230       @results = map
2231         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2232         @{$data}[1 .. $#$data]
2233       ;
2234     }
2235     else {
2236
2237       $guard = $rsrc->schema->storage->txn_scope_guard
2238         if @$data > 1;
2239
2240       @results = map { $self->new_result($_)->insert } @$data;
2241     }
2242
2243     $guard->commit if $guard;
2244     return wantarray ? @results : \@results;
2245   }
2246
2247   # we have to deal with *possibly incomplete* related data
2248   # this means we have to walk the data structure twice
2249   # whether we want this or not
2250   # jnap, I hate you ;)
2251   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2252
2253   my ($colinfo, $colnames, $slices_with_rels);
2254   my $data_start = 0;
2255
2256   DATA_SLICE:
2257   for my $i (0 .. $#$data) {
2258
2259     my $current_slice_seen_rel_infos;
2260
2261 ### Determine/Supplement collists
2262 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2263     if( ref $data->[$i] eq 'ARRAY' ) {
2264
2265       # positional(!) explicit column list
2266       if ($i == 0) {
2267         # column names only, nothing to do
2268         return if @$data == 1;
2269
2270         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2271           for 0 .. $#{$data->[0]};
2272
2273         $data_start = 1;
2274
2275         next DATA_SLICE;
2276       }
2277       else {
2278         for (values %$colinfo) {
2279           if ($_->{is_rel} ||= (
2280             $rel_info->{$_->{name}}
2281               and
2282             (
2283               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2284                 or
2285               ref $data->[$i][$_->{pos}] eq 'HASH'
2286                 or
2287               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2288             )
2289               and
2290             1
2291           )) {
2292
2293             # moar sanity check... sigh
2294             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2295               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2296                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2297                 return my $throwaway = $self->populate(@_);
2298               }
2299             }
2300
2301             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2302           }
2303         }
2304       }
2305
2306      if ($current_slice_seen_rel_infos) {
2307         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2308
2309         # this is needed further down to decide whether or not to fallback to create()
2310         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2311           for 0 .. $#$colnames;
2312       }
2313     }
2314     elsif( ref $data->[$i] eq 'HASH' ) {
2315
2316       for ( sort keys %{$data->[$i]} ) {
2317
2318         $colinfo->{$_} ||= do {
2319
2320           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2321             if $data_start; # it will be 0 on AoH, 1 on AoA
2322
2323           push @$colnames, $_;
2324
2325           # RV
2326           { pos => $#$colnames, name => $_ }
2327         };
2328
2329         if ($colinfo->{$_}{is_rel} ||= (
2330           $rel_info->{$_}
2331             and
2332           (
2333             ref $data->[$i]{$_} eq 'ARRAY'
2334               or
2335             ref $data->[$i]{$_} eq 'HASH'
2336               or
2337             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2338           )
2339             and
2340           1
2341         )) {
2342
2343           # moar sanity check... sigh
2344           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2345             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2346               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2347               return my $throwaway = $self->populate(@_);
2348             }
2349           }
2350
2351           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2352         }
2353       }
2354
2355       if ($current_slice_seen_rel_infos) {
2356         push @$slices_with_rels, $data->[$i];
2357
2358         # this is needed further down to decide whether or not to fallback to create()
2359         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2360           for keys %{$data->[$i]};
2361       }
2362     }
2363     else {
2364       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2365     }
2366
2367     if ( grep
2368       { $_->{attrs}{is_depends_on} }
2369       @{ $current_slice_seen_rel_infos || [] }
2370     ) {
2371       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2372       return my $throwaway = $self->populate(@_);
2373     }
2374   }
2375
2376   if( $slices_with_rels ) {
2377
2378     # need to exclude the rel "columns"
2379     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2380
2381     # extra sanity check - ensure the main source is in fact identifiable
2382     # the localizing of nullability is insane, but oh well... the use-case is legit
2383     my $ci = $rsrc->columns_info($colnames);
2384
2385     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2386       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2387
2388     unless( $rsrc->_identifying_column_set($ci) ) {
2389       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2390       return my $throwaway = $self->populate(@_);
2391     }
2392   }
2393
2394 ### inherit the data locked in the conditions of the resultset
2395   my ($rs_data) = $self->_merge_with_rscond({});
2396   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2397
2398   # if anything left - decompose rs_data
2399   my $rs_data_vals;
2400   if (keys %$rs_data) {
2401      push @$rs_data_vals, $rs_data->{$_}
2402       for sort keys %$rs_data;
2403   }
2404
2405 ### start work
2406   my $guard;
2407   $guard = $rsrc->schema->storage->txn_scope_guard
2408     if $slices_with_rels;
2409
2410 ### main source data
2411   # FIXME - need to switch entirely to a coderef-based thing,
2412   # so that large sets aren't copied several times... I think
2413   $rsrc->storage->_insert_bulk(
2414     $rsrc,
2415     [ @$colnames, sort keys %$rs_data ],
2416     [ map {
2417       ref $data->[$_] eq 'ARRAY'
2418       ? (
2419           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2420         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2421         :                     $data->[$_]
2422       )
2423       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2424     } $data_start .. $#$data ],
2425   );
2426
2427 ### do the children relationships
2428   if ( $slices_with_rels ) {
2429     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2430       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2431
2432     for my $sl (@$slices_with_rels) {
2433
2434       my ($main_proto, $main_proto_rs);
2435       for my $rel (@rels) {
2436         next unless defined $sl->{$rel};
2437
2438         $main_proto ||= {
2439           %$rs_data,
2440           (map { $_ => $sl->{$_} } @$colnames),
2441         };
2442
2443         unless (defined $colinfo->{$rel}{rs}) {
2444
2445           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2446
2447           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2448             rel_name => $rel,
2449             self_alias => "\xFE", # irrelevant
2450             foreign_alias => "\xFF", # irrelevant
2451           )->{identity_map} || {} } };
2452
2453         }
2454
2455         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2456           {
2457             $_ => { '=' =>
2458               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2459                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2460                  ->as_query
2461             }
2462           }
2463           keys %{$colinfo->{$rel}{fk_map}}
2464         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2465
2466         1;
2467       }
2468     }
2469   }
2470
2471   $guard->commit if $guard;
2472 }
2473
2474 =head2 pager
2475
2476 =over 4
2477
2478 =item Arguments: none
2479
2480 =item Return Value: L<$pager|Data::Page>
2481
2482 =back
2483
2484 Returns a L<Data::Page> object for the current resultset. Only makes
2485 sense for queries with a C<page> attribute.
2486
2487 To get the full count of entries for a paged resultset, call
2488 C<total_entries> on the L<Data::Page> object.
2489
2490 =cut
2491
2492 sub pager {
2493   my ($self) = @_;
2494
2495   return $self->{pager} if $self->{pager};
2496
2497   my $attrs = $self->{attrs};
2498   if (!defined $attrs->{page}) {
2499     $self->throw_exception("Can't create pager for non-paged rs");
2500   }
2501   elsif ($attrs->{page} <= 0) {
2502     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2503   }
2504   $attrs->{rows} ||= 10;
2505
2506   # throw away the paging flags and re-run the count (possibly
2507   # with a subselect) to get the real total count
2508   my $count_attrs = { %$attrs };
2509   delete @{$count_attrs}{qw/rows offset page pager/};
2510
2511   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2512
2513   require DBIx::Class::ResultSet::Pager;
2514   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2515     sub { $total_rs->count },  #lazy-get the total
2516     $attrs->{rows},
2517     $self->{attrs}{page},
2518   );
2519 }
2520
2521 =head2 page
2522
2523 =over 4
2524
2525 =item Arguments: $page_number
2526
2527 =item Return Value: L<$resultset|/search>
2528
2529 =back
2530
2531 Returns a resultset for the $page_number page of the resultset on which page
2532 is called, where each page contains a number of rows equal to the 'rows'
2533 attribute set on the resultset (10 by default).
2534
2535 =cut
2536
2537 sub page {
2538   my ($self, $page) = @_;
2539   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2540 }
2541
2542 =head2 new_result
2543
2544 =over 4
2545
2546 =item Arguments: \%col_data
2547
2548 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2549
2550 =back
2551
2552 Creates a new result object in the resultset's result class and returns
2553 it. The row is not inserted into the database at this point, call
2554 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2555 will tell you whether the result object has been inserted or not.
2556
2557 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2558
2559 =cut
2560
2561 sub new_result {
2562   my ($self, $values) = @_;
2563
2564   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2565     if @_ > 2;
2566
2567   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2568     unless (ref $values eq 'HASH');
2569
2570   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2571
2572   my $new = $self->result_class->new({
2573     %$merged_cond,
2574     ( @$cols_from_relations
2575       ? (-cols_from_relations => $cols_from_relations)
2576       : ()
2577     ),
2578     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2579   });
2580
2581   if (
2582     reftype($new) eq 'HASH'
2583       and
2584     ! keys %$new
2585       and
2586     blessed($new)
2587   ) {
2588     carp_unique (sprintf (
2589       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2590       $self->result_class,
2591     ));
2592   }
2593
2594   $new;
2595 }
2596
2597 # _merge_with_rscond
2598 #
2599 # Takes a simple hash of K/V data and returns its copy merged with the
2600 # condition already present on the resultset. Additionally returns an
2601 # arrayref of value/condition names, which were inferred from related
2602 # objects (this is needed for in-memory related objects)
2603 sub _merge_with_rscond {
2604   my ($self, $data) = @_;
2605
2606   my ($implied_data, @cols_from_relations);
2607
2608   my $alias = $self->{attrs}{alias};
2609
2610   if (! defined $self->{cond}) {
2611     # just massage $data below
2612   }
2613   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2614     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2615     @cols_from_relations = keys %{ $implied_data || {} };
2616   }
2617   else {
2618     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2619     $implied_data = { map {
2620       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2621     } keys %$eqs };
2622   }
2623
2624   return (
2625     { map
2626       { %{ $self->_remove_alias($_, $alias) } }
2627       # precedence must be given to passed values over values inherited from
2628       # the cond, so the order here is important.
2629       ( $implied_data||(), $data)
2630     },
2631     \@cols_from_relations
2632   );
2633 }
2634
2635 # _has_resolved_attr
2636 #
2637 # determines if the resultset defines at least one
2638 # of the attributes supplied
2639 #
2640 # used to determine if a subquery is necessary
2641 #
2642 # supports some virtual attributes:
2643 #   -join
2644 #     This will scan for any joins being present on the resultset.
2645 #     It is not a mere key-search but a deep inspection of {from}
2646 #
2647
2648 sub _has_resolved_attr {
2649   my ($self, @attr_names) = @_;
2650
2651   my $attrs = $self->_resolved_attrs;
2652
2653   my %extra_checks;
2654
2655   for my $n (@attr_names) {
2656     if (grep { $n eq $_ } (qw/-join/) ) {
2657       $extra_checks{$n}++;
2658       next;
2659     }
2660
2661     my $attr =  $attrs->{$n};
2662
2663     next if not defined $attr;
2664
2665     if (ref $attr eq 'HASH') {
2666       return 1 if keys %$attr;
2667     }
2668     elsif (ref $attr eq 'ARRAY') {
2669       return 1 if @$attr;
2670     }
2671     else {
2672       return 1 if $attr;
2673     }
2674   }
2675
2676   # a resolved join is expressed as a multi-level from
2677   return 1 if (
2678     $extra_checks{-join}
2679       and
2680     ref $attrs->{from} eq 'ARRAY'
2681       and
2682     @{$attrs->{from}} > 1
2683   );
2684
2685   return 0;
2686 }
2687
2688 # _remove_alias
2689 #
2690 # Remove the specified alias from the specified query hash. A copy is made so
2691 # the original query is not modified.
2692
2693 sub _remove_alias {
2694   my ($self, $query, $alias) = @_;
2695
2696   my %orig = %{ $query || {} };
2697   my %unaliased;
2698
2699   foreach my $key (keys %orig) {
2700     if ($key !~ /\./) {
2701       $unaliased{$key} = $orig{$key};
2702       next;
2703     }
2704     $unaliased{$1} = $orig{$key}
2705       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2706   }
2707
2708   return \%unaliased;
2709 }
2710
2711 =head2 as_query
2712
2713 =over 4
2714
2715 =item Arguments: none
2716
2717 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2718
2719 =back
2720
2721 Returns the SQL query and bind vars associated with the invocant.
2722
2723 This is generally used as the RHS for a subquery.
2724
2725 =cut
2726
2727 sub as_query {
2728   my $self = shift;
2729
2730   my $attrs = { %{ $self->_resolved_attrs } };
2731
2732   my $aq = $self->result_source->storage->_select_args_to_query (
2733     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2734   );
2735
2736   $aq;
2737 }
2738
2739 =head2 find_or_new
2740
2741 =over 4
2742
2743 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2744
2745 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2746
2747 =back
2748
2749   my $artist = $schema->resultset('Artist')->find_or_new(
2750     { artist => 'fred' }, { key => 'artists' });
2751
2752   $cd->cd_to_producer->find_or_new({ producer => $producer },
2753                                    { key => 'primary' });
2754
2755 Find an existing record from this resultset using L</find>. if none exists,
2756 instantiate a new result object and return it. The object will not be saved
2757 into your storage until you call L<DBIx::Class::Row/insert> on it.
2758
2759 You most likely want this method when looking for existing rows using a unique
2760 constraint that is not the primary key, or looking for related rows.
2761
2762 If you want objects to be saved immediately, use L</find_or_create> instead.
2763
2764 B<Note>: Make sure to read the documentation of L</find> and understand the
2765 significance of the C<key> attribute, as its lack may skew your search, and
2766 subsequently result in spurious new objects.
2767
2768 B<Note>: Take care when using C<find_or_new> with a table having
2769 columns with default values that you intend to be automatically
2770 supplied by the database (e.g. an auto_increment primary key column).
2771 In normal usage, the value of such columns should NOT be included at
2772 all in the call to C<find_or_new>, even when set to C<undef>.
2773
2774 =cut
2775
2776 sub find_or_new {
2777   my $self     = shift;
2778   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2779   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2780   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2781     return $row;
2782   }
2783   return $self->new_result($hash);
2784 }
2785
2786 =head2 create
2787
2788 =over 4
2789
2790 =item Arguments: \%col_data
2791
2792 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2793
2794 =back
2795
2796 Attempt to create a single new row or a row with multiple related rows
2797 in the table represented by the resultset (and related tables). This
2798 will not check for duplicate rows before inserting, use
2799 L</find_or_create> to do that.
2800
2801 To create one row for this resultset, pass a hashref of key/value
2802 pairs representing the columns of the table and the values you wish to
2803 store. If the appropriate relationships are set up, foreign key fields
2804 can also be passed an object representing the foreign row, and the
2805 value will be set to its primary key.
2806
2807 To create related objects, pass a hashref of related-object column values
2808 B<keyed on the relationship name>. If the relationship is of type C<multi>
2809 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2810 The process will correctly identify columns holding foreign keys, and will
2811 transparently populate them from the keys of the corresponding relation.
2812 This can be applied recursively, and will work correctly for a structure
2813 with an arbitrary depth and width, as long as the relationships actually
2814 exists and the correct column data has been supplied.
2815
2816 Instead of hashrefs of plain related data (key/value pairs), you may
2817 also pass new or inserted objects. New objects (not inserted yet, see
2818 L</new_result>), will be inserted into their appropriate tables.
2819
2820 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2821
2822 Example of creating a new row.
2823
2824   $person_rs->create({
2825     name=>"Some Person",
2826     email=>"somebody@someplace.com"
2827   });
2828
2829 Example of creating a new row and also creating rows in a related C<has_many>
2830 or C<has_one> resultset.  Note Arrayref.
2831
2832   $artist_rs->create(
2833      { artistid => 4, name => 'Manufactured Crap', cds => [
2834         { title => 'My First CD', year => 2006 },
2835         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2836       ],
2837      },
2838   );
2839
2840 Example of creating a new row and also creating a row in a related
2841 C<belongs_to> resultset. Note Hashref.
2842
2843   $cd_rs->create({
2844     title=>"Music for Silly Walks",
2845     year=>2000,
2846     artist => {
2847       name=>"Silly Musician",
2848     }
2849   });
2850
2851 =over
2852
2853 =item WARNING
2854
2855 When subclassing ResultSet never attempt to override this method. Since
2856 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2857 lot of the internals simply never call it, so your override will be
2858 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2859 or L<DBIx::Class::Row/insert> depending on how early in the
2860 L</create> process you need to intervene. See also warning pertaining to
2861 L</new>.
2862
2863 =back
2864
2865 =cut
2866
2867 sub create {
2868   #my ($self, $col_data) = @_;
2869   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2870   return shift->new_result(shift)->insert;
2871 }
2872
2873 =head2 find_or_create
2874
2875 =over 4
2876
2877 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2878
2879 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2880
2881 =back
2882
2883   $cd->cd_to_producer->find_or_create({ producer => $producer },
2884                                       { key => 'primary' });
2885
2886 Tries to find a record based on its primary key or unique constraints; if none
2887 is found, creates one and returns that instead.
2888
2889   my $cd = $schema->resultset('CD')->find_or_create({
2890     cdid   => 5,
2891     artist => 'Massive Attack',
2892     title  => 'Mezzanine',
2893     year   => 2005,
2894   });
2895
2896 Also takes an optional C<key> attribute, to search by a specific key or unique
2897 constraint. For example:
2898
2899   my $cd = $schema->resultset('CD')->find_or_create(
2900     {
2901       artist => 'Massive Attack',
2902       title  => 'Mezzanine',
2903     },
2904     { key => 'cd_artist_title' }
2905   );
2906
2907 B<Note>: Make sure to read the documentation of L</find> and understand the
2908 significance of the C<key> attribute, as its lack may skew your search, and
2909 subsequently result in spurious row creation.
2910
2911 B<Note>: Because find_or_create() reads from the database and then
2912 possibly inserts based on the result, this method is subject to a race
2913 condition. Another process could create a record in the table after
2914 the find has completed and before the create has started. To avoid
2915 this problem, use find_or_create() inside a transaction.
2916
2917 B<Note>: Take care when using C<find_or_create> with a table having
2918 columns with default values that you intend to be automatically
2919 supplied by the database (e.g. an auto_increment primary key column).
2920 In normal usage, the value of such columns should NOT be included at
2921 all in the call to C<find_or_create>, even when set to C<undef>.
2922
2923 See also L</find> and L</update_or_create>. For information on how to declare
2924 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2925
2926 If you need to know if an existing row was found or a new one created use
2927 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2928 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2929 database!
2930
2931   my $cd = $schema->resultset('CD')->find_or_new({
2932     cdid   => 5,
2933     artist => 'Massive Attack',
2934     title  => 'Mezzanine',
2935     year   => 2005,
2936   });
2937
2938   if( !$cd->in_storage ) {
2939       # do some stuff
2940       $cd->insert;
2941   }
2942
2943 =cut
2944
2945 sub find_or_create {
2946   my $self     = shift;
2947   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2948   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2949   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2950     return $row;
2951   }
2952   return $self->new_result($hash)->insert;
2953 }
2954
2955 =head2 update_or_create
2956
2957 =over 4
2958
2959 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2960
2961 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2962
2963 =back
2964
2965   $resultset->update_or_create({ col => $val, ... });
2966
2967 Like L</find_or_create>, but if a row is found it is immediately updated via
2968 C<< $found_row->update (\%col_data) >>.
2969
2970
2971 Takes an optional C<key> attribute to search on a specific unique constraint.
2972 For example:
2973
2974   # In your application
2975   my $cd = $schema->resultset('CD')->update_or_create(
2976     {
2977       artist => 'Massive Attack',
2978       title  => 'Mezzanine',
2979       year   => 1998,
2980     },
2981     { key => 'cd_artist_title' }
2982   );
2983
2984   $cd->cd_to_producer->update_or_create({
2985     producer => $producer,
2986     name => 'harry',
2987   }, {
2988     key => 'primary',
2989   });
2990
2991 B<Note>: Make sure to read the documentation of L</find> and understand the
2992 significance of the C<key> attribute, as its lack may skew your search, and
2993 subsequently result in spurious row creation.
2994
2995 B<Note>: Take care when using C<update_or_create> with a table having
2996 columns with default values that you intend to be automatically
2997 supplied by the database (e.g. an auto_increment primary key column).
2998 In normal usage, the value of such columns should NOT be included at
2999 all in the call to C<update_or_create>, even when set to C<undef>.
3000
3001 See also L</find> and L</find_or_create>. For information on how to declare
3002 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3003
3004 If you need to know if an existing row was updated or a new one created use
3005 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3006 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3007 database!
3008
3009 =cut
3010
3011 sub update_or_create {
3012   my $self = shift;
3013   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3014   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3015
3016   my $row = $self->find($cond, $attrs);
3017   if (defined $row) {
3018     $row->update($cond);
3019     return $row;
3020   }
3021
3022   return $self->new_result($cond)->insert;
3023 }
3024
3025 =head2 update_or_new
3026
3027 =over 4
3028
3029 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3030
3031 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3032
3033 =back
3034
3035   $resultset->update_or_new({ col => $val, ... });
3036
3037 Like L</find_or_new> but if a row is found it is immediately updated via
3038 C<< $found_row->update (\%col_data) >>.
3039
3040 For example:
3041
3042   # In your application
3043   my $cd = $schema->resultset('CD')->update_or_new(
3044     {
3045       artist => 'Massive Attack',
3046       title  => 'Mezzanine',
3047       year   => 1998,
3048     },
3049     { key => 'cd_artist_title' }
3050   );
3051
3052   if ($cd->in_storage) {
3053       # the cd was updated
3054   }
3055   else {
3056       # the cd is not yet in the database, let's insert it
3057       $cd->insert;
3058   }
3059
3060 B<Note>: Make sure to read the documentation of L</find> and understand the
3061 significance of the C<key> attribute, as its lack may skew your search, and
3062 subsequently result in spurious new objects.
3063
3064 B<Note>: Take care when using C<update_or_new> with a table having
3065 columns with default values that you intend to be automatically
3066 supplied by the database (e.g. an auto_increment primary key column).
3067 In normal usage, the value of such columns should NOT be included at
3068 all in the call to C<update_or_new>, even when set to C<undef>.
3069
3070 See also L</find>, L</find_or_create> and L</find_or_new>.
3071
3072 =cut
3073
3074 sub update_or_new {
3075     my $self  = shift;
3076     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3077     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3078
3079     my $row = $self->find( $cond, $attrs );
3080     if ( defined $row ) {
3081         $row->update($cond);
3082         return $row;
3083     }
3084
3085     return $self->new_result($cond);
3086 }
3087
3088 =head2 get_cache
3089
3090 =over 4
3091
3092 =item Arguments: none
3093
3094 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3095
3096 =back
3097
3098 Gets the contents of the cache for the resultset, if the cache is set.
3099
3100 The cache is populated either by using the L</prefetch> attribute to
3101 L</search> or by calling L</set_cache>.
3102
3103 =cut
3104
3105 sub get_cache {
3106   shift->{all_cache};
3107 }
3108
3109 =head2 set_cache
3110
3111 =over 4
3112
3113 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3114
3115 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3116
3117 =back
3118
3119 Sets the contents of the cache for the resultset. Expects an arrayref
3120 of objects of the same class as those produced by the resultset. Note that
3121 if the cache is set, the resultset will return the cached objects rather
3122 than re-querying the database even if the cache attr is not set.
3123
3124 The contents of the cache can also be populated by using the
3125 L</prefetch> attribute to L</search>.
3126
3127 =cut
3128
3129 sub set_cache {
3130   my ( $self, $data ) = @_;
3131   $self->throw_exception("set_cache requires an arrayref")
3132       if defined($data) && (ref $data ne 'ARRAY');
3133   $self->{all_cache} = $data;
3134 }
3135
3136 =head2 clear_cache
3137
3138 =over 4
3139
3140 =item Arguments: none
3141
3142 =item Return Value: undef
3143
3144 =back
3145
3146 Clears the cache for the resultset.
3147
3148 =cut
3149
3150 sub clear_cache {
3151   shift->set_cache(undef);
3152 }
3153
3154 =head2 is_paged
3155
3156 =over 4
3157
3158 =item Arguments: none
3159
3160 =item Return Value: true, if the resultset has been paginated
3161
3162 =back
3163
3164 =cut
3165
3166 sub is_paged {
3167   my ($self) = @_;
3168   return !!$self->{attrs}{page};
3169 }
3170
3171 =head2 is_ordered
3172
3173 =over 4
3174
3175 =item Arguments: none
3176
3177 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3178
3179 =back
3180
3181 =cut
3182
3183 sub is_ordered {
3184   my ($self) = @_;
3185   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3186 }
3187
3188 =head2 related_resultset
3189
3190 =over 4
3191
3192 =item Arguments: $rel_name
3193
3194 =item Return Value: L<$resultset|/search>
3195
3196 =back
3197
3198 Returns a related resultset for the supplied relationship name.
3199
3200   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3201
3202 =cut
3203
3204 sub related_resultset {
3205   $_[0]->throw_exception(
3206     'Extra arguments to $rs->related_resultset() were always quietly '
3207   . 'discarded without consideration, you need to switch to '
3208   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3209   ) if @_ > 2;
3210
3211   return $_[0]->{related_resultsets}{$_[1]}
3212     if defined $_[0]->{related_resultsets}{$_[1]};
3213
3214   my ($self, $rel) = @_;
3215
3216   return $self->{related_resultsets}{$rel} = do {
3217     my $rsrc = $self->result_source;
3218     my $rel_info = $rsrc->relationship_info($rel);
3219
3220     $self->throw_exception(
3221       "search_related: result source '" . $rsrc->source_name .
3222         "' has no such relationship $rel")
3223       unless $rel_info;
3224
3225     my $attrs = $self->_chain_relationship($rel);
3226
3227     my $storage = $rsrc->schema->storage;
3228
3229     # Previously this atribute was deleted (instead of being set as it is now)
3230     # Doing so seems to be harmless in all available test permutations
3231     # See also 01d59a6a6 and mst's comment below
3232     #
3233     $attrs->{alias} = $storage->relname_to_table_alias(
3234       $rel,
3235       $attrs->{seen_join}{$rel}
3236     );
3237
3238     # since this is search_related, and we already slid the select window inwards
3239     # (the select/as attrs were deleted in the beginning), we need to flip all
3240     # left joins to inner, so we get the expected results
3241     # read the comment on top of the actual function to see what this does
3242     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3243
3244     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3245     delete $attrs->{result_class};
3246
3247     my $new = do {
3248
3249       # The reason we do this now instead of passing the alias to the
3250       # search_rs below is that if you wrap/overload resultset on the
3251       # source you need to know what alias it's -going- to have for things
3252       # to work sanely (e.g. RestrictWithObject wants to be able to add
3253       # extra query restrictions, and these may need to be $alias.)
3254       #                                       -- mst ~ 2007 (01d59a6a6)
3255       #
3256       # FIXME - this seems to be no longer neccessary (perhaps due to the
3257       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3258       # dependent (as of Jun 2015 ) does not yield any difference with or
3259       # without this line. Nevertheless keep it as is for now, to minimize
3260       # churn, there is enough potential for breakage in 0.0829xx as it is
3261       #                                       -- ribasushi Jun 2015
3262       #
3263       my $rel_source = $rsrc->related_source($rel);
3264       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3265
3266       $rel_source->resultset->search_rs( undef, $attrs );
3267     };
3268
3269     if (my $cache = $self->get_cache) {
3270       my @related_cache = map
3271         { $_->related_resultset($rel)->get_cache || () }
3272         @$cache
3273       ;
3274
3275       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3276     }
3277
3278     $new;
3279   };
3280 }
3281
3282 =head2 current_source_alias
3283
3284 =over 4
3285
3286 =item Arguments: none
3287
3288 =item Return Value: $source_alias
3289
3290 =back
3291
3292 Returns the current table alias for the result source this resultset is built
3293 on, that will be used in the SQL query. Usually it is C<me>.
3294
3295 Currently the source alias that refers to the result set returned by a
3296 L</search>/L</find> family method depends on how you got to the resultset: it's
3297 C<me> by default, but eg. L</search_related> aliases it to the related result
3298 source name (and keeps C<me> referring to the original result set). The long
3299 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3300 (and make this method unnecessary).
3301
3302 Thus it's currently necessary to use this method in predefined queries (see
3303 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3304 source alias of the current result set:
3305
3306   # in a result set class
3307   sub modified_by {
3308     my ($self, $user) = @_;
3309
3310     my $me = $self->current_source_alias;
3311
3312     return $self->search({
3313       "$me.modified" => $user->id,
3314     });
3315   }
3316
3317 The alias of L<newly created resultsets|/search> can be altered by the
3318 L<alias attribute|/alias>.
3319
3320 =cut
3321
3322 sub current_source_alias {
3323   return (shift->{attrs} || {})->{alias} || 'me';
3324 }
3325
3326 =head2 as_subselect_rs
3327
3328 =over 4
3329
3330 =item Arguments: none
3331
3332 =item Return Value: L<$resultset|/search>
3333
3334 =back
3335
3336 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3337 "virtual view" by including it as a subquery within the from clause.  From this
3338 point on, any joined tables are inaccessible to ->search on the resultset (as if
3339 it were simply where-filtered without joins).  For example:
3340
3341  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3342
3343  # 'x' now pollutes the query namespace
3344
3345  # So the following works as expected
3346  my $ok_rs = $rs->search({'x.other' => 1});
3347
3348  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3349  # def) we look for one row with contradictory terms and join in another table
3350  # (aliased 'x_2') which we never use
3351  my $broken_rs = $rs->search({'x.name' => 'def'});
3352
3353  my $rs2 = $rs->as_subselect_rs;
3354
3355  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3356  my $not_joined_rs = $rs2->search({'x.other' => 1});
3357
3358  # works as expected: finds a 'table' row related to two x rows (abc and def)
3359  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3360
3361 Another example of when one might use this would be to select a subset of
3362 columns in a group by clause:
3363
3364  my $rs = $schema->resultset('Bar')->search(undef, {
3365    group_by => [qw{ id foo_id baz_id }],
3366  })->as_subselect_rs->search(undef, {
3367    columns => [qw{ id foo_id }]
3368  });
3369
3370 In the above example normally columns would have to be equal to the group by,
3371 but because we isolated the group by into a subselect the above works.
3372
3373 =cut
3374
3375 sub as_subselect_rs {
3376   my $self = shift;
3377
3378   my $attrs = $self->_resolved_attrs;
3379
3380   my $fresh_rs = (ref $self)->new (
3381     $self->result_source
3382   );
3383
3384   # these pieces will be locked in the subquery
3385   delete $fresh_rs->{cond};
3386   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3387
3388   return $fresh_rs->search( {}, {
3389     from => [{
3390       $attrs->{alias} => $self->as_query,
3391       -alias  => $attrs->{alias},
3392       -rsrc   => $self->result_source,
3393     }],
3394     alias => $attrs->{alias},
3395   });
3396 }
3397
3398 # This code is called by search_related, and makes sure there
3399 # is clear separation between the joins before, during, and
3400 # after the relationship. This information is needed later
3401 # in order to properly resolve prefetch aliases (any alias
3402 # with a relation_chain_depth less than the depth of the
3403 # current prefetch is not considered)
3404 #
3405 # The increments happen twice per join. An even number means a
3406 # relationship specified via a search_related, whereas an odd
3407 # number indicates a join/prefetch added via attributes
3408 #
3409 # Also this code will wrap the current resultset (the one we
3410 # chain to) in a subselect IFF it contains limiting attributes
3411 sub _chain_relationship {
3412   my ($self, $rel) = @_;
3413   my $source = $self->result_source;
3414   my $attrs = { %{$self->{attrs}||{}} };
3415
3416   # we need to take the prefetch the attrs into account before we
3417   # ->_resolve_join as otherwise they get lost - captainL
3418   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3419
3420   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3421
3422   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3423
3424   my $from;
3425   my @force_subq_attrs = qw/offset rows group_by having/;
3426
3427   if (
3428     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3429       ||
3430     $self->_has_resolved_attr (@force_subq_attrs)
3431   ) {
3432     # Nuke the prefetch (if any) before the new $rs attrs
3433     # are resolved (prefetch is useless - we are wrapping
3434     # a subquery anyway).
3435     my $rs_copy = $self->search;
3436     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3437       $rs_copy->{attrs}{join},
3438       delete $rs_copy->{attrs}{prefetch},
3439     );
3440
3441     $from = [{
3442       -rsrc   => $source,
3443       -alias  => $attrs->{alias},
3444       $attrs->{alias} => $rs_copy->as_query,
3445     }];
3446     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3447     $seen->{-relation_chain_depth} = 0;
3448   }
3449   elsif ($attrs->{from}) {  #shallow copy suffices
3450     $from = [ @{$attrs->{from}} ];
3451   }
3452   else {
3453     $from = [{
3454       -rsrc  => $source,
3455       -alias => $attrs->{alias},
3456       $attrs->{alias} => $source->from,
3457     }];
3458   }
3459
3460   my $jpath = ($seen->{-relation_chain_depth})
3461     ? $from->[-1][0]{-join_path}
3462     : [];
3463
3464   my @requested_joins = $source->_resolve_join(
3465     $join,
3466     $attrs->{alias},
3467     $seen,
3468     $jpath,
3469   );
3470
3471   push @$from, @requested_joins;
3472
3473   $seen->{-relation_chain_depth}++;
3474
3475   # if $self already had a join/prefetch specified on it, the requested
3476   # $rel might very well be already included. What we do in this case
3477   # is effectively a no-op (except that we bump up the chain_depth on
3478   # the join in question so we could tell it *is* the search_related)
3479   my $already_joined;
3480
3481   # we consider the last one thus reverse
3482   for my $j (reverse @requested_joins) {
3483     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3484     if ($rel eq $last_j) {
3485       $j->[0]{-relation_chain_depth}++;
3486       $already_joined++;
3487       last;
3488     }
3489   }
3490
3491   unless ($already_joined) {
3492     push @$from, $source->_resolve_join(
3493       $rel,
3494       $attrs->{alias},
3495       $seen,
3496       $jpath,
3497     );
3498   }
3499
3500   $seen->{-relation_chain_depth}++;
3501
3502   return {%$attrs, from => $from, seen_join => $seen};
3503 }
3504
3505 sub _resolved_attrs {
3506   my $self = shift;
3507   return $self->{_attrs} if $self->{_attrs};
3508
3509   my $attrs  = { %{ $self->{attrs} || {} } };
3510   my $source = $attrs->{result_source} = $self->result_source;
3511   my $alias  = $attrs->{alias};
3512
3513   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3514     if $attrs->{collapse} and $attrs->{distinct};
3515
3516
3517   # Sanity check the paging attributes
3518   # SQLMaker does it too, but in case of a software_limit we'll never get there
3519   if (defined $attrs->{offset}) {
3520     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3521       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3522   }
3523   if (defined $attrs->{rows}) {
3524     $self->throw_exception("The rows attribute must be a positive integer if present")
3525       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3526   }
3527
3528
3529   # default selection list
3530   $attrs->{columns} = [ $source->columns ]
3531     unless grep { exists $attrs->{$_} } qw/columns cols select as/;
3532
3533   # merge selectors together
3534   for (qw/columns select as/) {
3535     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3536       if $attrs->{$_} or $attrs->{"+$_"};
3537   }
3538
3539   # disassemble columns
3540   my (@sel, @as);
3541   if (my $cols = delete $attrs->{columns}) {
3542     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3543       if (ref $c eq 'HASH') {
3544         for my $as (sort keys %$c) {
3545           push @sel, $c->{$as};
3546           push @as, $as;
3547         }
3548       }
3549       else {
3550         push @sel, $c;
3551         push @as, $c;
3552       }
3553     }
3554   }
3555
3556   # when trying to weed off duplicates later do not go past this point -
3557   # everything added from here on is unbalanced "anyone's guess" stuff
3558   my $dedup_stop_idx = $#as;
3559
3560   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3561     if $attrs->{as};
3562   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3563     if $attrs->{select};
3564
3565   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3566   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3567
3568   # disqualify all $alias.col as-bits (inflate-map mandated)
3569   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3570
3571   # de-duplicate the result (remove *identical* select/as pairs)
3572   # and also die on duplicate {as} pointing to different {select}s
3573   # not using a c-style for as the condition is prone to shrinkage
3574   my $seen;
3575   my $i = 0;
3576   while ($i <= $dedup_stop_idx) {
3577     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3578       splice @sel, $i, 1;
3579       splice @as, $i, 1;
3580       $dedup_stop_idx--;
3581     }
3582     elsif ($seen->{$as[$i]}++) {
3583       $self->throw_exception(
3584         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3585       );
3586     }
3587     else {
3588       $i++;
3589     }
3590   }
3591
3592   $attrs->{select} = \@sel;
3593   $attrs->{as} = \@as;
3594
3595   $attrs->{from} ||= [{
3596     -rsrc   => $source,
3597     -alias  => $self->{attrs}{alias},
3598     $self->{attrs}{alias} => $source->from,
3599   }];
3600
3601   if ( $attrs->{join} || $attrs->{prefetch} ) {
3602
3603     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3604       if ref $attrs->{from} ne 'ARRAY';
3605
3606     my $join = (delete $attrs->{join}) || {};
3607
3608     if ( defined $attrs->{prefetch} ) {
3609       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3610     }
3611
3612     $attrs->{from} =    # have to copy here to avoid corrupting the original
3613       [
3614         @{ $attrs->{from} },
3615         $source->_resolve_join(
3616           $join,
3617           $alias,
3618           { %{ $attrs->{seen_join} || {} } },
3619           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3620             ? $attrs->{from}[-1][0]{-join_path}
3621             : []
3622           ,
3623         )
3624       ];
3625   }
3626
3627
3628   for my $attr (qw(order_by group_by)) {
3629
3630     if ( defined $attrs->{$attr} ) {
3631       $attrs->{$attr} = (
3632         ref( $attrs->{$attr} ) eq 'ARRAY'
3633         ? [ @{ $attrs->{$attr} } ]
3634         : [ $attrs->{$attr} || () ]
3635       );
3636
3637       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3638     }
3639   }
3640
3641
3642   # set collapse default based on presence of prefetch
3643   my $prefetch;
3644   if (
3645     defined $attrs->{prefetch}
3646       and
3647     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3648   ) {
3649     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3650       if defined $attrs->{collapse} and ! $attrs->{collapse};
3651
3652     $attrs->{collapse} = 1;
3653   }
3654
3655
3656   # run through the resulting joinstructure (starting from our current slot)
3657   # and unset collapse if proven unnecessary
3658   #
3659   # also while we are at it find out if the current root source has
3660   # been premultiplied by previous related_source chaining
3661   #
3662   # this allows to predict whether a root object with all other relation
3663   # data set to NULL is in fact unique
3664   if ($attrs->{collapse}) {
3665
3666     if (ref $attrs->{from} eq 'ARRAY') {
3667
3668       if (@{$attrs->{from}} == 1) {
3669         # no joins - no collapse
3670         $attrs->{collapse} = 0;
3671       }
3672       else {
3673         # find where our table-spec starts
3674         my @fromlist = @{$attrs->{from}};
3675         while (@fromlist) {
3676           my $t = shift @fromlist;
3677
3678           my $is_multi;
3679           # me vs join from-spec distinction - a ref means non-root
3680           if (ref $t eq 'ARRAY') {
3681             $t = $t->[0];
3682             $is_multi ||= ! $t->{-is_single};
3683           }
3684           last if ($t->{-alias} && $t->{-alias} eq $alias);
3685           $attrs->{_main_source_premultiplied} ||= $is_multi;
3686         }
3687
3688         # no non-singles remaining, nor any premultiplication - nothing to collapse
3689         if (
3690           ! $attrs->{_main_source_premultiplied}
3691             and
3692           ! grep { ! $_->[0]{-is_single} } @fromlist
3693         ) {
3694           $attrs->{collapse} = 0;
3695         }
3696       }
3697     }
3698
3699     else {
3700       # if we can not analyze the from - err on the side of safety
3701       $attrs->{_main_source_premultiplied} = 1;
3702     }
3703   }
3704
3705
3706   # generate the distinct induced group_by before injecting the prefetched select/as parts
3707   if (delete $attrs->{distinct}) {
3708     if ($attrs->{group_by}) {
3709       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3710     }
3711     else {
3712       $attrs->{_grouped_by_distinct} = 1;
3713       # distinct affects only the main selection part, not what prefetch may add below
3714       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3715
3716       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3717       # The thinking is: if we are collapsing the subquerying prefetch engine will
3718       # rip stuff apart for us anyway, and we do not want to have a potentially
3719       # function-converted external order_by
3720       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3721       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3722     }
3723   }
3724
3725
3726   # generate selections based on the prefetch helper
3727   if ($prefetch) {
3728
3729     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3730       if $attrs->{_dark_selector};
3731
3732     # this is a separate structure (we don't look in {from} directly)
3733     # as the resolver needs to shift things off the lists to work
3734     # properly (identical-prefetches on different branches)
3735     my $joined_node_aliases_map = {};
3736     if (ref $attrs->{from} eq 'ARRAY') {
3737
3738       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3739
3740       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3741         next unless $j->[0]{-alias};
3742         next unless $j->[0]{-join_path};
3743         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3744
3745         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3746
3747         my $p = $joined_node_aliases_map;
3748         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3749         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3750       }
3751     }
3752
3753     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3754       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3755   }
3756
3757
3758   $attrs->{_simple_passthrough_construction} = !(
3759     $attrs->{collapse}
3760       or
3761     grep { $_ =~ /\./ } @{$attrs->{as}}
3762   );
3763
3764
3765   # if both page and offset are specified, produce a combined offset
3766   # even though it doesn't make much sense, this is what pre 081xx has
3767   # been doing
3768   if (my $page = delete $attrs->{page}) {
3769     $attrs->{offset} =
3770       ($attrs->{rows} * ($page - 1))
3771             +
3772       ($attrs->{offset} || 0)
3773     ;
3774   }
3775
3776   return $self->{_attrs} = $attrs;
3777 }
3778
3779 sub _rollout_attr {
3780   my ($self, $attr) = @_;
3781
3782   if (ref $attr eq 'HASH') {
3783     return $self->_rollout_hash($attr);
3784   } elsif (ref $attr eq 'ARRAY') {
3785     return $self->_rollout_array($attr);
3786   } else {
3787     return [$attr];
3788   }
3789 }
3790
3791 sub _rollout_array {
3792   my ($self, $attr) = @_;
3793
3794   my @rolled_array;
3795   foreach my $element (@{$attr}) {
3796     if (ref $element eq 'HASH') {
3797       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3798     } elsif (ref $element eq 'ARRAY') {
3799       #  XXX - should probably recurse here
3800       push( @rolled_array, @{$self->_rollout_array($element)} );
3801     } else {
3802       push( @rolled_array, $element );
3803     }
3804   }
3805   return \@rolled_array;
3806 }
3807
3808 sub _rollout_hash {
3809   my ($self, $attr) = @_;
3810
3811   my @rolled_array;
3812   foreach my $key (keys %{$attr}) {
3813     push( @rolled_array, { $key => $attr->{$key} } );
3814   }
3815   return \@rolled_array;
3816 }
3817
3818 sub _calculate_score {
3819   my ($self, $a, $b) = @_;
3820
3821   if (defined $a xor defined $b) {
3822     return 0;
3823   }
3824   elsif (not defined $a) {
3825     return 1;
3826   }
3827
3828   if (ref $b eq 'HASH') {
3829     my ($b_key) = keys %{$b};
3830     $b_key = '' if ! defined $b_key;
3831     if (ref $a eq 'HASH') {
3832       my ($a_key) = keys %{$a};
3833       $a_key = '' if ! defined $a_key;
3834       if ($a_key eq $b_key) {
3835         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3836       } else {
3837         return 0;
3838       }
3839     } else {
3840       return ($a eq $b_key) ? 1 : 0;
3841     }
3842   } else {
3843     if (ref $a eq 'HASH') {
3844       my ($a_key) = keys %{$a};
3845       return ($b eq $a_key) ? 1 : 0;
3846     } else {
3847       return ($b eq $a) ? 1 : 0;
3848     }
3849   }
3850 }
3851
3852 sub _merge_joinpref_attr {
3853   my ($self, $orig, $import) = @_;
3854
3855   return $import unless defined($orig);
3856   return $orig unless defined($import);
3857
3858   $orig = $self->_rollout_attr($orig);
3859   $import = $self->_rollout_attr($import);
3860
3861   my $seen_keys;
3862   foreach my $import_element ( @{$import} ) {
3863     # find best candidate from $orig to merge $b_element into
3864     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3865     foreach my $orig_element ( @{$orig} ) {
3866       my $score = $self->_calculate_score( $orig_element, $import_element );
3867       if ($score > $best_candidate->{score}) {
3868         $best_candidate->{position} = $position;
3869         $best_candidate->{score} = $score;
3870       }
3871       $position++;
3872     }
3873     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3874     $import_key = '' if not defined $import_key;
3875
3876     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3877       push( @{$orig}, $import_element );
3878     } else {
3879       my $orig_best = $orig->[$best_candidate->{position}];
3880       # merge orig_best and b_element together and replace original with merged
3881       if (ref $orig_best ne 'HASH') {
3882         $orig->[$best_candidate->{position}] = $import_element;
3883       } elsif (ref $import_element eq 'HASH') {
3884         my ($key) = keys %{$orig_best};
3885         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3886       }
3887     }
3888     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3889   }
3890
3891   return @$orig ? $orig : ();
3892 }
3893
3894 {
3895   my $hm;
3896
3897   sub _merge_attr {
3898     $hm ||= do {
3899       require Hash::Merge;
3900       my $hm = Hash::Merge->new;
3901
3902       $hm->specify_behavior({
3903         SCALAR => {
3904           SCALAR => sub {
3905             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3906
3907             if ($defl xor $defr) {
3908               return [ $defl ? $_[0] : $_[1] ];
3909             }
3910             elsif (! $defl) {
3911               return [];
3912             }
3913             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3914               return [ $_[0] ];
3915             }
3916             else {
3917               return [$_[0], $_[1]];
3918             }
3919           },
3920           ARRAY => sub {
3921             return $_[1] if !defined $_[0];
3922             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
3923             return [$_[0], @{$_[1]}]
3924           },
3925           HASH  => sub {
3926             return [] if !defined $_[0] and !keys %{$_[1]};
3927             return [ $_[1] ] if !defined $_[0];
3928             return [ $_[0] ] if !keys %{$_[1]};
3929             return [$_[0], $_[1]]
3930           },
3931         },
3932         ARRAY => {
3933           SCALAR => sub {
3934             return $_[0] if !defined $_[1];
3935             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
3936             return [@{$_[0]}, $_[1]]
3937           },
3938           ARRAY => sub {
3939             my @ret = @{$_[0]} or return $_[1];
3940             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3941             my %idx = map { $_ => 1 } @ret;
3942             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3943             \@ret;
3944           },
3945           HASH => sub {
3946             return [ $_[1] ] if ! @{$_[0]};
3947             return $_[0] if !keys %{$_[1]};
3948             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
3949             return [ @{$_[0]}, $_[1] ];
3950           },
3951         },
3952         HASH => {
3953           SCALAR => sub {
3954             return [] if !keys %{$_[0]} and !defined $_[1];
3955             return [ $_[0] ] if !defined $_[1];
3956             return [ $_[1] ] if !keys %{$_[0]};
3957             return [$_[0], $_[1]]
3958           },
3959           ARRAY => sub {
3960             return [] if !keys %{$_[0]} and !@{$_[1]};
3961             return [ $_[0] ] if !@{$_[1]};
3962             return $_[1] if !keys %{$_[0]};
3963             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
3964             return [ $_[0], @{$_[1]} ];
3965           },
3966           HASH => sub {
3967             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3968             return [ $_[0] ] if !keys %{$_[1]};
3969             return [ $_[1] ] if !keys %{$_[0]};
3970             return [ $_[0] ] if $_[0] eq $_[1];
3971             return [ $_[0], $_[1] ];
3972           },
3973         }
3974       } => 'DBIC_RS_ATTR_MERGER');
3975       $hm;
3976     };
3977
3978     return $hm->merge ($_[1], $_[2]);
3979   }
3980 }
3981
3982 sub STORABLE_freeze {
3983   my ($self, $cloning) = @_;
3984   my $to_serialize = { %$self };
3985
3986   # A cursor in progress can't be serialized (and would make little sense anyway)
3987   # the parser can be regenerated (and can't be serialized)
3988   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3989
3990   # nor is it sensical to store a not-yet-fired-count pager
3991   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3992     delete $to_serialize->{pager};
3993   }
3994
3995   Storable::nfreeze($to_serialize);
3996 }
3997
3998 # need this hook for symmetry
3999 sub STORABLE_thaw {
4000   my ($self, $cloning, $serialized) = @_;
4001
4002   %$self = %{ Storable::thaw($serialized) };
4003
4004   $self;
4005 }
4006
4007
4008 =head2 throw_exception
4009
4010 See L<DBIx::Class::Schema/throw_exception> for details.
4011
4012 =cut
4013
4014 sub throw_exception {
4015   my $self=shift;
4016
4017   if (ref $self and my $rsrc = $self->result_source) {
4018     $rsrc->throw_exception(@_)
4019   }
4020   else {
4021     DBIx::Class::Exception->throw(@_);
4022   }
4023 }
4024
4025 1;
4026
4027 __END__
4028
4029 # XXX: FIXME: Attributes docs need clearing up
4030
4031 =head1 ATTRIBUTES
4032
4033 Attributes are used to refine a ResultSet in various ways when
4034 searching for data. They can be passed to any method which takes an
4035 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4036 L</count>.
4037
4038 Default attributes can be set on the result class using
4039 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4040 the CAVEATS on that feature before using it!)
4041
4042 These are in no particular order:
4043
4044 =head2 order_by
4045
4046 =over 4
4047
4048 =item Value: ( $order_by | \@order_by | \%order_by )
4049
4050 =back
4051
4052 Which column(s) to order the results by.
4053
4054 [The full list of suitable values is documented in
4055 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4056 common options.]
4057
4058 If a single column name, or an arrayref of names is supplied, the
4059 argument is passed through directly to SQL. The hashref syntax allows
4060 for connection-agnostic specification of ordering direction:
4061
4062  For descending order:
4063
4064   order_by => { -desc => [qw/col1 col2 col3/] }
4065
4066  For explicit ascending order:
4067
4068   order_by => { -asc => 'col' }
4069
4070 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4071 supported, although you are strongly encouraged to use the hashref
4072 syntax as outlined above.
4073
4074 =head2 columns
4075
4076 =over 4
4077
4078 =item Value: \@columns | \%columns | $column
4079
4080 =back
4081
4082 Shortcut to request a particular set of columns to be retrieved. Each
4083 column spec may be a string (a table column name), or a hash (in which
4084 case the key is the C<as> value, and the value is used as the C<select>
4085 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4086 it and sets C<select> from that, then auto-populates C<as> from
4087 C<select> as normal. (You may also use the C<cols> attribute, as in
4088 earlier versions of DBIC, but this is deprecated)
4089
4090 Essentially C<columns> does the same as L</select> and L</as>.
4091
4092     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4093
4094 is the same as
4095
4096     select => [qw(some_column another_column)],
4097     as     => [qw(some_column dbic_slot)]
4098
4099 If you want to individually retrieve related columns (in essence perform
4100 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4101 chain such that it matches existing relationships:
4102
4103     my $rs = $schema->resultset('Artist')->search({}, {
4104         # required to tell DBIC to collapse has_many relationships
4105         collapse => 1,
4106         join     => { cds => 'tracks' },
4107         '+columns'  => {
4108           'cds.cdid'         => 'cds.cdid',
4109           'cds.tracks.title' => 'tracks.title',
4110         },
4111     });
4112
4113 Like elsewhere, literal SQL or literal values can be included by using a
4114 scalar reference or a literal bind value, and these values will be available
4115 in the result with C<get_column> (see also
4116 L<SQL::Abstract/Literal SQL and value type operators>):
4117
4118     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4119     # bind values: $true_value, $false_value
4120     columns => [
4121         {
4122             foo => \1,
4123             bar => \q{'a string'},
4124             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4125         }
4126     ]
4127
4128 =head2 +columns
4129
4130 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4131 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4132 with a unary plus operator before it, which is the same as simply C<columns>.
4133
4134 =over 4
4135
4136 =item Value: \@extra_columns
4137
4138 =back
4139
4140 Indicates additional columns to be selected from storage. Works the same as
4141 L</columns> but adds columns to the current selection. (You may also use the
4142 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4143 deprecated)
4144
4145   $schema->resultset('CD')->search(undef, {
4146     '+columns' => ['artist.name'],
4147     join => ['artist']
4148   });
4149
4150 would return all CDs and include a 'name' column to the information
4151 passed to object inflation. Note that the 'artist' is the name of the
4152 column (or relationship) accessor, and 'name' is the name of the column
4153 accessor in the related table.
4154
4155 =head2 select
4156
4157 =over 4
4158
4159 =item Value: \@select_columns
4160
4161 =back
4162
4163 Indicates which columns should be selected from the storage. You can use
4164 column names, or in the case of RDBMS back ends, function or stored procedure
4165 names:
4166
4167   $rs = $schema->resultset('Employee')->search(undef, {
4168     select => [
4169       'name',
4170       { count => 'employeeid' },
4171       { max => { length => 'name' }, -as => 'longest_name' }
4172     ]
4173   });
4174
4175   # Equivalent SQL
4176   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4177
4178 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4179 use L</select>, to instruct DBIx::Class how to store the result of the column.
4180
4181 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4182 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4183 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4184 function attribute> supplied as shown in the example above.
4185
4186 =head2 +select
4187
4188 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4189 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4190 with a unary plus operator before it, which is the same as simply C<select>.
4191
4192 =over 4
4193
4194 =item Value: \@extra_select_columns
4195
4196 =back
4197
4198 Indicates additional columns to be selected from storage.  Works the same as
4199 L</select> but adds columns to the current selection, instead of specifying
4200 a new explicit list.
4201
4202 =head2 as
4203
4204 =over 4
4205
4206 =item Value: \@inflation_names
4207
4208 =back
4209
4210 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4211 slot name in which the column value will be stored within the
4212 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4213 identifier by the C<get_column> method (or via the object accessor B<if one
4214 with the same name already exists>) as shown below.
4215
4216 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4217 aliasing C<AS>. See L</select> for details.
4218
4219   $rs = $schema->resultset('Employee')->search(undef, {
4220     select => [
4221       'name',
4222       { count => 'employeeid' },
4223       { max => { length => 'name' }, -as => 'longest_name' }
4224     ],
4225     as => [qw/
4226       name
4227       employee_count
4228       max_name_length
4229     /],
4230   });
4231
4232 If the object against which the search is performed already has an accessor
4233 matching a column name specified in C<as>, the value can be retrieved using
4234 the accessor as normal:
4235
4236   my $name = $employee->name();
4237
4238 If on the other hand an accessor does not exist in the object, you need to
4239 use C<get_column> instead:
4240
4241   my $employee_count = $employee->get_column('employee_count');
4242
4243 You can create your own accessors if required - see
4244 L<DBIx::Class::Manual::Cookbook> for details.
4245
4246 =head2 +as
4247
4248 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4249 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4250 with a unary plus operator before it, which is the same as simply C<as>.
4251
4252 =over 4
4253
4254 =item Value: \@extra_inflation_names
4255
4256 =back
4257
4258 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4259
4260 =head2 join
4261
4262 =over 4
4263
4264 =item Value: ($rel_name | \@rel_names | \%rel_names)
4265
4266 =back
4267
4268 Contains a list of relationships that should be joined for this query.  For
4269 example:
4270
4271   # Get CDs by Nine Inch Nails
4272   my $rs = $schema->resultset('CD')->search(
4273     { 'artist.name' => 'Nine Inch Nails' },
4274     { join => 'artist' }
4275   );
4276
4277 Can also contain a hash reference to refer to the other relation's relations.
4278 For example:
4279
4280   package MyApp::Schema::Track;
4281   use base qw/DBIx::Class/;
4282   __PACKAGE__->table('track');
4283   __PACKAGE__->add_columns(qw/trackid cd position title/);
4284   __PACKAGE__->set_primary_key('trackid');
4285   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4286   1;
4287
4288   # In your application
4289   my $rs = $schema->resultset('Artist')->search(
4290     { 'track.title' => 'Teardrop' },
4291     {
4292       join     => { cd => 'track' },
4293       order_by => 'artist.name',
4294     }
4295   );
4296
4297 You need to use the relationship (not the table) name in  conditions,
4298 because they are aliased as such. The current table is aliased as "me", so
4299 you need to use me.column_name in order to avoid ambiguity. For example:
4300
4301   # Get CDs from 1984 with a 'Foo' track
4302   my $rs = $schema->resultset('CD')->search(
4303     {
4304       'me.year' => 1984,
4305       'tracks.name' => 'Foo'
4306     },
4307     { join => 'tracks' }
4308   );
4309
4310 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4311 similarly for a third time). For e.g.
4312
4313   my $rs = $schema->resultset('Artist')->search({
4314     'cds.title'   => 'Down to Earth',
4315     'cds_2.title' => 'Popular',
4316   }, {
4317     join => [ qw/cds cds/ ],
4318   });
4319
4320 will return a set of all artists that have both a cd with title 'Down
4321 to Earth' and a cd with title 'Popular'.
4322
4323 If you want to fetch related objects from other tables as well, see L</prefetch>
4324 below.
4325
4326  NOTE: An internal join-chain pruner will discard certain joins while
4327  constructing the actual SQL query, as long as the joins in question do not
4328  affect the retrieved result. This for example includes 1:1 left joins
4329  that are not part of the restriction specification (WHERE/HAVING) nor are
4330  a part of the query selection.
4331
4332 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4333
4334 =head2 collapse
4335
4336 =over 4
4337
4338 =item Value: (0 | 1)
4339
4340 =back
4341
4342 When set to a true value, indicates that any rows fetched from joined has_many
4343 relationships are to be aggregated into the corresponding "parent" object. For
4344 example, the resultset:
4345
4346   my $rs = $schema->resultset('CD')->search({}, {
4347     '+columns' => [ qw/ tracks.title tracks.position / ],
4348     join => 'tracks',
4349     collapse => 1,
4350   });
4351
4352 While executing the following query:
4353
4354   SELECT me.*, tracks.title, tracks.position
4355     FROM cd me
4356     LEFT JOIN track tracks
4357       ON tracks.cdid = me.cdid
4358
4359 Will return only as many objects as there are rows in the CD source, even
4360 though the result of the query may span many rows. Each of these CD objects
4361 will in turn have multiple "Track" objects hidden behind the has_many
4362 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4363 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4364 product"), with each CD object containing exactly one of all fetched Track data.
4365
4366 When a collapse is requested on a non-ordered resultset, an order by some
4367 unique part of the main source (the left-most table) is inserted automatically.
4368 This is done so that the resultset is allowed to be "lazy" - calling
4369 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4370 object with all of its related data.
4371
4372 If an L</order_by> is already declared, and orders the resultset in a way that
4373 makes collapsing as described above impossible (e.g. C<< ORDER BY
4374 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4375 switch to "eager" mode and slurp the entire resultset before constructing the
4376 first object returned by L</next>.
4377
4378 Setting this attribute on a resultset that does not join any has_many
4379 relations is a no-op.
4380
4381 For a more in-depth discussion, see L</PREFETCHING>.
4382
4383 =head2 prefetch
4384
4385 =over 4
4386
4387 =item Value: ($rel_name | \@rel_names | \%rel_names)
4388
4389 =back
4390
4391 This attribute is a shorthand for specifying a L</join> spec, adding all
4392 columns from the joined related sources as L</+columns> and setting
4393 L</collapse> to a true value. It can be thought of as a rough B<superset>
4394 of the L</join> attribute.
4395
4396 For example, the following two queries are equivalent:
4397
4398   my $rs = $schema->resultset('Artist')->search({}, {
4399     prefetch => { cds => ['genre', 'tracks' ] },
4400   });
4401
4402 and
4403
4404   my $rs = $schema->resultset('Artist')->search({}, {
4405     join => { cds => ['genre', 'tracks' ] },
4406     collapse => 1,
4407     '+columns' => [
4408       (map
4409         { +{ "cds.$_" => "cds.$_" } }
4410         $schema->source('Artist')->related_source('cds')->columns
4411       ),
4412       (map
4413         { +{ "cds.genre.$_" => "genre.$_" } }
4414         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4415       ),
4416       (map
4417         { +{ "cds.tracks.$_" => "tracks.$_" } }
4418         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4419       ),
4420     ],
4421   });
4422
4423 Both producing the following SQL:
4424
4425   SELECT  me.artistid, me.name, me.rank, me.charfield,
4426           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4427           genre.genreid, genre.name,
4428           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4429     FROM artist me
4430     LEFT JOIN cd cds
4431       ON cds.artist = me.artistid
4432     LEFT JOIN genre genre
4433       ON genre.genreid = cds.genreid
4434     LEFT JOIN track tracks
4435       ON tracks.cd = cds.cdid
4436   ORDER BY me.artistid
4437
4438 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4439 the arguments are properly merged and generally do the right thing. For
4440 example, you may want to do the following:
4441
4442   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4443     { 'genre.genreid' => undef },
4444     {
4445       join => { cds => 'genre' },
4446       prefetch => 'cds',
4447     }
4448   );
4449
4450 Which generates the following SQL:
4451
4452   SELECT  me.artistid, me.name, me.rank, me.charfield,
4453           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4454     FROM artist me
4455     LEFT JOIN cd cds
4456       ON cds.artist = me.artistid
4457     LEFT JOIN genre genre
4458       ON genre.genreid = cds.genreid
4459   WHERE genre.genreid IS NULL
4460   ORDER BY me.artistid
4461
4462 For a more in-depth discussion, see L</PREFETCHING>.
4463
4464 =head2 alias
4465
4466 =over 4
4467
4468 =item Value: $source_alias
4469
4470 =back
4471
4472 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4473 nested search queries (sub-SELECTs) might need specific aliases set to
4474 reference inner queries.  For example:
4475
4476    my $q = $rs
4477       ->related_resultset('CDs')
4478       ->related_resultset('Tracks')
4479       ->search({
4480          'track.id' => { -ident => 'none_search.id' },
4481       })
4482       ->as_query;
4483
4484    my $ids = $self->search({
4485       -not_exists => $q,
4486    }, {
4487       alias    => 'none_search',
4488       group_by => 'none_search.id',
4489    })->get_column('id')->as_query;
4490
4491    $self->search({ id => { -in => $ids } })
4492
4493 This attribute is directly tied to L</current_source_alias>.
4494
4495 =head2 page
4496
4497 =over 4
4498
4499 =item Value: $page
4500
4501 =back
4502
4503 Makes the resultset paged and specifies the page to retrieve. Effectively
4504 identical to creating a non-pages resultset and then calling ->page($page)
4505 on it.
4506
4507 If L</rows> attribute is not specified it defaults to 10 rows per page.
4508
4509 When you have a paged resultset, L</count> will only return the number
4510 of rows in the page. To get the total, use the L</pager> and call
4511 C<total_entries> on it.
4512
4513 =head2 rows
4514
4515 =over 4
4516
4517 =item Value: $rows
4518
4519 =back
4520
4521 Specifies the maximum number of rows for direct retrieval or the number of
4522 rows per page if the page attribute or method is used.
4523
4524 =head2 offset
4525
4526 =over 4
4527
4528 =item Value: $offset
4529
4530 =back
4531
4532 Specifies the (zero-based) row number for the  first row to be returned, or the
4533 of the first row of the first page if paging is used.
4534
4535 =head2 software_limit
4536
4537 =over 4
4538
4539 =item Value: (0 | 1)
4540
4541 =back
4542
4543 When combined with L</rows> and/or L</offset> the generated SQL will not
4544 include any limit dialect stanzas. Instead the entire result will be selected
4545 as if no limits were specified, and DBIC will perform the limit locally, by
4546 artificially advancing and finishing the resulting L</cursor>.
4547
4548 This is the recommended way of performing resultset limiting when no sane RDBMS
4549 implementation is available (e.g.
4550 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4551 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4552
4553 =head2 group_by
4554
4555 =over 4
4556
4557 =item Value: \@columns
4558
4559 =back
4560
4561 A arrayref of columns to group by. Can include columns of joined tables.
4562
4563   group_by => [qw/ column1 column2 ... /]
4564
4565 =head2 having
4566
4567 =over 4
4568
4569 =item Value: $condition
4570
4571 =back
4572
4573 The HAVING operator specifies a B<secondary> condition applied to the set
4574 after the grouping calculations have been done. In other words it is a
4575 constraint just like L</where> (and accepting the same
4576 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4577 as it exists after GROUP BY has taken place. Specifying L</having> without
4578 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4579
4580 E.g.
4581
4582   having => { 'count_employee' => { '>=', 100 } }
4583
4584 or with an in-place function in which case literal SQL is required:
4585
4586   having => \[ 'count(employee) >= ?', 100 ]
4587
4588 =head2 distinct
4589
4590 =over 4
4591
4592 =item Value: (0 | 1)
4593
4594 =back
4595
4596 Set to 1 to automatically generate a L</group_by> clause based on the selection
4597 (including intelligent handling of L</order_by> contents). Note that the group
4598 criteria calculation takes place over the B<final> selection. This includes
4599 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4600 L</search> calls, and standalone columns selected via
4601 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4602 extra selections specified via L</prefetch> - such selections are explicitly
4603 excluded from group criteria calculations.
4604
4605 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4606 setting is ignored and an appropriate warning is issued.
4607
4608 =head2 where
4609
4610 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4611 conditions, same as the B<first> argument to the L<search operator|/search>
4612
4613   # only return rows WHERE deleted IS NULL for all searches
4614   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4615
4616 Note that the above example is
4617 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4618
4619 =head2 cache
4620
4621 Set to 1 to cache search results. This prevents extra SQL queries if you
4622 revisit rows in your ResultSet:
4623
4624   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4625
4626   while( my $artist = $resultset->next ) {
4627     ... do stuff ...
4628   }
4629
4630   $resultset->first; # without cache, this would issue a query
4631
4632 By default, searches are not cached.
4633
4634 For more examples of using these attributes, see
4635 L<DBIx::Class::Manual::Cookbook>.
4636
4637 =head2 for
4638
4639 =over 4
4640
4641 =item Value: ( 'update' | 'shared' | \$scalar )
4642
4643 =back
4644
4645 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4646 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4647 query.
4648
4649 =head1 PREFETCHING
4650
4651 DBIx::Class supports arbitrary related data prefetching from multiple related
4652 sources. Any combination of relationship types and column sets are supported.
4653 If L<collapsing|/collapse> is requested, there is an additional requirement of
4654 selecting enough data to make every individual object uniquely identifiable.
4655
4656 Here are some more involved examples, based on the following relationship map:
4657
4658   # Assuming:
4659   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4660   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4661   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4662
4663   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4664
4665   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4666
4667
4668
4669   my $rs = $schema->resultset('Tag')->search(
4670     undef,
4671     {
4672       prefetch => {
4673         cd => 'artist'
4674       }
4675     }
4676   );
4677
4678 The initial search results in SQL like the following:
4679
4680   SELECT tag.*, cd.*, artist.* FROM tag
4681   JOIN cd ON tag.cd = cd.cdid
4682   JOIN artist ON cd.artist = artist.artistid
4683
4684 L<DBIx::Class> has no need to go back to the database when we access the
4685 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4686 case.
4687
4688 Simple prefetches will be joined automatically, so there is no need
4689 for a C<join> attribute in the above search.
4690
4691 The L</prefetch> attribute can be used with any of the relationship types
4692 and multiple prefetches can be specified together. Below is a more complex
4693 example that prefetches a CD's artist, its liner notes (if present),
4694 the cover image, the tracks on that CD, and the guests on those
4695 tracks.
4696
4697   my $rs = $schema->resultset('CD')->search(
4698     undef,
4699     {
4700       prefetch => [
4701         { artist => 'record_label'},  # belongs_to => belongs_to
4702         'liner_note',                 # might_have
4703         'cover_image',                # has_one
4704         { tracks => 'guests' },       # has_many => has_many
4705       ]
4706     }
4707   );
4708
4709 This will produce SQL like the following:
4710
4711   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4712          tracks.*, guests.*
4713     FROM cd me
4714     JOIN artist artist
4715       ON artist.artistid = me.artistid
4716     JOIN record_label record_label
4717       ON record_label.labelid = artist.labelid
4718     LEFT JOIN track tracks
4719       ON tracks.cdid = me.cdid
4720     LEFT JOIN guest guests
4721       ON guests.trackid = track.trackid
4722     LEFT JOIN liner_notes liner_note
4723       ON liner_note.cdid = me.cdid
4724     JOIN cd_artwork cover_image
4725       ON cover_image.cdid = me.cdid
4726   ORDER BY tracks.cd
4727
4728 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4729 C<tracks>, and C<guests> of the CD will all be available through the
4730 relationship accessors without the need for additional queries to the
4731 database.
4732
4733 =head3 CAVEATS
4734
4735 Prefetch does a lot of deep magic. As such, it may not behave exactly
4736 as you might expect.
4737
4738 =over 4
4739
4740 =item *
4741
4742 Prefetch uses the L</cache> to populate the prefetched relationships. This
4743 may or may not be what you want.
4744
4745 =item *
4746
4747 If you specify a condition on a prefetched relationship, ONLY those
4748 rows that match the prefetched condition will be fetched into that relationship.
4749 This means that adding prefetch to a search() B<may alter> what is returned by
4750 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4751
4752   my $artist_rs = $schema->resultset('Artist')->search({
4753       'cds.year' => 2008,
4754   }, {
4755       join => 'cds',
4756   });
4757
4758   my $count = $artist_rs->first->cds->count;
4759
4760   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4761
4762   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4763
4764   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4765
4766 That cmp_ok() may or may not pass depending on the datasets involved. In other
4767 words the C<WHERE> condition would apply to the entire dataset, just like
4768 it would in regular SQL. If you want to add a condition only to the "right side"
4769 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4770 condition|DBIx::Class::Relationship::Base/condition>
4771
4772 =back
4773
4774 =head1 DBIC BIND VALUES
4775
4776 Because DBIC may need more information to bind values than just the column name
4777 and value itself, it uses a special format for both passing and receiving bind
4778 values.  Each bind value should be composed of an arrayref of
4779 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4780
4781 =over 4
4782
4783 =item dbd_attrs
4784
4785 If present (in any form), this is what is being passed directly to bind_param.
4786 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4787 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4788
4789 If this is specified, all other bind options described below are ignored.
4790
4791 =item sqlt_datatype
4792
4793 If present, this is used to infer the actual bind attribute by passing to
4794 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4795 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4796
4797 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4798 currently drivers are expected to "Do the Right Thing" when given a common
4799 datatype name.  (Not ideal, but that's what we got at this point.)
4800
4801 =item sqlt_size
4802
4803 Currently used to correctly allocate buffers for bind_param_inout().
4804 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4805 or to a sensible value based on the "data_type".
4806
4807 =item dbic_colname
4808
4809 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4810 explicitly specified they are never overridden).  Also used by some weird DBDs,
4811 where the column name should be available at bind_param time (e.g. Oracle).
4812
4813 =back
4814
4815 For backwards compatibility and convenience, the following shortcuts are
4816 supported:
4817
4818   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4819   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4820   [ undef,   $val ] === [ {}, $val ]
4821   $val              === [ {}, $val ]
4822
4823 =head1 FURTHER QUESTIONS?
4824
4825 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4826
4827 =head1 COPYRIGHT AND LICENSE
4828
4829 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4830 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4831 redistribute it and/or modify it under the same terms as the
4832 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4833
4834 =cut