lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray is_plain_value is_literal_value
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes using Moose
 171
 172 If you want to make your custom ResultSet classes with L<Moose>, use a template
 173 similar to:
 174
 175     package MyApp::Schema::ResultSet::User;
 176
 177     use Moose;
 178     use MooseX::NonMoose;
 179     extends 'DBIx::Class::ResultSet';
 180
 181     sub BUILDARGS { $_[2] }
 182
 183     ...your code...
 184
 185     __PACKAGE__->meta->make_immutable;
 186
 187     1;
 188
 189 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 190 clash with the regular ResultSet constructor. Alternatively, you can use:
 191
 192     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 193
 194 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 195 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 196
 197 =head1 METHODS
 198
 199 =head2 new
 200
 201 =over 4
 202
 203 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 204
 205 =item Return Value: L<$resultset|/search>
 206
 207 =back
 208
 209 The resultset constructor. Takes a source object (usually a
 210 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 211 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 212 executed as needed by the other methods.
 213
 214 Generally you never construct a resultset manually. Instead you get one
 215 from e.g. a
 216 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 217 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 218 scalar context):
 219
 220   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 221
 222 =over
 223
 224 =item WARNING
 225
 226 If called on an object, proxies to L</new_result> instead, so
 227
 228   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 229
 230 will return a CD object, not a ResultSet, and is equivalent to:
 231
 232   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 233
 234 Please also keep in mind that many internals call L</new_result> directly,
 235 so overloading this method with the idea of intercepting new result object
 236 creation B<will not work>. See also warning pertaining to L</create>.
 237
 238 =back
 239
 240 =cut
 241
 242 sub new {
 243   my $class = shift;
 244   return $class->new_result(@_) if ref $class;
 245
 246   my ($source, $attrs) = @_;
 247   $source = $source->resolve
 248     if $source->isa('DBIx::Class::ResultSourceHandle');
 249
 250   $attrs = { %{$attrs||{}} };
 251   delete @{$attrs}{qw(_last_sqlmaker_alias_map _related_results_construction)};
 252
 253   if ($attrs->{page}) {
 254     $attrs->{rows} ||= 10;
 255   }
 256
 257   $attrs->{alias} ||= 'me';
 258
 259   my $self = bless {
 260     result_source => $source,
 261     cond => $attrs->{where},
 262     pager => undef,
 263     attrs => $attrs,
 264   }, $class;
 265
 266   # if there is a dark selector, this means we are already in a
 267   # chain and the cleanup/sanification was taken care of by
 268   # _search_rs already
 269   $self->_normalize_selection($attrs)
 270     unless $attrs->{_dark_selector};
 271
 272   $self->result_class(
 273     $attrs->{result_class} || $source->result_class
 274   );
 275
 276   $self;
 277 }
 278
 279 =head2 search
 280
 281 =over 4
 282
 283 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 284
 285 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 286
 287 =back
 288
 289   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 290   my $new_rs = $cd_rs->search({ year => 2005 });
 291
 292   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 293                  # year = 2005 OR year = 2004
 294
 295 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 296 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 297 To avoid that, use L</search_rs>.
 298
 299 If you need to pass in additional attributes but no additional condition,
 300 call it as C<search(undef, \%attrs)>.
 301
 302   # "SELECT name, artistid FROM $artist_table"
 303   my @all_artists = $schema->resultset('Artist')->search(undef, {
 304     columns => [qw/name artistid/],
 305   });
 306
 307 For a list of attributes that can be passed to C<search>, see
 308 L</ATTRIBUTES>. For more examples of using this function, see
 309 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 310 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 311 and its extension L<DBIx::Class::SQLMaker>.
 312
 313 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 314
 315 =head3 CAVEAT
 316
 317 Note that L</search> does not process/deflate any of the values passed in the
 318 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 319 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 320 manually that any value passed to this method will stringify to something the
 321 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 322 objects, for more info see:
 323 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 324
 325 =cut
 326
 327 sub search {
 328   my $self = shift;
 329   my $rs = $self->search_rs( @_ );
 330
 331   if (wantarray) {
 332     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray($rs);
 333     return $rs->all;
 334   }
 335   elsif (defined wantarray) {
 336     return $rs;
 337   }
 338   else {
 339     # we can be called by a relationship helper, which in
 340     # turn may be called in void context due to some braindead
 341     # overload or whatever else the user decided to be clever
 342     # at this particular day. Thus limit the exception to
 343     # external code calls only
 344     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 345       if (caller)[0] !~ /^\QDBIx::Class::/;
 346
 347     return ();
 348   }
 349 }
 350
 351 =head2 search_rs
 352
 353 =over 4
 354
 355 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 356
 357 =item Return Value: L<$resultset|/search>
 358
 359 =back
 360
 361 This method does the same exact thing as search() except it will
 362 always return a resultset, even in list context.
 363
 364 =cut
 365
 366 sub search_rs {
 367   my $self = shift;
 368
 369   my $rsrc = $self->result_source;
 370   my ($call_cond, $call_attrs);
 371
 372   # Special-case handling for (undef, undef) or (undef)
 373   # Note that (foo => undef) is valid deprecated syntax
 374   @_ = () if not scalar grep { defined $_ } @_;
 375
 376   # just a cond
 377   if (@_ == 1) {
 378     $call_cond = shift;
 379   }
 380   # fish out attrs in the ($condref, $attr) case
 381   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 382     ($call_cond, $call_attrs) = @_;
 383   }
 384   elsif (@_ % 2) {
 385     $self->throw_exception('Odd number of arguments to search')
 386   }
 387   # legacy search
 388   elsif (@_) {
 389     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 390       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 391
 392     for my $i (0 .. $#_) {
 393       next if $i % 2;
 394       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 395         if (! defined $_[$i] or ref $_[$i] ne '');
 396     }
 397
 398     $call_cond = { @_ };
 399   }
 400
 401   # see if we can keep the cache (no $rs changes)
 402   my $cache;
 403   my %safe = (alias => 1, cache => 1);
 404   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 405     ! defined $call_cond
 406       or
 407     ref $call_cond eq 'HASH' && ! keys %$call_cond
 408       or
 409     ref $call_cond eq 'ARRAY' && ! @$call_cond
 410   )) {
 411     $cache = $self->get_cache;
 412   }
 413
 414   my $old_attrs = { %{$self->{attrs}} };
 415   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 416
 417   my $new_attrs = { %$old_attrs };
 418
 419   # take care of call attrs (only if anything is changing)
 420   if ($call_attrs and keys %$call_attrs) {
 421
 422     # copy for _normalize_selection
 423     $call_attrs = { %$call_attrs };
 424
 425     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 426
 427     # reset the current selector list if new selectors are supplied
 428     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 429       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 430     }
 431
 432     # Normalize the new selector list (operates on the passed-in attr structure)
 433     # Need to do it on every chain instead of only once on _resolved_attrs, in
 434     # order to allow detection of empty vs partial 'as'
 435     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 436       if $old_attrs->{_dark_selector};
 437     $self->_normalize_selection ($call_attrs);
 438
 439     # start with blind overwriting merge, exclude selector attrs
 440     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 441     delete @{$new_attrs}{@selector_attrs};
 442
 443     for (@selector_attrs) {
 444       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 445         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 446     }
 447
 448     # older deprecated name, use only if {columns} is not there
 449     if (my $c = delete $new_attrs->{cols}) {
 450       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 451       if ($new_attrs->{columns}) {
 452         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 453       }
 454       else {
 455         $new_attrs->{columns} = $c;
 456       }
 457     }
 458
 459
 460     # join/prefetch use their own crazy merging heuristics
 461     foreach my $key (qw/join prefetch/) {
 462       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 463         if exists $call_attrs->{$key};
 464     }
 465
 466     # stack binds together
 467     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 468   }
 469
 470
 471   for ($old_where, $call_cond) {
 472     if (defined $_) {
 473       $new_attrs->{where} = $self->_stack_cond (
 474         $_, $new_attrs->{where}
 475       );
 476     }
 477   }
 478
 479   if (defined $old_having) {
 480     $new_attrs->{having} = $self->_stack_cond (
 481       $old_having, $new_attrs->{having}
 482     )
 483   }
 484
 485   my $rs = (ref $self)->new($rsrc, $new_attrs);
 486
 487   $rs->set_cache($cache) if ($cache);
 488
 489   return $rs;
 490 }
 491
 492 my $dark_sel_dumper;
 493 sub _normalize_selection {
 494   my ($self, $attrs) = @_;
 495
 496   # legacy syntax
 497   if ( exists $attrs->{include_columns} ) {
 498     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 499     $attrs->{'+columns'} = $self->_merge_attr(
 500       $attrs->{'+columns'}, delete $attrs->{include_columns}
 501     );
 502   }
 503
 504   # columns are always placed first, however
 505
 506   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 507   # delay the decision on whether to use a default select list ($rsrc->columns)
 508   # allowing stuff like the remove_columns helper to work
 509   #
 510   # select/as +select/+as pairs need special handling - the amount of select/as
 511   # elements in each pair does *not* have to be equal (think multicolumn
 512   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 513   # supplied at all) - try to infer the alias, either from the -as parameter
 514   # of the selector spec, or use the parameter whole if it looks like a column
 515   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 516   # is ok as well), but make sure no more additions to the 'as' chain take place
 517   for my $pref ('', '+') {
 518
 519     my ($sel, $as) = map {
 520       my $key = "${pref}${_}";
 521
 522       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 523         ? @{$attrs->{$key}}
 524         : $attrs->{$key} || ()
 525       ];
 526       delete $attrs->{$key};
 527       $val;
 528     } qw/select as/;
 529
 530     if (! @$as and ! @$sel ) {
 531       next;
 532     }
 533     elsif (@$as and ! @$sel) {
 534       $self->throw_exception(
 535         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 536       );
 537     }
 538     elsif( ! @$as ) {
 539       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 540       # if any @$as has been supplied we assume the user knows what (s)he is doing
 541       # and blindly keep stacking up pieces
 542       unless ($attrs->{_dark_selector}) {
 543         SELECTOR:
 544         for (@$sel) {
 545           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 546             push @$as, $_->{-as};
 547           }
 548           # assume any plain no-space, no-parenthesis string to be a column spec
 549           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 550           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 551             push @$as, $_;
 552           }
 553           # if all else fails - raise a flag that no more aliasing will be allowed
 554           else {
 555             $attrs->{_dark_selector} = {
 556               plus_stage => $pref,
 557               string => ($dark_sel_dumper ||= do {
 558                   require Data::Dumper::Concise;
 559                   Data::Dumper::Concise::DumperObject()->Indent(0);
 560                 })->Values([$_])->Dump
 561               ,
 562             };
 563             last SELECTOR;
 564           }
 565         }
 566       }
 567     }
 568     elsif (@$as < @$sel) {
 569       $self->throw_exception(
 570         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 571       );
 572     }
 573     elsif ($pref and $attrs->{_dark_selector}) {
 574       $self->throw_exception(
 575         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 576       );
 577     }
 578
 579
 580     # merge result
 581     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 582     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 583   }
 584 }
 585
 586 sub _stack_cond {
 587   my ($self, $left, $right) = @_;
 588
 589   (
 590     (ref $_ eq 'ARRAY' and !@$_)
 591       or
 592     (ref $_ eq 'HASH' and ! keys %$_)
 593   ) and $_ = undef for ($left, $right);
 594
 595   # either on of the two undef or both undef
 596   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 597     return defined $left ? $left : $right;
 598   }
 599
 600   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 601
 602   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 603
 604     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 605     my @fin = shift @vals;
 606
 607     for my $v (@vals) {
 608       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 609     }
 610
 611     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 612   }
 613
 614   $cond;
 615 }
 616
 617 =head2 search_literal
 618
 619 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 620 should only be used in that context. C<search_literal> is a convenience
 621 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 622 want to ensure columns are bound correctly, use L</search>.
 623
 624 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 625 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 626 require C<search_literal>.
 627
 628 =over 4
 629
 630 =item Arguments: $sql_fragment, @standalone_bind_values
 631
 632 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 633
 634 =back
 635
 636   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 637   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 638
 639 Pass a literal chunk of SQL to be added to the conditional part of the
 640 resultset query.
 641
 642 Example of how to use C<search> instead of C<search_literal>
 643
 644   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 645   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 646
 647 =cut
 648
 649 sub search_literal {
 650   my ($self, $sql, @bind) = @_;
 651   my $attr;
 652   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 653     $attr = pop @bind;
 654   }
 655   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 656 }
 657
 658 =head2 find
 659
 660 =over 4
 661
 662 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 663
 664 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 665
 666 =back
 667
 668 Finds and returns a single row based on supplied criteria. Takes either a
 669 hashref with the same format as L</create> (including inference of foreign
 670 keys from related objects), or a list of primary key values in the same
 671 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 672 declaration on the L</result_source>.
 673
 674 In either case an attempt is made to combine conditions already existing on
 675 the resultset with the condition passed to this method.
 676
 677 To aid with preparing the correct query for the storage you may supply the
 678 C<key> attribute, which is the name of a
 679 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 680 unique constraint corresponding to the
 681 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 682 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 683 to construct a query that satisfies the named unique constraint fully (
 684 non-NULL values for each column member of the constraint) an exception is
 685 thrown.
 686
 687 If no C<key> is specified, the search is carried over all unique constraints
 688 which are fully defined by the available condition.
 689
 690 If no such constraint is found, C<find> currently defaults to a simple
 691 C<< search->(\%column_values) >> which may or may not do what you expect.
 692 Note that this fallback behavior may be deprecated in further versions. If
 693 you need to search with arbitrary conditions - use L</search>. If the query
 694 resulting from this fallback produces more than one row, a warning to the
 695 effect is issued, though only the first row is constructed and returned as
 696 C<$result_object>.
 697
 698 In addition to C<key>, L</find> recognizes and applies standard
 699 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 700
 701 Note that if you have extra concerns about the correctness of the resulting
 702 query you need to specify the C<key> attribute and supply the entire condition
 703 as an argument to find (since it is not always possible to perform the
 704 combination of the resultset condition with the supplied one, especially if
 705 the resultset condition contains literal sql).
 706
 707 For example, to find a row by its primary key:
 708
 709   my $cd = $schema->resultset('CD')->find(5);
 710
 711 You can also find a row by a specific unique constraint:
 712
 713   my $cd = $schema->resultset('CD')->find(
 714     {
 715       artist => 'Massive Attack',
 716       title  => 'Mezzanine',
 717     },
 718     { key => 'cd_artist_title' }
 719   );
 720
 721 See also L</find_or_create> and L</update_or_create>.
 722
 723 =cut
 724
 725 sub find {
 726   my $self = shift;
 727   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 728
 729   my $rsrc = $self->result_source;
 730
 731   my $constraint_name;
 732   if (exists $attrs->{key}) {
 733     $constraint_name = defined $attrs->{key}
 734       ? $attrs->{key}
 735       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 736     ;
 737   }
 738
 739   # Parse out the condition from input
 740   my $call_cond;
 741
 742   if (ref $_[0] eq 'HASH') {
 743     $call_cond = { %{$_[0]} };
 744   }
 745   else {
 746     # if only values are supplied we need to default to 'primary'
 747     $constraint_name = 'primary' unless defined $constraint_name;
 748
 749     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 750
 751     $self->throw_exception(
 752       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 753     ) unless @c_cols;
 754
 755     $self->throw_exception (
 756       'find() expects either a column/value hashref, or a list of values '
 757     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 758     ) unless @c_cols == @_;
 759
 760     $call_cond = {};
 761     @{$call_cond}{@c_cols} = @_;
 762   }
 763
 764   my %related;
 765   for my $key (keys %$call_cond) {
 766     if (
 767       my $keyref = ref($call_cond->{$key})
 768         and
 769       my $relinfo = $rsrc->relationship_info($key)
 770     ) {
 771       my $val = delete $call_cond->{$key};
 772
 773       next if $keyref eq 'ARRAY'; # has_many for multi_create
 774
 775       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 776         $relinfo->{cond}, $val, $key, $key
 777       );
 778
 779       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 780          if $crosstable or ref($rel_cond) ne 'HASH';
 781
 782       # supplement
 783       @related{keys %$rel_cond} = values %$rel_cond;
 784     }
 785   }
 786
 787   # relationship conditions take precedence (?)
 788   @{$call_cond}{keys %related} = values %related;
 789
 790   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 791   my $final_cond;
 792   if (defined $constraint_name) {
 793     $final_cond = $self->_qualify_cond_columns (
 794
 795       $self->_build_unique_cond (
 796         $constraint_name,
 797         $call_cond,
 798       ),
 799
 800       $alias,
 801     );
 802   }
 803   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 804     # This means that we got here after a merger of relationship conditions
 805     # in ::Relationship::Base::search_related (the row method), and furthermore
 806     # the relationship is of the 'single' type. This means that the condition
 807     # provided by the relationship (already attached to $self) is sufficient,
 808     # as there can be only one row in the database that would satisfy the
 809     # relationship
 810   }
 811   else {
 812     # no key was specified - fall down to heuristics mode:
 813     # run through all unique queries registered on the resultset, and
 814     # 'OR' all qualifying queries together
 815     my (@unique_queries, %seen_column_combinations);
 816     for my $c_name ($rsrc->unique_constraint_names) {
 817       next if $seen_column_combinations{
 818         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 819       }++;
 820
 821       push @unique_queries, try {
 822         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 823       } || ();
 824     }
 825
 826     $final_cond = @unique_queries
 827       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 828       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 829     ;
 830   }
 831
 832   # Run the query, passing the result_class since it should propagate for find
 833   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 834   if ($rs->_resolved_attrs->{collapse}) {
 835     my $row = $rs->next;
 836     carp "Query returned more than one row" if $rs->next;
 837     return $row;
 838   }
 839   else {
 840     return $rs->single;
 841   }
 842 }
 843
 844 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 845 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 846 #
 847 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 848 # condition. It is provided for overrides until a saner way forward is devised
 849 #
 850 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 851 # the road. Please adjust your tests accordingly to catch this situation early
 852 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 853 #
 854 # The method will not be removed without an adequately complete replacement
 855 # for strict-mode enforcement
 856 sub _non_unique_find_fallback {
 857   my ($self, $cond, $attrs) = @_;
 858
 859   return $self->_qualify_cond_columns(
 860     $cond,
 861     exists $attrs->{alias}
 862       ? $attrs->{alias}
 863       : $self->{attrs}{alias}
 864   );
 865 }
 866
 867
 868 sub _qualify_cond_columns {
 869   my ($self, $cond, $alias) = @_;
 870
 871   my %aliased = %$cond;
 872   for (keys %aliased) {
 873     $aliased{"$alias.$_"} = delete $aliased{$_}
 874       if $_ !~ /\./;
 875   }
 876
 877   return \%aliased;
 878 }
 879
 880 sub _build_unique_cond {
 881   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 882
 883   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 884
 885   # combination may fail if $self->{cond} is non-trivial
 886   my ($final_cond) = try {
 887     $self->_merge_with_rscond ($extra_cond)
 888   } catch {
 889     +{ %$extra_cond }
 890   };
 891
 892   # trim out everything not in $columns
 893   $final_cond = { map {
 894     exists $final_cond->{$_}
 895       ? ( $_ => $final_cond->{$_} )
 896       : ()
 897   } @c_cols };
 898
 899   if (my @missing = grep
 900     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 901     (@c_cols)
 902   ) {
 903     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 904       $constraint_name,
 905       join (', ', map { "'$_'" } @missing),
 906     ) );
 907   }
 908
 909   if (
 910     !$croak_on_null
 911       and
 912     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 913       and
 914     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 915   ) {
 916     carp_unique ( sprintf (
 917       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 918     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 919     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 920       $constraint_name,
 921       join (', ', map { "'$_'" } @undefs),
 922     ));
 923   }
 924
 925   return $final_cond;
 926 }
 927
 928 =head2 search_related
 929
 930 =over 4
 931
 932 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 933
 934 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 935
 936 =back
 937
 938   $new_rs = $cd_rs->search_related('artist', {
 939     name => 'Emo-R-Us',
 940   });
 941
 942 Searches the specified relationship, optionally specifying a condition and
 943 attributes for matching records. See L</ATTRIBUTES> for more information.
 944
 945 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 946 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 947
 948 See also L</search_related_rs>.
 949
 950 =cut
 951
 952 sub search_related {
 953   return shift->related_resultset(shift)->search(@_);
 954 }
 955
 956 =head2 search_related_rs
 957
 958 This method works exactly the same as search_related, except that
 959 it guarantees a resultset, even in list context.
 960
 961 =cut
 962
 963 sub search_related_rs {
 964   return shift->related_resultset(shift)->search_rs(@_);
 965 }
 966
 967 =head2 cursor
 968
 969 =over 4
 970
 971 =item Arguments: none
 972
 973 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 974
 975 =back
 976
 977 Returns a storage-driven cursor to the given resultset. See
 978 L<DBIx::Class::Cursor> for more information.
 979
 980 =cut
 981
 982 sub cursor {
 983   my $self = shift;
 984
 985   return $self->{cursor} ||= do {
 986     my $attrs = $self->_resolved_attrs;
 987     $self->result_source->storage->select(
 988       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
 989     );
 990   };
 991 }
 992
 993 =head2 single
 994
 995 =over 4
 996
 997 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
 998
 999 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1000
