lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use DBIx::Class::Exception;
   8 use Data::Page;
   9 use Storable;
  10 use DBIx::Class::ResultSetColumn;
  11 use DBIx::Class::ResultSourceHandle;
  12 use List::Util ();
  13 use Scalar::Util 'blessed';
  14 use namespace::clean;
  15
  16 use overload
  17         '0+'     => "count",
  18         'bool'   => "_bool",
  19         fallback => 1;
  20
  21 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  22
  23 =head1 NAME
  24
  25 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  26
  27 =head1 SYNOPSIS
  28
  29   my $users_rs   = $schema->resultset('User');
  30   while( $user = $users_rs->next) {
  31     print $user->username;
  32   }
  33
  34   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  35   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  36
  37 =head1 DESCRIPTION
  38
  39 A ResultSet is an object which stores a set of conditions representing
  40 a query. It is the backbone of DBIx::Class (i.e. the really
  41 important/useful bit).
  42
  43 No SQL is executed on the database when a ResultSet is created, it
  44 just stores all the conditions needed to create the query.
  45
  46 A basic ResultSet representing the data of an entire table is returned
  47 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  48 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  49
  50   my $users_rs = $schema->resultset('User');
  51
  52 A new ResultSet is returned from calling L</search> on an existing
  53 ResultSet. The new one will contain all the conditions of the
  54 original, plus any new conditions added in the C<search> call.
  55
  56 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  57 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  58 represents.
  59
  60 The query that the ResultSet represents is B<only> executed against
  61 the database when these methods are called:
  62 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  63
  64 If a resultset is used in a numeric context it returns the L</count>.
  65 However, if it is used in a boolean context it is B<always> true.  So if
  66 you want to check if a resultset has any results, you must use C<if $rs
  67 != 0>.
  68
  69 =head1 EXAMPLES
  70
  71 =head2 Chaining resultsets
  72
  73 Let's say you've got a query that needs to be run to return some data
  74 to the user. But, you have an authorization system in place that
  75 prevents certain users from seeing certain information. So, you want
  76 to construct the basic query in one method, but add constraints to it in
  77 another.
  78
  79   sub get_data {
  80     my $self = shift;
  81     my $request = $self->get_request; # Get a request object somehow.
  82     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  83
  84     my $cd_rs = $schema->resultset('CD')->search({
  85       title => $request->param('title'),
  86       year => $request->param('year'),
  87     });
  88
  89     $self->apply_security_policy( $cd_rs );
  90
  91     return $cd_rs->all();
  92   }
  93
  94   sub apply_security_policy {
  95     my $self = shift;
  96     my ($rs) = @_;
  97
  98     return $rs->search({
  99       subversive => 0,
 100     });
 101   }
 102
 103 =head3 Resolving conditions and attributes
 104
 105 When a resultset is chained from another resultset, conditions and
 106 attributes with the same keys need resolving.
 107
 108 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 109 into the existing ones from the original resultset.
 110
 111 The L</where> and L</having> attributes, and any search conditions, are
 112 merged with an SQL C<AND> to the existing condition from the original
 113 resultset.
 114
 115 All other attributes are overridden by any new ones supplied in the
 116 search attributes.
 117
 118 =head2 Multiple queries
 119
 120 Since a resultset just defines a query, you can do all sorts of
 121 things with it with the same object.
 122
 123   # Don't hit the DB yet.
 124   my $cd_rs = $schema->resultset('CD')->search({
 125     title => 'something',
 126     year => 2009,
 127   });
 128
 129   # Each of these hits the DB individually.
 130   my $count = $cd_rs->count;
 131   my $most_recent = $cd_rs->get_column('date_released')->max();
 132   my @records = $cd_rs->all;
 133
 134 And it's not just limited to SELECT statements.
 135
 136   $cd_rs->delete();
 137
 138 This is even cooler:
 139
 140   $cd_rs->create({ artist => 'Fred' });
 141
 142 Which is the same as:
 143
 144   $schema->resultset('CD')->create({
 145     title => 'something',
 146     year => 2009,
 147     artist => 'Fred'
 148   });
 149
 150 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 151
 152 =head1 METHODS
 153
 154 =head2 new
 155
 156 =over 4
 157
 158 =item Arguments: $source, \%$attrs
 159
 160 =item Return Value: $rs
 161
 162 =back
 163
 164 The resultset constructor. Takes a source object (usually a
 165 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 166 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 167 executed as needed by the other methods.
 168
 169 Generally you won't need to construct a resultset manually.  You'll
 170 automatically get one from e.g. a L</search> called in scalar context:
 171
 172   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 173
 174 IMPORTANT: If called on an object, proxies to new_result instead so
 175
 176   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 177
 178 will return a CD object, not a ResultSet.
 179
 180 =cut
 181
 182 sub new {
 183   my $class = shift;
 184   return $class->new_result(@_) if ref $class;
 185
 186   my ($source, $attrs) = @_;
 187   $source = $source->handle
 188     unless $source->isa('DBIx::Class::ResultSourceHandle');
 189   $attrs = { %{$attrs||{}} };
 190
 191   if ($attrs->{page}) {
 192     $attrs->{rows} ||= 10;
 193   }
 194
 195   $attrs->{alias} ||= 'me';
 196
 197   # Creation of {} and bless separated to mitigate RH perl bug
 198   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 199   my $self = {
 200     _source_handle => $source,
 201     cond => $attrs->{where},
 202     pager => undef,
 203     attrs => $attrs
 204   };
 205
 206   bless $self, $class;
 207
 208   $self->result_class(
 209     $attrs->{result_class} || $source->resolve->result_class
 210   );
 211
 212   return $self;
 213 }
 214
 215 =head2 search
 216
 217 =over 4
 218
 219 =item Arguments: $cond, \%attrs?
 220
 221 =item Return Value: $resultset (scalar context), @row_objs (list context)
 222
 223 =back
 224
 225   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 226   my $new_rs = $cd_rs->search({ year => 2005 });
 227
 228   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 229                  # year = 2005 OR year = 2004
 230
 231 If you need to pass in additional attributes but no additional condition,
 232 call it as C<search(undef, \%attrs)>.
 233
 234   # "SELECT name, artistid FROM $artist_table"
 235   my @all_artists = $schema->resultset('Artist')->search(undef, {
 236     columns => [qw/name artistid/],
 237   });
 238
 239 For a list of attributes that can be passed to C<search>, see
 240 L</ATTRIBUTES>. For more examples of using this function, see
 241 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 242 documentation for the first argument, see L<SQL::Abstract>.
 243
 244 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 245
 246 =cut
 247
 248 sub search {
 249   my $self = shift;
 250   my $rs = $self->search_rs( @_ );
 251   return (wantarray ? $rs->all : $rs);
 252 }
 253
 254 =head2 search_rs
 255
 256 =over 4
 257
 258 =item Arguments: $cond, \%attrs?
 259
 260 =item Return Value: $resultset
 261
 262 =back
 263
 264 This method does the same exact thing as search() except it will
 265 always return a resultset, even in list context.
 266
 267 =cut
 268
 269 sub search_rs {
 270   my $self = shift;
 271
 272   # Special-case handling for (undef, undef).
 273   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 274     pop(@_); pop(@_);
 275   }
 276
 277   my $attrs = {};
 278   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 279   my $our_attrs = { %{$self->{attrs}} };
 280   my $having = delete $our_attrs->{having};
 281   my $where = delete $our_attrs->{where};
 282
 283   my $rows;
 284
 285   my %safe = (alias => 1, cache => 1);
 286
 287   unless (
 288     (@_ && defined($_[0])) # @_ == () or (undef)
 289     ||
 290     (keys %$attrs # empty attrs or only 'safe' attrs
 291     && List::Util::first { !$safe{$_} } keys %$attrs)
 292   ) {
 293     # no search, effectively just a clone
 294     $rows = $self->get_cache;
 295   }
 296
 297   # reset the selector list
 298   if (List::Util::first { exists $attrs->{$_} } qw{columns select as}) {
 299      delete @{$our_attrs}{qw{select as columns +select +as +columns include_columns}};
 300   }
 301
 302   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 303
 304   # merge new attrs into inherited
 305   foreach my $key (qw/join prefetch +select +as +columns include_columns bind/) {
 306     next unless exists $attrs->{$key};
 307     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 308   }
 309
 310   my $cond = (@_
 311     ? (
 312         (@_ == 1 || ref $_[0] eq "HASH")
 313           ? (
 314               (ref $_[0] eq 'HASH')
 315                 ? (
 316                     (keys %{ $_[0] }  > 0)
 317                       ? shift
 318                       : undef
 319                    )
 320                 :  shift
 321              )
 322           : (
 323               (@_ % 2)
 324                 ? $self->throw_exception("Odd number of arguments to search")
 325                 : {@_}
 326              )
 327       )
 328     : undef
 329   );
 330
 331   if (defined $where) {
 332     $new_attrs->{where} = (
 333       defined $new_attrs->{where}
 334         ? { '-and' => [
 335               map {
 336                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 337               } $where, $new_attrs->{where}
 338             ]
 339           }
 340         : $where);
 341   }
 342
 343   if (defined $cond) {
 344     $new_attrs->{where} = (
 345       defined $new_attrs->{where}
 346         ? { '-and' => [
 347               map {
 348                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 349               } $cond, $new_attrs->{where}
 350             ]
 351           }
 352         : $cond);
 353   }
 354
 355   if (defined $having) {
 356     $new_attrs->{having} = (
 357       defined $new_attrs->{having}
 358         ? { '-and' => [
 359               map {
 360                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 361               } $having, $new_attrs->{having}
 362             ]
 363           }
 364         : $having);
 365   }
 366
 367   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 368
 369   $rs->set_cache($rows) if ($rows);
 370
 371   return $rs;
 372 }
 373
 374 =head2 search_literal
 375
 376 =over 4
 377
 378 =item Arguments: $sql_fragment, @bind_values
 379
 380 =item Return Value: $resultset (scalar context), @row_objs (list context)
 381
 382 =back
 383
 384   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 385   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 386
 387 Pass a literal chunk of SQL to be added to the conditional part of the
 388 resultset query.
 389
 390 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 391 only be used in that context. C<search_literal> is a convenience method.
 392 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 393 columns are bound correctly, use C<search>.
 394
 395 Example of how to use C<search> instead of C<search_literal>
 396
 397   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 398   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 399
 400
 401 See L<DBIx::Class::Manual::Cookbook/Searching> and
 402 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 403 require C<search_literal>.
 404
 405 =cut
 406
 407 sub search_literal {
 408   my ($self, $sql, @bind) = @_;
 409   my $attr;
 410   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 411     $attr = pop @bind;
 412   }
 413   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 414 }
 415
 416 =head2 find
 417
 418 =over 4
 419
 420 =item Arguments: @values | \%cols, \%attrs?
 421
 422 =item Return Value: $row_object | undef
 423
 424 =back
 425
 426 Finds a row based on its primary key or unique constraint. For example, to find
 427 a row by its primary key:
 428
 429   my $cd = $schema->resultset('CD')->find(5);
 430
 431 You can also find a row by a specific unique constraint using the C<key>
 432 attribute. For example:
 433
 434   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 435     key => 'cd_artist_title'
 436   });
 437
 438 Additionally, you can specify the columns explicitly by name:
 439
 440   my $cd = $schema->resultset('CD')->find(
 441     {
 442       artist => 'Massive Attack',
 443       title  => 'Mezzanine',
 444     },
 445     { key => 'cd_artist_title' }
 446   );
 447
 448 If the C<key> is specified as C<primary>, it searches only on the primary key.
 449
 450 If no C<key> is specified, it searches on all unique constraints defined on the
 451 source for which column data is provided, including the primary key.
 452
 453 If your table does not have a primary key, you B<must> provide a value for the
 454 C<key> attribute matching one of the unique constraints on the source.
 455
 456 In addition to C<key>, L</find> recognizes and applies standard
 457 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 458
 459 Note: If your query does not return only one row, a warning is generated:
 460
 461   Query returned more than one row
 462
 463 See also L</find_or_create> and L</update_or_create>. For information on how to
 464 declare unique constraints, see
 465 L<DBIx::Class::ResultSource/add_unique_constraint>.
 466
 467 =cut
 468
 469 sub find {
 470   my $self = shift;
 471   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 472
 473   # Default to the primary key, but allow a specific key
 474   my @cols = exists $attrs->{key}
 475     ? $self->result_source->unique_constraint_columns($attrs->{key})
 476     : $self->result_source->primary_columns;
 477   $self->throw_exception(
 478     "Can't find unless a primary key is defined or unique constraint is specified"
 479   ) unless @cols;
 480
 481   # Parse out a hashref from input
 482   my $input_query;
 483   if (ref $_[0] eq 'HASH') {
 484     $input_query = { %{$_[0]} };
 485   }
 486   elsif (@_ == @cols) {
 487     $input_query = {};
 488     @{$input_query}{@cols} = @_;
 489   }
 490   else {
 491     # Compatibility: Allow e.g. find(id => $value)
 492     carp "Find by key => value deprecated; please use a hashref instead";
 493     $input_query = {@_};
 494   }
 495
 496   my (%related, $info);
 497
 498   KEY: foreach my $key (keys %$input_query) {
 499     if (ref($input_query->{$key})
 500         && ($info = $self->result_source->relationship_info($key))) {
 501       my $val = delete $input_query->{$key};
 502       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 503       my $rel_q = $self->result_source->_resolve_condition(
 504                     $info->{cond}, $val, $key
 505                   );
 506       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 507       @related{keys %$rel_q} = values %$rel_q;
 508     }
 509   }
 510   if (my @keys = keys %related) {
 511     @{$input_query}{@keys} = values %related;
 512   }
 513
 514
 515   # Build the final query: Default to the disjunction of the unique queries,
 516   # but allow the input query in case the ResultSet defines the query or the
 517   # user is abusing find
 518   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 519   my $query;
 520   if (exists $attrs->{key}) {
 521     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 522     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 523     $query = $self->_add_alias($unique_query, $alias);
 524   }
 525   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 526     # This means that we got here after a merger of relationship conditions
 527     # in ::Relationship::Base::search_related (the row method), and furthermore
 528     # the relationship is of the 'single' type. This means that the condition
 529     # provided by the relationship (already attached to $self) is sufficient,
 530     # as there can be only one row in the database that would satisfy the
 531     # relationship
 532   }
 533   else {
 534     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 535     $query = @unique_queries
 536       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 537       : $self->_add_alias($input_query, $alias);
 538   }
 539
 540   # Run the query, passing the result_class since it should propagate for find
 541   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 542   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 543     my $row = $rs->next;
 544     carp "Query returned more than one row" if $rs->next;
 545     return $row;
 546   }
 547   else {
 548     return $rs->single;
 549   }
 550 }
 551
 552 # _add_alias
 553 #
 554 # Add the specified alias to the specified query hash. A copy is made so the
 555 # original query is not modified.
 556
 557 sub _add_alias {
 558   my ($self, $query, $alias) = @_;
 559
 560   my %aliased = %$query;
 561   foreach my $col (grep { ! m/\./ } keys %aliased) {
 562     $aliased{"$alias.$col"} = delete $aliased{$col};
 563   }
 564
 565   return \%aliased;
 566 }
 567
 568 # _unique_queries
 569 #
 570 # Build a list of queries which satisfy unique constraints.
 571
 572 sub _unique_queries {
 573   my ($self, $query, $attrs) = @_;
 574
 575   my @constraint_names = exists $attrs->{key}
 576     ? ($attrs->{key})
 577     : $self->result_source->unique_constraint_names;
 578
 579   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 580   my $num_where = scalar keys %$where;
 581
 582   my (@unique_queries, %seen_column_combinations);
 583   foreach my $name (@constraint_names) {
 584     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 585
 586     my $constraint_sig = join "\x00", sort @constraint_cols;
 587     next if $seen_column_combinations{$constraint_sig}++;
 588
 589     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 590
 591     my $num_cols = scalar @constraint_cols;
 592     my $num_query = scalar keys %$unique_query;
 593
 594     my $total = $num_query + $num_where;
 595     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 596       # The query is either unique on its own or is unique in combination with
 597       # the existing where clause
 598       push @unique_queries, $unique_query;
 599     }
 600   }
 601
 602   return @unique_queries;
 603 }
 604
 605 # _build_unique_query
 606 #
 607 # Constrain the specified query hash based on the specified column names.
 608
 609 sub _build_unique_query {
 610   my ($self, $query, $unique_cols) = @_;
 611
 612   return {
 613     map  { $_ => $query->{$_} }
 614     grep { exists $query->{$_} }
 615       @$unique_cols
 616   };
 617 }
 618
 619 =head2 search_related
 620
 621 =over 4
 622
 623 =item Arguments: $rel, $cond, \%attrs?
 624
 625 =item Return Value: $new_resultset
 626
 627 =back
 628
 629   $new_rs = $cd_rs->search_related('artist', {
 630     name => 'Emo-R-Us',
 631   });
 632
 633 Searches the specified relationship, optionally specifying a condition and
 634 attributes for matching records. See L</ATTRIBUTES> for more information.
 635
 636 =cut
 637
 638 sub search_related {
 639   return shift->related_resultset(shift)->search(@_);
 640 }
 641
 642 =head2 search_related_rs
 643
 644 This method works exactly the same as search_related, except that
 645 it guarantees a resultset, even in list context.
 646
 647 =cut
 648
 649 sub search_related_rs {
 650   return shift->related_resultset(shift)->search_rs(@_);
 651 }
 652
 653 =head2 cursor
 654
 655 =over 4
 656
 657 =item Arguments: none
 658
 659 =item Return Value: $cursor
 660
 661 =back
 662
 663 Returns a storage-driven cursor to the given resultset. See
 664 L<DBIx::Class::Cursor> for more information.
 665
 666 =cut
 667
 668 sub cursor {
 669   my ($self) = @_;
 670
 671   my $attrs = $self->_resolved_attrs_copy;
 672
 673   return $self->{cursor}
 674     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 675           $attrs->{where},$attrs);
 676 }
 677
 678 =head2 single
 679
 680 =over 4
 681
 682 =item Arguments: $cond?
 683
 684 =item Return Value: $row_object?
 685
 686 =back
 687
 688   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 689
 690 Inflates the first result without creating a cursor if the resultset has
 691 any records in it; if not returns nothing. Used by L</find> as a lean version of
 692 L</search>.
 693
 694 While this method can take an optional search condition (just like L</search>)
 695 being a fast-code-path it does not recognize search attributes. If you need to
 696 add extra joins or similar, call L</search> and then chain-call L</single> on the
 697 L<DBIx::Class::ResultSet> returned.
 698
 699 =over
 700
 701 =item B<Note>
 702
 703 As of 0.08100, this method enforces the assumption that the preceding
 704 query returns only one row. If more than one row is returned, you will receive
 705 a warning:
 706
 707   Query returned more than one row
 708
 709 In this case, you should be using L</next> or L</find> instead, or if you really
 710 know what you are doing, use the L</rows> attribute to explicitly limit the size
 711 of the resultset.
 712
 713 This method will also throw an exception if it is called on a resultset prefetching
 714 has_many, as such a prefetch implies fetching multiple rows from the database in
 715 order to assemble the resulting object.
 716
 717 =back
 718
 719 =cut
 720
 721 sub single {
 722   my ($self, $where) = @_;
 723   if(@_ > 2) {
 724       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 725   }
 726
 727   my $attrs = $self->_resolved_attrs_copy;
 728
 729   if (keys %{$attrs->{collapse}}) {
 730     $self->throw_exception(
 731       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 732     );
 733   }
 734
 735   if ($where) {
 736     if (defined $attrs->{where}) {
 737       $attrs->{where} = {
 738         '-and' =>
 739             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 740                $where, delete $attrs->{where} ]
 741       };
 742     } else {
 743       $attrs->{where} = $where;
 744     }
 745   }
 746
 747 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 748 #  unless ($self->_is_unique_query($attrs->{where})) {
 749 #    carp "Query not guaranteed to return a single row"
 750 #      . "; please declare your unique constraints or use search instead";
 751 #  }
 752
 753   my @data = $self->result_source->storage->select_single(
 754     $attrs->{from}, $attrs->{select},
 755     $attrs->{where}, $attrs
 756   );
 757
 758   return (@data ? ($self->_construct_object(@data))[0] : undef);
 759 }
 760
 761
 762 # _is_unique_query
 763 #
 764 # Try to determine if the specified query is guaranteed to be unique, based on
 765 # the declared unique constraints.
 766
 767 sub _is_unique_query {
 768   my ($self, $query) = @_;
 769
 770   my $collapsed = $self->_collapse_query($query);
 771   my $alias = $self->{attrs}{alias};
 772
 773   foreach my $name ($self->result_source->unique_constraint_names) {
 774     my @unique_cols = map {
 775       "$alias.$_"
 776     } $self->result_source->unique_constraint_columns($name);
 777
 778     # Count the values for each unique column
 779     my %seen = map { $_ => 0 } @unique_cols;
 780
 781     foreach my $key (keys %$collapsed) {
 782       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 783       next unless exists $seen{$aliased};  # Additional constraints are okay
 784       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 785     }
 786
 787     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 788     return 1 unless grep { $_ != 1 } values %seen;
 789   }
 790
 791   return 0;
 792 }
 793
 794 # _collapse_query
 795 #
 796 # Recursively collapse the query, accumulating values for each column.
 797
 798 sub _collapse_query {
 799   my ($self, $query, $collapsed) = @_;
 800
 801   $collapsed ||= {};
 802
 803   if (ref $query eq 'ARRAY') {
 804     foreach my $subquery (@$query) {
 805       next unless ref $subquery;  # -or
 806       $collapsed = $self->_collapse_query($subquery, $collapsed);
 807     }
 808   }
 809   elsif (ref $query eq 'HASH') {
 810     if (keys %$query and (keys %$query)[0] eq '-and') {
 811       foreach my $subquery (@{$query->{-and}}) {
 812         $collapsed = $self->_collapse_query($subquery, $collapsed);
 813       }
 814     }
 815     else {
 816       foreach my $col (keys %$query) {
 817         my $value = $query->{$col};
 818         $collapsed->{$col}{$value}++;
 819       }
 820     }
 821   }
 822
 823   return $collapsed;
 824 }
 825
 826 =head2 get_column
 827
 828 =over 4
 829
 830 =item Arguments: $cond?
 831
 832 =item Return Value: $resultsetcolumn
 833
 834 =back
 835
 836   my $max_length = $rs->get_column('length')->max;
 837
 838 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 839
 840 =cut
 841
 842 sub get_column {
 843   my ($self, $column) = @_;
 844   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 845   return $new;
 846 }
 847
 848 =head2 search_like
 849
 850 =over 4
 851
 852 =item Arguments: $cond, \%attrs?
 853
 854 =item Return Value: $resultset (scalar context), @row_objs (list context)
 855
 856 =back
 857
 858   # WHERE title LIKE '%blue%'
 859   $cd_rs = $rs->search_like({ title => '%blue%'});
 860
 861 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 862 that this is simply a convenience method retained for ex Class::DBI users.
 863 You most likely want to use L</search> with specific operators.
 864
 865 For more information, see L<DBIx::Class::Manual::Cookbook>.
 866
 867 This method is deprecated and will be removed in 0.09. Use L</search()>
 868 instead. An example conversion is:
 869
 870   ->search_like({ foo => 'bar' });
 871
 872   # Becomes
 873
 874   ->search({ foo => { like => 'bar' } });
 875
 876 =cut
 877
 878 sub search_like {
 879   my $class = shift;
 880   carp (
 881     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 882    .' Instead use ->search({ x => { -like => "y%" } })'
 883    .' (note the outer pair of {}s - they are important!)'
 884   );
 885   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 886   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 887   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 888   return $class->search($query, { %$attrs });
 889 }
 890
 891 =head2 slice
 892
 893 =over 4
 894
 895 =item Arguments: $first, $last
 896
 897 =item Return Value: $resultset (scalar context), @row_objs (list context)
 898
 899 =back
 900
 901 Returns a resultset or object list representing a subset of elements from the
 902 resultset slice is called on. Indexes are from 0, i.e., to get the first
 903 three records, call:
 904
 905   my ($one, $two, $three) = $rs->slice(0, 2);
 906
 907 =cut
 908
 909 sub slice {
 910   my ($self, $min, $max) = @_;
 911   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 912   $attrs->{offset} = $self->{attrs}{offset} || 0;
 913   $attrs->{offset} += $min;
 914   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 915   return $self->search(undef(), $attrs);
 916   #my $slice = (ref $self)->new($self->result_source, $attrs);
 917   #return (wantarray ? $slice->all : $slice);
 918 }
 919
 920 =head2 next
 921
 922 =over 4
 923
 924 =item Arguments: none
 925
 926 =item Return Value: $result?
 927
 928 =back
 929
 930 Returns the next element in the resultset (C<undef> is there is none).
 931
 932 Can be used to efficiently iterate over records in the resultset:
 933
 934   my $rs = $schema->resultset('CD')->search;
 935   while (my $cd = $rs->next) {
 936     print $cd->title;
 937   }
 938
 939 Note that you need to store the resultset object, and call C<next> on it.
 940 Calling C<< resultset('Table')->next >> repeatedly will always return the
 941 first record from the resultset.
 942
 943 =cut
 944
 945 sub next {
 946   my ($self) = @_;
 947   if (my $cache = $self->get_cache) {
 948     $self->{all_cache_position} ||= 0;
 949     return $cache->[$self->{all_cache_position}++];
 950   }
 951   if ($self->{attrs}{cache}) {
 952     $self->{all_cache_position} = 1;
 953     return ($self->all)[0];
 954   }
 955   if ($self->{stashed_objects}) {
 956     my $obj = shift(@{$self->{stashed_objects}});
 957     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 958     return $obj;
 959   }
 960   my @row = (
 961     exists $self->{stashed_row}
 962       ? @{delete $self->{stashed_row}}
 963       : $self->cursor->next
 964   );
 965   return undef unless (@row);
 966   my ($row, @more) = $self->_construct_object(@row);
 967   $self->{stashed_objects} = \@more if @more;
 968   return $row;
 969 }
 970
 971 sub _construct_object {
 972   my ($self, @row) = @_;
 973
 974   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 975     or return ();
 976   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 977   @new = $self->{_attrs}{record_filter}->(@new)
 978     if exists $self->{_attrs}{record_filter};
 979   return @new;
 980 }
 981
 982 sub _collapse_result {
 983   my ($self, $as_proto, $row) = @_;
 984
 985   my @copy = @$row;
 986
 987   # 'foo'         => [ undef, 'foo' ]
 988   # 'foo.bar'     => [ 'foo', 'bar' ]
 989   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 990
 991   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 992
 993   my %collapse = %{$self->{_attrs}{collapse}||{}};
 994
 995   my @pri_index;
 996
 997   # if we're doing collapsing (has_many prefetch) we need to grab records
 998   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 999   # we know we don't have to bother.
1000
1001   # the reason for not using the collapse stuff directly is because if you
1002   # had for e.g. two artists in a row with no cds, the collapse info for
1003   # both would be NULL (undef) so you'd lose the second artist
1004
1005   # store just the index so we can check the array positions from the row
1006   # without having to contruct the full hash
1007
1008   if (keys %collapse) {
1009     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1010     foreach my $i (0 .. $#construct_as) {
1011       next if defined($construct_as[$i][0]); # only self table
1012       if (delete $pri{$construct_as[$i][1]}) {
1013         push(@pri_index, $i);
1014       }
1015       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1016     }
1017   }
1018
1019   # no need to do an if, it'll be empty if @pri_index is empty anyway
1020
1021   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1022
1023   my @const_rows;
1024
1025   do { # no need to check anything at the front, we always want the first row
1026
1027     my %const;
1028
1029     foreach my $this_as (@construct_as) {
1030       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1031     }
1032
1033     push(@const_rows, \%const);
1034
1035   } until ( # no pri_index => no collapse => drop straight out
1036       !@pri_index
1037     or
1038       do { # get another row, stash it, drop out if different PK
1039
1040         @copy = $self->cursor->next;
1041         $self->{stashed_row} = \@copy;
1042
1043         # last thing in do block, counts as true if anything doesn't match
1044
1045         # check xor defined first for NULL vs. NOT NULL then if one is
1046         # defined the other must be so check string equality
1047
1048         grep {
1049           (defined $pri_vals{$_} ^ defined $copy[$_])
1050           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1051         } @pri_index;
1052       }
1053   );
1054
1055   my $alias = $self->{attrs}{alias};
1056   my $info = [];
1057
1058   my %collapse_pos;
1059
1060   my @const_keys;
1061
1062   foreach my $const (@const_rows) {
1063     scalar @const_keys or do {
1064       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1065     };
1066     foreach my $key (@const_keys) {
1067       if (length $key) {
1068         my $target = $info;
1069         my @parts = split(/\./, $key);
1070         my $cur = '';
1071         my $data = $const->{$key};
1072         foreach my $p (@parts) {
1073           $target = $target->[1]->{$p} ||= [];
1074           $cur .= ".${p}";
1075           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1076             # collapsing at this point and on final part
1077             my $pos = $collapse_pos{$cur};
1078             CK: foreach my $ck (@ckey) {
1079               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1080                 $collapse_pos{$cur} = $data;
1081                 delete @collapse_pos{ # clear all positioning for sub-entries
1082                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1083                 };
1084                 push(@$target, []);
1085                 last CK;
1086               }
1087             }
1088           }
1089           if (exists $collapse{$cur}) {
1090             $target = $target->[-1];
1091           }
1092         }
1093         $target->[0] = $data;
1094       } else {
1095         $info->[0] = $const->{$key};
1096       }
1097     }
1098   }
1099
1100   return $info;
1101 }
1102
1103 =head2 result_source
1104
1105 =over 4
1106
1107 =item Arguments: $result_source?
1108
1109 =item Return Value: $result_source
1110
1111 =back
1112
1113 An accessor for the primary ResultSource object from which this ResultSet
1114 is derived.
1115
1116 =head2 result_class
1117
1118 =over 4
1119
1120 =item Arguments: $result_class?
1121
1122 =item Return Value: $result_class
1123
1124 =back
1125
1126 An accessor for the class to use when creating row objects. Defaults to
1127 C<< result_source->result_class >> - which in most cases is the name of the
1128 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1129
1130 Note that changing the result_class will also remove any components
1131 that were originally loaded in the source class via
1132 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1133 in the original source class will not run.
1134
1135 =cut
1136
1137 sub result_class {
1138   my ($self, $result_class) = @_;
1139   if ($result_class) {
1140     unless (ref $result_class) { # don't fire this for an object
1141       $self->ensure_class_loaded($result_class);
1142     }
1143     $self->_result_class($result_class);
1144     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1145     # permit the user to set result class on one result set only; it only
1146     # chains if provided to search()
1147     #$self->{attrs}{result_class} = $result_class if ref $self;
1148   }
1149   $self->_result_class;
1150 }
1151
1152 =head2 count
1153
1154 =over 4
1155
1156 =item Arguments: $cond, \%attrs??
1157
1158 =item Return Value: $count
1159
1160 =back
1161
1162 Performs an SQL C<COUNT> with the same query as the resultset was built
1163 with to find the number of elements. Passing arguments is equivalent to
1164 C<< $rs->search ($cond, \%attrs)->count >>
1165
1166 =cut
1167
1168 sub count {
1169   my $self = shift;
1170   return $self->search(@_)->count if @_ and defined $_[0];
1171   return scalar @{ $self->get_cache } if $self->get_cache;
1172
1173   my $attrs = $self->_resolved_attrs_copy;
1174
1175   # this is a little optimization - it is faster to do the limit
1176   # adjustments in software, instead of a subquery
1177   my $rows = delete $attrs->{rows};
1178   my $offset = delete $attrs->{offset};
1179
1180   my $crs;
1181   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1182     $crs = $self->_count_subq_rs ($attrs);
1183   }
1184   else {
1185     $crs = $self->_count_rs ($attrs);
1186   }
1187   my $count = $crs->next;
1188
1189   $count -= $offset if $offset;
1190   $count = $rows if $rows and $rows < $count;
1191   $count = 0 if ($count < 0);
1192
1193   return $count;
1194 }
1195
1196 =head2 count_rs
1197
1198 =over 4
1199
1200 =item Arguments: $cond, \%attrs??
1201
1202 =item Return Value: $count_rs
1203
1204 =back
1205
1206 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1207 This can be very handy for subqueries:
1208
1209   ->search( { amount => $some_rs->count_rs->as_query } )
1210
1211 As with regular resultsets the SQL query will be executed only after
1212 the resultset is accessed via L</next> or L</all>. That would return
1213 the same single value obtainable via L</count>.
1214
1215 =cut
1216
1217 sub count_rs {
1218   my $self = shift;
1219   return $self->search(@_)->count_rs if @_;
1220
1221   # this may look like a lack of abstraction (count() does about the same)
1222   # but in fact an _rs *must* use a subquery for the limits, as the
1223   # software based limiting can not be ported if this $rs is to be used
1224   # in a subquery itself (i.e. ->as_query)
1225   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1226     return $self->_count_subq_rs;
1227   }
1228   else {
1229     return $self->_count_rs;
1230   }
1231 }
1232
1233 #
1234 # returns a ResultSetColumn object tied to the count query
1235 #
1236 sub _count_rs {
1237   my ($self, $attrs) = @_;
1238
1239   my $rsrc = $self->result_source;
1240   $attrs ||= $self->_resolved_attrs;
1241
1242   my $tmp_attrs = { %$attrs };
1243   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1244   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1251
1252   return $tmp_rs;
1253 }
1254
1255 #
1256 # same as above but uses a subquery
1257 #
1258 sub _count_subq_rs {
1259   my ($self, $attrs) = @_;
1260
1261   my $rsrc = $self->result_source;
1262   $attrs ||= $self->_resolved_attrs;
1263
1264   my $sub_attrs = { %$attrs };
1265   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1266   delete @{$sub_attrs}{qw/collapse select _prefetch_select as order_by for/};
1267
1268   # if we multi-prefetch we group_by primary keys only as this is what we would
1269   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1270   if ( keys %{$attrs->{collapse}}  ) {
1271     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1272   }
1273
1274   # Calculate subquery selector
1275   if (my $g = $sub_attrs->{group_by}) {
1276
1277     my $sql_maker = $rsrc->storage->sql_maker;
1278
1279     # necessary as the group_by may refer to aliased functions
1280     my $sel_index;
1281     for my $sel (@{$attrs->{select}}) {
1282       $sel_index->{$sel->{-as}} = $sel
1283         if (ref $sel eq 'HASH' and $sel->{-as});
1284     }
1285
1286     for my $g_part (@$g) {
1287       my $colpiece = $sel_index->{$g_part} || $g_part;
1288
1289       # disqualify join-based group_by's. Arcane but possible query
1290       # also horrible horrible hack to alias a column (not a func.)
1291       # (probably need to introduce SQLA syntax)
1292       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1293         my $as = $colpiece;
1294         $as =~ s/\./__/;
1295         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1296       }
1297       push @{$sub_attrs->{select}}, $colpiece;
1298     }
1299   }
1300   else {
1301     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1302     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1303   }
1304
1305   return $rsrc->resultset_class
1306                ->new ($rsrc, $sub_attrs)
1307                 ->as_subselect_rs
1308                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1309                   ->get_column ('count');
1310 }
1311
1312 sub _bool {
1313   return 1;
1314 }
1315
1316 =head2 count_literal
1317
1318 =over 4
1319
1320 =item Arguments: $sql_fragment, @bind_values
1321
1322 =item Return Value: $count
1323
1324 =back
1325
1326 Counts the results in a literal query. Equivalent to calling L</search_literal>
1327 with the passed arguments, then L</count>.
1328
1329 =cut
1330
1331 sub count_literal { shift->search_literal(@_)->count; }
1332
1333 =head2 all
1334
1335 =over 4
1336
1337 =item Arguments: none
1338
1339 =item Return Value: @objects
1340
1341 =back
1342
1343 Returns all elements in the resultset. Called implicitly if the resultset
1344 is returned in list context.
1345
1346 =cut
1347
1348 sub all {
1349   my $self = shift;
1350   if(@_) {
1351       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1352   }
1353
1354   return @{ $self->get_cache } if $self->get_cache;
1355
1356   my @obj;
1357
1358   if (keys %{$self->_resolved_attrs->{collapse}}) {
1359     # Using $self->cursor->all is really just an optimisation.
1360     # If we're collapsing has_many prefetches it probably makes
1361     # very little difference, and this is cleaner than hacking
1362     # _construct_object to survive the approach
1363     $self->cursor->reset;
1364     my @row = $self->cursor->next;
1365     while (@row) {
1366       push(@obj, $self->_construct_object(@row));
1367       @row = (exists $self->{stashed_row}
1368                ? @{delete $self->{stashed_row}}
1369                : $self->cursor->next);
1370     }
1371   } else {
1372     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1373   }
1374
1375   $self->set_cache(\@obj) if $self->{attrs}{cache};
1376
1377   return @obj;
1378 }
1379
1380 =head2 reset
1381
1382 =over 4
1383
1384 =item Arguments: none
1385
1386 =item Return Value: $self
1387
1388 =back
1389
1390 Resets the resultset's cursor, so you can iterate through the elements again.
1391 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1392 another query.
1393
1394 =cut
1395
1396 sub reset {
1397   my ($self) = @_;
1398   delete $self->{_attrs} if exists $self->{_attrs};
1399   $self->{all_cache_position} = 0;
1400   $self->cursor->reset;
1401   return $self;
1402 }
1403
1404 =head2 first
1405
1406 =over 4
1407
1408 =item Arguments: none
1409
1410 =item Return Value: $object?
1411
1412 =back
1413
1414 Resets the resultset and returns an object for the first result (if the
1415 resultset returns anything).
1416
1417 =cut
1418
1419 sub first {
1420   return $_[0]->reset->next;
1421 }
1422
1423
1424 # _rs_update_delete
1425 #
1426 # Determines whether and what type of subquery is required for the $rs operation.
1427 # If grouping is necessary either supplies its own, or verifies the current one
1428 # After all is done delegates to the proper storage method.
1429
1430 sub _rs_update_delete {
1431   my ($self, $op, $values) = @_;
1432
1433   my $rsrc = $self->result_source;
1434
1435   # if a condition exists we need to strip all table qualifiers
1436   # if this is not possible we'll force a subquery below
1437   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1438
1439   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1440   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/rows offset/);
1441
1442   if ($needs_group_by_subq or $needs_subq) {
1443
1444     # make a new $rs selecting only the PKs (that's all we really need)
1445     my $attrs = $self->_resolved_attrs_copy;
1446
1447
1448     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_select as/;
1449     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1450
1451     if ($needs_group_by_subq) {
1452       # make sure no group_by was supplied, or if there is one - make sure it matches
1453       # the columns compiled above perfectly. Anything else can not be sanely executed
1454       # on most databases so croak right then and there
1455
1456       if (my $g = $attrs->{group_by}) {
1457         my @current_group_by = map
1458           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1459           @$g
1460         ;
1461
1462         if (
1463           join ("\x00", sort @current_group_by)
1464             ne
1465           join ("\x00", sort @{$attrs->{columns}} )
1466         ) {
1467           $self->throw_exception (
1468             "You have just attempted a $op operation on a resultset which does group_by"
1469             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1470             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1471             . ' kind of queries. Please retry the operation with a modified group_by or'
1472             . ' without using one at all.'
1473           );
1474         }
1475       }
1476       else {
1477         $attrs->{group_by} = $attrs->{columns};
1478       }
1479     }
1480
1481     my $subrs = (ref $self)->new($rsrc, $attrs);
1482     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1483   }
1484   else {
1485     return $rsrc->storage->$op(
1486       $rsrc,
1487       $op eq 'update' ? $values : (),
1488       $cond,
1489     );
1490   }
1491 }
1492
1493 =head2 update
1494
1495 =over 4
1496
1497 =item Arguments: \%values
1498
1499 =item Return Value: $storage_rv
1500
1501 =back
1502
1503 Sets the specified columns in the resultset to the supplied values in a
1504 single query. Return value will be true if the update succeeded or false
1505 if no records were updated; exact type of success value is storage-dependent.
1506
1507 =cut
1508
1509 sub update {
1510   my ($self, $values) = @_;
1511   $self->throw_exception('Values for update must be a hash')
1512     unless ref $values eq 'HASH';
1513
1514   return $self->_rs_update_delete ('update', $values);
1515 }
1516
1517 =head2 update_all
1518
1519 =over 4
1520
1521 =item Arguments: \%values
1522
1523 =item Return Value: 1
1524
1525 =back
1526
1527 Fetches all objects and updates them one at a time. Note that C<update_all>
1528 will run DBIC cascade triggers, while L</update> will not.
1529
1530 =cut
1531
1532 sub update_all {
1533   my ($self, $values) = @_;
1534   $self->throw_exception('Values for update_all must be a hash')
1535     unless ref $values eq 'HASH';
1536
1537   my $guard = $self->result_source->schema->txn_scope_guard;
1538   $_->update($values) for $self->all;
1539   $guard->commit;
1540   return 1;
1541 }
1542
1543 =head2 delete
1544
1545 =over 4
1546
1547 =item Arguments: none
1548
1549 =item Return Value: $storage_rv
1550
1551 =back
1552
1553 Deletes the contents of the resultset from its result source. Note that this
1554 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1555 to run. See also L<DBIx::Class::Row/delete>.
1556
1557 Return value will be the number of rows deleted; exact type of return value
1558 is storage-dependent.
1559
1560 =cut
1561
1562 sub delete {
1563   my $self = shift;
1564   $self->throw_exception('delete does not accept any arguments')
1565     if @_;
1566
1567   return $self->_rs_update_delete ('delete');
1568 }
1569
1570 =head2 delete_all
1571
1572 =over 4
1573
1574 =item Arguments: none
1575
1576 =item Return Value: 1
1577
1578 =back
1579
1580 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1581 will run DBIC cascade triggers, while L</delete> will not.
1582
1583 =cut
1584
1585 sub delete_all {
1586   my $self = shift;
1587   $self->throw_exception('delete_all does not accept any arguments')
1588     if @_;
1589
1590   my $guard = $self->result_source->schema->txn_scope_guard;
1591   $_->delete for $self->all;
1592   $guard->commit;
1593   return 1;
1594 }
1595
1596 =head2 populate
1597
1598 =over 4
1599
1600 =item Arguments: \@data;
1601
1602 =back
1603
1604 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1605 For the arrayref of hashrefs style each hashref should be a structure suitable
1606 forsubmitting to a $resultset->create(...) method.
1607
1608 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1609 to insert the data, as this is a faster method.
1610
1611 Otherwise, each set of data is inserted into the database using
1612 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1613 accumulated into an array. The array itself, or an array reference
1614 is returned depending on scalar or list context.
1615
1616 Example:  Assuming an Artist Class that has many CDs Classes relating:
1617
1618   my $Artist_rs = $schema->resultset("Artist");
1619
1620   ## Void Context Example
1621   $Artist_rs->populate([
1622      { artistid => 4, name => 'Manufactured Crap', cds => [
1623         { title => 'My First CD', year => 2006 },
1624         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1625       ],
1626      },
1627      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1628         { title => 'My parents sold me to a record company', year => 2005 },
1629         { title => 'Why Am I So Ugly?', year => 2006 },
1630         { title => 'I Got Surgery and am now Popular', year => 2007 }
1631       ],
1632      },
1633   ]);
1634
1635   ## Array Context Example
1636   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1637     { name => "Artist One"},
1638     { name => "Artist Two"},
1639     { name => "Artist Three", cds=> [
1640     { title => "First CD", year => 2007},
1641     { title => "Second CD", year => 2008},
1642   ]}
1643   ]);
1644
1645   print $ArtistOne->name; ## response is 'Artist One'
1646   print $ArtistThree->cds->count ## reponse is '2'
1647
1648 For the arrayref of arrayrefs style,  the first element should be a list of the
1649 fieldsnames to which the remaining elements are rows being inserted.  For
1650 example:
1651
1652   $Arstist_rs->populate([
1653     [qw/artistid name/],
1654     [100, 'A Formally Unknown Singer'],
1655     [101, 'A singer that jumped the shark two albums ago'],
1656     [102, 'An actually cool singer'],
1657   ]);
1658
1659 Please note an important effect on your data when choosing between void and
1660 wantarray context. Since void context goes straight to C<insert_bulk> in
1661 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1662 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1663 create primary keys for you, you will find that your PKs are empty.  In this
1664 case you will have to use the wantarray context in order to create those
1665 values.
1666
1667 =cut
1668
1669 sub populate {
1670   my $self = shift;
1671
1672   # cruft placed in standalone method
1673   my $data = $self->_normalize_populate_args(@_);
1674
1675   if(defined wantarray) {
1676     my @created;
1677     foreach my $item (@$data) {
1678       push(@created, $self->create($item));
1679     }
1680     return wantarray ? @created : \@created;
1681   } else {
1682     my $first = $data->[0];
1683
1684     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1685     # it relationship data
1686     my (@rels, @columns);
1687     for (keys %$first) {
1688       my $ref = ref $first->{$_};
1689       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1690         ? push @rels, $_
1691         : push @columns, $_
1692       ;
1693     }
1694
1695     my @pks = $self->result_source->primary_columns;
1696
1697     ## do the belongs_to relationships
1698     foreach my $index (0..$#$data) {
1699
1700       # delegate to create() for any dataset without primary keys with specified relationships
1701       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1702         for my $r (@rels) {
1703           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1704             my @ret = $self->populate($data);
1705             return;
1706           }
1707         }
1708       }
1709
1710       foreach my $rel (@rels) {
1711         next unless ref $data->[$index]->{$rel} eq "HASH";
1712         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1713         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1714         my $related = $result->result_source->_resolve_condition(
1715           $result->result_source->relationship_info($reverse)->{cond},
1716           $self,
1717           $result,
1718         );
1719
1720         delete $data->[$index]->{$rel};
1721         $data->[$index] = {%{$data->[$index]}, %$related};
1722
1723         push @columns, keys %$related if $index == 0;
1724       }
1725     }
1726
1727     ## inherit the data locked in the conditions of the resultset
1728     my ($rs_data) = $self->_merge_cond_with_data({});
1729     delete @{$rs_data}{@columns};
1730     my @inherit_cols = keys %$rs_data;
1731     my @inherit_data = values %$rs_data;
1732
1733     ## do bulk insert on current row
1734     $self->result_source->storage->insert_bulk(
1735       $self->result_source,
1736       [@columns, @inherit_cols],
1737       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1738     );
1739
1740     ## do the has_many relationships
1741     foreach my $item (@$data) {
1742
1743       foreach my $rel (@rels) {
1744         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1745
1746         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1747      || $self->throw_exception('Cannot find the relating object.');
1748
1749         my $child = $parent->$rel;
1750
1751         my $related = $child->result_source->_resolve_condition(
1752           $parent->result_source->relationship_info($rel)->{cond},
1753           $child,
1754           $parent,
1755         );
1756
1757         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1758         my @populate = map { {%$_, %$related} } @rows_to_add;
1759
1760         $child->populate( \@populate );
1761       }
1762     }
1763   }
1764 }
1765
1766
1767 # populate() argumnets went over several incarnations
1768 # What we ultimately support is AoH
1769 sub _normalize_populate_args {
1770   my ($self, $arg) = @_;
1771
1772   if (ref $arg eq 'ARRAY') {
1773     if (ref $arg->[0] eq 'HASH') {
1774       return $arg;
1775     }
1776     elsif (ref $arg->[0] eq 'ARRAY') {
1777       my @ret;
1778       my @colnames = @{$arg->[0]};
1779       foreach my $values (@{$arg}[1 .. $#$arg]) {
1780         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
1781       }
1782       return \@ret;
1783     }
1784   }
1785
1786   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
1787 }
1788
1789 =head2 pager
1790
1791 =over 4
1792
1793 =item Arguments: none
1794
1795 =item Return Value: $pager
1796
1797 =back
1798
1799 Return Value a L<Data::Page> object for the current resultset. Only makes
1800 sense for queries with a C<page> attribute.
1801
1802 To get the full count of entries for a paged resultset, call
1803 C<total_entries> on the L<Data::Page> object.
1804
1805 =cut
1806
1807 sub pager {
1808   my ($self) = @_;
1809
1810   return $self->{pager} if $self->{pager};
1811
1812   my $attrs = $self->{attrs};
1813   $self->throw_exception("Can't create pager for non-paged rs")
1814     unless $self->{attrs}{page};
1815   $attrs->{rows} ||= 10;
1816
1817   # throw away the paging flags and re-run the count (possibly
1818   # with a subselect) to get the real total count
1819   my $count_attrs = { %$attrs };
1820   delete $count_attrs->{$_} for qw/rows offset page pager/;
1821   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1822
1823   return $self->{pager} = Data::Page->new(
1824     $total_count,
1825     $attrs->{rows},
1826     $self->{attrs}{page}
1827   );
1828 }
1829
1830 =head2 page
1831
1832 =over 4
1833
1834 =item Arguments: $page_number
1835
1836 =item Return Value: $rs
1837
1838 =back
1839
1840 Returns a resultset for the $page_number page of the resultset on which page
1841 is called, where each page contains a number of rows equal to the 'rows'
1842 attribute set on the resultset (10 by default).
1843
1844 =cut
1845
1846 sub page {
1847   my ($self, $page) = @_;
1848   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1849 }
1850
1851 =head2 new_result
1852
1853 =over 4
1854
1855 =item Arguments: \%vals
1856
1857 =item Return Value: $rowobject
1858
1859 =back
1860
1861 Creates a new row object in the resultset's result class and returns
1862 it. The row is not inserted into the database at this point, call
1863 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1864 will tell you whether the row object has been inserted or not.
1865
1866 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1867
1868 =cut
1869
1870 sub new_result {
1871   my ($self, $values) = @_;
1872   $self->throw_exception( "new_result needs a hash" )
1873     unless (ref $values eq 'HASH');
1874
1875   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
1876
1877   my %new = (
1878     %$merged_cond,
1879     @$cols_from_relations
1880       ? (-cols_from_relations => $cols_from_relations)
1881       : (),
1882     -source_handle => $self->_source_handle,
1883     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1884   );
1885
1886   return $self->result_class->new(\%new);
1887 }
1888
1889 # _merge_cond_with_data
1890 #
1891 # Takes a simple hash of K/V data and returns its copy merged with the
1892 # condition already present on the resultset. Additionally returns an
1893 # arrayref of value/condition names, which were inferred from related
1894 # objects (this is needed for in-memory related objects)
1895 sub _merge_cond_with_data {
1896   my ($self, $data) = @_;
1897
1898   my (%new_data, @cols_from_relations);
1899
1900   my $alias = $self->{attrs}{alias};
1901
1902   if (! defined $self->{cond}) {
1903     # just massage $data below
1904   }
1905   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
1906     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1907     @cols_from_relations = keys %new_data;
1908   }
1909   elsif (ref $self->{cond} ne 'HASH') {
1910     $self->throw_exception(
1911       "Can't abstract implicit construct, resultset condition not a hash"
1912     );
1913   }
1914   else {
1915     # precendence must be given to passed values over values inherited from
1916     # the cond, so the order here is important.
1917     my $collapsed_cond = $self->_collapse_cond($self->{cond});
1918     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
1919
1920     while ( my($col, $value) = each %implied ) {
1921       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
1922         $new_data{$col} = $value->{'='};
1923         next;
1924       }
1925       $new_data{$col} = $value if $self->_is_deterministic_value($value);
1926     }
1927   }
1928
1929   %new_data = (
1930     %new_data,
1931     %{ $self->_remove_alias($data, $alias) },
1932   );
1933
1934   return (\%new_data, \@cols_from_relations);
1935 }
1936
1937 # _is_deterministic_value
1938 #
1939 # Make an effor to strip non-deterministic values from the condition,
1940 # to make sure new_result chokes less
1941
1942 sub _is_deterministic_value {
1943   my $self = shift;
1944   my $value = shift;
1945   my $ref_type = ref $value;
1946   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1947   return 1 if blessed $value;
1948   return 0;
1949 }
1950
1951 # _has_resolved_attr
1952 #
1953 # determines if the resultset defines at least one
1954 # of the attributes supplied
1955 #
1956 # used to determine if a subquery is neccessary
1957 #
1958 # supports some virtual attributes:
1959 #   -join
1960 #     This will scan for any joins being present on the resultset.
1961 #     It is not a mere key-search but a deep inspection of {from}
1962 #
1963
1964 sub _has_resolved_attr {
1965   my ($self, @attr_names) = @_;
1966
1967   my $attrs = $self->_resolved_attrs;
1968
1969   my %extra_checks;
1970
1971   for my $n (@attr_names) {
1972     if (grep { $n eq $_ } (qw/-join/) ) {
1973       $extra_checks{$n}++;
1974       next;
1975     }
1976
1977     my $attr =  $attrs->{$n};
1978
1979     next if not defined $attr;
1980
1981     if (ref $attr eq 'HASH') {
1982       return 1 if keys %$attr;
1983     }
1984     elsif (ref $attr eq 'ARRAY') {
1985       return 1 if @$attr;
1986     }
1987     else {
1988       return 1 if $attr;
1989     }
1990   }
1991
1992   # a resolved join is expressed as a multi-level from
1993   return 1 if (
1994     $extra_checks{-join}
1995       and
1996     ref $attrs->{from} eq 'ARRAY'
1997       and
1998     @{$attrs->{from}} > 1
1999   );
2000
2001   return 0;
2002 }
2003
2004 # _collapse_cond
2005 #
2006 # Recursively collapse the condition.
2007
2008 sub _collapse_cond {
2009   my ($self, $cond, $collapsed) = @_;
2010
2011   $collapsed ||= {};
2012
2013   if (ref $cond eq 'ARRAY') {
2014     foreach my $subcond (@$cond) {
2015       next unless ref $subcond;  # -or
2016       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2017     }
2018   }
2019   elsif (ref $cond eq 'HASH') {
2020     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2021       foreach my $subcond (@{$cond->{-and}}) {
2022         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2023       }
2024     }
2025     else {
2026       foreach my $col (keys %$cond) {
2027         my $value = $cond->{$col};
2028         $collapsed->{$col} = $value;
2029       }
2030     }
2031   }
2032
2033   return $collapsed;
2034 }
2035
2036 # _remove_alias
2037 #
2038 # Remove the specified alias from the specified query hash. A copy is made so
2039 # the original query is not modified.
2040
2041 sub _remove_alias {
2042   my ($self, $query, $alias) = @_;
2043
2044   my %orig = %{ $query || {} };
2045   my %unaliased;
2046
2047   foreach my $key (keys %orig) {
2048     if ($key !~ /\./) {
2049       $unaliased{$key} = $orig{$key};
2050       next;
2051     }
2052     $unaliased{$1} = $orig{$key}
2053       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2054   }
2055
2056   return \%unaliased;
2057 }
2058
2059 =head2 as_query
2060
2061 =over 4
2062
2063 =item Arguments: none
2064
2065 =item Return Value: \[ $sql, @bind ]
2066
2067 =back
2068
2069 Returns the SQL query and bind vars associated with the invocant.
2070
2071 This is generally used as the RHS for a subquery.
2072
2073 =cut
2074
2075 sub as_query {
2076   my $self = shift;
2077
2078   my $attrs = $self->_resolved_attrs_copy;
2079
2080   # For future use:
2081   #
2082   # in list ctx:
2083   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2084   # $sql also has no wrapping parenthesis in list ctx
2085   #
2086   my $sqlbind = $self->result_source->storage
2087     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2088
2089   return $sqlbind;
2090 }
2091
2092 =head2 find_or_new
2093
2094 =over 4
2095
2096 =item Arguments: \%vals, \%attrs?
2097
2098 =item Return Value: $rowobject
2099
2100 =back
2101
2102   my $artist = $schema->resultset('Artist')->find_or_new(
2103     { artist => 'fred' }, { key => 'artists' });
2104
2105   $cd->cd_to_producer->find_or_new({ producer => $producer },
2106                                    { key => 'primary });
2107
2108 Find an existing record from this resultset, based on its primary
2109 key, or a unique constraint. If none exists, instantiate a new result
2110 object and return it. The object will not be saved into your storage
2111 until you call L<DBIx::Class::Row/insert> on it.
2112
2113 You most likely want this method when looking for existing rows using
2114 a unique constraint that is not the primary key, or looking for
2115 related rows.
2116
2117 If you want objects to be saved immediately, use L</find_or_create>
2118 instead.
2119
2120 B<Note>: Take care when using C<find_or_new> with a table having
2121 columns with default values that you intend to be automatically
2122 supplied by the database (e.g. an auto_increment primary key column).
2123 In normal usage, the value of such columns should NOT be included at
2124 all in the call to C<find_or_new>, even when set to C<undef>.
2125
2126 =cut
2127
2128 sub find_or_new {
2129   my $self     = shift;
2130   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2131   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2132   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2133     return $row;
2134   }
2135   return $self->new_result($hash);
2136 }
2137
2138 =head2 create
2139
2140 =over 4
2141
2142 =item Arguments: \%vals
2143
2144 =item Return Value: a L<DBIx::Class::Row> $object
2145
2146 =back
2147
2148 Attempt to create a single new row or a row with multiple related rows
2149 in the table represented by the resultset (and related tables). This
2150 will not check for duplicate rows before inserting, use
2151 L</find_or_create> to do that.
2152
2153 To create one row for this resultset, pass a hashref of key/value
2154 pairs representing the columns of the table and the values you wish to
2155 store. If the appropriate relationships are set up, foreign key fields
2156 can also be passed an object representing the foreign row, and the
2157 value will be set to its primary key.
2158
2159 To create related objects, pass a hashref of related-object column values
2160 B<keyed on the relationship name>. If the relationship is of type C<multi>
2161 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2162 The process will correctly identify columns holding foreign keys, and will
2163 transparently populate them from the keys of the corresponding relation.
2164 This can be applied recursively, and will work correctly for a structure
2165 with an arbitrary depth and width, as long as the relationships actually
2166 exists and the correct column data has been supplied.
2167
2168
2169 Instead of hashrefs of plain related data (key/value pairs), you may
2170 also pass new or inserted objects. New objects (not inserted yet, see
2171 L</new>), will be inserted into their appropriate tables.
2172
2173 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2174
2175 Example of creating a new row.
2176
2177   $person_rs->create({
2178     name=>"Some Person",
2179     email=>"somebody@someplace.com"
2180   });
2181
2182 Example of creating a new row and also creating rows in a related C<has_many>
2183 or C<has_one> resultset.  Note Arrayref.
2184
2185   $artist_rs->create(
2186      { artistid => 4, name => 'Manufactured Crap', cds => [
2187         { title => 'My First CD', year => 2006 },
2188         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2189       ],
2190      },
2191   );
2192
2193 Example of creating a new row and also creating a row in a related
2194 C<belongs_to> resultset. Note Hashref.
2195
2196   $cd_rs->create({
2197     title=>"Music for Silly Walks",
2198     year=>2000,
2199     artist => {
2200       name=>"Silly Musician",
2201     }
2202   });
2203
2204 =over
2205
2206 =item WARNING
2207
2208 When subclassing ResultSet never attempt to override this method. Since
2209 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2210 lot of the internals simply never call it, so your override will be
2211 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2212 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2213 L</create> process you need to intervene.
2214
2215 =back
2216
2217 =cut
2218
2219 sub create {
2220   my ($self, $attrs) = @_;
2221   $self->throw_exception( "create needs a hashref" )
2222     unless ref $attrs eq 'HASH';
2223   return $self->new_result($attrs)->insert;
2224 }
2225
2226 =head2 find_or_create
2227
2228 =over 4
2229
2230 =item Arguments: \%vals, \%attrs?
2231
2232 =item Return Value: $rowobject
2233
2234 =back
2235
2236   $cd->cd_to_producer->find_or_create({ producer => $producer },
2237                                       { key => 'primary' });
2238
2239 Tries to find a record based on its primary key or unique constraints; if none
2240 is found, creates one and returns that instead.
2241
2242   my $cd = $schema->resultset('CD')->find_or_create({
2243     cdid   => 5,
2244     artist => 'Massive Attack',
2245     title  => 'Mezzanine',
2246     year   => 2005,
2247   });
2248
2249 Also takes an optional C<key> attribute, to search by a specific key or unique
2250 constraint. For example:
2251
2252   my $cd = $schema->resultset('CD')->find_or_create(
2253     {
2254       artist => 'Massive Attack',
2255       title  => 'Mezzanine',
2256     },
2257     { key => 'cd_artist_title' }
2258   );
2259
2260 B<Note>: Because find_or_create() reads from the database and then
2261 possibly inserts based on the result, this method is subject to a race
2262 condition. Another process could create a record in the table after
2263 the find has completed and before the create has started. To avoid
2264 this problem, use find_or_create() inside a transaction.
2265
2266 B<Note>: Take care when using C<find_or_create> with a table having
2267 columns with default values that you intend to be automatically
2268 supplied by the database (e.g. an auto_increment primary key column).
2269 In normal usage, the value of such columns should NOT be included at
2270 all in the call to C<find_or_create>, even when set to C<undef>.
2271
2272 See also L</find> and L</update_or_create>. For information on how to declare
2273 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2274
2275 =cut
2276
2277 sub find_or_create {
2278   my $self     = shift;
2279   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2280   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2281   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2282     return $row;
2283   }
2284   return $self->create($hash);
2285 }
2286
2287 =head2 update_or_create
2288
2289 =over 4
2290
2291 =item Arguments: \%col_values, { key => $unique_constraint }?
2292
2293 =item Return Value: $rowobject
2294
2295 =back
2296
2297   $resultset->update_or_create({ col => $val, ... });
2298
2299 First, searches for an existing row matching one of the unique constraints
2300 (including the primary key) on the source of this resultset. If a row is
2301 found, updates it with the other given column values. Otherwise, creates a new
2302 row.
2303
2304 Takes an optional C<key> attribute to search on a specific unique constraint.
2305 For example:
2306
2307   # In your application
2308   my $cd = $schema->resultset('CD')->update_or_create(
2309     {
2310       artist => 'Massive Attack',
2311       title  => 'Mezzanine',
2312       year   => 1998,
2313     },
2314     { key => 'cd_artist_title' }
2315   );
2316
2317   $cd->cd_to_producer->update_or_create({
2318     producer => $producer,
2319     name => 'harry',
2320   }, {
2321     key => 'primary',
2322   });
2323
2324
2325 If no C<key> is specified, it searches on all unique constraints defined on the
2326 source, including the primary key.
2327
2328 If the C<key> is specified as C<primary>, it searches only on the primary key.
2329
2330 See also L</find> and L</find_or_create>. For information on how to declare
2331 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2332
2333 B<Note>: Take care when using C<update_or_create> with a table having
2334 columns with default values that you intend to be automatically
2335 supplied by the database (e.g. an auto_increment primary key column).
2336 In normal usage, the value of such columns should NOT be included at
2337 all in the call to C<update_or_create>, even when set to C<undef>.
2338
2339 =cut
2340
2341 sub update_or_create {
2342   my $self = shift;
2343   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2344   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2345
2346   my $row = $self->find($cond, $attrs);
2347   if (defined $row) {
2348     $row->update($cond);
2349     return $row;
2350   }
2351
2352   return $self->create($cond);
2353 }
2354
2355 =head2 update_or_new
2356
2357 =over 4
2358
2359 =item Arguments: \%col_values, { key => $unique_constraint }?
2360
2361 =item Return Value: $rowobject
2362
2363 =back
2364
2365   $resultset->update_or_new({ col => $val, ... });
2366
2367 First, searches for an existing row matching one of the unique constraints
2368 (including the primary key) on the source of this resultset. If a row is
2369 found, updates it with the other given column values. Otherwise, instantiate
2370 a new result object and return it. The object will not be saved into your storage
2371 until you call L<DBIx::Class::Row/insert> on it.
2372
2373 Takes an optional C<key> attribute to search on a specific unique constraint.
2374 For example:
2375
2376   # In your application
2377   my $cd = $schema->resultset('CD')->update_or_new(
2378     {
2379       artist => 'Massive Attack',
2380       title  => 'Mezzanine',
2381       year   => 1998,
2382     },
2383     { key => 'cd_artist_title' }
2384   );
2385
2386   if ($cd->in_storage) {
2387       # the cd was updated
2388   }
2389   else {
2390       # the cd is not yet in the database, let's insert it
2391       $cd->insert;
2392   }
2393
2394 B<Note>: Take care when using C<update_or_new> with a table having
2395 columns with default values that you intend to be automatically
2396 supplied by the database (e.g. an auto_increment primary key column).
2397 In normal usage, the value of such columns should NOT be included at
2398 all in the call to C<update_or_new>, even when set to C<undef>.
2399
2400 See also L</find>, L</find_or_create> and L</find_or_new>.
2401
2402 =cut
2403
2404 sub update_or_new {
2405     my $self  = shift;
2406     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2407     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2408
2409     my $row = $self->find( $cond, $attrs );
2410     if ( defined $row ) {
2411         $row->update($cond);
2412         return $row;
2413     }
2414
2415     return $self->new_result($cond);
2416 }
2417
2418 =head2 get_cache
2419
2420 =over 4
2421
2422 =item Arguments: none
2423
2424 =item Return Value: \@cache_objects?
2425
2426 =back
2427
2428 Gets the contents of the cache for the resultset, if the cache is set.
2429
2430 The cache is populated either by using the L</prefetch> attribute to
2431 L</search> or by calling L</set_cache>.
2432
2433 =cut
2434
2435 sub get_cache {
2436   shift->{all_cache};
2437 }
2438
2439 =head2 set_cache
2440
2441 =over 4
2442
2443 =item Arguments: \@cache_objects
2444
2445 =item Return Value: \@cache_objects
2446
2447 =back
2448
2449 Sets the contents of the cache for the resultset. Expects an arrayref
2450 of objects of the same class as those produced by the resultset. Note that
2451 if the cache is set the resultset will return the cached objects rather
2452 than re-querying the database even if the cache attr is not set.
2453
2454 The contents of the cache can also be populated by using the
2455 L</prefetch> attribute to L</search>.
2456
2457 =cut
2458
2459 sub set_cache {
2460   my ( $self, $data ) = @_;
2461   $self->throw_exception("set_cache requires an arrayref")
2462       if defined($data) && (ref $data ne 'ARRAY');
2463   $self->{all_cache} = $data;
2464 }
2465
2466 =head2 clear_cache
2467
2468 =over 4
2469
2470 =item Arguments: none
2471
2472 =item Return Value: []
2473
2474 =back
2475
2476 Clears the cache for the resultset.
2477
2478 =cut
2479
2480 sub clear_cache {
2481   shift->set_cache(undef);
2482 }
2483
2484 =head2 is_paged
2485
2486 =over 4
2487
2488 =item Arguments: none
2489
2490 =item Return Value: true, if the resultset has been paginated
2491
2492 =back
2493
2494 =cut
2495
2496 sub is_paged {
2497   my ($self) = @_;
2498   return !!$self->{attrs}{page};
2499 }
2500
2501 =head2 is_ordered
2502
2503 =over 4
2504
2505 =item Arguments: none
2506
2507 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2508
2509 =back
2510
2511 =cut
2512
2513 sub is_ordered {
2514   my ($self) = @_;
2515   return scalar $self->result_source->storage->_parse_order_by($self->{attrs}{order_by});
2516 }
2517
2518 =head2 related_resultset
2519
2520 =over 4
2521
2522 =item Arguments: $relationship_name
2523
2524 =item Return Value: $resultset
2525
2526 =back
2527
2528 Returns a related resultset for the supplied relationship name.
2529
2530   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2531
2532 =cut
2533
2534 sub related_resultset {
2535   my ($self, $rel) = @_;
2536
2537   $self->{related_resultsets} ||= {};
2538   return $self->{related_resultsets}{$rel} ||= do {
2539     my $rsrc = $self->result_source;
2540     my $rel_info = $rsrc->relationship_info($rel);
2541
2542     $self->throw_exception(
2543       "search_related: result source '" . $rsrc->source_name .
2544         "' has no such relationship $rel")
2545       unless $rel_info;
2546
2547     my $attrs = $self->_chain_relationship($rel);
2548
2549     my $join_count = $attrs->{seen_join}{$rel};
2550
2551     my $alias = $self->result_source->storage
2552         ->relname_to_table_alias($rel, $join_count);
2553
2554     # since this is search_related, and we already slid the select window inwards
2555     # (the select/as attrs were deleted in the beginning), we need to flip all
2556     # left joins to inner, so we get the expected results
2557     # read the comment on top of the actual function to see what this does
2558     $attrs->{from} = $rsrc->schema->storage->_straight_join_to_node ($attrs->{from}, $alias);
2559
2560
2561     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2562     delete @{$attrs}{qw(result_class alias)};
2563
2564     my $new_cache;
2565
2566     if (my $cache = $self->get_cache) {
2567       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2568         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2569                         @$cache ];
2570       }
2571     }
2572
2573     my $rel_source = $rsrc->related_source($rel);
2574
2575     my $new = do {
2576
2577       # The reason we do this now instead of passing the alias to the
2578       # search_rs below is that if you wrap/overload resultset on the
2579       # source you need to know what alias it's -going- to have for things
2580       # to work sanely (e.g. RestrictWithObject wants to be able to add
2581       # extra query restrictions, and these may need to be $alias.)
2582
2583       my $rel_attrs = $rel_source->resultset_attributes;
2584       local $rel_attrs->{alias} = $alias;
2585
2586       $rel_source->resultset
2587                  ->search_rs(
2588                      undef, {
2589                        %$attrs,
2590                        where => $attrs->{where},
2591                    });
2592     };
2593     $new->set_cache($new_cache) if $new_cache;
2594     $new;
2595   };
2596 }
2597
2598 =head2 current_source_alias
2599
2600 =over 4
2601
2602 =item Arguments: none
2603
2604 =item Return Value: $source_alias
2605
2606 =back
2607
2608 Returns the current table alias for the result source this resultset is built
2609 on, that will be used in the SQL query. Usually it is C<me>.
2610
2611 Currently the source alias that refers to the result set returned by a
2612 L</search>/L</find> family method depends on how you got to the resultset: it's
2613 C<me> by default, but eg. L</search_related> aliases it to the related result
2614 source name (and keeps C<me> referring to the original result set). The long
2615 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2616 (and make this method unnecessary).
2617
2618 Thus it's currently necessary to use this method in predefined queries (see
2619 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2620 source alias of the current result set:
2621
2622   # in a result set class
2623   sub modified_by {
2624     my ($self, $user) = @_;
2625
2626     my $me = $self->current_source_alias;
2627
2628     return $self->search(
2629       "$me.modified" => $user->id,
2630     );
2631   }
2632
2633 =cut
2634
2635 sub current_source_alias {
2636   my ($self) = @_;
2637
2638   return ($self->{attrs} || {})->{alias} || 'me';
2639 }
2640
2641 =head2 as_subselect_rs
2642
2643 =over 4
2644
2645 =item Arguments: none
2646
2647 =item Return Value: $resultset
2648
2649 =back
2650
2651 Act as a barrier to SQL symbols.  The resultset provided will be made into a
2652 "virtual view" by including it as a subquery within the from clause.  From this
2653 point on, any joined tables are inaccessible to ->search on the resultset (as if
2654 it were simply where-filtered without joins).  For example:
2655
2656  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
2657
2658  # 'x' now pollutes the query namespace
2659
2660  # So the following works as expected
2661  my $ok_rs = $rs->search({'x.other' => 1});
2662
2663  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
2664  # def) we look for one row with contradictory terms and join in another table
2665  # (aliased 'x_2') which we never use
2666  my $broken_rs = $rs->search({'x.name' => 'def'});
2667
2668  my $rs2 = $rs->as_subselect_rs;
2669
2670  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
2671  my $not_joined_rs = $rs2->search({'x.other' => 1});
2672
2673  # works as expected: finds a 'table' row related to two x rows (abc and def)
2674  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
2675
2676 Another example of when one might use this would be to select a subset of
2677 columns in a group by clause:
2678
2679  my $rs = $schema->resultset('Bar')->search(undef, {
2680    group_by => [qw{ id foo_id baz_id }],
2681  })->as_subselect_rs->search(undef, {
2682    columns => [qw{ id foo_id }]
2683  });
2684
2685 In the above example normally columns would have to be equal to the group by,
2686 but because we isolated the group by into a subselect the above works.
2687
2688 =cut
2689
2690 sub as_subselect_rs {
2691   my $self = shift;
2692
2693   my $attrs = $self->_resolved_attrs;
2694
2695   my $fresh_rs = (ref $self)->new (
2696     $self->result_source
2697   );
2698
2699   # these pieces will be locked in the subquery
2700   delete $fresh_rs->{cond};
2701   delete @{$fresh_rs->{attrs}}{qw/where bind/};
2702
2703   return $fresh_rs->search( {}, {
2704     from => [{
2705       $attrs->{alias} => $self->as_query,
2706       -alias         => $attrs->{alias},
2707       -source_handle => $self->result_source->handle,
2708     }],
2709     alias => $attrs->{alias},
2710   });
2711 }
2712
2713 # This code is called by search_related, and makes sure there
2714 # is clear separation between the joins before, during, and
2715 # after the relationship. This information is needed later
2716 # in order to properly resolve prefetch aliases (any alias
2717 # with a relation_chain_depth less than the depth of the
2718 # current prefetch is not considered)
2719 #
2720 # The increments happen twice per join. An even number means a
2721 # relationship specified via a search_related, whereas an odd
2722 # number indicates a join/prefetch added via attributes
2723 #
2724 # Also this code will wrap the current resultset (the one we
2725 # chain to) in a subselect IFF it contains limiting attributes
2726 sub _chain_relationship {
2727   my ($self, $rel) = @_;
2728   my $source = $self->result_source;
2729   my $attrs = { %{$self->{attrs}||{}} };
2730
2731   # we need to take the prefetch the attrs into account before we
2732   # ->_resolve_join as otherwise they get lost - captainL
2733   my $join = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2734
2735   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
2736
2737   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
2738
2739   my $from;
2740   my @force_subq_attrs = qw/offset rows group_by having/;
2741
2742   if (
2743     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
2744       ||
2745     $self->_has_resolved_attr (@force_subq_attrs)
2746   ) {
2747     # Nuke the prefetch (if any) before the new $rs attrs
2748     # are resolved (prefetch is useless - we are wrapping
2749     # a subquery anyway).
2750     my $rs_copy = $self->search;
2751     $rs_copy->{attrs}{join} = $self->_merge_attr (
2752       $rs_copy->{attrs}{join},
2753       delete $rs_copy->{attrs}{prefetch},
2754     );
2755
2756     $from = [{
2757       -source_handle => $source->handle,
2758       -alias => $attrs->{alias},
2759       $attrs->{alias} => $rs_copy->as_query,
2760     }];
2761     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
2762     $seen->{-relation_chain_depth} = 0;
2763   }
2764   elsif ($attrs->{from}) {  #shallow copy suffices
2765     $from = [ @{$attrs->{from}} ];
2766   }
2767   else {
2768     $from = [{
2769       -source_handle => $source->handle,
2770       -alias => $attrs->{alias},
2771       $attrs->{alias} => $source->from,
2772     }];
2773   }
2774
2775   my $jpath = ($seen->{-relation_chain_depth})
2776     ? $from->[-1][0]{-join_path}
2777     : [];
2778
2779   my @requested_joins = $source->_resolve_join(
2780     $join,
2781     $attrs->{alias},
2782     $seen,
2783     $jpath,
2784   );
2785
2786   push @$from, @requested_joins;
2787
2788   $seen->{-relation_chain_depth}++;
2789
2790   # if $self already had a join/prefetch specified on it, the requested
2791   # $rel might very well be already included. What we do in this case
2792   # is effectively a no-op (except that we bump up the chain_depth on
2793   # the join in question so we could tell it *is* the search_related)
2794   my $already_joined;
2795
2796   # we consider the last one thus reverse
2797   for my $j (reverse @requested_joins) {
2798     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
2799     if ($rel eq $last_j) {
2800       $j->[0]{-relation_chain_depth}++;
2801       $already_joined++;
2802       last;
2803     }
2804   }
2805
2806   unless ($already_joined) {
2807     push @$from, $source->_resolve_join(
2808       $rel,
2809       $attrs->{alias},
2810       $seen,
2811       $jpath,
2812     );
2813   }
2814
2815   $seen->{-relation_chain_depth}++;
2816
2817   return {%$attrs, from => $from, seen_join => $seen};
2818 }
2819
2820 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2821 sub _resolved_attrs_copy {
2822   my $self = shift;
2823   return { %{$self->_resolved_attrs (@_)} };
2824 }
2825
2826 sub _resolved_attrs {
2827   my $self = shift;
2828   return $self->{_attrs} if $self->{_attrs};
2829
2830   my $attrs  = { %{ $self->{attrs} || {} } };
2831   my $source = $self->result_source;
2832   my $alias  = $attrs->{alias};
2833
2834   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2835   my @colbits;
2836
2837   # build columns (as long as select isn't set) into a set of as/select hashes
2838   unless ( $attrs->{select} ) {
2839
2840     my @cols;
2841     if ( ref $attrs->{columns} eq 'ARRAY' ) {
2842       @cols = @{ delete $attrs->{columns}}
2843     } elsif ( defined $attrs->{columns} ) {
2844       @cols = delete $attrs->{columns}
2845     } else {
2846       @cols = $source->columns
2847     }
2848
2849     for (@cols) {
2850       if ( ref $_ eq 'HASH' ) {
2851         push @colbits, $_
2852       } else {
2853         my $key = /^\Q${alias}.\E(.+)$/
2854           ? "$1"
2855           : "$_";
2856         my $value = /\./
2857           ? "$_"
2858           : "${alias}.$_";
2859         push @colbits, { $key => $value };
2860       }
2861     }
2862   }
2863
2864   # add the additional columns on
2865   foreach (qw{include_columns +columns}) {
2866     if ( $attrs->{$_} ) {
2867       my @list = ( ref($attrs->{$_}) eq 'ARRAY' )
2868         ? @{ delete $attrs->{$_} }
2869         : delete $attrs->{$_};
2870       for (@list) {
2871         if ( ref($_) eq 'HASH' ) {
2872           push @colbits, $_
2873         } else {
2874           my $key = ( split /\./, $_ )[-1];
2875           my $value = ( /\./ ? $_ : "$alias.$_" );
2876           push @colbits, { $key => $value };
2877         }
2878       }
2879     }
2880   }
2881
2882   # start with initial select items
2883   if ( $attrs->{select} ) {
2884     $attrs->{select} =
2885         ( ref $attrs->{select} eq 'ARRAY' )
2886       ? [ @{ $attrs->{select} } ]
2887       : [ $attrs->{select} ];
2888
2889     if ( $attrs->{as} ) {
2890       $attrs->{as} =
2891         (
2892           ref $attrs->{as} eq 'ARRAY'
2893             ? [ @{ $attrs->{as} } ]
2894             : [ $attrs->{as} ]
2895         )
2896     } else {
2897       $attrs->{as} = [ map {
2898          m/^\Q${alias}.\E(.+)$/
2899            ? $1
2900            : $_
2901          } @{ $attrs->{select} }
2902       ]
2903     }
2904   }
2905   else {
2906
2907     # otherwise we intialise select & as to empty
2908     $attrs->{select} = [];
2909     $attrs->{as}     = [];
2910   }
2911
2912   # now add colbits to select/as
2913   push @{ $attrs->{select} }, map values %{$_}, @colbits;
2914   push @{ $attrs->{as}     }, map keys   %{$_}, @colbits;
2915
2916   if ( my $adds = delete $attrs->{'+select'} ) {
2917     $adds = [$adds] unless ref $adds eq 'ARRAY';
2918     push @{ $attrs->{select} },
2919       map { /\./ || ref $_ ? $_ : "$alias.$_" } @$adds;
2920   }
2921   if ( my $adds = delete $attrs->{'+as'} ) {
2922     $adds = [$adds] unless ref $adds eq 'ARRAY';
2923     push @{ $attrs->{as} }, @$adds;
2924   }
2925
2926   $attrs->{from} ||= [{
2927     -source_handle => $source->handle,
2928     -alias => $self->{attrs}{alias},
2929     $self->{attrs}{alias} => $source->from,
2930   }];
2931
2932   if ( $attrs->{join} || $attrs->{prefetch} ) {
2933
2934     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2935       if ref $attrs->{from} ne 'ARRAY';
2936
2937     my $join = delete $attrs->{join} || {};
2938
2939     if ( defined $attrs->{prefetch} ) {
2940       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2941     }
2942
2943     $attrs->{from} =    # have to copy here to avoid corrupting the original
2944       [
2945         @{ $attrs->{from} },
2946         $source->_resolve_join(
2947           $join,
2948           $alias,
2949           { %{ $attrs->{seen_join} || {} } },
2950           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
2951             ? $attrs->{from}[-1][0]{-join_path}
2952             : []
2953           ,
2954         )
2955       ];
2956   }
2957
2958   if ( defined $attrs->{order_by} ) {
2959     $attrs->{order_by} = (
2960       ref( $attrs->{order_by} ) eq 'ARRAY'
2961       ? [ @{ $attrs->{order_by} } ]
2962       : [ $attrs->{order_by} || () ]
2963     );
2964   }
2965
2966   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2967     $attrs->{group_by} = [ $attrs->{group_by} ];
2968   }
2969
2970   # generate the distinct induced group_by early, as prefetch will be carried via a
2971   # subquery (since a group_by is present)
2972   if (delete $attrs->{distinct}) {
2973     if ($attrs->{group_by}) {
2974       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2975     }
2976     else {
2977       my $storage = $self->result_source->schema->storage;
2978       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
2979
2980       my $group_spec = $attrs->{group_by} = [];
2981       my %group_index;
2982
2983       for (@{$attrs->{select}}) {
2984         if (! ref($_) or ref ($_) ne 'HASH' ) {
2985           push @$group_spec, $_;
2986           $group_index{$_}++;
2987           if ($rs_column_list->{$_} and $_ !~ /\./ ) {
2988             # add a fully qualified version as well
2989             $group_index{"$rs_column_list->{$_}{-source_alias}.$_"}++;
2990           }
2991         }
2992       }
2993       # add any order_by parts that are not already present in the group_by
2994       # we need to be careful not to add any named functions/aggregates
2995       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
2996       for my $chunk ($storage->_parse_order_by($attrs->{order_by})) {
2997
2998         # only consider real columns (for functions the user got to do an explicit group_by)
2999         my $colinfo = $rs_column_list->{$chunk}
3000           or next;
3001
3002         $chunk = "$colinfo->{-source_alias}.$chunk" if $chunk !~ /\./;
3003         push @$group_spec, $chunk unless $group_index{$chunk}++;
3004       }
3005     }
3006   }
3007
3008   $attrs->{collapse} ||= {};
3009   if ( my $prefetch = delete $attrs->{prefetch} ) {
3010     $prefetch = $self->_merge_attr( {}, $prefetch );
3011
3012     my $prefetch_ordering = [];
3013
3014     # this is a separate structure (we don't look in {from} directly)
3015     # as the resolver needs to shift things off the lists to work
3016     # properly (identical-prefetches on different branches)
3017     my $join_map = {};
3018     if (ref $attrs->{from} eq 'ARRAY') {
3019
3020       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3021
3022       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3023         next unless $j->[0]{-alias};
3024         next unless $j->[0]{-join_path};
3025         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3026
3027         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3028
3029         my $p = $join_map;
3030         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3031         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3032       }
3033     }
3034
3035     my @prefetch =
3036       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3037
3038     # we need to somehow mark which columns came from prefetch
3039     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
3040
3041     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
3042     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3043
3044     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3045     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3046   }
3047
3048   # if both page and offset are specified, produce a combined offset
3049   # even though it doesn't make much sense, this is what pre 081xx has
3050   # been doing
3051   if (my $page = delete $attrs->{page}) {
3052     $attrs->{offset} =
3053       ($attrs->{rows} * ($page - 1))
3054             +
3055       ($attrs->{offset} || 0)
3056     ;
3057   }
3058
3059   return $self->{_attrs} = $attrs;
3060 }
3061
3062 sub _rollout_attr {
3063   my ($self, $attr) = @_;
3064
3065   if (ref $attr eq 'HASH') {
3066     return $self->_rollout_hash($attr);
3067   } elsif (ref $attr eq 'ARRAY') {
3068     return $self->_rollout_array($attr);
3069   } else {
3070     return [$attr];
3071   }
3072 }
3073
3074 sub _rollout_array {
3075   my ($self, $attr) = @_;
3076
3077   my @rolled_array;
3078   foreach my $element (@{$attr}) {
3079     if (ref $element eq 'HASH') {
3080       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3081     } elsif (ref $element eq 'ARRAY') {
3082       #  XXX - should probably recurse here
3083       push( @rolled_array, @{$self->_rollout_array($element)} );
3084     } else {
3085       push( @rolled_array, $element );
3086     }
3087   }
3088   return \@rolled_array;
3089 }
3090
3091 sub _rollout_hash {
3092   my ($self, $attr) = @_;
3093
3094   my @rolled_array;
3095   foreach my $key (keys %{$attr}) {
3096     push( @rolled_array, { $key => $attr->{$key} } );
3097   }
3098   return \@rolled_array;
3099 }
3100
3101 sub _calculate_score {
3102   my ($self, $a, $b) = @_;
3103
3104   if (defined $a xor defined $b) {
3105     return 0;
3106   }
3107   elsif (not defined $a) {
3108     return 1;
3109   }
3110
3111   if (ref $b eq 'HASH') {
3112     my ($b_key) = keys %{$b};
3113     if (ref $a eq 'HASH') {
3114       my ($a_key) = keys %{$a};
3115       if ($a_key eq $b_key) {
3116         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3117       } else {
3118         return 0;
3119       }
3120     } else {
3121       return ($a eq $b_key) ? 1 : 0;
3122     }
3123   } else {
3124     if (ref $a eq 'HASH') {
3125       my ($a_key) = keys %{$a};
3126       return ($b eq $a_key) ? 1 : 0;
3127     } else {
3128       return ($b eq $a) ? 1 : 0;
3129     }
3130   }
3131 }
3132
3133 sub _merge_attr {
3134   my ($self, $orig, $import) = @_;
3135
3136   return $import unless defined($orig);
3137   return $orig unless defined($import);
3138
3139   $orig = $self->_rollout_attr($orig);
3140   $import = $self->_rollout_attr($import);
3141
3142   my $seen_keys;
3143   foreach my $import_element ( @{$import} ) {
3144     # find best candidate from $orig to merge $b_element into
3145     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3146     foreach my $orig_element ( @{$orig} ) {
3147       my $score = $self->_calculate_score( $orig_element, $import_element );
3148       if ($score > $best_candidate->{score}) {
3149         $best_candidate->{position} = $position;
3150         $best_candidate->{score} = $score;
3151       }
3152       $position++;
3153     }
3154     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3155
3156     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3157       push( @{$orig}, $import_element );
3158     } else {
3159       my $orig_best = $orig->[$best_candidate->{position}];
3160       # merge orig_best and b_element together and replace original with merged
3161       if (ref $orig_best ne 'HASH') {
3162         $orig->[$best_candidate->{position}] = $import_element;
3163       } elsif (ref $import_element eq 'HASH') {
3164         my ($key) = keys %{$orig_best};
3165         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3166       }
3167     }
3168     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3169   }
3170
3171   return $orig;
3172 }
3173
3174 sub result_source {
3175     my $self = shift;
3176
3177     if (@_) {
3178         $self->_source_handle($_[0]->handle);
3179     } else {
3180         $self->_source_handle->resolve;
3181     }
3182 }
3183
3184 =head2 throw_exception
3185
3186 See L<DBIx::Class::Schema/throw_exception> for details.
3187
3188 =cut
3189
3190 sub throw_exception {
3191   my $self=shift;
3192
3193   if (ref $self && $self->_source_handle->schema) {
3194     $self->_source_handle->schema->throw_exception(@_)
3195   }
3196   else {
3197     DBIx::Class::Exception->throw(@_);
3198   }
3199 }
3200
3201 # XXX: FIXME: Attributes docs need clearing up
3202
3203 =head1 ATTRIBUTES
3204
3205 Attributes are used to refine a ResultSet in various ways when
3206 searching for data. They can be passed to any method which takes an
3207 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3208 L</count>.
3209
3210 These are in no particular order:
3211
3212 =head2 order_by
3213
3214 =over 4
3215
3216 =item Value: ( $order_by | \@order_by | \%order_by )
3217
3218 =back
3219
3220 Which column(s) to order the results by.
3221
3222 [The full list of suitable values is documented in
3223 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3224 common options.]
3225
3226 If a single column name, or an arrayref of names is supplied, the
3227 argument is passed through directly to SQL. The hashref syntax allows
3228 for connection-agnostic specification of ordering direction:
3229
3230  For descending order:
3231
3232   order_by => { -desc => [qw/col1 col2 col3/] }
3233
3234  For explicit ascending order:
3235
3236   order_by => { -asc => 'col' }
3237
3238 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3239 supported, although you are strongly encouraged to use the hashref
3240 syntax as outlined above.
3241
3242 =head2 columns
3243
3244 =over 4
3245
3246 =item Value: \@columns
3247
3248 =back
3249
3250 Shortcut to request a particular set of columns to be retrieved. Each
3251 column spec may be a string (a table column name), or a hash (in which
3252 case the key is the C<as> value, and the value is used as the C<select>
3253 expression). Adds C<me.> onto the start of any column without a C<.> in
3254 it and sets C<select> from that, then auto-populates C<as> from
3255 C<select> as normal. (You may also use the C<cols> attribute, as in
3256 earlier versions of DBIC.)
3257
3258 =head2 +columns
3259
3260 =over 4
3261
3262 =item Value: \@columns
3263
3264 =back
3265
3266 Indicates additional columns to be selected from storage. Works the same
3267 as L</columns> but adds columns to the selection. (You may also use the
3268 C<include_columns> attribute, as in earlier versions of DBIC). For
3269 example:-
3270
3271   $schema->resultset('CD')->search(undef, {
3272     '+columns' => ['artist.name'],
3273     join => ['artist']
3274   });
3275
3276 would return all CDs and include a 'name' column to the information
3277 passed to object inflation. Note that the 'artist' is the name of the
3278 column (or relationship) accessor, and 'name' is the name of the column
3279 accessor in the related table.
3280
3281 =head2 include_columns
3282
3283 =over 4
3284
3285 =item Value: \@columns
3286
3287 =back
3288
3289 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3290
3291 =head2 select
3292
3293 =over 4
3294
3295 =item Value: \@select_columns
3296
3297 =back
3298
3299 Indicates which columns should be selected from the storage. You can use
3300 column names, or in the case of RDBMS back ends, function or stored procedure
3301 names:
3302
3303   $rs = $schema->resultset('Employee')->search(undef, {
3304     select => [
3305       'name',
3306       { count => 'employeeid' },
3307       { max => { length => 'name' }, -as => 'longest_name' }
3308     ]
3309   });
3310
3311   # Equivalent SQL
3312   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3313
3314 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3315 use L</select>, to instruct DBIx::Class how to store the result of the column.
3316 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3317 identifier aliasing. You can however alias a function, so you can use it in
3318 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3319 attribute> supplied as shown in the example above.
3320
3321 =head2 +select
3322
3323 =over 4
3324
3325 Indicates additional columns to be selected from storage.  Works the same as
3326 L</select> but adds columns to the default selection, instead of specifying
3327 an explicit list.
3328
3329 =back
3330
3331 =head2 +as
3332
3333 =over 4
3334
3335 Indicates additional column names for those added via L</+select>. See L</as>.
3336
3337 =back
3338
3339 =head2 as
3340
3341 =over 4
3342
3343 =item Value: \@inflation_names
3344
3345 =back
3346
3347 Indicates column names for object inflation. That is L</as> indicates the
3348 slot name in which the column value will be stored within the
3349 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3350 identifier by the C<get_column> method (or via the object accessor B<if one
3351 with the same name already exists>) as shown below. The L</as> attribute has
3352 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3353
3354   $rs = $schema->resultset('Employee')->search(undef, {
3355     select => [
3356       'name',
3357       { count => 'employeeid' },
3358       { max => { length => 'name' }, -as => 'longest_name' }
3359     ],
3360     as => [qw/
3361       name
3362       employee_count
3363       max_name_length
3364     /],
3365   });
3366
3367 If the object against which the search is performed already has an accessor
3368 matching a column name specified in C<as>, the value can be retrieved using
3369 the accessor as normal:
3370
3371   my $name = $employee->name();
3372
3373 If on the other hand an accessor does not exist in the object, you need to
3374 use C<get_column> instead:
3375
3376   my $employee_count = $employee->get_column('employee_count');
3377
3378 You can create your own accessors if required - see
3379 L<DBIx::Class::Manual::Cookbook> for details.
3380
3381 =head2 join
3382
3383 =over 4
3384
3385 =item Value: ($rel_name | \@rel_names | \%rel_names)
3386
3387 =back
3388
3389 Contains a list of relationships that should be joined for this query.  For
3390 example:
3391
3392   # Get CDs by Nine Inch Nails
3393   my $rs = $schema->resultset('CD')->search(
3394     { 'artist.name' => 'Nine Inch Nails' },
3395     { join => 'artist' }
3396   );
3397
3398 Can also contain a hash reference to refer to the other relation's relations.
3399 For example:
3400
3401   package MyApp::Schema::Track;
3402   use base qw/DBIx::Class/;
3403   __PACKAGE__->table('track');
3404   __PACKAGE__->add_columns(qw/trackid cd position title/);
3405   __PACKAGE__->set_primary_key('trackid');
3406   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3407   1;
3408
3409   # In your application
3410   my $rs = $schema->resultset('Artist')->search(
3411     { 'track.title' => 'Teardrop' },
3412     {
3413       join     => { cd => 'track' },
3414       order_by => 'artist.name',
3415     }
3416   );
3417
3418 You need to use the relationship (not the table) name in  conditions,
3419 because they are aliased as such. The current table is aliased as "me", so
3420 you need to use me.column_name in order to avoid ambiguity. For example:
3421
3422   # Get CDs from 1984 with a 'Foo' track
3423   my $rs = $schema->resultset('CD')->search(
3424     {
3425       'me.year' => 1984,
3426       'tracks.name' => 'Foo'
3427     },
3428     { join => 'tracks' }
3429   );
3430
3431 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3432 similarly for a third time). For e.g.
3433
3434   my $rs = $schema->resultset('Artist')->search({
3435     'cds.title'   => 'Down to Earth',
3436     'cds_2.title' => 'Popular',
3437   }, {
3438     join => [ qw/cds cds/ ],
3439   });
3440
3441 will return a set of all artists that have both a cd with title 'Down
3442 to Earth' and a cd with title 'Popular'.
3443
3444 If you want to fetch related objects from other tables as well, see C<prefetch>
3445 below.
3446
3447 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3448
3449 =head2 prefetch
3450
3451 =over 4
3452
3453 =item Value: ($rel_name | \@rel_names | \%rel_names)
3454
3455 =back
3456
3457 Contains one or more relationships that should be fetched along with
3458 the main query (when they are accessed afterwards the data will
3459 already be available, without extra queries to the database).  This is
3460 useful for when you know you will need the related objects, because it
3461 saves at least one query:
3462
3463   my $rs = $schema->resultset('Tag')->search(
3464     undef,
3465     {
3466       prefetch => {
3467         cd => 'artist'
3468       }
3469     }
3470   );
3471
3472 The initial search results in SQL like the following:
3473
3474   SELECT tag.*, cd.*, artist.* FROM tag
3475   JOIN cd ON tag.cd = cd.cdid
3476   JOIN artist ON cd.artist = artist.artistid
3477
3478 L<DBIx::Class> has no need to go back to the database when we access the
3479 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3480 case.
3481
3482 Simple prefetches will be joined automatically, so there is no need
3483 for a C<join> attribute in the above search.
3484
3485 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3486 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3487 with an accessor type of 'single' or 'filter'). A more complex example that
3488 prefetches an artists cds, the tracks on those cds, and the tags associated
3489 with that artist is given below (assuming many-to-many from artists to tags):
3490
3491  my $rs = $schema->resultset('Artist')->search(
3492    undef,
3493    {
3494      prefetch => [
3495        { cds => 'tracks' },
3496        { artist_tags => 'tags' }
3497      ]
3498    }
3499  );
3500
3501
3502 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3503 attributes will be ignored.
3504
3505 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3506 exactly as you might expect.
3507
3508 =over 4
3509
3510 =item *
3511
3512 Prefetch uses the L</cache> to populate the prefetched relationships. This
3513 may or may not be what you want.
3514
3515 =item *
3516
3517 If you specify a condition on a prefetched relationship, ONLY those
3518 rows that match the prefetched condition will be fetched into that relationship.
3519 This means that adding prefetch to a search() B<may alter> what is returned by
3520 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3521
3522   my $artist_rs = $schema->resultset('Artist')->search({
3523       'cds.year' => 2008,
3524   }, {
3525       join => 'cds',
3526   });
3527
3528   my $count = $artist_rs->first->cds->count;
3529
3530   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3531
3532   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3533
3534   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3535
3536 that cmp_ok() may or may not pass depending on the datasets involved. This
3537 behavior may or may not survive the 0.09 transition.
3538
3539 =back
3540
3541 =head2 page
3542
3543 =over 4
3544
3545 =item Value: $page
3546
3547 =back
3548
3549 Makes the resultset paged and specifies the page to retrieve. Effectively
3550 identical to creating a non-pages resultset and then calling ->page($page)
3551 on it.
3552
3553 If L<rows> attribute is not specified it defaults to 10 rows per page.
3554
3555 When you have a paged resultset, L</count> will only return the number
3556 of rows in the page. To get the total, use the L</pager> and call
3557 C<total_entries> on it.
3558
3559 =head2 rows
3560
3561 =over 4
3562
3563 =item Value: $rows
3564
3565 =back
3566
3567 Specifies the maximum number of rows for direct retrieval or the number of
3568 rows per page if the page attribute or method is used.
3569
3570 =head2 offset
3571
3572 =over 4
3573
3574 =item Value: $offset
3575
3576 =back
3577
3578 Specifies the (zero-based) row number for the  first row to be returned, or the
3579 of the first row of the first page if paging is used.
3580
3581 =head2 group_by
3582
3583 =over 4
3584
3585 =item Value: \@columns
3586
3587 =back
3588
3589 A arrayref of columns to group by. Can include columns of joined tables.
3590
3591   group_by => [qw/ column1 column2 ... /]
3592
3593 =head2 having
3594
3595 =over 4
3596
3597 =item Value: $condition
3598
3599 =back
3600
3601 HAVING is a select statement attribute that is applied between GROUP BY and
3602 ORDER BY. It is applied to the after the grouping calculations have been
3603 done.
3604
3605   having => { 'count(employee)' => { '>=', 100 } }
3606
3607 =head2 distinct
3608
3609 =over 4
3610
3611 =item Value: (0 | 1)
3612
3613 =back
3614
3615 Set to 1 to group by all columns. If the resultset already has a group_by
3616 attribute, this setting is ignored and an appropriate warning is issued.
3617
3618 =head2 where
3619
3620 =over 4
3621
3622 Adds to the WHERE clause.
3623
3624   # only return rows WHERE deleted IS NULL for all searches
3625   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3626
3627 Can be overridden by passing C<< { where => undef } >> as an attribute
3628 to a resultset.
3629
3630 =back
3631
3632 =head2 cache
3633
3634 Set to 1 to cache search results. This prevents extra SQL queries if you
3635 revisit rows in your ResultSet:
3636
3637   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3638
3639   while( my $artist = $resultset->next ) {
3640     ... do stuff ...
3641   }
3642
3643   $rs->first; # without cache, this would issue a query
3644
3645 By default, searches are not cached.
3646
3647 For more examples of using these attributes, see
3648 L<DBIx::Class::Manual::Cookbook>.
3649
3650 =head2 for
3651
3652 =over 4
3653
3654 =item Value: ( 'update' | 'shared' )
3655
3656 =back
3657
3658 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3659 ... FOR SHARED.
3660
3661 =cut
3662
3663 1;