lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use DBIx::Class::Exception;
   8 use Data::Page;
   9 use Storable;
  10 use DBIx::Class::ResultSetColumn;
  11 use DBIx::Class::ResultSourceHandle;
  12 use List::Util ();
  13 use Scalar::Util qw/blessed weaken/;
  14 use Try::Tiny;
  15 use namespace::clean;
  16
  17 use overload
  18         '0+'     => "count",
  19         'bool'   => "_bool",
  20         fallback => 1;
  21
  22 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  23
  24 =head1 NAME
  25
  26 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  27
  28 =head1 SYNOPSIS
  29
  30   my $users_rs   = $schema->resultset('User');
  31   while( $user = $users_rs->next) {
  32     print $user->username;
  33   }
  34
  35   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  36   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  37
  38 =head1 DESCRIPTION
  39
  40 A ResultSet is an object which stores a set of conditions representing
  41 a query. It is the backbone of DBIx::Class (i.e. the really
  42 important/useful bit).
  43
  44 No SQL is executed on the database when a ResultSet is created, it
  45 just stores all the conditions needed to create the query.
  46
  47 A basic ResultSet representing the data of an entire table is returned
  48 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  49 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  50
  51   my $users_rs = $schema->resultset('User');
  52
  53 A new ResultSet is returned from calling L</search> on an existing
  54 ResultSet. The new one will contain all the conditions of the
  55 original, plus any new conditions added in the C<search> call.
  56
  57 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  58 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  59 represents.
  60
  61 The query that the ResultSet represents is B<only> executed against
  62 the database when these methods are called:
  63 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  64
  65 If a resultset is used in a numeric context it returns the L</count>.
  66 However, if it is used in a boolean context it is B<always> true.  So if
  67 you want to check if a resultset has any results, you must use C<if $rs
  68 != 0>.
  69
  70 =head1 EXAMPLES
  71
  72 =head2 Chaining resultsets
  73
  74 Let's say you've got a query that needs to be run to return some data
  75 to the user. But, you have an authorization system in place that
  76 prevents certain users from seeing certain information. So, you want
  77 to construct the basic query in one method, but add constraints to it in
  78 another.
  79
  80   sub get_data {
  81     my $self = shift;
  82     my $request = $self->get_request; # Get a request object somehow.
  83     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  84
  85     my $cd_rs = $schema->resultset('CD')->search({
  86       title => $request->param('title'),
  87       year => $request->param('year'),
  88     });
  89
  90     $self->apply_security_policy( $cd_rs );
  91
  92     return $cd_rs->all();
  93   }
  94
  95   sub apply_security_policy {
  96     my $self = shift;
  97     my ($rs) = @_;
  98
  99     return $rs->search({
 100       subversive => 0,
 101     });
 102   }
 103
 104 =head3 Resolving conditions and attributes
 105
 106 When a resultset is chained from another resultset, conditions and
 107 attributes with the same keys need resolving.
 108
 109 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 110 into the existing ones from the original resultset.
 111
 112 The L</where> and L</having> attributes, and any search conditions, are
 113 merged with an SQL C<AND> to the existing condition from the original
 114 resultset.
 115
 116 All other attributes are overridden by any new ones supplied in the
 117 search attributes.
 118
 119 =head2 Multiple queries
 120
 121 Since a resultset just defines a query, you can do all sorts of
 122 things with it with the same object.
 123
 124   # Don't hit the DB yet.
 125   my $cd_rs = $schema->resultset('CD')->search({
 126     title => 'something',
 127     year => 2009,
 128   });
 129
 130   # Each of these hits the DB individually.
 131   my $count = $cd_rs->count;
 132   my $most_recent = $cd_rs->get_column('date_released')->max();
 133   my @records = $cd_rs->all;
 134
 135 And it's not just limited to SELECT statements.
 136
 137   $cd_rs->delete();
 138
 139 This is even cooler:
 140
 141   $cd_rs->create({ artist => 'Fred' });
 142
 143 Which is the same as:
 144
 145   $schema->resultset('CD')->create({
 146     title => 'something',
 147     year => 2009,
 148     artist => 'Fred'
 149   });
 150
 151 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 152
 153 =head1 METHODS
 154
 155 =head2 new
 156
 157 =over 4
 158
 159 =item Arguments: $source, \%$attrs
 160
 161 =item Return Value: $rs
 162
 163 =back
 164
 165 The resultset constructor. Takes a source object (usually a
 166 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 167 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 168 executed as needed by the other methods.
 169
 170 Generally you won't need to construct a resultset manually.  You'll
 171 automatically get one from e.g. a L</search> called in scalar context:
 172
 173   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 174
 175 IMPORTANT: If called on an object, proxies to new_result instead so
 176
 177   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 178
 179 will return a CD object, not a ResultSet.
 180
 181 =cut
 182
 183 sub new {
 184   my $class = shift;
 185   return $class->new_result(@_) if ref $class;
 186
 187   my ($source, $attrs) = @_;
 188   $source = $source->handle
 189     unless $source->isa('DBIx::Class::ResultSourceHandle');
 190   $attrs = { %{$attrs||{}} };
 191
 192   if ($attrs->{page}) {
 193     $attrs->{rows} ||= 10;
 194   }
 195
 196   $attrs->{alias} ||= 'me';
 197
 198   # Creation of {} and bless separated to mitigate RH perl bug
 199   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 200   my $self = {
 201     _source_handle => $source,
 202     cond => $attrs->{where},
 203     pager => undef,
 204     attrs => $attrs
 205   };
 206
 207   bless $self, $class;
 208
 209   $self->result_class(
 210     $attrs->{result_class} || $source->resolve->result_class
 211   );
 212
 213   return $self;
 214 }
 215
 216 =head2 search
 217
 218 =over 4
 219
 220 =item Arguments: $cond, \%attrs?
 221
 222 =item Return Value: $resultset (scalar context), @row_objs (list context)
 223
 224 =back
 225
 226   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 227   my $new_rs = $cd_rs->search({ year => 2005 });
 228
 229   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 230                  # year = 2005 OR year = 2004
 231
 232 If you need to pass in additional attributes but no additional condition,
 233 call it as C<search(undef, \%attrs)>.
 234
 235   # "SELECT name, artistid FROM $artist_table"
 236   my @all_artists = $schema->resultset('Artist')->search(undef, {
 237     columns => [qw/name artistid/],
 238   });
 239
 240 For a list of attributes that can be passed to C<search>, see
 241 L</ATTRIBUTES>. For more examples of using this function, see
 242 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 243 documentation for the first argument, see L<SQL::Abstract>.
 244
 245 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 246
 247 =cut
 248
 249 sub search {
 250   my $self = shift;
 251   my $rs = $self->search_rs( @_ );
 252   return (wantarray ? $rs->all : $rs);
 253 }
 254
 255 =head2 search_rs
 256
 257 =over 4
 258
 259 =item Arguments: $cond, \%attrs?
 260
 261 =item Return Value: $resultset
 262
 263 =back
 264
 265 This method does the same exact thing as search() except it will
 266 always return a resultset, even in list context.
 267
 268 =cut
 269
 270 sub search_rs {
 271   my $self = shift;
 272
 273   # Special-case handling for (undef, undef).
 274   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 275     pop(@_); pop(@_);
 276   }
 277
 278   my $attrs = {};
 279   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 280   my $our_attrs = { %{$self->{attrs}} };
 281   my $having = delete $our_attrs->{having};
 282   my $where = delete $our_attrs->{where};
 283
 284   my $rows;
 285
 286   my %safe = (alias => 1, cache => 1);
 287
 288   unless (
 289     (@_ && defined($_[0])) # @_ == () or (undef)
 290     ||
 291     (keys %$attrs # empty attrs or only 'safe' attrs
 292     && List::Util::first { !$safe{$_} } keys %$attrs)
 293   ) {
 294     # no search, effectively just a clone
 295     $rows = $self->get_cache;
 296   }
 297
 298   # reset the selector list
 299   if (List::Util::first { exists $attrs->{$_} } qw{columns select as}) {
 300      delete @{$our_attrs}{qw{select as columns +select +as +columns include_columns}};
 301   }
 302
 303   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 304
 305   # merge new attrs into inherited
 306   foreach my $key (qw/join prefetch +select +as +columns include_columns bind/) {
 307     next unless exists $attrs->{$key};
 308     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 309   }
 310
 311   my $cond = (@_
 312     ? (
 313         (@_ == 1 || ref $_[0] eq "HASH")
 314           ? (
 315               (ref $_[0] eq 'HASH')
 316                 ? (
 317                     (keys %{ $_[0] }  > 0)
 318                       ? shift
 319                       : undef
 320                    )
 321                 :  shift
 322              )
 323           : (
 324               (@_ % 2)
 325                 ? $self->throw_exception("Odd number of arguments to search")
 326                 : {@_}
 327              )
 328       )
 329     : undef
 330   );
 331
 332   if (defined $where) {
 333     $new_attrs->{where} = (
 334       defined $new_attrs->{where}
 335         ? { '-and' => [
 336               map {
 337                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 338               } $where, $new_attrs->{where}
 339             ]
 340           }
 341         : $where);
 342   }
 343
 344   if (defined $cond) {
 345     $new_attrs->{where} = (
 346       defined $new_attrs->{where}
 347         ? { '-and' => [
 348               map {
 349                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 350               } $cond, $new_attrs->{where}
 351             ]
 352           }
 353         : $cond);
 354   }
 355
 356   if (defined $having) {
 357     $new_attrs->{having} = (
 358       defined $new_attrs->{having}
 359         ? { '-and' => [
 360               map {
 361                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 362               } $having, $new_attrs->{having}
 363             ]
 364           }
 365         : $having);
 366   }
 367
 368   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 369
 370   $rs->set_cache($rows) if ($rows);
 371
 372   return $rs;
 373 }
 374
 375 =head2 search_literal
 376
 377 =over 4
 378
 379 =item Arguments: $sql_fragment, @bind_values
 380
 381 =item Return Value: $resultset (scalar context), @row_objs (list context)
 382
 383 =back
 384
 385   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 386   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 387
 388 Pass a literal chunk of SQL to be added to the conditional part of the
 389 resultset query.
 390
 391 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 392 only be used in that context. C<search_literal> is a convenience method.
 393 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 394 columns are bound correctly, use C<search>.
 395
 396 Example of how to use C<search> instead of C<search_literal>
 397
 398   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 399   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 400
 401
 402 See L<DBIx::Class::Manual::Cookbook/Searching> and
 403 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 404 require C<search_literal>.
 405
 406 =cut
 407
 408 sub search_literal {
 409   my ($self, $sql, @bind) = @_;
 410   my $attr;
 411   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 412     $attr = pop @bind;
 413   }
 414   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 415 }
 416
 417 =head2 find
 418
 419 =over 4
 420
 421 =item Arguments: @values | \%cols, \%attrs?
 422
 423 =item Return Value: $row_object | undef
 424
 425 =back
 426
 427 Finds a row based on its primary key or unique constraint. For example, to find
 428 a row by its primary key:
 429
 430   my $cd = $schema->resultset('CD')->find(5);
 431
 432 You can also find a row by a specific unique constraint using the C<key>
 433 attribute. For example:
 434
 435   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 436     key => 'cd_artist_title'
 437   });
 438
 439 Additionally, you can specify the columns explicitly by name:
 440
 441   my $cd = $schema->resultset('CD')->find(
 442     {
 443       artist => 'Massive Attack',
 444       title  => 'Mezzanine',
 445     },
 446     { key => 'cd_artist_title' }
 447   );
 448
 449 If the C<key> is specified as C<primary>, it searches only on the primary key.
 450
 451 If no C<key> is specified, it searches on all unique constraints defined on the
 452 source for which column data is provided, including the primary key.
 453
 454 If your table does not have a primary key, you B<must> provide a value for the
 455 C<key> attribute matching one of the unique constraints on the source.
 456
 457 In addition to C<key>, L</find> recognizes and applies standard
 458 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 459
 460 Note: If your query does not return only one row, a warning is generated:
 461
 462   Query returned more than one row
 463
 464 See also L</find_or_create> and L</update_or_create>. For information on how to
 465 declare unique constraints, see
 466 L<DBIx::Class::ResultSource/add_unique_constraint>.
 467
 468 =cut
 469
 470 sub find {
 471   my $self = shift;
 472   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 473
 474   # Default to the primary key, but allow a specific key
 475   my @cols = exists $attrs->{key}
 476     ? $self->result_source->unique_constraint_columns($attrs->{key})
 477     : $self->result_source->primary_columns;
 478   $self->throw_exception(
 479     "Can't find unless a primary key is defined or unique constraint is specified"
 480   ) unless @cols;
 481
 482   # Parse out a hashref from input
 483   my $input_query;
 484   if (ref $_[0] eq 'HASH') {
 485     $input_query = { %{$_[0]} };
 486   }
 487   elsif (@_ == @cols) {
 488     $input_query = {};
 489     @{$input_query}{@cols} = @_;
 490   }
 491   else {
 492     # Compatibility: Allow e.g. find(id => $value)
 493     carp "Find by key => value deprecated; please use a hashref instead";
 494     $input_query = {@_};
 495   }
 496
 497   my (%related, $info);
 498
 499   KEY: foreach my $key (keys %$input_query) {
 500     if (ref($input_query->{$key})
 501         && ($info = $self->result_source->relationship_info($key))) {
 502       my $val = delete $input_query->{$key};
 503       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 504       my $rel_q = $self->result_source->_resolve_condition(
 505                     $info->{cond}, $val, $key
 506                   );
 507       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 508       @related{keys %$rel_q} = values %$rel_q;
 509     }
 510   }
 511   if (my @keys = keys %related) {
 512     @{$input_query}{@keys} = values %related;
 513   }
 514
 515
 516   # Build the final query: Default to the disjunction of the unique queries,
 517   # but allow the input query in case the ResultSet defines the query or the
 518   # user is abusing find
 519   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 520   my $query;
 521   if (exists $attrs->{key}) {
 522     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 523     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 524     $query = $self->_add_alias($unique_query, $alias);
 525   }
 526   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 527     # This means that we got here after a merger of relationship conditions
 528     # in ::Relationship::Base::search_related (the row method), and furthermore
 529     # the relationship is of the 'single' type. This means that the condition
 530     # provided by the relationship (already attached to $self) is sufficient,
 531     # as there can be only one row in the database that would satisfy the
 532     # relationship
 533   }
 534   else {
 535     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 536     $query = @unique_queries
 537       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 538       : $self->_add_alias($input_query, $alias);
 539   }
 540
 541   # Run the query, passing the result_class since it should propagate for find
 542   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 543   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 544     my $row = $rs->next;
 545     carp "Query returned more than one row" if $rs->next;
 546     return $row;
 547   }
 548   else {
 549     return $rs->single;
 550   }
 551 }
 552
 553 # _add_alias
 554 #
 555 # Add the specified alias to the specified query hash. A copy is made so the
 556 # original query is not modified.
 557
 558 sub _add_alias {
 559   my ($self, $query, $alias) = @_;
 560
 561   my %aliased = %$query;
 562   foreach my $col (grep { ! m/\./ } keys %aliased) {
 563     $aliased{"$alias.$col"} = delete $aliased{$col};
 564   }
 565
 566   return \%aliased;
 567 }
 568
 569 # _unique_queries
 570 #
 571 # Build a list of queries which satisfy unique constraints.
 572
 573 sub _unique_queries {
 574   my ($self, $query, $attrs) = @_;
 575
 576   my @constraint_names = exists $attrs->{key}
 577     ? ($attrs->{key})
 578     : $self->result_source->unique_constraint_names;
 579
 580   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 581   my $num_where = scalar keys %$where;
 582
 583   my (@unique_queries, %seen_column_combinations);
 584   foreach my $name (@constraint_names) {
 585     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 586
 587     my $constraint_sig = join "\x00", sort @constraint_cols;
 588     next if $seen_column_combinations{$constraint_sig}++;
 589
 590     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 591
 592     my $num_cols = scalar @constraint_cols;
 593     my $num_query = scalar keys %$unique_query;
 594
 595     my $total = $num_query + $num_where;
 596     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 597       # The query is either unique on its own or is unique in combination with
 598       # the existing where clause
 599       push @unique_queries, $unique_query;
 600     }
 601   }
 602
 603   return @unique_queries;
 604 }
 605
 606 # _build_unique_query
 607 #
 608 # Constrain the specified query hash based on the specified column names.
 609
 610 sub _build_unique_query {
 611   my ($self, $query, $unique_cols) = @_;
 612
 613   return {
 614     map  { $_ => $query->{$_} }
 615     grep { exists $query->{$_} }
 616       @$unique_cols
 617   };
 618 }
 619
 620 =head2 search_related
 621
 622 =over 4
 623
 624 =item Arguments: $rel, $cond, \%attrs?
 625
 626 =item Return Value: $new_resultset
 627
 628 =back
 629
 630   $new_rs = $cd_rs->search_related('artist', {
 631     name => 'Emo-R-Us',
 632   });
 633
 634 Searches the specified relationship, optionally specifying a condition and
 635 attributes for matching records. See L</ATTRIBUTES> for more information.
 636
 637 =cut
 638
 639 sub search_related {
 640   return shift->related_resultset(shift)->search(@_);
 641 }
 642
 643 =head2 search_related_rs
 644
 645 This method works exactly the same as search_related, except that
 646 it guarantees a resultset, even in list context.
 647
 648 =cut
 649
 650 sub search_related_rs {
 651   return shift->related_resultset(shift)->search_rs(@_);
 652 }
 653
 654 =head2 cursor
 655
 656 =over 4
 657
 658 =item Arguments: none
 659
 660 =item Return Value: $cursor
 661
 662 =back
 663
 664 Returns a storage-driven cursor to the given resultset. See
 665 L<DBIx::Class::Cursor> for more information.
 666
 667 =cut
 668
 669 sub cursor {
 670   my ($self) = @_;
 671
 672   my $attrs = $self->_resolved_attrs_copy;
 673
 674   return $self->{cursor}
 675     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 676           $attrs->{where},$attrs);
 677 }
 678
 679 =head2 single
 680
 681 =over 4
 682
 683 =item Arguments: $cond?
 684
 685 =item Return Value: $row_object | undef
 686
 687 =back
 688
 689   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 690
 691 Inflates the first result without creating a cursor if the resultset has
 692 any records in it; if not returns C<undef>. Used by L</find> as a lean version
 693 of L</search>.
 694
 695 While this method can take an optional search condition (just like L</search>)
 696 being a fast-code-path it does not recognize search attributes. If you need to
 697 add extra joins or similar, call L</search> and then chain-call L</single> on the
 698 L<DBIx::Class::ResultSet> returned.
 699
 700 =over
 701
 702 =item B<Note>
 703
 704 As of 0.08100, this method enforces the assumption that the preceding
 705 query returns only one row. If more than one row is returned, you will receive
 706 a warning:
 707
 708   Query returned more than one row
 709
 710 In this case, you should be using L</next> or L</find> instead, or if you really
 711 know what you are doing, use the L</rows> attribute to explicitly limit the size
 712 of the resultset.
 713
 714 This method will also throw an exception if it is called on a resultset prefetching
 715 has_many, as such a prefetch implies fetching multiple rows from the database in
 716 order to assemble the resulting object.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = $self->_resolved_attrs_copy;
 729
 730   if (keys %{$attrs->{collapse}}) {
 731     $self->throw_exception(
 732       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 733     );
 734   }
 735
 736   if ($where) {
 737     if (defined $attrs->{where}) {
 738       $attrs->{where} = {
 739         '-and' =>
 740             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 741                $where, delete $attrs->{where} ]
 742       };
 743     } else {
 744       $attrs->{where} = $where;
 745     }
 746   }
 747
 748 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 749 #  unless ($self->_is_unique_query($attrs->{where})) {
 750 #    carp "Query not guaranteed to return a single row"
 751 #      . "; please declare your unique constraints or use search instead";
 752 #  }
 753
 754   my @data = $self->result_source->storage->select_single(
 755     $attrs->{from}, $attrs->{select},
 756     $attrs->{where}, $attrs
 757   );
 758
 759   return (@data ? ($self->_construct_object(@data))[0] : undef);
 760 }
 761
 762
 763 # _is_unique_query
 764 #
 765 # Try to determine if the specified query is guaranteed to be unique, based on
 766 # the declared unique constraints.
 767
 768 sub _is_unique_query {
 769   my ($self, $query) = @_;
 770
 771   my $collapsed = $self->_collapse_query($query);
 772   my $alias = $self->{attrs}{alias};
 773
 774   foreach my $name ($self->result_source->unique_constraint_names) {
 775     my @unique_cols = map {
 776       "$alias.$_"
 777     } $self->result_source->unique_constraint_columns($name);
 778
 779     # Count the values for each unique column
 780     my %seen = map { $_ => 0 } @unique_cols;
 781
 782     foreach my $key (keys %$collapsed) {
 783       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 784       next unless exists $seen{$aliased};  # Additional constraints are okay
 785       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 786     }
 787
 788     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 789     return 1 unless grep { $_ != 1 } values %seen;
 790   }
 791
 792   return 0;
 793 }
 794
 795 # _collapse_query
 796 #
 797 # Recursively collapse the query, accumulating values for each column.
 798
 799 sub _collapse_query {
 800   my ($self, $query, $collapsed) = @_;
 801
 802   $collapsed ||= {};
 803
 804   if (ref $query eq 'ARRAY') {
 805     foreach my $subquery (@$query) {
 806       next unless ref $subquery;  # -or
 807       $collapsed = $self->_collapse_query($subquery, $collapsed);
 808     }
 809   }
 810   elsif (ref $query eq 'HASH') {
 811     if (keys %$query and (keys %$query)[0] eq '-and') {
 812       foreach my $subquery (@{$query->{-and}}) {
 813         $collapsed = $self->_collapse_query($subquery, $collapsed);
 814       }
 815     }
 816     else {
 817       foreach my $col (keys %$query) {
 818         my $value = $query->{$col};
 819         $collapsed->{$col}{$value}++;
 820       }
 821     }
 822   }
 823
 824   return $collapsed;
 825 }
 826
 827 =head2 get_column
 828
 829 =over 4
 830
 831 =item Arguments: $cond?
 832
 833 =item Return Value: $resultsetcolumn
 834
 835 =back
 836
 837   my $max_length = $rs->get_column('length')->max;
 838
 839 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 840
 841 =cut
 842
 843 sub get_column {
 844   my ($self, $column) = @_;
 845   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 846   return $new;
 847 }
 848
 849 =head2 search_like
 850
 851 =over 4
 852
 853 =item Arguments: $cond, \%attrs?
 854
 855 =item Return Value: $resultset (scalar context), @row_objs (list context)
 856
 857 =back
 858
 859   # WHERE title LIKE '%blue%'
 860   $cd_rs = $rs->search_like({ title => '%blue%'});
 861
 862 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 863 that this is simply a convenience method retained for ex Class::DBI users.
 864 You most likely want to use L</search> with specific operators.
 865
 866 For more information, see L<DBIx::Class::Manual::Cookbook>.
 867
 868 This method is deprecated and will be removed in 0.09. Use L</search()>
 869 instead. An example conversion is:
 870
 871   ->search_like({ foo => 'bar' });
 872
 873   # Becomes
 874
 875   ->search({ foo => { like => 'bar' } });
 876
 877 =cut
 878
 879 sub search_like {
 880   my $class = shift;
 881   carp (
 882     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 883    .' Instead use ->search({ x => { -like => "y%" } })'
 884    .' (note the outer pair of {}s - they are important!)'
 885   );
 886   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 887   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 888   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 889   return $class->search($query, { %$attrs });
 890 }
 891
 892 =head2 slice
 893
 894 =over 4
 895
 896 =item Arguments: $first, $last
 897
 898 =item Return Value: $resultset (scalar context), @row_objs (list context)
 899
 900 =back
 901
 902 Returns a resultset or object list representing a subset of elements from the
 903 resultset slice is called on. Indexes are from 0, i.e., to get the first
 904 three records, call:
 905
 906   my ($one, $two, $three) = $rs->slice(0, 2);
 907
 908 =cut
 909
 910 sub slice {
 911   my ($self, $min, $max) = @_;
 912   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 913   $attrs->{offset} = $self->{attrs}{offset} || 0;
 914   $attrs->{offset} += $min;
 915   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 916   return $self->search(undef, $attrs);
 917   #my $slice = (ref $self)->new($self->result_source, $attrs);
 918   #return (wantarray ? $slice->all : $slice);
 919 }
 920
 921 =head2 next
 922
 923 =over 4
 924
 925 =item Arguments: none
 926
 927 =item Return Value: $result | undef
 928
 929 =back
 930
 931 Returns the next element in the resultset (C<undef> is there is none).
 932
 933 Can be used to efficiently iterate over records in the resultset:
 934
 935   my $rs = $schema->resultset('CD')->search;
 936   while (my $cd = $rs->next) {
 937     print $cd->title;
 938   }
 939
 940 Note that you need to store the resultset object, and call C<next> on it.
 941 Calling C<< resultset('Table')->next >> repeatedly will always return the
 942 first record from the resultset.
 943
 944 =cut
 945
 946 sub next {
 947   my ($self) = @_;
 948   if (my $cache = $self->get_cache) {
 949     $self->{all_cache_position} ||= 0;
 950     return $cache->[$self->{all_cache_position}++];
 951   }
 952   if ($self->{attrs}{cache}) {
 953     delete $self->{pager};
 954     $self->{all_cache_position} = 1;
 955     return ($self->all)[0];
 956   }
 957   if ($self->{stashed_objects}) {
 958     my $obj = shift(@{$self->{stashed_objects}});
 959     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 960     return $obj;
 961   }
 962   my @row = (
 963     exists $self->{stashed_row}
 964       ? @{delete $self->{stashed_row}}
 965       : $self->cursor->next
 966   );
 967   return undef unless (@row);
 968   my ($row, @more) = $self->_construct_object(@row);
 969   $self->{stashed_objects} = \@more if @more;
 970   return $row;
 971 }
 972
 973 sub _construct_object {
 974   my ($self, @row) = @_;
 975
 976   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 977     or return ();
 978   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 979   @new = $self->{_attrs}{record_filter}->(@new)
 980     if exists $self->{_attrs}{record_filter};
 981   return @new;
 982 }
 983
 984 sub _collapse_result {
 985   my ($self, $as_proto, $row) = @_;
 986
 987   my @copy = @$row;
 988
 989   # 'foo'         => [ undef, 'foo' ]
 990   # 'foo.bar'     => [ 'foo', 'bar' ]
 991   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 992
 993   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 994
 995   my %collapse = %{$self->{_attrs}{collapse}||{}};
 996
 997   my @pri_index;
 998
 999   # if we're doing collapsing (has_many prefetch) we need to grab records
1000   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1001   # we know we don't have to bother.
1002
1003   # the reason for not using the collapse stuff directly is because if you
1004   # had for e.g. two artists in a row with no cds, the collapse info for
1005   # both would be NULL (undef) so you'd lose the second artist
1006
1007   # store just the index so we can check the array positions from the row
1008   # without having to contruct the full hash
1009
1010   if (keys %collapse) {
1011     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1012     foreach my $i (0 .. $#construct_as) {
1013       next if defined($construct_as[$i][0]); # only self table
1014       if (delete $pri{$construct_as[$i][1]}) {
1015         push(@pri_index, $i);
1016       }
1017       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1018     }
1019   }
1020
1021   # no need to do an if, it'll be empty if @pri_index is empty anyway
1022
1023   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1024
1025   my @const_rows;
1026
1027   do { # no need to check anything at the front, we always want the first row
1028
1029     my %const;
1030
1031     foreach my $this_as (@construct_as) {
1032       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1033     }
1034
1035     push(@const_rows, \%const);
1036
1037   } until ( # no pri_index => no collapse => drop straight out
1038       !@pri_index
1039     or
1040       do { # get another row, stash it, drop out if different PK
1041
1042         @copy = $self->cursor->next;
1043         $self->{stashed_row} = \@copy;
1044
1045         # last thing in do block, counts as true if anything doesn't match
1046
1047         # check xor defined first for NULL vs. NOT NULL then if one is
1048         # defined the other must be so check string equality
1049
1050         grep {
1051           (defined $pri_vals{$_} ^ defined $copy[$_])
1052           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1053         } @pri_index;
1054       }
1055   );
1056
1057   my $alias = $self->{attrs}{alias};
1058   my $info = [];
1059
1060   my %collapse_pos;
1061
1062   my @const_keys;
1063
1064   foreach my $const (@const_rows) {
1065     scalar @const_keys or do {
1066       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1067     };
1068     foreach my $key (@const_keys) {
1069       if (length $key) {
1070         my $target = $info;
1071         my @parts = split(/\./, $key);
1072         my $cur = '';
1073         my $data = $const->{$key};
1074         foreach my $p (@parts) {
1075           $target = $target->[1]->{$p} ||= [];
1076           $cur .= ".${p}";
1077           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1078             # collapsing at this point and on final part
1079             my $pos = $collapse_pos{$cur};
1080             CK: foreach my $ck (@ckey) {
1081               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1082                 $collapse_pos{$cur} = $data;
1083                 delete @collapse_pos{ # clear all positioning for sub-entries
1084                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1085                 };
1086                 push(@$target, []);
1087                 last CK;
1088               }
1089             }
1090           }
1091           if (exists $collapse{$cur}) {
1092             $target = $target->[-1];
1093           }
1094         }
1095         $target->[0] = $data;
1096       } else {
1097         $info->[0] = $const->{$key};
1098       }
1099     }
1100   }
1101
1102   return $info;
1103 }
1104
1105 =head2 result_source
1106
1107 =over 4
1108
1109 =item Arguments: $result_source?
1110
1111 =item Return Value: $result_source
1112
1113 =back
1114
1115 An accessor for the primary ResultSource object from which this ResultSet
1116 is derived.
1117
1118 =head2 result_class
1119
1120 =over 4
1121
1122 =item Arguments: $result_class?
1123
1124 =item Return Value: $result_class
1125
1126 =back
1127
1128 An accessor for the class to use when creating row objects. Defaults to
1129 C<< result_source->result_class >> - which in most cases is the name of the
1130 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1131
1132 Note that changing the result_class will also remove any components
1133 that were originally loaded in the source class via
1134 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1135 in the original source class will not run.
1136
1137 =cut
1138
1139 sub result_class {
1140   my ($self, $result_class) = @_;
1141   if ($result_class) {
1142     unless (ref $result_class) { # don't fire this for an object
1143       $self->ensure_class_loaded($result_class);
1144     }
1145     $self->_result_class($result_class);
1146     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1147     # permit the user to set result class on one result set only; it only
1148     # chains if provided to search()
1149     #$self->{attrs}{result_class} = $result_class if ref $self;
1150   }
1151   $self->_result_class;
1152 }
1153
1154 =head2 count
1155
1156 =over 4
1157
1158 =item Arguments: $cond, \%attrs??
1159
1160 =item Return Value: $count
1161
1162 =back
1163
1164 Performs an SQL C<COUNT> with the same query as the resultset was built
1165 with to find the number of elements. Passing arguments is equivalent to
1166 C<< $rs->search ($cond, \%attrs)->count >>
1167
1168 =cut
1169
1170 sub count {
1171   my $self = shift;
1172   return $self->search(@_)->count if @_ and defined $_[0];
1173   return scalar @{ $self->get_cache } if $self->get_cache;
1174
1175   my $attrs = $self->_resolved_attrs_copy;
1176
1177   # this is a little optimization - it is faster to do the limit
1178   # adjustments in software, instead of a subquery
1179   my $rows = delete $attrs->{rows};
1180   my $offset = delete $attrs->{offset};
1181
1182   my $crs;
1183   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1184     $crs = $self->_count_subq_rs ($attrs);
1185   }
1186   else {
1187     $crs = $self->_count_rs ($attrs);
1188   }
1189   my $count = $crs->next;
1190
1191   $count -= $offset if $offset;
1192   $count = $rows if $rows and $rows < $count;
1193   $count = 0 if ($count < 0);
1194
1195   return $count;
1196 }
1197
1198 =head2 count_rs
1199
1200 =over 4
1201
1202 =item Arguments: $cond, \%attrs??
1203
1204 =item Return Value: $count_rs
1205
1206 =back
1207
1208 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1209 This can be very handy for subqueries:
1210
1211   ->search( { amount => $some_rs->count_rs->as_query } )
1212
1213 As with regular resultsets the SQL query will be executed only after
1214 the resultset is accessed via L</next> or L</all>. That would return
1215 the same single value obtainable via L</count>.
1216
1217 =cut
1218
1219 sub count_rs {
1220   my $self = shift;
1221   return $self->search(@_)->count_rs if @_;
1222
1223   # this may look like a lack of abstraction (count() does about the same)
1224   # but in fact an _rs *must* use a subquery for the limits, as the
1225   # software based limiting can not be ported if this $rs is to be used
1226   # in a subquery itself (i.e. ->as_query)
1227   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1228     return $self->_count_subq_rs;
1229   }
1230   else {
1231     return $self->_count_rs;
1232   }
1233 }
1234
1235 #
1236 # returns a ResultSetColumn object tied to the count query
1237 #
1238 sub _count_rs {
1239   my ($self, $attrs) = @_;
1240
1241   my $rsrc = $self->result_source;
1242   $attrs ||= $self->_resolved_attrs;
1243
1244   my $tmp_attrs = { %$attrs };
1245   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1246   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1247
1248   # overwrite the selector (supplied by the storage)
1249   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1250   $tmp_attrs->{as} = 'count';
1251
1252   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1253
1254   return $tmp_rs;
1255 }
1256
1257 #
1258 # same as above but uses a subquery
1259 #
1260 sub _count_subq_rs {
1261   my ($self, $attrs) = @_;
1262
1263   my $rsrc = $self->result_source;
1264   $attrs ||= $self->_resolved_attrs;
1265
1266   my $sub_attrs = { %$attrs };
1267   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1268   delete @{$sub_attrs}{qw/collapse select _prefetch_select as order_by for/};
1269
1270   # if we multi-prefetch we group_by primary keys only as this is what we would
1271   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1272   if ( keys %{$attrs->{collapse}}  ) {
1273     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1274   }
1275
1276   # Calculate subquery selector
1277   if (my $g = $sub_attrs->{group_by}) {
1278
1279     my $sql_maker = $rsrc->storage->sql_maker;
1280
1281     # necessary as the group_by may refer to aliased functions
1282     my $sel_index;
1283     for my $sel (@{$attrs->{select}}) {
1284       $sel_index->{$sel->{-as}} = $sel
1285         if (ref $sel eq 'HASH' and $sel->{-as});
1286     }
1287
1288     for my $g_part (@$g) {
1289       my $colpiece = $sel_index->{$g_part} || $g_part;
1290
1291       # disqualify join-based group_by's. Arcane but possible query
1292       # also horrible horrible hack to alias a column (not a func.)
1293       # (probably need to introduce SQLA syntax)
1294       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1295         my $as = $colpiece;
1296         $as =~ s/\./__/;
1297         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1298       }
1299       push @{$sub_attrs->{select}}, $colpiece;
1300     }
1301   }
1302   else {
1303     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1304     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1305   }
1306
1307   return $rsrc->resultset_class
1308                ->new ($rsrc, $sub_attrs)
1309                 ->as_subselect_rs
1310                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1311                   ->get_column ('count');
1312 }
1313
1314 sub _bool {
1315   return 1;
1316 }
1317
1318 =head2 count_literal
1319
1320 =over 4
1321
1322 =item Arguments: $sql_fragment, @bind_values
1323
1324 =item Return Value: $count
1325
1326 =back
1327
1328 Counts the results in a literal query. Equivalent to calling L</search_literal>
1329 with the passed arguments, then L</count>.
1330
1331 =cut
1332
1333 sub count_literal { shift->search_literal(@_)->count; }
1334
1335 =head2 all
1336
1337 =over 4
1338
1339 =item Arguments: none
1340
1341 =item Return Value: @objects
1342
1343 =back
1344
1345 Returns all elements in the resultset. Called implicitly if the resultset
1346 is returned in list context.
1347
1348 =cut
1349
1350 sub all {
1351   my $self = shift;
1352   if(@_) {
1353       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1354   }
1355
1356   return @{ $self->get_cache } if $self->get_cache;
1357
1358   my @obj;
1359
1360   if (keys %{$self->_resolved_attrs->{collapse}}) {
1361     # Using $self->cursor->all is really just an optimisation.
1362     # If we're collapsing has_many prefetches it probably makes
1363     # very little difference, and this is cleaner than hacking
1364     # _construct_object to survive the approach
1365     $self->cursor->reset;
1366     my @row = $self->cursor->next;
1367     while (@row) {
1368       push(@obj, $self->_construct_object(@row));
1369       @row = (exists $self->{stashed_row}
1370                ? @{delete $self->{stashed_row}}
1371                : $self->cursor->next);
1372     }
1373   } else {
1374     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1375   }
1376
1377   $self->set_cache(\@obj) if $self->{attrs}{cache};
1378
1379   return @obj;
1380 }
1381
1382 =head2 reset
1383
1384 =over 4
1385
1386 =item Arguments: none
1387
1388 =item Return Value: $self
1389
1390 =back
1391
1392 Resets the resultset's cursor, so you can iterate through the elements again.
1393 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1394 another query.
1395
1396 =cut
1397
1398 sub reset {
1399   my ($self) = @_;
1400   delete $self->{_attrs} if exists $self->{_attrs};
1401   $self->{all_cache_position} = 0;
1402   $self->cursor->reset;
1403   return $self;
1404 }
1405
1406 =head2 first
1407
1408 =over 4
1409
1410 =item Arguments: none
1411
1412 =item Return Value: $object | undef
1413
1414 =back
1415
1416 Resets the resultset and returns an object for the first result (or C<undef>
1417 if the resultset is empty).
1418
1419 =cut
1420
1421 sub first {
1422   return $_[0]->reset->next;
1423 }
1424
1425
1426 # _rs_update_delete
1427 #
1428 # Determines whether and what type of subquery is required for the $rs operation.
1429 # If grouping is necessary either supplies its own, or verifies the current one
1430 # After all is done delegates to the proper storage method.
1431
1432 sub _rs_update_delete {
1433   my ($self, $op, $values) = @_;
1434
1435   my $rsrc = $self->result_source;
1436
1437   # if a condition exists we need to strip all table qualifiers
1438   # if this is not possible we'll force a subquery below
1439   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1440
1441   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1442   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/rows offset/);
1443
1444   if ($needs_group_by_subq or $needs_subq) {
1445
1446     # make a new $rs selecting only the PKs (that's all we really need)
1447     my $attrs = $self->_resolved_attrs_copy;
1448
1449
1450     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_select as/;
1451     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1452
1453     if ($needs_group_by_subq) {
1454       # make sure no group_by was supplied, or if there is one - make sure it matches
1455       # the columns compiled above perfectly. Anything else can not be sanely executed
1456       # on most databases so croak right then and there
1457
1458       if (my $g = $attrs->{group_by}) {
1459         my @current_group_by = map
1460           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1461           @$g
1462         ;
1463
1464         if (
1465           join ("\x00", sort @current_group_by)
1466             ne
1467           join ("\x00", sort @{$attrs->{columns}} )
1468         ) {
1469           $self->throw_exception (
1470             "You have just attempted a $op operation on a resultset which does group_by"
1471             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1472             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1473             . ' kind of queries. Please retry the operation with a modified group_by or'
1474             . ' without using one at all.'
1475           );
1476         }
1477       }
1478       else {
1479         $attrs->{group_by} = $attrs->{columns};
1480       }
1481     }
1482
1483     my $subrs = (ref $self)->new($rsrc, $attrs);
1484     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1485   }
1486   else {
1487     return $rsrc->storage->$op(
1488       $rsrc,
1489       $op eq 'update' ? $values : (),
1490       $cond,
1491     );
1492   }
1493 }
1494
1495 =head2 update
1496
1497 =over 4
1498
1499 =item Arguments: \%values
1500
1501 =item Return Value: $storage_rv
1502
1503 =back
1504
1505 Sets the specified columns in the resultset to the supplied values in a
1506 single query. Return value will be true if the update succeeded or false
1507 if no records were updated; exact type of success value is storage-dependent.
1508
1509 =cut
1510
1511 sub update {
1512   my ($self, $values) = @_;
1513   $self->throw_exception('Values for update must be a hash')
1514     unless ref $values eq 'HASH';
1515
1516   return $self->_rs_update_delete ('update', $values);
1517 }
1518
1519 =head2 update_all
1520
1521 =over 4
1522
1523 =item Arguments: \%values
1524
1525 =item Return Value: 1
1526
1527 =back
1528
1529 Fetches all objects and updates them one at a time. Note that C<update_all>
1530 will run DBIC cascade triggers, while L</update> will not.
1531
1532 =cut
1533
1534 sub update_all {
1535   my ($self, $values) = @_;
1536   $self->throw_exception('Values for update_all must be a hash')
1537     unless ref $values eq 'HASH';
1538
1539   my $guard = $self->result_source->schema->txn_scope_guard;
1540   $_->update($values) for $self->all;
1541   $guard->commit;
1542   return 1;
1543 }
1544
1545 =head2 delete
1546
1547 =over 4
1548
1549 =item Arguments: none
1550
1551 =item Return Value: $storage_rv
1552
1553 =back
1554
1555 Deletes the contents of the resultset from its result source. Note that this
1556 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1557 to run. See also L<DBIx::Class::Row/delete>.
1558
1559 Return value will be the number of rows deleted; exact type of return value
1560 is storage-dependent.
1561
1562 =cut
1563
1564 sub delete {
1565   my $self = shift;
1566   $self->throw_exception('delete does not accept any arguments')
1567     if @_;
1568
1569   return $self->_rs_update_delete ('delete');
1570 }
1571
1572 =head2 delete_all
1573
1574 =over 4
1575
1576 =item Arguments: none
1577
1578 =item Return Value: 1
1579
1580 =back
1581
1582 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1583 will run DBIC cascade triggers, while L</delete> will not.
1584
1585 =cut
1586
1587 sub delete_all {
1588   my $self = shift;
1589   $self->throw_exception('delete_all does not accept any arguments')
1590     if @_;
1591
1592   my $guard = $self->result_source->schema->txn_scope_guard;
1593   $_->delete for $self->all;
1594   $guard->commit;
1595   return 1;
1596 }
1597
1598 =head2 populate
1599
1600 =over 4
1601
1602 =item Arguments: \@data;
1603
1604 =back
1605
1606 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1607 For the arrayref of hashrefs style each hashref should be a structure suitable
1608 forsubmitting to a $resultset->create(...) method.
1609
1610 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1611 to insert the data, as this is a faster method.
1612
1613 Otherwise, each set of data is inserted into the database using
1614 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1615 accumulated into an array. The array itself, or an array reference
1616 is returned depending on scalar or list context.
1617
1618 Example:  Assuming an Artist Class that has many CDs Classes relating:
1619
1620   my $Artist_rs = $schema->resultset("Artist");
1621
1622   ## Void Context Example
1623   $Artist_rs->populate([
1624      { artistid => 4, name => 'Manufactured Crap', cds => [
1625         { title => 'My First CD', year => 2006 },
1626         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1627       ],
1628      },
1629      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1630         { title => 'My parents sold me to a record company', year => 2005 },
1631         { title => 'Why Am I So Ugly?', year => 2006 },
1632         { title => 'I Got Surgery and am now Popular', year => 2007 }
1633       ],
1634      },
1635   ]);
1636
1637   ## Array Context Example
1638   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1639     { name => "Artist One"},
1640     { name => "Artist Two"},
1641     { name => "Artist Three", cds=> [
1642     { title => "First CD", year => 2007},
1643     { title => "Second CD", year => 2008},
1644   ]}
1645   ]);
1646
1647   print $ArtistOne->name; ## response is 'Artist One'
1648   print $ArtistThree->cds->count ## reponse is '2'
1649
1650 For the arrayref of arrayrefs style,  the first element should be a list of the
1651 fieldsnames to which the remaining elements are rows being inserted.  For
1652 example:
1653
1654   $Arstist_rs->populate([
1655     [qw/artistid name/],
1656     [100, 'A Formally Unknown Singer'],
1657     [101, 'A singer that jumped the shark two albums ago'],
1658     [102, 'An actually cool singer'],
1659   ]);
1660
1661 Please note an important effect on your data when choosing between void and
1662 wantarray context. Since void context goes straight to C<insert_bulk> in
1663 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1664 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1665 create primary keys for you, you will find that your PKs are empty.  In this
1666 case you will have to use the wantarray context in order to create those
1667 values.
1668
1669 =cut
1670
1671 sub populate {
1672   my $self = shift;
1673
1674   # cruft placed in standalone method
1675   my $data = $self->_normalize_populate_args(@_);
1676
1677   if(defined wantarray) {
1678     my @created;
1679     foreach my $item (@$data) {
1680       push(@created, $self->create($item));
1681     }
1682     return wantarray ? @created : \@created;
1683   } else {
1684     my $first = $data->[0];
1685
1686     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1687     # it relationship data
1688     my (@rels, @columns);
1689     for (keys %$first) {
1690       my $ref = ref $first->{$_};
1691       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1692         ? push @rels, $_
1693         : push @columns, $_
1694       ;
1695     }
1696
1697     my @pks = $self->result_source->primary_columns;
1698
1699     ## do the belongs_to relationships
1700     foreach my $index (0..$#$data) {
1701
1702       # delegate to create() for any dataset without primary keys with specified relationships
1703       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1704         for my $r (@rels) {
1705           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1706             my @ret = $self->populate($data);
1707             return;
1708           }
1709         }
1710       }
1711
1712       foreach my $rel (@rels) {
1713         next unless ref $data->[$index]->{$rel} eq "HASH";
1714         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1715         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1716         my $related = $result->result_source->_resolve_condition(
1717           $result->result_source->relationship_info($reverse)->{cond},
1718           $self,
1719           $result,
1720         );
1721
1722         delete $data->[$index]->{$rel};
1723         $data->[$index] = {%{$data->[$index]}, %$related};
1724
1725         push @columns, keys %$related if $index == 0;
1726       }
1727     }
1728
1729     ## inherit the data locked in the conditions of the resultset
1730     my ($rs_data) = $self->_merge_cond_with_data({});
1731     delete @{$rs_data}{@columns};
1732     my @inherit_cols = keys %$rs_data;
1733     my @inherit_data = values %$rs_data;
1734
1735     ## do bulk insert on current row
1736     $self->result_source->storage->insert_bulk(
1737       $self->result_source,
1738       [@columns, @inherit_cols],
1739       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1740     );
1741
1742     ## do the has_many relationships
1743     foreach my $item (@$data) {
1744
1745       foreach my $rel (@rels) {
1746         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1747
1748         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1749      || $self->throw_exception('Cannot find the relating object.');
1750
1751         my $child = $parent->$rel;
1752
1753         my $related = $child->result_source->_resolve_condition(
1754           $parent->result_source->relationship_info($rel)->{cond},
1755           $child,
1756           $parent,
1757         );
1758
1759         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1760         my @populate = map { {%$_, %$related} } @rows_to_add;
1761
1762         $child->populate( \@populate );
1763       }
1764     }
1765   }
1766 }
1767
1768
1769 # populate() argumnets went over several incarnations
1770 # What we ultimately support is AoH
1771 sub _normalize_populate_args {
1772   my ($self, $arg) = @_;
1773
1774   if (ref $arg eq 'ARRAY') {
1775     if (ref $arg->[0] eq 'HASH') {
1776       return $arg;
1777     }
1778     elsif (ref $arg->[0] eq 'ARRAY') {
1779       my @ret;
1780       my @colnames = @{$arg->[0]};
1781       foreach my $values (@{$arg}[1 .. $#$arg]) {
1782         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
1783       }
1784       return \@ret;
1785     }
1786   }
1787
1788   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
1789 }
1790
1791 =head2 pager
1792
1793 =over 4
1794
1795 =item Arguments: none
1796
1797 =item Return Value: $pager
1798
1799 =back
1800
1801 Return Value a L<Data::Page> object for the current resultset. Only makes
1802 sense for queries with a C<page> attribute.
1803
1804 To get the full count of entries for a paged resultset, call
1805 C<total_entries> on the L<Data::Page> object.
1806
1807 =cut
1808
1809 # make a wizard good for both a scalar and a hashref
1810 my $mk_lazy_count_wizard = sub {
1811   require Variable::Magic;
1812
1813   my $stash = { total_rs => shift };
1814   my $slot = shift; # only used by the hashref magic
1815
1816   my $magic = Variable::Magic::wizard (
1817     data => sub { $stash },
1818
1819     (!$slot)
1820     ? (
1821       # the scalar magic
1822       get => sub {
1823         # set value lazily, and dispell for good
1824         ${$_[0]} = $_[1]{total_rs}->count;
1825         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref});
1826         return 1;
1827       },
1828       set => sub {
1829         # an explicit set implies dispell as well
1830         # the unless() is to work around "fun and giggles" below
1831         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref})
1832           unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
1833         return 1;
1834       },
1835     )
1836     : (
1837       # the uvar magic
1838       fetch => sub {
1839         if ($_[2] eq $slot and !$_[1]{inactive}) {
1840           my $cnt = $_[1]{total_rs}->count;
1841           $_[0]->{$slot} = $cnt;
1842
1843           # attempting to dispell in a fetch handle (works in store), seems
1844           # to invariable segfault on 5.10, 5.12, 5.13 :(
1845           # so use an inactivator instead
1846           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
1847           $_[1]{inactive}++;
1848         }
1849         return 1;
1850       },
1851       store => sub {
1852         if (! $_[1]{inactive} and $_[2] eq $slot) {
1853           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
1854           $_[1]{inactive}++
1855             unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
1856         }
1857         return 1;
1858       },
1859     ),
1860   );
1861
1862   $stash->{magic_selfref} = $magic;
1863   weaken ($stash->{magic_selfref}); # this fails on 5.8.1
1864
1865   return $magic;
1866 };
1867
1868 # the tie class for 5.8.1
1869 {
1870   package DBIx::Class::__DBIC_LAZY_RS_COUNT__;
1871   use base qw/Tie::Hash/;
1872
1873   sub FIRSTKEY { my $dummy = scalar keys %{$_[0]{data}}; each %{$_[0]{data}} }
1874   sub NEXTKEY  { each %{$_[0]{data}} }
1875   sub EXISTS   { exists $_[0]{data}{$_[1]} }
1876   sub DELETE   { delete $_[0]{data}{$_[1]} }
1877   sub CLEAR    { %{$_[0]{data}} = () }
1878   sub SCALAR   { scalar %{$_[0]{data}} }
1879
1880   sub TIEHASH {
1881     $_[1]{data} = {%{$_[1]{selfref}}};
1882     %{$_[1]{selfref}} = ();
1883     Scalar::Util::weaken ($_[1]{selfref});
1884     return bless ($_[1], $_[0]);
1885   };
1886
1887   sub FETCH {
1888     if ($_[1] eq $_[0]{slot}) {
1889       my $cnt = $_[0]{data}{$_[1]} = $_[0]{total_rs}->count;
1890       untie %{$_[0]{selfref}};
1891       %{$_[0]{selfref}} = %{$_[0]{data}};
1892       return $cnt;
1893     }
1894     else {
1895       $_[0]{data}{$_[1]};
1896     }
1897   }
1898
1899   sub STORE {
1900     $_[0]{data}{$_[1]} = $_[2];
1901     if ($_[1] eq $_[0]{slot}) {
1902       untie %{$_[0]{selfref}};
1903       %{$_[0]{selfref}} = %{$_[0]{data}};
1904     }
1905     $_[2];
1906   }
1907 }
1908
1909 sub pager {
1910   my ($self) = @_;
1911
1912   return $self->{pager} if $self->{pager};
1913
1914   if ($self->get_cache) {
1915     $self->throw_exception ('Pagers on cached resultsets are not supported');
1916   }
1917
1918   my $attrs = $self->{attrs};
1919   $self->throw_exception("Can't create pager for non-paged rs")
1920     unless $self->{attrs}{page};
1921   $attrs->{rows} ||= 10;
1922
1923   # throw away the paging flags and re-run the count (possibly
1924   # with a subselect) to get the real total count
1925   my $count_attrs = { %$attrs };
1926   delete $count_attrs->{$_} for qw/rows offset page pager/;
1927   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
1928
1929
1930 ### the following may seem awkward and dirty, but it's a thought-experiment
1931 ### necessary for future development of DBIx::DS. Do *NOT* change this code
1932 ### before talking to ribasushi/mst
1933
1934   my $pager = Data::Page->new(
1935     0,  #start with an empty set
1936     $attrs->{rows},
1937     $self->{attrs}{page},
1938   );
1939
1940   my $data_slot = 'total_entries';
1941
1942   # Since we are interested in a cached value (once it's set - it's set), every
1943   # technique will detach from the magic-host once the time comes to fire the
1944   # ->count (or in the segfaulting case of >= 5.10 it will deactivate itself)
1945
1946   if ($] < 5.008003) {
1947     # 5.8.1 throws 'Modification of a read-only value attempted' when one tries
1948     # to weakref the magic container :(
1949     # tested on 5.8.1
1950     tie (%$pager, 'DBIx::Class::__DBIC_LAZY_RS_COUNT__',
1951       { slot => $data_slot, total_rs => $total_rs, selfref => $pager }
1952     );
1953   }
1954   elsif ($] < 5.010) {
1955     # We can use magic on the hash value slot. It's interesting that the magic is
1956     # attached to the hash-slot, and does *not* stop working once I do the dummy
1957     # assignments after the cast()
1958     # tested on 5.8.3 and 5.8.9
1959     my $magic = $mk_lazy_count_wizard->($total_rs);
1960     Variable::Magic::cast ( $pager->{$data_slot}, $magic );
1961
1962     # this is for fun and giggles
1963     $pager->{$data_slot} = -1;
1964     $pager->{$data_slot} = 0;
1965
1966     # this does not work for scalars, but works with
1967     # uvar magic below
1968     #my %vals = %$pager;
1969     #%$pager = ();
1970     #%{$pager} = %vals;
1971   }
1972   else {
1973     # And the uvar magic
1974     # works on 5.10.1, 5.12.1 and 5.13.4 in its current form,
1975     # however see the wizard maker for more notes
1976     my $magic = $mk_lazy_count_wizard->($total_rs, $data_slot);
1977     Variable::Magic::cast ( %$pager, $magic );
1978
1979     # still works
1980     $pager->{$data_slot} = -1;
1981     $pager->{$data_slot} = 0;
1982
1983     # this now works
1984     my %vals = %$pager;
1985     %$pager = ();
1986     %{$pager} = %vals;
1987   }
1988
1989   return $self->{pager} = $pager;
1990 }
1991
1992 =head2 page
1993
1994 =over 4
1995
1996 =item Arguments: $page_number
1997
1998 =item Return Value: $rs
1999
2000 =back
2001
2002 Returns a resultset for the $page_number page of the resultset on which page
2003 is called, where each page contains a number of rows equal to the 'rows'
2004 attribute set on the resultset (10 by default).
2005
2006 =cut
2007
2008 sub page {
2009   my ($self, $page) = @_;
2010   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2011 }
2012
2013 =head2 new_result
2014
2015 =over 4
2016
2017 =item Arguments: \%vals
2018
2019 =item Return Value: $rowobject
2020
2021 =back
2022
2023 Creates a new row object in the resultset's result class and returns
2024 it. The row is not inserted into the database at this point, call
2025 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2026 will tell you whether the row object has been inserted or not.
2027
2028 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2029
2030 =cut
2031
2032 sub new_result {
2033   my ($self, $values) = @_;
2034   $self->throw_exception( "new_result needs a hash" )
2035     unless (ref $values eq 'HASH');
2036
2037   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
2038
2039   my %new = (
2040     %$merged_cond,
2041     @$cols_from_relations
2042       ? (-cols_from_relations => $cols_from_relations)
2043       : (),
2044     -source_handle => $self->_source_handle,
2045     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2046   );
2047
2048   return $self->result_class->new(\%new);
2049 }
2050
2051 # _merge_cond_with_data
2052 #
2053 # Takes a simple hash of K/V data and returns its copy merged with the
2054 # condition already present on the resultset. Additionally returns an
2055 # arrayref of value/condition names, which were inferred from related
2056 # objects (this is needed for in-memory related objects)
2057 sub _merge_cond_with_data {
2058   my ($self, $data) = @_;
2059
2060   my (%new_data, @cols_from_relations);
2061
2062   my $alias = $self->{attrs}{alias};
2063
2064   if (! defined $self->{cond}) {
2065     # just massage $data below
2066   }
2067   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2068     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2069     @cols_from_relations = keys %new_data;
2070   }
2071   elsif (ref $self->{cond} ne 'HASH') {
2072     $self->throw_exception(
2073       "Can't abstract implicit construct, resultset condition not a hash"
2074     );
2075   }
2076   else {
2077     # precendence must be given to passed values over values inherited from
2078     # the cond, so the order here is important.
2079     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2080     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2081
2082     while ( my($col, $value) = each %implied ) {
2083       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
2084         $new_data{$col} = $value->{'='};
2085         next;
2086       }
2087       $new_data{$col} = $value if $self->_is_deterministic_value($value);
2088     }
2089   }
2090
2091   %new_data = (
2092     %new_data,
2093     %{ $self->_remove_alias($data, $alias) },
2094   );
2095
2096   return (\%new_data, \@cols_from_relations);
2097 }
2098
2099 # _is_deterministic_value
2100 #
2101 # Make an effor to strip non-deterministic values from the condition,
2102 # to make sure new_result chokes less
2103
2104 sub _is_deterministic_value {
2105   my $self = shift;
2106   my $value = shift;
2107   my $ref_type = ref $value;
2108   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2109   return 1 if blessed $value;
2110   return 0;
2111 }
2112
2113 # _has_resolved_attr
2114 #
2115 # determines if the resultset defines at least one
2116 # of the attributes supplied
2117 #
2118 # used to determine if a subquery is neccessary
2119 #
2120 # supports some virtual attributes:
2121 #   -join
2122 #     This will scan for any joins being present on the resultset.
2123 #     It is not a mere key-search but a deep inspection of {from}
2124 #
2125
2126 sub _has_resolved_attr {
2127   my ($self, @attr_names) = @_;
2128
2129   my $attrs = $self->_resolved_attrs;
2130
2131   my %extra_checks;
2132
2133   for my $n (@attr_names) {
2134     if (grep { $n eq $_ } (qw/-join/) ) {
2135       $extra_checks{$n}++;
2136       next;
2137     }
2138
2139     my $attr =  $attrs->{$n};
2140
2141     next if not defined $attr;
2142
2143     if (ref $attr eq 'HASH') {
2144       return 1 if keys %$attr;
2145     }
2146     elsif (ref $attr eq 'ARRAY') {
2147       return 1 if @$attr;
2148     }
2149     else {
2150       return 1 if $attr;
2151     }
2152   }
2153
2154   # a resolved join is expressed as a multi-level from
2155   return 1 if (
2156     $extra_checks{-join}
2157       and
2158     ref $attrs->{from} eq 'ARRAY'
2159       and
2160     @{$attrs->{from}} > 1
2161   );
2162
2163   return 0;
2164 }
2165
2166 # _collapse_cond
2167 #
2168 # Recursively collapse the condition.
2169
2170 sub _collapse_cond {
2171   my ($self, $cond, $collapsed) = @_;
2172
2173   $collapsed ||= {};
2174
2175   if (ref $cond eq 'ARRAY') {
2176     foreach my $subcond (@$cond) {
2177       next unless ref $subcond;  # -or
2178       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2179     }
2180   }
2181   elsif (ref $cond eq 'HASH') {
2182     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2183       foreach my $subcond (@{$cond->{-and}}) {
2184         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2185       }
2186     }
2187     else {
2188       foreach my $col (keys %$cond) {
2189         my $value = $cond->{$col};
2190         $collapsed->{$col} = $value;
2191       }
2192     }
2193   }
2194
2195   return $collapsed;
2196 }
2197
2198 # _remove_alias
2199 #
2200 # Remove the specified alias from the specified query hash. A copy is made so
2201 # the original query is not modified.
2202
2203 sub _remove_alias {
2204   my ($self, $query, $alias) = @_;
2205
2206   my %orig = %{ $query || {} };
2207   my %unaliased;
2208
2209   foreach my $key (keys %orig) {
2210     if ($key !~ /\./) {
2211       $unaliased{$key} = $orig{$key};
2212       next;
2213     }
2214     $unaliased{$1} = $orig{$key}
2215       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2216   }
2217
2218   return \%unaliased;
2219 }
2220
2221 =head2 as_query
2222
2223 =over 4
2224
2225 =item Arguments: none
2226
2227 =item Return Value: \[ $sql, @bind ]
2228
2229 =back
2230
2231 Returns the SQL query and bind vars associated with the invocant.
2232
2233 This is generally used as the RHS for a subquery.
2234
2235 =cut
2236
2237 sub as_query {
2238   my $self = shift;
2239
2240   my $attrs = $self->_resolved_attrs_copy;
2241
2242   # For future use:
2243   #
2244   # in list ctx:
2245   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2246   # $sql also has no wrapping parenthesis in list ctx
2247   #
2248   my $sqlbind = $self->result_source->storage
2249     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2250
2251   return $sqlbind;
2252 }
2253
2254 =head2 find_or_new
2255
2256 =over 4
2257
2258 =item Arguments: \%vals, \%attrs?
2259
2260 =item Return Value: $rowobject
2261
2262 =back
2263
2264   my $artist = $schema->resultset('Artist')->find_or_new(
2265     { artist => 'fred' }, { key => 'artists' });
2266
2267   $cd->cd_to_producer->find_or_new({ producer => $producer },
2268                                    { key => 'primary });
2269
2270 Find an existing record from this resultset, based on its primary
2271 key, or a unique constraint. If none exists, instantiate a new result
2272 object and return it. The object will not be saved into your storage
2273 until you call L<DBIx::Class::Row/insert> on it.
2274
2275 You most likely want this method when looking for existing rows using
2276 a unique constraint that is not the primary key, or looking for
2277 related rows.
2278
2279 If you want objects to be saved immediately, use L</find_or_create>
2280 instead.
2281
2282 B<Note>: Take care when using C<find_or_new> with a table having
2283 columns with default values that you intend to be automatically
2284 supplied by the database (e.g. an auto_increment primary key column).
2285 In normal usage, the value of such columns should NOT be included at
2286 all in the call to C<find_or_new>, even when set to C<undef>.
2287
2288 =cut
2289
2290 sub find_or_new {
2291   my $self     = shift;
2292   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2293   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2294   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2295     return $row;
2296   }
2297   return $self->new_result($hash);
2298 }
2299
2300 =head2 create
2301
2302 =over 4
2303
2304 =item Arguments: \%vals
2305
2306 =item Return Value: a L<DBIx::Class::Row> $object
2307
2308 =back
2309
2310 Attempt to create a single new row or a row with multiple related rows
2311 in the table represented by the resultset (and related tables). This
2312 will not check for duplicate rows before inserting, use
2313 L</find_or_create> to do that.
2314
2315 To create one row for this resultset, pass a hashref of key/value
2316 pairs representing the columns of the table and the values you wish to
2317 store. If the appropriate relationships are set up, foreign key fields
2318 can also be passed an object representing the foreign row, and the
2319 value will be set to its primary key.
2320
2321 To create related objects, pass a hashref of related-object column values
2322 B<keyed on the relationship name>. If the relationship is of type C<multi>
2323 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2324 The process will correctly identify columns holding foreign keys, and will
2325 transparently populate them from the keys of the corresponding relation.
2326 This can be applied recursively, and will work correctly for a structure
2327 with an arbitrary depth and width, as long as the relationships actually
2328 exists and the correct column data has been supplied.
2329
2330
2331 Instead of hashrefs of plain related data (key/value pairs), you may
2332 also pass new or inserted objects. New objects (not inserted yet, see
2333 L</new>), will be inserted into their appropriate tables.
2334
2335 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2336
2337 Example of creating a new row.
2338
2339   $person_rs->create({
2340     name=>"Some Person",
2341     email=>"somebody@someplace.com"
2342   });
2343
2344 Example of creating a new row and also creating rows in a related C<has_many>
2345 or C<has_one> resultset.  Note Arrayref.
2346
2347   $artist_rs->create(
2348      { artistid => 4, name => 'Manufactured Crap', cds => [
2349         { title => 'My First CD', year => 2006 },
2350         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2351       ],
2352      },
2353   );
2354
2355 Example of creating a new row and also creating a row in a related
2356 C<belongs_to> resultset. Note Hashref.
2357
2358   $cd_rs->create({
2359     title=>"Music for Silly Walks",
2360     year=>2000,
2361     artist => {
2362       name=>"Silly Musician",
2363     }
2364   });
2365
2366 =over
2367
2368 =item WARNING
2369
2370 When subclassing ResultSet never attempt to override this method. Since
2371 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2372 lot of the internals simply never call it, so your override will be
2373 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2374 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2375 L</create> process you need to intervene.
2376
2377 =back
2378
2379 =cut
2380
2381 sub create {
2382   my ($self, $attrs) = @_;
2383   $self->throw_exception( "create needs a hashref" )
2384     unless ref $attrs eq 'HASH';
2385   return $self->new_result($attrs)->insert;
2386 }
2387
2388 =head2 find_or_create
2389
2390 =over 4
2391
2392 =item Arguments: \%vals, \%attrs?
2393
2394 =item Return Value: $rowobject
2395
2396 =back
2397
2398   $cd->cd_to_producer->find_or_create({ producer => $producer },
2399                                       { key => 'primary' });
2400
2401 Tries to find a record based on its primary key or unique constraints; if none
2402 is found, creates one and returns that instead.
2403
2404   my $cd = $schema->resultset('CD')->find_or_create({
2405     cdid   => 5,
2406     artist => 'Massive Attack',
2407     title  => 'Mezzanine',
2408     year   => 2005,
2409   });
2410
2411 Also takes an optional C<key> attribute, to search by a specific key or unique
2412 constraint. For example:
2413
2414   my $cd = $schema->resultset('CD')->find_or_create(
2415     {
2416       artist => 'Massive Attack',
2417       title  => 'Mezzanine',
2418     },
2419     { key => 'cd_artist_title' }
2420   );
2421
2422 B<Note>: Because find_or_create() reads from the database and then
2423 possibly inserts based on the result, this method is subject to a race
2424 condition. Another process could create a record in the table after
2425 the find has completed and before the create has started. To avoid
2426 this problem, use find_or_create() inside a transaction.
2427
2428 B<Note>: Take care when using C<find_or_create> with a table having
2429 columns with default values that you intend to be automatically
2430 supplied by the database (e.g. an auto_increment primary key column).
2431 In normal usage, the value of such columns should NOT be included at
2432 all in the call to C<find_or_create>, even when set to C<undef>.
2433
2434 See also L</find> and L</update_or_create>. For information on how to declare
2435 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2436
2437 =cut
2438
2439 sub find_or_create {
2440   my $self     = shift;
2441   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2442   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2443   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2444     return $row;
2445   }
2446   return $self->create($hash);
2447 }
2448
2449 =head2 update_or_create
2450
2451 =over 4
2452
2453 =item Arguments: \%col_values, { key => $unique_constraint }?
2454
2455 =item Return Value: $rowobject
2456
2457 =back
2458
2459   $resultset->update_or_create({ col => $val, ... });
2460
2461 First, searches for an existing row matching one of the unique constraints
2462 (including the primary key) on the source of this resultset. If a row is
2463 found, updates it with the other given column values. Otherwise, creates a new
2464 row.
2465
2466 Takes an optional C<key> attribute to search on a specific unique constraint.
2467 For example:
2468
2469   # In your application
2470   my $cd = $schema->resultset('CD')->update_or_create(
2471     {
2472       artist => 'Massive Attack',
2473       title  => 'Mezzanine',
2474       year   => 1998,
2475     },
2476     { key => 'cd_artist_title' }
2477   );
2478
2479   $cd->cd_to_producer->update_or_create({
2480     producer => $producer,
2481     name => 'harry',
2482   }, {
2483     key => 'primary',
2484   });
2485
2486
2487 If no C<key> is specified, it searches on all unique constraints defined on the
2488 source, including the primary key.
2489
2490 If the C<key> is specified as C<primary>, it searches only on the primary key.
2491
2492 See also L</find> and L</find_or_create>. For information on how to declare
2493 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2494
2495 B<Note>: Take care when using C<update_or_create> with a table having
2496 columns with default values that you intend to be automatically
2497 supplied by the database (e.g. an auto_increment primary key column).
2498 In normal usage, the value of such columns should NOT be included at
2499 all in the call to C<update_or_create>, even when set to C<undef>.
2500
2501 =cut
2502
2503 sub update_or_create {
2504   my $self = shift;
2505   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2506   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2507
2508   my $row = $self->find($cond, $attrs);
2509   if (defined $row) {
2510     $row->update($cond);
2511     return $row;
2512   }
2513
2514   return $self->create($cond);
2515 }
2516
2517 =head2 update_or_new
2518
2519 =over 4
2520
2521 =item Arguments: \%col_values, { key => $unique_constraint }?
2522
2523 =item Return Value: $rowobject
2524
2525 =back
2526
2527   $resultset->update_or_new({ col => $val, ... });
2528
2529 First, searches for an existing row matching one of the unique constraints
2530 (including the primary key) on the source of this resultset. If a row is
2531 found, updates it with the other given column values. Otherwise, instantiate
2532 a new result object and return it. The object will not be saved into your storage
2533 until you call L<DBIx::Class::Row/insert> on it.
2534
2535 Takes an optional C<key> attribute to search on a specific unique constraint.
2536 For example:
2537
2538   # In your application
2539   my $cd = $schema->resultset('CD')->update_or_new(
2540     {
2541       artist => 'Massive Attack',
2542       title  => 'Mezzanine',
2543       year   => 1998,
2544     },
2545     { key => 'cd_artist_title' }
2546   );
2547
2548   if ($cd->in_storage) {
2549       # the cd was updated
2550   }
2551   else {
2552       # the cd is not yet in the database, let's insert it
2553       $cd->insert;
2554   }
2555
2556 B<Note>: Take care when using C<update_or_new> with a table having
2557 columns with default values that you intend to be automatically
2558 supplied by the database (e.g. an auto_increment primary key column).
2559 In normal usage, the value of such columns should NOT be included at
2560 all in the call to C<update_or_new>, even when set to C<undef>.
2561
2562 See also L</find>, L</find_or_create> and L</find_or_new>.
2563
2564 =cut
2565
2566 sub update_or_new {
2567     my $self  = shift;
2568     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2569     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2570
2571     my $row = $self->find( $cond, $attrs );
2572     if ( defined $row ) {
2573         $row->update($cond);
2574         return $row;
2575     }
2576
2577     return $self->new_result($cond);
2578 }
2579
2580 =head2 get_cache
2581
2582 =over 4
2583
2584 =item Arguments: none
2585
2586 =item Return Value: \@cache_objects | undef
2587
2588 =back
2589
2590 Gets the contents of the cache for the resultset, if the cache is set.
2591
2592 The cache is populated either by using the L</prefetch> attribute to
2593 L</search> or by calling L</set_cache>.
2594
2595 =cut
2596
2597 sub get_cache {
2598   shift->{all_cache};
2599 }
2600
2601 =head2 set_cache
2602
2603 =over 4
2604
2605 =item Arguments: \@cache_objects
2606
2607 =item Return Value: \@cache_objects
2608
2609 =back
2610
2611 Sets the contents of the cache for the resultset. Expects an arrayref
2612 of objects of the same class as those produced by the resultset. Note that
2613 if the cache is set the resultset will return the cached objects rather
2614 than re-querying the database even if the cache attr is not set.
2615
2616 The contents of the cache can also be populated by using the
2617 L</prefetch> attribute to L</search>.
2618
2619 =cut
2620
2621 sub set_cache {
2622   my ( $self, $data ) = @_;
2623   $self->throw_exception("set_cache requires an arrayref")
2624       if defined($data) && (ref $data ne 'ARRAY');
2625   $self->{all_cache} = $data;
2626 }
2627
2628 =head2 clear_cache
2629
2630 =over 4
2631
2632 =item Arguments: none
2633
2634 =item Return Value: undef
2635
2636 =back
2637
2638 Clears the cache for the resultset.
2639
2640 =cut
2641
2642 sub clear_cache {
2643   shift->set_cache(undef);
2644 }
2645
2646 =head2 is_paged
2647
2648 =over 4
2649
2650 =item Arguments: none
2651
2652 =item Return Value: true, if the resultset has been paginated
2653
2654 =back
2655
2656 =cut
2657
2658 sub is_paged {
2659   my ($self) = @_;
2660   return !!$self->{attrs}{page};
2661 }
2662
2663 =head2 is_ordered
2664
2665 =over 4
2666
2667 =item Arguments: none
2668
2669 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2670
2671 =back
2672
2673 =cut
2674
2675 sub is_ordered {
2676   my ($self) = @_;
2677   return scalar $self->result_source->storage->_extract_order_columns($self->{attrs}{order_by});
2678 }
2679
2680 =head2 related_resultset
2681
2682 =over 4
2683
2684 =item Arguments: $relationship_name
2685
2686 =item Return Value: $resultset
2687
2688 =back
2689
2690 Returns a related resultset for the supplied relationship name.
2691
2692   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2693
2694 =cut
2695
2696 sub related_resultset {
2697   my ($self, $rel) = @_;
2698
2699   $self->{related_resultsets} ||= {};
2700   return $self->{related_resultsets}{$rel} ||= do {
2701     my $rsrc = $self->result_source;
2702     my $rel_info = $rsrc->relationship_info($rel);
2703
2704     $self->throw_exception(
2705       "search_related: result source '" . $rsrc->source_name .
2706         "' has no such relationship $rel")
2707       unless $rel_info;
2708
2709     my $attrs = $self->_chain_relationship($rel);
2710
2711     my $join_count = $attrs->{seen_join}{$rel};
2712
2713     my $alias = $self->result_source->storage
2714         ->relname_to_table_alias($rel, $join_count);
2715
2716     # since this is search_related, and we already slid the select window inwards
2717     # (the select/as attrs were deleted in the beginning), we need to flip all
2718     # left joins to inner, so we get the expected results
2719     # read the comment on top of the actual function to see what this does
2720     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2721
2722
2723     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2724     delete @{$attrs}{qw(result_class alias)};
2725
2726     my $new_cache;
2727
2728     if (my $cache = $self->get_cache) {
2729       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2730         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2731                         @$cache ];
2732       }
2733     }
2734
2735     my $rel_source = $rsrc->related_source($rel);
2736
2737     my $new = do {
2738
2739       # The reason we do this now instead of passing the alias to the
2740       # search_rs below is that if you wrap/overload resultset on the
2741       # source you need to know what alias it's -going- to have for things
2742       # to work sanely (e.g. RestrictWithObject wants to be able to add
2743       # extra query restrictions, and these may need to be $alias.)
2744
2745       my $rel_attrs = $rel_source->resultset_attributes;
2746       local $rel_attrs->{alias} = $alias;
2747
2748       $rel_source->resultset
2749                  ->search_rs(
2750                      undef, {
2751                        %$attrs,
2752                        where => $attrs->{where},
2753                    });
2754     };
2755     $new->set_cache($new_cache) if $new_cache;
2756     $new;
2757   };
2758 }
2759
2760 =head2 current_source_alias
2761
2762 =over 4
2763
2764 =item Arguments: none
2765
2766 =item Return Value: $source_alias
2767
2768 =back
2769
2770 Returns the current table alias for the result source this resultset is built
2771 on, that will be used in the SQL query. Usually it is C<me>.
2772
2773 Currently the source alias that refers to the result set returned by a
2774 L</search>/L</find> family method depends on how you got to the resultset: it's
2775 C<me> by default, but eg. L</search_related> aliases it to the related result
2776 source name (and keeps C<me> referring to the original result set). The long
2777 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2778 (and make this method unnecessary).
2779
2780 Thus it's currently necessary to use this method in predefined queries (see
2781 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2782 source alias of the current result set:
2783
2784   # in a result set class
2785   sub modified_by {
2786     my ($self, $user) = @_;
2787
2788     my $me = $self->current_source_alias;
2789
2790     return $self->search(
2791       "$me.modified" => $user->id,
2792     );
2793   }
2794
2795 =cut
2796
2797 sub current_source_alias {
2798   my ($self) = @_;
2799
2800   return ($self->{attrs} || {})->{alias} || 'me';
2801 }
2802
2803 =head2 as_subselect_rs
2804
2805 =over 4
2806
2807 =item Arguments: none
2808
2809 =item Return Value: $resultset
2810
2811 =back
2812
2813 Act as a barrier to SQL symbols.  The resultset provided will be made into a
2814 "virtual view" by including it as a subquery within the from clause.  From this
2815 point on, any joined tables are inaccessible to ->search on the resultset (as if
2816 it were simply where-filtered without joins).  For example:
2817
2818  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
2819
2820  # 'x' now pollutes the query namespace
2821
2822  # So the following works as expected
2823  my $ok_rs = $rs->search({'x.other' => 1});
2824
2825  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
2826  # def) we look for one row with contradictory terms and join in another table
2827  # (aliased 'x_2') which we never use
2828  my $broken_rs = $rs->search({'x.name' => 'def'});
2829
2830  my $rs2 = $rs->as_subselect_rs;
2831
2832  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
2833  my $not_joined_rs = $rs2->search({'x.other' => 1});
2834
2835  # works as expected: finds a 'table' row related to two x rows (abc and def)
2836  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
2837
2838 Another example of when one might use this would be to select a subset of
2839 columns in a group by clause:
2840
2841  my $rs = $schema->resultset('Bar')->search(undef, {
2842    group_by => [qw{ id foo_id baz_id }],
2843  })->as_subselect_rs->search(undef, {
2844    columns => [qw{ id foo_id }]
2845  });
2846
2847 In the above example normally columns would have to be equal to the group by,
2848 but because we isolated the group by into a subselect the above works.
2849
2850 =cut
2851
2852 sub as_subselect_rs {
2853   my $self = shift;
2854
2855   my $attrs = $self->_resolved_attrs;
2856
2857   my $fresh_rs = (ref $self)->new (
2858     $self->result_source
2859   );
2860
2861   # these pieces will be locked in the subquery
2862   delete $fresh_rs->{cond};
2863   delete @{$fresh_rs->{attrs}}{qw/where bind/};
2864
2865   return $fresh_rs->search( {}, {
2866     from => [{
2867       $attrs->{alias} => $self->as_query,
2868       -alias         => $attrs->{alias},
2869       -source_handle => $self->result_source->handle,
2870     }],
2871     alias => $attrs->{alias},
2872   });
2873 }
2874
2875 # This code is called by search_related, and makes sure there
2876 # is clear separation between the joins before, during, and
2877 # after the relationship. This information is needed later
2878 # in order to properly resolve prefetch aliases (any alias
2879 # with a relation_chain_depth less than the depth of the
2880 # current prefetch is not considered)
2881 #
2882 # The increments happen twice per join. An even number means a
2883 # relationship specified via a search_related, whereas an odd
2884 # number indicates a join/prefetch added via attributes
2885 #
2886 # Also this code will wrap the current resultset (the one we
2887 # chain to) in a subselect IFF it contains limiting attributes
2888 sub _chain_relationship {
2889   my ($self, $rel) = @_;
2890   my $source = $self->result_source;
2891   my $attrs = { %{$self->{attrs}||{}} };
2892
2893   # we need to take the prefetch the attrs into account before we
2894   # ->_resolve_join as otherwise they get lost - captainL
2895   my $join = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2896
2897   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
2898
2899   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
2900
2901   my $from;
2902   my @force_subq_attrs = qw/offset rows group_by having/;
2903
2904   if (
2905     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
2906       ||
2907     $self->_has_resolved_attr (@force_subq_attrs)
2908   ) {
2909     # Nuke the prefetch (if any) before the new $rs attrs
2910     # are resolved (prefetch is useless - we are wrapping
2911     # a subquery anyway).
2912     my $rs_copy = $self->search;
2913     $rs_copy->{attrs}{join} = $self->_merge_attr (
2914       $rs_copy->{attrs}{join},
2915       delete $rs_copy->{attrs}{prefetch},
2916     );
2917
2918     $from = [{
2919       -source_handle => $source->handle,
2920       -alias => $attrs->{alias},
2921       $attrs->{alias} => $rs_copy->as_query,
2922     }];
2923     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
2924     $seen->{-relation_chain_depth} = 0;
2925   }
2926   elsif ($attrs->{from}) {  #shallow copy suffices
2927     $from = [ @{$attrs->{from}} ];
2928   }
2929   else {
2930     $from = [{
2931       -source_handle => $source->handle,
2932       -alias => $attrs->{alias},
2933       $attrs->{alias} => $source->from,
2934     }];
2935   }
2936
2937   my $jpath = ($seen->{-relation_chain_depth})
2938     ? $from->[-1][0]{-join_path}
2939     : [];
2940
2941   my @requested_joins = $source->_resolve_join(
2942     $join,
2943     $attrs->{alias},
2944     $seen,
2945     $jpath,
2946   );
2947
2948   push @$from, @requested_joins;
2949
2950   $seen->{-relation_chain_depth}++;
2951
2952   # if $self already had a join/prefetch specified on it, the requested
2953   # $rel might very well be already included. What we do in this case
2954   # is effectively a no-op (except that we bump up the chain_depth on
2955   # the join in question so we could tell it *is* the search_related)
2956   my $already_joined;
2957
2958   # we consider the last one thus reverse
2959   for my $j (reverse @requested_joins) {
2960     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
2961     if ($rel eq $last_j) {
2962       $j->[0]{-relation_chain_depth}++;
2963       $already_joined++;
2964       last;
2965     }
2966   }
2967
2968   unless ($already_joined) {
2969     push @$from, $source->_resolve_join(
2970       $rel,
2971       $attrs->{alias},
2972       $seen,
2973       $jpath,
2974     );
2975   }
2976
2977   $seen->{-relation_chain_depth}++;
2978
2979   return {%$attrs, from => $from, seen_join => $seen};
2980 }
2981
2982 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2983 sub _resolved_attrs_copy {
2984   my $self = shift;
2985   return { %{$self->_resolved_attrs (@_)} };
2986 }
2987
2988 sub _resolved_attrs {
2989   my $self = shift;
2990   return $self->{_attrs} if $self->{_attrs};
2991
2992   my $attrs  = { %{ $self->{attrs} || {} } };
2993   my $source = $self->result_source;
2994   my $alias  = $attrs->{alias};
2995
2996   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2997   my @colbits;
2998
2999   # build columns (as long as select isn't set) into a set of as/select hashes
3000   unless ( $attrs->{select} ) {
3001
3002     my @cols;
3003     if ( ref $attrs->{columns} eq 'ARRAY' ) {
3004       @cols = @{ delete $attrs->{columns}}
3005     } elsif ( defined $attrs->{columns} ) {
3006       @cols = delete $attrs->{columns}
3007     } else {
3008       @cols = $source->columns
3009     }
3010
3011     for (@cols) {
3012       if ( ref $_ eq 'HASH' ) {
3013         push @colbits, $_
3014       } else {
3015         my $key = /^\Q${alias}.\E(.+)$/
3016           ? "$1"
3017           : "$_";
3018         my $value = /\./
3019           ? "$_"
3020           : "${alias}.$_";
3021         push @colbits, { $key => $value };
3022       }
3023     }
3024   }
3025
3026   # add the additional columns on
3027   foreach (qw{include_columns +columns}) {
3028     if ( $attrs->{$_} ) {
3029       my @list = ( ref($attrs->{$_}) eq 'ARRAY' )
3030         ? @{ delete $attrs->{$_} }
3031         : delete $attrs->{$_};
3032       for (@list) {
3033         if ( ref($_) eq 'HASH' ) {
3034           push @colbits, $_
3035         } else {
3036           my $key = ( split /\./, $_ )[-1];
3037           my $value = ( /\./ ? $_ : "$alias.$_" );
3038           push @colbits, { $key => $value };
3039         }
3040       }
3041     }
3042   }
3043
3044   # start with initial select items
3045   if ( $attrs->{select} ) {
3046     $attrs->{select} =
3047         ( ref $attrs->{select} eq 'ARRAY' )
3048       ? [ @{ $attrs->{select} } ]
3049       : [ $attrs->{select} ];
3050
3051     if ( $attrs->{as} ) {
3052       $attrs->{as} =
3053         (
3054           ref $attrs->{as} eq 'ARRAY'
3055             ? [ @{ $attrs->{as} } ]
3056             : [ $attrs->{as} ]
3057         )
3058     } else {
3059       $attrs->{as} = [ map {
3060          m/^\Q${alias}.\E(.+)$/
3061            ? $1
3062            : $_
3063          } @{ $attrs->{select} }
3064       ]
3065     }
3066   }
3067   else {
3068
3069     # otherwise we intialise select & as to empty
3070     $attrs->{select} = [];
3071     $attrs->{as}     = [];
3072   }
3073
3074   # now add colbits to select/as
3075   push @{ $attrs->{select} }, map values %{$_}, @colbits;
3076   push @{ $attrs->{as}     }, map keys   %{$_}, @colbits;
3077
3078   if ( my $adds = delete $attrs->{'+select'} ) {
3079     $adds = [$adds] unless ref $adds eq 'ARRAY';
3080     push @{ $attrs->{select} },
3081       map { /\./ || ref $_ ? $_ : "$alias.$_" } @$adds;
3082   }
3083   if ( my $adds = delete $attrs->{'+as'} ) {
3084     $adds = [$adds] unless ref $adds eq 'ARRAY';
3085     push @{ $attrs->{as} }, @$adds;
3086   }
3087
3088   $attrs->{from} ||= [{
3089     -source_handle => $source->handle,
3090     -alias => $self->{attrs}{alias},
3091     $self->{attrs}{alias} => $source->from,
3092   }];
3093
3094   if ( $attrs->{join} || $attrs->{prefetch} ) {
3095
3096     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3097       if ref $attrs->{from} ne 'ARRAY';
3098
3099     my $join = delete $attrs->{join} || {};
3100
3101     if ( defined $attrs->{prefetch} ) {
3102       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
3103     }
3104
3105     $attrs->{from} =    # have to copy here to avoid corrupting the original
3106       [
3107         @{ $attrs->{from} },
3108         $source->_resolve_join(
3109           $join,
3110           $alias,
3111           { %{ $attrs->{seen_join} || {} } },
3112           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3113             ? $attrs->{from}[-1][0]{-join_path}
3114             : []
3115           ,
3116         )
3117       ];
3118   }
3119
3120   if ( defined $attrs->{order_by} ) {
3121     $attrs->{order_by} = (
3122       ref( $attrs->{order_by} ) eq 'ARRAY'
3123       ? [ @{ $attrs->{order_by} } ]
3124       : [ $attrs->{order_by} || () ]
3125     );
3126   }
3127
3128   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3129     $attrs->{group_by} = [ $attrs->{group_by} ];
3130   }
3131
3132   # generate the distinct induced group_by early, as prefetch will be carried via a
3133   # subquery (since a group_by is present)
3134   if (delete $attrs->{distinct}) {
3135     if ($attrs->{group_by}) {
3136       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3137     }
3138     else {
3139       my $storage = $self->result_source->schema->storage;
3140       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
3141
3142       my $group_spec = $attrs->{group_by} = [];
3143       my %group_index;
3144
3145       for (@{$attrs->{select}}) {
3146         if (! ref($_) or ref ($_) ne 'HASH' ) {
3147           push @$group_spec, $_;
3148           $group_index{$_}++;
3149           if ($rs_column_list->{$_} and $_ !~ /\./ ) {
3150             # add a fully qualified version as well
3151             $group_index{"$rs_column_list->{$_}{-source_alias}.$_"}++;
3152           }
3153         }
3154       }
3155       # add any order_by parts that are not already present in the group_by
3156       # we need to be careful not to add any named functions/aggregates
3157       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
3158       for my $chunk ($storage->_extract_order_columns($attrs->{order_by})) {
3159
3160         # only consider real columns (for functions the user got to do an explicit group_by)
3161         my $colinfo = $rs_column_list->{$chunk}
3162           or next;
3163
3164         $chunk = "$colinfo->{-source_alias}.$chunk" if $chunk !~ /\./;
3165         push @$group_spec, $chunk unless $group_index{$chunk}++;
3166       }
3167     }
3168   }
3169
3170   $attrs->{collapse} ||= {};
3171   if ( my $prefetch = delete $attrs->{prefetch} ) {
3172     $prefetch = $self->_merge_attr( {}, $prefetch );
3173
3174     my $prefetch_ordering = [];
3175
3176     # this is a separate structure (we don't look in {from} directly)
3177     # as the resolver needs to shift things off the lists to work
3178     # properly (identical-prefetches on different branches)
3179     my $join_map = {};
3180     if (ref $attrs->{from} eq 'ARRAY') {
3181
3182       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3183
3184       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3185         next unless $j->[0]{-alias};
3186         next unless $j->[0]{-join_path};
3187         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3188
3189         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3190
3191         my $p = $join_map;
3192         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3193         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3194       }
3195     }
3196
3197     my @prefetch =
3198       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3199
3200     # we need to somehow mark which columns came from prefetch
3201     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
3202
3203     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
3204     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3205
3206     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3207     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3208   }
3209
3210   # if both page and offset are specified, produce a combined offset
3211   # even though it doesn't make much sense, this is what pre 081xx has
3212   # been doing
3213   if (my $page = delete $attrs->{page}) {
3214     $attrs->{offset} =
3215       ($attrs->{rows} * ($page - 1))
3216             +
3217       ($attrs->{offset} || 0)
3218     ;
3219   }
3220
3221   return $self->{_attrs} = $attrs;
3222 }
3223
3224 sub _rollout_attr {
3225   my ($self, $attr) = @_;
3226
3227   if (ref $attr eq 'HASH') {
3228     return $self->_rollout_hash($attr);
3229   } elsif (ref $attr eq 'ARRAY') {
3230     return $self->_rollout_array($attr);
3231   } else {
3232     return [$attr];
3233   }
3234 }
3235
3236 sub _rollout_array {
3237   my ($self, $attr) = @_;
3238
3239   my @rolled_array;
3240   foreach my $element (@{$attr}) {
3241     if (ref $element eq 'HASH') {
3242       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3243     } elsif (ref $element eq 'ARRAY') {
3244       #  XXX - should probably recurse here
3245       push( @rolled_array, @{$self->_rollout_array($element)} );
3246     } else {
3247       push( @rolled_array, $element );
3248     }
3249   }
3250   return \@rolled_array;
3251 }
3252
3253 sub _rollout_hash {
3254   my ($self, $attr) = @_;
3255
3256   my @rolled_array;
3257   foreach my $key (keys %{$attr}) {
3258     push( @rolled_array, { $key => $attr->{$key} } );
3259   }
3260   return \@rolled_array;
3261 }
3262
3263 sub _calculate_score {
3264   my ($self, $a, $b) = @_;
3265
3266   if (defined $a xor defined $b) {
3267     return 0;
3268   }
3269   elsif (not defined $a) {
3270     return 1;
3271   }
3272
3273   if (ref $b eq 'HASH') {
3274     my ($b_key) = keys %{$b};
3275     if (ref $a eq 'HASH') {
3276       my ($a_key) = keys %{$a};
3277       if ($a_key eq $b_key) {
3278         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3279       } else {
3280         return 0;
3281       }
3282     } else {
3283       return ($a eq $b_key) ? 1 : 0;
3284     }
3285   } else {
3286     if (ref $a eq 'HASH') {
3287       my ($a_key) = keys %{$a};
3288       return ($b eq $a_key) ? 1 : 0;
3289     } else {
3290       return ($b eq $a) ? 1 : 0;
3291     }
3292   }
3293 }
3294
3295 sub _merge_attr {
3296   my ($self, $orig, $import) = @_;
3297
3298   return $import unless defined($orig);
3299   return $orig unless defined($import);
3300
3301   $orig = $self->_rollout_attr($orig);
3302   $import = $self->_rollout_attr($import);
3303
3304   my $seen_keys;
3305   foreach my $import_element ( @{$import} ) {
3306     # find best candidate from $orig to merge $b_element into
3307     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3308     foreach my $orig_element ( @{$orig} ) {
3309       my $score = $self->_calculate_score( $orig_element, $import_element );
3310       if ($score > $best_candidate->{score}) {
3311         $best_candidate->{position} = $position;
3312         $best_candidate->{score} = $score;
3313       }
3314       $position++;
3315     }
3316     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3317
3318     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3319       push( @{$orig}, $import_element );
3320     } else {
3321       my $orig_best = $orig->[$best_candidate->{position}];
3322       # merge orig_best and b_element together and replace original with merged
3323       if (ref $orig_best ne 'HASH') {
3324         $orig->[$best_candidate->{position}] = $import_element;
3325       } elsif (ref $import_element eq 'HASH') {
3326         my ($key) = keys %{$orig_best};
3327         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3328       }
3329     }
3330     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3331   }
3332
3333   return $orig;
3334 }
3335
3336 sub result_source {
3337     my $self = shift;
3338
3339     if (@_) {
3340         $self->_source_handle($_[0]->handle);
3341     } else {
3342         $self->_source_handle->resolve;
3343     }
3344 }
3345
3346 =head2 throw_exception
3347
3348 See L<DBIx::Class::Schema/throw_exception> for details.
3349
3350 =cut
3351
3352 sub throw_exception {
3353   my $self=shift;
3354
3355   if (ref $self && $self->_source_handle->schema) {
3356     $self->_source_handle->schema->throw_exception(@_)
3357   }
3358   else {
3359     DBIx::Class::Exception->throw(@_);
3360   }
3361 }
3362
3363 # XXX: FIXME: Attributes docs need clearing up
3364
3365 =head1 ATTRIBUTES
3366
3367 Attributes are used to refine a ResultSet in various ways when
3368 searching for data. They can be passed to any method which takes an
3369 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3370 L</count>.
3371
3372 These are in no particular order:
3373
3374 =head2 order_by
3375
3376 =over 4
3377
3378 =item Value: ( $order_by | \@order_by | \%order_by )
3379
3380 =back
3381
3382 Which column(s) to order the results by.
3383
3384 [The full list of suitable values is documented in
3385 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3386 common options.]
3387
3388 If a single column name, or an arrayref of names is supplied, the
3389 argument is passed through directly to SQL. The hashref syntax allows
3390 for connection-agnostic specification of ordering direction:
3391
3392  For descending order:
3393
3394   order_by => { -desc => [qw/col1 col2 col3/] }
3395
3396  For explicit ascending order:
3397
3398   order_by => { -asc => 'col' }
3399
3400 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3401 supported, although you are strongly encouraged to use the hashref
3402 syntax as outlined above.
3403
3404 =head2 columns
3405
3406 =over 4
3407
3408 =item Value: \@columns
3409
3410 =back
3411
3412 Shortcut to request a particular set of columns to be retrieved. Each
3413 column spec may be a string (a table column name), or a hash (in which
3414 case the key is the C<as> value, and the value is used as the C<select>
3415 expression). Adds C<me.> onto the start of any column without a C<.> in
3416 it and sets C<select> from that, then auto-populates C<as> from
3417 C<select> as normal. (You may also use the C<cols> attribute, as in
3418 earlier versions of DBIC.)
3419
3420 Essentially C<columns> does the same as L</select> and L</as>.
3421
3422     columns => [ 'foo', { bar => 'baz' } ]
3423
3424 is the same as
3425
3426     select => [qw/foo baz/],
3427     as => [qw/foo bar/]
3428
3429 =head2 +columns
3430
3431 =over 4
3432
3433 =item Value: \@columns
3434
3435 =back
3436
3437 Indicates additional columns to be selected from storage. Works the same
3438 as L</columns> but adds columns to the selection. (You may also use the
3439 C<include_columns> attribute, as in earlier versions of DBIC). For
3440 example:-
3441
3442   $schema->resultset('CD')->search(undef, {
3443     '+columns' => ['artist.name'],
3444     join => ['artist']
3445   });
3446
3447 would return all CDs and include a 'name' column to the information
3448 passed to object inflation. Note that the 'artist' is the name of the
3449 column (or relationship) accessor, and 'name' is the name of the column
3450 accessor in the related table.
3451
3452 =head2 include_columns
3453
3454 =over 4
3455
3456 =item Value: \@columns
3457
3458 =back
3459
3460 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3461
3462 =head2 select
3463
3464 =over 4
3465
3466 =item Value: \@select_columns
3467
3468 =back
3469
3470 Indicates which columns should be selected from the storage. You can use
3471 column names, or in the case of RDBMS back ends, function or stored procedure
3472 names:
3473
3474   $rs = $schema->resultset('Employee')->search(undef, {
3475     select => [
3476       'name',
3477       { count => 'employeeid' },
3478       { max => { length => 'name' }, -as => 'longest_name' }
3479     ]
3480   });
3481
3482   # Equivalent SQL
3483   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3484
3485 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3486 use L</select>, to instruct DBIx::Class how to store the result of the column.
3487 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3488 identifier aliasing. You can however alias a function, so you can use it in
3489 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3490 attribute> supplied as shown in the example above.
3491
3492 =head2 +select
3493
3494 =over 4
3495
3496 Indicates additional columns to be selected from storage.  Works the same as
3497 L</select> but adds columns to the default selection, instead of specifying
3498 an explicit list.
3499
3500 =back
3501
3502 =head2 +as
3503
3504 =over 4
3505
3506 Indicates additional column names for those added via L</+select>. See L</as>.
3507
3508 =back
3509
3510 =head2 as
3511
3512 =over 4
3513
3514 =item Value: \@inflation_names
3515
3516 =back
3517
3518 Indicates column names for object inflation. That is L</as> indicates the
3519 slot name in which the column value will be stored within the
3520 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3521 identifier by the C<get_column> method (or via the object accessor B<if one
3522 with the same name already exists>) as shown below. The L</as> attribute has
3523 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3524
3525   $rs = $schema->resultset('Employee')->search(undef, {
3526     select => [
3527       'name',
3528       { count => 'employeeid' },
3529       { max => { length => 'name' }, -as => 'longest_name' }
3530     ],
3531     as => [qw/
3532       name
3533       employee_count
3534       max_name_length
3535     /],
3536   });
3537
3538 If the object against which the search is performed already has an accessor
3539 matching a column name specified in C<as>, the value can be retrieved using
3540 the accessor as normal:
3541
3542   my $name = $employee->name();
3543
3544 If on the other hand an accessor does not exist in the object, you need to
3545 use C<get_column> instead:
3546
3547   my $employee_count = $employee->get_column('employee_count');
3548
3549 You can create your own accessors if required - see
3550 L<DBIx::Class::Manual::Cookbook> for details.
3551
3552 =head2 join
3553
3554 =over 4
3555
3556 =item Value: ($rel_name | \@rel_names | \%rel_names)
3557
3558 =back
3559
3560 Contains a list of relationships that should be joined for this query.  For
3561 example:
3562
3563   # Get CDs by Nine Inch Nails
3564   my $rs = $schema->resultset('CD')->search(
3565     { 'artist.name' => 'Nine Inch Nails' },
3566     { join => 'artist' }
3567   );
3568
3569 Can also contain a hash reference to refer to the other relation's relations.
3570 For example:
3571
3572   package MyApp::Schema::Track;
3573   use base qw/DBIx::Class/;
3574   __PACKAGE__->table('track');
3575   __PACKAGE__->add_columns(qw/trackid cd position title/);
3576   __PACKAGE__->set_primary_key('trackid');
3577   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3578   1;
3579
3580   # In your application
3581   my $rs = $schema->resultset('Artist')->search(
3582     { 'track.title' => 'Teardrop' },
3583     {
3584       join     => { cd => 'track' },
3585       order_by => 'artist.name',
3586     }
3587   );
3588
3589 You need to use the relationship (not the table) name in  conditions,
3590 because they are aliased as such. The current table is aliased as "me", so
3591 you need to use me.column_name in order to avoid ambiguity. For example:
3592
3593   # Get CDs from 1984 with a 'Foo' track
3594   my $rs = $schema->resultset('CD')->search(
3595     {
3596       'me.year' => 1984,
3597       'tracks.name' => 'Foo'
3598     },
3599     { join => 'tracks' }
3600   );
3601
3602 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3603 similarly for a third time). For e.g.
3604
3605   my $rs = $schema->resultset('Artist')->search({
3606     'cds.title'   => 'Down to Earth',
3607     'cds_2.title' => 'Popular',
3608   }, {
3609     join => [ qw/cds cds/ ],
3610   });
3611
3612 will return a set of all artists that have both a cd with title 'Down
3613 to Earth' and a cd with title 'Popular'.
3614
3615 If you want to fetch related objects from other tables as well, see C<prefetch>
3616 below.
3617
3618 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3619
3620 =head2 prefetch
3621
3622 =over 4
3623
3624 =item Value: ($rel_name | \@rel_names | \%rel_names)
3625
3626 =back
3627
3628 Contains one or more relationships that should be fetched along with
3629 the main query (when they are accessed afterwards the data will
3630 already be available, without extra queries to the database).  This is
3631 useful for when you know you will need the related objects, because it
3632 saves at least one query:
3633
3634   my $rs = $schema->resultset('Tag')->search(
3635     undef,
3636     {
3637       prefetch => {
3638         cd => 'artist'
3639       }
3640     }
3641   );
3642
3643 The initial search results in SQL like the following:
3644
3645   SELECT tag.*, cd.*, artist.* FROM tag
3646   JOIN cd ON tag.cd = cd.cdid
3647   JOIN artist ON cd.artist = artist.artistid
3648
3649 L<DBIx::Class> has no need to go back to the database when we access the
3650 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3651 case.
3652
3653 Simple prefetches will be joined automatically, so there is no need
3654 for a C<join> attribute in the above search.
3655
3656 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3657 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3658 with an accessor type of 'single' or 'filter'). A more complex example that
3659 prefetches an artists cds, the tracks on those cds, and the tags associated
3660 with that artist is given below (assuming many-to-many from artists to tags):
3661
3662  my $rs = $schema->resultset('Artist')->search(
3663    undef,
3664    {
3665      prefetch => [
3666        { cds => 'tracks' },
3667        { artist_tags => 'tags' }
3668      ]
3669    }
3670  );
3671
3672
3673 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3674 attributes will be ignored.
3675
3676 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3677 exactly as you might expect.
3678
3679 =over 4
3680
3681 =item *
3682
3683 Prefetch uses the L</cache> to populate the prefetched relationships. This
3684 may or may not be what you want.
3685
3686 =item *
3687
3688 If you specify a condition on a prefetched relationship, ONLY those
3689 rows that match the prefetched condition will be fetched into that relationship.
3690 This means that adding prefetch to a search() B<may alter> what is returned by
3691 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3692
3693   my $artist_rs = $schema->resultset('Artist')->search({
3694       'cds.year' => 2008,
3695   }, {
3696       join => 'cds',
3697   });
3698
3699   my $count = $artist_rs->first->cds->count;
3700
3701   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3702
3703   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3704
3705   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3706
3707 that cmp_ok() may or may not pass depending on the datasets involved. This
3708 behavior may or may not survive the 0.09 transition.
3709
3710 =back
3711
3712 =head2 page
3713
3714 =over 4
3715
3716 =item Value: $page
3717
3718 =back
3719
3720 Makes the resultset paged and specifies the page to retrieve. Effectively
3721 identical to creating a non-pages resultset and then calling ->page($page)
3722 on it.
3723
3724 If L<rows> attribute is not specified it defaults to 10 rows per page.
3725
3726 When you have a paged resultset, L</count> will only return the number
3727 of rows in the page. To get the total, use the L</pager> and call
3728 C<total_entries> on it.
3729
3730 =head2 rows
3731
3732 =over 4
3733
3734 =item Value: $rows
3735
3736 =back
3737
3738 Specifies the maximum number of rows for direct retrieval or the number of
3739 rows per page if the page attribute or method is used.
3740
3741 =head2 offset
3742
3743 =over 4
3744
3745 =item Value: $offset
3746
3747 =back
3748
3749 Specifies the (zero-based) row number for the  first row to be returned, or the
3750 of the first row of the first page if paging is used.
3751
3752 =head2 group_by
3753
3754 =over 4
3755
3756 =item Value: \@columns
3757
3758 =back
3759
3760 A arrayref of columns to group by. Can include columns of joined tables.
3761
3762   group_by => [qw/ column1 column2 ... /]
3763
3764 =head2 having
3765
3766 =over 4
3767
3768 =item Value: $condition
3769
3770 =back
3771
3772 HAVING is a select statement attribute that is applied between GROUP BY and
3773 ORDER BY. It is applied to the after the grouping calculations have been
3774 done.
3775
3776   having => { 'count(employee)' => { '>=', 100 } }
3777
3778 =head2 distinct
3779
3780 =over 4
3781
3782 =item Value: (0 | 1)
3783
3784 =back
3785
3786 Set to 1 to group by all columns. If the resultset already has a group_by
3787 attribute, this setting is ignored and an appropriate warning is issued.
3788
3789 =head2 where
3790
3791 =over 4
3792
3793 Adds to the WHERE clause.
3794
3795   # only return rows WHERE deleted IS NULL for all searches
3796   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3797
3798 Can be overridden by passing C<< { where => undef } >> as an attribute
3799 to a resultset.
3800
3801 =back
3802
3803 =head2 cache
3804
3805 Set to 1 to cache search results. This prevents extra SQL queries if you
3806 revisit rows in your ResultSet:
3807
3808   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3809
3810   while( my $artist = $resultset->next ) {
3811     ... do stuff ...
3812   }
3813
3814   $rs->first; # without cache, this would issue a query
3815
3816 By default, searches are not cached.
3817
3818 For more examples of using these attributes, see
3819 L<DBIx::Class::Manual::Cookbook>.
3820
3821 =head2 for
3822
3823 =over 4
3824
3825 =item Value: ( 'update' | 'shared' )
3826
3827 =back
3828
3829 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3830 ... FOR SHARED.
3831
3832 =cut
3833
3834 1;