1001 =back
1002
1003   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1004
1005 Inflates the first result without creating a cursor if the resultset has
1006 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1007 of L</search>.
1008
1009 While this method can take an optional search condition (just like L</search>)
1010 being a fast-code-path it does not recognize search attributes. If you need to
1011 add extra joins or similar, call L</search> and then chain-call L</single> on the
1012 L<DBIx::Class::ResultSet> returned.
1013
1014 =over
1015
1016 =item B<Note>
1017
1018 As of 0.08100, this method enforces the assumption that the preceding
1019 query returns only one row. If more than one row is returned, you will receive
1020 a warning:
1021
1022   Query returned more than one row
1023
1024 In this case, you should be using L</next> or L</find> instead, or if you really
1025 know what you are doing, use the L</rows> attribute to explicitly limit the size
1026 of the resultset.
1027
1028 This method will also throw an exception if it is called on a resultset prefetching
1029 has_many, as such a prefetch implies fetching multiple rows from the database in
1030 order to assemble the resulting object.
1031
1032 =back
1033
1034 =cut
1035
1036 sub single {
1037   my ($self, $where) = @_;
1038   if(@_ > 2) {
1039       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1040   }
1041
1042   my $attrs = { %{$self->_resolved_attrs} };
1043
1044   $self->throw_exception(
1045     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1046   ) if $attrs->{collapse};
1047
1048   if ($where) {
1049     if (defined $attrs->{where}) {
1050       $attrs->{where} = {
1051         '-and' =>
1052             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1053                $where, delete $attrs->{where} ]
1054       };
1055     } else {
1056       $attrs->{where} = $where;
1057     }
1058   }
1059
1060   my $data = [ $self->result_source->storage->select_single(
1061     $attrs->{from}, $attrs->{select},
1062     $attrs->{where}, $attrs
1063   )];
1064
1065   return undef unless @$data;
1066   $self->{_stashed_rows} = [ $data ];
1067   $self->_construct_results->[0];
1068 }
1069
1070 =head2 get_column
1071
1072 =over 4
1073
1074 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1075
1076 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1077
1078 =back
1079
1080   my $max_length = $rs->get_column('length')->max;
1081
1082 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1083
1084 =cut
1085
1086 sub get_column {
1087   my ($self, $column) = @_;
1088   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1089   return $new;
1090 }
1091
1092 =head2 search_like
1093
1094 =over 4
1095
1096 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1097
1098 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1099
1100 =back
1101
1102   # WHERE title LIKE '%blue%'
1103   $cd_rs = $rs->search_like({ title => '%blue%'});
1104
1105 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1106 that this is simply a convenience method retained for ex Class::DBI users.
1107 You most likely want to use L</search> with specific operators.
1108
1109 For more information, see L<DBIx::Class::Manual::Cookbook>.
1110
1111 This method is deprecated and will be removed in 0.09. Use L</search()>
1112 instead. An example conversion is:
1113
1114   ->search_like({ foo => 'bar' });
1115
1116   # Becomes
1117
1118   ->search({ foo => { like => 'bar' } });
1119
1120 =cut
1121
1122 sub search_like {
1123   my $class = shift;
1124   carp_unique (
1125     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1126    .' Instead use ->search({ x => { -like => "y%" } })'
1127    .' (note the outer pair of {}s - they are important!)'
1128   );
1129   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1130   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1131   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1132   return $class->search($query, { %$attrs });
1133 }
1134
1135 =head2 slice
1136
1137 =over 4
1138
1139 =item Arguments: $first, $last
1140
1141 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1142
1143 =back
1144
1145 Returns a resultset or object list representing a subset of elements from the
1146 resultset slice is called on. Indexes are from 0, i.e., to get the first
1147 three records, call:
1148
1149   my ($one, $two, $three) = $rs->slice(0, 2);
1150
1151 =cut
1152
1153 sub slice {
1154   my ($self, $min, $max) = @_;
1155   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1156   $attrs->{offset} = $self->{attrs}{offset} || 0;
1157   $attrs->{offset} += $min;
1158   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1159   return $self->search(undef, $attrs);
1160 }
1161
1162 =head2 next
1163
1164 =over 4
1165
1166 =item Arguments: none
1167
1168 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1169
1170 =back
1171
1172 Returns the next element in the resultset (C<undef> is there is none).
1173
1174 Can be used to efficiently iterate over records in the resultset:
1175
1176   my $rs = $schema->resultset('CD')->search;
1177   while (my $cd = $rs->next) {
1178     print $cd->title;
1179   }
1180
1181 Note that you need to store the resultset object, and call C<next> on it.
1182 Calling C<< resultset('Table')->next >> repeatedly will always return the
1183 first record from the resultset.
1184
1185 =cut
1186
1187 sub next {
1188   my ($self) = @_;
1189
1190   if (my $cache = $self->get_cache) {
1191     $self->{all_cache_position} ||= 0;
1192     return $cache->[$self->{all_cache_position}++];
1193   }
1194
1195   if ($self->{attrs}{cache}) {
1196     delete $self->{pager};
1197     $self->{all_cache_position} = 1;
1198     return ($self->all)[0];
1199   }
1200
1201   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1202
1203   $self->{_stashed_results} = $self->_construct_results
1204     or return undef;
1205
1206   return shift @{$self->{_stashed_results}};
1207 }
1208
1209 # Constructs as many results as it can in one pass while respecting
1210 # cursor laziness. Several modes of operation:
1211 #
1212 # * Always builds everything present in @{$self->{_stashed_rows}}
1213 # * If called with $fetch_all true - pulls everything off the cursor and
1214 #   builds all result structures (or objects) in one pass
1215 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1216 #   and if the resultset is ordered properly by the left side:
1217 #   * Fetches stuff off the cursor until the "master object" changes,
1218 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1219 #   OR
1220 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1221 #     was requested (there is no other way to collapse except for an
1222 #     eager cursor)
1223 # * If no collapse is requested - just get the next row, construct and
1224 #   return
1225 sub _construct_results {
1226   my ($self, $fetch_all) = @_;
1227
1228   my $rsrc = $self->result_source;
1229   my $attrs = $self->_resolved_attrs;
1230
1231   if (
1232     ! $fetch_all
1233       and
1234     ! $attrs->{order_by}
1235       and
1236     $attrs->{collapse}
1237       and
1238     my @pcols = $rsrc->primary_columns
1239   ) {
1240     # default order for collapsing unless the user asked for something
1241     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1242     $attrs->{_ordered_for_collapse} = 1;
1243     $attrs->{_order_is_artificial} = 1;
1244   }
1245
1246   # this will be used as both initial raw-row collector AND as a RV of
1247   # _construct_results. Not regrowing the array twice matters a lot...
1248   # a surprising amount actually
1249   my $rows = delete $self->{_stashed_rows};
1250
1251   my $cursor; # we may not need one at all
1252
1253   my $did_fetch_all = $fetch_all;
1254
1255   if ($fetch_all) {
1256     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1257     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1258   }
1259   elsif( $attrs->{collapse} ) {
1260
1261     # a cursor will need to be closed over in case of collapse
1262     $cursor = $self->cursor;
1263
1264     $attrs->{_ordered_for_collapse} = (
1265       (
1266         $attrs->{order_by}
1267           and
1268         $rsrc->schema
1269               ->storage
1270                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1271       ) ? 1 : 0
1272     ) unless defined $attrs->{_ordered_for_collapse};
1273
1274     if (! $attrs->{_ordered_for_collapse}) {
1275       $did_fetch_all = 1;
1276
1277       # instead of looping over ->next, use ->all in stealth mode
1278       # *without* calling a ->reset afterwards
1279       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1280       if (! $cursor->{_done}) {
1281         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1282         $cursor->{_done} = 1;
1283       }
1284     }
1285   }
1286
1287   if (! $did_fetch_all and ! @{$rows||[]} ) {
1288     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1289     $cursor ||= $self->cursor;
1290     if (scalar (my @r = $cursor->next) ) {
1291       $rows = [ \@r ];
1292     }
1293   }
1294
1295   return undef unless @{$rows||[]};
1296
1297   # sanity check - people are too clever for their own good
1298   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1299
1300     my $multiplied_selectors;
1301     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1302       if (
1303         $aliastypes->{multiplying}{$sel_alias}
1304           or
1305         $aliastypes->{premultiplied}{$sel_alias}
1306       ) {
1307         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1308       }
1309     }
1310
1311     for my $i (0 .. $#{$attrs->{as}} ) {
1312       my $sel = $attrs->{select}[$i];
1313
1314       if (ref $sel eq 'SCALAR') {
1315         $sel = $$sel;
1316       }
1317       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1318         $sel = $$sel->[0];
1319       }
1320
1321       $self->throw_exception(
1322         'Result collapse not possible - selection from a has_many source redirected to the main object'
1323       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1324     }
1325   }
1326
1327   # hotspot - skip the setter
1328   my $res_class = $self->_result_class;
1329
1330   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1331     $res_class->can ('inflate_result')
1332       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1333   };
1334
1335   my $infmap = $attrs->{as};
1336
1337   $self->{_result_inflator}{is_core_row} = ( (
1338     $inflator_cref
1339       ==
1340     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1341   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1342
1343   $self->{_result_inflator}{is_hri} = ( (
1344     ! $self->{_result_inflator}{is_core_row}
1345       and
1346     $inflator_cref == (
1347       require DBIx::Class::ResultClass::HashRefInflator
1348         &&
1349       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1350     )
1351   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1352
1353
1354   if (! $attrs->{_related_results_construction}) {
1355     # construct a much simpler array->hash folder for the one-table cases right here
1356     if ($self->{_result_inflator}{is_hri}) {
1357       for my $r (@$rows) {
1358         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1359       }
1360     }
1361     # FIXME SUBOPTIMAL this is a very very very hot spot
1362     # while rather optimal we can *still* do much better, by
1363     # building a smarter Row::inflate_result(), and
1364     # switch to feeding it data via a much leaner interface
1365     #
1366     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1367     # this particular resultset size
1368     elsif (@$rows < 60) {
1369       for my $r (@$rows) {
1370         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1371       }
1372     }
1373     else {
1374       eval sprintf (
1375         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1376         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1377       );
1378     }
1379   }
1380   else {
1381     my $parser_type =
1382         $self->{_result_inflator}{is_hri}       ? 'hri'
1383       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1384       :                                           'classic_nonpruning'
1385     ;
1386
1387     # $args and $attrs to _mk_row_parser are separated to delineate what is
1388     # core collapser stuff and what is dbic $rs specific
1389     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1390       eval => 1,
1391       inflate_map => $infmap,
1392       collapse => $attrs->{collapse},
1393       premultiplied => $attrs->{_main_source_premultiplied},
1394       hri_style => $self->{_result_inflator}{is_hri},
1395       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1396     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1397
1398     # column_info metadata historically hasn't been too reliable.
1399     # We need to start fixing this somehow (the collapse resolver
1400     # can't work without it). Add an explicit check for the *main*
1401     # result, hopefully this will gradually weed out such errors
1402     #
1403     # FIXME - this is a temporary kludge that reduces performance
1404     # It is however necessary for the time being
1405     my ($unrolled_non_null_cols_to_check, $err);
1406
1407     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1408
1409       $err =
1410         'Collapse aborted due to invalid ResultSource metadata - the following '
1411       . 'selections are declared non-nullable but NULLs were retrieved: '
1412       ;
1413
1414       my @violating_idx;
1415       COL: for my $i (@$check_non_null_cols) {
1416         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1417       }
1418
1419       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1420         if @violating_idx;
1421
1422       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1423     }
1424
1425     my $next_cref =
1426       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1427     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1428 sub {
1429   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1430   my @r = $cursor->next or return;
1431   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1432     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1433   }
1434   \@r
1435 }
1436 EOS
1437     : sub {
1438         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1439         my @r = $cursor->next or return;
1440         \@r
1441       }
1442     ;
1443
1444     $self->{_row_parser}{$parser_type}{cref}->(
1445       $rows,
1446       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1447     );
1448
1449     # Special-case multi-object HRI - there is no $inflator_cref pass
1450     unless ($self->{_result_inflator}{is_hri}) {
1451       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1452     }
1453   }
1454
1455   # The @$rows check seems odd at first - why wouldn't we want to warn
1456   # regardless? The issue is things like find() etc, where the user
1457   # *knows* only one result will come back. In these cases the ->all
1458   # is not a pessimization, but rather something we actually want
1459   carp_unique(
1460     'Unable to properly collapse has_many results in iterator mode due '
1461   . 'to order criteria - performed an eager cursor slurp underneath. '
1462   . 'Consider using ->all() instead'
1463   ) if ( ! $fetch_all and @$rows > 1 );
1464
1465   return $rows;
1466 }
1467
1468 =head2 result_source
1469
1470 =over 4
1471
1472 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1473
1474 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1475
1476 =back
1477
1478 An accessor for the primary ResultSource object from which this ResultSet
1479 is derived.
1480
1481 =head2 result_class
1482
1483 =over 4
1484
1485 =item Arguments: $result_class?
1486
1487 =item Return Value: $result_class
1488
1489 =back
1490
1491 An accessor for the class to use when creating result objects. Defaults to
1492 C<< result_source->result_class >> - which in most cases is the name of the
1493 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1494
1495 Note that changing the result_class will also remove any components
1496 that were originally loaded in the source class via
1497 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1498 in the original source class will not run.
1499
1500 =cut
1501
1502 sub result_class {
1503   my ($self, $result_class) = @_;
1504   if ($result_class) {
1505
1506     # don't fire this for an object
1507     $self->ensure_class_loaded($result_class)
1508       unless ref($result_class);
1509
1510     if ($self->get_cache) {
1511       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1512     }
1513     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1514     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1515       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1516     }
1517
1518     $self->_result_class($result_class);
1519
1520     delete $self->{_result_inflator};
1521   }
1522   $self->_result_class;
1523 }
1524
1525 =head2 count
1526
1527 =over 4
1528
1529 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1530
1531 =item Return Value: $count
1532
1533 =back
1534
1535 Performs an SQL C<COUNT> with the same query as the resultset was built
1536 with to find the number of elements. Passing arguments is equivalent to
1537 C<< $rs->search ($cond, \%attrs)->count >>
1538
1539 =cut
1540
1541 sub count {
1542   my $self = shift;
1543   return $self->search(@_)->count if @_ and defined $_[0];
1544   return scalar @{ $self->get_cache } if $self->get_cache;
1545
1546   my $attrs = { %{ $self->_resolved_attrs } };
1547
1548   # this is a little optimization - it is faster to do the limit
1549   # adjustments in software, instead of a subquery
1550   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1551
1552   my $crs;
1553   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1554     $crs = $self->_count_subq_rs ($attrs);
1555   }
1556   else {
1557     $crs = $self->_count_rs ($attrs);
1558   }
1559   my $count = $crs->next;
1560
1561   $count -= $offset if $offset;
1562   $count = $rows if $rows and $rows < $count;
1563   $count = 0 if ($count < 0);
1564
1565   return $count;
1566 }
1567
1568 =head2 count_rs
1569
1570 =over 4
1571
1572 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1573
1574 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1575
1576 =back
1577
1578 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1579 This can be very handy for subqueries:
1580
1581   ->search( { amount => $some_rs->count_rs->as_query } )
1582
1583 As with regular resultsets the SQL query will be executed only after
1584 the resultset is accessed via L</next> or L</all>. That would return
1585 the same single value obtainable via L</count>.
1586
1587 =cut
1588
1589 sub count_rs {
1590   my $self = shift;
1591   return $self->search(@_)->count_rs if @_;
1592
1593   # this may look like a lack of abstraction (count() does about the same)
1594   # but in fact an _rs *must* use a subquery for the limits, as the
1595   # software based limiting can not be ported if this $rs is to be used
1596   # in a subquery itself (i.e. ->as_query)
1597   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1598     return $self->_count_subq_rs($self->{_attrs});
1599   }
1600   else {
1601     return $self->_count_rs($self->{_attrs});
1602   }
1603 }
1604
1605 #
1606 # returns a ResultSetColumn object tied to the count query
1607 #
1608 sub _count_rs {
1609   my ($self, $attrs) = @_;
1610
1611   my $rsrc = $self->result_source;
1612
1613   my $tmp_attrs = { %$attrs };
1614   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1615   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1616
1617   # overwrite the selector (supplied by the storage)
1618   $rsrc->resultset_class->new($rsrc, {
1619     %$tmp_attrs,
1620     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1621     as => 'count',
1622   })->get_column ('count');
1623 }
1624
1625 #
1626 # same as above but uses a subquery
1627 #
1628 sub _count_subq_rs {
1629   my ($self, $attrs) = @_;
1630
1631   my $rsrc = $self->result_source;
1632
1633   my $sub_attrs = { %$attrs };
1634   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1635   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1636
1637   # if we multi-prefetch we group_by something unique, as this is what we would
1638   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1639   if ( $attrs->{collapse}  ) {
1640     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1641       $rsrc->_identifying_column_set || $self->throw_exception(
1642         'Unable to construct a unique group_by criteria properly collapsing the '
1643       . 'has_many prefetch before count()'
1644       );
1645     } ]
1646   }
1647
1648   # Calculate subquery selector
1649   if (my $g = $sub_attrs->{group_by}) {
1650
1651     my $sql_maker = $rsrc->storage->sql_maker;
1652
1653     # necessary as the group_by may refer to aliased functions
1654     my $sel_index;
1655     for my $sel (@{$attrs->{select}}) {
1656       $sel_index->{$sel->{-as}} = $sel
1657         if (ref $sel eq 'HASH' and $sel->{-as});
1658     }
1659
1660     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1661     # also look for named aggregates referred in the having clause
1662     # having often contains scalarrefs - thus parse it out entirely
1663     my @parts = @$g;
1664     if ($attrs->{having}) {
1665       local $sql_maker->{having_bind};
1666       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1667       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1668       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1669         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1670         # if we don't unset it we screw up retarded but unfortunately working
1671         # 'MAX(foo.bar)' => { '>', 3 }
1672         $sql_maker->{name_sep} = '';
1673       }
1674
1675       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1676
1677       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1678       my %seen_having;
1679
1680       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1681       # and if all fails for an utterly naive quoted scalar-with-function
1682       while ($having_sql =~ /
1683         $rquote $sep $lquote (.+?) $rquote
1684           |
1685         [\s,] \w+ \. (\w+) [\s,]
1686           |
1687         [\s,] $lquote (.+?) $rquote [\s,]
1688       /gx) {
1689         my $part = $1 || $2 || $3;  # one of them matched if we got here
1690         unless ($seen_having{$part}++) {
1691           push @parts, $part;
1692         }
1693       }
1694     }
1695
1696     for (@parts) {
1697       my $colpiece = $sel_index->{$_} || $_;
1698
1699       # unqualify join-based group_by's. Arcane but possible query
1700       # also horrible horrible hack to alias a column (not a func.)
1701       # (probably need to introduce SQLA syntax)
1702       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1703         my $as = $colpiece;
1704         $as =~ s/\./__/;
1705         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1706       }
1707       push @{$sub_attrs->{select}}, $colpiece;
1708     }
1709   }
1710   else {
1711     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1712     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1713   }
1714
1715   return $rsrc->resultset_class
1716                ->new ($rsrc, $sub_attrs)
1717                 ->as_subselect_rs
1718                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1719                   ->get_column ('count');
1720 }
1721
1722
1723 =head2 count_literal
1724
1725 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1726 should only be used in that context. See L</search_literal> for further info.
1727
1728 =over 4
1729
1730 =item Arguments: $sql_fragment, @standalone_bind_values
1731
1732 =item Return Value: $count
1733
1734 =back
1735
1736 Counts the results in a literal query. Equivalent to calling L</search_literal>
1737 with the passed arguments, then L</count>.
1738
1739 =cut
1740
1741 sub count_literal { shift->search_literal(@_)->count; }
1742
1743 =head2 all
1744
1745 =over 4
1746
1747 =item Arguments: none
1748
1749 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1750
1751 =back
1752
1753 Returns all elements in the resultset.
1754
1755 =cut
1756
1757 sub all {
1758   my $self = shift;
1759   if(@_) {
1760     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1761   }
1762
1763   delete @{$self}{qw/_stashed_rows _stashed_results/};
1764
1765   if (my $c = $self->get_cache) {
1766     return @$c;
1767   }
1768
1769   $self->cursor->reset;
1770
1771   my $objs = $self->_construct_results('fetch_all') || [];
1772
1773   $self->set_cache($objs) if $self->{attrs}{cache};
1774
1775   return @$objs;
1776 }
1777
1778 =head2 reset
1779
1780 =over 4
1781
1782 =item Arguments: none
1783
1784 =item Return Value: $self
1785
1786 =back
1787
1788 Resets the resultset's cursor, so you can iterate through the elements again.
1789 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1790 another query.
1791
1792 =cut
1793
1794 sub reset {
1795   my ($self) = @_;
1796
1797   delete @{$self}{qw/_stashed_rows _stashed_results/};
1798   $self->{all_cache_position} = 0;
1799   $self->cursor->reset;
1800   return $self;
1801 }
1802
1803 =head2 first
1804
1805 =over 4
1806
1807 =item Arguments: none
1808
1809 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1810
1811 =back
1812
1813 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1814 an object for the first result (or C<undef> if the resultset is empty).
1815
1816 =cut
1817
1818 sub first {
1819   return $_[0]->reset->next;
1820 }
1821
1822
1823 # _rs_update_delete
1824 #
1825 # Determines whether and what type of subquery is required for the $rs operation.
1826 # If grouping is necessary either supplies its own, or verifies the current one
1827 # After all is done delegates to the proper storage method.
1828
1829 sub _rs_update_delete {
1830   my ($self, $op, $values) = @_;
1831
1832   my $rsrc = $self->result_source;
1833   my $storage = $rsrc->schema->storage;
1834
1835   my $attrs = { %{$self->_resolved_attrs} };
1836
1837   my $join_classifications;
1838   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1839
1840   # do we need a subquery for any reason?
1841   my $needs_subq = (
1842     defined $existing_group_by
1843       or
1844     # if {from} is unparseable wrap a subq
1845     ref($attrs->{from}) ne 'ARRAY'
1846       or
1847     # limits call for a subq
1848     $self->_has_resolved_attr(qw/rows offset/)
1849   );
1850
1851   # simplify the joinmap, so we can further decide if a subq is necessary
1852   if (!$needs_subq and @{$attrs->{from}} > 1) {
1853
1854     ($attrs->{from}, $join_classifications) =
1855       $storage->_prune_unused_joins ($attrs);
1856
1857     # any non-pruneable non-local restricting joins imply subq
1858     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1859   }
1860
1861   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1862   $needs_subq ||= (
1863     (ref $attrs->{from}[0]) ne 'HASH'
1864       or
1865     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1866   );
1867
1868   my ($cond, $guard);
1869   # do we need anything like a subquery?
1870   if (! $needs_subq) {
1871     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1872     # a condition containing 'me' or other table prefixes will not work
1873     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1874     $cond = do {
1875       my $sqla = $rsrc->storage->sql_maker;
1876       local $sqla->{_dequalify_idents} = 1;
1877       \[ $sqla->_recurse_where($self->{cond}) ];
1878     };
1879   }
1880   else {
1881     # we got this far - means it is time to wrap a subquery
1882     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1883       sprintf(
1884         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1885         $op,
1886         $rsrc->source_name,
1887       )
1888     );
1889
1890     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1891     delete $attrs->{$_} for qw/select as collapse/;
1892     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1893
1894     # this will be consumed by the pruner waaaaay down the stack
1895     $attrs->{_force_prune_multiplying_joins} = 1;
1896
1897     my $subrs = (ref $self)->new($rsrc, $attrs);
1898
1899     if (@$idcols == 1) {
1900       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1901     }
1902     elsif ($storage->_use_multicolumn_in) {
1903       # no syntax for calling this properly yet
1904       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1905       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1906         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1907         $subrs->as_query
1908       ),
1909     }
1910     else {
1911       # if all else fails - get all primary keys and operate over a ORed set
1912       # wrap in a transaction for consistency
1913       # this is where the group_by/multiplication starts to matter
1914       if (
1915         $existing_group_by
1916           or
1917         # we do not need to check pre-multipliers, since if the premulti is there, its
1918         # parent (who is multi) will be there too
1919         keys %{ $join_classifications->{multiplying} || {} }
1920       ) {
1921         # make sure if there is a supplied group_by it matches the columns compiled above
1922         # perfectly. Anything else can not be sanely executed on most databases so croak
1923         # right then and there
1924         if ($existing_group_by) {
1925           my @current_group_by = map
1926             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1927             @$existing_group_by
1928           ;
1929
1930           if (
1931             join ("\x00", sort @current_group_by)
1932               ne
1933             join ("\x00", sort @{$attrs->{columns}} )
1934           ) {
1935             $self->throw_exception (
1936               "You have just attempted a $op operation on a resultset which does group_by"
1937               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1938               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1939               . ' kind of queries. Please retry the operation with a modified group_by or'
1940               . ' without using one at all.'
1941             );
1942           }
1943         }
1944
1945         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1946       }
1947
1948       $guard = $storage->txn_scope_guard;
1949
1950       for my $row ($subrs->cursor->all) {
1951         push @$cond, { map
1952           { $idcols->[$_] => $row->[$_] }
1953           (0 .. $#$idcols)
1954         };
1955       }
1956     }
1957   }
1958
1959   my $res = $cond ? $storage->$op (
1960     $rsrc,
1961     $op eq 'update' ? $values : (),
1962     $cond,
1963   ) : '0E0';
1964
1965   $guard->commit if $guard;
1966
1967   return $res;
1968 }
1969
1970 =head2 update
1971
1972 =over 4
1973
1974 =item Arguments: \%values
1975
1976 =item Return Value: $underlying_storage_rv
1977
1978 =back
1979
1980 Sets the specified columns in the resultset to the supplied values in a
1981 single query. Note that this will not run any accessor/set_column/update
1982 triggers, nor will it update any result object instances derived from this
1983 resultset (this includes the contents of the L<resultset cache|/set_cache>
1984 if any). See L</update_all> if you need to execute any on-update
1985 triggers or cascades defined either by you or a
1986 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1987
1988 The return value is a pass through of what the underlying
1989 storage backend returned, and may vary. See L<DBI/execute> for the most
1990 common case.
1991
1992 =head3 CAVEAT
1993
1994 Note that L</update> does not process/deflate any of the values passed in.
1995 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1996 ensure manually that any value passed to this method will stringify to
1997 something the RDBMS knows how to deal with. A notable example is the
1998 handling of L<DateTime> objects, for more info see:
1999 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2000
2001 =cut
2002
2003 sub update {
2004   my ($self, $values) = @_;
2005   $self->throw_exception('Values for update must be a hash')
2006     unless ref $values eq 'HASH';
2007
2008   return $self->_rs_update_delete ('update', $values);
2009 }
2010
2011 =head2 update_all
2012
2013 =over 4
2014
2015 =item Arguments: \%values
2016
2017 =item Return Value: 1
2018
2019 =back
2020
2021 Fetches all objects and updates them one at a time via
2022 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2023 triggers, while L</update> will not.
2024
2025 =cut
2026
2027 sub update_all {
2028   my ($self, $values) = @_;
2029   $self->throw_exception('Values for update_all must be a hash')
2030     unless ref $values eq 'HASH';
2031
2032   my $guard = $self->result_source->schema->txn_scope_guard;
2033   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2034   $guard->commit;
2035   return 1;
2036 }
2037
2038 =head2 delete
2039
2040 =over 4
2041
2042 =item Arguments: none
2043
2044 =item Return Value: $underlying_storage_rv
2045
2046 =back
2047
2048 Deletes the rows matching this resultset in a single query. Note that this
2049 will not run any delete triggers, nor will it alter the
2050 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2051 derived from this resultset (this includes the contents of the
2052 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2053 execute any on-delete triggers or cascades defined either by you or a
2054 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2055
2056 The return value is a pass through of what the underlying storage backend
2057 returned, and may vary. See L<DBI/execute> for the most common case.
2058
2059 =cut
2060
2061 sub delete {
2062   my $self = shift;
2063   $self->throw_exception('delete does not accept any arguments')
2064     if @_;
2065
2066   return $self->_rs_update_delete ('delete');
2067 }
2068
2069 =head2 delete_all
2070
2071 =over 4
2072
2073 =item Arguments: none
2074
2075 =item Return Value: 1
2076
2077 =back
2078
2079 Fetches all objects and deletes them one at a time via
2080 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2081 triggers, while L</delete> will not.
2082
2083 =cut
2084
2085 sub delete_all {
2086   my $self = shift;
2087   $self->throw_exception('delete_all does not accept any arguments')
2088     if @_;
2089
2090   my $guard = $self->result_source->schema->txn_scope_guard;
2091   $_->delete for $self->all;
2092   $guard->commit;
2093   return 1;
2094 }
2095
2096 =head2 populate
2097
2098 =over 4
2099
2100 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2101
2102 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2103
2104 =back
2105
2106 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2107 arrayrefs.
2108
2109 =over
2110
2111 =item NOTE
2112
2113 The context of this method call has an important effect on what is
2114 submitted to storage. In void context data is fed directly to fastpath
2115 insertion routines provided by the underlying storage (most often
2116 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2117 L<insert|DBIx::Class::Row/insert> calls on the
2118 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2119 augmentation of these methods provided by components. For example if you
2120 are using something like L<DBIx::Class::UUIDColumns> to create primary
2121 keys for you, you will find that your PKs are empty.  In this case you
2122 will have to explicitly force scalar or list context in order to create
2123 those values.
2124
2125 =back
2126
2127 In non-void (scalar or list) context, this method is simply a wrapper
2128 for L</create>. Depending on list or scalar context either a list of
2129 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2130 containing these objects is returned.
2131
2132 When supplying data in "arrayref of arrayrefs" invocation style, the
2133 first element should be a list of column names and each subsequent
2134 element should be a data value in the earlier specified column order.
2135 For example:
2136
2137   $schema->resultset("Artist")->populate([
2138     [ qw( artistid name ) ],
2139     [ 100, 'A Formally Unknown Singer' ],
2140     [ 101, 'A singer that jumped the shark two albums ago' ],
2141     [ 102, 'An actually cool singer' ],
2142   ]);
2143
2144 For the arrayref of hashrefs style each hashref should be a structure
2145 suitable for passing to L</create>. Multi-create is also permitted with
2146 this syntax.
2147
2148   $schema->resultset("Artist")->populate([
2149      { artistid => 4, name => 'Manufactured Crap', cds => [
2150         { title => 'My First CD', year => 2006 },
2151         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2152       ],
2153      },
2154      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2155         { title => 'My parents sold me to a record company', year => 2005 },
2156         { title => 'Why Am I So Ugly?', year => 2006 },
2157         { title => 'I Got Surgery and am now Popular', year => 2007 }
2158       ],
2159      },
2160   ]);
2161
2162 If you attempt a void-context multi-create as in the example above (each
2163 Artist also has the related list of CDs), and B<do not> supply the
2164 necessary autoinc foreign key information, this method will proxy to the
2165 less efficient L</create>, and then throw the Result objects away. In this
2166 case there are obviously no benefits to using this method over L</create>.
2167
2168 =cut
2169
2170 sub populate {
2171   my $self = shift;
2172
2173   # cruft placed in standalone method
2174   my $data = $self->_normalize_populate_args(@_);
2175
2176   return unless @$data;
2177
2178   if(defined wantarray) {
2179     my @created = map { $self->create($_) } @$data;
2180     return wantarray ? @created : \@created;
2181   }
2182   else {
2183     my $first = $data->[0];
2184
2185     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2186     # it relationship data
2187     my (@rels, @columns);
2188     my $rsrc = $self->result_source;
2189     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2190     for (keys %$first) {
2191       my $ref = ref $first->{$_};
2192       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2193         ? push @rels, $_
2194         : push @columns, $_
2195       ;
2196     }
2197
2198     my @pks = $rsrc->primary_columns;
2199
2200     ## do the belongs_to relationships
2201     foreach my $index (0..$#$data) {
2202
2203       # delegate to create() for any dataset without primary keys with specified relationships
2204       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2205         for my $r (@rels) {
2206           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2207             my @ret = $self->populate($data);
2208             return;
2209           }
2210         }
2211       }
2212
2213       foreach my $rel (@rels) {
2214         next unless ref $data->[$index]->{$rel} eq "HASH";
2215         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2216         my (undef, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2217         my $related = $result->result_source->_resolve_condition(
2218           $reverse_relinfo->{cond},
2219           $self,
2220           $result,
2221           $rel,
2222         );
2223
2224         delete $data->[$index]->{$rel};
2225         $data->[$index] = {%{$data->[$index]}, %$related};
2226
2227         push @columns, keys %$related if $index == 0;
2228       }
2229     }
2230
2231     ## inherit the data locked in the conditions of the resultset
2232     my ($rs_data) = $self->_merge_with_rscond({});
2233     delete @{$rs_data}{@columns};
2234
2235     ## do bulk insert on current row
2236     $rsrc->storage->insert_bulk(
2237       $rsrc,
2238       [@columns, keys %$rs_data],
2239       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2240     );
2241
2242     ## do the has_many relationships
2243     foreach my $item (@$data) {
2244
2245       my $main_row;
2246
2247       foreach my $rel (@rels) {
2248         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2249
2250         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2251
2252         my $child = $main_row->$rel;
2253
2254         my $related = $child->result_source->_resolve_condition(
2255           $rels->{$rel}{cond},
2256           $child,
2257           $main_row,
2258           $rel,
2259         );
2260
2261         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2262         my @populate = map { {%$_, %$related} } @rows_to_add;
2263
2264         $child->populate( \@populate );
2265       }
2266     }
2267   }
2268 }
2269
2270
2271 # populate() arguments went over several incarnations
2272 # What we ultimately support is AoH
2273 sub _normalize_populate_args {
2274   my ($self, $arg) = @_;
2275
2276   if (ref $arg eq 'ARRAY') {
2277     if (!@$arg) {
2278       return [];
2279     }
2280     elsif (ref $arg->[0] eq 'HASH') {
2281       return $arg;
2282     }
2283     elsif (ref $arg->[0] eq 'ARRAY') {
2284       my @ret;
2285       my @colnames = @{$arg->[0]};
2286       foreach my $values (@{$arg}[1 .. $#$arg]) {
2287         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2288       }
2289       return \@ret;
2290     }
2291   }
2292
2293   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2294 }
2295
2296 =head2 pager
2297
2298 =over 4
2299
2300 =item Arguments: none
2301
2302 =item Return Value: L<$pager|Data::Page>
2303
2304 =back
2305
2306 Returns a L<Data::Page> object for the current resultset. Only makes
2307 sense for queries with a C<page> attribute.
2308
2309 To get the full count of entries for a paged resultset, call
2310 C<total_entries> on the L<Data::Page> object.
2311
2312 =cut
2313
2314 sub pager {
2315   my ($self) = @_;
2316
2317   return $self->{pager} if $self->{pager};
2318
2319   my $attrs = $self->{attrs};
2320   if (!defined $attrs->{page}) {
2321     $self->throw_exception("Can't create pager for non-paged rs");
2322   }
2323   elsif ($attrs->{page} <= 0) {
2324     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2325   }
2326   $attrs->{rows} ||= 10;
2327
2328   # throw away the paging flags and re-run the count (possibly
2329   # with a subselect) to get the real total count
2330   my $count_attrs = { %$attrs };
2331   delete @{$count_attrs}{qw/rows offset page pager/};
2332
2333   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2334
2335   require DBIx::Class::ResultSet::Pager;
2336   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2337     sub { $total_rs->count },  #lazy-get the total
2338     $attrs->{rows},
2339     $self->{attrs}{page},
2340   );
2341 }
2342
2343 =head2 page
2344
2345 =over 4
2346
2347 =item Arguments: $page_number
2348
2349 =item Return Value: L<$resultset|/search>
2350
2351 =back
2352
2353 Returns a resultset for the $page_number page of the resultset on which page
2354 is called, where each page contains a number of rows equal to the 'rows'
2355 attribute set on the resultset (10 by default).
2356
2357 =cut
2358
2359 sub page {
2360   my ($self, $page) = @_;
2361   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2362 }
2363
2364 =head2 new_result
2365
2366 =over 4
2367
2368 =item Arguments: \%col_data
2369
2370 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2371
2372 =back
2373
2374 Creates a new result object in the resultset's result class and returns
2375 it. The row is not inserted into the database at this point, call
2376 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2377 will tell you whether the result object has been inserted or not.
2378
2379 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2380
2381 =cut
2382
2383 sub new_result {
2384   my ($self, $values) = @_;
2385
2386   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2387     if @_ > 2;
2388
2389   $self->throw_exception( "new_result expects a hashref" )
2390     unless (ref $values eq 'HASH');
2391
2392   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2393
2394   my $new = $self->result_class->new({
2395     %$merged_cond,
2396     ( @$cols_from_relations
2397       ? (-cols_from_relations => $cols_from_relations)
2398       : ()
2399     ),
2400     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2401   });
2402
2403   if (
2404     reftype($new) eq 'HASH'
2405       and
2406     ! keys %$new
2407       and
2408     blessed($new)
2409   ) {
2410     carp_unique (sprintf (
2411       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2412       $self->result_class,
2413     ));
2414   }
2415
2416   $new;
2417 }
2418
2419 # _merge_with_rscond
2420 #
2421 # Takes a simple hash of K/V data and returns its copy merged with the
2422 # condition already present on the resultset. Additionally returns an
2423 # arrayref of value/condition names, which were inferred from related
2424 # objects (this is needed for in-memory related objects)
2425 sub _merge_with_rscond {
2426   my ($self, $data) = @_;
2427
2428   my (%new_data, @cols_from_relations);
2429
2430   my $alias = $self->{attrs}{alias};
2431
2432   if (! defined $self->{cond}) {
2433     # just massage $data below
2434   }
2435   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2436     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2437     @cols_from_relations = keys %new_data;
2438   }
2439   elsif (ref $self->{cond} ne 'HASH') {
2440     $self->throw_exception(
2441       "Can't abstract implicit construct, resultset condition not a hash"
2442     );
2443   }
2444   else {
2445     if ($self->{cond}) {
2446       my $implied = $self->_remove_alias(
2447         $self->result_source->schema->storage->_collapse_cond($self->{cond}),
2448         $alias,
2449       );
2450
2451       for my $c (keys %$implied) {
2452         my $v = $implied->{$c};
2453         if ( ! length ref $v or is_plain_value($v) ) {
2454           $new_data{$c} = $v;
2455         }
2456         elsif (
2457           ref $v eq 'HASH' and keys %$v == 1 and exists $v->{'='} and is_literal_value($v->{'='})
2458         ) {
2459           $new_data{$c} = $v->{'='};
2460         }
2461       }
2462     }
2463   }
2464
2465   # precedence must be given to passed values over values inherited from
2466   # the cond, so the order here is important.
2467   %new_data = (
2468     %new_data,
2469     %{ $self->_remove_alias($data, $alias) },
2470   );
2471
2472   return (\%new_data, \@cols_from_relations);
2473 }
2474
2475 # _has_resolved_attr
2476 #
2477 # determines if the resultset defines at least one
2478 # of the attributes supplied
2479 #
2480 # used to determine if a subquery is necessary
2481 #
2482 # supports some virtual attributes:
2483 #   -join
2484 #     This will scan for any joins being present on the resultset.
2485 #     It is not a mere key-search but a deep inspection of {from}
2486 #
2487
2488 sub _has_resolved_attr {
2489   my ($self, @attr_names) = @_;
2490
2491   my $attrs = $self->_resolved_attrs;
2492
2493   my %extra_checks;
2494
2495   for my $n (@attr_names) {
2496     if (grep { $n eq $_ } (qw/-join/) ) {
2497       $extra_checks{$n}++;
2498       next;
2499     }
2500
2501     my $attr =  $attrs->{$n};
2502
2503     next if not defined $attr;
2504
2505     if (ref $attr eq 'HASH') {
2506       return 1 if keys %$attr;
2507     }
2508     elsif (ref $attr eq 'ARRAY') {
2509       return 1 if @$attr;
2510     }
2511     else {
2512       return 1 if $attr;
2513     }
2514   }
2515
2516   # a resolved join is expressed as a multi-level from
2517   return 1 if (
2518     $extra_checks{-join}
2519       and
2520     ref $attrs->{from} eq 'ARRAY'
2521       and
2522     @{$attrs->{from}} > 1
2523   );
2524
2525   return 0;
2526 }
2527
2528 # _remove_alias
2529 #
2530 # Remove the specified alias from the specified query hash. A copy is made so
2531 # the original query is not modified.
2532
2533 sub _remove_alias {
2534   my ($self, $query, $alias) = @_;
2535
2536   my %orig = %{ $query || {} };
2537   my %unaliased;
2538
2539   foreach my $key (keys %orig) {
2540     if ($key !~ /\./) {
2541       $unaliased{$key} = $orig{$key};
2542       next;
2543     }
2544     $unaliased{$1} = $orig{$key}
2545       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2546   }
2547
2548   return \%unaliased;
2549 }
2550
2551 =head2 as_query
2552
2553 =over 4
2554
2555 =item Arguments: none
2556
2557 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2558
2559 =back
2560
2561 Returns the SQL query and bind vars associated with the invocant.
2562
2563 This is generally used as the RHS for a subquery.
2564
2565 =cut
2566
2567 sub as_query {
2568   my $self = shift;
2569
2570   my $attrs = { %{ $self->_resolved_attrs } };
2571
2572   my $aq = $self->result_source->storage->_select_args_to_query (
2573     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2574   );
2575
2576   $aq;
2577 }
2578
2579 =head2 find_or_new
2580
2581 =over 4
2582
2583 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2584
2585 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2586
2587 =back
2588
2589   my $artist = $schema->resultset('Artist')->find_or_new(
2590     { artist => 'fred' }, { key => 'artists' });
2591
2592   $cd->cd_to_producer->find_or_new({ producer => $producer },
2593                                    { key => 'primary' });
2594
2595 Find an existing record from this resultset using L</find>. if none exists,
2596 instantiate a new result object and return it. The object will not be saved
2597 into your storage until you call L<DBIx::Class::Row/insert> on it.
2598
2599 You most likely want this method when looking for existing rows using a unique
2600 constraint that is not the primary key, or looking for related rows.
2601
2602 If you want objects to be saved immediately, use L</find_or_create> instead.
2603
2604 B<Note>: Make sure to read the documentation of L</find> and understand the
2605 significance of the C<key> attribute, as its lack may skew your search, and
2606 subsequently result in spurious new objects.
2607
2608 B<Note>: Take care when using C<find_or_new> with a table having
2609 columns with default values that you intend to be automatically
2610 supplied by the database (e.g. an auto_increment primary key column).
2611 In normal usage, the value of such columns should NOT be included at
2612 all in the call to C<find_or_new>, even when set to C<undef>.
2613
2614 =cut
2615
2616 sub find_or_new {
2617   my $self     = shift;
2618   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2619   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2620   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2621     return $row;
2622   }
2623   return $self->new_result($hash);
2624 }
2625
2626 =head2 create
2627
2628 =over 4
2629
2630 =item Arguments: \%col_data
2631
2632 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2633
2634 =back
2635
2636 Attempt to create a single new row or a row with multiple related rows
2637 in the table represented by the resultset (and related tables). This
2638 will not check for duplicate rows before inserting, use
2639 L</find_or_create> to do that.
2640
2641 To create one row for this resultset, pass a hashref of key/value
2642 pairs representing the columns of the table and the values you wish to
2643 store. If the appropriate relationships are set up, foreign key fields
2644 can also be passed an object representing the foreign row, and the
2645 value will be set to its primary key.
2646
2647 To create related objects, pass a hashref of related-object column values
2648 B<keyed on the relationship name>. If the relationship is of type C<multi>
2649 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2650 The process will correctly identify columns holding foreign keys, and will
2651 transparently populate them from the keys of the corresponding relation.
2652 This can be applied recursively, and will work correctly for a structure
2653 with an arbitrary depth and width, as long as the relationships actually
2654 exists and the correct column data has been supplied.
2655
2656 Instead of hashrefs of plain related data (key/value pairs), you may
2657 also pass new or inserted objects. New objects (not inserted yet, see
2658 L</new_result>), will be inserted into their appropriate tables.
2659
2660 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2661
2662 Example of creating a new row.
2663
2664   $person_rs->create({
2665     name=>"Some Person",
2666     email=>"somebody@someplace.com"
2667   });
2668
2669 Example of creating a new row and also creating rows in a related C<has_many>
2670 or C<has_one> resultset.  Note Arrayref.
2671
2672   $artist_rs->create(
2673      { artistid => 4, name => 'Manufactured Crap', cds => [
2674         { title => 'My First CD', year => 2006 },
2675         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2676       ],
2677      },
2678   );
2679
2680 Example of creating a new row and also creating a row in a related
2681 C<belongs_to> resultset. Note Hashref.
2682
2683   $cd_rs->create({
2684     title=>"Music for Silly Walks",
2685     year=>2000,
2686     artist => {
2687       name=>"Silly Musician",
2688     }
2689   });
2690
2691 =over
2692
2693 =item WARNING
2694
2695 When subclassing ResultSet never attempt to override this method. Since
2696 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2697 lot of the internals simply never call it, so your override will be
2698 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2699 or L<DBIx::Class::Row/insert> depending on how early in the
2700 L</create> process you need to intervene. See also warning pertaining to
2701 L</new>.
2702
2703 =back
2704
2705 =cut
2706
2707 sub create {
2708   my ($self, $col_data) = @_;
2709   $self->throw_exception( "create needs a hashref" )
2710     unless ref $col_data eq 'HASH';
2711   return $self->new_result($col_data)->insert;
2712 }
2713
2714 =head2 find_or_create
2715
2716 =over 4
2717
2718 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2719
2720 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2721
2722 =back
2723
2724   $cd->cd_to_producer->find_or_create({ producer => $producer },
2725                                       { key => 'primary' });
2726
2727 Tries to find a record based on its primary key or unique constraints; if none
2728 is found, creates one and returns that instead.
2729
2730   my $cd = $schema->resultset('CD')->find_or_create({
2731     cdid   => 5,
2732     artist => 'Massive Attack',
2733     title  => 'Mezzanine',
2734     year   => 2005,
2735   });
2736
2737 Also takes an optional C<key> attribute, to search by a specific key or unique
2738 constraint. For example:
2739
2740   my $cd = $schema->resultset('CD')->find_or_create(
2741     {
2742       artist => 'Massive Attack',
2743       title  => 'Mezzanine',
2744     },
2745     { key => 'cd_artist_title' }
2746   );
2747
2748 B<Note>: Make sure to read the documentation of L</find> and understand the
2749 significance of the C<key> attribute, as its lack may skew your search, and
2750 subsequently result in spurious row creation.
2751
2752 B<Note>: Because find_or_create() reads from the database and then
2753 possibly inserts based on the result, this method is subject to a race
2754 condition. Another process could create a record in the table after
2755 the find has completed and before the create has started. To avoid
2756 this problem, use find_or_create() inside a transaction.
2757
2758 B<Note>: Take care when using C<find_or_create> with a table having
2759 columns with default values that you intend to be automatically
2760 supplied by the database (e.g. an auto_increment primary key column).
2761 In normal usage, the value of such columns should NOT be included at
2762 all in the call to C<find_or_create>, even when set to C<undef>.
2763
2764 See also L</find> and L</update_or_create>. For information on how to declare
2765 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2766
2767 If you need to know if an existing row was found or a new one created use
2768 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2769 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2770 database!
2771
2772   my $cd = $schema->resultset('CD')->find_or_new({
2773     cdid   => 5,
2774     artist => 'Massive Attack',
2775     title  => 'Mezzanine',
2776     year   => 2005,
2777   });
2778
2779   if( !$cd->in_storage ) {
2780       # do some stuff
2781       $cd->insert;
2782   }
2783
2784 =cut
2785
2786 sub find_or_create {
2787   my $self     = shift;
2788   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2789   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2790   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2791     return $row;
2792   }
2793   return $self->create($hash);
2794 }
2795
2796 =head2 update_or_create
2797
2798 =over 4
2799
2800 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2801
2802 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2803
2804 =back
2805
2806   $resultset->update_or_create({ col => $val, ... });
2807
2808 Like L</find_or_create>, but if a row is found it is immediately updated via
2809 C<< $found_row->update (\%col_data) >>.
2810
2811
2812 Takes an optional C<key> attribute to search on a specific unique constraint.
2813 For example:
2814
2815   # In your application
2816   my $cd = $schema->resultset('CD')->update_or_create(
2817     {
2818       artist => 'Massive Attack',
2819       title  => 'Mezzanine',
2820       year   => 1998,
2821     },
2822     { key => 'cd_artist_title' }
2823   );
2824
2825   $cd->cd_to_producer->update_or_create({
2826     producer => $producer,
2827     name => 'harry',
2828   }, {
2829     key => 'primary',
2830   });
2831
2832 B<Note>: Make sure to read the documentation of L</find> and understand the
2833 significance of the C<key> attribute, as its lack may skew your search, and
2834 subsequently result in spurious row creation.
2835
2836 B<Note>: Take care when using C<update_or_create> with a table having
2837 columns with default values that you intend to be automatically
2838 supplied by the database (e.g. an auto_increment primary key column).
2839 In normal usage, the value of such columns should NOT be included at
2840 all in the call to C<update_or_create>, even when set to C<undef>.
2841
2842 See also L</find> and L</find_or_create>. For information on how to declare
2843 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2844
2845 If you need to know if an existing row was updated or a new one created use
2846 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2847 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2848 database!
2849
2850 =cut
2851
2852 sub update_or_create {
2853   my $self = shift;
2854   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2855   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2856
2857   my $row = $self->find($cond, $attrs);
2858   if (defined $row) {
2859     $row->update($cond);
2860     return $row;
2861   }
2862
2863   return $self->create($cond);
2864 }
2865
2866 =head2 update_or_new
2867
2868 =over 4
2869
2870 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2871
2872 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2873
2874 =back
2875
2876   $resultset->update_or_new({ col => $val, ... });
2877
2878 Like L</find_or_new> but if a row is found it is immediately updated via
2879 C<< $found_row->update (\%col_data) >>.
2880
2881 For example:
2882
2883   # In your application
2884   my $cd = $schema->resultset('CD')->update_or_new(
2885     {
2886       artist => 'Massive Attack',
2887       title  => 'Mezzanine',
2888       year   => 1998,
2889     },
2890     { key => 'cd_artist_title' }
2891   );
2892
2893   if ($cd->in_storage) {
2894       # the cd was updated
2895   }
2896   else {
2897       # the cd is not yet in the database, let's insert it
2898       $cd->insert;
2899   }
2900
2901 B<Note>: Make sure to read the documentation of L</find> and understand the
2902 significance of the C<key> attribute, as its lack may skew your search, and
2903 subsequently result in spurious new objects.
2904
2905 B<Note>: Take care when using C<update_or_new> with a table having
2906 columns with default values that you intend to be automatically
2907 supplied by the database (e.g. an auto_increment primary key column).
2908 In normal usage, the value of such columns should NOT be included at
2909 all in the call to C<update_or_new>, even when set to C<undef>.
2910
2911 See also L</find>, L</find_or_create> and L</find_or_new>.
2912
2913 =cut
2914
2915 sub update_or_new {
2916     my $self  = shift;
2917     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2918     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2919
2920     my $row = $self->find( $cond, $attrs );
2921     if ( defined $row ) {
2922         $row->update($cond);
2923         return $row;
2924     }
2925
2926     return $self->new_result($cond);
2927 }
2928
2929 =head2 get_cache
2930
2931 =over 4
2932
2933 =item Arguments: none
2934
2935 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2936
2937 =back
2938
2939 Gets the contents of the cache for the resultset, if the cache is set.
2940
2941 The cache is populated either by using the L</prefetch> attribute to
2942 L</search> or by calling L</set_cache>.
2943
2944 =cut
2945
2946 sub get_cache {
2947   shift->{all_cache};
2948 }
2949
2950 =head2 set_cache
2951
2952 =over 4
2953
2954 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2955
2956 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2957
2958 =back
2959
2960 Sets the contents of the cache for the resultset. Expects an arrayref
2961 of objects of the same class as those produced by the resultset. Note that
2962 if the cache is set, the resultset will return the cached objects rather
2963 than re-querying the database even if the cache attr is not set.
2964
2965 The contents of the cache can also be populated by using the
2966 L</prefetch> attribute to L</search>.
2967
2968 =cut
2969
2970 sub set_cache {
2971   my ( $self, $data ) = @_;
2972   $self->throw_exception("set_cache requires an arrayref")
2973       if defined($data) && (ref $data ne 'ARRAY');
2974   $self->{all_cache} = $data;
2975 }
2976
2977 =head2 clear_cache
2978
2979 =over 4
2980
2981 =item Arguments: none
2982
2983 =item Return Value: undef
2984
2985 =back
2986
2987 Clears the cache for the resultset.
2988
2989 =cut
2990
2991 sub clear_cache {
2992   shift->set_cache(undef);
2993 }
2994
2995 =head2 is_paged
2996
2997 =over 4
2998
2999 =item Arguments: none
3000
3001 =item Return Value: true, if the resultset has been paginated
3002
3003 =back
3004
3005 =cut
3006
3007 sub is_paged {
3008   my ($self) = @_;
3009   return !!$self->{attrs}{page};
3010 }
3011
3012 =head2 is_ordered
3013
3014 =over 4
3015
3016 =item Arguments: none
3017
3018 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3019
3020 =back
3021
3022 =cut
3023
3024 sub is_ordered {
3025   my ($self) = @_;
3026   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3027 }
3028
3029 =head2 related_resultset
3030
3031 =over 4
3032
3033 =item Arguments: $rel_name
3034
3035 =item Return Value: L<$resultset|/search>
3036
3037 =back
3038
3039 Returns a related resultset for the supplied relationship name.
3040
3041   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3042
3043 =cut
3044
3045 sub related_resultset {
3046   my ($self, $rel) = @_;
3047
3048   return $self->{related_resultsets}{$rel}
3049     if defined $self->{related_resultsets}{$rel};
3050
3051   return $self->{related_resultsets}{$rel} = do {
3052     my $rsrc = $self->result_source;
3053     my $rel_info = $rsrc->relationship_info($rel);
3054
3055     $self->throw_exception(
3056       "search_related: result source '" . $rsrc->source_name .
3057         "' has no such relationship $rel")
3058       unless $rel_info;
3059
3060     my $attrs = $self->_chain_relationship($rel);
3061
3062     my $join_count = $attrs->{seen_join}{$rel};
3063
3064     my $alias = $self->result_source->storage
3065         ->relname_to_table_alias($rel, $join_count);
3066
3067     # since this is search_related, and we already slid the select window inwards
3068     # (the select/as attrs were deleted in the beginning), we need to flip all
3069     # left joins to inner, so we get the expected results
3070     # read the comment on top of the actual function to see what this does
3071     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3072
3073
3074     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3075     delete @{$attrs}{qw(result_class alias)};
3076
3077     my $rel_source = $rsrc->related_source($rel);
3078
3079     my $new = do {
3080
3081       # The reason we do this now instead of passing the alias to the
3082       # search_rs below is that if you wrap/overload resultset on the
3083       # source you need to know what alias it's -going- to have for things
3084       # to work sanely (e.g. RestrictWithObject wants to be able to add
3085       # extra query restrictions, and these may need to be $alias.)
3086
3087       my $rel_attrs = $rel_source->resultset_attributes;
3088       local $rel_attrs->{alias} = $alias;
3089
3090       $rel_source->resultset
3091                  ->search_rs(
3092                      undef, {
3093                        %$attrs,
3094                        where => $attrs->{where},
3095                    });
3096     };
3097
3098     if (my $cache = $self->get_cache) {
3099       my @related_cache = map
3100         { $_->related_resultset($rel)->get_cache || () }
3101         @$cache
3102       ;
3103
3104       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3105     }
3106
3107     $new;
3108   };
3109 }
3110
3111 =head2 current_source_alias
3112
3113 =over 4
3114
3115 =item Arguments: none
3116
3117 =item Return Value: $source_alias
3118
3119 =back
3120
3121 Returns the current table alias for the result source this resultset is built
3122 on, that will be used in the SQL query. Usually it is C<me>.
3123
3124 Currently the source alias that refers to the result set returned by a
3125 L</search>/L</find> family method depends on how you got to the resultset: it's
3126 C<me> by default, but eg. L</search_related> aliases it to the related result
3127 source name (and keeps C<me> referring to the original result set). The long
3128 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3129 (and make this method unnecessary).
3130
3131 Thus it's currently necessary to use this method in predefined queries (see
3132 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3133 source alias of the current result set:
3134
3135   # in a result set class
3136   sub modified_by {
3137     my ($self, $user) = @_;
3138
3139     my $me = $self->current_source_alias;
3140
3141     return $self->search({
3142       "$me.modified" => $user->id,
3143     });
3144   }
3145
3146 =cut
3147
3148 sub current_source_alias {
3149   return (shift->{attrs} || {})->{alias} || 'me';
3150 }
3151
3152 =head2 as_subselect_rs
3153
3154 =over 4
3155
3156 =item Arguments: none
3157
3158 =item Return Value: L<$resultset|/search>
3159
3160 =back
3161
3162 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3163 "virtual view" by including it as a subquery within the from clause.  From this
3164 point on, any joined tables are inaccessible to ->search on the resultset (as if
3165 it were simply where-filtered without joins).  For example:
3166
3167  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3168
3169  # 'x' now pollutes the query namespace
3170
3171  # So the following works as expected
3172  my $ok_rs = $rs->search({'x.other' => 1});
3173
3174  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3175  # def) we look for one row with contradictory terms and join in another table
3176  # (aliased 'x_2') which we never use
3177  my $broken_rs = $rs->search({'x.name' => 'def'});
3178
3179  my $rs2 = $rs->as_subselect_rs;
3180
3181  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3182  my $not_joined_rs = $rs2->search({'x.other' => 1});
3183
3184  # works as expected: finds a 'table' row related to two x rows (abc and def)
3185  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3186
3187 Another example of when one might use this would be to select a subset of
3188 columns in a group by clause:
3189
3190  my $rs = $schema->resultset('Bar')->search(undef, {
3191    group_by => [qw{ id foo_id baz_id }],
3192  })->as_subselect_rs->search(undef, {
3193    columns => [qw{ id foo_id }]
3194  });
3195
3196 In the above example normally columns would have to be equal to the group by,
3197 but because we isolated the group by into a subselect the above works.
3198
3199 =cut
3200
3201 sub as_subselect_rs {
3202   my $self = shift;
3203
3204   my $attrs = $self->_resolved_attrs;
3205
3206   my $fresh_rs = (ref $self)->new (
3207     $self->result_source
3208   );
3209
3210   # these pieces will be locked in the subquery
3211   delete $fresh_rs->{cond};
3212   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3213
3214   return $fresh_rs->search( {}, {
3215     from => [{
3216       $attrs->{alias} => $self->as_query,
3217       -alias  => $attrs->{alias},
3218       -rsrc   => $self->result_source,
3219     }],
3220     alias => $attrs->{alias},
3221   });
3222 }
3223
3224 # This code is called by search_related, and makes sure there
3225 # is clear separation between the joins before, during, and
3226 # after the relationship. This information is needed later
3227 # in order to properly resolve prefetch aliases (any alias
3228 # with a relation_chain_depth less than the depth of the
3229 # current prefetch is not considered)
3230 #
3231 # The increments happen twice per join. An even number means a
3232 # relationship specified via a search_related, whereas an odd
3233 # number indicates a join/prefetch added via attributes
3234 #
3235 # Also this code will wrap the current resultset (the one we
3236 # chain to) in a subselect IFF it contains limiting attributes
3237 sub _chain_relationship {
3238   my ($self, $rel) = @_;
3239   my $source = $self->result_source;
3240   my $attrs = { %{$self->{attrs}||{}} };
3241
3242   # we need to take the prefetch the attrs into account before we
3243   # ->_resolve_join as otherwise they get lost - captainL
3244   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3245
3246   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3247
3248   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3249
3250   my $from;
3251   my @force_subq_attrs = qw/offset rows group_by having/;
3252
3253   if (
3254     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3255       ||
3256     $self->_has_resolved_attr (@force_subq_attrs)
3257   ) {
3258     # Nuke the prefetch (if any) before the new $rs attrs
3259     # are resolved (prefetch is useless - we are wrapping
3260     # a subquery anyway).
3261     my $rs_copy = $self->search;
3262     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3263       $rs_copy->{attrs}{join},
3264       delete $rs_copy->{attrs}{prefetch},
3265     );
3266
3267     $from = [{
3268       -rsrc   => $source,
3269       -alias  => $attrs->{alias},
3270       $attrs->{alias} => $rs_copy->as_query,
3271     }];
3272     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3273     $seen->{-relation_chain_depth} = 0;
3274   }
3275   elsif ($attrs->{from}) {  #shallow copy suffices
3276     $from = [ @{$attrs->{from}} ];
3277   }
3278   else {
3279     $from = [{
3280       -rsrc  => $source,
3281       -alias => $attrs->{alias},
3282       $attrs->{alias} => $source->from,
3283     }];
3284   }
3285
3286   my $jpath = ($seen->{-relation_chain_depth})
3287     ? $from->[-1][0]{-join_path}
3288     : [];
3289
3290   my @requested_joins = $source->_resolve_join(
3291     $join,
3292     $attrs->{alias},
3293     $seen,
3294     $jpath,
3295   );
3296
3297   push @$from, @requested_joins;
3298
3299   $seen->{-relation_chain_depth}++;
3300
3301   # if $self already had a join/prefetch specified on it, the requested
3302   # $rel might very well be already included. What we do in this case
3303   # is effectively a no-op (except that we bump up the chain_depth on
3304   # the join in question so we could tell it *is* the search_related)
3305   my $already_joined;
3306
3307   # we consider the last one thus reverse
3308   for my $j (reverse @requested_joins) {
3309     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3310     if ($rel eq $last_j) {
3311       $j->[0]{-relation_chain_depth}++;
3312       $already_joined++;
3313       last;
3314     }
3315   }
3316
3317   unless ($already_joined) {
3318     push @$from, $source->_resolve_join(
3319       $rel,
3320       $attrs->{alias},
3321       $seen,
3322       $jpath,
3323     );
3324   }
3325
3326   $seen->{-relation_chain_depth}++;
3327
3328   return {%$attrs, from => $from, seen_join => $seen};
3329 }
3330
3331 sub _resolved_attrs {
3332   my $self = shift;
3333   return $self->{_attrs} if $self->{_attrs};
3334
3335   my $attrs  = { %{ $self->{attrs} || {} } };
3336   my $source = $self->result_source;
3337   my $alias  = $attrs->{alias};
3338
3339   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3340     if $attrs->{collapse} and $attrs->{distinct};
3341
3342   # default selection list
3343   $attrs->{columns} = [ $source->columns ]
3344     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3345
3346   # merge selectors together
3347   for (qw/columns select as/) {
3348     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3349       if $attrs->{$_} or $attrs->{"+$_"};
3350   }
3351
3352   # disassemble columns
3353   my (@sel, @as);
3354   if (my $cols = delete $attrs->{columns}) {
3355     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3356       if (ref $c eq 'HASH') {
3357         for my $as (sort keys %$c) {
3358           push @sel, $c->{$as};
3359           push @as, $as;
3360         }
3361       }
3362       else {
3363         push @sel, $c;
3364         push @as, $c;
3365       }
3366     }
3367   }
3368
3369   # when trying to weed off duplicates later do not go past this point -
3370   # everything added from here on is unbalanced "anyone's guess" stuff
3371   my $dedup_stop_idx = $#as;
3372
3373   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3374     if $attrs->{as};
3375   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3376     if $attrs->{select};
3377
3378   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3379   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3380
3381   # disqualify all $alias.col as-bits (inflate-map mandated)
3382   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3383
3384   # de-duplicate the result (remove *identical* select/as pairs)
3385   # and also die on duplicate {as} pointing to different {select}s
3386   # not using a c-style for as the condition is prone to shrinkage
3387   my $seen;
3388   my $i = 0;
3389   while ($i <= $dedup_stop_idx) {
3390     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3391       splice @sel, $i, 1;
3392       splice @as, $i, 1;
3393       $dedup_stop_idx--;
3394     }
3395     elsif ($seen->{$as[$i]}++) {
3396       $self->throw_exception(
3397         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3398       );
3399     }
3400     else {
3401       $i++;
3402     }
3403   }
3404
3405   $attrs->{select} = \@sel;
3406   $attrs->{as} = \@as;
3407
3408   $attrs->{from} ||= [{
3409     -rsrc   => $source,
3410     -alias  => $self->{attrs}{alias},
3411     $self->{attrs}{alias} => $source->from,
3412   }];
3413
3414   if ( $attrs->{join} || $attrs->{prefetch} ) {
3415
3416     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3417       if ref $attrs->{from} ne 'ARRAY';
3418
3419     my $join = (delete $attrs->{join}) || {};
3420
3421     if ( defined $attrs->{prefetch} ) {
3422       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3423     }
3424
3425     $attrs->{from} =    # have to copy here to avoid corrupting the original
3426       [
3427         @{ $attrs->{from} },
3428         $source->_resolve_join(
3429           $join,
3430           $alias,
3431           { %{ $attrs->{seen_join} || {} } },
3432           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3433             ? $attrs->{from}[-1][0]{-join_path}
3434             : []
3435           ,
3436         )
3437       ];
3438   }
3439
3440   if ( defined $attrs->{order_by} ) {
3441     $attrs->{order_by} = (
3442       ref( $attrs->{order_by} ) eq 'ARRAY'
3443       ? [ @{ $attrs->{order_by} } ]
3444       : [ $attrs->{order_by} || () ]
3445     );
3446   }
3447
3448   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3449     $attrs->{group_by} = [ $attrs->{group_by} ];
3450   }
3451
3452
3453   # generate selections based on the prefetch helper
3454   my ($prefetch, @prefetch_select, @prefetch_as);
3455   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3456     if defined $attrs->{prefetch};
3457
3458   if ($prefetch) {
3459
3460     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3461       if $attrs->{_dark_selector};
3462
3463     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3464       if defined $attrs->{collapse} and ! $attrs->{collapse};
3465
3466     $attrs->{collapse} = 1;
3467
3468     # this is a separate structure (we don't look in {from} directly)
3469     # as the resolver needs to shift things off the lists to work
3470     # properly (identical-prefetches on different branches)
3471     my $join_map = {};
3472     if (ref $attrs->{from} eq 'ARRAY') {
3473
3474       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3475
3476       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3477         next unless $j->[0]{-alias};
3478         next unless $j->[0]{-join_path};
3479         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3480
3481         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3482
3483         my $p = $join_map;
3484         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3485         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3486       }
3487     }
3488
3489     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3490
3491     # save these for after distinct resolution
3492     @prefetch_select = map { $_->[0] } @prefetch;
3493     @prefetch_as = map { $_->[1] } @prefetch;
3494   }
3495
3496   # run through the resulting joinstructure (starting from our current slot)
3497   # and unset collapse if proven unnecessary
3498   #
3499   # also while we are at it find out if the current root source has
3500   # been premultiplied by previous related_source chaining
3501   #
3502   # this allows to predict whether a root object with all other relation
3503   # data set to NULL is in fact unique
3504   if ($attrs->{collapse}) {
3505
3506     if (ref $attrs->{from} eq 'ARRAY') {
3507
3508       if (@{$attrs->{from}} == 1) {
3509         # no joins - no collapse
3510         $attrs->{collapse} = 0;
3511       }
3512       else {
3513         # find where our table-spec starts
3514         my @fromlist = @{$attrs->{from}};
3515         while (@fromlist) {
3516           my $t = shift @fromlist;
3517
3518           my $is_multi;
3519           # me vs join from-spec distinction - a ref means non-root
3520           if (ref $t eq 'ARRAY') {
3521             $t = $t->[0];
3522             $is_multi ||= ! $t->{-is_single};
3523           }
3524           last if ($t->{-alias} && $t->{-alias} eq $alias);
3525           $attrs->{_main_source_premultiplied} ||= $is_multi;
3526         }
3527
3528         # no non-singles remaining, nor any premultiplication - nothing to collapse
3529         if (
3530           ! $attrs->{_main_source_premultiplied}
3531             and
3532           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3533         ) {
3534           $attrs->{collapse} = 0;
3535         }
3536       }
3537     }
3538
3539     else {
3540       # if we can not analyze the from - err on the side of safety
3541       $attrs->{_main_source_premultiplied} = 1;
3542     }
3543   }
3544
3545   # generate the distinct induced group_by before injecting the prefetched select/as parts
3546   if (delete $attrs->{distinct}) {
3547     if ($attrs->{group_by}) {
3548       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3549     }
3550     else {
3551       $attrs->{_grouped_by_distinct} = 1;
3552       # distinct affects only the main selection part, not what prefetch may add below
3553       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3554
3555       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3556       # The thinking is: if we are collapsing the subquerying prefetch engine will
3557       # rip stuff apart for us anyway, and we do not want to have a potentially
3558       # function-converted external order_by
3559       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3560       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3561     }
3562   }
3563
3564   # inject prefetch-bound selection (if any)
3565   push @{$attrs->{select}}, @prefetch_select;
3566   push @{$attrs->{as}}, @prefetch_as;
3567
3568   # whether we can get away with the dumbest (possibly DBI-internal) collapser
3569   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3570     $attrs->{_related_results_construction} = 1;
3571   }
3572
3573   # if both page and offset are specified, produce a combined offset
3574   # even though it doesn't make much sense, this is what pre 081xx has
3575   # been doing
3576   if (my $page = delete $attrs->{page}) {
3577     $attrs->{offset} =
3578       ($attrs->{rows} * ($page - 1))
3579             +
3580       ($attrs->{offset} || 0)
3581     ;
3582   }
3583
3584   return $self->{_attrs} = $attrs;
3585 }
3586
3587 sub _rollout_attr {
3588   my ($self, $attr) = @_;
3589
3590   if (ref $attr eq 'HASH') {
3591     return $self->_rollout_hash($attr);
3592   } elsif (ref $attr eq 'ARRAY') {
3593     return $self->_rollout_array($attr);
3594   } else {
3595     return [$attr];
3596   }
3597 }
3598
3599 sub _rollout_array {
3600   my ($self, $attr) = @_;
3601
3602   my @rolled_array;
3603   foreach my $element (@{$attr}) {
3604     if (ref $element eq 'HASH') {
3605       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3606     } elsif (ref $element eq 'ARRAY') {
3607       #  XXX - should probably recurse here
3608       push( @rolled_array, @{$self->_rollout_array($element)} );
3609     } else {
3610       push( @rolled_array, $element );
3611     }
3612   }
3613   return \@rolled_array;
3614 }
3615
3616 sub _rollout_hash {
3617   my ($self, $attr) = @_;
3618
3619   my @rolled_array;
3620   foreach my $key (keys %{$attr}) {
3621     push( @rolled_array, { $key => $attr->{$key} } );
3622   }
3623   return \@rolled_array;
3624 }
3625
3626 sub _calculate_score {
3627   my ($self, $a, $b) = @_;
3628
3629   if (defined $a xor defined $b) {
3630     return 0;
3631   }
3632   elsif (not defined $a) {
3633     return 1;
3634   }
3635
3636   if (ref $b eq 'HASH') {
3637     my ($b_key) = keys %{$b};
3638     if (ref $a eq 'HASH') {
3639       my ($a_key) = keys %{$a};
3640       if ($a_key eq $b_key) {
3641         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3642       } else {
3643         return 0;
3644       }
3645     } else {
3646       return ($a eq $b_key) ? 1 : 0;
3647     }
3648   } else {
3649     if (ref $a eq 'HASH') {
3650       my ($a_key) = keys %{$a};
3651       return ($b eq $a_key) ? 1 : 0;
3652     } else {
3653       return ($b eq $a) ? 1 : 0;
3654     }
3655   }
3656 }
3657
3658 sub _merge_joinpref_attr {
3659   my ($self, $orig, $import) = @_;
3660
3661   return $import unless defined($orig);
3662   return $orig unless defined($import);
3663
3664   $orig = $self->_rollout_attr($orig);
3665   $import = $self->_rollout_attr($import);
3666
3667   my $seen_keys;
3668   foreach my $import_element ( @{$import} ) {
3669     # find best candidate from $orig to merge $b_element into
3670     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3671     foreach my $orig_element ( @{$orig} ) {
3672       my $score = $self->_calculate_score( $orig_element, $import_element );
3673       if ($score > $best_candidate->{score}) {
3674         $best_candidate->{position} = $position;
3675         $best_candidate->{score} = $score;
3676       }
3677       $position++;
3678     }
3679     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3680     $import_key = '' if not defined $import_key;
3681
3682     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3683       push( @{$orig}, $import_element );
3684     } else {
3685       my $orig_best = $orig->[$best_candidate->{position}];
3686       # merge orig_best and b_element together and replace original with merged
3687       if (ref $orig_best ne 'HASH') {
3688         $orig->[$best_candidate->{position}] = $import_element;
3689       } elsif (ref $import_element eq 'HASH') {
3690         my ($key) = keys %{$orig_best};
3691         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3692       }
3693     }
3694     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3695   }
3696
3697   return @$orig ? $orig : ();
3698 }
3699
3700 {
3701   my $hm;
3702
3703   sub _merge_attr {
3704     $hm ||= do {
3705       require Hash::Merge;
3706       my $hm = Hash::Merge->new;
3707
3708       $hm->specify_behavior({
3709         SCALAR => {
3710           SCALAR => sub {
3711             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3712
3713             if ($defl xor $defr) {
3714               return [ $defl ? $_[0] : $_[1] ];
3715             }
3716             elsif (! $defl) {
3717               return [];
3718             }
3719             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3720               return [ $_[0] ];
3721             }
3722             else {
3723               return [$_[0], $_[1]];
3724             }
3725           },
3726           ARRAY => sub {
3727             return $_[1] if !defined $_[0];
3728             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3729             return [$_[0], @{$_[1]}]
3730           },
3731           HASH  => sub {
3732             return [] if !defined $_[0] and !keys %{$_[1]};
3733             return [ $_[1] ] if !defined $_[0];
3734             return [ $_[0] ] if !keys %{$_[1]};
3735             return [$_[0], $_[1]]
3736           },
3737         },
3738         ARRAY => {
3739           SCALAR => sub {
3740             return $_[0] if !defined $_[1];
3741             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3742             return [@{$_[0]}, $_[1]]
3743           },
3744           ARRAY => sub {
3745             my @ret = @{$_[0]} or return $_[1];
3746             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3747             my %idx = map { $_ => 1 } @ret;
3748             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3749             \@ret;
3750           },
3751           HASH => sub {
3752             return [ $_[1] ] if ! @{$_[0]};
3753             return $_[0] if !keys %{$_[1]};
3754             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3755             return [ @{$_[0]}, $_[1] ];
3756           },
3757         },
3758         HASH => {
3759           SCALAR => sub {
3760             return [] if !keys %{$_[0]} and !defined $_[1];
3761             return [ $_[0] ] if !defined $_[1];
3762             return [ $_[1] ] if !keys %{$_[0]};
3763             return [$_[0], $_[1]]
3764           },
3765           ARRAY => sub {
3766             return [] if !keys %{$_[0]} and !@{$_[1]};
3767             return [ $_[0] ] if !@{$_[1]};
3768             return $_[1] if !keys %{$_[0]};
3769             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3770             return [ $_[0], @{$_[1]} ];
3771           },
3772           HASH => sub {
3773             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3774             return [ $_[0] ] if !keys %{$_[1]};
3775             return [ $_[1] ] if !keys %{$_[0]};
3776             return [ $_[0] ] if $_[0] eq $_[1];
3777             return [ $_[0], $_[1] ];
3778           },
3779         }
3780       } => 'DBIC_RS_ATTR_MERGER');
3781       $hm;
3782     };
3783
3784     return $hm->merge ($_[1], $_[2]);
3785   }
3786 }
3787
3788 sub STORABLE_freeze {
3789   my ($self, $cloning) = @_;
3790   my $to_serialize = { %$self };
3791
3792   # A cursor in progress can't be serialized (and would make little sense anyway)
3793   # the parser can be regenerated (and can't be serialized)
3794   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3795
3796   # nor is it sensical to store a not-yet-fired-count pager
3797   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3798     delete $to_serialize->{pager};
3799   }
3800
3801   Storable::nfreeze($to_serialize);
3802 }
3803
3804 # need this hook for symmetry
3805 sub STORABLE_thaw {
3806   my ($self, $cloning, $serialized) = @_;
3807
3808   %$self = %{ Storable::thaw($serialized) };
3809
3810   $self;
3811 }
3812
3813
3814 =head2 throw_exception
3815
3816 See L<DBIx::Class::Schema/throw_exception> for details.
3817
3818 =cut
3819
3820 sub throw_exception {
3821   my $self=shift;
3822
3823   if (ref $self and my $rsrc = $self->result_source) {
3824     $rsrc->throw_exception(@_)
3825   }
3826   else {
3827     DBIx::Class::Exception->throw(@_);
3828   }
3829 }
3830
3831 1;
3832
3833 __END__
3834
3835 # XXX: FIXME: Attributes docs need clearing up
3836
3837 =head1 ATTRIBUTES
3838
3839 Attributes are used to refine a ResultSet in various ways when
3840 searching for data. They can be passed to any method which takes an
3841 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3842 L</count>.
3843
3844 Default attributes can be set on the result class using
3845 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3846 the CAVEATS on that feature before using it!)
3847
3848 These are in no particular order:
3849
3850 =head2 order_by
3851
3852 =over 4
3853
3854 =item Value: ( $order_by | \@order_by | \%order_by )
3855
3856 =back
3857
3858 Which column(s) to order the results by.
3859
3860 [The full list of suitable values is documented in
3861 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3862 common options.]
3863
3864 If a single column name, or an arrayref of names is supplied, the
3865 argument is passed through directly to SQL. The hashref syntax allows
3866 for connection-agnostic specification of ordering direction:
3867
3868  For descending order:
3869
3870   order_by => { -desc => [qw/col1 col2 col3/] }
3871
3872  For explicit ascending order:
3873
3874   order_by => { -asc => 'col' }
3875
3876 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3877 supported, although you are strongly encouraged to use the hashref
3878 syntax as outlined above.
3879
3880 =head2 columns
3881
3882 =over 4
3883
3884 =item Value: \@columns | \%columns | $column
3885
3886 =back
3887
3888 Shortcut to request a particular set of columns to be retrieved. Each
3889 column spec may be a string (a table column name), or a hash (in which
3890 case the key is the C<as> value, and the value is used as the C<select>
3891 expression). Adds C<me.> onto the start of any column without a C<.> in
3892 it and sets C<select> from that, then auto-populates C<as> from
3893 C<select> as normal. (You may also use the C<cols> attribute, as in
3894 earlier versions of DBIC, but this is deprecated)
3895
3896 Essentially C<columns> does the same as L</select> and L</as>.
3897
3898     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
3899
3900 is the same as
3901
3902     select => [qw(some_column another_column)],
3903     as     => [qw(some_column dbic_slot)]
3904
3905 If you want to individually retrieve related columns (in essence perform
3906 manual prefetch) you have to make sure to specify the correct inflation slot
3907 chain such that it matches existing relationships:
3908
3909     my $rs = $schema->resultset('Artist')->search({}, {
3910         # required to tell DBIC to collapse has_many relationships
3911         collapse => 1,
3912         join     => { cds => 'tracks'},
3913         '+columns'  => {
3914           'cds.cdid'         => 'cds.cdid',
3915           'cds.tracks.title' => 'tracks.title',
3916         },
3917     });
3918
3919 =head2 +columns
3920
3921 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
3922 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
3923 with a unary plus operator before it, which is the same as simply C<columns>.
3924
3925 =over 4
3926
3927 =item Value: \@extra_columns
3928
3929 =back
3930
3931 Indicates additional columns to be selected from storage. Works the same as
3932 L</columns> but adds columns to the current selection. (You may also use the
3933 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3934 deprecated)
3935
3936   $schema->resultset('CD')->search(undef, {
3937     '+columns' => ['artist.name'],
3938     join => ['artist']
3939   });
3940
3941 would return all CDs and include a 'name' column to the information
3942 passed to object inflation. Note that the 'artist' is the name of the
3943 column (or relationship) accessor, and 'name' is the name of the column
3944 accessor in the related table.
3945
3946 =head2 select
3947
3948 =over 4
3949
3950 =item Value: \@select_columns
3951
3952 =back
3953
3954 Indicates which columns should be selected from the storage. You can use
3955 column names, or in the case of RDBMS back ends, function or stored procedure
3956 names:
3957
3958   $rs = $schema->resultset('Employee')->search(undef, {
3959     select => [
3960       'name',
3961       { count => 'employeeid' },
3962       { max => { length => 'name' }, -as => 'longest_name' }
3963     ]
3964   });
3965
3966   # Equivalent SQL
3967   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3968
3969 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3970 use L</select>, to instruct DBIx::Class how to store the result of the column.
3971 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3972 identifier aliasing. You can however alias a function, so you can use it in
3973 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3974 attribute> supplied as shown in the example above.
3975
3976 =head2 +select
3977
3978 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
3979 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
3980 with a unary plus operator before it, which is the same as simply C<select>.
3981
3982 =over 4
3983
3984 =item Value: \@extra_select_columns
3985
3986 =back
3987
3988 Indicates additional columns to be selected from storage.  Works the same as
3989 L</select> but adds columns to the current selection, instead of specifying
3990 a new explicit list.
3991
3992 =head2 as
3993
3994 =over 4
3995
3996 =item Value: \@inflation_names
3997
3998 =back
3999
4000 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4001 slot name in which the column value will be stored within the
4002 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4003 identifier by the C<get_column> method (or via the object accessor B<if one
4004 with the same name already exists>) as shown below. The L</as> attribute has
4005 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4006
4007   $rs = $schema->resultset('Employee')->search(undef, {
4008     select => [
4009       'name',
4010       { count => 'employeeid' },
4011       { max => { length => 'name' }, -as => 'longest_name' }
4012     ],
4013     as => [qw/
4014       name
4015       employee_count
4016       max_name_length
4017     /],
4018   });
4019
4020 If the object against which the search is performed already has an accessor
4021 matching a column name specified in C<as>, the value can be retrieved using
4022 the accessor as normal:
4023
4024   my $name = $employee->name();
4025
4026 If on the other hand an accessor does not exist in the object, you need to
4027 use C<get_column> instead:
4028
4029   my $employee_count = $employee->get_column('employee_count');
4030
4031 You can create your own accessors if required - see
4032 L<DBIx::Class::Manual::Cookbook> for details.
4033
4034 =head2 +as
4035
4036 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4037 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4038 with a unary plus operator before it, which is the same as simply C<as>.
4039
4040 =over 4
4041
4042 =item Value: \@extra_inflation_names
4043
4044 =back
4045
4046 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4047
4048 =head2 join
4049
4050 =over 4
4051
4052 =item Value: ($rel_name | \@rel_names | \%rel_names)
4053
4054 =back
4055
4056 Contains a list of relationships that should be joined for this query.  For
4057 example:
4058
4059   # Get CDs by Nine Inch Nails
4060   my $rs = $schema->resultset('CD')->search(
4061     { 'artist.name' => 'Nine Inch Nails' },
4062     { join => 'artist' }
4063   );
4064
4065 Can also contain a hash reference to refer to the other relation's relations.
4066 For example:
4067
4068   package MyApp::Schema::Track;
4069   use base qw/DBIx::Class/;
4070   __PACKAGE__->table('track');
4071   __PACKAGE__->add_columns(qw/trackid cd position title/);
4072   __PACKAGE__->set_primary_key('trackid');
4073   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4074   1;
4075
4076   # In your application
4077   my $rs = $schema->resultset('Artist')->search(
4078     { 'track.title' => 'Teardrop' },
4079     {
4080       join     => { cd => 'track' },
4081       order_by => 'artist.name',
4082     }
4083   );
4084
4085 You need to use the relationship (not the table) name in  conditions,
4086 because they are aliased as such. The current table is aliased as "me", so
4087 you need to use me.column_name in order to avoid ambiguity. For example:
4088
4089   # Get CDs from 1984 with a 'Foo' track
4090   my $rs = $schema->resultset('CD')->search(
4091     {
4092       'me.year' => 1984,
4093       'tracks.name' => 'Foo'
4094     },
4095     { join => 'tracks' }
4096   );
4097
4098 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4099 similarly for a third time). For e.g.
4100
4101   my $rs = $schema->resultset('Artist')->search({
4102     'cds.title'   => 'Down to Earth',
4103     'cds_2.title' => 'Popular',
4104   }, {
4105     join => [ qw/cds cds/ ],
4106   });
4107
4108 will return a set of all artists that have both a cd with title 'Down
4109 to Earth' and a cd with title 'Popular'.
4110
4111 If you want to fetch related objects from other tables as well, see L</prefetch>
4112 below.
4113
4114  NOTE: An internal join-chain pruner will discard certain joins while
4115  constructing the actual SQL query, as long as the joins in question do not
4116  affect the retrieved result. This for example includes 1:1 left joins
4117  that are not part of the restriction specification (WHERE/HAVING) nor are
4118  a part of the query selection.
4119
4120 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4121
4122 =head2 collapse
4123
4124 =over 4
4125
4126 =item Value: (0 | 1)
4127
4128 =back
4129
4130 When set to a true value, indicates that any rows fetched from joined has_many
4131 relationships are to be aggregated into the corresponding "parent" object. For
4132 example, the resultset:
4133
4134   my $rs = $schema->resultset('CD')->search({}, {
4135     '+columns' => [ qw/ tracks.title tracks.position / ],
4136     join => 'tracks',
4137     collapse => 1,
4138   });
4139
4140 While executing the following query:
4141
4142   SELECT me.*, tracks.title, tracks.position
4143     FROM cd me
4144     LEFT JOIN track tracks
4145       ON tracks.cdid = me.cdid
4146
4147 Will return only as many objects as there are rows in the CD source, even
4148 though the result of the query may span many rows. Each of these CD objects
4149 will in turn have multiple "Track" objects hidden behind the has_many
4150 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4151 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4152 product"), with each CD object containing exactly one of all fetched Track data.
4153
4154 When a collapse is requested on a non-ordered resultset, an order by some
4155 unique part of the main source (the left-most table) is inserted automatically.
4156 This is done so that the resultset is allowed to be "lazy" - calling
4157 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4158 object with all of its related data.
4159
4160 If an L</order_by> is already declared, and orders the resultset in a way that
4161 makes collapsing as described above impossible (e.g. C<< ORDER BY
4162 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4163 switch to "eager" mode and slurp the entire resultset before constructing the
4164 first object returned by L</next>.
4165
4166 Setting this attribute on a resultset that does not join any has_many
4167 relations is a no-op.
4168
4169 For a more in-depth discussion, see L</PREFETCHING>.
4170
4171 =head2 prefetch
4172
4173 =over 4
4174
4175 =item Value: ($rel_name | \@rel_names | \%rel_names)
4176
4177 =back
4178
4179 This attribute is a shorthand for specifying a L</join> spec, adding all
4180 columns from the joined related sources as L</+columns> and setting
4181 L</collapse> to a true value. For example, the following two queries are
4182 equivalent:
4183
4184   my $rs = $schema->resultset('Artist')->search({}, {
4185     prefetch => { cds => ['genre', 'tracks' ] },
4186   });
4187
4188 and
4189
4190   my $rs = $schema->resultset('Artist')->search({}, {
4191     join => { cds => ['genre', 'tracks' ] },
4192     collapse => 1,
4193     '+columns' => [
4194       (map
4195         { +{ "cds.$_" => "cds.$_" } }
4196         $schema->source('Artist')->related_source('cds')->columns
4197       ),
4198       (map
4199         { +{ "cds.genre.$_" => "genre.$_" } }
4200         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4201       ),
4202       (map
4203         { +{ "cds.tracks.$_" => "tracks.$_" } }
4204         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4205       ),
4206     ],
4207   });
4208
4209 Both producing the following SQL:
4210
4211   SELECT  me.artistid, me.name, me.rank, me.charfield,
4212           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4213           genre.genreid, genre.name,
4214           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4215     FROM artist me
4216     LEFT JOIN cd cds
4217       ON cds.artist = me.artistid
4218     LEFT JOIN genre genre
4219       ON genre.genreid = cds.genreid
4220     LEFT JOIN track tracks
4221       ON tracks.cd = cds.cdid
4222   ORDER BY me.artistid
4223
4224 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4225 the arguments are properly merged and generally do the right thing. For
4226 example, you may want to do the following:
4227
4228   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4229     { 'genre.genreid' => undef },
4230     {
4231       join => { cds => 'genre' },
4232       prefetch => 'cds',
4233     }
4234   );
4235
4236 Which generates the following SQL:
4237
4238   SELECT  me.artistid, me.name, me.rank, me.charfield,
4239           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4240     FROM artist me
4241     LEFT JOIN cd cds
4242       ON cds.artist = me.artistid
4243     LEFT JOIN genre genre
4244       ON genre.genreid = cds.genreid
4245   WHERE genre.genreid IS NULL
4246   ORDER BY me.artistid
4247
4248 For a more in-depth discussion, see L</PREFETCHING>.
4249
4250 =head2 alias
4251
4252 =over 4
4253
4254 =item Value: $source_alias
4255
4256 =back
4257
4258 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4259 nested search queries (sub-SELECTs) might need specific aliases set to
4260 reference inner queries.  For example:
4261
4262    my $q = $rs
4263       ->related_resultset('CDs')
4264       ->related_resultset('Tracks')
4265       ->search({
4266          'track.id' => { -ident => 'none_search.id' },
4267       })
4268       ->as_query;
4269
4270    my $ids = $self->search({
4271       -not_exists => $q,
4272    }, {
4273       alias    => 'none_search',
4274       group_by => 'none_search.id',
4275    })->get_column('id')->as_query;
4276
4277    $self->search({ id => { -in => $ids } })
4278
4279 This attribute is directly tied to L</current_source_alias>.
4280
4281 =head2 page
4282
4283 =over 4
4284
4285 =item Value: $page
4286
4287 =back
4288
4289 Makes the resultset paged and specifies the page to retrieve. Effectively
4290 identical to creating a non-pages resultset and then calling ->page($page)
4291 on it.
4292
4293 If L</rows> attribute is not specified it defaults to 10 rows per page.
4294
4295 When you have a paged resultset, L</count> will only return the number
4296 of rows in the page. To get the total, use the L</pager> and call
4297 C<total_entries> on it.
4298
4299 =head2 rows
4300
4301 =over 4
4302
4303 =item Value: $rows
4304
4305 =back
4306
4307 Specifies the maximum number of rows for direct retrieval or the number of
4308 rows per page if the page attribute or method is used.
4309
4310 =head2 offset
4311
4312 =over 4
4313
4314 =item Value: $offset
4315
4316 =back
4317
4318 Specifies the (zero-based) row number for the  first row to be returned, or the
4319 of the first row of the first page if paging is used.
4320
4321 =head2 software_limit
4322
4323 =over 4
4324
4325 =item Value: (0 | 1)
4326
4327 =back
4328
4329 When combined with L</rows> and/or L</offset> the generated SQL will not
4330 include any limit dialect stanzas. Instead the entire result will be selected
4331 as if no limits were specified, and DBIC will perform the limit locally, by
4332 artificially advancing and finishing the resulting L</cursor>.
4333
4334 This is the recommended way of performing resultset limiting when no sane RDBMS
4335 implementation is available (e.g.
4336 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4337 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4338
4339 =head2 group_by
4340
4341 =over 4
4342
4343 =item Value: \@columns
4344
4345 =back
4346
4347 A arrayref of columns to group by. Can include columns of joined tables.
4348
4349   group_by => [qw/ column1 column2 ... /]
4350
4351 =head2 having
4352
4353 =over 4
4354
4355 =item Value: $condition
4356
4357 =back
4358
4359 HAVING is a select statement attribute that is applied between GROUP BY and
4360 ORDER BY. It is applied to the after the grouping calculations have been
4361 done.
4362
4363   having => { 'count_employee' => { '>=', 100 } }
4364
4365 or with an in-place function in which case literal SQL is required:
4366
4367   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4368
4369 =head2 distinct
4370
4371 =over 4
4372
4373 =item Value: (0 | 1)
4374
4375 =back
4376
4377 Set to 1 to automatically generate a L</group_by> clause based on the selection
4378 (including intelligent handling of L</order_by> contents). Note that the group
4379 criteria calculation takes place over the B<final> selection. This includes
4380 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4381 L</search> calls, and standalone columns selected via
4382 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4383 extra selections specified via L</prefetch> - such selections are explicitly
4384 excluded from group criteria calculations.
4385
4386 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4387 setting is ignored and an appropriate warning is issued.
4388
4389 =head2 where
4390
4391 =over 4
4392
4393 Adds to the WHERE clause.
4394
4395   # only return rows WHERE deleted IS NULL for all searches
4396   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4397
4398 Can be overridden by passing C<< { where => undef } >> as an attribute
4399 to a resultset.
4400
4401 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4402
4403 =back
4404
4405 =head2 cache
4406
4407 Set to 1 to cache search results. This prevents extra SQL queries if you
4408 revisit rows in your ResultSet:
4409
4410   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4411
4412   while( my $artist = $resultset->next ) {
4413     ... do stuff ...
4414   }
4415
4416   $rs->first; # without cache, this would issue a query
4417
4418 By default, searches are not cached.
4419
4420 For more examples of using these attributes, see
4421 L<DBIx::Class::Manual::Cookbook>.
4422
4423 =head2 for
4424
4425 =over 4
4426
4427 =item Value: ( 'update' | 'shared' | \$scalar )
4428
4429 =back
4430
4431 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4432 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4433 query.
4434
4435 =head1 PREFETCHING
4436
4437 DBIx::Class supports arbitrary related data prefetching from multiple related
4438 sources. Any combination of relationship types and column sets are supported.
4439 If L<collapsing|/collapse> is requested, there is an additional requirement of
4440 selecting enough data to make every individual object uniquely identifiable.
4441
4442 Here are some more involved examples, based on the following relationship map:
4443
4444   # Assuming:
4445   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4446   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4447   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4448
4449   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4450
4451   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4452
4453
4454
4455   my $rs = $schema->resultset('Tag')->search(
4456     undef,
4457     {
4458       prefetch => {
4459         cd => 'artist'
4460       }
4461     }
4462   );
4463
4464 The initial search results in SQL like the following:
4465
4466   SELECT tag.*, cd.*, artist.* FROM tag
4467   JOIN cd ON tag.cd = cd.cdid
4468   JOIN artist ON cd.artist = artist.artistid
4469
4470 L<DBIx::Class> has no need to go back to the database when we access the
4471 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4472 case.
4473
4474 Simple prefetches will be joined automatically, so there is no need
4475 for a C<join> attribute in the above search.
4476
4477 The L</prefetch> attribute can be used with any of the relationship types
4478 and multiple prefetches can be specified together. Below is a more complex
4479 example that prefetches a CD's artist, its liner notes (if present),
4480 the cover image, the tracks on that CD, and the guests on those
4481 tracks.
4482
4483   my $rs = $schema->resultset('CD')->search(
4484     undef,
4485     {
4486       prefetch => [
4487         { artist => 'record_label'},  # belongs_to => belongs_to
4488         'liner_note',                 # might_have
4489         'cover_image',                # has_one
4490         { tracks => 'guests' },       # has_many => has_many
4491       ]
4492     }
4493   );
4494
4495 This will produce SQL like the following:
4496
4497   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4498          tracks.*, guests.*
4499     FROM cd me
4500     JOIN artist artist
4501       ON artist.artistid = me.artistid
4502     JOIN record_label record_label
4503       ON record_label.labelid = artist.labelid
4504     LEFT JOIN track tracks
4505       ON tracks.cdid = me.cdid
4506     LEFT JOIN guest guests
4507       ON guests.trackid = track.trackid
4508     LEFT JOIN liner_notes liner_note
4509       ON liner_note.cdid = me.cdid
4510     JOIN cd_artwork cover_image
4511       ON cover_image.cdid = me.cdid
4512   ORDER BY tracks.cd
4513
4514 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4515 C<tracks>, and C<guests> of the CD will all be available through the
4516 relationship accessors without the need for additional queries to the
4517 database.
4518
4519 =head3 CAVEATS
4520
4521 Prefetch does a lot of deep magic. As such, it may not behave exactly
4522 as you might expect.
4523
4524 =over 4
4525
4526 =item *
4527
4528 Prefetch uses the L</cache> to populate the prefetched relationships. This
4529 may or may not be what you want.
4530
4531 =item *
4532
4533 If you specify a condition on a prefetched relationship, ONLY those
4534 rows that match the prefetched condition will be fetched into that relationship.
4535 This means that adding prefetch to a search() B<may alter> what is returned by
4536 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4537
4538   my $artist_rs = $schema->resultset('Artist')->search({
4539       'cds.year' => 2008,
4540   }, {
4541       join => 'cds',
4542   });
4543
4544   my $count = $artist_rs->first->cds->count;
4545
4546   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4547
4548   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4549
4550   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4551
4552 That cmp_ok() may or may not pass depending on the datasets involved. In other
4553 words the C<WHERE> condition would apply to the entire dataset, just like
4554 it would in regular SQL. If you want to add a condition only to the "right side"
4555 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4556 condition|DBIx::Class::Relationship::Base/condition>
4557
4558 =back
4559
4560 =head1 DBIC BIND VALUES
4561
4562 Because DBIC may need more information to bind values than just the column name
4563 and value itself, it uses a special format for both passing and receiving bind
4564 values.  Each bind value should be composed of an arrayref of
4565 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4566
4567 =over 4
4568
4569 =item dbd_attrs
4570
4571 If present (in any form), this is what is being passed directly to bind_param.
4572 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4573 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4574
4575 If this is specified, all other bind options described below are ignored.
4576
4577 =item sqlt_datatype
4578
4579 If present, this is used to infer the actual bind attribute by passing to
4580 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4581 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4582
4583 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4584 currently drivers are expected to "Do the Right Thing" when given a common
4585 datatype name.  (Not ideal, but that's what we got at this point.)
4586
4587 =item sqlt_size
4588
4589 Currently used to correctly allocate buffers for bind_param_inout().
4590 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4591 or to a sensible value based on the "data_type".
4592
4593 =item dbic_colname
4594
4595 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4596 explicitly specified they are never overridden).  Also used by some weird DBDs,
4597 where the column name should be available at bind_param time (e.g. Oracle).
4598
4599 =back
4600
4601 For backwards compatibility and convenience, the following shortcuts are
4602 supported:
4603
4604   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4605   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4606   [ undef,   $val ] === [ {}, $val ]
4607   $val              === [ {}, $val ]
4608
4609 =head1 AUTHOR AND CONTRIBUTORS
4610
4611 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4612
4613 =head1 LICENSE
4614
4615 You may distribute this code under the same terms as Perl itself.
4616