lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 my @count_via_subq_attrs = qw/join seen_join prefetch group_by/;
1154 sub count {
1155   my $self = shift;
1156   return $self->search(@_)->count if @_ and defined $_[0];
1157   return scalar @{ $self->get_cache } if $self->get_cache;
1158
1159   my @check_attrs = @count_via_subq_attrs;
1160
1161   # if we are not paged - we are simply asking for a limit
1162   if (not $self->{attrs}{page} and not $self->{attrs}{software_limit}) {
1163     push @check_attrs, qw/rows offset/;
1164   }
1165
1166   return $self->_has_attr (@check_attrs)
1167     ? $self->_count_subq
1168     : $self->_count_simple
1169 }
1170
1171 sub _count_subq {
1172   my $self = shift;
1173
1174   my $attrs = { %{$self->_resolved_attrs} };
1175
1176   # copy for the subquery, we need to do some adjustments to it too
1177   my $sub_attrs = { %$attrs };
1178
1179   # these can not go in the subquery either
1180   delete $sub_attrs->{$_} for qw/prefetch select +select as +as columns +columns/;
1181
1182   # force a group_by and the same set of columns (most databases require this)
1183   $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1184
1185   $attrs->{from} = [{
1186     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1187   }];
1188
1189   # the subquery replaces this
1190   delete $attrs->{where};
1191
1192   return $self->__count ($attrs);
1193 }
1194
1195 sub _count_simple {
1196   my $self = shift;
1197
1198   my $count = $self->__count;
1199   return 0 unless $count;
1200
1201   # need to take offset from resolved attrs
1202
1203   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1204   $count = $self->{attrs}{rows} if
1205     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1206   $count = 0 if ($count < 0);
1207   return $count;
1208 }
1209
1210 sub __count {
1211   my ($self, $attrs) = @_;
1212
1213   $attrs ||= { %{$self->{attrs}} };
1214
1215   # take off any subquery attrs (they'd be incorporated in the subquery),
1216   # any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1217   delete $attrs->{$_} for (@count_via_subq_attrs, qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1218
1219   $attrs->{select} = { count => '*' };
1220   $attrs->{as} = [qw/count/];
1221
1222   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1223   my ($count) = $tmp_rs->cursor->next;
1224
1225   return $count;
1226 }
1227
1228 sub _bool {
1229   return 1;
1230 }
1231
1232 =head2 count_literal
1233
1234 =over 4
1235
1236 =item Arguments: $sql_fragment, @bind_values
1237
1238 =item Return Value: $count
1239
1240 =back
1241
1242 Counts the results in a literal query. Equivalent to calling L</search_literal>
1243 with the passed arguments, then L</count>.
1244
1245 =cut
1246
1247 sub count_literal { shift->search_literal(@_)->count; }
1248
1249 =head2 all
1250
1251 =over 4
1252
1253 =item Arguments: none
1254
1255 =item Return Value: @objects
1256
1257 =back
1258
1259 Returns all elements in the resultset. Called implicitly if the resultset
1260 is returned in list context.
1261
1262 =cut
1263
1264 sub all {
1265   my $self = shift;
1266   if(@_) {
1267       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1268   }
1269
1270   return @{ $self->get_cache } if $self->get_cache;
1271
1272   my @obj;
1273
1274   # TODO: don't call resolve here
1275   if (keys %{$self->_resolved_attrs->{collapse}}) {
1276 #  if ($self->{attrs}{prefetch}) {
1277       # Using $self->cursor->all is really just an optimisation.
1278       # If we're collapsing has_many prefetches it probably makes
1279       # very little difference, and this is cleaner than hacking
1280       # _construct_object to survive the approach
1281     my @row = $self->cursor->next;
1282     while (@row) {
1283       push(@obj, $self->_construct_object(@row));
1284       @row = (exists $self->{stashed_row}
1285                ? @{delete $self->{stashed_row}}
1286                : $self->cursor->next);
1287     }
1288   } else {
1289     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1290   }
1291
1292   $self->set_cache(\@obj) if $self->{attrs}{cache};
1293   return @obj;
1294 }
1295
1296 =head2 reset
1297
1298 =over 4
1299
1300 =item Arguments: none
1301
1302 =item Return Value: $self
1303
1304 =back
1305
1306 Resets the resultset's cursor, so you can iterate through the elements again.
1307
1308 =cut
1309
1310 sub reset {
1311   my ($self) = @_;
1312   delete $self->{_attrs} if exists $self->{_attrs};
1313   $self->{all_cache_position} = 0;
1314   $self->cursor->reset;
1315   return $self;
1316 }
1317
1318 =head2 first
1319
1320 =over 4
1321
1322 =item Arguments: none
1323
1324 =item Return Value: $object?
1325
1326 =back
1327
1328 Resets the resultset and returns an object for the first result (if the
1329 resultset returns anything).
1330
1331 =cut
1332
1333 sub first {
1334   return $_[0]->reset->next;
1335 }
1336
1337
1338 # _update_delete_via_subq
1339 #
1340 # Presence of some rs attributes requires a subquery to reliably
1341 # update/deletre
1342 #
1343
1344 sub _update_delete_via_subq {
1345   return $_[0]->_has_attr (qw/join seen_join group_by row offset page/);
1346 }
1347
1348
1349 # _cond_for_update_delete
1350 #
1351 # update/delete require the condition to be modified to handle
1352 # the differing SQL syntax available.  This transforms the $self->{cond}
1353 # appropriately, returning the new condition.
1354
1355 sub _cond_for_update_delete {
1356   my ($self, $full_cond) = @_;
1357   my $cond = {};
1358
1359   $full_cond ||= $self->{cond};
1360   # No-op. No condition, we're updating/deleting everything
1361   return $cond unless ref $full_cond;
1362
1363   if (ref $full_cond eq 'ARRAY') {
1364     $cond = [
1365       map {
1366         my %hash;
1367         foreach my $key (keys %{$_}) {
1368           $key =~ /([^.]+)$/;
1369           $hash{$1} = $_->{$key};
1370         }
1371         \%hash;
1372       } @{$full_cond}
1373     ];
1374   }
1375   elsif (ref $full_cond eq 'HASH') {
1376     if ((keys %{$full_cond})[0] eq '-and') {
1377       $cond->{-and} = [];
1378       my @cond = @{$full_cond->{-and}};
1379        for (my $i = 0; $i < @cond; $i++) {
1380         my $entry = $cond[$i];
1381         my $hash;
1382         if (ref $entry eq 'HASH') {
1383           $hash = $self->_cond_for_update_delete($entry);
1384         }
1385         else {
1386           $entry =~ /([^.]+)$/;
1387           $hash->{$1} = $cond[++$i];
1388         }
1389         push @{$cond->{-and}}, $hash;
1390       }
1391     }
1392     else {
1393       foreach my $key (keys %{$full_cond}) {
1394         $key =~ /([^.]+)$/;
1395         $cond->{$1} = $full_cond->{$key};
1396       }
1397     }
1398   }
1399   else {
1400     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1401   }
1402
1403   return $cond;
1404 }
1405
1406
1407 =head2 update
1408
1409 =over 4
1410
1411 =item Arguments: \%values
1412
1413 =item Return Value: $storage_rv
1414
1415 =back
1416
1417 Sets the specified columns in the resultset to the supplied values in a
1418 single query. Return value will be true if the update succeeded or false
1419 if no records were updated; exact type of success value is storage-dependent.
1420
1421 =cut
1422
1423 sub update {
1424   my ($self, $values) = @_;
1425   $self->throw_exception('Values for update must be a hash')
1426     unless ref $values eq 'HASH';
1427
1428   # rs operations with subqueries are Storage dependent - delegate
1429   if ($self->_update_delete_via_subq) {
1430     return $self->result_source->storage->subq_update_delete($self, 'update', $values);
1431   }
1432
1433   my $cond = $self->_cond_for_update_delete;
1434
1435   return $self->result_source->storage->update(
1436     $self->result_source, $values, $cond
1437   );
1438 }
1439
1440 =head2 update_all
1441
1442 =over 4
1443
1444 =item Arguments: \%values
1445
1446 =item Return Value: 1
1447
1448 =back
1449
1450 Fetches all objects and updates them one at a time. Note that C<update_all>
1451 will run DBIC cascade triggers, while L</update> will not.
1452
1453 =cut
1454
1455 sub update_all {
1456   my ($self, $values) = @_;
1457   $self->throw_exception('Values for update_all must be a hash')
1458     unless ref $values eq 'HASH';
1459   foreach my $obj ($self->all) {
1460     $obj->set_columns($values)->update;
1461   }
1462   return 1;
1463 }
1464
1465 =head2 delete
1466
1467 =over 4
1468
1469 =item Arguments: none
1470
1471 =item Return Value: 1
1472
1473 =back
1474
1475 Deletes the contents of the resultset from its result source. Note that this
1476 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1477 to run. See also L<DBIx::Class::Row/delete>.
1478
1479 delete may not generate correct SQL for a query with joins or a resultset
1480 chained from a related resultset.  In this case it will generate a warning:-
1481
1482 In these cases you may find that delete_all is more appropriate, or you
1483 need to respecify your query in a way that can be expressed without a join.
1484
1485 =cut
1486
1487 sub delete {
1488   my $self = shift;
1489   $self->throw_exception('delete does not accept any arguments')
1490     if @_;
1491
1492   # rs operations with subqueries are Storage dependent - delegate
1493   if ($self->_update_delete_via_subq) {
1494     return $self->result_source->storage->subq_update_delete($self, 'delete');
1495   }
1496
1497   my $cond = $self->_cond_for_update_delete;
1498
1499   $self->result_source->storage->delete($self->result_source, $cond);
1500   return 1;
1501 }
1502
1503 =head2 delete_all
1504
1505 =over 4
1506
1507 =item Arguments: none
1508
1509 =item Return Value: 1
1510
1511 =back
1512
1513 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1514 will run DBIC cascade triggers, while L</delete> will not.
1515
1516 =cut
1517
1518 sub delete_all {
1519   my $self = shift;
1520   $self->throw_exception('delete_all does not accept any arguments')
1521     if @_;
1522
1523   $_->delete for $self->all;
1524   return 1;
1525 }
1526
1527 =head2 populate
1528
1529 =over 4
1530
1531 =item Arguments: \@data;
1532
1533 =back
1534
1535 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1536 For the arrayref of hashrefs style each hashref should be a structure suitable
1537 forsubmitting to a $resultset->create(...) method.
1538
1539 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1540 to insert the data, as this is a faster method.
1541
1542 Otherwise, each set of data is inserted into the database using
1543 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1544 objects is returned.
1545
1546 Example:  Assuming an Artist Class that has many CDs Classes relating:
1547
1548   my $Artist_rs = $schema->resultset("Artist");
1549
1550   ## Void Context Example
1551   $Artist_rs->populate([
1552      { artistid => 4, name => 'Manufactured Crap', cds => [
1553         { title => 'My First CD', year => 2006 },
1554         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1555       ],
1556      },
1557      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1558         { title => 'My parents sold me to a record company' ,year => 2005 },
1559         { title => 'Why Am I So Ugly?', year => 2006 },
1560         { title => 'I Got Surgery and am now Popular', year => 2007 }
1561       ],
1562      },
1563   ]);
1564
1565   ## Array Context Example
1566   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1567     { name => "Artist One"},
1568     { name => "Artist Two"},
1569     { name => "Artist Three", cds=> [
1570     { title => "First CD", year => 2007},
1571     { title => "Second CD", year => 2008},
1572   ]}
1573   ]);
1574
1575   print $ArtistOne->name; ## response is 'Artist One'
1576   print $ArtistThree->cds->count ## reponse is '2'
1577
1578 For the arrayref of arrayrefs style,  the first element should be a list of the
1579 fieldsnames to which the remaining elements are rows being inserted.  For
1580 example:
1581
1582   $Arstist_rs->populate([
1583     [qw/artistid name/],
1584     [100, 'A Formally Unknown Singer'],
1585     [101, 'A singer that jumped the shark two albums ago'],
1586     [102, 'An actually cool singer.'],
1587   ]);
1588
1589 Please note an important effect on your data when choosing between void and
1590 wantarray context. Since void context goes straight to C<insert_bulk> in
1591 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1592 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1593 create primary keys for you, you will find that your PKs are empty.  In this
1594 case you will have to use the wantarray context in order to create those
1595 values.
1596
1597 =cut
1598
1599 sub populate {
1600   my $self = shift @_;
1601   my $data = ref $_[0][0] eq 'HASH'
1602     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1603     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1604
1605   if(defined wantarray) {
1606     my @created;
1607     foreach my $item (@$data) {
1608       push(@created, $self->create($item));
1609     }
1610     return @created;
1611   } else {
1612     my ($first, @rest) = @$data;
1613
1614     my @names = grep {!ref $first->{$_}} keys %$first;
1615     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1616     my @pks = $self->result_source->primary_columns;
1617
1618     ## do the belongs_to relationships
1619     foreach my $index (0..$#$data) {
1620       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1621         my @ret = $self->populate($data);
1622         return;
1623       }
1624
1625       foreach my $rel (@rels) {
1626         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1627         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1628         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1629         my $related = $result->result_source->resolve_condition(
1630           $result->result_source->relationship_info($reverse)->{cond},
1631           $self,
1632           $result,
1633         );
1634
1635         delete $data->[$index]->{$rel};
1636         $data->[$index] = {%{$data->[$index]}, %$related};
1637
1638         push @names, keys %$related if $index == 0;
1639       }
1640     }
1641
1642     ## do bulk insert on current row
1643     my @values = map { [ @$_{@names} ] } @$data;
1644
1645     $self->result_source->storage->insert_bulk(
1646       $self->result_source,
1647       \@names,
1648       \@values,
1649     );
1650
1651     ## do the has_many relationships
1652     foreach my $item (@$data) {
1653
1654       foreach my $rel (@rels) {
1655         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1656
1657         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1658      || $self->throw_exception('Cannot find the relating object.');
1659
1660         my $child = $parent->$rel;
1661
1662         my $related = $child->result_source->resolve_condition(
1663           $parent->result_source->relationship_info($rel)->{cond},
1664           $child,
1665           $parent,
1666         );
1667
1668         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1669         my @populate = map { {%$_, %$related} } @rows_to_add;
1670
1671         $child->populate( \@populate );
1672       }
1673     }
1674   }
1675 }
1676
1677 =head2 _normalize_populate_args ($args)
1678
1679 Private method used by L</populate> to normalize its incoming arguments.  Factored
1680 out in case you want to subclass and accept new argument structures to the
1681 L</populate> method.
1682
1683 =cut
1684
1685 sub _normalize_populate_args {
1686   my ($self, $data) = @_;
1687   my @names = @{shift(@$data)};
1688   my @results_to_create;
1689   foreach my $datum (@$data) {
1690     my %result_to_create;
1691     foreach my $index (0..$#names) {
1692       $result_to_create{$names[$index]} = $$datum[$index];
1693     }
1694     push @results_to_create, \%result_to_create;
1695   }
1696   return \@results_to_create;
1697 }
1698
1699 =head2 pager
1700
1701 =over 4
1702
1703 =item Arguments: none
1704
1705 =item Return Value: $pager
1706
1707 =back
1708
1709 Return Value a L<Data::Page> object for the current resultset. Only makes
1710 sense for queries with a C<page> attribute.
1711
1712 To get the full count of entries for a paged resultset, call
1713 C<total_entries> on the L<Data::Page> object.
1714
1715 =cut
1716
1717 sub pager {
1718   my ($self) = @_;
1719
1720   return $self->{pager} if $self->{pager};
1721
1722   my $attrs = $self->{attrs};
1723   $self->throw_exception("Can't create pager for non-paged rs")
1724     unless $self->{attrs}{page};
1725   $attrs->{rows} ||= 10;
1726
1727   # throw away the paging flags and re-run the count (possibly
1728   # with a subselect) to get the real total count
1729   my $count_attrs = { %$attrs };
1730   delete $count_attrs->{$_} for qw/rows offset page pager/;
1731   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1732
1733   return $self->{pager} = Data::Page->new(
1734     $total_count,
1735     $attrs->{rows},
1736     $self->{attrs}{page}
1737   );
1738 }
1739
1740 =head2 page
1741
1742 =over 4
1743
1744 =item Arguments: $page_number
1745
1746 =item Return Value: $rs
1747
1748 =back
1749
1750 Returns a resultset for the $page_number page of the resultset on which page
1751 is called, where each page contains a number of rows equal to the 'rows'
1752 attribute set on the resultset (10 by default).
1753
1754 =cut
1755
1756 sub page {
1757   my ($self, $page) = @_;
1758   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1759 }
1760
1761 =head2 new_result
1762
1763 =over 4
1764
1765 =item Arguments: \%vals
1766
1767 =item Return Value: $rowobject
1768
1769 =back
1770
1771 Creates a new row object in the resultset's result class and returns
1772 it. The row is not inserted into the database at this point, call
1773 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1774 will tell you whether the row object has been inserted or not.
1775
1776 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1777
1778 =cut
1779
1780 sub new_result {
1781   my ($self, $values) = @_;
1782   $self->throw_exception( "new_result needs a hash" )
1783     unless (ref $values eq 'HASH');
1784
1785   my %new;
1786   my $alias = $self->{attrs}{alias};
1787
1788   if (
1789     defined $self->{cond}
1790     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1791   ) {
1792     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1793     $new{-from_resultset} = [ keys %new ] if keys %new;
1794   } else {
1795     $self->throw_exception(
1796       "Can't abstract implicit construct, condition not a hash"
1797     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1798
1799     my $collapsed_cond = (
1800       $self->{cond}
1801         ? $self->_collapse_cond($self->{cond})
1802         : {}
1803     );
1804
1805     # precendence must be given to passed values over values inherited from
1806     # the cond, so the order here is important.
1807     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1808     while( my($col,$value) = each %implied ){
1809       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1810         $new{$col} = $value->{'='};
1811         next;
1812       }
1813       $new{$col} = $value if $self->_is_deterministic_value($value);
1814     }
1815   }
1816
1817   %new = (
1818     %new,
1819     %{ $self->_remove_alias($values, $alias) },
1820     -source_handle => $self->_source_handle,
1821     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1822   );
1823
1824   return $self->result_class->new(\%new);
1825 }
1826
1827 # _is_deterministic_value
1828 #
1829 # Make an effor to strip non-deterministic values from the condition,
1830 # to make sure new_result chokes less
1831
1832 sub _is_deterministic_value {
1833   my $self = shift;
1834   my $value = shift;
1835   my $ref_type = ref $value;
1836   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1837   return 1 if Scalar::Util::blessed($value);
1838   return 0;
1839 }
1840
1841 # _has_attr
1842 #
1843 # determines if the resultset defines at least one
1844 # of the attributes supplied
1845 #
1846 # used to determine if a subquery is neccessary
1847
1848 sub _has_attr {
1849   my ($self, @attr_names) = @_;
1850
1851   my $attrs = $self->_resolved_attrs;
1852
1853   my $join_check_req;
1854
1855   for my $n (@attr_names) {
1856     return 1 if defined $attrs->{$n};
1857     ++$join_check_req if $n =~ /join/;
1858   }
1859
1860   # a join can be expressed as a multi-level from
1861   return 1 if (
1862     $join_check_req
1863       and
1864     ref $attrs->{from} eq 'ARRAY'
1865       and
1866     @{$attrs->{from}} > 1
1867   );
1868
1869   return 0;
1870 }
1871
1872 # _collapse_cond
1873 #
1874 # Recursively collapse the condition.
1875
1876 sub _collapse_cond {
1877   my ($self, $cond, $collapsed) = @_;
1878
1879   $collapsed ||= {};
1880
1881   if (ref $cond eq 'ARRAY') {
1882     foreach my $subcond (@$cond) {
1883       next unless ref $subcond;  # -or
1884       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1885     }
1886   }
1887   elsif (ref $cond eq 'HASH') {
1888     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1889       foreach my $subcond (@{$cond->{-and}}) {
1890         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1891       }
1892     }
1893     else {
1894       foreach my $col (keys %$cond) {
1895         my $value = $cond->{$col};
1896         $collapsed->{$col} = $value;
1897       }
1898     }
1899   }
1900
1901   return $collapsed;
1902 }
1903
1904 # _remove_alias
1905 #
1906 # Remove the specified alias from the specified query hash. A copy is made so
1907 # the original query is not modified.
1908
1909 sub _remove_alias {
1910   my ($self, $query, $alias) = @_;
1911
1912   my %orig = %{ $query || {} };
1913   my %unaliased;
1914
1915   foreach my $key (keys %orig) {
1916     if ($key !~ /\./) {
1917       $unaliased{$key} = $orig{$key};
1918       next;
1919     }
1920     $unaliased{$1} = $orig{$key}
1921       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1922   }
1923
1924   return \%unaliased;
1925 }
1926
1927 =head2 as_query (EXPERIMENTAL)
1928
1929 =over 4
1930
1931 =item Arguments: none
1932
1933 =item Return Value: \[ $sql, @bind ]
1934
1935 =back
1936
1937 Returns the SQL query and bind vars associated with the invocant.
1938
1939 This is generally used as the RHS for a subquery.
1940
1941 B<NOTE>: This feature is still experimental.
1942
1943 =cut
1944
1945 sub as_query { return shift->cursor->as_query(@_) }
1946
1947 =head2 find_or_new
1948
1949 =over 4
1950
1951 =item Arguments: \%vals, \%attrs?
1952
1953 =item Return Value: $rowobject
1954
1955 =back
1956
1957   my $artist = $schema->resultset('Artist')->find_or_new(
1958     { artist => 'fred' }, { key => 'artists' });
1959
1960   $cd->cd_to_producer->find_or_new({ producer => $producer },
1961                                    { key => 'primary });
1962
1963 Find an existing record from this resultset, based on its primary
1964 key, or a unique constraint. If none exists, instantiate a new result
1965 object and return it. The object will not be saved into your storage
1966 until you call L<DBIx::Class::Row/insert> on it.
1967
1968 You most likely want this method when looking for existing rows using
1969 a unique constraint that is not the primary key, or looking for
1970 related rows.
1971
1972 If you want objects to be saved immediately, use L</find_or_create> instead.
1973
1974 B<Note>: C<find_or_new> is probably not what you want when creating a
1975 new row in a table that uses primary keys supplied by the
1976 database. Passing in a primary key column with a value of I<undef>
1977 will cause L</find> to attempt to search for a row with a value of
1978 I<NULL>.
1979
1980 =cut
1981
1982 sub find_or_new {
1983   my $self     = shift;
1984   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1985   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1986   my $exists   = $self->find($hash, $attrs);
1987   return defined $exists ? $exists : $self->new_result($hash);
1988 }
1989
1990 =head2 create
1991
1992 =over 4
1993
1994 =item Arguments: \%vals
1995
1996 =item Return Value: a L<DBIx::Class::Row> $object
1997
1998 =back
1999
2000 Attempt to create a single new row or a row with multiple related rows
2001 in the table represented by the resultset (and related tables). This
2002 will not check for duplicate rows before inserting, use
2003 L</find_or_create> to do that.
2004
2005 To create one row for this resultset, pass a hashref of key/value
2006 pairs representing the columns of the table and the values you wish to
2007 store. If the appropriate relationships are set up, foreign key fields
2008 can also be passed an object representing the foreign row, and the
2009 value will be set to its primary key.
2010
2011 To create related objects, pass a hashref for the value if the related
2012 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2013 and use the name of the relationship as the key. (NOT the name of the field,
2014 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2015 of hashrefs containing the data for each of the rows to create in the foreign
2016 tables, again using the relationship name as the key.
2017
2018 Instead of hashrefs of plain related data (key/value pairs), you may
2019 also pass new or inserted objects. New objects (not inserted yet, see
2020 L</new>), will be inserted into their appropriate tables.
2021
2022 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2023
2024 Example of creating a new row.
2025
2026   $person_rs->create({
2027     name=>"Some Person",
2028     email=>"somebody@someplace.com"
2029   });
2030
2031 Example of creating a new row and also creating rows in a related C<has_many>
2032 or C<has_one> resultset.  Note Arrayref.
2033
2034   $artist_rs->create(
2035      { artistid => 4, name => 'Manufactured Crap', cds => [
2036         { title => 'My First CD', year => 2006 },
2037         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2038       ],
2039      },
2040   );
2041
2042 Example of creating a new row and also creating a row in a related
2043 C<belongs_to>resultset. Note Hashref.
2044
2045   $cd_rs->create({
2046     title=>"Music for Silly Walks",
2047     year=>2000,
2048     artist => {
2049       name=>"Silly Musician",
2050     }
2051   });
2052
2053 =cut
2054
2055 sub create {
2056   my ($self, $attrs) = @_;
2057   $self->throw_exception( "create needs a hashref" )
2058     unless ref $attrs eq 'HASH';
2059   return $self->new_result($attrs)->insert;
2060 }
2061
2062 =head2 find_or_create
2063
2064 =over 4
2065
2066 =item Arguments: \%vals, \%attrs?
2067
2068 =item Return Value: $rowobject
2069
2070 =back
2071
2072   $cd->cd_to_producer->find_or_create({ producer => $producer },
2073                                       { key => 'primary });
2074
2075 Tries to find a record based on its primary key or unique constraints; if none
2076 is found, creates one and returns that instead.
2077
2078   my $cd = $schema->resultset('CD')->find_or_create({
2079     cdid   => 5,
2080     artist => 'Massive Attack',
2081     title  => 'Mezzanine',
2082     year   => 2005,
2083   });
2084
2085 Also takes an optional C<key> attribute, to search by a specific key or unique
2086 constraint. For example:
2087
2088   my $cd = $schema->resultset('CD')->find_or_create(
2089     {
2090       artist => 'Massive Attack',
2091       title  => 'Mezzanine',
2092     },
2093     { key => 'cd_artist_title' }
2094   );
2095
2096 B<Note>: Because find_or_create() reads from the database and then
2097 possibly inserts based on the result, this method is subject to a race
2098 condition. Another process could create a record in the table after
2099 the find has completed and before the create has started. To avoid
2100 this problem, use find_or_create() inside a transaction.
2101
2102 B<Note>: C<find_or_create> is probably not what you want when creating
2103 a new row in a table that uses primary keys supplied by the
2104 database. Passing in a primary key column with a value of I<undef>
2105 will cause L</find> to attempt to search for a row with a value of
2106 I<NULL>.
2107
2108 See also L</find> and L</update_or_create>. For information on how to declare
2109 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2110
2111 =cut
2112
2113 sub find_or_create {
2114   my $self     = shift;
2115   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2116   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2117   my $exists   = $self->find($hash, $attrs);
2118   return defined $exists ? $exists : $self->create($hash);
2119 }
2120
2121 =head2 update_or_create
2122
2123 =over 4
2124
2125 =item Arguments: \%col_values, { key => $unique_constraint }?
2126
2127 =item Return Value: $rowobject
2128
2129 =back
2130
2131   $resultset->update_or_create({ col => $val, ... });
2132
2133 First, searches for an existing row matching one of the unique constraints
2134 (including the primary key) on the source of this resultset. If a row is
2135 found, updates it with the other given column values. Otherwise, creates a new
2136 row.
2137
2138 Takes an optional C<key> attribute to search on a specific unique constraint.
2139 For example:
2140
2141   # In your application
2142   my $cd = $schema->resultset('CD')->update_or_create(
2143     {
2144       artist => 'Massive Attack',
2145       title  => 'Mezzanine',
2146       year   => 1998,
2147     },
2148     { key => 'cd_artist_title' }
2149   );
2150
2151   $cd->cd_to_producer->update_or_create({
2152     producer => $producer,
2153     name => 'harry',
2154   }, {
2155     key => 'primary,
2156   });
2157
2158
2159 If no C<key> is specified, it searches on all unique constraints defined on the
2160 source, including the primary key.
2161
2162 If the C<key> is specified as C<primary>, it searches only on the primary key.
2163
2164 See also L</find> and L</find_or_create>. For information on how to declare
2165 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2166
2167 B<Note>: C<update_or_create> is probably not what you want when
2168 looking for a row in a table that uses primary keys supplied by the
2169 database, unless you actually have a key value. Passing in a primary
2170 key column with a value of I<undef> will cause L</find> to attempt to
2171 search for a row with a value of I<NULL>.
2172
2173 =cut
2174
2175 sub update_or_create {
2176   my $self = shift;
2177   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2178   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2179
2180   my $row = $self->find($cond, $attrs);
2181   if (defined $row) {
2182     $row->update($cond);
2183     return $row;
2184   }
2185
2186   return $self->create($cond);
2187 }
2188
2189 =head2 update_or_new
2190
2191 =over 4
2192
2193 =item Arguments: \%col_values, { key => $unique_constraint }?
2194
2195 =item Return Value: $rowobject
2196
2197 =back
2198
2199   $resultset->update_or_new({ col => $val, ... });
2200
2201 First, searches for an existing row matching one of the unique constraints
2202 (including the primary key) on the source of this resultset. If a row is
2203 found, updates it with the other given column values. Otherwise, instantiate
2204 a new result object and return it. The object will not be saved into your storage
2205 until you call L<DBIx::Class::Row/insert> on it.
2206
2207 Takes an optional C<key> attribute to search on a specific unique constraint.
2208 For example:
2209
2210   # In your application
2211   my $cd = $schema->resultset('CD')->update_or_new(
2212     {
2213       artist => 'Massive Attack',
2214       title  => 'Mezzanine',
2215       year   => 1998,
2216     },
2217     { key => 'cd_artist_title' }
2218   );
2219
2220   if ($cd->in_storage) {
2221       # the cd was updated
2222   }
2223   else {
2224       # the cd is not yet in the database, let's insert it
2225       $cd->insert;
2226   }
2227
2228 See also L</find>, L</find_or_create> and L<find_or_new>.
2229
2230 =cut
2231
2232 sub update_or_new {
2233     my $self  = shift;
2234     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2235     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2236
2237     my $row = $self->find( $cond, $attrs );
2238     if ( defined $row ) {
2239         $row->update($cond);
2240         return $row;
2241     }
2242
2243     return $self->new_result($cond);
2244 }
2245
2246 =head2 get_cache
2247
2248 =over 4
2249
2250 =item Arguments: none
2251
2252 =item Return Value: \@cache_objects?
2253
2254 =back
2255
2256 Gets the contents of the cache for the resultset, if the cache is set.
2257
2258 The cache is populated either by using the L</prefetch> attribute to
2259 L</search> or by calling L</set_cache>.
2260
2261 =cut
2262
2263 sub get_cache {
2264   shift->{all_cache};
2265 }
2266
2267 =head2 set_cache
2268
2269 =over 4
2270
2271 =item Arguments: \@cache_objects
2272
2273 =item Return Value: \@cache_objects
2274
2275 =back
2276
2277 Sets the contents of the cache for the resultset. Expects an arrayref
2278 of objects of the same class as those produced by the resultset. Note that
2279 if the cache is set the resultset will return the cached objects rather
2280 than re-querying the database even if the cache attr is not set.
2281
2282 The contents of the cache can also be populated by using the
2283 L</prefetch> attribute to L</search>.
2284
2285 =cut
2286
2287 sub set_cache {
2288   my ( $self, $data ) = @_;
2289   $self->throw_exception("set_cache requires an arrayref")
2290       if defined($data) && (ref $data ne 'ARRAY');
2291   $self->{all_cache} = $data;
2292 }
2293
2294 =head2 clear_cache
2295
2296 =over 4
2297
2298 =item Arguments: none
2299
2300 =item Return Value: []
2301
2302 =back
2303
2304 Clears the cache for the resultset.
2305
2306 =cut
2307
2308 sub clear_cache {
2309   shift->set_cache(undef);
2310 }
2311
2312 =head2 related_resultset
2313
2314 =over 4
2315
2316 =item Arguments: $relationship_name
2317
2318 =item Return Value: $resultset
2319
2320 =back
2321
2322 Returns a related resultset for the supplied relationship name.
2323
2324   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2325
2326 =cut
2327
2328 sub related_resultset {
2329   my ($self, $rel) = @_;
2330
2331   $self->{related_resultsets} ||= {};
2332   return $self->{related_resultsets}{$rel} ||= do {
2333     my $rel_obj = $self->result_source->relationship_info($rel);
2334
2335     $self->throw_exception(
2336       "search_related: result source '" . $self->result_source->source_name .
2337         "' has no such relationship $rel")
2338       unless $rel_obj;
2339
2340     my ($from,$seen) = $self->_resolve_from($rel);
2341
2342     my $join_count = $seen->{$rel};
2343     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2344
2345     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2346     my %attrs = %{$self->{attrs}||{}};
2347     delete @attrs{qw(result_class alias)};
2348
2349     my $new_cache;
2350
2351     if (my $cache = $self->get_cache) {
2352       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2353         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2354                         @$cache ];
2355       }
2356     }
2357
2358     my $rel_source = $self->result_source->related_source($rel);
2359
2360     my $new = do {
2361
2362       # The reason we do this now instead of passing the alias to the
2363       # search_rs below is that if you wrap/overload resultset on the
2364       # source you need to know what alias it's -going- to have for things
2365       # to work sanely (e.g. RestrictWithObject wants to be able to add
2366       # extra query restrictions, and these may need to be $alias.)
2367
2368       my $attrs = $rel_source->resultset_attributes;
2369       local $attrs->{alias} = $alias;
2370
2371       $rel_source->resultset
2372                  ->search_rs(
2373                      undef, {
2374                        %attrs,
2375                        join => undef,
2376                        prefetch => undef,
2377                        select => undef,
2378                        as => undef,
2379                        where => $self->{cond},
2380                        seen_join => $seen,
2381                        from => $from,
2382                    });
2383     };
2384     $new->set_cache($new_cache) if $new_cache;
2385     $new;
2386   };
2387 }
2388
2389 =head2 current_source_alias
2390
2391 =over 4
2392
2393 =item Arguments: none
2394
2395 =item Return Value: $source_alias
2396
2397 =back
2398
2399 Returns the current table alias for the result source this resultset is built
2400 on, that will be used in the SQL query. Usually it is C<me>.
2401
2402 Currently the source alias that refers to the result set returned by a
2403 L</search>/L</find> family method depends on how you got to the resultset: it's
2404 C<me> by default, but eg. L</search_related> aliases it to the related result
2405 source name (and keeps C<me> referring to the original result set). The long
2406 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2407 (and make this method unnecessary).
2408
2409 Thus it's currently necessary to use this method in predefined queries (see
2410 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2411 source alias of the current result set:
2412
2413   # in a result set class
2414   sub modified_by {
2415     my ($self, $user) = @_;
2416
2417     my $me = $self->current_source_alias;
2418
2419     return $self->search(
2420       "$me.modified" => $user->id,
2421     );
2422   }
2423
2424 =cut
2425
2426 sub current_source_alias {
2427   my ($self) = @_;
2428
2429   return ($self->{attrs} || {})->{alias} || 'me';
2430 }
2431
2432 # This code is called by search_related, and makes sure there
2433 # is clear separation between the joins before, during, and
2434 # after the relationship. This information is needed later
2435 # in order to properly resolve prefetch aliases (any alias
2436 # with a relation_chain_depth less than the depth of the
2437 # current prefetch is not considered)
2438 sub _resolve_from {
2439   my ($self, $extra_join) = @_;
2440   my $source = $self->result_source;
2441   my $attrs = $self->{attrs};
2442
2443   my $from = $attrs->{from}
2444     || [ { $attrs->{alias} => $source->from } ];
2445
2446   my $seen = { %{$attrs->{seen_join}||{}} };
2447
2448   # we need to take the prefetch the attrs into account before we
2449   # ->resolve_join as otherwise they get lost - captainL
2450   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2451
2452   push @$from, $source->resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2453
2454   ++$seen->{-relation_chain_depth};
2455
2456   push @$from, $source->resolve_join($extra_join, $attrs->{alias}, $seen);
2457
2458   ++$seen->{-relation_chain_depth};
2459
2460   return ($from,$seen);
2461 }
2462
2463 sub _resolved_attrs {
2464   my $self = shift;
2465   return $self->{_attrs} if $self->{_attrs};
2466
2467   my $attrs  = { %{ $self->{attrs} || {} } };
2468   my $source = $self->result_source;
2469   my $alias  = $attrs->{alias};
2470
2471   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2472   my @colbits;
2473
2474   # build columns (as long as select isn't set) into a set of as/select hashes
2475   unless ( $attrs->{select} ) {
2476       @colbits = map {
2477           ( ref($_) eq 'HASH' )
2478               ? $_
2479               : {
2480                   (
2481                     /^\Q${alias}.\E(.+)$/
2482                       ? "$1"
2483                       : "$_"
2484                   )
2485                 =>
2486                   (
2487                     /\./
2488                       ? "$_"
2489                       : "${alias}.$_"
2490                   )
2491             }
2492       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2493   }
2494   # add the additional columns on
2495   foreach ( 'include_columns', '+columns' ) {
2496       push @colbits, map {
2497           ( ref($_) eq 'HASH' )
2498             ? $_
2499             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2500       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2501   }
2502
2503   # start with initial select items
2504   if ( $attrs->{select} ) {
2505     $attrs->{select} =
2506         ( ref $attrs->{select} eq 'ARRAY' )
2507       ? [ @{ $attrs->{select} } ]
2508       : [ $attrs->{select} ];
2509     $attrs->{as} = (
2510       $attrs->{as}
2511       ? (
2512         ref $attrs->{as} eq 'ARRAY'
2513         ? [ @{ $attrs->{as} } ]
2514         : [ $attrs->{as} ]
2515         )
2516       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2517     );
2518   }
2519   else {
2520
2521     # otherwise we intialise select & as to empty
2522     $attrs->{select} = [];
2523     $attrs->{as}     = [];
2524   }
2525
2526   # now add colbits to select/as
2527   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2528   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2529
2530   my $adds;
2531   if ( $adds = delete $attrs->{'+select'} ) {
2532     $adds = [$adds] unless ref $adds eq 'ARRAY';
2533     push(
2534       @{ $attrs->{select} },
2535       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2536     );
2537   }
2538   if ( $adds = delete $attrs->{'+as'} ) {
2539     $adds = [$adds] unless ref $adds eq 'ARRAY';
2540     push( @{ $attrs->{as} }, @$adds );
2541   }
2542
2543   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2544
2545   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2546     my $join = delete $attrs->{join} || {};
2547
2548     if ( defined $attrs->{prefetch} ) {
2549       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2550
2551     }
2552
2553     $attrs->{from} =    # have to copy here to avoid corrupting the original
2554       [
2555       @{ $attrs->{from} },
2556       $source->resolve_join(
2557         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2558       )
2559       ];
2560
2561   }
2562
2563   $attrs->{group_by} ||= $attrs->{select}
2564     if delete $attrs->{distinct};
2565   if ( $attrs->{order_by} ) {
2566     $attrs->{order_by} = (
2567       ref( $attrs->{order_by} ) eq 'ARRAY'
2568       ? [ @{ $attrs->{order_by} } ]
2569       : [ $attrs->{order_by} ]
2570     );
2571   }
2572   else {
2573     $attrs->{order_by} = [];
2574   }
2575
2576   my $collapse = $attrs->{collapse} || {};
2577   if ( my $prefetch = delete $attrs->{prefetch} ) {
2578     $prefetch = $self->_merge_attr( {}, $prefetch );
2579     my @pre_order;
2580     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2581
2582       # bring joins back to level of current class
2583       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2584       my @prefetch =
2585         $source->resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2586       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2587       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2588     }
2589     push( @{ $attrs->{order_by} }, @pre_order );
2590   }
2591   $attrs->{collapse} = $collapse;
2592
2593   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2594     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2595   }
2596
2597   return $self->{_attrs} = $attrs;
2598 }
2599
2600 sub _joinpath_aliases {
2601   my ($self, $fromspec, $seen) = @_;
2602
2603   my $paths = {};
2604   return $paths unless ref $fromspec eq 'ARRAY';
2605
2606   for my $j (@$fromspec) {
2607
2608     next if ref $j ne 'ARRAY';
2609     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2610
2611     my $p = $paths;
2612     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2613     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2614   }
2615
2616   return $paths;
2617 }
2618
2619 sub _rollout_attr {
2620   my ($self, $attr) = @_;
2621
2622   if (ref $attr eq 'HASH') {
2623     return $self->_rollout_hash($attr);
2624   } elsif (ref $attr eq 'ARRAY') {
2625     return $self->_rollout_array($attr);
2626   } else {
2627     return [$attr];
2628   }
2629 }
2630
2631 sub _rollout_array {
2632   my ($self, $attr) = @_;
2633
2634   my @rolled_array;
2635   foreach my $element (@{$attr}) {
2636     if (ref $element eq 'HASH') {
2637       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2638     } elsif (ref $element eq 'ARRAY') {
2639       #  XXX - should probably recurse here
2640       push( @rolled_array, @{$self->_rollout_array($element)} );
2641     } else {
2642       push( @rolled_array, $element );
2643     }
2644   }
2645   return \@rolled_array;
2646 }
2647
2648 sub _rollout_hash {
2649   my ($self, $attr) = @_;
2650
2651   my @rolled_array;
2652   foreach my $key (keys %{$attr}) {
2653     push( @rolled_array, { $key => $attr->{$key} } );
2654   }
2655   return \@rolled_array;
2656 }
2657
2658 sub _calculate_score {
2659   my ($self, $a, $b) = @_;
2660
2661   if (ref $b eq 'HASH') {
2662     my ($b_key) = keys %{$b};
2663     if (ref $a eq 'HASH') {
2664       my ($a_key) = keys %{$a};
2665       if ($a_key eq $b_key) {
2666         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2667       } else {
2668         return 0;
2669       }
2670     } else {
2671       return ($a eq $b_key) ? 1 : 0;
2672     }
2673   } else {
2674     if (ref $a eq 'HASH') {
2675       my ($a_key) = keys %{$a};
2676       return ($b eq $a_key) ? 1 : 0;
2677     } else {
2678       return ($b eq $a) ? 1 : 0;
2679     }
2680   }
2681 }
2682
2683 sub _merge_attr {
2684   my ($self, $orig, $import) = @_;
2685
2686   return $import unless defined($orig);
2687   return $orig unless defined($import);
2688
2689   $orig = $self->_rollout_attr($orig);
2690   $import = $self->_rollout_attr($import);
2691
2692   my $seen_keys;
2693   foreach my $import_element ( @{$import} ) {
2694     # find best candidate from $orig to merge $b_element into
2695     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2696     foreach my $orig_element ( @{$orig} ) {
2697       my $score = $self->_calculate_score( $orig_element, $import_element );
2698       if ($score > $best_candidate->{score}) {
2699         $best_candidate->{position} = $position;
2700         $best_candidate->{score} = $score;
2701       }
2702       $position++;
2703     }
2704     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2705
2706     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2707       push( @{$orig}, $import_element );
2708     } else {
2709       my $orig_best = $orig->[$best_candidate->{position}];
2710       # merge orig_best and b_element together and replace original with merged
2711       if (ref $orig_best ne 'HASH') {
2712         $orig->[$best_candidate->{position}] = $import_element;
2713       } elsif (ref $import_element eq 'HASH') {
2714         my ($key) = keys %{$orig_best};
2715         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2716       }
2717     }
2718     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2719   }
2720
2721   return $orig;
2722 }
2723
2724 sub result_source {
2725     my $self = shift;
2726
2727     if (@_) {
2728         $self->_source_handle($_[0]->handle);
2729     } else {
2730         $self->_source_handle->resolve;
2731     }
2732 }
2733
2734 =head2 throw_exception
2735
2736 See L<DBIx::Class::Schema/throw_exception> for details.
2737
2738 =cut
2739
2740 sub throw_exception {
2741   my $self=shift;
2742   if (ref $self && $self->_source_handle->schema) {
2743     $self->_source_handle->schema->throw_exception(@_)
2744   } else {
2745     croak(@_);
2746   }
2747
2748 }
2749
2750 # XXX: FIXME: Attributes docs need clearing up
2751
2752 =head1 ATTRIBUTES
2753
2754 Attributes are used to refine a ResultSet in various ways when
2755 searching for data. They can be passed to any method which takes an
2756 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2757 L</count>.
2758
2759 These are in no particular order:
2760
2761 =head2 order_by
2762
2763 =over 4
2764
2765 =item Value: ( $order_by | \@order_by | \%order_by )
2766
2767 =back
2768
2769 Which column(s) to order the results by. If a single column name, or
2770 an arrayref of names is supplied, the argument is passed through
2771 directly to SQL. The hashref syntax allows for connection-agnostic
2772 specification of ordering direction:
2773
2774  For descending order:
2775
2776   order_by => { -desc => [qw/col1 col2 col3/] }
2777
2778  For explicit ascending order:
2779
2780   order_by => { -asc => 'col' }
2781
2782 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2783 supported, although you are strongly encouraged to use the hashref
2784 syntax as outlined above.
2785
2786 =head2 columns
2787
2788 =over 4
2789
2790 =item Value: \@columns
2791
2792 =back
2793
2794 Shortcut to request a particular set of columns to be retrieved. Each
2795 column spec may be a string (a table column name), or a hash (in which
2796 case the key is the C<as> value, and the value is used as the C<select>
2797 expression). Adds C<me.> onto the start of any column without a C<.> in
2798 it and sets C<select> from that, then auto-populates C<as> from
2799 C<select> as normal. (You may also use the C<cols> attribute, as in
2800 earlier versions of DBIC.)
2801
2802 =head2 +columns
2803
2804 =over 4
2805
2806 =item Value: \@columns
2807
2808 =back
2809
2810 Indicates additional columns to be selected from storage. Works the same
2811 as L</columns> but adds columns to the selection. (You may also use the
2812 C<include_columns> attribute, as in earlier versions of DBIC). For
2813 example:-
2814
2815   $schema->resultset('CD')->search(undef, {
2816     '+columns' => ['artist.name'],
2817     join => ['artist']
2818   });
2819
2820 would return all CDs and include a 'name' column to the information
2821 passed to object inflation. Note that the 'artist' is the name of the
2822 column (or relationship) accessor, and 'name' is the name of the column
2823 accessor in the related table.
2824
2825 =head2 include_columns
2826
2827 =over 4
2828
2829 =item Value: \@columns
2830
2831 =back
2832
2833 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2834
2835 =head2 select
2836
2837 =over 4
2838
2839 =item Value: \@select_columns
2840
2841 =back
2842
2843 Indicates which columns should be selected from the storage. You can use
2844 column names, or in the case of RDBMS back ends, function or stored procedure
2845 names:
2846
2847   $rs = $schema->resultset('Employee')->search(undef, {
2848     select => [
2849       'name',
2850       { count => 'employeeid' },
2851       { sum => 'salary' }
2852     ]
2853   });
2854
2855 When you use function/stored procedure names and do not supply an C<as>
2856 attribute, the column names returned are storage-dependent. E.g. MySQL would
2857 return a column named C<count(employeeid)> in the above example.
2858
2859 =head2 +select
2860
2861 =over 4
2862
2863 Indicates additional columns to be selected from storage.  Works the same as
2864 L</select> but adds columns to the selection.
2865
2866 =back
2867
2868 =head2 +as
2869
2870 =over 4
2871
2872 Indicates additional column names for those added via L</+select>. See L</as>.
2873
2874 =back
2875
2876 =head2 as
2877
2878 =over 4
2879
2880 =item Value: \@inflation_names
2881
2882 =back
2883
2884 Indicates column names for object inflation. That is, C<as>
2885 indicates the name that the column can be accessed as via the
2886 C<get_column> method (or via the object accessor, B<if one already
2887 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2888
2889 The C<as> attribute is used in conjunction with C<select>,
2890 usually when C<select> contains one or more function or stored
2891 procedure names:
2892
2893   $rs = $schema->resultset('Employee')->search(undef, {
2894     select => [
2895       'name',
2896       { count => 'employeeid' }
2897     ],
2898     as => ['name', 'employee_count'],
2899   });
2900
2901   my $employee = $rs->first(); # get the first Employee
2902
2903 If the object against which the search is performed already has an accessor
2904 matching a column name specified in C<as>, the value can be retrieved using
2905 the accessor as normal:
2906
2907   my $name = $employee->name();
2908
2909 If on the other hand an accessor does not exist in the object, you need to
2910 use C<get_column> instead:
2911
2912   my $employee_count = $employee->get_column('employee_count');
2913
2914 You can create your own accessors if required - see
2915 L<DBIx::Class::Manual::Cookbook> for details.
2916
2917 Please note: This will NOT insert an C<AS employee_count> into the SQL
2918 statement produced, it is used for internal access only. Thus
2919 attempting to use the accessor in an C<order_by> clause or similar
2920 will fail miserably.
2921
2922 To get around this limitation, you can supply literal SQL to your
2923 C<select> attibute that contains the C<AS alias> text, eg:
2924
2925   select => [\'myfield AS alias']
2926
2927 =head2 join
2928
2929 =over 4
2930
2931 =item Value: ($rel_name | \@rel_names | \%rel_names)
2932
2933 =back
2934
2935 Contains a list of relationships that should be joined for this query.  For
2936 example:
2937
2938   # Get CDs by Nine Inch Nails
2939   my $rs = $schema->resultset('CD')->search(
2940     { 'artist.name' => 'Nine Inch Nails' },
2941     { join => 'artist' }
2942   );
2943
2944 Can also contain a hash reference to refer to the other relation's relations.
2945 For example:
2946
2947   package MyApp::Schema::Track;
2948   use base qw/DBIx::Class/;
2949   __PACKAGE__->table('track');
2950   __PACKAGE__->add_columns(qw/trackid cd position title/);
2951   __PACKAGE__->set_primary_key('trackid');
2952   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2953   1;
2954
2955   # In your application
2956   my $rs = $schema->resultset('Artist')->search(
2957     { 'track.title' => 'Teardrop' },
2958     {
2959       join     => { cd => 'track' },
2960       order_by => 'artist.name',
2961     }
2962   );
2963
2964 You need to use the relationship (not the table) name in  conditions,
2965 because they are aliased as such. The current table is aliased as "me", so
2966 you need to use me.column_name in order to avoid ambiguity. For example:
2967
2968   # Get CDs from 1984 with a 'Foo' track
2969   my $rs = $schema->resultset('CD')->search(
2970     {
2971       'me.year' => 1984,
2972       'tracks.name' => 'Foo'
2973     },
2974     { join => 'tracks' }
2975   );
2976
2977 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2978 similarly for a third time). For e.g.
2979
2980   my $rs = $schema->resultset('Artist')->search({
2981     'cds.title'   => 'Down to Earth',
2982     'cds_2.title' => 'Popular',
2983   }, {
2984     join => [ qw/cds cds/ ],
2985   });
2986
2987 will return a set of all artists that have both a cd with title 'Down
2988 to Earth' and a cd with title 'Popular'.
2989
2990 If you want to fetch related objects from other tables as well, see C<prefetch>
2991 below.
2992
2993 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2994
2995 =head2 prefetch
2996
2997 =over 4
2998
2999 =item Value: ($rel_name | \@rel_names | \%rel_names)
3000
3001 =back
3002
3003 Contains one or more relationships that should be fetched along with
3004 the main query (when they are accessed afterwards the data will
3005 already be available, without extra queries to the database).  This is
3006 useful for when you know you will need the related objects, because it
3007 saves at least one query:
3008
3009   my $rs = $schema->resultset('Tag')->search(
3010     undef,
3011     {
3012       prefetch => {
3013         cd => 'artist'
3014       }
3015     }
3016   );
3017
3018 The initial search results in SQL like the following:
3019
3020   SELECT tag.*, cd.*, artist.* FROM tag
3021   JOIN cd ON tag.cd = cd.cdid
3022   JOIN artist ON cd.artist = artist.artistid
3023
3024 L<DBIx::Class> has no need to go back to the database when we access the
3025 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3026 case.
3027
3028 Simple prefetches will be joined automatically, so there is no need
3029 for a C<join> attribute in the above search.
3030
3031 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3032 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3033 with an accessor type of 'single' or 'filter'). A more complex example that
3034 prefetches an artists cds, the tracks on those cds, and the tags associted
3035 with that artist is given below (assuming many-to-many from artists to tags):
3036
3037  my $rs = $schema->resultset('Artist')->search(
3038    undef,
3039    {
3040      prefetch => [
3041        { cds => 'tracks' },
3042        { artist_tags => 'tags' }
3043      ]
3044    }
3045  );
3046
3047
3048 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3049 attributes will be ignored.
3050
3051 =head2 page
3052
3053 =over 4
3054
3055 =item Value: $page
3056
3057 =back
3058
3059 Makes the resultset paged and specifies the page to retrieve. Effectively
3060 identical to creating a non-pages resultset and then calling ->page($page)
3061 on it.
3062
3063 If L<rows> attribute is not specified it defualts to 10 rows per page.
3064
3065 When you have a paged resultset, L</count> will only return the number
3066 of rows in the page. To get the total, use the L</pager> and call
3067 C<total_entries> on it.
3068
3069 =head2 rows
3070
3071 =over 4
3072
3073 =item Value: $rows
3074
3075 =back
3076
3077 Specifes the maximum number of rows for direct retrieval or the number of
3078 rows per page if the page attribute or method is used.
3079
3080 =head2 offset
3081
3082 =over 4
3083
3084 =item Value: $offset
3085
3086 =back
3087
3088 Specifies the (zero-based) row number for the  first row to be returned, or the
3089 of the first row of the first page if paging is used.
3090
3091 =head2 group_by
3092
3093 =over 4
3094
3095 =item Value: \@columns
3096
3097 =back
3098
3099 A arrayref of columns to group by. Can include columns of joined tables.
3100
3101   group_by => [qw/ column1 column2 ... /]
3102
3103 =head2 having
3104
3105 =over 4
3106
3107 =item Value: $condition
3108
3109 =back
3110
3111 HAVING is a select statement attribute that is applied between GROUP BY and
3112 ORDER BY. It is applied to the after the grouping calculations have been
3113 done.
3114
3115   having => { 'count(employee)' => { '>=', 100 } }
3116
3117 =head2 distinct
3118
3119 =over 4
3120
3121 =item Value: (0 | 1)
3122
3123 =back
3124
3125 Set to 1 to group by all columns.
3126
3127 =head2 where
3128
3129 =over 4
3130
3131 Adds to the WHERE clause.
3132
3133   # only return rows WHERE deleted IS NULL for all searches
3134   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3135
3136 Can be overridden by passing C<{ where => undef }> as an attribute
3137 to a resulset.
3138
3139 =back
3140
3141 =head2 cache
3142
3143 Set to 1 to cache search results. This prevents extra SQL queries if you
3144 revisit rows in your ResultSet:
3145
3146   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3147
3148   while( my $artist = $resultset->next ) {
3149     ... do stuff ...
3150   }
3151
3152   $rs->first; # without cache, this would issue a query
3153
3154 By default, searches are not cached.
3155
3156 For more examples of using these attributes, see
3157 L<DBIx::Class::Manual::Cookbook>.
3158
3159 =head2 from
3160
3161 =over 4
3162
3163 =item Value: \@from_clause
3164
3165 =back
3166
3167 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3168 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3169 clauses.
3170
3171 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3172
3173 C<join> will usually do what you need and it is strongly recommended that you
3174 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3175 And we really do mean "cannot", not just tried and failed. Attempting to use
3176 this because you're having problems with C<join> is like trying to use x86
3177 ASM because you've got a syntax error in your C. Trust us on this.
3178
3179 Now, if you're still really, really sure you need to use this (and if you're
3180 not 100% sure, ask the mailing list first), here's an explanation of how this
3181 works.
3182
3183 The syntax is as follows -
3184
3185   [
3186     { <alias1> => <table1> },
3187     [
3188       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3189       [], # nested JOIN (optional)
3190       { <table1.column1> => <table2.column2>, ... (more conditions) },
3191     ],
3192     # More of the above [ ] may follow for additional joins
3193   ]
3194
3195   <table1> <alias1>
3196   JOIN
3197     <table2> <alias2>
3198     [JOIN ...]
3199   ON <table1.column1> = <table2.column2>
3200   <more joins may follow>
3201
3202 An easy way to follow the examples below is to remember the following:
3203
3204     Anything inside "[]" is a JOIN
3205     Anything inside "{}" is a condition for the enclosing JOIN
3206
3207 The following examples utilize a "person" table in a family tree application.
3208 In order to express parent->child relationships, this table is self-joined:
3209
3210     # Person->belongs_to('father' => 'Person');
3211     # Person->belongs_to('mother' => 'Person');
3212
3213 C<from> can be used to nest joins. Here we return all children with a father,
3214 then search against all mothers of those children:
3215
3216   $rs = $schema->resultset('Person')->search(
3217       undef,
3218       {
3219           alias => 'mother', # alias columns in accordance with "from"
3220           from => [
3221               { mother => 'person' },
3222               [
3223                   [
3224                       { child => 'person' },
3225                       [
3226                           { father => 'person' },
3227                           { 'father.person_id' => 'child.father_id' }
3228                       ]
3229                   ],
3230                   { 'mother.person_id' => 'child.mother_id' }
3231               ],
3232           ]
3233       },
3234   );
3235
3236   # Equivalent SQL:
3237   # SELECT mother.* FROM person mother
3238   # JOIN (
3239   #   person child
3240   #   JOIN person father
3241   #   ON ( father.person_id = child.father_id )
3242   # )
3243   # ON ( mother.person_id = child.mother_id )
3244
3245 The type of any join can be controlled manually. To search against only people
3246 with a father in the person table, we could explicitly use C<INNER JOIN>:
3247
3248     $rs = $schema->resultset('Person')->search(
3249         undef,
3250         {
3251             alias => 'child', # alias columns in accordance with "from"
3252             from => [
3253                 { child => 'person' },
3254                 [
3255                     { father => 'person', -join_type => 'inner' },
3256                     { 'father.id' => 'child.father_id' }
3257                 ],
3258             ]
3259         },
3260     );
3261
3262     # Equivalent SQL:
3263     # SELECT child.* FROM person child
3264     # INNER JOIN person father ON child.father_id = father.id
3265
3266 If you need to express really complex joins or you need a subselect, you
3267 can supply literal SQL to C<from> via a scalar reference. In this case
3268 the contents of the scalar will replace the table name asscoiated with the
3269 resultsource.
3270
3271 WARNING: This technique might very well not work as expected on chained
3272 searches - you have been warned.
3273
3274     # Assuming the Event resultsource is defined as:
3275
3276         MySchema::Event->add_columns (
3277             sequence => {
3278                 data_type => 'INT',
3279                 is_auto_increment => 1,
3280             },
3281             location => {
3282                 data_type => 'INT',
3283             },
3284             type => {
3285                 data_type => 'INT',
3286             },
3287         );
3288         MySchema::Event->set_primary_key ('sequence');
3289
3290     # This will get back the latest event for every location. The column
3291     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3292     # combo to limit the resultset
3293
3294     $rs = $schema->resultset('Event');
3295     $table = $rs->result_source->name;
3296     $latest = $rs->search (
3297         undef,
3298         { from => \ "
3299             (SELECT e1.* FROM $table e1
3300                 JOIN $table e2
3301                     ON e1.location = e2.location
3302                     AND e1.sequence < e2.sequence
3303                 WHERE e2.sequence is NULL
3304             ) me",
3305         },
3306     );
3307
3308     # Equivalent SQL (with the DBIC chunks added):
3309
3310     SELECT me.sequence, me.location, me.type FROM
3311        (SELECT e1.* FROM events e1
3312            JOIN events e2
3313                ON e1.location = e2.location
3314                AND e1.sequence < e2.sequence
3315            WHERE e2.sequence is NULL
3316        ) me;
3317
3318 =head2 for
3319
3320 =over 4
3321
3322 =item Value: ( 'update' | 'shared' )
3323
3324 =back
3325
3326 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3327 ... FOR SHARED.
3328
3329 =cut
3330
3331 1;