lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  29
  30 =head1 NAME
  31
  32 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  33
  34 =head1 SYNOPSIS
  35
  36   my $users_rs = $schema->resultset('User');
  37   while( $user = $users_rs->next) {
  38     print $user->username;
  39   }
  40
  41   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  42   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  43
  44 =head1 DESCRIPTION
  45
  46 A ResultSet is an object which stores a set of conditions representing
  47 a query. It is the backbone of DBIx::Class (i.e. the really
  48 important/useful bit).
  49
  50 No SQL is executed on the database when a ResultSet is created, it
  51 just stores all the conditions needed to create the query.
  52
  53 A basic ResultSet representing the data of an entire table is returned
  54 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  55 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  56
  57   my $users_rs = $schema->resultset('User');
  58
  59 A new ResultSet is returned from calling L</search> on an existing
  60 ResultSet. The new one will contain all the conditions of the
  61 original, plus any new conditions added in the C<search> call.
  62
  63 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  64 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  65 represents.
  66
  67 The query that the ResultSet represents is B<only> executed against
  68 the database when these methods are called:
  69 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  70
  71 If a resultset is used in a numeric context it returns the L</count>.
  72 However, if it is used in a boolean context it is B<always> true.  So if
  73 you want to check if a resultset has any results, you must use C<if $rs
  74 != 0>.
  75
  76 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  77
  78 If you want to make your custom ResultSet classes with L<Moose>, use a template
  79 similar to:
  80
  81     package MyApp::Schema::ResultSet::User;
  82
  83     use Moose;
  84     use namespace::autoclean;
  85     use MooseX::NonMoose;
  86     extends 'DBIx::Class::ResultSet';
  87
  88     sub BUILDARGS { $_[2] }
  89
  90     ...your code...
  91
  92     __PACKAGE__->meta->make_immutable;
  93
  94     1;
  95
  96 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  97 clash with the regular ResultSet constructor. Alternatively, you can use:
  98
  99     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 100
 101 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 102 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 103
 104 =head1 EXAMPLES
 105
 106 =head2 Chaining resultsets
 107
 108 Let's say you've got a query that needs to be run to return some data
 109 to the user. But, you have an authorization system in place that
 110 prevents certain users from seeing certain information. So, you want
 111 to construct the basic query in one method, but add constraints to it in
 112 another.
 113
 114   sub get_data {
 115     my $self = shift;
 116     my $request = $self->get_request; # Get a request object somehow.
 117     my $schema = $self->result_source->schema;
 118
 119     my $cd_rs = $schema->resultset('CD')->search({
 120       title => $request->param('title'),
 121       year => $request->param('year'),
 122     });
 123
 124     $cd_rs = $self->apply_security_policy( $cd_rs );
 125
 126     return $cd_rs->all();
 127   }
 128
 129   sub apply_security_policy {
 130     my $self = shift;
 131     my ($rs) = @_;
 132
 133     return $rs->search({
 134       subversive => 0,
 135     });
 136   }
 137
 138 =head3 Resolving conditions and attributes
 139
 140 When a resultset is chained from another resultset, conditions and
 141 attributes with the same keys need resolving.
 142
 143 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 144 into the existing ones from the original resultset.
 145
 146 The L</where> and L</having> attributes, and any search conditions, are
 147 merged with an SQL C<AND> to the existing condition from the original
 148 resultset.
 149
 150 All other attributes are overridden by any new ones supplied in the
 151 search attributes.
 152
 153 =head2 Multiple queries
 154
 155 Since a resultset just defines a query, you can do all sorts of
 156 things with it with the same object.
 157
 158   # Don't hit the DB yet.
 159   my $cd_rs = $schema->resultset('CD')->search({
 160     title => 'something',
 161     year => 2009,
 162   });
 163
 164   # Each of these hits the DB individually.
 165   my $count = $cd_rs->count;
 166   my $most_recent = $cd_rs->get_column('date_released')->max();
 167   my @records = $cd_rs->all;
 168
 169 And it's not just limited to SELECT statements.
 170
 171   $cd_rs->delete();
 172
 173 This is even cooler:
 174
 175   $cd_rs->create({ artist => 'Fred' });
 176
 177 Which is the same as:
 178
 179   $schema->resultset('CD')->create({
 180     title => 'something',
 181     year => 2009,
 182     artist => 'Fred'
 183   });
 184
 185 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 186
 187 =head1 METHODS
 188
 189 =head2 new
 190
 191 =over 4
 192
 193 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 194
 195 =item Return Value: L<$resultset|/search>
 196
 197 =back
 198
 199 The resultset constructor. Takes a source object (usually a
 200 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 201 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 202 executed as needed by the other methods.
 203
 204 Generally you never construct a resultset manually. Instead you get one
 205 from e.g. a
 206 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 207 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 208 scalar context):
 209
 210   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 211
 212 =over
 213
 214 =item WARNING
 215
 216 If called on an object, proxies to L</new_result> instead, so
 217
 218   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 219
 220 will return a CD object, not a ResultSet, and is equivalent to:
 221
 222   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 223
 224 Please also keep in mind that many internals call L</new_result> directly,
 225 so overloading this method with the idea of intercepting new result object
 226 creation B<will not work>. See also warning pertaining to L</create>.
 227
 228 =back
 229
 230 =cut
 231
 232 sub new {
 233   my $class = shift;
 234   return $class->new_result(@_) if ref $class;
 235
 236   my ($source, $attrs) = @_;
 237   $source = $source->resolve
 238     if $source->isa('DBIx::Class::ResultSourceHandle');
 239   $attrs = { %{$attrs||{}} };
 240
 241   if ($attrs->{page}) {
 242     $attrs->{rows} ||= 10;
 243   }
 244
 245   $attrs->{alias} ||= 'me';
 246
 247   my $self = bless {
 248     result_source => $source,
 249     cond => $attrs->{where},
 250     pager => undef,
 251     attrs => $attrs,
 252   }, $class;
 253
 254   # if there is a dark selector, this means we are already in a
 255   # chain and the cleanup/sanification was taken care of by
 256   # _search_rs already
 257   $self->_normalize_selection($attrs)
 258     unless $attrs->{_dark_selector};
 259
 260   $self->result_class(
 261     $attrs->{result_class} || $source->result_class
 262   );
 263
 264   $self;
 265 }
 266
 267 =head2 search
 268
 269 =over 4
 270
 271 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 272
 273 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 274
 275 =back
 276
 277   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 278   my $new_rs = $cd_rs->search({ year => 2005 });
 279
 280   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 281                  # year = 2005 OR year = 2004
 282
 283 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 284 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 285 To avoid that, use L</search_rs>.
 286
 287 If you need to pass in additional attributes but no additional condition,
 288 call it as C<search(undef, \%attrs)>.
 289
 290   # "SELECT name, artistid FROM $artist_table"
 291   my @all_artists = $schema->resultset('Artist')->search(undef, {
 292     columns => [qw/name artistid/],
 293   });
 294
 295 For a list of attributes that can be passed to C<search>, see
 296 L</ATTRIBUTES>. For more examples of using this function, see
 297 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 298 documentation for the first argument, see L<SQL::Abstract>
 299 and its extension L<DBIx::Class::SQLMaker>.
 300
 301 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 302
 303 =head3 CAVEAT
 304
 305 Note that L</search> does not process/deflate any of the values passed in the
 306 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 307 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 308 manually that any value passed to this method will stringify to something the
 309 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 310 objects, for more info see:
 311 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 312
 313 =cut
 314
 315 sub search {
 316   my $self = shift;
 317   my $rs = $self->search_rs( @_ );
 318
 319   if (wantarray) {
 320     return $rs->all;
 321   }
 322   elsif (defined wantarray) {
 323     return $rs;
 324   }
 325   else {
 326     # we can be called by a relationship helper, which in
 327     # turn may be called in void context due to some braindead
 328     # overload or whatever else the user decided to be clever
 329     # at this particular day. Thus limit the exception to
 330     # external code calls only
 331     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 332       if (caller)[0] !~ /^\QDBIx::Class::/;
 333
 334     return ();
 335   }
 336 }
 337
 338 =head2 search_rs
 339
 340 =over 4
 341
 342 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 343
 344 =item Return Value: L<$resultset|/search>
 345
 346 =back
 347
 348 This method does the same exact thing as search() except it will
 349 always return a resultset, even in list context.
 350
 351 =cut
 352
 353 sub search_rs {
 354   my $self = shift;
 355
 356   my $rsrc = $self->result_source;
 357   my ($call_cond, $call_attrs);
 358
 359   # Special-case handling for (undef, undef) or (undef)
 360   # Note that (foo => undef) is valid deprecated syntax
 361   @_ = () if not scalar grep { defined $_ } @_;
 362
 363   # just a cond
 364   if (@_ == 1) {
 365     $call_cond = shift;
 366   }
 367   # fish out attrs in the ($condref, $attr) case
 368   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 369     ($call_cond, $call_attrs) = @_;
 370   }
 371   elsif (@_ % 2) {
 372     $self->throw_exception('Odd number of arguments to search')
 373   }
 374   # legacy search
 375   elsif (@_) {
 376     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 377       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 378
 379     for my $i (0 .. $#_) {
 380       next if $i % 2;
 381       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 382         if (! defined $_[$i] or ref $_[$i] ne '');
 383     }
 384
 385     $call_cond = { @_ };
 386   }
 387
 388   # see if we can keep the cache (no $rs changes)
 389   my $cache;
 390   my %safe = (alias => 1, cache => 1);
 391   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 392     ! defined $_[0]
 393       or
 394     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 395       or
 396     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 397   )) {
 398     $cache = $self->get_cache;
 399   }
 400
 401   my $old_attrs = { %{$self->{attrs}} };
 402   my $old_having = delete $old_attrs->{having};
 403   my $old_where = delete $old_attrs->{where};
 404
 405   my $new_attrs = { %$old_attrs };
 406
 407   # take care of call attrs (only if anything is changing)
 408   if ($call_attrs and keys %$call_attrs) {
 409
 410     # copy for _normalize_selection
 411     $call_attrs = { %$call_attrs };
 412
 413     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 414
 415     # reset the current selector list if new selectors are supplied
 416     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 417       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 418     }
 419
 420     # Normalize the new selector list (operates on the passed-in attr structure)
 421     # Need to do it on every chain instead of only once on _resolved_attrs, in
 422     # order to allow detection of empty vs partial 'as'
 423     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 424       if $old_attrs->{_dark_selector};
 425     $self->_normalize_selection ($call_attrs);
 426
 427     # start with blind overwriting merge, exclude selector attrs
 428     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 429     delete @{$new_attrs}{@selector_attrs};
 430
 431     for (@selector_attrs) {
 432       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 433         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 434     }
 435
 436     # older deprecated name, use only if {columns} is not there
 437     if (my $c = delete $new_attrs->{cols}) {
 438       if ($new_attrs->{columns}) {
 439         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 440       }
 441       else {
 442         $new_attrs->{columns} = $c;
 443       }
 444     }
 445
 446
 447     # join/prefetch use their own crazy merging heuristics
 448     foreach my $key (qw/join prefetch/) {
 449       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 450         if exists $call_attrs->{$key};
 451     }
 452
 453     # stack binds together
 454     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 455   }
 456
 457
 458   for ($old_where, $call_cond) {
 459     if (defined $_) {
 460       $new_attrs->{where} = $self->_stack_cond (
 461         $_, $new_attrs->{where}
 462       );
 463     }
 464   }
 465
 466   if (defined $old_having) {
 467     $new_attrs->{having} = $self->_stack_cond (
 468       $old_having, $new_attrs->{having}
 469     )
 470   }
 471
 472   my $rs = (ref $self)->new($rsrc, $new_attrs);
 473
 474   $rs->set_cache($cache) if ($cache);
 475
 476   return $rs;
 477 }
 478
 479 my $dark_sel_dumper;
 480 sub _normalize_selection {
 481   my ($self, $attrs) = @_;
 482
 483   # legacy syntax
 484   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 485     if exists $attrs->{include_columns};
 486
 487   # columns are always placed first, however
 488
 489   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 490   # delay the decision on whether to use a default select list ($rsrc->columns)
 491   # allowing stuff like the remove_columns helper to work
 492   #
 493   # select/as +select/+as pairs need special handling - the amount of select/as
 494   # elements in each pair does *not* have to be equal (think multicolumn
 495   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 496   # supplied at all) - try to infer the alias, either from the -as parameter
 497   # of the selector spec, or use the parameter whole if it looks like a column
 498   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 499   # is ok as well), but make sure no more additions to the 'as' chain take place
 500   for my $pref ('', '+') {
 501
 502     my ($sel, $as) = map {
 503       my $key = "${pref}${_}";
 504
 505       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 506         ? @{$attrs->{$key}}
 507         : $attrs->{$key} || ()
 508       ];
 509       delete $attrs->{$key};
 510       $val;
 511     } qw/select as/;
 512
 513     if (! @$as and ! @$sel ) {
 514       next;
 515     }
 516     elsif (@$as and ! @$sel) {
 517       $self->throw_exception(
 518         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 519       );
 520     }
 521     elsif( ! @$as ) {
 522       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 523       # if any @$as has been supplied we assume the user knows what (s)he is doing
 524       # and blindly keep stacking up pieces
 525       unless ($attrs->{_dark_selector}) {
 526         SELECTOR:
 527         for (@$sel) {
 528           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 529             push @$as, $_->{-as};
 530           }
 531           # assume any plain no-space, no-parenthesis string to be a column spec
 532           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 533           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 534             push @$as, $_;
 535           }
 536           # if all else fails - raise a flag that no more aliasing will be allowed
 537           else {
 538             $attrs->{_dark_selector} = {
 539               plus_stage => $pref,
 540               string => ($dark_sel_dumper ||= do {
 541                   require Data::Dumper::Concise;
 542                   Data::Dumper::Concise::DumperObject()->Indent(0);
 543                 })->Values([$_])->Dump
 544               ,
 545             };
 546             last SELECTOR;
 547           }
 548         }
 549       }
 550     }
 551     elsif (@$as < @$sel) {
 552       $self->throw_exception(
 553         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 554       );
 555     }
 556     elsif ($pref and $attrs->{_dark_selector}) {
 557       $self->throw_exception(
 558         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 559       );
 560     }
 561
 562
 563     # merge result
 564     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 565     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 566   }
 567 }
 568
 569 sub _stack_cond {
 570   my ($self, $left, $right) = @_;
 571
 572   # collapse single element top-level conditions
 573   # (single pass only, unlikely to need recursion)
 574   for ($left, $right) {
 575     if (ref $_ eq 'ARRAY') {
 576       if (@$_ == 0) {
 577         $_ = undef;
 578       }
 579       elsif (@$_ == 1) {
 580         $_ = $_->[0];
 581       }
 582     }
 583     elsif (ref $_ eq 'HASH') {
 584       my ($first, $more) = keys %$_;
 585
 586       # empty hash
 587       if (! defined $first) {
 588         $_ = undef;
 589       }
 590       # one element hash
 591       elsif (! defined $more) {
 592         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 593           $_ = $_->{'-and'};
 594         }
 595         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 596           $_ = $_->{'-or'};
 597         }
 598       }
 599     }
 600   }
 601
 602   # merge hashes with weeding out of duplicates (simple cases only)
 603   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 604
 605     # shallow copy to destroy
 606     $right = { %$right };
 607     for (grep { exists $right->{$_} } keys %$left) {
 608       # the use of eq_deeply here is justified - the rhs of an
 609       # expression can contain a lot of twisted weird stuff
 610       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 611     }
 612
 613     $right = undef unless keys %$right;
 614   }
 615
 616
 617   if (defined $left xor defined $right) {
 618     return defined $left ? $left : $right;
 619   }
 620   elsif (! defined $left) {
 621     return undef;
 622   }
 623   else {
 624     return { -and => [ $left, $right ] };
 625   }
 626 }
 627
 628 =head2 search_literal
 629
 630 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 631 should only be used in that context. C<search_literal> is a convenience
 632 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 633 want to ensure columns are bound correctly, use L</search>.
 634
 635 See L<DBIx::Class::Manual::Cookbook/Searching> and
 636 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 637 require C<search_literal>.
 638
 639 =over 4
 640
 641 =item Arguments: $sql_fragment, @standalone_bind_values
 642
 643 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 644
 645 =back
 646
 647   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 648   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 649
 650 Pass a literal chunk of SQL to be added to the conditional part of the
 651 resultset query.
 652
 653 Example of how to use C<search> instead of C<search_literal>
 654
 655   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 656   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 657
 658 =cut
 659
 660 sub search_literal {
 661   my ($self, $sql, @bind) = @_;
 662   my $attr;
 663   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 664     $attr = pop @bind;
 665   }
 666   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 667 }
 668
 669 =head2 find
 670
 671 =over 4
 672
 673 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 674
 675 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 676
 677 =back
 678
 679 Finds and returns a single row based on supplied criteria. Takes either a
 680 hashref with the same format as L</create> (including inference of foreign
 681 keys from related objects), or a list of primary key values in the same
 682 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 683 declaration on the L</result_source>.
 684
 685 In either case an attempt is made to combine conditions already existing on
 686 the resultset with the condition passed to this method.
 687
 688 To aid with preparing the correct query for the storage you may supply the
 689 C<key> attribute, which is the name of a
 690 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 691 unique constraint corresponding to the
 692 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 693 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 694 to construct a query that satisfies the named unique constraint fully (
 695 non-NULL values for each column member of the constraint) an exception is
 696 thrown.
 697
 698 If no C<key> is specified, the search is carried over all unique constraints
 699 which are fully defined by the available condition.
 700
 701 If no such constraint is found, C<find> currently defaults to a simple
 702 C<< search->(\%column_values) >> which may or may not do what you expect.
 703 Note that this fallback behavior may be deprecated in further versions. If
 704 you need to search with arbitrary conditions - use L</search>. If the query
 705 resulting from this fallback produces more than one row, a warning to the
 706 effect is issued, though only the first row is constructed and returned as
 707 C<$result_object>.
 708
 709 In addition to C<key>, L</find> recognizes and applies standard
 710 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 711
 712 Note that if you have extra concerns about the correctness of the resulting
 713 query you need to specify the C<key> attribute and supply the entire condition
 714 as an argument to find (since it is not always possible to perform the
 715 combination of the resultset condition with the supplied one, especially if
 716 the resultset condition contains literal sql).
 717
 718 For example, to find a row by its primary key:
 719
 720   my $cd = $schema->resultset('CD')->find(5);
 721
 722 You can also find a row by a specific unique constraint:
 723
 724   my $cd = $schema->resultset('CD')->find(
 725     {
 726       artist => 'Massive Attack',
 727       title  => 'Mezzanine',
 728     },
 729     { key => 'cd_artist_title' }
 730   );
 731
 732 See also L</find_or_create> and L</update_or_create>.
 733
 734 =cut
 735
 736 sub find {
 737   my $self = shift;
 738   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 739
 740   my $rsrc = $self->result_source;
 741
 742   my $constraint_name;
 743   if (exists $attrs->{key}) {
 744     $constraint_name = defined $attrs->{key}
 745       ? $attrs->{key}
 746       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 747     ;
 748   }
 749
 750   # Parse out the condition from input
 751   my $call_cond;
 752
 753   if (ref $_[0] eq 'HASH') {
 754     $call_cond = { %{$_[0]} };
 755   }
 756   else {
 757     # if only values are supplied we need to default to 'primary'
 758     $constraint_name = 'primary' unless defined $constraint_name;
 759
 760     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 761
 762     $self->throw_exception(
 763       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 764     ) unless @c_cols;
 765
 766     $self->throw_exception (
 767       'find() expects either a column/value hashref, or a list of values '
 768     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 769     ) unless @c_cols == @_;
 770
 771     $call_cond = {};
 772     @{$call_cond}{@c_cols} = @_;
 773   }
 774
 775   my %related;
 776   for my $key (keys %$call_cond) {
 777     if (
 778       my $keyref = ref($call_cond->{$key})
 779         and
 780       my $relinfo = $rsrc->relationship_info($key)
 781     ) {
 782       my $val = delete $call_cond->{$key};
 783
 784       next if $keyref eq 'ARRAY'; # has_many for multi_create
 785
 786       my $rel_q = $rsrc->_resolve_condition(
 787         $relinfo->{cond}, $val, $key, $key
 788       );
 789       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 790       @related{keys %$rel_q} = values %$rel_q;
 791     }
 792   }
 793
 794   # relationship conditions take precedence (?)
 795   @{$call_cond}{keys %related} = values %related;
 796
 797   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 798   my $final_cond;
 799   if (defined $constraint_name) {
 800     $final_cond = $self->_qualify_cond_columns (
 801
 802       $self->_build_unique_cond (
 803         $constraint_name,
 804         $call_cond,
 805       ),
 806
 807       $alias,
 808     );
 809   }
 810   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 811     # This means that we got here after a merger of relationship conditions
 812     # in ::Relationship::Base::search_related (the row method), and furthermore
 813     # the relationship is of the 'single' type. This means that the condition
 814     # provided by the relationship (already attached to $self) is sufficient,
 815     # as there can be only one row in the database that would satisfy the
 816     # relationship
 817   }
 818   else {
 819     # no key was specified - fall down to heuristics mode:
 820     # run through all unique queries registered on the resultset, and
 821     # 'OR' all qualifying queries together
 822     my (@unique_queries, %seen_column_combinations);
 823     for my $c_name ($rsrc->unique_constraint_names) {
 824       next if $seen_column_combinations{
 825         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 826       }++;
 827
 828       push @unique_queries, try {
 829         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 830       } || ();
 831     }
 832
 833     $final_cond = @unique_queries
 834       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 835       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 836     ;
 837   }
 838
 839   # Run the query, passing the result_class since it should propagate for find
 840   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 841   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 842     my $row = $rs->next;
 843     carp "Query returned more than one row" if $rs->next;
 844     return $row;
 845   }
 846   else {
 847     return $rs->single;
 848   }
 849 }
 850
 851 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 852 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 853 #
 854 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 855 # condition. It is provided for overrides until a saner way forward is devised
 856 #
 857 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 858 # the road. Please adjust your tests accordingly to catch this situation early
 859 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 860 #
 861 # The method will not be removed without an adequately complete replacement
 862 # for strict-mode enforcement
 863 sub _non_unique_find_fallback {
 864   my ($self, $cond, $attrs) = @_;
 865
 866   return $self->_qualify_cond_columns(
 867     $cond,
 868     exists $attrs->{alias}
 869       ? $attrs->{alias}
 870       : $self->{attrs}{alias}
 871   );
 872 }
 873
 874
 875 sub _qualify_cond_columns {
 876   my ($self, $cond, $alias) = @_;
 877
 878   my %aliased = %$cond;
 879   for (keys %aliased) {
 880     $aliased{"$alias.$_"} = delete $aliased{$_}
 881       if $_ !~ /\./;
 882   }
 883
 884   return \%aliased;
 885 }
 886
 887 sub _build_unique_cond {
 888   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 889
 890   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 891
 892   # combination may fail if $self->{cond} is non-trivial
 893   my ($final_cond) = try {
 894     $self->_merge_with_rscond ($extra_cond)
 895   } catch {
 896     +{ %$extra_cond }
 897   };
 898
 899   # trim out everything not in $columns
 900   $final_cond = { map {
 901     exists $final_cond->{$_}
 902       ? ( $_ => $final_cond->{$_} )
 903       : ()
 904   } @c_cols };
 905
 906   if (my @missing = grep
 907     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 908     (@c_cols)
 909   ) {
 910     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 911       $constraint_name,
 912       join (', ', map { "'$_'" } @missing),
 913     ) );
 914   }
 915
 916   if (
 917     !$croak_on_null
 918       and
 919     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 920       and
 921     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 922   ) {
 923     carp_unique ( sprintf (
 924       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 925     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 926     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 927       $constraint_name,
 928       join (', ', map { "'$_'" } @undefs),
 929     ));
 930   }
 931
 932   return $final_cond;
 933 }
 934
 935 =head2 search_related
 936
 937 =over 4
 938
 939 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 940
 941 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 942
 943 =back
 944
 945   $new_rs = $cd_rs->search_related('artist', {
 946     name => 'Emo-R-Us',
 947   });
 948
 949 Searches the specified relationship, optionally specifying a condition and
 950 attributes for matching records. See L</ATTRIBUTES> for more information.
 951
 952 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 953 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 954
 955 See also L</search_related_rs>.
 956
 957 =cut
 958
 959 sub search_related {
 960   return shift->related_resultset(shift)->search(@_);
 961 }
 962
 963 =head2 search_related_rs
 964
 965 This method works exactly the same as search_related, except that
 966 it guarantees a resultset, even in list context.
 967
 968 =cut
 969
 970 sub search_related_rs {
 971   return shift->related_resultset(shift)->search_rs(@_);
 972 }
 973
 974 =head2 cursor
 975
 976 =over 4
 977
 978 =item Arguments: none
 979
 980 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 981
 982 =back
 983
 984 Returns a storage-driven cursor to the given resultset. See
 985 L<DBIx::Class::Cursor> for more information.
 986
 987 =cut
 988
 989 sub cursor {
 990   my $self = shift;
 991
 992   return $self->{cursor} ||= do {
 993     my $attrs = { %{$self->_resolved_attrs } };
 994     $self->result_source->storage->select(
 995       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
 996     );
 997   };
 998 }
 999
