lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304
 305   if (ref $class) {
 306     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 307     return $class->new_result(@_);
 308   }
 309
 310   my ($source, $attrs) = @_;
 311   $source = $source->resolve
 312     if $source->isa('DBIx::Class::ResultSourceHandle');
 313
 314   $attrs = { %{$attrs||{}} };
 315   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 316
 317   if ($attrs->{page}) {
 318     $attrs->{rows} ||= 10;
 319   }
 320
 321   $attrs->{alias} ||= 'me';
 322
 323   my $self = bless {
 324     result_source => $source,
 325     cond => $attrs->{where},
 326     pager => undef,
 327     attrs => $attrs,
 328   }, $class;
 329
 330   # if there is a dark selector, this means we are already in a
 331   # chain and the cleanup/sanification was taken care of by
 332   # _search_rs already
 333   $self->_normalize_selection($attrs)
 334     unless $attrs->{_dark_selector};
 335
 336   $self->result_class(
 337     $attrs->{result_class} || $source->result_class
 338   );
 339
 340   $self;
 341 }
 342
 343 =head2 search
 344
 345 =over 4
 346
 347 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 348
 349 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 350
 351 =back
 352
 353   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 354   my $new_rs = $cd_rs->search({ year => 2005 });
 355
 356   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 357                  # year = 2005 OR year = 2004
 358
 359 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 360 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 361 To avoid that, use L</search_rs>.
 362
 363 If you need to pass in additional attributes but no additional condition,
 364 call it as C<search(undef, \%attrs)>.
 365
 366   # "SELECT name, artistid FROM $artist_table"
 367   my @all_artists = $schema->resultset('Artist')->search(undef, {
 368     columns => [qw/name artistid/],
 369   });
 370
 371 For a list of attributes that can be passed to C<search>, see
 372 L</ATTRIBUTES>. For more examples of using this function, see
 373 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 374 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 375 and its extension L<DBIx::Class::SQLMaker>.
 376
 377 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 378
 379 =head3 CAVEAT
 380
 381 Note that L</search> does not process/deflate any of the values passed in the
 382 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 383 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 384 manually that any value passed to this method will stringify to something the
 385 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 386 objects, for more info see:
 387 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 388
 389 =cut
 390
 391 sub search {
 392   my $self = shift;
 393   my $rs = $self->search_rs( @_ );
 394
 395   if (wantarray) {
 396     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 397     return $rs->all;
 398   }
 399   elsif (defined wantarray) {
 400     return $rs;
 401   }
 402   else {
 403     # we can be called by a relationship helper, which in
 404     # turn may be called in void context due to some braindead
 405     # overload or whatever else the user decided to be clever
 406     # at this particular day. Thus limit the exception to
 407     # external code calls only
 408     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 409       if (caller)[0] !~ /^\QDBIx::Class::/;
 410
 411     return ();
 412   }
 413 }
 414
 415 =head2 search_rs
 416
 417 =over 4
 418
 419 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 420
 421 =item Return Value: L<$resultset|/search>
 422
 423 =back
 424
 425 This method does the same exact thing as search() except it will
 426 always return a resultset, even in list context.
 427
 428 =cut
 429
 430 sub search_rs {
 431   my $self = shift;
 432
 433   my $rsrc = $self->result_source;
 434   my ($call_cond, $call_attrs);
 435
 436   # Special-case handling for (undef, undef) or (undef)
 437   # Note that (foo => undef) is valid deprecated syntax
 438   @_ = () if not scalar grep { defined $_ } @_;
 439
 440   # just a cond
 441   if (@_ == 1) {
 442     $call_cond = shift;
 443   }
 444   # fish out attrs in the ($condref, $attr) case
 445   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 446     ($call_cond, $call_attrs) = @_;
 447   }
 448   elsif (@_ % 2) {
 449     $self->throw_exception('Odd number of arguments to search')
 450   }
 451   # legacy search
 452   elsif (@_) {
 453     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 454       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 455
 456     for my $i (0 .. $#_) {
 457       next if $i % 2;
 458       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 459         if (! defined $_[$i] or ref $_[$i] ne '');
 460     }
 461
 462     $call_cond = { @_ };
 463   }
 464
 465   # see if we can keep the cache (no $rs changes)
 466   my $cache;
 467   my %safe = (alias => 1, cache => 1);
 468   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 469     ! defined $call_cond
 470       or
 471     ref $call_cond eq 'HASH' && ! keys %$call_cond
 472       or
 473     ref $call_cond eq 'ARRAY' && ! @$call_cond
 474   )) {
 475     $cache = $self->get_cache;
 476   }
 477
 478   my $old_attrs = { %{$self->{attrs}} };
 479   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 480
 481   my $new_attrs = { %$old_attrs };
 482
 483   # take care of call attrs (only if anything is changing)
 484   if ($call_attrs and keys %$call_attrs) {
 485
 486     # copy for _normalize_selection
 487     $call_attrs = { %$call_attrs };
 488
 489     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 490
 491     # reset the current selector list if new selectors are supplied
 492     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 493       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 494     }
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 my $dark_sel_dumper;
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => ($dark_sel_dumper ||= do {
 622                   require Data::Dumper::Concise;
 623                   Data::Dumper::Concise::DumperObject()->Indent(0);
 624                 })->Values([$_])->Dump
 625               ,
 626             };
 627             last SELECTOR;
 628           }
 629         }
 630       }
 631     }
 632     elsif (@$as < @$sel) {
 633       $self->throw_exception(
 634         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 635       );
 636     }
 637     elsif ($pref and $attrs->{_dark_selector}) {
 638       $self->throw_exception(
 639         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 640       );
 641     }
 642
 643
 644     # merge result
 645     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 646     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 647   }
 648 }
 649
 650 sub _stack_cond {
 651   my ($self, $left, $right) = @_;
 652
 653   (
 654     (ref $_ eq 'ARRAY' and !@$_)
 655       or
 656     (ref $_ eq 'HASH' and ! keys %$_)
 657   ) and $_ = undef for ($left, $right);
 658
 659   # either on of the two undef or both undef
 660   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 661     return defined $left ? $left : $right;
 662   }
 663
 664   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 665
 666   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 667
 668     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 669     my @fin = shift @vals;
 670
 671     for my $v (@vals) {
 672       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 673     }
 674
 675     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 676   }
 677
 678   $cond;
 679 }
 680
 681 =head2 search_literal
 682
 683 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 684 should only be used in that context. C<search_literal> is a convenience
 685 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 686 want to ensure columns are bound correctly, use L</search>.
 687
 688 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 689 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 690 require C<search_literal>.
 691
 692 =over 4
 693
 694 =item Arguments: $sql_fragment, @standalone_bind_values
 695
 696 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 697
 698 =back
 699
 700   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 701   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 702
 703 Pass a literal chunk of SQL to be added to the conditional part of the
 704 resultset query.
 705
 706 Example of how to use C<search> instead of C<search_literal>
 707
 708   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 709   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 710
 711 =cut
 712
 713 sub search_literal {
 714   my ($self, $sql, @bind) = @_;
 715   my $attr;
 716   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 717     $attr = pop @bind;
 718   }
 719   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 720 }
 721
 722 =head2 find
 723
 724 =over 4
 725
 726 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 727
 728 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 729
 730 =back
 731
 732 Finds and returns a single row based on supplied criteria. Takes either a
 733 hashref with the same format as L</create> (including inference of foreign
 734 keys from related objects), or a list of primary key values in the same
 735 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 736 declaration on the L</result_source>.
 737
 738 In either case an attempt is made to combine conditions already existing on
 739 the resultset with the condition passed to this method.
 740
 741 To aid with preparing the correct query for the storage you may supply the
 742 C<key> attribute, which is the name of a
 743 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 744 unique constraint corresponding to the
 745 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 746 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 747 to construct a query that satisfies the named unique constraint fully (
 748 non-NULL values for each column member of the constraint) an exception is
 749 thrown.
 750
 751 If no C<key> is specified, the search is carried over all unique constraints
 752 which are fully defined by the available condition.
 753
 754 If no such constraint is found, C<find> currently defaults to a simple
 755 C<< search->(\%column_values) >> which may or may not do what you expect.
 756 Note that this fallback behavior may be deprecated in further versions. If
 757 you need to search with arbitrary conditions - use L</search>. If the query
 758 resulting from this fallback produces more than one row, a warning to the
 759 effect is issued, though only the first row is constructed and returned as
 760 C<$result_object>.
 761
 762 In addition to C<key>, L</find> recognizes and applies standard
 763 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 764
 765 Note that if you have extra concerns about the correctness of the resulting
 766 query you need to specify the C<key> attribute and supply the entire condition
 767 as an argument to find (since it is not always possible to perform the
 768 combination of the resultset condition with the supplied one, especially if
 769 the resultset condition contains literal sql).
 770
 771 For example, to find a row by its primary key:
 772
 773   my $cd = $schema->resultset('CD')->find(5);
 774
 775 You can also find a row by a specific unique constraint:
 776
 777   my $cd = $schema->resultset('CD')->find(
 778     {
 779       artist => 'Massive Attack',
 780       title  => 'Mezzanine',
 781     },
 782     { key => 'cd_artist_title' }
 783   );
 784
 785 See also L</find_or_create> and L</update_or_create>.
 786
 787 =cut
 788
 789 sub find {
 790   my $self = shift;
 791   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 792
 793   my $rsrc = $self->result_source;
 794
 795   my $constraint_name;
 796   if (exists $attrs->{key}) {
 797     $constraint_name = defined $attrs->{key}
 798       ? $attrs->{key}
 799       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 800     ;
 801   }
 802
 803   # Parse out the condition from input
 804   my $call_cond;
 805
 806   if (ref $_[0] eq 'HASH') {
 807     $call_cond = { %{$_[0]} };
 808   }
 809   else {
 810     # if only values are supplied we need to default to 'primary'
 811     $constraint_name = 'primary' unless defined $constraint_name;
 812
 813     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 814
 815     $self->throw_exception(
 816       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 817     ) unless @c_cols;
 818
 819     $self->throw_exception (
 820       'find() expects either a column/value hashref, or a list of values '
 821     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 822     ) unless @c_cols == @_;
 823
 824     $call_cond = {};
 825     @{$call_cond}{@c_cols} = @_;
 826   }
 827
 828   for my $key (keys %$call_cond) {
 829     if (
 830       length ref($call_cond->{$key})
 831         and
 832       my $relinfo = $rsrc->relationship_info($key)
 833         and
 834       # implicitly skip has_many's (likely MC)
 835       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 836     ) {
 837       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 838         $relinfo->{cond}, $val, $key, $key
 839       );
 840
 841       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 842          if $crosstable or ref($rel_cond) ne 'HASH';
 843
 844       # supplement condition
 845       # relationship conditions take precedence (?)
 846       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 847     }
 848   }
 849
 850
 851   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 852   my $final_cond;
 853   if (defined $constraint_name) {
 854     $final_cond = $self->_qualify_cond_columns (
 855
 856       $self->_build_unique_cond (
 857         $constraint_name,
 858         $call_cond,
 859       ),
 860
 861       $alias,
 862     );
 863   }
 864   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 865     # This means that we got here after a merger of relationship conditions
 866     # in ::Relationship::Base::search_related (the row method), and furthermore
 867     # the relationship is of the 'single' type. This means that the condition
 868     # provided by the relationship (already attached to $self) is sufficient,
 869     # as there can be only one row in the database that would satisfy the
 870     # relationship
 871   }
 872   else {
 873     # no key was specified - fall down to heuristics mode:
 874     # run through all unique queries registered on the resultset, and
 875     # 'OR' all qualifying queries together
 876     my (@unique_queries, %seen_column_combinations);
 877     for my $c_name ($rsrc->unique_constraint_names) {
 878       next if $seen_column_combinations{
 879         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 880       }++;
 881
 882       push @unique_queries, try {
 883         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 884       } || ();
 885     }
 886
 887     $final_cond = @unique_queries
 888       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 889       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 890     ;
 891   }
 892
 893   # Run the query, passing the result_class since it should propagate for find
 894   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 895   if ($rs->_resolved_attrs->{collapse}) {
 896     my $row = $rs->next;
 897     carp "Query returned more than one row" if $rs->next;
 898     return $row;
 899   }
 900   else {
 901     return $rs->single;
 902   }
 903 }
 904
 905 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 906 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 907 #
 908 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 909 # condition. It is provided for overrides until a saner way forward is devised
 910 #
 911 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 912 # the road. Please adjust your tests accordingly to catch this situation early
 913 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 914 #
 915 # The method will not be removed without an adequately complete replacement
 916 # for strict-mode enforcement
 917 sub _non_unique_find_fallback {
 918   my ($self, $cond, $attrs) = @_;
 919
 920   return $self->_qualify_cond_columns(
 921     $cond,
 922     exists $attrs->{alias}
 923       ? $attrs->{alias}
 924       : $self->{attrs}{alias}
 925   );
 926 }
 927
 928
 929 sub _qualify_cond_columns {
 930   my ($self, $cond, $alias) = @_;
 931
 932   my %aliased = %$cond;
 933   for (keys %aliased) {
 934     $aliased{"$alias.$_"} = delete $aliased{$_}
 935       if $_ !~ /\./;
 936   }
 937
 938   return \%aliased;
 939 }
 940
 941 sub _build_unique_cond {
 942   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 943
 944   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 945
 946   # combination may fail if $self->{cond} is non-trivial
 947   my ($final_cond) = try {
 948     $self->_merge_with_rscond ($extra_cond)
 949   } catch {
 950     +{ %$extra_cond }
 951   };
 952
 953   # trim out everything not in $columns
 954   $final_cond = { map {
 955     exists $final_cond->{$_}
 956       ? ( $_ => $final_cond->{$_} )
 957       : ()
 958   } @c_cols };
 959
 960   if (my @missing = grep
 961     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 962     (@c_cols)
 963   ) {
 964     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 965       $constraint_name,
 966       join (', ', map { "'$_'" } @missing),
 967     ) );
 968   }
 969
 970   if (
 971     !$croak_on_null
 972       and
 973     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 974       and
 975     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 976   ) {
 977     carp_unique ( sprintf (
 978       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 979     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 980     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 981       $constraint_name,
 982       join (', ', map { "'$_'" } @undefs),
 983     ));
 984   }
 985
 986   return $final_cond;
 987 }
 988
 989 =head2 search_related
 990
 991 =over 4
 992
 993 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 994
 995 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 996
 997 =back
 998
 999   $new_rs = $cd_rs->search_related('artist', {
1000     name => 'Emo-R-Us',
1001   });
1002
1003 Searches the specified relationship, optionally specifying a condition and
1004 attributes for matching records. See L</ATTRIBUTES> for more information.
1005
1006 In list context, C<< ->all() >> is called implicitly on the resultset, thus
1007 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
1008
1009 See also L</search_related_rs>.
1010
1011 =cut
1012
1013 sub search_related {
1014   return shift->related_resultset(shift)->search(@_);
1015 }
1016
1017 =head2 search_related_rs
1018
1019 This method works exactly the same as search_related, except that
1020 it guarantees a resultset, even in list context.
1021
1022 =cut
1023
1024 sub search_related_rs {
1025   return shift->related_resultset(shift)->search_rs(@_);
1026 }
1027
1028 =head2 cursor
1029
1030 =over 4
1031
1032 =item Arguments: none
1033
1034 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1035
1036 =back
1037
1038 Returns a storage-driven cursor to the given resultset. See
1039 L<DBIx::Class::Cursor> for more information.
1040
1041 =cut
1042
1043 sub cursor {
1044   my $self = shift;
1045
1046   return $self->{cursor} ||= do {
1047     my $attrs = $self->_resolved_attrs;
1048     $self->result_source->storage->select(
1049       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1050     );
1051   };
1052 }
1053
1054 =head2 single
1055
1056 =over 4
1057
1058 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1059
1060 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1061
1062 =back
1063
1064   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1065
1066 Inflates the first result without creating a cursor if the resultset has
1067 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1068 of L</search>.
1069
1070 While this method can take an optional search condition (just like L</search>)
1071 being a fast-code-path it does not recognize search attributes. If you need to
1072 add extra joins or similar, call L</search> and then chain-call L</single> on the
1073 L<DBIx::Class::ResultSet> returned.
1074
1075 =over
1076
1077 =item B<Note>
1078
1079 As of 0.08100, this method enforces the assumption that the preceding
1080 query returns only one row. If more than one row is returned, you will receive
1081 a warning:
1082
1083   Query returned more than one row
1084
1085 In this case, you should be using L</next> or L</find> instead, or if you really
1086 know what you are doing, use the L</rows> attribute to explicitly limit the size
1087 of the resultset.
1088
1089 This method will also throw an exception if it is called on a resultset prefetching
1090 has_many, as such a prefetch implies fetching multiple rows from the database in
1091 order to assemble the resulting object.
1092
1093 =back
1094
1095 =cut
1096
1097 sub single {
1098   my ($self, $where) = @_;
1099   if(@_ > 2) {
1100       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1101   }
1102
1103   my $attrs = { %{$self->_resolved_attrs} };
1104
1105   $self->throw_exception(
1106     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1107   ) if $attrs->{collapse};
1108
1109   if ($where) {
1110     if (defined $attrs->{where}) {
1111       $attrs->{where} = {
1112         '-and' =>
1113             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1114                $where, delete $attrs->{where} ]
1115       };
1116     } else {
1117       $attrs->{where} = $where;
1118     }
1119   }
1120
1121   my $data = [ $self->result_source->storage->select_single(
1122     $attrs->{from}, $attrs->{select},
1123     $attrs->{where}, $attrs
1124   )];
1125
1126   return undef unless @$data;
1127   $self->{_stashed_rows} = [ $data ];
1128   $self->_construct_results->[0];
1129 }
1130
1131 =head2 get_column
1132
1133 =over 4
1134
1135 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1136
1137 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1138
1139 =back
1140
1141   my $max_length = $rs->get_column('length')->max;
1142
1143 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1144
1145 =cut
1146
1147 sub get_column {
1148   my ($self, $column) = @_;
1149   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1150   return $new;
1151 }
1152
1153 =head2 search_like
1154
1155 =over 4
1156
1157 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1158
1159 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1160
1161 =back
1162
1163   # WHERE title LIKE '%blue%'
1164   $cd_rs = $rs->search_like({ title => '%blue%'});
1165
1166 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1167 that this is simply a convenience method retained for ex Class::DBI users.
1168 You most likely want to use L</search> with specific operators.
1169
1170 For more information, see L<DBIx::Class::Manual::Cookbook>.
1171
1172 This method is deprecated and will be removed in 0.09. Use L</search()>
1173 instead. An example conversion is:
1174
1175   ->search_like({ foo => 'bar' });
1176
1177   # Becomes
1178
1179   ->search({ foo => { like => 'bar' } });
1180
1181 =cut
1182
1183 sub search_like {
1184   my $class = shift;
1185   carp_unique (
1186     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1187    .' Instead use ->search({ x => { -like => "y%" } })'
1188    .' (note the outer pair of {}s - they are important!)'
1189   );
1190   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1191   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1192   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1193   return $class->search($query, { %$attrs });
1194 }
1195
1196 =head2 slice
1197
1198 =over 4
1199
1200 =item Arguments: $first, $last
1201
1202 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1203
1204 =back
1205
1206 Returns a resultset or object list representing a subset of elements from the
1207 resultset slice is called on. Indexes are from 0, i.e., to get the first
1208 three records, call:
1209
1210   my ($one, $two, $three) = $rs->slice(0, 2);
1211
1212 =cut
1213
1214 sub slice {
1215   my ($self, $min, $max) = @_;
1216   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1217   $attrs->{offset} = $self->{attrs}{offset} || 0;
1218   $attrs->{offset} += $min;
1219   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1220   return $self->search(undef, $attrs);
1221 }
1222
1223 =head2 next
1224
1225 =over 4
1226
1227 =item Arguments: none
1228
1229 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1230
1231 =back
1232
1233 Returns the next element in the resultset (C<undef> is there is none).
1234
1235 Can be used to efficiently iterate over records in the resultset:
1236
1237   my $rs = $schema->resultset('CD')->search;
1238   while (my $cd = $rs->next) {
1239     print $cd->title;
1240   }
1241
1242 Note that you need to store the resultset object, and call C<next> on it.
1243 Calling C<< resultset('Table')->next >> repeatedly will always return the
1244 first record from the resultset.
1245
1246 =cut
1247
1248 sub next {
1249   my ($self) = @_;
1250
1251   if (my $cache = $self->get_cache) {
1252     $self->{all_cache_position} ||= 0;
1253     return $cache->[$self->{all_cache_position}++];
1254   }
1255
1256   if ($self->{attrs}{cache}) {
1257     delete $self->{pager};
1258     $self->{all_cache_position} = 1;
1259     return ($self->all)[0];
1260   }
1261
1262   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1263
1264   $self->{_stashed_results} = $self->_construct_results
1265     or return undef;
1266
1267   return shift @{$self->{_stashed_results}};
1268 }
1269
1270 # Constructs as many results as it can in one pass while respecting
1271 # cursor laziness. Several modes of operation:
1272 #
1273 # * Always builds everything present in @{$self->{_stashed_rows}}
1274 # * If called with $fetch_all true - pulls everything off the cursor and
1275 #   builds all result structures (or objects) in one pass
1276 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1277 #   and if the resultset is ordered properly by the left side:
1278 #   * Fetches stuff off the cursor until the "master object" changes,
1279 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1280 #   OR
1281 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1282 #     was requested (there is no other way to collapse except for an
1283 #     eager cursor)
1284 # * If no collapse is requested - just get the next row, construct and
1285 #   return
1286 sub _construct_results {
1287   my ($self, $fetch_all) = @_;
1288
1289   my $rsrc = $self->result_source;
1290   my $attrs = $self->_resolved_attrs;
1291
1292   if (
1293     ! $fetch_all
1294       and
1295     ! $attrs->{order_by}
1296       and
1297     $attrs->{collapse}
1298       and
1299     my @pcols = $rsrc->primary_columns
1300   ) {
1301     # default order for collapsing unless the user asked for something
1302     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1303     $attrs->{_ordered_for_collapse} = 1;
1304     $attrs->{_order_is_artificial} = 1;
1305   }
1306
1307   # this will be used as both initial raw-row collector AND as a RV of
1308   # _construct_results. Not regrowing the array twice matters a lot...
1309   # a surprising amount actually
1310   my $rows = delete $self->{_stashed_rows};
1311
1312   my $cursor; # we may not need one at all
1313
1314   my $did_fetch_all = $fetch_all;
1315
1316   if ($fetch_all) {
1317     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1318     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1319   }
1320   elsif( $attrs->{collapse} ) {
1321
1322     # a cursor will need to be closed over in case of collapse
1323     $cursor = $self->cursor;
1324
1325     $attrs->{_ordered_for_collapse} = (
1326       (
1327         $attrs->{order_by}
1328           and
1329         $rsrc->schema
1330               ->storage
1331                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1332       ) ? 1 : 0
1333     ) unless defined $attrs->{_ordered_for_collapse};
1334
1335     if (! $attrs->{_ordered_for_collapse}) {
1336       $did_fetch_all = 1;
1337
1338       # instead of looping over ->next, use ->all in stealth mode
1339       # *without* calling a ->reset afterwards
1340       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1341       if (! $cursor->{_done}) {
1342         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1343         $cursor->{_done} = 1;
1344       }
1345     }
1346   }
1347
1348   if (! $did_fetch_all and ! @{$rows||[]} ) {
1349     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1350     $cursor ||= $self->cursor;
1351     if (scalar (my @r = $cursor->next) ) {
1352       $rows = [ \@r ];
1353     }
1354   }
1355
1356   return undef unless @{$rows||[]};
1357
1358   # sanity check - people are too clever for their own good
1359   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1360
1361     my $multiplied_selectors;
1362     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1363       if (
1364         $aliastypes->{multiplying}{$sel_alias}
1365           or
1366         $aliastypes->{premultiplied}{$sel_alias}
1367       ) {
1368         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1369       }
1370     }
1371
1372     for my $i (0 .. $#{$attrs->{as}} ) {
1373       my $sel = $attrs->{select}[$i];
1374
1375       if (ref $sel eq 'SCALAR') {
1376         $sel = $$sel;
1377       }
1378       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1379         $sel = $$sel->[0];
1380       }
1381
1382       $self->throw_exception(
1383         'Result collapse not possible - selection from a has_many source redirected to the main object'
1384       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1385     }
1386   }
1387
1388   # hotspot - skip the setter
1389   my $res_class = $self->_result_class;
1390
1391   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1392     $res_class->can ('inflate_result')
1393       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1394   };
1395
1396   my $infmap = $attrs->{as};
1397
1398   $self->{_result_inflator}{is_core_row} = ( (
1399     $inflator_cref
1400       ==
1401     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1402   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1403
1404   $self->{_result_inflator}{is_hri} = ( (
1405     ! $self->{_result_inflator}{is_core_row}
1406       and
1407     $inflator_cref == (
1408       require DBIx::Class::ResultClass::HashRefInflator
1409         &&
1410       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1411     )
1412   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1413
1414
1415   if ($attrs->{_simple_passthrough_construction}) {
1416     # construct a much simpler array->hash folder for the one-table HRI cases right here
1417     if ($self->{_result_inflator}{is_hri}) {
1418       for my $r (@$rows) {
1419         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1420       }
1421     }
1422     # FIXME SUBOPTIMAL this is a very very very hot spot
1423     # while rather optimal we can *still* do much better, by
1424     # building a smarter Row::inflate_result(), and
1425     # switch to feeding it data via a much leaner interface
1426     #
1427     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1428     # this particular resultset size
1429     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1430       for my $r (@$rows) {
1431         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1432       }
1433     }
1434     else {
1435       eval sprintf (
1436         ( $self->{_result_inflator}{is_core_row}
1437           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1438           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1439           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1440         ),
1441         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1442       );
1443     }
1444   }
1445   else {
1446     my $parser_type =
1447         $self->{_result_inflator}{is_hri}       ? 'hri'
1448       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1449       :                                           'classic_nonpruning'
1450     ;
1451
1452     # $args and $attrs to _mk_row_parser are separated to delineate what is
1453     # core collapser stuff and what is dbic $rs specific
1454     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1455       eval => 1,
1456       inflate_map => $infmap,
1457       collapse => $attrs->{collapse},
1458       premultiplied => $attrs->{_main_source_premultiplied},
1459       hri_style => $self->{_result_inflator}{is_hri},
1460       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1461     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1462
1463     # column_info metadata historically hasn't been too reliable.
1464     # We need to start fixing this somehow (the collapse resolver
1465     # can't work without it). Add an explicit check for the *main*
1466     # result, hopefully this will gradually weed out such errors
1467     #
1468     # FIXME - this is a temporary kludge that reduces performance
1469     # It is however necessary for the time being
1470     my ($unrolled_non_null_cols_to_check, $err);
1471
1472     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1473
1474       $err =
1475         'Collapse aborted due to invalid ResultSource metadata - the following '
1476       . 'selections are declared non-nullable but NULLs were retrieved: '
1477       ;
1478
1479       my @violating_idx;
1480       COL: for my $i (@$check_non_null_cols) {
1481         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1482       }
1483
1484       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1485         if @violating_idx;
1486
1487       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1488     }
1489
1490     my $next_cref =
1491       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1492     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1493 sub {
1494   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1495   my @r = $cursor->next or return;
1496   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1497     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1498   }
1499   \@r
1500 }
1501 EOS
1502     : sub {
1503         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1504         my @r = $cursor->next or return;
1505         \@r
1506       }
1507     ;
1508
1509     $self->{_row_parser}{$parser_type}{cref}->(
1510       $rows,
1511       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1512     );
1513
1514     # simple in-place substitution, does not regrow $rows
1515     if ($self->{_result_inflator}{is_core_row}) {
1516       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1517     }
1518     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1519     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1520       # the inflator may be a multiplier/reductor - put it in list ctx
1521       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1522     }
1523   }
1524
1525   # The @$rows check seems odd at first - why wouldn't we want to warn
1526   # regardless? The issue is things like find() etc, where the user
1527   # *knows* only one result will come back. In these cases the ->all
1528   # is not a pessimization, but rather something we actually want
1529   carp_unique(
1530     'Unable to properly collapse has_many results in iterator mode due '
1531   . 'to order criteria - performed an eager cursor slurp underneath. '
1532   . 'Consider using ->all() instead'
1533   ) if ( ! $fetch_all and @$rows > 1 );
1534
1535   return $rows;
1536 }
1537
1538 =head2 result_source
1539
1540 =over 4
1541
1542 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1543
1544 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1545
1546 =back
1547
1548 An accessor for the primary ResultSource object from which this ResultSet
1549 is derived.
1550
1551 =head2 result_class
1552
1553 =over 4
1554
1555 =item Arguments: $result_class?
1556
1557 =item Return Value: $result_class
1558
1559 =back
1560
1561 An accessor for the class to use when creating result objects. Defaults to
1562 C<< result_source->result_class >> - which in most cases is the name of the
1563 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1564
1565 Note that changing the result_class will also remove any components
1566 that were originally loaded in the source class via
1567 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1568 in the original source class will not run.
1569
1570 =cut
1571
1572 sub result_class {
1573   my ($self, $result_class) = @_;
1574   if ($result_class) {
1575
1576     # don't fire this for an object
1577     $self->ensure_class_loaded($result_class)
1578       unless ref($result_class);
1579
1580     if ($self->get_cache) {
1581       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1582     }
1583     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1584     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1585       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1586     }
1587
1588     $self->_result_class($result_class);
1589
1590     delete $self->{_result_inflator};
1591   }
1592   $self->_result_class;
1593 }
1594
1595 =head2 count
1596
1597 =over 4
1598
1599 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1600
1601 =item Return Value: $count
1602
1603 =back
1604
1605 Performs an SQL C<COUNT> with the same query as the resultset was built
1606 with to find the number of elements. Passing arguments is equivalent to
1607 C<< $rs->search ($cond, \%attrs)->count >>
1608
1609 =cut
1610
1611 sub count {
1612   my $self = shift;
1613   return $self->search(@_)->count if @_ and defined $_[0];
1614   return scalar @{ $self->get_cache } if $self->get_cache;
1615
1616   my $attrs = { %{ $self->_resolved_attrs } };
1617
1618   # this is a little optimization - it is faster to do the limit
1619   # adjustments in software, instead of a subquery
1620   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1621
1622   my $crs;
1623   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1624     $crs = $self->_count_subq_rs ($attrs);
1625   }
1626   else {
1627     $crs = $self->_count_rs ($attrs);
1628   }
1629   my $count = $crs->next;
1630
1631   $count -= $offset if $offset;
1632   $count = $rows if $rows and $rows < $count;
1633   $count = 0 if ($count < 0);
1634
1635   return $count;
1636 }
1637
1638 =head2 count_rs
1639
1640 =over 4
1641
1642 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1643
1644 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1645
1646 =back
1647
1648 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1649 This can be very handy for subqueries:
1650
1651   ->search( { amount => $some_rs->count_rs->as_query } )
1652
1653 As with regular resultsets the SQL query will be executed only after
1654 the resultset is accessed via L</next> or L</all>. That would return
1655 the same single value obtainable via L</count>.
1656
1657 =cut
1658
1659 sub count_rs {
1660   my $self = shift;
1661   return $self->search(@_)->count_rs if @_;
1662
1663   # this may look like a lack of abstraction (count() does about the same)
1664   # but in fact an _rs *must* use a subquery for the limits, as the
1665   # software based limiting can not be ported if this $rs is to be used
1666   # in a subquery itself (i.e. ->as_query)
1667   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1668     return $self->_count_subq_rs($self->{_attrs});
1669   }
1670   else {
1671     return $self->_count_rs($self->{_attrs});
1672   }
1673 }
1674
1675 #
1676 # returns a ResultSetColumn object tied to the count query
1677 #
1678 sub _count_rs {
1679   my ($self, $attrs) = @_;
1680
1681   my $rsrc = $self->result_source;
1682
1683   my $tmp_attrs = { %$attrs };
1684   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1685   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1686
1687   # overwrite the selector (supplied by the storage)
1688   $rsrc->resultset_class->new($rsrc, {
1689     %$tmp_attrs,
1690     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1691     as => 'count',
1692   })->get_column ('count');
1693 }
1694
1695 #
1696 # same as above but uses a subquery
1697 #
1698 sub _count_subq_rs {
1699   my ($self, $attrs) = @_;
1700
1701   my $rsrc = $self->result_source;
1702
1703   my $sub_attrs = { %$attrs };
1704   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1705   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1706
1707   # if we multi-prefetch we group_by something unique, as this is what we would
1708   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1709   if ( $attrs->{collapse}  ) {
1710     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1711       $rsrc->_identifying_column_set || $self->throw_exception(
1712         'Unable to construct a unique group_by criteria properly collapsing the '
1713       . 'has_many prefetch before count()'
1714       );
1715     } ]
1716   }
1717
1718   # Calculate subquery selector
1719   if (my $g = $sub_attrs->{group_by}) {
1720
1721     my $sql_maker = $rsrc->storage->sql_maker;
1722
1723     # necessary as the group_by may refer to aliased functions
1724     my $sel_index;
1725     for my $sel (@{$attrs->{select}}) {
1726       $sel_index->{$sel->{-as}} = $sel
1727         if (ref $sel eq 'HASH' and $sel->{-as});
1728     }
1729
1730     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1731     # also look for named aggregates referred in the having clause
1732     # having often contains scalarrefs - thus parse it out entirely
1733     my @parts = @$g;
1734     if ($attrs->{having}) {
1735       local $sql_maker->{having_bind};
1736       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1737       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1738       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1739         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1740         # if we don't unset it we screw up retarded but unfortunately working
1741         # 'MAX(foo.bar)' => { '>', 3 }
1742         $sql_maker->{name_sep} = '';
1743       }
1744
1745       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1746
1747       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1748       my %seen_having;
1749
1750       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1751       # and if all fails for an utterly naive quoted scalar-with-function
1752       while ($having_sql =~ /
1753         $rquote $sep $lquote (.+?) $rquote
1754           |
1755         [\s,] \w+ \. (\w+) [\s,]
1756           |
1757         [\s,] $lquote (.+?) $rquote [\s,]
1758       /gx) {
1759         my $part = $1 || $2 || $3;  # one of them matched if we got here
1760         unless ($seen_having{$part}++) {
1761           push @parts, $part;
1762         }
1763       }
1764     }
1765
1766     for (@parts) {
1767       my $colpiece = $sel_index->{$_} || $_;
1768
1769       # unqualify join-based group_by's. Arcane but possible query
1770       # also horrible horrible hack to alias a column (not a func.)
1771       # (probably need to introduce SQLA syntax)
1772       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1773         my $as = $colpiece;
1774         $as =~ s/\./__/;
1775         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1776       }
1777       push @{$sub_attrs->{select}}, $colpiece;
1778     }
1779   }
1780   else {
1781     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1782     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1783   }
1784
1785   return $rsrc->resultset_class
1786                ->new ($rsrc, $sub_attrs)
1787                 ->as_subselect_rs
1788                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1789                   ->get_column ('count');
1790 }
1791
1792
1793 =head2 count_literal
1794
1795 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1796 should only be used in that context. See L</search_literal> for further info.
1797
1798 =over 4
1799
1800 =item Arguments: $sql_fragment, @standalone_bind_values
1801
1802 =item Return Value: $count
1803
1804 =back
1805
1806 Counts the results in a literal query. Equivalent to calling L</search_literal>
1807 with the passed arguments, then L</count>.
1808
1809 =cut
1810
1811 sub count_literal { shift->search_literal(@_)->count; }
1812
1813 =head2 all
1814
1815 =over 4
1816
1817 =item Arguments: none
1818
1819 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1820
1821 =back
1822
1823 Returns all elements in the resultset.
1824
1825 =cut
1826
1827 sub all {
1828   my $self = shift;
1829   if(@_) {
1830     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1831   }
1832
1833   delete @{$self}{qw/_stashed_rows _stashed_results/};
1834
1835   if (my $c = $self->get_cache) {
1836     return @$c;
1837   }
1838
1839   $self->cursor->reset;
1840
1841   my $objs = $self->_construct_results('fetch_all') || [];
1842
1843   $self->set_cache($objs) if $self->{attrs}{cache};
1844
1845   return @$objs;
1846 }
1847
1848 =head2 reset
1849
1850 =over 4
1851
1852 =item Arguments: none
1853
1854 =item Return Value: $self
1855
1856 =back
1857
1858 Resets the resultset's cursor, so you can iterate through the elements again.
1859 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1860 another query.
1861
1862 =cut
1863
1864 sub reset {
1865   my ($self) = @_;
1866
1867   delete @{$self}{qw/_stashed_rows _stashed_results/};
1868   $self->{all_cache_position} = 0;
1869   $self->cursor->reset;
1870   return $self;
1871 }
1872
1873 =head2 first
1874
1875 =over 4
1876
1877 =item Arguments: none
1878
1879 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1880
1881 =back
1882
1883 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1884 an object for the first result (or C<undef> if the resultset is empty).
1885
1886 =cut
1887
1888 sub first {
1889   return $_[0]->reset->next;
1890 }
1891
1892
1893 # _rs_update_delete
1894 #
1895 # Determines whether and what type of subquery is required for the $rs operation.
1896 # If grouping is necessary either supplies its own, or verifies the current one
1897 # After all is done delegates to the proper storage method.
1898
1899 sub _rs_update_delete {
1900   my ($self, $op, $values) = @_;
1901
1902   my $rsrc = $self->result_source;
1903   my $storage = $rsrc->schema->storage;
1904
1905   my $attrs = { %{$self->_resolved_attrs} };
1906
1907   my $join_classifications;
1908   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1909
1910   # do we need a subquery for any reason?
1911   my $needs_subq = (
1912     defined $existing_group_by
1913       or
1914     # if {from} is unparseable wrap a subq
1915     ref($attrs->{from}) ne 'ARRAY'
1916       or
1917     # limits call for a subq
1918     $self->_has_resolved_attr(qw/rows offset/)
1919   );
1920
1921   # simplify the joinmap, so we can further decide if a subq is necessary
1922   if (!$needs_subq and @{$attrs->{from}} > 1) {
1923
1924     ($attrs->{from}, $join_classifications) =
1925       $storage->_prune_unused_joins ($attrs);
1926
1927     # any non-pruneable non-local restricting joins imply subq
1928     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1929   }
1930
1931   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1932   $needs_subq ||= (
1933     (ref $attrs->{from}[0]) ne 'HASH'
1934       or
1935     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1936   );
1937
1938   my ($cond, $guard);
1939   # do we need anything like a subquery?
1940   if (! $needs_subq) {
1941     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1942     # a condition containing 'me' or other table prefixes will not work
1943     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1944     $cond = do {
1945       my $sqla = $rsrc->storage->sql_maker;
1946       local $sqla->{_dequalify_idents} = 1;
1947       \[ $sqla->_recurse_where($self->{cond}) ];
1948     };
1949   }
1950   else {
1951     # we got this far - means it is time to wrap a subquery
1952     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1953       sprintf(
1954         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1955         $op,
1956         $rsrc->source_name,
1957       )
1958     );
1959
1960     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1961     delete $attrs->{$_} for qw/select as collapse/;
1962     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1963
1964     # this will be consumed by the pruner waaaaay down the stack
1965     $attrs->{_force_prune_multiplying_joins} = 1;
1966
1967     my $subrs = (ref $self)->new($rsrc, $attrs);
1968
1969     if (@$idcols == 1) {
1970       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1971     }
1972     elsif ($storage->_use_multicolumn_in) {
1973       # no syntax for calling this properly yet
1974       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1975       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1976         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1977         $subrs->as_query
1978       ),
1979     }
1980     else {
1981       # if all else fails - get all primary keys and operate over a ORed set
1982       # wrap in a transaction for consistency
1983       # this is where the group_by/multiplication starts to matter
1984       if (
1985         $existing_group_by
1986           or
1987         # we do not need to check pre-multipliers, since if the premulti is there, its
1988         # parent (who is multi) will be there too
1989         keys %{ $join_classifications->{multiplying} || {} }
1990       ) {
1991         # make sure if there is a supplied group_by it matches the columns compiled above
1992         # perfectly. Anything else can not be sanely executed on most databases so croak
1993         # right then and there
1994         if ($existing_group_by) {
1995           my @current_group_by = map
1996             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1997             @$existing_group_by
1998           ;
1999
2000           if (
2001             join ("\x00", sort @current_group_by)
2002               ne
2003             join ("\x00", sort @{$attrs->{columns}} )
2004           ) {
2005             $self->throw_exception (
2006               "You have just attempted a $op operation on a resultset which does group_by"
2007               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
2008               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
2009               . ' kind of queries. Please retry the operation with a modified group_by or'
2010               . ' without using one at all.'
2011             );
2012           }
2013         }
2014
2015         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2016       }
2017
2018       $guard = $storage->txn_scope_guard;
2019
2020       for my $row ($subrs->cursor->all) {
2021         push @$cond, { map
2022           { $idcols->[$_] => $row->[$_] }
2023           (0 .. $#$idcols)
2024         };
2025       }
2026     }
2027   }
2028
2029   my $res = $cond ? $storage->$op (
2030     $rsrc,
2031     $op eq 'update' ? $values : (),
2032     $cond,
2033   ) : '0E0';
2034
2035   $guard->commit if $guard;
2036
2037   return $res;
2038 }
2039
2040 =head2 update
2041
2042 =over 4
2043
2044 =item Arguments: \%values
2045
2046 =item Return Value: $underlying_storage_rv
2047
2048 =back
2049
2050 Sets the specified columns in the resultset to the supplied values in a
2051 single query. Note that this will not run any accessor/set_column/update
2052 triggers, nor will it update any result object instances derived from this
2053 resultset (this includes the contents of the L<resultset cache|/set_cache>
2054 if any). See L</update_all> if you need to execute any on-update
2055 triggers or cascades defined either by you or a
2056 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2057
2058 The return value is a pass through of what the underlying
2059 storage backend returned, and may vary. See L<DBI/execute> for the most
2060 common case.
2061
2062 =head3 CAVEAT
2063
2064 Note that L</update> does not process/deflate any of the values passed in.
2065 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2066 ensure manually that any value passed to this method will stringify to
2067 something the RDBMS knows how to deal with. A notable example is the
2068 handling of L<DateTime> objects, for more info see:
2069 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2070
2071 =cut
2072
2073 sub update {
2074   my ($self, $values) = @_;
2075   $self->throw_exception('Values for update must be a hash')
2076     unless ref $values eq 'HASH';
2077
2078   return $self->_rs_update_delete ('update', $values);
2079 }
2080
2081 =head2 update_all
2082
2083 =over 4
2084
2085 =item Arguments: \%values
2086
2087 =item Return Value: 1
2088
2089 =back
2090
2091 Fetches all objects and updates them one at a time via
2092 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2093 triggers, while L</update> will not.
2094
2095 =cut
2096
2097 sub update_all {
2098   my ($self, $values) = @_;
2099   $self->throw_exception('Values for update_all must be a hash')
2100     unless ref $values eq 'HASH';
2101
2102   my $guard = $self->result_source->schema->txn_scope_guard;
2103   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2104   $guard->commit;
2105   return 1;
2106 }
2107
2108 =head2 delete
2109
2110 =over 4
2111
2112 =item Arguments: none
2113
2114 =item Return Value: $underlying_storage_rv
2115
2116 =back
2117
2118 Deletes the rows matching this resultset in a single query. Note that this
2119 will not run any delete triggers, nor will it alter the
2120 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2121 derived from this resultset (this includes the contents of the
2122 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2123 execute any on-delete triggers or cascades defined either by you or a
2124 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2125
2126 The return value is a pass through of what the underlying storage backend
2127 returned, and may vary. See L<DBI/execute> for the most common case.
2128
2129 =cut
2130
2131 sub delete {
2132   my $self = shift;
2133   $self->throw_exception('delete does not accept any arguments')
2134     if @_;
2135
2136   return $self->_rs_update_delete ('delete');
2137 }
2138
2139 =head2 delete_all
2140
2141 =over 4
2142
2143 =item Arguments: none
2144
2145 =item Return Value: 1
2146
2147 =back
2148
2149 Fetches all objects and deletes them one at a time via
2150 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2151 triggers, while L</delete> will not.
2152
2153 =cut
2154
2155 sub delete_all {
2156   my $self = shift;
2157   $self->throw_exception('delete_all does not accept any arguments')
2158     if @_;
2159
2160   my $guard = $self->result_source->schema->txn_scope_guard;
2161   $_->delete for $self->all;
2162   $guard->commit;
2163   return 1;
2164 }
2165
2166 =head2 populate
2167
2168 =over 4
2169
2170 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2171
2172 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2173
2174 =back
2175
2176 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2177 arrayrefs.
2178
2179 =over
2180
2181 =item NOTE
2182
2183 The context of this method call has an important effect on what is
2184 submitted to storage. In void context data is fed directly to fastpath
2185 insertion routines provided by the underlying storage (most often
2186 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2187 L<insert|DBIx::Class::Row/insert> calls on the
2188 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2189 augmentation of these methods provided by components. For example if you
2190 are using something like L<DBIx::Class::UUIDColumns> to create primary
2191 keys for you, you will find that your PKs are empty.  In this case you
2192 will have to explicitly force scalar or list context in order to create
2193 those values.
2194
2195 =back
2196
2197 In non-void (scalar or list) context, this method is simply a wrapper
2198 for L</create>. Depending on list or scalar context either a list of
2199 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2200 containing these objects is returned.
2201
2202 When supplying data in "arrayref of arrayrefs" invocation style, the
2203 first element should be a list of column names and each subsequent
2204 element should be a data value in the earlier specified column order.
2205 For example:
2206
2207   $schema->resultset("Artist")->populate([
2208     [ qw( artistid name ) ],
2209     [ 100, 'A Formally Unknown Singer' ],
2210     [ 101, 'A singer that jumped the shark two albums ago' ],
2211     [ 102, 'An actually cool singer' ],
2212   ]);
2213
2214 For the arrayref of hashrefs style each hashref should be a structure
2215 suitable for passing to L</create>. Multi-create is also permitted with
2216 this syntax.
2217
2218   $schema->resultset("Artist")->populate([
2219      { artistid => 4, name => 'Manufactured Crap', cds => [
2220         { title => 'My First CD', year => 2006 },
2221         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2222       ],
2223      },
2224      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2225         { title => 'My parents sold me to a record company', year => 2005 },
2226         { title => 'Why Am I So Ugly?', year => 2006 },
2227         { title => 'I Got Surgery and am now Popular', year => 2007 }
2228       ],
2229      },
2230   ]);
2231
2232 If you attempt a void-context multi-create as in the example above (each
2233 Artist also has the related list of CDs), and B<do not> supply the
2234 necessary autoinc foreign key information, this method will proxy to the
2235 less efficient L</create>, and then throw the Result objects away. In this
2236 case there are obviously no benefits to using this method over L</create>.
2237
2238 =cut
2239
2240 sub populate {
2241   my $self = shift;
2242
2243   my ($data, $guard);
2244
2245   # this is naive and just a quick check
2246   # the types will need to be checked more thoroughly when the
2247   # multi-source populate gets added
2248   if (ref $_[0] eq 'ARRAY') {
2249     return unless @{$_[0]};
2250
2251     $data = $_[0] if (ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY');
2252   }
2253
2254   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs')
2255     unless $data;
2256
2257   # FIXME - no cref handling
2258   # At this point assume either hashes or arrays
2259
2260   if(defined wantarray) {
2261     my @results;
2262
2263     $guard = $self->result_source->schema->storage->txn_scope_guard
2264       if ( @$data > 2 or ( @$data == 2 and ref $data->[0] eq 'ARRAY' ) );
2265
2266     if (ref $data->[0] eq 'ARRAY') {
2267       @results = map
2268         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2269         @{$data}[1 .. $#$data]
2270       ;
2271     }
2272     else {
2273       @results = map { $self->new_result($_)->insert } @$data;
2274     }
2275
2276     $guard->commit if $guard;
2277     return wantarray ? @results : \@results;
2278   }
2279
2280   # we have to deal with *possibly incomplete* related data
2281   # this means we have to walk the data structure twice
2282   # whether we want this or not
2283   # jnap, I hate you ;)
2284   my $rsrc = $self->result_source;
2285   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2286
2287   my ($colinfo, $colnames, $slices_with_rels);
2288   my $data_start = 0;
2289
2290   DATA_SLICE:
2291   for my $i (0 .. $#$data) {
2292
2293     my $current_slice_seen_rel_infos;
2294
2295 ### Determine/Supplement collists
2296 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2297     if( ref $data->[$i] eq 'ARRAY' ) {
2298
2299       # positional(!) explicit column list
2300       if ($i == 0) {
2301
2302         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2303           for 0 .. $#{$data->[0]};
2304
2305         $data_start = 1;
2306
2307         next DATA_SLICE;
2308       }
2309       else {
2310         for (values %$colinfo) {
2311           if ($_->{is_rel} ||= (
2312             $rel_info->{$_->{name}}
2313               and
2314             (
2315               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2316                 or
2317               ref $data->[$i][$_->{pos}] eq 'HASH'
2318                 or
2319               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2320             )
2321               and
2322             1
2323           )) {
2324
2325             # moar sanity check... sigh
2326             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2327               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2328                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2329                 return my $throwaway = $self->populate(@_);
2330               }
2331             }
2332
2333             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2334           }
2335         }
2336       }
2337
2338      if ($current_slice_seen_rel_infos) {
2339         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2340
2341         # this is needed further down to decide whether or not to fallback to create()
2342         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2343           for 0 .. $#$colnames;
2344       }
2345     }
2346     elsif( ref $data->[$i] eq 'HASH' ) {
2347
2348       for ( sort keys %{$data->[$i]} ) {
2349
2350         $colinfo->{$_} ||= do {
2351
2352           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2353             if $data_start; # it will be 0 on AoH, 1 on AoA
2354
2355           push @$colnames, $_;
2356
2357           # RV
2358           { pos => $#$colnames, name => $_ }
2359         };
2360
2361         if ($colinfo->{$_}{is_rel} ||= (
2362           $rel_info->{$_}
2363             and
2364           (
2365             ref $data->[$i]{$_} eq 'ARRAY'
2366               or
2367             ref $data->[$i]{$_} eq 'HASH'
2368               or
2369             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2370           )
2371             and
2372           1
2373         )) {
2374
2375           # moar sanity check... sigh
2376           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2377             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2378               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2379               return my $throwaway = $self->populate(@_);
2380             }
2381           }
2382
2383           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2384         }
2385       }
2386
2387       if ($current_slice_seen_rel_infos) {
2388         push @$slices_with_rels, $data->[$i];
2389
2390         # this is needed further down to decide whether or not to fallback to create()
2391         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2392           for keys %{$data->[$i]};
2393       }
2394     }
2395     else {
2396       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2397     }
2398
2399     if ( grep
2400       { $_->{attrs}{is_depends_on} }
2401       @{ $current_slice_seen_rel_infos || [] }
2402     ) {
2403       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2404       return my $throwaway = $self->populate(@_);
2405     }
2406   }
2407
2408   if( $slices_with_rels ) {
2409
2410     # need to exclude the rel "columns"
2411     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2412
2413     # extra sanity check - ensure the main source is in fact identifiable
2414     # the localizing of nullability is insane, but oh well... the use-case is legit
2415     my $ci = $rsrc->columns_info($colnames);
2416
2417     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2418       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2419
2420     unless( $rsrc->_identifying_column_set($ci) ) {
2421       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2422       return my $throwaway = $self->populate(@_);
2423     }
2424   }
2425
2426 ### inherit the data locked in the conditions of the resultset
2427   my ($rs_data) = $self->_merge_with_rscond({});
2428   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2429
2430   # if anything left - decompose rs_data
2431   my $rs_data_vals;
2432   if (keys %$rs_data) {
2433      push @$rs_data_vals, $rs_data->{$_}
2434       for sort keys %$rs_data;
2435   }
2436
2437 ### start work
2438   $guard = $rsrc->schema->storage->txn_scope_guard
2439     if $slices_with_rels;
2440
2441 ### main source data
2442   # FIXME - need to switch entirely to a coderef-based thing,
2443   # so that large sets aren't copied several times... I think
2444   $rsrc->storage->insert_bulk(
2445     $rsrc,
2446     [ @$colnames, sort keys %$rs_data ],
2447     [ map {
2448       ref $data->[$_] eq 'ARRAY'
2449       ? (
2450           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2451         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2452         :                     $data->[$_]
2453       )
2454       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2455     } $data_start .. $#$data ],
2456   );
2457
2458 ### do the children relationships
2459   if ( $slices_with_rels ) {
2460     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2461       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2462
2463     for my $sl (@$slices_with_rels) {
2464
2465       my ($main_proto, $main_proto_rs);
2466       for my $rel (@rels) {
2467         next unless defined $sl->{$rel};
2468
2469         $main_proto ||= {
2470           %$rs_data,
2471           (map { $_ => $sl->{$_} } @$colnames),
2472         };
2473
2474         unless (defined $colinfo->{$rel}{rs}) {
2475
2476           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2477
2478           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2479             rel_name => $rel,
2480             self_alias => "\xFE", # irrelevant
2481             foreign_alias => "\xFF", # irrelevant
2482           )->{identity_map} || {} } };
2483
2484         }
2485
2486         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2487           {
2488             $_ => { '=' =>
2489               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2490                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2491                  ->as_query
2492             }
2493           }
2494           keys %{$colinfo->{$rel}{fk_map}}
2495         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2496
2497         1;
2498       }
2499     }
2500   }
2501
2502   $guard->commit if $guard;
2503 }
2504
2505 =head2 pager
2506
2507 =over 4
2508
2509 =item Arguments: none
2510
2511 =item Return Value: L<$pager|Data::Page>
2512
2513 =back
2514
2515 Returns a L<Data::Page> object for the current resultset. Only makes
2516 sense for queries with a C<page> attribute.
2517
2518 To get the full count of entries for a paged resultset, call
2519 C<total_entries> on the L<Data::Page> object.
2520
2521 =cut
2522
2523 sub pager {
2524   my ($self) = @_;
2525
2526   return $self->{pager} if $self->{pager};
2527
2528   my $attrs = $self->{attrs};
2529   if (!defined $attrs->{page}) {
2530     $self->throw_exception("Can't create pager for non-paged rs");
2531   }
2532   elsif ($attrs->{page} <= 0) {
2533     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2534   }
2535   $attrs->{rows} ||= 10;
2536
2537   # throw away the paging flags and re-run the count (possibly
2538   # with a subselect) to get the real total count
2539   my $count_attrs = { %$attrs };
2540   delete @{$count_attrs}{qw/rows offset page pager/};
2541
2542   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2543
2544   require DBIx::Class::ResultSet::Pager;
2545   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2546     sub { $total_rs->count },  #lazy-get the total
2547     $attrs->{rows},
2548     $self->{attrs}{page},
2549   );
2550 }
2551
2552 =head2 page
2553
2554 =over 4
2555
2556 =item Arguments: $page_number
2557
2558 =item Return Value: L<$resultset|/search>
2559
2560 =back
2561
2562 Returns a resultset for the $page_number page of the resultset on which page
2563 is called, where each page contains a number of rows equal to the 'rows'
2564 attribute set on the resultset (10 by default).
2565
2566 =cut
2567
2568 sub page {
2569   my ($self, $page) = @_;
2570   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2571 }
2572
2573 =head2 new_result
2574
2575 =over 4
2576
2577 =item Arguments: \%col_data
2578
2579 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2580
2581 =back
2582
2583 Creates a new result object in the resultset's result class and returns
2584 it. The row is not inserted into the database at this point, call
2585 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2586 will tell you whether the result object has been inserted or not.
2587
2588 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2589
2590 =cut
2591
2592 sub new_result {
2593   my ($self, $values) = @_;
2594
2595   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2596     if @_ > 2;
2597
2598   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2599     unless (ref $values eq 'HASH');
2600
2601   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2602
2603   my $new = $self->result_class->new({
2604     %$merged_cond,
2605     ( @$cols_from_relations
2606       ? (-cols_from_relations => $cols_from_relations)
2607       : ()
2608     ),
2609     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2610   });
2611
2612   if (
2613     reftype($new) eq 'HASH'
2614       and
2615     ! keys %$new
2616       and
2617     blessed($new)
2618   ) {
2619     carp_unique (sprintf (
2620       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2621       $self->result_class,
2622     ));
2623   }
2624
2625   $new;
2626 }
2627
2628 # _merge_with_rscond
2629 #
2630 # Takes a simple hash of K/V data and returns its copy merged with the
2631 # condition already present on the resultset. Additionally returns an
2632 # arrayref of value/condition names, which were inferred from related
2633 # objects (this is needed for in-memory related objects)
2634 sub _merge_with_rscond {
2635   my ($self, $data) = @_;
2636
2637   my ($implied_data, @cols_from_relations);
2638
2639   my $alias = $self->{attrs}{alias};
2640
2641   if (! defined $self->{cond}) {
2642     # just massage $data below
2643   }
2644   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2645     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2646     @cols_from_relations = keys %{ $implied_data || {} };
2647   }
2648   else {
2649     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2650     $implied_data = { map {
2651       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2652     } keys %$eqs };
2653   }
2654
2655   return (
2656     { map
2657       { %{ $self->_remove_alias($_, $alias) } }
2658       # precedence must be given to passed values over values inherited from
2659       # the cond, so the order here is important.
2660       ( $implied_data||(), $data)
2661     },
2662     \@cols_from_relations
2663   );
2664 }
2665
2666 # _has_resolved_attr
2667 #
2668 # determines if the resultset defines at least one
2669 # of the attributes supplied
2670 #
2671 # used to determine if a subquery is necessary
2672 #
2673 # supports some virtual attributes:
2674 #   -join
2675 #     This will scan for any joins being present on the resultset.
2676 #     It is not a mere key-search but a deep inspection of {from}
2677 #
2678
2679 sub _has_resolved_attr {
2680   my ($self, @attr_names) = @_;
2681
2682   my $attrs = $self->_resolved_attrs;
2683
2684   my %extra_checks;
2685
2686   for my $n (@attr_names) {
2687     if (grep { $n eq $_ } (qw/-join/) ) {
2688       $extra_checks{$n}++;
2689       next;
2690     }
2691
2692     my $attr =  $attrs->{$n};
2693
2694     next if not defined $attr;
2695
2696     if (ref $attr eq 'HASH') {
2697       return 1 if keys %$attr;
2698     }
2699     elsif (ref $attr eq 'ARRAY') {
2700       return 1 if @$attr;
2701     }
2702     else {
2703       return 1 if $attr;
2704     }
2705   }
2706
2707   # a resolved join is expressed as a multi-level from
2708   return 1 if (
2709     $extra_checks{-join}
2710       and
2711     ref $attrs->{from} eq 'ARRAY'
2712       and
2713     @{$attrs->{from}} > 1
2714   );
2715
2716   return 0;
2717 }
2718
2719 # _remove_alias
2720 #
2721 # Remove the specified alias from the specified query hash. A copy is made so
2722 # the original query is not modified.
2723
2724 sub _remove_alias {
2725   my ($self, $query, $alias) = @_;
2726
2727   my %orig = %{ $query || {} };
2728   my %unaliased;
2729
2730   foreach my $key (keys %orig) {
2731     if ($key !~ /\./) {
2732       $unaliased{$key} = $orig{$key};
2733       next;
2734     }
2735     $unaliased{$1} = $orig{$key}
2736       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2737   }
2738
2739   return \%unaliased;
2740 }
2741
2742 =head2 as_query
2743
2744 =over 4
2745
2746 =item Arguments: none
2747
2748 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2749
2750 =back
2751
2752 Returns the SQL query and bind vars associated with the invocant.
2753
2754 This is generally used as the RHS for a subquery.
2755
2756 =cut
2757
2758 sub as_query {
2759   my $self = shift;
2760
2761   my $attrs = { %{ $self->_resolved_attrs } };
2762
2763   my $aq = $self->result_source->storage->_select_args_to_query (
2764     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2765   );
2766
2767   $aq;
2768 }
2769
2770 =head2 find_or_new
2771
2772 =over 4
2773
2774 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2775
2776 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2777
2778 =back
2779
2780   my $artist = $schema->resultset('Artist')->find_or_new(
2781     { artist => 'fred' }, { key => 'artists' });
2782
2783   $cd->cd_to_producer->find_or_new({ producer => $producer },
2784                                    { key => 'primary' });
2785
2786 Find an existing record from this resultset using L</find>. if none exists,
2787 instantiate a new result object and return it. The object will not be saved
2788 into your storage until you call L<DBIx::Class::Row/insert> on it.
2789
2790 You most likely want this method when looking for existing rows using a unique
2791 constraint that is not the primary key, or looking for related rows.
2792
2793 If you want objects to be saved immediately, use L</find_or_create> instead.
2794
2795 B<Note>: Make sure to read the documentation of L</find> and understand the
2796 significance of the C<key> attribute, as its lack may skew your search, and
2797 subsequently result in spurious new objects.
2798
2799 B<Note>: Take care when using C<find_or_new> with a table having
2800 columns with default values that you intend to be automatically
2801 supplied by the database (e.g. an auto_increment primary key column).
2802 In normal usage, the value of such columns should NOT be included at
2803 all in the call to C<find_or_new>, even when set to C<undef>.
2804
2805 =cut
2806
2807 sub find_or_new {
2808   my $self     = shift;
2809   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2810   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2811   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2812     return $row;
2813   }
2814   return $self->new_result($hash);
2815 }
2816
2817 =head2 create
2818
2819 =over 4
2820
2821 =item Arguments: \%col_data
2822
2823 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2824
2825 =back
2826
2827 Attempt to create a single new row or a row with multiple related rows
2828 in the table represented by the resultset (and related tables). This
2829 will not check for duplicate rows before inserting, use
2830 L</find_or_create> to do that.
2831
2832 To create one row for this resultset, pass a hashref of key/value
2833 pairs representing the columns of the table and the values you wish to
2834 store. If the appropriate relationships are set up, foreign key fields
2835 can also be passed an object representing the foreign row, and the
2836 value will be set to its primary key.
2837
2838 To create related objects, pass a hashref of related-object column values
2839 B<keyed on the relationship name>. If the relationship is of type C<multi>
2840 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2841 The process will correctly identify columns holding foreign keys, and will
2842 transparently populate them from the keys of the corresponding relation.
2843 This can be applied recursively, and will work correctly for a structure
2844 with an arbitrary depth and width, as long as the relationships actually
2845 exists and the correct column data has been supplied.
2846
2847 Instead of hashrefs of plain related data (key/value pairs), you may
2848 also pass new or inserted objects. New objects (not inserted yet, see
2849 L</new_result>), will be inserted into their appropriate tables.
2850
2851 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2852
2853 Example of creating a new row.
2854
2855   $person_rs->create({
2856     name=>"Some Person",
2857     email=>"somebody@someplace.com"
2858   });
2859
2860 Example of creating a new row and also creating rows in a related C<has_many>
2861 or C<has_one> resultset.  Note Arrayref.
2862
2863   $artist_rs->create(
2864      { artistid => 4, name => 'Manufactured Crap', cds => [
2865         { title => 'My First CD', year => 2006 },
2866         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2867       ],
2868      },
2869   );
2870
2871 Example of creating a new row and also creating a row in a related
2872 C<belongs_to> resultset. Note Hashref.
2873
2874   $cd_rs->create({
2875     title=>"Music for Silly Walks",
2876     year=>2000,
2877     artist => {
2878       name=>"Silly Musician",
2879     }
2880   });
2881
2882 =over
2883
2884 =item WARNING
2885
2886 When subclassing ResultSet never attempt to override this method. Since
2887 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2888 lot of the internals simply never call it, so your override will be
2889 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2890 or L<DBIx::Class::Row/insert> depending on how early in the
2891 L</create> process you need to intervene. See also warning pertaining to
2892 L</new>.
2893
2894 =back
2895
2896 =cut
2897
2898 sub create {
2899   #my ($self, $col_data) = @_;
2900   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2901   return shift->new_result(shift)->insert;
2902 }
2903
2904 =head2 find_or_create
2905
2906 =over 4
2907
2908 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2909
2910 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2911
2912 =back
2913
2914   $cd->cd_to_producer->find_or_create({ producer => $producer },
2915                                       { key => 'primary' });
2916
2917 Tries to find a record based on its primary key or unique constraints; if none
2918 is found, creates one and returns that instead.
2919
2920   my $cd = $schema->resultset('CD')->find_or_create({
2921     cdid   => 5,
2922     artist => 'Massive Attack',
2923     title  => 'Mezzanine',
2924     year   => 2005,
2925   });
2926
2927 Also takes an optional C<key> attribute, to search by a specific key or unique
2928 constraint. For example:
2929
2930   my $cd = $schema->resultset('CD')->find_or_create(
2931     {
2932       artist => 'Massive Attack',
2933       title  => 'Mezzanine',
2934     },
2935     { key => 'cd_artist_title' }
2936   );
2937
2938 B<Note>: Make sure to read the documentation of L</find> and understand the
2939 significance of the C<key> attribute, as its lack may skew your search, and
2940 subsequently result in spurious row creation.
2941
2942 B<Note>: Because find_or_create() reads from the database and then
2943 possibly inserts based on the result, this method is subject to a race
2944 condition. Another process could create a record in the table after
2945 the find has completed and before the create has started. To avoid
2946 this problem, use find_or_create() inside a transaction.
2947
2948 B<Note>: Take care when using C<find_or_create> with a table having
2949 columns with default values that you intend to be automatically
2950 supplied by the database (e.g. an auto_increment primary key column).
2951 In normal usage, the value of such columns should NOT be included at
2952 all in the call to C<find_or_create>, even when set to C<undef>.
2953
2954 See also L</find> and L</update_or_create>. For information on how to declare
2955 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2956
2957 If you need to know if an existing row was found or a new one created use
2958 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2959 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2960 database!
2961
2962   my $cd = $schema->resultset('CD')->find_or_new({
2963     cdid   => 5,
2964     artist => 'Massive Attack',
2965     title  => 'Mezzanine',
2966     year   => 2005,
2967   });
2968
2969   if( !$cd->in_storage ) {
2970       # do some stuff
2971       $cd->insert;
2972   }
2973
2974 =cut
2975
2976 sub find_or_create {
2977   my $self     = shift;
2978   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2979   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2980   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2981     return $row;
2982   }
2983   return $self->new_result($hash)->insert;
2984 }
2985
2986 =head2 update_or_create
2987
2988 =over 4
2989
2990 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2991
2992 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2993
2994 =back
2995
2996   $resultset->update_or_create({ col => $val, ... });
2997
2998 Like L</find_or_create>, but if a row is found it is immediately updated via
2999 C<< $found_row->update (\%col_data) >>.
3000
3001
3002 Takes an optional C<key> attribute to search on a specific unique constraint.
3003 For example:
3004
3005   # In your application
3006   my $cd = $schema->resultset('CD')->update_or_create(
3007     {
3008       artist => 'Massive Attack',
3009       title  => 'Mezzanine',
3010       year   => 1998,
3011     },
3012     { key => 'cd_artist_title' }
3013   );
3014
3015   $cd->cd_to_producer->update_or_create({
3016     producer => $producer,
3017     name => 'harry',
3018   }, {
3019     key => 'primary',
3020   });
3021
3022 B<Note>: Make sure to read the documentation of L</find> and understand the
3023 significance of the C<key> attribute, as its lack may skew your search, and
3024 subsequently result in spurious row creation.
3025
3026 B<Note>: Take care when using C<update_or_create> with a table having
3027 columns with default values that you intend to be automatically
3028 supplied by the database (e.g. an auto_increment primary key column).
3029 In normal usage, the value of such columns should NOT be included at
3030 all in the call to C<update_or_create>, even when set to C<undef>.
3031
3032 See also L</find> and L</find_or_create>. For information on how to declare
3033 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3034
3035 If you need to know if an existing row was updated or a new one created use
3036 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3037 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3038 database!
3039
3040 =cut
3041
3042 sub update_or_create {
3043   my $self = shift;
3044   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3045   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3046
3047   my $row = $self->find($cond, $attrs);
3048   if (defined $row) {
3049     $row->update($cond);
3050     return $row;
3051   }
3052
3053   return $self->new_result($cond)->insert;
3054 }
3055
3056 =head2 update_or_new
3057
3058 =over 4
3059
3060 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3061
3062 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3063
3064 =back
3065
3066   $resultset->update_or_new({ col => $val, ... });
3067
3068 Like L</find_or_new> but if a row is found it is immediately updated via
3069 C<< $found_row->update (\%col_data) >>.
3070
3071 For example:
3072
3073   # In your application
3074   my $cd = $schema->resultset('CD')->update_or_new(
3075     {
3076       artist => 'Massive Attack',
3077       title  => 'Mezzanine',
3078       year   => 1998,
3079     },
3080     { key => 'cd_artist_title' }
3081   );
3082
3083   if ($cd->in_storage) {
3084       # the cd was updated
3085   }
3086   else {
3087       # the cd is not yet in the database, let's insert it
3088       $cd->insert;
3089   }
3090
3091 B<Note>: Make sure to read the documentation of L</find> and understand the
3092 significance of the C<key> attribute, as its lack may skew your search, and
3093 subsequently result in spurious new objects.
3094
3095 B<Note>: Take care when using C<update_or_new> with a table having
3096 columns with default values that you intend to be automatically
3097 supplied by the database (e.g. an auto_increment primary key column).
3098 In normal usage, the value of such columns should NOT be included at
3099 all in the call to C<update_or_new>, even when set to C<undef>.
3100
3101 See also L</find>, L</find_or_create> and L</find_or_new>.
3102
3103 =cut
3104
3105 sub update_or_new {
3106     my $self  = shift;
3107     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3108     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3109
3110     my $row = $self->find( $cond, $attrs );
3111     if ( defined $row ) {
3112         $row->update($cond);
3113         return $row;
3114     }
3115
3116     return $self->new_result($cond);
3117 }
3118
3119 =head2 get_cache
3120
3121 =over 4
3122
3123 =item Arguments: none
3124
3125 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3126
3127 =back
3128
3129 Gets the contents of the cache for the resultset, if the cache is set.
3130
3131 The cache is populated either by using the L</prefetch> attribute to
3132 L</search> or by calling L</set_cache>.
3133
3134 =cut
3135
3136 sub get_cache {
3137   shift->{all_cache};
3138 }
3139
3140 =head2 set_cache
3141
3142 =over 4
3143
3144 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3145
3146 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3147
3148 =back
3149
3150 Sets the contents of the cache for the resultset. Expects an arrayref
3151 of objects of the same class as those produced by the resultset. Note that
3152 if the cache is set, the resultset will return the cached objects rather
3153 than re-querying the database even if the cache attr is not set.
3154
3155 The contents of the cache can also be populated by using the
3156 L</prefetch> attribute to L</search>.
3157
3158 =cut
3159
3160 sub set_cache {
3161   my ( $self, $data ) = @_;
3162   $self->throw_exception("set_cache requires an arrayref")
3163       if defined($data) && (ref $data ne 'ARRAY');
3164   $self->{all_cache} = $data;
3165 }
3166
3167 =head2 clear_cache
3168
3169 =over 4
3170
3171 =item Arguments: none
3172
3173 =item Return Value: undef
3174
3175 =back
3176
3177 Clears the cache for the resultset.
3178
3179 =cut
3180
3181 sub clear_cache {
3182   shift->set_cache(undef);
3183 }
3184
3185 =head2 is_paged
3186
3187 =over 4
3188
3189 =item Arguments: none
3190
3191 =item Return Value: true, if the resultset has been paginated
3192
3193 =back
3194
3195 =cut
3196
3197 sub is_paged {
3198   my ($self) = @_;
3199   return !!$self->{attrs}{page};
3200 }
3201
3202 =head2 is_ordered
3203
3204 =over 4
3205
3206 =item Arguments: none
3207
3208 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3209
3210 =back
3211
3212 =cut
3213
3214 sub is_ordered {
3215   my ($self) = @_;
3216   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3217 }
3218
3219 =head2 related_resultset
3220
3221 =over 4
3222
3223 =item Arguments: $rel_name
3224
3225 =item Return Value: L<$resultset|/search>
3226
3227 =back
3228
3229 Returns a related resultset for the supplied relationship name.
3230
3231   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3232
3233 =cut
3234
3235 sub related_resultset {
3236   my ($self, $rel) = @_;
3237
3238   return $self->{related_resultsets}{$rel}
3239     if defined $self->{related_resultsets}{$rel};
3240
3241   return $self->{related_resultsets}{$rel} = do {
3242     my $rsrc = $self->result_source;
3243     my $rel_info = $rsrc->relationship_info($rel);
3244
3245     $self->throw_exception(
3246       "search_related: result source '" . $rsrc->source_name .
3247         "' has no such relationship $rel")
3248       unless $rel_info;
3249
3250     my $attrs = $self->_chain_relationship($rel);
3251
3252     my $join_count = $attrs->{seen_join}{$rel};
3253
3254     my $alias = $self->result_source->storage
3255         ->relname_to_table_alias($rel, $join_count);
3256
3257     # since this is search_related, and we already slid the select window inwards
3258     # (the select/as attrs were deleted in the beginning), we need to flip all
3259     # left joins to inner, so we get the expected results
3260     # read the comment on top of the actual function to see what this does
3261     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3262
3263
3264     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3265     delete @{$attrs}{qw(result_class alias)};
3266
3267     my $rel_source = $rsrc->related_source($rel);
3268
3269     my $new = do {
3270
3271       # The reason we do this now instead of passing the alias to the
3272       # search_rs below is that if you wrap/overload resultset on the
3273       # source you need to know what alias it's -going- to have for things
3274       # to work sanely (e.g. RestrictWithObject wants to be able to add
3275       # extra query restrictions, and these may need to be $alias.)
3276
3277       my $rel_attrs = $rel_source->resultset_attributes;
3278       local $rel_attrs->{alias} = $alias;
3279
3280       $rel_source->resultset
3281                  ->search_rs(
3282                      undef, {
3283                        %$attrs,
3284                        where => $attrs->{where},
3285                    });
3286     };
3287
3288     if (my $cache = $self->get_cache) {
3289       my @related_cache = map
3290         { $_->related_resultset($rel)->get_cache || () }
3291         @$cache
3292       ;
3293
3294       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3295     }
3296
3297     $new;
3298   };
3299 }
3300
3301 =head2 current_source_alias
3302
3303 =over 4
3304
3305 =item Arguments: none
3306
3307 =item Return Value: $source_alias
3308
3309 =back
3310
3311 Returns the current table alias for the result source this resultset is built
3312 on, that will be used in the SQL query. Usually it is C<me>.
3313
3314 Currently the source alias that refers to the result set returned by a
3315 L</search>/L</find> family method depends on how you got to the resultset: it's
3316 C<me> by default, but eg. L</search_related> aliases it to the related result
3317 source name (and keeps C<me> referring to the original result set). The long
3318 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3319 (and make this method unnecessary).
3320
3321 Thus it's currently necessary to use this method in predefined queries (see
3322 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3323 source alias of the current result set:
3324
3325   # in a result set class
3326   sub modified_by {
3327     my ($self, $user) = @_;
3328
3329     my $me = $self->current_source_alias;
3330
3331     return $self->search({
3332       "$me.modified" => $user->id,
3333     });
3334   }
3335
3336 =cut
3337
3338 sub current_source_alias {
3339   return (shift->{attrs} || {})->{alias} || 'me';
3340 }
3341
3342 =head2 as_subselect_rs
3343
3344 =over 4
3345
3346 =item Arguments: none
3347
3348 =item Return Value: L<$resultset|/search>
3349
3350 =back
3351
3352 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3353 "virtual view" by including it as a subquery within the from clause.  From this
3354 point on, any joined tables are inaccessible to ->search on the resultset (as if
3355 it were simply where-filtered without joins).  For example:
3356
3357  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3358
3359  # 'x' now pollutes the query namespace
3360
3361  # So the following works as expected
3362  my $ok_rs = $rs->search({'x.other' => 1});
3363
3364  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3365  # def) we look for one row with contradictory terms and join in another table
3366  # (aliased 'x_2') which we never use
3367  my $broken_rs = $rs->search({'x.name' => 'def'});
3368
3369  my $rs2 = $rs->as_subselect_rs;
3370
3371  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3372  my $not_joined_rs = $rs2->search({'x.other' => 1});
3373
3374  # works as expected: finds a 'table' row related to two x rows (abc and def)
3375  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3376
3377 Another example of when one might use this would be to select a subset of
3378 columns in a group by clause:
3379
3380  my $rs = $schema->resultset('Bar')->search(undef, {
3381    group_by => [qw{ id foo_id baz_id }],
3382  })->as_subselect_rs->search(undef, {
3383    columns => [qw{ id foo_id }]
3384  });
3385
3386 In the above example normally columns would have to be equal to the group by,
3387 but because we isolated the group by into a subselect the above works.
3388
3389 =cut
3390
3391 sub as_subselect_rs {
3392   my $self = shift;
3393
3394   my $attrs = $self->_resolved_attrs;
3395
3396   my $fresh_rs = (ref $self)->new (
3397     $self->result_source
3398   );
3399
3400   # these pieces will be locked in the subquery
3401   delete $fresh_rs->{cond};
3402   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3403
3404   return $fresh_rs->search( {}, {
3405     from => [{
3406       $attrs->{alias} => $self->as_query,
3407       -alias  => $attrs->{alias},
3408       -rsrc   => $self->result_source,
3409     }],
3410     alias => $attrs->{alias},
3411   });
3412 }
3413
3414 # This code is called by search_related, and makes sure there
3415 # is clear separation between the joins before, during, and
3416 # after the relationship. This information is needed later
3417 # in order to properly resolve prefetch aliases (any alias
3418 # with a relation_chain_depth less than the depth of the
3419 # current prefetch is not considered)
3420 #
3421 # The increments happen twice per join. An even number means a
3422 # relationship specified via a search_related, whereas an odd
3423 # number indicates a join/prefetch added via attributes
3424 #
3425 # Also this code will wrap the current resultset (the one we
3426 # chain to) in a subselect IFF it contains limiting attributes
3427 sub _chain_relationship {
3428   my ($self, $rel) = @_;
3429   my $source = $self->result_source;
3430   my $attrs = { %{$self->{attrs}||{}} };
3431
3432   # we need to take the prefetch the attrs into account before we
3433   # ->_resolve_join as otherwise they get lost - captainL
3434   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3435
3436   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3437
3438   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3439
3440   my $from;
3441   my @force_subq_attrs = qw/offset rows group_by having/;
3442
3443   if (
3444     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3445       ||
3446     $self->_has_resolved_attr (@force_subq_attrs)
3447   ) {
3448     # Nuke the prefetch (if any) before the new $rs attrs
3449     # are resolved (prefetch is useless - we are wrapping
3450     # a subquery anyway).
3451     my $rs_copy = $self->search;
3452     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3453       $rs_copy->{attrs}{join},
3454       delete $rs_copy->{attrs}{prefetch},
3455     );
3456
3457     $from = [{
3458       -rsrc   => $source,
3459       -alias  => $attrs->{alias},
3460       $attrs->{alias} => $rs_copy->as_query,
3461     }];
3462     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3463     $seen->{-relation_chain_depth} = 0;
3464   }
3465   elsif ($attrs->{from}) {  #shallow copy suffices
3466     $from = [ @{$attrs->{from}} ];
3467   }
3468   else {
3469     $from = [{
3470       -rsrc  => $source,
3471       -alias => $attrs->{alias},
3472       $attrs->{alias} => $source->from,
3473     }];
3474   }
3475
3476   my $jpath = ($seen->{-relation_chain_depth})
3477     ? $from->[-1][0]{-join_path}
3478     : [];
3479
3480   my @requested_joins = $source->_resolve_join(
3481     $join,
3482     $attrs->{alias},
3483     $seen,
3484     $jpath,
3485   );
3486
3487   push @$from, @requested_joins;
3488
3489   $seen->{-relation_chain_depth}++;
3490
3491   # if $self already had a join/prefetch specified on it, the requested
3492   # $rel might very well be already included. What we do in this case
3493   # is effectively a no-op (except that we bump up the chain_depth on
3494   # the join in question so we could tell it *is* the search_related)
3495   my $already_joined;
3496
3497   # we consider the last one thus reverse
3498   for my $j (reverse @requested_joins) {
3499     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3500     if ($rel eq $last_j) {
3501       $j->[0]{-relation_chain_depth}++;
3502       $already_joined++;
3503       last;
3504     }
3505   }
3506
3507   unless ($already_joined) {
3508     push @$from, $source->_resolve_join(
3509       $rel,
3510       $attrs->{alias},
3511       $seen,
3512       $jpath,
3513     );
3514   }
3515
3516   $seen->{-relation_chain_depth}++;
3517
3518   return {%$attrs, from => $from, seen_join => $seen};
3519 }
3520
3521 sub _resolved_attrs {
3522   my $self = shift;
3523   return $self->{_attrs} if $self->{_attrs};
3524
3525   my $attrs  = { %{ $self->{attrs} || {} } };
3526   my $source = $attrs->{result_source} = $self->result_source;
3527   my $alias  = $attrs->{alias};
3528
3529   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3530     if $attrs->{collapse} and $attrs->{distinct};
3531
3532   # default selection list
3533   $attrs->{columns} = [ $source->columns ]
3534     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3535
3536   # merge selectors together
3537   for (qw/columns select as/) {
3538     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3539       if $attrs->{$_} or $attrs->{"+$_"};
3540   }
3541
3542   # disassemble columns
3543   my (@sel, @as);
3544   if (my $cols = delete $attrs->{columns}) {
3545     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3546       if (ref $c eq 'HASH') {
3547         for my $as (sort keys %$c) {
3548           push @sel, $c->{$as};
3549           push @as, $as;
3550         }
3551       }
3552       else {
3553         push @sel, $c;
3554         push @as, $c;
3555       }
3556     }
3557   }
3558
3559   # when trying to weed off duplicates later do not go past this point -
3560   # everything added from here on is unbalanced "anyone's guess" stuff
3561   my $dedup_stop_idx = $#as;
3562
3563   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3564     if $attrs->{as};
3565   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3566     if $attrs->{select};
3567
3568   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3569   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3570
3571   # disqualify all $alias.col as-bits (inflate-map mandated)
3572   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3573
3574   # de-duplicate the result (remove *identical* select/as pairs)
3575   # and also die on duplicate {as} pointing to different {select}s
3576   # not using a c-style for as the condition is prone to shrinkage
3577   my $seen;
3578   my $i = 0;
3579   while ($i <= $dedup_stop_idx) {
3580     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3581       splice @sel, $i, 1;
3582       splice @as, $i, 1;
3583       $dedup_stop_idx--;
3584     }
3585     elsif ($seen->{$as[$i]}++) {
3586       $self->throw_exception(
3587         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3588       );
3589     }
3590     else {
3591       $i++;
3592     }
3593   }
3594
3595   $attrs->{select} = \@sel;
3596   $attrs->{as} = \@as;
3597
3598   $attrs->{from} ||= [{
3599     -rsrc   => $source,
3600     -alias  => $self->{attrs}{alias},
3601     $self->{attrs}{alias} => $source->from,
3602   }];
3603
3604   if ( $attrs->{join} || $attrs->{prefetch} ) {
3605
3606     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3607       if ref $attrs->{from} ne 'ARRAY';
3608
3609     my $join = (delete $attrs->{join}) || {};
3610
3611     if ( defined $attrs->{prefetch} ) {
3612       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3613     }
3614
3615     $attrs->{from} =    # have to copy here to avoid corrupting the original
3616       [
3617         @{ $attrs->{from} },
3618         $source->_resolve_join(
3619           $join,
3620           $alias,
3621           { %{ $attrs->{seen_join} || {} } },
3622           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3623             ? $attrs->{from}[-1][0]{-join_path}
3624             : []
3625           ,
3626         )
3627       ];
3628   }
3629
3630   if ( defined $attrs->{order_by} ) {
3631     $attrs->{order_by} = (
3632       ref( $attrs->{order_by} ) eq 'ARRAY'
3633       ? [ @{ $attrs->{order_by} } ]
3634       : [ $attrs->{order_by} || () ]
3635     );
3636   }
3637
3638   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3639     $attrs->{group_by} = [ $attrs->{group_by} ];
3640   }
3641
3642
3643   # generate selections based on the prefetch helper
3644   my ($prefetch, @prefetch_select, @prefetch_as);
3645   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3646     if defined $attrs->{prefetch};
3647
3648   if ($prefetch) {
3649
3650     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3651       if $attrs->{_dark_selector};
3652
3653     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3654       if defined $attrs->{collapse} and ! $attrs->{collapse};
3655
3656     $attrs->{collapse} = 1;
3657
3658     # this is a separate structure (we don't look in {from} directly)
3659     # as the resolver needs to shift things off the lists to work
3660     # properly (identical-prefetches on different branches)
3661     my $join_map = {};
3662     if (ref $attrs->{from} eq 'ARRAY') {
3663
3664       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3665
3666       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3667         next unless $j->[0]{-alias};
3668         next unless $j->[0]{-join_path};
3669         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3670
3671         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3672
3673         my $p = $join_map;
3674         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3675         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3676       }
3677     }
3678
3679     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3680
3681     # save these for after distinct resolution
3682     @prefetch_select = map { $_->[0] } @prefetch;
3683     @prefetch_as = map { $_->[1] } @prefetch;
3684   }
3685
3686   # run through the resulting joinstructure (starting from our current slot)
3687   # and unset collapse if proven unnecessary
3688   #
3689   # also while we are at it find out if the current root source has
3690   # been premultiplied by previous related_source chaining
3691   #
3692   # this allows to predict whether a root object with all other relation
3693   # data set to NULL is in fact unique
3694   if ($attrs->{collapse}) {
3695
3696     if (ref $attrs->{from} eq 'ARRAY') {
3697
3698       if (@{$attrs->{from}} == 1) {
3699         # no joins - no collapse
3700         $attrs->{collapse} = 0;
3701       }
3702       else {
3703         # find where our table-spec starts
3704         my @fromlist = @{$attrs->{from}};
3705         while (@fromlist) {
3706           my $t = shift @fromlist;
3707
3708           my $is_multi;
3709           # me vs join from-spec distinction - a ref means non-root
3710           if (ref $t eq 'ARRAY') {
3711             $t = $t->[0];
3712             $is_multi ||= ! $t->{-is_single};
3713           }
3714           last if ($t->{-alias} && $t->{-alias} eq $alias);
3715           $attrs->{_main_source_premultiplied} ||= $is_multi;
3716         }
3717
3718         # no non-singles remaining, nor any premultiplication - nothing to collapse
3719         if (
3720           ! $attrs->{_main_source_premultiplied}
3721             and
3722           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3723         ) {
3724           $attrs->{collapse} = 0;
3725         }
3726       }
3727     }
3728
3729     else {
3730       # if we can not analyze the from - err on the side of safety
3731       $attrs->{_main_source_premultiplied} = 1;
3732     }
3733   }
3734
3735   # generate the distinct induced group_by before injecting the prefetched select/as parts
3736   if (delete $attrs->{distinct}) {
3737     if ($attrs->{group_by}) {
3738       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3739     }
3740     else {
3741       $attrs->{_grouped_by_distinct} = 1;
3742       # distinct affects only the main selection part, not what prefetch may add below
3743       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3744
3745       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3746       # The thinking is: if we are collapsing the subquerying prefetch engine will
3747       # rip stuff apart for us anyway, and we do not want to have a potentially
3748       # function-converted external order_by
3749       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3750       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3751     }
3752   }
3753
3754   # inject prefetch-bound selection (if any)
3755   push @{$attrs->{select}}, @prefetch_select;
3756   push @{$attrs->{as}}, @prefetch_as;
3757
3758   $attrs->{_simple_passthrough_construction} = !(
3759     $attrs->{collapse}
3760       or
3761     grep { $_ =~ /\./ } @{$attrs->{as}}
3762   );
3763
3764   # if both page and offset are specified, produce a combined offset
3765   # even though it doesn't make much sense, this is what pre 081xx has
3766   # been doing
3767   if (my $page = delete $attrs->{page}) {
3768     $attrs->{offset} =
3769       ($attrs->{rows} * ($page - 1))
3770             +
3771       ($attrs->{offset} || 0)
3772     ;
3773   }
3774
3775   return $self->{_attrs} = $attrs;
3776 }
3777
3778 sub _rollout_attr {
3779   my ($self, $attr) = @_;
3780
3781   if (ref $attr eq 'HASH') {
3782     return $self->_rollout_hash($attr);
3783   } elsif (ref $attr eq 'ARRAY') {
3784     return $self->_rollout_array($attr);
3785   } else {
3786     return [$attr];
3787   }
3788 }
3789
3790 sub _rollout_array {
3791   my ($self, $attr) = @_;
3792
3793   my @rolled_array;
3794   foreach my $element (@{$attr}) {
3795     if (ref $element eq 'HASH') {
3796       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3797     } elsif (ref $element eq 'ARRAY') {
3798       #  XXX - should probably recurse here
3799       push( @rolled_array, @{$self->_rollout_array($element)} );
3800     } else {
3801       push( @rolled_array, $element );
3802     }
3803   }
3804   return \@rolled_array;
3805 }
3806
3807 sub _rollout_hash {
3808   my ($self, $attr) = @_;
3809
3810   my @rolled_array;
3811   foreach my $key (keys %{$attr}) {
3812     push( @rolled_array, { $key => $attr->{$key} } );
3813   }
3814   return \@rolled_array;
3815 }
3816
3817 sub _calculate_score {
3818   my ($self, $a, $b) = @_;
3819
3820   if (defined $a xor defined $b) {
3821     return 0;
3822   }
3823   elsif (not defined $a) {
3824     return 1;
3825   }
3826
3827   if (ref $b eq 'HASH') {
3828     my ($b_key) = keys %{$b};
3829     if (ref $a eq 'HASH') {
3830       my ($a_key) = keys %{$a};
3831       if ($a_key eq $b_key) {
3832         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3833       } else {
3834         return 0;
3835       }
3836     } else {
3837       return ($a eq $b_key) ? 1 : 0;
3838     }
3839   } else {
3840     if (ref $a eq 'HASH') {
3841       my ($a_key) = keys %{$a};
3842       return ($b eq $a_key) ? 1 : 0;
3843     } else {
3844       return ($b eq $a) ? 1 : 0;
3845     }
3846   }
3847 }
3848
3849 sub _merge_joinpref_attr {
3850   my ($self, $orig, $import) = @_;
3851
3852   return $import unless defined($orig);
3853   return $orig unless defined($import);
3854
3855   $orig = $self->_rollout_attr($orig);
3856   $import = $self->_rollout_attr($import);
3857
3858   my $seen_keys;
3859   foreach my $import_element ( @{$import} ) {
3860     # find best candidate from $orig to merge $b_element into
3861     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3862     foreach my $orig_element ( @{$orig} ) {
3863       my $score = $self->_calculate_score( $orig_element, $import_element );
3864       if ($score > $best_candidate->{score}) {
3865         $best_candidate->{position} = $position;
3866         $best_candidate->{score} = $score;
3867       }
3868       $position++;
3869     }
3870     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3871     $import_key = '' if not defined $import_key;
3872
3873     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3874       push( @{$orig}, $import_element );
3875     } else {
3876       my $orig_best = $orig->[$best_candidate->{position}];
3877       # merge orig_best and b_element together and replace original with merged
3878       if (ref $orig_best ne 'HASH') {
3879         $orig->[$best_candidate->{position}] = $import_element;
3880       } elsif (ref $import_element eq 'HASH') {
3881         my ($key) = keys %{$orig_best};
3882         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3883       }
3884     }
3885     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3886   }
3887
3888   return @$orig ? $orig : ();
3889 }
3890
3891 {
3892   my $hm;
3893
3894   sub _merge_attr {
3895     $hm ||= do {
3896       require Hash::Merge;
3897       my $hm = Hash::Merge->new;
3898
3899       $hm->specify_behavior({
3900         SCALAR => {
3901           SCALAR => sub {
3902             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3903
3904             if ($defl xor $defr) {
3905               return [ $defl ? $_[0] : $_[1] ];
3906             }
3907             elsif (! $defl) {
3908               return [];
3909             }
3910             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3911               return [ $_[0] ];
3912             }
3913             else {
3914               return [$_[0], $_[1]];
3915             }
3916           },
3917           ARRAY => sub {
3918             return $_[1] if !defined $_[0];
3919             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3920             return [$_[0], @{$_[1]}]
3921           },
3922           HASH  => sub {
3923             return [] if !defined $_[0] and !keys %{$_[1]};
3924             return [ $_[1] ] if !defined $_[0];
3925             return [ $_[0] ] if !keys %{$_[1]};
3926             return [$_[0], $_[1]]
3927           },
3928         },
3929         ARRAY => {
3930           SCALAR => sub {
3931             return $_[0] if !defined $_[1];
3932             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3933             return [@{$_[0]}, $_[1]]
3934           },
3935           ARRAY => sub {
3936             my @ret = @{$_[0]} or return $_[1];
3937             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3938             my %idx = map { $_ => 1 } @ret;
3939             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3940             \@ret;
3941           },
3942           HASH => sub {
3943             return [ $_[1] ] if ! @{$_[0]};
3944             return $_[0] if !keys %{$_[1]};
3945             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3946             return [ @{$_[0]}, $_[1] ];
3947           },
3948         },
3949         HASH => {
3950           SCALAR => sub {
3951             return [] if !keys %{$_[0]} and !defined $_[1];
3952             return [ $_[0] ] if !defined $_[1];
3953             return [ $_[1] ] if !keys %{$_[0]};
3954             return [$_[0], $_[1]]
3955           },
3956           ARRAY => sub {
3957             return [] if !keys %{$_[0]} and !@{$_[1]};
3958             return [ $_[0] ] if !@{$_[1]};
3959             return $_[1] if !keys %{$_[0]};
3960             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3961             return [ $_[0], @{$_[1]} ];
3962           },
3963           HASH => sub {
3964             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3965             return [ $_[0] ] if !keys %{$_[1]};
3966             return [ $_[1] ] if !keys %{$_[0]};
3967             return [ $_[0] ] if $_[0] eq $_[1];
3968             return [ $_[0], $_[1] ];
3969           },
3970         }
3971       } => 'DBIC_RS_ATTR_MERGER');
3972       $hm;
3973     };
3974
3975     return $hm->merge ($_[1], $_[2]);
3976   }
3977 }
3978
3979 sub STORABLE_freeze {
3980   my ($self, $cloning) = @_;
3981   my $to_serialize = { %$self };
3982
3983   # A cursor in progress can't be serialized (and would make little sense anyway)
3984   # the parser can be regenerated (and can't be serialized)
3985   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3986
3987   # nor is it sensical to store a not-yet-fired-count pager
3988   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3989     delete $to_serialize->{pager};
3990   }
3991
3992   Storable::nfreeze($to_serialize);
3993 }
3994
3995 # need this hook for symmetry
3996 sub STORABLE_thaw {
3997   my ($self, $cloning, $serialized) = @_;
3998
3999   %$self = %{ Storable::thaw($serialized) };
4000
4001   $self;
4002 }
4003
4004
4005 =head2 throw_exception
4006
4007 See L<DBIx::Class::Schema/throw_exception> for details.
4008
4009 =cut
4010
4011 sub throw_exception {
4012   my $self=shift;
4013
4014   if (ref $self and my $rsrc = $self->result_source) {
4015     $rsrc->throw_exception(@_)
4016   }
4017   else {
4018     DBIx::Class::Exception->throw(@_);
4019   }
4020 }
4021
4022 1;
4023
4024 __END__
4025
4026 # XXX: FIXME: Attributes docs need clearing up
4027
4028 =head1 ATTRIBUTES
4029
4030 Attributes are used to refine a ResultSet in various ways when
4031 searching for data. They can be passed to any method which takes an
4032 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4033 L</count>.
4034
4035 Default attributes can be set on the result class using
4036 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4037 the CAVEATS on that feature before using it!)
4038
4039 These are in no particular order:
4040
4041 =head2 order_by
4042
4043 =over 4
4044
4045 =item Value: ( $order_by | \@order_by | \%order_by )
4046
4047 =back
4048
4049 Which column(s) to order the results by.
4050
4051 [The full list of suitable values is documented in
4052 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4053 common options.]
4054
4055 If a single column name, or an arrayref of names is supplied, the
4056 argument is passed through directly to SQL. The hashref syntax allows
4057 for connection-agnostic specification of ordering direction:
4058
4059  For descending order:
4060
4061   order_by => { -desc => [qw/col1 col2 col3/] }
4062
4063  For explicit ascending order:
4064
4065   order_by => { -asc => 'col' }
4066
4067 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4068 supported, although you are strongly encouraged to use the hashref
4069 syntax as outlined above.
4070
4071 =head2 columns
4072
4073 =over 4
4074
4075 =item Value: \@columns | \%columns | $column
4076
4077 =back
4078
4079 Shortcut to request a particular set of columns to be retrieved. Each
4080 column spec may be a string (a table column name), or a hash (in which
4081 case the key is the C<as> value, and the value is used as the C<select>
4082 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4083 it and sets C<select> from that, then auto-populates C<as> from
4084 C<select> as normal. (You may also use the C<cols> attribute, as in
4085 earlier versions of DBIC, but this is deprecated)
4086
4087 Essentially C<columns> does the same as L</select> and L</as>.
4088
4089     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4090
4091 is the same as
4092
4093     select => [qw(some_column another_column)],
4094     as     => [qw(some_column dbic_slot)]
4095
4096 If you want to individually retrieve related columns (in essence perform
4097 manual prefetch) you have to make sure to specify the correct inflation slot
4098 chain such that it matches existing relationships:
4099
4100     my $rs = $schema->resultset('Artist')->search({}, {
4101         # required to tell DBIC to collapse has_many relationships
4102         collapse => 1,
4103         join     => { cds => 'tracks'},
4104         '+columns'  => {
4105           'cds.cdid'         => 'cds.cdid',
4106           'cds.tracks.title' => 'tracks.title',
4107         },
4108     });
4109
4110 =head2 +columns
4111
4112 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4113 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4114 with a unary plus operator before it, which is the same as simply C<columns>.
4115
4116 =over 4
4117
4118 =item Value: \@extra_columns
4119
4120 =back
4121
4122 Indicates additional columns to be selected from storage. Works the same as
4123 L</columns> but adds columns to the current selection. (You may also use the
4124 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4125 deprecated)
4126
4127   $schema->resultset('CD')->search(undef, {
4128     '+columns' => ['artist.name'],
4129     join => ['artist']
4130   });
4131
4132 would return all CDs and include a 'name' column to the information
4133 passed to object inflation. Note that the 'artist' is the name of the
4134 column (or relationship) accessor, and 'name' is the name of the column
4135 accessor in the related table.
4136
4137 =head2 select
4138
4139 =over 4
4140
4141 =item Value: \@select_columns
4142
4143 =back
4144
4145 Indicates which columns should be selected from the storage. You can use
4146 column names, or in the case of RDBMS back ends, function or stored procedure
4147 names:
4148
4149   $rs = $schema->resultset('Employee')->search(undef, {
4150     select => [
4151       'name',
4152       { count => 'employeeid' },
4153       { max => { length => 'name' }, -as => 'longest_name' }
4154     ]
4155   });
4156
4157   # Equivalent SQL
4158   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4159
4160 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4161 use L</select>, to instruct DBIx::Class how to store the result of the column.
4162 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4163 identifier aliasing. You can however alias a function, so you can use it in
4164 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4165 attribute> supplied as shown in the example above.
4166
4167 =head2 +select
4168
4169 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4170 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4171 with a unary plus operator before it, which is the same as simply C<select>.
4172
4173 =over 4
4174
4175 =item Value: \@extra_select_columns
4176
4177 =back
4178
4179 Indicates additional columns to be selected from storage.  Works the same as
4180 L</select> but adds columns to the current selection, instead of specifying
4181 a new explicit list.
4182
4183 =head2 as
4184
4185 =over 4
4186
4187 =item Value: \@inflation_names
4188
4189 =back
4190
4191 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4192 slot name in which the column value will be stored within the
4193 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4194 identifier by the C<get_column> method (or via the object accessor B<if one
4195 with the same name already exists>) as shown below. The L</as> attribute has
4196 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4197
4198   $rs = $schema->resultset('Employee')->search(undef, {
4199     select => [
4200       'name',
4201       { count => 'employeeid' },
4202       { max => { length => 'name' }, -as => 'longest_name' }
4203     ],
4204     as => [qw/
4205       name
4206       employee_count
4207       max_name_length
4208     /],
4209   });
4210
4211 If the object against which the search is performed already has an accessor
4212 matching a column name specified in C<as>, the value can be retrieved using
4213 the accessor as normal:
4214
4215   my $name = $employee->name();
4216
4217 If on the other hand an accessor does not exist in the object, you need to
4218 use C<get_column> instead:
4219
4220   my $employee_count = $employee->get_column('employee_count');
4221
4222 You can create your own accessors if required - see
4223 L<DBIx::Class::Manual::Cookbook> for details.
4224
4225 =head2 +as
4226
4227 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4228 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4229 with a unary plus operator before it, which is the same as simply C<as>.
4230
4231 =over 4
4232
4233 =item Value: \@extra_inflation_names
4234
4235 =back
4236
4237 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4238
4239 =head2 join
4240
4241 =over 4
4242
4243 =item Value: ($rel_name | \@rel_names | \%rel_names)
4244
4245 =back
4246
4247 Contains a list of relationships that should be joined for this query.  For
4248 example:
4249
4250   # Get CDs by Nine Inch Nails
4251   my $rs = $schema->resultset('CD')->search(
4252     { 'artist.name' => 'Nine Inch Nails' },
4253     { join => 'artist' }
4254   );
4255
4256 Can also contain a hash reference to refer to the other relation's relations.
4257 For example:
4258
4259   package MyApp::Schema::Track;
4260   use base qw/DBIx::Class/;
4261   __PACKAGE__->table('track');
4262   __PACKAGE__->add_columns(qw/trackid cd position title/);
4263   __PACKAGE__->set_primary_key('trackid');
4264   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4265   1;
4266
4267   # In your application
4268   my $rs = $schema->resultset('Artist')->search(
4269     { 'track.title' => 'Teardrop' },
4270     {
4271       join     => { cd => 'track' },
4272       order_by => 'artist.name',
4273     }
4274   );
4275
4276 You need to use the relationship (not the table) name in  conditions,
4277 because they are aliased as such. The current table is aliased as "me", so
4278 you need to use me.column_name in order to avoid ambiguity. For example:
4279
4280   # Get CDs from 1984 with a 'Foo' track
4281   my $rs = $schema->resultset('CD')->search(
4282     {
4283       'me.year' => 1984,
4284       'tracks.name' => 'Foo'
4285     },
4286     { join => 'tracks' }
4287   );
4288
4289 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4290 similarly for a third time). For e.g.
4291
4292   my $rs = $schema->resultset('Artist')->search({
4293     'cds.title'   => 'Down to Earth',
4294     'cds_2.title' => 'Popular',
4295   }, {
4296     join => [ qw/cds cds/ ],
4297   });
4298
4299 will return a set of all artists that have both a cd with title 'Down
4300 to Earth' and a cd with title 'Popular'.
4301
4302 If you want to fetch related objects from other tables as well, see L</prefetch>
4303 below.
4304
4305  NOTE: An internal join-chain pruner will discard certain joins while
4306  constructing the actual SQL query, as long as the joins in question do not
4307  affect the retrieved result. This for example includes 1:1 left joins
4308  that are not part of the restriction specification (WHERE/HAVING) nor are
4309  a part of the query selection.
4310
4311 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4312
4313 =head2 collapse
4314
4315 =over 4
4316
4317 =item Value: (0 | 1)
4318
4319 =back
4320
4321 When set to a true value, indicates that any rows fetched from joined has_many
4322 relationships are to be aggregated into the corresponding "parent" object. For
4323 example, the resultset:
4324
4325   my $rs = $schema->resultset('CD')->search({}, {
4326     '+columns' => [ qw/ tracks.title tracks.position / ],
4327     join => 'tracks',
4328     collapse => 1,
4329   });
4330
4331 While executing the following query:
4332
4333   SELECT me.*, tracks.title, tracks.position
4334     FROM cd me
4335     LEFT JOIN track tracks
4336       ON tracks.cdid = me.cdid
4337
4338 Will return only as many objects as there are rows in the CD source, even
4339 though the result of the query may span many rows. Each of these CD objects
4340 will in turn have multiple "Track" objects hidden behind the has_many
4341 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4342 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4343 product"), with each CD object containing exactly one of all fetched Track data.
4344
4345 When a collapse is requested on a non-ordered resultset, an order by some
4346 unique part of the main source (the left-most table) is inserted automatically.
4347 This is done so that the resultset is allowed to be "lazy" - calling
4348 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4349 object with all of its related data.
4350
4351 If an L</order_by> is already declared, and orders the resultset in a way that
4352 makes collapsing as described above impossible (e.g. C<< ORDER BY
4353 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4354 switch to "eager" mode and slurp the entire resultset before constructing the
4355 first object returned by L</next>.
4356
4357 Setting this attribute on a resultset that does not join any has_many
4358 relations is a no-op.
4359
4360 For a more in-depth discussion, see L</PREFETCHING>.
4361
4362 =head2 prefetch
4363
4364 =over 4
4365
4366 =item Value: ($rel_name | \@rel_names | \%rel_names)
4367
4368 =back
4369
4370 This attribute is a shorthand for specifying a L</join> spec, adding all
4371 columns from the joined related sources as L</+columns> and setting
4372 L</collapse> to a true value. For example, the following two queries are
4373 equivalent:
4374
4375   my $rs = $schema->resultset('Artist')->search({}, {
4376     prefetch => { cds => ['genre', 'tracks' ] },
4377   });
4378
4379 and
4380
4381   my $rs = $schema->resultset('Artist')->search({}, {
4382     join => { cds => ['genre', 'tracks' ] },
4383     collapse => 1,
4384     '+columns' => [
4385       (map
4386         { +{ "cds.$_" => "cds.$_" } }
4387         $schema->source('Artist')->related_source('cds')->columns
4388       ),
4389       (map
4390         { +{ "cds.genre.$_" => "genre.$_" } }
4391         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4392       ),
4393       (map
4394         { +{ "cds.tracks.$_" => "tracks.$_" } }
4395         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4396       ),
4397     ],
4398   });
4399
4400 Both producing the following SQL:
4401
4402   SELECT  me.artistid, me.name, me.rank, me.charfield,
4403           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4404           genre.genreid, genre.name,
4405           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4406     FROM artist me
4407     LEFT JOIN cd cds
4408       ON cds.artist = me.artistid
4409     LEFT JOIN genre genre
4410       ON genre.genreid = cds.genreid
4411     LEFT JOIN track tracks
4412       ON tracks.cd = cds.cdid
4413   ORDER BY me.artistid
4414
4415 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4416 the arguments are properly merged and generally do the right thing. For
4417 example, you may want to do the following:
4418
4419   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4420     { 'genre.genreid' => undef },
4421     {
4422       join => { cds => 'genre' },
4423       prefetch => 'cds',
4424     }
4425   );
4426
4427 Which generates the following SQL:
4428
4429   SELECT  me.artistid, me.name, me.rank, me.charfield,
4430           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4431     FROM artist me
4432     LEFT JOIN cd cds
4433       ON cds.artist = me.artistid
4434     LEFT JOIN genre genre
4435       ON genre.genreid = cds.genreid
4436   WHERE genre.genreid IS NULL
4437   ORDER BY me.artistid
4438
4439 For a more in-depth discussion, see L</PREFETCHING>.
4440
4441 =head2 alias
4442
4443 =over 4
4444
4445 =item Value: $source_alias
4446
4447 =back
4448
4449 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4450 nested search queries (sub-SELECTs) might need specific aliases set to
4451 reference inner queries.  For example:
4452
4453    my $q = $rs
4454       ->related_resultset('CDs')
4455       ->related_resultset('Tracks')
4456       ->search({
4457          'track.id' => { -ident => 'none_search.id' },
4458       })
4459       ->as_query;
4460
4461    my $ids = $self->search({
4462       -not_exists => $q,
4463    }, {
4464       alias    => 'none_search',
4465       group_by => 'none_search.id',
4466    })->get_column('id')->as_query;
4467
4468    $self->search({ id => { -in => $ids } })
4469
4470 This attribute is directly tied to L</current_source_alias>.
4471
4472 =head2 page
4473
4474 =over 4
4475
4476 =item Value: $page
4477
4478 =back
4479
4480 Makes the resultset paged and specifies the page to retrieve. Effectively
4481 identical to creating a non-pages resultset and then calling ->page($page)
4482 on it.
4483
4484 If L</rows> attribute is not specified it defaults to 10 rows per page.
4485
4486 When you have a paged resultset, L</count> will only return the number
4487 of rows in the page. To get the total, use the L</pager> and call
4488 C<total_entries> on it.
4489
4490 =head2 rows
4491
4492 =over 4
4493
4494 =item Value: $rows
4495
4496 =back
4497
4498 Specifies the maximum number of rows for direct retrieval or the number of
4499 rows per page if the page attribute or method is used.
4500
4501 =head2 offset
4502
4503 =over 4
4504
4505 =item Value: $offset
4506
4507 =back
4508
4509 Specifies the (zero-based) row number for the  first row to be returned, or the
4510 of the first row of the first page if paging is used.
4511
4512 =head2 software_limit
4513
4514 =over 4
4515
4516 =item Value: (0 | 1)
4517
4518 =back
4519
4520 When combined with L</rows> and/or L</offset> the generated SQL will not
4521 include any limit dialect stanzas. Instead the entire result will be selected
4522 as if no limits were specified, and DBIC will perform the limit locally, by
4523 artificially advancing and finishing the resulting L</cursor>.
4524
4525 This is the recommended way of performing resultset limiting when no sane RDBMS
4526 implementation is available (e.g.
4527 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4528 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4529
4530 =head2 group_by
4531
4532 =over 4
4533
4534 =item Value: \@columns
4535
4536 =back
4537
4538 A arrayref of columns to group by. Can include columns of joined tables.
4539
4540   group_by => [qw/ column1 column2 ... /]
4541
4542 =head2 having
4543
4544 =over 4
4545
4546 =item Value: $condition
4547
4548 =back
4549
4550 HAVING is a select statement attribute that is applied between GROUP BY and
4551 ORDER BY. It is applied to the after the grouping calculations have been
4552 done.
4553
4554   having => { 'count_employee' => { '>=', 100 } }
4555
4556 or with an in-place function in which case literal SQL is required:
4557
4558   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4559
4560 =head2 distinct
4561
4562 =over 4
4563
4564 =item Value: (0 | 1)
4565
4566 =back
4567
4568 Set to 1 to automatically generate a L</group_by> clause based on the selection
4569 (including intelligent handling of L</order_by> contents). Note that the group
4570 criteria calculation takes place over the B<final> selection. This includes
4571 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4572 L</search> calls, and standalone columns selected via
4573 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4574 extra selections specified via L</prefetch> - such selections are explicitly
4575 excluded from group criteria calculations.
4576
4577 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4578 setting is ignored and an appropriate warning is issued.
4579
4580 =head2 where
4581
4582 =over 4
4583
4584 Adds to the WHERE clause.
4585
4586   # only return rows WHERE deleted IS NULL for all searches
4587   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4588
4589 Can be overridden by passing C<< { where => undef } >> as an attribute
4590 to a resultset.
4591
4592 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4593
4594 =back
4595
4596 =head2 cache
4597
4598 Set to 1 to cache search results. This prevents extra SQL queries if you
4599 revisit rows in your ResultSet:
4600
4601   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4602
4603   while( my $artist = $resultset->next ) {
4604     ... do stuff ...
4605   }
4606
4607   $rs->first; # without cache, this would issue a query
4608
4609 By default, searches are not cached.
4610
4611 For more examples of using these attributes, see
4612 L<DBIx::Class::Manual::Cookbook>.
4613
4614 =head2 for
4615
4616 =over 4
4617
4618 =item Value: ( 'update' | 'shared' | \$scalar )
4619
4620 =back
4621
4622 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4623 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4624 query.
4625
4626 =head1 PREFETCHING
4627
4628 DBIx::Class supports arbitrary related data prefetching from multiple related
4629 sources. Any combination of relationship types and column sets are supported.
4630 If L<collapsing|/collapse> is requested, there is an additional requirement of
4631 selecting enough data to make every individual object uniquely identifiable.
4632
4633 Here are some more involved examples, based on the following relationship map:
4634
4635   # Assuming:
4636   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4637   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4638   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4639
4640   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4641
4642   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4643
4644
4645
4646   my $rs = $schema->resultset('Tag')->search(
4647     undef,
4648     {
4649       prefetch => {
4650         cd => 'artist'
4651       }
4652     }
4653   );
4654
4655 The initial search results in SQL like the following:
4656
4657   SELECT tag.*, cd.*, artist.* FROM tag
4658   JOIN cd ON tag.cd = cd.cdid
4659   JOIN artist ON cd.artist = artist.artistid
4660
4661 L<DBIx::Class> has no need to go back to the database when we access the
4662 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4663 case.
4664
4665 Simple prefetches will be joined automatically, so there is no need
4666 for a C<join> attribute in the above search.
4667
4668 The L</prefetch> attribute can be used with any of the relationship types
4669 and multiple prefetches can be specified together. Below is a more complex
4670 example that prefetches a CD's artist, its liner notes (if present),
4671 the cover image, the tracks on that CD, and the guests on those
4672 tracks.
4673
4674   my $rs = $schema->resultset('CD')->search(
4675     undef,
4676     {
4677       prefetch => [
4678         { artist => 'record_label'},  # belongs_to => belongs_to
4679         'liner_note',                 # might_have
4680         'cover_image',                # has_one
4681         { tracks => 'guests' },       # has_many => has_many
4682       ]
4683     }
4684   );
4685
4686 This will produce SQL like the following:
4687
4688   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4689          tracks.*, guests.*
4690     FROM cd me
4691     JOIN artist artist
4692       ON artist.artistid = me.artistid
4693     JOIN record_label record_label
4694       ON record_label.labelid = artist.labelid
4695     LEFT JOIN track tracks
4696       ON tracks.cdid = me.cdid
4697     LEFT JOIN guest guests
4698       ON guests.trackid = track.trackid
4699     LEFT JOIN liner_notes liner_note
4700       ON liner_note.cdid = me.cdid
4701     JOIN cd_artwork cover_image
4702       ON cover_image.cdid = me.cdid
4703   ORDER BY tracks.cd
4704
4705 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4706 C<tracks>, and C<guests> of the CD will all be available through the
4707 relationship accessors without the need for additional queries to the
4708 database.
4709
4710 =head3 CAVEATS
4711
4712 Prefetch does a lot of deep magic. As such, it may not behave exactly
4713 as you might expect.
4714
4715 =over 4
4716
4717 =item *
4718
4719 Prefetch uses the L</cache> to populate the prefetched relationships. This
4720 may or may not be what you want.
4721
4722 =item *
4723
4724 If you specify a condition on a prefetched relationship, ONLY those
4725 rows that match the prefetched condition will be fetched into that relationship.
4726 This means that adding prefetch to a search() B<may alter> what is returned by
4727 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4728
4729   my $artist_rs = $schema->resultset('Artist')->search({
4730       'cds.year' => 2008,
4731   }, {
4732       join => 'cds',
4733   });
4734
4735   my $count = $artist_rs->first->cds->count;
4736
4737   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4738
4739   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4740
4741   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4742
4743 That cmp_ok() may or may not pass depending on the datasets involved. In other
4744 words the C<WHERE> condition would apply to the entire dataset, just like
4745 it would in regular SQL. If you want to add a condition only to the "right side"
4746 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4747 condition|DBIx::Class::Relationship::Base/condition>
4748
4749 =back
4750
4751 =head1 DBIC BIND VALUES
4752
4753 Because DBIC may need more information to bind values than just the column name
4754 and value itself, it uses a special format for both passing and receiving bind
4755 values.  Each bind value should be composed of an arrayref of
4756 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4757
4758 =over 4
4759
4760 =item dbd_attrs
4761
4762 If present (in any form), this is what is being passed directly to bind_param.
4763 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4764 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4765
4766 If this is specified, all other bind options described below are ignored.
4767
4768 =item sqlt_datatype
4769
4770 If present, this is used to infer the actual bind attribute by passing to
4771 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4772 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4773
4774 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4775 currently drivers are expected to "Do the Right Thing" when given a common
4776 datatype name.  (Not ideal, but that's what we got at this point.)
4777
4778 =item sqlt_size
4779
4780 Currently used to correctly allocate buffers for bind_param_inout().
4781 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4782 or to a sensible value based on the "data_type".
4783
4784 =item dbic_colname
4785
4786 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4787 explicitly specified they are never overridden).  Also used by some weird DBDs,
4788 where the column name should be available at bind_param time (e.g. Oracle).
4789
4790 =back
4791
4792 For backwards compatibility and convenience, the following shortcuts are
4793 supported:
4794
4795   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4796   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4797   [ undef,   $val ] === [ {}, $val ]
4798   $val              === [ {}, $val ]
4799
4800 =head1 AUTHOR AND CONTRIBUTORS
4801
4802 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4803
4804 =head1 LICENSE
4805
4806 You may distribute this code under the same terms as Perl itself.
4807