lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360
 361   $rs->set_cache($rows) if ($rows);
 362
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   my @copy = @$row;
 978
 979   # 'foo'         => [ undef, 'foo' ]
 980   # 'foo.bar'     => [ 'foo', 'bar' ]
 981   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 982
 983   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 984
 985   my %collapse = %{$self->{_attrs}{collapse}||{}};
 986
 987   my @pri_index;
 988
 989   # if we're doing collapsing (has_many prefetch) we need to grab records
 990   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 991   # we know we don't have to bother.
 992
 993   # the reason for not using the collapse stuff directly is because if you
 994   # had for e.g. two artists in a row with no cds, the collapse info for
 995   # both would be NULL (undef) so you'd lose the second artist
 996
 997   # store just the index so we can check the array positions from the row
 998   # without having to contruct the full hash
 999
1000   if (keys %collapse) {
1001     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1002     foreach my $i (0 .. $#construct_as) {
1003       next if defined($construct_as[$i][0]); # only self table
1004       if (delete $pri{$construct_as[$i][1]}) {
1005         push(@pri_index, $i);
1006       }
1007       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1008     }
1009   }
1010
1011   # no need to do an if, it'll be empty if @pri_index is empty anyway
1012
1013   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1014
1015   my @const_rows;
1016
1017   do { # no need to check anything at the front, we always want the first row
1018
1019     my %const;
1020
1021     foreach my $this_as (@construct_as) {
1022       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1023     }
1024
1025     push(@const_rows, \%const);
1026
1027   } until ( # no pri_index => no collapse => drop straight out
1028       !@pri_index
1029     or
1030       do { # get another row, stash it, drop out if different PK
1031
1032         @copy = $self->cursor->next;
1033         $self->{stashed_row} = \@copy;
1034
1035         # last thing in do block, counts as true if anything doesn't match
1036
1037         # check xor defined first for NULL vs. NOT NULL then if one is
1038         # defined the other must be so check string equality
1039
1040         grep {
1041           (defined $pri_vals{$_} ^ defined $copy[$_])
1042           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1043         } @pri_index;
1044       }
1045   );
1046
1047   my $alias = $self->{attrs}{alias};
1048   my $info = [];
1049
1050   my %collapse_pos;
1051
1052   my @const_keys;
1053
1054   foreach my $const (@const_rows) {
1055     scalar @const_keys or do {
1056       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1057     };
1058     foreach my $key (@const_keys) {
1059       if (length $key) {
1060         my $target = $info;
1061         my @parts = split(/\./, $key);
1062         my $cur = '';
1063         my $data = $const->{$key};
1064         foreach my $p (@parts) {
1065           $target = $target->[1]->{$p} ||= [];
1066           $cur .= ".${p}";
1067           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1068             # collapsing at this point and on final part
1069             my $pos = $collapse_pos{$cur};
1070             CK: foreach my $ck (@ckey) {
1071               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1072                 $collapse_pos{$cur} = $data;
1073                 delete @collapse_pos{ # clear all positioning for sub-entries
1074                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1075                 };
1076                 push(@$target, []);
1077                 last CK;
1078               }
1079             }
1080           }
1081           if (exists $collapse{$cur}) {
1082             $target = $target->[-1];
1083           }
1084         }
1085         $target->[0] = $data;
1086       } else {
1087         $info->[0] = $const->{$key};
1088       }
1089     }
1090   }
1091
1092   return $info;
1093 }
1094
1095 =head2 result_source
1096
1097 =over 4
1098
1099 =item Arguments: $result_source?
1100
1101 =item Return Value: $result_source
1102
1103 =back
1104
1105 An accessor for the primary ResultSource object from which this ResultSet
1106 is derived.
1107
1108 =head2 result_class
1109
1110 =over 4
1111
1112 =item Arguments: $result_class?
1113
1114 =item Return Value: $result_class
1115
1116 =back
1117
1118 An accessor for the class to use when creating row objects. Defaults to
1119 C<< result_source->result_class >> - which in most cases is the name of the
1120 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1121
1122 Note that changing the result_class will also remove any components
1123 that were originally loaded in the source class via
1124 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1125 in the original source class will not run.
1126
1127 =cut
1128
1129 sub result_class {
1130   my ($self, $result_class) = @_;
1131   if ($result_class) {
1132     $self->ensure_class_loaded($result_class);
1133     $self->_result_class($result_class);
1134   }
1135   $self->_result_class;
1136 }
1137
1138 =head2 count
1139
1140 =over 4
1141
1142 =item Arguments: $cond, \%attrs??
1143
1144 =item Return Value: $count
1145
1146 =back
1147
1148 Performs an SQL C<COUNT> with the same query as the resultset was built
1149 with to find the number of elements. Passing arguments is equivalent to
1150 C<< $rs->search ($cond, \%attrs)->count >>
1151
1152 =cut
1153
1154 sub count {
1155   my $self = shift;
1156   return $self->search(@_)->count if @_ and defined $_[0];
1157   return scalar @{ $self->get_cache } if $self->get_cache;
1158
1159   my $attrs = $self->_resolved_attrs_copy;
1160
1161   # this is a little optimization - it is faster to do the limit
1162   # adjustments in software, instead of a subquery
1163   my $rows = delete $attrs->{rows};
1164   my $offset = delete $attrs->{offset};
1165
1166   my $crs;
1167   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1168     $crs = $self->_count_subq_rs ($attrs);
1169   }
1170   else {
1171     $crs = $self->_count_rs ($attrs);
1172   }
1173   my $count = $crs->next;
1174
1175   $count -= $offset if $offset;
1176   $count = $rows if $rows and $rows < $count;
1177   $count = 0 if ($count < 0);
1178
1179   return $count;
1180 }
1181
1182 =head2 count_rs
1183
1184 =over 4
1185
1186 =item Arguments: $cond, \%attrs??
1187
1188 =item Return Value: $count_rs
1189
1190 =back
1191
1192 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1193 This can be very handy for subqueries:
1194
1195   ->search( { amount => $some_rs->count_rs->as_query } )
1196
1197 As with regular resultsets the SQL query will be executed only after
1198 the resultset is accessed via L</next> or L</all>. That would return
1199 the same single value obtainable via L</count>.
1200
1201 =cut
1202
1203 sub count_rs {
1204   my $self = shift;
1205   return $self->search(@_)->count_rs if @_;
1206
1207   # this may look like a lack of abstraction (count() does about the same)
1208   # but in fact an _rs *must* use a subquery for the limits, as the
1209   # software based limiting can not be ported if this $rs is to be used
1210   # in a subquery itself (i.e. ->as_query)
1211   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1212     return $self->_count_subq_rs;
1213   }
1214   else {
1215     return $self->_count_rs;
1216   }
1217 }
1218
1219 #
1220 # returns a ResultSetColumn object tied to the count query
1221 #
1222 sub _count_rs {
1223   my ($self, $attrs) = @_;
1224
1225   my $rsrc = $self->result_source;
1226   $attrs ||= $self->_resolved_attrs;
1227
1228   my $tmp_attrs = { %$attrs };
1229
1230   # take off any limits, record_filter is cdbi, and no point of ordering a count
1231   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1232
1233   # overwrite the selector (supplied by the storage)
1234   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1235   $tmp_attrs->{as} = 'count';
1236
1237   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1238
1239   return $tmp_rs;
1240 }
1241
1242 #
1243 # same as above but uses a subquery
1244 #
1245 sub _count_subq_rs {
1246   my ($self, $attrs) = @_;
1247
1248   my $rsrc = $self->result_source;
1249   $attrs ||= $self->_resolved_attrs_copy;
1250
1251   my $sub_attrs = { %$attrs };
1252
1253   # extra selectors do not go in the subquery and there is no point of ordering it
1254   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1255
1256   # if we multi-prefetch we group_by primary keys only as this is what we would
1257   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1258   if ( keys %{$attrs->{collapse}}  ) {
1259     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1260   }
1261
1262   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1263
1264   # this is so that the query can be simplified e.g.
1265   # * ordering can be thrown away in things like Top limit
1266   $sub_attrs->{-for_count_only} = 1;
1267
1268   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1269
1270   $attrs->{from} = [{
1271     -alias => 'count_subq',
1272     -source_handle => $rsrc->handle,
1273     count_subq => $sub_rs->as_query,
1274   }];
1275
1276   # the subquery replaces this
1277   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1278
1279   return $self->_count_rs ($attrs);
1280 }
1281
1282 sub _bool {
1283   return 1;
1284 }
1285
1286 =head2 count_literal
1287
1288 =over 4
1289
1290 =item Arguments: $sql_fragment, @bind_values
1291
1292 =item Return Value: $count
1293
1294 =back
1295
1296 Counts the results in a literal query. Equivalent to calling L</search_literal>
1297 with the passed arguments, then L</count>.
1298
1299 =cut
1300
1301 sub count_literal { shift->search_literal(@_)->count; }
1302
1303 =head2 all
1304
1305 =over 4
1306
1307 =item Arguments: none
1308
1309 =item Return Value: @objects
1310
1311 =back
1312
1313 Returns all elements in the resultset. Called implicitly if the resultset
1314 is returned in list context.
1315
1316 =cut
1317
1318 sub all {
1319   my $self = shift;
1320   if(@_) {
1321       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1322   }
1323
1324   return @{ $self->get_cache } if $self->get_cache;
1325
1326   my @obj;
1327
1328   if (keys %{$self->_resolved_attrs->{collapse}}) {
1329     # Using $self->cursor->all is really just an optimisation.
1330     # If we're collapsing has_many prefetches it probably makes
1331     # very little difference, and this is cleaner than hacking
1332     # _construct_object to survive the approach
1333     $self->cursor->reset;
1334     my @row = $self->cursor->next;
1335     while (@row) {
1336       push(@obj, $self->_construct_object(@row));
1337       @row = (exists $self->{stashed_row}
1338                ? @{delete $self->{stashed_row}}
1339                : $self->cursor->next);
1340     }
1341   } else {
1342     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1343   }
1344
1345   $self->set_cache(\@obj) if $self->{attrs}{cache};
1346
1347   return @obj;
1348 }
1349
1350 =head2 reset
1351
1352 =over 4
1353
1354 =item Arguments: none
1355
1356 =item Return Value: $self
1357
1358 =back
1359
1360 Resets the resultset's cursor, so you can iterate through the elements again.
1361 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1362 another query.
1363
1364 =cut
1365
1366 sub reset {
1367   my ($self) = @_;
1368   delete $self->{_attrs} if exists $self->{_attrs};
1369   $self->{all_cache_position} = 0;
1370   $self->cursor->reset;
1371   return $self;
1372 }
1373
1374 =head2 first
1375
1376 =over 4
1377
1378 =item Arguments: none
1379
1380 =item Return Value: $object?
1381
1382 =back
1383
1384 Resets the resultset and returns an object for the first result (if the
1385 resultset returns anything).
1386
1387 =cut
1388
1389 sub first {
1390   return $_[0]->reset->next;
1391 }
1392
1393
1394 # _rs_update_delete
1395 #
1396 # Determines whether and what type of subquery is required for the $rs operation.
1397 # If grouping is necessary either supplies its own, or verifies the current one
1398 # After all is done delegates to the proper storage method.
1399
1400 sub _rs_update_delete {
1401   my ($self, $op, $values) = @_;
1402
1403   my $rsrc = $self->result_source;
1404
1405   # if a condition exists we need to strip all table qualifiers
1406   # if this is not possible we'll force a subquery below
1407   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1408
1409   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1410   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/row offset/);
1411
1412   if ($needs_group_by_subq or $needs_subq) {
1413
1414     # make a new $rs selecting only the PKs (that's all we really need)
1415     my $attrs = $self->_resolved_attrs_copy;
1416
1417     delete $attrs->{$_} for qw/collapse select as/;
1418     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1419
1420     if ($needs_group_by_subq) {
1421       # make sure no group_by was supplied, or if there is one - make sure it matches
1422       # the columns compiled above perfectly. Anything else can not be sanely executed
1423       # on most databases so croak right then and there
1424
1425       if (my $g = $attrs->{group_by}) {
1426         my @current_group_by = map
1427           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1428           @$g
1429         ;
1430
1431         if (
1432           join ("\x00", sort @current_group_by)
1433             ne
1434           join ("\x00", sort @{$attrs->{columns}} )
1435         ) {
1436           $self->throw_exception (
1437             "You have just attempted a $op operation on a resultset which does group_by"
1438             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1439             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1440             . ' kind of queries. Please retry the operation with a modified group_by or'
1441             . ' without using one at all.'
1442           );
1443         }
1444       }
1445       else {
1446         $attrs->{group_by} = $attrs->{columns};
1447       }
1448     }
1449
1450     my $subrs = (ref $self)->new($rsrc, $attrs);
1451
1452     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1453   }
1454   else {
1455     return $rsrc->storage->$op(
1456       $rsrc,
1457       $op eq 'update' ? $values : (),
1458       $cond,
1459     );
1460   }
1461 }
1462
1463 =head2 update
1464
1465 =over 4
1466
1467 =item Arguments: \%values
1468
1469 =item Return Value: $storage_rv
1470
1471 =back
1472
1473 Sets the specified columns in the resultset to the supplied values in a
1474 single query. Return value will be true if the update succeeded or false
1475 if no records were updated; exact type of success value is storage-dependent.
1476
1477 =cut
1478
1479 sub update {
1480   my ($self, $values) = @_;
1481   $self->throw_exception('Values for update must be a hash')
1482     unless ref $values eq 'HASH';
1483
1484   return $self->_rs_update_delete ('update', $values);
1485 }
1486
1487 =head2 update_all
1488
1489 =over 4
1490
1491 =item Arguments: \%values
1492
1493 =item Return Value: 1
1494
1495 =back
1496
1497 Fetches all objects and updates them one at a time. Note that C<update_all>
1498 will run DBIC cascade triggers, while L</update> will not.
1499
1500 =cut
1501
1502 sub update_all {
1503   my ($self, $values) = @_;
1504   $self->throw_exception('Values for update_all must be a hash')
1505     unless ref $values eq 'HASH';
1506   foreach my $obj ($self->all) {
1507     $obj->set_columns($values)->update;
1508   }
1509   return 1;
1510 }
1511
1512 =head2 delete
1513
1514 =over 4
1515
1516 =item Arguments: none
1517
1518 =item Return Value: $storage_rv
1519
1520 =back
1521
1522 Deletes the contents of the resultset from its result source. Note that this
1523 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1524 to run. See also L<DBIx::Class::Row/delete>.
1525
1526 Return value will be the amount of rows deleted; exact type of return value
1527 is storage-dependent.
1528
1529 =cut
1530
1531 sub delete {
1532   my $self = shift;
1533   $self->throw_exception('delete does not accept any arguments')
1534     if @_;
1535
1536   return $self->_rs_update_delete ('delete');
1537 }
1538
1539 =head2 delete_all
1540
1541 =over 4
1542
1543 =item Arguments: none
1544
1545 =item Return Value: 1
1546
1547 =back
1548
1549 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1550 will run DBIC cascade triggers, while L</delete> will not.
1551
1552 =cut
1553
1554 sub delete_all {
1555   my $self = shift;
1556   $self->throw_exception('delete_all does not accept any arguments')
1557     if @_;
1558
1559   $_->delete for $self->all;
1560   return 1;
1561 }
1562
1563 =head2 populate
1564
1565 =over 4
1566
1567 =item Arguments: \@data;
1568
1569 =back
1570
1571 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1572 For the arrayref of hashrefs style each hashref should be a structure suitable
1573 forsubmitting to a $resultset->create(...) method.
1574
1575 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1576 to insert the data, as this is a faster method.
1577
1578 Otherwise, each set of data is inserted into the database using
1579 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1580 accumulated into an array. The array itself, or an array reference
1581 is returned depending on scalar or list context.
1582
1583 Example:  Assuming an Artist Class that has many CDs Classes relating:
1584
1585   my $Artist_rs = $schema->resultset("Artist");
1586
1587   ## Void Context Example
1588   $Artist_rs->populate([
1589      { artistid => 4, name => 'Manufactured Crap', cds => [
1590         { title => 'My First CD', year => 2006 },
1591         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1592       ],
1593      },
1594      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1595         { title => 'My parents sold me to a record company' ,year => 2005 },
1596         { title => 'Why Am I So Ugly?', year => 2006 },
1597         { title => 'I Got Surgery and am now Popular', year => 2007 }
1598       ],
1599      },
1600   ]);
1601
1602   ## Array Context Example
1603   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1604     { name => "Artist One"},
1605     { name => "Artist Two"},
1606     { name => "Artist Three", cds=> [
1607     { title => "First CD", year => 2007},
1608     { title => "Second CD", year => 2008},
1609   ]}
1610   ]);
1611
1612   print $ArtistOne->name; ## response is 'Artist One'
1613   print $ArtistThree->cds->count ## reponse is '2'
1614
1615 For the arrayref of arrayrefs style,  the first element should be a list of the
1616 fieldsnames to which the remaining elements are rows being inserted.  For
1617 example:
1618
1619   $Arstist_rs->populate([
1620     [qw/artistid name/],
1621     [100, 'A Formally Unknown Singer'],
1622     [101, 'A singer that jumped the shark two albums ago'],
1623     [102, 'An actually cool singer.'],
1624   ]);
1625
1626 Please note an important effect on your data when choosing between void and
1627 wantarray context. Since void context goes straight to C<insert_bulk> in
1628 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1629 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1630 create primary keys for you, you will find that your PKs are empty.  In this
1631 case you will have to use the wantarray context in order to create those
1632 values.
1633
1634 =cut
1635
1636 sub populate {
1637   my $self = shift;
1638
1639   # cruft placed in standalone method
1640   my $data = $self->_normalize_populate_args(@_);
1641
1642   if(defined wantarray) {
1643     my @created;
1644     foreach my $item (@$data) {
1645       push(@created, $self->create($item));
1646     }
1647     return wantarray ? @created : \@created;
1648   } else {
1649     my $first = $data->[0];
1650
1651     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1652     # it relationship data
1653     my (@rels, @columns);
1654     for (keys %$first) {
1655       my $ref = ref $first->{$_};
1656       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1657         ? push @rels, $_
1658         : push @columns, $_
1659       ;
1660     }
1661
1662     my @pks = $self->result_source->primary_columns;
1663
1664     ## do the belongs_to relationships
1665     foreach my $index (0..$#$data) {
1666
1667       # delegate to create() for any dataset without primary keys with specified relationships
1668       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1669         for my $r (@rels) {
1670           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1671             my @ret = $self->populate($data);
1672             return;
1673           }
1674         }
1675       }
1676
1677       foreach my $rel (@rels) {
1678         next unless ref $data->[$index]->{$rel} eq "HASH";
1679         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1680         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1681         my $related = $result->result_source->_resolve_condition(
1682           $result->result_source->relationship_info($reverse)->{cond},
1683           $self,
1684           $result,
1685         );
1686
1687         delete $data->[$index]->{$rel};
1688         $data->[$index] = {%{$data->[$index]}, %$related};
1689
1690         push @columns, keys %$related if $index == 0;
1691       }
1692     }
1693
1694     ## inherit the data locked in the conditions of the resultset
1695     my ($rs_data) = $self->_merge_cond_with_data({});
1696     delete @{$rs_data}{@columns};
1697     my @inherit_cols = keys %$rs_data;
1698     my @inherit_data = values %$rs_data;
1699
1700     ## do bulk insert on current row
1701     $self->result_source->storage->insert_bulk(
1702       $self->result_source,
1703       [@columns, @inherit_cols],
1704       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1705     );
1706
1707     ## do the has_many relationships
1708     foreach my $item (@$data) {
1709
1710       foreach my $rel (@rels) {
1711         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1712
1713         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1714      || $self->throw_exception('Cannot find the relating object.');
1715
1716         my $child = $parent->$rel;
1717
1718         my $related = $child->result_source->_resolve_condition(
1719           $parent->result_source->relationship_info($rel)->{cond},
1720           $child,
1721           $parent,
1722         );
1723
1724         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1725         my @populate = map { {%$_, %$related} } @rows_to_add;
1726
1727         $child->populate( \@populate );
1728       }
1729     }
1730   }
1731 }
1732
1733
1734 # populate() argumnets went over several incarnations
1735 # What we ultimately support is AoH
1736 sub _normalize_populate_args {
1737   my ($self, $arg) = @_;
1738
1739   if (ref $arg eq 'ARRAY') {
1740     if (ref $arg->[0] eq 'HASH') {
1741       return $arg;
1742     }
1743     elsif (ref $arg->[0] eq 'ARRAY') {
1744       my @ret;
1745       my @colnames = @{$arg->[0]};
1746       foreach my $values (@{$arg}[1 .. $#$arg]) {
1747         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
1748       }
1749       return \@ret;
1750     }
1751   }
1752
1753   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
1754 }
1755
1756 =head2 pager
1757
1758 =over 4
1759
1760 =item Arguments: none
1761
1762 =item Return Value: $pager
1763
1764 =back
1765
1766 Return Value a L<Data::Page> object for the current resultset. Only makes
1767 sense for queries with a C<page> attribute.
1768
1769 To get the full count of entries for a paged resultset, call
1770 C<total_entries> on the L<Data::Page> object.
1771
1772 =cut
1773
1774 sub pager {
1775   my ($self) = @_;
1776
1777   return $self->{pager} if $self->{pager};
1778
1779   my $attrs = $self->{attrs};
1780   $self->throw_exception("Can't create pager for non-paged rs")
1781     unless $self->{attrs}{page};
1782   $attrs->{rows} ||= 10;
1783
1784   # throw away the paging flags and re-run the count (possibly
1785   # with a subselect) to get the real total count
1786   my $count_attrs = { %$attrs };
1787   delete $count_attrs->{$_} for qw/rows offset page pager/;
1788   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1789
1790   return $self->{pager} = Data::Page->new(
1791     $total_count,
1792     $attrs->{rows},
1793     $self->{attrs}{page}
1794   );
1795 }
1796
1797 =head2 page
1798
1799 =over 4
1800
1801 =item Arguments: $page_number
1802
1803 =item Return Value: $rs
1804
1805 =back
1806
1807 Returns a resultset for the $page_number page of the resultset on which page
1808 is called, where each page contains a number of rows equal to the 'rows'
1809 attribute set on the resultset (10 by default).
1810
1811 =cut
1812
1813 sub page {
1814   my ($self, $page) = @_;
1815   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1816 }
1817
1818 =head2 new_result
1819
1820 =over 4
1821
1822 =item Arguments: \%vals
1823
1824 =item Return Value: $rowobject
1825
1826 =back
1827
1828 Creates a new row object in the resultset's result class and returns
1829 it. The row is not inserted into the database at this point, call
1830 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1831 will tell you whether the row object has been inserted or not.
1832
1833 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1834
1835 =cut
1836
1837 sub new_result {
1838   my ($self, $values) = @_;
1839   $self->throw_exception( "new_result needs a hash" )
1840     unless (ref $values eq 'HASH');
1841
1842   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
1843
1844   my %new = (
1845     %$merged_cond,
1846     @$cols_from_relations
1847       ? (-cols_from_relations => $cols_from_relations)
1848       : (),
1849     -source_handle => $self->_source_handle,
1850     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1851   );
1852
1853   return $self->result_class->new(\%new);
1854 }
1855
1856 # _merge_cond_with_data
1857 #
1858 # Takes a simple hash of K/V data and returns its copy merged with the
1859 # condition already present on the resultset. Additionally returns an
1860 # arrayref of value/condition names, which were inferred from related
1861 # objects (this is needed for in-memory related objects)
1862 sub _merge_cond_with_data {
1863   my ($self, $data) = @_;
1864
1865   my (%new_data, @cols_from_relations);
1866
1867   my $alias = $self->{attrs}{alias};
1868
1869   if (! defined $self->{cond}) {
1870     # just massage $data below
1871   }
1872   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
1873     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1874     @cols_from_relations = keys %new_data;
1875   }
1876   elsif (ref $self->{cond} ne 'HASH') {
1877     $self->throw_exception(
1878       "Can't abstract implicit construct, resultset condition not a hash"
1879     );
1880   }
1881   else {
1882     # precendence must be given to passed values over values inherited from
1883     # the cond, so the order here is important.
1884     my $collapsed_cond = $self->_collapse_cond($self->{cond});
1885     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
1886
1887     while ( my($col, $value) = each %implied ) {
1888       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
1889         $new_data{$col} = $value->{'='};
1890         next;
1891       }
1892       $new_data{$col} = $value if $self->_is_deterministic_value($value);
1893     }
1894   }
1895
1896   %new_data = (
1897     %new_data,
1898     %{ $self->_remove_alias($data, $alias) },
1899   );
1900
1901   return (\%new_data, \@cols_from_relations);
1902 }
1903
1904 # _is_deterministic_value
1905 #
1906 # Make an effor to strip non-deterministic values from the condition,
1907 # to make sure new_result chokes less
1908
1909 sub _is_deterministic_value {
1910   my $self = shift;
1911   my $value = shift;
1912   my $ref_type = ref $value;
1913   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1914   return 1 if Scalar::Util::blessed($value);
1915   return 0;
1916 }
1917
1918 # _has_resolved_attr
1919 #
1920 # determines if the resultset defines at least one
1921 # of the attributes supplied
1922 #
1923 # used to determine if a subquery is neccessary
1924 #
1925 # supports some virtual attributes:
1926 #   -join
1927 #     This will scan for any joins being present on the resultset.
1928 #     It is not a mere key-search but a deep inspection of {from}
1929 #
1930
1931 sub _has_resolved_attr {
1932   my ($self, @attr_names) = @_;
1933
1934   my $attrs = $self->_resolved_attrs;
1935
1936   my %extra_checks;
1937
1938   for my $n (@attr_names) {
1939     if (grep { $n eq $_ } (qw/-join/) ) {
1940       $extra_checks{$n}++;
1941       next;
1942     }
1943
1944     my $attr =  $attrs->{$n};
1945
1946     next if not defined $attr;
1947
1948     if (ref $attr eq 'HASH') {
1949       return 1 if keys %$attr;
1950     }
1951     elsif (ref $attr eq 'ARRAY') {
1952       return 1 if @$attr;
1953     }
1954     else {
1955       return 1 if $attr;
1956     }
1957   }
1958
1959   # a resolved join is expressed as a multi-level from
1960   return 1 if (
1961     $extra_checks{-join}
1962       and
1963     ref $attrs->{from} eq 'ARRAY'
1964       and
1965     @{$attrs->{from}} > 1
1966   );
1967
1968   return 0;
1969 }
1970
1971 # _collapse_cond
1972 #
1973 # Recursively collapse the condition.
1974
1975 sub _collapse_cond {
1976   my ($self, $cond, $collapsed) = @_;
1977
1978   $collapsed ||= {};
1979
1980   if (ref $cond eq 'ARRAY') {
1981     foreach my $subcond (@$cond) {
1982       next unless ref $subcond;  # -or
1983       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1984     }
1985   }
1986   elsif (ref $cond eq 'HASH') {
1987     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1988       foreach my $subcond (@{$cond->{-and}}) {
1989         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1990       }
1991     }
1992     else {
1993       foreach my $col (keys %$cond) {
1994         my $value = $cond->{$col};
1995         $collapsed->{$col} = $value;
1996       }
1997     }
1998   }
1999
2000   return $collapsed;
2001 }
2002
2003 # _remove_alias
2004 #
2005 # Remove the specified alias from the specified query hash. A copy is made so
2006 # the original query is not modified.
2007
2008 sub _remove_alias {
2009   my ($self, $query, $alias) = @_;
2010
2011   my %orig = %{ $query || {} };
2012   my %unaliased;
2013
2014   foreach my $key (keys %orig) {
2015     if ($key !~ /\./) {
2016       $unaliased{$key} = $orig{$key};
2017       next;
2018     }
2019     $unaliased{$1} = $orig{$key}
2020       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2021   }
2022
2023   return \%unaliased;
2024 }
2025
2026 =head2 as_query
2027
2028 =over 4
2029
2030 =item Arguments: none
2031
2032 =item Return Value: \[ $sql, @bind ]
2033
2034 =back
2035
2036 Returns the SQL query and bind vars associated with the invocant.
2037
2038 This is generally used as the RHS for a subquery.
2039
2040 =cut
2041
2042 sub as_query {
2043   my $self = shift;
2044
2045   my $attrs = $self->_resolved_attrs_copy;
2046
2047   # For future use:
2048   #
2049   # in list ctx:
2050   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2051   # $sql also has no wrapping parenthesis in list ctx
2052   #
2053   my $sqlbind = $self->result_source->storage
2054     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2055
2056   return $sqlbind;
2057 }
2058
2059 =head2 find_or_new
2060
2061 =over 4
2062
2063 =item Arguments: \%vals, \%attrs?
2064
2065 =item Return Value: $rowobject
2066
2067 =back
2068
2069   my $artist = $schema->resultset('Artist')->find_or_new(
2070     { artist => 'fred' }, { key => 'artists' });
2071
2072   $cd->cd_to_producer->find_or_new({ producer => $producer },
2073                                    { key => 'primary });
2074
2075 Find an existing record from this resultset, based on its primary
2076 key, or a unique constraint. If none exists, instantiate a new result
2077 object and return it. The object will not be saved into your storage
2078 until you call L<DBIx::Class::Row/insert> on it.
2079
2080 You most likely want this method when looking for existing rows using
2081 a unique constraint that is not the primary key, or looking for
2082 related rows.
2083
2084 If you want objects to be saved immediately, use L</find_or_create>
2085 instead.
2086
2087 B<Note>: Take care when using C<find_or_new> with a table having
2088 columns with default values that you intend to be automatically
2089 supplied by the database (e.g. an auto_increment primary key column).
2090 In normal usage, the value of such columns should NOT be included at
2091 all in the call to C<find_or_new>, even when set to C<undef>.
2092
2093 =cut
2094
2095 sub find_or_new {
2096   my $self     = shift;
2097   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2098   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2099   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2100     return $row;
2101   }
2102   return $self->new_result($hash);
2103 }
2104
2105 =head2 create
2106
2107 =over 4
2108
2109 =item Arguments: \%vals
2110
2111 =item Return Value: a L<DBIx::Class::Row> $object
2112
2113 =back
2114
2115 Attempt to create a single new row or a row with multiple related rows
2116 in the table represented by the resultset (and related tables). This
2117 will not check for duplicate rows before inserting, use
2118 L</find_or_create> to do that.
2119
2120 To create one row for this resultset, pass a hashref of key/value
2121 pairs representing the columns of the table and the values you wish to
2122 store. If the appropriate relationships are set up, foreign key fields
2123 can also be passed an object representing the foreign row, and the
2124 value will be set to its primary key.
2125
2126 To create related objects, pass a hashref of related-object column values
2127 B<keyed on the relationship name>. If the relationship is of type C<multi>
2128 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2129 The process will correctly identify columns holding foreign keys, and will
2130 transparrently populate them from the keys of the corresponding relation.
2131 This can be applied recursively, and will work correctly for a structure
2132 with an arbitrary depth and width, as long as the relationships actually
2133 exists and the correct column data has been supplied.
2134
2135
2136 Instead of hashrefs of plain related data (key/value pairs), you may
2137 also pass new or inserted objects. New objects (not inserted yet, see
2138 L</new>), will be inserted into their appropriate tables.
2139
2140 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2141
2142 Example of creating a new row.
2143
2144   $person_rs->create({
2145     name=>"Some Person",
2146     email=>"somebody@someplace.com"
2147   });
2148
2149 Example of creating a new row and also creating rows in a related C<has_many>
2150 or C<has_one> resultset.  Note Arrayref.
2151
2152   $artist_rs->create(
2153      { artistid => 4, name => 'Manufactured Crap', cds => [
2154         { title => 'My First CD', year => 2006 },
2155         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2156       ],
2157      },
2158   );
2159
2160 Example of creating a new row and also creating a row in a related
2161 C<belongs_to>resultset. Note Hashref.
2162
2163   $cd_rs->create({
2164     title=>"Music for Silly Walks",
2165     year=>2000,
2166     artist => {
2167       name=>"Silly Musician",
2168     }
2169   });
2170
2171 =over
2172
2173 =item WARNING
2174
2175 When subclassing ResultSet never attempt to override this method. Since
2176 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2177 lot of the internals simply never call it, so your override will be
2178 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2179 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2180 L</create> process you need to intervene.
2181
2182 =back
2183
2184 =cut
2185
2186 sub create {
2187   my ($self, $attrs) = @_;
2188   $self->throw_exception( "create needs a hashref" )
2189     unless ref $attrs eq 'HASH';
2190   return $self->new_result($attrs)->insert;
2191 }
2192
2193 =head2 find_or_create
2194
2195 =over 4
2196
2197 =item Arguments: \%vals, \%attrs?
2198
2199 =item Return Value: $rowobject
2200
2201 =back
2202
2203   $cd->cd_to_producer->find_or_create({ producer => $producer },
2204                                       { key => 'primary' });
2205
2206 Tries to find a record based on its primary key or unique constraints; if none
2207 is found, creates one and returns that instead.
2208
2209   my $cd = $schema->resultset('CD')->find_or_create({
2210     cdid   => 5,
2211     artist => 'Massive Attack',
2212     title  => 'Mezzanine',
2213     year   => 2005,
2214   });
2215
2216 Also takes an optional C<key> attribute, to search by a specific key or unique
2217 constraint. For example:
2218
2219   my $cd = $schema->resultset('CD')->find_or_create(
2220     {
2221       artist => 'Massive Attack',
2222       title  => 'Mezzanine',
2223     },
2224     { key => 'cd_artist_title' }
2225   );
2226
2227 B<Note>: Because find_or_create() reads from the database and then
2228 possibly inserts based on the result, this method is subject to a race
2229 condition. Another process could create a record in the table after
2230 the find has completed and before the create has started. To avoid
2231 this problem, use find_or_create() inside a transaction.
2232
2233 B<Note>: Take care when using C<find_or_create> with a table having
2234 columns with default values that you intend to be automatically
2235 supplied by the database (e.g. an auto_increment primary key column).
2236 In normal usage, the value of such columns should NOT be included at
2237 all in the call to C<find_or_create>, even when set to C<undef>.
2238
2239 See also L</find> and L</update_or_create>. For information on how to declare
2240 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2241
2242 =cut
2243
2244 sub find_or_create {
2245   my $self     = shift;
2246   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2247   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2248   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2249     return $row;
2250   }
2251   return $self->create($hash);
2252 }
2253
2254 =head2 update_or_create
2255
2256 =over 4
2257
2258 =item Arguments: \%col_values, { key => $unique_constraint }?
2259
2260 =item Return Value: $rowobject
2261
2262 =back
2263
2264   $resultset->update_or_create({ col => $val, ... });
2265
2266 First, searches for an existing row matching one of the unique constraints
2267 (including the primary key) on the source of this resultset. If a row is
2268 found, updates it with the other given column values. Otherwise, creates a new
2269 row.
2270
2271 Takes an optional C<key> attribute to search on a specific unique constraint.
2272 For example:
2273
2274   # In your application
2275   my $cd = $schema->resultset('CD')->update_or_create(
2276     {
2277       artist => 'Massive Attack',
2278       title  => 'Mezzanine',
2279       year   => 1998,
2280     },
2281     { key => 'cd_artist_title' }
2282   );
2283
2284   $cd->cd_to_producer->update_or_create({
2285     producer => $producer,
2286     name => 'harry',
2287   }, {
2288     key => 'primary,
2289   });
2290
2291
2292 If no C<key> is specified, it searches on all unique constraints defined on the
2293 source, including the primary key.
2294
2295 If the C<key> is specified as C<primary>, it searches only on the primary key.
2296
2297 See also L</find> and L</find_or_create>. For information on how to declare
2298 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2299
2300 B<Note>: Take care when using C<update_or_create> with a table having
2301 columns with default values that you intend to be automatically
2302 supplied by the database (e.g. an auto_increment primary key column).
2303 In normal usage, the value of such columns should NOT be included at
2304 all in the call to C<update_or_create>, even when set to C<undef>.
2305
2306 =cut
2307
2308 sub update_or_create {
2309   my $self = shift;
2310   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2311   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2312
2313   my $row = $self->find($cond, $attrs);
2314   if (defined $row) {
2315     $row->update($cond);
2316     return $row;
2317   }
2318
2319   return $self->create($cond);
2320 }
2321
2322 =head2 update_or_new
2323
2324 =over 4
2325
2326 =item Arguments: \%col_values, { key => $unique_constraint }?
2327
2328 =item Return Value: $rowobject
2329
2330 =back
2331
2332   $resultset->update_or_new({ col => $val, ... });
2333
2334 First, searches for an existing row matching one of the unique constraints
2335 (including the primary key) on the source of this resultset. If a row is
2336 found, updates it with the other given column values. Otherwise, instantiate
2337 a new result object and return it. The object will not be saved into your storage
2338 until you call L<DBIx::Class::Row/insert> on it.
2339
2340 Takes an optional C<key> attribute to search on a specific unique constraint.
2341 For example:
2342
2343   # In your application
2344   my $cd = $schema->resultset('CD')->update_or_new(
2345     {
2346       artist => 'Massive Attack',
2347       title  => 'Mezzanine',
2348       year   => 1998,
2349     },
2350     { key => 'cd_artist_title' }
2351   );
2352
2353   if ($cd->in_storage) {
2354       # the cd was updated
2355   }
2356   else {
2357       # the cd is not yet in the database, let's insert it
2358       $cd->insert;
2359   }
2360
2361 B<Note>: Take care when using C<update_or_new> with a table having
2362 columns with default values that you intend to be automatically
2363 supplied by the database (e.g. an auto_increment primary key column).
2364 In normal usage, the value of such columns should NOT be included at
2365 all in the call to C<update_or_new>, even when set to C<undef>.
2366
2367 See also L</find>, L</find_or_create> and L</find_or_new>.
2368
2369 =cut
2370
2371 sub update_or_new {
2372     my $self  = shift;
2373     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2374     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2375
2376     my $row = $self->find( $cond, $attrs );
2377     if ( defined $row ) {
2378         $row->update($cond);
2379         return $row;
2380     }
2381
2382     return $self->new_result($cond);
2383 }
2384
2385 =head2 get_cache
2386
2387 =over 4
2388
2389 =item Arguments: none
2390
2391 =item Return Value: \@cache_objects?
2392
2393 =back
2394
2395 Gets the contents of the cache for the resultset, if the cache is set.
2396
2397 The cache is populated either by using the L</prefetch> attribute to
2398 L</search> or by calling L</set_cache>.
2399
2400 =cut
2401
2402 sub get_cache {
2403   shift->{all_cache};
2404 }
2405
2406 =head2 set_cache
2407
2408 =over 4
2409
2410 =item Arguments: \@cache_objects
2411
2412 =item Return Value: \@cache_objects
2413
2414 =back
2415
2416 Sets the contents of the cache for the resultset. Expects an arrayref
2417 of objects of the same class as those produced by the resultset. Note that
2418 if the cache is set the resultset will return the cached objects rather
2419 than re-querying the database even if the cache attr is not set.
2420
2421 The contents of the cache can also be populated by using the
2422 L</prefetch> attribute to L</search>.
2423
2424 =cut
2425
2426 sub set_cache {
2427   my ( $self, $data ) = @_;
2428   $self->throw_exception("set_cache requires an arrayref")
2429       if defined($data) && (ref $data ne 'ARRAY');
2430   $self->{all_cache} = $data;
2431 }
2432
2433 =head2 clear_cache
2434
2435 =over 4
2436
2437 =item Arguments: none
2438
2439 =item Return Value: []
2440
2441 =back
2442
2443 Clears the cache for the resultset.
2444
2445 =cut
2446
2447 sub clear_cache {
2448   shift->set_cache(undef);
2449 }
2450
2451 =head2 is_paged
2452
2453 =over 4
2454
2455 =item Arguments: none
2456
2457 =item Return Value: true, if the resultset has been paginated
2458
2459 =back
2460
2461 =cut
2462
2463 sub is_paged {
2464   my ($self) = @_;
2465   return !!$self->{attrs}{page};
2466 }
2467
2468 =head2 related_resultset
2469
2470 =over 4
2471
2472 =item Arguments: $relationship_name
2473
2474 =item Return Value: $resultset
2475
2476 =back
2477
2478 Returns a related resultset for the supplied relationship name.
2479
2480   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2481
2482 =cut
2483
2484 sub related_resultset {
2485   my ($self, $rel) = @_;
2486
2487   $self->{related_resultsets} ||= {};
2488   return $self->{related_resultsets}{$rel} ||= do {
2489     my $rsrc = $self->result_source;
2490     my $rel_info = $rsrc->relationship_info($rel);
2491
2492     $self->throw_exception(
2493       "search_related: result source '" . $rsrc->source_name .
2494         "' has no such relationship $rel")
2495       unless $rel_info;
2496
2497     my $attrs = $self->_chain_relationship($rel);
2498
2499     my $join_count = $attrs->{seen_join}{$rel};
2500
2501     my $alias = $self->result_source->storage
2502         ->relname_to_table_alias($rel, $join_count);
2503
2504     # since this is search_related, and we already slid the select window inwards
2505     # (the select/as attrs were deleted in the beginning), we need to flip all
2506     # left joins to inner, so we get the expected results
2507     # read the comment on top of the actual function to see what this does
2508     $attrs->{from} = $rsrc->schema->storage->_straight_join_to_node ($attrs->{from}, $alias);
2509
2510
2511     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2512     delete @{$attrs}{qw(result_class alias)};
2513
2514     my $new_cache;
2515
2516     if (my $cache = $self->get_cache) {
2517       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2518         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2519                         @$cache ];
2520       }
2521     }
2522
2523     my $rel_source = $rsrc->related_source($rel);
2524
2525     my $new = do {
2526
2527       # The reason we do this now instead of passing the alias to the
2528       # search_rs below is that if you wrap/overload resultset on the
2529       # source you need to know what alias it's -going- to have for things
2530       # to work sanely (e.g. RestrictWithObject wants to be able to add
2531       # extra query restrictions, and these may need to be $alias.)
2532
2533       my $rel_attrs = $rel_source->resultset_attributes;
2534       local $rel_attrs->{alias} = $alias;
2535
2536       $rel_source->resultset
2537                  ->search_rs(
2538                      undef, {
2539                        %$attrs,
2540                        where => $attrs->{where},
2541                    });
2542     };
2543     $new->set_cache($new_cache) if $new_cache;
2544     $new;
2545   };
2546 }
2547
2548 =head2 current_source_alias
2549
2550 =over 4
2551
2552 =item Arguments: none
2553
2554 =item Return Value: $source_alias
2555
2556 =back
2557
2558 Returns the current table alias for the result source this resultset is built
2559 on, that will be used in the SQL query. Usually it is C<me>.
2560
2561 Currently the source alias that refers to the result set returned by a
2562 L</search>/L</find> family method depends on how you got to the resultset: it's
2563 C<me> by default, but eg. L</search_related> aliases it to the related result
2564 source name (and keeps C<me> referring to the original result set). The long
2565 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2566 (and make this method unnecessary).
2567
2568 Thus it's currently necessary to use this method in predefined queries (see
2569 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2570 source alias of the current result set:
2571
2572   # in a result set class
2573   sub modified_by {
2574     my ($self, $user) = @_;
2575
2576     my $me = $self->current_source_alias;
2577
2578     return $self->search(
2579       "$me.modified" => $user->id,
2580     );
2581   }
2582
2583 =cut
2584
2585 sub current_source_alias {
2586   my ($self) = @_;
2587
2588   return ($self->{attrs} || {})->{alias} || 'me';
2589 }
2590
2591 =head2 as_subselect_rs
2592
2593 =over 4
2594
2595 =item Arguments: none
2596
2597 =item Return Value: $resultset
2598
2599 =back
2600
2601 Act as a barrier to SQL symbols.  The resultset provided will be made into a
2602 "virtual view" by including it as a subquery within the from clause.  From this
2603 point on, any joined tables are inaccessible to ->search on the resultset (as if
2604 it were simply where-filtered without joins).  For example:
2605
2606  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
2607
2608  # 'x' now pollutes the query namespace
2609
2610  # So the following works as expected
2611  my $ok_rs = $rs->search({'x.other' => 1});
2612
2613  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
2614  # def) we look for one row with contradictory terms and join in another table
2615  # (aliased 'x_2') which we never use
2616  my $broken_rs = $rs->search({'x.name' => 'def'});
2617
2618  my $rs2 = $rs->as_subselect_rs;
2619
2620  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
2621  my $not_joined_rs = $rs2->search({'x.other' => 1});
2622
2623  # works as expected: finds a 'table' row related to two x rows (abc and def)
2624  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
2625
2626 Another example of when one might use this would be to select a subset of
2627 columns in a group by clause:
2628
2629  my $rs = $schema->resultset('Bar')->search(undef, {
2630    group_by => [qw{ id foo_id baz_id }],
2631  })->as_subselect_rs->search(undef, {
2632    columns => [qw{ id foo_id }]
2633  });
2634
2635 In the above example normally columns would have to be equal to the group by,
2636 but because we isolated the group by into a subselect the above works.
2637
2638 =cut
2639
2640 sub as_subselect_rs {
2641    my $self = shift;
2642
2643    return $self->result_source->resultset->search( undef, {
2644       alias => $self->current_source_alias,
2645       from => [{
2646             $self->current_source_alias => $self->as_query,
2647             -alias         => $self->current_source_alias,
2648             -source_handle => $self->result_source->handle,
2649          }]
2650    });
2651 }
2652
2653 # This code is called by search_related, and makes sure there
2654 # is clear separation between the joins before, during, and
2655 # after the relationship. This information is needed later
2656 # in order to properly resolve prefetch aliases (any alias
2657 # with a relation_chain_depth less than the depth of the
2658 # current prefetch is not considered)
2659 #
2660 # The increments happen twice per join. An even number means a
2661 # relationship specified via a search_related, whereas an odd
2662 # number indicates a join/prefetch added via attributes
2663 #
2664 # Also this code will wrap the current resultset (the one we
2665 # chain to) in a subselect IFF it contains limiting attributes
2666 sub _chain_relationship {
2667   my ($self, $rel) = @_;
2668   my $source = $self->result_source;
2669   my $attrs = { %{$self->{attrs}||{}} };
2670
2671   # we need to take the prefetch the attrs into account before we
2672   # ->_resolve_join as otherwise they get lost - captainL
2673   my $join = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2674
2675   delete @{$attrs}{qw/join prefetch collapse distinct select as columns +select +as +columns/};
2676
2677   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
2678
2679   my $from;
2680   my @force_subq_attrs = qw/offset rows group_by having/;
2681
2682   if (
2683     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
2684       ||
2685     $self->_has_resolved_attr (@force_subq_attrs)
2686   ) {
2687     # Nuke the prefetch (if any) before the new $rs attrs
2688     # are resolved (prefetch is useless - we are wrapping
2689     # a subquery anyway).
2690     my $rs_copy = $self->search;
2691     $rs_copy->{attrs}{join} = $self->_merge_attr (
2692       $rs_copy->{attrs}{join},
2693       delete $rs_copy->{attrs}{prefetch},
2694     );
2695
2696     $from = [{
2697       -source_handle => $source->handle,
2698       -alias => $attrs->{alias},
2699       $attrs->{alias} => $rs_copy->as_query,
2700     }];
2701     delete @{$attrs}{@force_subq_attrs, 'where'};
2702     $seen->{-relation_chain_depth} = 0;
2703   }
2704   elsif ($attrs->{from}) {  #shallow copy suffices
2705     $from = [ @{$attrs->{from}} ];
2706   }
2707   else {
2708     $from = [{
2709       -source_handle => $source->handle,
2710       -alias => $attrs->{alias},
2711       $attrs->{alias} => $source->from,
2712     }];
2713   }
2714
2715   my $jpath = ($seen->{-relation_chain_depth})
2716     ? $from->[-1][0]{-join_path}
2717     : [];
2718
2719   my @requested_joins = $source->_resolve_join(
2720     $join,
2721     $attrs->{alias},
2722     $seen,
2723     $jpath,
2724   );
2725
2726   push @$from, @requested_joins;
2727
2728   $seen->{-relation_chain_depth}++;
2729
2730   # if $self already had a join/prefetch specified on it, the requested
2731   # $rel might very well be already included. What we do in this case
2732   # is effectively a no-op (except that we bump up the chain_depth on
2733   # the join in question so we could tell it *is* the search_related)
2734   my $already_joined;
2735
2736   # we consider the last one thus reverse
2737   for my $j (reverse @requested_joins) {
2738     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
2739     if ($rel eq $last_j) {
2740       $j->[0]{-relation_chain_depth}++;
2741       $already_joined++;
2742       last;
2743     }
2744   }
2745
2746   unless ($already_joined) {
2747     push @$from, $source->_resolve_join(
2748       $rel,
2749       $attrs->{alias},
2750       $seen,
2751       $jpath,
2752     );
2753   }
2754
2755   $seen->{-relation_chain_depth}++;
2756
2757   return {%$attrs, from => $from, seen_join => $seen};
2758 }
2759
2760 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2761 sub _resolved_attrs_copy {
2762   my $self = shift;
2763   return { %{$self->_resolved_attrs (@_)} };
2764 }
2765
2766 sub _resolved_attrs {
2767   my $self = shift;
2768   return $self->{_attrs} if $self->{_attrs};
2769
2770   my $attrs  = { %{ $self->{attrs} || {} } };
2771   my $source = $self->result_source;
2772   my $alias  = $attrs->{alias};
2773
2774   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2775   my @colbits;
2776
2777   # build columns (as long as select isn't set) into a set of as/select hashes
2778   unless ( $attrs->{select} ) {
2779
2780     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2781       ? @{ delete $attrs->{columns}}
2782       : (
2783           ( delete $attrs->{columns} )
2784             ||
2785           $source->columns
2786         )
2787     ;
2788
2789     @colbits = map {
2790       ( ref($_) eq 'HASH' )
2791       ? $_
2792       : {
2793           (
2794             /^\Q${alias}.\E(.+)$/
2795               ? "$1"
2796               : "$_"
2797           )
2798             =>
2799           (
2800             /\./
2801               ? "$_"
2802               : "${alias}.$_"
2803           )
2804         }
2805     } @cols;
2806   }
2807
2808   # add the additional columns on
2809   foreach ( 'include_columns', '+columns' ) {
2810       push @colbits, map {
2811           ( ref($_) eq 'HASH' )
2812             ? $_
2813             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2814       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2815   }
2816
2817   # start with initial select items
2818   if ( $attrs->{select} ) {
2819     $attrs->{select} =
2820         ( ref $attrs->{select} eq 'ARRAY' )
2821       ? [ @{ $attrs->{select} } ]
2822       : [ $attrs->{select} ];
2823     $attrs->{as} = (
2824       $attrs->{as}
2825       ? (
2826         ref $attrs->{as} eq 'ARRAY'
2827         ? [ @{ $attrs->{as} } ]
2828         : [ $attrs->{as} ]
2829         )
2830       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2831     );
2832   }
2833   else {
2834
2835     # otherwise we intialise select & as to empty
2836     $attrs->{select} = [];
2837     $attrs->{as}     = [];
2838   }
2839
2840   # now add colbits to select/as
2841   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2842   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2843
2844   my $adds;
2845   if ( $adds = delete $attrs->{'+select'} ) {
2846     $adds = [$adds] unless ref $adds eq 'ARRAY';
2847     push(
2848       @{ $attrs->{select} },
2849       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2850     );
2851   }
2852   if ( $adds = delete $attrs->{'+as'} ) {
2853     $adds = [$adds] unless ref $adds eq 'ARRAY';
2854     push( @{ $attrs->{as} }, @$adds );
2855   }
2856
2857   $attrs->{from} ||= [ {
2858     -source_handle => $source->handle,
2859     -alias => $self->{attrs}{alias},
2860     $self->{attrs}{alias} => $source->from,
2861   } ];
2862
2863   if ( $attrs->{join} || $attrs->{prefetch} ) {
2864
2865     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2866       if ref $attrs->{from} ne 'ARRAY';
2867
2868     my $join = delete $attrs->{join} || {};
2869
2870     if ( defined $attrs->{prefetch} ) {
2871       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2872     }
2873
2874     $attrs->{from} =    # have to copy here to avoid corrupting the original
2875       [
2876         @{ $attrs->{from} },
2877         $source->_resolve_join(
2878           $join,
2879           $alias,
2880           { %{ $attrs->{seen_join} || {} } },
2881           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2882             ? $attrs->{from}[-1][0]{-join_path}
2883             : []
2884           ,
2885         )
2886       ];
2887   }
2888
2889   if ( defined $attrs->{order_by} ) {
2890     $attrs->{order_by} = (
2891       ref( $attrs->{order_by} ) eq 'ARRAY'
2892       ? [ @{ $attrs->{order_by} } ]
2893       : [ $attrs->{order_by} || () ]
2894     );
2895   }
2896
2897   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2898     $attrs->{group_by} = [ $attrs->{group_by} ];
2899   }
2900
2901   # generate the distinct induced group_by early, as prefetch will be carried via a
2902   # subquery (since a group_by is present)
2903   if (delete $attrs->{distinct}) {
2904     if ($attrs->{group_by}) {
2905       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2906     }
2907     else {
2908       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2909
2910       # add any order_by parts that are not already present in the group_by
2911       # we need to be careful not to add any named functions/aggregates
2912       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
2913       my %already_grouped = map { $_ => 1 } (@{$attrs->{group_by}});
2914
2915       my $storage = $self->result_source->schema->storage;
2916
2917       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
2918
2919       for my $chunk ($storage->_parse_order_by($attrs->{order_by})) {
2920         if ($rs_column_list->{$chunk} && not $already_grouped{$chunk}++) {
2921           push @{$attrs->{group_by}}, $chunk;
2922         }
2923       }
2924     }
2925   }
2926
2927   $attrs->{collapse} ||= {};
2928   if ( my $prefetch = delete $attrs->{prefetch} ) {
2929     $prefetch = $self->_merge_attr( {}, $prefetch );
2930
2931     my $prefetch_ordering = [];
2932
2933     # this is a separate structure (we don't look in {from} directly)
2934     # as the resolver needs to shift things off the lists to work
2935     # properly (identical-prefetches on different branches)
2936     my $join_map = {};
2937     if (ref $attrs->{from} eq 'ARRAY') {
2938
2939       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
2940
2941       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
2942         next unless $j->[0]{-alias};
2943         next unless $j->[0]{-join_path};
2944         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
2945
2946         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
2947
2948         my $p = $join_map;
2949         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
2950         push @{$p->{-join_aliases} }, $j->[0]{-alias};
2951       }
2952     }
2953
2954     my @prefetch =
2955       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2956
2957     # we need to somehow mark which columns came from prefetch
2958     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2959
2960     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2961     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2962
2963     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2964     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2965   }
2966
2967   # if both page and offset are specified, produce a combined offset
2968   # even though it doesn't make much sense, this is what pre 081xx has
2969   # been doing
2970   if (my $page = delete $attrs->{page}) {
2971     $attrs->{offset} =
2972       ($attrs->{rows} * ($page - 1))
2973             +
2974       ($attrs->{offset} || 0)
2975     ;
2976   }
2977
2978   return $self->{_attrs} = $attrs;
2979 }
2980
2981 sub _rollout_attr {
2982   my ($self, $attr) = @_;
2983
2984   if (ref $attr eq 'HASH') {
2985     return $self->_rollout_hash($attr);
2986   } elsif (ref $attr eq 'ARRAY') {
2987     return $self->_rollout_array($attr);
2988   } else {
2989     return [$attr];
2990   }
2991 }
2992
2993 sub _rollout_array {
2994   my ($self, $attr) = @_;
2995
2996   my @rolled_array;
2997   foreach my $element (@{$attr}) {
2998     if (ref $element eq 'HASH') {
2999       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3000     } elsif (ref $element eq 'ARRAY') {
3001       #  XXX - should probably recurse here
3002       push( @rolled_array, @{$self->_rollout_array($element)} );
3003     } else {
3004       push( @rolled_array, $element );
3005     }
3006   }
3007   return \@rolled_array;
3008 }
3009
3010 sub _rollout_hash {
3011   my ($self, $attr) = @_;
3012
3013   my @rolled_array;
3014   foreach my $key (keys %{$attr}) {
3015     push( @rolled_array, { $key => $attr->{$key} } );
3016   }
3017   return \@rolled_array;
3018 }
3019
3020 sub _calculate_score {
3021   my ($self, $a, $b) = @_;
3022
3023   if (defined $a xor defined $b) {
3024     return 0;
3025   }
3026   elsif (not defined $a) {
3027     return 1;
3028   }
3029
3030   if (ref $b eq 'HASH') {
3031     my ($b_key) = keys %{$b};
3032     if (ref $a eq 'HASH') {
3033       my ($a_key) = keys %{$a};
3034       if ($a_key eq $b_key) {
3035         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3036       } else {
3037         return 0;
3038       }
3039     } else {
3040       return ($a eq $b_key) ? 1 : 0;
3041     }
3042   } else {
3043     if (ref $a eq 'HASH') {
3044       my ($a_key) = keys %{$a};
3045       return ($b eq $a_key) ? 1 : 0;
3046     } else {
3047       return ($b eq $a) ? 1 : 0;
3048     }
3049   }
3050 }
3051
3052 sub _merge_attr {
3053   my ($self, $orig, $import) = @_;
3054
3055   return $import unless defined($orig);
3056   return $orig unless defined($import);
3057
3058   $orig = $self->_rollout_attr($orig);
3059   $import = $self->_rollout_attr($import);
3060
3061   my $seen_keys;
3062   foreach my $import_element ( @{$import} ) {
3063     # find best candidate from $orig to merge $b_element into
3064     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3065     foreach my $orig_element ( @{$orig} ) {
3066       my $score = $self->_calculate_score( $orig_element, $import_element );
3067       if ($score > $best_candidate->{score}) {
3068         $best_candidate->{position} = $position;
3069         $best_candidate->{score} = $score;
3070       }
3071       $position++;
3072     }
3073     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3074
3075     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3076       push( @{$orig}, $import_element );
3077     } else {
3078       my $orig_best = $orig->[$best_candidate->{position}];
3079       # merge orig_best and b_element together and replace original with merged
3080       if (ref $orig_best ne 'HASH') {
3081         $orig->[$best_candidate->{position}] = $import_element;
3082       } elsif (ref $import_element eq 'HASH') {
3083         my ($key) = keys %{$orig_best};
3084         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3085       }
3086     }
3087     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3088   }
3089
3090   return $orig;
3091 }
3092
3093 sub result_source {
3094     my $self = shift;
3095
3096     if (@_) {
3097         $self->_source_handle($_[0]->handle);
3098     } else {
3099         $self->_source_handle->resolve;
3100     }
3101 }
3102
3103 =head2 throw_exception
3104
3105 See L<DBIx::Class::Schema/throw_exception> for details.
3106
3107 =cut
3108
3109 sub throw_exception {
3110   my $self=shift;
3111
3112   if (ref $self && $self->_source_handle->schema) {
3113     $self->_source_handle->schema->throw_exception(@_)
3114   }
3115   else {
3116     DBIx::Class::Exception->throw(@_);
3117   }
3118 }
3119
3120 # XXX: FIXME: Attributes docs need clearing up
3121
3122 =head1 ATTRIBUTES
3123
3124 Attributes are used to refine a ResultSet in various ways when
3125 searching for data. They can be passed to any method which takes an
3126 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3127 L</count>.
3128
3129 These are in no particular order:
3130
3131 =head2 order_by
3132
3133 =over 4
3134
3135 =item Value: ( $order_by | \@order_by | \%order_by )
3136
3137 =back
3138
3139 Which column(s) to order the results by.
3140
3141 [The full list of suitable values is documented in
3142 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3143 common options.]
3144
3145 If a single column name, or an arrayref of names is supplied, the
3146 argument is passed through directly to SQL. The hashref syntax allows
3147 for connection-agnostic specification of ordering direction:
3148
3149  For descending order:
3150
3151   order_by => { -desc => [qw/col1 col2 col3/] }
3152
3153  For explicit ascending order:
3154
3155   order_by => { -asc => 'col' }
3156
3157 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3158 supported, although you are strongly encouraged to use the hashref
3159 syntax as outlined above.
3160
3161 =head2 columns
3162
3163 =over 4
3164
3165 =item Value: \@columns
3166
3167 =back
3168
3169 Shortcut to request a particular set of columns to be retrieved. Each
3170 column spec may be a string (a table column name), or a hash (in which
3171 case the key is the C<as> value, and the value is used as the C<select>
3172 expression). Adds C<me.> onto the start of any column without a C<.> in
3173 it and sets C<select> from that, then auto-populates C<as> from
3174 C<select> as normal. (You may also use the C<cols> attribute, as in
3175 earlier versions of DBIC.)
3176
3177 =head2 +columns
3178
3179 =over 4
3180
3181 =item Value: \@columns
3182
3183 =back
3184
3185 Indicates additional columns to be selected from storage. Works the same
3186 as L</columns> but adds columns to the selection. (You may also use the
3187 C<include_columns> attribute, as in earlier versions of DBIC). For
3188 example:-
3189
3190   $schema->resultset('CD')->search(undef, {
3191     '+columns' => ['artist.name'],
3192     join => ['artist']
3193   });
3194
3195 would return all CDs and include a 'name' column to the information
3196 passed to object inflation. Note that the 'artist' is the name of the
3197 column (or relationship) accessor, and 'name' is the name of the column
3198 accessor in the related table.
3199
3200 =head2 include_columns
3201
3202 =over 4
3203
3204 =item Value: \@columns
3205
3206 =back
3207
3208 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3209
3210 =head2 select
3211
3212 =over 4
3213
3214 =item Value: \@select_columns
3215
3216 =back
3217
3218 Indicates which columns should be selected from the storage. You can use
3219 column names, or in the case of RDBMS back ends, function or stored procedure
3220 names:
3221
3222   $rs = $schema->resultset('Employee')->search(undef, {
3223     select => [
3224       'name',
3225       { count => 'employeeid' },
3226       { sum => 'salary' }
3227     ]
3228   });
3229
3230 When you use function/stored procedure names and do not supply an C<as>
3231 attribute, the column names returned are storage-dependent. E.g. MySQL would
3232 return a column named C<count(employeeid)> in the above example.
3233
3234 B<NOTE:> You will almost always need a corresponding 'as' entry when you use
3235 'select'.
3236
3237 =head2 +select
3238
3239 =over 4
3240
3241 Indicates additional columns to be selected from storage.  Works the same as
3242 L</select> but adds columns to the selection.
3243
3244 =back
3245
3246 =head2 +as
3247
3248 =over 4
3249
3250 Indicates additional column names for those added via L</+select>. See L</as>.
3251
3252 =back
3253
3254 =head2 as
3255
3256 =over 4
3257
3258 =item Value: \@inflation_names
3259
3260 =back
3261
3262 Indicates column names for object inflation. That is, C<as>
3263 indicates the name that the column can be accessed as via the
3264 C<get_column> method (or via the object accessor, B<if one already
3265 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3266
3267 The C<as> attribute is used in conjunction with C<select>,
3268 usually when C<select> contains one or more function or stored
3269 procedure names:
3270
3271   $rs = $schema->resultset('Employee')->search(undef, {
3272     select => [
3273       'name',
3274       { count => 'employeeid' }
3275     ],
3276     as => ['name', 'employee_count'],
3277   });
3278
3279   my $employee = $rs->first(); # get the first Employee
3280
3281 If the object against which the search is performed already has an accessor
3282 matching a column name specified in C<as>, the value can be retrieved using
3283 the accessor as normal:
3284
3285   my $name = $employee->name();
3286
3287 If on the other hand an accessor does not exist in the object, you need to
3288 use C<get_column> instead:
3289
3290   my $employee_count = $employee->get_column('employee_count');
3291
3292 You can create your own accessors if required - see
3293 L<DBIx::Class::Manual::Cookbook> for details.
3294
3295 Please note: This will NOT insert an C<AS employee_count> into the SQL
3296 statement produced, it is used for internal access only. Thus
3297 attempting to use the accessor in an C<order_by> clause or similar
3298 will fail miserably.
3299
3300 To get around this limitation, you can supply literal SQL to your
3301 C<select> attibute that contains the C<AS alias> text, eg:
3302
3303   select => [\'myfield AS alias']
3304
3305 =head2 join
3306
3307 =over 4
3308
3309 =item Value: ($rel_name | \@rel_names | \%rel_names)
3310
3311 =back
3312
3313 Contains a list of relationships that should be joined for this query.  For
3314 example:
3315
3316   # Get CDs by Nine Inch Nails
3317   my $rs = $schema->resultset('CD')->search(
3318     { 'artist.name' => 'Nine Inch Nails' },
3319     { join => 'artist' }
3320   );
3321
3322 Can also contain a hash reference to refer to the other relation's relations.
3323 For example:
3324
3325   package MyApp::Schema::Track;
3326   use base qw/DBIx::Class/;
3327   __PACKAGE__->table('track');
3328   __PACKAGE__->add_columns(qw/trackid cd position title/);
3329   __PACKAGE__->set_primary_key('trackid');
3330   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3331   1;
3332
3333   # In your application
3334   my $rs = $schema->resultset('Artist')->search(
3335     { 'track.title' => 'Teardrop' },
3336     {
3337       join     => { cd => 'track' },
3338       order_by => 'artist.name',
3339     }
3340   );
3341
3342 You need to use the relationship (not the table) name in  conditions,
3343 because they are aliased as such. The current table is aliased as "me", so
3344 you need to use me.column_name in order to avoid ambiguity. For example:
3345
3346   # Get CDs from 1984 with a 'Foo' track
3347   my $rs = $schema->resultset('CD')->search(
3348     {
3349       'me.year' => 1984,
3350       'tracks.name' => 'Foo'
3351     },
3352     { join => 'tracks' }
3353   );
3354
3355 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3356 similarly for a third time). For e.g.
3357
3358   my $rs = $schema->resultset('Artist')->search({
3359     'cds.title'   => 'Down to Earth',
3360     'cds_2.title' => 'Popular',
3361   }, {
3362     join => [ qw/cds cds/ ],
3363   });
3364
3365 will return a set of all artists that have both a cd with title 'Down
3366 to Earth' and a cd with title 'Popular'.
3367
3368 If you want to fetch related objects from other tables as well, see C<prefetch>
3369 below.
3370
3371 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3372
3373 =head2 prefetch
3374
3375 =over 4
3376
3377 =item Value: ($rel_name | \@rel_names | \%rel_names)
3378
3379 =back
3380
3381 Contains one or more relationships that should be fetched along with
3382 the main query (when they are accessed afterwards the data will
3383 already be available, without extra queries to the database).  This is
3384 useful for when you know you will need the related objects, because it
3385 saves at least one query:
3386
3387   my $rs = $schema->resultset('Tag')->search(
3388     undef,
3389     {
3390       prefetch => {
3391         cd => 'artist'
3392       }
3393     }
3394   );
3395
3396 The initial search results in SQL like the following:
3397
3398   SELECT tag.*, cd.*, artist.* FROM tag
3399   JOIN cd ON tag.cd = cd.cdid
3400   JOIN artist ON cd.artist = artist.artistid
3401
3402 L<DBIx::Class> has no need to go back to the database when we access the
3403 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3404 case.
3405
3406 Simple prefetches will be joined automatically, so there is no need
3407 for a C<join> attribute in the above search.
3408
3409 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3410 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3411 with an accessor type of 'single' or 'filter'). A more complex example that
3412 prefetches an artists cds, the tracks on those cds, and the tags associted
3413 with that artist is given below (assuming many-to-many from artists to tags):
3414
3415  my $rs = $schema->resultset('Artist')->search(
3416    undef,
3417    {
3418      prefetch => [
3419        { cds => 'tracks' },
3420        { artist_tags => 'tags' }
3421      ]
3422    }
3423  );
3424
3425
3426 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3427 attributes will be ignored.
3428
3429 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3430 exactly as you might expect.
3431
3432 =over 4
3433
3434 =item *
3435
3436 Prefetch uses the L</cache> to populate the prefetched relationships. This
3437 may or may not be what you want.
3438
3439 =item *
3440
3441 If you specify a condition on a prefetched relationship, ONLY those
3442 rows that match the prefetched condition will be fetched into that relationship.
3443 This means that adding prefetch to a search() B<may alter> what is returned by
3444 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3445
3446   my $artist_rs = $schema->resultset('Artist')->search({
3447       'cds.year' => 2008,
3448   }, {
3449       join => 'cds',
3450   });
3451
3452   my $count = $artist_rs->first->cds->count;
3453
3454   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3455
3456   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3457
3458   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3459
3460 that cmp_ok() may or may not pass depending on the datasets involved. This
3461 behavior may or may not survive the 0.09 transition.
3462
3463 =back
3464
3465 =head2 page
3466
3467 =over 4
3468
3469 =item Value: $page
3470
3471 =back
3472
3473 Makes the resultset paged and specifies the page to retrieve. Effectively
3474 identical to creating a non-pages resultset and then calling ->page($page)
3475 on it.
3476
3477 If L<rows> attribute is not specified it defaults to 10 rows per page.
3478
3479 When you have a paged resultset, L</count> will only return the number
3480 of rows in the page. To get the total, use the L</pager> and call
3481 C<total_entries> on it.
3482
3483 =head2 rows
3484
3485 =over 4
3486
3487 =item Value: $rows
3488
3489 =back
3490
3491 Specifes the maximum number of rows for direct retrieval or the number of
3492 rows per page if the page attribute or method is used.
3493
3494 =head2 offset
3495
3496 =over 4
3497
3498 =item Value: $offset
3499
3500 =back
3501
3502 Specifies the (zero-based) row number for the  first row to be returned, or the
3503 of the first row of the first page if paging is used.
3504
3505 =head2 group_by
3506
3507 =over 4
3508
3509 =item Value: \@columns
3510
3511 =back
3512
3513 A arrayref of columns to group by. Can include columns of joined tables.
3514
3515   group_by => [qw/ column1 column2 ... /]
3516
3517 =head2 having
3518
3519 =over 4
3520
3521 =item Value: $condition
3522
3523 =back
3524
3525 HAVING is a select statement attribute that is applied between GROUP BY and
3526 ORDER BY. It is applied to the after the grouping calculations have been
3527 done.
3528
3529   having => { 'count(employee)' => { '>=', 100 } }
3530
3531 =head2 distinct
3532
3533 =over 4
3534
3535 =item Value: (0 | 1)
3536
3537 =back
3538
3539 Set to 1 to group by all columns. If the resultset already has a group_by
3540 attribute, this setting is ignored and an appropriate warning is issued.
3541
3542 =head2 where
3543
3544 =over 4
3545
3546 Adds to the WHERE clause.
3547
3548   # only return rows WHERE deleted IS NULL for all searches
3549   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3550
3551 Can be overridden by passing C<< { where => undef } >> as an attribute
3552 to a resultset.
3553
3554 =back
3555
3556 =head2 cache
3557
3558 Set to 1 to cache search results. This prevents extra SQL queries if you
3559 revisit rows in your ResultSet:
3560
3561   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3562
3563   while( my $artist = $resultset->next ) {
3564     ... do stuff ...
3565   }
3566
3567   $rs->first; # without cache, this would issue a query
3568
3569 By default, searches are not cached.
3570
3571 For more examples of using these attributes, see
3572 L<DBIx::Class::Manual::Cookbook>.
3573
3574 =head2 for
3575
3576 =over 4
3577
3578 =item Value: ( 'update' | 'shared' )
3579
3580 =back
3581
3582 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3583 ... FOR SHARED.
3584
3585 =cut
3586
3587 1;