lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use DBIx::Class::ResultClass::HashRefInflator;
   9 use Scalar::Util qw/blessed weaken reftype/;
  10 use DBIx::Class::_Util qw(
  11   dbic_internal_try dump_value
  12   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  13 );
  14 use Try::Tiny;
  15
  16 # not importing first() as it will clash with our own method
  17 use List::Util ();
  18
  19 BEGIN {
  20   # De-duplication in _merge_attr() is disabled, but left in for reference
  21   # (the merger is used for other things that ought not to be de-duped)
  22   *__HM_DEDUP = sub () { 0 };
  23 }
  24
  25 use namespace::clean;
  26
  27 use overload
  28         '0+'     => "count",
  29         'bool'   => "_bool",
  30         fallback => 1;
  31
  32 # this is real - CDBICompat overrides it with insanity
  33 # yes, prototype won't matter, but that's for now ;)
  34 sub _bool () { 1 }
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  37
  38 =head1 NAME
  39
  40 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  41
  42 =head1 SYNOPSIS
  43
  44   my $users_rs = $schema->resultset('User');
  45   while( $user = $users_rs->next) {
  46     print $user->username;
  47   }
  48
  49   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  50   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  51
  52 =head1 DESCRIPTION
  53
  54 A ResultSet is an object which stores a set of conditions representing
  55 a query. It is the backbone of DBIx::Class (i.e. the really
  56 important/useful bit).
  57
  58 No SQL is executed on the database when a ResultSet is created, it
  59 just stores all the conditions needed to create the query.
  60
  61 A basic ResultSet representing the data of an entire table is returned
  62 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  63 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  64
  65   my $users_rs = $schema->resultset('User');
  66
  67 A new ResultSet is returned from calling L</search> on an existing
  68 ResultSet. The new one will contain all the conditions of the
  69 original, plus any new conditions added in the C<search> call.
  70
  71 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  72 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  73 represents.
  74
  75 The query that the ResultSet represents is B<only> executed against
  76 the database when these methods are called:
  77 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  78
  79 If a resultset is used in a numeric context it returns the L</count>.
  80 However, if it is used in a boolean context it is B<always> true.  So if
  81 you want to check if a resultset has any results, you must use C<if $rs
  82 != 0>.
  83
  84 =head1 EXAMPLES
  85
  86 =head2 Chaining resultsets
  87
  88 Let's say you've got a query that needs to be run to return some data
  89 to the user. But, you have an authorization system in place that
  90 prevents certain users from seeing certain information. So, you want
  91 to construct the basic query in one method, but add constraints to it in
  92 another.
  93
  94   sub get_data {
  95     my $self = shift;
  96     my $request = $self->get_request; # Get a request object somehow.
  97     my $schema = $self->result_source->schema;
  98
  99     my $cd_rs = $schema->resultset('CD')->search({
 100       title => $request->param('title'),
 101       year => $request->param('year'),
 102     });
 103
 104     $cd_rs = $self->apply_security_policy( $cd_rs );
 105
 106     return $cd_rs->all();
 107   }
 108
 109   sub apply_security_policy {
 110     my $self = shift;
 111     my ($rs) = @_;
 112
 113     return $rs->search({
 114       subversive => 0,
 115     });
 116   }
 117
 118 =head3 Resolving conditions and attributes
 119
 120 When a resultset is chained from another resultset (e.g.:
 121 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 122 and attributes with the same keys need resolving.
 123
 124 If any of L</columns>, L</select>, L</as> are present, they reset the
 125 original selection, and start the selection "clean".
 126
 127 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 128 are merged into the existing ones from the original resultset.
 129
 130 The L</where> and L</having> attributes, and any search conditions, are
 131 merged with an SQL C<AND> to the existing condition from the original
 132 resultset.
 133
 134 All other attributes are overridden by any new ones supplied in the
 135 search attributes.
 136
 137 =head2 Multiple queries
 138
 139 Since a resultset just defines a query, you can do all sorts of
 140 things with it with the same object.
 141
 142   # Don't hit the DB yet.
 143   my $cd_rs = $schema->resultset('CD')->search({
 144     title => 'something',
 145     year => 2009,
 146   });
 147
 148   # Each of these hits the DB individually.
 149   my $count = $cd_rs->count;
 150   my $most_recent = $cd_rs->get_column('date_released')->max();
 151   my @records = $cd_rs->all;
 152
 153 And it's not just limited to SELECT statements.
 154
 155   $cd_rs->delete();
 156
 157 This is even cooler:
 158
 159   $cd_rs->create({ artist => 'Fred' });
 160
 161 Which is the same as:
 162
 163   $schema->resultset('CD')->create({
 164     title => 'something',
 165     year => 2009,
 166     artist => 'Fred'
 167   });
 168
 169 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 170
 171 =head2 Custom ResultSet classes
 172
 173 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 174
 175   package MyApp::Schema::ResultSet::User;
 176
 177   use strict;
 178   use warnings;
 179
 180   use base 'DBIx::Class::ResultSet';
 181
 182   sub active {
 183     my $self = shift;
 184     $self->search({ $self->current_source_alias . '.active' => 1 });
 185   }
 186
 187   sub unverified {
 188     my $self = shift;
 189     $self->search({ $self->current_source_alias . '.verified' => 0 });
 190   }
 191
 192   sub created_n_days_ago {
 193     my ($self, $days_ago) = @_;
 194     $self->search({
 195       $self->current_source_alias . '.create_date' => {
 196         '<=',
 197       $self->result_source->schema->storage->datetime_parser->format_datetime(
 198         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 199       )}
 200     });
 201   }
 202
 203   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 204
 205   1;
 206
 207 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 208 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 209 L<ResulSet|DBIx::Class::ResultSet> classes.
 210
 211 =head3 ResultSet subclassing with Moose and similar constructor-providers
 212
 213 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 214 you may find it useful if your ResultSets contain a lot of business logic
 215 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 216 your code via roles.
 217
 218 In order to write custom ResultSet classes with L<Moo> you need to use the
 219 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 220 unusual signature of the L<constructor provided by DBIC
 221 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 222
 223   use Moo;
 224   extends 'DBIx::Class::ResultSet';
 225   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 226
 227   ...your code...
 228
 229   1;
 230
 231 If you want to build your custom ResultSet classes with L<Moose>, you need
 232 a similar, though a little more elaborate template in order to interface the
 233 inlining of the L<Moose>-provided
 234 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 235 with the DBIC one.
 236
 237   package MyApp::Schema::ResultSet::User;
 238
 239   use Moose;
 240   use MooseX::NonMoose;
 241   extends 'DBIx::Class::ResultSet';
 242
 243   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 244
 245   ...your code...
 246
 247   __PACKAGE__->meta->make_immutable;
 248
 249   1;
 250
 251 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 252 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 253 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 254 instead by doing:
 255
 256   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 257
 258 =head1 METHODS
 259
 260 =head2 new
 261
 262 =over 4
 263
 264 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 265
 266 =item Return Value: L<$resultset|/search>
 267
 268 =back
 269
 270 The resultset constructor. Takes a source object (usually a
 271 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 272 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 273 executed as needed by the other methods.
 274
 275 Generally you never construct a resultset manually. Instead you get one
 276 from e.g. a
 277 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 278 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 279 scalar context):
 280
 281   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 282
 283 =over
 284
 285 =item WARNING
 286
 287 If called on an object, proxies to L</new_result> instead, so
 288
 289   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 290
 291 will return a CD object, not a ResultSet, and is equivalent to:
 292
 293   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 294
 295 Please also keep in mind that many internals call L</new_result> directly,
 296 so overloading this method with the idea of intercepting new result object
 297 creation B<will not work>. See also warning pertaining to L</create>.
 298
 299 =back
 300
 301 =cut
 302
 303 sub new {
 304   my $class = shift;
 305
 306   if (ref $class) {
 307     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 308     return $class->new_result(@_);
 309   }
 310
 311   my ($source, $attrs) = @_;
 312   $source = $source->resolve
 313     if $source->isa('DBIx::Class::ResultSourceHandle');
 314
 315   $attrs = { %{$attrs||{}} };
 316   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 317
 318   if ($attrs->{page}) {
 319     $attrs->{rows} ||= 10;
 320   }
 321
 322   $attrs->{alias} ||= 'me';
 323
 324   my $self = bless {
 325     result_source => $source,
 326     cond => $attrs->{where},
 327     pager => undef,
 328     attrs => $attrs,
 329   }, $class;
 330
 331   # if there is a dark selector, this means we are already in a
 332   # chain and the cleanup/sanification was taken care of by
 333   # _search_rs already
 334   $self->_normalize_selection($attrs)
 335     unless $attrs->{_dark_selector};
 336
 337   $self->result_class(
 338     $attrs->{result_class} || $source->result_class
 339   );
 340
 341   $self;
 342 }
 343
 344 =head2 search
 345
 346 =over 4
 347
 348 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 349
 350 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 351
 352 =back
 353
 354   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 355   my $new_rs = $cd_rs->search({ year => 2005 });
 356
 357   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 358                  # year = 2005 OR year = 2004
 359
 360 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 361 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 362 To avoid that, use L</search_rs>.
 363
 364 If you need to pass in additional attributes but no additional condition,
 365 call it as C<search(undef, \%attrs)>.
 366
 367   # "SELECT name, artistid FROM $artist_table"
 368   my @all_artists = $schema->resultset('Artist')->search(undef, {
 369     columns => [qw/name artistid/],
 370   });
 371
 372 For a list of attributes that can be passed to C<search>, see
 373 L</ATTRIBUTES>. For more examples of using this function, see
 374 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 375 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 376 and its extension L<DBIx::Class::SQLMaker>.
 377
 378 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 379
 380 =head3 CAVEAT
 381
 382 Note that L</search> does not process/deflate any of the values passed in the
 383 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 384 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 385 manually that any value passed to this method will stringify to something the
 386 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 387 objects, for more info see:
 388 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 389
 390 =cut
 391
 392 sub search {
 393   my $self = shift;
 394   my $rs = $self->search_rs( @_ );
 395
 396   if (wantarray) {
 397     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 398     return $rs->all;
 399   }
 400   elsif (defined wantarray) {
 401     return $rs;
 402   }
 403   else {
 404     # we can be called by a relationship helper, which in
 405     # turn may be called in void context due to some braindead
 406     # overload or whatever else the user decided to be clever
 407     # at this particular day. Thus limit the exception to
 408     # external code calls only
 409     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 410       if (caller)[0] !~ /^\QDBIx::Class::/;
 411
 412     return ();
 413   }
 414 }
 415
 416 =head2 search_rs
 417
 418 =over 4
 419
 420 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 421
 422 =item Return Value: L<$resultset|/search>
 423
 424 =back
 425
 426 This method does the same exact thing as search() except it will
 427 always return a resultset, even in list context.
 428
 429 =cut
 430
 431 sub search_rs {
 432   my $self = shift;
 433
 434   my $rsrc = $self->result_source;
 435   my ($call_cond, $call_attrs);
 436
 437   # Special-case handling for (undef, undef) or (undef)
 438   # Note that (foo => undef) is valid deprecated syntax
 439   @_ = () if not scalar grep { defined $_ } @_;
 440
 441   # just a cond
 442   if (@_ == 1) {
 443     $call_cond = shift;
 444   }
 445   # fish out attrs in the ($condref, $attr) case
 446   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 447     ($call_cond, $call_attrs) = @_;
 448   }
 449   elsif (@_ % 2) {
 450     $self->throw_exception('Odd number of arguments to search')
 451   }
 452   # legacy search
 453   elsif (@_) {
 454     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 455       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 456
 457     for my $i (0 .. $#_) {
 458       next if $i % 2;
 459       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 460         if (! defined $_[$i] or length ref $_[$i] );
 461     }
 462
 463     $call_cond = { @_ };
 464   }
 465
 466   # see if we can keep the cache (no $rs changes)
 467   my $cache;
 468   my %safe = (alias => 1, cache => 1);
 469   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 470     ! defined $call_cond
 471       or
 472     ref $call_cond eq 'HASH' && ! keys %$call_cond
 473       or
 474     ref $call_cond eq 'ARRAY' && ! @$call_cond
 475   )) {
 476     $cache = $self->get_cache;
 477   }
 478
 479   my $old_attrs = { %{$self->{attrs}} };
 480   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 481
 482   my $new_attrs = { %$old_attrs };
 483
 484   # take care of call attrs (only if anything is changing)
 485   if ($call_attrs and keys %$call_attrs) {
 486
 487     # copy for _normalize_selection
 488     $call_attrs = { %$call_attrs };
 489
 490     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 491
 492     # reset the current selector list if new selectors are supplied
 493     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 494       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 495     }
 496
 497     # Normalize the new selector list (operates on the passed-in attr structure)
 498     # Need to do it on every chain instead of only once on _resolved_attrs, in
 499     # order to allow detection of empty vs partial 'as'
 500     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 501       if $old_attrs->{_dark_selector};
 502     $self->_normalize_selection ($call_attrs);
 503
 504     # start with blind overwriting merge, exclude selector attrs
 505     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 506     delete @{$new_attrs}{@selector_attrs};
 507
 508     for (@selector_attrs) {
 509       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 510         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 511     }
 512
 513     # older deprecated name, use only if {columns} is not there
 514     if (my $c = delete $new_attrs->{cols}) {
 515       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 516       if ($new_attrs->{columns}) {
 517         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 518       }
 519       else {
 520         $new_attrs->{columns} = $c;
 521       }
 522     }
 523
 524
 525     # join/prefetch use their own crazy merging heuristics
 526     foreach my $key (qw/join prefetch/) {
 527       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 528         if exists $call_attrs->{$key};
 529     }
 530
 531     # stack binds together
 532     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 533   }
 534
 535
 536   for ($old_where, $call_cond) {
 537     if (defined $_) {
 538       $new_attrs->{where} = $self->_stack_cond (
 539         $_, $new_attrs->{where}
 540       );
 541     }
 542   }
 543
 544   if (defined $old_having) {
 545     $new_attrs->{having} = $self->_stack_cond (
 546       $old_having, $new_attrs->{having}
 547     )
 548   }
 549
 550   my $rs = (ref $self)->new($rsrc, $new_attrs);
 551
 552   $rs->set_cache($cache) if ($cache);
 553
 554   return $rs;
 555 }
 556
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => do {
 622                 local $Data::Dumper::Indent = 0;
 623                 dump_value $_;
 624               },
 625             };
 626             last SELECTOR;
 627           }
 628         }
 629       }
 630     }
 631     elsif (@$as < @$sel) {
 632       $self->throw_exception(
 633         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 634       );
 635     }
 636     elsif ($pref and $attrs->{_dark_selector}) {
 637       $self->throw_exception(
 638         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 639       );
 640     }
 641
 642
 643     # merge result
 644     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 645     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 646   }
 647 }
 648
 649 sub _stack_cond {
 650   my ($self, $left, $right) = @_;
 651
 652   (
 653     (ref $_ eq 'ARRAY' and !@$_)
 654       or
 655     (ref $_ eq 'HASH' and ! keys %$_)
 656   ) and $_ = undef for ($left, $right);
 657
 658   # either one of the two undef
 659   if ( (defined $left) xor (defined $right) ) {
 660     return defined $left ? $left : $right;
 661   }
 662   # both undef
 663   elsif ( ! defined $left ) {
 664     return undef
 665   }
 666   else {
 667     return $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 668   }
 669 }
 670
 671 =head2 search_literal
 672
 673 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 674 should only be used in that context. C<search_literal> is a convenience
 675 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 676 want to ensure columns are bound correctly, use L</search>.
 677
 678 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 679 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 680 require C<search_literal>.
 681
 682 =over 4
 683
 684 =item Arguments: $sql_fragment, @standalone_bind_values
 685
 686 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 687
 688 =back
 689
 690   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 691   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 692
 693 Pass a literal chunk of SQL to be added to the conditional part of the
 694 resultset query.
 695
 696 Example of how to use C<search> instead of C<search_literal>
 697
 698   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 699   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 700
 701 =cut
 702
 703 sub search_literal {
 704   my ($self, $sql, @bind) = @_;
 705   my $attr;
 706   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 707     $attr = pop @bind;
 708   }
 709   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 710 }
 711
 712 =head2 find
 713
 714 =over 4
 715
 716 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 717
 718 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 719
 720 =back
 721
 722 Finds and returns a single row based on supplied criteria. Takes either a
 723 hashref with the same format as L</create> (including inference of foreign
 724 keys from related objects), or a list of primary key values in the same
 725 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 726 declaration on the L</result_source>.
 727
 728 In either case an attempt is made to combine conditions already existing on
 729 the resultset with the condition passed to this method.
 730
 731 To aid with preparing the correct query for the storage you may supply the
 732 C<key> attribute, which is the name of a
 733 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 734 unique constraint corresponding to the
 735 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 736 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 737 to construct a query that satisfies the named unique constraint fully (
 738 non-NULL values for each column member of the constraint) an exception is
 739 thrown.
 740
 741 If no C<key> is specified, the search is carried over all unique constraints
 742 which are fully defined by the available condition.
 743
 744 If no such constraint is found, C<find> currently defaults to a simple
 745 C<< search->(\%column_values) >> which may or may not do what you expect.
 746 Note that this fallback behavior may be deprecated in further versions. If
 747 you need to search with arbitrary conditions - use L</search>. If the query
 748 resulting from this fallback produces more than one row, a warning to the
 749 effect is issued, though only the first row is constructed and returned as
 750 C<$result_object>.
 751
 752 In addition to C<key>, L</find> recognizes and applies standard
 753 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 754
 755 Note that if you have extra concerns about the correctness of the resulting
 756 query you need to specify the C<key> attribute and supply the entire condition
 757 as an argument to find (since it is not always possible to perform the
 758 combination of the resultset condition with the supplied one, especially if
 759 the resultset condition contains literal sql).
 760
 761 For example, to find a row by its primary key:
 762
 763   my $cd = $schema->resultset('CD')->find(5);
 764
 765 You can also find a row by a specific unique constraint:
 766
 767   my $cd = $schema->resultset('CD')->find(
 768     {
 769       artist => 'Massive Attack',
 770       title  => 'Mezzanine',
 771     },
 772     { key => 'cd_artist_title' }
 773   );
 774
 775 See also L</find_or_create> and L</update_or_create>.
 776
 777 =cut
 778
 779 sub find {
 780   my $self = shift;
 781   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 782
 783   my $rsrc = $self->result_source;
 784
 785   my $constraint_name;
 786   if (exists $attrs->{key}) {
 787     $constraint_name = defined $attrs->{key}
 788       ? $attrs->{key}
 789       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 790     ;
 791   }
 792
 793   # Parse out the condition from input
 794   my $call_cond;
 795
 796   if (ref $_[0] eq 'HASH') {
 797     $call_cond = { %{$_[0]} };
 798   }
 799   else {
 800     # if only values are supplied we need to default to 'primary'
 801     $constraint_name = 'primary' unless defined $constraint_name;
 802
 803     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 804
 805     $self->throw_exception(
 806       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 807     ) unless @c_cols;
 808
 809     $self->throw_exception (
 810       'find() expects either a column/value hashref, or a list of values '
 811     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 812     ) unless @c_cols == @_;
 813
 814     @{$call_cond}{@c_cols} = @_;
 815   }
 816
 817   # process relationship data if any
 818   for my $key (keys %$call_cond) {
 819     if (
 820       length ref($call_cond->{$key})
 821         and
 822       my $relinfo = $rsrc->relationship_info($key)
 823         and
 824       # implicitly skip has_many's (likely MC)
 825       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 826     ) {
 827       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 828         $relinfo->{cond}, $val, $key, $key
 829       );
 830
 831       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 832          if $crosstable or ref($rel_cond) ne 'HASH';
 833
 834       # supplement condition
 835       # relationship conditions take precedence (?)
 836       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 837     }
 838   }
 839
 840   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 841   my $final_cond;
 842   if (defined $constraint_name) {
 843     $final_cond = $self->_qualify_cond_columns (
 844
 845       $self->result_source->_minimal_valueset_satisfying_constraint(
 846         constraint_name => $constraint_name,
 847         values => ($self->_merge_with_rscond($call_cond))[0],
 848         carp_on_nulls => 1,
 849       ),
 850
 851       $alias,
 852     );
 853   }
 854   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 855     # This means that we got here after a merger of relationship conditions
 856     # in ::Relationship::Base::search_related (the row method), and furthermore
 857     # the relationship is of the 'single' type. This means that the condition
 858     # provided by the relationship (already attached to $self) is sufficient,
 859     # as there can be only one row in the database that would satisfy the
 860     # relationship
 861   }
 862   else {
 863     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 864
 865     # no key was specified - fall down to heuristics mode:
 866     # run through all unique queries registered on the resultset, and
 867     # 'OR' all qualifying queries together
 868     #
 869     # always start from 'primary' if it exists at all
 870     for my $c_name ( sort {
 871         $a eq 'primary' ? -1
 872       : $b eq 'primary' ? 1
 873       : $a cmp $b
 874     } $rsrc->unique_constraint_names) {
 875
 876       next if $seen_column_combinations{
 877         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 878       }++;
 879
 880       dbic_internal_try {
 881         push @unique_queries, $self->_qualify_cond_columns(
 882           $self->result_source->_minimal_valueset_satisfying_constraint(
 883             constraint_name => $c_name,
 884             values => ($self->_merge_with_rscond($call_cond))[0],
 885             columns_info => ($ci ||= $self->result_source->columns_info),
 886           ),
 887           $alias
 888         );
 889       }
 890       catch {
 891         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 892       };
 893     }
 894
 895     $final_cond =
 896         @unique_queries   ? \@unique_queries
 897       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 898       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 899     ;
 900   }
 901
 902   # Run the query, passing the result_class since it should propagate for find
 903   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 904   if ($rs->_resolved_attrs->{collapse}) {
 905     my $row = $rs->next;
 906     carp "Query returned more than one row" if $rs->next;
 907     return $row;
 908   }
 909   else {
 910     return $rs->single;
 911   }
 912 }
 913
 914 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 915 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 916 #
 917 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 918 # condition. It is provided for overrides until a saner way forward is devised
 919 #
 920 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 921 # the road. Please adjust your tests accordingly to catch this situation early
 922 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 923 #
 924 # The method will not be removed without an adequately complete replacement
 925 # for strict-mode enforcement
 926 sub _non_unique_find_fallback {
 927   my ($self, $cond, $attrs) = @_;
 928
 929   return $self->_qualify_cond_columns(
 930     $cond,
 931     exists $attrs->{alias}
 932       ? $attrs->{alias}
 933       : $self->{attrs}{alias}
 934   );
 935 }
 936
 937
 938 sub _qualify_cond_columns {
 939   my ($self, $cond, $alias) = @_;
 940
 941   my %aliased = %$cond;
 942   for (keys %aliased) {
 943     $aliased{"$alias.$_"} = delete $aliased{$_}
 944       if $_ !~ /\./;
 945   }
 946
 947   return \%aliased;
 948 }
 949
 950 sub _build_unique_cond {
 951   carp_unique sprintf
 952     '_build_unique_cond is a private method, and moreover is about to go '
 953   . 'away. Please contact the development team at %s if you believe you '
 954   . 'have a genuine use for this method, in order to discuss alternatives.',
 955     DBIx::Class::_ENV_::HELP_URL,
 956   ;
 957
 958   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 959
 960   $self->result_source->_minimal_valueset_satisfying_constraint(
 961     constraint_name => $constraint_name,
 962     values => $cond,
 963     carp_on_nulls => !$croak_on_null
 964   );
 965 }
 966
 967 =head2 search_related
 968
 969 =over 4
 970
 971 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 972
 973 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 974
 975 =back
 976
 977   $new_rs = $cd_rs->search_related('artist', {
 978     name => 'Emo-R-Us',
 979   });
 980
 981 Searches the specified relationship, optionally specifying a condition and
 982 attributes for matching records. See L</ATTRIBUTES> for more information.
 983
 984 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 985 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 986
 987 See also L</search_related_rs>.
 988
 989 =cut
 990
 991 sub search_related {
 992   return shift->related_resultset(shift)->search(@_);
 993 }
 994
 995 =head2 search_related_rs
 996
 997 This method works exactly the same as search_related, except that
 998 it guarantees a resultset, even in list context.
 999
