lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799 #      warn "ARRAY: " . Dumper $subquery;
 800       $collapsed = $self->_collapse_query($subquery, $collapsed);
 801     }
 802   }
 803   elsif (ref $query eq 'HASH') {
 804     if (keys %$query and (keys %$query)[0] eq '-and') {
 805       foreach my $subquery (@{$query->{-and}}) {
 806 #        warn "HASH: " . Dumper $subquery;
 807         $collapsed = $self->_collapse_query($subquery, $collapsed);
 808       }
 809     }
 810     else {
 811 #      warn "LEAF: " . Dumper $query;
 812       foreach my $col (keys %$query) {
 813         my $value = $query->{$col};
 814         $collapsed->{$col}{$value}++;
 815       }
 816     }
 817   }
 818
 819   return $collapsed;
 820 }
 821
 822 =head2 get_column
 823
 824 =over 4
 825
 826 =item Arguments: $cond?
 827
 828 =item Return Value: $resultsetcolumn
 829
 830 =back
 831
 832   my $max_length = $rs->get_column('length')->max;
 833
 834 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 835
 836 =cut
 837
 838 sub get_column {
 839   my ($self, $column) = @_;
 840   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 841   return $new;
 842 }
 843
 844 =head2 search_like
 845
 846 =over 4
 847
 848 =item Arguments: $cond, \%attrs?
 849
 850 =item Return Value: $resultset (scalar context), @row_objs (list context)
 851
 852 =back
 853
 854   # WHERE title LIKE '%blue%'
 855   $cd_rs = $rs->search_like({ title => '%blue%'});
 856
 857 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 858 that this is simply a convenience method retained for ex Class::DBI users.
 859 You most likely want to use L</search> with specific operators.
 860
 861 For more information, see L<DBIx::Class::Manual::Cookbook>.
 862
 863 This method is deprecated and will be removed in 0.09. Use L</search()>
 864 instead. An example conversion is:
 865
 866   ->search_like({ foo => 'bar' });
 867
 868   # Becomes
 869
 870   ->search({ foo => { like => 'bar' } });
 871
 872 =cut
 873
 874 sub search_like {
 875   my $class = shift;
 876   carp join ("\n",
 877     'search_like() is deprecated and will be removed in 0.09.',
 878     'Instead use ->search({ x => { -like => "y%" } })',
 879     '(note the outer pair of {}s - they are important!)'
 880   );
 881   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 882   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 883   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 884   return $class->search($query, { %$attrs });
 885 }
 886
 887 =head2 slice
 888
 889 =over 4
 890
 891 =item Arguments: $first, $last
 892
 893 =item Return Value: $resultset (scalar context), @row_objs (list context)
 894
 895 =back
 896
 897 Returns a resultset or object list representing a subset of elements from the
 898 resultset slice is called on. Indexes are from 0, i.e., to get the first
 899 three records, call:
 900
 901   my ($one, $two, $three) = $rs->slice(0, 2);
 902
 903 =cut
 904
 905 sub slice {
 906   my ($self, $min, $max) = @_;
 907   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 908   $attrs->{offset} = $self->{attrs}{offset} || 0;
 909   $attrs->{offset} += $min;
 910   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 911   return $self->search(undef(), $attrs);
 912   #my $slice = (ref $self)->new($self->result_source, $attrs);
 913   #return (wantarray ? $slice->all : $slice);
 914 }
 915
 916 =head2 next
 917
 918 =over 4
 919
 920 =item Arguments: none
 921
 922 =item Return Value: $result?
 923
 924 =back
 925
 926 Returns the next element in the resultset (C<undef> is there is none).
 927
 928 Can be used to efficiently iterate over records in the resultset:
 929
 930   my $rs = $schema->resultset('CD')->search;
 931   while (my $cd = $rs->next) {
 932     print $cd->title;
 933   }
 934
 935 Note that you need to store the resultset object, and call C<next> on it.
 936 Calling C<< resultset('Table')->next >> repeatedly will always return the
 937 first record from the resultset.
 938
 939 =cut
 940
 941 sub next {
 942   my ($self) = @_;
 943   if (my $cache = $self->get_cache) {
 944     $self->{all_cache_position} ||= 0;
 945     return $cache->[$self->{all_cache_position}++];
 946   }
 947   if ($self->{attrs}{cache}) {
 948     $self->{all_cache_position} = 1;
 949     return ($self->all)[0];
 950   }
 951   if ($self->{stashed_objects}) {
 952     my $obj = shift(@{$self->{stashed_objects}});
 953     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 954     return $obj;
 955   }
 956   my @row = (
 957     exists $self->{stashed_row}
 958       ? @{delete $self->{stashed_row}}
 959       : $self->cursor->next
 960   );
 961   return undef unless (@row);
 962   my ($row, @more) = $self->_construct_object(@row);
 963   $self->{stashed_objects} = \@more if @more;
 964   return $row;
 965 }
 966
 967 sub _construct_object {
 968   my ($self, @row) = @_;
 969   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 970   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 971   @new = $self->{_attrs}{record_filter}->(@new)
 972     if exists $self->{_attrs}{record_filter};
 973   return @new;
 974 }
 975
 976 sub _collapse_result {
 977   my ($self, $as_proto, $row) = @_;
 978
 979   my @copy = @$row;
 980
 981   # 'foo'         => [ undef, 'foo' ]
 982   # 'foo.bar'     => [ 'foo', 'bar' ]
 983   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 984
 985   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 986
 987   my %collapse = %{$self->{_attrs}{collapse}||{}};
 988
 989   my @pri_index;
 990
 991   # if we're doing collapsing (has_many prefetch) we need to grab records
 992   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 993   # we know we don't have to bother.
 994
 995   # the reason for not using the collapse stuff directly is because if you
 996   # had for e.g. two artists in a row with no cds, the collapse info for
 997   # both would be NULL (undef) so you'd lose the second artist
 998
 999   # store just the index so we can check the array positions from the row
1000   # without having to contruct the full hash
1001
1002   if (keys %collapse) {
1003     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1004     foreach my $i (0 .. $#construct_as) {
1005       next if defined($construct_as[$i][0]); # only self table
1006       if (delete $pri{$construct_as[$i][1]}) {
1007         push(@pri_index, $i);
1008       }
1009       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1010     }
1011   }
1012
1013   # no need to do an if, it'll be empty if @pri_index is empty anyway
1014
1015   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1016
1017   my @const_rows;
1018
1019   do { # no need to check anything at the front, we always want the first row
1020
1021     my %const;
1022
1023     foreach my $this_as (@construct_as) {
1024       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1025     }
1026
1027     push(@const_rows, \%const);
1028
1029   } until ( # no pri_index => no collapse => drop straight out
1030       !@pri_index
1031     or
1032       do { # get another row, stash it, drop out if different PK
1033
1034         @copy = $self->cursor->next;
1035         $self->{stashed_row} = \@copy;
1036
1037         # last thing in do block, counts as true if anything doesn't match
1038
1039         # check xor defined first for NULL vs. NOT NULL then if one is
1040         # defined the other must be so check string equality
1041
1042         grep {
1043           (defined $pri_vals{$_} ^ defined $copy[$_])
1044           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1045         } @pri_index;
1046       }
1047   );
1048
1049   my $alias = $self->{attrs}{alias};
1050   my $info = [];
1051
1052   my %collapse_pos;
1053
1054   my @const_keys;
1055
1056   foreach my $const (@const_rows) {
1057     scalar @const_keys or do {
1058       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1059     };
1060     foreach my $key (@const_keys) {
1061       if (length $key) {
1062         my $target = $info;
1063         my @parts = split(/\./, $key);
1064         my $cur = '';
1065         my $data = $const->{$key};
1066         foreach my $p (@parts) {
1067           $target = $target->[1]->{$p} ||= [];
1068           $cur .= ".${p}";
1069           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1070             # collapsing at this point and on final part
1071             my $pos = $collapse_pos{$cur};
1072             CK: foreach my $ck (@ckey) {
1073               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1074                 $collapse_pos{$cur} = $data;
1075                 delete @collapse_pos{ # clear all positioning for sub-entries
1076                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1077                 };
1078                 push(@$target, []);
1079                 last CK;
1080               }
1081             }
1082           }
1083           if (exists $collapse{$cur}) {
1084             $target = $target->[-1];
1085           }
1086         }
1087         $target->[0] = $data;
1088       } else {
1089         $info->[0] = $const->{$key};
1090       }
1091     }
1092   }
1093
1094   return $info;
1095 }
1096
1097 =head2 result_source
1098
1099 =over 4
1100
1101 =item Arguments: $result_source?
1102
1103 =item Return Value: $result_source
1104
1105 =back
1106
1107 An accessor for the primary ResultSource object from which this ResultSet
1108 is derived.
1109
1110 =head2 result_class
1111
1112 =over 4
1113
1114 =item Arguments: $result_class?
1115
1116 =item Return Value: $result_class
1117
1118 =back
1119
1120 An accessor for the class to use when creating row objects. Defaults to
1121 C<< result_source->result_class >> - which in most cases is the name of the
1122 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1123
1124 Note that changing the result_class will also remove any components
1125 that were originally loaded in the source class via
1126 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1127 in the original source class will not run.
1128
1129 =cut
1130
1131 sub result_class {
1132   my ($self, $result_class) = @_;
1133   if ($result_class) {
1134     $self->ensure_class_loaded($result_class);
1135     $self->_result_class($result_class);
1136   }
1137   $self->_result_class;
1138 }
1139
1140 =head2 count
1141
1142 =over 4
1143
1144 =item Arguments: $cond, \%attrs??
1145
1146 =item Return Value: $count
1147
1148 =back
1149
1150 Performs an SQL C<COUNT> with the same query as the resultset was built
1151 with to find the number of elements. If passed arguments, does a search
1152 on the resultset and counts the results of that.
1153
1154 Note: When using C<count> with C<group_by>, L<DBIx::Class> emulates C<GROUP BY>
1155 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
1156 not support C<DISTINCT> with multiple columns. If you are using such a
1157 database, you should only use columns from the main table in your C<group_by>
1158 clause.
1159
1160 =cut
1161
1162 sub count {
1163   my $self = shift;
1164   return $self->search(@_)->count if @_ and defined $_[0];
1165   return scalar @{ $self->get_cache } if $self->get_cache;
1166   my $count = $self->_count;
1167   return 0 unless $count;
1168
1169   # need to take offset from resolved attrs
1170
1171   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1172   $count = $self->{attrs}{rows} if
1173     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1174   $count = 0 if ($count < 0);
1175   return $count;
1176 }
1177
1178 sub _count { # Separated out so pager can get the full count
1179   my $self = shift;
1180   my $select = { count => '*' };
1181
1182   my $attrs = { %{$self->_resolved_attrs} };
1183   if (my $group_by = delete $attrs->{group_by}) {
1184     delete $attrs->{having};
1185     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
1186     # todo: try CONCAT for multi-column pk
1187     my @pk = $self->result_source->primary_columns;
1188     if (@pk == 1) {
1189       my $alias = $attrs->{alias};
1190       foreach my $column (@distinct) {
1191         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
1192           @distinct = ($column);
1193           last;
1194         }
1195       }
1196     }
1197
1198     $select = { count => { distinct => \@distinct } };
1199   }
1200
1201   $attrs->{select} = $select;
1202   $attrs->{as} = [qw/count/];
1203
1204   # offset, order by and page are not needed to count. record_filter is cdbi
1205   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
1206
1207   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1208   my ($count) = $tmp_rs->cursor->next;
1209   return $count;
1210 }
1211
1212 sub _bool {
1213   return 1;
1214 }
1215
1216 =head2 count_literal
1217
1218 =over 4
1219
1220 =item Arguments: $sql_fragment, @bind_values
1221
1222 =item Return Value: $count
1223
1224 =back
1225
1226 Counts the results in a literal query. Equivalent to calling L</search_literal>
1227 with the passed arguments, then L</count>.
1228
1229 =cut
1230
1231 sub count_literal { shift->search_literal(@_)->count; }
1232
1233 =head2 all
1234
1235 =over 4
1236
1237 =item Arguments: none
1238
1239 =item Return Value: @objects
1240
1241 =back
1242
1243 Returns all elements in the resultset. Called implicitly if the resultset
1244 is returned in list context.
1245
1246 =cut
1247
1248 sub all {
1249   my $self = shift;
1250   if(@_) {
1251       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1252   }
1253
1254   return @{ $self->get_cache } if $self->get_cache;
1255
1256   my @obj;
1257
1258   # TODO: don't call resolve here
1259   if (keys %{$self->_resolved_attrs->{collapse}}) {
1260 #  if ($self->{attrs}{prefetch}) {
1261       # Using $self->cursor->all is really just an optimisation.
1262       # If we're collapsing has_many prefetches it probably makes
1263       # very little difference, and this is cleaner than hacking
1264       # _construct_object to survive the approach
1265     my @row = $self->cursor->next;
1266     while (@row) {
1267       push(@obj, $self->_construct_object(@row));
1268       @row = (exists $self->{stashed_row}
1269                ? @{delete $self->{stashed_row}}
1270                : $self->cursor->next);
1271     }
1272   } else {
1273     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1274   }
1275
1276   $self->set_cache(\@obj) if $self->{attrs}{cache};
1277   return @obj;
1278 }
1279
1280 =head2 reset
1281
1282 =over 4
1283
1284 =item Arguments: none
1285
1286 =item Return Value: $self
1287
1288 =back
1289
1290 Resets the resultset's cursor, so you can iterate through the elements again.
1291
1292 =cut
1293
1294 sub reset {
1295   my ($self) = @_;
1296   delete $self->{_attrs} if exists $self->{_attrs};
1297   $self->{all_cache_position} = 0;
1298   $self->cursor->reset;
1299   return $self;
1300 }
1301
1302 =head2 first
1303
1304 =over 4
1305
1306 =item Arguments: none
1307
1308 =item Return Value: $object?
1309
1310 =back
1311
1312 Resets the resultset and returns an object for the first result (if the
1313 resultset returns anything).
1314
1315 =cut
1316
1317 sub first {
1318   return $_[0]->reset->next;
1319 }
1320
1321 # _cond_for_update_delete
1322 #
1323 # update/delete require the condition to be modified to handle
1324 # the differing SQL syntax available.  This transforms the $self->{cond}
1325 # appropriately, returning the new condition.
1326
1327 sub _cond_for_update_delete {
1328   my ($self, $full_cond) = @_;
1329   my $cond = {};
1330
1331   $full_cond ||= $self->{cond};
1332   # No-op. No condition, we're updating/deleting everything
1333   return $cond unless ref $full_cond;
1334
1335   if (ref $full_cond eq 'ARRAY') {
1336     $cond = [
1337       map {
1338         my %hash;
1339         foreach my $key (keys %{$_}) {
1340           $key =~ /([^.]+)$/;
1341           $hash{$1} = $_->{$key};
1342         }
1343         \%hash;
1344       } @{$full_cond}
1345     ];
1346   }
1347   elsif (ref $full_cond eq 'HASH') {
1348     if ((keys %{$full_cond})[0] eq '-and') {
1349       $cond->{-and} = [];
1350
1351       my @cond = @{$full_cond->{-and}};
1352       for (my $i = 0; $i < @cond; $i++) {
1353         my $entry = $cond[$i];
1354
1355         my $hash;
1356         if (ref $entry eq 'HASH') {
1357           $hash = $self->_cond_for_update_delete($entry);
1358         }
1359         else {
1360           $entry =~ /([^.]+)$/;
1361           $hash->{$1} = $cond[++$i];
1362         }
1363
1364         push @{$cond->{-and}}, $hash;
1365       }
1366     }
1367     else {
1368       foreach my $key (keys %{$full_cond}) {
1369         $key =~ /([^.]+)$/;
1370         $cond->{$1} = $full_cond->{$key};
1371       }
1372     }
1373   }
1374   else {
1375     $self->throw_exception(
1376       "Can't update/delete on resultset with condition unless hash or array"
1377     );
1378   }
1379
1380   return $cond;
1381 }
1382
1383
1384 =head2 update
1385
1386 =over 4
1387
1388 =item Arguments: \%values
1389
1390 =item Return Value: $storage_rv
1391
1392 =back
1393
1394 Sets the specified columns in the resultset to the supplied values in a
1395 single query. Return value will be true if the update succeeded or false
1396 if no records were updated; exact type of success value is storage-dependent.
1397
1398 =cut
1399
1400 sub update {
1401   my ($self, $values) = @_;
1402   $self->throw_exception("Values for update must be a hash")
1403     unless ref $values eq 'HASH';
1404
1405   carp(   'WARNING! Currently $rs->update() does not generate proper SQL'
1406         . ' on joined resultsets, and may affect rows well outside of the'
1407         . ' contents of $rs. Use at your own risk' )
1408     if ( $self->{attrs}{seen_join} );
1409
1410   my $cond = $self->_cond_for_update_delete;
1411
1412   return $self->result_source->storage->update(
1413     $self->result_source, $values, $cond
1414   );
1415 }
1416
1417 =head2 update_all
1418
1419 =over 4
1420
1421 =item Arguments: \%values
1422
1423 =item Return Value: 1
1424
1425 =back
1426
1427 Fetches all objects and updates them one at a time. Note that C<update_all>
1428 will run DBIC cascade triggers, while L</update> will not.
1429
1430 =cut
1431
1432 sub update_all {
1433   my ($self, $values) = @_;
1434   $self->throw_exception("Values for update must be a hash")
1435     unless ref $values eq 'HASH';
1436   foreach my $obj ($self->all) {
1437     $obj->set_columns($values)->update;
1438   }
1439   return 1;
1440 }
1441
1442 =head2 delete
1443
1444 =over 4
1445
1446 =item Arguments: none
1447
1448 =item Return Value: 1
1449
1450 =back
1451
1452 Deletes the contents of the resultset from its result source. Note that this
1453 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1454 to run. See also L<DBIx::Class::Row/delete>.
1455
1456 delete may not generate correct SQL for a query with joins or a resultset
1457 chained from a related resultset.  In this case it will generate a warning:-
1458
1459   WARNING! Currently $rs->delete() does not generate proper SQL on
1460   joined resultsets, and may delete rows well outside of the contents
1461   of $rs. Use at your own risk
1462
1463 In these cases you may find that delete_all is more appropriate, or you
1464 need to respecify your query in a way that can be expressed without a join.
1465
1466 =cut
1467
1468 sub delete {
1469   my ($self) = @_;
1470   $self->throw_exception("Delete should not be passed any arguments")
1471     if $_[1];
1472   carp(   'WARNING! Currently $rs->delete() does not generate proper SQL'
1473         . ' on joined resultsets, and may delete rows well outside of the'
1474         . ' contents of $rs. Use at your own risk' )
1475     if ( $self->{attrs}{seen_join} );
1476   my $cond = $self->_cond_for_update_delete;
1477
1478   $self->result_source->storage->delete($self->result_source, $cond);
1479   return 1;
1480 }
1481
1482 =head2 delete_all
1483
1484 =over 4
1485
1486 =item Arguments: none
1487
1488 =item Return Value: 1
1489
1490 =back
1491
1492 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1493 will run DBIC cascade triggers, while L</delete> will not.
1494
1495 =cut
1496
1497 sub delete_all {
1498   my ($self) = @_;
1499   $_->delete for $self->all;
1500   return 1;
1501 }
1502
1503 =head2 populate
1504
1505 =over 4
1506
1507 =item Arguments: \@data;
1508
1509 =back
1510
1511 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1512 For the arrayref of hashrefs style each hashref should be a structure suitable
1513 forsubmitting to a $resultset->create(...) method.
1514
1515 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1516 to insert the data, as this is a faster method.
1517
1518 Otherwise, each set of data is inserted into the database using
1519 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1520 objects is returned.
1521
1522 Example:  Assuming an Artist Class that has many CDs Classes relating:
1523
1524   my $Artist_rs = $schema->resultset("Artist");
1525
1526   ## Void Context Example
1527   $Artist_rs->populate([
1528      { artistid => 4, name => 'Manufactured Crap', cds => [
1529         { title => 'My First CD', year => 2006 },
1530         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1531       ],
1532      },
1533      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1534         { title => 'My parents sold me to a record company' ,year => 2005 },
1535         { title => 'Why Am I So Ugly?', year => 2006 },
1536         { title => 'I Got Surgery and am now Popular', year => 2007 }
1537       ],
1538      },
1539   ]);
1540
1541   ## Array Context Example
1542   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1543     { name => "Artist One"},
1544     { name => "Artist Two"},
1545     { name => "Artist Three", cds=> [
1546     { title => "First CD", year => 2007},
1547     { title => "Second CD", year => 2008},
1548   ]}
1549   ]);
1550
1551   print $ArtistOne->name; ## response is 'Artist One'
1552   print $ArtistThree->cds->count ## reponse is '2'
1553
1554 For the arrayref of arrayrefs style,  the first element should be a list of the
1555 fieldsnames to which the remaining elements are rows being inserted.  For
1556 example:
1557
1558   $Arstist_rs->populate([
1559     [qw/artistid name/],
1560     [100, 'A Formally Unknown Singer'],
1561     [101, 'A singer that jumped the shark two albums ago'],
1562     [102, 'An actually cool singer.'],
1563   ]);
1564
1565 Please note an important effect on your data when choosing between void and
1566 wantarray context. Since void context goes straight to C<insert_bulk> in
1567 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1568 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1569 create primary keys for you, you will find that your PKs are empty.  In this
1570 case you will have to use the wantarray context in order to create those
1571 values.
1572
1573 =cut
1574
1575 sub populate {
1576   my $self = shift @_;
1577   my $data = ref $_[0][0] eq 'HASH'
1578     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1579     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1580
1581   if(defined wantarray) {
1582     my @created;
1583     foreach my $item (@$data) {
1584       push(@created, $self->create($item));
1585     }
1586     return @created;
1587   } else {
1588     my ($first, @rest) = @$data;
1589
1590     my @names = grep {!ref $first->{$_}} keys %$first;
1591     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1592     my @pks = $self->result_source->primary_columns;
1593
1594     ## do the belongs_to relationships
1595     foreach my $index (0..$#$data) {
1596       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1597         my @ret = $self->populate($data);
1598         return;
1599       }
1600
1601       foreach my $rel (@rels) {
1602         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1603         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1604         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1605         my $related = $result->result_source->resolve_condition(
1606           $result->result_source->relationship_info($reverse)->{cond},
1607           $self,
1608           $result,
1609         );
1610
1611         delete $data->[$index]->{$rel};
1612         $data->[$index] = {%{$data->[$index]}, %$related};
1613
1614         push @names, keys %$related if $index == 0;
1615       }
1616     }
1617
1618     ## do bulk insert on current row
1619     my @values = map { [ @$_{@names} ] } @$data;
1620
1621     $self->result_source->storage->insert_bulk(
1622       $self->result_source,
1623       \@names,
1624       \@values,
1625     );
1626
1627     ## do the has_many relationships
1628     foreach my $item (@$data) {
1629
1630       foreach my $rel (@rels) {
1631         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1632
1633         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1634      || $self->throw_exception('Cannot find the relating object.');
1635
1636         my $child = $parent->$rel;
1637
1638         my $related = $child->result_source->resolve_condition(
1639           $parent->result_source->relationship_info($rel)->{cond},
1640           $child,
1641           $parent,
1642         );
1643
1644         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1645         my @populate = map { {%$_, %$related} } @rows_to_add;
1646
1647         $child->populate( \@populate );
1648       }
1649     }
1650   }
1651 }
1652
1653 =head2 _normalize_populate_args ($args)
1654
1655 Private method used by L</populate> to normalize its incoming arguments.  Factored
1656 out in case you want to subclass and accept new argument structures to the
1657 L</populate> method.
1658
1659 =cut
1660
1661 sub _normalize_populate_args {
1662   my ($self, $data) = @_;
1663   my @names = @{shift(@$data)};
1664   my @results_to_create;
1665   foreach my $datum (@$data) {
1666     my %result_to_create;
1667     foreach my $index (0..$#names) {
1668       $result_to_create{$names[$index]} = $$datum[$index];
1669     }
1670     push @results_to_create, \%result_to_create;
1671   }
1672   return \@results_to_create;
1673 }
1674
1675 =head2 pager
1676
1677 =over 4
1678
1679 =item Arguments: none
1680
1681 =item Return Value: $pager
1682
1683 =back
1684
1685 Return Value a L<Data::Page> object for the current resultset. Only makes
1686 sense for queries with a C<page> attribute.
1687
1688 To get the full count of entries for a paged resultset, call
1689 C<total_entries> on the L<Data::Page> object.
1690
1691 =cut
1692
1693 sub pager {
1694   my ($self) = @_;
1695   my $attrs = $self->{attrs};
1696   $self->throw_exception("Can't create pager for non-paged rs")
1697     unless $self->{attrs}{page};
1698   $attrs->{rows} ||= 10;
1699   return $self->{pager} ||= Data::Page->new(
1700     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1701 }
1702
1703 =head2 page
1704
1705 =over 4
1706
1707 =item Arguments: $page_number
1708
1709 =item Return Value: $rs
1710
1711 =back
1712
1713 Returns a resultset for the $page_number page of the resultset on which page
1714 is called, where each page contains a number of rows equal to the 'rows'
1715 attribute set on the resultset (10 by default).
1716
1717 =cut
1718
1719 sub page {
1720   my ($self, $page) = @_;
1721   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1722 }
1723
1724 =head2 new_result
1725
1726 =over 4
1727
1728 =item Arguments: \%vals
1729
1730 =item Return Value: $rowobject
1731
1732 =back
1733
1734 Creates a new row object in the resultset's result class and returns
1735 it. The row is not inserted into the database at this point, call
1736 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1737 will tell you whether the row object has been inserted or not.
1738
1739 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1740
1741 =cut
1742
1743 sub new_result {
1744   my ($self, $values) = @_;
1745   $self->throw_exception( "new_result needs a hash" )
1746     unless (ref $values eq 'HASH');
1747
1748   my %new;
1749   my $alias = $self->{attrs}{alias};
1750
1751   if (
1752     defined $self->{cond}
1753     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1754   ) {
1755     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1756     $new{-from_resultset} = [ keys %new ] if keys %new;
1757   } else {
1758     $self->throw_exception(
1759       "Can't abstract implicit construct, condition not a hash"
1760     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1761
1762     my $collapsed_cond = (
1763       $self->{cond}
1764         ? $self->_collapse_cond($self->{cond})
1765         : {}
1766     );
1767
1768     # precendence must be given to passed values over values inherited from
1769     # the cond, so the order here is important.
1770     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1771     while( my($col,$value) = each %implied ){
1772       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1773         $new{$col} = $value->{'='};
1774         next;
1775       }
1776       $new{$col} = $value if $self->_is_deterministic_value($value);
1777     }
1778   }
1779
1780   %new = (
1781     %new,
1782     %{ $self->_remove_alias($values, $alias) },
1783     -source_handle => $self->_source_handle,
1784     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1785   );
1786
1787   return $self->result_class->new(\%new);
1788 }
1789
1790 # _is_deterministic_value
1791 #
1792 # Make an effor to strip non-deterministic values from the condition,
1793 # to make sure new_result chokes less
1794
1795 sub _is_deterministic_value {
1796   my $self = shift;
1797   my $value = shift;
1798   my $ref_type = ref $value;
1799   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1800   return 1 if Scalar::Util::blessed($value);
1801   return 0;
1802 }
1803
1804 # _collapse_cond
1805 #
1806 # Recursively collapse the condition.
1807
1808 sub _collapse_cond {
1809   my ($self, $cond, $collapsed) = @_;
1810
1811   $collapsed ||= {};
1812
1813   if (ref $cond eq 'ARRAY') {
1814     foreach my $subcond (@$cond) {
1815       next unless ref $subcond;  # -or
1816 #      warn "ARRAY: " . Dumper $subcond;
1817       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1818     }
1819   }
1820   elsif (ref $cond eq 'HASH') {
1821     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1822       foreach my $subcond (@{$cond->{-and}}) {
1823 #        warn "HASH: " . Dumper $subcond;
1824         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1825       }
1826     }
1827     else {
1828 #      warn "LEAF: " . Dumper $cond;
1829       foreach my $col (keys %$cond) {
1830         my $value = $cond->{$col};
1831         $collapsed->{$col} = $value;
1832       }
1833     }
1834   }
1835
1836   return $collapsed;
1837 }
1838
1839 # _remove_alias
1840 #
1841 # Remove the specified alias from the specified query hash. A copy is made so
1842 # the original query is not modified.
1843
1844 sub _remove_alias {
1845   my ($self, $query, $alias) = @_;
1846
1847   my %orig = %{ $query || {} };
1848   my %unaliased;
1849
1850   foreach my $key (keys %orig) {
1851     if ($key !~ /\./) {
1852       $unaliased{$key} = $orig{$key};
1853       next;
1854     }
1855     $unaliased{$1} = $orig{$key}
1856       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1857   }
1858
1859   return \%unaliased;
1860 }
1861
1862 =head2 as_query (EXPERIMENTAL)
1863
1864 =over 4
1865
1866 =item Arguments: none
1867
1868 =item Return Value: \[ $sql, @bind ]
1869
1870 =back
1871
1872 Returns the SQL query and bind vars associated with the invocant.
1873
1874 This is generally used as the RHS for a subquery.
1875
1876 B<NOTE>: This feature is still experimental.
1877
1878 =cut
1879
1880 sub as_query { return shift->cursor->as_query(@_) }
1881
1882 =head2 find_or_new
1883
1884 =over 4
1885
1886 =item Arguments: \%vals, \%attrs?
1887
1888 =item Return Value: $rowobject
1889
1890 =back
1891
1892   my $artist = $schema->resultset('Artist')->find_or_new(
1893     { artist => 'fred' }, { key => 'artists' });
1894
1895   $cd->cd_to_producer->find_or_new({ producer => $producer },
1896                                    { key => 'primary });
1897
1898 Find an existing record from this resultset, based on its primary
1899 key, or a unique constraint. If none exists, instantiate a new result
1900 object and return it. The object will not be saved into your storage
1901 until you call L<DBIx::Class::Row/insert> on it.
1902
1903 You most likely want this method when looking for existing rows using
1904 a unique constraint that is not the primary key, or looking for
1905 related rows.
1906
1907 If you want objects to be saved immediately, use L</find_or_create> instead.
1908
1909 B<Note>: C<find_or_new> is probably not what you want when creating a
1910 new row in a table that uses primary keys supplied by the
1911 database. Passing in a primary key column with a value of I<undef>
1912 will cause L</find> to attempt to search for a row with a value of
1913 I<NULL>.
1914
1915 =cut
1916
1917 sub find_or_new {
1918   my $self     = shift;
1919   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1920   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1921   my $exists   = $self->find($hash, $attrs);
1922   return defined $exists ? $exists : $self->new_result($hash);
1923 }
1924
1925 =head2 create
1926
1927 =over 4
1928
1929 =item Arguments: \%vals
1930
1931 =item Return Value: a L<DBIx::Class::Row> $object
1932
1933 =back
1934
1935 Attempt to create a single new row or a row with multiple related rows
1936 in the table represented by the resultset (and related tables). This
1937 will not check for duplicate rows before inserting, use
1938 L</find_or_create> to do that.
1939
1940 To create one row for this resultset, pass a hashref of key/value
1941 pairs representing the columns of the table and the values you wish to
1942 store. If the appropriate relationships are set up, foreign key fields
1943 can also be passed an object representing the foreign row, and the
1944 value will be set to its primary key.
1945
1946 To create related objects, pass a hashref for the value if the related
1947 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1948 and use the name of the relationship as the key. (NOT the name of the field,
1949 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1950 of hashrefs containing the data for each of the rows to create in the foreign
1951 tables, again using the relationship name as the key.
1952
1953 Instead of hashrefs of plain related data (key/value pairs), you may
1954 also pass new or inserted objects. New objects (not inserted yet, see
1955 L</new>), will be inserted into their appropriate tables.
1956
1957 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1958
1959 Example of creating a new row.
1960
1961   $person_rs->create({
1962     name=>"Some Person",
1963     email=>"somebody@someplace.com"
1964   });
1965
1966 Example of creating a new row and also creating rows in a related C<has_many>
1967 or C<has_one> resultset.  Note Arrayref.
1968
1969   $artist_rs->create(
1970      { artistid => 4, name => 'Manufactured Crap', cds => [
1971         { title => 'My First CD', year => 2006 },
1972         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1973       ],
1974      },
1975   );
1976
1977 Example of creating a new row and also creating a row in a related
1978 C<belongs_to>resultset. Note Hashref.
1979
1980   $cd_rs->create({
1981     title=>"Music for Silly Walks",
1982     year=>2000,
1983     artist => {
1984       name=>"Silly Musician",
1985     }
1986   });
1987
1988 =cut
1989
1990 sub create {
1991   my ($self, $attrs) = @_;
1992   $self->throw_exception( "create needs a hashref" )
1993     unless ref $attrs eq 'HASH';
1994   return $self->new_result($attrs)->insert;
1995 }
1996
1997 =head2 find_or_create
1998
1999 =over 4
2000
2001 =item Arguments: \%vals, \%attrs?
2002
2003 =item Return Value: $rowobject
2004
2005 =back
2006
2007   $cd->cd_to_producer->find_or_create({ producer => $producer },
2008                                       { key => 'primary });
2009
2010 Tries to find a record based on its primary key or unique constraints; if none
2011 is found, creates one and returns that instead.
2012
2013   my $cd = $schema->resultset('CD')->find_or_create({
2014     cdid   => 5,
2015     artist => 'Massive Attack',
2016     title  => 'Mezzanine',
2017     year   => 2005,
2018   });
2019
2020 Also takes an optional C<key> attribute, to search by a specific key or unique
2021 constraint. For example:
2022
2023   my $cd = $schema->resultset('CD')->find_or_create(
2024     {
2025       artist => 'Massive Attack',
2026       title  => 'Mezzanine',
2027     },
2028     { key => 'cd_artist_title' }
2029   );
2030
2031 B<Note>: Because find_or_create() reads from the database and then
2032 possibly inserts based on the result, this method is subject to a race
2033 condition. Another process could create a record in the table after
2034 the find has completed and before the create has started. To avoid
2035 this problem, use find_or_create() inside a transaction.
2036
2037 B<Note>: C<find_or_create> is probably not what you want when creating
2038 a new row in a table that uses primary keys supplied by the
2039 database. Passing in a primary key column with a value of I<undef>
2040 will cause L</find> to attempt to search for a row with a value of
2041 I<NULL>.
2042
2043 See also L</find> and L</update_or_create>. For information on how to declare
2044 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2045
2046 =cut
2047
2048 sub find_or_create {
2049   my $self     = shift;
2050   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2051   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2052   my $exists   = $self->find($hash, $attrs);
2053   return defined $exists ? $exists : $self->create($hash);
2054 }
2055
2056 =head2 update_or_create
2057
2058 =over 4
2059
2060 =item Arguments: \%col_values, { key => $unique_constraint }?
2061
2062 =item Return Value: $rowobject
2063
2064 =back
2065
2066   $resultset->update_or_create({ col => $val, ... });
2067
2068 First, searches for an existing row matching one of the unique constraints
2069 (including the primary key) on the source of this resultset. If a row is
2070 found, updates it with the other given column values. Otherwise, creates a new
2071 row.
2072
2073 Takes an optional C<key> attribute to search on a specific unique constraint.
2074 For example:
2075
2076   # In your application
2077   my $cd = $schema->resultset('CD')->update_or_create(
2078     {
2079       artist => 'Massive Attack',
2080       title  => 'Mezzanine',
2081       year   => 1998,
2082     },
2083     { key => 'cd_artist_title' }
2084   );
2085
2086   $cd->cd_to_producer->update_or_create({
2087     producer => $producer,
2088     name => 'harry',
2089   }, {
2090     key => 'primary,
2091   });
2092
2093
2094 If no C<key> is specified, it searches on all unique constraints defined on the
2095 source, including the primary key.
2096
2097 If the C<key> is specified as C<primary>, it searches only on the primary key.
2098
2099 See also L</find> and L</find_or_create>. For information on how to declare
2100 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2101
2102 B<Note>: C<update_or_create> is probably not what you want when
2103 looking for a row in a table that uses primary keys supplied by the
2104 database, unless you actually have a key value. Passing in a primary
2105 key column with a value of I<undef> will cause L</find> to attempt to
2106 search for a row with a value of I<NULL>.
2107
2108 =cut
2109
2110 sub update_or_create {
2111   my $self = shift;
2112   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2113   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2114
2115   my $row = $self->find($cond, $attrs);
2116   if (defined $row) {
2117     $row->update($cond);
2118     return $row;
2119   }
2120
2121   return $self->create($cond);
2122 }
2123
2124 =head2 update_or_new
2125
2126 =over 4
2127
2128 =item Arguments: \%col_values, { key => $unique_constraint }?
2129
2130 =item Return Value: $rowobject
2131
2132 =back
2133
2134   $resultset->update_or_new({ col => $val, ... });
2135
2136 First, searches for an existing row matching one of the unique constraints
2137 (including the primary key) on the source of this resultset. If a row is
2138 found, updates it with the other given column values. Otherwise, instantiate
2139 a new result object and return it. The object will not be saved into your storage
2140 until you call L<DBIx::Class::Row/insert> on it.
2141
2142 Takes an optional C<key> attribute to search on a specific unique constraint.
2143 For example:
2144
2145   # In your application
2146   my $cd = $schema->resultset('CD')->update_or_new(
2147     {
2148       artist => 'Massive Attack',
2149       title  => 'Mezzanine',
2150       year   => 1998,
2151     },
2152     { key => 'cd_artist_title' }
2153   );
2154
2155   if ($cd->in_storage) {
2156       # the cd was updated
2157   }
2158   else {
2159       # the cd is not yet in the database, let's insert it
2160       $cd->insert;
2161   }
2162
2163 See also L</find>, L</find_or_create> and L<find_or_new>.
2164
2165 =cut
2166
2167 sub update_or_new {
2168     my $self  = shift;
2169     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2170     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2171
2172     my $row = $self->find( $cond, $attrs );
2173     if ( defined $row ) {
2174         $row->update($cond);
2175         return $row;
2176     }
2177
2178     return $self->new_result($cond);
2179 }
2180
2181 =head2 get_cache
2182
2183 =over 4
2184
2185 =item Arguments: none
2186
2187 =item Return Value: \@cache_objects?
2188
2189 =back
2190
2191 Gets the contents of the cache for the resultset, if the cache is set.
2192
2193 The cache is populated either by using the L</prefetch> attribute to
2194 L</search> or by calling L</set_cache>.
2195
2196 =cut
2197
2198 sub get_cache {
2199   shift->{all_cache};
2200 }
2201
2202 =head2 set_cache
2203
2204 =over 4
2205
2206 =item Arguments: \@cache_objects
2207
2208 =item Return Value: \@cache_objects
2209
2210 =back
2211
2212 Sets the contents of the cache for the resultset. Expects an arrayref
2213 of objects of the same class as those produced by the resultset. Note that
2214 if the cache is set the resultset will return the cached objects rather
2215 than re-querying the database even if the cache attr is not set.
2216
2217 The contents of the cache can also be populated by using the
2218 L</prefetch> attribute to L</search>.
2219
2220 =cut
2221
2222 sub set_cache {
2223   my ( $self, $data ) = @_;
2224   $self->throw_exception("set_cache requires an arrayref")
2225       if defined($data) && (ref $data ne 'ARRAY');
2226   $self->{all_cache} = $data;
2227 }
2228
2229 =head2 clear_cache
2230
2231 =over 4
2232
2233 =item Arguments: none
2234
2235 =item Return Value: []
2236
2237 =back
2238
2239 Clears the cache for the resultset.
2240
2241 =cut
2242
2243 sub clear_cache {
2244   shift->set_cache(undef);
2245 }
2246
2247 =head2 related_resultset
2248
2249 =over 4
2250
2251 =item Arguments: $relationship_name
2252
2253 =item Return Value: $resultset
2254
2255 =back
2256
2257 Returns a related resultset for the supplied relationship name.
2258
2259   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2260
2261 =cut
2262
2263 sub related_resultset {
2264   my ($self, $rel) = @_;
2265
2266   $self->{related_resultsets} ||= {};
2267   return $self->{related_resultsets}{$rel} ||= do {
2268     my $rel_obj = $self->result_source->relationship_info($rel);
2269
2270     $self->throw_exception(
2271       "search_related: result source '" . $self->result_source->source_name .
2272         "' has no such relationship $rel")
2273       unless $rel_obj;
2274
2275     my ($from,$seen) = $self->_resolve_from($rel);
2276
2277     my $join_count = $seen->{$rel};
2278     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2279
2280     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2281     my %attrs = %{$self->{attrs}||{}};
2282     delete @attrs{qw(result_class alias)};
2283
2284     my $new_cache;
2285
2286     if (my $cache = $self->get_cache) {
2287       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2288         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2289                         @$cache ];
2290       }
2291     }
2292
2293     my $rel_source = $self->result_source->related_source($rel);
2294
2295     my $new = do {
2296
2297       # The reason we do this now instead of passing the alias to the
2298       # search_rs below is that if you wrap/overload resultset on the
2299       # source you need to know what alias it's -going- to have for things
2300       # to work sanely (e.g. RestrictWithObject wants to be able to add
2301       # extra query restrictions, and these may need to be $alias.)
2302
2303       my $attrs = $rel_source->resultset_attributes;
2304       local $attrs->{alias} = $alias;
2305
2306       $rel_source->resultset
2307                  ->search_rs(
2308                      undef, {
2309                        %attrs,
2310                        join => undef,
2311                        prefetch => undef,
2312                        select => undef,
2313                        as => undef,
2314                        where => $self->{cond},
2315                        seen_join => $seen,
2316                        from => $from,
2317                    });
2318     };
2319     $new->set_cache($new_cache) if $new_cache;
2320     $new;
2321   };
2322 }
2323
2324 =head2 current_source_alias
2325
2326 =over 4
2327
2328 =item Arguments: none
2329
2330 =item Return Value: $source_alias
2331
2332 =back
2333
2334 Returns the current table alias for the result source this resultset is built
2335 on, that will be used in the SQL query. Usually it is C<me>.
2336
2337 Currently the source alias that refers to the result set returned by a
2338 L</search>/L</find> family method depends on how you got to the resultset: it's
2339 C<me> by default, but eg. L</search_related> aliases it to the related result
2340 source name (and keeps C<me> referring to the original result set). The long
2341 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2342 (and make this method unnecessary).
2343
2344 Thus it's currently necessary to use this method in predefined queries (see
2345 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2346 source alias of the current result set:
2347
2348   # in a result set class
2349   sub modified_by {
2350     my ($self, $user) = @_;
2351
2352     my $me = $self->current_source_alias;
2353
2354     return $self->search(
2355       "$me.modified" => $user->id,
2356     );
2357   }
2358
2359 =cut
2360
2361 sub current_source_alias {
2362   my ($self) = @_;
2363
2364   return ($self->{attrs} || {})->{alias} || 'me';
2365 }
2366
2367 sub _resolve_from {
2368   my ($self, $extra_join) = @_;
2369   my $source = $self->result_source;
2370   my $attrs = $self->{attrs};
2371
2372   my $from = $attrs->{from}
2373     || [ { $attrs->{alias} => $source->from } ];
2374
2375   my $seen = { %{$attrs->{seen_join}||{}} };
2376
2377   my $join = ($attrs->{join}
2378                ? [ $attrs->{join}, $extra_join ]
2379                : $extra_join);
2380
2381   # we need to take the prefetch the attrs into account before we
2382   # ->resolve_join as otherwise they get lost - captainL
2383   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2384
2385   $from = [
2386     @$from,
2387     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2388   ];
2389
2390   return ($from,$seen);
2391 }
2392
2393 sub _resolved_attrs {
2394   my $self = shift;
2395   return $self->{_attrs} if $self->{_attrs};
2396
2397   my $attrs  = { %{ $self->{attrs} || {} } };
2398   my $source = $self->result_source;
2399   my $alias  = $attrs->{alias};
2400
2401   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2402   my @colbits;
2403
2404   # build columns (as long as select isn't set) into a set of as/select hashes
2405   unless ( $attrs->{select} ) {
2406       @colbits = map {
2407           ( ref($_) eq 'HASH' )
2408               ? $_
2409               : {
2410                   (
2411                     /^\Q${alias}.\E(.+)$/
2412                       ? "$1"
2413                       : "$_"
2414                   )
2415                 =>
2416                   (
2417                     /\./
2418                       ? "$_"
2419                       : "${alias}.$_"
2420                   )
2421             }
2422       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2423   }
2424   # add the additional columns on
2425   foreach ( 'include_columns', '+columns' ) {
2426       push @colbits, map {
2427           ( ref($_) eq 'HASH' )
2428             ? $_
2429             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2430       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2431   }
2432
2433   # start with initial select items
2434   if ( $attrs->{select} ) {
2435     $attrs->{select} =
2436         ( ref $attrs->{select} eq 'ARRAY' )
2437       ? [ @{ $attrs->{select} } ]
2438       : [ $attrs->{select} ];
2439     $attrs->{as} = (
2440       $attrs->{as}
2441       ? (
2442         ref $attrs->{as} eq 'ARRAY'
2443         ? [ @{ $attrs->{as} } ]
2444         : [ $attrs->{as} ]
2445         )
2446       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2447     );
2448   }
2449   else {
2450
2451     # otherwise we intialise select & as to empty
2452     $attrs->{select} = [];
2453     $attrs->{as}     = [];
2454   }
2455
2456   # now add colbits to select/as
2457   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2458   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2459
2460   my $adds;
2461   if ( $adds = delete $attrs->{'+select'} ) {
2462     $adds = [$adds] unless ref $adds eq 'ARRAY';
2463     push(
2464       @{ $attrs->{select} },
2465       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2466     );
2467   }
2468   if ( $adds = delete $attrs->{'+as'} ) {
2469     $adds = [$adds] unless ref $adds eq 'ARRAY';
2470     push( @{ $attrs->{as} }, @$adds );
2471   }
2472
2473   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2474
2475   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2476     my $join = delete $attrs->{join} || {};
2477
2478     if ( defined $attrs->{prefetch} ) {
2479       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2480
2481     }
2482
2483     $attrs->{from} =    # have to copy here to avoid corrupting the original
2484       [
2485       @{ $attrs->{from} },
2486       $source->resolve_join(
2487         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2488       )
2489       ];
2490
2491   }
2492
2493   $attrs->{group_by} ||= $attrs->{select}
2494     if delete $attrs->{distinct};
2495   if ( $attrs->{order_by} ) {
2496     $attrs->{order_by} = (
2497       ref( $attrs->{order_by} ) eq 'ARRAY'
2498       ? [ @{ $attrs->{order_by} } ]
2499       : [ $attrs->{order_by} ]
2500     );
2501   }
2502   else {
2503     $attrs->{order_by} = [];
2504   }
2505
2506   my $collapse = $attrs->{collapse} || {};
2507   if ( my $prefetch = delete $attrs->{prefetch} ) {
2508     $prefetch = $self->_merge_attr( {}, $prefetch );
2509     my @pre_order;
2510     my $seen = { %{ $attrs->{seen_join} || {} } };
2511     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2512
2513       # bring joins back to level of current class
2514       my @prefetch =
2515         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2516       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2517       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2518     }
2519     push( @{ $attrs->{order_by} }, @pre_order );
2520   }
2521   $attrs->{collapse} = $collapse;
2522
2523   if ( $attrs->{page} ) {
2524     $attrs->{offset} ||= 0;
2525     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2526   }
2527
2528   return $self->{_attrs} = $attrs;
2529 }
2530
2531 sub _rollout_attr {
2532   my ($self, $attr) = @_;
2533
2534   if (ref $attr eq 'HASH') {
2535     return $self->_rollout_hash($attr);
2536   } elsif (ref $attr eq 'ARRAY') {
2537     return $self->_rollout_array($attr);
2538   } else {
2539     return [$attr];
2540   }
2541 }
2542
2543 sub _rollout_array {
2544   my ($self, $attr) = @_;
2545
2546   my @rolled_array;
2547   foreach my $element (@{$attr}) {
2548     if (ref $element eq 'HASH') {
2549       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2550     } elsif (ref $element eq 'ARRAY') {
2551       #  XXX - should probably recurse here
2552       push( @rolled_array, @{$self->_rollout_array($element)} );
2553     } else {
2554       push( @rolled_array, $element );
2555     }
2556   }
2557   return \@rolled_array;
2558 }
2559
2560 sub _rollout_hash {
2561   my ($self, $attr) = @_;
2562
2563   my @rolled_array;
2564   foreach my $key (keys %{$attr}) {
2565     push( @rolled_array, { $key => $attr->{$key} } );
2566   }
2567   return \@rolled_array;
2568 }
2569
2570 sub _calculate_score {
2571   my ($self, $a, $b) = @_;
2572
2573   if (ref $b eq 'HASH') {
2574     my ($b_key) = keys %{$b};
2575     if (ref $a eq 'HASH') {
2576       my ($a_key) = keys %{$a};
2577       if ($a_key eq $b_key) {
2578         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2579       } else {
2580         return 0;
2581       }
2582     } else {
2583       return ($a eq $b_key) ? 1 : 0;
2584     }
2585   } else {
2586     if (ref $a eq 'HASH') {
2587       my ($a_key) = keys %{$a};
2588       return ($b eq $a_key) ? 1 : 0;
2589     } else {
2590       return ($b eq $a) ? 1 : 0;
2591     }
2592   }
2593 }
2594
2595 sub _merge_attr {
2596   my ($self, $orig, $import) = @_;
2597
2598   return $import unless defined($orig);
2599   return $orig unless defined($import);
2600
2601   $orig = $self->_rollout_attr($orig);
2602   $import = $self->_rollout_attr($import);
2603
2604   my $seen_keys;
2605   foreach my $import_element ( @{$import} ) {
2606     # find best candidate from $orig to merge $b_element into
2607     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2608     foreach my $orig_element ( @{$orig} ) {
2609       my $score = $self->_calculate_score( $orig_element, $import_element );
2610       if ($score > $best_candidate->{score}) {
2611         $best_candidate->{position} = $position;
2612         $best_candidate->{score} = $score;
2613       }
2614       $position++;
2615     }
2616     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2617
2618     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2619       push( @{$orig}, $import_element );
2620     } else {
2621       my $orig_best = $orig->[$best_candidate->{position}];
2622       # merge orig_best and b_element together and replace original with merged
2623       if (ref $orig_best ne 'HASH') {
2624         $orig->[$best_candidate->{position}] = $import_element;
2625       } elsif (ref $import_element eq 'HASH') {
2626         my ($key) = keys %{$orig_best};
2627         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2628       }
2629     }
2630     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2631   }
2632
2633   return $orig;
2634 }
2635
2636 sub result_source {
2637     my $self = shift;
2638
2639     if (@_) {
2640         $self->_source_handle($_[0]->handle);
2641     } else {
2642         $self->_source_handle->resolve;
2643     }
2644 }
2645
2646 =head2 throw_exception
2647
2648 See L<DBIx::Class::Schema/throw_exception> for details.
2649
2650 =cut
2651
2652 sub throw_exception {
2653   my $self=shift;
2654   if (ref $self && $self->_source_handle->schema) {
2655     $self->_source_handle->schema->throw_exception(@_)
2656   } else {
2657     croak(@_);
2658   }
2659
2660 }
2661
2662 # XXX: FIXME: Attributes docs need clearing up
2663
2664 =head1 ATTRIBUTES
2665
2666 Attributes are used to refine a ResultSet in various ways when
2667 searching for data. They can be passed to any method which takes an
2668 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2669 L</count>.
2670
2671 These are in no particular order:
2672
2673 =head2 order_by
2674
2675 =over 4
2676
2677 =item Value: ( $order_by | \@order_by | \%order_by )
2678
2679 =back
2680
2681 Which column(s) to order the results by. If a single column name, or
2682 an arrayref of names is supplied, the argument is passed through
2683 directly to SQL. The hashref syntax allows for connection-agnostic
2684 specification of ordering direction:
2685
2686  For descending order:
2687
2688   order_by => { -desc => [qw/col1 col2 col3/] }
2689
2690  For explicit ascending order:
2691
2692   order_by => { -asc => 'col' }
2693
2694 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2695 supported, although you are strongly encouraged to use the hashref
2696 syntax as outlined above.
2697
2698 =head2 columns
2699
2700 =over 4
2701
2702 =item Value: \@columns
2703
2704 =back
2705
2706 Shortcut to request a particular set of columns to be retrieved. Each
2707 column spec may be a string (a table column name), or a hash (in which
2708 case the key is the C<as> value, and the value is used as the C<select>
2709 expression). Adds C<me.> onto the start of any column without a C<.> in
2710 it and sets C<select> from that, then auto-populates C<as> from
2711 C<select> as normal. (You may also use the C<cols> attribute, as in
2712 earlier versions of DBIC.)
2713
2714 =head2 +columns
2715
2716 =over 4
2717
2718 =item Value: \@columns
2719
2720 =back
2721
2722 Indicates additional columns to be selected from storage. Works the same
2723 as L</columns> but adds columns to the selection. (You may also use the
2724 C<include_columns> attribute, as in earlier versions of DBIC). For
2725 example:-
2726
2727   $schema->resultset('CD')->search(undef, {
2728     '+columns' => ['artist.name'],
2729     join => ['artist']
2730   });
2731
2732 would return all CDs and include a 'name' column to the information
2733 passed to object inflation. Note that the 'artist' is the name of the
2734 column (or relationship) accessor, and 'name' is the name of the column
2735 accessor in the related table.
2736
2737 =head2 include_columns
2738
2739 =over 4
2740
2741 =item Value: \@columns
2742
2743 =back
2744
2745 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2746
2747 =head2 select
2748
2749 =over 4
2750
2751 =item Value: \@select_columns
2752
2753 =back
2754
2755 Indicates which columns should be selected from the storage. You can use
2756 column names, or in the case of RDBMS back ends, function or stored procedure
2757 names:
2758
2759   $rs = $schema->resultset('Employee')->search(undef, {
2760     select => [
2761       'name',
2762       { count => 'employeeid' },
2763       { sum => 'salary' }
2764     ]
2765   });
2766
2767 When you use function/stored procedure names and do not supply an C<as>
2768 attribute, the column names returned are storage-dependent. E.g. MySQL would
2769 return a column named C<count(employeeid)> in the above example.
2770
2771 =head2 +select
2772
2773 =over 4
2774
2775 Indicates additional columns to be selected from storage.  Works the same as
2776 L</select> but adds columns to the selection.
2777
2778 =back
2779
2780 =head2 +as
2781
2782 =over 4
2783
2784 Indicates additional column names for those added via L</+select>. See L</as>.
2785
2786 =back
2787
2788 =head2 as
2789
2790 =over 4
2791
2792 =item Value: \@inflation_names
2793
2794 =back
2795
2796 Indicates column names for object inflation. That is, C<as>
2797 indicates the name that the column can be accessed as via the
2798 C<get_column> method (or via the object accessor, B<if one already
2799 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2800
2801 The C<as> attribute is used in conjunction with C<select>,
2802 usually when C<select> contains one or more function or stored
2803 procedure names:
2804
2805   $rs = $schema->resultset('Employee')->search(undef, {
2806     select => [
2807       'name',
2808       { count => 'employeeid' }
2809     ],
2810     as => ['name', 'employee_count'],
2811   });
2812
2813   my $employee = $rs->first(); # get the first Employee
2814
2815 If the object against which the search is performed already has an accessor
2816 matching a column name specified in C<as>, the value can be retrieved using
2817 the accessor as normal:
2818
2819   my $name = $employee->name();
2820
2821 If on the other hand an accessor does not exist in the object, you need to
2822 use C<get_column> instead:
2823
2824   my $employee_count = $employee->get_column('employee_count');
2825
2826 You can create your own accessors if required - see
2827 L<DBIx::Class::Manual::Cookbook> for details.
2828
2829 Please note: This will NOT insert an C<AS employee_count> into the SQL
2830 statement produced, it is used for internal access only. Thus
2831 attempting to use the accessor in an C<order_by> clause or similar
2832 will fail miserably.
2833
2834 To get around this limitation, you can supply literal SQL to your
2835 C<select> attibute that contains the C<AS alias> text, eg:
2836
2837   select => [\'myfield AS alias']
2838
2839 =head2 join
2840
2841 =over 4
2842
2843 =item Value: ($rel_name | \@rel_names | \%rel_names)
2844
2845 =back
2846
2847 Contains a list of relationships that should be joined for this query.  For
2848 example:
2849
2850   # Get CDs by Nine Inch Nails
2851   my $rs = $schema->resultset('CD')->search(
2852     { 'artist.name' => 'Nine Inch Nails' },
2853     { join => 'artist' }
2854   );
2855
2856 Can also contain a hash reference to refer to the other relation's relations.
2857 For example:
2858
2859   package MyApp::Schema::Track;
2860   use base qw/DBIx::Class/;
2861   __PACKAGE__->table('track');
2862   __PACKAGE__->add_columns(qw/trackid cd position title/);
2863   __PACKAGE__->set_primary_key('trackid');
2864   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2865   1;
2866
2867   # In your application
2868   my $rs = $schema->resultset('Artist')->search(
2869     { 'track.title' => 'Teardrop' },
2870     {
2871       join     => { cd => 'track' },
2872       order_by => 'artist.name',
2873     }
2874   );
2875
2876 You need to use the relationship (not the table) name in  conditions,
2877 because they are aliased as such. The current table is aliased as "me", so
2878 you need to use me.column_name in order to avoid ambiguity. For example:
2879
2880   # Get CDs from 1984 with a 'Foo' track
2881   my $rs = $schema->resultset('CD')->search(
2882     {
2883       'me.year' => 1984,
2884       'tracks.name' => 'Foo'
2885     },
2886     { join => 'tracks' }
2887   );
2888
2889 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2890 similarly for a third time). For e.g.
2891
2892   my $rs = $schema->resultset('Artist')->search({
2893     'cds.title'   => 'Down to Earth',
2894     'cds_2.title' => 'Popular',
2895   }, {
2896     join => [ qw/cds cds/ ],
2897   });
2898
2899 will return a set of all artists that have both a cd with title 'Down
2900 to Earth' and a cd with title 'Popular'.
2901
2902 If you want to fetch related objects from other tables as well, see C<prefetch>
2903 below.
2904
2905 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2906
2907 =head2 prefetch
2908
2909 =over 4
2910
2911 =item Value: ($rel_name | \@rel_names | \%rel_names)
2912
2913 =back
2914
2915 Contains one or more relationships that should be fetched along with
2916 the main query (when they are accessed afterwards the data will
2917 already be available, without extra queries to the database).  This is
2918 useful for when you know you will need the related objects, because it
2919 saves at least one query:
2920
2921   my $rs = $schema->resultset('Tag')->search(
2922     undef,
2923     {
2924       prefetch => {
2925         cd => 'artist'
2926       }
2927     }
2928   );
2929
2930 The initial search results in SQL like the following:
2931
2932   SELECT tag.*, cd.*, artist.* FROM tag
2933   JOIN cd ON tag.cd = cd.cdid
2934   JOIN artist ON cd.artist = artist.artistid
2935
2936 L<DBIx::Class> has no need to go back to the database when we access the
2937 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2938 case.
2939
2940 Simple prefetches will be joined automatically, so there is no need
2941 for a C<join> attribute in the above search.
2942
2943 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2944 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2945 with an accessor type of 'single' or 'filter'). A more complex example that
2946 prefetches an artists cds, the tracks on those cds, and the tags associted
2947 with that artist is given below (assuming many-to-many from artists to tags):
2948
2949  my $rs = $schema->resultset('Artist')->search(
2950    undef,
2951    {
2952      prefetch => [
2953        { cds => 'tracks' },
2954        { artist_tags => 'tags' }
2955      ]
2956    }
2957  );
2958
2959
2960 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2961 attributes will be ignored.
2962
2963 =head2 page
2964
2965 =over 4
2966
2967 =item Value: $page
2968
2969 =back
2970
2971 Makes the resultset paged and specifies the page to retrieve. Effectively
2972 identical to creating a non-pages resultset and then calling ->page($page)
2973 on it.
2974
2975 If L<rows> attribute is not specified it defualts to 10 rows per page.
2976
2977 When you have a paged resultset, L</count> will only return the number
2978 of rows in the page. To get the total, use the L</pager> and call
2979 C<total_entries> on it.
2980
2981 =head2 rows
2982
2983 =over 4
2984
2985 =item Value: $rows
2986
2987 =back
2988
2989 Specifes the maximum number of rows for direct retrieval or the number of
2990 rows per page if the page attribute or method is used.
2991
2992 =head2 offset
2993
2994 =over 4
2995
2996 =item Value: $offset
2997
2998 =back
2999
3000 Specifies the (zero-based) row number for the  first row to be returned, or the
3001 of the first row of the first page if paging is used.
3002
3003 =head2 group_by
3004
3005 =over 4
3006
3007 =item Value: \@columns
3008
3009 =back
3010
3011 A arrayref of columns to group by. Can include columns of joined tables.
3012
3013   group_by => [qw/ column1 column2 ... /]
3014
3015 =head2 having
3016
3017 =over 4
3018
3019 =item Value: $condition
3020
3021 =back
3022
3023 HAVING is a select statement attribute that is applied between GROUP BY and
3024 ORDER BY. It is applied to the after the grouping calculations have been
3025 done.
3026
3027   having => { 'count(employee)' => { '>=', 100 } }
3028
3029 =head2 distinct
3030
3031 =over 4
3032
3033 =item Value: (0 | 1)
3034
3035 =back
3036
3037 Set to 1 to group by all columns.
3038
3039 =head2 where
3040
3041 =over 4
3042
3043 Adds to the WHERE clause.
3044
3045   # only return rows WHERE deleted IS NULL for all searches
3046   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3047
3048 Can be overridden by passing C<{ where => undef }> as an attribute
3049 to a resulset.
3050
3051 =back
3052
3053 =head2 cache
3054
3055 Set to 1 to cache search results. This prevents extra SQL queries if you
3056 revisit rows in your ResultSet:
3057
3058   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3059
3060   while( my $artist = $resultset->next ) {
3061     ... do stuff ...
3062   }
3063
3064   $rs->first; # without cache, this would issue a query
3065
3066 By default, searches are not cached.
3067
3068 For more examples of using these attributes, see
3069 L<DBIx::Class::Manual::Cookbook>.
3070
3071 =head2 from
3072
3073 =over 4
3074
3075 =item Value: \@from_clause
3076
3077 =back
3078
3079 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3080 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3081 clauses.
3082
3083 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3084
3085 C<join> will usually do what you need and it is strongly recommended that you
3086 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3087 And we really do mean "cannot", not just tried and failed. Attempting to use
3088 this because you're having problems with C<join> is like trying to use x86
3089 ASM because you've got a syntax error in your C. Trust us on this.
3090
3091 Now, if you're still really, really sure you need to use this (and if you're
3092 not 100% sure, ask the mailing list first), here's an explanation of how this
3093 works.
3094
3095 The syntax is as follows -
3096
3097   [
3098     { <alias1> => <table1> },
3099     [
3100       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3101       [], # nested JOIN (optional)
3102       { <table1.column1> => <table2.column2>, ... (more conditions) },
3103     ],
3104     # More of the above [ ] may follow for additional joins
3105   ]
3106
3107   <table1> <alias1>
3108   JOIN
3109     <table2> <alias2>
3110     [JOIN ...]
3111   ON <table1.column1> = <table2.column2>
3112   <more joins may follow>
3113
3114 An easy way to follow the examples below is to remember the following:
3115
3116     Anything inside "[]" is a JOIN
3117     Anything inside "{}" is a condition for the enclosing JOIN
3118
3119 The following examples utilize a "person" table in a family tree application.
3120 In order to express parent->child relationships, this table is self-joined:
3121
3122     # Person->belongs_to('father' => 'Person');
3123     # Person->belongs_to('mother' => 'Person');
3124
3125 C<from> can be used to nest joins. Here we return all children with a father,
3126 then search against all mothers of those children:
3127
3128   $rs = $schema->resultset('Person')->search(
3129       undef,
3130       {
3131           alias => 'mother', # alias columns in accordance with "from"
3132           from => [
3133               { mother => 'person' },
3134               [
3135                   [
3136                       { child => 'person' },
3137                       [
3138                           { father => 'person' },
3139                           { 'father.person_id' => 'child.father_id' }
3140                       ]
3141                   ],
3142                   { 'mother.person_id' => 'child.mother_id' }
3143               ],
3144           ]
3145       },
3146   );
3147
3148   # Equivalent SQL:
3149   # SELECT mother.* FROM person mother
3150   # JOIN (
3151   #   person child
3152   #   JOIN person father
3153   #   ON ( father.person_id = child.father_id )
3154   # )
3155   # ON ( mother.person_id = child.mother_id )
3156
3157 The type of any join can be controlled manually. To search against only people
3158 with a father in the person table, we could explicitly use C<INNER JOIN>:
3159
3160     $rs = $schema->resultset('Person')->search(
3161         undef,
3162         {
3163             alias => 'child', # alias columns in accordance with "from"
3164             from => [
3165                 { child => 'person' },
3166                 [
3167                     { father => 'person', -join_type => 'inner' },
3168                     { 'father.id' => 'child.father_id' }
3169                 ],
3170             ]
3171         },
3172     );
3173
3174     # Equivalent SQL:
3175     # SELECT child.* FROM person child
3176     # INNER JOIN person father ON child.father_id = father.id
3177
3178 If you need to express really complex joins or you need a subselect, you
3179 can supply literal SQL to C<from> via a scalar reference. In this case
3180 the contents of the scalar will replace the table name asscoiated with the
3181 resultsource.
3182
3183 WARNING: This technique might very well not work as expected on chained
3184 searches - you have been warned.
3185
3186     # Assuming the Event resultsource is defined as:
3187
3188         MySchema::Event->add_columns (
3189             sequence => {
3190                 data_type => 'INT',
3191                 is_auto_increment => 1,
3192             },
3193             location => {
3194                 data_type => 'INT',
3195             },
3196             type => {
3197                 data_type => 'INT',
3198             },
3199         );
3200         MySchema::Event->set_primary_key ('sequence');
3201
3202     # This will get back the latest event for every location. The column
3203     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3204     # combo to limit the resultset
3205
3206     $rs = $schema->resultset('Event');
3207     $table = $rs->result_source->name;
3208     $latest = $rs->search (
3209         undef,
3210         { from => \ "
3211             (SELECT e1.* FROM $table e1
3212                 JOIN $table e2
3213                     ON e1.location = e2.location
3214                     AND e1.sequence < e2.sequence
3215                 WHERE e2.sequence is NULL
3216             ) me",
3217         },
3218     );
3219
3220     # Equivalent SQL (with the DBIC chunks added):
3221
3222     SELECT me.sequence, me.location, me.type FROM
3223        (SELECT e1.* FROM events e1
3224            JOIN events e2
3225                ON e1.location = e2.location
3226                AND e1.sequence < e2.sequence
3227            WHERE e2.sequence is NULL
3228        ) me;
3229
3230 =head2 for
3231
3232 =over 4
3233
3234 =item Value: ( 'update' | 'shared' )
3235
3236 =back
3237
3238 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3239 ... FOR SHARED.
3240
3241 =cut
3242
3243 1;