1000 =head2 single
1001
1002 =over 4
1003
1004 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1005
1006 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1007
1008 =back
1009
1010   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1011
1012 Inflates the first result without creating a cursor if the resultset has
1013 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1014 of L</search>.
1015
1016 While this method can take an optional search condition (just like L</search>)
1017 being a fast-code-path it does not recognize search attributes. If you need to
1018 add extra joins or similar, call L</search> and then chain-call L</single> on the
1019 L<DBIx::Class::ResultSet> returned.
1020
1021 =over
1022
1023 =item B<Note>
1024
1025 As of 0.08100, this method enforces the assumption that the preceding
1026 query returns only one row. If more than one row is returned, you will receive
1027 a warning:
1028
1029   Query returned more than one row
1030
1031 In this case, you should be using L</next> or L</find> instead, or if you really
1032 know what you are doing, use the L</rows> attribute to explicitly limit the size
1033 of the resultset.
1034
1035 This method will also throw an exception if it is called on a resultset prefetching
1036 has_many, as such a prefetch implies fetching multiple rows from the database in
1037 order to assemble the resulting object.
1038
1039 =back
1040
1041 =cut
1042
1043 sub single {
1044   my ($self, $where) = @_;
1045   if(@_ > 2) {
1046       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1047   }
1048
1049   my $attrs = { %{$self->_resolved_attrs} };
1050
1051   if (keys %{$attrs->{collapse}}) {
1052     $self->throw_exception(
1053       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1054     );
1055   }
1056
1057   if ($where) {
1058     if (defined $attrs->{where}) {
1059       $attrs->{where} = {
1060         '-and' =>
1061             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1062                $where, delete $attrs->{where} ]
1063       };
1064     } else {
1065       $attrs->{where} = $where;
1066     }
1067   }
1068
1069   my @data = $self->result_source->storage->select_single(
1070     $attrs->{from}, $attrs->{select},
1071     $attrs->{where}, $attrs
1072   );
1073
1074   return (@data ? ($self->_construct_object(@data))[0] : undef);
1075 }
1076
1077
1078 # _collapse_query
1079 #
1080 # Recursively collapse the query, accumulating values for each column.
1081
1082 sub _collapse_query {
1083   my ($self, $query, $collapsed) = @_;
1084
1085   $collapsed ||= {};
1086
1087   if (ref $query eq 'ARRAY') {
1088     foreach my $subquery (@$query) {
1089       next unless ref $subquery;  # -or
1090       $collapsed = $self->_collapse_query($subquery, $collapsed);
1091     }
1092   }
1093   elsif (ref $query eq 'HASH') {
1094     if (keys %$query and (keys %$query)[0] eq '-and') {
1095       foreach my $subquery (@{$query->{-and}}) {
1096         $collapsed = $self->_collapse_query($subquery, $collapsed);
1097       }
1098     }
1099     else {
1100       foreach my $col (keys %$query) {
1101         my $value = $query->{$col};
1102         $collapsed->{$col}{$value}++;
1103       }
1104     }
1105   }
1106
1107   return $collapsed;
1108 }
1109
1110 =head2 get_column
1111
1112 =over 4
1113
1114 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1115
1116 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1117
1118 =back
1119
1120   my $max_length = $rs->get_column('length')->max;
1121
1122 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1123
1124 =cut
1125
1126 sub get_column {
1127   my ($self, $column) = @_;
1128   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1129   return $new;
1130 }
1131
1132 =head2 search_like
1133
1134 =over 4
1135
1136 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1137
1138 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1139
1140 =back
1141
1142   # WHERE title LIKE '%blue%'
1143   $cd_rs = $rs->search_like({ title => '%blue%'});
1144
1145 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1146 that this is simply a convenience method retained for ex Class::DBI users.
1147 You most likely want to use L</search> with specific operators.
1148
1149 For more information, see L<DBIx::Class::Manual::Cookbook>.
1150
1151 This method is deprecated and will be removed in 0.09. Use L</search()>
1152 instead. An example conversion is:
1153
1154   ->search_like({ foo => 'bar' });
1155
1156   # Becomes
1157
1158   ->search({ foo => { like => 'bar' } });
1159
1160 =cut
1161
1162 sub search_like {
1163   my $class = shift;
1164   carp_unique (
1165     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1166    .' Instead use ->search({ x => { -like => "y%" } })'
1167    .' (note the outer pair of {}s - they are important!)'
1168   );
1169   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1170   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1171   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1172   return $class->search($query, { %$attrs });
1173 }
1174
1175 =head2 slice
1176
1177 =over 4
1178
1179 =item Arguments: $first, $last
1180
1181 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1182
1183 =back
1184
1185 Returns a resultset or object list representing a subset of elements from the
1186 resultset slice is called on. Indexes are from 0, i.e., to get the first
1187 three records, call:
1188
1189   my ($one, $two, $three) = $rs->slice(0, 2);
1190
1191 =cut
1192
1193 sub slice {
1194   my ($self, $min, $max) = @_;
1195   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1196   $attrs->{offset} = $self->{attrs}{offset} || 0;
1197   $attrs->{offset} += $min;
1198   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1199   return $self->search(undef, $attrs);
1200   #my $slice = (ref $self)->new($self->result_source, $attrs);
1201   #return (wantarray ? $slice->all : $slice);
1202 }
1203
1204 =head2 next
1205
1206 =over 4
1207
1208 =item Arguments: none
1209
1210 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1211
1212 =back
1213
1214 Returns the next element in the resultset (C<undef> is there is none).
1215
1216 Can be used to efficiently iterate over records in the resultset:
1217
1218   my $rs = $schema->resultset('CD')->search;
1219   while (my $cd = $rs->next) {
1220     print $cd->title;
1221   }
1222
1223 Note that you need to store the resultset object, and call C<next> on it.
1224 Calling C<< resultset('Table')->next >> repeatedly will always return the
1225 first record from the resultset.
1226
1227 =cut
1228
1229 sub next {
1230   my ($self) = @_;
1231   if (my $cache = $self->get_cache) {
1232     $self->{all_cache_position} ||= 0;
1233     return $cache->[$self->{all_cache_position}++];
1234   }
1235   if ($self->{attrs}{cache}) {
1236     delete $self->{pager};
1237     $self->{all_cache_position} = 1;
1238     return ($self->all)[0];
1239   }
1240   if ($self->{stashed_objects}) {
1241     my $obj = shift(@{$self->{stashed_objects}});
1242     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1243     return $obj;
1244   }
1245   my @row = (
1246     exists $self->{stashed_row}
1247       ? @{delete $self->{stashed_row}}
1248       : $self->cursor->next
1249   );
1250   return undef unless (@row);
1251   my ($row, @more) = $self->_construct_object(@row);
1252   $self->{stashed_objects} = \@more if @more;
1253   return $row;
1254 }
1255
1256 sub _construct_object {
1257   my ($self, @row) = @_;
1258
1259   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1260     or return ();
1261   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1262   @new = $self->{_attrs}{record_filter}->(@new)
1263     if exists $self->{_attrs}{record_filter};
1264   return @new;
1265 }
1266
1267 sub _collapse_result {
1268   my ($self, $as_proto, $row) = @_;
1269
1270   my @copy = @$row;
1271
1272   # 'foo'         => [ undef, 'foo' ]
1273   # 'foo.bar'     => [ 'foo', 'bar' ]
1274   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1275
1276   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1277
1278   my %collapse = %{$self->{_attrs}{collapse}||{}};
1279
1280   my @pri_index;
1281
1282   # if we're doing collapsing (has_many prefetch) we need to grab records
1283   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1284   # we know we don't have to bother.
1285
1286   # the reason for not using the collapse stuff directly is because if you
1287   # had for e.g. two artists in a row with no cds, the collapse info for
1288   # both would be NULL (undef) so you'd lose the second artist
1289
1290   # store just the index so we can check the array positions from the row
1291   # without having to contruct the full hash
1292
1293   if (keys %collapse) {
1294     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1295     foreach my $i (0 .. $#construct_as) {
1296       next if defined($construct_as[$i][0]); # only self table
1297       if (delete $pri{$construct_as[$i][1]}) {
1298         push(@pri_index, $i);
1299       }
1300       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1301     }
1302   }
1303
1304   # no need to do an if, it'll be empty if @pri_index is empty anyway
1305
1306   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1307
1308   my @const_rows;
1309
1310   do { # no need to check anything at the front, we always want the first row
1311
1312     my %const;
1313
1314     foreach my $this_as (@construct_as) {
1315       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1316     }
1317
1318     push(@const_rows, \%const);
1319
1320   } until ( # no pri_index => no collapse => drop straight out
1321       !@pri_index
1322     or
1323       do { # get another row, stash it, drop out if different PK
1324
1325         @copy = $self->cursor->next;
1326         $self->{stashed_row} = \@copy;
1327
1328         # last thing in do block, counts as true if anything doesn't match
1329
1330         # check xor defined first for NULL vs. NOT NULL then if one is
1331         # defined the other must be so check string equality
1332
1333         grep {
1334           (defined $pri_vals{$_} ^ defined $copy[$_])
1335           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1336         } @pri_index;
1337       }
1338   );
1339
1340   my $alias = $self->{attrs}{alias};
1341   my $info = [];
1342
1343   my %collapse_pos;
1344
1345   my @const_keys;
1346
1347   foreach my $const (@const_rows) {
1348     scalar @const_keys or do {
1349       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1350     };
1351     foreach my $key (@const_keys) {
1352       if (length $key) {
1353         my $target = $info;
1354         my @parts = split(/\./, $key);
1355         my $cur = '';
1356         my $data = $const->{$key};
1357         foreach my $p (@parts) {
1358           $target = $target->[1]->{$p} ||= [];
1359           $cur .= ".${p}";
1360           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1361             # collapsing at this point and on final part
1362             my $pos = $collapse_pos{$cur};
1363             CK: foreach my $ck (@ckey) {
1364               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1365                 $collapse_pos{$cur} = $data;
1366                 delete @collapse_pos{ # clear all positioning for sub-entries
1367                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1368                 };
1369                 push(@$target, []);
1370                 last CK;
1371               }
1372             }
1373           }
1374           if (exists $collapse{$cur}) {
1375             $target = $target->[-1];
1376           }
1377         }
1378         $target->[0] = $data;
1379       } else {
1380         $info->[0] = $const->{$key};
1381       }
1382     }
1383   }
1384
1385   return $info;
1386 }
1387
1388 =head2 result_source
1389
1390 =over 4
1391
1392 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1393
1394 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1395
1396 =back
1397
1398 An accessor for the primary ResultSource object from which this ResultSet
1399 is derived.
1400
1401 =head2 result_class
1402
1403 =over 4
1404
1405 =item Arguments: $result_class?
1406
1407 =item Return Value: $result_class
1408
1409 =back
1410
1411 An accessor for the class to use when creating result objects. Defaults to
1412 C<< result_source->result_class >> - which in most cases is the name of the
1413 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1414
1415 Note that changing the result_class will also remove any components
1416 that were originally loaded in the source class via
1417 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1418 in the original source class will not run.
1419
1420 =cut
1421
1422 sub result_class {
1423   my ($self, $result_class) = @_;
1424   if ($result_class) {
1425     unless (ref $result_class) { # don't fire this for an object
1426       $self->ensure_class_loaded($result_class);
1427     }
1428     $self->_result_class($result_class);
1429     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1430     # permit the user to set result class on one result set only; it only
1431     # chains if provided to search()
1432     #$self->{attrs}{result_class} = $result_class if ref $self;
1433   }
1434   $self->_result_class;
1435 }
1436
1437 =head2 count
1438
1439 =over 4
1440
1441 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1442
1443 =item Return Value: $count
1444
1445 =back
1446
1447 Performs an SQL C<COUNT> with the same query as the resultset was built
1448 with to find the number of elements. Passing arguments is equivalent to
1449 C<< $rs->search ($cond, \%attrs)->count >>
1450
1451 =cut
1452
1453 sub count {
1454   my $self = shift;
1455   return $self->search(@_)->count if @_ and defined $_[0];
1456   return scalar @{ $self->get_cache } if $self->get_cache;
1457
1458   my $attrs = { %{ $self->_resolved_attrs } };
1459
1460   # this is a little optimization - it is faster to do the limit
1461   # adjustments in software, instead of a subquery
1462   my $rows = delete $attrs->{rows};
1463   my $offset = delete $attrs->{offset};
1464
1465   my $crs;
1466   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1467     $crs = $self->_count_subq_rs ($attrs);
1468   }
1469   else {
1470     $crs = $self->_count_rs ($attrs);
1471   }
1472   my $count = $crs->next;
1473
1474   $count -= $offset if $offset;
1475   $count = $rows if $rows and $rows < $count;
1476   $count = 0 if ($count < 0);
1477
1478   return $count;
1479 }
1480
1481 =head2 count_rs
1482
1483 =over 4
1484
1485 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1486
1487 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1488
1489 =back
1490
1491 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1492 This can be very handy for subqueries:
1493
1494   ->search( { amount => $some_rs->count_rs->as_query } )
1495
1496 As with regular resultsets the SQL query will be executed only after
1497 the resultset is accessed via L</next> or L</all>. That would return
1498 the same single value obtainable via L</count>.
1499
1500 =cut
1501
1502 sub count_rs {
1503   my $self = shift;
1504   return $self->search(@_)->count_rs if @_;
1505
1506   # this may look like a lack of abstraction (count() does about the same)
1507   # but in fact an _rs *must* use a subquery for the limits, as the
1508   # software based limiting can not be ported if this $rs is to be used
1509   # in a subquery itself (i.e. ->as_query)
1510   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1511     return $self->_count_subq_rs;
1512   }
1513   else {
1514     return $self->_count_rs;
1515   }
1516 }
1517
1518 #
1519 # returns a ResultSetColumn object tied to the count query
1520 #
1521 sub _count_rs {
1522   my ($self, $attrs) = @_;
1523
1524   my $rsrc = $self->result_source;
1525   $attrs ||= $self->_resolved_attrs;
1526
1527   my $tmp_attrs = { %$attrs };
1528   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1529   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1530
1531   # overwrite the selector (supplied by the storage)
1532   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1533   $tmp_attrs->{as} = 'count';
1534   delete @{$tmp_attrs}{qw/columns/};
1535
1536   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1537
1538   return $tmp_rs;
1539 }
1540
1541 #
1542 # same as above but uses a subquery
1543 #
1544 sub _count_subq_rs {
1545   my ($self, $attrs) = @_;
1546
1547   my $rsrc = $self->result_source;
1548   $attrs ||= $self->_resolved_attrs;
1549
1550   my $sub_attrs = { %$attrs };
1551   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1552   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1553
1554   # if we multi-prefetch we group_by something unique, as this is what we would
1555   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1556   if ( keys %{$attrs->{collapse}}  ) {
1557     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1558       $rsrc->_identifying_column_set || $self->throw_exception(
1559         'Unable to construct a unique group_by criteria properly collapsing the '
1560       . 'has_many prefetch before count()'
1561       );
1562     } ]
1563   }
1564
1565   # Calculate subquery selector
1566   if (my $g = $sub_attrs->{group_by}) {
1567
1568     my $sql_maker = $rsrc->storage->sql_maker;
1569
1570     # necessary as the group_by may refer to aliased functions
1571     my $sel_index;
1572     for my $sel (@{$attrs->{select}}) {
1573       $sel_index->{$sel->{-as}} = $sel
1574         if (ref $sel eq 'HASH' and $sel->{-as});
1575     }
1576
1577     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1578     # also look for named aggregates referred in the having clause
1579     # having often contains scalarrefs - thus parse it out entirely
1580     my @parts = @$g;
1581     if ($attrs->{having}) {
1582       local $sql_maker->{having_bind};
1583       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1584       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1585       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1586         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1587         # if we don't unset it we screw up retarded but unfortunately working
1588         # 'MAX(foo.bar)' => { '>', 3 }
1589         $sql_maker->{name_sep} = '';
1590       }
1591
1592       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1593
1594       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1595
1596       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1597       # and if all fails for an utterly naive quoted scalar-with-function
1598       while ($sql =~ /
1599         $rquote $sep $lquote (.+?) $rquote
1600           |
1601         [\s,] \w+ \. (\w+) [\s,]
1602           |
1603         [\s,] $lquote (.+?) $rquote [\s,]
1604       /gx) {
1605         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1606       }
1607     }
1608
1609     for (@parts) {
1610       my $colpiece = $sel_index->{$_} || $_;
1611
1612       # unqualify join-based group_by's. Arcane but possible query
1613       # also horrible horrible hack to alias a column (not a func.)
1614       # (probably need to introduce SQLA syntax)
1615       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1616         my $as = $colpiece;
1617         $as =~ s/\./__/;
1618         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1619       }
1620       push @{$sub_attrs->{select}}, $colpiece;
1621     }
1622   }
1623   else {
1624     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1625     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1626   }
1627
1628   return $rsrc->resultset_class
1629                ->new ($rsrc, $sub_attrs)
1630                 ->as_subselect_rs
1631                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1632                   ->get_column ('count');
1633 }
1634
1635 sub _bool {
1636   return 1;
1637 }
1638
1639 =head2 count_literal
1640
1641 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1642 should only be used in that context. See L</search_literal> for further info.
1643
1644 =over 4
1645
1646 =item Arguments: $sql_fragment, @standalone_bind_values
1647
1648 =item Return Value: $count
1649
1650 =back
1651
1652 Counts the results in a literal query. Equivalent to calling L</search_literal>
1653 with the passed arguments, then L</count>.
1654
1655 =cut
1656
1657 sub count_literal { shift->search_literal(@_)->count; }
1658
1659 =head2 all
1660
1661 =over 4
1662
1663 =item Arguments: none
1664
1665 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1666
1667 =back
1668
1669 Returns all elements in the resultset.
1670
1671 =cut
1672
1673 sub all {
1674   my $self = shift;
1675   if(@_) {
1676       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1677   }
1678
1679   return @{ $self->get_cache } if $self->get_cache;
1680
1681   my @obj;
1682
1683   if (keys %{$self->_resolved_attrs->{collapse}}) {
1684     # Using $self->cursor->all is really just an optimisation.
1685     # If we're collapsing has_many prefetches it probably makes
1686     # very little difference, and this is cleaner than hacking
1687     # _construct_object to survive the approach
1688     $self->cursor->reset;
1689     my @row = $self->cursor->next;
1690     while (@row) {
1691       push(@obj, $self->_construct_object(@row));
1692       @row = (exists $self->{stashed_row}
1693                ? @{delete $self->{stashed_row}}
1694                : $self->cursor->next);
1695     }
1696   } else {
1697     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1698   }
1699
1700   $self->set_cache(\@obj) if $self->{attrs}{cache};
1701
1702   return @obj;
1703 }
1704
1705 =head2 reset
1706
1707 =over 4
1708
1709 =item Arguments: none
1710
1711 =item Return Value: $self
1712
1713 =back
1714
1715 Resets the resultset's cursor, so you can iterate through the elements again.
1716 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1717 another query.
1718
1719 =cut
1720
1721 sub reset {
1722   my ($self) = @_;
1723   $self->{all_cache_position} = 0;
1724   $self->cursor->reset;
1725   return $self;
1726 }
1727
1728 =head2 first
1729
1730 =over 4
1731
1732 =item Arguments: none
1733
1734 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1735
1736 =back
1737
1738 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1739 an object for the first result (or C<undef> if the resultset is empty).
1740
1741 =cut
1742
1743 sub first {
1744   return $_[0]->reset->next;
1745 }
1746
1747
1748 # _rs_update_delete
1749 #
1750 # Determines whether and what type of subquery is required for the $rs operation.
1751 # If grouping is necessary either supplies its own, or verifies the current one
1752 # After all is done delegates to the proper storage method.
1753
1754 sub _rs_update_delete {
1755   my ($self, $op, $values) = @_;
1756
1757   my $rsrc = $self->result_source;
1758   my $storage = $rsrc->schema->storage;
1759
1760   my $attrs = { %{$self->_resolved_attrs} };
1761
1762   my $join_classifications;
1763   my $existing_group_by = delete $attrs->{group_by};
1764
1765   # do we need a subquery for any reason?
1766   my $needs_subq = (
1767     defined $existing_group_by
1768       or
1769     # if {from} is unparseable wrap a subq
1770     ref($attrs->{from}) ne 'ARRAY'
1771       or
1772     # limits call for a subq
1773     $self->_has_resolved_attr(qw/rows offset/)
1774   );
1775
1776   # simplify the joinmap, so we can further decide if a subq is necessary
1777   if (!$needs_subq and @{$attrs->{from}} > 1) {
1778     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1779
1780     # check if there are any joins left after the prune
1781     if ( @{$attrs->{from}} > 1 ) {
1782       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1783         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1784         $attrs->{select},
1785         $self->{cond},
1786         $attrs
1787       );
1788
1789       # any non-pruneable joins imply subq
1790       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1791     }
1792   }
1793
1794   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1795   $needs_subq ||= (
1796     (ref $attrs->{from}[0]) ne 'HASH'
1797       or
1798     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1799   );
1800
1801   my ($cond, $guard);
1802   # do we need anything like a subquery?
1803   if (! $needs_subq) {
1804     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1805     # a condition containing 'me' or other table prefixes will not work
1806     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1807     $cond = do {
1808       my $sqla = $rsrc->storage->sql_maker;
1809       local $sqla->{_dequalify_idents} = 1;
1810       \[ $sqla->_recurse_where($self->{cond}) ];
1811     };
1812   }
1813   else {
1814     # we got this far - means it is time to wrap a subquery
1815     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1816       sprintf(
1817         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1818         $op,
1819         $rsrc->source_name,
1820       )
1821     );
1822
1823     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1824     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1825     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1826     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1827     my $subrs = (ref $self)->new($rsrc, $attrs);
1828
1829     if (@$idcols == 1) {
1830       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1831     }
1832     elsif ($storage->_use_multicolumn_in) {
1833       # no syntax for calling this properly yet
1834       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1835       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1836         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1837         $subrs->as_query
1838       ),
1839     }
1840     else {
1841       # if all else fails - get all primary keys and operate over a ORed set
1842       # wrap in a transaction for consistency
1843       # this is where the group_by/multiplication starts to matter
1844       if (
1845         $existing_group_by
1846           or
1847         keys %{ $join_classifications->{multiplying} || {} }
1848       ) {
1849         # make sure if there is a supplied group_by it matches the columns compiled above
1850         # perfectly. Anything else can not be sanely executed on most databases so croak
1851         # right then and there
1852         if ($existing_group_by) {
1853           my @current_group_by = map
1854             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1855             @$existing_group_by
1856           ;
1857
1858           if (
1859             join ("\x00", sort @current_group_by)
1860               ne
1861             join ("\x00", sort @{$attrs->{columns}} )
1862           ) {
1863             $self->throw_exception (
1864               "You have just attempted a $op operation on a resultset which does group_by"
1865               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1866               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1867               . ' kind of queries. Please retry the operation with a modified group_by or'
1868               . ' without using one at all.'
1869             );
1870           }
1871         }
1872
1873         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1874       }
1875
1876       $guard = $storage->txn_scope_guard;
1877
1878       $cond = [];
1879       for my $row ($subrs->cursor->all) {
1880         push @$cond, { map
1881           { $idcols->[$_] => $row->[$_] }
1882           (0 .. $#$idcols)
1883         };
1884       }
1885     }
1886   }
1887
1888   my $res = $storage->$op (
1889     $rsrc,
1890     $op eq 'update' ? $values : (),
1891     $cond,
1892   );
1893
1894   $guard->commit if $guard;
1895
1896   return $res;
1897 }
1898
1899 =head2 update
1900
1901 =over 4
1902
1903 =item Arguments: \%values
1904
1905 =item Return Value: $underlying_storage_rv
1906
1907 =back
1908
1909 Sets the specified columns in the resultset to the supplied values in a
1910 single query. Note that this will not run any accessor/set_column/update
1911 triggers, nor will it update any result object instances derived from this
1912 resultset (this includes the contents of the L<resultset cache|/set_cache>
1913 if any). See L</update_all> if you need to execute any on-update
1914 triggers or cascades defined either by you or a
1915 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1916
1917 The return value is a pass through of what the underlying
1918 storage backend returned, and may vary. See L<DBI/execute> for the most
1919 common case.
1920
1921 =head3 CAVEAT
1922
1923 Note that L</update> does not process/deflate any of the values passed in.
1924 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1925 ensure manually that any value passed to this method will stringify to
1926 something the RDBMS knows how to deal with. A notable example is the
1927 handling of L<DateTime> objects, for more info see:
1928 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1929
1930 =cut
1931
1932 sub update {
1933   my ($self, $values) = @_;
1934   $self->throw_exception('Values for update must be a hash')
1935     unless ref $values eq 'HASH';
1936
1937   return $self->_rs_update_delete ('update', $values);
1938 }
1939
1940 =head2 update_all
1941
1942 =over 4
1943
1944 =item Arguments: \%values
1945
1946 =item Return Value: 1
1947
1948 =back
1949
1950 Fetches all objects and updates them one at a time via
1951 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1952 triggers, while L</update> will not.
1953
1954 =cut
1955
1956 sub update_all {
1957   my ($self, $values) = @_;
1958   $self->throw_exception('Values for update_all must be a hash')
1959     unless ref $values eq 'HASH';
1960
1961   my $guard = $self->result_source->schema->txn_scope_guard;
1962   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1963   $guard->commit;
1964   return 1;
1965 }
1966
1967 =head2 delete
1968
1969 =over 4
1970
1971 =item Arguments: none
1972
1973 =item Return Value: $underlying_storage_rv
1974
1975 =back
1976
1977 Deletes the rows matching this resultset in a single query. Note that this
1978 will not run any delete triggers, nor will it alter the
1979 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1980 derived from this resultset (this includes the contents of the
1981 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1982 execute any on-delete triggers or cascades defined either by you or a
1983 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1984
1985 The return value is a pass through of what the underlying storage backend
1986 returned, and may vary. See L<DBI/execute> for the most common case.
1987
1988 =cut
1989
1990 sub delete {
1991   my $self = shift;
1992   $self->throw_exception('delete does not accept any arguments')
1993     if @_;
1994
1995   return $self->_rs_update_delete ('delete');
1996 }
1997
1998 =head2 delete_all
1999
2000 =over 4
2001
2002 =item Arguments: none
2003
2004 =item Return Value: 1
2005
2006 =back
2007
2008 Fetches all objects and deletes them one at a time via
2009 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2010 triggers, while L</delete> will not.
2011
2012 =cut
2013
2014 sub delete_all {
2015   my $self = shift;
2016   $self->throw_exception('delete_all does not accept any arguments')
2017     if @_;
2018
2019   my $guard = $self->result_source->schema->txn_scope_guard;
2020   $_->delete for $self->all;
2021   $guard->commit;
2022   return 1;
2023 }
2024
2025 =head2 populate
2026
2027 =over 4
2028
2029 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2030
2031 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2032
2033 =back
2034
2035 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2036 arrayrefs.
2037
2038 =over
2039
2040 =item NOTE
2041
2042 The context of this method call has an important effect on what is
2043 submitted to storage. In void context data is fed directly to fastpath
2044 insertion routines provided by the underlying storage (most often
2045 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2046 L<insert|DBIx::Class::Row/insert> calls on the
2047 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2048 augmentation of these methods provided by components. For example if you
2049 are using something like L<DBIx::Class::UUIDColumns> to create primary
2050 keys for you, you will find that your PKs are empty.  In this case you
2051 will have to explicitly force scalar or list context in order to create
2052 those values.
2053
2054 =back
2055
2056 In non-void (scalar or list) context, this method is simply a wrapper
2057 for L</create>. Depending on list or scalar context either a list of
2058 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2059 containing these objects is returned.
2060
2061 When supplying data in "arrayref of arrayrefs" invocation style, the
2062 first element should be a list of column names and each subsequent
2063 element should be a data value in the earlier specified column order.
2064 For example:
2065
2066   $Arstist_rs->populate([
2067     [ qw( artistid name ) ],
2068     [ 100, 'A Formally Unknown Singer' ],
2069     [ 101, 'A singer that jumped the shark two albums ago' ],
2070     [ 102, 'An actually cool singer' ],
2071   ]);
2072
2073 For the arrayref of hashrefs style each hashref should be a structure
2074 suitable for passing to L</create>. Multi-create is also permitted with
2075 this syntax.
2076
2077   $schema->resultset("Artist")->populate([
2078      { artistid => 4, name => 'Manufactured Crap', cds => [
2079         { title => 'My First CD', year => 2006 },
2080         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2081       ],
2082      },
2083      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2084         { title => 'My parents sold me to a record company', year => 2005 },
2085         { title => 'Why Am I So Ugly?', year => 2006 },
2086         { title => 'I Got Surgery and am now Popular', year => 2007 }
2087       ],
2088      },
2089   ]);
2090
2091 If you attempt a void-context multi-create as in the example above (each
2092 Artist also has the related list of CDs), and B<do not> supply the
2093 necessary autoinc foreign key information, this method will proxy to the
2094 less efficient L</create>, and then throw the Result objects away. In this
2095 case there are obviously no benefits to using this method over L</create>.
2096
2097 =cut
2098
2099 sub populate {
2100   my $self = shift;
2101
2102   # cruft placed in standalone method
2103   my $data = $self->_normalize_populate_args(@_);
2104
2105   return unless @$data;
2106
2107   if(defined wantarray) {
2108     my @created = map { $self->create($_) } @$data;
2109     return wantarray ? @created : \@created;
2110   }
2111   else {
2112     my $first = $data->[0];
2113
2114     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2115     # it relationship data
2116     my (@rels, @columns);
2117     my $rsrc = $self->result_source;
2118     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2119     for (keys %$first) {
2120       my $ref = ref $first->{$_};
2121       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2122         ? push @rels, $_
2123         : push @columns, $_
2124       ;
2125     }
2126
2127     my @pks = $rsrc->primary_columns;
2128
2129     ## do the belongs_to relationships
2130     foreach my $index (0..$#$data) {
2131
2132       # delegate to create() for any dataset without primary keys with specified relationships
2133       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2134         for my $r (@rels) {
2135           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2136             my @ret = $self->populate($data);
2137             return;
2138           }
2139         }
2140       }
2141
2142       foreach my $rel (@rels) {
2143         next unless ref $data->[$index]->{$rel} eq "HASH";
2144         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2145         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2146         my $related = $result->result_source->_resolve_condition(
2147           $reverse_relinfo->{cond},
2148           $self,
2149           $result,
2150           $rel,
2151         );
2152
2153         delete $data->[$index]->{$rel};
2154         $data->[$index] = {%{$data->[$index]}, %$related};
2155
2156         push @columns, keys %$related if $index == 0;
2157       }
2158     }
2159
2160     ## inherit the data locked in the conditions of the resultset
2161     my ($rs_data) = $self->_merge_with_rscond({});
2162     delete @{$rs_data}{@columns};
2163
2164     ## do bulk insert on current row
2165     $rsrc->storage->insert_bulk(
2166       $rsrc,
2167       [@columns, keys %$rs_data],
2168       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2169     );
2170
2171     ## do the has_many relationships
2172     foreach my $item (@$data) {
2173
2174       my $main_row;
2175
2176       foreach my $rel (@rels) {
2177         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2178
2179         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2180
2181         my $child = $main_row->$rel;
2182
2183         my $related = $child->result_source->_resolve_condition(
2184           $rels->{$rel}{cond},
2185           $child,
2186           $main_row,
2187           $rel,
2188         );
2189
2190         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2191         my @populate = map { {%$_, %$related} } @rows_to_add;
2192
2193         $child->populate( \@populate );
2194       }
2195     }
2196   }
2197 }
2198
2199
2200 # populate() argumnets went over several incarnations
2201 # What we ultimately support is AoH
2202 sub _normalize_populate_args {
2203   my ($self, $arg) = @_;
2204
2205   if (ref $arg eq 'ARRAY') {
2206     if (!@$arg) {
2207       return [];
2208     }
2209     elsif (ref $arg->[0] eq 'HASH') {
2210       return $arg;
2211     }
2212     elsif (ref $arg->[0] eq 'ARRAY') {
2213       my @ret;
2214       my @colnames = @{$arg->[0]};
2215       foreach my $values (@{$arg}[1 .. $#$arg]) {
2216         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2217       }
2218       return \@ret;
2219     }
2220   }
2221
2222   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2223 }
2224
2225 =head2 pager
2226
2227 =over 4
2228
2229 =item Arguments: none
2230
2231 =item Return Value: L<$pager|Data::Page>
2232
2233 =back
2234
2235 Returns a L<Data::Page> object for the current resultset. Only makes
2236 sense for queries with a C<page> attribute.
2237
2238 To get the full count of entries for a paged resultset, call
2239 C<total_entries> on the L<Data::Page> object.
2240
2241 =cut
2242
2243 sub pager {
2244   my ($self) = @_;
2245
2246   return $self->{pager} if $self->{pager};
2247
2248   my $attrs = $self->{attrs};
2249   if (!defined $attrs->{page}) {
2250     $self->throw_exception("Can't create pager for non-paged rs");
2251   }
2252   elsif ($attrs->{page} <= 0) {
2253     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2254   }
2255   $attrs->{rows} ||= 10;
2256
2257   # throw away the paging flags and re-run the count (possibly
2258   # with a subselect) to get the real total count
2259   my $count_attrs = { %$attrs };
2260   delete $count_attrs->{$_} for qw/rows offset page pager/;
2261
2262   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2263
2264   require DBIx::Class::ResultSet::Pager;
2265   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2266     sub { $total_rs->count },  #lazy-get the total
2267     $attrs->{rows},
2268     $self->{attrs}{page},
2269   );
2270 }
2271
2272 =head2 page
2273
2274 =over 4
2275
2276 =item Arguments: $page_number
2277
2278 =item Return Value: L<$resultset|/search>
2279
2280 =back
2281
2282 Returns a resultset for the $page_number page of the resultset on which page
2283 is called, where each page contains a number of rows equal to the 'rows'
2284 attribute set on the resultset (10 by default).
2285
2286 =cut
2287
2288 sub page {
2289   my ($self, $page) = @_;
2290   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2291 }
2292
2293 =head2 new_result
2294
2295 =over 4
2296
2297 =item Arguments: \%col_data
2298
2299 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2300
2301 =back
2302
2303 Creates a new result object in the resultset's result class and returns
2304 it. The row is not inserted into the database at this point, call
2305 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2306 will tell you whether the result object has been inserted or not.
2307
2308 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2309
2310 =cut
2311
2312 sub new_result {
2313   my ($self, $values) = @_;
2314
2315   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2316     if @_ > 2;
2317
2318   $self->throw_exception( "new_result expects a hashref" )
2319     unless (ref $values eq 'HASH');
2320
2321   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2322
2323   my %new = (
2324     %$merged_cond,
2325     @$cols_from_relations
2326       ? (-cols_from_relations => $cols_from_relations)
2327       : (),
2328     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2329   );
2330
2331   return $self->result_class->new(\%new);
2332 }
2333
2334 # _merge_with_rscond
2335 #
2336 # Takes a simple hash of K/V data and returns its copy merged with the
2337 # condition already present on the resultset. Additionally returns an
2338 # arrayref of value/condition names, which were inferred from related
2339 # objects (this is needed for in-memory related objects)
2340 sub _merge_with_rscond {
2341   my ($self, $data) = @_;
2342
2343   my (%new_data, @cols_from_relations);
2344
2345   my $alias = $self->{attrs}{alias};
2346
2347   if (! defined $self->{cond}) {
2348     # just massage $data below
2349   }
2350   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2351     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2352     @cols_from_relations = keys %new_data;
2353   }
2354   elsif (ref $self->{cond} ne 'HASH') {
2355     $self->throw_exception(
2356       "Can't abstract implicit construct, resultset condition not a hash"
2357     );
2358   }
2359   else {
2360     # precendence must be given to passed values over values inherited from
2361     # the cond, so the order here is important.
2362     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2363     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2364
2365     while ( my($col, $value) = each %implied ) {
2366       my $vref = ref $value;
2367       if (
2368         $vref eq 'HASH'
2369           and
2370         keys(%$value) == 1
2371           and
2372         (keys %$value)[0] eq '='
2373       ) {
2374         $new_data{$col} = $value->{'='};
2375       }
2376       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2377         $new_data{$col} = $value;
2378       }
2379     }
2380   }
2381
2382   %new_data = (
2383     %new_data,
2384     %{ $self->_remove_alias($data, $alias) },
2385   );
2386
2387   return (\%new_data, \@cols_from_relations);
2388 }
2389
2390 # _has_resolved_attr
2391 #
2392 # determines if the resultset defines at least one
2393 # of the attributes supplied
2394 #
2395 # used to determine if a subquery is neccessary
2396 #
2397 # supports some virtual attributes:
2398 #   -join
2399 #     This will scan for any joins being present on the resultset.
2400 #     It is not a mere key-search but a deep inspection of {from}
2401 #
2402
2403 sub _has_resolved_attr {
2404   my ($self, @attr_names) = @_;
2405
2406   my $attrs = $self->_resolved_attrs;
2407
2408   my %extra_checks;
2409
2410   for my $n (@attr_names) {
2411     if (grep { $n eq $_ } (qw/-join/) ) {
2412       $extra_checks{$n}++;
2413       next;
2414     }
2415
2416     my $attr =  $attrs->{$n};
2417
2418     next if not defined $attr;
2419
2420     if (ref $attr eq 'HASH') {
2421       return 1 if keys %$attr;
2422     }
2423     elsif (ref $attr eq 'ARRAY') {
2424       return 1 if @$attr;
2425     }
2426     else {
2427       return 1 if $attr;
2428     }
2429   }
2430
2431   # a resolved join is expressed as a multi-level from
2432   return 1 if (
2433     $extra_checks{-join}
2434       and
2435     ref $attrs->{from} eq 'ARRAY'
2436       and
2437     @{$attrs->{from}} > 1
2438   );
2439
2440   return 0;
2441 }
2442
2443 # _collapse_cond
2444 #
2445 # Recursively collapse the condition.
2446
2447 sub _collapse_cond {
2448   my ($self, $cond, $collapsed) = @_;
2449
2450   $collapsed ||= {};
2451
2452   if (ref $cond eq 'ARRAY') {
2453     foreach my $subcond (@$cond) {
2454       next unless ref $subcond;  # -or
2455       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2456     }
2457   }
2458   elsif (ref $cond eq 'HASH') {
2459     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2460       foreach my $subcond (@{$cond->{-and}}) {
2461         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2462       }
2463     }
2464     else {
2465       foreach my $col (keys %$cond) {
2466         my $value = $cond->{$col};
2467         $collapsed->{$col} = $value;
2468       }
2469     }
2470   }
2471
2472   return $collapsed;
2473 }
2474
2475 # _remove_alias
2476 #
2477 # Remove the specified alias from the specified query hash. A copy is made so
2478 # the original query is not modified.
2479
2480 sub _remove_alias {
2481   my ($self, $query, $alias) = @_;
2482
2483   my %orig = %{ $query || {} };
2484   my %unaliased;
2485
2486   foreach my $key (keys %orig) {
2487     if ($key !~ /\./) {
2488       $unaliased{$key} = $orig{$key};
2489       next;
2490     }
2491     $unaliased{$1} = $orig{$key}
2492       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2493   }
2494
2495   return \%unaliased;
2496 }
2497
2498 =head2 as_query
2499
2500 =over 4
2501
2502 =item Arguments: none
2503
2504 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2505
2506 =back
2507
2508 Returns the SQL query and bind vars associated with the invocant.
2509
2510 This is generally used as the RHS for a subquery.
2511
2512 =cut
2513
2514 sub as_query {
2515   my $self = shift;
2516
2517   my $attrs = { %{ $self->_resolved_attrs } };
2518
2519   # For future use:
2520   #
2521   # in list ctx:
2522   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2523   # $sql also has no wrapping parenthesis in list ctx
2524   #
2525   my $sqlbind = $self->result_source->storage
2526     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2527
2528   return $sqlbind;
2529 }
2530
2531 =head2 find_or_new
2532
2533 =over 4
2534
2535 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2536
2537 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2538
2539 =back
2540
2541   my $artist = $schema->resultset('Artist')->find_or_new(
2542     { artist => 'fred' }, { key => 'artists' });
2543
2544   $cd->cd_to_producer->find_or_new({ producer => $producer },
2545                                    { key => 'primary });
2546
2547 Find an existing record from this resultset using L</find>. if none exists,
2548 instantiate a new result object and return it. The object will not be saved
2549 into your storage until you call L<DBIx::Class::Row/insert> on it.
2550
2551 You most likely want this method when looking for existing rows using a unique
2552 constraint that is not the primary key, or looking for related rows.
2553
2554 If you want objects to be saved immediately, use L</find_or_create> instead.
2555
2556 B<Note>: Make sure to read the documentation of L</find> and understand the
2557 significance of the C<key> attribute, as its lack may skew your search, and
2558 subsequently result in spurious new objects.
2559
2560 B<Note>: Take care when using C<find_or_new> with a table having
2561 columns with default values that you intend to be automatically
2562 supplied by the database (e.g. an auto_increment primary key column).
2563 In normal usage, the value of such columns should NOT be included at
2564 all in the call to C<find_or_new>, even when set to C<undef>.
2565
2566 =cut
2567
2568 sub find_or_new {
2569   my $self     = shift;
2570   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2571   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2572   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2573     return $row;
2574   }
2575   return $self->new_result($hash);
2576 }
2577
2578 =head2 create
2579
2580 =over 4
2581
2582 =item Arguments: \%col_data
2583
2584 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2585
2586 =back
2587
2588 Attempt to create a single new row or a row with multiple related rows
2589 in the table represented by the resultset (and related tables). This
2590 will not check for duplicate rows before inserting, use
2591 L</find_or_create> to do that.
2592
2593 To create one row for this resultset, pass a hashref of key/value
2594 pairs representing the columns of the table and the values you wish to
2595 store. If the appropriate relationships are set up, foreign key fields
2596 can also be passed an object representing the foreign row, and the
2597 value will be set to its primary key.
2598
2599 To create related objects, pass a hashref of related-object column values
2600 B<keyed on the relationship name>. If the relationship is of type C<multi>
2601 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2602 The process will correctly identify columns holding foreign keys, and will
2603 transparently populate them from the keys of the corresponding relation.
2604 This can be applied recursively, and will work correctly for a structure
2605 with an arbitrary depth and width, as long as the relationships actually
2606 exists and the correct column data has been supplied.
2607
2608 Instead of hashrefs of plain related data (key/value pairs), you may
2609 also pass new or inserted objects. New objects (not inserted yet, see
2610 L</new_result>), will be inserted into their appropriate tables.
2611
2612 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2613
2614 Example of creating a new row.
2615
2616   $person_rs->create({
2617     name=>"Some Person",
2618     email=>"somebody@someplace.com"
2619   });
2620
2621 Example of creating a new row and also creating rows in a related C<has_many>
2622 or C<has_one> resultset.  Note Arrayref.
2623
2624   $artist_rs->create(
2625      { artistid => 4, name => 'Manufactured Crap', cds => [
2626         { title => 'My First CD', year => 2006 },
2627         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2628       ],
2629      },
2630   );
2631
2632 Example of creating a new row and also creating a row in a related
2633 C<belongs_to> resultset. Note Hashref.
2634
2635   $cd_rs->create({
2636     title=>"Music for Silly Walks",
2637     year=>2000,
2638     artist => {
2639       name=>"Silly Musician",
2640     }
2641   });
2642
2643 =over
2644
2645 =item WARNING
2646
2647 When subclassing ResultSet never attempt to override this method. Since
2648 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2649 lot of the internals simply never call it, so your override will be
2650 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2651 or L<DBIx::Class::Row/insert> depending on how early in the
2652 L</create> process you need to intervene. See also warning pertaining to
2653 L</new>.
2654
2655 =back
2656
2657 =cut
2658
2659 sub create {
2660   my ($self, $attrs) = @_;
2661   $self->throw_exception( "create needs a hashref" )
2662     unless ref $attrs eq 'HASH';
2663   return $self->new_result($attrs)->insert;
2664 }
2665
2666 =head2 find_or_create
2667
2668 =over 4
2669
2670 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2671
2672 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2673
2674 =back
2675
2676   $cd->cd_to_producer->find_or_create({ producer => $producer },
2677                                       { key => 'primary' });
2678
2679 Tries to find a record based on its primary key or unique constraints; if none
2680 is found, creates one and returns that instead.
2681
2682   my $cd = $schema->resultset('CD')->find_or_create({
2683     cdid   => 5,
2684     artist => 'Massive Attack',
2685     title  => 'Mezzanine',
2686     year   => 2005,
2687   });
2688
2689 Also takes an optional C<key> attribute, to search by a specific key or unique
2690 constraint. For example:
2691
2692   my $cd = $schema->resultset('CD')->find_or_create(
2693     {
2694       artist => 'Massive Attack',
2695       title  => 'Mezzanine',
2696     },
2697     { key => 'cd_artist_title' }
2698   );
2699
2700 B<Note>: Make sure to read the documentation of L</find> and understand the
2701 significance of the C<key> attribute, as its lack may skew your search, and
2702 subsequently result in spurious row creation.
2703
2704 B<Note>: Because find_or_create() reads from the database and then
2705 possibly inserts based on the result, this method is subject to a race
2706 condition. Another process could create a record in the table after
2707 the find has completed and before the create has started. To avoid
2708 this problem, use find_or_create() inside a transaction.
2709
2710 B<Note>: Take care when using C<find_or_create> with a table having
2711 columns with default values that you intend to be automatically
2712 supplied by the database (e.g. an auto_increment primary key column).
2713 In normal usage, the value of such columns should NOT be included at
2714 all in the call to C<find_or_create>, even when set to C<undef>.
2715
2716 See also L</find> and L</update_or_create>. For information on how to declare
2717 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2718
2719 If you need to know if an existing row was found or a new one created use
2720 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2721 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2722 database!
2723
2724   my $cd = $schema->resultset('CD')->find_or_new({
2725     cdid   => 5,
2726     artist => 'Massive Attack',
2727     title  => 'Mezzanine',
2728     year   => 2005,
2729   });
2730
2731   if( !$cd->in_storage ) {
2732       # do some stuff
2733       $cd->insert;
2734   }
2735
2736 =cut
2737
2738 sub find_or_create {
2739   my $self     = shift;
2740   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2741   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2742   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2743     return $row;
2744   }
2745   return $self->create($hash);
2746 }
2747
2748 =head2 update_or_create
2749
2750 =over 4
2751
2752 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2753
2754 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2755
2756 =back
2757
2758   $resultset->update_or_create({ col => $val, ... });
2759
2760 Like L</find_or_create>, but if a row is found it is immediately updated via
2761 C<< $found_row->update (\%col_data) >>.
2762
2763
2764 Takes an optional C<key> attribute to search on a specific unique constraint.
2765 For example:
2766
2767   # In your application
2768   my $cd = $schema->resultset('CD')->update_or_create(
2769     {
2770       artist => 'Massive Attack',
2771       title  => 'Mezzanine',
2772       year   => 1998,
2773     },
2774     { key => 'cd_artist_title' }
2775   );
2776
2777   $cd->cd_to_producer->update_or_create({
2778     producer => $producer,
2779     name => 'harry',
2780   }, {
2781     key => 'primary',
2782   });
2783
2784 B<Note>: Make sure to read the documentation of L</find> and understand the
2785 significance of the C<key> attribute, as its lack may skew your search, and
2786 subsequently result in spurious row creation.
2787
2788 B<Note>: Take care when using C<update_or_create> with a table having
2789 columns with default values that you intend to be automatically
2790 supplied by the database (e.g. an auto_increment primary key column).
2791 In normal usage, the value of such columns should NOT be included at
2792 all in the call to C<update_or_create>, even when set to C<undef>.
2793
2794 See also L</find> and L</find_or_create>. For information on how to declare
2795 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2796
2797 If you need to know if an existing row was updated or a new one created use
2798 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2799 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2800 database!
2801
2802 =cut
2803
2804 sub update_or_create {
2805   my $self = shift;
2806   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2807   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2808
2809   my $row = $self->find($cond, $attrs);
2810   if (defined $row) {
2811     $row->update($cond);
2812     return $row;
2813   }
2814
2815   return $self->create($cond);
2816 }
2817
2818 =head2 update_or_new
2819
2820 =over 4
2821
2822 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2823
2824 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2825
2826 =back
2827
2828   $resultset->update_or_new({ col => $val, ... });
2829
2830 Like L</find_or_new> but if a row is found it is immediately updated via
2831 C<< $found_row->update (\%col_data) >>.
2832
2833 For example:
2834
2835   # In your application
2836   my $cd = $schema->resultset('CD')->update_or_new(
2837     {
2838       artist => 'Massive Attack',
2839       title  => 'Mezzanine',
2840       year   => 1998,
2841     },
2842     { key => 'cd_artist_title' }
2843   );
2844
2845   if ($cd->in_storage) {
2846       # the cd was updated
2847   }
2848   else {
2849       # the cd is not yet in the database, let's insert it
2850       $cd->insert;
2851   }
2852
2853 B<Note>: Make sure to read the documentation of L</find> and understand the
2854 significance of the C<key> attribute, as its lack may skew your search, and
2855 subsequently result in spurious new objects.
2856
2857 B<Note>: Take care when using C<update_or_new> with a table having
2858 columns with default values that you intend to be automatically
2859 supplied by the database (e.g. an auto_increment primary key column).
2860 In normal usage, the value of such columns should NOT be included at
2861 all in the call to C<update_or_new>, even when set to C<undef>.
2862
2863 See also L</find>, L</find_or_create> and L</find_or_new>.
2864
2865 =cut
2866
2867 sub update_or_new {
2868     my $self  = shift;
2869     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2870     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2871
2872     my $row = $self->find( $cond, $attrs );
2873     if ( defined $row ) {
2874         $row->update($cond);
2875         return $row;
2876     }
2877
2878     return $self->new_result($cond);
2879 }
2880
2881 =head2 get_cache
2882
2883 =over 4
2884
2885 =item Arguments: none
2886
2887 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2888
2889 =back
2890
2891 Gets the contents of the cache for the resultset, if the cache is set.
2892
2893 The cache is populated either by using the L</prefetch> attribute to
2894 L</search> or by calling L</set_cache>.
2895
2896 =cut
2897
2898 sub get_cache {
2899   shift->{all_cache};
2900 }
2901
2902 =head2 set_cache
2903
2904 =over 4
2905
2906 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2907
2908 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2909
2910 =back
2911
2912 Sets the contents of the cache for the resultset. Expects an arrayref
2913 of objects of the same class as those produced by the resultset. Note that
2914 if the cache is set, the resultset will return the cached objects rather
2915 than re-querying the database even if the cache attr is not set.
2916
2917 The contents of the cache can also be populated by using the
2918 L</prefetch> attribute to L</search>.
2919
2920 =cut
2921
2922 sub set_cache {
2923   my ( $self, $data ) = @_;
2924   $self->throw_exception("set_cache requires an arrayref")
2925       if defined($data) && (ref $data ne 'ARRAY');
2926   $self->{all_cache} = $data;
2927 }
2928
2929 =head2 clear_cache
2930
2931 =over 4
2932
2933 =item Arguments: none
2934
2935 =item Return Value: undef
2936
2937 =back
2938
2939 Clears the cache for the resultset.
2940
2941 =cut
2942
2943 sub clear_cache {
2944   shift->set_cache(undef);
2945 }
2946
2947 =head2 is_paged
2948
2949 =over 4
2950
2951 =item Arguments: none
2952
2953 =item Return Value: true, if the resultset has been paginated
2954
2955 =back
2956
2957 =cut
2958
2959 sub is_paged {
2960   my ($self) = @_;
2961   return !!$self->{attrs}{page};
2962 }
2963
2964 =head2 is_ordered
2965
2966 =over 4
2967
2968 =item Arguments: none
2969
2970 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2971
2972 =back
2973
2974 =cut
2975
2976 sub is_ordered {
2977   my ($self) = @_;
2978   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2979 }
2980
2981 =head2 related_resultset
2982
2983 =over 4
2984
2985 =item Arguments: $rel_name
2986
2987 =item Return Value: L<$resultset|/search>
2988
2989 =back
2990
2991 Returns a related resultset for the supplied relationship name.
2992
2993   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2994
2995 =cut
2996
2997 sub related_resultset {
2998   my ($self, $rel) = @_;
2999
3000   $self->{related_resultsets} ||= {};
3001   return $self->{related_resultsets}{$rel} ||= do {
3002     my $rsrc = $self->result_source;
3003     my $rel_info = $rsrc->relationship_info($rel);
3004
3005     $self->throw_exception(
3006       "search_related: result source '" . $rsrc->source_name .
3007         "' has no such relationship $rel")
3008       unless $rel_info;
3009
3010     my $attrs = $self->_chain_relationship($rel);
3011
3012     my $join_count = $attrs->{seen_join}{$rel};
3013
3014     my $alias = $self->result_source->storage
3015         ->relname_to_table_alias($rel, $join_count);
3016
3017     # since this is search_related, and we already slid the select window inwards
3018     # (the select/as attrs were deleted in the beginning), we need to flip all
3019     # left joins to inner, so we get the expected results
3020     # read the comment on top of the actual function to see what this does
3021     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3022
3023
3024     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3025     delete @{$attrs}{qw(result_class alias)};
3026
3027     my $new_cache;
3028
3029     if (my $cache = $self->get_cache) {
3030       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3031         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3032                         @$cache ];
3033       }
3034     }
3035
3036     my $rel_source = $rsrc->related_source($rel);
3037
3038     my $new = do {
3039
3040       # The reason we do this now instead of passing the alias to the
3041       # search_rs below is that if you wrap/overload resultset on the
3042       # source you need to know what alias it's -going- to have for things
3043       # to work sanely (e.g. RestrictWithObject wants to be able to add
3044       # extra query restrictions, and these may need to be $alias.)
3045
3046       my $rel_attrs = $rel_source->resultset_attributes;
3047       local $rel_attrs->{alias} = $alias;
3048
3049       $rel_source->resultset
3050                  ->search_rs(
3051                      undef, {
3052                        %$attrs,
3053                        where => $attrs->{where},
3054                    });
3055     };
3056     $new->set_cache($new_cache) if $new_cache;
3057     $new;
3058   };
3059 }
3060
3061 =head2 current_source_alias
3062
3063 =over 4
3064
3065 =item Arguments: none
3066
3067 =item Return Value: $source_alias
3068
3069 =back
3070
3071 Returns the current table alias for the result source this resultset is built
3072 on, that will be used in the SQL query. Usually it is C<me>.
3073
3074 Currently the source alias that refers to the result set returned by a
3075 L</search>/L</find> family method depends on how you got to the resultset: it's
3076 C<me> by default, but eg. L</search_related> aliases it to the related result
3077 source name (and keeps C<me> referring to the original result set). The long
3078 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3079 (and make this method unnecessary).
3080
3081 Thus it's currently necessary to use this method in predefined queries (see
3082 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3083 source alias of the current result set:
3084
3085   # in a result set class
3086   sub modified_by {
3087     my ($self, $user) = @_;
3088
3089     my $me = $self->current_source_alias;
3090
3091     return $self->search({
3092       "$me.modified" => $user->id,
3093     });
3094   }
3095
3096 =cut
3097
3098 sub current_source_alias {
3099   return (shift->{attrs} || {})->{alias} || 'me';
3100 }
3101
3102 =head2 as_subselect_rs
3103
3104 =over 4
3105
3106 =item Arguments: none
3107
3108 =item Return Value: L<$resultset|/search>
3109
3110 =back
3111
3112 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3113 "virtual view" by including it as a subquery within the from clause.  From this
3114 point on, any joined tables are inaccessible to ->search on the resultset (as if
3115 it were simply where-filtered without joins).  For example:
3116
3117  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3118
3119  # 'x' now pollutes the query namespace
3120
3121  # So the following works as expected
3122  my $ok_rs = $rs->search({'x.other' => 1});
3123
3124  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3125  # def) we look for one row with contradictory terms and join in another table
3126  # (aliased 'x_2') which we never use
3127  my $broken_rs = $rs->search({'x.name' => 'def'});
3128
3129  my $rs2 = $rs->as_subselect_rs;
3130
3131  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3132  my $not_joined_rs = $rs2->search({'x.other' => 1});
3133
3134  # works as expected: finds a 'table' row related to two x rows (abc and def)
3135  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3136
3137 Another example of when one might use this would be to select a subset of
3138 columns in a group by clause:
3139
3140  my $rs = $schema->resultset('Bar')->search(undef, {
3141    group_by => [qw{ id foo_id baz_id }],
3142  })->as_subselect_rs->search(undef, {
3143    columns => [qw{ id foo_id }]
3144  });
3145
3146 In the above example normally columns would have to be equal to the group by,
3147 but because we isolated the group by into a subselect the above works.
3148
3149 =cut
3150
3151 sub as_subselect_rs {
3152   my $self = shift;
3153
3154   my $attrs = $self->_resolved_attrs;
3155
3156   my $fresh_rs = (ref $self)->new (
3157     $self->result_source
3158   );
3159
3160   # these pieces will be locked in the subquery
3161   delete $fresh_rs->{cond};
3162   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3163
3164   return $fresh_rs->search( {}, {
3165     from => [{
3166       $attrs->{alias} => $self->as_query,
3167       -alias  => $attrs->{alias},
3168       -rsrc   => $self->result_source,
3169     }],
3170     alias => $attrs->{alias},
3171   });
3172 }
3173
3174 # This code is called by search_related, and makes sure there
3175 # is clear separation between the joins before, during, and
3176 # after the relationship. This information is needed later
3177 # in order to properly resolve prefetch aliases (any alias
3178 # with a relation_chain_depth less than the depth of the
3179 # current prefetch is not considered)
3180 #
3181 # The increments happen twice per join. An even number means a
3182 # relationship specified via a search_related, whereas an odd
3183 # number indicates a join/prefetch added via attributes
3184 #
3185 # Also this code will wrap the current resultset (the one we
3186 # chain to) in a subselect IFF it contains limiting attributes
3187 sub _chain_relationship {
3188   my ($self, $rel) = @_;
3189   my $source = $self->result_source;
3190   my $attrs = { %{$self->{attrs}||{}} };
3191
3192   # we need to take the prefetch the attrs into account before we
3193   # ->_resolve_join as otherwise they get lost - captainL
3194   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3195
3196   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3197
3198   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3199
3200   my $from;
3201   my @force_subq_attrs = qw/offset rows group_by having/;
3202
3203   if (
3204     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3205       ||
3206     $self->_has_resolved_attr (@force_subq_attrs)
3207   ) {
3208     # Nuke the prefetch (if any) before the new $rs attrs
3209     # are resolved (prefetch is useless - we are wrapping
3210     # a subquery anyway).
3211     my $rs_copy = $self->search;
3212     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3213       $rs_copy->{attrs}{join},
3214       delete $rs_copy->{attrs}{prefetch},
3215     );
3216
3217     $from = [{
3218       -rsrc   => $source,
3219       -alias  => $attrs->{alias},
3220       $attrs->{alias} => $rs_copy->as_query,
3221     }];
3222     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3223     $seen->{-relation_chain_depth} = 0;
3224   }
3225   elsif ($attrs->{from}) {  #shallow copy suffices
3226     $from = [ @{$attrs->{from}} ];
3227   }
3228   else {
3229     $from = [{
3230       -rsrc  => $source,
3231       -alias => $attrs->{alias},
3232       $attrs->{alias} => $source->from,
3233     }];
3234   }
3235
3236   my $jpath = ($seen->{-relation_chain_depth})
3237     ? $from->[-1][0]{-join_path}
3238     : [];
3239
3240   my @requested_joins = $source->_resolve_join(
3241     $join,
3242     $attrs->{alias},
3243     $seen,
3244     $jpath,
3245   );
3246
3247   push @$from, @requested_joins;
3248
3249   $seen->{-relation_chain_depth}++;
3250
3251   # if $self already had a join/prefetch specified on it, the requested
3252   # $rel might very well be already included. What we do in this case
3253   # is effectively a no-op (except that we bump up the chain_depth on
3254   # the join in question so we could tell it *is* the search_related)
3255   my $already_joined;
3256
3257   # we consider the last one thus reverse
3258   for my $j (reverse @requested_joins) {
3259     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3260     if ($rel eq $last_j) {
3261       $j->[0]{-relation_chain_depth}++;
3262       $already_joined++;
3263       last;
3264     }
3265   }
3266
3267   unless ($already_joined) {
3268     push @$from, $source->_resolve_join(
3269       $rel,
3270       $attrs->{alias},
3271       $seen,
3272       $jpath,
3273     );
3274   }
3275
3276   $seen->{-relation_chain_depth}++;
3277
3278   return {%$attrs, from => $from, seen_join => $seen};
3279 }
3280
3281 sub _resolved_attrs {
3282   my $self = shift;
3283   return $self->{_attrs} if $self->{_attrs};
3284
3285   my $attrs  = { %{ $self->{attrs} || {} } };
3286   my $source = $self->result_source;
3287   my $alias  = $attrs->{alias};
3288
3289   # default selection list
3290   $attrs->{columns} = [ $source->columns ]
3291     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3292
3293   # merge selectors together
3294   for (qw/columns select as/) {
3295     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3296       if $attrs->{$_} or $attrs->{"+$_"};
3297   }
3298
3299   # disassemble columns
3300   my (@sel, @as);
3301   if (my $cols = delete $attrs->{columns}) {
3302     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3303       if (ref $c eq 'HASH') {
3304         for my $as (sort keys %$c) {
3305           push @sel, $c->{$as};
3306           push @as, $as;
3307         }
3308       }
3309       else {
3310         push @sel, $c;
3311         push @as, $c;
3312       }
3313     }
3314   }
3315
3316   # when trying to weed off duplicates later do not go past this point -
3317   # everything added from here on is unbalanced "anyone's guess" stuff
3318   my $dedup_stop_idx = $#as;
3319
3320   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3321     if $attrs->{as};
3322   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3323     if $attrs->{select};
3324
3325   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3326   for (@sel) {
3327     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3328   }
3329
3330   # disqualify all $alias.col as-bits (collapser mandated)
3331   for (@as) {
3332     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3333   }
3334
3335   # de-duplicate the result (remove *identical* select/as pairs)
3336   # and also die on duplicate {as} pointing to different {select}s
3337   # not using a c-style for as the condition is prone to shrinkage
3338   my $seen;
3339   my $i = 0;
3340   while ($i <= $dedup_stop_idx) {
3341     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3342       splice @sel, $i, 1;
3343       splice @as, $i, 1;
3344       $dedup_stop_idx--;
3345     }
3346     elsif ($seen->{$as[$i]}++) {
3347       $self->throw_exception(
3348         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3349       );
3350     }
3351     else {
3352       $i++;
3353     }
3354   }
3355
3356   $attrs->{select} = \@sel;
3357   $attrs->{as} = \@as;
3358
3359   $attrs->{from} ||= [{
3360     -rsrc   => $source,
3361     -alias  => $self->{attrs}{alias},
3362     $self->{attrs}{alias} => $source->from,
3363   }];
3364
3365   if ( $attrs->{join} || $attrs->{prefetch} ) {
3366
3367     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3368       if ref $attrs->{from} ne 'ARRAY';
3369
3370     my $join = (delete $attrs->{join}) || {};
3371
3372     if ( defined $attrs->{prefetch} ) {
3373       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3374     }
3375
3376     $attrs->{from} =    # have to copy here to avoid corrupting the original
3377       [
3378         @{ $attrs->{from} },
3379         $source->_resolve_join(
3380           $join,
3381           $alias,
3382           { %{ $attrs->{seen_join} || {} } },
3383           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3384             ? $attrs->{from}[-1][0]{-join_path}
3385             : []
3386           ,
3387         )
3388       ];
3389   }
3390
3391   if ( defined $attrs->{order_by} ) {
3392     $attrs->{order_by} = (
3393       ref( $attrs->{order_by} ) eq 'ARRAY'
3394       ? [ @{ $attrs->{order_by} } ]
3395       : [ $attrs->{order_by} || () ]
3396     );
3397   }
3398
3399   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3400     $attrs->{group_by} = [ $attrs->{group_by} ];
3401   }
3402
3403   # generate the distinct induced group_by early, as prefetch will be carried via a
3404   # subquery (since a group_by is present)
3405   if (delete $attrs->{distinct}) {
3406     if ($attrs->{group_by}) {
3407       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3408     }
3409     else {
3410       # distinct affects only the main selection part, not what prefetch may
3411       # add below.
3412       $attrs->{group_by} = $source->storage->_group_over_selection (
3413         $attrs->{from},
3414         $attrs->{select},
3415         $attrs->{order_by},
3416       );
3417     }
3418   }
3419
3420   $attrs->{collapse} ||= {};
3421   if ($attrs->{prefetch}) {
3422
3423     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3424       if $attrs->{_dark_selector};
3425
3426     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3427
3428     my $prefetch_ordering = [];
3429
3430     # this is a separate structure (we don't look in {from} directly)
3431     # as the resolver needs to shift things off the lists to work
3432     # properly (identical-prefetches on different branches)
3433     my $join_map = {};
3434     if (ref $attrs->{from} eq 'ARRAY') {
3435
3436       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3437
3438       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3439         next unless $j->[0]{-alias};
3440         next unless $j->[0]{-join_path};
3441         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3442
3443         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3444
3445         my $p = $join_map;
3446         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3447         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3448       }
3449     }
3450
3451     my @prefetch =
3452       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3453
3454     # we need to somehow mark which columns came from prefetch
3455     if (@prefetch) {
3456       my $sel_end = $#{$attrs->{select}};
3457       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3458     }
3459
3460     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3461     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3462
3463     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3464     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3465   }
3466
3467   # if both page and offset are specified, produce a combined offset
3468   # even though it doesn't make much sense, this is what pre 081xx has
3469   # been doing
3470   if (my $page = delete $attrs->{page}) {
3471     $attrs->{offset} =
3472       ($attrs->{rows} * ($page - 1))
3473             +
3474       ($attrs->{offset} || 0)
3475     ;
3476   }
3477
3478   return $self->{_attrs} = $attrs;
3479 }
3480
3481 sub _rollout_attr {
3482   my ($self, $attr) = @_;
3483
3484   if (ref $attr eq 'HASH') {
3485     return $self->_rollout_hash($attr);
3486   } elsif (ref $attr eq 'ARRAY') {
3487     return $self->_rollout_array($attr);
3488   } else {
3489     return [$attr];
3490   }
3491 }
3492
3493 sub _rollout_array {
3494   my ($self, $attr) = @_;
3495
3496   my @rolled_array;
3497   foreach my $element (@{$attr}) {
3498     if (ref $element eq 'HASH') {
3499       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3500     } elsif (ref $element eq 'ARRAY') {
3501       #  XXX - should probably recurse here
3502       push( @rolled_array, @{$self->_rollout_array($element)} );
3503     } else {
3504       push( @rolled_array, $element );
3505     }
3506   }
3507   return \@rolled_array;
3508 }
3509
3510 sub _rollout_hash {
3511   my ($self, $attr) = @_;
3512
3513   my @rolled_array;
3514   foreach my $key (keys %{$attr}) {
3515     push( @rolled_array, { $key => $attr->{$key} } );
3516   }
3517   return \@rolled_array;
3518 }
3519
3520 sub _calculate_score {
3521   my ($self, $a, $b) = @_;
3522
3523   if (defined $a xor defined $b) {
3524     return 0;
3525   }
3526   elsif (not defined $a) {
3527     return 1;
3528   }
3529
3530   if (ref $b eq 'HASH') {
3531     my ($b_key) = keys %{$b};
3532     if (ref $a eq 'HASH') {
3533       my ($a_key) = keys %{$a};
3534       if ($a_key eq $b_key) {
3535         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3536       } else {
3537         return 0;
3538       }
3539     } else {
3540       return ($a eq $b_key) ? 1 : 0;
3541     }
3542   } else {
3543     if (ref $a eq 'HASH') {
3544       my ($a_key) = keys %{$a};
3545       return ($b eq $a_key) ? 1 : 0;
3546     } else {
3547       return ($b eq $a) ? 1 : 0;
3548     }
3549   }
3550 }
3551
3552 sub _merge_joinpref_attr {
3553   my ($self, $orig, $import) = @_;
3554
3555   return $import unless defined($orig);
3556   return $orig unless defined($import);
3557
3558   $orig = $self->_rollout_attr($orig);
3559   $import = $self->_rollout_attr($import);
3560
3561   my $seen_keys;
3562   foreach my $import_element ( @{$import} ) {
3563     # find best candidate from $orig to merge $b_element into
3564     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3565     foreach my $orig_element ( @{$orig} ) {
3566       my $score = $self->_calculate_score( $orig_element, $import_element );
3567       if ($score > $best_candidate->{score}) {
3568         $best_candidate->{position} = $position;
3569         $best_candidate->{score} = $score;
3570       }
3571       $position++;
3572     }
3573     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3574     $import_key = '' if not defined $import_key;
3575
3576     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3577       push( @{$orig}, $import_element );
3578     } else {
3579       my $orig_best = $orig->[$best_candidate->{position}];
3580       # merge orig_best and b_element together and replace original with merged
3581       if (ref $orig_best ne 'HASH') {
3582         $orig->[$best_candidate->{position}] = $import_element;
3583       } elsif (ref $import_element eq 'HASH') {
3584         my ($key) = keys %{$orig_best};
3585         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3586       }
3587     }
3588     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3589   }
3590
3591   return $orig;
3592 }
3593
3594 {
3595   my $hm;
3596
3597   sub _merge_attr {
3598     $hm ||= do {
3599       require Hash::Merge;
3600       my $hm = Hash::Merge->new;
3601
3602       $hm->specify_behavior({
3603         SCALAR => {
3604           SCALAR => sub {
3605             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3606
3607             if ($defl xor $defr) {
3608               return [ $defl ? $_[0] : $_[1] ];
3609             }
3610             elsif (! $defl) {
3611               return [];
3612             }
3613             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3614               return [ $_[0] ];
3615             }
3616             else {
3617               return [$_[0], $_[1]];
3618             }
3619           },
3620           ARRAY => sub {
3621             return $_[1] if !defined $_[0];
3622             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3623             return [$_[0], @{$_[1]}]
3624           },
3625           HASH  => sub {
3626             return [] if !defined $_[0] and !keys %{$_[1]};
3627             return [ $_[1] ] if !defined $_[0];
3628             return [ $_[0] ] if !keys %{$_[1]};
3629             return [$_[0], $_[1]]
3630           },
3631         },
3632         ARRAY => {
3633           SCALAR => sub {
3634             return $_[0] if !defined $_[1];
3635             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3636             return [@{$_[0]}, $_[1]]
3637           },
3638           ARRAY => sub {
3639             my @ret = @{$_[0]} or return $_[1];
3640             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3641             my %idx = map { $_ => 1 } @ret;
3642             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3643             \@ret;
3644           },
3645           HASH => sub {
3646             return [ $_[1] ] if ! @{$_[0]};
3647             return $_[0] if !keys %{$_[1]};
3648             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3649             return [ @{$_[0]}, $_[1] ];
3650           },
3651         },
3652         HASH => {
3653           SCALAR => sub {
3654             return [] if !keys %{$_[0]} and !defined $_[1];
3655             return [ $_[0] ] if !defined $_[1];
3656             return [ $_[1] ] if !keys %{$_[0]};
3657             return [$_[0], $_[1]]
3658           },
3659           ARRAY => sub {
3660             return [] if !keys %{$_[0]} and !@{$_[1]};
3661             return [ $_[0] ] if !@{$_[1]};
3662             return $_[1] if !keys %{$_[0]};
3663             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3664             return [ $_[0], @{$_[1]} ];
3665           },
3666           HASH => sub {
3667             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3668             return [ $_[0] ] if !keys %{$_[1]};
3669             return [ $_[1] ] if !keys %{$_[0]};
3670             return [ $_[0] ] if $_[0] eq $_[1];
3671             return [ $_[0], $_[1] ];
3672           },
3673         }
3674       } => 'DBIC_RS_ATTR_MERGER');
3675       $hm;
3676     };
3677
3678     return $hm->merge ($_[1], $_[2]);
3679   }
3680 }
3681
3682 sub STORABLE_freeze {
3683   my ($self, $cloning) = @_;
3684   my $to_serialize = { %$self };
3685
3686   # A cursor in progress can't be serialized (and would make little sense anyway)
3687   delete $to_serialize->{cursor};
3688
3689   # nor is it sensical to store a not-yet-fired-count pager
3690   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3691     delete $to_serialize->{pager};
3692   }
3693
3694   Storable::nfreeze($to_serialize);
3695 }
3696
3697 # need this hook for symmetry
3698 sub STORABLE_thaw {
3699   my ($self, $cloning, $serialized) = @_;
3700
3701   %$self = %{ Storable::thaw($serialized) };
3702
3703   $self;
3704 }
3705
3706
3707 =head2 throw_exception
3708
3709 See L<DBIx::Class::Schema/throw_exception> for details.
3710
3711 =cut
3712
3713 sub throw_exception {
3714   my $self=shift;
3715
3716   if (ref $self and my $rsrc = $self->result_source) {
3717     $rsrc->throw_exception(@_)
3718   }
3719   else {
3720     DBIx::Class::Exception->throw(@_);
3721   }
3722 }
3723
3724 # XXX: FIXME: Attributes docs need clearing up
3725
3726 =head1 ATTRIBUTES
3727
3728 Attributes are used to refine a ResultSet in various ways when
3729 searching for data. They can be passed to any method which takes an
3730 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3731 L</count>.
3732
3733 Default attributes can be set on the result class using
3734 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3735 the CAVEATS on that feature before using it!)
3736
3737 These are in no particular order:
3738
3739 =head2 order_by
3740
3741 =over 4
3742
3743 =item Value: ( $order_by | \@order_by | \%order_by )
3744
3745 =back
3746
3747 Which column(s) to order the results by.
3748
3749 [The full list of suitable values is documented in
3750 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3751 common options.]
3752
3753 If a single column name, or an arrayref of names is supplied, the
3754 argument is passed through directly to SQL. The hashref syntax allows
3755 for connection-agnostic specification of ordering direction:
3756
3757  For descending order:
3758
3759   order_by => { -desc => [qw/col1 col2 col3/] }
3760
3761  For explicit ascending order:
3762
3763   order_by => { -asc => 'col' }
3764
3765 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3766 supported, although you are strongly encouraged to use the hashref
3767 syntax as outlined above.
3768
3769 =head2 columns
3770
3771 =over 4
3772
3773 =item Value: \@columns
3774
3775 =back
3776
3777 Shortcut to request a particular set of columns to be retrieved. Each
3778 column spec may be a string (a table column name), or a hash (in which
3779 case the key is the C<as> value, and the value is used as the C<select>
3780 expression). Adds C<me.> onto the start of any column without a C<.> in
3781 it and sets C<select> from that, then auto-populates C<as> from
3782 C<select> as normal. (You may also use the C<cols> attribute, as in
3783 earlier versions of DBIC.)
3784
3785 Essentially C<columns> does the same as L</select> and L</as>.
3786
3787     columns => [ 'foo', { bar => 'baz' } ]
3788
3789 is the same as
3790
3791     select => [qw/foo baz/],
3792     as => [qw/foo bar/]
3793
3794 =head2 +columns
3795
3796 =over 4
3797
3798 =item Value: \@columns
3799
3800 =back
3801
3802 Indicates additional columns to be selected from storage. Works the same
3803 as L</columns> but adds columns to the selection. (You may also use the
3804 C<include_columns> attribute, as in earlier versions of DBIC). For
3805 example:-
3806
3807   $schema->resultset('CD')->search(undef, {
3808     '+columns' => ['artist.name'],
3809     join => ['artist']
3810   });
3811
3812 would return all CDs and include a 'name' column to the information
3813 passed to object inflation. Note that the 'artist' is the name of the
3814 column (or relationship) accessor, and 'name' is the name of the column
3815 accessor in the related table.
3816
3817 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3818 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3819 unary plus operator before it.
3820
3821 =head2 include_columns
3822
3823 =over 4
3824
3825 =item Value: \@columns
3826
3827 =back
3828
3829 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3830
3831 =head2 select
3832
3833 =over 4
3834
3835 =item Value: \@select_columns
3836
3837 =back
3838
3839 Indicates which columns should be selected from the storage. You can use
3840 column names, or in the case of RDBMS back ends, function or stored procedure
3841 names:
3842
3843   $rs = $schema->resultset('Employee')->search(undef, {
3844     select => [
3845       'name',
3846       { count => 'employeeid' },
3847       { max => { length => 'name' }, -as => 'longest_name' }
3848     ]
3849   });
3850
3851   # Equivalent SQL
3852   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3853
3854 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3855 use L</select>, to instruct DBIx::Class how to store the result of the column.
3856 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3857 identifier aliasing. You can however alias a function, so you can use it in
3858 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3859 attribute> supplied as shown in the example above.
3860
3861 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3862 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3863 unary plus operator before it.
3864
3865 =head2 +select
3866
3867 =over 4
3868
3869 Indicates additional columns to be selected from storage.  Works the same as
3870 L</select> but adds columns to the default selection, instead of specifying
3871 an explicit list.
3872
3873 =back
3874
3875 =head2 +as
3876
3877 =over 4
3878
3879 Indicates additional column names for those added via L</+select>. See L</as>.
3880
3881 =back
3882
3883 =head2 as
3884
3885 =over 4
3886
3887 =item Value: \@inflation_names
3888
3889 =back
3890
3891 Indicates column names for object inflation. That is L</as> indicates the
3892 slot name in which the column value will be stored within the
3893 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3894 identifier by the C<get_column> method (or via the object accessor B<if one
3895 with the same name already exists>) as shown below. The L</as> attribute has
3896 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3897
3898   $rs = $schema->resultset('Employee')->search(undef, {
3899     select => [
3900       'name',
3901       { count => 'employeeid' },
3902       { max => { length => 'name' }, -as => 'longest_name' }
3903     ],
3904     as => [qw/
3905       name
3906       employee_count
3907       max_name_length
3908     /],
3909   });
3910
3911 If the object against which the search is performed already has an accessor
3912 matching a column name specified in C<as>, the value can be retrieved using
3913 the accessor as normal:
3914
3915   my $name = $employee->name();
3916
3917 If on the other hand an accessor does not exist in the object, you need to
3918 use C<get_column> instead:
3919
3920   my $employee_count = $employee->get_column('employee_count');
3921
3922 You can create your own accessors if required - see
3923 L<DBIx::Class::Manual::Cookbook> for details.
3924
3925 =head2 join
3926
3927 =over 4
3928
3929 =item Value: ($rel_name | \@rel_names | \%rel_names)
3930
3931 =back
3932
3933 Contains a list of relationships that should be joined for this query.  For
3934 example:
3935
3936   # Get CDs by Nine Inch Nails
3937   my $rs = $schema->resultset('CD')->search(
3938     { 'artist.name' => 'Nine Inch Nails' },
3939     { join => 'artist' }
3940   );
3941
3942 Can also contain a hash reference to refer to the other relation's relations.
3943 For example:
3944
3945   package MyApp::Schema::Track;
3946   use base qw/DBIx::Class/;
3947   __PACKAGE__->table('track');
3948   __PACKAGE__->add_columns(qw/trackid cd position title/);
3949   __PACKAGE__->set_primary_key('trackid');
3950   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3951   1;
3952
3953   # In your application
3954   my $rs = $schema->resultset('Artist')->search(
3955     { 'track.title' => 'Teardrop' },
3956     {
3957       join     => { cd => 'track' },
3958       order_by => 'artist.name',
3959     }
3960   );
3961
3962 You need to use the relationship (not the table) name in  conditions,
3963 because they are aliased as such. The current table is aliased as "me", so
3964 you need to use me.column_name in order to avoid ambiguity. For example:
3965
3966   # Get CDs from 1984 with a 'Foo' track
3967   my $rs = $schema->resultset('CD')->search(
3968     {
3969       'me.year' => 1984,
3970       'tracks.name' => 'Foo'
3971     },
3972     { join => 'tracks' }
3973   );
3974
3975 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3976 similarly for a third time). For e.g.
3977
3978   my $rs = $schema->resultset('Artist')->search({
3979     'cds.title'   => 'Down to Earth',
3980     'cds_2.title' => 'Popular',
3981   }, {
3982     join => [ qw/cds cds/ ],
3983   });
3984
3985 will return a set of all artists that have both a cd with title 'Down
3986 to Earth' and a cd with title 'Popular'.
3987
3988 If you want to fetch related objects from other tables as well, see C<prefetch>
3989 below.
3990
3991  NOTE: An internal join-chain pruner will discard certain joins while
3992  constructing the actual SQL query, as long as the joins in question do not
3993  affect the retrieved result. This for example includes 1:1 left joins
3994  that are not part of the restriction specification (WHERE/HAVING) nor are
3995  a part of the query selection.
3996
3997 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3998
3999 =head2 prefetch
4000
4001 =over 4
4002
4003 =item Value: ($rel_name | \@rel_names | \%rel_names)
4004
4005 =back
4006
4007 Contains one or more relationships that should be fetched along with
4008 the main query (when they are accessed afterwards the data will
4009 already be available, without extra queries to the database).  This is
4010 useful for when you know you will need the related objects, because it
4011 saves at least one query:
4012
4013   my $rs = $schema->resultset('Tag')->search(
4014     undef,
4015     {
4016       prefetch => {
4017         cd => 'artist'
4018       }
4019     }
4020   );
4021
4022 The initial search results in SQL like the following:
4023
4024   SELECT tag.*, cd.*, artist.* FROM tag
4025   JOIN cd ON tag.cd = cd.cdid
4026   JOIN artist ON cd.artist = artist.artistid
4027
4028 L<DBIx::Class> has no need to go back to the database when we access the
4029 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4030 case.
4031
4032 Simple prefetches will be joined automatically, so there is no need
4033 for a C<join> attribute in the above search.
4034
4035 L</prefetch> can be used with the any of the relationship types and
4036 multiple prefetches can be specified together. Below is a more complex
4037 example that prefetches a CD's artist, its liner notes (if present),
4038 the cover image, the tracks on that cd, and the guests on those
4039 tracks.
4040
4041  # Assuming:
4042  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4043  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4044  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4045  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4046
4047  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4048
4049  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4050
4051
4052  my $rs = $schema->resultset('CD')->search(
4053    undef,
4054    {
4055      prefetch => [
4056        { artist => 'record_label'},  # belongs_to => belongs_to
4057        'liner_note',                 # might_have
4058        'cover_image',                # has_one
4059        { tracks => 'guests' },       # has_many => has_many
4060      ]
4061    }
4062  );
4063
4064 This will produce SQL like the following:
4065
4066  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4067         tracks.*, guests.*
4068    FROM cd me
4069    JOIN artist artist
4070      ON artist.artistid = me.artistid
4071    JOIN record_label record_label
4072      ON record_label.labelid = artist.labelid
4073    LEFT JOIN track tracks
4074      ON tracks.cdid = me.cdid
4075    LEFT JOIN guest guests
4076      ON guests.trackid = track.trackid
4077    LEFT JOIN liner_notes liner_note
4078      ON liner_note.cdid = me.cdid
4079    JOIN cd_artwork cover_image
4080      ON cover_image.cdid = me.cdid
4081  ORDER BY tracks.cd
4082
4083 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4084 C<tracks>, and C<guests> of the CD will all be available through the
4085 relationship accessors without the need for additional queries to the
4086 database.
4087
4088 However, there is one caveat to be observed: it can be dangerous to
4089 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4090 relationship on a given level. e.g.:
4091
4092  my $rs = $schema->resultset('CD')->search(
4093    undef,
4094    {
4095      prefetch => [
4096        'tracks',                         # has_many
4097        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4098      ]
4099    }
4100  );
4101
4102 The collapser currently can't identify duplicate tuples for multiple
4103 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4104 result the second L<has_many|DBIx::Class::Relationship/has_many>
4105 relation could contain redundant objects.
4106
4107 =head3 Using L</prefetch> with L</join>
4108
4109 L</prefetch> implies a L</join> with the equivalent argument, and is
4110 properly merged with any existing L</join> specification. So the
4111 following:
4112
4113   my $rs = $schema->resultset('CD')->search(
4114    {'record_label.name' => 'Music Product Ltd.'},
4115    {
4116      join     => {artist => 'record_label'},
4117      prefetch => 'artist',
4118    }
4119  );
4120
4121 ... will work, searching on the record label's name, but only
4122 prefetching the C<artist>.
4123
4124 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4125
4126 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4127 prefetched relations.  So given:
4128
4129   my $rs = $schema->resultset('CD')->search(
4130    undef,
4131    {
4132      select   => ['cd.title'],
4133      as       => ['cd_title'],
4134      prefetch => 'artist',
4135    }
4136  );
4137
4138 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4139 becomes: C<'cd_title', 'artist.*'>.
4140
4141 =head3 CAVEATS
4142
4143 Prefetch does a lot of deep magic. As such, it may not behave exactly
4144 as you might expect.
4145
4146 =over 4
4147
4148 =item *
4149
4150 Prefetch uses the L</cache> to populate the prefetched relationships. This
4151 may or may not be what you want.
4152
4153 =item *
4154
4155 If you specify a condition on a prefetched relationship, ONLY those
4156 rows that match the prefetched condition will be fetched into that relationship.
4157 This means that adding prefetch to a search() B<may alter> what is returned by
4158 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4159
4160   my $artist_rs = $schema->resultset('Artist')->search({
4161       'cds.year' => 2008,
4162   }, {
4163       join => 'cds',
4164   });
4165
4166   my $count = $artist_rs->first->cds->count;
4167
4168   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4169
4170   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4171
4172   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4173
4174 that cmp_ok() may or may not pass depending on the datasets involved. This
4175 behavior may or may not survive the 0.09 transition.
4176
4177 =back
4178
4179 =head2 alias
4180
4181 =over 4
4182
4183 =item Value: $source_alias
4184
4185 =back
4186
4187 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4188 nested search queries (sub-SELECTs) might need specific aliases set to
4189 reference inner queries.  For example:
4190
4191    my $q = $rs
4192       ->related_resultset('CDs')
4193       ->related_resultset('Tracks')
4194       ->search({
4195          'track.id' => { -ident => 'none_search.id' },
4196       })
4197       ->as_query;
4198
4199    my $ids = $self->search({
4200       -not_exists => $q,
4201    }, {
4202       alias    => 'none_search',
4203       group_by => 'none_search.id',
4204    })->get_column('id')->as_query;
4205
4206    $self->search({ id => { -in => $ids } })
4207
4208 This attribute is directly tied to L</current_source_alias>.
4209
4210 =head2 page
4211
4212 =over 4
4213
4214 =item Value: $page
4215
4216 =back
4217
4218 Makes the resultset paged and specifies the page to retrieve. Effectively
4219 identical to creating a non-pages resultset and then calling ->page($page)
4220 on it.
4221
4222 If L</rows> attribute is not specified it defaults to 10 rows per page.
4223
4224 When you have a paged resultset, L</count> will only return the number
4225 of rows in the page. To get the total, use the L</pager> and call
4226 C<total_entries> on it.
4227
4228 =head2 rows
4229
4230 =over 4
4231
4232 =item Value: $rows
4233
4234 =back
4235
4236 Specifies the maximum number of rows for direct retrieval or the number of
4237 rows per page if the page attribute or method is used.
4238
4239 =head2 offset
4240
4241 =over 4
4242
4243 =item Value: $offset
4244
4245 =back
4246
4247 Specifies the (zero-based) row number for the  first row to be returned, or the
4248 of the first row of the first page if paging is used.
4249
4250 =head2 software_limit
4251
4252 =over 4
4253
4254 =item Value: (0 | 1)
4255
4256 =back
4257
4258 When combined with L</rows> and/or L</offset> the generated SQL will not
4259 include any limit dialect stanzas. Instead the entire result will be selected
4260 as if no limits were specified, and DBIC will perform the limit locally, by
4261 artificially advancing and finishing the resulting L</cursor>.
4262
4263 This is the recommended way of performing resultset limiting when no sane RDBMS
4264 implementation is available (e.g.
4265 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4266 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4267
4268 =head2 group_by
4269
4270 =over 4
4271
4272 =item Value: \@columns
4273
4274 =back
4275
4276 A arrayref of columns to group by. Can include columns of joined tables.
4277
4278   group_by => [qw/ column1 column2 ... /]
4279
4280 =head2 having
4281
4282 =over 4
4283
4284 =item Value: $condition
4285
4286 =back
4287
4288 HAVING is a select statement attribute that is applied between GROUP BY and
4289 ORDER BY. It is applied to the after the grouping calculations have been
4290 done.
4291
4292   having => { 'count_employee' => { '>=', 100 } }
4293
4294 or with an in-place function in which case literal SQL is required:
4295
4296   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4297
4298 =head2 distinct
4299
4300 =over 4
4301
4302 =item Value: (0 | 1)
4303
4304 =back
4305
4306 Set to 1 to group by all columns. If the resultset already has a group_by
4307 attribute, this setting is ignored and an appropriate warning is issued.
4308
4309 =head2 where
4310
4311 =over 4
4312
4313 Adds to the WHERE clause.
4314
4315   # only return rows WHERE deleted IS NULL for all searches
4316   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4317
4318 Can be overridden by passing C<< { where => undef } >> as an attribute
4319 to a resultset.
4320
4321 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4322
4323 =back
4324
4325 =head2 cache
4326
4327 Set to 1 to cache search results. This prevents extra SQL queries if you
4328 revisit rows in your ResultSet:
4329
4330   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4331
4332   while( my $artist = $resultset->next ) {
4333     ... do stuff ...
4334   }
4335
4336   $rs->first; # without cache, this would issue a query
4337
4338 By default, searches are not cached.
4339
4340 For more examples of using these attributes, see
4341 L<DBIx::Class::Manual::Cookbook>.
4342
4343 =head2 for
4344
4345 =over 4
4346
4347 =item Value: ( 'update' | 'shared' | \$scalar )
4348
4349 =back
4350
4351 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4352 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4353 query.
4354
4355 =head1 DBIC BIND VALUES
4356
4357 Because DBIC may need more information to bind values than just the column name
4358 and value itself, it uses a special format for both passing and receiving bind
4359 values.  Each bind value should be composed of an arrayref of
4360 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4361
4362 =over 4
4363
4364 =item dbd_attrs
4365
4366 If present (in any form), this is what is being passed directly to bind_param.
4367 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4368 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4369
4370 If this is specified, all other bind options described below are ignored.
4371
4372 =item sqlt_datatype
4373
4374 If present, this is used to infer the actual bind attribute by passing to
4375 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4376 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4377
4378 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4379 currently drivers are expected to "Do the Right Thing" when given a common
4380 datatype name.  (Not ideal, but that's what we got at this point.)
4381
4382 =item sqlt_size
4383
4384 Currently used to correctly allocate buffers for bind_param_inout().
4385 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4386 or to a sensible value based on the "data_type".
4387
4388 =item dbic_colname
4389
4390 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4391 explicitly specified they are never overriden).  Also used by some weird DBDs,
4392 where the column name should be available at bind_param time (e.g. Oracle).
4393
4394 =back
4395
4396 For backwards compatibility and convenience, the following shortcuts are
4397 supported:
4398
4399   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4400   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4401   [ undef,   $val ] === [ {}, $val ]
4402
4403 =head1 AUTHOR AND CONTRIBUTORS
4404
4405 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4406
4407 =head1 LICENSE
4408
4409 You may distribute this code under the same terms as Perl itself.
4410
4411 =cut
4412
4413 1;