lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  29
  30 =head1 NAME
  31
  32 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  33
  34 =head1 SYNOPSIS
  35
  36   my $users_rs = $schema->resultset('User');
  37   while( $user = $users_rs->next) {
  38     print $user->username;
  39   }
  40
  41   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  42   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  43
  44 =head1 DESCRIPTION
  45
  46 A ResultSet is an object which stores a set of conditions representing
  47 a query. It is the backbone of DBIx::Class (i.e. the really
  48 important/useful bit).
  49
  50 No SQL is executed on the database when a ResultSet is created, it
  51 just stores all the conditions needed to create the query.
  52
  53 A basic ResultSet representing the data of an entire table is returned
  54 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  55 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  56
  57   my $users_rs = $schema->resultset('User');
  58
  59 A new ResultSet is returned from calling L</search> on an existing
  60 ResultSet. The new one will contain all the conditions of the
  61 original, plus any new conditions added in the C<search> call.
  62
  63 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  64 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  65 represents.
  66
  67 The query that the ResultSet represents is B<only> executed against
  68 the database when these methods are called:
  69 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  70
  71 If a resultset is used in a numeric context it returns the L</count>.
  72 However, if it is used in a boolean context it is B<always> true.  So if
  73 you want to check if a resultset has any results, you must use C<if $rs
  74 != 0>.
  75
  76 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  77
  78 If you want to make your custom ResultSet classes with L<Moose>, use a template
  79 similar to:
  80
  81     package MyApp::Schema::ResultSet::User;
  82
  83     use Moose;
  84     use namespace::autoclean;
  85     use MooseX::NonMoose;
  86     extends 'DBIx::Class::ResultSet';
  87
  88     sub BUILDARGS { $_[2] }
  89
  90     ...your code...
  91
  92     __PACKAGE__->meta->make_immutable;
  93
  94     1;
  95
  96 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  97 clash with the regular ResultSet constructor. Alternatively, you can use:
  98
  99     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 100
 101 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 102 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 103
 104 =head1 EXAMPLES
 105
 106 =head2 Chaining resultsets
 107
 108 Let's say you've got a query that needs to be run to return some data
 109 to the user. But, you have an authorization system in place that
 110 prevents certain users from seeing certain information. So, you want
 111 to construct the basic query in one method, but add constraints to it in
 112 another.
 113
 114   sub get_data {
 115     my $self = shift;
 116     my $request = $self->get_request; # Get a request object somehow.
 117     my $schema = $self->result_source->schema;
 118
 119     my $cd_rs = $schema->resultset('CD')->search({
 120       title => $request->param('title'),
 121       year => $request->param('year'),
 122     });
 123
 124     $cd_rs = $self->apply_security_policy( $cd_rs );
 125
 126     return $cd_rs->all();
 127   }
 128
 129   sub apply_security_policy {
 130     my $self = shift;
 131     my ($rs) = @_;
 132
 133     return $rs->search({
 134       subversive => 0,
 135     });
 136   }
 137
 138 =head3 Resolving conditions and attributes
 139
 140 When a resultset is chained from another resultset, conditions and
 141 attributes with the same keys need resolving.
 142
 143 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 144 into the existing ones from the original resultset.
 145
 146 The L</where> and L</having> attributes, and any search conditions, are
 147 merged with an SQL C<AND> to the existing condition from the original
 148 resultset.
 149
 150 All other attributes are overridden by any new ones supplied in the
 151 search attributes.
 152
 153 =head2 Multiple queries
 154
 155 Since a resultset just defines a query, you can do all sorts of
 156 things with it with the same object.
 157
 158   # Don't hit the DB yet.
 159   my $cd_rs = $schema->resultset('CD')->search({
 160     title => 'something',
 161     year => 2009,
 162   });
 163
 164   # Each of these hits the DB individually.
 165   my $count = $cd_rs->count;
 166   my $most_recent = $cd_rs->get_column('date_released')->max();
 167   my @records = $cd_rs->all;
 168
 169 And it's not just limited to SELECT statements.
 170
 171   $cd_rs->delete();
 172
 173 This is even cooler:
 174
 175   $cd_rs->create({ artist => 'Fred' });
 176
 177 Which is the same as:
 178
 179   $schema->resultset('CD')->create({
 180     title => 'something',
 181     year => 2009,
 182     artist => 'Fred'
 183   });
 184
 185 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 186
 187 =head1 METHODS
 188
 189 =head2 new
 190
 191 =over 4
 192
 193 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 194
 195 =item Return Value: L<$resultset|/search>
 196
 197 =back
 198
 199 The resultset constructor. Takes a source object (usually a
 200 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 201 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 202 executed as needed by the other methods.
 203
 204 Generally you never construct a resultset manually. Instead you get one
 205 from e.g. a
 206 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 207 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 208 scalar context):
 209
 210   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 211
 212 =over
 213
 214 =item WARNING
 215
 216 If called on an object, proxies to L</new_result> instead, so
 217
 218   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 219
 220 will return a CD object, not a ResultSet, and is equivalent to:
 221
 222   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 223
 224 Please also keep in mind that many internals call L</new_result> directly,
 225 so overloading this method with the idea of intercepting new result object
 226 creation B<will not work>. See also warning pertaining to L</create>.
 227
 228 =back
 229
 230 =cut
 231
 232 sub new {
 233   my $class = shift;
 234   return $class->new_result(@_) if ref $class;
 235
 236   my ($source, $attrs) = @_;
 237   $source = $source->resolve
 238     if $source->isa('DBIx::Class::ResultSourceHandle');
 239   $attrs = { %{$attrs||{}} };
 240
 241   if ($attrs->{page}) {
 242     $attrs->{rows} ||= 10;
 243   }
 244
 245   $attrs->{alias} ||= 'me';
 246
 247   my $self = bless {
 248     result_source => $source,
 249     cond => $attrs->{where},
 250     pager => undef,
 251     attrs => $attrs,
 252   }, $class;
 253
 254   # if there is a dark selector, this means we are already in a
 255   # chain and the cleanup/sanification was taken care of by
 256   # _search_rs already
 257   $self->_normalize_selection($attrs)
 258     unless $attrs->{_dark_selector};
 259
 260   $self->result_class(
 261     $attrs->{result_class} || $source->result_class
 262   );
 263
 264   $self;
 265 }
 266
 267 =head2 search
 268
 269 =over 4
 270
 271 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 272
 273 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 274
 275 =back
 276
 277   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 278   my $new_rs = $cd_rs->search({ year => 2005 });
 279
 280   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 281                  # year = 2005 OR year = 2004
 282
 283 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 284 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 285 To avoid that, use L</search_rs>.
 286
 287 If you need to pass in additional attributes but no additional condition,
 288 call it as C<search(undef, \%attrs)>.
 289
 290   # "SELECT name, artistid FROM $artist_table"
 291   my @all_artists = $schema->resultset('Artist')->search(undef, {
 292     columns => [qw/name artistid/],
 293   });
 294
 295 For a list of attributes that can be passed to C<search>, see
 296 L</ATTRIBUTES>. For more examples of using this function, see
 297 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 298 documentation for the first argument, see L<SQL::Abstract>
 299 and its extension L<DBIx::Class::SQLMaker>.
 300
 301 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 302
 303 =head3 CAVEAT
 304
 305 Note that L</search> does not process/deflate any of the values passed in the
 306 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 307 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 308 manually that any value passed to this method will stringify to something the
 309 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 310 objects, for more info see:
 311 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 312
 313 =cut
 314
 315 sub search {
 316   my $self = shift;
 317   my $rs = $self->search_rs( @_ );
 318
 319   if (wantarray) {
 320     return $rs->all;
 321   }
 322   elsif (defined wantarray) {
 323     return $rs;
 324   }
 325   else {
 326     # we can be called by a relationship helper, which in
 327     # turn may be called in void context due to some braindead
 328     # overload or whatever else the user decided to be clever
 329     # at this particular day. Thus limit the exception to
 330     # external code calls only
 331     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 332       if (caller)[0] !~ /^\QDBIx::Class::/;
 333
 334     return ();
 335   }
 336 }
 337
 338 =head2 search_rs
 339
 340 =over 4
 341
 342 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 343
 344 =item Return Value: L<$resultset|/search>
 345
 346 =back
 347
 348 This method does the same exact thing as search() except it will
 349 always return a resultset, even in list context.
 350
 351 =cut
 352
 353 sub search_rs {
 354   my $self = shift;
 355
 356   my $rsrc = $self->result_source;
 357   my ($call_cond, $call_attrs);
 358
 359   # Special-case handling for (undef, undef) or (undef)
 360   # Note that (foo => undef) is valid deprecated syntax
 361   @_ = () if not scalar grep { defined $_ } @_;
 362
 363   # just a cond
 364   if (@_ == 1) {
 365     $call_cond = shift;
 366   }
 367   # fish out attrs in the ($condref, $attr) case
 368   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 369     ($call_cond, $call_attrs) = @_;
 370   }
 371   elsif (@_ % 2) {
 372     $self->throw_exception('Odd number of arguments to search')
 373   }
 374   # legacy search
 375   elsif (@_) {
 376     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 377       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 378
 379     for my $i (0 .. $#_) {
 380       next if $i % 2;
 381       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 382         if (! defined $_[$i] or ref $_[$i] ne '');
 383     }
 384
 385     $call_cond = { @_ };
 386   }
 387
 388   # see if we can keep the cache (no $rs changes)
 389   my $cache;
 390   my %safe = (alias => 1, cache => 1);
 391   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 392     ! defined $_[0]
 393       or
 394     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 395       or
 396     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 397   )) {
 398     $cache = $self->get_cache;
 399   }
 400
 401   my $old_attrs = { %{$self->{attrs}} };
 402   my $old_having = delete $old_attrs->{having};
 403   my $old_where = delete $old_attrs->{where};
 404
 405   my $new_attrs = { %$old_attrs };
 406
 407   # take care of call attrs (only if anything is changing)
 408   if ($call_attrs and keys %$call_attrs) {
 409
 410     # copy for _normalize_selection
 411     $call_attrs = { %$call_attrs };
 412
 413     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 414
 415     # reset the current selector list if new selectors are supplied
 416     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 417       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 418     }
 419
 420     # Normalize the new selector list (operates on the passed-in attr structure)
 421     # Need to do it on every chain instead of only once on _resolved_attrs, in
 422     # order to allow detection of empty vs partial 'as'
 423     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 424       if $old_attrs->{_dark_selector};
 425     $self->_normalize_selection ($call_attrs);
 426
 427     # start with blind overwriting merge, exclude selector attrs
 428     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 429     delete @{$new_attrs}{@selector_attrs};
 430
 431     for (@selector_attrs) {
 432       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 433         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 434     }
 435
 436     # older deprecated name, use only if {columns} is not there
 437     if (my $c = delete $new_attrs->{cols}) {
 438       if ($new_attrs->{columns}) {
 439         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 440       }
 441       else {
 442         $new_attrs->{columns} = $c;
 443       }
 444     }
 445
 446
 447     # join/prefetch use their own crazy merging heuristics
 448     foreach my $key (qw/join prefetch/) {
 449       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 450         if exists $call_attrs->{$key};
 451     }
 452
 453     # stack binds together
 454     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 455   }
 456
 457
 458   for ($old_where, $call_cond) {
 459     if (defined $_) {
 460       $new_attrs->{where} = $self->_stack_cond (
 461         $_, $new_attrs->{where}
 462       );
 463     }
 464   }
 465
 466   if (defined $old_having) {
 467     $new_attrs->{having} = $self->_stack_cond (
 468       $old_having, $new_attrs->{having}
 469     )
 470   }
 471
 472   my $rs = (ref $self)->new($rsrc, $new_attrs);
 473
 474   $rs->set_cache($cache) if ($cache);
 475
 476   return $rs;
 477 }
 478
 479 my $dark_sel_dumper;
 480 sub _normalize_selection {
 481   my ($self, $attrs) = @_;
 482
 483   # legacy syntax
 484   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 485     if exists $attrs->{include_columns};
 486
 487   # columns are always placed first, however
 488
 489   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 490   # delay the decision on whether to use a default select list ($rsrc->columns)
 491   # allowing stuff like the remove_columns helper to work
 492   #
 493   # select/as +select/+as pairs need special handling - the amount of select/as
 494   # elements in each pair does *not* have to be equal (think multicolumn
 495   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 496   # supplied at all) - try to infer the alias, either from the -as parameter
 497   # of the selector spec, or use the parameter whole if it looks like a column
 498   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 499   # is ok as well), but make sure no more additions to the 'as' chain take place
 500   for my $pref ('', '+') {
 501
 502     my ($sel, $as) = map {
 503       my $key = "${pref}${_}";
 504
 505       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 506         ? @{$attrs->{$key}}
 507         : $attrs->{$key} || ()
 508       ];
 509       delete $attrs->{$key};
 510       $val;
 511     } qw/select as/;
 512
 513     if (! @$as and ! @$sel ) {
 514       next;
 515     }
 516     elsif (@$as and ! @$sel) {
 517       $self->throw_exception(
 518         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 519       );
 520     }
 521     elsif( ! @$as ) {
 522       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 523       # if any @$as has been supplied we assume the user knows what (s)he is doing
 524       # and blindly keep stacking up pieces
 525       unless ($attrs->{_dark_selector}) {
 526         SELECTOR:
 527         for (@$sel) {
 528           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 529             push @$as, $_->{-as};
 530           }
 531           # assume any plain no-space, no-parenthesis string to be a column spec
 532           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 533           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 534             push @$as, $_;
 535           }
 536           # if all else fails - raise a flag that no more aliasing will be allowed
 537           else {
 538             $attrs->{_dark_selector} = {
 539               plus_stage => $pref,
 540               string => ($dark_sel_dumper ||= do {
 541                   require Data::Dumper::Concise;
 542                   Data::Dumper::Concise::DumperObject()->Indent(0);
 543                 })->Values([$_])->Dump
 544               ,
 545             };
 546             last SELECTOR;
 547           }
 548         }
 549       }
 550     }
 551     elsif (@$as < @$sel) {
 552       $self->throw_exception(
 553         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 554       );
 555     }
 556     elsif ($pref and $attrs->{_dark_selector}) {
 557       $self->throw_exception(
 558         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 559       );
 560     }
 561
 562
 563     # merge result
 564     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 565     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 566   }
 567 }
 568
 569 sub _stack_cond {
 570   my ($self, $left, $right) = @_;
 571
 572   # collapse single element top-level conditions
 573   # (single pass only, unlikely to need recursion)
 574   for ($left, $right) {
 575     if (ref $_ eq 'ARRAY') {
 576       if (@$_ == 0) {
 577         $_ = undef;
 578       }
 579       elsif (@$_ == 1) {
 580         $_ = $_->[0];
 581       }
 582     }
 583     elsif (ref $_ eq 'HASH') {
 584       my ($first, $more) = keys %$_;
 585
 586       # empty hash
 587       if (! defined $first) {
 588         $_ = undef;
 589       }
 590       # one element hash
 591       elsif (! defined $more) {
 592         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 593           $_ = $_->{'-and'};
 594         }
 595         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 596           $_ = $_->{'-or'};
 597         }
 598       }
 599     }
 600   }
 601
 602   # merge hashes with weeding out of duplicates (simple cases only)
 603   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 604
 605     # shallow copy to destroy
 606     $right = { %$right };
 607     for (grep { exists $right->{$_} } keys %$left) {
 608       # the use of eq_deeply here is justified - the rhs of an
 609       # expression can contain a lot of twisted weird stuff
 610       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 611     }
 612
 613     $right = undef unless keys %$right;
 614   }
 615
 616
 617   if (defined $left xor defined $right) {
 618     return defined $left ? $left : $right;
 619   }
 620   elsif (! defined $left) {
 621     return undef;
 622   }
 623   else {
 624     return { -and => [ $left, $right ] };
 625   }
 626 }
 627
 628 =head2 search_literal
 629
 630 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 631 should only be used in that context. C<search_literal> is a convenience
 632 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 633 want to ensure columns are bound correctly, use L</search>.
 634
 635 See L<DBIx::Class::Manual::Cookbook/Searching> and
 636 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 637 require C<search_literal>.
 638
 639 =over 4
 640
 641 =item Arguments: $sql_fragment, @standalone_bind_values
 642
 643 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 644
 645 =back
 646
 647   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 648   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 649
 650 Pass a literal chunk of SQL to be added to the conditional part of the
 651 resultset query.
 652
 653 Example of how to use C<search> instead of C<search_literal>
 654
 655   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 656   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 657
 658 =cut
 659
 660 sub search_literal {
 661   my ($self, $sql, @bind) = @_;
 662   my $attr;
 663   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 664     $attr = pop @bind;
 665   }
 666   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 667 }
 668
 669 =head2 find
 670
 671 =over 4
 672
 673 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 674
 675 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 676
 677 =back
 678
 679 Finds and returns a single row based on supplied criteria. Takes either a
 680 hashref with the same format as L</create> (including inference of foreign
 681 keys from related objects), or a list of primary key values in the same
 682 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 683 declaration on the L</result_source>.
 684
 685 In either case an attempt is made to combine conditions already existing on
 686 the resultset with the condition passed to this method.
 687
 688 To aid with preparing the correct query for the storage you may supply the
 689 C<key> attribute, which is the name of a
 690 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 691 unique constraint corresponding to the
 692 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 693 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 694 to construct a query that satisfies the named unique constraint fully (
 695 non-NULL values for each column member of the constraint) an exception is
 696 thrown.
 697
 698 If no C<key> is specified, the search is carried over all unique constraints
 699 which are fully defined by the available condition.
 700
 701 If no such constraint is found, C<find> currently defaults to a simple
 702 C<< search->(\%column_values) >> which may or may not do what you expect.
 703 Note that this fallback behavior may be deprecated in further versions. If
 704 you need to search with arbitrary conditions - use L</search>. If the query
 705 resulting from this fallback produces more than one row, a warning to the
 706 effect is issued, though only the first row is constructed and returned as
 707 C<$result_object>.
 708
 709 In addition to C<key>, L</find> recognizes and applies standard
 710 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 711
 712 Note that if you have extra concerns about the correctness of the resulting
 713 query you need to specify the C<key> attribute and supply the entire condition
 714 as an argument to find (since it is not always possible to perform the
 715 combination of the resultset condition with the supplied one, especially if
 716 the resultset condition contains literal sql).
 717
 718 For example, to find a row by its primary key:
 719
 720   my $cd = $schema->resultset('CD')->find(5);
 721
 722 You can also find a row by a specific unique constraint:
 723
 724   my $cd = $schema->resultset('CD')->find(
 725     {
 726       artist => 'Massive Attack',
 727       title  => 'Mezzanine',
 728     },
 729     { key => 'cd_artist_title' }
 730   );
 731
 732 See also L</find_or_create> and L</update_or_create>.
 733
 734 =cut
 735
 736 sub find {
 737   my $self = shift;
 738   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 739
 740   my $rsrc = $self->result_source;
 741
 742   my $constraint_name;
 743   if (exists $attrs->{key}) {
 744     $constraint_name = defined $attrs->{key}
 745       ? $attrs->{key}
 746       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 747     ;
 748   }
 749
 750   # Parse out the condition from input
 751   my $call_cond;
 752
 753   if (ref $_[0] eq 'HASH') {
 754     $call_cond = { %{$_[0]} };
 755   }
 756   else {
 757     # if only values are supplied we need to default to 'primary'
 758     $constraint_name = 'primary' unless defined $constraint_name;
 759
 760     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 761
 762     $self->throw_exception(
 763       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 764     ) unless @c_cols;
 765
 766     $self->throw_exception (
 767       'find() expects either a column/value hashref, or a list of values '
 768     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 769     ) unless @c_cols == @_;
 770
 771     $call_cond = {};
 772     @{$call_cond}{@c_cols} = @_;
 773   }
 774
 775   my %related;
 776   for my $key (keys %$call_cond) {
 777     if (
 778       my $keyref = ref($call_cond->{$key})
 779         and
 780       my $relinfo = $rsrc->relationship_info($key)
 781     ) {
 782       my $val = delete $call_cond->{$key};
 783
 784       next if $keyref eq 'ARRAY'; # has_many for multi_create
 785
 786       my $rel_q = $rsrc->_resolve_condition(
 787         $relinfo->{cond}, $val, $key, $key
 788       );
 789       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 790       @related{keys %$rel_q} = values %$rel_q;
 791     }
 792   }
 793
 794   # relationship conditions take precedence (?)
 795   @{$call_cond}{keys %related} = values %related;
 796
 797   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 798   my $final_cond;
 799   if (defined $constraint_name) {
 800     $final_cond = $self->_qualify_cond_columns (
 801
 802       $self->_build_unique_cond (
 803         $constraint_name,
 804         $call_cond,
 805       ),
 806
 807       $alias,
 808     );
 809   }
 810   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 811     # This means that we got here after a merger of relationship conditions
 812     # in ::Relationship::Base::search_related (the row method), and furthermore
 813     # the relationship is of the 'single' type. This means that the condition
 814     # provided by the relationship (already attached to $self) is sufficient,
 815     # as there can be only one row in the database that would satisfy the
 816     # relationship
 817   }
 818   else {
 819     # no key was specified - fall down to heuristics mode:
 820     # run through all unique queries registered on the resultset, and
 821     # 'OR' all qualifying queries together
 822     my (@unique_queries, %seen_column_combinations);
 823     for my $c_name ($rsrc->unique_constraint_names) {
 824       next if $seen_column_combinations{
 825         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 826       }++;
 827
 828       push @unique_queries, try {
 829         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 830       } || ();
 831     }
 832
 833     $final_cond = @unique_queries
 834       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 835       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 836     ;
 837   }
 838
 839   # Run the query, passing the result_class since it should propagate for find
 840   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 841   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 842     my $row = $rs->next;
 843     carp "Query returned more than one row" if $rs->next;
 844     return $row;
 845   }
 846   else {
 847     return $rs->single;
 848   }
 849 }
 850
 851 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 852 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 853 #
 854 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 855 # condition. It is provided for overrides until a saner way forward is devised
 856 #
 857 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 858 # the road. Please adjust your tests accordingly to catch this situation early
 859 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 860 #
 861 # The method will not be removed without an adequately complete replacement
 862 # for strict-mode enforcement
 863 sub _non_unique_find_fallback {
 864   my ($self, $cond, $attrs) = @_;
 865
 866   return $self->_qualify_cond_columns(
 867     $cond,
 868     exists $attrs->{alias}
 869       ? $attrs->{alias}
 870       : $self->{attrs}{alias}
 871   );
 872 }
 873
 874
 875 sub _qualify_cond_columns {
 876   my ($self, $cond, $alias) = @_;
 877
 878   my %aliased = %$cond;
 879   for (keys %aliased) {
 880     $aliased{"$alias.$_"} = delete $aliased{$_}
 881       if $_ !~ /\./;
 882   }
 883
 884   return \%aliased;
 885 }
 886
 887 sub _build_unique_cond {
 888   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 889
 890   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 891
 892   # combination may fail if $self->{cond} is non-trivial
 893   my ($final_cond) = try {
 894     $self->_merge_with_rscond ($extra_cond)
 895   } catch {
 896     +{ %$extra_cond }
 897   };
 898
 899   # trim out everything not in $columns
 900   $final_cond = { map {
 901     exists $final_cond->{$_}
 902       ? ( $_ => $final_cond->{$_} )
 903       : ()
 904   } @c_cols };
 905
 906   if (my @missing = grep
 907     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 908     (@c_cols)
 909   ) {
 910     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 911       $constraint_name,
 912       join (', ', map { "'$_'" } @missing),
 913     ) );
 914   }
 915
 916   if (
 917     !$croak_on_null
 918       and
 919     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 920       and
 921     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 922   ) {
 923     carp_unique ( sprintf (
 924       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 925     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 926     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 927       $constraint_name,
 928       join (', ', map { "'$_'" } @undefs),
 929     ));
 930   }
 931
 932   return $final_cond;
 933 }
 934
 935 =head2 search_related
 936
 937 =over 4
 938
 939 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 940
 941 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 942
 943 =back
 944
 945   $new_rs = $cd_rs->search_related('artist', {
 946     name => 'Emo-R-Us',
 947   });
 948
 949 Searches the specified relationship, optionally specifying a condition and
 950 attributes for matching records. See L</ATTRIBUTES> for more information.
 951
 952 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 953 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 954
 955 See also L</search_related_rs>.
 956
 957 =cut
 958
 959 sub search_related {
 960   return shift->related_resultset(shift)->search(@_);
 961 }
 962
 963 =head2 search_related_rs
 964
 965 This method works exactly the same as search_related, except that
 966 it guarantees a resultset, even in list context.
 967
 968 =cut
 969
 970 sub search_related_rs {
 971   return shift->related_resultset(shift)->search_rs(@_);
 972 }
 973
 974 =head2 cursor
 975
 976 =over 4
 977
 978 =item Arguments: none
 979
 980 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 981
 982 =back
 983
 984 Returns a storage-driven cursor to the given resultset. See
 985 L<DBIx::Class::Cursor> for more information.
 986
 987 =cut
 988
 989 sub cursor {
 990   my $self = shift;
 991
 992   return $self->{cursor} ||= do {
 993     my $attrs = { %{$self->_resolved_attrs } };
 994     $self->result_source->storage->select(
 995       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
 996     );
 997   };
 998 }
 999
