lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304
 305   if (ref $class) {
 306     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 307     return $class->new_result(@_);
 308   }
 309
 310   my ($source, $attrs) = @_;
 311   $source = $source->resolve
 312     if $source->isa('DBIx::Class::ResultSourceHandle');
 313
 314   $attrs = { %{$attrs||{}} };
 315   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 316
 317   if ($attrs->{page}) {
 318     $attrs->{rows} ||= 10;
 319   }
 320
 321   $attrs->{alias} ||= 'me';
 322
 323   my $self = bless {
 324     result_source => $source,
 325     cond => $attrs->{where},
 326     pager => undef,
 327     attrs => $attrs,
 328   }, $class;
 329
 330   # if there is a dark selector, this means we are already in a
 331   # chain and the cleanup/sanification was taken care of by
 332   # _search_rs already
 333   $self->_normalize_selection($attrs)
 334     unless $attrs->{_dark_selector};
 335
 336   $self->result_class(
 337     $attrs->{result_class} || $source->result_class
 338   );
 339
 340   $self;
 341 }
 342
 343 =head2 search
 344
 345 =over 4
 346
 347 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 348
 349 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 350
 351 =back
 352
 353   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 354   my $new_rs = $cd_rs->search({ year => 2005 });
 355
 356   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 357                  # year = 2005 OR year = 2004
 358
 359 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 360 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 361 To avoid that, use L</search_rs>.
 362
 363 If you need to pass in additional attributes but no additional condition,
 364 call it as C<search(undef, \%attrs)>.
 365
 366   # "SELECT name, artistid FROM $artist_table"
 367   my @all_artists = $schema->resultset('Artist')->search(undef, {
 368     columns => [qw/name artistid/],
 369   });
 370
 371 For a list of attributes that can be passed to C<search>, see
 372 L</ATTRIBUTES>. For more examples of using this function, see
 373 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 374 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 375 and its extension L<DBIx::Class::SQLMaker>.
 376
 377 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 378
 379 =head3 CAVEAT
 380
 381 Note that L</search> does not process/deflate any of the values passed in the
 382 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 383 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 384 manually that any value passed to this method will stringify to something the
 385 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 386 objects, for more info see:
 387 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 388
 389 =cut
 390
 391 sub search {
 392   my $self = shift;
 393   my $rs = $self->search_rs( @_ );
 394
 395   if (wantarray) {
 396     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 397     return $rs->all;
 398   }
 399   elsif (defined wantarray) {
 400     return $rs;
 401   }
 402   else {
 403     # we can be called by a relationship helper, which in
 404     # turn may be called in void context due to some braindead
 405     # overload or whatever else the user decided to be clever
 406     # at this particular day. Thus limit the exception to
 407     # external code calls only
 408     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 409       if (caller)[0] !~ /^\QDBIx::Class::/;
 410
 411     return ();
 412   }
 413 }
 414
 415 =head2 search_rs
 416
 417 =over 4
 418
 419 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 420
 421 =item Return Value: L<$resultset|/search>
 422
 423 =back
 424
 425 This method does the same exact thing as search() except it will
 426 always return a resultset, even in list context.
 427
 428 =cut
 429
 430 sub search_rs {
 431   my $self = shift;
 432
 433   my $rsrc = $self->result_source;
 434   my ($call_cond, $call_attrs);
 435
 436   # Special-case handling for (undef, undef) or (undef)
 437   # Note that (foo => undef) is valid deprecated syntax
 438   @_ = () if not scalar grep { defined $_ } @_;
 439
 440   # just a cond
 441   if (@_ == 1) {
 442     $call_cond = shift;
 443   }
 444   # fish out attrs in the ($condref, $attr) case
 445   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 446     ($call_cond, $call_attrs) = @_;
 447   }
 448   elsif (@_ % 2) {
 449     $self->throw_exception('Odd number of arguments to search')
 450   }
 451   # legacy search
 452   elsif (@_) {
 453     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 454       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 455
 456     for my $i (0 .. $#_) {
 457       next if $i % 2;
 458       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 459         if (! defined $_[$i] or ref $_[$i] ne '');
 460     }
 461
 462     $call_cond = { @_ };
 463   }
 464
 465   # see if we can keep the cache (no $rs changes)
 466   my $cache;
 467   my %safe = (alias => 1, cache => 1);
 468   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 469     ! defined $call_cond
 470       or
 471     ref $call_cond eq 'HASH' && ! keys %$call_cond
 472       or
 473     ref $call_cond eq 'ARRAY' && ! @$call_cond
 474   )) {
 475     $cache = $self->get_cache;
 476   }
 477
 478   my $old_attrs = { %{$self->{attrs}} };
 479   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 480
 481   my $new_attrs = { %$old_attrs };
 482
 483   # take care of call attrs (only if anything is changing)
 484   if ($call_attrs and keys %$call_attrs) {
 485
 486     # copy for _normalize_selection
 487     $call_attrs = { %$call_attrs };
 488
 489     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 490
 491     # reset the current selector list if new selectors are supplied
 492     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 493       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 494     }
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 my $dark_sel_dumper;
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => ($dark_sel_dumper ||= do {
 622                   require Data::Dumper::Concise;
 623                   Data::Dumper::Concise::DumperObject()->Indent(0);
 624                 })->Values([$_])->Dump
 625               ,
 626             };
 627             last SELECTOR;
 628           }
 629         }
 630       }
 631     }
 632     elsif (@$as < @$sel) {
 633       $self->throw_exception(
 634         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 635       );
 636     }
 637     elsif ($pref and $attrs->{_dark_selector}) {
 638       $self->throw_exception(
 639         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 640       );
 641     }
 642
 643
 644     # merge result
 645     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 646     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 647   }
 648 }
 649
 650 sub _stack_cond {
 651   my ($self, $left, $right) = @_;
 652
 653   (
 654     (ref $_ eq 'ARRAY' and !@$_)
 655       or
 656     (ref $_ eq 'HASH' and ! keys %$_)
 657   ) and $_ = undef for ($left, $right);
 658
 659   # either on of the two undef or both undef
 660   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 661     return defined $left ? $left : $right;
 662   }
 663
 664   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 665
 666   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 667
 668     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 669     my @fin = shift @vals;
 670
 671     for my $v (@vals) {
 672       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 673     }
 674
 675     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 676   }
 677
 678   $cond;
 679 }
 680
 681 =head2 search_literal
 682
 683 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 684 should only be used in that context. C<search_literal> is a convenience
 685 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 686 want to ensure columns are bound correctly, use L</search>.
 687
 688 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 689 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 690 require C<search_literal>.
 691
 692 =over 4
 693
 694 =item Arguments: $sql_fragment, @standalone_bind_values
 695
 696 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 697
 698 =back
 699
 700   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 701   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 702
 703 Pass a literal chunk of SQL to be added to the conditional part of the
 704 resultset query.
 705
 706 Example of how to use C<search> instead of C<search_literal>
 707
 708   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 709   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 710
 711 =cut
 712
 713 sub search_literal {
 714   my ($self, $sql, @bind) = @_;
 715   my $attr;
 716   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 717     $attr = pop @bind;
 718   }
 719   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 720 }
 721
 722 =head2 find
 723
 724 =over 4
 725
 726 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 727
 728 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 729
 730 =back
 731
 732 Finds and returns a single row based on supplied criteria. Takes either a
 733 hashref with the same format as L</create> (including inference of foreign
 734 keys from related objects), or a list of primary key values in the same
 735 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 736 declaration on the L</result_source>.
 737
 738 In either case an attempt is made to combine conditions already existing on
 739 the resultset with the condition passed to this method.
 740
 741 To aid with preparing the correct query for the storage you may supply the
 742 C<key> attribute, which is the name of a
 743 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 744 unique constraint corresponding to the
 745 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 746 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 747 to construct a query that satisfies the named unique constraint fully (
 748 non-NULL values for each column member of the constraint) an exception is
 749 thrown.
 750
 751 If no C<key> is specified, the search is carried over all unique constraints
 752 which are fully defined by the available condition.
 753
 754 If no such constraint is found, C<find> currently defaults to a simple
 755 C<< search->(\%column_values) >> which may or may not do what you expect.
 756 Note that this fallback behavior may be deprecated in further versions. If
 757 you need to search with arbitrary conditions - use L</search>. If the query
 758 resulting from this fallback produces more than one row, a warning to the
 759 effect is issued, though only the first row is constructed and returned as
 760 C<$result_object>.
 761
 762 In addition to C<key>, L</find> recognizes and applies standard
 763 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 764
 765 Note that if you have extra concerns about the correctness of the resulting
 766 query you need to specify the C<key> attribute and supply the entire condition
 767 as an argument to find (since it is not always possible to perform the
 768 combination of the resultset condition with the supplied one, especially if
 769 the resultset condition contains literal sql).
 770
 771 For example, to find a row by its primary key:
 772
 773   my $cd = $schema->resultset('CD')->find(5);
 774
 775 You can also find a row by a specific unique constraint:
 776
 777   my $cd = $schema->resultset('CD')->find(
 778     {
 779       artist => 'Massive Attack',
 780       title  => 'Mezzanine',
 781     },
 782     { key => 'cd_artist_title' }
 783   );
 784
 785 See also L</find_or_create> and L</update_or_create>.
 786
 787 =cut
 788
 789 sub find {
 790   my $self = shift;
 791   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 792
 793   my $rsrc = $self->result_source;
 794
 795   my $constraint_name;
 796   if (exists $attrs->{key}) {
 797     $constraint_name = defined $attrs->{key}
 798       ? $attrs->{key}
 799       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 800     ;
 801   }
 802
 803   # Parse out the condition from input
 804   my $call_cond;
 805
 806   if (ref $_[0] eq 'HASH') {
 807     $call_cond = { %{$_[0]} };
 808   }
 809   else {
 810     # if only values are supplied we need to default to 'primary'
 811     $constraint_name = 'primary' unless defined $constraint_name;
 812
 813     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 814
 815     $self->throw_exception(
 816       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 817     ) unless @c_cols;
 818
 819     $self->throw_exception (
 820       'find() expects either a column/value hashref, or a list of values '
 821     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 822     ) unless @c_cols == @_;
 823
 824     @{$call_cond}{@c_cols} = @_;
 825   }
 826
 827   # process relationship data if any
 828   for my $key (keys %$call_cond) {
 829     if (
 830       length ref($call_cond->{$key})
 831         and
 832       my $relinfo = $rsrc->relationship_info($key)
 833         and
 834       # implicitly skip has_many's (likely MC)
 835       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 836     ) {
 837       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 838         $relinfo->{cond}, $val, $key, $key
 839       );
 840
 841       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 842          if $crosstable or ref($rel_cond) ne 'HASH';
 843
 844       # supplement condition
 845       # relationship conditions take precedence (?)
 846       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 847     }
 848   }
 849
 850   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 851   my $final_cond;
 852   if (defined $constraint_name) {
 853     $final_cond = $self->_qualify_cond_columns (
 854
 855       $self->result_source->_minimal_valueset_satisfying_constraint(
 856         constraint_name => $constraint_name,
 857         values => ($self->_merge_with_rscond($call_cond))[0],
 858         carp_on_nulls => 1,
 859       ),
 860
 861       $alias,
 862     );
 863   }
 864   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 865     # This means that we got here after a merger of relationship conditions
 866     # in ::Relationship::Base::search_related (the row method), and furthermore
 867     # the relationship is of the 'single' type. This means that the condition
 868     # provided by the relationship (already attached to $self) is sufficient,
 869     # as there can be only one row in the database that would satisfy the
 870     # relationship
 871   }
 872   else {
 873     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 874
 875     # no key was specified - fall down to heuristics mode:
 876     # run through all unique queries registered on the resultset, and
 877     # 'OR' all qualifying queries together
 878     #
 879     # always start from 'primary' if it exists at all
 880     for my $c_name ( sort {
 881         $a eq 'primary' ? -1
 882       : $b eq 'primary' ? 1
 883       : $a cmp $b
 884     } $rsrc->unique_constraint_names) {
 885
 886       next if $seen_column_combinations{
 887         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 888       }++;
 889
 890       try {
 891         push @unique_queries, $self->_qualify_cond_columns(
 892           $self->result_source->_minimal_valueset_satisfying_constraint(
 893             constraint_name => $c_name,
 894             values => ($self->_merge_with_rscond($call_cond))[0],
 895             columns_info => ($ci ||= $self->result_source->columns_info),
 896           ),
 897           $alias
 898         );
 899       }
 900       catch {
 901         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 902       };
 903     }
 904
 905     $final_cond =
 906         @unique_queries   ? \@unique_queries
 907       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 908       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 909     ;
 910   }
 911
 912   # Run the query, passing the result_class since it should propagate for find
 913   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 914   if ($rs->_resolved_attrs->{collapse}) {
 915     my $row = $rs->next;
 916     carp "Query returned more than one row" if $rs->next;
 917     return $row;
 918   }
 919   else {
 920     return $rs->single;
 921   }
 922 }
 923
 924 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 925 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 926 #
 927 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 928 # condition. It is provided for overrides until a saner way forward is devised
 929 #
 930 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 931 # the road. Please adjust your tests accordingly to catch this situation early
 932 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 933 #
 934 # The method will not be removed without an adequately complete replacement
 935 # for strict-mode enforcement
 936 sub _non_unique_find_fallback {
 937   my ($self, $cond, $attrs) = @_;
 938
 939   return $self->_qualify_cond_columns(
 940     $cond,
 941     exists $attrs->{alias}
 942       ? $attrs->{alias}
 943       : $self->{attrs}{alias}
 944   );
 945 }
 946
 947
 948 sub _qualify_cond_columns {
 949   my ($self, $cond, $alias) = @_;
 950
 951   my %aliased = %$cond;
 952   for (keys %aliased) {
 953     $aliased{"$alias.$_"} = delete $aliased{$_}
 954       if $_ !~ /\./;
 955   }
 956
 957   return \%aliased;
 958 }
 959
 960 sub _build_unique_cond {
 961   carp_unique sprintf
 962     '_build_unique_cond is a private method, and moreover is about to go '
 963   . 'away. Please contact the development team at %s if you believe you '
 964   . 'have a genuine use for this method, in order to discuss alternatives.',
 965     DBIx::Class::_ENV_::HELP_URL,
 966   ;
 967
 968   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 969
 970   $self->result_source->_minimal_valueset_satisfying_constraint(
 971     constraint_name => $constraint_name,
 972     values => $cond,
 973     carp_on_nulls => !$croak_on_null
 974   );
 975 }
 976
 977 =head2 search_related
 978
 979 =over 4
 980
 981 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 982
 983 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 984
 985 =back
 986
 987   $new_rs = $cd_rs->search_related('artist', {
 988     name => 'Emo-R-Us',
 989   });
 990
 991 Searches the specified relationship, optionally specifying a condition and
 992 attributes for matching records. See L</ATTRIBUTES> for more information.
 993
 994 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 995 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 996
 997 See also L</search_related_rs>.
 998
 999 =cut
