lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 195
 196 =item Return Value: L<$resultset|/search>
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you never construct a resultset manually. Instead you get one
 206 from e.g. a
 207 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 208 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 209 scalar context):
 210
 211   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 212
 213 =over
 214
 215 =item WARNING
 216
 217 If called on an object, proxies to L</new_result> instead, so
 218
 219   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 220
 221 will return a CD object, not a ResultSet, and is equivalent to:
 222
 223   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 224
 225 Please also keep in mind that many internals call L</new_result> directly,
 226 so overloading this method with the idea of intercepting new result object
 227 creation B<will not work>. See also warning pertaining to L</create>.
 228
 229 =back
 230
 231 =cut
 232
 233 sub new {
 234   my $class = shift;
 235   return $class->new_result(@_) if ref $class;
 236
 237   my ($source, $attrs) = @_;
 238   $source = $source->resolve
 239     if $source->isa('DBIx::Class::ResultSourceHandle');
 240   $attrs = { %{$attrs||{}} };
 241
 242   if ($attrs->{page}) {
 243     $attrs->{rows} ||= 10;
 244   }
 245
 246   $attrs->{alias} ||= 'me';
 247
 248   my $self = bless {
 249     result_source => $source,
 250     cond => $attrs->{where},
 251     pager => undef,
 252     attrs => $attrs,
 253   }, $class;
 254
 255   # if there is a dark selector, this means we are already in a
 256   # chain and the cleanup/sanification was taken care of by
 257   # _search_rs already
 258   $self->_normalize_selection($attrs)
 259     unless $attrs->{_dark_selector};
 260
 261   $self->result_class(
 262     $attrs->{result_class} || $source->result_class
 263   );
 264
 265   $self;
 266 }
 267
 268 =head2 search
 269
 270 =over 4
 271
 272 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 273
 274 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 275
 276 =back
 277
 278   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 279   my $new_rs = $cd_rs->search({ year => 2005 });
 280
 281   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 282                  # year = 2005 OR year = 2004
 283
 284 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 285 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 286 To avoid that, use L</search_rs>.
 287
 288 If you need to pass in additional attributes but no additional condition,
 289 call it as C<search(undef, \%attrs)>.
 290
 291   # "SELECT name, artistid FROM $artist_table"
 292   my @all_artists = $schema->resultset('Artist')->search(undef, {
 293     columns => [qw/name artistid/],
 294   });
 295
 296 For a list of attributes that can be passed to C<search>, see
 297 L</ATTRIBUTES>. For more examples of using this function, see
 298 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 299 documentation for the first argument, see L<SQL::Abstract>
 300 and its extension L<DBIx::Class::SQLMaker>.
 301
 302 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 303
 304 =head3 CAVEAT
 305
 306 Note that L</search> does not process/deflate any of the values passed in the
 307 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 308 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 309 manually that any value passed to this method will stringify to something the
 310 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 311 objects, for more info see:
 312 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 313
 314 =cut
 315
 316 sub search {
 317   my $self = shift;
 318   my $rs = $self->search_rs( @_ );
 319
 320   if (wantarray) {
 321     return $rs->all;
 322   }
 323   elsif (defined wantarray) {
 324     return $rs;
 325   }
 326   else {
 327     # we can be called by a relationship helper, which in
 328     # turn may be called in void context due to some braindead
 329     # overload or whatever else the user decided to be clever
 330     # at this particular day. Thus limit the exception to
 331     # external code calls only
 332     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 333       if (caller)[0] !~ /^\QDBIx::Class::/;
 334
 335     return ();
 336   }
 337 }
 338
 339 =head2 search_rs
 340
 341 =over 4
 342
 343 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 344
 345 =item Return Value: L<$resultset|/search>
 346
 347 =back
 348
 349 This method does the same exact thing as search() except it will
 350 always return a resultset, even in list context.
 351
 352 =cut
 353
 354 sub search_rs {
 355   my $self = shift;
 356
 357   my $rsrc = $self->result_source;
 358   my ($call_cond, $call_attrs);
 359
 360   # Special-case handling for (undef, undef) or (undef)
 361   # Note that (foo => undef) is valid deprecated syntax
 362   @_ = () if not scalar grep { defined $_ } @_;
 363
 364   # just a cond
 365   if (@_ == 1) {
 366     $call_cond = shift;
 367   }
 368   # fish out attrs in the ($condref, $attr) case
 369   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 370     ($call_cond, $call_attrs) = @_;
 371   }
 372   elsif (@_ % 2) {
 373     $self->throw_exception('Odd number of arguments to search')
 374   }
 375   # legacy search
 376   elsif (@_) {
 377     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 378       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 379
 380     for my $i (0 .. $#_) {
 381       next if $i % 2;
 382       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 383         if (! defined $_[$i] or ref $_[$i] ne '');
 384     }
 385
 386     $call_cond = { @_ };
 387   }
 388
 389   # see if we can keep the cache (no $rs changes)
 390   my $cache;
 391   my %safe = (alias => 1, cache => 1);
 392   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 393     ! defined $_[0]
 394       or
 395     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 396       or
 397     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 398   )) {
 399     $cache = $self->get_cache;
 400   }
 401
 402   my $old_attrs = { %{$self->{attrs}} };
 403   my $old_having = delete $old_attrs->{having};
 404   my $old_where = delete $old_attrs->{where};
 405
 406   my $new_attrs = { %$old_attrs };
 407
 408   # take care of call attrs (only if anything is changing)
 409   if ($call_attrs and keys %$call_attrs) {
 410
 411     # copy for _normalize_selection
 412     $call_attrs = { %$call_attrs };
 413
 414     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 415
 416     # reset the current selector list if new selectors are supplied
 417     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 418       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 419     }
 420
 421     # Normalize the new selector list (operates on the passed-in attr structure)
 422     # Need to do it on every chain instead of only once on _resolved_attrs, in
 423     # order to allow detection of empty vs partial 'as'
 424     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 425       if $old_attrs->{_dark_selector};
 426     $self->_normalize_selection ($call_attrs);
 427
 428     # start with blind overwriting merge, exclude selector attrs
 429     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 430     delete @{$new_attrs}{@selector_attrs};
 431
 432     for (@selector_attrs) {
 433       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 434         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 435     }
 436
 437     # older deprecated name, use only if {columns} is not there
 438     if (my $c = delete $new_attrs->{cols}) {
 439       if ($new_attrs->{columns}) {
 440         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 441       }
 442       else {
 443         $new_attrs->{columns} = $c;
 444       }
 445     }
 446
 447
 448     # join/prefetch use their own crazy merging heuristics
 449     foreach my $key (qw/join prefetch/) {
 450       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 451         if exists $call_attrs->{$key};
 452     }
 453
 454     # stack binds together
 455     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 456   }
 457
 458
 459   for ($old_where, $call_cond) {
 460     if (defined $_) {
 461       $new_attrs->{where} = $self->_stack_cond (
 462         $_, $new_attrs->{where}
 463       );
 464     }
 465   }
 466
 467   if (defined $old_having) {
 468     $new_attrs->{having} = $self->_stack_cond (
 469       $old_having, $new_attrs->{having}
 470     )
 471   }
 472
 473   my $rs = (ref $self)->new($rsrc, $new_attrs);
 474
 475   $rs->set_cache($cache) if ($cache);
 476
 477   return $rs;
 478 }
 479
 480 my $dark_sel_dumper;
 481 sub _normalize_selection {
 482   my ($self, $attrs) = @_;
 483
 484   # legacy syntax
 485   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 486     if exists $attrs->{include_columns};
 487
 488   # columns are always placed first, however
 489
 490   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 491   # delay the decision on whether to use a default select list ($rsrc->columns)
 492   # allowing stuff like the remove_columns helper to work
 493   #
 494   # select/as +select/+as pairs need special handling - the amount of select/as
 495   # elements in each pair does *not* have to be equal (think multicolumn
 496   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 497   # supplied at all) - try to infer the alias, either from the -as parameter
 498   # of the selector spec, or use the parameter whole if it looks like a column
 499   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 500   # is ok as well), but make sure no more additions to the 'as' chain take place
 501   for my $pref ('', '+') {
 502
 503     my ($sel, $as) = map {
 504       my $key = "${pref}${_}";
 505
 506       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 507         ? @{$attrs->{$key}}
 508         : $attrs->{$key} || ()
 509       ];
 510       delete $attrs->{$key};
 511       $val;
 512     } qw/select as/;
 513
 514     if (! @$as and ! @$sel ) {
 515       next;
 516     }
 517     elsif (@$as and ! @$sel) {
 518       $self->throw_exception(
 519         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 520       );
 521     }
 522     elsif( ! @$as ) {
 523       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 524       # if any @$as has been supplied we assume the user knows what (s)he is doing
 525       # and blindly keep stacking up pieces
 526       unless ($attrs->{_dark_selector}) {
 527         SELECTOR:
 528         for (@$sel) {
 529           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 530             push @$as, $_->{-as};
 531           }
 532           # assume any plain no-space, no-parenthesis string to be a column spec
 533           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 534           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 535             push @$as, $_;
 536           }
 537           # if all else fails - raise a flag that no more aliasing will be allowed
 538           else {
 539             $attrs->{_dark_selector} = {
 540               plus_stage => $pref,
 541               string => ($dark_sel_dumper ||= do {
 542                   require Data::Dumper::Concise;
 543                   Data::Dumper::Concise::DumperObject()->Indent(0);
 544                 })->Values([$_])->Dump
 545               ,
 546             };
 547             last SELECTOR;
 548           }
 549         }
 550       }
 551     }
 552     elsif (@$as < @$sel) {
 553       $self->throw_exception(
 554         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 555       );
 556     }
 557     elsif ($pref and $attrs->{_dark_selector}) {
 558       $self->throw_exception(
 559         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 560       );
 561     }
 562
 563
 564     # merge result
 565     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 566     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 567   }
 568 }
 569
 570 sub _stack_cond {
 571   my ($self, $left, $right) = @_;
 572
 573   # collapse single element top-level conditions
 574   # (single pass only, unlikely to need recursion)
 575   for ($left, $right) {
 576     if (ref $_ eq 'ARRAY') {
 577       if (@$_ == 0) {
 578         $_ = undef;
 579       }
 580       elsif (@$_ == 1) {
 581         $_ = $_->[0];
 582       }
 583     }
 584     elsif (ref $_ eq 'HASH') {
 585       my ($first, $more) = keys %$_;
 586
 587       # empty hash
 588       if (! defined $first) {
 589         $_ = undef;
 590       }
 591       # one element hash
 592       elsif (! defined $more) {
 593         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 594           $_ = $_->{'-and'};
 595         }
 596         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 597           $_ = $_->{'-or'};
 598         }
 599       }
 600     }
 601   }
 602
 603   # merge hashes with weeding out of duplicates (simple cases only)
 604   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 605
 606     # shallow copy to destroy
 607     $right = { %$right };
 608     for (grep { exists $right->{$_} } keys %$left) {
 609       # the use of eq_deeply here is justified - the rhs of an
 610       # expression can contain a lot of twisted weird stuff
 611       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 612     }
 613
 614     $right = undef unless keys %$right;
 615   }
 616
 617
 618   if (defined $left xor defined $right) {
 619     return defined $left ? $left : $right;
 620   }
 621   elsif (! defined $left) {
 622     return undef;
 623   }
 624   else {
 625     return { -and => [ $left, $right ] };
 626   }
 627 }
 628
 629 =head2 search_literal
 630
 631 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 632 should only be used in that context. C<search_literal> is a convenience
 633 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 634 want to ensure columns are bound correctly, use L</search>.
 635
 636 See L<DBIx::Class::Manual::Cookbook/Searching> and
 637 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 638 require C<search_literal>.
 639
 640 =over 4
 641
 642 =item Arguments: $sql_fragment, @standalone_bind_values
 643
 644 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 645
 646 =back
 647
 648   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 649   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 650
 651 Pass a literal chunk of SQL to be added to the conditional part of the
 652 resultset query.
 653
 654 Example of how to use C<search> instead of C<search_literal>
 655
 656   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 657   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 658
 659 =cut
 660
 661 sub search_literal {
 662   my ($self, $sql, @bind) = @_;
 663   my $attr;
 664   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 665     $attr = pop @bind;
 666   }
 667   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 668 }
 669
 670 =head2 find
 671
 672 =over 4
 673
 674 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 675
 676 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 677
 678 =back
 679
 680 Finds and returns a single row based on supplied criteria. Takes either a
 681 hashref with the same format as L</create> (including inference of foreign
 682 keys from related objects), or a list of primary key values in the same
 683 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 684 declaration on the L</result_source>.
 685
 686 In either case an attempt is made to combine conditions already existing on
 687 the resultset with the condition passed to this method.
 688
 689 To aid with preparing the correct query for the storage you may supply the
 690 C<key> attribute, which is the name of a
 691 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 692 unique constraint corresponding to the
 693 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 694 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 695 to construct a query that satisfies the named unique constraint fully (
 696 non-NULL values for each column member of the constraint) an exception is
 697 thrown.
 698
 699 If no C<key> is specified, the search is carried over all unique constraints
 700 which are fully defined by the available condition.
 701
 702 If no such constraint is found, C<find> currently defaults to a simple
 703 C<< search->(\%column_values) >> which may or may not do what you expect.
 704 Note that this fallback behavior may be deprecated in further versions. If
 705 you need to search with arbitrary conditions - use L</search>. If the query
 706 resulting from this fallback produces more than one row, a warning to the
 707 effect is issued, though only the first row is constructed and returned as
 708 C<$result_object>.
 709
 710 In addition to C<key>, L</find> recognizes and applies standard
 711 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 712
 713 Note that if you have extra concerns about the correctness of the resulting
 714 query you need to specify the C<key> attribute and supply the entire condition
 715 as an argument to find (since it is not always possible to perform the
 716 combination of the resultset condition with the supplied one, especially if
 717 the resultset condition contains literal sql).
 718
 719 For example, to find a row by its primary key:
 720
 721   my $cd = $schema->resultset('CD')->find(5);
 722
 723 You can also find a row by a specific unique constraint:
 724
 725   my $cd = $schema->resultset('CD')->find(
 726     {
 727       artist => 'Massive Attack',
 728       title  => 'Mezzanine',
 729     },
 730     { key => 'cd_artist_title' }
 731   );
 732
 733 See also L</find_or_create> and L</update_or_create>.
 734
 735 =cut
 736
 737 sub find {
 738   my $self = shift;
 739   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 740
 741   my $rsrc = $self->result_source;
 742
 743   my $constraint_name;
 744   if (exists $attrs->{key}) {
 745     $constraint_name = defined $attrs->{key}
 746       ? $attrs->{key}
 747       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 748     ;
 749   }
 750
 751   # Parse out the condition from input
 752   my $call_cond;
 753
 754   if (ref $_[0] eq 'HASH') {
 755     $call_cond = { %{$_[0]} };
 756   }
 757   else {
 758     # if only values are supplied we need to default to 'primary'
 759     $constraint_name = 'primary' unless defined $constraint_name;
 760
 761     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 762
 763     $self->throw_exception(
 764       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 765     ) unless @c_cols;
 766
 767     $self->throw_exception (
 768       'find() expects either a column/value hashref, or a list of values '
 769     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 770     ) unless @c_cols == @_;
 771
 772     $call_cond = {};
 773     @{$call_cond}{@c_cols} = @_;
 774   }
 775
 776   my %related;
 777   for my $key (keys %$call_cond) {
 778     if (
 779       my $keyref = ref($call_cond->{$key})
 780         and
 781       my $relinfo = $rsrc->relationship_info($key)
 782     ) {
 783       my $val = delete $call_cond->{$key};
 784
 785       next if $keyref eq 'ARRAY'; # has_many for multi_create
 786
 787       my $rel_q = $rsrc->_resolve_condition(
 788         $relinfo->{cond}, $val, $key, $key
 789       );
 790       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 791       @related{keys %$rel_q} = values %$rel_q;
 792     }
 793   }
 794
 795   # relationship conditions take precedence (?)
 796   @{$call_cond}{keys %related} = values %related;
 797
 798   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 799   my $final_cond;
 800   if (defined $constraint_name) {
 801     $final_cond = $self->_qualify_cond_columns (
 802
 803       $self->_build_unique_cond (
 804         $constraint_name,
 805         $call_cond,
 806       ),
 807
 808       $alias,
 809     );
 810   }
 811   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 812     # This means that we got here after a merger of relationship conditions
 813     # in ::Relationship::Base::search_related (the row method), and furthermore
 814     # the relationship is of the 'single' type. This means that the condition
 815     # provided by the relationship (already attached to $self) is sufficient,
 816     # as there can be only one row in the database that would satisfy the
 817     # relationship
 818   }
 819   else {
 820     # no key was specified - fall down to heuristics mode:
 821     # run through all unique queries registered on the resultset, and
 822     # 'OR' all qualifying queries together
 823     my (@unique_queries, %seen_column_combinations);
 824     for my $c_name ($rsrc->unique_constraint_names) {
 825       next if $seen_column_combinations{
 826         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 827       }++;
 828
 829       push @unique_queries, try {
 830         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 831       } || ();
 832     }
 833
 834     $final_cond = @unique_queries
 835       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 836       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 837     ;
 838   }
 839
 840   # Run the query, passing the result_class since it should propagate for find
 841   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 842   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 843     my $row = $rs->next;
 844     carp "Query returned more than one row" if $rs->next;
 845     return $row;
 846   }
 847   else {
 848     return $rs->single;
 849   }
 850 }
 851
 852 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 853 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 854 #
 855 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 856 # condition. It is provided for overrides until a saner way forward is devised
 857 #
 858 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 859 # the road. Please adjust your tests accordingly to catch this situation early
 860 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 861 #
 862 # The method will not be removed without an adequately complete replacement
 863 # for strict-mode enforcement
 864 sub _non_unique_find_fallback {
 865   my ($self, $cond, $attrs) = @_;
 866
 867   return $self->_qualify_cond_columns(
 868     $cond,
 869     exists $attrs->{alias}
 870       ? $attrs->{alias}
 871       : $self->{attrs}{alias}
 872   );
 873 }
 874
 875
 876 sub _qualify_cond_columns {
 877   my ($self, $cond, $alias) = @_;
 878
 879   my %aliased = %$cond;
 880   for (keys %aliased) {
 881     $aliased{"$alias.$_"} = delete $aliased{$_}
 882       if $_ !~ /\./;
 883   }
 884
 885   return \%aliased;
 886 }
 887
 888 sub _build_unique_cond {
 889   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 890
 891   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 892
 893   # combination may fail if $self->{cond} is non-trivial
 894   my ($final_cond) = try {
 895     $self->_merge_with_rscond ($extra_cond)
 896   } catch {
 897     +{ %$extra_cond }
 898   };
 899
 900   # trim out everything not in $columns
 901   $final_cond = { map {
 902     exists $final_cond->{$_}
 903       ? ( $_ => $final_cond->{$_} )
 904       : ()
 905   } @c_cols };
 906
 907   if (my @missing = grep
 908     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 909     (@c_cols)
 910   ) {
 911     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 912       $constraint_name,
 913       join (', ', map { "'$_'" } @missing),
 914     ) );
 915   }
 916
 917   if (
 918     !$croak_on_null
 919       and
 920     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 921       and
 922     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 923   ) {
 924     carp_unique ( sprintf (
 925       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 926     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 927     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 928       $constraint_name,
 929       join (', ', map { "'$_'" } @undefs),
 930     ));
 931   }
 932
 933   return $final_cond;
 934 }
 935
 936 =head2 search_related
 937
 938 =over 4
 939
 940 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 941
 942 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 943
 944 =back
 945
 946   $new_rs = $cd_rs->search_related('artist', {
 947     name => 'Emo-R-Us',
 948   });
 949
 950 Searches the specified relationship, optionally specifying a condition and
 951 attributes for matching records. See L</ATTRIBUTES> for more information.
 952
 953 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 954 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 955
 956 See also L</search_related_rs>.
 957
 958 =cut
 959
 960 sub search_related {
 961   return shift->related_resultset(shift)->search(@_);
 962 }
 963
 964 =head2 search_related_rs
 965
 966 This method works exactly the same as search_related, except that
 967 it guarantees a resultset, even in list context.
 968
 969 =cut
 970
 971 sub search_related_rs {
 972   return shift->related_resultset(shift)->search_rs(@_);
 973 }
 974
 975 =head2 cursor
 976
 977 =over 4
 978
 979 =item Arguments: none
 980
 981 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 982
 983 =back
 984
 985 Returns a storage-driven cursor to the given resultset. See
 986 L<DBIx::Class::Cursor> for more information.
 987
 988 =cut
 989
 990 sub cursor {
 991   my ($self) = @_;
 992
 993   my $attrs = $self->_resolved_attrs_copy;
 994
 995   return $self->{cursor}
 996     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 997           $attrs->{where},$attrs);
 998 }
 999
