lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'DBIx::Class';
   7
   8 use DBIx::Class::Carp;
   9 use DBIx::Class::ResultSetColumn;
  10 use DBIx::Class::ResultClass::HashRefInflator;
  11 use Scalar::Util qw( blessed reftype );
  12 use DBIx::Class::_Util qw(
  13   dbic_internal_try dbic_internal_catch dump_value
  14   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  15 );
  16 use DBIx::Class::SQLMaker::Util qw( normalize_sqla_condition extract_equality_conditions );
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304
 305   if (ref $class) {
 306     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 307     return $class->new_result(@_);
 308   }
 309
 310   my ($source, $attrs) = @_;
 311   $source = $source->resolve
 312     if $source->isa('DBIx::Class::ResultSourceHandle');
 313
 314   $attrs = { %{$attrs||{}} };
 315   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 316
 317   if ($attrs->{page}) {
 318     $attrs->{rows} ||= 10;
 319   }
 320
 321   $attrs->{alias} ||= 'me';
 322
 323   my $self = bless {
 324     result_source => $source,
 325     cond => $attrs->{where},
 326     pager => undef,
 327     attrs => $attrs,
 328   }, $class;
 329
 330   # if there is a dark selector, this means we are already in a
 331   # chain and the cleanup/sanification was taken care of by
 332   # _search_rs already
 333   $self->_normalize_selection($attrs)
 334     unless $attrs->{_dark_selector};
 335
 336   $self->result_class(
 337     $attrs->{result_class} || $source->result_class
 338   );
 339
 340   $self;
 341 }
 342
 343 =head2 search
 344
 345 =over 4
 346
 347 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 348
 349 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 350
 351 =back
 352
 353   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 354   my $new_rs = $cd_rs->search({ year => 2005 });
 355
 356   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 357                  # year = 2005 OR year = 2004
 358
 359 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 360 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 361 To avoid that, use L</search_rs>.
 362
 363 If you need to pass in additional attributes but no additional condition,
 364 call it as C<search(undef, \%attrs)>.
 365
 366   # "SELECT name, artistid FROM $artist_table"
 367   my @all_artists = $schema->resultset('Artist')->search(undef, {
 368     columns => [qw/name artistid/],
 369   });
 370
 371 For a list of attributes that can be passed to C<search>, see
 372 L</ATTRIBUTES>. For more examples of using this function, see
 373 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 374 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 375 and its extension L<DBIx::Class::SQLMaker>.
 376
 377 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 378
 379 =head3 CAVEAT
 380
 381 Note that L</search> does not process/deflate any of the values passed in the
 382 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 383 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 384 manually that any value passed to this method will stringify to something the
 385 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 386 objects, for more info see:
 387 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 388
 389 =cut
 390
 391 sub search {
 392   my $self = shift;
 393   my $rs = $self->search_rs( @_ );
 394
 395   if (wantarray) {
 396     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 397     return $rs->all;
 398   }
 399   elsif (defined wantarray) {
 400     return $rs;
 401   }
 402   else {
 403     # we can be called by a relationship helper, which in
 404     # turn may be called in void context due to some braindead
 405     # overload or whatever else the user decided to be clever
 406     # at this particular day. Thus limit the exception to
 407     # external code calls only
 408     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 409       if (caller)[0] !~ /^\QDBIx::Class::/;
 410
 411     return ();
 412   }
 413 }
 414
 415 =head2 search_rs
 416
 417 =over 4
 418
 419 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 420
 421 =item Return Value: L<$resultset|/search>
 422
 423 =back
 424
 425 This method does the same exact thing as search() except it will
 426 always return a resultset, even in list context.
 427
 428 =cut
 429
 430 sub search_rs {
 431   my $self = shift;
 432
 433   my $rsrc = $self->result_source;
 434   my ($call_cond, $call_attrs);
 435
 436   # Special-case handling for (undef, undef) or (undef)
 437   # Note that (foo => undef) is valid deprecated syntax
 438   @_ = () if not scalar grep { defined $_ } @_;
 439
 440   # just a cond
 441   if (@_ == 1) {
 442     $call_cond = shift;
 443   }
 444   # fish out attrs in the ($condref, $attr) case
 445   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 446     ($call_cond, $call_attrs) = @_;
 447   }
 448   elsif (@_ % 2) {
 449     $self->throw_exception('Odd number of arguments to search')
 450   }
 451   # legacy search
 452   elsif (@_) {
 453     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 454       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 455
 456     for my $i (0 .. $#_) {
 457       next if $i % 2;
 458       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 459         if (! defined $_[$i] or length ref $_[$i] );
 460     }
 461
 462     $call_cond = { @_ };
 463   }
 464
 465   # see if we can keep the cache (no $rs changes)
 466   my $cache;
 467   my %safe = (alias => 1, cache => 1);
 468   if ( ! grep { !$safe{$_} } keys %$call_attrs and (
 469     ! defined $call_cond
 470       or
 471     ref $call_cond eq 'HASH' && ! keys %$call_cond
 472       or
 473     ref $call_cond eq 'ARRAY' && ! @$call_cond
 474   )) {
 475     $cache = $self->get_cache;
 476   }
 477
 478   my $old_attrs = { %{$self->{attrs}} };
 479   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 480
 481   my $new_attrs = { %$old_attrs };
 482
 483   # take care of call attrs (only if anything is changing)
 484   if ($call_attrs and keys %$call_attrs) {
 485
 486     # copy for _normalize_selection
 487     $call_attrs = { %$call_attrs };
 488
 489     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 490
 491     # reset the current selector list if new selectors are supplied
 492     delete @{$old_attrs}{(@selector_attrs, '_dark_selector')}
 493       if grep { exists $call_attrs->{$_} } qw(columns cols select as);
 494
 495     # Normalize the new selector list (operates on the passed-in attr structure)
 496     # Need to do it on every chain instead of only once on _resolved_attrs, in
 497     # order to allow detection of empty vs partial 'as'
 498     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 499       if $old_attrs->{_dark_selector};
 500     $self->_normalize_selection ($call_attrs);
 501
 502     # start with blind overwriting merge, exclude selector attrs
 503     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 504     delete @{$new_attrs}{@selector_attrs};
 505
 506     for (@selector_attrs) {
 507       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 508         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 509     }
 510
 511     # older deprecated name, use only if {columns} is not there
 512     if (my $c = delete $new_attrs->{cols}) {
 513       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 514       if ($new_attrs->{columns}) {
 515         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 516       }
 517       else {
 518         $new_attrs->{columns} = $c;
 519       }
 520     }
 521
 522
 523     # join/prefetch use their own crazy merging heuristics
 524     foreach my $key (qw/join prefetch/) {
 525       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 526         if exists $call_attrs->{$key};
 527     }
 528
 529     # stack binds together
 530     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 531   }
 532
 533
 534   for ($old_where, $call_cond) {
 535     if (defined $_) {
 536       $new_attrs->{where} = $self->_stack_cond (
 537         $_, $new_attrs->{where}
 538       );
 539     }
 540   }
 541
 542   if (defined $old_having) {
 543     $new_attrs->{having} = $self->_stack_cond (
 544       $old_having, $new_attrs->{having}
 545     )
 546   }
 547
 548   my $rs = (ref $self)->new($rsrc, $new_attrs);
 549
 550   $rs->set_cache($cache) if ($cache);
 551
 552   return $rs;
 553 }
 554
 555 sub _normalize_selection {
 556   my ($self, $attrs) = @_;
 557
 558   # legacy syntax
 559   if ( exists $attrs->{include_columns} ) {
 560     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 561     $attrs->{'+columns'} = $self->_merge_attr(
 562       $attrs->{'+columns'}, delete $attrs->{include_columns}
 563     );
 564   }
 565
 566   # columns are always placed first, however
 567
 568   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 569   # delay the decision on whether to use a default select list ($rsrc->columns)
 570   # allowing stuff like the remove_columns helper to work
 571   #
 572   # select/as +select/+as pairs need special handling - the amount of select/as
 573   # elements in each pair does *not* have to be equal (think multicolumn
 574   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 575   # supplied at all) - try to infer the alias, either from the -as parameter
 576   # of the selector spec, or use the parameter whole if it looks like a column
 577   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 578   # is ok as well), but make sure no more additions to the 'as' chain take place
 579   for my $pref ('', '+') {
 580
 581     my ($sel, $as) = map {
 582       my $key = "${pref}${_}";
 583
 584       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 585         ? @{$attrs->{$key}}
 586         : $attrs->{$key} || ()
 587       ];
 588       delete $attrs->{$key};
 589       $val;
 590     } qw/select as/;
 591
 592     if (! @$as and ! @$sel ) {
 593       next;
 594     }
 595     elsif (@$as and ! @$sel) {
 596       $self->throw_exception(
 597         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 598       );
 599     }
 600     elsif( ! @$as ) {
 601       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 602       # if any @$as has been supplied we assume the user knows what (s)he is doing
 603       # and blindly keep stacking up pieces
 604       unless ($attrs->{_dark_selector}) {
 605         SELECTOR:
 606         for (@$sel) {
 607           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 608             push @$as, $_->{-as};
 609           }
 610           # assume any plain no-space, no-parenthesis string to be a column spec
 611           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 612           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 613             push @$as, $_;
 614           }
 615           # if all else fails - raise a flag that no more aliasing will be allowed
 616           else {
 617             $attrs->{_dark_selector} = {
 618               plus_stage => $pref,
 619               string => do {
 620                 local $Data::Dumper::Indent = 0;
 621                 dump_value $_;
 622               },
 623             };
 624             last SELECTOR;
 625           }
 626         }
 627       }
 628     }
 629     elsif (@$as < @$sel) {
 630       $self->throw_exception(
 631         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 632       );
 633     }
 634     elsif ($pref and $attrs->{_dark_selector}) {
 635       $self->throw_exception(
 636         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 637       );
 638     }
 639
 640
 641     # merge result
 642     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 643     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 644   }
 645 }
 646
 647 sub _stack_cond {
 648   my ($self, $left, $right) = @_;
 649
 650   (
 651     (ref $_ eq 'ARRAY' and !@$_)
 652       or
 653     (ref $_ eq 'HASH' and ! keys %$_)
 654   ) and $_ = undef for ($left, $right);
 655
 656   return(
 657     # either one of the two undef
 658     ( (defined $left) xor (defined $right) )  ? ( defined $left ? $left : $right )
 659
 660     # both undef
 661   : ( ! defined $left )                       ? undef
 662
 663                                               : { -and => [$left, $right] }
 664   );
 665 }
 666
 667 =head2 search_literal
 668
 669 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 670 should only be used in that context. C<search_literal> is a convenience
 671 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 672 want to ensure columns are bound correctly, use L</search>.
 673
 674 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 675 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 676 require C<search_literal>.
 677
 678 =over 4
 679
 680 =item Arguments: $sql_fragment, @standalone_bind_values
 681
 682 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 683
 684 =back
 685
 686   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 687   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 688
 689 Pass a literal chunk of SQL to be added to the conditional part of the
 690 resultset query.
 691
 692 Example of how to use C<search> instead of C<search_literal>
 693
 694   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 695   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 696
 697 =cut
 698
 699 sub search_literal {
 700   my ($self, $sql, @bind) = @_;
 701   my $attr;
 702   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 703     $attr = pop @bind;
 704   }
 705   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 706 }
 707
 708 =head2 find
 709
 710 =over 4
 711
 712 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 713
 714 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 715
 716 =back
 717
 718 Finds and returns a single row based on supplied criteria. Takes either a
 719 hashref with the same format as L</create> (including inference of foreign
 720 keys from related objects), or a list of primary key values in the same
 721 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 722 declaration on the L</result_source>.
 723
 724 In either case an attempt is made to combine conditions already existing on
 725 the resultset with the condition passed to this method.
 726
 727 To aid with preparing the correct query for the storage you may supply the
 728 C<key> attribute, which is the name of a
 729 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 730 unique constraint corresponding to the
 731 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 732 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 733 to construct a query that satisfies the named unique constraint fully (
 734 non-NULL values for each column member of the constraint) an exception is
 735 thrown.
 736
 737 If no C<key> is specified, the search is carried over all unique constraints
 738 which are fully defined by the available condition.
 739
 740 If no such constraint is found, C<find> currently defaults to a simple
 741 C<< search->(\%column_values) >> which may or may not do what you expect.
 742 Note that this fallback behavior may be deprecated in further versions. If
 743 you need to search with arbitrary conditions - use L</search>. If the query
 744 resulting from this fallback produces more than one row, a warning to the
 745 effect is issued, though only the first row is constructed and returned as
 746 C<$result_object>.
 747
 748 In addition to C<key>, L</find> recognizes and applies standard
 749 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 750
 751 Note that if you have extra concerns about the correctness of the resulting
 752 query you need to specify the C<key> attribute and supply the entire condition
 753 as an argument to find (since it is not always possible to perform the
 754 combination of the resultset condition with the supplied one, especially if
 755 the resultset condition contains literal sql).
 756
 757 For example, to find a row by its primary key:
 758
 759   my $cd = $schema->resultset('CD')->find(5);
 760
 761 You can also find a row by a specific unique constraint:
 762
 763   my $cd = $schema->resultset('CD')->find(
 764     {
 765       artist => 'Massive Attack',
 766       title  => 'Mezzanine',
 767     },
 768     { key => 'cd_artist_title' }
 769   );
 770
 771 See also L</find_or_create> and L</update_or_create>.
 772
 773 =cut
 774
 775 sub find {
 776   my $self = shift;
 777   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
 778
 779   my $rsrc = $self->result_source;
 780
 781   my $constraint_name;
 782   if (exists $attrs->{key}) {
 783     $constraint_name = defined $attrs->{key}
 784       ? $attrs->{key}
 785       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 786     ;
 787   }
 788
 789   # Parse out the condition from input
 790   my $call_cond;
 791
 792   if (ref $_[0] eq 'HASH') {
 793     $call_cond = { %{$_[0]} };
 794   }
 795   else {
 796     # if only values are supplied we need to default to 'primary'
 797     $constraint_name = 'primary' unless defined $constraint_name;
 798
 799     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 800
 801     $self->throw_exception(
 802       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 803     ) unless @c_cols;
 804
 805     $self->throw_exception (
 806       'find() expects either a column/value hashref, or a list of values '
 807     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 808     ) unless @c_cols == @_;
 809
 810     @{$call_cond}{@c_cols} = @_;
 811   }
 812
 813   # process relationship data if any
 814   for my $key (keys %$call_cond) {
 815     if (
 816       length ref($call_cond->{$key})
 817         and
 818       my $relinfo = $rsrc->relationship_info($key)
 819         and
 820       # implicitly skip has_many's (likely MC)
 821       ( ref( my $val = delete $call_cond->{$key} ) ne 'ARRAY' )
 822     ) {
 823       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 824         $relinfo->{cond}, $val, $key, $key
 825       );
 826
 827       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 828          if $crosstable or ref($rel_cond) ne 'HASH';
 829
 830       # supplement condition
 831       # relationship conditions take precedence (?)
 832       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 833     }
 834   }
 835
 836   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 837   my $final_cond;
 838   if (defined $constraint_name) {
 839     $final_cond = $self->_qualify_cond_columns (
 840
 841       $rsrc->_minimal_valueset_satisfying_constraint(
 842         constraint_name => $constraint_name,
 843         values => ($self->_merge_with_rscond($call_cond))[0],
 844         carp_on_nulls => 1,
 845       ),
 846
 847       $alias,
 848     );
 849   }
 850   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 851     # This means that we got here after a merger of relationship conditions
 852     # in ::Relationship::Base::search_related (the row method), and furthermore
 853     # the relationship is of the 'single' type. This means that the condition
 854     # provided by the relationship (already attached to $self) is sufficient,
 855     # as there can be only one row in the database that would satisfy the
 856     # relationship
 857   }
 858   else {
 859     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 860
 861     # no key was specified - fall down to heuristics mode:
 862     # run through all unique queries registered on the resultset, and
 863     # 'OR' all qualifying queries together
 864     #
 865     # always start from 'primary' if it exists at all
 866     for my $c_name ( sort {
 867         $a eq 'primary' ? -1
 868       : $b eq 'primary' ? 1
 869       : $a cmp $b
 870     } $rsrc->unique_constraint_names) {
 871
 872       next if $seen_column_combinations{
 873         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 874       }++;
 875
 876       dbic_internal_try {
 877         push @unique_queries, $self->_qualify_cond_columns(
 878           $rsrc->_minimal_valueset_satisfying_constraint(
 879             constraint_name => $c_name,
 880             values => ($self->_merge_with_rscond($call_cond))[0],
 881             columns_info => ($ci ||= $rsrc->columns_info),
 882           ),
 883           $alias
 884         );
 885       }
 886       dbic_internal_catch {
 887         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 888       };
 889     }
 890
 891     $final_cond =
 892         @unique_queries   ? \@unique_queries
 893       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 894       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 895     ;
 896   }
 897
 898   # Run the query, passing the result_class since it should propagate for find
 899   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 900   if ($rs->_resolved_attrs->{collapse}) {
 901     my $row = $rs->next;
 902     carp "Query returned more than one row" if $rs->next;
 903     return $row;
 904   }
 905   else {
 906     return $rs->single;
 907   }
 908 }
 909
 910 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 911 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 912 #
 913 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 914 # condition. It is provided for overrides until a saner way forward is devised
 915 #
 916 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 917 # the road. Please adjust your tests accordingly to catch this situation early
 918 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 919 #
 920 # The method will not be removed without an adequately complete replacement
 921 # for strict-mode enforcement
 922 sub _non_unique_find_fallback {
 923   my ($self, $cond, $attrs) = @_;
 924
 925   return $self->_qualify_cond_columns(
 926     $cond,
 927     exists $attrs->{alias}
 928       ? $attrs->{alias}
 929       : $self->{attrs}{alias}
 930   );
 931 }
 932
 933
 934 sub _qualify_cond_columns {
 935   my ($self, $cond, $alias) = @_;
 936
 937   my %aliased = %$cond;
 938   for (keys %aliased) {
 939     $aliased{"$alias.$_"} = delete $aliased{$_}
 940       if $_ !~ /\./;
 941   }
 942
 943   return \%aliased;
 944 }
 945
 946 sub _build_unique_cond {
 947   carp_unique sprintf
 948     '_build_unique_cond is a private method, and moreover is about to go '
 949   . 'away. Please contact the development team at %s if you believe you '
 950   . 'have a genuine use for this method, in order to discuss alternatives.',
 951     DBIx::Class::_ENV_::HELP_URL,
 952   ;
 953
 954   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 955
 956   $self->result_source->_minimal_valueset_satisfying_constraint(
 957     constraint_name => $constraint_name,
 958     values => $cond,
 959     carp_on_nulls => !$croak_on_null
 960   );
 961 }
 962
 963 =head2 search_related
 964
 965 =over 4
 966
 967 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 968
 969 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 970
 971 =back
 972
 973   $new_rs = $cd_rs->search_related('artist', {
 974     name => 'Emo-R-Us',
 975   });
 976
 977 Searches the specified relationship, optionally specifying a condition and
 978 attributes for matching records. See L</ATTRIBUTES> for more information.
 979
 980 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 981 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 982
 983 See also L</search_related_rs>.
 984
 985 =cut
 986
 987 sub search_related :DBIC_method_is_indirect_sugar {
 988   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 989   return shift->related_resultset(shift)->search(@_);
 990 }
 991
 992 =head2 search_related_rs
 993
 994 This method works exactly the same as search_related, except that
 995 it guarantees a resultset, even in list context.
 996
 997 =cut
 998
 999 sub search_related_rs :DBIC_method_is_indirect_sugar {
1000   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1001   return shift->related_resultset(shift)->search_rs(@_);
1002 }
1003
1004 =head2 cursor
1005
1006 =over 4
1007
1008 =item Arguments: none
1009
1010 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1011
1012 =back
1013
1014 Returns a storage-driven cursor to the given resultset. See
1015 L<DBIx::Class::Cursor> for more information.
1016
1017 =cut
1018
1019 sub cursor {
1020   my $self = shift;
1021
1022   return $self->{cursor} ||= do {
1023     my $attrs = $self->_resolved_attrs;
1024     $self->result_source->schema->storage->select(
1025       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1026     );
1027   };
1028 }
1029
1030 =head2 single
1031
1032 =over 4
1033
1034 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1035
1036 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1037
1038 =back
1039
1040   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1041
1042 Inflates the first result without creating a cursor if the resultset has
1043 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1044 of L</search>.
1045
1046 While this method can take an optional search condition (just like L</search>)
1047 being a fast-code-path it does not recognize search attributes. If you need to
1048 add extra joins or similar, call L</search> and then chain-call L</single> on the
1049 L<DBIx::Class::ResultSet> returned.
1050
1051 =over
1052
1053 =item B<Note>
1054
1055 As of 0.08100, this method enforces the assumption that the preceding
1056 query returns only one row. If more than one row is returned, you will receive
1057 a warning:
1058
1059   Query returned more than one row
1060
1061 In this case, you should be using L</next> or L</find> instead, or if you really
1062 know what you are doing, use the L</rows> attribute to explicitly limit the size
1063 of the resultset.
1064
1065 This method will also throw an exception if it is called on a resultset prefetching
1066 has_many, as such a prefetch implies fetching multiple rows from the database in
1067 order to assemble the resulting object.
1068
1069 =back
1070
1071 =cut
1072
1073 sub single {
1074   my ($self, $where) = @_;
1075   if(@_ > 2) {
1076       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1077   }
1078
1079   my $attrs = { %{$self->_resolved_attrs} };
1080
1081   $self->throw_exception(
1082     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1083   ) if $attrs->{collapse};
1084
1085   if ($where) {
1086     if (defined $attrs->{where}) {
1087       $attrs->{where} = {
1088         '-and' =>
1089             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1090                $where, delete $attrs->{where} ]
1091       };
1092     } else {
1093       $attrs->{where} = $where;
1094     }
1095   }
1096
1097   my $data = [ $self->result_source->schema->storage->select_single(
1098     $attrs->{from}, $attrs->{select},
1099     $attrs->{where}, $attrs
1100   )];
1101
1102   return undef unless @$data;
1103   $self->{_stashed_rows} = [ $data ];
1104   $self->_construct_results->[0];
1105 }
1106
1107 =head2 get_column
1108
1109 =over 4
1110
1111 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1112
1113 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1114
1115 =back
1116
1117   my $max_length = $rs->get_column('length')->max;
1118
1119 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1120
1121 =cut
1122
1123 sub get_column {
1124   DBIx::Class::ResultSetColumn->new(@_);
1125 }
1126
1127 =head2 search_like
1128
1129 =over 4
1130
1131 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1132
1133 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1134
1135 =back
1136
1137   # WHERE title LIKE '%blue%'
1138   $cd_rs = $rs->search_like({ title => '%blue%'});
1139
1140 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1141 that this is simply a convenience method retained for ex Class::DBI users.
1142 You most likely want to use L</search> with specific operators.
1143
1144 For more information, see L<DBIx::Class::Manual::Cookbook>.
1145
1146 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1147 instead. An example conversion is:
1148
1149   ->search_like({ foo => 'bar' });
1150
1151   # Becomes
1152
1153   ->search({ foo => { like => 'bar' } });
1154
1155 =cut
1156
1157 sub search_like {
1158   my $class = shift;
1159   carp_unique (
1160     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1161    .' Instead use ->search({ x => { -like => "y%" } })'
1162    .' (note the outer pair of {}s - they are important!)'
1163   );
1164   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
1165   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1166   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1167   return $class->search($query, { %$attrs });
1168 }
1169
1170 =head2 slice
1171
1172 =over 4
1173
1174 =item Arguments: $first, $last
1175
1176 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1177
1178 =back
1179
1180 Returns a resultset or object list representing a subset of elements from the
1181 resultset slice is called on. Indexes are from 0, i.e., to get the first
1182 three records, call:
1183
1184   my ($one, $two, $three) = $rs->slice(0, 2);
1185
1186 =cut
1187
1188 sub slice {
1189   my ($self, $min, $max) = @_;
1190   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1191   $attrs->{offset} = $self->{attrs}{offset} || 0;
1192   $attrs->{offset} += $min;
1193   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1194   return $self->search(undef, $attrs);
1195 }
1196
1197 =head2 next
1198
1199 =over 4
1200
1201 =item Arguments: none
1202
1203 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1204
1205 =back
1206
1207 Returns the next element in the resultset (C<undef> is there is none).
1208
1209 Can be used to efficiently iterate over records in the resultset:
1210
1211   my $rs = $schema->resultset('CD')->search;
1212   while (my $cd = $rs->next) {
1213     print $cd->title;
1214   }
1215
1216 Note that you need to store the resultset object, and call C<next> on it.
1217 Calling C<< resultset('Table')->next >> repeatedly will always return the
1218 first record from the resultset.
1219
1220 =cut
1221
1222 sub next {
1223   my ($self) = @_;
1224
1225   if (my $cache = $self->get_cache) {
1226     $self->{all_cache_position} ||= 0;
1227     return $cache->[$self->{all_cache_position}++];
1228   }
1229
1230   if ($self->{attrs}{cache}) {
1231     delete $self->{pager};
1232     $self->{all_cache_position} = 1;
1233     return ($self->all)[0];
1234   }
1235
1236   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1237
1238   $self->{_stashed_results} = $self->_construct_results
1239     or return undef;
1240
1241   return shift @{$self->{_stashed_results}};
1242 }
1243
1244 # Constructs as many results as it can in one pass while respecting
1245 # cursor laziness. Several modes of operation:
1246 #
1247 # * Always builds everything present in @{$self->{_stashed_rows}}
1248 # * If called with $fetch_all true - pulls everything off the cursor and
1249 #   builds all result structures (or objects) in one pass
1250 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1251 #   and if the resultset is ordered properly by the left side:
1252 #   * Fetches stuff off the cursor until the "master object" changes,
1253 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1254 #   OR
1255 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1256 #     was requested (there is no other way to collapse except for an
1257 #     eager cursor)
1258 # * If no collapse is requested - just get the next row, construct and
1259 #   return
1260 sub _construct_results {
1261   my ($self, $fetch_all) = @_;
1262
1263   my $rsrc = $self->result_source;
1264   my $attrs = $self->_resolved_attrs;
1265
1266   if (
1267     ! $fetch_all
1268       and
1269     ! $attrs->{order_by}
1270       and
1271     $attrs->{collapse}
1272       and
1273     my @pcols = $rsrc->primary_columns
1274   ) {
1275     # default order for collapsing unless the user asked for something
1276     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1277     $attrs->{_ordered_for_collapse} = 1;
1278     $attrs->{_order_is_artificial} = 1;
1279   }
1280
1281   # this will be used as both initial raw-row collector AND as a RV of
1282   # _construct_results. Not regrowing the array twice matters a lot...
1283   # a surprising amount actually
1284   my $rows = delete $self->{_stashed_rows};
1285
1286   my $cursor; # we may not need one at all
1287
1288   my $did_fetch_all = $fetch_all;
1289
1290   if ($fetch_all) {
1291     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1292     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1293   }
1294   elsif( $attrs->{collapse} ) {
1295
1296     # a cursor will need to be closed over in case of collapse
1297     $cursor = $self->cursor;
1298
1299     $attrs->{_ordered_for_collapse} = (
1300       (
1301         $attrs->{order_by}
1302           and
1303         $rsrc->schema
1304               ->storage
1305                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1306       ) ? 1 : 0
1307     ) unless defined $attrs->{_ordered_for_collapse};
1308
1309     if (! $attrs->{_ordered_for_collapse}) {
1310       $did_fetch_all = 1;
1311
1312       # instead of looping over ->next, use ->all in stealth mode
1313       # *without* calling a ->reset afterwards
1314       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1315       if (! $cursor->{_done}) {
1316         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1317         $cursor->{_done} = 1;
1318       }
1319     }
1320   }
1321
1322   if (! $did_fetch_all and ! @{$rows||[]} ) {
1323     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1324     $cursor ||= $self->cursor;
1325     if (scalar (my @r = $cursor->next) ) {
1326       $rows = [ \@r ];
1327     }
1328   }
1329
1330   return undef unless @{$rows||[]};
1331
1332   # sanity check - people are too clever for their own good
1333   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1334
1335     my $multiplied_selectors;
1336     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1337       if (
1338         $aliastypes->{multiplying}{$sel_alias}
1339           or
1340         $aliastypes->{premultiplied}{$sel_alias}
1341       ) {
1342         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1343       }
1344     }
1345
1346     for my $i (0 .. $#{$attrs->{as}} ) {
1347       my $sel = $attrs->{select}[$i];
1348
1349       if (ref $sel eq 'SCALAR') {
1350         $sel = $$sel;
1351       }
1352       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1353         $sel = $$sel->[0];
1354       }
1355
1356       $self->throw_exception(
1357         'Result collapse not possible - selection from a has_many source redirected to the main object'
1358       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1359     }
1360   }
1361
1362   # hotspot - skip the setter
1363   my $res_class = $self->_result_class;
1364
1365   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1366     $res_class->can ('inflate_result')
1367       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1368   };
1369
1370   my $infmap = $attrs->{as};
1371
1372   $self->{_result_inflator}{is_core_row} = ( (
1373     $inflator_cref
1374       ==
1375     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1376   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1377
1378   $self->{_result_inflator}{is_hri} = ( (
1379     ! $self->{_result_inflator}{is_core_row}
1380       and
1381     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1382   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1383
1384
1385   if ($attrs->{_simple_passthrough_construction}) {
1386     # construct a much simpler array->hash folder for the one-table HRI cases right here
1387     if ($self->{_result_inflator}{is_hri}) {
1388       for my $r (@$rows) {
1389         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1390       }
1391     }
1392     # FIXME SUBOPTIMAL this is a very very very hot spot
1393     # while rather optimal we can *still* do much better, by
1394     # building a smarter Row::inflate_result(), and
1395     # switch to feeding it data via a much leaner interface
1396     #
1397     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1398     # this particular resultset size
1399     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1400       for my $r (@$rows) {
1401         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1402       }
1403     }
1404     else {
1405       eval sprintf (
1406         ( $self->{_result_inflator}{is_core_row}
1407           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1408           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1409           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1410         ),
1411         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1412       ) . '; 1' or die;
1413     }
1414   }
1415   else {
1416     my $parser_type =
1417         $self->{_result_inflator}{is_hri}       ? 'hri'
1418       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1419       :                                           'classic_nonpruning'
1420     ;
1421
1422     unless( $self->{_row_parser}{$parser_type}{cref} ) {
1423
1424       # $args and $attrs to _mk_row_parser are separated to delineate what is
1425       # core collapser stuff and what is dbic $rs specific
1426       $self->{_row_parser}{$parser_type}{src} = $rsrc->_mk_row_parser({
1427         inflate_map => $infmap,
1428         collapse => $attrs->{collapse},
1429         premultiplied => $attrs->{_main_source_premultiplied},
1430         hri_style => $self->{_result_inflator}{is_hri},
1431         prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1432       }, $attrs);
1433
1434       $self->{_row_parser}{$parser_type}{cref} = do {
1435         package # hide form PAUSE
1436           DBIx::Class::__GENERATED_ROW_PARSER__;
1437
1438         eval $self->{_row_parser}{$parser_type}{src};
1439       } || die $@;
1440     }
1441
1442     # this needs to close over the *current* cursor, hence why it is not cached above
1443     my $next_cref = ($did_fetch_all or ! $attrs->{collapse})
1444       ? undef
1445       : sub {
1446         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1447         my @r = $cursor->next or return;
1448         \@r
1449       }
1450     ;
1451
1452     $self->{_row_parser}{$parser_type}{cref}->(
1453       $rows,
1454       $next_cref,
1455       ( $self->{_stashed_rows} = [] ),
1456       ( my $null_violations = {} ),
1457     );
1458
1459     $self->throw_exception(
1460       'Collapse aborted - the following columns are declared (or defaulted to) '
1461     . 'non-nullable within DBIC but NULLs were retrieved from storage: '
1462     . join( ', ', map { "'$infmap->[$_]'" } sort { $a <=> $b } keys %$null_violations )
1463     . ' within data row ' . dump_value({
1464       map {
1465         $infmap->[$_] =>
1466           ( ! defined $self->{_stashed_rows}[0][$_] or length $self->{_stashed_rows}[0][$_] < 50 )
1467             ? $self->{_stashed_rows}[0][$_]
1468             : substr( $self->{_stashed_rows}[0][$_], 0, 50 ) . '...'
1469       } 0 .. $#{$self->{_stashed_rows}[0]}
1470     })
1471     ) if keys %$null_violations;
1472
1473     # simple in-place substitution, does not regrow $rows
1474     if ($self->{_result_inflator}{is_core_row}) {
1475       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1476     }
1477     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1478     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1479       # the inflator may be a multiplier/reductor - put it in list ctx
1480       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1481     }
1482   }
1483
1484   # The @$rows check seems odd at first - why wouldn't we want to warn
1485   # regardless? The issue is things like find() etc, where the user
1486   # *knows* only one result will come back. In these cases the ->all
1487   # is not a pessimization, but rather something we actually want
1488   carp_unique(
1489     'Unable to properly collapse has_many results in iterator mode due '
1490   . 'to order criteria - performed an eager cursor slurp underneath. '
1491   . 'Consider using ->all() instead'
1492   ) if ( ! $fetch_all and @$rows > 1 );
1493
1494   return $rows;
1495 }
1496
1497 =head2 result_source
1498
1499 =over 4
1500
1501 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1502
1503 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1504
1505 =back
1506
1507 An accessor for the primary ResultSource object from which this ResultSet
1508 is derived.
1509
1510 =head2 result_class
1511
1512 =over 4
1513
1514 =item Arguments: $result_class?
1515
1516 =item Return Value: $result_class
1517
1518 =back
1519
1520 An accessor for the class to use when creating result objects. Defaults to
1521 C<< result_source->result_class >> - which in most cases is the name of the
1522 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1523
1524 Note that changing the result_class will also remove any components
1525 that were originally loaded in the source class via
1526 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1527 Any overloaded methods in the original source class will not run.
1528
1529 =cut
1530
1531 sub result_class {
1532   my ($self, $result_class) = @_;
1533   if ($result_class) {
1534
1535     # don't fire this for an object
1536     $self->ensure_class_loaded($result_class)
1537       unless ref($result_class);
1538
1539     if ($self->get_cache) {
1540       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1541     }
1542     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1543     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1544       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1545     }
1546
1547     $self->_result_class($result_class);
1548
1549     delete $self->{_result_inflator};
1550   }
1551   $self->_result_class;
1552 }
1553
1554 =head2 count
1555
1556 =over 4
1557
1558 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1559
1560 =item Return Value: $count
1561
1562 =back
1563
1564 Performs an SQL C<COUNT> with the same query as the resultset was built
1565 with to find the number of elements. Passing arguments is equivalent to
1566 C<< $rs->search ($cond, \%attrs)->count >>
1567
1568 =cut
1569
1570 sub count {
1571   my $self = shift;
1572   return $self->search(@_)->count if @_ and defined $_[0];
1573   return scalar @{ $self->get_cache } if $self->get_cache;
1574
1575   my $attrs = { %{ $self->_resolved_attrs } };
1576
1577   # this is a little optimization - it is faster to do the limit
1578   # adjustments in software, instead of a subquery
1579   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1580
1581   my $crs;
1582   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1583     $crs = $self->_count_subq_rs ($attrs);
1584   }
1585   else {
1586     $crs = $self->_count_rs ($attrs);
1587   }
1588   my $count = $crs->next;
1589
1590   $count -= $offset if $offset;
1591   $count = $rows if $rows and $rows < $count;
1592   $count = 0 if ($count < 0);
1593
1594   return $count;
1595 }
1596
1597 =head2 count_rs
1598
1599 =over 4
1600
1601 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1602
1603 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1604
1605 =back
1606
1607 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1608 This can be very handy for subqueries:
1609
1610   ->search( { amount => $some_rs->count_rs->as_query } )
1611
1612 As with regular resultsets the SQL query will be executed only after
1613 the resultset is accessed via L</next> or L</all>. That would return
1614 the same single value obtainable via L</count>.
1615
1616 =cut
1617
1618 sub count_rs {
1619   my $self = shift;
1620   return $self->search(@_)->count_rs if @_;
1621
1622   # this may look like a lack of abstraction (count() does about the same)
1623   # but in fact an _rs *must* use a subquery for the limits, as the
1624   # software based limiting can not be ported if this $rs is to be used
1625   # in a subquery itself (i.e. ->as_query)
1626   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1627     return $self->_count_subq_rs($self->{_attrs});
1628   }
1629   else {
1630     return $self->_count_rs($self->{_attrs});
1631   }
1632 }
1633
1634 #
1635 # returns a ResultSetColumn object tied to the count query
1636 #
1637 sub _count_rs {
1638   my ($self, $attrs) = @_;
1639
1640   my $rsrc = $self->result_source;
1641
1642   my $tmp_attrs = { %$attrs };
1643   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1644   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1645
1646   # overwrite the selector (supplied by the storage)
1647   $rsrc->resultset_class->new($rsrc, {
1648     %$tmp_attrs,
1649     select => $rsrc->schema->storage->_count_select ($rsrc, $attrs),
1650     as => 'count',
1651   })->get_column ('count');
1652 }
1653
1654 #
1655 # same as above but uses a subquery
1656 #
1657 sub _count_subq_rs {
1658   my ($self, $attrs) = @_;
1659
1660   my $rsrc = $self->result_source;
1661
1662   my $sub_attrs = { %$attrs };
1663   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1664   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1665
1666   # if we multi-prefetch we group_by something unique, as this is what we would
1667   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1668   if ( $attrs->{collapse}  ) {
1669     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1670       $rsrc->_identifying_column_set || $self->throw_exception(
1671         'Unable to construct a unique group_by criteria properly collapsing the '
1672       . 'has_many prefetch before count()'
1673       );
1674     } ]
1675   }
1676
1677   # Calculate subquery selector
1678   if (my $g = $sub_attrs->{group_by}) {
1679
1680     my $sql_maker = $rsrc->schema->storage->sql_maker;
1681
1682     # necessary as the group_by may refer to aliased functions
1683     my $sel_index;
1684     for my $sel (@{$attrs->{select}}) {
1685       $sel_index->{$sel->{-as}} = $sel
1686         if (ref $sel eq 'HASH' and $sel->{-as});
1687     }
1688
1689     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1690     # also look for named aggregates referred in the having clause
1691     # having often contains scalarrefs - thus parse it out entirely
1692     my @parts = @$g;
1693     if ($attrs->{having}) {
1694       local $sql_maker->{having_bind};
1695       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1696       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1697       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1698         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1699         # if we don't unset it we screw up retarded but unfortunately working
1700         # 'MAX(foo.bar)' => { '>', 3 }
1701         $sql_maker->{name_sep} = '';
1702       }
1703
1704       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1705
1706       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1707       my %seen_having;
1708
1709       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1710       # and if all fails for an utterly naive quoted scalar-with-function
1711       while ($having_sql =~ /
1712         $rquote $sep $lquote (.+?) $rquote
1713           |
1714         [\s,] \w+ \. (\w+) [\s,]
1715           |
1716         [\s,] $lquote (.+?) $rquote [\s,]
1717       /gx) {
1718         my $part = $1 || $2 || $3;  # one of them matched if we got here
1719         unless ($seen_having{$part}++) {
1720           push @parts, $part;
1721         }
1722       }
1723     }
1724
1725     for (@parts) {
1726       my $colpiece = $sel_index->{$_} || $_;
1727
1728       # unqualify join-based group_by's. Arcane but possible query
1729       # also horrible horrible hack to alias a column (not a func.)
1730       # (probably need to introduce SQLA syntax)
1731       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1732         my $as = $colpiece;
1733         $as =~ s/\./__/;
1734         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1735       }
1736       push @{$sub_attrs->{select}}, $colpiece;
1737     }
1738   }
1739   else {
1740     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1741     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1742   }
1743
1744   return $rsrc->resultset_class
1745                ->new ($rsrc, $sub_attrs)
1746                 ->as_subselect_rs
1747                  ->search ({}, { columns => { count => $rsrc->schema->storage->_count_select ($rsrc, $attrs) } })
1748                   ->get_column ('count');
1749 }
1750
1751
1752 =head2 count_literal
1753
1754 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1755 should only be used in that context. See L</search_literal> for further info.
1756
1757 =over 4
1758
1759 =item Arguments: $sql_fragment, @standalone_bind_values
1760
1761 =item Return Value: $count
1762
1763 =back
1764
1765 Counts the results in a literal query. Equivalent to calling L</search_literal>
1766 with the passed arguments, then L</count>.
1767
1768 =cut
1769
1770 sub count_literal :DBIC_method_is_indirect_sugar {
1771   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1772   shift->search_literal(@_)->count
1773 }
1774
1775 =head2 all
1776
1777 =over 4
1778
1779 =item Arguments: none
1780
1781 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1782
1783 =back
1784
1785 Returns all elements in the resultset.
1786
1787 =cut
1788
1789 sub all {
1790   my $self = shift;
1791   if(@_) {
1792     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1793   }
1794
1795   delete @{$self}{qw/_stashed_rows _stashed_results/};
1796
1797   if (my $c = $self->get_cache) {
1798     return @$c;
1799   }
1800
1801   $self->cursor->reset;
1802
1803   my $objs = $self->_construct_results('fetch_all') || [];
1804
1805   $self->set_cache($objs) if $self->{attrs}{cache};
1806
1807   return @$objs;
1808 }
1809
1810 =head2 reset
1811
1812 =over 4
1813
1814 =item Arguments: none
1815
1816 =item Return Value: $self
1817
1818 =back
1819
1820 Resets the resultset's cursor, so you can iterate through the elements again.
1821 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1822 another query.
1823
1824 =cut
1825
1826 sub reset {
1827   my ($self) = @_;
1828
1829   delete @{$self}{qw/_stashed_rows _stashed_results/};
1830   $self->{all_cache_position} = 0;
1831   $self->cursor->reset;
1832   return $self;
1833 }
1834
1835 =head2 first
1836
1837 =over 4
1838
1839 =item Arguments: none
1840
1841 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1842
1843 =back
1844
1845 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1846 an object for the first result (or C<undef> if the resultset is empty).
1847
1848 =cut
1849
1850 sub first :DBIC_method_is_indirect_sugar {
1851   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1852   return $_[0]->reset->next;
1853 }
1854
1855
1856 # _rs_update_delete
1857 #
1858 # Determines whether and what type of subquery is required for the $rs operation.
1859 # If grouping is necessary either supplies its own, or verifies the current one
1860 # After all is done delegates to the proper storage method.
1861
1862 sub _rs_update_delete {
1863   my ($self, $op, $values) = @_;
1864
1865   my $rsrc = $self->result_source;
1866   my $storage = $rsrc->schema->storage;
1867
1868   my $attrs = { %{$self->_resolved_attrs} };
1869
1870   my $join_classifications;
1871   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1872
1873   # do we need a subquery for any reason?
1874   my $needs_subq = (
1875     defined $existing_group_by
1876       or
1877     # if {from} is unparseable wrap a subq
1878     ref($attrs->{from}) ne 'ARRAY'
1879       or
1880     # limits call for a subq
1881     $self->_has_resolved_attr(qw/rows offset/)
1882   );
1883
1884   # simplify the joinmap, so we can further decide if a subq is necessary
1885   if (!$needs_subq and @{$attrs->{from}} > 1) {
1886
1887     ($attrs->{from}, $join_classifications) =
1888       $storage->_prune_unused_joins ($attrs);
1889
1890     # any non-pruneable non-local restricting joins imply subq
1891     $needs_subq = grep { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1892   }
1893
1894   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1895   $needs_subq ||= (
1896     (ref $attrs->{from}[0]) ne 'HASH'
1897       or
1898     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1899   );
1900
1901   my ($cond, $guard);
1902   # do we need anything like a subquery?
1903   if (! $needs_subq) {
1904     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1905     # a condition containing 'me' or other table prefixes will not work
1906     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1907     $cond = do {
1908       my $sqla = $rsrc->schema->storage->sql_maker;
1909       local $sqla->{_dequalify_idents} = 1;
1910       \[ $sqla->_recurse_where($self->{cond}) ];
1911     };
1912   }
1913   else {
1914     # we got this far - means it is time to wrap a subquery
1915     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1916       sprintf(
1917         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1918         $op,
1919         $rsrc->source_name,
1920       )
1921     );
1922
1923     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1924     delete $attrs->{$_} for qw/select as collapse/;
1925     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1926
1927     # this will be consumed by the pruner waaaaay down the stack
1928     $attrs->{_force_prune_multiplying_joins} = 1;
1929
1930     my $subrs = (ref $self)->new($rsrc, $attrs);
1931
1932     if (@$idcols == 1) {
1933       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1934     }
1935     elsif ($storage->_use_multicolumn_in) {
1936       # no syntax for calling this properly yet
1937       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1938       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1939         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1940         $subrs->as_query
1941       ),
1942     }
1943     else {
1944       # if all else fails - get all primary keys and operate over a ORed set
1945       # wrap in a transaction for consistency
1946       # this is where the group_by/multiplication starts to matter
1947       if (
1948         $existing_group_by
1949           or
1950         # we do not need to check pre-multipliers, since if the premulti is there, its
1951         # parent (who is multi) will be there too
1952         keys %{ $join_classifications->{multiplying} || {} }
1953       ) {
1954         # make sure if there is a supplied group_by it matches the columns compiled above
1955         # perfectly. Anything else can not be sanely executed on most databases so croak
1956         # right then and there
1957         if ($existing_group_by) {
1958           my @current_group_by = map
1959             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1960             @$existing_group_by
1961           ;
1962
1963           if (
1964             join ("\x00", sort @current_group_by)
1965               ne
1966             join ("\x00", sort @{$attrs->{columns}} )
1967           ) {
1968             $self->throw_exception (
1969               "You have just attempted a $op operation on a resultset which does group_by"
1970               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1971               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1972               . ' kind of queries. Please retry the operation with a modified group_by or'
1973               . ' without using one at all.'
1974             );
1975           }
1976         }
1977
1978         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1979       }
1980
1981       $guard = $storage->txn_scope_guard;
1982
1983       for my $row ($subrs->cursor->all) {
1984         push @$cond, { map
1985           { $idcols->[$_] => $row->[$_] }
1986           (0 .. $#$idcols)
1987         };
1988       }
1989     }
1990   }
1991
1992   my $res = $cond ? $storage->$op (
1993     $rsrc,
1994     $op eq 'update' ? $values : (),
1995     $cond,
1996   ) : '0E0';
1997
1998   $guard->commit if $guard;
1999
2000   return $res;
2001 }
2002
2003 =head2 update
2004
2005 =over 4
2006
2007 =item Arguments: \%values
2008
2009 =item Return Value: $underlying_storage_rv
2010
2011 =back
2012
2013 Sets the specified columns in the resultset to the supplied values in a
2014 single query. Note that this will not run any accessor/set_column/update
2015 triggers, nor will it update any result object instances derived from this
2016 resultset (this includes the contents of the L<resultset cache|/set_cache>
2017 if any). See L</update_all> if you need to execute any on-update
2018 triggers or cascades defined either by you or a
2019 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2020
2021 The return value is a pass through of what the underlying
2022 storage backend returned, and may vary. See L<DBI/execute> for the most
2023 common case.
2024
2025 =head3 CAVEAT
2026
2027 Note that L</update> does not process/deflate any of the values passed in.
2028 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2029 ensure manually that any value passed to this method will stringify to
2030 something the RDBMS knows how to deal with. A notable example is the
2031 handling of L<DateTime> objects, for more info see:
2032 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2033
2034 =cut
2035
2036 sub update {
2037   my ($self, $values) = @_;
2038   $self->throw_exception('Values for update must be a hash')
2039     unless ref $values eq 'HASH';
2040
2041   return $self->_rs_update_delete ('update', $values);
2042 }
2043
2044 =head2 update_all
2045
2046 =over 4
2047
2048 =item Arguments: \%values
2049
2050 =item Return Value: 1
2051
2052 =back
2053
2054 Fetches all objects and updates them one at a time via
2055 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2056 triggers, while L</update> will not.
2057
2058 =cut
2059
2060 sub update_all {
2061   my ($self, $values) = @_;
2062   $self->throw_exception('Values for update_all must be a hash')
2063     unless ref $values eq 'HASH';
2064
2065   my $guard = $self->result_source->schema->txn_scope_guard;
2066   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2067   $guard->commit;
2068   return 1;
2069 }
2070
2071 =head2 delete
2072
2073 =over 4
2074
2075 =item Arguments: none
2076
2077 =item Return Value: $underlying_storage_rv
2078
2079 =back
2080
2081 Deletes the rows matching this resultset in a single query. Note that this
2082 will not run any delete triggers, nor will it alter the
2083 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2084 derived from this resultset (this includes the contents of the
2085 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2086 execute any on-delete triggers or cascades defined either by you or a
2087 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2088
2089 The return value is a pass through of what the underlying storage backend
2090 returned, and may vary. See L<DBI/execute> for the most common case.
2091
2092 =cut
2093
2094 sub delete {
2095   my $self = shift;
2096   $self->throw_exception('delete does not accept any arguments')
2097     if @_;
2098
2099   return $self->_rs_update_delete ('delete');
2100 }
2101
2102 =head2 delete_all
2103
2104 =over 4
2105
2106 =item Arguments: none
2107
2108 =item Return Value: 1
2109
2110 =back
2111
2112 Fetches all objects and deletes them one at a time via
2113 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2114 triggers, while L</delete> will not.
2115
2116 =cut
2117
2118 sub delete_all {
2119   my $self = shift;
2120   $self->throw_exception('delete_all does not accept any arguments')
2121     if @_;
2122
2123   my $guard = $self->result_source->schema->txn_scope_guard;
2124   $_->delete for $self->all;
2125   $guard->commit;
2126   return 1;
2127 }
2128
2129 =head2 populate
2130
2131 =over 4
2132
2133 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2134
2135 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2136
2137 =back
2138
2139 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2140 arrayrefs.
2141
2142 =over
2143
2144 =item NOTE
2145
2146 The context of this method call has an important effect on what is
2147 submitted to storage. In void context data is fed directly to fastpath
2148 insertion routines provided by the underlying storage (most often
2149 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2150 L<insert|DBIx::Class::Row/insert> calls on the
2151 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2152 augmentation of these methods provided by components. For example if you
2153 are using something like L<DBIx::Class::UUIDColumns> to create primary
2154 keys for you, you will find that your PKs are empty.  In this case you
2155 will have to explicitly force scalar or list context in order to create
2156 those values.
2157
2158 =back
2159
2160 In non-void (scalar or list) context, this method is simply a wrapper
2161 for L</create>. Depending on list or scalar context either a list of
2162 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2163 containing these objects is returned.
2164
2165 When supplying data in "arrayref of arrayrefs" invocation style, the
2166 first element should be a list of column names and each subsequent
2167 element should be a data value in the earlier specified column order.
2168 For example:
2169
2170   $schema->resultset("Artist")->populate([
2171     [ qw( artistid name ) ],
2172     [ 100, 'A Formally Unknown Singer' ],
2173     [ 101, 'A singer that jumped the shark two albums ago' ],
2174     [ 102, 'An actually cool singer' ],
2175   ]);
2176
2177 For the arrayref of hashrefs style each hashref should be a structure
2178 suitable for passing to L</create>. Multi-create is also permitted with
2179 this syntax.
2180
2181   $schema->resultset("Artist")->populate([
2182      { artistid => 4, name => 'Manufactured Crap', cds => [
2183         { title => 'My First CD', year => 2006 },
2184         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2185       ],
2186      },
2187      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2188         { title => 'My parents sold me to a record company', year => 2005 },
2189         { title => 'Why Am I So Ugly?', year => 2006 },
2190         { title => 'I Got Surgery and am now Popular', year => 2007 }
2191       ],
2192      },
2193   ]);
2194
2195 If you attempt a void-context multi-create as in the example above (each
2196 Artist also has the related list of CDs), and B<do not> supply the
2197 necessary autoinc foreign key information, this method will proxy to the
2198 less efficient L</create>, and then throw the Result objects away. In this
2199 case there are obviously no benefits to using this method over L</create>.
2200
2201 =cut
2202
2203 sub populate {
2204   my $self = shift;
2205
2206   # this is naive and just a quick check
2207   # the types will need to be checked more thoroughly when the
2208   # multi-source populate gets added
2209   my $data = (
2210     ref $_[0] eq 'ARRAY'
2211       and
2212     ( @{$_[0]} or return )
2213       and
2214     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2215       and
2216     $_[0]
2217   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2218
2219   # FIXME - no cref handling
2220   # At this point assume either hashes or arrays
2221
2222   my $rsrc = $self->result_source;
2223
2224   if(defined wantarray) {
2225     my (@results, $guard);
2226
2227     if (ref $data->[0] eq 'ARRAY') {
2228       # column names only, nothing to do
2229       return if @$data == 1;
2230
2231       $guard = $rsrc->schema->storage->txn_scope_guard
2232         if @$data > 2;
2233
2234       @results = map
2235         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2236         @{$data}[1 .. $#$data]
2237       ;
2238     }
2239     else {
2240
2241       $guard = $rsrc->schema->storage->txn_scope_guard
2242         if @$data > 1;
2243
2244       @results = map { $self->new_result($_)->insert } @$data;
2245     }
2246
2247     $guard->commit if $guard;
2248     return wantarray ? @results : \@results;
2249   }
2250
2251   # we have to deal with *possibly incomplete* related data
2252   # this means we have to walk the data structure twice
2253   # whether we want this or not
2254   # jnap, I hate you ;)
2255   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2256
2257   my ($colinfo, $colnames, $slices_with_rels);
2258   my $data_start = 0;
2259
2260   DATA_SLICE:
2261   for my $i (0 .. $#$data) {
2262
2263     my $current_slice_seen_rel_infos;
2264
2265 ### Determine/Supplement collists
2266 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2267     if( ref $data->[$i] eq 'ARRAY' ) {
2268
2269       # positional(!) explicit column list
2270       if ($i == 0) {
2271         # column names only, nothing to do
2272         return if @$data == 1;
2273
2274         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2275           for 0 .. $#{$data->[0]};
2276
2277         $data_start = 1;
2278
2279         next DATA_SLICE;
2280       }
2281       else {
2282         for (values %$colinfo) {
2283           if ($_->{is_rel} ||= (
2284             $rel_info->{$_->{name}}
2285               and
2286             (
2287               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2288                 or
2289               ref $data->[$i][$_->{pos}] eq 'HASH'
2290                 or
2291               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2292             )
2293               and
2294             1
2295           )) {
2296
2297             # moar sanity check... sigh
2298             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2299               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2300                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2301                 return my $throwaway = $self->populate(@_);
2302               }
2303             }
2304
2305             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2306           }
2307         }
2308       }
2309
2310      if ($current_slice_seen_rel_infos) {
2311         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2312
2313         # this is needed further down to decide whether or not to fallback to create()
2314         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2315           for 0 .. $#$colnames;
2316       }
2317     }
2318     elsif( ref $data->[$i] eq 'HASH' ) {
2319
2320       for ( sort keys %{$data->[$i]} ) {
2321
2322         $colinfo->{$_} ||= do {
2323
2324           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2325             if $data_start; # it will be 0 on AoH, 1 on AoA
2326
2327           push @$colnames, $_;
2328
2329           # RV
2330           { pos => $#$colnames, name => $_ }
2331         };
2332
2333         if ($colinfo->{$_}{is_rel} ||= (
2334           $rel_info->{$_}
2335             and
2336           (
2337             ref $data->[$i]{$_} eq 'ARRAY'
2338               or
2339             ref $data->[$i]{$_} eq 'HASH'
2340               or
2341             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2342           )
2343             and
2344           1
2345         )) {
2346
2347           # moar sanity check... sigh
2348           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2349             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2350               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2351               return my $throwaway = $self->populate(@_);
2352             }
2353           }
2354
2355           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2356         }
2357       }
2358
2359       if ($current_slice_seen_rel_infos) {
2360         push @$slices_with_rels, $data->[$i];
2361
2362         # this is needed further down to decide whether or not to fallback to create()
2363         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2364           for keys %{$data->[$i]};
2365       }
2366     }
2367     else {
2368       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2369     }
2370
2371     if ( grep
2372       { $_->{attrs}{is_depends_on} }
2373       @{ $current_slice_seen_rel_infos || [] }
2374     ) {
2375       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2376       return my $throwaway = $self->populate(@_);
2377     }
2378   }
2379
2380   if( $slices_with_rels ) {
2381
2382     # need to exclude the rel "columns"
2383     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2384
2385     # extra sanity check - ensure the main source is in fact identifiable
2386     # the localizing of nullability is insane, but oh well... the use-case is legit
2387     my $ci = $rsrc->columns_info($colnames);
2388
2389     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2390       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2391
2392     unless( $rsrc->_identifying_column_set($ci) ) {
2393       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2394       return my $throwaway = $self->populate(@_);
2395     }
2396   }
2397
2398 ### inherit the data locked in the conditions of the resultset
2399   my ($rs_data) = $self->_merge_with_rscond({});
2400   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2401
2402   # if anything left - decompose rs_data
2403   my $rs_data_vals;
2404   if (keys %$rs_data) {
2405      push @$rs_data_vals, $rs_data->{$_}
2406       for sort keys %$rs_data;
2407   }
2408
2409 ### start work
2410   my $guard;
2411   $guard = $rsrc->schema->storage->txn_scope_guard
2412     if $slices_with_rels;
2413
2414 ### main source data
2415   # FIXME - need to switch entirely to a coderef-based thing,
2416   # so that large sets aren't copied several times... I think
2417   $rsrc->schema->storage->_insert_bulk(
2418     $rsrc,
2419     [ @$colnames, sort keys %$rs_data ],
2420     [ map {
2421       ref $data->[$_] eq 'ARRAY'
2422       ? (
2423           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2424         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2425         :                     $data->[$_]
2426       )
2427       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2428     } $data_start .. $#$data ],
2429   );
2430
2431 ### do the children relationships
2432   if ( $slices_with_rels ) {
2433     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2434       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2435
2436     for my $sl (@$slices_with_rels) {
2437
2438       my ($main_proto, $main_proto_rs);
2439       for my $rel (@rels) {
2440         next unless defined $sl->{$rel};
2441
2442         $main_proto ||= {
2443           %$rs_data,
2444           (map { $_ => $sl->{$_} } @$colnames),
2445         };
2446
2447         unless (defined $colinfo->{$rel}{rs}) {
2448
2449           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2450
2451           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2452             rel_name => $rel,
2453             self_alias => "\xFE", # irrelevant
2454             foreign_alias => "\xFF", # irrelevant
2455           )->{identity_map} || {} } };
2456
2457         }
2458
2459         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2460           {
2461             $_ => { '=' =>
2462               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2463                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2464                  ->as_query
2465             }
2466           }
2467           keys %{$colinfo->{$rel}{fk_map}}
2468         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2469
2470         1;
2471       }
2472     }
2473   }
2474
2475   $guard->commit if $guard;
2476 }
2477
2478 =head2 pager
2479
2480 =over 4
2481
2482 =item Arguments: none
2483
2484 =item Return Value: L<$pager|Data::Page>
2485
2486 =back
2487
2488 Returns a L<Data::Page> object for the current resultset. Only makes
2489 sense for queries with a C<page> attribute.
2490
2491 To get the full count of entries for a paged resultset, call
2492 C<total_entries> on the L<Data::Page> object.
2493
2494 =cut
2495
2496 sub pager {
2497   my ($self) = @_;
2498
2499   return $self->{pager} if $self->{pager};
2500
2501   my $attrs = $self->{attrs};
2502   if (!defined $attrs->{page}) {
2503     $self->throw_exception("Can't create pager for non-paged rs");
2504   }
2505   elsif ($attrs->{page} <= 0) {
2506     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2507   }
2508   $attrs->{rows} ||= 10;
2509
2510   # throw away the paging flags and re-run the count (possibly
2511   # with a subselect) to get the real total count
2512   my $count_attrs = { %$attrs };
2513   delete @{$count_attrs}{qw/rows offset page pager/};
2514
2515   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2516
2517   require DBIx::Class::ResultSet::Pager;
2518   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2519     sub { $total_rs->count },  #lazy-get the total
2520     $attrs->{rows},
2521     $self->{attrs}{page},
2522   );
2523 }
2524
2525 =head2 page
2526
2527 =over 4
2528
2529 =item Arguments: $page_number
2530
2531 =item Return Value: L<$resultset|/search>
2532
2533 =back
2534
2535 Returns a resultset for the $page_number page of the resultset on which page
2536 is called, where each page contains a number of rows equal to the 'rows'
2537 attribute set on the resultset (10 by default).
2538
2539 =cut
2540
2541 sub page {
2542   my ($self, $page) = @_;
2543   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2544 }
2545
2546 =head2 new_result
2547
2548 =over 4
2549
2550 =item Arguments: \%col_data
2551
2552 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2553
2554 =back
2555
2556 Creates a new result object in the resultset's result class and returns
2557 it. The row is not inserted into the database at this point, call
2558 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2559 will tell you whether the result object has been inserted or not.
2560
2561 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2562
2563 =cut
2564
2565 sub new_result {
2566   my ($self, $values) = @_;
2567
2568   $self->throw_exception( "Result object instantiation requires a single hashref argument" )
2569     if @_ > 2 or ref $values ne 'HASH';
2570
2571   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2572
2573   my $new = $self->result_class->new({
2574     %$merged_cond,
2575     ( @$cols_from_relations
2576       ? (-cols_from_relations => $cols_from_relations)
2577       : ()
2578     ),
2579     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2580   });
2581
2582   if (
2583     reftype($new) eq 'HASH'
2584       and
2585     ! keys %$new
2586       and
2587     blessed($new)
2588   ) {
2589     carp_unique (sprintf (
2590       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2591       $self->result_class,
2592     ));
2593   }
2594
2595   $new;
2596 }
2597
2598 # _merge_with_rscond
2599 #
2600 # Takes a simple hash of K/V data and returns its copy merged with the
2601 # condition already present on the resultset. Additionally returns an
2602 # arrayref of value/condition names, which were inferred from related
2603 # objects (this is needed for in-memory related objects)
2604 sub _merge_with_rscond {
2605   my ($self, $data) = @_;
2606
2607   my ($implied_data, @cols_from_relations);
2608
2609   my $alias = $self->{attrs}{alias};
2610
2611   if (! defined $self->{cond}) {
2612     # just massage $data below
2613   }
2614   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2615     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2616     @cols_from_relations = keys %{ $implied_data || {} };
2617   }
2618   else {
2619     my $eqs = extract_equality_conditions( $self->{cond}, 'consider_nulls' );
2620     $implied_data = { map {
2621       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2622     } keys %$eqs };
2623   }
2624
2625   return (
2626     { map
2627       { %{ $self->_remove_alias($_, $alias) } }
2628       # precedence must be given to passed values over values inherited from
2629       # the cond, so the order here is important.
2630       ( $implied_data||(), $data)
2631     },
2632     \@cols_from_relations
2633   );
2634 }
2635
2636 # _has_resolved_attr
2637 #
2638 # determines if the resultset defines at least one
2639 # of the attributes supplied
2640 #
2641 # used to determine if a subquery is necessary
2642 #
2643 # supports some virtual attributes:
2644 #   -join
2645 #     This will scan for any joins being present on the resultset.
2646 #     It is not a mere key-search but a deep inspection of {from}
2647 #
2648
2649 sub _has_resolved_attr {
2650   my ($self, @attr_names) = @_;
2651
2652   my $attrs = $self->_resolved_attrs;
2653
2654   my %extra_checks;
2655
2656   for my $n (@attr_names) {
2657     if (grep { $n eq $_ } (qw/-join/) ) {
2658       $extra_checks{$n}++;
2659       next;
2660     }
2661
2662     my $attr =  $attrs->{$n};
2663
2664     next if not defined $attr;
2665
2666     if (ref $attr eq 'HASH') {
2667       return 1 if keys %$attr;
2668     }
2669     elsif (ref $attr eq 'ARRAY') {
2670       return 1 if @$attr;
2671     }
2672     else {
2673       return 1 if $attr;
2674     }
2675   }
2676
2677   # a resolved join is expressed as a multi-level from
2678   return 1 if (
2679     $extra_checks{-join}
2680       and
2681     ref $attrs->{from} eq 'ARRAY'
2682       and
2683     @{$attrs->{from}} > 1
2684   );
2685
2686   return 0;
2687 }
2688
2689 # _remove_alias
2690 #
2691 # Remove the specified alias from the specified query hash. A copy is made so
2692 # the original query is not modified.
2693
2694 sub _remove_alias {
2695   my ($self, $query, $alias) = @_;
2696
2697   my %orig = %{ $query || {} };
2698   my %unaliased;
2699
2700   foreach my $key (keys %orig) {
2701     if ($key !~ /\./) {
2702       $unaliased{$key} = $orig{$key};
2703       next;
2704     }
2705     $unaliased{$1} = $orig{$key}
2706       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2707   }
2708
2709   return \%unaliased;
2710 }
2711
2712 =head2 as_query
2713
2714 =over 4
2715
2716 =item Arguments: none
2717
2718 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2719
2720 =back
2721
2722 Returns the SQL query and bind vars associated with the invocant.
2723
2724 This is generally used as the RHS for a subquery.
2725
2726 =cut
2727
2728 sub as_query {
2729   my $self = shift;
2730
2731   my $attrs = { %{ $self->_resolved_attrs } };
2732
2733   my $aq = $self->result_source->schema->storage->_select_args_to_query (
2734     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2735   );
2736
2737   $aq;
2738 }
2739
2740 =head2 find_or_new
2741
2742 =over 4
2743
2744 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2745
2746 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2747
2748 =back
2749
2750   my $artist = $schema->resultset('Artist')->find_or_new(
2751     { artist => 'fred' }, { key => 'artists' });
2752
2753   $cd->cd_to_producer->find_or_new({ producer => $producer },
2754                                    { key => 'primary' });
2755
2756 Find an existing record from this resultset using L</find>. if none exists,
2757 instantiate a new result object and return it. The object will not be saved
2758 into your storage until you call L<DBIx::Class::Row/insert> on it.
2759
2760 You most likely want this method when looking for existing rows using a unique
2761 constraint that is not the primary key, or looking for related rows.
2762
2763 If you want objects to be saved immediately, use L</find_or_create> instead.
2764
2765 B<Note>: Make sure to read the documentation of L</find> and understand the
2766 significance of the C<key> attribute, as its lack may skew your search, and
2767 subsequently result in spurious new objects.
2768
2769 B<Note>: Take care when using C<find_or_new> with a table having
2770 columns with default values that you intend to be automatically
2771 supplied by the database (e.g. an auto_increment primary key column).
2772 In normal usage, the value of such columns should NOT be included at
2773 all in the call to C<find_or_new>, even when set to C<undef>.
2774
2775 =cut
2776
2777 sub find_or_new {
2778   my $self     = shift;
2779   my $attrs    = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
2780   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2781   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2782     return $row;
2783   }
2784   return $self->new_result($hash);
2785 }
2786
2787 =head2 create
2788
2789 =over 4
2790
2791 =item Arguments: \%col_data
2792
2793 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2794
2795 =back
2796
2797 Attempt to create a single new row or a row with multiple related rows
2798 in the table represented by the resultset (and related tables). This
2799 will not check for duplicate rows before inserting, use
2800 L</find_or_create> to do that.
2801
2802 To create one row for this resultset, pass a hashref of key/value
2803 pairs representing the columns of the table and the values you wish to
2804 store. If the appropriate relationships are set up, foreign key fields
2805 can also be passed an object representing the foreign row, and the
2806 value will be set to its primary key.
2807
2808 To create related objects, pass a hashref of related-object column values
2809 B<keyed on the relationship name>. If the relationship is of type C<multi>
2810 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2811 The process will correctly identify columns holding foreign keys, and will
2812 transparently populate them from the keys of the corresponding relation.
2813 This can be applied recursively, and will work correctly for a structure
2814 with an arbitrary depth and width, as long as the relationships actually
2815 exists and the correct column data has been supplied.
2816
2817 Instead of hashrefs of plain related data (key/value pairs), you may
2818 also pass new or inserted objects. New objects (not inserted yet, see
2819 L</new_result>), will be inserted into their appropriate tables.
2820
2821 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2822
2823 Example of creating a new row.
2824
2825   $person_rs->create({
2826     name=>"Some Person",
2827     email=>"somebody@someplace.com"
2828   });
2829
2830 Example of creating a new row and also creating rows in a related C<has_many>
2831 or C<has_one> resultset.  Note Arrayref.
2832
2833   $artist_rs->create(
2834      { artistid => 4, name => 'Manufactured Crap', cds => [
2835         { title => 'My First CD', year => 2006 },
2836         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2837       ],
2838      },
2839   );
2840
2841 Example of creating a new row and also creating a row in a related
2842 C<belongs_to> resultset. Note Hashref.
2843
2844   $cd_rs->create({
2845     title=>"Music for Silly Walks",
2846     year=>2000,
2847     artist => {
2848       name=>"Silly Musician",
2849     }
2850   });
2851
2852 =over
2853
2854 =item WARNING
2855
2856 When subclassing ResultSet never attempt to override this method. Since
2857 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2858 lot of the internals simply never call it, so your override will be
2859 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2860 or L<DBIx::Class::Row/insert> depending on how early in the
2861 L</create> process you need to intervene. See also warning pertaining to
2862 L</new>.
2863
2864 =back
2865
2866 =cut
2867
2868 sub create :DBIC_method_is_indirect_sugar {
2869   #my ($self, $col_data) = @_;
2870   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2871   return shift->new_result(shift)->insert;
2872 }
2873
2874 =head2 find_or_create
2875
2876 =over 4
2877
2878 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2879
2880 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2881
2882 =back
2883
2884   $cd->cd_to_producer->find_or_create({ producer => $producer },
2885                                       { key => 'primary' });
2886
2887 Tries to find a record based on its primary key or unique constraints; if none
2888 is found, creates one and returns that instead.
2889
2890   my $cd = $schema->resultset('CD')->find_or_create({
2891     cdid   => 5,
2892     artist => 'Massive Attack',
2893     title  => 'Mezzanine',
2894     year   => 2005,
2895   });
2896
2897 Also takes an optional C<key> attribute, to search by a specific key or unique
2898 constraint. For example:
2899
2900   my $cd = $schema->resultset('CD')->find_or_create(
2901     {
2902       artist => 'Massive Attack',
2903       title  => 'Mezzanine',
2904     },
2905     { key => 'cd_artist_title' }
2906   );
2907
2908 B<Note>: Make sure to read the documentation of L</find> and understand the
2909 significance of the C<key> attribute, as its lack may skew your search, and
2910 subsequently result in spurious row creation.
2911
2912 B<Note>: Because find_or_create() reads from the database and then
2913 possibly inserts based on the result, this method is subject to a race
2914 condition. Another process could create a record in the table after
2915 the find has completed and before the create has started. To avoid
2916 this problem, use find_or_create() inside a transaction.
2917
2918 B<Note>: Take care when using C<find_or_create> with a table having
2919 columns with default values that you intend to be automatically
2920 supplied by the database (e.g. an auto_increment primary key column).
2921 In normal usage, the value of such columns should NOT be included at
2922 all in the call to C<find_or_create>, even when set to C<undef>.
2923
2924 See also L</find> and L</update_or_create>. For information on how to declare
2925 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2926
2927 If you need to know if an existing row was found or a new one created use
2928 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2929 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2930 database!
2931
2932   my $cd = $schema->resultset('CD')->find_or_new({
2933     cdid   => 5,
2934     artist => 'Massive Attack',
2935     title  => 'Mezzanine',
2936     year   => 2005,
2937   });
2938
2939   if( !$cd->in_storage ) {
2940       # do some stuff
2941       $cd->insert;
2942   }
2943
2944 =cut
2945
2946 sub find_or_create {
2947   my $self     = shift;
2948   my $attrs    = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
2949   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2950   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2951     return $row;
2952   }
2953   return $self->new_result($hash)->insert;
2954 }
2955
2956 =head2 update_or_create
2957
2958 =over 4
2959
2960 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2961
2962 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2963
2964 =back
2965
2966   $resultset->update_or_create({ col => $val, ... });
2967
2968 Like L</find_or_create>, but if a row is found it is immediately updated via
2969 C<< $found_row->update (\%col_data) >>.
2970
2971
2972 Takes an optional C<key> attribute to search on a specific unique constraint.
2973 For example:
2974
2975   # In your application
2976   my $cd = $schema->resultset('CD')->update_or_create(
2977     {
2978       artist => 'Massive Attack',
2979       title  => 'Mezzanine',
2980       year   => 1998,
2981     },
2982     { key => 'cd_artist_title' }
2983   );
2984
2985   $cd->cd_to_producer->update_or_create({
2986     producer => $producer,
2987     name => 'harry',
2988   }, {
2989     key => 'primary',
2990   });
2991
2992 B<Note>: Make sure to read the documentation of L</find> and understand the
2993 significance of the C<key> attribute, as its lack may skew your search, and
2994 subsequently result in spurious row creation.
2995
2996 B<Note>: Take care when using C<update_or_create> with a table having
2997 columns with default values that you intend to be automatically
2998 supplied by the database (e.g. an auto_increment primary key column).
2999 In normal usage, the value of such columns should NOT be included at
3000 all in the call to C<update_or_create>, even when set to C<undef>.
3001
3002 See also L</find> and L</find_or_create>. For information on how to declare
3003 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3004
3005 If you need to know if an existing row was updated or a new one created use
3006 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3007 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3008 database!
3009
3010 =cut
3011
3012 sub update_or_create {
3013   my $self = shift;
3014   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
3015   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3016
3017   my $row = $self->find($cond, $attrs);
3018   if (defined $row) {
3019     $row->update($cond);
3020     return $row;
3021   }
3022
3023   return $self->new_result($cond)->insert;
3024 }
3025
3026 =head2 update_or_new
3027
3028 =over 4
3029
3030 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3031
3032 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3033
3034 =back
3035
3036   $resultset->update_or_new({ col => $val, ... });
3037
3038 Like L</find_or_new> but if a row is found it is immediately updated via
3039 C<< $found_row->update (\%col_data) >>.
3040
3041 For example:
3042
3043   # In your application
3044   my $cd = $schema->resultset('CD')->update_or_new(
3045     {
3046       artist => 'Massive Attack',
3047       title  => 'Mezzanine',
3048       year   => 1998,
3049     },
3050     { key => 'cd_artist_title' }
3051   );
3052
3053   if ($cd->in_storage) {
3054       # the cd was updated
3055   }
3056   else {
3057       # the cd is not yet in the database, let's insert it
3058       $cd->insert;
3059   }
3060
3061 B<Note>: Make sure to read the documentation of L</find> and understand the
3062 significance of the C<key> attribute, as its lack may skew your search, and
3063 subsequently result in spurious new objects.
3064
3065 B<Note>: Take care when using C<update_or_new> with a table having
3066 columns with default values that you intend to be automatically
3067 supplied by the database (e.g. an auto_increment primary key column).
3068 In normal usage, the value of such columns should NOT be included at
3069 all in the call to C<update_or_new>, even when set to C<undef>.
3070
3071 See also L</find>, L</find_or_create> and L</find_or_new>.
3072
3073 =cut
3074
3075 sub update_or_new {
3076     my $self  = shift;
3077     my $attrs = ( @_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {} );
3078     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3079
3080     my $row = $self->find( $cond, $attrs );
3081     if ( defined $row ) {
3082         $row->update($cond);
3083         return $row;
3084     }
3085
3086     return $self->new_result($cond);
3087 }
3088
3089 =head2 get_cache
3090
3091 =over 4
3092
3093 =item Arguments: none
3094
3095 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3096
3097 =back
3098
3099 Gets the contents of the cache for the resultset, if the cache is set.
3100
3101 The cache is populated either by using the L</prefetch> attribute to
3102 L</search> or by calling L</set_cache>.
3103
3104 =cut
3105
3106 sub get_cache {
3107   shift->{all_cache};
3108 }
3109
3110 =head2 set_cache
3111
3112 =over 4
3113
3114 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3115
3116 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3117
3118 =back
3119
3120 Sets the contents of the cache for the resultset. Expects an arrayref
3121 of objects of the same class as those produced by the resultset. Note that
3122 if the cache is set, the resultset will return the cached objects rather
3123 than re-querying the database even if the cache attr is not set.
3124
3125 The contents of the cache can also be populated by using the
3126 L</prefetch> attribute to L</search>.
3127
3128 =cut
3129
3130 sub set_cache {
3131   my ( $self, $data ) = @_;
3132   $self->throw_exception("set_cache requires an arrayref")
3133       if defined($data) && (ref $data ne 'ARRAY');
3134   $self->{all_cache} = $data;
3135 }
3136
3137 =head2 clear_cache
3138
3139 =over 4
3140
3141 =item Arguments: none
3142
3143 =item Return Value: undef
3144
3145 =back
3146
3147 Clears the cache for the resultset.
3148
3149 =cut
3150
3151 sub clear_cache {
3152   shift->set_cache(undef);
3153 }
3154
3155 =head2 is_paged
3156
3157 =over 4
3158
3159 =item Arguments: none
3160
3161 =item Return Value: true, if the resultset has been paginated
3162
3163 =back
3164
3165 =cut
3166
3167 sub is_paged {
3168   my ($self) = @_;
3169   return !!$self->{attrs}{page};
3170 }
3171
3172 =head2 is_ordered
3173
3174 =over 4
3175
3176 =item Arguments: none
3177
3178 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3179
3180 =back
3181
3182 =cut
3183
3184 sub is_ordered {
3185   my ($self) = @_;
3186   return scalar $self->result_source->schema->storage->_extract_order_criteria($self->{attrs}{order_by});
3187 }
3188
3189 =head2 related_resultset
3190
3191 =over 4
3192
3193 =item Arguments: $rel_name
3194
3195 =item Return Value: L<$resultset|/search>
3196
3197 =back
3198
3199 Returns a related resultset for the supplied relationship name.
3200
3201   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3202
3203 =cut
3204
3205 sub related_resultset {
3206   $_[0]->throw_exception(
3207     'Extra arguments to $rs->related_resultset() were always quietly '
3208   . 'discarded without consideration, you need to switch to '
3209   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3210   ) if @_ > 2;
3211
3212   return $_[0]->{related_resultsets}{$_[1]}
3213     if defined $_[0]->{related_resultsets}{$_[1]};
3214
3215   my ($self, $rel) = @_;
3216
3217   return $self->{related_resultsets}{$rel} = do {
3218     my $rsrc = $self->result_source;
3219     my $rel_info = $rsrc->relationship_info($rel);
3220
3221     $self->throw_exception(
3222       "search_related: result source '" . $rsrc->source_name .
3223         "' has no such relationship $rel")
3224       unless $rel_info;
3225
3226     my $attrs = $self->_chain_relationship($rel);
3227
3228     my $storage = $rsrc->schema->storage;
3229
3230     # Previously this atribute was deleted (instead of being set as it is now)
3231     # Doing so seems to be harmless in all available test permutations
3232     # See also 01d59a6a6 and mst's comment below
3233     #
3234     $attrs->{alias} = $storage->relname_to_table_alias(
3235       $rel,
3236       $attrs->{seen_join}{$rel}
3237     );
3238
3239     # since this is search_related, and we already slid the select window inwards
3240     # (the select/as attrs were deleted in the beginning), we need to flip all
3241     # left joins to inner, so we get the expected results
3242     # read the comment on top of the actual function to see what this does
3243     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3244
3245     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3246     delete $attrs->{result_class};
3247
3248     my $new = do {
3249
3250       # The reason we do this now instead of passing the alias to the
3251       # search_rs below is that if you wrap/overload resultset on the
3252       # source you need to know what alias it's -going- to have for things
3253       # to work sanely (e.g. RestrictWithObject wants to be able to add
3254       # extra query restrictions, and these may need to be $alias.)
3255       #                                       -- mst ~ 2007 (01d59a6a6)
3256       #
3257       # FIXME - this seems to be no longer neccessary (perhaps due to the
3258       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3259       # dependent (as of Jun 2015 ) does not yield any difference with or
3260       # without this line. Nevertheless keep it as is for now, to minimize
3261       # churn, there is enough potential for breakage in 0.0829xx as it is
3262       #                                       -- ribasushi Jun 2015
3263       #
3264       my $rel_source = $rsrc->related_source($rel);
3265       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3266
3267       $rel_source->resultset->search_rs( undef, $attrs );
3268     };
3269
3270     if (my $cache = $self->get_cache) {
3271       my @related_cache = map
3272         { $_->related_resultset($rel)->get_cache || () }
3273         @$cache
3274       ;
3275
3276       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3277     }
3278
3279     $new;
3280   };
3281 }
3282
3283 =head2 current_source_alias
3284
3285 =over 4
3286
3287 =item Arguments: none
3288
3289 =item Return Value: $source_alias
3290
3291 =back
3292
3293 Returns the current table alias for the result source this resultset is built
3294 on, that will be used in the SQL query. Usually it is C<me>.
3295
3296 Currently the source alias that refers to the result set returned by a
3297 L</search>/L</find> family method depends on how you got to the resultset: it's
3298 C<me> by default, but eg. L</search_related> aliases it to the related result
3299 source name (and keeps C<me> referring to the original result set). The long
3300 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3301 (and make this method unnecessary).
3302
3303 Thus it's currently necessary to use this method in predefined queries (see
3304 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3305 source alias of the current result set:
3306
3307   # in a result set class
3308   sub modified_by {
3309     my ($self, $user) = @_;
3310
3311     my $me = $self->current_source_alias;
3312
3313     return $self->search({
3314       "$me.modified" => $user->id,
3315     });
3316   }
3317
3318 The alias of L<newly created resultsets|/search> can be altered by the
3319 L<alias attribute|/alias>.
3320
3321 =cut
3322
3323 sub current_source_alias {
3324   return (shift->{attrs} || {})->{alias} || 'me';
3325 }
3326
3327 =head2 as_subselect_rs
3328
3329 =over 4
3330
3331 =item Arguments: none
3332
3333 =item Return Value: L<$resultset|/search>
3334
3335 =back
3336
3337 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3338 "virtual view" by including it as a subquery within the from clause.  From this
3339 point on, any joined tables are inaccessible to ->search on the resultset (as if
3340 it were simply where-filtered without joins).  For example:
3341
3342  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3343
3344  # 'x' now pollutes the query namespace
3345
3346  # So the following works as expected
3347  my $ok_rs = $rs->search({'x.other' => 1});
3348
3349  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3350  # def) we look for one row with contradictory terms and join in another table
3351  # (aliased 'x_2') which we never use
3352  my $broken_rs = $rs->search({'x.name' => 'def'});
3353
3354  my $rs2 = $rs->as_subselect_rs;
3355
3356  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3357  my $not_joined_rs = $rs2->search({'x.other' => 1});
3358
3359  # works as expected: finds a 'table' row related to two x rows (abc and def)
3360  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3361
3362 Another example of when one might use this would be to select a subset of
3363 columns in a group by clause:
3364
3365  my $rs = $schema->resultset('Bar')->search(undef, {
3366    group_by => [qw{ id foo_id baz_id }],
3367  })->as_subselect_rs->search(undef, {
3368    columns => [qw{ id foo_id }]
3369  });
3370
3371 In the above example normally columns would have to be equal to the group by,
3372 but because we isolated the group by into a subselect the above works.
3373
3374 =cut
3375
3376 sub as_subselect_rs {
3377   my $self = shift;
3378
3379   my $attrs = $self->_resolved_attrs;
3380
3381   my $fresh_rs = (ref $self)->new (
3382     $self->result_source
3383   );
3384
3385   # these pieces will be locked in the subquery
3386   delete $fresh_rs->{cond};
3387   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3388
3389   return $fresh_rs->search( {}, {
3390     from => [{
3391       $attrs->{alias} => $self->as_query,
3392       -alias  => $attrs->{alias},
3393       -rsrc   => $self->result_source,
3394     }],
3395     alias => $attrs->{alias},
3396   });
3397 }
3398
3399 # This code is called by search_related, and makes sure there
3400 # is clear separation between the joins before, during, and
3401 # after the relationship. This information is needed later
3402 # in order to properly resolve prefetch aliases (any alias
3403 # with a relation_chain_depth less than the depth of the
3404 # current prefetch is not considered)
3405 #
3406 # The increments happen twice per join. An even number means a
3407 # relationship specified via a search_related, whereas an odd
3408 # number indicates a join/prefetch added via attributes
3409 #
3410 # Also this code will wrap the current resultset (the one we
3411 # chain to) in a subselect IFF it contains limiting attributes
3412 sub _chain_relationship {
3413   my ($self, $rel) = @_;
3414   my $source = $self->result_source;
3415   my $attrs = { %{$self->{attrs}||{}} };
3416
3417   # we need to take the prefetch the attrs into account before we
3418   # ->_resolve_join as otherwise they get lost - captainL
3419   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3420
3421   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3422
3423   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3424
3425   my $from;
3426   my @force_subq_attrs = qw/offset rows group_by having/;
3427
3428   if (
3429     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3430       ||
3431     $self->_has_resolved_attr (@force_subq_attrs)
3432   ) {
3433     # Nuke the prefetch (if any) before the new $rs attrs
3434     # are resolved (prefetch is useless - we are wrapping
3435     # a subquery anyway).
3436     my $rs_copy = $self->search;
3437     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3438       $rs_copy->{attrs}{join},
3439       delete $rs_copy->{attrs}{prefetch},
3440     );
3441
3442     $from = [{
3443       -rsrc   => $source,
3444       -alias  => $attrs->{alias},
3445       $attrs->{alias} => $rs_copy->as_query,
3446     }];
3447     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3448     $seen->{-relation_chain_depth} = 0;
3449   }
3450   elsif ($attrs->{from}) {  #shallow copy suffices
3451     $from = [ @{$attrs->{from}} ];
3452   }
3453   else {
3454     $from = [{
3455       -rsrc  => $source,
3456       -alias => $attrs->{alias},
3457       $attrs->{alias} => $source->from,
3458     }];
3459   }
3460
3461   my $jpath = ($seen->{-relation_chain_depth})
3462     ? $from->[-1][0]{-join_path}
3463     : [];
3464
3465   my @requested_joins = $source->_resolve_join(
3466     $join,
3467     $attrs->{alias},
3468     $seen,
3469     $jpath,
3470   );
3471
3472   push @$from, @requested_joins;
3473
3474   $seen->{-relation_chain_depth}++;
3475
3476   # if $self already had a join/prefetch specified on it, the requested
3477   # $rel might very well be already included. What we do in this case
3478   # is effectively a no-op (except that we bump up the chain_depth on
3479   # the join in question so we could tell it *is* the search_related)
3480   my $already_joined;
3481
3482   # we consider the last one thus reverse
3483   for my $j (reverse @requested_joins) {
3484     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3485     if ($rel eq $last_j) {
3486       $j->[0]{-relation_chain_depth}++;
3487       $already_joined++;
3488       last;
3489     }
3490   }
3491
3492   unless ($already_joined) {
3493     push @$from, $source->_resolve_join(
3494       $rel,
3495       $attrs->{alias},
3496       $seen,
3497       $jpath,
3498     );
3499   }
3500
3501   $seen->{-relation_chain_depth}++;
3502
3503   return {%$attrs, from => $from, seen_join => $seen};
3504 }
3505
3506 sub _resolved_attrs {
3507   my $self = shift;
3508   return $self->{_attrs} if $self->{_attrs};
3509
3510   my $attrs  = { %{ $self->{attrs} || {} } };
3511   my $source = $attrs->{result_source} = $self->result_source;
3512   my $alias  = $attrs->{alias};
3513
3514   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3515     if $attrs->{collapse} and $attrs->{distinct};
3516
3517
3518   # Sanity check the paging attributes
3519   # SQLMaker does it too, but in case of a software_limit we'll never get there
3520   if (defined $attrs->{offset}) {
3521     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3522       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3523   }
3524   if (defined $attrs->{rows}) {
3525     $self->throw_exception("The rows attribute must be a positive integer if present")
3526       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3527   }
3528
3529   # normalize where condition
3530   $attrs->{where} = normalize_sqla_condition( $attrs->{where} )
3531     if $attrs->{where};
3532
3533   # default selection list
3534   $attrs->{columns} = [ $source->columns ]
3535     unless grep { exists $attrs->{$_} } qw/columns cols select as/;
3536
3537   # merge selectors together
3538   for (qw/columns select as/) {
3539     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3540       if $attrs->{$_} or $attrs->{"+$_"};
3541   }
3542
3543   # disassemble columns
3544   my (@sel, @as);
3545   if (my $cols = delete $attrs->{columns}) {
3546     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3547       if (ref $c eq 'HASH') {
3548         for my $as (sort keys %$c) {
3549           push @sel, $c->{$as};
3550           push @as, $as;
3551         }
3552       }
3553       else {
3554         push @sel, $c;
3555         push @as, $c;
3556       }
3557     }
3558   }
3559
3560   # when trying to weed off duplicates later do not go past this point -
3561   # everything added from here on is unbalanced "anyone's guess" stuff
3562   my $dedup_stop_idx = $#as;
3563
3564   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3565     if $attrs->{as};
3566   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3567     if $attrs->{select};
3568
3569   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3570   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3571
3572   # disqualify all $alias.col as-bits (inflate-map mandated)
3573   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3574
3575   # de-duplicate the result (remove *identical* select/as pairs)
3576   # and also die on duplicate {as} pointing to different {select}s
3577   # not using a c-style for as the condition is prone to shrinkage
3578   my $seen;
3579   my $i = 0;
3580   while ($i <= $dedup_stop_idx) {
3581     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3582       splice @sel, $i, 1;
3583       splice @as, $i, 1;
3584       $dedup_stop_idx--;
3585     }
3586     elsif ($seen->{$as[$i]}++) {
3587       $self->throw_exception(
3588         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3589       );
3590     }
3591     else {
3592       $i++;
3593     }
3594   }
3595
3596   $attrs->{select} = \@sel;
3597   $attrs->{as} = \@as;
3598
3599   $attrs->{from} ||= [{
3600     -rsrc   => $source,
3601     -alias  => $self->{attrs}{alias},
3602     $self->{attrs}{alias} => $source->from,
3603   }];
3604
3605   if ( $attrs->{join} || $attrs->{prefetch} ) {
3606
3607     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3608       if ref $attrs->{from} ne 'ARRAY';
3609
3610     my $join = (delete $attrs->{join}) || {};
3611
3612     if ( defined $attrs->{prefetch} ) {
3613       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3614     }
3615
3616     $attrs->{from} =    # have to copy here to avoid corrupting the original
3617       [
3618         @{ $attrs->{from} },
3619         $source->_resolve_join(
3620           $join,
3621           $alias,
3622           { %{ $attrs->{seen_join} || {} } },
3623           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3624             ? $attrs->{from}[-1][0]{-join_path}
3625             : []
3626           ,
3627         )
3628       ];
3629   }
3630
3631
3632   for my $attr (qw(order_by group_by)) {
3633
3634     if ( defined $attrs->{$attr} ) {
3635       $attrs->{$attr} = (
3636         ref( $attrs->{$attr} ) eq 'ARRAY'
3637         ? [ @{ $attrs->{$attr} } ]
3638         : [ $attrs->{$attr} || () ]
3639       );
3640
3641       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3642     }
3643   }
3644
3645
3646   # set collapse default based on presence of prefetch
3647   my $prefetch;
3648   if (
3649     defined $attrs->{prefetch}
3650       and
3651     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3652   ) {
3653     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3654       if defined $attrs->{collapse} and ! $attrs->{collapse};
3655
3656     $attrs->{collapse} = 1;
3657   }
3658
3659
3660   # run through the resulting joinstructure (starting from our current slot)
3661   # and unset collapse if proven unnecessary
3662   #
3663   # also while we are at it find out if the current root source has
3664   # been premultiplied by previous related_source chaining
3665   #
3666   # this allows to predict whether a root object with all other relation
3667   # data set to NULL is in fact unique
3668   if ($attrs->{collapse}) {
3669
3670     if (ref $attrs->{from} eq 'ARRAY') {
3671
3672       if (@{$attrs->{from}} == 1) {
3673         # no joins - no collapse
3674         $attrs->{collapse} = 0;
3675       }
3676       else {
3677         # find where our table-spec starts
3678         my @fromlist = @{$attrs->{from}};
3679         while (@fromlist) {
3680           my $t = shift @fromlist;
3681
3682           my $is_multi;
3683           # me vs join from-spec distinction - a ref means non-root
3684           if (ref $t eq 'ARRAY') {
3685             $t = $t->[0];
3686             $is_multi ||= ! $t->{-is_single};
3687           }
3688           last if ($t->{-alias} && $t->{-alias} eq $alias);
3689           $attrs->{_main_source_premultiplied} ||= $is_multi;
3690         }
3691
3692         # no non-singles remaining, nor any premultiplication - nothing to collapse
3693         if (
3694           ! $attrs->{_main_source_premultiplied}
3695             and
3696           ! grep { ! $_->[0]{-is_single} } @fromlist
3697         ) {
3698           $attrs->{collapse} = 0;
3699         }
3700       }
3701     }
3702
3703     else {
3704       # if we can not analyze the from - err on the side of safety
3705       $attrs->{_main_source_premultiplied} = 1;
3706     }
3707   }
3708
3709
3710   # generate the distinct induced group_by before injecting the prefetched select/as parts
3711   if (delete $attrs->{distinct}) {
3712     if ($attrs->{group_by}) {
3713       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3714     }
3715     else {
3716       $attrs->{_grouped_by_distinct} = 1;
3717       # distinct affects only the main selection part, not what prefetch may add below
3718       ($attrs->{group_by}, my $new_order) = $source->schema->storage->_group_over_selection($attrs);
3719
3720       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3721       # The thinking is: if we are collapsing the subquerying prefetch engine will
3722       # rip stuff apart for us anyway, and we do not want to have a potentially
3723       # function-converted external order_by
3724       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3725       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3726     }
3727   }
3728
3729
3730   # generate selections based on the prefetch helper
3731   if ($prefetch) {
3732
3733     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3734       if $attrs->{_dark_selector};
3735
3736     # this is a separate structure (we don't look in {from} directly)
3737     # as the resolver needs to shift things off the lists to work
3738     # properly (identical-prefetches on different branches)
3739     my $joined_node_aliases_map = {};
3740     if (ref $attrs->{from} eq 'ARRAY') {
3741
3742       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3743
3744       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3745         next unless $j->[0]{-alias};
3746         next unless $j->[0]{-join_path};
3747         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3748
3749         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3750
3751         my $p = $joined_node_aliases_map;
3752         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3753         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3754       }
3755     }
3756
3757     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3758       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3759   }
3760
3761
3762   $attrs->{_simple_passthrough_construction} = !(
3763     $attrs->{collapse}
3764       or
3765     grep { $_ =~ /\./ } @{$attrs->{as}}
3766   );
3767
3768
3769   # if both page and offset are specified, produce a combined offset
3770   # even though it doesn't make much sense, this is what pre 081xx has
3771   # been doing
3772   if (my $page = delete $attrs->{page}) {
3773     $attrs->{offset} =
3774       ($attrs->{rows} * ($page - 1))
3775             +
3776       ($attrs->{offset} || 0)
3777     ;
3778   }
3779
3780   return $self->{_attrs} = $attrs;
3781 }
3782
3783 sub _rollout_attr {
3784   my ($self, $attr) = @_;
3785
3786   if (ref $attr eq 'HASH') {
3787     return $self->_rollout_hash($attr);
3788   } elsif (ref $attr eq 'ARRAY') {
3789     return $self->_rollout_array($attr);
3790   } else {
3791     return [$attr];
3792   }
3793 }
3794
3795 sub _rollout_array {
3796   my ($self, $attr) = @_;
3797
3798   my @rolled_array;
3799   foreach my $element (@{$attr}) {
3800     if (ref $element eq 'HASH') {
3801       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3802     } elsif (ref $element eq 'ARRAY') {
3803       #  XXX - should probably recurse here
3804       push( @rolled_array, @{$self->_rollout_array($element)} );
3805     } else {
3806       push( @rolled_array, $element );
3807     }
3808   }
3809   return \@rolled_array;
3810 }
3811
3812 sub _rollout_hash {
3813   my ($self, $attr) = @_;
3814
3815   my @rolled_array;
3816   foreach my $key (keys %{$attr}) {
3817     push( @rolled_array, { $key => $attr->{$key} } );
3818   }
3819   return \@rolled_array;
3820 }
3821
3822 sub _calculate_score {
3823   my ($self, $a, $b) = @_;
3824
3825   if (defined $a xor defined $b) {
3826     return 0;
3827   }
3828   elsif (not defined $a) {
3829     return 1;
3830   }
3831
3832   if (ref $b eq 'HASH') {
3833     my ($b_key) = keys %{$b};
3834     $b_key = '' if ! defined $b_key;
3835     if (ref $a eq 'HASH') {
3836       my ($a_key) = keys %{$a};
3837       $a_key = '' if ! defined $a_key;
3838       if ($a_key eq $b_key) {
3839         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3840       } else {
3841         return 0;
3842       }
3843     } else {
3844       return ($a eq $b_key) ? 1 : 0;
3845     }
3846   } else {
3847     if (ref $a eq 'HASH') {
3848       my ($a_key) = keys %{$a};
3849       return ($b eq $a_key) ? 1 : 0;
3850     } else {
3851       return ($b eq $a) ? 1 : 0;
3852     }
3853   }
3854 }
3855
3856 sub _merge_joinpref_attr {
3857   my ($self, $orig, $import) = @_;
3858
3859   return $import unless defined($orig);
3860   return $orig unless defined($import);
3861
3862   $orig = $self->_rollout_attr($orig);
3863   $import = $self->_rollout_attr($import);
3864
3865   my $seen_keys;
3866   foreach my $import_element ( @{$import} ) {
3867     # find best candidate from $orig to merge $b_element into
3868     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3869     foreach my $orig_element ( @{$orig} ) {
3870       my $score = $self->_calculate_score( $orig_element, $import_element );
3871       if ($score > $best_candidate->{score}) {
3872         $best_candidate->{position} = $position;
3873         $best_candidate->{score} = $score;
3874       }
3875       $position++;
3876     }
3877     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3878     $import_key = '' if not defined $import_key;
3879
3880     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3881       push( @{$orig}, $import_element );
3882     } else {
3883       my $orig_best = $orig->[$best_candidate->{position}];
3884       # merge orig_best and b_element together and replace original with merged
3885       if (ref $orig_best ne 'HASH') {
3886         $orig->[$best_candidate->{position}] = $import_element;
3887       } elsif (ref $import_element eq 'HASH') {
3888         my ($key) = keys %{$orig_best};
3889         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3890       }
3891     }
3892     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3893   }
3894
3895   return @$orig ? $orig : ();
3896 }
3897
3898 {
3899   my $hm;
3900
3901   sub _merge_attr {
3902     $hm ||= do {
3903       require Hash::Merge;
3904       my $hm = Hash::Merge->new;
3905
3906       $hm->specify_behavior({
3907         SCALAR => {
3908           SCALAR => sub {
3909             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3910
3911             if ($defl xor $defr) {
3912               return [ $defl ? $_[0] : $_[1] ];
3913             }
3914             elsif (! $defl) {
3915               return [];
3916             }
3917             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3918               return [ $_[0] ];
3919             }
3920             else {
3921               return [$_[0], $_[1]];
3922             }
3923           },
3924           ARRAY => sub {
3925             return $_[1] if !defined $_[0];
3926             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
3927             return [$_[0], @{$_[1]}]
3928           },
3929           HASH  => sub {
3930             return [] if !defined $_[0] and !keys %{$_[1]};
3931             return [ $_[1] ] if !defined $_[0];
3932             return [ $_[0] ] if !keys %{$_[1]};
3933             return [$_[0], $_[1]]
3934           },
3935         },
3936         ARRAY => {
3937           SCALAR => sub {
3938             return $_[0] if !defined $_[1];
3939             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
3940             return [@{$_[0]}, $_[1]]
3941           },
3942           ARRAY => sub {
3943             my @ret = @{$_[0]} or return $_[1];
3944             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3945             my %idx = map { $_ => 1 } @ret;
3946             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3947             \@ret;
3948           },
3949           HASH => sub {
3950             return [ $_[1] ] if ! @{$_[0]};
3951             return $_[0] if !keys %{$_[1]};
3952             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
3953             return [ @{$_[0]}, $_[1] ];
3954           },
3955         },
3956         HASH => {
3957           SCALAR => sub {
3958             return [] if !keys %{$_[0]} and !defined $_[1];
3959             return [ $_[0] ] if !defined $_[1];
3960             return [ $_[1] ] if !keys %{$_[0]};
3961             return [$_[0], $_[1]]
3962           },
3963           ARRAY => sub {
3964             return [] if !keys %{$_[0]} and !@{$_[1]};
3965             return [ $_[0] ] if !@{$_[1]};
3966             return $_[1] if !keys %{$_[0]};
3967             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
3968             return [ $_[0], @{$_[1]} ];
3969           },
3970           HASH => sub {
3971             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3972             return [ $_[0] ] if !keys %{$_[1]};
3973             return [ $_[1] ] if !keys %{$_[0]};
3974             return [ $_[0] ] if $_[0] eq $_[1];
3975             return [ $_[0], $_[1] ];
3976           },
3977         }
3978       } => 'DBIC_RS_ATTR_MERGER');
3979       $hm;
3980     };
3981
3982     return $hm->merge ($_[1], $_[2]);
3983   }
3984 }
3985
3986 sub STORABLE_freeze {
3987   my ($self, $cloning) = @_;
3988   my $to_serialize = { %$self };
3989
3990   # A cursor in progress can't be serialized (and would make little sense anyway)
3991   # the parser can be regenerated (and can't be serialized)
3992   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3993
3994   # nor is it sensical to store a not-yet-fired-count pager
3995   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3996     delete $to_serialize->{pager};
3997   }
3998
3999   Storable::nfreeze($to_serialize);
4000 }
4001
4002 # need this hook for symmetry
4003 sub STORABLE_thaw {
4004   my ($self, $cloning, $serialized) = @_;
4005
4006   %$self = %{ Storable::thaw($serialized) };
4007
4008   $self;
4009 }
4010
4011
4012 =head2 throw_exception
4013
4014 See L<DBIx::Class::Schema/throw_exception> for details.
4015
4016 =cut
4017
4018 sub throw_exception {
4019   my $self=shift;
4020
4021   if (ref $self and my $rsrc = $self->result_source) {
4022     $rsrc->throw_exception(@_)
4023   }
4024   else {
4025     DBIx::Class::Exception->throw(@_);
4026   }
4027 }
4028
4029 1;
4030
4031 __END__
4032
4033 # XXX: FIXME: Attributes docs need clearing up
4034
4035 =head1 ATTRIBUTES
4036
4037 Attributes are used to refine a ResultSet in various ways when
4038 searching for data. They can be passed to any method which takes an
4039 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4040 L</count>.
4041
4042 Default attributes can be set on the result class using
4043 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4044 the CAVEATS on that feature before using it!)
4045
4046 These are in no particular order:
4047
4048 =head2 order_by
4049
4050 =over 4
4051
4052 =item Value: ( $order_by | \@order_by | \%order_by )
4053
4054 =back
4055
4056 Which column(s) to order the results by.
4057
4058 [The full list of suitable values is documented in
4059 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4060 common options.]
4061
4062 If a single column name, or an arrayref of names is supplied, the
4063 argument is passed through directly to SQL. The hashref syntax allows
4064 for connection-agnostic specification of ordering direction:
4065
4066  For descending order:
4067
4068   order_by => { -desc => [qw/col1 col2 col3/] }
4069
4070  For explicit ascending order:
4071
4072   order_by => { -asc => 'col' }
4073
4074 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4075 supported, although you are strongly encouraged to use the hashref
4076 syntax as outlined above.
4077
4078 =head2 columns
4079
4080 =over 4
4081
4082 =item Value: \@columns | \%columns | $column
4083
4084 =back
4085
4086 Shortcut to request a particular set of columns to be retrieved. Each
4087 column spec may be a string (a table column name), or a hash (in which
4088 case the key is the C<as> value, and the value is used as the C<select>
4089 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4090 it and sets C<select> from that, then auto-populates C<as> from
4091 C<select> as normal. (You may also use the C<cols> attribute, as in
4092 earlier versions of DBIC, but this is deprecated)
4093
4094 Essentially C<columns> does the same as L</select> and L</as>.
4095
4096     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4097
4098 is the same as
4099
4100     select => [qw(some_column another_column)],
4101     as     => [qw(some_column dbic_slot)]
4102
4103 If you want to individually retrieve related columns (in essence perform
4104 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4105 chain such that it matches existing relationships:
4106
4107     my $rs = $schema->resultset('Artist')->search({}, {
4108         # required to tell DBIC to collapse has_many relationships
4109         collapse => 1,
4110         join     => { cds => 'tracks' },
4111         '+columns'  => {
4112           'cds.cdid'         => 'cds.cdid',
4113           'cds.tracks.title' => 'tracks.title',
4114         },
4115     });
4116
4117 Like elsewhere, literal SQL or literal values can be included by using a
4118 scalar reference or a literal bind value, and these values will be available
4119 in the result with C<get_column> (see also
4120 L<SQL::Abstract/Literal SQL and value type operators>):
4121
4122     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4123     # bind values: $true_value, $false_value
4124     columns => [
4125         {
4126             foo => \1,
4127             bar => \q{'a string'},
4128             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4129         }
4130     ]
4131
4132 =head2 +columns
4133
4134 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4135 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4136 with a unary plus operator before it, which is the same as simply C<columns>.
4137
4138 =over 4
4139
4140 =item Value: \@extra_columns
4141
4142 =back
4143
4144 Indicates additional columns to be selected from storage. Works the same as
4145 L</columns> but adds columns to the current selection. (You may also use the
4146 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4147 deprecated)
4148
4149   $schema->resultset('CD')->search(undef, {
4150     '+columns' => ['artist.name'],
4151     join => ['artist']
4152   });
4153
4154 would return all CDs and include a 'name' column to the information
4155 passed to object inflation. Note that the 'artist' is the name of the
4156 column (or relationship) accessor, and 'name' is the name of the column
4157 accessor in the related table.
4158
4159 =head2 select
4160
4161 =over 4
4162
4163 =item Value: \@select_columns
4164
4165 =back
4166
4167 Indicates which columns should be selected from the storage. You can use
4168 column names, or in the case of RDBMS back ends, function or stored procedure
4169 names:
4170
4171   $rs = $schema->resultset('Employee')->search(undef, {
4172     select => [
4173       'name',
4174       { count => 'employeeid' },
4175       { max => { length => 'name' }, -as => 'longest_name' }
4176     ]
4177   });
4178
4179   # Equivalent SQL
4180   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4181
4182 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4183 use L</select>, to instruct DBIx::Class how to store the result of the column.
4184
4185 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4186 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4187 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4188 function attribute> supplied as shown in the example above.
4189
4190 =head2 +select
4191
4192 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4193 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4194 with a unary plus operator before it, which is the same as simply C<select>.
4195
4196 =over 4
4197
4198 =item Value: \@extra_select_columns
4199
4200 =back
4201
4202 Indicates additional columns to be selected from storage.  Works the same as
4203 L</select> but adds columns to the current selection, instead of specifying
4204 a new explicit list.
4205
4206 =head2 as
4207
4208 =over 4
4209
4210 =item Value: \@inflation_names
4211
4212 =back
4213
4214 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4215 slot name in which the column value will be stored within the
4216 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4217 identifier by the C<get_column> method (or via the object accessor B<if one
4218 with the same name already exists>) as shown below.
4219
4220 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4221 aliasing C<AS>. See L</select> for details.
4222
4223   $rs = $schema->resultset('Employee')->search(undef, {
4224     select => [
4225       'name',
4226       { count => 'employeeid' },
4227       { max => { length => 'name' }, -as => 'longest_name' }
4228     ],
4229     as => [qw/
4230       name
4231       employee_count
4232       max_name_length
4233     /],
4234   });
4235
4236 If the object against which the search is performed already has an accessor
4237 matching a column name specified in C<as>, the value can be retrieved using
4238 the accessor as normal:
4239
4240   my $name = $employee->name();
4241
4242 If on the other hand an accessor does not exist in the object, you need to
4243 use C<get_column> instead:
4244
4245   my $employee_count = $employee->get_column('employee_count');
4246
4247 You can create your own accessors if required - see
4248 L<DBIx::Class::Manual::Cookbook> for details.
4249
4250 =head2 +as
4251
4252 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4253 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4254 with a unary plus operator before it, which is the same as simply C<as>.
4255
4256 =over 4
4257
4258 =item Value: \@extra_inflation_names
4259
4260 =back
4261
4262 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4263
4264 =head2 join
4265
4266 =over 4
4267
4268 =item Value: ($rel_name | \@rel_names | \%rel_names)
4269
4270 =back
4271
4272 Contains a list of relationships that should be joined for this query.  For
4273 example:
4274
4275   # Get CDs by Nine Inch Nails
4276   my $rs = $schema->resultset('CD')->search(
4277     { 'artist.name' => 'Nine Inch Nails' },
4278     { join => 'artist' }
4279   );
4280
4281 Can also contain a hash reference to refer to the other relation's relations.
4282 For example:
4283
4284   package MyApp::Schema::Track;
4285   use base qw/DBIx::Class/;
4286   __PACKAGE__->table('track');
4287   __PACKAGE__->add_columns(qw/trackid cd position title/);
4288   __PACKAGE__->set_primary_key('trackid');
4289   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4290   1;
4291
4292   # In your application
4293   my $rs = $schema->resultset('Artist')->search(
4294     { 'track.title' => 'Teardrop' },
4295     {
4296       join     => { cd => 'track' },
4297       order_by => 'artist.name',
4298     }
4299   );
4300
4301 You need to use the relationship (not the table) name in  conditions,
4302 because they are aliased as such. The current table is aliased as "me", so
4303 you need to use me.column_name in order to avoid ambiguity. For example:
4304
4305   # Get CDs from 1984 with a 'Foo' track
4306   my $rs = $schema->resultset('CD')->search(
4307     {
4308       'me.year' => 1984,
4309       'tracks.name' => 'Foo'
4310     },
4311     { join => 'tracks' }
4312   );
4313
4314 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4315 similarly for a third time). For e.g.
4316
4317   my $rs = $schema->resultset('Artist')->search({
4318     'cds.title'   => 'Down to Earth',
4319     'cds_2.title' => 'Popular',
4320   }, {
4321     join => [ qw/cds cds/ ],
4322   });
4323
4324 will return a set of all artists that have both a cd with title 'Down
4325 to Earth' and a cd with title 'Popular'.
4326
4327 If you want to fetch related objects from other tables as well, see L</prefetch>
4328 below.
4329
4330  NOTE: An internal join-chain pruner will discard certain joins while
4331  constructing the actual SQL query, as long as the joins in question do not
4332  affect the retrieved result. This for example includes 1:1 left joins
4333  that are not part of the restriction specification (WHERE/HAVING) nor are
4334  a part of the query selection.
4335
4336 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4337
4338 =head2 collapse
4339
4340 =over 4
4341
4342 =item Value: (0 | 1)
4343
4344 =back
4345
4346 When set to a true value, indicates that any rows fetched from joined has_many
4347 relationships are to be aggregated into the corresponding "parent" object. For
4348 example, the resultset:
4349
4350   my $rs = $schema->resultset('CD')->search({}, {
4351     '+columns' => [ qw/ tracks.title tracks.position / ],
4352     join => 'tracks',
4353     collapse => 1,
4354   });
4355
4356 While executing the following query:
4357
4358   SELECT me.*, tracks.title, tracks.position
4359     FROM cd me
4360     LEFT JOIN track tracks
4361       ON tracks.cdid = me.cdid
4362
4363 Will return only as many objects as there are rows in the CD source, even
4364 though the result of the query may span many rows. Each of these CD objects
4365 will in turn have multiple "Track" objects hidden behind the has_many
4366 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4367 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4368 product"), with each CD object containing exactly one of all fetched Track data.
4369
4370 When a collapse is requested on a non-ordered resultset, an order by some
4371 unique part of the main source (the left-most table) is inserted automatically.
4372 This is done so that the resultset is allowed to be "lazy" - calling
4373 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4374 object with all of its related data.
4375
4376 If an L</order_by> is already declared, and orders the resultset in a way that
4377 makes collapsing as described above impossible (e.g. C<< ORDER BY
4378 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4379 switch to "eager" mode and slurp the entire resultset before constructing the
4380 first object returned by L</next>.
4381
4382 Setting this attribute on a resultset that does not join any has_many
4383 relations is a no-op.
4384
4385 For a more in-depth discussion, see L</PREFETCHING>.
4386
4387 =head2 prefetch
4388
4389 =over 4
4390
4391 =item Value: ($rel_name | \@rel_names | \%rel_names)
4392
4393 =back
4394
4395 This attribute is a shorthand for specifying a L</join> spec, adding all
4396 columns from the joined related sources as L</+columns> and setting
4397 L</collapse> to a true value. It can be thought of as a rough B<superset>
4398 of the L</join> attribute.
4399
4400 For example, the following two queries are equivalent:
4401
4402   my $rs = $schema->resultset('Artist')->search({}, {
4403     prefetch => { cds => ['genre', 'tracks' ] },
4404   });
4405
4406 and
4407
4408   my $rs = $schema->resultset('Artist')->search({}, {
4409     join => { cds => ['genre', 'tracks' ] },
4410     collapse => 1,
4411     '+columns' => [
4412       (map
4413         { +{ "cds.$_" => "cds.$_" } }
4414         $schema->source('Artist')->related_source('cds')->columns
4415       ),
4416       (map
4417         { +{ "cds.genre.$_" => "genre.$_" } }
4418         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4419       ),
4420       (map
4421         { +{ "cds.tracks.$_" => "tracks.$_" } }
4422         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4423       ),
4424     ],
4425   });
4426
4427 Both producing the following SQL:
4428
4429   SELECT  me.artistid, me.name, me.rank, me.charfield,
4430           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4431           genre.genreid, genre.name,
4432           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4433     FROM artist me
4434     LEFT JOIN cd cds
4435       ON cds.artist = me.artistid
4436     LEFT JOIN genre genre
4437       ON genre.genreid = cds.genreid
4438     LEFT JOIN track tracks
4439       ON tracks.cd = cds.cdid
4440   ORDER BY me.artistid
4441
4442 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4443 the arguments are properly merged and generally do the right thing. For
4444 example, you may want to do the following:
4445
4446   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4447     { 'genre.genreid' => undef },
4448     {
4449       join => { cds => 'genre' },
4450       prefetch => 'cds',
4451     }
4452   );
4453
4454 Which generates the following SQL:
4455
4456   SELECT  me.artistid, me.name, me.rank, me.charfield,
4457           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4458     FROM artist me
4459     LEFT JOIN cd cds
4460       ON cds.artist = me.artistid
4461     LEFT JOIN genre genre
4462       ON genre.genreid = cds.genreid
4463   WHERE genre.genreid IS NULL
4464   ORDER BY me.artistid
4465
4466 For a more in-depth discussion, see L</PREFETCHING>.
4467
4468 =head2 alias
4469
4470 =over 4
4471
4472 =item Value: $source_alias
4473
4474 =back
4475
4476 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4477 nested search queries (sub-SELECTs) might need specific aliases set to
4478 reference inner queries.  For example:
4479
4480    my $q = $rs
4481       ->related_resultset('CDs')
4482       ->related_resultset('Tracks')
4483       ->search({
4484          'track.id' => { -ident => 'none_search.id' },
4485       })
4486       ->as_query;
4487
4488    my $ids = $self->search({
4489       -not_exists => $q,
4490    }, {
4491       alias    => 'none_search',
4492       group_by => 'none_search.id',
4493    })->get_column('id')->as_query;
4494
4495    $self->search({ id => { -in => $ids } })
4496
4497 This attribute is directly tied to L</current_source_alias>.
4498
4499 =head2 page
4500
4501 =over 4
4502
4503 =item Value: $page
4504
4505 =back
4506
4507 Makes the resultset paged and specifies the page to retrieve. Effectively
4508 identical to creating a non-pages resultset and then calling ->page($page)
4509 on it.
4510
4511 If L</rows> attribute is not specified it defaults to 10 rows per page.
4512
4513 When you have a paged resultset, L</count> will only return the number
4514 of rows in the page. To get the total, use the L</pager> and call
4515 C<total_entries> on it.
4516
4517 =head2 rows
4518
4519 =over 4
4520
4521 =item Value: $rows
4522
4523 =back
4524
4525 Specifies the maximum number of rows for direct retrieval or the number of
4526 rows per page if the page attribute or method is used.
4527
4528 =head2 offset
4529
4530 =over 4
4531
4532 =item Value: $offset
4533
4534 =back
4535
4536 Specifies the (zero-based) row number for the  first row to be returned, or the
4537 of the first row of the first page if paging is used.
4538
4539 =head2 software_limit
4540
4541 =over 4
4542
4543 =item Value: (0 | 1)
4544
4545 =back
4546
4547 When combined with L</rows> and/or L</offset> the generated SQL will not
4548 include any limit dialect stanzas. Instead the entire result will be selected
4549 as if no limits were specified, and DBIC will perform the limit locally, by
4550 artificially advancing and finishing the resulting L</cursor>.
4551
4552 This is the recommended way of performing resultset limiting when no sane RDBMS
4553 implementation is available (e.g.
4554 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4555 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4556
4557 =head2 group_by
4558
4559 =over 4
4560
4561 =item Value: \@columns
4562
4563 =back
4564
4565 A arrayref of columns to group by. Can include columns of joined tables.
4566
4567   group_by => [qw/ column1 column2 ... /]
4568
4569 =head2 having
4570
4571 =over 4
4572
4573 =item Value: $condition
4574
4575 =back
4576
4577 The HAVING operator specifies a B<secondary> condition applied to the set
4578 after the grouping calculations have been done. In other words it is a
4579 constraint just like L</where> (and accepting the same
4580 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4581 as it exists after GROUP BY has taken place. Specifying L</having> without
4582 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4583
4584 E.g.
4585
4586   having => { 'count_employee' => { '>=', 100 } }
4587
4588 or with an in-place function in which case literal SQL is required:
4589
4590   having => \[ 'count(employee) >= ?', 100 ]
4591
4592 =head2 distinct
4593
4594 =over 4
4595
4596 =item Value: (0 | 1)
4597
4598 =back
4599
4600 Set to 1 to automatically generate a L</group_by> clause based on the selection
4601 (including intelligent handling of L</order_by> contents). Note that the group
4602 criteria calculation takes place over the B<final> selection. This includes
4603 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4604 L</search> calls, and standalone columns selected via
4605 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4606 extra selections specified via L</prefetch> - such selections are explicitly
4607 excluded from group criteria calculations.
4608
4609 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4610 setting is ignored and an appropriate warning is issued.
4611
4612 =head2 where
4613
4614 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4615 conditions, same as the B<first> argument to the L<search operator|/search>
4616
4617   # only return rows WHERE deleted IS NULL for all searches
4618   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4619
4620 Note that the above example is
4621 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4622
4623 =head2 cache
4624
4625 Set to 1 to cache search results. This prevents extra SQL queries if you
4626 revisit rows in your ResultSet:
4627
4628   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4629
4630   while( my $artist = $resultset->next ) {
4631     ... do stuff ...
4632   }
4633
4634   $resultset->first; # without cache, this would issue a query
4635
4636 By default, searches are not cached.
4637
4638 For more examples of using these attributes, see
4639 L<DBIx::Class::Manual::Cookbook>.
4640
4641 =head2 for
4642
4643 =over 4
4644
4645 =item Value: ( 'update' | 'shared' | \$scalar )
4646
4647 =back
4648
4649 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4650 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4651 query.
4652
4653 =head1 PREFETCHING
4654
4655 DBIx::Class supports arbitrary related data prefetching from multiple related
4656 sources. Any combination of relationship types and column sets are supported.
4657 If L<collapsing|/collapse> is requested, there is an additional requirement of
4658 selecting enough data to make every individual object uniquely identifiable.
4659
4660 Here are some more involved examples, based on the following relationship map:
4661
4662   # Assuming:
4663   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4664   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4665   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4666
4667   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4668
4669   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4670
4671
4672
4673   my $rs = $schema->resultset('Tag')->search(
4674     undef,
4675     {
4676       prefetch => {
4677         cd => 'artist'
4678       }
4679     }
4680   );
4681
4682 The initial search results in SQL like the following:
4683
4684   SELECT tag.*, cd.*, artist.* FROM tag
4685   JOIN cd ON tag.cd = cd.cdid
4686   JOIN artist ON cd.artist = artist.artistid
4687
4688 L<DBIx::Class> has no need to go back to the database when we access the
4689 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4690 case.
4691
4692 Simple prefetches will be joined automatically, so there is no need
4693 for a C<join> attribute in the above search.
4694
4695 The L</prefetch> attribute can be used with any of the relationship types
4696 and multiple prefetches can be specified together. Below is a more complex
4697 example that prefetches a CD's artist, its liner notes (if present),
4698 the cover image, the tracks on that CD, and the guests on those
4699 tracks.
4700
4701   my $rs = $schema->resultset('CD')->search(
4702     undef,
4703     {
4704       prefetch => [
4705         { artist => 'record_label'},  # belongs_to => belongs_to
4706         'liner_note',                 # might_have
4707         'cover_image',                # has_one
4708         { tracks => 'guests' },       # has_many => has_many
4709       ]
4710     }
4711   );
4712
4713 This will produce SQL like the following:
4714
4715   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4716          tracks.*, guests.*
4717     FROM cd me
4718     JOIN artist artist
4719       ON artist.artistid = me.artistid
4720     JOIN record_label record_label
4721       ON record_label.labelid = artist.labelid
4722     LEFT JOIN track tracks
4723       ON tracks.cdid = me.cdid
4724     LEFT JOIN guest guests
4725       ON guests.trackid = track.trackid
4726     LEFT JOIN liner_notes liner_note
4727       ON liner_note.cdid = me.cdid
4728     JOIN cd_artwork cover_image
4729       ON cover_image.cdid = me.cdid
4730   ORDER BY tracks.cd
4731
4732 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4733 C<tracks>, and C<guests> of the CD will all be available through the
4734 relationship accessors without the need for additional queries to the
4735 database.
4736
4737 =head3 CAVEATS
4738
4739 Prefetch does a lot of deep magic. As such, it may not behave exactly
4740 as you might expect.
4741
4742 =over 4
4743
4744 =item *
4745
4746 Prefetch uses the L</cache> to populate the prefetched relationships. This
4747 may or may not be what you want.
4748
4749 =item *
4750
4751 If you specify a condition on a prefetched relationship, ONLY those
4752 rows that match the prefetched condition will be fetched into that relationship.
4753 This means that adding prefetch to a search() B<may alter> what is returned by
4754 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4755
4756   my $artist_rs = $schema->resultset('Artist')->search({
4757       'cds.year' => 2008,
4758   }, {
4759       join => 'cds',
4760   });
4761
4762   my $count = $artist_rs->first->cds->count;
4763
4764   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4765
4766   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4767
4768   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4769
4770 That cmp_ok() may or may not pass depending on the datasets involved. In other
4771 words the C<WHERE> condition would apply to the entire dataset, just like
4772 it would in regular SQL. If you want to add a condition only to the "right side"
4773 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4774 condition|DBIx::Class::Relationship::Base/condition>
4775
4776 =back
4777
4778 =head1 DBIC BIND VALUES
4779
4780 Because DBIC may need more information to bind values than just the column name
4781 and value itself, it uses a special format for both passing and receiving bind
4782 values.  Each bind value should be composed of an arrayref of
4783 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4784
4785 =over 4
4786
4787 =item dbd_attrs
4788
4789 If present (in any form), this is what is being passed directly to bind_param.
4790 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4791 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4792
4793 If this is specified, all other bind options described below are ignored.
4794
4795 =item sqlt_datatype
4796
4797 If present, this is used to infer the actual bind attribute by passing to
4798 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4799 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4800
4801 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4802 currently drivers are expected to "Do the Right Thing" when given a common
4803 datatype name.  (Not ideal, but that's what we got at this point.)
4804
4805 =item sqlt_size
4806
4807 Currently used to correctly allocate buffers for bind_param_inout().
4808 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4809 or to a sensible value based on the "data_type".
4810
4811 =item dbic_colname
4812
4813 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4814 explicitly specified they are never overridden).  Also used by some weird DBDs,
4815 where the column name should be available at bind_param time (e.g. Oracle).
4816
4817 =back
4818
4819 For backwards compatibility and convenience, the following shortcuts are
4820 supported:
4821
4822   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4823   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4824   [ undef,   $val ] === [ {}, $val ]
4825   $val              === [ {}, $val ]
4826
4827 =head1 FURTHER QUESTIONS?
4828
4829 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4830
4831 =head1 COPYRIGHT AND LICENSE
4832
4833 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4834 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4835 redistribute it and/or modify it under the same terms as the
4836 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4837
4838 =cut