lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799 #      warn "ARRAY: " . Dumper $subquery;
 800       $collapsed = $self->_collapse_query($subquery, $collapsed);
 801     }
 802   }
 803   elsif (ref $query eq 'HASH') {
 804     if (keys %$query and (keys %$query)[0] eq '-and') {
 805       foreach my $subquery (@{$query->{-and}}) {
 806 #        warn "HASH: " . Dumper $subquery;
 807         $collapsed = $self->_collapse_query($subquery, $collapsed);
 808       }
 809     }
 810     else {
 811 #      warn "LEAF: " . Dumper $query;
 812       foreach my $col (keys %$query) {
 813         my $value = $query->{$col};
 814         $collapsed->{$col}{$value}++;
 815       }
 816     }
 817   }
 818
 819   return $collapsed;
 820 }
 821
 822 =head2 get_column
 823
 824 =over 4
 825
 826 =item Arguments: $cond?
 827
 828 =item Return Value: $resultsetcolumn
 829
 830 =back
 831
 832   my $max_length = $rs->get_column('length')->max;
 833
 834 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 835
 836 =cut
 837
 838 sub get_column {
 839   my ($self, $column) = @_;
 840   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 841   return $new;
 842 }
 843
 844 =head2 search_like
 845
 846 =over 4
 847
 848 =item Arguments: $cond, \%attrs?
 849
 850 =item Return Value: $resultset (scalar context), @row_objs (list context)
 851
 852 =back
 853
 854   # WHERE title LIKE '%blue%'
 855   $cd_rs = $rs->search_like({ title => '%blue%'});
 856
 857 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 858 that this is simply a convenience method retained for ex Class::DBI users.
 859 You most likely want to use L</search> with specific operators.
 860
 861 For more information, see L<DBIx::Class::Manual::Cookbook>.
 862
 863 This method is deprecated and will be removed in 0.09. Use L</search()>
 864 instead. An example conversion is:
 865
 866   ->search_like({ foo => 'bar' });
 867
 868   # Becomes
 869
 870   ->search({ foo => { like => 'bar' } });
 871
 872 =cut
 873
 874 sub search_like {
 875   my $class = shift;
 876   carp "search_like() is deprecated and will be removed in 0.09. Use search() instead.";
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 966   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 967   @new = $self->{_attrs}{record_filter}->(@new)
 968     if exists $self->{_attrs}{record_filter};
 969   return @new;
 970 }
 971
 972 sub _collapse_result {
 973   my ($self, $as_proto, $row) = @_;
 974
 975   my @copy = @$row;
 976
 977   # 'foo'         => [ undef, 'foo' ]
 978   # 'foo.bar'     => [ 'foo', 'bar' ]
 979   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 980
 981   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 982
 983   my %collapse = %{$self->{_attrs}{collapse}||{}};
 984
 985   my @pri_index;
 986
 987   # if we're doing collapsing (has_many prefetch) we need to grab records
 988   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 989   # we know we don't have to bother.
 990
 991   # the reason for not using the collapse stuff directly is because if you
 992   # had for e.g. two artists in a row with no cds, the collapse info for
 993   # both would be NULL (undef) so you'd lose the second artist
 994
 995   # store just the index so we can check the array positions from the row
 996   # without having to contruct the full hash
 997
 998   if (keys %collapse) {
 999     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1000     foreach my $i (0 .. $#construct_as) {
1001       next if defined($construct_as[$i][0]); # only self table
1002       if (delete $pri{$construct_as[$i][1]}) {
1003         push(@pri_index, $i);
1004       }
1005       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1006     }
1007   }
1008
1009   # no need to do an if, it'll be empty if @pri_index is empty anyway
1010
1011   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1012
1013   my @const_rows;
1014
1015   do { # no need to check anything at the front, we always want the first row
1016
1017     my %const;
1018
1019     foreach my $this_as (@construct_as) {
1020       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1021     }
1022
1023     push(@const_rows, \%const);
1024
1025   } until ( # no pri_index => no collapse => drop straight out
1026       !@pri_index
1027     or
1028       do { # get another row, stash it, drop out if different PK
1029
1030         @copy = $self->cursor->next;
1031         $self->{stashed_row} = \@copy;
1032
1033         # last thing in do block, counts as true if anything doesn't match
1034
1035         # check xor defined first for NULL vs. NOT NULL then if one is
1036         # defined the other must be so check string equality
1037
1038         grep {
1039           (defined $pri_vals{$_} ^ defined $copy[$_])
1040           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1041         } @pri_index;
1042       }
1043   );
1044
1045   my $alias = $self->{attrs}{alias};
1046   my $info = [];
1047
1048   my %collapse_pos;
1049
1050   my @const_keys;
1051
1052   foreach my $const (@const_rows) {
1053     scalar @const_keys or do {
1054       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1055     };
1056     foreach my $key (@const_keys) {
1057       if (length $key) {
1058         my $target = $info;
1059         my @parts = split(/\./, $key);
1060         my $cur = '';
1061         my $data = $const->{$key};
1062         foreach my $p (@parts) {
1063           $target = $target->[1]->{$p} ||= [];
1064           $cur .= ".${p}";
1065           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1066             # collapsing at this point and on final part
1067             my $pos = $collapse_pos{$cur};
1068             CK: foreach my $ck (@ckey) {
1069               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1070                 $collapse_pos{$cur} = $data;
1071                 delete @collapse_pos{ # clear all positioning for sub-entries
1072                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1073                 };
1074                 push(@$target, []);
1075                 last CK;
1076               }
1077             }
1078           }
1079           if (exists $collapse{$cur}) {
1080             $target = $target->[-1];
1081           }
1082         }
1083         $target->[0] = $data;
1084       } else {
1085         $info->[0] = $const->{$key};
1086       }
1087     }
1088   }
1089
1090   return $info;
1091 }
1092
1093 =head2 result_source
1094
1095 =over 4
1096
1097 =item Arguments: $result_source?
1098
1099 =item Return Value: $result_source
1100
1101 =back
1102
1103 An accessor for the primary ResultSource object from which this ResultSet
1104 is derived.
1105
1106 =head2 result_class
1107
1108 =over 4
1109
1110 =item Arguments: $result_class?
1111
1112 =item Return Value: $result_class
1113
1114 =back
1115
1116 An accessor for the class to use when creating row objects. Defaults to
1117 C<< result_source->result_class >> - which in most cases is the name of the
1118 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1119
1120 =cut
1121
1122 sub result_class {
1123   my ($self, $result_class) = @_;
1124   if ($result_class) {
1125     $self->ensure_class_loaded($result_class);
1126     $self->_result_class($result_class);
1127   }
1128   $self->_result_class;
1129 }
1130
1131 =head2 count
1132
1133 =over 4
1134
1135 =item Arguments: $cond, \%attrs??
1136
1137 =item Return Value: $count
1138
1139 =back
1140
1141 Performs an SQL C<COUNT> with the same query as the resultset was built
1142 with to find the number of elements. If passed arguments, does a search
1143 on the resultset and counts the results of that.
1144
1145 Note: When using C<count> with C<group_by>, L<DBIx::Class> emulates C<GROUP BY>
1146 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
1147 not support C<DISTINCT> with multiple columns. If you are using such a
1148 database, you should only use columns from the main table in your C<group_by>
1149 clause.
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157   my $count = $self->_count;
1158   return 0 unless $count;
1159
1160   # need to take offset from resolved attrs
1161
1162   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1163   $count = $self->{attrs}{rows} if
1164     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1165   $count = 0 if ($count < 0);
1166   return $count;
1167 }
1168
1169 sub _count { # Separated out so pager can get the full count
1170   my $self = shift;
1171   my $select = { count => '*' };
1172
1173   my $attrs = { %{$self->_resolved_attrs} };
1174   if (my $group_by = delete $attrs->{group_by}) {
1175     delete $attrs->{having};
1176     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
1177     # todo: try CONCAT for multi-column pk
1178     my @pk = $self->result_source->primary_columns;
1179     if (@pk == 1) {
1180       my $alias = $attrs->{alias};
1181       foreach my $column (@distinct) {
1182         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
1183           @distinct = ($column);
1184           last;
1185         }
1186       }
1187     }
1188
1189     $select = { count => { distinct => \@distinct } };
1190   }
1191
1192   $attrs->{select} = $select;
1193   $attrs->{as} = [qw/count/];
1194
1195   # offset, order by and page are not needed to count. record_filter is cdbi
1196   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
1197
1198   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1199   my ($count) = $tmp_rs->cursor->next;
1200   return $count;
1201 }
1202
1203 sub _bool {
1204   return 1;
1205 }
1206
1207 =head2 count_literal
1208
1209 =over 4
1210
1211 =item Arguments: $sql_fragment, @bind_values
1212
1213 =item Return Value: $count
1214
1215 =back
1216
1217 Counts the results in a literal query. Equivalent to calling L</search_literal>
1218 with the passed arguments, then L</count>.
1219
1220 =cut
1221
1222 sub count_literal { shift->search_literal(@_)->count; }
1223
1224 =head2 all
1225
1226 =over 4
1227
1228 =item Arguments: none
1229
1230 =item Return Value: @objects
1231
1232 =back
1233
1234 Returns all elements in the resultset. Called implicitly if the resultset
1235 is returned in list context.
1236
1237 =cut
1238
1239 sub all {
1240   my $self = shift;
1241   if(@_) {
1242       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1243   }
1244
1245   return @{ $self->get_cache } if $self->get_cache;
1246
1247   my @obj;
1248
1249   # TODO: don't call resolve here
1250   if (keys %{$self->_resolved_attrs->{collapse}}) {
1251 #  if ($self->{attrs}{prefetch}) {
1252       # Using $self->cursor->all is really just an optimisation.
1253       # If we're collapsing has_many prefetches it probably makes
1254       # very little difference, and this is cleaner than hacking
1255       # _construct_object to survive the approach
1256     my @row = $self->cursor->next;
1257     while (@row) {
1258       push(@obj, $self->_construct_object(@row));
1259       @row = (exists $self->{stashed_row}
1260                ? @{delete $self->{stashed_row}}
1261                : $self->cursor->next);
1262     }
1263   } else {
1264     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1265   }
1266
1267   $self->set_cache(\@obj) if $self->{attrs}{cache};
1268   return @obj;
1269 }
1270
1271 =head2 reset
1272
1273 =over 4
1274
1275 =item Arguments: none
1276
1277 =item Return Value: $self
1278
1279 =back
1280
1281 Resets the resultset's cursor, so you can iterate through the elements again.
1282
1283 =cut
1284
1285 sub reset {
1286   my ($self) = @_;
1287   delete $self->{_attrs} if exists $self->{_attrs};
1288   $self->{all_cache_position} = 0;
1289   $self->cursor->reset;
1290   return $self;
1291 }
1292
1293 =head2 first
1294
1295 =over 4
1296
1297 =item Arguments: none
1298
1299 =item Return Value: $object?
1300
1301 =back
1302
1303 Resets the resultset and returns an object for the first result (if the
1304 resultset returns anything).
1305
1306 =cut
1307
1308 sub first {
1309   return $_[0]->reset->next;
1310 }
1311
1312 # _cond_for_update_delete
1313 #
1314 # update/delete require the condition to be modified to handle
1315 # the differing SQL syntax available.  This transforms the $self->{cond}
1316 # appropriately, returning the new condition.
1317
1318 sub _cond_for_update_delete {
1319   my ($self, $full_cond) = @_;
1320   my $cond = {};
1321
1322   $full_cond ||= $self->{cond};
1323   # No-op. No condition, we're updating/deleting everything
1324   return $cond unless ref $full_cond;
1325
1326   if (ref $full_cond eq 'ARRAY') {
1327     $cond = [
1328       map {
1329         my %hash;
1330         foreach my $key (keys %{$_}) {
1331           $key =~ /([^.]+)$/;
1332           $hash{$1} = $_->{$key};
1333         }
1334         \%hash;
1335       } @{$full_cond}
1336     ];
1337   }
1338   elsif (ref $full_cond eq 'HASH') {
1339     if ((keys %{$full_cond})[0] eq '-and') {
1340       $cond->{-and} = [];
1341
1342       my @cond = @{$full_cond->{-and}};
1343       for (my $i = 0; $i < @cond; $i++) {
1344         my $entry = $cond[$i];
1345
1346         my $hash;
1347         if (ref $entry eq 'HASH') {
1348           $hash = $self->_cond_for_update_delete($entry);
1349         }
1350         else {
1351           $entry =~ /([^.]+)$/;
1352           $hash->{$1} = $cond[++$i];
1353         }
1354
1355         push @{$cond->{-and}}, $hash;
1356       }
1357     }
1358     else {
1359       foreach my $key (keys %{$full_cond}) {
1360         $key =~ /([^.]+)$/;
1361         $cond->{$1} = $full_cond->{$key};
1362       }
1363     }
1364   }
1365   else {
1366     $self->throw_exception(
1367       "Can't update/delete on resultset with condition unless hash or array"
1368     );
1369   }
1370
1371   return $cond;
1372 }
1373
1374
1375 =head2 update
1376
1377 =over 4
1378
1379 =item Arguments: \%values
1380
1381 =item Return Value: $storage_rv
1382
1383 =back
1384
1385 Sets the specified columns in the resultset to the supplied values in a
1386 single query. Return value will be true if the update succeeded or false
1387 if no records were updated; exact type of success value is storage-dependent.
1388
1389 =cut
1390
1391 sub update {
1392   my ($self, $values) = @_;
1393   $self->throw_exception("Values for update must be a hash")
1394     unless ref $values eq 'HASH';
1395
1396   carp(   'WARNING! Currently $rs->update() does not generate proper SQL'
1397         . ' on joined resultsets, and may affect rows well outside of the'
1398         . ' contents of $rs. Use at your own risk' )
1399     if ( $self->{attrs}{seen_join} );
1400
1401   my $cond = $self->_cond_for_update_delete;
1402
1403   return $self->result_source->storage->update(
1404     $self->result_source, $values, $cond
1405   );
1406 }
1407
1408 =head2 update_all
1409
1410 =over 4
1411
1412 =item Arguments: \%values
1413
1414 =item Return Value: 1
1415
1416 =back
1417
1418 Fetches all objects and updates them one at a time. Note that C<update_all>
1419 will run DBIC cascade triggers, while L</update> will not.
1420
1421 =cut
1422
1423 sub update_all {
1424   my ($self, $values) = @_;
1425   $self->throw_exception("Values for update must be a hash")
1426     unless ref $values eq 'HASH';
1427   foreach my $obj ($self->all) {
1428     $obj->set_columns($values)->update;
1429   }
1430   return 1;
1431 }
1432
1433 =head2 delete
1434
1435 =over 4
1436
1437 =item Arguments: none
1438
1439 =item Return Value: 1
1440
1441 =back
1442
1443 Deletes the contents of the resultset from its result source. Note that this
1444 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1445 to run. See also L<DBIx::Class::Row/delete>.
1446
1447 delete may not generate correct SQL for a query with joins or a resultset
1448 chained from a related resultset.  In this case it will generate a warning:-
1449
1450   WARNING! Currently $rs->delete() does not generate proper SQL on
1451   joined resultsets, and may delete rows well outside of the contents
1452   of $rs. Use at your own risk
1453
1454 In these cases you may find that delete_all is more appropriate, or you
1455 need to respecify your query in a way that can be expressed without a join.
1456
1457 =cut
1458
1459 sub delete {
1460   my ($self) = @_;
1461   $self->throw_exception("Delete should not be passed any arguments")
1462     if $_[1];
1463   carp(   'WARNING! Currently $rs->delete() does not generate proper SQL'
1464         . ' on joined resultsets, and may delete rows well outside of the'
1465         . ' contents of $rs. Use at your own risk' )
1466     if ( $self->{attrs}{seen_join} );
1467   my $cond = $self->_cond_for_update_delete;
1468
1469   $self->result_source->storage->delete($self->result_source, $cond);
1470   return 1;
1471 }
1472
1473 =head2 delete_all
1474
1475 =over 4
1476
1477 =item Arguments: none
1478
1479 =item Return Value: 1
1480
1481 =back
1482
1483 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1484 will run DBIC cascade triggers, while L</delete> will not.
1485
1486 =cut
1487
1488 sub delete_all {
1489   my ($self) = @_;
1490   $_->delete for $self->all;
1491   return 1;
1492 }
1493
1494 =head2 populate
1495
1496 =over 4
1497
1498 =item Arguments: \@data;
1499
1500 =back
1501
1502 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1503 For the arrayref of hashrefs style each hashref should be a structure suitable
1504 forsubmitting to a $resultset->create(...) method.
1505
1506 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1507 to insert the data, as this is a faster method.
1508
1509 Otherwise, each set of data is inserted into the database using
1510 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1511 objects is returned.
1512
1513 Example:  Assuming an Artist Class that has many CDs Classes relating:
1514
1515   my $Artist_rs = $schema->resultset("Artist");
1516
1517   ## Void Context Example
1518   $Artist_rs->populate([
1519      { artistid => 4, name => 'Manufactured Crap', cds => [
1520         { title => 'My First CD', year => 2006 },
1521         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1522       ],
1523      },
1524      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1525         { title => 'My parents sold me to a record company' ,year => 2005 },
1526         { title => 'Why Am I So Ugly?', year => 2006 },
1527         { title => 'I Got Surgery and am now Popular', year => 2007 }
1528       ],
1529      },
1530   ]);
1531
1532   ## Array Context Example
1533   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1534     { name => "Artist One"},
1535     { name => "Artist Two"},
1536     { name => "Artist Three", cds=> [
1537     { title => "First CD", year => 2007},
1538     { title => "Second CD", year => 2008},
1539   ]}
1540   ]);
1541
1542   print $ArtistOne->name; ## response is 'Artist One'
1543   print $ArtistThree->cds->count ## reponse is '2'
1544
1545 For the arrayref of arrayrefs style,  the first element should be a list of the
1546 fieldsnames to which the remaining elements are rows being inserted.  For
1547 example:
1548
1549   $Arstist_rs->populate([
1550     [qw/artistid name/],
1551     [100, 'A Formally Unknown Singer'],
1552     [101, 'A singer that jumped the shark two albums ago'],
1553     [102, 'An actually cool singer.'],
1554   ]);
1555
1556 Please note an important effect on your data when choosing between void and
1557 wantarray context. Since void context goes straight to C<insert_bulk> in
1558 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1559 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1560 create primary keys for you, you will find that your PKs are empty.  In this
1561 case you will have to use the wantarray context in order to create those
1562 values.
1563
1564 =cut
1565
1566 sub populate {
1567   my $self = shift @_;
1568   my $data = ref $_[0][0] eq 'HASH'
1569     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1570     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1571
1572   if(defined wantarray) {
1573     my @created;
1574     foreach my $item (@$data) {
1575       push(@created, $self->create($item));
1576     }
1577     return @created;
1578   } else {
1579     my ($first, @rest) = @$data;
1580
1581     my @names = grep {!ref $first->{$_}} keys %$first;
1582     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1583     my @pks = $self->result_source->primary_columns;
1584
1585     ## do the belongs_to relationships
1586     foreach my $index (0..$#$data) {
1587       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1588         my @ret = $self->populate($data);
1589         return;
1590       }
1591
1592       foreach my $rel (@rels) {
1593         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1594         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1595         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1596         my $related = $result->result_source->resolve_condition(
1597           $result->result_source->relationship_info($reverse)->{cond},
1598           $self,
1599           $result,
1600         );
1601
1602         delete $data->[$index]->{$rel};
1603         $data->[$index] = {%{$data->[$index]}, %$related};
1604
1605         push @names, keys %$related if $index == 0;
1606       }
1607     }
1608
1609     ## do bulk insert on current row
1610     my @values = map { [ @$_{@names} ] } @$data;
1611
1612     $self->result_source->storage->insert_bulk(
1613       $self->result_source,
1614       \@names,
1615       \@values,
1616     );
1617
1618     ## do the has_many relationships
1619     foreach my $item (@$data) {
1620
1621       foreach my $rel (@rels) {
1622         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1623
1624         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1625      || $self->throw_exception('Cannot find the relating object.');
1626
1627         my $child = $parent->$rel;
1628
1629         my $related = $child->result_source->resolve_condition(
1630           $parent->result_source->relationship_info($rel)->{cond},
1631           $child,
1632           $parent,
1633         );
1634
1635         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1636         my @populate = map { {%$_, %$related} } @rows_to_add;
1637
1638         $child->populate( \@populate );
1639       }
1640     }
1641   }
1642 }
1643
1644 =head2 _normalize_populate_args ($args)
1645
1646 Private method used by L</populate> to normalize its incoming arguments.  Factored
1647 out in case you want to subclass and accept new argument structures to the
1648 L</populate> method.
1649
1650 =cut
1651
1652 sub _normalize_populate_args {
1653   my ($self, $data) = @_;
1654   my @names = @{shift(@$data)};
1655   my @results_to_create;
1656   foreach my $datum (@$data) {
1657     my %result_to_create;
1658     foreach my $index (0..$#names) {
1659       $result_to_create{$names[$index]} = $$datum[$index];
1660     }
1661     push @results_to_create, \%result_to_create;
1662   }
1663   return \@results_to_create;
1664 }
1665
1666 =head2 pager
1667
1668 =over 4
1669
1670 =item Arguments: none
1671
1672 =item Return Value: $pager
1673
1674 =back
1675
1676 Return Value a L<Data::Page> object for the current resultset. Only makes
1677 sense for queries with a C<page> attribute.
1678
1679 To get the full count of entries for a paged resultset, call
1680 C<total_entries> on the L<Data::Page> object.
1681
1682 =cut
1683
1684 sub pager {
1685   my ($self) = @_;
1686   my $attrs = $self->{attrs};
1687   $self->throw_exception("Can't create pager for non-paged rs")
1688     unless $self->{attrs}{page};
1689   $attrs->{rows} ||= 10;
1690   return $self->{pager} ||= Data::Page->new(
1691     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1692 }
1693
1694 =head2 page
1695
1696 =over 4
1697
1698 =item Arguments: $page_number
1699
1700 =item Return Value: $rs
1701
1702 =back
1703
1704 Returns a resultset for the $page_number page of the resultset on which page
1705 is called, where each page contains a number of rows equal to the 'rows'
1706 attribute set on the resultset (10 by default).
1707
1708 =cut
1709
1710 sub page {
1711   my ($self, $page) = @_;
1712   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1713 }
1714
1715 =head2 new_result
1716
1717 =over 4
1718
1719 =item Arguments: \%vals
1720
1721 =item Return Value: $rowobject
1722
1723 =back
1724
1725 Creates a new row object in the resultset's result class and returns
1726 it. The row is not inserted into the database at this point, call
1727 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1728 will tell you whether the row object has been inserted or not.
1729
1730 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1731
1732 =cut
1733
1734 sub new_result {
1735   my ($self, $values) = @_;
1736   $self->throw_exception( "new_result needs a hash" )
1737     unless (ref $values eq 'HASH');
1738
1739   my %new;
1740   my $alias = $self->{attrs}{alias};
1741
1742   if (
1743     defined $self->{cond}
1744     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1745   ) {
1746     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1747     $new{-from_resultset} = [ keys %new ] if keys %new;
1748   } else {
1749     $self->throw_exception(
1750       "Can't abstract implicit construct, condition not a hash"
1751     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1752
1753     my $collapsed_cond = (
1754       $self->{cond}
1755         ? $self->_collapse_cond($self->{cond})
1756         : {}
1757     );
1758
1759     # precendence must be given to passed values over values inherited from
1760     # the cond, so the order here is important.
1761     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1762     while( my($col,$value) = each %implied ){
1763       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1764         $new{$col} = $value->{'='};
1765         next;
1766       }
1767       $new{$col} = $value if $self->_is_deterministic_value($value);
1768     }
1769   }
1770
1771   %new = (
1772     %new,
1773     %{ $self->_remove_alias($values, $alias) },
1774     -source_handle => $self->_source_handle,
1775     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1776   );
1777
1778   return $self->result_class->new(\%new);
1779 }
1780
1781 # _is_deterministic_value
1782 #
1783 # Make an effor to strip non-deterministic values from the condition,
1784 # to make sure new_result chokes less
1785
1786 sub _is_deterministic_value {
1787   my $self = shift;
1788   my $value = shift;
1789   my $ref_type = ref $value;
1790   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1791   return 1 if Scalar::Util::blessed($value);
1792   return 0;
1793 }
1794
1795 # _collapse_cond
1796 #
1797 # Recursively collapse the condition.
1798
1799 sub _collapse_cond {
1800   my ($self, $cond, $collapsed) = @_;
1801
1802   $collapsed ||= {};
1803
1804   if (ref $cond eq 'ARRAY') {
1805     foreach my $subcond (@$cond) {
1806       next unless ref $subcond;  # -or
1807 #      warn "ARRAY: " . Dumper $subcond;
1808       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1809     }
1810   }
1811   elsif (ref $cond eq 'HASH') {
1812     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1813       foreach my $subcond (@{$cond->{-and}}) {
1814 #        warn "HASH: " . Dumper $subcond;
1815         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1816       }
1817     }
1818     else {
1819 #      warn "LEAF: " . Dumper $cond;
1820       foreach my $col (keys %$cond) {
1821         my $value = $cond->{$col};
1822         $collapsed->{$col} = $value;
1823       }
1824     }
1825   }
1826
1827   return $collapsed;
1828 }
1829
1830 # _remove_alias
1831 #
1832 # Remove the specified alias from the specified query hash. A copy is made so
1833 # the original query is not modified.
1834
1835 sub _remove_alias {
1836   my ($self, $query, $alias) = @_;
1837
1838   my %orig = %{ $query || {} };
1839   my %unaliased;
1840
1841   foreach my $key (keys %orig) {
1842     if ($key !~ /\./) {
1843       $unaliased{$key} = $orig{$key};
1844       next;
1845     }
1846     $unaliased{$1} = $orig{$key}
1847       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1848   }
1849
1850   return \%unaliased;
1851 }
1852
1853 =head2 as_query (EXPERIMENTAL)
1854
1855 =over 4
1856
1857 =item Arguments: none
1858
1859 =item Return Value: \[ $sql, @bind ]
1860
1861 =back
1862
1863 Returns the SQL query and bind vars associated with the invocant.
1864
1865 This is generally used as the RHS for a subquery.
1866
1867 B<NOTE>: This feature is still experimental.
1868
1869 =cut
1870
1871 sub as_query { return shift->cursor->as_query(@_) }
1872
1873 =head2 find_or_new
1874
1875 =over 4
1876
1877 =item Arguments: \%vals, \%attrs?
1878
1879 =item Return Value: $rowobject
1880
1881 =back
1882
1883   my $artist = $schema->resultset('Artist')->find_or_new(
1884     { artist => 'fred' }, { key => 'artists' });
1885
1886   $cd->cd_to_producer->find_or_new({ producer => $producer },
1887                                    { key => 'primary });
1888
1889 Find an existing record from this resultset, based on its primary
1890 key, or a unique constraint. If none exists, instantiate a new result
1891 object and return it. The object will not be saved into your storage
1892 until you call L<DBIx::Class::Row/insert> on it.
1893
1894 You most likely want this method when looking for existing rows using
1895 a unique constraint that is not the primary key, or looking for
1896 related rows.
1897
1898 If you want objects to be saved immediately, use L</find_or_create> instead.
1899
1900 B<Note>: C<find_or_new> is probably not what you want when creating a
1901 new row in a table that uses primary keys supplied by the
1902 database. Passing in a primary key column with a value of I<undef>
1903 will cause L</find> to attempt to search for a row with a value of
1904 I<NULL>.
1905
1906 =cut
1907
1908 sub find_or_new {
1909   my $self     = shift;
1910   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1911   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1912   my $exists   = $self->find($hash, $attrs);
1913   return defined $exists ? $exists : $self->new_result($hash);
1914 }
1915
1916 =head2 create
1917
1918 =over 4
1919
1920 =item Arguments: \%vals
1921
1922 =item Return Value: a L<DBIx::Class::Row> $object
1923
1924 =back
1925
1926 Attempt to create a single new row or a row with multiple related rows
1927 in the table represented by the resultset (and related tables). This
1928 will not check for duplicate rows before inserting, use
1929 L</find_or_create> to do that.
1930
1931 To create one row for this resultset, pass a hashref of key/value
1932 pairs representing the columns of the table and the values you wish to
1933 store. If the appropriate relationships are set up, foreign key fields
1934 can also be passed an object representing the foreign row, and the
1935 value will be set to its primary key.
1936
1937 To create related objects, pass a hashref for the value if the related
1938 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1939 and use the name of the relationship as the key. (NOT the name of the field,
1940 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1941 of hashrefs containing the data for each of the rows to create in the foreign
1942 tables, again using the relationship name as the key.
1943
1944 Instead of hashrefs of plain related data (key/value pairs), you may
1945 also pass new or inserted objects. New objects (not inserted yet, see
1946 L</new>), will be inserted into their appropriate tables.
1947
1948 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1949
1950 Example of creating a new row.
1951
1952   $person_rs->create({
1953     name=>"Some Person",
1954     email=>"somebody@someplace.com"
1955   });
1956
1957 Example of creating a new row and also creating rows in a related C<has_many>
1958 or C<has_one> resultset.  Note Arrayref.
1959
1960   $artist_rs->create(
1961      { artistid => 4, name => 'Manufactured Crap', cds => [
1962         { title => 'My First CD', year => 2006 },
1963         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1964       ],
1965      },
1966   );
1967
1968 Example of creating a new row and also creating a row in a related
1969 C<belongs_to>resultset. Note Hashref.
1970
1971   $cd_rs->create({
1972     title=>"Music for Silly Walks",
1973     year=>2000,
1974     artist => {
1975       name=>"Silly Musician",
1976     }
1977   });
1978
1979 =cut
1980
1981 sub create {
1982   my ($self, $attrs) = @_;
1983   $self->throw_exception( "create needs a hashref" )
1984     unless ref $attrs eq 'HASH';
1985   return $self->new_result($attrs)->insert;
1986 }
1987
1988 =head2 find_or_create
1989
1990 =over 4
1991
1992 =item Arguments: \%vals, \%attrs?
1993
1994 =item Return Value: $rowobject
1995
1996 =back
1997
1998   $cd->cd_to_producer->find_or_create({ producer => $producer },
1999                                       { key => 'primary });
2000
2001 Tries to find a record based on its primary key or unique constraints; if none
2002 is found, creates one and returns that instead.
2003
2004   my $cd = $schema->resultset('CD')->find_or_create({
2005     cdid   => 5,
2006     artist => 'Massive Attack',
2007     title  => 'Mezzanine',
2008     year   => 2005,
2009   });
2010
2011 Also takes an optional C<key> attribute, to search by a specific key or unique
2012 constraint. For example:
2013
2014   my $cd = $schema->resultset('CD')->find_or_create(
2015     {
2016       artist => 'Massive Attack',
2017       title  => 'Mezzanine',
2018     },
2019     { key => 'cd_artist_title' }
2020   );
2021
2022 B<Note>: Because find_or_create() reads from the database and then
2023 possibly inserts based on the result, this method is subject to a race
2024 condition. Another process could create a record in the table after
2025 the find has completed and before the create has started. To avoid
2026 this problem, use find_or_create() inside a transaction.
2027
2028 B<Note>: C<find_or_create> is probably not what you want when creating
2029 a new row in a table that uses primary keys supplied by the
2030 database. Passing in a primary key column with a value of I<undef>
2031 will cause L</find> to attempt to search for a row with a value of
2032 I<NULL>.
2033
2034 See also L</find> and L</update_or_create>. For information on how to declare
2035 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2036
2037 =cut
2038
2039 sub find_or_create {
2040   my $self     = shift;
2041   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2042   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2043   my $exists   = $self->find($hash, $attrs);
2044   return defined $exists ? $exists : $self->create($hash);
2045 }
2046
2047 =head2 update_or_create
2048
2049 =over 4
2050
2051 =item Arguments: \%col_values, { key => $unique_constraint }?
2052
2053 =item Return Value: $rowobject
2054
2055 =back
2056
2057   $resultset->update_or_create({ col => $val, ... });
2058
2059 First, searches for an existing row matching one of the unique constraints
2060 (including the primary key) on the source of this resultset. If a row is
2061 found, updates it with the other given column values. Otherwise, creates a new
2062 row.
2063
2064 Takes an optional C<key> attribute to search on a specific unique constraint.
2065 For example:
2066
2067   # In your application
2068   my $cd = $schema->resultset('CD')->update_or_create(
2069     {
2070       artist => 'Massive Attack',
2071       title  => 'Mezzanine',
2072       year   => 1998,
2073     },
2074     { key => 'cd_artist_title' }
2075   );
2076
2077   $cd->cd_to_producer->update_or_create({
2078     producer => $producer,
2079     name => 'harry',
2080   }, {
2081     key => 'primary,
2082   });
2083
2084
2085 If no C<key> is specified, it searches on all unique constraints defined on the
2086 source, including the primary key.
2087
2088 If the C<key> is specified as C<primary>, it searches only on the primary key.
2089
2090 See also L</find> and L</find_or_create>. For information on how to declare
2091 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2092
2093 B<Note>: C<update_or_create> is probably not what you want when
2094 looking for a row in a table that uses primary keys supplied by the
2095 database, unless you actually have a key value. Passing in a primary
2096 key column with a value of I<undef> will cause L</find> to attempt to
2097 search for a row with a value of I<NULL>.
2098
2099 =cut
2100
2101 sub update_or_create {
2102   my $self = shift;
2103   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2104   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2105
2106   my $row = $self->find($cond, $attrs);
2107   if (defined $row) {
2108     $row->update($cond);
2109     return $row;
2110   }
2111
2112   return $self->create($cond);
2113 }
2114
2115 =head2 get_cache
2116
2117 =over 4
2118
2119 =item Arguments: none
2120
2121 =item Return Value: \@cache_objects?
2122
2123 =back
2124
2125 Gets the contents of the cache for the resultset, if the cache is set.
2126
2127 The cache is populated either by using the L</prefetch> attribute to
2128 L</search> or by calling L</set_cache>.
2129
2130 =cut
2131
2132 sub get_cache {
2133   shift->{all_cache};
2134 }
2135
2136 =head2 set_cache
2137
2138 =over 4
2139
2140 =item Arguments: \@cache_objects
2141
2142 =item Return Value: \@cache_objects
2143
2144 =back
2145
2146 Sets the contents of the cache for the resultset. Expects an arrayref
2147 of objects of the same class as those produced by the resultset. Note that
2148 if the cache is set the resultset will return the cached objects rather
2149 than re-querying the database even if the cache attr is not set.
2150
2151 The contents of the cache can also be populated by using the
2152 L</prefetch> attribute to L</search>.
2153
2154 =cut
2155
2156 sub set_cache {
2157   my ( $self, $data ) = @_;
2158   $self->throw_exception("set_cache requires an arrayref")
2159       if defined($data) && (ref $data ne 'ARRAY');
2160   $self->{all_cache} = $data;
2161 }
2162
2163 =head2 clear_cache
2164
2165 =over 4
2166
2167 =item Arguments: none
2168
2169 =item Return Value: []
2170
2171 =back
2172
2173 Clears the cache for the resultset.
2174
2175 =cut
2176
2177 sub clear_cache {
2178   shift->set_cache(undef);
2179 }
2180
2181 =head2 related_resultset
2182
2183 =over 4
2184
2185 =item Arguments: $relationship_name
2186
2187 =item Return Value: $resultset
2188
2189 =back
2190
2191 Returns a related resultset for the supplied relationship name.
2192
2193   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2194
2195 =cut
2196
2197 sub related_resultset {
2198   my ($self, $rel) = @_;
2199
2200   $self->{related_resultsets} ||= {};
2201   return $self->{related_resultsets}{$rel} ||= do {
2202     my $rel_obj = $self->result_source->relationship_info($rel);
2203
2204     $self->throw_exception(
2205       "search_related: result source '" . $self->result_source->source_name .
2206         "' has no such relationship $rel")
2207       unless $rel_obj;
2208
2209     my ($from,$seen) = $self->_resolve_from($rel);
2210
2211     my $join_count = $seen->{$rel};
2212     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2213
2214     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2215     my %attrs = %{$self->{attrs}||{}};
2216     delete @attrs{qw(result_class alias)};
2217
2218     my $new_cache;
2219
2220     if (my $cache = $self->get_cache) {
2221       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2222         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2223                         @$cache ];
2224       }
2225     }
2226
2227     my $rel_source = $self->result_source->related_source($rel);
2228
2229     my $new = do {
2230
2231       # The reason we do this now instead of passing the alias to the
2232       # search_rs below is that if you wrap/overload resultset on the
2233       # source you need to know what alias it's -going- to have for things
2234       # to work sanely (e.g. RestrictWithObject wants to be able to add
2235       # extra query restrictions, and these may need to be $alias.)
2236
2237       my $attrs = $rel_source->resultset_attributes;
2238       local $attrs->{alias} = $alias;
2239
2240       $rel_source->resultset
2241                  ->search_rs(
2242                      undef, {
2243                        %attrs,
2244                        join => undef,
2245                        prefetch => undef,
2246                        select => undef,
2247                        as => undef,
2248                        where => $self->{cond},
2249                        seen_join => $seen,
2250                        from => $from,
2251                    });
2252     };
2253     $new->set_cache($new_cache) if $new_cache;
2254     $new;
2255   };
2256 }
2257
2258 =head2 current_source_alias
2259
2260 =over 4
2261
2262 =item Arguments: none
2263
2264 =item Return Value: $source_alias
2265
2266 =back
2267
2268 Returns the current table alias for the result source this resultset is built
2269 on, that will be used in the SQL query. Usually it is C<me>.
2270
2271 Currently the source alias that refers to the result set returned by a
2272 L</search>/L</find> family method depends on how you got to the resultset: it's
2273 C<me> by default, but eg. L</search_related> aliases it to the related result
2274 source name (and keeps C<me> referring to the original result set). The long
2275 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2276 (and make this method unnecessary).
2277
2278 Thus it's currently necessary to use this method in predefined queries (see
2279 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2280 source alias of the current result set:
2281
2282   # in a result set class
2283   sub modified_by {
2284     my ($self, $user) = @_;
2285
2286     my $me = $self->current_source_alias;
2287
2288     return $self->search(
2289       "$me.modified" => $user->id,
2290     );
2291   }
2292
2293 =cut
2294
2295 sub current_source_alias {
2296   my ($self) = @_;
2297
2298   return ($self->{attrs} || {})->{alias} || 'me';
2299 }
2300
2301 sub _resolve_from {
2302   my ($self, $extra_join) = @_;
2303   my $source = $self->result_source;
2304   my $attrs = $self->{attrs};
2305
2306   my $from = $attrs->{from}
2307     || [ { $attrs->{alias} => $source->from } ];
2308
2309   my $seen = { %{$attrs->{seen_join}||{}} };
2310
2311   my $join = ($attrs->{join}
2312                ? [ $attrs->{join}, $extra_join ]
2313                : $extra_join);
2314
2315   # we need to take the prefetch the attrs into account before we
2316   # ->resolve_join as otherwise they get lost - captainL
2317   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2318
2319   $from = [
2320     @$from,
2321     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2322   ];
2323
2324   return ($from,$seen);
2325 }
2326
2327 sub _resolved_attrs {
2328   my $self = shift;
2329   return $self->{_attrs} if $self->{_attrs};
2330
2331   my $attrs  = { %{ $self->{attrs} || {} } };
2332   my $source = $self->result_source;
2333   my $alias  = $attrs->{alias};
2334
2335   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2336   my @colbits;
2337
2338   # build columns (as long as select isn't set) into a set of as/select hashes
2339   unless ( $attrs->{select} ) {
2340       @colbits = map {
2341           ( ref($_) eq 'HASH' ) ? $_
2342             : {
2343               (
2344                   /^\Q${alias}.\E(.+)$/ ? $1
2345                   : $_
2346                 ) => ( /\./ ? $_ : "${alias}.$_" )
2347             }
2348       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2349   }
2350   # add the additional columns on
2351   foreach ( 'include_columns', '+columns' ) {
2352       push @colbits, map {
2353           ( ref($_) eq 'HASH' )
2354             ? $_
2355             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2356       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2357   }
2358
2359   # start with initial select items
2360   if ( $attrs->{select} ) {
2361     $attrs->{select} =
2362         ( ref $attrs->{select} eq 'ARRAY' )
2363       ? [ @{ $attrs->{select} } ]
2364       : [ $attrs->{select} ];
2365     $attrs->{as} = (
2366       $attrs->{as}
2367       ? (
2368         ref $attrs->{as} eq 'ARRAY'
2369         ? [ @{ $attrs->{as} } ]
2370         : [ $attrs->{as} ]
2371         )
2372       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2373     );
2374   }
2375   else {
2376
2377     # otherwise we intialise select & as to empty
2378     $attrs->{select} = [];
2379     $attrs->{as}     = [];
2380   }
2381
2382   # now add colbits to select/as
2383   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2384   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2385
2386   my $adds;
2387   if ( $adds = delete $attrs->{'+select'} ) {
2388     $adds = [$adds] unless ref $adds eq 'ARRAY';
2389     push(
2390       @{ $attrs->{select} },
2391       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2392     );
2393   }
2394   if ( $adds = delete $attrs->{'+as'} ) {
2395     $adds = [$adds] unless ref $adds eq 'ARRAY';
2396     push( @{ $attrs->{as} }, @$adds );
2397   }
2398
2399   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2400
2401   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2402     my $join = delete $attrs->{join} || {};
2403
2404     if ( defined $attrs->{prefetch} ) {
2405       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2406
2407     }
2408
2409     $attrs->{from} =    # have to copy here to avoid corrupting the original
2410       [
2411       @{ $attrs->{from} },
2412       $source->resolve_join(
2413         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2414       )
2415       ];
2416
2417   }
2418
2419   $attrs->{group_by} ||= $attrs->{select}
2420     if delete $attrs->{distinct};
2421   if ( $attrs->{order_by} ) {
2422     $attrs->{order_by} = (
2423       ref( $attrs->{order_by} ) eq 'ARRAY'
2424       ? [ @{ $attrs->{order_by} } ]
2425       : [ $attrs->{order_by} ]
2426     );
2427   }
2428   else {
2429     $attrs->{order_by} = [];
2430   }
2431
2432   my $collapse = $attrs->{collapse} || {};
2433   if ( my $prefetch = delete $attrs->{prefetch} ) {
2434     $prefetch = $self->_merge_attr( {}, $prefetch );
2435     my @pre_order;
2436     my $seen = { %{ $attrs->{seen_join} || {} } };
2437     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2438
2439       # bring joins back to level of current class
2440       my @prefetch =
2441         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2442       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2443       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2444     }
2445     push( @{ $attrs->{order_by} }, @pre_order );
2446   }
2447   $attrs->{collapse} = $collapse;
2448
2449   if ( $attrs->{page} ) {
2450     $attrs->{offset} ||= 0;
2451     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2452   }
2453
2454   return $self->{_attrs} = $attrs;
2455 }
2456
2457 sub _rollout_attr {
2458   my ($self, $attr) = @_;
2459
2460   if (ref $attr eq 'HASH') {
2461     return $self->_rollout_hash($attr);
2462   } elsif (ref $attr eq 'ARRAY') {
2463     return $self->_rollout_array($attr);
2464   } else {
2465     return [$attr];
2466   }
2467 }
2468
2469 sub _rollout_array {
2470   my ($self, $attr) = @_;
2471
2472   my @rolled_array;
2473   foreach my $element (@{$attr}) {
2474     if (ref $element eq 'HASH') {
2475       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2476     } elsif (ref $element eq 'ARRAY') {
2477       #  XXX - should probably recurse here
2478       push( @rolled_array, @{$self->_rollout_array($element)} );
2479     } else {
2480       push( @rolled_array, $element );
2481     }
2482   }
2483   return \@rolled_array;
2484 }
2485
2486 sub _rollout_hash {
2487   my ($self, $attr) = @_;
2488
2489   my @rolled_array;
2490   foreach my $key (keys %{$attr}) {
2491     push( @rolled_array, { $key => $attr->{$key} } );
2492   }
2493   return \@rolled_array;
2494 }
2495
2496 sub _calculate_score {
2497   my ($self, $a, $b) = @_;
2498
2499   if (ref $b eq 'HASH') {
2500     my ($b_key) = keys %{$b};
2501     if (ref $a eq 'HASH') {
2502       my ($a_key) = keys %{$a};
2503       if ($a_key eq $b_key) {
2504         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2505       } else {
2506         return 0;
2507       }
2508     } else {
2509       return ($a eq $b_key) ? 1 : 0;
2510     }
2511   } else {
2512     if (ref $a eq 'HASH') {
2513       my ($a_key) = keys %{$a};
2514       return ($b eq $a_key) ? 1 : 0;
2515     } else {
2516       return ($b eq $a) ? 1 : 0;
2517     }
2518   }
2519 }
2520
2521 sub _merge_attr {
2522   my ($self, $orig, $import) = @_;
2523
2524   return $import unless defined($orig);
2525   return $orig unless defined($import);
2526
2527   $orig = $self->_rollout_attr($orig);
2528   $import = $self->_rollout_attr($import);
2529
2530   my $seen_keys;
2531   foreach my $import_element ( @{$import} ) {
2532     # find best candidate from $orig to merge $b_element into
2533     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2534     foreach my $orig_element ( @{$orig} ) {
2535       my $score = $self->_calculate_score( $orig_element, $import_element );
2536       if ($score > $best_candidate->{score}) {
2537         $best_candidate->{position} = $position;
2538         $best_candidate->{score} = $score;
2539       }
2540       $position++;
2541     }
2542     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2543
2544     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2545       push( @{$orig}, $import_element );
2546     } else {
2547       my $orig_best = $orig->[$best_candidate->{position}];
2548       # merge orig_best and b_element together and replace original with merged
2549       if (ref $orig_best ne 'HASH') {
2550         $orig->[$best_candidate->{position}] = $import_element;
2551       } elsif (ref $import_element eq 'HASH') {
2552         my ($key) = keys %{$orig_best};
2553         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2554       }
2555     }
2556     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2557   }
2558
2559   return $orig;
2560 }
2561
2562 sub result_source {
2563     my $self = shift;
2564
2565     if (@_) {
2566         $self->_source_handle($_[0]->handle);
2567     } else {
2568         $self->_source_handle->resolve;
2569     }
2570 }
2571
2572 =head2 throw_exception
2573
2574 See L<DBIx::Class::Schema/throw_exception> for details.
2575
2576 =cut
2577
2578 sub throw_exception {
2579   my $self=shift;
2580   if (ref $self && $self->_source_handle->schema) {
2581     $self->_source_handle->schema->throw_exception(@_)
2582   } else {
2583     croak(@_);
2584   }
2585
2586 }
2587
2588 # XXX: FIXME: Attributes docs need clearing up
2589
2590 =head1 ATTRIBUTES
2591
2592 Attributes are used to refine a ResultSet in various ways when
2593 searching for data. They can be passed to any method which takes an
2594 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2595 L</count>.
2596
2597 These are in no particular order:
2598
2599 =head2 order_by
2600
2601 =over 4
2602
2603 =item Value: ( $order_by | \@order_by | \%order_by )
2604
2605 =back
2606
2607 Which column(s) to order the results by. If a single column name, or
2608 an arrayref of names is supplied, the argument is passed through
2609 directly to SQL. The hashref syntax allows for connection-agnostic
2610 specification of ordering direction:
2611
2612  For descending order:
2613
2614   order_by => { -desc => [qw/col1 col2 col3/] }
2615
2616  For explicit ascending order:
2617
2618   order_by => { -asc => 'col' }
2619
2620 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2621 supported, although you are strongly encouraged to use the hashref
2622 syntax as outlined above.
2623
2624 =head2 columns
2625
2626 =over 4
2627
2628 =item Value: \@columns
2629
2630 =back
2631
2632 Shortcut to request a particular set of columns to be retrieved. Each
2633 column spec may be a string (a table column name), or a hash (in which
2634 case the key is the C<as> value, and the value is used as the C<select>
2635 expression). Adds C<me.> onto the start of any column without a C<.> in
2636 it and sets C<select> from that, then auto-populates C<as> from
2637 C<select> as normal. (You may also use the C<cols> attribute, as in
2638 earlier versions of DBIC.)
2639
2640 =head2 +columns
2641
2642 =over 4
2643
2644 =item Value: \@columns
2645
2646 =back
2647
2648 Indicates additional columns to be selected from storage. Works the same
2649 as L</columns> but adds columns to the selection. (You may also use the
2650 C<include_columns> attribute, as in earlier versions of DBIC). For
2651 example:-
2652
2653   $schema->resultset('CD')->search(undef, {
2654     '+columns' => ['artist.name'],
2655     join => ['artist']
2656   });
2657
2658 would return all CDs and include a 'name' column to the information
2659 passed to object inflation. Note that the 'artist' is the name of the
2660 column (or relationship) accessor, and 'name' is the name of the column
2661 accessor in the related table.
2662
2663 =head2 include_columns
2664
2665 =over 4
2666
2667 =item Value: \@columns
2668
2669 =back
2670
2671 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2672
2673 =head2 select
2674
2675 =over 4
2676
2677 =item Value: \@select_columns
2678
2679 =back
2680
2681 Indicates which columns should be selected from the storage. You can use
2682 column names, or in the case of RDBMS back ends, function or stored procedure
2683 names:
2684
2685   $rs = $schema->resultset('Employee')->search(undef, {
2686     select => [
2687       'name',
2688       { count => 'employeeid' },
2689       { sum => 'salary' }
2690     ]
2691   });
2692
2693 When you use function/stored procedure names and do not supply an C<as>
2694 attribute, the column names returned are storage-dependent. E.g. MySQL would
2695 return a column named C<count(employeeid)> in the above example.
2696
2697 =head2 +select
2698
2699 =over 4
2700
2701 Indicates additional columns to be selected from storage.  Works the same as
2702 L</select> but adds columns to the selection.
2703
2704 =back
2705
2706 =head2 +as
2707
2708 =over 4
2709
2710 Indicates additional column names for those added via L</+select>. See L</as>.
2711
2712 =back
2713
2714 =head2 as
2715
2716 =over 4
2717
2718 =item Value: \@inflation_names
2719
2720 =back
2721
2722 Indicates column names for object inflation. That is, C<as>
2723 indicates the name that the column can be accessed as via the
2724 C<get_column> method (or via the object accessor, B<if one already
2725 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2726
2727 The C<as> attribute is used in conjunction with C<select>,
2728 usually when C<select> contains one or more function or stored
2729 procedure names:
2730
2731   $rs = $schema->resultset('Employee')->search(undef, {
2732     select => [
2733       'name',
2734       { count => 'employeeid' }
2735     ],
2736     as => ['name', 'employee_count'],
2737   });
2738
2739   my $employee = $rs->first(); # get the first Employee
2740
2741 If the object against which the search is performed already has an accessor
2742 matching a column name specified in C<as>, the value can be retrieved using
2743 the accessor as normal:
2744
2745   my $name = $employee->name();
2746
2747 If on the other hand an accessor does not exist in the object, you need to
2748 use C<get_column> instead:
2749
2750   my $employee_count = $employee->get_column('employee_count');
2751
2752 You can create your own accessors if required - see
2753 L<DBIx::Class::Manual::Cookbook> for details.
2754
2755 Please note: This will NOT insert an C<AS employee_count> into the SQL
2756 statement produced, it is used for internal access only. Thus
2757 attempting to use the accessor in an C<order_by> clause or similar
2758 will fail miserably.
2759
2760 To get around this limitation, you can supply literal SQL to your
2761 C<select> attibute that contains the C<AS alias> text, eg:
2762
2763   select => [\'myfield AS alias']
2764
2765 =head2 join
2766
2767 =over 4
2768
2769 =item Value: ($rel_name | \@rel_names | \%rel_names)
2770
2771 =back
2772
2773 Contains a list of relationships that should be joined for this query.  For
2774 example:
2775
2776   # Get CDs by Nine Inch Nails
2777   my $rs = $schema->resultset('CD')->search(
2778     { 'artist.name' => 'Nine Inch Nails' },
2779     { join => 'artist' }
2780   );
2781
2782 Can also contain a hash reference to refer to the other relation's relations.
2783 For example:
2784
2785   package MyApp::Schema::Track;
2786   use base qw/DBIx::Class/;
2787   __PACKAGE__->table('track');
2788   __PACKAGE__->add_columns(qw/trackid cd position title/);
2789   __PACKAGE__->set_primary_key('trackid');
2790   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2791   1;
2792
2793   # In your application
2794   my $rs = $schema->resultset('Artist')->search(
2795     { 'track.title' => 'Teardrop' },
2796     {
2797       join     => { cd => 'track' },
2798       order_by => 'artist.name',
2799     }
2800   );
2801
2802 You need to use the relationship (not the table) name in  conditions,
2803 because they are aliased as such. The current table is aliased as "me", so
2804 you need to use me.column_name in order to avoid ambiguity. For example:
2805
2806   # Get CDs from 1984 with a 'Foo' track
2807   my $rs = $schema->resultset('CD')->search(
2808     {
2809       'me.year' => 1984,
2810       'tracks.name' => 'Foo'
2811     },
2812     { join => 'tracks' }
2813   );
2814
2815 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2816 similarly for a third time). For e.g.
2817
2818   my $rs = $schema->resultset('Artist')->search({
2819     'cds.title'   => 'Down to Earth',
2820     'cds_2.title' => 'Popular',
2821   }, {
2822     join => [ qw/cds cds/ ],
2823   });
2824
2825 will return a set of all artists that have both a cd with title 'Down
2826 to Earth' and a cd with title 'Popular'.
2827
2828 If you want to fetch related objects from other tables as well, see C<prefetch>
2829 below.
2830
2831 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2832
2833 =head2 prefetch
2834
2835 =over 4
2836
2837 =item Value: ($rel_name | \@rel_names | \%rel_names)
2838
2839 =back
2840
2841 Contains one or more relationships that should be fetched along with
2842 the main query (when they are accessed afterwards the data will
2843 already be available, without extra queries to the database).  This is
2844 useful for when you know you will need the related objects, because it
2845 saves at least one query:
2846
2847   my $rs = $schema->resultset('Tag')->search(
2848     undef,
2849     {
2850       prefetch => {
2851         cd => 'artist'
2852       }
2853     }
2854   );
2855
2856 The initial search results in SQL like the following:
2857
2858   SELECT tag.*, cd.*, artist.* FROM tag
2859   JOIN cd ON tag.cd = cd.cdid
2860   JOIN artist ON cd.artist = artist.artistid
2861
2862 L<DBIx::Class> has no need to go back to the database when we access the
2863 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2864 case.
2865
2866 Simple prefetches will be joined automatically, so there is no need
2867 for a C<join> attribute in the above search.
2868
2869 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2870 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2871 with an accessor type of 'single' or 'filter'). A more complex example that
2872 prefetches an artists cds, the tracks on those cds, and the tags associted
2873 with that artist is given below (assuming many-to-many from artists to tags):
2874
2875  my $rs = $schema->resultset('Artist')->search(
2876    undef,
2877    {
2878      prefetch => [
2879        { cds => 'tracks' },
2880        { artist_tags => 'tags' }
2881      ]
2882    }
2883  );
2884
2885
2886 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2887 attributes will be ignored.
2888
2889 =head2 page
2890
2891 =over 4
2892
2893 =item Value: $page
2894
2895 =back
2896
2897 Makes the resultset paged and specifies the page to retrieve. Effectively
2898 identical to creating a non-pages resultset and then calling ->page($page)
2899 on it.
2900
2901 If L<rows> attribute is not specified it defualts to 10 rows per page.
2902
2903 When you have a paged resultset, L</count> will only return the number
2904 of rows in the page. To get the total, use the L</pager> and call
2905 C<total_entries> on it.
2906
2907 =head2 rows
2908
2909 =over 4
2910
2911 =item Value: $rows
2912
2913 =back
2914
2915 Specifes the maximum number of rows for direct retrieval or the number of
2916 rows per page if the page attribute or method is used.
2917
2918 =head2 offset
2919
2920 =over 4
2921
2922 =item Value: $offset
2923
2924 =back
2925
2926 Specifies the (zero-based) row number for the  first row to be returned, or the
2927 of the first row of the first page if paging is used.
2928
2929 =head2 group_by
2930
2931 =over 4
2932
2933 =item Value: \@columns
2934
2935 =back
2936
2937 A arrayref of columns to group by. Can include columns of joined tables.
2938
2939   group_by => [qw/ column1 column2 ... /]
2940
2941 =head2 having
2942
2943 =over 4
2944
2945 =item Value: $condition
2946
2947 =back
2948
2949 HAVING is a select statement attribute that is applied between GROUP BY and
2950 ORDER BY. It is applied to the after the grouping calculations have been
2951 done.
2952
2953   having => { 'count(employee)' => { '>=', 100 } }
2954
2955 =head2 distinct
2956
2957 =over 4
2958
2959 =item Value: (0 | 1)
2960
2961 =back
2962
2963 Set to 1 to group by all columns.
2964
2965 =head2 where
2966
2967 =over 4
2968
2969 Adds to the WHERE clause.
2970
2971   # only return rows WHERE deleted IS NULL for all searches
2972   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2973
2974 Can be overridden by passing C<{ where => undef }> as an attribute
2975 to a resulset.
2976
2977 =back
2978
2979 =head2 cache
2980
2981 Set to 1 to cache search results. This prevents extra SQL queries if you
2982 revisit rows in your ResultSet:
2983
2984   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2985
2986   while( my $artist = $resultset->next ) {
2987     ... do stuff ...
2988   }
2989
2990   $rs->first; # without cache, this would issue a query
2991
2992 By default, searches are not cached.
2993
2994 For more examples of using these attributes, see
2995 L<DBIx::Class::Manual::Cookbook>.
2996
2997 =head2 from
2998
2999 =over 4
3000
3001 =item Value: \@from_clause
3002
3003 =back
3004
3005 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3006 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3007 clauses.
3008
3009 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3010
3011 C<join> will usually do what you need and it is strongly recommended that you
3012 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3013 And we really do mean "cannot", not just tried and failed. Attempting to use
3014 this because you're having problems with C<join> is like trying to use x86
3015 ASM because you've got a syntax error in your C. Trust us on this.
3016
3017 Now, if you're still really, really sure you need to use this (and if you're
3018 not 100% sure, ask the mailing list first), here's an explanation of how this
3019 works.
3020
3021 The syntax is as follows -
3022
3023   [
3024     { <alias1> => <table1> },
3025     [
3026       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3027       [], # nested JOIN (optional)
3028       { <table1.column1> => <table2.column2>, ... (more conditions) },
3029     ],
3030     # More of the above [ ] may follow for additional joins
3031   ]
3032
3033   <table1> <alias1>
3034   JOIN
3035     <table2> <alias2>
3036     [JOIN ...]
3037   ON <table1.column1> = <table2.column2>
3038   <more joins may follow>
3039
3040 An easy way to follow the examples below is to remember the following:
3041
3042     Anything inside "[]" is a JOIN
3043     Anything inside "{}" is a condition for the enclosing JOIN
3044
3045 The following examples utilize a "person" table in a family tree application.
3046 In order to express parent->child relationships, this table is self-joined:
3047
3048     # Person->belongs_to('father' => 'Person');
3049     # Person->belongs_to('mother' => 'Person');
3050
3051 C<from> can be used to nest joins. Here we return all children with a father,
3052 then search against all mothers of those children:
3053
3054   $rs = $schema->resultset('Person')->search(
3055       undef,
3056       {
3057           alias => 'mother', # alias columns in accordance with "from"
3058           from => [
3059               { mother => 'person' },
3060               [
3061                   [
3062                       { child => 'person' },
3063                       [
3064                           { father => 'person' },
3065                           { 'father.person_id' => 'child.father_id' }
3066                       ]
3067                   ],
3068                   { 'mother.person_id' => 'child.mother_id' }
3069               ],
3070           ]
3071       },
3072   );
3073
3074   # Equivalent SQL:
3075   # SELECT mother.* FROM person mother
3076   # JOIN (
3077   #   person child
3078   #   JOIN person father
3079   #   ON ( father.person_id = child.father_id )
3080   # )
3081   # ON ( mother.person_id = child.mother_id )
3082
3083 The type of any join can be controlled manually. To search against only people
3084 with a father in the person table, we could explicitly use C<INNER JOIN>:
3085
3086     $rs = $schema->resultset('Person')->search(
3087         undef,
3088         {
3089             alias => 'child', # alias columns in accordance with "from"
3090             from => [
3091                 { child => 'person' },
3092                 [
3093                     { father => 'person', -join_type => 'inner' },
3094                     { 'father.id' => 'child.father_id' }
3095                 ],
3096             ]
3097         },
3098     );
3099
3100     # Equivalent SQL:
3101     # SELECT child.* FROM person child
3102     # INNER JOIN person father ON child.father_id = father.id
3103
3104 If you need to express really complex joins or you need a subselect, you
3105 can supply literal SQL to C<from> via a scalar reference. In this case
3106 the contents of the scalar will replace the table name asscoiated with the
3107 resultsource.
3108
3109 WARNING: This technique might very well not work as expected on chained
3110 searches - you have been warned.
3111
3112     # Assuming the Event resultsource is defined as:
3113
3114         MySchema::Event->add_columns (
3115             sequence => {
3116                 data_type => 'INT',
3117                 is_auto_increment => 1,
3118             },
3119             location => {
3120                 data_type => 'INT',
3121             },
3122             type => {
3123                 data_type => 'INT',
3124             },
3125         );
3126         MySchema::Event->set_primary_key ('sequence');
3127
3128     # This will get back the latest event for every location. The column
3129     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3130     # combo to limit the resultset
3131
3132     $rs = $schema->resultset('Event');
3133     $table = $rs->result_source->name;
3134     $latest = $rs->search (
3135         undef,
3136         { from => \ "
3137             (SELECT e1.* FROM $table e1
3138                 JOIN $table e2
3139                     ON e1.location = e2.location
3140                     AND e1.sequence < e2.sequence
3141                 WHERE e2.sequence is NULL
3142             ) me",
3143         },
3144     );
3145
3146     # Equivalent SQL (with the DBIC chunks added):
3147
3148     SELECT me.sequence, me.location, me.type FROM
3149        (SELECT e1.* FROM events e1
3150            JOIN events e2
3151                ON e1.location = e2.location
3152                AND e1.sequence < e2.sequence
3153            WHERE e2.sequence is NULL
3154        ) me;
3155
3156 =head2 for
3157
3158 =over 4
3159
3160 =item Value: ( 'update' | 'shared' )
3161
3162 =back
3163
3164 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3165 ... FOR SHARED.
3166
3167 =cut
3168
3169 1;