1000 =head2 single
1001
1002 =over 4
1003
1004 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1005
1006 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1007
1008 =back
1009
1010   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1011
1012 Inflates the first result without creating a cursor if the resultset has
1013 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1014 of L</search>.
1015
1016 While this method can take an optional search condition (just like L</search>)
1017 being a fast-code-path it does not recognize search attributes. If you need to
1018 add extra joins or similar, call L</search> and then chain-call L</single> on the
1019 L<DBIx::Class::ResultSet> returned.
1020
1021 =over
1022
1023 =item B<Note>
1024
1025 As of 0.08100, this method enforces the assumption that the preceding
1026 query returns only one row. If more than one row is returned, you will receive
1027 a warning:
1028
1029   Query returned more than one row
1030
1031 In this case, you should be using L</next> or L</find> instead, or if you really
1032 know what you are doing, use the L</rows> attribute to explicitly limit the size
1033 of the resultset.
1034
1035 This method will also throw an exception if it is called on a resultset prefetching
1036 has_many, as such a prefetch implies fetching multiple rows from the database in
1037 order to assemble the resulting object.
1038
1039 =back
1040
1041 =cut
1042
1043 sub single {
1044   my ($self, $where) = @_;
1045   if(@_ > 2) {
1046       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1047   }
1048
1049   my $attrs = $self->_resolved_attrs_copy;
1050
1051   if (keys %{$attrs->{collapse}}) {
1052     $self->throw_exception(
1053       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1054     );
1055   }
1056
1057   if ($where) {
1058     if (defined $attrs->{where}) {
1059       $attrs->{where} = {
1060         '-and' =>
1061             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1062                $where, delete $attrs->{where} ]
1063       };
1064     } else {
1065       $attrs->{where} = $where;
1066     }
1067   }
1068
1069   my @data = $self->result_source->storage->select_single(
1070     $attrs->{from}, $attrs->{select},
1071     $attrs->{where}, $attrs
1072   );
1073
1074   return (@data ? ($self->_construct_object(@data))[0] : undef);
1075 }
1076
1077
1078 # _collapse_query
1079 #
1080 # Recursively collapse the query, accumulating values for each column.
1081
1082 sub _collapse_query {
1083   my ($self, $query, $collapsed) = @_;
1084
1085   $collapsed ||= {};
1086
1087   if (ref $query eq 'ARRAY') {
1088     foreach my $subquery (@$query) {
1089       next unless ref $subquery;  # -or
1090       $collapsed = $self->_collapse_query($subquery, $collapsed);
1091     }
1092   }
1093   elsif (ref $query eq 'HASH') {
1094     if (keys %$query and (keys %$query)[0] eq '-and') {
1095       foreach my $subquery (@{$query->{-and}}) {
1096         $collapsed = $self->_collapse_query($subquery, $collapsed);
1097       }
1098     }
1099     else {
1100       foreach my $col (keys %$query) {
1101         my $value = $query->{$col};
1102         $collapsed->{$col}{$value}++;
1103       }
1104     }
1105   }
1106
1107   return $collapsed;
1108 }
1109
1110 =head2 get_column
1111
1112 =over 4
1113
1114 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1115
1116 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1117
1118 =back
1119
1120   my $max_length = $rs->get_column('length')->max;
1121
1122 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1123
1124 =cut
1125
1126 sub get_column {
1127   my ($self, $column) = @_;
1128   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1129   return $new;
1130 }
1131
1132 =head2 search_like
1133
1134 =over 4
1135
1136 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1137
1138 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1139
1140 =back
1141
1142   # WHERE title LIKE '%blue%'
1143   $cd_rs = $rs->search_like({ title => '%blue%'});
1144
1145 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1146 that this is simply a convenience method retained for ex Class::DBI users.
1147 You most likely want to use L</search> with specific operators.
1148
1149 For more information, see L<DBIx::Class::Manual::Cookbook>.
1150
1151 This method is deprecated and will be removed in 0.09. Use L</search()>
1152 instead. An example conversion is:
1153
1154   ->search_like({ foo => 'bar' });
1155
1156   # Becomes
1157
1158   ->search({ foo => { like => 'bar' } });
1159
1160 =cut
1161
1162 sub search_like {
1163   my $class = shift;
1164   carp_unique (
1165     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1166    .' Instead use ->search({ x => { -like => "y%" } })'
1167    .' (note the outer pair of {}s - they are important!)'
1168   );
1169   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1170   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1171   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1172   return $class->search($query, { %$attrs });
1173 }
1174
1175 =head2 slice
1176
1177 =over 4
1178
1179 =item Arguments: $first, $last
1180
1181 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1182
1183 =back
1184
1185 Returns a resultset or object list representing a subset of elements from the
1186 resultset slice is called on. Indexes are from 0, i.e., to get the first
1187 three records, call:
1188
1189   my ($one, $two, $three) = $rs->slice(0, 2);
1190
1191 =cut
1192
1193 sub slice {
1194   my ($self, $min, $max) = @_;
1195   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1196   $attrs->{offset} = $self->{attrs}{offset} || 0;
1197   $attrs->{offset} += $min;
1198   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1199   return $self->search(undef, $attrs);
1200   #my $slice = (ref $self)->new($self->result_source, $attrs);
1201   #return (wantarray ? $slice->all : $slice);
1202 }
1203
1204 =head2 next
1205
1206 =over 4
1207
1208 =item Arguments: none
1209
1210 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1211
1212 =back
1213
1214 Returns the next element in the resultset (C<undef> is there is none).
1215
1216 Can be used to efficiently iterate over records in the resultset:
1217
1218   my $rs = $schema->resultset('CD')->search;
1219   while (my $cd = $rs->next) {
1220     print $cd->title;
1221   }
1222
1223 Note that you need to store the resultset object, and call C<next> on it.
1224 Calling C<< resultset('Table')->next >> repeatedly will always return the
1225 first record from the resultset.
1226
1227 =cut
1228
1229 sub next {
1230   my ($self) = @_;
1231   if (my $cache = $self->get_cache) {
1232     $self->{all_cache_position} ||= 0;
1233     return $cache->[$self->{all_cache_position}++];
1234   }
1235   if ($self->{attrs}{cache}) {
1236     delete $self->{pager};
1237     $self->{all_cache_position} = 1;
1238     return ($self->all)[0];
1239   }
1240   if ($self->{stashed_objects}) {
1241     my $obj = shift(@{$self->{stashed_objects}});
1242     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1243     return $obj;
1244   }
1245   my @row = (
1246     exists $self->{stashed_row}
1247       ? @{delete $self->{stashed_row}}
1248       : $self->cursor->next
1249   );
1250   return undef unless (@row);
1251   my ($row, @more) = $self->_construct_object(@row);
1252   $self->{stashed_objects} = \@more if @more;
1253   return $row;
1254 }
1255
1256 sub _construct_object {
1257   my ($self, @row) = @_;
1258
1259   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1260     or return ();
1261   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1262   @new = $self->{_attrs}{record_filter}->(@new)
1263     if exists $self->{_attrs}{record_filter};
1264   return @new;
1265 }
1266
1267 sub _collapse_result {
1268   my ($self, $as_proto, $row) = @_;
1269
1270   my @copy = @$row;
1271
1272   # 'foo'         => [ undef, 'foo' ]
1273   # 'foo.bar'     => [ 'foo', 'bar' ]
1274   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1275
1276   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1277
1278   my %collapse = %{$self->{_attrs}{collapse}||{}};
1279
1280   my @pri_index;
1281
1282   # if we're doing collapsing (has_many prefetch) we need to grab records
1283   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1284   # we know we don't have to bother.
1285
1286   # the reason for not using the collapse stuff directly is because if you
1287   # had for e.g. two artists in a row with no cds, the collapse info for
1288   # both would be NULL (undef) so you'd lose the second artist
1289
1290   # store just the index so we can check the array positions from the row
1291   # without having to contruct the full hash
1292
1293   if (keys %collapse) {
1294     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1295     foreach my $i (0 .. $#construct_as) {
1296       next if defined($construct_as[$i][0]); # only self table
1297       if (delete $pri{$construct_as[$i][1]}) {
1298         push(@pri_index, $i);
1299       }
1300       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1301     }
1302   }
1303
1304   # no need to do an if, it'll be empty if @pri_index is empty anyway
1305
1306   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1307
1308   my @const_rows;
1309
1310   do { # no need to check anything at the front, we always want the first row
1311
1312     my %const;
1313
1314     foreach my $this_as (@construct_as) {
1315       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1316     }
1317
1318     push(@const_rows, \%const);
1319
1320   } until ( # no pri_index => no collapse => drop straight out
1321       !@pri_index
1322     or
1323       do { # get another row, stash it, drop out if different PK
1324
1325         @copy = $self->cursor->next;
1326         $self->{stashed_row} = \@copy;
1327
1328         # last thing in do block, counts as true if anything doesn't match
1329
1330         # check xor defined first for NULL vs. NOT NULL then if one is
1331         # defined the other must be so check string equality
1332
1333         grep {
1334           (defined $pri_vals{$_} ^ defined $copy[$_])
1335           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1336         } @pri_index;
1337       }
1338   );
1339
1340   my $alias = $self->{attrs}{alias};
1341   my $info = [];
1342
1343   my %collapse_pos;
1344
1345   my @const_keys;
1346
1347   foreach my $const (@const_rows) {
1348     scalar @const_keys or do {
1349       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1350     };
1351     foreach my $key (@const_keys) {
1352       if (length $key) {
1353         my $target = $info;
1354         my @parts = split(/\./, $key);
1355         my $cur = '';
1356         my $data = $const->{$key};
1357         foreach my $p (@parts) {
1358           $target = $target->[1]->{$p} ||= [];
1359           $cur .= ".${p}";
1360           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1361             # collapsing at this point and on final part
1362             my $pos = $collapse_pos{$cur};
1363             CK: foreach my $ck (@ckey) {
1364               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1365                 $collapse_pos{$cur} = $data;
1366                 delete @collapse_pos{ # clear all positioning for sub-entries
1367                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1368                 };
1369                 push(@$target, []);
1370                 last CK;
1371               }
1372             }
1373           }
1374           if (exists $collapse{$cur}) {
1375             $target = $target->[-1];
1376           }
1377         }
1378         $target->[0] = $data;
1379       } else {
1380         $info->[0] = $const->{$key};
1381       }
1382     }
1383   }
1384
1385   return $info;
1386 }
1387
1388 =head2 result_source
1389
1390 =over 4
1391
1392 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1393
1394 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1395
1396 =back
1397
1398 An accessor for the primary ResultSource object from which this ResultSet
1399 is derived.
1400
1401 =head2 result_class
1402
1403 =over 4
1404
1405 =item Arguments: $result_class?
1406
1407 =item Return Value: $result_class
1408
1409 =back
1410
1411 An accessor for the class to use when creating result objects. Defaults to
1412 C<< result_source->result_class >> - which in most cases is the name of the
1413 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1414
1415 Note that changing the result_class will also remove any components
1416 that were originally loaded in the source class via
1417 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1418 in the original source class will not run.
1419
1420 =cut
1421
1422 sub result_class {
1423   my ($self, $result_class) = @_;
1424   if ($result_class) {
1425     unless (ref $result_class) { # don't fire this for an object
1426       $self->ensure_class_loaded($result_class);
1427     }
1428     $self->_result_class($result_class);
1429     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1430     # permit the user to set result class on one result set only; it only
1431     # chains if provided to search()
1432     #$self->{attrs}{result_class} = $result_class if ref $self;
1433   }
1434   $self->_result_class;
1435 }
1436
1437 =head2 count
1438
1439 =over 4
1440
1441 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1442
1443 =item Return Value: $count
1444
1445 =back
1446
1447 Performs an SQL C<COUNT> with the same query as the resultset was built
1448 with to find the number of elements. Passing arguments is equivalent to
1449 C<< $rs->search ($cond, \%attrs)->count >>
1450
1451 =cut
1452
1453 sub count {
1454   my $self = shift;
1455   return $self->search(@_)->count if @_ and defined $_[0];
1456   return scalar @{ $self->get_cache } if $self->get_cache;
1457
1458   my $attrs = $self->_resolved_attrs_copy;
1459
1460   # this is a little optimization - it is faster to do the limit
1461   # adjustments in software, instead of a subquery
1462   my $rows = delete $attrs->{rows};
1463   my $offset = delete $attrs->{offset};
1464
1465   my $crs;
1466   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1467     $crs = $self->_count_subq_rs ($attrs);
1468   }
1469   else {
1470     $crs = $self->_count_rs ($attrs);
1471   }
1472   my $count = $crs->next;
1473
1474   $count -= $offset if $offset;
1475   $count = $rows if $rows and $rows < $count;
1476   $count = 0 if ($count < 0);
1477
1478   return $count;
1479 }
1480
1481 =head2 count_rs
1482
1483 =over 4
1484
1485 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1486
1487 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1488
1489 =back
1490
1491 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1492 This can be very handy for subqueries:
1493
1494   ->search( { amount => $some_rs->count_rs->as_query } )
1495
1496 As with regular resultsets the SQL query will be executed only after
1497 the resultset is accessed via L</next> or L</all>. That would return
1498 the same single value obtainable via L</count>.
1499
1500 =cut
1501
1502 sub count_rs {
1503   my $self = shift;
1504   return $self->search(@_)->count_rs if @_;
1505
1506   # this may look like a lack of abstraction (count() does about the same)
1507   # but in fact an _rs *must* use a subquery for the limits, as the
1508   # software based limiting can not be ported if this $rs is to be used
1509   # in a subquery itself (i.e. ->as_query)
1510   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1511     return $self->_count_subq_rs;
1512   }
1513   else {
1514     return $self->_count_rs;
1515   }
1516 }
1517
1518 #
1519 # returns a ResultSetColumn object tied to the count query
1520 #
1521 sub _count_rs {
1522   my ($self, $attrs) = @_;
1523
1524   my $rsrc = $self->result_source;
1525   $attrs ||= $self->_resolved_attrs;
1526
1527   my $tmp_attrs = { %$attrs };
1528   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1529   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1530
1531   # overwrite the selector (supplied by the storage)
1532   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1533   $tmp_attrs->{as} = 'count';
1534   delete @{$tmp_attrs}{qw/columns/};
1535
1536   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1537
1538   return $tmp_rs;
1539 }
1540
1541 #
1542 # same as above but uses a subquery
1543 #
1544 sub _count_subq_rs {
1545   my ($self, $attrs) = @_;
1546
1547   my $rsrc = $self->result_source;
1548   $attrs ||= $self->_resolved_attrs;
1549
1550   my $sub_attrs = { %$attrs };
1551   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1552   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1553
1554   # if we multi-prefetch we group_by something unique, as this is what we would
1555   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1556   if ( keys %{$attrs->{collapse}}  ) {
1557     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1558       $rsrc->_identifying_column_set || $self->throw_exception(
1559         'Unable to construct a unique group_by criteria properly collapsing the '
1560       . 'has_many prefetch before count()'
1561       );
1562     } ]
1563   }
1564
1565   # Calculate subquery selector
1566   if (my $g = $sub_attrs->{group_by}) {
1567
1568     my $sql_maker = $rsrc->storage->sql_maker;
1569
1570     # necessary as the group_by may refer to aliased functions
1571     my $sel_index;
1572     for my $sel (@{$attrs->{select}}) {
1573       $sel_index->{$sel->{-as}} = $sel
1574         if (ref $sel eq 'HASH' and $sel->{-as});
1575     }
1576
1577     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1578     # also look for named aggregates referred in the having clause
1579     # having often contains scalarrefs - thus parse it out entirely
1580     my @parts = @$g;
1581     if ($attrs->{having}) {
1582       local $sql_maker->{having_bind};
1583       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1584       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1585       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1586         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1587         # if we don't unset it we screw up retarded but unfortunately working
1588         # 'MAX(foo.bar)' => { '>', 3 }
1589         $sql_maker->{name_sep} = '';
1590       }
1591
1592       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1593
1594       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1595
1596       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1597       # and if all fails for an utterly naive quoted scalar-with-function
1598       while ($sql =~ /
1599         $rquote $sep $lquote (.+?) $rquote
1600           |
1601         [\s,] \w+ \. (\w+) [\s,]
1602           |
1603         [\s,] $lquote (.+?) $rquote [\s,]
1604       /gx) {
1605         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1606       }
1607     }
1608
1609     for (@parts) {
1610       my $colpiece = $sel_index->{$_} || $_;
1611
1612       # unqualify join-based group_by's. Arcane but possible query
1613       # also horrible horrible hack to alias a column (not a func.)
1614       # (probably need to introduce SQLA syntax)
1615       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1616         my $as = $colpiece;
1617         $as =~ s/\./__/;
1618         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1619       }
1620       push @{$sub_attrs->{select}}, $colpiece;
1621     }
1622   }
1623   else {
1624     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1625     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1626   }
1627
1628   return $rsrc->resultset_class
1629                ->new ($rsrc, $sub_attrs)
1630                 ->as_subselect_rs
1631                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1632                   ->get_column ('count');
1633 }
1634
1635 sub _bool {
1636   return 1;
1637 }
1638
1639 =head2 count_literal
1640
1641 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1642 should only be used in that context. See L</search_literal> for further info.
1643
1644 =over 4
1645
1646 =item Arguments: $sql_fragment, @standalone_bind_values
1647
1648 =item Return Value: $count
1649
1650 =back
1651
1652 Counts the results in a literal query. Equivalent to calling L</search_literal>
1653 with the passed arguments, then L</count>.
1654
1655 =cut
1656
1657 sub count_literal { shift->search_literal(@_)->count; }
1658
1659 =head2 all
1660
1661 =over 4
1662
1663 =item Arguments: none
1664
1665 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1666
1667 =back
1668
1669 Returns all elements in the resultset.
1670
1671 =cut
1672
1673 sub all {
1674   my $self = shift;
1675   if(@_) {
1676       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1677   }
1678
1679   return @{ $self->get_cache } if $self->get_cache;
1680
1681   my @obj;
1682
1683   if (keys %{$self->_resolved_attrs->{collapse}}) {
1684     # Using $self->cursor->all is really just an optimisation.
1685     # If we're collapsing has_many prefetches it probably makes
1686     # very little difference, and this is cleaner than hacking
1687     # _construct_object to survive the approach
1688     $self->cursor->reset;
1689     my @row = $self->cursor->next;
1690     while (@row) {
1691       push(@obj, $self->_construct_object(@row));
1692       @row = (exists $self->{stashed_row}
1693                ? @{delete $self->{stashed_row}}
1694                : $self->cursor->next);
1695     }
1696   } else {
1697     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1698   }
1699
1700   $self->set_cache(\@obj) if $self->{attrs}{cache};
1701
1702   return @obj;
1703 }
1704
1705 =head2 reset
1706
1707 =over 4
1708
1709 =item Arguments: none
1710
1711 =item Return Value: $self
1712
1713 =back
1714
1715 Resets the resultset's cursor, so you can iterate through the elements again.
1716 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1717 another query.
1718
1719 =cut
1720
1721 sub reset {
1722   my ($self) = @_;
1723   delete $self->{_attrs} if exists $self->{_attrs};
1724   $self->{all_cache_position} = 0;
1725   $self->cursor->reset;
1726   return $self;
1727 }
1728
1729 =head2 first
1730
1731 =over 4
1732
1733 =item Arguments: none
1734
1735 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1736
1737 =back
1738
1739 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1740 an object for the first result (or C<undef> if the resultset is empty).
1741
1742 =cut
1743
1744 sub first {
1745   return $_[0]->reset->next;
1746 }
1747
1748
1749 # _rs_update_delete
1750 #
1751 # Determines whether and what type of subquery is required for the $rs operation.
1752 # If grouping is necessary either supplies its own, or verifies the current one
1753 # After all is done delegates to the proper storage method.
1754
1755 sub _rs_update_delete {
1756   my ($self, $op, $values) = @_;
1757
1758   my $cond = $self->{cond};
1759   my $rsrc = $self->result_source;
1760   my $storage = $rsrc->schema->storage;
1761
1762   my $attrs = { %{$self->_resolved_attrs} };
1763
1764   my $existing_group_by = delete $attrs->{group_by};
1765   my $needs_subq = defined $existing_group_by;
1766
1767   # simplify the joinmap and maybe decide if a subquery is necessary
1768   my $relation_classifications = {};
1769
1770   if (ref($attrs->{from}) eq 'ARRAY') {
1771     # if we already know we need a subq, no point of classifying relations
1772     if (!$needs_subq and @{$attrs->{from}} > 1) {
1773       $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1774
1775       $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1776         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1777         $attrs->{select},
1778         $cond,
1779         $attrs
1780       );
1781     }
1782   }
1783   else {
1784     $needs_subq ||= 1; # if {from} is unparseable assume the worst
1785   }
1786
1787   # do we need anything like a subquery?
1788   if (
1789     ! $needs_subq
1790       and
1791     ! keys %{ $relation_classifications->{restricting} || {} }
1792       and
1793     ! $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1794   ) {
1795     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1796     # a condition containing 'me' or other table prefixes will not work
1797     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1798     my $cond = do {
1799       my $sqla = $rsrc->storage->sql_maker;
1800       local $sqla->{_dequalify_idents} = 1;
1801       \[ $sqla->_recurse_where($self->{cond}) ];
1802     };
1803     return $rsrc->storage->$op(
1804       $rsrc,
1805       $op eq 'update' ? $values : (),
1806       $cond,
1807     );
1808   }
1809
1810   # we got this far - means it is time to wrap a subquery
1811   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1812     sprintf(
1813       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1814       $op,
1815       $rsrc->source_name,
1816     )
1817   );
1818
1819   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1820   delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1821   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1822   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1823   my $subrs = (ref $self)->new($rsrc, $attrs);
1824
1825   if (@$idcols == 1) {
1826     return $storage->$op (
1827       $rsrc,
1828       $op eq 'update' ? $values : (),
1829       { $idcols->[0] => { -in => $subrs->as_query } },
1830     );
1831   }
1832   elsif ($storage->_use_multicolumn_in) {
1833     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1834     my $sql_maker = $storage->sql_maker;
1835     my ($sql, @bind) = @${$subrs->as_query};
1836     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1837       join (', ', map { $sql_maker->_quote ($_) } @$idcols),
1838       $sql,
1839     );
1840
1841     return $storage->$op (
1842       $rsrc,
1843       $op eq 'update' ? $values : (),
1844       \[$sql, @bind],
1845     );
1846   }
1847   else {
1848
1849     # if all else fails - get all primary keys and operate over a ORed set
1850     # wrap in a transaction for consistency
1851     # this is where the group_by starts to matter
1852     if (
1853       $existing_group_by
1854         or
1855       keys %{ $relation_classifications->{multiplying} || {} }
1856     ) {
1857       # make sure if there is a supplied group_by it matches the columns compiled above
1858       # perfectly. Anything else can not be sanely executed on most databases so croak
1859       # right then and there
1860       if ($existing_group_by) {
1861         my @current_group_by = map
1862           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1863           @$existing_group_by
1864         ;
1865
1866         if (
1867           join ("\x00", sort @current_group_by)
1868             ne
1869           join ("\x00", sort @{$attrs->{columns}} )
1870         ) {
1871           $self->throw_exception (
1872             "You have just attempted a $op operation on a resultset which does group_by"
1873             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1874             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1875             . ' kind of queries. Please retry the operation with a modified group_by or'
1876             . ' without using one at all.'
1877           );
1878         }
1879       }
1880
1881       $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1882     }
1883
1884     my $guard = $storage->txn_scope_guard;
1885
1886     my @op_condition;
1887     for my $row ($subrs->cursor->all) {
1888       push @op_condition, { map
1889         { $idcols->[$_] => $row->[$_] }
1890         (0 .. $#$idcols)
1891       };
1892     }
1893
1894     my $res = $storage->$op (
1895       $rsrc,
1896       $op eq 'update' ? $values : (),
1897       \@op_condition,
1898     );
1899
1900     $guard->commit;
1901
1902     return $res;
1903   }
1904 }
1905
1906 =head2 update
1907
1908 =over 4
1909
1910 =item Arguments: \%values
1911
1912 =item Return Value: $underlying_storage_rv
1913
1914 =back
1915
1916 Sets the specified columns in the resultset to the supplied values in a
1917 single query. Note that this will not run any accessor/set_column/update
1918 triggers, nor will it update any result object instances derived from this
1919 resultset (this includes the contents of the L<resultset cache|/set_cache>
1920 if any). See L</update_all> if you need to execute any on-update
1921 triggers or cascades defined either by you or a
1922 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1923
1924 The return value is a pass through of what the underlying
1925 storage backend returned, and may vary. See L<DBI/execute> for the most
1926 common case.
1927
1928 =head3 CAVEAT
1929
1930 Note that L</update> does not process/deflate any of the values passed in.
1931 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1932 ensure manually that any value passed to this method will stringify to
1933 something the RDBMS knows how to deal with. A notable example is the
1934 handling of L<DateTime> objects, for more info see:
1935 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1936
1937 =cut
1938
1939 sub update {
1940   my ($self, $values) = @_;
1941   $self->throw_exception('Values for update must be a hash')
1942     unless ref $values eq 'HASH';
1943
1944   return $self->_rs_update_delete ('update', $values);
1945 }
1946
1947 =head2 update_all
1948
1949 =over 4
1950
1951 =item Arguments: \%values
1952
1953 =item Return Value: 1
1954
1955 =back
1956
1957 Fetches all objects and updates them one at a time via
1958 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1959 triggers, while L</update> will not.
1960
1961 =cut
1962
1963 sub update_all {
1964   my ($self, $values) = @_;
1965   $self->throw_exception('Values for update_all must be a hash')
1966     unless ref $values eq 'HASH';
1967
1968   my $guard = $self->result_source->schema->txn_scope_guard;
1969   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1970   $guard->commit;
1971   return 1;
1972 }
1973
1974 =head2 delete
1975
1976 =over 4
1977
1978 =item Arguments: none
1979
1980 =item Return Value: $underlying_storage_rv
1981
1982 =back
1983
1984 Deletes the rows matching this resultset in a single query. Note that this
1985 will not run any delete triggers, nor will it alter the
1986 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1987 derived from this resultset (this includes the contents of the
1988 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1989 execute any on-delete triggers or cascades defined either by you or a
1990 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1991
1992 The return value is a pass through of what the underlying storage backend
1993 returned, and may vary. See L<DBI/execute> for the most common case.
1994
1995 =cut
1996
1997 sub delete {
1998   my $self = shift;
1999   $self->throw_exception('delete does not accept any arguments')
2000     if @_;
2001
2002   return $self->_rs_update_delete ('delete');
2003 }
2004
2005 =head2 delete_all
2006
2007 =over 4
2008
2009 =item Arguments: none
2010
2011 =item Return Value: 1
2012
2013 =back
2014
2015 Fetches all objects and deletes them one at a time via
2016 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2017 triggers, while L</delete> will not.
2018
2019 =cut
2020
2021 sub delete_all {
2022   my $self = shift;
2023   $self->throw_exception('delete_all does not accept any arguments')
2024     if @_;
2025
2026   my $guard = $self->result_source->schema->txn_scope_guard;
2027   $_->delete for $self->all;
2028   $guard->commit;
2029   return 1;
2030 }
2031
2032 =head2 populate
2033
2034 =over 4
2035
2036 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2037
2038 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2039
2040 =back
2041
2042 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2043 arrayrefs.
2044
2045 =over
2046
2047 =item NOTE
2048
2049 The context of this method call has an important effect on what is
2050 submitted to storage. In void context data is fed directly to fastpath
2051 insertion routines provided by the underlying storage (most often
2052 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2053 L<insert|DBIx::Class::Row/insert> calls on the
2054 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2055 augmentation of these methods provided by components. For example if you
2056 are using something like L<DBIx::Class::UUIDColumns> to create primary
2057 keys for you, you will find that your PKs are empty.  In this case you
2058 will have to explicitly force scalar or list context in order to create
2059 those values.
2060
2061 =back
2062
2063 In non-void (scalar or list) context, this method is simply a wrapper
2064 for L</create>. Depending on list or scalar context either a list of
2065 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2066 containing these objects is returned.
2067
2068 When supplying data in "arrayref of arrayrefs" invocation style, the
2069 first element should be a list of column names and each subsequent
2070 element should be a data value in the earlier specified column order.
2071 For example:
2072
2073   $Arstist_rs->populate([
2074     [ qw( artistid name ) ],
2075     [ 100, 'A Formally Unknown Singer' ],
2076     [ 101, 'A singer that jumped the shark two albums ago' ],
2077     [ 102, 'An actually cool singer' ],
2078   ]);
2079
2080 For the arrayref of hashrefs style each hashref should be a structure
2081 suitable for passing to L</create>. Multi-create is also permitted with
2082 this syntax.
2083
2084   $schema->resultset("Artist")->populate([
2085      { artistid => 4, name => 'Manufactured Crap', cds => [
2086         { title => 'My First CD', year => 2006 },
2087         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2088       ],
2089      },
2090      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2091         { title => 'My parents sold me to a record company', year => 2005 },
2092         { title => 'Why Am I So Ugly?', year => 2006 },
2093         { title => 'I Got Surgery and am now Popular', year => 2007 }
2094       ],
2095      },
2096   ]);
2097
2098 If you attempt a void-context multi-create as in the example above (each
2099 Artist also has the related list of CDs), and B<do not> supply the
2100 necessary autoinc foreign key information, this method will proxy to the
2101 less efficient L</create>, and then throw the Result objects away. In this
2102 case there are obviously no benefits to using this method over L</create>.
2103
2104 =cut
2105
2106 sub populate {
2107   my $self = shift;
2108
2109   # cruft placed in standalone method
2110   my $data = $self->_normalize_populate_args(@_);
2111
2112   return unless @$data;
2113
2114   if(defined wantarray) {
2115     my @created;
2116     foreach my $item (@$data) {
2117       push(@created, $self->create($item));
2118     }
2119     return wantarray ? @created : \@created;
2120   }
2121   else {
2122     my $first = $data->[0];
2123
2124     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2125     # it relationship data
2126     my (@rels, @columns);
2127     my $rsrc = $self->result_source;
2128     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2129     for (keys %$first) {
2130       my $ref = ref $first->{$_};
2131       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2132         ? push @rels, $_
2133         : push @columns, $_
2134       ;
2135     }
2136
2137     my @pks = $rsrc->primary_columns;
2138
2139     ## do the belongs_to relationships
2140     foreach my $index (0..$#$data) {
2141
2142       # delegate to create() for any dataset without primary keys with specified relationships
2143       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2144         for my $r (@rels) {
2145           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2146             my @ret = $self->populate($data);
2147             return;
2148           }
2149         }
2150       }
2151
2152       foreach my $rel (@rels) {
2153         next unless ref $data->[$index]->{$rel} eq "HASH";
2154         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2155         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2156         my $related = $result->result_source->_resolve_condition(
2157           $reverse_relinfo->{cond},
2158           $self,
2159           $result,
2160           $rel,
2161         );
2162
2163         delete $data->[$index]->{$rel};
2164         $data->[$index] = {%{$data->[$index]}, %$related};
2165
2166         push @columns, keys %$related if $index == 0;
2167       }
2168     }
2169
2170     ## inherit the data locked in the conditions of the resultset
2171     my ($rs_data) = $self->_merge_with_rscond({});
2172     delete @{$rs_data}{@columns};
2173
2174     ## do bulk insert on current row
2175     $rsrc->storage->insert_bulk(
2176       $rsrc,
2177       [@columns, keys %$rs_data],
2178       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2179     );
2180
2181     ## do the has_many relationships
2182     foreach my $item (@$data) {
2183
2184       my $main_row;
2185
2186       foreach my $rel (@rels) {
2187         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2188
2189         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2190
2191         my $child = $main_row->$rel;
2192
2193         my $related = $child->result_source->_resolve_condition(
2194           $rels->{$rel}{cond},
2195           $child,
2196           $main_row,
2197           $rel,
2198         );
2199
2200         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2201         my @populate = map { {%$_, %$related} } @rows_to_add;
2202
2203         $child->populate( \@populate );
2204       }
2205     }
2206   }
2207 }
2208
2209
2210 # populate() argumnets went over several incarnations
2211 # What we ultimately support is AoH
2212 sub _normalize_populate_args {
2213   my ($self, $arg) = @_;
2214
2215   if (ref $arg eq 'ARRAY') {
2216     if (!@$arg) {
2217       return [];
2218     }
2219     elsif (ref $arg->[0] eq 'HASH') {
2220       return $arg;
2221     }
2222     elsif (ref $arg->[0] eq 'ARRAY') {
2223       my @ret;
2224       my @colnames = @{$arg->[0]};
2225       foreach my $values (@{$arg}[1 .. $#$arg]) {
2226         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2227       }
2228       return \@ret;
2229     }
2230   }
2231
2232   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2233 }
2234
2235 =head2 pager
2236
2237 =over 4
2238
2239 =item Arguments: none
2240
2241 =item Return Value: L<$pager|Data::Page>
2242
2243 =back
2244
2245 Returns a L<Data::Page> object for the current resultset. Only makes
2246 sense for queries with a C<page> attribute.
2247
2248 To get the full count of entries for a paged resultset, call
2249 C<total_entries> on the L<Data::Page> object.
2250
2251 =cut
2252
2253 sub pager {
2254   my ($self) = @_;
2255
2256   return $self->{pager} if $self->{pager};
2257
2258   my $attrs = $self->{attrs};
2259   if (!defined $attrs->{page}) {
2260     $self->throw_exception("Can't create pager for non-paged rs");
2261   }
2262   elsif ($attrs->{page} <= 0) {
2263     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2264   }
2265   $attrs->{rows} ||= 10;
2266
2267   # throw away the paging flags and re-run the count (possibly
2268   # with a subselect) to get the real total count
2269   my $count_attrs = { %$attrs };
2270   delete $count_attrs->{$_} for qw/rows offset page pager/;
2271
2272   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2273
2274   require DBIx::Class::ResultSet::Pager;
2275   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2276     sub { $total_rs->count },  #lazy-get the total
2277     $attrs->{rows},
2278     $self->{attrs}{page},
2279   );
2280 }
2281
2282 =head2 page
2283
2284 =over 4
2285
2286 =item Arguments: $page_number
2287
2288 =item Return Value: L<$resultset|/search>
2289
2290 =back
2291
2292 Returns a resultset for the $page_number page of the resultset on which page
2293 is called, where each page contains a number of rows equal to the 'rows'
2294 attribute set on the resultset (10 by default).
2295
2296 =cut
2297
2298 sub page {
2299   my ($self, $page) = @_;
2300   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2301 }
2302
2303 =head2 new_result
2304
2305 =over 4
2306
2307 =item Arguments: \%col_data
2308
2309 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2310
2311 =back
2312
2313 Creates a new result object in the resultset's result class and returns
2314 it. The row is not inserted into the database at this point, call
2315 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2316 will tell you whether the result object has been inserted or not.
2317
2318 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2319
2320 =cut
2321
2322 sub new_result {
2323   my ($self, $values) = @_;
2324
2325   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2326     if @_ > 2;
2327
2328   $self->throw_exception( "new_result expects a hashref" )
2329     unless (ref $values eq 'HASH');
2330
2331   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2332
2333   my %new = (
2334     %$merged_cond,
2335     @$cols_from_relations
2336       ? (-cols_from_relations => $cols_from_relations)
2337       : (),
2338     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2339   );
2340
2341   return $self->result_class->new(\%new);
2342 }
2343
2344 # _merge_with_rscond
2345 #
2346 # Takes a simple hash of K/V data and returns its copy merged with the
2347 # condition already present on the resultset. Additionally returns an
2348 # arrayref of value/condition names, which were inferred from related
2349 # objects (this is needed for in-memory related objects)
2350 sub _merge_with_rscond {
2351   my ($self, $data) = @_;
2352
2353   my (%new_data, @cols_from_relations);
2354
2355   my $alias = $self->{attrs}{alias};
2356
2357   if (! defined $self->{cond}) {
2358     # just massage $data below
2359   }
2360   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2361     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2362     @cols_from_relations = keys %new_data;
2363   }
2364   elsif (ref $self->{cond} ne 'HASH') {
2365     $self->throw_exception(
2366       "Can't abstract implicit construct, resultset condition not a hash"
2367     );
2368   }
2369   else {
2370     # precendence must be given to passed values over values inherited from
2371     # the cond, so the order here is important.
2372     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2373     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2374
2375     while ( my($col, $value) = each %implied ) {
2376       my $vref = ref $value;
2377       if (
2378         $vref eq 'HASH'
2379           and
2380         keys(%$value) == 1
2381           and
2382         (keys %$value)[0] eq '='
2383       ) {
2384         $new_data{$col} = $value->{'='};
2385       }
2386       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2387         $new_data{$col} = $value;
2388       }
2389     }
2390   }
2391
2392   %new_data = (
2393     %new_data,
2394     %{ $self->_remove_alias($data, $alias) },
2395   );
2396
2397   return (\%new_data, \@cols_from_relations);
2398 }
2399
2400 # _has_resolved_attr
2401 #
2402 # determines if the resultset defines at least one
2403 # of the attributes supplied
2404 #
2405 # used to determine if a subquery is neccessary
2406 #
2407 # supports some virtual attributes:
2408 #   -join
2409 #     This will scan for any joins being present on the resultset.
2410 #     It is not a mere key-search but a deep inspection of {from}
2411 #
2412
2413 sub _has_resolved_attr {
2414   my ($self, @attr_names) = @_;
2415
2416   my $attrs = $self->_resolved_attrs;
2417
2418   my %extra_checks;
2419
2420   for my $n (@attr_names) {
2421     if (grep { $n eq $_ } (qw/-join/) ) {
2422       $extra_checks{$n}++;
2423       next;
2424     }
2425
2426     my $attr =  $attrs->{$n};
2427
2428     next if not defined $attr;
2429
2430     if (ref $attr eq 'HASH') {
2431       return 1 if keys %$attr;
2432     }
2433     elsif (ref $attr eq 'ARRAY') {
2434       return 1 if @$attr;
2435     }
2436     else {
2437       return 1 if $attr;
2438     }
2439   }
2440
2441   # a resolved join is expressed as a multi-level from
2442   return 1 if (
2443     $extra_checks{-join}
2444       and
2445     ref $attrs->{from} eq 'ARRAY'
2446       and
2447     @{$attrs->{from}} > 1
2448   );
2449
2450   return 0;
2451 }
2452
2453 # _collapse_cond
2454 #
2455 # Recursively collapse the condition.
2456
2457 sub _collapse_cond {
2458   my ($self, $cond, $collapsed) = @_;
2459
2460   $collapsed ||= {};
2461
2462   if (ref $cond eq 'ARRAY') {
2463     foreach my $subcond (@$cond) {
2464       next unless ref $subcond;  # -or
2465       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2466     }
2467   }
2468   elsif (ref $cond eq 'HASH') {
2469     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2470       foreach my $subcond (@{$cond->{-and}}) {
2471         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2472       }
2473     }
2474     else {
2475       foreach my $col (keys %$cond) {
2476         my $value = $cond->{$col};
2477         $collapsed->{$col} = $value;
2478       }
2479     }
2480   }
2481
2482   return $collapsed;
2483 }
2484
2485 # _remove_alias
2486 #
2487 # Remove the specified alias from the specified query hash. A copy is made so
2488 # the original query is not modified.
2489
2490 sub _remove_alias {
2491   my ($self, $query, $alias) = @_;
2492
2493   my %orig = %{ $query || {} };
2494   my %unaliased;
2495
2496   foreach my $key (keys %orig) {
2497     if ($key !~ /\./) {
2498       $unaliased{$key} = $orig{$key};
2499       next;
2500     }
2501     $unaliased{$1} = $orig{$key}
2502       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2503   }
2504
2505   return \%unaliased;
2506 }
2507
2508 =head2 as_query
2509
2510 =over 4
2511
2512 =item Arguments: none
2513
2514 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2515
2516 =back
2517
2518 Returns the SQL query and bind vars associated with the invocant.
2519
2520 This is generally used as the RHS for a subquery.
2521
2522 =cut
2523
2524 sub as_query {
2525   my $self = shift;
2526
2527   my $attrs = $self->_resolved_attrs_copy;
2528
2529   # For future use:
2530   #
2531   # in list ctx:
2532   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2533   # $sql also has no wrapping parenthesis in list ctx
2534   #
2535   my $sqlbind = $self->result_source->storage
2536     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2537
2538   return $sqlbind;
2539 }
2540
2541 =head2 find_or_new
2542
2543 =over 4
2544
2545 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2546
2547 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2548
2549 =back
2550
2551   my $artist = $schema->resultset('Artist')->find_or_new(
2552     { artist => 'fred' }, { key => 'artists' });
2553
2554   $cd->cd_to_producer->find_or_new({ producer => $producer },
2555                                    { key => 'primary });
2556
2557 Find an existing record from this resultset using L</find>. if none exists,
2558 instantiate a new result object and return it. The object will not be saved
2559 into your storage until you call L<DBIx::Class::Row/insert> on it.
2560
2561 You most likely want this method when looking for existing rows using a unique
2562 constraint that is not the primary key, or looking for related rows.
2563
2564 If you want objects to be saved immediately, use L</find_or_create> instead.
2565
2566 B<Note>: Make sure to read the documentation of L</find> and understand the
2567 significance of the C<key> attribute, as its lack may skew your search, and
2568 subsequently result in spurious new objects.
2569
2570 B<Note>: Take care when using C<find_or_new> with a table having
2571 columns with default values that you intend to be automatically
2572 supplied by the database (e.g. an auto_increment primary key column).
2573 In normal usage, the value of such columns should NOT be included at
2574 all in the call to C<find_or_new>, even when set to C<undef>.
2575
2576 =cut
2577
2578 sub find_or_new {
2579   my $self     = shift;
2580   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2581   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2582   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2583     return $row;
2584   }
2585   return $self->new_result($hash);
2586 }
2587
2588 =head2 create
2589
2590 =over 4
2591
2592 =item Arguments: \%col_data
2593
2594 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2595
2596 =back
2597
2598 Attempt to create a single new row or a row with multiple related rows
2599 in the table represented by the resultset (and related tables). This
2600 will not check for duplicate rows before inserting, use
2601 L</find_or_create> to do that.
2602
2603 To create one row for this resultset, pass a hashref of key/value
2604 pairs representing the columns of the table and the values you wish to
2605 store. If the appropriate relationships are set up, foreign key fields
2606 can also be passed an object representing the foreign row, and the
2607 value will be set to its primary key.
2608
2609 To create related objects, pass a hashref of related-object column values
2610 B<keyed on the relationship name>. If the relationship is of type C<multi>
2611 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2612 The process will correctly identify columns holding foreign keys, and will
2613 transparently populate them from the keys of the corresponding relation.
2614 This can be applied recursively, and will work correctly for a structure
2615 with an arbitrary depth and width, as long as the relationships actually
2616 exists and the correct column data has been supplied.
2617
2618 Instead of hashrefs of plain related data (key/value pairs), you may
2619 also pass new or inserted objects. New objects (not inserted yet, see
2620 L</new_result>), will be inserted into their appropriate tables.
2621
2622 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2623
2624 Example of creating a new row.
2625
2626   $person_rs->create({
2627     name=>"Some Person",
2628     email=>"somebody@someplace.com"
2629   });
2630
2631 Example of creating a new row and also creating rows in a related C<has_many>
2632 or C<has_one> resultset.  Note Arrayref.
2633
2634   $artist_rs->create(
2635      { artistid => 4, name => 'Manufactured Crap', cds => [
2636         { title => 'My First CD', year => 2006 },
2637         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2638       ],
2639      },
2640   );
2641
2642 Example of creating a new row and also creating a row in a related
2643 C<belongs_to> resultset. Note Hashref.
2644
2645   $cd_rs->create({
2646     title=>"Music for Silly Walks",
2647     year=>2000,
2648     artist => {
2649       name=>"Silly Musician",
2650     }
2651   });
2652
2653 =over
2654
2655 =item WARNING
2656
2657 When subclassing ResultSet never attempt to override this method. Since
2658 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2659 lot of the internals simply never call it, so your override will be
2660 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2661 or L<DBIx::Class::Row/insert> depending on how early in the
2662 L</create> process you need to intervene. See also warning pertaining to
2663 L</new>.
2664
2665 =back
2666
2667 =cut
2668
2669 sub create {
2670   my ($self, $attrs) = @_;
2671   $self->throw_exception( "create needs a hashref" )
2672     unless ref $attrs eq 'HASH';
2673   return $self->new_result($attrs)->insert;
2674 }
2675
2676 =head2 find_or_create
2677
2678 =over 4
2679
2680 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2681
2682 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2683
2684 =back
2685
2686   $cd->cd_to_producer->find_or_create({ producer => $producer },
2687                                       { key => 'primary' });
2688
2689 Tries to find a record based on its primary key or unique constraints; if none
2690 is found, creates one and returns that instead.
2691
2692   my $cd = $schema->resultset('CD')->find_or_create({
2693     cdid   => 5,
2694     artist => 'Massive Attack',
2695     title  => 'Mezzanine',
2696     year   => 2005,
2697   });
2698
2699 Also takes an optional C<key> attribute, to search by a specific key or unique
2700 constraint. For example:
2701
2702   my $cd = $schema->resultset('CD')->find_or_create(
2703     {
2704       artist => 'Massive Attack',
2705       title  => 'Mezzanine',
2706     },
2707     { key => 'cd_artist_title' }
2708   );
2709
2710 B<Note>: Make sure to read the documentation of L</find> and understand the
2711 significance of the C<key> attribute, as its lack may skew your search, and
2712 subsequently result in spurious row creation.
2713
2714 B<Note>: Because find_or_create() reads from the database and then
2715 possibly inserts based on the result, this method is subject to a race
2716 condition. Another process could create a record in the table after
2717 the find has completed and before the create has started. To avoid
2718 this problem, use find_or_create() inside a transaction.
2719
2720 B<Note>: Take care when using C<find_or_create> with a table having
2721 columns with default values that you intend to be automatically
2722 supplied by the database (e.g. an auto_increment primary key column).
2723 In normal usage, the value of such columns should NOT be included at
2724 all in the call to C<find_or_create>, even when set to C<undef>.
2725
2726 See also L</find> and L</update_or_create>. For information on how to declare
2727 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2728
2729 If you need to know if an existing row was found or a new one created use
2730 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2731 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2732 database!
2733
2734   my $cd = $schema->resultset('CD')->find_or_new({
2735     cdid   => 5,
2736     artist => 'Massive Attack',
2737     title  => 'Mezzanine',
2738     year   => 2005,
2739   });
2740
2741   if( !$cd->in_storage ) {
2742       # do some stuff
2743       $cd->insert;
2744   }
2745
2746 =cut
2747
2748 sub find_or_create {
2749   my $self     = shift;
2750   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2751   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2752   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2753     return $row;
2754   }
2755   return $self->create($hash);
2756 }
2757
2758 =head2 update_or_create
2759
2760 =over 4
2761
2762 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2763
2764 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2765
2766 =back
2767
2768   $resultset->update_or_create({ col => $val, ... });
2769
2770 Like L</find_or_create>, but if a row is found it is immediately updated via
2771 C<< $found_row->update (\%col_data) >>.
2772
2773
2774 Takes an optional C<key> attribute to search on a specific unique constraint.
2775 For example:
2776
2777   # In your application
2778   my $cd = $schema->resultset('CD')->update_or_create(
2779     {
2780       artist => 'Massive Attack',
2781       title  => 'Mezzanine',
2782       year   => 1998,
2783     },
2784     { key => 'cd_artist_title' }
2785   );
2786
2787   $cd->cd_to_producer->update_or_create({
2788     producer => $producer,
2789     name => 'harry',
2790   }, {
2791     key => 'primary',
2792   });
2793
2794 B<Note>: Make sure to read the documentation of L</find> and understand the
2795 significance of the C<key> attribute, as its lack may skew your search, and
2796 subsequently result in spurious row creation.
2797
2798 B<Note>: Take care when using C<update_or_create> with a table having
2799 columns with default values that you intend to be automatically
2800 supplied by the database (e.g. an auto_increment primary key column).
2801 In normal usage, the value of such columns should NOT be included at
2802 all in the call to C<update_or_create>, even when set to C<undef>.
2803
2804 See also L</find> and L</find_or_create>. For information on how to declare
2805 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2806
2807 If you need to know if an existing row was updated or a new one created use
2808 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2809 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2810 database!
2811
2812 =cut
2813
2814 sub update_or_create {
2815   my $self = shift;
2816   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2817   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2818
2819   my $row = $self->find($cond, $attrs);
2820   if (defined $row) {
2821     $row->update($cond);
2822     return $row;
2823   }
2824
2825   return $self->create($cond);
2826 }
2827
2828 =head2 update_or_new
2829
2830 =over 4
2831
2832 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2833
2834 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2835
2836 =back
2837
2838   $resultset->update_or_new({ col => $val, ... });
2839
2840 Like L</find_or_new> but if a row is found it is immediately updated via
2841 C<< $found_row->update (\%col_data) >>.
2842
2843 For example:
2844
2845   # In your application
2846   my $cd = $schema->resultset('CD')->update_or_new(
2847     {
2848       artist => 'Massive Attack',
2849       title  => 'Mezzanine',
2850       year   => 1998,
2851     },
2852     { key => 'cd_artist_title' }
2853   );
2854
2855   if ($cd->in_storage) {
2856       # the cd was updated
2857   }
2858   else {
2859       # the cd is not yet in the database, let's insert it
2860       $cd->insert;
2861   }
2862
2863 B<Note>: Make sure to read the documentation of L</find> and understand the
2864 significance of the C<key> attribute, as its lack may skew your search, and
2865 subsequently result in spurious new objects.
2866
2867 B<Note>: Take care when using C<update_or_new> with a table having
2868 columns with default values that you intend to be automatically
2869 supplied by the database (e.g. an auto_increment primary key column).
2870 In normal usage, the value of such columns should NOT be included at
2871 all in the call to C<update_or_new>, even when set to C<undef>.
2872
2873 See also L</find>, L</find_or_create> and L</find_or_new>.
2874
2875 =cut
2876
2877 sub update_or_new {
2878     my $self  = shift;
2879     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2880     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2881
2882     my $row = $self->find( $cond, $attrs );
2883     if ( defined $row ) {
2884         $row->update($cond);
2885         return $row;
2886     }
2887
2888     return $self->new_result($cond);
2889 }
2890
2891 =head2 get_cache
2892
2893 =over 4
2894
2895 =item Arguments: none
2896
2897 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2898
2899 =back
2900
2901 Gets the contents of the cache for the resultset, if the cache is set.
2902
2903 The cache is populated either by using the L</prefetch> attribute to
2904 L</search> or by calling L</set_cache>.
2905
2906 =cut
2907
2908 sub get_cache {
2909   shift->{all_cache};
2910 }
2911
2912 =head2 set_cache
2913
2914 =over 4
2915
2916 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2917
2918 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2919
2920 =back
2921
2922 Sets the contents of the cache for the resultset. Expects an arrayref
2923 of objects of the same class as those produced by the resultset. Note that
2924 if the cache is set, the resultset will return the cached objects rather
2925 than re-querying the database even if the cache attr is not set.
2926
2927 The contents of the cache can also be populated by using the
2928 L</prefetch> attribute to L</search>.
2929
2930 =cut
2931
2932 sub set_cache {
2933   my ( $self, $data ) = @_;
2934   $self->throw_exception("set_cache requires an arrayref")
2935       if defined($data) && (ref $data ne 'ARRAY');
2936   $self->{all_cache} = $data;
2937 }
2938
2939 =head2 clear_cache
2940
2941 =over 4
2942
2943 =item Arguments: none
2944
2945 =item Return Value: undef
2946
2947 =back
2948
2949 Clears the cache for the resultset.
2950
2951 =cut
2952
2953 sub clear_cache {
2954   shift->set_cache(undef);
2955 }
2956
2957 =head2 is_paged
2958
2959 =over 4
2960
2961 =item Arguments: none
2962
2963 =item Return Value: true, if the resultset has been paginated
2964
2965 =back
2966
2967 =cut
2968
2969 sub is_paged {
2970   my ($self) = @_;
2971   return !!$self->{attrs}{page};
2972 }
2973
2974 =head2 is_ordered
2975
2976 =over 4
2977
2978 =item Arguments: none
2979
2980 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2981
2982 =back
2983
2984 =cut
2985
2986 sub is_ordered {
2987   my ($self) = @_;
2988   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2989 }
2990
2991 =head2 related_resultset
2992
2993 =over 4
2994
2995 =item Arguments: $rel_name
2996
2997 =item Return Value: L<$resultset|/search>
2998
2999 =back
3000
3001 Returns a related resultset for the supplied relationship name.
3002
3003   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3004
3005 =cut
3006
3007 sub related_resultset {
3008   my ($self, $rel) = @_;
3009
3010   $self->{related_resultsets} ||= {};
3011   return $self->{related_resultsets}{$rel} ||= do {
3012     my $rsrc = $self->result_source;
3013     my $rel_info = $rsrc->relationship_info($rel);
3014
3015     $self->throw_exception(
3016       "search_related: result source '" . $rsrc->source_name .
3017         "' has no such relationship $rel")
3018       unless $rel_info;
3019
3020     my $attrs = $self->_chain_relationship($rel);
3021
3022     my $join_count = $attrs->{seen_join}{$rel};
3023
3024     my $alias = $self->result_source->storage
3025         ->relname_to_table_alias($rel, $join_count);
3026
3027     # since this is search_related, and we already slid the select window inwards
3028     # (the select/as attrs were deleted in the beginning), we need to flip all
3029     # left joins to inner, so we get the expected results
3030     # read the comment on top of the actual function to see what this does
3031     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3032
3033
3034     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3035     delete @{$attrs}{qw(result_class alias)};
3036
3037     my $new_cache;
3038
3039     if (my $cache = $self->get_cache) {
3040       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3041         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3042                         @$cache ];
3043       }
3044     }
3045
3046     my $rel_source = $rsrc->related_source($rel);
3047
3048     my $new = do {
3049
3050       # The reason we do this now instead of passing the alias to the
3051       # search_rs below is that if you wrap/overload resultset on the
3052       # source you need to know what alias it's -going- to have for things
3053       # to work sanely (e.g. RestrictWithObject wants to be able to add
3054       # extra query restrictions, and these may need to be $alias.)
3055
3056       my $rel_attrs = $rel_source->resultset_attributes;
3057       local $rel_attrs->{alias} = $alias;
3058
3059       $rel_source->resultset
3060                  ->search_rs(
3061                      undef, {
3062                        %$attrs,
3063                        where => $attrs->{where},
3064                    });
3065     };
3066     $new->set_cache($new_cache) if $new_cache;
3067     $new;
3068   };
3069 }
3070
3071 =head2 current_source_alias
3072
3073 =over 4
3074
3075 =item Arguments: none
3076
3077 =item Return Value: $source_alias
3078
3079 =back
3080
3081 Returns the current table alias for the result source this resultset is built
3082 on, that will be used in the SQL query. Usually it is C<me>.
3083
3084 Currently the source alias that refers to the result set returned by a
3085 L</search>/L</find> family method depends on how you got to the resultset: it's
3086 C<me> by default, but eg. L</search_related> aliases it to the related result
3087 source name (and keeps C<me> referring to the original result set). The long
3088 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3089 (and make this method unnecessary).
3090
3091 Thus it's currently necessary to use this method in predefined queries (see
3092 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3093 source alias of the current result set:
3094
3095   # in a result set class
3096   sub modified_by {
3097     my ($self, $user) = @_;
3098
3099     my $me = $self->current_source_alias;
3100
3101     return $self->search({
3102       "$me.modified" => $user->id,
3103     });
3104   }
3105
3106 =cut
3107
3108 sub current_source_alias {
3109   my ($self) = @_;
3110
3111   return ($self->{attrs} || {})->{alias} || 'me';
3112 }
3113
3114 =head2 as_subselect_rs
3115
3116 =over 4
3117
3118 =item Arguments: none
3119
3120 =item Return Value: L<$resultset|/search>
3121
3122 =back
3123
3124 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3125 "virtual view" by including it as a subquery within the from clause.  From this
3126 point on, any joined tables are inaccessible to ->search on the resultset (as if
3127 it were simply where-filtered without joins).  For example:
3128
3129  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3130
3131  # 'x' now pollutes the query namespace
3132
3133  # So the following works as expected
3134  my $ok_rs = $rs->search({'x.other' => 1});
3135
3136  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3137  # def) we look for one row with contradictory terms and join in another table
3138  # (aliased 'x_2') which we never use
3139  my $broken_rs = $rs->search({'x.name' => 'def'});
3140
3141  my $rs2 = $rs->as_subselect_rs;
3142
3143  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3144  my $not_joined_rs = $rs2->search({'x.other' => 1});
3145
3146  # works as expected: finds a 'table' row related to two x rows (abc and def)
3147  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3148
3149 Another example of when one might use this would be to select a subset of
3150 columns in a group by clause:
3151
3152  my $rs = $schema->resultset('Bar')->search(undef, {
3153    group_by => [qw{ id foo_id baz_id }],
3154  })->as_subselect_rs->search(undef, {
3155    columns => [qw{ id foo_id }]
3156  });
3157
3158 In the above example normally columns would have to be equal to the group by,
3159 but because we isolated the group by into a subselect the above works.
3160
3161 =cut
3162
3163 sub as_subselect_rs {
3164   my $self = shift;
3165
3166   my $attrs = $self->_resolved_attrs;
3167
3168   my $fresh_rs = (ref $self)->new (
3169     $self->result_source
3170   );
3171
3172   # these pieces will be locked in the subquery
3173   delete $fresh_rs->{cond};
3174   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3175
3176   return $fresh_rs->search( {}, {
3177     from => [{
3178       $attrs->{alias} => $self->as_query,
3179       -alias  => $attrs->{alias},
3180       -rsrc   => $self->result_source,
3181     }],
3182     alias => $attrs->{alias},
3183   });
3184 }
3185
3186 # This code is called by search_related, and makes sure there
3187 # is clear separation between the joins before, during, and
3188 # after the relationship. This information is needed later
3189 # in order to properly resolve prefetch aliases (any alias
3190 # with a relation_chain_depth less than the depth of the
3191 # current prefetch is not considered)
3192 #
3193 # The increments happen twice per join. An even number means a
3194 # relationship specified via a search_related, whereas an odd
3195 # number indicates a join/prefetch added via attributes
3196 #
3197 # Also this code will wrap the current resultset (the one we
3198 # chain to) in a subselect IFF it contains limiting attributes
3199 sub _chain_relationship {
3200   my ($self, $rel) = @_;
3201   my $source = $self->result_source;
3202   my $attrs = { %{$self->{attrs}||{}} };
3203
3204   # we need to take the prefetch the attrs into account before we
3205   # ->_resolve_join as otherwise they get lost - captainL
3206   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3207
3208   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3209
3210   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3211
3212   my $from;
3213   my @force_subq_attrs = qw/offset rows group_by having/;
3214
3215   if (
3216     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3217       ||
3218     $self->_has_resolved_attr (@force_subq_attrs)
3219   ) {
3220     # Nuke the prefetch (if any) before the new $rs attrs
3221     # are resolved (prefetch is useless - we are wrapping
3222     # a subquery anyway).
3223     my $rs_copy = $self->search;
3224     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3225       $rs_copy->{attrs}{join},
3226       delete $rs_copy->{attrs}{prefetch},
3227     );
3228
3229     $from = [{
3230       -rsrc   => $source,
3231       -alias  => $attrs->{alias},
3232       $attrs->{alias} => $rs_copy->as_query,
3233     }];
3234     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3235     $seen->{-relation_chain_depth} = 0;
3236   }
3237   elsif ($attrs->{from}) {  #shallow copy suffices
3238     $from = [ @{$attrs->{from}} ];
3239   }
3240   else {
3241     $from = [{
3242       -rsrc  => $source,
3243       -alias => $attrs->{alias},
3244       $attrs->{alias} => $source->from,
3245     }];
3246   }
3247
3248   my $jpath = ($seen->{-relation_chain_depth})
3249     ? $from->[-1][0]{-join_path}
3250     : [];
3251
3252   my @requested_joins = $source->_resolve_join(
3253     $join,
3254     $attrs->{alias},
3255     $seen,
3256     $jpath,
3257   );
3258
3259   push @$from, @requested_joins;
3260
3261   $seen->{-relation_chain_depth}++;
3262
3263   # if $self already had a join/prefetch specified on it, the requested
3264   # $rel might very well be already included. What we do in this case
3265   # is effectively a no-op (except that we bump up the chain_depth on
3266   # the join in question so we could tell it *is* the search_related)
3267   my $already_joined;
3268
3269   # we consider the last one thus reverse
3270   for my $j (reverse @requested_joins) {
3271     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3272     if ($rel eq $last_j) {
3273       $j->[0]{-relation_chain_depth}++;
3274       $already_joined++;
3275       last;
3276     }
3277   }
3278
3279   unless ($already_joined) {
3280     push @$from, $source->_resolve_join(
3281       $rel,
3282       $attrs->{alias},
3283       $seen,
3284       $jpath,
3285     );
3286   }
3287
3288   $seen->{-relation_chain_depth}++;
3289
3290   return {%$attrs, from => $from, seen_join => $seen};
3291 }
3292
3293 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3294 sub _resolved_attrs_copy {
3295   my $self = shift;
3296   return { %{$self->_resolved_attrs (@_)} };
3297 }
3298
3299 sub _resolved_attrs {
3300   my $self = shift;
3301   return $self->{_attrs} if $self->{_attrs};
3302
3303   my $attrs  = { %{ $self->{attrs} || {} } };
3304   my $source = $self->result_source;
3305   my $alias  = $attrs->{alias};
3306
3307   # default selection list
3308   $attrs->{columns} = [ $source->columns ]
3309     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3310
3311   # merge selectors together
3312   for (qw/columns select as/) {
3313     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3314       if $attrs->{$_} or $attrs->{"+$_"};
3315   }
3316
3317   # disassemble columns
3318   my (@sel, @as);
3319   if (my $cols = delete $attrs->{columns}) {
3320     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3321       if (ref $c eq 'HASH') {
3322         for my $as (sort keys %$c) {
3323           push @sel, $c->{$as};
3324           push @as, $as;
3325         }
3326       }
3327       else {
3328         push @sel, $c;
3329         push @as, $c;
3330       }
3331     }
3332   }
3333
3334   # when trying to weed off duplicates later do not go past this point -
3335   # everything added from here on is unbalanced "anyone's guess" stuff
3336   my $dedup_stop_idx = $#as;
3337
3338   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3339     if $attrs->{as};
3340   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3341     if $attrs->{select};
3342
3343   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3344   for (@sel) {
3345     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3346   }
3347
3348   # disqualify all $alias.col as-bits (collapser mandated)
3349   for (@as) {
3350     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3351   }
3352
3353   # de-duplicate the result (remove *identical* select/as pairs)
3354   # and also die on duplicate {as} pointing to different {select}s
3355   # not using a c-style for as the condition is prone to shrinkage
3356   my $seen;
3357   my $i = 0;
3358   while ($i <= $dedup_stop_idx) {
3359     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3360       splice @sel, $i, 1;
3361       splice @as, $i, 1;
3362       $dedup_stop_idx--;
3363     }
3364     elsif ($seen->{$as[$i]}++) {
3365       $self->throw_exception(
3366         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3367       );
3368     }
3369     else {
3370       $i++;
3371     }
3372   }
3373
3374   $attrs->{select} = \@sel;
3375   $attrs->{as} = \@as;
3376
3377   $attrs->{from} ||= [{
3378     -rsrc   => $source,
3379     -alias  => $self->{attrs}{alias},
3380     $self->{attrs}{alias} => $source->from,
3381   }];
3382
3383   if ( $attrs->{join} || $attrs->{prefetch} ) {
3384
3385     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3386       if ref $attrs->{from} ne 'ARRAY';
3387
3388     my $join = (delete $attrs->{join}) || {};
3389
3390     if ( defined $attrs->{prefetch} ) {
3391       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3392     }
3393
3394     $attrs->{from} =    # have to copy here to avoid corrupting the original
3395       [
3396         @{ $attrs->{from} },
3397         $source->_resolve_join(
3398           $join,
3399           $alias,
3400           { %{ $attrs->{seen_join} || {} } },
3401           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3402             ? $attrs->{from}[-1][0]{-join_path}
3403             : []
3404           ,
3405         )
3406       ];
3407   }
3408
3409   if ( defined $attrs->{order_by} ) {
3410     $attrs->{order_by} = (
3411       ref( $attrs->{order_by} ) eq 'ARRAY'
3412       ? [ @{ $attrs->{order_by} } ]
3413       : [ $attrs->{order_by} || () ]
3414     );
3415   }
3416
3417   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3418     $attrs->{group_by} = [ $attrs->{group_by} ];
3419   }
3420
3421   # generate the distinct induced group_by early, as prefetch will be carried via a
3422   # subquery (since a group_by is present)
3423   if (delete $attrs->{distinct}) {
3424     if ($attrs->{group_by}) {
3425       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3426     }
3427     else {
3428       # distinct affects only the main selection part, not what prefetch may
3429       # add below.
3430       $attrs->{group_by} = $source->storage->_group_over_selection (
3431         $attrs->{from},
3432         $attrs->{select},
3433         $attrs->{order_by},
3434       );
3435     }
3436   }
3437
3438   $attrs->{collapse} ||= {};
3439   if ($attrs->{prefetch}) {
3440
3441     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3442       if $attrs->{_dark_selector};
3443
3444     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3445
3446     my $prefetch_ordering = [];
3447
3448     # this is a separate structure (we don't look in {from} directly)
3449     # as the resolver needs to shift things off the lists to work
3450     # properly (identical-prefetches on different branches)
3451     my $join_map = {};
3452     if (ref $attrs->{from} eq 'ARRAY') {
3453
3454       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3455
3456       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3457         next unless $j->[0]{-alias};
3458         next unless $j->[0]{-join_path};
3459         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3460
3461         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3462
3463         my $p = $join_map;
3464         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3465         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3466       }
3467     }
3468
3469     my @prefetch =
3470       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3471
3472     # we need to somehow mark which columns came from prefetch
3473     if (@prefetch) {
3474       my $sel_end = $#{$attrs->{select}};
3475       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3476     }
3477
3478     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3479     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3480
3481     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3482     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3483   }
3484
3485   # if both page and offset are specified, produce a combined offset
3486   # even though it doesn't make much sense, this is what pre 081xx has
3487   # been doing
3488   if (my $page = delete $attrs->{page}) {
3489     $attrs->{offset} =
3490       ($attrs->{rows} * ($page - 1))
3491             +
3492       ($attrs->{offset} || 0)
3493     ;
3494   }
3495
3496   return $self->{_attrs} = $attrs;
3497 }
3498
3499 sub _rollout_attr {
3500   my ($self, $attr) = @_;
3501
3502   if (ref $attr eq 'HASH') {
3503     return $self->_rollout_hash($attr);
3504   } elsif (ref $attr eq 'ARRAY') {
3505     return $self->_rollout_array($attr);
3506   } else {
3507     return [$attr];
3508   }
3509 }
3510
3511 sub _rollout_array {
3512   my ($self, $attr) = @_;
3513
3514   my @rolled_array;
3515   foreach my $element (@{$attr}) {
3516     if (ref $element eq 'HASH') {
3517       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3518     } elsif (ref $element eq 'ARRAY') {
3519       #  XXX - should probably recurse here
3520       push( @rolled_array, @{$self->_rollout_array($element)} );
3521     } else {
3522       push( @rolled_array, $element );
3523     }
3524   }
3525   return \@rolled_array;
3526 }
3527
3528 sub _rollout_hash {
3529   my ($self, $attr) = @_;
3530
3531   my @rolled_array;
3532   foreach my $key (keys %{$attr}) {
3533     push( @rolled_array, { $key => $attr->{$key} } );
3534   }
3535   return \@rolled_array;
3536 }
3537
3538 sub _calculate_score {
3539   my ($self, $a, $b) = @_;
3540
3541   if (defined $a xor defined $b) {
3542     return 0;
3543   }
3544   elsif (not defined $a) {
3545     return 1;
3546   }
3547
3548   if (ref $b eq 'HASH') {
3549     my ($b_key) = keys %{$b};
3550     if (ref $a eq 'HASH') {
3551       my ($a_key) = keys %{$a};
3552       if ($a_key eq $b_key) {
3553         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3554       } else {
3555         return 0;
3556       }
3557     } else {
3558       return ($a eq $b_key) ? 1 : 0;
3559     }
3560   } else {
3561     if (ref $a eq 'HASH') {
3562       my ($a_key) = keys %{$a};
3563       return ($b eq $a_key) ? 1 : 0;
3564     } else {
3565       return ($b eq $a) ? 1 : 0;
3566     }
3567   }
3568 }
3569
3570 sub _merge_joinpref_attr {
3571   my ($self, $orig, $import) = @_;
3572
3573   return $import unless defined($orig);
3574   return $orig unless defined($import);
3575
3576   $orig = $self->_rollout_attr($orig);
3577   $import = $self->_rollout_attr($import);
3578
3579   my $seen_keys;
3580   foreach my $import_element ( @{$import} ) {
3581     # find best candidate from $orig to merge $b_element into
3582     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3583     foreach my $orig_element ( @{$orig} ) {
3584       my $score = $self->_calculate_score( $orig_element, $import_element );
3585       if ($score > $best_candidate->{score}) {
3586         $best_candidate->{position} = $position;
3587         $best_candidate->{score} = $score;
3588       }
3589       $position++;
3590     }
3591     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3592     $import_key = '' if not defined $import_key;
3593
3594     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3595       push( @{$orig}, $import_element );
3596     } else {
3597       my $orig_best = $orig->[$best_candidate->{position}];
3598       # merge orig_best and b_element together and replace original with merged
3599       if (ref $orig_best ne 'HASH') {
3600         $orig->[$best_candidate->{position}] = $import_element;
3601       } elsif (ref $import_element eq 'HASH') {
3602         my ($key) = keys %{$orig_best};
3603         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3604       }
3605     }
3606     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3607   }
3608
3609   return $orig;
3610 }
3611
3612 {
3613   my $hm;
3614
3615   sub _merge_attr {
3616     $hm ||= do {
3617       require Hash::Merge;
3618       my $hm = Hash::Merge->new;
3619
3620       $hm->specify_behavior({
3621         SCALAR => {
3622           SCALAR => sub {
3623             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3624
3625             if ($defl xor $defr) {
3626               return [ $defl ? $_[0] : $_[1] ];
3627             }
3628             elsif (! $defl) {
3629               return [];
3630             }
3631             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3632               return [ $_[0] ];
3633             }
3634             else {
3635               return [$_[0], $_[1]];
3636             }
3637           },
3638           ARRAY => sub {
3639             return $_[1] if !defined $_[0];
3640             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3641             return [$_[0], @{$_[1]}]
3642           },
3643           HASH  => sub {
3644             return [] if !defined $_[0] and !keys %{$_[1]};
3645             return [ $_[1] ] if !defined $_[0];
3646             return [ $_[0] ] if !keys %{$_[1]};
3647             return [$_[0], $_[1]]
3648           },
3649         },
3650         ARRAY => {
3651           SCALAR => sub {
3652             return $_[0] if !defined $_[1];
3653             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3654             return [@{$_[0]}, $_[1]]
3655           },
3656           ARRAY => sub {
3657             my @ret = @{$_[0]} or return $_[1];
3658             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3659             my %idx = map { $_ => 1 } @ret;
3660             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3661             \@ret;
3662           },
3663           HASH => sub {
3664             return [ $_[1] ] if ! @{$_[0]};
3665             return $_[0] if !keys %{$_[1]};
3666             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3667             return [ @{$_[0]}, $_[1] ];
3668           },
3669         },
3670         HASH => {
3671           SCALAR => sub {
3672             return [] if !keys %{$_[0]} and !defined $_[1];
3673             return [ $_[0] ] if !defined $_[1];
3674             return [ $_[1] ] if !keys %{$_[0]};
3675             return [$_[0], $_[1]]
3676           },
3677           ARRAY => sub {
3678             return [] if !keys %{$_[0]} and !@{$_[1]};
3679             return [ $_[0] ] if !@{$_[1]};
3680             return $_[1] if !keys %{$_[0]};
3681             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3682             return [ $_[0], @{$_[1]} ];
3683           },
3684           HASH => sub {
3685             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3686             return [ $_[0] ] if !keys %{$_[1]};
3687             return [ $_[1] ] if !keys %{$_[0]};
3688             return [ $_[0] ] if $_[0] eq $_[1];
3689             return [ $_[0], $_[1] ];
3690           },
3691         }
3692       } => 'DBIC_RS_ATTR_MERGER');
3693       $hm;
3694     };
3695
3696     return $hm->merge ($_[1], $_[2]);
3697   }
3698 }
3699
3700 sub STORABLE_freeze {
3701   my ($self, $cloning) = @_;
3702   my $to_serialize = { %$self };
3703
3704   # A cursor in progress can't be serialized (and would make little sense anyway)
3705   delete $to_serialize->{cursor};
3706
3707   # nor is it sensical to store a not-yet-fired-count pager
3708   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3709     delete $to_serialize->{pager};
3710   }
3711
3712   Storable::nfreeze($to_serialize);
3713 }
3714
3715 # need this hook for symmetry
3716 sub STORABLE_thaw {
3717   my ($self, $cloning, $serialized) = @_;
3718
3719   %$self = %{ Storable::thaw($serialized) };
3720
3721   $self;
3722 }
3723
3724
3725 =head2 throw_exception
3726
3727 See L<DBIx::Class::Schema/throw_exception> for details.
3728
3729 =cut
3730
3731 sub throw_exception {
3732   my $self=shift;
3733
3734   if (ref $self and my $rsrc = $self->result_source) {
3735     $rsrc->throw_exception(@_)
3736   }
3737   else {
3738     DBIx::Class::Exception->throw(@_);
3739   }
3740 }
3741
3742 # XXX: FIXME: Attributes docs need clearing up
3743
3744 =head1 ATTRIBUTES
3745
3746 Attributes are used to refine a ResultSet in various ways when
3747 searching for data. They can be passed to any method which takes an
3748 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3749 L</count>.
3750
3751 Default attributes can be set on the result class using
3752 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3753 the CAVEATS on that feature before using it!)
3754
3755 These are in no particular order:
3756
3757 =head2 order_by
3758
3759 =over 4
3760
3761 =item Value: ( $order_by | \@order_by | \%order_by )
3762
3763 =back
3764
3765 Which column(s) to order the results by.
3766
3767 [The full list of suitable values is documented in
3768 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3769 common options.]
3770
3771 If a single column name, or an arrayref of names is supplied, the
3772 argument is passed through directly to SQL. The hashref syntax allows
3773 for connection-agnostic specification of ordering direction:
3774
3775  For descending order:
3776
3777   order_by => { -desc => [qw/col1 col2 col3/] }
3778
3779  For explicit ascending order:
3780
3781   order_by => { -asc => 'col' }
3782
3783 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3784 supported, although you are strongly encouraged to use the hashref
3785 syntax as outlined above.
3786
3787 =head2 columns
3788
3789 =over 4
3790
3791 =item Value: \@columns
3792
3793 =back
3794
3795 Shortcut to request a particular set of columns to be retrieved. Each
3796 column spec may be a string (a table column name), or a hash (in which
3797 case the key is the C<as> value, and the value is used as the C<select>
3798 expression). Adds C<me.> onto the start of any column without a C<.> in
3799 it and sets C<select> from that, then auto-populates C<as> from
3800 C<select> as normal. (You may also use the C<cols> attribute, as in
3801 earlier versions of DBIC.)
3802
3803 Essentially C<columns> does the same as L</select> and L</as>.
3804
3805     columns => [ 'foo', { bar => 'baz' } ]
3806
3807 is the same as
3808
3809     select => [qw/foo baz/],
3810     as => [qw/foo bar/]
3811
3812 =head2 +columns
3813
3814 =over 4
3815
3816 =item Value: \@columns
3817
3818 =back
3819
3820 Indicates additional columns to be selected from storage. Works the same
3821 as L</columns> but adds columns to the selection. (You may also use the
3822 C<include_columns> attribute, as in earlier versions of DBIC). For
3823 example:-
3824
3825   $schema->resultset('CD')->search(undef, {
3826     '+columns' => ['artist.name'],
3827     join => ['artist']
3828   });
3829
3830 would return all CDs and include a 'name' column to the information
3831 passed to object inflation. Note that the 'artist' is the name of the
3832 column (or relationship) accessor, and 'name' is the name of the column
3833 accessor in the related table.
3834
3835 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3836 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3837 unary plus operator before it.
3838
3839 =head2 include_columns
3840
3841 =over 4
3842
3843 =item Value: \@columns
3844
3845 =back
3846
3847 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3848
3849 =head2 select
3850
3851 =over 4
3852
3853 =item Value: \@select_columns
3854
3855 =back
3856
3857 Indicates which columns should be selected from the storage. You can use
3858 column names, or in the case of RDBMS back ends, function or stored procedure
3859 names:
3860
3861   $rs = $schema->resultset('Employee')->search(undef, {
3862     select => [
3863       'name',
3864       { count => 'employeeid' },
3865       { max => { length => 'name' }, -as => 'longest_name' }
3866     ]
3867   });
3868
3869   # Equivalent SQL
3870   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3871
3872 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3873 use L</select>, to instruct DBIx::Class how to store the result of the column.
3874 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3875 identifier aliasing. You can however alias a function, so you can use it in
3876 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3877 attribute> supplied as shown in the example above.
3878
3879 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3880 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3881 unary plus operator before it.
3882
3883 =head2 +select
3884
3885 =over 4
3886
3887 Indicates additional columns to be selected from storage.  Works the same as
3888 L</select> but adds columns to the default selection, instead of specifying
3889 an explicit list.
3890
3891 =back
3892
3893 =head2 +as
3894
3895 =over 4
3896
3897 Indicates additional column names for those added via L</+select>. See L</as>.
3898
3899 =back
3900
3901 =head2 as
3902
3903 =over 4
3904
3905 =item Value: \@inflation_names
3906
3907 =back
3908
3909 Indicates column names for object inflation. That is L</as> indicates the
3910 slot name in which the column value will be stored within the
3911 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3912 identifier by the C<get_column> method (or via the object accessor B<if one
3913 with the same name already exists>) as shown below. The L</as> attribute has
3914 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3915
3916   $rs = $schema->resultset('Employee')->search(undef, {
3917     select => [
3918       'name',
3919       { count => 'employeeid' },
3920       { max => { length => 'name' }, -as => 'longest_name' }
3921     ],
3922     as => [qw/
3923       name
3924       employee_count
3925       max_name_length
3926     /],
3927   });
3928
3929 If the object against which the search is performed already has an accessor
3930 matching a column name specified in C<as>, the value can be retrieved using
3931 the accessor as normal:
3932
3933   my $name = $employee->name();
3934
3935 If on the other hand an accessor does not exist in the object, you need to
3936 use C<get_column> instead:
3937
3938   my $employee_count = $employee->get_column('employee_count');
3939
3940 You can create your own accessors if required - see
3941 L<DBIx::Class::Manual::Cookbook> for details.
3942
3943 =head2 join
3944
3945 =over 4
3946
3947 =item Value: ($rel_name | \@rel_names | \%rel_names)
3948
3949 =back
3950
3951 Contains a list of relationships that should be joined for this query.  For
3952 example:
3953
3954   # Get CDs by Nine Inch Nails
3955   my $rs = $schema->resultset('CD')->search(
3956     { 'artist.name' => 'Nine Inch Nails' },
3957     { join => 'artist' }
3958   );
3959
3960 Can also contain a hash reference to refer to the other relation's relations.
3961 For example:
3962
3963   package MyApp::Schema::Track;
3964   use base qw/DBIx::Class/;
3965   __PACKAGE__->table('track');
3966   __PACKAGE__->add_columns(qw/trackid cd position title/);
3967   __PACKAGE__->set_primary_key('trackid');
3968   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3969   1;
3970
3971   # In your application
3972   my $rs = $schema->resultset('Artist')->search(
3973     { 'track.title' => 'Teardrop' },
3974     {
3975       join     => { cd => 'track' },
3976       order_by => 'artist.name',
3977     }
3978   );
3979
3980 You need to use the relationship (not the table) name in  conditions,
3981 because they are aliased as such. The current table is aliased as "me", so
3982 you need to use me.column_name in order to avoid ambiguity. For example:
3983
3984   # Get CDs from 1984 with a 'Foo' track
3985   my $rs = $schema->resultset('CD')->search(
3986     {
3987       'me.year' => 1984,
3988       'tracks.name' => 'Foo'
3989     },
3990     { join => 'tracks' }
3991   );
3992
3993 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3994 similarly for a third time). For e.g.
3995
3996   my $rs = $schema->resultset('Artist')->search({
3997     'cds.title'   => 'Down to Earth',
3998     'cds_2.title' => 'Popular',
3999   }, {
4000     join => [ qw/cds cds/ ],
4001   });
4002
4003 will return a set of all artists that have both a cd with title 'Down
4004 to Earth' and a cd with title 'Popular'.
4005
4006 If you want to fetch related objects from other tables as well, see C<prefetch>
4007 below.
4008
4009  NOTE: An internal join-chain pruner will discard certain joins while
4010  constructing the actual SQL query, as long as the joins in question do not
4011  affect the retrieved result. This for example includes 1:1 left joins
4012  that are not part of the restriction specification (WHERE/HAVING) nor are
4013  a part of the query selection.
4014
4015 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4016
4017 =head2 prefetch
4018
4019 =over 4
4020
4021 =item Value: ($rel_name | \@rel_names | \%rel_names)
4022
4023 =back
4024
4025 Contains one or more relationships that should be fetched along with
4026 the main query (when they are accessed afterwards the data will
4027 already be available, without extra queries to the database).  This is
4028 useful for when you know you will need the related objects, because it
4029 saves at least one query:
4030
4031   my $rs = $schema->resultset('Tag')->search(
4032     undef,
4033     {
4034       prefetch => {
4035         cd => 'artist'
4036       }
4037     }
4038   );
4039
4040 The initial search results in SQL like the following:
4041
4042   SELECT tag.*, cd.*, artist.* FROM tag
4043   JOIN cd ON tag.cd = cd.cdid
4044   JOIN artist ON cd.artist = artist.artistid
4045
4046 L<DBIx::Class> has no need to go back to the database when we access the
4047 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4048 case.
4049
4050 Simple prefetches will be joined automatically, so there is no need
4051 for a C<join> attribute in the above search.
4052
4053 L</prefetch> can be used with the any of the relationship types and
4054 multiple prefetches can be specified together. Below is a more complex
4055 example that prefetches a CD's artist, its liner notes (if present),
4056 the cover image, the tracks on that cd, and the guests on those
4057 tracks.
4058
4059  # Assuming:
4060  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4061  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4062  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4063  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4064
4065  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4066
4067  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4068
4069
4070  my $rs = $schema->resultset('CD')->search(
4071    undef,
4072    {
4073      prefetch => [
4074        { artist => 'record_label'},  # belongs_to => belongs_to
4075        'liner_note',                 # might_have
4076        'cover_image',                # has_one
4077        { tracks => 'guests' },       # has_many => has_many
4078      ]
4079    }
4080  );
4081
4082 This will produce SQL like the following:
4083
4084  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4085         tracks.*, guests.*
4086    FROM cd me
4087    JOIN artist artist
4088      ON artist.artistid = me.artistid
4089    JOIN record_label record_label
4090      ON record_label.labelid = artist.labelid
4091    LEFT JOIN track tracks
4092      ON tracks.cdid = me.cdid
4093    LEFT JOIN guest guests
4094      ON guests.trackid = track.trackid
4095    LEFT JOIN liner_notes liner_note
4096      ON liner_note.cdid = me.cdid
4097    JOIN cd_artwork cover_image
4098      ON cover_image.cdid = me.cdid
4099  ORDER BY tracks.cd
4100
4101 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4102 C<tracks>, and C<guests> of the CD will all be available through the
4103 relationship accessors without the need for additional queries to the
4104 database.
4105
4106 However, there is one caveat to be observed: it can be dangerous to
4107 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4108 relationship on a given level. e.g.:
4109
4110  my $rs = $schema->resultset('CD')->search(
4111    undef,
4112    {
4113      prefetch => [
4114        'tracks',                         # has_many
4115        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4116      ]
4117    }
4118  );
4119
4120 The collapser currently can't identify duplicate tuples for multiple
4121 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4122 result the second L<has_many|DBIx::Class::Relationship/has_many>
4123 relation could contain redundant objects.
4124
4125 =head3 Using L</prefetch> with L</join>
4126
4127 L</prefetch> implies a L</join> with the equivalent argument, and is
4128 properly merged with any existing L</join> specification. So the
4129 following:
4130
4131   my $rs = $schema->resultset('CD')->search(
4132    {'record_label.name' => 'Music Product Ltd.'},
4133    {
4134      join     => {artist => 'record_label'},
4135      prefetch => 'artist',
4136    }
4137  );
4138
4139 ... will work, searching on the record label's name, but only
4140 prefetching the C<artist>.
4141
4142 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4143
4144 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4145 prefetched relations.  So given:
4146
4147   my $rs = $schema->resultset('CD')->search(
4148    undef,
4149    {
4150      select   => ['cd.title'],
4151      as       => ['cd_title'],
4152      prefetch => 'artist',
4153    }
4154  );
4155
4156 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4157 becomes: C<'cd_title', 'artist.*'>.
4158
4159 =head3 CAVEATS
4160
4161 Prefetch does a lot of deep magic. As such, it may not behave exactly
4162 as you might expect.
4163
4164 =over 4
4165
4166 =item *
4167
4168 Prefetch uses the L</cache> to populate the prefetched relationships. This
4169 may or may not be what you want.
4170
4171 =item *
4172
4173 If you specify a condition on a prefetched relationship, ONLY those
4174 rows that match the prefetched condition will be fetched into that relationship.
4175 This means that adding prefetch to a search() B<may alter> what is returned by
4176 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4177
4178   my $artist_rs = $schema->resultset('Artist')->search({
4179       'cds.year' => 2008,
4180   }, {
4181       join => 'cds',
4182   });
4183
4184   my $count = $artist_rs->first->cds->count;
4185
4186   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4187
4188   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4189
4190   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4191
4192 that cmp_ok() may or may not pass depending on the datasets involved. This
4193 behavior may or may not survive the 0.09 transition.
4194
4195 =back
4196
4197 =head2 alias
4198
4199 =over 4
4200
4201 =item Value: $source_alias
4202
4203 =back
4204
4205 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4206 nested search queries (sub-SELECTs) might need specific aliases set to
4207 reference inner queries.  For example:
4208
4209    my $q = $rs
4210       ->related_resultset('CDs')
4211       ->related_resultset('Tracks')
4212       ->search({
4213          'track.id' => { -ident => 'none_search.id' },
4214       })
4215       ->as_query;
4216
4217    my $ids = $self->search({
4218       -not_exists => $q,
4219    }, {
4220       alias    => 'none_search',
4221       group_by => 'none_search.id',
4222    })->get_column('id')->as_query;
4223
4224    $self->search({ id => { -in => $ids } })
4225
4226 This attribute is directly tied to L</current_source_alias>.
4227
4228 =head2 page
4229
4230 =over 4
4231
4232 =item Value: $page
4233
4234 =back
4235
4236 Makes the resultset paged and specifies the page to retrieve. Effectively
4237 identical to creating a non-pages resultset and then calling ->page($page)
4238 on it.
4239
4240 If L</rows> attribute is not specified it defaults to 10 rows per page.
4241
4242 When you have a paged resultset, L</count> will only return the number
4243 of rows in the page. To get the total, use the L</pager> and call
4244 C<total_entries> on it.
4245
4246 =head2 rows
4247
4248 =over 4
4249
4250 =item Value: $rows
4251
4252 =back
4253
4254 Specifies the maximum number of rows for direct retrieval or the number of
4255 rows per page if the page attribute or method is used.
4256
4257 =head2 offset
4258
4259 =over 4
4260
4261 =item Value: $offset
4262
4263 =back
4264
4265 Specifies the (zero-based) row number for the  first row to be returned, or the
4266 of the first row of the first page if paging is used.
4267
4268 =head2 software_limit
4269
4270 =over 4
4271
4272 =item Value: (0 | 1)
4273
4274 =back
4275
4276 When combined with L</rows> and/or L</offset> the generated SQL will not
4277 include any limit dialect stanzas. Instead the entire result will be selected
4278 as if no limits were specified, and DBIC will perform the limit locally, by
4279 artificially advancing and finishing the resulting L</cursor>.
4280
4281 This is the recommended way of performing resultset limiting when no sane RDBMS
4282 implementation is available (e.g.
4283 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4284 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4285
4286 =head2 group_by
4287
4288 =over 4
4289
4290 =item Value: \@columns
4291
4292 =back
4293
4294 A arrayref of columns to group by. Can include columns of joined tables.
4295
4296   group_by => [qw/ column1 column2 ... /]
4297
4298 =head2 having
4299
4300 =over 4
4301
4302 =item Value: $condition
4303
4304 =back
4305
4306 HAVING is a select statement attribute that is applied between GROUP BY and
4307 ORDER BY. It is applied to the after the grouping calculations have been
4308 done.
4309
4310   having => { 'count_employee' => { '>=', 100 } }
4311
4312 or with an in-place function in which case literal SQL is required:
4313
4314   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4315
4316 =head2 distinct
4317
4318 =over 4
4319
4320 =item Value: (0 | 1)
4321
4322 =back
4323
4324 Set to 1 to group by all columns. If the resultset already has a group_by
4325 attribute, this setting is ignored and an appropriate warning is issued.
4326
4327 =head2 where
4328
4329 =over 4
4330
4331 Adds to the WHERE clause.
4332
4333   # only return rows WHERE deleted IS NULL for all searches
4334   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4335
4336 Can be overridden by passing C<< { where => undef } >> as an attribute
4337 to a resultset.
4338
4339 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4340
4341 =back
4342
4343 =head2 cache
4344
4345 Set to 1 to cache search results. This prevents extra SQL queries if you
4346 revisit rows in your ResultSet:
4347
4348   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4349
4350   while( my $artist = $resultset->next ) {
4351     ... do stuff ...
4352   }
4353
4354   $rs->first; # without cache, this would issue a query
4355
4356 By default, searches are not cached.
4357
4358 For more examples of using these attributes, see
4359 L<DBIx::Class::Manual::Cookbook>.
4360
4361 =head2 for
4362
4363 =over 4
4364
4365 =item Value: ( 'update' | 'shared' | \$scalar )
4366
4367 =back
4368
4369 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4370 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4371 query.
4372
4373 =head1 DBIC BIND VALUES
4374
4375 Because DBIC may need more information to bind values than just the column name
4376 and value itself, it uses a special format for both passing and receiving bind
4377 values.  Each bind value should be composed of an arrayref of
4378 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4379
4380 =over 4
4381
4382 =item dbd_attrs
4383
4384 If present (in any form), this is what is being passed directly to bind_param.
4385 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4386 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4387
4388 If this is specified, all other bind options described below are ignored.
4389
4390 =item sqlt_datatype
4391
4392 If present, this is used to infer the actual bind attribute by passing to
4393 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4394 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4395
4396 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4397 currently drivers are expected to "Do the Right Thing" when given a common
4398 datatype name.  (Not ideal, but that's what we got at this point.)
4399
4400 =item sqlt_size
4401
4402 Currently used to correctly allocate buffers for bind_param_inout().
4403 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4404 or to a sensible value based on the "data_type".
4405
4406 =item dbic_colname
4407
4408 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4409 explicitly specified they are never overriden).  Also used by some weird DBDs,
4410 where the column name should be available at bind_param time (e.g. Oracle).
4411
4412 =back
4413
4414 For backwards compatibility and convenience, the following shortcuts are
4415 supported:
4416
4417   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4418   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4419   [ undef,   $val ] === [ {}, $val ]
4420
4421 =head1 AUTHOR AND CONTRIBUTORS
4422
4423 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4424
4425 =head1 LICENSE
4426
4427 You may distribute this code under the same terms as Perl itself.
4428
4429 =cut
4430
4431 1;