lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use base qw/DBIx::Class/;
  15
  16 __PACKAGE__->mk_group_accessors('simple' => qw/result_class _source_handle/);
  17
  18 =head1 NAME
  19
  20 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  21
  22 =head1 SYNOPSIS
  23
  24   my $rs   = $schema->resultset('User')->search(registered => 1);
  25   my @rows = $schema->resultset('CD')->search(year => 2005);
  26
  27 =head1 DESCRIPTION
  28
  29 The resultset is also known as an iterator. It is responsible for handling
  30 queries that may return an arbitrary number of rows, e.g. via L</search>
  31 or a C<has_many> relationship.
  32
  33 In the examples below, the following table classes are used:
  34
  35   package MyApp::Schema::Artist;
  36   use base qw/DBIx::Class/;
  37   __PACKAGE__->load_components(qw/Core/);
  38   __PACKAGE__->table('artist');
  39   __PACKAGE__->add_columns(qw/artistid name/);
  40   __PACKAGE__->set_primary_key('artistid');
  41   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  42   1;
  43
  44   package MyApp::Schema::CD;
  45   use base qw/DBIx::Class/;
  46   __PACKAGE__->load_components(qw/Core/);
  47   __PACKAGE__->table('cd');
  48   __PACKAGE__->add_columns(qw/cdid artist title year/);
  49   __PACKAGE__->set_primary_key('cdid');
  50   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  51   1;
  52
  53 =head1 OVERLOADING
  54
  55 If a resultset is used as a number it returns the C<count()>.  However, if it is used as a boolean it is always true.  So if you want to check if a result set has any results use C<if $rs != 0>.  C<if $rs> will always be true.
  56
  57 =head1 METHODS
  58
  59 =head2 new
  60
  61 =over 4
  62
  63 =item Arguments: $source, \%$attrs
  64
  65 =item Return Value: $rs
  66
  67 =back
  68
  69 The resultset constructor. Takes a source object (usually a
  70 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  71 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  72 executed as needed by the other methods.
  73
  74 Generally you won't need to construct a resultset manually.  You'll
  75 automatically get one from e.g. a L</search> called in scalar context:
  76
  77   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  78
  79 IMPORTANT: If called on an object, proxies to new_result instead so
  80
  81   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  82
  83 will return a CD object, not a ResultSet.
  84
  85 =cut
  86
  87 sub new {
  88   my $class = shift;
  89   return $class->new_result(@_) if ref $class;
  90
  91   my ($source, $attrs) = @_;
  92   $source = $source->handle
  93     unless $source->isa('DBIx::Class::ResultSourceHandle');
  94   $attrs = { %{$attrs||{}} };
  95
  96   if ($attrs->{page}) {
  97     $attrs->{rows} ||= 10;
  98   }
  99
 100   $attrs->{alias} ||= 'me';
 101
 102   my $self = {
 103     _source_handle => $source,
 104     result_class => $attrs->{result_class} || $source->resolve->result_class,
 105     cond => $attrs->{where},
 106     count => undef,
 107     pager => undef,
 108     attrs => $attrs
 109   };
 110
 111   bless $self, $class;
 112
 113   return $self;
 114 }
 115
 116 =head2 search
 117
 118 =over 4
 119
 120 =item Arguments: $cond, \%attrs?
 121
 122 =item Return Value: $resultset (scalar context), @row_objs (list context)
 123
 124 =back
 125
 126   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 127   my $new_rs = $cd_rs->search({ year => 2005 });
 128
 129   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 130                  # year = 2005 OR year = 2004
 131
 132 If you need to pass in additional attributes but no additional condition,
 133 call it as C<search(undef, \%attrs)>.
 134
 135   # "SELECT name, artistid FROM $artist_table"
 136   my @all_artists = $schema->resultset('Artist')->search(undef, {
 137     columns => [qw/name artistid/],
 138   });
 139
 140 For a list of attributes that can be passed to C<search>, see
 141 L</ATTRIBUTES>. For more examples of using this function, see
 142 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 143 documentation for the first argument, see L<SQL::Abstract>.
 144
 145 =cut
 146
 147 sub search {
 148   my $self = shift;
 149   my $rs = $self->search_rs( @_ );
 150   return (wantarray ? $rs->all : $rs);
 151 }
 152
 153 =head2 search_rs
 154
 155 =over 4
 156
 157 =item Arguments: $cond, \%attrs?
 158
 159 =item Return Value: $resultset
 160
 161 =back
 162
 163 This method does the same exact thing as search() except it will
 164 always return a resultset, even in list context.
 165
 166 =cut
 167
 168 sub search_rs {
 169   my $self = shift;
 170
 171   my $rows;
 172
 173   unless (@_) {                 # no search, effectively just a clone
 174     $rows = $self->get_cache;
 175   }
 176
 177   my $attrs = {};
 178   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 179   my $our_attrs = { %{$self->{attrs}} };
 180   my $having = delete $our_attrs->{having};
 181   my $where = delete $our_attrs->{where};
 182
 183   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 184
 185   # merge new attrs into inherited
 186   foreach my $key (qw/join prefetch/) {
 187     next unless exists $attrs->{$key};
 188     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 189   }
 190
 191   my $cond = (@_
 192     ? (
 193         (@_ == 1 || ref $_[0] eq "HASH")
 194           ? (
 195               (ref $_[0] eq 'HASH')
 196                 ? (
 197                     (keys %{ $_[0] }  > 0)
 198                       ? shift
 199                       : undef
 200                    )
 201                 :  shift
 202              )
 203           : (
 204               (@_ % 2)
 205                 ? $self->throw_exception("Odd number of arguments to search")
 206                 : {@_}
 207              )
 208       )
 209     : undef
 210   );
 211
 212   if (defined $where) {
 213     $new_attrs->{where} = (
 214       defined $new_attrs->{where}
 215         ? { '-and' => [
 216               map {
 217                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 218               } $where, $new_attrs->{where}
 219             ]
 220           }
 221         : $where);
 222   }
 223
 224   if (defined $cond) {
 225     $new_attrs->{where} = (
 226       defined $new_attrs->{where}
 227         ? { '-and' => [
 228               map {
 229                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 230               } $cond, $new_attrs->{where}
 231             ]
 232           }
 233         : $cond);
 234   }
 235
 236   if (defined $having) {
 237     $new_attrs->{having} = (
 238       defined $new_attrs->{having}
 239         ? { '-and' => [
 240               map {
 241                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 242               } $having, $new_attrs->{having}
 243             ]
 244           }
 245         : $having);
 246   }
 247
 248   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 249   if ($rows) {
 250     $rs->set_cache($rows);
 251   }
 252   return $rs;
 253 }
 254
 255 =head2 search_literal
 256
 257 =over 4
 258
 259 =item Arguments: $sql_fragment, @bind_values
 260
 261 =item Return Value: $resultset (scalar context), @row_objs (list context)
 262
 263 =back
 264
 265   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 266   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 267
 268 Pass a literal chunk of SQL to be added to the conditional part of the
 269 resultset query.
 270
 271 =cut
 272
 273 sub search_literal {
 274   my ($self, $cond, @vals) = @_;
 275   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 276   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 277   return $self->search(\$cond, $attrs);
 278 }
 279
 280 =head2 find
 281
 282 =over 4
 283
 284 =item Arguments: @values | \%cols, \%attrs?
 285
 286 =item Return Value: $row_object
 287
 288 =back
 289
 290 Finds a row based on its primary key or unique constraint. For example, to find
 291 a row by its primary key:
 292
 293   my $cd = $schema->resultset('CD')->find(5);
 294
 295 You can also find a row by a specific unique constraint using the C<key>
 296 attribute. For example:
 297
 298   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 299     key => 'cd_artist_title'
 300   });
 301
 302 Additionally, you can specify the columns explicitly by name:
 303
 304   my $cd = $schema->resultset('CD')->find(
 305     {
 306       artist => 'Massive Attack',
 307       title  => 'Mezzanine',
 308     },
 309     { key => 'cd_artist_title' }
 310   );
 311
 312 If the C<key> is specified as C<primary>, it searches only on the primary key.
 313
 314 If no C<key> is specified, it searches on all unique constraints defined on the
 315 source, including the primary key.
 316
 317 If your table does not have a primary key, you B<must> provide a value for the
 318 C<key> attribute matching one of the unique constraints on the source.
 319
 320 See also L</find_or_create> and L</update_or_create>. For information on how to
 321 declare unique constraints, see
 322 L<DBIx::Class::ResultSource/add_unique_constraint>.
 323
 324 =cut
 325
 326 sub find {
 327   my $self = shift;
 328   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 329
 330   # Default to the primary key, but allow a specific key
 331   my @cols = exists $attrs->{key}
 332     ? $self->result_source->unique_constraint_columns($attrs->{key})
 333     : $self->result_source->primary_columns;
 334   $self->throw_exception(
 335     "Can't find unless a primary key is defined or unique constraint is specified"
 336   ) unless @cols;
 337
 338   # Parse out a hashref from input
 339   my $input_query;
 340   if (ref $_[0] eq 'HASH') {
 341     $input_query = { %{$_[0]} };
 342   }
 343   elsif (@_ == @cols) {
 344     $input_query = {};
 345     @{$input_query}{@cols} = @_;
 346   }
 347   else {
 348     # Compatibility: Allow e.g. find(id => $value)
 349     carp "Find by key => value deprecated; please use a hashref instead";
 350     $input_query = {@_};
 351   }
 352
 353   my (%related, $info);
 354
 355   KEY: foreach my $key (keys %$input_query) {
 356     if (ref($input_query->{$key})
 357         && ($info = $self->result_source->relationship_info($key))) {
 358       my $val = delete $input_query->{$key};
 359       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 360       my $rel_q = $self->result_source->resolve_condition(
 361                     $info->{cond}, $val, $key
 362                   );
 363       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 364       @related{keys %$rel_q} = values %$rel_q;
 365     }
 366   }
 367   if (my @keys = keys %related) {
 368     @{$input_query}{@keys} = values %related;
 369   }
 370
 371   my @unique_queries = $self->_unique_queries($input_query, $attrs);
 372
 373   # Build the final query: Default to the disjunction of the unique queries,
 374   # but allow the input query in case the ResultSet defines the query or the
 375   # user is abusing find
 376   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 377   my $query = @unique_queries
 378     ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 379     : $self->_add_alias($input_query, $alias);
 380
 381   # Run the query
 382   if (keys %$attrs) {
 383     my $rs = $self->search($query, $attrs);
 384     return keys %{$rs->_resolved_attrs->{collapse}} ? $rs->next : $rs->single;
 385   }
 386   else {
 387     return keys %{$self->_resolved_attrs->{collapse}}
 388       ? $self->search($query)->next
 389       : $self->single($query);
 390   }
 391 }
 392
 393 # _add_alias
 394 #
 395 # Add the specified alias to the specified query hash. A copy is made so the
 396 # original query is not modified.
 397
 398 sub _add_alias {
 399   my ($self, $query, $alias) = @_;
 400
 401   my %aliased = %$query;
 402   foreach my $col (grep { ! m/\./ } keys %aliased) {
 403     $aliased{"$alias.$col"} = delete $aliased{$col};
 404   }
 405
 406   return \%aliased;
 407 }
 408
 409 # _unique_queries
 410 #
 411 # Build a list of queries which satisfy unique constraints.
 412
 413 sub _unique_queries {
 414   my ($self, $query, $attrs) = @_;
 415
 416   my @constraint_names = exists $attrs->{key}
 417     ? ($attrs->{key})
 418     : $self->result_source->unique_constraint_names;
 419
 420   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 421   my $num_where = scalar keys %$where;
 422
 423   my @unique_queries;
 424   foreach my $name (@constraint_names) {
 425     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 426     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 427
 428     my $num_cols = scalar @unique_cols;
 429     my $num_query = scalar keys %$unique_query;
 430
 431     my $total = $num_query + $num_where;
 432     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 433       # The query is either unique on its own or is unique in combination with
 434       # the existing where clause
 435       push @unique_queries, $unique_query;
 436     }
 437   }
 438
 439   return @unique_queries;
 440 }
 441
 442 # _build_unique_query
 443 #
 444 # Constrain the specified query hash based on the specified column names.
 445
 446 sub _build_unique_query {
 447   my ($self, $query, $unique_cols) = @_;
 448
 449   return {
 450     map  { $_ => $query->{$_} }
 451     grep { exists $query->{$_} }
 452       @$unique_cols
 453   };
 454 }
 455
 456 =head2 search_related
 457
 458 =over 4
 459
 460 =item Arguments: $rel, $cond, \%attrs?
 461
 462 =item Return Value: $new_resultset
 463
 464 =back
 465
 466   $new_rs = $cd_rs->search_related('artist', {
 467     name => 'Emo-R-Us',
 468   });
 469
 470 Searches the specified relationship, optionally specifying a condition and
 471 attributes for matching records. See L</ATTRIBUTES> for more information.
 472
 473 =cut
 474
 475 sub search_related {
 476   return shift->related_resultset(shift)->search(@_);
 477 }
 478
 479 =head2 cursor
 480
 481 =over 4
 482
 483 =item Arguments: none
 484
 485 =item Return Value: $cursor
 486
 487 =back
 488
 489 Returns a storage-driven cursor to the given resultset. See
 490 L<DBIx::Class::Cursor> for more information.
 491
 492 =cut
 493
 494 sub cursor {
 495   my ($self) = @_;
 496
 497   my $attrs = { %{$self->_resolved_attrs} };
 498   return $self->{cursor}
 499     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 500           $attrs->{where},$attrs);
 501 }
 502
 503 =head2 single
 504
 505 =over 4
 506
 507 =item Arguments: $cond?
 508
 509 =item Return Value: $row_object?
 510
 511 =back
 512
 513   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 514
 515 Inflates the first result without creating a cursor if the resultset has
 516 any records in it; if not returns nothing. Used by L</find> as an optimisation.
 517
 518 Can optionally take an additional condition *only* - this is a fast-code-path
 519 method; if you need to add extra joins or similar call ->search and then
 520 ->single without a condition on the $rs returned from that.
 521
 522 =cut
 523
 524 sub single {
 525   my ($self, $where) = @_;
 526   my $attrs = { %{$self->_resolved_attrs} };
 527   if ($where) {
 528     if (defined $attrs->{where}) {
 529       $attrs->{where} = {
 530         '-and' =>
 531             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 532                $where, delete $attrs->{where} ]
 533       };
 534     } else {
 535       $attrs->{where} = $where;
 536     }
 537   }
 538
 539 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 540 #  unless ($self->_is_unique_query($attrs->{where})) {
 541 #    carp "Query not guaranteed to return a single row"
 542 #      . "; please declare your unique constraints or use search instead";
 543 #  }
 544
 545   my @data = $self->result_source->storage->select_single(
 546     $attrs->{from}, $attrs->{select},
 547     $attrs->{where}, $attrs
 548   );
 549
 550   return (@data ? ($self->_construct_object(@data))[0] : undef);
 551 }
 552
 553 # _is_unique_query
 554 #
 555 # Try to determine if the specified query is guaranteed to be unique, based on
 556 # the declared unique constraints.
 557
 558 sub _is_unique_query {
 559   my ($self, $query) = @_;
 560
 561   my $collapsed = $self->_collapse_query($query);
 562   my $alias = $self->{attrs}{alias};
 563
 564   foreach my $name ($self->result_source->unique_constraint_names) {
 565     my @unique_cols = map {
 566       "$alias.$_"
 567     } $self->result_source->unique_constraint_columns($name);
 568
 569     # Count the values for each unique column
 570     my %seen = map { $_ => 0 } @unique_cols;
 571
 572     foreach my $key (keys %$collapsed) {
 573       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 574       next unless exists $seen{$aliased};  # Additional constraints are okay
 575       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 576     }
 577
 578     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 579     return 1 unless grep { $_ != 1 } values %seen;
 580   }
 581
 582   return 0;
 583 }
 584
 585 # _collapse_query
 586 #
 587 # Recursively collapse the query, accumulating values for each column.
 588
 589 sub _collapse_query {
 590   my ($self, $query, $collapsed) = @_;
 591
 592   $collapsed ||= {};
 593
 594   if (ref $query eq 'ARRAY') {
 595     foreach my $subquery (@$query) {
 596       next unless ref $subquery;  # -or
 597 #      warn "ARRAY: " . Dumper $subquery;
 598       $collapsed = $self->_collapse_query($subquery, $collapsed);
 599     }
 600   }
 601   elsif (ref $query eq 'HASH') {
 602     if (keys %$query and (keys %$query)[0] eq '-and') {
 603       foreach my $subquery (@{$query->{-and}}) {
 604 #        warn "HASH: " . Dumper $subquery;
 605         $collapsed = $self->_collapse_query($subquery, $collapsed);
 606       }
 607     }
 608     else {
 609 #      warn "LEAF: " . Dumper $query;
 610       foreach my $col (keys %$query) {
 611         my $value = $query->{$col};
 612         $collapsed->{$col}{$value}++;
 613       }
 614     }
 615   }
 616
 617   return $collapsed;
 618 }
 619
 620 =head2 get_column
 621
 622 =over 4
 623
 624 =item Arguments: $cond?
 625
 626 =item Return Value: $resultsetcolumn
 627
 628 =back
 629
 630   my $max_length = $rs->get_column('length')->max;
 631
 632 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 633
 634 =cut
 635
 636 sub get_column {
 637   my ($self, $column) = @_;
 638   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 639   return $new;
 640 }
 641
 642 =head2 search_like
 643
 644 =over 4
 645
 646 =item Arguments: $cond, \%attrs?
 647
 648 =item Return Value: $resultset (scalar context), @row_objs (list context)
 649
 650 =back
 651
 652   # WHERE title LIKE '%blue%'
 653   $cd_rs = $rs->search_like({ title => '%blue%'});
 654
 655 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 656 that this is simply a convenience method. You most likely want to use
 657 L</search> with specific operators.
 658
 659 For more information, see L<DBIx::Class::Manual::Cookbook>.
 660
 661 =cut
 662
 663 sub search_like {
 664   my $class = shift;
 665   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 666   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 667   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 668   return $class->search($query, { %$attrs });
 669 }
 670
 671 =head2 slice
 672
 673 =over 4
 674
 675 =item Arguments: $first, $last
 676
 677 =item Return Value: $resultset (scalar context), @row_objs (list context)
 678
 679 =back
 680
 681 Returns a resultset or object list representing a subset of elements from the
 682 resultset slice is called on. Indexes are from 0, i.e., to get the first
 683 three records, call:
 684
 685   my ($one, $two, $three) = $rs->slice(0, 2);
 686
 687 =cut
 688
 689 sub slice {
 690   my ($self, $min, $max) = @_;
 691   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 692   $attrs->{offset} = $self->{attrs}{offset} || 0;
 693   $attrs->{offset} += $min;
 694   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 695   return $self->search(undef(), $attrs);
 696   #my $slice = (ref $self)->new($self->result_source, $attrs);
 697   #return (wantarray ? $slice->all : $slice);
 698 }
 699
 700 =head2 next
 701
 702 =over 4
 703
 704 =item Arguments: none
 705
 706 =item Return Value: $result?
 707
 708 =back
 709
 710 Returns the next element in the resultset (C<undef> is there is none).
 711
 712 Can be used to efficiently iterate over records in the resultset:
 713
 714   my $rs = $schema->resultset('CD')->search;
 715   while (my $cd = $rs->next) {
 716     print $cd->title;
 717   }
 718
 719 Note that you need to store the resultset object, and call C<next> on it.
 720 Calling C<< resultset('Table')->next >> repeatedly will always return the
 721 first record from the resultset.
 722
 723 =cut
 724
 725 sub next {
 726   my ($self) = @_;
 727   if (my $cache = $self->get_cache) {
 728     $self->{all_cache_position} ||= 0;
 729     return $cache->[$self->{all_cache_position}++];
 730   }
 731   if ($self->{attrs}{cache}) {
 732     $self->{all_cache_position} = 1;
 733     return ($self->all)[0];
 734   }
 735   if ($self->{stashed_objects}) {
 736     my $obj = shift(@{$self->{stashed_objects}});
 737     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 738     return $obj;
 739   }
 740   my @row = (
 741     exists $self->{stashed_row}
 742       ? @{delete $self->{stashed_row}}
 743       : $self->cursor->next
 744   );
 745   return undef unless (@row);
 746   my ($row, @more) = $self->_construct_object(@row);
 747   $self->{stashed_objects} = \@more if @more;
 748   return $row;
 749 }
 750
 751 sub _construct_object {
 752   my ($self, @row) = @_;
 753   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 754   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 755   @new = $self->{_attrs}{record_filter}->(@new)
 756     if exists $self->{_attrs}{record_filter};
 757   return @new;
 758 }
 759
 760 sub _collapse_result {
 761   my ($self, $as_proto, $row) = @_;
 762
 763   my @copy = @$row;
 764
 765   # 'foo'         => [ undef, 'foo' ]
 766   # 'foo.bar'     => [ 'foo', 'bar' ]
 767   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 768
 769   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 770
 771   my %collapse = %{$self->{_attrs}{collapse}||{}};
 772
 773   my @pri_index;
 774
 775   # if we're doing collapsing (has_many prefetch) we need to grab records
 776   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 777   # we know we don't have to bother.
 778
 779   # the reason for not using the collapse stuff directly is because if you
 780   # had for e.g. two artists in a row with no cds, the collapse info for
 781   # both would be NULL (undef) so you'd lose the second artist
 782
 783   # store just the index so we can check the array positions from the row
 784   # without having to contruct the full hash
 785
 786   if (keys %collapse) {
 787     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 788     foreach my $i (0 .. $#construct_as) {
 789       next if defined($construct_as[$i][0]); # only self table
 790       if (delete $pri{$construct_as[$i][1]}) {
 791         push(@pri_index, $i);
 792       }
 793       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 794     }
 795   }
 796
 797   # no need to do an if, it'll be empty if @pri_index is empty anyway
 798
 799   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 800
 801   my @const_rows;
 802
 803   do { # no need to check anything at the front, we always want the first row
 804
 805     my %const;
 806
 807     foreach my $this_as (@construct_as) {
 808       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 809     }
 810
 811     push(@const_rows, \%const);
 812
 813   } until ( # no pri_index => no collapse => drop straight out
 814       !@pri_index
 815     or
 816       do { # get another row, stash it, drop out if different PK
 817
 818         @copy = $self->cursor->next;
 819         $self->{stashed_row} = \@copy;
 820
 821         # last thing in do block, counts as true if anything doesn't match
 822
 823         # check xor defined first for NULL vs. NOT NULL then if one is
 824         # defined the other must be so check string equality
 825
 826         grep {
 827           (defined $pri_vals{$_} ^ defined $copy[$_])
 828           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 829         } @pri_index;
 830       }
 831   );
 832
 833   my $alias = $self->{attrs}{alias};
 834   my $info = [];
 835
 836   my %collapse_pos;
 837
 838   my @const_keys;
 839
 840   foreach my $const (@const_rows) {
 841     scalar @const_keys or do {
 842       @const_keys = sort { length($a) <=> length($b) } keys %$const;
 843     };
 844     foreach my $key (@const_keys) {
 845       if (length $key) {
 846         my $target = $info;
 847         my @parts = split(/\./, $key);
 848         my $cur = '';
 849         my $data = $const->{$key};
 850         foreach my $p (@parts) {
 851           $target = $target->[1]->{$p} ||= [];
 852           $cur .= ".${p}";
 853           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
 854             # collapsing at this point and on final part
 855             my $pos = $collapse_pos{$cur};
 856             CK: foreach my $ck (@ckey) {
 857               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
 858                 $collapse_pos{$cur} = $data;
 859                 delete @collapse_pos{ # clear all positioning for sub-entries
 860                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
 861                 };
 862                 push(@$target, []);
 863                 last CK;
 864               }
 865             }
 866           }
 867           if (exists $collapse{$cur}) {
 868             $target = $target->[-1];
 869           }
 870         }
 871         $target->[0] = $data;
 872       } else {
 873         $info->[0] = $const->{$key};
 874       }
 875     }
 876   }
 877
 878   return $info;
 879 }
 880
 881 =head2 result_source
 882
 883 =over 4
 884
 885 =item Arguments: $result_source?
 886
 887 =item Return Value: $result_source
 888
 889 =back
 890
 891 An accessor for the primary ResultSource object from which this ResultSet
 892 is derived.
 893
 894 =head2 result_class
 895
 896 =over 4
 897
 898 =item Arguments: $result_class?
 899
 900 =item Return Value: $result_class
 901
 902 =back
 903
 904 An accessor for the class to use when creating row objects. Defaults to
 905 C<< result_source->result_class >> - which in most cases is the name of the
 906 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
 907
 908 =cut
 909
 910
 911 =head2 count
 912
 913 =over 4
 914
 915 =item Arguments: $cond, \%attrs??
 916
 917 =item Return Value: $count
 918
 919 =back
 920
 921 Performs an SQL C<COUNT> with the same query as the resultset was built
 922 with to find the number of elements. If passed arguments, does a search
 923 on the resultset and counts the results of that.
 924
 925 Note: When using C<count> with C<group_by>, L<DBIX::Class> emulates C<GROUP BY>
 926 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
 927 not support C<DISTINCT> with multiple columns. If you are using such a
 928 database, you should only use columns from the main table in your C<group_by>
 929 clause.
 930
 931 =cut
 932
 933 sub count {
 934   my $self = shift;
 935   return $self->search(@_)->count if @_ and defined $_[0];
 936   return scalar @{ $self->get_cache } if $self->get_cache;
 937   my $count = $self->_count;
 938   return 0 unless $count;
 939
 940   # need to take offset from resolved attrs
 941
 942   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
 943   $count = $self->{attrs}{rows} if
 944     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
 945   $count = 0 if ($count < 0);
 946   return $count;
 947 }
 948
 949 sub _count { # Separated out so pager can get the full count
 950   my $self = shift;
 951   my $select = { count => '*' };
 952
 953   my $attrs = { %{$self->_resolved_attrs} };
 954   if (my $group_by = delete $attrs->{group_by}) {
 955     delete $attrs->{having};
 956     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
 957     # todo: try CONCAT for multi-column pk
 958     my @pk = $self->result_source->primary_columns;
 959     if (@pk == 1) {
 960       my $alias = $attrs->{alias};
 961       foreach my $column (@distinct) {
 962         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
 963           @distinct = ($column);
 964           last;
 965         }
 966       }
 967     }
 968
 969     $select = { count => { distinct => \@distinct } };
 970   }
 971
 972   $attrs->{select} = $select;
 973   $attrs->{as} = [qw/count/];
 974
 975   # offset, order by and page are not needed to count. record_filter is cdbi
 976   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
 977
 978   my $tmp_rs = (ref $self)->new($self->_source_handle, $attrs);
 979   my ($count) = $tmp_rs->cursor->next;
 980   return $count;
 981 }
 982
 983 sub _bool {
 984   return 1;
 985 }
 986
 987 =head2 count_literal
 988
 989 =over 4
 990
 991 =item Arguments: $sql_fragment, @bind_values
 992
 993 =item Return Value: $count
 994
 995 =back
 996
 997 Counts the results in a literal query. Equivalent to calling L</search_literal>
 998 with the passed arguments, then L</count>.
 999
