lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 961   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 962   @new = $self->{_attrs}{record_filter}->(@new)
 963     if exists $self->{_attrs}{record_filter};
 964   return @new;
 965 }
 966
 967 sub _collapse_result {
 968   my ($self, $as_proto, $row) = @_;
 969
 970   my @copy = @$row;
 971
 972   # 'foo'         => [ undef, 'foo' ]
 973   # 'foo.bar'     => [ 'foo', 'bar' ]
 974   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 975
 976   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 977
 978   my %collapse = %{$self->{_attrs}{collapse}||{}};
 979
 980   my @pri_index;
 981
 982   # if we're doing collapsing (has_many prefetch) we need to grab records
 983   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 984   # we know we don't have to bother.
 985
 986   # the reason for not using the collapse stuff directly is because if you
 987   # had for e.g. two artists in a row with no cds, the collapse info for
 988   # both would be NULL (undef) so you'd lose the second artist
 989
 990   # store just the index so we can check the array positions from the row
 991   # without having to contruct the full hash
 992
 993   if (keys %collapse) {
 994     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 995     foreach my $i (0 .. $#construct_as) {
 996       next if defined($construct_as[$i][0]); # only self table
 997       if (delete $pri{$construct_as[$i][1]}) {
 998         push(@pri_index, $i);
 999       }
1000       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1001     }
1002   }
1003
1004   # no need to do an if, it'll be empty if @pri_index is empty anyway
1005
1006   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1007
1008   my @const_rows;
1009
1010   do { # no need to check anything at the front, we always want the first row
1011
1012     my %const;
1013
1014     foreach my $this_as (@construct_as) {
1015       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1016     }
1017
1018     push(@const_rows, \%const);
1019
1020   } until ( # no pri_index => no collapse => drop straight out
1021       !@pri_index
1022     or
1023       do { # get another row, stash it, drop out if different PK
1024
1025         @copy = $self->cursor->next;
1026         $self->{stashed_row} = \@copy;
1027
1028         # last thing in do block, counts as true if anything doesn't match
1029
1030         # check xor defined first for NULL vs. NOT NULL then if one is
1031         # defined the other must be so check string equality
1032
1033         grep {
1034           (defined $pri_vals{$_} ^ defined $copy[$_])
1035           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1036         } @pri_index;
1037       }
1038   );
1039
1040   my $alias = $self->{attrs}{alias};
1041   my $info = [];
1042
1043   my %collapse_pos;
1044
1045   my @const_keys;
1046
1047   foreach my $const (@const_rows) {
1048     scalar @const_keys or do {
1049       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1050     };
1051     foreach my $key (@const_keys) {
1052       if (length $key) {
1053         my $target = $info;
1054         my @parts = split(/\./, $key);
1055         my $cur = '';
1056         my $data = $const->{$key};
1057         foreach my $p (@parts) {
1058           $target = $target->[1]->{$p} ||= [];
1059           $cur .= ".${p}";
1060           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1061             # collapsing at this point and on final part
1062             my $pos = $collapse_pos{$cur};
1063             CK: foreach my $ck (@ckey) {
1064               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1065                 $collapse_pos{$cur} = $data;
1066                 delete @collapse_pos{ # clear all positioning for sub-entries
1067                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1068                 };
1069                 push(@$target, []);
1070                 last CK;
1071               }
1072             }
1073           }
1074           if (exists $collapse{$cur}) {
1075             $target = $target->[-1];
1076           }
1077         }
1078         $target->[0] = $data;
1079       } else {
1080         $info->[0] = $const->{$key};
1081       }
1082     }
1083   }
1084
1085   return $info;
1086 }
1087
1088 =head2 result_source
1089
1090 =over 4
1091
1092 =item Arguments: $result_source?
1093
1094 =item Return Value: $result_source
1095
1096 =back
1097
1098 An accessor for the primary ResultSource object from which this ResultSet
1099 is derived.
1100
1101 =head2 result_class
1102
1103 =over 4
1104
1105 =item Arguments: $result_class?
1106
1107 =item Return Value: $result_class
1108
1109 =back
1110
1111 An accessor for the class to use when creating row objects. Defaults to
1112 C<< result_source->result_class >> - which in most cases is the name of the
1113 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1114
1115 Note that changing the result_class will also remove any components
1116 that were originally loaded in the source class via
1117 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1118 in the original source class will not run.
1119
1120 =cut
1121
1122 sub result_class {
1123   my ($self, $result_class) = @_;
1124   if ($result_class) {
1125     $self->ensure_class_loaded($result_class);
1126     $self->_result_class($result_class);
1127   }
1128   $self->_result_class;
1129 }
1130
1131 =head2 count
1132
1133 =over 4
1134
1135 =item Arguments: $cond, \%attrs??
1136
1137 =item Return Value: $count
1138
1139 =back
1140
1141 Performs an SQL C<COUNT> with the same query as the resultset was built
1142 with to find the number of elements. Passing arguments is equivalent to
1143 C<< $rs->search ($cond, \%attrs)->count >>
1144
1145 =cut
1146
1147 sub count {
1148   my $self = shift;
1149   return $self->search(@_)->count if @_ and defined $_[0];
1150   return scalar @{ $self->get_cache } if $self->get_cache;
1151
1152   my $attrs = $self->_resolved_attrs_copy;
1153
1154   # this is a little optimization - it is faster to do the limit
1155   # adjustments in software, instead of a subquery
1156   my $rows = delete $attrs->{rows};
1157   my $offset = delete $attrs->{offset};
1158
1159   my $crs;
1160   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1161     $crs = $self->_count_subq_rs ($attrs);
1162   }
1163   else {
1164     $crs = $self->_count_rs ($attrs);
1165   }
1166   my $count = $crs->next;
1167
1168   $count -= $offset if $offset;
1169   $count = $rows if $rows and $rows < $count;
1170   $count = 0 if ($count < 0);
1171
1172   return $count;
1173 }
1174
1175 =head2 count_rs
1176
1177 =over 4
1178
1179 =item Arguments: $cond, \%attrs??
1180
1181 =item Return Value: $count_rs
1182
1183 =back
1184
1185 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1186 This can be very handy for subqueries:
1187
1188   ->search( { amount => $some_rs->count_rs->as_query } )
1189
1190 As with regular resultsets the SQL query will be executed only after
1191 the resultset is accessed via L</next> or L</all>. That would return
1192 the same single value obtainable via L</count>.
1193
1194 =cut
1195
1196 sub count_rs {
1197   my $self = shift;
1198   return $self->search(@_)->count_rs if @_;
1199
1200   # this may look like a lack of abstraction (count() does about the same)
1201   # but in fact an _rs *must* use a subquery for the limits, as the
1202   # software based limiting can not be ported if this $rs is to be used
1203   # in a subquery itself (i.e. ->as_query)
1204   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1205     return $self->_count_subq_rs;
1206   }
1207   else {
1208     return $self->_count_rs;
1209   }
1210 }
1211
1212 #
1213 # returns a ResultSetColumn object tied to the count query
1214 #
1215 sub _count_rs {
1216   my ($self, $attrs) = @_;
1217
1218   my $rsrc = $self->result_source;
1219   $attrs ||= $self->_resolved_attrs;
1220
1221   my $tmp_attrs = { %$attrs };
1222
1223   # take off any limits, record_filter is cdbi, and no point of ordering a count
1224   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1225
1226   # overwrite the selector (supplied by the storage)
1227   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1228   $tmp_attrs->{as} = 'count';
1229
1230   # read the function comment
1231   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1232     $tmp_attrs->{from}, $tmp_attrs->{alias}
1233   );
1234
1235   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1236
1237   return $tmp_rs;
1238 }
1239
1240 #
1241 # same as above but uses a subquery
1242 #
1243 sub _count_subq_rs {
1244   my ($self, $attrs) = @_;
1245
1246   my $rsrc = $self->result_source;
1247   $attrs ||= $self->_resolved_attrs_copy;
1248
1249   my $sub_attrs = { %$attrs };
1250
1251   # extra selectors do not go in the subquery and there is no point of ordering it
1252   delete $sub_attrs->{$_} for qw/collapse prefetch_select select as order_by/;
1253
1254   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1255   # clobber old group_by regardless
1256   if ( keys %{$attrs->{collapse}} ) {
1257     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1258   }
1259
1260   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1261
1262   # read the function comment
1263   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1264     $sub_attrs->{from}, $sub_attrs->{alias}
1265   );
1266
1267   $attrs->{from} = [{
1268     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1269   }];
1270
1271   # the subquery replaces this
1272   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1273
1274   return $self->_count_rs ($attrs);
1275 }
1276
1277
1278 # The DBIC relationship chaining implementation is pretty simple - every
1279 # new related_relationship is pushed onto the {from} stack, and the {select}
1280 # window simply slides further in. This means that when we count somewhere
1281 # in the middle, we got to make sure that everything in the join chain is an
1282 # actual inner join, otherwise the count will come back with unpredictable
1283 # results (a resultset may be generated with _some_ rows regardless of if
1284 # the relation which the $rs currently selects has rows or not). E.g.
1285 # $artist_rs->cds->count - normally generates:
1286 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1287 # which actually returns the number of artists * (number of cds || 1)
1288 #
1289 # So what we do here is crawl {from}, determine if the current alias is at
1290 # the top of the stack, and if not - make sure the chain is inner-joined down
1291 # to the root.
1292 #
1293 sub _switch_to_inner_join_if_needed {
1294   my ($self, $from, $alias) = @_;
1295
1296   return $from if (
1297     ref $from ne 'ARRAY'
1298       ||
1299     ref $from->[0] ne 'HASH'
1300       ||
1301     ! $from->[0]{-alias}
1302       ||
1303     $from->[0]{-alias} eq $alias
1304   );
1305
1306   # this would be the case with a subquery - we'll never find
1307   # the target as it is not in the parseable part of {from}
1308   return $from if @$from == 1;
1309
1310   my (@switch_idx, $found_target);
1311
1312   JOINSCAN:
1313   for my $i (1 .. $#$from) {
1314
1315     push @switch_idx, $i;
1316     my $j = $from->[$i];
1317     my $jalias = $j->[0]{-alias};
1318
1319     # we found our current target - delete any siblings (same level joins)
1320     # and bail out
1321     if ($jalias eq $alias) {
1322       $found_target++;
1323
1324       my $cur_depth = $j->[0]{-relation_chain_depth};
1325       # we are -1, so look at -2
1326       while (@switch_idx > 1
1327               && $from->[$switch_idx[-2]][0]{-relation_chain_depth} == $cur_depth
1328       ) {
1329         splice @switch_idx, -2, 1;
1330       }
1331
1332       last JOINSCAN;
1333     }
1334   }
1335
1336   # something else went wrong
1337   return $from unless $found_target;
1338
1339   # So it looks like we will have to switch some stuff around.
1340   # local() is useless here as we will be leaving the scope
1341   # anyway, and deep cloning is just too fucking expensive
1342   # So replace the inner hashref manually
1343   my @new_from;
1344   my $sw_idx = { map { $_ => 1 } @switch_idx };
1345
1346   for my $i (0 .. $#$from) {
1347     if ($sw_idx->{$i}) {
1348       my %attrs = %{$from->[$i][0]};
1349       delete $attrs{-join_type};
1350
1351       push @new_from, [
1352         \%attrs,
1353         @{$from->[$i]}[ 1 .. $#{$from->[$i]} ],
1354       ];
1355     }
1356     else {
1357       push @new_from, $from->[$i];
1358     }
1359   }
1360
1361   return \@new_from;
1362 }
1363
1364
1365 sub _bool {
1366   return 1;
1367 }
1368
1369 =head2 count_literal
1370
1371 =over 4
1372
1373 =item Arguments: $sql_fragment, @bind_values
1374
1375 =item Return Value: $count
1376
1377 =back
1378
1379 Counts the results in a literal query. Equivalent to calling L</search_literal>
1380 with the passed arguments, then L</count>.
1381
1382 =cut
1383
1384 sub count_literal { shift->search_literal(@_)->count; }
1385
1386 =head2 all
1387
1388 =over 4
1389
1390 =item Arguments: none
1391
1392 =item Return Value: @objects
1393
1394 =back
1395
1396 Returns all elements in the resultset. Called implicitly if the resultset
1397 is returned in list context.
1398
1399 =cut
1400
1401 sub all {
1402   my $self = shift;
1403   if(@_) {
1404       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1405   }
1406
1407   return @{ $self->get_cache } if $self->get_cache;
1408
1409   my @obj;
1410
1411   if (keys %{$self->_resolved_attrs->{collapse}}) {
1412     # Using $self->cursor->all is really just an optimisation.
1413     # If we're collapsing has_many prefetches it probably makes
1414     # very little difference, and this is cleaner than hacking
1415     # _construct_object to survive the approach
1416     $self->cursor->reset;
1417     my @row = $self->cursor->next;
1418     while (@row) {
1419       push(@obj, $self->_construct_object(@row));
1420       @row = (exists $self->{stashed_row}
1421                ? @{delete $self->{stashed_row}}
1422                : $self->cursor->next);
1423     }
1424   } else {
1425     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1426   }
1427
1428   $self->set_cache(\@obj) if $self->{attrs}{cache};
1429   return @obj;
1430 }
1431
1432 =head2 reset
1433
1434 =over 4
1435
1436 =item Arguments: none
1437
1438 =item Return Value: $self
1439
1440 =back
1441
1442 Resets the resultset's cursor, so you can iterate through the elements again.
1443 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1444 another query.
1445
1446 =cut
1447
1448 sub reset {
1449   my ($self) = @_;
1450   delete $self->{_attrs} if exists $self->{_attrs};
1451   $self->{all_cache_position} = 0;
1452   $self->cursor->reset;
1453   return $self;
1454 }
1455
1456 =head2 first
1457
1458 =over 4
1459
1460 =item Arguments: none
1461
1462 =item Return Value: $object?
1463
1464 =back
1465
1466 Resets the resultset and returns an object for the first result (if the
1467 resultset returns anything).
1468
1469 =cut
1470
1471 sub first {
1472   return $_[0]->reset->next;
1473 }
1474
1475
1476 # _rs_update_delete
1477 #
1478 # Determines whether and what type of subquery is required for the $rs operation.
1479 # If grouping is necessary either supplies its own, or verifies the current one
1480 # After all is done delegates to the proper storage method.
1481
1482 sub _rs_update_delete {
1483   my ($self, $op, $values) = @_;
1484
1485   my $rsrc = $self->result_source;
1486
1487   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1488   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1489
1490   if ($needs_group_by_subq or $needs_subq) {
1491
1492     # make a new $rs selecting only the PKs (that's all we really need)
1493     my $attrs = $self->_resolved_attrs_copy;
1494
1495     delete $attrs->{$_} for qw/collapse select as/;
1496     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1497
1498     if ($needs_group_by_subq) {
1499       # make sure no group_by was supplied, or if there is one - make sure it matches
1500       # the columns compiled above perfectly. Anything else can not be sanely executed
1501       # on most databases so croak right then and there
1502
1503       if (my $g = $attrs->{group_by}) {
1504         my @current_group_by = map
1505           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1506           (ref $g eq 'ARRAY' ? @$g : $g );
1507
1508         if (
1509           join ("\x00", sort @current_group_by)
1510             ne
1511           join ("\x00", sort @{$attrs->{columns}} )
1512         ) {
1513           $self->throw_exception (
1514             "You have just attempted a $op operation on a resultset which does group_by"
1515             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1516             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1517             . ' kind of queries. Please retry the operation with a modified group_by or'
1518             . ' without using one at all.'
1519           );
1520         }
1521       }
1522       else {
1523         $attrs->{group_by} = $attrs->{columns};
1524       }
1525     }
1526
1527     my $subrs = (ref $self)->new($rsrc, $attrs);
1528
1529     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1530   }
1531   else {
1532     return $rsrc->storage->$op(
1533       $rsrc,
1534       $op eq 'update' ? $values : (),
1535       $self->_cond_for_update_delete,
1536     );
1537   }
1538 }
1539
1540
1541 # _cond_for_update_delete
1542 #
1543 # update/delete require the condition to be modified to handle
1544 # the differing SQL syntax available.  This transforms the $self->{cond}
1545 # appropriately, returning the new condition.
1546
1547 sub _cond_for_update_delete {
1548   my ($self, $full_cond) = @_;
1549   my $cond = {};
1550
1551   $full_cond ||= $self->{cond};
1552   # No-op. No condition, we're updating/deleting everything
1553   return $cond unless ref $full_cond;
1554
1555   if (ref $full_cond eq 'ARRAY') {
1556     $cond = [
1557       map {
1558         my %hash;
1559         foreach my $key (keys %{$_}) {
1560           $key =~ /([^.]+)$/;
1561           $hash{$1} = $_->{$key};
1562         }
1563         \%hash;
1564       } @{$full_cond}
1565     ];
1566   }
1567   elsif (ref $full_cond eq 'HASH') {
1568     if ((keys %{$full_cond})[0] eq '-and') {
1569       $cond->{-and} = [];
1570       my @cond = @{$full_cond->{-and}};
1571        for (my $i = 0; $i < @cond; $i++) {
1572         my $entry = $cond[$i];
1573         my $hash;
1574         if (ref $entry eq 'HASH') {
1575           $hash = $self->_cond_for_update_delete($entry);
1576         }
1577         else {
1578           $entry =~ /([^.]+)$/;
1579           $hash->{$1} = $cond[++$i];
1580         }
1581         push @{$cond->{-and}}, $hash;
1582       }
1583     }
1584     else {
1585       foreach my $key (keys %{$full_cond}) {
1586         $key =~ /([^.]+)$/;
1587         $cond->{$1} = $full_cond->{$key};
1588       }
1589     }
1590   }
1591   else {
1592     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1593   }
1594
1595   return $cond;
1596 }
1597
1598
1599 =head2 update
1600
1601 =over 4
1602
1603 =item Arguments: \%values
1604
1605 =item Return Value: $storage_rv
1606
1607 =back
1608
1609 Sets the specified columns in the resultset to the supplied values in a
1610 single query. Return value will be true if the update succeeded or false
1611 if no records were updated; exact type of success value is storage-dependent.
1612
1613 =cut
1614
1615 sub update {
1616   my ($self, $values) = @_;
1617   $self->throw_exception('Values for update must be a hash')
1618     unless ref $values eq 'HASH';
1619
1620   return $self->_rs_update_delete ('update', $values);
1621 }
1622
1623 =head2 update_all
1624
1625 =over 4
1626
1627 =item Arguments: \%values
1628
1629 =item Return Value: 1
1630
1631 =back
1632
1633 Fetches all objects and updates them one at a time. Note that C<update_all>
1634 will run DBIC cascade triggers, while L</update> will not.
1635
1636 =cut
1637
1638 sub update_all {
1639   my ($self, $values) = @_;
1640   $self->throw_exception('Values for update_all must be a hash')
1641     unless ref $values eq 'HASH';
1642   foreach my $obj ($self->all) {
1643     $obj->set_columns($values)->update;
1644   }
1645   return 1;
1646 }
1647
1648 =head2 delete
1649
1650 =over 4
1651
1652 =item Arguments: none
1653
1654 =item Return Value: $storage_rv
1655
1656 =back
1657
1658 Deletes the contents of the resultset from its result source. Note that this
1659 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1660 to run. See also L<DBIx::Class::Row/delete>.
1661
1662 Return value will be the amount of rows deleted; exact type of return value
1663 is storage-dependent.
1664
1665 =cut
1666
1667 sub delete {
1668   my $self = shift;
1669   $self->throw_exception('delete does not accept any arguments')
1670     if @_;
1671
1672   return $self->_rs_update_delete ('delete');
1673 }
1674
1675 =head2 delete_all
1676
1677 =over 4
1678
1679 =item Arguments: none
1680
1681 =item Return Value: 1
1682
1683 =back
1684
1685 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1686 will run DBIC cascade triggers, while L</delete> will not.
1687
1688 =cut
1689
1690 sub delete_all {
1691   my $self = shift;
1692   $self->throw_exception('delete_all does not accept any arguments')
1693     if @_;
1694
1695   $_->delete for $self->all;
1696   return 1;
1697 }
1698
1699 =head2 populate
1700
1701 =over 4
1702
1703 =item Arguments: \@data;
1704
1705 =back
1706
1707 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1708 For the arrayref of hashrefs style each hashref should be a structure suitable
1709 forsubmitting to a $resultset->create(...) method.
1710
1711 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1712 to insert the data, as this is a faster method.
1713
1714 Otherwise, each set of data is inserted into the database using
1715 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1716 accumulated into an array. The array itself, or an array reference
1717 is returned depending on scalar or list context.
1718
1719 Example:  Assuming an Artist Class that has many CDs Classes relating:
1720
1721   my $Artist_rs = $schema->resultset("Artist");
1722
1723   ## Void Context Example
1724   $Artist_rs->populate([
1725      { artistid => 4, name => 'Manufactured Crap', cds => [
1726         { title => 'My First CD', year => 2006 },
1727         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1728       ],
1729      },
1730      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1731         { title => 'My parents sold me to a record company' ,year => 2005 },
1732         { title => 'Why Am I So Ugly?', year => 2006 },
1733         { title => 'I Got Surgery and am now Popular', year => 2007 }
1734       ],
1735      },
1736   ]);
1737
1738   ## Array Context Example
1739   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1740     { name => "Artist One"},
1741     { name => "Artist Two"},
1742     { name => "Artist Three", cds=> [
1743     { title => "First CD", year => 2007},
1744     { title => "Second CD", year => 2008},
1745   ]}
1746   ]);
1747
1748   print $ArtistOne->name; ## response is 'Artist One'
1749   print $ArtistThree->cds->count ## reponse is '2'
1750
1751 For the arrayref of arrayrefs style,  the first element should be a list of the
1752 fieldsnames to which the remaining elements are rows being inserted.  For
1753 example:
1754
1755   $Arstist_rs->populate([
1756     [qw/artistid name/],
1757     [100, 'A Formally Unknown Singer'],
1758     [101, 'A singer that jumped the shark two albums ago'],
1759     [102, 'An actually cool singer.'],
1760   ]);
1761
1762 Please note an important effect on your data when choosing between void and
1763 wantarray context. Since void context goes straight to C<insert_bulk> in
1764 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1765 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1766 create primary keys for you, you will find that your PKs are empty.  In this
1767 case you will have to use the wantarray context in order to create those
1768 values.
1769
1770 =cut
1771
1772 sub populate {
1773   my $self = shift @_;
1774   my $data = ref $_[0][0] eq 'HASH'
1775     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1776     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1777
1778   if(defined wantarray) {
1779     my @created;
1780     foreach my $item (@$data) {
1781       push(@created, $self->create($item));
1782     }
1783     return wantarray ? @created : \@created;
1784   } else {
1785     my ($first, @rest) = @$data;
1786
1787     my @names = grep {!ref $first->{$_}} keys %$first;
1788     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1789     my @pks = $self->result_source->primary_columns;
1790
1791     ## do the belongs_to relationships
1792     foreach my $index (0..$#$data) {
1793
1794       # delegate to create() for any dataset without primary keys with specified relationships
1795       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1796         for my $r (@rels) {
1797           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1798             my @ret = $self->populate($data);
1799             return;
1800           }
1801         }
1802       }
1803
1804       foreach my $rel (@rels) {
1805         next unless ref $data->[$index]->{$rel} eq "HASH";
1806         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1807         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1808         my $related = $result->result_source->_resolve_condition(
1809           $result->result_source->relationship_info($reverse)->{cond},
1810           $self,
1811           $result,
1812         );
1813
1814         delete $data->[$index]->{$rel};
1815         $data->[$index] = {%{$data->[$index]}, %$related};
1816
1817         push @names, keys %$related if $index == 0;
1818       }
1819     }
1820
1821     ## do bulk insert on current row
1822     my @values = map { [ @$_{@names} ] } @$data;
1823
1824     $self->result_source->storage->insert_bulk(
1825       $self->result_source,
1826       \@names,
1827       \@values,
1828     );
1829
1830     ## do the has_many relationships
1831     foreach my $item (@$data) {
1832
1833       foreach my $rel (@rels) {
1834         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1835
1836         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1837      || $self->throw_exception('Cannot find the relating object.');
1838
1839         my $child = $parent->$rel;
1840
1841         my $related = $child->result_source->_resolve_condition(
1842           $parent->result_source->relationship_info($rel)->{cond},
1843           $child,
1844           $parent,
1845         );
1846
1847         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1848         my @populate = map { {%$_, %$related} } @rows_to_add;
1849
1850         $child->populate( \@populate );
1851       }
1852     }
1853   }
1854 }
1855
1856 =head2 _normalize_populate_args ($args)
1857
1858 Private method used by L</populate> to normalize its incoming arguments.  Factored
1859 out in case you want to subclass and accept new argument structures to the
1860 L</populate> method.
1861
1862 =cut
1863
1864 sub _normalize_populate_args {
1865   my ($self, $data) = @_;
1866   my @names = @{shift(@$data)};
1867   my @results_to_create;
1868   foreach my $datum (@$data) {
1869     my %result_to_create;
1870     foreach my $index (0..$#names) {
1871       $result_to_create{$names[$index]} = $$datum[$index];
1872     }
1873     push @results_to_create, \%result_to_create;
1874   }
1875   return \@results_to_create;
1876 }
1877
1878 =head2 pager
1879
1880 =over 4
1881
1882 =item Arguments: none
1883
1884 =item Return Value: $pager
1885
1886 =back
1887
1888 Return Value a L<Data::Page> object for the current resultset. Only makes
1889 sense for queries with a C<page> attribute.
1890
1891 To get the full count of entries for a paged resultset, call
1892 C<total_entries> on the L<Data::Page> object.
1893
1894 =cut
1895
1896 sub pager {
1897   my ($self) = @_;
1898
1899   return $self->{pager} if $self->{pager};
1900
1901   my $attrs = $self->{attrs};
1902   $self->throw_exception("Can't create pager for non-paged rs")
1903     unless $self->{attrs}{page};
1904   $attrs->{rows} ||= 10;
1905
1906   # throw away the paging flags and re-run the count (possibly
1907   # with a subselect) to get the real total count
1908   my $count_attrs = { %$attrs };
1909   delete $count_attrs->{$_} for qw/rows offset page pager/;
1910   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1911
1912   return $self->{pager} = Data::Page->new(
1913     $total_count,
1914     $attrs->{rows},
1915     $self->{attrs}{page}
1916   );
1917 }
1918
1919 =head2 page
1920
1921 =over 4
1922
1923 =item Arguments: $page_number
1924
1925 =item Return Value: $rs
1926
1927 =back
1928
1929 Returns a resultset for the $page_number page of the resultset on which page
1930 is called, where each page contains a number of rows equal to the 'rows'
1931 attribute set on the resultset (10 by default).
1932
1933 =cut
1934
1935 sub page {
1936   my ($self, $page) = @_;
1937   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1938 }
1939
1940 =head2 new_result
1941
1942 =over 4
1943
1944 =item Arguments: \%vals
1945
1946 =item Return Value: $rowobject
1947
1948 =back
1949
1950 Creates a new row object in the resultset's result class and returns
1951 it. The row is not inserted into the database at this point, call
1952 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1953 will tell you whether the row object has been inserted or not.
1954
1955 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1956
1957 =cut
1958
1959 sub new_result {
1960   my ($self, $values) = @_;
1961   $self->throw_exception( "new_result needs a hash" )
1962     unless (ref $values eq 'HASH');
1963
1964   my %new;
1965   my $alias = $self->{attrs}{alias};
1966
1967   if (
1968     defined $self->{cond}
1969     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1970   ) {
1971     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1972     $new{-from_resultset} = [ keys %new ] if keys %new;
1973   } else {
1974     $self->throw_exception(
1975       "Can't abstract implicit construct, condition not a hash"
1976     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1977
1978     my $collapsed_cond = (
1979       $self->{cond}
1980         ? $self->_collapse_cond($self->{cond})
1981         : {}
1982     );
1983
1984     # precendence must be given to passed values over values inherited from
1985     # the cond, so the order here is important.
1986     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1987     while( my($col,$value) = each %implied ){
1988       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1989         $new{$col} = $value->{'='};
1990         next;
1991       }
1992       $new{$col} = $value if $self->_is_deterministic_value($value);
1993     }
1994   }
1995
1996   %new = (
1997     %new,
1998     %{ $self->_remove_alias($values, $alias) },
1999     -source_handle => $self->_source_handle,
2000     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2001   );
2002
2003   return $self->result_class->new(\%new);
2004 }
2005
2006 # _is_deterministic_value
2007 #
2008 # Make an effor to strip non-deterministic values from the condition,
2009 # to make sure new_result chokes less
2010
2011 sub _is_deterministic_value {
2012   my $self = shift;
2013   my $value = shift;
2014   my $ref_type = ref $value;
2015   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2016   return 1 if Scalar::Util::blessed($value);
2017   return 0;
2018 }
2019
2020 # _has_resolved_attr
2021 #
2022 # determines if the resultset defines at least one
2023 # of the attributes supplied
2024 #
2025 # used to determine if a subquery is neccessary
2026 #
2027 # supports some  virtual attributes:
2028 #   -join
2029 #     This will scan for any joins being present on the resultset.
2030 #     It is not a mere key-search but a deep inspection of {from}
2031 #
2032
2033 sub _has_resolved_attr {
2034   my ($self, @attr_names) = @_;
2035
2036   my $attrs = $self->_resolved_attrs;
2037
2038   my %extra_checks;
2039
2040   for my $n (@attr_names) {
2041     if (grep { $n eq $_ } (qw/-join/) ) {
2042       $extra_checks{$n}++;
2043       next;
2044     }
2045
2046     my $attr =  $attrs->{$n};
2047
2048     next if not defined $attr;
2049
2050     if (ref $attr eq 'HASH') {
2051       return 1 if keys %$attr;
2052     }
2053     elsif (ref $attr eq 'ARRAY') {
2054       return 1 if @$attr;
2055     }
2056     else {
2057       return 1 if $attr;
2058     }
2059   }
2060
2061   # a resolved join is expressed as a multi-level from
2062   return 1 if (
2063     $extra_checks{-join}
2064       and
2065     ref $attrs->{from} eq 'ARRAY'
2066       and
2067     @{$attrs->{from}} > 1
2068   );
2069
2070   return 0;
2071 }
2072
2073 # _collapse_cond
2074 #
2075 # Recursively collapse the condition.
2076
2077 sub _collapse_cond {
2078   my ($self, $cond, $collapsed) = @_;
2079
2080   $collapsed ||= {};
2081
2082   if (ref $cond eq 'ARRAY') {
2083     foreach my $subcond (@$cond) {
2084       next unless ref $subcond;  # -or
2085       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2086     }
2087   }
2088   elsif (ref $cond eq 'HASH') {
2089     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2090       foreach my $subcond (@{$cond->{-and}}) {
2091         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2092       }
2093     }
2094     else {
2095       foreach my $col (keys %$cond) {
2096         my $value = $cond->{$col};
2097         $collapsed->{$col} = $value;
2098       }
2099     }
2100   }
2101
2102   return $collapsed;
2103 }
2104
2105 # _remove_alias
2106 #
2107 # Remove the specified alias from the specified query hash. A copy is made so
2108 # the original query is not modified.
2109
2110 sub _remove_alias {
2111   my ($self, $query, $alias) = @_;
2112
2113   my %orig = %{ $query || {} };
2114   my %unaliased;
2115
2116   foreach my $key (keys %orig) {
2117     if ($key !~ /\./) {
2118       $unaliased{$key} = $orig{$key};
2119       next;
2120     }
2121     $unaliased{$1} = $orig{$key}
2122       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2123   }
2124
2125   return \%unaliased;
2126 }
2127
2128 =head2 as_query (EXPERIMENTAL)
2129
2130 =over 4
2131
2132 =item Arguments: none
2133
2134 =item Return Value: \[ $sql, @bind ]
2135
2136 =back
2137
2138 Returns the SQL query and bind vars associated with the invocant.
2139
2140 This is generally used as the RHS for a subquery.
2141
2142 B<NOTE>: This feature is still experimental.
2143
2144 =cut
2145
2146 sub as_query {
2147   my $self = shift;
2148
2149   my $attrs = $self->_resolved_attrs_copy;
2150
2151   # For future use:
2152   #
2153   # in list ctx:
2154   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2155   # $sql also has no wrapping parenthesis in list ctx
2156   #
2157   my $sqlbind = $self->result_source->storage
2158     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2159
2160   return $sqlbind;
2161 }
2162
2163 =head2 find_or_new
2164
2165 =over 4
2166
2167 =item Arguments: \%vals, \%attrs?
2168
2169 =item Return Value: $rowobject
2170
2171 =back
2172
2173   my $artist = $schema->resultset('Artist')->find_or_new(
2174     { artist => 'fred' }, { key => 'artists' });
2175
2176   $cd->cd_to_producer->find_or_new({ producer => $producer },
2177                                    { key => 'primary });
2178
2179 Find an existing record from this resultset, based on its primary
2180 key, or a unique constraint. If none exists, instantiate a new result
2181 object and return it. The object will not be saved into your storage
2182 until you call L<DBIx::Class::Row/insert> on it.
2183
2184 You most likely want this method when looking for existing rows using
2185 a unique constraint that is not the primary key, or looking for
2186 related rows.
2187
2188 If you want objects to be saved immediately, use L</find_or_create> instead.
2189
2190 B<Note>: C<find_or_new> is probably not what you want when creating a
2191 new row in a table that uses primary keys supplied by the
2192 database. Passing in a primary key column with a value of I<undef>
2193 will cause L</find> to attempt to search for a row with a value of
2194 I<NULL>.
2195
2196 =cut
2197
2198 sub find_or_new {
2199   my $self     = shift;
2200   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2201   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2202   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2203     return $row;
2204   }
2205   return $self->new_result($hash);
2206 }
2207
2208 =head2 create
2209
2210 =over 4
2211
2212 =item Arguments: \%vals
2213
2214 =item Return Value: a L<DBIx::Class::Row> $object
2215
2216 =back
2217
2218 Attempt to create a single new row or a row with multiple related rows
2219 in the table represented by the resultset (and related tables). This
2220 will not check for duplicate rows before inserting, use
2221 L</find_or_create> to do that.
2222
2223 To create one row for this resultset, pass a hashref of key/value
2224 pairs representing the columns of the table and the values you wish to
2225 store. If the appropriate relationships are set up, foreign key fields
2226 can also be passed an object representing the foreign row, and the
2227 value will be set to its primary key.
2228
2229 To create related objects, pass a hashref for the value if the related
2230 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2231 and use the name of the relationship as the key. (NOT the name of the field,
2232 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2233 of hashrefs containing the data for each of the rows to create in the foreign
2234 tables, again using the relationship name as the key.
2235
2236 Instead of hashrefs of plain related data (key/value pairs), you may
2237 also pass new or inserted objects. New objects (not inserted yet, see
2238 L</new>), will be inserted into their appropriate tables.
2239
2240 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2241
2242 Example of creating a new row.
2243
2244   $person_rs->create({
2245     name=>"Some Person",
2246     email=>"somebody@someplace.com"
2247   });
2248
2249 Example of creating a new row and also creating rows in a related C<has_many>
2250 or C<has_one> resultset.  Note Arrayref.
2251
2252   $artist_rs->create(
2253      { artistid => 4, name => 'Manufactured Crap', cds => [
2254         { title => 'My First CD', year => 2006 },
2255         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2256       ],
2257      },
2258   );
2259
2260 Example of creating a new row and also creating a row in a related
2261 C<belongs_to>resultset. Note Hashref.
2262
2263   $cd_rs->create({
2264     title=>"Music for Silly Walks",
2265     year=>2000,
2266     artist => {
2267       name=>"Silly Musician",
2268     }
2269   });
2270
2271 =cut
2272
2273 sub create {
2274   my ($self, $attrs) = @_;
2275   $self->throw_exception( "create needs a hashref" )
2276     unless ref $attrs eq 'HASH';
2277   return $self->new_result($attrs)->insert;
2278 }
2279
2280 =head2 find_or_create
2281
2282 =over 4
2283
2284 =item Arguments: \%vals, \%attrs?
2285
2286 =item Return Value: $rowobject
2287
2288 =back
2289
2290   $cd->cd_to_producer->find_or_create({ producer => $producer },
2291                                       { key => 'primary' });
2292
2293 Tries to find a record based on its primary key or unique constraints; if none
2294 is found, creates one and returns that instead.
2295
2296   my $cd = $schema->resultset('CD')->find_or_create({
2297     cdid   => 5,
2298     artist => 'Massive Attack',
2299     title  => 'Mezzanine',
2300     year   => 2005,
2301   });
2302
2303 Also takes an optional C<key> attribute, to search by a specific key or unique
2304 constraint. For example:
2305
2306   my $cd = $schema->resultset('CD')->find_or_create(
2307     {
2308       artist => 'Massive Attack',
2309       title  => 'Mezzanine',
2310     },
2311     { key => 'cd_artist_title' }
2312   );
2313
2314 B<Note>: Because find_or_create() reads from the database and then
2315 possibly inserts based on the result, this method is subject to a race
2316 condition. Another process could create a record in the table after
2317 the find has completed and before the create has started. To avoid
2318 this problem, use find_or_create() inside a transaction.
2319
2320 B<Note>: C<find_or_create> is probably not what you want when creating
2321 a new row in a table that uses primary keys supplied by the
2322 database. Passing in a primary key column with a value of I<undef>
2323 will cause L</find> to attempt to search for a row with a value of
2324 I<NULL>.
2325
2326 See also L</find> and L</update_or_create>. For information on how to declare
2327 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2328
2329 =cut
2330
2331 sub find_or_create {
2332   my $self     = shift;
2333   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2334   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2335   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2336     return $row;
2337   }
2338   return $self->create($hash);
2339 }
2340
2341 =head2 update_or_create
2342
2343 =over 4
2344
2345 =item Arguments: \%col_values, { key => $unique_constraint }?
2346
2347 =item Return Value: $rowobject
2348
2349 =back
2350
2351   $resultset->update_or_create({ col => $val, ... });
2352
2353 First, searches for an existing row matching one of the unique constraints
2354 (including the primary key) on the source of this resultset. If a row is
2355 found, updates it with the other given column values. Otherwise, creates a new
2356 row.
2357
2358 Takes an optional C<key> attribute to search on a specific unique constraint.
2359 For example:
2360
2361   # In your application
2362   my $cd = $schema->resultset('CD')->update_or_create(
2363     {
2364       artist => 'Massive Attack',
2365       title  => 'Mezzanine',
2366       year   => 1998,
2367     },
2368     { key => 'cd_artist_title' }
2369   );
2370
2371   $cd->cd_to_producer->update_or_create({
2372     producer => $producer,
2373     name => 'harry',
2374   }, {
2375     key => 'primary,
2376   });
2377
2378
2379 If no C<key> is specified, it searches on all unique constraints defined on the
2380 source, including the primary key.
2381
2382 If the C<key> is specified as C<primary>, it searches only on the primary key.
2383
2384 See also L</find> and L</find_or_create>. For information on how to declare
2385 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2386
2387 B<Note>: C<update_or_create> is probably not what you want when
2388 looking for a row in a table that uses primary keys supplied by the
2389 database, unless you actually have a key value. Passing in a primary
2390 key column with a value of I<undef> will cause L</find> to attempt to
2391 search for a row with a value of I<NULL>.
2392
2393 =cut
2394
2395 sub update_or_create {
2396   my $self = shift;
2397   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2398   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2399
2400   my $row = $self->find($cond, $attrs);
2401   if (defined $row) {
2402     $row->update($cond);
2403     return $row;
2404   }
2405
2406   return $self->create($cond);
2407 }
2408
2409 =head2 update_or_new
2410
2411 =over 4
2412
2413 =item Arguments: \%col_values, { key => $unique_constraint }?
2414
2415 =item Return Value: $rowobject
2416
2417 =back
2418
2419   $resultset->update_or_new({ col => $val, ... });
2420
2421 First, searches for an existing row matching one of the unique constraints
2422 (including the primary key) on the source of this resultset. If a row is
2423 found, updates it with the other given column values. Otherwise, instantiate
2424 a new result object and return it. The object will not be saved into your storage
2425 until you call L<DBIx::Class::Row/insert> on it.
2426
2427 Takes an optional C<key> attribute to search on a specific unique constraint.
2428 For example:
2429
2430   # In your application
2431   my $cd = $schema->resultset('CD')->update_or_new(
2432     {
2433       artist => 'Massive Attack',
2434       title  => 'Mezzanine',
2435       year   => 1998,
2436     },
2437     { key => 'cd_artist_title' }
2438   );
2439
2440   if ($cd->in_storage) {
2441       # the cd was updated
2442   }
2443   else {
2444       # the cd is not yet in the database, let's insert it
2445       $cd->insert;
2446   }
2447
2448 See also L</find>, L</find_or_create> and L<find_or_new>.
2449
2450 =cut
2451
2452 sub update_or_new {
2453     my $self  = shift;
2454     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2455     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2456
2457     my $row = $self->find( $cond, $attrs );
2458     if ( defined $row ) {
2459         $row->update($cond);
2460         return $row;
2461     }
2462
2463     return $self->new_result($cond);
2464 }
2465
2466 =head2 get_cache
2467
2468 =over 4
2469
2470 =item Arguments: none
2471
2472 =item Return Value: \@cache_objects?
2473
2474 =back
2475
2476 Gets the contents of the cache for the resultset, if the cache is set.
2477
2478 The cache is populated either by using the L</prefetch> attribute to
2479 L</search> or by calling L</set_cache>.
2480
2481 =cut
2482
2483 sub get_cache {
2484   shift->{all_cache};
2485 }
2486
2487 =head2 set_cache
2488
2489 =over 4
2490
2491 =item Arguments: \@cache_objects
2492
2493 =item Return Value: \@cache_objects
2494
2495 =back
2496
2497 Sets the contents of the cache for the resultset. Expects an arrayref
2498 of objects of the same class as those produced by the resultset. Note that
2499 if the cache is set the resultset will return the cached objects rather
2500 than re-querying the database even if the cache attr is not set.
2501
2502 The contents of the cache can also be populated by using the
2503 L</prefetch> attribute to L</search>.
2504
2505 =cut
2506
2507 sub set_cache {
2508   my ( $self, $data ) = @_;
2509   $self->throw_exception("set_cache requires an arrayref")
2510       if defined($data) && (ref $data ne 'ARRAY');
2511   $self->{all_cache} = $data;
2512 }
2513
2514 =head2 clear_cache
2515
2516 =over 4
2517
2518 =item Arguments: none
2519
2520 =item Return Value: []
2521
2522 =back
2523
2524 Clears the cache for the resultset.
2525
2526 =cut
2527
2528 sub clear_cache {
2529   shift->set_cache(undef);
2530 }
2531
2532 =head2 related_resultset
2533
2534 =over 4
2535
2536 =item Arguments: $relationship_name
2537
2538 =item Return Value: $resultset
2539
2540 =back
2541
2542 Returns a related resultset for the supplied relationship name.
2543
2544   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2545
2546 =cut
2547
2548 sub related_resultset {
2549   my ($self, $rel) = @_;
2550
2551   $self->{related_resultsets} ||= {};
2552   return $self->{related_resultsets}{$rel} ||= do {
2553     my $rel_info = $self->result_source->relationship_info($rel);
2554
2555     $self->throw_exception(
2556       "search_related: result source '" . $self->result_source->source_name .
2557         "' has no such relationship $rel")
2558       unless $rel_info;
2559
2560     my ($from,$seen) = $self->_chain_relationship($rel);
2561
2562     my $join_count = $seen->{$rel};
2563     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2564
2565     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2566     my %attrs = %{$self->{attrs}||{}};
2567     delete @attrs{qw(result_class alias)};
2568
2569     my $new_cache;
2570
2571     if (my $cache = $self->get_cache) {
2572       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2573         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2574                         @$cache ];
2575       }
2576     }
2577
2578     my $rel_source = $self->result_source->related_source($rel);
2579
2580     my $new = do {
2581
2582       # The reason we do this now instead of passing the alias to the
2583       # search_rs below is that if you wrap/overload resultset on the
2584       # source you need to know what alias it's -going- to have for things
2585       # to work sanely (e.g. RestrictWithObject wants to be able to add
2586       # extra query restrictions, and these may need to be $alias.)
2587
2588       my $attrs = $rel_source->resultset_attributes;
2589       local $attrs->{alias} = $alias;
2590
2591       $rel_source->resultset
2592                  ->search_rs(
2593                      undef, {
2594                        %attrs,
2595                        join => undef,
2596                        prefetch => undef,
2597                        select => undef,
2598                        as => undef,
2599                        where => $self->{cond},
2600                        seen_join => $seen,
2601                        from => $from,
2602                    });
2603     };
2604     $new->set_cache($new_cache) if $new_cache;
2605     $new;
2606   };
2607 }
2608
2609 =head2 current_source_alias
2610
2611 =over 4
2612
2613 =item Arguments: none
2614
2615 =item Return Value: $source_alias
2616
2617 =back
2618
2619 Returns the current table alias for the result source this resultset is built
2620 on, that will be used in the SQL query. Usually it is C<me>.
2621
2622 Currently the source alias that refers to the result set returned by a
2623 L</search>/L</find> family method depends on how you got to the resultset: it's
2624 C<me> by default, but eg. L</search_related> aliases it to the related result
2625 source name (and keeps C<me> referring to the original result set). The long
2626 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2627 (and make this method unnecessary).
2628
2629 Thus it's currently necessary to use this method in predefined queries (see
2630 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2631 source alias of the current result set:
2632
2633   # in a result set class
2634   sub modified_by {
2635     my ($self, $user) = @_;
2636
2637     my $me = $self->current_source_alias;
2638
2639     return $self->search(
2640       "$me.modified" => $user->id,
2641     );
2642   }
2643
2644 =cut
2645
2646 sub current_source_alias {
2647   my ($self) = @_;
2648
2649   return ($self->{attrs} || {})->{alias} || 'me';
2650 }
2651
2652 # This code is called by search_related, and makes sure there
2653 # is clear separation between the joins before, during, and
2654 # after the relationship. This information is needed later
2655 # in order to properly resolve prefetch aliases (any alias
2656 # with a relation_chain_depth less than the depth of the
2657 # current prefetch is not considered)
2658 sub _chain_relationship {
2659   my ($self, $rel) = @_;
2660   my $source = $self->result_source;
2661   my $attrs = $self->{attrs};
2662
2663   my $from = [ @{
2664       $attrs->{from}
2665         ||
2666       [{
2667         -source_handle => $source->handle,
2668         -alias => $attrs->{alias},
2669         $attrs->{alias} => $source->from,
2670       }]
2671   }];
2672
2673   my $seen = { %{$attrs->{seen_join} || {} } };
2674
2675   # we need to take the prefetch the attrs into account before we
2676   # ->_resolve_join as otherwise they get lost - captainL
2677   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2678
2679   my @requested_joins = $source->_resolve_join($merged, $attrs->{alias}, $seen);
2680
2681   push @$from, @requested_joins;
2682
2683   ++$seen->{-relation_chain_depth};
2684
2685   # if $self already had a join/prefetch specified on it, the requested
2686   # $rel might very well be already included. What we do in this case
2687   # is effectively a no-op (except that we bump up the chain_depth on
2688   # the join in question so we could tell it *is* the search_related)
2689   my $already_joined;
2690
2691   # we consider the last one thus reverse
2692   for my $j (reverse @requested_joins) {
2693     if ($rel eq $j->[0]{-join_path}[-1]) {
2694       $j->[0]{-relation_chain_depth}++;
2695       $already_joined++;
2696       last;
2697     }
2698   }
2699   unless ($already_joined) {
2700     push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2701   }
2702
2703   ++$seen->{-relation_chain_depth};
2704
2705   return ($from,$seen);
2706 }
2707
2708 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2709 sub _resolved_attrs_copy {
2710   my $self = shift;
2711   return { %{$self->_resolved_attrs (@_)} };
2712 }
2713
2714 sub _resolved_attrs {
2715   my $self = shift;
2716   return $self->{_attrs} if $self->{_attrs};
2717
2718   my $attrs  = { %{ $self->{attrs} || {} } };
2719   my $source = $self->result_source;
2720   my $alias  = $attrs->{alias};
2721
2722   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2723   my @colbits;
2724
2725   # build columns (as long as select isn't set) into a set of as/select hashes
2726   unless ( $attrs->{select} ) {
2727       @colbits = map {
2728           ( ref($_) eq 'HASH' )
2729               ? $_
2730               : {
2731                   (
2732                     /^\Q${alias}.\E(.+)$/
2733                       ? "$1"
2734                       : "$_"
2735                   )
2736                 =>
2737                   (
2738                     /\./
2739                       ? "$_"
2740                       : "${alias}.$_"
2741                   )
2742             }
2743       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2744   }
2745   # add the additional columns on
2746   foreach ( 'include_columns', '+columns' ) {
2747       push @colbits, map {
2748           ( ref($_) eq 'HASH' )
2749             ? $_
2750             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2751       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2752   }
2753
2754   # start with initial select items
2755   if ( $attrs->{select} ) {
2756     $attrs->{select} =
2757         ( ref $attrs->{select} eq 'ARRAY' )
2758       ? [ @{ $attrs->{select} } ]
2759       : [ $attrs->{select} ];
2760     $attrs->{as} = (
2761       $attrs->{as}
2762       ? (
2763         ref $attrs->{as} eq 'ARRAY'
2764         ? [ @{ $attrs->{as} } ]
2765         : [ $attrs->{as} ]
2766         )
2767       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2768     );
2769   }
2770   else {
2771
2772     # otherwise we intialise select & as to empty
2773     $attrs->{select} = [];
2774     $attrs->{as}     = [];
2775   }
2776
2777   # now add colbits to select/as
2778   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2779   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2780
2781   my $adds;
2782   if ( $adds = delete $attrs->{'+select'} ) {
2783     $adds = [$adds] unless ref $adds eq 'ARRAY';
2784     push(
2785       @{ $attrs->{select} },
2786       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2787     );
2788   }
2789   if ( $adds = delete $attrs->{'+as'} ) {
2790     $adds = [$adds] unless ref $adds eq 'ARRAY';
2791     push( @{ $attrs->{as} }, @$adds );
2792   }
2793
2794   $attrs->{from} ||= [ {
2795     -source_handle => $source->handle,
2796     -alias => $self->{attrs}{alias},
2797     $self->{attrs}{alias} => $source->from,
2798   } ];
2799
2800   if ( $attrs->{join} || $attrs->{prefetch} ) {
2801
2802     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2803       if ref $attrs->{from} ne 'ARRAY';
2804
2805     my $join = delete $attrs->{join} || {};
2806
2807     if ( defined $attrs->{prefetch} ) {
2808       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2809     }
2810
2811     $attrs->{from} =    # have to copy here to avoid corrupting the original
2812       [
2813         @{ $attrs->{from} },
2814         $source->_resolve_join(
2815           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2816         )
2817       ];
2818   }
2819
2820   if ( $attrs->{order_by} ) {
2821     $attrs->{order_by} = (
2822       ref( $attrs->{order_by} ) eq 'ARRAY'
2823       ? [ @{ $attrs->{order_by} } ]
2824       : [ $attrs->{order_by} ]
2825     );
2826   }
2827
2828   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2829     $attrs->{group_by} = [ $attrs->{group_by} ];
2830   }
2831
2832   # If the order_by is otherwise empty - we will use this for TOP limit
2833   # emulation and the like.
2834   # Although this is needed only if the order_by is not defined, it is
2835   # actually cheaper to just populate this rather than properly examining
2836   # order_by (stuf like [ {} ] and the like)
2837   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2838
2839
2840   $attrs->{collapse} ||= {};
2841   if ( my $prefetch = delete $attrs->{prefetch} ) {
2842     $prefetch = $self->_merge_attr( {}, $prefetch );
2843
2844     my $prefetch_ordering = [];
2845
2846     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2847
2848     my @prefetch =
2849       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2850
2851     $attrs->{prefetch_select} = [ map { $_->[0] } @prefetch ];
2852     push @{ $attrs->{select} }, @{$attrs->{prefetch_select}};
2853     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2854
2855     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2856     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2857   }
2858
2859
2860   if (delete $attrs->{distinct}) {
2861     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2862   }
2863
2864   # if both page and offset are specified, produce a combined offset
2865   # even though it doesn't make much sense, this is what pre 081xx has
2866   # been doing
2867   if (my $page = delete $attrs->{page}) {
2868     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2869       ($attrs->{offset} || 0);
2870   }
2871
2872   return $self->{_attrs} = $attrs;
2873 }
2874
2875 sub _joinpath_aliases {
2876   my ($self, $fromspec, $seen) = @_;
2877
2878   my $paths = {};
2879   return $paths unless ref $fromspec eq 'ARRAY';
2880
2881   for my $j (@$fromspec) {
2882
2883     next if ref $j ne 'ARRAY';
2884     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2885
2886     my $p = $paths;
2887     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2888     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2889   }
2890
2891   return $paths;
2892 }
2893
2894 sub _rollout_attr {
2895   my ($self, $attr) = @_;
2896
2897   if (ref $attr eq 'HASH') {
2898     return $self->_rollout_hash($attr);
2899   } elsif (ref $attr eq 'ARRAY') {
2900     return $self->_rollout_array($attr);
2901   } else {
2902     return [$attr];
2903   }
2904 }
2905
2906 sub _rollout_array {
2907   my ($self, $attr) = @_;
2908
2909   my @rolled_array;
2910   foreach my $element (@{$attr}) {
2911     if (ref $element eq 'HASH') {
2912       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2913     } elsif (ref $element eq 'ARRAY') {
2914       #  XXX - should probably recurse here
2915       push( @rolled_array, @{$self->_rollout_array($element)} );
2916     } else {
2917       push( @rolled_array, $element );
2918     }
2919   }
2920   return \@rolled_array;
2921 }
2922
2923 sub _rollout_hash {
2924   my ($self, $attr) = @_;
2925
2926   my @rolled_array;
2927   foreach my $key (keys %{$attr}) {
2928     push( @rolled_array, { $key => $attr->{$key} } );
2929   }
2930   return \@rolled_array;
2931 }
2932
2933 sub _calculate_score {
2934   my ($self, $a, $b) = @_;
2935
2936   if (ref $b eq 'HASH') {
2937     my ($b_key) = keys %{$b};
2938     if (ref $a eq 'HASH') {
2939       my ($a_key) = keys %{$a};
2940       if ($a_key eq $b_key) {
2941         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2942       } else {
2943         return 0;
2944       }
2945     } else {
2946       return ($a eq $b_key) ? 1 : 0;
2947     }
2948   } else {
2949     if (ref $a eq 'HASH') {
2950       my ($a_key) = keys %{$a};
2951       return ($b eq $a_key) ? 1 : 0;
2952     } else {
2953       return ($b eq $a) ? 1 : 0;
2954     }
2955   }
2956 }
2957
2958 sub _merge_attr {
2959   my ($self, $orig, $import) = @_;
2960
2961   return $import unless defined($orig);
2962   return $orig unless defined($import);
2963
2964   $orig = $self->_rollout_attr($orig);
2965   $import = $self->_rollout_attr($import);
2966
2967   my $seen_keys;
2968   foreach my $import_element ( @{$import} ) {
2969     # find best candidate from $orig to merge $b_element into
2970     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2971     foreach my $orig_element ( @{$orig} ) {
2972       my $score = $self->_calculate_score( $orig_element, $import_element );
2973       if ($score > $best_candidate->{score}) {
2974         $best_candidate->{position} = $position;
2975         $best_candidate->{score} = $score;
2976       }
2977       $position++;
2978     }
2979     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2980
2981     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2982       push( @{$orig}, $import_element );
2983     } else {
2984       my $orig_best = $orig->[$best_candidate->{position}];
2985       # merge orig_best and b_element together and replace original with merged
2986       if (ref $orig_best ne 'HASH') {
2987         $orig->[$best_candidate->{position}] = $import_element;
2988       } elsif (ref $import_element eq 'HASH') {
2989         my ($key) = keys %{$orig_best};
2990         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2991       }
2992     }
2993     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2994   }
2995
2996   return $orig;
2997 }
2998
2999 sub result_source {
3000     my $self = shift;
3001
3002     if (@_) {
3003         $self->_source_handle($_[0]->handle);
3004     } else {
3005         $self->_source_handle->resolve;
3006     }
3007 }
3008
3009 =head2 throw_exception
3010
3011 See L<DBIx::Class::Schema/throw_exception> for details.
3012
3013 =cut
3014
3015 sub throw_exception {
3016   my $self=shift;
3017   if (ref $self && $self->_source_handle->schema) {
3018     $self->_source_handle->schema->throw_exception(@_)
3019   } else {
3020     croak(@_);
3021   }
3022
3023 }
3024
3025 # XXX: FIXME: Attributes docs need clearing up
3026
3027 =head1 ATTRIBUTES
3028
3029 Attributes are used to refine a ResultSet in various ways when
3030 searching for data. They can be passed to any method which takes an
3031 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3032 L</count>.
3033
3034 These are in no particular order:
3035
3036 =head2 order_by
3037
3038 =over 4
3039
3040 =item Value: ( $order_by | \@order_by | \%order_by )
3041
3042 =back
3043
3044 Which column(s) to order the results by. If a single column name, or
3045 an arrayref of names is supplied, the argument is passed through
3046 directly to SQL. The hashref syntax allows for connection-agnostic
3047 specification of ordering direction:
3048
3049  For descending order:
3050
3051   order_by => { -desc => [qw/col1 col2 col3/] }
3052
3053  For explicit ascending order:
3054
3055   order_by => { -asc => 'col' }
3056
3057 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3058 supported, although you are strongly encouraged to use the hashref
3059 syntax as outlined above.
3060
3061 =head2 columns
3062
3063 =over 4
3064
3065 =item Value: \@columns
3066
3067 =back
3068
3069 Shortcut to request a particular set of columns to be retrieved. Each
3070 column spec may be a string (a table column name), or a hash (in which
3071 case the key is the C<as> value, and the value is used as the C<select>
3072 expression). Adds C<me.> onto the start of any column without a C<.> in
3073 it and sets C<select> from that, then auto-populates C<as> from
3074 C<select> as normal. (You may also use the C<cols> attribute, as in
3075 earlier versions of DBIC.)
3076
3077 =head2 +columns
3078
3079 =over 4
3080
3081 =item Value: \@columns
3082
3083 =back
3084
3085 Indicates additional columns to be selected from storage. Works the same
3086 as L</columns> but adds columns to the selection. (You may also use the
3087 C<include_columns> attribute, as in earlier versions of DBIC). For
3088 example:-
3089
3090   $schema->resultset('CD')->search(undef, {
3091     '+columns' => ['artist.name'],
3092     join => ['artist']
3093   });
3094
3095 would return all CDs and include a 'name' column to the information
3096 passed to object inflation. Note that the 'artist' is the name of the
3097 column (or relationship) accessor, and 'name' is the name of the column
3098 accessor in the related table.
3099
3100 =head2 include_columns
3101
3102 =over 4
3103
3104 =item Value: \@columns
3105
3106 =back
3107
3108 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3109
3110 =head2 select
3111
3112 =over 4
3113
3114 =item Value: \@select_columns
3115
3116 =back
3117
3118 Indicates which columns should be selected from the storage. You can use
3119 column names, or in the case of RDBMS back ends, function or stored procedure
3120 names:
3121
3122   $rs = $schema->resultset('Employee')->search(undef, {
3123     select => [
3124       'name',
3125       { count => 'employeeid' },
3126       { sum => 'salary' }
3127     ]
3128   });
3129
3130 When you use function/stored procedure names and do not supply an C<as>
3131 attribute, the column names returned are storage-dependent. E.g. MySQL would
3132 return a column named C<count(employeeid)> in the above example.
3133
3134 =head2 +select
3135
3136 =over 4
3137
3138 Indicates additional columns to be selected from storage.  Works the same as
3139 L</select> but adds columns to the selection.
3140
3141 =back
3142
3143 =head2 +as
3144
3145 =over 4
3146
3147 Indicates additional column names for those added via L</+select>. See L</as>.
3148
3149 =back
3150
3151 =head2 as
3152
3153 =over 4
3154
3155 =item Value: \@inflation_names
3156
3157 =back
3158
3159 Indicates column names for object inflation. That is, C<as>
3160 indicates the name that the column can be accessed as via the
3161 C<get_column> method (or via the object accessor, B<if one already
3162 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3163
3164 The C<as> attribute is used in conjunction with C<select>,
3165 usually when C<select> contains one or more function or stored
3166 procedure names:
3167
3168   $rs = $schema->resultset('Employee')->search(undef, {
3169     select => [
3170       'name',
3171       { count => 'employeeid' }
3172     ],
3173     as => ['name', 'employee_count'],
3174   });
3175
3176   my $employee = $rs->first(); # get the first Employee
3177
3178 If the object against which the search is performed already has an accessor
3179 matching a column name specified in C<as>, the value can be retrieved using
3180 the accessor as normal:
3181
3182   my $name = $employee->name();
3183
3184 If on the other hand an accessor does not exist in the object, you need to
3185 use C<get_column> instead:
3186
3187   my $employee_count = $employee->get_column('employee_count');
3188
3189 You can create your own accessors if required - see
3190 L<DBIx::Class::Manual::Cookbook> for details.
3191
3192 Please note: This will NOT insert an C<AS employee_count> into the SQL
3193 statement produced, it is used for internal access only. Thus
3194 attempting to use the accessor in an C<order_by> clause or similar
3195 will fail miserably.
3196
3197 To get around this limitation, you can supply literal SQL to your
3198 C<select> attibute that contains the C<AS alias> text, eg:
3199
3200   select => [\'myfield AS alias']
3201
3202 =head2 join
3203
3204 =over 4
3205
3206 =item Value: ($rel_name | \@rel_names | \%rel_names)
3207
3208 =back
3209
3210 Contains a list of relationships that should be joined for this query.  For
3211 example:
3212
3213   # Get CDs by Nine Inch Nails
3214   my $rs = $schema->resultset('CD')->search(
3215     { 'artist.name' => 'Nine Inch Nails' },
3216     { join => 'artist' }
3217   );
3218
3219 Can also contain a hash reference to refer to the other relation's relations.
3220 For example:
3221
3222   package MyApp::Schema::Track;
3223   use base qw/DBIx::Class/;
3224   __PACKAGE__->table('track');
3225   __PACKAGE__->add_columns(qw/trackid cd position title/);
3226   __PACKAGE__->set_primary_key('trackid');
3227   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3228   1;
3229
3230   # In your application
3231   my $rs = $schema->resultset('Artist')->search(
3232     { 'track.title' => 'Teardrop' },
3233     {
3234       join     => { cd => 'track' },
3235       order_by => 'artist.name',
3236     }
3237   );
3238
3239 You need to use the relationship (not the table) name in  conditions,
3240 because they are aliased as such. The current table is aliased as "me", so
3241 you need to use me.column_name in order to avoid ambiguity. For example:
3242
3243   # Get CDs from 1984 with a 'Foo' track
3244   my $rs = $schema->resultset('CD')->search(
3245     {
3246       'me.year' => 1984,
3247       'tracks.name' => 'Foo'
3248     },
3249     { join => 'tracks' }
3250   );
3251
3252 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3253 similarly for a third time). For e.g.
3254
3255   my $rs = $schema->resultset('Artist')->search({
3256     'cds.title'   => 'Down to Earth',
3257     'cds_2.title' => 'Popular',
3258   }, {
3259     join => [ qw/cds cds/ ],
3260   });
3261
3262 will return a set of all artists that have both a cd with title 'Down
3263 to Earth' and a cd with title 'Popular'.
3264
3265 If you want to fetch related objects from other tables as well, see C<prefetch>
3266 below.
3267
3268 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3269
3270 =head2 prefetch
3271
3272 =over 4
3273
3274 =item Value: ($rel_name | \@rel_names | \%rel_names)
3275
3276 =back
3277
3278 Contains one or more relationships that should be fetched along with
3279 the main query (when they are accessed afterwards the data will
3280 already be available, without extra queries to the database).  This is
3281 useful for when you know you will need the related objects, because it
3282 saves at least one query:
3283
3284   my $rs = $schema->resultset('Tag')->search(
3285     undef,
3286     {
3287       prefetch => {
3288         cd => 'artist'
3289       }
3290     }
3291   );
3292
3293 The initial search results in SQL like the following:
3294
3295   SELECT tag.*, cd.*, artist.* FROM tag
3296   JOIN cd ON tag.cd = cd.cdid
3297   JOIN artist ON cd.artist = artist.artistid
3298
3299 L<DBIx::Class> has no need to go back to the database when we access the
3300 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3301 case.
3302
3303 Simple prefetches will be joined automatically, so there is no need
3304 for a C<join> attribute in the above search.
3305
3306 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3307 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3308 with an accessor type of 'single' or 'filter'). A more complex example that
3309 prefetches an artists cds, the tracks on those cds, and the tags associted
3310 with that artist is given below (assuming many-to-many from artists to tags):
3311
3312  my $rs = $schema->resultset('Artist')->search(
3313    undef,
3314    {
3315      prefetch => [
3316        { cds => 'tracks' },
3317        { artist_tags => 'tags' }
3318      ]
3319    }
3320  );
3321
3322
3323 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3324 attributes will be ignored.
3325
3326 =head2 page
3327
3328 =over 4
3329
3330 =item Value: $page
3331
3332 =back
3333
3334 Makes the resultset paged and specifies the page to retrieve. Effectively
3335 identical to creating a non-pages resultset and then calling ->page($page)
3336 on it.
3337
3338 If L<rows> attribute is not specified it defaults to 10 rows per page.
3339
3340 When you have a paged resultset, L</count> will only return the number
3341 of rows in the page. To get the total, use the L</pager> and call
3342 C<total_entries> on it.
3343
3344 =head2 rows
3345
3346 =over 4
3347
3348 =item Value: $rows
3349
3350 =back
3351
3352 Specifes the maximum number of rows for direct retrieval or the number of
3353 rows per page if the page attribute or method is used.
3354
3355 =head2 offset
3356
3357 =over 4
3358
3359 =item Value: $offset
3360
3361 =back
3362
3363 Specifies the (zero-based) row number for the  first row to be returned, or the
3364 of the first row of the first page if paging is used.
3365
3366 =head2 group_by
3367
3368 =over 4
3369
3370 =item Value: \@columns
3371
3372 =back
3373
3374 A arrayref of columns to group by. Can include columns of joined tables.
3375
3376   group_by => [qw/ column1 column2 ... /]
3377
3378 =head2 having
3379
3380 =over 4
3381
3382 =item Value: $condition
3383
3384 =back
3385
3386 HAVING is a select statement attribute that is applied between GROUP BY and
3387 ORDER BY. It is applied to the after the grouping calculations have been
3388 done.
3389
3390   having => { 'count(employee)' => { '>=', 100 } }
3391
3392 =head2 distinct
3393
3394 =over 4
3395
3396 =item Value: (0 | 1)
3397
3398 =back
3399
3400 Set to 1 to group by all columns.
3401
3402 =head2 where
3403
3404 =over 4
3405
3406 Adds to the WHERE clause.
3407
3408   # only return rows WHERE deleted IS NULL for all searches
3409   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3410
3411 Can be overridden by passing C<{ where => undef }> as an attribute
3412 to a resulset.
3413
3414 =back
3415
3416 =head2 cache
3417
3418 Set to 1 to cache search results. This prevents extra SQL queries if you
3419 revisit rows in your ResultSet:
3420
3421   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3422
3423   while( my $artist = $resultset->next ) {
3424     ... do stuff ...
3425   }
3426
3427   $rs->first; # without cache, this would issue a query
3428
3429 By default, searches are not cached.
3430
3431 For more examples of using these attributes, see
3432 L<DBIx::Class::Manual::Cookbook>.
3433
3434 =head2 from
3435
3436 =over 4
3437
3438 =item Value: \@from_clause
3439
3440 =back
3441
3442 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3443 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3444 clauses.
3445
3446 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3447
3448 C<join> will usually do what you need and it is strongly recommended that you
3449 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3450 And we really do mean "cannot", not just tried and failed. Attempting to use
3451 this because you're having problems with C<join> is like trying to use x86
3452 ASM because you've got a syntax error in your C. Trust us on this.
3453
3454 Now, if you're still really, really sure you need to use this (and if you're
3455 not 100% sure, ask the mailing list first), here's an explanation of how this
3456 works.
3457
3458 The syntax is as follows -
3459
3460   [
3461     { <alias1> => <table1> },
3462     [
3463       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3464       [], # nested JOIN (optional)
3465       { <table1.column1> => <table2.column2>, ... (more conditions) },
3466     ],
3467     # More of the above [ ] may follow for additional joins
3468   ]
3469
3470   <table1> <alias1>
3471   JOIN
3472     <table2> <alias2>
3473     [JOIN ...]
3474   ON <table1.column1> = <table2.column2>
3475   <more joins may follow>
3476
3477 An easy way to follow the examples below is to remember the following:
3478
3479     Anything inside "[]" is a JOIN
3480     Anything inside "{}" is a condition for the enclosing JOIN
3481
3482 The following examples utilize a "person" table in a family tree application.
3483 In order to express parent->child relationships, this table is self-joined:
3484
3485     # Person->belongs_to('father' => 'Person');
3486     # Person->belongs_to('mother' => 'Person');
3487
3488 C<from> can be used to nest joins. Here we return all children with a father,
3489 then search against all mothers of those children:
3490
3491   $rs = $schema->resultset('Person')->search(
3492       undef,
3493       {
3494           alias => 'mother', # alias columns in accordance with "from"
3495           from => [
3496               { mother => 'person' },
3497               [
3498                   [
3499                       { child => 'person' },
3500                       [
3501                           { father => 'person' },
3502                           { 'father.person_id' => 'child.father_id' }
3503                       ]
3504                   ],
3505                   { 'mother.person_id' => 'child.mother_id' }
3506               ],
3507           ]
3508       },
3509   );
3510
3511   # Equivalent SQL:
3512   # SELECT mother.* FROM person mother
3513   # JOIN (
3514   #   person child
3515   #   JOIN person father
3516   #   ON ( father.person_id = child.father_id )
3517   # )
3518   # ON ( mother.person_id = child.mother_id )
3519
3520 The type of any join can be controlled manually. To search against only people
3521 with a father in the person table, we could explicitly use C<INNER JOIN>:
3522
3523     $rs = $schema->resultset('Person')->search(
3524         undef,
3525         {
3526             alias => 'child', # alias columns in accordance with "from"
3527             from => [
3528                 { child => 'person' },
3529                 [
3530                     { father => 'person', -join_type => 'inner' },
3531                     { 'father.id' => 'child.father_id' }
3532                 ],
3533             ]
3534         },
3535     );
3536
3537     # Equivalent SQL:
3538     # SELECT child.* FROM person child
3539     # INNER JOIN person father ON child.father_id = father.id
3540
3541 You can select from a subquery by passing a resultset to from as follows.
3542
3543     $schema->resultset('Artist')->search(
3544         undef,
3545         {   alias => 'artist2',
3546             from  => [ { artist2 => $artist_rs->as_query } ],
3547         } );
3548
3549     # and you'll get sql like this..
3550     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3551     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3552
3553 If you need to express really complex joins, you
3554 can supply literal SQL to C<from> via a scalar reference. In this case
3555 the contents of the scalar will replace the table name associated with the
3556 resultsource.
3557
3558 WARNING: This technique might very well not work as expected on chained
3559 searches - you have been warned.
3560
3561     # Assuming the Event resultsource is defined as:
3562
3563         MySchema::Event->add_columns (
3564             sequence => {
3565                 data_type => 'INT',
3566                 is_auto_increment => 1,
3567             },
3568             location => {
3569                 data_type => 'INT',
3570             },
3571             type => {
3572                 data_type => 'INT',
3573             },
3574         );
3575         MySchema::Event->set_primary_key ('sequence');
3576
3577     # This will get back the latest event for every location. The column
3578     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3579     # combo to limit the resultset
3580
3581     $rs = $schema->resultset('Event');
3582     $table = $rs->result_source->name;
3583     $latest = $rs->search (
3584         undef,
3585         { from => \ "
3586             (SELECT e1.* FROM $table e1
3587                 JOIN $table e2
3588                     ON e1.location = e2.location
3589                     AND e1.sequence < e2.sequence
3590                 WHERE e2.sequence is NULL
3591             ) me",
3592         },
3593     );
3594
3595     # Equivalent SQL (with the DBIC chunks added):
3596
3597     SELECT me.sequence, me.location, me.type FROM
3598        (SELECT e1.* FROM events e1
3599            JOIN events e2
3600                ON e1.location = e2.location
3601                AND e1.sequence < e2.sequence
3602            WHERE e2.sequence is NULL
3603        ) me;
3604
3605 =head2 for
3606
3607 =over 4
3608
3609 =item Value: ( 'update' | 'shared' )
3610
3611 =back
3612
3613 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3614 ... FOR SHARED.
3615
3616 =cut
3617
3618 1;