1000 =head2 single
1001
1002 =over 4
1003
1004 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1005
1006 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1007
1008 =back
1009
1010   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1011
1012 Inflates the first result without creating a cursor if the resultset has
1013 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1014 of L</search>.
1015
1016 While this method can take an optional search condition (just like L</search>)
1017 being a fast-code-path it does not recognize search attributes. If you need to
1018 add extra joins or similar, call L</search> and then chain-call L</single> on the
1019 L<DBIx::Class::ResultSet> returned.
1020
1021 =over
1022
1023 =item B<Note>
1024
1025 As of 0.08100, this method enforces the assumption that the preceding
1026 query returns only one row. If more than one row is returned, you will receive
1027 a warning:
1028
1029   Query returned more than one row
1030
1031 In this case, you should be using L</next> or L</find> instead, or if you really
1032 know what you are doing, use the L</rows> attribute to explicitly limit the size
1033 of the resultset.
1034
1035 This method will also throw an exception if it is called on a resultset prefetching
1036 has_many, as such a prefetch implies fetching multiple rows from the database in
1037 order to assemble the resulting object.
1038
1039 =back
1040
1041 =cut
1042
1043 sub single {
1044   my ($self, $where) = @_;
1045   if(@_ > 2) {
1046       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1047   }
1048
1049   my $attrs = { %{$self->_resolved_attrs} };
1050
1051   if (keys %{$attrs->{collapse}}) {
1052     $self->throw_exception(
1053       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1054     );
1055   }
1056
1057   if ($where) {
1058     if (defined $attrs->{where}) {
1059       $attrs->{where} = {
1060         '-and' =>
1061             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1062                $where, delete $attrs->{where} ]
1063       };
1064     } else {
1065       $attrs->{where} = $where;
1066     }
1067   }
1068
1069   my @data = $self->result_source->storage->select_single(
1070     $attrs->{from}, $attrs->{select},
1071     $attrs->{where}, $attrs
1072   );
1073
1074   return (@data ? ($self->_construct_object(@data))[0] : undef);
1075 }
1076
1077
1078 # _collapse_query
1079 #
1080 # Recursively collapse the query, accumulating values for each column.
1081
1082 sub _collapse_query {
1083   my ($self, $query, $collapsed) = @_;
1084
1085   $collapsed ||= {};
1086
1087   if (ref $query eq 'ARRAY') {
1088     foreach my $subquery (@$query) {
1089       next unless ref $subquery;  # -or
1090       $collapsed = $self->_collapse_query($subquery, $collapsed);
1091     }
1092   }
1093   elsif (ref $query eq 'HASH') {
1094     if (keys %$query and (keys %$query)[0] eq '-and') {
1095       foreach my $subquery (@{$query->{-and}}) {
1096         $collapsed = $self->_collapse_query($subquery, $collapsed);
1097       }
1098     }
1099     else {
1100       foreach my $col (keys %$query) {
1101         my $value = $query->{$col};
1102         $collapsed->{$col}{$value}++;
1103       }
1104     }
1105   }
1106
1107   return $collapsed;
1108 }
1109
1110 =head2 get_column
1111
1112 =over 4
1113
1114 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1115
1116 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1117
1118 =back
1119
1120   my $max_length = $rs->get_column('length')->max;
1121
1122 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1123
1124 =cut
1125
1126 sub get_column {
1127   my ($self, $column) = @_;
1128   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1129   return $new;
1130 }
1131
1132 =head2 search_like
1133
1134 =over 4
1135
1136 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1137
1138 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1139
1140 =back
1141
1142   # WHERE title LIKE '%blue%'
1143   $cd_rs = $rs->search_like({ title => '%blue%'});
1144
1145 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1146 that this is simply a convenience method retained for ex Class::DBI users.
1147 You most likely want to use L</search> with specific operators.
1148
1149 For more information, see L<DBIx::Class::Manual::Cookbook>.
1150
1151 This method is deprecated and will be removed in 0.09. Use L</search()>
1152 instead. An example conversion is:
1153
1154   ->search_like({ foo => 'bar' });
1155
1156   # Becomes
1157
1158   ->search({ foo => { like => 'bar' } });
1159
1160 =cut
1161
1162 sub search_like {
1163   my $class = shift;
1164   carp_unique (
1165     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1166    .' Instead use ->search({ x => { -like => "y%" } })'
1167    .' (note the outer pair of {}s - they are important!)'
1168   );
1169   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1170   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1171   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1172   return $class->search($query, { %$attrs });
1173 }
1174
1175 =head2 slice
1176
1177 =over 4
1178
1179 =item Arguments: $first, $last
1180
1181 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1182
1183 =back
1184
1185 Returns a resultset or object list representing a subset of elements from the
1186 resultset slice is called on. Indexes are from 0, i.e., to get the first
1187 three records, call:
1188
1189   my ($one, $two, $three) = $rs->slice(0, 2);
1190
1191 =cut
1192
1193 sub slice {
1194   my ($self, $min, $max) = @_;
1195   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1196   $attrs->{offset} = $self->{attrs}{offset} || 0;
1197   $attrs->{offset} += $min;
1198   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1199   return $self->search(undef, $attrs);
1200   #my $slice = (ref $self)->new($self->result_source, $attrs);
1201   #return (wantarray ? $slice->all : $slice);
1202 }
1203
1204 =head2 next
1205
1206 =over 4
1207
1208 =item Arguments: none
1209
1210 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1211
1212 =back
1213
1214 Returns the next element in the resultset (C<undef> is there is none).
1215
1216 Can be used to efficiently iterate over records in the resultset:
1217
1218   my $rs = $schema->resultset('CD')->search;
1219   while (my $cd = $rs->next) {
1220     print $cd->title;
1221   }
1222
1223 Note that you need to store the resultset object, and call C<next> on it.
1224 Calling C<< resultset('Table')->next >> repeatedly will always return the
1225 first record from the resultset.
1226
1227 =cut
1228
1229 sub next {
1230   my ($self) = @_;
1231   if (my $cache = $self->get_cache) {
1232     $self->{all_cache_position} ||= 0;
1233     return $cache->[$self->{all_cache_position}++];
1234   }
1235   if ($self->{attrs}{cache}) {
1236     delete $self->{pager};
1237     $self->{all_cache_position} = 1;
1238     return ($self->all)[0];
1239   }
1240   if ($self->{stashed_objects}) {
1241     my $obj = shift(@{$self->{stashed_objects}});
1242     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1243     return $obj;
1244   }
1245   my @row = (
1246     exists $self->{stashed_row}
1247       ? @{delete $self->{stashed_row}}
1248       : $self->cursor->next
1249   );
1250   return undef unless (@row);
1251   my ($row, @more) = $self->_construct_object(@row);
1252   $self->{stashed_objects} = \@more if @more;
1253   return $row;
1254 }
1255
1256 sub _construct_object {
1257   my ($self, @row) = @_;
1258
1259   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1260     or return ();
1261   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1262   @new = $self->{_attrs}{record_filter}->(@new)
1263     if exists $self->{_attrs}{record_filter};
1264   return @new;
1265 }
1266
1267 sub _collapse_result {
1268   my ($self, $as_proto, $row) = @_;
1269
1270   my @copy = @$row;
1271
1272   # 'foo'         => [ undef, 'foo' ]
1273   # 'foo.bar'     => [ 'foo', 'bar' ]
1274   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1275
1276   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1277
1278   my %collapse = %{$self->{_attrs}{collapse}||{}};
1279
1280   my @pri_index;
1281
1282   # if we're doing collapsing (has_many prefetch) we need to grab records
1283   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1284   # we know we don't have to bother.
1285
1286   # the reason for not using the collapse stuff directly is because if you
1287   # had for e.g. two artists in a row with no cds, the collapse info for
1288   # both would be NULL (undef) so you'd lose the second artist
1289
1290   # store just the index so we can check the array positions from the row
1291   # without having to contruct the full hash
1292
1293   if (keys %collapse) {
1294     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1295     foreach my $i (0 .. $#construct_as) {
1296       next if defined($construct_as[$i][0]); # only self table
1297       if (delete $pri{$construct_as[$i][1]}) {
1298         push(@pri_index, $i);
1299       }
1300       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1301     }
1302   }
1303
1304   # no need to do an if, it'll be empty if @pri_index is empty anyway
1305
1306   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1307
1308   my @const_rows;
1309
1310   do { # no need to check anything at the front, we always want the first row
1311
1312     my %const;
1313
1314     foreach my $this_as (@construct_as) {
1315       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1316     }
1317
1318     push(@const_rows, \%const);
1319
1320   } until ( # no pri_index => no collapse => drop straight out
1321       !@pri_index
1322     or
1323       do { # get another row, stash it, drop out if different PK
1324
1325         @copy = $self->cursor->next;
1326         $self->{stashed_row} = \@copy;
1327
1328         # last thing in do block, counts as true if anything doesn't match
1329
1330         # check xor defined first for NULL vs. NOT NULL then if one is
1331         # defined the other must be so check string equality
1332
1333         grep {
1334           (defined $pri_vals{$_} ^ defined $copy[$_])
1335           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1336         } @pri_index;
1337       }
1338   );
1339
1340   my $alias = $self->{attrs}{alias};
1341   my $info = [];
1342
1343   my %collapse_pos;
1344
1345   my @const_keys;
1346
1347   foreach my $const (@const_rows) {
1348     scalar @const_keys or do {
1349       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1350     };
1351     foreach my $key (@const_keys) {
1352       if (length $key) {
1353         my $target = $info;
1354         my @parts = split(/\./, $key);
1355         my $cur = '';
1356         my $data = $const->{$key};
1357         foreach my $p (@parts) {
1358           $target = $target->[1]->{$p} ||= [];
1359           $cur .= ".${p}";
1360           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1361             # collapsing at this point and on final part
1362             my $pos = $collapse_pos{$cur};
1363             CK: foreach my $ck (@ckey) {
1364               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1365                 $collapse_pos{$cur} = $data;
1366                 delete @collapse_pos{ # clear all positioning for sub-entries
1367                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1368                 };
1369                 push(@$target, []);
1370                 last CK;
1371               }
1372             }
1373           }
1374           if (exists $collapse{$cur}) {
1375             $target = $target->[-1];
1376           }
1377         }
1378         $target->[0] = $data;
1379       } else {
1380         $info->[0] = $const->{$key};
1381       }
1382     }
1383   }
1384
1385   return $info;
1386 }
1387
1388 =head2 result_source
1389
1390 =over 4
1391
1392 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1393
1394 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1395
1396 =back
1397
1398 An accessor for the primary ResultSource object from which this ResultSet
1399 is derived.
1400
1401 =head2 result_class
1402
1403 =over 4
1404
1405 =item Arguments: $result_class?
1406
1407 =item Return Value: $result_class
1408
1409 =back
1410
1411 An accessor for the class to use when creating result objects. Defaults to
1412 C<< result_source->result_class >> - which in most cases is the name of the
1413 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1414
1415 Note that changing the result_class will also remove any components
1416 that were originally loaded in the source class via
1417 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1418 in the original source class will not run.
1419
1420 =cut
1421
1422 sub result_class {
1423   my ($self, $result_class) = @_;
1424   if ($result_class) {
1425     unless (ref $result_class) { # don't fire this for an object
1426       $self->ensure_class_loaded($result_class);
1427     }
1428     $self->_result_class($result_class);
1429     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1430     # permit the user to set result class on one result set only; it only
1431     # chains if provided to search()
1432     #$self->{attrs}{result_class} = $result_class if ref $self;
1433   }
1434   $self->_result_class;
1435 }
1436
1437 =head2 count
1438
1439 =over 4
1440
1441 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1442
1443 =item Return Value: $count
1444
1445 =back
1446
1447 Performs an SQL C<COUNT> with the same query as the resultset was built
1448 with to find the number of elements. Passing arguments is equivalent to
1449 C<< $rs->search ($cond, \%attrs)->count >>
1450
1451 =cut
1452
1453 sub count {
1454   my $self = shift;
1455   return $self->search(@_)->count if @_ and defined $_[0];
1456   return scalar @{ $self->get_cache } if $self->get_cache;
1457
1458   my $attrs = { %{ $self->_resolved_attrs } };
1459
1460   # this is a little optimization - it is faster to do the limit
1461   # adjustments in software, instead of a subquery
1462   my $rows = delete $attrs->{rows};
1463   my $offset = delete $attrs->{offset};
1464
1465   my $crs;
1466   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1467     $crs = $self->_count_subq_rs ($attrs);
1468   }
1469   else {
1470     $crs = $self->_count_rs ($attrs);
1471   }
1472   my $count = $crs->next;
1473
1474   $count -= $offset if $offset;
1475   $count = $rows if $rows and $rows < $count;
1476   $count = 0 if ($count < 0);
1477
1478   return $count;
1479 }
1480
1481 =head2 count_rs
1482
1483 =over 4
1484
1485 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1486
1487 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1488
1489 =back
1490
1491 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1492 This can be very handy for subqueries:
1493
1494   ->search( { amount => $some_rs->count_rs->as_query } )
1495
1496 As with regular resultsets the SQL query will be executed only after
1497 the resultset is accessed via L</next> or L</all>. That would return
1498 the same single value obtainable via L</count>.
1499
1500 =cut
1501
1502 sub count_rs {
1503   my $self = shift;
1504   return $self->search(@_)->count_rs if @_;
1505
1506   # this may look like a lack of abstraction (count() does about the same)
1507   # but in fact an _rs *must* use a subquery for the limits, as the
1508   # software based limiting can not be ported if this $rs is to be used
1509   # in a subquery itself (i.e. ->as_query)
1510   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1511     return $self->_count_subq_rs;
1512   }
1513   else {
1514     return $self->_count_rs;
1515   }
1516 }
1517
1518 #
1519 # returns a ResultSetColumn object tied to the count query
1520 #
1521 sub _count_rs {
1522   my ($self, $attrs) = @_;
1523
1524   my $rsrc = $self->result_source;
1525   $attrs ||= $self->_resolved_attrs;
1526
1527   my $tmp_attrs = { %$attrs };
1528   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1529   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1530
1531   # overwrite the selector (supplied by the storage)
1532   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1533   $tmp_attrs->{as} = 'count';
1534   delete @{$tmp_attrs}{qw/columns/};
1535
1536   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1537
1538   return $tmp_rs;
1539 }
1540
1541 #
1542 # same as above but uses a subquery
1543 #
1544 sub _count_subq_rs {
1545   my ($self, $attrs) = @_;
1546
1547   my $rsrc = $self->result_source;
1548   $attrs ||= $self->_resolved_attrs;
1549
1550   my $sub_attrs = { %$attrs };
1551   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1552   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1553
1554   # if we multi-prefetch we group_by something unique, as this is what we would
1555   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1556   if ( keys %{$attrs->{collapse}}  ) {
1557     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1558       $rsrc->_identifying_column_set || $self->throw_exception(
1559         'Unable to construct a unique group_by criteria properly collapsing the '
1560       . 'has_many prefetch before count()'
1561       );
1562     } ]
1563   }
1564
1565   # Calculate subquery selector
1566   if (my $g = $sub_attrs->{group_by}) {
1567
1568     my $sql_maker = $rsrc->storage->sql_maker;
1569
1570     # necessary as the group_by may refer to aliased functions
1571     my $sel_index;
1572     for my $sel (@{$attrs->{select}}) {
1573       $sel_index->{$sel->{-as}} = $sel
1574         if (ref $sel eq 'HASH' and $sel->{-as});
1575     }
1576
1577     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1578     # also look for named aggregates referred in the having clause
1579     # having often contains scalarrefs - thus parse it out entirely
1580     my @parts = @$g;
1581     if ($attrs->{having}) {
1582       local $sql_maker->{having_bind};
1583       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1584       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1585       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1586         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1587         # if we don't unset it we screw up retarded but unfortunately working
1588         # 'MAX(foo.bar)' => { '>', 3 }
1589         $sql_maker->{name_sep} = '';
1590       }
1591
1592       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1593
1594       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1595       my %seen_having;
1596
1597       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1598       # and if all fails for an utterly naive quoted scalar-with-function
1599       while ($having_sql =~ /
1600         $rquote $sep $lquote (.+?) $rquote
1601           |
1602         [\s,] \w+ \. (\w+) [\s,]
1603           |
1604         [\s,] $lquote (.+?) $rquote [\s,]
1605       /gx) {
1606         my $part = $1 || $2 || $3;  # one of them matched if we got here
1607         unless ($seen_having{$part}++) {
1608           push @parts, $part;
1609         }
1610       }
1611     }
1612
1613     for (@parts) {
1614       my $colpiece = $sel_index->{$_} || $_;
1615
1616       # unqualify join-based group_by's. Arcane but possible query
1617       # also horrible horrible hack to alias a column (not a func.)
1618       # (probably need to introduce SQLA syntax)
1619       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1620         my $as = $colpiece;
1621         $as =~ s/\./__/;
1622         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1623       }
1624       push @{$sub_attrs->{select}}, $colpiece;
1625     }
1626   }
1627   else {
1628     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1629     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1630   }
1631
1632   return $rsrc->resultset_class
1633                ->new ($rsrc, $sub_attrs)
1634                 ->as_subselect_rs
1635                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1636                   ->get_column ('count');
1637 }
1638
1639 sub _bool {
1640   return 1;
1641 }
1642
1643 =head2 count_literal
1644
1645 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1646 should only be used in that context. See L</search_literal> for further info.
1647
1648 =over 4
1649
1650 =item Arguments: $sql_fragment, @standalone_bind_values
1651
1652 =item Return Value: $count
1653
1654 =back
1655
1656 Counts the results in a literal query. Equivalent to calling L</search_literal>
1657 with the passed arguments, then L</count>.
1658
1659 =cut
1660
1661 sub count_literal { shift->search_literal(@_)->count; }
1662
1663 =head2 all
1664
1665 =over 4
1666
1667 =item Arguments: none
1668
1669 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1670
1671 =back
1672
1673 Returns all elements in the resultset.
1674
1675 =cut
1676
1677 sub all {
1678   my $self = shift;
1679   if(@_) {
1680       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1681   }
1682
1683   return @{ $self->get_cache } if $self->get_cache;
1684
1685   my @obj;
1686
1687   if (keys %{$self->_resolved_attrs->{collapse}}) {
1688     # Using $self->cursor->all is really just an optimisation.
1689     # If we're collapsing has_many prefetches it probably makes
1690     # very little difference, and this is cleaner than hacking
1691     # _construct_object to survive the approach
1692     $self->cursor->reset;
1693     my @row = $self->cursor->next;
1694     while (@row) {
1695       push(@obj, $self->_construct_object(@row));
1696       @row = (exists $self->{stashed_row}
1697                ? @{delete $self->{stashed_row}}
1698                : $self->cursor->next);
1699     }
1700   } else {
1701     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1702   }
1703
1704   $self->set_cache(\@obj) if $self->{attrs}{cache};
1705
1706   return @obj;
1707 }
1708
1709 =head2 reset
1710
1711 =over 4
1712
1713 =item Arguments: none
1714
1715 =item Return Value: $self
1716
1717 =back
1718
1719 Resets the resultset's cursor, so you can iterate through the elements again.
1720 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1721 another query.
1722
1723 =cut
1724
1725 sub reset {
1726   my ($self) = @_;
1727   $self->{all_cache_position} = 0;
1728   $self->cursor->reset;
1729   return $self;
1730 }
1731
1732 =head2 first
1733
1734 =over 4
1735
1736 =item Arguments: none
1737
1738 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1739
1740 =back
1741
1742 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1743 an object for the first result (or C<undef> if the resultset is empty).
1744
1745 =cut
1746
1747 sub first {
1748   return $_[0]->reset->next;
1749 }
1750
1751
1752 # _rs_update_delete
1753 #
1754 # Determines whether and what type of subquery is required for the $rs operation.
1755 # If grouping is necessary either supplies its own, or verifies the current one
1756 # After all is done delegates to the proper storage method.
1757
1758 sub _rs_update_delete {
1759   my ($self, $op, $values) = @_;
1760
1761   my $rsrc = $self->result_source;
1762   my $storage = $rsrc->schema->storage;
1763
1764   my $attrs = { %{$self->_resolved_attrs} };
1765
1766   my $join_classifications;
1767   my $existing_group_by = delete $attrs->{group_by};
1768
1769   # do we need a subquery for any reason?
1770   my $needs_subq = (
1771     defined $existing_group_by
1772       or
1773     # if {from} is unparseable wrap a subq
1774     ref($attrs->{from}) ne 'ARRAY'
1775       or
1776     # limits call for a subq
1777     $self->_has_resolved_attr(qw/rows offset/)
1778   );
1779
1780   # simplify the joinmap, so we can further decide if a subq is necessary
1781   if (!$needs_subq and @{$attrs->{from}} > 1) {
1782     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1783
1784     # check if there are any joins left after the prune
1785     if ( @{$attrs->{from}} > 1 ) {
1786       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1787         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1788         $attrs->{select},
1789         $self->{cond},
1790         $attrs
1791       );
1792
1793       # any non-pruneable joins imply subq
1794       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1795     }
1796   }
1797
1798   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1799   $needs_subq ||= (
1800     (ref $attrs->{from}[0]) ne 'HASH'
1801       or
1802     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1803   );
1804
1805   my ($cond, $guard);
1806   # do we need anything like a subquery?
1807   if (! $needs_subq) {
1808     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1809     # a condition containing 'me' or other table prefixes will not work
1810     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1811     $cond = do {
1812       my $sqla = $rsrc->storage->sql_maker;
1813       local $sqla->{_dequalify_idents} = 1;
1814       \[ $sqla->_recurse_where($self->{cond}) ];
1815     };
1816   }
1817   else {
1818     # we got this far - means it is time to wrap a subquery
1819     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1820       sprintf(
1821         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1822         $op,
1823         $rsrc->source_name,
1824       )
1825     );
1826
1827     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1828     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1829     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1830     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1831     my $subrs = (ref $self)->new($rsrc, $attrs);
1832
1833     if (@$idcols == 1) {
1834       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1835     }
1836     elsif ($storage->_use_multicolumn_in) {
1837       # no syntax for calling this properly yet
1838       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1839       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1840         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1841         $subrs->as_query
1842       ),
1843     }
1844     else {
1845       # if all else fails - get all primary keys and operate over a ORed set
1846       # wrap in a transaction for consistency
1847       # this is where the group_by/multiplication starts to matter
1848       if (
1849         $existing_group_by
1850           or
1851         keys %{ $join_classifications->{multiplying} || {} }
1852       ) {
1853         # make sure if there is a supplied group_by it matches the columns compiled above
1854         # perfectly. Anything else can not be sanely executed on most databases so croak
1855         # right then and there
1856         if ($existing_group_by) {
1857           my @current_group_by = map
1858             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1859             @$existing_group_by
1860           ;
1861
1862           if (
1863             join ("\x00", sort @current_group_by)
1864               ne
1865             join ("\x00", sort @{$attrs->{columns}} )
1866           ) {
1867             $self->throw_exception (
1868               "You have just attempted a $op operation on a resultset which does group_by"
1869               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1870               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1871               . ' kind of queries. Please retry the operation with a modified group_by or'
1872               . ' without using one at all.'
1873             );
1874           }
1875         }
1876
1877         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1878       }
1879
1880       $guard = $storage->txn_scope_guard;
1881
1882       $cond = [];
1883       for my $row ($subrs->cursor->all) {
1884         push @$cond, { map
1885           { $idcols->[$_] => $row->[$_] }
1886           (0 .. $#$idcols)
1887         };
1888       }
1889     }
1890   }
1891
1892   my $res = $storage->$op (
1893     $rsrc,
1894     $op eq 'update' ? $values : (),
1895     $cond,
1896   );
1897
1898   $guard->commit if $guard;
1899
1900   return $res;
1901 }
1902
1903 =head2 update
1904
1905 =over 4
1906
1907 =item Arguments: \%values
1908
1909 =item Return Value: $underlying_storage_rv
1910
1911 =back
1912
1913 Sets the specified columns in the resultset to the supplied values in a
1914 single query. Note that this will not run any accessor/set_column/update
1915 triggers, nor will it update any result object instances derived from this
1916 resultset (this includes the contents of the L<resultset cache|/set_cache>
1917 if any). See L</update_all> if you need to execute any on-update
1918 triggers or cascades defined either by you or a
1919 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1920
1921 The return value is a pass through of what the underlying
1922 storage backend returned, and may vary. See L<DBI/execute> for the most
1923 common case.
1924
1925 =head3 CAVEAT
1926
1927 Note that L</update> does not process/deflate any of the values passed in.
1928 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1929 ensure manually that any value passed to this method will stringify to
1930 something the RDBMS knows how to deal with. A notable example is the
1931 handling of L<DateTime> objects, for more info see:
1932 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1933
1934 =cut
1935
1936 sub update {
1937   my ($self, $values) = @_;
1938   $self->throw_exception('Values for update must be a hash')
1939     unless ref $values eq 'HASH';
1940
1941   return $self->_rs_update_delete ('update', $values);
1942 }
1943
1944 =head2 update_all
1945
1946 =over 4
1947
1948 =item Arguments: \%values
1949
1950 =item Return Value: 1
1951
1952 =back
1953
1954 Fetches all objects and updates them one at a time via
1955 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1956 triggers, while L</update> will not.
1957
1958 =cut
1959
1960 sub update_all {
1961   my ($self, $values) = @_;
1962   $self->throw_exception('Values for update_all must be a hash')
1963     unless ref $values eq 'HASH';
1964
1965   my $guard = $self->result_source->schema->txn_scope_guard;
1966   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1967   $guard->commit;
1968   return 1;
1969 }
1970
1971 =head2 delete
1972
1973 =over 4
1974
1975 =item Arguments: none
1976
1977 =item Return Value: $underlying_storage_rv
1978
1979 =back
1980
1981 Deletes the rows matching this resultset in a single query. Note that this
1982 will not run any delete triggers, nor will it alter the
1983 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1984 derived from this resultset (this includes the contents of the
1985 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1986 execute any on-delete triggers or cascades defined either by you or a
1987 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1988
1989 The return value is a pass through of what the underlying storage backend
1990 returned, and may vary. See L<DBI/execute> for the most common case.
1991
1992 =cut
1993
1994 sub delete {
1995   my $self = shift;
1996   $self->throw_exception('delete does not accept any arguments')
1997     if @_;
1998
1999   return $self->_rs_update_delete ('delete');
2000 }
2001
2002 =head2 delete_all
2003
2004 =over 4
2005
2006 =item Arguments: none
2007
2008 =item Return Value: 1
2009
2010 =back
2011
2012 Fetches all objects and deletes them one at a time via
2013 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2014 triggers, while L</delete> will not.
2015
2016 =cut
2017
2018 sub delete_all {
2019   my $self = shift;
2020   $self->throw_exception('delete_all does not accept any arguments')
2021     if @_;
2022
2023   my $guard = $self->result_source->schema->txn_scope_guard;
2024   $_->delete for $self->all;
2025   $guard->commit;
2026   return 1;
2027 }
2028
2029 =head2 populate
2030
2031 =over 4
2032
2033 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2034
2035 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2036
2037 =back
2038
2039 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2040 arrayrefs.
2041
2042 =over
2043
2044 =item NOTE
2045
2046 The context of this method call has an important effect on what is
2047 submitted to storage. In void context data is fed directly to fastpath
2048 insertion routines provided by the underlying storage (most often
2049 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2050 L<insert|DBIx::Class::Row/insert> calls on the
2051 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2052 augmentation of these methods provided by components. For example if you
2053 are using something like L<DBIx::Class::UUIDColumns> to create primary
2054 keys for you, you will find that your PKs are empty.  In this case you
2055 will have to explicitly force scalar or list context in order to create
2056 those values.
2057
2058 =back
2059
2060 In non-void (scalar or list) context, this method is simply a wrapper
2061 for L</create>. Depending on list or scalar context either a list of
2062 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2063 containing these objects is returned.
2064
2065 When supplying data in "arrayref of arrayrefs" invocation style, the
2066 first element should be a list of column names and each subsequent
2067 element should be a data value in the earlier specified column order.
2068 For example:
2069
2070   $Arstist_rs->populate([
2071     [ qw( artistid name ) ],
2072     [ 100, 'A Formally Unknown Singer' ],
2073     [ 101, 'A singer that jumped the shark two albums ago' ],
2074     [ 102, 'An actually cool singer' ],
2075   ]);
2076
2077 For the arrayref of hashrefs style each hashref should be a structure
2078 suitable for passing to L</create>. Multi-create is also permitted with
2079 this syntax.
2080
2081   $schema->resultset("Artist")->populate([
2082      { artistid => 4, name => 'Manufactured Crap', cds => [
2083         { title => 'My First CD', year => 2006 },
2084         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2085       ],
2086      },
2087      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2088         { title => 'My parents sold me to a record company', year => 2005 },
2089         { title => 'Why Am I So Ugly?', year => 2006 },
2090         { title => 'I Got Surgery and am now Popular', year => 2007 }
2091       ],
2092      },
2093   ]);
2094
2095 If you attempt a void-context multi-create as in the example above (each
2096 Artist also has the related list of CDs), and B<do not> supply the
2097 necessary autoinc foreign key information, this method will proxy to the
2098 less efficient L</create>, and then throw the Result objects away. In this
2099 case there are obviously no benefits to using this method over L</create>.
2100
2101 =cut
2102
2103 sub populate {
2104   my $self = shift;
2105
2106   # cruft placed in standalone method
2107   my $data = $self->_normalize_populate_args(@_);
2108
2109   return unless @$data;
2110
2111   if(defined wantarray) {
2112     my @created = map { $self->create($_) } @$data;
2113     return wantarray ? @created : \@created;
2114   }
2115   else {
2116     my $first = $data->[0];
2117
2118     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2119     # it relationship data
2120     my (@rels, @columns);
2121     my $rsrc = $self->result_source;
2122     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2123     for (keys %$first) {
2124       my $ref = ref $first->{$_};
2125       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2126         ? push @rels, $_
2127         : push @columns, $_
2128       ;
2129     }
2130
2131     my @pks = $rsrc->primary_columns;
2132
2133     ## do the belongs_to relationships
2134     foreach my $index (0..$#$data) {
2135
2136       # delegate to create() for any dataset without primary keys with specified relationships
2137       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2138         for my $r (@rels) {
2139           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2140             my @ret = $self->populate($data);
2141             return;
2142           }
2143         }
2144       }
2145
2146       foreach my $rel (@rels) {
2147         next unless ref $data->[$index]->{$rel} eq "HASH";
2148         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2149         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2150         my $related = $result->result_source->_resolve_condition(
2151           $reverse_relinfo->{cond},
2152           $self,
2153           $result,
2154           $rel,
2155         );
2156
2157         delete $data->[$index]->{$rel};
2158         $data->[$index] = {%{$data->[$index]}, %$related};
2159
2160         push @columns, keys %$related if $index == 0;
2161       }
2162     }
2163
2164     ## inherit the data locked in the conditions of the resultset
2165     my ($rs_data) = $self->_merge_with_rscond({});
2166     delete @{$rs_data}{@columns};
2167
2168     ## do bulk insert on current row
2169     $rsrc->storage->insert_bulk(
2170       $rsrc,
2171       [@columns, keys %$rs_data],
2172       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2173     );
2174
2175     ## do the has_many relationships
2176     foreach my $item (@$data) {
2177
2178       my $main_row;
2179
2180       foreach my $rel (@rels) {
2181         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2182
2183         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2184
2185         my $child = $main_row->$rel;
2186
2187         my $related = $child->result_source->_resolve_condition(
2188           $rels->{$rel}{cond},
2189           $child,
2190           $main_row,
2191           $rel,
2192         );
2193
2194         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2195         my @populate = map { {%$_, %$related} } @rows_to_add;
2196
2197         $child->populate( \@populate );
2198       }
2199     }
2200   }
2201 }
2202
2203
2204 # populate() argumnets went over several incarnations
2205 # What we ultimately support is AoH
2206 sub _normalize_populate_args {
2207   my ($self, $arg) = @_;
2208
2209   if (ref $arg eq 'ARRAY') {
2210     if (!@$arg) {
2211       return [];
2212     }
2213     elsif (ref $arg->[0] eq 'HASH') {
2214       return $arg;
2215     }
2216     elsif (ref $arg->[0] eq 'ARRAY') {
2217       my @ret;
2218       my @colnames = @{$arg->[0]};
2219       foreach my $values (@{$arg}[1 .. $#$arg]) {
2220         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2221       }
2222       return \@ret;
2223     }
2224   }
2225
2226   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2227 }
2228
2229 =head2 pager
2230
2231 =over 4
2232
2233 =item Arguments: none
2234
2235 =item Return Value: L<$pager|Data::Page>
2236
2237 =back
2238
2239 Returns a L<Data::Page> object for the current resultset. Only makes
2240 sense for queries with a C<page> attribute.
2241
2242 To get the full count of entries for a paged resultset, call
2243 C<total_entries> on the L<Data::Page> object.
2244
2245 =cut
2246
2247 sub pager {
2248   my ($self) = @_;
2249
2250   return $self->{pager} if $self->{pager};
2251
2252   my $attrs = $self->{attrs};
2253   if (!defined $attrs->{page}) {
2254     $self->throw_exception("Can't create pager for non-paged rs");
2255   }
2256   elsif ($attrs->{page} <= 0) {
2257     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2258   }
2259   $attrs->{rows} ||= 10;
2260
2261   # throw away the paging flags and re-run the count (possibly
2262   # with a subselect) to get the real total count
2263   my $count_attrs = { %$attrs };
2264   delete $count_attrs->{$_} for qw/rows offset page pager/;
2265
2266   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2267
2268   require DBIx::Class::ResultSet::Pager;
2269   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2270     sub { $total_rs->count },  #lazy-get the total
2271     $attrs->{rows},
2272     $self->{attrs}{page},
2273   );
2274 }
2275
2276 =head2 page
2277
2278 =over 4
2279
2280 =item Arguments: $page_number
2281
2282 =item Return Value: L<$resultset|/search>
2283
2284 =back
2285
2286 Returns a resultset for the $page_number page of the resultset on which page
2287 is called, where each page contains a number of rows equal to the 'rows'
2288 attribute set on the resultset (10 by default).
2289
2290 =cut
2291
2292 sub page {
2293   my ($self, $page) = @_;
2294   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2295 }
2296
2297 =head2 new_result
2298
2299 =over 4
2300
2301 =item Arguments: \%col_data
2302
2303 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2304
2305 =back
2306
2307 Creates a new result object in the resultset's result class and returns
2308 it. The row is not inserted into the database at this point, call
2309 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2310 will tell you whether the result object has been inserted or not.
2311
2312 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2313
2314 =cut
2315
2316 sub new_result {
2317   my ($self, $values) = @_;
2318
2319   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2320     if @_ > 2;
2321
2322   $self->throw_exception( "new_result expects a hashref" )
2323     unless (ref $values eq 'HASH');
2324
2325   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2326
2327   my %new = (
2328     %$merged_cond,
2329     @$cols_from_relations
2330       ? (-cols_from_relations => $cols_from_relations)
2331       : (),
2332     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2333   );
2334
2335   return $self->result_class->new(\%new);
2336 }
2337
2338 # _merge_with_rscond
2339 #
2340 # Takes a simple hash of K/V data and returns its copy merged with the
2341 # condition already present on the resultset. Additionally returns an
2342 # arrayref of value/condition names, which were inferred from related
2343 # objects (this is needed for in-memory related objects)
2344 sub _merge_with_rscond {
2345   my ($self, $data) = @_;
2346
2347   my (%new_data, @cols_from_relations);
2348
2349   my $alias = $self->{attrs}{alias};
2350
2351   if (! defined $self->{cond}) {
2352     # just massage $data below
2353   }
2354   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2355     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2356     @cols_from_relations = keys %new_data;
2357   }
2358   elsif (ref $self->{cond} ne 'HASH') {
2359     $self->throw_exception(
2360       "Can't abstract implicit construct, resultset condition not a hash"
2361     );
2362   }
2363   else {
2364     # precendence must be given to passed values over values inherited from
2365     # the cond, so the order here is important.
2366     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2367     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2368
2369     while ( my($col, $value) = each %implied ) {
2370       my $vref = ref $value;
2371       if (
2372         $vref eq 'HASH'
2373           and
2374         keys(%$value) == 1
2375           and
2376         (keys %$value)[0] eq '='
2377       ) {
2378         $new_data{$col} = $value->{'='};
2379       }
2380       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2381         $new_data{$col} = $value;
2382       }
2383     }
2384   }
2385
2386   %new_data = (
2387     %new_data,
2388     %{ $self->_remove_alias($data, $alias) },
2389   );
2390
2391   return (\%new_data, \@cols_from_relations);
2392 }
2393
2394 # _has_resolved_attr
2395 #
2396 # determines if the resultset defines at least one
2397 # of the attributes supplied
2398 #
2399 # used to determine if a subquery is neccessary
2400 #
2401 # supports some virtual attributes:
2402 #   -join
2403 #     This will scan for any joins being present on the resultset.
2404 #     It is not a mere key-search but a deep inspection of {from}
2405 #
2406
2407 sub _has_resolved_attr {
2408   my ($self, @attr_names) = @_;
2409
2410   my $attrs = $self->_resolved_attrs;
2411
2412   my %extra_checks;
2413
2414   for my $n (@attr_names) {
2415     if (grep { $n eq $_ } (qw/-join/) ) {
2416       $extra_checks{$n}++;
2417       next;
2418     }
2419
2420     my $attr =  $attrs->{$n};
2421
2422     next if not defined $attr;
2423
2424     if (ref $attr eq 'HASH') {
2425       return 1 if keys %$attr;
2426     }
2427     elsif (ref $attr eq 'ARRAY') {
2428       return 1 if @$attr;
2429     }
2430     else {
2431       return 1 if $attr;
2432     }
2433   }
2434
2435   # a resolved join is expressed as a multi-level from
2436   return 1 if (
2437     $extra_checks{-join}
2438       and
2439     ref $attrs->{from} eq 'ARRAY'
2440       and
2441     @{$attrs->{from}} > 1
2442   );
2443
2444   return 0;
2445 }
2446
2447 # _collapse_cond
2448 #
2449 # Recursively collapse the condition.
2450
2451 sub _collapse_cond {
2452   my ($self, $cond, $collapsed) = @_;
2453
2454   $collapsed ||= {};
2455
2456   if (ref $cond eq 'ARRAY') {
2457     foreach my $subcond (@$cond) {
2458       next unless ref $subcond;  # -or
2459       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2460     }
2461   }
2462   elsif (ref $cond eq 'HASH') {
2463     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2464       foreach my $subcond (@{$cond->{-and}}) {
2465         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2466       }
2467     }
2468     else {
2469       foreach my $col (keys %$cond) {
2470         my $value = $cond->{$col};
2471         $collapsed->{$col} = $value;
2472       }
2473     }
2474   }
2475
2476   return $collapsed;
2477 }
2478
2479 # _remove_alias
2480 #
2481 # Remove the specified alias from the specified query hash. A copy is made so
2482 # the original query is not modified.
2483
2484 sub _remove_alias {
2485   my ($self, $query, $alias) = @_;
2486
2487   my %orig = %{ $query || {} };
2488   my %unaliased;
2489
2490   foreach my $key (keys %orig) {
2491     if ($key !~ /\./) {
2492       $unaliased{$key} = $orig{$key};
2493       next;
2494     }
2495     $unaliased{$1} = $orig{$key}
2496       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2497   }
2498
2499   return \%unaliased;
2500 }
2501
2502 =head2 as_query
2503
2504 =over 4
2505
2506 =item Arguments: none
2507
2508 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2509
2510 =back
2511
2512 Returns the SQL query and bind vars associated with the invocant.
2513
2514 This is generally used as the RHS for a subquery.
2515
2516 =cut
2517
2518 sub as_query {
2519   my $self = shift;
2520
2521   my $attrs = { %{ $self->_resolved_attrs } };
2522
2523   # For future use:
2524   #
2525   # in list ctx:
2526   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2527   # $sql also has no wrapping parenthesis in list ctx
2528   #
2529   my $sqlbind = $self->result_source->storage
2530     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2531
2532   return $sqlbind;
2533 }
2534
2535 =head2 find_or_new
2536
2537 =over 4
2538
2539 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2540
2541 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2542
2543 =back
2544
2545   my $artist = $schema->resultset('Artist')->find_or_new(
2546     { artist => 'fred' }, { key => 'artists' });
2547
2548   $cd->cd_to_producer->find_or_new({ producer => $producer },
2549                                    { key => 'primary });
2550
2551 Find an existing record from this resultset using L</find>. if none exists,
2552 instantiate a new result object and return it. The object will not be saved
2553 into your storage until you call L<DBIx::Class::Row/insert> on it.
2554
2555 You most likely want this method when looking for existing rows using a unique
2556 constraint that is not the primary key, or looking for related rows.
2557
2558 If you want objects to be saved immediately, use L</find_or_create> instead.
2559
2560 B<Note>: Make sure to read the documentation of L</find> and understand the
2561 significance of the C<key> attribute, as its lack may skew your search, and
2562 subsequently result in spurious new objects.
2563
2564 B<Note>: Take care when using C<find_or_new> with a table having
2565 columns with default values that you intend to be automatically
2566 supplied by the database (e.g. an auto_increment primary key column).
2567 In normal usage, the value of such columns should NOT be included at
2568 all in the call to C<find_or_new>, even when set to C<undef>.
2569
2570 =cut
2571
2572 sub find_or_new {
2573   my $self     = shift;
2574   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2575   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2576   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2577     return $row;
2578   }
2579   return $self->new_result($hash);
2580 }
2581
2582 =head2 create
2583
2584 =over 4
2585
2586 =item Arguments: \%col_data
2587
2588 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2589
2590 =back
2591
2592 Attempt to create a single new row or a row with multiple related rows
2593 in the table represented by the resultset (and related tables). This
2594 will not check for duplicate rows before inserting, use
2595 L</find_or_create> to do that.
2596
2597 To create one row for this resultset, pass a hashref of key/value
2598 pairs representing the columns of the table and the values you wish to
2599 store. If the appropriate relationships are set up, foreign key fields
2600 can also be passed an object representing the foreign row, and the
2601 value will be set to its primary key.
2602
2603 To create related objects, pass a hashref of related-object column values
2604 B<keyed on the relationship name>. If the relationship is of type C<multi>
2605 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2606 The process will correctly identify columns holding foreign keys, and will
2607 transparently populate them from the keys of the corresponding relation.
2608 This can be applied recursively, and will work correctly for a structure
2609 with an arbitrary depth and width, as long as the relationships actually
2610 exists and the correct column data has been supplied.
2611
2612 Instead of hashrefs of plain related data (key/value pairs), you may
2613 also pass new or inserted objects. New objects (not inserted yet, see
2614 L</new_result>), will be inserted into their appropriate tables.
2615
2616 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2617
2618 Example of creating a new row.
2619
2620   $person_rs->create({
2621     name=>"Some Person",
2622     email=>"somebody@someplace.com"
2623   });
2624
2625 Example of creating a new row and also creating rows in a related C<has_many>
2626 or C<has_one> resultset.  Note Arrayref.
2627
2628   $artist_rs->create(
2629      { artistid => 4, name => 'Manufactured Crap', cds => [
2630         { title => 'My First CD', year => 2006 },
2631         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2632       ],
2633      },
2634   );
2635
2636 Example of creating a new row and also creating a row in a related
2637 C<belongs_to> resultset. Note Hashref.
2638
2639   $cd_rs->create({
2640     title=>"Music for Silly Walks",
2641     year=>2000,
2642     artist => {
2643       name=>"Silly Musician",
2644     }
2645   });
2646
2647 =over
2648
2649 =item WARNING
2650
2651 When subclassing ResultSet never attempt to override this method. Since
2652 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2653 lot of the internals simply never call it, so your override will be
2654 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2655 or L<DBIx::Class::Row/insert> depending on how early in the
2656 L</create> process you need to intervene. See also warning pertaining to
2657 L</new>.
2658
2659 =back
2660
2661 =cut
2662
2663 sub create {
2664   my ($self, $attrs) = @_;
2665   $self->throw_exception( "create needs a hashref" )
2666     unless ref $attrs eq 'HASH';
2667   return $self->new_result($attrs)->insert;
2668 }
2669
2670 =head2 find_or_create
2671
2672 =over 4
2673
2674 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2675
2676 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2677
2678 =back
2679
2680   $cd->cd_to_producer->find_or_create({ producer => $producer },
2681                                       { key => 'primary' });
2682
2683 Tries to find a record based on its primary key or unique constraints; if none
2684 is found, creates one and returns that instead.
2685
2686   my $cd = $schema->resultset('CD')->find_or_create({
2687     cdid   => 5,
2688     artist => 'Massive Attack',
2689     title  => 'Mezzanine',
2690     year   => 2005,
2691   });
2692
2693 Also takes an optional C<key> attribute, to search by a specific key or unique
2694 constraint. For example:
2695
2696   my $cd = $schema->resultset('CD')->find_or_create(
2697     {
2698       artist => 'Massive Attack',
2699       title  => 'Mezzanine',
2700     },
2701     { key => 'cd_artist_title' }
2702   );
2703
2704 B<Note>: Make sure to read the documentation of L</find> and understand the
2705 significance of the C<key> attribute, as its lack may skew your search, and
2706 subsequently result in spurious row creation.
2707
2708 B<Note>: Because find_or_create() reads from the database and then
2709 possibly inserts based on the result, this method is subject to a race
2710 condition. Another process could create a record in the table after
2711 the find has completed and before the create has started. To avoid
2712 this problem, use find_or_create() inside a transaction.
2713
2714 B<Note>: Take care when using C<find_or_create> with a table having
2715 columns with default values that you intend to be automatically
2716 supplied by the database (e.g. an auto_increment primary key column).
2717 In normal usage, the value of such columns should NOT be included at
2718 all in the call to C<find_or_create>, even when set to C<undef>.
2719
2720 See also L</find> and L</update_or_create>. For information on how to declare
2721 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2722
2723 If you need to know if an existing row was found or a new one created use
2724 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2725 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2726 database!
2727
2728   my $cd = $schema->resultset('CD')->find_or_new({
2729     cdid   => 5,
2730     artist => 'Massive Attack',
2731     title  => 'Mezzanine',
2732     year   => 2005,
2733   });
2734
2735   if( !$cd->in_storage ) {
2736       # do some stuff
2737       $cd->insert;
2738   }
2739
2740 =cut
2741
2742 sub find_or_create {
2743   my $self     = shift;
2744   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2745   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2746   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2747     return $row;
2748   }
2749   return $self->create($hash);
2750 }
2751
2752 =head2 update_or_create
2753
2754 =over 4
2755
2756 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2757
2758 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2759
2760 =back
2761
2762   $resultset->update_or_create({ col => $val, ... });
2763
2764 Like L</find_or_create>, but if a row is found it is immediately updated via
2765 C<< $found_row->update (\%col_data) >>.
2766
2767
2768 Takes an optional C<key> attribute to search on a specific unique constraint.
2769 For example:
2770
2771   # In your application
2772   my $cd = $schema->resultset('CD')->update_or_create(
2773     {
2774       artist => 'Massive Attack',
2775       title  => 'Mezzanine',
2776       year   => 1998,
2777     },
2778     { key => 'cd_artist_title' }
2779   );
2780
2781   $cd->cd_to_producer->update_or_create({
2782     producer => $producer,
2783     name => 'harry',
2784   }, {
2785     key => 'primary',
2786   });
2787
2788 B<Note>: Make sure to read the documentation of L</find> and understand the
2789 significance of the C<key> attribute, as its lack may skew your search, and
2790 subsequently result in spurious row creation.
2791
2792 B<Note>: Take care when using C<update_or_create> with a table having
2793 columns with default values that you intend to be automatically
2794 supplied by the database (e.g. an auto_increment primary key column).
2795 In normal usage, the value of such columns should NOT be included at
2796 all in the call to C<update_or_create>, even when set to C<undef>.
2797
2798 See also L</find> and L</find_or_create>. For information on how to declare
2799 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2800
2801 If you need to know if an existing row was updated or a new one created use
2802 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2803 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2804 database!
2805
2806 =cut
2807
2808 sub update_or_create {
2809   my $self = shift;
2810   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2811   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2812
2813   my $row = $self->find($cond, $attrs);
2814   if (defined $row) {
2815     $row->update($cond);
2816     return $row;
2817   }
2818
2819   return $self->create($cond);
2820 }
2821
2822 =head2 update_or_new
2823
2824 =over 4
2825
2826 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2827
2828 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2829
2830 =back
2831
2832   $resultset->update_or_new({ col => $val, ... });
2833
2834 Like L</find_or_new> but if a row is found it is immediately updated via
2835 C<< $found_row->update (\%col_data) >>.
2836
2837 For example:
2838
2839   # In your application
2840   my $cd = $schema->resultset('CD')->update_or_new(
2841     {
2842       artist => 'Massive Attack',
2843       title  => 'Mezzanine',
2844       year   => 1998,
2845     },
2846     { key => 'cd_artist_title' }
2847   );
2848
2849   if ($cd->in_storage) {
2850       # the cd was updated
2851   }
2852   else {
2853       # the cd is not yet in the database, let's insert it
2854       $cd->insert;
2855   }
2856
2857 B<Note>: Make sure to read the documentation of L</find> and understand the
2858 significance of the C<key> attribute, as its lack may skew your search, and
2859 subsequently result in spurious new objects.
2860
2861 B<Note>: Take care when using C<update_or_new> with a table having
2862 columns with default values that you intend to be automatically
2863 supplied by the database (e.g. an auto_increment primary key column).
2864 In normal usage, the value of such columns should NOT be included at
2865 all in the call to C<update_or_new>, even when set to C<undef>.
2866
2867 See also L</find>, L</find_or_create> and L</find_or_new>.
2868
2869 =cut
2870
2871 sub update_or_new {
2872     my $self  = shift;
2873     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2874     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2875
2876     my $row = $self->find( $cond, $attrs );
2877     if ( defined $row ) {
2878         $row->update($cond);
2879         return $row;
2880     }
2881
2882     return $self->new_result($cond);
2883 }
2884
2885 =head2 get_cache
2886
2887 =over 4
2888
2889 =item Arguments: none
2890
2891 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2892
2893 =back
2894
2895 Gets the contents of the cache for the resultset, if the cache is set.
2896
2897 The cache is populated either by using the L</prefetch> attribute to
2898 L</search> or by calling L</set_cache>.
2899
2900 =cut
2901
2902 sub get_cache {
2903   shift->{all_cache};
2904 }
2905
2906 =head2 set_cache
2907
2908 =over 4
2909
2910 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2911
2912 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2913
2914 =back
2915
2916 Sets the contents of the cache for the resultset. Expects an arrayref
2917 of objects of the same class as those produced by the resultset. Note that
2918 if the cache is set, the resultset will return the cached objects rather
2919 than re-querying the database even if the cache attr is not set.
2920
2921 The contents of the cache can also be populated by using the
2922 L</prefetch> attribute to L</search>.
2923
2924 =cut
2925
2926 sub set_cache {
2927   my ( $self, $data ) = @_;
2928   $self->throw_exception("set_cache requires an arrayref")
2929       if defined($data) && (ref $data ne 'ARRAY');
2930   $self->{all_cache} = $data;
2931 }
2932
2933 =head2 clear_cache
2934
2935 =over 4
2936
2937 =item Arguments: none
2938
2939 =item Return Value: undef
2940
2941 =back
2942
2943 Clears the cache for the resultset.
2944
2945 =cut
2946
2947 sub clear_cache {
2948   shift->set_cache(undef);
2949 }
2950
2951 =head2 is_paged
2952
2953 =over 4
2954
2955 =item Arguments: none
2956
2957 =item Return Value: true, if the resultset has been paginated
2958
2959 =back
2960
2961 =cut
2962
2963 sub is_paged {
2964   my ($self) = @_;
2965   return !!$self->{attrs}{page};
2966 }
2967
2968 =head2 is_ordered
2969
2970 =over 4
2971
2972 =item Arguments: none
2973
2974 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2975
2976 =back
2977
2978 =cut
2979
2980 sub is_ordered {
2981   my ($self) = @_;
2982   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2983 }
2984
2985 =head2 related_resultset
2986
2987 =over 4
2988
2989 =item Arguments: $rel_name
2990
2991 =item Return Value: L<$resultset|/search>
2992
2993 =back
2994
2995 Returns a related resultset for the supplied relationship name.
2996
2997   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2998
2999 =cut
3000
3001 sub related_resultset {
3002   my ($self, $rel) = @_;
3003
3004   $self->{related_resultsets} ||= {};
3005   return $self->{related_resultsets}{$rel} ||= do {
3006     my $rsrc = $self->result_source;
3007     my $rel_info = $rsrc->relationship_info($rel);
3008
3009     $self->throw_exception(
3010       "search_related: result source '" . $rsrc->source_name .
3011         "' has no such relationship $rel")
3012       unless $rel_info;
3013
3014     my $attrs = $self->_chain_relationship($rel);
3015
3016     my $join_count = $attrs->{seen_join}{$rel};
3017
3018     my $alias = $self->result_source->storage
3019         ->relname_to_table_alias($rel, $join_count);
3020
3021     # since this is search_related, and we already slid the select window inwards
3022     # (the select/as attrs were deleted in the beginning), we need to flip all
3023     # left joins to inner, so we get the expected results
3024     # read the comment on top of the actual function to see what this does
3025     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3026
3027
3028     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3029     delete @{$attrs}{qw(result_class alias)};
3030
3031     my $new_cache;
3032
3033     if (my $cache = $self->get_cache) {
3034       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3035         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3036                         @$cache ];
3037       }
3038     }
3039
3040     my $rel_source = $rsrc->related_source($rel);
3041
3042     my $new = do {
3043
3044       # The reason we do this now instead of passing the alias to the
3045       # search_rs below is that if you wrap/overload resultset on the
3046       # source you need to know what alias it's -going- to have for things
3047       # to work sanely (e.g. RestrictWithObject wants to be able to add
3048       # extra query restrictions, and these may need to be $alias.)
3049
3050       my $rel_attrs = $rel_source->resultset_attributes;
3051       local $rel_attrs->{alias} = $alias;
3052
3053       $rel_source->resultset
3054                  ->search_rs(
3055                      undef, {
3056                        %$attrs,
3057                        where => $attrs->{where},
3058                    });
3059     };
3060     $new->set_cache($new_cache) if $new_cache;
3061     $new;
3062   };
3063 }
3064
3065 =head2 current_source_alias
3066
3067 =over 4
3068
3069 =item Arguments: none
3070
3071 =item Return Value: $source_alias
3072
3073 =back
3074
3075 Returns the current table alias for the result source this resultset is built
3076 on, that will be used in the SQL query. Usually it is C<me>.
3077
3078 Currently the source alias that refers to the result set returned by a
3079 L</search>/L</find> family method depends on how you got to the resultset: it's
3080 C<me> by default, but eg. L</search_related> aliases it to the related result
3081 source name (and keeps C<me> referring to the original result set). The long
3082 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3083 (and make this method unnecessary).
3084
3085 Thus it's currently necessary to use this method in predefined queries (see
3086 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3087 source alias of the current result set:
3088
3089   # in a result set class
3090   sub modified_by {
3091     my ($self, $user) = @_;
3092
3093     my $me = $self->current_source_alias;
3094
3095     return $self->search({
3096       "$me.modified" => $user->id,
3097     });
3098   }
3099
3100 =cut
3101
3102 sub current_source_alias {
3103   return (shift->{attrs} || {})->{alias} || 'me';
3104 }
3105
3106 =head2 as_subselect_rs
3107
3108 =over 4
3109
3110 =item Arguments: none
3111
3112 =item Return Value: L<$resultset|/search>
3113
3114 =back
3115
3116 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3117 "virtual view" by including it as a subquery within the from clause.  From this
3118 point on, any joined tables are inaccessible to ->search on the resultset (as if
3119 it were simply where-filtered without joins).  For example:
3120
3121  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3122
3123  # 'x' now pollutes the query namespace
3124
3125  # So the following works as expected
3126  my $ok_rs = $rs->search({'x.other' => 1});
3127
3128  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3129  # def) we look for one row with contradictory terms and join in another table
3130  # (aliased 'x_2') which we never use
3131  my $broken_rs = $rs->search({'x.name' => 'def'});
3132
3133  my $rs2 = $rs->as_subselect_rs;
3134
3135  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3136  my $not_joined_rs = $rs2->search({'x.other' => 1});
3137
3138  # works as expected: finds a 'table' row related to two x rows (abc and def)
3139  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3140
3141 Another example of when one might use this would be to select a subset of
3142 columns in a group by clause:
3143
3144  my $rs = $schema->resultset('Bar')->search(undef, {
3145    group_by => [qw{ id foo_id baz_id }],
3146  })->as_subselect_rs->search(undef, {
3147    columns => [qw{ id foo_id }]
3148  });
3149
3150 In the above example normally columns would have to be equal to the group by,
3151 but because we isolated the group by into a subselect the above works.
3152
3153 =cut
3154
3155 sub as_subselect_rs {
3156   my $self = shift;
3157
3158   my $attrs = $self->_resolved_attrs;
3159
3160   my $fresh_rs = (ref $self)->new (
3161     $self->result_source
3162   );
3163
3164   # these pieces will be locked in the subquery
3165   delete $fresh_rs->{cond};
3166   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3167
3168   return $fresh_rs->search( {}, {
3169     from => [{
3170       $attrs->{alias} => $self->as_query,
3171       -alias  => $attrs->{alias},
3172       -rsrc   => $self->result_source,
3173     }],
3174     alias => $attrs->{alias},
3175   });
3176 }
3177
3178 # This code is called by search_related, and makes sure there
3179 # is clear separation between the joins before, during, and
3180 # after the relationship. This information is needed later
3181 # in order to properly resolve prefetch aliases (any alias
3182 # with a relation_chain_depth less than the depth of the
3183 # current prefetch is not considered)
3184 #
3185 # The increments happen twice per join. An even number means a
3186 # relationship specified via a search_related, whereas an odd
3187 # number indicates a join/prefetch added via attributes
3188 #
3189 # Also this code will wrap the current resultset (the one we
3190 # chain to) in a subselect IFF it contains limiting attributes
3191 sub _chain_relationship {
3192   my ($self, $rel) = @_;
3193   my $source = $self->result_source;
3194   my $attrs = { %{$self->{attrs}||{}} };
3195
3196   # we need to take the prefetch the attrs into account before we
3197   # ->_resolve_join as otherwise they get lost - captainL
3198   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3199
3200   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3201
3202   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3203
3204   my $from;
3205   my @force_subq_attrs = qw/offset rows group_by having/;
3206
3207   if (
3208     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3209       ||
3210     $self->_has_resolved_attr (@force_subq_attrs)
3211   ) {
3212     # Nuke the prefetch (if any) before the new $rs attrs
3213     # are resolved (prefetch is useless - we are wrapping
3214     # a subquery anyway).
3215     my $rs_copy = $self->search;
3216     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3217       $rs_copy->{attrs}{join},
3218       delete $rs_copy->{attrs}{prefetch},
3219     );
3220
3221     $from = [{
3222       -rsrc   => $source,
3223       -alias  => $attrs->{alias},
3224       $attrs->{alias} => $rs_copy->as_query,
3225     }];
3226     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3227     $seen->{-relation_chain_depth} = 0;
3228   }
3229   elsif ($attrs->{from}) {  #shallow copy suffices
3230     $from = [ @{$attrs->{from}} ];
3231   }
3232   else {
3233     $from = [{
3234       -rsrc  => $source,
3235       -alias => $attrs->{alias},
3236       $attrs->{alias} => $source->from,
3237     }];
3238   }
3239
3240   my $jpath = ($seen->{-relation_chain_depth})
3241     ? $from->[-1][0]{-join_path}
3242     : [];
3243
3244   my @requested_joins = $source->_resolve_join(
3245     $join,
3246     $attrs->{alias},
3247     $seen,
3248     $jpath,
3249   );
3250
3251   push @$from, @requested_joins;
3252
3253   $seen->{-relation_chain_depth}++;
3254
3255   # if $self already had a join/prefetch specified on it, the requested
3256   # $rel might very well be already included. What we do in this case
3257   # is effectively a no-op (except that we bump up the chain_depth on
3258   # the join in question so we could tell it *is* the search_related)
3259   my $already_joined;
3260
3261   # we consider the last one thus reverse
3262   for my $j (reverse @requested_joins) {
3263     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3264     if ($rel eq $last_j) {
3265       $j->[0]{-relation_chain_depth}++;
3266       $already_joined++;
3267       last;
3268     }
3269   }
3270
3271   unless ($already_joined) {
3272     push @$from, $source->_resolve_join(
3273       $rel,
3274       $attrs->{alias},
3275       $seen,
3276       $jpath,
3277     );
3278   }
3279
3280   $seen->{-relation_chain_depth}++;
3281
3282   return {%$attrs, from => $from, seen_join => $seen};
3283 }
3284
3285 sub _resolved_attrs {
3286   my $self = shift;
3287   return $self->{_attrs} if $self->{_attrs};
3288
3289   my $attrs  = { %{ $self->{attrs} || {} } };
3290   my $source = $self->result_source;
3291   my $alias  = $attrs->{alias};
3292
3293   # default selection list
3294   $attrs->{columns} = [ $source->columns ]
3295     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3296
3297   # merge selectors together
3298   for (qw/columns select as/) {
3299     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3300       if $attrs->{$_} or $attrs->{"+$_"};
3301   }
3302
3303   # disassemble columns
3304   my (@sel, @as);
3305   if (my $cols = delete $attrs->{columns}) {
3306     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3307       if (ref $c eq 'HASH') {
3308         for my $as (sort keys %$c) {
3309           push @sel, $c->{$as};
3310           push @as, $as;
3311         }
3312       }
3313       else {
3314         push @sel, $c;
3315         push @as, $c;
3316       }
3317     }
3318   }
3319
3320   # when trying to weed off duplicates later do not go past this point -
3321   # everything added from here on is unbalanced "anyone's guess" stuff
3322   my $dedup_stop_idx = $#as;
3323
3324   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3325     if $attrs->{as};
3326   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3327     if $attrs->{select};
3328
3329   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3330   for (@sel) {
3331     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3332   }
3333
3334   # disqualify all $alias.col as-bits (collapser mandated)
3335   for (@as) {
3336     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3337   }
3338
3339   # de-duplicate the result (remove *identical* select/as pairs)
3340   # and also die on duplicate {as} pointing to different {select}s
3341   # not using a c-style for as the condition is prone to shrinkage
3342   my $seen;
3343   my $i = 0;
3344   while ($i <= $dedup_stop_idx) {
3345     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3346       splice @sel, $i, 1;
3347       splice @as, $i, 1;
3348       $dedup_stop_idx--;
3349     }
3350     elsif ($seen->{$as[$i]}++) {
3351       $self->throw_exception(
3352         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3353       );
3354     }
3355     else {
3356       $i++;
3357     }
3358   }
3359
3360   $attrs->{select} = \@sel;
3361   $attrs->{as} = \@as;
3362
3363   $attrs->{from} ||= [{
3364     -rsrc   => $source,
3365     -alias  => $self->{attrs}{alias},
3366     $self->{attrs}{alias} => $source->from,
3367   }];
3368
3369   if ( $attrs->{join} || $attrs->{prefetch} ) {
3370
3371     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3372       if ref $attrs->{from} ne 'ARRAY';
3373
3374     my $join = (delete $attrs->{join}) || {};
3375
3376     if ( defined $attrs->{prefetch} ) {
3377       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3378     }
3379
3380     $attrs->{from} =    # have to copy here to avoid corrupting the original
3381       [
3382         @{ $attrs->{from} },
3383         $source->_resolve_join(
3384           $join,
3385           $alias,
3386           { %{ $attrs->{seen_join} || {} } },
3387           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3388             ? $attrs->{from}[-1][0]{-join_path}
3389             : []
3390           ,
3391         )
3392       ];
3393   }
3394
3395   if ( defined $attrs->{order_by} ) {
3396     $attrs->{order_by} = (
3397       ref( $attrs->{order_by} ) eq 'ARRAY'
3398       ? [ @{ $attrs->{order_by} } ]
3399       : [ $attrs->{order_by} || () ]
3400     );
3401   }
3402
3403   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3404     $attrs->{group_by} = [ $attrs->{group_by} ];
3405   }
3406
3407   # generate the distinct induced group_by early, as prefetch will be carried via a
3408   # subquery (since a group_by is present)
3409   if (delete $attrs->{distinct}) {
3410     if ($attrs->{group_by}) {
3411       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3412     }
3413     else {
3414       # distinct affects only the main selection part, not what prefetch may
3415       # add below.
3416       $attrs->{group_by} = $source->storage->_group_over_selection (
3417         $attrs->{from},
3418         $attrs->{select},
3419         $attrs->{order_by},
3420       );
3421     }
3422   }
3423
3424   $attrs->{collapse} ||= {};
3425   if ($attrs->{prefetch}) {
3426
3427     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3428       if $attrs->{_dark_selector};
3429
3430     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3431
3432     my $prefetch_ordering = [];
3433
3434     # this is a separate structure (we don't look in {from} directly)
3435     # as the resolver needs to shift things off the lists to work
3436     # properly (identical-prefetches on different branches)
3437     my $join_map = {};
3438     if (ref $attrs->{from} eq 'ARRAY') {
3439
3440       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3441
3442       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3443         next unless $j->[0]{-alias};
3444         next unless $j->[0]{-join_path};
3445         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3446
3447         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3448
3449         my $p = $join_map;
3450         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3451         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3452       }
3453     }
3454
3455     my @prefetch =
3456       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3457
3458     # we need to somehow mark which columns came from prefetch
3459     if (@prefetch) {
3460       my $sel_end = $#{$attrs->{select}};
3461       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3462     }
3463
3464     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3465     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3466
3467     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3468     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3469   }
3470
3471   # if both page and offset are specified, produce a combined offset
3472   # even though it doesn't make much sense, this is what pre 081xx has
3473   # been doing
3474   if (my $page = delete $attrs->{page}) {
3475     $attrs->{offset} =
3476       ($attrs->{rows} * ($page - 1))
3477             +
3478       ($attrs->{offset} || 0)
3479     ;
3480   }
3481
3482   return $self->{_attrs} = $attrs;
3483 }
3484
3485 sub _rollout_attr {
3486   my ($self, $attr) = @_;
3487
3488   if (ref $attr eq 'HASH') {
3489     return $self->_rollout_hash($attr);
3490   } elsif (ref $attr eq 'ARRAY') {
3491     return $self->_rollout_array($attr);
3492   } else {
3493     return [$attr];
3494   }
3495 }
3496
3497 sub _rollout_array {
3498   my ($self, $attr) = @_;
3499
3500   my @rolled_array;
3501   foreach my $element (@{$attr}) {
3502     if (ref $element eq 'HASH') {
3503       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3504     } elsif (ref $element eq 'ARRAY') {
3505       #  XXX - should probably recurse here
3506       push( @rolled_array, @{$self->_rollout_array($element)} );
3507     } else {
3508       push( @rolled_array, $element );
3509     }
3510   }
3511   return \@rolled_array;
3512 }
3513
3514 sub _rollout_hash {
3515   my ($self, $attr) = @_;
3516
3517   my @rolled_array;
3518   foreach my $key (keys %{$attr}) {
3519     push( @rolled_array, { $key => $attr->{$key} } );
3520   }
3521   return \@rolled_array;
3522 }
3523
3524 sub _calculate_score {
3525   my ($self, $a, $b) = @_;
3526
3527   if (defined $a xor defined $b) {
3528     return 0;
3529   }
3530   elsif (not defined $a) {
3531     return 1;
3532   }
3533
3534   if (ref $b eq 'HASH') {
3535     my ($b_key) = keys %{$b};
3536     if (ref $a eq 'HASH') {
3537       my ($a_key) = keys %{$a};
3538       if ($a_key eq $b_key) {
3539         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3540       } else {
3541         return 0;
3542       }
3543     } else {
3544       return ($a eq $b_key) ? 1 : 0;
3545     }
3546   } else {
3547     if (ref $a eq 'HASH') {
3548       my ($a_key) = keys %{$a};
3549       return ($b eq $a_key) ? 1 : 0;
3550     } else {
3551       return ($b eq $a) ? 1 : 0;
3552     }
3553   }
3554 }
3555
3556 sub _merge_joinpref_attr {
3557   my ($self, $orig, $import) = @_;
3558
3559   return $import unless defined($orig);
3560   return $orig unless defined($import);
3561
3562   $orig = $self->_rollout_attr($orig);
3563   $import = $self->_rollout_attr($import);
3564
3565   my $seen_keys;
3566   foreach my $import_element ( @{$import} ) {
3567     # find best candidate from $orig to merge $b_element into
3568     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3569     foreach my $orig_element ( @{$orig} ) {
3570       my $score = $self->_calculate_score( $orig_element, $import_element );
3571       if ($score > $best_candidate->{score}) {
3572         $best_candidate->{position} = $position;
3573         $best_candidate->{score} = $score;
3574       }
3575       $position++;
3576     }
3577     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3578     $import_key = '' if not defined $import_key;
3579
3580     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3581       push( @{$orig}, $import_element );
3582     } else {
3583       my $orig_best = $orig->[$best_candidate->{position}];
3584       # merge orig_best and b_element together and replace original with merged
3585       if (ref $orig_best ne 'HASH') {
3586         $orig->[$best_candidate->{position}] = $import_element;
3587       } elsif (ref $import_element eq 'HASH') {
3588         my ($key) = keys %{$orig_best};
3589         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3590       }
3591     }
3592     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3593   }
3594
3595   return $orig;
3596 }
3597
3598 {
3599   my $hm;
3600
3601   sub _merge_attr {
3602     $hm ||= do {
3603       require Hash::Merge;
3604       my $hm = Hash::Merge->new;
3605
3606       $hm->specify_behavior({
3607         SCALAR => {
3608           SCALAR => sub {
3609             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3610
3611             if ($defl xor $defr) {
3612               return [ $defl ? $_[0] : $_[1] ];
3613             }
3614             elsif (! $defl) {
3615               return [];
3616             }
3617             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3618               return [ $_[0] ];
3619             }
3620             else {
3621               return [$_[0], $_[1]];
3622             }
3623           },
3624           ARRAY => sub {
3625             return $_[1] if !defined $_[0];
3626             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3627             return [$_[0], @{$_[1]}]
3628           },
3629           HASH  => sub {
3630             return [] if !defined $_[0] and !keys %{$_[1]};
3631             return [ $_[1] ] if !defined $_[0];
3632             return [ $_[0] ] if !keys %{$_[1]};
3633             return [$_[0], $_[1]]
3634           },
3635         },
3636         ARRAY => {
3637           SCALAR => sub {
3638             return $_[0] if !defined $_[1];
3639             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3640             return [@{$_[0]}, $_[1]]
3641           },
3642           ARRAY => sub {
3643             my @ret = @{$_[0]} or return $_[1];
3644             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3645             my %idx = map { $_ => 1 } @ret;
3646             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3647             \@ret;
3648           },
3649           HASH => sub {
3650             return [ $_[1] ] if ! @{$_[0]};
3651             return $_[0] if !keys %{$_[1]};
3652             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3653             return [ @{$_[0]}, $_[1] ];
3654           },
3655         },
3656         HASH => {
3657           SCALAR => sub {
3658             return [] if !keys %{$_[0]} and !defined $_[1];
3659             return [ $_[0] ] if !defined $_[1];
3660             return [ $_[1] ] if !keys %{$_[0]};
3661             return [$_[0], $_[1]]
3662           },
3663           ARRAY => sub {
3664             return [] if !keys %{$_[0]} and !@{$_[1]};
3665             return [ $_[0] ] if !@{$_[1]};
3666             return $_[1] if !keys %{$_[0]};
3667             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3668             return [ $_[0], @{$_[1]} ];
3669           },
3670           HASH => sub {
3671             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3672             return [ $_[0] ] if !keys %{$_[1]};
3673             return [ $_[1] ] if !keys %{$_[0]};
3674             return [ $_[0] ] if $_[0] eq $_[1];
3675             return [ $_[0], $_[1] ];
3676           },
3677         }
3678       } => 'DBIC_RS_ATTR_MERGER');
3679       $hm;
3680     };
3681
3682     return $hm->merge ($_[1], $_[2]);
3683   }
3684 }
3685
3686 sub STORABLE_freeze {
3687   my ($self, $cloning) = @_;
3688   my $to_serialize = { %$self };
3689
3690   # A cursor in progress can't be serialized (and would make little sense anyway)
3691   delete $to_serialize->{cursor};
3692
3693   # nor is it sensical to store a not-yet-fired-count pager
3694   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3695     delete $to_serialize->{pager};
3696   }
3697
3698   Storable::nfreeze($to_serialize);
3699 }
3700
3701 # need this hook for symmetry
3702 sub STORABLE_thaw {
3703   my ($self, $cloning, $serialized) = @_;
3704
3705   %$self = %{ Storable::thaw($serialized) };
3706
3707   $self;
3708 }
3709
3710
3711 =head2 throw_exception
3712
3713 See L<DBIx::Class::Schema/throw_exception> for details.
3714
3715 =cut
3716
3717 sub throw_exception {
3718   my $self=shift;
3719
3720   if (ref $self and my $rsrc = $self->result_source) {
3721     $rsrc->throw_exception(@_)
3722   }
3723   else {
3724     DBIx::Class::Exception->throw(@_);
3725   }
3726 }
3727
3728 # XXX: FIXME: Attributes docs need clearing up
3729
3730 =head1 ATTRIBUTES
3731
3732 Attributes are used to refine a ResultSet in various ways when
3733 searching for data. They can be passed to any method which takes an
3734 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3735 L</count>.
3736
3737 Default attributes can be set on the result class using
3738 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3739 the CAVEATS on that feature before using it!)
3740
3741 These are in no particular order:
3742
3743 =head2 order_by
3744
3745 =over 4
3746
3747 =item Value: ( $order_by | \@order_by | \%order_by )
3748
3749 =back
3750
3751 Which column(s) to order the results by.
3752
3753 [The full list of suitable values is documented in
3754 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3755 common options.]
3756
3757 If a single column name, or an arrayref of names is supplied, the
3758 argument is passed through directly to SQL. The hashref syntax allows
3759 for connection-agnostic specification of ordering direction:
3760
3761  For descending order:
3762
3763   order_by => { -desc => [qw/col1 col2 col3/] }
3764
3765  For explicit ascending order:
3766
3767   order_by => { -asc => 'col' }
3768
3769 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3770 supported, although you are strongly encouraged to use the hashref
3771 syntax as outlined above.
3772
3773 =head2 columns
3774
3775 =over 4
3776
3777 =item Value: \@columns
3778
3779 =back
3780
3781 Shortcut to request a particular set of columns to be retrieved. Each
3782 column spec may be a string (a table column name), or a hash (in which
3783 case the key is the C<as> value, and the value is used as the C<select>
3784 expression). Adds C<me.> onto the start of any column without a C<.> in
3785 it and sets C<select> from that, then auto-populates C<as> from
3786 C<select> as normal. (You may also use the C<cols> attribute, as in
3787 earlier versions of DBIC.)
3788
3789 Essentially C<columns> does the same as L</select> and L</as>.
3790
3791     columns => [ 'foo', { bar => 'baz' } ]
3792
3793 is the same as
3794
3795     select => [qw/foo baz/],
3796     as => [qw/foo bar/]
3797
3798 =head2 +columns
3799
3800 =over 4
3801
3802 =item Value: \@columns
3803
3804 =back
3805
3806 Indicates additional columns to be selected from storage. Works the same
3807 as L</columns> but adds columns to the selection. (You may also use the
3808 C<include_columns> attribute, as in earlier versions of DBIC). For
3809 example:-
3810
3811   $schema->resultset('CD')->search(undef, {
3812     '+columns' => ['artist.name'],
3813     join => ['artist']
3814   });
3815
3816 would return all CDs and include a 'name' column to the information
3817 passed to object inflation. Note that the 'artist' is the name of the
3818 column (or relationship) accessor, and 'name' is the name of the column
3819 accessor in the related table.
3820
3821 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3822 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3823 unary plus operator before it.
3824
3825 =head2 include_columns
3826
3827 =over 4
3828
3829 =item Value: \@columns
3830
3831 =back
3832
3833 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3834
3835 =head2 select
3836
3837 =over 4
3838
3839 =item Value: \@select_columns
3840
3841 =back
3842
3843 Indicates which columns should be selected from the storage. You can use
3844 column names, or in the case of RDBMS back ends, function or stored procedure
3845 names:
3846
3847   $rs = $schema->resultset('Employee')->search(undef, {
3848     select => [
3849       'name',
3850       { count => 'employeeid' },
3851       { max => { length => 'name' }, -as => 'longest_name' }
3852     ]
3853   });
3854
3855   # Equivalent SQL
3856   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3857
3858 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3859 use L</select>, to instruct DBIx::Class how to store the result of the column.
3860 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3861 identifier aliasing. You can however alias a function, so you can use it in
3862 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3863 attribute> supplied as shown in the example above.
3864
3865 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3866 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3867 unary plus operator before it.
3868
3869 =head2 +select
3870
3871 =over 4
3872
3873 Indicates additional columns to be selected from storage.  Works the same as
3874 L</select> but adds columns to the default selection, instead of specifying
3875 an explicit list.
3876
3877 =back
3878
3879 =head2 +as
3880
3881 =over 4
3882
3883 Indicates additional column names for those added via L</+select>. See L</as>.
3884
3885 =back
3886
3887 =head2 as
3888
3889 =over 4
3890
3891 =item Value: \@inflation_names
3892
3893 =back
3894
3895 Indicates column names for object inflation. That is L</as> indicates the
3896 slot name in which the column value will be stored within the
3897 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3898 identifier by the C<get_column> method (or via the object accessor B<if one
3899 with the same name already exists>) as shown below. The L</as> attribute has
3900 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3901
3902   $rs = $schema->resultset('Employee')->search(undef, {
3903     select => [
3904       'name',
3905       { count => 'employeeid' },
3906       { max => { length => 'name' }, -as => 'longest_name' }
3907     ],
3908     as => [qw/
3909       name
3910       employee_count
3911       max_name_length
3912     /],
3913   });
3914
3915 If the object against which the search is performed already has an accessor
3916 matching a column name specified in C<as>, the value can be retrieved using
3917 the accessor as normal:
3918
3919   my $name = $employee->name();
3920
3921 If on the other hand an accessor does not exist in the object, you need to
3922 use C<get_column> instead:
3923
3924   my $employee_count = $employee->get_column('employee_count');
3925
3926 You can create your own accessors if required - see
3927 L<DBIx::Class::Manual::Cookbook> for details.
3928
3929 =head2 join
3930
3931 =over 4
3932
3933 =item Value: ($rel_name | \@rel_names | \%rel_names)
3934
3935 =back
3936
3937 Contains a list of relationships that should be joined for this query.  For
3938 example:
3939
3940   # Get CDs by Nine Inch Nails
3941   my $rs = $schema->resultset('CD')->search(
3942     { 'artist.name' => 'Nine Inch Nails' },
3943     { join => 'artist' }
3944   );
3945
3946 Can also contain a hash reference to refer to the other relation's relations.
3947 For example:
3948
3949   package MyApp::Schema::Track;
3950   use base qw/DBIx::Class/;
3951   __PACKAGE__->table('track');
3952   __PACKAGE__->add_columns(qw/trackid cd position title/);
3953   __PACKAGE__->set_primary_key('trackid');
3954   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3955   1;
3956
3957   # In your application
3958   my $rs = $schema->resultset('Artist')->search(
3959     { 'track.title' => 'Teardrop' },
3960     {
3961       join     => { cd => 'track' },
3962       order_by => 'artist.name',
3963     }
3964   );
3965
3966 You need to use the relationship (not the table) name in  conditions,
3967 because they are aliased as such. The current table is aliased as "me", so
3968 you need to use me.column_name in order to avoid ambiguity. For example:
3969
3970   # Get CDs from 1984 with a 'Foo' track
3971   my $rs = $schema->resultset('CD')->search(
3972     {
3973       'me.year' => 1984,
3974       'tracks.name' => 'Foo'
3975     },
3976     { join => 'tracks' }
3977   );
3978
3979 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3980 similarly for a third time). For e.g.
3981
3982   my $rs = $schema->resultset('Artist')->search({
3983     'cds.title'   => 'Down to Earth',
3984     'cds_2.title' => 'Popular',
3985   }, {
3986     join => [ qw/cds cds/ ],
3987   });
3988
3989 will return a set of all artists that have both a cd with title 'Down
3990 to Earth' and a cd with title 'Popular'.
3991
3992 If you want to fetch related objects from other tables as well, see C<prefetch>
3993 below.
3994
3995  NOTE: An internal join-chain pruner will discard certain joins while
3996  constructing the actual SQL query, as long as the joins in question do not
3997  affect the retrieved result. This for example includes 1:1 left joins
3998  that are not part of the restriction specification (WHERE/HAVING) nor are
3999  a part of the query selection.
4000
4001 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4002
4003 =head2 prefetch
4004
4005 =over 4
4006
4007 =item Value: ($rel_name | \@rel_names | \%rel_names)
4008
4009 =back
4010
4011 Contains one or more relationships that should be fetched along with
4012 the main query (when they are accessed afterwards the data will
4013 already be available, without extra queries to the database).  This is
4014 useful for when you know you will need the related objects, because it
4015 saves at least one query:
4016
4017   my $rs = $schema->resultset('Tag')->search(
4018     undef,
4019     {
4020       prefetch => {
4021         cd => 'artist'
4022       }
4023     }
4024   );
4025
4026 The initial search results in SQL like the following:
4027
4028   SELECT tag.*, cd.*, artist.* FROM tag
4029   JOIN cd ON tag.cd = cd.cdid
4030   JOIN artist ON cd.artist = artist.artistid
4031
4032 L<DBIx::Class> has no need to go back to the database when we access the
4033 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4034 case.
4035
4036 Simple prefetches will be joined automatically, so there is no need
4037 for a C<join> attribute in the above search.
4038
4039 L</prefetch> can be used with the any of the relationship types and
4040 multiple prefetches can be specified together. Below is a more complex
4041 example that prefetches a CD's artist, its liner notes (if present),
4042 the cover image, the tracks on that cd, and the guests on those
4043 tracks.
4044
4045  # Assuming:
4046  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4047  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4048  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4049  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4050
4051  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4052
4053  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4054
4055
4056  my $rs = $schema->resultset('CD')->search(
4057    undef,
4058    {
4059      prefetch => [
4060        { artist => 'record_label'},  # belongs_to => belongs_to
4061        'liner_note',                 # might_have
4062        'cover_image',                # has_one
4063        { tracks => 'guests' },       # has_many => has_many
4064      ]
4065    }
4066  );
4067
4068 This will produce SQL like the following:
4069
4070  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4071         tracks.*, guests.*
4072    FROM cd me
4073    JOIN artist artist
4074      ON artist.artistid = me.artistid
4075    JOIN record_label record_label
4076      ON record_label.labelid = artist.labelid
4077    LEFT JOIN track tracks
4078      ON tracks.cdid = me.cdid
4079    LEFT JOIN guest guests
4080      ON guests.trackid = track.trackid
4081    LEFT JOIN liner_notes liner_note
4082      ON liner_note.cdid = me.cdid
4083    JOIN cd_artwork cover_image
4084      ON cover_image.cdid = me.cdid
4085  ORDER BY tracks.cd
4086
4087 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4088 C<tracks>, and C<guests> of the CD will all be available through the
4089 relationship accessors without the need for additional queries to the
4090 database.
4091
4092 However, there is one caveat to be observed: it can be dangerous to
4093 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4094 relationship on a given level. e.g.:
4095
4096  my $rs = $schema->resultset('CD')->search(
4097    undef,
4098    {
4099      prefetch => [
4100        'tracks',                         # has_many
4101        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4102      ]
4103    }
4104  );
4105
4106 The collapser currently can't identify duplicate tuples for multiple
4107 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4108 result the second L<has_many|DBIx::Class::Relationship/has_many>
4109 relation could contain redundant objects.
4110
4111 =head3 Using L</prefetch> with L</join>
4112
4113 L</prefetch> implies a L</join> with the equivalent argument, and is
4114 properly merged with any existing L</join> specification. So the
4115 following:
4116
4117   my $rs = $schema->resultset('CD')->search(
4118    {'record_label.name' => 'Music Product Ltd.'},
4119    {
4120      join     => {artist => 'record_label'},
4121      prefetch => 'artist',
4122    }
4123  );
4124
4125 ... will work, searching on the record label's name, but only
4126 prefetching the C<artist>.
4127
4128 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4129
4130 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4131 prefetched relations.  So given:
4132
4133   my $rs = $schema->resultset('CD')->search(
4134    undef,
4135    {
4136      select   => ['cd.title'],
4137      as       => ['cd_title'],
4138      prefetch => 'artist',
4139    }
4140  );
4141
4142 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4143 becomes: C<'cd_title', 'artist.*'>.
4144
4145 =head3 CAVEATS
4146
4147 Prefetch does a lot of deep magic. As such, it may not behave exactly
4148 as you might expect.
4149
4150 =over 4
4151
4152 =item *
4153
4154 Prefetch uses the L</cache> to populate the prefetched relationships. This
4155 may or may not be what you want.
4156
4157 =item *
4158
4159 If you specify a condition on a prefetched relationship, ONLY those
4160 rows that match the prefetched condition will be fetched into that relationship.
4161 This means that adding prefetch to a search() B<may alter> what is returned by
4162 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4163
4164   my $artist_rs = $schema->resultset('Artist')->search({
4165       'cds.year' => 2008,
4166   }, {
4167       join => 'cds',
4168   });
4169
4170   my $count = $artist_rs->first->cds->count;
4171
4172   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4173
4174   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4175
4176   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4177
4178 that cmp_ok() may or may not pass depending on the datasets involved. This
4179 behavior may or may not survive the 0.09 transition.
4180
4181 =back
4182
4183 =head2 alias
4184
4185 =over 4
4186
4187 =item Value: $source_alias
4188
4189 =back
4190
4191 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4192 nested search queries (sub-SELECTs) might need specific aliases set to
4193 reference inner queries.  For example:
4194
4195    my $q = $rs
4196       ->related_resultset('CDs')
4197       ->related_resultset('Tracks')
4198       ->search({
4199          'track.id' => { -ident => 'none_search.id' },
4200       })
4201       ->as_query;
4202
4203    my $ids = $self->search({
4204       -not_exists => $q,
4205    }, {
4206       alias    => 'none_search',
4207       group_by => 'none_search.id',
4208    })->get_column('id')->as_query;
4209
4210    $self->search({ id => { -in => $ids } })
4211
4212 This attribute is directly tied to L</current_source_alias>.
4213
4214 =head2 page
4215
4216 =over 4
4217
4218 =item Value: $page
4219
4220 =back
4221
4222 Makes the resultset paged and specifies the page to retrieve. Effectively
4223 identical to creating a non-pages resultset and then calling ->page($page)
4224 on it.
4225
4226 If L</rows> attribute is not specified it defaults to 10 rows per page.
4227
4228 When you have a paged resultset, L</count> will only return the number
4229 of rows in the page. To get the total, use the L</pager> and call
4230 C<total_entries> on it.
4231
4232 =head2 rows
4233
4234 =over 4
4235
4236 =item Value: $rows
4237
4238 =back
4239
4240 Specifies the maximum number of rows for direct retrieval or the number of
4241 rows per page if the page attribute or method is used.
4242
4243 =head2 offset
4244
4245 =over 4
4246
4247 =item Value: $offset
4248
4249 =back
4250
4251 Specifies the (zero-based) row number for the  first row to be returned, or the
4252 of the first row of the first page if paging is used.
4253
4254 =head2 software_limit
4255
4256 =over 4
4257
4258 =item Value: (0 | 1)
4259
4260 =back
4261
4262 When combined with L</rows> and/or L</offset> the generated SQL will not
4263 include any limit dialect stanzas. Instead the entire result will be selected
4264 as if no limits were specified, and DBIC will perform the limit locally, by
4265 artificially advancing and finishing the resulting L</cursor>.
4266
4267 This is the recommended way of performing resultset limiting when no sane RDBMS
4268 implementation is available (e.g.
4269 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4270 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4271
4272 =head2 group_by
4273
4274 =over 4
4275
4276 =item Value: \@columns
4277
4278 =back
4279
4280 A arrayref of columns to group by. Can include columns of joined tables.
4281
4282   group_by => [qw/ column1 column2 ... /]
4283
4284 =head2 having
4285
4286 =over 4
4287
4288 =item Value: $condition
4289
4290 =back
4291
4292 HAVING is a select statement attribute that is applied between GROUP BY and
4293 ORDER BY. It is applied to the after the grouping calculations have been
4294 done.
4295
4296   having => { 'count_employee' => { '>=', 100 } }
4297
4298 or with an in-place function in which case literal SQL is required:
4299
4300   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4301
4302 =head2 distinct
4303
4304 =over 4
4305
4306 =item Value: (0 | 1)
4307
4308 =back
4309
4310 Set to 1 to group by all columns. If the resultset already has a group_by
4311 attribute, this setting is ignored and an appropriate warning is issued.
4312
4313 =head2 where
4314
4315 =over 4
4316
4317 Adds to the WHERE clause.
4318
4319   # only return rows WHERE deleted IS NULL for all searches
4320   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4321
4322 Can be overridden by passing C<< { where => undef } >> as an attribute
4323 to a resultset.
4324
4325 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4326
4327 =back
4328
4329 =head2 cache
4330
4331 Set to 1 to cache search results. This prevents extra SQL queries if you
4332 revisit rows in your ResultSet:
4333
4334   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4335
4336   while( my $artist = $resultset->next ) {
4337     ... do stuff ...
4338   }
4339
4340   $rs->first; # without cache, this would issue a query
4341
4342 By default, searches are not cached.
4343
4344 For more examples of using these attributes, see
4345 L<DBIx::Class::Manual::Cookbook>.
4346
4347 =head2 for
4348
4349 =over 4
4350
4351 =item Value: ( 'update' | 'shared' | \$scalar )
4352
4353 =back
4354
4355 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4356 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4357 query.
4358
4359 =head1 DBIC BIND VALUES
4360
4361 Because DBIC may need more information to bind values than just the column name
4362 and value itself, it uses a special format for both passing and receiving bind
4363 values.  Each bind value should be composed of an arrayref of
4364 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4365
4366 =over 4
4367
4368 =item dbd_attrs
4369
4370 If present (in any form), this is what is being passed directly to bind_param.
4371 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4372 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4373
4374 If this is specified, all other bind options described below are ignored.
4375
4376 =item sqlt_datatype
4377
4378 If present, this is used to infer the actual bind attribute by passing to
4379 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4380 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4381
4382 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4383 currently drivers are expected to "Do the Right Thing" when given a common
4384 datatype name.  (Not ideal, but that's what we got at this point.)
4385
4386 =item sqlt_size
4387
4388 Currently used to correctly allocate buffers for bind_param_inout().
4389 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4390 or to a sensible value based on the "data_type".
4391
4392 =item dbic_colname
4393
4394 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4395 explicitly specified they are never overriden).  Also used by some weird DBDs,
4396 where the column name should be available at bind_param time (e.g. Oracle).
4397
4398 =back
4399
4400 For backwards compatibility and convenience, the following shortcuts are
4401 supported:
4402
4403   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4404   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4405   [ undef,   $val ] === [ {}, $val ]
4406
4407 =head1 AUTHOR AND CONTRIBUTORS
4408
4409 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4410
4411 =head1 LICENSE
4412
4413 You may distribute this code under the same terms as Perl itself.
4414
4415 =cut
4416
4417 1;