1000
1001 sub search_related {
1002   return shift->related_resultset(shift)->search(@_);
1003 }
1004
1005 =head2 search_related_rs
1006
1007 This method works exactly the same as search_related, except that
1008 it guarantees a resultset, even in list context.
1009
1010 =cut
1011
1012 sub search_related_rs {
1013   return shift->related_resultset(shift)->search_rs(@_);
1014 }
1015
1016 =head2 cursor
1017
1018 =over 4
1019
1020 =item Arguments: none
1021
1022 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1023
1024 =back
1025
1026 Returns a storage-driven cursor to the given resultset. See
1027 L<DBIx::Class::Cursor> for more information.
1028
1029 =cut
1030
1031 sub cursor {
1032   my $self = shift;
1033
1034   return $self->{cursor} ||= do {
1035     my $attrs = $self->_resolved_attrs;
1036     $self->result_source->storage->select(
1037       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1038     );
1039   };
1040 }
1041
1042 =head2 single
1043
1044 =over 4
1045
1046 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1047
1048 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1049
1050 =back
1051
1052   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1053
1054 Inflates the first result without creating a cursor if the resultset has
1055 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1056 of L</search>.
1057
1058 While this method can take an optional search condition (just like L</search>)
1059 being a fast-code-path it does not recognize search attributes. If you need to
1060 add extra joins or similar, call L</search> and then chain-call L</single> on the
1061 L<DBIx::Class::ResultSet> returned.
1062
1063 =over
1064
1065 =item B<Note>
1066
1067 As of 0.08100, this method enforces the assumption that the preceding
1068 query returns only one row. If more than one row is returned, you will receive
1069 a warning:
1070
1071   Query returned more than one row
1072
1073 In this case, you should be using L</next> or L</find> instead, or if you really
1074 know what you are doing, use the L</rows> attribute to explicitly limit the size
1075 of the resultset.
1076
1077 This method will also throw an exception if it is called on a resultset prefetching
1078 has_many, as such a prefetch implies fetching multiple rows from the database in
1079 order to assemble the resulting object.
1080
1081 =back
1082
1083 =cut
1084
1085 sub single {
1086   my ($self, $where) = @_;
1087   if(@_ > 2) {
1088       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1089   }
1090
1091   my $attrs = { %{$self->_resolved_attrs} };
1092
1093   $self->throw_exception(
1094     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1095   ) if $attrs->{collapse};
1096
1097   if ($where) {
1098     if (defined $attrs->{where}) {
1099       $attrs->{where} = {
1100         '-and' =>
1101             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1102                $where, delete $attrs->{where} ]
1103       };
1104     } else {
1105       $attrs->{where} = $where;
1106     }
1107   }
1108
1109   my $data = [ $self->result_source->storage->select_single(
1110     $attrs->{from}, $attrs->{select},
1111     $attrs->{where}, $attrs
1112   )];
1113
1114   return undef unless @$data;
1115   $self->{_stashed_rows} = [ $data ];
1116   $self->_construct_results->[0];
1117 }
1118
1119 =head2 get_column
1120
1121 =over 4
1122
1123 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1124
1125 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1126
1127 =back
1128
1129   my $max_length = $rs->get_column('length')->max;
1130
1131 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1132
1133 =cut
1134
1135 sub get_column {
1136   my ($self, $column) = @_;
1137   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1138   return $new;
1139 }
1140
1141 =head2 search_like
1142
1143 =over 4
1144
1145 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1146
1147 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1148
1149 =back
1150
1151   # WHERE title LIKE '%blue%'
1152   $cd_rs = $rs->search_like({ title => '%blue%'});
1153
1154 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1155 that this is simply a convenience method retained for ex Class::DBI users.
1156 You most likely want to use L</search> with specific operators.
1157
1158 For more information, see L<DBIx::Class::Manual::Cookbook>.
1159
1160 This method is deprecated and will be removed in 0.09. Use L</search()>
1161 instead. An example conversion is:
1162
1163   ->search_like({ foo => 'bar' });
1164
1165   # Becomes
1166
1167   ->search({ foo => { like => 'bar' } });
1168
1169 =cut
1170
1171 sub search_like {
1172   my $class = shift;
1173   carp_unique (
1174     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1175    .' Instead use ->search({ x => { -like => "y%" } })'
1176    .' (note the outer pair of {}s - they are important!)'
1177   );
1178   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1179   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1180   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1181   return $class->search($query, { %$attrs });
1182 }
1183
1184 =head2 slice
1185
1186 =over 4
1187
1188 =item Arguments: $first, $last
1189
1190 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1191
1192 =back
1193
1194 Returns a resultset or object list representing a subset of elements from the
1195 resultset slice is called on. Indexes are from 0, i.e., to get the first
1196 three records, call:
1197
1198   my ($one, $two, $three) = $rs->slice(0, 2);
1199
1200 =cut
1201
1202 sub slice {
1203   my ($self, $min, $max) = @_;
1204   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1205   $attrs->{offset} = $self->{attrs}{offset} || 0;
1206   $attrs->{offset} += $min;
1207   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1208   return $self->search(undef, $attrs);
1209 }
1210
1211 =head2 next
1212
1213 =over 4
1214
1215 =item Arguments: none
1216
1217 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1218
1219 =back
1220
1221 Returns the next element in the resultset (C<undef> is there is none).
1222
1223 Can be used to efficiently iterate over records in the resultset:
1224
1225   my $rs = $schema->resultset('CD')->search;
1226   while (my $cd = $rs->next) {
1227     print $cd->title;
1228   }
1229
1230 Note that you need to store the resultset object, and call C<next> on it.
1231 Calling C<< resultset('Table')->next >> repeatedly will always return the
1232 first record from the resultset.
1233
1234 =cut
1235
1236 sub next {
1237   my ($self) = @_;
1238
1239   if (my $cache = $self->get_cache) {
1240     $self->{all_cache_position} ||= 0;
1241     return $cache->[$self->{all_cache_position}++];
1242   }
1243
1244   if ($self->{attrs}{cache}) {
1245     delete $self->{pager};
1246     $self->{all_cache_position} = 1;
1247     return ($self->all)[0];
1248   }
1249
1250   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1251
1252   $self->{_stashed_results} = $self->_construct_results
1253     or return undef;
1254
1255   return shift @{$self->{_stashed_results}};
1256 }
1257
1258 # Constructs as many results as it can in one pass while respecting
1259 # cursor laziness. Several modes of operation:
1260 #
1261 # * Always builds everything present in @{$self->{_stashed_rows}}
1262 # * If called with $fetch_all true - pulls everything off the cursor and
1263 #   builds all result structures (or objects) in one pass
1264 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1265 #   and if the resultset is ordered properly by the left side:
1266 #   * Fetches stuff off the cursor until the "master object" changes,
1267 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1268 #   OR
1269 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1270 #     was requested (there is no other way to collapse except for an
1271 #     eager cursor)
1272 # * If no collapse is requested - just get the next row, construct and
1273 #   return
1274 sub _construct_results {
1275   my ($self, $fetch_all) = @_;
1276
1277   my $rsrc = $self->result_source;
1278   my $attrs = $self->_resolved_attrs;
1279
1280   if (
1281     ! $fetch_all
1282       and
1283     ! $attrs->{order_by}
1284       and
1285     $attrs->{collapse}
1286       and
1287     my @pcols = $rsrc->primary_columns
1288   ) {
1289     # default order for collapsing unless the user asked for something
1290     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1291     $attrs->{_ordered_for_collapse} = 1;
1292     $attrs->{_order_is_artificial} = 1;
1293   }
1294
1295   # this will be used as both initial raw-row collector AND as a RV of
1296   # _construct_results. Not regrowing the array twice matters a lot...
1297   # a surprising amount actually
1298   my $rows = delete $self->{_stashed_rows};
1299
1300   my $cursor; # we may not need one at all
1301
1302   my $did_fetch_all = $fetch_all;
1303
1304   if ($fetch_all) {
1305     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1306     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1307   }
1308   elsif( $attrs->{collapse} ) {
1309
1310     # a cursor will need to be closed over in case of collapse
1311     $cursor = $self->cursor;
1312
1313     $attrs->{_ordered_for_collapse} = (
1314       (
1315         $attrs->{order_by}
1316           and
1317         $rsrc->schema
1318               ->storage
1319                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1320       ) ? 1 : 0
1321     ) unless defined $attrs->{_ordered_for_collapse};
1322
1323     if (! $attrs->{_ordered_for_collapse}) {
1324       $did_fetch_all = 1;
1325
1326       # instead of looping over ->next, use ->all in stealth mode
1327       # *without* calling a ->reset afterwards
1328       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1329       if (! $cursor->{_done}) {
1330         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1331         $cursor->{_done} = 1;
1332       }
1333     }
1334   }
1335
1336   if (! $did_fetch_all and ! @{$rows||[]} ) {
1337     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1338     $cursor ||= $self->cursor;
1339     if (scalar (my @r = $cursor->next) ) {
1340       $rows = [ \@r ];
1341     }
1342   }
1343
1344   return undef unless @{$rows||[]};
1345
1346   # sanity check - people are too clever for their own good
1347   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1348
1349     my $multiplied_selectors;
1350     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1351       if (
1352         $aliastypes->{multiplying}{$sel_alias}
1353           or
1354         $aliastypes->{premultiplied}{$sel_alias}
1355       ) {
1356         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1357       }
1358     }
1359
1360     for my $i (0 .. $#{$attrs->{as}} ) {
1361       my $sel = $attrs->{select}[$i];
1362
1363       if (ref $sel eq 'SCALAR') {
1364         $sel = $$sel;
1365       }
1366       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1367         $sel = $$sel->[0];
1368       }
1369
1370       $self->throw_exception(
1371         'Result collapse not possible - selection from a has_many source redirected to the main object'
1372       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1373     }
1374   }
1375
1376   # hotspot - skip the setter
1377   my $res_class = $self->_result_class;
1378
1379   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1380     $res_class->can ('inflate_result')
1381       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1382   };
1383
1384   my $infmap = $attrs->{as};
1385
1386   $self->{_result_inflator}{is_core_row} = ( (
1387     $inflator_cref
1388       ==
1389     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1390   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1391
1392   $self->{_result_inflator}{is_hri} = ( (
1393     ! $self->{_result_inflator}{is_core_row}
1394       and
1395     $inflator_cref == (
1396       require DBIx::Class::ResultClass::HashRefInflator
1397         &&
1398       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1399     )
1400   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1401
1402
1403   if ($attrs->{_simple_passthrough_construction}) {
1404     # construct a much simpler array->hash folder for the one-table HRI cases right here
1405     if ($self->{_result_inflator}{is_hri}) {
1406       for my $r (@$rows) {
1407         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1408       }
1409     }
1410     # FIXME SUBOPTIMAL this is a very very very hot spot
1411     # while rather optimal we can *still* do much better, by
1412     # building a smarter Row::inflate_result(), and
1413     # switch to feeding it data via a much leaner interface
1414     #
1415     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1416     # this particular resultset size
1417     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1418       for my $r (@$rows) {
1419         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1420       }
1421     }
1422     else {
1423       eval sprintf (
1424         ( $self->{_result_inflator}{is_core_row}
1425           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1426           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1427           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1428         ),
1429         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1430       );
1431     }
1432   }
1433   else {
1434     my $parser_type =
1435         $self->{_result_inflator}{is_hri}       ? 'hri'
1436       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1437       :                                           'classic_nonpruning'
1438     ;
1439
1440     # $args and $attrs to _mk_row_parser are separated to delineate what is
1441     # core collapser stuff and what is dbic $rs specific
1442     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1443       eval => 1,
1444       inflate_map => $infmap,
1445       collapse => $attrs->{collapse},
1446       premultiplied => $attrs->{_main_source_premultiplied},
1447       hri_style => $self->{_result_inflator}{is_hri},
1448       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1449     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1450
1451     # column_info metadata historically hasn't been too reliable.
1452     # We need to start fixing this somehow (the collapse resolver
1453     # can't work without it). Add an explicit check for the *main*
1454     # result, hopefully this will gradually weed out such errors
1455     #
1456     # FIXME - this is a temporary kludge that reduces performance
1457     # It is however necessary for the time being
1458     my ($unrolled_non_null_cols_to_check, $err);
1459
1460     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1461
1462       $err =
1463         'Collapse aborted due to invalid ResultSource metadata - the following '
1464       . 'selections are declared non-nullable but NULLs were retrieved: '
1465       ;
1466
1467       my @violating_idx;
1468       COL: for my $i (@$check_non_null_cols) {
1469         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1470       }
1471
1472       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1473         if @violating_idx;
1474
1475       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1476     }
1477
1478     my $next_cref =
1479       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1480     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1481 sub {
1482   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1483   my @r = $cursor->next or return;
1484   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1485     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1486   }
1487   \@r
1488 }
1489 EOS
1490     : sub {
1491         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1492         my @r = $cursor->next or return;
1493         \@r
1494       }
1495     ;
1496
1497     $self->{_row_parser}{$parser_type}{cref}->(
1498       $rows,
1499       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1500     );
1501
1502     # simple in-place substitution, does not regrow $rows
1503     if ($self->{_result_inflator}{is_core_row}) {
1504       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1505     }
1506     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1507     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1508       # the inflator may be a multiplier/reductor - put it in list ctx
1509       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1510     }
1511   }
1512
1513   # The @$rows check seems odd at first - why wouldn't we want to warn
1514   # regardless? The issue is things like find() etc, where the user
1515   # *knows* only one result will come back. In these cases the ->all
1516   # is not a pessimization, but rather something we actually want
1517   carp_unique(
1518     'Unable to properly collapse has_many results in iterator mode due '
1519   . 'to order criteria - performed an eager cursor slurp underneath. '
1520   . 'Consider using ->all() instead'
1521   ) if ( ! $fetch_all and @$rows > 1 );
1522
1523   return $rows;
1524 }
1525
1526 =head2 result_source
1527
1528 =over 4
1529
1530 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1531
1532 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1533
1534 =back
1535
1536 An accessor for the primary ResultSource object from which this ResultSet
1537 is derived.
1538
1539 =head2 result_class
1540
1541 =over 4
1542
1543 =item Arguments: $result_class?
1544
1545 =item Return Value: $result_class
1546
1547 =back
1548
1549 An accessor for the class to use when creating result objects. Defaults to
1550 C<< result_source->result_class >> - which in most cases is the name of the
1551 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1552
1553 Note that changing the result_class will also remove any components
1554 that were originally loaded in the source class via
1555 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1556 in the original source class will not run.
1557
1558 =cut
1559
1560 sub result_class {
1561   my ($self, $result_class) = @_;
1562   if ($result_class) {
1563
1564     # don't fire this for an object
1565     $self->ensure_class_loaded($result_class)
1566       unless ref($result_class);
1567
1568     if ($self->get_cache) {
1569       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1570     }
1571     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1572     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1573       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1574     }
1575
1576     $self->_result_class($result_class);
1577
1578     delete $self->{_result_inflator};
1579   }
1580   $self->_result_class;
1581 }
1582
1583 =head2 count
1584
1585 =over 4
1586
1587 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1588
1589 =item Return Value: $count
1590
1591 =back
1592
1593 Performs an SQL C<COUNT> with the same query as the resultset was built
1594 with to find the number of elements. Passing arguments is equivalent to
1595 C<< $rs->search ($cond, \%attrs)->count >>
1596
1597 =cut
1598
1599 sub count {
1600   my $self = shift;
1601   return $self->search(@_)->count if @_ and defined $_[0];
1602   return scalar @{ $self->get_cache } if $self->get_cache;
1603
1604   my $attrs = { %{ $self->_resolved_attrs } };
1605
1606   # this is a little optimization - it is faster to do the limit
1607   # adjustments in software, instead of a subquery
1608   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1609
1610   my $crs;
1611   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1612     $crs = $self->_count_subq_rs ($attrs);
1613   }
1614   else {
1615     $crs = $self->_count_rs ($attrs);
1616   }
1617   my $count = $crs->next;
1618
1619   $count -= $offset if $offset;
1620   $count = $rows if $rows and $rows < $count;
1621   $count = 0 if ($count < 0);
1622
1623   return $count;
1624 }
1625
1626 =head2 count_rs
1627
1628 =over 4
1629
1630 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1631
1632 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1633
1634 =back
1635
1636 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1637 This can be very handy for subqueries:
1638
1639   ->search( { amount => $some_rs->count_rs->as_query } )
1640
1641 As with regular resultsets the SQL query will be executed only after
1642 the resultset is accessed via L</next> or L</all>. That would return
1643 the same single value obtainable via L</count>.
1644
1645 =cut
1646
1647 sub count_rs {
1648   my $self = shift;
1649   return $self->search(@_)->count_rs if @_;
1650
1651   # this may look like a lack of abstraction (count() does about the same)
1652   # but in fact an _rs *must* use a subquery for the limits, as the
1653   # software based limiting can not be ported if this $rs is to be used
1654   # in a subquery itself (i.e. ->as_query)
1655   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1656     return $self->_count_subq_rs($self->{_attrs});
1657   }
1658   else {
1659     return $self->_count_rs($self->{_attrs});
1660   }
1661 }
1662
1663 #
1664 # returns a ResultSetColumn object tied to the count query
1665 #
1666 sub _count_rs {
1667   my ($self, $attrs) = @_;
1668
1669   my $rsrc = $self->result_source;
1670
1671   my $tmp_attrs = { %$attrs };
1672   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1673   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1674
1675   # overwrite the selector (supplied by the storage)
1676   $rsrc->resultset_class->new($rsrc, {
1677     %$tmp_attrs,
1678     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1679     as => 'count',
1680   })->get_column ('count');
1681 }
1682
1683 #
1684 # same as above but uses a subquery
1685 #
1686 sub _count_subq_rs {
1687   my ($self, $attrs) = @_;
1688
1689   my $rsrc = $self->result_source;
1690
1691   my $sub_attrs = { %$attrs };
1692   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1693   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1694
1695   # if we multi-prefetch we group_by something unique, as this is what we would
1696   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1697   if ( $attrs->{collapse}  ) {
1698     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1699       $rsrc->_identifying_column_set || $self->throw_exception(
1700         'Unable to construct a unique group_by criteria properly collapsing the '
1701       . 'has_many prefetch before count()'
1702       );
1703     } ]
1704   }
1705
1706   # Calculate subquery selector
1707   if (my $g = $sub_attrs->{group_by}) {
1708
1709     my $sql_maker = $rsrc->storage->sql_maker;
1710
1711     # necessary as the group_by may refer to aliased functions
1712     my $sel_index;
1713     for my $sel (@{$attrs->{select}}) {
1714       $sel_index->{$sel->{-as}} = $sel
1715         if (ref $sel eq 'HASH' and $sel->{-as});
1716     }
1717
1718     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1719     # also look for named aggregates referred in the having clause
1720     # having often contains scalarrefs - thus parse it out entirely
1721     my @parts = @$g;
1722     if ($attrs->{having}) {
1723       local $sql_maker->{having_bind};
1724       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1725       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1726       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1727         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1728         # if we don't unset it we screw up retarded but unfortunately working
1729         # 'MAX(foo.bar)' => { '>', 3 }
1730         $sql_maker->{name_sep} = '';
1731       }
1732
1733       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1734
1735       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1736       my %seen_having;
1737
1738       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1739       # and if all fails for an utterly naive quoted scalar-with-function
1740       while ($having_sql =~ /
1741         $rquote $sep $lquote (.+?) $rquote
1742           |
1743         [\s,] \w+ \. (\w+) [\s,]
1744           |
1745         [\s,] $lquote (.+?) $rquote [\s,]
1746       /gx) {
1747         my $part = $1 || $2 || $3;  # one of them matched if we got here
1748         unless ($seen_having{$part}++) {
1749           push @parts, $part;
1750         }
1751       }
1752     }
1753
1754     for (@parts) {
1755       my $colpiece = $sel_index->{$_} || $_;
1756
1757       # unqualify join-based group_by's. Arcane but possible query
1758       # also horrible horrible hack to alias a column (not a func.)
1759       # (probably need to introduce SQLA syntax)
1760       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1761         my $as = $colpiece;
1762         $as =~ s/\./__/;
1763         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1764       }
1765       push @{$sub_attrs->{select}}, $colpiece;
1766     }
1767   }
1768   else {
1769     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1770     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1771   }
1772
1773   return $rsrc->resultset_class
1774                ->new ($rsrc, $sub_attrs)
1775                 ->as_subselect_rs
1776                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1777                   ->get_column ('count');
1778 }
1779
1780
1781 =head2 count_literal
1782
1783 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1784 should only be used in that context. See L</search_literal> for further info.
1785
1786 =over 4
1787
1788 =item Arguments: $sql_fragment, @standalone_bind_values
1789
1790 =item Return Value: $count
1791
1792 =back
1793
1794 Counts the results in a literal query. Equivalent to calling L</search_literal>
1795 with the passed arguments, then L</count>.
1796
1797 =cut
1798
1799 sub count_literal { shift->search_literal(@_)->count; }
1800
1801 =head2 all
1802
1803 =over 4
1804
1805 =item Arguments: none
1806
1807 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1808
1809 =back
1810
1811 Returns all elements in the resultset.
1812
1813 =cut
1814
1815 sub all {
1816   my $self = shift;
1817   if(@_) {
1818     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1819   }
1820
1821   delete @{$self}{qw/_stashed_rows _stashed_results/};
1822
1823   if (my $c = $self->get_cache) {
1824     return @$c;
1825   }
1826
1827   $self->cursor->reset;
1828
1829   my $objs = $self->_construct_results('fetch_all') || [];
1830
1831   $self->set_cache($objs) if $self->{attrs}{cache};
1832
1833   return @$objs;
1834 }
1835
1836 =head2 reset
1837
1838 =over 4
1839
1840 =item Arguments: none
1841
1842 =item Return Value: $self
1843
1844 =back
1845
1846 Resets the resultset's cursor, so you can iterate through the elements again.
1847 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1848 another query.
1849
1850 =cut
1851
1852 sub reset {
1853   my ($self) = @_;
1854
1855   delete @{$self}{qw/_stashed_rows _stashed_results/};
1856   $self->{all_cache_position} = 0;
1857   $self->cursor->reset;
1858   return $self;
1859 }
1860
1861 =head2 first
1862
1863 =over 4
1864
1865 =item Arguments: none
1866
1867 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1868
1869 =back
1870
1871 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1872 an object for the first result (or C<undef> if the resultset is empty).
1873
1874 =cut
1875
1876 sub first {
1877   return $_[0]->reset->next;
1878 }
1879
1880
1881 # _rs_update_delete
1882 #
1883 # Determines whether and what type of subquery is required for the $rs operation.
1884 # If grouping is necessary either supplies its own, or verifies the current one
1885 # After all is done delegates to the proper storage method.
1886
1887 sub _rs_update_delete {
1888   my ($self, $op, $values) = @_;
1889
1890   my $rsrc = $self->result_source;
1891   my $storage = $rsrc->schema->storage;
1892
1893   my $attrs = { %{$self->_resolved_attrs} };
1894
1895   my $join_classifications;
1896   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1897
1898   # do we need a subquery for any reason?
1899   my $needs_subq = (
1900     defined $existing_group_by
1901       or
1902     # if {from} is unparseable wrap a subq
1903     ref($attrs->{from}) ne 'ARRAY'
1904       or
1905     # limits call for a subq
1906     $self->_has_resolved_attr(qw/rows offset/)
1907   );
1908
1909   # simplify the joinmap, so we can further decide if a subq is necessary
1910   if (!$needs_subq and @{$attrs->{from}} > 1) {
1911
1912     ($attrs->{from}, $join_classifications) =
1913       $storage->_prune_unused_joins ($attrs);
1914
1915     # any non-pruneable non-local restricting joins imply subq
1916     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1917   }
1918
1919   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1920   $needs_subq ||= (
1921     (ref $attrs->{from}[0]) ne 'HASH'
1922       or
1923     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1924   );
1925
1926   my ($cond, $guard);
1927   # do we need anything like a subquery?
1928   if (! $needs_subq) {
1929     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1930     # a condition containing 'me' or other table prefixes will not work
1931     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1932     $cond = do {
1933       my $sqla = $rsrc->storage->sql_maker;
1934       local $sqla->{_dequalify_idents} = 1;
1935       \[ $sqla->_recurse_where($self->{cond}) ];
1936     };
1937   }
1938   else {
1939     # we got this far - means it is time to wrap a subquery
1940     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1941       sprintf(
1942         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1943         $op,
1944         $rsrc->source_name,
1945       )
1946     );
1947
1948     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1949     delete $attrs->{$_} for qw/select as collapse/;
1950     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1951
1952     # this will be consumed by the pruner waaaaay down the stack
1953     $attrs->{_force_prune_multiplying_joins} = 1;
1954
1955     my $subrs = (ref $self)->new($rsrc, $attrs);
1956
1957     if (@$idcols == 1) {
1958       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1959     }
1960     elsif ($storage->_use_multicolumn_in) {
1961       # no syntax for calling this properly yet
1962       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1963       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1964         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1965         $subrs->as_query
1966       ),
1967     }
1968     else {
1969       # if all else fails - get all primary keys and operate over a ORed set
1970       # wrap in a transaction for consistency
1971       # this is where the group_by/multiplication starts to matter
1972       if (
1973         $existing_group_by
1974           or
1975         # we do not need to check pre-multipliers, since if the premulti is there, its
1976         # parent (who is multi) will be there too
1977         keys %{ $join_classifications->{multiplying} || {} }
1978       ) {
1979         # make sure if there is a supplied group_by it matches the columns compiled above
1980         # perfectly. Anything else can not be sanely executed on most databases so croak
1981         # right then and there
1982         if ($existing_group_by) {
1983           my @current_group_by = map
1984             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1985             @$existing_group_by
1986           ;
1987
1988           if (
1989             join ("\x00", sort @current_group_by)
1990               ne
1991             join ("\x00", sort @{$attrs->{columns}} )
1992           ) {
1993             $self->throw_exception (
1994               "You have just attempted a $op operation on a resultset which does group_by"
1995               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1996               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1997               . ' kind of queries. Please retry the operation with a modified group_by or'
1998               . ' without using one at all.'
1999             );
2000           }
2001         }
2002
2003         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2004       }
2005
2006       $guard = $storage->txn_scope_guard;
2007
2008       for my $row ($subrs->cursor->all) {
2009         push @$cond, { map
2010           { $idcols->[$_] => $row->[$_] }
2011           (0 .. $#$idcols)
2012         };
2013       }
2014     }
2015   }
2016
2017   my $res = $cond ? $storage->$op (
2018     $rsrc,
2019     $op eq 'update' ? $values : (),
2020     $cond,
2021   ) : '0E0';
2022
2023   $guard->commit if $guard;
2024
2025   return $res;
2026 }
2027
2028 =head2 update
2029
2030 =over 4
2031
2032 =item Arguments: \%values
2033
2034 =item Return Value: $underlying_storage_rv
2035
2036 =back
2037
2038 Sets the specified columns in the resultset to the supplied values in a
2039 single query. Note that this will not run any accessor/set_column/update
2040 triggers, nor will it update any result object instances derived from this
2041 resultset (this includes the contents of the L<resultset cache|/set_cache>
2042 if any). See L</update_all> if you need to execute any on-update
2043 triggers or cascades defined either by you or a
2044 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2045
2046 The return value is a pass through of what the underlying
2047 storage backend returned, and may vary. See L<DBI/execute> for the most
2048 common case.
2049
2050 =head3 CAVEAT
2051
2052 Note that L</update> does not process/deflate any of the values passed in.
2053 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2054 ensure manually that any value passed to this method will stringify to
2055 something the RDBMS knows how to deal with. A notable example is the
2056 handling of L<DateTime> objects, for more info see:
2057 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2058
2059 =cut
2060
2061 sub update {
2062   my ($self, $values) = @_;
2063   $self->throw_exception('Values for update must be a hash')
2064     unless ref $values eq 'HASH';
2065
2066   return $self->_rs_update_delete ('update', $values);
2067 }
2068
2069 =head2 update_all
2070
2071 =over 4
2072
2073 =item Arguments: \%values
2074
2075 =item Return Value: 1
2076
2077 =back
2078
2079 Fetches all objects and updates them one at a time via
2080 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2081 triggers, while L</update> will not.
2082
2083 =cut
2084
2085 sub update_all {
2086   my ($self, $values) = @_;
2087   $self->throw_exception('Values for update_all must be a hash')
2088     unless ref $values eq 'HASH';
2089
2090   my $guard = $self->result_source->schema->txn_scope_guard;
2091   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2092   $guard->commit;
2093   return 1;
2094 }
2095
2096 =head2 delete
2097
2098 =over 4
2099
2100 =item Arguments: none
2101
2102 =item Return Value: $underlying_storage_rv
2103
2104 =back
2105
2106 Deletes the rows matching this resultset in a single query. Note that this
2107 will not run any delete triggers, nor will it alter the
2108 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2109 derived from this resultset (this includes the contents of the
2110 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2111 execute any on-delete triggers or cascades defined either by you or a
2112 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2113
2114 The return value is a pass through of what the underlying storage backend
2115 returned, and may vary. See L<DBI/execute> for the most common case.
2116
2117 =cut
2118
2119 sub delete {
2120   my $self = shift;
2121   $self->throw_exception('delete does not accept any arguments')
2122     if @_;
2123
2124   return $self->_rs_update_delete ('delete');
2125 }
2126
2127 =head2 delete_all
2128
2129 =over 4
2130
2131 =item Arguments: none
2132
2133 =item Return Value: 1
2134
2135 =back
2136
2137 Fetches all objects and deletes them one at a time via
2138 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2139 triggers, while L</delete> will not.
2140
2141 =cut
2142
2143 sub delete_all {
2144   my $self = shift;
2145   $self->throw_exception('delete_all does not accept any arguments')
2146     if @_;
2147
2148   my $guard = $self->result_source->schema->txn_scope_guard;
2149   $_->delete for $self->all;
2150   $guard->commit;
2151   return 1;
2152 }
2153
2154 =head2 populate
2155
2156 =over 4
2157
2158 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2159
2160 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2161
2162 =back
2163
2164 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2165 arrayrefs.
2166
2167 =over
2168
2169 =item NOTE
2170
2171 The context of this method call has an important effect on what is
2172 submitted to storage. In void context data is fed directly to fastpath
2173 insertion routines provided by the underlying storage (most often
2174 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2175 L<insert|DBIx::Class::Row/insert> calls on the
2176 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2177 augmentation of these methods provided by components. For example if you
2178 are using something like L<DBIx::Class::UUIDColumns> to create primary
2179 keys for you, you will find that your PKs are empty.  In this case you
2180 will have to explicitly force scalar or list context in order to create
2181 those values.
2182
2183 =back
2184
2185 In non-void (scalar or list) context, this method is simply a wrapper
2186 for L</create>. Depending on list or scalar context either a list of
2187 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2188 containing these objects is returned.
2189
2190 When supplying data in "arrayref of arrayrefs" invocation style, the
2191 first element should be a list of column names and each subsequent
2192 element should be a data value in the earlier specified column order.
2193 For example:
2194
2195   $schema->resultset("Artist")->populate([
2196     [ qw( artistid name ) ],
2197     [ 100, 'A Formally Unknown Singer' ],
2198     [ 101, 'A singer that jumped the shark two albums ago' ],
2199     [ 102, 'An actually cool singer' ],
2200   ]);
2201
2202 For the arrayref of hashrefs style each hashref should be a structure
2203 suitable for passing to L</create>. Multi-create is also permitted with
2204 this syntax.
2205
2206   $schema->resultset("Artist")->populate([
2207      { artistid => 4, name => 'Manufactured Crap', cds => [
2208         { title => 'My First CD', year => 2006 },
2209         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2210       ],
2211      },
2212      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2213         { title => 'My parents sold me to a record company', year => 2005 },
2214         { title => 'Why Am I So Ugly?', year => 2006 },
2215         { title => 'I Got Surgery and am now Popular', year => 2007 }
2216       ],
2217      },
2218   ]);
2219
2220 If you attempt a void-context multi-create as in the example above (each
2221 Artist also has the related list of CDs), and B<do not> supply the
2222 necessary autoinc foreign key information, this method will proxy to the
2223 less efficient L</create>, and then throw the Result objects away. In this
2224 case there are obviously no benefits to using this method over L</create>.
2225
2226 =cut
2227
2228 sub populate {
2229   my $self = shift;
2230
2231   # this is naive and just a quick check
2232   # the types will need to be checked more thoroughly when the
2233   # multi-source populate gets added
2234   my $data = (
2235     ref $_[0] eq 'ARRAY'
2236       and
2237     ( @{$_[0]} or return )
2238       and
2239     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2240       and
2241     $_[0]
2242   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2243
2244   # FIXME - no cref handling
2245   # At this point assume either hashes or arrays
2246
2247   if(defined wantarray) {
2248     my (@results, $guard);
2249
2250     if (ref $data->[0] eq 'ARRAY') {
2251       # column names only, nothing to do
2252       return if @$data == 1;
2253
2254       $guard = $self->result_source->schema->storage->txn_scope_guard
2255         if @$data > 2;
2256
2257       @results = map
2258         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2259         @{$data}[1 .. $#$data]
2260       ;
2261     }
2262     else {
2263
2264       $guard = $self->result_source->schema->storage->txn_scope_guard
2265         if @$data > 1;
2266
2267       @results = map { $self->new_result($_)->insert } @$data;
2268     }
2269
2270     $guard->commit if $guard;
2271     return wantarray ? @results : \@results;
2272   }
2273
2274   # we have to deal with *possibly incomplete* related data
2275   # this means we have to walk the data structure twice
2276   # whether we want this or not
2277   # jnap, I hate you ;)
2278   my $rsrc = $self->result_source;
2279   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2280
2281   my ($colinfo, $colnames, $slices_with_rels);
2282   my $data_start = 0;
2283
2284   DATA_SLICE:
2285   for my $i (0 .. $#$data) {
2286
2287     my $current_slice_seen_rel_infos;
2288
2289 ### Determine/Supplement collists
2290 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2291     if( ref $data->[$i] eq 'ARRAY' ) {
2292
2293       # positional(!) explicit column list
2294       if ($i == 0) {
2295         # column names only, nothing to do
2296         return if @$data == 1;
2297
2298         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2299           for 0 .. $#{$data->[0]};
2300
2301         $data_start = 1;
2302
2303         next DATA_SLICE;
2304       }
2305       else {
2306         for (values %$colinfo) {
2307           if ($_->{is_rel} ||= (
2308             $rel_info->{$_->{name}}
2309               and
2310             (
2311               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2312                 or
2313               ref $data->[$i][$_->{pos}] eq 'HASH'
2314                 or
2315               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2316             )
2317               and
2318             1
2319           )) {
2320
2321             # moar sanity check... sigh
2322             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2323               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2324                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2325                 return my $throwaway = $self->populate(@_);
2326               }
2327             }
2328
2329             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2330           }
2331         }
2332       }
2333
2334      if ($current_slice_seen_rel_infos) {
2335         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2336
2337         # this is needed further down to decide whether or not to fallback to create()
2338         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2339           for 0 .. $#$colnames;
2340       }
2341     }
2342     elsif( ref $data->[$i] eq 'HASH' ) {
2343
2344       for ( sort keys %{$data->[$i]} ) {
2345
2346         $colinfo->{$_} ||= do {
2347
2348           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2349             if $data_start; # it will be 0 on AoH, 1 on AoA
2350
2351           push @$colnames, $_;
2352
2353           # RV
2354           { pos => $#$colnames, name => $_ }
2355         };
2356
2357         if ($colinfo->{$_}{is_rel} ||= (
2358           $rel_info->{$_}
2359             and
2360           (
2361             ref $data->[$i]{$_} eq 'ARRAY'
2362               or
2363             ref $data->[$i]{$_} eq 'HASH'
2364               or
2365             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2366           )
2367             and
2368           1
2369         )) {
2370
2371           # moar sanity check... sigh
2372           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2373             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2374               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2375               return my $throwaway = $self->populate(@_);
2376             }
2377           }
2378
2379           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2380         }
2381       }
2382
2383       if ($current_slice_seen_rel_infos) {
2384         push @$slices_with_rels, $data->[$i];
2385
2386         # this is needed further down to decide whether or not to fallback to create()
2387         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2388           for keys %{$data->[$i]};
2389       }
2390     }
2391     else {
2392       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2393     }
2394
2395     if ( grep
2396       { $_->{attrs}{is_depends_on} }
2397       @{ $current_slice_seen_rel_infos || [] }
2398     ) {
2399       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2400       return my $throwaway = $self->populate(@_);
2401     }
2402   }
2403
2404   if( $slices_with_rels ) {
2405
2406     # need to exclude the rel "columns"
2407     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2408
2409     # extra sanity check - ensure the main source is in fact identifiable
2410     # the localizing of nullability is insane, but oh well... the use-case is legit
2411     my $ci = $rsrc->columns_info($colnames);
2412
2413     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2414       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2415
2416     unless( $rsrc->_identifying_column_set($ci) ) {
2417       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2418       return my $throwaway = $self->populate(@_);
2419     }
2420   }
2421
2422 ### inherit the data locked in the conditions of the resultset
2423   my ($rs_data) = $self->_merge_with_rscond({});
2424   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2425
2426   # if anything left - decompose rs_data
2427   my $rs_data_vals;
2428   if (keys %$rs_data) {
2429      push @$rs_data_vals, $rs_data->{$_}
2430       for sort keys %$rs_data;
2431   }
2432
2433 ### start work
2434   my $guard;
2435   $guard = $rsrc->schema->storage->txn_scope_guard
2436     if $slices_with_rels;
2437
2438 ### main source data
2439   # FIXME - need to switch entirely to a coderef-based thing,
2440   # so that large sets aren't copied several times... I think
2441   $rsrc->storage->_insert_bulk(
2442     $rsrc,
2443     [ @$colnames, sort keys %$rs_data ],
2444     [ map {
2445       ref $data->[$_] eq 'ARRAY'
2446       ? (
2447           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2448         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2449         :                     $data->[$_]
2450       )
2451       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2452     } $data_start .. $#$data ],
2453   );
2454
2455 ### do the children relationships
2456   if ( $slices_with_rels ) {
2457     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2458       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2459
2460     for my $sl (@$slices_with_rels) {
2461
2462       my ($main_proto, $main_proto_rs);
2463       for my $rel (@rels) {
2464         next unless defined $sl->{$rel};
2465
2466         $main_proto ||= {
2467           %$rs_data,
2468           (map { $_ => $sl->{$_} } @$colnames),
2469         };
2470
2471         unless (defined $colinfo->{$rel}{rs}) {
2472
2473           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2474
2475           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2476             rel_name => $rel,
2477             self_alias => "\xFE", # irrelevant
2478             foreign_alias => "\xFF", # irrelevant
2479           )->{identity_map} || {} } };
2480
2481         }
2482
2483         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2484           {
2485             $_ => { '=' =>
2486               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2487                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2488                  ->as_query
2489             }
2490           }
2491           keys %{$colinfo->{$rel}{fk_map}}
2492         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2493
2494         1;
2495       }
2496     }
2497   }
2498
2499   $guard->commit if $guard;
2500 }
2501
2502 =head2 pager
2503
2504 =over 4
2505
2506 =item Arguments: none
2507
2508 =item Return Value: L<$pager|Data::Page>
2509
2510 =back
2511
2512 Returns a L<Data::Page> object for the current resultset. Only makes
2513 sense for queries with a C<page> attribute.
2514
2515 To get the full count of entries for a paged resultset, call
2516 C<total_entries> on the L<Data::Page> object.
2517
2518 =cut
2519
2520 sub pager {
2521   my ($self) = @_;
2522
2523   return $self->{pager} if $self->{pager};
2524
2525   my $attrs = $self->{attrs};
2526   if (!defined $attrs->{page}) {
2527     $self->throw_exception("Can't create pager for non-paged rs");
2528   }
2529   elsif ($attrs->{page} <= 0) {
2530     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2531   }
2532   $attrs->{rows} ||= 10;
2533
2534   # throw away the paging flags and re-run the count (possibly
2535   # with a subselect) to get the real total count
2536   my $count_attrs = { %$attrs };
2537   delete @{$count_attrs}{qw/rows offset page pager/};
2538
2539   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2540
2541   require DBIx::Class::ResultSet::Pager;
2542   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2543     sub { $total_rs->count },  #lazy-get the total
2544     $attrs->{rows},
2545     $self->{attrs}{page},
2546   );
2547 }
2548
2549 =head2 page
2550
2551 =over 4
2552
2553 =item Arguments: $page_number
2554
2555 =item Return Value: L<$resultset|/search>
2556
2557 =back
2558
2559 Returns a resultset for the $page_number page of the resultset on which page
2560 is called, where each page contains a number of rows equal to the 'rows'
2561 attribute set on the resultset (10 by default).
2562
2563 =cut
2564
2565 sub page {
2566   my ($self, $page) = @_;
2567   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2568 }
2569
2570 =head2 new_result
2571
2572 =over 4
2573
2574 =item Arguments: \%col_data
2575
2576 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2577
2578 =back
2579
2580 Creates a new result object in the resultset's result class and returns
2581 it. The row is not inserted into the database at this point, call
2582 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2583 will tell you whether the result object has been inserted or not.
2584
2585 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2586
2587 =cut
2588
2589 sub new_result {
2590   my ($self, $values) = @_;
2591
2592   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2593     if @_ > 2;
2594
2595   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2596     unless (ref $values eq 'HASH');
2597
2598   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2599
2600   my $new = $self->result_class->new({
2601     %$merged_cond,
2602     ( @$cols_from_relations
2603       ? (-cols_from_relations => $cols_from_relations)
2604       : ()
2605     ),
2606     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2607   });
2608
2609   if (
2610     reftype($new) eq 'HASH'
2611       and
2612     ! keys %$new
2613       and
2614     blessed($new)
2615   ) {
2616     carp_unique (sprintf (
2617       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2618       $self->result_class,
2619     ));
2620   }
2621
2622   $new;
2623 }
2624
2625 # _merge_with_rscond
2626 #
2627 # Takes a simple hash of K/V data and returns its copy merged with the
2628 # condition already present on the resultset. Additionally returns an
2629 # arrayref of value/condition names, which were inferred from related
2630 # objects (this is needed for in-memory related objects)
2631 sub _merge_with_rscond {
2632   my ($self, $data) = @_;
2633
2634   my ($implied_data, @cols_from_relations);
2635
2636   my $alias = $self->{attrs}{alias};
2637
2638   if (! defined $self->{cond}) {
2639     # just massage $data below
2640   }
2641   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2642     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2643     @cols_from_relations = keys %{ $implied_data || {} };
2644   }
2645   else {
2646     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2647     $implied_data = { map {
2648       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2649     } keys %$eqs };
2650   }
2651
2652   return (
2653     { map
2654       { %{ $self->_remove_alias($_, $alias) } }
2655       # precedence must be given to passed values over values inherited from
2656       # the cond, so the order here is important.
2657       ( $implied_data||(), $data)
2658     },
2659     \@cols_from_relations
2660   );
2661 }
2662
2663 # _has_resolved_attr
2664 #
2665 # determines if the resultset defines at least one
2666 # of the attributes supplied
2667 #
2668 # used to determine if a subquery is necessary
2669 #
2670 # supports some virtual attributes:
2671 #   -join
2672 #     This will scan for any joins being present on the resultset.
2673 #     It is not a mere key-search but a deep inspection of {from}
2674 #
2675
2676 sub _has_resolved_attr {
2677   my ($self, @attr_names) = @_;
2678
2679   my $attrs = $self->_resolved_attrs;
2680
2681   my %extra_checks;
2682
2683   for my $n (@attr_names) {
2684     if (grep { $n eq $_ } (qw/-join/) ) {
2685       $extra_checks{$n}++;
2686       next;
2687     }
2688
2689     my $attr =  $attrs->{$n};
2690
2691     next if not defined $attr;
2692
2693     if (ref $attr eq 'HASH') {
2694       return 1 if keys %$attr;
2695     }
2696     elsif (ref $attr eq 'ARRAY') {
2697       return 1 if @$attr;
2698     }
2699     else {
2700       return 1 if $attr;
2701     }
2702   }
2703
2704   # a resolved join is expressed as a multi-level from
2705   return 1 if (
2706     $extra_checks{-join}
2707       and
2708     ref $attrs->{from} eq 'ARRAY'
2709       and
2710     @{$attrs->{from}} > 1
2711   );
2712
2713   return 0;
2714 }
2715
2716 # _remove_alias
2717 #
2718 # Remove the specified alias from the specified query hash. A copy is made so
2719 # the original query is not modified.
2720
2721 sub _remove_alias {
2722   my ($self, $query, $alias) = @_;
2723
2724   my %orig = %{ $query || {} };
2725   my %unaliased;
2726
2727   foreach my $key (keys %orig) {
2728     if ($key !~ /\./) {
2729       $unaliased{$key} = $orig{$key};
2730       next;
2731     }
2732     $unaliased{$1} = $orig{$key}
2733       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2734   }
2735
2736   return \%unaliased;
2737 }
2738
2739 =head2 as_query
2740
2741 =over 4
2742
2743 =item Arguments: none
2744
2745 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2746
2747 =back
2748
2749 Returns the SQL query and bind vars associated with the invocant.
2750
2751 This is generally used as the RHS for a subquery.
2752
2753 =cut
2754
2755 sub as_query {
2756   my $self = shift;
2757
2758   my $attrs = { %{ $self->_resolved_attrs } };
2759
2760   my $aq = $self->result_source->storage->_select_args_to_query (
2761     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2762   );
2763
2764   $aq;
2765 }
2766
2767 =head2 find_or_new
2768
2769 =over 4
2770
2771 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2772
2773 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2774
2775 =back
2776
2777   my $artist = $schema->resultset('Artist')->find_or_new(
2778     { artist => 'fred' }, { key => 'artists' });
2779
2780   $cd->cd_to_producer->find_or_new({ producer => $producer },
2781                                    { key => 'primary' });
2782
2783 Find an existing record from this resultset using L</find>. if none exists,
2784 instantiate a new result object and return it. The object will not be saved
2785 into your storage until you call L<DBIx::Class::Row/insert> on it.
2786
2787 You most likely want this method when looking for existing rows using a unique
2788 constraint that is not the primary key, or looking for related rows.
2789
2790 If you want objects to be saved immediately, use L</find_or_create> instead.
2791
2792 B<Note>: Make sure to read the documentation of L</find> and understand the
2793 significance of the C<key> attribute, as its lack may skew your search, and
2794 subsequently result in spurious new objects.
2795
2796 B<Note>: Take care when using C<find_or_new> with a table having
2797 columns with default values that you intend to be automatically
2798 supplied by the database (e.g. an auto_increment primary key column).
2799 In normal usage, the value of such columns should NOT be included at
2800 all in the call to C<find_or_new>, even when set to C<undef>.
2801
2802 =cut
2803
2804 sub find_or_new {
2805   my $self     = shift;
2806   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2807   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2808   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2809     return $row;
2810   }
2811   return $self->new_result($hash);
2812 }
2813
2814 =head2 create
2815
2816 =over 4
2817
2818 =item Arguments: \%col_data
2819
2820 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2821
2822 =back
2823
2824 Attempt to create a single new row or a row with multiple related rows
2825 in the table represented by the resultset (and related tables). This
2826 will not check for duplicate rows before inserting, use
2827 L</find_or_create> to do that.
2828
2829 To create one row for this resultset, pass a hashref of key/value
2830 pairs representing the columns of the table and the values you wish to
2831 store. If the appropriate relationships are set up, foreign key fields
2832 can also be passed an object representing the foreign row, and the
2833 value will be set to its primary key.
2834
2835 To create related objects, pass a hashref of related-object column values
2836 B<keyed on the relationship name>. If the relationship is of type C<multi>
2837 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2838 The process will correctly identify columns holding foreign keys, and will
2839 transparently populate them from the keys of the corresponding relation.
2840 This can be applied recursively, and will work correctly for a structure
2841 with an arbitrary depth and width, as long as the relationships actually
2842 exists and the correct column data has been supplied.
2843
2844 Instead of hashrefs of plain related data (key/value pairs), you may
2845 also pass new or inserted objects. New objects (not inserted yet, see
2846 L</new_result>), will be inserted into their appropriate tables.
2847
2848 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2849
2850 Example of creating a new row.
2851
2852   $person_rs->create({
2853     name=>"Some Person",
2854     email=>"somebody@someplace.com"
2855   });
2856
2857 Example of creating a new row and also creating rows in a related C<has_many>
2858 or C<has_one> resultset.  Note Arrayref.
2859
2860   $artist_rs->create(
2861      { artistid => 4, name => 'Manufactured Crap', cds => [
2862         { title => 'My First CD', year => 2006 },
2863         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2864       ],
2865      },
2866   );
2867
2868 Example of creating a new row and also creating a row in a related
2869 C<belongs_to> resultset. Note Hashref.
2870
2871   $cd_rs->create({
2872     title=>"Music for Silly Walks",
2873     year=>2000,
2874     artist => {
2875       name=>"Silly Musician",
2876     }
2877   });
2878
2879 =over
2880
2881 =item WARNING
2882
2883 When subclassing ResultSet never attempt to override this method. Since
2884 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2885 lot of the internals simply never call it, so your override will be
2886 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2887 or L<DBIx::Class::Row/insert> depending on how early in the
2888 L</create> process you need to intervene. See also warning pertaining to
2889 L</new>.
2890
2891 =back
2892
2893 =cut
2894
2895 sub create {
2896   #my ($self, $col_data) = @_;
2897   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2898   return shift->new_result(shift)->insert;
2899 }
2900
2901 =head2 find_or_create
2902
2903 =over 4
2904
2905 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2906
2907 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2908
2909 =back
2910
2911   $cd->cd_to_producer->find_or_create({ producer => $producer },
2912                                       { key => 'primary' });
2913
2914 Tries to find a record based on its primary key or unique constraints; if none
2915 is found, creates one and returns that instead.
2916
2917   my $cd = $schema->resultset('CD')->find_or_create({
2918     cdid   => 5,
2919     artist => 'Massive Attack',
2920     title  => 'Mezzanine',
2921     year   => 2005,
2922   });
2923
2924 Also takes an optional C<key> attribute, to search by a specific key or unique
2925 constraint. For example:
2926
2927   my $cd = $schema->resultset('CD')->find_or_create(
2928     {
2929       artist => 'Massive Attack',
2930       title  => 'Mezzanine',
2931     },
2932     { key => 'cd_artist_title' }
2933   );
2934
2935 B<Note>: Make sure to read the documentation of L</find> and understand the
2936 significance of the C<key> attribute, as its lack may skew your search, and
2937 subsequently result in spurious row creation.
2938
2939 B<Note>: Because find_or_create() reads from the database and then
2940 possibly inserts based on the result, this method is subject to a race
2941 condition. Another process could create a record in the table after
2942 the find has completed and before the create has started. To avoid
2943 this problem, use find_or_create() inside a transaction.
2944
2945 B<Note>: Take care when using C<find_or_create> with a table having
2946 columns with default values that you intend to be automatically
2947 supplied by the database (e.g. an auto_increment primary key column).
2948 In normal usage, the value of such columns should NOT be included at
2949 all in the call to C<find_or_create>, even when set to C<undef>.
2950
2951 See also L</find> and L</update_or_create>. For information on how to declare
2952 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2953
2954 If you need to know if an existing row was found or a new one created use
2955 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2956 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2957 database!
2958
2959   my $cd = $schema->resultset('CD')->find_or_new({
2960     cdid   => 5,
2961     artist => 'Massive Attack',
2962     title  => 'Mezzanine',
2963     year   => 2005,
2964   });
2965
2966   if( !$cd->in_storage ) {
2967       # do some stuff
2968       $cd->insert;
2969   }
2970
2971 =cut
2972
2973 sub find_or_create {
2974   my $self     = shift;
2975   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2976   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2977   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2978     return $row;
2979   }
2980   return $self->new_result($hash)->insert;
2981 }
2982
2983 =head2 update_or_create
2984
2985 =over 4
2986
2987 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2988
2989 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2990
2991 =back
2992
2993   $resultset->update_or_create({ col => $val, ... });
2994
2995 Like L</find_or_create>, but if a row is found it is immediately updated via
2996 C<< $found_row->update (\%col_data) >>.
2997
2998
2999 Takes an optional C<key> attribute to search on a specific unique constraint.
3000 For example:
3001
3002   # In your application
3003   my $cd = $schema->resultset('CD')->update_or_create(
3004     {
3005       artist => 'Massive Attack',
3006       title  => 'Mezzanine',
3007       year   => 1998,
3008     },
3009     { key => 'cd_artist_title' }
3010   );
3011
3012   $cd->cd_to_producer->update_or_create({
3013     producer => $producer,
3014     name => 'harry',
3015   }, {
3016     key => 'primary',
3017   });
3018
3019 B<Note>: Make sure to read the documentation of L</find> and understand the
3020 significance of the C<key> attribute, as its lack may skew your search, and
3021 subsequently result in spurious row creation.
3022
3023 B<Note>: Take care when using C<update_or_create> with a table having
3024 columns with default values that you intend to be automatically
3025 supplied by the database (e.g. an auto_increment primary key column).
3026 In normal usage, the value of such columns should NOT be included at
3027 all in the call to C<update_or_create>, even when set to C<undef>.
3028
3029 See also L</find> and L</find_or_create>. For information on how to declare
3030 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3031
3032 If you need to know if an existing row was updated or a new one created use
3033 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3034 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3035 database!
3036
3037 =cut
3038
3039 sub update_or_create {
3040   my $self = shift;
3041   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3042   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3043
3044   my $row = $self->find($cond, $attrs);
3045   if (defined $row) {
3046     $row->update($cond);
3047     return $row;
3048   }
3049
3050   return $self->new_result($cond)->insert;
3051 }
3052
3053 =head2 update_or_new
3054
3055 =over 4
3056
3057 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3058
3059 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3060
3061 =back
3062
3063   $resultset->update_or_new({ col => $val, ... });
3064
3065 Like L</find_or_new> but if a row is found it is immediately updated via
3066 C<< $found_row->update (\%col_data) >>.
3067
3068 For example:
3069
3070   # In your application
3071   my $cd = $schema->resultset('CD')->update_or_new(
3072     {
3073       artist => 'Massive Attack',
3074       title  => 'Mezzanine',
3075       year   => 1998,
3076     },
3077     { key => 'cd_artist_title' }
3078   );
3079
3080   if ($cd->in_storage) {
3081       # the cd was updated
3082   }
3083   else {
3084       # the cd is not yet in the database, let's insert it
3085       $cd->insert;
3086   }
3087
3088 B<Note>: Make sure to read the documentation of L</find> and understand the
3089 significance of the C<key> attribute, as its lack may skew your search, and
3090 subsequently result in spurious new objects.
3091
3092 B<Note>: Take care when using C<update_or_new> with a table having
3093 columns with default values that you intend to be automatically
3094 supplied by the database (e.g. an auto_increment primary key column).
3095 In normal usage, the value of such columns should NOT be included at
3096 all in the call to C<update_or_new>, even when set to C<undef>.
3097
3098 See also L</find>, L</find_or_create> and L</find_or_new>.
3099
3100 =cut
3101
3102 sub update_or_new {
3103     my $self  = shift;
3104     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3105     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3106
3107     my $row = $self->find( $cond, $attrs );
3108     if ( defined $row ) {
3109         $row->update($cond);
3110         return $row;
3111     }
3112
3113     return $self->new_result($cond);
3114 }
3115
3116 =head2 get_cache
3117
3118 =over 4
3119
3120 =item Arguments: none
3121
3122 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3123
3124 =back
3125
3126 Gets the contents of the cache for the resultset, if the cache is set.
3127
3128 The cache is populated either by using the L</prefetch> attribute to
3129 L</search> or by calling L</set_cache>.
3130
3131 =cut
3132
3133 sub get_cache {
3134   shift->{all_cache};
3135 }
3136
3137 =head2 set_cache
3138
3139 =over 4
3140
3141 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3142
3143 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3144
3145 =back
3146
3147 Sets the contents of the cache for the resultset. Expects an arrayref
3148 of objects of the same class as those produced by the resultset. Note that
3149 if the cache is set, the resultset will return the cached objects rather
3150 than re-querying the database even if the cache attr is not set.
3151
3152 The contents of the cache can also be populated by using the
3153 L</prefetch> attribute to L</search>.
3154
3155 =cut
3156
3157 sub set_cache {
3158   my ( $self, $data ) = @_;
3159   $self->throw_exception("set_cache requires an arrayref")
3160       if defined($data) && (ref $data ne 'ARRAY');
3161   $self->{all_cache} = $data;
3162 }
3163
3164 =head2 clear_cache
3165
3166 =over 4
3167
3168 =item Arguments: none
3169
3170 =item Return Value: undef
3171
3172 =back
3173
3174 Clears the cache for the resultset.
3175
3176 =cut
3177
3178 sub clear_cache {
3179   shift->set_cache(undef);
3180 }
3181
3182 =head2 is_paged
3183
3184 =over 4
3185
3186 =item Arguments: none
3187
3188 =item Return Value: true, if the resultset has been paginated
3189
3190 =back
3191
3192 =cut
3193
3194 sub is_paged {
3195   my ($self) = @_;
3196   return !!$self->{attrs}{page};
3197 }
3198
3199 =head2 is_ordered
3200
3201 =over 4
3202
3203 =item Arguments: none
3204
3205 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3206
3207 =back
3208
3209 =cut
3210
3211 sub is_ordered {
3212   my ($self) = @_;
3213   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3214 }
3215
3216 =head2 related_resultset
3217
3218 =over 4
3219
3220 =item Arguments: $rel_name
3221
3222 =item Return Value: L<$resultset|/search>
3223
3224 =back
3225
3226 Returns a related resultset for the supplied relationship name.
3227
3228   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3229
3230 =cut
3231
3232 sub related_resultset {
3233   my ($self, $rel) = @_;
3234
3235   return $self->{related_resultsets}{$rel}
3236     if defined $self->{related_resultsets}{$rel};
3237
3238   return $self->{related_resultsets}{$rel} = do {
3239     my $rsrc = $self->result_source;
3240     my $rel_info = $rsrc->relationship_info($rel);
3241
3242     $self->throw_exception(
3243       "search_related: result source '" . $rsrc->source_name .
3244         "' has no such relationship $rel")
3245       unless $rel_info;
3246
3247     my $attrs = $self->_chain_relationship($rel);
3248
3249     my $join_count = $attrs->{seen_join}{$rel};
3250
3251     my $alias = $self->result_source->storage
3252         ->relname_to_table_alias($rel, $join_count);
3253
3254     # since this is search_related, and we already slid the select window inwards
3255     # (the select/as attrs were deleted in the beginning), we need to flip all
3256     # left joins to inner, so we get the expected results
3257     # read the comment on top of the actual function to see what this does
3258     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3259
3260
3261     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3262     delete @{$attrs}{qw(result_class alias)};
3263
3264     my $rel_source = $rsrc->related_source($rel);
3265
3266     my $new = do {
3267
3268       # The reason we do this now instead of passing the alias to the
3269       # search_rs below is that if you wrap/overload resultset on the
3270       # source you need to know what alias it's -going- to have for things
3271       # to work sanely (e.g. RestrictWithObject wants to be able to add
3272       # extra query restrictions, and these may need to be $alias.)
3273
3274       my $rel_attrs = $rel_source->resultset_attributes;
3275       local $rel_attrs->{alias} = $alias;
3276
3277       $rel_source->resultset
3278                  ->search_rs(
3279                      undef, {
3280                        %$attrs,
3281                        where => $attrs->{where},
3282                    });
3283     };
3284
3285     if (my $cache = $self->get_cache) {
3286       my @related_cache = map
3287         { $_->related_resultset($rel)->get_cache || () }
3288         @$cache
3289       ;
3290
3291       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3292     }
3293
3294     $new;
3295   };
3296 }
3297
3298 =head2 current_source_alias
3299
3300 =over 4
3301
3302 =item Arguments: none
3303
3304 =item Return Value: $source_alias
3305
3306 =back
3307
3308 Returns the current table alias for the result source this resultset is built
3309 on, that will be used in the SQL query. Usually it is C<me>.
3310
3311 Currently the source alias that refers to the result set returned by a
3312 L</search>/L</find> family method depends on how you got to the resultset: it's
3313 C<me> by default, but eg. L</search_related> aliases it to the related result
3314 source name (and keeps C<me> referring to the original result set). The long
3315 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3316 (and make this method unnecessary).
3317
3318 Thus it's currently necessary to use this method in predefined queries (see
3319 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3320 source alias of the current result set:
3321
3322   # in a result set class
3323   sub modified_by {
3324     my ($self, $user) = @_;
3325
3326     my $me = $self->current_source_alias;
3327
3328     return $self->search({
3329       "$me.modified" => $user->id,
3330     });
3331   }
3332
3333 =cut
3334
3335 sub current_source_alias {
3336   return (shift->{attrs} || {})->{alias} || 'me';
3337 }
3338
3339 =head2 as_subselect_rs
3340
3341 =over 4
3342
3343 =item Arguments: none
3344
3345 =item Return Value: L<$resultset|/search>
3346
3347 =back
3348
3349 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3350 "virtual view" by including it as a subquery within the from clause.  From this
3351 point on, any joined tables are inaccessible to ->search on the resultset (as if
3352 it were simply where-filtered without joins).  For example:
3353
3354  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3355
3356  # 'x' now pollutes the query namespace
3357
3358  # So the following works as expected
3359  my $ok_rs = $rs->search({'x.other' => 1});
3360
3361  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3362  # def) we look for one row with contradictory terms and join in another table
3363  # (aliased 'x_2') which we never use
3364  my $broken_rs = $rs->search({'x.name' => 'def'});
3365
3366  my $rs2 = $rs->as_subselect_rs;
3367
3368  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3369  my $not_joined_rs = $rs2->search({'x.other' => 1});
3370
3371  # works as expected: finds a 'table' row related to two x rows (abc and def)
3372  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3373
3374 Another example of when one might use this would be to select a subset of
3375 columns in a group by clause:
3376
3377  my $rs = $schema->resultset('Bar')->search(undef, {
3378    group_by => [qw{ id foo_id baz_id }],
3379  })->as_subselect_rs->search(undef, {
3380    columns => [qw{ id foo_id }]
3381  });
3382
3383 In the above example normally columns would have to be equal to the group by,
3384 but because we isolated the group by into a subselect the above works.
3385
3386 =cut
3387
3388 sub as_subselect_rs {
3389   my $self = shift;
3390
3391   my $attrs = $self->_resolved_attrs;
3392
3393   my $fresh_rs = (ref $self)->new (
3394     $self->result_source
3395   );
3396
3397   # these pieces will be locked in the subquery
3398   delete $fresh_rs->{cond};
3399   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3400
3401   return $fresh_rs->search( {}, {
3402     from => [{
3403       $attrs->{alias} => $self->as_query,
3404       -alias  => $attrs->{alias},
3405       -rsrc   => $self->result_source,
3406     }],
3407     alias => $attrs->{alias},
3408   });
3409 }
3410
3411 # This code is called by search_related, and makes sure there
3412 # is clear separation between the joins before, during, and
3413 # after the relationship. This information is needed later
3414 # in order to properly resolve prefetch aliases (any alias
3415 # with a relation_chain_depth less than the depth of the
3416 # current prefetch is not considered)
3417 #
3418 # The increments happen twice per join. An even number means a
3419 # relationship specified via a search_related, whereas an odd
3420 # number indicates a join/prefetch added via attributes
3421 #
3422 # Also this code will wrap the current resultset (the one we
3423 # chain to) in a subselect IFF it contains limiting attributes
3424 sub _chain_relationship {
3425   my ($self, $rel) = @_;
3426   my $source = $self->result_source;
3427   my $attrs = { %{$self->{attrs}||{}} };
3428
3429   # we need to take the prefetch the attrs into account before we
3430   # ->_resolve_join as otherwise they get lost - captainL
3431   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3432
3433   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3434
3435   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3436
3437   my $from;
3438   my @force_subq_attrs = qw/offset rows group_by having/;
3439
3440   if (
3441     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3442       ||
3443     $self->_has_resolved_attr (@force_subq_attrs)
3444   ) {
3445     # Nuke the prefetch (if any) before the new $rs attrs
3446     # are resolved (prefetch is useless - we are wrapping
3447     # a subquery anyway).
3448     my $rs_copy = $self->search;
3449     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3450       $rs_copy->{attrs}{join},
3451       delete $rs_copy->{attrs}{prefetch},
3452     );
3453
3454     $from = [{
3455       -rsrc   => $source,
3456       -alias  => $attrs->{alias},
3457       $attrs->{alias} => $rs_copy->as_query,
3458     }];
3459     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3460     $seen->{-relation_chain_depth} = 0;
3461   }
3462   elsif ($attrs->{from}) {  #shallow copy suffices
3463     $from = [ @{$attrs->{from}} ];
3464   }
3465   else {
3466     $from = [{
3467       -rsrc  => $source,
3468       -alias => $attrs->{alias},
3469       $attrs->{alias} => $source->from,
3470     }];
3471   }
3472
3473   my $jpath = ($seen->{-relation_chain_depth})
3474     ? $from->[-1][0]{-join_path}
3475     : [];
3476
3477   my @requested_joins = $source->_resolve_join(
3478     $join,
3479     $attrs->{alias},
3480     $seen,
3481     $jpath,
3482   );
3483
3484   push @$from, @requested_joins;
3485
3486   $seen->{-relation_chain_depth}++;
3487
3488   # if $self already had a join/prefetch specified on it, the requested
3489   # $rel might very well be already included. What we do in this case
3490   # is effectively a no-op (except that we bump up the chain_depth on
3491   # the join in question so we could tell it *is* the search_related)
3492   my $already_joined;
3493
3494   # we consider the last one thus reverse
3495   for my $j (reverse @requested_joins) {
3496     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3497     if ($rel eq $last_j) {
3498       $j->[0]{-relation_chain_depth}++;
3499       $already_joined++;
3500       last;
3501     }
3502   }
3503
3504   unless ($already_joined) {
3505     push @$from, $source->_resolve_join(
3506       $rel,
3507       $attrs->{alias},
3508       $seen,
3509       $jpath,
3510     );
3511   }
3512
3513   $seen->{-relation_chain_depth}++;
3514
3515   return {%$attrs, from => $from, seen_join => $seen};
3516 }
3517
3518 sub _resolved_attrs {
3519   my $self = shift;
3520   return $self->{_attrs} if $self->{_attrs};
3521
3522   my $attrs  = { %{ $self->{attrs} || {} } };
3523   my $source = $attrs->{result_source} = $self->result_source;
3524   my $alias  = $attrs->{alias};
3525
3526   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3527     if $attrs->{collapse} and $attrs->{distinct};
3528
3529   # default selection list
3530   $attrs->{columns} = [ $source->columns ]
3531     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3532
3533   # merge selectors together
3534   for (qw/columns select as/) {
3535     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3536       if $attrs->{$_} or $attrs->{"+$_"};
3537   }
3538
3539   # disassemble columns
3540   my (@sel, @as);
3541   if (my $cols = delete $attrs->{columns}) {
3542     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3543       if (ref $c eq 'HASH') {
3544         for my $as (sort keys %$c) {
3545           push @sel, $c->{$as};
3546           push @as, $as;
3547         }
3548       }
3549       else {
3550         push @sel, $c;
3551         push @as, $c;
3552       }
3553     }
3554   }
3555
3556   # when trying to weed off duplicates later do not go past this point -
3557   # everything added from here on is unbalanced "anyone's guess" stuff
3558   my $dedup_stop_idx = $#as;
3559
3560   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3561     if $attrs->{as};
3562   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3563     if $attrs->{select};
3564
3565   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3566   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3567
3568   # disqualify all $alias.col as-bits (inflate-map mandated)
3569   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3570
3571   # de-duplicate the result (remove *identical* select/as pairs)
3572   # and also die on duplicate {as} pointing to different {select}s
3573   # not using a c-style for as the condition is prone to shrinkage
3574   my $seen;
3575   my $i = 0;
3576   while ($i <= $dedup_stop_idx) {
3577     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3578       splice @sel, $i, 1;
3579       splice @as, $i, 1;
3580       $dedup_stop_idx--;
3581     }
3582     elsif ($seen->{$as[$i]}++) {
3583       $self->throw_exception(
3584         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3585       );
3586     }
3587     else {
3588       $i++;
3589     }
3590   }
3591
3592   $attrs->{select} = \@sel;
3593   $attrs->{as} = \@as;
3594
3595   $attrs->{from} ||= [{
3596     -rsrc   => $source,
3597     -alias  => $self->{attrs}{alias},
3598     $self->{attrs}{alias} => $source->from,
3599   }];
3600
3601   if ( $attrs->{join} || $attrs->{prefetch} ) {
3602
3603     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3604       if ref $attrs->{from} ne 'ARRAY';
3605
3606     my $join = (delete $attrs->{join}) || {};
3607
3608     if ( defined $attrs->{prefetch} ) {
3609       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3610     }
3611
3612     $attrs->{from} =    # have to copy here to avoid corrupting the original
3613       [
3614         @{ $attrs->{from} },
3615         $source->_resolve_join(
3616           $join,
3617           $alias,
3618           { %{ $attrs->{seen_join} || {} } },
3619           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3620             ? $attrs->{from}[-1][0]{-join_path}
3621             : []
3622           ,
3623         )
3624       ];
3625   }
3626
3627   if ( defined $attrs->{order_by} ) {
3628     $attrs->{order_by} = (
3629       ref( $attrs->{order_by} ) eq 'ARRAY'
3630       ? [ @{ $attrs->{order_by} } ]
3631       : [ $attrs->{order_by} || () ]
3632     );
3633   }
3634
3635   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3636     $attrs->{group_by} = [ $attrs->{group_by} ];
3637   }
3638
3639
3640   # generate selections based on the prefetch helper
3641   my ($prefetch, @prefetch_select, @prefetch_as);
3642   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3643     if defined $attrs->{prefetch};
3644
3645   if ($prefetch) {
3646
3647     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3648       if $attrs->{_dark_selector};
3649
3650     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3651       if defined $attrs->{collapse} and ! $attrs->{collapse};
3652
3653     $attrs->{collapse} = 1;
3654
3655     # this is a separate structure (we don't look in {from} directly)
3656     # as the resolver needs to shift things off the lists to work
3657     # properly (identical-prefetches on different branches)
3658     my $join_map = {};
3659     if (ref $attrs->{from} eq 'ARRAY') {
3660
3661       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3662
3663       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3664         next unless $j->[0]{-alias};
3665         next unless $j->[0]{-join_path};
3666         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3667
3668         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3669
3670         my $p = $join_map;
3671         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3672         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3673       }
3674     }
3675
3676     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3677
3678     # save these for after distinct resolution
3679     @prefetch_select = map { $_->[0] } @prefetch;
3680     @prefetch_as = map { $_->[1] } @prefetch;
3681   }
3682
3683   # run through the resulting joinstructure (starting from our current slot)
3684   # and unset collapse if proven unnecessary
3685   #
3686   # also while we are at it find out if the current root source has
3687   # been premultiplied by previous related_source chaining
3688   #
3689   # this allows to predict whether a root object with all other relation
3690   # data set to NULL is in fact unique
3691   if ($attrs->{collapse}) {
3692
3693     if (ref $attrs->{from} eq 'ARRAY') {
3694
3695       if (@{$attrs->{from}} == 1) {
3696         # no joins - no collapse
3697         $attrs->{collapse} = 0;
3698       }
3699       else {
3700         # find where our table-spec starts
3701         my @fromlist = @{$attrs->{from}};
3702         while (@fromlist) {
3703           my $t = shift @fromlist;
3704
3705           my $is_multi;
3706           # me vs join from-spec distinction - a ref means non-root
3707           if (ref $t eq 'ARRAY') {
3708             $t = $t->[0];
3709             $is_multi ||= ! $t->{-is_single};
3710           }
3711           last if ($t->{-alias} && $t->{-alias} eq $alias);
3712           $attrs->{_main_source_premultiplied} ||= $is_multi;
3713         }
3714
3715         # no non-singles remaining, nor any premultiplication - nothing to collapse
3716         if (
3717           ! $attrs->{_main_source_premultiplied}
3718             and
3719           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3720         ) {
3721           $attrs->{collapse} = 0;
3722         }
3723       }
3724     }
3725
3726     else {
3727       # if we can not analyze the from - err on the side of safety
3728       $attrs->{_main_source_premultiplied} = 1;
3729     }
3730   }
3731
3732   # generate the distinct induced group_by before injecting the prefetched select/as parts
3733   if (delete $attrs->{distinct}) {
3734     if ($attrs->{group_by}) {
3735       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3736     }
3737     else {
3738       $attrs->{_grouped_by_distinct} = 1;
3739       # distinct affects only the main selection part, not what prefetch may add below
3740       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3741
3742       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3743       # The thinking is: if we are collapsing the subquerying prefetch engine will
3744       # rip stuff apart for us anyway, and we do not want to have a potentially
3745       # function-converted external order_by
3746       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3747       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3748     }
3749   }
3750
3751   # inject prefetch-bound selection (if any)
3752   push @{$attrs->{select}}, @prefetch_select;
3753   push @{$attrs->{as}}, @prefetch_as;
3754
3755   $attrs->{_simple_passthrough_construction} = !(
3756     $attrs->{collapse}
3757       or
3758     grep { $_ =~ /\./ } @{$attrs->{as}}
3759   );
3760
3761   # if both page and offset are specified, produce a combined offset
3762   # even though it doesn't make much sense, this is what pre 081xx has
3763   # been doing
3764   if (my $page = delete $attrs->{page}) {
3765     $attrs->{offset} =
3766       ($attrs->{rows} * ($page - 1))
3767             +
3768       ($attrs->{offset} || 0)
3769     ;
3770   }
3771
3772   return $self->{_attrs} = $attrs;
3773 }
3774
3775 sub _rollout_attr {
3776   my ($self, $attr) = @_;
3777
3778   if (ref $attr eq 'HASH') {
3779     return $self->_rollout_hash($attr);
3780   } elsif (ref $attr eq 'ARRAY') {
3781     return $self->_rollout_array($attr);
3782   } else {
3783     return [$attr];
3784   }
3785 }
3786
3787 sub _rollout_array {
3788   my ($self, $attr) = @_;
3789
3790   my @rolled_array;
3791   foreach my $element (@{$attr}) {
3792     if (ref $element eq 'HASH') {
3793       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3794     } elsif (ref $element eq 'ARRAY') {
3795       #  XXX - should probably recurse here
3796       push( @rolled_array, @{$self->_rollout_array($element)} );
3797     } else {
3798       push( @rolled_array, $element );
3799     }
3800   }
3801   return \@rolled_array;
3802 }
3803
3804 sub _rollout_hash {
3805   my ($self, $attr) = @_;
3806
3807   my @rolled_array;
3808   foreach my $key (keys %{$attr}) {
3809     push( @rolled_array, { $key => $attr->{$key} } );
3810   }
3811   return \@rolled_array;
3812 }
3813
3814 sub _calculate_score {
3815   my ($self, $a, $b) = @_;
3816
3817   if (defined $a xor defined $b) {
3818     return 0;
3819   }
3820   elsif (not defined $a) {
3821     return 1;
3822   }
3823
3824   if (ref $b eq 'HASH') {
3825     my ($b_key) = keys %{$b};
3826     if (ref $a eq 'HASH') {
3827       my ($a_key) = keys %{$a};
3828       if ($a_key eq $b_key) {
3829         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3830       } else {
3831         return 0;
3832       }
3833     } else {
3834       return ($a eq $b_key) ? 1 : 0;
3835     }
3836   } else {
3837     if (ref $a eq 'HASH') {
3838       my ($a_key) = keys %{$a};
3839       return ($b eq $a_key) ? 1 : 0;
3840     } else {
3841       return ($b eq $a) ? 1 : 0;
3842     }
3843   }
3844 }
3845
3846 sub _merge_joinpref_attr {
3847   my ($self, $orig, $import) = @_;
3848
3849   return $import unless defined($orig);
3850   return $orig unless defined($import);
3851
3852   $orig = $self->_rollout_attr($orig);
3853   $import = $self->_rollout_attr($import);
3854
3855   my $seen_keys;
3856   foreach my $import_element ( @{$import} ) {
3857     # find best candidate from $orig to merge $b_element into
3858     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3859     foreach my $orig_element ( @{$orig} ) {
3860       my $score = $self->_calculate_score( $orig_element, $import_element );
3861       if ($score > $best_candidate->{score}) {
3862         $best_candidate->{position} = $position;
3863         $best_candidate->{score} = $score;
3864       }
3865       $position++;
3866     }
3867     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3868     $import_key = '' if not defined $import_key;
3869
3870     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3871       push( @{$orig}, $import_element );
3872     } else {
3873       my $orig_best = $orig->[$best_candidate->{position}];
3874       # merge orig_best and b_element together and replace original with merged
3875       if (ref $orig_best ne 'HASH') {
3876         $orig->[$best_candidate->{position}] = $import_element;
3877       } elsif (ref $import_element eq 'HASH') {
3878         my ($key) = keys %{$orig_best};
3879         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3880       }
3881     }
3882     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3883   }
3884
3885   return @$orig ? $orig : ();
3886 }
3887
3888 {
3889   my $hm;
3890
3891   sub _merge_attr {
3892     $hm ||= do {
3893       require Hash::Merge;
3894       my $hm = Hash::Merge->new;
3895
3896       $hm->specify_behavior({
3897         SCALAR => {
3898           SCALAR => sub {
3899             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3900
3901             if ($defl xor $defr) {
3902               return [ $defl ? $_[0] : $_[1] ];
3903             }
3904             elsif (! $defl) {
3905               return [];
3906             }
3907             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3908               return [ $_[0] ];
3909             }
3910             else {
3911               return [$_[0], $_[1]];
3912             }
3913           },
3914           ARRAY => sub {
3915             return $_[1] if !defined $_[0];
3916             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3917             return [$_[0], @{$_[1]}]
3918           },
3919           HASH  => sub {
3920             return [] if !defined $_[0] and !keys %{$_[1]};
3921             return [ $_[1] ] if !defined $_[0];
3922             return [ $_[0] ] if !keys %{$_[1]};
3923             return [$_[0], $_[1]]
3924           },
3925         },
3926         ARRAY => {
3927           SCALAR => sub {
3928             return $_[0] if !defined $_[1];
3929             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3930             return [@{$_[0]}, $_[1]]
3931           },
3932           ARRAY => sub {
3933             my @ret = @{$_[0]} or return $_[1];
3934             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3935             my %idx = map { $_ => 1 } @ret;
3936             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3937             \@ret;
3938           },
3939           HASH => sub {
3940             return [ $_[1] ] if ! @{$_[0]};
3941             return $_[0] if !keys %{$_[1]};
3942             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3943             return [ @{$_[0]}, $_[1] ];
3944           },
3945         },
3946         HASH => {
3947           SCALAR => sub {
3948             return [] if !keys %{$_[0]} and !defined $_[1];
3949             return [ $_[0] ] if !defined $_[1];
3950             return [ $_[1] ] if !keys %{$_[0]};
3951             return [$_[0], $_[1]]
3952           },
3953           ARRAY => sub {
3954             return [] if !keys %{$_[0]} and !@{$_[1]};
3955             return [ $_[0] ] if !@{$_[1]};
3956             return $_[1] if !keys %{$_[0]};
3957             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3958             return [ $_[0], @{$_[1]} ];
3959           },
3960           HASH => sub {
3961             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3962             return [ $_[0] ] if !keys %{$_[1]};
3963             return [ $_[1] ] if !keys %{$_[0]};
3964             return [ $_[0] ] if $_[0] eq $_[1];
3965             return [ $_[0], $_[1] ];
3966           },
3967         }
3968       } => 'DBIC_RS_ATTR_MERGER');
3969       $hm;
3970     };
3971
3972     return $hm->merge ($_[1], $_[2]);
3973   }
3974 }
3975
3976 sub STORABLE_freeze {
3977   my ($self, $cloning) = @_;
3978   my $to_serialize = { %$self };
3979
3980   # A cursor in progress can't be serialized (and would make little sense anyway)
3981   # the parser can be regenerated (and can't be serialized)
3982   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3983
3984   # nor is it sensical to store a not-yet-fired-count pager
3985   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3986     delete $to_serialize->{pager};
3987   }
3988
3989   Storable::nfreeze($to_serialize);
3990 }
3991
3992 # need this hook for symmetry
3993 sub STORABLE_thaw {
3994   my ($self, $cloning, $serialized) = @_;
3995
3996   %$self = %{ Storable::thaw($serialized) };
3997
3998   $self;
3999 }
4000
4001
4002 =head2 throw_exception
4003
4004 See L<DBIx::Class::Schema/throw_exception> for details.
4005
4006 =cut
4007
4008 sub throw_exception {
4009   my $self=shift;
4010
4011   if (ref $self and my $rsrc = $self->result_source) {
4012     $rsrc->throw_exception(@_)
4013   }
4014   else {
4015     DBIx::Class::Exception->throw(@_);
4016   }
4017 }
4018
4019 1;
4020
4021 __END__
4022
4023 # XXX: FIXME: Attributes docs need clearing up
4024
4025 =head1 ATTRIBUTES
4026
4027 Attributes are used to refine a ResultSet in various ways when
4028 searching for data. They can be passed to any method which takes an
4029 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4030 L</count>.
4031
4032 Default attributes can be set on the result class using
4033 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4034 the CAVEATS on that feature before using it!)
4035
4036 These are in no particular order:
4037
4038 =head2 order_by
4039
4040 =over 4
4041
4042 =item Value: ( $order_by | \@order_by | \%order_by )
4043
4044 =back
4045
4046 Which column(s) to order the results by.
4047
4048 [The full list of suitable values is documented in
4049 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4050 common options.]
4051
4052 If a single column name, or an arrayref of names is supplied, the
4053 argument is passed through directly to SQL. The hashref syntax allows
4054 for connection-agnostic specification of ordering direction:
4055
4056  For descending order:
4057
4058   order_by => { -desc => [qw/col1 col2 col3/] }
4059
4060  For explicit ascending order:
4061
4062   order_by => { -asc => 'col' }
4063
4064 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4065 supported, although you are strongly encouraged to use the hashref
4066 syntax as outlined above.
4067
4068 =head2 columns
4069
4070 =over 4
4071
4072 =item Value: \@columns | \%columns | $column
4073
4074 =back
4075
4076 Shortcut to request a particular set of columns to be retrieved. Each
4077 column spec may be a string (a table column name), or a hash (in which
4078 case the key is the C<as> value, and the value is used as the C<select>
4079 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4080 it and sets C<select> from that, then auto-populates C<as> from
4081 C<select> as normal. (You may also use the C<cols> attribute, as in
4082 earlier versions of DBIC, but this is deprecated)
4083
4084 Essentially C<columns> does the same as L</select> and L</as>.
4085
4086     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4087
4088 is the same as
4089
4090     select => [qw(some_column another_column)],
4091     as     => [qw(some_column dbic_slot)]
4092
4093 If you want to individually retrieve related columns (in essence perform
4094 manual prefetch) you have to make sure to specify the correct inflation slot
4095 chain such that it matches existing relationships:
4096
4097     my $rs = $schema->resultset('Artist')->search({}, {
4098         # required to tell DBIC to collapse has_many relationships
4099         collapse => 1,
4100         join     => { cds => 'tracks'},
4101         '+columns'  => {
4102           'cds.cdid'         => 'cds.cdid',
4103           'cds.tracks.title' => 'tracks.title',
4104         },
4105     });
4106
4107 =head2 +columns
4108
4109 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4110 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4111 with a unary plus operator before it, which is the same as simply C<columns>.
4112
4113 =over 4
4114
4115 =item Value: \@extra_columns
4116
4117 =back
4118
4119 Indicates additional columns to be selected from storage. Works the same as
4120 L</columns> but adds columns to the current selection. (You may also use the
4121 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4122 deprecated)
4123
4124   $schema->resultset('CD')->search(undef, {
4125     '+columns' => ['artist.name'],
4126     join => ['artist']
4127   });
4128
4129 would return all CDs and include a 'name' column to the information
4130 passed to object inflation. Note that the 'artist' is the name of the
4131 column (or relationship) accessor, and 'name' is the name of the column
4132 accessor in the related table.
4133
4134 =head2 select
4135
4136 =over 4
4137
4138 =item Value: \@select_columns
4139
4140 =back
4141
4142 Indicates which columns should be selected from the storage. You can use
4143 column names, or in the case of RDBMS back ends, function or stored procedure
4144 names:
4145
4146   $rs = $schema->resultset('Employee')->search(undef, {
4147     select => [
4148       'name',
4149       { count => 'employeeid' },
4150       { max => { length => 'name' }, -as => 'longest_name' }
4151     ]
4152   });
4153
4154   # Equivalent SQL
4155   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4156
4157 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4158 use L</select>, to instruct DBIx::Class how to store the result of the column.
4159 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4160 identifier aliasing. You can however alias a function, so you can use it in
4161 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4162 attribute> supplied as shown in the example above.
4163
4164 =head2 +select
4165
4166 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4167 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4168 with a unary plus operator before it, which is the same as simply C<select>.
4169
4170 =over 4
4171
4172 =item Value: \@extra_select_columns
4173
4174 =back
4175
4176 Indicates additional columns to be selected from storage.  Works the same as
4177 L</select> but adds columns to the current selection, instead of specifying
4178 a new explicit list.
4179
4180 =head2 as
4181
4182 =over 4
4183
4184 =item Value: \@inflation_names
4185
4186 =back
4187
4188 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4189 slot name in which the column value will be stored within the
4190 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4191 identifier by the C<get_column> method (or via the object accessor B<if one
4192 with the same name already exists>) as shown below. The L</as> attribute has
4193 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4194
4195   $rs = $schema->resultset('Employee')->search(undef, {
4196     select => [
4197       'name',
4198       { count => 'employeeid' },
4199       { max => { length => 'name' }, -as => 'longest_name' }
4200     ],
4201     as => [qw/
4202       name
4203       employee_count
4204       max_name_length
4205     /],
4206   });
4207
4208 If the object against which the search is performed already has an accessor
4209 matching a column name specified in C<as>, the value can be retrieved using
4210 the accessor as normal:
4211
4212   my $name = $employee->name();
4213
4214 If on the other hand an accessor does not exist in the object, you need to
4215 use C<get_column> instead:
4216
4217   my $employee_count = $employee->get_column('employee_count');
4218
4219 You can create your own accessors if required - see
4220 L<DBIx::Class::Manual::Cookbook> for details.
4221
4222 =head2 +as
4223
4224 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4225 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4226 with a unary plus operator before it, which is the same as simply C<as>.
4227
4228 =over 4
4229
4230 =item Value: \@extra_inflation_names
4231
4232 =back
4233
4234 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4235
4236 =head2 join
4237
4238 =over 4
4239
4240 =item Value: ($rel_name | \@rel_names | \%rel_names)
4241
4242 =back
4243
4244 Contains a list of relationships that should be joined for this query.  For
4245 example:
4246
4247   # Get CDs by Nine Inch Nails
4248   my $rs = $schema->resultset('CD')->search(
4249     { 'artist.name' => 'Nine Inch Nails' },
4250     { join => 'artist' }
4251   );
4252
4253 Can also contain a hash reference to refer to the other relation's relations.
4254 For example:
4255
4256   package MyApp::Schema::Track;
4257   use base qw/DBIx::Class/;
4258   __PACKAGE__->table('track');
4259   __PACKAGE__->add_columns(qw/trackid cd position title/);
4260   __PACKAGE__->set_primary_key('trackid');
4261   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4262   1;
4263
4264   # In your application
4265   my $rs = $schema->resultset('Artist')->search(
4266     { 'track.title' => 'Teardrop' },
4267     {
4268       join     => { cd => 'track' },
4269       order_by => 'artist.name',
4270     }
4271   );
4272
4273 You need to use the relationship (not the table) name in  conditions,
4274 because they are aliased as such. The current table is aliased as "me", so
4275 you need to use me.column_name in order to avoid ambiguity. For example:
4276
4277   # Get CDs from 1984 with a 'Foo' track
4278   my $rs = $schema->resultset('CD')->search(
4279     {
4280       'me.year' => 1984,
4281       'tracks.name' => 'Foo'
4282     },
4283     { join => 'tracks' }
4284   );
4285
4286 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4287 similarly for a third time). For e.g.
4288
4289   my $rs = $schema->resultset('Artist')->search({
4290     'cds.title'   => 'Down to Earth',
4291     'cds_2.title' => 'Popular',
4292   }, {
4293     join => [ qw/cds cds/ ],
4294   });
4295
4296 will return a set of all artists that have both a cd with title 'Down
4297 to Earth' and a cd with title 'Popular'.
4298
4299 If you want to fetch related objects from other tables as well, see L</prefetch>
4300 below.
4301
4302  NOTE: An internal join-chain pruner will discard certain joins while
4303  constructing the actual SQL query, as long as the joins in question do not
4304  affect the retrieved result. This for example includes 1:1 left joins
4305  that are not part of the restriction specification (WHERE/HAVING) nor are
4306  a part of the query selection.
4307
4308 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4309
4310 =head2 collapse
4311
4312 =over 4
4313
4314 =item Value: (0 | 1)
4315
4316 =back
4317
4318 When set to a true value, indicates that any rows fetched from joined has_many
4319 relationships are to be aggregated into the corresponding "parent" object. For
4320 example, the resultset:
4321
4322   my $rs = $schema->resultset('CD')->search({}, {
4323     '+columns' => [ qw/ tracks.title tracks.position / ],
4324     join => 'tracks',
4325     collapse => 1,
4326   });
4327
4328 While executing the following query:
4329
4330   SELECT me.*, tracks.title, tracks.position
4331     FROM cd me
4332     LEFT JOIN track tracks
4333       ON tracks.cdid = me.cdid
4334
4335 Will return only as many objects as there are rows in the CD source, even
4336 though the result of the query may span many rows. Each of these CD objects
4337 will in turn have multiple "Track" objects hidden behind the has_many
4338 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4339 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4340 product"), with each CD object containing exactly one of all fetched Track data.
4341
4342 When a collapse is requested on a non-ordered resultset, an order by some
4343 unique part of the main source (the left-most table) is inserted automatically.
4344 This is done so that the resultset is allowed to be "lazy" - calling
4345 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4346 object with all of its related data.
4347
4348 If an L</order_by> is already declared, and orders the resultset in a way that
4349 makes collapsing as described above impossible (e.g. C<< ORDER BY
4350 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4351 switch to "eager" mode and slurp the entire resultset before constructing the
4352 first object returned by L</next>.
4353
4354 Setting this attribute on a resultset that does not join any has_many
4355 relations is a no-op.
4356
4357 For a more in-depth discussion, see L</PREFETCHING>.
4358
4359 =head2 prefetch
4360
4361 =over 4
4362
4363 =item Value: ($rel_name | \@rel_names | \%rel_names)
4364
4365 =back
4366
4367 This attribute is a shorthand for specifying a L</join> spec, adding all
4368 columns from the joined related sources as L</+columns> and setting
4369 L</collapse> to a true value. It can be thought of as a rough B<superset>
4370 of the L</join> attribute.
4371
4372 For example, the following two queries are equivalent:
4373
4374   my $rs = $schema->resultset('Artist')->search({}, {
4375     prefetch => { cds => ['genre', 'tracks' ] },
4376   });
4377
4378 and
4379
4380   my $rs = $schema->resultset('Artist')->search({}, {
4381     join => { cds => ['genre', 'tracks' ] },
4382     collapse => 1,
4383     '+columns' => [
4384       (map
4385         { +{ "cds.$_" => "cds.$_" } }
4386         $schema->source('Artist')->related_source('cds')->columns
4387       ),
4388       (map
4389         { +{ "cds.genre.$_" => "genre.$_" } }
4390         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4391       ),
4392       (map
4393         { +{ "cds.tracks.$_" => "tracks.$_" } }
4394         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4395       ),
4396     ],
4397   });
4398
4399 Both producing the following SQL:
4400
4401   SELECT  me.artistid, me.name, me.rank, me.charfield,
4402           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4403           genre.genreid, genre.name,
4404           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4405     FROM artist me
4406     LEFT JOIN cd cds
4407       ON cds.artist = me.artistid
4408     LEFT JOIN genre genre
4409       ON genre.genreid = cds.genreid
4410     LEFT JOIN track tracks
4411       ON tracks.cd = cds.cdid
4412   ORDER BY me.artistid
4413
4414 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4415 the arguments are properly merged and generally do the right thing. For
4416 example, you may want to do the following:
4417
4418   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4419     { 'genre.genreid' => undef },
4420     {
4421       join => { cds => 'genre' },
4422       prefetch => 'cds',
4423     }
4424   );
4425
4426 Which generates the following SQL:
4427
4428   SELECT  me.artistid, me.name, me.rank, me.charfield,
4429           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4430     FROM artist me
4431     LEFT JOIN cd cds
4432       ON cds.artist = me.artistid
4433     LEFT JOIN genre genre
4434       ON genre.genreid = cds.genreid
4435   WHERE genre.genreid IS NULL
4436   ORDER BY me.artistid
4437
4438 For a more in-depth discussion, see L</PREFETCHING>.
4439
4440 =head2 alias
4441
4442 =over 4
4443
4444 =item Value: $source_alias
4445
4446 =back
4447
4448 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4449 nested search queries (sub-SELECTs) might need specific aliases set to
4450 reference inner queries.  For example:
4451
4452    my $q = $rs
4453       ->related_resultset('CDs')
4454       ->related_resultset('Tracks')
4455       ->search({
4456          'track.id' => { -ident => 'none_search.id' },
4457       })
4458       ->as_query;
4459
4460    my $ids = $self->search({
4461       -not_exists => $q,
4462    }, {
4463       alias    => 'none_search',
4464       group_by => 'none_search.id',
4465    })->get_column('id')->as_query;
4466
4467    $self->search({ id => { -in => $ids } })
4468
4469 This attribute is directly tied to L</current_source_alias>.
4470
4471 =head2 page
4472
4473 =over 4
4474
4475 =item Value: $page
4476
4477 =back
4478
4479 Makes the resultset paged and specifies the page to retrieve. Effectively
4480 identical to creating a non-pages resultset and then calling ->page($page)
4481 on it.
4482
4483 If L</rows> attribute is not specified it defaults to 10 rows per page.
4484
4485 When you have a paged resultset, L</count> will only return the number
4486 of rows in the page. To get the total, use the L</pager> and call
4487 C<total_entries> on it.
4488
4489 =head2 rows
4490
4491 =over 4
4492
4493 =item Value: $rows
4494
4495 =back
4496
4497 Specifies the maximum number of rows for direct retrieval or the number of
4498 rows per page if the page attribute or method is used.
4499
4500 =head2 offset
4501
4502 =over 4
4503
4504 =item Value: $offset
4505
4506 =back
4507
4508 Specifies the (zero-based) row number for the  first row to be returned, or the
4509 of the first row of the first page if paging is used.
4510
4511 =head2 software_limit
4512
4513 =over 4
4514
4515 =item Value: (0 | 1)
4516
4517 =back
4518
4519 When combined with L</rows> and/or L</offset> the generated SQL will not
4520 include any limit dialect stanzas. Instead the entire result will be selected
4521 as if no limits were specified, and DBIC will perform the limit locally, by
4522 artificially advancing and finishing the resulting L</cursor>.
4523
4524 This is the recommended way of performing resultset limiting when no sane RDBMS
4525 implementation is available (e.g.
4526 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4527 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4528
4529 =head2 group_by
4530
4531 =over 4
4532
4533 =item Value: \@columns
4534
4535 =back
4536
4537 A arrayref of columns to group by. Can include columns of joined tables.
4538
4539   group_by => [qw/ column1 column2 ... /]
4540
4541 =head2 having
4542
4543 =over 4
4544
4545 =item Value: $condition
4546
4547 =back
4548
4549 The HAVING operator specifies a B<secondary> condition applied to the set
4550 after the grouping calculations have been done. In other words it is a
4551 constraint just like L</where> (and accepting the same
4552 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4553 as it exists after GROUP BY has taken place. Specifying L</having> without
4554 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4555
4556 E.g.
4557
4558   having => { 'count_employee' => { '>=', 100 } }
4559
4560 or with an in-place function in which case literal SQL is required:
4561
4562   having => \[ 'count(employee) >= ?', 100 ]
4563
4564 =head2 distinct
4565
4566 =over 4
4567
4568 =item Value: (0 | 1)
4569
4570 =back
4571
4572 Set to 1 to automatically generate a L</group_by> clause based on the selection
4573 (including intelligent handling of L</order_by> contents). Note that the group
4574 criteria calculation takes place over the B<final> selection. This includes
4575 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4576 L</search> calls, and standalone columns selected via
4577 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4578 extra selections specified via L</prefetch> - such selections are explicitly
4579 excluded from group criteria calculations.
4580
4581 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4582 setting is ignored and an appropriate warning is issued.
4583
4584 =head2 where
4585
4586 =over 4
4587
4588 Adds to the WHERE clause.
4589
4590   # only return rows WHERE deleted IS NULL for all searches
4591   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4592
4593 Can be overridden by passing C<< { where => undef } >> as an attribute
4594 to a resultset.
4595
4596 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4597
4598 =back
4599
4600 =head2 cache
4601
4602 Set to 1 to cache search results. This prevents extra SQL queries if you
4603 revisit rows in your ResultSet:
4604
4605   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4606
4607   while( my $artist = $resultset->next ) {
4608     ... do stuff ...
4609   }
4610
4611   $rs->first; # without cache, this would issue a query
4612
4613 By default, searches are not cached.
4614
4615 For more examples of using these attributes, see
4616 L<DBIx::Class::Manual::Cookbook>.
4617
4618 =head2 for
4619
4620 =over 4
4621
4622 =item Value: ( 'update' | 'shared' | \$scalar )
4623
4624 =back
4625
4626 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4627 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4628 query.
4629
4630 =head1 PREFETCHING
4631
4632 DBIx::Class supports arbitrary related data prefetching from multiple related
4633 sources. Any combination of relationship types and column sets are supported.
4634 If L<collapsing|/collapse> is requested, there is an additional requirement of
4635 selecting enough data to make every individual object uniquely identifiable.
4636
4637 Here are some more involved examples, based on the following relationship map:
4638
4639   # Assuming:
4640   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4641   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4642   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4643
4644   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4645
4646   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4647
4648
4649
4650   my $rs = $schema->resultset('Tag')->search(
4651     undef,
4652     {
4653       prefetch => {
4654         cd => 'artist'
4655       }
4656     }
4657   );
4658
4659 The initial search results in SQL like the following:
4660
4661   SELECT tag.*, cd.*, artist.* FROM tag
4662   JOIN cd ON tag.cd = cd.cdid
4663   JOIN artist ON cd.artist = artist.artistid
4664
4665 L<DBIx::Class> has no need to go back to the database when we access the
4666 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4667 case.
4668
4669 Simple prefetches will be joined automatically, so there is no need
4670 for a C<join> attribute in the above search.
4671
4672 The L</prefetch> attribute can be used with any of the relationship types
4673 and multiple prefetches can be specified together. Below is a more complex
4674 example that prefetches a CD's artist, its liner notes (if present),
4675 the cover image, the tracks on that CD, and the guests on those
4676 tracks.
4677
4678   my $rs = $schema->resultset('CD')->search(
4679     undef,
4680     {
4681       prefetch => [
4682         { artist => 'record_label'},  # belongs_to => belongs_to
4683         'liner_note',                 # might_have
4684         'cover_image',                # has_one
4685         { tracks => 'guests' },       # has_many => has_many
4686       ]
4687     }
4688   );
4689
4690 This will produce SQL like the following:
4691
4692   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4693          tracks.*, guests.*
4694     FROM cd me
4695     JOIN artist artist
4696       ON artist.artistid = me.artistid
4697     JOIN record_label record_label
4698       ON record_label.labelid = artist.labelid
4699     LEFT JOIN track tracks
4700       ON tracks.cdid = me.cdid
4701     LEFT JOIN guest guests
4702       ON guests.trackid = track.trackid
4703     LEFT JOIN liner_notes liner_note
4704       ON liner_note.cdid = me.cdid
4705     JOIN cd_artwork cover_image
4706       ON cover_image.cdid = me.cdid
4707   ORDER BY tracks.cd
4708
4709 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4710 C<tracks>, and C<guests> of the CD will all be available through the
4711 relationship accessors without the need for additional queries to the
4712 database.
4713
4714 =head3 CAVEATS
4715
4716 Prefetch does a lot of deep magic. As such, it may not behave exactly
4717 as you might expect.
4718
4719 =over 4
4720
4721 =item *
4722
4723 Prefetch uses the L</cache> to populate the prefetched relationships. This
4724 may or may not be what you want.
4725
4726 =item *
4727
4728 If you specify a condition on a prefetched relationship, ONLY those
4729 rows that match the prefetched condition will be fetched into that relationship.
4730 This means that adding prefetch to a search() B<may alter> what is returned by
4731 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4732
4733   my $artist_rs = $schema->resultset('Artist')->search({
4734       'cds.year' => 2008,
4735   }, {
4736       join => 'cds',
4737   });
4738
4739   my $count = $artist_rs->first->cds->count;
4740
4741   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4742
4743   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4744
4745   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4746
4747 That cmp_ok() may or may not pass depending on the datasets involved. In other
4748 words the C<WHERE> condition would apply to the entire dataset, just like
4749 it would in regular SQL. If you want to add a condition only to the "right side"
4750 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4751 condition|DBIx::Class::Relationship::Base/condition>
4752
4753 =back
4754
4755 =head1 DBIC BIND VALUES
4756
4757 Because DBIC may need more information to bind values than just the column name
4758 and value itself, it uses a special format for both passing and receiving bind
4759 values.  Each bind value should be composed of an arrayref of
4760 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4761
4762 =over 4
4763
4764 =item dbd_attrs
4765
4766 If present (in any form), this is what is being passed directly to bind_param.
4767 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4768 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4769
4770 If this is specified, all other bind options described below are ignored.
4771
4772 =item sqlt_datatype
4773
4774 If present, this is used to infer the actual bind attribute by passing to
4775 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4776 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4777
4778 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4779 currently drivers are expected to "Do the Right Thing" when given a common
4780 datatype name.  (Not ideal, but that's what we got at this point.)
4781
4782 =item sqlt_size
4783
4784 Currently used to correctly allocate buffers for bind_param_inout().
4785 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4786 or to a sensible value based on the "data_type".
4787
4788 =item dbic_colname
4789
4790 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4791 explicitly specified they are never overridden).  Also used by some weird DBDs,
4792 where the column name should be available at bind_param time (e.g. Oracle).
4793
4794 =back
4795
4796 For backwards compatibility and convenience, the following shortcuts are
4797 supported:
4798
4799   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4800   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4801   [ undef,   $val ] === [ {}, $val ]
4802   $val              === [ {}, $val ]
4803
4804 =head1 AUTHOR AND CONTRIBUTORS
4805
4806 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4807
4808 =head1 LICENSE
4809
4810 You may distribute this code under the same terms as Perl itself.
4811