1000 =cut
1001
1002 sub search_related_rs {
1003   return shift->related_resultset(shift)->search_rs(@_);
1004 }
1005
1006 =head2 cursor
1007
1008 =over 4
1009
1010 =item Arguments: none
1011
1012 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1013
1014 =back
1015
1016 Returns a storage-driven cursor to the given resultset. See
1017 L<DBIx::Class::Cursor> for more information.
1018
1019 =cut
1020
1021 sub cursor {
1022   my $self = shift;
1023
1024   return $self->{cursor} ||= do {
1025     my $attrs = $self->_resolved_attrs;
1026     $self->result_source->storage->select(
1027       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1028     );
1029   };
1030 }
1031
1032 =head2 single
1033
1034 =over 4
1035
1036 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1037
1038 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1039
1040 =back
1041
1042   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1043
1044 Inflates the first result without creating a cursor if the resultset has
1045 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1046 of L</search>.
1047
1048 While this method can take an optional search condition (just like L</search>)
1049 being a fast-code-path it does not recognize search attributes. If you need to
1050 add extra joins or similar, call L</search> and then chain-call L</single> on the
1051 L<DBIx::Class::ResultSet> returned.
1052
1053 =over
1054
1055 =item B<Note>
1056
1057 As of 0.08100, this method enforces the assumption that the preceding
1058 query returns only one row. If more than one row is returned, you will receive
1059 a warning:
1060
1061   Query returned more than one row
1062
1063 In this case, you should be using L</next> or L</find> instead, or if you really
1064 know what you are doing, use the L</rows> attribute to explicitly limit the size
1065 of the resultset.
1066
1067 This method will also throw an exception if it is called on a resultset prefetching
1068 has_many, as such a prefetch implies fetching multiple rows from the database in
1069 order to assemble the resulting object.
1070
1071 =back
1072
1073 =cut
1074
1075 sub single {
1076   my ($self, $where) = @_;
1077   if(@_ > 2) {
1078       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1079   }
1080
1081   my $attrs = { %{$self->_resolved_attrs} };
1082
1083   $self->throw_exception(
1084     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1085   ) if $attrs->{collapse};
1086
1087   if ($where) {
1088     if (defined $attrs->{where}) {
1089       $attrs->{where} = {
1090         '-and' =>
1091             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1092                $where, delete $attrs->{where} ]
1093       };
1094     } else {
1095       $attrs->{where} = $where;
1096     }
1097   }
1098
1099   my $data = [ $self->result_source->storage->select_single(
1100     $attrs->{from}, $attrs->{select},
1101     $attrs->{where}, $attrs
1102   )];
1103
1104   return undef unless @$data;
1105   $self->{_stashed_rows} = [ $data ];
1106   $self->_construct_results->[0];
1107 }
1108
1109 =head2 get_column
1110
1111 =over 4
1112
1113 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1114
1115 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1116
1117 =back
1118
1119   my $max_length = $rs->get_column('length')->max;
1120
1121 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1122
1123 =cut
1124
1125 sub get_column {
1126   my ($self, $column) = @_;
1127   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1128   return $new;
1129 }
1130
1131 =head2 search_like
1132
1133 =over 4
1134
1135 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1136
1137 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1138
1139 =back
1140
1141   # WHERE title LIKE '%blue%'
1142   $cd_rs = $rs->search_like({ title => '%blue%'});
1143
1144 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1145 that this is simply a convenience method retained for ex Class::DBI users.
1146 You most likely want to use L</search> with specific operators.
1147
1148 For more information, see L<DBIx::Class::Manual::Cookbook>.
1149
1150 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1151 instead. An example conversion is:
1152
1153   ->search_like({ foo => 'bar' });
1154
1155   # Becomes
1156
1157   ->search({ foo => { like => 'bar' } });
1158
1159 =cut
1160
1161 sub search_like {
1162   my $class = shift;
1163   carp_unique (
1164     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1165    .' Instead use ->search({ x => { -like => "y%" } })'
1166    .' (note the outer pair of {}s - they are important!)'
1167   );
1168   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1169   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1170   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1171   return $class->search($query, { %$attrs });
1172 }
1173
1174 =head2 slice
1175
1176 =over 4
1177
1178 =item Arguments: $first, $last
1179
1180 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1181
1182 =back
1183
1184 Returns a resultset or object list representing a subset of elements from the
1185 resultset slice is called on. Indexes are from 0, i.e., to get the first
1186 three records, call:
1187
1188   my ($one, $two, $three) = $rs->slice(0, 2);
1189
1190 =cut
1191
1192 sub slice {
1193   my ($self, $min, $max) = @_;
1194   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1195   $attrs->{offset} = $self->{attrs}{offset} || 0;
1196   $attrs->{offset} += $min;
1197   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1198   return $self->search(undef, $attrs);
1199 }
1200
1201 =head2 next
1202
1203 =over 4
1204
1205 =item Arguments: none
1206
1207 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1208
1209 =back
1210
1211 Returns the next element in the resultset (C<undef> is there is none).
1212
1213 Can be used to efficiently iterate over records in the resultset:
1214
1215   my $rs = $schema->resultset('CD')->search;
1216   while (my $cd = $rs->next) {
1217     print $cd->title;
1218   }
1219
1220 Note that you need to store the resultset object, and call C<next> on it.
1221 Calling C<< resultset('Table')->next >> repeatedly will always return the
1222 first record from the resultset.
1223
1224 =cut
1225
1226 sub next {
1227   my ($self) = @_;
1228
1229   if (my $cache = $self->get_cache) {
1230     $self->{all_cache_position} ||= 0;
1231     return $cache->[$self->{all_cache_position}++];
1232   }
1233
1234   if ($self->{attrs}{cache}) {
1235     delete $self->{pager};
1236     $self->{all_cache_position} = 1;
1237     return ($self->all)[0];
1238   }
1239
1240   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1241
1242   $self->{_stashed_results} = $self->_construct_results
1243     or return undef;
1244
1245   return shift @{$self->{_stashed_results}};
1246 }
1247
1248 # Constructs as many results as it can in one pass while respecting
1249 # cursor laziness. Several modes of operation:
1250 #
1251 # * Always builds everything present in @{$self->{_stashed_rows}}
1252 # * If called with $fetch_all true - pulls everything off the cursor and
1253 #   builds all result structures (or objects) in one pass
1254 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1255 #   and if the resultset is ordered properly by the left side:
1256 #   * Fetches stuff off the cursor until the "master object" changes,
1257 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1258 #   OR
1259 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1260 #     was requested (there is no other way to collapse except for an
1261 #     eager cursor)
1262 # * If no collapse is requested - just get the next row, construct and
1263 #   return
1264 sub _construct_results {
1265   my ($self, $fetch_all) = @_;
1266
1267   my $rsrc = $self->result_source;
1268   my $attrs = $self->_resolved_attrs;
1269
1270   if (
1271     ! $fetch_all
1272       and
1273     ! $attrs->{order_by}
1274       and
1275     $attrs->{collapse}
1276       and
1277     my @pcols = $rsrc->primary_columns
1278   ) {
1279     # default order for collapsing unless the user asked for something
1280     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1281     $attrs->{_ordered_for_collapse} = 1;
1282     $attrs->{_order_is_artificial} = 1;
1283   }
1284
1285   # this will be used as both initial raw-row collector AND as a RV of
1286   # _construct_results. Not regrowing the array twice matters a lot...
1287   # a surprising amount actually
1288   my $rows = delete $self->{_stashed_rows};
1289
1290   my $cursor; # we may not need one at all
1291
1292   my $did_fetch_all = $fetch_all;
1293
1294   if ($fetch_all) {
1295     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1296     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1297   }
1298   elsif( $attrs->{collapse} ) {
1299
1300     # a cursor will need to be closed over in case of collapse
1301     $cursor = $self->cursor;
1302
1303     $attrs->{_ordered_for_collapse} = (
1304       (
1305         $attrs->{order_by}
1306           and
1307         $rsrc->schema
1308               ->storage
1309                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1310       ) ? 1 : 0
1311     ) unless defined $attrs->{_ordered_for_collapse};
1312
1313     if (! $attrs->{_ordered_for_collapse}) {
1314       $did_fetch_all = 1;
1315
1316       # instead of looping over ->next, use ->all in stealth mode
1317       # *without* calling a ->reset afterwards
1318       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1319       if (! $cursor->{_done}) {
1320         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1321         $cursor->{_done} = 1;
1322       }
1323     }
1324   }
1325
1326   if (! $did_fetch_all and ! @{$rows||[]} ) {
1327     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1328     $cursor ||= $self->cursor;
1329     if (scalar (my @r = $cursor->next) ) {
1330       $rows = [ \@r ];
1331     }
1332   }
1333
1334   return undef unless @{$rows||[]};
1335
1336   # sanity check - people are too clever for their own good
1337   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1338
1339     my $multiplied_selectors;
1340     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1341       if (
1342         $aliastypes->{multiplying}{$sel_alias}
1343           or
1344         $aliastypes->{premultiplied}{$sel_alias}
1345       ) {
1346         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1347       }
1348     }
1349
1350     for my $i (0 .. $#{$attrs->{as}} ) {
1351       my $sel = $attrs->{select}[$i];
1352
1353       if (ref $sel eq 'SCALAR') {
1354         $sel = $$sel;
1355       }
1356       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1357         $sel = $$sel->[0];
1358       }
1359
1360       $self->throw_exception(
1361         'Result collapse not possible - selection from a has_many source redirected to the main object'
1362       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1363     }
1364   }
1365
1366   # hotspot - skip the setter
1367   my $res_class = $self->_result_class;
1368
1369   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1370     $res_class->can ('inflate_result')
1371       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1372   };
1373
1374   my $infmap = $attrs->{as};
1375
1376   $self->{_result_inflator}{is_core_row} = ( (
1377     $inflator_cref
1378       ==
1379     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1380   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1381
1382   $self->{_result_inflator}{is_hri} = ( (
1383     ! $self->{_result_inflator}{is_core_row}
1384       and
1385     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1386   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1387
1388
1389   if ($attrs->{_simple_passthrough_construction}) {
1390     # construct a much simpler array->hash folder for the one-table HRI cases right here
1391     if ($self->{_result_inflator}{is_hri}) {
1392       for my $r (@$rows) {
1393         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1394       }
1395     }
1396     # FIXME SUBOPTIMAL this is a very very very hot spot
1397     # while rather optimal we can *still* do much better, by
1398     # building a smarter Row::inflate_result(), and
1399     # switch to feeding it data via a much leaner interface
1400     #
1401     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1402     # this particular resultset size
1403     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1404       for my $r (@$rows) {
1405         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1406       }
1407     }
1408     else {
1409       eval sprintf (
1410         ( $self->{_result_inflator}{is_core_row}
1411           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1412           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1413           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1414         ),
1415         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1416       );
1417     }
1418   }
1419   else {
1420     my $parser_type =
1421         $self->{_result_inflator}{is_hri}       ? 'hri'
1422       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1423       :                                           'classic_nonpruning'
1424     ;
1425
1426     # $args and $attrs to _mk_row_parser are separated to delineate what is
1427     # core collapser stuff and what is dbic $rs specific
1428     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1429       eval => 1,
1430       inflate_map => $infmap,
1431       collapse => $attrs->{collapse},
1432       premultiplied => $attrs->{_main_source_premultiplied},
1433       hri_style => $self->{_result_inflator}{is_hri},
1434       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1435     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1436
1437     # column_info metadata historically hasn't been too reliable.
1438     # We need to start fixing this somehow (the collapse resolver
1439     # can't work without it). Add an explicit check for the *main*
1440     # result, hopefully this will gradually weed out such errors
1441     #
1442     # FIXME - this is a temporary kludge that reduces performance
1443     # It is however necessary for the time being
1444     my ($unrolled_non_null_cols_to_check, $err);
1445
1446     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1447
1448       $err =
1449         'Collapse aborted due to invalid ResultSource metadata - the following '
1450       . 'selections are declared non-nullable but NULLs were retrieved: '
1451       ;
1452
1453       my @violating_idx;
1454       COL: for my $i (@$check_non_null_cols) {
1455         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1456       }
1457
1458       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1459         if @violating_idx;
1460
1461       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1462
1463       utf8::upgrade($unrolled_non_null_cols_to_check)
1464         if DBIx::Class::_ENV_::STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE;
1465     }
1466
1467     my $next_cref =
1468       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1469     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1470 sub {
1471   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1472   my @r = $cursor->next or return;
1473   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1474     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1475   }
1476   \@r
1477 }
1478 EOS
1479     : sub {
1480         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1481         my @r = $cursor->next or return;
1482         \@r
1483       }
1484     ;
1485
1486     $self->{_row_parser}{$parser_type}{cref}->(
1487       $rows,
1488       $next_cref,
1489       ( $self->{_stashed_rows} = [] ),
1490     );
1491
1492     # simple in-place substitution, does not regrow $rows
1493     if ($self->{_result_inflator}{is_core_row}) {
1494       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1495     }
1496     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1497     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1498       # the inflator may be a multiplier/reductor - put it in list ctx
1499       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1500     }
1501   }
1502
1503   # The @$rows check seems odd at first - why wouldn't we want to warn
1504   # regardless? The issue is things like find() etc, where the user
1505   # *knows* only one result will come back. In these cases the ->all
1506   # is not a pessimization, but rather something we actually want
1507   carp_unique(
1508     'Unable to properly collapse has_many results in iterator mode due '
1509   . 'to order criteria - performed an eager cursor slurp underneath. '
1510   . 'Consider using ->all() instead'
1511   ) if ( ! $fetch_all and @$rows > 1 );
1512
1513   return $rows;
1514 }
1515
1516 =head2 result_source
1517
1518 =over 4
1519
1520 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1521
1522 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1523
1524 =back
1525
1526 An accessor for the primary ResultSource object from which this ResultSet
1527 is derived.
1528
1529 =head2 result_class
1530
1531 =over 4
1532
1533 =item Arguments: $result_class?
1534
1535 =item Return Value: $result_class
1536
1537 =back
1538
1539 An accessor for the class to use when creating result objects. Defaults to
1540 C<< result_source->result_class >> - which in most cases is the name of the
1541 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1542
1543 Note that changing the result_class will also remove any components
1544 that were originally loaded in the source class via
1545 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1546 Any overloaded methods in the original source class will not run.
1547
1548 =cut
1549
1550 sub result_class {
1551   my ($self, $result_class) = @_;
1552   if ($result_class) {
1553
1554     # don't fire this for an object
1555     $self->ensure_class_loaded($result_class)
1556       unless ref($result_class);
1557
1558     if ($self->get_cache) {
1559       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1560     }
1561     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1562     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1563       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1564     }
1565
1566     $self->_result_class($result_class);
1567
1568     delete $self->{_result_inflator};
1569   }
1570   $self->_result_class;
1571 }
1572
1573 =head2 count
1574
1575 =over 4
1576
1577 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1578
1579 =item Return Value: $count
1580
1581 =back
1582
1583 Performs an SQL C<COUNT> with the same query as the resultset was built
1584 with to find the number of elements. Passing arguments is equivalent to
1585 C<< $rs->search ($cond, \%attrs)->count >>
1586
1587 =cut
1588
1589 sub count {
1590   my $self = shift;
1591   return $self->search(@_)->count if @_ and defined $_[0];
1592   return scalar @{ $self->get_cache } if $self->get_cache;
1593
1594   my $attrs = { %{ $self->_resolved_attrs } };
1595
1596   # this is a little optimization - it is faster to do the limit
1597   # adjustments in software, instead of a subquery
1598   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1599
1600   my $crs;
1601   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1602     $crs = $self->_count_subq_rs ($attrs);
1603   }
1604   else {
1605     $crs = $self->_count_rs ($attrs);
1606   }
1607   my $count = $crs->next;
1608
1609   $count -= $offset if $offset;
1610   $count = $rows if $rows and $rows < $count;
1611   $count = 0 if ($count < 0);
1612
1613   return $count;
1614 }
1615
1616 =head2 count_rs
1617
1618 =over 4
1619
1620 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1621
1622 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1623
1624 =back
1625
1626 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1627 This can be very handy for subqueries:
1628
1629   ->search( { amount => $some_rs->count_rs->as_query } )
1630
1631 As with regular resultsets the SQL query will be executed only after
1632 the resultset is accessed via L</next> or L</all>. That would return
1633 the same single value obtainable via L</count>.
1634
1635 =cut
1636
1637 sub count_rs {
1638   my $self = shift;
1639   return $self->search(@_)->count_rs if @_;
1640
1641   # this may look like a lack of abstraction (count() does about the same)
1642   # but in fact an _rs *must* use a subquery for the limits, as the
1643   # software based limiting can not be ported if this $rs is to be used
1644   # in a subquery itself (i.e. ->as_query)
1645   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1646     return $self->_count_subq_rs($self->{_attrs});
1647   }
1648   else {
1649     return $self->_count_rs($self->{_attrs});
1650   }
1651 }
1652
1653 #
1654 # returns a ResultSetColumn object tied to the count query
1655 #
1656 sub _count_rs {
1657   my ($self, $attrs) = @_;
1658
1659   my $rsrc = $self->result_source;
1660
1661   my $tmp_attrs = { %$attrs };
1662   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1663   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1664
1665   # overwrite the selector (supplied by the storage)
1666   $rsrc->resultset_class->new($rsrc, {
1667     %$tmp_attrs,
1668     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1669     as => 'count',
1670   })->get_column ('count');
1671 }
1672
1673 #
1674 # same as above but uses a subquery
1675 #
1676 sub _count_subq_rs {
1677   my ($self, $attrs) = @_;
1678
1679   my $rsrc = $self->result_source;
1680
1681   my $sub_attrs = { %$attrs };
1682   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1683   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1684
1685   # if we multi-prefetch we group_by something unique, as this is what we would
1686   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1687   if ( $attrs->{collapse}  ) {
1688     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1689       $rsrc->_identifying_column_set || $self->throw_exception(
1690         'Unable to construct a unique group_by criteria properly collapsing the '
1691       . 'has_many prefetch before count()'
1692       );
1693     } ]
1694   }
1695
1696   # Calculate subquery selector
1697   if (my $g = $sub_attrs->{group_by}) {
1698
1699     my $sql_maker = $rsrc->storage->sql_maker;
1700
1701     # necessary as the group_by may refer to aliased functions
1702     my $sel_index;
1703     for my $sel (@{$attrs->{select}}) {
1704       $sel_index->{$sel->{-as}} = $sel
1705         if (ref $sel eq 'HASH' and $sel->{-as});
1706     }
1707
1708     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1709     # also look for named aggregates referred in the having clause
1710     # having often contains scalarrefs - thus parse it out entirely
1711     my @parts = @$g;
1712     if ($attrs->{having}) {
1713       local $sql_maker->{having_bind};
1714       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1715       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1716       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1717         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1718         # if we don't unset it we screw up retarded but unfortunately working
1719         # 'MAX(foo.bar)' => { '>', 3 }
1720         $sql_maker->{name_sep} = '';
1721       }
1722
1723       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1724
1725       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1726       my %seen_having;
1727
1728       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1729       # and if all fails for an utterly naive quoted scalar-with-function
1730       while ($having_sql =~ /
1731         $rquote $sep $lquote (.+?) $rquote
1732           |
1733         [\s,] \w+ \. (\w+) [\s,]
1734           |
1735         [\s,] $lquote (.+?) $rquote [\s,]
1736       /gx) {
1737         my $part = $1 || $2 || $3;  # one of them matched if we got here
1738         unless ($seen_having{$part}++) {
1739           push @parts, $part;
1740         }
1741       }
1742     }
1743
1744     for (@parts) {
1745       my $colpiece = $sel_index->{$_} || $_;
1746
1747       # unqualify join-based group_by's. Arcane but possible query
1748       # also horrible horrible hack to alias a column (not a func.)
1749       # (probably need to introduce SQLA syntax)
1750       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1751         my $as = $colpiece;
1752         $as =~ s/\./__/;
1753         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1754       }
1755       push @{$sub_attrs->{select}}, $colpiece;
1756     }
1757   }
1758   else {
1759     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1760     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1761   }
1762
1763   return $rsrc->resultset_class
1764                ->new ($rsrc, $sub_attrs)
1765                 ->as_subselect_rs
1766                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1767                   ->get_column ('count');
1768 }
1769
1770
1771 =head2 count_literal
1772
1773 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1774 should only be used in that context. See L</search_literal> for further info.
1775
1776 =over 4
1777
1778 =item Arguments: $sql_fragment, @standalone_bind_values
1779
1780 =item Return Value: $count
1781
1782 =back
1783
1784 Counts the results in a literal query. Equivalent to calling L</search_literal>
1785 with the passed arguments, then L</count>.
1786
1787 =cut
1788
1789 sub count_literal { shift->search_literal(@_)->count; }
1790
1791 =head2 all
1792
1793 =over 4
1794
1795 =item Arguments: none
1796
1797 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1798
1799 =back
1800
1801 Returns all elements in the resultset.
1802
1803 =cut
1804
1805 sub all {
1806   my $self = shift;
1807   if(@_) {
1808     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1809   }
1810
1811   delete @{$self}{qw/_stashed_rows _stashed_results/};
1812
1813   if (my $c = $self->get_cache) {
1814     return @$c;
1815   }
1816
1817   $self->cursor->reset;
1818
1819   my $objs = $self->_construct_results('fetch_all') || [];
1820
1821   $self->set_cache($objs) if $self->{attrs}{cache};
1822
1823   return @$objs;
1824 }
1825
1826 =head2 reset
1827
1828 =over 4
1829
1830 =item Arguments: none
1831
1832 =item Return Value: $self
1833
1834 =back
1835
1836 Resets the resultset's cursor, so you can iterate through the elements again.
1837 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1838 another query.
1839
1840 =cut
1841
1842 sub reset {
1843   my ($self) = @_;
1844
1845   delete @{$self}{qw/_stashed_rows _stashed_results/};
1846   $self->{all_cache_position} = 0;
1847   $self->cursor->reset;
1848   return $self;
1849 }
1850
1851 =head2 first
1852
1853 =over 4
1854
1855 =item Arguments: none
1856
1857 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1858
1859 =back
1860
1861 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1862 an object for the first result (or C<undef> if the resultset is empty).
1863
1864 =cut
1865
1866 sub first {
1867   return $_[0]->reset->next;
1868 }
1869
1870
1871 # _rs_update_delete
1872 #
1873 # Determines whether and what type of subquery is required for the $rs operation.
1874 # If grouping is necessary either supplies its own, or verifies the current one
1875 # After all is done delegates to the proper storage method.
1876
1877 sub _rs_update_delete {
1878   my ($self, $op, $values) = @_;
1879
1880   my $rsrc = $self->result_source;
1881   my $storage = $rsrc->schema->storage;
1882
1883   my $attrs = { %{$self->_resolved_attrs} };
1884
1885   my $join_classifications;
1886   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1887
1888   # do we need a subquery for any reason?
1889   my $needs_subq = (
1890     defined $existing_group_by
1891       or
1892     # if {from} is unparseable wrap a subq
1893     ref($attrs->{from}) ne 'ARRAY'
1894       or
1895     # limits call for a subq
1896     $self->_has_resolved_attr(qw/rows offset/)
1897   );
1898
1899   # simplify the joinmap, so we can further decide if a subq is necessary
1900   if (!$needs_subq and @{$attrs->{from}} > 1) {
1901
1902     ($attrs->{from}, $join_classifications) =
1903       $storage->_prune_unused_joins ($attrs);
1904
1905     # any non-pruneable non-local restricting joins imply subq
1906     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1907   }
1908
1909   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1910   $needs_subq ||= (
1911     (ref $attrs->{from}[0]) ne 'HASH'
1912       or
1913     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1914   );
1915
1916   my ($cond, $guard);
1917   # do we need anything like a subquery?
1918   if (! $needs_subq) {
1919     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1920     # a condition containing 'me' or other table prefixes will not work
1921     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1922     $cond = do {
1923       my $sqla = $rsrc->storage->sql_maker;
1924       local $sqla->{_dequalify_idents} = 1;
1925       \[ $sqla->_recurse_where($self->{cond}) ];
1926     };
1927   }
1928   else {
1929     # we got this far - means it is time to wrap a subquery
1930     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1931       sprintf(
1932         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1933         $op,
1934         $rsrc->source_name,
1935       )
1936     );
1937
1938     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1939     delete $attrs->{$_} for qw/select as collapse/;
1940     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1941
1942     # this will be consumed by the pruner waaaaay down the stack
1943     $attrs->{_force_prune_multiplying_joins} = 1;
1944
1945     my $subrs = (ref $self)->new($rsrc, $attrs);
1946
1947     if (@$idcols == 1) {
1948       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1949     }
1950     elsif ($storage->_use_multicolumn_in) {
1951       # no syntax for calling this properly yet
1952       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1953       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1954         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1955         $subrs->as_query
1956       ),
1957     }
1958     else {
1959       # if all else fails - get all primary keys and operate over a ORed set
1960       # wrap in a transaction for consistency
1961       # this is where the group_by/multiplication starts to matter
1962       if (
1963         $existing_group_by
1964           or
1965         # we do not need to check pre-multipliers, since if the premulti is there, its
1966         # parent (who is multi) will be there too
1967         keys %{ $join_classifications->{multiplying} || {} }
1968       ) {
1969         # make sure if there is a supplied group_by it matches the columns compiled above
1970         # perfectly. Anything else can not be sanely executed on most databases so croak
1971         # right then and there
1972         if ($existing_group_by) {
1973           my @current_group_by = map
1974             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1975             @$existing_group_by
1976           ;
1977
1978           if (
1979             join ("\x00", sort @current_group_by)
1980               ne
1981             join ("\x00", sort @{$attrs->{columns}} )
1982           ) {
1983             $self->throw_exception (
1984               "You have just attempted a $op operation on a resultset which does group_by"
1985               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1986               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1987               . ' kind of queries. Please retry the operation with a modified group_by or'
1988               . ' without using one at all.'
1989             );
1990           }
1991         }
1992
1993         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1994       }
1995
1996       $guard = $storage->txn_scope_guard;
1997
1998       for my $row ($subrs->cursor->all) {
1999         push @$cond, { map
2000           { $idcols->[$_] => $row->[$_] }
2001           (0 .. $#$idcols)
2002         };
2003       }
2004     }
2005   }
2006
2007   my $res = $cond ? $storage->$op (
2008     $rsrc,
2009     $op eq 'update' ? $values : (),
2010     $cond,
2011   ) : '0E0';
2012
2013   $guard->commit if $guard;
2014
2015   return $res;
2016 }
2017
2018 =head2 update
2019
2020 =over 4
2021
2022 =item Arguments: \%values
2023
2024 =item Return Value: $underlying_storage_rv
2025
2026 =back
2027
2028 Sets the specified columns in the resultset to the supplied values in a
2029 single query. Note that this will not run any accessor/set_column/update
2030 triggers, nor will it update any result object instances derived from this
2031 resultset (this includes the contents of the L<resultset cache|/set_cache>
2032 if any). See L</update_all> if you need to execute any on-update
2033 triggers or cascades defined either by you or a
2034 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2035
2036 The return value is a pass through of what the underlying
2037 storage backend returned, and may vary. See L<DBI/execute> for the most
2038 common case.
2039
2040 =head3 CAVEAT
2041
2042 Note that L</update> does not process/deflate any of the values passed in.
2043 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2044 ensure manually that any value passed to this method will stringify to
2045 something the RDBMS knows how to deal with. A notable example is the
2046 handling of L<DateTime> objects, for more info see:
2047 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2048
2049 =cut
2050
2051 sub update {
2052   my ($self, $values) = @_;
2053   $self->throw_exception('Values for update must be a hash')
2054     unless ref $values eq 'HASH';
2055
2056   return $self->_rs_update_delete ('update', $values);
2057 }
2058
2059 =head2 update_all
2060
2061 =over 4
2062
2063 =item Arguments: \%values
2064
2065 =item Return Value: 1
2066
2067 =back
2068
2069 Fetches all objects and updates them one at a time via
2070 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2071 triggers, while L</update> will not.
2072
2073 =cut
2074
2075 sub update_all {
2076   my ($self, $values) = @_;
2077   $self->throw_exception('Values for update_all must be a hash')
2078     unless ref $values eq 'HASH';
2079
2080   my $guard = $self->result_source->schema->txn_scope_guard;
2081   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2082   $guard->commit;
2083   return 1;
2084 }
2085
2086 =head2 delete
2087
2088 =over 4
2089
2090 =item Arguments: none
2091
2092 =item Return Value: $underlying_storage_rv
2093
2094 =back
2095
2096 Deletes the rows matching this resultset in a single query. Note that this
2097 will not run any delete triggers, nor will it alter the
2098 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2099 derived from this resultset (this includes the contents of the
2100 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2101 execute any on-delete triggers or cascades defined either by you or a
2102 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2103
2104 The return value is a pass through of what the underlying storage backend
2105 returned, and may vary. See L<DBI/execute> for the most common case.
2106
2107 =cut
2108
2109 sub delete {
2110   my $self = shift;
2111   $self->throw_exception('delete does not accept any arguments')
2112     if @_;
2113
2114   return $self->_rs_update_delete ('delete');
2115 }
2116
2117 =head2 delete_all
2118
2119 =over 4
2120
2121 =item Arguments: none
2122
2123 =item Return Value: 1
2124
2125 =back
2126
2127 Fetches all objects and deletes them one at a time via
2128 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2129 triggers, while L</delete> will not.
2130
2131 =cut
2132
2133 sub delete_all {
2134   my $self = shift;
2135   $self->throw_exception('delete_all does not accept any arguments')
2136     if @_;
2137
2138   my $guard = $self->result_source->schema->txn_scope_guard;
2139   $_->delete for $self->all;
2140   $guard->commit;
2141   return 1;
2142 }
2143
2144 =head2 populate
2145
2146 =over 4
2147
2148 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2149
2150 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2151
2152 =back
2153
2154 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2155 arrayrefs.
2156
2157 =over
2158
2159 =item NOTE
2160
2161 The context of this method call has an important effect on what is
2162 submitted to storage. In void context data is fed directly to fastpath
2163 insertion routines provided by the underlying storage (most often
2164 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2165 L<insert|DBIx::Class::Row/insert> calls on the
2166 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2167 augmentation of these methods provided by components. For example if you
2168 are using something like L<DBIx::Class::UUIDColumns> to create primary
2169 keys for you, you will find that your PKs are empty.  In this case you
2170 will have to explicitly force scalar or list context in order to create
2171 those values.
2172
2173 =back
2174
2175 In non-void (scalar or list) context, this method is simply a wrapper
2176 for L</create>. Depending on list or scalar context either a list of
2177 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2178 containing these objects is returned.
2179
2180 When supplying data in "arrayref of arrayrefs" invocation style, the
2181 first element should be a list of column names and each subsequent
2182 element should be a data value in the earlier specified column order.
2183 For example:
2184
2185   $schema->resultset("Artist")->populate([
2186     [ qw( artistid name ) ],
2187     [ 100, 'A Formally Unknown Singer' ],
2188     [ 101, 'A singer that jumped the shark two albums ago' ],
2189     [ 102, 'An actually cool singer' ],
2190   ]);
2191
2192 For the arrayref of hashrefs style each hashref should be a structure
2193 suitable for passing to L</create>. Multi-create is also permitted with
2194 this syntax.
2195
2196   $schema->resultset("Artist")->populate([
2197      { artistid => 4, name => 'Manufactured Crap', cds => [
2198         { title => 'My First CD', year => 2006 },
2199         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2200       ],
2201      },
2202      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2203         { title => 'My parents sold me to a record company', year => 2005 },
2204         { title => 'Why Am I So Ugly?', year => 2006 },
2205         { title => 'I Got Surgery and am now Popular', year => 2007 }
2206       ],
2207      },
2208   ]);
2209
2210 If you attempt a void-context multi-create as in the example above (each
2211 Artist also has the related list of CDs), and B<do not> supply the
2212 necessary autoinc foreign key information, this method will proxy to the
2213 less efficient L</create>, and then throw the Result objects away. In this
2214 case there are obviously no benefits to using this method over L</create>.
2215
2216 =cut
2217
2218 sub populate {
2219   my $self = shift;
2220
2221   # this is naive and just a quick check
2222   # the types will need to be checked more thoroughly when the
2223   # multi-source populate gets added
2224   my $data = (
2225     ref $_[0] eq 'ARRAY'
2226       and
2227     ( @{$_[0]} or return )
2228       and
2229     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2230       and
2231     $_[0]
2232   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2233
2234   # FIXME - no cref handling
2235   # At this point assume either hashes or arrays
2236
2237   if(defined wantarray) {
2238     my (@results, $guard);
2239
2240     if (ref $data->[0] eq 'ARRAY') {
2241       # column names only, nothing to do
2242       return if @$data == 1;
2243
2244       $guard = $self->result_source->schema->storage->txn_scope_guard
2245         if @$data > 2;
2246
2247       @results = map
2248         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2249         @{$data}[1 .. $#$data]
2250       ;
2251     }
2252     else {
2253
2254       $guard = $self->result_source->schema->storage->txn_scope_guard
2255         if @$data > 1;
2256
2257       @results = map { $self->new_result($_)->insert } @$data;
2258     }
2259
2260     $guard->commit if $guard;
2261     return wantarray ? @results : \@results;
2262   }
2263
2264   # we have to deal with *possibly incomplete* related data
2265   # this means we have to walk the data structure twice
2266   # whether we want this or not
2267   # jnap, I hate you ;)
2268   my $rsrc = $self->result_source;
2269   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2270
2271   my ($colinfo, $colnames, $slices_with_rels);
2272   my $data_start = 0;
2273
2274   DATA_SLICE:
2275   for my $i (0 .. $#$data) {
2276
2277     my $current_slice_seen_rel_infos;
2278
2279 ### Determine/Supplement collists
2280 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2281     if( ref $data->[$i] eq 'ARRAY' ) {
2282
2283       # positional(!) explicit column list
2284       if ($i == 0) {
2285         # column names only, nothing to do
2286         return if @$data == 1;
2287
2288         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2289           for 0 .. $#{$data->[0]};
2290
2291         $data_start = 1;
2292
2293         next DATA_SLICE;
2294       }
2295       else {
2296         for (values %$colinfo) {
2297           if ($_->{is_rel} ||= (
2298             $rel_info->{$_->{name}}
2299               and
2300             (
2301               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2302                 or
2303               ref $data->[$i][$_->{pos}] eq 'HASH'
2304                 or
2305               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2306             )
2307               and
2308             1
2309           )) {
2310
2311             # moar sanity check... sigh
2312             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2313               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2314                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2315                 return my $throwaway = $self->populate(@_);
2316               }
2317             }
2318
2319             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2320           }
2321         }
2322       }
2323
2324      if ($current_slice_seen_rel_infos) {
2325         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2326
2327         # this is needed further down to decide whether or not to fallback to create()
2328         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2329           for 0 .. $#$colnames;
2330       }
2331     }
2332     elsif( ref $data->[$i] eq 'HASH' ) {
2333
2334       for ( sort keys %{$data->[$i]} ) {
2335
2336         $colinfo->{$_} ||= do {
2337
2338           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2339             if $data_start; # it will be 0 on AoH, 1 on AoA
2340
2341           push @$colnames, $_;
2342
2343           # RV
2344           { pos => $#$colnames, name => $_ }
2345         };
2346
2347         if ($colinfo->{$_}{is_rel} ||= (
2348           $rel_info->{$_}
2349             and
2350           (
2351             ref $data->[$i]{$_} eq 'ARRAY'
2352               or
2353             ref $data->[$i]{$_} eq 'HASH'
2354               or
2355             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2356           )
2357             and
2358           1
2359         )) {
2360
2361           # moar sanity check... sigh
2362           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2363             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2364               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2365               return my $throwaway = $self->populate(@_);
2366             }
2367           }
2368
2369           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2370         }
2371       }
2372
2373       if ($current_slice_seen_rel_infos) {
2374         push @$slices_with_rels, $data->[$i];
2375
2376         # this is needed further down to decide whether or not to fallback to create()
2377         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2378           for keys %{$data->[$i]};
2379       }
2380     }
2381     else {
2382       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2383     }
2384
2385     if ( grep
2386       { $_->{attrs}{is_depends_on} }
2387       @{ $current_slice_seen_rel_infos || [] }
2388     ) {
2389       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2390       return my $throwaway = $self->populate(@_);
2391     }
2392   }
2393
2394   if( $slices_with_rels ) {
2395
2396     # need to exclude the rel "columns"
2397     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2398
2399     # extra sanity check - ensure the main source is in fact identifiable
2400     # the localizing of nullability is insane, but oh well... the use-case is legit
2401     my $ci = $rsrc->columns_info($colnames);
2402
2403     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2404       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2405
2406     unless( $rsrc->_identifying_column_set($ci) ) {
2407       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2408       return my $throwaway = $self->populate(@_);
2409     }
2410   }
2411
2412 ### inherit the data locked in the conditions of the resultset
2413   my ($rs_data) = $self->_merge_with_rscond({});
2414   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2415
2416   # if anything left - decompose rs_data
2417   my $rs_data_vals;
2418   if (keys %$rs_data) {
2419      push @$rs_data_vals, $rs_data->{$_}
2420       for sort keys %$rs_data;
2421   }
2422
2423 ### start work
2424   my $guard;
2425   $guard = $rsrc->schema->storage->txn_scope_guard
2426     if $slices_with_rels;
2427
2428 ### main source data
2429   # FIXME - need to switch entirely to a coderef-based thing,
2430   # so that large sets aren't copied several times... I think
2431   $rsrc->storage->_insert_bulk(
2432     $rsrc,
2433     [ @$colnames, sort keys %$rs_data ],
2434     [ map {
2435       ref $data->[$_] eq 'ARRAY'
2436       ? (
2437           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2438         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2439         :                     $data->[$_]
2440       )
2441       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2442     } $data_start .. $#$data ],
2443   );
2444
2445 ### do the children relationships
2446   if ( $slices_with_rels ) {
2447     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2448       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2449
2450     for my $sl (@$slices_with_rels) {
2451
2452       my ($main_proto, $main_proto_rs);
2453       for my $rel (@rels) {
2454         next unless defined $sl->{$rel};
2455
2456         $main_proto ||= {
2457           %$rs_data,
2458           (map { $_ => $sl->{$_} } @$colnames),
2459         };
2460
2461         unless (defined $colinfo->{$rel}{rs}) {
2462
2463           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2464
2465           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2466             rel_name => $rel,
2467             self_alias => "\xFE", # irrelevant
2468             foreign_alias => "\xFF", # irrelevant
2469           )->{identity_map} || {} } };
2470
2471         }
2472
2473         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2474           {
2475             $_ => { '=' =>
2476               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2477                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2478                  ->as_query
2479             }
2480           }
2481           keys %{$colinfo->{$rel}{fk_map}}
2482         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2483
2484         1;
2485       }
2486     }
2487   }
2488
2489   $guard->commit if $guard;
2490 }
2491
2492 =head2 pager
2493
2494 =over 4
2495
2496 =item Arguments: none
2497
2498 =item Return Value: L<$pager|Data::Page>
2499
2500 =back
2501
2502 Returns a L<Data::Page> object for the current resultset. Only makes
2503 sense for queries with a C<page> attribute.
2504
2505 To get the full count of entries for a paged resultset, call
2506 C<total_entries> on the L<Data::Page> object.
2507
2508 =cut
2509
2510 sub pager {
2511   my ($self) = @_;
2512
2513   return $self->{pager} if $self->{pager};
2514
2515   my $attrs = $self->{attrs};
2516   if (!defined $attrs->{page}) {
2517     $self->throw_exception("Can't create pager for non-paged rs");
2518   }
2519   elsif ($attrs->{page} <= 0) {
2520     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2521   }
2522   $attrs->{rows} ||= 10;
2523
2524   # throw away the paging flags and re-run the count (possibly
2525   # with a subselect) to get the real total count
2526   my $count_attrs = { %$attrs };
2527   delete @{$count_attrs}{qw/rows offset page pager/};
2528
2529   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2530
2531   require DBIx::Class::ResultSet::Pager;
2532   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2533     sub { $total_rs->count },  #lazy-get the total
2534     $attrs->{rows},
2535     $self->{attrs}{page},
2536   );
2537 }
2538
2539 =head2 page
2540
2541 =over 4
2542
2543 =item Arguments: $page_number
2544
2545 =item Return Value: L<$resultset|/search>
2546
2547 =back
2548
2549 Returns a resultset for the $page_number page of the resultset on which page
2550 is called, where each page contains a number of rows equal to the 'rows'
2551 attribute set on the resultset (10 by default).
2552
2553 =cut
2554
2555 sub page {
2556   my ($self, $page) = @_;
2557   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2558 }
2559
2560 =head2 new_result
2561
2562 =over 4
2563
2564 =item Arguments: \%col_data
2565
2566 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2567
2568 =back
2569
2570 Creates a new result object in the resultset's result class and returns
2571 it. The row is not inserted into the database at this point, call
2572 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2573 will tell you whether the result object has been inserted or not.
2574
2575 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2576
2577 =cut
2578
2579 sub new_result {
2580   my ($self, $values) = @_;
2581
2582   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2583     if @_ > 2;
2584
2585   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2586     unless (ref $values eq 'HASH');
2587
2588   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2589
2590   my $new = $self->result_class->new({
2591     %$merged_cond,
2592     ( @$cols_from_relations
2593       ? (-cols_from_relations => $cols_from_relations)
2594       : ()
2595     ),
2596     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2597   });
2598
2599   if (
2600     reftype($new) eq 'HASH'
2601       and
2602     ! keys %$new
2603       and
2604     blessed($new)
2605   ) {
2606     carp_unique (sprintf (
2607       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2608       $self->result_class,
2609     ));
2610   }
2611
2612   $new;
2613 }
2614
2615 # _merge_with_rscond
2616 #
2617 # Takes a simple hash of K/V data and returns its copy merged with the
2618 # condition already present on the resultset. Additionally returns an
2619 # arrayref of value/condition names, which were inferred from related
2620 # objects (this is needed for in-memory related objects)
2621 sub _merge_with_rscond {
2622   my ($self, $data) = @_;
2623
2624   my ($implied_data, @cols_from_relations);
2625
2626   my $alias = $self->{attrs}{alias};
2627
2628   if (! defined $self->{cond}) {
2629     # just massage $data below
2630   }
2631   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2632     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2633     @cols_from_relations = keys %{ $implied_data || {} };
2634   }
2635   else {
2636     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2637     $implied_data = { map {
2638       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2639     } keys %$eqs };
2640   }
2641
2642   return (
2643     { map
2644       { %{ $self->_remove_alias($_, $alias) } }
2645       # precedence must be given to passed values over values inherited from
2646       # the cond, so the order here is important.
2647       ( $implied_data||(), $data)
2648     },
2649     \@cols_from_relations
2650   );
2651 }
2652
2653 # _has_resolved_attr
2654 #
2655 # determines if the resultset defines at least one
2656 # of the attributes supplied
2657 #
2658 # used to determine if a subquery is necessary
2659 #
2660 # supports some virtual attributes:
2661 #   -join
2662 #     This will scan for any joins being present on the resultset.
2663 #     It is not a mere key-search but a deep inspection of {from}
2664 #
2665
2666 sub _has_resolved_attr {
2667   my ($self, @attr_names) = @_;
2668
2669   my $attrs = $self->_resolved_attrs;
2670
2671   my %extra_checks;
2672
2673   for my $n (@attr_names) {
2674     if (grep { $n eq $_ } (qw/-join/) ) {
2675       $extra_checks{$n}++;
2676       next;
2677     }
2678
2679     my $attr =  $attrs->{$n};
2680
2681     next if not defined $attr;
2682
2683     if (ref $attr eq 'HASH') {
2684       return 1 if keys %$attr;
2685     }
2686     elsif (ref $attr eq 'ARRAY') {
2687       return 1 if @$attr;
2688     }
2689     else {
2690       return 1 if $attr;
2691     }
2692   }
2693
2694   # a resolved join is expressed as a multi-level from
2695   return 1 if (
2696     $extra_checks{-join}
2697       and
2698     ref $attrs->{from} eq 'ARRAY'
2699       and
2700     @{$attrs->{from}} > 1
2701   );
2702
2703   return 0;
2704 }
2705
2706 # _remove_alias
2707 #
2708 # Remove the specified alias from the specified query hash. A copy is made so
2709 # the original query is not modified.
2710
2711 sub _remove_alias {
2712   my ($self, $query, $alias) = @_;
2713
2714   my %orig = %{ $query || {} };
2715   my %unaliased;
2716
2717   foreach my $key (keys %orig) {
2718     if ($key !~ /\./) {
2719       $unaliased{$key} = $orig{$key};
2720       next;
2721     }
2722     $unaliased{$1} = $orig{$key}
2723       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2724   }
2725
2726   return \%unaliased;
2727 }
2728
2729 =head2 as_query
2730
2731 =over 4
2732
2733 =item Arguments: none
2734
2735 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2736
2737 =back
2738
2739 Returns the SQL query and bind vars associated with the invocant.
2740
2741 This is generally used as the RHS for a subquery.
2742
2743 =cut
2744
2745 sub as_query {
2746   my $self = shift;
2747
2748   my $attrs = { %{ $self->_resolved_attrs } };
2749
2750   my $aq = $self->result_source->storage->_select_args_to_query (
2751     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2752   );
2753
2754   $aq;
2755 }
2756
2757 =head2 find_or_new
2758
2759 =over 4
2760
2761 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2762
2763 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2764
2765 =back
2766
2767   my $artist = $schema->resultset('Artist')->find_or_new(
2768     { artist => 'fred' }, { key => 'artists' });
2769
2770   $cd->cd_to_producer->find_or_new({ producer => $producer },
2771                                    { key => 'primary' });
2772
2773 Find an existing record from this resultset using L</find>. if none exists,
2774 instantiate a new result object and return it. The object will not be saved
2775 into your storage until you call L<DBIx::Class::Row/insert> on it.
2776
2777 You most likely want this method when looking for existing rows using a unique
2778 constraint that is not the primary key, or looking for related rows.
2779
2780 If you want objects to be saved immediately, use L</find_or_create> instead.
2781
2782 B<Note>: Make sure to read the documentation of L</find> and understand the
2783 significance of the C<key> attribute, as its lack may skew your search, and
2784 subsequently result in spurious new objects.
2785
2786 B<Note>: Take care when using C<find_or_new> with a table having
2787 columns with default values that you intend to be automatically
2788 supplied by the database (e.g. an auto_increment primary key column).
2789 In normal usage, the value of such columns should NOT be included at
2790 all in the call to C<find_or_new>, even when set to C<undef>.
2791
2792 =cut
2793
2794 sub find_or_new {
2795   my $self     = shift;
2796   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2797   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2798   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2799     return $row;
2800   }
2801   return $self->new_result($hash);
2802 }
2803
2804 =head2 create
2805
2806 =over 4
2807
2808 =item Arguments: \%col_data
2809
2810 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2811
2812 =back
2813
2814 Attempt to create a single new row or a row with multiple related rows
2815 in the table represented by the resultset (and related tables). This
2816 will not check for duplicate rows before inserting, use
2817 L</find_or_create> to do that.
2818
2819 To create one row for this resultset, pass a hashref of key/value
2820 pairs representing the columns of the table and the values you wish to
2821 store. If the appropriate relationships are set up, foreign key fields
2822 can also be passed an object representing the foreign row, and the
2823 value will be set to its primary key.
2824
2825 To create related objects, pass a hashref of related-object column values
2826 B<keyed on the relationship name>. If the relationship is of type C<multi>
2827 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2828 The process will correctly identify columns holding foreign keys, and will
2829 transparently populate them from the keys of the corresponding relation.
2830 This can be applied recursively, and will work correctly for a structure
2831 with an arbitrary depth and width, as long as the relationships actually
2832 exists and the correct column data has been supplied.
2833
2834 Instead of hashrefs of plain related data (key/value pairs), you may
2835 also pass new or inserted objects. New objects (not inserted yet, see
2836 L</new_result>), will be inserted into their appropriate tables.
2837
2838 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2839
2840 Example of creating a new row.
2841
2842   $person_rs->create({
2843     name=>"Some Person",
2844     email=>"somebody@someplace.com"
2845   });
2846
2847 Example of creating a new row and also creating rows in a related C<has_many>
2848 or C<has_one> resultset.  Note Arrayref.
2849
2850   $artist_rs->create(
2851      { artistid => 4, name => 'Manufactured Crap', cds => [
2852         { title => 'My First CD', year => 2006 },
2853         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2854       ],
2855      },
2856   );
2857
2858 Example of creating a new row and also creating a row in a related
2859 C<belongs_to> resultset. Note Hashref.
2860
2861   $cd_rs->create({
2862     title=>"Music for Silly Walks",
2863     year=>2000,
2864     artist => {
2865       name=>"Silly Musician",
2866     }
2867   });
2868
2869 =over
2870
2871 =item WARNING
2872
2873 When subclassing ResultSet never attempt to override this method. Since
2874 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2875 lot of the internals simply never call it, so your override will be
2876 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2877 or L<DBIx::Class::Row/insert> depending on how early in the
2878 L</create> process you need to intervene. See also warning pertaining to
2879 L</new>.
2880
2881 =back
2882
2883 =cut
2884
2885 sub create {
2886   #my ($self, $col_data) = @_;
2887   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2888   return shift->new_result(shift)->insert;
2889 }
2890
2891 =head2 find_or_create
2892
2893 =over 4
2894
2895 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2896
2897 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2898
2899 =back
2900
2901   $cd->cd_to_producer->find_or_create({ producer => $producer },
2902                                       { key => 'primary' });
2903
2904 Tries to find a record based on its primary key or unique constraints; if none
2905 is found, creates one and returns that instead.
2906
2907   my $cd = $schema->resultset('CD')->find_or_create({
2908     cdid   => 5,
2909     artist => 'Massive Attack',
2910     title  => 'Mezzanine',
2911     year   => 2005,
2912   });
2913
2914 Also takes an optional C<key> attribute, to search by a specific key or unique
2915 constraint. For example:
2916
2917   my $cd = $schema->resultset('CD')->find_or_create(
2918     {
2919       artist => 'Massive Attack',
2920       title  => 'Mezzanine',
2921     },
2922     { key => 'cd_artist_title' }
2923   );
2924
2925 B<Note>: Make sure to read the documentation of L</find> and understand the
2926 significance of the C<key> attribute, as its lack may skew your search, and
2927 subsequently result in spurious row creation.
2928
2929 B<Note>: Because find_or_create() reads from the database and then
2930 possibly inserts based on the result, this method is subject to a race
2931 condition. Another process could create a record in the table after
2932 the find has completed and before the create has started. To avoid
2933 this problem, use find_or_create() inside a transaction.
2934
2935 B<Note>: Take care when using C<find_or_create> with a table having
2936 columns with default values that you intend to be automatically
2937 supplied by the database (e.g. an auto_increment primary key column).
2938 In normal usage, the value of such columns should NOT be included at
2939 all in the call to C<find_or_create>, even when set to C<undef>.
2940
2941 See also L</find> and L</update_or_create>. For information on how to declare
2942 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2943
2944 If you need to know if an existing row was found or a new one created use
2945 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2946 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2947 database!
2948
2949   my $cd = $schema->resultset('CD')->find_or_new({
2950     cdid   => 5,
2951     artist => 'Massive Attack',
2952     title  => 'Mezzanine',
2953     year   => 2005,
2954   });
2955
2956   if( !$cd->in_storage ) {
2957       # do some stuff
2958       $cd->insert;
2959   }
2960
2961 =cut
2962
2963 sub find_or_create {
2964   my $self     = shift;
2965   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2966   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2967   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2968     return $row;
2969   }
2970   return $self->new_result($hash)->insert;
2971 }
2972
2973 =head2 update_or_create
2974
2975 =over 4
2976
2977 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2978
2979 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2980
2981 =back
2982
2983   $resultset->update_or_create({ col => $val, ... });
2984
2985 Like L</find_or_create>, but if a row is found it is immediately updated via
2986 C<< $found_row->update (\%col_data) >>.
2987
2988
2989 Takes an optional C<key> attribute to search on a specific unique constraint.
2990 For example:
2991
2992   # In your application
2993   my $cd = $schema->resultset('CD')->update_or_create(
2994     {
2995       artist => 'Massive Attack',
2996       title  => 'Mezzanine',
2997       year   => 1998,
2998     },
2999     { key => 'cd_artist_title' }
3000   );
3001
3002   $cd->cd_to_producer->update_or_create({
3003     producer => $producer,
3004     name => 'harry',
3005   }, {
3006     key => 'primary',
3007   });
3008
3009 B<Note>: Make sure to read the documentation of L</find> and understand the
3010 significance of the C<key> attribute, as its lack may skew your search, and
3011 subsequently result in spurious row creation.
3012
3013 B<Note>: Take care when using C<update_or_create> with a table having
3014 columns with default values that you intend to be automatically
3015 supplied by the database (e.g. an auto_increment primary key column).
3016 In normal usage, the value of such columns should NOT be included at
3017 all in the call to C<update_or_create>, even when set to C<undef>.
3018
3019 See also L</find> and L</find_or_create>. For information on how to declare
3020 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3021
3022 If you need to know if an existing row was updated or a new one created use
3023 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3024 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3025 database!
3026
3027 =cut
3028
3029 sub update_or_create {
3030   my $self = shift;
3031   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3032   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3033
3034   my $row = $self->find($cond, $attrs);
3035   if (defined $row) {
3036     $row->update($cond);
3037     return $row;
3038   }
3039
3040   return $self->new_result($cond)->insert;
3041 }
3042
3043 =head2 update_or_new
3044
3045 =over 4
3046
3047 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3048
3049 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3050
3051 =back
3052
3053   $resultset->update_or_new({ col => $val, ... });
3054
3055 Like L</find_or_new> but if a row is found it is immediately updated via
3056 C<< $found_row->update (\%col_data) >>.
3057
3058 For example:
3059
3060   # In your application
3061   my $cd = $schema->resultset('CD')->update_or_new(
3062     {
3063       artist => 'Massive Attack',
3064       title  => 'Mezzanine',
3065       year   => 1998,
3066     },
3067     { key => 'cd_artist_title' }
3068   );
3069
3070   if ($cd->in_storage) {
3071       # the cd was updated
3072   }
3073   else {
3074       # the cd is not yet in the database, let's insert it
3075       $cd->insert;
3076   }
3077
3078 B<Note>: Make sure to read the documentation of L</find> and understand the
3079 significance of the C<key> attribute, as its lack may skew your search, and
3080 subsequently result in spurious new objects.
3081
3082 B<Note>: Take care when using C<update_or_new> with a table having
3083 columns with default values that you intend to be automatically
3084 supplied by the database (e.g. an auto_increment primary key column).
3085 In normal usage, the value of such columns should NOT be included at
3086 all in the call to C<update_or_new>, even when set to C<undef>.
3087
3088 See also L</find>, L</find_or_create> and L</find_or_new>.
3089
3090 =cut
3091
3092 sub update_or_new {
3093     my $self  = shift;
3094     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3095     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3096
3097     my $row = $self->find( $cond, $attrs );
3098     if ( defined $row ) {
3099         $row->update($cond);
3100         return $row;
3101     }
3102
3103     return $self->new_result($cond);
3104 }
3105
3106 =head2 get_cache
3107
3108 =over 4
3109
3110 =item Arguments: none
3111
3112 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3113
3114 =back
3115
3116 Gets the contents of the cache for the resultset, if the cache is set.
3117
3118 The cache is populated either by using the L</prefetch> attribute to
3119 L</search> or by calling L</set_cache>.
3120
3121 =cut
3122
3123 sub get_cache {
3124   shift->{all_cache};
3125 }
3126
3127 =head2 set_cache
3128
3129 =over 4
3130
3131 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3132
3133 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3134
3135 =back
3136
3137 Sets the contents of the cache for the resultset. Expects an arrayref
3138 of objects of the same class as those produced by the resultset. Note that
3139 if the cache is set, the resultset will return the cached objects rather
3140 than re-querying the database even if the cache attr is not set.
3141
3142 The contents of the cache can also be populated by using the
3143 L</prefetch> attribute to L</search>.
3144
3145 =cut
3146
3147 sub set_cache {
3148   my ( $self, $data ) = @_;
3149   $self->throw_exception("set_cache requires an arrayref")
3150       if defined($data) && (ref $data ne 'ARRAY');
3151   $self->{all_cache} = $data;
3152 }
3153
3154 =head2 clear_cache
3155
3156 =over 4
3157
3158 =item Arguments: none
3159
3160 =item Return Value: undef
3161
3162 =back
3163
3164 Clears the cache for the resultset.
3165
3166 =cut
3167
3168 sub clear_cache {
3169   shift->set_cache(undef);
3170 }
3171
3172 =head2 is_paged
3173
3174 =over 4
3175
3176 =item Arguments: none
3177
3178 =item Return Value: true, if the resultset has been paginated
3179
3180 =back
3181
3182 =cut
3183
3184 sub is_paged {
3185   my ($self) = @_;
3186   return !!$self->{attrs}{page};
3187 }
3188
3189 =head2 is_ordered
3190
3191 =over 4
3192
3193 =item Arguments: none
3194
3195 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3196
3197 =back
3198
3199 =cut
3200
3201 sub is_ordered {
3202   my ($self) = @_;
3203   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3204 }
3205
3206 =head2 related_resultset
3207
3208 =over 4
3209
3210 =item Arguments: $rel_name
3211
3212 =item Return Value: L<$resultset|/search>
3213
3214 =back
3215
3216 Returns a related resultset for the supplied relationship name.
3217
3218   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3219
3220 =cut
3221
3222 sub related_resultset {
3223   $_[0]->throw_exception(
3224     'Extra arguments to $rs->related_resultset() were always quietly '
3225   . 'discarded without consideration, you need to switch to '
3226   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3227   ) if @_ > 2;
3228
3229   return $_[0]->{related_resultsets}{$_[1]}
3230     if defined $_[0]->{related_resultsets}{$_[1]};
3231
3232   my ($self, $rel) = @_;
3233
3234   return $self->{related_resultsets}{$rel} = do {
3235     my $rsrc = $self->result_source;
3236     my $rel_info = $rsrc->relationship_info($rel);
3237
3238     $self->throw_exception(
3239       "search_related: result source '" . $rsrc->source_name .
3240         "' has no such relationship $rel")
3241       unless $rel_info;
3242
3243     my $attrs = $self->_chain_relationship($rel);
3244
3245     my $storage = $rsrc->schema->storage;
3246
3247     # Previously this atribute was deleted (instead of being set as it is now)
3248     # Doing so seems to be harmless in all available test permutations
3249     # See also 01d59a6a6 and mst's comment below
3250     #
3251     $attrs->{alias} = $storage->relname_to_table_alias(
3252       $rel,
3253       $attrs->{seen_join}{$rel}
3254     );
3255
3256     # since this is search_related, and we already slid the select window inwards
3257     # (the select/as attrs were deleted in the beginning), we need to flip all
3258     # left joins to inner, so we get the expected results
3259     # read the comment on top of the actual function to see what this does
3260     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3261
3262     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3263     delete $attrs->{result_class};
3264
3265     my $new = do {
3266
3267       # The reason we do this now instead of passing the alias to the
3268       # search_rs below is that if you wrap/overload resultset on the
3269       # source you need to know what alias it's -going- to have for things
3270       # to work sanely (e.g. RestrictWithObject wants to be able to add
3271       # extra query restrictions, and these may need to be $alias.)
3272       #                                       -- mst ~ 2007 (01d59a6a6)
3273       #
3274       # FIXME - this seems to be no longer neccessary (perhaps due to the
3275       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3276       # dependent (as of Jun 2015 ) does not yield any difference with or
3277       # without this line. Nevertheless keep it as is for now, to minimize
3278       # churn, there is enough potential for breakage in 0.0829xx as it is
3279       #                                       -- ribasushi Jun 2015
3280       #
3281       my $rel_source = $rsrc->related_source($rel);
3282       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3283
3284       $rel_source->resultset->search_rs( undef, $attrs );
3285     };
3286
3287     if (my $cache = $self->get_cache) {
3288       my @related_cache = map
3289         { $_->related_resultset($rel)->get_cache || () }
3290         @$cache
3291       ;
3292
3293       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3294     }
3295
3296     $new;
3297   };
3298 }
3299
3300 =head2 current_source_alias
3301
3302 =over 4
3303
3304 =item Arguments: none
3305
3306 =item Return Value: $source_alias
3307
3308 =back
3309
3310 Returns the current table alias for the result source this resultset is built
3311 on, that will be used in the SQL query. Usually it is C<me>.
3312
3313 Currently the source alias that refers to the result set returned by a
3314 L</search>/L</find> family method depends on how you got to the resultset: it's
3315 C<me> by default, but eg. L</search_related> aliases it to the related result
3316 source name (and keeps C<me> referring to the original result set). The long
3317 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3318 (and make this method unnecessary).
3319
3320 Thus it's currently necessary to use this method in predefined queries (see
3321 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3322 source alias of the current result set:
3323
3324   # in a result set class
3325   sub modified_by {
3326     my ($self, $user) = @_;
3327
3328     my $me = $self->current_source_alias;
3329
3330     return $self->search({
3331       "$me.modified" => $user->id,
3332     });
3333   }
3334
3335 The alias of L<newly created resultsets|/search> can be altered by the
3336 L<alias attribute|/alias>.
3337
3338 =cut
3339
3340 sub current_source_alias {
3341   return (shift->{attrs} || {})->{alias} || 'me';
3342 }
3343
3344 =head2 as_subselect_rs
3345
3346 =over 4
3347
3348 =item Arguments: none
3349
3350 =item Return Value: L<$resultset|/search>
3351
3352 =back
3353
3354 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3355 "virtual view" by including it as a subquery within the from clause.  From this
3356 point on, any joined tables are inaccessible to ->search on the resultset (as if
3357 it were simply where-filtered without joins).  For example:
3358
3359  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3360
3361  # 'x' now pollutes the query namespace
3362
3363  # So the following works as expected
3364  my $ok_rs = $rs->search({'x.other' => 1});
3365
3366  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3367  # def) we look for one row with contradictory terms and join in another table
3368  # (aliased 'x_2') which we never use
3369  my $broken_rs = $rs->search({'x.name' => 'def'});
3370
3371  my $rs2 = $rs->as_subselect_rs;
3372
3373  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3374  my $not_joined_rs = $rs2->search({'x.other' => 1});
3375
3376  # works as expected: finds a 'table' row related to two x rows (abc and def)
3377  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3378
3379 Another example of when one might use this would be to select a subset of
3380 columns in a group by clause:
3381
3382  my $rs = $schema->resultset('Bar')->search(undef, {
3383    group_by => [qw{ id foo_id baz_id }],
3384  })->as_subselect_rs->search(undef, {
3385    columns => [qw{ id foo_id }]
3386  });
3387
3388 In the above example normally columns would have to be equal to the group by,
3389 but because we isolated the group by into a subselect the above works.
3390
3391 =cut
3392
3393 sub as_subselect_rs {
3394   my $self = shift;
3395
3396   my $attrs = $self->_resolved_attrs;
3397
3398   my $fresh_rs = (ref $self)->new (
3399     $self->result_source
3400   );
3401
3402   # these pieces will be locked in the subquery
3403   delete $fresh_rs->{cond};
3404   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3405
3406   return $fresh_rs->search( {}, {
3407     from => [{
3408       $attrs->{alias} => $self->as_query,
3409       -alias  => $attrs->{alias},
3410       -rsrc   => $self->result_source,
3411     }],
3412     alias => $attrs->{alias},
3413   });
3414 }
3415
3416 # This code is called by search_related, and makes sure there
3417 # is clear separation between the joins before, during, and
3418 # after the relationship. This information is needed later
3419 # in order to properly resolve prefetch aliases (any alias
3420 # with a relation_chain_depth less than the depth of the
3421 # current prefetch is not considered)
3422 #
3423 # The increments happen twice per join. An even number means a
3424 # relationship specified via a search_related, whereas an odd
3425 # number indicates a join/prefetch added via attributes
3426 #
3427 # Also this code will wrap the current resultset (the one we
3428 # chain to) in a subselect IFF it contains limiting attributes
3429 sub _chain_relationship {
3430   my ($self, $rel) = @_;
3431   my $source = $self->result_source;
3432   my $attrs = { %{$self->{attrs}||{}} };
3433
3434   # we need to take the prefetch the attrs into account before we
3435   # ->_resolve_join as otherwise they get lost - captainL
3436   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3437
3438   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3439
3440   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3441
3442   my $from;
3443   my @force_subq_attrs = qw/offset rows group_by having/;
3444
3445   if (
3446     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3447       ||
3448     $self->_has_resolved_attr (@force_subq_attrs)
3449   ) {
3450     # Nuke the prefetch (if any) before the new $rs attrs
3451     # are resolved (prefetch is useless - we are wrapping
3452     # a subquery anyway).
3453     my $rs_copy = $self->search;
3454     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3455       $rs_copy->{attrs}{join},
3456       delete $rs_copy->{attrs}{prefetch},
3457     );
3458
3459     $from = [{
3460       -rsrc   => $source,
3461       -alias  => $attrs->{alias},
3462       $attrs->{alias} => $rs_copy->as_query,
3463     }];
3464     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3465     $seen->{-relation_chain_depth} = 0;
3466   }
3467   elsif ($attrs->{from}) {  #shallow copy suffices
3468     $from = [ @{$attrs->{from}} ];
3469   }
3470   else {
3471     $from = [{
3472       -rsrc  => $source,
3473       -alias => $attrs->{alias},
3474       $attrs->{alias} => $source->from,
3475     }];
3476   }
3477
3478   my $jpath = ($seen->{-relation_chain_depth})
3479     ? $from->[-1][0]{-join_path}
3480     : [];
3481
3482   my @requested_joins = $source->_resolve_join(
3483     $join,
3484     $attrs->{alias},
3485     $seen,
3486     $jpath,
3487   );
3488
3489   push @$from, @requested_joins;
3490
3491   $seen->{-relation_chain_depth}++;
3492
3493   # if $self already had a join/prefetch specified on it, the requested
3494   # $rel might very well be already included. What we do in this case
3495   # is effectively a no-op (except that we bump up the chain_depth on
3496   # the join in question so we could tell it *is* the search_related)
3497   my $already_joined;
3498
3499   # we consider the last one thus reverse
3500   for my $j (reverse @requested_joins) {
3501     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3502     if ($rel eq $last_j) {
3503       $j->[0]{-relation_chain_depth}++;
3504       $already_joined++;
3505       last;
3506     }
3507   }
3508
3509   unless ($already_joined) {
3510     push @$from, $source->_resolve_join(
3511       $rel,
3512       $attrs->{alias},
3513       $seen,
3514       $jpath,
3515     );
3516   }
3517
3518   $seen->{-relation_chain_depth}++;
3519
3520   return {%$attrs, from => $from, seen_join => $seen};
3521 }
3522
3523 sub _resolved_attrs {
3524   my $self = shift;
3525   return $self->{_attrs} if $self->{_attrs};
3526
3527   my $attrs  = { %{ $self->{attrs} || {} } };
3528   my $source = $attrs->{result_source} = $self->result_source;
3529   my $alias  = $attrs->{alias};
3530
3531   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3532     if $attrs->{collapse} and $attrs->{distinct};
3533
3534
3535   # Sanity check the paging attributes
3536   # SQLMaker does it too, but in case of a software_limit we'll never get there
3537   if (defined $attrs->{offset}) {
3538     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3539       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3540   }
3541   if (defined $attrs->{rows}) {
3542     $self->throw_exception("The rows attribute must be a positive integer if present")
3543       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3544   }
3545
3546
3547   # default selection list
3548   $attrs->{columns} = [ $source->columns ]
3549     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3550
3551   # merge selectors together
3552   for (qw/columns select as/) {
3553     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3554       if $attrs->{$_} or $attrs->{"+$_"};
3555   }
3556
3557   # disassemble columns
3558   my (@sel, @as);
3559   if (my $cols = delete $attrs->{columns}) {
3560     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3561       if (ref $c eq 'HASH') {
3562         for my $as (sort keys %$c) {
3563           push @sel, $c->{$as};
3564           push @as, $as;
3565         }
3566       }
3567       else {
3568         push @sel, $c;
3569         push @as, $c;
3570       }
3571     }
3572   }
3573
3574   # when trying to weed off duplicates later do not go past this point -
3575   # everything added from here on is unbalanced "anyone's guess" stuff
3576   my $dedup_stop_idx = $#as;
3577
3578   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3579     if $attrs->{as};
3580   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3581     if $attrs->{select};
3582
3583   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3584   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3585
3586   # disqualify all $alias.col as-bits (inflate-map mandated)
3587   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3588
3589   # de-duplicate the result (remove *identical* select/as pairs)
3590   # and also die on duplicate {as} pointing to different {select}s
3591   # not using a c-style for as the condition is prone to shrinkage
3592   my $seen;
3593   my $i = 0;
3594   while ($i <= $dedup_stop_idx) {
3595     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3596       splice @sel, $i, 1;
3597       splice @as, $i, 1;
3598       $dedup_stop_idx--;
3599     }
3600     elsif ($seen->{$as[$i]}++) {
3601       $self->throw_exception(
3602         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3603       );
3604     }
3605     else {
3606       $i++;
3607     }
3608   }
3609
3610   $attrs->{select} = \@sel;
3611   $attrs->{as} = \@as;
3612
3613   $attrs->{from} ||= [{
3614     -rsrc   => $source,
3615     -alias  => $self->{attrs}{alias},
3616     $self->{attrs}{alias} => $source->from,
3617   }];
3618
3619   if ( $attrs->{join} || $attrs->{prefetch} ) {
3620
3621     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3622       if ref $attrs->{from} ne 'ARRAY';
3623
3624     my $join = (delete $attrs->{join}) || {};
3625
3626     if ( defined $attrs->{prefetch} ) {
3627       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3628     }
3629
3630     $attrs->{from} =    # have to copy here to avoid corrupting the original
3631       [
3632         @{ $attrs->{from} },
3633         $source->_resolve_join(
3634           $join,
3635           $alias,
3636           { %{ $attrs->{seen_join} || {} } },
3637           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3638             ? $attrs->{from}[-1][0]{-join_path}
3639             : []
3640           ,
3641         )
3642       ];
3643   }
3644
3645
3646   for my $attr (qw(order_by group_by)) {
3647
3648     if ( defined $attrs->{$attr} ) {
3649       $attrs->{$attr} = (
3650         ref( $attrs->{$attr} ) eq 'ARRAY'
3651         ? [ @{ $attrs->{$attr} } ]
3652         : [ $attrs->{$attr} || () ]
3653       );
3654
3655       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3656     }
3657   }
3658
3659
3660   # set collapse default based on presence of prefetch
3661   my $prefetch;
3662   if (
3663     defined $attrs->{prefetch}
3664       and
3665     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3666   ) {
3667     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3668       if defined $attrs->{collapse} and ! $attrs->{collapse};
3669
3670     $attrs->{collapse} = 1;
3671   }
3672
3673
3674   # run through the resulting joinstructure (starting from our current slot)
3675   # and unset collapse if proven unnecessary
3676   #
3677   # also while we are at it find out if the current root source has
3678   # been premultiplied by previous related_source chaining
3679   #
3680   # this allows to predict whether a root object with all other relation
3681   # data set to NULL is in fact unique
3682   if ($attrs->{collapse}) {
3683
3684     if (ref $attrs->{from} eq 'ARRAY') {
3685
3686       if (@{$attrs->{from}} == 1) {
3687         # no joins - no collapse
3688         $attrs->{collapse} = 0;
3689       }
3690       else {
3691         # find where our table-spec starts
3692         my @fromlist = @{$attrs->{from}};
3693         while (@fromlist) {
3694           my $t = shift @fromlist;
3695
3696           my $is_multi;
3697           # me vs join from-spec distinction - a ref means non-root
3698           if (ref $t eq 'ARRAY') {
3699             $t = $t->[0];
3700             $is_multi ||= ! $t->{-is_single};
3701           }
3702           last if ($t->{-alias} && $t->{-alias} eq $alias);
3703           $attrs->{_main_source_premultiplied} ||= $is_multi;
3704         }
3705
3706         # no non-singles remaining, nor any premultiplication - nothing to collapse
3707         if (
3708           ! $attrs->{_main_source_premultiplied}
3709             and
3710           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3711         ) {
3712           $attrs->{collapse} = 0;
3713         }
3714       }
3715     }
3716
3717     else {
3718       # if we can not analyze the from - err on the side of safety
3719       $attrs->{_main_source_premultiplied} = 1;
3720     }
3721   }
3722
3723
3724   # generate the distinct induced group_by before injecting the prefetched select/as parts
3725   if (delete $attrs->{distinct}) {
3726     if ($attrs->{group_by}) {
3727       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3728     }
3729     else {
3730       $attrs->{_grouped_by_distinct} = 1;
3731       # distinct affects only the main selection part, not what prefetch may add below
3732       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3733
3734       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3735       # The thinking is: if we are collapsing the subquerying prefetch engine will
3736       # rip stuff apart for us anyway, and we do not want to have a potentially
3737       # function-converted external order_by
3738       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3739       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3740     }
3741   }
3742
3743
3744   # generate selections based on the prefetch helper
3745   if ($prefetch) {
3746
3747     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3748       if $attrs->{_dark_selector};
3749
3750     # this is a separate structure (we don't look in {from} directly)
3751     # as the resolver needs to shift things off the lists to work
3752     # properly (identical-prefetches on different branches)
3753     my $joined_node_aliases_map = {};
3754     if (ref $attrs->{from} eq 'ARRAY') {
3755
3756       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3757
3758       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3759         next unless $j->[0]{-alias};
3760         next unless $j->[0]{-join_path};
3761         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3762
3763         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3764
3765         my $p = $joined_node_aliases_map;
3766         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3767         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3768       }
3769     }
3770
3771     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3772       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3773   }
3774
3775
3776   $attrs->{_simple_passthrough_construction} = !(
3777     $attrs->{collapse}
3778       or
3779     grep { $_ =~ /\./ } @{$attrs->{as}}
3780   );
3781
3782
3783   # if both page and offset are specified, produce a combined offset
3784   # even though it doesn't make much sense, this is what pre 081xx has
3785   # been doing
3786   if (my $page = delete $attrs->{page}) {
3787     $attrs->{offset} =
3788       ($attrs->{rows} * ($page - 1))
3789             +
3790       ($attrs->{offset} || 0)
3791     ;
3792   }
3793
3794   return $self->{_attrs} = $attrs;
3795 }
3796
3797 sub _rollout_attr {
3798   my ($self, $attr) = @_;
3799
3800   if (ref $attr eq 'HASH') {
3801     return $self->_rollout_hash($attr);
3802   } elsif (ref $attr eq 'ARRAY') {
3803     return $self->_rollout_array($attr);
3804   } else {
3805     return [$attr];
3806   }
3807 }
3808
3809 sub _rollout_array {
3810   my ($self, $attr) = @_;
3811
3812   my @rolled_array;
3813   foreach my $element (@{$attr}) {
3814     if (ref $element eq 'HASH') {
3815       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3816     } elsif (ref $element eq 'ARRAY') {
3817       #  XXX - should probably recurse here
3818       push( @rolled_array, @{$self->_rollout_array($element)} );
3819     } else {
3820       push( @rolled_array, $element );
3821     }
3822   }
3823   return \@rolled_array;
3824 }
3825
3826 sub _rollout_hash {
3827   my ($self, $attr) = @_;
3828
3829   my @rolled_array;
3830   foreach my $key (keys %{$attr}) {
3831     push( @rolled_array, { $key => $attr->{$key} } );
3832   }
3833   return \@rolled_array;
3834 }
3835
3836 sub _calculate_score {
3837   my ($self, $a, $b) = @_;
3838
3839   if (defined $a xor defined $b) {
3840     return 0;
3841   }
3842   elsif (not defined $a) {
3843     return 1;
3844   }
3845
3846   if (ref $b eq 'HASH') {
3847     my ($b_key) = keys %{$b};
3848     $b_key = '' if ! defined $b_key;
3849     if (ref $a eq 'HASH') {
3850       my ($a_key) = keys %{$a};
3851       $a_key = '' if ! defined $a_key;
3852       if ($a_key eq $b_key) {
3853         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3854       } else {
3855         return 0;
3856       }
3857     } else {
3858       return ($a eq $b_key) ? 1 : 0;
3859     }
3860   } else {
3861     if (ref $a eq 'HASH') {
3862       my ($a_key) = keys %{$a};
3863       return ($b eq $a_key) ? 1 : 0;
3864     } else {
3865       return ($b eq $a) ? 1 : 0;
3866     }
3867   }
3868 }
3869
3870 sub _merge_joinpref_attr {
3871   my ($self, $orig, $import) = @_;
3872
3873   return $import unless defined($orig);
3874   return $orig unless defined($import);
3875
3876   $orig = $self->_rollout_attr($orig);
3877   $import = $self->_rollout_attr($import);
3878
3879   my $seen_keys;
3880   foreach my $import_element ( @{$import} ) {
3881     # find best candidate from $orig to merge $b_element into
3882     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3883     foreach my $orig_element ( @{$orig} ) {
3884       my $score = $self->_calculate_score( $orig_element, $import_element );
3885       if ($score > $best_candidate->{score}) {
3886         $best_candidate->{position} = $position;
3887         $best_candidate->{score} = $score;
3888       }
3889       $position++;
3890     }
3891     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3892     $import_key = '' if not defined $import_key;
3893
3894     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3895       push( @{$orig}, $import_element );
3896     } else {
3897       my $orig_best = $orig->[$best_candidate->{position}];
3898       # merge orig_best and b_element together and replace original with merged
3899       if (ref $orig_best ne 'HASH') {
3900         $orig->[$best_candidate->{position}] = $import_element;
3901       } elsif (ref $import_element eq 'HASH') {
3902         my ($key) = keys %{$orig_best};
3903         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3904       }
3905     }
3906     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3907   }
3908
3909   return @$orig ? $orig : ();
3910 }
3911
3912 {
3913   my $hm;
3914
3915   sub _merge_attr {
3916     $hm ||= do {
3917       require Hash::Merge;
3918       my $hm = Hash::Merge->new;
3919
3920       $hm->specify_behavior({
3921         SCALAR => {
3922           SCALAR => sub {
3923             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3924
3925             if ($defl xor $defr) {
3926               return [ $defl ? $_[0] : $_[1] ];
3927             }
3928             elsif (! $defl) {
3929               return [];
3930             }
3931             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3932               return [ $_[0] ];
3933             }
3934             else {
3935               return [$_[0], $_[1]];
3936             }
3937           },
3938           ARRAY => sub {
3939             return $_[1] if !defined $_[0];
3940             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3941             return [$_[0], @{$_[1]}]
3942           },
3943           HASH  => sub {
3944             return [] if !defined $_[0] and !keys %{$_[1]};
3945             return [ $_[1] ] if !defined $_[0];
3946             return [ $_[0] ] if !keys %{$_[1]};
3947             return [$_[0], $_[1]]
3948           },
3949         },
3950         ARRAY => {
3951           SCALAR => sub {
3952             return $_[0] if !defined $_[1];
3953             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3954             return [@{$_[0]}, $_[1]]
3955           },
3956           ARRAY => sub {
3957             my @ret = @{$_[0]} or return $_[1];
3958             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3959             my %idx = map { $_ => 1 } @ret;
3960             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3961             \@ret;
3962           },
3963           HASH => sub {
3964             return [ $_[1] ] if ! @{$_[0]};
3965             return $_[0] if !keys %{$_[1]};
3966             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3967             return [ @{$_[0]}, $_[1] ];
3968           },
3969         },
3970         HASH => {
3971           SCALAR => sub {
3972             return [] if !keys %{$_[0]} and !defined $_[1];
3973             return [ $_[0] ] if !defined $_[1];
3974             return [ $_[1] ] if !keys %{$_[0]};
3975             return [$_[0], $_[1]]
3976           },
3977           ARRAY => sub {
3978             return [] if !keys %{$_[0]} and !@{$_[1]};
3979             return [ $_[0] ] if !@{$_[1]};
3980             return $_[1] if !keys %{$_[0]};
3981             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3982             return [ $_[0], @{$_[1]} ];
3983           },
3984           HASH => sub {
3985             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3986             return [ $_[0] ] if !keys %{$_[1]};
3987             return [ $_[1] ] if !keys %{$_[0]};
3988             return [ $_[0] ] if $_[0] eq $_[1];
3989             return [ $_[0], $_[1] ];
3990           },
3991         }
3992       } => 'DBIC_RS_ATTR_MERGER');
3993       $hm;
3994     };
3995
3996     return $hm->merge ($_[1], $_[2]);
3997   }
3998 }
3999
4000 sub STORABLE_freeze {
4001   my ($self, $cloning) = @_;
4002   my $to_serialize = { %$self };
4003
4004   # A cursor in progress can't be serialized (and would make little sense anyway)
4005   # the parser can be regenerated (and can't be serialized)
4006   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
4007
4008   # nor is it sensical to store a not-yet-fired-count pager
4009   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
4010     delete $to_serialize->{pager};
4011   }
4012
4013   Storable::nfreeze($to_serialize);
4014 }
4015
4016 # need this hook for symmetry
4017 sub STORABLE_thaw {
4018   my ($self, $cloning, $serialized) = @_;
4019
4020   %$self = %{ Storable::thaw($serialized) };
4021
4022   $self;
4023 }
4024
4025
4026 =head2 throw_exception
4027
4028 See L<DBIx::Class::Schema/throw_exception> for details.
4029
4030 =cut
4031
4032 sub throw_exception {
4033   my $self=shift;
4034
4035   if (ref $self and my $rsrc = $self->result_source) {
4036     $rsrc->throw_exception(@_)
4037   }
4038   else {
4039     DBIx::Class::Exception->throw(@_);
4040   }
4041 }
4042
4043 1;
4044
4045 __END__
4046
4047 # XXX: FIXME: Attributes docs need clearing up
4048
4049 =head1 ATTRIBUTES
4050
4051 Attributes are used to refine a ResultSet in various ways when
4052 searching for data. They can be passed to any method which takes an
4053 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4054 L</count>.
4055
4056 Default attributes can be set on the result class using
4057 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4058 the CAVEATS on that feature before using it!)
4059
4060 These are in no particular order:
4061
4062 =head2 order_by
4063
4064 =over 4
4065
4066 =item Value: ( $order_by | \@order_by | \%order_by )
4067
4068 =back
4069
4070 Which column(s) to order the results by.
4071
4072 [The full list of suitable values is documented in
4073 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4074 common options.]
4075
4076 If a single column name, or an arrayref of names is supplied, the
4077 argument is passed through directly to SQL. The hashref syntax allows
4078 for connection-agnostic specification of ordering direction:
4079
4080  For descending order:
4081
4082   order_by => { -desc => [qw/col1 col2 col3/] }
4083
4084  For explicit ascending order:
4085
4086   order_by => { -asc => 'col' }
4087
4088 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4089 supported, although you are strongly encouraged to use the hashref
4090 syntax as outlined above.
4091
4092 =head2 columns
4093
4094 =over 4
4095
4096 =item Value: \@columns | \%columns | $column
4097
4098 =back
4099
4100 Shortcut to request a particular set of columns to be retrieved. Each
4101 column spec may be a string (a table column name), or a hash (in which
4102 case the key is the C<as> value, and the value is used as the C<select>
4103 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4104 it and sets C<select> from that, then auto-populates C<as> from
4105 C<select> as normal. (You may also use the C<cols> attribute, as in
4106 earlier versions of DBIC, but this is deprecated)
4107
4108 Essentially C<columns> does the same as L</select> and L</as>.
4109
4110     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4111
4112 is the same as
4113
4114     select => [qw(some_column another_column)],
4115     as     => [qw(some_column dbic_slot)]
4116
4117 If you want to individually retrieve related columns (in essence perform
4118 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4119 chain such that it matches existing relationships:
4120
4121     my $rs = $schema->resultset('Artist')->search({}, {
4122         # required to tell DBIC to collapse has_many relationships
4123         collapse => 1,
4124         join     => { cds => 'tracks' },
4125         '+columns'  => {
4126           'cds.cdid'         => 'cds.cdid',
4127           'cds.tracks.title' => 'tracks.title',
4128         },
4129     });
4130
4131 Like elsewhere, literal SQL or literal values can be included by using a
4132 scalar reference or a literal bind value, and these values will be available
4133 in the result with C<get_column> (see also
4134 L<SQL::Abstract/Literal SQL and value type operators>):
4135
4136     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4137     # bind values: $true_value, $false_value
4138     columns => [
4139         {
4140             foo => \1,
4141             bar => \q{'a string'},
4142             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4143         }
4144     ]
4145
4146 =head2 +columns
4147
4148 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4149 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4150 with a unary plus operator before it, which is the same as simply C<columns>.
4151
4152 =over 4
4153
4154 =item Value: \@extra_columns
4155
4156 =back
4157
4158 Indicates additional columns to be selected from storage. Works the same as
4159 L</columns> but adds columns to the current selection. (You may also use the
4160 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4161 deprecated)
4162
4163   $schema->resultset('CD')->search(undef, {
4164     '+columns' => ['artist.name'],
4165     join => ['artist']
4166   });
4167
4168 would return all CDs and include a 'name' column to the information
4169 passed to object inflation. Note that the 'artist' is the name of the
4170 column (or relationship) accessor, and 'name' is the name of the column
4171 accessor in the related table.
4172
4173 =head2 select
4174
4175 =over 4
4176
4177 =item Value: \@select_columns
4178
4179 =back
4180
4181 Indicates which columns should be selected from the storage. You can use
4182 column names, or in the case of RDBMS back ends, function or stored procedure
4183 names:
4184
4185   $rs = $schema->resultset('Employee')->search(undef, {
4186     select => [
4187       'name',
4188       { count => 'employeeid' },
4189       { max => { length => 'name' }, -as => 'longest_name' }
4190     ]
4191   });
4192
4193   # Equivalent SQL
4194   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4195
4196 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4197 use L</select>, to instruct DBIx::Class how to store the result of the column.
4198
4199 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4200 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4201 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4202 function attribute> supplied as shown in the example above.
4203
4204 =head2 +select
4205
4206 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4207 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4208 with a unary plus operator before it, which is the same as simply C<select>.
4209
4210 =over 4
4211
4212 =item Value: \@extra_select_columns
4213
4214 =back
4215
4216 Indicates additional columns to be selected from storage.  Works the same as
4217 L</select> but adds columns to the current selection, instead of specifying
4218 a new explicit list.
4219
4220 =head2 as
4221
4222 =over 4
4223
4224 =item Value: \@inflation_names
4225
4226 =back
4227
4228 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4229 slot name in which the column value will be stored within the
4230 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4231 identifier by the C<get_column> method (or via the object accessor B<if one
4232 with the same name already exists>) as shown below.
4233
4234 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4235 aliasing C<AS>. See L</select> for details.
4236
4237   $rs = $schema->resultset('Employee')->search(undef, {
4238     select => [
4239       'name',
4240       { count => 'employeeid' },
4241       { max => { length => 'name' }, -as => 'longest_name' }
4242     ],
4243     as => [qw/
4244       name
4245       employee_count
4246       max_name_length
4247     /],
4248   });
4249
4250 If the object against which the search is performed already has an accessor
4251 matching a column name specified in C<as>, the value can be retrieved using
4252 the accessor as normal:
4253
4254   my $name = $employee->name();
4255
4256 If on the other hand an accessor does not exist in the object, you need to
4257 use C<get_column> instead:
4258
4259   my $employee_count = $employee->get_column('employee_count');
4260
4261 You can create your own accessors if required - see
4262 L<DBIx::Class::Manual::Cookbook> for details.
4263
4264 =head2 +as
4265
4266 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4267 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4268 with a unary plus operator before it, which is the same as simply C<as>.
4269
4270 =over 4
4271
4272 =item Value: \@extra_inflation_names
4273
4274 =back
4275
4276 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4277
4278 =head2 join
4279
4280 =over 4
4281
4282 =item Value: ($rel_name | \@rel_names | \%rel_names)
4283
4284 =back
4285
4286 Contains a list of relationships that should be joined for this query.  For
4287 example:
4288
4289   # Get CDs by Nine Inch Nails
4290   my $rs = $schema->resultset('CD')->search(
4291     { 'artist.name' => 'Nine Inch Nails' },
4292     { join => 'artist' }
4293   );
4294
4295 Can also contain a hash reference to refer to the other relation's relations.
4296 For example:
4297
4298   package MyApp::Schema::Track;
4299   use base qw/DBIx::Class/;
4300   __PACKAGE__->table('track');
4301   __PACKAGE__->add_columns(qw/trackid cd position title/);
4302   __PACKAGE__->set_primary_key('trackid');
4303   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4304   1;
4305
4306   # In your application
4307   my $rs = $schema->resultset('Artist')->search(
4308     { 'track.title' => 'Teardrop' },
4309     {
4310       join     => { cd => 'track' },
4311       order_by => 'artist.name',
4312     }
4313   );
4314
4315 You need to use the relationship (not the table) name in  conditions,
4316 because they are aliased as such. The current table is aliased as "me", so
4317 you need to use me.column_name in order to avoid ambiguity. For example:
4318
4319   # Get CDs from 1984 with a 'Foo' track
4320   my $rs = $schema->resultset('CD')->search(
4321     {
4322       'me.year' => 1984,
4323       'tracks.name' => 'Foo'
4324     },
4325     { join => 'tracks' }
4326   );
4327
4328 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4329 similarly for a third time). For e.g.
4330
4331   my $rs = $schema->resultset('Artist')->search({
4332     'cds.title'   => 'Down to Earth',
4333     'cds_2.title' => 'Popular',
4334   }, {
4335     join => [ qw/cds cds/ ],
4336   });
4337
4338 will return a set of all artists that have both a cd with title 'Down
4339 to Earth' and a cd with title 'Popular'.
4340
4341 If you want to fetch related objects from other tables as well, see L</prefetch>
4342 below.
4343
4344  NOTE: An internal join-chain pruner will discard certain joins while
4345  constructing the actual SQL query, as long as the joins in question do not
4346  affect the retrieved result. This for example includes 1:1 left joins
4347  that are not part of the restriction specification (WHERE/HAVING) nor are
4348  a part of the query selection.
4349
4350 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4351
4352 =head2 collapse
4353
4354 =over 4
4355
4356 =item Value: (0 | 1)
4357
4358 =back
4359
4360 When set to a true value, indicates that any rows fetched from joined has_many
4361 relationships are to be aggregated into the corresponding "parent" object. For
4362 example, the resultset:
4363
4364   my $rs = $schema->resultset('CD')->search({}, {
4365     '+columns' => [ qw/ tracks.title tracks.position / ],
4366     join => 'tracks',
4367     collapse => 1,
4368   });
4369
4370 While executing the following query:
4371
4372   SELECT me.*, tracks.title, tracks.position
4373     FROM cd me
4374     LEFT JOIN track tracks
4375       ON tracks.cdid = me.cdid
4376
4377 Will return only as many objects as there are rows in the CD source, even
4378 though the result of the query may span many rows. Each of these CD objects
4379 will in turn have multiple "Track" objects hidden behind the has_many
4380 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4381 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4382 product"), with each CD object containing exactly one of all fetched Track data.
4383
4384 When a collapse is requested on a non-ordered resultset, an order by some
4385 unique part of the main source (the left-most table) is inserted automatically.
4386 This is done so that the resultset is allowed to be "lazy" - calling
4387 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4388 object with all of its related data.
4389
4390 If an L</order_by> is already declared, and orders the resultset in a way that
4391 makes collapsing as described above impossible (e.g. C<< ORDER BY
4392 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4393 switch to "eager" mode and slurp the entire resultset before constructing the
4394 first object returned by L</next>.
4395
4396 Setting this attribute on a resultset that does not join any has_many
4397 relations is a no-op.
4398
4399 For a more in-depth discussion, see L</PREFETCHING>.
4400
4401 =head2 prefetch
4402
4403 =over 4
4404
4405 =item Value: ($rel_name | \@rel_names | \%rel_names)
4406
4407 =back
4408
4409 This attribute is a shorthand for specifying a L</join> spec, adding all
4410 columns from the joined related sources as L</+columns> and setting
4411 L</collapse> to a true value. It can be thought of as a rough B<superset>
4412 of the L</join> attribute.
4413
4414 For example, the following two queries are equivalent:
4415
4416   my $rs = $schema->resultset('Artist')->search({}, {
4417     prefetch => { cds => ['genre', 'tracks' ] },
4418   });
4419
4420 and
4421
4422   my $rs = $schema->resultset('Artist')->search({}, {
4423     join => { cds => ['genre', 'tracks' ] },
4424     collapse => 1,
4425     '+columns' => [
4426       (map
4427         { +{ "cds.$_" => "cds.$_" } }
4428         $schema->source('Artist')->related_source('cds')->columns
4429       ),
4430       (map
4431         { +{ "cds.genre.$_" => "genre.$_" } }
4432         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4433       ),
4434       (map
4435         { +{ "cds.tracks.$_" => "tracks.$_" } }
4436         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4437       ),
4438     ],
4439   });
4440
4441 Both producing the following SQL:
4442
4443   SELECT  me.artistid, me.name, me.rank, me.charfield,
4444           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4445           genre.genreid, genre.name,
4446           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4447     FROM artist me
4448     LEFT JOIN cd cds
4449       ON cds.artist = me.artistid
4450     LEFT JOIN genre genre
4451       ON genre.genreid = cds.genreid
4452     LEFT JOIN track tracks
4453       ON tracks.cd = cds.cdid
4454   ORDER BY me.artistid
4455
4456 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4457 the arguments are properly merged and generally do the right thing. For
4458 example, you may want to do the following:
4459
4460   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4461     { 'genre.genreid' => undef },
4462     {
4463       join => { cds => 'genre' },
4464       prefetch => 'cds',
4465     }
4466   );
4467
4468 Which generates the following SQL:
4469
4470   SELECT  me.artistid, me.name, me.rank, me.charfield,
4471           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4472     FROM artist me
4473     LEFT JOIN cd cds
4474       ON cds.artist = me.artistid
4475     LEFT JOIN genre genre
4476       ON genre.genreid = cds.genreid
4477   WHERE genre.genreid IS NULL
4478   ORDER BY me.artistid
4479
4480 For a more in-depth discussion, see L</PREFETCHING>.
4481
4482 =head2 alias
4483
4484 =over 4
4485
4486 =item Value: $source_alias
4487
4488 =back
4489
4490 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4491 nested search queries (sub-SELECTs) might need specific aliases set to
4492 reference inner queries.  For example:
4493
4494    my $q = $rs
4495       ->related_resultset('CDs')
4496       ->related_resultset('Tracks')
4497       ->search({
4498          'track.id' => { -ident => 'none_search.id' },
4499       })
4500       ->as_query;
4501
4502    my $ids = $self->search({
4503       -not_exists => $q,
4504    }, {
4505       alias    => 'none_search',
4506       group_by => 'none_search.id',
4507    })->get_column('id')->as_query;
4508
4509    $self->search({ id => { -in => $ids } })
4510
4511 This attribute is directly tied to L</current_source_alias>.
4512
4513 =head2 page
4514
4515 =over 4
4516
4517 =item Value: $page
4518
4519 =back
4520
4521 Makes the resultset paged and specifies the page to retrieve. Effectively
4522 identical to creating a non-pages resultset and then calling ->page($page)
4523 on it.
4524
4525 If L</rows> attribute is not specified it defaults to 10 rows per page.
4526
4527 When you have a paged resultset, L</count> will only return the number
4528 of rows in the page. To get the total, use the L</pager> and call
4529 C<total_entries> on it.
4530
4531 =head2 rows
4532
4533 =over 4
4534
4535 =item Value: $rows
4536
4537 =back
4538
4539 Specifies the maximum number of rows for direct retrieval or the number of
4540 rows per page if the page attribute or method is used.
4541
4542 =head2 offset
4543
4544 =over 4
4545
4546 =item Value: $offset
4547
4548 =back
4549
4550 Specifies the (zero-based) row number for the  first row to be returned, or the
4551 of the first row of the first page if paging is used.
4552
4553 =head2 software_limit
4554
4555 =over 4
4556
4557 =item Value: (0 | 1)
4558
4559 =back
4560
4561 When combined with L</rows> and/or L</offset> the generated SQL will not
4562 include any limit dialect stanzas. Instead the entire result will be selected
4563 as if no limits were specified, and DBIC will perform the limit locally, by
4564 artificially advancing and finishing the resulting L</cursor>.
4565
4566 This is the recommended way of performing resultset limiting when no sane RDBMS
4567 implementation is available (e.g.
4568 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4569 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4570
4571 =head2 group_by
4572
4573 =over 4
4574
4575 =item Value: \@columns
4576
4577 =back
4578
4579 A arrayref of columns to group by. Can include columns of joined tables.
4580
4581   group_by => [qw/ column1 column2 ... /]
4582
4583 =head2 having
4584
4585 =over 4
4586
4587 =item Value: $condition
4588
4589 =back
4590
4591 The HAVING operator specifies a B<secondary> condition applied to the set
4592 after the grouping calculations have been done. In other words it is a
4593 constraint just like L</where> (and accepting the same
4594 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4595 as it exists after GROUP BY has taken place. Specifying L</having> without
4596 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4597
4598 E.g.
4599
4600   having => { 'count_employee' => { '>=', 100 } }
4601
4602 or with an in-place function in which case literal SQL is required:
4603
4604   having => \[ 'count(employee) >= ?', 100 ]
4605
4606 =head2 distinct
4607
4608 =over 4
4609
4610 =item Value: (0 | 1)
4611
4612 =back
4613
4614 Set to 1 to automatically generate a L</group_by> clause based on the selection
4615 (including intelligent handling of L</order_by> contents). Note that the group
4616 criteria calculation takes place over the B<final> selection. This includes
4617 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4618 L</search> calls, and standalone columns selected via
4619 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4620 extra selections specified via L</prefetch> - such selections are explicitly
4621 excluded from group criteria calculations.
4622
4623 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4624 setting is ignored and an appropriate warning is issued.
4625
4626 =head2 where
4627
4628 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4629 conditions, same as the B<first> argument to the L<search operator|/search>
4630
4631   # only return rows WHERE deleted IS NULL for all searches
4632   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4633
4634 Note that the above example is
4635 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4636
4637 =head2 cache
4638
4639 Set to 1 to cache search results. This prevents extra SQL queries if you
4640 revisit rows in your ResultSet:
4641
4642   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4643
4644   while( my $artist = $resultset->next ) {
4645     ... do stuff ...
4646   }
4647
4648   $resultset->first; # without cache, this would issue a query
4649
4650 By default, searches are not cached.
4651
4652 For more examples of using these attributes, see
4653 L<DBIx::Class::Manual::Cookbook>.
4654
4655 =head2 for
4656
4657 =over 4
4658
4659 =item Value: ( 'update' | 'shared' | \$scalar )
4660
4661 =back
4662
4663 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4664 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4665 query.
4666
4667 =head1 PREFETCHING
4668
4669 DBIx::Class supports arbitrary related data prefetching from multiple related
4670 sources. Any combination of relationship types and column sets are supported.
4671 If L<collapsing|/collapse> is requested, there is an additional requirement of
4672 selecting enough data to make every individual object uniquely identifiable.
4673
4674 Here are some more involved examples, based on the following relationship map:
4675
4676   # Assuming:
4677   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4678   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4679   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4680
4681   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4682
4683   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4684
4685
4686
4687   my $rs = $schema->resultset('Tag')->search(
4688     undef,
4689     {
4690       prefetch => {
4691         cd => 'artist'
4692       }
4693     }
4694   );
4695
4696 The initial search results in SQL like the following:
4697
4698   SELECT tag.*, cd.*, artist.* FROM tag
4699   JOIN cd ON tag.cd = cd.cdid
4700   JOIN artist ON cd.artist = artist.artistid
4701
4702 L<DBIx::Class> has no need to go back to the database when we access the
4703 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4704 case.
4705
4706 Simple prefetches will be joined automatically, so there is no need
4707 for a C<join> attribute in the above search.
4708
4709 The L</prefetch> attribute can be used with any of the relationship types
4710 and multiple prefetches can be specified together. Below is a more complex
4711 example that prefetches a CD's artist, its liner notes (if present),
4712 the cover image, the tracks on that CD, and the guests on those
4713 tracks.
4714
4715   my $rs = $schema->resultset('CD')->search(
4716     undef,
4717     {
4718       prefetch => [
4719         { artist => 'record_label'},  # belongs_to => belongs_to
4720         'liner_note',                 # might_have
4721         'cover_image',                # has_one
4722         { tracks => 'guests' },       # has_many => has_many
4723       ]
4724     }
4725   );
4726
4727 This will produce SQL like the following:
4728
4729   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4730          tracks.*, guests.*
4731     FROM cd me
4732     JOIN artist artist
4733       ON artist.artistid = me.artistid
4734     JOIN record_label record_label
4735       ON record_label.labelid = artist.labelid
4736     LEFT JOIN track tracks
4737       ON tracks.cdid = me.cdid
4738     LEFT JOIN guest guests
4739       ON guests.trackid = track.trackid
4740     LEFT JOIN liner_notes liner_note
4741       ON liner_note.cdid = me.cdid
4742     JOIN cd_artwork cover_image
4743       ON cover_image.cdid = me.cdid
4744   ORDER BY tracks.cd
4745
4746 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4747 C<tracks>, and C<guests> of the CD will all be available through the
4748 relationship accessors without the need for additional queries to the
4749 database.
4750
4751 =head3 CAVEATS
4752
4753 Prefetch does a lot of deep magic. As such, it may not behave exactly
4754 as you might expect.
4755
4756 =over 4
4757
4758 =item *
4759
4760 Prefetch uses the L</cache> to populate the prefetched relationships. This
4761 may or may not be what you want.
4762
4763 =item *
4764
4765 If you specify a condition on a prefetched relationship, ONLY those
4766 rows that match the prefetched condition will be fetched into that relationship.
4767 This means that adding prefetch to a search() B<may alter> what is returned by
4768 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4769
4770   my $artist_rs = $schema->resultset('Artist')->search({
4771       'cds.year' => 2008,
4772   }, {
4773       join => 'cds',
4774   });
4775
4776   my $count = $artist_rs->first->cds->count;
4777
4778   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4779
4780   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4781
4782   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4783
4784 That cmp_ok() may or may not pass depending on the datasets involved. In other
4785 words the C<WHERE> condition would apply to the entire dataset, just like
4786 it would in regular SQL. If you want to add a condition only to the "right side"
4787 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4788 condition|DBIx::Class::Relationship::Base/condition>
4789
4790 =back
4791
4792 =head1 DBIC BIND VALUES
4793
4794 Because DBIC may need more information to bind values than just the column name
4795 and value itself, it uses a special format for both passing and receiving bind
4796 values.  Each bind value should be composed of an arrayref of
4797 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4798
4799 =over 4
4800
4801 =item dbd_attrs
4802
4803 If present (in any form), this is what is being passed directly to bind_param.
4804 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4805 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4806
4807 If this is specified, all other bind options described below are ignored.
4808
4809 =item sqlt_datatype
4810
4811 If present, this is used to infer the actual bind attribute by passing to
4812 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4813 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4814
4815 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4816 currently drivers are expected to "Do the Right Thing" when given a common
4817 datatype name.  (Not ideal, but that's what we got at this point.)
4818
4819 =item sqlt_size
4820
4821 Currently used to correctly allocate buffers for bind_param_inout().
4822 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4823 or to a sensible value based on the "data_type".
4824
4825 =item dbic_colname
4826
4827 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4828 explicitly specified they are never overridden).  Also used by some weird DBDs,
4829 where the column name should be available at bind_param time (e.g. Oracle).
4830
4831 =back
4832
4833 For backwards compatibility and convenience, the following shortcuts are
4834 supported:
4835
4836   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4837   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4838   [ undef,   $val ] === [ {}, $val ]
4839   $val              === [ {}, $val ]
4840
4841 =head1 FURTHER QUESTIONS?
4842
4843 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4844
4845 =head1 COPYRIGHT AND LICENSE
4846
4847 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4848 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4849 redistribute it and/or modify it under the same terms as the
4850 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4851
4852 =cut