1000 =cut
1001
1002 sub count_literal { shift->search_literal(@_)->count; }
1003
1004 =head2 all
1005
1006 =over 4
1007
1008 =item Arguments: none
1009
1010 =item Return Value: @objects
1011
1012 =back
1013
1014 Returns all elements in the resultset. Called implicitly if the resultset
1015 is returned in list context.
1016
1017 =cut
1018
1019 sub all {
1020   my ($self) = @_;
1021   return @{ $self->get_cache } if $self->get_cache;
1022
1023   my @obj;
1024
1025   # TODO: don't call resolve here
1026   if (keys %{$self->_resolved_attrs->{collapse}}) {
1027 #  if ($self->{attrs}{prefetch}) {
1028       # Using $self->cursor->all is really just an optimisation.
1029       # If we're collapsing has_many prefetches it probably makes
1030       # very little difference, and this is cleaner than hacking
1031       # _construct_object to survive the approach
1032     my @row = $self->cursor->next;
1033     while (@row) {
1034       push(@obj, $self->_construct_object(@row));
1035       @row = (exists $self->{stashed_row}
1036                ? @{delete $self->{stashed_row}}
1037                : $self->cursor->next);
1038     }
1039   } else {
1040     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1041   }
1042
1043   $self->set_cache(\@obj) if $self->{attrs}{cache};
1044   return @obj;
1045 }
1046
1047 =head2 reset
1048
1049 =over 4
1050
1051 =item Arguments: none
1052
1053 =item Return Value: $self
1054
1055 =back
1056
1057 Resets the resultset's cursor, so you can iterate through the elements again.
1058
1059 =cut
1060
1061 sub reset {
1062   my ($self) = @_;
1063   delete $self->{_attrs} if exists $self->{_attrs};
1064   $self->{all_cache_position} = 0;
1065   $self->cursor->reset;
1066   return $self;
1067 }
1068
1069 =head2 first
1070
1071 =over 4
1072
1073 =item Arguments: none
1074
1075 =item Return Value: $object?
1076
1077 =back
1078
1079 Resets the resultset and returns an object for the first result (if the
1080 resultset returns anything).
1081
1082 =cut
1083
1084 sub first {
1085   return $_[0]->reset->next;
1086 }
1087
1088 # _cond_for_update_delete
1089 #
1090 # update/delete require the condition to be modified to handle
1091 # the differing SQL syntax available.  This transforms the $self->{cond}
1092 # appropriately, returning the new condition.
1093
1094 sub _cond_for_update_delete {
1095   my ($self, $full_cond) = @_;
1096   my $cond = {};
1097
1098   $full_cond ||= $self->{cond};
1099   # No-op. No condition, we're updating/deleting everything
1100   return $cond unless ref $full_cond;
1101
1102   if (ref $full_cond eq 'ARRAY') {
1103     $cond = [
1104       map {
1105         my %hash;
1106         foreach my $key (keys %{$_}) {
1107           $key =~ /([^.]+)$/;
1108           $hash{$1} = $_->{$key};
1109         }
1110         \%hash;
1111       } @{$full_cond}
1112     ];
1113   }
1114   elsif (ref $full_cond eq 'HASH') {
1115     if ((keys %{$full_cond})[0] eq '-and') {
1116       $cond->{-and} = [];
1117
1118       my @cond = @{$full_cond->{-and}};
1119       for (my $i = 0; $i < @cond; $i++) {
1120         my $entry = $cond[$i];
1121
1122         my $hash;
1123         if (ref $entry eq 'HASH') {
1124           $hash = $self->_cond_for_update_delete($entry);
1125         }
1126         else {
1127           $entry =~ /([^.]+)$/;
1128           $hash->{$1} = $cond[++$i];
1129         }
1130
1131         push @{$cond->{-and}}, $hash;
1132       }
1133     }
1134     else {
1135       foreach my $key (keys %{$full_cond}) {
1136         $key =~ /([^.]+)$/;
1137         $cond->{$1} = $full_cond->{$key};
1138       }
1139     }
1140   }
1141   else {
1142     $self->throw_exception(
1143       "Can't update/delete on resultset with condition unless hash or array"
1144     );
1145   }
1146
1147   return $cond;
1148 }
1149
1150
1151 =head2 update
1152
1153 =over 4
1154
1155 =item Arguments: \%values
1156
1157 =item Return Value: $storage_rv
1158
1159 =back
1160
1161 Sets the specified columns in the resultset to the supplied values in a
1162 single query. Return value will be true if the update succeeded or false
1163 if no records were updated; exact type of success value is storage-dependent.
1164
1165 =cut
1166
1167 sub update {
1168   my ($self, $values) = @_;
1169   $self->throw_exception("Values for update must be a hash")
1170     unless ref $values eq 'HASH';
1171
1172   my $cond = $self->_cond_for_update_delete;
1173
1174   return $self->result_source->storage->update(
1175     $self->result_source, $values, $cond
1176   );
1177 }
1178
1179 =head2 update_all
1180
1181 =over 4
1182
1183 =item Arguments: \%values
1184
1185 =item Return Value: 1
1186
1187 =back
1188
1189 Fetches all objects and updates them one at a time. Note that C<update_all>
1190 will run DBIC cascade triggers, while L</update> will not.
1191
1192 =cut
1193
1194 sub update_all {
1195   my ($self, $values) = @_;
1196   $self->throw_exception("Values for update must be a hash")
1197     unless ref $values eq 'HASH';
1198   foreach my $obj ($self->all) {
1199     $obj->set_columns($values)->update;
1200   }
1201   return 1;
1202 }
1203
1204 =head2 delete
1205
1206 =over 4
1207
1208 =item Arguments: none
1209
1210 =item Return Value: 1
1211
1212 =back
1213
1214 Deletes the contents of the resultset from its result source. Note that this
1215 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1216 to run. See also L<DBIx::Class::Row/delete>.
1217
1218 =cut
1219
1220 sub delete {
1221   my ($self) = @_;
1222
1223   my $cond = $self->_cond_for_update_delete;
1224
1225   $self->result_source->storage->delete($self->result_source, $cond);
1226   return 1;
1227 }
1228
1229 =head2 delete_all
1230
1231 =over 4
1232
1233 =item Arguments: none
1234
1235 =item Return Value: 1
1236
1237 =back
1238
1239 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1240 will run DBIC cascade triggers, while L</delete> will not.
1241
1242 =cut
1243
1244 sub delete_all {
1245   my ($self) = @_;
1246   $_->delete for $self->all;
1247   return 1;
1248 }
1249
1250 =head2 populate
1251
1252 =over 4
1253
1254 =item Arguments: \@data;
1255
1256 =back
1257
1258 Pass an arrayref of hashrefs. Each hashref should be a structure suitable for
1259 submitting to a $resultset->create(...) method.
1260
1261 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1262 to insert the data, as this is a faster method.
1263
1264 Otherwise, each set of data is inserted into the database using
1265 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1266 objects is returned.
1267
1268 Example:  Assuming an Artist Class that has many CDs Classes relating:
1269
1270   my $Artist_rs = $schema->resultset("Artist");
1271
1272   ## Void Context Example
1273   $Artist_rs->populate([
1274      { artistid => 4, name => 'Manufactured Crap', cds => [
1275         { title => 'My First CD', year => 2006 },
1276         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1277       ],
1278      },
1279      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1280         { title => 'My parents sold me to a record company' ,year => 2005 },
1281         { title => 'Why Am I So Ugly?', year => 2006 },
1282         { title => 'I Got Surgery and am now Popular', year => 2007 }
1283       ],
1284      },
1285   ]);
1286
1287   ## Array Context Example
1288   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1289     { name => "Artist One"},
1290     { name => "Artist Two"},
1291     { name => "Artist Three", cds=> [
1292     { title => "First CD", year => 2007},
1293     { title => "Second CD", year => 2008},
1294   ]}
1295   ]);
1296
1297   print $ArtistOne->name; ## response is 'Artist One'
1298   print $ArtistThree->cds->count ## reponse is '2'
1299
1300 =cut
1301
1302 sub populate {
1303   my ($self, $data) = @_;
1304
1305   if(defined wantarray) {
1306     my @created;
1307     foreach my $item (@$data) {
1308       push(@created, $self->create($item));
1309     }
1310     return @created;
1311   } else {
1312     my ($first, @rest) = @$data;
1313
1314     my @names = grep {!ref $first->{$_}} keys %$first;
1315     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1316     my @pks = $self->result_source->primary_columns;
1317
1318     ## do the belongs_to relationships
1319     foreach my $index (0..$#$data) {
1320       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1321         my @ret = $self->populate($data);
1322         return;
1323       }
1324
1325       foreach my $rel (@rels) {
1326         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1327         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1328         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1329         my $related = $result->result_source->resolve_condition(
1330           $result->result_source->relationship_info($reverse)->{cond},
1331           $self,
1332           $result,
1333         );
1334
1335         delete $data->[$index]->{$rel};
1336         $data->[$index] = {%{$data->[$index]}, %$related};
1337
1338         push @names, keys %$related if $index == 0;
1339       }
1340     }
1341
1342     ## do bulk insert on current row
1343     my @values = map { [ @$_{@names} ] } @$data;
1344
1345     $self->result_source->storage->insert_bulk(
1346       $self->result_source,
1347       \@names,
1348       \@values,
1349     );
1350
1351     ## do the has_many relationships
1352     foreach my $item (@$data) {
1353
1354       foreach my $rel (@rels) {
1355         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1356
1357         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1358      || $self->throw_exception('Cannot find the relating object.');
1359
1360         my $child = $parent->$rel;
1361
1362         my $related = $child->result_source->resolve_condition(
1363           $parent->result_source->relationship_info($rel)->{cond},
1364           $child,
1365           $parent,
1366         );
1367
1368         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1369         my @populate = map { {%$_, %$related} } @rows_to_add;
1370
1371         $child->populate( \@populate );
1372       }
1373     }
1374   }
1375 }
1376
1377 =head2 pager
1378
1379 =over 4
1380
1381 =item Arguments: none
1382
1383 =item Return Value: $pager
1384
1385 =back
1386
1387 Return Value a L<Data::Page> object for the current resultset. Only makes
1388 sense for queries with a C<page> attribute.
1389
1390 =cut
1391
1392 sub pager {
1393   my ($self) = @_;
1394   my $attrs = $self->{attrs};
1395   $self->throw_exception("Can't create pager for non-paged rs")
1396     unless $self->{attrs}{page};
1397   $attrs->{rows} ||= 10;
1398   return $self->{pager} ||= Data::Page->new(
1399     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1400 }
1401
1402 =head2 page
1403
1404 =over 4
1405
1406 =item Arguments: $page_number
1407
1408 =item Return Value: $rs
1409
1410 =back
1411
1412 Returns a resultset for the $page_number page of the resultset on which page
1413 is called, where each page contains a number of rows equal to the 'rows'
1414 attribute set on the resultset (10 by default).
1415
1416 =cut
1417
1418 sub page {
1419   my ($self, $page) = @_;
1420   return (ref $self)->new($self->_source_handle, { %{$self->{attrs}}, page => $page });
1421 }
1422
1423 =head2 new_result
1424
1425 =over 4
1426
1427 =item Arguments: \%vals
1428
1429 =item Return Value: $object
1430
1431 =back
1432
1433 Creates an object in the resultset's result class and returns it.
1434
1435 =cut
1436
1437 sub new_result {
1438   my ($self, $values) = @_;
1439   $self->throw_exception( "new_result needs a hash" )
1440     unless (ref $values eq 'HASH');
1441   $self->throw_exception(
1442     "Can't abstract implicit construct, condition not a hash"
1443   ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1444
1445   my $alias = $self->{attrs}{alias};
1446   my $collapsed_cond = $self->{cond} ? $self->_collapse_cond($self->{cond}) : {};
1447   my %new = (
1448     %{ $self->_remove_alias($values, $alias) },
1449     %{ $self->_remove_alias($collapsed_cond, $alias) },
1450     -source_handle => $self->_source_handle,
1451     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1452   );
1453
1454   return $self->result_class->new(\%new);
1455 }
1456
1457 # _collapse_cond
1458 #
1459 # Recursively collapse the condition.
1460
1461 sub _collapse_cond {
1462   my ($self, $cond, $collapsed) = @_;
1463
1464   $collapsed ||= {};
1465
1466   if (ref $cond eq 'ARRAY') {
1467     foreach my $subcond (@$cond) {
1468       next unless ref $subcond;  # -or
1469 #      warn "ARRAY: " . Dumper $subcond;
1470       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1471     }
1472   }
1473   elsif (ref $cond eq 'HASH') {
1474     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1475       foreach my $subcond (@{$cond->{-and}}) {
1476 #        warn "HASH: " . Dumper $subcond;
1477         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1478       }
1479     }
1480     else {
1481 #      warn "LEAF: " . Dumper $cond;
1482       foreach my $col (keys %$cond) {
1483         my $value = $cond->{$col};
1484         $collapsed->{$col} = $value;
1485       }
1486     }
1487   }
1488
1489   return $collapsed;
1490 }
1491
1492 # _remove_alias
1493 #
1494 # Remove the specified alias from the specified query hash. A copy is made so
1495 # the original query is not modified.
1496
1497 sub _remove_alias {
1498   my ($self, $query, $alias) = @_;
1499
1500   my %orig = %{ $query || {} };
1501   my %unaliased;
1502
1503   foreach my $key (keys %orig) {
1504     if ($key !~ /\./) {
1505       $unaliased{$key} = $orig{$key};
1506       next;
1507     }
1508     $unaliased{$1} = $orig{$key}
1509       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1510   }
1511
1512   return \%unaliased;
1513 }
1514
1515 =head2 find_or_new
1516
1517 =over 4
1518
1519 =item Arguments: \%vals, \%attrs?
1520
1521 =item Return Value: $object
1522
1523 =back
1524
1525 Find an existing record from this resultset. If none exists, instantiate a new
1526 result object and return it. The object will not be saved into your storage
1527 until you call L<DBIx::Class::Row/insert> on it.
1528
1529 If you want objects to be saved immediately, use L</find_or_create> instead.
1530
1531 =cut
1532
1533 sub find_or_new {
1534   my $self     = shift;
1535   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1536   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1537   my $exists   = $self->find($hash, $attrs);
1538   return defined $exists ? $exists : $self->new_result($hash);
1539 }
1540
1541 =head2 create
1542
1543 =over 4
1544
1545 =item Arguments: \%vals
1546
1547 =item Return Value: $object
1548
1549 =back
1550
1551 Inserts a record into the resultset and returns the object representing it.
1552
1553 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1554
1555 =cut
1556
1557 sub create {
1558   my ($self, $attrs) = @_;
1559   $self->throw_exception( "create needs a hashref" )
1560     unless ref $attrs eq 'HASH';
1561   return $self->new_result($attrs)->insert;
1562 }
1563
1564 =head2 find_or_create
1565
1566 =over 4
1567
1568 =item Arguments: \%vals, \%attrs?
1569
1570 =item Return Value: $object
1571
1572 =back
1573
1574   $class->find_or_create({ key => $val, ... });
1575
1576 Tries to find a record based on its primary key or unique constraint; if none
1577 is found, creates one and returns that instead.
1578
1579   my $cd = $schema->resultset('CD')->find_or_create({
1580     cdid   => 5,
1581     artist => 'Massive Attack',
1582     title  => 'Mezzanine',
1583     year   => 2005,
1584   });
1585
1586 Also takes an optional C<key> attribute, to search by a specific key or unique
1587 constraint. For example:
1588
1589   my $cd = $schema->resultset('CD')->find_or_create(
1590     {
1591       artist => 'Massive Attack',
1592       title  => 'Mezzanine',
1593     },
1594     { key => 'cd_artist_title' }
1595   );
1596
1597 See also L</find> and L</update_or_create>. For information on how to declare
1598 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1599
1600 =cut
1601
1602 sub find_or_create {
1603   my $self     = shift;
1604   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1605   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1606   my $exists   = $self->find($hash, $attrs);
1607   return defined $exists ? $exists : $self->create($hash);
1608 }
1609
1610 =head2 update_or_create
1611
1612 =over 4
1613
1614 =item Arguments: \%col_values, { key => $unique_constraint }?
1615
1616 =item Return Value: $object
1617
1618 =back
1619
1620   $class->update_or_create({ col => $val, ... });
1621
1622 First, searches for an existing row matching one of the unique constraints
1623 (including the primary key) on the source of this resultset. If a row is
1624 found, updates it with the other given column values. Otherwise, creates a new
1625 row.
1626
1627 Takes an optional C<key> attribute to search on a specific unique constraint.
1628 For example:
1629
1630   # In your application
1631   my $cd = $schema->resultset('CD')->update_or_create(
1632     {
1633       artist => 'Massive Attack',
1634       title  => 'Mezzanine',
1635       year   => 1998,
1636     },
1637     { key => 'cd_artist_title' }
1638   );
1639
1640 If no C<key> is specified, it searches on all unique constraints defined on the
1641 source, including the primary key.
1642
1643 If the C<key> is specified as C<primary>, it searches only on the primary key.
1644
1645 See also L</find> and L</find_or_create>. For information on how to declare
1646 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1647
1648 =cut
1649
1650 sub update_or_create {
1651   my $self = shift;
1652   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1653   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
1654
1655   my $row = $self->find($cond, $attrs);
1656   if (defined $row) {
1657     $row->update($cond);
1658     return $row;
1659   }
1660
1661   return $self->create($cond);
1662 }
1663
1664 =head2 get_cache
1665
1666 =over 4
1667
1668 =item Arguments: none
1669
1670 =item Return Value: \@cache_objects?
1671
1672 =back
1673
1674 Gets the contents of the cache for the resultset, if the cache is set.
1675
1676 =cut
1677
1678 sub get_cache {
1679   shift->{all_cache};
1680 }
1681
1682 =head2 set_cache
1683
1684 =over 4
1685
1686 =item Arguments: \@cache_objects
1687
1688 =item Return Value: \@cache_objects
1689
1690 =back
1691
1692 Sets the contents of the cache for the resultset. Expects an arrayref
1693 of objects of the same class as those produced by the resultset. Note that
1694 if the cache is set the resultset will return the cached objects rather
1695 than re-querying the database even if the cache attr is not set.
1696
1697 =cut
1698
1699 sub set_cache {
1700   my ( $self, $data ) = @_;
1701   $self->throw_exception("set_cache requires an arrayref")
1702       if defined($data) && (ref $data ne 'ARRAY');
1703   $self->{all_cache} = $data;
1704 }
1705
1706 =head2 clear_cache
1707
1708 =over 4
1709
1710 =item Arguments: none
1711
1712 =item Return Value: []
1713
1714 =back
1715
1716 Clears the cache for the resultset.
1717
1718 =cut
1719
1720 sub clear_cache {
1721   shift->set_cache(undef);
1722 }
1723
1724 =head2 related_resultset
1725
1726 =over 4
1727
1728 =item Arguments: $relationship_name
1729
1730 =item Return Value: $resultset
1731
1732 =back
1733
1734 Returns a related resultset for the supplied relationship name.
1735
1736   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1737
1738 =cut
1739
1740 sub related_resultset {
1741   my ($self, $rel) = @_;
1742
1743   $self->{related_resultsets} ||= {};
1744   return $self->{related_resultsets}{$rel} ||= do {
1745     my $rel_obj = $self->result_source->relationship_info($rel);
1746
1747     $self->throw_exception(
1748       "search_related: result source '" . $self->_source_handle->source_moniker .
1749         "' has no such relationship $rel")
1750       unless $rel_obj;
1751
1752     my ($from,$seen) = $self->_resolve_from($rel);
1753
1754     my $join_count = $seen->{$rel};
1755     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
1756
1757     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
1758     my %attrs = %{$self->{attrs}||{}};
1759     delete $attrs{result_class};
1760
1761     my $new_cache;
1762
1763     if (my $cache = $self->get_cache) {
1764       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
1765         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
1766                         @$cache ];
1767       }
1768     }
1769
1770     my $new = $self->_source_handle
1771                    ->schema
1772                    ->resultset($rel_obj->{class})
1773                    ->search_rs(
1774                        undef, {
1775                          %attrs,
1776                          join => undef,
1777                          prefetch => undef,
1778                          select => undef,
1779                          as => undef,
1780                          alias => $alias,
1781                          where => $self->{cond},
1782                          seen_join => $seen,
1783                          from => $from,
1784                      });
1785     $new->set_cache($new_cache) if $new_cache;
1786     $new;
1787   };
1788 }
1789
1790 sub _resolve_from {
1791   my ($self, $extra_join) = @_;
1792   my $source = $self->result_source;
1793   my $attrs = $self->{attrs};
1794
1795   my $from = $attrs->{from}
1796     || [ { $attrs->{alias} => $source->from } ];
1797
1798   my $seen = { %{$attrs->{seen_join}||{}} };
1799
1800   my $join = ($attrs->{join}
1801                ? [ $attrs->{join}, $extra_join ]
1802                : $extra_join);
1803
1804   # we need to take the prefetch the attrs into account before we
1805   # ->resolve_join as otherwise they get lost - captainL
1806   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
1807
1808   $from = [
1809     @$from,
1810     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
1811   ];
1812
1813   return ($from,$seen);
1814 }
1815
1816 sub _resolved_attrs {
1817   my $self = shift;
1818   return $self->{_attrs} if $self->{_attrs};
1819
1820   my $attrs = { %{$self->{attrs}||{}} };
1821   my $source = $self->result_source;
1822   my $alias = $attrs->{alias};
1823
1824   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
1825   if ($attrs->{columns}) {
1826     delete $attrs->{as};
1827   } elsif (!$attrs->{select}) {
1828     $attrs->{columns} = [ $source->columns ];
1829   }
1830
1831   $attrs->{select} =
1832     ($attrs->{select}
1833       ? (ref $attrs->{select} eq 'ARRAY'
1834           ? [ @{$attrs->{select}} ]
1835           : [ $attrs->{select} ])
1836       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
1837     );
1838   $attrs->{as} =
1839     ($attrs->{as}
1840       ? (ref $attrs->{as} eq 'ARRAY'
1841           ? [ @{$attrs->{as}} ]
1842           : [ $attrs->{as} ])
1843       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
1844     );
1845
1846   my $adds;
1847   if ($adds = delete $attrs->{include_columns}) {
1848     $adds = [$adds] unless ref $adds eq 'ARRAY';
1849     push(@{$attrs->{select}}, @$adds);
1850     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
1851   }
1852   if ($adds = delete $attrs->{'+select'}) {
1853     $adds = [$adds] unless ref $adds eq 'ARRAY';
1854     push(@{$attrs->{select}},
1855            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
1856   }
1857   if (my $adds = delete $attrs->{'+as'}) {
1858     $adds = [$adds] unless ref $adds eq 'ARRAY';
1859     push(@{$attrs->{as}}, @$adds);
1860   }
1861
1862   $attrs->{from} ||= [ { 'me' => $source->from } ];
1863
1864   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
1865     my $join = delete $attrs->{join} || {};
1866
1867     if (defined $attrs->{prefetch}) {
1868       $join = $self->_merge_attr(
1869         $join, $attrs->{prefetch}
1870       );
1871
1872     }
1873
1874     $attrs->{from} =   # have to copy here to avoid corrupting the original
1875       [
1876         @{$attrs->{from}},
1877         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
1878       ];
1879
1880   }
1881
1882   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
1883   if ($attrs->{order_by}) {
1884     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
1885                            ? [ @{$attrs->{order_by}} ]
1886                            : [ $attrs->{order_by} ]);
1887   } else {
1888     $attrs->{order_by} = [];
1889   }
1890
1891   my $collapse = $attrs->{collapse} || {};
1892   if (my $prefetch = delete $attrs->{prefetch}) {
1893     $prefetch = $self->_merge_attr({}, $prefetch);
1894     my @pre_order;
1895     my $seen = $attrs->{seen_join} || {};
1896     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
1897       # bring joins back to level of current class
1898       my @prefetch = $source->resolve_prefetch(
1899         $p, $alias, $seen, \@pre_order, $collapse
1900       );
1901       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
1902       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
1903     }
1904     push(@{$attrs->{order_by}}, @pre_order);
1905   }
1906   $attrs->{collapse} = $collapse;
1907
1908   if ($attrs->{page}) {
1909     $attrs->{offset} ||= 0;
1910     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
1911   }
1912
1913   return $self->{_attrs} = $attrs;
1914 }
1915
1916 sub _rollout_attr {
1917   my ($self, $attr) = @_;
1918
1919   if (ref $attr eq 'HASH') {
1920     return $self->_rollout_hash($attr);
1921   } elsif (ref $attr eq 'ARRAY') {
1922     return $self->_rollout_array($attr);
1923   } else {
1924     return [$attr];
1925   }
1926 }
1927
1928 sub _rollout_array {
1929   my ($self, $attr) = @_;
1930
1931   my @rolled_array;
1932   foreach my $element (@{$attr}) {
1933     if (ref $element eq 'HASH') {
1934       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
1935     } elsif (ref $element eq 'ARRAY') {
1936       #  XXX - should probably recurse here
1937       push( @rolled_array, @{$self->_rollout_array($element)} );
1938     } else {
1939       push( @rolled_array, $element );
1940     }
1941   }
1942   return \@rolled_array;
1943 }
1944
1945 sub _rollout_hash {
1946   my ($self, $attr) = @_;
1947
1948   my @rolled_array;
1949   foreach my $key (keys %{$attr}) {
1950     push( @rolled_array, { $key => $attr->{$key} } );
1951   }
1952   return \@rolled_array;
1953 }
1954
1955 sub _calculate_score {
1956   my ($self, $a, $b) = @_;
1957
1958   if (ref $b eq 'HASH') {
1959     my ($b_key) = keys %{$b};
1960     if (ref $a eq 'HASH') {
1961       my ($a_key) = keys %{$a};
1962       if ($a_key eq $b_key) {
1963         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
1964       } else {
1965         return 0;
1966       }
1967     } else {
1968       return ($a eq $b_key) ? 1 : 0;
1969     }
1970   } else {
1971     if (ref $a eq 'HASH') {
1972       my ($a_key) = keys %{$a};
1973       return ($b eq $a_key) ? 1 : 0;
1974     } else {
1975       return ($b eq $a) ? 1 : 0;
1976     }
1977   }
1978 }
1979
1980 sub _merge_attr {
1981   my ($self, $a, $b) = @_;
1982
1983   return $b unless defined($a);
1984   return $a unless defined($b);
1985
1986   $a = $self->_rollout_attr($a);
1987   $b = $self->_rollout_attr($b);
1988
1989   my $seen_keys;
1990   foreach my $b_element ( @{$b} ) {
1991     # find best candidate from $a to merge $b_element into
1992     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
1993     foreach my $a_element ( @{$a} ) {
1994       my $score = $self->_calculate_score( $a_element, $b_element );
1995       if ($score > $best_candidate->{score}) {
1996         $best_candidate->{position} = $position;
1997         $best_candidate->{score} = $score;
1998       }
1999       $position++;
2000     }
2001     my ($b_key) = ( ref $b_element eq 'HASH' ) ? keys %{$b_element} : ($b_element);
2002     if ($best_candidate->{score} == 0 || exists $seen_keys->{$b_key}) {
2003       push( @{$a}, $b_element );
2004     } else {
2005       $seen_keys->{$b_key} = 1; # don't merge the same key twice
2006       my $a_best = $a->[$best_candidate->{position}];
2007       # merge a_best and b_element together and replace original with merged
2008       if (ref $a_best ne 'HASH') {
2009         $a->[$best_candidate->{position}] = $b_element;
2010       } elsif (ref $b_element eq 'HASH') {
2011         my ($key) = keys %{$a_best};
2012         $a->[$best_candidate->{position}] = { $key => $self->_merge_attr($a_best->{$key}, $b_element->{$key}) };
2013       }
2014     }
2015   }
2016
2017   return $a;
2018 }
2019
2020 sub result_source {
2021     my $self = shift;
2022
2023     if (@_) {
2024         $self->_source_handle($_[0]->handle);
2025     } else {
2026         $self->_source_handle->resolve;
2027     }
2028 }
2029
2030 =head2 throw_exception
2031
2032 See L<DBIx::Class::Schema/throw_exception> for details.
2033
2034 =cut
2035
2036 sub throw_exception {
2037   my $self=shift;
2038   $self->_source_handle->schema->throw_exception(@_);
2039 }
2040
2041 # XXX: FIXME: Attributes docs need clearing up
2042
2043 =head1 ATTRIBUTES
2044
2045 The resultset takes various attributes that modify its behavior. Here's an
2046 overview of them:
2047
2048 =head2 order_by
2049
2050 =over 4
2051
2052 =item Value: ($order_by | \@order_by)
2053
2054 =back
2055
2056 Which column(s) to order the results by. This is currently passed
2057 through directly to SQL, so you can give e.g. C<year DESC> for a
2058 descending order on the column `year'.
2059
2060 Please note that if you have C<quote_char> enabled (see
2061 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
2062 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
2063 so you will need to manually quote things as appropriate.)
2064
2065 =head2 columns
2066
2067 =over 4
2068
2069 =item Value: \@columns
2070
2071 =back
2072
2073 Shortcut to request a particular set of columns to be retrieved.  Adds
2074 C<me.> onto the start of any column without a C<.> in it and sets C<select>
2075 from that, then auto-populates C<as> from C<select> as normal. (You may also
2076 use the C<cols> attribute, as in earlier versions of DBIC.)
2077
2078 =head2 include_columns
2079
2080 =over 4
2081
2082 =item Value: \@columns
2083
2084 =back
2085
2086 Shortcut to include additional columns in the returned results - for example
2087
2088   $schema->resultset('CD')->search(undef, {
2089     include_columns => ['artist.name'],
2090     join => ['artist']
2091   });
2092
2093 would return all CDs and include a 'name' column to the information
2094 passed to object inflation. Note that the 'artist' is the name of the
2095 column (or relationship) accessor, and 'name' is the name of the column
2096 accessor in the related table.
2097
2098 =head2 select
2099
2100 =over 4
2101
2102 =item Value: \@select_columns
2103
2104 =back
2105
2106 Indicates which columns should be selected from the storage. You can use
2107 column names, or in the case of RDBMS back ends, function or stored procedure
2108 names:
2109
2110   $rs = $schema->resultset('Employee')->search(undef, {
2111     select => [
2112       'name',
2113       { count => 'employeeid' },
2114       { sum => 'salary' }
2115     ]
2116   });
2117
2118 When you use function/stored procedure names and do not supply an C<as>
2119 attribute, the column names returned are storage-dependent. E.g. MySQL would
2120 return a column named C<count(employeeid)> in the above example.
2121
2122 =head2 +select
2123
2124 =over 4
2125
2126 Indicates additional columns to be selected from storage.  Works the same as
2127 L<select> but adds columns to the selection.
2128
2129 =back
2130
2131 =head2 +as
2132
2133 =over 4
2134
2135 Indicates additional column names for those added via L<+select>.
2136
2137 =back
2138
2139 =head2 as
2140
2141 =over 4
2142
2143 =item Value: \@inflation_names
2144
2145 =back
2146
2147 Indicates column names for object inflation. That is, c< as >
2148 indicates the name that the column can be accessed as via the
2149 C<get_column> method (or via the object accessor, B<if one already
2150 exists>).  It has nothing to do with the SQL code C< SELECT foo AS bar
2151 >.
2152
2153 The C< as > attribute is used in conjunction with C<select>,
2154 usually when C<select> contains one or more function or stored
2155 procedure names:
2156
2157   $rs = $schema->resultset('Employee')->search(undef, {
2158     select => [
2159       'name',
2160       { count => 'employeeid' }
2161     ],
2162     as => ['name', 'employee_count'],
2163   });
2164
2165   my $employee = $rs->first(); # get the first Employee
2166
2167 If the object against which the search is performed already has an accessor
2168 matching a column name specified in C<as>, the value can be retrieved using
2169 the accessor as normal:
2170
2171   my $name = $employee->name();
2172
2173 If on the other hand an accessor does not exist in the object, you need to
2174 use C<get_column> instead:
2175
2176   my $employee_count = $employee->get_column('employee_count');
2177
2178 You can create your own accessors if required - see
2179 L<DBIx::Class::Manual::Cookbook> for details.
2180
2181 Please note: This will NOT insert an C<AS employee_count> into the SQL
2182 statement produced, it is used for internal access only. Thus
2183 attempting to use the accessor in an C<order_by> clause or similar
2184 will fail miserably.
2185
2186 To get around this limitation, you can supply literal SQL to your
2187 C<select> attibute that contains the C<AS alias> text, eg:
2188
2189   select => [\'myfield AS alias']
2190
2191 =head2 join
2192
2193 =over 4
2194
2195 =item Value: ($rel_name | \@rel_names | \%rel_names)
2196
2197 =back
2198
2199 Contains a list of relationships that should be joined for this query.  For
2200 example:
2201
2202   # Get CDs by Nine Inch Nails
2203   my $rs = $schema->resultset('CD')->search(
2204     { 'artist.name' => 'Nine Inch Nails' },
2205     { join => 'artist' }
2206   );
2207
2208 Can also contain a hash reference to refer to the other relation's relations.
2209 For example:
2210
2211   package MyApp::Schema::Track;
2212   use base qw/DBIx::Class/;
2213   __PACKAGE__->table('track');
2214   __PACKAGE__->add_columns(qw/trackid cd position title/);
2215   __PACKAGE__->set_primary_key('trackid');
2216   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2217   1;
2218
2219   # In your application
2220   my $rs = $schema->resultset('Artist')->search(
2221     { 'track.title' => 'Teardrop' },
2222     {
2223       join     => { cd => 'track' },
2224       order_by => 'artist.name',
2225     }
2226   );
2227
2228 You need to use the relationship (not the table) name in  conditions,
2229 because they are aliased as such. The current table is aliased as "me", so
2230 you need to use me.column_name in order to avoid ambiguity. For example:
2231
2232   # Get CDs from 1984 with a 'Foo' track
2233   my $rs = $schema->resultset('CD')->search(
2234     {
2235       'me.year' => 1984,
2236       'tracks.name' => 'Foo'
2237     },
2238     { join => 'tracks' }
2239   );
2240
2241 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2242 similarly for a third time). For e.g.
2243
2244   my $rs = $schema->resultset('Artist')->search({
2245     'cds.title'   => 'Down to Earth',
2246     'cds_2.title' => 'Popular',
2247   }, {
2248     join => [ qw/cds cds/ ],
2249   });
2250
2251 will return a set of all artists that have both a cd with title 'Down
2252 to Earth' and a cd with title 'Popular'.
2253
2254 If you want to fetch related objects from other tables as well, see C<prefetch>
2255 below.
2256
2257 =head2 prefetch
2258
2259 =over 4
2260
2261 =item Value: ($rel_name | \@rel_names | \%rel_names)
2262
2263 =back
2264
2265 Contains one or more relationships that should be fetched along with the main
2266 query (when they are accessed afterwards they will have already been
2267 "prefetched").  This is useful for when you know you will need the related
2268 objects, because it saves at least one query:
2269
2270   my $rs = $schema->resultset('Tag')->search(
2271     undef,
2272     {
2273       prefetch => {
2274         cd => 'artist'
2275       }
2276     }
2277   );
2278
2279 The initial search results in SQL like the following:
2280
2281   SELECT tag.*, cd.*, artist.* FROM tag
2282   JOIN cd ON tag.cd = cd.cdid
2283   JOIN artist ON cd.artist = artist.artistid
2284
2285 L<DBIx::Class> has no need to go back to the database when we access the
2286 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2287 case.
2288
2289 Simple prefetches will be joined automatically, so there is no need
2290 for a C<join> attribute in the above search. If you're prefetching to
2291 depth (e.g. { cd => { artist => 'label' } or similar), you'll need to
2292 specify the join as well.
2293
2294 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2295 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2296 with an accessor type of 'single' or 'filter').
2297
2298 =head2 page
2299
2300 =over 4
2301
2302 =item Value: $page
2303
2304 =back
2305
2306 Makes the resultset paged and specifies the page to retrieve. Effectively
2307 identical to creating a non-pages resultset and then calling ->page($page)
2308 on it.
2309
2310 If L<rows> attribute is not specified it defualts to 10 rows per page.
2311
2312 =head2 rows
2313
2314 =over 4
2315
2316 =item Value: $rows
2317
2318 =back
2319
2320 Specifes the maximum number of rows for direct retrieval or the number of
2321 rows per page if the page attribute or method is used.
2322
2323 =head2 offset
2324
2325 =over 4
2326
2327 =item Value: $offset
2328
2329 =back
2330
2331 Specifies the (zero-based) row number for the  first row to be returned, or the
2332 of the first row of the first page if paging is used.
2333
2334 =head2 group_by
2335
2336 =over 4
2337
2338 =item Value: \@columns
2339
2340 =back
2341
2342 A arrayref of columns to group by. Can include columns of joined tables.
2343
2344   group_by => [qw/ column1 column2 ... /]
2345
2346 =head2 having
2347
2348 =over 4
2349
2350 =item Value: $condition
2351
2352 =back
2353
2354 HAVING is a select statement attribute that is applied between GROUP BY and
2355 ORDER BY. It is applied to the after the grouping calculations have been
2356 done.
2357
2358   having => { 'count(employee)' => { '>=', 100 } }
2359
2360 =head2 distinct
2361
2362 =over 4
2363
2364 =item Value: (0 | 1)
2365
2366 =back
2367
2368 Set to 1 to group by all columns.
2369
2370 =head2 where
2371
2372 =over 4
2373
2374 Adds to the WHERE clause.
2375
2376   # only return rows WHERE deleted IS NULL for all searches
2377   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2378
2379 Can be overridden by passing C<{ where => undef }> as an attribute
2380 to a resulset.
2381
2382 =back
2383
2384 =head2 cache
2385
2386 Set to 1 to cache search results. This prevents extra SQL queries if you
2387 revisit rows in your ResultSet:
2388
2389   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2390
2391   while( my $artist = $resultset->next ) {
2392     ... do stuff ...
2393   }
2394
2395   $rs->first; # without cache, this would issue a query
2396
2397 By default, searches are not cached.
2398
2399 For more examples of using these attributes, see
2400 L<DBIx::Class::Manual::Cookbook>.
2401
2402 =head2 from
2403
2404 =over 4
2405
2406 =item Value: \@from_clause
2407
2408 =back
2409
2410 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2411 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2412 clauses.
2413
2414 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2415
2416 C<join> will usually do what you need and it is strongly recommended that you
2417 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2418 And we really do mean "cannot", not just tried and failed. Attempting to use
2419 this because you're having problems with C<join> is like trying to use x86
2420 ASM because you've got a syntax error in your C. Trust us on this.
2421
2422 Now, if you're still really, really sure you need to use this (and if you're
2423 not 100% sure, ask the mailing list first), here's an explanation of how this
2424 works.
2425
2426 The syntax is as follows -
2427
2428   [
2429     { <alias1> => <table1> },
2430     [
2431       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2432       [], # nested JOIN (optional)
2433       { <table1.column1> => <table2.column2>, ... (more conditions) },
2434     ],
2435     # More of the above [ ] may follow for additional joins
2436   ]
2437
2438   <table1> <alias1>
2439   JOIN
2440     <table2> <alias2>
2441     [JOIN ...]
2442   ON <table1.column1> = <table2.column2>
2443   <more joins may follow>
2444
2445 An easy way to follow the examples below is to remember the following:
2446
2447     Anything inside "[]" is a JOIN
2448     Anything inside "{}" is a condition for the enclosing JOIN
2449
2450 The following examples utilize a "person" table in a family tree application.
2451 In order to express parent->child relationships, this table is self-joined:
2452
2453     # Person->belongs_to('father' => 'Person');
2454     # Person->belongs_to('mother' => 'Person');
2455
2456 C<from> can be used to nest joins. Here we return all children with a father,
2457 then search against all mothers of those children:
2458
2459   $rs = $schema->resultset('Person')->search(
2460       undef,
2461       {
2462           alias => 'mother', # alias columns in accordance with "from"
2463           from => [
2464               { mother => 'person' },
2465               [
2466                   [
2467                       { child => 'person' },
2468                       [
2469                           { father => 'person' },
2470                           { 'father.person_id' => 'child.father_id' }
2471                       ]
2472                   ],
2473                   { 'mother.person_id' => 'child.mother_id' }
2474               ],
2475           ]
2476       },
2477   );
2478
2479   # Equivalent SQL:
2480   # SELECT mother.* FROM person mother
2481   # JOIN (
2482   #   person child
2483   #   JOIN person father
2484   #   ON ( father.person_id = child.father_id )
2485   # )
2486   # ON ( mother.person_id = child.mother_id )
2487
2488 The type of any join can be controlled manually. To search against only people
2489 with a father in the person table, we could explicitly use C<INNER JOIN>:
2490
2491     $rs = $schema->resultset('Person')->search(
2492         undef,
2493         {
2494             alias => 'child', # alias columns in accordance with "from"
2495             from => [
2496                 { child => 'person' },
2497                 [
2498                     { father => 'person', -join_type => 'inner' },
2499                     { 'father.id' => 'child.father_id' }
2500                 ],
2501             ]
2502         },
2503     );
2504
2505     # Equivalent SQL:
2506     # SELECT child.* FROM person child
2507     # INNER JOIN person father ON child.father_id = father.id
2508
2509 =cut
2510
2511 1;