lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360   if ($rows) {
 361     $rs->set_cache($rows);
 362   }
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, $attrs);
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   # if the first row that ever came in is totally empty - this means we got
 978   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 979   # instead of producing a {}
 980   #
 981   my $has_def;
 982   for (@$row) {
 983     if (defined $_) {
 984       $has_def++;
 985       last;
 986     }
 987   }
 988   return undef unless $has_def;
 989
 990   my @copy = @$row;
 991
 992   # 'foo'         => [ undef, 'foo' ]
 993   # 'foo.bar'     => [ 'foo', 'bar' ]
 994   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 995
 996   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 997
 998   my %collapse = %{$self->{_attrs}{collapse}||{}};
 999
1000   my @pri_index;
1001
1002   # if we're doing collapsing (has_many prefetch) we need to grab records
1003   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1004   # we know we don't have to bother.
1005
1006   # the reason for not using the collapse stuff directly is because if you
1007   # had for e.g. two artists in a row with no cds, the collapse info for
1008   # both would be NULL (undef) so you'd lose the second artist
1009
1010   # store just the index so we can check the array positions from the row
1011   # without having to contruct the full hash
1012
1013   if (keys %collapse) {
1014     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1015     foreach my $i (0 .. $#construct_as) {
1016       next if defined($construct_as[$i][0]); # only self table
1017       if (delete $pri{$construct_as[$i][1]}) {
1018         push(@pri_index, $i);
1019       }
1020       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1021     }
1022   }
1023
1024   # no need to do an if, it'll be empty if @pri_index is empty anyway
1025
1026   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1027
1028   my @const_rows;
1029
1030   do { # no need to check anything at the front, we always want the first row
1031
1032     my %const;
1033
1034     foreach my $this_as (@construct_as) {
1035       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1036     }
1037
1038     push(@const_rows, \%const);
1039
1040   } until ( # no pri_index => no collapse => drop straight out
1041       !@pri_index
1042     or
1043       do { # get another row, stash it, drop out if different PK
1044
1045         @copy = $self->cursor->next;
1046         $self->{stashed_row} = \@copy;
1047
1048         # last thing in do block, counts as true if anything doesn't match
1049
1050         # check xor defined first for NULL vs. NOT NULL then if one is
1051         # defined the other must be so check string equality
1052
1053         grep {
1054           (defined $pri_vals{$_} ^ defined $copy[$_])
1055           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1056         } @pri_index;
1057       }
1058   );
1059
1060   my $alias = $self->{attrs}{alias};
1061   my $info = [];
1062
1063   my %collapse_pos;
1064
1065   my @const_keys;
1066
1067   foreach my $const (@const_rows) {
1068     scalar @const_keys or do {
1069       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1070     };
1071     foreach my $key (@const_keys) {
1072       if (length $key) {
1073         my $target = $info;
1074         my @parts = split(/\./, $key);
1075         my $cur = '';
1076         my $data = $const->{$key};
1077         foreach my $p (@parts) {
1078           $target = $target->[1]->{$p} ||= [];
1079           $cur .= ".${p}";
1080           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1081             # collapsing at this point and on final part
1082             my $pos = $collapse_pos{$cur};
1083             CK: foreach my $ck (@ckey) {
1084               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1085                 $collapse_pos{$cur} = $data;
1086                 delete @collapse_pos{ # clear all positioning for sub-entries
1087                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1088                 };
1089                 push(@$target, []);
1090                 last CK;
1091               }
1092             }
1093           }
1094           if (exists $collapse{$cur}) {
1095             $target = $target->[-1];
1096           }
1097         }
1098         $target->[0] = $data;
1099       } else {
1100         $info->[0] = $const->{$key};
1101       }
1102     }
1103   }
1104
1105   return $info;
1106 }
1107
1108 =head2 result_source
1109
1110 =over 4
1111
1112 =item Arguments: $result_source?
1113
1114 =item Return Value: $result_source
1115
1116 =back
1117
1118 An accessor for the primary ResultSource object from which this ResultSet
1119 is derived.
1120
1121 =head2 result_class
1122
1123 =over 4
1124
1125 =item Arguments: $result_class?
1126
1127 =item Return Value: $result_class
1128
1129 =back
1130
1131 An accessor for the class to use when creating row objects. Defaults to
1132 C<< result_source->result_class >> - which in most cases is the name of the
1133 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1134
1135 Note that changing the result_class will also remove any components
1136 that were originally loaded in the source class via
1137 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1138 in the original source class will not run.
1139
1140 =cut
1141
1142 sub result_class {
1143   my ($self, $result_class) = @_;
1144   if ($result_class) {
1145     $self->ensure_class_loaded($result_class);
1146     $self->_result_class($result_class);
1147   }
1148   $self->_result_class;
1149 }
1150
1151 =head2 count
1152
1153 =over 4
1154
1155 =item Arguments: $cond, \%attrs??
1156
1157 =item Return Value: $count
1158
1159 =back
1160
1161 Performs an SQL C<COUNT> with the same query as the resultset was built
1162 with to find the number of elements. Passing arguments is equivalent to
1163 C<< $rs->search ($cond, \%attrs)->count >>
1164
1165 =cut
1166
1167 sub count {
1168   my $self = shift;
1169   return $self->search(@_)->count if @_ and defined $_[0];
1170   return scalar @{ $self->get_cache } if $self->get_cache;
1171
1172   my $attrs = $self->_resolved_attrs_copy;
1173
1174   # this is a little optimization - it is faster to do the limit
1175   # adjustments in software, instead of a subquery
1176   my $rows = delete $attrs->{rows};
1177   my $offset = delete $attrs->{offset};
1178
1179   my $crs;
1180   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1181     $crs = $self->_count_subq_rs ($attrs);
1182   }
1183   else {
1184     $crs = $self->_count_rs ($attrs);
1185   }
1186   my $count = $crs->next;
1187
1188   $count -= $offset if $offset;
1189   $count = $rows if $rows and $rows < $count;
1190   $count = 0 if ($count < 0);
1191
1192   return $count;
1193 }
1194
1195 =head2 count_rs
1196
1197 =over 4
1198
1199 =item Arguments: $cond, \%attrs??
1200
1201 =item Return Value: $count_rs
1202
1203 =back
1204
1205 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1206 This can be very handy for subqueries:
1207
1208   ->search( { amount => $some_rs->count_rs->as_query } )
1209
1210 As with regular resultsets the SQL query will be executed only after
1211 the resultset is accessed via L</next> or L</all>. That would return
1212 the same single value obtainable via L</count>.
1213
1214 =cut
1215
1216 sub count_rs {
1217   my $self = shift;
1218   return $self->search(@_)->count_rs if @_;
1219
1220   # this may look like a lack of abstraction (count() does about the same)
1221   # but in fact an _rs *must* use a subquery for the limits, as the
1222   # software based limiting can not be ported if this $rs is to be used
1223   # in a subquery itself (i.e. ->as_query)
1224   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1225     return $self->_count_subq_rs;
1226   }
1227   else {
1228     return $self->_count_rs;
1229   }
1230 }
1231
1232 #
1233 # returns a ResultSetColumn object tied to the count query
1234 #
1235 sub _count_rs {
1236   my ($self, $attrs) = @_;
1237
1238   my $rsrc = $self->result_source;
1239   $attrs ||= $self->_resolved_attrs;
1240
1241   my $tmp_attrs = { %$attrs };
1242
1243   # take off any limits, record_filter is cdbi, and no point of ordering a count
1244   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   # read the comment on top of the actual function to see what this does
1251   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1252     $tmp_attrs->{from}, $tmp_attrs->{alias}
1253   );
1254
1255   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1256
1257   return $tmp_rs;
1258 }
1259
1260 #
1261 # same as above but uses a subquery
1262 #
1263 sub _count_subq_rs {
1264   my ($self, $attrs) = @_;
1265
1266   my $rsrc = $self->result_source;
1267   $attrs ||= $self->_resolved_attrs_copy;
1268
1269   my $sub_attrs = { %$attrs };
1270
1271   # extra selectors do not go in the subquery and there is no point of ordering it
1272   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1273
1274   # if we prefetch, we group_by primary keys only as this is what we would get out
1275   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1276   if ( keys %{$attrs->{collapse}} ) {
1277     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1278   }
1279
1280   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1281
1282   # read the comment on top of the actual function to see what this does
1283   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1284     $sub_attrs->{from}, $sub_attrs->{alias}
1285   );
1286
1287   # this is so that ordering can be thrown away in things like Top limit
1288   $sub_attrs->{-for_count_only} = 1;
1289
1290   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1291
1292   $attrs->{from} = [{
1293     -alias => 'count_subq',
1294     -source_handle => $rsrc->handle,
1295     count_subq => $sub_rs->as_query,
1296   }];
1297
1298   # the subquery replaces this
1299   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1300
1301   return $self->_count_rs ($attrs);
1302 }
1303
1304
1305 # The DBIC relationship chaining implementation is pretty simple - every
1306 # new related_relationship is pushed onto the {from} stack, and the {select}
1307 # window simply slides further in. This means that when we count somewhere
1308 # in the middle, we got to make sure that everything in the join chain is an
1309 # actual inner join, otherwise the count will come back with unpredictable
1310 # results (a resultset may be generated with _some_ rows regardless of if
1311 # the relation which the $rs currently selects has rows or not). E.g.
1312 # $artist_rs->cds->count - normally generates:
1313 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1314 # which actually returns the number of artists * (number of cds || 1)
1315 #
1316 # So what we do here is crawl {from}, determine if the current alias is at
1317 # the top of the stack, and if not - make sure the chain is inner-joined down
1318 # to the root.
1319 #
1320 sub _switch_to_inner_join_if_needed {
1321   my ($self, $from, $alias) = @_;
1322
1323   # subqueries and other oddness is naturally not supported
1324   return $from if (
1325     ref $from ne 'ARRAY'
1326       ||
1327     @$from <= 1
1328       ||
1329     ref $from->[0] ne 'HASH'
1330       ||
1331     ! $from->[0]{-alias}
1332       ||
1333     $from->[0]{-alias} eq $alias
1334   );
1335
1336   my $switch_branch;
1337   JOINSCAN:
1338   for my $j (@{$from}[1 .. $#$from]) {
1339     if ($j->[0]{-alias} eq $alias) {
1340       $switch_branch = $j->[0]{-join_path};
1341       last JOINSCAN;
1342     }
1343   }
1344
1345   # something else went wrong
1346   return $from unless $switch_branch;
1347
1348   # So it looks like we will have to switch some stuff around.
1349   # local() is useless here as we will be leaving the scope
1350   # anyway, and deep cloning is just too fucking expensive
1351   # So replace the inner hashref manually
1352   my @new_from = ($from->[0]);
1353   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1354
1355   for my $j (@{$from}[1 .. $#$from]) {
1356     my $jalias = $j->[0]{-alias};
1357
1358     if ($sw_idx->{$jalias}) {
1359       my %attrs = %{$j->[0]};
1360       delete $attrs{-join_type};
1361       push @new_from, [
1362         \%attrs,
1363         @{$j}[ 1 .. $#$j ],
1364       ];
1365     }
1366     else {
1367       push @new_from, $j;
1368     }
1369   }
1370
1371   return \@new_from;
1372 }
1373
1374
1375 sub _bool {
1376   return 1;
1377 }
1378
1379 =head2 count_literal
1380
1381 =over 4
1382
1383 =item Arguments: $sql_fragment, @bind_values
1384
1385 =item Return Value: $count
1386
1387 =back
1388
1389 Counts the results in a literal query. Equivalent to calling L</search_literal>
1390 with the passed arguments, then L</count>.
1391
1392 =cut
1393
1394 sub count_literal { shift->search_literal(@_)->count; }
1395
1396 =head2 all
1397
1398 =over 4
1399
1400 =item Arguments: none
1401
1402 =item Return Value: @objects
1403
1404 =back
1405
1406 Returns all elements in the resultset. Called implicitly if the resultset
1407 is returned in list context.
1408
1409 =cut
1410
1411 sub all {
1412   my $self = shift;
1413   if(@_) {
1414       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1415   }
1416
1417   return @{ $self->get_cache } if $self->get_cache;
1418
1419   my @obj;
1420
1421   if (keys %{$self->_resolved_attrs->{collapse}}) {
1422     # Using $self->cursor->all is really just an optimisation.
1423     # If we're collapsing has_many prefetches it probably makes
1424     # very little difference, and this is cleaner than hacking
1425     # _construct_object to survive the approach
1426     $self->cursor->reset;
1427     my @row = $self->cursor->next;
1428     while (@row) {
1429       push(@obj, $self->_construct_object(@row));
1430       @row = (exists $self->{stashed_row}
1431                ? @{delete $self->{stashed_row}}
1432                : $self->cursor->next);
1433     }
1434   } else {
1435     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1436   }
1437
1438   $self->set_cache(\@obj) if $self->{attrs}{cache};
1439
1440   return @obj;
1441 }
1442
1443 =head2 reset
1444
1445 =over 4
1446
1447 =item Arguments: none
1448
1449 =item Return Value: $self
1450
1451 =back
1452
1453 Resets the resultset's cursor, so you can iterate through the elements again.
1454 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1455 another query.
1456
1457 =cut
1458
1459 sub reset {
1460   my ($self) = @_;
1461   delete $self->{_attrs} if exists $self->{_attrs};
1462   $self->{all_cache_position} = 0;
1463   $self->cursor->reset;
1464   return $self;
1465 }
1466
1467 =head2 first
1468
1469 =over 4
1470
1471 =item Arguments: none
1472
1473 =item Return Value: $object?
1474
1475 =back
1476
1477 Resets the resultset and returns an object for the first result (if the
1478 resultset returns anything).
1479
1480 =cut
1481
1482 sub first {
1483   return $_[0]->reset->next;
1484 }
1485
1486
1487 # _rs_update_delete
1488 #
1489 # Determines whether and what type of subquery is required for the $rs operation.
1490 # If grouping is necessary either supplies its own, or verifies the current one
1491 # After all is done delegates to the proper storage method.
1492
1493 sub _rs_update_delete {
1494   my ($self, $op, $values) = @_;
1495
1496   my $rsrc = $self->result_source;
1497
1498   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1499   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1500
1501   if ($needs_group_by_subq or $needs_subq) {
1502
1503     # make a new $rs selecting only the PKs (that's all we really need)
1504     my $attrs = $self->_resolved_attrs_copy;
1505
1506     delete $attrs->{$_} for qw/collapse select as/;
1507     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1508
1509     if ($needs_group_by_subq) {
1510       # make sure no group_by was supplied, or if there is one - make sure it matches
1511       # the columns compiled above perfectly. Anything else can not be sanely executed
1512       # on most databases so croak right then and there
1513
1514       if (my $g = $attrs->{group_by}) {
1515         my @current_group_by = map
1516           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1517           @$g
1518         ;
1519
1520         if (
1521           join ("\x00", sort @current_group_by)
1522             ne
1523           join ("\x00", sort @{$attrs->{columns}} )
1524         ) {
1525           $self->throw_exception (
1526             "You have just attempted a $op operation on a resultset which does group_by"
1527             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1528             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1529             . ' kind of queries. Please retry the operation with a modified group_by or'
1530             . ' without using one at all.'
1531           );
1532         }
1533       }
1534       else {
1535         $attrs->{group_by} = $attrs->{columns};
1536       }
1537     }
1538
1539     my $subrs = (ref $self)->new($rsrc, $attrs);
1540
1541     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1542   }
1543   else {
1544     return $rsrc->storage->$op(
1545       $rsrc,
1546       $op eq 'update' ? $values : (),
1547       $self->_cond_for_update_delete,
1548     );
1549   }
1550 }
1551
1552
1553 # _cond_for_update_delete
1554 #
1555 # update/delete require the condition to be modified to handle
1556 # the differing SQL syntax available.  This transforms the $self->{cond}
1557 # appropriately, returning the new condition.
1558
1559 sub _cond_for_update_delete {
1560   my ($self, $full_cond) = @_;
1561   my $cond = {};
1562
1563   $full_cond ||= $self->{cond};
1564   # No-op. No condition, we're updating/deleting everything
1565   return $cond unless ref $full_cond;
1566
1567   if (ref $full_cond eq 'ARRAY') {
1568     $cond = [
1569       map {
1570         my %hash;
1571         foreach my $key (keys %{$_}) {
1572           $key =~ /([^.]+)$/;
1573           $hash{$1} = $_->{$key};
1574         }
1575         \%hash;
1576       } @{$full_cond}
1577     ];
1578   }
1579   elsif (ref $full_cond eq 'HASH') {
1580     if ((keys %{$full_cond})[0] eq '-and') {
1581       $cond->{-and} = [];
1582       my @cond = @{$full_cond->{-and}};
1583        for (my $i = 0; $i < @cond; $i++) {
1584         my $entry = $cond[$i];
1585         my $hash;
1586         if (ref $entry eq 'HASH') {
1587           $hash = $self->_cond_for_update_delete($entry);
1588         }
1589         else {
1590           $entry =~ /([^.]+)$/;
1591           $hash->{$1} = $cond[++$i];
1592         }
1593         push @{$cond->{-and}}, $hash;
1594       }
1595     }
1596     else {
1597       foreach my $key (keys %{$full_cond}) {
1598         $key =~ /([^.]+)$/;
1599         $cond->{$1} = $full_cond->{$key};
1600       }
1601     }
1602   }
1603   else {
1604     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1605   }
1606
1607   return $cond;
1608 }
1609
1610
1611 =head2 update
1612
1613 =over 4
1614
1615 =item Arguments: \%values
1616
1617 =item Return Value: $storage_rv
1618
1619 =back
1620
1621 Sets the specified columns in the resultset to the supplied values in a
1622 single query. Return value will be true if the update succeeded or false
1623 if no records were updated; exact type of success value is storage-dependent.
1624
1625 =cut
1626
1627 sub update {
1628   my ($self, $values) = @_;
1629   $self->throw_exception('Values for update must be a hash')
1630     unless ref $values eq 'HASH';
1631
1632   return $self->_rs_update_delete ('update', $values);
1633 }
1634
1635 =head2 update_all
1636
1637 =over 4
1638
1639 =item Arguments: \%values
1640
1641 =item Return Value: 1
1642
1643 =back
1644
1645 Fetches all objects and updates them one at a time. Note that C<update_all>
1646 will run DBIC cascade triggers, while L</update> will not.
1647
1648 =cut
1649
1650 sub update_all {
1651   my ($self, $values) = @_;
1652   $self->throw_exception('Values for update_all must be a hash')
1653     unless ref $values eq 'HASH';
1654   foreach my $obj ($self->all) {
1655     $obj->set_columns($values)->update;
1656   }
1657   return 1;
1658 }
1659
1660 =head2 delete
1661
1662 =over 4
1663
1664 =item Arguments: none
1665
1666 =item Return Value: $storage_rv
1667
1668 =back
1669
1670 Deletes the contents of the resultset from its result source. Note that this
1671 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1672 to run. See also L<DBIx::Class::Row/delete>.
1673
1674 Return value will be the amount of rows deleted; exact type of return value
1675 is storage-dependent.
1676
1677 =cut
1678
1679 sub delete {
1680   my $self = shift;
1681   $self->throw_exception('delete does not accept any arguments')
1682     if @_;
1683
1684   return $self->_rs_update_delete ('delete');
1685 }
1686
1687 =head2 delete_all
1688
1689 =over 4
1690
1691 =item Arguments: none
1692
1693 =item Return Value: 1
1694
1695 =back
1696
1697 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1698 will run DBIC cascade triggers, while L</delete> will not.
1699
1700 =cut
1701
1702 sub delete_all {
1703   my $self = shift;
1704   $self->throw_exception('delete_all does not accept any arguments')
1705     if @_;
1706
1707   $_->delete for $self->all;
1708   return 1;
1709 }
1710
1711 =head2 populate
1712
1713 =over 4
1714
1715 =item Arguments: \@data;
1716
1717 =back
1718
1719 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1720 For the arrayref of hashrefs style each hashref should be a structure suitable
1721 forsubmitting to a $resultset->create(...) method.
1722
1723 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1724 to insert the data, as this is a faster method.
1725
1726 Otherwise, each set of data is inserted into the database using
1727 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1728 accumulated into an array. The array itself, or an array reference
1729 is returned depending on scalar or list context.
1730
1731 Example:  Assuming an Artist Class that has many CDs Classes relating:
1732
1733   my $Artist_rs = $schema->resultset("Artist");
1734
1735   ## Void Context Example
1736   $Artist_rs->populate([
1737      { artistid => 4, name => 'Manufactured Crap', cds => [
1738         { title => 'My First CD', year => 2006 },
1739         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1740       ],
1741      },
1742      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1743         { title => 'My parents sold me to a record company' ,year => 2005 },
1744         { title => 'Why Am I So Ugly?', year => 2006 },
1745         { title => 'I Got Surgery and am now Popular', year => 2007 }
1746       ],
1747      },
1748   ]);
1749
1750   ## Array Context Example
1751   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1752     { name => "Artist One"},
1753     { name => "Artist Two"},
1754     { name => "Artist Three", cds=> [
1755     { title => "First CD", year => 2007},
1756     { title => "Second CD", year => 2008},
1757   ]}
1758   ]);
1759
1760   print $ArtistOne->name; ## response is 'Artist One'
1761   print $ArtistThree->cds->count ## reponse is '2'
1762
1763 For the arrayref of arrayrefs style,  the first element should be a list of the
1764 fieldsnames to which the remaining elements are rows being inserted.  For
1765 example:
1766
1767   $Arstist_rs->populate([
1768     [qw/artistid name/],
1769     [100, 'A Formally Unknown Singer'],
1770     [101, 'A singer that jumped the shark two albums ago'],
1771     [102, 'An actually cool singer.'],
1772   ]);
1773
1774 Please note an important effect on your data when choosing between void and
1775 wantarray context. Since void context goes straight to C<insert_bulk> in
1776 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1777 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1778 create primary keys for you, you will find that your PKs are empty.  In this
1779 case you will have to use the wantarray context in order to create those
1780 values.
1781
1782 =cut
1783
1784 sub populate {
1785   my $self = shift @_;
1786   my $data = ref $_[0][0] eq 'HASH'
1787     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1788     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1789
1790   if(defined wantarray) {
1791     my @created;
1792     foreach my $item (@$data) {
1793       push(@created, $self->create($item));
1794     }
1795     return wantarray ? @created : \@created;
1796   } else {
1797     my ($first, @rest) = @$data;
1798
1799     my @names = grep {!ref $first->{$_}} keys %$first;
1800     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1801     my @pks = $self->result_source->primary_columns;
1802
1803     ## do the belongs_to relationships
1804     foreach my $index (0..$#$data) {
1805
1806       # delegate to create() for any dataset without primary keys with specified relationships
1807       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1808         for my $r (@rels) {
1809           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1810             my @ret = $self->populate($data);
1811             return;
1812           }
1813         }
1814       }
1815
1816       foreach my $rel (@rels) {
1817         next unless ref $data->[$index]->{$rel} eq "HASH";
1818         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1819         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1820         my $related = $result->result_source->_resolve_condition(
1821           $result->result_source->relationship_info($reverse)->{cond},
1822           $self,
1823           $result,
1824         );
1825
1826         delete $data->[$index]->{$rel};
1827         $data->[$index] = {%{$data->[$index]}, %$related};
1828
1829         push @names, keys %$related if $index == 0;
1830       }
1831     }
1832
1833     ## do bulk insert on current row
1834     my @values = map { [ @$_{@names} ] } @$data;
1835
1836     $self->result_source->storage->insert_bulk(
1837       $self->result_source,
1838       \@names,
1839       \@values,
1840     );
1841
1842     ## do the has_many relationships
1843     foreach my $item (@$data) {
1844
1845       foreach my $rel (@rels) {
1846         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1847
1848         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1849      || $self->throw_exception('Cannot find the relating object.');
1850
1851         my $child = $parent->$rel;
1852
1853         my $related = $child->result_source->_resolve_condition(
1854           $parent->result_source->relationship_info($rel)->{cond},
1855           $child,
1856           $parent,
1857         );
1858
1859         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1860         my @populate = map { {%$_, %$related} } @rows_to_add;
1861
1862         $child->populate( \@populate );
1863       }
1864     }
1865   }
1866 }
1867
1868 =head2 _normalize_populate_args ($args)
1869
1870 Private method used by L</populate> to normalize its incoming arguments.  Factored
1871 out in case you want to subclass and accept new argument structures to the
1872 L</populate> method.
1873
1874 =cut
1875
1876 sub _normalize_populate_args {
1877   my ($self, $data) = @_;
1878   my @names = @{shift(@$data)};
1879   my @results_to_create;
1880   foreach my $datum (@$data) {
1881     my %result_to_create;
1882     foreach my $index (0..$#names) {
1883       $result_to_create{$names[$index]} = $$datum[$index];
1884     }
1885     push @results_to_create, \%result_to_create;
1886   }
1887   return \@results_to_create;
1888 }
1889
1890 =head2 pager
1891
1892 =over 4
1893
1894 =item Arguments: none
1895
1896 =item Return Value: $pager
1897
1898 =back
1899
1900 Return Value a L<Data::Page> object for the current resultset. Only makes
1901 sense for queries with a C<page> attribute.
1902
1903 To get the full count of entries for a paged resultset, call
1904 C<total_entries> on the L<Data::Page> object.
1905
1906 =cut
1907
1908 sub pager {
1909   my ($self) = @_;
1910
1911   return $self->{pager} if $self->{pager};
1912
1913   my $attrs = $self->{attrs};
1914   $self->throw_exception("Can't create pager for non-paged rs")
1915     unless $self->{attrs}{page};
1916   $attrs->{rows} ||= 10;
1917
1918   # throw away the paging flags and re-run the count (possibly
1919   # with a subselect) to get the real total count
1920   my $count_attrs = { %$attrs };
1921   delete $count_attrs->{$_} for qw/rows offset page pager/;
1922   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1923
1924   return $self->{pager} = Data::Page->new(
1925     $total_count,
1926     $attrs->{rows},
1927     $self->{attrs}{page}
1928   );
1929 }
1930
1931 =head2 page
1932
1933 =over 4
1934
1935 =item Arguments: $page_number
1936
1937 =item Return Value: $rs
1938
1939 =back
1940
1941 Returns a resultset for the $page_number page of the resultset on which page
1942 is called, where each page contains a number of rows equal to the 'rows'
1943 attribute set on the resultset (10 by default).
1944
1945 =cut
1946
1947 sub page {
1948   my ($self, $page) = @_;
1949   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1950 }
1951
1952 =head2 new_result
1953
1954 =over 4
1955
1956 =item Arguments: \%vals
1957
1958 =item Return Value: $rowobject
1959
1960 =back
1961
1962 Creates a new row object in the resultset's result class and returns
1963 it. The row is not inserted into the database at this point, call
1964 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1965 will tell you whether the row object has been inserted or not.
1966
1967 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1968
1969 =cut
1970
1971 sub new_result {
1972   my ($self, $values) = @_;
1973   $self->throw_exception( "new_result needs a hash" )
1974     unless (ref $values eq 'HASH');
1975
1976   my %new;
1977   my $alias = $self->{attrs}{alias};
1978
1979   if (
1980     defined $self->{cond}
1981     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1982   ) {
1983     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1984     $new{-from_resultset} = [ keys %new ] if keys %new;
1985   } else {
1986     $self->throw_exception(
1987       "Can't abstract implicit construct, condition not a hash"
1988     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1989
1990     my $collapsed_cond = (
1991       $self->{cond}
1992         ? $self->_collapse_cond($self->{cond})
1993         : {}
1994     );
1995
1996     # precendence must be given to passed values over values inherited from
1997     # the cond, so the order here is important.
1998     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1999     while( my($col,$value) = each %implied ){
2000       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
2001         $new{$col} = $value->{'='};
2002         next;
2003       }
2004       $new{$col} = $value if $self->_is_deterministic_value($value);
2005     }
2006   }
2007
2008   %new = (
2009     %new,
2010     %{ $self->_remove_alias($values, $alias) },
2011     -source_handle => $self->_source_handle,
2012     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2013   );
2014
2015   return $self->result_class->new(\%new);
2016 }
2017
2018 # _is_deterministic_value
2019 #
2020 # Make an effor to strip non-deterministic values from the condition,
2021 # to make sure new_result chokes less
2022
2023 sub _is_deterministic_value {
2024   my $self = shift;
2025   my $value = shift;
2026   my $ref_type = ref $value;
2027   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2028   return 1 if Scalar::Util::blessed($value);
2029   return 0;
2030 }
2031
2032 # _has_resolved_attr
2033 #
2034 # determines if the resultset defines at least one
2035 # of the attributes supplied
2036 #
2037 # used to determine if a subquery is neccessary
2038 #
2039 # supports some virtual attributes:
2040 #   -join
2041 #     This will scan for any joins being present on the resultset.
2042 #     It is not a mere key-search but a deep inspection of {from}
2043 #
2044
2045 sub _has_resolved_attr {
2046   my ($self, @attr_names) = @_;
2047
2048   my $attrs = $self->_resolved_attrs;
2049
2050   my %extra_checks;
2051
2052   for my $n (@attr_names) {
2053     if (grep { $n eq $_ } (qw/-join/) ) {
2054       $extra_checks{$n}++;
2055       next;
2056     }
2057
2058     my $attr =  $attrs->{$n};
2059
2060     next if not defined $attr;
2061
2062     if (ref $attr eq 'HASH') {
2063       return 1 if keys %$attr;
2064     }
2065     elsif (ref $attr eq 'ARRAY') {
2066       return 1 if @$attr;
2067     }
2068     else {
2069       return 1 if $attr;
2070     }
2071   }
2072
2073   # a resolved join is expressed as a multi-level from
2074   return 1 if (
2075     $extra_checks{-join}
2076       and
2077     ref $attrs->{from} eq 'ARRAY'
2078       and
2079     @{$attrs->{from}} > 1
2080   );
2081
2082   return 0;
2083 }
2084
2085 # _collapse_cond
2086 #
2087 # Recursively collapse the condition.
2088
2089 sub _collapse_cond {
2090   my ($self, $cond, $collapsed) = @_;
2091
2092   $collapsed ||= {};
2093
2094   if (ref $cond eq 'ARRAY') {
2095     foreach my $subcond (@$cond) {
2096       next unless ref $subcond;  # -or
2097       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2098     }
2099   }
2100   elsif (ref $cond eq 'HASH') {
2101     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2102       foreach my $subcond (@{$cond->{-and}}) {
2103         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2104       }
2105     }
2106     else {
2107       foreach my $col (keys %$cond) {
2108         my $value = $cond->{$col};
2109         $collapsed->{$col} = $value;
2110       }
2111     }
2112   }
2113
2114   return $collapsed;
2115 }
2116
2117 # _remove_alias
2118 #
2119 # Remove the specified alias from the specified query hash. A copy is made so
2120 # the original query is not modified.
2121
2122 sub _remove_alias {
2123   my ($self, $query, $alias) = @_;
2124
2125   my %orig = %{ $query || {} };
2126   my %unaliased;
2127
2128   foreach my $key (keys %orig) {
2129     if ($key !~ /\./) {
2130       $unaliased{$key} = $orig{$key};
2131       next;
2132     }
2133     $unaliased{$1} = $orig{$key}
2134       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2135   }
2136
2137   return \%unaliased;
2138 }
2139
2140 =head2 as_query (EXPERIMENTAL)
2141
2142 =over 4
2143
2144 =item Arguments: none
2145
2146 =item Return Value: \[ $sql, @bind ]
2147
2148 =back
2149
2150 Returns the SQL query and bind vars associated with the invocant.
2151
2152 This is generally used as the RHS for a subquery.
2153
2154 B<NOTE>: This feature is still experimental.
2155
2156 =cut
2157
2158 sub as_query {
2159   my $self = shift;
2160
2161   my $attrs = $self->_resolved_attrs_copy;
2162
2163   # For future use:
2164   #
2165   # in list ctx:
2166   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2167   # $sql also has no wrapping parenthesis in list ctx
2168   #
2169   my $sqlbind = $self->result_source->storage
2170     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2171
2172   return $sqlbind;
2173 }
2174
2175 =head2 find_or_new
2176
2177 =over 4
2178
2179 =item Arguments: \%vals, \%attrs?
2180
2181 =item Return Value: $rowobject
2182
2183 =back
2184
2185   my $artist = $schema->resultset('Artist')->find_or_new(
2186     { artist => 'fred' }, { key => 'artists' });
2187
2188   $cd->cd_to_producer->find_or_new({ producer => $producer },
2189                                    { key => 'primary });
2190
2191 Find an existing record from this resultset, based on its primary
2192 key, or a unique constraint. If none exists, instantiate a new result
2193 object and return it. The object will not be saved into your storage
2194 until you call L<DBIx::Class::Row/insert> on it.
2195
2196 You most likely want this method when looking for existing rows using
2197 a unique constraint that is not the primary key, or looking for
2198 related rows.
2199
2200 If you want objects to be saved immediately, use L</find_or_create>
2201 instead.
2202
2203 B<Note>: Take care when using C<find_or_new> with a table having
2204 columns with default values that you intend to be automatically
2205 supplied by the database (e.g. an auto_increment primary key column).
2206 In normal usage, the value of such columns should NOT be included at
2207 all in the call to C<find_or_new>, even when set to C<undef>.
2208
2209 =cut
2210
2211 sub find_or_new {
2212   my $self     = shift;
2213   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2214   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2215   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2216     return $row;
2217   }
2218   return $self->new_result($hash);
2219 }
2220
2221 =head2 create
2222
2223 =over 4
2224
2225 =item Arguments: \%vals
2226
2227 =item Return Value: a L<DBIx::Class::Row> $object
2228
2229 =back
2230
2231 Attempt to create a single new row or a row with multiple related rows
2232 in the table represented by the resultset (and related tables). This
2233 will not check for duplicate rows before inserting, use
2234 L</find_or_create> to do that.
2235
2236 To create one row for this resultset, pass a hashref of key/value
2237 pairs representing the columns of the table and the values you wish to
2238 store. If the appropriate relationships are set up, foreign key fields
2239 can also be passed an object representing the foreign row, and the
2240 value will be set to its primary key.
2241
2242 To create related objects, pass a hashref of related-object column values
2243 B<keyed on the relationship name>. If the relationship is of type C<multi>
2244 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2245 The process will correctly identify columns holding foreign keys, and will
2246 transparrently populate them from the keys of the corresponding relation.
2247 This can be applied recursively, and will work correctly for a structure
2248 with an arbitrary depth and width, as long as the relationships actually
2249 exists and the correct column data has been supplied.
2250
2251
2252 Instead of hashrefs of plain related data (key/value pairs), you may
2253 also pass new or inserted objects. New objects (not inserted yet, see
2254 L</new>), will be inserted into their appropriate tables.
2255
2256 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2257
2258 Example of creating a new row.
2259
2260   $person_rs->create({
2261     name=>"Some Person",
2262     email=>"somebody@someplace.com"
2263   });
2264
2265 Example of creating a new row and also creating rows in a related C<has_many>
2266 or C<has_one> resultset.  Note Arrayref.
2267
2268   $artist_rs->create(
2269      { artistid => 4, name => 'Manufactured Crap', cds => [
2270         { title => 'My First CD', year => 2006 },
2271         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2272       ],
2273      },
2274   );
2275
2276 Example of creating a new row and also creating a row in a related
2277 C<belongs_to>resultset. Note Hashref.
2278
2279   $cd_rs->create({
2280     title=>"Music for Silly Walks",
2281     year=>2000,
2282     artist => {
2283       name=>"Silly Musician",
2284     }
2285   });
2286
2287 =over
2288
2289 =item WARNING
2290
2291 When subclassing ResultSet never attempt to override this method. Since
2292 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2293 lot of the internals simply never call it, so your override will be
2294 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2295 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2296 L</create> process you need to intervene.
2297
2298 =back
2299
2300 =cut
2301
2302 sub create {
2303   my ($self, $attrs) = @_;
2304   $self->throw_exception( "create needs a hashref" )
2305     unless ref $attrs eq 'HASH';
2306   return $self->new_result($attrs)->insert;
2307 }
2308
2309 =head2 find_or_create
2310
2311 =over 4
2312
2313 =item Arguments: \%vals, \%attrs?
2314
2315 =item Return Value: $rowobject
2316
2317 =back
2318
2319   $cd->cd_to_producer->find_or_create({ producer => $producer },
2320                                       { key => 'primary' });
2321
2322 Tries to find a record based on its primary key or unique constraints; if none
2323 is found, creates one and returns that instead.
2324
2325   my $cd = $schema->resultset('CD')->find_or_create({
2326     cdid   => 5,
2327     artist => 'Massive Attack',
2328     title  => 'Mezzanine',
2329     year   => 2005,
2330   });
2331
2332 Also takes an optional C<key> attribute, to search by a specific key or unique
2333 constraint. For example:
2334
2335   my $cd = $schema->resultset('CD')->find_or_create(
2336     {
2337       artist => 'Massive Attack',
2338       title  => 'Mezzanine',
2339     },
2340     { key => 'cd_artist_title' }
2341   );
2342
2343 B<Note>: Because find_or_create() reads from the database and then
2344 possibly inserts based on the result, this method is subject to a race
2345 condition. Another process could create a record in the table after
2346 the find has completed and before the create has started. To avoid
2347 this problem, use find_or_create() inside a transaction.
2348
2349 B<Note>: Take care when using C<find_or_create> with a table having
2350 columns with default values that you intend to be automatically
2351 supplied by the database (e.g. an auto_increment primary key column).
2352 In normal usage, the value of such columns should NOT be included at
2353 all in the call to C<find_or_create>, even when set to C<undef>.
2354
2355 See also L</find> and L</update_or_create>. For information on how to declare
2356 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2357
2358 =cut
2359
2360 sub find_or_create {
2361   my $self     = shift;
2362   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2363   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2364   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2365     return $row;
2366   }
2367   return $self->create($hash);
2368 }
2369
2370 =head2 update_or_create
2371
2372 =over 4
2373
2374 =item Arguments: \%col_values, { key => $unique_constraint }?
2375
2376 =item Return Value: $rowobject
2377
2378 =back
2379
2380   $resultset->update_or_create({ col => $val, ... });
2381
2382 First, searches for an existing row matching one of the unique constraints
2383 (including the primary key) on the source of this resultset. If a row is
2384 found, updates it with the other given column values. Otherwise, creates a new
2385 row.
2386
2387 Takes an optional C<key> attribute to search on a specific unique constraint.
2388 For example:
2389
2390   # In your application
2391   my $cd = $schema->resultset('CD')->update_or_create(
2392     {
2393       artist => 'Massive Attack',
2394       title  => 'Mezzanine',
2395       year   => 1998,
2396     },
2397     { key => 'cd_artist_title' }
2398   );
2399
2400   $cd->cd_to_producer->update_or_create({
2401     producer => $producer,
2402     name => 'harry',
2403   }, {
2404     key => 'primary,
2405   });
2406
2407
2408 If no C<key> is specified, it searches on all unique constraints defined on the
2409 source, including the primary key.
2410
2411 If the C<key> is specified as C<primary>, it searches only on the primary key.
2412
2413 See also L</find> and L</find_or_create>. For information on how to declare
2414 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2415
2416 B<Note>: Take care when using C<update_or_create> with a table having
2417 columns with default values that you intend to be automatically
2418 supplied by the database (e.g. an auto_increment primary key column).
2419 In normal usage, the value of such columns should NOT be included at
2420 all in the call to C<update_or_create>, even when set to C<undef>.
2421
2422 =cut
2423
2424 sub update_or_create {
2425   my $self = shift;
2426   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2427   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2428
2429   my $row = $self->find($cond, $attrs);
2430   if (defined $row) {
2431     $row->update($cond);
2432     return $row;
2433   }
2434
2435   return $self->create($cond);
2436 }
2437
2438 =head2 update_or_new
2439
2440 =over 4
2441
2442 =item Arguments: \%col_values, { key => $unique_constraint }?
2443
2444 =item Return Value: $rowobject
2445
2446 =back
2447
2448   $resultset->update_or_new({ col => $val, ... });
2449
2450 First, searches for an existing row matching one of the unique constraints
2451 (including the primary key) on the source of this resultset. If a row is
2452 found, updates it with the other given column values. Otherwise, instantiate
2453 a new result object and return it. The object will not be saved into your storage
2454 until you call L<DBIx::Class::Row/insert> on it.
2455
2456 Takes an optional C<key> attribute to search on a specific unique constraint.
2457 For example:
2458
2459   # In your application
2460   my $cd = $schema->resultset('CD')->update_or_new(
2461     {
2462       artist => 'Massive Attack',
2463       title  => 'Mezzanine',
2464       year   => 1998,
2465     },
2466     { key => 'cd_artist_title' }
2467   );
2468
2469   if ($cd->in_storage) {
2470       # the cd was updated
2471   }
2472   else {
2473       # the cd is not yet in the database, let's insert it
2474       $cd->insert;
2475   }
2476
2477 B<Note>: Take care when using C<update_or_new> with a table having
2478 columns with default values that you intend to be automatically
2479 supplied by the database (e.g. an auto_increment primary key column).
2480 In normal usage, the value of such columns should NOT be included at
2481 all in the call to C<update_or_new>, even when set to C<undef>.
2482
2483 See also L</find>, L</find_or_create> and L</find_or_new>.
2484
2485 =cut
2486
2487 sub update_or_new {
2488     my $self  = shift;
2489     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2490     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2491
2492     my $row = $self->find( $cond, $attrs );
2493     if ( defined $row ) {
2494         $row->update($cond);
2495         return $row;
2496     }
2497
2498     return $self->new_result($cond);
2499 }
2500
2501 =head2 get_cache
2502
2503 =over 4
2504
2505 =item Arguments: none
2506
2507 =item Return Value: \@cache_objects?
2508
2509 =back
2510
2511 Gets the contents of the cache for the resultset, if the cache is set.
2512
2513 The cache is populated either by using the L</prefetch> attribute to
2514 L</search> or by calling L</set_cache>.
2515
2516 =cut
2517
2518 sub get_cache {
2519   shift->{all_cache};
2520 }
2521
2522 =head2 set_cache
2523
2524 =over 4
2525
2526 =item Arguments: \@cache_objects
2527
2528 =item Return Value: \@cache_objects
2529
2530 =back
2531
2532 Sets the contents of the cache for the resultset. Expects an arrayref
2533 of objects of the same class as those produced by the resultset. Note that
2534 if the cache is set the resultset will return the cached objects rather
2535 than re-querying the database even if the cache attr is not set.
2536
2537 The contents of the cache can also be populated by using the
2538 L</prefetch> attribute to L</search>.
2539
2540 =cut
2541
2542 sub set_cache {
2543   my ( $self, $data ) = @_;
2544   $self->throw_exception("set_cache requires an arrayref")
2545       if defined($data) && (ref $data ne 'ARRAY');
2546   $self->{all_cache} = $data;
2547 }
2548
2549 =head2 clear_cache
2550
2551 =over 4
2552
2553 =item Arguments: none
2554
2555 =item Return Value: []
2556
2557 =back
2558
2559 Clears the cache for the resultset.
2560
2561 =cut
2562
2563 sub clear_cache {
2564   shift->set_cache(undef);
2565 }
2566
2567 =head2 related_resultset
2568
2569 =over 4
2570
2571 =item Arguments: $relationship_name
2572
2573 =item Return Value: $resultset
2574
2575 =back
2576
2577 Returns a related resultset for the supplied relationship name.
2578
2579   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2580
2581 =cut
2582
2583 sub related_resultset {
2584   my ($self, $rel) = @_;
2585
2586   $self->{related_resultsets} ||= {};
2587   return $self->{related_resultsets}{$rel} ||= do {
2588     my $rel_info = $self->result_source->relationship_info($rel);
2589
2590     $self->throw_exception(
2591       "search_related: result source '" . $self->result_source->source_name .
2592         "' has no such relationship $rel")
2593       unless $rel_info;
2594
2595     my ($from,$seen) = $self->_chain_relationship($rel);
2596
2597     my $join_count = $seen->{$rel};
2598     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2599
2600     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2601     my %attrs = %{$self->{attrs}||{}};
2602     delete @attrs{qw(result_class alias)};
2603
2604     my $new_cache;
2605
2606     if (my $cache = $self->get_cache) {
2607       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2608         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2609                         @$cache ];
2610       }
2611     }
2612
2613     my $rel_source = $self->result_source->related_source($rel);
2614
2615     my $new = do {
2616
2617       # The reason we do this now instead of passing the alias to the
2618       # search_rs below is that if you wrap/overload resultset on the
2619       # source you need to know what alias it's -going- to have for things
2620       # to work sanely (e.g. RestrictWithObject wants to be able to add
2621       # extra query restrictions, and these may need to be $alias.)
2622
2623       my $attrs = $rel_source->resultset_attributes;
2624       local $attrs->{alias} = $alias;
2625
2626       $rel_source->resultset
2627                  ->search_rs(
2628                      undef, {
2629                        %attrs,
2630                        join => undef,
2631                        prefetch => undef,
2632                        select => undef,
2633                        as => undef,
2634                        where => $self->{cond},
2635                        seen_join => $seen,
2636                        from => $from,
2637                    });
2638     };
2639     $new->set_cache($new_cache) if $new_cache;
2640     $new;
2641   };
2642 }
2643
2644 =head2 current_source_alias
2645
2646 =over 4
2647
2648 =item Arguments: none
2649
2650 =item Return Value: $source_alias
2651
2652 =back
2653
2654 Returns the current table alias for the result source this resultset is built
2655 on, that will be used in the SQL query. Usually it is C<me>.
2656
2657 Currently the source alias that refers to the result set returned by a
2658 L</search>/L</find> family method depends on how you got to the resultset: it's
2659 C<me> by default, but eg. L</search_related> aliases it to the related result
2660 source name (and keeps C<me> referring to the original result set). The long
2661 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2662 (and make this method unnecessary).
2663
2664 Thus it's currently necessary to use this method in predefined queries (see
2665 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2666 source alias of the current result set:
2667
2668   # in a result set class
2669   sub modified_by {
2670     my ($self, $user) = @_;
2671
2672     my $me = $self->current_source_alias;
2673
2674     return $self->search(
2675       "$me.modified" => $user->id,
2676     );
2677   }
2678
2679 =cut
2680
2681 sub current_source_alias {
2682   my ($self) = @_;
2683
2684   return ($self->{attrs} || {})->{alias} || 'me';
2685 }
2686
2687 # This code is called by search_related, and makes sure there
2688 # is clear separation between the joins before, during, and
2689 # after the relationship. This information is needed later
2690 # in order to properly resolve prefetch aliases (any alias
2691 # with a relation_chain_depth less than the depth of the
2692 # current prefetch is not considered)
2693 #
2694 # The increments happen in 1/2s to make it easier to correlate the
2695 # join depth with the join path. An integer means a relationship
2696 # specified via a search_related, whereas a fraction means an added
2697 # join/prefetch via attributes
2698 sub _chain_relationship {
2699   my ($self, $rel) = @_;
2700   my $source = $self->result_source;
2701   my $attrs = $self->{attrs};
2702
2703   my $from = [ @{
2704       $attrs->{from}
2705         ||
2706       [{
2707         -source_handle => $source->handle,
2708         -alias => $attrs->{alias},
2709         $attrs->{alias} => $source->from,
2710       }]
2711   }];
2712
2713   my $seen = { %{$attrs->{seen_join} || {} } };
2714   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2715     ? $from->[-1][0]{-join_path}
2716     : [];
2717
2718
2719   # we need to take the prefetch the attrs into account before we
2720   # ->_resolve_join as otherwise they get lost - captainL
2721   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2722
2723   my @requested_joins = $source->_resolve_join(
2724     $merged,
2725     $attrs->{alias},
2726     $seen,
2727     $jpath,
2728   );
2729
2730   push @$from, @requested_joins;
2731
2732   $seen->{-relation_chain_depth} += 0.5;
2733
2734   # if $self already had a join/prefetch specified on it, the requested
2735   # $rel might very well be already included. What we do in this case
2736   # is effectively a no-op (except that we bump up the chain_depth on
2737   # the join in question so we could tell it *is* the search_related)
2738   my $already_joined;
2739
2740
2741   # we consider the last one thus reverse
2742   for my $j (reverse @requested_joins) {
2743     if ($rel eq $j->[0]{-join_path}[-1]) {
2744       $j->[0]{-relation_chain_depth} += 0.5;
2745       $already_joined++;
2746       last;
2747     }
2748   }
2749
2750 # alternative way to scan the entire chain - not backwards compatible
2751 #  for my $j (reverse @$from) {
2752 #    next unless ref $j eq 'ARRAY';
2753 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2754 #      $j->[0]{-relation_chain_depth} += 0.5;
2755 #      $already_joined++;
2756 #      last;
2757 #    }
2758 #  }
2759
2760   unless ($already_joined) {
2761     push @$from, $source->_resolve_join(
2762       $rel,
2763       $attrs->{alias},
2764       $seen,
2765       $jpath,
2766     );
2767   }
2768
2769   $seen->{-relation_chain_depth} += 0.5;
2770
2771   return ($from,$seen);
2772 }
2773
2774 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2775 sub _resolved_attrs_copy {
2776   my $self = shift;
2777   return { %{$self->_resolved_attrs (@_)} };
2778 }
2779
2780 sub _resolved_attrs {
2781   my $self = shift;
2782   return $self->{_attrs} if $self->{_attrs};
2783
2784   my $attrs  = { %{ $self->{attrs} || {} } };
2785   my $source = $self->result_source;
2786   my $alias  = $attrs->{alias};
2787
2788   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2789   my @colbits;
2790
2791   # build columns (as long as select isn't set) into a set of as/select hashes
2792   unless ( $attrs->{select} ) {
2793
2794     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2795       ? @{ delete $attrs->{columns}}
2796       : (
2797           ( delete $attrs->{columns} )
2798             ||
2799           $source->storage->_order_select_columns(
2800               $source,
2801               [ $source->columns ],
2802           )
2803         )
2804     ;
2805
2806     @colbits = map {
2807       ( ref($_) eq 'HASH' )
2808       ? $_
2809       : {
2810           (
2811             /^\Q${alias}.\E(.+)$/
2812               ? "$1"
2813               : "$_"
2814           )
2815             =>
2816           (
2817             /\./
2818               ? "$_"
2819               : "${alias}.$_"
2820           )
2821         }
2822     } @cols;
2823   }
2824
2825   # add the additional columns on
2826   foreach ( 'include_columns', '+columns' ) {
2827       push @colbits, map {
2828           ( ref($_) eq 'HASH' )
2829             ? $_
2830             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2831       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2832   }
2833
2834   # start with initial select items
2835   if ( $attrs->{select} ) {
2836     $attrs->{select} =
2837         ( ref $attrs->{select} eq 'ARRAY' )
2838       ? [ @{ $attrs->{select} } ]
2839       : [ $attrs->{select} ];
2840     $attrs->{as} = (
2841       $attrs->{as}
2842       ? (
2843         ref $attrs->{as} eq 'ARRAY'
2844         ? [ @{ $attrs->{as} } ]
2845         : [ $attrs->{as} ]
2846         )
2847       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2848     );
2849   }
2850   else {
2851
2852     # otherwise we intialise select & as to empty
2853     $attrs->{select} = [];
2854     $attrs->{as}     = [];
2855   }
2856
2857   # now add colbits to select/as
2858   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2859   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2860
2861   my $adds;
2862   if ( $adds = delete $attrs->{'+select'} ) {
2863     $adds = [$adds] unless ref $adds eq 'ARRAY';
2864     push(
2865       @{ $attrs->{select} },
2866       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2867     );
2868   }
2869   if ( $adds = delete $attrs->{'+as'} ) {
2870     $adds = [$adds] unless ref $adds eq 'ARRAY';
2871     push( @{ $attrs->{as} }, @$adds );
2872   }
2873
2874   $attrs->{from} ||= [ {
2875     -source_handle => $source->handle,
2876     -alias => $self->{attrs}{alias},
2877     $self->{attrs}{alias} => $source->from,
2878   } ];
2879
2880   if ( $attrs->{join} || $attrs->{prefetch} ) {
2881
2882     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2883       if ref $attrs->{from} ne 'ARRAY';
2884
2885     my $join = delete $attrs->{join} || {};
2886
2887     if ( defined $attrs->{prefetch} ) {
2888       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2889     }
2890
2891     $attrs->{from} =    # have to copy here to avoid corrupting the original
2892       [
2893         @{ $attrs->{from} },
2894         $source->_resolve_join(
2895           $join,
2896           $alias,
2897           { %{ $attrs->{seen_join} || {} } },
2898           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2899             ? $attrs->{from}[-1][0]{-join_path}
2900             : []
2901           ,
2902         )
2903       ];
2904   }
2905
2906   if ( defined $attrs->{order_by} ) {
2907     $attrs->{order_by} = (
2908       ref( $attrs->{order_by} ) eq 'ARRAY'
2909       ? [ @{ $attrs->{order_by} } ]
2910       : [ $attrs->{order_by} || () ]
2911     );
2912   }
2913
2914   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2915     $attrs->{group_by} = [ $attrs->{group_by} ];
2916   }
2917
2918   # generate the distinct induced group_by early, as prefetch will be carried via a
2919   # subquery (since a group_by is present)
2920   if (delete $attrs->{distinct}) {
2921     if ($attrs->{group_by}) {
2922       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2923     }
2924     else {
2925       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2926     }
2927   }
2928
2929   $attrs->{collapse} ||= {};
2930   if ( my $prefetch = delete $attrs->{prefetch} ) {
2931     $prefetch = $self->_merge_attr( {}, $prefetch );
2932
2933     my $prefetch_ordering = [];
2934
2935     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2936
2937     my @prefetch =
2938       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2939
2940     # we need to somehow mark which columns came from prefetch
2941     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2942
2943     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2944     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2945
2946     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2947     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2948   }
2949
2950   # if both page and offset are specified, produce a combined offset
2951   # even though it doesn't make much sense, this is what pre 081xx has
2952   # been doing
2953   if (my $page = delete $attrs->{page}) {
2954     $attrs->{offset} =
2955       ($attrs->{rows} * ($page - 1))
2956             +
2957       ($attrs->{offset} || 0)
2958     ;
2959   }
2960
2961   return $self->{_attrs} = $attrs;
2962 }
2963
2964 sub _joinpath_aliases {
2965   my ($self, $fromspec, $seen) = @_;
2966
2967   my $paths = {};
2968   return $paths unless ref $fromspec eq 'ARRAY';
2969
2970   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2971
2972   if (int ($cur_depth) != $cur_depth) {
2973     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2974   }
2975
2976   for my $j (@$fromspec) {
2977
2978     next if ref $j ne 'ARRAY';
2979     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2980
2981     my $jpath = $j->[0]{-join_path};
2982
2983     my $p = $paths;
2984     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2985     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2986   }
2987
2988   return $paths;
2989 }
2990
2991 sub _rollout_attr {
2992   my ($self, $attr) = @_;
2993
2994   if (ref $attr eq 'HASH') {
2995     return $self->_rollout_hash($attr);
2996   } elsif (ref $attr eq 'ARRAY') {
2997     return $self->_rollout_array($attr);
2998   } else {
2999     return [$attr];
3000   }
3001 }
3002
3003 sub _rollout_array {
3004   my ($self, $attr) = @_;
3005
3006   my @rolled_array;
3007   foreach my $element (@{$attr}) {
3008     if (ref $element eq 'HASH') {
3009       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3010     } elsif (ref $element eq 'ARRAY') {
3011       #  XXX - should probably recurse here
3012       push( @rolled_array, @{$self->_rollout_array($element)} );
3013     } else {
3014       push( @rolled_array, $element );
3015     }
3016   }
3017   return \@rolled_array;
3018 }
3019
3020 sub _rollout_hash {
3021   my ($self, $attr) = @_;
3022
3023   my @rolled_array;
3024   foreach my $key (keys %{$attr}) {
3025     push( @rolled_array, { $key => $attr->{$key} } );
3026   }
3027   return \@rolled_array;
3028 }
3029
3030 sub _calculate_score {
3031   my ($self, $a, $b) = @_;
3032
3033   if (defined $a xor defined $b) {
3034     return 0;
3035   }
3036   elsif (not defined $a) {
3037     return 1;
3038   }
3039
3040   if (ref $b eq 'HASH') {
3041     my ($b_key) = keys %{$b};
3042     if (ref $a eq 'HASH') {
3043       my ($a_key) = keys %{$a};
3044       if ($a_key eq $b_key) {
3045         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3046       } else {
3047         return 0;
3048       }
3049     } else {
3050       return ($a eq $b_key) ? 1 : 0;
3051     }
3052   } else {
3053     if (ref $a eq 'HASH') {
3054       my ($a_key) = keys %{$a};
3055       return ($b eq $a_key) ? 1 : 0;
3056     } else {
3057       return ($b eq $a) ? 1 : 0;
3058     }
3059   }
3060 }
3061
3062 sub _merge_attr {
3063   my ($self, $orig, $import) = @_;
3064
3065   return $import unless defined($orig);
3066   return $orig unless defined($import);
3067
3068   $orig = $self->_rollout_attr($orig);
3069   $import = $self->_rollout_attr($import);
3070
3071   my $seen_keys;
3072   foreach my $import_element ( @{$import} ) {
3073     # find best candidate from $orig to merge $b_element into
3074     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3075     foreach my $orig_element ( @{$orig} ) {
3076       my $score = $self->_calculate_score( $orig_element, $import_element );
3077       if ($score > $best_candidate->{score}) {
3078         $best_candidate->{position} = $position;
3079         $best_candidate->{score} = $score;
3080       }
3081       $position++;
3082     }
3083     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3084
3085     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3086       push( @{$orig}, $import_element );
3087     } else {
3088       my $orig_best = $orig->[$best_candidate->{position}];
3089       # merge orig_best and b_element together and replace original with merged
3090       if (ref $orig_best ne 'HASH') {
3091         $orig->[$best_candidate->{position}] = $import_element;
3092       } elsif (ref $import_element eq 'HASH') {
3093         my ($key) = keys %{$orig_best};
3094         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3095       }
3096     }
3097     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3098   }
3099
3100   return $orig;
3101 }
3102
3103 sub result_source {
3104     my $self = shift;
3105
3106     if (@_) {
3107         $self->_source_handle($_[0]->handle);
3108     } else {
3109         $self->_source_handle->resolve;
3110     }
3111 }
3112
3113 =head2 throw_exception
3114
3115 See L<DBIx::Class::Schema/throw_exception> for details.
3116
3117 =cut
3118
3119 sub throw_exception {
3120   my $self=shift;
3121
3122   if (ref $self && $self->_source_handle->schema) {
3123     $self->_source_handle->schema->throw_exception(@_)
3124   }
3125   else {
3126     DBIx::Class::Exception->throw(@_);
3127   }
3128 }
3129
3130 # XXX: FIXME: Attributes docs need clearing up
3131
3132 =head1 ATTRIBUTES
3133
3134 Attributes are used to refine a ResultSet in various ways when
3135 searching for data. They can be passed to any method which takes an
3136 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3137 L</count>.
3138
3139 These are in no particular order:
3140
3141 =head2 order_by
3142
3143 =over 4
3144
3145 =item Value: ( $order_by | \@order_by | \%order_by )
3146
3147 =back
3148
3149 Which column(s) to order the results by.
3150
3151 [The full list of suitable values is documented in
3152 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3153 common options.]
3154
3155 If a single column name, or an arrayref of names is supplied, the
3156 argument is passed through directly to SQL. The hashref syntax allows
3157 for connection-agnostic specification of ordering direction:
3158
3159  For descending order:
3160
3161   order_by => { -desc => [qw/col1 col2 col3/] }
3162
3163  For explicit ascending order:
3164
3165   order_by => { -asc => 'col' }
3166
3167 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3168 supported, although you are strongly encouraged to use the hashref
3169 syntax as outlined above.
3170
3171 =head2 columns
3172
3173 =over 4
3174
3175 =item Value: \@columns
3176
3177 =back
3178
3179 Shortcut to request a particular set of columns to be retrieved. Each
3180 column spec may be a string (a table column name), or a hash (in which
3181 case the key is the C<as> value, and the value is used as the C<select>
3182 expression). Adds C<me.> onto the start of any column without a C<.> in
3183 it and sets C<select> from that, then auto-populates C<as> from
3184 C<select> as normal. (You may also use the C<cols> attribute, as in
3185 earlier versions of DBIC.)
3186
3187 =head2 +columns
3188
3189 =over 4
3190
3191 =item Value: \@columns
3192
3193 =back
3194
3195 Indicates additional columns to be selected from storage. Works the same
3196 as L</columns> but adds columns to the selection. (You may also use the
3197 C<include_columns> attribute, as in earlier versions of DBIC). For
3198 example:-
3199
3200   $schema->resultset('CD')->search(undef, {
3201     '+columns' => ['artist.name'],
3202     join => ['artist']
3203   });
3204
3205 would return all CDs and include a 'name' column to the information
3206 passed to object inflation. Note that the 'artist' is the name of the
3207 column (or relationship) accessor, and 'name' is the name of the column
3208 accessor in the related table.
3209
3210 =head2 include_columns
3211
3212 =over 4
3213
3214 =item Value: \@columns
3215
3216 =back
3217
3218 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3219
3220 =head2 select
3221
3222 =over 4
3223
3224 =item Value: \@select_columns
3225
3226 =back
3227
3228 Indicates which columns should be selected from the storage. You can use
3229 column names, or in the case of RDBMS back ends, function or stored procedure
3230 names:
3231
3232   $rs = $schema->resultset('Employee')->search(undef, {
3233     select => [
3234       'name',
3235       { count => 'employeeid' },
3236       { sum => 'salary' }
3237     ]
3238   });
3239
3240 When you use function/stored procedure names and do not supply an C<as>
3241 attribute, the column names returned are storage-dependent. E.g. MySQL would
3242 return a column named C<count(employeeid)> in the above example.
3243
3244 =head2 +select
3245
3246 =over 4
3247
3248 Indicates additional columns to be selected from storage.  Works the same as
3249 L</select> but adds columns to the selection.
3250
3251 =back
3252
3253 =head2 +as
3254
3255 =over 4
3256
3257 Indicates additional column names for those added via L</+select>. See L</as>.
3258
3259 =back
3260
3261 =head2 as
3262
3263 =over 4
3264
3265 =item Value: \@inflation_names
3266
3267 =back
3268
3269 Indicates column names for object inflation. That is, C<as>
3270 indicates the name that the column can be accessed as via the
3271 C<get_column> method (or via the object accessor, B<if one already
3272 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3273
3274 The C<as> attribute is used in conjunction with C<select>,
3275 usually when C<select> contains one or more function or stored
3276 procedure names:
3277
3278   $rs = $schema->resultset('Employee')->search(undef, {
3279     select => [
3280       'name',
3281       { count => 'employeeid' }
3282     ],
3283     as => ['name', 'employee_count'],
3284   });
3285
3286   my $employee = $rs->first(); # get the first Employee
3287
3288 If the object against which the search is performed already has an accessor
3289 matching a column name specified in C<as>, the value can be retrieved using
3290 the accessor as normal:
3291
3292   my $name = $employee->name();
3293
3294 If on the other hand an accessor does not exist in the object, you need to
3295 use C<get_column> instead:
3296
3297   my $employee_count = $employee->get_column('employee_count');
3298
3299 You can create your own accessors if required - see
3300 L<DBIx::Class::Manual::Cookbook> for details.
3301
3302 Please note: This will NOT insert an C<AS employee_count> into the SQL
3303 statement produced, it is used for internal access only. Thus
3304 attempting to use the accessor in an C<order_by> clause or similar
3305 will fail miserably.
3306
3307 To get around this limitation, you can supply literal SQL to your
3308 C<select> attibute that contains the C<AS alias> text, eg:
3309
3310   select => [\'myfield AS alias']
3311
3312 =head2 join
3313
3314 =over 4
3315
3316 =item Value: ($rel_name | \@rel_names | \%rel_names)
3317
3318 =back
3319
3320 Contains a list of relationships that should be joined for this query.  For
3321 example:
3322
3323   # Get CDs by Nine Inch Nails
3324   my $rs = $schema->resultset('CD')->search(
3325     { 'artist.name' => 'Nine Inch Nails' },
3326     { join => 'artist' }
3327   );
3328
3329 Can also contain a hash reference to refer to the other relation's relations.
3330 For example:
3331
3332   package MyApp::Schema::Track;
3333   use base qw/DBIx::Class/;
3334   __PACKAGE__->table('track');
3335   __PACKAGE__->add_columns(qw/trackid cd position title/);
3336   __PACKAGE__->set_primary_key('trackid');
3337   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3338   1;
3339
3340   # In your application
3341   my $rs = $schema->resultset('Artist')->search(
3342     { 'track.title' => 'Teardrop' },
3343     {
3344       join     => { cd => 'track' },
3345       order_by => 'artist.name',
3346     }
3347   );
3348
3349 You need to use the relationship (not the table) name in  conditions,
3350 because they are aliased as such. The current table is aliased as "me", so
3351 you need to use me.column_name in order to avoid ambiguity. For example:
3352
3353   # Get CDs from 1984 with a 'Foo' track
3354   my $rs = $schema->resultset('CD')->search(
3355     {
3356       'me.year' => 1984,
3357       'tracks.name' => 'Foo'
3358     },
3359     { join => 'tracks' }
3360   );
3361
3362 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3363 similarly for a third time). For e.g.
3364
3365   my $rs = $schema->resultset('Artist')->search({
3366     'cds.title'   => 'Down to Earth',
3367     'cds_2.title' => 'Popular',
3368   }, {
3369     join => [ qw/cds cds/ ],
3370   });
3371
3372 will return a set of all artists that have both a cd with title 'Down
3373 to Earth' and a cd with title 'Popular'.
3374
3375 If you want to fetch related objects from other tables as well, see C<prefetch>
3376 below.
3377
3378 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3379
3380 =head2 prefetch
3381
3382 =over 4
3383
3384 =item Value: ($rel_name | \@rel_names | \%rel_names)
3385
3386 =back
3387
3388 Contains one or more relationships that should be fetched along with
3389 the main query (when they are accessed afterwards the data will
3390 already be available, without extra queries to the database).  This is
3391 useful for when you know you will need the related objects, because it
3392 saves at least one query:
3393
3394   my $rs = $schema->resultset('Tag')->search(
3395     undef,
3396     {
3397       prefetch => {
3398         cd => 'artist'
3399       }
3400     }
3401   );
3402
3403 The initial search results in SQL like the following:
3404
3405   SELECT tag.*, cd.*, artist.* FROM tag
3406   JOIN cd ON tag.cd = cd.cdid
3407   JOIN artist ON cd.artist = artist.artistid
3408
3409 L<DBIx::Class> has no need to go back to the database when we access the
3410 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3411 case.
3412
3413 Simple prefetches will be joined automatically, so there is no need
3414 for a C<join> attribute in the above search.
3415
3416 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3417 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3418 with an accessor type of 'single' or 'filter'). A more complex example that
3419 prefetches an artists cds, the tracks on those cds, and the tags associted
3420 with that artist is given below (assuming many-to-many from artists to tags):
3421
3422  my $rs = $schema->resultset('Artist')->search(
3423    undef,
3424    {
3425      prefetch => [
3426        { cds => 'tracks' },
3427        { artist_tags => 'tags' }
3428      ]
3429    }
3430  );
3431
3432
3433 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3434 attributes will be ignored.
3435
3436 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3437 exactly as you might expect.
3438
3439 =over 4
3440
3441 =item *
3442
3443 Prefetch uses the L</cache> to populate the prefetched relationships. This
3444 may or may not be what you want.
3445
3446 =item *
3447
3448 If you specify a condition on a prefetched relationship, ONLY those
3449 rows that match the prefetched condition will be fetched into that relationship.
3450 This means that adding prefetch to a search() B<may alter> what is returned by
3451 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3452
3453   my $artist_rs = $schema->resultset('Artist')->search({
3454       'cds.year' => 2008,
3455   }, {
3456       join => 'cds',
3457   });
3458
3459   my $count = $artist_rs->first->cds->count;
3460
3461   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3462
3463   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3464
3465   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3466
3467 that cmp_ok() may or may not pass depending on the datasets involved. This
3468 behavior may or may not survive the 0.09 transition.
3469
3470 =back
3471
3472 =head2 page
3473
3474 =over 4
3475
3476 =item Value: $page
3477
3478 =back
3479
3480 Makes the resultset paged and specifies the page to retrieve. Effectively
3481 identical to creating a non-pages resultset and then calling ->page($page)
3482 on it.
3483
3484 If L<rows> attribute is not specified it defaults to 10 rows per page.
3485
3486 When you have a paged resultset, L</count> will only return the number
3487 of rows in the page. To get the total, use the L</pager> and call
3488 C<total_entries> on it.
3489
3490 =head2 rows
3491
3492 =over 4
3493
3494 =item Value: $rows
3495
3496 =back
3497
3498 Specifes the maximum number of rows for direct retrieval or the number of
3499 rows per page if the page attribute or method is used.
3500
3501 =head2 offset
3502
3503 =over 4
3504
3505 =item Value: $offset
3506
3507 =back
3508
3509 Specifies the (zero-based) row number for the  first row to be returned, or the
3510 of the first row of the first page if paging is used.
3511
3512 =head2 group_by
3513
3514 =over 4
3515
3516 =item Value: \@columns
3517
3518 =back
3519
3520 A arrayref of columns to group by. Can include columns of joined tables.
3521
3522   group_by => [qw/ column1 column2 ... /]
3523
3524 =head2 having
3525
3526 =over 4
3527
3528 =item Value: $condition
3529
3530 =back
3531
3532 HAVING is a select statement attribute that is applied between GROUP BY and
3533 ORDER BY. It is applied to the after the grouping calculations have been
3534 done.
3535
3536   having => { 'count(employee)' => { '>=', 100 } }
3537
3538 =head2 distinct
3539
3540 =over 4
3541
3542 =item Value: (0 | 1)
3543
3544 =back
3545
3546 Set to 1 to group by all columns. If the resultset already has a group_by
3547 attribute, this setting is ignored and an appropriate warning is issued.
3548
3549 =head2 where
3550
3551 =over 4
3552
3553 Adds to the WHERE clause.
3554
3555   # only return rows WHERE deleted IS NULL for all searches
3556   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3557
3558 Can be overridden by passing C<{ where => undef }> as an attribute
3559 to a resulset.
3560
3561 =back
3562
3563 =head2 cache
3564
3565 Set to 1 to cache search results. This prevents extra SQL queries if you
3566 revisit rows in your ResultSet:
3567
3568   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3569
3570   while( my $artist = $resultset->next ) {
3571     ... do stuff ...
3572   }
3573
3574   $rs->first; # without cache, this would issue a query
3575
3576 By default, searches are not cached.
3577
3578 For more examples of using these attributes, see
3579 L<DBIx::Class::Manual::Cookbook>.
3580
3581 =head2 for
3582
3583 =over 4
3584
3585 =item Value: ( 'update' | 'shared' )
3586
3587 =back
3588
3589 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3590 ... FOR SHARED.
3591
3592 =cut
3593
3594 1;