lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  23
  24 =head1 SYNOPSIS
  25
  26   my $rs   = $schema->resultset('User')->search({ registered => 1 });
  27   my @rows = $schema->resultset('CD')->search({ year => 2005 })->all();
  28
  29 =head1 DESCRIPTION
  30
  31 The resultset is also known as an iterator. It is responsible for handling
  32 queries that may return an arbitrary number of rows, e.g. via L</search>
  33 or a C<has_many> relationship.
  34
  35 In the examples below, the following table classes are used:
  36
  37   package MyApp::Schema::Artist;
  38   use base qw/DBIx::Class/;
  39   __PACKAGE__->load_components(qw/Core/);
  40   __PACKAGE__->table('artist');
  41   __PACKAGE__->add_columns(qw/artistid name/);
  42   __PACKAGE__->set_primary_key('artistid');
  43   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  44   1;
  45
  46   package MyApp::Schema::CD;
  47   use base qw/DBIx::Class/;
  48   __PACKAGE__->load_components(qw/Core/);
  49   __PACKAGE__->table('cd');
  50   __PACKAGE__->add_columns(qw/cdid artist title year/);
  51   __PACKAGE__->set_primary_key('cdid');
  52   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  53   1;
  54
  55 =head1 OVERLOADING
  56
  57 If a resultset is used in a numeric context it returns the L</count>.
  58 However, if it is used in a booleand context it is always true.  So if
  59 you want to check if a resultset has any results use C<if $rs != 0>.
  60 C<if $rs> will always be true.
  61
  62 =head1 METHODS
  63
  64 =head2 new
  65
  66 =over 4
  67
  68 =item Arguments: $source, \%$attrs
  69
  70 =item Return Value: $rs
  71
  72 =back
  73
  74 The resultset constructor. Takes a source object (usually a
  75 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  76 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  77 executed as needed by the other methods.
  78
  79 Generally you won't need to construct a resultset manually.  You'll
  80 automatically get one from e.g. a L</search> called in scalar context:
  81
  82   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  83
  84 IMPORTANT: If called on an object, proxies to new_result instead so
  85
  86   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  87
  88 will return a CD object, not a ResultSet.
  89
  90 =cut
  91
  92 sub new {
  93   my $class = shift;
  94   return $class->new_result(@_) if ref $class;
  95
  96   my ($source, $attrs) = @_;
  97   $source = $source->handle
  98     unless $source->isa('DBIx::Class::ResultSourceHandle');
  99   $attrs = { %{$attrs||{}} };
 100
 101   if ($attrs->{page}) {
 102     $attrs->{rows} ||= 10;
 103   }
 104
 105   $attrs->{alias} ||= 'me';
 106
 107   # Creation of {} and bless separated to mitigate RH perl bug
 108   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 109   my $self = {
 110     _source_handle => $source,
 111     cond => $attrs->{where},
 112     count => undef,
 113     pager => undef,
 114     attrs => $attrs
 115   };
 116
 117   bless $self, $class;
 118
 119   $self->result_class(
 120     $attrs->{result_class} || $source->resolve->result_class
 121   );
 122
 123   return $self;
 124 }
 125
 126 =head2 search
 127
 128 =over 4
 129
 130 =item Arguments: $cond, \%attrs?
 131
 132 =item Return Value: $resultset (scalar context), @row_objs (list context)
 133
 134 =back
 135
 136   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 137   my $new_rs = $cd_rs->search({ year => 2005 });
 138
 139   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 140                  # year = 2005 OR year = 2004
 141
 142 If you need to pass in additional attributes but no additional condition,
 143 call it as C<search(undef, \%attrs)>.
 144
 145   # "SELECT name, artistid FROM $artist_table"
 146   my @all_artists = $schema->resultset('Artist')->search(undef, {
 147     columns => [qw/name artistid/],
 148   });
 149
 150 For a list of attributes that can be passed to C<search>, see
 151 L</ATTRIBUTES>. For more examples of using this function, see
 152 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 153 documentation for the first argument, see L<SQL::Abstract>.
 154
 155 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 156
 157 =cut
 158
 159 sub search {
 160   my $self = shift;
 161   my $rs = $self->search_rs( @_ );
 162   return (wantarray ? $rs->all : $rs);
 163 }
 164
 165 =head2 search_rs
 166
 167 =over 4
 168
 169 =item Arguments: $cond, \%attrs?
 170
 171 =item Return Value: $resultset
 172
 173 =back
 174
 175 This method does the same exact thing as search() except it will
 176 always return a resultset, even in list context.
 177
 178 =cut
 179
 180 sub search_rs {
 181   my $self = shift;
 182
 183   my $attrs = {};
 184   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 185   my $our_attrs = { %{$self->{attrs}} };
 186   my $having = delete $our_attrs->{having};
 187   my $where = delete $our_attrs->{where};
 188
 189   my $rows;
 190
 191   my %safe = (alias => 1, cache => 1);
 192
 193   unless (
 194     (@_ && defined($_[0])) # @_ == () or (undef)
 195     ||
 196     (keys %$attrs # empty attrs or only 'safe' attrs
 197     && List::Util::first { !$safe{$_} } keys %$attrs)
 198   ) {
 199     # no search, effectively just a clone
 200     $rows = $self->get_cache;
 201   }
 202
 203   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 204
 205   # merge new attrs into inherited
 206   foreach my $key (qw/join prefetch +select +as/) {
 207     next unless exists $attrs->{$key};
 208     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 209   }
 210
 211   my $cond = (@_
 212     ? (
 213         (@_ == 1 || ref $_[0] eq "HASH")
 214           ? (
 215               (ref $_[0] eq 'HASH')
 216                 ? (
 217                     (keys %{ $_[0] }  > 0)
 218                       ? shift
 219                       : undef
 220                    )
 221                 :  shift
 222              )
 223           : (
 224               (@_ % 2)
 225                 ? $self->throw_exception("Odd number of arguments to search")
 226                 : {@_}
 227              )
 228       )
 229     : undef
 230   );
 231
 232   if (defined $where) {
 233     $new_attrs->{where} = (
 234       defined $new_attrs->{where}
 235         ? { '-and' => [
 236               map {
 237                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 238               } $where, $new_attrs->{where}
 239             ]
 240           }
 241         : $where);
 242   }
 243
 244   if (defined $cond) {
 245     $new_attrs->{where} = (
 246       defined $new_attrs->{where}
 247         ? { '-and' => [
 248               map {
 249                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 250               } $cond, $new_attrs->{where}
 251             ]
 252           }
 253         : $cond);
 254   }
 255
 256   if (defined $having) {
 257     $new_attrs->{having} = (
 258       defined $new_attrs->{having}
 259         ? { '-and' => [
 260               map {
 261                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 262               } $having, $new_attrs->{having}
 263             ]
 264           }
 265         : $having);
 266   }
 267
 268   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 269   if ($rows) {
 270     $rs->set_cache($rows);
 271   }
 272   return $rs;
 273 }
 274
 275 =head2 search_literal
 276
 277 =over 4
 278
 279 =item Arguments: $sql_fragment, @bind_values
 280
 281 =item Return Value: $resultset (scalar context), @row_objs (list context)
 282
 283 =back
 284
 285   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 286   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 287
 288 Pass a literal chunk of SQL to be added to the conditional part of the
 289 resultset query.
 290
 291 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 292 only be used in that context. There are known problems using C<search_literal>
 293 in chained queries; it can result in bind values in the wrong order.  See
 294 L<DBIx::Class::Manual::Cookbook/Searching> and
 295 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 296 require C<search_literal>.
 297
 298 =cut
 299
 300 sub search_literal {
 301   my ($self, $cond, @vals) = @_;
 302   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 303   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 304   return $self->search(\$cond, $attrs);
 305 }
 306
 307 =head2 find
 308
 309 =over 4
 310
 311 =item Arguments: @values | \%cols, \%attrs?
 312
 313 =item Return Value: $row_object | undef
 314
 315 =back
 316
 317 Finds a row based on its primary key or unique constraint. For example, to find
 318 a row by its primary key:
 319
 320   my $cd = $schema->resultset('CD')->find(5);
 321
 322 You can also find a row by a specific unique constraint using the C<key>
 323 attribute. For example:
 324
 325   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 326     key => 'cd_artist_title'
 327   });
 328
 329 Additionally, you can specify the columns explicitly by name:
 330
 331   my $cd = $schema->resultset('CD')->find(
 332     {
 333       artist => 'Massive Attack',
 334       title  => 'Mezzanine',
 335     },
 336     { key => 'cd_artist_title' }
 337   );
 338
 339 If the C<key> is specified as C<primary>, it searches only on the primary key.
 340
 341 If no C<key> is specified, it searches on all unique constraints defined on the
 342 source for which column data is provided, including the primary key.
 343
 344 If your table does not have a primary key, you B<must> provide a value for the
 345 C<key> attribute matching one of the unique constraints on the source.
 346
 347 In addition to C<key>, L</find> recognizes and applies standard
 348 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 349
 350 Note: If your query does not return only one row, a warning is generated:
 351
 352   Query returned more than one row
 353
 354 See also L</find_or_create> and L</update_or_create>. For information on how to
 355 declare unique constraints, see
 356 L<DBIx::Class::ResultSource/add_unique_constraint>.
 357
 358 =cut
 359
 360 sub find {
 361   my $self = shift;
 362   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 363
 364   # Default to the primary key, but allow a specific key
 365   my @cols = exists $attrs->{key}
 366     ? $self->result_source->unique_constraint_columns($attrs->{key})
 367     : $self->result_source->primary_columns;
 368   $self->throw_exception(
 369     "Can't find unless a primary key is defined or unique constraint is specified"
 370   ) unless @cols;
 371
 372   # Parse out a hashref from input
 373   my $input_query;
 374   if (ref $_[0] eq 'HASH') {
 375     $input_query = { %{$_[0]} };
 376   }
 377   elsif (@_ == @cols) {
 378     $input_query = {};
 379     @{$input_query}{@cols} = @_;
 380   }
 381   else {
 382     # Compatibility: Allow e.g. find(id => $value)
 383     carp "Find by key => value deprecated; please use a hashref instead";
 384     $input_query = {@_};
 385   }
 386
 387   my (%related, $info);
 388
 389   KEY: foreach my $key (keys %$input_query) {
 390     if (ref($input_query->{$key})
 391         && ($info = $self->result_source->relationship_info($key))) {
 392       my $val = delete $input_query->{$key};
 393       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 394       my $rel_q = $self->result_source->resolve_condition(
 395                     $info->{cond}, $val, $key
 396                   );
 397       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 398       @related{keys %$rel_q} = values %$rel_q;
 399     }
 400   }
 401   if (my @keys = keys %related) {
 402     @{$input_query}{@keys} = values %related;
 403   }
 404
 405
 406   # Build the final query: Default to the disjunction of the unique queries,
 407   # but allow the input query in case the ResultSet defines the query or the
 408   # user is abusing find
 409   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 410   my $query;
 411   if (exists $attrs->{key}) {
 412     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 413     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 414     $query = $self->_add_alias($unique_query, $alias);
 415   }
 416   else {
 417     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 418     $query = @unique_queries
 419       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 420       : $self->_add_alias($input_query, $alias);
 421   }
 422
 423   # Run the query
 424   if (keys %$attrs) {
 425     my $rs = $self->search($query, $attrs);
 426     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 427       my $row = $rs->next;
 428       carp "Query returned more than one row" if $rs->next;
 429       return $row;
 430     }
 431     else {
 432       return $rs->single;
 433     }
 434   }
 435   else {
 436     if (keys %{$self->_resolved_attrs->{collapse}}) {
 437       my $rs = $self->search($query);
 438       my $row = $rs->next;
 439       carp "Query returned more than one row" if $rs->next;
 440       return $row;
 441     }
 442     else {
 443       return $self->single($query);
 444     }
 445   }
 446 }
 447
 448 # _add_alias
 449 #
 450 # Add the specified alias to the specified query hash. A copy is made so the
 451 # original query is not modified.
 452
 453 sub _add_alias {
 454   my ($self, $query, $alias) = @_;
 455
 456   my %aliased = %$query;
 457   foreach my $col (grep { ! m/\./ } keys %aliased) {
 458     $aliased{"$alias.$col"} = delete $aliased{$col};
 459   }
 460
 461   return \%aliased;
 462 }
 463
 464 # _unique_queries
 465 #
 466 # Build a list of queries which satisfy unique constraints.
 467
 468 sub _unique_queries {
 469   my ($self, $query, $attrs) = @_;
 470
 471   my @constraint_names = exists $attrs->{key}
 472     ? ($attrs->{key})
 473     : $self->result_source->unique_constraint_names;
 474
 475   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 476   my $num_where = scalar keys %$where;
 477
 478   my @unique_queries;
 479   foreach my $name (@constraint_names) {
 480     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 481     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 482
 483     my $num_cols = scalar @unique_cols;
 484     my $num_query = scalar keys %$unique_query;
 485
 486     my $total = $num_query + $num_where;
 487     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 488       # The query is either unique on its own or is unique in combination with
 489       # the existing where clause
 490       push @unique_queries, $unique_query;
 491     }
 492   }
 493
 494   return @unique_queries;
 495 }
 496
 497 # _build_unique_query
 498 #
 499 # Constrain the specified query hash based on the specified column names.
 500
 501 sub _build_unique_query {
 502   my ($self, $query, $unique_cols) = @_;
 503
 504   return {
 505     map  { $_ => $query->{$_} }
 506     grep { exists $query->{$_} }
 507       @$unique_cols
 508   };
 509 }
 510
 511 =head2 search_related
 512
 513 =over 4
 514
 515 =item Arguments: $rel, $cond, \%attrs?
 516
 517 =item Return Value: $new_resultset
 518
 519 =back
 520
 521   $new_rs = $cd_rs->search_related('artist', {
 522     name => 'Emo-R-Us',
 523   });
 524
 525 Searches the specified relationship, optionally specifying a condition and
 526 attributes for matching records. See L</ATTRIBUTES> for more information.
 527
 528 =cut
 529
 530 sub search_related {
 531   return shift->related_resultset(shift)->search(@_);
 532 }
 533
 534 =head2 search_related_rs
 535
 536 This method works exactly the same as search_related, except that
 537 it guarantees a restultset, even in list context.
 538
 539 =cut
 540
 541 sub search_related_rs {
 542   return shift->related_resultset(shift)->search_rs(@_);
 543 }
 544
 545 =head2 cursor
 546
 547 =over 4
 548
 549 =item Arguments: none
 550
 551 =item Return Value: $cursor
 552
 553 =back
 554
 555 Returns a storage-driven cursor to the given resultset. See
 556 L<DBIx::Class::Cursor> for more information.
 557
 558 =cut
 559
 560 sub cursor {
 561   my ($self) = @_;
 562
 563   my $attrs = { %{$self->_resolved_attrs} };
 564   return $self->{cursor}
 565     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 566           $attrs->{where},$attrs);
 567 }
 568
 569 =head2 single
 570
 571 =over 4
 572
 573 =item Arguments: $cond?
 574
 575 =item Return Value: $row_object?
 576
 577 =back
 578
 579   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 580
 581 Inflates the first result without creating a cursor if the resultset has
 582 any records in it; if not returns nothing. Used by L</find> as a lean version of
 583 L</search>.
 584
 585 While this method can take an optional search condition (just like L</search>)
 586 being a fast-code-path it does not recognize search attributes. If you need to
 587 add extra joins or similar, call L</search> and then chain-call L</single> on the
 588 L<DBIx::Class::ResultSet> returned.
 589
 590 =over
 591
 592 =item B<Note>
 593
 594 As of 0.08100, this method enforces the assumption that the preceeding
 595 query returns only one row. If more than one row is returned, you will receive
 596 a warning:
 597
 598   Query returned more than one row
 599
 600 In this case, you should be using L</first> or L</find> instead, or if you really
 601 know what you are doing, use the L</rows> attribute to explicitly limit the size
 602 of the resultset.
 603
 604 =back
 605
 606 =cut
 607
 608 sub single {
 609   my ($self, $where) = @_;
 610   my $attrs = { %{$self->_resolved_attrs} };
 611   if ($where) {
 612     if (defined $attrs->{where}) {
 613       $attrs->{where} = {
 614         '-and' =>
 615             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 616                $where, delete $attrs->{where} ]
 617       };
 618     } else {
 619       $attrs->{where} = $where;
 620     }
 621   }
 622
 623 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 624 #  unless ($self->_is_unique_query($attrs->{where})) {
 625 #    carp "Query not guaranteed to return a single row"
 626 #      . "; please declare your unique constraints or use search instead";
 627 #  }
 628
 629   my @data = $self->result_source->storage->select_single(
 630     $attrs->{from}, $attrs->{select},
 631     $attrs->{where}, $attrs
 632   );
 633
 634   return (@data ? ($self->_construct_object(@data))[0] : undef);
 635 }
 636
 637 # _is_unique_query
 638 #
 639 # Try to determine if the specified query is guaranteed to be unique, based on
 640 # the declared unique constraints.
 641
 642 sub _is_unique_query {
 643   my ($self, $query) = @_;
 644
 645   my $collapsed = $self->_collapse_query($query);
 646   my $alias = $self->{attrs}{alias};
 647
 648   foreach my $name ($self->result_source->unique_constraint_names) {
 649     my @unique_cols = map {
 650       "$alias.$_"
 651     } $self->result_source->unique_constraint_columns($name);
 652
 653     # Count the values for each unique column
 654     my %seen = map { $_ => 0 } @unique_cols;
 655
 656     foreach my $key (keys %$collapsed) {
 657       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 658       next unless exists $seen{$aliased};  # Additional constraints are okay
 659       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 660     }
 661
 662     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 663     return 1 unless grep { $_ != 1 } values %seen;
 664   }
 665
 666   return 0;
 667 }
 668
 669 # _collapse_query
 670 #
 671 # Recursively collapse the query, accumulating values for each column.
 672
 673 sub _collapse_query {
 674   my ($self, $query, $collapsed) = @_;
 675
 676   $collapsed ||= {};
 677
 678   if (ref $query eq 'ARRAY') {
 679     foreach my $subquery (@$query) {
 680       next unless ref $subquery;  # -or
 681 #      warn "ARRAY: " . Dumper $subquery;
 682       $collapsed = $self->_collapse_query($subquery, $collapsed);
 683     }
 684   }
 685   elsif (ref $query eq 'HASH') {
 686     if (keys %$query and (keys %$query)[0] eq '-and') {
 687       foreach my $subquery (@{$query->{-and}}) {
 688 #        warn "HASH: " . Dumper $subquery;
 689         $collapsed = $self->_collapse_query($subquery, $collapsed);
 690       }
 691     }
 692     else {
 693 #      warn "LEAF: " . Dumper $query;
 694       foreach my $col (keys %$query) {
 695         my $value = $query->{$col};
 696         $collapsed->{$col}{$value}++;
 697       }
 698     }
 699   }
 700
 701   return $collapsed;
 702 }
 703
 704 =head2 get_column
 705
 706 =over 4
 707
 708 =item Arguments: $cond?
 709
 710 =item Return Value: $resultsetcolumn
 711
 712 =back
 713
 714   my $max_length = $rs->get_column('length')->max;
 715
 716 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 717
 718 =cut
 719
 720 sub get_column {
 721   my ($self, $column) = @_;
 722   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 723   return $new;
 724 }
 725
 726 =head2 search_like
 727
 728 =over 4
 729
 730 =item Arguments: $cond, \%attrs?
 731
 732 =item Return Value: $resultset (scalar context), @row_objs (list context)
 733
 734 =back
 735
 736   # WHERE title LIKE '%blue%'
 737   $cd_rs = $rs->search_like({ title => '%blue%'});
 738
 739 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 740 that this is simply a convenience method. You most likely want to use
 741 L</search> with specific operators.
 742
 743 For more information, see L<DBIx::Class::Manual::Cookbook>.
 744
 745 =cut
 746
 747 sub search_like {
 748   my $class = shift;
 749   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 750   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 751   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 752   return $class->search($query, { %$attrs });
 753 }
 754
 755 =head2 slice
 756
 757 =over 4
 758
 759 =item Arguments: $first, $last
 760
 761 =item Return Value: $resultset (scalar context), @row_objs (list context)
 762
 763 =back
 764
 765 Returns a resultset or object list representing a subset of elements from the
 766 resultset slice is called on. Indexes are from 0, i.e., to get the first
 767 three records, call:
 768
 769   my ($one, $two, $three) = $rs->slice(0, 2);
 770
 771 =cut
 772
 773 sub slice {
 774   my ($self, $min, $max) = @_;
 775   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 776   $attrs->{offset} = $self->{attrs}{offset} || 0;
 777   $attrs->{offset} += $min;
 778   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 779   return $self->search(undef(), $attrs);
 780   #my $slice = (ref $self)->new($self->result_source, $attrs);
 781   #return (wantarray ? $slice->all : $slice);
 782 }
 783
 784 =head2 next
 785
 786 =over 4
 787
 788 =item Arguments: none
 789
 790 =item Return Value: $result?
 791
 792 =back
 793
 794 Returns the next element in the resultset (C<undef> is there is none).
 795
 796 Can be used to efficiently iterate over records in the resultset:
 797
 798   my $rs = $schema->resultset('CD')->search;
 799   while (my $cd = $rs->next) {
 800     print $cd->title;
 801   }
 802
 803 Note that you need to store the resultset object, and call C<next> on it.
 804 Calling C<< resultset('Table')->next >> repeatedly will always return the
 805 first record from the resultset.
 806
 807 =cut
 808
 809 sub next {
 810   my ($self) = @_;
 811   if (my $cache = $self->get_cache) {
 812     $self->{all_cache_position} ||= 0;
 813     return $cache->[$self->{all_cache_position}++];
 814   }
 815   if ($self->{attrs}{cache}) {
 816     $self->{all_cache_position} = 1;
 817     return ($self->all)[0];
 818   }
 819   if ($self->{stashed_objects}) {
 820     my $obj = shift(@{$self->{stashed_objects}});
 821     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 822     return $obj;
 823   }
 824   my @row = (
 825     exists $self->{stashed_row}
 826       ? @{delete $self->{stashed_row}}
 827       : $self->cursor->next
 828   );
 829   return undef unless (@row);
 830   my ($row, @more) = $self->_construct_object(@row);
 831   $self->{stashed_objects} = \@more if @more;
 832   return $row;
 833 }
 834
 835 sub _construct_object {
 836   my ($self, @row) = @_;
 837   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 838   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 839   @new = $self->{_attrs}{record_filter}->(@new)
 840     if exists $self->{_attrs}{record_filter};
 841   return @new;
 842 }
 843
 844 sub _collapse_result {
 845   my ($self, $as_proto, $row) = @_;
 846
 847   my @copy = @$row;
 848
 849   # 'foo'         => [ undef, 'foo' ]
 850   # 'foo.bar'     => [ 'foo', 'bar' ]
 851   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 852
 853   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 854
 855   my %collapse = %{$self->{_attrs}{collapse}||{}};
 856
 857   my @pri_index;
 858
 859   # if we're doing collapsing (has_many prefetch) we need to grab records
 860   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 861   # we know we don't have to bother.
 862
 863   # the reason for not using the collapse stuff directly is because if you
 864   # had for e.g. two artists in a row with no cds, the collapse info for
 865   # both would be NULL (undef) so you'd lose the second artist
 866
 867   # store just the index so we can check the array positions from the row
 868   # without having to contruct the full hash
 869
 870   if (keys %collapse) {
 871     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 872     foreach my $i (0 .. $#construct_as) {
 873       next if defined($construct_as[$i][0]); # only self table
 874       if (delete $pri{$construct_as[$i][1]}) {
 875         push(@pri_index, $i);
 876       }
 877       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 878     }
 879   }
 880
 881   # no need to do an if, it'll be empty if @pri_index is empty anyway
 882
 883   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 884
 885   my @const_rows;
 886
 887   do { # no need to check anything at the front, we always want the first row
 888
 889     my %const;
 890
 891     foreach my $this_as (@construct_as) {
 892       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 893     }
 894
 895     push(@const_rows, \%const);
 896
 897   } until ( # no pri_index => no collapse => drop straight out
 898       !@pri_index
 899     or
 900       do { # get another row, stash it, drop out if different PK
 901
 902         @copy = $self->cursor->next;
 903         $self->{stashed_row} = \@copy;
 904
 905         # last thing in do block, counts as true if anything doesn't match
 906
 907         # check xor defined first for NULL vs. NOT NULL then if one is
 908         # defined the other must be so check string equality
 909
 910         grep {
 911           (defined $pri_vals{$_} ^ defined $copy[$_])
 912           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 913         } @pri_index;
 914       }
 915   );
 916
 917   my $alias = $self->{attrs}{alias};
 918   my $info = [];
 919
 920   my %collapse_pos;
 921
 922   my @const_keys;
 923
 924   foreach my $const (@const_rows) {
 925     scalar @const_keys or do {
 926       @const_keys = sort { length($a) <=> length($b) } keys %$const;
 927     };
 928     foreach my $key (@const_keys) {
 929       if (length $key) {
 930         my $target = $info;
 931         my @parts = split(/\./, $key);
 932         my $cur = '';
 933         my $data = $const->{$key};
 934         foreach my $p (@parts) {
 935           $target = $target->[1]->{$p} ||= [];
 936           $cur .= ".${p}";
 937           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
 938             # collapsing at this point and on final part
 939             my $pos = $collapse_pos{$cur};
 940             CK: foreach my $ck (@ckey) {
 941               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
 942                 $collapse_pos{$cur} = $data;
 943                 delete @collapse_pos{ # clear all positioning for sub-entries
 944                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
 945                 };
 946                 push(@$target, []);
 947                 last CK;
 948               }
 949             }
 950           }
 951           if (exists $collapse{$cur}) {
 952             $target = $target->[-1];
 953           }
 954         }
 955         $target->[0] = $data;
 956       } else {
 957         $info->[0] = $const->{$key};
 958       }
 959     }
 960   }
 961
 962   return $info;
 963 }
 964
 965 =head2 result_source
 966
 967 =over 4
 968
 969 =item Arguments: $result_source?
 970
 971 =item Return Value: $result_source
 972
 973 =back
 974
 975 An accessor for the primary ResultSource object from which this ResultSet
 976 is derived.
 977
 978 =head2 result_class
 979
 980 =over 4
 981
 982 =item Arguments: $result_class?
 983
 984 =item Return Value: $result_class
 985
 986 =back
 987
 988 An accessor for the class to use when creating row objects. Defaults to
 989 C<< result_source->result_class >> - which in most cases is the name of the
 990 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
 991
 992 =cut
 993
 994 sub result_class {
 995   my ($self, $result_class) = @_;
 996   if ($result_class) {
 997     $self->ensure_class_loaded($result_class);
 998     $self->_result_class($result_class);
 999   }
1000   $self->_result_class;
1001 }
1002
1003 =head2 count
1004
1005 =over 4
1006
1007 =item Arguments: $cond, \%attrs??
1008
1009 =item Return Value: $count
1010
1011 =back
1012
1013 Performs an SQL C<COUNT> with the same query as the resultset was built
1014 with to find the number of elements. If passed arguments, does a search
1015 on the resultset and counts the results of that.
1016
1017 Note: When using C<count> with C<group_by>, L<DBIx::Class> emulates C<GROUP BY>
1018 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
1019 not support C<DISTINCT> with multiple columns. If you are using such a
1020 database, you should only use columns from the main table in your C<group_by>
1021 clause.
1022
1023 =cut
1024
1025 sub count {
1026   my $self = shift;
1027   return $self->search(@_)->count if @_ and defined $_[0];
1028   return scalar @{ $self->get_cache } if $self->get_cache;
1029   my $count = $self->_count;
1030   return 0 unless $count;
1031
1032   # need to take offset from resolved attrs
1033
1034   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1035   $count = $self->{attrs}{rows} if
1036     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1037   $count = 0 if ($count < 0);
1038   return $count;
1039 }
1040
1041 sub _count { # Separated out so pager can get the full count
1042   my $self = shift;
1043   my $select = { count => '*' };
1044
1045   my $attrs = { %{$self->_resolved_attrs} };
1046   if (my $group_by = delete $attrs->{group_by}) {
1047     delete $attrs->{having};
1048     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
1049     # todo: try CONCAT for multi-column pk
1050     my @pk = $self->result_source->primary_columns;
1051     if (@pk == 1) {
1052       my $alias = $attrs->{alias};
1053       foreach my $column (@distinct) {
1054         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
1055           @distinct = ($column);
1056           last;
1057         }
1058       }
1059     }
1060
1061     $select = { count => { distinct => \@distinct } };
1062   }
1063
1064   $attrs->{select} = $select;
1065   $attrs->{as} = [qw/count/];
1066
1067   # offset, order by and page are not needed to count. record_filter is cdbi
1068   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
1069
1070   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1071   my ($count) = $tmp_rs->cursor->next;
1072   return $count;
1073 }
1074
1075 sub _bool {
1076   return 1;
1077 }
1078
1079 =head2 count_literal
1080
1081 =over 4
1082
1083 =item Arguments: $sql_fragment, @bind_values
1084
1085 =item Return Value: $count
1086
1087 =back
1088
1089 Counts the results in a literal query. Equivalent to calling L</search_literal>
1090 with the passed arguments, then L</count>.
1091
1092 =cut
1093
1094 sub count_literal { shift->search_literal(@_)->count; }
1095
1096 =head2 all
1097
1098 =over 4
1099
1100 =item Arguments: none
1101
1102 =item Return Value: @objects
1103
1104 =back
1105
1106 Returns all elements in the resultset. Called implicitly if the resultset
1107 is returned in list context.
1108
1109 =cut
1110
1111 sub all {
1112   my ($self) = @_;
1113   return @{ $self->get_cache } if $self->get_cache;
1114
1115   my @obj;
1116
1117   # TODO: don't call resolve here
1118   if (keys %{$self->_resolved_attrs->{collapse}}) {
1119 #  if ($self->{attrs}{prefetch}) {
1120       # Using $self->cursor->all is really just an optimisation.
1121       # If we're collapsing has_many prefetches it probably makes
1122       # very little difference, and this is cleaner than hacking
1123       # _construct_object to survive the approach
1124     my @row = $self->cursor->next;
1125     while (@row) {
1126       push(@obj, $self->_construct_object(@row));
1127       @row = (exists $self->{stashed_row}
1128                ? @{delete $self->{stashed_row}}
1129                : $self->cursor->next);
1130     }
1131   } else {
1132     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1133   }
1134
1135   $self->set_cache(\@obj) if $self->{attrs}{cache};
1136   return @obj;
1137 }
1138
1139 =head2 reset
1140
1141 =over 4
1142
1143 =item Arguments: none
1144
1145 =item Return Value: $self
1146
1147 =back
1148
1149 Resets the resultset's cursor, so you can iterate through the elements again.
1150
1151 =cut
1152
1153 sub reset {
1154   my ($self) = @_;
1155   delete $self->{_attrs} if exists $self->{_attrs};
1156   $self->{all_cache_position} = 0;
1157   $self->cursor->reset;
1158   return $self;
1159 }
1160
1161 =head2 first
1162
1163 =over 4
1164
1165 =item Arguments: none
1166
1167 =item Return Value: $object?
1168
1169 =back
1170
1171 Resets the resultset and returns an object for the first result (if the
1172 resultset returns anything).
1173
1174 =cut
1175
1176 sub first {
1177   return $_[0]->reset->next;
1178 }
1179
1180 # _cond_for_update_delete
1181 #
1182 # update/delete require the condition to be modified to handle
1183 # the differing SQL syntax available.  This transforms the $self->{cond}
1184 # appropriately, returning the new condition.
1185
1186 sub _cond_for_update_delete {
1187   my ($self, $full_cond) = @_;
1188   my $cond = {};
1189
1190   $full_cond ||= $self->{cond};
1191   # No-op. No condition, we're updating/deleting everything
1192   return $cond unless ref $full_cond;
1193
1194   if (ref $full_cond eq 'ARRAY') {
1195     $cond = [
1196       map {
1197         my %hash;
1198         foreach my $key (keys %{$_}) {
1199           $key =~ /([^.]+)$/;
1200           $hash{$1} = $_->{$key};
1201         }
1202         \%hash;
1203       } @{$full_cond}
1204     ];
1205   }
1206   elsif (ref $full_cond eq 'HASH') {
1207     if ((keys %{$full_cond})[0] eq '-and') {
1208       $cond->{-and} = [];
1209
1210       my @cond = @{$full_cond->{-and}};
1211       for (my $i = 0; $i < @cond; $i++) {
1212         my $entry = $cond[$i];
1213
1214         my $hash;
1215         if (ref $entry eq 'HASH') {
1216           $hash = $self->_cond_for_update_delete($entry);
1217         }
1218         else {
1219           $entry =~ /([^.]+)$/;
1220           $hash->{$1} = $cond[++$i];
1221         }
1222
1223         push @{$cond->{-and}}, $hash;
1224       }
1225     }
1226     else {
1227       foreach my $key (keys %{$full_cond}) {
1228         $key =~ /([^.]+)$/;
1229         $cond->{$1} = $full_cond->{$key};
1230       }
1231     }
1232   }
1233   else {
1234     $self->throw_exception(
1235       "Can't update/delete on resultset with condition unless hash or array"
1236     );
1237   }
1238
1239   return $cond;
1240 }
1241
1242
1243 =head2 update
1244
1245 =over 4
1246
1247 =item Arguments: \%values
1248
1249 =item Return Value: $storage_rv
1250
1251 =back
1252
1253 Sets the specified columns in the resultset to the supplied values in a
1254 single query. Return value will be true if the update succeeded or false
1255 if no records were updated; exact type of success value is storage-dependent.
1256
1257 =cut
1258
1259 sub update {
1260   my ($self, $values) = @_;
1261   $self->throw_exception("Values for update must be a hash")
1262     unless ref $values eq 'HASH';
1263
1264   my $cond = $self->_cond_for_update_delete;
1265
1266   return $self->result_source->storage->update(
1267     $self->result_source, $values, $cond
1268   );
1269 }
1270
1271 =head2 update_all
1272
1273 =over 4
1274
1275 =item Arguments: \%values
1276
1277 =item Return Value: 1
1278
1279 =back
1280
1281 Fetches all objects and updates them one at a time. Note that C<update_all>
1282 will run DBIC cascade triggers, while L</update> will not.
1283
1284 =cut
1285
1286 sub update_all {
1287   my ($self, $values) = @_;
1288   $self->throw_exception("Values for update must be a hash")
1289     unless ref $values eq 'HASH';
1290   foreach my $obj ($self->all) {
1291     $obj->set_columns($values)->update;
1292   }
1293   return 1;
1294 }
1295
1296 =head2 delete
1297
1298 =over 4
1299
1300 =item Arguments: none
1301
1302 =item Return Value: 1
1303
1304 =back
1305
1306 Deletes the contents of the resultset from its result source. Note that this
1307 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1308 to run. See also L<DBIx::Class::Row/delete>.
1309
1310 delete may not generate correct SQL for a query with joins or a resultset
1311 chained from a related resultset.  In this case it will generate a warning:-
1312
1313   WARNING! Currently $rs->delete() does not generate proper SQL on
1314   joined resultsets, and may delete rows well outside of the contents
1315   of $rs. Use at your own risk
1316
1317 In these cases you may find that delete_all is more appropriate, or you
1318 need to respecify your query in a way that can be expressed without a join.
1319
1320 =cut
1321
1322 sub delete {
1323   my ($self) = @_;
1324   $self->throw_exception("Delete should not be passed any arguments")
1325     if $_[1];
1326   carp(   'WARNING! Currently $rs->delete() does not generate proper SQL'
1327         . ' on joined resultsets, and may delete rows well outside of the'
1328         . ' contents of $rs. Use at your own risk' )
1329     if ( $self->{attrs}{seen_join} );
1330   my $cond = $self->_cond_for_update_delete;
1331
1332   $self->result_source->storage->delete($self->result_source, $cond);
1333   return 1;
1334 }
1335
1336 =head2 delete_all
1337
1338 =over 4
1339
1340 =item Arguments: none
1341
1342 =item Return Value: 1
1343
1344 =back
1345
1346 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1347 will run DBIC cascade triggers, while L</delete> will not.
1348
1349 =cut
1350
1351 sub delete_all {
1352   my ($self) = @_;
1353   $_->delete for $self->all;
1354   return 1;
1355 }
1356
1357 =head2 populate
1358
1359 =over 4
1360
1361 =item Arguments: \@data;
1362
1363 =back
1364
1365 Pass an arrayref of hashrefs. Each hashref should be a structure suitable for
1366 submitting to a $resultset->create(...) method.
1367
1368 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1369 to insert the data, as this is a faster method.
1370
1371 Otherwise, each set of data is inserted into the database using
1372 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1373 objects is returned.
1374
1375 Example:  Assuming an Artist Class that has many CDs Classes relating:
1376
1377   my $Artist_rs = $schema->resultset("Artist");
1378
1379   ## Void Context Example
1380   $Artist_rs->populate([
1381      { artistid => 4, name => 'Manufactured Crap', cds => [
1382         { title => 'My First CD', year => 2006 },
1383         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1384       ],
1385      },
1386      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1387         { title => 'My parents sold me to a record company' ,year => 2005 },
1388         { title => 'Why Am I So Ugly?', year => 2006 },
1389         { title => 'I Got Surgery and am now Popular', year => 2007 }
1390       ],
1391      },
1392   ]);
1393
1394   ## Array Context Example
1395   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1396     { name => "Artist One"},
1397     { name => "Artist Two"},
1398     { name => "Artist Three", cds=> [
1399     { title => "First CD", year => 2007},
1400     { title => "Second CD", year => 2008},
1401   ]}
1402   ]);
1403
1404   print $ArtistOne->name; ## response is 'Artist One'
1405   print $ArtistThree->cds->count ## reponse is '2'
1406
1407 Please note an important effect on your data when choosing between void and
1408 wantarray context. Since void context goes straight to C<insert_bulk> in
1409 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1410 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1411 create primary keys for you, you will find that your PKs are empty.  In this
1412 case you will have to use the wantarray context in order to create those
1413 values.
1414
1415 =cut
1416
1417 sub populate {
1418   my ($self, $data) = @_;
1419
1420   if(defined wantarray) {
1421     my @created;
1422     foreach my $item (@$data) {
1423       push(@created, $self->create($item));
1424     }
1425     return @created;
1426   } else {
1427     my ($first, @rest) = @$data;
1428
1429     my @names = grep {!ref $first->{$_}} keys %$first;
1430     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1431     my @pks = $self->result_source->primary_columns;
1432
1433     ## do the belongs_to relationships
1434     foreach my $index (0..$#$data) {
1435       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1436         my @ret = $self->populate($data);
1437         return;
1438       }
1439
1440       foreach my $rel (@rels) {
1441         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1442         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1443         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1444         my $related = $result->result_source->resolve_condition(
1445           $result->result_source->relationship_info($reverse)->{cond},
1446           $self,
1447           $result,
1448         );
1449
1450         delete $data->[$index]->{$rel};
1451         $data->[$index] = {%{$data->[$index]}, %$related};
1452
1453         push @names, keys %$related if $index == 0;
1454       }
1455     }
1456
1457     ## do bulk insert on current row
1458     my @values = map { [ @$_{@names} ] } @$data;
1459
1460     $self->result_source->storage->insert_bulk(
1461       $self->result_source,
1462       \@names,
1463       \@values,
1464     );
1465
1466     ## do the has_many relationships
1467     foreach my $item (@$data) {
1468
1469       foreach my $rel (@rels) {
1470         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1471
1472         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1473      || $self->throw_exception('Cannot find the relating object.');
1474
1475         my $child = $parent->$rel;
1476
1477         my $related = $child->result_source->resolve_condition(
1478           $parent->result_source->relationship_info($rel)->{cond},
1479           $child,
1480           $parent,
1481         );
1482
1483         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1484         my @populate = map { {%$_, %$related} } @rows_to_add;
1485
1486         $child->populate( \@populate );
1487       }
1488     }
1489   }
1490 }
1491
1492 =head2 pager
1493
1494 =over 4
1495
1496 =item Arguments: none
1497
1498 =item Return Value: $pager
1499
1500 =back
1501
1502 Return Value a L<Data::Page> object for the current resultset. Only makes
1503 sense for queries with a C<page> attribute.
1504
1505 =cut
1506
1507 sub pager {
1508   my ($self) = @_;
1509   my $attrs = $self->{attrs};
1510   $self->throw_exception("Can't create pager for non-paged rs")
1511     unless $self->{attrs}{page};
1512   $attrs->{rows} ||= 10;
1513   return $self->{pager} ||= Data::Page->new(
1514     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1515 }
1516
1517 =head2 page
1518
1519 =over 4
1520
1521 =item Arguments: $page_number
1522
1523 =item Return Value: $rs
1524
1525 =back
1526
1527 Returns a resultset for the $page_number page of the resultset on which page
1528 is called, where each page contains a number of rows equal to the 'rows'
1529 attribute set on the resultset (10 by default).
1530
1531 =cut
1532
1533 sub page {
1534   my ($self, $page) = @_;
1535   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1536 }
1537
1538 =head2 new_result
1539
1540 =over 4
1541
1542 =item Arguments: \%vals
1543
1544 =item Return Value: $rowobject
1545
1546 =back
1547
1548 Creates a new row object in the resultset's result class and returns
1549 it. The row is not inserted into the database at this point, call
1550 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1551 will tell you whether the row object has been inserted or not.
1552
1553 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1554
1555 =cut
1556
1557 sub new_result {
1558   my ($self, $values) = @_;
1559   $self->throw_exception( "new_result needs a hash" )
1560     unless (ref $values eq 'HASH');
1561
1562   my %new;
1563   my $alias = $self->{attrs}{alias};
1564
1565   if (
1566     defined $self->{cond}
1567     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1568   ) {
1569     %new = %{$self->{attrs}{related_objects}};
1570   } else {
1571     $self->throw_exception(
1572       "Can't abstract implicit construct, condition not a hash"
1573     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1574
1575     my $collapsed_cond = (
1576       $self->{cond}
1577         ? $self->_collapse_cond($self->{cond})
1578         : {}
1579     );
1580
1581     # precendence must be given to passed values over values inherited from
1582     # the cond, so the order here is important.
1583     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1584     while( my($col,$value) = each %implied ){
1585       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1586         $new{$col} = $value->{'='};
1587         next;
1588       }
1589       $new{$col} = $value if $self->_is_deterministic_value($value);
1590     }
1591   }
1592
1593   %new = (
1594     %new,
1595     %{ $self->_remove_alias($values, $alias) },
1596     -source_handle => $self->_source_handle,
1597     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1598   );
1599
1600   return $self->result_class->new(\%new);
1601 }
1602
1603 # _is_deterministic_value
1604 #
1605 # Make an effor to strip non-deterministic values from the condition,
1606 # to make sure new_result chokes less
1607
1608 sub _is_deterministic_value {
1609   my $self = shift;
1610   my $value = shift;
1611   my $ref_type = ref $value;
1612   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1613   return 1 if Scalar::Util::blessed($value);
1614   return 0;
1615 }
1616
1617 # _collapse_cond
1618 #
1619 # Recursively collapse the condition.
1620
1621 sub _collapse_cond {
1622   my ($self, $cond, $collapsed) = @_;
1623
1624   $collapsed ||= {};
1625
1626   if (ref $cond eq 'ARRAY') {
1627     foreach my $subcond (@$cond) {
1628       next unless ref $subcond;  # -or
1629 #      warn "ARRAY: " . Dumper $subcond;
1630       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1631     }
1632   }
1633   elsif (ref $cond eq 'HASH') {
1634     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1635       foreach my $subcond (@{$cond->{-and}}) {
1636 #        warn "HASH: " . Dumper $subcond;
1637         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1638       }
1639     }
1640     else {
1641 #      warn "LEAF: " . Dumper $cond;
1642       foreach my $col (keys %$cond) {
1643         my $value = $cond->{$col};
1644         $collapsed->{$col} = $value;
1645       }
1646     }
1647   }
1648
1649   return $collapsed;
1650 }
1651
1652 # _remove_alias
1653 #
1654 # Remove the specified alias from the specified query hash. A copy is made so
1655 # the original query is not modified.
1656
1657 sub _remove_alias {
1658   my ($self, $query, $alias) = @_;
1659
1660   my %orig = %{ $query || {} };
1661   my %unaliased;
1662
1663   foreach my $key (keys %orig) {
1664     if ($key !~ /\./) {
1665       $unaliased{$key} = $orig{$key};
1666       next;
1667     }
1668     $unaliased{$1} = $orig{$key}
1669       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1670   }
1671
1672   return \%unaliased;
1673 }
1674
1675 =head2 find_or_new
1676
1677 =over 4
1678
1679 =item Arguments: \%vals, \%attrs?
1680
1681 =item Return Value: $rowobject
1682
1683 =back
1684
1685   my $artist = $schema->resultset('Artist')->find_or_new(
1686     { artist => 'fred' }, { key => 'artists' });
1687
1688   $cd->cd_to_producer->find_or_new({ producer => $producer },
1689                                    { key => 'primary });
1690
1691 Find an existing record from this resultset, based on it's primary
1692 key, or a unique constraint. If none exists, instantiate a new result
1693 object and return it. The object will not be saved into your storage
1694 until you call L<DBIx::Class::Row/insert> on it.
1695
1696 You most likely want this method when looking for existing rows using
1697 a unique constraint that is not the primary key, or looking for
1698 related rows.
1699
1700 If you want objects to be saved immediately, use L</find_or_create> instead.
1701
1702 B<Note>: C<find_or_new> is probably not what you want when creating a
1703 new row in a table that uses primary keys supplied by the
1704 database. Passing in a primary key column with a value of I<undef>
1705 will cause L</find> to attempt to search for a row with a value of
1706 I<NULL>.
1707
1708 =cut
1709
1710 sub find_or_new {
1711   my $self     = shift;
1712   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1713   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1714   my $exists   = $self->find($hash, $attrs);
1715   return defined $exists ? $exists : $self->new_result($hash);
1716 }
1717
1718 =head2 create
1719
1720 =over 4
1721
1722 =item Arguments: \%vals
1723
1724 =item Return Value: a L<DBIx::Class::Row> $object
1725
1726 =back
1727
1728 Attempt to create a single new row or a row with multiple related rows
1729 in the table represented by the resultset (and related tables). This
1730 will not check for duplicate rows before inserting, use
1731 L</find_or_create> to do that.
1732
1733 To create one row for this resultset, pass a hashref of key/value
1734 pairs representing the columns of the table and the values you wish to
1735 store. If the appropriate relationships are set up, foreign key fields
1736 can also be passed an object representing the foreign row, and the
1737 value will be set to it's primary key.
1738
1739 To create related objects, pass a hashref for the value if the related
1740 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1741 and use the name of the relationship as the key. (NOT the name of the field,
1742 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1743 of hashrefs containing the data for each of the rows to create in the foreign
1744 tables, again using the relationship name as the key.
1745
1746 Instead of hashrefs of plain related data (key/value pairs), you may
1747 also pass new or inserted objects. New objects (not inserted yet, see
1748 L</new>), will be inserted into their appropriate tables.
1749
1750 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1751
1752 Example of creating a new row.
1753
1754   $person_rs->create({
1755     name=>"Some Person",
1756         email=>"somebody@someplace.com"
1757   });
1758
1759 Example of creating a new row and also creating rows in a related C<has_many>
1760 or C<has_one> resultset.  Note Arrayref.
1761
1762   $artist_rs->create(
1763      { artistid => 4, name => 'Manufactured Crap', cds => [
1764         { title => 'My First CD', year => 2006 },
1765         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1766       ],
1767      },
1768   );
1769
1770 Example of creating a new row and also creating a row in a related
1771 C<belongs_to>resultset. Note Hashref.
1772
1773   $cd_rs->create({
1774     title=>"Music for Silly Walks",
1775         year=>2000,
1776         artist => {
1777           name=>"Silly Musician",
1778         }
1779   });
1780
1781 =cut
1782
1783 sub create {
1784   my ($self, $attrs) = @_;
1785   $self->throw_exception( "create needs a hashref" )
1786     unless ref $attrs eq 'HASH';
1787   return $self->new_result($attrs)->insert;
1788 }
1789
1790 =head2 find_or_create
1791
1792 =over 4
1793
1794 =item Arguments: \%vals, \%attrs?
1795
1796 =item Return Value: $rowobject
1797
1798 =back
1799
1800   $cd->cd_to_producer->find_or_create({ producer => $producer },
1801                                       { key => 'primary });
1802
1803 Tries to find a record based on its primary key or unique constraints; if none
1804 is found, creates one and returns that instead.
1805
1806   my $cd = $schema->resultset('CD')->find_or_create({
1807     cdid   => 5,
1808     artist => 'Massive Attack',
1809     title  => 'Mezzanine',
1810     year   => 2005,
1811   });
1812
1813 Also takes an optional C<key> attribute, to search by a specific key or unique
1814 constraint. For example:
1815
1816   my $cd = $schema->resultset('CD')->find_or_create(
1817     {
1818       artist => 'Massive Attack',
1819       title  => 'Mezzanine',
1820     },
1821     { key => 'cd_artist_title' }
1822   );
1823
1824 B<Note>: Because find_or_create() reads from the database and then
1825 possibly inserts based on the result, this method is subject to a race
1826 condition. Another process could create a record in the table after
1827 the find has completed and before the create has started. To avoid
1828 this problem, use find_or_create() inside a transaction.
1829
1830 B<Note>: C<find_or_create> is probably not what you want when creating
1831 a new row in a table that uses primary keys supplied by the
1832 database. Passing in a primary key column with a value of I<undef>
1833 will cause L</find> to attempt to search for a row with a value of
1834 I<NULL>.
1835
1836 See also L</find> and L</update_or_create>. For information on how to declare
1837 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1838
1839 =cut
1840
1841 sub find_or_create {
1842   my $self     = shift;
1843   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1844   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1845   my $exists   = $self->find($hash, $attrs);
1846   return defined $exists ? $exists : $self->create($hash);
1847 }
1848
1849 =head2 update_or_create
1850
1851 =over 4
1852
1853 =item Arguments: \%col_values, { key => $unique_constraint }?
1854
1855 =item Return Value: $rowobject
1856
1857 =back
1858
1859   $resultset->update_or_create({ col => $val, ... });
1860
1861 First, searches for an existing row matching one of the unique constraints
1862 (including the primary key) on the source of this resultset. If a row is
1863 found, updates it with the other given column values. Otherwise, creates a new
1864 row.
1865
1866 Takes an optional C<key> attribute to search on a specific unique constraint.
1867 For example:
1868
1869   # In your application
1870   my $cd = $schema->resultset('CD')->update_or_create(
1871     {
1872       artist => 'Massive Attack',
1873       title  => 'Mezzanine',
1874       year   => 1998,
1875     },
1876     { key => 'cd_artist_title' }
1877   );
1878
1879   $cd->cd_to_producer->update_or_create({
1880     producer => $producer,
1881     name => 'harry',
1882   }, {
1883     key => 'primary,
1884   });
1885
1886
1887 If no C<key> is specified, it searches on all unique constraints defined on the
1888 source, including the primary key.
1889
1890 If the C<key> is specified as C<primary>, it searches only on the primary key.
1891
1892 See also L</find> and L</find_or_create>. For information on how to declare
1893 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1894
1895 B<Note>: C<update_or_create> is probably not what you want when
1896 looking for a row in a table that uses primary keys supplied by the
1897 database, unless you actually have a key value. Passing in a primary
1898 key column with a value of I<undef> will cause L</find> to attempt to
1899 search for a row with a value of I<NULL>.
1900
1901 =cut
1902
1903 sub update_or_create {
1904   my $self = shift;
1905   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1906   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
1907
1908   my $row = $self->find($cond, $attrs);
1909   if (defined $row) {
1910     $row->update($cond);
1911     return $row;
1912   }
1913
1914   return $self->create($cond);
1915 }
1916
1917 =head2 get_cache
1918
1919 =over 4
1920
1921 =item Arguments: none
1922
1923 =item Return Value: \@cache_objects?
1924
1925 =back
1926
1927 Gets the contents of the cache for the resultset, if the cache is set.
1928
1929 The cache is populated either by using the L</prefetch> attribute to
1930 L</search> or by calling L</set_cache>.
1931
1932 =cut
1933
1934 sub get_cache {
1935   shift->{all_cache};
1936 }
1937
1938 =head2 set_cache
1939
1940 =over 4
1941
1942 =item Arguments: \@cache_objects
1943
1944 =item Return Value: \@cache_objects
1945
1946 =back
1947
1948 Sets the contents of the cache for the resultset. Expects an arrayref
1949 of objects of the same class as those produced by the resultset. Note that
1950 if the cache is set the resultset will return the cached objects rather
1951 than re-querying the database even if the cache attr is not set.
1952
1953 The contents of the cache can also be populated by using the
1954 L</prefetch> attribute to L</search>.
1955
1956 =cut
1957
1958 sub set_cache {
1959   my ( $self, $data ) = @_;
1960   $self->throw_exception("set_cache requires an arrayref")
1961       if defined($data) && (ref $data ne 'ARRAY');
1962   $self->{all_cache} = $data;
1963 }
1964
1965 =head2 clear_cache
1966
1967 =over 4
1968
1969 =item Arguments: none
1970
1971 =item Return Value: []
1972
1973 =back
1974
1975 Clears the cache for the resultset.
1976
1977 =cut
1978
1979 sub clear_cache {
1980   shift->set_cache(undef);
1981 }
1982
1983 =head2 related_resultset
1984
1985 =over 4
1986
1987 =item Arguments: $relationship_name
1988
1989 =item Return Value: $resultset
1990
1991 =back
1992
1993 Returns a related resultset for the supplied relationship name.
1994
1995   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1996
1997 =cut
1998
1999 sub related_resultset {
2000   my ($self, $rel) = @_;
2001
2002   $self->{related_resultsets} ||= {};
2003   return $self->{related_resultsets}{$rel} ||= do {
2004     my $rel_obj = $self->result_source->relationship_info($rel);
2005
2006     $self->throw_exception(
2007       "search_related: result source '" . $self->result_source->source_name .
2008         "' has no such relationship $rel")
2009       unless $rel_obj;
2010
2011     my ($from,$seen) = $self->_resolve_from($rel);
2012
2013     my $join_count = $seen->{$rel};
2014     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2015
2016     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2017     my %attrs = %{$self->{attrs}||{}};
2018     delete @attrs{qw(result_class alias)};
2019
2020     my $new_cache;
2021
2022     if (my $cache = $self->get_cache) {
2023       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2024         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2025                         @$cache ];
2026       }
2027     }
2028
2029     my $rel_source = $self->result_source->related_source($rel);
2030
2031     my $new = do {
2032
2033       # The reason we do this now instead of passing the alias to the
2034       # search_rs below is that if you wrap/overload resultset on the
2035       # source you need to know what alias it's -going- to have for things
2036       # to work sanely (e.g. RestrictWithObject wants to be able to add
2037       # extra query restrictions, and these may need to be $alias.)
2038
2039       my $attrs = $rel_source->resultset_attributes;
2040       local $attrs->{alias} = $alias;
2041
2042       $rel_source->resultset
2043                  ->search_rs(
2044                      undef, {
2045                        %attrs,
2046                        join => undef,
2047                        prefetch => undef,
2048                        select => undef,
2049                        as => undef,
2050                        where => $self->{cond},
2051                        seen_join => $seen,
2052                        from => $from,
2053                    });
2054     };
2055     $new->set_cache($new_cache) if $new_cache;
2056     $new;
2057   };
2058 }
2059
2060 sub _resolve_from {
2061   my ($self, $extra_join) = @_;
2062   my $source = $self->result_source;
2063   my $attrs = $self->{attrs};
2064
2065   my $from = $attrs->{from}
2066     || [ { $attrs->{alias} => $source->from } ];
2067
2068   my $seen = { %{$attrs->{seen_join}||{}} };
2069
2070   my $join = ($attrs->{join}
2071                ? [ $attrs->{join}, $extra_join ]
2072                : $extra_join);
2073
2074   # we need to take the prefetch the attrs into account before we
2075   # ->resolve_join as otherwise they get lost - captainL
2076   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2077
2078   $from = [
2079     @$from,
2080     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2081   ];
2082
2083   return ($from,$seen);
2084 }
2085
2086 sub _resolved_attrs {
2087   my $self = shift;
2088   return $self->{_attrs} if $self->{_attrs};
2089
2090   my $attrs = { %{$self->{attrs}||{}} };
2091   my $source = $self->result_source;
2092   my $alias = $attrs->{alias};
2093
2094   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2095   if ($attrs->{columns}) {
2096     delete $attrs->{as};
2097   } elsif (!$attrs->{select}) {
2098     $attrs->{columns} = [ $source->columns ];
2099   }
2100
2101   $attrs->{select} =
2102     ($attrs->{select}
2103       ? (ref $attrs->{select} eq 'ARRAY'
2104           ? [ @{$attrs->{select}} ]
2105           : [ $attrs->{select} ])
2106       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
2107     );
2108   $attrs->{as} =
2109     ($attrs->{as}
2110       ? (ref $attrs->{as} eq 'ARRAY'
2111           ? [ @{$attrs->{as}} ]
2112           : [ $attrs->{as} ])
2113       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
2114     );
2115
2116   my $adds;
2117   if ($adds = delete $attrs->{include_columns}) {
2118     $adds = [$adds] unless ref $adds eq 'ARRAY';
2119     push(@{$attrs->{select}}, @$adds);
2120     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
2121   }
2122   if ($adds = delete $attrs->{'+select'}) {
2123     $adds = [$adds] unless ref $adds eq 'ARRAY';
2124     push(@{$attrs->{select}},
2125            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
2126   }
2127   if (my $adds = delete $attrs->{'+as'}) {
2128     $adds = [$adds] unless ref $adds eq 'ARRAY';
2129     push(@{$attrs->{as}}, @$adds);
2130   }
2131
2132   $attrs->{from} ||= [ { 'me' => $source->from } ];
2133
2134   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
2135     my $join = delete $attrs->{join} || {};
2136
2137     if (defined $attrs->{prefetch}) {
2138       $join = $self->_merge_attr(
2139         $join, $attrs->{prefetch}
2140       );
2141
2142     }
2143
2144     $attrs->{from} =   # have to copy here to avoid corrupting the original
2145       [
2146         @{$attrs->{from}},
2147         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
2148       ];
2149
2150   }
2151
2152   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
2153   if ($attrs->{order_by}) {
2154     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
2155                            ? [ @{$attrs->{order_by}} ]
2156                            : [ $attrs->{order_by} ]);
2157   } else {
2158     $attrs->{order_by} = [];
2159   }
2160
2161   my $collapse = $attrs->{collapse} || {};
2162   if (my $prefetch = delete $attrs->{prefetch}) {
2163     $prefetch = $self->_merge_attr({}, $prefetch);
2164     my @pre_order;
2165     my $seen = $attrs->{seen_join} || {};
2166     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
2167       # bring joins back to level of current class
2168       my @prefetch = $source->resolve_prefetch(
2169         $p, $alias, $seen, \@pre_order, $collapse
2170       );
2171       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
2172       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
2173     }
2174     push(@{$attrs->{order_by}}, @pre_order);
2175   }
2176   $attrs->{collapse} = $collapse;
2177
2178   if ($attrs->{page}) {
2179     $attrs->{offset} ||= 0;
2180     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
2181   }
2182
2183   return $self->{_attrs} = $attrs;
2184 }
2185
2186 sub _rollout_attr {
2187   my ($self, $attr) = @_;
2188
2189   if (ref $attr eq 'HASH') {
2190     return $self->_rollout_hash($attr);
2191   } elsif (ref $attr eq 'ARRAY') {
2192     return $self->_rollout_array($attr);
2193   } else {
2194     return [$attr];
2195   }
2196 }
2197
2198 sub _rollout_array {
2199   my ($self, $attr) = @_;
2200
2201   my @rolled_array;
2202   foreach my $element (@{$attr}) {
2203     if (ref $element eq 'HASH') {
2204       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2205     } elsif (ref $element eq 'ARRAY') {
2206       #  XXX - should probably recurse here
2207       push( @rolled_array, @{$self->_rollout_array($element)} );
2208     } else {
2209       push( @rolled_array, $element );
2210     }
2211   }
2212   return \@rolled_array;
2213 }
2214
2215 sub _rollout_hash {
2216   my ($self, $attr) = @_;
2217
2218   my @rolled_array;
2219   foreach my $key (keys %{$attr}) {
2220     push( @rolled_array, { $key => $attr->{$key} } );
2221   }
2222   return \@rolled_array;
2223 }
2224
2225 sub _calculate_score {
2226   my ($self, $a, $b) = @_;
2227
2228   if (ref $b eq 'HASH') {
2229     my ($b_key) = keys %{$b};
2230     if (ref $a eq 'HASH') {
2231       my ($a_key) = keys %{$a};
2232       if ($a_key eq $b_key) {
2233         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2234       } else {
2235         return 0;
2236       }
2237     } else {
2238       return ($a eq $b_key) ? 1 : 0;
2239     }
2240   } else {
2241     if (ref $a eq 'HASH') {
2242       my ($a_key) = keys %{$a};
2243       return ($b eq $a_key) ? 1 : 0;
2244     } else {
2245       return ($b eq $a) ? 1 : 0;
2246     }
2247   }
2248 }
2249
2250 sub _merge_attr {
2251   my ($self, $orig, $import) = @_;
2252
2253   return $import unless defined($orig);
2254   return $orig unless defined($import);
2255
2256   $orig = $self->_rollout_attr($orig);
2257   $import = $self->_rollout_attr($import);
2258
2259   my $seen_keys;
2260   foreach my $import_element ( @{$import} ) {
2261     # find best candidate from $orig to merge $b_element into
2262     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2263     foreach my $orig_element ( @{$orig} ) {
2264       my $score = $self->_calculate_score( $orig_element, $import_element );
2265       if ($score > $best_candidate->{score}) {
2266         $best_candidate->{position} = $position;
2267         $best_candidate->{score} = $score;
2268       }
2269       $position++;
2270     }
2271     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2272
2273     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2274       push( @{$orig}, $import_element );
2275     } else {
2276       my $orig_best = $orig->[$best_candidate->{position}];
2277       # merge orig_best and b_element together and replace original with merged
2278       if (ref $orig_best ne 'HASH') {
2279         $orig->[$best_candidate->{position}] = $import_element;
2280       } elsif (ref $import_element eq 'HASH') {
2281         my ($key) = keys %{$orig_best};
2282         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2283       }
2284     }
2285     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2286   }
2287
2288   return $orig;
2289 }
2290
2291 sub result_source {
2292     my $self = shift;
2293
2294     if (@_) {
2295         $self->_source_handle($_[0]->handle);
2296     } else {
2297         $self->_source_handle->resolve;
2298     }
2299 }
2300
2301 =head2 throw_exception
2302
2303 See L<DBIx::Class::Schema/throw_exception> for details.
2304
2305 =cut
2306
2307 sub throw_exception {
2308   my $self=shift;
2309   if (ref $self && $self->_source_handle->schema) {
2310     $self->_source_handle->schema->throw_exception(@_)
2311   } else {
2312     croak(@_);
2313   }
2314
2315 }
2316
2317 # XXX: FIXME: Attributes docs need clearing up
2318
2319 =head1 ATTRIBUTES
2320
2321 The resultset takes various attributes that modify its behavior. Here's an
2322 overview of them:
2323
2324 =head2 order_by
2325
2326 =over 4
2327
2328 =item Value: ($order_by | \@order_by)
2329
2330 =back
2331
2332 Which column(s) to order the results by. This is currently passed
2333 through directly to SQL, so you can give e.g. C<year DESC> for a
2334 descending order on the column `year'.
2335
2336 Please note that if you have C<quote_char> enabled (see
2337 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
2338 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
2339 so you will need to manually quote things as appropriate.)
2340
2341 =head2 columns
2342
2343 =over 4
2344
2345 =item Value: \@columns
2346
2347 =back
2348
2349 Shortcut to request a particular set of columns to be retrieved.  Adds
2350 C<me.> onto the start of any column without a C<.> in it and sets C<select>
2351 from that, then auto-populates C<as> from C<select> as normal. (You may also
2352 use the C<cols> attribute, as in earlier versions of DBIC.)
2353
2354 =head2 include_columns
2355
2356 =over 4
2357
2358 =item Value: \@columns
2359
2360 =back
2361
2362 Shortcut to include additional columns in the returned results - for example
2363
2364   $schema->resultset('CD')->search(undef, {
2365     include_columns => ['artist.name'],
2366     join => ['artist']
2367   });
2368
2369 would return all CDs and include a 'name' column to the information
2370 passed to object inflation. Note that the 'artist' is the name of the
2371 column (or relationship) accessor, and 'name' is the name of the column
2372 accessor in the related table.
2373
2374 =head2 select
2375
2376 =over 4
2377
2378 =item Value: \@select_columns
2379
2380 =back
2381
2382 Indicates which columns should be selected from the storage. You can use
2383 column names, or in the case of RDBMS back ends, function or stored procedure
2384 names:
2385
2386   $rs = $schema->resultset('Employee')->search(undef, {
2387     select => [
2388       'name',
2389       { count => 'employeeid' },
2390       { sum => 'salary' }
2391     ]
2392   });
2393
2394 When you use function/stored procedure names and do not supply an C<as>
2395 attribute, the column names returned are storage-dependent. E.g. MySQL would
2396 return a column named C<count(employeeid)> in the above example.
2397
2398 =head2 +select
2399
2400 =over 4
2401
2402 Indicates additional columns to be selected from storage.  Works the same as
2403 L</select> but adds columns to the selection.
2404
2405 =back
2406
2407 =head2 +as
2408
2409 =over 4
2410
2411 Indicates additional column names for those added via L</+select>.
2412
2413 =back
2414
2415 =head2 as
2416
2417 =over 4
2418
2419 =item Value: \@inflation_names
2420
2421 =back
2422
2423 Indicates column names for object inflation. That is, C<as>
2424 indicates the name that the column can be accessed as via the
2425 C<get_column> method (or via the object accessor, B<if one already
2426 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2427
2428 The C<as> attribute is used in conjunction with C<select>,
2429 usually when C<select> contains one or more function or stored
2430 procedure names:
2431
2432   $rs = $schema->resultset('Employee')->search(undef, {
2433     select => [
2434       'name',
2435       { count => 'employeeid' }
2436     ],
2437     as => ['name', 'employee_count'],
2438   });
2439
2440   my $employee = $rs->first(); # get the first Employee
2441
2442 If the object against which the search is performed already has an accessor
2443 matching a column name specified in C<as>, the value can be retrieved using
2444 the accessor as normal:
2445
2446   my $name = $employee->name();
2447
2448 If on the other hand an accessor does not exist in the object, you need to
2449 use C<get_column> instead:
2450
2451   my $employee_count = $employee->get_column('employee_count');
2452
2453 You can create your own accessors if required - see
2454 L<DBIx::Class::Manual::Cookbook> for details.
2455
2456 Please note: This will NOT insert an C<AS employee_count> into the SQL
2457 statement produced, it is used for internal access only. Thus
2458 attempting to use the accessor in an C<order_by> clause or similar
2459 will fail miserably.
2460
2461 To get around this limitation, you can supply literal SQL to your
2462 C<select> attibute that contains the C<AS alias> text, eg:
2463
2464   select => [\'myfield AS alias']
2465
2466 =head2 join
2467
2468 =over 4
2469
2470 =item Value: ($rel_name | \@rel_names | \%rel_names)
2471
2472 =back
2473
2474 Contains a list of relationships that should be joined for this query.  For
2475 example:
2476
2477   # Get CDs by Nine Inch Nails
2478   my $rs = $schema->resultset('CD')->search(
2479     { 'artist.name' => 'Nine Inch Nails' },
2480     { join => 'artist' }
2481   );
2482
2483 Can also contain a hash reference to refer to the other relation's relations.
2484 For example:
2485
2486   package MyApp::Schema::Track;
2487   use base qw/DBIx::Class/;
2488   __PACKAGE__->table('track');
2489   __PACKAGE__->add_columns(qw/trackid cd position title/);
2490   __PACKAGE__->set_primary_key('trackid');
2491   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2492   1;
2493
2494   # In your application
2495   my $rs = $schema->resultset('Artist')->search(
2496     { 'track.title' => 'Teardrop' },
2497     {
2498       join     => { cd => 'track' },
2499       order_by => 'artist.name',
2500     }
2501   );
2502
2503 You need to use the relationship (not the table) name in  conditions,
2504 because they are aliased as such. The current table is aliased as "me", so
2505 you need to use me.column_name in order to avoid ambiguity. For example:
2506
2507   # Get CDs from 1984 with a 'Foo' track
2508   my $rs = $schema->resultset('CD')->search(
2509     {
2510       'me.year' => 1984,
2511       'tracks.name' => 'Foo'
2512     },
2513     { join => 'tracks' }
2514   );
2515
2516 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2517 similarly for a third time). For e.g.
2518
2519   my $rs = $schema->resultset('Artist')->search({
2520     'cds.title'   => 'Down to Earth',
2521     'cds_2.title' => 'Popular',
2522   }, {
2523     join => [ qw/cds cds/ ],
2524   });
2525
2526 will return a set of all artists that have both a cd with title 'Down
2527 to Earth' and a cd with title 'Popular'.
2528
2529 If you want to fetch related objects from other tables as well, see C<prefetch>
2530 below.
2531
2532 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2533
2534 =head2 prefetch
2535
2536 =over 4
2537
2538 =item Value: ($rel_name | \@rel_names | \%rel_names)
2539
2540 =back
2541
2542 Contains one or more relationships that should be fetched along with
2543 the main query (when they are accessed afterwards the data will
2544 already be available, without extra queries to the database).  This is
2545 useful for when you know you will need the related objects, because it
2546 saves at least one query:
2547
2548   my $rs = $schema->resultset('Tag')->search(
2549     undef,
2550     {
2551       prefetch => {
2552         cd => 'artist'
2553       }
2554     }
2555   );
2556
2557 The initial search results in SQL like the following:
2558
2559   SELECT tag.*, cd.*, artist.* FROM tag
2560   JOIN cd ON tag.cd = cd.cdid
2561   JOIN artist ON cd.artist = artist.artistid
2562
2563 L<DBIx::Class> has no need to go back to the database when we access the
2564 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2565 case.
2566
2567 Simple prefetches will be joined automatically, so there is no need
2568 for a C<join> attribute in the above search.
2569
2570 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2571 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2572 with an accessor type of 'single' or 'filter'). A more complex example that
2573 prefetches an artists cds, the tracks on those cds, and the tags associted
2574 with that artist is given below (assuming many-to-many from artists to tags):
2575
2576  my $rs = $schema->resultset('Artist')->search(
2577    undef,
2578    {
2579      prefetch => [
2580        { cds => 'tracks' },
2581        { artist_tags => 'tags' }
2582      ]
2583    }
2584  );
2585
2586
2587 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2588 attributes will be ignored.
2589
2590 =head2 page
2591
2592 =over 4
2593
2594 =item Value: $page
2595
2596 =back
2597
2598 Makes the resultset paged and specifies the page to retrieve. Effectively
2599 identical to creating a non-pages resultset and then calling ->page($page)
2600 on it.
2601
2602 If L<rows> attribute is not specified it defualts to 10 rows per page.
2603
2604 =head2 rows
2605
2606 =over 4
2607
2608 =item Value: $rows
2609
2610 =back
2611
2612 Specifes the maximum number of rows for direct retrieval or the number of
2613 rows per page if the page attribute or method is used.
2614
2615 =head2 offset
2616
2617 =over 4
2618
2619 =item Value: $offset
2620
2621 =back
2622
2623 Specifies the (zero-based) row number for the  first row to be returned, or the
2624 of the first row of the first page if paging is used.
2625
2626 =head2 group_by
2627
2628 =over 4
2629
2630 =item Value: \@columns
2631
2632 =back
2633
2634 A arrayref of columns to group by. Can include columns of joined tables.
2635
2636   group_by => [qw/ column1 column2 ... /]
2637
2638 =head2 having
2639
2640 =over 4
2641
2642 =item Value: $condition
2643
2644 =back
2645
2646 HAVING is a select statement attribute that is applied between GROUP BY and
2647 ORDER BY. It is applied to the after the grouping calculations have been
2648 done.
2649
2650   having => { 'count(employee)' => { '>=', 100 } }
2651
2652 =head2 distinct
2653
2654 =over 4
2655
2656 =item Value: (0 | 1)
2657
2658 =back
2659
2660 Set to 1 to group by all columns.
2661
2662 =head2 where
2663
2664 =over 4
2665
2666 Adds to the WHERE clause.
2667
2668   # only return rows WHERE deleted IS NULL for all searches
2669   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2670
2671 Can be overridden by passing C<{ where => undef }> as an attribute
2672 to a resulset.
2673
2674 =back
2675
2676 =head2 cache
2677
2678 Set to 1 to cache search results. This prevents extra SQL queries if you
2679 revisit rows in your ResultSet:
2680
2681   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2682
2683   while( my $artist = $resultset->next ) {
2684     ... do stuff ...
2685   }
2686
2687   $rs->first; # without cache, this would issue a query
2688
2689 By default, searches are not cached.
2690
2691 For more examples of using these attributes, see
2692 L<DBIx::Class::Manual::Cookbook>.
2693
2694 =head2 from
2695
2696 =over 4
2697
2698 =item Value: \@from_clause
2699
2700 =back
2701
2702 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2703 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2704 clauses.
2705
2706 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2707
2708 C<join> will usually do what you need and it is strongly recommended that you
2709 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2710 And we really do mean "cannot", not just tried and failed. Attempting to use
2711 this because you're having problems with C<join> is like trying to use x86
2712 ASM because you've got a syntax error in your C. Trust us on this.
2713
2714 Now, if you're still really, really sure you need to use this (and if you're
2715 not 100% sure, ask the mailing list first), here's an explanation of how this
2716 works.
2717
2718 The syntax is as follows -
2719
2720   [
2721     { <alias1> => <table1> },
2722     [
2723       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2724       [], # nested JOIN (optional)
2725       { <table1.column1> => <table2.column2>, ... (more conditions) },
2726     ],
2727     # More of the above [ ] may follow for additional joins
2728   ]
2729
2730   <table1> <alias1>
2731   JOIN
2732     <table2> <alias2>
2733     [JOIN ...]
2734   ON <table1.column1> = <table2.column2>
2735   <more joins may follow>
2736
2737 An easy way to follow the examples below is to remember the following:
2738
2739     Anything inside "[]" is a JOIN
2740     Anything inside "{}" is a condition for the enclosing JOIN
2741
2742 The following examples utilize a "person" table in a family tree application.
2743 In order to express parent->child relationships, this table is self-joined:
2744
2745     # Person->belongs_to('father' => 'Person');
2746     # Person->belongs_to('mother' => 'Person');
2747
2748 C<from> can be used to nest joins. Here we return all children with a father,
2749 then search against all mothers of those children:
2750
2751   $rs = $schema->resultset('Person')->search(
2752       undef,
2753       {
2754           alias => 'mother', # alias columns in accordance with "from"
2755           from => [
2756               { mother => 'person' },
2757               [
2758                   [
2759                       { child => 'person' },
2760                       [
2761                           { father => 'person' },
2762                           { 'father.person_id' => 'child.father_id' }
2763                       ]
2764                   ],
2765                   { 'mother.person_id' => 'child.mother_id' }
2766               ],
2767           ]
2768       },
2769   );
2770
2771   # Equivalent SQL:
2772   # SELECT mother.* FROM person mother
2773   # JOIN (
2774   #   person child
2775   #   JOIN person father
2776   #   ON ( father.person_id = child.father_id )
2777   # )
2778   # ON ( mother.person_id = child.mother_id )
2779
2780 The type of any join can be controlled manually. To search against only people
2781 with a father in the person table, we could explicitly use C<INNER JOIN>:
2782
2783     $rs = $schema->resultset('Person')->search(
2784         undef,
2785         {
2786             alias => 'child', # alias columns in accordance with "from"
2787             from => [
2788                 { child => 'person' },
2789                 [
2790                     { father => 'person', -join_type => 'inner' },
2791                     { 'father.id' => 'child.father_id' }
2792                 ],
2793             ]
2794         },
2795     );
2796
2797     # Equivalent SQL:
2798     # SELECT child.* FROM person child
2799     # INNER JOIN person father ON child.father_id = father.id
2800
2801 If you need to express really complex joins or you need a subselect, you
2802 can supply literal SQL to C<from> via a scalar reference. In this case
2803 the contents of the scalar will replace the table name asscoiated with the
2804 resultsource.
2805
2806 WARNING: This technique might very well not work as expected on chained
2807 searches - you have been warned.
2808
2809     # Assuming the Event resultsource is defined as:
2810
2811         MySchema::Event->add_columns (
2812             sequence => {
2813                 data_type => 'INT',
2814                 is_auto_increment => 1,
2815             },
2816             location => {
2817                 data_type => 'INT',
2818             },
2819             type => {
2820                 data_type => 'INT',
2821             },
2822         );
2823         MySchema::Event->set_primary_key ('sequence');
2824
2825     # This will get back the latest event for every location. The column
2826     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
2827     # combo to limit the resultset
2828
2829     $rs = $schema->resultset('Event');
2830     $table = $rs->result_source->name;
2831     $latest = $rs->search (
2832         undef,
2833         { from => \ "
2834             (SELECT e1.* FROM $table e1
2835                 JOIN $table e2
2836                     ON e1.location = e2.location
2837                     AND e1.sequence < e2.sequence
2838                 WHERE e2.sequence is NULL
2839             ) me",
2840         },
2841     );
2842
2843     # Equivalent SQL (with the DBIC chunks added):
2844
2845     SELECT me.sequence, me.location, me.type FROM
2846        (SELECT e1.* FROM events e1
2847            JOIN events e2
2848                ON e1.location = e2.location
2849                AND e1.sequence < e2.sequence
2850            WHERE e2.sequence is NULL
2851        ) me;
2852
2853 =head2 for
2854
2855 =over 4
2856
2857 =item Value: ( 'update' | 'shared' )
2858
2859 =back
2860
2861 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
2862 ... FOR SHARED.
2863
2864 =cut
2865
2866 1;